Merge branch 'terencehill/automatic_sendcvar' into 'master'
[xonotic/xonotic-data.pk3dir.git] / qcsrc / server / client.qc
1 #include "client.qh"
2
3 #include <server/defs.qh>
4 #include <server/miscfunctions.qh>
5 #include <common/effects/all.qh>
6 #include "anticheat.qh"
7 #include "impulse.qh"
8 #include "player.qh"
9 #include "ipban.qh"
10 #include "miscfunctions.qh"
11 #include "portals.qh"
12 #include "teamplay.qh"
13 #include "spawnpoints.qh"
14 #include "resources.qh"
15 #include "g_damage.qh"
16 #include "handicap.qh"
17 #include "g_hook.qh"
18 #include "command/common.qh"
19 #include "command/vote.qh"
20 #include "clientkill.qh"
21 #include "cheats.qh"
22 #include "g_world.qh"
23 #include "race.qh"
24 #include "antilag.qh"
25 #include "campaign.qh"
26 #include "command/common.qh"
27 #include "scores_rules.qh"
28
29 #include "bot/api.qh"
30
31 #include "../common/ent_cs.qh"
32 #include "../common/wepent.qh"
33 #include <common/state.qh>
34
35 #include "compat/quake3.qh"
36
37 #include <common/effects/qc/globalsound.qh>
38
39 #include "../common/mapobjects/func/conveyor.qh"
40 #include "../common/mapobjects/teleporters.qh"
41 #include "../common/mapobjects/target/spawnpoint.qh"
42 #include <common/mapobjects/trigger/counter.qh>
43
44 #include "../common/vehicles/all.qh"
45
46 #include "weapons/hitplot.qh"
47 #include "weapons/weaponsystem.qh"
48
49 #include "../common/net_notice.qh"
50 #include "../common/net_linked.qh"
51 #include "../common/physics/player.qh"
52
53 #include <common/vehicles/sv_vehicles.qh>
54
55 #include "../common/items/_mod.qh"
56
57 #include "../common/mutators/mutator/waypoints/all.qh"
58 #include "../common/mutators/mutator/instagib/sv_instagib.qh"
59 #include <common/gamemodes/_mod.qh>
60
61 #include "../common/mapobjects/subs.qh"
62 #include "../common/mapobjects/triggers.qh"
63 #include "../common/mapobjects/trigger/secret.qh"
64
65 #include "../common/minigames/sv_minigames.qh"
66
67 #include "../common/items/inventory.qh"
68
69 #include "../common/monsters/sv_monsters.qh"
70
71 #include "../lib/warpzone/server.qh"
72
73 #include <common/mutators/mutator/overkill/oknex.qh>
74
75 STATIC_METHOD(Client, Add, void(Client this, int _team))
76 {
77     ClientConnect(this);
78     TRANSMUTE(Player, this);
79     this.frame = 12; // 7
80     this.team = _team;
81     PutClientInServer(this);
82 }
83
84 STATIC_METHOD(Client, Remove, void(Client this))
85 {
86     TRANSMUTE(Observer, this);
87     PutClientInServer(this);
88     ClientDisconnect(this);
89 }
90
91 void send_CSQC_teamnagger() {
92         WriteHeader(MSG_BROADCAST, TE_CSQC_TEAMNAGGER);
93 }
94
95 int CountSpectators(entity player, entity to)
96 {
97         if(!player) { return 0; } // not sure how, but best to be safe
98
99         int spec_count = 0;
100
101         FOREACH_CLIENT(IS_REAL_CLIENT(it) && IS_SPEC(it) && it != to && it.enemy == player,
102         {
103                 spec_count++;
104         });
105
106         return spec_count;
107 }
108
109 void WriteSpectators(entity player, entity to)
110 {
111         if(!player) { return; } // not sure how, but best to be safe
112
113         FOREACH_CLIENT(IS_REAL_CLIENT(it) && IS_SPEC(it) && it != to && it.enemy == player,
114         {
115                 WriteByte(MSG_ENTITY, num_for_edict(it));
116         });
117 }
118
119 bool ClientData_Send(entity this, entity to, int sf)
120 {
121         assert(to == this.owner, return false);
122
123         entity e = to;
124         if (IS_SPEC(e)) e = e.enemy;
125
126         sf = 0;
127         if (CS(e).race_completed)       sf |= BIT(0); // forced scoreboard
128         if (CS(to).spectatee_status)    sf |= BIT(1); // spectator ent number follows
129         if (CS(e).zoomstate)            sf |= BIT(2); // zoomed
130         if (autocvar_sv_showspectators) sf |= BIT(4); // show spectators
131
132         WriteHeader(MSG_ENTITY, ENT_CLIENT_CLIENTDATA);
133         WriteByte(MSG_ENTITY, sf);
134
135         if (sf & BIT(1))
136                 WriteByte(MSG_ENTITY, CS(to).spectatee_status);
137
138         if(sf & BIT(4))
139         {
140                 float specs = CountSpectators(e, to);
141                 WriteByte(MSG_ENTITY, specs);
142                 WriteSpectators(e, to);
143         }
144
145         return true;
146 }
147
148 void ClientData_Attach(entity this)
149 {
150         Net_LinkEntity(CS(this).clientdata = new_pure(clientdata), false, 0, ClientData_Send);
151         CS(this).clientdata.drawonlytoclient = this;
152         CS(this).clientdata.owner = this;
153 }
154
155 void ClientData_Detach(entity this)
156 {
157         delete(CS(this).clientdata);
158         CS(this).clientdata = NULL;
159 }
160
161 void ClientData_Touch(entity e)
162 {
163         entity cd = CS(e).clientdata;
164         if (cd) { cd.SendFlags = 1; }
165
166         // make it spectatable
167         FOREACH_CLIENT(IS_REAL_CLIENT(it) && it != e && IS_SPEC(it) && it.enemy == e,
168         {
169                 entity cd = CS(it).clientdata;
170                 if (cd) { cd.SendFlags = 1; }
171         });
172 }
173
174
175 /*
176 =============
177 CheckPlayerModel
178
179 Checks if the argument string can be a valid playermodel.
180 Returns a valid one in doubt.
181 =============
182 */
183 string FallbackPlayerModel;
184 string CheckPlayerModel(string plyermodel) {
185         if(FallbackPlayerModel != cvar_defstring("_cl_playermodel"))
186         {
187                 // note: we cannot summon Don Strunzone here, some player may
188                 // still have the model string set. In case anyone manages how
189                 // to change a cvar default, we'll have a small leak here.
190                 FallbackPlayerModel = strzone(cvar_defstring("_cl_playermodel"));
191         }
192         // only in right path
193         if( substring(plyermodel,0,14) != "models/player/")
194                 return FallbackPlayerModel;
195         // only good file extensions
196         if(substring(plyermodel,-4,4) != ".zym")
197         if(substring(plyermodel,-4,4) != ".dpm")
198         if(substring(plyermodel,-4,4) != ".iqm")
199         if(substring(plyermodel,-4,4) != ".md3")
200         if(substring(plyermodel,-4,4) != ".psk")
201                 return FallbackPlayerModel;
202         // forbid the LOD models
203         if(substring(plyermodel, -9,5) == "_lod1")
204                 return FallbackPlayerModel;
205         if(substring(plyermodel, -9,5) == "_lod2")
206                 return FallbackPlayerModel;
207         if(plyermodel != strtolower(plyermodel))
208                 return FallbackPlayerModel;
209         // also, restrict to server models
210         if(autocvar_sv_servermodelsonly)
211         {
212                 if(!fexists(plyermodel))
213                         return FallbackPlayerModel;
214         }
215         return plyermodel;
216 }
217
218 void setplayermodel(entity e, string modelname)
219 {
220         precache_model(modelname);
221         _setmodel(e, modelname);
222         player_setupanimsformodel(e);
223         if(!autocvar_g_debug_globalsounds)
224                 UpdatePlayerSounds(e);
225 }
226
227 /** putting a client as observer in the server */
228 void PutObserverInServer(entity this)
229 {
230     bool mutator_returnvalue = MUTATOR_CALLHOOK(MakePlayerObserver, this);
231         PlayerState_detach(this);
232
233         if (IS_PLAYER(this))
234         {
235                 if(GetResource(this, RES_HEALTH) >= 1)
236                 {
237                         // despawn effect
238                         Send_Effect(EFFECT_SPAWN_NEUTRAL, this.origin, '0 0 0', 1);
239                 }
240
241                 // was a player, recount votes and ready status
242                 if(IS_REAL_CLIENT(this))
243                 {
244                         if (vote_called) { VoteCount(false); }
245                         ReadyCount();
246                 }
247     }
248
249     {
250         entity spot = SelectSpawnPoint(this, true);
251         if (!spot) LOG_FATAL("No spawnpoints for observers?!?");
252         this.angles = vec2(spot.angles);
253         this.fixangle = true;
254         // offset it so that the spectator spawns higher off the ground, looks better this way
255         setorigin(this, spot.origin + STAT(PL_VIEW_OFS, this));
256         if (IS_REAL_CLIENT(this))
257         {
258             msg_entity = this;
259             WriteByte(MSG_ONE, SVC_SETVIEW);
260             WriteEntity(MSG_ONE, this);
261         }
262         // give the spectator some space between walls for MOVETYPE_FLY_WORLDONLY
263         // so that your view doesn't go into the ceiling with MOVETYPE_FLY_WORLDONLY, previously "PL_VIEW_OFS"
264         if(!autocvar_g_debug_globalsounds)
265         {
266                 // needed for player sounds
267                 this.model = "";
268                 FixPlayermodel(this);
269         }
270         setmodel(this, MDL_Null);
271         setsize(this, STAT(PL_CROUCH_MIN, this), STAT(PL_CROUCH_MAX, this));
272         this.view_ofs = '0 0 0';
273     }
274
275     RemoveGrapplingHooks(this);
276         Portal_ClearAll(this);
277         Unfreeze(this, false);
278         SetSpectatee(this, NULL);
279
280         if (this.alivetime)
281         {
282                 if (!warmup_stage)
283                         PlayerStats_GameReport_Event_Player(this, PLAYERSTATS_ALIVETIME, time - this.alivetime);
284                 this.alivetime = 0;
285         }
286
287         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
288
289         WaypointSprite_PlayerDead(this);
290
291         if (CS(this).killcount != FRAGS_SPECTATOR)
292         {
293                 if(!game_stopped)
294                 if(autocvar_g_chat_nospectators == 1 || (!warmup_stage && autocvar_g_chat_nospectators == 2))
295                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_CHAT_NOSPECTATORS);
296         }
297
298         accuracy_resend(this);
299
300         CS(this).spectatortime = time;
301         if(this.bot_attack)
302                 IL_REMOVE(g_bot_targets, this);
303         this.bot_attack = false;
304         if(this.monster_attack)
305                 IL_REMOVE(g_monster_targets, this);
306         this.monster_attack = false;
307     STAT(HUD, this) = HUD_NORMAL;
308         TRANSMUTE(Observer, this);
309         this.iscreature = false;
310         this.teleportable = TELEPORT_SIMPLE;
311         if(this.damagedbycontents)
312                 IL_REMOVE(g_damagedbycontents, this);
313         this.damagedbycontents = false;
314         SetResourceExplicit(this, RES_HEALTH, FRAGS_SPECTATOR);
315         SetSpectatee_status(this, etof(this));
316         this.takedamage = DAMAGE_NO;
317         this.solid = SOLID_NOT;
318         set_movetype(this, MOVETYPE_FLY_WORLDONLY); // user preference is controlled by playerprethink
319         this.flags = FL_CLIENT | FL_NOTARGET;
320         this.effects = 0;
321         SetResourceExplicit(this, RES_ARMOR, autocvar_g_balance_armor_start); // was 666?!
322         this.pauserotarmor_finished = 0;
323         this.pauserothealth_finished = 0;
324         this.pauseregen_finished = 0;
325         this.damageforcescale = 0;
326         this.death_time = 0;
327         this.respawn_flags = 0;
328         this.respawn_time = 0;
329         STAT(RESPAWN_TIME, this) = 0;
330         this.alpha = 0;
331         this.scale = 0;
332         this.fade_time = 0;
333         this.pain_frame = 0;
334         this.pain_finished = 0;
335         this.strength_finished = 0;
336         this.invincible_finished = 0;
337         this.superweapons_finished = 0;
338         //this.dphitcontentsmask = 0;
339         this.dphitcontentsmask = DPCONTENTS_SOLID;
340         if (autocvar_g_playerclip_collisions)
341                 this.dphitcontentsmask |= DPCONTENTS_PLAYERCLIP;
342         this.pushltime = 0;
343         this.istypefrag = 0;
344         setthink(this, func_null);
345         this.nextthink = 0;
346         this.deadflag = DEAD_NO;
347         this.crouch = false;
348         STAT(REVIVE_PROGRESS, this) = 0;
349         this.revival_time = 0;
350         this.draggable = drag_undraggable;
351
352         this.items = 0;
353         STAT(WEAPONS, this) = '0 0 0';
354         this.drawonlytoclient = this;
355
356         this.viewloc = NULL;
357
358         //this.spawnpoint_targ = NULL; // keep it so they can return to where they were?
359
360         this.weaponmodel = "";
361         for (int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
362         {
363                 this.weaponentities[slot] = NULL;
364         }
365         this.exteriorweaponentity = NULL;
366         CS(this).killcount = FRAGS_SPECTATOR;
367         this.velocity = '0 0 0';
368         this.avelocity = '0 0 0';
369         this.punchangle = '0 0 0';
370         this.punchvector = '0 0 0';
371         this.oldvelocity = this.velocity;
372         this.fire_endtime = -1;
373         this.event_damage = func_null;
374         this.event_heal = func_null;
375
376         for(int slot = 0; slot < MAX_AXH; ++slot)
377         {
378                 entity axh = this.(AuxiliaryXhair[slot]);
379                 this.(AuxiliaryXhair[slot]) = NULL;
380
381                 if(axh.owner == this && axh != NULL && !wasfreed(axh))
382                         delete(axh);
383         }
384
385         if (mutator_returnvalue)
386         {
387                 // mutator prevents resetting teams+score
388         }
389         else
390         {
391                 SetPlayerTeam(this, -1, TEAM_CHANGE_SPECTATOR);
392                 this.frags = FRAGS_SPECTATOR;
393         }
394         if (CS(this).just_joined)
395                 CS(this).just_joined = false;
396 }
397
398 int player_getspecies(entity this)
399 {
400         get_model_parameters(this.model, this.skin);
401         int s = get_model_parameters_species;
402         get_model_parameters(string_null, 0);
403         if (s < 0) return SPECIES_HUMAN;
404         return s;
405 }
406
407 .float model_randomizer;
408 void FixPlayermodel(entity player)
409 {
410         string defaultmodel = "";
411         int defaultskin = 0;
412         if(autocvar_sv_defaultcharacter)
413         {
414                 if(teamplay)
415                 {
416                         switch(player.team)
417                         {
418                                 case NUM_TEAM_1: defaultmodel = autocvar_sv_defaultplayermodel_red; defaultskin = autocvar_sv_defaultplayerskin_red; break;
419                                 case NUM_TEAM_2: defaultmodel = autocvar_sv_defaultplayermodel_blue; defaultskin = autocvar_sv_defaultplayerskin_blue; break;
420                                 case NUM_TEAM_3: defaultmodel = autocvar_sv_defaultplayermodel_yellow; defaultskin = autocvar_sv_defaultplayerskin_yellow; break;
421                                 case NUM_TEAM_4: defaultmodel = autocvar_sv_defaultplayermodel_pink; defaultskin = autocvar_sv_defaultplayerskin_pink; break;
422                         }
423                 }
424
425                 if(defaultmodel == "")
426                 {
427                         defaultmodel = autocvar_sv_defaultplayermodel;
428                         defaultskin = autocvar_sv_defaultplayerskin;
429                 }
430
431                 int n = tokenize_console(defaultmodel);
432                 if(n > 0)
433                 {
434                         defaultmodel = argv(floor(n * CS(player).model_randomizer));
435                         // However, do NOT randomize if the player-selected model is in the list.
436                         for (int i = 0; i < n; ++i)
437                                 if ((argv(i) == player.playermodel && defaultskin == stof(player.playerskin)) || argv(i) == strcat(player.playermodel, ":", player.playerskin))
438                                         defaultmodel = argv(i);
439                 }
440
441                 int i = strstrofs(defaultmodel, ":", 0);
442                 if(i >= 0)
443                 {
444                         defaultskin = stof(substring(defaultmodel, i+1, -1));
445                         defaultmodel = substring(defaultmodel, 0, i);
446                 }
447         }
448         if(autocvar_sv_defaultcharacterskin && !defaultskin)
449         {
450                 if(teamplay)
451                 {
452                         switch(player.team)
453                         {
454                                 case NUM_TEAM_1: defaultskin = autocvar_sv_defaultplayerskin_red; break;
455                                 case NUM_TEAM_2: defaultskin = autocvar_sv_defaultplayerskin_blue; break;
456                                 case NUM_TEAM_3: defaultskin = autocvar_sv_defaultplayerskin_yellow; break;
457                                 case NUM_TEAM_4: defaultskin = autocvar_sv_defaultplayerskin_pink; break;
458                         }
459                 }
460
461                 if(!defaultskin)
462                         defaultskin = autocvar_sv_defaultplayerskin;
463         }
464
465         MUTATOR_CALLHOOK(FixPlayermodel, defaultmodel, defaultskin, player);
466         defaultmodel = M_ARGV(0, string);
467         defaultskin = M_ARGV(1, int);
468
469         bool chmdl = false;
470         int oldskin;
471         if(defaultmodel != "")
472         {
473                 if (defaultmodel != player.model)
474                 {
475                         vector m1 = player.mins;
476                         vector m2 = player.maxs;
477                         setplayermodel (player, defaultmodel);
478                         setsize (player, m1, m2);
479                         chmdl = true;
480                 }
481
482                 oldskin = player.skin;
483                 player.skin = defaultskin;
484         } else {
485                 if (player.playermodel != player.model || player.playermodel == "")
486                 {
487                         player.playermodel = CheckPlayerModel(player.playermodel); // this is never "", so no endless loop
488                         vector m1 = player.mins;
489                         vector m2 = player.maxs;
490                         setplayermodel (player, player.playermodel);
491                         setsize (player, m1, m2);
492                         chmdl = true;
493                 }
494
495                 if(!autocvar_sv_defaultcharacterskin)
496                 {
497                         oldskin = player.skin;
498                         player.skin = stof(player.playerskin);
499                 }
500                 else
501                 {
502                         oldskin = player.skin;
503                         player.skin = defaultskin;
504                 }
505         }
506
507         if(chmdl || oldskin != player.skin) // model or skin has changed
508         {
509                 player.species = player_getspecies(player); // update species
510                 if(!autocvar_g_debug_globalsounds)
511                         UpdatePlayerSounds(player); // update skin sounds
512         }
513
514         if(!teamplay)
515                 if(strlen(autocvar_sv_defaultplayercolors))
516                         if(player.clientcolors != stof(autocvar_sv_defaultplayercolors))
517                                 setcolor(player, stof(autocvar_sv_defaultplayercolors));
518 }
519
520 void PutPlayerInServer(entity this)
521 {
522         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
523
524         PlayerState_attach(this);
525         accuracy_resend(this);
526
527         if (this.team < 0)
528                 TeamBalance_JoinBestTeam(this);
529
530         entity spot = SelectSpawnPoint(this, false);
531         if (!spot) {
532                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_JOIN_NOSPAWNS);
533                 return; // spawn failed
534         }
535
536         TRANSMUTE(Player, this);
537
538         CS(this).wasplayer = true;
539         this.iscreature = true;
540         this.teleportable = TELEPORT_NORMAL;
541         if(!this.damagedbycontents)
542                 IL_PUSH(g_damagedbycontents, this);
543         this.damagedbycontents = true;
544         set_movetype(this, MOVETYPE_WALK);
545         this.solid = SOLID_SLIDEBOX;
546         this.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_SOLID;
547         if (autocvar_g_playerclip_collisions)
548                 this.dphitcontentsmask |= DPCONTENTS_PLAYERCLIP;
549         if (IS_BOT_CLIENT(this) && autocvar_g_botclip_collisions)
550                 this.dphitcontentsmask |= DPCONTENTS_BOTCLIP;
551         this.frags = FRAGS_PLAYER;
552         if (INDEPENDENT_PLAYERS) MAKE_INDEPENDENT_PLAYER(this);
553         this.flags = FL_CLIENT | FL_PICKUPITEMS;
554         if (autocvar__notarget)
555                 this.flags |= FL_NOTARGET;
556         this.takedamage = DAMAGE_AIM;
557         this.effects = EF_TELEPORT_BIT | EF_RESTARTANIM_BIT;
558
559         if (warmup_stage) {
560                 SetResource(this, RES_SHELLS, warmup_start_ammo_shells);
561                 SetResource(this, RES_BULLETS, warmup_start_ammo_nails);
562                 SetResource(this, RES_ROCKETS, warmup_start_ammo_rockets);
563                 SetResource(this, RES_CELLS, warmup_start_ammo_cells);
564                 SetResource(this, RES_PLASMA, warmup_start_ammo_plasma);
565                 SetResource(this, RES_FUEL, warmup_start_ammo_fuel);
566                 SetResource(this, RES_HEALTH, warmup_start_health);
567                 SetResource(this, RES_ARMOR, warmup_start_armorvalue);
568                 STAT(WEAPONS, this) = WARMUP_START_WEAPONS;
569         } else {
570                 SetResource(this, RES_SHELLS, start_ammo_shells);
571                 SetResource(this, RES_BULLETS, start_ammo_nails);
572                 SetResource(this, RES_ROCKETS, start_ammo_rockets);
573                 SetResource(this, RES_CELLS, start_ammo_cells);
574                 SetResource(this, RES_PLASMA, start_ammo_plasma);
575                 SetResource(this, RES_FUEL, start_ammo_fuel);
576                 SetResource(this, RES_HEALTH, start_health);
577                 SetResource(this, RES_ARMOR, start_armorvalue);
578                 STAT(WEAPONS, this) = start_weapons;
579                 if (MUTATOR_CALLHOOK(ForbidRandomStartWeapons, this) == false)
580                 {
581                         GiveRandomWeapons(this, random_start_weapons_count,
582                                 autocvar_g_random_start_weapons, random_start_ammo);
583                 }
584         }
585         SetSpectatee_status(this, 0);
586
587         PS(this).dual_weapons = '0 0 0';
588
589         this.superweapons_finished = (STAT(WEAPONS, this) & WEPSET_SUPERWEAPONS) ? time + autocvar_g_balance_superweapons_time : 0;
590
591         this.items = start_items;
592
593         this.spawnshieldtime = time + autocvar_g_spawnshieldtime;
594         this.pauserotarmor_finished = time + autocvar_g_balance_pause_armor_rot_spawn;
595         this.pauserothealth_finished = time + autocvar_g_balance_pause_health_rot_spawn;
596         this.pauserotfuel_finished = time + autocvar_g_balance_pause_fuel_rot_spawn;
597         this.pauseregen_finished = time + autocvar_g_balance_pause_health_regen_spawn;
598         if (!sv_ready_restart_after_countdown && time < game_starttime)
599         {
600                 float f = game_starttime - time;
601                 this.spawnshieldtime += f;
602                 this.pauserotarmor_finished += f;
603                 this.pauserothealth_finished += f;
604                 this.pauseregen_finished += f;
605         }
606
607         this.damageforcescale = 2;
608         this.death_time = 0;
609         this.respawn_flags = 0;
610         this.respawn_time = 0;
611         STAT(RESPAWN_TIME, this) = 0;
612         this.scale = autocvar_sv_player_scale;
613         this.fade_time = 0;
614         this.pain_frame = 0;
615         this.pain_finished = 0;
616         this.pushltime = 0;
617         setthink(this, func_null); // players have no think function
618         this.nextthink = 0;
619         this.dmg_team = 0;
620         PS(this).ballistics_density = autocvar_g_ballistics_density_player;
621
622         this.deadflag = DEAD_NO;
623
624         this.angles = spot.angles;
625         this.angles_z = 0; // never spawn tilted even if the spot says to
626         if (IS_BOT_CLIENT(this))
627         {
628                 this.v_angle = this.angles;
629                 bot_aim_reset(this);
630         }
631         this.fixangle = true; // turn this way immediately
632         this.oldvelocity = this.velocity = '0 0 0';
633         this.avelocity = '0 0 0';
634         this.punchangle = '0 0 0';
635         this.punchvector = '0 0 0';
636
637         this.strength_finished = 0;
638         this.invincible_finished = 0;
639         this.fire_endtime = -1;
640         STAT(REVIVE_PROGRESS, this) = 0;
641         this.revival_time = 0;
642
643         this.air_finished = time + 12;
644         this.waterlevel = WATERLEVEL_NONE;
645         this.watertype = CONTENT_EMPTY;
646
647         entity spawnevent = new_pure(spawnevent);
648         spawnevent.owner = this;
649         Net_LinkEntity(spawnevent, false, 0.5, SpawnEvent_Send);
650
651         // Cut off any still running player sounds.
652         stopsound(this, CH_PLAYER_SINGLE);
653
654         this.model = "";
655         FixPlayermodel(this);
656         this.drawonlytoclient = NULL;
657
658         this.viewloc = NULL;
659
660         for(int slot = 0; slot < MAX_AXH; ++slot)
661         {
662                 entity axh = this.(AuxiliaryXhair[slot]);
663                 this.(AuxiliaryXhair[slot]) = NULL;
664
665                 if(axh.owner == this && axh != NULL && !wasfreed(axh))
666                         delete(axh);
667         }
668
669         this.spawnpoint_targ = NULL;
670
671         this.crouch = false;
672         this.view_ofs = STAT(PL_VIEW_OFS, this);
673         setsize(this, STAT(PL_MIN, this), STAT(PL_MAX, this));
674         this.spawnorigin = spot.origin;
675         setorigin(this, spot.origin + '0 0 1' * (1 - this.mins.z - 24));
676         // don't reset back to last position, even if new position is stuck in solid
677         this.oldorigin = this.origin;
678         if(this.conveyor)
679                 IL_REMOVE(g_conveyed, this);
680         this.conveyor = NULL; // prevent conveyors at the previous location from moving a freshly spawned player
681         STAT(HUD, this) = HUD_NORMAL;
682
683         this.event_damage = PlayerDamage;
684         this.event_heal = PlayerHeal;
685
686         this.draggable = func_null;
687
688         if(!this.bot_attack)
689                 IL_PUSH(g_bot_targets, this);
690         this.bot_attack = true;
691         if(!this.monster_attack)
692                 IL_PUSH(g_monster_targets, this);
693         this.monster_attack = true;
694         navigation_dynamicgoal_init(this, false);
695
696         PHYS_INPUT_BUTTON_ATCK(this) = PHYS_INPUT_BUTTON_JUMP(this) = PHYS_INPUT_BUTTON_ATCK2(this) = false;
697
698         // player was spectator
699         if (CS(this).killcount == FRAGS_SPECTATOR) {
700                 PlayerScore_Clear(this);
701                 CS(this).killcount = 0;
702                 CS(this).startplaytime = time;
703         }
704
705         for (int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
706         {
707                 .entity weaponentity = weaponentities[slot];
708                 entity oldwep = this.(weaponentity);
709                 CL_SpawnWeaponentity(this, weaponentity);
710                 if(oldwep && oldwep.owner == this)
711                         this.(weaponentity).m_gunalign = oldwep.m_gunalign;
712         }
713         this.alpha = default_player_alpha;
714         this.colormod = '1 1 1' * autocvar_g_player_brightness;
715         this.exteriorweaponentity.alpha = default_weapon_alpha;
716
717         this.speedrunning = false;
718
719         this.counter_cnt = 0;
720         this.fragsfilter_cnt = 0;
721
722         target_voicescript_clear(this);
723
724         // reset fields the weapons may use
725         FOREACH(Weapons, true, {
726                 it.wr_resetplayer(it, this);
727                         // reload all reloadable weapons
728                 if (it.spawnflags & WEP_FLAG_RELOADABLE) {
729                         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
730                         {
731                                 .entity weaponentity = weaponentities[slot];
732                                 this.(weaponentity).weapon_load[it.m_id] = it.reloading_ammo;
733                         }
734                 }
735         });
736
737         {
738                 string s = spot.target;
739                 if(g_assault || g_race) // TODO: make targeting work in assault & race without this hack
740                         spot.target = string_null;
741                 SUB_UseTargets(spot, this, NULL);
742                 if(g_assault || g_race)
743                         spot.target = s;
744         }
745
746         Unfreeze(this, false);
747
748         MUTATOR_CALLHOOK(PlayerSpawn, this, spot);
749
750         if (autocvar_spawn_debug)
751         {
752                 sprint(this, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
753                 delete(spot); // usefull for checking if there are spawnpoints, that let drop through the floor
754         }
755
756         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
757         {
758                 .entity weaponentity = weaponentities[slot];
759                 if(slot == 0 || autocvar_g_weaponswitch_debug == 1)
760                         this.(weaponentity).m_switchweapon = w_getbestweapon(this, weaponentity);
761                 else
762                         this.(weaponentity).m_switchweapon = WEP_Null;
763                 this.(weaponentity).m_weapon = WEP_Null;
764                 this.(weaponentity).weaponname = "";
765                 this.(weaponentity).m_switchingweapon = WEP_Null;
766                 this.(weaponentity).cnt = -1;
767         }
768
769         MUTATOR_CALLHOOK(PlayerWeaponSelect, this);
770
771         if (CS(this).impulse) ImpulseCommands(this);
772
773         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
774         {
775                 .entity weaponentity = weaponentities[slot];
776                 W_WeaponFrame(this, weaponentity);
777         }
778
779         if (!warmup_stage && !this.alivetime)
780                 this.alivetime = time;
781
782         antilag_clear(this, CS(this));
783 }
784
785 /** Called when a client spawns in the server */
786 void PutClientInServer(entity this)
787 {
788         if (IS_BOT_CLIENT(this)) {
789                 TRANSMUTE(Player, this);
790         } else if (IS_REAL_CLIENT(this)) {
791                 msg_entity = this;
792                 WriteByte(MSG_ONE, SVC_SETVIEW);
793                 WriteEntity(MSG_ONE, this);
794         }
795         if (game_stopped)
796                 TRANSMUTE(Observer, this);
797
798         SetSpectatee(this, NULL);
799
800         // reset player keys
801         if(PS(this))
802                 PS(this).itemkeys = 0;
803
804         MUTATOR_CALLHOOK(PutClientInServer, this);
805
806         if (IS_OBSERVER(this)) {
807                 PutObserverInServer(this);
808         } else if (IS_PLAYER(this)) {
809                 PutPlayerInServer(this);
810         }
811 }
812
813 // TODO do we need all these fields, or should we stop autodetecting runtime
814 // changes and just have a console command to update this?
815 bool ClientInit_SendEntity(entity this, entity to, int sf)
816 {
817         WriteHeader(MSG_ENTITY, _ENT_CLIENT_INIT);
818         return = true;
819         msg_entity = to;
820         // MSG_INIT replacement
821         // TODO: make easier to use
822         Registry_send_all();
823         W_PROP_reload(MSG_ONE, to);
824         ClientInit_misc(this);
825         MUTATOR_CALLHOOK(Ent_Init);
826 }
827 void ClientInit_misc(entity this)
828 {
829         int channel = MSG_ONE;
830         WriteHeader(channel, ENT_CLIENT_INIT);
831         WriteByte(channel, g_nexball_meter_period * 32);
832         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[0]));
833         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[1]));
834         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[2]));
835         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[3]));
836         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[0]));
837         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[1]));
838         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[2]));
839         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[3]));
840
841         if(sv_foginterval && world.fog != "")
842                 WriteString(channel, world.fog);
843         else
844                 WriteString(channel, "");
845         WriteByte(channel, this.count * 255.0); // g_balance_armor_blockpercent
846         WriteByte(channel, this.cnt * 255.0); // g_balance_damagepush_speedfactor
847         WriteByte(channel, serverflags);
848         WriteCoord(channel, autocvar_g_trueaim_minrange);
849 }
850
851 void ClientInit_CheckUpdate(entity this)
852 {
853         this.nextthink = time;
854         if(this.count != autocvar_g_balance_armor_blockpercent)
855         {
856                 this.count = autocvar_g_balance_armor_blockpercent;
857                 this.SendFlags |= 1;
858         }
859         if(this.cnt != autocvar_g_balance_damagepush_speedfactor)
860         {
861                 this.cnt = autocvar_g_balance_damagepush_speedfactor;
862                 this.SendFlags |= 1;
863         }
864 }
865
866 void ClientInit_Spawn()
867 {
868         entity e = new_pure(clientinit);
869         setthink(e, ClientInit_CheckUpdate);
870         Net_LinkEntity(e, false, 0, ClientInit_SendEntity);
871
872         ClientInit_CheckUpdate(e);
873 }
874
875 /*
876 =============
877 SetNewParms
878 =============
879 */
880 void SetNewParms ()
881 {
882         // initialize parms for a new player
883         parm1 = -(86400 * 366);
884
885         MUTATOR_CALLHOOK(SetNewParms);
886 }
887
888 /*
889 =============
890 SetChangeParms
891 =============
892 */
893 void SetChangeParms (entity this)
894 {
895         // save parms for level change
896         parm1 = CS(this).parm_idlesince - time;
897
898         MUTATOR_CALLHOOK(SetChangeParms);
899 }
900
901 /*
902 =============
903 DecodeLevelParms
904 =============
905 */
906 void DecodeLevelParms(entity this)
907 {
908         // load parms
909         CS(this).parm_idlesince = parm1;
910         if (CS(this).parm_idlesince == -(86400 * 366))
911                 CS(this).parm_idlesince = time;
912
913         // whatever happens, allow 60 seconds of idling directly after connect for map loading
914         CS(this).parm_idlesince = max(CS(this).parm_idlesince, time - sv_maxidle + 60);
915
916         MUTATOR_CALLHOOK(DecodeLevelParms);
917 }
918
919 void FixClientCvars(entity e)
920 {
921         // send prediction settings to the client
922         stuffcmd(e, "\nin_bindmap 0 0\n");
923         if(autocvar_g_antilag == 3) // client side hitscan
924                 stuffcmd(e, "cl_cmd settemp cl_prydoncursor_notrace 0\n");
925         if(autocvar_sv_gentle)
926                 stuffcmd(e, "cl_cmd settemp cl_gentle 1\n");
927
928         stuffcmd(e, sprintf("\ncl_jumpspeedcap_min \"%s\"\n", autocvar_sv_jumpspeedcap_min));
929         stuffcmd(e, sprintf("\ncl_jumpspeedcap_max \"%s\"\n", autocvar_sv_jumpspeedcap_max));
930
931         stuffcmd(e, sprintf("\ncl_shootfromfixedorigin \"%s\"\n", autocvar_g_shootfromfixedorigin));
932
933         MUTATOR_CALLHOOK(FixClientCvars, e);
934 }
935
936 bool findinlist_abbrev(string tofind, string list)
937 {
938         if(list == "" || tofind == "")
939                 return false; // empty list or search, just return
940
941         // this function allows abbreviated strings!
942         FOREACH_WORD(list, it == substring(tofind, 0, strlen(it)),
943         {
944                 return true;
945         });
946
947         return false;
948 }
949
950 bool PlayerInIPList(entity p, string iplist)
951 {
952         // some safety checks (never allow local?)
953         if(p.netaddress == "local" || p.netaddress == "" || !IS_REAL_CLIENT(p))
954                 return false;
955
956         return findinlist_abbrev(p.netaddress, iplist);
957 }
958
959 bool PlayerInIDList(entity p, string idlist)
960 {
961         // NOTE: we do NOT check crypto_idfp_signed here, an unsigned ID is fine too for this
962         if(!p.crypto_idfp)
963                 return false;
964
965         return findinlist_abbrev(p.crypto_idfp, idlist);
966 }
967
968 bool PlayerInList(entity player, string list)
969 {
970         return boolean(PlayerInIDList(player, list) || PlayerInIPList(player, list));
971 }
972
973 #ifdef DP_EXT_PRECONNECT
974 /*
975 =============
976 ClientPreConnect
977
978 Called once (not at each match start) when a client begins a connection to the server
979 =============
980 */
981 void ClientPreConnect(entity this)
982 {
983         if(autocvar_sv_eventlog)
984         {
985                 GameLogEcho(sprintf(":connect:%d:%d:%s",
986                         this.playerid,
987                         etof(this),
988                         ((IS_REAL_CLIENT(this)) ? this.netaddress : "bot")
989                 ));
990         }
991 }
992 #endif
993
994 string GetClientVersionMessage(entity this)
995 {
996         if (CS(this).version_mismatch) {
997                 if(CS(this).version < autocvar_gameversion) {
998                         return strcat("This is Xonotic ", autocvar_g_xonoticversion,
999                                 "\n^3Your client version is outdated.\n\n\n### YOU WON'T BE ABLE TO PLAY ON THIS SERVER ###\n\n\nPlease update!!!^8");
1000                 } else {
1001                         return strcat("This is Xonotic ", autocvar_g_xonoticversion,
1002                                 "\n^3This server is using an outdated Xonotic version.\n\n\n ### THIS SERVER IS INCOMPATIBLE AND THUS YOU CANNOT JOIN ###.^8");
1003                 }
1004         } else {
1005                 return strcat("Welcome to Xonotic ", autocvar_g_xonoticversion);
1006         }
1007 }
1008
1009 string getwelcomemessage(entity this)
1010 {
1011         MUTATOR_CALLHOOK(BuildMutatorsPrettyString, "");
1012         string modifications = M_ARGV(0, string);
1013
1014         if(g_weaponarena)
1015         {
1016                 if(g_weaponarena_random)
1017                         modifications = strcat(modifications, ", ", ftos(g_weaponarena_random), " of ", g_weaponarena_list, " Arena");
1018                 else
1019                         modifications = strcat(modifications, ", ", g_weaponarena_list, " Arena");
1020         }
1021         else if(cvar("g_balance_blaster_weaponstartoverride") == 0)
1022                 modifications = strcat(modifications, ", No start weapons");
1023         if(cvar("sv_gravity") < stof(cvar_defstring("sv_gravity")))
1024                 modifications = strcat(modifications, ", Low gravity");
1025         if(g_weapon_stay && !g_cts)
1026                 modifications = strcat(modifications, ", Weapons stay");
1027         if(g_jetpack)
1028                 modifications = strcat(modifications, ", Jet pack");
1029         if(autocvar_g_powerups == 0)
1030                 modifications = strcat(modifications, ", No powerups");
1031         if(autocvar_g_powerups > 0)
1032                 modifications = strcat(modifications, ", Powerups");
1033         modifications = substring(modifications, 2, strlen(modifications) - 2);
1034
1035         string versionmessage = GetClientVersionMessage(this);
1036         string s = strcat(versionmessage, "^8\n^8\nmatch type is ^1", gamemode_name, "^8\n");
1037         s = strcat(s, "^8\nCurrent map: ^2", GetMapname(), "^8\n");
1038
1039         if(modifications != "")
1040                 s = strcat(s, "^8\nactive modifications: ^3", modifications, "^8\n");
1041
1042         if(cache_lastmutatormsg != autocvar_g_mutatormsg)
1043         {
1044                 strcpy(cache_lastmutatormsg, autocvar_g_mutatormsg);
1045                 strcpy(cache_mutatormsg, cache_lastmutatormsg);
1046         }
1047
1048         if (cache_mutatormsg != "") {
1049                 s = strcat(s, "\n\n^8special gameplay tips: ^7", cache_mutatormsg);
1050         }
1051
1052         string mutator_msg = "";
1053         MUTATOR_CALLHOOK(BuildGameplayTipsString, mutator_msg);
1054         mutator_msg = M_ARGV(0, string);
1055
1056         s = strcat(s, mutator_msg); // trust that the mutator will do proper formatting
1057
1058         string motd = autocvar_sv_motd;
1059         if (motd != "") {
1060                 s = strcat(s, "\n\n^8MOTD: ^7", strreplace("\\n", "\n", motd));
1061         }
1062         return s;
1063 }
1064
1065 bool autocvar_sv_qcphysics = false; // TODO this is for testing - remove when qcphysics work
1066
1067 /**
1068 =============
1069 ClientConnect
1070
1071 Called when a client connects to the server
1072 =============
1073 */
1074 void ClientConnect(entity this)
1075 {
1076         if (Ban_MaybeEnforceBanOnce(this)) return;
1077         assert(!IS_CLIENT(this), return);
1078         this.flags |= FL_CLIENT;
1079         assert(player_count >= 0, player_count = 0);
1080
1081 #ifdef WATERMARK
1082         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_WATERMARK, WATERMARK);
1083 #endif
1084         TRANSMUTE(Client, this);
1085         CS(this).version_nagtime = time + 10 + random() * 10;
1086
1087         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_JOIN_CONNECT, this.netname);
1088
1089         bot_clientconnect(this);
1090
1091         Player_DetermineForcedTeam(this);
1092
1093         TRANSMUTE(Observer, this);
1094
1095         PlayerStats_GameReport_AddEvent(sprintf("kills-%d", this.playerid));
1096
1097         // always track bots, don't ask for cl_allow_uidtracking
1098         if (IS_BOT_CLIENT(this))
1099                 PlayerStats_GameReport_AddPlayer(this);
1100         else
1101                 CS(this).allowed_timeouts = autocvar_sv_timeout_number;
1102
1103         if (autocvar_sv_eventlog)
1104                 GameLogEcho(strcat(":join:", ftos(this.playerid), ":", ftos(etof(this)), ":", ((IS_REAL_CLIENT(this)) ? this.netaddress : "bot"), ":", playername(this, false)));
1105
1106         CS(this).just_joined = true;  // stop spamming the eventlog with additional lines when the client connects
1107
1108         stuffcmd(this, clientstuff, "\n");
1109         stuffcmd(this, "cl_particles_reloadeffects\n"); // TODO do we still need this?
1110
1111         FixClientCvars(this);
1112
1113         // get version info from player
1114         stuffcmd(this, "cmd clientversion $gameversion\n");
1115
1116         // notify about available teams
1117         if (teamplay)
1118         {
1119                 entity balance = TeamBalance_CheckAllowedTeams(this);
1120                 int t = TeamBalance_GetAllowedTeams(balance);
1121                 TeamBalance_Destroy(balance);
1122                 stuffcmd(this, sprintf("set _teams_available %d\n", t));
1123         }
1124         else
1125         {
1126                 stuffcmd(this, "set _teams_available 0\n");
1127         }
1128
1129         bot_relinkplayerlist();
1130
1131         CS(this).spectatortime = time;
1132         if (blockSpectators)
1133         {
1134                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
1135         }
1136
1137         CS(this).jointime = time;
1138
1139         if (IS_REAL_CLIENT(this))
1140         {
1141                 if (g_weaponarena_weapons == WEPSET(TUBA))
1142                         stuffcmd(this, "cl_cmd settemp chase_active 1\n");
1143         }
1144
1145         if (!sv_foginterval && world.fog != "")
1146                 stuffcmd(this, strcat("\nfog ", world.fog, "\nr_fog_exp2 0\nr_drawfog 1\n"));
1147
1148         if (autocvar_sv_teamnagger && !(autocvar_bot_vs_human && AvailableTeams() == 2))
1149                 if(!MUTATOR_CALLHOOK(HideTeamNagger, this))
1150                         send_CSQC_teamnagger();
1151
1152         CSQCMODEL_AUTOINIT(this);
1153
1154         CS(this).model_randomizer = random();
1155
1156         if (IS_REAL_CLIENT(this))
1157                 sv_notice_join(this);
1158
1159         this.move_qcphysics = autocvar_sv_qcphysics;
1160
1161         // update physics stats (players can spawn before physics runs)
1162         Physics_UpdateStats(this);
1163
1164         IL_EACH(g_initforplayer, it.init_for_player, {
1165                 it.init_for_player(it, this);
1166         });
1167
1168         Handicap_Initialize(this);
1169
1170         MUTATOR_CALLHOOK(ClientConnect, this);
1171
1172         if (IS_REAL_CLIENT(this))
1173         {
1174                 if (!autocvar_g_campaign && !IS_PLAYER(this))
1175                 {
1176                         CS(this).motd_actived_time = -1;
1177                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOTD, getwelcomemessage(this));
1178                 }
1179         }
1180 }
1181 /*
1182 =============
1183 ClientDisconnect
1184
1185 Called when a client disconnects from the server
1186 =============
1187 */
1188 .entity chatbubbleentity;
1189 void ClientDisconnect(entity this)
1190 {
1191         assert(IS_CLIENT(this), return);
1192
1193         PlayerStats_GameReport_FinalizePlayer(this);
1194         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
1195         if (CS(this).active_minigame) part_minigame(this);
1196         if (IS_PLAYER(this)) Send_Effect(EFFECT_SPAWN_NEUTRAL, this.origin, '0 0 0', 1);
1197
1198         if (autocvar_sv_eventlog)
1199                 GameLogEcho(strcat(":part:", ftos(this.playerid)));
1200
1201         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_QUIT_DISCONNECT, this.netname);
1202
1203         if(IS_SPEC(this))
1204                 SetSpectatee(this, NULL);
1205
1206     MUTATOR_CALLHOOK(ClientDisconnect, this);
1207
1208         strfree(CS(this).netname_previous); // needs to be before the CS entity is removed!
1209         strfree(CS(this).weaponorder_byimpulse);
1210         ClientState_detach(this);
1211
1212         Portal_ClearAll(this);
1213
1214         Unfreeze(this, false);
1215
1216         RemoveGrapplingHooks(this);
1217
1218         // Here, everything has been done that requires this player to be a client.
1219
1220         this.flags &= ~FL_CLIENT;
1221
1222         if (this.chatbubbleentity) delete(this.chatbubbleentity);
1223         if (this.killindicator) delete(this.killindicator);
1224
1225         WaypointSprite_PlayerGone(this);
1226
1227         bot_relinkplayerlist();
1228
1229         strfree(this.clientstatus);
1230         if (this.personal) delete(this.personal);
1231
1232         this.playerid = 0;
1233         ReadyCount();
1234         if (vote_called && IS_REAL_CLIENT(this)) VoteCount(false);
1235
1236         ONREMOVE(this);
1237 }
1238
1239 void ChatBubbleThink(entity this)
1240 {
1241         this.nextthink = time;
1242         if ((this.owner.alpha < 0) || this.owner.chatbubbleentity != this)
1243         {
1244                 if(this.owner) // but why can that ever be NULL?
1245                         this.owner.chatbubbleentity = NULL;
1246                 delete(this);
1247                 return;
1248         }
1249
1250         this.mdl = "";
1251
1252         if ( !IS_DEAD(this.owner) && IS_PLAYER(this.owner) )
1253         {
1254                 if ( CS(this.owner).active_minigame && PHYS_INPUT_BUTTON_MINIGAME(this.owner) )
1255                         this.mdl = "models/sprites/minigame_busy.iqm";
1256                 else if (PHYS_INPUT_BUTTON_CHAT(this.owner))
1257                         this.mdl = "models/misc/chatbubble.spr";
1258         }
1259
1260         if ( this.model != this.mdl )
1261                 _setmodel(this, this.mdl);
1262
1263 }
1264
1265 void UpdateChatBubble(entity this)
1266 {
1267         if (this.alpha < 0)
1268                 return;
1269         // spawn a chatbubble entity if needed
1270         if (!this.chatbubbleentity)
1271         {
1272                 this.chatbubbleentity = new(chatbubbleentity);
1273                 this.chatbubbleentity.owner = this;
1274                 this.chatbubbleentity.exteriormodeltoclient = this;
1275                 setthink(this.chatbubbleentity, ChatBubbleThink);
1276                 this.chatbubbleentity.nextthink = time;
1277                 setmodel(this.chatbubbleentity, MDL_CHAT); // precision set below
1278                 //setorigin(this.chatbubbleentity, this.origin + '0 0 15' + this.maxs_z * '0 0 1');
1279                 setorigin(this.chatbubbleentity, '0 0 15' + this.maxs_z * '0 0 1');
1280                 setattachment(this.chatbubbleentity, this, "");  // sticks to moving player better, also conserves bandwidth
1281                 this.chatbubbleentity.mdl = this.chatbubbleentity.model;
1282                 //this.chatbubbleentity.model = "";
1283                 this.chatbubbleentity.effects = EF_LOWPRECISION;
1284         }
1285 }
1286
1287
1288 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
1289 // added to the model skins
1290 /*void UpdateColorModHack()
1291 {
1292         float c;
1293         c = this.clientcolors & 15;
1294         // LordHavoc: only bothering to support white, green, red, yellow, blue
1295              if (!teamplay) this.colormod = '0 0 0';
1296         else if (c ==  0) this.colormod = '1.00 1.00 1.00';
1297         else if (c ==  3) this.colormod = '0.10 1.73 0.10';
1298         else if (c ==  4) this.colormod = '1.73 0.10 0.10';
1299         else if (c == 12) this.colormod = '1.22 1.22 0.10';
1300         else if (c == 13) this.colormod = '0.10 0.10 1.73';
1301         else this.colormod = '1 1 1';
1302 }*/
1303
1304 void respawn(entity this)
1305 {
1306         if(this.alpha >= 0 && autocvar_g_respawn_ghosts)
1307         {
1308                 this.solid = SOLID_NOT;
1309                 this.takedamage = DAMAGE_NO;
1310                 set_movetype(this, MOVETYPE_FLY);
1311                 this.velocity = '0 0 1' * autocvar_g_respawn_ghosts_speed;
1312                 this.avelocity = randomvec() * autocvar_g_respawn_ghosts_speed * 3 - randomvec() * autocvar_g_respawn_ghosts_speed * 3;
1313                 this.effects |= CSQCMODEL_EF_RESPAWNGHOST;
1314                 Send_Effect(EFFECT_RESPAWN_GHOST, this.origin, '0 0 0', 1);
1315                 if(autocvar_g_respawn_ghosts_maxtime)
1316                         SUB_SetFade (this, time + autocvar_g_respawn_ghosts_maxtime / 2 + random () * (autocvar_g_respawn_ghosts_maxtime - autocvar_g_respawn_ghosts_maxtime / 2), 1.5);
1317         }
1318
1319         CopyBody(this, 1);
1320
1321         this.effects |= EF_NODRAW; // prevent another CopyBody
1322         PutClientInServer(this);
1323 }
1324
1325 ERASEABLE
1326 void PrintToChat(entity client, string text)
1327 {
1328         text = strcat("\{1}^7", text, "\n");
1329         sprint(client, text);
1330 }
1331
1332 ERASEABLE
1333 void DebugPrintToChat(entity client, string text)
1334 {
1335         if (autocvar_developer)
1336         {
1337                 PrintToChat(client, text);
1338         }
1339 }
1340
1341 ERASEABLE
1342 void PrintToChatAll(string text)
1343 {
1344         text = strcat("\{1}^7", text, "\n");
1345         bprint(text);
1346 }
1347
1348 ERASEABLE
1349 void DebugPrintToChatAll(string text)
1350 {
1351         if (autocvar_developer)
1352         {
1353                 PrintToChatAll(text);
1354         }
1355 }
1356
1357 ERASEABLE
1358 void PrintToChatTeam(int team_num, string text)
1359 {
1360         text = strcat("\{1}^7", text, "\n");
1361         FOREACH_CLIENT(IS_REAL_CLIENT(it),
1362         {
1363                 if (it.team == team_num)
1364                 {
1365                         sprint(it, text);
1366                 }
1367         });
1368 }
1369
1370 ERASEABLE
1371 void DebugPrintToChatTeam(int team_num, string text)
1372 {
1373         if (autocvar_developer)
1374         {
1375                 PrintToChatTeam(team_num, text);
1376         }
1377 }
1378
1379 void play_countdown(entity this, float finished, Sound samp)
1380 {
1381         TC(Sound, samp);
1382         if(IS_REAL_CLIENT(this))
1383                 if(floor(finished - time - frametime) != floor(finished - time))
1384                         if(finished - time < 6)
1385                                 sound (this, CH_INFO, samp, VOL_BASE, ATTEN_NORM);
1386 }
1387
1388 void player_powerups(entity this)
1389 {
1390         // add a way to see what the items were BEFORE all of these checks for the mutator hook
1391         int items_prev = this.items;
1392
1393         if((this.items & IT_USING_JETPACK) && !IS_DEAD(this) && !game_stopped)
1394                 this.modelflags |= MF_ROCKET;
1395         else
1396                 this.modelflags &= ~MF_ROCKET;
1397
1398         this.effects &= ~(EF_RED | EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT | EF_FLAME | EF_NODEPTHTEST);
1399
1400         if((this.alpha < 0 || IS_DEAD(this)) && !this.vehicle) // don't apply the flags if the player is gibbed
1401                 return;
1402
1403         Fire_ApplyDamage(this);
1404         Fire_ApplyEffect(this);
1405
1406         if (!MUTATOR_IS_ENABLED(mutator_instagib))
1407         {
1408                 if (this.items & ITEM_Strength.m_itemid)
1409                 {
1410                         play_countdown(this, this.strength_finished, SND_POWEROFF);
1411                         this.effects = this.effects | (EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT);
1412                         if (time > this.strength_finished)
1413                         {
1414                                 this.items = this.items - (this.items & ITEM_Strength.m_itemid);
1415                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERDOWN_STRENGTH, this.netname);
1416                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERDOWN_STRENGTH);
1417                         }
1418                 }
1419                 else
1420                 {
1421                         if (time < this.strength_finished)
1422                         {
1423                                 this.items = this.items | ITEM_Strength.m_itemid;
1424                                 if(!g_cts)
1425                                         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERUP_STRENGTH, this.netname);
1426                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERUP_STRENGTH);
1427                         }
1428                 }
1429                 if (this.items & ITEM_Shield.m_itemid)
1430                 {
1431                         play_countdown(this, this.invincible_finished, SND_POWEROFF);
1432                         this.effects = this.effects | (EF_RED | EF_ADDITIVE | EF_FULLBRIGHT);
1433                         if (time > this.invincible_finished)
1434                         {
1435                                 this.items = this.items - (this.items & ITEM_Shield.m_itemid);
1436                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERDOWN_SHIELD, this.netname);
1437                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERDOWN_SHIELD);
1438                         }
1439                 }
1440                 else
1441                 {
1442                         if (time < this.invincible_finished)
1443                         {
1444                                 this.items = this.items | ITEM_Shield.m_itemid;
1445                                 if(!g_cts)
1446                                         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERUP_SHIELD, this.netname);
1447                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERUP_SHIELD);
1448                         }
1449                 }
1450                 if (this.items & IT_SUPERWEAPON)
1451                 {
1452                         if (!(STAT(WEAPONS, this) & WEPSET_SUPERWEAPONS))
1453                         {
1454                                 this.superweapons_finished = 0;
1455                                 this.items = this.items - (this.items & IT_SUPERWEAPON);
1456                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_LOST, this.netname);
1457                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_LOST);
1458                         }
1459                         else if (this.items & IT_UNLIMITED_SUPERWEAPONS)
1460                         {
1461                                 // don't let them run out
1462                         }
1463                         else
1464                         {
1465                                 play_countdown(this, this.superweapons_finished, SND_POWEROFF);
1466                                 if (time > this.superweapons_finished)
1467                                 {
1468                                         this.items = this.items - (this.items & IT_SUPERWEAPON);
1469                                         STAT(WEAPONS, this) &= ~WEPSET_SUPERWEAPONS;
1470                                         //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_BROKEN, this.netname);
1471                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_BROKEN);
1472                                 }
1473                         }
1474                 }
1475                 else if(STAT(WEAPONS, this) & WEPSET_SUPERWEAPONS)
1476                 {
1477                         if (time < this.superweapons_finished || (this.items & IT_UNLIMITED_SUPERWEAPONS))
1478                         {
1479                                 this.items = this.items | IT_SUPERWEAPON;
1480                                 if(!(this.items & IT_UNLIMITED_SUPERWEAPONS))
1481                                 {
1482                                         if(!g_cts)
1483                                                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_PICKUP, this.netname);
1484                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_PICKUP);
1485                                 }
1486                         }
1487                         else
1488                         {
1489                                 this.superweapons_finished = 0;
1490                                 STAT(WEAPONS, this) &= ~WEPSET_SUPERWEAPONS;
1491                         }
1492                 }
1493                 else
1494                 {
1495                         this.superweapons_finished = 0;
1496                 }
1497         }
1498
1499         if(autocvar_g_nodepthtestplayers)
1500                 this.effects = this.effects | EF_NODEPTHTEST;
1501
1502         if(autocvar_g_fullbrightplayers)
1503                 this.effects = this.effects | EF_FULLBRIGHT;
1504
1505         if (time >= game_starttime)
1506         if (time < this.spawnshieldtime)
1507                 this.effects = this.effects | (EF_ADDITIVE | EF_FULLBRIGHT);
1508
1509         MUTATOR_CALLHOOK(PlayerPowerups, this, items_prev);
1510 }
1511
1512 float CalcRegen(float current, float stable, float regenfactor, float regenframetime)
1513 {
1514         if(current > stable)
1515                 return current;
1516         else if(current > stable - 0.25) // when close enough, "snap"
1517                 return stable;
1518         else
1519                 return min(stable, current + (stable - current) * regenfactor * regenframetime);
1520 }
1521
1522 float CalcRot(float current, float stable, float rotfactor, float rotframetime)
1523 {
1524         if(current < stable)
1525                 return current;
1526         else if(current < stable + 0.25) // when close enough, "snap"
1527                 return stable;
1528         else
1529                 return max(stable, current + (stable - current) * rotfactor * rotframetime);
1530 }
1531
1532 float CalcRotRegen(float current, float regenstable, float regenfactor, float regenlinear, float regenframetime, float rotstable, float rotfactor, float rotlinear, float rotframetime, float limit)
1533 {
1534         if(current > rotstable)
1535         {
1536                 if(rotframetime > 0)
1537                 {
1538                         current = CalcRot(current, rotstable, rotfactor, rotframetime);
1539                         current = max(rotstable, current - rotlinear * rotframetime);
1540                 }
1541         }
1542         else if(current < regenstable)
1543         {
1544                 if(regenframetime > 0)
1545                 {
1546                         current = CalcRegen(current, regenstable, regenfactor, regenframetime);
1547                         current = min(regenstable, current + regenlinear * regenframetime);
1548                 }
1549         }
1550
1551         if(current > limit)
1552                 current = limit;
1553
1554         return current;
1555 }
1556
1557 void player_regen(entity this)
1558 {
1559         float max_mod, regen_mod, rot_mod, limit_mod;
1560         max_mod = regen_mod = rot_mod = limit_mod = 1;
1561
1562         float regen_health = autocvar_g_balance_health_regen;
1563         float regen_health_linear = autocvar_g_balance_health_regenlinear;
1564         float regen_health_rot = autocvar_g_balance_health_rot;
1565         float regen_health_rotlinear = autocvar_g_balance_health_rotlinear;
1566         float regen_health_stable = autocvar_g_balance_health_regenstable;
1567         float regen_health_rotstable = autocvar_g_balance_health_rotstable;
1568         bool mutator_returnvalue = MUTATOR_CALLHOOK(PlayerRegen, this, max_mod, regen_mod, rot_mod, limit_mod, regen_health, regen_health_linear, regen_health_rot,
1569                 regen_health_rotlinear, regen_health_stable, regen_health_rotstable);
1570         max_mod = M_ARGV(1, float);
1571         regen_mod = M_ARGV(2, float);
1572         rot_mod = M_ARGV(3, float);
1573         limit_mod = M_ARGV(4, float);
1574         regen_health = M_ARGV(5, float);
1575         regen_health_linear = M_ARGV(6, float);
1576         regen_health_rot = M_ARGV(7, float);
1577         regen_health_rotlinear = M_ARGV(8, float);
1578         regen_health_stable = M_ARGV(9, float);
1579         regen_health_rotstable = M_ARGV(10, float);
1580
1581         if(!mutator_returnvalue)
1582         if(!STAT(FROZEN, this))
1583         {
1584                 float mina, maxa, limith, limita;
1585                 maxa = autocvar_g_balance_armor_rotstable;
1586                 mina = autocvar_g_balance_armor_regenstable;
1587                 limith = GetResourceLimit(this, RES_HEALTH);
1588                 limita = GetResourceLimit(this, RES_ARMOR);
1589
1590                 regen_health_rotstable = regen_health_rotstable * max_mod;
1591                 regen_health_stable = regen_health_stable * max_mod;
1592                 limith = limith * limit_mod;
1593                 limita = limita * limit_mod;
1594
1595                 SetResource(this, RES_ARMOR, CalcRotRegen(GetResource(this, RES_ARMOR), mina, autocvar_g_balance_armor_regen, autocvar_g_balance_armor_regenlinear, 
1596                                                                         regen_mod * frametime * (time > this.pauseregen_finished), maxa, autocvar_g_balance_armor_rot, autocvar_g_balance_armor_rotlinear,
1597                                                                         rot_mod * frametime * (time > this.pauserotarmor_finished), limita));
1598                 SetResource(this, RES_HEALTH, CalcRotRegen(GetResource(this, RES_HEALTH), regen_health_stable, regen_health, regen_health_linear,
1599                                                                         regen_mod * frametime * (time > this.pauseregen_finished), regen_health_rotstable, regen_health_rot, regen_health_rotlinear,
1600                                                                         rot_mod * frametime * (time > this.pauserothealth_finished), limith));
1601         }
1602
1603         // if player rotted to death...  die!
1604         // check this outside above checks, as player may still be able to rot to death
1605         if(GetResource(this, RES_HEALTH) < 1)
1606         {
1607                 if(this.vehicle)
1608                         vehicles_exit(this.vehicle, VHEF_RELEASE);
1609                 if(this.event_damage)
1610                         this.event_damage(this, this, this, 1, DEATH_ROT.m_id, DMG_NOWEP, this.origin, '0 0 0');
1611         }
1612
1613         if (!(this.items & IT_UNLIMITED_WEAPON_AMMO))
1614         {
1615                 float minf, maxf, limitf;
1616
1617                 maxf = autocvar_g_balance_fuel_rotstable;
1618                 minf = autocvar_g_balance_fuel_regenstable;
1619                 limitf = GetResourceLimit(this, RES_FUEL);
1620
1621                 SetResource(this, RES_FUEL, CalcRotRegen(GetResource(this, RES_FUEL), minf, autocvar_g_balance_fuel_regen, autocvar_g_balance_fuel_regenlinear, 
1622                                                                                 frametime * (time > this.pauseregen_finished) * ((this.items & ITEM_JetpackRegen.m_itemid) != 0),
1623                                                                                 maxf, autocvar_g_balance_fuel_rot, autocvar_g_balance_fuel_rotlinear, frametime * (time > this.pauserotfuel_finished), limitf));
1624         }
1625 }
1626
1627 bool zoomstate_set;
1628 void SetZoomState(entity this, float newzoom)
1629 {
1630         if(newzoom != CS(this).zoomstate)
1631         {
1632                 CS(this).zoomstate = newzoom;
1633                 ClientData_Touch(this);
1634         }
1635         zoomstate_set = true;
1636 }
1637
1638 void GetPressedKeys(entity this)
1639 {
1640         MUTATOR_CALLHOOK(GetPressedKeys, this);
1641         int keys = STAT(PRESSED_KEYS, this);
1642         keys = BITSET(keys, KEY_FORWARD,        CS(this).movement.x > 0);
1643         keys = BITSET(keys, KEY_BACKWARD,       CS(this).movement.x < 0);
1644         keys = BITSET(keys, KEY_RIGHT,          CS(this).movement.y > 0);
1645         keys = BITSET(keys, KEY_LEFT,           CS(this).movement.y < 0);
1646
1647         keys = BITSET(keys, KEY_JUMP,           PHYS_INPUT_BUTTON_JUMP(this));
1648         keys = BITSET(keys, KEY_CROUCH,         IS_DUCKED(this)); // workaround: player can't un-crouch until their path is clear, so we keep the button held here
1649         keys = BITSET(keys, KEY_ATCK,           PHYS_INPUT_BUTTON_ATCK(this));
1650         keys = BITSET(keys, KEY_ATCK2,          PHYS_INPUT_BUTTON_ATCK2(this));
1651         CS(this).pressedkeys = keys; // store for other users
1652
1653         STAT(PRESSED_KEYS, this) = keys;
1654 }
1655
1656 /*
1657 ======================
1658 spectate mode routines
1659 ======================
1660 */
1661
1662 void SpectateCopy(entity this, entity spectatee)
1663 {
1664         TC(Client, this); TC(Client, spectatee);
1665
1666         MUTATOR_CALLHOOK(SpectateCopy, spectatee, this);
1667         PS(this) = PS(spectatee);
1668         this.armortype = spectatee.armortype;
1669         SetResourceExplicit(this, RES_ARMOR, GetResource(spectatee, RES_ARMOR));
1670         SetResourceExplicit(this, RES_CELLS, GetResource(spectatee, RES_CELLS));
1671         SetResourceExplicit(this, RES_PLASMA, GetResource(spectatee, RES_PLASMA));
1672         SetResourceExplicit(this, RES_SHELLS, GetResource(spectatee, RES_SHELLS));
1673         SetResourceExplicit(this, RES_BULLETS, GetResource(spectatee, RES_BULLETS));
1674         SetResourceExplicit(this, RES_ROCKETS, GetResource(spectatee, RES_ROCKETS));
1675         SetResourceExplicit(this, RES_FUEL, GetResource(spectatee, RES_FUEL));
1676         this.effects = spectatee.effects & EFMASK_CHEAP; // eat performance
1677         SetResourceExplicit(this, RES_HEALTH, GetResource(spectatee, RES_HEALTH));
1678         CS(this).impulse = 0;
1679         this.items = spectatee.items;
1680         STAT(LAST_PICKUP, this) = STAT(LAST_PICKUP, spectatee);
1681         STAT(HIT_TIME, this) = STAT(HIT_TIME, spectatee);
1682         this.strength_finished = spectatee.strength_finished;
1683         this.invincible_finished = spectatee.invincible_finished;
1684         this.superweapons_finished = spectatee.superweapons_finished;
1685         STAT(PRESSED_KEYS, this) = STAT(PRESSED_KEYS, spectatee);
1686         STAT(WEAPONS, this) = STAT(WEAPONS, spectatee);
1687         this.punchangle = spectatee.punchangle;
1688         this.view_ofs = spectatee.view_ofs;
1689         this.velocity = spectatee.velocity;
1690         this.dmg_take = spectatee.dmg_take;
1691         this.dmg_save = spectatee.dmg_save;
1692         this.dmg_inflictor = spectatee.dmg_inflictor;
1693         this.v_angle = spectatee.v_angle;
1694         this.angles = spectatee.v_angle;
1695         STAT(FROZEN, this) = STAT(FROZEN, spectatee);
1696         STAT(REVIVE_PROGRESS, this) = STAT(REVIVE_PROGRESS, spectatee);
1697         this.viewloc = spectatee.viewloc;
1698         if(!PHYS_INPUT_BUTTON_USE(this) && STAT(CAMERA_SPECTATOR, this) != 2)
1699                 this.fixangle = true;
1700         setorigin(this, spectatee.origin);
1701         setsize(this, spectatee.mins, spectatee.maxs);
1702         SetZoomState(this, CS(spectatee).zoomstate);
1703
1704     anticheat_spectatecopy(this, spectatee);
1705         STAT(HUD, this) = STAT(HUD, spectatee);
1706         if(spectatee.vehicle)
1707     {
1708         this.angles = spectatee.v_angle;
1709
1710         //this.fixangle = false;
1711         //this.velocity = spectatee.vehicle.velocity;
1712         this.vehicle_health = spectatee.vehicle_health;
1713         this.vehicle_shield = spectatee.vehicle_shield;
1714         this.vehicle_energy = spectatee.vehicle_energy;
1715         this.vehicle_ammo1 = spectatee.vehicle_ammo1;
1716         this.vehicle_ammo2 = spectatee.vehicle_ammo2;
1717         this.vehicle_reload1 = spectatee.vehicle_reload1;
1718         this.vehicle_reload2 = spectatee.vehicle_reload2;
1719
1720         //msg_entity = this;
1721
1722        // WriteByte (MSG_ONE, SVC_SETVIEWANGLES);
1723             //WriteAngle(MSG_ONE,  spectatee.v_angle.x);
1724            // WriteAngle(MSG_ONE,  spectatee.v_angle.y);
1725            // WriteAngle(MSG_ONE,  spectatee.v_angle.z);
1726
1727         //WriteByte (MSG_ONE, SVC_SETVIEW);
1728         //    WriteEntity(MSG_ONE, this);
1729         //makevectors(spectatee.v_angle);
1730         //setorigin(this, spectatee.origin - v_forward * 400 + v_up * 300);*/
1731     }
1732 }
1733
1734 bool SpectateUpdate(entity this)
1735 {
1736         if(!this.enemy)
1737                 return false;
1738
1739         if(!IS_PLAYER(this.enemy) || this == this.enemy)
1740         {
1741                 SetSpectatee(this, NULL);
1742                 return false;
1743         }
1744
1745         SpectateCopy(this, this.enemy);
1746
1747         return true;
1748 }
1749
1750 bool SpectateSet(entity this)
1751 {
1752         if(!IS_PLAYER(this.enemy))
1753                 return false;
1754
1755         ClientData_Touch(this.enemy);
1756
1757         msg_entity = this;
1758         WriteByte(MSG_ONE, SVC_SETVIEW);
1759         WriteEntity(MSG_ONE, this.enemy);
1760         set_movetype(this, MOVETYPE_NONE);
1761         accuracy_resend(this);
1762
1763         if(!SpectateUpdate(this))
1764                 PutObserverInServer(this);
1765
1766         return true;
1767 }
1768
1769 void SetSpectatee_status(entity this, int spectatee_num)
1770 {
1771         int oldspectatee_status = CS(this).spectatee_status;
1772         CS(this).spectatee_status = spectatee_num;
1773
1774         if (CS(this).spectatee_status != oldspectatee_status)
1775         {
1776                 ClientData_Touch(this);
1777                 if (g_race || g_cts) race_InitSpectator();
1778         }
1779 }
1780
1781 void SetSpectatee(entity this, entity spectatee)
1782 {
1783         if(IS_BOT_CLIENT(this))
1784                 return; // bots abuse .enemy, this code is useless to them
1785
1786         entity old_spectatee = this.enemy;
1787
1788         this.enemy = spectatee;
1789
1790         // WEAPONTODO
1791         // these are required to fix the spectator bug with arc
1792         if(old_spectatee)
1793         {
1794                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1795                 {
1796                         .entity weaponentity = weaponentities[slot];
1797                         if(old_spectatee.(weaponentity).arc_beam)
1798                                 old_spectatee.(weaponentity).arc_beam.SendFlags |= ARC_SF_SETTINGS;
1799                 }
1800         }
1801         if(this.enemy)
1802         {
1803                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1804                 {
1805                         .entity weaponentity = weaponentities[slot];
1806                         if(this.enemy.(weaponentity).arc_beam)
1807                                 this.enemy.(weaponentity).arc_beam.SendFlags |= ARC_SF_SETTINGS;
1808                 }
1809         }
1810
1811         if (this.enemy)
1812                 SetSpectatee_status(this, etof(this.enemy));
1813
1814         // needed to update spectator list
1815         if(old_spectatee) { ClientData_Touch(old_spectatee); }
1816 }
1817
1818 bool Spectate(entity this, entity pl)
1819 {
1820         if(MUTATOR_CALLHOOK(SpectateSet, this, pl))
1821                 return false;
1822         pl = M_ARGV(1, entity);
1823
1824         SetSpectatee(this, pl);
1825         return SpectateSet(this);
1826 }
1827
1828 bool SpectateNext(entity this)
1829 {
1830         entity ent = find(this.enemy, classname, STR_PLAYER);
1831
1832         if (MUTATOR_CALLHOOK(SpectateNext, this, ent))
1833                 ent = M_ARGV(1, entity);
1834         else if (!ent)
1835                 ent = find(ent, classname, STR_PLAYER);
1836
1837         if(ent) { SetSpectatee(this, ent); }
1838
1839         return SpectateSet(this);
1840 }
1841
1842 bool SpectatePrev(entity this)
1843 {
1844         // NOTE: chain order is from the highest to the lower entnum (unlike find)
1845         entity ent = findchain(classname, STR_PLAYER);
1846         if (!ent) // no player
1847                 return false;
1848
1849         entity first = ent;
1850         // skip players until current spectated player
1851         if(this.enemy)
1852         while(ent && ent != this.enemy)
1853                 ent = ent.chain;
1854
1855         switch (MUTATOR_CALLHOOK(SpectatePrev, this, ent, first))
1856         {
1857                 case MUT_SPECPREV_FOUND:
1858                     ent = M_ARGV(1, entity);
1859                     break;
1860                 case MUT_SPECPREV_RETURN:
1861                     return true;
1862                 case MUT_SPECPREV_CONTINUE:
1863                 default:
1864                 {
1865                         if(ent.chain)
1866                                 ent = ent.chain;
1867                         else
1868                                 ent = first;
1869                         break;
1870                 }
1871         }
1872
1873         SetSpectatee(this, ent);
1874         return SpectateSet(this);
1875 }
1876
1877 /*
1878 =============
1879 ShowRespawnCountdown()
1880
1881 Update a respawn countdown display.
1882 =============
1883 */
1884 void ShowRespawnCountdown(entity this)
1885 {
1886         float number;
1887         if(!IS_DEAD(this)) // just respawned?
1888                 return;
1889         else
1890         {
1891                 number = ceil(this.respawn_time - time);
1892                 if(number <= 0)
1893                         return;
1894                 if(number <= this.respawn_countdown)
1895                 {
1896                         this.respawn_countdown = number - 1;
1897                         if(ceil(this.respawn_time - (time + 0.5)) == number) // only say it if it is the same number even in 0.5s; to prevent overlapping sounds
1898                                 { Send_Notification(NOTIF_ONE, this, MSG_ANNCE, Announcer_PickNumber(CNT_RESPAWN, number)); }
1899                 }
1900         }
1901 }
1902
1903 .bool team_selected;
1904 bool ShowTeamSelection(entity this)
1905 {
1906         if (!teamplay || autocvar_g_campaign || autocvar_g_balance_teams || this.team_selected || (CS(this).wasplayer && autocvar_g_changeteam_banned) || Player_HasRealForcedTeam(this))
1907                 return false;
1908         stuffcmd(this, "menu_showteamselect\n");
1909         return true;
1910 }
1911 void Join(entity this)
1912 {
1913         TRANSMUTE(Player, this);
1914
1915         if(!this.team_selected)
1916         if(autocvar_g_campaign || autocvar_g_balance_teams)
1917                 TeamBalance_JoinBestTeam(this);
1918
1919         if(autocvar_g_campaign)
1920                 campaign_bots_may_start = true;
1921
1922         Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_PREVENT_JOIN);
1923
1924         PutClientInServer(this);
1925
1926         if(IS_PLAYER(this))
1927         if(teamplay && this.team != -1)
1928         {
1929         }
1930         else
1931                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_JOIN_PLAY, this.netname);
1932         this.team_selected = false;
1933 }
1934
1935 int GetPlayerLimit()
1936 {
1937         int player_limit = autocvar_g_maxplayers;
1938         MUTATOR_CALLHOOK(GetPlayerLimit, player_limit);
1939         player_limit = M_ARGV(0, int);
1940         return player_limit;
1941 }
1942
1943 /**
1944  * Determines whether the player is allowed to join. This depends on cvar
1945  * g_maxplayers, if it isn't used this function always return true, otherwise
1946  * it checks whether the number of currently playing players exceeds g_maxplayers.
1947  * @return int number of free slots for players, 0 if none
1948  */
1949 int nJoinAllowed(entity this, entity ignore)
1950 {
1951         if(!ignore)
1952         // this is called that way when checking if anyone may be able to join (to build qcstatus)
1953         // so report 0 free slots if restricted
1954         {
1955                 if(autocvar_g_forced_team_otherwise == "spectate")
1956                         return 0;
1957                 if(autocvar_g_forced_team_otherwise == "spectator")
1958                         return 0;
1959         }
1960
1961         if(this && (Player_GetForcedTeamIndex(this) == TEAM_FORCE_SPECTATOR))
1962                 return 0; // forced spectators can never join
1963
1964         // TODO simplify this
1965         int totalClients = 0;
1966         int currentlyPlaying = 0;
1967         FOREACH_CLIENT(true, {
1968                 if(it != ignore)
1969                         ++totalClients;
1970                 if(IS_REAL_CLIENT(it))
1971                 if(IS_PLAYER(it) || it.caplayer)
1972                         ++currentlyPlaying;
1973         });
1974
1975         int player_limit = GetPlayerLimit();
1976
1977         float free_slots = 0;
1978         if (!player_limit)
1979                 free_slots = maxclients - totalClients;
1980         else if(currentlyPlaying < player_limit)
1981                 free_slots = min(maxclients - totalClients, player_limit - currentlyPlaying);
1982
1983         static float join_prevent_msg_time = 0;
1984         if(this && ignore && !free_slots && time > join_prevent_msg_time)
1985         {
1986                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_JOIN_PREVENT);
1987                 join_prevent_msg_time = time + 3;
1988         }
1989
1990         return free_slots;
1991 }
1992
1993 /**
1994  * Checks whether the client is an observer or spectator, if so, he will get kicked after
1995  * g_maxplayers_spectator_blocktime seconds
1996  */
1997 void checkSpectatorBlock(entity this)
1998 {
1999         if(IS_SPEC(this) || IS_OBSERVER(this))
2000         if(!this.caplayer)
2001         if(IS_REAL_CLIENT(this))
2002         {
2003                 if( time > (CS(this).spectatortime + autocvar_g_maxplayers_spectator_blocktime) ) {
2004                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_QUIT_KICK_SPECTATING);
2005                         dropclient(this);
2006                 }
2007         }
2008 }
2009
2010 void PrintWelcomeMessage(entity this)
2011 {
2012         if(CS(this).motd_actived_time == 0)
2013         {
2014                 if (autocvar_g_campaign) {
2015                         if ((IS_PLAYER(this) && PHYS_INPUT_BUTTON_INFO(this)) || (!IS_PLAYER(this))) {
2016                                 CS(this).motd_actived_time = time;
2017                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOTD, campaign_message);
2018                         }
2019                 } else {
2020                         if (PHYS_INPUT_BUTTON_INFO(this)) {
2021                                 CS(this).motd_actived_time = time;
2022                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOTD, getwelcomemessage(this));
2023                         }
2024                 }
2025         }
2026         else if(CS(this).motd_actived_time > 0) // showing MOTD or campaign message
2027         {
2028                 if (autocvar_g_campaign) {
2029                         if (PHYS_INPUT_BUTTON_INFO(this))
2030                                 CS(this).motd_actived_time = time;
2031                         else if ((time - CS(this).motd_actived_time > 2) && IS_PLAYER(this)) { // hide it some seconds after BUTTON_INFO has been released
2032                                 CS(this).motd_actived_time = 0;
2033                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_MOTD);
2034                         }
2035                 } else {
2036                         if (PHYS_INPUT_BUTTON_INFO(this))
2037                                 CS(this).motd_actived_time = time;
2038                         else if (time - CS(this).motd_actived_time > 2) { // hide it some seconds after BUTTON_INFO has been released
2039                                 CS(this).motd_actived_time = 0;
2040                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_MOTD);
2041                         }
2042                 }
2043         }
2044         else //if(CS(this).motd_actived_time < 0) // just connected, motd is active
2045         {
2046                 if(PHYS_INPUT_BUTTON_INFO(this)) // BUTTON_INFO hides initial MOTD
2047                         CS(this).motd_actived_time = -2; // wait until BUTTON_INFO gets released
2048                 else if(CS(this).motd_actived_time == -2 || IS_PLAYER(this) || IS_SPEC(this))
2049                 {
2050                         // instantly hide MOTD
2051                         CS(this).motd_actived_time = 0;
2052                         Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_MOTD);
2053                 }
2054         }
2055 }
2056
2057 const int MIN_SPEC_TIME = 1;
2058 bool joinAllowed(entity this)
2059 {
2060         if (CS(this).version_mismatch) return false;
2061         if (time < CS(this).jointime + MIN_SPEC_TIME) return false;
2062         if (!nJoinAllowed(this, this)) return false;
2063         if (teamplay && lockteams) return false;
2064         if (MUTATOR_CALLHOOK(ForbidSpawn, this)) return false;
2065         if (ShowTeamSelection(this)) return false;
2066         return true;
2067 }
2068
2069 .int items_added;
2070 .string shootfromfixedorigin;
2071 bool PlayerThink(entity this)
2072 {
2073         if (game_stopped || intermission_running) {
2074                 this.modelflags &= ~MF_ROCKET;
2075                 if(intermission_running)
2076                         IntermissionThink(this);
2077                 return false;
2078         }
2079
2080         if (timeout_status == TIMEOUT_ACTIVE) {
2081         // don't allow the player to turn around while game is paused
2082                 // FIXME turn this into CSQC stuff
2083                 this.v_angle = this.lastV_angle;
2084                 this.angles = this.lastV_angle;
2085                 this.fixangle = true;
2086         }
2087
2088         if (frametime) player_powerups(this);
2089
2090         if (IS_DEAD(this)) {
2091                 if (this.personal && g_race_qualifying) {
2092                         if (time > this.respawn_time) {
2093                                 STAT(RESPAWN_TIME, this) = this.respawn_time = time + 1; // only retry once a second
2094                                 respawn(this);
2095                                 CS(this).impulse = CHIMPULSE_SPEEDRUN.impulse;
2096                         }
2097                 } else {
2098                         if (frametime) player_anim(this);
2099
2100                         if (this.respawn_flags & RESPAWN_DENY)
2101                         {
2102                                 STAT(RESPAWN_TIME, this) = 0;
2103                                 return false;
2104                         }
2105
2106                         bool button_pressed = (PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_JUMP(this) || PHYS_INPUT_BUTTON_ATCK2(this) || PHYS_INPUT_BUTTON_HOOK(this) || PHYS_INPUT_BUTTON_USE(this));
2107
2108                         switch(this.deadflag)
2109                         {
2110                                 case DEAD_DYING:
2111                                 {
2112                                         if ((this.respawn_flags & RESPAWN_FORCE) && !(this.respawn_time < this.respawn_time_max))
2113                                                 this.deadflag = DEAD_RESPAWNING;
2114                                         else if (!button_pressed || (time >= this.respawn_time_max && (this.respawn_flags & RESPAWN_FORCE)))
2115                                                 this.deadflag = DEAD_DEAD;
2116                                         break;
2117                                 }
2118                                 case DEAD_DEAD:
2119                                 {
2120                                         if (button_pressed)
2121                                                 this.deadflag = DEAD_RESPAWNABLE;
2122                                         else if (time >= this.respawn_time_max && (this.respawn_flags & RESPAWN_FORCE))
2123                                                 this.deadflag = DEAD_RESPAWNING;
2124                                         break;
2125                                 }
2126                                 case DEAD_RESPAWNABLE:
2127                                 {
2128                                         if (!button_pressed || (this.respawn_flags & RESPAWN_FORCE))
2129                                                 this.deadflag = DEAD_RESPAWNING;
2130                                         break;
2131                                 }
2132                                 case DEAD_RESPAWNING:
2133                                 {
2134                                         if (time > this.respawn_time)
2135                                         {
2136                                                 this.respawn_time = time + 1; // only retry once a second
2137                                                 this.respawn_time_max = this.respawn_time;
2138                                                 respawn(this);
2139                                         }
2140                                         break;
2141                                 }
2142                         }
2143
2144                         ShowRespawnCountdown(this);
2145
2146                         if (this.respawn_flags & RESPAWN_SILENT)
2147                                 STAT(RESPAWN_TIME, this) = 0;
2148                         else if ((this.respawn_flags & RESPAWN_FORCE) && this.respawn_time < this.respawn_time_max)
2149                         {
2150                                 if (time < this.respawn_time)
2151                                         STAT(RESPAWN_TIME, this) = this.respawn_time;
2152                                 else if (this.deadflag != DEAD_RESPAWNING)
2153                                         STAT(RESPAWN_TIME, this) = -this.respawn_time_max;
2154                         }
2155                         else
2156                                 STAT(RESPAWN_TIME, this) = this.respawn_time;
2157                 }
2158
2159                 // if respawning, invert stat_respawn_time to indicate this, the client translates it
2160                 if (this.deadflag == DEAD_RESPAWNING && STAT(RESPAWN_TIME, this) > 0)
2161                         STAT(RESPAWN_TIME, this) *= -1;
2162
2163                 return false;
2164         }
2165
2166         FixPlayermodel(this);
2167
2168         if (this.shootfromfixedorigin != autocvar_g_shootfromfixedorigin) {
2169                 this.shootfromfixedorigin = autocvar_g_shootfromfixedorigin;
2170                 stuffcmd(this, sprintf("\ncl_shootfromfixedorigin \"%s\"\n", autocvar_g_shootfromfixedorigin));
2171         }
2172
2173         // LordHavoc: allow firing on move frames (sub-ticrate), this gives better timing on slow servers
2174         //if(frametime)
2175         {
2176                 this.items &= ~this.items_added;
2177
2178                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2179                 {
2180                         .entity weaponentity = weaponentities[slot];
2181                         W_WeaponFrame(this, weaponentity);
2182                 }
2183
2184                 this.items_added = 0;
2185                 if ((this.items & ITEM_Jetpack.m_itemid) && ((this.items & ITEM_JetpackRegen.m_itemid) || GetResource(this, RES_FUEL) >= 0.01))
2186             this.items_added |= IT_FUEL;
2187
2188                 this.items |= this.items_added;
2189         }
2190
2191         player_regen(this);
2192
2193         // WEAPONTODO: Add a weapon request for this
2194         // rot vortex charge to the charge limit
2195         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2196         {
2197                 .entity weaponentity = weaponentities[slot];
2198                 if (WEP_CVAR(vortex, charge_rot_rate) && this.(weaponentity).vortex_charge > WEP_CVAR(vortex, charge_limit) && this.(weaponentity).vortex_charge_rottime < time)
2199                         this.(weaponentity).vortex_charge = bound(WEP_CVAR(vortex, charge_limit), this.(weaponentity).vortex_charge - WEP_CVAR(vortex, charge_rot_rate) * frametime / W_TICSPERFRAME, 1);
2200         }
2201
2202         if (frametime) player_anim(this);
2203
2204         // secret status
2205         secrets_setstatus(this);
2206
2207         // monsters status
2208         monsters_setstatus(this);
2209
2210         this.dmg_team = max(0, this.dmg_team - autocvar_g_teamdamage_resetspeed * frametime);
2211
2212         return true;
2213 }
2214
2215 .bool would_spectate;
2216 void ObserverThink(entity this)
2217 {
2218         if ( CS(this).impulse )
2219         {
2220                 MinigameImpulse(this, CS(this).impulse);
2221                 CS(this).impulse = 0;
2222         }
2223
2224         if (this.flags & FL_JUMPRELEASED) {
2225                 if (PHYS_INPUT_BUTTON_JUMP(this) && joinAllowed(this)) {
2226                         this.flags &= ~FL_JUMPRELEASED;
2227                         this.flags |= FL_SPAWNING;
2228                 } else if(PHYS_INPUT_BUTTON_ATCK(this) && !CS(this).version_mismatch || this.would_spectate) {
2229                         this.flags &= ~FL_JUMPRELEASED;
2230                         if(SpectateNext(this)) {
2231                                 TRANSMUTE(Spectator, this);
2232                         }
2233                 } else {
2234                         int preferred_movetype = ((!PHYS_INPUT_BUTTON_USE(this) ? CS(this).cvar_cl_clippedspectating : !CS(this).cvar_cl_clippedspectating) ? MOVETYPE_FLY_WORLDONLY : MOVETYPE_NOCLIP);
2235                         set_movetype(this, preferred_movetype);
2236                 }
2237         } else {
2238                 if (!(PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_JUMP(this))) {
2239                         this.flags |= FL_JUMPRELEASED;
2240                         if(this.flags & FL_SPAWNING)
2241                         {
2242                                 this.flags &= ~FL_SPAWNING;
2243                                 Join(this);
2244                                 return;
2245                         }
2246                 }
2247         }
2248 }
2249
2250 void SpectatorThink(entity this)
2251 {
2252         if ( CS(this).impulse )
2253         {
2254                 if(MinigameImpulse(this, CS(this).impulse))
2255                         CS(this).impulse = 0;
2256
2257                 if (CS(this).impulse == IMP_weapon_drop.impulse)
2258                 {
2259                         STAT(CAMERA_SPECTATOR, this) = (STAT(CAMERA_SPECTATOR, this) + 1) % 3;
2260                         CS(this).impulse = 0;
2261                         return;
2262                 }
2263         }
2264
2265         if (this.flags & FL_JUMPRELEASED) {
2266                 if (PHYS_INPUT_BUTTON_JUMP(this) && joinAllowed(this)) {
2267                         this.flags &= ~FL_JUMPRELEASED;
2268                         this.flags |= FL_SPAWNING;
2269                 } else if(PHYS_INPUT_BUTTON_ATCK(this) || CS(this).impulse == 10 || CS(this).impulse == 15 || CS(this).impulse == 18 || (CS(this).impulse >= 200 && CS(this).impulse <= 209)) {
2270                         this.flags &= ~FL_JUMPRELEASED;
2271                         if(SpectateNext(this)) {
2272                                 TRANSMUTE(Spectator, this);
2273                         } else {
2274                                 TRANSMUTE(Observer, this);
2275                                 PutClientInServer(this);
2276                         }
2277                         CS(this).impulse = 0;
2278                 } else if(CS(this).impulse == 12 || CS(this).impulse == 16  || CS(this).impulse == 19 || (CS(this).impulse >= 220 && CS(this).impulse <= 229)) {
2279                         this.flags &= ~FL_JUMPRELEASED;
2280                         if(SpectatePrev(this)) {
2281                                 TRANSMUTE(Spectator, this);
2282                         } else {
2283                                 TRANSMUTE(Observer, this);
2284                                 PutClientInServer(this);
2285                         }
2286                         CS(this).impulse = 0;
2287                 } else if (PHYS_INPUT_BUTTON_ATCK2(this)) {
2288                         this.would_spectate = false;
2289                         this.flags &= ~FL_JUMPRELEASED;
2290                         TRANSMUTE(Observer, this);
2291                         PutClientInServer(this);
2292                 } else {
2293                         if(!SpectateUpdate(this))
2294                         {
2295                                 if(!SpectateNext(this))
2296                                 {
2297                                         PutObserverInServer(this);
2298                                         this.would_spectate = true;
2299                                 }
2300                         }
2301                 }
2302         } else {
2303                 if (!(PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_ATCK2(this))) {
2304                         this.flags |= FL_JUMPRELEASED;
2305                         if(this.flags & FL_SPAWNING)
2306                         {
2307                                 this.flags &= ~FL_SPAWNING;
2308                                 Join(this);
2309                                 return;
2310                         }
2311                 }
2312                 if(!SpectateUpdate(this))
2313                         PutObserverInServer(this);
2314         }
2315
2316         this.flags |= FL_CLIENT | FL_NOTARGET;
2317 }
2318
2319 void PlayerUseKey(entity this)
2320 {
2321         if (!IS_PLAYER(this))
2322                 return;
2323
2324         if(this.vehicle)
2325         {
2326                 if(!game_stopped)
2327                 {
2328                         vehicles_exit(this.vehicle, VHEF_NORMAL);
2329                         return;
2330                 }
2331         }
2332         else if(autocvar_g_vehicles_enter)
2333         {
2334                 if(!game_stopped && !STAT(FROZEN, this) && !IS_DEAD(this) && !IS_INDEPENDENT_PLAYER(this))
2335                 {
2336                         entity head, closest_target = NULL;
2337                         head = WarpZone_FindRadius(this.origin, autocvar_g_vehicles_enter_radius, true);
2338
2339                         while(head) // find the closest acceptable target to enter
2340                         {
2341                                 if(IS_VEHICLE(head) && !IS_DEAD(head) && head.takedamage != DAMAGE_NO)
2342                                 if(!head.owner || ((head.vehicle_flags & VHF_MULTISLOT) && SAME_TEAM(head.owner, this)))
2343                                 {
2344                                         if(closest_target)
2345                                         {
2346                                                 if(vlen2(this.origin - head.origin) < vlen2(this.origin - closest_target.origin))
2347                                                 { closest_target = head; }
2348                                         }
2349                                         else { closest_target = head; }
2350                                 }
2351
2352                                 head = head.chain;
2353                         }
2354
2355                         if(closest_target) { vehicles_enter(this, closest_target); return; }
2356                 }
2357         }
2358
2359         // a use key was pressed; call handlers
2360         MUTATOR_CALLHOOK(PlayerUseKey, this);
2361 }
2362
2363
2364 /*
2365 =============
2366 PlayerPreThink
2367
2368 Called every frame for each client before the physics are run
2369 =============
2370 */
2371 .float last_vehiclecheck;
2372 void PlayerPreThink (entity this)
2373 {
2374         STAT(GUNALIGN, this) = CS(this).cvar_cl_gunalign; // TODO
2375         STAT(MOVEVARS_CL_TRACK_CANJUMP, this) = CS(this).cvar_cl_movement_track_canjump;
2376
2377         WarpZone_PlayerPhysics_FixVAngle(this);
2378
2379         if (frametime) {
2380                 // physics frames: update anticheat stuff
2381                 anticheat_prethink(this);
2382         }
2383
2384         if (blockSpectators && frametime) {
2385                 // WORKAROUND: only use dropclient in server frames (frametime set).
2386                 // Never use it in cl_movement frames (frametime zero).
2387                 checkSpectatorBlock(this);
2388         }
2389
2390         zoomstate_set = false;
2391
2392         // Check for nameless players
2393         if (this.netname == "" || this.netname != CS(this).netname_previous)
2394         {
2395                 bool assume_unchanged = (CS(this).netname_previous == "");
2396                 if (autocvar_name_maxlength > 0 && strlennocol(this.netname) > autocvar_name_maxlength)
2397                 {
2398                         int new_length = textLengthUpToLength(this.netname, autocvar_name_maxlength, strlennocol);
2399                         this.netname = strzone(strcat(substring(this.netname, 0, new_length), "^7"));
2400                         sprint(this, sprintf("Warning: your name is longer than %d characters, it has been truncated.\n", autocvar_name_maxlength));
2401                         assume_unchanged = false;
2402                         // stuffcmd(this, strcat("name ", this.netname, "\n")); // maybe?
2403                 }
2404                 if (isInvisibleString(this.netname))
2405                 {
2406                         this.netname = strzone(sprintf("Player#%d", this.playerid));
2407                         sprint(this, "Warning: invisible names are not allowed.\n");
2408                         assume_unchanged = false;
2409                         // stuffcmd(this, strcat("name ", this.netname, "\n")); // maybe?
2410                 }
2411                 if (!assume_unchanged && autocvar_sv_eventlog)
2412                         GameLogEcho(strcat(":name:", ftos(this.playerid), ":", playername(this, false)));
2413                 strcpy(CS(this).netname_previous, this.netname);
2414         }
2415
2416         // version nagging
2417         if (CS(this).version_nagtime && CS(this).cvar_g_xonoticversion && time > CS(this).version_nagtime) {
2418         CS(this).version_nagtime = 0;
2419         if (strstrofs(CS(this).cvar_g_xonoticversion, "git", 0) >= 0 || strstrofs(CS(this).cvar_g_xonoticversion, "autobuild", 0) >= 0) {
2420             // git client
2421         } else if (strstrofs(autocvar_g_xonoticversion, "git", 0) >= 0 || strstrofs(autocvar_g_xonoticversion, "autobuild", 0) >= 0) {
2422             // git server
2423             Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_BETA, autocvar_g_xonoticversion, CS(this).cvar_g_xonoticversion);
2424         } else {
2425             int r = vercmp(CS(this).cvar_g_xonoticversion, autocvar_g_xonoticversion);
2426             if (r < 0) { // old client
2427                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_OUTDATED, autocvar_g_xonoticversion, CS(this).cvar_g_xonoticversion);
2428             } else if (r > 0) { // old server
2429                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_OLD, autocvar_g_xonoticversion, CS(this).cvar_g_xonoticversion);
2430             }
2431         }
2432     }
2433
2434         // GOD MODE info
2435         if (!(this.flags & FL_GODMODE) && this.max_armorvalue)
2436         {
2437                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_GODMODE_OFF, this.max_armorvalue);
2438                 this.max_armorvalue = 0;
2439         }
2440
2441         if(IS_PLAYER(this))
2442         {
2443                 if (STAT(FROZEN, this) == FROZEN_TEMP_REVIVING)
2444                 {
2445                         STAT(REVIVE_PROGRESS, this) = bound(0, STAT(REVIVE_PROGRESS, this) + frametime * this.revive_speed, 1);
2446                         SetResourceExplicit(this, RES_HEALTH, max(1, STAT(REVIVE_PROGRESS, this) * start_health));
2447                         this.iceblock.alpha = bound(0.2, 1 - STAT(REVIVE_PROGRESS, this), 1);
2448
2449                         if (STAT(REVIVE_PROGRESS, this) >= 1)
2450                                 Unfreeze(this, false);
2451                 }
2452                 else if (STAT(FROZEN, this) == FROZEN_TEMP_DYING)
2453                 {
2454                         STAT(REVIVE_PROGRESS, this) = bound(0, STAT(REVIVE_PROGRESS, this) - frametime * this.revive_speed, 1);
2455                         SetResourceExplicit(this, RES_HEALTH, max(0, autocvar_g_nades_ice_health + (start_health-autocvar_g_nades_ice_health) * STAT(REVIVE_PROGRESS, this)));
2456
2457                         if (GetResource(this, RES_HEALTH) < 1)
2458                         {
2459                                 if (this.vehicle)
2460                                         vehicles_exit(this.vehicle, VHEF_RELEASE);
2461                                 if(this.event_damage)
2462                                         this.event_damage(this, this, this.frozen_by, 1, DEATH_NADE_ICE_FREEZE.m_id, DMG_NOWEP, this.origin, '0 0 0');
2463                         }
2464                         else if (STAT(REVIVE_PROGRESS, this) <= 0)
2465                                 Unfreeze(this, false);
2466                 }
2467         }
2468
2469         MUTATOR_CALLHOOK(PlayerPreThink, this);
2470
2471         if(autocvar_g_vehicles_enter && (time > this.last_vehiclecheck) && !game_stopped && !this.vehicle)
2472         if(IS_PLAYER(this) && !STAT(FROZEN, this) && !IS_DEAD(this) && !IS_INDEPENDENT_PLAYER(this))
2473         {
2474                 FOREACH_ENTITY_RADIUS(this.origin, autocvar_g_vehicles_enter_radius, IS_VEHICLE(it) && !IS_DEAD(it) && it.takedamage != DAMAGE_NO,
2475                 {
2476                         if(!it.owner)
2477                         {
2478                                 if(!it.team || SAME_TEAM(this, it))
2479                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER);
2480                                 else if(autocvar_g_vehicles_steal)
2481                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER_STEAL);
2482                         }
2483                         else if((it.vehicle_flags & VHF_MULTISLOT) && SAME_TEAM(it.owner, this))
2484                         {
2485                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER_GUNNER);
2486                         }
2487                 });
2488
2489                 this.last_vehiclecheck = time + 1;
2490         }
2491
2492         if(!CS(this).cvar_cl_newusekeysupported) // FIXME remove this - it was a stupid idea to begin with, we can JUST use the button
2493         {
2494                 if(PHYS_INPUT_BUTTON_USE(this) && !CS(this).usekeypressed)
2495                         PlayerUseKey(this);
2496                 CS(this).usekeypressed = PHYS_INPUT_BUTTON_USE(this);
2497         }
2498
2499         if (IS_REAL_CLIENT(this))
2500                 PrintWelcomeMessage(this);
2501
2502         if (IS_PLAYER(this)) {
2503                 if (IS_REAL_CLIENT(this) && time < CS(this).jointime + MIN_SPEC_TIME)
2504                         error("Client can't be spawned as player on connection!");
2505                 if(!PlayerThink(this))
2506                         return;
2507         }
2508         else if (game_stopped || intermission_running) {
2509                 if(intermission_running)
2510                         IntermissionThink(this);
2511                 return;
2512         }
2513         else if (IS_REAL_CLIENT(this) && !CS(this).autojoin_checked && time >= CS(this).jointime + MIN_SPEC_TIME)
2514         {
2515                 CS(this).autojoin_checked = true;
2516                 // don't do this in ClientConnect
2517                 // many things can go wrong if a client is spawned as player on connection
2518                 if (MUTATOR_CALLHOOK(AutoJoinOnConnection, this)
2519                         || (!(autocvar_sv_spectate || autocvar_g_campaign || (Player_GetForcedTeamIndex(this) == TEAM_FORCE_SPECTATOR))
2520                                 && (!teamplay || autocvar_g_balance_teams)))
2521                 {
2522                         campaign_bots_may_start = true;
2523                         Join(this);
2524                         return;
2525                 }
2526         }
2527         else if (IS_OBSERVER(this)) {
2528                 ObserverThink(this);
2529         }
2530         else if (IS_SPEC(this)) {
2531                 SpectatorThink(this);
2532         }
2533
2534         // WEAPONTODO: Add weapon request for this
2535         if (!zoomstate_set) {
2536                 bool wep_zoomed = false;
2537                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2538                 {
2539                         .entity weaponentity = weaponentities[slot];
2540                         Weapon thiswep = this.(weaponentity).m_weapon;
2541                         if(thiswep != WEP_Null && thiswep.wr_zoom)
2542                                 wep_zoomed += thiswep.wr_zoom(thiswep, this);
2543                 }
2544                 SetZoomState(this, PHYS_INPUT_BUTTON_ZOOM(this) || PHYS_INPUT_BUTTON_ZOOMSCRIPT(this) || wep_zoomed);
2545     }
2546
2547         if (CS(this).teamkill_soundtime && time > CS(this).teamkill_soundtime)
2548         {
2549                 CS(this).teamkill_soundtime = 0;
2550
2551                 entity e = CS(this).teamkill_soundsource;
2552                 entity oldpusher = e.pusher;
2553                 e.pusher = this;
2554                 PlayerSound(e, playersound_teamshoot, CH_VOICE, VOL_BASEVOICE, VOICETYPE_LASTATTACKER_ONLY);
2555                 e.pusher = oldpusher;
2556         }
2557
2558         if (CS(this).taunt_soundtime && time > CS(this).taunt_soundtime) {
2559                 CS(this).taunt_soundtime = 0;
2560                 PlayerSound(this, playersound_taunt, CH_VOICE, VOL_BASEVOICE, VOICETYPE_AUTOTAUNT);
2561         }
2562
2563         target_voicescript_next(this);
2564
2565         // WEAPONTODO: Move into weaponsystem somehow
2566         // if a player goes unarmed after holding a loaded weapon, empty his clip size and remove the crosshair ammo ring
2567         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2568         {
2569                 .entity weaponentity = weaponentities[slot];
2570                 if(this.(weaponentity).m_weapon == WEP_Null)
2571                         this.(weaponentity).clip_load = this.(weaponentity).clip_size = 0;
2572         }
2573 }
2574
2575 void DrownPlayer(entity this)
2576 {
2577         if(IS_DEAD(this) || game_stopped || time < game_starttime)
2578                 return;
2579
2580         if (this.waterlevel != WATERLEVEL_SUBMERGED || this.vehicle)
2581         {
2582                 if(this.air_finished < time)
2583                         PlayerSound(this, playersound_gasp, CH_PLAYER, VOL_BASE, VOICETYPE_PLAYERSOUND);
2584                 this.air_finished = time + autocvar_g_balance_contents_drowndelay;
2585         }
2586         else if (this.air_finished < time)
2587         {       // drown!
2588                 if (this.pain_finished < time)
2589                 {
2590                         Damage (this, NULL, NULL, autocvar_g_balance_contents_playerdamage_drowning * autocvar_g_balance_contents_damagerate, DEATH_DROWN.m_id, DMG_NOWEP, this.origin, '0 0 0');
2591                         this.pain_finished = time + 0.5;
2592                 }
2593         }
2594 }
2595
2596 .bool move_qcphysics;
2597
2598 void Player_Physics(entity this)
2599 {
2600         this.movetype = (this.move_qcphysics) ? MOVETYPE_QCPLAYER : this.move_movetype;
2601
2602         if(!this.move_qcphysics)
2603                 return;
2604
2605         if(!frametime && !CS(this).pm_frametime)
2606                 return;
2607
2608         Movetype_Physics_NoMatchTicrate(this, CS(this).pm_frametime, true);
2609
2610         CS(this).pm_frametime = 0;
2611 }
2612
2613 /*
2614 =============
2615 PlayerPostThink
2616
2617 Called every frame for each client after the physics are run
2618 =============
2619 */
2620 void PlayerPostThink (entity this)
2621 {
2622         Player_Physics(this);
2623
2624         if (sv_maxidle > 0)
2625         if (frametime) // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2626         if (IS_REAL_CLIENT(this))
2627         if (IS_PLAYER(this) || sv_maxidle_spectatorsareidle)
2628         {
2629                 int totalClients = 0;
2630                 if(sv_maxidle_slots > 0)
2631                 {
2632                         FOREACH_CLIENT(IS_REAL_CLIENT(it) || sv_maxidle_slots_countbots,
2633                         {
2634                                 ++totalClients;
2635                         });
2636                 }
2637
2638                 if (sv_maxidle_slots > 0 && (maxclients - totalClients) > sv_maxidle_slots)
2639                 { /* do nothing */ }
2640                 else if (time - CS(this).parm_idlesince < 1) // instead of (time == this.parm_idlesince) to support sv_maxidle <= 10
2641                 {
2642                         if (CS(this).idlekick_lasttimeleft)
2643                         {
2644                                 CS(this).idlekick_lasttimeleft = 0;
2645                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_IDLING);
2646                         }
2647                 }
2648                 else
2649                 {
2650                         float timeleft = ceil(sv_maxidle - (time - CS(this).parm_idlesince));
2651                         if (timeleft == min(10, sv_maxidle - 1)) { // - 1 to support sv_maxidle <= 10
2652                                 if (!CS(this).idlekick_lasttimeleft)
2653                                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_DISCONNECT_IDLING, timeleft);
2654                         }
2655                         if (timeleft <= 0) {
2656                                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_QUIT_KICK_IDLING, this.netname);
2657                                 dropclient(this);
2658                                 return;
2659                         }
2660                         else if (timeleft <= 10) {
2661                                 if (timeleft != CS(this).idlekick_lasttimeleft) {
2662                                     Send_Notification(NOTIF_ONE, this, MSG_ANNCE, Announcer_PickNumber(CNT_IDLE, timeleft));
2663                 }
2664                                 CS(this).idlekick_lasttimeleft = timeleft;
2665                         }
2666                 }
2667         }
2668
2669         CheatFrame(this);
2670
2671         if (game_stopped)
2672         {
2673                 this.solid = SOLID_NOT;
2674                 this.takedamage = DAMAGE_NO;
2675                 set_movetype(this, MOVETYPE_NONE);
2676         }
2677
2678         if (IS_PLAYER(this)) {
2679                 if(this.death_time == time && IS_DEAD(this))
2680                 {
2681                         // player's bbox gets resized now, instead of in the damage event that killed the player,
2682                         // once all the damage events of this frame have been processed with normal size
2683                         this.maxs.z = 5;
2684                         setsize(this, this.mins, this.maxs);
2685                 }
2686                 DrownPlayer(this);
2687                 UpdateChatBubble(this);
2688                 if (CS(this).impulse) ImpulseCommands(this);
2689                 if (game_stopped)
2690                 {
2691                         CSQCMODEL_AUTOUPDATE(this);
2692                         return;
2693                 }
2694                 GetPressedKeys(this);
2695         }
2696
2697         if (this.waypointsprite_attachedforcarrier) {
2698                 float hp = healtharmor_maxdamage(GetResource(this, RES_HEALTH), GetResource(this, RES_ARMOR), autocvar_g_balance_armor_blockpercent, DEATH_WEAPON.m_id).x;
2699                 WaypointSprite_UpdateHealth(this.waypointsprite_attachedforcarrier, hp);
2700         }
2701
2702         CSQCMODEL_AUTOUPDATE(this);
2703 }
2704
2705 /**
2706  * message "": do not say, just test flood control
2707  * return value:
2708  *   1 = accept
2709  *   0 = reject
2710  *  -1 = fake accept
2711  */
2712 int Say(entity source, int teamsay, entity privatesay, string msgin, bool floodcontrol)
2713 {
2714         if (!teamsay && !privatesay && substring(msgin, 0, 1) == " ")
2715                 msgin = substring(msgin, 1, -1); // work around DP say bug (say_team does not have this!)
2716
2717         if (source)
2718                 msgin = formatmessage(source, msgin);
2719
2720         string colorstr;
2721         if (!(IS_PLAYER(source) || source.caplayer))
2722                 colorstr = "^0"; // black for spectators
2723         else if(teamplay)
2724                 colorstr = Team_ColorCode(source.team);
2725         else
2726         {
2727                 colorstr = "";
2728                 teamsay = false;
2729         }
2730
2731         if (!source) {
2732                 colorstr = "";
2733                 teamsay = false;
2734         }
2735
2736         if(msgin != "")
2737                 msgin = trigger_magicear_processmessage_forallears(source, teamsay, privatesay, msgin);
2738
2739         /*
2740          * using bprint solves this... me stupid
2741         // how can we prevent the message from appearing in a listen server?
2742         // for now, just give "say" back and only handle say_team
2743         if(!teamsay)
2744         {
2745                 clientcommand(source, strcat("say ", msgin));
2746                 return;
2747         }
2748         */
2749
2750         string namestr = "";
2751         if (source)
2752                 namestr = playername(source, autocvar_g_chat_teamcolors);
2753
2754         string colorprefix = (strdecolorize(namestr) == namestr) ? "^3" : "^7";
2755
2756         string msgstr = "", cmsgstr = "";
2757         string privatemsgprefix = string_null;
2758         int privatemsgprefixlen = 0;
2759         if (msgin != "")
2760         {
2761                 bool found_me = false;
2762                 if(strstrofs(msgin, "/me", 0) >= 0)
2763                 {
2764                         string newmsgin = "";
2765                         string newnamestr = ((teamsay) ? strcat(colorstr, "(", colorprefix, namestr, colorstr, ")", "^7") : strcat(colorprefix, namestr, "^7"));
2766                         FOREACH_WORD(msgin, true,
2767                         {
2768                                 if(strdecolorize(it) == "/me")
2769                                 {
2770                                         found_me = true;
2771                                         newmsgin = cons(newmsgin, newnamestr);
2772                                 }
2773                                 else
2774                                         newmsgin = cons(newmsgin, it);
2775                         });
2776                         msgin = newmsgin;
2777                 }
2778
2779                 if(privatesay)
2780                 {
2781                         msgstr = strcat("\{1}\{13}* ", colorprefix, namestr, "^3 tells you: ^7");
2782                         privatemsgprefixlen = strlen(msgstr);
2783                         msgstr = strcat(msgstr, msgin);
2784                         cmsgstr = strcat(colorstr, colorprefix, namestr, "^3 tells you:\n^7", msgin);
2785                         privatemsgprefix = strcat("\{1}\{13}* ^3You tell ", playername(privatesay, autocvar_g_chat_teamcolors), ": ^7");
2786                 }
2787                 else if(teamsay)
2788                 {
2789                         if(found_me)
2790                         {
2791                                 //msgin = strreplace("/me", "", msgin);
2792                                 //msgin = substring(msgin, 3, strlen(msgin));
2793                                 //msgin = strreplace("/me", strcat(colorstr, "(", colorprefix, namestr, colorstr, ")^7"), msgin);
2794                                 msgstr = strcat("\{1}\{13}^4* ", "^7", msgin);
2795                         }
2796                         else
2797                                 msgstr = strcat("\{1}\{13}", colorstr, "(", colorprefix, namestr, colorstr, ") ^7", msgin);
2798                         cmsgstr = strcat(colorstr, "(", colorprefix, namestr, colorstr, ")\n^7", msgin);
2799                 }
2800                 else
2801                 {
2802                         if(found_me)
2803                         {
2804                                 //msgin = strreplace("/me", "", msgin);
2805                                 //msgin = substring(msgin, 3, strlen(msgin));
2806                                 //msgin = strreplace("/me", strcat(colorprefix, namestr), msgin);
2807                                 msgstr = strcat("\{1}^4* ^7", msgin);
2808                         }
2809                         else {
2810                                 msgstr = "\{1}";
2811                                 msgstr = strcat(msgstr, (namestr != "") ? strcat(colorprefix, namestr, "^7: ") : "^7");
2812                                 msgstr = strcat(msgstr, msgin);
2813                         }
2814                         cmsgstr = "";
2815                 }
2816                 msgstr = strcat(strreplace("\n", " ", msgstr), "\n"); // newlines only are good for centerprint
2817         }
2818
2819         string fullmsgstr = msgstr;
2820         string fullcmsgstr = cmsgstr;
2821
2822         // FLOOD CONTROL
2823         int flood = 0;
2824         var .float flood_field = floodcontrol_chat;
2825         if(floodcontrol && source)
2826         {
2827                 float flood_spl;
2828                 float flood_burst;
2829                 float flood_lmax;
2830                 float lines;
2831                 if(privatesay)
2832                 {
2833                         flood_spl = autocvar_g_chat_flood_spl_tell;
2834                         flood_burst = autocvar_g_chat_flood_burst_tell;
2835                         flood_lmax = autocvar_g_chat_flood_lmax_tell;
2836                         flood_field = floodcontrol_chattell;
2837                 }
2838                 else if(teamsay)
2839                 {
2840                         flood_spl = autocvar_g_chat_flood_spl_team;
2841                         flood_burst = autocvar_g_chat_flood_burst_team;
2842                         flood_lmax = autocvar_g_chat_flood_lmax_team;
2843                         flood_field = floodcontrol_chatteam;
2844                 }
2845                 else
2846                 {
2847                         flood_spl = autocvar_g_chat_flood_spl;
2848                         flood_burst = autocvar_g_chat_flood_burst;
2849                         flood_lmax = autocvar_g_chat_flood_lmax;
2850                         flood_field = floodcontrol_chat;
2851                 }
2852                 flood_burst = max(0, flood_burst - 1);
2853                 // to match explanation in default.cfg, a value of 3 must allow three-line bursts and not four!
2854
2855                 // do flood control for the default line size
2856                 if(msgstr != "")
2857                 {
2858                         getWrappedLine_remaining = msgstr;
2859                         msgstr = "";
2860                         lines = 0;
2861                         while(getWrappedLine_remaining && (!flood_lmax || lines <= flood_lmax))
2862                         {
2863                                 msgstr = strcat(msgstr, " ", getWrappedLineLen(82.4289758859709, strlennocol)); // perl averagewidth.pl < gfx/vera-sans.width
2864                                 ++lines;
2865                         }
2866                         msgstr = substring(msgstr, 1, strlen(msgstr) - 1);
2867
2868                         if(getWrappedLine_remaining != "")
2869                         {
2870                                 msgstr = strcat(msgstr, "\n");
2871                                 flood = 2;
2872                         }
2873
2874                         if (time >= source.(flood_field))
2875                         {
2876                                 source.(flood_field) = max(time - flood_burst * flood_spl, source.(flood_field)) + lines * flood_spl;
2877                         }
2878                         else
2879                         {
2880                                 flood = 1;
2881                                 msgstr = fullmsgstr;
2882                         }
2883                 }
2884                 else
2885                 {
2886                         if (time >= source.(flood_field))
2887                                 source.(flood_field) = max(time - flood_burst * flood_spl, source.(flood_field)) + flood_spl;
2888                         else
2889                                 flood = 1;
2890                 }
2891
2892                 if (timeout_status == TIMEOUT_ACTIVE) // when game is paused, no flood protection
2893                         source.(flood_field) = flood = 0;
2894         }
2895
2896         string sourcemsgstr, sourcecmsgstr;
2897         if(flood == 2) // cannot happen for empty msgstr
2898         {
2899                 if(autocvar_g_chat_flood_notify_flooder)
2900                 {
2901                         sourcemsgstr = strcat(msgstr, "\n^3FLOOD CONTROL: ^7message too long, trimmed\n");
2902                         sourcecmsgstr = "";
2903                 }
2904                 else
2905                 {
2906                         sourcemsgstr = fullmsgstr;
2907                         sourcecmsgstr = fullcmsgstr;
2908                 }
2909                 cmsgstr = "";
2910         }
2911         else
2912         {
2913                 sourcemsgstr = msgstr;
2914                 sourcecmsgstr = cmsgstr;
2915         }
2916
2917         if (!privatesay && source && !(IS_PLAYER(source) || source.caplayer))
2918         {
2919                 if (!game_stopped)
2920                 if (teamsay || (autocvar_g_chat_nospectators == 1) || (autocvar_g_chat_nospectators == 2 && !warmup_stage))
2921                         teamsay = -1; // spectators
2922         }
2923
2924         if(flood)
2925                 LOG_INFO("NOTE: ", playername(source, true), "^7 is flooding.");
2926
2927         // build sourcemsgstr by cutting off a prefix and replacing it by the other one
2928         if(privatesay)
2929                 sourcemsgstr = strcat(privatemsgprefix, substring(sourcemsgstr, privatemsgprefixlen, -1));
2930
2931         int ret;
2932         if(source && CS(source).muted)
2933         {
2934                 // always fake the message
2935                 ret = -1;
2936         }
2937         else if(flood == 1)
2938         {
2939                 if (autocvar_g_chat_flood_notify_flooder)
2940                 {
2941                         sprint(source, strcat("^3FLOOD CONTROL: ^7wait ^1", ftos(source.(flood_field) - time), "^3 seconds\n"));
2942                         ret = 0;
2943                 }
2944                 else
2945                         ret = -1;
2946         }
2947         else
2948         {
2949                 ret = 1;
2950         }
2951
2952         if (privatesay && source && !(IS_PLAYER(source) || source.caplayer))
2953         {
2954                 if (!game_stopped)
2955                 if ((privatesay && (IS_PLAYER(privatesay) || privatesay.caplayer)) && ((autocvar_g_chat_nospectators == 1) || (autocvar_g_chat_nospectators == 2 && !warmup_stage)))
2956                         ret = -1; // just hide the message completely
2957         }
2958
2959         MUTATOR_CALLHOOK(ChatMessage, source, ret);
2960         ret = M_ARGV(1, int);
2961
2962         string event_log_msg = "";
2963
2964         if(sourcemsgstr != "" && ret != 0)
2965         {
2966                 if(ret < 0) // faked message, because the player is muted
2967                 {
2968                         sprint(source, sourcemsgstr);
2969                         if(sourcecmsgstr != "" && !privatesay)
2970                                 centerprint(source, sourcecmsgstr);
2971                 }
2972                 else if(privatesay) // private message, between 2 people only
2973                 {
2974                         sprint(source, sourcemsgstr);
2975                         if (!autocvar_g_chat_tellprivacy) { dedicated_print(msgstr); } // send to server console too if "tellprivacy" is disabled
2976                         if(!MUTATOR_CALLHOOK(ChatMessageTo, privatesay, source))
2977                         {
2978                                 sprint(privatesay, msgstr);
2979                                 if(cmsgstr != "")
2980                                         centerprint(privatesay, cmsgstr);
2981                         }
2982                 }
2983                 else if ( teamsay && CS(source).active_minigame )
2984                 {
2985                         sprint(source, sourcemsgstr);
2986                         dedicated_print(msgstr); // send to server console too
2987                         FOREACH_CLIENT(IS_REAL_CLIENT(it) && it != source && CS(it).active_minigame == CS(source).active_minigame && !MUTATOR_CALLHOOK(ChatMessageTo, it, source), {
2988                                 sprint(it, msgstr);
2989                         });
2990                         event_log_msg = sprintf(":chat_minigame:%d:%s:%s", source.playerid, CS(source).active_minigame.netname, msgin);
2991
2992                 }
2993                 else if(teamsay > 0) // team message, only sent to team mates
2994                 {
2995                         sprint(source, sourcemsgstr);
2996                         dedicated_print(msgstr); // send to server console too
2997                         if(sourcecmsgstr != "")
2998                                 centerprint(source, sourcecmsgstr);
2999                         FOREACH_CLIENT((IS_PLAYER(it) || it.caplayer) && IS_REAL_CLIENT(it) && it != source && it.team == source.team && !MUTATOR_CALLHOOK(ChatMessageTo, it, source), {
3000                                 sprint(it, msgstr);
3001                                 if(cmsgstr != "")
3002                                         centerprint(it, cmsgstr);
3003                         });
3004                         event_log_msg = sprintf(":chat_team:%d:%d:%s", source.playerid, source.team, strreplace("\n", " ", msgin));
3005                 }
3006                 else if(teamsay < 0) // spectator message, only sent to spectators
3007                 {
3008                         sprint(source, sourcemsgstr);
3009                         dedicated_print(msgstr); // send to server console too
3010                         FOREACH_CLIENT(!(IS_PLAYER(it) || it.caplayer) && IS_REAL_CLIENT(it) && it != source && !MUTATOR_CALLHOOK(ChatMessageTo, it, source), {
3011                                 sprint(it, msgstr);
3012                         });
3013                         event_log_msg = sprintf(":chat_spec:%d:%s", source.playerid, strreplace("\n", " ", msgin));
3014                 }
3015                 else
3016                 {
3017                         if (source) {
3018                                 sprint(source, sourcemsgstr);
3019                                 dedicated_print(msgstr); // send to server console too
3020                                 MX_Say(strcat(playername(source, true), "^7: ", msgin));
3021                         }
3022                         FOREACH_CLIENT(IS_REAL_CLIENT(it) && it != source && !MUTATOR_CALLHOOK(ChatMessageTo, it, source), {
3023                                 sprint(it, msgstr);
3024                         });
3025                         event_log_msg = sprintf(":chat:%d:%s", source.playerid, strreplace("\n", " ", msgin));
3026                 }
3027         }
3028
3029         if (autocvar_sv_eventlog && (event_log_msg != "")) {
3030                 GameLogEcho(event_log_msg);
3031         }
3032
3033         return ret;
3034 }
3035
3036 // hack to copy the button fields from the client entity to the Client State
3037 void PM_UpdateButtons(entity this, entity store)
3038 {
3039         if(this.impulse)
3040                 store.impulse = this.impulse;
3041         this.impulse = 0;
3042
3043         bool typing = this.buttonchat || this.button12;
3044
3045         store.button0 = (typing) ? 0 : this.button0;
3046         //button1?!
3047         store.button2 = (typing) ? 0 : this.button2;
3048         store.button3 = (typing) ? 0 : this.button3;
3049         store.button4 = this.button4;
3050         store.button5 = (typing) ? 0 : this.button5;
3051         store.button6 = this.button6;
3052         store.button7 = this.button7;
3053         store.button8 = this.button8;
3054         store.button9 = this.button9;
3055         store.button10 = this.button10;
3056         store.button11 = this.button11;
3057         store.button12 = this.button12;
3058         store.button13 = this.button13;
3059         store.button14 = this.button14;
3060         store.button15 = this.button15;
3061         store.button16 = this.button16;
3062         store.buttonuse = this.buttonuse;
3063         store.buttonchat = this.buttonchat;
3064
3065         store.cursor_active = this.cursor_active;
3066         store.cursor_screen = this.cursor_screen;
3067         store.cursor_trace_start = this.cursor_trace_start;
3068         store.cursor_trace_endpos = this.cursor_trace_endpos;
3069         store.cursor_trace_ent = this.cursor_trace_ent;
3070
3071         store.ping = this.ping;
3072         store.ping_packetloss = this.ping_packetloss;
3073         store.ping_movementloss = this.ping_movementloss;
3074
3075         store.v_angle = this.v_angle;
3076         store.movement = (typing) ? '0 0 0' : this.movement;
3077 }
3078
3079 NET_HANDLE(fpsreport, bool)
3080 {
3081         int fps = ReadShort();
3082         PlayerScore_Set(sender, SP_FPS, fps);
3083         return true;
3084 }