9ba4feeb114e3970365204a2d0b0e9e344dfaa37
[xonotic/xonotic-data.pk3dir.git] / qcsrc / server / client.qc
1 #include "client.qh"
2
3 #include <server/defs.qh>
4 #include <server/miscfunctions.qh>
5 #include <common/effects/all.qh>
6 #include "anticheat.qh"
7 #include "impulse.qh"
8 #include "player.qh"
9 #include "ipban.qh"
10 #include "miscfunctions.qh"
11 #include "portals.qh"
12 #include "teamplay.qh"
13 #include "spawnpoints.qh"
14 #include "resources.qh"
15 #include "g_damage.qh"
16 #include "handicap.qh"
17 #include "g_hook.qh"
18 #include "command/common.qh"
19 #include "command/vote.qh"
20 #include "clientkill.qh"
21 #include "cheats.qh"
22 #include "g_world.qh"
23 #include "race.qh"
24 #include "antilag.qh"
25 #include "campaign.qh"
26 #include "command/common.qh"
27 #include "scores_rules.qh"
28
29 #include "bot/api.qh"
30
31 #include "../common/ent_cs.qh"
32 #include "../common/wepent.qh"
33 #include <common/state.qh>
34
35 #include "compat/quake3.qh"
36
37 #include <common/effects/qc/globalsound.qh>
38
39 #include "../common/mapobjects/func/conveyor.qh"
40 #include "../common/mapobjects/teleporters.qh"
41 #include "../common/mapobjects/target/spawnpoint.qh"
42 #include <common/mapobjects/trigger/counter.qh>
43
44 #include "../common/vehicles/all.qh"
45
46 #include "weapons/hitplot.qh"
47 #include "weapons/weaponsystem.qh"
48
49 #include "../common/net_notice.qh"
50 #include "../common/net_linked.qh"
51 #include "../common/physics/player.qh"
52
53 #include <common/vehicles/sv_vehicles.qh>
54
55 #include "../common/items/_mod.qh"
56
57 #include "../common/mutators/mutator/waypoints/all.qh"
58 #include "../common/mutators/mutator/instagib/sv_instagib.qh"
59 #include <common/gamemodes/_mod.qh>
60
61 #include "../common/mapobjects/subs.qh"
62 #include "../common/mapobjects/triggers.qh"
63 #include "../common/mapobjects/trigger/secret.qh"
64
65 #include "../common/minigames/sv_minigames.qh"
66
67 #include "../common/items/inventory.qh"
68
69 #include "../common/monsters/sv_monsters.qh"
70
71 #include "../lib/warpzone/server.qh"
72
73 #include <common/mutators/mutator/overkill/oknex.qh>
74
75 STATIC_METHOD(Client, Add, void(Client this, int _team))
76 {
77     ClientConnect(this);
78     TRANSMUTE(Player, this);
79     this.frame = 12; // 7
80     this.team = _team;
81     PutClientInServer(this);
82 }
83
84 STATIC_METHOD(Client, Remove, void(Client this))
85 {
86     TRANSMUTE(Observer, this);
87     PutClientInServer(this);
88     ClientDisconnect(this);
89 }
90
91 void send_CSQC_teamnagger() {
92         WriteHeader(MSG_BROADCAST, TE_CSQC_TEAMNAGGER);
93 }
94
95 int CountSpectators(entity player, entity to)
96 {
97         if(!player) { return 0; } // not sure how, but best to be safe
98
99         int spec_count = 0;
100
101         FOREACH_CLIENT(IS_REAL_CLIENT(it) && IS_SPEC(it) && it != to && it.enemy == player,
102         {
103                 spec_count++;
104         });
105
106         return spec_count;
107 }
108
109 void WriteSpectators(entity player, entity to)
110 {
111         if(!player) { return; } // not sure how, but best to be safe
112
113         FOREACH_CLIENT(IS_REAL_CLIENT(it) && IS_SPEC(it) && it != to && it.enemy == player,
114         {
115                 WriteByte(MSG_ENTITY, num_for_edict(it));
116         });
117 }
118
119 bool ClientData_Send(entity this, entity to, int sf)
120 {
121         assert(to == this.owner, return false);
122
123         entity e = to;
124         if (IS_SPEC(e)) e = e.enemy;
125
126         sf = 0;
127         if (CS(e).race_completed)       sf |= BIT(0); // forced scoreboard
128         if (CS(to).spectatee_status)    sf |= BIT(1); // spectator ent number follows
129         if (CS(e).zoomstate)            sf |= BIT(2); // zoomed
130         if (autocvar_sv_showspectators) sf |= BIT(4); // show spectators
131
132         WriteHeader(MSG_ENTITY, ENT_CLIENT_CLIENTDATA);
133         WriteByte(MSG_ENTITY, sf);
134
135         if (sf & BIT(1))
136                 WriteByte(MSG_ENTITY, CS(to).spectatee_status);
137
138         if(sf & BIT(4))
139         {
140                 float specs = CountSpectators(e, to);
141                 WriteByte(MSG_ENTITY, specs);
142                 WriteSpectators(e, to);
143         }
144
145         return true;
146 }
147
148 void ClientData_Attach(entity this)
149 {
150         Net_LinkEntity(CS(this).clientdata = new_pure(clientdata), false, 0, ClientData_Send);
151         CS(this).clientdata.drawonlytoclient = this;
152         CS(this).clientdata.owner = this;
153 }
154
155 void ClientData_Detach(entity this)
156 {
157         delete(CS(this).clientdata);
158         CS(this).clientdata = NULL;
159 }
160
161 void ClientData_Touch(entity e)
162 {
163         entity cd = CS(e).clientdata;
164         if (cd) { cd.SendFlags = 1; }
165
166         // make it spectatable
167         FOREACH_CLIENT(IS_REAL_CLIENT(it) && it != e && IS_SPEC(it) && it.enemy == e,
168         {
169                 entity cd = CS(it).clientdata;
170                 if (cd) { cd.SendFlags = 1; }
171         });
172 }
173
174
175 /*
176 =============
177 CheckPlayerModel
178
179 Checks if the argument string can be a valid playermodel.
180 Returns a valid one in doubt.
181 =============
182 */
183 string FallbackPlayerModel;
184 string CheckPlayerModel(string plyermodel) {
185         if(FallbackPlayerModel != cvar_defstring("_cl_playermodel"))
186         {
187                 // note: we cannot summon Don Strunzone here, some player may
188                 // still have the model string set. In case anyone manages how
189                 // to change a cvar default, we'll have a small leak here.
190                 FallbackPlayerModel = strzone(cvar_defstring("_cl_playermodel"));
191         }
192         // only in right path
193         if( substring(plyermodel,0,14) != "models/player/")
194                 return FallbackPlayerModel;
195         // only good file extensions
196         if(substring(plyermodel,-4,4) != ".zym")
197         if(substring(plyermodel,-4,4) != ".dpm")
198         if(substring(plyermodel,-4,4) != ".iqm")
199         if(substring(plyermodel,-4,4) != ".md3")
200         if(substring(plyermodel,-4,4) != ".psk")
201                 return FallbackPlayerModel;
202         // forbid the LOD models
203         if(substring(plyermodel, -9,5) == "_lod1")
204                 return FallbackPlayerModel;
205         if(substring(plyermodel, -9,5) == "_lod2")
206                 return FallbackPlayerModel;
207         if(plyermodel != strtolower(plyermodel))
208                 return FallbackPlayerModel;
209         // also, restrict to server models
210         if(autocvar_sv_servermodelsonly)
211         {
212                 if(!fexists(plyermodel))
213                         return FallbackPlayerModel;
214         }
215         return plyermodel;
216 }
217
218 void setplayermodel(entity e, string modelname)
219 {
220         precache_model(modelname);
221         _setmodel(e, modelname);
222         player_setupanimsformodel(e);
223         if(!autocvar_g_debug_globalsounds)
224                 UpdatePlayerSounds(e);
225 }
226
227 /** putting a client as observer in the server */
228 void PutObserverInServer(entity this)
229 {
230     bool mutator_returnvalue = MUTATOR_CALLHOOK(MakePlayerObserver, this);
231         PlayerState_detach(this);
232
233         if (IS_PLAYER(this))
234         {
235                 if(GetResource(this, RES_HEALTH) >= 1)
236                 {
237                         // despawn effect
238                         Send_Effect(EFFECT_SPAWN_NEUTRAL, this.origin, '0 0 0', 1);
239                 }
240
241                 // was a player, recount votes and ready status
242                 if(IS_REAL_CLIENT(this))
243                 {
244                         if (vote_called) { VoteCount(false); }
245                         ReadyCount();
246                 }
247     }
248
249     {
250         entity spot = SelectSpawnPoint(this, true);
251         if (!spot) LOG_FATAL("No spawnpoints for observers?!?");
252         this.angles = vec2(spot.angles);
253         this.fixangle = true;
254         // offset it so that the spectator spawns higher off the ground, looks better this way
255         setorigin(this, spot.origin + STAT(PL_VIEW_OFS, this));
256         if (IS_REAL_CLIENT(this))
257         {
258             msg_entity = this;
259             WriteByte(MSG_ONE, SVC_SETVIEW);
260             WriteEntity(MSG_ONE, this);
261         }
262         // give the spectator some space between walls for MOVETYPE_FLY_WORLDONLY
263         // so that your view doesn't go into the ceiling with MOVETYPE_FLY_WORLDONLY, previously "PL_VIEW_OFS"
264         if(!autocvar_g_debug_globalsounds)
265         {
266                 // needed for player sounds
267                 this.model = "";
268                 FixPlayermodel(this);
269         }
270         setmodel(this, MDL_Null);
271         setsize(this, STAT(PL_CROUCH_MIN, this), STAT(PL_CROUCH_MAX, this));
272         this.view_ofs = '0 0 0';
273     }
274
275     RemoveGrapplingHooks(this);
276         Portal_ClearAll(this);
277         Unfreeze(this, false);
278         SetSpectatee(this, NULL);
279
280         if (this.alivetime)
281         {
282                 if (!warmup_stage)
283                         PlayerStats_GameReport_Event_Player(this, PLAYERSTATS_ALIVETIME, time - this.alivetime);
284                 this.alivetime = 0;
285         }
286
287         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
288
289         WaypointSprite_PlayerDead(this);
290
291         if (CS(this).killcount != FRAGS_SPECTATOR)
292         {
293                 if(!game_stopped)
294                 if(autocvar_g_chat_nospectators == 1 || (!warmup_stage && autocvar_g_chat_nospectators == 2))
295                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_CHAT_NOSPECTATORS);
296         }
297
298         accuracy_resend(this);
299
300         CS(this).spectatortime = time;
301         if(this.bot_attack)
302                 IL_REMOVE(g_bot_targets, this);
303         this.bot_attack = false;
304         if(this.monster_attack)
305                 IL_REMOVE(g_monster_targets, this);
306         this.monster_attack = false;
307     STAT(HUD, this) = HUD_NORMAL;
308         TRANSMUTE(Observer, this);
309         this.iscreature = false;
310         this.teleportable = TELEPORT_SIMPLE;
311         if(this.damagedbycontents)
312                 IL_REMOVE(g_damagedbycontents, this);
313         this.damagedbycontents = false;
314         SetResourceExplicit(this, RES_HEALTH, FRAGS_SPECTATOR);
315         SetSpectatee_status(this, etof(this));
316         this.takedamage = DAMAGE_NO;
317         this.solid = SOLID_NOT;
318         set_movetype(this, MOVETYPE_FLY_WORLDONLY); // user preference is controlled by playerprethink
319         this.flags = FL_CLIENT | FL_NOTARGET;
320         this.effects = 0;
321         SetResourceExplicit(this, RES_ARMOR, autocvar_g_balance_armor_start); // was 666?!
322         this.pauserotarmor_finished = 0;
323         this.pauserothealth_finished = 0;
324         this.pauseregen_finished = 0;
325         this.damageforcescale = 0;
326         this.death_time = 0;
327         this.respawn_flags = 0;
328         this.respawn_time = 0;
329         STAT(RESPAWN_TIME, this) = 0;
330         this.alpha = 0;
331         this.scale = 0;
332         this.fade_time = 0;
333         this.pain_frame = 0;
334         this.pain_finished = 0;
335         this.strength_finished = 0;
336         this.invincible_finished = 0;
337         this.superweapons_finished = 0;
338         //this.dphitcontentsmask = 0;
339         this.dphitcontentsmask = DPCONTENTS_SOLID;
340         if (autocvar_g_playerclip_collisions)
341                 this.dphitcontentsmask |= DPCONTENTS_PLAYERCLIP;
342         this.pushltime = 0;
343         this.istypefrag = 0;
344         setthink(this, func_null);
345         this.nextthink = 0;
346         this.deadflag = DEAD_NO;
347         this.crouch = false;
348         STAT(REVIVE_PROGRESS, this) = 0;
349         this.revival_time = 0;
350         this.draggable = drag_undraggable;
351
352         this.items = 0;
353         STAT(WEAPONS, this) = '0 0 0';
354         this.drawonlytoclient = this;
355
356         this.viewloc = NULL;
357
358         //this.spawnpoint_targ = NULL; // keep it so they can return to where they were?
359
360         this.weaponmodel = "";
361         for (int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
362         {
363                 this.weaponentities[slot] = NULL;
364         }
365         this.exteriorweaponentity = NULL;
366         CS(this).killcount = FRAGS_SPECTATOR;
367         this.velocity = '0 0 0';
368         this.avelocity = '0 0 0';
369         this.punchangle = '0 0 0';
370         this.punchvector = '0 0 0';
371         this.oldvelocity = this.velocity;
372         this.fire_endtime = -1;
373         this.event_damage = func_null;
374         this.event_heal = func_null;
375
376         for(int slot = 0; slot < MAX_AXH; ++slot)
377         {
378                 entity axh = this.(AuxiliaryXhair[slot]);
379                 this.(AuxiliaryXhair[slot]) = NULL;
380
381                 if(axh.owner == this && axh != NULL && !wasfreed(axh))
382                         delete(axh);
383         }
384
385         if (mutator_returnvalue)
386         {
387                 // mutator prevents resetting teams+score
388         }
389         else
390         {
391                 SetPlayerTeam(this, -1, TEAM_CHANGE_SPECTATOR);
392                 this.frags = FRAGS_SPECTATOR;
393         }
394         if (CS(this).just_joined)
395                 CS(this).just_joined = false;
396 }
397
398 int player_getspecies(entity this)
399 {
400         get_model_parameters(this.model, this.skin);
401         int s = get_model_parameters_species;
402         get_model_parameters(string_null, 0);
403         if (s < 0) return SPECIES_HUMAN;
404         return s;
405 }
406
407 .float model_randomizer;
408 void FixPlayermodel(entity player)
409 {
410         string defaultmodel = "";
411         int defaultskin = 0;
412         if(autocvar_sv_defaultcharacter)
413         {
414                 if(teamplay)
415                 {
416                         switch(player.team)
417                         {
418                                 case NUM_TEAM_1: defaultmodel = autocvar_sv_defaultplayermodel_red; defaultskin = autocvar_sv_defaultplayerskin_red; break;
419                                 case NUM_TEAM_2: defaultmodel = autocvar_sv_defaultplayermodel_blue; defaultskin = autocvar_sv_defaultplayerskin_blue; break;
420                                 case NUM_TEAM_3: defaultmodel = autocvar_sv_defaultplayermodel_yellow; defaultskin = autocvar_sv_defaultplayerskin_yellow; break;
421                                 case NUM_TEAM_4: defaultmodel = autocvar_sv_defaultplayermodel_pink; defaultskin = autocvar_sv_defaultplayerskin_pink; break;
422                         }
423                 }
424
425                 if(defaultmodel == "")
426                 {
427                         defaultmodel = autocvar_sv_defaultplayermodel;
428                         defaultskin = autocvar_sv_defaultplayerskin;
429                 }
430
431                 int n = tokenize_console(defaultmodel);
432                 if(n > 0)
433                 {
434                         defaultmodel = argv(floor(n * CS(player).model_randomizer));
435                         // However, do NOT randomize if the player-selected model is in the list.
436                         for (int i = 0; i < n; ++i)
437                                 if ((argv(i) == player.playermodel && defaultskin == stof(player.playerskin)) || argv(i) == strcat(player.playermodel, ":", player.playerskin))
438                                         defaultmodel = argv(i);
439                 }
440
441                 int i = strstrofs(defaultmodel, ":", 0);
442                 if(i >= 0)
443                 {
444                         defaultskin = stof(substring(defaultmodel, i+1, -1));
445                         defaultmodel = substring(defaultmodel, 0, i);
446                 }
447         }
448         if(autocvar_sv_defaultcharacterskin && !defaultskin)
449         {
450                 if(teamplay)
451                 {
452                         switch(player.team)
453                         {
454                                 case NUM_TEAM_1: defaultskin = autocvar_sv_defaultplayerskin_red; break;
455                                 case NUM_TEAM_2: defaultskin = autocvar_sv_defaultplayerskin_blue; break;
456                                 case NUM_TEAM_3: defaultskin = autocvar_sv_defaultplayerskin_yellow; break;
457                                 case NUM_TEAM_4: defaultskin = autocvar_sv_defaultplayerskin_pink; break;
458                         }
459                 }
460
461                 if(!defaultskin)
462                         defaultskin = autocvar_sv_defaultplayerskin;
463         }
464
465         MUTATOR_CALLHOOK(FixPlayermodel, defaultmodel, defaultskin, player);
466         defaultmodel = M_ARGV(0, string);
467         defaultskin = M_ARGV(1, int);
468
469         bool chmdl = false;
470         int oldskin;
471         if(defaultmodel != "")
472         {
473                 if (defaultmodel != player.model)
474                 {
475                         vector m1 = player.mins;
476                         vector m2 = player.maxs;
477                         setplayermodel (player, defaultmodel);
478                         setsize (player, m1, m2);
479                         chmdl = true;
480                 }
481
482                 oldskin = player.skin;
483                 player.skin = defaultskin;
484         } else {
485                 if (player.playermodel != player.model || player.playermodel == "")
486                 {
487                         player.playermodel = CheckPlayerModel(player.playermodel); // this is never "", so no endless loop
488                         vector m1 = player.mins;
489                         vector m2 = player.maxs;
490                         setplayermodel (player, player.playermodel);
491                         setsize (player, m1, m2);
492                         chmdl = true;
493                 }
494
495                 if(!autocvar_sv_defaultcharacterskin)
496                 {
497                         oldskin = player.skin;
498                         player.skin = stof(player.playerskin);
499                 }
500                 else
501                 {
502                         oldskin = player.skin;
503                         player.skin = defaultskin;
504                 }
505         }
506
507         if(chmdl || oldskin != player.skin) // model or skin has changed
508         {
509                 player.species = player_getspecies(player); // update species
510                 if(!autocvar_g_debug_globalsounds)
511                         UpdatePlayerSounds(player); // update skin sounds
512         }
513
514         if(!teamplay)
515                 if(strlen(autocvar_sv_defaultplayercolors))
516                         if(player.clientcolors != stof(autocvar_sv_defaultplayercolors))
517                                 setcolor(player, stof(autocvar_sv_defaultplayercolors));
518 }
519
520 void PutPlayerInServer(entity this)
521 {
522         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
523
524         PlayerState_attach(this);
525         accuracy_resend(this);
526
527         if (this.team < 0)
528                 TeamBalance_JoinBestTeam(this);
529
530         entity spot = SelectSpawnPoint(this, false);
531         if (!spot) {
532                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_JOIN_NOSPAWNS);
533                 return; // spawn failed
534         }
535
536         TRANSMUTE(Player, this);
537
538         CS(this).wasplayer = true;
539         this.iscreature = true;
540         this.teleportable = TELEPORT_NORMAL;
541         if(!this.damagedbycontents)
542                 IL_PUSH(g_damagedbycontents, this);
543         this.damagedbycontents = true;
544         set_movetype(this, MOVETYPE_WALK);
545         this.solid = SOLID_SLIDEBOX;
546         this.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_SOLID;
547         if (autocvar_g_playerclip_collisions)
548                 this.dphitcontentsmask |= DPCONTENTS_PLAYERCLIP;
549         if (IS_BOT_CLIENT(this) && autocvar_g_botclip_collisions)
550                 this.dphitcontentsmask |= DPCONTENTS_BOTCLIP;
551         this.frags = FRAGS_PLAYER;
552         if (INDEPENDENT_PLAYERS) MAKE_INDEPENDENT_PLAYER(this);
553         this.flags = FL_CLIENT | FL_PICKUPITEMS;
554         if (autocvar__notarget)
555                 this.flags |= FL_NOTARGET;
556         this.takedamage = DAMAGE_AIM;
557         this.effects = EF_TELEPORT_BIT | EF_RESTARTANIM_BIT;
558
559         if (warmup_stage) {
560                 SetResource(this, RES_SHELLS, warmup_start_ammo_shells);
561                 SetResource(this, RES_BULLETS, warmup_start_ammo_nails);
562                 SetResource(this, RES_ROCKETS, warmup_start_ammo_rockets);
563                 SetResource(this, RES_CELLS, warmup_start_ammo_cells);
564                 SetResource(this, RES_PLASMA, warmup_start_ammo_plasma);
565                 SetResource(this, RES_FUEL, warmup_start_ammo_fuel);
566                 SetResource(this, RES_HEALTH, warmup_start_health);
567                 SetResource(this, RES_ARMOR, warmup_start_armorvalue);
568                 STAT(WEAPONS, this) = WARMUP_START_WEAPONS;
569         } else {
570                 SetResource(this, RES_SHELLS, start_ammo_shells);
571                 SetResource(this, RES_BULLETS, start_ammo_nails);
572                 SetResource(this, RES_ROCKETS, start_ammo_rockets);
573                 SetResource(this, RES_CELLS, start_ammo_cells);
574                 SetResource(this, RES_PLASMA, start_ammo_plasma);
575                 SetResource(this, RES_FUEL, start_ammo_fuel);
576                 SetResource(this, RES_HEALTH, start_health);
577                 SetResource(this, RES_ARMOR, start_armorvalue);
578                 STAT(WEAPONS, this) = start_weapons;
579                 if (MUTATOR_CALLHOOK(ForbidRandomStartWeapons, this) == false)
580                 {
581                         GiveRandomWeapons(this, random_start_weapons_count,
582                                 autocvar_g_random_start_weapons, random_start_ammo);
583                 }
584         }
585         SetSpectatee_status(this, 0);
586
587         PS(this).dual_weapons = '0 0 0';
588
589         this.superweapons_finished = (STAT(WEAPONS, this) & WEPSET_SUPERWEAPONS) ? time + autocvar_g_balance_superweapons_time : 0;
590
591         this.items = start_items;
592
593         this.spawnshieldtime = time + autocvar_g_spawnshieldtime;
594         this.pauserotarmor_finished = time + autocvar_g_balance_pause_armor_rot_spawn;
595         this.pauserothealth_finished = time + autocvar_g_balance_pause_health_rot_spawn;
596         this.pauserotfuel_finished = time + autocvar_g_balance_pause_fuel_rot_spawn;
597         this.pauseregen_finished = time + autocvar_g_balance_pause_health_regen_spawn;
598         if (!sv_ready_restart_after_countdown && time < game_starttime)
599         {
600                 float f = game_starttime - time;
601                 this.spawnshieldtime += f;
602                 this.pauserotarmor_finished += f;
603                 this.pauserothealth_finished += f;
604                 this.pauseregen_finished += f;
605         }
606
607         this.damageforcescale = 2;
608         this.death_time = 0;
609         this.respawn_flags = 0;
610         this.respawn_time = 0;
611         STAT(RESPAWN_TIME, this) = 0;
612         this.scale = autocvar_sv_player_scale;
613         this.fade_time = 0;
614         this.pain_frame = 0;
615         this.pain_finished = 0;
616         this.pushltime = 0;
617         setthink(this, func_null); // players have no think function
618         this.nextthink = 0;
619         this.dmg_team = 0;
620         PS(this).ballistics_density = autocvar_g_ballistics_density_player;
621
622         this.deadflag = DEAD_NO;
623
624         this.angles = spot.angles;
625         this.angles_z = 0; // never spawn tilted even if the spot says to
626         if (IS_BOT_CLIENT(this))
627         {
628                 this.v_angle = this.angles;
629                 bot_aim_reset(this);
630         }
631         this.fixangle = true; // turn this way immediately
632         this.oldvelocity = this.velocity = '0 0 0';
633         this.avelocity = '0 0 0';
634         this.punchangle = '0 0 0';
635         this.punchvector = '0 0 0';
636
637         this.strength_finished = 0;
638         this.invincible_finished = 0;
639         this.fire_endtime = -1;
640         STAT(REVIVE_PROGRESS, this) = 0;
641         this.revival_time = 0;
642
643         this.air_finished = time + 12;
644         this.waterlevel = WATERLEVEL_NONE;
645         this.watertype = CONTENT_EMPTY;
646
647         entity spawnevent = new_pure(spawnevent);
648         spawnevent.owner = this;
649         Net_LinkEntity(spawnevent, false, 0.5, SpawnEvent_Send);
650
651         // Cut off any still running player sounds.
652         stopsound(this, CH_PLAYER_SINGLE);
653
654         this.model = "";
655         FixPlayermodel(this);
656         this.drawonlytoclient = NULL;
657
658         this.viewloc = NULL;
659
660         for(int slot = 0; slot < MAX_AXH; ++slot)
661         {
662                 entity axh = this.(AuxiliaryXhair[slot]);
663                 this.(AuxiliaryXhair[slot]) = NULL;
664
665                 if(axh.owner == this && axh != NULL && !wasfreed(axh))
666                         delete(axh);
667         }
668
669         this.spawnpoint_targ = NULL;
670
671         this.crouch = false;
672         this.view_ofs = STAT(PL_VIEW_OFS, this);
673         setsize(this, STAT(PL_MIN, this), STAT(PL_MAX, this));
674         this.spawnorigin = spot.origin;
675         setorigin(this, spot.origin + '0 0 1' * (1 - this.mins.z - 24));
676         // don't reset back to last position, even if new position is stuck in solid
677         this.oldorigin = this.origin;
678         if(this.conveyor)
679                 IL_REMOVE(g_conveyed, this);
680         this.conveyor = NULL; // prevent conveyors at the previous location from moving a freshly spawned player
681         STAT(HUD, this) = HUD_NORMAL;
682
683         this.event_damage = PlayerDamage;
684         this.event_heal = PlayerHeal;
685
686         this.draggable = func_null;
687
688         if(!this.bot_attack)
689                 IL_PUSH(g_bot_targets, this);
690         this.bot_attack = true;
691         if(!this.monster_attack)
692                 IL_PUSH(g_monster_targets, this);
693         this.monster_attack = true;
694         navigation_dynamicgoal_init(this, false);
695
696         PHYS_INPUT_BUTTON_ATCK(this) = PHYS_INPUT_BUTTON_JUMP(this) = PHYS_INPUT_BUTTON_ATCK2(this) = false;
697
698         // player was spectator
699         if (CS(this).killcount == FRAGS_SPECTATOR) {
700                 PlayerScore_Clear(this);
701                 CS(this).killcount = 0;
702                 CS(this).startplaytime = time;
703         }
704
705         for (int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
706         {
707                 .entity weaponentity = weaponentities[slot];
708                 entity oldwep = this.(weaponentity);
709                 CL_SpawnWeaponentity(this, weaponentity);
710                 if(oldwep && oldwep.owner == this)
711                         this.(weaponentity).m_gunalign = oldwep.m_gunalign;
712         }
713         this.alpha = default_player_alpha;
714         this.colormod = '1 1 1' * autocvar_g_player_brightness;
715         this.exteriorweaponentity.alpha = default_weapon_alpha;
716
717         this.speedrunning = false;
718
719         this.counter_cnt = 0;
720         this.fragsfilter_cnt = 0;
721
722         target_voicescript_clear(this);
723
724         // reset fields the weapons may use
725         FOREACH(Weapons, true, {
726                 it.wr_resetplayer(it, this);
727                         // reload all reloadable weapons
728                 if (it.spawnflags & WEP_FLAG_RELOADABLE) {
729                         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
730                         {
731                                 .entity weaponentity = weaponentities[slot];
732                                 this.(weaponentity).weapon_load[it.m_id] = it.reloading_ammo;
733                         }
734                 }
735         });
736
737         {
738                 string s = spot.target;
739                 if(g_assault || g_race) // TODO: make targeting work in assault & race without this hack
740                         spot.target = string_null;
741                 SUB_UseTargets(spot, this, NULL);
742                 if(g_assault || g_race)
743                         spot.target = s;
744         }
745
746         Unfreeze(this, false);
747
748         MUTATOR_CALLHOOK(PlayerSpawn, this, spot);
749
750         if (autocvar_spawn_debug)
751         {
752                 sprint(this, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
753                 delete(spot); // usefull for checking if there are spawnpoints, that let drop through the floor
754         }
755
756         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
757         {
758                 .entity weaponentity = weaponentities[slot];
759                 if(slot == 0 || autocvar_g_weaponswitch_debug == 1)
760                         this.(weaponentity).m_switchweapon = w_getbestweapon(this, weaponentity);
761                 else
762                         this.(weaponentity).m_switchweapon = WEP_Null;
763                 this.(weaponentity).m_weapon = WEP_Null;
764                 this.(weaponentity).weaponname = "";
765                 this.(weaponentity).m_switchingweapon = WEP_Null;
766                 this.(weaponentity).cnt = -1;
767         }
768
769         MUTATOR_CALLHOOK(PlayerWeaponSelect, this);
770
771         if (CS(this).impulse) ImpulseCommands(this);
772
773         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
774         {
775                 .entity weaponentity = weaponentities[slot];
776                 W_WeaponFrame(this, weaponentity);
777         }
778
779         if (!warmup_stage && !this.alivetime)
780                 this.alivetime = time;
781
782         antilag_clear(this, CS(this));
783 }
784
785 /** Called when a client spawns in the server */
786 void PutClientInServer(entity this)
787 {
788         if (IS_BOT_CLIENT(this)) {
789                 TRANSMUTE(Player, this);
790         } else if (IS_REAL_CLIENT(this)) {
791                 msg_entity = this;
792                 WriteByte(MSG_ONE, SVC_SETVIEW);
793                 WriteEntity(MSG_ONE, this);
794         }
795         if (game_stopped)
796                 TRANSMUTE(Observer, this);
797
798         SetSpectatee(this, NULL);
799
800         // reset player keys
801         if(PS(this))
802                 PS(this).itemkeys = 0;
803
804         MUTATOR_CALLHOOK(PutClientInServer, this);
805
806         if (IS_OBSERVER(this)) {
807                 PutObserverInServer(this);
808         } else if (IS_PLAYER(this)) {
809                 PutPlayerInServer(this);
810         }
811 }
812
813 // TODO do we need all these fields, or should we stop autodetecting runtime
814 // changes and just have a console command to update this?
815 bool ClientInit_SendEntity(entity this, entity to, int sf)
816 {
817         WriteHeader(MSG_ENTITY, _ENT_CLIENT_INIT);
818         return = true;
819         msg_entity = to;
820         // MSG_INIT replacement
821         // TODO: make easier to use
822         Registry_send_all();
823         W_PROP_reload(MSG_ONE, to);
824         ClientInit_misc(this);
825         MUTATOR_CALLHOOK(Ent_Init);
826 }
827 void ClientInit_misc(entity this)
828 {
829         int channel = MSG_ONE;
830         WriteHeader(channel, ENT_CLIENT_INIT);
831         WriteByte(channel, g_nexball_meter_period * 32);
832         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[0]));
833         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[1]));
834         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[2]));
835         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[3]));
836         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[0]));
837         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[1]));
838         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[2]));
839         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[3]));
840
841         if(sv_foginterval && world.fog != "")
842                 WriteString(channel, world.fog);
843         else
844                 WriteString(channel, "");
845         WriteByte(channel, this.count * 255.0); // g_balance_armor_blockpercent
846         WriteByte(channel, this.cnt * 255.0); // g_balance_damagepush_speedfactor
847         WriteByte(channel, serverflags);
848         WriteCoord(channel, autocvar_g_trueaim_minrange);
849 }
850
851 void ClientInit_CheckUpdate(entity this)
852 {
853         this.nextthink = time;
854         if(this.count != autocvar_g_balance_armor_blockpercent)
855         {
856                 this.count = autocvar_g_balance_armor_blockpercent;
857                 this.SendFlags |= 1;
858         }
859         if(this.cnt != autocvar_g_balance_damagepush_speedfactor)
860         {
861                 this.cnt = autocvar_g_balance_damagepush_speedfactor;
862                 this.SendFlags |= 1;
863         }
864 }
865
866 void ClientInit_Spawn()
867 {
868         entity e = new_pure(clientinit);
869         setthink(e, ClientInit_CheckUpdate);
870         Net_LinkEntity(e, false, 0, ClientInit_SendEntity);
871
872         ClientInit_CheckUpdate(e);
873 }
874
875 /*
876 =============
877 SetNewParms
878 =============
879 */
880 void SetNewParms ()
881 {
882         // initialize parms for a new player
883         parm1 = -(86400 * 366);
884
885         MUTATOR_CALLHOOK(SetNewParms);
886 }
887
888 /*
889 =============
890 SetChangeParms
891 =============
892 */
893 void SetChangeParms (entity this)
894 {
895         // save parms for level change
896         parm1 = CS(this).parm_idlesince - time;
897
898         MUTATOR_CALLHOOK(SetChangeParms);
899 }
900
901 /*
902 =============
903 DecodeLevelParms
904 =============
905 */
906 void DecodeLevelParms(entity this)
907 {
908         // load parms
909         CS(this).parm_idlesince = parm1;
910         if (CS(this).parm_idlesince == -(86400 * 366))
911                 CS(this).parm_idlesince = time;
912
913         // whatever happens, allow 60 seconds of idling directly after connect for map loading
914         CS(this).parm_idlesince = max(CS(this).parm_idlesince, time - sv_maxidle + 60);
915
916         MUTATOR_CALLHOOK(DecodeLevelParms);
917 }
918
919 void FixClientCvars(entity e)
920 {
921         // send prediction settings to the client
922         stuffcmd(e, "\nin_bindmap 0 0\n");
923         if(autocvar_g_antilag == 3) // client side hitscan
924                 stuffcmd(e, "cl_cmd settemp cl_prydoncursor_notrace 0\n");
925         if(autocvar_sv_gentle)
926                 stuffcmd(e, "cl_cmd settemp cl_gentle 1\n");
927
928         stuffcmd(e, sprintf("\ncl_jumpspeedcap_min \"%s\"\n", autocvar_sv_jumpspeedcap_min));
929         stuffcmd(e, sprintf("\ncl_jumpspeedcap_max \"%s\"\n", autocvar_sv_jumpspeedcap_max));
930
931         stuffcmd(e, sprintf("\ncl_shootfromfixedorigin \"%s\"\n", autocvar_g_shootfromfixedorigin));
932
933         MUTATOR_CALLHOOK(FixClientCvars, e);
934 }
935
936 bool findinlist_abbrev(string tofind, string list)
937 {
938         if(list == "" || tofind == "")
939                 return false; // empty list or search, just return
940
941         // this function allows abbreviated strings!
942         FOREACH_WORD(list, it == substring(tofind, 0, strlen(it)),
943         {
944                 return true;
945         });
946
947         return false;
948 }
949
950 bool PlayerInIPList(entity p, string iplist)
951 {
952         // some safety checks (never allow local?)
953         if(p.netaddress == "local" || p.netaddress == "" || !IS_REAL_CLIENT(p))
954                 return false;
955
956         return findinlist_abbrev(p.netaddress, iplist);
957 }
958
959 bool PlayerInIDList(entity p, string idlist)
960 {
961         // NOTE: we do NOT check crypto_idfp_signed here, an unsigned ID is fine too for this
962         if(!p.crypto_idfp)
963                 return false;
964
965         return findinlist_abbrev(p.crypto_idfp, idlist);
966 }
967
968 bool PlayerInList(entity player, string list)
969 {
970         return boolean(PlayerInIDList(player, list) || PlayerInIPList(player, list));
971 }
972
973 #ifdef DP_EXT_PRECONNECT
974 /*
975 =============
976 ClientPreConnect
977
978 Called once (not at each match start) when a client begins a connection to the server
979 =============
980 */
981 void ClientPreConnect(entity this)
982 {
983         if(autocvar_sv_eventlog)
984         {
985                 GameLogEcho(sprintf(":connect:%d:%d:%s",
986                         this.playerid,
987                         etof(this),
988                         ((IS_REAL_CLIENT(this)) ? this.netaddress : "bot")
989                 ));
990         }
991 }
992 #endif
993
994 string GetClientVersionMessage(entity this)
995 {
996         if (CS(this).version_mismatch) {
997                 if(CS(this).version < autocvar_gameversion) {
998                         return strcat("This is Xonotic ", autocvar_g_xonoticversion,
999                                 "\n^3Your client version is outdated.\n\n\n### YOU WON'T BE ABLE TO PLAY ON THIS SERVER ###\n\n\nPlease update!!!^8");
1000                 } else {
1001                         return strcat("This is Xonotic ", autocvar_g_xonoticversion,
1002                                 "\n^3This server is using an outdated Xonotic version.\n\n\n ### THIS SERVER IS INCOMPATIBLE AND THUS YOU CANNOT JOIN ###.^8");
1003                 }
1004         } else {
1005                 return strcat("Welcome to Xonotic ", autocvar_g_xonoticversion);
1006         }
1007 }
1008
1009 string getwelcomemessage(entity this)
1010 {
1011         MUTATOR_CALLHOOK(BuildMutatorsPrettyString, "");
1012         string modifications = M_ARGV(0, string);
1013
1014         if(g_weaponarena)
1015         {
1016                 if(g_weaponarena_random)
1017                         modifications = strcat(modifications, ", ", ftos(g_weaponarena_random), " of ", g_weaponarena_list, " Arena");
1018                 else
1019                         modifications = strcat(modifications, ", ", g_weaponarena_list, " Arena");
1020         }
1021         else if(cvar("g_balance_blaster_weaponstartoverride") == 0)
1022                 modifications = strcat(modifications, ", No start weapons");
1023         if(cvar("sv_gravity") < stof(cvar_defstring("sv_gravity")))
1024                 modifications = strcat(modifications, ", Low gravity");
1025         if(g_weapon_stay && !g_cts)
1026                 modifications = strcat(modifications, ", Weapons stay");
1027         if(g_jetpack)
1028                 modifications = strcat(modifications, ", Jet pack");
1029         if(autocvar_g_powerups == 0)
1030                 modifications = strcat(modifications, ", No powerups");
1031         if(autocvar_g_powerups > 0)
1032                 modifications = strcat(modifications, ", Powerups");
1033         modifications = substring(modifications, 2, strlen(modifications) - 2);
1034
1035         string versionmessage = GetClientVersionMessage(this);
1036         string s = strcat(versionmessage, "^8\n^8\nmatch type is ^1", gamemode_name, "^8\n");
1037
1038         if(modifications != "")
1039                 s = strcat(s, "^8\nactive modifications: ^3", modifications, "^8\n");
1040
1041         if(cache_lastmutatormsg != autocvar_g_mutatormsg)
1042         {
1043                 strcpy(cache_lastmutatormsg, autocvar_g_mutatormsg);
1044                 strcpy(cache_mutatormsg, cache_lastmutatormsg);
1045         }
1046
1047         if (cache_mutatormsg != "") {
1048                 s = strcat(s, "\n\n^8special gameplay tips: ^7", cache_mutatormsg);
1049         }
1050
1051         string mutator_msg = "";
1052         MUTATOR_CALLHOOK(BuildGameplayTipsString, mutator_msg);
1053         mutator_msg = M_ARGV(0, string);
1054
1055         s = strcat(s, mutator_msg); // trust that the mutator will do proper formatting
1056
1057         string motd = autocvar_sv_motd;
1058         if (motd != "") {
1059                 s = strcat(s, "\n\n^8MOTD: ^7", strreplace("\\n", "\n", motd));
1060         }
1061         return s;
1062 }
1063
1064 bool autocvar_sv_qcphysics = false; // TODO this is for testing - remove when qcphysics work
1065
1066 /**
1067 =============
1068 ClientConnect
1069
1070 Called when a client connects to the server
1071 =============
1072 */
1073 void ClientConnect(entity this)
1074 {
1075         if (Ban_MaybeEnforceBanOnce(this)) return;
1076         assert(!IS_CLIENT(this), return);
1077         this.flags |= FL_CLIENT;
1078         assert(player_count >= 0, player_count = 0);
1079
1080 #ifdef WATERMARK
1081         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_WATERMARK, WATERMARK);
1082 #endif
1083         TRANSMUTE(Client, this);
1084         CS(this).version_nagtime = time + 10 + random() * 10;
1085
1086         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_JOIN_CONNECT, this.netname);
1087
1088         bot_clientconnect(this);
1089
1090         Player_DetermineForcedTeam(this);
1091
1092         TRANSMUTE(Observer, this);
1093
1094         PlayerStats_GameReport_AddEvent(sprintf("kills-%d", this.playerid));
1095
1096         // always track bots, don't ask for cl_allow_uidtracking
1097         if (IS_BOT_CLIENT(this))
1098                 PlayerStats_GameReport_AddPlayer(this);
1099         else
1100                 CS(this).allowed_timeouts = autocvar_sv_timeout_number;
1101
1102         if (autocvar_sv_eventlog)
1103                 GameLogEcho(strcat(":join:", ftos(this.playerid), ":", ftos(etof(this)), ":", ((IS_REAL_CLIENT(this)) ? this.netaddress : "bot"), ":", playername(this, false)));
1104
1105         CS(this).just_joined = true;  // stop spamming the eventlog with additional lines when the client connects
1106
1107         stuffcmd(this, clientstuff, "\n");
1108         stuffcmd(this, "cl_particles_reloadeffects\n"); // TODO do we still need this?
1109
1110         FixClientCvars(this);
1111
1112         // get version info from player
1113         stuffcmd(this, "cmd clientversion $gameversion\n");
1114
1115         // notify about available teams
1116         if (teamplay)
1117         {
1118                 entity balance = TeamBalance_CheckAllowedTeams(this);
1119                 int t = TeamBalance_GetAllowedTeams(balance);
1120                 TeamBalance_Destroy(balance);
1121                 stuffcmd(this, sprintf("set _teams_available %d\n", t));
1122         }
1123         else
1124         {
1125                 stuffcmd(this, "set _teams_available 0\n");
1126         }
1127
1128         bot_relinkplayerlist();
1129
1130         CS(this).spectatortime = time;
1131         if (blockSpectators)
1132         {
1133                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
1134         }
1135
1136         CS(this).jointime = time;
1137
1138         if (IS_REAL_CLIENT(this))
1139         {
1140                 if (g_weaponarena_weapons == WEPSET(TUBA))
1141                         stuffcmd(this, "cl_cmd settemp chase_active 1\n");
1142         }
1143
1144         if (!sv_foginterval && world.fog != "")
1145                 stuffcmd(this, strcat("\nfog ", world.fog, "\nr_fog_exp2 0\nr_drawfog 1\n"));
1146
1147         if (autocvar_sv_teamnagger && !(autocvar_bot_vs_human && AvailableTeams() == 2))
1148                 if(!MUTATOR_CALLHOOK(HideTeamNagger, this))
1149                         send_CSQC_teamnagger();
1150
1151         CSQCMODEL_AUTOINIT(this);
1152
1153         CS(this).model_randomizer = random();
1154
1155         if (IS_REAL_CLIENT(this))
1156                 sv_notice_join(this);
1157
1158         this.move_qcphysics = autocvar_sv_qcphysics;
1159
1160         // update physics stats (players can spawn before physics runs)
1161         Physics_UpdateStats(this);
1162
1163         IL_EACH(g_initforplayer, it.init_for_player, {
1164                 it.init_for_player(it, this);
1165         });
1166
1167         Handicap_Initialize(this);
1168
1169         MUTATOR_CALLHOOK(ClientConnect, this);
1170
1171         if (IS_REAL_CLIENT(this))
1172         {
1173                 if (!autocvar_g_campaign && !IS_PLAYER(this))
1174                 {
1175                         CS(this).motd_actived_time = -1;
1176                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOTD, getwelcomemessage(this));
1177                 }
1178         }
1179 }
1180 /*
1181 =============
1182 ClientDisconnect
1183
1184 Called when a client disconnects from the server
1185 =============
1186 */
1187 .entity chatbubbleentity;
1188 void ClientDisconnect(entity this)
1189 {
1190         assert(IS_CLIENT(this), return);
1191
1192         PlayerStats_GameReport_FinalizePlayer(this);
1193         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
1194         if (CS(this).active_minigame) part_minigame(this);
1195         if (IS_PLAYER(this)) Send_Effect(EFFECT_SPAWN_NEUTRAL, this.origin, '0 0 0', 1);
1196
1197         if (autocvar_sv_eventlog)
1198                 GameLogEcho(strcat(":part:", ftos(this.playerid)));
1199
1200         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_QUIT_DISCONNECT, this.netname);
1201
1202         if(IS_SPEC(this))
1203                 SetSpectatee(this, NULL);
1204
1205     MUTATOR_CALLHOOK(ClientDisconnect, this);
1206
1207         strfree(CS(this).netname_previous); // needs to be before the CS entity is removed!
1208         strfree(CS(this).weaponorder_byimpulse);
1209         ClientState_detach(this);
1210
1211         Portal_ClearAll(this);
1212
1213         Unfreeze(this, false);
1214
1215         RemoveGrapplingHooks(this);
1216
1217         // Here, everything has been done that requires this player to be a client.
1218
1219         this.flags &= ~FL_CLIENT;
1220
1221         if (this.chatbubbleentity) delete(this.chatbubbleentity);
1222         if (this.killindicator) delete(this.killindicator);
1223
1224         WaypointSprite_PlayerGone(this);
1225
1226         bot_relinkplayerlist();
1227
1228         strfree(this.clientstatus);
1229         if (this.personal) delete(this.personal);
1230
1231         this.playerid = 0;
1232         ReadyCount();
1233         if (vote_called && IS_REAL_CLIENT(this)) VoteCount(false);
1234
1235         ONREMOVE(this);
1236 }
1237
1238 void ChatBubbleThink(entity this)
1239 {
1240         this.nextthink = time;
1241         if ((this.owner.alpha < 0) || this.owner.chatbubbleentity != this)
1242         {
1243                 if(this.owner) // but why can that ever be NULL?
1244                         this.owner.chatbubbleentity = NULL;
1245                 delete(this);
1246                 return;
1247         }
1248
1249         this.mdl = "";
1250
1251         if ( !IS_DEAD(this.owner) && IS_PLAYER(this.owner) )
1252         {
1253                 if ( CS(this.owner).active_minigame && PHYS_INPUT_BUTTON_MINIGAME(this.owner) )
1254                         this.mdl = "models/sprites/minigame_busy.iqm";
1255                 else if (PHYS_INPUT_BUTTON_CHAT(this.owner))
1256                         this.mdl = "models/misc/chatbubble.spr";
1257         }
1258
1259         if ( this.model != this.mdl )
1260                 _setmodel(this, this.mdl);
1261
1262 }
1263
1264 void UpdateChatBubble(entity this)
1265 {
1266         if (this.alpha < 0)
1267                 return;
1268         // spawn a chatbubble entity if needed
1269         if (!this.chatbubbleentity)
1270         {
1271                 this.chatbubbleentity = new(chatbubbleentity);
1272                 this.chatbubbleentity.owner = this;
1273                 this.chatbubbleentity.exteriormodeltoclient = this;
1274                 setthink(this.chatbubbleentity, ChatBubbleThink);
1275                 this.chatbubbleentity.nextthink = time;
1276                 setmodel(this.chatbubbleentity, MDL_CHAT); // precision set below
1277                 //setorigin(this.chatbubbleentity, this.origin + '0 0 15' + this.maxs_z * '0 0 1');
1278                 setorigin(this.chatbubbleentity, '0 0 15' + this.maxs_z * '0 0 1');
1279                 setattachment(this.chatbubbleentity, this, "");  // sticks to moving player better, also conserves bandwidth
1280                 this.chatbubbleentity.mdl = this.chatbubbleentity.model;
1281                 //this.chatbubbleentity.model = "";
1282                 this.chatbubbleentity.effects = EF_LOWPRECISION;
1283         }
1284 }
1285
1286
1287 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
1288 // added to the model skins
1289 /*void UpdateColorModHack()
1290 {
1291         float c;
1292         c = this.clientcolors & 15;
1293         // LordHavoc: only bothering to support white, green, red, yellow, blue
1294              if (!teamplay) this.colormod = '0 0 0';
1295         else if (c ==  0) this.colormod = '1.00 1.00 1.00';
1296         else if (c ==  3) this.colormod = '0.10 1.73 0.10';
1297         else if (c ==  4) this.colormod = '1.73 0.10 0.10';
1298         else if (c == 12) this.colormod = '1.22 1.22 0.10';
1299         else if (c == 13) this.colormod = '0.10 0.10 1.73';
1300         else this.colormod = '1 1 1';
1301 }*/
1302
1303 void respawn(entity this)
1304 {
1305         if(this.alpha >= 0 && autocvar_g_respawn_ghosts)
1306         {
1307                 this.solid = SOLID_NOT;
1308                 this.takedamage = DAMAGE_NO;
1309                 set_movetype(this, MOVETYPE_FLY);
1310                 this.velocity = '0 0 1' * autocvar_g_respawn_ghosts_speed;
1311                 this.avelocity = randomvec() * autocvar_g_respawn_ghosts_speed * 3 - randomvec() * autocvar_g_respawn_ghosts_speed * 3;
1312                 this.effects |= CSQCMODEL_EF_RESPAWNGHOST;
1313                 Send_Effect(EFFECT_RESPAWN_GHOST, this.origin, '0 0 0', 1);
1314                 if(autocvar_g_respawn_ghosts_maxtime)
1315                         SUB_SetFade (this, time + autocvar_g_respawn_ghosts_maxtime / 2 + random () * (autocvar_g_respawn_ghosts_maxtime - autocvar_g_respawn_ghosts_maxtime / 2), 1.5);
1316         }
1317
1318         CopyBody(this, 1);
1319
1320         this.effects |= EF_NODRAW; // prevent another CopyBody
1321         PutClientInServer(this);
1322 }
1323
1324 void PrintToChat(entity client, string text)
1325 {
1326         text = strcat("\{1}^7", text, "\n");
1327         sprint(client, text);
1328 }
1329
1330 void DebugPrintToChat(entity client, string text)
1331 {
1332         if (autocvar_developer)
1333         {
1334                 PrintToChat(client, text);
1335         }
1336 }
1337
1338 void PrintToChatAll(string text)
1339 {
1340         text = strcat("\{1}^7", text, "\n");
1341         bprint(text);
1342 }
1343
1344 void DebugPrintToChatAll(string text)
1345 {
1346         if (autocvar_developer)
1347         {
1348                 PrintToChatAll(text);
1349         }
1350 }
1351
1352 void PrintToChatTeam(int team_num, string text)
1353 {
1354         text = strcat("\{1}^7", text, "\n");
1355         FOREACH_CLIENT(IS_REAL_CLIENT(it),
1356         {
1357                 if (it.team == team_num)
1358                 {
1359                         sprint(it, text);
1360                 }
1361         });
1362 }
1363
1364 void DebugPrintToChatTeam(int team_num, string text)
1365 {
1366         if (autocvar_developer)
1367         {
1368                 PrintToChatTeam(team_num, text);
1369         }
1370 }
1371
1372 void play_countdown(entity this, float finished, Sound samp)
1373 {
1374         TC(Sound, samp);
1375         if(IS_REAL_CLIENT(this))
1376                 if(floor(finished - time - frametime) != floor(finished - time))
1377                         if(finished - time < 6)
1378                                 sound (this, CH_INFO, samp, VOL_BASE, ATTEN_NORM);
1379 }
1380
1381 void player_powerups(entity this)
1382 {
1383         // add a way to see what the items were BEFORE all of these checks for the mutator hook
1384         int items_prev = this.items;
1385
1386         if((this.items & IT_USING_JETPACK) && !IS_DEAD(this) && !game_stopped)
1387                 this.modelflags |= MF_ROCKET;
1388         else
1389                 this.modelflags &= ~MF_ROCKET;
1390
1391         this.effects &= ~(EF_RED | EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT | EF_FLAME | EF_NODEPTHTEST);
1392
1393         if((this.alpha < 0 || IS_DEAD(this)) && !this.vehicle) // don't apply the flags if the player is gibbed
1394                 return;
1395
1396         Fire_ApplyDamage(this);
1397         Fire_ApplyEffect(this);
1398
1399         if (!MUTATOR_IS_ENABLED(mutator_instagib))
1400         {
1401                 if (this.items & ITEM_Strength.m_itemid)
1402                 {
1403                         play_countdown(this, this.strength_finished, SND_POWEROFF);
1404                         this.effects = this.effects | (EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT);
1405                         if (time > this.strength_finished)
1406                         {
1407                                 this.items = this.items - (this.items & ITEM_Strength.m_itemid);
1408                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERDOWN_STRENGTH, this.netname);
1409                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERDOWN_STRENGTH);
1410                         }
1411                 }
1412                 else
1413                 {
1414                         if (time < this.strength_finished)
1415                         {
1416                                 this.items = this.items | ITEM_Strength.m_itemid;
1417                                 if(!g_cts)
1418                                         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERUP_STRENGTH, this.netname);
1419                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERUP_STRENGTH);
1420                         }
1421                 }
1422                 if (this.items & ITEM_Shield.m_itemid)
1423                 {
1424                         play_countdown(this, this.invincible_finished, SND_POWEROFF);
1425                         this.effects = this.effects | (EF_RED | EF_ADDITIVE | EF_FULLBRIGHT);
1426                         if (time > this.invincible_finished)
1427                         {
1428                                 this.items = this.items - (this.items & ITEM_Shield.m_itemid);
1429                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERDOWN_SHIELD, this.netname);
1430                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERDOWN_SHIELD);
1431                         }
1432                 }
1433                 else
1434                 {
1435                         if (time < this.invincible_finished)
1436                         {
1437                                 this.items = this.items | ITEM_Shield.m_itemid;
1438                                 if(!g_cts)
1439                                         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERUP_SHIELD, this.netname);
1440                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERUP_SHIELD);
1441                         }
1442                 }
1443                 if (this.items & IT_SUPERWEAPON)
1444                 {
1445                         if (!(STAT(WEAPONS, this) & WEPSET_SUPERWEAPONS))
1446                         {
1447                                 this.superweapons_finished = 0;
1448                                 this.items = this.items - (this.items & IT_SUPERWEAPON);
1449                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_LOST, this.netname);
1450                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_LOST);
1451                         }
1452                         else if (this.items & IT_UNLIMITED_SUPERWEAPONS)
1453                         {
1454                                 // don't let them run out
1455                         }
1456                         else
1457                         {
1458                                 play_countdown(this, this.superweapons_finished, SND_POWEROFF);
1459                                 if (time > this.superweapons_finished)
1460                                 {
1461                                         this.items = this.items - (this.items & IT_SUPERWEAPON);
1462                                         STAT(WEAPONS, this) &= ~WEPSET_SUPERWEAPONS;
1463                                         //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_BROKEN, this.netname);
1464                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_BROKEN);
1465                                 }
1466                         }
1467                 }
1468                 else if(STAT(WEAPONS, this) & WEPSET_SUPERWEAPONS)
1469                 {
1470                         if (time < this.superweapons_finished || (this.items & IT_UNLIMITED_SUPERWEAPONS))
1471                         {
1472                                 this.items = this.items | IT_SUPERWEAPON;
1473                                 if(!(this.items & IT_UNLIMITED_SUPERWEAPONS))
1474                                 {
1475                                         if(!g_cts)
1476                                                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_PICKUP, this.netname);
1477                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_PICKUP);
1478                                 }
1479                         }
1480                         else
1481                         {
1482                                 this.superweapons_finished = 0;
1483                                 STAT(WEAPONS, this) &= ~WEPSET_SUPERWEAPONS;
1484                         }
1485                 }
1486                 else
1487                 {
1488                         this.superweapons_finished = 0;
1489                 }
1490         }
1491
1492         if(autocvar_g_nodepthtestplayers)
1493                 this.effects = this.effects | EF_NODEPTHTEST;
1494
1495         if(autocvar_g_fullbrightplayers)
1496                 this.effects = this.effects | EF_FULLBRIGHT;
1497
1498         if (time >= game_starttime)
1499         if (time < this.spawnshieldtime)
1500                 this.effects = this.effects | (EF_ADDITIVE | EF_FULLBRIGHT);
1501
1502         MUTATOR_CALLHOOK(PlayerPowerups, this, items_prev);
1503 }
1504
1505 float CalcRegen(float current, float stable, float regenfactor, float regenframetime)
1506 {
1507         if(current > stable)
1508                 return current;
1509         else if(current > stable - 0.25) // when close enough, "snap"
1510                 return stable;
1511         else
1512                 return min(stable, current + (stable - current) * regenfactor * regenframetime);
1513 }
1514
1515 float CalcRot(float current, float stable, float rotfactor, float rotframetime)
1516 {
1517         if(current < stable)
1518                 return current;
1519         else if(current < stable + 0.25) // when close enough, "snap"
1520                 return stable;
1521         else
1522                 return max(stable, current + (stable - current) * rotfactor * rotframetime);
1523 }
1524
1525 float CalcRotRegen(float current, float regenstable, float regenfactor, float regenlinear, float regenframetime, float rotstable, float rotfactor, float rotlinear, float rotframetime, float limit)
1526 {
1527         if(current > rotstable)
1528         {
1529                 if(rotframetime > 0)
1530                 {
1531                         current = CalcRot(current, rotstable, rotfactor, rotframetime);
1532                         current = max(rotstable, current - rotlinear * rotframetime);
1533                 }
1534         }
1535         else if(current < regenstable)
1536         {
1537                 if(regenframetime > 0)
1538                 {
1539                         current = CalcRegen(current, regenstable, regenfactor, regenframetime);
1540                         current = min(regenstable, current + regenlinear * regenframetime);
1541                 }
1542         }
1543
1544         if(current > limit)
1545                 current = limit;
1546
1547         return current;
1548 }
1549
1550 void player_regen(entity this)
1551 {
1552         float max_mod, regen_mod, rot_mod, limit_mod;
1553         max_mod = regen_mod = rot_mod = limit_mod = 1;
1554
1555         float regen_health = autocvar_g_balance_health_regen;
1556         float regen_health_linear = autocvar_g_balance_health_regenlinear;
1557         float regen_health_rot = autocvar_g_balance_health_rot;
1558         float regen_health_rotlinear = autocvar_g_balance_health_rotlinear;
1559         float regen_health_stable = autocvar_g_balance_health_regenstable;
1560         float regen_health_rotstable = autocvar_g_balance_health_rotstable;
1561         bool mutator_returnvalue = MUTATOR_CALLHOOK(PlayerRegen, this, max_mod, regen_mod, rot_mod, limit_mod, regen_health, regen_health_linear, regen_health_rot,
1562                 regen_health_rotlinear, regen_health_stable, regen_health_rotstable);
1563         max_mod = M_ARGV(1, float);
1564         regen_mod = M_ARGV(2, float);
1565         rot_mod = M_ARGV(3, float);
1566         limit_mod = M_ARGV(4, float);
1567         regen_health = M_ARGV(5, float);
1568         regen_health_linear = M_ARGV(6, float);
1569         regen_health_rot = M_ARGV(7, float);
1570         regen_health_rotlinear = M_ARGV(8, float);
1571         regen_health_stable = M_ARGV(9, float);
1572         regen_health_rotstable = M_ARGV(10, float);
1573
1574         if(!mutator_returnvalue)
1575         if(!STAT(FROZEN, this))
1576         {
1577                 float mina, maxa, limith, limita;
1578                 maxa = autocvar_g_balance_armor_rotstable;
1579                 mina = autocvar_g_balance_armor_regenstable;
1580                 limith = GetResourceLimit(this, RES_HEALTH);
1581                 limita = GetResourceLimit(this, RES_ARMOR);
1582
1583                 regen_health_rotstable = regen_health_rotstable * max_mod;
1584                 regen_health_stable = regen_health_stable * max_mod;
1585                 limith = limith * limit_mod;
1586                 limita = limita * limit_mod;
1587
1588                 SetResource(this, RES_ARMOR, CalcRotRegen(GetResource(this, RES_ARMOR), mina, autocvar_g_balance_armor_regen, autocvar_g_balance_armor_regenlinear, 
1589                                                                         regen_mod * frametime * (time > this.pauseregen_finished), maxa, autocvar_g_balance_armor_rot, autocvar_g_balance_armor_rotlinear,
1590                                                                         rot_mod * frametime * (time > this.pauserotarmor_finished), limita));
1591                 SetResource(this, RES_HEALTH, CalcRotRegen(GetResource(this, RES_HEALTH), regen_health_stable, regen_health, regen_health_linear,
1592                                                                         regen_mod * frametime * (time > this.pauseregen_finished), regen_health_rotstable, regen_health_rot, regen_health_rotlinear,
1593                                                                         rot_mod * frametime * (time > this.pauserothealth_finished), limith));
1594         }
1595
1596         // if player rotted to death...  die!
1597         // check this outside above checks, as player may still be able to rot to death
1598         if(GetResource(this, RES_HEALTH) < 1)
1599         {
1600                 if(this.vehicle)
1601                         vehicles_exit(this.vehicle, VHEF_RELEASE);
1602                 if(this.event_damage)
1603                         this.event_damage(this, this, this, 1, DEATH_ROT.m_id, DMG_NOWEP, this.origin, '0 0 0');
1604         }
1605
1606         if (!(this.items & IT_UNLIMITED_WEAPON_AMMO))
1607         {
1608                 float minf, maxf, limitf;
1609
1610                 maxf = autocvar_g_balance_fuel_rotstable;
1611                 minf = autocvar_g_balance_fuel_regenstable;
1612                 limitf = GetResourceLimit(this, RES_FUEL);
1613
1614                 SetResource(this, RES_FUEL, CalcRotRegen(GetResource(this, RES_FUEL), minf, autocvar_g_balance_fuel_regen, autocvar_g_balance_fuel_regenlinear, 
1615                                                                                 frametime * (time > this.pauseregen_finished) * ((this.items & ITEM_JetpackRegen.m_itemid) != 0),
1616                                                                                 maxf, autocvar_g_balance_fuel_rot, autocvar_g_balance_fuel_rotlinear, frametime * (time > this.pauserotfuel_finished), limitf));
1617         }
1618 }
1619
1620 bool zoomstate_set;
1621 void SetZoomState(entity this, float newzoom)
1622 {
1623         if(newzoom != CS(this).zoomstate)
1624         {
1625                 CS(this).zoomstate = newzoom;
1626                 ClientData_Touch(this);
1627         }
1628         zoomstate_set = true;
1629 }
1630
1631 void GetPressedKeys(entity this)
1632 {
1633         MUTATOR_CALLHOOK(GetPressedKeys, this);
1634         int keys = STAT(PRESSED_KEYS, this);
1635         keys = BITSET(keys, KEY_FORWARD,        CS(this).movement.x > 0);
1636         keys = BITSET(keys, KEY_BACKWARD,       CS(this).movement.x < 0);
1637         keys = BITSET(keys, KEY_RIGHT,          CS(this).movement.y > 0);
1638         keys = BITSET(keys, KEY_LEFT,           CS(this).movement.y < 0);
1639
1640         keys = BITSET(keys, KEY_JUMP,           PHYS_INPUT_BUTTON_JUMP(this));
1641         keys = BITSET(keys, KEY_CROUCH,         IS_DUCKED(this)); // workaround: player can't un-crouch until their path is clear, so we keep the button held here
1642         keys = BITSET(keys, KEY_ATCK,           PHYS_INPUT_BUTTON_ATCK(this));
1643         keys = BITSET(keys, KEY_ATCK2,          PHYS_INPUT_BUTTON_ATCK2(this));
1644         CS(this).pressedkeys = keys; // store for other users
1645
1646         STAT(PRESSED_KEYS, this) = keys;
1647 }
1648
1649 /*
1650 ======================
1651 spectate mode routines
1652 ======================
1653 */
1654
1655 void SpectateCopy(entity this, entity spectatee)
1656 {
1657         TC(Client, this); TC(Client, spectatee);
1658
1659         MUTATOR_CALLHOOK(SpectateCopy, spectatee, this);
1660         PS(this) = PS(spectatee);
1661         this.armortype = spectatee.armortype;
1662         SetResourceExplicit(this, RES_ARMOR, GetResource(spectatee, RES_ARMOR));
1663         SetResourceExplicit(this, RES_CELLS, GetResource(spectatee, RES_CELLS));
1664         SetResourceExplicit(this, RES_PLASMA, GetResource(spectatee, RES_PLASMA));
1665         SetResourceExplicit(this, RES_SHELLS, GetResource(spectatee, RES_SHELLS));
1666         SetResourceExplicit(this, RES_BULLETS, GetResource(spectatee, RES_BULLETS));
1667         SetResourceExplicit(this, RES_ROCKETS, GetResource(spectatee, RES_ROCKETS));
1668         SetResourceExplicit(this, RES_FUEL, GetResource(spectatee, RES_FUEL));
1669         this.effects = spectatee.effects & EFMASK_CHEAP; // eat performance
1670         SetResourceExplicit(this, RES_HEALTH, GetResource(spectatee, RES_HEALTH));
1671         CS(this).impulse = 0;
1672         this.items = spectatee.items;
1673         STAT(LAST_PICKUP, this) = STAT(LAST_PICKUP, spectatee);
1674         STAT(HIT_TIME, this) = STAT(HIT_TIME, spectatee);
1675         this.strength_finished = spectatee.strength_finished;
1676         this.invincible_finished = spectatee.invincible_finished;
1677         this.superweapons_finished = spectatee.superweapons_finished;
1678         STAT(PRESSED_KEYS, this) = STAT(PRESSED_KEYS, spectatee);
1679         STAT(WEAPONS, this) = STAT(WEAPONS, spectatee);
1680         this.punchangle = spectatee.punchangle;
1681         this.view_ofs = spectatee.view_ofs;
1682         this.velocity = spectatee.velocity;
1683         this.dmg_take = spectatee.dmg_take;
1684         this.dmg_save = spectatee.dmg_save;
1685         this.dmg_inflictor = spectatee.dmg_inflictor;
1686         this.v_angle = spectatee.v_angle;
1687         this.angles = spectatee.v_angle;
1688         STAT(FROZEN, this) = STAT(FROZEN, spectatee);
1689         STAT(REVIVE_PROGRESS, this) = STAT(REVIVE_PROGRESS, spectatee);
1690         this.viewloc = spectatee.viewloc;
1691         if(!PHYS_INPUT_BUTTON_USE(this) && STAT(CAMERA_SPECTATOR, this) != 2)
1692                 this.fixangle = true;
1693         setorigin(this, spectatee.origin);
1694         setsize(this, spectatee.mins, spectatee.maxs);
1695         SetZoomState(this, CS(spectatee).zoomstate);
1696
1697     anticheat_spectatecopy(this, spectatee);
1698         STAT(HUD, this) = STAT(HUD, spectatee);
1699         if(spectatee.vehicle)
1700     {
1701         this.angles = spectatee.v_angle;
1702
1703         //this.fixangle = false;
1704         //this.velocity = spectatee.vehicle.velocity;
1705         this.vehicle_health = spectatee.vehicle_health;
1706         this.vehicle_shield = spectatee.vehicle_shield;
1707         this.vehicle_energy = spectatee.vehicle_energy;
1708         this.vehicle_ammo1 = spectatee.vehicle_ammo1;
1709         this.vehicle_ammo2 = spectatee.vehicle_ammo2;
1710         this.vehicle_reload1 = spectatee.vehicle_reload1;
1711         this.vehicle_reload2 = spectatee.vehicle_reload2;
1712
1713         //msg_entity = this;
1714
1715        // WriteByte (MSG_ONE, SVC_SETVIEWANGLES);
1716             //WriteAngle(MSG_ONE,  spectatee.v_angle.x);
1717            // WriteAngle(MSG_ONE,  spectatee.v_angle.y);
1718            // WriteAngle(MSG_ONE,  spectatee.v_angle.z);
1719
1720         //WriteByte (MSG_ONE, SVC_SETVIEW);
1721         //    WriteEntity(MSG_ONE, this);
1722         //makevectors(spectatee.v_angle);
1723         //setorigin(this, spectatee.origin - v_forward * 400 + v_up * 300);*/
1724     }
1725 }
1726
1727 bool SpectateUpdate(entity this)
1728 {
1729         if(!this.enemy)
1730                 return false;
1731
1732         if(!IS_PLAYER(this.enemy) || this == this.enemy)
1733         {
1734                 SetSpectatee(this, NULL);
1735                 return false;
1736         }
1737
1738         SpectateCopy(this, this.enemy);
1739
1740         return true;
1741 }
1742
1743 bool SpectateSet(entity this)
1744 {
1745         if(!IS_PLAYER(this.enemy))
1746                 return false;
1747
1748         ClientData_Touch(this.enemy);
1749
1750         msg_entity = this;
1751         WriteByte(MSG_ONE, SVC_SETVIEW);
1752         WriteEntity(MSG_ONE, this.enemy);
1753         set_movetype(this, MOVETYPE_NONE);
1754         accuracy_resend(this);
1755
1756         if(!SpectateUpdate(this))
1757                 PutObserverInServer(this);
1758
1759         return true;
1760 }
1761
1762 void SetSpectatee_status(entity this, int spectatee_num)
1763 {
1764         int oldspectatee_status = CS(this).spectatee_status;
1765         CS(this).spectatee_status = spectatee_num;
1766
1767         if (CS(this).spectatee_status != oldspectatee_status)
1768         {
1769                 ClientData_Touch(this);
1770                 if (g_race || g_cts) race_InitSpectator();
1771         }
1772 }
1773
1774 void SetSpectatee(entity this, entity spectatee)
1775 {
1776         if(IS_BOT_CLIENT(this))
1777                 return; // bots abuse .enemy, this code is useless to them
1778
1779         entity old_spectatee = this.enemy;
1780
1781         this.enemy = spectatee;
1782
1783         // WEAPONTODO
1784         // these are required to fix the spectator bug with arc
1785         if(old_spectatee)
1786         {
1787                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1788                 {
1789                         .entity weaponentity = weaponentities[slot];
1790                         if(old_spectatee.(weaponentity).arc_beam)
1791                                 old_spectatee.(weaponentity).arc_beam.SendFlags |= ARC_SF_SETTINGS;
1792                 }
1793         }
1794         if(this.enemy)
1795         {
1796                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1797                 {
1798                         .entity weaponentity = weaponentities[slot];
1799                         if(this.enemy.(weaponentity).arc_beam)
1800                                 this.enemy.(weaponentity).arc_beam.SendFlags |= ARC_SF_SETTINGS;
1801                 }
1802         }
1803
1804         if (this.enemy)
1805                 SetSpectatee_status(this, etof(this.enemy));
1806
1807         // needed to update spectator list
1808         if(old_spectatee) { ClientData_Touch(old_spectatee); }
1809 }
1810
1811 bool Spectate(entity this, entity pl)
1812 {
1813         if(MUTATOR_CALLHOOK(SpectateSet, this, pl))
1814                 return false;
1815         pl = M_ARGV(1, entity);
1816
1817         SetSpectatee(this, pl);
1818         return SpectateSet(this);
1819 }
1820
1821 bool SpectateNext(entity this)
1822 {
1823         entity ent = find(this.enemy, classname, STR_PLAYER);
1824
1825         if (MUTATOR_CALLHOOK(SpectateNext, this, ent))
1826                 ent = M_ARGV(1, entity);
1827         else if (!ent)
1828                 ent = find(ent, classname, STR_PLAYER);
1829
1830         if(ent) { SetSpectatee(this, ent); }
1831
1832         return SpectateSet(this);
1833 }
1834
1835 bool SpectatePrev(entity this)
1836 {
1837         // NOTE: chain order is from the highest to the lower entnum (unlike find)
1838         entity ent = findchain(classname, STR_PLAYER);
1839         if (!ent) // no player
1840                 return false;
1841
1842         entity first = ent;
1843         // skip players until current spectated player
1844         if(this.enemy)
1845         while(ent && ent != this.enemy)
1846                 ent = ent.chain;
1847
1848         switch (MUTATOR_CALLHOOK(SpectatePrev, this, ent, first))
1849         {
1850                 case MUT_SPECPREV_FOUND:
1851                     ent = M_ARGV(1, entity);
1852                     break;
1853                 case MUT_SPECPREV_RETURN:
1854                     return true;
1855                 case MUT_SPECPREV_CONTINUE:
1856                 default:
1857                 {
1858                         if(ent.chain)
1859                                 ent = ent.chain;
1860                         else
1861                                 ent = first;
1862                         break;
1863                 }
1864         }
1865
1866         SetSpectatee(this, ent);
1867         return SpectateSet(this);
1868 }
1869
1870 /*
1871 =============
1872 ShowRespawnCountdown()
1873
1874 Update a respawn countdown display.
1875 =============
1876 */
1877 void ShowRespawnCountdown(entity this)
1878 {
1879         float number;
1880         if(!IS_DEAD(this)) // just respawned?
1881                 return;
1882         else
1883         {
1884                 number = ceil(this.respawn_time - time);
1885                 if(number <= 0)
1886                         return;
1887                 if(number <= this.respawn_countdown)
1888                 {
1889                         this.respawn_countdown = number - 1;
1890                         if(ceil(this.respawn_time - (time + 0.5)) == number) // only say it if it is the same number even in 0.5s; to prevent overlapping sounds
1891                                 { Send_Notification(NOTIF_ONE, this, MSG_ANNCE, Announcer_PickNumber(CNT_RESPAWN, number)); }
1892                 }
1893         }
1894 }
1895
1896 .bool team_selected;
1897 bool ShowTeamSelection(entity this)
1898 {
1899         if (!teamplay || autocvar_g_campaign || autocvar_g_balance_teams || this.team_selected || (CS(this).wasplayer && autocvar_g_changeteam_banned) || Player_HasRealForcedTeam(this))
1900                 return false;
1901         stuffcmd(this, "menu_showteamselect\n");
1902         return true;
1903 }
1904 void Join(entity this)
1905 {
1906         TRANSMUTE(Player, this);
1907
1908         if(!this.team_selected)
1909         if(autocvar_g_campaign || autocvar_g_balance_teams)
1910                 TeamBalance_JoinBestTeam(this);
1911
1912         if(autocvar_g_campaign)
1913                 campaign_bots_may_start = true;
1914
1915         Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_PREVENT_JOIN);
1916
1917         PutClientInServer(this);
1918
1919         if(IS_PLAYER(this))
1920         if(teamplay && this.team != -1)
1921         {
1922         }
1923         else
1924                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_JOIN_PLAY, this.netname);
1925         this.team_selected = false;
1926 }
1927
1928 int GetPlayerLimit()
1929 {
1930         int player_limit = autocvar_g_maxplayers;
1931         MUTATOR_CALLHOOK(GetPlayerLimit, player_limit);
1932         player_limit = M_ARGV(0, int);
1933         return player_limit;
1934 }
1935
1936 /**
1937  * Determines whether the player is allowed to join. This depends on cvar
1938  * g_maxplayers, if it isn't used this function always return true, otherwise
1939  * it checks whether the number of currently playing players exceeds g_maxplayers.
1940  * @return int number of free slots for players, 0 if none
1941  */
1942 int nJoinAllowed(entity this, entity ignore)
1943 {
1944         if(!ignore)
1945         // this is called that way when checking if anyone may be able to join (to build qcstatus)
1946         // so report 0 free slots if restricted
1947         {
1948                 if(autocvar_g_forced_team_otherwise == "spectate")
1949                         return 0;
1950                 if(autocvar_g_forced_team_otherwise == "spectator")
1951                         return 0;
1952         }
1953
1954         if(this && (Player_GetForcedTeamIndex(this) == TEAM_FORCE_SPECTATOR))
1955                 return 0; // forced spectators can never join
1956
1957         // TODO simplify this
1958         int totalClients = 0;
1959         int currentlyPlaying = 0;
1960         FOREACH_CLIENT(true, {
1961                 if(it != ignore)
1962                         ++totalClients;
1963                 if(IS_REAL_CLIENT(it))
1964                 if(IS_PLAYER(it) || it.caplayer)
1965                         ++currentlyPlaying;
1966         });
1967
1968         int player_limit = GetPlayerLimit();
1969
1970         float free_slots = 0;
1971         if (!player_limit)
1972                 free_slots = maxclients - totalClients;
1973         else if(currentlyPlaying < player_limit)
1974                 free_slots = min(maxclients - totalClients, player_limit - currentlyPlaying);
1975
1976         static float join_prevent_msg_time = 0;
1977         if(this && ignore && !free_slots && time > join_prevent_msg_time)
1978         {
1979                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_JOIN_PREVENT);
1980                 join_prevent_msg_time = time + 3;
1981         }
1982
1983         return free_slots;
1984 }
1985
1986 /**
1987  * Checks whether the client is an observer or spectator, if so, he will get kicked after
1988  * g_maxplayers_spectator_blocktime seconds
1989  */
1990 void checkSpectatorBlock(entity this)
1991 {
1992         if(IS_SPEC(this) || IS_OBSERVER(this))
1993         if(!this.caplayer)
1994         if(IS_REAL_CLIENT(this))
1995         {
1996                 if( time > (CS(this).spectatortime + autocvar_g_maxplayers_spectator_blocktime) ) {
1997                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_QUIT_KICK_SPECTATING);
1998                         dropclient(this);
1999                 }
2000         }
2001 }
2002
2003 void PrintWelcomeMessage(entity this)
2004 {
2005         if(CS(this).motd_actived_time == 0)
2006         {
2007                 if (autocvar_g_campaign) {
2008                         if ((IS_PLAYER(this) && PHYS_INPUT_BUTTON_INFO(this)) || (!IS_PLAYER(this))) {
2009                                 CS(this).motd_actived_time = time;
2010                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOTD, campaign_message);
2011                         }
2012                 } else {
2013                         if (PHYS_INPUT_BUTTON_INFO(this)) {
2014                                 CS(this).motd_actived_time = time;
2015                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOTD, getwelcomemessage(this));
2016                         }
2017                 }
2018         }
2019         else if(CS(this).motd_actived_time > 0) // showing MOTD or campaign message
2020         {
2021                 if (autocvar_g_campaign) {
2022                         if (PHYS_INPUT_BUTTON_INFO(this))
2023                                 CS(this).motd_actived_time = time;
2024                         else if ((time - CS(this).motd_actived_time > 2) && IS_PLAYER(this)) { // hide it some seconds after BUTTON_INFO has been released
2025                                 CS(this).motd_actived_time = 0;
2026                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_MOTD);
2027                         }
2028                 } else {
2029                         if (PHYS_INPUT_BUTTON_INFO(this))
2030                                 CS(this).motd_actived_time = time;
2031                         else if (time - CS(this).motd_actived_time > 2) { // hide it some seconds after BUTTON_INFO has been released
2032                                 CS(this).motd_actived_time = 0;
2033                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_MOTD);
2034                         }
2035                 }
2036         }
2037         else //if(CS(this).motd_actived_time < 0) // just connected, motd is active
2038         {
2039                 if(PHYS_INPUT_BUTTON_INFO(this)) // BUTTON_INFO hides initial MOTD
2040                         CS(this).motd_actived_time = -2; // wait until BUTTON_INFO gets released
2041                 else if(CS(this).motd_actived_time == -2 || IS_PLAYER(this) || IS_SPEC(this))
2042                 {
2043                         // instanctly hide MOTD
2044                         CS(this).motd_actived_time = 0;
2045                         Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_MOTD);
2046                 }
2047         }
2048 }
2049
2050 const int MIN_SPEC_TIME = 1;
2051 bool joinAllowed(entity this)
2052 {
2053         if (CS(this).version_mismatch) return false;
2054         if (time < CS(this).jointime + MIN_SPEC_TIME) return false;
2055         if (!nJoinAllowed(this, this)) return false;
2056         if (teamplay && lockteams) return false;
2057         if (MUTATOR_CALLHOOK(ForbidSpawn, this)) return false;
2058         if (ShowTeamSelection(this)) return false;
2059         return true;
2060 }
2061
2062 .int items_added;
2063 .string shootfromfixedorigin;
2064 bool PlayerThink(entity this)
2065 {
2066         if (game_stopped || intermission_running) {
2067                 this.modelflags &= ~MF_ROCKET;
2068                 if(intermission_running)
2069                         IntermissionThink(this);
2070                 return false;
2071         }
2072
2073         if (timeout_status == TIMEOUT_ACTIVE) {
2074         // don't allow the player to turn around while game is paused
2075                 // FIXME turn this into CSQC stuff
2076                 this.v_angle = this.lastV_angle;
2077                 this.angles = this.lastV_angle;
2078                 this.fixangle = true;
2079         }
2080
2081         if (frametime) player_powerups(this);
2082
2083         if (IS_DEAD(this)) {
2084                 if (this.personal && g_race_qualifying) {
2085                         if (time > this.respawn_time) {
2086                                 STAT(RESPAWN_TIME, this) = this.respawn_time = time + 1; // only retry once a second
2087                                 respawn(this);
2088                                 CS(this).impulse = CHIMPULSE_SPEEDRUN.impulse;
2089                         }
2090                 } else {
2091                         if (frametime) player_anim(this);
2092
2093                         if (this.respawn_flags & RESPAWN_DENY)
2094                         {
2095                                 STAT(RESPAWN_TIME, this) = 0;
2096                                 return false;
2097                         }
2098
2099                         bool button_pressed = (PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_JUMP(this) || PHYS_INPUT_BUTTON_ATCK2(this) || PHYS_INPUT_BUTTON_HOOK(this) || PHYS_INPUT_BUTTON_USE(this));
2100
2101                         switch(this.deadflag)
2102                         {
2103                                 case DEAD_DYING:
2104                                 {
2105                                         if ((this.respawn_flags & RESPAWN_FORCE) && !(this.respawn_time < this.respawn_time_max))
2106                                                 this.deadflag = DEAD_RESPAWNING;
2107                                         else if (!button_pressed || (time >= this.respawn_time_max && (this.respawn_flags & RESPAWN_FORCE)))
2108                                                 this.deadflag = DEAD_DEAD;
2109                                         break;
2110                                 }
2111                                 case DEAD_DEAD:
2112                                 {
2113                                         if (button_pressed)
2114                                                 this.deadflag = DEAD_RESPAWNABLE;
2115                                         else if (time >= this.respawn_time_max && (this.respawn_flags & RESPAWN_FORCE))
2116                                                 this.deadflag = DEAD_RESPAWNING;
2117                                         break;
2118                                 }
2119                                 case DEAD_RESPAWNABLE:
2120                                 {
2121                                         if (!button_pressed || (this.respawn_flags & RESPAWN_FORCE))
2122                                                 this.deadflag = DEAD_RESPAWNING;
2123                                         break;
2124                                 }
2125                                 case DEAD_RESPAWNING:
2126                                 {
2127                                         if (time > this.respawn_time)
2128                                         {
2129                                                 this.respawn_time = time + 1; // only retry once a second
2130                                                 this.respawn_time_max = this.respawn_time;
2131                                                 respawn(this);
2132                                         }
2133                                         break;
2134                                 }
2135                         }
2136
2137                         ShowRespawnCountdown(this);
2138
2139                         if (this.respawn_flags & RESPAWN_SILENT)
2140                                 STAT(RESPAWN_TIME, this) = 0;
2141                         else if ((this.respawn_flags & RESPAWN_FORCE) && this.respawn_time < this.respawn_time_max)
2142                         {
2143                                 if (time < this.respawn_time)
2144                                         STAT(RESPAWN_TIME, this) = this.respawn_time;
2145                                 else if (this.deadflag != DEAD_RESPAWNING)
2146                                         STAT(RESPAWN_TIME, this) = -this.respawn_time_max;
2147                         }
2148                         else
2149                                 STAT(RESPAWN_TIME, this) = this.respawn_time;
2150                 }
2151
2152                 // if respawning, invert stat_respawn_time to indicate this, the client translates it
2153                 if (this.deadflag == DEAD_RESPAWNING && STAT(RESPAWN_TIME, this) > 0)
2154                         STAT(RESPAWN_TIME, this) *= -1;
2155
2156                 return false;
2157         }
2158
2159         FixPlayermodel(this);
2160
2161         if (this.shootfromfixedorigin != autocvar_g_shootfromfixedorigin) {
2162                 this.shootfromfixedorigin = autocvar_g_shootfromfixedorigin;
2163                 stuffcmd(this, sprintf("\ncl_shootfromfixedorigin \"%s\"\n", autocvar_g_shootfromfixedorigin));
2164         }
2165
2166         // LordHavoc: allow firing on move frames (sub-ticrate), this gives better timing on slow servers
2167         //if(frametime)
2168         {
2169                 this.items &= ~this.items_added;
2170
2171                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2172                 {
2173                         .entity weaponentity = weaponentities[slot];
2174                         W_WeaponFrame(this, weaponentity);
2175                 }
2176
2177                 this.items_added = 0;
2178                 if ((this.items & ITEM_Jetpack.m_itemid) && ((this.items & ITEM_JetpackRegen.m_itemid) || GetResource(this, RES_FUEL) >= 0.01))
2179             this.items_added |= IT_FUEL;
2180
2181                 this.items |= this.items_added;
2182         }
2183
2184         player_regen(this);
2185
2186         // WEAPONTODO: Add a weapon request for this
2187         // rot vortex charge to the charge limit
2188         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2189         {
2190                 .entity weaponentity = weaponentities[slot];
2191                 if (WEP_CVAR(vortex, charge_rot_rate) && this.(weaponentity).vortex_charge > WEP_CVAR(vortex, charge_limit) && this.(weaponentity).vortex_charge_rottime < time)
2192                         this.(weaponentity).vortex_charge = bound(WEP_CVAR(vortex, charge_limit), this.(weaponentity).vortex_charge - WEP_CVAR(vortex, charge_rot_rate) * frametime / W_TICSPERFRAME, 1);
2193         }
2194
2195         if (frametime) player_anim(this);
2196
2197         // secret status
2198         secrets_setstatus(this);
2199
2200         // monsters status
2201         monsters_setstatus(this);
2202
2203         this.dmg_team = max(0, this.dmg_team - autocvar_g_teamdamage_resetspeed * frametime);
2204
2205         return true;
2206 }
2207
2208 .bool would_spectate;
2209 void ObserverThink(entity this)
2210 {
2211         if ( CS(this).impulse )
2212         {
2213                 MinigameImpulse(this, CS(this).impulse);
2214                 CS(this).impulse = 0;
2215         }
2216
2217         if (this.flags & FL_JUMPRELEASED) {
2218                 if (PHYS_INPUT_BUTTON_JUMP(this) && joinAllowed(this)) {
2219                         this.flags &= ~FL_JUMPRELEASED;
2220                         this.flags |= FL_SPAWNING;
2221                 } else if(PHYS_INPUT_BUTTON_ATCK(this) && !CS(this).version_mismatch || this.would_spectate) {
2222                         this.flags &= ~FL_JUMPRELEASED;
2223                         if(SpectateNext(this)) {
2224                                 TRANSMUTE(Spectator, this);
2225                         }
2226                 } else {
2227                         int preferred_movetype = ((!PHYS_INPUT_BUTTON_USE(this) ? CS(this).cvar_cl_clippedspectating : !CS(this).cvar_cl_clippedspectating) ? MOVETYPE_FLY_WORLDONLY : MOVETYPE_NOCLIP);
2228                         set_movetype(this, preferred_movetype);
2229                 }
2230         } else {
2231                 if (!(PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_JUMP(this))) {
2232                         this.flags |= FL_JUMPRELEASED;
2233                         if(this.flags & FL_SPAWNING)
2234                         {
2235                                 this.flags &= ~FL_SPAWNING;
2236                                 Join(this);
2237                                 return;
2238                         }
2239                 }
2240         }
2241 }
2242
2243 void SpectatorThink(entity this)
2244 {
2245         if ( CS(this).impulse )
2246         {
2247                 if(MinigameImpulse(this, CS(this).impulse))
2248                         CS(this).impulse = 0;
2249
2250                 if (CS(this).impulse == IMP_weapon_drop.impulse)
2251                 {
2252                         STAT(CAMERA_SPECTATOR, this) = (STAT(CAMERA_SPECTATOR, this) + 1) % 3;
2253                         CS(this).impulse = 0;
2254                         return;
2255                 }
2256         }
2257
2258         if (this.flags & FL_JUMPRELEASED) {
2259                 if (PHYS_INPUT_BUTTON_JUMP(this) && joinAllowed(this)) {
2260                         this.flags &= ~FL_JUMPRELEASED;
2261                         this.flags |= FL_SPAWNING;
2262                 } else if(PHYS_INPUT_BUTTON_ATCK(this) || CS(this).impulse == 10 || CS(this).impulse == 15 || CS(this).impulse == 18 || (CS(this).impulse >= 200 && CS(this).impulse <= 209)) {
2263                         this.flags &= ~FL_JUMPRELEASED;
2264                         if(SpectateNext(this)) {
2265                                 TRANSMUTE(Spectator, this);
2266                         } else {
2267                                 TRANSMUTE(Observer, this);
2268                                 PutClientInServer(this);
2269                         }
2270                         CS(this).impulse = 0;
2271                 } else if(CS(this).impulse == 12 || CS(this).impulse == 16  || CS(this).impulse == 19 || (CS(this).impulse >= 220 && CS(this).impulse <= 229)) {
2272                         this.flags &= ~FL_JUMPRELEASED;
2273                         if(SpectatePrev(this)) {
2274                                 TRANSMUTE(Spectator, this);
2275                         } else {
2276                                 TRANSMUTE(Observer, this);
2277                                 PutClientInServer(this);
2278                         }
2279                         CS(this).impulse = 0;
2280                 } else if (PHYS_INPUT_BUTTON_ATCK2(this)) {
2281                         this.would_spectate = false;
2282                         this.flags &= ~FL_JUMPRELEASED;
2283                         TRANSMUTE(Observer, this);
2284                         PutClientInServer(this);
2285                 } else {
2286                         if(!SpectateUpdate(this))
2287                         {
2288                                 if(!SpectateNext(this))
2289                                 {
2290                                         PutObserverInServer(this);
2291                                         this.would_spectate = true;
2292                                 }
2293                         }
2294                 }
2295         } else {
2296                 if (!(PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_ATCK2(this))) {
2297                         this.flags |= FL_JUMPRELEASED;
2298                         if(this.flags & FL_SPAWNING)
2299                         {
2300                                 this.flags &= ~FL_SPAWNING;
2301                                 Join(this);
2302                                 return;
2303                         }
2304                 }
2305                 if(!SpectateUpdate(this))
2306                         PutObserverInServer(this);
2307         }
2308
2309         this.flags |= FL_CLIENT | FL_NOTARGET;
2310 }
2311
2312 void PlayerUseKey(entity this)
2313 {
2314         if (!IS_PLAYER(this))
2315                 return;
2316
2317         if(this.vehicle)
2318         {
2319                 if(!game_stopped)
2320                 {
2321                         vehicles_exit(this.vehicle, VHEF_NORMAL);
2322                         return;
2323                 }
2324         }
2325         else if(autocvar_g_vehicles_enter)
2326         {
2327                 if(!STAT(FROZEN, this))
2328                 if(!IS_DEAD(this))
2329                 if(!game_stopped)
2330                 {
2331                         entity head, closest_target = NULL;
2332                         head = WarpZone_FindRadius(this.origin, autocvar_g_vehicles_enter_radius, true);
2333
2334                         while(head) // find the closest acceptable target to enter
2335                         {
2336                                 if(IS_VEHICLE(head))
2337                                 if(!IS_DEAD(head))
2338                                 if(!head.owner || ((head.vehicle_flags & VHF_MULTISLOT) && SAME_TEAM(head.owner, this)))
2339                                 if(head.takedamage != DAMAGE_NO)
2340                                 {
2341                                         if(closest_target)
2342                                         {
2343                                                 if(vlen2(this.origin - head.origin) < vlen2(this.origin - closest_target.origin))
2344                                                 { closest_target = head; }
2345                                         }
2346                                         else { closest_target = head; }
2347                                 }
2348
2349                                 head = head.chain;
2350                         }
2351
2352                         if(closest_target) { vehicles_enter(this, closest_target); return; }
2353                 }
2354         }
2355
2356         // a use key was pressed; call handlers
2357         MUTATOR_CALLHOOK(PlayerUseKey, this);
2358 }
2359
2360
2361 /*
2362 =============
2363 PlayerPreThink
2364
2365 Called every frame for each client before the physics are run
2366 =============
2367 */
2368 .float last_vehiclecheck;
2369 void PlayerPreThink (entity this)
2370 {
2371         STAT(GUNALIGN, this) = CS(this).cvar_cl_gunalign; // TODO
2372         STAT(MOVEVARS_CL_TRACK_CANJUMP, this) = CS(this).cvar_cl_movement_track_canjump;
2373
2374         WarpZone_PlayerPhysics_FixVAngle(this);
2375
2376         if (frametime) {
2377                 // physics frames: update anticheat stuff
2378                 anticheat_prethink(this);
2379         }
2380
2381         if (blockSpectators && frametime) {
2382                 // WORKAROUND: only use dropclient in server frames (frametime set).
2383                 // Never use it in cl_movement frames (frametime zero).
2384                 checkSpectatorBlock(this);
2385         }
2386
2387         zoomstate_set = false;
2388
2389         // Check for nameless players
2390         if (this.netname == "" || this.netname != CS(this).netname_previous)
2391         {
2392                 bool assume_unchanged = (CS(this).netname_previous == "");
2393                 if (isInvisibleString(this.netname))
2394                 {
2395                         this.netname = strzone(sprintf("Player#%d", this.playerid));
2396                         assume_unchanged = false;
2397                         // stuffcmd(this, strcat("name ", this.netname, "\n")); // maybe?
2398                 }
2399                 if (!assume_unchanged && autocvar_sv_eventlog)
2400                         GameLogEcho(strcat(":name:", ftos(this.playerid), ":", playername(this, false)));
2401                 strcpy(CS(this).netname_previous, this.netname);
2402         }
2403
2404         // version nagging
2405         if (CS(this).version_nagtime && CS(this).cvar_g_xonoticversion && time > CS(this).version_nagtime) {
2406         CS(this).version_nagtime = 0;
2407         if (strstrofs(CS(this).cvar_g_xonoticversion, "git", 0) >= 0 || strstrofs(CS(this).cvar_g_xonoticversion, "autobuild", 0) >= 0) {
2408             // git client
2409         } else if (strstrofs(autocvar_g_xonoticversion, "git", 0) >= 0 || strstrofs(autocvar_g_xonoticversion, "autobuild", 0) >= 0) {
2410             // git server
2411             Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_BETA, autocvar_g_xonoticversion, CS(this).cvar_g_xonoticversion);
2412         } else {
2413             int r = vercmp(CS(this).cvar_g_xonoticversion, autocvar_g_xonoticversion);
2414             if (r < 0) { // old client
2415                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_OUTDATED, autocvar_g_xonoticversion, CS(this).cvar_g_xonoticversion);
2416             } else if (r > 0) { // old server
2417                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_OLD, autocvar_g_xonoticversion, CS(this).cvar_g_xonoticversion);
2418             }
2419         }
2420     }
2421
2422         // GOD MODE info
2423         if (!(this.flags & FL_GODMODE) && this.max_armorvalue)
2424         {
2425                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_GODMODE_OFF, this.max_armorvalue);
2426                 this.max_armorvalue = 0;
2427         }
2428
2429         if(IS_PLAYER(this))
2430         {
2431                 if (STAT(FROZEN, this) == FROZEN_TEMP_REVIVING)
2432                 {
2433                         STAT(REVIVE_PROGRESS, this) = bound(0, STAT(REVIVE_PROGRESS, this) + frametime * this.revive_speed, 1);
2434                         SetResourceExplicit(this, RES_HEALTH, max(1, STAT(REVIVE_PROGRESS, this) * start_health));
2435                         this.iceblock.alpha = bound(0.2, 1 - STAT(REVIVE_PROGRESS, this), 1);
2436
2437                         if (STAT(REVIVE_PROGRESS, this) >= 1)
2438                                 Unfreeze(this, false);
2439                 }
2440                 else if (STAT(FROZEN, this) == FROZEN_TEMP_DYING)
2441                 {
2442                         STAT(REVIVE_PROGRESS, this) = bound(0, STAT(REVIVE_PROGRESS, this) - frametime * this.revive_speed, 1);
2443                         SetResourceExplicit(this, RES_HEALTH, max(0, autocvar_g_nades_ice_health + (start_health-autocvar_g_nades_ice_health) * STAT(REVIVE_PROGRESS, this)));
2444
2445                         if (GetResource(this, RES_HEALTH) < 1)
2446                         {
2447                                 if (this.vehicle)
2448                                         vehicles_exit(this.vehicle, VHEF_RELEASE);
2449                                 if(this.event_damage)
2450                                         this.event_damage(this, this, this.frozen_by, 1, DEATH_NADE_ICE_FREEZE.m_id, DMG_NOWEP, this.origin, '0 0 0');
2451                         }
2452                         else if (STAT(REVIVE_PROGRESS, this) <= 0)
2453                                 Unfreeze(this, false);
2454                 }
2455         }
2456
2457         MUTATOR_CALLHOOK(PlayerPreThink, this);
2458
2459         if(autocvar_g_vehicles_enter && (time > this.last_vehiclecheck) && !game_stopped && !this.vehicle)
2460         if(IS_PLAYER(this) && !STAT(FROZEN, this) && !IS_DEAD(this))
2461         {
2462                 FOREACH_ENTITY_RADIUS(this.origin, autocvar_g_vehicles_enter_radius, IS_VEHICLE(it),
2463                 {
2464                         if(!IS_DEAD(it) && it.takedamage != DAMAGE_NO)
2465                         if((it.vehicle_flags & VHF_MULTISLOT) && SAME_TEAM(it.owner, this))
2466                         {
2467                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER_GUNNER);
2468                         }
2469                         else if(!it.owner)
2470                         {
2471                                 if(!it.team || SAME_TEAM(this, it))
2472                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER);
2473                                 else if(autocvar_g_vehicles_steal)
2474                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER_STEAL);
2475                         }
2476                 });
2477
2478                 this.last_vehiclecheck = time + 1;
2479         }
2480
2481         if(!CS(this).cvar_cl_newusekeysupported) // FIXME remove this - it was a stupid idea to begin with, we can JUST use the button
2482         {
2483                 if(PHYS_INPUT_BUTTON_USE(this) && !CS(this).usekeypressed)
2484                         PlayerUseKey(this);
2485                 CS(this).usekeypressed = PHYS_INPUT_BUTTON_USE(this);
2486         }
2487
2488         if (IS_REAL_CLIENT(this))
2489                 PrintWelcomeMessage(this);
2490
2491         if (IS_PLAYER(this)) {
2492                 if (IS_REAL_CLIENT(this) && time < CS(this).jointime + MIN_SPEC_TIME)
2493                         error("Client can't be spawned as player on connection!");
2494                 if(!PlayerThink(this))
2495                         return;
2496         }
2497         else if (game_stopped || intermission_running) {
2498                 if(intermission_running)
2499                         IntermissionThink(this);
2500                 return;
2501         }
2502         else if (IS_REAL_CLIENT(this) && !CS(this).autojoin_checked && time >= CS(this).jointime + MIN_SPEC_TIME)
2503         {
2504                 CS(this).autojoin_checked = true;
2505                 // don't do this in ClientConnect
2506                 // many things can go wrong if a client is spawned as player on connection
2507                 if (MUTATOR_CALLHOOK(AutoJoinOnConnection, this)
2508                         || (!(autocvar_sv_spectate || autocvar_g_campaign || (Player_GetForcedTeamIndex(this) == TEAM_FORCE_SPECTATOR))
2509                                 && (!teamplay || autocvar_g_balance_teams)))
2510                 {
2511                         campaign_bots_may_start = true;
2512                         Join(this);
2513                         return;
2514                 }
2515         }
2516         else if (IS_OBSERVER(this)) {
2517                 ObserverThink(this);
2518         }
2519         else if (IS_SPEC(this)) {
2520                 SpectatorThink(this);
2521         }
2522
2523         // WEAPONTODO: Add weapon request for this
2524         if (!zoomstate_set) {
2525                 bool wep_zoomed = false;
2526                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2527                 {
2528                         .entity weaponentity = weaponentities[slot];
2529                         Weapon thiswep = this.(weaponentity).m_weapon;
2530                         if(thiswep != WEP_Null && thiswep.wr_zoom)
2531                                 wep_zoomed += thiswep.wr_zoom(thiswep, this);
2532                 }
2533                 SetZoomState(this, PHYS_INPUT_BUTTON_ZOOM(this) || PHYS_INPUT_BUTTON_ZOOMSCRIPT(this) || wep_zoomed);
2534     }
2535
2536         if (CS(this).teamkill_soundtime && time > CS(this).teamkill_soundtime)
2537         {
2538                 CS(this).teamkill_soundtime = 0;
2539
2540                 entity e = CS(this).teamkill_soundsource;
2541                 entity oldpusher = e.pusher;
2542                 e.pusher = this;
2543                 PlayerSound(e, playersound_teamshoot, CH_VOICE, VOL_BASEVOICE, VOICETYPE_LASTATTACKER_ONLY);
2544                 e.pusher = oldpusher;
2545         }
2546
2547         if (CS(this).taunt_soundtime && time > CS(this).taunt_soundtime) {
2548                 CS(this).taunt_soundtime = 0;
2549                 PlayerSound(this, playersound_taunt, CH_VOICE, VOL_BASEVOICE, VOICETYPE_AUTOTAUNT);
2550         }
2551
2552         target_voicescript_next(this);
2553
2554         // WEAPONTODO: Move into weaponsystem somehow
2555         // if a player goes unarmed after holding a loaded weapon, empty his clip size and remove the crosshair ammo ring
2556         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2557         {
2558                 .entity weaponentity = weaponentities[slot];
2559                 if(this.(weaponentity).m_weapon == WEP_Null)
2560                         this.(weaponentity).clip_load = this.(weaponentity).clip_size = 0;
2561         }
2562 }
2563
2564 void DrownPlayer(entity this)
2565 {
2566         if(IS_DEAD(this) || game_stopped || time < game_starttime)
2567                 return;
2568
2569         if (this.waterlevel != WATERLEVEL_SUBMERGED || this.vehicle)
2570         {
2571                 if(this.air_finished < time)
2572                         PlayerSound(this, playersound_gasp, CH_PLAYER, VOL_BASE, VOICETYPE_PLAYERSOUND);
2573                 this.air_finished = time + autocvar_g_balance_contents_drowndelay;
2574         }
2575         else if (this.air_finished < time)
2576         {       // drown!
2577                 if (this.pain_finished < time)
2578                 {
2579                         Damage (this, NULL, NULL, autocvar_g_balance_contents_playerdamage_drowning * autocvar_g_balance_contents_damagerate, DEATH_DROWN.m_id, DMG_NOWEP, this.origin, '0 0 0');
2580                         this.pain_finished = time + 0.5;
2581                 }
2582         }
2583 }
2584
2585 .bool move_qcphysics;
2586
2587 void Player_Physics(entity this)
2588 {
2589         this.movetype = (this.move_qcphysics) ? MOVETYPE_QCPLAYER : this.move_movetype;
2590
2591         if(!this.move_qcphysics)
2592                 return;
2593
2594         if(!frametime && !CS(this).pm_frametime)
2595                 return;
2596
2597         Movetype_Physics_NoMatchTicrate(this, CS(this).pm_frametime, true);
2598
2599         CS(this).pm_frametime = 0;
2600 }
2601
2602 /*
2603 =============
2604 PlayerPostThink
2605
2606 Called every frame for each client after the physics are run
2607 =============
2608 */
2609 void PlayerPostThink (entity this)
2610 {
2611         Player_Physics(this);
2612
2613         if (sv_maxidle > 0)
2614         if (frametime) // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2615         if (IS_REAL_CLIENT(this))
2616         if (IS_PLAYER(this) || sv_maxidle_spectatorsareidle)
2617         {
2618                 int totalClients = 0;
2619                 if(sv_maxidle_slots > 0)
2620                 {
2621                         FOREACH_CLIENT(IS_REAL_CLIENT(it) || sv_maxidle_slots_countbots,
2622                         {
2623                                 ++totalClients;
2624                         });
2625                 }
2626
2627                 if (sv_maxidle_slots > 0 && (maxclients - totalClients) > sv_maxidle_slots)
2628                 { /* do nothing */ }
2629                 else if (time - CS(this).parm_idlesince < 1) // instead of (time == this.parm_idlesince) to support sv_maxidle <= 10
2630                 {
2631                         if (CS(this).idlekick_lasttimeleft)
2632                         {
2633                                 CS(this).idlekick_lasttimeleft = 0;
2634                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_IDLING);
2635                         }
2636                 }
2637                 else
2638                 {
2639                         float timeleft = ceil(sv_maxidle - (time - CS(this).parm_idlesince));
2640                         if (timeleft == min(10, sv_maxidle - 1)) { // - 1 to support sv_maxidle <= 10
2641                                 if (!CS(this).idlekick_lasttimeleft)
2642                                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_DISCONNECT_IDLING, timeleft);
2643                         }
2644                         if (timeleft <= 0) {
2645                                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_QUIT_KICK_IDLING, this.netname);
2646                                 dropclient(this);
2647                                 return;
2648                         }
2649                         else if (timeleft <= 10) {
2650                                 if (timeleft != CS(this).idlekick_lasttimeleft) {
2651                                     Send_Notification(NOTIF_ONE, this, MSG_ANNCE, Announcer_PickNumber(CNT_IDLE, timeleft));
2652                 }
2653                                 CS(this).idlekick_lasttimeleft = timeleft;
2654                         }
2655                 }
2656         }
2657
2658         CheatFrame(this);
2659
2660         if (game_stopped)
2661         {
2662                 this.solid = SOLID_NOT;
2663                 this.takedamage = DAMAGE_NO;
2664                 set_movetype(this, MOVETYPE_NONE);
2665         }
2666
2667         if (IS_PLAYER(this)) {
2668                 if(this.death_time == time && IS_DEAD(this))
2669                 {
2670                         // player's bbox gets resized now, instead of in the damage event that killed the player,
2671                         // once all the damage events of this frame have been processed with normal size
2672                         this.maxs.z = 5;
2673                         setsize(this, this.mins, this.maxs);
2674                 }
2675                 DrownPlayer(this);
2676                 UpdateChatBubble(this);
2677                 if (CS(this).impulse) ImpulseCommands(this);
2678                 if (game_stopped)
2679                 {
2680                         CSQCMODEL_AUTOUPDATE(this);
2681                         return;
2682                 }
2683                 GetPressedKeys(this);
2684         }
2685
2686         if (this.waypointsprite_attachedforcarrier) {
2687                 float hp = healtharmor_maxdamage(GetResource(this, RES_HEALTH), GetResource(this, RES_ARMOR), autocvar_g_balance_armor_blockpercent, DEATH_WEAPON.m_id).x;
2688                 WaypointSprite_UpdateHealth(this.waypointsprite_attachedforcarrier, hp);
2689         }
2690
2691         CSQCMODEL_AUTOUPDATE(this);
2692 }
2693
2694 /**
2695  * message "": do not say, just test flood control
2696  * return value:
2697  *   1 = accept
2698  *   0 = reject
2699  *  -1 = fake accept
2700  */
2701 int Say(entity source, int teamsay, entity privatesay, string msgin, bool floodcontrol)
2702 {
2703         if (!teamsay && !privatesay && substring(msgin, 0, 1) == " ")
2704                 msgin = substring(msgin, 1, -1); // work around DP say bug (say_team does not have this!)
2705
2706         if (source)
2707                 msgin = formatmessage(source, msgin);
2708
2709         string colorstr;
2710         if (!(IS_PLAYER(source) || source.caplayer))
2711                 colorstr = "^0"; // black for spectators
2712         else if(teamplay)
2713                 colorstr = Team_ColorCode(source.team);
2714         else
2715         {
2716                 colorstr = "";
2717                 teamsay = false;
2718         }
2719
2720         if (!source) {
2721                 colorstr = "";
2722                 teamsay = false;
2723         }
2724
2725         if(msgin != "")
2726                 msgin = trigger_magicear_processmessage_forallears(source, teamsay, privatesay, msgin);
2727
2728         /*
2729          * using bprint solves this... me stupid
2730         // how can we prevent the message from appearing in a listen server?
2731         // for now, just give "say" back and only handle say_team
2732         if(!teamsay)
2733         {
2734                 clientcommand(source, strcat("say ", msgin));
2735                 return;
2736         }
2737         */
2738
2739         string namestr = "";
2740         if (source)
2741                 namestr = playername(source, autocvar_g_chat_teamcolors);
2742
2743         string colorprefix = (strdecolorize(namestr) == namestr) ? "^3" : "^7";
2744
2745         string msgstr = "", cmsgstr = "";
2746         string privatemsgprefix = string_null;
2747         int privatemsgprefixlen = 0;
2748         if (msgin != "")
2749         {
2750                 bool found_me = false;
2751                 if(strstrofs(msgin, "/me", 0) >= 0)
2752                 {
2753                         string newmsgin = "";
2754                         string newnamestr = ((teamsay) ? strcat(colorstr, "(", colorprefix, namestr, colorstr, ")", "^7") : strcat(colorprefix, namestr, "^7"));
2755                         FOREACH_WORD(msgin, true,
2756                         {
2757                                 if(strdecolorize(it) == "/me")
2758                                 {
2759                                         found_me = true;
2760                                         newmsgin = cons(newmsgin, newnamestr);
2761                                 }
2762                                 else
2763                                         newmsgin = cons(newmsgin, it);
2764                         });
2765                         msgin = newmsgin;
2766                 }
2767
2768                 if(privatesay)
2769                 {
2770                         msgstr = strcat("\{1}\{13}* ", colorprefix, namestr, "^3 tells you: ^7");
2771                         privatemsgprefixlen = strlen(msgstr);
2772                         msgstr = strcat(msgstr, msgin);
2773                         cmsgstr = strcat(colorstr, colorprefix, namestr, "^3 tells you:\n^7", msgin);
2774                         privatemsgprefix = strcat("\{1}\{13}* ^3You tell ", playername(privatesay, autocvar_g_chat_teamcolors), ": ^7");
2775                 }
2776                 else if(teamsay)
2777                 {
2778                         if(found_me)
2779                         {
2780                                 //msgin = strreplace("/me", "", msgin);
2781                                 //msgin = substring(msgin, 3, strlen(msgin));
2782                                 //msgin = strreplace("/me", strcat(colorstr, "(", colorprefix, namestr, colorstr, ")^7"), msgin);
2783                                 msgstr = strcat("\{1}\{13}^4* ", "^7", msgin);
2784                         }
2785                         else
2786                                 msgstr = strcat("\{1}\{13}", colorstr, "(", colorprefix, namestr, colorstr, ") ^7", msgin);
2787                         cmsgstr = strcat(colorstr, "(", colorprefix, namestr, colorstr, ")\n^7", msgin);
2788                 }
2789                 else
2790                 {
2791                         if(found_me)
2792                         {
2793                                 //msgin = strreplace("/me", "", msgin);
2794                                 //msgin = substring(msgin, 3, strlen(msgin));
2795                                 //msgin = strreplace("/me", strcat(colorprefix, namestr), msgin);
2796                                 msgstr = strcat("\{1}^4* ^7", msgin);
2797                         }
2798                         else {
2799                                 msgstr = "\{1}";
2800                                 msgstr = strcat(msgstr, (namestr != "") ? strcat(colorprefix, namestr, "^7: ") : "^7");
2801                                 msgstr = strcat(msgstr, msgin);
2802                         }
2803                         cmsgstr = "";
2804                 }
2805                 msgstr = strcat(strreplace("\n", " ", msgstr), "\n"); // newlines only are good for centerprint
2806         }
2807
2808         string fullmsgstr = msgstr;
2809         string fullcmsgstr = cmsgstr;
2810
2811         // FLOOD CONTROL
2812         int flood = 0;
2813         var .float flood_field = floodcontrol_chat;
2814         if(floodcontrol && source)
2815         {
2816                 float flood_spl;
2817                 float flood_burst;
2818                 float flood_lmax;
2819                 float lines;
2820                 if(privatesay)
2821                 {
2822                         flood_spl = autocvar_g_chat_flood_spl_tell;
2823                         flood_burst = autocvar_g_chat_flood_burst_tell;
2824                         flood_lmax = autocvar_g_chat_flood_lmax_tell;
2825                         flood_field = floodcontrol_chattell;
2826                 }
2827                 else if(teamsay)
2828                 {
2829                         flood_spl = autocvar_g_chat_flood_spl_team;
2830                         flood_burst = autocvar_g_chat_flood_burst_team;
2831                         flood_lmax = autocvar_g_chat_flood_lmax_team;
2832                         flood_field = floodcontrol_chatteam;
2833                 }
2834                 else
2835                 {
2836                         flood_spl = autocvar_g_chat_flood_spl;
2837                         flood_burst = autocvar_g_chat_flood_burst;
2838                         flood_lmax = autocvar_g_chat_flood_lmax;
2839                         flood_field = floodcontrol_chat;
2840                 }
2841                 flood_burst = max(0, flood_burst - 1);
2842                 // to match explanation in default.cfg, a value of 3 must allow three-line bursts and not four!
2843
2844                 // do flood control for the default line size
2845                 if(msgstr != "")
2846                 {
2847                         getWrappedLine_remaining = msgstr;
2848                         msgstr = "";
2849                         lines = 0;
2850                         while(getWrappedLine_remaining && (!flood_lmax || lines <= flood_lmax))
2851                         {
2852                                 msgstr = strcat(msgstr, " ", getWrappedLineLen(82.4289758859709, strlennocol)); // perl averagewidth.pl < gfx/vera-sans.width
2853                                 ++lines;
2854                         }
2855                         msgstr = substring(msgstr, 1, strlen(msgstr) - 1);
2856
2857                         if(getWrappedLine_remaining != "")
2858                         {
2859                                 msgstr = strcat(msgstr, "\n");
2860                                 flood = 2;
2861                         }
2862
2863                         if (time >= source.(flood_field))
2864                         {
2865                                 source.(flood_field) = max(time - flood_burst * flood_spl, source.(flood_field)) + lines * flood_spl;
2866                         }
2867                         else
2868                         {
2869                                 flood = 1;
2870                                 msgstr = fullmsgstr;
2871                         }
2872                 }
2873                 else
2874                 {
2875                         if (time >= source.(flood_field))
2876                                 source.(flood_field) = max(time - flood_burst * flood_spl, source.(flood_field)) + flood_spl;
2877                         else
2878                                 flood = 1;
2879                 }
2880
2881                 if (timeout_status == TIMEOUT_ACTIVE) // when game is paused, no flood protection
2882                         source.(flood_field) = flood = 0;
2883         }
2884
2885         string sourcemsgstr, sourcecmsgstr;
2886         if(flood == 2) // cannot happen for empty msgstr
2887         {
2888                 if(autocvar_g_chat_flood_notify_flooder)
2889                 {
2890                         sourcemsgstr = strcat(msgstr, "\n^3FLOOD CONTROL: ^7message too long, trimmed\n");
2891                         sourcecmsgstr = "";
2892                 }
2893                 else
2894                 {
2895                         sourcemsgstr = fullmsgstr;
2896                         sourcecmsgstr = fullcmsgstr;
2897                 }
2898                 cmsgstr = "";
2899         }
2900         else
2901         {
2902                 sourcemsgstr = msgstr;
2903                 sourcecmsgstr = cmsgstr;
2904         }
2905
2906         if (!privatesay && source && !(IS_PLAYER(source) || source.caplayer))
2907         {
2908                 if (!game_stopped)
2909                 if (teamsay || (autocvar_g_chat_nospectators == 1) || (autocvar_g_chat_nospectators == 2 && !warmup_stage))
2910                         teamsay = -1; // spectators
2911         }
2912
2913         if(flood)
2914                 LOG_INFO("NOTE: ", playername(source, true), "^7 is flooding.");
2915
2916         // build sourcemsgstr by cutting off a prefix and replacing it by the other one
2917         if(privatesay)
2918                 sourcemsgstr = strcat(privatemsgprefix, substring(sourcemsgstr, privatemsgprefixlen, -1));
2919
2920         int ret;
2921         if(source && CS(source).muted)
2922         {
2923                 // always fake the message
2924                 ret = -1;
2925         }
2926         else if(flood == 1)
2927         {
2928                 if (autocvar_g_chat_flood_notify_flooder)
2929                 {
2930                         sprint(source, strcat("^3FLOOD CONTROL: ^7wait ^1", ftos(source.(flood_field) - time), "^3 seconds\n"));
2931                         ret = 0;
2932                 }
2933                 else
2934                         ret = -1;
2935         }
2936         else
2937         {
2938                 ret = 1;
2939         }
2940
2941         if (privatesay && source && !(IS_PLAYER(source) || source.caplayer))
2942         {
2943                 if (!game_stopped)
2944                 if ((privatesay && (IS_PLAYER(privatesay) || privatesay.caplayer)) && ((autocvar_g_chat_nospectators == 1) || (autocvar_g_chat_nospectators == 2 && !warmup_stage)))
2945                         ret = -1; // just hide the message completely
2946         }
2947
2948         MUTATOR_CALLHOOK(ChatMessage, source, ret);
2949         ret = M_ARGV(1, int);
2950
2951         string event_log_msg = "";
2952
2953         if(sourcemsgstr != "" && ret != 0)
2954         {
2955                 if(ret < 0) // faked message, because the player is muted
2956                 {
2957                         sprint(source, sourcemsgstr);
2958                         if(sourcecmsgstr != "" && !privatesay)
2959                                 centerprint(source, sourcecmsgstr);
2960                 }
2961                 else if(privatesay) // private message, between 2 people only
2962                 {
2963                         sprint(source, sourcemsgstr);
2964                         if (!autocvar_g_chat_tellprivacy) { dedicated_print(msgstr); } // send to server console too if "tellprivacy" is disabled
2965                         if(!MUTATOR_CALLHOOK(ChatMessageTo, privatesay, source))
2966                         {
2967                                 sprint(privatesay, msgstr);
2968                                 if(cmsgstr != "")
2969                                         centerprint(privatesay, cmsgstr);
2970                         }
2971                 }
2972                 else if ( teamsay && CS(source).active_minigame )
2973                 {
2974                         sprint(source, sourcemsgstr);
2975                         dedicated_print(msgstr); // send to server console too
2976                         FOREACH_CLIENT(IS_REAL_CLIENT(it) && it != source && CS(it).active_minigame == CS(source).active_minigame && !MUTATOR_CALLHOOK(ChatMessageTo, it, source), {
2977                                 sprint(it, msgstr);
2978                         });
2979                         event_log_msg = sprintf(":chat_minigame:%d:%s:%s", source.playerid, CS(source).active_minigame.netname, msgin);
2980
2981                 }
2982                 else if(teamsay > 0) // team message, only sent to team mates
2983                 {
2984                         sprint(source, sourcemsgstr);
2985                         dedicated_print(msgstr); // send to server console too
2986                         if(sourcecmsgstr != "")
2987                                 centerprint(source, sourcecmsgstr);
2988                         FOREACH_CLIENT((IS_PLAYER(it) || it.caplayer) && IS_REAL_CLIENT(it) && it != source && it.team == source.team && !MUTATOR_CALLHOOK(ChatMessageTo, it, source), {
2989                                 sprint(it, msgstr);
2990                                 if(cmsgstr != "")
2991                                         centerprint(it, cmsgstr);
2992                         });
2993                         event_log_msg = sprintf(":chat_team:%d:%d:%s", source.playerid, source.team, strreplace("\n", " ", msgin));
2994                 }
2995                 else if(teamsay < 0) // spectator message, only sent to spectators
2996                 {
2997                         sprint(source, sourcemsgstr);
2998                         dedicated_print(msgstr); // send to server console too
2999                         FOREACH_CLIENT(!(IS_PLAYER(it) || it.caplayer) && IS_REAL_CLIENT(it) && it != source && !MUTATOR_CALLHOOK(ChatMessageTo, it, source), {
3000                                 sprint(it, msgstr);
3001                         });
3002                         event_log_msg = sprintf(":chat_spec:%d:%s", source.playerid, strreplace("\n", " ", msgin));
3003                 }
3004                 else
3005                 {
3006                         if (source) {
3007                                 sprint(source, sourcemsgstr);
3008                                 dedicated_print(msgstr); // send to server console too
3009                                 MX_Say(strcat(playername(source, true), "^7: ", msgin));
3010                         }
3011                         FOREACH_CLIENT(IS_REAL_CLIENT(it) && it != source && !MUTATOR_CALLHOOK(ChatMessageTo, it, source), {
3012                                 sprint(it, msgstr);
3013                         });
3014                         event_log_msg = sprintf(":chat:%d:%s", source.playerid, strreplace("\n", " ", msgin));
3015                 }
3016         }
3017
3018         if (autocvar_sv_eventlog && (event_log_msg != "")) {
3019                 GameLogEcho(event_log_msg);
3020         }
3021
3022         return ret;
3023 }
3024
3025 // hack to copy the button fields from the client entity to the Client State
3026 void PM_UpdateButtons(entity this, entity store)
3027 {
3028         if(this.impulse)
3029                 store.impulse = this.impulse;
3030         this.impulse = 0;
3031
3032         bool typing = this.buttonchat || this.button12;
3033
3034         store.button0 = (typing) ? 0 : this.button0;
3035         //button1?!
3036         store.button2 = (typing) ? 0 : this.button2;
3037         store.button3 = (typing) ? 0 : this.button3;
3038         store.button4 = this.button4;
3039         store.button5 = (typing) ? 0 : this.button5;
3040         store.button6 = this.button6;
3041         store.button7 = this.button7;
3042         store.button8 = this.button8;
3043         store.button9 = this.button9;
3044         store.button10 = this.button10;
3045         store.button11 = this.button11;
3046         store.button12 = this.button12;
3047         store.button13 = this.button13;
3048         store.button14 = this.button14;
3049         store.button15 = this.button15;
3050         store.button16 = this.button16;
3051         store.buttonuse = this.buttonuse;
3052         store.buttonchat = this.buttonchat;
3053
3054         store.cursor_active = this.cursor_active;
3055         store.cursor_screen = this.cursor_screen;
3056         store.cursor_trace_start = this.cursor_trace_start;
3057         store.cursor_trace_endpos = this.cursor_trace_endpos;
3058         store.cursor_trace_ent = this.cursor_trace_ent;
3059
3060         store.ping = this.ping;
3061         store.ping_packetloss = this.ping_packetloss;
3062         store.ping_movementloss = this.ping_movementloss;
3063
3064         store.v_angle = this.v_angle;
3065         store.movement = (typing) ? '0 0 0' : this.movement;
3066 }
3067
3068 NET_HANDLE(fpsreport, bool)
3069 {
3070         int fps = ReadShort();
3071         PlayerScore_Set(sender, SP_FPS, fps);
3072         return true;
3073 }