qcsrc/server/client.qc

   1 #include "client.qh"
   2
   3 #include <server/defs.qh>
   4 #include <server/miscfunctions.qh>
   5 #include <common/effects/all.qh>
   6 #include "anticheat.qh"
   7 #include "impulse.qh"
   8 #include "player.qh"
   9 #include "ipban.qh"
  10 #include "miscfunctions.qh"
  11 #include "portals.qh"
  12 #include "teamplay.qh"
  13 #include "playerdemo.qh"
  14 #include "spawnpoints.qh"
  15 #include "resources.qh"
  16 #include "g_damage.qh"
  17 #include "handicap.qh"
  18 #include "g_hook.qh"
  19 #include "command/common.qh"
  20 #include "cheats.qh"
  21 #include "g_world.qh"
  22 #include "race.qh"
  23 #include "antilag.qh"
  24 #include "campaign.qh"
  25 #include "command/common.qh"
  26 #include "scores_rules.qh"
  27
  28 #include "bot/api.qh"
  29
  30 #include "../common/ent_cs.qh"
  31 #include "../common/wepent.qh"
  32 #include <common/state.qh>
  33
  34 #include <common/effects/qc/globalsound.qh>
  35
  36 #include "../common/triggers/func/conveyor.qh"
  37 #include "../common/triggers/teleporters.qh"
  38 #include "../common/triggers/target/spawnpoint.qh"
  39
  40 #include "../common/vehicles/all.qh"
  41
  42 #include "weapons/hitplot.qh"
  43 #include "weapons/weaponsystem.qh"
  44
  45 #include "../common/net_notice.qh"
  46 #include "../common/net_linked.qh"
  47 #include "../common/physics/player.qh"
  48
  49 #include "../common/items/_mod.qh"
  50
  51 #include "../common/mutators/mutator/waypoints/all.qh"
  52
  53 #include "../common/triggers/subs.qh"
  54 #include "../common/triggers/triggers.qh"
  55 #include "../common/triggers/trigger/secret.qh"
  56
  57 #include "../common/minigames/sv_minigames.qh"
  58
  59 #include "../common/items/inventory.qh"
  60
  61 #include "../common/monsters/sv_monsters.qh"
  62
  63 #include "../lib/warpzone/server.qh"
  64
  65 #include <common/mutators/mutator/overkill/oknex.qh>
  66
  67 STATIC_METHOD(Client, Add, void(Client this, int _team))
  68 {
  69     ClientConnect(this);
  70     TRANSMUTE(Player, this);
  71     this.frame = 12; // 7
  72     this.team = _team;
  73     PutClientInServer(this);
  74 }
  75
  76 void PutObserverInServer(entity this);
  77
  78 STATIC_METHOD(Client, Remove, void(Client this))
  79 {
  80     TRANSMUTE(Observer, this);
  81     PutClientInServer(this);
  82     ClientDisconnect(this);
  83 }
  84
  85 void send_CSQC_teamnagger() {
  86         WriteHeader(MSG_BROADCAST, TE_CSQC_TEAMNAGGER);
  87 }
  88
  89 int CountSpectators(entity player, entity to)
  90 {
  91         if(!player) { return 0; } // not sure how, but best to be safe
  92
  93         int spec_count = 0;
  94
  95         FOREACH_CLIENT(IS_REAL_CLIENT(it) && IS_SPEC(it) && it != to && it.enemy == player,
  96         {
  97                 spec_count++;
  98         });
  99
 100         return spec_count;
 101 }
 102
 103 void WriteSpectators(entity player, entity to)
 104 {
 105         if(!player) { return; } // not sure how, but best to be safe
 106
 107         FOREACH_CLIENT(IS_REAL_CLIENT(it) && IS_SPEC(it) && it != to && it.enemy == player,
 108         {
 109                 WriteByte(MSG_ENTITY, num_for_edict(it));
 110         });
 111 }
 112
 113 bool ClientData_Send(entity this, entity to, int sf)
 114 {
 115         assert(to == this.owner, return false);
 116
 117         entity e = to;
 118         if (IS_SPEC(e)) e = e.enemy;
 119
 120         sf = 0;
 121         if (CS(e).race_completed)       sf |= BIT(0); // forced scoreboard
 122         if (CS(to).spectatee_status)    sf |= BIT(1); // spectator ent number follows
 123         if (CS(e).zoomstate)            sf |= BIT(2); // zoomed
 124         if (autocvar_sv_showspectators) sf |= BIT(4); // show spectators
 125
 126         WriteHeader(MSG_ENTITY, ENT_CLIENT_CLIENTDATA);
 127         WriteByte(MSG_ENTITY, sf);
 128
 129         if (sf & BIT(1))
 130                 WriteByte(MSG_ENTITY, CS(to).spectatee_status);
 131
 132         if(sf & BIT(4))
 133         {
 134                 float specs = CountSpectators(e, to);
 135                 WriteByte(MSG_ENTITY, specs);
 136                 WriteSpectators(e, to);
 137         }
 138
 139         return true;
 140 }
 141
 142 void ClientData_Attach(entity this)
 143 {
 144         Net_LinkEntity(CS(this).clientdata = new_pure(clientdata), false, 0, ClientData_Send);
 145         CS(this).clientdata.drawonlytoclient = this;
 146         CS(this).clientdata.owner = this;
 147 }
 148
 149 void ClientData_Detach(entity this)
 150 {
 151         delete(CS(this).clientdata);
 152         CS(this).clientdata = NULL;
 153 }
 154
 155 void ClientData_Touch(entity e)
 156 {
 157         entity cd = CS(e).clientdata;
 158         if (cd) { cd.SendFlags = 1; }
 159
 160         // make it spectatable
 161         FOREACH_CLIENT(IS_REAL_CLIENT(it) && it != e && IS_SPEC(it) && it.enemy == e,
 162         {
 163                 entity cd = CS(it).clientdata;
 164                 if (cd) { cd.SendFlags = 1; }
 165         });
 166 }
 167
 168 void SetSpectatee(entity this, entity spectatee);
 169 void SetSpectatee_status(entity this, int spectatee_num);
 170
 171
 172 /*
 173 =============
 174 CheckPlayerModel
 175
 176 Checks if the argument string can be a valid playermodel.
 177 Returns a valid one in doubt.
 178 =============
 179 */
 180 string FallbackPlayerModel;
 181 string CheckPlayerModel(string plyermodel) {
 182         if(FallbackPlayerModel != cvar_defstring("_cl_playermodel"))
 183         {
 184                 // note: we cannot summon Don Strunzone here, some player may
 185                 // still have the model string set. In case anyone manages how
 186                 // to change a cvar default, we'll have a small leak here.
 187                 FallbackPlayerModel = strzone(cvar_defstring("_cl_playermodel"));
 188         }
 189         // only in right path
 190         if( substring(plyermodel,0,14) != "models/player/")
 191                 return FallbackPlayerModel;
 192         // only good file extensions
 193         if(substring(plyermodel,-4,4) != ".zym")
 194         if(substring(plyermodel,-4,4) != ".dpm")
 195         if(substring(plyermodel,-4,4) != ".iqm")
 196         if(substring(plyermodel,-4,4) != ".md3")
 197         if(substring(plyermodel,-4,4) != ".psk")
 198                 return FallbackPlayerModel;
 199         // forbid the LOD models
 200         if(substring(plyermodel, -9,5) == "_lod1")
 201                 return FallbackPlayerModel;
 202         if(substring(plyermodel, -9,5) == "_lod2")
 203                 return FallbackPlayerModel;
 204         if(plyermodel != strtolower(plyermodel))
 205                 return FallbackPlayerModel;
 206         // also, restrict to server models
 207         if(autocvar_sv_servermodelsonly)
 208         {
 209                 if(!fexists(plyermodel))
 210                         return FallbackPlayerModel;
 211         }
 212         return plyermodel;
 213 }
 214
 215 void setplayermodel(entity e, string modelname)
 216 {
 217         precache_model(modelname);
 218         _setmodel(e, modelname);
 219         player_setupanimsformodel(e);
 220         if(!autocvar_g_debug_globalsounds)
 221                 UpdatePlayerSounds(e);
 222 }
 223
 224 void FixPlayermodel(entity player);
 225 /** putting a client as observer in the server */
 226 void PutObserverInServer(entity this)
 227 {
 228     bool mutator_returnvalue = MUTATOR_CALLHOOK(MakePlayerObserver, this);
 229         PlayerState_detach(this);
 230
 231         if (IS_PLAYER(this))
 232         {
 233                 if(this.health >= 1)
 234                 {
 235                         // despawn effect
 236                         Send_Effect(EFFECT_SPAWN_NEUTRAL, this.origin, '0 0 0', 1);
 237                 }
 238
 239                 // was a player, recount votes and ready status
 240                 if(IS_REAL_CLIENT(this))
 241                 {
 242                         if (vote_called) { VoteCount(false); }
 243                         ReadyCount();
 244                 }
 245     }
 246
 247     {
 248         entity spot = SelectSpawnPoint(this, true);
 249         if (!spot) LOG_FATAL("No spawnpoints for observers?!?");
 250         this.angles = vec2(spot.angles);
 251         this.fixangle = true;
 252         // offset it so that the spectator spawns higher off the ground, looks better this way
 253         setorigin(this, spot.origin + STAT(PL_VIEW_OFS, this));
 254         if (IS_REAL_CLIENT(this))
 255         {
 256             msg_entity = this;
 257             WriteByte(MSG_ONE, SVC_SETVIEW);
 258             WriteEntity(MSG_ONE, this);
 259         }
 260         // give the spectator some space between walls for MOVETYPE_FLY_WORLDONLY
 261         // so that your view doesn't go into the ceiling with MOVETYPE_FLY_WORLDONLY, previously "PL_VIEW_OFS"
 262         if(!autocvar_g_debug_globalsounds)
 263         {
 264                 // needed for player sounds
 265                 this.model = "";
 266                 FixPlayermodel(this);
 267         }
 268         setmodel(this, MDL_Null);
 269         setsize(this, STAT(PL_CROUCH_MIN, this), STAT(PL_CROUCH_MAX, this));
 270         this.view_ofs = '0 0 0';
 271     }
 272
 273     RemoveGrapplingHooks(this);
 274         Portal_ClearAll(this);
 275         Unfreeze(this);
 276         SetSpectatee(this, NULL);
 277
 278         if (this.alivetime)
 279         {
 280                 if (!warmup_stage)
 281                         PlayerStats_GameReport_Event_Player(this, PLAYERSTATS_ALIVETIME, time - this.alivetime);
 282                 this.alivetime = 0;
 283         }
 284
 285         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
 286
 287         WaypointSprite_PlayerDead(this);
 288
 289         if (mutator_returnvalue) {
 290             // mutator prevents resetting teams+score
 291         } else {
 292                 int oldteam = this.team;
 293                 this.team = -1;  // move this as it is needed to log the player spectating in eventlog
 294                 MUTATOR_CALLHOOK(Player_ChangedTeam, this, oldteam, this.team);
 295         this.frags = FRAGS_SPECTATOR;
 296         PlayerScore_Clear(this);  // clear scores when needed
 297     }
 298
 299         if (CS(this).killcount != FRAGS_SPECTATOR)
 300         {
 301                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_QUIT_SPECTATE, this.netname);
 302                 if(!game_stopped)
 303                 if(autocvar_g_chat_nospectators == 1 || (!warmup_stage && autocvar_g_chat_nospectators == 2))
 304                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_CHAT_NOSPECTATORS);
 305
 306                 if(!CS(this).just_joined)
 307                         LogTeamchange(this.playerid, -1, 4);
 308                 else
 309                         CS(this).just_joined = false;
 310         }
 311
 312         accuracy_resend(this);
 313
 314         CS(this).spectatortime = time;
 315         if(this.bot_attack)
 316                 IL_REMOVE(g_bot_targets, this);
 317         this.bot_attack = false;
 318         if(this.monster_attack)
 319                 IL_REMOVE(g_monster_targets, this);
 320         this.monster_attack = false;
 321     STAT(HUD, this) = HUD_NORMAL;
 322         TRANSMUTE(Observer, this);
 323         this.iscreature = false;
 324         this.teleportable = TELEPORT_SIMPLE;
 325         if(this.damagedbycontents)
 326                 IL_REMOVE(g_damagedbycontents, this);
 327         this.damagedbycontents = false;
 328         this.health = FRAGS_SPECTATOR;
 329         SetSpectatee_status(this, etof(this));
 330         this.takedamage = DAMAGE_NO;
 331         this.solid = SOLID_NOT;
 332         set_movetype(this, MOVETYPE_FLY_WORLDONLY); // user preference is controlled by playerprethink
 333         this.flags = FL_CLIENT | FL_NOTARGET;
 334         this.armorvalue = 666;
 335         this.effects = 0;
 336         this.armorvalue = autocvar_g_balance_armor_start;
 337         this.pauserotarmor_finished = 0;
 338         this.pauserothealth_finished = 0;
 339         this.pauseregen_finished = 0;
 340         this.damageforcescale = 0;
 341         this.death_time = 0;
 342         this.respawn_flags = 0;
 343         this.respawn_time = 0;
 344         STAT(RESPAWN_TIME, this) = 0;
 345         this.alpha = 0;
 346         this.scale = 0;
 347         this.fade_time = 0;
 348         this.pain_frame = 0;
 349         this.pain_finished = 0;
 350         this.strength_finished = 0;
 351         this.invincible_finished = 0;
 352         this.superweapons_finished = 0;
 353         this.dphitcontentsmask = 0;
 354         this.pushltime = 0;
 355         this.istypefrag = 0;
 356         setthink(this, func_null);
 357         this.nextthink = 0;
 358         this.deadflag = DEAD_NO;
 359         this.crouch = false;
 360         STAT(REVIVE_PROGRESS, this) = 0;
 361         this.revival_time = 0;
 362
 363         this.items = 0;
 364         this.weapons = '0 0 0';
 365         this.drawonlytoclient = this;
 366
 367         this.viewloc = NULL;
 368
 369         //this.spawnpoint_targ = NULL; // keep it so they can return to where they were?
 370
 371         this.weaponmodel = "";
 372         for (int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 373         {
 374                 this.weaponentities[slot] = NULL;
 375         }
 376         this.exteriorweaponentity = NULL;
 377         CS(this).killcount = FRAGS_SPECTATOR;
 378         this.velocity = '0 0 0';
 379         this.avelocity = '0 0 0';
 380         this.punchangle = '0 0 0';
 381         this.punchvector = '0 0 0';
 382         this.oldvelocity = this.velocity;
 383         this.fire_endtime = -1;
 384         this.event_damage = func_null;
 385
 386         for(int slot = 0; slot < MAX_AXH; ++slot)
 387         {
 388                 entity axh = this.(AuxiliaryXhair[slot]);
 389                 this.(AuxiliaryXhair[slot]) = NULL;
 390
 391                 if(axh.owner == this && axh != NULL && !wasfreed(axh))
 392                         delete(axh);
 393         }
 394 }
 395
 396 int player_getspecies(entity this)
 397 {
 398         get_model_parameters(this.model, this.skin);
 399         int s = get_model_parameters_species;
 400         get_model_parameters(string_null, 0);
 401         if (s < 0) return SPECIES_HUMAN;
 402         return s;
 403 }
 404
 405 .float model_randomizer;
 406 void FixPlayermodel(entity player)
 407 {
 408         string defaultmodel = "";
 409         int defaultskin = 0;
 410         if(autocvar_sv_defaultcharacter)
 411         {
 412                 if(teamplay)
 413                 {
 414                         switch(player.team)
 415                         {
 416                                 case NUM_TEAM_1: defaultmodel = autocvar_sv_defaultplayermodel_red; defaultskin = autocvar_sv_defaultplayerskin_red; break;
 417                                 case NUM_TEAM_2: defaultmodel = autocvar_sv_defaultplayermodel_blue; defaultskin = autocvar_sv_defaultplayerskin_blue; break;
 418                                 case NUM_TEAM_3: defaultmodel = autocvar_sv_defaultplayermodel_yellow; defaultskin = autocvar_sv_defaultplayerskin_yellow; break;
 419                                 case NUM_TEAM_4: defaultmodel = autocvar_sv_defaultplayermodel_pink; defaultskin = autocvar_sv_defaultplayerskin_pink; break;
 420                         }
 421                 }
 422
 423                 if(defaultmodel == "")
 424                 {
 425                         defaultmodel = autocvar_sv_defaultplayermodel;
 426                         defaultskin = autocvar_sv_defaultplayerskin;
 427                 }
 428
 429                 int n = tokenize_console(defaultmodel);
 430                 if(n > 0)
 431                 {
 432                         defaultmodel = argv(floor(n * CS(player).model_randomizer));
 433                         // However, do NOT randomize if the player-selected model is in the list.
 434                         for (int i = 0; i < n; ++i)
 435                                 if ((argv(i) == player.playermodel && defaultskin == stof(player.playerskin)) || argv(i) == strcat(player.playermodel, ":", player.playerskin))
 436                                         defaultmodel = argv(i);
 437                 }
 438
 439                 int i = strstrofs(defaultmodel, ":", 0);
 440                 if(i >= 0)
 441                 {
 442                         defaultskin = stof(substring(defaultmodel, i+1, -1));
 443                         defaultmodel = substring(defaultmodel, 0, i);
 444                 }
 445         }
 446         if(autocvar_sv_defaultcharacterskin && !defaultskin)
 447         {
 448                 if(teamplay)
 449                 {
 450                         switch(player.team)
 451                         {
 452                                 case NUM_TEAM_1: defaultskin = autocvar_sv_defaultplayerskin_red; break;
 453                                 case NUM_TEAM_2: defaultskin = autocvar_sv_defaultplayerskin_blue; break;
 454                                 case NUM_TEAM_3: defaultskin = autocvar_sv_defaultplayerskin_yellow; break;
 455                                 case NUM_TEAM_4: defaultskin = autocvar_sv_defaultplayerskin_pink; break;
 456                         }
 457                 }
 458
 459                 if(!defaultskin)
 460                         defaultskin = autocvar_sv_defaultplayerskin;
 461         }
 462
 463         MUTATOR_CALLHOOK(FixPlayermodel, defaultmodel, defaultskin, player);
 464         defaultmodel = M_ARGV(0, string);
 465         defaultskin = M_ARGV(1, int);
 466
 467         bool chmdl = false;
 468         int oldskin;
 469         if(defaultmodel != "")
 470         {
 471                 if (defaultmodel != player.model)
 472                 {
 473                         vector m1 = player.mins;
 474                         vector m2 = player.maxs;
 475                         setplayermodel (player, defaultmodel);
 476                         setsize (player, m1, m2);
 477                         chmdl = true;
 478                 }
 479
 480                 oldskin = player.skin;
 481                 player.skin = defaultskin;
 482         } else {
 483                 if (player.playermodel != player.model || player.playermodel == "")
 484                 {
 485                         player.playermodel = CheckPlayerModel(player.playermodel); // this is never "", so no endless loop
 486                         vector m1 = player.mins;
 487                         vector m2 = player.maxs;
 488                         setplayermodel (player, player.playermodel);
 489                         setsize (player, m1, m2);
 490                         chmdl = true;
 491                 }
 492
 493                 if(!autocvar_sv_defaultcharacterskin)
 494                 {
 495                         oldskin = player.skin;
 496                         player.skin = stof(player.playerskin);
 497                 }
 498                 else
 499                 {
 500                         oldskin = player.skin;
 501                         player.skin = defaultskin;
 502                 }
 503         }
 504
 505         if(chmdl || oldskin != player.skin) // model or skin has changed
 506         {
 507                 player.species = player_getspecies(player); // update species
 508                 if(!autocvar_g_debug_globalsounds)
 509                         UpdatePlayerSounds(player); // update skin sounds
 510         }
 511
 512         if(!teamplay)
 513                 if(strlen(autocvar_sv_defaultplayercolors))
 514                         if(player.clientcolors != stof(autocvar_sv_defaultplayercolors))
 515                                 setcolor(player, stof(autocvar_sv_defaultplayercolors));
 516 }
 517
 518 void PutPlayerInServer(entity this)
 519 {
 520         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
 521
 522         PlayerState_attach(this);
 523         accuracy_resend(this);
 524
 525         if (this.team < 0)
 526                 JoinBestTeam(this, true);
 527
 528         entity spot = SelectSpawnPoint(this, false);
 529         if (!spot) {
 530                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_JOIN_NOSPAWNS);
 531                 return; // spawn failed
 532         }
 533
 534         TRANSMUTE(Player, this);
 535
 536         CS(this).wasplayer = true;
 537         this.iscreature = true;
 538         this.teleportable = TELEPORT_NORMAL;
 539         if(!this.damagedbycontents)
 540                 IL_PUSH(g_damagedbycontents, this);
 541         this.damagedbycontents = true;
 542         set_movetype(this, MOVETYPE_WALK);
 543         this.solid = SOLID_SLIDEBOX;
 544         this.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_SOLID;
 545         if (autocvar_g_playerclip_collisions)
 546                 this.dphitcontentsmask |= DPCONTENTS_PLAYERCLIP;
 547         if (IS_BOT_CLIENT(this) && autocvar_g_botclip_collisions)
 548                 this.dphitcontentsmask |= DPCONTENTS_BOTCLIP;
 549         this.frags = FRAGS_PLAYER;
 550         if (INDEPENDENT_PLAYERS) MAKE_INDEPENDENT_PLAYER(this);
 551         this.flags = FL_CLIENT | FL_PICKUPITEMS;
 552         if (autocvar__notarget)
 553                 this.flags |= FL_NOTARGET;
 554         this.takedamage = DAMAGE_AIM;
 555         this.effects = EF_TELEPORT_BIT | EF_RESTARTANIM_BIT;
 556
 557         if (warmup_stage) {
 558                 this.ammo_shells = warmup_start_ammo_shells;
 559                 this.ammo_nails = warmup_start_ammo_nails;
 560                 this.ammo_rockets = warmup_start_ammo_rockets;
 561                 this.ammo_cells = warmup_start_ammo_cells;
 562                 this.ammo_plasma = warmup_start_ammo_plasma;
 563                 this.ammo_fuel = warmup_start_ammo_fuel;
 564                 this.health = warmup_start_health;
 565                 this.armorvalue = warmup_start_armorvalue;
 566                 this.weapons = WARMUP_START_WEAPONS;
 567         } else {
 568                 this.ammo_shells = start_ammo_shells;
 569                 this.ammo_nails = start_ammo_nails;
 570                 this.ammo_rockets = start_ammo_rockets;
 571                 this.ammo_cells = start_ammo_cells;
 572                 this.ammo_plasma = start_ammo_plasma;
 573                 this.ammo_fuel = start_ammo_fuel;
 574                 this.health = start_health;
 575                 this.armorvalue = start_armorvalue;
 576                 this.weapons = start_weapons;
 577                 if (MUTATOR_CALLHOOK(ForbidRandomStartWeapons, this) == false)
 578                 {
 579                         GiveRandomWeapons(this, random_start_weapons_count,
 580                                 autocvar_g_random_start_weapons, random_start_ammo);
 581                 }
 582         }
 583         SetSpectatee_status(this, 0);
 584
 585         PS(this).dual_weapons = '0 0 0';
 586
 587         this.superweapons_finished = (this.weapons & WEPSET_SUPERWEAPONS) ? time + autocvar_g_balance_superweapons_time : 0;
 588
 589         this.items = start_items;
 590
 591         this.spawnshieldtime = time + autocvar_g_spawnshieldtime;
 592         this.pauserotarmor_finished = time + autocvar_g_balance_pause_armor_rot_spawn;
 593         this.pauserothealth_finished = time + autocvar_g_balance_pause_health_rot_spawn;
 594         this.pauserotfuel_finished = time + autocvar_g_balance_pause_fuel_rot_spawn;
 595         this.pauseregen_finished = time + autocvar_g_balance_pause_health_regen_spawn;
 596         if (!sv_ready_restart_after_countdown && time < game_starttime)
 597         {
 598                 float f = game_starttime - time;
 599                 this.spawnshieldtime += f;
 600                 this.pauserotarmor_finished += f;
 601                 this.pauserothealth_finished += f;
 602                 this.pauseregen_finished += f;
 603         }
 604
 605         this.damageforcescale = 2;
 606         this.death_time = 0;
 607         this.respawn_flags = 0;
 608         this.respawn_time = 0;
 609         STAT(RESPAWN_TIME, this) = 0;
 610         this.scale = autocvar_sv_player_scale;
 611         this.fade_time = 0;
 612         this.pain_frame = 0;
 613         this.pain_finished = 0;
 614         this.pushltime = 0;
 615         setthink(this, func_null); // players have no think function
 616         this.nextthink = 0;
 617         this.dmg_team = 0;
 618         PS(this).ballistics_density = autocvar_g_ballistics_density_player;
 619
 620         this.deadflag = DEAD_NO;
 621
 622         this.angles = spot.angles;
 623         this.angles_z = 0; // never spawn tilted even if the spot says to
 624         if (IS_BOT_CLIENT(this))
 625                 this.v_angle = this.angles;
 626         this.fixangle = true; // turn this way immediately
 627         this.oldvelocity = this.velocity = '0 0 0';
 628         this.avelocity = '0 0 0';
 629         this.punchangle = '0 0 0';
 630         this.punchvector = '0 0 0';
 631
 632         this.strength_finished = 0;
 633         this.invincible_finished = 0;
 634         this.fire_endtime = -1;
 635         STAT(REVIVE_PROGRESS, this) = 0;
 636         this.revival_time = 0;
 637
 638         this.air_finished = time + 12;
 639         this.waterlevel = WATERLEVEL_NONE;
 640         this.watertype = CONTENT_EMPTY;
 641
 642         entity spawnevent = new_pure(spawnevent);
 643         spawnevent.owner = this;
 644         Net_LinkEntity(spawnevent, false, 0.5, SpawnEvent_Send);
 645
 646         // Cut off any still running player sounds.
 647         stopsound(this, CH_PLAYER_SINGLE);
 648
 649         this.model = "";
 650         FixPlayermodel(this);
 651         this.drawonlytoclient = NULL;
 652
 653         this.viewloc = NULL;
 654
 655         for(int slot = 0; slot < MAX_AXH; ++slot)
 656         {
 657                 entity axh = this.(AuxiliaryXhair[slot]);
 658                 this.(AuxiliaryXhair[slot]) = NULL;
 659
 660                 if(axh.owner == this && axh != NULL && !wasfreed(axh))
 661                         delete(axh);
 662         }
 663
 664         this.spawnpoint_targ = NULL;
 665
 666         this.crouch = false;
 667         this.view_ofs = STAT(PL_VIEW_OFS, this);
 668         setsize(this, STAT(PL_MIN, this), STAT(PL_MAX, this));
 669         this.spawnorigin = spot.origin;
 670         setorigin(this, spot.origin + '0 0 1' * (1 - this.mins.z - 24));
 671         // don't reset back to last position, even if new position is stuck in solid
 672         this.oldorigin = this.origin;
 673         if(this.conveyor)
 674                 IL_REMOVE(g_conveyed, this);
 675         this.conveyor = NULL; // prevent conveyors at the previous location from moving a freshly spawned player
 676         STAT(HUD, this) = HUD_NORMAL;
 677
 678         this.event_damage = PlayerDamage;
 679
 680         if(!this.bot_attack)
 681                 IL_PUSH(g_bot_targets, this);
 682         this.bot_attack = true;
 683         if(!this.monster_attack)
 684                 IL_PUSH(g_monster_targets, this);
 685         this.monster_attack = true;
 686         navigation_dynamicgoal_init(this, false);
 687
 688         PHYS_INPUT_BUTTON_ATCK(this) = PHYS_INPUT_BUTTON_JUMP(this) = PHYS_INPUT_BUTTON_ATCK2(this) = false;
 689
 690         // player was spectator
 691         if (CS(this).killcount == FRAGS_SPECTATOR) {
 692                 PlayerScore_Clear(this);
 693                 CS(this).killcount = 0;
 694                 CS(this).startplaytime = time;
 695         }
 696
 697         for (int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 698         {
 699                 .entity weaponentity = weaponentities[slot];
 700                 entity oldwep = this.(weaponentity);
 701                 CL_SpawnWeaponentity(this, weaponentity);
 702                 if(oldwep && oldwep.owner == this)
 703                         this.(weaponentity).m_gunalign = oldwep.m_gunalign;
 704         }
 705         this.alpha = default_player_alpha;
 706         this.colormod = '1 1 1' * autocvar_g_player_brightness;
 707         this.exteriorweaponentity.alpha = default_weapon_alpha;
 708
 709         this.speedrunning = false;
 710
 711         target_voicescript_clear(this);
 712
 713         // reset fields the weapons may use
 714         FOREACH(Weapons, true, {
 715                 it.wr_resetplayer(it, this);
 716                         // reload all reloadable weapons
 717                 if (it.spawnflags & WEP_FLAG_RELOADABLE) {
 718                         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 719                         {
 720                                 .entity weaponentity = weaponentities[slot];
 721                                 this.(weaponentity).weapon_load[it.m_id] = it.reloading_ammo;
 722                         }
 723                 }
 724         });
 725
 726         {
 727                 string s = spot.target;
 728                 spot.target = string_null;
 729                 SUB_UseTargets(spot, this, NULL);
 730                 spot.target = s;
 731         }
 732
 733         Unfreeze(this);
 734
 735         MUTATOR_CALLHOOK(PlayerSpawn, this, spot);
 736
 737         if (autocvar_spawn_debug)
 738         {
 739                 sprint(this, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
 740                 delete(spot); // usefull for checking if there are spawnpoints, that let drop through the floor
 741         }
 742
 743         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 744         {
 745                 .entity weaponentity = weaponentities[slot];
 746                 if(slot == 0 || autocvar_g_weaponswitch_debug == 1)
 747                         this.(weaponentity).m_switchweapon = w_getbestweapon(this, weaponentity);
 748                 else
 749                         this.(weaponentity).m_switchweapon = WEP_Null;
 750                 this.(weaponentity).m_weapon = WEP_Null;
 751                 this.(weaponentity).weaponname = "";
 752                 this.(weaponentity).m_switchingweapon = WEP_Null;
 753                 this.(weaponentity).cnt = -1;
 754         }
 755
 756         MUTATOR_CALLHOOK(PlayerWeaponSelect, this);
 757
 758         if (!warmup_stage && !this.alivetime)
 759                 this.alivetime = time;
 760
 761         antilag_clear(this, CS(this));
 762 }
 763
 764 /** Called when a client spawns in the server */
 765 void PutClientInServer(entity this)
 766 {
 767         if (IS_BOT_CLIENT(this)) {
 768                 TRANSMUTE(Player, this);
 769         } else if (IS_REAL_CLIENT(this)) {
 770                 msg_entity = this;
 771                 WriteByte(MSG_ONE, SVC_SETVIEW);
 772                 WriteEntity(MSG_ONE, this);
 773         }
 774         if (game_stopped)
 775                 TRANSMUTE(Observer, this);
 776
 777         SetSpectatee(this, NULL);
 778
 779         // reset player keys
 780         if(PS(this))
 781                 PS(this).itemkeys = 0;
 782
 783         MUTATOR_CALLHOOK(PutClientInServer, this);
 784
 785         if (IS_OBSERVER(this)) {
 786                 PutObserverInServer(this);
 787         } else if (IS_PLAYER(this)) {
 788                 PutPlayerInServer(this);
 789         }
 790 }
 791
 792 void ClientInit_misc(entity this);
 793
 794 // TODO do we need all these fields, or should we stop autodetecting runtime
 795 // changes and just have a console command to update this?
 796 bool ClientInit_SendEntity(entity this, entity to, int sf)
 797 {
 798         WriteHeader(MSG_ENTITY, _ENT_CLIENT_INIT);
 799         return = true;
 800         msg_entity = to;
 801         // MSG_INIT replacement
 802         // TODO: make easier to use
 803         Registry_send_all();
 804         W_PROP_reload(MSG_ONE, to);
 805         ClientInit_misc(this);
 806         MUTATOR_CALLHOOK(Ent_Init);
 807 }
 808 void ClientInit_misc(entity this)
 809 {
 810         int channel = MSG_ONE;
 811         WriteHeader(channel, ENT_CLIENT_INIT);
 812         WriteByte(channel, g_nexball_meter_period * 32);
 813         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[0]));
 814         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[1]));
 815         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[2]));
 816         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[3]));
 817         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[0]));
 818         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[1]));
 819         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[2]));
 820         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[3]));
 821
 822         if(sv_foginterval && world.fog != "")
 823                 WriteString(channel, world.fog);
 824         else
 825                 WriteString(channel, "");
 826         WriteByte(channel, this.count * 255.0); // g_balance_armor_blockpercent
 827         WriteByte(channel, this.cnt * 255.0); // g_balance_damagepush_speedfactor
 828         WriteByte(channel, serverflags);
 829         WriteCoord(channel, autocvar_g_trueaim_minrange);
 830 }
 831
 832 void ClientInit_CheckUpdate(entity this)
 833 {
 834         this.nextthink = time;
 835         if(this.count != autocvar_g_balance_armor_blockpercent)
 836         {
 837                 this.count = autocvar_g_balance_armor_blockpercent;
 838                 this.SendFlags |= 1;
 839         }
 840         if(this.cnt != autocvar_g_balance_damagepush_speedfactor)
 841         {
 842                 this.cnt = autocvar_g_balance_damagepush_speedfactor;
 843                 this.SendFlags |= 1;
 844         }
 845 }
 846
 847 void ClientInit_Spawn()
 848 {
 849         entity e = new_pure(clientinit);
 850         setthink(e, ClientInit_CheckUpdate);
 851         Net_LinkEntity(e, false, 0, ClientInit_SendEntity);
 852
 853         ClientInit_CheckUpdate(e);
 854 }
 855
 856 /*
 857 =============
 858 SetNewParms
 859 =============
 860 */
 861 void SetNewParms ()
 862 {
 863         // initialize parms for a new player
 864         parm1 = -(86400 * 366);
 865
 866         MUTATOR_CALLHOOK(SetNewParms);
 867 }
 868
 869 /*
 870 =============
 871 SetChangeParms
 872 =============
 873 */
 874 void SetChangeParms (entity this)
 875 {
 876         // save parms for level change
 877         parm1 = CS(this).parm_idlesince - time;
 878
 879         MUTATOR_CALLHOOK(SetChangeParms);
 880 }
 881
 882 /*
 883 =============
 884 DecodeLevelParms
 885 =============
 886 */
 887 void DecodeLevelParms(entity this)
 888 {
 889         // load parms
 890         CS(this).parm_idlesince = parm1;
 891         if (CS(this).parm_idlesince == -(86400 * 366))
 892                 CS(this).parm_idlesince = time;
 893
 894         // whatever happens, allow 60 seconds of idling directly after connect for map loading
 895         CS(this).parm_idlesince = max(CS(this).parm_idlesince, time - sv_maxidle + 60);
 896
 897         MUTATOR_CALLHOOK(DecodeLevelParms);
 898 }
 899
 900 /*
 901 =============
 902 ClientKill
 903
 904 Called when a client types 'kill' in the console
 905 =============
 906 */
 907
 908 .float clientkill_nexttime;
 909 void ClientKill_Now_TeamChange(entity this)
 910 {
 911         if(this.killindicator_teamchange == -1)
 912         {
 913                 JoinBestTeam( this, true );
 914         }
 915         else if(this.killindicator_teamchange == -2)
 916         {
 917                 if(blockSpectators)
 918                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
 919                 PutObserverInServer(this);
 920         }
 921         else
 922                 SV_ChangeTeam(this, this.killindicator_teamchange - 1);
 923         this.killindicator_teamchange = 0;
 924 }
 925
 926 void ClientKill_Now(entity this)
 927 {
 928         if(this.vehicle)
 929         {
 930             vehicles_exit(this.vehicle, VHEF_RELEASE);
 931             if(!this.killindicator_teamchange)
 932             {
 933             this.vehicle_health = -1;
 934             Damage(this, this, this, 1 , DEATH_KILL.m_id, DMG_NOWEP, this.origin, '0 0 0');
 935             }
 936         }
 937
 938         if(this.killindicator && !wasfreed(this.killindicator))
 939                 delete(this.killindicator);
 940
 941         this.killindicator = NULL;
 942
 943         if(this.killindicator_teamchange)
 944                 ClientKill_Now_TeamChange(this);
 945
 946         if (!IS_SPEC(this) && !IS_OBSERVER(this) && MUTATOR_CALLHOOK(ClientKill_Now, this) == false)
 947         {
 948                 Damage(this, this, this, 100000, DEATH_KILL.m_id, DMG_NOWEP, this.origin, '0 0 0');
 949         }
 950
 951         // now I am sure the player IS dead
 952 }
 953 void KillIndicator_Think(entity this)
 954 {
 955         if (game_stopped)
 956         {
 957                 this.owner.killindicator = NULL;
 958                 delete(this);
 959                 return;
 960         }
 961
 962         if (this.owner.alpha < 0 && !this.owner.vehicle)
 963         {
 964                 this.owner.killindicator = NULL;
 965                 delete(this);
 966                 return;
 967         }
 968
 969         if(this.cnt <= 0)
 970         {
 971                 ClientKill_Now(this.owner);
 972                 return;
 973         }
 974     else if(this.health == 1) // health == 1 means that it's silent
 975     {
 976         this.nextthink = time + 1;
 977         this.cnt -= 1;
 978     }
 979         else
 980         {
 981                 if(this.cnt <= 10)
 982                         setmodel(this, MDL_NUM(this.cnt));
 983                 if(IS_REAL_CLIENT(this.owner))
 984                 {
 985                         if(this.cnt <= 10)
 986                                 { Send_Notification(NOTIF_ONE, this.owner, MSG_ANNCE, Announcer_PickNumber(CNT_KILL, this.cnt)); }
 987                 }
 988                 this.nextthink = time + 1;
 989                 this.cnt -= 1;
 990         }
 991 }
 992
 993 float clientkilltime;
 994 void ClientKill_TeamChange (entity this, float targetteam) // 0 = don't change, -1 = auto, -2 = spec
 995 {
 996         float killtime;
 997         float starttime;
 998
 999         if (game_stopped)
1000                 return;
1001
1002         killtime = autocvar_g_balance_kill_delay;
1003
1004     if(MUTATOR_CALLHOOK(ClientKill, this, killtime))
1005         return;
1006     killtime = M_ARGV(1, float);
1007
1008         this.killindicator_teamchange = targetteam;
1009
1010     if(!this.killindicator)
1011         {
1012                 if(!IS_DEAD(this))
1013                 {
1014                         killtime = max(killtime, this.clientkill_nexttime - time);
1015                         this.clientkill_nexttime = time + killtime + autocvar_g_balance_kill_antispam;
1016                 }
1017
1018                 if(killtime <= 0 || !IS_PLAYER(this) || IS_DEAD(this))
1019                 {
1020                         ClientKill_Now(this);
1021                 }
1022                 else
1023                 {
1024                         starttime = max(time, clientkilltime);
1025
1026                         this.killindicator = spawn();
1027                         this.killindicator.owner = this;
1028                         this.killindicator.scale = 0.5;
1029                         setattachment(this.killindicator, this, "");
1030                         setorigin(this.killindicator, '0 0 52');
1031                         setthink(this.killindicator, KillIndicator_Think);
1032                         this.killindicator.nextthink = starttime + (this.lip) * 0.05;
1033                         clientkilltime = max(clientkilltime, this.killindicator.nextthink + 0.05);
1034                         this.killindicator.cnt = ceil(killtime);
1035                         this.killindicator.count = bound(0, ceil(killtime), 10);
1036                         //sprint(this, strcat("^1You'll be dead in ", ftos(this.killindicator.cnt), " seconds\n"));
1037
1038                         IL_EACH(g_clones, it.enemy == this && !(it.effects & CSQCMODEL_EF_RESPAWNGHOST),
1039                         {
1040                                 it.killindicator = spawn();
1041                                 it.killindicator.owner = it;
1042                                 it.killindicator.scale = 0.5;
1043                                 setattachment(it.killindicator, it, "");
1044                                 setorigin(it.killindicator, '0 0 52');
1045                                 setthink(it.killindicator, KillIndicator_Think);
1046                                 it.killindicator.nextthink = starttime + (it.lip) * 0.05;
1047                                 //clientkilltime = max(clientkilltime, it.killindicator.nextthink + 0.05);
1048                                 it.killindicator.cnt = ceil(killtime);
1049                         });
1050                         this.lip = 0;
1051                 }
1052         }
1053         if(this.killindicator)
1054         {
1055                 if(targetteam == 0) // just die
1056                 {
1057                         this.killindicator.colormod = '0 0 0';
1058                         if(IS_REAL_CLIENT(this))
1059                         if(this.killindicator.cnt > 0)
1060                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_TEAMCHANGE_SUICIDE, this.killindicator.cnt);
1061                 }
1062                 else if(targetteam == -1) // auto
1063                 {
1064                         this.killindicator.colormod = '0 1 0';
1065                         if(IS_REAL_CLIENT(this))
1066                         if(this.killindicator.cnt > 0)
1067                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_TEAMCHANGE_AUTO, this.killindicator.cnt);
1068                 }
1069                 else if(targetteam == -2) // spectate
1070                 {
1071                         this.killindicator.colormod = '0.5 0.5 0.5';
1072                         if(IS_REAL_CLIENT(this))
1073                         if(this.killindicator.cnt > 0)
1074                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_TEAMCHANGE_SPECTATE, this.killindicator.cnt);
1075                 }
1076                 else
1077                 {
1078                         this.killindicator.colormod = Team_ColorRGB(targetteam);
1079                         if(IS_REAL_CLIENT(this))
1080                         if(this.killindicator.cnt > 0)
1081                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, APP_TEAM_NUM(targetteam, CENTER_TEAMCHANGE), this.killindicator.cnt);
1082                 }
1083         }
1084
1085 }
1086
1087 void ClientKill (entity this)
1088 {
1089         if(game_stopped) return;
1090         if(this.player_blocked) return;
1091         if(STAT(FROZEN, this)) return;
1092
1093         ClientKill_TeamChange(this, 0);
1094 }
1095
1096 void FixClientCvars(entity e)
1097 {
1098         // send prediction settings to the client
1099         stuffcmd(e, "\nin_bindmap 0 0\n");
1100         if(autocvar_g_antilag == 3) // client side hitscan
1101                 stuffcmd(e, "cl_cmd settemp cl_prydoncursor_notrace 0\n");
1102         if(autocvar_sv_gentle)
1103                 stuffcmd(e, "cl_cmd settemp cl_gentle 1\n");
1104
1105         stuffcmd(e, sprintf("\ncl_jumpspeedcap_min \"%s\"\n", autocvar_sv_jumpspeedcap_min));
1106         stuffcmd(e, sprintf("\ncl_jumpspeedcap_max \"%s\"\n", autocvar_sv_jumpspeedcap_max));
1107
1108         stuffcmd(e, sprintf("\ncl_shootfromfixedorigin \"%s\"\n", autocvar_g_shootfromfixedorigin));
1109
1110         MUTATOR_CALLHOOK(FixClientCvars, e);
1111 }
1112
1113 bool findinlist_abbrev(string tofind, string list)
1114 {
1115         if(list == "" || tofind == "")
1116                 return false; // empty list or search, just return
1117
1118         // this function allows abbreviated strings!
1119         FOREACH_WORD(list, it == substring(tofind, 0, strlen(it)),
1120         {
1121                 return true;
1122         });
1123
1124         return false;
1125 }
1126
1127 bool PlayerInIPList(entity p, string iplist)
1128 {
1129         // some safety checks (never allow local?)
1130         if(p.netaddress == "local" || p.netaddress == "" || !IS_REAL_CLIENT(p))
1131                 return false;
1132
1133         return findinlist_abbrev(p.netaddress, iplist);
1134 }
1135
1136 bool PlayerInIDList(entity p, string idlist)
1137 {
1138         // NOTE: we do NOT check crypto_idfp_signed here, an unsigned ID is fine too for this
1139         if(!p.crypto_idfp)
1140                 return false;
1141
1142         return findinlist_abbrev(p.crypto_idfp, idlist);
1143 }
1144
1145 bool PlayerInList(entity player, string list)
1146 {
1147         return boolean(PlayerInIDList(player, list) || PlayerInIPList(player, list));
1148 }
1149
1150 #ifdef DP_EXT_PRECONNECT
1151 /*
1152 =============
1153 ClientPreConnect
1154
1155 Called once (not at each match start) when a client begins a connection to the server
1156 =============
1157 */
1158 void ClientPreConnect(entity this)
1159 {
1160         if(autocvar_sv_eventlog)
1161         {
1162                 GameLogEcho(sprintf(":connect:%d:%d:%s",
1163                         this.playerid,
1164                         etof(this),
1165                         ((IS_REAL_CLIENT(this)) ? this.netaddress : "bot")
1166                 ));
1167         }
1168 }
1169 #endif
1170
1171 /**
1172 =============
1173 ClientConnect
1174
1175 Called when a client connects to the server
1176 =============
1177 */
1178 void ClientConnect(entity this)
1179 {
1180         if (Ban_MaybeEnforceBanOnce(this)) return;
1181         assert(!IS_CLIENT(this), return);
1182         this.flags |= FL_CLIENT;
1183         assert(player_count >= 0, player_count = 0);
1184
1185 #ifdef WATERMARK
1186         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_WATERMARK, WATERMARK);
1187 #endif
1188         TRANSMUTE(Client, this);
1189         CS(this).version_nagtime = time + 10 + random() * 10;
1190
1191         // identify the right forced team
1192         if (autocvar_g_campaign)
1193         {
1194                 if (IS_REAL_CLIENT(this)) // only players, not bots
1195                 {
1196                         switch (autocvar_g_campaign_forceteam)
1197                         {
1198                                 case 1: this.team_forced = NUM_TEAM_1; break;
1199                                 case 2: this.team_forced = NUM_TEAM_2; break;
1200                                 case 3: this.team_forced = NUM_TEAM_3; break;
1201                                 case 4: this.team_forced = NUM_TEAM_4; break;
1202                                 default: this.team_forced = 0;
1203                         }
1204                 }
1205         }
1206         else if (PlayerInList(this, autocvar_g_forced_team_red))    this.team_forced = NUM_TEAM_1;
1207         else if (PlayerInList(this, autocvar_g_forced_team_blue))   this.team_forced = NUM_TEAM_2;
1208         else if (PlayerInList(this, autocvar_g_forced_team_yellow)) this.team_forced = NUM_TEAM_3;
1209         else if (PlayerInList(this, autocvar_g_forced_team_pink))   this.team_forced = NUM_TEAM_4;
1210         else switch (autocvar_g_forced_team_otherwise)
1211         {
1212                 default: this.team_forced = 0; break;
1213                 case "red": this.team_forced = NUM_TEAM_1; break;
1214                 case "blue": this.team_forced = NUM_TEAM_2; break;
1215                 case "yellow": this.team_forced = NUM_TEAM_3; break;
1216                 case "pink": this.team_forced = NUM_TEAM_4; break;
1217                 case "spectate":
1218                 case "spectator":
1219                         this.team_forced = -1;
1220                         break;
1221         }
1222         if (!teamplay && this.team_forced > 0) this.team_forced = 0;
1223
1224         int playerid_save = this.playerid;
1225         this.playerid = 0; // silent
1226         JoinBestTeam(this, false); // if the team number is valid, keep it
1227         this.playerid = playerid_save;
1228
1229         if (autocvar_sv_spectate || autocvar_g_campaign || this.team_forced < 0) {
1230                 TRANSMUTE(Observer, this);
1231         } else {
1232                 if (!teamplay || autocvar_g_balance_teams) {
1233                         TRANSMUTE(Player, this);
1234                         campaign_bots_may_start = true;
1235                 } else {
1236                         TRANSMUTE(Observer, this); // do it anyway
1237                 }
1238         }
1239
1240         PlayerStats_GameReport_AddEvent(sprintf("kills-%d", this.playerid));
1241
1242         // always track bots, don't ask for cl_allow_uidtracking
1243         if (IS_BOT_CLIENT(this))
1244                 PlayerStats_GameReport_AddPlayer(this);
1245         else
1246                 CS(this).allowed_timeouts = autocvar_sv_timeout_number;
1247
1248         if (autocvar_sv_eventlog)
1249                 GameLogEcho(strcat(":join:", ftos(this.playerid), ":", ftos(etof(this)), ":", ((IS_REAL_CLIENT(this)) ? this.netaddress : "bot"), ":", playername(this, false)));
1250
1251         LogTeamchange(this.playerid, this.team, 1);
1252
1253         CS(this).just_joined = true;  // stop spamming the eventlog with additional lines when the client connects
1254
1255         if(teamplay && IS_PLAYER(this))
1256                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, APP_TEAM_NUM(this.team, INFO_JOIN_CONNECT_TEAM), this.netname);
1257         else
1258                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_JOIN_CONNECT, this.netname);
1259
1260         stuffcmd(this, clientstuff, "\n");
1261         stuffcmd(this, "cl_particles_reloadeffects\n"); // TODO do we still need this?
1262
1263         FixClientCvars(this);
1264
1265         // get version info from player
1266         stuffcmd(this, "cmd clientversion $gameversion\n");
1267
1268         // notify about available teams
1269         if (teamplay)
1270         {
1271                 CheckAllowedTeams(this);
1272                 int t = 0;
1273                 if (c1 >= 0) t |= BIT(0);
1274                 if (c2 >= 0) t |= BIT(1);
1275                 if (c3 >= 0) t |= BIT(2);
1276                 if (c4 >= 0) t |= BIT(3);
1277                 stuffcmd(this, sprintf("set _teams_available %d\n", t));
1278         }
1279         else
1280         {
1281                 stuffcmd(this, "set _teams_available 0\n");
1282         }
1283
1284         bot_relinkplayerlist();
1285
1286         CS(this).spectatortime = time;
1287         if (blockSpectators)
1288         {
1289                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
1290         }
1291
1292         CS(this).jointime = time;
1293
1294         if (IS_REAL_CLIENT(this))
1295         {
1296                 if (g_weaponarena_weapons == WEPSET(TUBA))
1297                         stuffcmd(this, "cl_cmd settemp chase_active 1\n");
1298         }
1299
1300         if (!sv_foginterval && world.fog != "")
1301                 stuffcmd(this, strcat("\nfog ", world.fog, "\nr_fog_exp2 0\nr_drawfog 1\n"));
1302
1303         if (autocvar_sv_teamnagger && !(autocvar_bot_vs_human && AvailableTeams() == 2))
1304                 if(!MUTATOR_CALLHOOK(HideTeamNagger, this))
1305                         send_CSQC_teamnagger();
1306
1307         CSQCMODEL_AUTOINIT(this);
1308
1309         CS(this).model_randomizer = random();
1310
1311         if (IS_REAL_CLIENT(this))
1312                 sv_notice_join(this);
1313
1314         // update physics stats (players can spawn before physics runs)
1315         Physics_UpdateStats(this);
1316
1317         IL_EACH(g_initforplayer, it.init_for_player, {
1318                 it.init_for_player(it, this);
1319         });
1320
1321         Handicap_Initialize(this);
1322
1323         MUTATOR_CALLHOOK(ClientConnect, this);
1324
1325         if (IS_REAL_CLIENT(this))
1326         {
1327                 if (!autocvar_g_campaign && !IS_PLAYER(this))
1328                 {
1329                         CS(this).motd_actived_time = -1;
1330                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOTD, getwelcomemessage(this));
1331                 }
1332         }
1333 }
1334 /*
1335 =============
1336 ClientDisconnect
1337
1338 Called when a client disconnects from the server
1339 =============
1340 */
1341 .entity chatbubbleentity;
1342 void ReadyCount();
1343 void ClientDisconnect(entity this)
1344 {
1345         assert(IS_CLIENT(this), return);
1346
1347         PlayerStats_GameReport_FinalizePlayer(this);
1348         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
1349         if (CS(this).active_minigame) part_minigame(this);
1350         if (IS_PLAYER(this)) Send_Effect(EFFECT_SPAWN_NEUTRAL, this.origin, '0 0 0', 1);
1351
1352         if (autocvar_sv_eventlog)
1353                 GameLogEcho(strcat(":part:", ftos(this.playerid)));
1354
1355         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_QUIT_DISCONNECT, this.netname);
1356
1357         if(IS_SPEC(this))
1358                 SetSpectatee(this, NULL);
1359
1360     MUTATOR_CALLHOOK(ClientDisconnect, this);
1361
1362         strfree(CS(this).netname_previous); // needs to be before the CS entity is removed!
1363         strfree(CS(this).weaponorder_byimpulse);
1364         ClientState_detach(this);
1365
1366         Portal_ClearAll(this);
1367
1368         Unfreeze(this);
1369
1370         RemoveGrapplingHooks(this);
1371
1372         // Here, everything has been done that requires this player to be a client.
1373
1374         this.flags &= ~FL_CLIENT;
1375
1376         if (this.chatbubbleentity) delete(this.chatbubbleentity);
1377         if (this.killindicator) delete(this.killindicator);
1378
1379         WaypointSprite_PlayerGone(this);
1380
1381         bot_relinkplayerlist();
1382
1383         strfree(this.clientstatus);
1384         if (this.personal) delete(this.personal);
1385
1386         this.playerid = 0;
1387         ReadyCount();
1388         if (vote_called && IS_REAL_CLIENT(this)) VoteCount(false);
1389
1390         ONREMOVE(this);
1391 }
1392
1393 void ChatBubbleThink(entity this)
1394 {
1395         this.nextthink = time;
1396         if ((this.owner.alpha < 0) || this.owner.chatbubbleentity != this)
1397         {
1398                 if(this.owner) // but why can that ever be NULL?
1399                         this.owner.chatbubbleentity = NULL;
1400                 delete(this);
1401                 return;
1402         }
1403
1404         this.mdl = "";
1405
1406         if ( !IS_DEAD(this.owner) && IS_PLAYER(this.owner) )
1407         {
1408                 if ( CS(this.owner).active_minigame )
1409                         this.mdl = "models/sprites/minigame_busy.iqm";
1410                 else if (PHYS_INPUT_BUTTON_CHAT(this.owner))
1411                         this.mdl = "models/misc/chatbubble.spr";
1412         }
1413
1414         if ( this.model != this.mdl )
1415                 _setmodel(this, this.mdl);
1416
1417 }
1418
1419 void UpdateChatBubble(entity this)
1420 {
1421         if (this.alpha < 0)
1422                 return;
1423         // spawn a chatbubble entity if needed
1424         if (!this.chatbubbleentity)
1425         {
1426                 this.chatbubbleentity = new(chatbubbleentity);
1427                 this.chatbubbleentity.owner = this;
1428                 this.chatbubbleentity.exteriormodeltoclient = this;
1429                 setthink(this.chatbubbleentity, ChatBubbleThink);
1430                 this.chatbubbleentity.nextthink = time;
1431                 setmodel(this.chatbubbleentity, MDL_CHAT); // precision set below
1432                 //setorigin(this.chatbubbleentity, this.origin + '0 0 15' + this.maxs_z * '0 0 1');
1433                 setorigin(this.chatbubbleentity, '0 0 15' + this.maxs_z * '0 0 1');
1434                 setattachment(this.chatbubbleentity, this, "");  // sticks to moving player better, also conserves bandwidth
1435                 this.chatbubbleentity.mdl = this.chatbubbleentity.model;
1436                 //this.chatbubbleentity.model = "";
1437                 this.chatbubbleentity.effects = EF_LOWPRECISION;
1438         }
1439 }
1440
1441
1442 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
1443 // added to the model skins
1444 /*void UpdateColorModHack()
1445 {
1446         float c;
1447         c = this.clientcolors & 15;
1448         // LordHavoc: only bothering to support white, green, red, yellow, blue
1449              if (!teamplay) this.colormod = '0 0 0';
1450         else if (c ==  0) this.colormod = '1.00 1.00 1.00';
1451         else if (c ==  3) this.colormod = '0.10 1.73 0.10';
1452         else if (c ==  4) this.colormod = '1.73 0.10 0.10';
1453         else if (c == 12) this.colormod = '1.22 1.22 0.10';
1454         else if (c == 13) this.colormod = '0.10 0.10 1.73';
1455         else this.colormod = '1 1 1';
1456 }*/
1457
1458 void respawn(entity this)
1459 {
1460         if(this.alpha >= 0 && autocvar_g_respawn_ghosts)
1461         {
1462                 this.solid = SOLID_NOT;
1463                 this.takedamage = DAMAGE_NO;
1464                 set_movetype(this, MOVETYPE_FLY);
1465                 this.velocity = '0 0 1' * autocvar_g_respawn_ghosts_speed;
1466                 this.avelocity = randomvec() * autocvar_g_respawn_ghosts_speed * 3 - randomvec() * autocvar_g_respawn_ghosts_speed * 3;
1467                 this.effects |= CSQCMODEL_EF_RESPAWNGHOST;
1468                 Send_Effect(EFFECT_RESPAWN_GHOST, this.origin, '0 0 0', 1);
1469                 if(autocvar_g_respawn_ghosts_maxtime)
1470                         SUB_SetFade (this, time + autocvar_g_respawn_ghosts_maxtime / 2 + random () * (autocvar_g_respawn_ghosts_maxtime - autocvar_g_respawn_ghosts_maxtime / 2), 1.5);
1471         }
1472
1473         CopyBody(this, 1);
1474
1475         this.effects |= EF_NODRAW; // prevent another CopyBody
1476         PutClientInServer(this);
1477 }
1478
1479 void play_countdown(entity this, float finished, Sound samp)
1480 {
1481     TC(Sound, samp);
1482         if(IS_REAL_CLIENT(this))
1483                 if(floor(finished - time - frametime) != floor(finished - time))
1484                         if(finished - time < 6)
1485                                 sound (this, CH_INFO, samp, VOL_BASE, ATTEN_NORM);
1486 }
1487
1488 void player_powerups(entity this)
1489 {
1490         // add a way to see what the items were BEFORE all of these checks for the mutator hook
1491         int items_prev = this.items;
1492
1493         if((this.items & IT_USING_JETPACK) && !IS_DEAD(this) && !game_stopped)
1494                 this.modelflags |= MF_ROCKET;
1495         else
1496                 this.modelflags &= ~MF_ROCKET;
1497
1498         this.effects &= ~(EF_RED | EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT | EF_FLAME | EF_NODEPTHTEST);
1499
1500         if((this.alpha < 0 || IS_DEAD(this)) && !this.vehicle) // don't apply the flags if the player is gibbed
1501                 return;
1502
1503         Fire_ApplyDamage(this);
1504         Fire_ApplyEffect(this);
1505
1506         if (!autocvar_g_instagib)
1507         {
1508                 if (this.items & ITEM_Strength.m_itemid)
1509                 {
1510                         play_countdown(this, this.strength_finished, SND_POWEROFF);
1511                         this.effects = this.effects | (EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT);
1512                         if (time > this.strength_finished)
1513                         {
1514                                 this.items = this.items - (this.items & ITEM_Strength.m_itemid);
1515                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERDOWN_STRENGTH, this.netname);
1516                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERDOWN_STRENGTH);
1517                         }
1518                 }
1519                 else
1520                 {
1521                         if (time < this.strength_finished)
1522                         {
1523                                 this.items = this.items | ITEM_Strength.m_itemid;
1524                                 if(!g_cts)
1525                                         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERUP_STRENGTH, this.netname);
1526                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERUP_STRENGTH);
1527                         }
1528                 }
1529                 if (this.items & ITEM_Shield.m_itemid)
1530                 {
1531                         play_countdown(this, this.invincible_finished, SND_POWEROFF);
1532                         this.effects = this.effects | (EF_RED | EF_ADDITIVE | EF_FULLBRIGHT);
1533                         if (time > this.invincible_finished)
1534                         {
1535                                 this.items = this.items - (this.items & ITEM_Shield.m_itemid);
1536                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERDOWN_SHIELD, this.netname);
1537                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERDOWN_SHIELD);
1538                         }
1539                 }
1540                 else
1541                 {
1542                         if (time < this.invincible_finished)
1543                         {
1544                                 this.items = this.items | ITEM_Shield.m_itemid;
1545                                 if(!g_cts)
1546                                         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERUP_SHIELD, this.netname);
1547                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERUP_SHIELD);
1548                         }
1549                 }
1550                 if (this.items & IT_SUPERWEAPON)
1551                 {
1552                         if (!(this.weapons & WEPSET_SUPERWEAPONS))
1553                         {
1554                                 this.superweapons_finished = 0;
1555                                 this.items = this.items - (this.items & IT_SUPERWEAPON);
1556                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_LOST, this.netname);
1557                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_LOST);
1558                         }
1559                         else if (this.items & IT_UNLIMITED_SUPERWEAPONS)
1560                         {
1561                                 // don't let them run out
1562                         }
1563                         else
1564                         {
1565                                 play_countdown(this, this.superweapons_finished, SND_POWEROFF);
1566                                 if (time > this.superweapons_finished)
1567                                 {
1568                                         this.items = this.items - (this.items & IT_SUPERWEAPON);
1569                                         this.weapons &= ~WEPSET_SUPERWEAPONS;
1570                                         //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_BROKEN, this.netname);
1571                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_BROKEN);
1572                                 }
1573                         }
1574                 }
1575                 else if(this.weapons & WEPSET_SUPERWEAPONS)
1576                 {
1577                         if (time < this.superweapons_finished || (this.items & IT_UNLIMITED_SUPERWEAPONS))
1578                         {
1579                                 this.items = this.items | IT_SUPERWEAPON;
1580                                 if(!g_cts)
1581                                         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_PICKUP, this.netname);
1582                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_PICKUP);
1583                         }
1584                         else
1585                         {
1586                                 this.superweapons_finished = 0;
1587                                 this.weapons &= ~WEPSET_SUPERWEAPONS;
1588                         }
1589                 }
1590                 else
1591                 {
1592                         this.superweapons_finished = 0;
1593                 }
1594         }
1595
1596         if(autocvar_g_nodepthtestplayers)
1597                 this.effects = this.effects | EF_NODEPTHTEST;
1598
1599         if(autocvar_g_fullbrightplayers)
1600                 this.effects = this.effects | EF_FULLBRIGHT;
1601
1602         if (time >= game_starttime)
1603         if (time < this.spawnshieldtime)
1604                 this.effects = this.effects | (EF_ADDITIVE | EF_FULLBRIGHT);
1605
1606         MUTATOR_CALLHOOK(PlayerPowerups, this, items_prev);
1607 }
1608
1609 float CalcRegen(float current, float stable, float regenfactor, float regenframetime)
1610 {
1611         if(current > stable)
1612                 return current;
1613         else if(current > stable - 0.25) // when close enough, "snap"
1614                 return stable;
1615         else
1616                 return min(stable, current + (stable - current) * regenfactor * regenframetime);
1617 }
1618
1619 float CalcRot(float current, float stable, float rotfactor, float rotframetime)
1620 {
1621         if(current < stable)
1622                 return current;
1623         else if(current < stable + 0.25) // when close enough, "snap"
1624                 return stable;
1625         else
1626                 return max(stable, current + (stable - current) * rotfactor * rotframetime);
1627 }
1628
1629 float CalcRotRegen(float current, float regenstable, float regenfactor, float regenlinear, float regenframetime, float rotstable, float rotfactor, float rotlinear, float rotframetime, float limit)
1630 {
1631         if(current > rotstable)
1632         {
1633                 if(rotframetime > 0)
1634                 {
1635                         current = CalcRot(current, rotstable, rotfactor, rotframetime);
1636                         current = max(rotstable, current - rotlinear * rotframetime);
1637                 }
1638         }
1639         else if(current < regenstable)
1640         {
1641                 if(regenframetime > 0)
1642                 {
1643                         current = CalcRegen(current, regenstable, regenfactor, regenframetime);
1644                         current = min(regenstable, current + regenlinear * regenframetime);
1645                 }
1646         }
1647
1648         if(current > limit)
1649                 current = limit;
1650
1651         return current;
1652 }
1653
1654 void player_regen(entity this)
1655 {
1656         float max_mod, regen_mod, rot_mod, limit_mod;
1657         max_mod = regen_mod = rot_mod = limit_mod = 1;
1658
1659         float regen_health = autocvar_g_balance_health_regen;
1660         float regen_health_linear = autocvar_g_balance_health_regenlinear;
1661         float regen_health_rot = autocvar_g_balance_health_rot;
1662         float regen_health_rotlinear = autocvar_g_balance_health_rotlinear;
1663         float regen_health_stable = autocvar_g_balance_health_regenstable;
1664         float regen_health_rotstable = autocvar_g_balance_health_rotstable;
1665         bool mutator_returnvalue = MUTATOR_CALLHOOK(PlayerRegen, this, max_mod, regen_mod, rot_mod, limit_mod, regen_health, regen_health_linear, regen_health_rot,
1666                 regen_health_rotlinear, regen_health_stable, regen_health_rotstable);
1667         max_mod = M_ARGV(1, float);
1668         regen_mod = M_ARGV(2, float);
1669         rot_mod = M_ARGV(3, float);
1670         limit_mod = M_ARGV(4, float);
1671         regen_health = M_ARGV(5, float);
1672         regen_health_linear = M_ARGV(6, float);
1673         regen_health_rot = M_ARGV(7, float);
1674         regen_health_rotlinear = M_ARGV(8, float);
1675         regen_health_stable = M_ARGV(9, float);
1676         regen_health_rotstable = M_ARGV(10, float);
1677
1678         if(!mutator_returnvalue)
1679         if(!STAT(FROZEN, this))
1680         {
1681                 float mina, maxa, limith, limita;
1682                 maxa = autocvar_g_balance_armor_rotstable;
1683                 mina = autocvar_g_balance_armor_regenstable;
1684                 limith = GetResourceLimit(this, RESOURCE_HEALTH);
1685                 limita = GetResourceLimit(this, RESOURCE_ARMOR);
1686
1687                 regen_health_rotstable = regen_health_rotstable * max_mod;
1688                 regen_health_stable = regen_health_stable * max_mod;
1689                 limith = limith * limit_mod;
1690                 limita = limita * limit_mod;
1691
1692                 this.armorvalue = CalcRotRegen(this.armorvalue, mina, autocvar_g_balance_armor_regen, autocvar_g_balance_armor_regenlinear, regen_mod * frametime * (time > this.pauseregen_finished), maxa, autocvar_g_balance_armor_rot, autocvar_g_balance_armor_rotlinear, rot_mod * frametime * (time > this.pauserotarmor_finished), limita);
1693                 this.health = CalcRotRegen(this.health, regen_health_stable, regen_health, regen_health_linear, regen_mod * frametime * (time > this.pauseregen_finished), regen_health_rotstable, regen_health_rot, regen_health_rotlinear, rot_mod * frametime * (time > this.pauserothealth_finished), limith);
1694         }
1695
1696         // if player rotted to death...  die!
1697         // check this outside above checks, as player may still be able to rot to death
1698         if(this.health < 1)
1699         {
1700                 if(this.vehicle)
1701                         vehicles_exit(this.vehicle, VHEF_RELEASE);
1702                 if(this.event_damage)
1703                         this.event_damage(this, this, this, 1, DEATH_ROT.m_id, DMG_NOWEP, this.origin, '0 0 0');
1704         }
1705
1706         if (!(this.items & IT_UNLIMITED_WEAPON_AMMO))
1707         {
1708                 float minf, maxf, limitf;
1709
1710                 maxf = autocvar_g_balance_fuel_rotstable;
1711                 minf = autocvar_g_balance_fuel_regenstable;
1712                 limitf = GetResourceLimit(this, RESOURCE_FUEL);
1713
1714                 this.ammo_fuel = CalcRotRegen(this.ammo_fuel, minf, autocvar_g_balance_fuel_regen, autocvar_g_balance_fuel_regenlinear, frametime * (time > this.pauseregen_finished) * ((this.items & ITEM_JetpackRegen.m_itemid) != 0), maxf, autocvar_g_balance_fuel_rot, autocvar_g_balance_fuel_rotlinear, frametime * (time > this.pauserotfuel_finished), limitf);
1715         }
1716         // Ugly hack to make sure the health and armor don't go beyond hard limit.
1717         // TODO: Remove this hack when all code uses GivePlayerHealth and
1718         // GivePlayerArmor.
1719         if (this.health > RESOURCE_AMOUNT_HARD_LIMIT)
1720         {
1721                 this.health = RESOURCE_AMOUNT_HARD_LIMIT;
1722         }
1723         if (this.armorvalue > RESOURCE_AMOUNT_HARD_LIMIT)
1724         {
1725                 this.armorvalue = RESOURCE_AMOUNT_HARD_LIMIT;
1726         }
1727         // End hack.
1728 }
1729
1730 bool zoomstate_set;
1731 void SetZoomState(entity this, float newzoom)
1732 {
1733         if(newzoom != CS(this).zoomstate)
1734         {
1735                 CS(this).zoomstate = newzoom;
1736                 ClientData_Touch(this);
1737         }
1738         zoomstate_set = true;
1739 }
1740
1741 void GetPressedKeys(entity this)
1742 {
1743         MUTATOR_CALLHOOK(GetPressedKeys, this);
1744         int keys = STAT(PRESSED_KEYS, this);
1745         keys = BITSET(keys, KEY_FORWARD,        CS(this).movement.x > 0);
1746         keys = BITSET(keys, KEY_BACKWARD,       CS(this).movement.x < 0);
1747         keys = BITSET(keys, KEY_RIGHT,          CS(this).movement.y > 0);
1748         keys = BITSET(keys, KEY_LEFT,           CS(this).movement.y < 0);
1749
1750         keys = BITSET(keys, KEY_JUMP,           PHYS_INPUT_BUTTON_JUMP(this));
1751         keys = BITSET(keys, KEY_CROUCH,         PHYS_INPUT_BUTTON_CROUCH(this));
1752         keys = BITSET(keys, KEY_ATCK,           PHYS_INPUT_BUTTON_ATCK(this));
1753         keys = BITSET(keys, KEY_ATCK2,          PHYS_INPUT_BUTTON_ATCK2(this));
1754         CS(this).pressedkeys = keys; // store for other users
1755
1756         STAT(PRESSED_KEYS, this) = keys;
1757 }
1758
1759 /*
1760 ======================
1761 spectate mode routines
1762 ======================
1763 */
1764
1765 void SpectateCopy(entity this, entity spectatee)
1766 {
1767     TC(Client, this); TC(Client, spectatee);
1768
1769         MUTATOR_CALLHOOK(SpectateCopy, spectatee, this);
1770         PS(this) = PS(spectatee);
1771         this.armortype = spectatee.armortype;
1772         this.armorvalue = spectatee.armorvalue;
1773         this.ammo_cells = spectatee.ammo_cells;
1774         this.ammo_plasma = spectatee.ammo_plasma;
1775         this.ammo_shells = spectatee.ammo_shells;
1776         this.ammo_nails = spectatee.ammo_nails;
1777         this.ammo_rockets = spectatee.ammo_rockets;
1778         this.ammo_fuel = spectatee.ammo_fuel;
1779         this.effects = spectatee.effects & EFMASK_CHEAP; // eat performance
1780         this.health = spectatee.health;
1781         CS(this).impulse = 0;
1782         this.items = spectatee.items;
1783         STAT(LAST_PICKUP, this) = STAT(LAST_PICKUP, spectatee);
1784         STAT(HIT_TIME, this) = STAT(HIT_TIME, spectatee);
1785         this.strength_finished = spectatee.strength_finished;
1786         this.invincible_finished = spectatee.invincible_finished;
1787         this.superweapons_finished = spectatee.superweapons_finished;
1788         STAT(PRESSED_KEYS, this) = STAT(PRESSED_KEYS, spectatee);
1789         this.weapons = spectatee.weapons;
1790         this.punchangle = spectatee.punchangle;
1791         this.view_ofs = spectatee.view_ofs;
1792         this.velocity = spectatee.velocity;
1793         this.dmg_take = spectatee.dmg_take;
1794         this.dmg_save = spectatee.dmg_save;
1795         this.dmg_inflictor = spectatee.dmg_inflictor;
1796         this.v_angle = spectatee.v_angle;
1797         this.angles = spectatee.v_angle;
1798         STAT(FROZEN, this) = STAT(FROZEN, spectatee);
1799         STAT(REVIVE_PROGRESS, this) = STAT(REVIVE_PROGRESS, spectatee);
1800         this.viewloc = spectatee.viewloc;
1801         if(!PHYS_INPUT_BUTTON_USE(this) && STAT(CAMERA_SPECTATOR, this) != 2)
1802                 this.fixangle = true;
1803         setorigin(this, spectatee.origin);
1804         setsize(this, spectatee.mins, spectatee.maxs);
1805         SetZoomState(this, CS(spectatee).zoomstate);
1806
1807     anticheat_spectatecopy(this, spectatee);
1808         STAT(HUD, this) = STAT(HUD, spectatee);
1809         if(spectatee.vehicle)
1810     {
1811         this.angles = spectatee.v_angle;
1812
1813         //this.fixangle = false;
1814         //this.velocity = spectatee.vehicle.velocity;
1815         this.vehicle_health = spectatee.vehicle_health;
1816         this.vehicle_shield = spectatee.vehicle_shield;
1817         this.vehicle_energy = spectatee.vehicle_energy;
1818         this.vehicle_ammo1 = spectatee.vehicle_ammo1;
1819         this.vehicle_ammo2 = spectatee.vehicle_ammo2;
1820         this.vehicle_reload1 = spectatee.vehicle_reload1;
1821         this.vehicle_reload2 = spectatee.vehicle_reload2;
1822
1823         //msg_entity = this;
1824
1825        // WriteByte (MSG_ONE, SVC_SETVIEWANGLES);
1826             //WriteAngle(MSG_ONE,  spectatee.v_angle.x);
1827            // WriteAngle(MSG_ONE,  spectatee.v_angle.y);
1828            // WriteAngle(MSG_ONE,  spectatee.v_angle.z);
1829
1830         //WriteByte (MSG_ONE, SVC_SETVIEW);
1831         //    WriteEntity(MSG_ONE, this);
1832         //makevectors(spectatee.v_angle);
1833         //setorigin(this, spectatee.origin - v_forward * 400 + v_up * 300);*/
1834     }
1835 }
1836
1837 bool SpectateUpdate(entity this)
1838 {
1839         if(!this.enemy)
1840                 return false;
1841
1842         if(!IS_PLAYER(this.enemy) || this == this.enemy)
1843         {
1844                 SetSpectatee(this, NULL);
1845                 return false;
1846         }
1847
1848         SpectateCopy(this, this.enemy);
1849
1850         return true;
1851 }
1852
1853 bool SpectateSet(entity this)
1854 {
1855         if(!IS_PLAYER(this.enemy))
1856                 return false;
1857
1858         ClientData_Touch(this.enemy);
1859
1860         msg_entity = this;
1861         WriteByte(MSG_ONE, SVC_SETVIEW);
1862         WriteEntity(MSG_ONE, this.enemy);
1863         set_movetype(this, MOVETYPE_NONE);
1864         accuracy_resend(this);
1865
1866         if(!SpectateUpdate(this))
1867                 PutObserverInServer(this);
1868
1869         return true;
1870 }
1871
1872 void SetSpectatee_status(entity this, int spectatee_num)
1873 {
1874         int oldspectatee_status = CS(this).spectatee_status;
1875         CS(this).spectatee_status = spectatee_num;
1876
1877         if (CS(this).spectatee_status != oldspectatee_status)
1878         {
1879                 ClientData_Touch(this);
1880                 if (g_race || g_cts) race_InitSpectator();
1881         }
1882 }
1883
1884 void SetSpectatee(entity this, entity spectatee)
1885 {
1886         if(IS_BOT_CLIENT(this))
1887                 return; // bots abuse .enemy, this code is useless to them
1888
1889         entity old_spectatee = this.enemy;
1890
1891         this.enemy = spectatee;
1892
1893         // WEAPONTODO
1894         // these are required to fix the spectator bug with arc
1895         if(old_spectatee)
1896         {
1897                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1898                 {
1899                         .entity weaponentity = weaponentities[slot];
1900                         if(old_spectatee.(weaponentity).arc_beam)
1901                                 old_spectatee.(weaponentity).arc_beam.SendFlags |= ARC_SF_SETTINGS;
1902                 }
1903         }
1904         if(this.enemy)
1905         {
1906                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1907                 {
1908                         .entity weaponentity = weaponentities[slot];
1909                         if(this.enemy.(weaponentity).arc_beam)
1910                                 this.enemy.(weaponentity).arc_beam.SendFlags |= ARC_SF_SETTINGS;
1911                 }
1912         }
1913
1914         if (this.enemy)
1915                 SetSpectatee_status(this, etof(this.enemy));
1916
1917         // needed to update spectator list
1918         if(old_spectatee) { ClientData_Touch(old_spectatee); }
1919 }
1920
1921 bool Spectate(entity this, entity pl)
1922 {
1923         if(MUTATOR_CALLHOOK(SpectateSet, this, pl))
1924                 return false;
1925         pl = M_ARGV(1, entity);
1926
1927         SetSpectatee(this, pl);
1928         return SpectateSet(this);
1929 }
1930
1931 bool SpectateNext(entity this)
1932 {
1933         entity ent = find(this.enemy, classname, STR_PLAYER);
1934
1935         if (MUTATOR_CALLHOOK(SpectateNext, this, ent))
1936                 ent = M_ARGV(1, entity);
1937         else if (!ent)
1938                 ent = find(ent, classname, STR_PLAYER);
1939
1940         if(ent) { SetSpectatee(this, ent); }
1941
1942         return SpectateSet(this);
1943 }
1944
1945 bool SpectatePrev(entity this)
1946 {
1947         // NOTE: chain order is from the highest to the lower entnum (unlike find)
1948         entity ent = findchain(classname, STR_PLAYER);
1949         if (!ent) // no player
1950                 return false;
1951
1952         entity first = ent;
1953         // skip players until current spectated player
1954         if(this.enemy)
1955         while(ent && ent != this.enemy)
1956                 ent = ent.chain;
1957
1958         switch (MUTATOR_CALLHOOK(SpectatePrev, this, ent, first))
1959         {
1960                 case MUT_SPECPREV_FOUND:
1961                     ent = M_ARGV(1, entity);
1962                     break;
1963                 case MUT_SPECPREV_RETURN:
1964                     return true;
1965                 case MUT_SPECPREV_CONTINUE:
1966                 default:
1967                 {
1968                         if(ent.chain)
1969                                 ent = ent.chain;
1970                         else
1971                                 ent = first;
1972                         break;
1973                 }
1974         }
1975
1976         SetSpectatee(this, ent);
1977         return SpectateSet(this);
1978 }
1979
1980 /*
1981 =============
1982 ShowRespawnCountdown()
1983
1984 Update a respawn countdown display.
1985 =============
1986 */
1987 void ShowRespawnCountdown(entity this)
1988 {
1989         float number;
1990         if(!IS_DEAD(this)) // just respawned?
1991                 return;
1992         else
1993         {
1994                 number = ceil(this.respawn_time - time);
1995                 if(number <= 0)
1996                         return;
1997                 if(number <= this.respawn_countdown)
1998                 {
1999                         this.respawn_countdown = number - 1;
2000                         if(ceil(this.respawn_time - (time + 0.5)) == number) // only say it if it is the same number even in 0.5s; to prevent overlapping sounds
2001                                 { Send_Notification(NOTIF_ONE, this, MSG_ANNCE, Announcer_PickNumber(CNT_RESPAWN, number)); }
2002                 }
2003         }
2004 }
2005
2006 .bool team_selected;
2007 bool ShowTeamSelection(entity this)
2008 {
2009         if(!teamplay || autocvar_g_campaign || autocvar_g_balance_teams || this.team_selected || (CS(this).wasplayer && autocvar_g_changeteam_banned) || this.team_forced > 0)
2010                 return false;
2011         stuffcmd(this, "menu_showteamselect\n");
2012         return true;
2013 }
2014 void Join(entity this)
2015 {
2016         TRANSMUTE(Player, this);
2017
2018         if(!this.team_selected)
2019         if(autocvar_g_campaign || autocvar_g_balance_teams)
2020                 JoinBestTeam(this, true);
2021
2022         if(autocvar_g_campaign)
2023                 campaign_bots_may_start = true;
2024
2025         Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_PREVENT_JOIN);
2026
2027         PutClientInServer(this);
2028
2029         if(IS_PLAYER(this))
2030         if(teamplay && this.team != -1)
2031                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, APP_TEAM_NUM(this.team, INFO_JOIN_PLAY_TEAM), this.netname);
2032         else
2033                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_JOIN_PLAY, this.netname);
2034         this.team_selected = false;
2035 }
2036
2037 /**
2038  * Determines whether the player is allowed to join. This depends on cvar
2039  * g_maxplayers, if it isn't used this function always return true, otherwise
2040  * it checks whether the number of currently playing players exceeds g_maxplayers.
2041  * @return int number of free slots for players, 0 if none
2042  */
2043 int nJoinAllowed(entity this, entity ignore)
2044 {
2045         if(!ignore)
2046         // this is called that way when checking if anyone may be able to join (to build qcstatus)
2047         // so report 0 free slots if restricted
2048         {
2049                 if(autocvar_g_forced_team_otherwise == "spectate")
2050                         return 0;
2051                 if(autocvar_g_forced_team_otherwise == "spectator")
2052                         return 0;
2053         }
2054
2055         if(this && this.team_forced < 0)
2056                 return 0; // forced spectators can never join
2057
2058         // TODO simplify this
2059         int totalClients = 0;
2060         int currentlyPlaying = 0;
2061         FOREACH_CLIENT(true, {
2062                 if(it != ignore)
2063                         ++totalClients;
2064                 if(IS_REAL_CLIENT(it))
2065                 if(IS_PLAYER(it) || it.caplayer)
2066                         ++currentlyPlaying;
2067         });
2068
2069         float free_slots = 0;
2070         if (!autocvar_g_maxplayers)
2071                 free_slots = maxclients - totalClients;
2072         else if(currentlyPlaying < autocvar_g_maxplayers)
2073                 free_slots = min(maxclients - totalClients, autocvar_g_maxplayers - currentlyPlaying);
2074
2075         static float join_prevent_msg_time = 0;
2076         if(this && ignore && !free_slots && time > join_prevent_msg_time)
2077         {
2078                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_JOIN_PREVENT);
2079                 join_prevent_msg_time = time + 3;
2080         }
2081
2082         return free_slots;
2083 }
2084
2085 /**
2086  * Checks whether the client is an observer or spectator, if so, he will get kicked after
2087  * g_maxplayers_spectator_blocktime seconds
2088  */
2089 void checkSpectatorBlock(entity this)
2090 {
2091         if(IS_SPEC(this) || IS_OBSERVER(this))
2092         if(!this.caplayer)
2093         if(IS_REAL_CLIENT(this))
2094         {
2095                 if( time > (CS(this).spectatortime + autocvar_g_maxplayers_spectator_blocktime) ) {
2096                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_QUIT_KICK_SPECTATING);
2097                         dropclient(this);
2098                 }
2099         }
2100 }
2101
2102 void PrintWelcomeMessage(entity this)
2103 {
2104         if(CS(this).motd_actived_time == 0)
2105         {
2106                 if (autocvar_g_campaign) {
2107                         if ((IS_PLAYER(this) && PHYS_INPUT_BUTTON_INFO(this)) || (!IS_PLAYER(this))) {
2108                                 CS(this).motd_actived_time = time;
2109                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOTD, campaign_message);
2110                         }
2111                 } else {
2112                         if (PHYS_INPUT_BUTTON_INFO(this)) {
2113                                 CS(this).motd_actived_time = time;
2114                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOTD, getwelcomemessage(this));
2115                         }
2116                 }
2117         }
2118         else if(CS(this).motd_actived_time > 0) // showing MOTD or campaign message
2119         {
2120                 if (autocvar_g_campaign) {
2121                         if (PHYS_INPUT_BUTTON_INFO(this))
2122                                 CS(this).motd_actived_time = time;
2123                         else if ((time - CS(this).motd_actived_time > 2) && IS_PLAYER(this)) { // hide it some seconds after BUTTON_INFO has been released
2124                                 CS(this).motd_actived_time = 0;
2125                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_MOTD);
2126                         }
2127                 } else {
2128                         if (PHYS_INPUT_BUTTON_INFO(this))
2129                                 CS(this).motd_actived_time = time;
2130                         else if (time - CS(this).motd_actived_time > 2) { // hide it some seconds after BUTTON_INFO has been released
2131                                 CS(this).motd_actived_time = 0;
2132                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_MOTD);
2133                         }
2134                 }
2135         }
2136         else //if(CS(this).motd_actived_time < 0) // just connected, motd is active
2137         {
2138                 if(PHYS_INPUT_BUTTON_INFO(this)) // BUTTON_INFO hides initial MOTD
2139                         CS(this).motd_actived_time = -2; // wait until BUTTON_INFO gets released
2140                 else if(CS(this).motd_actived_time == -2 || IS_PLAYER(this) || IS_SPEC(this))
2141                 {
2142                         // instanctly hide MOTD
2143                         CS(this).motd_actived_time = 0;
2144                         Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_MOTD);
2145                 }
2146         }
2147 }
2148
2149 bool joinAllowed(entity this)
2150 {
2151         if (CS(this).version_mismatch) return false;
2152         if (!nJoinAllowed(this, this)) return false;
2153         if (teamplay && lockteams) return false;
2154         if (ShowTeamSelection(this)) return false;
2155         if (MUTATOR_CALLHOOK(ForbidSpawn, this)) return false;
2156         return true;
2157 }
2158
2159 .int items_added;
2160 .string shootfromfixedorigin;
2161 bool PlayerThink(entity this)
2162 {
2163         if (game_stopped || intermission_running) {
2164                 this.modelflags &= ~MF_ROCKET;
2165                 if(intermission_running)
2166                         IntermissionThink(this);
2167                 return false;
2168         }
2169
2170         if (timeout_status == TIMEOUT_ACTIVE) {
2171         // don't allow the player to turn around while game is paused
2172                 // FIXME turn this into CSQC stuff
2173                 this.v_angle = this.lastV_angle;
2174                 this.angles = this.lastV_angle;
2175                 this.fixangle = true;
2176         }
2177
2178         if (frametime) player_powerups(this);
2179
2180         if (IS_DEAD(this)) {
2181                 if (this.personal && g_race_qualifying) {
2182                         if (time > this.respawn_time) {
2183                                 STAT(RESPAWN_TIME, this) = this.respawn_time = time + 1; // only retry once a second
2184                                 respawn(this);
2185                                 CS(this).impulse = CHIMPULSE_SPEEDRUN.impulse;
2186                         }
2187                 } else {
2188                         if (frametime) player_anim(this);
2189
2190                         if (this.respawn_flags & RESPAWN_DENY)
2191                         {
2192                                 STAT(RESPAWN_TIME, this) = 0;
2193                                 return false;
2194                         }
2195
2196                         bool button_pressed = (PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_JUMP(this) || PHYS_INPUT_BUTTON_ATCK2(this) || PHYS_INPUT_BUTTON_HOOK(this) || PHYS_INPUT_BUTTON_USE(this));
2197
2198                         switch(this.deadflag)
2199                         {
2200                                 case DEAD_DYING:
2201                                 {
2202                                         if ((this.respawn_flags & RESPAWN_FORCE) && !(this.respawn_time < this.respawn_time_max))
2203                                                 this.deadflag = DEAD_RESPAWNING;
2204                                         else if (!button_pressed || (time >= this.respawn_time_max && (this.respawn_flags & RESPAWN_FORCE)))
2205                                                 this.deadflag = DEAD_DEAD;
2206                                         break;
2207                                 }
2208                                 case DEAD_DEAD:
2209                                 {
2210                                         if (button_pressed)
2211                                                 this.deadflag = DEAD_RESPAWNABLE;
2212                                         else if (time >= this.respawn_time_max && (this.respawn_flags & RESPAWN_FORCE))
2213                                                 this.deadflag = DEAD_RESPAWNING;
2214                                         break;
2215                                 }
2216                                 case DEAD_RESPAWNABLE:
2217                                 {
2218                                         if (!button_pressed || (this.respawn_flags & RESPAWN_FORCE))
2219                                                 this.deadflag = DEAD_RESPAWNING;
2220                                         break;
2221                                 }
2222                                 case DEAD_RESPAWNING:
2223                                 {
2224                                         if (time > this.respawn_time)
2225                                         {
2226                                                 this.respawn_time = time + 1; // only retry once a second
2227                                                 this.respawn_time_max = this.respawn_time;
2228                                                 respawn(this);
2229                                         }
2230                                         break;
2231                                 }
2232                         }
2233
2234                         ShowRespawnCountdown(this);
2235
2236                         if (this.respawn_flags & RESPAWN_SILENT)
2237                                 STAT(RESPAWN_TIME, this) = 0;
2238                         else if ((this.respawn_flags & RESPAWN_FORCE) && this.respawn_time < this.respawn_time_max)
2239                         {
2240                                 if (time < this.respawn_time)
2241                                         STAT(RESPAWN_TIME, this) = this.respawn_time;
2242                                 else if (this.deadflag != DEAD_RESPAWNING)
2243                                         STAT(RESPAWN_TIME, this) = -this.respawn_time_max;
2244                         }
2245                         else
2246                                 STAT(RESPAWN_TIME, this) = this.respawn_time;
2247                 }
2248
2249                 // if respawning, invert stat_respawn_time to indicate this, the client translates it
2250                 if (this.deadflag == DEAD_RESPAWNING && STAT(RESPAWN_TIME, this) > 0)
2251                         STAT(RESPAWN_TIME, this) *= -1;
2252
2253                 return false;
2254         }
2255
2256         FixPlayermodel(this);
2257
2258         if (this.shootfromfixedorigin != autocvar_g_shootfromfixedorigin) {
2259                 this.shootfromfixedorigin = autocvar_g_shootfromfixedorigin;
2260                 stuffcmd(this, sprintf("\ncl_shootfromfixedorigin \"%s\"\n", autocvar_g_shootfromfixedorigin));
2261         }
2262
2263         // LordHavoc: allow firing on move frames (sub-ticrate), this gives better timing on slow servers
2264         //if(frametime)
2265         {
2266                 this.items &= ~this.items_added;
2267
2268                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2269                 {
2270                         .entity weaponentity = weaponentities[slot];
2271                         W_WeaponFrame(this, weaponentity);
2272                 }
2273
2274                 this.items_added = 0;
2275                 if ((this.items & ITEM_Jetpack.m_itemid) && ((this.items & ITEM_JetpackRegen.m_itemid) || this.ammo_fuel >= 0.01))
2276             this.items_added |= IT_FUEL;
2277
2278                 this.items |= this.items_added;
2279         }
2280
2281         player_regen(this);
2282
2283         // WEAPONTODO: Add a weapon request for this
2284         // rot vortex charge to the charge limit
2285         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2286         {
2287                 .entity weaponentity = weaponentities[slot];
2288                 if (WEP_CVAR(vortex, charge_rot_rate) && this.(weaponentity).vortex_charge > WEP_CVAR(vortex, charge_limit) && this.(weaponentity).vortex_charge_rottime < time)
2289                         this.(weaponentity).vortex_charge = bound(WEP_CVAR(vortex, charge_limit), this.(weaponentity).vortex_charge - WEP_CVAR(vortex, charge_rot_rate) * frametime / W_TICSPERFRAME, 1);
2290         }
2291
2292         if (frametime) player_anim(this);
2293
2294         // secret status
2295         secrets_setstatus(this);
2296
2297         // monsters status
2298         monsters_setstatus(this);
2299
2300         this.dmg_team = max(0, this.dmg_team - autocvar_g_teamdamage_resetspeed * frametime);
2301
2302         return true;
2303 }
2304
2305 void ObserverThink(entity this)
2306 {
2307         if ( CS(this).impulse )
2308         {
2309                 MinigameImpulse(this, CS(this).impulse);
2310                 CS(this).impulse = 0;
2311         }
2312
2313         if (this.flags & FL_JUMPRELEASED) {
2314                 if (PHYS_INPUT_BUTTON_JUMP(this) && joinAllowed(this)) {
2315                         this.flags &= ~FL_JUMPRELEASED;
2316                         this.flags |= FL_SPAWNING;
2317                 } else if(PHYS_INPUT_BUTTON_ATCK(this) && !CS(this).version_mismatch) {
2318                         this.flags &= ~FL_JUMPRELEASED;
2319                         if(SpectateNext(this)) {
2320                                 TRANSMUTE(Spectator, this);
2321                         }
2322                 } else {
2323                         int preferred_movetype = ((!PHYS_INPUT_BUTTON_USE(this) ? CS(this).cvar_cl_clippedspectating : !CS(this).cvar_cl_clippedspectating) ? MOVETYPE_FLY_WORLDONLY : MOVETYPE_NOCLIP);
2324                         set_movetype(this, preferred_movetype);
2325                 }
2326         } else {
2327                 if (!(PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_JUMP(this))) {
2328                         this.flags |= FL_JUMPRELEASED;
2329                         if(this.flags & FL_SPAWNING)
2330                         {
2331                                 this.flags &= ~FL_SPAWNING;
2332                                 Join(this);
2333                                 return;
2334                         }
2335                 }
2336         }
2337 }
2338
2339 void SpectatorThink(entity this)
2340 {
2341         if ( CS(this).impulse )
2342         {
2343                 if(MinigameImpulse(this, CS(this).impulse))
2344                         CS(this).impulse = 0;
2345
2346                 if (CS(this).impulse == IMP_weapon_drop.impulse)
2347                 {
2348                         STAT(CAMERA_SPECTATOR, this) = (STAT(CAMERA_SPECTATOR, this) + 1) % 3;
2349                         CS(this).impulse = 0;
2350                         return;
2351                 }
2352         }
2353
2354         if (this.flags & FL_JUMPRELEASED) {
2355                 if (PHYS_INPUT_BUTTON_JUMP(this) && joinAllowed(this)) {
2356                         this.flags &= ~FL_JUMPRELEASED;
2357                         this.flags |= FL_SPAWNING;
2358                 } else if(PHYS_INPUT_BUTTON_ATCK(this) || CS(this).impulse == 10 || CS(this).impulse == 15 || CS(this).impulse == 18 || (CS(this).impulse >= 200 && CS(this).impulse <= 209)) {
2359                         this.flags &= ~FL_JUMPRELEASED;
2360                         if(SpectateNext(this)) {
2361                                 TRANSMUTE(Spectator, this);
2362                         } else {
2363                                 TRANSMUTE(Observer, this);
2364                                 PutClientInServer(this);
2365                         }
2366                         CS(this).impulse = 0;
2367                 } else if(CS(this).impulse == 12 || CS(this).impulse == 16  || CS(this).impulse == 19 || (CS(this).impulse >= 220 && CS(this).impulse <= 229)) {
2368                         this.flags &= ~FL_JUMPRELEASED;
2369                         if(SpectatePrev(this)) {
2370                                 TRANSMUTE(Spectator, this);
2371                         } else {
2372                                 TRANSMUTE(Observer, this);
2373                                 PutClientInServer(this);
2374                         }
2375                         CS(this).impulse = 0;
2376                 } else if (PHYS_INPUT_BUTTON_ATCK2(this)) {
2377                         this.flags &= ~FL_JUMPRELEASED;
2378                         TRANSMUTE(Observer, this);
2379                         PutClientInServer(this);
2380                 } else {
2381                         if(!SpectateUpdate(this))
2382                                 PutObserverInServer(this);
2383                 }
2384         } else {
2385                 if (!(PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_ATCK2(this))) {
2386                         this.flags |= FL_JUMPRELEASED;
2387                         if(this.flags & FL_SPAWNING)
2388                         {
2389                                 this.flags &= ~FL_SPAWNING;
2390                                 Join(this);
2391                                 return;
2392                         }
2393                 }
2394                 if(!SpectateUpdate(this))
2395                         PutObserverInServer(this);
2396         }
2397
2398         this.flags |= FL_CLIENT | FL_NOTARGET;
2399 }
2400
2401 void vehicles_enter (entity pl, entity veh);
2402 void PlayerUseKey(entity this)
2403 {
2404         if (!IS_PLAYER(this))
2405                 return;
2406
2407         if(this.vehicle)
2408         {
2409                 if(!game_stopped)
2410                 {
2411                         vehicles_exit(this.vehicle, VHEF_NORMAL);
2412                         return;
2413                 }
2414         }
2415         else if(autocvar_g_vehicles_enter)
2416         {
2417                 if(!STAT(FROZEN, this))
2418                 if(!IS_DEAD(this))
2419                 if(!game_stopped)
2420                 {
2421                         entity head, closest_target = NULL;
2422                         head = WarpZone_FindRadius(this.origin, autocvar_g_vehicles_enter_radius, true);
2423
2424                         while(head) // find the closest acceptable target to enter
2425                         {
2426                                 if(IS_VEHICLE(head))
2427                                 if(!IS_DEAD(head))
2428                                 if(!head.owner || ((head.vehicle_flags & VHF_MULTISLOT) && SAME_TEAM(head.owner, this)))
2429                                 if(head.takedamage != DAMAGE_NO)
2430                                 {
2431                                         if(closest_target)
2432                                         {
2433                                                 if(vlen2(this.origin - head.origin) < vlen2(this.origin - closest_target.origin))
2434                                                 { closest_target = head; }
2435                                         }
2436                                         else { closest_target = head; }
2437                                 }
2438
2439                                 head = head.chain;
2440                         }
2441
2442                         if(closest_target) { vehicles_enter(this, closest_target); return; }
2443                 }
2444         }
2445
2446         // a use key was pressed; call handlers
2447         MUTATOR_CALLHOOK(PlayerUseKey, this);
2448 }
2449
2450
2451 /*
2452 =============
2453 PlayerPreThink
2454
2455 Called every frame for each client before the physics are run
2456 =============
2457 */
2458 .float last_vehiclecheck;
2459 void PlayerPreThink (entity this)
2460 {
2461         STAT(GUNALIGN, this) = CS(this).cvar_cl_gunalign; // TODO
2462         STAT(MOVEVARS_CL_TRACK_CANJUMP, this) = CS(this).cvar_cl_movement_track_canjump;
2463
2464         WarpZone_PlayerPhysics_FixVAngle(this);
2465
2466         if (frametime) {
2467                 // physics frames: update anticheat stuff
2468                 anticheat_prethink(this);
2469         }
2470
2471         if (blockSpectators && frametime) {
2472                 // WORKAROUND: only use dropclient in server frames (frametime set).
2473                 // Never use it in cl_movement frames (frametime zero).
2474                 checkSpectatorBlock(this);
2475         }
2476
2477         zoomstate_set = false;
2478
2479         // Check for nameless players
2480         if (this.netname == "" || this.netname != CS(this).netname_previous)
2481         {
2482                 bool assume_unchanged = (CS(this).netname_previous == "");
2483                 if (isInvisibleString(this.netname))
2484                 {
2485                         this.netname = strzone(sprintf("Player#%d", this.playerid));
2486                         assume_unchanged = false;
2487                         // stuffcmd(this, strcat("name ", this.netname, "\n")); // maybe?
2488                 }
2489                 if (!assume_unchanged && autocvar_sv_eventlog)
2490                         GameLogEcho(strcat(":name:", ftos(this.playerid), ":", playername(this, false)));
2491                 strcpy(CS(this).netname_previous, this.netname);
2492         }
2493
2494         // version nagging
2495         if (CS(this).version_nagtime && CS(this).cvar_g_xonoticversion && time > CS(this).version_nagtime) {
2496         CS(this).version_nagtime = 0;
2497         if (strstrofs(CS(this).cvar_g_xonoticversion, "git", 0) >= 0 || strstrofs(CS(this).cvar_g_xonoticversion, "autobuild", 0) >= 0) {
2498             // git client
2499         } else if (strstrofs(autocvar_g_xonoticversion, "git", 0) >= 0 || strstrofs(autocvar_g_xonoticversion, "autobuild", 0) >= 0) {
2500             // git server
2501             Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_BETA, autocvar_g_xonoticversion, CS(this).cvar_g_xonoticversion);
2502         } else {
2503             int r = vercmp(CS(this).cvar_g_xonoticversion, autocvar_g_xonoticversion);
2504             if (r < 0) { // old client
2505                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_OUTDATED, autocvar_g_xonoticversion, CS(this).cvar_g_xonoticversion);
2506             } else if (r > 0) { // old server
2507                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_OLD, autocvar_g_xonoticversion, CS(this).cvar_g_xonoticversion);
2508             }
2509         }
2510     }
2511
2512         // GOD MODE info
2513         if (!(this.flags & FL_GODMODE) && this.max_armorvalue)
2514         {
2515                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_GODMODE_OFF, this.max_armorvalue);
2516                 this.max_armorvalue = 0;
2517         }
2518
2519         if(IS_PLAYER(this))
2520         {
2521                 if (STAT(FROZEN, this) == 2)
2522                 {
2523                         STAT(REVIVE_PROGRESS, this) = bound(0, STAT(REVIVE_PROGRESS, this) + frametime * this.revive_speed, 1);
2524                         this.health = max(1, STAT(REVIVE_PROGRESS, this) * start_health);
2525                         this.iceblock.alpha = bound(0.2, 1 - STAT(REVIVE_PROGRESS, this), 1);
2526
2527                         if (STAT(REVIVE_PROGRESS, this) >= 1)
2528                                 Unfreeze(this);
2529                 }
2530                 else if (STAT(FROZEN, this) == 3)
2531                 {
2532                         STAT(REVIVE_PROGRESS, this) = bound(0, STAT(REVIVE_PROGRESS, this) - frametime * this.revive_speed, 1);
2533                         this.health = max(0, autocvar_g_nades_ice_health + (start_health-autocvar_g_nades_ice_health) * STAT(REVIVE_PROGRESS, this) );
2534
2535                         if (this.health < 1)
2536                         {
2537                                 if (this.vehicle)
2538                                         vehicles_exit(this.vehicle, VHEF_RELEASE);
2539                                 if(this.event_damage)
2540                                         this.event_damage(this, this, this.frozen_by, 1, DEATH_NADE_ICE_FREEZE.m_id, DMG_NOWEP, this.origin, '0 0 0');
2541                         }
2542                         else if (STAT(REVIVE_PROGRESS, this) <= 0)
2543                                 Unfreeze(this);
2544                 }
2545         }
2546
2547         MUTATOR_CALLHOOK(PlayerPreThink, this);
2548
2549         if(autocvar_g_vehicles_enter && (time > this.last_vehiclecheck) && !game_stopped && !this.vehicle)
2550         if(IS_PLAYER(this) && !STAT(FROZEN, this) && !IS_DEAD(this))
2551         {
2552                 FOREACH_ENTITY_RADIUS(this.origin, autocvar_g_vehicles_enter_radius, IS_VEHICLE(it),
2553                 {
2554                         if(!IS_DEAD(it) && it.takedamage != DAMAGE_NO)
2555                         if((it.vehicle_flags & VHF_MULTISLOT) && SAME_TEAM(it.owner, this))
2556                         {
2557                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER_GUNNER);
2558                         }
2559                         else if(!it.owner)
2560                         {
2561                                 if(!it.team || SAME_TEAM(this, it))
2562                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER);
2563                                 else if(autocvar_g_vehicles_steal)
2564                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER_STEAL);
2565                         }
2566                 });
2567
2568                 this.last_vehiclecheck = time + 1;
2569         }
2570
2571         if(!CS(this).cvar_cl_newusekeysupported) // FIXME remove this - it was a stupid idea to begin with, we can JUST use the button
2572         {
2573                 if(PHYS_INPUT_BUTTON_USE(this) && !CS(this).usekeypressed)
2574                         PlayerUseKey(this);
2575                 CS(this).usekeypressed = PHYS_INPUT_BUTTON_USE(this);
2576         }
2577
2578         if (IS_REAL_CLIENT(this))
2579                 PrintWelcomeMessage(this);
2580
2581         if (IS_PLAYER(this)) {
2582                 if(!PlayerThink(this))
2583                         return;
2584         }
2585         else if (game_stopped || intermission_running) {
2586                 if(intermission_running)
2587                         IntermissionThink(this);
2588                 return;
2589         }
2590         else if (IS_OBSERVER(this)) {
2591                 ObserverThink(this);
2592         }
2593         else if (IS_SPEC(this)) {
2594                 SpectatorThink(this);
2595         }
2596
2597         // WEAPONTODO: Add weapon request for this
2598         if (!zoomstate_set) {
2599                 bool wep_zoomed = false;
2600                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2601                 {
2602                         .entity weaponentity = weaponentities[slot];
2603                         Weapon thiswep = this.(weaponentity).m_weapon;
2604                         if(thiswep != WEP_Null && thiswep.wr_zoom)
2605                                 wep_zoomed += thiswep.wr_zoom(thiswep, this);
2606                 }
2607                 SetZoomState(this, PHYS_INPUT_BUTTON_ZOOM(this) || PHYS_INPUT_BUTTON_ZOOMSCRIPT(this) || wep_zoomed);
2608     }
2609
2610         if (CS(this).teamkill_soundtime && time > CS(this).teamkill_soundtime)
2611         {
2612                 CS(this).teamkill_soundtime = 0;
2613
2614                 entity e = CS(this).teamkill_soundsource;
2615                 entity oldpusher = e.pusher;
2616                 e.pusher = this;
2617                 PlayerSound(e, playersound_teamshoot, CH_VOICE, VOL_BASEVOICE, VOICETYPE_LASTATTACKER_ONLY);
2618                 e.pusher = oldpusher;
2619         }
2620
2621         if (CS(this).taunt_soundtime && time > CS(this).taunt_soundtime) {
2622                 CS(this).taunt_soundtime = 0;
2623                 PlayerSound(this, playersound_taunt, CH_VOICE, VOL_BASEVOICE, VOICETYPE_AUTOTAUNT);
2624         }
2625
2626         target_voicescript_next(this);
2627
2628         // WEAPONTODO: Move into weaponsystem somehow
2629         // if a player goes unarmed after holding a loaded weapon, empty his clip size and remove the crosshair ammo ring
2630         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2631         {
2632                 .entity weaponentity = weaponentities[slot];
2633                 if(this.(weaponentity).m_weapon == WEP_Null)
2634                         this.(weaponentity).clip_load = this.(weaponentity).clip_size = 0;
2635         }
2636 }
2637
2638 void DrownPlayer(entity this)
2639 {
2640         if(IS_DEAD(this) || game_stopped || time < game_starttime)
2641                 return;
2642
2643         if (this.waterlevel != WATERLEVEL_SUBMERGED || this.vehicle)
2644         {
2645                 if(this.air_finished < time)
2646                         PlayerSound(this, playersound_gasp, CH_PLAYER, VOL_BASE, VOICETYPE_PLAYERSOUND);
2647                 this.air_finished = time + autocvar_g_balance_contents_drowndelay;
2648         }
2649         else if (this.air_finished < time)
2650         {       // drown!
2651                 if (this.pain_finished < time)
2652                 {
2653                         Damage (this, NULL, NULL, autocvar_g_balance_contents_playerdamage_drowning * autocvar_g_balance_contents_damagerate, DEATH_DROWN.m_id, DMG_NOWEP, this.origin, '0 0 0');
2654                         this.pain_finished = time + 0.5;
2655                 }
2656         }
2657 }
2658
2659 .bool move_qcphysics;
2660
2661 void Player_Physics(entity this)
2662 {
2663         set_movetype(this, this.move_movetype);
2664
2665         if(!this.move_qcphysics)
2666                 return;
2667
2668         if(!frametime && !CS(this).pm_frametime)
2669                 return;
2670
2671         Movetype_Physics_NoMatchTicrate(this, CS(this).pm_frametime, true);
2672
2673         CS(this).pm_frametime = 0;
2674 }
2675
2676 /*
2677 =============
2678 PlayerPostThink
2679
2680 Called every frame for each client after the physics are run
2681 =============
2682 */
2683 void PlayerPostThink (entity this)
2684 {
2685         Player_Physics(this);
2686
2687         if (sv_maxidle > 0)
2688         if (frametime) // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2689         if (IS_REAL_CLIENT(this))
2690         if (IS_PLAYER(this) || sv_maxidle_spectatorsareidle)
2691         {
2692                 int totalClients = 0;
2693                 if(sv_maxidle_slots > 0)
2694                 {
2695                         FOREACH_CLIENT(IS_REAL_CLIENT(it) || sv_maxidle_slots_countbots,
2696                         {
2697                                 ++totalClients;
2698                         });
2699                 }
2700
2701                 if (sv_maxidle_slots > 0 && (maxclients - totalClients) > sv_maxidle_slots)
2702                 { /* do nothing */ }
2703                 else if (time - CS(this).parm_idlesince < 1) // instead of (time == this.parm_idlesince) to support sv_maxidle <= 10
2704                 {
2705                         if (CS(this).idlekick_lasttimeleft)
2706                         {
2707                                 CS(this).idlekick_lasttimeleft = 0;
2708                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_IDLING);
2709                         }
2710                 }
2711                 else
2712                 {
2713                         float timeleft = ceil(sv_maxidle - (time - CS(this).parm_idlesince));
2714                         if (timeleft == min(10, sv_maxidle - 1)) { // - 1 to support sv_maxidle <= 10
2715                                 if (!CS(this).idlekick_lasttimeleft)
2716                                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_DISCONNECT_IDLING, timeleft);
2717                         }
2718                         if (timeleft <= 0) {
2719                                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_QUIT_KICK_IDLING, this.netname);
2720                                 dropclient(this);
2721                                 return;
2722                         }
2723                         else if (timeleft <= 10) {
2724                                 if (timeleft != CS(this).idlekick_lasttimeleft) {
2725                                     Send_Notification(NOTIF_ONE, this, MSG_ANNCE, Announcer_PickNumber(CNT_IDLE, timeleft));
2726                 }
2727                                 CS(this).idlekick_lasttimeleft = timeleft;
2728                         }
2729                 }
2730         }
2731
2732         CheatFrame(this);
2733
2734         if (game_stopped)
2735         {
2736                 this.solid = SOLID_NOT;
2737                 this.takedamage = DAMAGE_NO;
2738                 set_movetype(this, MOVETYPE_NONE);
2739         }
2740
2741         if (IS_PLAYER(this)) {
2742                 if(this.death_time == time && IS_DEAD(this))
2743                 {
2744                         // player's bbox gets resized now, instead of in the damage event that killed the player,
2745                         // once all the damage events of this frame have been processed with normal size
2746                         this.maxs.z = 5;
2747                         setsize(this, this.mins, this.maxs);
2748                 }
2749                 DrownPlayer(this);
2750                 UpdateChatBubble(this);
2751                 if (CS(this).impulse) ImpulseCommands(this);
2752                 if (game_stopped)
2753                 {
2754                         CSQCMODEL_AUTOUPDATE(this);
2755                         return;
2756                 }
2757                 GetPressedKeys(this);
2758         }
2759
2760         if (this.waypointsprite_attachedforcarrier) {
2761             vector v = healtharmor_maxdamage(this.health, this.armorvalue, autocvar_g_balance_armor_blockpercent, DEATH_WEAPON.m_id);
2762                 WaypointSprite_UpdateHealth(this.waypointsprite_attachedforcarrier, '1 0 0' * v);
2763     }
2764
2765         playerdemo_write(this);
2766
2767         CSQCMODEL_AUTOUPDATE(this);
2768 }
2769
2770 // hack to copy the button fields from the client entity to the Client State
2771 void PM_UpdateButtons(entity this, entity store)
2772 {
2773         if(this.impulse)
2774                 store.impulse = this.impulse;
2775         this.impulse = 0;
2776
2777         bool typing = this.buttonchat;
2778
2779         store.button0 = (typing) ? 0 : this.button0;
2780         //button1?!
2781         store.button2 = (typing) ? 0 : this.button2;
2782         store.button3 = (typing) ? 0 : this.button3;
2783         store.button4 = this.button4;
2784         store.button5 = (typing) ? 0 : this.button5;
2785         store.button6 = this.button6;
2786         store.button7 = this.button7;
2787         store.button8 = this.button8;
2788         store.button9 = this.button9;
2789         store.button10 = this.button10;
2790         store.button11 = this.button11;
2791         store.button12 = this.button12;
2792         store.button13 = this.button13;
2793         store.button14 = this.button14;
2794         store.button15 = this.button15;
2795         store.button16 = this.button16;
2796         store.buttonuse = this.buttonuse;
2797         store.buttonchat = this.buttonchat;
2798
2799         store.cursor_active = this.cursor_active;
2800         store.cursor_screen = this.cursor_screen;
2801         store.cursor_trace_start = this.cursor_trace_start;
2802         store.cursor_trace_endpos = this.cursor_trace_endpos;
2803         store.cursor_trace_ent = this.cursor_trace_ent;
2804
2805         store.ping = this.ping;
2806         store.ping_packetloss = this.ping_packetloss;
2807         store.ping_movementloss = this.ping_movementloss;
2808
2809         store.v_angle = this.v_angle;
2810         store.movement = (typing) ? '0 0 0' : this.movement;
2811 }
2812
2813 NET_HANDLE(fpsreport, bool)
2814 {
2815         int fps = ReadShort();
2816         PlayerScore_Set(sender, SP_FPS, fps);
2817         return true;
2818 }