qcsrc/server/client.qc

   1 #include "client.qh"
   2
   3 #include <server/defs.qh>
   4 #include <server/miscfunctions.qh>
   5 #include <common/effects/all.qh>
   6 #include "anticheat.qh"
   7 #include "impulse.qh"
   8 #include "player.qh"
   9 #include "ipban.qh"
  10 #include "miscfunctions.qh"
  11 #include "portals.qh"
  12 #include "teamplay.qh"
  13 #include "spawnpoints.qh"
  14 #include "resources.qh"
  15 #include "g_damage.qh"
  16 #include "handicap.qh"
  17 #include "g_hook.qh"
  18 #include "command/common.qh"
  19 #include "command/vote.qh"
  20 #include "clientkill.qh"
  21 #include "cheats.qh"
  22 #include "g_world.qh"
  23 #include "race.qh"
  24 #include "antilag.qh"
  25 #include "campaign.qh"
  26 #include "command/common.qh"
  27 #include "scores_rules.qh"
  28 #include "weapons/common.qh"
  29
  30 #include "bot/api.qh"
  31
  32 #include "../common/ent_cs.qh"
  33 #include "../common/wepent.qh"
  34 #include <common/state.qh>
  35
  36 #include "compat/quake3.qh"
  37
  38 #include <common/effects/qc/globalsound.qh>
  39
  40 #include "../common/mapobjects/func/conveyor.qh"
  41 #include "../common/mapobjects/teleporters.qh"
  42 #include "../common/mapobjects/target/spawnpoint.qh"
  43 #include <common/mapobjects/trigger/counter.qh>
  44 #include <common/mapobjects/trigger/swamp.qh>
  45
  46 #include "../common/vehicles/all.qh"
  47
  48 #include "weapons/hitplot.qh"
  49 #include "weapons/weaponsystem.qh"
  50
  51 #include "../common/net_notice.qh"
  52 #include "../common/net_linked.qh"
  53 #include "../common/physics/player.qh"
  54
  55 #include <common/vehicles/sv_vehicles.qh>
  56
  57 #include "../common/items/_mod.qh"
  58
  59 #include "../common/mutators/mutator/waypoints/all.qh"
  60 #include "../common/mutators/mutator/instagib/sv_instagib.qh"
  61 #include <common/gamemodes/_mod.qh>
  62
  63 #include "../common/mapobjects/subs.qh"
  64 #include "../common/mapobjects/triggers.qh"
  65 #include "../common/mapobjects/trigger/secret.qh"
  66
  67 #include "../common/minigames/sv_minigames.qh"
  68
  69 #include "../common/items/inventory.qh"
  70
  71 #include "../common/monsters/sv_monsters.qh"
  72
  73 #include "../lib/warpzone/server.qh"
  74
  75 #include <common/mutators/mutator/overkill/oknex.qh>
  76
  77 STATIC_METHOD(Client, Add, void(Client this, int _team))
  78 {
  79     ClientConnect(this);
  80     TRANSMUTE(Player, this);
  81     this.frame = 12; // 7
  82     this.team = _team;
  83     PutClientInServer(this);
  84 }
  85
  86 STATIC_METHOD(Client, Remove, void(Client this))
  87 {
  88     TRANSMUTE(Observer, this);
  89     PutClientInServer(this);
  90     ClientDisconnect(this);
  91 }
  92
  93 void send_CSQC_teamnagger() {
  94         WriteHeader(MSG_BROADCAST, TE_CSQC_TEAMNAGGER);
  95 }
  96
  97 int CountSpectators(entity player, entity to)
  98 {
  99         if(!player) { return 0; } // not sure how, but best to be safe
 100
 101         int spec_count = 0;
 102
 103         FOREACH_CLIENT(IS_REAL_CLIENT(it) && IS_SPEC(it) && it != to && it.enemy == player,
 104         {
 105                 spec_count++;
 106         });
 107
 108         return spec_count;
 109 }
 110
 111 void WriteSpectators(entity player, entity to)
 112 {
 113         if(!player) { return; } // not sure how, but best to be safe
 114
 115         FOREACH_CLIENT(IS_REAL_CLIENT(it) && IS_SPEC(it) && it != to && it.enemy == player,
 116         {
 117                 WriteByte(MSG_ENTITY, num_for_edict(it));
 118         });
 119 }
 120
 121 bool ClientData_Send(entity this, entity to, int sf)
 122 {
 123         assert(to == this.owner, return false);
 124
 125         entity e = to;
 126         if (IS_SPEC(e)) e = e.enemy;
 127
 128         sf = 0;
 129         if (CS(e).race_completed)       sf |= BIT(0); // forced scoreboard
 130         if (CS(to).spectatee_status)    sf |= BIT(1); // spectator ent number follows
 131         if (CS(e).zoomstate)            sf |= BIT(2); // zoomed
 132         if (autocvar_sv_showspectators) sf |= BIT(4); // show spectators
 133
 134         WriteHeader(MSG_ENTITY, ENT_CLIENT_CLIENTDATA);
 135         WriteByte(MSG_ENTITY, sf);
 136
 137         if (sf & BIT(1))
 138                 WriteByte(MSG_ENTITY, CS(to).spectatee_status);
 139
 140         if(sf & BIT(4))
 141         {
 142                 float specs = CountSpectators(e, to);
 143                 WriteByte(MSG_ENTITY, specs);
 144                 WriteSpectators(e, to);
 145         }
 146
 147         return true;
 148 }
 149
 150 void ClientData_Attach(entity this)
 151 {
 152         Net_LinkEntity(CS(this).clientdata = new_pure(clientdata), false, 0, ClientData_Send);
 153         CS(this).clientdata.drawonlytoclient = this;
 154         CS(this).clientdata.owner = this;
 155 }
 156
 157 void ClientData_Detach(entity this)
 158 {
 159         delete(CS(this).clientdata);
 160         CS(this).clientdata = NULL;
 161 }
 162
 163 void ClientData_Touch(entity e)
 164 {
 165         entity cd = CS(e).clientdata;
 166         if (cd) { cd.SendFlags = 1; }
 167
 168         // make it spectatable
 169         FOREACH_CLIENT(IS_REAL_CLIENT(it) && it != e && IS_SPEC(it) && it.enemy == e,
 170         {
 171                 entity cd = CS(it).clientdata;
 172                 if (cd) { cd.SendFlags = 1; }
 173         });
 174 }
 175
 176
 177 /*
 178 =============
 179 CheckPlayerModel
 180
 181 Checks if the argument string can be a valid playermodel.
 182 Returns a valid one in doubt.
 183 =============
 184 */
 185 string FallbackPlayerModel;
 186 string CheckPlayerModel(string plyermodel) {
 187         if(FallbackPlayerModel != cvar_defstring("_cl_playermodel"))
 188         {
 189                 // note: we cannot summon Don Strunzone here, some player may
 190                 // still have the model string set. In case anyone manages how
 191                 // to change a cvar default, we'll have a small leak here.
 192                 FallbackPlayerModel = strzone(cvar_defstring("_cl_playermodel"));
 193         }
 194         // only in right path
 195         if( substring(plyermodel,0,14) != "models/player/")
 196                 return FallbackPlayerModel;
 197         // only good file extensions
 198         if(substring(plyermodel,-4,4) != ".zym")
 199         if(substring(plyermodel,-4,4) != ".dpm")
 200         if(substring(plyermodel,-4,4) != ".iqm")
 201         if(substring(plyermodel,-4,4) != ".md3")
 202         if(substring(plyermodel,-4,4) != ".psk")
 203                 return FallbackPlayerModel;
 204         // forbid the LOD models
 205         if(substring(plyermodel, -9,5) == "_lod1")
 206                 return FallbackPlayerModel;
 207         if(substring(plyermodel, -9,5) == "_lod2")
 208                 return FallbackPlayerModel;
 209         if(plyermodel != strtolower(plyermodel))
 210                 return FallbackPlayerModel;
 211         // also, restrict to server models
 212         if(autocvar_sv_servermodelsonly)
 213         {
 214                 if(!fexists(plyermodel))
 215                         return FallbackPlayerModel;
 216         }
 217         return plyermodel;
 218 }
 219
 220 void setplayermodel(entity e, string modelname)
 221 {
 222         precache_model(modelname);
 223         _setmodel(e, modelname);
 224         player_setupanimsformodel(e);
 225         if(!autocvar_g_debug_globalsounds)
 226                 UpdatePlayerSounds(e);
 227 }
 228
 229 /** putting a client as observer in the server */
 230 void PutObserverInServer(entity this)
 231 {
 232     bool mutator_returnvalue = MUTATOR_CALLHOOK(MakePlayerObserver, this);
 233         PlayerState_detach(this);
 234
 235         if (IS_PLAYER(this))
 236         {
 237                 if(GetResource(this, RES_HEALTH) >= 1)
 238                 {
 239                         // despawn effect
 240                         Send_Effect(EFFECT_SPAWN_NEUTRAL, this.origin, '0 0 0', 1);
 241                 }
 242
 243                 // was a player, recount votes and ready status
 244                 if(IS_REAL_CLIENT(this))
 245                 {
 246                         if (vote_called) { VoteCount(false); }
 247                         ReadyCount();
 248                 }
 249     }
 250
 251     {
 252         entity spot = SelectSpawnPoint(this, true);
 253         if (!spot) LOG_FATAL("No spawnpoints for observers?!?");
 254         this.angles = vec2(spot.angles);
 255         this.fixangle = true;
 256         // offset it so that the spectator spawns higher off the ground, looks better this way
 257         setorigin(this, spot.origin + STAT(PL_VIEW_OFS, this));
 258         if (IS_REAL_CLIENT(this))
 259         {
 260             msg_entity = this;
 261             WriteByte(MSG_ONE, SVC_SETVIEW);
 262             WriteEntity(MSG_ONE, this);
 263         }
 264         // give the spectator some space between walls for MOVETYPE_FLY_WORLDONLY
 265         // so that your view doesn't go into the ceiling with MOVETYPE_FLY_WORLDONLY, previously "PL_VIEW_OFS"
 266         if(!autocvar_g_debug_globalsounds)
 267         {
 268                 // needed for player sounds
 269                 this.model = "";
 270                 FixPlayermodel(this);
 271         }
 272         setmodel(this, MDL_Null);
 273         setsize(this, STAT(PL_CROUCH_MIN, this), STAT(PL_CROUCH_MAX, this));
 274         this.view_ofs = '0 0 0';
 275     }
 276
 277     RemoveGrapplingHooks(this);
 278         Portal_ClearAll(this);
 279         Unfreeze(this, false);
 280         SetSpectatee(this, NULL);
 281
 282         if (this.alivetime)
 283         {
 284                 if (!warmup_stage)
 285                         PlayerStats_GameReport_Event_Player(this, PLAYERSTATS_ALIVETIME, time - this.alivetime);
 286                 this.alivetime = 0;
 287         }
 288
 289         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
 290
 291         WaypointSprite_PlayerDead(this);
 292
 293         if (CS(this).killcount != FRAGS_SPECTATOR)
 294         {
 295                 if(!game_stopped)
 296                 if(autocvar_g_chat_nospectators == 1 || (!warmup_stage && autocvar_g_chat_nospectators == 2))
 297                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_CHAT_NOSPECTATORS);
 298         }
 299
 300         accuracy_resend(this);
 301
 302         CS(this).spectatortime = time;
 303         if(this.bot_attack)
 304                 IL_REMOVE(g_bot_targets, this);
 305         this.bot_attack = false;
 306         if(this.monster_attack)
 307                 IL_REMOVE(g_monster_targets, this);
 308         this.monster_attack = false;
 309     STAT(HUD, this) = HUD_NORMAL;
 310         TRANSMUTE(Observer, this);
 311         this.iscreature = false;
 312         this.teleportable = TELEPORT_SIMPLE;
 313         if(this.damagedbycontents)
 314                 IL_REMOVE(g_damagedbycontents, this);
 315         this.damagedbycontents = false;
 316         SetResourceExplicit(this, RES_HEALTH, FRAGS_SPECTATOR);
 317         SetSpectatee_status(this, etof(this));
 318         this.takedamage = DAMAGE_NO;
 319         this.solid = SOLID_NOT;
 320         set_movetype(this, MOVETYPE_FLY_WORLDONLY); // user preference is controlled by playerprethink
 321         this.flags = FL_CLIENT | FL_NOTARGET;
 322         this.effects = 0;
 323         SetResourceExplicit(this, RES_ARMOR, autocvar_g_balance_armor_start); // was 666?!
 324         this.pauserotarmor_finished = 0;
 325         this.pauserothealth_finished = 0;
 326         this.pauseregen_finished = 0;
 327         this.damageforcescale = 0;
 328         this.death_time = 0;
 329         this.respawn_flags = 0;
 330         this.respawn_time = 0;
 331         STAT(RESPAWN_TIME, this) = 0;
 332         this.alpha = 0;
 333         this.scale = 0;
 334         this.fade_time = 0;
 335         this.pain_frame = 0;
 336         this.pain_finished = 0;
 337         STAT(STRENGTH_FINISHED, this) = 0;
 338         STAT(INVINCIBLE_FINISHED, this) = 0;
 339         STAT(SUPERWEAPONS_FINISHED, this) = 0;
 340         this.air_finished = 0;
 341         //this.dphitcontentsmask = 0;
 342         this.dphitcontentsmask = DPCONTENTS_SOLID;
 343         if (autocvar_g_playerclip_collisions)
 344                 this.dphitcontentsmask |= DPCONTENTS_PLAYERCLIP;
 345         this.pushltime = 0;
 346         this.istypefrag = 0;
 347         setthink(this, func_null);
 348         this.nextthink = 0;
 349         this.deadflag = DEAD_NO;
 350         this.crouch = false;
 351         STAT(REVIVE_PROGRESS, this) = 0;
 352         this.revival_time = 0;
 353         this.draggable = drag_undraggable;
 354
 355         this.items = 0;
 356         STAT(WEAPONS, this) = '0 0 0';
 357         this.drawonlytoclient = this;
 358
 359         this.viewloc = NULL;
 360
 361         //this.spawnpoint_targ = NULL; // keep it so they can return to where they were?
 362
 363         this.weaponmodel = "";
 364         for (int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 365         {
 366                 this.weaponentities[slot] = NULL;
 367         }
 368         this.exteriorweaponentity = NULL;
 369         CS(this).killcount = FRAGS_SPECTATOR;
 370         this.velocity = '0 0 0';
 371         this.avelocity = '0 0 0';
 372         this.punchangle = '0 0 0';
 373         this.punchvector = '0 0 0';
 374         this.oldvelocity = this.velocity;
 375         this.fire_endtime = -1;
 376         this.event_damage = func_null;
 377         this.event_heal = func_null;
 378
 379         for(int slot = 0; slot < MAX_AXH; ++slot)
 380         {
 381                 entity axh = this.(AuxiliaryXhair[slot]);
 382                 this.(AuxiliaryXhair[slot]) = NULL;
 383
 384                 if(axh.owner == this && axh != NULL && !wasfreed(axh))
 385                         delete(axh);
 386         }
 387
 388         if (mutator_returnvalue)
 389         {
 390                 // mutator prevents resetting teams+score
 391         }
 392         else
 393         {
 394                 SetPlayerTeam(this, -1, TEAM_CHANGE_SPECTATOR);
 395                 this.frags = FRAGS_SPECTATOR;
 396         }
 397         if (CS(this).just_joined)
 398                 CS(this).just_joined = false;
 399 }
 400
 401 int player_getspecies(entity this)
 402 {
 403         get_model_parameters(this.model, this.skin);
 404         int s = get_model_parameters_species;
 405         get_model_parameters(string_null, 0);
 406         if (s < 0) return SPECIES_HUMAN;
 407         return s;
 408 }
 409
 410 .float model_randomizer;
 411 void FixPlayermodel(entity player)
 412 {
 413         string defaultmodel = "";
 414         int defaultskin = 0;
 415         if(autocvar_sv_defaultcharacter)
 416         {
 417                 if(teamplay)
 418                 {
 419                         switch(player.team)
 420                         {
 421                                 case NUM_TEAM_1: defaultmodel = autocvar_sv_defaultplayermodel_red; defaultskin = autocvar_sv_defaultplayerskin_red; break;
 422                                 case NUM_TEAM_2: defaultmodel = autocvar_sv_defaultplayermodel_blue; defaultskin = autocvar_sv_defaultplayerskin_blue; break;
 423                                 case NUM_TEAM_3: defaultmodel = autocvar_sv_defaultplayermodel_yellow; defaultskin = autocvar_sv_defaultplayerskin_yellow; break;
 424                                 case NUM_TEAM_4: defaultmodel = autocvar_sv_defaultplayermodel_pink; defaultskin = autocvar_sv_defaultplayerskin_pink; break;
 425                         }
 426                 }
 427
 428                 if(defaultmodel == "")
 429                 {
 430                         defaultmodel = autocvar_sv_defaultplayermodel;
 431                         defaultskin = autocvar_sv_defaultplayerskin;
 432                 }
 433
 434                 int n = tokenize_console(defaultmodel);
 435                 if(n > 0)
 436                 {
 437                         defaultmodel = argv(floor(n * CS(player).model_randomizer));
 438                         // However, do NOT randomize if the player-selected model is in the list.
 439                         for (int i = 0; i < n; ++i)
 440                                 if ((argv(i) == player.playermodel && defaultskin == stof(player.playerskin)) || argv(i) == strcat(player.playermodel, ":", player.playerskin))
 441                                         defaultmodel = argv(i);
 442                 }
 443
 444                 int i = strstrofs(defaultmodel, ":", 0);
 445                 if(i >= 0)
 446                 {
 447                         defaultskin = stof(substring(defaultmodel, i+1, -1));
 448                         defaultmodel = substring(defaultmodel, 0, i);
 449                 }
 450         }
 451         if(autocvar_sv_defaultcharacterskin && !defaultskin)
 452         {
 453                 if(teamplay)
 454                 {
 455                         switch(player.team)
 456                         {
 457                                 case NUM_TEAM_1: defaultskin = autocvar_sv_defaultplayerskin_red; break;
 458                                 case NUM_TEAM_2: defaultskin = autocvar_sv_defaultplayerskin_blue; break;
 459                                 case NUM_TEAM_3: defaultskin = autocvar_sv_defaultplayerskin_yellow; break;
 460                                 case NUM_TEAM_4: defaultskin = autocvar_sv_defaultplayerskin_pink; break;
 461                         }
 462                 }
 463
 464                 if(!defaultskin)
 465                         defaultskin = autocvar_sv_defaultplayerskin;
 466         }
 467
 468         MUTATOR_CALLHOOK(FixPlayermodel, defaultmodel, defaultskin, player);
 469         defaultmodel = M_ARGV(0, string);
 470         defaultskin = M_ARGV(1, int);
 471
 472         bool chmdl = false;
 473         int oldskin;
 474         if(defaultmodel != "")
 475         {
 476                 if (defaultmodel != player.model)
 477                 {
 478                         vector m1 = player.mins;
 479                         vector m2 = player.maxs;
 480                         setplayermodel (player, defaultmodel);
 481                         setsize (player, m1, m2);
 482                         chmdl = true;
 483                 }
 484
 485                 oldskin = player.skin;
 486                 player.skin = defaultskin;
 487         } else {
 488                 if (player.playermodel != player.model || player.playermodel == "")
 489                 {
 490                         player.playermodel = CheckPlayerModel(player.playermodel); // this is never "", so no endless loop
 491                         vector m1 = player.mins;
 492                         vector m2 = player.maxs;
 493                         setplayermodel (player, player.playermodel);
 494                         setsize (player, m1, m2);
 495                         chmdl = true;
 496                 }
 497
 498                 if(!autocvar_sv_defaultcharacterskin)
 499                 {
 500                         oldskin = player.skin;
 501                         player.skin = stof(player.playerskin);
 502                 }
 503                 else
 504                 {
 505                         oldskin = player.skin;
 506                         player.skin = defaultskin;
 507                 }
 508         }
 509
 510         if(chmdl || oldskin != player.skin) // model or skin has changed
 511         {
 512                 player.species = player_getspecies(player); // update species
 513                 if(!autocvar_g_debug_globalsounds)
 514                         UpdatePlayerSounds(player); // update skin sounds
 515         }
 516
 517         if(!teamplay)
 518                 if(strlen(autocvar_sv_defaultplayercolors))
 519                         if(player.clientcolors != stof(autocvar_sv_defaultplayercolors))
 520                                 setcolor(player, stof(autocvar_sv_defaultplayercolors));
 521 }
 522
 523 void PutPlayerInServer(entity this)
 524 {
 525         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
 526
 527         PlayerState_attach(this);
 528         accuracy_resend(this);
 529
 530         if (this.team < 0)
 531                 TeamBalance_JoinBestTeam(this);
 532
 533         entity spot = SelectSpawnPoint(this, false);
 534         if (!spot) {
 535                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_JOIN_NOSPAWNS);
 536                 return; // spawn failed
 537         }
 538
 539         TRANSMUTE(Player, this);
 540
 541         CS(this).wasplayer = true;
 542         this.iscreature = true;
 543         this.teleportable = TELEPORT_NORMAL;
 544         if(!this.damagedbycontents)
 545                 IL_PUSH(g_damagedbycontents, this);
 546         this.damagedbycontents = true;
 547         set_movetype(this, MOVETYPE_WALK);
 548         this.solid = SOLID_SLIDEBOX;
 549         this.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_SOLID;
 550         if (autocvar_g_playerclip_collisions)
 551                 this.dphitcontentsmask |= DPCONTENTS_PLAYERCLIP;
 552         if (IS_BOT_CLIENT(this) && autocvar_g_botclip_collisions)
 553                 this.dphitcontentsmask |= DPCONTENTS_BOTCLIP;
 554         this.frags = FRAGS_PLAYER;
 555         if (INDEPENDENT_PLAYERS) MAKE_INDEPENDENT_PLAYER(this);
 556         this.flags = FL_CLIENT | FL_PICKUPITEMS;
 557         if (autocvar__notarget)
 558                 this.flags |= FL_NOTARGET;
 559         this.takedamage = DAMAGE_AIM;
 560         this.effects = EF_TELEPORT_BIT | EF_RESTARTANIM_BIT;
 561
 562         if (warmup_stage) {
 563                 SetResource(this, RES_SHELLS, warmup_start_ammo_shells);
 564                 SetResource(this, RES_BULLETS, warmup_start_ammo_nails);
 565                 SetResource(this, RES_ROCKETS, warmup_start_ammo_rockets);
 566                 SetResource(this, RES_CELLS, warmup_start_ammo_cells);
 567                 SetResource(this, RES_PLASMA, warmup_start_ammo_plasma);
 568                 SetResource(this, RES_FUEL, warmup_start_ammo_fuel);
 569                 SetResource(this, RES_HEALTH, warmup_start_health);
 570                 SetResource(this, RES_ARMOR, warmup_start_armorvalue);
 571                 STAT(WEAPONS, this) = WARMUP_START_WEAPONS;
 572         } else {
 573                 SetResource(this, RES_SHELLS, start_ammo_shells);
 574                 SetResource(this, RES_BULLETS, start_ammo_nails);
 575                 SetResource(this, RES_ROCKETS, start_ammo_rockets);
 576                 SetResource(this, RES_CELLS, start_ammo_cells);
 577                 SetResource(this, RES_PLASMA, start_ammo_plasma);
 578                 SetResource(this, RES_FUEL, start_ammo_fuel);
 579                 SetResource(this, RES_HEALTH, start_health);
 580                 SetResource(this, RES_ARMOR, start_armorvalue);
 581                 STAT(WEAPONS, this) = start_weapons;
 582                 if (MUTATOR_CALLHOOK(ForbidRandomStartWeapons, this) == false)
 583                 {
 584                         GiveRandomWeapons(this, random_start_weapons_count,
 585                                 autocvar_g_random_start_weapons, random_start_ammo);
 586                 }
 587         }
 588         SetSpectatee_status(this, 0);
 589
 590         PS(this).dual_weapons = '0 0 0';
 591
 592         STAT(SUPERWEAPONS_FINISHED, this) = (STAT(WEAPONS, this) & WEPSET_SUPERWEAPONS) ? time + autocvar_g_balance_superweapons_time : 0;
 593
 594         this.items = start_items;
 595
 596         this.spawnshieldtime = time + autocvar_g_spawnshieldtime;
 597         this.pauserotarmor_finished = time + autocvar_g_balance_pause_armor_rot_spawn;
 598         this.pauserothealth_finished = time + autocvar_g_balance_pause_health_rot_spawn;
 599         this.pauserotfuel_finished = time + autocvar_g_balance_pause_fuel_rot_spawn;
 600         this.pauseregen_finished = time + autocvar_g_balance_pause_health_regen_spawn;
 601         if (!sv_ready_restart_after_countdown && time < game_starttime)
 602         {
 603                 float f = game_starttime - time;
 604                 this.spawnshieldtime += f;
 605                 this.pauserotarmor_finished += f;
 606                 this.pauserothealth_finished += f;
 607                 this.pauseregen_finished += f;
 608         }
 609
 610         this.damageforcescale = autocvar_g_player_damageforcescale;
 611         this.death_time = 0;
 612         this.respawn_flags = 0;
 613         this.respawn_time = 0;
 614         STAT(RESPAWN_TIME, this) = 0;
 615         bool q3dfcompat = autocvar_sv_q3defragcompat && autocvar_sv_q3defragcompat_changehitbox;
 616         this.scale = ((q3dfcompat) ? 0.9 : autocvar_sv_player_scale);
 617         this.fade_time = 0;
 618         this.pain_frame = 0;
 619         this.pain_finished = 0;
 620         this.pushltime = 0;
 621         setthink(this, func_null); // players have no think function
 622         this.nextthink = 0;
 623         this.dmg_team = 0;
 624         PS(this).ballistics_density = autocvar_g_ballistics_density_player;
 625
 626         this.deadflag = DEAD_NO;
 627
 628         this.angles = spot.angles;
 629         this.angles_z = 0; // never spawn tilted even if the spot says to
 630         if (IS_BOT_CLIENT(this))
 631         {
 632                 this.v_angle = this.angles;
 633                 bot_aim_reset(this);
 634         }
 635         this.fixangle = true; // turn this way immediately
 636         this.oldvelocity = this.velocity = '0 0 0';
 637         this.avelocity = '0 0 0';
 638         this.punchangle = '0 0 0';
 639         this.punchvector = '0 0 0';
 640
 641         STAT(STRENGTH_FINISHED, this) = 0;
 642         STAT(INVINCIBLE_FINISHED, this) = 0;
 643         this.fire_endtime = -1;
 644         STAT(REVIVE_PROGRESS, this) = 0;
 645         this.revival_time = 0;
 646
 647         // TODO: we can't set these in the PlayerSpawn hook since the target code is called before it!
 648         STAT(BUFFS, this) = 0;
 649         STAT(BUFF_TIME, this) = 0;
 650
 651         this.air_finished = 0;
 652         this.waterlevel = WATERLEVEL_NONE;
 653         this.watertype = CONTENT_EMPTY;
 654
 655         entity spawnevent = new_pure(spawnevent);
 656         spawnevent.owner = this;
 657         Net_LinkEntity(spawnevent, false, 0.5, SpawnEvent_Send);
 658
 659         // Cut off any still running player sounds.
 660         stopsound(this, CH_PLAYER_SINGLE);
 661
 662         this.model = "";
 663         FixPlayermodel(this);
 664         this.drawonlytoclient = NULL;
 665
 666         this.viewloc = NULL;
 667
 668         for(int slot = 0; slot < MAX_AXH; ++slot)
 669         {
 670                 entity axh = this.(AuxiliaryXhair[slot]);
 671                 this.(AuxiliaryXhair[slot]) = NULL;
 672
 673                 if(axh.owner == this && axh != NULL && !wasfreed(axh))
 674                         delete(axh);
 675         }
 676
 677         this.spawnpoint_targ = NULL;
 678
 679         this.crouch = false;
 680         this.view_ofs = STAT(PL_VIEW_OFS, this);
 681         setsize(this, STAT(PL_MIN, this), STAT(PL_MAX, this));
 682         this.spawnorigin = spot.origin;
 683         setorigin(this, spot.origin + '0 0 1' * (1 - this.mins.z - 24));
 684         // don't reset back to last position, even if new position is stuck in solid
 685         this.oldorigin = this.origin;
 686         if(this.conveyor)
 687                 IL_REMOVE(g_conveyed, this);
 688         this.conveyor = NULL; // prevent conveyors at the previous location from moving a freshly spawned player
 689         if(this.swampslug)
 690                 IL_REMOVE(g_swamped, this);
 691         this.swampslug = NULL;
 692         this.swamp_interval = 0;
 693         STAT(HUD, this) = HUD_NORMAL;
 694
 695         this.event_damage = PlayerDamage;
 696         this.event_heal = PlayerHeal;
 697
 698         this.draggable = func_null;
 699
 700         if(!this.bot_attack)
 701                 IL_PUSH(g_bot_targets, this);
 702         this.bot_attack = true;
 703         if(!this.monster_attack)
 704                 IL_PUSH(g_monster_targets, this);
 705         this.monster_attack = true;
 706         navigation_dynamicgoal_init(this, false);
 707
 708         PHYS_INPUT_BUTTON_ATCK(this) = PHYS_INPUT_BUTTON_JUMP(this) = PHYS_INPUT_BUTTON_ATCK2(this) = false;
 709
 710         // player was spectator
 711         if (CS(this).killcount == FRAGS_SPECTATOR) {
 712                 PlayerScore_Clear(this);
 713                 CS(this).killcount = 0;
 714                 CS(this).startplaytime = time;
 715         }
 716
 717         for (int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 718         {
 719                 .entity weaponentity = weaponentities[slot];
 720                 CL_SpawnWeaponentity(this, weaponentity);
 721         }
 722         this.alpha = default_player_alpha;
 723         this.colormod = '1 1 1' * autocvar_g_player_brightness;
 724         this.exteriorweaponentity.alpha = default_weapon_alpha;
 725
 726         this.speedrunning = false;
 727
 728         this.counter_cnt = 0;
 729         this.fragsfilter_cnt = 0;
 730
 731         target_voicescript_clear(this);
 732
 733         // reset fields the weapons may use
 734         FOREACH(Weapons, true, {
 735                 it.wr_resetplayer(it, this);
 736                         // reload all reloadable weapons
 737                 if (it.spawnflags & WEP_FLAG_RELOADABLE) {
 738                         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 739                         {
 740                                 .entity weaponentity = weaponentities[slot];
 741                                 this.(weaponentity).weapon_load[it.m_id] = it.reloading_ammo;
 742                         }
 743                 }
 744         });
 745
 746         {
 747                 string s = spot.target;
 748                 if(g_assault || g_race) // TODO: make targeting work in assault & race without this hack
 749                         spot.target = string_null;
 750                 SUB_UseTargets(spot, this, NULL);
 751                 if(g_assault || g_race)
 752                         spot.target = s;
 753         }
 754
 755         Unfreeze(this, false);
 756
 757         MUTATOR_CALLHOOK(PlayerSpawn, this, spot);
 758
 759         if (autocvar_spawn_debug)
 760         {
 761                 sprint(this, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
 762                 delete(spot); // usefull for checking if there are spawnpoints, that let drop through the floor
 763         }
 764
 765         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 766         {
 767                 .entity weaponentity = weaponentities[slot];
 768                 if(slot == 0 || autocvar_g_weaponswitch_debug == 1)
 769                         this.(weaponentity).m_switchweapon = w_getbestweapon(this, weaponentity);
 770                 else
 771                         this.(weaponentity).m_switchweapon = WEP_Null;
 772                 this.(weaponentity).m_weapon = WEP_Null;
 773                 this.(weaponentity).weaponname = "";
 774                 this.(weaponentity).m_switchingweapon = WEP_Null;
 775                 this.(weaponentity).cnt = -1;
 776         }
 777
 778         MUTATOR_CALLHOOK(PlayerWeaponSelect, this);
 779
 780         if (CS(this).impulse) ImpulseCommands(this);
 781
 782         W_ResetGunAlign(this, CS(this).cvar_cl_gunalign);
 783         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 784         {
 785                 .entity weaponentity = weaponentities[slot];
 786                 W_WeaponFrame(this, weaponentity);
 787         }
 788
 789         if (!warmup_stage && !this.alivetime)
 790                 this.alivetime = time;
 791
 792         antilag_clear(this, CS(this));
 793 }
 794
 795 /** Called when a client spawns in the server */
 796 void PutClientInServer(entity this)
 797 {
 798         if (IS_BOT_CLIENT(this)) {
 799                 TRANSMUTE(Player, this);
 800         } else if (IS_REAL_CLIENT(this)) {
 801                 msg_entity = this;
 802                 WriteByte(MSG_ONE, SVC_SETVIEW);
 803                 WriteEntity(MSG_ONE, this);
 804         }
 805         if (game_stopped)
 806                 TRANSMUTE(Observer, this);
 807
 808         SetSpectatee(this, NULL);
 809
 810         // reset player keys
 811         if(PS(this))
 812                 PS(this).itemkeys = 0;
 813
 814         MUTATOR_CALLHOOK(PutClientInServer, this);
 815
 816         if (IS_OBSERVER(this)) {
 817                 PutObserverInServer(this);
 818         } else if (IS_PLAYER(this)) {
 819                 PutPlayerInServer(this);
 820         }
 821 }
 822
 823 // TODO do we need all these fields, or should we stop autodetecting runtime
 824 // changes and just have a console command to update this?
 825 bool ClientInit_SendEntity(entity this, entity to, int sf)
 826 {
 827         WriteHeader(MSG_ENTITY, _ENT_CLIENT_INIT);
 828         return = true;
 829         msg_entity = to;
 830         // MSG_INIT replacement
 831         // TODO: make easier to use
 832         Registry_send_all();
 833         W_PROP_reload(MSG_ONE, to);
 834         ClientInit_misc(this);
 835         MUTATOR_CALLHOOK(Ent_Init);
 836 }
 837 void ClientInit_misc(entity this)
 838 {
 839         int channel = MSG_ONE;
 840         WriteHeader(channel, ENT_CLIENT_INIT);
 841         WriteByte(channel, g_nexball_meter_period * 32);
 842         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[0]));
 843         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[1]));
 844         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[2]));
 845         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[3]));
 846         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[0]));
 847         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[1]));
 848         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[2]));
 849         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[3]));
 850
 851         if(sv_foginterval && world.fog != "")
 852                 WriteString(channel, world.fog);
 853         else
 854                 WriteString(channel, "");
 855         WriteByte(channel, this.count * 255.0); // g_balance_armor_blockpercent
 856         WriteByte(channel, this.cnt * 255.0); // g_balance_damagepush_speedfactor
 857         WriteByte(channel, serverflags);
 858         WriteCoord(channel, autocvar_g_trueaim_minrange);
 859 }
 860
 861 void ClientInit_CheckUpdate(entity this)
 862 {
 863         this.nextthink = time;
 864         if(this.count != autocvar_g_balance_armor_blockpercent)
 865         {
 866                 this.count = autocvar_g_balance_armor_blockpercent;
 867                 this.SendFlags |= 1;
 868         }
 869         if(this.cnt != autocvar_g_balance_damagepush_speedfactor)
 870         {
 871                 this.cnt = autocvar_g_balance_damagepush_speedfactor;
 872                 this.SendFlags |= 1;
 873         }
 874 }
 875
 876 void ClientInit_Spawn()
 877 {
 878         entity e = new_pure(clientinit);
 879         setthink(e, ClientInit_CheckUpdate);
 880         Net_LinkEntity(e, false, 0, ClientInit_SendEntity);
 881
 882         ClientInit_CheckUpdate(e);
 883 }
 884
 885 /*
 886 =============
 887 SetNewParms
 888 =============
 889 */
 890 void SetNewParms ()
 891 {
 892         // initialize parms for a new player
 893         parm1 = -(86400 * 366);
 894
 895         MUTATOR_CALLHOOK(SetNewParms);
 896 }
 897
 898 /*
 899 =============
 900 SetChangeParms
 901 =============
 902 */
 903 void SetChangeParms (entity this)
 904 {
 905         // save parms for level change
 906         parm1 = CS(this).parm_idlesince - time;
 907
 908         MUTATOR_CALLHOOK(SetChangeParms);
 909 }
 910
 911 /*
 912 =============
 913 DecodeLevelParms
 914 =============
 915 */
 916 void DecodeLevelParms(entity this)
 917 {
 918         // load parms
 919         CS(this).parm_idlesince = parm1;
 920         if (CS(this).parm_idlesince == -(86400 * 366))
 921                 CS(this).parm_idlesince = time;
 922
 923         // whatever happens, allow 60 seconds of idling directly after connect for map loading
 924         CS(this).parm_idlesince = max(CS(this).parm_idlesince, time - sv_maxidle + 60);
 925
 926         MUTATOR_CALLHOOK(DecodeLevelParms);
 927 }
 928
 929 void FixClientCvars(entity e)
 930 {
 931         // send prediction settings to the client
 932         stuffcmd(e, "\nin_bindmap 0 0\n");
 933         if(autocvar_g_antilag == 3) // client side hitscan
 934                 stuffcmd(e, "cl_cmd settemp cl_prydoncursor_notrace 0\n");
 935         if(autocvar_sv_gentle)
 936                 stuffcmd(e, "cl_cmd settemp cl_gentle 1\n");
 937
 938         stuffcmd(e, sprintf("\ncl_jumpspeedcap_min \"%s\"\n", autocvar_sv_jumpspeedcap_min));
 939         stuffcmd(e, sprintf("\ncl_jumpspeedcap_max \"%s\"\n", autocvar_sv_jumpspeedcap_max));
 940
 941         stuffcmd(e, sprintf("\ncl_shootfromfixedorigin \"%s\"\n", autocvar_g_shootfromfixedorigin));
 942
 943         MUTATOR_CALLHOOK(FixClientCvars, e);
 944 }
 945
 946 bool findinlist_abbrev(string tofind, string list)
 947 {
 948         if(list == "" || tofind == "")
 949                 return false; // empty list or search, just return
 950
 951         // this function allows abbreviated strings!
 952         FOREACH_WORD(list, it == substring(tofind, 0, strlen(it)),
 953         {
 954                 return true;
 955         });
 956
 957         return false;
 958 }
 959
 960 bool PlayerInIPList(entity p, string iplist)
 961 {
 962         // some safety checks (never allow local?)
 963         if(p.netaddress == "local" || p.netaddress == "" || !IS_REAL_CLIENT(p))
 964                 return false;
 965
 966         return findinlist_abbrev(p.netaddress, iplist);
 967 }
 968
 969 bool PlayerInIDList(entity p, string idlist)
 970 {
 971         // NOTE: we do NOT check crypto_idfp_signed here, an unsigned ID is fine too for this
 972         if(!p.crypto_idfp)
 973                 return false;
 974
 975         return findinlist_abbrev(p.crypto_idfp, idlist);
 976 }
 977
 978 bool PlayerInList(entity player, string list)
 979 {
 980         return boolean(PlayerInIDList(player, list) || PlayerInIPList(player, list));
 981 }
 982
 983 #ifdef DP_EXT_PRECONNECT
 984 /*
 985 =============
 986 ClientPreConnect
 987
 988 Called once (not at each match start) when a client begins a connection to the server
 989 =============
 990 */
 991 void ClientPreConnect(entity this)
 992 {
 993         if(autocvar_sv_eventlog)
 994         {
 995                 GameLogEcho(sprintf(":connect:%d:%d:%s",
 996                         this.playerid,
 997                         etof(this),
 998                         ((IS_REAL_CLIENT(this)) ? this.netaddress : "bot")
 999                 ));
1000         }
1001 }
1002 #endif
1003
1004 string GetClientVersionMessage(entity this)
1005 {
1006         if (CS(this).version_mismatch) {
1007                 if(CS(this).version < autocvar_gameversion) {
1008                         return strcat("This is Xonotic ", autocvar_g_xonoticversion,
1009                                 "\n^3Your client version is outdated.\n\n\n### YOU WON'T BE ABLE TO PLAY ON THIS SERVER ###\n\n\nPlease update!!!^8");
1010                 } else {
1011                         return strcat("This is Xonotic ", autocvar_g_xonoticversion,
1012                                 "\n^3This server is using an outdated Xonotic version.\n\n\n ### THIS SERVER IS INCOMPATIBLE AND THUS YOU CANNOT JOIN ###.^8");
1013                 }
1014         } else {
1015                 return strcat("Welcome to Xonotic ", autocvar_g_xonoticversion);
1016         }
1017 }
1018
1019 string getwelcomemessage(entity this)
1020 {
1021         MUTATOR_CALLHOOK(BuildMutatorsPrettyString, "");
1022         string modifications = M_ARGV(0, string);
1023
1024         if(g_weaponarena)
1025         {
1026                 if(g_weaponarena_random)
1027                         modifications = strcat(modifications, ", ", ftos(g_weaponarena_random), " of ", g_weaponarena_list, " Arena");
1028                 else
1029                         modifications = strcat(modifications, ", ", g_weaponarena_list, " Arena");
1030         }
1031         else if(cvar("g_balance_blaster_weaponstartoverride") == 0)
1032                 modifications = strcat(modifications, ", No start weapons");
1033         if(cvar("sv_gravity") < stof(cvar_defstring("sv_gravity")))
1034                 modifications = strcat(modifications, ", Low gravity");
1035         if(g_weapon_stay && !g_cts)
1036                 modifications = strcat(modifications, ", Weapons stay");
1037         if(g_jetpack)
1038                 modifications = strcat(modifications, ", Jet pack");
1039         if(autocvar_g_powerups == 0)
1040                 modifications = strcat(modifications, ", No powerups");
1041         if(autocvar_g_powerups > 0)
1042                 modifications = strcat(modifications, ", Powerups");
1043         modifications = substring(modifications, 2, strlen(modifications) - 2);
1044
1045         string versionmessage = GetClientVersionMessage(this);
1046         string s = strcat(versionmessage, "^8\n^8\nhost is ^9", autocvar_hostname, "^8\n");
1047
1048         s = strcat(s, "^8\nmatch type is ^1", gamemode_name, "^8\n");
1049
1050         if(modifications != "")
1051                 s = strcat(s, "^8\nactive modifications: ^3", modifications, "^8\n");
1052
1053         if(cache_lastmutatormsg != autocvar_g_mutatormsg)
1054         {
1055                 strcpy(cache_lastmutatormsg, autocvar_g_mutatormsg);
1056                 strcpy(cache_mutatormsg, cache_lastmutatormsg);
1057         }
1058
1059         if (cache_mutatormsg != "") {
1060                 s = strcat(s, "\n\n^8special gameplay tips: ^7", cache_mutatormsg);
1061         }
1062
1063         string mutator_msg = "";
1064         MUTATOR_CALLHOOK(BuildGameplayTipsString, mutator_msg);
1065         mutator_msg = M_ARGV(0, string);
1066
1067         s = strcat(s, mutator_msg); // trust that the mutator will do proper formatting
1068
1069         string motd = autocvar_sv_motd;
1070         if (motd != "") {
1071                 s = strcat(s, "\n\n^8MOTD: ^7", strreplace("\\n", "\n", motd));
1072         }
1073         return s;
1074 }
1075
1076 bool autocvar_sv_qcphysics = true; // TODO this is for testing - remove when qcphysics work
1077
1078 /**
1079 =============
1080 ClientConnect
1081
1082 Called when a client connects to the server
1083 =============
1084 */
1085 void ClientConnect(entity this)
1086 {
1087         if (Ban_MaybeEnforceBanOnce(this)) return;
1088         assert(!IS_CLIENT(this), return);
1089         this.flags |= FL_CLIENT;
1090         assert(player_count >= 0, player_count = 0);
1091
1092 #ifdef WATERMARK
1093         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_WATERMARK, WATERMARK);
1094 #endif
1095         TRANSMUTE(Client, this);
1096         CS(this).version_nagtime = time + 10 + random() * 10;
1097
1098         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_JOIN_CONNECT, this.netname);
1099
1100         bot_clientconnect(this);
1101
1102         Player_DetermineForcedTeam(this);
1103
1104         TRANSMUTE(Observer, this);
1105
1106         PlayerStats_GameReport_AddEvent(sprintf("kills-%d", this.playerid));
1107
1108         // always track bots, don't ask for cl_allow_uidtracking
1109         if (IS_BOT_CLIENT(this))
1110                 PlayerStats_GameReport_AddPlayer(this);
1111         else
1112                 CS(this).allowed_timeouts = autocvar_sv_timeout_number;
1113
1114         if (autocvar_sv_eventlog)
1115                 GameLogEcho(strcat(":join:", ftos(this.playerid), ":", ftos(etof(this)), ":", ((IS_REAL_CLIENT(this)) ? GameLog_ProcessIP(this.netaddress) : "bot"), ":", playername(this, false)));
1116
1117         CS(this).just_joined = true;  // stop spamming the eventlog with additional lines when the client connects
1118
1119         stuffcmd(this, clientstuff, "\n");
1120         stuffcmd(this, "cl_particles_reloadeffects\n"); // TODO do we still need this?
1121
1122         FixClientCvars(this);
1123
1124         // get version info from player
1125         stuffcmd(this, "cmd clientversion $gameversion\n");
1126
1127         // notify about available teams
1128         if (teamplay)
1129         {
1130                 entity balance = TeamBalance_CheckAllowedTeams(this);
1131                 int t = TeamBalance_GetAllowedTeams(balance);
1132                 TeamBalance_Destroy(balance);
1133                 stuffcmd(this, sprintf("set _teams_available %d\n", t));
1134         }
1135         else
1136         {
1137                 stuffcmd(this, "set _teams_available 0\n");
1138         }
1139
1140         bot_relinkplayerlist();
1141
1142         CS(this).spectatortime = time;
1143         if (blockSpectators)
1144         {
1145                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
1146         }
1147
1148         CS(this).jointime = time;
1149
1150         if (IS_REAL_CLIENT(this))
1151         {
1152                 if (g_weaponarena_weapons == WEPSET(TUBA))
1153                         stuffcmd(this, "cl_cmd settemp chase_active 1\n");
1154         }
1155
1156         if (!sv_foginterval && world.fog != "")
1157                 stuffcmd(this, strcat("\nfog ", world.fog, "\nr_fog_exp2 0\nr_drawfog 1\n"));
1158
1159         if (autocvar_sv_teamnagger && !(autocvar_bot_vs_human && AvailableTeams() == 2))
1160                 if(!MUTATOR_CALLHOOK(HideTeamNagger, this))
1161                         send_CSQC_teamnagger();
1162
1163         CSQCMODEL_AUTOINIT(this);
1164
1165         CS(this).model_randomizer = random();
1166
1167         if (IS_REAL_CLIENT(this))
1168                 sv_notice_join(this);
1169
1170         this.move_qcphysics = autocvar_sv_qcphysics;
1171
1172         // update physics stats (players can spawn before physics runs)
1173         Physics_UpdateStats(this);
1174
1175         IL_EACH(g_initforplayer, it.init_for_player, {
1176                 it.init_for_player(it, this);
1177         });
1178
1179         Handicap_Initialize(this);
1180
1181         MUTATOR_CALLHOOK(ClientConnect, this);
1182
1183         if (IS_REAL_CLIENT(this))
1184         {
1185                 if (!autocvar_g_campaign && !IS_PLAYER(this))
1186                 {
1187                         CS(this).motd_actived_time = -1;
1188                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOTD, getwelcomemessage(this));
1189                 }
1190         }
1191 }
1192 /*
1193 =============
1194 ClientDisconnect
1195
1196 Called when a client disconnects from the server
1197 =============
1198 */
1199 .entity chatbubbleentity;
1200 void ClientDisconnect(entity this)
1201 {
1202         assert(IS_CLIENT(this), return);
1203
1204         PlayerStats_GameReport_FinalizePlayer(this);
1205         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
1206         if (CS(this).active_minigame) part_minigame(this);
1207         if (IS_PLAYER(this)) Send_Effect(EFFECT_SPAWN_NEUTRAL, this.origin, '0 0 0', 1);
1208
1209         if (autocvar_sv_eventlog)
1210                 GameLogEcho(strcat(":part:", ftos(this.playerid)));
1211
1212         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_QUIT_DISCONNECT, this.netname);
1213
1214         if(IS_SPEC(this))
1215                 SetSpectatee(this, NULL);
1216
1217     MUTATOR_CALLHOOK(ClientDisconnect, this);
1218
1219         strfree(CS(this).netname_previous); // needs to be before the CS entity is removed!
1220         strfree(CS(this).weaponorder_byimpulse);
1221         ClientState_detach(this);
1222
1223         Portal_ClearAll(this);
1224
1225         Unfreeze(this, false);
1226
1227         RemoveGrapplingHooks(this);
1228
1229         // Here, everything has been done that requires this player to be a client.
1230
1231         this.flags &= ~FL_CLIENT;
1232
1233         if (this.chatbubbleentity) delete(this.chatbubbleentity);
1234         if (this.killindicator) delete(this.killindicator);
1235
1236         WaypointSprite_PlayerGone(this);
1237
1238         bot_relinkplayerlist();
1239
1240         strfree(this.clientstatus);
1241         if (this.personal) delete(this.personal);
1242
1243         this.playerid = 0;
1244         ReadyCount();
1245         if (vote_called && IS_REAL_CLIENT(this)) VoteCount(false);
1246
1247         ONREMOVE(this);
1248 }
1249
1250 void ChatBubbleThink(entity this)
1251 {
1252         this.nextthink = time;
1253         if ((this.owner.alpha < 0) || this.owner.chatbubbleentity != this)
1254         {
1255                 if(this.owner) // but why can that ever be NULL?
1256                         this.owner.chatbubbleentity = NULL;
1257                 delete(this);
1258                 return;
1259         }
1260
1261         this.mdl = "";
1262
1263         if ( !IS_DEAD(this.owner) && IS_PLAYER(this.owner) )
1264         {
1265                 if ( CS(this.owner).active_minigame && PHYS_INPUT_BUTTON_MINIGAME(this.owner) )
1266                         this.mdl = "models/sprites/minigame_busy.iqm";
1267                 else if (PHYS_INPUT_BUTTON_CHAT(this.owner))
1268                         this.mdl = "models/misc/chatbubble.spr";
1269         }
1270
1271         if ( this.model != this.mdl )
1272                 _setmodel(this, this.mdl);
1273
1274 }
1275
1276 void UpdateChatBubble(entity this)
1277 {
1278         if (this.alpha < 0)
1279                 return;
1280         // spawn a chatbubble entity if needed
1281         if (!this.chatbubbleentity)
1282         {
1283                 this.chatbubbleentity = new(chatbubbleentity);
1284                 this.chatbubbleentity.owner = this;
1285                 this.chatbubbleentity.exteriormodeltoclient = this;
1286                 setthink(this.chatbubbleentity, ChatBubbleThink);
1287                 this.chatbubbleentity.nextthink = time;
1288                 setmodel(this.chatbubbleentity, MDL_CHAT); // precision set below
1289                 //setorigin(this.chatbubbleentity, this.origin + '0 0 15' + this.maxs_z * '0 0 1');
1290                 setorigin(this.chatbubbleentity, '0 0 15' + this.maxs_z * '0 0 1');
1291                 setattachment(this.chatbubbleentity, this, "");  // sticks to moving player better, also conserves bandwidth
1292                 this.chatbubbleentity.mdl = this.chatbubbleentity.model;
1293                 //this.chatbubbleentity.model = "";
1294                 this.chatbubbleentity.effects = EF_LOWPRECISION;
1295         }
1296 }
1297
1298
1299 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
1300 // added to the model skins
1301 /*void UpdateColorModHack()
1302 {
1303         float c;
1304         c = this.clientcolors & 15;
1305         // LordHavoc: only bothering to support white, green, red, yellow, blue
1306              if (!teamplay) this.colormod = '0 0 0';
1307         else if (c ==  0) this.colormod = '1.00 1.00 1.00';
1308         else if (c ==  3) this.colormod = '0.10 1.73 0.10';
1309         else if (c ==  4) this.colormod = '1.73 0.10 0.10';
1310         else if (c == 12) this.colormod = '1.22 1.22 0.10';
1311         else if (c == 13) this.colormod = '0.10 0.10 1.73';
1312         else this.colormod = '1 1 1';
1313 }*/
1314
1315 void respawn(entity this)
1316 {
1317         if(this.alpha >= 0 && autocvar_g_respawn_ghosts)
1318         {
1319                 this.solid = SOLID_NOT;
1320                 this.takedamage = DAMAGE_NO;
1321                 set_movetype(this, MOVETYPE_FLY);
1322                 this.velocity = '0 0 1' * autocvar_g_respawn_ghosts_speed;
1323                 this.avelocity = randomvec() * autocvar_g_respawn_ghosts_speed * 3 - randomvec() * autocvar_g_respawn_ghosts_speed * 3;
1324                 this.effects |= CSQCMODEL_EF_RESPAWNGHOST;
1325                 Send_Effect(EFFECT_RESPAWN_GHOST, this.origin, '0 0 0', 1);
1326                 if(autocvar_g_respawn_ghosts_maxtime)
1327                         SUB_SetFade (this, time + autocvar_g_respawn_ghosts_maxtime / 2 + random () * (autocvar_g_respawn_ghosts_maxtime - autocvar_g_respawn_ghosts_maxtime / 2), 1.5);
1328         }
1329
1330         CopyBody(this, 1);
1331
1332         this.effects |= EF_NODRAW; // prevent another CopyBody
1333         PutClientInServer(this);
1334 }
1335
1336 ERASEABLE
1337 void PrintToChat(entity client, string text)
1338 {
1339         text = strcat("\{1}^7", text, "\n");
1340         sprint(client, text);
1341 }
1342
1343 ERASEABLE
1344 void DebugPrintToChat(entity client, string text)
1345 {
1346         if (autocvar_developer > 0)
1347         {
1348                 PrintToChat(client, text);
1349         }
1350 }
1351
1352 ERASEABLE
1353 void PrintToChatAll(string text)
1354 {
1355         text = strcat("\{1}^7", text, "\n");
1356         bprint(text);
1357 }
1358
1359 ERASEABLE
1360 void DebugPrintToChatAll(string text)
1361 {
1362         if (autocvar_developer > 0)
1363         {
1364                 PrintToChatAll(text);
1365         }
1366 }
1367
1368 ERASEABLE
1369 void PrintToChatTeam(int team_num, string text)
1370 {
1371         text = strcat("\{1}^7", text, "\n");
1372         FOREACH_CLIENT(IS_REAL_CLIENT(it),
1373         {
1374                 if (it.team == team_num)
1375                 {
1376                         sprint(it, text);
1377                 }
1378         });
1379 }
1380
1381 ERASEABLE
1382 void DebugPrintToChatTeam(int team_num, string text)
1383 {
1384         if (autocvar_developer > 0)
1385         {
1386                 PrintToChatTeam(team_num, text);
1387         }
1388 }
1389
1390 void play_countdown(entity this, float finished, Sound samp)
1391 {
1392         TC(Sound, samp);
1393         if(IS_REAL_CLIENT(this))
1394                 if(floor(finished - time - frametime) != floor(finished - time))
1395                         if(finished - time < 6)
1396                                 sound (this, CH_INFO, samp, VOL_BASE, ATTEN_NORM);
1397 }
1398
1399 void player_powerups(entity this)
1400 {
1401         // add a way to see what the items were BEFORE all of these checks for the mutator hook
1402         int items_prev = this.items;
1403
1404         if((this.items & IT_USING_JETPACK) && !IS_DEAD(this) && !game_stopped)
1405                 this.modelflags |= MF_ROCKET;
1406         else
1407                 this.modelflags &= ~MF_ROCKET;
1408
1409         this.effects &= ~(EF_RED | EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT | EF_FLAME | EF_NODEPTHTEST);
1410
1411         if((this.alpha < 0 || IS_DEAD(this)) && !this.vehicle) // don't apply the flags if the player is gibbed
1412                 return;
1413
1414         Fire_ApplyDamage(this);
1415         Fire_ApplyEffect(this);
1416
1417         if (!MUTATOR_IS_ENABLED(mutator_instagib))
1418         {
1419                 if (this.items & ITEM_Strength.m_itemid)
1420                 {
1421                         play_countdown(this, STAT(STRENGTH_FINISHED, this), SND_POWEROFF);
1422                         this.effects = this.effects | (EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT);
1423                         if (time > STAT(STRENGTH_FINISHED, this))
1424                         {
1425                                 this.items = this.items - (this.items & ITEM_Strength.m_itemid);
1426                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERDOWN_STRENGTH, this.netname);
1427                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERDOWN_STRENGTH);
1428                         }
1429                 }
1430                 else
1431                 {
1432                         if (time < STAT(STRENGTH_FINISHED, this))
1433                         {
1434                                 this.items = this.items | ITEM_Strength.m_itemid;
1435                                 if(!g_cts)
1436                                         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERUP_STRENGTH, this.netname);
1437                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERUP_STRENGTH);
1438                         }
1439                 }
1440                 if (this.items & ITEM_Shield.m_itemid)
1441                 {
1442                         play_countdown(this, STAT(INVINCIBLE_FINISHED, this), SND_POWEROFF);
1443                         this.effects = this.effects | (EF_RED | EF_ADDITIVE | EF_FULLBRIGHT);
1444                         if (time > STAT(INVINCIBLE_FINISHED, this))
1445                         {
1446                                 this.items = this.items - (this.items & ITEM_Shield.m_itemid);
1447                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERDOWN_SHIELD, this.netname);
1448                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERDOWN_SHIELD);
1449                         }
1450                 }
1451                 else
1452                 {
1453                         if (time < STAT(INVINCIBLE_FINISHED, this))
1454                         {
1455                                 this.items = this.items | ITEM_Shield.m_itemid;
1456                                 if(!g_cts)
1457                                         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERUP_SHIELD, this.netname);
1458                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERUP_SHIELD);
1459                         }
1460                 }
1461                 if (this.items & IT_SUPERWEAPON)
1462                 {
1463                         if (!(STAT(WEAPONS, this) & WEPSET_SUPERWEAPONS))
1464                         {
1465                                 STAT(SUPERWEAPONS_FINISHED, this) = 0;
1466                                 this.items = this.items - (this.items & IT_SUPERWEAPON);
1467                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_LOST, this.netname);
1468                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_LOST);
1469                         }
1470                         else if (this.items & IT_UNLIMITED_SUPERWEAPONS)
1471                         {
1472                                 // don't let them run out
1473                         }
1474                         else
1475                         {
1476                                 play_countdown(this, STAT(SUPERWEAPONS_FINISHED, this), SND_POWEROFF);
1477                                 if (time > STAT(SUPERWEAPONS_FINISHED, this))
1478                                 {
1479                                         this.items = this.items - (this.items & IT_SUPERWEAPON);
1480                                         STAT(WEAPONS, this) &= ~WEPSET_SUPERWEAPONS;
1481                                         //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_BROKEN, this.netname);
1482                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_BROKEN);
1483                                 }
1484                         }
1485                 }
1486                 else if(STAT(WEAPONS, this) & WEPSET_SUPERWEAPONS)
1487                 {
1488                         if (time < STAT(SUPERWEAPONS_FINISHED, this) || (this.items & IT_UNLIMITED_SUPERWEAPONS))
1489                         {
1490                                 this.items = this.items | IT_SUPERWEAPON;
1491                                 if(!(this.items & IT_UNLIMITED_SUPERWEAPONS))
1492                                 {
1493                                         if(!g_cts)
1494                                                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_PICKUP, this.netname);
1495                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_PICKUP);
1496                                 }
1497                         }
1498                         else
1499                         {
1500                                 STAT(SUPERWEAPONS_FINISHED, this) = 0;
1501                                 STAT(WEAPONS, this) &= ~WEPSET_SUPERWEAPONS;
1502                         }
1503                 }
1504                 else
1505                 {
1506                         STAT(SUPERWEAPONS_FINISHED, this) = 0;
1507                 }
1508         }
1509
1510         if(autocvar_g_nodepthtestplayers)
1511                 this.effects = this.effects | EF_NODEPTHTEST;
1512
1513         if(autocvar_g_fullbrightplayers)
1514                 this.effects = this.effects | EF_FULLBRIGHT;
1515
1516         if (time >= game_starttime)
1517         if (time < this.spawnshieldtime)
1518                 this.effects = this.effects | (EF_ADDITIVE | EF_FULLBRIGHT);
1519
1520         MUTATOR_CALLHOOK(PlayerPowerups, this, items_prev);
1521 }
1522
1523 float CalcRegen(float current, float stable, float regenfactor, float regenframetime)
1524 {
1525         if(current > stable)
1526                 return current;
1527         else if(current > stable - 0.25) // when close enough, "snap"
1528                 return stable;
1529         else
1530                 return min(stable, current + (stable - current) * regenfactor * regenframetime);
1531 }
1532
1533 float CalcRot(float current, float stable, float rotfactor, float rotframetime)
1534 {
1535         if(current < stable)
1536                 return current;
1537         else if(current < stable + 0.25) // when close enough, "snap"
1538                 return stable;
1539         else
1540                 return max(stable, current + (stable - current) * rotfactor * rotframetime);
1541 }
1542
1543 void RotRegen(entity this, int res, float regenstable, float regenfactor, float regenlinear, float regenframetime, float rotstable, float rotfactor, float rotlinear, float rotframetime, float limit_mod)
1544 {
1545         float old = GetResource(this, res);
1546         float current = old;
1547         if(current > rotstable)
1548         {
1549                 if(rotframetime > 0)
1550                 {
1551                         current = CalcRot(current, rotstable, rotfactor, rotframetime);
1552                         current = max(rotstable, current - rotlinear * rotframetime);
1553                 }
1554         }
1555         else if(current < regenstable)
1556         {
1557                 if(regenframetime > 0)
1558                 {
1559                         current = CalcRegen(current, regenstable, regenfactor, regenframetime);
1560                         current = min(regenstable, current + regenlinear * regenframetime);
1561                 }
1562         }
1563
1564         float limit = GetResourceLimit(this, res) * limit_mod;
1565         if(current > limit)
1566                 current = limit;
1567
1568         if (current != old)
1569                 SetResource(this, res, current);
1570 }
1571
1572 void player_regen(entity this)
1573 {
1574         float max_mod, regen_mod, rot_mod, limit_mod;
1575         max_mod = regen_mod = rot_mod = limit_mod = 1;
1576
1577         float regen_health = autocvar_g_balance_health_regen;
1578         float regen_health_linear = autocvar_g_balance_health_regenlinear;
1579         float regen_health_rot = autocvar_g_balance_health_rot;
1580         float regen_health_rotlinear = autocvar_g_balance_health_rotlinear;
1581         float regen_health_stable = autocvar_g_balance_health_regenstable;
1582         float regen_health_rotstable = autocvar_g_balance_health_rotstable;
1583         bool mutator_returnvalue = MUTATOR_CALLHOOK(PlayerRegen, this, max_mod, regen_mod, rot_mod, limit_mod, regen_health, regen_health_linear, regen_health_rot,
1584                 regen_health_rotlinear, regen_health_stable, regen_health_rotstable);
1585         max_mod = M_ARGV(1, float);
1586         regen_mod = M_ARGV(2, float);
1587         rot_mod = M_ARGV(3, float);
1588         limit_mod = M_ARGV(4, float);
1589         regen_health = M_ARGV(5, float);
1590         regen_health_linear = M_ARGV(6, float);
1591         regen_health_rot = M_ARGV(7, float);
1592         regen_health_rotlinear = M_ARGV(8, float);
1593         regen_health_stable = M_ARGV(9, float);
1594         regen_health_rotstable = M_ARGV(10, float);
1595
1596         if(!mutator_returnvalue)
1597         if(!STAT(FROZEN, this))
1598         {
1599                 float maxa = autocvar_g_balance_armor_rotstable;
1600                 float mina = autocvar_g_balance_armor_regenstable;
1601
1602                 RotRegen(this, RES_ARMOR, mina, autocvar_g_balance_armor_regen, autocvar_g_balance_armor_regenlinear,
1603                         regen_mod * frametime * (time > this.pauseregen_finished), maxa, autocvar_g_balance_armor_rot, autocvar_g_balance_armor_rotlinear,
1604                         rot_mod * frametime * (time > this.pauserotarmor_finished), limit_mod);
1605
1606                 RotRegen(this, RES_HEALTH, regen_health_stable * max_mod, regen_health, regen_health_linear,
1607                         regen_mod * frametime * (time > this.pauseregen_finished), regen_health_rotstable * max_mod, regen_health_rot, regen_health_rotlinear,
1608                         rot_mod * frametime * (time > this.pauserothealth_finished), limit_mod);
1609         }
1610
1611         // if player rotted to death...  die!
1612         // check this outside above checks, as player may still be able to rot to death
1613         if(GetResource(this, RES_HEALTH) < 1)
1614         {
1615                 if(this.vehicle)
1616                         vehicles_exit(this.vehicle, VHEF_RELEASE);
1617                 if(this.event_damage)
1618                         this.event_damage(this, this, this, 1, DEATH_ROT.m_id, DMG_NOWEP, this.origin, '0 0 0');
1619         }
1620
1621         if (!(this.items & IT_UNLIMITED_AMMO))
1622         {
1623                 float maxf = autocvar_g_balance_fuel_rotstable;
1624                 float minf = autocvar_g_balance_fuel_regenstable;
1625
1626                 RotRegen(this, RES_FUEL, minf, autocvar_g_balance_fuel_regen, autocvar_g_balance_fuel_regenlinear,
1627                         frametime * (time > this.pauseregen_finished) * ((this.items & ITEM_JetpackRegen.m_itemid) != 0),
1628                         maxf, autocvar_g_balance_fuel_rot, autocvar_g_balance_fuel_rotlinear, frametime * (time > this.pauserotfuel_finished), 1);
1629         }
1630 }
1631
1632 bool zoomstate_set;
1633 void SetZoomState(entity this, float newzoom)
1634 {
1635         if(newzoom != CS(this).zoomstate)
1636         {
1637                 CS(this).zoomstate = newzoom;
1638                 ClientData_Touch(this);
1639         }
1640         zoomstate_set = true;
1641 }
1642
1643 void GetPressedKeys(entity this)
1644 {
1645         MUTATOR_CALLHOOK(GetPressedKeys, this);
1646         int keys = STAT(PRESSED_KEYS, this);
1647         keys = BITSET(keys, KEY_FORWARD,        CS(this).movement.x > 0);
1648         keys = BITSET(keys, KEY_BACKWARD,       CS(this).movement.x < 0);
1649         keys = BITSET(keys, KEY_RIGHT,          CS(this).movement.y > 0);
1650         keys = BITSET(keys, KEY_LEFT,           CS(this).movement.y < 0);
1651
1652         keys = BITSET(keys, KEY_JUMP,           PHYS_INPUT_BUTTON_JUMP(this));
1653         keys = BITSET(keys, KEY_CROUCH,         IS_DUCKED(this)); // workaround: player can't un-crouch until their path is clear, so we keep the button held here
1654         keys = BITSET(keys, KEY_ATCK,           PHYS_INPUT_BUTTON_ATCK(this));
1655         keys = BITSET(keys, KEY_ATCK2,          PHYS_INPUT_BUTTON_ATCK2(this));
1656         CS(this).pressedkeys = keys; // store for other users
1657
1658         STAT(PRESSED_KEYS, this) = keys;
1659 }
1660
1661 /*
1662 ======================
1663 spectate mode routines
1664 ======================
1665 */
1666
1667 void SpectateCopy(entity this, entity spectatee)
1668 {
1669         TC(Client, this); TC(Client, spectatee);
1670
1671         MUTATOR_CALLHOOK(SpectateCopy, spectatee, this);
1672         PS(this) = PS(spectatee);
1673         this.armortype = spectatee.armortype;
1674         SetResourceExplicit(this, RES_ARMOR, GetResource(spectatee, RES_ARMOR));
1675         SetResourceExplicit(this, RES_CELLS, GetResource(spectatee, RES_CELLS));
1676         SetResourceExplicit(this, RES_PLASMA, GetResource(spectatee, RES_PLASMA));
1677         SetResourceExplicit(this, RES_SHELLS, GetResource(spectatee, RES_SHELLS));
1678         SetResourceExplicit(this, RES_BULLETS, GetResource(spectatee, RES_BULLETS));
1679         SetResourceExplicit(this, RES_ROCKETS, GetResource(spectatee, RES_ROCKETS));
1680         SetResourceExplicit(this, RES_FUEL, GetResource(spectatee, RES_FUEL));
1681         this.effects = spectatee.effects & EFMASK_CHEAP; // eat performance
1682         SetResourceExplicit(this, RES_HEALTH, GetResource(spectatee, RES_HEALTH));
1683         CS(this).impulse = 0;
1684         this.disableclientprediction = 1; // no need to run prediction on a spectator
1685         this.items = spectatee.items;
1686         STAT(LAST_PICKUP, this) = STAT(LAST_PICKUP, spectatee);
1687         STAT(HIT_TIME, this) = STAT(HIT_TIME, spectatee);
1688         STAT(STRENGTH_FINISHED, this) = STAT(STRENGTH_FINISHED, spectatee);
1689         STAT(INVINCIBLE_FINISHED, this) = STAT(INVINCIBLE_FINISHED, spectatee);
1690         STAT(SUPERWEAPONS_FINISHED, this) = STAT(SUPERWEAPONS_FINISHED, spectatee);
1691         this.air_finished = spectatee.air_finished;
1692         STAT(PRESSED_KEYS, this) = STAT(PRESSED_KEYS, spectatee);
1693         STAT(WEAPONS, this) = STAT(WEAPONS, spectatee);
1694         this.punchangle = spectatee.punchangle;
1695         this.view_ofs = spectatee.view_ofs;
1696         this.velocity = spectatee.velocity;
1697         this.dmg_take = spectatee.dmg_take;
1698         this.dmg_save = spectatee.dmg_save;
1699         this.dmg_inflictor = spectatee.dmg_inflictor;
1700         this.v_angle = spectatee.v_angle;
1701         this.angles = spectatee.v_angle;
1702         STAT(FROZEN, this) = STAT(FROZEN, spectatee);
1703         STAT(REVIVE_PROGRESS, this) = STAT(REVIVE_PROGRESS, spectatee);
1704         this.viewloc = spectatee.viewloc;
1705         if(!PHYS_INPUT_BUTTON_USE(this) && STAT(CAMERA_SPECTATOR, this) != 2)
1706                 this.fixangle = true;
1707         setorigin(this, spectatee.origin);
1708         setsize(this, spectatee.mins, spectatee.maxs);
1709         SetZoomState(this, CS(spectatee).zoomstate);
1710
1711     anticheat_spectatecopy(this, spectatee);
1712         STAT(HUD, this) = STAT(HUD, spectatee);
1713         if(spectatee.vehicle)
1714     {
1715         this.angles = spectatee.v_angle;
1716
1717         //this.fixangle = false;
1718         //this.velocity = spectatee.vehicle.velocity;
1719         this.vehicle_health = spectatee.vehicle_health;
1720         this.vehicle_shield = spectatee.vehicle_shield;
1721         this.vehicle_energy = spectatee.vehicle_energy;
1722         this.vehicle_ammo1 = spectatee.vehicle_ammo1;
1723         this.vehicle_ammo2 = spectatee.vehicle_ammo2;
1724         this.vehicle_reload1 = spectatee.vehicle_reload1;
1725         this.vehicle_reload2 = spectatee.vehicle_reload2;
1726
1727         //msg_entity = this;
1728
1729        // WriteByte (MSG_ONE, SVC_SETVIEWANGLES);
1730             //WriteAngle(MSG_ONE,  spectatee.v_angle.x);
1731            // WriteAngle(MSG_ONE,  spectatee.v_angle.y);
1732            // WriteAngle(MSG_ONE,  spectatee.v_angle.z);
1733
1734         //WriteByte (MSG_ONE, SVC_SETVIEW);
1735         //    WriteEntity(MSG_ONE, this);
1736         //makevectors(spectatee.v_angle);
1737         //setorigin(this, spectatee.origin - v_forward * 400 + v_up * 300);*/
1738     }
1739 }
1740
1741 bool SpectateUpdate(entity this)
1742 {
1743         if(!this.enemy)
1744                 return false;
1745
1746         if(!IS_PLAYER(this.enemy) || this == this.enemy)
1747         {
1748                 SetSpectatee(this, NULL);
1749                 return false;
1750         }
1751
1752         SpectateCopy(this, this.enemy);
1753
1754         return true;
1755 }
1756
1757 bool SpectateSet(entity this)
1758 {
1759         if(!IS_PLAYER(this.enemy))
1760                 return false;
1761
1762         ClientData_Touch(this.enemy);
1763
1764         msg_entity = this;
1765         WriteByte(MSG_ONE, SVC_SETVIEW);
1766         WriteEntity(MSG_ONE, this.enemy);
1767         set_movetype(this, MOVETYPE_NONE);
1768         accuracy_resend(this);
1769
1770         if(!SpectateUpdate(this))
1771                 PutObserverInServer(this);
1772
1773         return true;
1774 }
1775
1776 void SetSpectatee_status(entity this, int spectatee_num)
1777 {
1778         int oldspectatee_status = CS(this).spectatee_status;
1779         CS(this).spectatee_status = spectatee_num;
1780
1781         if (CS(this).spectatee_status != oldspectatee_status)
1782         {
1783                 if (STAT(PRESSED_KEYS, this))
1784                 {
1785                         CS(this).pressedkeys = 0;
1786                         STAT(PRESSED_KEYS, this) = 0;
1787                 }
1788                 ClientData_Touch(this);
1789                 if (g_race || g_cts) race_InitSpectator();
1790         }
1791 }
1792
1793 void SetSpectatee(entity this, entity spectatee)
1794 {
1795         if(IS_BOT_CLIENT(this))
1796                 return; // bots abuse .enemy, this code is useless to them
1797
1798         entity old_spectatee = this.enemy;
1799
1800         this.enemy = spectatee;
1801
1802         // WEAPONTODO
1803         // these are required to fix the spectator bug with arc
1804         if(old_spectatee)
1805         {
1806                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1807                 {
1808                         .entity weaponentity = weaponentities[slot];
1809                         if(old_spectatee.(weaponentity).arc_beam)
1810                                 old_spectatee.(weaponentity).arc_beam.SendFlags |= ARC_SF_SETTINGS;
1811                 }
1812         }
1813         if(this.enemy)
1814         {
1815                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1816                 {
1817                         .entity weaponentity = weaponentities[slot];
1818                         if(this.enemy.(weaponentity).arc_beam)
1819                                 this.enemy.(weaponentity).arc_beam.SendFlags |= ARC_SF_SETTINGS;
1820                 }
1821         }
1822
1823         if (this.enemy)
1824                 SetSpectatee_status(this, etof(this.enemy));
1825
1826         // needed to update spectator list
1827         if(old_spectatee) { ClientData_Touch(old_spectatee); }
1828 }
1829
1830 bool Spectate(entity this, entity pl)
1831 {
1832         if(MUTATOR_CALLHOOK(SpectateSet, this, pl))
1833                 return false;
1834         pl = M_ARGV(1, entity);
1835
1836         SetSpectatee(this, pl);
1837         return SpectateSet(this);
1838 }
1839
1840 bool SpectateNext(entity this)
1841 {
1842         entity ent = find(this.enemy, classname, STR_PLAYER);
1843
1844         if (MUTATOR_CALLHOOK(SpectateNext, this, ent))
1845                 ent = M_ARGV(1, entity);
1846         else if (!ent)
1847                 ent = find(ent, classname, STR_PLAYER);
1848
1849         if(ent) { SetSpectatee(this, ent); }
1850
1851         return SpectateSet(this);
1852 }
1853
1854 bool SpectatePrev(entity this)
1855 {
1856         // NOTE: chain order is from the highest to the lower entnum (unlike find)
1857         entity ent = findchain(classname, STR_PLAYER);
1858         if (!ent) // no player
1859                 return false;
1860
1861         entity first = ent;
1862         // skip players until current spectated player
1863         if(this.enemy)
1864         while(ent && ent != this.enemy)
1865                 ent = ent.chain;
1866
1867         switch (MUTATOR_CALLHOOK(SpectatePrev, this, ent, first))
1868         {
1869                 case MUT_SPECPREV_FOUND:
1870                     ent = M_ARGV(1, entity);
1871                     break;
1872                 case MUT_SPECPREV_RETURN:
1873                     return true;
1874                 case MUT_SPECPREV_CONTINUE:
1875                 default:
1876                 {
1877                         if(ent.chain)
1878                                 ent = ent.chain;
1879                         else
1880                                 ent = first;
1881                         break;
1882                 }
1883         }
1884
1885         SetSpectatee(this, ent);
1886         return SpectateSet(this);
1887 }
1888
1889 /*
1890 =============
1891 ShowRespawnCountdown()
1892
1893 Update a respawn countdown display.
1894 =============
1895 */
1896 void ShowRespawnCountdown(entity this)
1897 {
1898         float number;
1899         if(!IS_DEAD(this)) // just respawned?
1900                 return;
1901         else
1902         {
1903                 number = ceil(this.respawn_time - time);
1904                 if(number <= 0)
1905                         return;
1906                 if(number <= this.respawn_countdown)
1907                 {
1908                         this.respawn_countdown = number - 1;
1909                         if(ceil(this.respawn_time - (time + 0.5)) == number) // only say it if it is the same number even in 0.5s; to prevent overlapping sounds
1910                                 { Send_Notification(NOTIF_ONE, this, MSG_ANNCE, Announcer_PickNumber(CNT_RESPAWN, number)); }
1911                 }
1912         }
1913 }
1914
1915 .bool team_selected;
1916 bool ShowTeamSelection(entity this)
1917 {
1918         if (!teamplay || autocvar_g_campaign || autocvar_g_balance_teams || this.team_selected || (CS(this).wasplayer && autocvar_g_changeteam_banned) || Player_HasRealForcedTeam(this))
1919                 return false;
1920         stuffcmd(this, "menu_showteamselect\n");
1921         return true;
1922 }
1923 void Join(entity this)
1924 {
1925         TRANSMUTE(Player, this);
1926
1927         if(!this.team_selected)
1928         if(autocvar_g_campaign || autocvar_g_balance_teams)
1929                 TeamBalance_JoinBestTeam(this);
1930
1931         if(autocvar_g_campaign)
1932                 campaign_bots_may_start = true;
1933
1934         Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_PREVENT_JOIN);
1935
1936         PutClientInServer(this);
1937
1938         if(IS_PLAYER(this))
1939         if(teamplay && this.team != -1)
1940         {
1941         }
1942         else
1943                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_JOIN_PLAY, this.netname);
1944         this.team_selected = false;
1945 }
1946
1947 int GetPlayerLimit()
1948 {
1949         int player_limit = autocvar_g_maxplayers;
1950         MUTATOR_CALLHOOK(GetPlayerLimit, player_limit);
1951         player_limit = M_ARGV(0, int);
1952         return player_limit;
1953 }
1954
1955 /**
1956  * Determines whether the player is allowed to join. This depends on cvar
1957  * g_maxplayers, if it isn't used this function always return true, otherwise
1958  * it checks whether the number of currently playing players exceeds g_maxplayers.
1959  * @return int number of free slots for players, 0 if none
1960  */
1961 int nJoinAllowed(entity this, entity ignore)
1962 {
1963         if(!ignore)
1964         // this is called that way when checking if anyone may be able to join (to build qcstatus)
1965         // so report 0 free slots if restricted
1966         {
1967                 if(autocvar_g_forced_team_otherwise == "spectate")
1968                         return 0;
1969                 if(autocvar_g_forced_team_otherwise == "spectator")
1970                         return 0;
1971         }
1972
1973         if(this && (Player_GetForcedTeamIndex(this) == TEAM_FORCE_SPECTATOR))
1974                 return 0; // forced spectators can never join
1975
1976         // TODO simplify this
1977         int totalClients = 0;
1978         int currentlyPlaying = 0;
1979         FOREACH_CLIENT(true, {
1980                 if(it != ignore)
1981                         ++totalClients;
1982                 if(IS_REAL_CLIENT(it))
1983                 if(IS_PLAYER(it) || it.caplayer)
1984                         ++currentlyPlaying;
1985         });
1986
1987         int player_limit = GetPlayerLimit();
1988
1989         float free_slots = 0;
1990         if (!player_limit)
1991                 free_slots = maxclients - totalClients;
1992         else if(currentlyPlaying < player_limit)
1993                 free_slots = min(maxclients - totalClients, player_limit - currentlyPlaying);
1994
1995         static float msg_time = 0;
1996         if(this && !this.caplayer && ignore && !free_slots && time > msg_time)
1997         {
1998                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_JOIN_PREVENT);
1999                 msg_time = time + 0.5;
2000         }
2001
2002         return free_slots;
2003 }
2004
2005 /**
2006  * Checks whether the client is an observer or spectator, if so, he will get kicked after
2007  * g_maxplayers_spectator_blocktime seconds
2008  */
2009 void checkSpectatorBlock(entity this)
2010 {
2011         if(IS_SPEC(this) || IS_OBSERVER(this))
2012         if(!this.caplayer)
2013         if(IS_REAL_CLIENT(this))
2014         {
2015                 if( time > (CS(this).spectatortime + autocvar_g_maxplayers_spectator_blocktime) ) {
2016                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_QUIT_KICK_SPECTATING);
2017                         dropclient(this);
2018                 }
2019         }
2020 }
2021
2022 void PrintWelcomeMessage(entity this)
2023 {
2024         if(CS(this).motd_actived_time == 0)
2025         {
2026                 if (autocvar_g_campaign) {
2027                         if ((IS_PLAYER(this) && PHYS_INPUT_BUTTON_INFO(this)) || (!IS_PLAYER(this))) {
2028                                 CS(this).motd_actived_time = time;
2029                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_CAMPAIGN_MESSAGE, Campaign_GetMessage(), Campaign_GetLevelNum());
2030                         }
2031                 } else {
2032                         if (PHYS_INPUT_BUTTON_INFO(this)) {
2033                                 CS(this).motd_actived_time = time;
2034                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOTD, getwelcomemessage(this));
2035                         }
2036                 }
2037         }
2038         else if(CS(this).motd_actived_time > 0) // showing MOTD or campaign message
2039         {
2040                 if (autocvar_g_campaign) {
2041                         if (PHYS_INPUT_BUTTON_INFO(this))
2042                                 CS(this).motd_actived_time = time;
2043                         else if ((time - CS(this).motd_actived_time > 2) && IS_PLAYER(this)) { // hide it some seconds after BUTTON_INFO has been released
2044                                 CS(this).motd_actived_time = 0;
2045                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_CAMPAIGN_MESSAGE);
2046                         }
2047                 } else {
2048                         if (PHYS_INPUT_BUTTON_INFO(this))
2049                                 CS(this).motd_actived_time = time;
2050                         else if (time - CS(this).motd_actived_time > 2) { // hide it some seconds after BUTTON_INFO has been released
2051                                 CS(this).motd_actived_time = 0;
2052                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_MOTD);
2053                         }
2054                 }
2055         }
2056         else //if(CS(this).motd_actived_time < 0) // just connected, motd is active
2057         {
2058                 if(PHYS_INPUT_BUTTON_INFO(this)) // BUTTON_INFO hides initial MOTD
2059                         CS(this).motd_actived_time = -2; // wait until BUTTON_INFO gets released
2060                 else if (CS(this).motd_actived_time == -2)
2061                 {
2062                         // instantly hide MOTD
2063                         CS(this).motd_actived_time = 0;
2064                         if (autocvar_g_campaign)
2065                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_CAMPAIGN_MESSAGE);
2066                         else
2067                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_MOTD);
2068                 }
2069                 else if (IS_PLAYER(this) || IS_SPEC(this))
2070                 {
2071                         // FIXME occasionally for some reason MOTD never goes away
2072                         // delay MOTD removal a little bit in the hope it fixes this bug
2073                         if (CS(this).motd_actived_time == -1) // MOTD marked to fade away as soon as client becomes player or spectator
2074                                 CS(this).motd_actived_time = -(5 + floor(random() * 10)); // add small delay
2075                         else //if (CS(this).motd_actived_time < -2)
2076                                 CS(this).motd_actived_time++;
2077                 }
2078         }
2079 }
2080
2081 const int MIN_SPEC_TIME = 1;
2082 bool joinAllowed(entity this)
2083 {
2084         if (CS(this).version_mismatch) return false;
2085         if (time < CS(this).jointime + MIN_SPEC_TIME) return false;
2086         if (!nJoinAllowed(this, this)) return false;
2087         if (teamplay && lockteams) return false;
2088         if (MUTATOR_CALLHOOK(ForbidSpawn, this)) return false;
2089         if (ShowTeamSelection(this)) return false;
2090         return true;
2091 }
2092
2093 .int items_added;
2094 .string shootfromfixedorigin;
2095 .bool dualwielding_prev;
2096 bool PlayerThink(entity this)
2097 {
2098         if (game_stopped || intermission_running) {
2099                 this.modelflags &= ~MF_ROCKET;
2100                 if(intermission_running)
2101                         IntermissionThink(this);
2102                 return false;
2103         }
2104
2105         if (timeout_status == TIMEOUT_ACTIVE) {
2106         // don't allow the player to turn around while game is paused
2107                 // FIXME turn this into CSQC stuff
2108                 this.v_angle = this.lastV_angle;
2109                 this.angles = this.lastV_angle;
2110                 this.fixangle = true;
2111         }
2112
2113         if (frametime) player_powerups(this);
2114
2115         if (IS_DEAD(this)) {
2116                 if (this.personal && g_race_qualifying) {
2117                         if (time > this.respawn_time) {
2118                                 STAT(RESPAWN_TIME, this) = this.respawn_time = time + 1; // only retry once a second
2119                                 respawn(this);
2120                                 CS(this).impulse = CHIMPULSE_SPEEDRUN.impulse;
2121                         }
2122                 } else {
2123                         if (frametime) player_anim(this);
2124
2125                         if (this.respawn_flags & RESPAWN_DENY)
2126                         {
2127                                 STAT(RESPAWN_TIME, this) = 0;
2128                                 return false;
2129                         }
2130
2131                         bool button_pressed = (PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_JUMP(this) || PHYS_INPUT_BUTTON_ATCK2(this) || PHYS_INPUT_BUTTON_HOOK(this) || PHYS_INPUT_BUTTON_USE(this));
2132
2133                         switch(this.deadflag)
2134                         {
2135                                 case DEAD_DYING:
2136                                 {
2137                                         if ((this.respawn_flags & RESPAWN_FORCE) && !(this.respawn_time < this.respawn_time_max))
2138                                                 this.deadflag = DEAD_RESPAWNING;
2139                                         else if (!button_pressed || (time >= this.respawn_time_max && (this.respawn_flags & RESPAWN_FORCE)))
2140                                                 this.deadflag = DEAD_DEAD;
2141                                         break;
2142                                 }
2143                                 case DEAD_DEAD:
2144                                 {
2145                                         if (button_pressed)
2146                                                 this.deadflag = DEAD_RESPAWNABLE;
2147                                         else if (time >= this.respawn_time_max && (this.respawn_flags & RESPAWN_FORCE))
2148                                                 this.deadflag = DEAD_RESPAWNING;
2149                                         break;
2150                                 }
2151                                 case DEAD_RESPAWNABLE:
2152                                 {
2153                                         if (!button_pressed || (this.respawn_flags & RESPAWN_FORCE))
2154                                                 this.deadflag = DEAD_RESPAWNING;
2155                                         break;
2156                                 }
2157                                 case DEAD_RESPAWNING:
2158                                 {
2159                                         if (time > this.respawn_time)
2160                                         {
2161                                                 this.respawn_time = time + 1; // only retry once a second
2162                                                 this.respawn_time_max = this.respawn_time;
2163                                                 respawn(this);
2164                                         }
2165                                         break;
2166                                 }
2167                         }
2168
2169                         ShowRespawnCountdown(this);
2170
2171                         if (this.respawn_flags & RESPAWN_SILENT)
2172                                 STAT(RESPAWN_TIME, this) = 0;
2173                         else if ((this.respawn_flags & RESPAWN_FORCE) && this.respawn_time < this.respawn_time_max)
2174                         {
2175                                 if (time < this.respawn_time)
2176                                         STAT(RESPAWN_TIME, this) = this.respawn_time;
2177                                 else if (this.deadflag != DEAD_RESPAWNING)
2178                                         STAT(RESPAWN_TIME, this) = -this.respawn_time_max;
2179                         }
2180                         else
2181                                 STAT(RESPAWN_TIME, this) = this.respawn_time;
2182                 }
2183
2184                 // if respawning, invert stat_respawn_time to indicate this, the client translates it
2185                 if (this.deadflag == DEAD_RESPAWNING && STAT(RESPAWN_TIME, this) > 0)
2186                         STAT(RESPAWN_TIME, this) *= -1;
2187
2188                 return false;
2189         }
2190
2191         FixPlayermodel(this);
2192
2193         if (this.shootfromfixedorigin != autocvar_g_shootfromfixedorigin) {
2194                 this.shootfromfixedorigin = autocvar_g_shootfromfixedorigin;
2195                 stuffcmd(this, sprintf("\ncl_shootfromfixedorigin \"%s\"\n", autocvar_g_shootfromfixedorigin));
2196         }
2197
2198         // reset gun alignment when dual wielding status changes
2199         // to ensure guns are always aligned right and left
2200         bool dualwielding = W_DualWielding(this);
2201         if(this.dualwielding_prev != dualwielding)
2202         {
2203                 W_ResetGunAlign(this, CS(this).cvar_cl_gunalign);
2204                 this.dualwielding_prev = dualwielding;
2205         }
2206
2207         // LordHavoc: allow firing on move frames (sub-ticrate), this gives better timing on slow servers
2208         //if(frametime)
2209         {
2210                 this.items &= ~this.items_added;
2211
2212                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2213                 {
2214                         .entity weaponentity = weaponentities[slot];
2215                         if(WEP_CVAR(vortex, charge_always))
2216                                 W_Vortex_Charge(this, weaponentity, frametime);
2217                         W_WeaponFrame(this, weaponentity);
2218                 }
2219
2220                 this.items_added = 0;
2221                 if ((this.items & ITEM_Jetpack.m_itemid) && ((this.items & ITEM_JetpackRegen.m_itemid) || GetResource(this, RES_FUEL) >= 0.01))
2222             this.items_added |= IT_FUEL;
2223
2224                 this.items |= this.items_added;
2225         }
2226
2227         if (frametime)
2228         {
2229                 // WEAPONTODO: Add a weapon request for this
2230                 // rot vortex charge to the charge limit
2231                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2232                 {
2233                         .entity weaponentity = weaponentities[slot];
2234                         if (WEP_CVAR(vortex, charge_rot_rate) && this.(weaponentity).vortex_charge > WEP_CVAR(vortex, charge_limit) && this.(weaponentity).vortex_charge_rottime < time)
2235                                 this.(weaponentity).vortex_charge = bound(WEP_CVAR(vortex, charge_limit), this.(weaponentity).vortex_charge - WEP_CVAR(vortex, charge_rot_rate) * frametime / W_TICSPERFRAME, 1);
2236                 }
2237
2238                 player_regen(this);
2239                 player_anim(this);
2240                 this.dmg_team = max(0, this.dmg_team - autocvar_g_teamdamage_resetspeed * frametime);
2241         }
2242
2243         secrets_setstatus(this);
2244         monsters_setstatus(this);
2245
2246         return true;
2247 }
2248
2249 .bool would_spectate;
2250 void ObserverThink(entity this)
2251 {
2252         if ( CS(this).impulse )
2253         {
2254                 MinigameImpulse(this, CS(this).impulse);
2255                 CS(this).impulse = 0;
2256         }
2257
2258         if (this.flags & FL_JUMPRELEASED) {
2259                 if (PHYS_INPUT_BUTTON_JUMP(this) && joinAllowed(this)) {
2260                         this.flags &= ~FL_JUMPRELEASED;
2261                         this.flags |= FL_SPAWNING;
2262                 } else if(PHYS_INPUT_BUTTON_ATCK(this) && !CS(this).version_mismatch || this.would_spectate) {
2263                         this.flags &= ~FL_JUMPRELEASED;
2264                         if(SpectateNext(this)) {
2265                                 TRANSMUTE(Spectator, this);
2266                         }
2267                 } else {
2268                         int preferred_movetype = ((!PHYS_INPUT_BUTTON_USE(this) ? CS(this).cvar_cl_clippedspectating : !CS(this).cvar_cl_clippedspectating) ? MOVETYPE_FLY_WORLDONLY : MOVETYPE_NOCLIP);
2269                         set_movetype(this, preferred_movetype);
2270                 }
2271         } else {
2272                 if (!(PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_JUMP(this))) {
2273                         this.flags |= FL_JUMPRELEASED;
2274                         if(this.flags & FL_SPAWNING)
2275                         {
2276                                 this.flags &= ~FL_SPAWNING;
2277                                 if(joinAllowed(this))
2278                                         Join(this);
2279                                 return;
2280                         }
2281                 }
2282         }
2283 }
2284
2285 void SpectatorThink(entity this)
2286 {
2287         if ( CS(this).impulse )
2288         {
2289                 if(MinigameImpulse(this, CS(this).impulse))
2290                         CS(this).impulse = 0;
2291
2292                 if (CS(this).impulse == IMP_weapon_drop.impulse)
2293                 {
2294                         STAT(CAMERA_SPECTATOR, this) = (STAT(CAMERA_SPECTATOR, this) + 1) % 3;
2295                         CS(this).impulse = 0;
2296                         return;
2297                 }
2298         }
2299
2300         if (this.flags & FL_JUMPRELEASED) {
2301                 if (PHYS_INPUT_BUTTON_JUMP(this) && joinAllowed(this)) {
2302                         this.flags &= ~FL_JUMPRELEASED;
2303                         this.flags |= FL_SPAWNING;
2304                 } else if(PHYS_INPUT_BUTTON_ATCK(this) || CS(this).impulse == 10 || CS(this).impulse == 15 || CS(this).impulse == 18 || (CS(this).impulse >= 200 && CS(this).impulse <= 209)) {
2305                         this.flags &= ~FL_JUMPRELEASED;
2306                         if(SpectateNext(this)) {
2307                                 TRANSMUTE(Spectator, this);
2308                         } else {
2309                                 TRANSMUTE(Observer, this);
2310                                 PutClientInServer(this);
2311                         }
2312                         CS(this).impulse = 0;
2313                 } else if(CS(this).impulse == 12 || CS(this).impulse == 16  || CS(this).impulse == 19 || (CS(this).impulse >= 220 && CS(this).impulse <= 229)) {
2314                         this.flags &= ~FL_JUMPRELEASED;
2315                         if(SpectatePrev(this)) {
2316                                 TRANSMUTE(Spectator, this);
2317                         } else {
2318                                 TRANSMUTE(Observer, this);
2319                                 PutClientInServer(this);
2320                         }
2321                         CS(this).impulse = 0;
2322                 } else if (PHYS_INPUT_BUTTON_ATCK2(this)) {
2323                         this.would_spectate = false;
2324                         this.flags &= ~FL_JUMPRELEASED;
2325                         TRANSMUTE(Observer, this);
2326                         PutClientInServer(this);
2327                 } else {
2328                         if(!SpectateUpdate(this))
2329                         {
2330                                 if(!SpectateNext(this))
2331                                 {
2332                                         PutObserverInServer(this);
2333                                         this.would_spectate = true;
2334                                 }
2335                         }
2336                 }
2337         } else {
2338                 if (!(PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_ATCK2(this))) {
2339                         this.flags |= FL_JUMPRELEASED;
2340                         if(this.flags & FL_SPAWNING)
2341                         {
2342                                 this.flags &= ~FL_SPAWNING;
2343                                 Join(this);
2344                                 return;
2345                         }
2346                 }
2347                 if(!SpectateUpdate(this))
2348                         PutObserverInServer(this);
2349         }
2350
2351         this.flags |= FL_CLIENT | FL_NOTARGET;
2352 }
2353
2354 void PlayerUseKey(entity this)
2355 {
2356         if (!IS_PLAYER(this))
2357                 return;
2358
2359         if(this.vehicle)
2360         {
2361                 if(!game_stopped)
2362                 {
2363                         vehicles_exit(this.vehicle, VHEF_NORMAL);
2364                         return;
2365                 }
2366         }
2367         else if(autocvar_g_vehicles_enter)
2368         {
2369                 if(!game_stopped && !STAT(FROZEN, this) && !IS_DEAD(this) && !IS_INDEPENDENT_PLAYER(this))
2370                 {
2371                         entity head, closest_target = NULL;
2372                         head = WarpZone_FindRadius(this.origin, autocvar_g_vehicles_enter_radius, true);
2373
2374                         while(head) // find the closest acceptable target to enter
2375                         {
2376                                 if(IS_VEHICLE(head) && !IS_DEAD(head) && head.takedamage != DAMAGE_NO)
2377                                 if(!head.owner || ((head.vehicle_flags & VHF_MULTISLOT) && SAME_TEAM(head.owner, this)))
2378                                 {
2379                                         if(closest_target)
2380                                         {
2381                                                 if(vlen2(this.origin - head.origin) < vlen2(this.origin - closest_target.origin))
2382                                                 { closest_target = head; }
2383                                         }
2384                                         else { closest_target = head; }
2385                                 }
2386
2387                                 head = head.chain;
2388                         }
2389
2390                         if(closest_target) { vehicles_enter(this, closest_target); return; }
2391                 }
2392         }
2393
2394         // a use key was pressed; call handlers
2395         MUTATOR_CALLHOOK(PlayerUseKey, this);
2396 }
2397
2398
2399 /*
2400 =============
2401 PlayerPreThink
2402
2403 Called every frame for each client before the physics are run
2404 =============
2405 */
2406 .float last_vehiclecheck;
2407 void PlayerPreThink (entity this)
2408 {
2409         STAT(GUNALIGN, this) = CS(this).cvar_cl_gunalign; // TODO
2410         STAT(MOVEVARS_CL_TRACK_CANJUMP, this) = CS(this).cvar_cl_movement_track_canjump;
2411
2412         WarpZone_PlayerPhysics_FixVAngle(this);
2413
2414         if (frametime) {
2415                 // physics frames: update anticheat stuff
2416                 anticheat_prethink(this);
2417         }
2418
2419         if (blockSpectators && frametime) {
2420                 // WORKAROUND: only use dropclient in server frames (frametime set).
2421                 // Never use it in cl_movement frames (frametime zero).
2422                 checkSpectatorBlock(this);
2423         }
2424
2425         zoomstate_set = false;
2426
2427         // Check for nameless players
2428         if (this.netname == "" || this.netname != CS(this).netname_previous)
2429         {
2430                 bool assume_unchanged = (CS(this).netname_previous == "");
2431                 if (autocvar_sv_name_maxlength > 0 && strlennocol(this.netname) > autocvar_sv_name_maxlength)
2432                 {
2433                         int new_length = textLengthUpToLength(this.netname, autocvar_sv_name_maxlength, strlennocol);
2434                         this.netname = strzone(strcat(substring(this.netname, 0, new_length), "^7"));
2435                         sprint(this, sprintf("Warning: your name is longer than %d characters, it has been truncated.\n", autocvar_sv_name_maxlength));
2436                         assume_unchanged = false;
2437                         // stuffcmd(this, strcat("name ", this.netname, "\n")); // maybe?
2438                 }
2439                 if (isInvisibleString(this.netname))
2440                 {
2441                         this.netname = strzone(sprintf("Player#%d", this.playerid));
2442                         sprint(this, "Warning: invisible names are not allowed.\n");
2443                         assume_unchanged = false;
2444                         // stuffcmd(this, strcat("name ", this.netname, "\n")); // maybe?
2445                 }
2446                 if (!assume_unchanged && autocvar_sv_eventlog)
2447                         GameLogEcho(strcat(":name:", ftos(this.playerid), ":", playername(this, false)));
2448                 strcpy(CS(this).netname_previous, this.netname);
2449         }
2450
2451         // version nagging
2452         if (CS(this).version_nagtime && CS(this).cvar_g_xonoticversion && time > CS(this).version_nagtime) {
2453         CS(this).version_nagtime = 0;
2454         if (strstrofs(CS(this).cvar_g_xonoticversion, "git", 0) >= 0 || strstrofs(CS(this).cvar_g_xonoticversion, "autobuild", 0) >= 0) {
2455             // git client
2456         } else if (strstrofs(autocvar_g_xonoticversion, "git", 0) >= 0 || strstrofs(autocvar_g_xonoticversion, "autobuild", 0) >= 0) {
2457             // git server
2458             Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_BETA, autocvar_g_xonoticversion, CS(this).cvar_g_xonoticversion);
2459         } else {
2460             int r = vercmp(CS(this).cvar_g_xonoticversion, autocvar_g_xonoticversion);
2461             if (r < 0) { // old client
2462                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_OUTDATED, autocvar_g_xonoticversion, CS(this).cvar_g_xonoticversion);
2463             } else if (r > 0) { // old server
2464                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_OLD, autocvar_g_xonoticversion, CS(this).cvar_g_xonoticversion);
2465             }
2466         }
2467     }
2468
2469         // GOD MODE info
2470         if (!(this.flags & FL_GODMODE) && this.max_armorvalue)
2471         {
2472                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_GODMODE_OFF, this.max_armorvalue);
2473                 this.max_armorvalue = 0;
2474         }
2475
2476         if (frametime && IS_PLAYER(this))
2477         {
2478                 if (STAT(FROZEN, this) == FROZEN_TEMP_REVIVING)
2479                 {
2480                         STAT(REVIVE_PROGRESS, this) = bound(0, STAT(REVIVE_PROGRESS, this) + frametime * this.revive_speed, 1);
2481                         SetResourceExplicit(this, RES_HEALTH, max(1, STAT(REVIVE_PROGRESS, this) * start_health));
2482                         this.iceblock.alpha = bound(0.2, 1 - STAT(REVIVE_PROGRESS, this), 1);
2483
2484                         if (STAT(REVIVE_PROGRESS, this) >= 1)
2485                                 Unfreeze(this, false);
2486                 }
2487                 else if (STAT(FROZEN, this) == FROZEN_TEMP_DYING)
2488                 {
2489                         STAT(REVIVE_PROGRESS, this) = bound(0, STAT(REVIVE_PROGRESS, this) - frametime * this.revive_speed, 1);
2490                         SetResourceExplicit(this, RES_HEALTH, max(0, autocvar_g_nades_ice_health + (start_health-autocvar_g_nades_ice_health) * STAT(REVIVE_PROGRESS, this)));
2491
2492                         if (GetResource(this, RES_HEALTH) < 1)
2493                         {
2494                                 if (this.vehicle)
2495                                         vehicles_exit(this.vehicle, VHEF_RELEASE);
2496                                 if(this.event_damage)
2497                                         this.event_damage(this, this, this.frozen_by, 1, DEATH_NADE_ICE_FREEZE.m_id, DMG_NOWEP, this.origin, '0 0 0');
2498                         }
2499                         else if (STAT(REVIVE_PROGRESS, this) <= 0)
2500                                 Unfreeze(this, false);
2501                 }
2502         }
2503
2504         MUTATOR_CALLHOOK(PlayerPreThink, this);
2505
2506         if(autocvar_g_vehicles_enter && (time > this.last_vehiclecheck) && !game_stopped && !this.vehicle)
2507         if(IS_PLAYER(this) && !STAT(FROZEN, this) && !IS_DEAD(this) && !IS_INDEPENDENT_PLAYER(this))
2508         {
2509                 FOREACH_ENTITY_RADIUS(this.origin, autocvar_g_vehicles_enter_radius, IS_VEHICLE(it) && !IS_DEAD(it) && it.takedamage != DAMAGE_NO,
2510                 {
2511                         if(!it.owner)
2512                         {
2513                                 if(!it.team || SAME_TEAM(this, it))
2514                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER);
2515                                 else if(autocvar_g_vehicles_steal)
2516                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER_STEAL);
2517                         }
2518                         else if((it.vehicle_flags & VHF_MULTISLOT) && SAME_TEAM(it.owner, this))
2519                         {
2520                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER_GUNNER);
2521                         }
2522                 });
2523
2524                 this.last_vehiclecheck = time + 1;
2525         }
2526
2527         if(!CS(this).cvar_cl_newusekeysupported) // FIXME remove this - it was a stupid idea to begin with, we can JUST use the button
2528         {
2529                 if(PHYS_INPUT_BUTTON_USE(this) && !CS(this).usekeypressed)
2530                         PlayerUseKey(this);
2531                 CS(this).usekeypressed = PHYS_INPUT_BUTTON_USE(this);
2532         }
2533
2534         if (IS_REAL_CLIENT(this))
2535                 PrintWelcomeMessage(this);
2536
2537         if (IS_PLAYER(this)) {
2538                 if (IS_REAL_CLIENT(this) && time < CS(this).jointime + MIN_SPEC_TIME)
2539                         error("Client can't be spawned as player on connection!");
2540                 if(!PlayerThink(this))
2541                         return;
2542         }
2543         else if (game_stopped || intermission_running) {
2544                 if(intermission_running)
2545                         IntermissionThink(this);
2546                 return;
2547         }
2548         else if (IS_REAL_CLIENT(this) && !CS(this).autojoin_checked && time >= CS(this).jointime + MIN_SPEC_TIME)
2549         {
2550                 CS(this).autojoin_checked = true;
2551                 // don't do this in ClientConnect
2552                 // many things can go wrong if a client is spawned as player on connection
2553                 if (MUTATOR_CALLHOOK(AutoJoinOnConnection, this)
2554                         || (!(autocvar_sv_spectate || autocvar_g_campaign || (Player_GetForcedTeamIndex(this) == TEAM_FORCE_SPECTATOR))
2555                                 && (!teamplay || autocvar_g_balance_teams)))
2556                 {
2557                         campaign_bots_may_start = true;
2558                         Join(this);
2559                         return;
2560                 }
2561         }
2562         else if (IS_OBSERVER(this)) {
2563                 ObserverThink(this);
2564         }
2565         else if (IS_SPEC(this)) {
2566                 SpectatorThink(this);
2567         }
2568
2569         // WEAPONTODO: Add weapon request for this
2570         if (!zoomstate_set) {
2571                 bool wep_zoomed = false;
2572                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2573                 {
2574                         .entity weaponentity = weaponentities[slot];
2575                         Weapon thiswep = this.(weaponentity).m_weapon;
2576                         if(thiswep != WEP_Null && thiswep.wr_zoom)
2577                                 wep_zoomed += thiswep.wr_zoom(thiswep, this);
2578                 }
2579                 SetZoomState(this, PHYS_INPUT_BUTTON_ZOOM(this) || PHYS_INPUT_BUTTON_ZOOMSCRIPT(this) || wep_zoomed);
2580     }
2581
2582         if (CS(this).teamkill_soundtime && time > CS(this).teamkill_soundtime)
2583         {
2584                 CS(this).teamkill_soundtime = 0;
2585
2586                 entity e = CS(this).teamkill_soundsource;
2587                 entity oldpusher = e.pusher;
2588                 e.pusher = this;
2589                 PlayerSound(e, playersound_teamshoot, CH_VOICE, VOL_BASEVOICE, VOICETYPE_LASTATTACKER_ONLY);
2590                 e.pusher = oldpusher;
2591         }
2592
2593         if (CS(this).taunt_soundtime && time > CS(this).taunt_soundtime) {
2594                 CS(this).taunt_soundtime = 0;
2595                 PlayerSound(this, playersound_taunt, CH_VOICE, VOL_BASEVOICE, VOICETYPE_AUTOTAUNT);
2596         }
2597
2598         target_voicescript_next(this);
2599
2600         // WEAPONTODO: Move into weaponsystem somehow
2601         // if a player goes unarmed after holding a loaded weapon, empty his clip size and remove the crosshair ammo ring
2602         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2603         {
2604                 .entity weaponentity = weaponentities[slot];
2605                 if(this.(weaponentity).m_weapon == WEP_Null)
2606                         this.(weaponentity).clip_load = this.(weaponentity).clip_size = 0;
2607         }
2608 }
2609
2610 void DrownPlayer(entity this)
2611 {
2612         if(IS_DEAD(this) || game_stopped || time < game_starttime || this.vehicle
2613                 || STAT(FROZEN, this) || this.watertype != CONTENT_WATER)
2614         {
2615                 this.air_finished = 0;
2616                 return;
2617         }
2618
2619         if (this.waterlevel != WATERLEVEL_SUBMERGED)
2620         {
2621                 if(this.air_finished && this.air_finished < time)
2622                         PlayerSound(this, playersound_gasp, CH_PLAYER, VOL_BASE, VOICETYPE_PLAYERSOUND);
2623                 this.air_finished = 0;
2624         }
2625         else
2626         {
2627                 if (!this.air_finished)
2628                         this.air_finished = time + autocvar_g_balance_contents_drowndelay;
2629                 if (this.air_finished < time)
2630                 {       // drown!
2631                         if (this.pain_finished < time)
2632                         {
2633                                 Damage (this, NULL, NULL, autocvar_g_balance_contents_playerdamage_drowning * autocvar_g_balance_contents_damagerate, DEATH_DROWN.m_id, DMG_NOWEP, this.origin, '0 0 0');
2634                                 this.pain_finished = time + 0.5;
2635                         }
2636                 }
2637         }
2638 }
2639
2640 .bool move_qcphysics;
2641
2642 void Player_Physics(entity this)
2643 {
2644         this.movetype = (this.move_qcphysics) ? MOVETYPE_QCPLAYER : this.move_movetype;
2645
2646         if(!this.move_qcphysics)
2647                 return;
2648
2649         if(!frametime && !CS(this).pm_frametime)
2650                 return;
2651
2652         Movetype_Physics_NoMatchTicrate(this, CS(this).pm_frametime, true);
2653
2654         CS(this).pm_frametime = 0;
2655 }
2656
2657 /*
2658 =============
2659 PlayerPostThink
2660
2661 Called every frame for each client after the physics are run
2662 =============
2663 */
2664 void PlayerPostThink (entity this)
2665 {
2666         Player_Physics(this);
2667
2668         if (sv_maxidle > 0)
2669         if (frametime) // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2670         if (IS_REAL_CLIENT(this))
2671         if (IS_PLAYER(this) || sv_maxidle_spectatorsareidle)
2672         {
2673                 int totalClients = 0;
2674                 if(sv_maxidle_slots > 0)
2675                 {
2676                         FOREACH_CLIENT(IS_REAL_CLIENT(it) || sv_maxidle_slots_countbots,
2677                         {
2678                                 ++totalClients;
2679                         });
2680                 }
2681
2682                 if (sv_maxidle_slots > 0 && (maxclients - totalClients) > sv_maxidle_slots)
2683                 { /* do nothing */ }
2684                 else if (time - CS(this).parm_idlesince < 1) // instead of (time == this.parm_idlesince) to support sv_maxidle <= 10
2685                 {
2686                         if (CS(this).idlekick_lasttimeleft)
2687                         {
2688                                 CS(this).idlekick_lasttimeleft = 0;
2689                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_IDLING);
2690                         }
2691                 }
2692                 else
2693                 {
2694                         float timeleft = ceil(sv_maxidle - (time - CS(this).parm_idlesince));
2695                         if (timeleft == min(10, sv_maxidle - 1)) { // - 1 to support sv_maxidle <= 10
2696                                 if (!CS(this).idlekick_lasttimeleft)
2697                                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_DISCONNECT_IDLING, timeleft);
2698                         }
2699                         if (timeleft <= 0) {
2700                                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_QUIT_KICK_IDLING, this.netname);
2701                                 dropclient(this);
2702                                 return;
2703                         }
2704                         else if (timeleft <= 10) {
2705                                 if (timeleft != CS(this).idlekick_lasttimeleft) {
2706                                     Send_Notification(NOTIF_ONE, this, MSG_ANNCE, Announcer_PickNumber(CNT_IDLE, timeleft));
2707                 }
2708                                 CS(this).idlekick_lasttimeleft = timeleft;
2709                         }
2710                 }
2711         }
2712
2713         CheatFrame(this);
2714
2715         if (game_stopped)
2716         {
2717                 this.solid = SOLID_NOT;
2718                 this.takedamage = DAMAGE_NO;
2719                 set_movetype(this, MOVETYPE_NONE);
2720         }
2721
2722         if (IS_PLAYER(this)) {
2723                 if(this.death_time == time && IS_DEAD(this))
2724                 {
2725                         // player's bbox gets resized now, instead of in the damage event that killed the player,
2726                         // once all the damage events of this frame have been processed with normal size
2727                         this.maxs.z = 5;
2728                         setsize(this, this.mins, this.maxs);
2729                 }
2730                 DrownPlayer(this);
2731                 UpdateChatBubble(this);
2732                 if (CS(this).impulse) ImpulseCommands(this);
2733                 if (game_stopped)
2734                 {
2735                         CSQCMODEL_AUTOUPDATE(this);
2736                         return;
2737                 }
2738                 GetPressedKeys(this);
2739         }
2740         else if (IS_OBSERVER(this) && STAT(PRESSED_KEYS, this))
2741         {
2742                 CS(this).pressedkeys = 0;
2743                 STAT(PRESSED_KEYS, this) = 0;
2744         }
2745
2746         if (this.waypointsprite_attachedforcarrier) {
2747                 float hp = healtharmor_maxdamage(GetResource(this, RES_HEALTH), GetResource(this, RES_ARMOR), autocvar_g_balance_armor_blockpercent, DEATH_WEAPON.m_id).x;
2748                 WaypointSprite_UpdateHealth(this.waypointsprite_attachedforcarrier, hp);
2749         }
2750
2751         CSQCMODEL_AUTOUPDATE(this);
2752 }
2753
2754 /**
2755  * message "": do not say, just test flood control
2756  * return value:
2757  *   1 = accept
2758  *   0 = reject
2759  *  -1 = fake accept
2760  */
2761 int Say(entity source, int teamsay, entity privatesay, string msgin, bool floodcontrol)
2762 {
2763         if (!teamsay && !privatesay && substring(msgin, 0, 1) == " ")
2764                 msgin = substring(msgin, 1, -1); // work around DP say bug (say_team does not have this!)
2765
2766         if (source)
2767                 msgin = formatmessage(source, msgin);
2768
2769         string colorstr;
2770         if (!(IS_PLAYER(source) || source.caplayer))
2771                 colorstr = "^0"; // black for spectators
2772         else if(teamplay)
2773                 colorstr = Team_ColorCode(source.team);
2774         else
2775         {
2776                 colorstr = "";
2777                 teamsay = false;
2778         }
2779
2780         if (!source) {
2781                 colorstr = "";
2782                 teamsay = false;
2783         }
2784
2785         if(msgin != "")
2786                 msgin = trigger_magicear_processmessage_forallears(source, teamsay, privatesay, msgin);
2787
2788         /*
2789          * using bprint solves this... me stupid
2790         // how can we prevent the message from appearing in a listen server?
2791         // for now, just give "say" back and only handle say_team
2792         if(!teamsay)
2793         {
2794                 clientcommand(source, strcat("say ", msgin));
2795                 return;
2796         }
2797         */
2798
2799         string namestr = "";
2800         if (source)
2801                 namestr = playername(source, autocvar_g_chat_teamcolors);
2802
2803         string colorprefix = (strdecolorize(namestr) == namestr) ? "^3" : "^7";
2804
2805         string msgstr = "", cmsgstr = "";
2806         string privatemsgprefix = string_null;
2807         int privatemsgprefixlen = 0;
2808         if (msgin != "")
2809         {
2810                 bool found_me = false;
2811                 if(strstrofs(msgin, "/me", 0) >= 0)
2812                 {
2813                         string newmsgin = "";
2814                         string newnamestr = ((teamsay) ? strcat(colorstr, "(", colorprefix, namestr, colorstr, ")", "^7") : strcat(colorprefix, namestr, "^7"));
2815                         FOREACH_WORD(msgin, true,
2816                         {
2817                                 if(strdecolorize(it) == "/me")
2818                                 {
2819                                         found_me = true;
2820                                         newmsgin = cons(newmsgin, newnamestr);
2821                                 }
2822                                 else
2823                                         newmsgin = cons(newmsgin, it);
2824                         });
2825                         msgin = newmsgin;
2826                 }
2827
2828                 if(privatesay)
2829                 {
2830                         msgstr = strcat("\{1}\{13}* ", colorprefix, namestr, "^3 tells you: ^7");
2831                         privatemsgprefixlen = strlen(msgstr);
2832                         msgstr = strcat(msgstr, msgin);
2833                         cmsgstr = strcat(colorstr, colorprefix, namestr, "^3 tells you:\n^7", msgin);
2834                         privatemsgprefix = strcat("\{1}\{13}* ^3You tell ", playername(privatesay, autocvar_g_chat_teamcolors), ": ^7");
2835                 }
2836                 else if(teamsay)
2837                 {
2838                         if(found_me)
2839                         {
2840                                 //msgin = strreplace("/me", "", msgin);
2841                                 //msgin = substring(msgin, 3, strlen(msgin));
2842                                 //msgin = strreplace("/me", strcat(colorstr, "(", colorprefix, namestr, colorstr, ")^7"), msgin);
2843                                 msgstr = strcat("\{1}\{13}^4* ", "^7", msgin);
2844                         }
2845                         else
2846                                 msgstr = strcat("\{1}\{13}", colorstr, "(", colorprefix, namestr, colorstr, ") ^7", msgin);
2847                         cmsgstr = strcat(colorstr, "(", colorprefix, namestr, colorstr, ")\n^7", msgin);
2848                 }
2849                 else
2850                 {
2851                         if(found_me)
2852                         {
2853                                 //msgin = strreplace("/me", "", msgin);
2854                                 //msgin = substring(msgin, 3, strlen(msgin));
2855                                 //msgin = strreplace("/me", strcat(colorprefix, namestr), msgin);
2856                                 msgstr = strcat("\{1}^4* ^7", msgin);
2857                         }
2858                         else {
2859                                 msgstr = "\{1}";
2860                                 msgstr = strcat(msgstr, (namestr != "") ? strcat(colorprefix, namestr, "^7: ") : "^7");
2861                                 msgstr = strcat(msgstr, msgin);
2862                         }
2863                         cmsgstr = "";
2864                 }
2865                 msgstr = strcat(strreplace("\n", " ", msgstr), "\n"); // newlines only are good for centerprint
2866         }
2867
2868         string fullmsgstr = msgstr;
2869         string fullcmsgstr = cmsgstr;
2870
2871         // FLOOD CONTROL
2872         int flood = 0;
2873         var .float flood_field = floodcontrol_chat;
2874         if(floodcontrol && source)
2875         {
2876                 float flood_spl;
2877                 float flood_burst;
2878                 float flood_lmax;
2879                 float lines;
2880                 if(privatesay)
2881                 {
2882                         flood_spl = autocvar_g_chat_flood_spl_tell;
2883                         flood_burst = autocvar_g_chat_flood_burst_tell;
2884                         flood_lmax = autocvar_g_chat_flood_lmax_tell;
2885                         flood_field = floodcontrol_chattell;
2886                 }
2887                 else if(teamsay)
2888                 {
2889                         flood_spl = autocvar_g_chat_flood_spl_team;
2890                         flood_burst = autocvar_g_chat_flood_burst_team;
2891                         flood_lmax = autocvar_g_chat_flood_lmax_team;
2892                         flood_field = floodcontrol_chatteam;
2893                 }
2894                 else
2895                 {
2896                         flood_spl = autocvar_g_chat_flood_spl;
2897                         flood_burst = autocvar_g_chat_flood_burst;
2898                         flood_lmax = autocvar_g_chat_flood_lmax;
2899                         flood_field = floodcontrol_chat;
2900                 }
2901                 flood_burst = max(0, flood_burst - 1);
2902                 // to match explanation in default.cfg, a value of 3 must allow three-line bursts and not four!
2903
2904                 // do flood control for the default line size
2905                 if(msgstr != "")
2906                 {
2907                         getWrappedLine_remaining = msgstr;
2908                         msgstr = "";
2909                         lines = 0;
2910                         while(getWrappedLine_remaining && (!flood_lmax || lines <= flood_lmax))
2911                         {
2912                                 msgstr = strcat(msgstr, " ", getWrappedLineLen(82.4289758859709, strlennocol)); // perl averagewidth.pl < gfx/vera-sans.width
2913                                 ++lines;
2914                         }
2915                         msgstr = substring(msgstr, 1, strlen(msgstr) - 1);
2916
2917                         if(getWrappedLine_remaining != "")
2918                         {
2919                                 msgstr = strcat(msgstr, "\n");
2920                                 flood = 2;
2921                         }
2922
2923                         if (time >= source.(flood_field))
2924                         {
2925                                 source.(flood_field) = max(time - flood_burst * flood_spl, source.(flood_field)) + lines * flood_spl;
2926                         }
2927                         else
2928                         {
2929                                 flood = 1;
2930                                 msgstr = fullmsgstr;
2931                         }
2932                 }
2933                 else
2934                 {
2935                         if (time >= source.(flood_field))
2936                                 source.(flood_field) = max(time - flood_burst * flood_spl, source.(flood_field)) + flood_spl;
2937                         else
2938                                 flood = 1;
2939                 }
2940
2941                 if (timeout_status == TIMEOUT_ACTIVE) // when game is paused, no flood protection
2942                         source.(flood_field) = flood = 0;
2943         }
2944
2945         string sourcemsgstr, sourcecmsgstr;
2946         if(flood == 2) // cannot happen for empty msgstr
2947         {
2948                 if(autocvar_g_chat_flood_notify_flooder)
2949                 {
2950                         sourcemsgstr = strcat(msgstr, "\n^3FLOOD CONTROL: ^7message too long, trimmed\n");
2951                         sourcecmsgstr = "";
2952                 }
2953                 else
2954                 {
2955                         sourcemsgstr = fullmsgstr;
2956                         sourcecmsgstr = fullcmsgstr;
2957                 }
2958                 cmsgstr = "";
2959         }
2960         else
2961         {
2962                 sourcemsgstr = msgstr;
2963                 sourcecmsgstr = cmsgstr;
2964         }
2965
2966         if (!privatesay && source && !(IS_PLAYER(source) || source.caplayer))
2967         {
2968                 if (!game_stopped)
2969                 if (teamsay || (autocvar_g_chat_nospectators == 1) || (autocvar_g_chat_nospectators == 2 && !warmup_stage))
2970                         teamsay = -1; // spectators
2971         }
2972
2973         if(flood)
2974                 LOG_INFO("NOTE: ", playername(source, true), "^7 is flooding.");
2975
2976         // build sourcemsgstr by cutting off a prefix and replacing it by the other one
2977         if(privatesay)
2978                 sourcemsgstr = strcat(privatemsgprefix, substring(sourcemsgstr, privatemsgprefixlen, -1));
2979
2980         int ret;
2981         if(source && CS(source).muted)
2982         {
2983                 // always fake the message
2984                 ret = -1;
2985         }
2986         else if(flood == 1)
2987         {
2988                 if (autocvar_g_chat_flood_notify_flooder)
2989                 {
2990                         sprint(source, strcat("^3FLOOD CONTROL: ^7wait ^1", ftos(source.(flood_field) - time), "^3 seconds\n"));
2991                         ret = 0;
2992                 }
2993                 else
2994                         ret = -1;
2995         }
2996         else
2997         {
2998                 ret = 1;
2999         }
3000
3001         if (privatesay && source && !(IS_PLAYER(source) || source.caplayer))
3002         {
3003                 if (!game_stopped)
3004                 if ((privatesay && (IS_PLAYER(privatesay) || privatesay.caplayer)) && ((autocvar_g_chat_nospectators == 1) || (autocvar_g_chat_nospectators == 2 && !warmup_stage)))
3005                         ret = -1; // just hide the message completely
3006         }
3007
3008         MUTATOR_CALLHOOK(ChatMessage, source, ret);
3009         ret = M_ARGV(1, int);
3010
3011         string event_log_msg = "";
3012
3013         if(sourcemsgstr != "" && ret != 0)
3014         {
3015                 if(ret < 0) // faked message, because the player is muted
3016                 {
3017                         sprint(source, sourcemsgstr);
3018                         if(sourcecmsgstr != "" && !privatesay)
3019                                 centerprint(source, sourcecmsgstr);
3020                 }
3021                 else if(privatesay) // private message, between 2 people only
3022                 {
3023                         sprint(source, sourcemsgstr);
3024                         if (!autocvar_g_chat_tellprivacy) { dedicated_print(msgstr); } // send to server console too if "tellprivacy" is disabled
3025                         if(!MUTATOR_CALLHOOK(ChatMessageTo, privatesay, source))
3026                         {
3027                                 sprint(privatesay, msgstr);
3028                                 if(cmsgstr != "")
3029                                         centerprint(privatesay, cmsgstr);
3030                         }
3031                 }
3032                 else if ( teamsay && CS(source).active_minigame )
3033                 {
3034                         sprint(source, sourcemsgstr);
3035                         dedicated_print(msgstr); // send to server console too
3036                         FOREACH_CLIENT(IS_REAL_CLIENT(it) && it != source && CS(it).active_minigame == CS(source).active_minigame && !MUTATOR_CALLHOOK(ChatMessageTo, it, source), {
3037                                 sprint(it, msgstr);
3038                         });
3039                         event_log_msg = sprintf(":chat_minigame:%d:%s:%s", source.playerid, CS(source).active_minigame.netname, msgin);
3040
3041                 }
3042                 else if(teamsay > 0) // team message, only sent to team mates
3043                 {
3044                         sprint(source, sourcemsgstr);
3045                         dedicated_print(msgstr); // send to server console too
3046                         if(sourcecmsgstr != "")
3047                                 centerprint(source, sourcecmsgstr);
3048                         FOREACH_CLIENT((IS_PLAYER(it) || it.caplayer) && IS_REAL_CLIENT(it) && it != source && it.team == source.team && !MUTATOR_CALLHOOK(ChatMessageTo, it, source), {
3049                                 sprint(it, msgstr);
3050                                 if(cmsgstr != "")
3051                                         centerprint(it, cmsgstr);
3052                         });
3053                         event_log_msg = sprintf(":chat_team:%d:%d:%s", source.playerid, source.team, strreplace("\n", " ", msgin));
3054                 }
3055                 else if(teamsay < 0) // spectator message, only sent to spectators
3056                 {
3057                         sprint(source, sourcemsgstr);
3058                         dedicated_print(msgstr); // send to server console too
3059                         FOREACH_CLIENT(!(IS_PLAYER(it) || it.caplayer) && IS_REAL_CLIENT(it) && it != source && !MUTATOR_CALLHOOK(ChatMessageTo, it, source), {
3060                                 sprint(it, msgstr);
3061                         });
3062                         event_log_msg = sprintf(":chat_spec:%d:%s", source.playerid, strreplace("\n", " ", msgin));
3063                 }
3064                 else
3065                 {
3066                         if (source) {
3067                                 sprint(source, sourcemsgstr);
3068                                 dedicated_print(msgstr); // send to server console too
3069                                 MX_Say(strcat(playername(source, true), "^7: ", msgin));
3070                         }
3071                         FOREACH_CLIENT(IS_REAL_CLIENT(it) && it != source && !MUTATOR_CALLHOOK(ChatMessageTo, it, source), {
3072                                 sprint(it, msgstr);
3073                         });
3074                         event_log_msg = sprintf(":chat:%d:%s", source.playerid, strreplace("\n", " ", msgin));
3075                 }
3076         }
3077
3078         if (autocvar_sv_eventlog && (event_log_msg != "")) {
3079                 GameLogEcho(event_log_msg);
3080         }
3081
3082         return ret;
3083 }
3084
3085 // hack to copy the button fields from the client entity to the Client State
3086 void PM_UpdateButtons(entity this, entity store)
3087 {
3088         if(this.impulse)
3089                 store.impulse = this.impulse;
3090         this.impulse = 0;
3091
3092         bool typing = this.buttonchat || this.button12;
3093
3094         store.button0 = (typing) ? 0 : this.button0;
3095         //button1?!
3096         store.button2 = (typing) ? 0 : this.button2;
3097         store.button3 = (typing) ? 0 : this.button3;
3098         store.button4 = this.button4;
3099         store.button5 = (typing) ? 0 : this.button5;
3100         store.button6 = this.button6;
3101         store.button7 = this.button7;
3102         store.button8 = this.button8;
3103         store.button9 = this.button9;
3104         store.button10 = this.button10;
3105         store.button11 = this.button11;
3106         store.button12 = this.button12;
3107         store.button13 = this.button13;
3108         store.button14 = this.button14;
3109         store.button15 = this.button15;
3110         store.button16 = this.button16;
3111         store.buttonuse = this.buttonuse;
3112         store.buttonchat = this.buttonchat;
3113
3114         store.cursor_active = this.cursor_active;
3115         store.cursor_screen = this.cursor_screen;
3116         store.cursor_trace_start = this.cursor_trace_start;
3117         store.cursor_trace_endpos = this.cursor_trace_endpos;
3118         store.cursor_trace_ent = this.cursor_trace_ent;
3119
3120         store.ping = this.ping;
3121         store.ping_packetloss = this.ping_packetloss;
3122         store.ping_movementloss = this.ping_movementloss;
3123
3124         store.v_angle = this.v_angle;
3125         store.movement = (typing) ? '0 0 0' : this.movement;
3126 }
3127
3128 NET_HANDLE(fpsreport, bool)
3129 {
3130         int fps = ReadShort();
3131         PlayerScore_Set(sender, SP_FPS, fps);
3132         return true;
3133 }