qcsrc/server/client.qc

   1 #include "client.qh"
   2
   3 #include <server/defs.qh>
   4 #include <server/miscfunctions.qh>
   5 #include <common/effects/all.qh>
   6 #include "anticheat.qh"
   7 #include "impulse.qh"
   8 #include "player.qh"
   9 #include "ipban.qh"
  10 #include "miscfunctions.qh"
  11 #include "portals.qh"
  12 #include "teamplay.qh"
  13 #include "spawnpoints.qh"
  14 #include "resources.qh"
  15 #include "g_damage.qh"
  16 #include "handicap.qh"
  17 #include "g_hook.qh"
  18 #include "command/common.qh"
  19 #include "command/vote.qh"
  20 #include "clientkill.qh"
  21 #include "cheats.qh"
  22 #include "g_world.qh"
  23 #include "race.qh"
  24 #include "antilag.qh"
  25 #include "campaign.qh"
  26 #include "command/common.qh"
  27 #include "scores_rules.qh"
  28 #include "weapons/common.qh"
  29
  30 #include "bot/api.qh"
  31
  32 #include "../common/ent_cs.qh"
  33 #include "../common/wepent.qh"
  34 #include <common/state.qh>
  35
  36 #include "compat/quake3.qh"
  37
  38 #include <common/effects/qc/globalsound.qh>
  39
  40 #include "../common/mapobjects/func/conveyor.qh"
  41 #include "../common/mapobjects/teleporters.qh"
  42 #include "../common/mapobjects/target/spawnpoint.qh"
  43 #include <common/mapobjects/trigger/counter.qh>
  44 #include <common/mapobjects/trigger/swamp.qh>
  45
  46 #include "../common/vehicles/all.qh"
  47
  48 #include "weapons/hitplot.qh"
  49 #include "weapons/weaponsystem.qh"
  50
  51 #include "../common/net_notice.qh"
  52 #include "../common/net_linked.qh"
  53 #include "../common/physics/player.qh"
  54
  55 #include <common/vehicles/sv_vehicles.qh>
  56
  57 #include "../common/items/_mod.qh"
  58
  59 #include "../common/mutators/mutator/waypoints/all.qh"
  60 #include "../common/mutators/mutator/instagib/sv_instagib.qh"
  61 #include <common/gamemodes/_mod.qh>
  62
  63 #include "../common/mapobjects/subs.qh"
  64 #include "../common/mapobjects/triggers.qh"
  65 #include "../common/mapobjects/trigger/secret.qh"
  66
  67 #include "../common/minigames/sv_minigames.qh"
  68
  69 #include "../common/items/inventory.qh"
  70
  71 #include "../common/monsters/sv_monsters.qh"
  72
  73 #include "../lib/warpzone/server.qh"
  74
  75 #include <common/mutators/mutator/overkill/oknex.qh>
  76
  77 STATIC_METHOD(Client, Add, void(Client this, int _team))
  78 {
  79     ClientConnect(this);
  80     TRANSMUTE(Player, this);
  81     this.frame = 12; // 7
  82     this.team = _team;
  83     PutClientInServer(this);
  84 }
  85
  86 STATIC_METHOD(Client, Remove, void(Client this))
  87 {
  88     TRANSMUTE(Observer, this);
  89     PutClientInServer(this);
  90     ClientDisconnect(this);
  91 }
  92
  93 void send_CSQC_teamnagger() {
  94         WriteHeader(MSG_BROADCAST, TE_CSQC_TEAMNAGGER);
  95 }
  96
  97 int CountSpectators(entity player, entity to)
  98 {
  99         if(!player) { return 0; } // not sure how, but best to be safe
 100
 101         int spec_count = 0;
 102
 103         FOREACH_CLIENT(IS_REAL_CLIENT(it) && IS_SPEC(it) && it != to && it.enemy == player,
 104         {
 105                 spec_count++;
 106         });
 107
 108         return spec_count;
 109 }
 110
 111 void WriteSpectators(entity player, entity to)
 112 {
 113         if(!player) { return; } // not sure how, but best to be safe
 114
 115         FOREACH_CLIENT(IS_REAL_CLIENT(it) && IS_SPEC(it) && it != to && it.enemy == player,
 116         {
 117                 WriteByte(MSG_ENTITY, num_for_edict(it));
 118         });
 119 }
 120
 121 bool ClientData_Send(entity this, entity to, int sf)
 122 {
 123         assert(to == this.owner, return false);
 124
 125         entity e = to;
 126         if (IS_SPEC(e)) e = e.enemy;
 127
 128         sf = 0;
 129         if (CS(e).race_completed)       sf |= BIT(0); // forced scoreboard
 130         if (CS(to).spectatee_status)    sf |= BIT(1); // spectator ent number follows
 131         if (CS(e).zoomstate)            sf |= BIT(2); // zoomed
 132         if (autocvar_sv_showspectators) sf |= BIT(4); // show spectators
 133
 134         WriteHeader(MSG_ENTITY, ENT_CLIENT_CLIENTDATA);
 135         WriteByte(MSG_ENTITY, sf);
 136
 137         if (sf & BIT(1))
 138                 WriteByte(MSG_ENTITY, CS(to).spectatee_status);
 139
 140         if(sf & BIT(4))
 141         {
 142                 float specs = CountSpectators(e, to);
 143                 WriteByte(MSG_ENTITY, specs);
 144                 WriteSpectators(e, to);
 145         }
 146
 147         return true;
 148 }
 149
 150 void ClientData_Attach(entity this)
 151 {
 152         Net_LinkEntity(CS(this).clientdata = new_pure(clientdata), false, 0, ClientData_Send);
 153         CS(this).clientdata.drawonlytoclient = this;
 154         CS(this).clientdata.owner = this;
 155 }
 156
 157 void ClientData_Detach(entity this)
 158 {
 159         delete(CS(this).clientdata);
 160         CS(this).clientdata = NULL;
 161 }
 162
 163 void ClientData_Touch(entity e)
 164 {
 165         entity cd = CS(e).clientdata;
 166         if (cd) { cd.SendFlags = 1; }
 167
 168         // make it spectatable
 169         FOREACH_CLIENT(IS_REAL_CLIENT(it) && it != e && IS_SPEC(it) && it.enemy == e,
 170         {
 171                 entity cd = CS(it).clientdata;
 172                 if (cd) { cd.SendFlags = 1; }
 173         });
 174 }
 175
 176
 177 /*
 178 =============
 179 CheckPlayerModel
 180
 181 Checks if the argument string can be a valid playermodel.
 182 Returns a valid one in doubt.
 183 =============
 184 */
 185 string FallbackPlayerModel;
 186 string CheckPlayerModel(string plyermodel) {
 187         if(FallbackPlayerModel != cvar_defstring("_cl_playermodel"))
 188         {
 189                 // note: we cannot summon Don Strunzone here, some player may
 190                 // still have the model string set. In case anyone manages how
 191                 // to change a cvar default, we'll have a small leak here.
 192                 FallbackPlayerModel = strzone(cvar_defstring("_cl_playermodel"));
 193         }
 194         // only in right path
 195         if( substring(plyermodel,0,14) != "models/player/")
 196                 return FallbackPlayerModel;
 197         // only good file extensions
 198         if(substring(plyermodel,-4,4) != ".zym")
 199         if(substring(plyermodel,-4,4) != ".dpm")
 200         if(substring(plyermodel,-4,4) != ".iqm")
 201         if(substring(plyermodel,-4,4) != ".md3")
 202         if(substring(plyermodel,-4,4) != ".psk")
 203                 return FallbackPlayerModel;
 204         // forbid the LOD models
 205         if(substring(plyermodel, -9,5) == "_lod1")
 206                 return FallbackPlayerModel;
 207         if(substring(plyermodel, -9,5) == "_lod2")
 208                 return FallbackPlayerModel;
 209         if(plyermodel != strtolower(plyermodel))
 210                 return FallbackPlayerModel;
 211         // also, restrict to server models
 212         if(autocvar_sv_servermodelsonly)
 213         {
 214                 if(!fexists(plyermodel))
 215                         return FallbackPlayerModel;
 216         }
 217         return plyermodel;
 218 }
 219
 220 void setplayermodel(entity e, string modelname)
 221 {
 222         precache_model(modelname);
 223         _setmodel(e, modelname);
 224         player_setupanimsformodel(e);
 225         if(!autocvar_g_debug_globalsounds)
 226                 UpdatePlayerSounds(e);
 227 }
 228
 229 /** putting a client as observer in the server */
 230 void PutObserverInServer(entity this)
 231 {
 232     bool mutator_returnvalue = MUTATOR_CALLHOOK(MakePlayerObserver, this);
 233         PlayerState_detach(this);
 234
 235         if (IS_PLAYER(this))
 236         {
 237                 if(GetResource(this, RES_HEALTH) >= 1)
 238                 {
 239                         // despawn effect
 240                         Send_Effect(EFFECT_SPAWN_NEUTRAL, this.origin, '0 0 0', 1);
 241                 }
 242
 243                 // was a player, recount votes and ready status
 244                 if(IS_REAL_CLIENT(this))
 245                 {
 246                         if (vote_called) { VoteCount(false); }
 247                         ReadyCount();
 248                 }
 249     }
 250
 251     {
 252         entity spot = SelectSpawnPoint(this, true);
 253         if (!spot) LOG_FATAL("No spawnpoints for observers?!?");
 254         this.angles = vec2(spot.angles);
 255         this.fixangle = true;
 256         // offset it so that the spectator spawns higher off the ground, looks better this way
 257         setorigin(this, spot.origin + STAT(PL_VIEW_OFS, this));
 258         if (IS_REAL_CLIENT(this))
 259         {
 260             msg_entity = this;
 261             WriteByte(MSG_ONE, SVC_SETVIEW);
 262             WriteEntity(MSG_ONE, this);
 263         }
 264         // give the spectator some space between walls for MOVETYPE_FLY_WORLDONLY
 265         // so that your view doesn't go into the ceiling with MOVETYPE_FLY_WORLDONLY, previously "PL_VIEW_OFS"
 266         if(!autocvar_g_debug_globalsounds)
 267         {
 268                 // needed for player sounds
 269                 this.model = "";
 270                 FixPlayermodel(this);
 271         }
 272         setmodel(this, MDL_Null);
 273         setsize(this, STAT(PL_CROUCH_MIN, this), STAT(PL_CROUCH_MAX, this));
 274         this.view_ofs = '0 0 0';
 275     }
 276
 277     RemoveGrapplingHooks(this);
 278         Portal_ClearAll(this);
 279         Unfreeze(this, false);
 280         SetSpectatee(this, NULL);
 281
 282         if (this.alivetime)
 283         {
 284                 if (!warmup_stage)
 285                         PlayerStats_GameReport_Event_Player(this, PLAYERSTATS_ALIVETIME, time - this.alivetime);
 286                 this.alivetime = 0;
 287         }
 288
 289         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
 290
 291         WaypointSprite_PlayerDead(this);
 292
 293         if (CS(this).killcount != FRAGS_SPECTATOR)
 294         {
 295                 if(!game_stopped)
 296                 if(autocvar_g_chat_nospectators == 1 || (!warmup_stage && autocvar_g_chat_nospectators == 2))
 297                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_CHAT_NOSPECTATORS);
 298         }
 299
 300         accuracy_resend(this);
 301
 302         CS(this).spectatortime = time;
 303         if(this.bot_attack)
 304                 IL_REMOVE(g_bot_targets, this);
 305         this.bot_attack = false;
 306         if(this.monster_attack)
 307                 IL_REMOVE(g_monster_targets, this);
 308         this.monster_attack = false;
 309     STAT(HUD, this) = HUD_NORMAL;
 310         TRANSMUTE(Observer, this);
 311         this.iscreature = false;
 312         this.teleportable = TELEPORT_SIMPLE;
 313         if(this.damagedbycontents)
 314                 IL_REMOVE(g_damagedbycontents, this);
 315         this.damagedbycontents = false;
 316         SetResourceExplicit(this, RES_HEALTH, FRAGS_SPECTATOR);
 317         SetSpectatee_status(this, etof(this));
 318         this.takedamage = DAMAGE_NO;
 319         this.solid = SOLID_NOT;
 320         set_movetype(this, MOVETYPE_FLY_WORLDONLY); // user preference is controlled by playerprethink
 321         this.flags = FL_CLIENT | FL_NOTARGET;
 322         this.effects = 0;
 323         SetResourceExplicit(this, RES_ARMOR, autocvar_g_balance_armor_start); // was 666?!
 324         this.pauserotarmor_finished = 0;
 325         this.pauserothealth_finished = 0;
 326         this.pauseregen_finished = 0;
 327         this.damageforcescale = 0;
 328         this.death_time = 0;
 329         this.respawn_flags = 0;
 330         this.respawn_time = 0;
 331         STAT(RESPAWN_TIME, this) = 0;
 332         this.alpha = 0;
 333         this.scale = 0;
 334         this.fade_time = 0;
 335         this.pain_frame = 0;
 336         this.pain_finished = 0;
 337         this.strength_finished = 0;
 338         this.invincible_finished = 0;
 339         this.superweapons_finished = 0;
 340         //this.dphitcontentsmask = 0;
 341         this.dphitcontentsmask = DPCONTENTS_SOLID;
 342         if (autocvar_g_playerclip_collisions)
 343                 this.dphitcontentsmask |= DPCONTENTS_PLAYERCLIP;
 344         this.pushltime = 0;
 345         this.istypefrag = 0;
 346         setthink(this, func_null);
 347         this.nextthink = 0;
 348         this.deadflag = DEAD_NO;
 349         this.crouch = false;
 350         STAT(REVIVE_PROGRESS, this) = 0;
 351         this.revival_time = 0;
 352         this.draggable = drag_undraggable;
 353
 354         this.items = 0;
 355         STAT(WEAPONS, this) = '0 0 0';
 356         this.drawonlytoclient = this;
 357
 358         this.viewloc = NULL;
 359
 360         //this.spawnpoint_targ = NULL; // keep it so they can return to where they were?
 361
 362         this.weaponmodel = "";
 363         for (int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 364         {
 365                 this.weaponentities[slot] = NULL;
 366         }
 367         this.exteriorweaponentity = NULL;
 368         CS(this).killcount = FRAGS_SPECTATOR;
 369         this.velocity = '0 0 0';
 370         this.avelocity = '0 0 0';
 371         this.punchangle = '0 0 0';
 372         this.punchvector = '0 0 0';
 373         this.oldvelocity = this.velocity;
 374         this.fire_endtime = -1;
 375         this.event_damage = func_null;
 376         this.event_heal = func_null;
 377
 378         for(int slot = 0; slot < MAX_AXH; ++slot)
 379         {
 380                 entity axh = this.(AuxiliaryXhair[slot]);
 381                 this.(AuxiliaryXhair[slot]) = NULL;
 382
 383                 if(axh.owner == this && axh != NULL && !wasfreed(axh))
 384                         delete(axh);
 385         }
 386
 387         if (mutator_returnvalue)
 388         {
 389                 // mutator prevents resetting teams+score
 390         }
 391         else
 392         {
 393                 SetPlayerTeam(this, -1, TEAM_CHANGE_SPECTATOR);
 394                 this.frags = FRAGS_SPECTATOR;
 395         }
 396         if (CS(this).just_joined)
 397                 CS(this).just_joined = false;
 398 }
 399
 400 int player_getspecies(entity this)
 401 {
 402         get_model_parameters(this.model, this.skin);
 403         int s = get_model_parameters_species;
 404         get_model_parameters(string_null, 0);
 405         if (s < 0) return SPECIES_HUMAN;
 406         return s;
 407 }
 408
 409 .float model_randomizer;
 410 void FixPlayermodel(entity player)
 411 {
 412         string defaultmodel = "";
 413         int defaultskin = 0;
 414         if(autocvar_sv_defaultcharacter)
 415         {
 416                 if(teamplay)
 417                 {
 418                         switch(player.team)
 419                         {
 420                                 case NUM_TEAM_1: defaultmodel = autocvar_sv_defaultplayermodel_red; defaultskin = autocvar_sv_defaultplayerskin_red; break;
 421                                 case NUM_TEAM_2: defaultmodel = autocvar_sv_defaultplayermodel_blue; defaultskin = autocvar_sv_defaultplayerskin_blue; break;
 422                                 case NUM_TEAM_3: defaultmodel = autocvar_sv_defaultplayermodel_yellow; defaultskin = autocvar_sv_defaultplayerskin_yellow; break;
 423                                 case NUM_TEAM_4: defaultmodel = autocvar_sv_defaultplayermodel_pink; defaultskin = autocvar_sv_defaultplayerskin_pink; break;
 424                         }
 425                 }
 426
 427                 if(defaultmodel == "")
 428                 {
 429                         defaultmodel = autocvar_sv_defaultplayermodel;
 430                         defaultskin = autocvar_sv_defaultplayerskin;
 431                 }
 432
 433                 int n = tokenize_console(defaultmodel);
 434                 if(n > 0)
 435                 {
 436                         defaultmodel = argv(floor(n * CS(player).model_randomizer));
 437                         // However, do NOT randomize if the player-selected model is in the list.
 438                         for (int i = 0; i < n; ++i)
 439                                 if ((argv(i) == player.playermodel && defaultskin == stof(player.playerskin)) || argv(i) == strcat(player.playermodel, ":", player.playerskin))
 440                                         defaultmodel = argv(i);
 441                 }
 442
 443                 int i = strstrofs(defaultmodel, ":", 0);
 444                 if(i >= 0)
 445                 {
 446                         defaultskin = stof(substring(defaultmodel, i+1, -1));
 447                         defaultmodel = substring(defaultmodel, 0, i);
 448                 }
 449         }
 450         if(autocvar_sv_defaultcharacterskin && !defaultskin)
 451         {
 452                 if(teamplay)
 453                 {
 454                         switch(player.team)
 455                         {
 456                                 case NUM_TEAM_1: defaultskin = autocvar_sv_defaultplayerskin_red; break;
 457                                 case NUM_TEAM_2: defaultskin = autocvar_sv_defaultplayerskin_blue; break;
 458                                 case NUM_TEAM_3: defaultskin = autocvar_sv_defaultplayerskin_yellow; break;
 459                                 case NUM_TEAM_4: defaultskin = autocvar_sv_defaultplayerskin_pink; break;
 460                         }
 461                 }
 462
 463                 if(!defaultskin)
 464                         defaultskin = autocvar_sv_defaultplayerskin;
 465         }
 466
 467         MUTATOR_CALLHOOK(FixPlayermodel, defaultmodel, defaultskin, player);
 468         defaultmodel = M_ARGV(0, string);
 469         defaultskin = M_ARGV(1, int);
 470
 471         bool chmdl = false;
 472         int oldskin;
 473         if(defaultmodel != "")
 474         {
 475                 if (defaultmodel != player.model)
 476                 {
 477                         vector m1 = player.mins;
 478                         vector m2 = player.maxs;
 479                         setplayermodel (player, defaultmodel);
 480                         setsize (player, m1, m2);
 481                         chmdl = true;
 482                 }
 483
 484                 oldskin = player.skin;
 485                 player.skin = defaultskin;
 486         } else {
 487                 if (player.playermodel != player.model || player.playermodel == "")
 488                 {
 489                         player.playermodel = CheckPlayerModel(player.playermodel); // this is never "", so no endless loop
 490                         vector m1 = player.mins;
 491                         vector m2 = player.maxs;
 492                         setplayermodel (player, player.playermodel);
 493                         setsize (player, m1, m2);
 494                         chmdl = true;
 495                 }
 496
 497                 if(!autocvar_sv_defaultcharacterskin)
 498                 {
 499                         oldskin = player.skin;
 500                         player.skin = stof(player.playerskin);
 501                 }
 502                 else
 503                 {
 504                         oldskin = player.skin;
 505                         player.skin = defaultskin;
 506                 }
 507         }
 508
 509         if(chmdl || oldskin != player.skin) // model or skin has changed
 510         {
 511                 player.species = player_getspecies(player); // update species
 512                 if(!autocvar_g_debug_globalsounds)
 513                         UpdatePlayerSounds(player); // update skin sounds
 514         }
 515
 516         if(!teamplay)
 517                 if(strlen(autocvar_sv_defaultplayercolors))
 518                         if(player.clientcolors != stof(autocvar_sv_defaultplayercolors))
 519                                 setcolor(player, stof(autocvar_sv_defaultplayercolors));
 520 }
 521
 522 void PutPlayerInServer(entity this)
 523 {
 524         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
 525
 526         PlayerState_attach(this);
 527         accuracy_resend(this);
 528
 529         if (this.team < 0)
 530                 TeamBalance_JoinBestTeam(this);
 531
 532         entity spot = SelectSpawnPoint(this, false);
 533         if (!spot) {
 534                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_JOIN_NOSPAWNS);
 535                 return; // spawn failed
 536         }
 537
 538         TRANSMUTE(Player, this);
 539
 540         CS(this).wasplayer = true;
 541         this.iscreature = true;
 542         this.teleportable = TELEPORT_NORMAL;
 543         if(!this.damagedbycontents)
 544                 IL_PUSH(g_damagedbycontents, this);
 545         this.damagedbycontents = true;
 546         set_movetype(this, MOVETYPE_WALK);
 547         this.solid = SOLID_SLIDEBOX;
 548         this.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_SOLID;
 549         if (autocvar_g_playerclip_collisions)
 550                 this.dphitcontentsmask |= DPCONTENTS_PLAYERCLIP;
 551         if (IS_BOT_CLIENT(this) && autocvar_g_botclip_collisions)
 552                 this.dphitcontentsmask |= DPCONTENTS_BOTCLIP;
 553         this.frags = FRAGS_PLAYER;
 554         if (INDEPENDENT_PLAYERS) MAKE_INDEPENDENT_PLAYER(this);
 555         this.flags = FL_CLIENT | FL_PICKUPITEMS;
 556         if (autocvar__notarget)
 557                 this.flags |= FL_NOTARGET;
 558         this.takedamage = DAMAGE_AIM;
 559         this.effects = EF_TELEPORT_BIT | EF_RESTARTANIM_BIT;
 560
 561         if (warmup_stage) {
 562                 SetResource(this, RES_SHELLS, warmup_start_ammo_shells);
 563                 SetResource(this, RES_BULLETS, warmup_start_ammo_nails);
 564                 SetResource(this, RES_ROCKETS, warmup_start_ammo_rockets);
 565                 SetResource(this, RES_CELLS, warmup_start_ammo_cells);
 566                 SetResource(this, RES_PLASMA, warmup_start_ammo_plasma);
 567                 SetResource(this, RES_FUEL, warmup_start_ammo_fuel);
 568                 SetResource(this, RES_HEALTH, warmup_start_health);
 569                 SetResource(this, RES_ARMOR, warmup_start_armorvalue);
 570                 STAT(WEAPONS, this) = WARMUP_START_WEAPONS;
 571         } else {
 572                 SetResource(this, RES_SHELLS, start_ammo_shells);
 573                 SetResource(this, RES_BULLETS, start_ammo_nails);
 574                 SetResource(this, RES_ROCKETS, start_ammo_rockets);
 575                 SetResource(this, RES_CELLS, start_ammo_cells);
 576                 SetResource(this, RES_PLASMA, start_ammo_plasma);
 577                 SetResource(this, RES_FUEL, start_ammo_fuel);
 578                 SetResource(this, RES_HEALTH, start_health);
 579                 SetResource(this, RES_ARMOR, start_armorvalue);
 580                 STAT(WEAPONS, this) = start_weapons;
 581                 if (MUTATOR_CALLHOOK(ForbidRandomStartWeapons, this) == false)
 582                 {
 583                         GiveRandomWeapons(this, random_start_weapons_count,
 584                                 autocvar_g_random_start_weapons, random_start_ammo);
 585                 }
 586         }
 587         SetSpectatee_status(this, 0);
 588
 589         PS(this).dual_weapons = '0 0 0';
 590
 591         this.superweapons_finished = (STAT(WEAPONS, this) & WEPSET_SUPERWEAPONS) ? time + autocvar_g_balance_superweapons_time : 0;
 592
 593         this.items = start_items;
 594
 595         this.spawnshieldtime = time + autocvar_g_spawnshieldtime;
 596         this.pauserotarmor_finished = time + autocvar_g_balance_pause_armor_rot_spawn;
 597         this.pauserothealth_finished = time + autocvar_g_balance_pause_health_rot_spawn;
 598         this.pauserotfuel_finished = time + autocvar_g_balance_pause_fuel_rot_spawn;
 599         this.pauseregen_finished = time + autocvar_g_balance_pause_health_regen_spawn;
 600         if (!sv_ready_restart_after_countdown && time < game_starttime)
 601         {
 602                 float f = game_starttime - time;
 603                 this.spawnshieldtime += f;
 604                 this.pauserotarmor_finished += f;
 605                 this.pauserothealth_finished += f;
 606                 this.pauseregen_finished += f;
 607         }
 608
 609         this.damageforcescale = autocvar_g_player_damageforcescale;
 610         this.death_time = 0;
 611         this.respawn_flags = 0;
 612         this.respawn_time = 0;
 613         STAT(RESPAWN_TIME, this) = 0;
 614         bool q3dfcompat = autocvar_sv_q3defragcompat && autocvar_sv_q3defragcompat_changehitbox;
 615         this.scale = ((q3dfcompat) ? 0.9 : autocvar_sv_player_scale);
 616         this.fade_time = 0;
 617         this.pain_frame = 0;
 618         this.pain_finished = 0;
 619         this.pushltime = 0;
 620         setthink(this, func_null); // players have no think function
 621         this.nextthink = 0;
 622         this.dmg_team = 0;
 623         PS(this).ballistics_density = autocvar_g_ballistics_density_player;
 624
 625         this.deadflag = DEAD_NO;
 626
 627         this.angles = spot.angles;
 628         this.angles_z = 0; // never spawn tilted even if the spot says to
 629         if (IS_BOT_CLIENT(this))
 630         {
 631                 this.v_angle = this.angles;
 632                 bot_aim_reset(this);
 633         }
 634         this.fixangle = true; // turn this way immediately
 635         this.oldvelocity = this.velocity = '0 0 0';
 636         this.avelocity = '0 0 0';
 637         this.punchangle = '0 0 0';
 638         this.punchvector = '0 0 0';
 639
 640         this.strength_finished = 0;
 641         this.invincible_finished = 0;
 642         this.fire_endtime = -1;
 643         STAT(REVIVE_PROGRESS, this) = 0;
 644         this.revival_time = 0;
 645
 646         // TODO: we can't set these in the PlayerSpawn hook since the target code is called before it!
 647         STAT(BUFFS, this) = 0;
 648         STAT(BUFF_TIME, this) = 0;
 649
 650         this.air_finished = time + autocvar_g_balance_contents_drowndelay;
 651         this.waterlevel = WATERLEVEL_NONE;
 652         this.watertype = CONTENT_EMPTY;
 653
 654         entity spawnevent = new_pure(spawnevent);
 655         spawnevent.owner = this;
 656         Net_LinkEntity(spawnevent, false, 0.5, SpawnEvent_Send);
 657
 658         // Cut off any still running player sounds.
 659         stopsound(this, CH_PLAYER_SINGLE);
 660
 661         this.model = "";
 662         FixPlayermodel(this);
 663         this.drawonlytoclient = NULL;
 664
 665         this.viewloc = NULL;
 666
 667         for(int slot = 0; slot < MAX_AXH; ++slot)
 668         {
 669                 entity axh = this.(AuxiliaryXhair[slot]);
 670                 this.(AuxiliaryXhair[slot]) = NULL;
 671
 672                 if(axh.owner == this && axh != NULL && !wasfreed(axh))
 673                         delete(axh);
 674         }
 675
 676         this.spawnpoint_targ = NULL;
 677
 678         this.crouch = false;
 679         this.view_ofs = STAT(PL_VIEW_OFS, this);
 680         setsize(this, STAT(PL_MIN, this), STAT(PL_MAX, this));
 681         this.spawnorigin = spot.origin;
 682         setorigin(this, spot.origin + '0 0 1' * (1 - this.mins.z - 24));
 683         // don't reset back to last position, even if new position is stuck in solid
 684         this.oldorigin = this.origin;
 685         if(this.conveyor)
 686                 IL_REMOVE(g_conveyed, this);
 687         this.conveyor = NULL; // prevent conveyors at the previous location from moving a freshly spawned player
 688         if(this.swampslug)
 689                 delete(this.swampslug);
 690         this.in_swamp = false;
 691         STAT(HUD, this) = HUD_NORMAL;
 692
 693         this.event_damage = PlayerDamage;
 694         this.event_heal = PlayerHeal;
 695
 696         this.draggable = func_null;
 697
 698         if(!this.bot_attack)
 699                 IL_PUSH(g_bot_targets, this);
 700         this.bot_attack = true;
 701         if(!this.monster_attack)
 702                 IL_PUSH(g_monster_targets, this);
 703         this.monster_attack = true;
 704         navigation_dynamicgoal_init(this, false);
 705
 706         PHYS_INPUT_BUTTON_ATCK(this) = PHYS_INPUT_BUTTON_JUMP(this) = PHYS_INPUT_BUTTON_ATCK2(this) = false;
 707
 708         // player was spectator
 709         if (CS(this).killcount == FRAGS_SPECTATOR) {
 710                 PlayerScore_Clear(this);
 711                 CS(this).killcount = 0;
 712                 CS(this).startplaytime = time;
 713         }
 714
 715         for (int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 716         {
 717                 .entity weaponentity = weaponentities[slot];
 718                 CL_SpawnWeaponentity(this, weaponentity);
 719         }
 720         this.alpha = default_player_alpha;
 721         this.colormod = '1 1 1' * autocvar_g_player_brightness;
 722         this.exteriorweaponentity.alpha = default_weapon_alpha;
 723
 724         this.speedrunning = false;
 725
 726         this.counter_cnt = 0;
 727         this.fragsfilter_cnt = 0;
 728
 729         target_voicescript_clear(this);
 730
 731         // reset fields the weapons may use
 732         FOREACH(Weapons, true, {
 733                 it.wr_resetplayer(it, this);
 734                         // reload all reloadable weapons
 735                 if (it.spawnflags & WEP_FLAG_RELOADABLE) {
 736                         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 737                         {
 738                                 .entity weaponentity = weaponentities[slot];
 739                                 this.(weaponentity).weapon_load[it.m_id] = it.reloading_ammo;
 740                         }
 741                 }
 742         });
 743
 744         {
 745                 string s = spot.target;
 746                 if(g_assault || g_race) // TODO: make targeting work in assault & race without this hack
 747                         spot.target = string_null;
 748                 SUB_UseTargets(spot, this, NULL);
 749                 if(g_assault || g_race)
 750                         spot.target = s;
 751         }
 752
 753         Unfreeze(this, false);
 754
 755         MUTATOR_CALLHOOK(PlayerSpawn, this, spot);
 756
 757         if (autocvar_spawn_debug)
 758         {
 759                 sprint(this, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
 760                 delete(spot); // usefull for checking if there are spawnpoints, that let drop through the floor
 761         }
 762
 763         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 764         {
 765                 .entity weaponentity = weaponentities[slot];
 766                 if(slot == 0 || autocvar_g_weaponswitch_debug == 1)
 767                         this.(weaponentity).m_switchweapon = w_getbestweapon(this, weaponentity);
 768                 else
 769                         this.(weaponentity).m_switchweapon = WEP_Null;
 770                 this.(weaponentity).m_weapon = WEP_Null;
 771                 this.(weaponentity).weaponname = "";
 772                 this.(weaponentity).m_switchingweapon = WEP_Null;
 773                 this.(weaponentity).cnt = -1;
 774         }
 775
 776         MUTATOR_CALLHOOK(PlayerWeaponSelect, this);
 777
 778         if (CS(this).impulse) ImpulseCommands(this);
 779
 780         W_ResetGunAlign(this, CS(this).cvar_cl_gunalign);
 781         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 782         {
 783                 .entity weaponentity = weaponentities[slot];
 784                 W_WeaponFrame(this, weaponentity);
 785         }
 786
 787         if (!warmup_stage && !this.alivetime)
 788                 this.alivetime = time;
 789
 790         antilag_clear(this, CS(this));
 791 }
 792
 793 /** Called when a client spawns in the server */
 794 void PutClientInServer(entity this)
 795 {
 796         if (IS_BOT_CLIENT(this)) {
 797                 TRANSMUTE(Player, this);
 798         } else if (IS_REAL_CLIENT(this)) {
 799                 msg_entity = this;
 800                 WriteByte(MSG_ONE, SVC_SETVIEW);
 801                 WriteEntity(MSG_ONE, this);
 802         }
 803         if (game_stopped)
 804                 TRANSMUTE(Observer, this);
 805
 806         SetSpectatee(this, NULL);
 807
 808         // reset player keys
 809         if(PS(this))
 810                 PS(this).itemkeys = 0;
 811
 812         MUTATOR_CALLHOOK(PutClientInServer, this);
 813
 814         if (IS_OBSERVER(this)) {
 815                 PutObserverInServer(this);
 816         } else if (IS_PLAYER(this)) {
 817                 PutPlayerInServer(this);
 818         }
 819 }
 820
 821 // TODO do we need all these fields, or should we stop autodetecting runtime
 822 // changes and just have a console command to update this?
 823 bool ClientInit_SendEntity(entity this, entity to, int sf)
 824 {
 825         WriteHeader(MSG_ENTITY, _ENT_CLIENT_INIT);
 826         return = true;
 827         msg_entity = to;
 828         // MSG_INIT replacement
 829         // TODO: make easier to use
 830         Registry_send_all();
 831         W_PROP_reload(MSG_ONE, to);
 832         ClientInit_misc(this);
 833         MUTATOR_CALLHOOK(Ent_Init);
 834 }
 835 void ClientInit_misc(entity this)
 836 {
 837         int channel = MSG_ONE;
 838         WriteHeader(channel, ENT_CLIENT_INIT);
 839         WriteByte(channel, g_nexball_meter_period * 32);
 840         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[0]));
 841         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[1]));
 842         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[2]));
 843         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[3]));
 844         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[0]));
 845         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[1]));
 846         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[2]));
 847         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[3]));
 848
 849         if(sv_foginterval && world.fog != "")
 850                 WriteString(channel, world.fog);
 851         else
 852                 WriteString(channel, "");
 853         WriteByte(channel, this.count * 255.0); // g_balance_armor_blockpercent
 854         WriteByte(channel, this.cnt * 255.0); // g_balance_damagepush_speedfactor
 855         WriteByte(channel, serverflags);
 856         WriteCoord(channel, autocvar_g_trueaim_minrange);
 857 }
 858
 859 void ClientInit_CheckUpdate(entity this)
 860 {
 861         this.nextthink = time;
 862         if(this.count != autocvar_g_balance_armor_blockpercent)
 863         {
 864                 this.count = autocvar_g_balance_armor_blockpercent;
 865                 this.SendFlags |= 1;
 866         }
 867         if(this.cnt != autocvar_g_balance_damagepush_speedfactor)
 868         {
 869                 this.cnt = autocvar_g_balance_damagepush_speedfactor;
 870                 this.SendFlags |= 1;
 871         }
 872 }
 873
 874 void ClientInit_Spawn()
 875 {
 876         entity e = new_pure(clientinit);
 877         setthink(e, ClientInit_CheckUpdate);
 878         Net_LinkEntity(e, false, 0, ClientInit_SendEntity);
 879
 880         ClientInit_CheckUpdate(e);
 881 }
 882
 883 /*
 884 =============
 885 SetNewParms
 886 =============
 887 */
 888 void SetNewParms ()
 889 {
 890         // initialize parms for a new player
 891         parm1 = -(86400 * 366);
 892
 893         MUTATOR_CALLHOOK(SetNewParms);
 894 }
 895
 896 /*
 897 =============
 898 SetChangeParms
 899 =============
 900 */
 901 void SetChangeParms (entity this)
 902 {
 903         // save parms for level change
 904         parm1 = CS(this).parm_idlesince - time;
 905
 906         MUTATOR_CALLHOOK(SetChangeParms);
 907 }
 908
 909 /*
 910 =============
 911 DecodeLevelParms
 912 =============
 913 */
 914 void DecodeLevelParms(entity this)
 915 {
 916         // load parms
 917         CS(this).parm_idlesince = parm1;
 918         if (CS(this).parm_idlesince == -(86400 * 366))
 919                 CS(this).parm_idlesince = time;
 920
 921         // whatever happens, allow 60 seconds of idling directly after connect for map loading
 922         CS(this).parm_idlesince = max(CS(this).parm_idlesince, time - sv_maxidle + 60);
 923
 924         MUTATOR_CALLHOOK(DecodeLevelParms);
 925 }
 926
 927 void FixClientCvars(entity e)
 928 {
 929         // send prediction settings to the client
 930         stuffcmd(e, "\nin_bindmap 0 0\n");
 931         if(autocvar_g_antilag == 3) // client side hitscan
 932                 stuffcmd(e, "cl_cmd settemp cl_prydoncursor_notrace 0\n");
 933         if(autocvar_sv_gentle)
 934                 stuffcmd(e, "cl_cmd settemp cl_gentle 1\n");
 935
 936         stuffcmd(e, sprintf("\ncl_jumpspeedcap_min \"%s\"\n", autocvar_sv_jumpspeedcap_min));
 937         stuffcmd(e, sprintf("\ncl_jumpspeedcap_max \"%s\"\n", autocvar_sv_jumpspeedcap_max));
 938
 939         stuffcmd(e, sprintf("\ncl_shootfromfixedorigin \"%s\"\n", autocvar_g_shootfromfixedorigin));
 940
 941         MUTATOR_CALLHOOK(FixClientCvars, e);
 942 }
 943
 944 bool findinlist_abbrev(string tofind, string list)
 945 {
 946         if(list == "" || tofind == "")
 947                 return false; // empty list or search, just return
 948
 949         // this function allows abbreviated strings!
 950         FOREACH_WORD(list, it == substring(tofind, 0, strlen(it)),
 951         {
 952                 return true;
 953         });
 954
 955         return false;
 956 }
 957
 958 bool PlayerInIPList(entity p, string iplist)
 959 {
 960         // some safety checks (never allow local?)
 961         if(p.netaddress == "local" || p.netaddress == "" || !IS_REAL_CLIENT(p))
 962                 return false;
 963
 964         return findinlist_abbrev(p.netaddress, iplist);
 965 }
 966
 967 bool PlayerInIDList(entity p, string idlist)
 968 {
 969         // NOTE: we do NOT check crypto_idfp_signed here, an unsigned ID is fine too for this
 970         if(!p.crypto_idfp)
 971                 return false;
 972
 973         return findinlist_abbrev(p.crypto_idfp, idlist);
 974 }
 975
 976 bool PlayerInList(entity player, string list)
 977 {
 978         return boolean(PlayerInIDList(player, list) || PlayerInIPList(player, list));
 979 }
 980
 981 #ifdef DP_EXT_PRECONNECT
 982 /*
 983 =============
 984 ClientPreConnect
 985
 986 Called once (not at each match start) when a client begins a connection to the server
 987 =============
 988 */
 989 void ClientPreConnect(entity this)
 990 {
 991         if(autocvar_sv_eventlog)
 992         {
 993                 GameLogEcho(sprintf(":connect:%d:%d:%s",
 994                         this.playerid,
 995                         etof(this),
 996                         ((IS_REAL_CLIENT(this)) ? this.netaddress : "bot")
 997                 ));
 998         }
 999 }
1000 #endif
1001
1002 string GetClientVersionMessage(entity this)
1003 {
1004         if (CS(this).version_mismatch) {
1005                 if(CS(this).version < autocvar_gameversion) {
1006                         return strcat("This is Xonotic ", autocvar_g_xonoticversion,
1007                                 "\n^3Your client version is outdated.\n\n\n### YOU WON'T BE ABLE TO PLAY ON THIS SERVER ###\n\n\nPlease update!!!^8");
1008                 } else {
1009                         return strcat("This is Xonotic ", autocvar_g_xonoticversion,
1010                                 "\n^3This server is using an outdated Xonotic version.\n\n\n ### THIS SERVER IS INCOMPATIBLE AND THUS YOU CANNOT JOIN ###.^8");
1011                 }
1012         } else {
1013                 return strcat("Welcome to Xonotic ", autocvar_g_xonoticversion);
1014         }
1015 }
1016
1017 string getwelcomemessage(entity this)
1018 {
1019         MUTATOR_CALLHOOK(BuildMutatorsPrettyString, "");
1020         string modifications = M_ARGV(0, string);
1021
1022         if(g_weaponarena)
1023         {
1024                 if(g_weaponarena_random)
1025                         modifications = strcat(modifications, ", ", ftos(g_weaponarena_random), " of ", g_weaponarena_list, " Arena");
1026                 else
1027                         modifications = strcat(modifications, ", ", g_weaponarena_list, " Arena");
1028         }
1029         else if(cvar("g_balance_blaster_weaponstartoverride") == 0)
1030                 modifications = strcat(modifications, ", No start weapons");
1031         if(cvar("sv_gravity") < stof(cvar_defstring("sv_gravity")))
1032                 modifications = strcat(modifications, ", Low gravity");
1033         if(g_weapon_stay && !g_cts)
1034                 modifications = strcat(modifications, ", Weapons stay");
1035         if(g_jetpack)
1036                 modifications = strcat(modifications, ", Jet pack");
1037         if(autocvar_g_powerups == 0)
1038                 modifications = strcat(modifications, ", No powerups");
1039         if(autocvar_g_powerups > 0)
1040                 modifications = strcat(modifications, ", Powerups");
1041         modifications = substring(modifications, 2, strlen(modifications) - 2);
1042
1043         string versionmessage = GetClientVersionMessage(this);
1044         string s = strcat(versionmessage, "^8\n^8\nmatch type is ^1", gamemode_name, "^8\n");
1045
1046         if(modifications != "")
1047                 s = strcat(s, "^8\nactive modifications: ^3", modifications, "^8\n");
1048
1049         if(cache_lastmutatormsg != autocvar_g_mutatormsg)
1050         {
1051                 strcpy(cache_lastmutatormsg, autocvar_g_mutatormsg);
1052                 strcpy(cache_mutatormsg, cache_lastmutatormsg);
1053         }
1054
1055         if (cache_mutatormsg != "") {
1056                 s = strcat(s, "\n\n^8special gameplay tips: ^7", cache_mutatormsg);
1057         }
1058
1059         string mutator_msg = "";
1060         MUTATOR_CALLHOOK(BuildGameplayTipsString, mutator_msg);
1061         mutator_msg = M_ARGV(0, string);
1062
1063         s = strcat(s, mutator_msg); // trust that the mutator will do proper formatting
1064
1065         string motd = autocvar_sv_motd;
1066         if (motd != "") {
1067                 s = strcat(s, "\n\n^8MOTD: ^7", strreplace("\\n", "\n", motd));
1068         }
1069         return s;
1070 }
1071
1072 bool autocvar_sv_qcphysics = true; // TODO this is for testing - remove when qcphysics work
1073
1074 /**
1075 =============
1076 ClientConnect
1077
1078 Called when a client connects to the server
1079 =============
1080 */
1081 void ClientConnect(entity this)
1082 {
1083         if (Ban_MaybeEnforceBanOnce(this)) return;
1084         assert(!IS_CLIENT(this), return);
1085         this.flags |= FL_CLIENT;
1086         assert(player_count >= 0, player_count = 0);
1087
1088 #ifdef WATERMARK
1089         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_WATERMARK, WATERMARK);
1090 #endif
1091         TRANSMUTE(Client, this);
1092         CS(this).version_nagtime = time + 10 + random() * 10;
1093
1094         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_JOIN_CONNECT, this.netname);
1095
1096         bot_clientconnect(this);
1097
1098         Player_DetermineForcedTeam(this);
1099
1100         TRANSMUTE(Observer, this);
1101
1102         PlayerStats_GameReport_AddEvent(sprintf("kills-%d", this.playerid));
1103
1104         // always track bots, don't ask for cl_allow_uidtracking
1105         if (IS_BOT_CLIENT(this))
1106                 PlayerStats_GameReport_AddPlayer(this);
1107         else
1108                 CS(this).allowed_timeouts = autocvar_sv_timeout_number;
1109
1110         if (autocvar_sv_eventlog)
1111                 GameLogEcho(strcat(":join:", ftos(this.playerid), ":", ftos(etof(this)), ":", ((IS_REAL_CLIENT(this)) ? GameLog_ProcessIP(this.netaddress) : "bot"), ":", playername(this, false)));
1112
1113         CS(this).just_joined = true;  // stop spamming the eventlog with additional lines when the client connects
1114
1115         stuffcmd(this, clientstuff, "\n");
1116         stuffcmd(this, "cl_particles_reloadeffects\n"); // TODO do we still need this?
1117
1118         FixClientCvars(this);
1119
1120         // get version info from player
1121         stuffcmd(this, "cmd clientversion $gameversion\n");
1122
1123         // notify about available teams
1124         if (teamplay)
1125         {
1126                 entity balance = TeamBalance_CheckAllowedTeams(this);
1127                 int t = TeamBalance_GetAllowedTeams(balance);
1128                 TeamBalance_Destroy(balance);
1129                 stuffcmd(this, sprintf("set _teams_available %d\n", t));
1130         }
1131         else
1132         {
1133                 stuffcmd(this, "set _teams_available 0\n");
1134         }
1135
1136         bot_relinkplayerlist();
1137
1138         CS(this).spectatortime = time;
1139         if (blockSpectators)
1140         {
1141                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
1142         }
1143
1144         CS(this).jointime = time;
1145
1146         if (IS_REAL_CLIENT(this))
1147         {
1148                 if (g_weaponarena_weapons == WEPSET(TUBA))
1149                         stuffcmd(this, "cl_cmd settemp chase_active 1\n");
1150         }
1151
1152         if (!sv_foginterval && world.fog != "")
1153                 stuffcmd(this, strcat("\nfog ", world.fog, "\nr_fog_exp2 0\nr_drawfog 1\n"));
1154
1155         if (autocvar_sv_teamnagger && !(autocvar_bot_vs_human && AvailableTeams() == 2))
1156                 if(!MUTATOR_CALLHOOK(HideTeamNagger, this))
1157                         send_CSQC_teamnagger();
1158
1159         CSQCMODEL_AUTOINIT(this);
1160
1161         CS(this).model_randomizer = random();
1162
1163         if (IS_REAL_CLIENT(this))
1164                 sv_notice_join(this);
1165
1166         this.move_qcphysics = autocvar_sv_qcphysics;
1167
1168         // update physics stats (players can spawn before physics runs)
1169         Physics_UpdateStats(this);
1170
1171         IL_EACH(g_initforplayer, it.init_for_player, {
1172                 it.init_for_player(it, this);
1173         });
1174
1175         Handicap_Initialize(this);
1176
1177         MUTATOR_CALLHOOK(ClientConnect, this);
1178
1179         if (IS_REAL_CLIENT(this))
1180         {
1181                 if (!autocvar_g_campaign && !IS_PLAYER(this))
1182                 {
1183                         CS(this).motd_actived_time = -1;
1184                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOTD, getwelcomemessage(this));
1185                 }
1186         }
1187 }
1188 /*
1189 =============
1190 ClientDisconnect
1191
1192 Called when a client disconnects from the server
1193 =============
1194 */
1195 .entity chatbubbleentity;
1196 void ClientDisconnect(entity this)
1197 {
1198         assert(IS_CLIENT(this), return);
1199
1200         PlayerStats_GameReport_FinalizePlayer(this);
1201         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
1202         if (CS(this).active_minigame) part_minigame(this);
1203         if (IS_PLAYER(this)) Send_Effect(EFFECT_SPAWN_NEUTRAL, this.origin, '0 0 0', 1);
1204
1205         if (autocvar_sv_eventlog)
1206                 GameLogEcho(strcat(":part:", ftos(this.playerid)));
1207
1208         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_QUIT_DISCONNECT, this.netname);
1209
1210         if(IS_SPEC(this))
1211                 SetSpectatee(this, NULL);
1212
1213     MUTATOR_CALLHOOK(ClientDisconnect, this);
1214
1215         strfree(CS(this).netname_previous); // needs to be before the CS entity is removed!
1216         strfree(CS(this).weaponorder_byimpulse);
1217         ClientState_detach(this);
1218
1219         Portal_ClearAll(this);
1220
1221         Unfreeze(this, false);
1222
1223         RemoveGrapplingHooks(this);
1224
1225         // Here, everything has been done that requires this player to be a client.
1226
1227         this.flags &= ~FL_CLIENT;
1228
1229         if (this.chatbubbleentity) delete(this.chatbubbleentity);
1230         if (this.killindicator) delete(this.killindicator);
1231
1232         WaypointSprite_PlayerGone(this);
1233
1234         bot_relinkplayerlist();
1235
1236         strfree(this.clientstatus);
1237         if (this.personal) delete(this.personal);
1238
1239         this.playerid = 0;
1240         ReadyCount();
1241         if (vote_called && IS_REAL_CLIENT(this)) VoteCount(false);
1242
1243         ONREMOVE(this);
1244 }
1245
1246 void ChatBubbleThink(entity this)
1247 {
1248         this.nextthink = time;
1249         if ((this.owner.alpha < 0) || this.owner.chatbubbleentity != this)
1250         {
1251                 if(this.owner) // but why can that ever be NULL?
1252                         this.owner.chatbubbleentity = NULL;
1253                 delete(this);
1254                 return;
1255         }
1256
1257         this.mdl = "";
1258
1259         if ( !IS_DEAD(this.owner) && IS_PLAYER(this.owner) )
1260         {
1261                 if ( CS(this.owner).active_minigame && PHYS_INPUT_BUTTON_MINIGAME(this.owner) )
1262                         this.mdl = "models/sprites/minigame_busy.iqm";
1263                 else if (PHYS_INPUT_BUTTON_CHAT(this.owner))
1264                         this.mdl = "models/misc/chatbubble.spr";
1265         }
1266
1267         if ( this.model != this.mdl )
1268                 _setmodel(this, this.mdl);
1269
1270 }
1271
1272 void UpdateChatBubble(entity this)
1273 {
1274         if (this.alpha < 0)
1275                 return;
1276         // spawn a chatbubble entity if needed
1277         if (!this.chatbubbleentity)
1278         {
1279                 this.chatbubbleentity = new(chatbubbleentity);
1280                 this.chatbubbleentity.owner = this;
1281                 this.chatbubbleentity.exteriormodeltoclient = this;
1282                 setthink(this.chatbubbleentity, ChatBubbleThink);
1283                 this.chatbubbleentity.nextthink = time;
1284                 setmodel(this.chatbubbleentity, MDL_CHAT); // precision set below
1285                 //setorigin(this.chatbubbleentity, this.origin + '0 0 15' + this.maxs_z * '0 0 1');
1286                 setorigin(this.chatbubbleentity, '0 0 15' + this.maxs_z * '0 0 1');
1287                 setattachment(this.chatbubbleentity, this, "");  // sticks to moving player better, also conserves bandwidth
1288                 this.chatbubbleentity.mdl = this.chatbubbleentity.model;
1289                 //this.chatbubbleentity.model = "";
1290                 this.chatbubbleentity.effects = EF_LOWPRECISION;
1291         }
1292 }
1293
1294
1295 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
1296 // added to the model skins
1297 /*void UpdateColorModHack()
1298 {
1299         float c;
1300         c = this.clientcolors & 15;
1301         // LordHavoc: only bothering to support white, green, red, yellow, blue
1302              if (!teamplay) this.colormod = '0 0 0';
1303         else if (c ==  0) this.colormod = '1.00 1.00 1.00';
1304         else if (c ==  3) this.colormod = '0.10 1.73 0.10';
1305         else if (c ==  4) this.colormod = '1.73 0.10 0.10';
1306         else if (c == 12) this.colormod = '1.22 1.22 0.10';
1307         else if (c == 13) this.colormod = '0.10 0.10 1.73';
1308         else this.colormod = '1 1 1';
1309 }*/
1310
1311 void respawn(entity this)
1312 {
1313         if(this.alpha >= 0 && autocvar_g_respawn_ghosts)
1314         {
1315                 this.solid = SOLID_NOT;
1316                 this.takedamage = DAMAGE_NO;
1317                 set_movetype(this, MOVETYPE_FLY);
1318                 this.velocity = '0 0 1' * autocvar_g_respawn_ghosts_speed;
1319                 this.avelocity = randomvec() * autocvar_g_respawn_ghosts_speed * 3 - randomvec() * autocvar_g_respawn_ghosts_speed * 3;
1320                 this.effects |= CSQCMODEL_EF_RESPAWNGHOST;
1321                 Send_Effect(EFFECT_RESPAWN_GHOST, this.origin, '0 0 0', 1);
1322                 if(autocvar_g_respawn_ghosts_maxtime)
1323                         SUB_SetFade (this, time + autocvar_g_respawn_ghosts_maxtime / 2 + random () * (autocvar_g_respawn_ghosts_maxtime - autocvar_g_respawn_ghosts_maxtime / 2), 1.5);
1324         }
1325
1326         CopyBody(this, 1);
1327
1328         this.effects |= EF_NODRAW; // prevent another CopyBody
1329         PutClientInServer(this);
1330 }
1331
1332 ERASEABLE
1333 void PrintToChat(entity client, string text)
1334 {
1335         text = strcat("\{1}^7", text, "\n");
1336         sprint(client, text);
1337 }
1338
1339 ERASEABLE
1340 void DebugPrintToChat(entity client, string text)
1341 {
1342         if (autocvar_developer > 0)
1343         {
1344                 PrintToChat(client, text);
1345         }
1346 }
1347
1348 ERASEABLE
1349 void PrintToChatAll(string text)
1350 {
1351         text = strcat("\{1}^7", text, "\n");
1352         bprint(text);
1353 }
1354
1355 ERASEABLE
1356 void DebugPrintToChatAll(string text)
1357 {
1358         if (autocvar_developer > 0)
1359         {
1360                 PrintToChatAll(text);
1361         }
1362 }
1363
1364 ERASEABLE
1365 void PrintToChatTeam(int team_num, string text)
1366 {
1367         text = strcat("\{1}^7", text, "\n");
1368         FOREACH_CLIENT(IS_REAL_CLIENT(it),
1369         {
1370                 if (it.team == team_num)
1371                 {
1372                         sprint(it, text);
1373                 }
1374         });
1375 }
1376
1377 ERASEABLE
1378 void DebugPrintToChatTeam(int team_num, string text)
1379 {
1380         if (autocvar_developer > 0)
1381         {
1382                 PrintToChatTeam(team_num, text);
1383         }
1384 }
1385
1386 void play_countdown(entity this, float finished, Sound samp)
1387 {
1388         TC(Sound, samp);
1389         if(IS_REAL_CLIENT(this))
1390                 if(floor(finished - time - frametime) != floor(finished - time))
1391                         if(finished - time < 6)
1392                                 sound (this, CH_INFO, samp, VOL_BASE, ATTEN_NORM);
1393 }
1394
1395 void player_powerups(entity this)
1396 {
1397         // add a way to see what the items were BEFORE all of these checks for the mutator hook
1398         int items_prev = this.items;
1399
1400         if((this.items & IT_USING_JETPACK) && !IS_DEAD(this) && !game_stopped)
1401                 this.modelflags |= MF_ROCKET;
1402         else
1403                 this.modelflags &= ~MF_ROCKET;
1404
1405         this.effects &= ~(EF_RED | EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT | EF_FLAME | EF_NODEPTHTEST);
1406
1407         if((this.alpha < 0 || IS_DEAD(this)) && !this.vehicle) // don't apply the flags if the player is gibbed
1408                 return;
1409
1410         Fire_ApplyDamage(this);
1411         Fire_ApplyEffect(this);
1412
1413         if (!MUTATOR_IS_ENABLED(mutator_instagib))
1414         {
1415                 if (this.items & ITEM_Strength.m_itemid)
1416                 {
1417                         play_countdown(this, this.strength_finished, SND_POWEROFF);
1418                         this.effects = this.effects | (EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT);
1419                         if (time > this.strength_finished)
1420                         {
1421                                 this.items = this.items - (this.items & ITEM_Strength.m_itemid);
1422                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERDOWN_STRENGTH, this.netname);
1423                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERDOWN_STRENGTH);
1424                         }
1425                 }
1426                 else
1427                 {
1428                         if (time < this.strength_finished)
1429                         {
1430                                 this.items = this.items | ITEM_Strength.m_itemid;
1431                                 if(!g_cts)
1432                                         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERUP_STRENGTH, this.netname);
1433                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERUP_STRENGTH);
1434                         }
1435                 }
1436                 if (this.items & ITEM_Shield.m_itemid)
1437                 {
1438                         play_countdown(this, this.invincible_finished, SND_POWEROFF);
1439                         this.effects = this.effects | (EF_RED | EF_ADDITIVE | EF_FULLBRIGHT);
1440                         if (time > this.invincible_finished)
1441                         {
1442                                 this.items = this.items - (this.items & ITEM_Shield.m_itemid);
1443                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERDOWN_SHIELD, this.netname);
1444                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERDOWN_SHIELD);
1445                         }
1446                 }
1447                 else
1448                 {
1449                         if (time < this.invincible_finished)
1450                         {
1451                                 this.items = this.items | ITEM_Shield.m_itemid;
1452                                 if(!g_cts)
1453                                         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERUP_SHIELD, this.netname);
1454                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERUP_SHIELD);
1455                         }
1456                 }
1457                 if (this.items & IT_SUPERWEAPON)
1458                 {
1459                         if (!(STAT(WEAPONS, this) & WEPSET_SUPERWEAPONS))
1460                         {
1461                                 this.superweapons_finished = 0;
1462                                 this.items = this.items - (this.items & IT_SUPERWEAPON);
1463                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_LOST, this.netname);
1464                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_LOST);
1465                         }
1466                         else if (this.items & IT_UNLIMITED_SUPERWEAPONS)
1467                         {
1468                                 // don't let them run out
1469                         }
1470                         else
1471                         {
1472                                 play_countdown(this, this.superweapons_finished, SND_POWEROFF);
1473                                 if (time > this.superweapons_finished)
1474                                 {
1475                                         this.items = this.items - (this.items & IT_SUPERWEAPON);
1476                                         STAT(WEAPONS, this) &= ~WEPSET_SUPERWEAPONS;
1477                                         //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_BROKEN, this.netname);
1478                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_BROKEN);
1479                                 }
1480                         }
1481                 }
1482                 else if(STAT(WEAPONS, this) & WEPSET_SUPERWEAPONS)
1483                 {
1484                         if (time < this.superweapons_finished || (this.items & IT_UNLIMITED_SUPERWEAPONS))
1485                         {
1486                                 this.items = this.items | IT_SUPERWEAPON;
1487                                 if(!(this.items & IT_UNLIMITED_SUPERWEAPONS))
1488                                 {
1489                                         if(!g_cts)
1490                                                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_PICKUP, this.netname);
1491                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_PICKUP);
1492                                 }
1493                         }
1494                         else
1495                         {
1496                                 this.superweapons_finished = 0;
1497                                 STAT(WEAPONS, this) &= ~WEPSET_SUPERWEAPONS;
1498                         }
1499                 }
1500                 else
1501                 {
1502                         this.superweapons_finished = 0;
1503                 }
1504         }
1505
1506         if(autocvar_g_nodepthtestplayers)
1507                 this.effects = this.effects | EF_NODEPTHTEST;
1508
1509         if(autocvar_g_fullbrightplayers)
1510                 this.effects = this.effects | EF_FULLBRIGHT;
1511
1512         if (time >= game_starttime)
1513         if (time < this.spawnshieldtime)
1514                 this.effects = this.effects | (EF_ADDITIVE | EF_FULLBRIGHT);
1515
1516         MUTATOR_CALLHOOK(PlayerPowerups, this, items_prev);
1517 }
1518
1519 float CalcRegen(float current, float stable, float regenfactor, float regenframetime)
1520 {
1521         if(current > stable)
1522                 return current;
1523         else if(current > stable - 0.25) // when close enough, "snap"
1524                 return stable;
1525         else
1526                 return min(stable, current + (stable - current) * regenfactor * regenframetime);
1527 }
1528
1529 float CalcRot(float current, float stable, float rotfactor, float rotframetime)
1530 {
1531         if(current < stable)
1532                 return current;
1533         else if(current < stable + 0.25) // when close enough, "snap"
1534                 return stable;
1535         else
1536                 return max(stable, current + (stable - current) * rotfactor * rotframetime);
1537 }
1538
1539 float CalcRotRegen(float current, float regenstable, float regenfactor, float regenlinear, float regenframetime, float rotstable, float rotfactor, float rotlinear, float rotframetime, float limit)
1540 {
1541         if(current > rotstable)
1542         {
1543                 if(rotframetime > 0)
1544                 {
1545                         current = CalcRot(current, rotstable, rotfactor, rotframetime);
1546                         current = max(rotstable, current - rotlinear * rotframetime);
1547                 }
1548         }
1549         else if(current < regenstable)
1550         {
1551                 if(regenframetime > 0)
1552                 {
1553                         current = CalcRegen(current, regenstable, regenfactor, regenframetime);
1554                         current = min(regenstable, current + regenlinear * regenframetime);
1555                 }
1556         }
1557
1558         if(current > limit)
1559                 current = limit;
1560
1561         return current;
1562 }
1563
1564 void player_regen(entity this)
1565 {
1566         float max_mod, regen_mod, rot_mod, limit_mod;
1567         max_mod = regen_mod = rot_mod = limit_mod = 1;
1568
1569         float regen_health = autocvar_g_balance_health_regen;
1570         float regen_health_linear = autocvar_g_balance_health_regenlinear;
1571         float regen_health_rot = autocvar_g_balance_health_rot;
1572         float regen_health_rotlinear = autocvar_g_balance_health_rotlinear;
1573         float regen_health_stable = autocvar_g_balance_health_regenstable;
1574         float regen_health_rotstable = autocvar_g_balance_health_rotstable;
1575         bool mutator_returnvalue = MUTATOR_CALLHOOK(PlayerRegen, this, max_mod, regen_mod, rot_mod, limit_mod, regen_health, regen_health_linear, regen_health_rot,
1576                 regen_health_rotlinear, regen_health_stable, regen_health_rotstable);
1577         max_mod = M_ARGV(1, float);
1578         regen_mod = M_ARGV(2, float);
1579         rot_mod = M_ARGV(3, float);
1580         limit_mod = M_ARGV(4, float);
1581         regen_health = M_ARGV(5, float);
1582         regen_health_linear = M_ARGV(6, float);
1583         regen_health_rot = M_ARGV(7, float);
1584         regen_health_rotlinear = M_ARGV(8, float);
1585         regen_health_stable = M_ARGV(9, float);
1586         regen_health_rotstable = M_ARGV(10, float);
1587
1588         if(!mutator_returnvalue)
1589         if(!STAT(FROZEN, this))
1590         {
1591                 float mina, maxa, limith, limita;
1592                 maxa = autocvar_g_balance_armor_rotstable;
1593                 mina = autocvar_g_balance_armor_regenstable;
1594                 limith = GetResourceLimit(this, RES_HEALTH);
1595                 limita = GetResourceLimit(this, RES_ARMOR);
1596
1597                 regen_health_rotstable = regen_health_rotstable * max_mod;
1598                 regen_health_stable = regen_health_stable * max_mod;
1599                 limith = limith * limit_mod;
1600                 limita = limita * limit_mod;
1601
1602                 SetResource(this, RES_ARMOR, CalcRotRegen(GetResource(this, RES_ARMOR), mina, autocvar_g_balance_armor_regen, autocvar_g_balance_armor_regenlinear,
1603                                                                         regen_mod * frametime * (time > this.pauseregen_finished), maxa, autocvar_g_balance_armor_rot, autocvar_g_balance_armor_rotlinear,
1604                                                                         rot_mod * frametime * (time > this.pauserotarmor_finished), limita));
1605                 SetResource(this, RES_HEALTH, CalcRotRegen(GetResource(this, RES_HEALTH), regen_health_stable, regen_health, regen_health_linear,
1606                                                                         regen_mod * frametime * (time > this.pauseregen_finished), regen_health_rotstable, regen_health_rot, regen_health_rotlinear,
1607                                                                         rot_mod * frametime * (time > this.pauserothealth_finished), limith));
1608         }
1609
1610         // if player rotted to death...  die!
1611         // check this outside above checks, as player may still be able to rot to death
1612         if(GetResource(this, RES_HEALTH) < 1)
1613         {
1614                 if(this.vehicle)
1615                         vehicles_exit(this.vehicle, VHEF_RELEASE);
1616                 if(this.event_damage)
1617                         this.event_damage(this, this, this, 1, DEATH_ROT.m_id, DMG_NOWEP, this.origin, '0 0 0');
1618         }
1619
1620         if (!(this.items & IT_UNLIMITED_AMMO))
1621         {
1622                 float minf, maxf, limitf;
1623
1624                 maxf = autocvar_g_balance_fuel_rotstable;
1625                 minf = autocvar_g_balance_fuel_regenstable;
1626                 limitf = GetResourceLimit(this, RES_FUEL);
1627
1628                 SetResource(this, RES_FUEL, CalcRotRegen(GetResource(this, RES_FUEL), minf, autocvar_g_balance_fuel_regen, autocvar_g_balance_fuel_regenlinear,
1629                                                                                 frametime * (time > this.pauseregen_finished) * ((this.items & ITEM_JetpackRegen.m_itemid) != 0),
1630                                                                                 maxf, autocvar_g_balance_fuel_rot, autocvar_g_balance_fuel_rotlinear, frametime * (time > this.pauserotfuel_finished), limitf));
1631         }
1632 }
1633
1634 bool zoomstate_set;
1635 void SetZoomState(entity this, float newzoom)
1636 {
1637         if(newzoom != CS(this).zoomstate)
1638         {
1639                 CS(this).zoomstate = newzoom;
1640                 ClientData_Touch(this);
1641         }
1642         zoomstate_set = true;
1643 }
1644
1645 void GetPressedKeys(entity this)
1646 {
1647         MUTATOR_CALLHOOK(GetPressedKeys, this);
1648         int keys = STAT(PRESSED_KEYS, this);
1649         keys = BITSET(keys, KEY_FORWARD,        CS(this).movement.x > 0);
1650         keys = BITSET(keys, KEY_BACKWARD,       CS(this).movement.x < 0);
1651         keys = BITSET(keys, KEY_RIGHT,          CS(this).movement.y > 0);
1652         keys = BITSET(keys, KEY_LEFT,           CS(this).movement.y < 0);
1653
1654         keys = BITSET(keys, KEY_JUMP,           PHYS_INPUT_BUTTON_JUMP(this));
1655         keys = BITSET(keys, KEY_CROUCH,         IS_DUCKED(this)); // workaround: player can't un-crouch until their path is clear, so we keep the button held here
1656         keys = BITSET(keys, KEY_ATCK,           PHYS_INPUT_BUTTON_ATCK(this));
1657         keys = BITSET(keys, KEY_ATCK2,          PHYS_INPUT_BUTTON_ATCK2(this));
1658         CS(this).pressedkeys = keys; // store for other users
1659
1660         STAT(PRESSED_KEYS, this) = keys;
1661 }
1662
1663 /*
1664 ======================
1665 spectate mode routines
1666 ======================
1667 */
1668
1669 void SpectateCopy(entity this, entity spectatee)
1670 {
1671         TC(Client, this); TC(Client, spectatee);
1672
1673         MUTATOR_CALLHOOK(SpectateCopy, spectatee, this);
1674         PS(this) = PS(spectatee);
1675         this.armortype = spectatee.armortype;
1676         SetResourceExplicit(this, RES_ARMOR, GetResource(spectatee, RES_ARMOR));
1677         SetResourceExplicit(this, RES_CELLS, GetResource(spectatee, RES_CELLS));
1678         SetResourceExplicit(this, RES_PLASMA, GetResource(spectatee, RES_PLASMA));
1679         SetResourceExplicit(this, RES_SHELLS, GetResource(spectatee, RES_SHELLS));
1680         SetResourceExplicit(this, RES_BULLETS, GetResource(spectatee, RES_BULLETS));
1681         SetResourceExplicit(this, RES_ROCKETS, GetResource(spectatee, RES_ROCKETS));
1682         SetResourceExplicit(this, RES_FUEL, GetResource(spectatee, RES_FUEL));
1683         this.effects = spectatee.effects & EFMASK_CHEAP; // eat performance
1684         SetResourceExplicit(this, RES_HEALTH, GetResource(spectatee, RES_HEALTH));
1685         CS(this).impulse = 0;
1686         this.disableclientprediction = 1; // no need to run prediction on a spectator
1687         this.items = spectatee.items;
1688         STAT(LAST_PICKUP, this) = STAT(LAST_PICKUP, spectatee);
1689         STAT(HIT_TIME, this) = STAT(HIT_TIME, spectatee);
1690         this.strength_finished = spectatee.strength_finished;
1691         this.invincible_finished = spectatee.invincible_finished;
1692         this.superweapons_finished = spectatee.superweapons_finished;
1693         STAT(PRESSED_KEYS, this) = STAT(PRESSED_KEYS, spectatee);
1694         STAT(WEAPONS, this) = STAT(WEAPONS, spectatee);
1695         this.punchangle = spectatee.punchangle;
1696         this.view_ofs = spectatee.view_ofs;
1697         this.velocity = spectatee.velocity;
1698         this.dmg_take = spectatee.dmg_take;
1699         this.dmg_save = spectatee.dmg_save;
1700         this.dmg_inflictor = spectatee.dmg_inflictor;
1701         this.v_angle = spectatee.v_angle;
1702         this.angles = spectatee.v_angle;
1703         STAT(FROZEN, this) = STAT(FROZEN, spectatee);
1704         STAT(REVIVE_PROGRESS, this) = STAT(REVIVE_PROGRESS, spectatee);
1705         this.viewloc = spectatee.viewloc;
1706         if(!PHYS_INPUT_BUTTON_USE(this) && STAT(CAMERA_SPECTATOR, this) != 2)
1707                 this.fixangle = true;
1708         setorigin(this, spectatee.origin);
1709         setsize(this, spectatee.mins, spectatee.maxs);
1710         SetZoomState(this, CS(spectatee).zoomstate);
1711
1712     anticheat_spectatecopy(this, spectatee);
1713         STAT(HUD, this) = STAT(HUD, spectatee);
1714         if(spectatee.vehicle)
1715     {
1716         this.angles = spectatee.v_angle;
1717
1718         //this.fixangle = false;
1719         //this.velocity = spectatee.vehicle.velocity;
1720         this.vehicle_health = spectatee.vehicle_health;
1721         this.vehicle_shield = spectatee.vehicle_shield;
1722         this.vehicle_energy = spectatee.vehicle_energy;
1723         this.vehicle_ammo1 = spectatee.vehicle_ammo1;
1724         this.vehicle_ammo2 = spectatee.vehicle_ammo2;
1725         this.vehicle_reload1 = spectatee.vehicle_reload1;
1726         this.vehicle_reload2 = spectatee.vehicle_reload2;
1727
1728         //msg_entity = this;
1729
1730        // WriteByte (MSG_ONE, SVC_SETVIEWANGLES);
1731             //WriteAngle(MSG_ONE,  spectatee.v_angle.x);
1732            // WriteAngle(MSG_ONE,  spectatee.v_angle.y);
1733            // WriteAngle(MSG_ONE,  spectatee.v_angle.z);
1734
1735         //WriteByte (MSG_ONE, SVC_SETVIEW);
1736         //    WriteEntity(MSG_ONE, this);
1737         //makevectors(spectatee.v_angle);
1738         //setorigin(this, spectatee.origin - v_forward * 400 + v_up * 300);*/
1739     }
1740 }
1741
1742 bool SpectateUpdate(entity this)
1743 {
1744         if(!this.enemy)
1745                 return false;
1746
1747         if(!IS_PLAYER(this.enemy) || this == this.enemy)
1748         {
1749                 SetSpectatee(this, NULL);
1750                 return false;
1751         }
1752
1753         SpectateCopy(this, this.enemy);
1754
1755         return true;
1756 }
1757
1758 bool SpectateSet(entity this)
1759 {
1760         if(!IS_PLAYER(this.enemy))
1761                 return false;
1762
1763         ClientData_Touch(this.enemy);
1764
1765         msg_entity = this;
1766         WriteByte(MSG_ONE, SVC_SETVIEW);
1767         WriteEntity(MSG_ONE, this.enemy);
1768         set_movetype(this, MOVETYPE_NONE);
1769         accuracy_resend(this);
1770
1771         if(!SpectateUpdate(this))
1772                 PutObserverInServer(this);
1773
1774         return true;
1775 }
1776
1777 void SetSpectatee_status(entity this, int spectatee_num)
1778 {
1779         int oldspectatee_status = CS(this).spectatee_status;
1780         CS(this).spectatee_status = spectatee_num;
1781
1782         if (CS(this).spectatee_status != oldspectatee_status)
1783         {
1784                 if (STAT(PRESSED_KEYS, this))
1785                 {
1786                         CS(this).pressedkeys = 0;
1787                         STAT(PRESSED_KEYS, this) = 0;
1788                 }
1789                 ClientData_Touch(this);
1790                 if (g_race || g_cts) race_InitSpectator();
1791         }
1792 }
1793
1794 void SetSpectatee(entity this, entity spectatee)
1795 {
1796         if(IS_BOT_CLIENT(this))
1797                 return; // bots abuse .enemy, this code is useless to them
1798
1799         entity old_spectatee = this.enemy;
1800
1801         this.enemy = spectatee;
1802
1803         // WEAPONTODO
1804         // these are required to fix the spectator bug with arc
1805         if(old_spectatee)
1806         {
1807                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1808                 {
1809                         .entity weaponentity = weaponentities[slot];
1810                         if(old_spectatee.(weaponentity).arc_beam)
1811                                 old_spectatee.(weaponentity).arc_beam.SendFlags |= ARC_SF_SETTINGS;
1812                 }
1813         }
1814         if(this.enemy)
1815         {
1816                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1817                 {
1818                         .entity weaponentity = weaponentities[slot];
1819                         if(this.enemy.(weaponentity).arc_beam)
1820                                 this.enemy.(weaponentity).arc_beam.SendFlags |= ARC_SF_SETTINGS;
1821                 }
1822         }
1823
1824         if (this.enemy)
1825                 SetSpectatee_status(this, etof(this.enemy));
1826
1827         // needed to update spectator list
1828         if(old_spectatee) { ClientData_Touch(old_spectatee); }
1829 }
1830
1831 bool Spectate(entity this, entity pl)
1832 {
1833         if(MUTATOR_CALLHOOK(SpectateSet, this, pl))
1834                 return false;
1835         pl = M_ARGV(1, entity);
1836
1837         SetSpectatee(this, pl);
1838         return SpectateSet(this);
1839 }
1840
1841 bool SpectateNext(entity this)
1842 {
1843         entity ent = find(this.enemy, classname, STR_PLAYER);
1844
1845         if (MUTATOR_CALLHOOK(SpectateNext, this, ent))
1846                 ent = M_ARGV(1, entity);
1847         else if (!ent)
1848                 ent = find(ent, classname, STR_PLAYER);
1849
1850         if(ent) { SetSpectatee(this, ent); }
1851
1852         return SpectateSet(this);
1853 }
1854
1855 bool SpectatePrev(entity this)
1856 {
1857         // NOTE: chain order is from the highest to the lower entnum (unlike find)
1858         entity ent = findchain(classname, STR_PLAYER);
1859         if (!ent) // no player
1860                 return false;
1861
1862         entity first = ent;
1863         // skip players until current spectated player
1864         if(this.enemy)
1865         while(ent && ent != this.enemy)
1866                 ent = ent.chain;
1867
1868         switch (MUTATOR_CALLHOOK(SpectatePrev, this, ent, first))
1869         {
1870                 case MUT_SPECPREV_FOUND:
1871                     ent = M_ARGV(1, entity);
1872                     break;
1873                 case MUT_SPECPREV_RETURN:
1874                     return true;
1875                 case MUT_SPECPREV_CONTINUE:
1876                 default:
1877                 {
1878                         if(ent.chain)
1879                                 ent = ent.chain;
1880                         else
1881                                 ent = first;
1882                         break;
1883                 }
1884         }
1885
1886         SetSpectatee(this, ent);
1887         return SpectateSet(this);
1888 }
1889
1890 /*
1891 =============
1892 ShowRespawnCountdown()
1893
1894 Update a respawn countdown display.
1895 =============
1896 */
1897 void ShowRespawnCountdown(entity this)
1898 {
1899         float number;
1900         if(!IS_DEAD(this)) // just respawned?
1901                 return;
1902         else
1903         {
1904                 number = ceil(this.respawn_time - time);
1905                 if(number <= 0)
1906                         return;
1907                 if(number <= this.respawn_countdown)
1908                 {
1909                         this.respawn_countdown = number - 1;
1910                         if(ceil(this.respawn_time - (time + 0.5)) == number) // only say it if it is the same number even in 0.5s; to prevent overlapping sounds
1911                                 { Send_Notification(NOTIF_ONE, this, MSG_ANNCE, Announcer_PickNumber(CNT_RESPAWN, number)); }
1912                 }
1913         }
1914 }
1915
1916 .bool team_selected;
1917 bool ShowTeamSelection(entity this)
1918 {
1919         if (!teamplay || autocvar_g_campaign || autocvar_g_balance_teams || this.team_selected || (CS(this).wasplayer && autocvar_g_changeteam_banned) || Player_HasRealForcedTeam(this))
1920                 return false;
1921         stuffcmd(this, "menu_showteamselect\n");
1922         return true;
1923 }
1924 void Join(entity this)
1925 {
1926         TRANSMUTE(Player, this);
1927
1928         if(!this.team_selected)
1929         if(autocvar_g_campaign || autocvar_g_balance_teams)
1930                 TeamBalance_JoinBestTeam(this);
1931
1932         if(autocvar_g_campaign)
1933                 campaign_bots_may_start = true;
1934
1935         Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_PREVENT_JOIN);
1936
1937         PutClientInServer(this);
1938
1939         if(IS_PLAYER(this))
1940         if(teamplay && this.team != -1)
1941         {
1942         }
1943         else
1944                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_JOIN_PLAY, this.netname);
1945         this.team_selected = false;
1946 }
1947
1948 int GetPlayerLimit()
1949 {
1950         int player_limit = autocvar_g_maxplayers;
1951         MUTATOR_CALLHOOK(GetPlayerLimit, player_limit);
1952         player_limit = M_ARGV(0, int);
1953         return player_limit;
1954 }
1955
1956 /**
1957  * Determines whether the player is allowed to join. This depends on cvar
1958  * g_maxplayers, if it isn't used this function always return true, otherwise
1959  * it checks whether the number of currently playing players exceeds g_maxplayers.
1960  * @return int number of free slots for players, 0 if none
1961  */
1962 int nJoinAllowed(entity this, entity ignore)
1963 {
1964         if(!ignore)
1965         // this is called that way when checking if anyone may be able to join (to build qcstatus)
1966         // so report 0 free slots if restricted
1967         {
1968                 if(autocvar_g_forced_team_otherwise == "spectate")
1969                         return 0;
1970                 if(autocvar_g_forced_team_otherwise == "spectator")
1971                         return 0;
1972         }
1973
1974         if(this && (Player_GetForcedTeamIndex(this) == TEAM_FORCE_SPECTATOR))
1975                 return 0; // forced spectators can never join
1976
1977         // TODO simplify this
1978         int totalClients = 0;
1979         int currentlyPlaying = 0;
1980         FOREACH_CLIENT(true, {
1981                 if(it != ignore)
1982                         ++totalClients;
1983                 if(IS_REAL_CLIENT(it))
1984                 if(IS_PLAYER(it) || it.caplayer)
1985                         ++currentlyPlaying;
1986         });
1987
1988         int player_limit = GetPlayerLimit();
1989
1990         float free_slots = 0;
1991         if (!player_limit)
1992                 free_slots = maxclients - totalClients;
1993         else if(currentlyPlaying < player_limit)
1994                 free_slots = min(maxclients - totalClients, player_limit - currentlyPlaying);
1995
1996         static float join_prevent_msg_time = 0;
1997         if(this && ignore && !free_slots && time > join_prevent_msg_time)
1998         {
1999                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_JOIN_PREVENT);
2000                 join_prevent_msg_time = time + 3;
2001         }
2002
2003         return free_slots;
2004 }
2005
2006 /**
2007  * Checks whether the client is an observer or spectator, if so, he will get kicked after
2008  * g_maxplayers_spectator_blocktime seconds
2009  */
2010 void checkSpectatorBlock(entity this)
2011 {
2012         if(IS_SPEC(this) || IS_OBSERVER(this))
2013         if(!this.caplayer)
2014         if(IS_REAL_CLIENT(this))
2015         {
2016                 if( time > (CS(this).spectatortime + autocvar_g_maxplayers_spectator_blocktime) ) {
2017                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_QUIT_KICK_SPECTATING);
2018                         dropclient(this);
2019                 }
2020         }
2021 }
2022
2023 void PrintWelcomeMessage(entity this)
2024 {
2025         if(CS(this).motd_actived_time == 0)
2026         {
2027                 if (autocvar_g_campaign) {
2028                         if ((IS_PLAYER(this) && PHYS_INPUT_BUTTON_INFO(this)) || (!IS_PLAYER(this))) {
2029                                 CS(this).motd_actived_time = time;
2030                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_CAMPAIGN_MESSAGE, Campaign_GetMessage(), Campaign_GetLevelNum());
2031                         }
2032                 } else {
2033                         if (PHYS_INPUT_BUTTON_INFO(this)) {
2034                                 CS(this).motd_actived_time = time;
2035                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOTD, getwelcomemessage(this));
2036                         }
2037                 }
2038         }
2039         else if(CS(this).motd_actived_time > 0) // showing MOTD or campaign message
2040         {
2041                 if (autocvar_g_campaign) {
2042                         if (PHYS_INPUT_BUTTON_INFO(this))
2043                                 CS(this).motd_actived_time = time;
2044                         else if ((time - CS(this).motd_actived_time > 2) && IS_PLAYER(this)) { // hide it some seconds after BUTTON_INFO has been released
2045                                 CS(this).motd_actived_time = 0;
2046                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_CAMPAIGN_MESSAGE);
2047                         }
2048                 } else {
2049                         if (PHYS_INPUT_BUTTON_INFO(this))
2050                                 CS(this).motd_actived_time = time;
2051                         else if (time - CS(this).motd_actived_time > 2) { // hide it some seconds after BUTTON_INFO has been released
2052                                 CS(this).motd_actived_time = 0;
2053                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_MOTD);
2054                         }
2055                 }
2056         }
2057         else //if(CS(this).motd_actived_time < 0) // just connected, motd is active
2058         {
2059                 if(PHYS_INPUT_BUTTON_INFO(this)) // BUTTON_INFO hides initial MOTD
2060                         CS(this).motd_actived_time = -2; // wait until BUTTON_INFO gets released
2061                 else if (CS(this).motd_actived_time == -2)
2062                 {
2063                         // instantly hide MOTD
2064                         CS(this).motd_actived_time = 0;
2065                         if (autocvar_g_campaign)
2066                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_CAMPAIGN_MESSAGE);
2067                         else
2068                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_MOTD);
2069                 }
2070                 else if (IS_PLAYER(this) || IS_SPEC(this))
2071                 {
2072                         // FIXME occasionally for some reason MOTD never goes away
2073                         // delay MOTD removal a little bit in the hope it fixes this bug
2074                         if (CS(this).motd_actived_time == -1) // MOTD marked to fade away as soon as client becomes player or spectator
2075                                 CS(this).motd_actived_time = -(5 + floor(random() * 10)); // add small delay
2076                         else //if (CS(this).motd_actived_time < -2)
2077                                 CS(this).motd_actived_time++;
2078                 }
2079         }
2080 }
2081
2082 const int MIN_SPEC_TIME = 1;
2083 bool joinAllowed(entity this)
2084 {
2085         if (CS(this).version_mismatch) return false;
2086         if (time < CS(this).jointime + MIN_SPEC_TIME) return false;
2087         if (!nJoinAllowed(this, this)) return false;
2088         if (teamplay && lockteams) return false;
2089         if (MUTATOR_CALLHOOK(ForbidSpawn, this)) return false;
2090         if (ShowTeamSelection(this)) return false;
2091         return true;
2092 }
2093
2094 .int items_added;
2095 .string shootfromfixedorigin;
2096 .bool dualwielding_prev;
2097 bool PlayerThink(entity this)
2098 {
2099         if (game_stopped || intermission_running) {
2100                 this.modelflags &= ~MF_ROCKET;
2101                 if(intermission_running)
2102                         IntermissionThink(this);
2103                 return false;
2104         }
2105
2106         if (timeout_status == TIMEOUT_ACTIVE) {
2107         // don't allow the player to turn around while game is paused
2108                 // FIXME turn this into CSQC stuff
2109                 this.v_angle = this.lastV_angle;
2110                 this.angles = this.lastV_angle;
2111                 this.fixangle = true;
2112         }
2113
2114         if (frametime) player_powerups(this);
2115
2116         if (IS_DEAD(this)) {
2117                 if (this.personal && g_race_qualifying) {
2118                         if (time > this.respawn_time) {
2119                                 STAT(RESPAWN_TIME, this) = this.respawn_time = time + 1; // only retry once a second
2120                                 respawn(this);
2121                                 CS(this).impulse = CHIMPULSE_SPEEDRUN.impulse;
2122                         }
2123                 } else {
2124                         if (frametime) player_anim(this);
2125
2126                         if (this.respawn_flags & RESPAWN_DENY)
2127                         {
2128                                 STAT(RESPAWN_TIME, this) = 0;
2129                                 return false;
2130                         }
2131
2132                         bool button_pressed = (PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_JUMP(this) || PHYS_INPUT_BUTTON_ATCK2(this) || PHYS_INPUT_BUTTON_HOOK(this) || PHYS_INPUT_BUTTON_USE(this));
2133
2134                         switch(this.deadflag)
2135                         {
2136                                 case DEAD_DYING:
2137                                 {
2138                                         if ((this.respawn_flags & RESPAWN_FORCE) && !(this.respawn_time < this.respawn_time_max))
2139                                                 this.deadflag = DEAD_RESPAWNING;
2140                                         else if (!button_pressed || (time >= this.respawn_time_max && (this.respawn_flags & RESPAWN_FORCE)))
2141                                                 this.deadflag = DEAD_DEAD;
2142                                         break;
2143                                 }
2144                                 case DEAD_DEAD:
2145                                 {
2146                                         if (button_pressed)
2147                                                 this.deadflag = DEAD_RESPAWNABLE;
2148                                         else if (time >= this.respawn_time_max && (this.respawn_flags & RESPAWN_FORCE))
2149                                                 this.deadflag = DEAD_RESPAWNING;
2150                                         break;
2151                                 }
2152                                 case DEAD_RESPAWNABLE:
2153                                 {
2154                                         if (!button_pressed || (this.respawn_flags & RESPAWN_FORCE))
2155                                                 this.deadflag = DEAD_RESPAWNING;
2156                                         break;
2157                                 }
2158                                 case DEAD_RESPAWNING:
2159                                 {
2160                                         if (time > this.respawn_time)
2161                                         {
2162                                                 this.respawn_time = time + 1; // only retry once a second
2163                                                 this.respawn_time_max = this.respawn_time;
2164                                                 respawn(this);
2165                                         }
2166                                         break;
2167                                 }
2168                         }
2169
2170                         ShowRespawnCountdown(this);
2171
2172                         if (this.respawn_flags & RESPAWN_SILENT)
2173                                 STAT(RESPAWN_TIME, this) = 0;
2174                         else if ((this.respawn_flags & RESPAWN_FORCE) && this.respawn_time < this.respawn_time_max)
2175                         {
2176                                 if (time < this.respawn_time)
2177                                         STAT(RESPAWN_TIME, this) = this.respawn_time;
2178                                 else if (this.deadflag != DEAD_RESPAWNING)
2179                                         STAT(RESPAWN_TIME, this) = -this.respawn_time_max;
2180                         }
2181                         else
2182                                 STAT(RESPAWN_TIME, this) = this.respawn_time;
2183                 }
2184
2185                 // if respawning, invert stat_respawn_time to indicate this, the client translates it
2186                 if (this.deadflag == DEAD_RESPAWNING && STAT(RESPAWN_TIME, this) > 0)
2187                         STAT(RESPAWN_TIME, this) *= -1;
2188
2189                 return false;
2190         }
2191
2192         FixPlayermodel(this);
2193
2194         if (this.shootfromfixedorigin != autocvar_g_shootfromfixedorigin) {
2195                 this.shootfromfixedorigin = autocvar_g_shootfromfixedorigin;
2196                 stuffcmd(this, sprintf("\ncl_shootfromfixedorigin \"%s\"\n", autocvar_g_shootfromfixedorigin));
2197         }
2198
2199         // reset gun alignment when dual wielding status changes
2200         // to ensure guns are always aligned right and left
2201         bool dualwielding = W_DualWielding(this);
2202         if(this.dualwielding_prev != dualwielding)
2203         {
2204                 W_ResetGunAlign(this, CS(this).cvar_cl_gunalign);
2205                 this.dualwielding_prev = dualwielding;
2206         }
2207
2208         // LordHavoc: allow firing on move frames (sub-ticrate), this gives better timing on slow servers
2209         //if(frametime)
2210         {
2211                 this.items &= ~this.items_added;
2212
2213                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2214                 {
2215                         .entity weaponentity = weaponentities[slot];
2216                         if(WEP_CVAR(vortex, charge_always))
2217                                 W_Vortex_Charge(this, weaponentity, frametime);
2218                         W_WeaponFrame(this, weaponentity);
2219                 }
2220
2221                 this.items_added = 0;
2222                 if ((this.items & ITEM_Jetpack.m_itemid) && ((this.items & ITEM_JetpackRegen.m_itemid) || GetResource(this, RES_FUEL) >= 0.01))
2223             this.items_added |= IT_FUEL;
2224
2225                 this.items |= this.items_added;
2226         }
2227
2228         if (frametime)
2229         {
2230                 // WEAPONTODO: Add a weapon request for this
2231                 // rot vortex charge to the charge limit
2232                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2233                 {
2234                         .entity weaponentity = weaponentities[slot];
2235                         if (WEP_CVAR(vortex, charge_rot_rate) && this.(weaponentity).vortex_charge > WEP_CVAR(vortex, charge_limit) && this.(weaponentity).vortex_charge_rottime < time)
2236                                 this.(weaponentity).vortex_charge = bound(WEP_CVAR(vortex, charge_limit), this.(weaponentity).vortex_charge - WEP_CVAR(vortex, charge_rot_rate) * frametime / W_TICSPERFRAME, 1);
2237                 }
2238
2239                 player_regen(this);
2240                 player_anim(this);
2241                 this.dmg_team = max(0, this.dmg_team - autocvar_g_teamdamage_resetspeed * frametime);
2242         }
2243
2244         secrets_setstatus(this);
2245         monsters_setstatus(this);
2246
2247         return true;
2248 }
2249
2250 .bool would_spectate;
2251 void ObserverThink(entity this)
2252 {
2253         if ( CS(this).impulse )
2254         {
2255                 MinigameImpulse(this, CS(this).impulse);
2256                 CS(this).impulse = 0;
2257         }
2258
2259         if (this.flags & FL_JUMPRELEASED) {
2260                 if (PHYS_INPUT_BUTTON_JUMP(this) && joinAllowed(this)) {
2261                         this.flags &= ~FL_JUMPRELEASED;
2262                         this.flags |= FL_SPAWNING;
2263                 } else if(PHYS_INPUT_BUTTON_ATCK(this) && !CS(this).version_mismatch || this.would_spectate) {
2264                         this.flags &= ~FL_JUMPRELEASED;
2265                         if(SpectateNext(this)) {
2266                                 TRANSMUTE(Spectator, this);
2267                         }
2268                 } else {
2269                         int preferred_movetype = ((!PHYS_INPUT_BUTTON_USE(this) ? CS(this).cvar_cl_clippedspectating : !CS(this).cvar_cl_clippedspectating) ? MOVETYPE_FLY_WORLDONLY : MOVETYPE_NOCLIP);
2270                         set_movetype(this, preferred_movetype);
2271                 }
2272         } else {
2273                 if (!(PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_JUMP(this))) {
2274                         this.flags |= FL_JUMPRELEASED;
2275                         if(this.flags & FL_SPAWNING)
2276                         {
2277                                 this.flags &= ~FL_SPAWNING;
2278                                 Join(this);
2279                                 return;
2280                         }
2281                 }
2282         }
2283 }
2284
2285 void SpectatorThink(entity this)
2286 {
2287         if ( CS(this).impulse )
2288         {
2289                 if(MinigameImpulse(this, CS(this).impulse))
2290                         CS(this).impulse = 0;
2291
2292                 if (CS(this).impulse == IMP_weapon_drop.impulse)
2293                 {
2294                         STAT(CAMERA_SPECTATOR, this) = (STAT(CAMERA_SPECTATOR, this) + 1) % 3;
2295                         CS(this).impulse = 0;
2296                         return;
2297                 }
2298         }
2299
2300         if (this.flags & FL_JUMPRELEASED) {
2301                 if (PHYS_INPUT_BUTTON_JUMP(this) && joinAllowed(this)) {
2302                         this.flags &= ~FL_JUMPRELEASED;
2303                         this.flags |= FL_SPAWNING;
2304                 } else if(PHYS_INPUT_BUTTON_ATCK(this) || CS(this).impulse == 10 || CS(this).impulse == 15 || CS(this).impulse == 18 || (CS(this).impulse >= 200 && CS(this).impulse <= 209)) {
2305                         this.flags &= ~FL_JUMPRELEASED;
2306                         if(SpectateNext(this)) {
2307                                 TRANSMUTE(Spectator, this);
2308                         } else {
2309                                 TRANSMUTE(Observer, this);
2310                                 PutClientInServer(this);
2311                         }
2312                         CS(this).impulse = 0;
2313                 } else if(CS(this).impulse == 12 || CS(this).impulse == 16  || CS(this).impulse == 19 || (CS(this).impulse >= 220 && CS(this).impulse <= 229)) {
2314                         this.flags &= ~FL_JUMPRELEASED;
2315                         if(SpectatePrev(this)) {
2316                                 TRANSMUTE(Spectator, this);
2317                         } else {
2318                                 TRANSMUTE(Observer, this);
2319                                 PutClientInServer(this);
2320                         }
2321                         CS(this).impulse = 0;
2322                 } else if (PHYS_INPUT_BUTTON_ATCK2(this)) {
2323                         this.would_spectate = false;
2324                         this.flags &= ~FL_JUMPRELEASED;
2325                         TRANSMUTE(Observer, this);
2326                         PutClientInServer(this);
2327                 } else {
2328                         if(!SpectateUpdate(this))
2329                         {
2330                                 if(!SpectateNext(this))
2331                                 {
2332                                         PutObserverInServer(this);
2333                                         this.would_spectate = true;
2334                                 }
2335                         }
2336                 }
2337         } else {
2338                 if (!(PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_ATCK2(this))) {
2339                         this.flags |= FL_JUMPRELEASED;
2340                         if(this.flags & FL_SPAWNING)
2341                         {
2342                                 this.flags &= ~FL_SPAWNING;
2343                                 Join(this);
2344                                 return;
2345                         }
2346                 }
2347                 if(!SpectateUpdate(this))
2348                         PutObserverInServer(this);
2349         }
2350
2351         this.flags |= FL_CLIENT | FL_NOTARGET;
2352 }
2353
2354 void PlayerUseKey(entity this)
2355 {
2356         if (!IS_PLAYER(this))
2357                 return;
2358
2359         if(this.vehicle)
2360         {
2361                 if(!game_stopped)
2362                 {
2363                         vehicles_exit(this.vehicle, VHEF_NORMAL);
2364                         return;
2365                 }
2366         }
2367         else if(autocvar_g_vehicles_enter)
2368         {
2369                 if(!game_stopped && !STAT(FROZEN, this) && !IS_DEAD(this) && !IS_INDEPENDENT_PLAYER(this))
2370                 {
2371                         entity head, closest_target = NULL;
2372                         head = WarpZone_FindRadius(this.origin, autocvar_g_vehicles_enter_radius, true);
2373
2374                         while(head) // find the closest acceptable target to enter
2375                         {
2376                                 if(IS_VEHICLE(head) && !IS_DEAD(head) && head.takedamage != DAMAGE_NO)
2377                                 if(!head.owner || ((head.vehicle_flags & VHF_MULTISLOT) && SAME_TEAM(head.owner, this)))
2378                                 {
2379                                         if(closest_target)
2380                                         {
2381                                                 if(vlen2(this.origin - head.origin) < vlen2(this.origin - closest_target.origin))
2382                                                 { closest_target = head; }
2383                                         }
2384                                         else { closest_target = head; }
2385                                 }
2386
2387                                 head = head.chain;
2388                         }
2389
2390                         if(closest_target) { vehicles_enter(this, closest_target); return; }
2391                 }
2392         }
2393
2394         // a use key was pressed; call handlers
2395         MUTATOR_CALLHOOK(PlayerUseKey, this);
2396 }
2397
2398
2399 /*
2400 =============
2401 PlayerPreThink
2402
2403 Called every frame for each client before the physics are run
2404 =============
2405 */
2406 .float last_vehiclecheck;
2407 void PlayerPreThink (entity this)
2408 {
2409         STAT(GUNALIGN, this) = CS(this).cvar_cl_gunalign; // TODO
2410         STAT(MOVEVARS_CL_TRACK_CANJUMP, this) = CS(this).cvar_cl_movement_track_canjump;
2411
2412         WarpZone_PlayerPhysics_FixVAngle(this);
2413
2414         if (frametime) {
2415                 // physics frames: update anticheat stuff
2416                 anticheat_prethink(this);
2417         }
2418
2419         if (blockSpectators && frametime) {
2420                 // WORKAROUND: only use dropclient in server frames (frametime set).
2421                 // Never use it in cl_movement frames (frametime zero).
2422                 checkSpectatorBlock(this);
2423         }
2424
2425         zoomstate_set = false;
2426
2427         // Check for nameless players
2428         if (this.netname == "" || this.netname != CS(this).netname_previous)
2429         {
2430                 bool assume_unchanged = (CS(this).netname_previous == "");
2431                 if (autocvar_sv_name_maxlength > 0 && strlennocol(this.netname) > autocvar_sv_name_maxlength)
2432                 {
2433                         int new_length = textLengthUpToLength(this.netname, autocvar_sv_name_maxlength, strlennocol);
2434                         this.netname = strzone(strcat(substring(this.netname, 0, new_length), "^7"));
2435                         sprint(this, sprintf("Warning: your name is longer than %d characters, it has been truncated.\n", autocvar_sv_name_maxlength));
2436                         assume_unchanged = false;
2437                         // stuffcmd(this, strcat("name ", this.netname, "\n")); // maybe?
2438                 }
2439                 if (isInvisibleString(this.netname))
2440                 {
2441                         this.netname = strzone(sprintf("Player#%d", this.playerid));
2442                         sprint(this, "Warning: invisible names are not allowed.\n");
2443                         assume_unchanged = false;
2444                         // stuffcmd(this, strcat("name ", this.netname, "\n")); // maybe?
2445                 }
2446                 if (!assume_unchanged && autocvar_sv_eventlog)
2447                         GameLogEcho(strcat(":name:", ftos(this.playerid), ":", playername(this, false)));
2448                 strcpy(CS(this).netname_previous, this.netname);
2449         }
2450
2451         // version nagging
2452         if (CS(this).version_nagtime && CS(this).cvar_g_xonoticversion && time > CS(this).version_nagtime) {
2453         CS(this).version_nagtime = 0;
2454         if (strstrofs(CS(this).cvar_g_xonoticversion, "git", 0) >= 0 || strstrofs(CS(this).cvar_g_xonoticversion, "autobuild", 0) >= 0) {
2455             // git client
2456         } else if (strstrofs(autocvar_g_xonoticversion, "git", 0) >= 0 || strstrofs(autocvar_g_xonoticversion, "autobuild", 0) >= 0) {
2457             // git server
2458             Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_BETA, autocvar_g_xonoticversion, CS(this).cvar_g_xonoticversion);
2459         } else {
2460             int r = vercmp(CS(this).cvar_g_xonoticversion, autocvar_g_xonoticversion);
2461             if (r < 0) { // old client
2462                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_OUTDATED, autocvar_g_xonoticversion, CS(this).cvar_g_xonoticversion);
2463             } else if (r > 0) { // old server
2464                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_OLD, autocvar_g_xonoticversion, CS(this).cvar_g_xonoticversion);
2465             }
2466         }
2467     }
2468
2469         // GOD MODE info
2470         if (!(this.flags & FL_GODMODE) && this.max_armorvalue)
2471         {
2472                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_GODMODE_OFF, this.max_armorvalue);
2473                 this.max_armorvalue = 0;
2474         }
2475
2476         if (frametime && IS_PLAYER(this))
2477         {
2478                 if (STAT(FROZEN, this) == FROZEN_TEMP_REVIVING)
2479                 {
2480                         STAT(REVIVE_PROGRESS, this) = bound(0, STAT(REVIVE_PROGRESS, this) + frametime * this.revive_speed, 1);
2481                         SetResourceExplicit(this, RES_HEALTH, max(1, STAT(REVIVE_PROGRESS, this) * start_health));
2482                         this.iceblock.alpha = bound(0.2, 1 - STAT(REVIVE_PROGRESS, this), 1);
2483
2484                         if (STAT(REVIVE_PROGRESS, this) >= 1)
2485                                 Unfreeze(this, false);
2486                 }
2487                 else if (STAT(FROZEN, this) == FROZEN_TEMP_DYING)
2488                 {
2489                         STAT(REVIVE_PROGRESS, this) = bound(0, STAT(REVIVE_PROGRESS, this) - frametime * this.revive_speed, 1);
2490                         SetResourceExplicit(this, RES_HEALTH, max(0, autocvar_g_nades_ice_health + (start_health-autocvar_g_nades_ice_health) * STAT(REVIVE_PROGRESS, this)));
2491
2492                         if (GetResource(this, RES_HEALTH) < 1)
2493                         {
2494                                 if (this.vehicle)
2495                                         vehicles_exit(this.vehicle, VHEF_RELEASE);
2496                                 if(this.event_damage)
2497                                         this.event_damage(this, this, this.frozen_by, 1, DEATH_NADE_ICE_FREEZE.m_id, DMG_NOWEP, this.origin, '0 0 0');
2498                         }
2499                         else if (STAT(REVIVE_PROGRESS, this) <= 0)
2500                                 Unfreeze(this, false);
2501                 }
2502         }
2503
2504         MUTATOR_CALLHOOK(PlayerPreThink, this);
2505
2506         if(autocvar_g_vehicles_enter && (time > this.last_vehiclecheck) && !game_stopped && !this.vehicle)
2507         if(IS_PLAYER(this) && !STAT(FROZEN, this) && !IS_DEAD(this) && !IS_INDEPENDENT_PLAYER(this))
2508         {
2509                 FOREACH_ENTITY_RADIUS(this.origin, autocvar_g_vehicles_enter_radius, IS_VEHICLE(it) && !IS_DEAD(it) && it.takedamage != DAMAGE_NO,
2510                 {
2511                         if(!it.owner)
2512                         {
2513                                 if(!it.team || SAME_TEAM(this, it))
2514                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER);
2515                                 else if(autocvar_g_vehicles_steal)
2516                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER_STEAL);
2517                         }
2518                         else if((it.vehicle_flags & VHF_MULTISLOT) && SAME_TEAM(it.owner, this))
2519                         {
2520                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER_GUNNER);
2521                         }
2522                 });
2523
2524                 this.last_vehiclecheck = time + 1;
2525         }
2526
2527         if(!CS(this).cvar_cl_newusekeysupported) // FIXME remove this - it was a stupid idea to begin with, we can JUST use the button
2528         {
2529                 if(PHYS_INPUT_BUTTON_USE(this) && !CS(this).usekeypressed)
2530                         PlayerUseKey(this);
2531                 CS(this).usekeypressed = PHYS_INPUT_BUTTON_USE(this);
2532         }
2533
2534         if (IS_REAL_CLIENT(this))
2535                 PrintWelcomeMessage(this);
2536
2537         if (IS_PLAYER(this)) {
2538                 if (IS_REAL_CLIENT(this) && time < CS(this).jointime + MIN_SPEC_TIME)
2539                         error("Client can't be spawned as player on connection!");
2540                 if(!PlayerThink(this))
2541                         return;
2542         }
2543         else if (game_stopped || intermission_running) {
2544                 if(intermission_running)
2545                         IntermissionThink(this);
2546                 return;
2547         }
2548         else if (IS_REAL_CLIENT(this) && !CS(this).autojoin_checked && time >= CS(this).jointime + MIN_SPEC_TIME)
2549         {
2550                 CS(this).autojoin_checked = true;
2551                 // don't do this in ClientConnect
2552                 // many things can go wrong if a client is spawned as player on connection
2553                 if (MUTATOR_CALLHOOK(AutoJoinOnConnection, this)
2554                         || (!(autocvar_sv_spectate || autocvar_g_campaign || (Player_GetForcedTeamIndex(this) == TEAM_FORCE_SPECTATOR))
2555                                 && (!teamplay || autocvar_g_balance_teams)))
2556                 {
2557                         campaign_bots_may_start = true;
2558                         Join(this);
2559                         return;
2560                 }
2561         }
2562         else if (IS_OBSERVER(this)) {
2563                 ObserverThink(this);
2564         }
2565         else if (IS_SPEC(this)) {
2566                 SpectatorThink(this);
2567         }
2568
2569         // WEAPONTODO: Add weapon request for this
2570         if (!zoomstate_set) {
2571                 bool wep_zoomed = false;
2572                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2573                 {
2574                         .entity weaponentity = weaponentities[slot];
2575                         Weapon thiswep = this.(weaponentity).m_weapon;
2576                         if(thiswep != WEP_Null && thiswep.wr_zoom)
2577                                 wep_zoomed += thiswep.wr_zoom(thiswep, this);
2578                 }
2579                 SetZoomState(this, PHYS_INPUT_BUTTON_ZOOM(this) || PHYS_INPUT_BUTTON_ZOOMSCRIPT(this) || wep_zoomed);
2580     }
2581
2582         if (CS(this).teamkill_soundtime && time > CS(this).teamkill_soundtime)
2583         {
2584                 CS(this).teamkill_soundtime = 0;
2585
2586                 entity e = CS(this).teamkill_soundsource;
2587                 entity oldpusher = e.pusher;
2588                 e.pusher = this;
2589                 PlayerSound(e, playersound_teamshoot, CH_VOICE, VOL_BASEVOICE, VOICETYPE_LASTATTACKER_ONLY);
2590                 e.pusher = oldpusher;
2591         }
2592
2593         if (CS(this).taunt_soundtime && time > CS(this).taunt_soundtime) {
2594                 CS(this).taunt_soundtime = 0;
2595                 PlayerSound(this, playersound_taunt, CH_VOICE, VOL_BASEVOICE, VOICETYPE_AUTOTAUNT);
2596         }
2597
2598         target_voicescript_next(this);
2599
2600         // WEAPONTODO: Move into weaponsystem somehow
2601         // if a player goes unarmed after holding a loaded weapon, empty his clip size and remove the crosshair ammo ring
2602         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2603         {
2604                 .entity weaponentity = weaponentities[slot];
2605                 if(this.(weaponentity).m_weapon == WEP_Null)
2606                         this.(weaponentity).clip_load = this.(weaponentity).clip_size = 0;
2607         }
2608 }
2609
2610 void DrownPlayer(entity this)
2611 {
2612         if(IS_DEAD(this) || game_stopped || time < game_starttime)
2613                 return;
2614
2615         if (this.waterlevel != WATERLEVEL_SUBMERGED || this.vehicle)
2616         {
2617                 if(this.air_finished < time)
2618                         PlayerSound(this, playersound_gasp, CH_PLAYER, VOL_BASE, VOICETYPE_PLAYERSOUND);
2619                 this.air_finished = time + autocvar_g_balance_contents_drowndelay;
2620         }
2621         else if (this.air_finished < time)
2622         {       // drown!
2623                 if (this.pain_finished < time)
2624                 {
2625                         Damage (this, NULL, NULL, autocvar_g_balance_contents_playerdamage_drowning * autocvar_g_balance_contents_damagerate, DEATH_DROWN.m_id, DMG_NOWEP, this.origin, '0 0 0');
2626                         this.pain_finished = time + 0.5;
2627                 }
2628         }
2629 }
2630
2631 .bool move_qcphysics;
2632
2633 void Player_Physics(entity this)
2634 {
2635         this.movetype = (this.move_qcphysics) ? MOVETYPE_QCPLAYER : this.move_movetype;
2636
2637         if(!this.move_qcphysics)
2638                 return;
2639
2640         if(!frametime && !CS(this).pm_frametime)
2641                 return;
2642
2643         Movetype_Physics_NoMatchTicrate(this, CS(this).pm_frametime, true);
2644
2645         CS(this).pm_frametime = 0;
2646 }
2647
2648 /*
2649 =============
2650 PlayerPostThink
2651
2652 Called every frame for each client after the physics are run
2653 =============
2654 */
2655 void PlayerPostThink (entity this)
2656 {
2657         Player_Physics(this);
2658
2659         if (sv_maxidle > 0)
2660         if (frametime) // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2661         if (IS_REAL_CLIENT(this))
2662         if (IS_PLAYER(this) || sv_maxidle_spectatorsareidle)
2663         {
2664                 int totalClients = 0;
2665                 if(sv_maxidle_slots > 0)
2666                 {
2667                         FOREACH_CLIENT(IS_REAL_CLIENT(it) || sv_maxidle_slots_countbots,
2668                         {
2669                                 ++totalClients;
2670                         });
2671                 }
2672
2673                 if (sv_maxidle_slots > 0 && (maxclients - totalClients) > sv_maxidle_slots)
2674                 { /* do nothing */ }
2675                 else if (time - CS(this).parm_idlesince < 1) // instead of (time == this.parm_idlesince) to support sv_maxidle <= 10
2676                 {
2677                         if (CS(this).idlekick_lasttimeleft)
2678                         {
2679                                 CS(this).idlekick_lasttimeleft = 0;
2680                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_IDLING);
2681                         }
2682                 }
2683                 else
2684                 {
2685                         float timeleft = ceil(sv_maxidle - (time - CS(this).parm_idlesince));
2686                         if (timeleft == min(10, sv_maxidle - 1)) { // - 1 to support sv_maxidle <= 10
2687                                 if (!CS(this).idlekick_lasttimeleft)
2688                                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_DISCONNECT_IDLING, timeleft);
2689                         }
2690                         if (timeleft <= 0) {
2691                                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_QUIT_KICK_IDLING, this.netname);
2692                                 dropclient(this);
2693                                 return;
2694                         }
2695                         else if (timeleft <= 10) {
2696                                 if (timeleft != CS(this).idlekick_lasttimeleft) {
2697                                     Send_Notification(NOTIF_ONE, this, MSG_ANNCE, Announcer_PickNumber(CNT_IDLE, timeleft));
2698                 }
2699                                 CS(this).idlekick_lasttimeleft = timeleft;
2700                         }
2701                 }
2702         }
2703
2704         CheatFrame(this);
2705
2706         if (game_stopped)
2707         {
2708                 this.solid = SOLID_NOT;
2709                 this.takedamage = DAMAGE_NO;
2710                 set_movetype(this, MOVETYPE_NONE);
2711         }
2712
2713         if (IS_PLAYER(this)) {
2714                 if(this.death_time == time && IS_DEAD(this))
2715                 {
2716                         // player's bbox gets resized now, instead of in the damage event that killed the player,
2717                         // once all the damage events of this frame have been processed with normal size
2718                         this.maxs.z = 5;
2719                         setsize(this, this.mins, this.maxs);
2720                 }
2721                 DrownPlayer(this);
2722                 UpdateChatBubble(this);
2723                 if (CS(this).impulse) ImpulseCommands(this);
2724                 if (game_stopped)
2725                 {
2726                         CSQCMODEL_AUTOUPDATE(this);
2727                         return;
2728                 }
2729                 GetPressedKeys(this);
2730         }
2731         else if (IS_OBSERVER(this) && STAT(PRESSED_KEYS, this))
2732         {
2733                 CS(this).pressedkeys = 0;
2734                 STAT(PRESSED_KEYS, this) = 0;
2735         }
2736
2737         if (this.waypointsprite_attachedforcarrier) {
2738                 float hp = healtharmor_maxdamage(GetResource(this, RES_HEALTH), GetResource(this, RES_ARMOR), autocvar_g_balance_armor_blockpercent, DEATH_WEAPON.m_id).x;
2739                 WaypointSprite_UpdateHealth(this.waypointsprite_attachedforcarrier, hp);
2740         }
2741
2742         CSQCMODEL_AUTOUPDATE(this);
2743 }
2744
2745 /**
2746  * message "": do not say, just test flood control
2747  * return value:
2748  *   1 = accept
2749  *   0 = reject
2750  *  -1 = fake accept
2751  */
2752 int Say(entity source, int teamsay, entity privatesay, string msgin, bool floodcontrol)
2753 {
2754         if (!teamsay && !privatesay && substring(msgin, 0, 1) == " ")
2755                 msgin = substring(msgin, 1, -1); // work around DP say bug (say_team does not have this!)
2756
2757         if (source)
2758                 msgin = formatmessage(source, msgin);
2759
2760         string colorstr;
2761         if (!(IS_PLAYER(source) || source.caplayer))
2762                 colorstr = "^0"; // black for spectators
2763         else if(teamplay)
2764                 colorstr = Team_ColorCode(source.team);
2765         else
2766         {
2767                 colorstr = "";
2768                 teamsay = false;
2769         }
2770
2771         if (!source) {
2772                 colorstr = "";
2773                 teamsay = false;
2774         }
2775
2776         if(msgin != "")
2777                 msgin = trigger_magicear_processmessage_forallears(source, teamsay, privatesay, msgin);
2778
2779         /*
2780          * using bprint solves this... me stupid
2781         // how can we prevent the message from appearing in a listen server?
2782         // for now, just give "say" back and only handle say_team
2783         if(!teamsay)
2784         {
2785                 clientcommand(source, strcat("say ", msgin));
2786                 return;
2787         }
2788         */
2789
2790         string namestr = "";
2791         if (source)
2792                 namestr = playername(source, autocvar_g_chat_teamcolors);
2793
2794         string colorprefix = (strdecolorize(namestr) == namestr) ? "^3" : "^7";
2795
2796         string msgstr = "", cmsgstr = "";
2797         string privatemsgprefix = string_null;
2798         int privatemsgprefixlen = 0;
2799         if (msgin != "")
2800         {
2801                 bool found_me = false;
2802                 if(strstrofs(msgin, "/me", 0) >= 0)
2803                 {
2804                         string newmsgin = "";
2805                         string newnamestr = ((teamsay) ? strcat(colorstr, "(", colorprefix, namestr, colorstr, ")", "^7") : strcat(colorprefix, namestr, "^7"));
2806                         FOREACH_WORD(msgin, true,
2807                         {
2808                                 if(strdecolorize(it) == "/me")
2809                                 {
2810                                         found_me = true;
2811                                         newmsgin = cons(newmsgin, newnamestr);
2812                                 }
2813                                 else
2814                                         newmsgin = cons(newmsgin, it);
2815                         });
2816                         msgin = newmsgin;
2817                 }
2818
2819                 if(privatesay)
2820                 {
2821                         msgstr = strcat("\{1}\{13}* ", colorprefix, namestr, "^3 tells you: ^7");
2822                         privatemsgprefixlen = strlen(msgstr);
2823                         msgstr = strcat(msgstr, msgin);
2824                         cmsgstr = strcat(colorstr, colorprefix, namestr, "^3 tells you:\n^7", msgin);
2825                         privatemsgprefix = strcat("\{1}\{13}* ^3You tell ", playername(privatesay, autocvar_g_chat_teamcolors), ": ^7");
2826                 }
2827                 else if(teamsay)
2828                 {
2829                         if(found_me)
2830                         {
2831                                 //msgin = strreplace("/me", "", msgin);
2832                                 //msgin = substring(msgin, 3, strlen(msgin));
2833                                 //msgin = strreplace("/me", strcat(colorstr, "(", colorprefix, namestr, colorstr, ")^7"), msgin);
2834                                 msgstr = strcat("\{1}\{13}^4* ", "^7", msgin);
2835                         }
2836                         else
2837                                 msgstr = strcat("\{1}\{13}", colorstr, "(", colorprefix, namestr, colorstr, ") ^7", msgin);
2838                         cmsgstr = strcat(colorstr, "(", colorprefix, namestr, colorstr, ")\n^7", msgin);
2839                 }
2840                 else
2841                 {
2842                         if(found_me)
2843                         {
2844                                 //msgin = strreplace("/me", "", msgin);
2845                                 //msgin = substring(msgin, 3, strlen(msgin));
2846                                 //msgin = strreplace("/me", strcat(colorprefix, namestr), msgin);
2847                                 msgstr = strcat("\{1}^4* ^7", msgin);
2848                         }
2849                         else {
2850                                 msgstr = "\{1}";
2851                                 msgstr = strcat(msgstr, (namestr != "") ? strcat(colorprefix, namestr, "^7: ") : "^7");
2852                                 msgstr = strcat(msgstr, msgin);
2853                         }
2854                         cmsgstr = "";
2855                 }
2856                 msgstr = strcat(strreplace("\n", " ", msgstr), "\n"); // newlines only are good for centerprint
2857         }
2858
2859         string fullmsgstr = msgstr;
2860         string fullcmsgstr = cmsgstr;
2861
2862         // FLOOD CONTROL
2863         int flood = 0;
2864         var .float flood_field = floodcontrol_chat;
2865         if(floodcontrol && source)
2866         {
2867                 float flood_spl;
2868                 float flood_burst;
2869                 float flood_lmax;
2870                 float lines;
2871                 if(privatesay)
2872                 {
2873                         flood_spl = autocvar_g_chat_flood_spl_tell;
2874                         flood_burst = autocvar_g_chat_flood_burst_tell;
2875                         flood_lmax = autocvar_g_chat_flood_lmax_tell;
2876                         flood_field = floodcontrol_chattell;
2877                 }
2878                 else if(teamsay)
2879                 {
2880                         flood_spl = autocvar_g_chat_flood_spl_team;
2881                         flood_burst = autocvar_g_chat_flood_burst_team;
2882                         flood_lmax = autocvar_g_chat_flood_lmax_team;
2883                         flood_field = floodcontrol_chatteam;
2884                 }
2885                 else
2886                 {
2887                         flood_spl = autocvar_g_chat_flood_spl;
2888                         flood_burst = autocvar_g_chat_flood_burst;
2889                         flood_lmax = autocvar_g_chat_flood_lmax;
2890                         flood_field = floodcontrol_chat;
2891                 }
2892                 flood_burst = max(0, flood_burst - 1);
2893                 // to match explanation in default.cfg, a value of 3 must allow three-line bursts and not four!
2894
2895                 // do flood control for the default line size
2896                 if(msgstr != "")
2897                 {
2898                         getWrappedLine_remaining = msgstr;
2899                         msgstr = "";
2900                         lines = 0;
2901                         while(getWrappedLine_remaining && (!flood_lmax || lines <= flood_lmax))
2902                         {
2903                                 msgstr = strcat(msgstr, " ", getWrappedLineLen(82.4289758859709, strlennocol)); // perl averagewidth.pl < gfx/vera-sans.width
2904                                 ++lines;
2905                         }
2906                         msgstr = substring(msgstr, 1, strlen(msgstr) - 1);
2907
2908                         if(getWrappedLine_remaining != "")
2909                         {
2910                                 msgstr = strcat(msgstr, "\n");
2911                                 flood = 2;
2912                         }
2913
2914                         if (time >= source.(flood_field))
2915                         {
2916                                 source.(flood_field) = max(time - flood_burst * flood_spl, source.(flood_field)) + lines * flood_spl;
2917                         }
2918                         else
2919                         {
2920                                 flood = 1;
2921                                 msgstr = fullmsgstr;
2922                         }
2923                 }
2924                 else
2925                 {
2926                         if (time >= source.(flood_field))
2927                                 source.(flood_field) = max(time - flood_burst * flood_spl, source.(flood_field)) + flood_spl;
2928                         else
2929                                 flood = 1;
2930                 }
2931
2932                 if (timeout_status == TIMEOUT_ACTIVE) // when game is paused, no flood protection
2933                         source.(flood_field) = flood = 0;
2934         }
2935
2936         string sourcemsgstr, sourcecmsgstr;
2937         if(flood == 2) // cannot happen for empty msgstr
2938         {
2939                 if(autocvar_g_chat_flood_notify_flooder)
2940                 {
2941                         sourcemsgstr = strcat(msgstr, "\n^3FLOOD CONTROL: ^7message too long, trimmed\n");
2942                         sourcecmsgstr = "";
2943                 }
2944                 else
2945                 {
2946                         sourcemsgstr = fullmsgstr;
2947                         sourcecmsgstr = fullcmsgstr;
2948                 }
2949                 cmsgstr = "";
2950         }
2951         else
2952         {
2953                 sourcemsgstr = msgstr;
2954                 sourcecmsgstr = cmsgstr;
2955         }
2956
2957         if (!privatesay && source && !(IS_PLAYER(source) || source.caplayer))
2958         {
2959                 if (!game_stopped)
2960                 if (teamsay || (autocvar_g_chat_nospectators == 1) || (autocvar_g_chat_nospectators == 2 && !warmup_stage))
2961                         teamsay = -1; // spectators
2962         }
2963
2964         if(flood)
2965                 LOG_INFO("NOTE: ", playername(source, true), "^7 is flooding.");
2966
2967         // build sourcemsgstr by cutting off a prefix and replacing it by the other one
2968         if(privatesay)
2969                 sourcemsgstr = strcat(privatemsgprefix, substring(sourcemsgstr, privatemsgprefixlen, -1));
2970
2971         int ret;
2972         if(source && CS(source).muted)
2973         {
2974                 // always fake the message
2975                 ret = -1;
2976         }
2977         else if(flood == 1)
2978         {
2979                 if (autocvar_g_chat_flood_notify_flooder)
2980                 {
2981                         sprint(source, strcat("^3FLOOD CONTROL: ^7wait ^1", ftos(source.(flood_field) - time), "^3 seconds\n"));
2982                         ret = 0;
2983                 }
2984                 else
2985                         ret = -1;
2986         }
2987         else
2988         {
2989                 ret = 1;
2990         }
2991
2992         if (privatesay && source && !(IS_PLAYER(source) || source.caplayer))
2993         {
2994                 if (!game_stopped)
2995                 if ((privatesay && (IS_PLAYER(privatesay) || privatesay.caplayer)) && ((autocvar_g_chat_nospectators == 1) || (autocvar_g_chat_nospectators == 2 && !warmup_stage)))
2996                         ret = -1; // just hide the message completely
2997         }
2998
2999         MUTATOR_CALLHOOK(ChatMessage, source, ret);
3000         ret = M_ARGV(1, int);
3001
3002         string event_log_msg = "";
3003
3004         if(sourcemsgstr != "" && ret != 0)
3005         {
3006                 if(ret < 0) // faked message, because the player is muted
3007                 {
3008                         sprint(source, sourcemsgstr);
3009                         if(sourcecmsgstr != "" && !privatesay)
3010                                 centerprint(source, sourcecmsgstr);
3011                 }
3012                 else if(privatesay) // private message, between 2 people only
3013                 {
3014                         sprint(source, sourcemsgstr);
3015                         if (!autocvar_g_chat_tellprivacy) { dedicated_print(msgstr); } // send to server console too if "tellprivacy" is disabled
3016                         if(!MUTATOR_CALLHOOK(ChatMessageTo, privatesay, source))
3017                         {
3018                                 sprint(privatesay, msgstr);
3019                                 if(cmsgstr != "")
3020                                         centerprint(privatesay, cmsgstr);
3021                         }
3022                 }
3023                 else if ( teamsay && CS(source).active_minigame )
3024                 {
3025                         sprint(source, sourcemsgstr);
3026                         dedicated_print(msgstr); // send to server console too
3027                         FOREACH_CLIENT(IS_REAL_CLIENT(it) && it != source && CS(it).active_minigame == CS(source).active_minigame && !MUTATOR_CALLHOOK(ChatMessageTo, it, source), {
3028                                 sprint(it, msgstr);
3029                         });
3030                         event_log_msg = sprintf(":chat_minigame:%d:%s:%s", source.playerid, CS(source).active_minigame.netname, msgin);
3031
3032                 }
3033                 else if(teamsay > 0) // team message, only sent to team mates
3034                 {
3035                         sprint(source, sourcemsgstr);
3036                         dedicated_print(msgstr); // send to server console too
3037                         if(sourcecmsgstr != "")
3038                                 centerprint(source, sourcecmsgstr);
3039                         FOREACH_CLIENT((IS_PLAYER(it) || it.caplayer) && IS_REAL_CLIENT(it) && it != source && it.team == source.team && !MUTATOR_CALLHOOK(ChatMessageTo, it, source), {
3040                                 sprint(it, msgstr);
3041                                 if(cmsgstr != "")
3042                                         centerprint(it, cmsgstr);
3043                         });
3044                         event_log_msg = sprintf(":chat_team:%d:%d:%s", source.playerid, source.team, strreplace("\n", " ", msgin));
3045                 }
3046                 else if(teamsay < 0) // spectator message, only sent to spectators
3047                 {
3048                         sprint(source, sourcemsgstr);
3049                         dedicated_print(msgstr); // send to server console too
3050                         FOREACH_CLIENT(!(IS_PLAYER(it) || it.caplayer) && IS_REAL_CLIENT(it) && it != source && !MUTATOR_CALLHOOK(ChatMessageTo, it, source), {
3051                                 sprint(it, msgstr);
3052                         });
3053                         event_log_msg = sprintf(":chat_spec:%d:%s", source.playerid, strreplace("\n", " ", msgin));
3054                 }
3055                 else
3056                 {
3057                         if (source) {
3058                                 sprint(source, sourcemsgstr);
3059                                 dedicated_print(msgstr); // send to server console too
3060                                 MX_Say(strcat(playername(source, true), "^7: ", msgin));
3061                         }
3062                         FOREACH_CLIENT(IS_REAL_CLIENT(it) && it != source && !MUTATOR_CALLHOOK(ChatMessageTo, it, source), {
3063                                 sprint(it, msgstr);
3064                         });
3065                         event_log_msg = sprintf(":chat:%d:%s", source.playerid, strreplace("\n", " ", msgin));
3066                 }
3067         }
3068
3069         if (autocvar_sv_eventlog && (event_log_msg != "")) {
3070                 GameLogEcho(event_log_msg);
3071         }
3072
3073         return ret;
3074 }
3075
3076 // hack to copy the button fields from the client entity to the Client State
3077 void PM_UpdateButtons(entity this, entity store)
3078 {
3079         if(this.impulse)
3080                 store.impulse = this.impulse;
3081         this.impulse = 0;
3082
3083         bool typing = this.buttonchat || this.button12;
3084
3085         store.button0 = (typing) ? 0 : this.button0;
3086         //button1?!
3087         store.button2 = (typing) ? 0 : this.button2;
3088         store.button3 = (typing) ? 0 : this.button3;
3089         store.button4 = this.button4;
3090         store.button5 = (typing) ? 0 : this.button5;
3091         store.button6 = this.button6;
3092         store.button7 = this.button7;
3093         store.button8 = this.button8;
3094         store.button9 = this.button9;
3095         store.button10 = this.button10;
3096         store.button11 = this.button11;
3097         store.button12 = this.button12;
3098         store.button13 = this.button13;
3099         store.button14 = this.button14;
3100         store.button15 = this.button15;
3101         store.button16 = this.button16;
3102         store.buttonuse = this.buttonuse;
3103         store.buttonchat = this.buttonchat;
3104
3105         store.cursor_active = this.cursor_active;
3106         store.cursor_screen = this.cursor_screen;
3107         store.cursor_trace_start = this.cursor_trace_start;
3108         store.cursor_trace_endpos = this.cursor_trace_endpos;
3109         store.cursor_trace_ent = this.cursor_trace_ent;
3110
3111         store.ping = this.ping;
3112         store.ping_packetloss = this.ping_packetloss;
3113         store.ping_movementloss = this.ping_movementloss;
3114
3115         store.v_angle = this.v_angle;
3116         store.movement = (typing) ? '0 0 0' : this.movement;
3117 }
3118
3119 NET_HANDLE(fpsreport, bool)
3120 {
3121         int fps = ReadShort();
3122         PlayerScore_Set(sender, SP_FPS, fps);
3123         return true;
3124 }