Merge branch 'master' into Lyberta/StandaloneOverkillWeapons
[xonotic/xonotic-data.pk3dir.git] / qcsrc / server / client.qc
1 #include "client.qh"
2
3 #include "anticheat.qh"
4 #include "impulse.qh"
5 #include "player.qh"
6 #include "ipban.qh"
7 #include "miscfunctions.qh"
8 #include "portals.qh"
9 #include "teamplay.qh"
10 #include "playerdemo.qh"
11 #include "spawnpoints.qh"
12 #include "g_damage.qh"
13 #include "g_hook.qh"
14 #include "command/common.qh"
15 #include "cheats.qh"
16 #include "g_world.qh"
17 #include "race.qh"
18 #include "antilag.qh"
19 #include "campaign.qh"
20 #include "command/common.qh"
21 #include "scores_rules.qh"
22
23 #include "bot/api.qh"
24
25 #include "../common/ent_cs.qh"
26 #include "../common/wepent.qh"
27 #include <common/state.qh>
28
29 #include <common/effects/qc/globalsound.qh>
30
31 #include "../common/triggers/func/conveyor.qh"
32 #include "../common/triggers/teleporters.qh"
33
34 #include "../common/vehicles/all.qh"
35
36 #include "weapons/hitplot.qh"
37 #include "weapons/weaponsystem.qh"
38
39 #include "../common/net_notice.qh"
40 #include "../common/net_linked.qh"
41 #include "../common/physics/player.qh"
42
43 #include "../common/items/_mod.qh"
44
45 #include "../common/mutators/mutator/waypoints/all.qh"
46
47 #include "../common/triggers/subs.qh"
48 #include "../common/triggers/triggers.qh"
49 #include "../common/triggers/trigger/secret.qh"
50
51 #include "../common/minigames/sv_minigames.qh"
52
53 #include "../common/items/inventory.qh"
54
55 #include "../common/monsters/sv_monsters.qh"
56
57 #include "../lib/warpzone/server.qh"
58
59 #include <common/mutators/mutator/overkill/okvortex.qh>
60
61 STATIC_METHOD(Client, Add, void(Client this, int _team))
62 {
63     ClientConnect(this);
64     TRANSMUTE(Player, this);
65     this.frame = 12; // 7
66     this.team = _team;
67     PutClientInServer(this);
68 }
69
70 void PutObserverInServer(entity this);
71
72 STATIC_METHOD(Client, Remove, void(Client this))
73 {
74     TRANSMUTE(Observer, this);
75     PutClientInServer(this);
76     ClientDisconnect(this);
77 }
78
79 void send_CSQC_teamnagger() {
80         WriteHeader(MSG_BROADCAST, TE_CSQC_TEAMNAGGER);
81 }
82
83 int CountSpectators(entity player, entity to)
84 {
85         if(!player) { return 0; } // not sure how, but best to be safe
86
87         int spec_count = 0;
88
89         FOREACH_CLIENT(IS_REAL_CLIENT(it) && IS_SPEC(it) && it != to && it.enemy == player,
90         {
91                 spec_count++;
92         });
93
94         return spec_count;
95 }
96
97 void WriteSpectators(entity player, entity to)
98 {
99         if(!player) { return; } // not sure how, but best to be safe
100
101         FOREACH_CLIENT(IS_REAL_CLIENT(it) && IS_SPEC(it) && it != to && it.enemy == player,
102         {
103                 WriteByte(MSG_ENTITY, num_for_edict(it));
104         });
105 }
106
107 bool ClientData_Send(entity this, entity to, int sf)
108 {
109         assert(to == this.owner, return false);
110
111         entity e = to;
112         if (IS_SPEC(e)) e = e.enemy;
113
114         sf = 0;
115         if (e.race_completed)       sf |= 1; // forced scoreboard
116         if (to.spectatee_status)    sf |= 2; // spectator ent number follows
117         if (e.zoomstate)            sf |= 4; // zoomed
118         if (autocvar_sv_showspectators) sf |= 16; // show spectators
119
120         WriteHeader(MSG_ENTITY, ENT_CLIENT_CLIENTDATA);
121         WriteByte(MSG_ENTITY, sf);
122
123         if (sf & 2)
124         {
125                 WriteByte(MSG_ENTITY, to.spectatee_status);
126         }
127
128         if(sf & 16)
129         {
130                 float specs = CountSpectators(e, to);
131                 WriteByte(MSG_ENTITY, specs);
132                 WriteSpectators(e, to);
133         }
134
135         return true;
136 }
137
138 void ClientData_Attach(entity this)
139 {
140         Net_LinkEntity(this.clientdata = new_pure(clientdata), false, 0, ClientData_Send);
141         this.clientdata.drawonlytoclient = this;
142         this.clientdata.owner = this;
143 }
144
145 void ClientData_Detach(entity this)
146 {
147         delete(this.clientdata);
148         this.clientdata = NULL;
149 }
150
151 void ClientData_Touch(entity e)
152 {
153         e.clientdata.SendFlags = 1;
154
155         // make it spectatable
156         FOREACH_CLIENT(IS_REAL_CLIENT(it) && it != e && IS_SPEC(it) && it.enemy == e, LAMBDA(it.clientdata.SendFlags = 1));
157 }
158
159 .string netname_previous;
160
161 void SetSpectatee(entity this, entity spectatee);
162 void SetSpectatee_status(entity this, int spectatee_num);
163
164
165 /*
166 =============
167 CheckPlayerModel
168
169 Checks if the argument string can be a valid playermodel.
170 Returns a valid one in doubt.
171 =============
172 */
173 string FallbackPlayerModel;
174 string CheckPlayerModel(string plyermodel) {
175         if(FallbackPlayerModel != cvar_defstring("_cl_playermodel"))
176         {
177                 // note: we cannot summon Don Strunzone here, some player may
178                 // still have the model string set. In case anyone manages how
179                 // to change a cvar default, we'll have a small leak here.
180                 FallbackPlayerModel = strzone(cvar_defstring("_cl_playermodel"));
181         }
182         // only in right path
183         if( substring(plyermodel,0,14) != "models/player/")
184                 return FallbackPlayerModel;
185         // only good file extensions
186         if(substring(plyermodel,-4,4) != ".zym")
187         if(substring(plyermodel,-4,4) != ".dpm")
188         if(substring(plyermodel,-4,4) != ".iqm")
189         if(substring(plyermodel,-4,4) != ".md3")
190         if(substring(plyermodel,-4,4) != ".psk")
191                 return FallbackPlayerModel;
192         // forbid the LOD models
193         if(substring(plyermodel, -9,5) == "_lod1")
194                 return FallbackPlayerModel;
195         if(substring(plyermodel, -9,5) == "_lod2")
196                 return FallbackPlayerModel;
197         if(plyermodel != strtolower(plyermodel))
198                 return FallbackPlayerModel;
199         // also, restrict to server models
200         if(autocvar_sv_servermodelsonly)
201         {
202                 if(!fexists(plyermodel))
203                         return FallbackPlayerModel;
204         }
205         return plyermodel;
206 }
207
208 void setplayermodel(entity e, string modelname)
209 {
210         precache_model(modelname);
211         _setmodel(e, modelname);
212         player_setupanimsformodel(e);
213         if(!autocvar_g_debug_globalsounds)
214                 UpdatePlayerSounds(e);
215 }
216
217 void FixPlayermodel(entity player);
218 /** putting a client as observer in the server */
219 void PutObserverInServer(entity this)
220 {
221     bool mutator_returnvalue = MUTATOR_CALLHOOK(MakePlayerObserver, this);
222         PlayerState_detach(this);
223
224         if (IS_PLAYER(this) && this.health >= 1) {
225         // despawn effect
226                 Send_Effect(EFFECT_SPAWN_NEUTRAL, this.origin, '0 0 0', 1);
227     }
228
229     {
230         entity spot = SelectSpawnPoint(this, true);
231         if (!spot) LOG_FATAL("No spawnpoints for observers?!?");
232         this.angles = spot.angles;
233         this.angles_z = 0;
234         this.fixangle = true;
235         // offset it so that the spectator spawns higher off the ground, looks better this way
236         setorigin(this, spot.origin + STAT(PL_VIEW_OFS, this));
237         this.prevorigin = this.origin;
238         if (IS_REAL_CLIENT(this))
239         {
240             msg_entity = this;
241             WriteByte(MSG_ONE, SVC_SETVIEW);
242             WriteEntity(MSG_ONE, this);
243         }
244         // give the spectator some space between walls for MOVETYPE_FLY_WORLDONLY
245         // so that your view doesn't go into the ceiling with MOVETYPE_FLY_WORLDONLY, previously "PL_VIEW_OFS"
246         if(!autocvar_g_debug_globalsounds)
247         {
248                 // needed for player sounds
249                 this.model = "";
250                 FixPlayermodel(this);
251         }
252         setmodel(this, MDL_Null);
253         setsize(this, STAT(PL_CROUCH_MIN, this), STAT(PL_CROUCH_MAX, this));
254         this.view_ofs = '0 0 0';
255     }
256
257     RemoveGrapplingHooks(this);
258         Portal_ClearAll(this);
259         Unfreeze(this);
260         SetSpectatee(this, NULL);
261
262         if (this.alivetime)
263         {
264                 if (!warmup_stage)
265                         PS_GR_P_ADDVAL(this, PLAYERSTATS_ALIVETIME, time - this.alivetime);
266                 this.alivetime = 0;
267         }
268
269         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
270
271         WaypointSprite_PlayerDead(this);
272
273         if (mutator_returnvalue) {
274             // mutator prevents resetting teams+score
275         } else {
276                 this.team = -1;  // move this as it is needed to log the player spectating in eventlog
277         this.frags = FRAGS_SPECTATOR;
278         PlayerScore_Clear(this);  // clear scores when needed
279     }
280
281         if (this.killcount != FRAGS_SPECTATOR)
282         {
283                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_QUIT_SPECTATE, this.netname);
284                 if(!game_stopped)
285                 if(autocvar_g_chat_nospectators == 1 || (!warmup_stage && autocvar_g_chat_nospectators == 2))
286                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_CHAT_NOSPECTATORS);
287
288                 if(this.just_joined == false) {
289                         LogTeamchange(this.playerid, -1, 4);
290                 } else
291                         this.just_joined = false;
292         }
293
294         accuracy_resend(this);
295
296         this.spectatortime = time;
297         if(this.bot_attack)
298                 IL_REMOVE(g_bot_targets, this);
299         this.bot_attack = false;
300     this.hud = HUD_NORMAL;
301         TRANSMUTE(Observer, this);
302         this.iscreature = false;
303         this.teleportable = TELEPORT_SIMPLE;
304         if(this.damagedbycontents)
305                 IL_REMOVE(g_damagedbycontents, this);
306         this.damagedbycontents = false;
307         this.health = FRAGS_SPECTATOR;
308         SetSpectatee_status(this, etof(this));
309         this.takedamage = DAMAGE_NO;
310         this.solid = SOLID_NOT;
311         set_movetype(this, MOVETYPE_FLY_WORLDONLY); // user preference is controlled by playerprethink
312         this.flags = FL_CLIENT | FL_NOTARGET;
313         this.armorvalue = 666;
314         this.effects = 0;
315         this.armorvalue = autocvar_g_balance_armor_start;
316         this.pauserotarmor_finished = 0;
317         this.pauserothealth_finished = 0;
318         this.pauseregen_finished = 0;
319         this.damageforcescale = 0;
320         this.death_time = 0;
321         this.respawn_flags = 0;
322         this.respawn_time = 0;
323         this.stat_respawn_time = 0;
324         this.alpha = 0;
325         this.scale = 0;
326         this.fade_time = 0;
327         this.pain_frame = 0;
328         this.pain_finished = 0;
329         this.strength_finished = 0;
330         this.invincible_finished = 0;
331         this.superweapons_finished = 0;
332         this.pushltime = 0;
333         this.istypefrag = 0;
334         setthink(this, func_null);
335         this.nextthink = 0;
336         this.deadflag = DEAD_NO;
337         this.crouch = false;
338         this.revive_progress = 0;
339         this.revival_time = 0;
340
341         this.items = 0;
342         this.weapons = '0 0 0';
343         this.dual_weapons = '0 0 0';
344         this.drawonlytoclient = this;
345
346         this.weaponmodel = "";
347         for (int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
348         {
349                 this.weaponentities[slot] = NULL;
350         }
351         this.exteriorweaponentity = NULL;
352         this.killcount = FRAGS_SPECTATOR;
353         this.velocity = '0 0 0';
354         this.avelocity = '0 0 0';
355         this.punchangle = '0 0 0';
356         this.punchvector = '0 0 0';
357         this.oldvelocity = this.velocity;
358         this.fire_endtime = -1;
359         this.event_damage = func_null;
360
361         for(int slot = 0; slot < MAX_AXH; ++slot)
362         {
363                 entity axh = this.(AuxiliaryXhair[slot]);
364                 this.(AuxiliaryXhair[slot]) = NULL;
365
366                 if(axh.owner == this && axh != NULL && !wasfreed(axh))
367                         delete(axh);
368         }
369 }
370
371 int player_getspecies(entity this)
372 {
373         get_model_parameters(this.model, this.skin);
374         int s = get_model_parameters_species;
375         get_model_parameters(string_null, 0);
376         if (s < 0) return SPECIES_HUMAN;
377         return s;
378 }
379
380 .float model_randomizer;
381 void FixPlayermodel(entity player)
382 {
383         string defaultmodel = "";
384         int defaultskin = 0;
385         if(autocvar_sv_defaultcharacter)
386         {
387                 if(teamplay)
388                 {
389                         switch(player.team)
390                         {
391                                 case NUM_TEAM_1: defaultmodel = autocvar_sv_defaultplayermodel_red; defaultskin = autocvar_sv_defaultplayerskin_red; break;
392                                 case NUM_TEAM_2: defaultmodel = autocvar_sv_defaultplayermodel_blue; defaultskin = autocvar_sv_defaultplayerskin_blue; break;
393                                 case NUM_TEAM_3: defaultmodel = autocvar_sv_defaultplayermodel_yellow; defaultskin = autocvar_sv_defaultplayerskin_yellow; break;
394                                 case NUM_TEAM_4: defaultmodel = autocvar_sv_defaultplayermodel_pink; defaultskin = autocvar_sv_defaultplayerskin_pink; break;
395                         }
396                 }
397
398                 if(defaultmodel == "")
399                 {
400                         defaultmodel = autocvar_sv_defaultplayermodel;
401                         defaultskin = autocvar_sv_defaultplayerskin;
402                 }
403
404                 int n = tokenize_console(defaultmodel);
405                 if(n > 0)
406                 {
407                         defaultmodel = argv(floor(n * player.model_randomizer));
408                         // However, do NOT randomize if the player-selected model is in the list.
409                         for (int i = 0; i < n; ++i)
410                                 if ((argv(i) == player.playermodel && defaultskin == stof(player.playerskin)) || argv(i) == strcat(player.playermodel, ":", player.playerskin))
411                                         defaultmodel = argv(i);
412                 }
413
414                 int i = strstrofs(defaultmodel, ":", 0);
415                 if(i >= 0)
416                 {
417                         defaultskin = stof(substring(defaultmodel, i+1, -1));
418                         defaultmodel = substring(defaultmodel, 0, i);
419                 }
420         }
421         if(autocvar_sv_defaultcharacterskin && !defaultskin)
422         {
423                 if(teamplay)
424                 {
425                         switch(player.team)
426                         {
427                                 case NUM_TEAM_1: defaultskin = autocvar_sv_defaultplayerskin_red; break;
428                                 case NUM_TEAM_2: defaultskin = autocvar_sv_defaultplayerskin_blue; break;
429                                 case NUM_TEAM_3: defaultskin = autocvar_sv_defaultplayerskin_yellow; break;
430                                 case NUM_TEAM_4: defaultskin = autocvar_sv_defaultplayerskin_pink; break;
431                         }
432                 }
433
434                 if(!defaultskin)
435                         defaultskin = autocvar_sv_defaultplayerskin;
436         }
437
438         MUTATOR_CALLHOOK(FixPlayermodel, defaultmodel, defaultskin, player);
439         defaultmodel = M_ARGV(0, string);
440         defaultskin = M_ARGV(1, int);
441
442         bool chmdl = false;
443         int oldskin;
444         if(defaultmodel != "")
445         {
446                 if (defaultmodel != player.model)
447                 {
448                         vector m1 = player.mins;
449                         vector m2 = player.maxs;
450                         setplayermodel (player, defaultmodel);
451                         setsize (player, m1, m2);
452                         chmdl = true;
453                 }
454
455                 oldskin = player.skin;
456                 player.skin = defaultskin;
457         } else {
458                 if (player.playermodel != player.model || player.playermodel == "")
459                 {
460                         player.playermodel = CheckPlayerModel(player.playermodel); // this is never "", so no endless loop
461                         vector m1 = player.mins;
462                         vector m2 = player.maxs;
463                         setplayermodel (player, player.playermodel);
464                         setsize (player, m1, m2);
465                         chmdl = true;
466                 }
467
468                 if(!autocvar_sv_defaultcharacterskin)
469                 {
470                         oldskin = player.skin;
471                         player.skin = stof(player.playerskin);
472                 }
473                 else
474                 {
475                         oldskin = player.skin;
476                         player.skin = defaultskin;
477                 }
478         }
479
480         if(chmdl || oldskin != player.skin) // model or skin has changed
481         {
482                 player.species = player_getspecies(player); // update species
483                 if(!autocvar_g_debug_globalsounds)
484                         UpdatePlayerSounds(player); // update skin sounds
485         }
486
487         if(!teamplay)
488                 if(strlen(autocvar_sv_defaultplayercolors))
489                         if(player.clientcolors != stof(autocvar_sv_defaultplayercolors))
490                                 setcolor(player, stof(autocvar_sv_defaultplayercolors));
491 }
492
493
494 /** Called when a client spawns in the server */
495 void PutClientInServer(entity this)
496 {
497         if (IS_BOT_CLIENT(this)) {
498                 TRANSMUTE(Player, this);
499         } else if (IS_REAL_CLIENT(this)) {
500                 msg_entity = this;
501                 WriteByte(MSG_ONE, SVC_SETVIEW);
502                 WriteEntity(MSG_ONE, this);
503         }
504         if (game_stopped)
505                 TRANSMUTE(Observer, this);
506
507         SetSpectatee(this, NULL);
508
509         // reset player keys
510         this.itemkeys = 0;
511
512         MUTATOR_CALLHOOK(PutClientInServer, this);
513
514         if (IS_OBSERVER(this)) {
515                 PutObserverInServer(this);
516         } else if (IS_PLAYER(this)) {
517                 if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
518
519                 PlayerState_attach(this);
520                 accuracy_resend(this);
521
522                 if (this.team < 0)
523                         JoinBestTeam(this, false, true);
524
525                 entity spot = SelectSpawnPoint(this, false);
526                 if (!spot) {
527                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_JOIN_NOSPAWNS);
528                         return; // spawn failed
529                 }
530
531                 TRANSMUTE(Player, this);
532
533                 this.wasplayer = true;
534                 this.iscreature = true;
535                 this.teleportable = TELEPORT_NORMAL;
536                 if(!this.damagedbycontents)
537                         IL_PUSH(g_damagedbycontents, this);
538                 this.damagedbycontents = true;
539                 set_movetype(this, MOVETYPE_WALK);
540                 this.solid = SOLID_SLIDEBOX;
541                 this.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_SOLID;
542                 if (autocvar_g_playerclip_collisions)
543                         this.dphitcontentsmask |= DPCONTENTS_PLAYERCLIP;
544                 if (IS_BOT_CLIENT(this) && autocvar_g_botclip_collisions)
545                         this.dphitcontentsmask |= DPCONTENTS_BOTCLIP;
546                 this.frags = FRAGS_PLAYER;
547                 if (INDEPENDENT_PLAYERS) MAKE_INDEPENDENT_PLAYER(this);
548                 this.flags = FL_CLIENT | FL_PICKUPITEMS;
549                 if (autocvar__notarget)
550                         this.flags |= FL_NOTARGET;
551                 this.takedamage = DAMAGE_AIM;
552                 this.effects = EF_TELEPORT_BIT | EF_RESTARTANIM_BIT;
553                 this.dmg = 2; // WTF
554
555                 if (warmup_stage) {
556                         this.ammo_shells = warmup_start_ammo_shells;
557                         this.ammo_nails = warmup_start_ammo_nails;
558                         this.ammo_rockets = warmup_start_ammo_rockets;
559                         this.ammo_cells = warmup_start_ammo_cells;
560                         this.ammo_plasma = warmup_start_ammo_plasma;
561                         this.ammo_fuel = warmup_start_ammo_fuel;
562                         this.health = warmup_start_health;
563                         this.armorvalue = warmup_start_armorvalue;
564                         this.weapons = WARMUP_START_WEAPONS;
565                 } else {
566                         this.ammo_shells = start_ammo_shells;
567                         this.ammo_nails = start_ammo_nails;
568                         this.ammo_rockets = start_ammo_rockets;
569                         this.ammo_cells = start_ammo_cells;
570                         this.ammo_plasma = start_ammo_plasma;
571                         this.ammo_fuel = start_ammo_fuel;
572                         this.health = start_health;
573                         this.armorvalue = start_armorvalue;
574                         this.weapons = start_weapons;
575                 }
576                 SetSpectatee_status(this, 0);
577
578                 this.dual_weapons = '0 0 0';
579
580                 this.superweapons_finished = (this.weapons & WEPSET_SUPERWEAPONS) ? time + autocvar_g_balance_superweapons_time : 0;
581
582                 this.items = start_items;
583
584                 this.spawnshieldtime = time + autocvar_g_spawnshieldtime;
585                 this.pauserotarmor_finished = time + autocvar_g_balance_pause_armor_rot_spawn;
586                 this.pauserothealth_finished = time + autocvar_g_balance_pause_health_rot_spawn;
587                 this.pauserotfuel_finished = time + autocvar_g_balance_pause_fuel_rot_spawn;
588                 this.pauseregen_finished = time + autocvar_g_balance_pause_health_regen_spawn;
589                 // extend the pause of rotting if client was reset at the beginning of the countdown
590                 if (!autocvar_sv_ready_restart_after_countdown && time < game_starttime) { // TODO why is this cvar NOTted?
591                         float f = game_starttime - time;
592                         this.spawnshieldtime += f;
593                         this.pauserotarmor_finished += f;
594                         this.pauserothealth_finished += f;
595                         this.pauseregen_finished += f;
596                 }
597                 this.damageforcescale = 2;
598                 this.death_time = 0;
599                 this.respawn_flags = 0;
600                 this.respawn_time = 0;
601                 this.stat_respawn_time = 0;
602                 this.scale = autocvar_sv_player_scale;
603                 this.fade_time = 0;
604                 this.pain_frame = 0;
605                 this.pain_finished = 0;
606                 this.pushltime = 0;
607                 setthink(this, func_null); // players have no think function
608                 this.nextthink = 0;
609                 this.dmg_team = 0;
610                 this.ballistics_density = autocvar_g_ballistics_density_player;
611
612                 this.deadflag = DEAD_NO;
613
614                 this.angles = spot.angles;
615                 this.angles_z = 0; // never spawn tilted even if the spot says to
616                 if (IS_BOT_CLIENT(this))
617                         this.v_angle = this.angles;
618                 this.fixangle = true; // turn this way immediately
619                 this.oldvelocity = this.velocity = '0 0 0';
620                 this.avelocity = '0 0 0';
621                 this.punchangle = '0 0 0';
622                 this.punchvector = '0 0 0';
623
624                 this.strength_finished = 0;
625                 this.invincible_finished = 0;
626                 this.fire_endtime = -1;
627                 this.revive_progress = 0;
628                 this.revival_time = 0;
629                 this.air_finished = time + 12;
630
631                 entity spawnevent = new_pure(spawnevent);
632                 spawnevent.owner = this;
633                 Net_LinkEntity(spawnevent, false, 0.5, SpawnEvent_Send);
634
635                 // Cut off any still running player sounds.
636                 stopsound(this, CH_PLAYER_SINGLE);
637
638                 this.model = "";
639                 FixPlayermodel(this);
640                 this.drawonlytoclient = NULL;
641
642                 this.viewloc = NULL;
643
644                 this.crouch = false;
645                 this.view_ofs = STAT(PL_VIEW_OFS, this);
646                 setsize(this, STAT(PL_MIN, this), STAT(PL_MAX, this));
647                 this.spawnorigin = spot.origin;
648                 setorigin(this, spot.origin + '0 0 1' * (1 - this.mins.z - 24));
649                 // don't reset back to last position, even if new position is stuck in solid
650                 this.oldorigin = this.origin;
651                 this.prevorigin = this.origin;
652                 this.lastteleporttime = time; // prevent insane speeds due to changing origin
653                 if(this.conveyor)
654                         IL_REMOVE(g_conveyed, this);
655                 this.conveyor = NULL; // prevent conveyors at the previous location from moving a freshly spawned player
656                 this.hud = HUD_NORMAL;
657
658                 this.event_damage = PlayerDamage;
659
660                 if(!this.bot_attack)
661                         IL_PUSH(g_bot_targets, this);
662                 this.bot_attack = true;
663                 this.monster_attack = true;
664                 navigation_dynamicgoal_init(this, false);
665
666                 PHYS_INPUT_BUTTON_ATCK(this) = PHYS_INPUT_BUTTON_JUMP(this) = PHYS_INPUT_BUTTON_ATCK2(this) = false;
667
668                 if (this.killcount == FRAGS_SPECTATOR) {
669                         PlayerScore_Clear(this);
670                         this.killcount = 0;
671                 }
672
673                 for (int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
674                 {
675                         .entity weaponentity = weaponentities[slot];
676                         entity oldwep = this.(weaponentity);
677                         CL_SpawnWeaponentity(this, weaponentity);
678                         if(oldwep && oldwep.owner == this)
679                                 this.(weaponentity).m_gunalign = oldwep.m_gunalign;
680                 }
681                 this.alpha = default_player_alpha;
682                 this.colormod = '1 1 1' * autocvar_g_player_brightness;
683                 this.exteriorweaponentity.alpha = default_weapon_alpha;
684
685                 this.speedrunning = false;
686
687                 target_voicescript_clear(this);
688
689                 // reset fields the weapons may use
690                 FOREACH(Weapons, true, LAMBDA(
691                         it.wr_resetplayer(it, this);
692                         // reload all reloadable weapons
693                         if (it.spawnflags & WEP_FLAG_RELOADABLE) {
694                                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
695                                 {
696                                         .entity weaponentity = weaponentities[slot];
697                                         this.(weaponentity).weapon_load[it.m_id] = it.reloading_ammo;
698                                 }
699                         }
700                 ));
701
702                 {
703                         string s = spot.target;
704                         spot.target = string_null;
705                         SUB_UseTargets(spot, this, NULL);
706                         spot.target = s;
707                 }
708
709                 Unfreeze(this);
710
711                 MUTATOR_CALLHOOK(PlayerSpawn, this, spot);
712
713                 if (autocvar_spawn_debug)
714                 {
715                         sprint(this, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
716                         delete(spot); // usefull for checking if there are spawnpoints, that let drop through the floor
717                 }
718
719                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
720                 {
721                         .entity weaponentity = weaponentities[slot];
722                         if(slot == 0 || autocvar_g_weaponswitch_debug == 1)
723                                 this.(weaponentity).m_switchweapon = w_getbestweapon(this, weaponentity);
724                         else
725                                 this.(weaponentity).m_switchweapon = WEP_Null;
726                         this.(weaponentity).m_weapon = WEP_Null;
727                         this.(weaponentity).weaponname = "";
728                         this.(weaponentity).m_switchingweapon = WEP_Null;
729                         this.(weaponentity).cnt = -1;
730                 }
731
732                 MUTATOR_CALLHOOK(PlayerWeaponSelect, this);
733
734                 if (!warmup_stage && !this.alivetime)
735                         this.alivetime = time;
736
737                 antilag_clear(this, CS(this));
738         }
739 }
740
741 void ClientInit_misc(entity this);
742
743 // TODO do we need all these fields, or should we stop autodetecting runtime
744 // changes and just have a console command to update this?
745 bool ClientInit_SendEntity(entity this, entity to, int sf)
746 {
747         WriteHeader(MSG_ENTITY, _ENT_CLIENT_INIT);
748         return = true;
749         msg_entity = to;
750         // MSG_INIT replacement
751         // TODO: make easier to use
752         Registry_send_all();
753         W_PROP_reload(MSG_ONE, to);
754         ClientInit_misc(this);
755         MUTATOR_CALLHOOK(Ent_Init);
756 }
757 void ClientInit_misc(entity this)
758 {
759         int channel = MSG_ONE;
760         WriteHeader(channel, ENT_CLIENT_INIT);
761         WriteByte(channel, g_nexball_meter_period * 32);
762         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[0]));
763         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[1]));
764         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[2]));
765         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[3]));
766         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[0]));
767         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[1]));
768         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[2]));
769         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[3]));
770
771         if(sv_foginterval && world.fog != "")
772                 WriteString(channel, world.fog);
773         else
774                 WriteString(channel, "");
775         WriteByte(channel, this.count * 255.0); // g_balance_armor_blockpercent
776         WriteByte(channel, serverflags);
777         WriteCoord(channel, autocvar_g_trueaim_minrange);
778 }
779
780 void ClientInit_CheckUpdate(entity this)
781 {
782         this.nextthink = time;
783         if(this.count != autocvar_g_balance_armor_blockpercent)
784         {
785                 this.count = autocvar_g_balance_armor_blockpercent;
786                 this.SendFlags |= 1;
787         }
788 }
789
790 void ClientInit_Spawn()
791 {
792         entity e = new_pure(clientinit);
793         setthink(e, ClientInit_CheckUpdate);
794         Net_LinkEntity(e, false, 0, ClientInit_SendEntity);
795
796         ClientInit_CheckUpdate(e);
797 }
798
799 /*
800 =============
801 SetNewParms
802 =============
803 */
804 void SetNewParms ()
805 {
806         // initialize parms for a new player
807         parm1 = -(86400 * 366);
808
809         MUTATOR_CALLHOOK(SetNewParms);
810 }
811
812 /*
813 =============
814 SetChangeParms
815 =============
816 */
817 void SetChangeParms (entity this)
818 {
819         // save parms for level change
820         parm1 = this.parm_idlesince - time;
821
822         MUTATOR_CALLHOOK(SetChangeParms);
823 }
824
825 /*
826 =============
827 DecodeLevelParms
828 =============
829 */
830 void DecodeLevelParms(entity this)
831 {
832         // load parms
833         this.parm_idlesince = parm1;
834         if (this.parm_idlesince == -(86400 * 366))
835                 this.parm_idlesince = time;
836
837         // whatever happens, allow 60 seconds of idling directly after connect for map loading
838         this.parm_idlesince = max(this.parm_idlesince, time - sv_maxidle + 60);
839
840         MUTATOR_CALLHOOK(DecodeLevelParms);
841 }
842
843 /*
844 =============
845 ClientKill
846
847 Called when a client types 'kill' in the console
848 =============
849 */
850
851 .float clientkill_nexttime;
852 void ClientKill_Now_TeamChange(entity this)
853 {
854         if(this.killindicator_teamchange == -1)
855         {
856                 JoinBestTeam( this, false, true );
857         }
858         else if(this.killindicator_teamchange == -2)
859         {
860                 if(blockSpectators)
861                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
862                 PutObserverInServer(this);
863         }
864         else
865                 SV_ChangeTeam(this, this.killindicator_teamchange - 1);
866         this.killindicator_teamchange = 0;
867 }
868
869 void ClientKill_Now(entity this)
870 {
871         if(this.vehicle)
872         {
873             vehicles_exit(this.vehicle, VHEF_RELEASE);
874             if(!this.killindicator_teamchange)
875             {
876             this.vehicle_health = -1;
877             Damage(this, this, this, 1 , DEATH_KILL.m_id, this.origin, '0 0 0');
878             }
879         }
880
881         if(this.killindicator && !wasfreed(this.killindicator))
882                 delete(this.killindicator);
883
884         this.killindicator = NULL;
885
886         if(this.killindicator_teamchange)
887                 ClientKill_Now_TeamChange(this);
888
889         if(!IS_SPEC(this) && !IS_OBSERVER(this))
890                 Damage(this, this, this, 100000, DEATH_KILL.m_id, this.origin, '0 0 0');
891
892         // now I am sure the player IS dead
893 }
894 void KillIndicator_Think(entity this)
895 {
896         if (game_stopped)
897         {
898                 this.owner.killindicator = NULL;
899                 delete(this);
900                 return;
901         }
902
903         if (this.owner.alpha < 0 && !this.owner.vehicle)
904         {
905                 this.owner.killindicator = NULL;
906                 delete(this);
907                 return;
908         }
909
910         if(this.cnt <= 0)
911         {
912                 ClientKill_Now(this.owner);
913                 return;
914         }
915     else if(g_cts && this.health == 1) // health == 1 means that it's silent
916     {
917         this.nextthink = time + 1;
918         this.cnt -= 1;
919     }
920         else
921         {
922                 if(this.cnt <= 10)
923                         setmodel(this, MDL_NUM(this.cnt));
924                 if(IS_REAL_CLIENT(this.owner))
925                 {
926                         if(this.cnt <= 10)
927                                 { Send_Notification(NOTIF_ONE, this.owner, MSG_ANNCE, Announcer_PickNumber(CNT_KILL, this.cnt)); }
928                 }
929                 this.nextthink = time + 1;
930                 this.cnt -= 1;
931         }
932 }
933
934 float clientkilltime;
935 void ClientKill_TeamChange (entity this, float targetteam) // 0 = don't change, -1 = auto, -2 = spec
936 {
937         float killtime;
938         float starttime;
939
940         if (game_stopped)
941                 return;
942
943         killtime = autocvar_g_balance_kill_delay;
944
945         if(g_race_qualifying || g_cts)
946                 killtime = 0;
947
948     if(MUTATOR_CALLHOOK(ClientKill, this, killtime))
949         return;
950
951         this.killindicator_teamchange = targetteam;
952
953     if(!this.killindicator)
954         {
955                 if(!IS_DEAD(this))
956                 {
957                         killtime = max(killtime, this.clientkill_nexttime - time);
958                         this.clientkill_nexttime = time + killtime + autocvar_g_balance_kill_antispam;
959                 }
960
961                 if(killtime <= 0 || !IS_PLAYER(this) || IS_DEAD(this))
962                 {
963                         ClientKill_Now(this);
964                 }
965                 else
966                 {
967                         starttime = max(time, clientkilltime);
968
969                         this.killindicator = spawn();
970                         this.killindicator.owner = this;
971                         this.killindicator.scale = 0.5;
972                         setattachment(this.killindicator, this, "");
973                         setorigin(this.killindicator, '0 0 52');
974                         setthink(this.killindicator, KillIndicator_Think);
975                         this.killindicator.nextthink = starttime + (this.lip) * 0.05;
976                         clientkilltime = max(clientkilltime, this.killindicator.nextthink + 0.05);
977                         this.killindicator.cnt = ceil(killtime);
978                         this.killindicator.count = bound(0, ceil(killtime), 10);
979                         //sprint(this, strcat("^1You'll be dead in ", ftos(this.killindicator.cnt), " seconds\n"));
980
981                         IL_EACH(g_clones, it.enemy == this && !(it.effects & CSQCMODEL_EF_RESPAWNGHOST),
982                         {
983                                 it.killindicator = spawn();
984                                 it.killindicator.owner = it;
985                                 it.killindicator.scale = 0.5;
986                                 setattachment(it.killindicator, it, "");
987                                 setorigin(it.killindicator, '0 0 52');
988                                 setthink(it.killindicator, KillIndicator_Think);
989                                 it.killindicator.nextthink = starttime + (it.lip) * 0.05;
990                                 //clientkilltime = max(clientkilltime, it.killindicator.nextthink + 0.05);
991                                 it.killindicator.cnt = ceil(killtime);
992                         });
993                         this.lip = 0;
994                 }
995         }
996         if(this.killindicator)
997         {
998                 if(targetteam == 0) // just die
999                 {
1000                         this.killindicator.colormod = '0 0 0';
1001                         if(IS_REAL_CLIENT(this))
1002                         if(this.killindicator.cnt > 0)
1003                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_TEAMCHANGE_SUICIDE, this.killindicator.cnt);
1004                 }
1005                 else if(targetteam == -1) // auto
1006                 {
1007                         this.killindicator.colormod = '0 1 0';
1008                         if(IS_REAL_CLIENT(this))
1009                         if(this.killindicator.cnt > 0)
1010                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_TEAMCHANGE_AUTO, this.killindicator.cnt);
1011                 }
1012                 else if(targetteam == -2) // spectate
1013                 {
1014                         this.killindicator.colormod = '0.5 0.5 0.5';
1015                         if(IS_REAL_CLIENT(this))
1016                         if(this.killindicator.cnt > 0)
1017                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_TEAMCHANGE_SPECTATE, this.killindicator.cnt);
1018                 }
1019                 else
1020                 {
1021                         this.killindicator.colormod = Team_ColorRGB(targetteam);
1022                         if(IS_REAL_CLIENT(this))
1023                         if(this.killindicator.cnt > 0)
1024                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, APP_TEAM_NUM(targetteam, CENTER_TEAMCHANGE), this.killindicator.cnt);
1025                 }
1026         }
1027
1028 }
1029
1030 void ClientKill (entity this)
1031 {
1032         if(game_stopped) return;
1033         if(this.player_blocked) return;
1034         if(STAT(FROZEN, this)) return;
1035
1036         ClientKill_TeamChange(this, 0);
1037 }
1038
1039 void FixClientCvars(entity e)
1040 {
1041         // send prediction settings to the client
1042         stuffcmd(e, "\nin_bindmap 0 0\n");
1043         if(autocvar_g_antilag == 3) // client side hitscan
1044                 stuffcmd(e, "cl_cmd settemp cl_prydoncursor_notrace 0\n");
1045         if(autocvar_sv_gentle)
1046                 stuffcmd(e, "cl_cmd settemp cl_gentle 1\n");
1047
1048         MUTATOR_CALLHOOK(FixClientCvars, e);
1049 }
1050
1051 float PlayerInIDList(entity p, string idlist)
1052 {
1053         float n, i;
1054         string s;
1055
1056         // NOTE: we do NOT check crypto_idfp_signed here, an unsigned ID is fine too for this
1057         if (!p.crypto_idfp)
1058                 return 0;
1059
1060         // this function allows abbreviated player IDs too!
1061         n = tokenize_console(idlist);
1062         for(i = 0; i < n; ++i)
1063         {
1064                 s = argv(i);
1065                 if(s == substring(p.crypto_idfp, 0, strlen(s)))
1066                         return 1;
1067         }
1068
1069         return 0;
1070 }
1071
1072 #ifdef DP_EXT_PRECONNECT
1073 /*
1074 =============
1075 ClientPreConnect
1076
1077 Called once (not at each match start) when a client begins a connection to the server
1078 =============
1079 */
1080 void ClientPreConnect(entity this)
1081 {
1082         if(autocvar_sv_eventlog)
1083         {
1084                 GameLogEcho(sprintf(":connect:%d:%d:%s",
1085                         this.playerid,
1086                         etof(this),
1087                         ((IS_REAL_CLIENT(this)) ? this.netaddress : "bot")
1088                 ));
1089         }
1090 }
1091 #endif
1092
1093 /**
1094 =============
1095 ClientConnect
1096
1097 Called when a client connects to the server
1098 =============
1099 */
1100 void ClientConnect(entity this)
1101 {
1102         if (Ban_MaybeEnforceBanOnce(this)) return;
1103         assert(!IS_CLIENT(this), return);
1104         this.flags |= FL_CLIENT;
1105         assert(player_count >= 0, player_count = 0);
1106
1107 #ifdef WATERMARK
1108         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_WATERMARK, WATERMARK);
1109 #endif
1110         this.version_nagtime = time + 10 + random() * 10;
1111         TRANSMUTE(Client, this);
1112
1113         // identify the right forced team
1114         if (autocvar_g_campaign)
1115         {
1116                 if (IS_REAL_CLIENT(this)) // only players, not bots
1117                 {
1118                         switch (autocvar_g_campaign_forceteam)
1119                         {
1120                                 case 1: this.team_forced = NUM_TEAM_1; break;
1121                                 case 2: this.team_forced = NUM_TEAM_2; break;
1122                                 case 3: this.team_forced = NUM_TEAM_3; break;
1123                                 case 4: this.team_forced = NUM_TEAM_4; break;
1124                                 default: this.team_forced = 0;
1125                         }
1126                 }
1127         }
1128         else if (PlayerInIDList(this, autocvar_g_forced_team_red))    this.team_forced = NUM_TEAM_1;
1129         else if (PlayerInIDList(this, autocvar_g_forced_team_blue))   this.team_forced = NUM_TEAM_2;
1130         else if (PlayerInIDList(this, autocvar_g_forced_team_yellow)) this.team_forced = NUM_TEAM_3;
1131         else if (PlayerInIDList(this, autocvar_g_forced_team_pink))   this.team_forced = NUM_TEAM_4;
1132         else switch (autocvar_g_forced_team_otherwise)
1133         {
1134                 default: this.team_forced = 0; break;
1135                 case "red": this.team_forced = NUM_TEAM_1; break;
1136                 case "blue": this.team_forced = NUM_TEAM_2; break;
1137                 case "yellow": this.team_forced = NUM_TEAM_3; break;
1138                 case "pink": this.team_forced = NUM_TEAM_4; break;
1139                 case "spectate":
1140                 case "spectator":
1141                         this.team_forced = -1;
1142                         break;
1143         }
1144         if (!teamplay && this.team_forced > 0) this.team_forced = 0;
1145
1146     {
1147         int id = this.playerid;
1148         this.playerid = 0; // silent
1149             JoinBestTeam(this, false, false); // if the team number is valid, keep it
1150             this.playerid = id;
1151     }
1152
1153         if (autocvar_sv_spectate || autocvar_g_campaign || this.team_forced < 0) {
1154                 TRANSMUTE(Observer, this);
1155         } else {
1156                 if (!teamplay || autocvar_g_balance_teams) {
1157                         TRANSMUTE(Player, this);
1158                         campaign_bots_may_start = true;
1159                 } else {
1160                         TRANSMUTE(Observer, this); // do it anyway
1161                 }
1162         }
1163
1164         PlayerStats_GameReport_AddEvent(sprintf("kills-%d", this.playerid));
1165
1166         // always track bots, don't ask for cl_allow_uidtracking
1167     if (IS_BOT_CLIENT(this)) PlayerStats_GameReport_AddPlayer(this);
1168
1169         if (autocvar_sv_eventlog)
1170                 GameLogEcho(strcat(":join:", ftos(this.playerid), ":", ftos(etof(this)), ":", ((IS_REAL_CLIENT(this)) ? this.netaddress : "bot"), ":", playername(this, false)));
1171
1172         LogTeamchange(this.playerid, this.team, 1);
1173
1174         this.just_joined = true;  // stop spamming the eventlog with additional lines when the client connects
1175
1176         this.netname_previous = strzone(this.netname);
1177
1178         if(teamplay && IS_PLAYER(this))
1179                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, APP_TEAM_NUM(this.team, INFO_JOIN_CONNECT_TEAM), this.netname);
1180         else
1181                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_JOIN_CONNECT, this.netname);
1182
1183         stuffcmd(this, clientstuff, "\n");
1184         stuffcmd(this, "cl_particles_reloadeffects\n"); // TODO do we still need this?
1185
1186         FixClientCvars(this);
1187
1188         // get version info from player
1189         stuffcmd(this, "cmd clientversion $gameversion\n");
1190
1191         // notify about available teams
1192         if (teamplay)
1193         {
1194                 CheckAllowedTeams(this);
1195                 int t = 0;
1196                 if (c1 >= 0) t |= BIT(0);
1197                 if (c2 >= 0) t |= BIT(1);
1198                 if (c3 >= 0) t |= BIT(2);
1199                 if (c4 >= 0) t |= BIT(3);
1200                 stuffcmd(this, sprintf("set _teams_available %d\n", t));
1201         }
1202         else
1203         {
1204                 stuffcmd(this, "set _teams_available 0\n");
1205         }
1206
1207         bot_relinkplayerlist();
1208
1209         this.spectatortime = time;
1210         if (blockSpectators)
1211         {
1212                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
1213         }
1214
1215         this.jointime = time;
1216         this.allowed_timeouts = autocvar_sv_timeout_number;
1217
1218         if (IS_REAL_CLIENT(this))
1219         {
1220                 if (g_weaponarena_weapons == WEPSET(TUBA))
1221                         stuffcmd(this, "cl_cmd settemp chase_active 1\n");
1222         }
1223
1224         if (!sv_foginterval && world.fog != "")
1225                 stuffcmd(this, strcat("\nfog ", world.fog, "\nr_fog_exp2 0\nr_drawfog 1\n"));
1226
1227         if (autocvar_sv_teamnagger && !(autocvar_bot_vs_human && AvailableTeams() == 2))
1228                 if(!MUTATOR_CALLHOOK(HideTeamNagger, this))
1229                         send_CSQC_teamnagger();
1230
1231         CSQCMODEL_AUTOINIT(this);
1232
1233         this.model_randomizer = random();
1234
1235         if (IS_REAL_CLIENT(this))
1236                 sv_notice_join(this);
1237
1238         // update physics stats (players can spawn before physics runs)
1239         STAT(MOVEVARS_HIGHSPEED, this) = autocvar_g_movement_highspeed;
1240         MUTATOR_CALLHOOK(PlayerPhysics_UpdateStats, this); // do it BEFORE the function so we can modify highspeed!
1241         Physics_UpdateStats(this, PHYS_HIGHSPEED(this));
1242
1243         IL_EACH(g_initforplayer, it.init_for_player, {
1244                 it.init_for_player(it, this);
1245         });
1246
1247         MUTATOR_CALLHOOK(ClientConnect, this);
1248
1249         if (IS_REAL_CLIENT(this))
1250         {
1251                 if (!autocvar_g_campaign && !IS_PLAYER(this))
1252                 {
1253                         this.motd_actived_time = -1;
1254                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOTD, getwelcomemessage(this));
1255                 }
1256         }
1257 }
1258 /*
1259 =============
1260 ClientDisconnect
1261
1262 Called when a client disconnects from the server
1263 =============
1264 */
1265 .entity chatbubbleentity;
1266 void ReadyCount();
1267 void ClientDisconnect(entity this)
1268 {
1269         assert(IS_CLIENT(this), return);
1270
1271         PlayerStats_GameReport_FinalizePlayer(this);
1272         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
1273         if (this.active_minigame) part_minigame(this);
1274         if (IS_PLAYER(this)) Send_Effect(EFFECT_SPAWN_NEUTRAL, this.origin, '0 0 0', 1);
1275
1276         if (autocvar_sv_eventlog)
1277                 GameLogEcho(strcat(":part:", ftos(this.playerid)));
1278
1279         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_QUIT_DISCONNECT, this.netname);
1280
1281         if(IS_SPEC(this))
1282                 SetSpectatee(this, NULL);
1283
1284     MUTATOR_CALLHOOK(ClientDisconnect, this);
1285
1286         ClientState_detach(this);
1287
1288         Portal_ClearAll(this);
1289
1290         Unfreeze(this);
1291
1292         RemoveGrapplingHooks(this);
1293
1294         // Here, everything has been done that requires this player to be a client.
1295
1296         this.flags &= ~FL_CLIENT;
1297
1298         if (this.chatbubbleentity) delete(this.chatbubbleentity);
1299         if (this.killindicator) delete(this.killindicator);
1300
1301         WaypointSprite_PlayerGone(this);
1302
1303         bot_relinkplayerlist();
1304
1305         if (this.netname_previous) strunzone(this.netname_previous);
1306         if (this.clientstatus) strunzone(this.clientstatus);
1307         if (this.weaponorder_byimpulse) strunzone(this.weaponorder_byimpulse);
1308         if (this.personal) delete(this.personal);
1309
1310         this.playerid = 0;
1311         ReadyCount();
1312         if (vote_called && IS_REAL_CLIENT(this)) VoteCount(false);
1313
1314         ONREMOVE(this);
1315 }
1316
1317 void ChatBubbleThink(entity this)
1318 {
1319         this.nextthink = time;
1320         if ((this.owner.alpha < 0) || this.owner.chatbubbleentity != this)
1321         {
1322                 if(this.owner) // but why can that ever be NULL?
1323                         this.owner.chatbubbleentity = NULL;
1324                 delete(this);
1325                 return;
1326         }
1327
1328         this.mdl = "";
1329
1330         if ( !IS_DEAD(this.owner) && IS_PLAYER(this.owner) )
1331         {
1332                 if ( this.owner.active_minigame )
1333                         this.mdl = "models/sprites/minigame_busy.iqm";
1334                 else if (PHYS_INPUT_BUTTON_CHAT(this.owner))
1335                         this.mdl = "models/misc/chatbubble.spr";
1336         }
1337
1338         if ( this.model != this.mdl )
1339                 _setmodel(this, this.mdl);
1340
1341 }
1342
1343 void UpdateChatBubble(entity this)
1344 {
1345         if (this.alpha < 0)
1346                 return;
1347         // spawn a chatbubble entity if needed
1348         if (!this.chatbubbleentity)
1349         {
1350                 this.chatbubbleentity = new(chatbubbleentity);
1351                 this.chatbubbleentity.owner = this;
1352                 this.chatbubbleentity.exteriormodeltoclient = this;
1353                 setthink(this.chatbubbleentity, ChatBubbleThink);
1354                 this.chatbubbleentity.nextthink = time;
1355                 setmodel(this.chatbubbleentity, MDL_CHAT); // precision set below
1356                 //setorigin(this.chatbubbleentity, this.origin + '0 0 15' + this.maxs_z * '0 0 1');
1357                 setorigin(this.chatbubbleentity, '0 0 15' + this.maxs_z * '0 0 1');
1358                 setattachment(this.chatbubbleentity, this, "");  // sticks to moving player better, also conserves bandwidth
1359                 this.chatbubbleentity.mdl = this.chatbubbleentity.model;
1360                 //this.chatbubbleentity.model = "";
1361                 this.chatbubbleentity.effects = EF_LOWPRECISION;
1362         }
1363 }
1364
1365
1366 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
1367 // added to the model skins
1368 /*void UpdateColorModHack()
1369 {
1370         float c;
1371         c = this.clientcolors & 15;
1372         // LordHavoc: only bothering to support white, green, red, yellow, blue
1373              if (!teamplay) this.colormod = '0 0 0';
1374         else if (c ==  0) this.colormod = '1.00 1.00 1.00';
1375         else if (c ==  3) this.colormod = '0.10 1.73 0.10';
1376         else if (c ==  4) this.colormod = '1.73 0.10 0.10';
1377         else if (c == 12) this.colormod = '1.22 1.22 0.10';
1378         else if (c == 13) this.colormod = '0.10 0.10 1.73';
1379         else this.colormod = '1 1 1';
1380 }*/
1381
1382 void respawn(entity this)
1383 {
1384         if(this.alpha >= 0 && autocvar_g_respawn_ghosts)
1385         {
1386                 this.solid = SOLID_NOT;
1387                 this.takedamage = DAMAGE_NO;
1388                 set_movetype(this, MOVETYPE_FLY);
1389                 this.velocity = '0 0 1' * autocvar_g_respawn_ghosts_speed;
1390                 this.avelocity = randomvec() * autocvar_g_respawn_ghosts_speed * 3 - randomvec() * autocvar_g_respawn_ghosts_speed * 3;
1391                 this.effects |= CSQCMODEL_EF_RESPAWNGHOST;
1392                 Send_Effect(EFFECT_RESPAWN_GHOST, this.origin, '0 0 0', 1);
1393                 if(autocvar_g_respawn_ghosts_maxtime)
1394                         SUB_SetFade (this, time + autocvar_g_respawn_ghosts_maxtime / 2 + random () * (autocvar_g_respawn_ghosts_maxtime - autocvar_g_respawn_ghosts_maxtime / 2), 1.5);
1395         }
1396
1397         CopyBody(this, 1);
1398
1399         this.effects |= EF_NODRAW; // prevent another CopyBody
1400         PutClientInServer(this);
1401 }
1402
1403 void play_countdown(entity this, float finished, Sound samp)
1404 {
1405     TC(Sound, samp);
1406         if(IS_REAL_CLIENT(this))
1407                 if(floor(finished - time - frametime) != floor(finished - time))
1408                         if(finished - time < 6)
1409                                 sound (this, CH_INFO, samp, VOL_BASE, ATTEN_NORM);
1410 }
1411
1412 void player_powerups(entity this)
1413 {
1414         // add a way to see what the items were BEFORE all of these checks for the mutator hook
1415         int items_prev = this.items;
1416
1417         if((this.items & IT_USING_JETPACK) && !IS_DEAD(this) && !game_stopped)
1418                 this.modelflags |= MF_ROCKET;
1419         else
1420                 this.modelflags &= ~MF_ROCKET;
1421
1422         this.effects &= ~(EF_RED | EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT | EF_FLAME | EF_NODEPTHTEST);
1423
1424         if((this.alpha < 0 || IS_DEAD(this)) && !this.vehicle) // don't apply the flags if the player is gibbed
1425                 return;
1426
1427         Fire_ApplyDamage(this);
1428         Fire_ApplyEffect(this);
1429
1430         if (!g_instagib)
1431         {
1432                 if (this.items & ITEM_Strength.m_itemid)
1433                 {
1434                         play_countdown(this, this.strength_finished, SND_POWEROFF);
1435                         this.effects = this.effects | (EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT);
1436                         if (time > this.strength_finished)
1437                         {
1438                                 this.items = this.items - (this.items & ITEM_Strength.m_itemid);
1439                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERDOWN_STRENGTH, this.netname);
1440                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERDOWN_STRENGTH);
1441                         }
1442                 }
1443                 else
1444                 {
1445                         if (time < this.strength_finished)
1446                         {
1447                                 this.items = this.items | ITEM_Strength.m_itemid;
1448                                 if(!g_cts)
1449                                         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERUP_STRENGTH, this.netname);
1450                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERUP_STRENGTH);
1451                         }
1452                 }
1453                 if (this.items & ITEM_Shield.m_itemid)
1454                 {
1455                         play_countdown(this, this.invincible_finished, SND_POWEROFF);
1456                         this.effects = this.effects | (EF_RED | EF_ADDITIVE | EF_FULLBRIGHT);
1457                         if (time > this.invincible_finished)
1458                         {
1459                                 this.items = this.items - (this.items & ITEM_Shield.m_itemid);
1460                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERDOWN_SHIELD, this.netname);
1461                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERDOWN_SHIELD);
1462                         }
1463                 }
1464                 else
1465                 {
1466                         if (time < this.invincible_finished)
1467                         {
1468                                 this.items = this.items | ITEM_Shield.m_itemid;
1469                                 if(!g_cts)
1470                                         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERUP_SHIELD, this.netname);
1471                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERUP_SHIELD);
1472                         }
1473                 }
1474                 if (this.items & IT_SUPERWEAPON)
1475                 {
1476                         if (!(this.weapons & WEPSET_SUPERWEAPONS))
1477                         {
1478                                 this.superweapons_finished = 0;
1479                                 this.items = this.items - (this.items & IT_SUPERWEAPON);
1480                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_LOST, this.netname);
1481                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_LOST);
1482                         }
1483                         else if (this.items & IT_UNLIMITED_SUPERWEAPONS)
1484                         {
1485                                 // don't let them run out
1486                         }
1487                         else
1488                         {
1489                                 play_countdown(this, this.superweapons_finished, SND_POWEROFF);
1490                                 if (time > this.superweapons_finished)
1491                                 {
1492                                         this.items = this.items - (this.items & IT_SUPERWEAPON);
1493                                         this.weapons &= ~WEPSET_SUPERWEAPONS;
1494                                         //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_BROKEN, this.netname);
1495                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_BROKEN);
1496                                 }
1497                         }
1498                 }
1499                 else if(this.weapons & WEPSET_SUPERWEAPONS)
1500                 {
1501                         if (time < this.superweapons_finished || (this.items & IT_UNLIMITED_SUPERWEAPONS))
1502                         {
1503                                 this.items = this.items | IT_SUPERWEAPON;
1504                                 if(!g_cts)
1505                                         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_PICKUP, this.netname);
1506                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_PICKUP);
1507                         }
1508                         else
1509                         {
1510                                 this.superweapons_finished = 0;
1511                                 this.weapons &= ~WEPSET_SUPERWEAPONS;
1512                         }
1513                 }
1514                 else
1515                 {
1516                         this.superweapons_finished = 0;
1517                 }
1518         }
1519
1520         if(autocvar_g_nodepthtestplayers)
1521                 this.effects = this.effects | EF_NODEPTHTEST;
1522
1523         if(autocvar_g_fullbrightplayers)
1524                 this.effects = this.effects | EF_FULLBRIGHT;
1525
1526         if (time >= game_starttime)
1527         if (time < this.spawnshieldtime)
1528                 this.effects = this.effects | (EF_ADDITIVE | EF_FULLBRIGHT);
1529
1530         MUTATOR_CALLHOOK(PlayerPowerups, this, items_prev);
1531 }
1532
1533 float CalcRegen(float current, float stable, float regenfactor, float regenframetime)
1534 {
1535         if(current > stable)
1536                 return current;
1537         else if(current > stable - 0.25) // when close enough, "snap"
1538                 return stable;
1539         else
1540                 return min(stable, current + (stable - current) * regenfactor * regenframetime);
1541 }
1542
1543 float CalcRot(float current, float stable, float rotfactor, float rotframetime)
1544 {
1545         if(current < stable)
1546                 return current;
1547         else if(current < stable + 0.25) // when close enough, "snap"
1548                 return stable;
1549         else
1550                 return max(stable, current + (stable - current) * rotfactor * rotframetime);
1551 }
1552
1553 float CalcRotRegen(float current, float regenstable, float regenfactor, float regenlinear, float regenframetime, float rotstable, float rotfactor, float rotlinear, float rotframetime, float limit)
1554 {
1555         if(current > rotstable)
1556         {
1557                 if(rotframetime > 0)
1558                 {
1559                         current = CalcRot(current, rotstable, rotfactor, rotframetime);
1560                         current = max(rotstable, current - rotlinear * rotframetime);
1561                 }
1562         }
1563         else if(current < regenstable)
1564         {
1565                 if(regenframetime > 0)
1566                 {
1567                         current = CalcRegen(current, regenstable, regenfactor, regenframetime);
1568                         current = min(regenstable, current + regenlinear * regenframetime);
1569                 }
1570         }
1571
1572         if(current > limit)
1573                 current = limit;
1574
1575         return current;
1576 }
1577
1578 void player_regen(entity this)
1579 {
1580         float max_mod, regen_mod, rot_mod, limit_mod;
1581         max_mod = regen_mod = rot_mod = limit_mod = 1;
1582
1583         float regen_health = autocvar_g_balance_health_regen;
1584         float regen_health_linear = autocvar_g_balance_health_regenlinear;
1585         float regen_health_rot = autocvar_g_balance_health_rot;
1586         float regen_health_rotlinear = autocvar_g_balance_health_rotlinear;
1587         float regen_health_stable = autocvar_g_balance_health_regenstable;
1588         float regen_health_rotstable = autocvar_g_balance_health_rotstable;
1589         bool mutator_returnvalue = MUTATOR_CALLHOOK(PlayerRegen, this, max_mod, regen_mod, rot_mod, limit_mod, regen_health, regen_health_linear, regen_health_rot,
1590                 regen_health_rotlinear, regen_health_stable, regen_health_rotstable);
1591         max_mod = M_ARGV(1, float);
1592         regen_mod = M_ARGV(2, float);
1593         rot_mod = M_ARGV(3, float);
1594         limit_mod = M_ARGV(4, float);
1595         regen_health = M_ARGV(5, float);
1596         regen_health_linear = M_ARGV(6, float);
1597         regen_health_rot = M_ARGV(7, float);
1598         regen_health_rotlinear = M_ARGV(8, float);
1599         regen_health_stable = M_ARGV(9, float);
1600         regen_health_rotstable = M_ARGV(10, float);
1601
1602
1603         if(!mutator_returnvalue)
1604         if(!STAT(FROZEN, this))
1605         {
1606                 float mina, maxa, limith, limita;
1607                 maxa = autocvar_g_balance_armor_rotstable;
1608                 mina = autocvar_g_balance_armor_regenstable;
1609                 limith = autocvar_g_balance_health_limit;
1610                 limita = autocvar_g_balance_armor_limit;
1611
1612                 regen_health_rotstable = regen_health_rotstable * max_mod;
1613                 regen_health_stable = regen_health_stable * max_mod;
1614                 limith = limith * limit_mod;
1615                 limita = limita * limit_mod;
1616
1617                 this.armorvalue = CalcRotRegen(this.armorvalue, mina, autocvar_g_balance_armor_regen, autocvar_g_balance_armor_regenlinear, regen_mod * frametime * (time > this.pauseregen_finished), maxa, autocvar_g_balance_armor_rot, autocvar_g_balance_armor_rotlinear, rot_mod * frametime * (time > this.pauserotarmor_finished), limita);
1618                 this.health = CalcRotRegen(this.health, regen_health_stable, regen_health, regen_health_linear, regen_mod * frametime * (time > this.pauseregen_finished), regen_health_rotstable, regen_health_rot, regen_health_rotlinear, rot_mod * frametime * (time > this.pauserothealth_finished), limith);
1619         }
1620
1621         // if player rotted to death...  die!
1622         // check this outside above checks, as player may still be able to rot to death
1623         if(this.health < 1)
1624         {
1625                 if(this.vehicle)
1626                         vehicles_exit(this.vehicle, VHEF_RELEASE);
1627                 if(this.event_damage)
1628                         this.event_damage(this, this, this, 1, DEATH_ROT.m_id, this.origin, '0 0 0');
1629         }
1630
1631         if (!(this.items & IT_UNLIMITED_WEAPON_AMMO))
1632         {
1633                 float minf, maxf, limitf;
1634
1635                 maxf = autocvar_g_balance_fuel_rotstable;
1636                 minf = autocvar_g_balance_fuel_regenstable;
1637                 limitf = autocvar_g_balance_fuel_limit;
1638
1639                 this.ammo_fuel = CalcRotRegen(this.ammo_fuel, minf, autocvar_g_balance_fuel_regen, autocvar_g_balance_fuel_regenlinear, frametime * (time > this.pauseregen_finished) * ((this.items & ITEM_JetpackRegen.m_itemid) != 0), maxf, autocvar_g_balance_fuel_rot, autocvar_g_balance_fuel_rotlinear, frametime * (time > this.pauserotfuel_finished), limitf);
1640         }
1641 }
1642
1643 bool zoomstate_set;
1644 void SetZoomState(entity this, float newzoom)
1645 {
1646         if(newzoom != this.zoomstate)
1647         {
1648                 this.zoomstate = newzoom;
1649                 ClientData_Touch(this);
1650         }
1651         zoomstate_set = true;
1652 }
1653
1654 void GetPressedKeys(entity this)
1655 {
1656         MUTATOR_CALLHOOK(GetPressedKeys, this);
1657         int keys = STAT(PRESSED_KEYS, this);
1658         keys = BITSET(keys, KEY_FORWARD,        this.movement.x > 0);
1659         keys = BITSET(keys, KEY_BACKWARD,       this.movement.x < 0);
1660         keys = BITSET(keys, KEY_RIGHT,          this.movement.y > 0);
1661         keys = BITSET(keys, KEY_LEFT,           this.movement.y < 0);
1662
1663         keys = BITSET(keys, KEY_JUMP,           PHYS_INPUT_BUTTON_JUMP(this));
1664         keys = BITSET(keys, KEY_CROUCH,         PHYS_INPUT_BUTTON_CROUCH(this));
1665         keys = BITSET(keys, KEY_ATCK,           PHYS_INPUT_BUTTON_ATCK(this));
1666         keys = BITSET(keys, KEY_ATCK2,          PHYS_INPUT_BUTTON_ATCK2(this));
1667         this.pressedkeys = keys; // store for other users
1668
1669         STAT(PRESSED_KEYS, this) = keys;
1670 }
1671
1672 /*
1673 ======================
1674 spectate mode routines
1675 ======================
1676 */
1677
1678 void SpectateCopy(entity this, entity spectatee)
1679 {
1680     TC(Client, this); TC(Client, spectatee);
1681
1682         MUTATOR_CALLHOOK(SpectateCopy, spectatee, this);
1683         PS(this) = PS(spectatee);
1684         this.armortype = spectatee.armortype;
1685         this.armorvalue = spectatee.armorvalue;
1686         this.ammo_cells = spectatee.ammo_cells;
1687         this.ammo_plasma = spectatee.ammo_plasma;
1688         this.ammo_shells = spectatee.ammo_shells;
1689         this.ammo_nails = spectatee.ammo_nails;
1690         this.ammo_rockets = spectatee.ammo_rockets;
1691         this.ammo_fuel = spectatee.ammo_fuel;
1692         this.clip_load = spectatee.clip_load;
1693         this.clip_size = spectatee.clip_size;
1694         this.effects = spectatee.effects & EFMASK_CHEAP; // eat performance
1695         this.health = spectatee.health;
1696         this.impulse = 0;
1697         this.items = spectatee.items;
1698         this.last_pickup = spectatee.last_pickup;
1699         this.hit_time = spectatee.hit_time;
1700         this.strength_finished = spectatee.strength_finished;
1701         this.invincible_finished = spectatee.invincible_finished;
1702         this.superweapons_finished = spectatee.superweapons_finished;
1703         STAT(PRESSED_KEYS, this) = STAT(PRESSED_KEYS, spectatee);
1704         this.weapons = spectatee.weapons;
1705         this.dual_weapons = spectatee.dual_weapons;
1706         this.vortex_charge = spectatee.vortex_charge;
1707         this.vortex_chargepool_ammo = spectatee.vortex_chargepool_ammo;
1708         this.okvortex_charge = spectatee.okvortex_charge;
1709         this.okvortex_chargepool_ammo = spectatee.okvortex_chargepool_ammo;
1710         this.hagar_load = spectatee.hagar_load;
1711         this.arc_heat_percent = spectatee.arc_heat_percent;
1712         this.minelayer_mines = spectatee.minelayer_mines;
1713         this.punchangle = spectatee.punchangle;
1714         this.view_ofs = spectatee.view_ofs;
1715         this.velocity = spectatee.velocity;
1716         this.dmg_take = spectatee.dmg_take;
1717         this.dmg_save = spectatee.dmg_save;
1718         this.dmg_inflictor = spectatee.dmg_inflictor;
1719         this.v_angle = spectatee.v_angle;
1720         this.angles = spectatee.v_angle;
1721         STAT(FROZEN, this) = STAT(FROZEN, spectatee);
1722         this.revive_progress = spectatee.revive_progress;
1723         this.viewloc = spectatee.viewloc;
1724         if(!PHYS_INPUT_BUTTON_USE(this) && STAT(CAMERA_SPECTATOR, this) != 2)
1725                 this.fixangle = true;
1726         setorigin(this, spectatee.origin);
1727         setsize(this, spectatee.mins, spectatee.maxs);
1728         SetZoomState(this, spectatee.zoomstate);
1729
1730         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1731         {
1732                 .entity weaponentity = weaponentities[slot];
1733                 this.(weaponentity) = spectatee.(weaponentity);
1734         }
1735
1736         for(int slot = 0; slot < MAX_AXH; ++slot)
1737         {
1738                 this.(AuxiliaryXhair[slot]) = spectatee.(AuxiliaryXhair[slot]);
1739         }
1740
1741     anticheat_spectatecopy(this, spectatee);
1742         this.hud = spectatee.hud;
1743         if(spectatee.vehicle)
1744     {
1745         this.angles = spectatee.v_angle;
1746
1747         //this.fixangle = false;
1748         //this.velocity = spectatee.vehicle.velocity;
1749         this.vehicle_health = spectatee.vehicle_health;
1750         this.vehicle_shield = spectatee.vehicle_shield;
1751         this.vehicle_energy = spectatee.vehicle_energy;
1752         this.vehicle_ammo1 = spectatee.vehicle_ammo1;
1753         this.vehicle_ammo2 = spectatee.vehicle_ammo2;
1754         this.vehicle_reload1 = spectatee.vehicle_reload1;
1755         this.vehicle_reload2 = spectatee.vehicle_reload2;
1756
1757         //msg_entity = this;
1758
1759        // WriteByte (MSG_ONE, SVC_SETVIEWANGLES);
1760             //WriteAngle(MSG_ONE,  spectatee.v_angle.x);
1761            // WriteAngle(MSG_ONE,  spectatee.v_angle.y);
1762            // WriteAngle(MSG_ONE,  spectatee.v_angle.z);
1763
1764         //WriteByte (MSG_ONE, SVC_SETVIEW);
1765         //    WriteEntity(MSG_ONE, this);
1766         //makevectors(spectatee.v_angle);
1767         //setorigin(this, spectatee.origin - v_forward * 400 + v_up * 300);*/
1768     }
1769 }
1770
1771 bool SpectateUpdate(entity this)
1772 {
1773         if(!this.enemy)
1774                 return false;
1775
1776         if(!IS_PLAYER(this.enemy) || this == this.enemy)
1777         {
1778                 SetSpectatee(this, NULL);
1779                 return false;
1780         }
1781
1782         SpectateCopy(this, this.enemy);
1783
1784         return true;
1785 }
1786
1787 bool SpectateSet(entity this)
1788 {
1789         if(!IS_PLAYER(this.enemy))
1790                 return false;
1791
1792         ClientData_Touch(this.enemy);
1793
1794         msg_entity = this;
1795         WriteByte(MSG_ONE, SVC_SETVIEW);
1796         WriteEntity(MSG_ONE, this.enemy);
1797         set_movetype(this, MOVETYPE_NONE);
1798         accuracy_resend(this);
1799
1800         if(!SpectateUpdate(this))
1801                 PutObserverInServer(this);
1802
1803         return true;
1804 }
1805
1806 void SetSpectatee_status(entity this, int spectatee_num)
1807 {
1808         int oldspectatee_status = this.spectatee_status;
1809         this.spectatee_status = spectatee_num;
1810
1811         if (this.spectatee_status != oldspectatee_status)
1812         {
1813                 ClientData_Touch(this);
1814                 if (g_race || g_cts) race_InitSpectator();
1815         }
1816 }
1817
1818 void SetSpectatee(entity this, entity spectatee)
1819 {
1820         if(IS_BOT_CLIENT(this))
1821                 return; // bots abuse .enemy, this code is useless to them
1822
1823         entity old_spectatee = this.enemy;
1824
1825         this.enemy = spectatee;
1826
1827         // WEAPONTODO
1828         // these are required to fix the spectator bug with arc
1829         if(old_spectatee)
1830         {
1831                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1832                 {
1833                         .entity weaponentity = weaponentities[slot];
1834                         if(old_spectatee.(weaponentity).arc_beam)
1835                                 old_spectatee.(weaponentity).arc_beam.SendFlags |= ARC_SF_SETTINGS;
1836                 }
1837         }
1838         if(this.enemy)
1839         {
1840                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1841                 {
1842                         .entity weaponentity = weaponentities[slot];
1843                         if(this.enemy.(weaponentity).arc_beam)
1844                                 this.enemy.(weaponentity).arc_beam.SendFlags |= ARC_SF_SETTINGS;
1845                 }
1846         }
1847
1848         if (this.enemy)
1849                 SetSpectatee_status(this, etof(this.enemy));
1850
1851         // needed to update spectator list
1852         if(old_spectatee) { ClientData_Touch(old_spectatee); }
1853 }
1854
1855 bool Spectate(entity this, entity pl)
1856 {
1857         if(MUTATOR_CALLHOOK(SpectateSet, this, pl))
1858                 return false;
1859         pl = M_ARGV(1, entity);
1860
1861         SetSpectatee(this, pl);
1862         return SpectateSet(this);
1863 }
1864
1865 bool SpectateNext(entity this)
1866 {
1867         entity ent = find(this.enemy, classname, STR_PLAYER);
1868
1869         if (MUTATOR_CALLHOOK(SpectateNext, this, ent))
1870                 ent = M_ARGV(1, entity);
1871         else if (!ent)
1872                 ent = find(ent, classname, STR_PLAYER);
1873
1874         if(ent) { SetSpectatee(this, ent); }
1875
1876         return SpectateSet(this);
1877 }
1878
1879 bool SpectatePrev(entity this)
1880 {
1881         // NOTE: chain order is from the highest to the lower entnum (unlike find)
1882         entity ent = findchain(classname, STR_PLAYER);
1883         if (!ent) // no player
1884                 return false;
1885
1886         entity first = ent;
1887         // skip players until current spectated player
1888         if(this.enemy)
1889         while(ent && ent != this.enemy)
1890                 ent = ent.chain;
1891
1892         switch (MUTATOR_CALLHOOK(SpectatePrev, this, ent, first))
1893         {
1894                 case MUT_SPECPREV_FOUND:
1895                     ent = M_ARGV(1, entity);
1896                     break;
1897                 case MUT_SPECPREV_RETURN:
1898                     return true;
1899                 case MUT_SPECPREV_CONTINUE:
1900                 default:
1901                 {
1902                         if(ent.chain)
1903                                 ent = ent.chain;
1904                         else
1905                                 ent = first;
1906                         break;
1907                 }
1908         }
1909
1910         SetSpectatee(this, ent);
1911         return SpectateSet(this);
1912 }
1913
1914 /*
1915 =============
1916 ShowRespawnCountdown()
1917
1918 Update a respawn countdown display.
1919 =============
1920 */
1921 void ShowRespawnCountdown(entity this)
1922 {
1923         float number;
1924         if(!IS_DEAD(this)) // just respawned?
1925                 return;
1926         else
1927         {
1928                 number = ceil(this.respawn_time - time);
1929                 if(number <= 0)
1930                         return;
1931                 if(number <= this.respawn_countdown)
1932                 {
1933                         this.respawn_countdown = number - 1;
1934                         if(ceil(this.respawn_time - (time + 0.5)) == number) // only say it if it is the same number even in 0.5s; to prevent overlapping sounds
1935                                 { Send_Notification(NOTIF_ONE, this, MSG_ANNCE, Announcer_PickNumber(CNT_RESPAWN, number)); }
1936                 }
1937         }
1938 }
1939
1940 .bool team_selected;
1941 bool ShowTeamSelection(entity this)
1942 {
1943         if(!teamplay || autocvar_g_campaign || autocvar_g_balance_teams || this.team_selected || (this.wasplayer && autocvar_g_changeteam_banned) || this.team_forced > 0)
1944                 return false;
1945         stuffcmd(this, "menu_showteamselect\n");
1946         return true;
1947 }
1948 void Join(entity this)
1949 {
1950         TRANSMUTE(Player, this);
1951
1952         if(!this.team_selected)
1953         if(autocvar_g_campaign || autocvar_g_balance_teams)
1954                 JoinBestTeam(this, false, true);
1955
1956         if(autocvar_g_campaign)
1957                 campaign_bots_may_start = true;
1958
1959         Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_PREVENT_JOIN);
1960
1961         PutClientInServer(this);
1962
1963         if(IS_PLAYER(this))
1964         if(teamplay && this.team != -1)
1965                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, APP_TEAM_NUM(this.team, INFO_JOIN_PLAY_TEAM), this.netname);
1966         else
1967                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_JOIN_PLAY, this.netname);
1968         this.team_selected = false;
1969 }
1970
1971 /**
1972  * Determines whether the player is allowed to join. This depends on cvar
1973  * g_maxplayers, if it isn't used this function always return true, otherwise
1974  * it checks whether the number of currently playing players exceeds g_maxplayers.
1975  * @return int number of free slots for players, 0 if none
1976  */
1977 int nJoinAllowed(entity this, entity ignore)
1978 {
1979         if(!ignore)
1980         // this is called that way when checking if anyone may be able to join (to build qcstatus)
1981         // so report 0 free slots if restricted
1982         {
1983                 if(autocvar_g_forced_team_otherwise == "spectate")
1984                         return 0;
1985                 if(autocvar_g_forced_team_otherwise == "spectator")
1986                         return 0;
1987         }
1988
1989         if(this && this.team_forced < 0)
1990                 return 0; // forced spectators can never join
1991
1992         // TODO simplify this
1993         int totalClients = 0;
1994         int currentlyPlaying = 0;
1995         FOREACH_CLIENT(true, LAMBDA(
1996                 if(it != ignore)
1997                         ++totalClients;
1998                 if(IS_REAL_CLIENT(it))
1999                 if(IS_PLAYER(it) || it.caplayer)
2000                         ++currentlyPlaying;
2001         ));
2002
2003         float free_slots = 0;
2004         if (!autocvar_g_maxplayers)
2005                 free_slots = maxclients - totalClients;
2006         else if(currentlyPlaying < autocvar_g_maxplayers)
2007                 free_slots = min(maxclients - totalClients, autocvar_g_maxplayers - currentlyPlaying);
2008
2009         static float join_prevent_msg_time = 0;
2010         if(this && ignore && !free_slots && time > join_prevent_msg_time)
2011         {
2012                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_JOIN_PREVENT);
2013                 join_prevent_msg_time = time + 3;
2014         }
2015
2016         return free_slots;
2017 }
2018
2019 /**
2020  * Checks whether the client is an observer or spectator, if so, he will get kicked after
2021  * g_maxplayers_spectator_blocktime seconds
2022  */
2023 void checkSpectatorBlock(entity this)
2024 {
2025         if(IS_SPEC(this) || IS_OBSERVER(this))
2026         if(!this.caplayer)
2027         if(IS_REAL_CLIENT(this))
2028         {
2029                 if( time > (this.spectatortime + autocvar_g_maxplayers_spectator_blocktime) ) {
2030                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_QUIT_KICK_SPECTATING);
2031                         dropclient(this);
2032                 }
2033         }
2034 }
2035
2036 void PrintWelcomeMessage(entity this)
2037 {
2038         if(this.motd_actived_time == 0)
2039         {
2040                 if (autocvar_g_campaign) {
2041                         if ((IS_PLAYER(this) && PHYS_INPUT_BUTTON_INFO(this)) || (!IS_PLAYER(this))) {
2042                                 this.motd_actived_time = time;
2043                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOTD, campaign_message);
2044                         }
2045                 } else {
2046                         if (PHYS_INPUT_BUTTON_INFO(this)) {
2047                                 this.motd_actived_time = time;
2048                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOTD, getwelcomemessage(this));
2049                         }
2050                 }
2051         }
2052         else if(this.motd_actived_time > 0) // showing MOTD or campaign message
2053         {
2054                 if (autocvar_g_campaign) {
2055                         if (PHYS_INPUT_BUTTON_INFO(this))
2056                                 this.motd_actived_time = time;
2057                         else if ((time - this.motd_actived_time > 2) && IS_PLAYER(this)) { // hide it some seconds after BUTTON_INFO has been released
2058                                 this.motd_actived_time = 0;
2059                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_MOTD);
2060                         }
2061                 } else {
2062                         if (PHYS_INPUT_BUTTON_INFO(this))
2063                                 this.motd_actived_time = time;
2064                         else if (time - this.motd_actived_time > 2) { // hide it some seconds after BUTTON_INFO has been released
2065                                 this.motd_actived_time = 0;
2066                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_MOTD);
2067                         }
2068                 }
2069         }
2070         else //if(this.motd_actived_time < 0) // just connected, motd is active
2071         {
2072                 if(PHYS_INPUT_BUTTON_INFO(this)) // BUTTON_INFO hides initial MOTD
2073                         this.motd_actived_time = -2; // wait until BUTTON_INFO gets released
2074                 else if(this.motd_actived_time == -2 || IS_PLAYER(this) || IS_SPEC(this))
2075                 {
2076                         // instanctly hide MOTD
2077                         this.motd_actived_time = 0;
2078                         Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_MOTD);
2079                 }
2080         }
2081 }
2082
2083 bool joinAllowed(entity this)
2084 {
2085         if (this.version_mismatch) return false;
2086         if (!nJoinAllowed(this, this)) return false;
2087         if (teamplay && lockteams) return false;
2088         if (ShowTeamSelection(this)) return false;
2089         if (MUTATOR_CALLHOOK(ForbidSpawn, this)) return false;
2090         return true;
2091 }
2092
2093 void ObserverThink(entity this)
2094 {
2095         if ( this.impulse )
2096         {
2097                 MinigameImpulse(this, this.impulse);
2098                 this.impulse = 0;
2099         }
2100
2101         if (this.flags & FL_JUMPRELEASED) {
2102                 if (PHYS_INPUT_BUTTON_JUMP(this) && joinAllowed(this)) {
2103                         this.flags &= ~FL_JUMPRELEASED;
2104                         this.flags |= FL_SPAWNING;
2105                 } else if(PHYS_INPUT_BUTTON_ATCK(this) && !this.version_mismatch) {
2106                         this.flags &= ~FL_JUMPRELEASED;
2107                         if(SpectateNext(this)) {
2108                                 TRANSMUTE(Spectator, this);
2109                         }
2110                 } else {
2111                         int preferred_movetype = ((!PHYS_INPUT_BUTTON_USE(this) ? this.cvar_cl_clippedspectating : !this.cvar_cl_clippedspectating) ? MOVETYPE_FLY_WORLDONLY : MOVETYPE_NOCLIP);
2112                         set_movetype(this, preferred_movetype);
2113                 }
2114         } else {
2115                 if (!(PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_JUMP(this))) {
2116                         this.flags |= FL_JUMPRELEASED;
2117                         if(this.flags & FL_SPAWNING)
2118                         {
2119                                 this.flags &= ~FL_SPAWNING;
2120                                 Join(this);
2121                                 return;
2122                         }
2123                 }
2124         }
2125 }
2126
2127 void SpectatorThink(entity this)
2128 {
2129         if ( this.impulse )
2130         {
2131                 if(MinigameImpulse(this, this.impulse))
2132                         this.impulse = 0;
2133
2134                 if (this.impulse == IMP_weapon_drop.impulse)
2135                 {
2136                         STAT(CAMERA_SPECTATOR, this) = (STAT(CAMERA_SPECTATOR, this) + 1) % 3;
2137                         this.impulse = 0;
2138                         return;
2139                 }
2140         }
2141
2142         if (this.flags & FL_JUMPRELEASED) {
2143                 if (PHYS_INPUT_BUTTON_JUMP(this) && joinAllowed(this)) {
2144                         this.flags &= ~FL_JUMPRELEASED;
2145                         this.flags |= FL_SPAWNING;
2146                 } else if(PHYS_INPUT_BUTTON_ATCK(this) || this.impulse == 10 || this.impulse == 15 || this.impulse == 18 || (this.impulse >= 200 && this.impulse <= 209)) {
2147                         this.flags &= ~FL_JUMPRELEASED;
2148                         if(SpectateNext(this)) {
2149                                 TRANSMUTE(Spectator, this);
2150                         } else {
2151                                 TRANSMUTE(Observer, this);
2152                                 PutClientInServer(this);
2153                         }
2154                         this.impulse = 0;
2155                 } else if(this.impulse == 12 || this.impulse == 16  || this.impulse == 19 || (this.impulse >= 220 && this.impulse <= 229)) {
2156                         this.flags &= ~FL_JUMPRELEASED;
2157                         if(SpectatePrev(this)) {
2158                                 TRANSMUTE(Spectator, this);
2159                         } else {
2160                                 TRANSMUTE(Observer, this);
2161                                 PutClientInServer(this);
2162                         }
2163                         this.impulse = 0;
2164                 } else if (PHYS_INPUT_BUTTON_ATCK2(this)) {
2165                         this.flags &= ~FL_JUMPRELEASED;
2166                         TRANSMUTE(Observer, this);
2167                         PutClientInServer(this);
2168                 } else {
2169                         if(!SpectateUpdate(this))
2170                                 PutObserverInServer(this);
2171                 }
2172         } else {
2173                 if (!(PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_ATCK2(this))) {
2174                         this.flags |= FL_JUMPRELEASED;
2175                         if(this.flags & FL_SPAWNING)
2176                         {
2177                                 this.flags &= ~FL_SPAWNING;
2178                                 Join(this);
2179                                 return;
2180                         }
2181                 }
2182                 if(!SpectateUpdate(this))
2183                         PutObserverInServer(this);
2184         }
2185
2186         this.flags |= FL_CLIENT | FL_NOTARGET;
2187 }
2188
2189 void vehicles_enter (entity pl, entity veh);
2190 void PlayerUseKey(entity this)
2191 {
2192         if (!IS_PLAYER(this))
2193                 return;
2194
2195         if(this.vehicle)
2196         {
2197                 if(!game_stopped)
2198                 {
2199                         vehicles_exit(this.vehicle, VHEF_NORMAL);
2200                         return;
2201                 }
2202         }
2203         else if(autocvar_g_vehicles_enter)
2204         {
2205                 if(!STAT(FROZEN, this))
2206                 if(!IS_DEAD(this))
2207                 if(!game_stopped)
2208                 {
2209                         entity head, closest_target = NULL;
2210                         head = WarpZone_FindRadius(this.origin, autocvar_g_vehicles_enter_radius, true);
2211
2212                         while(head) // find the closest acceptable target to enter
2213                         {
2214                                 if(IS_VEHICLE(head))
2215                                 if(!IS_DEAD(head))
2216                                 if(!head.owner || ((head.vehicle_flags & VHF_MULTISLOT) && SAME_TEAM(head.owner, this)))
2217                                 if(head.takedamage != DAMAGE_NO)
2218                                 {
2219                                         if(closest_target)
2220                                         {
2221                                                 if(vlen2(this.origin - head.origin) < vlen2(this.origin - closest_target.origin))
2222                                                 { closest_target = head; }
2223                                         }
2224                                         else { closest_target = head; }
2225                                 }
2226
2227                                 head = head.chain;
2228                         }
2229
2230                         if(closest_target) { vehicles_enter(this, closest_target); return; }
2231                 }
2232         }
2233
2234         // a use key was pressed; call handlers
2235         MUTATOR_CALLHOOK(PlayerUseKey, this);
2236 }
2237
2238
2239 /*
2240 =============
2241 PlayerPreThink
2242
2243 Called every frame for each client before the physics are run
2244 =============
2245 */
2246 .float usekeypressed;
2247 .float last_vehiclecheck;
2248 .int items_added;
2249 void PlayerPreThink (entity this)
2250 {
2251         WarpZone_PlayerPhysics_FixVAngle(this);
2252
2253     STAT(GAMESTARTTIME, this) = game_starttime;
2254         STAT(ROUNDSTARTTIME, this) = round_starttime;
2255         STAT(ALLOW_OLDVORTEXBEAM, this) = autocvar_g_allow_oldvortexbeam;
2256         STAT(LEADLIMIT, this) = autocvar_leadlimit;
2257
2258         STAT(WEAPONSINMAP, this) = weaponsInMap;
2259
2260         if (frametime) {
2261                 // physics frames: update anticheat stuff
2262                 anticheat_prethink(this);
2263         }
2264
2265         if (blockSpectators && frametime) {
2266                 // WORKAROUND: only use dropclient in server frames (frametime set).
2267                 // Never use it in cl_movement frames (frametime zero).
2268                 checkSpectatorBlock(this);
2269     }
2270
2271         zoomstate_set = false;
2272
2273         // Check for nameless players
2274         if (isInvisibleString(this.netname)) {
2275                 this.netname = strzone(sprintf("Player#%d", this.playerid));
2276                 // stuffcmd(this, strcat("name ", this.netname, "\n")); // maybe?
2277         }
2278         if (this.netname != this.netname_previous) {
2279                 if (autocvar_sv_eventlog) {
2280                         GameLogEcho(strcat(":name:", ftos(this.playerid), ":", playername(this, false)));
2281         }
2282                 if (this.netname_previous) strunzone(this.netname_previous);
2283                 this.netname_previous = strzone(this.netname);
2284         }
2285
2286         // version nagging
2287         if (this.version_nagtime && this.cvar_g_xonoticversion && time > this.version_nagtime) {
2288         this.version_nagtime = 0;
2289         if (strstrofs(this.cvar_g_xonoticversion, "git", 0) >= 0 || strstrofs(this.cvar_g_xonoticversion, "autobuild", 0) >= 0) {
2290             // git client
2291         } else if (strstrofs(autocvar_g_xonoticversion, "git", 0) >= 0 || strstrofs(autocvar_g_xonoticversion, "autobuild", 0) >= 0) {
2292             // git server
2293             Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_BETA, autocvar_g_xonoticversion, this.cvar_g_xonoticversion);
2294         } else {
2295             int r = vercmp(this.cvar_g_xonoticversion, autocvar_g_xonoticversion);
2296             if (r < 0) { // old client
2297                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_OUTDATED, autocvar_g_xonoticversion, this.cvar_g_xonoticversion);
2298             } else if (r > 0) { // old server
2299                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_OLD, autocvar_g_xonoticversion, this.cvar_g_xonoticversion);
2300             }
2301         }
2302     }
2303
2304         // GOD MODE info
2305         if (!(this.flags & FL_GODMODE) && this.max_armorvalue)
2306         {
2307                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_GODMODE_OFF, this.max_armorvalue);
2308                 this.max_armorvalue = 0;
2309         }
2310
2311         if (STAT(FROZEN, this) == 2)
2312         {
2313                 this.revive_progress = bound(0, this.revive_progress + frametime * this.revive_speed, 1);
2314                 this.health = max(1, this.revive_progress * start_health);
2315                 this.iceblock.alpha = bound(0.2, 1 - this.revive_progress, 1);
2316
2317                 if (this.revive_progress >= 1)
2318                         Unfreeze(this);
2319         }
2320         else if (STAT(FROZEN, this) == 3)
2321         {
2322                 this.revive_progress = bound(0, this.revive_progress - frametime * this.revive_speed, 1);
2323                 this.health = max(0, autocvar_g_nades_ice_health + (start_health-autocvar_g_nades_ice_health) * this.revive_progress );
2324
2325                 if (this.health < 1)
2326                 {
2327                         if (this.vehicle)
2328                                 vehicles_exit(this.vehicle, VHEF_RELEASE);
2329                         if(this.event_damage)
2330                                 this.event_damage(this, this, this.frozen_by, 1, DEATH_NADE_ICE_FREEZE.m_id, this.origin, '0 0 0');
2331                 }
2332                 else if (this.revive_progress <= 0)
2333                         Unfreeze(this);
2334         }
2335
2336         MUTATOR_CALLHOOK(PlayerPreThink, this);
2337
2338         if(autocvar_g_vehicles_enter && (time > this.last_vehiclecheck) && !game_stopped && !this.vehicle)
2339         if(IS_PLAYER(this) && !STAT(FROZEN, this) && !IS_DEAD(this))
2340         {
2341                 FOREACH_ENTITY_RADIUS(this.origin, autocvar_g_vehicles_enter_radius, IS_VEHICLE(it),
2342                 {
2343                         if(!IS_DEAD(it) && it.takedamage != DAMAGE_NO)
2344                         if((it.vehicle_flags & VHF_MULTISLOT) && SAME_TEAM(it.owner, this))
2345                         {
2346                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER_GUNNER);
2347                         }
2348                         else if(!it.owner)
2349                         {
2350                                 if(!it.team || SAME_TEAM(this, it))
2351                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER);
2352                                 else if(autocvar_g_vehicles_steal)
2353                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER_STEAL);
2354                         }
2355                 });
2356
2357                 this.last_vehiclecheck = time + 1;
2358         }
2359
2360         if(!this.cvar_cl_newusekeysupported) // FIXME remove this - it was a stupid idea to begin with, we can JUST use the button
2361         {
2362                 if(PHYS_INPUT_BUTTON_USE(this) && !this.usekeypressed)
2363                         PlayerUseKey(this);
2364                 this.usekeypressed = PHYS_INPUT_BUTTON_USE(this);
2365         }
2366
2367         if (IS_REAL_CLIENT(this))
2368                 PrintWelcomeMessage(this);
2369
2370         if (IS_PLAYER(this)) {
2371                 CheckRules_Player(this);
2372
2373                 if (game_stopped || intermission_running) {
2374                         this.modelflags &= ~MF_ROCKET;
2375                         if(intermission_running)
2376                                 IntermissionThink(this);
2377                         return;
2378                 }
2379
2380                 if (timeout_status == TIMEOUT_ACTIVE) {
2381             // don't allow the player to turn around while game is paused
2382                         // FIXME turn this into CSQC stuff
2383                         this.v_angle = this.lastV_angle;
2384                         this.angles = this.lastV_angle;
2385                         this.fixangle = true;
2386                 }
2387
2388                 if (frametime) player_powerups(this);
2389
2390                 if (IS_DEAD(this)) {
2391                         if (this.personal && g_race_qualifying) {
2392                                 if (time > this.respawn_time) {
2393                                         STAT(RESPAWN_TIME, this) = this.respawn_time = time + 1; // only retry once a second
2394                                         respawn(this);
2395                                         this.impulse = CHIMPULSE_SPEEDRUN.impulse;
2396                                 }
2397                         } else {
2398                                 if (frametime) player_anim(this);
2399
2400                                 if (this.respawn_flags & RESPAWN_DENY)
2401                                 {
2402                                         STAT(RESPAWN_TIME, this) = 0;
2403                                         return;
2404                                 }
2405
2406                                 bool button_pressed = (PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_JUMP(this) || PHYS_INPUT_BUTTON_ATCK2(this) || PHYS_INPUT_BUTTON_HOOK(this) || PHYS_INPUT_BUTTON_USE(this));
2407
2408                                 switch(this.deadflag)
2409                                 {
2410                                         case DEAD_DYING:
2411                                         {
2412                                                 if ((this.respawn_flags & RESPAWN_FORCE) && !(this.respawn_time < this.respawn_time_max))
2413                                                         this.deadflag = DEAD_RESPAWNING;
2414                                                 else if (!button_pressed || (time >= this.respawn_time_max && (this.respawn_flags & RESPAWN_FORCE)))
2415                                                         this.deadflag = DEAD_DEAD;
2416                                                 break;
2417                                         }
2418                                         case DEAD_DEAD:
2419                                         {
2420                                                 if (button_pressed)
2421                                                         this.deadflag = DEAD_RESPAWNABLE;
2422                                                 else if (time >= this.respawn_time_max && (this.respawn_flags & RESPAWN_FORCE))
2423                                                         this.deadflag = DEAD_RESPAWNING;
2424                                                 break;
2425                                         }
2426                                         case DEAD_RESPAWNABLE:
2427                                         {
2428                                                 if (!button_pressed || (this.respawn_flags & RESPAWN_FORCE))
2429                                                         this.deadflag = DEAD_RESPAWNING;
2430                                                 break;
2431                                         }
2432                                         case DEAD_RESPAWNING:
2433                                         {
2434                                                 if (time > this.respawn_time)
2435                                                 {
2436                                                         this.respawn_time = time + 1; // only retry once a second
2437                                                         this.respawn_time_max = this.respawn_time;
2438                                                         respawn(this);
2439                                                 }
2440                                                 break;
2441                                         }
2442                                 }
2443
2444                                 ShowRespawnCountdown(this);
2445
2446                                 if (this.respawn_flags & RESPAWN_SILENT)
2447                                         STAT(RESPAWN_TIME, this) = 0;
2448                                 else if ((this.respawn_flags & RESPAWN_FORCE) && this.respawn_time < this.respawn_time_max)
2449                                 {
2450                                         if (time < this.respawn_time)
2451                                                 STAT(RESPAWN_TIME, this) = this.respawn_time;
2452                                         else if (this.deadflag != DEAD_RESPAWNING)
2453                                                 STAT(RESPAWN_TIME, this) = -this.respawn_time_max;
2454                                 }
2455                                 else
2456                                         STAT(RESPAWN_TIME, this) = this.respawn_time;
2457                         }
2458
2459                         // if respawning, invert stat_respawn_time to indicate this, the client translates it
2460                         if (this.deadflag == DEAD_RESPAWNING && STAT(RESPAWN_TIME, this) > 0)
2461                                 STAT(RESPAWN_TIME, this) *= -1;
2462
2463                         return;
2464                 }
2465
2466                 this.prevorigin = this.origin;
2467
2468                 bool have_hook = false;
2469                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2470                 {
2471                         .entity weaponentity = weaponentities[slot];
2472                         if(this.(weaponentity).hook.state)
2473                         {
2474                                 have_hook = true;
2475                                 break;
2476                         }
2477                 }
2478                 bool do_crouch = PHYS_INPUT_BUTTON_CROUCH(this);
2479                 if (have_hook) {
2480                         do_crouch = false;
2481                 } else if (this.waterlevel >= WATERLEVEL_SWIMMING) {
2482                         do_crouch = false;
2483                 } else if (this.vehicle) {
2484                         do_crouch = false;
2485                 } else if (STAT(FROZEN, this)) {
2486                         do_crouch = false;
2487         }
2488
2489                 if (do_crouch) {
2490                         if (!this.crouch) {
2491                                 this.crouch = true;
2492                                 this.view_ofs = STAT(PL_CROUCH_VIEW_OFS, this);
2493                                 setsize(this, STAT(PL_CROUCH_MIN, this), STAT(PL_CROUCH_MAX, this));
2494                                 // setanim(this, this.anim_duck, false, true, true); // this anim is BROKEN anyway
2495                         }
2496                 } else if (this.crouch) {
2497             tracebox(this.origin, STAT(PL_MIN, this), STAT(PL_MAX, this), this.origin, false, this);
2498             if (!trace_startsolid) {
2499                 this.crouch = false;
2500                 this.view_ofs = STAT(PL_VIEW_OFS, this);
2501                 setsize(this, STAT(PL_MIN, this), STAT(PL_MAX, this));
2502             }
2503                 }
2504
2505                 FixPlayermodel(this);
2506
2507                 // LordHavoc: allow firing on move frames (sub-ticrate), this gives better timing on slow servers
2508                 //if(frametime)
2509                 {
2510                         this.items &= ~this.items_added;
2511
2512                         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2513                         {
2514                                 .entity weaponentity = weaponentities[slot];
2515                                 W_WeaponFrame(this, weaponentity);
2516
2517                                 if(slot == 0)
2518                                 {
2519                                         this.clip_load = this.(weaponentity).clip_load;
2520                                         this.clip_size = this.(weaponentity).clip_size;
2521                                 }
2522                         }
2523
2524                         this.items_added = 0;
2525                         if (this.items & ITEM_Jetpack.m_itemid && (this.items & ITEM_JetpackRegen.m_itemid || this.ammo_fuel >= 0.01))
2526                 this.items_added |= IT_FUEL;
2527
2528                         this.items |= this.items_added;
2529                 }
2530
2531                 player_regen(this);
2532
2533                 // WEAPONTODO: Add a weapon request for this
2534                 // rot vortex charge to the charge limit
2535                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2536                 {
2537                         .entity weaponentity = weaponentities[slot];
2538                         if (WEP_CVAR(vortex, charge_rot_rate) && this.(weaponentity).vortex_charge > WEP_CVAR(vortex, charge_limit) && this.(weaponentity).vortex_charge_rottime < time)
2539                         {
2540                                 this.(weaponentity).vortex_charge = bound(WEP_CVAR(vortex, charge_limit), this.(weaponentity).vortex_charge - WEP_CVAR(vortex, charge_rot_rate) * frametime / W_TICSPERFRAME, 1);
2541                         }
2542                         if (WEP_CVAR(okvortex, charge_rot_rate) && this.(weaponentity).okvortex_charge > WEP_CVAR(okvortex, charge_limit) && this.(weaponentity).okvortex_charge_rottime < time)
2543                         {
2544                                 this.(weaponentity).okvortex_charge = bound(WEP_CVAR(okvortex, charge_limit), this.(weaponentity).okvortex_charge - WEP_CVAR(okvortex, charge_rot_rate) * frametime / W_TICSPERFRAME, 1);
2545                         }
2546                 }
2547
2548                 if (frametime) player_anim(this);
2549
2550                 // secret status
2551                 secrets_setstatus(this);
2552
2553                 // monsters status
2554                 monsters_setstatus(this);
2555
2556                 this.dmg_team = max(0, this.dmg_team - autocvar_g_teamdamage_resetspeed * frametime);
2557         }
2558         else if (game_stopped || intermission_running) {
2559                 if(intermission_running)
2560                         IntermissionThink(this);
2561                 return;
2562         }
2563         else if (IS_OBSERVER(this)) {
2564                 ObserverThink(this);
2565         }
2566         else if (IS_SPEC(this)) {
2567                 SpectatorThink(this);
2568         }
2569
2570         // WEAPONTODO: Add weapon request for this
2571         if (!zoomstate_set) {
2572                 bool wep_zoomed = false;
2573                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2574                 {
2575                         .entity weaponentity = weaponentities[slot];
2576                         Weapon thiswep = this.(weaponentity).m_weapon;
2577                         if(thiswep != WEP_Null && thiswep.wr_zoom)
2578                                 wep_zoomed += thiswep.wr_zoom(thiswep, this);
2579                 }
2580                 SetZoomState(this, PHYS_INPUT_BUTTON_ZOOM(this) || PHYS_INPUT_BUTTON_ZOOMSCRIPT(this) || wep_zoomed);
2581     }
2582
2583         if (this.teamkill_soundtime && time > this.teamkill_soundtime)
2584         {
2585                 this.teamkill_soundtime = 0;
2586
2587                 entity e = this.teamkill_soundsource;
2588                 entity oldpusher = e.pusher;
2589                 e.pusher = this;
2590                 PlayerSound(e, playersound_teamshoot, CH_VOICE, VOL_BASEVOICE, VOICETYPE_LASTATTACKER_ONLY);
2591                 e.pusher = oldpusher;
2592         }
2593
2594         if (this.taunt_soundtime && time > this.taunt_soundtime) {
2595                 this.taunt_soundtime = 0;
2596                 PlayerSound(this, playersound_taunt, CH_VOICE, VOL_BASEVOICE, VOICETYPE_AUTOTAUNT);
2597         }
2598
2599         target_voicescript_next(this);
2600
2601         // WEAPONTODO: Move into weaponsystem somehow
2602         // if a player goes unarmed after holding a loaded weapon, empty his clip size and remove the crosshair ammo ring
2603         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2604         {
2605                 .entity weaponentity = weaponentities[slot];
2606                 if(this.(weaponentity).m_weapon == WEP_Null)
2607                         this.(weaponentity).clip_load = this.(weaponentity).clip_size = 0;
2608         }
2609 }
2610
2611 void DrownPlayer(entity this)
2612 {
2613         if(IS_DEAD(this))
2614                 return;
2615
2616         if (this.waterlevel != WATERLEVEL_SUBMERGED || this.vehicle)
2617         {
2618                 if(this.air_finished < time)
2619                         PlayerSound(this, playersound_gasp, CH_PLAYER, VOL_BASE, VOICETYPE_PLAYERSOUND);
2620                 this.air_finished = time + autocvar_g_balance_contents_drowndelay;
2621                 this.dmg = 2;
2622         }
2623         else if (this.air_finished < time)
2624         {       // drown!
2625                 if (this.pain_finished < time)
2626                 {
2627                         Damage (this, NULL, NULL, autocvar_g_balance_contents_playerdamage_drowning * autocvar_g_balance_contents_damagerate, DEATH_DROWN.m_id, this.origin, '0 0 0');
2628                         this.pain_finished = time + 0.5;
2629                 }
2630         }
2631 }
2632
2633 .bool move_qcphysics;
2634
2635 void Player_Physics(entity this)
2636 {
2637         set_movetype(this, this.move_movetype);
2638
2639         if(!this.move_qcphysics)
2640                 return;
2641
2642         if(!frametime && !this.pm_frametime)
2643                 return;
2644
2645         Movetype_Physics_NoMatchTicrate(this, this.pm_frametime, true);
2646
2647         this.pm_frametime = 0;
2648 }
2649
2650 /*
2651 =============
2652 PlayerPostThink
2653
2654 Called every frame for each client after the physics are run
2655 =============
2656 */
2657 .float idlekick_lasttimeleft;
2658 void PlayerPostThink (entity this)
2659 {
2660         Player_Physics(this);
2661
2662         if (sv_maxidle > 0)
2663         if (frametime) // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2664         if (IS_REAL_CLIENT(this))
2665         if (IS_PLAYER(this) || sv_maxidle_spectatorsareidle)
2666         {
2667                 int totalClients = 0;
2668                 if(sv_maxidle_slots > 0)
2669                 {
2670                         FOREACH_CLIENT(IS_REAL_CLIENT(it) || sv_maxidle_slots_countbots,
2671                         {
2672                                 ++totalClients;
2673                         });
2674                 }
2675
2676                 if (sv_maxidle_slots > 0 && (maxclients - totalClients) > sv_maxidle_slots)
2677                 { /* do nothing */ }
2678                 else if (time - this.parm_idlesince < 1) // instead of (time == this.parm_idlesince) to support sv_maxidle <= 10
2679                 {
2680                         if (this.idlekick_lasttimeleft)
2681                         {
2682                                 this.idlekick_lasttimeleft = 0;
2683                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_IDLING);
2684                         }
2685                 }
2686                 else
2687                 {
2688                         float timeleft = ceil(sv_maxidle - (time - this.parm_idlesince));
2689                         if (timeleft == min(10, sv_maxidle - 1)) { // - 1 to support sv_maxidle <= 10
2690                                 if (!this.idlekick_lasttimeleft)
2691                                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_DISCONNECT_IDLING, timeleft);
2692                         }
2693                         if (timeleft <= 0) {
2694                                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_QUIT_KICK_IDLING, this.netname);
2695                                 dropclient(this);
2696                                 return;
2697                         }
2698                         else if (timeleft <= 10) {
2699                                 if (timeleft != this.idlekick_lasttimeleft) {
2700                                     Send_Notification(NOTIF_ONE, this, MSG_ANNCE, Announcer_PickNumber(CNT_IDLE, timeleft));
2701                 }
2702                                 this.idlekick_lasttimeleft = timeleft;
2703                         }
2704                 }
2705         }
2706
2707         CheatFrame(this);
2708
2709         //CheckPlayerJump();
2710         if (game_stopped)
2711         {
2712                 this.solid = SOLID_NOT;
2713                 this.takedamage = DAMAGE_NO;
2714                 set_movetype(this, MOVETYPE_NONE);
2715         }
2716
2717         if (IS_PLAYER(this)) {
2718                 DrownPlayer(this);
2719                 CheckRules_Player(this);
2720                 UpdateChatBubble(this);
2721                 if (this.impulse) ImpulseCommands(this);
2722                 if (game_stopped)
2723                 {
2724                         CSQCMODEL_AUTOUPDATE(this);
2725                         return;
2726                 }
2727                 GetPressedKeys(this);
2728         }
2729
2730         if (this.waypointsprite_attachedforcarrier) {
2731             vector v = healtharmor_maxdamage(this.health, this.armorvalue, autocvar_g_balance_armor_blockpercent, DEATH_WEAPON.m_id);
2732                 WaypointSprite_UpdateHealth(this.waypointsprite_attachedforcarrier, '1 0 0' * v);
2733     }
2734
2735         playerdemo_write(this);
2736
2737         CSQCMODEL_AUTOUPDATE(this);
2738 }