qcsrc/server/client.qc

   1 #include "client.qh"
   2
   3 #include "anticheat.qh"
   4 #include "impulse.qh"
   5 #include "player.qh"
   6 #include "ipban.qh"
   7 #include "miscfunctions.qh"
   8 #include "portals.qh"
   9 #include "teamplay.qh"
  10 #include "playerdemo.qh"
  11 #include "spawnpoints.qh"
  12 #include "g_damage.qh"
  13 #include "g_hook.qh"
  14 #include "command/common.qh"
  15 #include "cheats.qh"
  16 #include "g_world.qh"
  17 #include "race.qh"
  18 #include "antilag.qh"
  19 #include "campaign.qh"
  20 #include "command/common.qh"
  21 #include "scores_rules.qh"
  22
  23 #include "bot/api.qh"
  24
  25 #include "../common/ent_cs.qh"
  26 #include <common/state.qh>
  27
  28 #include <common/effects/qc/globalsound.qh>
  29
  30 #include "../common/triggers/func/conveyor.qh"
  31 #include "../common/triggers/teleporters.qh"
  32
  33 #include "../common/vehicles/all.qh"
  34
  35 #include "weapons/hitplot.qh"
  36 #include "weapons/weaponsystem.qh"
  37
  38 #include "../common/net_notice.qh"
  39 #include "../common/physics/player.qh"
  40
  41 #include "../common/items/_mod.qh"
  42
  43 #include "../common/mutators/mutator/waypoints/all.qh"
  44
  45 #include "../common/triggers/subs.qh"
  46 #include "../common/triggers/triggers.qh"
  47 #include "../common/triggers/trigger/secret.qh"
  48
  49 #include "../common/minigames/sv_minigames.qh"
  50
  51 #include "../common/items/inventory.qh"
  52
  53 #include "../common/monsters/sv_monsters.qh"
  54
  55 #include "../lib/warpzone/server.qh"
  56
  57 STATIC_METHOD(Client, Add, void(Client this, int _team))
  58 {
  59     ClientConnect(this);
  60     TRANSMUTE(Player, this);
  61     this.frame = 12; // 7
  62     this.team = _team;
  63     PutClientInServer(this);
  64 }
  65
  66 void PutObserverInServer(entity this);
  67
  68 STATIC_METHOD(Client, Remove, void(Client this))
  69 {
  70     TRANSMUTE(Observer, this);
  71     PutClientInServer(this);
  72     ClientDisconnect(this);
  73 }
  74
  75 void send_CSQC_teamnagger() {
  76         WriteHeader(MSG_BROADCAST, TE_CSQC_TEAMNAGGER);
  77 }
  78
  79 int CountSpectators(entity player, entity to)
  80 {
  81         if(!player) { return 0; } // not sure how, but best to be safe
  82
  83         int spec_count = 0;
  84
  85         FOREACH_CLIENT(IS_REAL_CLIENT(it) && IS_SPEC(it) && it != to && it.enemy == player,
  86         {
  87                 spec_count++;
  88         });
  89
  90         return spec_count;
  91 }
  92
  93 void WriteSpectators(entity player, entity to)
  94 {
  95         if(!player) { return; } // not sure how, but best to be safe
  96
  97         FOREACH_CLIENT(IS_REAL_CLIENT(it) && IS_SPEC(it) && it != to && it.enemy == player,
  98         {
  99                 WriteByte(MSG_ENTITY, num_for_edict(it));
 100         });
 101 }
 102
 103 bool ClientData_Send(entity this, entity to, int sf)
 104 {
 105         assert(to == this.owner, return false);
 106
 107         entity e = to;
 108         if (IS_SPEC(e)) e = e.enemy;
 109
 110         sf = 0;
 111         if (e.race_completed)       sf |= 1; // forced scoreboard
 112         if (to.spectatee_status)    sf |= 2; // spectator ent number follows
 113         if (e.zoomstate)            sf |= 4; // zoomed
 114         if (e.porto_v_angle_held)   sf |= 8; // angles held
 115         if (autocvar_sv_showspectators) sf |= 16; // show spectators
 116
 117         WriteHeader(MSG_ENTITY, ENT_CLIENT_CLIENTDATA);
 118         WriteByte(MSG_ENTITY, sf);
 119
 120         if (sf & 2)
 121         {
 122                 WriteByte(MSG_ENTITY, to.spectatee_status);
 123         }
 124         if (sf & 8)
 125         {
 126                 WriteAngle(MSG_ENTITY, e.v_angle.x);
 127                 WriteAngle(MSG_ENTITY, e.v_angle.y);
 128         }
 129
 130         if(sf & 16)
 131         {
 132                 float specs = CountSpectators(e, to);
 133                 WriteByte(MSG_ENTITY, specs);
 134                 WriteSpectators(e, to);
 135         }
 136
 137         return true;
 138 }
 139
 140 void ClientData_Attach(entity this)
 141 {
 142         Net_LinkEntity(this.clientdata = new_pure(clientdata), false, 0, ClientData_Send);
 143         this.clientdata.drawonlytoclient = this;
 144         this.clientdata.owner = this;
 145 }
 146
 147 void ClientData_Detach(entity this)
 148 {
 149         delete(this.clientdata);
 150         this.clientdata = NULL;
 151 }
 152
 153 void ClientData_Touch(entity e)
 154 {
 155         e.clientdata.SendFlags = 1;
 156
 157         // make it spectatable
 158         FOREACH_CLIENT(IS_REAL_CLIENT(it) && it != e && IS_SPEC(it) && it.enemy == e, LAMBDA(it.clientdata.SendFlags = 1));
 159 }
 160
 161 .string netname_previous;
 162
 163 void SetSpectatee(entity this, entity spectatee);
 164 void SetSpectatee_status(entity this, int spectatee_num);
 165
 166
 167 /*
 168 =============
 169 CheckPlayerModel
 170
 171 Checks if the argument string can be a valid playermodel.
 172 Returns a valid one in doubt.
 173 =============
 174 */
 175 string FallbackPlayerModel;
 176 string CheckPlayerModel(string plyermodel) {
 177         if(FallbackPlayerModel != cvar_defstring("_cl_playermodel"))
 178         {
 179                 // note: we cannot summon Don Strunzone here, some player may
 180                 // still have the model string set. In case anyone manages how
 181                 // to change a cvar default, we'll have a small leak here.
 182                 FallbackPlayerModel = strzone(cvar_defstring("_cl_playermodel"));
 183         }
 184         // only in right path
 185         if( substring(plyermodel,0,14) != "models/player/")
 186                 return FallbackPlayerModel;
 187         // only good file extensions
 188         if(substring(plyermodel,-4,4) != ".zym")
 189         if(substring(plyermodel,-4,4) != ".dpm")
 190         if(substring(plyermodel,-4,4) != ".iqm")
 191         if(substring(plyermodel,-4,4) != ".md3")
 192         if(substring(plyermodel,-4,4) != ".psk")
 193                 return FallbackPlayerModel;
 194         // forbid the LOD models
 195         if(substring(plyermodel, -9,5) == "_lod1")
 196                 return FallbackPlayerModel;
 197         if(substring(plyermodel, -9,5) == "_lod2")
 198                 return FallbackPlayerModel;
 199         if(plyermodel != strtolower(plyermodel))
 200                 return FallbackPlayerModel;
 201         // also, restrict to server models
 202         if(autocvar_sv_servermodelsonly)
 203         {
 204                 if(!fexists(plyermodel))
 205                         return FallbackPlayerModel;
 206         }
 207         return plyermodel;
 208 }
 209
 210 void setplayermodel(entity e, string modelname)
 211 {
 212         precache_model(modelname);
 213         _setmodel(e, modelname);
 214         player_setupanimsformodel(e);
 215         if(!autocvar_g_debug_globalsounds)
 216                 UpdatePlayerSounds(e);
 217 }
 218
 219 void FixPlayermodel(entity player);
 220 /** putting a client as observer in the server */
 221 void PutObserverInServer(entity this)
 222 {
 223     bool mutator_returnvalue = MUTATOR_CALLHOOK(MakePlayerObserver, this);
 224         PlayerState_detach(this);
 225
 226         if (IS_PLAYER(this) && this.health >= 1) {
 227         // despawn effect
 228                 Send_Effect(EFFECT_SPAWN_NEUTRAL, this.origin, '0 0 0', 1);
 229     }
 230
 231     {
 232         entity spot = SelectSpawnPoint(this, true);
 233         if (!spot) LOG_FATAL("No spawnpoints for observers?!?");
 234         this.angles = spot.angles;
 235         this.angles_z = 0;
 236         this.fixangle = true;
 237         // offset it so that the spectator spawns higher off the ground, looks better this way
 238         setorigin(this, spot.origin + STAT(PL_VIEW_OFS, NULL));
 239         this.prevorigin = this.origin;
 240         if (IS_REAL_CLIENT(this))
 241         {
 242             msg_entity = this;
 243             WriteByte(MSG_ONE, SVC_SETVIEW);
 244             WriteEntity(MSG_ONE, this);
 245         }
 246         // give the spectator some space between walls for MOVETYPE_FLY_WORLDONLY
 247         // so that your view doesn't go into the ceiling with MOVETYPE_FLY_WORLDONLY, previously "PL_VIEW_OFS"
 248         if(!autocvar_g_debug_globalsounds)
 249         {
 250                 // needed for player sounds
 251                 this.model = "";
 252                 FixPlayermodel(this);
 253         }
 254         setmodel(this, MDL_Null);
 255         setsize(this, STAT(PL_CROUCH_MIN, NULL), STAT(PL_CROUCH_MAX, NULL));
 256         this.view_ofs = '0 0 0';
 257     }
 258
 259     RemoveGrapplingHook(this);
 260         Portal_ClearAll(this);
 261         Unfreeze(this);
 262         SetSpectatee(this, NULL);
 263
 264         if (this.alivetime)
 265         {
 266                 if (!warmup_stage)
 267                         PS_GR_P_ADDVAL(this, PLAYERSTATS_ALIVETIME, time - this.alivetime);
 268                 this.alivetime = 0;
 269         }
 270
 271         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
 272
 273         WaypointSprite_PlayerDead(this);
 274
 275         if (mutator_returnvalue) {
 276             // mutator prevents resetting teams+score
 277         } else {
 278                 this.team = -1;  // move this as it is needed to log the player spectating in eventlog
 279         this.frags = FRAGS_SPECTATOR;
 280         PlayerScore_Clear(this);  // clear scores when needed
 281     }
 282
 283         if (this.killcount != FRAGS_SPECTATOR)
 284         {
 285                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_QUIT_SPECTATE, this.netname);
 286                 if(!intermission_running)
 287                 if(autocvar_g_chat_nospectators == 1 || (!(warmup_stage || gameover) && autocvar_g_chat_nospectators == 2))
 288                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_CHAT_NOSPECTATORS);
 289
 290                 if(this.just_joined == false) {
 291                         LogTeamchange(this.playerid, -1, 4);
 292                 } else
 293                         this.just_joined = false;
 294         }
 295
 296         accuracy_resend(this);
 297
 298         this.spectatortime = time;
 299         if(this.bot_attack)
 300                 IL_REMOVE(g_bot_targets, this);
 301         this.bot_attack = false;
 302     this.hud = HUD_NORMAL;
 303         TRANSMUTE(Observer, this);
 304         this.iscreature = false;
 305         this.teleportable = TELEPORT_SIMPLE;
 306         if(this.damagedbycontents)
 307                 IL_REMOVE(g_damagedbycontents, this);
 308         this.damagedbycontents = false;
 309         this.health = FRAGS_SPECTATOR;
 310         SetSpectatee_status(this, etof(this));
 311         this.takedamage = DAMAGE_NO;
 312         this.solid = SOLID_NOT;
 313         set_movetype(this, MOVETYPE_FLY_WORLDONLY); // user preference is controlled by playerprethink
 314         this.flags = FL_CLIENT | FL_NOTARGET;
 315         this.armorvalue = 666;
 316         this.effects = 0;
 317         this.armorvalue = autocvar_g_balance_armor_start;
 318         this.pauserotarmor_finished = 0;
 319         this.pauserothealth_finished = 0;
 320         this.pauseregen_finished = 0;
 321         this.damageforcescale = 0;
 322         this.death_time = 0;
 323         this.respawn_flags = 0;
 324         this.respawn_time = 0;
 325         this.stat_respawn_time = 0;
 326         this.alpha = 0;
 327         this.scale = 0;
 328         this.fade_time = 0;
 329         this.pain_frame = 0;
 330         this.pain_finished = 0;
 331         this.strength_finished = 0;
 332         this.invincible_finished = 0;
 333         this.superweapons_finished = 0;
 334         this.pushltime = 0;
 335         this.istypefrag = 0;
 336         setthink(this, func_null);
 337         this.nextthink = 0;
 338         this.hook_time = 0;
 339         this.deadflag = DEAD_NO;
 340         this.crouch = false;
 341         this.revival_time = 0;
 342
 343         this.items = 0;
 344         this.weapons = '0 0 0';
 345         this.drawonlytoclient = this;
 346
 347         this.weaponname = "";
 348         this.weaponmodel = "";
 349         for (int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 350         {
 351                 this.weaponentities[slot] = NULL;
 352         }
 353         this.exteriorweaponentity = NULL;
 354         this.killcount = FRAGS_SPECTATOR;
 355         this.velocity = '0 0 0';
 356         this.avelocity = '0 0 0';
 357         this.punchangle = '0 0 0';
 358         this.punchvector = '0 0 0';
 359         this.oldvelocity = this.velocity;
 360         this.fire_endtime = -1;
 361         this.event_damage = func_null;
 362
 363         STAT(ACTIVEWEAPON, this) = WEP_Null.m_id;
 364         STAT(SWITCHINGWEAPON, this) = WEP_Null.m_id;
 365         STAT(SWITCHWEAPON, this) = WEP_Null.m_id;
 366 }
 367
 368 int player_getspecies(entity this)
 369 {
 370         get_model_parameters(this.model, this.skin);
 371         int s = get_model_parameters_species;
 372         get_model_parameters(string_null, 0);
 373         if (s < 0) return SPECIES_HUMAN;
 374         return s;
 375 }
 376
 377 .float model_randomizer;
 378 void FixPlayermodel(entity player)
 379 {
 380         string defaultmodel = "";
 381         int defaultskin = 0;
 382         if(autocvar_sv_defaultcharacter)
 383         {
 384                 if(teamplay)
 385                 {
 386                         string s = Static_Team_ColorName_Lower(player.team);
 387                         if (s != "neutral")
 388                         {
 389                                 defaultmodel = cvar_string(strcat("sv_defaultplayermodel_", s));
 390                                 defaultskin = cvar(strcat("sv_defaultplayerskin_", s));
 391                         }
 392                 }
 393
 394                 if(defaultmodel == "")
 395                 {
 396                         defaultmodel = autocvar_sv_defaultplayermodel;
 397                         defaultskin = autocvar_sv_defaultplayerskin;
 398                 }
 399
 400                 int n = tokenize_console(defaultmodel);
 401                 if(n > 0)
 402                 {
 403                         defaultmodel = argv(floor(n * player.model_randomizer));
 404                         // However, do NOT randomize if the player-selected model is in the list.
 405                         for (int i = 0; i < n; ++i)
 406                                 if ((argv(i) == player.playermodel && defaultskin == stof(player.playerskin)) || argv(i) == strcat(player.playermodel, ":", player.playerskin))
 407                                         defaultmodel = argv(i);
 408                 }
 409
 410                 int i = strstrofs(defaultmodel, ":", 0);
 411                 if(i >= 0)
 412                 {
 413                         defaultskin = stof(substring(defaultmodel, i+1, -1));
 414                         defaultmodel = substring(defaultmodel, 0, i);
 415                 }
 416         }
 417         if(autocvar_sv_defaultcharacterskin && !defaultskin)
 418         {
 419                 if(teamplay)
 420                 {
 421                         string s = Static_Team_ColorName_Lower(player.team);
 422                         if (s != "neutral")
 423                                 defaultskin = cvar(strcat("sv_defaultplayerskin_", s));
 424                 }
 425
 426                 if(!defaultskin)
 427                         defaultskin = autocvar_sv_defaultplayerskin;
 428         }
 429
 430         MUTATOR_CALLHOOK(FixPlayermodel, defaultmodel, defaultskin, player);
 431         defaultmodel = M_ARGV(0, string);
 432         defaultskin = M_ARGV(1, int);
 433
 434         bool chmdl = false;
 435         int oldskin;
 436         if(defaultmodel != "")
 437         {
 438                 if (defaultmodel != player.model)
 439                 {
 440                         vector m1 = player.mins;
 441                         vector m2 = player.maxs;
 442                         setplayermodel (player, defaultmodel);
 443                         setsize (player, m1, m2);
 444                         chmdl = true;
 445                 }
 446
 447                 oldskin = player.skin;
 448                 player.skin = defaultskin;
 449         } else {
 450                 if (player.playermodel != player.model || player.playermodel == "")
 451                 {
 452                         player.playermodel = CheckPlayerModel(player.playermodel); // this is never "", so no endless loop
 453                         vector m1 = player.mins;
 454                         vector m2 = player.maxs;
 455                         setplayermodel (player, player.playermodel);
 456                         setsize (player, m1, m2);
 457                         chmdl = true;
 458                 }
 459
 460                 if(!autocvar_sv_defaultcharacterskin)
 461                 {
 462                         oldskin = player.skin;
 463                         player.skin = stof(player.playerskin);
 464                 }
 465                 else
 466                 {
 467                         oldskin = player.skin;
 468                         player.skin = defaultskin;
 469                 }
 470         }
 471
 472         if(chmdl || oldskin != player.skin) // model or skin has changed
 473         {
 474                 player.species = player_getspecies(player); // update species
 475                 if(!autocvar_g_debug_globalsounds)
 476                         UpdatePlayerSounds(player); // update skin sounds
 477         }
 478
 479         if(!teamplay)
 480                 if(strlen(autocvar_sv_defaultplayercolors))
 481                         if(player.clientcolors != stof(autocvar_sv_defaultplayercolors))
 482                                 setcolor(player, stof(autocvar_sv_defaultplayercolors));
 483 }
 484
 485
 486 /** Called when a client spawns in the server */
 487 void PutClientInServer(entity this)
 488 {
 489         if (IS_BOT_CLIENT(this)) {
 490                 TRANSMUTE(Player, this);
 491         } else if (IS_REAL_CLIENT(this)) {
 492                 msg_entity = this;
 493                 WriteByte(MSG_ONE, SVC_SETVIEW);
 494                 WriteEntity(MSG_ONE, this);
 495         }
 496         if (gameover) {
 497                 TRANSMUTE(Observer, this);
 498         }
 499
 500         SetSpectatee(this, NULL);
 501
 502         // reset player keys
 503         this.itemkeys = 0;
 504
 505         MUTATOR_CALLHOOK(PutClientInServer, this);
 506
 507         if (IS_OBSERVER(this)) {
 508                 PutObserverInServer(this);
 509         } else if (IS_PLAYER(this)) {
 510                 if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
 511
 512                 PlayerState_attach(this);
 513                 accuracy_resend(this);
 514
 515                 if (this.team < 0)
 516                         JoinBestTeam(this, false, true);
 517
 518                 entity spot = SelectSpawnPoint(this, false);
 519                 if (!spot) {
 520                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_JOIN_NOSPAWNS);
 521                         return; // spawn failed
 522                 }
 523
 524                 TRANSMUTE(Player, this);
 525
 526                 this.wasplayer = true;
 527                 this.iscreature = true;
 528                 this.teleportable = TELEPORT_NORMAL;
 529                 if(!this.damagedbycontents)
 530                         IL_PUSH(g_damagedbycontents, this);
 531                 this.damagedbycontents = true;
 532                 set_movetype(this, MOVETYPE_WALK);
 533                 this.solid = SOLID_SLIDEBOX;
 534                 this.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_SOLID;
 535                 if (autocvar_g_playerclip_collisions)
 536                         this.dphitcontentsmask |= DPCONTENTS_PLAYERCLIP;
 537                 if (IS_BOT_CLIENT(this) && autocvar_g_botclip_collisions)
 538                         this.dphitcontentsmask |= DPCONTENTS_BOTCLIP;
 539                 this.frags = FRAGS_PLAYER;
 540                 if (INDEPENDENT_PLAYERS) MAKE_INDEPENDENT_PLAYER(this);
 541                 this.flags = FL_CLIENT | FL_PICKUPITEMS;
 542                 if (autocvar__notarget)
 543                         this.flags |= FL_NOTARGET;
 544                 this.takedamage = DAMAGE_AIM;
 545                 this.effects = EF_TELEPORT_BIT | EF_RESTARTANIM_BIT;
 546                 this.dmg = 2; // WTF
 547
 548                 if (warmup_stage) {
 549                         this.ammo_shells = warmup_start_ammo_shells;
 550                         this.ammo_nails = warmup_start_ammo_nails;
 551                         this.ammo_rockets = warmup_start_ammo_rockets;
 552                         this.ammo_cells = warmup_start_ammo_cells;
 553                         this.ammo_plasma = warmup_start_ammo_plasma;
 554                         this.ammo_fuel = warmup_start_ammo_fuel;
 555                         this.health = warmup_start_health;
 556                         this.armorvalue = warmup_start_armorvalue;
 557                         this.weapons = WARMUP_START_WEAPONS;
 558                 } else {
 559                         this.ammo_shells = start_ammo_shells;
 560                         this.ammo_nails = start_ammo_nails;
 561                         this.ammo_rockets = start_ammo_rockets;
 562                         this.ammo_cells = start_ammo_cells;
 563                         this.ammo_plasma = start_ammo_plasma;
 564                         this.ammo_fuel = start_ammo_fuel;
 565                         this.health = start_health;
 566                         this.armorvalue = start_armorvalue;
 567                         this.weapons = start_weapons;
 568                 }
 569                 SetSpectatee_status(this, 0);
 570
 571                 this.superweapons_finished = (this.weapons & WEPSET_SUPERWEAPONS) ? time + autocvar_g_balance_superweapons_time : 0;
 572
 573                 this.items = start_items;
 574
 575                 this.spawnshieldtime = time + autocvar_g_spawnshieldtime;
 576                 this.pauserotarmor_finished = time + autocvar_g_balance_pause_armor_rot_spawn;
 577                 this.pauserothealth_finished = time + autocvar_g_balance_pause_health_rot_spawn;
 578                 this.pauserotfuel_finished = time + autocvar_g_balance_pause_fuel_rot_spawn;
 579                 this.pauseregen_finished = time + autocvar_g_balance_pause_health_regen_spawn;
 580                 // extend the pause of rotting if client was reset at the beginning of the countdown
 581                 if (!autocvar_sv_ready_restart_after_countdown && time < game_starttime) { // TODO why is this cvar NOTted?
 582                         float f = game_starttime - time;
 583                         this.spawnshieldtime += f;
 584                         this.pauserotarmor_finished += f;
 585                         this.pauserothealth_finished += f;
 586                         this.pauseregen_finished += f;
 587                 }
 588                 this.damageforcescale = 2;
 589                 this.death_time = 0;
 590                 this.respawn_flags = 0;
 591                 this.respawn_time = 0;
 592                 this.stat_respawn_time = 0;
 593                 this.scale = autocvar_sv_player_scale;
 594                 this.fade_time = 0;
 595                 this.pain_frame = 0;
 596                 this.pain_finished = 0;
 597                 this.pushltime = 0;
 598                 setthink(this, func_null); // players have no think function
 599                 this.nextthink = 0;
 600                 this.dmg_team = 0;
 601                 this.ballistics_density = autocvar_g_ballistics_density_player;
 602
 603                 this.deadflag = DEAD_NO;
 604
 605                 this.angles = spot.angles;
 606                 this.angles_z = 0; // never spawn tilted even if the spot says to
 607                 if (IS_BOT_CLIENT(this))
 608                         this.v_angle = this.angles;
 609                 this.fixangle = true; // turn this way immediately
 610                 this.oldvelocity = this.velocity = '0 0 0';
 611                 this.avelocity = '0 0 0';
 612                 this.punchangle = '0 0 0';
 613                 this.punchvector = '0 0 0';
 614
 615                 this.strength_finished = 0;
 616                 this.invincible_finished = 0;
 617                 this.fire_endtime = -1;
 618                 this.revival_time = 0;
 619                 this.air_finished = time + 12;
 620
 621                 entity spawnevent = new_pure(spawnevent);
 622                 spawnevent.owner = this;
 623                 Net_LinkEntity(spawnevent, false, 0.5, SpawnEvent_Send);
 624
 625                 // Cut off any still running player sounds.
 626                 stopsound(this, CH_PLAYER_SINGLE);
 627
 628                 this.model = "";
 629                 FixPlayermodel(this);
 630                 this.drawonlytoclient = NULL;
 631
 632                 this.crouch = false;
 633                 this.view_ofs = STAT(PL_VIEW_OFS, NULL);
 634                 setsize(this, STAT(PL_MIN, NULL), STAT(PL_MAX, NULL));
 635                 this.spawnorigin = spot.origin;
 636                 setorigin(this, spot.origin + '0 0 1' * (1 - this.mins.z - 24));
 637                 // don't reset back to last position, even if new position is stuck in solid
 638                 this.oldorigin = this.origin;
 639                 this.prevorigin = this.origin;
 640                 this.lastteleporttime = time; // prevent insane speeds due to changing origin
 641                 if(this.conveyor)
 642                         IL_REMOVE(g_conveyed, this);
 643                 this.conveyor = NULL; // prevent conveyors at the previous location from moving a freshly spawned player
 644                 this.hud = HUD_NORMAL;
 645
 646                 this.event_damage = PlayerDamage;
 647
 648                 if(!this.bot_attack)
 649                         IL_PUSH(g_bot_targets, this);
 650                 this.bot_attack = true;
 651                 this.monster_attack = true;
 652
 653                 PHYS_INPUT_BUTTON_ATCK(this) = PHYS_INPUT_BUTTON_JUMP(this) = PHYS_INPUT_BUTTON_ATCK2(this) = false;
 654
 655                 if (this.killcount == FRAGS_SPECTATOR) {
 656                         PlayerScore_Clear(this);
 657                         this.killcount = 0;
 658                 }
 659
 660                 for (int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 661                 {
 662                         CL_SpawnWeaponentity(this, weaponentities[slot]);
 663                 }
 664                 this.alpha = default_player_alpha;
 665                 this.colormod = '1 1 1' * autocvar_g_player_brightness;
 666                 this.exteriorweaponentity.alpha = default_weapon_alpha;
 667
 668                 this.speedrunning = false;
 669
 670                 target_voicescript_clear(this);
 671
 672                 // reset fields the weapons may use
 673                 FOREACH(Weapons, true, LAMBDA(
 674                         it.wr_resetplayer(it, this);
 675                         // reload all reloadable weapons
 676                         if (it.spawnflags & WEP_FLAG_RELOADABLE) {
 677                                 this.weapon_load[it.m_id] = it.reloading_ammo;
 678                         }
 679                 ));
 680
 681                 {
 682                         string s = spot.target;
 683                         spot.target = string_null;
 684                         SUB_UseTargets(spot, this, NULL);
 685                         spot.target = s;
 686                 }
 687
 688                 Unfreeze(this);
 689
 690                 MUTATOR_CALLHOOK(PlayerSpawn, this, spot);
 691
 692                 if (autocvar_spawn_debug)
 693                 {
 694                         sprint(this, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
 695                         delete(spot); // usefull for checking if there are spawnpoints, that let drop through the floor
 696                 }
 697
 698                 PS(this).m_switchweapon = w_getbestweapon(this);
 699                 this.cnt = -1; // W_LastWeapon will not complain
 700                 PS(this).m_weapon = WEP_Null;
 701                 this.weaponname = "";
 702                 PS(this).m_switchingweapon = WEP_Null;
 703
 704                 if (!warmup_stage && !this.alivetime)
 705                         this.alivetime = time;
 706
 707                 antilag_clear(this, CS(this));
 708         }
 709 }
 710
 711 void ClientInit_misc(entity this);
 712
 713 .float ebouncefactor, ebouncestop; // electro's values
 714 // TODO do we need all these fields, or should we stop autodetecting runtime
 715 // changes and just have a console command to update this?
 716 bool ClientInit_SendEntity(entity this, entity to, int sf)
 717 {
 718         WriteHeader(MSG_ENTITY, _ENT_CLIENT_INIT);
 719         return = true;
 720         msg_entity = to;
 721         // MSG_INIT replacement
 722         // TODO: make easier to use
 723         Registry_send_all();
 724         W_PROP_reload(MSG_ONE, to);
 725         ClientInit_misc(this);
 726         MUTATOR_CALLHOOK(Ent_Init);
 727 }
 728 void ClientInit_misc(entity this)
 729 {
 730         int channel = MSG_ONE;
 731         WriteHeader(channel, ENT_CLIENT_INIT);
 732         WriteByte(channel, g_nexball_meter_period * 32);
 733         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[0]));
 734         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[1]));
 735         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[2]));
 736         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[3]));
 737         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[0]));
 738         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[1]));
 739         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[2]));
 740         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[3]));
 741
 742         if(sv_foginterval && world.fog != "")
 743                 WriteString(channel, world.fog);
 744         else
 745                 WriteString(channel, "");
 746         WriteByte(channel, this.count * 255.0); // g_balance_armor_blockpercent
 747         WriteByte(channel, serverflags);
 748         WriteCoord(channel, autocvar_g_trueaim_minrange);
 749 }
 750
 751 void ClientInit_CheckUpdate(entity this)
 752 {
 753         this.nextthink = time;
 754         if(this.count != autocvar_g_balance_armor_blockpercent)
 755         {
 756                 this.count = autocvar_g_balance_armor_blockpercent;
 757                 this.SendFlags |= 1;
 758         }
 759 }
 760
 761 void ClientInit_Spawn()
 762 {
 763         entity e = new_pure(clientinit);
 764         setthink(e, ClientInit_CheckUpdate);
 765         Net_LinkEntity(e, false, 0, ClientInit_SendEntity);
 766
 767         ClientInit_CheckUpdate(e);
 768 }
 769
 770 /*
 771 =============
 772 SetNewParms
 773 =============
 774 */
 775 void SetNewParms ()
 776 {
 777         // initialize parms for a new player
 778         parm1 = -(86400 * 366);
 779
 780         MUTATOR_CALLHOOK(SetNewParms);
 781 }
 782
 783 /*
 784 =============
 785 SetChangeParms
 786 =============
 787 */
 788 void SetChangeParms (entity this)
 789 {
 790         // save parms for level change
 791         parm1 = this.parm_idlesince - time;
 792
 793         MUTATOR_CALLHOOK(SetChangeParms);
 794 }
 795
 796 /*
 797 =============
 798 DecodeLevelParms
 799 =============
 800 */
 801 void DecodeLevelParms(entity this)
 802 {
 803         // load parms
 804         this.parm_idlesince = parm1;
 805         if (this.parm_idlesince == -(86400 * 366))
 806                 this.parm_idlesince = time;
 807
 808         // whatever happens, allow 60 seconds of idling directly after connect for map loading
 809         this.parm_idlesince = max(this.parm_idlesince, time - sv_maxidle + 60);
 810
 811         MUTATOR_CALLHOOK(DecodeLevelParms);
 812 }
 813
 814 /*
 815 =============
 816 ClientKill
 817
 818 Called when a client types 'kill' in the console
 819 =============
 820 */
 821
 822 .float clientkill_nexttime;
 823 void ClientKill_Now_TeamChange(entity this)
 824 {
 825         if(this.killindicator_teamchange == -1)
 826         {
 827                 JoinBestTeam( this, false, true );
 828         }
 829         else if(this.killindicator_teamchange == -2)
 830         {
 831                 if(blockSpectators)
 832                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
 833                 PutObserverInServer(this);
 834         }
 835         else
 836                 SV_ChangeTeam(this, this.killindicator_teamchange - 1);
 837         this.killindicator_teamchange = 0;
 838 }
 839
 840 void ClientKill_Now(entity this)
 841 {
 842         if(this.vehicle)
 843         {
 844             vehicles_exit(this.vehicle, VHEF_RELEASE);
 845             if(!this.killindicator_teamchange)
 846             {
 847             this.vehicle_health = -1;
 848             Damage(this, this, this, 1 , DEATH_KILL.m_id, this.origin, '0 0 0');
 849             }
 850         }
 851
 852         if(this.killindicator && !wasfreed(this.killindicator))
 853                 delete(this.killindicator);
 854
 855         this.killindicator = NULL;
 856
 857         if(this.killindicator_teamchange)
 858                 ClientKill_Now_TeamChange(this);
 859
 860         if(!IS_SPEC(this) && !IS_OBSERVER(this))
 861                 Damage(this, this, this, 100000, DEATH_KILL.m_id, this.origin, '0 0 0');
 862
 863         // now I am sure the player IS dead
 864 }
 865 void KillIndicator_Think(entity this)
 866 {
 867         if (gameover)
 868         {
 869                 this.owner.killindicator = NULL;
 870                 delete(this);
 871                 return;
 872         }
 873
 874         if (this.owner.alpha < 0 && !this.owner.vehicle)
 875         {
 876                 this.owner.killindicator = NULL;
 877                 delete(this);
 878                 return;
 879         }
 880
 881         if(this.cnt <= 0)
 882         {
 883                 ClientKill_Now(this.owner);
 884                 return;
 885         }
 886     else if(g_cts && this.health == 1) // health == 1 means that it's silent
 887     {
 888         this.nextthink = time + 1;
 889         this.cnt -= 1;
 890     }
 891         else
 892         {
 893                 if(this.cnt <= 10)
 894                         setmodel(this, MDL_NUM(this.cnt));
 895                 if(IS_REAL_CLIENT(this.owner))
 896                 {
 897                         if(this.cnt <= 10)
 898                                 { Send_Notification(NOTIF_ONE, this.owner, MSG_ANNCE, Announcer_PickNumber(CNT_KILL, this.cnt)); }
 899                 }
 900                 this.nextthink = time + 1;
 901                 this.cnt -= 1;
 902         }
 903 }
 904
 905 float clientkilltime;
 906 void ClientKill_TeamChange (entity this, float targetteam) // 0 = don't change, -1 = auto, -2 = spec
 907 {
 908         float killtime;
 909         float starttime;
 910
 911         if (gameover)
 912                 return;
 913
 914         killtime = autocvar_g_balance_kill_delay;
 915
 916         if(g_race_qualifying || g_cts)
 917                 killtime = 0;
 918
 919     if(MUTATOR_CALLHOOK(ClientKill, this, killtime))
 920         return;
 921
 922         this.killindicator_teamchange = targetteam;
 923
 924     if(!this.killindicator)
 925         {
 926                 if(!IS_DEAD(this))
 927                 {
 928                         killtime = max(killtime, this.clientkill_nexttime - time);
 929                         this.clientkill_nexttime = time + killtime + autocvar_g_balance_kill_antispam;
 930                 }
 931
 932                 if(killtime <= 0 || !IS_PLAYER(this) || IS_DEAD(this))
 933                 {
 934                         ClientKill_Now(this);
 935                 }
 936                 else
 937                 {
 938                         starttime = max(time, clientkilltime);
 939
 940                         this.killindicator = spawn();
 941                         this.killindicator.owner = this;
 942                         this.killindicator.scale = 0.5;
 943                         setattachment(this.killindicator, this, "");
 944                         setorigin(this.killindicator, '0 0 52');
 945                         setthink(this.killindicator, KillIndicator_Think);
 946                         this.killindicator.nextthink = starttime + (this.lip) * 0.05;
 947                         clientkilltime = max(clientkilltime, this.killindicator.nextthink + 0.05);
 948                         this.killindicator.cnt = ceil(killtime);
 949                         this.killindicator.count = bound(0, ceil(killtime), 10);
 950                         //sprint(this, strcat("^1You'll be dead in ", ftos(this.killindicator.cnt), " seconds\n"));
 951
 952                         IL_EACH(g_clones, it.enemy == this && !(it.effects & CSQCMODEL_EF_RESPAWNGHOST),
 953                         {
 954                                 it.killindicator = spawn();
 955                                 it.killindicator.owner = it;
 956                                 it.killindicator.scale = 0.5;
 957                                 setattachment(it.killindicator, it, "");
 958                                 setorigin(it.killindicator, '0 0 52');
 959                                 setthink(it.killindicator, KillIndicator_Think);
 960                                 it.killindicator.nextthink = starttime + (it.lip) * 0.05;
 961                                 //clientkilltime = max(clientkilltime, it.killindicator.nextthink + 0.05);
 962                                 it.killindicator.cnt = ceil(killtime);
 963                         });
 964                         this.lip = 0;
 965                 }
 966         }
 967         if(this.killindicator)
 968         {
 969                 if(targetteam == 0) // just die
 970                 {
 971                         this.killindicator.colormod = '0 0 0';
 972                         if(IS_REAL_CLIENT(this))
 973                         if(this.killindicator.cnt > 0)
 974                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_TEAMCHANGE_SUICIDE, this.killindicator.cnt);
 975                 }
 976                 else if(targetteam == -1) // auto
 977                 {
 978                         this.killindicator.colormod = '0 1 0';
 979                         if(IS_REAL_CLIENT(this))
 980                         if(this.killindicator.cnt > 0)
 981                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_TEAMCHANGE_AUTO, this.killindicator.cnt);
 982                 }
 983                 else if(targetteam == -2) // spectate
 984                 {
 985                         this.killindicator.colormod = '0.5 0.5 0.5';
 986                         if(IS_REAL_CLIENT(this))
 987                         if(this.killindicator.cnt > 0)
 988                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_TEAMCHANGE_SPECTATE, this.killindicator.cnt);
 989                 }
 990                 else
 991                 {
 992                         this.killindicator.colormod = Team_ColorRGB(targetteam);
 993                         if(IS_REAL_CLIENT(this))
 994                         if(this.killindicator.cnt > 0)
 995                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, APP_TEAM_NUM(targetteam, CENTER_TEAMCHANGE), this.killindicator.cnt);
 996                 }
 997         }
 998
 999 }
1000
1001 void ClientKill (entity this)
1002 {
1003         if(gameover) return;
1004         if(this.player_blocked) return;
1005         if(STAT(FROZEN, this)) return;
1006
1007         ClientKill_TeamChange(this, 0);
1008 }
1009
1010 void FixClientCvars(entity e)
1011 {
1012         // send prediction settings to the client
1013         stuffcmd(e, "\nin_bindmap 0 0\n");
1014         if(autocvar_g_antilag == 3) // client side hitscan
1015                 stuffcmd(e, "cl_cmd settemp cl_prydoncursor_notrace 0\n");
1016         if(autocvar_sv_gentle)
1017                 stuffcmd(e, "cl_cmd settemp cl_gentle 1\n");
1018
1019         MUTATOR_CALLHOOK(FixClientCvars, e);
1020 }
1021
1022 float PlayerInIDList(entity p, string idlist)
1023 {
1024         float n, i;
1025         string s;
1026
1027         // NOTE: we do NOT check crypto_idfp_signed here, an unsigned ID is fine too for this
1028         if (!p.crypto_idfp)
1029                 return 0;
1030
1031         // this function allows abbreviated player IDs too!
1032         n = tokenize_console(idlist);
1033         for(i = 0; i < n; ++i)
1034         {
1035                 s = argv(i);
1036                 if(s == substring(p.crypto_idfp, 0, strlen(s)))
1037                         return 1;
1038         }
1039
1040         return 0;
1041 }
1042
1043 #ifdef DP_EXT_PRECONNECT
1044 /*
1045 =============
1046 ClientPreConnect
1047
1048 Called once (not at each match start) when a client begins a connection to the server
1049 =============
1050 */
1051 void ClientPreConnect ()
1052 {ENGINE_EVENT();
1053         if(autocvar_sv_eventlog)
1054         {
1055                 GameLogEcho(sprintf(":connect:%d:%d:%s",
1056                         this.playerid,
1057                         etof(this),
1058                         ((IS_REAL_CLIENT(this)) ? this.netaddress : "bot")
1059                 ));
1060         }
1061 }
1062 #endif
1063
1064 /**
1065 =============
1066 ClientConnect
1067
1068 Called when a client connects to the server
1069 =============
1070 */
1071 void ClientConnect(entity this)
1072 {
1073         if (Ban_MaybeEnforceBanOnce(this)) return;
1074         assert(!IS_CLIENT(this), return);
1075         this.flags |= FL_CLIENT;
1076         assert(player_count >= 0, player_count = 0);
1077
1078 #ifdef WATERMARK
1079         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_WATERMARK, WATERMARK);
1080 #endif
1081         this.version_nagtime = time + 10 + random() * 10;
1082         TRANSMUTE(Client, this);
1083
1084         // identify the right forced team
1085         if (autocvar_g_campaign)
1086         {
1087                 if (IS_REAL_CLIENT(this)) // only players, not bots
1088                 {
1089                         switch (autocvar_g_campaign_forceteam)
1090                         {
1091                                 case 1: this.team_forced = NUM_TEAM_1; break;
1092                                 case 2: this.team_forced = NUM_TEAM_2; break;
1093                                 case 3: this.team_forced = NUM_TEAM_3; break;
1094                                 case 4: this.team_forced = NUM_TEAM_4; break;
1095                                 default: this.team_forced = 0;
1096                         }
1097                 }
1098         }
1099         else if (PlayerInIDList(this, autocvar_g_forced_team_red))    this.team_forced = NUM_TEAM_1;
1100         else if (PlayerInIDList(this, autocvar_g_forced_team_blue))   this.team_forced = NUM_TEAM_2;
1101         else if (PlayerInIDList(this, autocvar_g_forced_team_yellow)) this.team_forced = NUM_TEAM_3;
1102         else if (PlayerInIDList(this, autocvar_g_forced_team_pink))   this.team_forced = NUM_TEAM_4;
1103         else switch (autocvar_g_forced_team_otherwise)
1104         {
1105                 default: this.team_forced = 0; break;
1106                 case "red": this.team_forced = NUM_TEAM_1; break;
1107                 case "blue": this.team_forced = NUM_TEAM_2; break;
1108                 case "yellow": this.team_forced = NUM_TEAM_3; break;
1109                 case "pink": this.team_forced = NUM_TEAM_4; break;
1110                 case "spectate":
1111                 case "spectator":
1112                         this.team_forced = -1;
1113                         break;
1114         }
1115         if (!teamplay && this.team_forced > 0) this.team_forced = 0;
1116
1117     {
1118         int id = this.playerid;
1119         this.playerid = 0; // silent
1120             JoinBestTeam(this, false, false); // if the team number is valid, keep it
1121             this.playerid = id;
1122     }
1123
1124         if (autocvar_sv_spectate || autocvar_g_campaign || this.team_forced < 0) {
1125                 TRANSMUTE(Observer, this);
1126         } else {
1127                 if (!teamplay || autocvar_g_balance_teams) {
1128                         TRANSMUTE(Player, this);
1129                         campaign_bots_may_start = true;
1130                 } else {
1131                         TRANSMUTE(Observer, this); // do it anyway
1132                 }
1133         }
1134
1135         PlayerStats_GameReport_AddEvent(sprintf("kills-%d", this.playerid));
1136
1137         // always track bots, don't ask for cl_allow_uidtracking
1138     if (IS_BOT_CLIENT(this)) PlayerStats_GameReport_AddPlayer(this);
1139
1140         if (autocvar_sv_eventlog)
1141                 GameLogEcho(strcat(":join:", ftos(this.playerid), ":", ftos(etof(this)), ":", ((IS_REAL_CLIENT(this)) ? this.netaddress : "bot"), ":", this.netname));
1142
1143         LogTeamchange(this.playerid, this.team, 1);
1144
1145         this.just_joined = true;  // stop spamming the eventlog with additional lines when the client connects
1146
1147         this.netname_previous = strzone(this.netname);
1148
1149         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, ((teamplay && IS_PLAYER(this)) ? APP_TEAM_ENT(this, INFO_JOIN_CONNECT_TEAM) : INFO_JOIN_CONNECT), this.netname);
1150
1151         stuffcmd(this, clientstuff, "\n");
1152         stuffcmd(this, "cl_particles_reloadeffects\n"); // TODO do we still need this?
1153
1154         FixClientCvars(this);
1155
1156         // get version info from player
1157         stuffcmd(this, "cmd clientversion $gameversion\n");
1158
1159         // notify about available teams
1160         if (teamplay)
1161         {
1162                 CheckAllowedTeams(this);
1163                 int t = 0;
1164                 if (c1 >= 0) t |= BIT(0);
1165                 if (c2 >= 0) t |= BIT(1);
1166                 if (c3 >= 0) t |= BIT(2);
1167                 if (c4 >= 0) t |= BIT(3);
1168                 stuffcmd(this, sprintf("set _teams_available %d\n", t));
1169         }
1170         else
1171         {
1172                 stuffcmd(this, "set _teams_available 0\n");
1173         }
1174
1175         bot_relinkplayerlist();
1176
1177         this.spectatortime = time;
1178         if (blockSpectators)
1179         {
1180                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
1181         }
1182
1183         this.jointime = time;
1184         this.allowed_timeouts = autocvar_sv_timeout_number;
1185
1186         if (IS_REAL_CLIENT(this))
1187         {
1188                 if (!autocvar_g_campaign)
1189                 {
1190                         this.motd_actived_time = -1;
1191                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOTD, getwelcomemessage(this));
1192                 }
1193
1194                 if (g_weaponarena_weapons == WEPSET(TUBA))
1195                         stuffcmd(this, "cl_cmd settemp chase_active 1\n");
1196         }
1197
1198         if (!sv_foginterval && world.fog != "")
1199                 stuffcmd(this, strcat("\nfog ", world.fog, "\nr_fog_exp2 0\nr_drawfog 1\n"));
1200
1201         if (autocvar_sv_teamnagger && !(autocvar_bot_vs_human && AvailableTeams() == 2))
1202                 if (!g_ca && !g_cts && !g_race) // teamnagger is currently bad for ca, race & cts
1203                         send_CSQC_teamnagger();
1204
1205         CSQCMODEL_AUTOINIT(this);
1206
1207         this.model_randomizer = random();
1208
1209         if (IS_REAL_CLIENT(this))
1210                 sv_notice_join(this);
1211
1212         IL_EACH(g_initforplayer, it.init_for_player, {
1213                 it.init_for_player(it, this);
1214         });
1215
1216         MUTATOR_CALLHOOK(ClientConnect, this);
1217 }
1218 /*
1219 =============
1220 ClientDisconnect
1221
1222 Called when a client disconnects from the server
1223 =============
1224 */
1225 .entity chatbubbleentity;
1226 void ReadyCount();
1227 void ClientDisconnect(entity this)
1228 {
1229         assert(IS_CLIENT(this), return);
1230
1231         PlayerStats_GameReport_FinalizePlayer(this);
1232         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
1233         if (this.active_minigame) part_minigame(this);
1234         if (IS_PLAYER(this)) Send_Effect(EFFECT_SPAWN_NEUTRAL, this.origin, '0 0 0', 1);
1235
1236         if (autocvar_sv_eventlog)
1237                 GameLogEcho(strcat(":part:", ftos(this.playerid)));
1238
1239         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_QUIT_DISCONNECT, this.netname);
1240
1241         SetSpectatee(this, NULL);
1242
1243     MUTATOR_CALLHOOK(ClientDisconnect, this);
1244
1245         ClientState_detach(this);
1246
1247         Portal_ClearAll(this);
1248
1249         Unfreeze(this);
1250
1251         RemoveGrapplingHook(this);
1252
1253         // Here, everything has been done that requires this player to be a client.
1254
1255         this.flags &= ~FL_CLIENT;
1256
1257         if (this.chatbubbleentity) delete(this.chatbubbleentity);
1258         if (this.killindicator) delete(this.killindicator);
1259
1260         WaypointSprite_PlayerGone(this);
1261
1262         bot_relinkplayerlist();
1263
1264         if (this.netname_previous) strunzone(this.netname_previous);
1265         if (this.clientstatus) strunzone(this.clientstatus);
1266         if (this.weaponorder_byimpulse) strunzone(this.weaponorder_byimpulse);
1267         if (this.personal) delete(this.personal);
1268
1269         this.playerid = 0;
1270         ReadyCount();
1271         if (vote_called && IS_REAL_CLIENT(this)) VoteCount(false);
1272 }
1273
1274 void ChatBubbleThink(entity this)
1275 {
1276         this.nextthink = time;
1277         if ((this.owner.alpha < 0) || this.owner.chatbubbleentity != this)
1278         {
1279                 if(this.owner) // but why can that ever be NULL?
1280                         this.owner.chatbubbleentity = NULL;
1281                 delete(this);
1282                 return;
1283         }
1284
1285         this.mdl = "";
1286
1287         if ( !IS_DEAD(this.owner) && IS_PLAYER(this.owner) )
1288         {
1289                 if ( this.owner.active_minigame )
1290                         this.mdl = "models/sprites/minigame_busy.iqm";
1291                 else if (PHYS_INPUT_BUTTON_CHAT(this.owner))
1292                         this.mdl = "models/misc/chatbubble.spr";
1293         }
1294
1295         if ( this.model != this.mdl )
1296                 _setmodel(this, this.mdl);
1297
1298 }
1299
1300 void UpdateChatBubble(entity this)
1301 {
1302         if (this.alpha < 0)
1303                 return;
1304         // spawn a chatbubble entity if needed
1305         if (!this.chatbubbleentity)
1306         {
1307                 this.chatbubbleentity = new(chatbubbleentity);
1308                 this.chatbubbleentity.owner = this;
1309                 this.chatbubbleentity.exteriormodeltoclient = this;
1310                 setthink(this.chatbubbleentity, ChatBubbleThink);
1311                 this.chatbubbleentity.nextthink = time;
1312                 setmodel(this.chatbubbleentity, MDL_CHAT); // precision set below
1313                 //setorigin(this.chatbubbleentity, this.origin + '0 0 15' + this.maxs_z * '0 0 1');
1314                 setorigin(this.chatbubbleentity, '0 0 15' + this.maxs_z * '0 0 1');
1315                 setattachment(this.chatbubbleentity, this, "");  // sticks to moving player better, also conserves bandwidth
1316                 this.chatbubbleentity.mdl = this.chatbubbleentity.model;
1317                 //this.chatbubbleentity.model = "";
1318                 this.chatbubbleentity.effects = EF_LOWPRECISION;
1319         }
1320 }
1321
1322
1323 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
1324 // added to the model skins
1325 /*void UpdateColorModHack()
1326 {
1327         float c;
1328         c = this.clientcolors & 15;
1329         // LordHavoc: only bothering to support white, green, red, yellow, blue
1330              if (!teamplay) this.colormod = '0 0 0';
1331         else if (c ==  0) this.colormod = '1.00 1.00 1.00';
1332         else if (c ==  3) this.colormod = '0.10 1.73 0.10';
1333         else if (c ==  4) this.colormod = '1.73 0.10 0.10';
1334         else if (c == 12) this.colormod = '1.22 1.22 0.10';
1335         else if (c == 13) this.colormod = '0.10 0.10 1.73';
1336         else this.colormod = '1 1 1';
1337 }*/
1338
1339 void respawn(entity this)
1340 {
1341         if(this.alpha >= 0 && autocvar_g_respawn_ghosts)
1342         {
1343                 this.solid = SOLID_NOT;
1344                 this.takedamage = DAMAGE_NO;
1345                 set_movetype(this, MOVETYPE_FLY);
1346                 this.velocity = '0 0 1' * autocvar_g_respawn_ghosts_speed;
1347                 this.avelocity = randomvec() * autocvar_g_respawn_ghosts_speed * 3 - randomvec() * autocvar_g_respawn_ghosts_speed * 3;
1348                 this.effects |= CSQCMODEL_EF_RESPAWNGHOST;
1349                 Send_Effect(EFFECT_RESPAWN_GHOST, this.origin, '0 0 0', 1);
1350                 if(autocvar_g_respawn_ghosts_maxtime)
1351                         SUB_SetFade (this, time + autocvar_g_respawn_ghosts_maxtime / 2 + random () * (autocvar_g_respawn_ghosts_maxtime - autocvar_g_respawn_ghosts_maxtime / 2), 1.5);
1352         }
1353
1354         CopyBody(this, 1);
1355
1356         this.effects |= EF_NODRAW; // prevent another CopyBody
1357         PutClientInServer(this);
1358 }
1359
1360 void play_countdown(entity this, float finished, Sound samp)
1361 {
1362     TC(Sound, samp);
1363         if(IS_REAL_CLIENT(this))
1364                 if(floor(finished - time - frametime) != floor(finished - time))
1365                         if(finished - time < 6)
1366                                 sound (this, CH_INFO, samp, VOL_BASE, ATTEN_NORM);
1367 }
1368
1369 void player_powerups(entity this)
1370 {
1371         // add a way to see what the items were BEFORE all of these checks for the mutator hook
1372         int items_prev = this.items;
1373
1374         if((this.items & IT_USING_JETPACK) && !IS_DEAD(this) && !gameover)
1375                 this.modelflags |= MF_ROCKET;
1376         else
1377                 this.modelflags &= ~MF_ROCKET;
1378
1379         this.effects &= ~(EF_RED | EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT | EF_FLAME | EF_NODEPTHTEST);
1380
1381         if((this.alpha < 0 || IS_DEAD(this)) && !this.vehicle) // don't apply the flags if the player is gibbed
1382                 return;
1383
1384         Fire_ApplyDamage(this);
1385         Fire_ApplyEffect(this);
1386
1387         if (!g_instagib)
1388         {
1389                 if (this.items & ITEM_Strength.m_itemid)
1390                 {
1391                         play_countdown(this, this.strength_finished, SND_POWEROFF);
1392                         this.effects = this.effects | (EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT);
1393                         if (time > this.strength_finished)
1394                         {
1395                                 this.items = this.items - (this.items & ITEM_Strength.m_itemid);
1396                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERDOWN_STRENGTH, this.netname);
1397                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERDOWN_STRENGTH);
1398                         }
1399                 }
1400                 else
1401                 {
1402                         if (time < this.strength_finished)
1403                         {
1404                                 this.items = this.items | ITEM_Strength.m_itemid;
1405                                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERUP_STRENGTH, this.netname);
1406                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERUP_STRENGTH);
1407                         }
1408                 }
1409                 if (this.items & ITEM_Shield.m_itemid)
1410                 {
1411                         play_countdown(this, this.invincible_finished, SND_POWEROFF);
1412                         this.effects = this.effects | (EF_RED | EF_ADDITIVE | EF_FULLBRIGHT);
1413                         if (time > this.invincible_finished)
1414                         {
1415                                 this.items = this.items - (this.items & ITEM_Shield.m_itemid);
1416                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERDOWN_SHIELD, this.netname);
1417                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERDOWN_SHIELD);
1418                         }
1419                 }
1420                 else
1421                 {
1422                         if (time < this.invincible_finished)
1423                         {
1424                                 this.items = this.items | ITEM_Shield.m_itemid;
1425                                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERUP_SHIELD, this.netname);
1426                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERUP_SHIELD);
1427                         }
1428                 }
1429                 if (this.items & IT_SUPERWEAPON)
1430                 {
1431                         if (!(this.weapons & WEPSET_SUPERWEAPONS))
1432                         {
1433                                 this.superweapons_finished = 0;
1434                                 this.items = this.items - (this.items & IT_SUPERWEAPON);
1435                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_LOST, this.netname);
1436                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_LOST);
1437                         }
1438                         else if (this.items & IT_UNLIMITED_SUPERWEAPONS)
1439                         {
1440                                 // don't let them run out
1441                         }
1442                         else
1443                         {
1444                                 play_countdown(this, this.superweapons_finished, SND_POWEROFF);
1445                                 if (time > this.superweapons_finished)
1446                                 {
1447                                         this.items = this.items - (this.items & IT_SUPERWEAPON);
1448                                         this.weapons &= ~WEPSET_SUPERWEAPONS;
1449                                         //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_BROKEN, this.netname);
1450                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_BROKEN);
1451                                 }
1452                         }
1453                 }
1454                 else if(this.weapons & WEPSET_SUPERWEAPONS)
1455                 {
1456                         if (time < this.superweapons_finished || (this.items & IT_UNLIMITED_SUPERWEAPONS))
1457                         {
1458                                 this.items = this.items | IT_SUPERWEAPON;
1459                                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_PICKUP, this.netname);
1460                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_PICKUP);
1461                         }
1462                         else
1463                         {
1464                                 this.superweapons_finished = 0;
1465                                 this.weapons &= ~WEPSET_SUPERWEAPONS;
1466                         }
1467                 }
1468                 else
1469                 {
1470                         this.superweapons_finished = 0;
1471                 }
1472         }
1473
1474         if(autocvar_g_nodepthtestplayers)
1475                 this.effects = this.effects | EF_NODEPTHTEST;
1476
1477         if(autocvar_g_fullbrightplayers)
1478                 this.effects = this.effects | EF_FULLBRIGHT;
1479
1480         if (time >= game_starttime)
1481         if (time < this.spawnshieldtime)
1482                 this.effects = this.effects | (EF_ADDITIVE | EF_FULLBRIGHT);
1483
1484         MUTATOR_CALLHOOK(PlayerPowerups, this, items_prev);
1485 }
1486
1487 float CalcRegen(float current, float stable, float regenfactor, float regenframetime)
1488 {
1489         if(current > stable)
1490                 return current;
1491         else if(current > stable - 0.25) // when close enough, "snap"
1492                 return stable;
1493         else
1494                 return min(stable, current + (stable - current) * regenfactor * regenframetime);
1495 }
1496
1497 float CalcRot(float current, float stable, float rotfactor, float rotframetime)
1498 {
1499         if(current < stable)
1500                 return current;
1501         else if(current < stable + 0.25) // when close enough, "snap"
1502                 return stable;
1503         else
1504                 return max(stable, current + (stable - current) * rotfactor * rotframetime);
1505 }
1506
1507 float CalcRotRegen(float current, float regenstable, float regenfactor, float regenlinear, float regenframetime, float rotstable, float rotfactor, float rotlinear, float rotframetime, float limit)
1508 {
1509         if(current > rotstable)
1510         {
1511                 if(rotframetime > 0)
1512                 {
1513                         current = CalcRot(current, rotstable, rotfactor, rotframetime);
1514                         current = max(rotstable, current - rotlinear * rotframetime);
1515                 }
1516         }
1517         else if(current < regenstable)
1518         {
1519                 if(regenframetime > 0)
1520                 {
1521                         current = CalcRegen(current, regenstable, regenfactor, regenframetime);
1522                         current = min(regenstable, current + regenlinear * regenframetime);
1523                 }
1524         }
1525
1526         if(current > limit)
1527                 current = limit;
1528
1529         return current;
1530 }
1531
1532 void player_regen(entity this)
1533 {
1534         float max_mod, regen_mod, rot_mod, limit_mod;
1535         max_mod = regen_mod = rot_mod = limit_mod = 1;
1536
1537         float regen_health = autocvar_g_balance_health_regen;
1538         float regen_health_linear = autocvar_g_balance_health_regenlinear;
1539         float regen_health_rot = autocvar_g_balance_health_rot;
1540         float regen_health_rotlinear = autocvar_g_balance_health_rotlinear;
1541         float regen_health_stable = autocvar_g_balance_health_regenstable;
1542         float regen_health_rotstable = autocvar_g_balance_health_rotstable;
1543         bool mutator_returnvalue = MUTATOR_CALLHOOK(PlayerRegen, this, max_mod, regen_mod, rot_mod, limit_mod, regen_health, regen_health_linear, regen_health_rot,
1544                 regen_health_rotlinear, regen_health_stable, regen_health_rotstable);
1545         max_mod = M_ARGV(1, float);
1546         regen_mod = M_ARGV(2, float);
1547         rot_mod = M_ARGV(3, float);
1548         limit_mod = M_ARGV(4, float);
1549         regen_health = M_ARGV(5, float);
1550         regen_health_linear = M_ARGV(6, float);
1551         regen_health_rot = M_ARGV(7, float);
1552         regen_health_rotlinear = M_ARGV(8, float);
1553         regen_health_stable = M_ARGV(9, float);
1554         regen_health_rotstable = M_ARGV(10, float);
1555
1556
1557         if(!mutator_returnvalue)
1558         if(!STAT(FROZEN, this))
1559         {
1560                 float mina, maxa, limith, limita;
1561                 maxa = autocvar_g_balance_armor_rotstable;
1562                 mina = autocvar_g_balance_armor_regenstable;
1563                 limith = autocvar_g_balance_health_limit;
1564                 limita = autocvar_g_balance_armor_limit;
1565
1566                 regen_health_rotstable = regen_health_rotstable * max_mod;
1567                 regen_health_stable = regen_health_stable * max_mod;
1568                 limith = limith * limit_mod;
1569                 limita = limita * limit_mod;
1570
1571                 this.armorvalue = CalcRotRegen(this.armorvalue, mina, autocvar_g_balance_armor_regen, autocvar_g_balance_armor_regenlinear, regen_mod * frametime * (time > this.pauseregen_finished), maxa, autocvar_g_balance_armor_rot, autocvar_g_balance_armor_rotlinear, rot_mod * frametime * (time > this.pauserotarmor_finished), limita);
1572                 this.health = CalcRotRegen(this.health, regen_health_stable, regen_health, regen_health_linear, regen_mod * frametime * (time > this.pauseregen_finished), regen_health_rotstable, regen_health_rot, regen_health_rotlinear, rot_mod * frametime * (time > this.pauserothealth_finished), limith);
1573         }
1574
1575         // if player rotted to death...  die!
1576         // check this outside above checks, as player may still be able to rot to death
1577         if(this.health < 1)
1578         {
1579                 if(this.vehicle)
1580                         vehicles_exit(this.vehicle, VHEF_RELEASE);
1581                 if(this.event_damage)
1582                         this.event_damage(this, this, this, 1, DEATH_ROT.m_id, this.origin, '0 0 0');
1583         }
1584
1585         if (!(this.items & IT_UNLIMITED_WEAPON_AMMO))
1586         {
1587                 float minf, maxf, limitf;
1588
1589                 maxf = autocvar_g_balance_fuel_rotstable;
1590                 minf = autocvar_g_balance_fuel_regenstable;
1591                 limitf = autocvar_g_balance_fuel_limit;
1592
1593                 this.ammo_fuel = CalcRotRegen(this.ammo_fuel, minf, autocvar_g_balance_fuel_regen, autocvar_g_balance_fuel_regenlinear, frametime * (time > this.pauseregen_finished) * ((this.items & ITEM_JetpackRegen.m_itemid) != 0), maxf, autocvar_g_balance_fuel_rot, autocvar_g_balance_fuel_rotlinear, frametime * (time > this.pauserotfuel_finished), limitf);
1594         }
1595 }
1596
1597 bool zoomstate_set;
1598 void SetZoomState(entity this, float z)
1599 {
1600         if(z != this.zoomstate)
1601         {
1602                 this.zoomstate = z;
1603                 ClientData_Touch(this);
1604         }
1605         zoomstate_set = true;
1606 }
1607
1608 void GetPressedKeys(entity this)
1609 {
1610         MUTATOR_CALLHOOK(GetPressedKeys, this);
1611         int keys = this.pressedkeys;
1612         keys = BITSET(keys, KEY_FORWARD,        this.movement.x > 0);
1613         keys = BITSET(keys, KEY_BACKWARD,       this.movement.x < 0);
1614         keys = BITSET(keys, KEY_RIGHT,          this.movement.y > 0);
1615         keys = BITSET(keys, KEY_LEFT,           this.movement.y < 0);
1616
1617         keys = BITSET(keys, KEY_JUMP,           PHYS_INPUT_BUTTON_JUMP(this));
1618         keys = BITSET(keys, KEY_CROUCH,         PHYS_INPUT_BUTTON_CROUCH(this));
1619         keys = BITSET(keys, KEY_ATCK,           PHYS_INPUT_BUTTON_ATCK(this));
1620         keys = BITSET(keys, KEY_ATCK2,          PHYS_INPUT_BUTTON_ATCK2(this));
1621         this.pressedkeys = keys;
1622 }
1623
1624 /*
1625 ======================
1626 spectate mode routines
1627 ======================
1628 */
1629
1630 void SpectateCopy(entity this, entity spectatee)
1631 {
1632     TC(Client, this); TC(Client, spectatee);
1633
1634         MUTATOR_CALLHOOK(SpectateCopy, spectatee, this);
1635         PS(this) = PS(spectatee);
1636         this.armortype = spectatee.armortype;
1637         this.armorvalue = spectatee.armorvalue;
1638         this.ammo_cells = spectatee.ammo_cells;
1639         this.ammo_plasma = spectatee.ammo_plasma;
1640         this.ammo_shells = spectatee.ammo_shells;
1641         this.ammo_nails = spectatee.ammo_nails;
1642         this.ammo_rockets = spectatee.ammo_rockets;
1643         this.ammo_fuel = spectatee.ammo_fuel;
1644         this.clip_load = spectatee.clip_load;
1645         this.clip_size = spectatee.clip_size;
1646         this.effects = spectatee.effects & EFMASK_CHEAP; // eat performance
1647         this.health = spectatee.health;
1648         this.impulse = 0;
1649         this.items = spectatee.items;
1650         this.last_pickup = spectatee.last_pickup;
1651         this.hit_time = spectatee.hit_time;
1652         this.strength_finished = spectatee.strength_finished;
1653         this.invincible_finished = spectatee.invincible_finished;
1654         this.pressedkeys = spectatee.pressedkeys;
1655         this.weapons = spectatee.weapons;
1656         this.vortex_charge = spectatee.vortex_charge;
1657         this.vortex_chargepool_ammo = spectatee.vortex_chargepool_ammo;
1658         this.hagar_load = spectatee.hagar_load;
1659         this.arc_heat_percent = spectatee.arc_heat_percent;
1660         this.minelayer_mines = spectatee.minelayer_mines;
1661         this.punchangle = spectatee.punchangle;
1662         this.view_ofs = spectatee.view_ofs;
1663         this.velocity = spectatee.velocity;
1664         this.dmg_take = spectatee.dmg_take;
1665         this.dmg_save = spectatee.dmg_save;
1666         this.dmg_inflictor = spectatee.dmg_inflictor;
1667         this.v_angle = spectatee.v_angle;
1668         this.angles = spectatee.v_angle;
1669         STAT(FROZEN, this) = STAT(FROZEN, spectatee);
1670         this.revive_progress = spectatee.revive_progress;
1671         if(!PHYS_INPUT_BUTTON_USE(this) && STAT(CAMERA_SPECTATOR, this) != 2)
1672                 this.fixangle = true;
1673         setorigin(this, spectatee.origin);
1674         setsize(this, spectatee.mins, spectatee.maxs);
1675         SetZoomState(this, spectatee.zoomstate);
1676
1677     anticheat_spectatecopy(this, spectatee);
1678         this.hud = spectatee.hud;
1679         if(spectatee.vehicle)
1680     {
1681         this.angles = spectatee.v_angle;
1682
1683         //this.fixangle = false;
1684         //this.velocity = spectatee.vehicle.velocity;
1685         this.vehicle_health = spectatee.vehicle_health;
1686         this.vehicle_shield = spectatee.vehicle_shield;
1687         this.vehicle_energy = spectatee.vehicle_energy;
1688         this.vehicle_ammo1 = spectatee.vehicle_ammo1;
1689         this.vehicle_ammo2 = spectatee.vehicle_ammo2;
1690         this.vehicle_reload1 = spectatee.vehicle_reload1;
1691         this.vehicle_reload2 = spectatee.vehicle_reload2;
1692
1693         //msg_entity = this;
1694
1695        // WriteByte (MSG_ONE, SVC_SETVIEWANGLES);
1696             //WriteAngle(MSG_ONE,  spectatee.v_angle.x);
1697            // WriteAngle(MSG_ONE,  spectatee.v_angle.y);
1698            // WriteAngle(MSG_ONE,  spectatee.v_angle.z);
1699
1700         //WriteByte (MSG_ONE, SVC_SETVIEW);
1701         //    WriteEntity(MSG_ONE, this);
1702         //makevectors(spectatee.v_angle);
1703         //setorigin(this, spectatee.origin - v_forward * 400 + v_up * 300);*/
1704     }
1705 }
1706
1707 bool SpectateUpdate(entity this)
1708 {
1709         if(!this.enemy)
1710             return false;
1711
1712         if(!IS_PLAYER(this.enemy) || this == this.enemy)
1713         {
1714                 SetSpectatee(this, NULL);
1715                 return false;
1716         }
1717
1718         SpectateCopy(this, this.enemy);
1719
1720         return true;
1721 }
1722
1723 bool SpectateSet(entity this)
1724 {
1725         if(!IS_PLAYER(this.enemy))
1726                 return false;
1727
1728         ClientData_Touch(this.enemy);
1729
1730         msg_entity = this;
1731         WriteByte(MSG_ONE, SVC_SETVIEW);
1732         WriteEntity(MSG_ONE, this.enemy);
1733         set_movetype(this, MOVETYPE_NONE);
1734         accuracy_resend(this);
1735
1736         if(!SpectateUpdate(this))
1737                 PutObserverInServer(this);
1738
1739         return true;
1740 }
1741
1742 void SetSpectatee_status(entity this, int spectatee_num)
1743 {
1744         int oldspectatee_status = this.spectatee_status;
1745         this.spectatee_status = spectatee_num;
1746
1747         if (this.spectatee_status != oldspectatee_status)
1748         {
1749                 ClientData_Touch(this);
1750                 if (g_race || g_cts) race_InitSpectator();
1751         }
1752 }
1753
1754 void SetSpectatee(entity this, entity spectatee)
1755 {
1756         entity old_spectatee = this.enemy;
1757
1758         this.enemy = spectatee;
1759
1760         // WEAPONTODO
1761         // these are required to fix the spectator bug with arc
1762         if(old_spectatee)
1763         {
1764                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1765                 {
1766                         .entity weaponentity = weaponentities[slot];
1767                         if(old_spectatee.(weaponentity).arc_beam)
1768                                 old_spectatee.(weaponentity).arc_beam.SendFlags |= ARC_SF_SETTINGS;
1769                 }
1770         }
1771         if(this.enemy)
1772         {
1773                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1774                 {
1775                         .entity weaponentity = weaponentities[slot];
1776                         if(this.enemy.(weaponentity).arc_beam)
1777                                 this.enemy.(weaponentity).arc_beam.SendFlags |= ARC_SF_SETTINGS;
1778                 }
1779         }
1780
1781         if (this.enemy)
1782                 SetSpectatee_status(this, etof(this.enemy));
1783
1784         // needed to update spectator list
1785         if(old_spectatee) { ClientData_Touch(old_spectatee); }
1786 }
1787
1788 bool Spectate(entity this, entity pl)
1789 {
1790         if(MUTATOR_CALLHOOK(SpectateSet, this, pl))
1791                 return false;
1792         pl = M_ARGV(1, entity);
1793
1794         SetSpectatee(this, pl);
1795         return SpectateSet(this);
1796 }
1797
1798 bool SpectateNext(entity this)
1799 {
1800         entity ent = find(this.enemy, classname, STR_PLAYER);
1801
1802         if (MUTATOR_CALLHOOK(SpectateNext, this, ent))
1803                 ent = M_ARGV(1, entity);
1804         else if (!ent)
1805                 ent = find(ent, classname, STR_PLAYER);
1806
1807         if(ent) { SetSpectatee(this, ent); }
1808
1809         return SpectateSet(this);
1810 }
1811
1812 bool SpectatePrev(entity this)
1813 {
1814         // NOTE: chain order is from the highest to the lower entnum (unlike find)
1815         entity ent = findchain(classname, STR_PLAYER);
1816         if (!ent) // no player
1817                 return false;
1818
1819         entity first = ent;
1820         // skip players until current spectated player
1821         if(this.enemy)
1822         while(ent && ent != this.enemy)
1823                 ent = ent.chain;
1824
1825         switch (MUTATOR_CALLHOOK(SpectatePrev, this, ent, first))
1826         {
1827                 case MUT_SPECPREV_FOUND:
1828                     ent = M_ARGV(1, entity);
1829                     break;
1830                 case MUT_SPECPREV_RETURN:
1831                     return true;
1832                 case MUT_SPECPREV_CONTINUE:
1833                 default:
1834                 {
1835                         if(ent.chain)
1836                                 ent = ent.chain;
1837                         else
1838                                 ent = first;
1839                         break;
1840                 }
1841         }
1842
1843         SetSpectatee(this, ent);
1844         return SpectateSet(this);
1845 }
1846
1847 /*
1848 =============
1849 ShowRespawnCountdown()
1850
1851 Update a respawn countdown display.
1852 =============
1853 */
1854 void ShowRespawnCountdown(entity this)
1855 {
1856         float number;
1857         if(!IS_DEAD(this)) // just respawned?
1858                 return;
1859         else
1860         {
1861                 number = ceil(this.respawn_time - time);
1862                 if(number <= 0)
1863                         return;
1864                 if(number <= this.respawn_countdown)
1865                 {
1866                         this.respawn_countdown = number - 1;
1867                         if(ceil(this.respawn_time - (time + 0.5)) == number) // only say it if it is the same number even in 0.5s; to prevent overlapping sounds
1868                                 { Send_Notification(NOTIF_ONE, this, MSG_ANNCE, Announcer_PickNumber(CNT_RESPAWN, number)); }
1869                 }
1870         }
1871 }
1872
1873 .float caplayer;
1874
1875 void LeaveSpectatorMode(entity this)
1876 {
1877         if(this.caplayer)
1878                 return;
1879         if(nJoinAllowed(this, this))
1880         {
1881                 if(!teamplay || autocvar_g_campaign || autocvar_g_balance_teams || (this.wasplayer && autocvar_g_changeteam_banned) || this.team_forced > 0)
1882                 {
1883                         TRANSMUTE(Player, this);
1884
1885                         SetSpectatee(this, NULL);
1886
1887                         if(autocvar_g_campaign || autocvar_g_balance_teams)
1888                                 { JoinBestTeam(this, false, true); }
1889
1890                         if(autocvar_g_campaign)
1891                                 { campaign_bots_may_start = true; }
1892
1893                         Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_PREVENT_JOIN);
1894
1895                         PutClientInServer(this);
1896
1897                         if(IS_PLAYER(this)) { Send_Notification(NOTIF_ALL, NULL, MSG_INFO, ((teamplay && this.team != -1) ? APP_TEAM_ENT(this, INFO_JOIN_PLAY_TEAM) : INFO_JOIN_PLAY), this.netname); }
1898                 }
1899                 else
1900                         stuffcmd(this, "menu_showteamselect\n");
1901         }
1902         else
1903         {
1904                 // Player may not join because g_maxplayers is set
1905                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_JOIN_PREVENT);
1906         }
1907 }
1908
1909 /**
1910  * Determines whether the player is allowed to join. This depends on cvar
1911  * g_maxplayers, if it isn't used this function always return true, otherwise
1912  * it checks whether the number of currently playing players exceeds g_maxplayers.
1913  * @return int number of free slots for players, 0 if none
1914  */
1915 bool nJoinAllowed(entity this, entity ignore)
1916 {
1917         if(!ignore)
1918         // this is called that way when checking if anyone may be able to join (to build qcstatus)
1919         // so report 0 free slots if restricted
1920         {
1921                 if(autocvar_g_forced_team_otherwise == "spectate")
1922                         return false;
1923                 if(autocvar_g_forced_team_otherwise == "spectator")
1924                         return false;
1925         }
1926
1927         if(this.team_forced < 0)
1928                 return false; // forced spectators can never join
1929
1930         // TODO simplify this
1931         int totalClients = 0;
1932         int currentlyPlaying = 0;
1933         FOREACH_CLIENT(true, LAMBDA(
1934                 if(it != ignore)
1935                         ++totalClients;
1936                 if(IS_REAL_CLIENT(it))
1937                 if(IS_PLAYER(it) || it.caplayer)
1938                         ++currentlyPlaying;
1939         ));
1940
1941         if (!autocvar_g_maxplayers)
1942                 return maxclients - totalClients;
1943
1944         if(currentlyPlaying < autocvar_g_maxplayers)
1945                 return min(maxclients - totalClients, autocvar_g_maxplayers - currentlyPlaying);
1946
1947         return false;
1948 }
1949
1950 /**
1951  * Checks whether the client is an observer or spectator, if so, he will get kicked after
1952  * g_maxplayers_spectator_blocktime seconds
1953  */
1954 void checkSpectatorBlock(entity this)
1955 {
1956         if(IS_SPEC(this) || IS_OBSERVER(this))
1957         if(!this.caplayer)
1958         if(IS_REAL_CLIENT(this))
1959         {
1960                 if( time > (this.spectatortime + autocvar_g_maxplayers_spectator_blocktime) ) {
1961                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_QUIT_KICK_SPECTATING);
1962                         dropclient(this);
1963                 }
1964         }
1965 }
1966
1967 void PrintWelcomeMessage(entity this)
1968 {
1969         if(this.motd_actived_time == 0)
1970         {
1971                 if (autocvar_g_campaign) {
1972                         if ((IS_PLAYER(this) && PHYS_INPUT_BUTTON_INFO(this)) || (!IS_PLAYER(this))) {
1973                                 this.motd_actived_time = time;
1974                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOTD, campaign_message);
1975                         }
1976                 } else {
1977                         if (PHYS_INPUT_BUTTON_INFO(this)) {
1978                                 this.motd_actived_time = time;
1979                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOTD, getwelcomemessage(this));
1980                         }
1981                 }
1982         }
1983         else if(this.motd_actived_time > 0) // showing MOTD or campaign message
1984         {
1985                 if (autocvar_g_campaign) {
1986                         if (PHYS_INPUT_BUTTON_INFO(this))
1987                                 this.motd_actived_time = time;
1988                         else if ((time - this.motd_actived_time > 2) && IS_PLAYER(this)) { // hide it some seconds after BUTTON_INFO has been released
1989                                 this.motd_actived_time = 0;
1990                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_MOTD);
1991                         }
1992                 } else {
1993                         if (PHYS_INPUT_BUTTON_INFO(this))
1994                                 this.motd_actived_time = time;
1995                         else if (time - this.motd_actived_time > 2) { // hide it some seconds after BUTTON_INFO has been released
1996                                 this.motd_actived_time = 0;
1997                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_MOTD);
1998                         }
1999                 }
2000         }
2001         else //if(this.motd_actived_time < 0) // just connected, motd is active
2002         {
2003                 if(PHYS_INPUT_BUTTON_INFO(this)) // BUTTON_INFO hides initial MOTD
2004                         this.motd_actived_time = -2; // wait until BUTTON_INFO gets released
2005                 else if(this.motd_actived_time == -2 || IS_PLAYER(this) || IS_SPEC(this))
2006                 {
2007                         // instanctly hide MOTD
2008                         this.motd_actived_time = 0;
2009                         Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_MOTD);
2010                 }
2011         }
2012 }
2013
2014 void ObserverThink(entity this)
2015 {
2016         if ( this.impulse )
2017         {
2018                 MinigameImpulse(this, this.impulse);
2019                 this.impulse = 0;
2020         }
2021         if (this.flags & FL_JUMPRELEASED) {
2022                 if (PHYS_INPUT_BUTTON_JUMP(this) && !this.version_mismatch) {
2023                         this.flags &= ~FL_JUMPRELEASED;
2024                         this.flags |= FL_SPAWNING;
2025                 } else if(PHYS_INPUT_BUTTON_ATCK(this) && !this.version_mismatch) {
2026                         this.flags &= ~FL_JUMPRELEASED;
2027                         if(SpectateNext(this)) {
2028                                 TRANSMUTE(Spectator, this);
2029                         }
2030                 } else {
2031                         int preferred_movetype = ((!PHYS_INPUT_BUTTON_USE(this) ? this.cvar_cl_clippedspectating : !this.cvar_cl_clippedspectating) ? MOVETYPE_FLY_WORLDONLY : MOVETYPE_NOCLIP);
2032                         set_movetype(this, preferred_movetype);
2033                 }
2034         } else {
2035                 if (!(PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_JUMP(this))) {
2036                         this.flags |= FL_JUMPRELEASED;
2037                         if(this.flags & FL_SPAWNING)
2038                         {
2039                                 this.flags &= ~FL_SPAWNING;
2040                                 LeaveSpectatorMode(this);
2041                                 return;
2042                         }
2043                 }
2044         }
2045 }
2046
2047 void SpectatorThink(entity this)
2048 {
2049         if ( this.impulse )
2050         {
2051                 if(MinigameImpulse(this, this.impulse))
2052                         this.impulse = 0;
2053
2054                 if (this.impulse == IMP_weapon_drop.impulse)
2055                 {
2056                         STAT(CAMERA_SPECTATOR, this) = (STAT(CAMERA_SPECTATOR, this) + 1) % 3;
2057                         this.impulse = 0;
2058                         return;
2059                 }
2060         }
2061         if (this.flags & FL_JUMPRELEASED) {
2062                 if (PHYS_INPUT_BUTTON_JUMP(this) && !this.version_mismatch) {
2063                         this.flags &= ~FL_JUMPRELEASED;
2064                         this.flags |= FL_SPAWNING;
2065                 } else if(PHYS_INPUT_BUTTON_ATCK(this) || this.impulse == 10 || this.impulse == 15 || this.impulse == 18 || (this.impulse >= 200 && this.impulse <= 209)) {
2066                         this.flags &= ~FL_JUMPRELEASED;
2067                         if(SpectateNext(this)) {
2068                                 TRANSMUTE(Spectator, this);
2069                         } else {
2070                                 TRANSMUTE(Observer, this);
2071                                 PutClientInServer(this);
2072                         }
2073                         this.impulse = 0;
2074                 } else if(this.impulse == 12 || this.impulse == 16  || this.impulse == 19 || (this.impulse >= 220 && this.impulse <= 229)) {
2075                         this.flags &= ~FL_JUMPRELEASED;
2076                         if(SpectatePrev(this)) {
2077                                 TRANSMUTE(Spectator, this);
2078                         } else {
2079                                 TRANSMUTE(Observer, this);
2080                                 PutClientInServer(this);
2081                         }
2082                         this.impulse = 0;
2083                 } else if (PHYS_INPUT_BUTTON_ATCK2(this)) {
2084                         this.flags &= ~FL_JUMPRELEASED;
2085                         TRANSMUTE(Observer, this);
2086                         PutClientInServer(this);
2087                 } else {
2088                         if(!SpectateUpdate(this))
2089                                 PutObserverInServer(this);
2090                 }
2091         } else {
2092                 if (!(PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_ATCK2(this))) {
2093                         this.flags |= FL_JUMPRELEASED;
2094                         if(this.flags & FL_SPAWNING)
2095                         {
2096                                 this.flags &= ~FL_SPAWNING;
2097                                 LeaveSpectatorMode(this);
2098                                 return;
2099                         }
2100                 }
2101                 if(!SpectateUpdate(this))
2102                         PutObserverInServer(this);
2103         }
2104
2105         this.flags |= FL_CLIENT | FL_NOTARGET;
2106 }
2107
2108 void vehicles_enter (entity pl, entity veh);
2109 void PlayerUseKey(entity this)
2110 {
2111         if (!IS_PLAYER(this))
2112                 return;
2113
2114         if(this.vehicle)
2115         {
2116                 if(!gameover)
2117                 {
2118                         vehicles_exit(this.vehicle, VHEF_NORMAL);
2119                         return;
2120                 }
2121         }
2122         else if(autocvar_g_vehicles_enter)
2123         {
2124                 if(!STAT(FROZEN, this))
2125                 if(!IS_DEAD(this))
2126                 if(!gameover)
2127                 {
2128                         entity head, closest_target = NULL;
2129                         head = WarpZone_FindRadius(this.origin, autocvar_g_vehicles_enter_radius, true);
2130
2131                         while(head) // find the closest acceptable target to enter
2132                         {
2133                                 if(IS_VEHICLE(head))
2134                                 if(!IS_DEAD(head))
2135                                 if(!head.owner || ((head.vehicle_flags & VHF_MULTISLOT) && SAME_TEAM(head.owner, this)))
2136                                 if(head.takedamage != DAMAGE_NO)
2137                                 {
2138                                         if(closest_target)
2139                                         {
2140                                                 if(vlen2(this.origin - head.origin) < vlen2(this.origin - closest_target.origin))
2141                                                 { closest_target = head; }
2142                                         }
2143                                         else { closest_target = head; }
2144                                 }
2145
2146                                 head = head.chain;
2147                         }
2148
2149                         if(closest_target) { vehicles_enter(this, closest_target); return; }
2150                 }
2151         }
2152
2153         // a use key was pressed; call handlers
2154         MUTATOR_CALLHOOK(PlayerUseKey, this);
2155 }
2156
2157
2158 /*
2159 =============
2160 PlayerPreThink
2161
2162 Called every frame for each client before the physics are run
2163 =============
2164 */
2165 .float usekeypressed;
2166 .float last_vehiclecheck;
2167 .int items_added;
2168 void PlayerPreThink (entity this)
2169 {
2170         WarpZone_PlayerPhysics_FixVAngle(this);
2171
2172     STAT(GAMESTARTTIME, this) = game_starttime;
2173         STAT(ROUNDSTARTTIME, this) = round_starttime;
2174         STAT(ALLOW_OLDVORTEXBEAM, this) = autocvar_g_allow_oldvortexbeam;
2175         STAT(LEADLIMIT, this) = autocvar_leadlimit;
2176
2177         STAT(WEAPONSINMAP, this) = weaponsInMap;
2178
2179         if (frametime) {
2180                 // physics frames: update anticheat stuff
2181                 anticheat_prethink(this);
2182         }
2183
2184         if (blockSpectators && frametime) {
2185                 // WORKAROUND: only use dropclient in server frames (frametime set).
2186                 // Never use it in cl_movement frames (frametime zero).
2187                 checkSpectatorBlock(this);
2188     }
2189
2190         zoomstate_set = false;
2191
2192         // Check for nameless players
2193         if (isInvisibleString(this.netname)) {
2194                 this.netname = strzone(sprintf("Player#%d", this.playerid));
2195                 // stuffcmd(this, strcat("name ", this.netname, "\n")); // maybe?
2196         }
2197         if (this.netname != this.netname_previous) {
2198                 if (autocvar_sv_eventlog) {
2199                         GameLogEcho(strcat(":name:", ftos(this.playerid), ":", this.netname));
2200         }
2201                 if (this.netname_previous) strunzone(this.netname_previous);
2202                 this.netname_previous = strzone(this.netname);
2203         }
2204
2205         // version nagging
2206         if (this.version_nagtime && this.cvar_g_xonoticversion && time > this.version_nagtime) {
2207         this.version_nagtime = 0;
2208         if (strstrofs(this.cvar_g_xonoticversion, "git", 0) >= 0 || strstrofs(this.cvar_g_xonoticversion, "autobuild", 0) >= 0) {
2209             // git client
2210         } else if (strstrofs(autocvar_g_xonoticversion, "git", 0) >= 0 || strstrofs(autocvar_g_xonoticversion, "autobuild", 0) >= 0) {
2211             // git server
2212             Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_BETA, autocvar_g_xonoticversion, this.cvar_g_xonoticversion);
2213         } else {
2214             int r = vercmp(this.cvar_g_xonoticversion, autocvar_g_xonoticversion);
2215             if (r < 0) { // old client
2216                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_OUTDATED, autocvar_g_xonoticversion, this.cvar_g_xonoticversion);
2217             } else if (r > 0) { // old server
2218                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_OLD, autocvar_g_xonoticversion, this.cvar_g_xonoticversion);
2219             }
2220         }
2221     }
2222
2223         // GOD MODE info
2224         if (!(this.flags & FL_GODMODE) && this.max_armorvalue)
2225         {
2226                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_GODMODE_OFF, this.max_armorvalue);
2227                 this.max_armorvalue = 0;
2228         }
2229
2230         if (STAT(FROZEN, this) == 2)
2231         {
2232                 this.revive_progress = bound(0, this.revive_progress + frametime * this.revive_speed, 1);
2233                 this.health = max(1, this.revive_progress * start_health);
2234                 this.iceblock.alpha = bound(0.2, 1 - this.revive_progress, 1);
2235
2236                 if (this.revive_progress >= 1)
2237                         Unfreeze(this);
2238         }
2239         else if (STAT(FROZEN, this) == 3)
2240         {
2241                 this.revive_progress = bound(0, this.revive_progress - frametime * this.revive_speed, 1);
2242                 this.health = max(0, autocvar_g_nades_ice_health + (start_health-autocvar_g_nades_ice_health) * this.revive_progress );
2243
2244                 if (this.health < 1)
2245                 {
2246                         if (this.vehicle)
2247                                 vehicles_exit(this.vehicle, VHEF_RELEASE);
2248                         if(this.event_damage)
2249                                 this.event_damage(this, this, this.frozen_by, 1, DEATH_NADE_ICE_FREEZE.m_id, this.origin, '0 0 0');
2250                 }
2251                 else if (this.revive_progress <= 0)
2252                         Unfreeze(this);
2253         }
2254
2255         MUTATOR_CALLHOOK(PlayerPreThink, this);
2256
2257         if(autocvar_g_vehicles_enter && (time > this.last_vehiclecheck) && !gameover && !this.vehicle)
2258         if(IS_PLAYER(this) && !STAT(FROZEN, this) && !IS_DEAD(this))
2259         {
2260                 FOREACH_ENTITY_RADIUS(this.origin, autocvar_g_vehicles_enter_radius, IS_VEHICLE(it),
2261                 {
2262                         if(!IS_DEAD(it) && it.takedamage != DAMAGE_NO)
2263                         if((it.vehicle_flags & VHF_MULTISLOT) && SAME_TEAM(it.owner, this))
2264                         {
2265                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER_GUNNER);
2266                         }
2267                         else if(!it.owner)
2268                         {
2269                                 if(!it.team || SAME_TEAM(this, it))
2270                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER);
2271                                 else if(autocvar_g_vehicles_steal)
2272                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER_STEAL);
2273                         }
2274                 });
2275
2276                 this.last_vehiclecheck = time + 1;
2277         }
2278
2279         if(!this.cvar_cl_newusekeysupported) // FIXME remove this - it was a stupid idea to begin with, we can JUST use the button
2280         {
2281                 if(PHYS_INPUT_BUTTON_USE(this) && !this.usekeypressed)
2282                         PlayerUseKey(this);
2283                 this.usekeypressed = PHYS_INPUT_BUTTON_USE(this);
2284         }
2285
2286         if (IS_REAL_CLIENT(this))
2287                 PrintWelcomeMessage(this);
2288
2289         if (IS_PLAYER(this)) {
2290                 CheckRules_Player(this);
2291
2292                 if (intermission_running) {
2293                         IntermissionThink(this);
2294                         return;
2295                 }
2296
2297                 if (timeout_status == TIMEOUT_ACTIVE) {
2298             // don't allow the player to turn around while game is paused
2299                         // FIXME turn this into CSQC stuff
2300                         this.v_angle = this.lastV_angle;
2301                         this.angles = this.lastV_angle;
2302                         this.fixangle = true;
2303                 }
2304
2305                 if (frametime) player_powerups(this);
2306
2307                 if (IS_DEAD(this)) {
2308                         if (this.personal && g_race_qualifying) {
2309                                 if (time > this.respawn_time) {
2310                                         STAT(RESPAWN_TIME, this) = this.respawn_time = time + 1; // only retry once a second
2311                                         respawn(this);
2312                                         this.impulse = CHIMPULSE_SPEEDRUN.impulse;
2313                                 }
2314                         } else {
2315                                 if (frametime) player_anim(this);
2316                                 bool button_pressed = (PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_JUMP(this) || PHYS_INPUT_BUTTON_ATCK2(this) || PHYS_INPUT_BUTTON_HOOK(this) || PHYS_INPUT_BUTTON_USE(this));
2317
2318                                 switch(this.deadflag)
2319                                 {
2320                                         case DEAD_DYING:
2321                                         {
2322                                                 if ((this.respawn_flags & RESPAWN_FORCE) && !(this.respawn_time < this.respawn_time_max))
2323                                                         this.deadflag = DEAD_RESPAWNING;
2324                                                 else if (!button_pressed || (this.respawn_flags & RESPAWN_FORCE))
2325                                                         this.deadflag = DEAD_DEAD;
2326                                                 break;
2327                                         }
2328                                         case DEAD_DEAD:
2329                                         {
2330                                                 if (button_pressed)
2331                                                         this.deadflag = DEAD_RESPAWNABLE;
2332                                                 else if (time >= this.respawn_time_max && (this.respawn_flags & RESPAWN_FORCE))
2333                                                         this.deadflag = DEAD_RESPAWNING;
2334                                                 break;
2335                                         }
2336                                         case DEAD_RESPAWNABLE:
2337                                         {
2338                                                 if (!button_pressed || (this.respawn_flags & RESPAWN_FORCE))
2339                                                         this.deadflag = DEAD_RESPAWNING;
2340                                                 break;
2341                                         }
2342                                         case DEAD_RESPAWNING:
2343                                         {
2344                                                 if (time > this.respawn_time)
2345                                                 {
2346                                                         this.respawn_time = time + 1; // only retry once a second
2347                                                         this.respawn_time_max = this.respawn_time;
2348                                                         respawn(this);
2349                                                 }
2350                                                 break;
2351                                         }
2352                                 }
2353
2354                                 ShowRespawnCountdown(this);
2355
2356                                 if (this.respawn_flags & RESPAWN_SILENT)
2357                                         STAT(RESPAWN_TIME, this) = 0;
2358                                 else if ((this.respawn_flags & RESPAWN_FORCE) && this.respawn_time < this.respawn_time_max)
2359                                 {
2360                                         if (time < this.respawn_time)
2361                                                 STAT(RESPAWN_TIME, this) = this.respawn_time;
2362                                         else if (this.deadflag != DEAD_RESPAWNING)
2363                                                 STAT(RESPAWN_TIME, this) = -this.respawn_time_max;
2364                                 }
2365                                 else
2366                                         STAT(RESPAWN_TIME, this) = this.respawn_time;
2367                         }
2368
2369                         // if respawning, invert stat_respawn_time to indicate this, the client translates it
2370                         if (this.deadflag == DEAD_RESPAWNING && STAT(RESPAWN_TIME, this) > 0)
2371                                 STAT(RESPAWN_TIME, this) *= -1;
2372
2373                         return;
2374                 }
2375
2376                 this.prevorigin = this.origin;
2377
2378                 bool do_crouch = PHYS_INPUT_BUTTON_CROUCH(this);
2379                 if (this.hook.state) {
2380                         do_crouch = false;
2381                 } else if (this.waterlevel >= WATERLEVEL_SWIMMING) {
2382                         do_crouch = false;
2383                 } else if (this.vehicle) {
2384                         do_crouch = false;
2385                 } else if (STAT(FROZEN, this)) {
2386                         do_crouch = false;
2387         }
2388
2389                 if (do_crouch) {
2390                         if (!this.crouch) {
2391                                 this.crouch = true;
2392                                 this.view_ofs = STAT(PL_CROUCH_VIEW_OFS, this);
2393                                 setsize(this, STAT(PL_CROUCH_MIN, this), STAT(PL_CROUCH_MAX, this));
2394                                 // setanim(this, this.anim_duck, false, true, true); // this anim is BROKEN anyway
2395                         }
2396                 } else if (this.crouch) {
2397             tracebox(this.origin, STAT(PL_MIN, this), STAT(PL_MAX, this), this.origin, false, this);
2398             if (!trace_startsolid) {
2399                 this.crouch = false;
2400                 this.view_ofs = STAT(PL_VIEW_OFS, this);
2401                 setsize(this, STAT(PL_MIN, this), STAT(PL_MAX, this));
2402             }
2403                 }
2404
2405                 FixPlayermodel(this);
2406
2407                 // LordHavoc: allow firing on move frames (sub-ticrate), this gives better timing on slow servers
2408                 //if(frametime)
2409                 {
2410                         this.items &= ~this.items_added;
2411
2412                         //for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2413                         //{
2414                                 //.entity weaponentity = weaponentities[slot];
2415                                 //W_WeaponFrame(this, weaponentity);
2416                         //}
2417                         .entity weaponentity = weaponentities[0]; // TODO
2418                         W_WeaponFrame(this, weaponentity);
2419
2420                         this.items_added = 0;
2421                         if (this.items & ITEM_Jetpack.m_itemid && (this.items & ITEM_JetpackRegen.m_itemid || this.ammo_fuel >= 0.01))
2422                 this.items_added |= IT_FUEL;
2423
2424                         this.items |= this.items_added;
2425                 }
2426
2427                 player_regen(this);
2428
2429                 // WEAPONTODO: Add a weapon request for this
2430                 // rot vortex charge to the charge limit
2431                 if (WEP_CVAR(vortex, charge_rot_rate) && this.vortex_charge > WEP_CVAR(vortex, charge_limit) && this.vortex_charge_rottime < time)
2432                         this.vortex_charge = bound(WEP_CVAR(vortex, charge_limit), this.vortex_charge - WEP_CVAR(vortex, charge_rot_rate) * frametime / W_TICSPERFRAME, 1);
2433
2434                 if (frametime) player_anim(this);
2435
2436                 // secret status
2437                 secrets_setstatus(this);
2438
2439                 // monsters status
2440                 monsters_setstatus(this);
2441
2442                 this.dmg_team = max(0, this.dmg_team - autocvar_g_teamdamage_resetspeed * frametime);
2443         }
2444         else if (gameover) {
2445                 if (intermission_running) IntermissionThink(this);
2446                 return;
2447         }
2448         else if (IS_OBSERVER(this)) {
2449                 ObserverThink(this);
2450         }
2451         else if (IS_SPEC(this)) {
2452                 SpectatorThink(this);
2453         }
2454
2455         // WEAPONTODO: Add weapon request for this
2456         if (!zoomstate_set) {
2457                 SetZoomState(this,
2458                         PHYS_INPUT_BUTTON_ZOOM(this) || PHYS_INPUT_BUTTON_ZOOMSCRIPT(this)
2459                         || (PHYS_INPUT_BUTTON_ATCK2(this) && PS(this).m_weapon == WEP_VORTEX)
2460                         || (PHYS_INPUT_BUTTON_ATCK2(this) && PS(this).m_weapon == WEP_RIFLE && WEP_CVAR(rifle, secondary) == 0)
2461                 );
2462     }
2463
2464         if (this.teamkill_soundtime && time > this.teamkill_soundtime)
2465         {
2466                 this.teamkill_soundtime = 0;
2467
2468                 entity e = this.teamkill_soundsource;
2469                 entity oldpusher = e.pusher;
2470                 e.pusher = this;
2471                 PlayerSound(e, playersound_teamshoot, CH_VOICE, VOL_BASEVOICE, VOICETYPE_LASTATTACKER_ONLY);
2472                 e.pusher = oldpusher;
2473         }
2474
2475         if (this.taunt_soundtime && time > this.taunt_soundtime) {
2476                 this.taunt_soundtime = 0;
2477                 PlayerSound(this, playersound_taunt, CH_VOICE, VOL_BASEVOICE, VOICETYPE_AUTOTAUNT);
2478         }
2479
2480         target_voicescript_next(this);
2481
2482         // WEAPONTODO: Move into weaponsystem somehow
2483         // if a player goes unarmed after holding a loaded weapon, empty his clip size and remove the crosshair ammo ring
2484         if (PS(this).m_weapon == WEP_Null)
2485                 this.clip_load = this.clip_size = 0;
2486 }
2487
2488 void DrownPlayer(entity this)
2489 {
2490         if(IS_DEAD(this))
2491                 return;
2492
2493         if (this.waterlevel != WATERLEVEL_SUBMERGED || this.vehicle)
2494         {
2495                 if(this.air_finished < time)
2496                         PlayerSound(this, playersound_gasp, CH_PLAYER, VOL_BASE, VOICETYPE_PLAYERSOUND);
2497                 this.air_finished = time + autocvar_g_balance_contents_drowndelay;
2498                 this.dmg = 2;
2499         }
2500         else if (this.air_finished < time)
2501         {       // drown!
2502                 if (this.pain_finished < time)
2503                 {
2504                         Damage (this, NULL, NULL, autocvar_g_balance_contents_playerdamage_drowning * autocvar_g_balance_contents_damagerate, DEATH_DROWN.m_id, this.origin, '0 0 0');
2505                         this.pain_finished = time + 0.5;
2506                 }
2507         }
2508 }
2509
2510 .bool move_qcphysics;
2511
2512 void Player_Physics(entity this)
2513 {
2514         set_movetype(this, this.move_movetype);
2515
2516         if(!this.move_qcphysics)
2517                 return;
2518
2519         if(!frametime && !this.pm_frametime)
2520                 return;
2521
2522         Movetype_Physics_NoMatchTicrate(this, this.pm_frametime, true);
2523
2524         this.pm_frametime = 0;
2525 }
2526
2527 /*
2528 =============
2529 PlayerPostThink
2530
2531 Called every frame for each client after the physics are run
2532 =============
2533 */
2534 .float idlekick_lasttimeleft;
2535 void PlayerPostThink (entity this)
2536 {
2537         Player_Physics(this);
2538
2539         if (sv_maxidle > 0)
2540         if (frametime) // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2541         if (IS_REAL_CLIENT(this))
2542         if (IS_PLAYER(this) || sv_maxidle_spectatorsareidle)
2543         {
2544                 int totalClients = 0;
2545                 if(sv_maxidle_slots > 0)
2546                 {
2547                         FOREACH_CLIENT(IS_REAL_CLIENT(it) || sv_maxidle_slots_countbots,
2548                         {
2549                                 ++totalClients;
2550                         });
2551                 }
2552
2553                 if (sv_maxidle_slots > 0 && (maxclients - totalClients) > sv_maxidle_slots)
2554                 { /* do nothing */ }
2555                 else if (time - this.parm_idlesince < 1) // instead of (time == this.parm_idlesince) to support sv_maxidle <= 10
2556                 {
2557                         if (this.idlekick_lasttimeleft)
2558                         {
2559                                 this.idlekick_lasttimeleft = 0;
2560                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_IDLING);
2561                         }
2562                 }
2563                 else
2564                 {
2565                         float timeleft = ceil(sv_maxidle - (time - this.parm_idlesince));
2566                         if (timeleft == min(10, sv_maxidle - 1)) { // - 1 to support sv_maxidle <= 10
2567                                 if (!this.idlekick_lasttimeleft)
2568                                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_DISCONNECT_IDLING, timeleft);
2569                         }
2570                         if (timeleft <= 0) {
2571                                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_QUIT_KICK_IDLING, this.netname);
2572                                 dropclient(this);
2573                                 return;
2574                         }
2575                         else if (timeleft <= 10) {
2576                                 if (timeleft != this.idlekick_lasttimeleft) {
2577                                     Send_Notification(NOTIF_ONE, this, MSG_ANNCE, Announcer_PickNumber(CNT_IDLE, timeleft));
2578                 }
2579                                 this.idlekick_lasttimeleft = timeleft;
2580                         }
2581                 }
2582         }
2583
2584         CheatFrame(this);
2585
2586         //CheckPlayerJump();
2587
2588         if (IS_PLAYER(this)) {
2589                 DrownPlayer(this);
2590                 CheckRules_Player(this);
2591                 UpdateChatBubble(this);
2592                 if (this.impulse) ImpulseCommands(this);
2593                 if (intermission_running) return; // intermission or finale
2594                 GetPressedKeys(this);
2595         }
2596
2597         if (this.waypointsprite_attachedforcarrier) {
2598             vector v = healtharmor_maxdamage(this.health, this.armorvalue, autocvar_g_balance_armor_blockpercent, DEATH_WEAPON.m_id);
2599                 WaypointSprite_UpdateHealth(this.waypointsprite_attachedforcarrier, '1 0 0' * v);
2600     }
2601
2602         playerdemo_write(this);
2603
2604         CSQCMODEL_AUTOUPDATE(this);
2605 }