qcsrc/server/client.qc

   1 #include "client.qh"
   2
   3 #include "anticheat.qh"
   4 #include "impulse.qh"
   5 #include "player.qh"
   6 #include "ipban.qh"
   7 #include "miscfunctions.qh"
   8 #include "portals.qh"
   9 #include "teamplay.qh"
  10 #include "playerdemo.qh"
  11 #include "spawnpoints.qh"
  12 #include "g_damage.qh"
  13 #include "g_hook.qh"
  14 #include "command/common.qh"
  15 #include "cheats.qh"
  16 #include "g_world.qh"
  17 #include "race.qh"
  18 #include "antilag.qh"
  19 #include "campaign.qh"
  20 #include "command/common.qh"
  21 #include "scores_rules.qh"
  22
  23 #include "bot/api.qh"
  24
  25 #include "../common/ent_cs.qh"
  26 #include "../common/wepent.qh"
  27 #include <common/state.qh>
  28
  29 #include <common/effects/qc/globalsound.qh>
  30
  31 #include "../common/triggers/func/conveyor.qh"
  32 #include "../common/triggers/teleporters.qh"
  33
  34 #include "../common/vehicles/all.qh"
  35
  36 #include "weapons/hitplot.qh"
  37 #include "weapons/weaponsystem.qh"
  38
  39 #include "../common/net_notice.qh"
  40 #include "../common/net_linked.qh"
  41 #include "../common/physics/player.qh"
  42
  43 #include "../common/items/_mod.qh"
  44
  45 #include "../common/mutators/mutator/waypoints/all.qh"
  46
  47 #include "../common/triggers/subs.qh"
  48 #include "../common/triggers/triggers.qh"
  49 #include "../common/triggers/trigger/secret.qh"
  50
  51 #include "../common/minigames/sv_minigames.qh"
  52
  53 #include "../common/items/inventory.qh"
  54
  55 #include "../common/monsters/sv_monsters.qh"
  56
  57 #include "../lib/warpzone/server.qh"
  58
  59 #include <common/mutators/mutator/overkill/okvortex.qh>
  60
  61 STATIC_METHOD(Client, Add, void(Client this, int _team))
  62 {
  63     ClientConnect(this);
  64     TRANSMUTE(Player, this);
  65     this.frame = 12; // 7
  66     this.team = _team;
  67     PutClientInServer(this);
  68 }
  69
  70 void PutObserverInServer(entity this);
  71
  72 STATIC_METHOD(Client, Remove, void(Client this))
  73 {
  74     TRANSMUTE(Observer, this);
  75     PutClientInServer(this);
  76     ClientDisconnect(this);
  77 }
  78
  79 void send_CSQC_teamnagger() {
  80         WriteHeader(MSG_BROADCAST, TE_CSQC_TEAMNAGGER);
  81 }
  82
  83 int CountSpectators(entity player, entity to)
  84 {
  85         if(!player) { return 0; } // not sure how, but best to be safe
  86
  87         int spec_count = 0;
  88
  89         FOREACH_CLIENT(IS_REAL_CLIENT(it) && IS_SPEC(it) && it != to && it.enemy == player,
  90         {
  91                 spec_count++;
  92         });
  93
  94         return spec_count;
  95 }
  96
  97 void WriteSpectators(entity player, entity to)
  98 {
  99         if(!player) { return; } // not sure how, but best to be safe
 100
 101         FOREACH_CLIENT(IS_REAL_CLIENT(it) && IS_SPEC(it) && it != to && it.enemy == player,
 102         {
 103                 WriteByte(MSG_ENTITY, num_for_edict(it));
 104         });
 105 }
 106
 107 bool ClientData_Send(entity this, entity to, int sf)
 108 {
 109         assert(to == this.owner, return false);
 110
 111         entity e = to;
 112         if (IS_SPEC(e)) e = e.enemy;
 113
 114         sf = 0;
 115         if (e.race_completed)       sf |= 1; // forced scoreboard
 116         if (to.spectatee_status)    sf |= 2; // spectator ent number follows
 117         if (e.zoomstate)            sf |= 4; // zoomed
 118         if (autocvar_sv_showspectators) sf |= 16; // show spectators
 119
 120         WriteHeader(MSG_ENTITY, ENT_CLIENT_CLIENTDATA);
 121         WriteByte(MSG_ENTITY, sf);
 122
 123         if (sf & 2)
 124         {
 125                 WriteByte(MSG_ENTITY, to.spectatee_status);
 126         }
 127
 128         if(sf & 16)
 129         {
 130                 float specs = CountSpectators(e, to);
 131                 WriteByte(MSG_ENTITY, specs);
 132                 WriteSpectators(e, to);
 133         }
 134
 135         return true;
 136 }
 137
 138 void ClientData_Attach(entity this)
 139 {
 140         Net_LinkEntity(this.clientdata = new_pure(clientdata), false, 0, ClientData_Send);
 141         this.clientdata.drawonlytoclient = this;
 142         this.clientdata.owner = this;
 143 }
 144
 145 void ClientData_Detach(entity this)
 146 {
 147         delete(this.clientdata);
 148         this.clientdata = NULL;
 149 }
 150
 151 void ClientData_Touch(entity e)
 152 {
 153         e.clientdata.SendFlags = 1;
 154
 155         // make it spectatable
 156         FOREACH_CLIENT(IS_REAL_CLIENT(it) && it != e && IS_SPEC(it) && it.enemy == e, LAMBDA(it.clientdata.SendFlags = 1));
 157 }
 158
 159 .string netname_previous;
 160
 161 void SetSpectatee(entity this, entity spectatee);
 162 void SetSpectatee_status(entity this, int spectatee_num);
 163
 164
 165 /*
 166 =============
 167 CheckPlayerModel
 168
 169 Checks if the argument string can be a valid playermodel.
 170 Returns a valid one in doubt.
 171 =============
 172 */
 173 string FallbackPlayerModel;
 174 string CheckPlayerModel(string plyermodel) {
 175         if(FallbackPlayerModel != cvar_defstring("_cl_playermodel"))
 176         {
 177                 // note: we cannot summon Don Strunzone here, some player may
 178                 // still have the model string set. In case anyone manages how
 179                 // to change a cvar default, we'll have a small leak here.
 180                 FallbackPlayerModel = strzone(cvar_defstring("_cl_playermodel"));
 181         }
 182         // only in right path
 183         if( substring(plyermodel,0,14) != "models/player/")
 184                 return FallbackPlayerModel;
 185         // only good file extensions
 186         if(substring(plyermodel,-4,4) != ".zym")
 187         if(substring(plyermodel,-4,4) != ".dpm")
 188         if(substring(plyermodel,-4,4) != ".iqm")
 189         if(substring(plyermodel,-4,4) != ".md3")
 190         if(substring(plyermodel,-4,4) != ".psk")
 191                 return FallbackPlayerModel;
 192         // forbid the LOD models
 193         if(substring(plyermodel, -9,5) == "_lod1")
 194                 return FallbackPlayerModel;
 195         if(substring(plyermodel, -9,5) == "_lod2")
 196                 return FallbackPlayerModel;
 197         if(plyermodel != strtolower(plyermodel))
 198                 return FallbackPlayerModel;
 199         // also, restrict to server models
 200         if(autocvar_sv_servermodelsonly)
 201         {
 202                 if(!fexists(plyermodel))
 203                         return FallbackPlayerModel;
 204         }
 205         return plyermodel;
 206 }
 207
 208 void setplayermodel(entity e, string modelname)
 209 {
 210         precache_model(modelname);
 211         _setmodel(e, modelname);
 212         player_setupanimsformodel(e);
 213         if(!autocvar_g_debug_globalsounds)
 214                 UpdatePlayerSounds(e);
 215 }
 216
 217 void FixPlayermodel(entity player);
 218 /** putting a client as observer in the server */
 219 void PutObserverInServer(entity this)
 220 {
 221     bool mutator_returnvalue = MUTATOR_CALLHOOK(MakePlayerObserver, this);
 222         PlayerState_detach(this);
 223
 224         if (IS_PLAYER(this) && this.health >= 1) {
 225         // despawn effect
 226                 Send_Effect(EFFECT_SPAWN_NEUTRAL, this.origin, '0 0 0', 1);
 227     }
 228
 229     {
 230         entity spot = SelectSpawnPoint(this, true);
 231         if (!spot) LOG_FATAL("No spawnpoints for observers?!?");
 232         this.angles = spot.angles;
 233         this.angles_z = 0;
 234         this.fixangle = true;
 235         // offset it so that the spectator spawns higher off the ground, looks better this way
 236         setorigin(this, spot.origin + STAT(PL_VIEW_OFS, this));
 237         this.prevorigin = this.origin;
 238         if (IS_REAL_CLIENT(this))
 239         {
 240             msg_entity = this;
 241             WriteByte(MSG_ONE, SVC_SETVIEW);
 242             WriteEntity(MSG_ONE, this);
 243         }
 244         // give the spectator some space between walls for MOVETYPE_FLY_WORLDONLY
 245         // so that your view doesn't go into the ceiling with MOVETYPE_FLY_WORLDONLY, previously "PL_VIEW_OFS"
 246         if(!autocvar_g_debug_globalsounds)
 247         {
 248                 // needed for player sounds
 249                 this.model = "";
 250                 FixPlayermodel(this);
 251         }
 252         setmodel(this, MDL_Null);
 253         setsize(this, STAT(PL_CROUCH_MIN, this), STAT(PL_CROUCH_MAX, this));
 254         this.view_ofs = '0 0 0';
 255     }
 256
 257     RemoveGrapplingHooks(this);
 258         Portal_ClearAll(this);
 259         Unfreeze(this);
 260         SetSpectatee(this, NULL);
 261
 262         if (this.alivetime)
 263         {
 264                 if (!warmup_stage)
 265                         PS_GR_P_ADDVAL(this, PLAYERSTATS_ALIVETIME, time - this.alivetime);
 266                 this.alivetime = 0;
 267         }
 268
 269         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
 270
 271         WaypointSprite_PlayerDead(this);
 272
 273         if (mutator_returnvalue) {
 274             // mutator prevents resetting teams+score
 275         } else {
 276                 this.team = -1;  // move this as it is needed to log the player spectating in eventlog
 277         this.frags = FRAGS_SPECTATOR;
 278         PlayerScore_Clear(this);  // clear scores when needed
 279     }
 280
 281         if (this.killcount != FRAGS_SPECTATOR)
 282         {
 283                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_QUIT_SPECTATE, this.netname);
 284                 if(!game_stopped)
 285                 if(autocvar_g_chat_nospectators == 1 || (!warmup_stage && autocvar_g_chat_nospectators == 2))
 286                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_CHAT_NOSPECTATORS);
 287
 288                 if(this.just_joined == false) {
 289                         LogTeamchange(this.playerid, -1, 4);
 290                 } else
 291                         this.just_joined = false;
 292         }
 293
 294         accuracy_resend(this);
 295
 296         this.spectatortime = time;
 297         if(this.bot_attack)
 298                 IL_REMOVE(g_bot_targets, this);
 299         this.bot_attack = false;
 300     this.hud = HUD_NORMAL;
 301         TRANSMUTE(Observer, this);
 302         this.iscreature = false;
 303         this.teleportable = TELEPORT_SIMPLE;
 304         if(this.damagedbycontents)
 305                 IL_REMOVE(g_damagedbycontents, this);
 306         this.damagedbycontents = false;
 307         this.health = FRAGS_SPECTATOR;
 308         SetSpectatee_status(this, etof(this));
 309         this.takedamage = DAMAGE_NO;
 310         this.solid = SOLID_NOT;
 311         set_movetype(this, MOVETYPE_FLY_WORLDONLY); // user preference is controlled by playerprethink
 312         this.flags = FL_CLIENT | FL_NOTARGET;
 313         this.armorvalue = 666;
 314         this.effects = 0;
 315         this.armorvalue = autocvar_g_balance_armor_start;
 316         this.pauserotarmor_finished = 0;
 317         this.pauserothealth_finished = 0;
 318         this.pauseregen_finished = 0;
 319         this.damageforcescale = 0;
 320         this.death_time = 0;
 321         this.respawn_flags = 0;
 322         this.respawn_time = 0;
 323         this.stat_respawn_time = 0;
 324         this.alpha = 0;
 325         this.scale = 0;
 326         this.fade_time = 0;
 327         this.pain_frame = 0;
 328         this.pain_finished = 0;
 329         this.strength_finished = 0;
 330         this.invincible_finished = 0;
 331         this.superweapons_finished = 0;
 332         this.pushltime = 0;
 333         this.istypefrag = 0;
 334         setthink(this, func_null);
 335         this.nextthink = 0;
 336         this.deadflag = DEAD_NO;
 337         this.crouch = false;
 338         this.revive_progress = 0;
 339         this.revival_time = 0;
 340
 341         this.items = 0;
 342         this.weapons = '0 0 0';
 343         this.dual_weapons = '0 0 0';
 344         this.drawonlytoclient = this;
 345
 346         this.weaponmodel = "";
 347         for (int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 348         {
 349                 this.weaponentities[slot] = NULL;
 350         }
 351         this.exteriorweaponentity = NULL;
 352         this.killcount = FRAGS_SPECTATOR;
 353         this.velocity = '0 0 0';
 354         this.avelocity = '0 0 0';
 355         this.punchangle = '0 0 0';
 356         this.punchvector = '0 0 0';
 357         this.oldvelocity = this.velocity;
 358         this.fire_endtime = -1;
 359         this.event_damage = func_null;
 360
 361         for(int slot = 0; slot < MAX_AXH; ++slot)
 362         {
 363                 entity axh = this.(AuxiliaryXhair[slot]);
 364                 this.(AuxiliaryXhair[slot]) = NULL;
 365
 366                 if(axh.owner == this && axh != NULL && !wasfreed(axh))
 367                         delete(axh);
 368         }
 369 }
 370
 371 int player_getspecies(entity this)
 372 {
 373         get_model_parameters(this.model, this.skin);
 374         int s = get_model_parameters_species;
 375         get_model_parameters(string_null, 0);
 376         if (s < 0) return SPECIES_HUMAN;
 377         return s;
 378 }
 379
 380 .float model_randomizer;
 381 void FixPlayermodel(entity player)
 382 {
 383         string defaultmodel = "";
 384         int defaultskin = 0;
 385         if(autocvar_sv_defaultcharacter)
 386         {
 387                 if(teamplay)
 388                 {
 389                         switch(player.team)
 390                         {
 391                                 case NUM_TEAM_1: defaultmodel = autocvar_sv_defaultplayermodel_red; defaultskin = autocvar_sv_defaultplayerskin_red; break;
 392                                 case NUM_TEAM_2: defaultmodel = autocvar_sv_defaultplayermodel_blue; defaultskin = autocvar_sv_defaultplayerskin_blue; break;
 393                                 case NUM_TEAM_3: defaultmodel = autocvar_sv_defaultplayermodel_yellow; defaultskin = autocvar_sv_defaultplayerskin_yellow; break;
 394                                 case NUM_TEAM_4: defaultmodel = autocvar_sv_defaultplayermodel_pink; defaultskin = autocvar_sv_defaultplayerskin_pink; break;
 395                         }
 396                 }
 397
 398                 if(defaultmodel == "")
 399                 {
 400                         defaultmodel = autocvar_sv_defaultplayermodel;
 401                         defaultskin = autocvar_sv_defaultplayerskin;
 402                 }
 403
 404                 int n = tokenize_console(defaultmodel);
 405                 if(n > 0)
 406                 {
 407                         defaultmodel = argv(floor(n * player.model_randomizer));
 408                         // However, do NOT randomize if the player-selected model is in the list.
 409                         for (int i = 0; i < n; ++i)
 410                                 if ((argv(i) == player.playermodel && defaultskin == stof(player.playerskin)) || argv(i) == strcat(player.playermodel, ":", player.playerskin))
 411                                         defaultmodel = argv(i);
 412                 }
 413
 414                 int i = strstrofs(defaultmodel, ":", 0);
 415                 if(i >= 0)
 416                 {
 417                         defaultskin = stof(substring(defaultmodel, i+1, -1));
 418                         defaultmodel = substring(defaultmodel, 0, i);
 419                 }
 420         }
 421         if(autocvar_sv_defaultcharacterskin && !defaultskin)
 422         {
 423                 if(teamplay)
 424                 {
 425                         switch(player.team)
 426                         {
 427                                 case NUM_TEAM_1: defaultskin = autocvar_sv_defaultplayerskin_red; break;
 428                                 case NUM_TEAM_2: defaultskin = autocvar_sv_defaultplayerskin_blue; break;
 429                                 case NUM_TEAM_3: defaultskin = autocvar_sv_defaultplayerskin_yellow; break;
 430                                 case NUM_TEAM_4: defaultskin = autocvar_sv_defaultplayerskin_pink; break;
 431                         }
 432                 }
 433
 434                 if(!defaultskin)
 435                         defaultskin = autocvar_sv_defaultplayerskin;
 436         }
 437
 438         MUTATOR_CALLHOOK(FixPlayermodel, defaultmodel, defaultskin, player);
 439         defaultmodel = M_ARGV(0, string);
 440         defaultskin = M_ARGV(1, int);
 441
 442         bool chmdl = false;
 443         int oldskin;
 444         if(defaultmodel != "")
 445         {
 446                 if (defaultmodel != player.model)
 447                 {
 448                         vector m1 = player.mins;
 449                         vector m2 = player.maxs;
 450                         setplayermodel (player, defaultmodel);
 451                         setsize (player, m1, m2);
 452                         chmdl = true;
 453                 }
 454
 455                 oldskin = player.skin;
 456                 player.skin = defaultskin;
 457         } else {
 458                 if (player.playermodel != player.model || player.playermodel == "")
 459                 {
 460                         player.playermodel = CheckPlayerModel(player.playermodel); // this is never "", so no endless loop
 461                         vector m1 = player.mins;
 462                         vector m2 = player.maxs;
 463                         setplayermodel (player, player.playermodel);
 464                         setsize (player, m1, m2);
 465                         chmdl = true;
 466                 }
 467
 468                 if(!autocvar_sv_defaultcharacterskin)
 469                 {
 470                         oldskin = player.skin;
 471                         player.skin = stof(player.playerskin);
 472                 }
 473                 else
 474                 {
 475                         oldskin = player.skin;
 476                         player.skin = defaultskin;
 477                 }
 478         }
 479
 480         if(chmdl || oldskin != player.skin) // model or skin has changed
 481         {
 482                 player.species = player_getspecies(player); // update species
 483                 if(!autocvar_g_debug_globalsounds)
 484                         UpdatePlayerSounds(player); // update skin sounds
 485         }
 486
 487         if(!teamplay)
 488                 if(strlen(autocvar_sv_defaultplayercolors))
 489                         if(player.clientcolors != stof(autocvar_sv_defaultplayercolors))
 490                                 setcolor(player, stof(autocvar_sv_defaultplayercolors));
 491 }
 492
 493
 494 /** Called when a client spawns in the server */
 495 void PutClientInServer(entity this)
 496 {
 497         if (IS_BOT_CLIENT(this)) {
 498                 TRANSMUTE(Player, this);
 499         } else if (IS_REAL_CLIENT(this)) {
 500                 msg_entity = this;
 501                 WriteByte(MSG_ONE, SVC_SETVIEW);
 502                 WriteEntity(MSG_ONE, this);
 503         }
 504         if (game_stopped)
 505                 TRANSMUTE(Observer, this);
 506
 507         SetSpectatee(this, NULL);
 508
 509         // reset player keys
 510         this.itemkeys = 0;
 511
 512         MUTATOR_CALLHOOK(PutClientInServer, this);
 513
 514         if (IS_OBSERVER(this)) {
 515                 PutObserverInServer(this);
 516         } else if (IS_PLAYER(this)) {
 517                 if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
 518
 519                 PlayerState_attach(this);
 520                 accuracy_resend(this);
 521
 522                 if (this.team < 0)
 523                         JoinBestTeam(this, false, true);
 524
 525                 entity spot = SelectSpawnPoint(this, false);
 526                 if (!spot) {
 527                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_JOIN_NOSPAWNS);
 528                         return; // spawn failed
 529                 }
 530
 531                 TRANSMUTE(Player, this);
 532
 533                 this.wasplayer = true;
 534                 this.iscreature = true;
 535                 this.teleportable = TELEPORT_NORMAL;
 536                 if(!this.damagedbycontents)
 537                         IL_PUSH(g_damagedbycontents, this);
 538                 this.damagedbycontents = true;
 539                 set_movetype(this, MOVETYPE_WALK);
 540                 this.solid = SOLID_SLIDEBOX;
 541                 this.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_SOLID;
 542                 if (autocvar_g_playerclip_collisions)
 543                         this.dphitcontentsmask |= DPCONTENTS_PLAYERCLIP;
 544                 if (IS_BOT_CLIENT(this) && autocvar_g_botclip_collisions)
 545                         this.dphitcontentsmask |= DPCONTENTS_BOTCLIP;
 546                 this.frags = FRAGS_PLAYER;
 547                 if (INDEPENDENT_PLAYERS) MAKE_INDEPENDENT_PLAYER(this);
 548                 this.flags = FL_CLIENT | FL_PICKUPITEMS;
 549                 if (autocvar__notarget)
 550                         this.flags |= FL_NOTARGET;
 551                 this.takedamage = DAMAGE_AIM;
 552                 this.effects = EF_TELEPORT_BIT | EF_RESTARTANIM_BIT;
 553                 this.dmg = 2; // WTF
 554
 555                 if (warmup_stage) {
 556                         this.ammo_shells = warmup_start_ammo_shells;
 557                         this.ammo_nails = warmup_start_ammo_nails;
 558                         this.ammo_rockets = warmup_start_ammo_rockets;
 559                         this.ammo_cells = warmup_start_ammo_cells;
 560                         this.ammo_plasma = warmup_start_ammo_plasma;
 561                         this.ammo_fuel = warmup_start_ammo_fuel;
 562                         this.health = warmup_start_health;
 563                         this.armorvalue = warmup_start_armorvalue;
 564                         this.weapons = WARMUP_START_WEAPONS;
 565                 } else {
 566                         this.ammo_shells = start_ammo_shells;
 567                         this.ammo_nails = start_ammo_nails;
 568                         this.ammo_rockets = start_ammo_rockets;
 569                         this.ammo_cells = start_ammo_cells;
 570                         this.ammo_plasma = start_ammo_plasma;
 571                         this.ammo_fuel = start_ammo_fuel;
 572                         this.health = start_health;
 573                         this.armorvalue = start_armorvalue;
 574                         this.weapons = start_weapons;
 575                 }
 576                 SetSpectatee_status(this, 0);
 577
 578                 this.dual_weapons = '0 0 0';
 579
 580                 this.superweapons_finished = (this.weapons & WEPSET_SUPERWEAPONS) ? time + autocvar_g_balance_superweapons_time : 0;
 581
 582                 this.items = start_items;
 583
 584                 this.spawnshieldtime = time + autocvar_g_spawnshieldtime;
 585                 this.pauserotarmor_finished = time + autocvar_g_balance_pause_armor_rot_spawn;
 586                 this.pauserothealth_finished = time + autocvar_g_balance_pause_health_rot_spawn;
 587                 this.pauserotfuel_finished = time + autocvar_g_balance_pause_fuel_rot_spawn;
 588                 this.pauseregen_finished = time + autocvar_g_balance_pause_health_regen_spawn;
 589                 // extend the pause of rotting if client was reset at the beginning of the countdown
 590                 if (!autocvar_sv_ready_restart_after_countdown && time < game_starttime) { // TODO why is this cvar NOTted?
 591                         float f = game_starttime - time;
 592                         this.spawnshieldtime += f;
 593                         this.pauserotarmor_finished += f;
 594                         this.pauserothealth_finished += f;
 595                         this.pauseregen_finished += f;
 596                 }
 597                 this.damageforcescale = 2;
 598                 this.death_time = 0;
 599                 this.respawn_flags = 0;
 600                 this.respawn_time = 0;
 601                 this.stat_respawn_time = 0;
 602                 this.scale = autocvar_sv_player_scale;
 603                 this.fade_time = 0;
 604                 this.pain_frame = 0;
 605                 this.pain_finished = 0;
 606                 this.pushltime = 0;
 607                 setthink(this, func_null); // players have no think function
 608                 this.nextthink = 0;
 609                 this.dmg_team = 0;
 610                 this.ballistics_density = autocvar_g_ballistics_density_player;
 611
 612                 this.deadflag = DEAD_NO;
 613
 614                 this.angles = spot.angles;
 615                 this.angles_z = 0; // never spawn tilted even if the spot says to
 616                 if (IS_BOT_CLIENT(this))
 617                         this.v_angle = this.angles;
 618                 this.fixangle = true; // turn this way immediately
 619                 this.oldvelocity = this.velocity = '0 0 0';
 620                 this.avelocity = '0 0 0';
 621                 this.punchangle = '0 0 0';
 622                 this.punchvector = '0 0 0';
 623
 624                 this.strength_finished = 0;
 625                 this.invincible_finished = 0;
 626                 this.fire_endtime = -1;
 627                 this.revive_progress = 0;
 628                 this.revival_time = 0;
 629                 this.air_finished = time + 12;
 630
 631                 entity spawnevent = new_pure(spawnevent);
 632                 spawnevent.owner = this;
 633                 Net_LinkEntity(spawnevent, false, 0.5, SpawnEvent_Send);
 634
 635                 // Cut off any still running player sounds.
 636                 stopsound(this, CH_PLAYER_SINGLE);
 637
 638                 this.model = "";
 639                 FixPlayermodel(this);
 640                 this.drawonlytoclient = NULL;
 641
 642                 this.viewloc = NULL;
 643
 644                 this.crouch = false;
 645                 this.view_ofs = STAT(PL_VIEW_OFS, this);
 646                 setsize(this, STAT(PL_MIN, this), STAT(PL_MAX, this));
 647                 this.spawnorigin = spot.origin;
 648                 setorigin(this, spot.origin + '0 0 1' * (1 - this.mins.z - 24));
 649                 // don't reset back to last position, even if new position is stuck in solid
 650                 this.oldorigin = this.origin;
 651                 this.prevorigin = this.origin;
 652                 this.lastteleporttime = time; // prevent insane speeds due to changing origin
 653                 if(this.conveyor)
 654                         IL_REMOVE(g_conveyed, this);
 655                 this.conveyor = NULL; // prevent conveyors at the previous location from moving a freshly spawned player
 656                 this.hud = HUD_NORMAL;
 657
 658                 this.event_damage = PlayerDamage;
 659
 660                 if(!this.bot_attack)
 661                         IL_PUSH(g_bot_targets, this);
 662                 this.bot_attack = true;
 663                 if(!this.monster_attack)
 664                         IL_PUSH(g_monster_targets, this);
 665                 this.monster_attack = true;
 666                 navigation_dynamicgoal_init(this, false);
 667
 668                 PHYS_INPUT_BUTTON_ATCK(this) = PHYS_INPUT_BUTTON_JUMP(this) = PHYS_INPUT_BUTTON_ATCK2(this) = false;
 669
 670                 if (this.killcount == FRAGS_SPECTATOR) {
 671                         PlayerScore_Clear(this);
 672                         this.killcount = 0;
 673                 }
 674
 675                 for (int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 676                 {
 677                         .entity weaponentity = weaponentities[slot];
 678                         entity oldwep = this.(weaponentity);
 679                         CL_SpawnWeaponentity(this, weaponentity);
 680                         if(oldwep && oldwep.owner == this)
 681                                 this.(weaponentity).m_gunalign = oldwep.m_gunalign;
 682                 }
 683                 this.alpha = default_player_alpha;
 684                 this.colormod = '1 1 1' * autocvar_g_player_brightness;
 685                 this.exteriorweaponentity.alpha = default_weapon_alpha;
 686
 687                 this.speedrunning = false;
 688
 689                 target_voicescript_clear(this);
 690
 691                 // reset fields the weapons may use
 692                 FOREACH(Weapons, true, LAMBDA(
 693                         it.wr_resetplayer(it, this);
 694                         // reload all reloadable weapons
 695                         if (it.spawnflags & WEP_FLAG_RELOADABLE) {
 696                                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 697                                 {
 698                                         .entity weaponentity = weaponentities[slot];
 699                                         this.(weaponentity).weapon_load[it.m_id] = it.reloading_ammo;
 700                                 }
 701                         }
 702                 ));
 703
 704                 {
 705                         string s = spot.target;
 706                         spot.target = string_null;
 707                         SUB_UseTargets(spot, this, NULL);
 708                         spot.target = s;
 709                 }
 710
 711                 Unfreeze(this);
 712
 713                 MUTATOR_CALLHOOK(PlayerSpawn, this, spot);
 714
 715                 if (autocvar_spawn_debug)
 716                 {
 717                         sprint(this, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
 718                         delete(spot); // usefull for checking if there are spawnpoints, that let drop through the floor
 719                 }
 720
 721                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 722                 {
 723                         .entity weaponentity = weaponentities[slot];
 724                         if(slot == 0 || autocvar_g_weaponswitch_debug == 1)
 725                                 this.(weaponentity).m_switchweapon = w_getbestweapon(this, weaponentity);
 726                         else
 727                                 this.(weaponentity).m_switchweapon = WEP_Null;
 728                         this.(weaponentity).m_weapon = WEP_Null;
 729                         this.(weaponentity).weaponname = "";
 730                         this.(weaponentity).m_switchingweapon = WEP_Null;
 731                         this.(weaponentity).cnt = -1;
 732                 }
 733
 734                 MUTATOR_CALLHOOK(PlayerWeaponSelect, this);
 735
 736                 if (!warmup_stage && !this.alivetime)
 737                         this.alivetime = time;
 738
 739                 antilag_clear(this, CS(this));
 740         }
 741 }
 742
 743 void ClientInit_misc(entity this);
 744
 745 // TODO do we need all these fields, or should we stop autodetecting runtime
 746 // changes and just have a console command to update this?
 747 bool ClientInit_SendEntity(entity this, entity to, int sf)
 748 {
 749         WriteHeader(MSG_ENTITY, _ENT_CLIENT_INIT);
 750         return = true;
 751         msg_entity = to;
 752         // MSG_INIT replacement
 753         // TODO: make easier to use
 754         Registry_send_all();
 755         W_PROP_reload(MSG_ONE, to);
 756         ClientInit_misc(this);
 757         MUTATOR_CALLHOOK(Ent_Init);
 758 }
 759 void ClientInit_misc(entity this)
 760 {
 761         int channel = MSG_ONE;
 762         WriteHeader(channel, ENT_CLIENT_INIT);
 763         WriteByte(channel, g_nexball_meter_period * 32);
 764         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[0]));
 765         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[1]));
 766         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[2]));
 767         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[3]));
 768         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[0]));
 769         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[1]));
 770         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[2]));
 771         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[3]));
 772
 773         if(sv_foginterval && world.fog != "")
 774                 WriteString(channel, world.fog);
 775         else
 776                 WriteString(channel, "");
 777         WriteByte(channel, this.count * 255.0); // g_balance_armor_blockpercent
 778         WriteByte(channel, serverflags);
 779         WriteCoord(channel, autocvar_g_trueaim_minrange);
 780 }
 781
 782 void ClientInit_CheckUpdate(entity this)
 783 {
 784         this.nextthink = time;
 785         if(this.count != autocvar_g_balance_armor_blockpercent)
 786         {
 787                 this.count = autocvar_g_balance_armor_blockpercent;
 788                 this.SendFlags |= 1;
 789         }
 790 }
 791
 792 void ClientInit_Spawn()
 793 {
 794         entity e = new_pure(clientinit);
 795         setthink(e, ClientInit_CheckUpdate);
 796         Net_LinkEntity(e, false, 0, ClientInit_SendEntity);
 797
 798         ClientInit_CheckUpdate(e);
 799 }
 800
 801 /*
 802 =============
 803 SetNewParms
 804 =============
 805 */
 806 void SetNewParms ()
 807 {
 808         // initialize parms for a new player
 809         parm1 = -(86400 * 366);
 810
 811         MUTATOR_CALLHOOK(SetNewParms);
 812 }
 813
 814 /*
 815 =============
 816 SetChangeParms
 817 =============
 818 */
 819 void SetChangeParms (entity this)
 820 {
 821         // save parms for level change
 822         parm1 = this.parm_idlesince - time;
 823
 824         MUTATOR_CALLHOOK(SetChangeParms);
 825 }
 826
 827 /*
 828 =============
 829 DecodeLevelParms
 830 =============
 831 */
 832 void DecodeLevelParms(entity this)
 833 {
 834         // load parms
 835         this.parm_idlesince = parm1;
 836         if (this.parm_idlesince == -(86400 * 366))
 837                 this.parm_idlesince = time;
 838
 839         // whatever happens, allow 60 seconds of idling directly after connect for map loading
 840         this.parm_idlesince = max(this.parm_idlesince, time - sv_maxidle + 60);
 841
 842         MUTATOR_CALLHOOK(DecodeLevelParms);
 843 }
 844
 845 /*
 846 =============
 847 ClientKill
 848
 849 Called when a client types 'kill' in the console
 850 =============
 851 */
 852
 853 .float clientkill_nexttime;
 854 void ClientKill_Now_TeamChange(entity this)
 855 {
 856         if(this.killindicator_teamchange == -1)
 857         {
 858                 JoinBestTeam( this, false, true );
 859         }
 860         else if(this.killindicator_teamchange == -2)
 861         {
 862                 if(blockSpectators)
 863                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
 864                 PutObserverInServer(this);
 865         }
 866         else
 867                 SV_ChangeTeam(this, this.killindicator_teamchange - 1);
 868         this.killindicator_teamchange = 0;
 869 }
 870
 871 void ClientKill_Now(entity this)
 872 {
 873         if(this.vehicle)
 874         {
 875             vehicles_exit(this.vehicle, VHEF_RELEASE);
 876             if(!this.killindicator_teamchange)
 877             {
 878             this.vehicle_health = -1;
 879             Damage(this, this, this, 1 , DEATH_KILL.m_id, this.origin, '0 0 0');
 880             }
 881         }
 882
 883         if(this.killindicator && !wasfreed(this.killindicator))
 884                 delete(this.killindicator);
 885
 886         this.killindicator = NULL;
 887
 888         if(this.killindicator_teamchange)
 889                 ClientKill_Now_TeamChange(this);
 890
 891         if(!IS_SPEC(this) && !IS_OBSERVER(this))
 892                 Damage(this, this, this, 100000, DEATH_KILL.m_id, this.origin, '0 0 0');
 893
 894         // now I am sure the player IS dead
 895 }
 896 void KillIndicator_Think(entity this)
 897 {
 898         if (game_stopped)
 899         {
 900                 this.owner.killindicator = NULL;
 901                 delete(this);
 902                 return;
 903         }
 904
 905         if (this.owner.alpha < 0 && !this.owner.vehicle)
 906         {
 907                 this.owner.killindicator = NULL;
 908                 delete(this);
 909                 return;
 910         }
 911
 912         if(this.cnt <= 0)
 913         {
 914                 ClientKill_Now(this.owner);
 915                 return;
 916         }
 917     else if(this.health == 1) // health == 1 means that it's silent
 918     {
 919         this.nextthink = time + 1;
 920         this.cnt -= 1;
 921     }
 922         else
 923         {
 924                 if(this.cnt <= 10)
 925                         setmodel(this, MDL_NUM(this.cnt));
 926                 if(IS_REAL_CLIENT(this.owner))
 927                 {
 928                         if(this.cnt <= 10)
 929                                 { Send_Notification(NOTIF_ONE, this.owner, MSG_ANNCE, Announcer_PickNumber(CNT_KILL, this.cnt)); }
 930                 }
 931                 this.nextthink = time + 1;
 932                 this.cnt -= 1;
 933         }
 934 }
 935
 936 float clientkilltime;
 937 void ClientKill_TeamChange (entity this, float targetteam) // 0 = don't change, -1 = auto, -2 = spec
 938 {
 939         float killtime;
 940         float starttime;
 941
 942         if (game_stopped)
 943                 return;
 944
 945         killtime = autocvar_g_balance_kill_delay;
 946
 947     if(MUTATOR_CALLHOOK(ClientKill, this, killtime))
 948         return;
 949     killtime = M_ARGV(1, float);
 950
 951         this.killindicator_teamchange = targetteam;
 952
 953     if(!this.killindicator)
 954         {
 955                 if(!IS_DEAD(this))
 956                 {
 957                         killtime = max(killtime, this.clientkill_nexttime - time);
 958                         this.clientkill_nexttime = time + killtime + autocvar_g_balance_kill_antispam;
 959                 }
 960
 961                 if(killtime <= 0 || !IS_PLAYER(this) || IS_DEAD(this))
 962                 {
 963                         ClientKill_Now(this);
 964                 }
 965                 else
 966                 {
 967                         starttime = max(time, clientkilltime);
 968
 969                         this.killindicator = spawn();
 970                         this.killindicator.owner = this;
 971                         this.killindicator.scale = 0.5;
 972                         setattachment(this.killindicator, this, "");
 973                         setorigin(this.killindicator, '0 0 52');
 974                         setthink(this.killindicator, KillIndicator_Think);
 975                         this.killindicator.nextthink = starttime + (this.lip) * 0.05;
 976                         clientkilltime = max(clientkilltime, this.killindicator.nextthink + 0.05);
 977                         this.killindicator.cnt = ceil(killtime);
 978                         this.killindicator.count = bound(0, ceil(killtime), 10);
 979                         //sprint(this, strcat("^1You'll be dead in ", ftos(this.killindicator.cnt), " seconds\n"));
 980
 981                         IL_EACH(g_clones, it.enemy == this && !(it.effects & CSQCMODEL_EF_RESPAWNGHOST),
 982                         {
 983                                 it.killindicator = spawn();
 984                                 it.killindicator.owner = it;
 985                                 it.killindicator.scale = 0.5;
 986                                 setattachment(it.killindicator, it, "");
 987                                 setorigin(it.killindicator, '0 0 52');
 988                                 setthink(it.killindicator, KillIndicator_Think);
 989                                 it.killindicator.nextthink = starttime + (it.lip) * 0.05;
 990                                 //clientkilltime = max(clientkilltime, it.killindicator.nextthink + 0.05);
 991                                 it.killindicator.cnt = ceil(killtime);
 992                         });
 993                         this.lip = 0;
 994                 }
 995         }
 996         if(this.killindicator)
 997         {
 998                 if(targetteam == 0) // just die
 999                 {
1000                         this.killindicator.colormod = '0 0 0';
1001                         if(IS_REAL_CLIENT(this))
1002                         if(this.killindicator.cnt > 0)
1003                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_TEAMCHANGE_SUICIDE, this.killindicator.cnt);
1004                 }
1005                 else if(targetteam == -1) // auto
1006                 {
1007                         this.killindicator.colormod = '0 1 0';
1008                         if(IS_REAL_CLIENT(this))
1009                         if(this.killindicator.cnt > 0)
1010                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_TEAMCHANGE_AUTO, this.killindicator.cnt);
1011                 }
1012                 else if(targetteam == -2) // spectate
1013                 {
1014                         this.killindicator.colormod = '0.5 0.5 0.5';
1015                         if(IS_REAL_CLIENT(this))
1016                         if(this.killindicator.cnt > 0)
1017                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_TEAMCHANGE_SPECTATE, this.killindicator.cnt);
1018                 }
1019                 else
1020                 {
1021                         this.killindicator.colormod = Team_ColorRGB(targetteam);
1022                         if(IS_REAL_CLIENT(this))
1023                         if(this.killindicator.cnt > 0)
1024                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, APP_TEAM_NUM(targetteam, CENTER_TEAMCHANGE), this.killindicator.cnt);
1025                 }
1026         }
1027
1028 }
1029
1030 void ClientKill (entity this)
1031 {
1032         if(game_stopped) return;
1033         if(this.player_blocked) return;
1034         if(STAT(FROZEN, this)) return;
1035
1036         ClientKill_TeamChange(this, 0);
1037 }
1038
1039 void FixClientCvars(entity e)
1040 {
1041         // send prediction settings to the client
1042         stuffcmd(e, "\nin_bindmap 0 0\n");
1043         if(autocvar_g_antilag == 3) // client side hitscan
1044                 stuffcmd(e, "cl_cmd settemp cl_prydoncursor_notrace 0\n");
1045         if(autocvar_sv_gentle)
1046                 stuffcmd(e, "cl_cmd settemp cl_gentle 1\n");
1047
1048         stuffcmd(e, sprintf("\ncl_jumpspeedcap_min \"%s\"\n", autocvar_sv_jumpspeedcap_min));
1049         stuffcmd(e, sprintf("\ncl_jumpspeedcap_max \"%s\"\n", autocvar_sv_jumpspeedcap_max));
1050
1051         MUTATOR_CALLHOOK(FixClientCvars, e);
1052 }
1053
1054 float PlayerInIDList(entity p, string idlist)
1055 {
1056         float n, i;
1057         string s;
1058
1059         // NOTE: we do NOT check crypto_idfp_signed here, an unsigned ID is fine too for this
1060         if (!p.crypto_idfp)
1061                 return 0;
1062
1063         // this function allows abbreviated player IDs too!
1064         n = tokenize_console(idlist);
1065         for(i = 0; i < n; ++i)
1066         {
1067                 s = argv(i);
1068                 if(s == substring(p.crypto_idfp, 0, strlen(s)))
1069                         return 1;
1070         }
1071
1072         return 0;
1073 }
1074
1075 #ifdef DP_EXT_PRECONNECT
1076 /*
1077 =============
1078 ClientPreConnect
1079
1080 Called once (not at each match start) when a client begins a connection to the server
1081 =============
1082 */
1083 void ClientPreConnect(entity this)
1084 {
1085         if(autocvar_sv_eventlog)
1086         {
1087                 GameLogEcho(sprintf(":connect:%d:%d:%s",
1088                         this.playerid,
1089                         etof(this),
1090                         ((IS_REAL_CLIENT(this)) ? this.netaddress : "bot")
1091                 ));
1092         }
1093 }
1094 #endif
1095
1096 /**
1097 =============
1098 ClientConnect
1099
1100 Called when a client connects to the server
1101 =============
1102 */
1103 void ClientConnect(entity this)
1104 {
1105         if (Ban_MaybeEnforceBanOnce(this)) return;
1106         assert(!IS_CLIENT(this), return);
1107         this.flags |= FL_CLIENT;
1108         assert(player_count >= 0, player_count = 0);
1109
1110 #ifdef WATERMARK
1111         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_WATERMARK, WATERMARK);
1112 #endif
1113         this.version_nagtime = time + 10 + random() * 10;
1114         TRANSMUTE(Client, this);
1115
1116         // identify the right forced team
1117         if (autocvar_g_campaign)
1118         {
1119                 if (IS_REAL_CLIENT(this)) // only players, not bots
1120                 {
1121                         switch (autocvar_g_campaign_forceteam)
1122                         {
1123                                 case 1: this.team_forced = NUM_TEAM_1; break;
1124                                 case 2: this.team_forced = NUM_TEAM_2; break;
1125                                 case 3: this.team_forced = NUM_TEAM_3; break;
1126                                 case 4: this.team_forced = NUM_TEAM_4; break;
1127                                 default: this.team_forced = 0;
1128                         }
1129                 }
1130         }
1131         else if (PlayerInIDList(this, autocvar_g_forced_team_red))    this.team_forced = NUM_TEAM_1;
1132         else if (PlayerInIDList(this, autocvar_g_forced_team_blue))   this.team_forced = NUM_TEAM_2;
1133         else if (PlayerInIDList(this, autocvar_g_forced_team_yellow)) this.team_forced = NUM_TEAM_3;
1134         else if (PlayerInIDList(this, autocvar_g_forced_team_pink))   this.team_forced = NUM_TEAM_4;
1135         else switch (autocvar_g_forced_team_otherwise)
1136         {
1137                 default: this.team_forced = 0; break;
1138                 case "red": this.team_forced = NUM_TEAM_1; break;
1139                 case "blue": this.team_forced = NUM_TEAM_2; break;
1140                 case "yellow": this.team_forced = NUM_TEAM_3; break;
1141                 case "pink": this.team_forced = NUM_TEAM_4; break;
1142                 case "spectate":
1143                 case "spectator":
1144                         this.team_forced = -1;
1145                         break;
1146         }
1147         if (!teamplay && this.team_forced > 0) this.team_forced = 0;
1148
1149     {
1150         int id = this.playerid;
1151         this.playerid = 0; // silent
1152             JoinBestTeam(this, false, false); // if the team number is valid, keep it
1153             this.playerid = id;
1154     }
1155
1156         if (autocvar_sv_spectate || autocvar_g_campaign || this.team_forced < 0) {
1157                 TRANSMUTE(Observer, this);
1158         } else {
1159                 if (!teamplay || autocvar_g_balance_teams) {
1160                         TRANSMUTE(Player, this);
1161                         campaign_bots_may_start = true;
1162                 } else {
1163                         TRANSMUTE(Observer, this); // do it anyway
1164                 }
1165         }
1166
1167         PlayerStats_GameReport_AddEvent(sprintf("kills-%d", this.playerid));
1168
1169         // always track bots, don't ask for cl_allow_uidtracking
1170     if (IS_BOT_CLIENT(this)) PlayerStats_GameReport_AddPlayer(this);
1171
1172         if (autocvar_sv_eventlog)
1173                 GameLogEcho(strcat(":join:", ftos(this.playerid), ":", ftos(etof(this)), ":", ((IS_REAL_CLIENT(this)) ? this.netaddress : "bot"), ":", playername(this, false)));
1174
1175         LogTeamchange(this.playerid, this.team, 1);
1176
1177         this.just_joined = true;  // stop spamming the eventlog with additional lines when the client connects
1178
1179         this.netname_previous = strzone(this.netname);
1180
1181         if(teamplay && IS_PLAYER(this))
1182                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, APP_TEAM_NUM(this.team, INFO_JOIN_CONNECT_TEAM), this.netname);
1183         else
1184                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_JOIN_CONNECT, this.netname);
1185
1186         stuffcmd(this, clientstuff, "\n");
1187         stuffcmd(this, "cl_particles_reloadeffects\n"); // TODO do we still need this?
1188
1189         FixClientCvars(this);
1190
1191         // get version info from player
1192         stuffcmd(this, "cmd clientversion $gameversion\n");
1193
1194         // notify about available teams
1195         if (teamplay)
1196         {
1197                 CheckAllowedTeams(this);
1198                 int t = 0;
1199                 if (c1 >= 0) t |= BIT(0);
1200                 if (c2 >= 0) t |= BIT(1);
1201                 if (c3 >= 0) t |= BIT(2);
1202                 if (c4 >= 0) t |= BIT(3);
1203                 stuffcmd(this, sprintf("set _teams_available %d\n", t));
1204         }
1205         else
1206         {
1207                 stuffcmd(this, "set _teams_available 0\n");
1208         }
1209
1210         bot_relinkplayerlist();
1211
1212         this.spectatortime = time;
1213         if (blockSpectators)
1214         {
1215                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
1216         }
1217
1218         this.jointime = time;
1219         this.allowed_timeouts = autocvar_sv_timeout_number;
1220
1221         if (IS_REAL_CLIENT(this))
1222         {
1223                 if (g_weaponarena_weapons == WEPSET(TUBA))
1224                         stuffcmd(this, "cl_cmd settemp chase_active 1\n");
1225         }
1226
1227         if (!sv_foginterval && world.fog != "")
1228                 stuffcmd(this, strcat("\nfog ", world.fog, "\nr_fog_exp2 0\nr_drawfog 1\n"));
1229
1230         if (autocvar_sv_teamnagger && !(autocvar_bot_vs_human && AvailableTeams() == 2))
1231                 if(!MUTATOR_CALLHOOK(HideTeamNagger, this))
1232                         send_CSQC_teamnagger();
1233
1234         CSQCMODEL_AUTOINIT(this);
1235
1236         this.model_randomizer = random();
1237
1238         if (IS_REAL_CLIENT(this))
1239                 sv_notice_join(this);
1240
1241         // update physics stats (players can spawn before physics runs)
1242         STAT(MOVEVARS_HIGHSPEED, this) = autocvar_g_movement_highspeed;
1243         MUTATOR_CALLHOOK(PlayerPhysics_UpdateStats, this); // do it BEFORE the function so we can modify highspeed!
1244         Physics_UpdateStats(this, PHYS_HIGHSPEED(this));
1245
1246         IL_EACH(g_initforplayer, it.init_for_player, {
1247                 it.init_for_player(it, this);
1248         });
1249
1250         MUTATOR_CALLHOOK(ClientConnect, this);
1251
1252         if (IS_REAL_CLIENT(this))
1253         {
1254                 if (!autocvar_g_campaign && !IS_PLAYER(this))
1255                 {
1256                         this.motd_actived_time = -1;
1257                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOTD, getwelcomemessage(this));
1258                 }
1259         }
1260 }
1261 /*
1262 =============
1263 ClientDisconnect
1264
1265 Called when a client disconnects from the server
1266 =============
1267 */
1268 .entity chatbubbleentity;
1269 void ReadyCount();
1270 void ClientDisconnect(entity this)
1271 {
1272         assert(IS_CLIENT(this), return);
1273
1274         PlayerStats_GameReport_FinalizePlayer(this);
1275         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
1276         if (this.active_minigame) part_minigame(this);
1277         if (IS_PLAYER(this)) Send_Effect(EFFECT_SPAWN_NEUTRAL, this.origin, '0 0 0', 1);
1278
1279         if (autocvar_sv_eventlog)
1280                 GameLogEcho(strcat(":part:", ftos(this.playerid)));
1281
1282         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_QUIT_DISCONNECT, this.netname);
1283
1284         if(IS_SPEC(this))
1285                 SetSpectatee(this, NULL);
1286
1287     MUTATOR_CALLHOOK(ClientDisconnect, this);
1288
1289         ClientState_detach(this);
1290
1291         Portal_ClearAll(this);
1292
1293         Unfreeze(this);
1294
1295         RemoveGrapplingHooks(this);
1296
1297         // Here, everything has been done that requires this player to be a client.
1298
1299         this.flags &= ~FL_CLIENT;
1300
1301         if (this.chatbubbleentity) delete(this.chatbubbleentity);
1302         if (this.killindicator) delete(this.killindicator);
1303
1304         WaypointSprite_PlayerGone(this);
1305
1306         bot_relinkplayerlist();
1307
1308         if (this.netname_previous) strunzone(this.netname_previous);
1309         if (this.clientstatus) strunzone(this.clientstatus);
1310         if (this.weaponorder_byimpulse) strunzone(this.weaponorder_byimpulse);
1311         if (this.personal) delete(this.personal);
1312
1313         this.playerid = 0;
1314         ReadyCount();
1315         if (vote_called && IS_REAL_CLIENT(this)) VoteCount(false);
1316
1317         ONREMOVE(this);
1318 }
1319
1320 void ChatBubbleThink(entity this)
1321 {
1322         this.nextthink = time;
1323         if ((this.owner.alpha < 0) || this.owner.chatbubbleentity != this)
1324         {
1325                 if(this.owner) // but why can that ever be NULL?
1326                         this.owner.chatbubbleentity = NULL;
1327                 delete(this);
1328                 return;
1329         }
1330
1331         this.mdl = "";
1332
1333         if ( !IS_DEAD(this.owner) && IS_PLAYER(this.owner) )
1334         {
1335                 if ( this.owner.active_minigame )
1336                         this.mdl = "models/sprites/minigame_busy.iqm";
1337                 else if (PHYS_INPUT_BUTTON_CHAT(this.owner))
1338                         this.mdl = "models/misc/chatbubble.spr";
1339         }
1340
1341         if ( this.model != this.mdl )
1342                 _setmodel(this, this.mdl);
1343
1344 }
1345
1346 void UpdateChatBubble(entity this)
1347 {
1348         if (this.alpha < 0)
1349                 return;
1350         // spawn a chatbubble entity if needed
1351         if (!this.chatbubbleentity)
1352         {
1353                 this.chatbubbleentity = new(chatbubbleentity);
1354                 this.chatbubbleentity.owner = this;
1355                 this.chatbubbleentity.exteriormodeltoclient = this;
1356                 setthink(this.chatbubbleentity, ChatBubbleThink);
1357                 this.chatbubbleentity.nextthink = time;
1358                 setmodel(this.chatbubbleentity, MDL_CHAT); // precision set below
1359                 //setorigin(this.chatbubbleentity, this.origin + '0 0 15' + this.maxs_z * '0 0 1');
1360                 setorigin(this.chatbubbleentity, '0 0 15' + this.maxs_z * '0 0 1');
1361                 setattachment(this.chatbubbleentity, this, "");  // sticks to moving player better, also conserves bandwidth
1362                 this.chatbubbleentity.mdl = this.chatbubbleentity.model;
1363                 //this.chatbubbleentity.model = "";
1364                 this.chatbubbleentity.effects = EF_LOWPRECISION;
1365         }
1366 }
1367
1368
1369 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
1370 // added to the model skins
1371 /*void UpdateColorModHack()
1372 {
1373         float c;
1374         c = this.clientcolors & 15;
1375         // LordHavoc: only bothering to support white, green, red, yellow, blue
1376              if (!teamplay) this.colormod = '0 0 0';
1377         else if (c ==  0) this.colormod = '1.00 1.00 1.00';
1378         else if (c ==  3) this.colormod = '0.10 1.73 0.10';
1379         else if (c ==  4) this.colormod = '1.73 0.10 0.10';
1380         else if (c == 12) this.colormod = '1.22 1.22 0.10';
1381         else if (c == 13) this.colormod = '0.10 0.10 1.73';
1382         else this.colormod = '1 1 1';
1383 }*/
1384
1385 void respawn(entity this)
1386 {
1387         if(this.alpha >= 0 && autocvar_g_respawn_ghosts)
1388         {
1389                 this.solid = SOLID_NOT;
1390                 this.takedamage = DAMAGE_NO;
1391                 set_movetype(this, MOVETYPE_FLY);
1392                 this.velocity = '0 0 1' * autocvar_g_respawn_ghosts_speed;
1393                 this.avelocity = randomvec() * autocvar_g_respawn_ghosts_speed * 3 - randomvec() * autocvar_g_respawn_ghosts_speed * 3;
1394                 this.effects |= CSQCMODEL_EF_RESPAWNGHOST;
1395                 Send_Effect(EFFECT_RESPAWN_GHOST, this.origin, '0 0 0', 1);
1396                 if(autocvar_g_respawn_ghosts_maxtime)
1397                         SUB_SetFade (this, time + autocvar_g_respawn_ghosts_maxtime / 2 + random () * (autocvar_g_respawn_ghosts_maxtime - autocvar_g_respawn_ghosts_maxtime / 2), 1.5);
1398         }
1399
1400         CopyBody(this, 1);
1401
1402         this.effects |= EF_NODRAW; // prevent another CopyBody
1403         PutClientInServer(this);
1404 }
1405
1406 void play_countdown(entity this, float finished, Sound samp)
1407 {
1408     TC(Sound, samp);
1409         if(IS_REAL_CLIENT(this))
1410                 if(floor(finished - time - frametime) != floor(finished - time))
1411                         if(finished - time < 6)
1412                                 sound (this, CH_INFO, samp, VOL_BASE, ATTEN_NORM);
1413 }
1414
1415 void player_powerups(entity this)
1416 {
1417         // add a way to see what the items were BEFORE all of these checks for the mutator hook
1418         int items_prev = this.items;
1419
1420         if((this.items & IT_USING_JETPACK) && !IS_DEAD(this) && !game_stopped)
1421                 this.modelflags |= MF_ROCKET;
1422         else
1423                 this.modelflags &= ~MF_ROCKET;
1424
1425         this.effects &= ~(EF_RED | EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT | EF_FLAME | EF_NODEPTHTEST);
1426
1427         if((this.alpha < 0 || IS_DEAD(this)) && !this.vehicle) // don't apply the flags if the player is gibbed
1428                 return;
1429
1430         Fire_ApplyDamage(this);
1431         Fire_ApplyEffect(this);
1432
1433         if (!g_instagib)
1434         {
1435                 if (this.items & ITEM_Strength.m_itemid)
1436                 {
1437                         play_countdown(this, this.strength_finished, SND_POWEROFF);
1438                         this.effects = this.effects | (EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT);
1439                         if (time > this.strength_finished)
1440                         {
1441                                 this.items = this.items - (this.items & ITEM_Strength.m_itemid);
1442                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERDOWN_STRENGTH, this.netname);
1443                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERDOWN_STRENGTH);
1444                         }
1445                 }
1446                 else
1447                 {
1448                         if (time < this.strength_finished)
1449                         {
1450                                 this.items = this.items | ITEM_Strength.m_itemid;
1451                                 if(!g_cts)
1452                                         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERUP_STRENGTH, this.netname);
1453                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERUP_STRENGTH);
1454                         }
1455                 }
1456                 if (this.items & ITEM_Shield.m_itemid)
1457                 {
1458                         play_countdown(this, this.invincible_finished, SND_POWEROFF);
1459                         this.effects = this.effects | (EF_RED | EF_ADDITIVE | EF_FULLBRIGHT);
1460                         if (time > this.invincible_finished)
1461                         {
1462                                 this.items = this.items - (this.items & ITEM_Shield.m_itemid);
1463                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERDOWN_SHIELD, this.netname);
1464                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERDOWN_SHIELD);
1465                         }
1466                 }
1467                 else
1468                 {
1469                         if (time < this.invincible_finished)
1470                         {
1471                                 this.items = this.items | ITEM_Shield.m_itemid;
1472                                 if(!g_cts)
1473                                         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERUP_SHIELD, this.netname);
1474                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERUP_SHIELD);
1475                         }
1476                 }
1477                 if (this.items & IT_SUPERWEAPON)
1478                 {
1479                         if (!(this.weapons & WEPSET_SUPERWEAPONS))
1480                         {
1481                                 this.superweapons_finished = 0;
1482                                 this.items = this.items - (this.items & IT_SUPERWEAPON);
1483                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_LOST, this.netname);
1484                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_LOST);
1485                         }
1486                         else if (this.items & IT_UNLIMITED_SUPERWEAPONS)
1487                         {
1488                                 // don't let them run out
1489                         }
1490                         else
1491                         {
1492                                 play_countdown(this, this.superweapons_finished, SND_POWEROFF);
1493                                 if (time > this.superweapons_finished)
1494                                 {
1495                                         this.items = this.items - (this.items & IT_SUPERWEAPON);
1496                                         this.weapons &= ~WEPSET_SUPERWEAPONS;
1497                                         //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_BROKEN, this.netname);
1498                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_BROKEN);
1499                                 }
1500                         }
1501                 }
1502                 else if(this.weapons & WEPSET_SUPERWEAPONS)
1503                 {
1504                         if (time < this.superweapons_finished || (this.items & IT_UNLIMITED_SUPERWEAPONS))
1505                         {
1506                                 this.items = this.items | IT_SUPERWEAPON;
1507                                 if(!g_cts)
1508                                         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_PICKUP, this.netname);
1509                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_PICKUP);
1510                         }
1511                         else
1512                         {
1513                                 this.superweapons_finished = 0;
1514                                 this.weapons &= ~WEPSET_SUPERWEAPONS;
1515                         }
1516                 }
1517                 else
1518                 {
1519                         this.superweapons_finished = 0;
1520                 }
1521         }
1522
1523         if(autocvar_g_nodepthtestplayers)
1524                 this.effects = this.effects | EF_NODEPTHTEST;
1525
1526         if(autocvar_g_fullbrightplayers)
1527                 this.effects = this.effects | EF_FULLBRIGHT;
1528
1529         if (time >= game_starttime)
1530         if (time < this.spawnshieldtime)
1531                 this.effects = this.effects | (EF_ADDITIVE | EF_FULLBRIGHT);
1532
1533         MUTATOR_CALLHOOK(PlayerPowerups, this, items_prev);
1534 }
1535
1536 float CalcRegen(float current, float stable, float regenfactor, float regenframetime)
1537 {
1538         if(current > stable)
1539                 return current;
1540         else if(current > stable - 0.25) // when close enough, "snap"
1541                 return stable;
1542         else
1543                 return min(stable, current + (stable - current) * regenfactor * regenframetime);
1544 }
1545
1546 float CalcRot(float current, float stable, float rotfactor, float rotframetime)
1547 {
1548         if(current < stable)
1549                 return current;
1550         else if(current < stable + 0.25) // when close enough, "snap"
1551                 return stable;
1552         else
1553                 return max(stable, current + (stable - current) * rotfactor * rotframetime);
1554 }
1555
1556 float CalcRotRegen(float current, float regenstable, float regenfactor, float regenlinear, float regenframetime, float rotstable, float rotfactor, float rotlinear, float rotframetime, float limit)
1557 {
1558         if(current > rotstable)
1559         {
1560                 if(rotframetime > 0)
1561                 {
1562                         current = CalcRot(current, rotstable, rotfactor, rotframetime);
1563                         current = max(rotstable, current - rotlinear * rotframetime);
1564                 }
1565         }
1566         else if(current < regenstable)
1567         {
1568                 if(regenframetime > 0)
1569                 {
1570                         current = CalcRegen(current, regenstable, regenfactor, regenframetime);
1571                         current = min(regenstable, current + regenlinear * regenframetime);
1572                 }
1573         }
1574
1575         if(current > limit)
1576                 current = limit;
1577
1578         return current;
1579 }
1580
1581 void player_regen(entity this)
1582 {
1583         float max_mod, regen_mod, rot_mod, limit_mod;
1584         max_mod = regen_mod = rot_mod = limit_mod = 1;
1585
1586         float regen_health = autocvar_g_balance_health_regen;
1587         float regen_health_linear = autocvar_g_balance_health_regenlinear;
1588         float regen_health_rot = autocvar_g_balance_health_rot;
1589         float regen_health_rotlinear = autocvar_g_balance_health_rotlinear;
1590         float regen_health_stable = autocvar_g_balance_health_regenstable;
1591         float regen_health_rotstable = autocvar_g_balance_health_rotstable;
1592         bool mutator_returnvalue = MUTATOR_CALLHOOK(PlayerRegen, this, max_mod, regen_mod, rot_mod, limit_mod, regen_health, regen_health_linear, regen_health_rot,
1593                 regen_health_rotlinear, regen_health_stable, regen_health_rotstable);
1594         max_mod = M_ARGV(1, float);
1595         regen_mod = M_ARGV(2, float);
1596         rot_mod = M_ARGV(3, float);
1597         limit_mod = M_ARGV(4, float);
1598         regen_health = M_ARGV(5, float);
1599         regen_health_linear = M_ARGV(6, float);
1600         regen_health_rot = M_ARGV(7, float);
1601         regen_health_rotlinear = M_ARGV(8, float);
1602         regen_health_stable = M_ARGV(9, float);
1603         regen_health_rotstable = M_ARGV(10, float);
1604
1605
1606         if(!mutator_returnvalue)
1607         if(!STAT(FROZEN, this))
1608         {
1609                 float mina, maxa, limith, limita;
1610                 maxa = autocvar_g_balance_armor_rotstable;
1611                 mina = autocvar_g_balance_armor_regenstable;
1612                 limith = autocvar_g_balance_health_limit;
1613                 limita = autocvar_g_balance_armor_limit;
1614
1615                 regen_health_rotstable = regen_health_rotstable * max_mod;
1616                 regen_health_stable = regen_health_stable * max_mod;
1617                 limith = limith * limit_mod;
1618                 limita = limita * limit_mod;
1619
1620                 this.armorvalue = CalcRotRegen(this.armorvalue, mina, autocvar_g_balance_armor_regen, autocvar_g_balance_armor_regenlinear, regen_mod * frametime * (time > this.pauseregen_finished), maxa, autocvar_g_balance_armor_rot, autocvar_g_balance_armor_rotlinear, rot_mod * frametime * (time > this.pauserotarmor_finished), limita);
1621                 this.health = CalcRotRegen(this.health, regen_health_stable, regen_health, regen_health_linear, regen_mod * frametime * (time > this.pauseregen_finished), regen_health_rotstable, regen_health_rot, regen_health_rotlinear, rot_mod * frametime * (time > this.pauserothealth_finished), limith);
1622         }
1623
1624         // if player rotted to death...  die!
1625         // check this outside above checks, as player may still be able to rot to death
1626         if(this.health < 1)
1627         {
1628                 if(this.vehicle)
1629                         vehicles_exit(this.vehicle, VHEF_RELEASE);
1630                 if(this.event_damage)
1631                         this.event_damage(this, this, this, 1, DEATH_ROT.m_id, this.origin, '0 0 0');
1632         }
1633
1634         if (!(this.items & IT_UNLIMITED_WEAPON_AMMO))
1635         {
1636                 float minf, maxf, limitf;
1637
1638                 maxf = autocvar_g_balance_fuel_rotstable;
1639                 minf = autocvar_g_balance_fuel_regenstable;
1640                 limitf = autocvar_g_balance_fuel_limit;
1641
1642                 this.ammo_fuel = CalcRotRegen(this.ammo_fuel, minf, autocvar_g_balance_fuel_regen, autocvar_g_balance_fuel_regenlinear, frametime * (time > this.pauseregen_finished) * ((this.items & ITEM_JetpackRegen.m_itemid) != 0), maxf, autocvar_g_balance_fuel_rot, autocvar_g_balance_fuel_rotlinear, frametime * (time > this.pauserotfuel_finished), limitf);
1643         }
1644 }
1645
1646 bool zoomstate_set;
1647 void SetZoomState(entity this, float newzoom)
1648 {
1649         if(newzoom != this.zoomstate)
1650         {
1651                 this.zoomstate = newzoom;
1652                 ClientData_Touch(this);
1653         }
1654         zoomstate_set = true;
1655 }
1656
1657 void GetPressedKeys(entity this)
1658 {
1659         MUTATOR_CALLHOOK(GetPressedKeys, this);
1660         int keys = STAT(PRESSED_KEYS, this);
1661         keys = BITSET(keys, KEY_FORWARD,        this.movement.x > 0);
1662         keys = BITSET(keys, KEY_BACKWARD,       this.movement.x < 0);
1663         keys = BITSET(keys, KEY_RIGHT,          this.movement.y > 0);
1664         keys = BITSET(keys, KEY_LEFT,           this.movement.y < 0);
1665
1666         keys = BITSET(keys, KEY_JUMP,           PHYS_INPUT_BUTTON_JUMP(this));
1667         keys = BITSET(keys, KEY_CROUCH,         PHYS_INPUT_BUTTON_CROUCH(this));
1668         keys = BITSET(keys, KEY_ATCK,           PHYS_INPUT_BUTTON_ATCK(this));
1669         keys = BITSET(keys, KEY_ATCK2,          PHYS_INPUT_BUTTON_ATCK2(this));
1670         this.pressedkeys = keys; // store for other users
1671
1672         STAT(PRESSED_KEYS, this) = keys;
1673 }
1674
1675 /*
1676 ======================
1677 spectate mode routines
1678 ======================
1679 */
1680
1681 void SpectateCopy(entity this, entity spectatee)
1682 {
1683     TC(Client, this); TC(Client, spectatee);
1684
1685         MUTATOR_CALLHOOK(SpectateCopy, spectatee, this);
1686         PS(this) = PS(spectatee);
1687         this.armortype = spectatee.armortype;
1688         this.armorvalue = spectatee.armorvalue;
1689         this.ammo_cells = spectatee.ammo_cells;
1690         this.ammo_plasma = spectatee.ammo_plasma;
1691         this.ammo_shells = spectatee.ammo_shells;
1692         this.ammo_nails = spectatee.ammo_nails;
1693         this.ammo_rockets = spectatee.ammo_rockets;
1694         this.ammo_fuel = spectatee.ammo_fuel;
1695         this.clip_load = spectatee.clip_load;
1696         this.clip_size = spectatee.clip_size;
1697         this.effects = spectatee.effects & EFMASK_CHEAP; // eat performance
1698         this.health = spectatee.health;
1699         this.impulse = 0;
1700         this.items = spectatee.items;
1701         this.last_pickup = spectatee.last_pickup;
1702         this.hit_time = spectatee.hit_time;
1703         this.strength_finished = spectatee.strength_finished;
1704         this.invincible_finished = spectatee.invincible_finished;
1705         this.superweapons_finished = spectatee.superweapons_finished;
1706         STAT(PRESSED_KEYS, this) = STAT(PRESSED_KEYS, spectatee);
1707         this.weapons = spectatee.weapons;
1708         this.dual_weapons = spectatee.dual_weapons;
1709         this.vortex_charge = spectatee.vortex_charge;
1710         this.vortex_chargepool_ammo = spectatee.vortex_chargepool_ammo;
1711         this.okvortex_charge = spectatee.okvortex_charge;
1712         this.okvortex_chargepool_ammo = spectatee.okvortex_chargepool_ammo;
1713         this.hagar_load = spectatee.hagar_load;
1714         this.arc_heat_percent = spectatee.arc_heat_percent;
1715         this.minelayer_mines = spectatee.minelayer_mines;
1716         this.punchangle = spectatee.punchangle;
1717         this.view_ofs = spectatee.view_ofs;
1718         this.velocity = spectatee.velocity;
1719         this.dmg_take = spectatee.dmg_take;
1720         this.dmg_save = spectatee.dmg_save;
1721         this.dmg_inflictor = spectatee.dmg_inflictor;
1722         this.v_angle = spectatee.v_angle;
1723         this.angles = spectatee.v_angle;
1724         STAT(FROZEN, this) = STAT(FROZEN, spectatee);
1725         this.revive_progress = spectatee.revive_progress;
1726         this.viewloc = spectatee.viewloc;
1727         if(!PHYS_INPUT_BUTTON_USE(this) && STAT(CAMERA_SPECTATOR, this) != 2)
1728                 this.fixangle = true;
1729         setorigin(this, spectatee.origin);
1730         setsize(this, spectatee.mins, spectatee.maxs);
1731         SetZoomState(this, spectatee.zoomstate);
1732
1733         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1734         {
1735                 .entity weaponentity = weaponentities[slot];
1736                 this.(weaponentity) = spectatee.(weaponentity);
1737         }
1738
1739         for(int slot = 0; slot < MAX_AXH; ++slot)
1740         {
1741                 this.(AuxiliaryXhair[slot]) = spectatee.(AuxiliaryXhair[slot]);
1742         }
1743
1744     anticheat_spectatecopy(this, spectatee);
1745         this.hud = spectatee.hud;
1746         if(spectatee.vehicle)
1747     {
1748         this.angles = spectatee.v_angle;
1749
1750         //this.fixangle = false;
1751         //this.velocity = spectatee.vehicle.velocity;
1752         this.vehicle_health = spectatee.vehicle_health;
1753         this.vehicle_shield = spectatee.vehicle_shield;
1754         this.vehicle_energy = spectatee.vehicle_energy;
1755         this.vehicle_ammo1 = spectatee.vehicle_ammo1;
1756         this.vehicle_ammo2 = spectatee.vehicle_ammo2;
1757         this.vehicle_reload1 = spectatee.vehicle_reload1;
1758         this.vehicle_reload2 = spectatee.vehicle_reload2;
1759
1760         //msg_entity = this;
1761
1762        // WriteByte (MSG_ONE, SVC_SETVIEWANGLES);
1763             //WriteAngle(MSG_ONE,  spectatee.v_angle.x);
1764            // WriteAngle(MSG_ONE,  spectatee.v_angle.y);
1765            // WriteAngle(MSG_ONE,  spectatee.v_angle.z);
1766
1767         //WriteByte (MSG_ONE, SVC_SETVIEW);
1768         //    WriteEntity(MSG_ONE, this);
1769         //makevectors(spectatee.v_angle);
1770         //setorigin(this, spectatee.origin - v_forward * 400 + v_up * 300);*/
1771     }
1772 }
1773
1774 bool SpectateUpdate(entity this)
1775 {
1776         if(!this.enemy)
1777                 return false;
1778
1779         if(!IS_PLAYER(this.enemy) || this == this.enemy)
1780         {
1781                 SetSpectatee(this, NULL);
1782                 return false;
1783         }
1784
1785         SpectateCopy(this, this.enemy);
1786
1787         return true;
1788 }
1789
1790 bool SpectateSet(entity this)
1791 {
1792         if(!IS_PLAYER(this.enemy))
1793                 return false;
1794
1795         ClientData_Touch(this.enemy);
1796
1797         msg_entity = this;
1798         WriteByte(MSG_ONE, SVC_SETVIEW);
1799         WriteEntity(MSG_ONE, this.enemy);
1800         set_movetype(this, MOVETYPE_NONE);
1801         accuracy_resend(this);
1802
1803         if(!SpectateUpdate(this))
1804                 PutObserverInServer(this);
1805
1806         return true;
1807 }
1808
1809 void SetSpectatee_status(entity this, int spectatee_num)
1810 {
1811         int oldspectatee_status = this.spectatee_status;
1812         this.spectatee_status = spectatee_num;
1813
1814         if (this.spectatee_status != oldspectatee_status)
1815         {
1816                 ClientData_Touch(this);
1817                 if (g_race || g_cts) race_InitSpectator();
1818         }
1819 }
1820
1821 void SetSpectatee(entity this, entity spectatee)
1822 {
1823         if(IS_BOT_CLIENT(this))
1824                 return; // bots abuse .enemy, this code is useless to them
1825
1826         entity old_spectatee = this.enemy;
1827
1828         this.enemy = spectatee;
1829
1830         // WEAPONTODO
1831         // these are required to fix the spectator bug with arc
1832         if(old_spectatee)
1833         {
1834                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1835                 {
1836                         .entity weaponentity = weaponentities[slot];
1837                         if(old_spectatee.(weaponentity).arc_beam)
1838                                 old_spectatee.(weaponentity).arc_beam.SendFlags |= ARC_SF_SETTINGS;
1839                 }
1840         }
1841         if(this.enemy)
1842         {
1843                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1844                 {
1845                         .entity weaponentity = weaponentities[slot];
1846                         if(this.enemy.(weaponentity).arc_beam)
1847                                 this.enemy.(weaponentity).arc_beam.SendFlags |= ARC_SF_SETTINGS;
1848                 }
1849         }
1850
1851         if (this.enemy)
1852                 SetSpectatee_status(this, etof(this.enemy));
1853
1854         // needed to update spectator list
1855         if(old_spectatee) { ClientData_Touch(old_spectatee); }
1856 }
1857
1858 bool Spectate(entity this, entity pl)
1859 {
1860         if(MUTATOR_CALLHOOK(SpectateSet, this, pl))
1861                 return false;
1862         pl = M_ARGV(1, entity);
1863
1864         SetSpectatee(this, pl);
1865         return SpectateSet(this);
1866 }
1867
1868 bool SpectateNext(entity this)
1869 {
1870         entity ent = find(this.enemy, classname, STR_PLAYER);
1871
1872         if (MUTATOR_CALLHOOK(SpectateNext, this, ent))
1873                 ent = M_ARGV(1, entity);
1874         else if (!ent)
1875                 ent = find(ent, classname, STR_PLAYER);
1876
1877         if(ent) { SetSpectatee(this, ent); }
1878
1879         return SpectateSet(this);
1880 }
1881
1882 bool SpectatePrev(entity this)
1883 {
1884         // NOTE: chain order is from the highest to the lower entnum (unlike find)
1885         entity ent = findchain(classname, STR_PLAYER);
1886         if (!ent) // no player
1887                 return false;
1888
1889         entity first = ent;
1890         // skip players until current spectated player
1891         if(this.enemy)
1892         while(ent && ent != this.enemy)
1893                 ent = ent.chain;
1894
1895         switch (MUTATOR_CALLHOOK(SpectatePrev, this, ent, first))
1896         {
1897                 case MUT_SPECPREV_FOUND:
1898                     ent = M_ARGV(1, entity);
1899                     break;
1900                 case MUT_SPECPREV_RETURN:
1901                     return true;
1902                 case MUT_SPECPREV_CONTINUE:
1903                 default:
1904                 {
1905                         if(ent.chain)
1906                                 ent = ent.chain;
1907                         else
1908                                 ent = first;
1909                         break;
1910                 }
1911         }
1912
1913         SetSpectatee(this, ent);
1914         return SpectateSet(this);
1915 }
1916
1917 /*
1918 =============
1919 ShowRespawnCountdown()
1920
1921 Update a respawn countdown display.
1922 =============
1923 */
1924 void ShowRespawnCountdown(entity this)
1925 {
1926         float number;
1927         if(!IS_DEAD(this)) // just respawned?
1928                 return;
1929         else
1930         {
1931                 number = ceil(this.respawn_time - time);
1932                 if(number <= 0)
1933                         return;
1934                 if(number <= this.respawn_countdown)
1935                 {
1936                         this.respawn_countdown = number - 1;
1937                         if(ceil(this.respawn_time - (time + 0.5)) == number) // only say it if it is the same number even in 0.5s; to prevent overlapping sounds
1938                                 { Send_Notification(NOTIF_ONE, this, MSG_ANNCE, Announcer_PickNumber(CNT_RESPAWN, number)); }
1939                 }
1940         }
1941 }
1942
1943 .bool team_selected;
1944 bool ShowTeamSelection(entity this)
1945 {
1946         if(!teamplay || autocvar_g_campaign || autocvar_g_balance_teams || this.team_selected || (this.wasplayer && autocvar_g_changeteam_banned) || this.team_forced > 0)
1947                 return false;
1948         stuffcmd(this, "menu_showteamselect\n");
1949         return true;
1950 }
1951 void Join(entity this)
1952 {
1953         TRANSMUTE(Player, this);
1954
1955         if(!this.team_selected)
1956         if(autocvar_g_campaign || autocvar_g_balance_teams)
1957                 JoinBestTeam(this, false, true);
1958
1959         if(autocvar_g_campaign)
1960                 campaign_bots_may_start = true;
1961
1962         Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_PREVENT_JOIN);
1963
1964         PutClientInServer(this);
1965
1966         if(IS_PLAYER(this))
1967         if(teamplay && this.team != -1)
1968                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, APP_TEAM_NUM(this.team, INFO_JOIN_PLAY_TEAM), this.netname);
1969         else
1970                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_JOIN_PLAY, this.netname);
1971         this.team_selected = false;
1972 }
1973
1974 /**
1975  * Determines whether the player is allowed to join. This depends on cvar
1976  * g_maxplayers, if it isn't used this function always return true, otherwise
1977  * it checks whether the number of currently playing players exceeds g_maxplayers.
1978  * @return int number of free slots for players, 0 if none
1979  */
1980 int nJoinAllowed(entity this, entity ignore)
1981 {
1982         if(!ignore)
1983         // this is called that way when checking if anyone may be able to join (to build qcstatus)
1984         // so report 0 free slots if restricted
1985         {
1986                 if(autocvar_g_forced_team_otherwise == "spectate")
1987                         return 0;
1988                 if(autocvar_g_forced_team_otherwise == "spectator")
1989                         return 0;
1990         }
1991
1992         if(this && this.team_forced < 0)
1993                 return 0; // forced spectators can never join
1994
1995         // TODO simplify this
1996         int totalClients = 0;
1997         int currentlyPlaying = 0;
1998         FOREACH_CLIENT(true, LAMBDA(
1999                 if(it != ignore)
2000                         ++totalClients;
2001                 if(IS_REAL_CLIENT(it))
2002                 if(IS_PLAYER(it) || it.caplayer)
2003                         ++currentlyPlaying;
2004         ));
2005
2006         float free_slots = 0;
2007         if (!autocvar_g_maxplayers)
2008                 free_slots = maxclients - totalClients;
2009         else if(currentlyPlaying < autocvar_g_maxplayers)
2010                 free_slots = min(maxclients - totalClients, autocvar_g_maxplayers - currentlyPlaying);
2011
2012         static float join_prevent_msg_time = 0;
2013         if(this && ignore && !free_slots && time > join_prevent_msg_time)
2014         {
2015                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_JOIN_PREVENT);
2016                 join_prevent_msg_time = time + 3;
2017         }
2018
2019         return free_slots;
2020 }
2021
2022 /**
2023  * Checks whether the client is an observer or spectator, if so, he will get kicked after
2024  * g_maxplayers_spectator_blocktime seconds
2025  */
2026 void checkSpectatorBlock(entity this)
2027 {
2028         if(IS_SPEC(this) || IS_OBSERVER(this))
2029         if(!this.caplayer)
2030         if(IS_REAL_CLIENT(this))
2031         {
2032                 if( time > (this.spectatortime + autocvar_g_maxplayers_spectator_blocktime) ) {
2033                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_QUIT_KICK_SPECTATING);
2034                         dropclient(this);
2035                 }
2036         }
2037 }
2038
2039 void PrintWelcomeMessage(entity this)
2040 {
2041         if(this.motd_actived_time == 0)
2042         {
2043                 if (autocvar_g_campaign) {
2044                         if ((IS_PLAYER(this) && PHYS_INPUT_BUTTON_INFO(this)) || (!IS_PLAYER(this))) {
2045                                 this.motd_actived_time = time;
2046                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOTD, campaign_message);
2047                         }
2048                 } else {
2049                         if (PHYS_INPUT_BUTTON_INFO(this)) {
2050                                 this.motd_actived_time = time;
2051                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOTD, getwelcomemessage(this));
2052                         }
2053                 }
2054         }
2055         else if(this.motd_actived_time > 0) // showing MOTD or campaign message
2056         {
2057                 if (autocvar_g_campaign) {
2058                         if (PHYS_INPUT_BUTTON_INFO(this))
2059                                 this.motd_actived_time = time;
2060                         else if ((time - this.motd_actived_time > 2) && IS_PLAYER(this)) { // hide it some seconds after BUTTON_INFO has been released
2061                                 this.motd_actived_time = 0;
2062                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_MOTD);
2063                         }
2064                 } else {
2065                         if (PHYS_INPUT_BUTTON_INFO(this))
2066                                 this.motd_actived_time = time;
2067                         else if (time - this.motd_actived_time > 2) { // hide it some seconds after BUTTON_INFO has been released
2068                                 this.motd_actived_time = 0;
2069                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_MOTD);
2070                         }
2071                 }
2072         }
2073         else //if(this.motd_actived_time < 0) // just connected, motd is active
2074         {
2075                 if(PHYS_INPUT_BUTTON_INFO(this)) // BUTTON_INFO hides initial MOTD
2076                         this.motd_actived_time = -2; // wait until BUTTON_INFO gets released
2077                 else if(this.motd_actived_time == -2 || IS_PLAYER(this) || IS_SPEC(this))
2078                 {
2079                         // instanctly hide MOTD
2080                         this.motd_actived_time = 0;
2081                         Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_MOTD);
2082                 }
2083         }
2084 }
2085
2086 bool joinAllowed(entity this)
2087 {
2088         if (this.version_mismatch) return false;
2089         if (!nJoinAllowed(this, this)) return false;
2090         if (teamplay && lockteams) return false;
2091         if (ShowTeamSelection(this)) return false;
2092         if (MUTATOR_CALLHOOK(ForbidSpawn, this)) return false;
2093         return true;
2094 }
2095
2096 void ObserverThink(entity this)
2097 {
2098         if ( this.impulse )
2099         {
2100                 MinigameImpulse(this, this.impulse);
2101                 this.impulse = 0;
2102         }
2103
2104         if (this.flags & FL_JUMPRELEASED) {
2105                 if (PHYS_INPUT_BUTTON_JUMP(this) && joinAllowed(this)) {
2106                         this.flags &= ~FL_JUMPRELEASED;
2107                         this.flags |= FL_SPAWNING;
2108                 } else if(PHYS_INPUT_BUTTON_ATCK(this) && !this.version_mismatch) {
2109                         this.flags &= ~FL_JUMPRELEASED;
2110                         if(SpectateNext(this)) {
2111                                 TRANSMUTE(Spectator, this);
2112                         }
2113                 } else {
2114                         int preferred_movetype = ((!PHYS_INPUT_BUTTON_USE(this) ? this.cvar_cl_clippedspectating : !this.cvar_cl_clippedspectating) ? MOVETYPE_FLY_WORLDONLY : MOVETYPE_NOCLIP);
2115                         set_movetype(this, preferred_movetype);
2116                 }
2117         } else {
2118                 if (!(PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_JUMP(this))) {
2119                         this.flags |= FL_JUMPRELEASED;
2120                         if(this.flags & FL_SPAWNING)
2121                         {
2122                                 this.flags &= ~FL_SPAWNING;
2123                                 Join(this);
2124                                 return;
2125                         }
2126                 }
2127         }
2128 }
2129
2130 void SpectatorThink(entity this)
2131 {
2132         if ( this.impulse )
2133         {
2134                 if(MinigameImpulse(this, this.impulse))
2135                         this.impulse = 0;
2136
2137                 if (this.impulse == IMP_weapon_drop.impulse)
2138                 {
2139                         STAT(CAMERA_SPECTATOR, this) = (STAT(CAMERA_SPECTATOR, this) + 1) % 3;
2140                         this.impulse = 0;
2141                         return;
2142                 }
2143         }
2144
2145         if (this.flags & FL_JUMPRELEASED) {
2146                 if (PHYS_INPUT_BUTTON_JUMP(this) && joinAllowed(this)) {
2147                         this.flags &= ~FL_JUMPRELEASED;
2148                         this.flags |= FL_SPAWNING;
2149                 } else if(PHYS_INPUT_BUTTON_ATCK(this) || this.impulse == 10 || this.impulse == 15 || this.impulse == 18 || (this.impulse >= 200 && this.impulse <= 209)) {
2150                         this.flags &= ~FL_JUMPRELEASED;
2151                         if(SpectateNext(this)) {
2152                                 TRANSMUTE(Spectator, this);
2153                         } else {
2154                                 TRANSMUTE(Observer, this);
2155                                 PutClientInServer(this);
2156                         }
2157                         this.impulse = 0;
2158                 } else if(this.impulse == 12 || this.impulse == 16  || this.impulse == 19 || (this.impulse >= 220 && this.impulse <= 229)) {
2159                         this.flags &= ~FL_JUMPRELEASED;
2160                         if(SpectatePrev(this)) {
2161                                 TRANSMUTE(Spectator, this);
2162                         } else {
2163                                 TRANSMUTE(Observer, this);
2164                                 PutClientInServer(this);
2165                         }
2166                         this.impulse = 0;
2167                 } else if (PHYS_INPUT_BUTTON_ATCK2(this)) {
2168                         this.flags &= ~FL_JUMPRELEASED;
2169                         TRANSMUTE(Observer, this);
2170                         PutClientInServer(this);
2171                 } else {
2172                         if(!SpectateUpdate(this))
2173                                 PutObserverInServer(this);
2174                 }
2175         } else {
2176                 if (!(PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_ATCK2(this))) {
2177                         this.flags |= FL_JUMPRELEASED;
2178                         if(this.flags & FL_SPAWNING)
2179                         {
2180                                 this.flags &= ~FL_SPAWNING;
2181                                 Join(this);
2182                                 return;
2183                         }
2184                 }
2185                 if(!SpectateUpdate(this))
2186                         PutObserverInServer(this);
2187         }
2188
2189         this.flags |= FL_CLIENT | FL_NOTARGET;
2190 }
2191
2192 void vehicles_enter (entity pl, entity veh);
2193 void PlayerUseKey(entity this)
2194 {
2195         if (!IS_PLAYER(this))
2196                 return;
2197
2198         if(this.vehicle)
2199         {
2200                 if(!game_stopped)
2201                 {
2202                         vehicles_exit(this.vehicle, VHEF_NORMAL);
2203                         return;
2204                 }
2205         }
2206         else if(autocvar_g_vehicles_enter)
2207         {
2208                 if(!STAT(FROZEN, this))
2209                 if(!IS_DEAD(this))
2210                 if(!game_stopped)
2211                 {
2212                         entity head, closest_target = NULL;
2213                         head = WarpZone_FindRadius(this.origin, autocvar_g_vehicles_enter_radius, true);
2214
2215                         while(head) // find the closest acceptable target to enter
2216                         {
2217                                 if(IS_VEHICLE(head))
2218                                 if(!IS_DEAD(head))
2219                                 if(!head.owner || ((head.vehicle_flags & VHF_MULTISLOT) && SAME_TEAM(head.owner, this)))
2220                                 if(head.takedamage != DAMAGE_NO)
2221                                 {
2222                                         if(closest_target)
2223                                         {
2224                                                 if(vlen2(this.origin - head.origin) < vlen2(this.origin - closest_target.origin))
2225                                                 { closest_target = head; }
2226                                         }
2227                                         else { closest_target = head; }
2228                                 }
2229
2230                                 head = head.chain;
2231                         }
2232
2233                         if(closest_target) { vehicles_enter(this, closest_target); return; }
2234                 }
2235         }
2236
2237         // a use key was pressed; call handlers
2238         MUTATOR_CALLHOOK(PlayerUseKey, this);
2239 }
2240
2241
2242 /*
2243 =============
2244 PlayerPreThink
2245
2246 Called every frame for each client before the physics are run
2247 =============
2248 */
2249 .float usekeypressed;
2250 .float last_vehiclecheck;
2251 .int items_added;
2252 void PlayerPreThink (entity this)
2253 {
2254         WarpZone_PlayerPhysics_FixVAngle(this);
2255
2256     STAT(GAMESTARTTIME, this) = game_starttime;
2257         STAT(ROUNDSTARTTIME, this) = round_starttime;
2258         STAT(ALLOW_OLDVORTEXBEAM, this) = autocvar_g_allow_oldvortexbeam;
2259         STAT(LEADLIMIT, this) = autocvar_leadlimit;
2260
2261         STAT(WEAPONSINMAP, this) = weaponsInMap;
2262
2263         if (frametime) {
2264                 // physics frames: update anticheat stuff
2265                 anticheat_prethink(this);
2266         }
2267
2268         if (blockSpectators && frametime) {
2269                 // WORKAROUND: only use dropclient in server frames (frametime set).
2270                 // Never use it in cl_movement frames (frametime zero).
2271                 checkSpectatorBlock(this);
2272     }
2273
2274         zoomstate_set = false;
2275
2276         // Check for nameless players
2277         if (isInvisibleString(this.netname)) {
2278                 this.netname = strzone(sprintf("Player#%d", this.playerid));
2279                 // stuffcmd(this, strcat("name ", this.netname, "\n")); // maybe?
2280         }
2281         if (this.netname != this.netname_previous) {
2282                 if (autocvar_sv_eventlog) {
2283                         GameLogEcho(strcat(":name:", ftos(this.playerid), ":", playername(this, false)));
2284         }
2285                 if (this.netname_previous) strunzone(this.netname_previous);
2286                 this.netname_previous = strzone(this.netname);
2287         }
2288
2289         // version nagging
2290         if (this.version_nagtime && this.cvar_g_xonoticversion && time > this.version_nagtime) {
2291         this.version_nagtime = 0;
2292         if (strstrofs(this.cvar_g_xonoticversion, "git", 0) >= 0 || strstrofs(this.cvar_g_xonoticversion, "autobuild", 0) >= 0) {
2293             // git client
2294         } else if (strstrofs(autocvar_g_xonoticversion, "git", 0) >= 0 || strstrofs(autocvar_g_xonoticversion, "autobuild", 0) >= 0) {
2295             // git server
2296             Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_BETA, autocvar_g_xonoticversion, this.cvar_g_xonoticversion);
2297         } else {
2298             int r = vercmp(this.cvar_g_xonoticversion, autocvar_g_xonoticversion);
2299             if (r < 0) { // old client
2300                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_OUTDATED, autocvar_g_xonoticversion, this.cvar_g_xonoticversion);
2301             } else if (r > 0) { // old server
2302                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_OLD, autocvar_g_xonoticversion, this.cvar_g_xonoticversion);
2303             }
2304         }
2305     }
2306
2307         // GOD MODE info
2308         if (!(this.flags & FL_GODMODE) && this.max_armorvalue)
2309         {
2310                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_GODMODE_OFF, this.max_armorvalue);
2311                 this.max_armorvalue = 0;
2312         }
2313
2314         if (STAT(FROZEN, this) == 2)
2315         {
2316                 this.revive_progress = bound(0, this.revive_progress + frametime * this.revive_speed, 1);
2317                 this.health = max(1, this.revive_progress * start_health);
2318                 this.iceblock.alpha = bound(0.2, 1 - this.revive_progress, 1);
2319
2320                 if (this.revive_progress >= 1)
2321                         Unfreeze(this);
2322         }
2323         else if (STAT(FROZEN, this) == 3)
2324         {
2325                 this.revive_progress = bound(0, this.revive_progress - frametime * this.revive_speed, 1);
2326                 this.health = max(0, autocvar_g_nades_ice_health + (start_health-autocvar_g_nades_ice_health) * this.revive_progress );
2327
2328                 if (this.health < 1)
2329                 {
2330                         if (this.vehicle)
2331                                 vehicles_exit(this.vehicle, VHEF_RELEASE);
2332                         if(this.event_damage)
2333                                 this.event_damage(this, this, this.frozen_by, 1, DEATH_NADE_ICE_FREEZE.m_id, this.origin, '0 0 0');
2334                 }
2335                 else if (this.revive_progress <= 0)
2336                         Unfreeze(this);
2337         }
2338
2339         MUTATOR_CALLHOOK(PlayerPreThink, this);
2340
2341         if(autocvar_g_vehicles_enter && (time > this.last_vehiclecheck) && !game_stopped && !this.vehicle)
2342         if(IS_PLAYER(this) && !STAT(FROZEN, this) && !IS_DEAD(this))
2343         {
2344                 FOREACH_ENTITY_RADIUS(this.origin, autocvar_g_vehicles_enter_radius, IS_VEHICLE(it),
2345                 {
2346                         if(!IS_DEAD(it) && it.takedamage != DAMAGE_NO)
2347                         if((it.vehicle_flags & VHF_MULTISLOT) && SAME_TEAM(it.owner, this))
2348                         {
2349                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER_GUNNER);
2350                         }
2351                         else if(!it.owner)
2352                         {
2353                                 if(!it.team || SAME_TEAM(this, it))
2354                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER);
2355                                 else if(autocvar_g_vehicles_steal)
2356                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER_STEAL);
2357                         }
2358                 });
2359
2360                 this.last_vehiclecheck = time + 1;
2361         }
2362
2363         if(!this.cvar_cl_newusekeysupported) // FIXME remove this - it was a stupid idea to begin with, we can JUST use the button
2364         {
2365                 if(PHYS_INPUT_BUTTON_USE(this) && !this.usekeypressed)
2366                         PlayerUseKey(this);
2367                 this.usekeypressed = PHYS_INPUT_BUTTON_USE(this);
2368         }
2369
2370         if (IS_REAL_CLIENT(this))
2371                 PrintWelcomeMessage(this);
2372
2373         if (IS_PLAYER(this)) {
2374                 CheckRules_Player(this);
2375
2376                 if (game_stopped || intermission_running) {
2377                         this.modelflags &= ~MF_ROCKET;
2378                         if(intermission_running)
2379                                 IntermissionThink(this);
2380                         return;
2381                 }
2382
2383                 if (timeout_status == TIMEOUT_ACTIVE) {
2384             // don't allow the player to turn around while game is paused
2385                         // FIXME turn this into CSQC stuff
2386                         this.v_angle = this.lastV_angle;
2387                         this.angles = this.lastV_angle;
2388                         this.fixangle = true;
2389                 }
2390
2391                 if (frametime) player_powerups(this);
2392
2393                 if (IS_DEAD(this)) {
2394                         if (this.personal && g_race_qualifying) {
2395                                 if (time > this.respawn_time) {
2396                                         STAT(RESPAWN_TIME, this) = this.respawn_time = time + 1; // only retry once a second
2397                                         respawn(this);
2398                                         this.impulse = CHIMPULSE_SPEEDRUN.impulse;
2399                                 }
2400                         } else {
2401                                 if (frametime) player_anim(this);
2402
2403                                 if (this.respawn_flags & RESPAWN_DENY)
2404                                 {
2405                                         STAT(RESPAWN_TIME, this) = 0;
2406                                         return;
2407                                 }
2408
2409                                 bool button_pressed = (PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_JUMP(this) || PHYS_INPUT_BUTTON_ATCK2(this) || PHYS_INPUT_BUTTON_HOOK(this) || PHYS_INPUT_BUTTON_USE(this));
2410
2411                                 switch(this.deadflag)
2412                                 {
2413                                         case DEAD_DYING:
2414                                         {
2415                                                 if ((this.respawn_flags & RESPAWN_FORCE) && !(this.respawn_time < this.respawn_time_max))
2416                                                         this.deadflag = DEAD_RESPAWNING;
2417                                                 else if (!button_pressed || (time >= this.respawn_time_max && (this.respawn_flags & RESPAWN_FORCE)))
2418                                                         this.deadflag = DEAD_DEAD;
2419                                                 break;
2420                                         }
2421                                         case DEAD_DEAD:
2422                                         {
2423                                                 if (button_pressed)
2424                                                         this.deadflag = DEAD_RESPAWNABLE;
2425                                                 else if (time >= this.respawn_time_max && (this.respawn_flags & RESPAWN_FORCE))
2426                                                         this.deadflag = DEAD_RESPAWNING;
2427                                                 break;
2428                                         }
2429                                         case DEAD_RESPAWNABLE:
2430                                         {
2431                                                 if (!button_pressed || (this.respawn_flags & RESPAWN_FORCE))
2432                                                         this.deadflag = DEAD_RESPAWNING;
2433                                                 break;
2434                                         }
2435                                         case DEAD_RESPAWNING:
2436                                         {
2437                                                 if (time > this.respawn_time)
2438                                                 {
2439                                                         this.respawn_time = time + 1; // only retry once a second
2440                                                         this.respawn_time_max = this.respawn_time;
2441                                                         respawn(this);
2442                                                 }
2443                                                 break;
2444                                         }
2445                                 }
2446
2447                                 ShowRespawnCountdown(this);
2448
2449                                 if (this.respawn_flags & RESPAWN_SILENT)
2450                                         STAT(RESPAWN_TIME, this) = 0;
2451                                 else if ((this.respawn_flags & RESPAWN_FORCE) && this.respawn_time < this.respawn_time_max)
2452                                 {
2453                                         if (time < this.respawn_time)
2454                                                 STAT(RESPAWN_TIME, this) = this.respawn_time;
2455                                         else if (this.deadflag != DEAD_RESPAWNING)
2456                                                 STAT(RESPAWN_TIME, this) = -this.respawn_time_max;
2457                                 }
2458                                 else
2459                                         STAT(RESPAWN_TIME, this) = this.respawn_time;
2460                         }
2461
2462                         // if respawning, invert stat_respawn_time to indicate this, the client translates it
2463                         if (this.deadflag == DEAD_RESPAWNING && STAT(RESPAWN_TIME, this) > 0)
2464                                 STAT(RESPAWN_TIME, this) *= -1;
2465
2466                         return;
2467                 }
2468
2469                 this.prevorigin = this.origin;
2470
2471                 bool have_hook = false;
2472                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2473                 {
2474                         .entity weaponentity = weaponentities[slot];
2475                         if(this.(weaponentity).hook.state)
2476                         {
2477                                 have_hook = true;
2478                                 break;
2479                         }
2480                 }
2481                 bool do_crouch = PHYS_INPUT_BUTTON_CROUCH(this);
2482                 if (have_hook) {
2483                         do_crouch = false;
2484                 } else if (this.waterlevel >= WATERLEVEL_SWIMMING) {
2485                         do_crouch = false;
2486                 } else if (this.vehicle) {
2487                         do_crouch = false;
2488                 } else if (STAT(FROZEN, this)) {
2489                         do_crouch = false;
2490         }
2491
2492                 if (do_crouch) {
2493                         if (!this.crouch) {
2494                                 this.crouch = true;
2495                                 this.view_ofs = STAT(PL_CROUCH_VIEW_OFS, this);
2496                                 setsize(this, STAT(PL_CROUCH_MIN, this), STAT(PL_CROUCH_MAX, this));
2497                                 // setanim(this, this.anim_duck, false, true, true); // this anim is BROKEN anyway
2498                         }
2499                 } else if (this.crouch) {
2500             tracebox(this.origin, STAT(PL_MIN, this), STAT(PL_MAX, this), this.origin, false, this);
2501             if (!trace_startsolid) {
2502                 this.crouch = false;
2503                 this.view_ofs = STAT(PL_VIEW_OFS, this);
2504                 setsize(this, STAT(PL_MIN, this), STAT(PL_MAX, this));
2505             }
2506                 }
2507
2508                 FixPlayermodel(this);
2509
2510                 // LordHavoc: allow firing on move frames (sub-ticrate), this gives better timing on slow servers
2511                 //if(frametime)
2512                 {
2513                         this.items &= ~this.items_added;
2514
2515                         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2516                         {
2517                                 .entity weaponentity = weaponentities[slot];
2518                                 W_WeaponFrame(this, weaponentity);
2519
2520                                 if(slot == 0)
2521                                 {
2522                                         this.clip_load = this.(weaponentity).clip_load;
2523                                         this.clip_size = this.(weaponentity).clip_size;
2524                                 }
2525                         }
2526
2527                         this.items_added = 0;
2528                         if (this.items & ITEM_Jetpack.m_itemid && (this.items & ITEM_JetpackRegen.m_itemid || this.ammo_fuel >= 0.01))
2529                 this.items_added |= IT_FUEL;
2530
2531                         this.items |= this.items_added;
2532                 }
2533
2534                 player_regen(this);
2535
2536                 // WEAPONTODO: Add a weapon request for this
2537                 // rot vortex charge to the charge limit
2538                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2539                 {
2540                         .entity weaponentity = weaponentities[slot];
2541                         if (WEP_CVAR(vortex, charge_rot_rate) && this.(weaponentity).vortex_charge > WEP_CVAR(vortex, charge_limit) && this.(weaponentity).vortex_charge_rottime < time)
2542                         {
2543                                 this.(weaponentity).vortex_charge = bound(WEP_CVAR(vortex, charge_limit), this.(weaponentity).vortex_charge - WEP_CVAR(vortex, charge_rot_rate) * frametime / W_TICSPERFRAME, 1);
2544                         }
2545                         if (WEP_CVAR(okvortex, charge_rot_rate) && this.(weaponentity).okvortex_charge > WEP_CVAR(okvortex, charge_limit) && this.(weaponentity).okvortex_charge_rottime < time)
2546                         {
2547                                 this.(weaponentity).okvortex_charge = bound(WEP_CVAR(okvortex, charge_limit), this.(weaponentity).okvortex_charge - WEP_CVAR(okvortex, charge_rot_rate) * frametime / W_TICSPERFRAME, 1);
2548                         }
2549                 }
2550
2551                 if (frametime) player_anim(this);
2552
2553                 // secret status
2554                 secrets_setstatus(this);
2555
2556                 // monsters status
2557                 monsters_setstatus(this);
2558
2559                 this.dmg_team = max(0, this.dmg_team - autocvar_g_teamdamage_resetspeed * frametime);
2560         }
2561         else if (game_stopped || intermission_running) {
2562                 if(intermission_running)
2563                         IntermissionThink(this);
2564                 return;
2565         }
2566         else if (IS_OBSERVER(this)) {
2567                 ObserverThink(this);
2568         }
2569         else if (IS_SPEC(this)) {
2570                 SpectatorThink(this);
2571         }
2572
2573         // WEAPONTODO: Add weapon request for this
2574         if (!zoomstate_set) {
2575                 bool wep_zoomed = false;
2576                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2577                 {
2578                         .entity weaponentity = weaponentities[slot];
2579                         Weapon thiswep = this.(weaponentity).m_weapon;
2580                         if(thiswep != WEP_Null && thiswep.wr_zoom)
2581                                 wep_zoomed += thiswep.wr_zoom(thiswep, this);
2582                 }
2583                 SetZoomState(this, PHYS_INPUT_BUTTON_ZOOM(this) || PHYS_INPUT_BUTTON_ZOOMSCRIPT(this) || wep_zoomed);
2584     }
2585
2586         if (this.teamkill_soundtime && time > this.teamkill_soundtime)
2587         {
2588                 this.teamkill_soundtime = 0;
2589
2590                 entity e = this.teamkill_soundsource;
2591                 entity oldpusher = e.pusher;
2592                 e.pusher = this;
2593                 PlayerSound(e, playersound_teamshoot, CH_VOICE, VOL_BASEVOICE, VOICETYPE_LASTATTACKER_ONLY);
2594                 e.pusher = oldpusher;
2595         }
2596
2597         if (this.taunt_soundtime && time > this.taunt_soundtime) {
2598                 this.taunt_soundtime = 0;
2599                 PlayerSound(this, playersound_taunt, CH_VOICE, VOL_BASEVOICE, VOICETYPE_AUTOTAUNT);
2600         }
2601
2602         target_voicescript_next(this);
2603
2604         // WEAPONTODO: Move into weaponsystem somehow
2605         // if a player goes unarmed after holding a loaded weapon, empty his clip size and remove the crosshair ammo ring
2606         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2607         {
2608                 .entity weaponentity = weaponentities[slot];
2609                 if(this.(weaponentity).m_weapon == WEP_Null)
2610                         this.(weaponentity).clip_load = this.(weaponentity).clip_size = 0;
2611         }
2612 }
2613
2614 void DrownPlayer(entity this)
2615 {
2616         if(IS_DEAD(this))
2617                 return;
2618
2619         if (this.waterlevel != WATERLEVEL_SUBMERGED || this.vehicle)
2620         {
2621                 if(this.air_finished < time)
2622                         PlayerSound(this, playersound_gasp, CH_PLAYER, VOL_BASE, VOICETYPE_PLAYERSOUND);
2623                 this.air_finished = time + autocvar_g_balance_contents_drowndelay;
2624                 this.dmg = 2;
2625         }
2626         else if (this.air_finished < time)
2627         {       // drown!
2628                 if (this.pain_finished < time)
2629                 {
2630                         Damage (this, NULL, NULL, autocvar_g_balance_contents_playerdamage_drowning * autocvar_g_balance_contents_damagerate, DEATH_DROWN.m_id, this.origin, '0 0 0');
2631                         this.pain_finished = time + 0.5;
2632                 }
2633         }
2634 }
2635
2636 .bool move_qcphysics;
2637
2638 void Player_Physics(entity this)
2639 {
2640         set_movetype(this, this.move_movetype);
2641
2642         if(!this.move_qcphysics)
2643                 return;
2644
2645         if(!frametime && !this.pm_frametime)
2646                 return;
2647
2648         Movetype_Physics_NoMatchTicrate(this, this.pm_frametime, true);
2649
2650         this.pm_frametime = 0;
2651 }
2652
2653 /*
2654 =============
2655 PlayerPostThink
2656
2657 Called every frame for each client after the physics are run
2658 =============
2659 */
2660 .float idlekick_lasttimeleft;
2661 void PlayerPostThink (entity this)
2662 {
2663         Player_Physics(this);
2664
2665         if (sv_maxidle > 0)
2666         if (frametime) // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2667         if (IS_REAL_CLIENT(this))
2668         if (IS_PLAYER(this) || sv_maxidle_spectatorsareidle)
2669         {
2670                 int totalClients = 0;
2671                 if(sv_maxidle_slots > 0)
2672                 {
2673                         FOREACH_CLIENT(IS_REAL_CLIENT(it) || sv_maxidle_slots_countbots,
2674                         {
2675                                 ++totalClients;
2676                         });
2677                 }
2678
2679                 if (sv_maxidle_slots > 0 && (maxclients - totalClients) > sv_maxidle_slots)
2680                 { /* do nothing */ }
2681                 else if (time - this.parm_idlesince < 1) // instead of (time == this.parm_idlesince) to support sv_maxidle <= 10
2682                 {
2683                         if (this.idlekick_lasttimeleft)
2684                         {
2685                                 this.idlekick_lasttimeleft = 0;
2686                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_IDLING);
2687                         }
2688                 }
2689                 else
2690                 {
2691                         float timeleft = ceil(sv_maxidle - (time - this.parm_idlesince));
2692                         if (timeleft == min(10, sv_maxidle - 1)) { // - 1 to support sv_maxidle <= 10
2693                                 if (!this.idlekick_lasttimeleft)
2694                                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_DISCONNECT_IDLING, timeleft);
2695                         }
2696                         if (timeleft <= 0) {
2697                                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_QUIT_KICK_IDLING, this.netname);
2698                                 dropclient(this);
2699                                 return;
2700                         }
2701                         else if (timeleft <= 10) {
2702                                 if (timeleft != this.idlekick_lasttimeleft) {
2703                                     Send_Notification(NOTIF_ONE, this, MSG_ANNCE, Announcer_PickNumber(CNT_IDLE, timeleft));
2704                 }
2705                                 this.idlekick_lasttimeleft = timeleft;
2706                         }
2707                 }
2708         }
2709
2710         CheatFrame(this);
2711
2712         //CheckPlayerJump();
2713         if (game_stopped)
2714         {
2715                 this.solid = SOLID_NOT;
2716                 this.takedamage = DAMAGE_NO;
2717                 set_movetype(this, MOVETYPE_NONE);
2718         }
2719
2720         if (IS_PLAYER(this)) {
2721                 DrownPlayer(this);
2722                 CheckRules_Player(this);
2723                 UpdateChatBubble(this);
2724                 if (this.impulse) ImpulseCommands(this);
2725                 if (game_stopped)
2726                 {
2727                         CSQCMODEL_AUTOUPDATE(this);
2728                         return;
2729                 }
2730                 GetPressedKeys(this);
2731         }
2732
2733         if (this.waypointsprite_attachedforcarrier) {
2734             vector v = healtharmor_maxdamage(this.health, this.armorvalue, autocvar_g_balance_armor_blockpercent, DEATH_WEAPON.m_id);
2735                 WaypointSprite_UpdateHealth(this.waypointsprite_attachedforcarrier, '1 0 0' * v);
2736     }
2737
2738         playerdemo_write(this);
2739
2740         CSQCMODEL_AUTOUPDATE(this);
2741 }