qcsrc/server/client.qc

   1 #include "client.qh"
   2
   3 #include <server/defs.qh>
   4 #include <server/miscfunctions.qh>
   5 #include <common/effects/all.qh>
   6 #include "anticheat.qh"
   7 #include "impulse.qh"
   8 #include "player.qh"
   9 #include "ipban.qh"
  10 #include "miscfunctions.qh"
  11 #include "portals.qh"
  12 #include "teamplay.qh"
  13 #include "spawnpoints.qh"
  14 #include "resources.qh"
  15 #include "g_damage.qh"
  16 #include "handicap.qh"
  17 #include "g_hook.qh"
  18 #include "command/common.qh"
  19 #include "command/vote.qh"
  20 #include "clientkill.qh"
  21 #include "cheats.qh"
  22 #include "g_world.qh"
  23 #include "race.qh"
  24 #include "antilag.qh"
  25 #include "campaign.qh"
  26 #include "command/common.qh"
  27 #include "scores_rules.qh"
  28 #include "weapons/common.qh"
  29
  30 #include "bot/api.qh"
  31
  32 #include "../common/ent_cs.qh"
  33 #include "../common/wepent.qh"
  34 #include <common/state.qh>
  35
  36 #include "compat/quake3.qh"
  37
  38 #include <common/effects/qc/globalsound.qh>
  39
  40 #include "../common/mapobjects/func/conveyor.qh"
  41 #include "../common/mapobjects/teleporters.qh"
  42 #include "../common/mapobjects/target/spawnpoint.qh"
  43 #include <common/mapobjects/trigger/counter.qh>
  44 #include <common/mapobjects/trigger/swamp.qh>
  45
  46 #include "../common/vehicles/all.qh"
  47
  48 #include "weapons/hitplot.qh"
  49 #include "weapons/weaponsystem.qh"
  50
  51 #include "../common/net_notice.qh"
  52 #include "../common/net_linked.qh"
  53 #include "../common/physics/player.qh"
  54
  55 #include <common/vehicles/sv_vehicles.qh>
  56
  57 #include "../common/items/_mod.qh"
  58
  59 #include "../common/mutators/mutator/waypoints/all.qh"
  60 #include "../common/mutators/mutator/instagib/sv_instagib.qh"
  61 #include <common/gamemodes/_mod.qh>
  62
  63 #include "../common/mapobjects/subs.qh"
  64 #include "../common/mapobjects/triggers.qh"
  65 #include "../common/mapobjects/trigger/secret.qh"
  66
  67 #include "../common/minigames/sv_minigames.qh"
  68
  69 #include "../common/items/inventory.qh"
  70
  71 #include "../common/monsters/sv_monsters.qh"
  72
  73 #include "../lib/warpzone/server.qh"
  74
  75 #include <common/mutators/mutator/overkill/oknex.qh>
  76
  77 STATIC_METHOD(Client, Add, void(Client this, int _team))
  78 {
  79     ClientConnect(this);
  80     TRANSMUTE(Player, this);
  81     this.frame = 12; // 7
  82     this.team = _team;
  83     PutClientInServer(this);
  84 }
  85
  86 STATIC_METHOD(Client, Remove, void(Client this))
  87 {
  88     TRANSMUTE(Observer, this);
  89     PutClientInServer(this);
  90     ClientDisconnect(this);
  91 }
  92
  93 void send_CSQC_teamnagger() {
  94         WriteHeader(MSG_BROADCAST, TE_CSQC_TEAMNAGGER);
  95 }
  96
  97 int CountSpectators(entity player, entity to)
  98 {
  99         if(!player) { return 0; } // not sure how, but best to be safe
 100
 101         int spec_count = 0;
 102
 103         FOREACH_CLIENT(IS_REAL_CLIENT(it) && IS_SPEC(it) && it != to && it.enemy == player,
 104         {
 105                 spec_count++;
 106         });
 107
 108         return spec_count;
 109 }
 110
 111 void WriteSpectators(entity player, entity to)
 112 {
 113         if(!player) { return; } // not sure how, but best to be safe
 114
 115         FOREACH_CLIENT(IS_REAL_CLIENT(it) && IS_SPEC(it) && it != to && it.enemy == player,
 116         {
 117                 WriteByte(MSG_ENTITY, num_for_edict(it));
 118         });
 119 }
 120
 121 bool ClientData_Send(entity this, entity to, int sf)
 122 {
 123         assert(to == this.owner, return false);
 124
 125         entity e = to;
 126         if (IS_SPEC(e)) e = e.enemy;
 127
 128         sf = 0;
 129         if (CS(e).race_completed)       sf |= BIT(0); // forced scoreboard
 130         if (CS(to).spectatee_status)    sf |= BIT(1); // spectator ent number follows
 131         if (CS(e).zoomstate)            sf |= BIT(2); // zoomed
 132         if (autocvar_sv_showspectators) sf |= BIT(4); // show spectators
 133
 134         WriteHeader(MSG_ENTITY, ENT_CLIENT_CLIENTDATA);
 135         WriteByte(MSG_ENTITY, sf);
 136
 137         if (sf & BIT(1))
 138                 WriteByte(MSG_ENTITY, CS(to).spectatee_status);
 139
 140         if(sf & BIT(4))
 141         {
 142                 float specs = CountSpectators(e, to);
 143                 WriteByte(MSG_ENTITY, specs);
 144                 WriteSpectators(e, to);
 145         }
 146
 147         return true;
 148 }
 149
 150 void ClientData_Attach(entity this)
 151 {
 152         Net_LinkEntity(CS(this).clientdata = new_pure(clientdata), false, 0, ClientData_Send);
 153         CS(this).clientdata.drawonlytoclient = this;
 154         CS(this).clientdata.owner = this;
 155 }
 156
 157 void ClientData_Detach(entity this)
 158 {
 159         delete(CS(this).clientdata);
 160         CS(this).clientdata = NULL;
 161 }
 162
 163 void ClientData_Touch(entity e)
 164 {
 165         entity cd = CS(e).clientdata;
 166         if (cd) { cd.SendFlags = 1; }
 167
 168         // make it spectatable
 169         FOREACH_CLIENT(IS_REAL_CLIENT(it) && it != e && IS_SPEC(it) && it.enemy == e,
 170         {
 171                 entity cd = CS(it).clientdata;
 172                 if (cd) { cd.SendFlags = 1; }
 173         });
 174 }
 175
 176
 177 /*
 178 =============
 179 CheckPlayerModel
 180
 181 Checks if the argument string can be a valid playermodel.
 182 Returns a valid one in doubt.
 183 =============
 184 */
 185 string FallbackPlayerModel;
 186 string CheckPlayerModel(string plyermodel) {
 187         if(FallbackPlayerModel != cvar_defstring("_cl_playermodel"))
 188         {
 189                 // note: we cannot summon Don Strunzone here, some player may
 190                 // still have the model string set. In case anyone manages how
 191                 // to change a cvar default, we'll have a small leak here.
 192                 FallbackPlayerModel = strzone(cvar_defstring("_cl_playermodel"));
 193         }
 194         // only in right path
 195         if( substring(plyermodel,0,14) != "models/player/")
 196                 return FallbackPlayerModel;
 197         // only good file extensions
 198         if(substring(plyermodel,-4,4) != ".zym")
 199         if(substring(plyermodel,-4,4) != ".dpm")
 200         if(substring(plyermodel,-4,4) != ".iqm")
 201         if(substring(plyermodel,-4,4) != ".md3")
 202         if(substring(plyermodel,-4,4) != ".psk")
 203                 return FallbackPlayerModel;
 204         // forbid the LOD models
 205         if(substring(plyermodel, -9,5) == "_lod1")
 206                 return FallbackPlayerModel;
 207         if(substring(plyermodel, -9,5) == "_lod2")
 208                 return FallbackPlayerModel;
 209         if(plyermodel != strtolower(plyermodel))
 210                 return FallbackPlayerModel;
 211         // also, restrict to server models
 212         if(autocvar_sv_servermodelsonly)
 213         {
 214                 if(!fexists(plyermodel))
 215                         return FallbackPlayerModel;
 216         }
 217         return plyermodel;
 218 }
 219
 220 void setplayermodel(entity e, string modelname)
 221 {
 222         precache_model(modelname);
 223         _setmodel(e, modelname);
 224         player_setupanimsformodel(e);
 225         if(!autocvar_g_debug_globalsounds)
 226                 UpdatePlayerSounds(e);
 227 }
 228
 229 /** putting a client as observer in the server */
 230 void PutObserverInServer(entity this)
 231 {
 232     bool mutator_returnvalue = MUTATOR_CALLHOOK(MakePlayerObserver, this);
 233         PlayerState_detach(this);
 234
 235         if (IS_PLAYER(this))
 236         {
 237                 if(GetResource(this, RES_HEALTH) >= 1)
 238                 {
 239                         // despawn effect
 240                         Send_Effect(EFFECT_SPAWN_NEUTRAL, this.origin, '0 0 0', 1);
 241                 }
 242
 243                 // was a player, recount votes and ready status
 244                 if(IS_REAL_CLIENT(this))
 245                 {
 246                         if (vote_called) { VoteCount(false); }
 247                         ReadyCount();
 248                 }
 249     }
 250
 251     {
 252         entity spot = SelectSpawnPoint(this, true);
 253         if (!spot) LOG_FATAL("No spawnpoints for observers?!?");
 254         this.angles = vec2(spot.angles);
 255         this.fixangle = true;
 256         // offset it so that the spectator spawns higher off the ground, looks better this way
 257         setorigin(this, spot.origin + STAT(PL_VIEW_OFS, this));
 258         if (IS_REAL_CLIENT(this))
 259         {
 260             msg_entity = this;
 261             WriteByte(MSG_ONE, SVC_SETVIEW);
 262             WriteEntity(MSG_ONE, this);
 263         }
 264         // give the spectator some space between walls for MOVETYPE_FLY_WORLDONLY
 265         // so that your view doesn't go into the ceiling with MOVETYPE_FLY_WORLDONLY, previously "PL_VIEW_OFS"
 266         if(!autocvar_g_debug_globalsounds)
 267         {
 268                 // needed for player sounds
 269                 this.model = "";
 270                 FixPlayermodel(this);
 271         }
 272         setmodel(this, MDL_Null);
 273         setsize(this, STAT(PL_CROUCH_MIN, this), STAT(PL_CROUCH_MAX, this));
 274         this.view_ofs = '0 0 0';
 275     }
 276
 277     RemoveGrapplingHooks(this);
 278         Portal_ClearAll(this);
 279         Unfreeze(this, false);
 280         SetSpectatee(this, NULL);
 281
 282         if (this.alivetime)
 283         {
 284                 if (!warmup_stage)
 285                         PlayerStats_GameReport_Event_Player(this, PLAYERSTATS_ALIVETIME, time - this.alivetime);
 286                 this.alivetime = 0;
 287         }
 288
 289         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
 290
 291         WaypointSprite_PlayerDead(this);
 292
 293         if (CS(this).killcount != FRAGS_SPECTATOR)
 294         {
 295                 if(!game_stopped)
 296                 if(autocvar_g_chat_nospectators == 1 || (!warmup_stage && autocvar_g_chat_nospectators == 2))
 297                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_CHAT_NOSPECTATORS);
 298         }
 299
 300         accuracy_resend(this);
 301
 302         CS(this).spectatortime = time;
 303         if(this.bot_attack)
 304                 IL_REMOVE(g_bot_targets, this);
 305         this.bot_attack = false;
 306         if(this.monster_attack)
 307                 IL_REMOVE(g_monster_targets, this);
 308         this.monster_attack = false;
 309     STAT(HUD, this) = HUD_NORMAL;
 310         TRANSMUTE(Observer, this);
 311         this.iscreature = false;
 312         this.teleportable = TELEPORT_SIMPLE;
 313         if(this.damagedbycontents)
 314                 IL_REMOVE(g_damagedbycontents, this);
 315         this.damagedbycontents = false;
 316         SetResourceExplicit(this, RES_HEALTH, FRAGS_SPECTATOR);
 317         SetSpectatee_status(this, etof(this));
 318         this.takedamage = DAMAGE_NO;
 319         this.solid = SOLID_NOT;
 320         set_movetype(this, MOVETYPE_FLY_WORLDONLY); // user preference is controlled by playerprethink
 321         this.flags = FL_CLIENT | FL_NOTARGET;
 322         this.effects = 0;
 323         SetResourceExplicit(this, RES_ARMOR, autocvar_g_balance_armor_start); // was 666?!
 324         this.pauserotarmor_finished = 0;
 325         this.pauserothealth_finished = 0;
 326         this.pauseregen_finished = 0;
 327         this.damageforcescale = 0;
 328         this.death_time = 0;
 329         this.respawn_flags = 0;
 330         this.respawn_time = 0;
 331         STAT(RESPAWN_TIME, this) = 0;
 332         this.alpha = 0;
 333         this.scale = 0;
 334         this.fade_time = 0;
 335         this.pain_frame = 0;
 336         this.pain_finished = 0;
 337         STAT(STRENGTH_FINISHED, this) = 0;
 338         STAT(INVINCIBLE_FINISHED, this) = 0;
 339         STAT(SUPERWEAPONS_FINISHED, this) = 0;
 340         this.air_finished = 0;
 341         //this.dphitcontentsmask = 0;
 342         this.dphitcontentsmask = DPCONTENTS_SOLID;
 343         if (autocvar_g_playerclip_collisions)
 344                 this.dphitcontentsmask |= DPCONTENTS_PLAYERCLIP;
 345         this.pushltime = 0;
 346         this.istypefrag = 0;
 347         setthink(this, func_null);
 348         this.nextthink = 0;
 349         this.deadflag = DEAD_NO;
 350         this.crouch = false;
 351         STAT(REVIVE_PROGRESS, this) = 0;
 352         this.revival_time = 0;
 353         this.draggable = drag_undraggable;
 354
 355         this.items = 0;
 356         STAT(WEAPONS, this) = '0 0 0';
 357         this.drawonlytoclient = this;
 358
 359         this.viewloc = NULL;
 360
 361         //this.spawnpoint_targ = NULL; // keep it so they can return to where they were?
 362
 363         this.weaponmodel = "";
 364         for (int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 365         {
 366                 this.weaponentities[slot] = NULL;
 367         }
 368         this.exteriorweaponentity = NULL;
 369         CS(this).killcount = FRAGS_SPECTATOR;
 370         this.velocity = '0 0 0';
 371         this.avelocity = '0 0 0';
 372         this.punchangle = '0 0 0';
 373         this.punchvector = '0 0 0';
 374         this.oldvelocity = this.velocity;
 375         this.fire_endtime = -1;
 376         this.event_damage = func_null;
 377         this.event_heal = func_null;
 378
 379         for(int slot = 0; slot < MAX_AXH; ++slot)
 380         {
 381                 entity axh = this.(AuxiliaryXhair[slot]);
 382                 this.(AuxiliaryXhair[slot]) = NULL;
 383
 384                 if(axh.owner == this && axh != NULL && !wasfreed(axh))
 385                         delete(axh);
 386         }
 387
 388         if (mutator_returnvalue)
 389         {
 390                 // mutator prevents resetting teams+score
 391         }
 392         else
 393         {
 394                 SetPlayerTeam(this, -1, TEAM_CHANGE_SPECTATOR);
 395                 this.frags = FRAGS_SPECTATOR;
 396         }
 397         if (CS(this).just_joined)
 398                 CS(this).just_joined = false;
 399 }
 400
 401 int player_getspecies(entity this)
 402 {
 403         get_model_parameters(this.model, this.skin);
 404         int s = get_model_parameters_species;
 405         get_model_parameters(string_null, 0);
 406         if (s < 0) return SPECIES_HUMAN;
 407         return s;
 408 }
 409
 410 .float model_randomizer;
 411 void FixPlayermodel(entity player)
 412 {
 413         string defaultmodel = "";
 414         int defaultskin = 0;
 415         if(autocvar_sv_defaultcharacter)
 416         {
 417                 if(teamplay)
 418                 {
 419                         switch(player.team)
 420                         {
 421                                 case NUM_TEAM_1: defaultmodel = autocvar_sv_defaultplayermodel_red; defaultskin = autocvar_sv_defaultplayerskin_red; break;
 422                                 case NUM_TEAM_2: defaultmodel = autocvar_sv_defaultplayermodel_blue; defaultskin = autocvar_sv_defaultplayerskin_blue; break;
 423                                 case NUM_TEAM_3: defaultmodel = autocvar_sv_defaultplayermodel_yellow; defaultskin = autocvar_sv_defaultplayerskin_yellow; break;
 424                                 case NUM_TEAM_4: defaultmodel = autocvar_sv_defaultplayermodel_pink; defaultskin = autocvar_sv_defaultplayerskin_pink; break;
 425                         }
 426                 }
 427
 428                 if(defaultmodel == "")
 429                 {
 430                         defaultmodel = autocvar_sv_defaultplayermodel;
 431                         defaultskin = autocvar_sv_defaultplayerskin;
 432                 }
 433
 434                 int n = tokenize_console(defaultmodel);
 435                 if(n > 0)
 436                 {
 437                         defaultmodel = argv(floor(n * CS(player).model_randomizer));
 438                         // However, do NOT randomize if the player-selected model is in the list.
 439                         for (int i = 0; i < n; ++i)
 440                                 if ((argv(i) == player.playermodel && defaultskin == stof(player.playerskin)) || argv(i) == strcat(player.playermodel, ":", player.playerskin))
 441                                         defaultmodel = argv(i);
 442                 }
 443
 444                 int i = strstrofs(defaultmodel, ":", 0);
 445                 if(i >= 0)
 446                 {
 447                         defaultskin = stof(substring(defaultmodel, i+1, -1));
 448                         defaultmodel = substring(defaultmodel, 0, i);
 449                 }
 450         }
 451         if(autocvar_sv_defaultcharacterskin && !defaultskin)
 452         {
 453                 if(teamplay)
 454                 {
 455                         switch(player.team)
 456                         {
 457                                 case NUM_TEAM_1: defaultskin = autocvar_sv_defaultplayerskin_red; break;
 458                                 case NUM_TEAM_2: defaultskin = autocvar_sv_defaultplayerskin_blue; break;
 459                                 case NUM_TEAM_3: defaultskin = autocvar_sv_defaultplayerskin_yellow; break;
 460                                 case NUM_TEAM_4: defaultskin = autocvar_sv_defaultplayerskin_pink; break;
 461                         }
 462                 }
 463
 464                 if(!defaultskin)
 465                         defaultskin = autocvar_sv_defaultplayerskin;
 466         }
 467
 468         MUTATOR_CALLHOOK(FixPlayermodel, defaultmodel, defaultskin, player);
 469         defaultmodel = M_ARGV(0, string);
 470         defaultskin = M_ARGV(1, int);
 471
 472         bool chmdl = false;
 473         int oldskin;
 474         if(defaultmodel != "")
 475         {
 476                 if (defaultmodel != player.model)
 477                 {
 478                         vector m1 = player.mins;
 479                         vector m2 = player.maxs;
 480                         setplayermodel (player, defaultmodel);
 481                         setsize (player, m1, m2);
 482                         chmdl = true;
 483                 }
 484
 485                 oldskin = player.skin;
 486                 player.skin = defaultskin;
 487         } else {
 488                 if (player.playermodel != player.model || player.playermodel == "")
 489                 {
 490                         player.playermodel = CheckPlayerModel(player.playermodel); // this is never "", so no endless loop
 491                         vector m1 = player.mins;
 492                         vector m2 = player.maxs;
 493                         setplayermodel (player, player.playermodel);
 494                         setsize (player, m1, m2);
 495                         chmdl = true;
 496                 }
 497
 498                 if(!autocvar_sv_defaultcharacterskin)
 499                 {
 500                         oldskin = player.skin;
 501                         player.skin = stof(player.playerskin);
 502                 }
 503                 else
 504                 {
 505                         oldskin = player.skin;
 506                         player.skin = defaultskin;
 507                 }
 508         }
 509
 510         if(chmdl || oldskin != player.skin) // model or skin has changed
 511         {
 512                 player.species = player_getspecies(player); // update species
 513                 if(!autocvar_g_debug_globalsounds)
 514                         UpdatePlayerSounds(player); // update skin sounds
 515         }
 516
 517         if(!teamplay)
 518                 if(strlen(autocvar_sv_defaultplayercolors))
 519                         if(player.clientcolors != stof(autocvar_sv_defaultplayercolors))
 520                                 setcolor(player, stof(autocvar_sv_defaultplayercolors));
 521 }
 522
 523 void PutPlayerInServer(entity this)
 524 {
 525         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
 526
 527         PlayerState_attach(this);
 528         accuracy_resend(this);
 529
 530         if (this.team < 0)
 531                 TeamBalance_JoinBestTeam(this);
 532
 533         entity spot = SelectSpawnPoint(this, false);
 534         if (!spot) {
 535                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_JOIN_NOSPAWNS);
 536                 return; // spawn failed
 537         }
 538
 539         TRANSMUTE(Player, this);
 540
 541         CS(this).wasplayer = true;
 542         this.iscreature = true;
 543         this.teleportable = TELEPORT_NORMAL;
 544         if(!this.damagedbycontents)
 545                 IL_PUSH(g_damagedbycontents, this);
 546         this.damagedbycontents = true;
 547         set_movetype(this, MOVETYPE_WALK);
 548         this.solid = SOLID_SLIDEBOX;
 549         this.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_SOLID;
 550         if (autocvar_g_playerclip_collisions)
 551                 this.dphitcontentsmask |= DPCONTENTS_PLAYERCLIP;
 552         if (IS_BOT_CLIENT(this) && autocvar_g_botclip_collisions)
 553                 this.dphitcontentsmask |= DPCONTENTS_BOTCLIP;
 554         this.frags = FRAGS_PLAYER;
 555         if (INDEPENDENT_PLAYERS) MAKE_INDEPENDENT_PLAYER(this);
 556         this.flags = FL_CLIENT | FL_PICKUPITEMS;
 557         if (autocvar__notarget)
 558                 this.flags |= FL_NOTARGET;
 559         this.takedamage = DAMAGE_AIM;
 560         this.effects = EF_TELEPORT_BIT | EF_RESTARTANIM_BIT;
 561
 562         if (warmup_stage) {
 563                 SetResource(this, RES_SHELLS, warmup_start_ammo_shells);
 564                 SetResource(this, RES_BULLETS, warmup_start_ammo_nails);
 565                 SetResource(this, RES_ROCKETS, warmup_start_ammo_rockets);
 566                 SetResource(this, RES_CELLS, warmup_start_ammo_cells);
 567                 SetResource(this, RES_PLASMA, warmup_start_ammo_plasma);
 568                 SetResource(this, RES_FUEL, warmup_start_ammo_fuel);
 569                 SetResource(this, RES_HEALTH, warmup_start_health);
 570                 SetResource(this, RES_ARMOR, warmup_start_armorvalue);
 571                 STAT(WEAPONS, this) = WARMUP_START_WEAPONS;
 572         } else {
 573                 SetResource(this, RES_SHELLS, start_ammo_shells);
 574                 SetResource(this, RES_BULLETS, start_ammo_nails);
 575                 SetResource(this, RES_ROCKETS, start_ammo_rockets);
 576                 SetResource(this, RES_CELLS, start_ammo_cells);
 577                 SetResource(this, RES_PLASMA, start_ammo_plasma);
 578                 SetResource(this, RES_FUEL, start_ammo_fuel);
 579                 SetResource(this, RES_HEALTH, start_health);
 580                 SetResource(this, RES_ARMOR, start_armorvalue);
 581                 STAT(WEAPONS, this) = start_weapons;
 582                 if (MUTATOR_CALLHOOK(ForbidRandomStartWeapons, this) == false)
 583                 {
 584                         GiveRandomWeapons(this, random_start_weapons_count,
 585                                 autocvar_g_random_start_weapons, random_start_ammo);
 586                 }
 587         }
 588         SetSpectatee_status(this, 0);
 589
 590         PS(this).dual_weapons = '0 0 0';
 591
 592         STAT(SUPERWEAPONS_FINISHED, this) = (STAT(WEAPONS, this) & WEPSET_SUPERWEAPONS) ? time + autocvar_g_balance_superweapons_time : 0;
 593
 594         this.items = start_items;
 595
 596         this.spawnshieldtime = time + autocvar_g_spawnshieldtime;
 597         this.pauserotarmor_finished = time + autocvar_g_balance_pause_armor_rot_spawn;
 598         this.pauserothealth_finished = time + autocvar_g_balance_pause_health_rot_spawn;
 599         this.pauserotfuel_finished = time + autocvar_g_balance_pause_fuel_rot_spawn;
 600         this.pauseregen_finished = time + autocvar_g_balance_pause_health_regen_spawn;
 601         if (!sv_ready_restart_after_countdown && time < game_starttime)
 602         {
 603                 float f = game_starttime - time;
 604                 this.spawnshieldtime += f;
 605                 this.pauserotarmor_finished += f;
 606                 this.pauserothealth_finished += f;
 607                 this.pauseregen_finished += f;
 608         }
 609
 610         this.damageforcescale = autocvar_g_player_damageforcescale;
 611         this.death_time = 0;
 612         this.respawn_flags = 0;
 613         this.respawn_time = 0;
 614         STAT(RESPAWN_TIME, this) = 0;
 615         bool q3dfcompat = autocvar_sv_q3defragcompat && autocvar_sv_q3defragcompat_changehitbox;
 616         this.scale = ((q3dfcompat) ? 0.9 : autocvar_sv_player_scale);
 617         this.fade_time = 0;
 618         this.pain_frame = 0;
 619         this.pain_finished = 0;
 620         this.pushltime = 0;
 621         setthink(this, func_null); // players have no think function
 622         this.nextthink = 0;
 623         this.dmg_team = 0;
 624         PS(this).ballistics_density = autocvar_g_ballistics_density_player;
 625
 626         this.deadflag = DEAD_NO;
 627
 628         this.angles = spot.angles;
 629         this.angles_z = 0; // never spawn tilted even if the spot says to
 630         if (IS_BOT_CLIENT(this))
 631         {
 632                 this.v_angle = this.angles;
 633                 bot_aim_reset(this);
 634         }
 635         this.fixangle = true; // turn this way immediately
 636         this.oldvelocity = this.velocity = '0 0 0';
 637         this.avelocity = '0 0 0';
 638         this.punchangle = '0 0 0';
 639         this.punchvector = '0 0 0';
 640
 641         STAT(STRENGTH_FINISHED, this) = 0;
 642         STAT(INVINCIBLE_FINISHED, this) = 0;
 643         this.fire_endtime = -1;
 644         STAT(REVIVE_PROGRESS, this) = 0;
 645         this.revival_time = 0;
 646
 647         // TODO: we can't set these in the PlayerSpawn hook since the target code is called before it!
 648         STAT(BUFFS, this) = 0;
 649         STAT(BUFF_TIME, this) = 0;
 650
 651         this.air_finished = 0;
 652         this.waterlevel = WATERLEVEL_NONE;
 653         this.watertype = CONTENT_EMPTY;
 654
 655         entity spawnevent = new_pure(spawnevent);
 656         spawnevent.owner = this;
 657         Net_LinkEntity(spawnevent, false, 0.5, SpawnEvent_Send);
 658
 659         // Cut off any still running player sounds.
 660         stopsound(this, CH_PLAYER_SINGLE);
 661         stopsound(this, CH_TRIGGER_SINGLE);
 662
 663         this.model = "";
 664         FixPlayermodel(this);
 665         this.drawonlytoclient = NULL;
 666
 667         this.viewloc = NULL;
 668
 669         for(int slot = 0; slot < MAX_AXH; ++slot)
 670         {
 671                 entity axh = this.(AuxiliaryXhair[slot]);
 672                 this.(AuxiliaryXhair[slot]) = NULL;
 673
 674                 if(axh.owner == this && axh != NULL && !wasfreed(axh))
 675                         delete(axh);
 676         }
 677
 678         this.spawnpoint_targ = NULL;
 679
 680         this.crouch = false;
 681         this.view_ofs = STAT(PL_VIEW_OFS, this);
 682         setsize(this, STAT(PL_MIN, this), STAT(PL_MAX, this));
 683         this.spawnorigin = spot.origin;
 684         setorigin(this, spot.origin + '0 0 1' * (1 - this.mins.z - 24));
 685         // don't reset back to last position, even if new position is stuck in solid
 686         this.oldorigin = this.origin;
 687         if(this.conveyor)
 688                 IL_REMOVE(g_conveyed, this);
 689         this.conveyor = NULL; // prevent conveyors at the previous location from moving a freshly spawned player
 690         if(this.swampslug)
 691                 IL_REMOVE(g_swamped, this);
 692         this.swampslug = NULL;
 693         this.swamp_interval = 0;
 694         IL_EACH(g_counters, it.realowner == this,
 695         {
 696                 delete(it);
 697         });
 698         STAT(HUD, this) = HUD_NORMAL;
 699
 700         this.event_damage = PlayerDamage;
 701         this.event_heal = PlayerHeal;
 702
 703         this.draggable = func_null;
 704
 705         if(!this.bot_attack)
 706                 IL_PUSH(g_bot_targets, this);
 707         this.bot_attack = true;
 708         if(!this.monster_attack)
 709                 IL_PUSH(g_monster_targets, this);
 710         this.monster_attack = true;
 711         navigation_dynamicgoal_init(this, false);
 712
 713         PHYS_INPUT_BUTTON_ATCK(this) = PHYS_INPUT_BUTTON_JUMP(this) = PHYS_INPUT_BUTTON_ATCK2(this) = false;
 714
 715         // player was spectator
 716         if (CS(this).killcount == FRAGS_SPECTATOR) {
 717                 PlayerScore_Clear(this);
 718                 CS(this).killcount = 0;
 719                 CS(this).startplaytime = time;
 720         }
 721
 722         for (int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 723         {
 724                 .entity weaponentity = weaponentities[slot];
 725                 CL_SpawnWeaponentity(this, weaponentity);
 726         }
 727         this.alpha = default_player_alpha;
 728         this.colormod = '1 1 1' * autocvar_g_player_brightness;
 729         this.exteriorweaponentity.alpha = default_weapon_alpha;
 730
 731         this.speedrunning = false;
 732
 733         this.counter_cnt = 0;
 734         this.fragsfilter_cnt = 0;
 735
 736         target_voicescript_clear(this);
 737
 738         // reset fields the weapons may use
 739         FOREACH(Weapons, true, {
 740                 it.wr_resetplayer(it, this);
 741                         // reload all reloadable weapons
 742                 if (it.spawnflags & WEP_FLAG_RELOADABLE) {
 743                         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 744                         {
 745                                 .entity weaponentity = weaponentities[slot];
 746                                 this.(weaponentity).weapon_load[it.m_id] = it.reloading_ammo;
 747                         }
 748                 }
 749         });
 750
 751         {
 752                 string s = spot.target;
 753                 if(g_assault || g_race) // TODO: make targeting work in assault & race without this hack
 754                         spot.target = string_null;
 755                 SUB_UseTargets(spot, this, NULL);
 756                 if(g_assault || g_race)
 757                         spot.target = s;
 758         }
 759
 760         Unfreeze(this, false);
 761
 762         MUTATOR_CALLHOOK(PlayerSpawn, this, spot);
 763
 764         if (autocvar_spawn_debug)
 765         {
 766                 sprint(this, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
 767                 delete(spot); // usefull for checking if there are spawnpoints, that let drop through the floor
 768         }
 769
 770         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 771         {
 772                 .entity weaponentity = weaponentities[slot];
 773                 if(slot == 0 || autocvar_g_weaponswitch_debug == 1)
 774                         this.(weaponentity).m_switchweapon = w_getbestweapon(this, weaponentity);
 775                 else
 776                         this.(weaponentity).m_switchweapon = WEP_Null;
 777                 this.(weaponentity).m_weapon = WEP_Null;
 778                 this.(weaponentity).weaponname = "";
 779                 this.(weaponentity).m_switchingweapon = WEP_Null;
 780                 this.(weaponentity).cnt = -1;
 781         }
 782
 783         MUTATOR_CALLHOOK(PlayerWeaponSelect, this);
 784
 785         if (CS(this).impulse) ImpulseCommands(this);
 786
 787         W_ResetGunAlign(this, CS(this).cvar_cl_gunalign);
 788         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 789         {
 790                 .entity weaponentity = weaponentities[slot];
 791                 W_WeaponFrame(this, weaponentity);
 792         }
 793
 794         if (!warmup_stage && !this.alivetime)
 795                 this.alivetime = time;
 796
 797         antilag_clear(this, CS(this));
 798 }
 799
 800 /** Called when a client spawns in the server */
 801 void PutClientInServer(entity this)
 802 {
 803         if (IS_BOT_CLIENT(this)) {
 804                 TRANSMUTE(Player, this);
 805         } else if (IS_REAL_CLIENT(this)) {
 806                 msg_entity = this;
 807                 WriteByte(MSG_ONE, SVC_SETVIEW);
 808                 WriteEntity(MSG_ONE, this);
 809         }
 810         if (game_stopped)
 811                 TRANSMUTE(Observer, this);
 812
 813         SetSpectatee(this, NULL);
 814
 815         // reset player keys
 816         if(PS(this))
 817                 PS(this).itemkeys = 0;
 818
 819         MUTATOR_CALLHOOK(PutClientInServer, this);
 820
 821         if (IS_OBSERVER(this)) {
 822                 PutObserverInServer(this);
 823         } else if (IS_PLAYER(this)) {
 824                 PutPlayerInServer(this);
 825         }
 826 }
 827
 828 // TODO do we need all these fields, or should we stop autodetecting runtime
 829 // changes and just have a console command to update this?
 830 bool ClientInit_SendEntity(entity this, entity to, int sf)
 831 {
 832         WriteHeader(MSG_ENTITY, _ENT_CLIENT_INIT);
 833         return = true;
 834         msg_entity = to;
 835         // MSG_INIT replacement
 836         // TODO: make easier to use
 837         Registry_send_all();
 838         W_PROP_reload(MSG_ONE, to);
 839         ClientInit_misc(this);
 840         MUTATOR_CALLHOOK(Ent_Init);
 841 }
 842 void ClientInit_misc(entity this)
 843 {
 844         int channel = MSG_ONE;
 845         WriteHeader(channel, ENT_CLIENT_INIT);
 846         WriteByte(channel, g_nexball_meter_period * 32);
 847         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[0]));
 848         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[1]));
 849         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[2]));
 850         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[3]));
 851         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[0]));
 852         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[1]));
 853         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[2]));
 854         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[3]));
 855
 856         if(sv_foginterval && world.fog != "")
 857                 WriteString(channel, world.fog);
 858         else
 859                 WriteString(channel, "");
 860         WriteByte(channel, this.count * 255.0); // g_balance_armor_blockpercent
 861         WriteByte(channel, this.cnt * 255.0); // g_balance_damagepush_speedfactor
 862         WriteByte(channel, serverflags);
 863         WriteCoord(channel, autocvar_g_trueaim_minrange);
 864 }
 865
 866 void ClientInit_CheckUpdate(entity this)
 867 {
 868         this.nextthink = time;
 869         if(this.count != autocvar_g_balance_armor_blockpercent)
 870         {
 871                 this.count = autocvar_g_balance_armor_blockpercent;
 872                 this.SendFlags |= 1;
 873         }
 874         if(this.cnt != autocvar_g_balance_damagepush_speedfactor)
 875         {
 876                 this.cnt = autocvar_g_balance_damagepush_speedfactor;
 877                 this.SendFlags |= 1;
 878         }
 879 }
 880
 881 void ClientInit_Spawn()
 882 {
 883         entity e = new_pure(clientinit);
 884         setthink(e, ClientInit_CheckUpdate);
 885         Net_LinkEntity(e, false, 0, ClientInit_SendEntity);
 886
 887         ClientInit_CheckUpdate(e);
 888 }
 889
 890 /*
 891 =============
 892 SetNewParms
 893 =============
 894 */
 895 void SetNewParms ()
 896 {
 897         // initialize parms for a new player
 898         parm1 = -(86400 * 366);
 899
 900         MUTATOR_CALLHOOK(SetNewParms);
 901 }
 902
 903 /*
 904 =============
 905 SetChangeParms
 906 =============
 907 */
 908 void SetChangeParms (entity this)
 909 {
 910         // save parms for level change
 911         parm1 = CS(this).parm_idlesince - time;
 912
 913         MUTATOR_CALLHOOK(SetChangeParms);
 914 }
 915
 916 /*
 917 =============
 918 DecodeLevelParms
 919 =============
 920 */
 921 void DecodeLevelParms(entity this)
 922 {
 923         // load parms
 924         CS(this).parm_idlesince = parm1;
 925         if (CS(this).parm_idlesince == -(86400 * 366))
 926                 CS(this).parm_idlesince = time;
 927
 928         // whatever happens, allow 60 seconds of idling directly after connect for map loading
 929         CS(this).parm_idlesince = max(CS(this).parm_idlesince, time - sv_maxidle + 60);
 930
 931         MUTATOR_CALLHOOK(DecodeLevelParms);
 932 }
 933
 934 void FixClientCvars(entity e)
 935 {
 936         // send prediction settings to the client
 937         stuffcmd(e, "\nin_bindmap 0 0\n");
 938         if(autocvar_g_antilag == 3) // client side hitscan
 939                 stuffcmd(e, "cl_cmd settemp cl_prydoncursor_notrace 0\n");
 940         if(autocvar_sv_gentle)
 941                 stuffcmd(e, "cl_cmd settemp cl_gentle 1\n");
 942
 943         stuffcmd(e, sprintf("\ncl_jumpspeedcap_min \"%s\"\n", autocvar_sv_jumpspeedcap_min));
 944         stuffcmd(e, sprintf("\ncl_jumpspeedcap_max \"%s\"\n", autocvar_sv_jumpspeedcap_max));
 945
 946         stuffcmd(e, sprintf("\ncl_shootfromfixedorigin \"%s\"\n", autocvar_g_shootfromfixedorigin));
 947
 948         MUTATOR_CALLHOOK(FixClientCvars, e);
 949 }
 950
 951 bool findinlist_abbrev(string tofind, string list)
 952 {
 953         if(list == "" || tofind == "")
 954                 return false; // empty list or search, just return
 955
 956         // this function allows abbreviated strings!
 957         FOREACH_WORD(list, it == substring(tofind, 0, strlen(it)),
 958         {
 959                 return true;
 960         });
 961
 962         return false;
 963 }
 964
 965 bool PlayerInIPList(entity p, string iplist)
 966 {
 967         // some safety checks (never allow local?)
 968         if(p.netaddress == "local" || p.netaddress == "" || !IS_REAL_CLIENT(p))
 969                 return false;
 970
 971         return findinlist_abbrev(p.netaddress, iplist);
 972 }
 973
 974 bool PlayerInIDList(entity p, string idlist)
 975 {
 976         // NOTE: we do NOT check crypto_idfp_signed here, an unsigned ID is fine too for this
 977         if(!p.crypto_idfp)
 978                 return false;
 979
 980         return findinlist_abbrev(p.crypto_idfp, idlist);
 981 }
 982
 983 bool PlayerInList(entity player, string list)
 984 {
 985         return boolean(PlayerInIDList(player, list) || PlayerInIPList(player, list));
 986 }
 987
 988 #ifdef DP_EXT_PRECONNECT
 989 /*
 990 =============
 991 ClientPreConnect
 992
 993 Called once (not at each match start) when a client begins a connection to the server
 994 =============
 995 */
 996 void ClientPreConnect(entity this)
 997 {
 998         if(autocvar_sv_eventlog)
 999         {
1000                 GameLogEcho(sprintf(":connect:%d:%d:%s",
1001                         this.playerid,
1002                         etof(this),
1003                         ((IS_REAL_CLIENT(this)) ? this.netaddress : "bot")
1004                 ));
1005         }
1006 }
1007 #endif
1008
1009 string GetClientVersionMessage(entity this)
1010 {
1011         if (CS(this).version_mismatch) {
1012                 if(CS(this).version < autocvar_gameversion) {
1013                         return strcat("This is Xonotic ", autocvar_g_xonoticversion,
1014                                 "\n^3Your client version is outdated.\n\n\n### YOU WON'T BE ABLE TO PLAY ON THIS SERVER ###\n\n\nPlease update!!!^8");
1015                 } else {
1016                         return strcat("This is Xonotic ", autocvar_g_xonoticversion,
1017                                 "\n^3This server is using an outdated Xonotic version.\n\n\n ### THIS SERVER IS INCOMPATIBLE AND THUS YOU CANNOT JOIN ###.^8");
1018                 }
1019         } else {
1020                 return strcat("Welcome to Xonotic ", autocvar_g_xonoticversion);
1021         }
1022 }
1023
1024 string getwelcomemessage(entity this)
1025 {
1026         MUTATOR_CALLHOOK(BuildMutatorsPrettyString, "");
1027         string modifications = M_ARGV(0, string);
1028
1029         if(g_weaponarena)
1030         {
1031                 if(g_weaponarena_random)
1032                         modifications = strcat(modifications, ", ", ftos(g_weaponarena_random), " of ", g_weaponarena_list, " Arena");
1033                 else
1034                         modifications = strcat(modifications, ", ", g_weaponarena_list, " Arena");
1035         }
1036         else if(cvar("g_balance_blaster_weaponstartoverride") == 0)
1037                 modifications = strcat(modifications, ", No start weapons");
1038         if(cvar("sv_gravity") < stof(cvar_defstring("sv_gravity")))
1039                 modifications = strcat(modifications, ", Low gravity");
1040         if(g_weapon_stay && !g_cts)
1041                 modifications = strcat(modifications, ", Weapons stay");
1042         if(g_jetpack)
1043                 modifications = strcat(modifications, ", Jet pack");
1044         if(autocvar_g_powerups == 0)
1045                 modifications = strcat(modifications, ", No powerups");
1046         if(autocvar_g_powerups > 0)
1047                 modifications = strcat(modifications, ", Powerups");
1048         modifications = substring(modifications, 2, strlen(modifications) - 2);
1049
1050         string versionmessage = GetClientVersionMessage(this);
1051         string s = strcat(versionmessage, "^8\n^8\nhost is ^9", autocvar_hostname, "^8\n");
1052
1053         s = strcat(s, "^8\nmatch type is ^1", gamemode_name, "^8\n");
1054
1055         if(modifications != "")
1056                 s = strcat(s, "^8\nactive modifications: ^3", modifications, "^8\n");
1057
1058         if(cache_lastmutatormsg != autocvar_g_mutatormsg)
1059         {
1060                 strcpy(cache_lastmutatormsg, autocvar_g_mutatormsg);
1061                 strcpy(cache_mutatormsg, cache_lastmutatormsg);
1062         }
1063
1064         if (cache_mutatormsg != "") {
1065                 s = strcat(s, "\n\n^8special gameplay tips: ^7", cache_mutatormsg);
1066         }
1067
1068         string mutator_msg = "";
1069         MUTATOR_CALLHOOK(BuildGameplayTipsString, mutator_msg);
1070         mutator_msg = M_ARGV(0, string);
1071
1072         s = strcat(s, mutator_msg); // trust that the mutator will do proper formatting
1073
1074         string motd = autocvar_sv_motd;
1075         if (motd != "") {
1076                 s = strcat(s, "\n\n^8MOTD: ^7", strreplace("\\n", "\n", motd));
1077         }
1078         return s;
1079 }
1080
1081 bool autocvar_sv_qcphysics = true; // TODO this is for testing - remove when qcphysics work
1082
1083 /**
1084 =============
1085 ClientConnect
1086
1087 Called when a client connects to the server
1088 =============
1089 */
1090 void ClientConnect(entity this)
1091 {
1092         if (Ban_MaybeEnforceBanOnce(this)) return;
1093         assert(!IS_CLIENT(this), return);
1094         this.flags |= FL_CLIENT;
1095         assert(player_count >= 0, player_count = 0);
1096
1097 #ifdef WATERMARK
1098         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_WATERMARK, WATERMARK);
1099 #endif
1100         TRANSMUTE(Client, this);
1101         CS(this).version_nagtime = time + 10 + random() * 10;
1102
1103         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_JOIN_CONNECT, this.netname);
1104
1105         bot_clientconnect(this);
1106
1107         Player_DetermineForcedTeam(this);
1108
1109         TRANSMUTE(Observer, this);
1110
1111         PlayerStats_GameReport_AddEvent(sprintf("kills-%d", this.playerid));
1112
1113         // always track bots, don't ask for cl_allow_uidtracking
1114         if (IS_BOT_CLIENT(this))
1115                 PlayerStats_GameReport_AddPlayer(this);
1116         else
1117                 CS(this).allowed_timeouts = autocvar_sv_timeout_number;
1118
1119         if (autocvar_sv_eventlog)
1120                 GameLogEcho(strcat(":join:", ftos(this.playerid), ":", ftos(etof(this)), ":", ((IS_REAL_CLIENT(this)) ? GameLog_ProcessIP(this.netaddress) : "bot"), ":", playername(this, false)));
1121
1122         CS(this).just_joined = true;  // stop spamming the eventlog with additional lines when the client connects
1123
1124         stuffcmd(this, clientstuff, "\n");
1125         stuffcmd(this, "cl_particles_reloadeffects\n"); // TODO do we still need this?
1126
1127         FixClientCvars(this);
1128
1129         // get version info from player
1130         stuffcmd(this, "cmd clientversion $gameversion\n");
1131
1132         // notify about available teams
1133         if (teamplay)
1134         {
1135                 entity balance = TeamBalance_CheckAllowedTeams(this);
1136                 int t = TeamBalance_GetAllowedTeams(balance);
1137                 TeamBalance_Destroy(balance);
1138                 stuffcmd(this, sprintf("set _teams_available %d\n", t));
1139         }
1140         else
1141         {
1142                 stuffcmd(this, "set _teams_available 0\n");
1143         }
1144
1145         bot_relinkplayerlist();
1146
1147         CS(this).spectatortime = time;
1148         if (blockSpectators)
1149         {
1150                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
1151         }
1152
1153         CS(this).jointime = time;
1154
1155         if (IS_REAL_CLIENT(this))
1156         {
1157                 if (g_weaponarena_weapons == WEPSET(TUBA))
1158                         stuffcmd(this, "cl_cmd settemp chase_active 1\n");
1159         }
1160
1161         if (!sv_foginterval && world.fog != "")
1162                 stuffcmd(this, strcat("\nfog ", world.fog, "\nr_fog_exp2 0\nr_drawfog 1\n"));
1163
1164         if (autocvar_sv_teamnagger && !(autocvar_bot_vs_human && AvailableTeams() == 2))
1165                 if(!MUTATOR_CALLHOOK(HideTeamNagger, this))
1166                         send_CSQC_teamnagger();
1167
1168         CSQCMODEL_AUTOINIT(this);
1169
1170         CS(this).model_randomizer = random();
1171
1172         if (IS_REAL_CLIENT(this))
1173                 sv_notice_join(this);
1174
1175         this.move_qcphysics = autocvar_sv_qcphysics;
1176
1177         // update physics stats (players can spawn before physics runs)
1178         Physics_UpdateStats(this);
1179
1180         IL_EACH(g_initforplayer, it.init_for_player, {
1181                 it.init_for_player(it, this);
1182         });
1183
1184         Handicap_Initialize(this);
1185
1186         MUTATOR_CALLHOOK(ClientConnect, this);
1187
1188         if (IS_REAL_CLIENT(this))
1189         {
1190                 if (!autocvar_g_campaign && !IS_PLAYER(this))
1191                 {
1192                         CS(this).motd_actived_time = -1;
1193                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOTD, getwelcomemessage(this));
1194                 }
1195         }
1196 }
1197 /*
1198 =============
1199 ClientDisconnect
1200
1201 Called when a client disconnects from the server
1202 =============
1203 */
1204 .entity chatbubbleentity;
1205 void ClientDisconnect(entity this)
1206 {
1207         assert(IS_CLIENT(this), return);
1208
1209         PlayerStats_GameReport_FinalizePlayer(this);
1210         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
1211         if (CS(this).active_minigame) part_minigame(this);
1212         if (IS_PLAYER(this)) Send_Effect(EFFECT_SPAWN_NEUTRAL, this.origin, '0 0 0', 1);
1213
1214         if (autocvar_sv_eventlog)
1215                 GameLogEcho(strcat(":part:", ftos(this.playerid)));
1216
1217         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_QUIT_DISCONNECT, this.netname);
1218
1219         if(IS_SPEC(this))
1220                 SetSpectatee(this, NULL);
1221
1222     MUTATOR_CALLHOOK(ClientDisconnect, this);
1223
1224         strfree(CS(this).netname_previous); // needs to be before the CS entity is removed!
1225         strfree(CS(this).weaponorder_byimpulse);
1226         ClientState_detach(this);
1227
1228         Portal_ClearAll(this);
1229
1230         Unfreeze(this, false);
1231
1232         RemoveGrapplingHooks(this);
1233
1234         // Here, everything has been done that requires this player to be a client.
1235
1236         this.flags &= ~FL_CLIENT;
1237
1238         if (this.chatbubbleentity) delete(this.chatbubbleentity);
1239         if (this.killindicator) delete(this.killindicator);
1240
1241         IL_EACH(g_counters, it.realowner == this,
1242         {
1243                 delete(it);
1244         });
1245
1246         WaypointSprite_PlayerGone(this);
1247
1248         bot_relinkplayerlist();
1249
1250         strfree(this.clientstatus);
1251         if (this.personal) delete(this.personal);
1252
1253         this.playerid = 0;
1254         ReadyCount();
1255         if (vote_called && IS_REAL_CLIENT(this)) VoteCount(false);
1256
1257         ONREMOVE(this);
1258 }
1259
1260 void ChatBubbleThink(entity this)
1261 {
1262         this.nextthink = time;
1263         if ((this.owner.alpha < 0) || this.owner.chatbubbleentity != this)
1264         {
1265                 if(this.owner) // but why can that ever be NULL?
1266                         this.owner.chatbubbleentity = NULL;
1267                 delete(this);
1268                 return;
1269         }
1270
1271         this.mdl = "";
1272
1273         if ( !IS_DEAD(this.owner) && IS_PLAYER(this.owner) )
1274         {
1275                 if ( CS(this.owner).active_minigame && PHYS_INPUT_BUTTON_MINIGAME(this.owner) )
1276                         this.mdl = "models/sprites/minigame_busy.iqm";
1277                 else if (PHYS_INPUT_BUTTON_CHAT(this.owner))
1278                         this.mdl = "models/misc/chatbubble.spr";
1279         }
1280
1281         if ( this.model != this.mdl )
1282                 _setmodel(this, this.mdl);
1283
1284 }
1285
1286 void UpdateChatBubble(entity this)
1287 {
1288         if (this.alpha < 0)
1289                 return;
1290         // spawn a chatbubble entity if needed
1291         if (!this.chatbubbleentity)
1292         {
1293                 this.chatbubbleentity = new(chatbubbleentity);
1294                 this.chatbubbleentity.owner = this;
1295                 this.chatbubbleentity.exteriormodeltoclient = this;
1296                 setthink(this.chatbubbleentity, ChatBubbleThink);
1297                 this.chatbubbleentity.nextthink = time;
1298                 setmodel(this.chatbubbleentity, MDL_CHAT); // precision set below
1299                 //setorigin(this.chatbubbleentity, this.origin + '0 0 15' + this.maxs_z * '0 0 1');
1300                 setorigin(this.chatbubbleentity, '0 0 15' + this.maxs_z * '0 0 1');
1301                 setattachment(this.chatbubbleentity, this, "");  // sticks to moving player better, also conserves bandwidth
1302                 this.chatbubbleentity.mdl = this.chatbubbleentity.model;
1303                 //this.chatbubbleentity.model = "";
1304                 this.chatbubbleentity.effects = EF_LOWPRECISION;
1305         }
1306 }
1307
1308
1309 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
1310 // added to the model skins
1311 /*void UpdateColorModHack()
1312 {
1313         float c;
1314         c = this.clientcolors & 15;
1315         // LordHavoc: only bothering to support white, green, red, yellow, blue
1316              if (!teamplay) this.colormod = '0 0 0';
1317         else if (c ==  0) this.colormod = '1.00 1.00 1.00';
1318         else if (c ==  3) this.colormod = '0.10 1.73 0.10';
1319         else if (c ==  4) this.colormod = '1.73 0.10 0.10';
1320         else if (c == 12) this.colormod = '1.22 1.22 0.10';
1321         else if (c == 13) this.colormod = '0.10 0.10 1.73';
1322         else this.colormod = '1 1 1';
1323 }*/
1324
1325 void respawn(entity this)
1326 {
1327         if(this.alpha >= 0 && autocvar_g_respawn_ghosts)
1328         {
1329                 this.solid = SOLID_NOT;
1330                 this.takedamage = DAMAGE_NO;
1331                 set_movetype(this, MOVETYPE_FLY);
1332                 this.velocity = '0 0 1' * autocvar_g_respawn_ghosts_speed;
1333                 this.avelocity = randomvec() * autocvar_g_respawn_ghosts_speed * 3 - randomvec() * autocvar_g_respawn_ghosts_speed * 3;
1334                 this.effects |= CSQCMODEL_EF_RESPAWNGHOST;
1335                 Send_Effect(EFFECT_RESPAWN_GHOST, this.origin, '0 0 0', 1);
1336                 if(autocvar_g_respawn_ghosts_maxtime)
1337                         SUB_SetFade (this, time + autocvar_g_respawn_ghosts_maxtime / 2 + random () * (autocvar_g_respawn_ghosts_maxtime - autocvar_g_respawn_ghosts_maxtime / 2), 1.5);
1338         }
1339
1340         CopyBody(this, 1);
1341
1342         this.effects |= EF_NODRAW; // prevent another CopyBody
1343         PutClientInServer(this);
1344 }
1345
1346 ERASEABLE
1347 void PrintToChat(entity client, string text)
1348 {
1349         text = strcat("\{1}^7", text, "\n");
1350         sprint(client, text);
1351 }
1352
1353 ERASEABLE
1354 void DebugPrintToChat(entity client, string text)
1355 {
1356         if (autocvar_developer > 0)
1357         {
1358                 PrintToChat(client, text);
1359         }
1360 }
1361
1362 ERASEABLE
1363 void PrintToChatAll(string text)
1364 {
1365         text = strcat("\{1}^7", text, "\n");
1366         bprint(text);
1367 }
1368
1369 ERASEABLE
1370 void DebugPrintToChatAll(string text)
1371 {
1372         if (autocvar_developer > 0)
1373         {
1374                 PrintToChatAll(text);
1375         }
1376 }
1377
1378 ERASEABLE
1379 void PrintToChatTeam(int team_num, string text)
1380 {
1381         text = strcat("\{1}^7", text, "\n");
1382         FOREACH_CLIENT(IS_REAL_CLIENT(it),
1383         {
1384                 if (it.team == team_num)
1385                 {
1386                         sprint(it, text);
1387                 }
1388         });
1389 }
1390
1391 ERASEABLE
1392 void DebugPrintToChatTeam(int team_num, string text)
1393 {
1394         if (autocvar_developer > 0)
1395         {
1396                 PrintToChatTeam(team_num, text);
1397         }
1398 }
1399
1400 void play_countdown(entity this, float finished, Sound samp)
1401 {
1402         TC(Sound, samp);
1403         if(IS_REAL_CLIENT(this))
1404                 if(floor(finished - time - frametime) != floor(finished - time))
1405                         if(finished - time < 6)
1406                                 sound (this, CH_INFO, samp, VOL_BASE, ATTEN_NORM);
1407 }
1408
1409 void player_powerups(entity this)
1410 {
1411         // add a way to see what the items were BEFORE all of these checks for the mutator hook
1412         int items_prev = this.items;
1413
1414         if((this.items & IT_USING_JETPACK) && !IS_DEAD(this) && !game_stopped)
1415                 this.modelflags |= MF_ROCKET;
1416         else
1417                 this.modelflags &= ~MF_ROCKET;
1418
1419         this.effects &= ~(EF_RED | EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT | EF_FLAME | EF_NODEPTHTEST);
1420
1421         if((this.alpha < 0 || IS_DEAD(this)) && !this.vehicle) // don't apply the flags if the player is gibbed
1422                 return;
1423
1424         Fire_ApplyDamage(this);
1425         Fire_ApplyEffect(this);
1426
1427         if (!MUTATOR_IS_ENABLED(mutator_instagib))
1428         {
1429                 if (this.items & ITEM_Strength.m_itemid)
1430                 {
1431                         play_countdown(this, STAT(STRENGTH_FINISHED, this), SND_POWEROFF);
1432                         this.effects = this.effects | (EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT);
1433                         if (time > STAT(STRENGTH_FINISHED, this))
1434                         {
1435                                 this.items = this.items - (this.items & ITEM_Strength.m_itemid);
1436                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERDOWN_STRENGTH, this.netname);
1437                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERDOWN_STRENGTH);
1438                         }
1439                 }
1440                 else
1441                 {
1442                         if (time < STAT(STRENGTH_FINISHED, this))
1443                         {
1444                                 this.items = this.items | ITEM_Strength.m_itemid;
1445                                 if(!g_cts)
1446                                         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERUP_STRENGTH, this.netname);
1447                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERUP_STRENGTH);
1448                         }
1449                 }
1450                 if (this.items & ITEM_Shield.m_itemid)
1451                 {
1452                         play_countdown(this, STAT(INVINCIBLE_FINISHED, this), SND_POWEROFF);
1453                         this.effects = this.effects | (EF_RED | EF_ADDITIVE | EF_FULLBRIGHT);
1454                         if (time > STAT(INVINCIBLE_FINISHED, this))
1455                         {
1456                                 this.items = this.items - (this.items & ITEM_Shield.m_itemid);
1457                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERDOWN_SHIELD, this.netname);
1458                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERDOWN_SHIELD);
1459                         }
1460                 }
1461                 else
1462                 {
1463                         if (time < STAT(INVINCIBLE_FINISHED, this))
1464                         {
1465                                 this.items = this.items | ITEM_Shield.m_itemid;
1466                                 if(!g_cts)
1467                                         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERUP_SHIELD, this.netname);
1468                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERUP_SHIELD);
1469                         }
1470                 }
1471                 if (this.items & IT_SUPERWEAPON)
1472                 {
1473                         if (!(STAT(WEAPONS, this) & WEPSET_SUPERWEAPONS))
1474                         {
1475                                 STAT(SUPERWEAPONS_FINISHED, this) = 0;
1476                                 this.items = this.items - (this.items & IT_SUPERWEAPON);
1477                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_LOST, this.netname);
1478                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_LOST);
1479                         }
1480                         else if (this.items & IT_UNLIMITED_SUPERWEAPONS)
1481                         {
1482                                 // don't let them run out
1483                         }
1484                         else
1485                         {
1486                                 play_countdown(this, STAT(SUPERWEAPONS_FINISHED, this), SND_POWEROFF);
1487                                 if (time > STAT(SUPERWEAPONS_FINISHED, this))
1488                                 {
1489                                         this.items = this.items - (this.items & IT_SUPERWEAPON);
1490                                         STAT(WEAPONS, this) &= ~WEPSET_SUPERWEAPONS;
1491                                         //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_BROKEN, this.netname);
1492                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_BROKEN);
1493                                 }
1494                         }
1495                 }
1496                 else if(STAT(WEAPONS, this) & WEPSET_SUPERWEAPONS)
1497                 {
1498                         if (time < STAT(SUPERWEAPONS_FINISHED, this) || (this.items & IT_UNLIMITED_SUPERWEAPONS))
1499                         {
1500                                 this.items = this.items | IT_SUPERWEAPON;
1501                                 if(!(this.items & IT_UNLIMITED_SUPERWEAPONS))
1502                                 {
1503                                         if(!g_cts)
1504                                                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_PICKUP, this.netname);
1505                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_PICKUP);
1506                                 }
1507                         }
1508                         else
1509                         {
1510                                 STAT(SUPERWEAPONS_FINISHED, this) = 0;
1511                                 STAT(WEAPONS, this) &= ~WEPSET_SUPERWEAPONS;
1512                         }
1513                 }
1514                 else
1515                 {
1516                         STAT(SUPERWEAPONS_FINISHED, this) = 0;
1517                 }
1518         }
1519
1520         if(autocvar_g_nodepthtestplayers)
1521                 this.effects = this.effects | EF_NODEPTHTEST;
1522
1523         if(autocvar_g_fullbrightplayers)
1524                 this.effects = this.effects | EF_FULLBRIGHT;
1525
1526         if (time >= game_starttime)
1527         if (time < this.spawnshieldtime)
1528                 this.effects = this.effects | (EF_ADDITIVE | EF_FULLBRIGHT);
1529
1530         MUTATOR_CALLHOOK(PlayerPowerups, this, items_prev);
1531 }
1532
1533 float CalcRegen(float current, float stable, float regenfactor, float regenframetime)
1534 {
1535         if(current > stable)
1536                 return current;
1537         else if(current > stable - 0.25) // when close enough, "snap"
1538                 return stable;
1539         else
1540                 return min(stable, current + (stable - current) * regenfactor * regenframetime);
1541 }
1542
1543 float CalcRot(float current, float stable, float rotfactor, float rotframetime)
1544 {
1545         if(current < stable)
1546                 return current;
1547         else if(current < stable + 0.25) // when close enough, "snap"
1548                 return stable;
1549         else
1550                 return max(stable, current + (stable - current) * rotfactor * rotframetime);
1551 }
1552
1553 void RotRegen(entity this, int res, float regenstable, float regenfactor, float regenlinear, float regenframetime, float rotstable, float rotfactor, float rotlinear, float rotframetime, float limit_mod)
1554 {
1555         float old = GetResource(this, res);
1556         float current = old;
1557         if(current > rotstable)
1558         {
1559                 if(rotframetime > 0)
1560                 {
1561                         current = CalcRot(current, rotstable, rotfactor, rotframetime);
1562                         current = max(rotstable, current - rotlinear * rotframetime);
1563                 }
1564         }
1565         else if(current < regenstable)
1566         {
1567                 if(regenframetime > 0)
1568                 {
1569                         current = CalcRegen(current, regenstable, regenfactor, regenframetime);
1570                         current = min(regenstable, current + regenlinear * regenframetime);
1571                 }
1572         }
1573
1574         float limit = GetResourceLimit(this, res) * limit_mod;
1575         if(current > limit)
1576                 current = limit;
1577
1578         if (current != old)
1579                 SetResource(this, res, current);
1580 }
1581
1582 void player_regen(entity this)
1583 {
1584         float max_mod, regen_mod, rot_mod, limit_mod;
1585         max_mod = regen_mod = rot_mod = limit_mod = 1;
1586
1587         float regen_health = autocvar_g_balance_health_regen;
1588         float regen_health_linear = autocvar_g_balance_health_regenlinear;
1589         float regen_health_rot = autocvar_g_balance_health_rot;
1590         float regen_health_rotlinear = autocvar_g_balance_health_rotlinear;
1591         float regen_health_stable = autocvar_g_balance_health_regenstable;
1592         float regen_health_rotstable = autocvar_g_balance_health_rotstable;
1593         bool mutator_returnvalue = MUTATOR_CALLHOOK(PlayerRegen, this, max_mod, regen_mod, rot_mod, limit_mod, regen_health, regen_health_linear, regen_health_rot,
1594                 regen_health_rotlinear, regen_health_stable, regen_health_rotstable);
1595         max_mod = M_ARGV(1, float);
1596         regen_mod = M_ARGV(2, float);
1597         rot_mod = M_ARGV(3, float);
1598         limit_mod = M_ARGV(4, float);
1599         regen_health = M_ARGV(5, float);
1600         regen_health_linear = M_ARGV(6, float);
1601         regen_health_rot = M_ARGV(7, float);
1602         regen_health_rotlinear = M_ARGV(8, float);
1603         regen_health_stable = M_ARGV(9, float);
1604         regen_health_rotstable = M_ARGV(10, float);
1605
1606         if(!mutator_returnvalue)
1607         if(!STAT(FROZEN, this))
1608         {
1609                 float maxa = autocvar_g_balance_armor_rotstable;
1610                 float mina = autocvar_g_balance_armor_regenstable;
1611
1612                 RotRegen(this, RES_ARMOR, mina, autocvar_g_balance_armor_regen, autocvar_g_balance_armor_regenlinear,
1613                         regen_mod * frametime * (time > this.pauseregen_finished), maxa, autocvar_g_balance_armor_rot, autocvar_g_balance_armor_rotlinear,
1614                         rot_mod * frametime * (time > this.pauserotarmor_finished), limit_mod);
1615
1616                 RotRegen(this, RES_HEALTH, regen_health_stable * max_mod, regen_health, regen_health_linear,
1617                         regen_mod * frametime * (time > this.pauseregen_finished), regen_health_rotstable * max_mod, regen_health_rot, regen_health_rotlinear,
1618                         rot_mod * frametime * (time > this.pauserothealth_finished), limit_mod);
1619         }
1620
1621         // if player rotted to death...  die!
1622         // check this outside above checks, as player may still be able to rot to death
1623         if(GetResource(this, RES_HEALTH) < 1)
1624         {
1625                 if(this.vehicle)
1626                         vehicles_exit(this.vehicle, VHEF_RELEASE);
1627                 if(this.event_damage)
1628                         this.event_damage(this, this, this, 1, DEATH_ROT.m_id, DMG_NOWEP, this.origin, '0 0 0');
1629         }
1630
1631         if (!(this.items & IT_UNLIMITED_AMMO))
1632         {
1633                 float maxf = autocvar_g_balance_fuel_rotstable;
1634                 float minf = autocvar_g_balance_fuel_regenstable;
1635
1636                 RotRegen(this, RES_FUEL, minf, autocvar_g_balance_fuel_regen, autocvar_g_balance_fuel_regenlinear,
1637                         frametime * (time > this.pauseregen_finished) * ((this.items & ITEM_JetpackRegen.m_itemid) != 0),
1638                         maxf, autocvar_g_balance_fuel_rot, autocvar_g_balance_fuel_rotlinear, frametime * (time > this.pauserotfuel_finished), 1);
1639         }
1640 }
1641
1642 bool zoomstate_set;
1643 void SetZoomState(entity this, float newzoom)
1644 {
1645         if(newzoom != CS(this).zoomstate)
1646         {
1647                 CS(this).zoomstate = newzoom;
1648                 ClientData_Touch(this);
1649         }
1650         zoomstate_set = true;
1651 }
1652
1653 void GetPressedKeys(entity this)
1654 {
1655         MUTATOR_CALLHOOK(GetPressedKeys, this);
1656         int keys = STAT(PRESSED_KEYS, this);
1657         keys = BITSET(keys, KEY_FORWARD,        CS(this).movement.x > 0);
1658         keys = BITSET(keys, KEY_BACKWARD,       CS(this).movement.x < 0);
1659         keys = BITSET(keys, KEY_RIGHT,          CS(this).movement.y > 0);
1660         keys = BITSET(keys, KEY_LEFT,           CS(this).movement.y < 0);
1661
1662         keys = BITSET(keys, KEY_JUMP,           PHYS_INPUT_BUTTON_JUMP(this));
1663         keys = BITSET(keys, KEY_CROUCH,         IS_DUCKED(this)); // workaround: player can't un-crouch until their path is clear, so we keep the button held here
1664         keys = BITSET(keys, KEY_ATCK,           PHYS_INPUT_BUTTON_ATCK(this));
1665         keys = BITSET(keys, KEY_ATCK2,          PHYS_INPUT_BUTTON_ATCK2(this));
1666         CS(this).pressedkeys = keys; // store for other users
1667
1668         STAT(PRESSED_KEYS, this) = keys;
1669 }
1670
1671 /*
1672 ======================
1673 spectate mode routines
1674 ======================
1675 */
1676
1677 void SpectateCopy(entity this, entity spectatee)
1678 {
1679         TC(Client, this); TC(Client, spectatee);
1680
1681         MUTATOR_CALLHOOK(SpectateCopy, spectatee, this);
1682         PS(this) = PS(spectatee);
1683         this.armortype = spectatee.armortype;
1684         SetResourceExplicit(this, RES_ARMOR, GetResource(spectatee, RES_ARMOR));
1685         SetResourceExplicit(this, RES_CELLS, GetResource(spectatee, RES_CELLS));
1686         SetResourceExplicit(this, RES_PLASMA, GetResource(spectatee, RES_PLASMA));
1687         SetResourceExplicit(this, RES_SHELLS, GetResource(spectatee, RES_SHELLS));
1688         SetResourceExplicit(this, RES_BULLETS, GetResource(spectatee, RES_BULLETS));
1689         SetResourceExplicit(this, RES_ROCKETS, GetResource(spectatee, RES_ROCKETS));
1690         SetResourceExplicit(this, RES_FUEL, GetResource(spectatee, RES_FUEL));
1691         this.effects = spectatee.effects & EFMASK_CHEAP; // eat performance
1692         SetResourceExplicit(this, RES_HEALTH, GetResource(spectatee, RES_HEALTH));
1693         CS(this).impulse = 0;
1694         this.disableclientprediction = 1; // no need to run prediction on a spectator
1695         this.items = spectatee.items;
1696         STAT(LAST_PICKUP, this) = STAT(LAST_PICKUP, spectatee);
1697         STAT(HIT_TIME, this) = STAT(HIT_TIME, spectatee);
1698         STAT(STRENGTH_FINISHED, this) = STAT(STRENGTH_FINISHED, spectatee);
1699         STAT(INVINCIBLE_FINISHED, this) = STAT(INVINCIBLE_FINISHED, spectatee);
1700         STAT(SUPERWEAPONS_FINISHED, this) = STAT(SUPERWEAPONS_FINISHED, spectatee);
1701         this.air_finished = spectatee.air_finished;
1702         STAT(PRESSED_KEYS, this) = STAT(PRESSED_KEYS, spectatee);
1703         STAT(WEAPONS, this) = STAT(WEAPONS, spectatee);
1704         this.punchangle = spectatee.punchangle;
1705         this.view_ofs = spectatee.view_ofs;
1706         this.velocity = spectatee.velocity;
1707         this.dmg_take = spectatee.dmg_take;
1708         this.dmg_save = spectatee.dmg_save;
1709         this.dmg_inflictor = spectatee.dmg_inflictor;
1710         this.v_angle = spectatee.v_angle;
1711         this.angles = spectatee.v_angle;
1712         STAT(FROZEN, this) = STAT(FROZEN, spectatee);
1713         STAT(REVIVE_PROGRESS, this) = STAT(REVIVE_PROGRESS, spectatee);
1714         this.viewloc = spectatee.viewloc;
1715         if(!PHYS_INPUT_BUTTON_USE(this) && STAT(CAMERA_SPECTATOR, this) != 2)
1716                 this.fixangle = true;
1717         setorigin(this, spectatee.origin);
1718         setsize(this, spectatee.mins, spectatee.maxs);
1719         SetZoomState(this, CS(spectatee).zoomstate);
1720
1721     anticheat_spectatecopy(this, spectatee);
1722         STAT(HUD, this) = STAT(HUD, spectatee);
1723         if(spectatee.vehicle)
1724     {
1725         this.angles = spectatee.v_angle;
1726
1727         //this.fixangle = false;
1728         //this.velocity = spectatee.vehicle.velocity;
1729         this.vehicle_health = spectatee.vehicle_health;
1730         this.vehicle_shield = spectatee.vehicle_shield;
1731         this.vehicle_energy = spectatee.vehicle_energy;
1732         this.vehicle_ammo1 = spectatee.vehicle_ammo1;
1733         this.vehicle_ammo2 = spectatee.vehicle_ammo2;
1734         this.vehicle_reload1 = spectatee.vehicle_reload1;
1735         this.vehicle_reload2 = spectatee.vehicle_reload2;
1736
1737         //msg_entity = this;
1738
1739        // WriteByte (MSG_ONE, SVC_SETVIEWANGLES);
1740             //WriteAngle(MSG_ONE,  spectatee.v_angle.x);
1741            // WriteAngle(MSG_ONE,  spectatee.v_angle.y);
1742            // WriteAngle(MSG_ONE,  spectatee.v_angle.z);
1743
1744         //WriteByte (MSG_ONE, SVC_SETVIEW);
1745         //    WriteEntity(MSG_ONE, this);
1746         //makevectors(spectatee.v_angle);
1747         //setorigin(this, spectatee.origin - v_forward * 400 + v_up * 300);*/
1748     }
1749 }
1750
1751 bool SpectateUpdate(entity this)
1752 {
1753         if(!this.enemy)
1754                 return false;
1755
1756         if(!IS_PLAYER(this.enemy) || this == this.enemy)
1757         {
1758                 SetSpectatee(this, NULL);
1759                 return false;
1760         }
1761
1762         SpectateCopy(this, this.enemy);
1763
1764         return true;
1765 }
1766
1767 bool SpectateSet(entity this)
1768 {
1769         if(!IS_PLAYER(this.enemy))
1770                 return false;
1771
1772         ClientData_Touch(this.enemy);
1773
1774         msg_entity = this;
1775         WriteByte(MSG_ONE, SVC_SETVIEW);
1776         WriteEntity(MSG_ONE, this.enemy);
1777         set_movetype(this, MOVETYPE_NONE);
1778         accuracy_resend(this);
1779
1780         if(!SpectateUpdate(this))
1781                 PutObserverInServer(this);
1782
1783         return true;
1784 }
1785
1786 void SetSpectatee_status(entity this, int spectatee_num)
1787 {
1788         int oldspectatee_status = CS(this).spectatee_status;
1789         CS(this).spectatee_status = spectatee_num;
1790
1791         if (CS(this).spectatee_status != oldspectatee_status)
1792         {
1793                 if (STAT(PRESSED_KEYS, this))
1794                 {
1795                         CS(this).pressedkeys = 0;
1796                         STAT(PRESSED_KEYS, this) = 0;
1797                 }
1798                 ClientData_Touch(this);
1799                 if (g_race || g_cts) race_InitSpectator();
1800         }
1801 }
1802
1803 void SetSpectatee(entity this, entity spectatee)
1804 {
1805         if(IS_BOT_CLIENT(this))
1806                 return; // bots abuse .enemy, this code is useless to them
1807
1808         entity old_spectatee = this.enemy;
1809
1810         this.enemy = spectatee;
1811
1812         // WEAPONTODO
1813         // these are required to fix the spectator bug with arc
1814         if(old_spectatee)
1815         {
1816                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1817                 {
1818                         .entity weaponentity = weaponentities[slot];
1819                         if(old_spectatee.(weaponentity).arc_beam)
1820                                 old_spectatee.(weaponentity).arc_beam.SendFlags |= ARC_SF_SETTINGS;
1821                 }
1822         }
1823         if(this.enemy)
1824         {
1825                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1826                 {
1827                         .entity weaponentity = weaponentities[slot];
1828                         if(this.enemy.(weaponentity).arc_beam)
1829                                 this.enemy.(weaponentity).arc_beam.SendFlags |= ARC_SF_SETTINGS;
1830                 }
1831         }
1832
1833         if (this.enemy)
1834                 SetSpectatee_status(this, etof(this.enemy));
1835
1836         // needed to update spectator list
1837         if(old_spectatee) { ClientData_Touch(old_spectatee); }
1838 }
1839
1840 bool Spectate(entity this, entity pl)
1841 {
1842         if(MUTATOR_CALLHOOK(SpectateSet, this, pl))
1843                 return false;
1844         pl = M_ARGV(1, entity);
1845
1846         SetSpectatee(this, pl);
1847         return SpectateSet(this);
1848 }
1849
1850 bool SpectateNext(entity this)
1851 {
1852         entity ent = find(this.enemy, classname, STR_PLAYER);
1853
1854         if (MUTATOR_CALLHOOK(SpectateNext, this, ent))
1855                 ent = M_ARGV(1, entity);
1856         else if (!ent)
1857                 ent = find(ent, classname, STR_PLAYER);
1858
1859         if(ent) { SetSpectatee(this, ent); }
1860
1861         return SpectateSet(this);
1862 }
1863
1864 bool SpectatePrev(entity this)
1865 {
1866         // NOTE: chain order is from the highest to the lower entnum (unlike find)
1867         entity ent = findchain(classname, STR_PLAYER);
1868         if (!ent) // no player
1869                 return false;
1870
1871         entity first = ent;
1872         // skip players until current spectated player
1873         if(this.enemy)
1874         while(ent && ent != this.enemy)
1875                 ent = ent.chain;
1876
1877         switch (MUTATOR_CALLHOOK(SpectatePrev, this, ent, first))
1878         {
1879                 case MUT_SPECPREV_FOUND:
1880                     ent = M_ARGV(1, entity);
1881                     break;
1882                 case MUT_SPECPREV_RETURN:
1883                     return true;
1884                 case MUT_SPECPREV_CONTINUE:
1885                 default:
1886                 {
1887                         if(ent.chain)
1888                                 ent = ent.chain;
1889                         else
1890                                 ent = first;
1891                         break;
1892                 }
1893         }
1894
1895         SetSpectatee(this, ent);
1896         return SpectateSet(this);
1897 }
1898
1899 /*
1900 =============
1901 ShowRespawnCountdown()
1902
1903 Update a respawn countdown display.
1904 =============
1905 */
1906 void ShowRespawnCountdown(entity this)
1907 {
1908         float number;
1909         if(!IS_DEAD(this)) // just respawned?
1910                 return;
1911         else
1912         {
1913                 number = ceil(this.respawn_time - time);
1914                 if(number <= 0)
1915                         return;
1916                 if(number <= this.respawn_countdown)
1917                 {
1918                         this.respawn_countdown = number - 1;
1919                         if(ceil(this.respawn_time - (time + 0.5)) == number) // only say it if it is the same number even in 0.5s; to prevent overlapping sounds
1920                                 { Send_Notification(NOTIF_ONE, this, MSG_ANNCE, Announcer_PickNumber(CNT_RESPAWN, number)); }
1921                 }
1922         }
1923 }
1924
1925 .bool team_selected;
1926 bool ShowTeamSelection(entity this)
1927 {
1928         if (!teamplay || autocvar_g_campaign || autocvar_g_balance_teams || this.team_selected || (CS(this).wasplayer && autocvar_g_changeteam_banned) || Player_HasRealForcedTeam(this))
1929                 return false;
1930         stuffcmd(this, "menu_showteamselect\n");
1931         return true;
1932 }
1933 void Join(entity this)
1934 {
1935         TRANSMUTE(Player, this);
1936
1937         if(!this.team_selected)
1938         if(autocvar_g_campaign || autocvar_g_balance_teams)
1939                 TeamBalance_JoinBestTeam(this);
1940
1941         if(autocvar_g_campaign)
1942                 campaign_bots_may_start = true;
1943
1944         Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_PREVENT_JOIN);
1945
1946         PutClientInServer(this);
1947
1948         if(IS_PLAYER(this))
1949         if(teamplay && this.team != -1)
1950         {
1951         }
1952         else
1953                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_JOIN_PLAY, this.netname);
1954         this.team_selected = false;
1955 }
1956
1957 int GetPlayerLimit()
1958 {
1959         if(g_duel)
1960                 return 2; // TODO: this workaround is needed since the mutator hook from duel can't be activated before the gametype is loaded (e.g. switching modes via gametype vote screen)
1961         int player_limit = autocvar_g_maxplayers;
1962         MUTATOR_CALLHOOK(GetPlayerLimit, player_limit);
1963         player_limit = M_ARGV(0, int);
1964         return player_limit;
1965 }
1966
1967 /**
1968  * Determines whether the player is allowed to join. This depends on cvar
1969  * g_maxplayers, if it isn't used this function always return true, otherwise
1970  * it checks whether the number of currently playing players exceeds g_maxplayers.
1971  * @return int number of free slots for players, 0 if none
1972  */
1973 int nJoinAllowed(entity this, entity ignore)
1974 {
1975         if(!ignore)
1976         // this is called that way when checking if anyone may be able to join (to build qcstatus)
1977         // so report 0 free slots if restricted
1978         {
1979                 if(autocvar_g_forced_team_otherwise == "spectate")
1980                         return 0;
1981                 if(autocvar_g_forced_team_otherwise == "spectator")
1982                         return 0;
1983         }
1984
1985         if(this && (Player_GetForcedTeamIndex(this) == TEAM_FORCE_SPECTATOR))
1986                 return 0; // forced spectators can never join
1987
1988         // TODO simplify this
1989         int totalClients = 0;
1990         int currentlyPlaying = 0;
1991         FOREACH_CLIENT(true, {
1992                 if(it != ignore)
1993                         ++totalClients;
1994                 if(IS_REAL_CLIENT(it))
1995                 if(IS_PLAYER(it) || it.caplayer)
1996                         ++currentlyPlaying;
1997         });
1998
1999         int player_limit = GetPlayerLimit();
2000
2001         float free_slots = 0;
2002         if (!player_limit)
2003                 free_slots = maxclients - totalClients;
2004         else if(currentlyPlaying < player_limit)
2005                 free_slots = min(maxclients - totalClients, player_limit - currentlyPlaying);
2006
2007         static float msg_time = 0;
2008         if(this && !this.caplayer && ignore && !free_slots && time > msg_time)
2009         {
2010                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_JOIN_PREVENT);
2011                 msg_time = time + 0.5;
2012         }
2013
2014         return free_slots;
2015 }
2016
2017 /**
2018  * Checks whether the client is an observer or spectator, if so, he will get kicked after
2019  * g_maxplayers_spectator_blocktime seconds
2020  */
2021 void checkSpectatorBlock(entity this)
2022 {
2023         if(IS_SPEC(this) || IS_OBSERVER(this))
2024         if(!this.caplayer)
2025         if(IS_REAL_CLIENT(this))
2026         {
2027                 if( time > (CS(this).spectatortime + autocvar_g_maxplayers_spectator_blocktime) ) {
2028                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_QUIT_KICK_SPECTATING);
2029                         dropclient(this);
2030                 }
2031         }
2032 }
2033
2034 void PrintWelcomeMessage(entity this)
2035 {
2036         if(CS(this).motd_actived_time == 0)
2037         {
2038                 if (autocvar_g_campaign) {
2039                         if ((IS_PLAYER(this) && PHYS_INPUT_BUTTON_INFO(this)) || (!IS_PLAYER(this))) {
2040                                 CS(this).motd_actived_time = time;
2041                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_CAMPAIGN_MESSAGE, Campaign_GetMessage(), Campaign_GetLevelNum());
2042                         }
2043                 } else {
2044                         if (PHYS_INPUT_BUTTON_INFO(this)) {
2045                                 CS(this).motd_actived_time = time;
2046                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOTD, getwelcomemessage(this));
2047                         }
2048                 }
2049         }
2050         else if(CS(this).motd_actived_time > 0) // showing MOTD or campaign message
2051         {
2052                 if (autocvar_g_campaign) {
2053                         if (PHYS_INPUT_BUTTON_INFO(this))
2054                                 CS(this).motd_actived_time = time;
2055                         else if ((time - CS(this).motd_actived_time > 2) && IS_PLAYER(this)) { // hide it some seconds after BUTTON_INFO has been released
2056                                 CS(this).motd_actived_time = 0;
2057                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_CAMPAIGN_MESSAGE);
2058                         }
2059                 } else {
2060                         if (PHYS_INPUT_BUTTON_INFO(this))
2061                                 CS(this).motd_actived_time = time;
2062                         else if (time - CS(this).motd_actived_time > 2) { // hide it some seconds after BUTTON_INFO has been released
2063                                 CS(this).motd_actived_time = 0;
2064                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_MOTD);
2065                         }
2066                 }
2067         }
2068         else //if(CS(this).motd_actived_time < 0) // just connected, motd is active
2069         {
2070                 if(PHYS_INPUT_BUTTON_INFO(this)) // BUTTON_INFO hides initial MOTD
2071                         CS(this).motd_actived_time = -2; // wait until BUTTON_INFO gets released
2072                 else if (CS(this).motd_actived_time == -2)
2073                 {
2074                         // instantly hide MOTD
2075                         CS(this).motd_actived_time = 0;
2076                         if (autocvar_g_campaign)
2077                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_CAMPAIGN_MESSAGE);
2078                         else
2079                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_MOTD);
2080                 }
2081                 else if (IS_PLAYER(this) || IS_SPEC(this))
2082                 {
2083                         // FIXME occasionally for some reason MOTD never goes away
2084                         // delay MOTD removal a little bit in the hope it fixes this bug
2085                         if (CS(this).motd_actived_time == -1) // MOTD marked to fade away as soon as client becomes player or spectator
2086                                 CS(this).motd_actived_time = -(5 + floor(random() * 10)); // add small delay
2087                         else //if (CS(this).motd_actived_time < -2)
2088                                 CS(this).motd_actived_time++;
2089                 }
2090         }
2091 }
2092
2093 const int MIN_SPEC_TIME = 1;
2094 bool joinAllowed(entity this)
2095 {
2096         if (CS(this).version_mismatch) return false;
2097         if (time < CS(this).jointime + MIN_SPEC_TIME) return false;
2098         if (!nJoinAllowed(this, this)) return false;
2099         if (teamplay && lockteams) return false;
2100         if (MUTATOR_CALLHOOK(ForbidSpawn, this)) return false;
2101         if (ShowTeamSelection(this)) return false;
2102         return true;
2103 }
2104
2105 .string shootfromfixedorigin;
2106 .bool dualwielding_prev;
2107 bool PlayerThink(entity this)
2108 {
2109         if (game_stopped || intermission_running) {
2110                 this.modelflags &= ~MF_ROCKET;
2111                 if(intermission_running)
2112                         IntermissionThink(this);
2113                 return false;
2114         }
2115
2116         if (timeout_status == TIMEOUT_ACTIVE) {
2117         // don't allow the player to turn around while game is paused
2118                 // FIXME turn this into CSQC stuff
2119                 this.v_angle = this.lastV_angle;
2120                 this.angles = this.lastV_angle;
2121                 this.fixangle = true;
2122         }
2123
2124         if (frametime) player_powerups(this);
2125
2126         if (IS_DEAD(this)) {
2127                 if (this.personal && g_race_qualifying) {
2128                         if (time > this.respawn_time) {
2129                                 STAT(RESPAWN_TIME, this) = this.respawn_time = time + 1; // only retry once a second
2130                                 respawn(this);
2131                                 CS(this).impulse = CHIMPULSE_SPEEDRUN.impulse;
2132                         }
2133                 } else {
2134                         if (frametime) player_anim(this);
2135
2136                         if (this.respawn_flags & RESPAWN_DENY)
2137                         {
2138                                 STAT(RESPAWN_TIME, this) = 0;
2139                                 return false;
2140                         }
2141
2142                         bool button_pressed = (PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_JUMP(this) || PHYS_INPUT_BUTTON_ATCK2(this) || PHYS_INPUT_BUTTON_HOOK(this) || PHYS_INPUT_BUTTON_USE(this));
2143
2144                         switch(this.deadflag)
2145                         {
2146                                 case DEAD_DYING:
2147                                 {
2148                                         if ((this.respawn_flags & RESPAWN_FORCE) && !(this.respawn_time < this.respawn_time_max))
2149                                                 this.deadflag = DEAD_RESPAWNING;
2150                                         else if (!button_pressed || (time >= this.respawn_time_max && (this.respawn_flags & RESPAWN_FORCE)))
2151                                                 this.deadflag = DEAD_DEAD;
2152                                         break;
2153                                 }
2154                                 case DEAD_DEAD:
2155                                 {
2156                                         if (button_pressed)
2157                                                 this.deadflag = DEAD_RESPAWNABLE;
2158                                         else if (time >= this.respawn_time_max && (this.respawn_flags & RESPAWN_FORCE))
2159                                                 this.deadflag = DEAD_RESPAWNING;
2160                                         break;
2161                                 }
2162                                 case DEAD_RESPAWNABLE:
2163                                 {
2164                                         if (!button_pressed || (this.respawn_flags & RESPAWN_FORCE))
2165                                                 this.deadflag = DEAD_RESPAWNING;
2166                                         break;
2167                                 }
2168                                 case DEAD_RESPAWNING:
2169                                 {
2170                                         if (time > this.respawn_time)
2171                                         {
2172                                                 this.respawn_time = time + 1; // only retry once a second
2173                                                 this.respawn_time_max = this.respawn_time;
2174                                                 respawn(this);
2175                                         }
2176                                         break;
2177                                 }
2178                         }
2179
2180                         ShowRespawnCountdown(this);
2181
2182                         if (this.respawn_flags & RESPAWN_SILENT)
2183                                 STAT(RESPAWN_TIME, this) = 0;
2184                         else if ((this.respawn_flags & RESPAWN_FORCE) && this.respawn_time < this.respawn_time_max)
2185                         {
2186                                 if (time < this.respawn_time)
2187                                         STAT(RESPAWN_TIME, this) = this.respawn_time;
2188                                 else if (this.deadflag != DEAD_RESPAWNING)
2189                                         STAT(RESPAWN_TIME, this) = -this.respawn_time_max;
2190                         }
2191                         else
2192                                 STAT(RESPAWN_TIME, this) = this.respawn_time;
2193                 }
2194
2195                 // if respawning, invert stat_respawn_time to indicate this, the client translates it
2196                 if (this.deadflag == DEAD_RESPAWNING && STAT(RESPAWN_TIME, this) > 0)
2197                         STAT(RESPAWN_TIME, this) *= -1;
2198
2199                 return false;
2200         }
2201
2202         FixPlayermodel(this);
2203
2204         if (this.shootfromfixedorigin != autocvar_g_shootfromfixedorigin) {
2205                 this.shootfromfixedorigin = autocvar_g_shootfromfixedorigin;
2206                 stuffcmd(this, sprintf("\ncl_shootfromfixedorigin \"%s\"\n", autocvar_g_shootfromfixedorigin));
2207         }
2208
2209         // reset gun alignment when dual wielding status changes
2210         // to ensure guns are always aligned right and left
2211         bool dualwielding = W_DualWielding(this);
2212         if(this.dualwielding_prev != dualwielding)
2213         {
2214                 W_ResetGunAlign(this, CS(this).cvar_cl_gunalign);
2215                 this.dualwielding_prev = dualwielding;
2216         }
2217
2218         // LordHavoc: allow firing on move frames (sub-ticrate), this gives better timing on slow servers
2219         //if(frametime)
2220         {
2221                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2222                 {
2223                         .entity weaponentity = weaponentities[slot];
2224                         if(WEP_CVAR(vortex, charge_always))
2225                                 W_Vortex_Charge(this, weaponentity, frametime);
2226                         W_WeaponFrame(this, weaponentity);
2227                 }
2228         }
2229
2230         if (frametime)
2231         {
2232                 // WEAPONTODO: Add a weapon request for this
2233                 // rot vortex charge to the charge limit
2234                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2235                 {
2236                         .entity weaponentity = weaponentities[slot];
2237                         if (WEP_CVAR(vortex, charge_rot_rate) && this.(weaponentity).vortex_charge > WEP_CVAR(vortex, charge_limit) && this.(weaponentity).vortex_charge_rottime < time)
2238                                 this.(weaponentity).vortex_charge = bound(WEP_CVAR(vortex, charge_limit), this.(weaponentity).vortex_charge - WEP_CVAR(vortex, charge_rot_rate) * frametime / W_TICSPERFRAME, 1);
2239                 }
2240
2241                 player_regen(this);
2242                 player_anim(this);
2243                 this.dmg_team = max(0, this.dmg_team - autocvar_g_teamdamage_resetspeed * frametime);
2244         }
2245
2246         secrets_setstatus(this);
2247         monsters_setstatus(this);
2248
2249         return true;
2250 }
2251
2252 .bool would_spectate;
2253 void ObserverThink(entity this)
2254 {
2255         if ( CS(this).impulse )
2256         {
2257                 MinigameImpulse(this, CS(this).impulse);
2258                 CS(this).impulse = 0;
2259         }
2260
2261         if (this.flags & FL_JUMPRELEASED) {
2262                 if (PHYS_INPUT_BUTTON_JUMP(this) && joinAllowed(this)) {
2263                         this.flags &= ~FL_JUMPRELEASED;
2264                         this.flags |= FL_SPAWNING;
2265                 } else if(PHYS_INPUT_BUTTON_ATCK(this) && !CS(this).version_mismatch || this.would_spectate) {
2266                         this.flags &= ~FL_JUMPRELEASED;
2267                         if(SpectateNext(this)) {
2268                                 TRANSMUTE(Spectator, this);
2269                         }
2270                 } else {
2271                         int preferred_movetype = ((!PHYS_INPUT_BUTTON_USE(this) ? CS(this).cvar_cl_clippedspectating : !CS(this).cvar_cl_clippedspectating) ? MOVETYPE_FLY_WORLDONLY : MOVETYPE_NOCLIP);
2272                         set_movetype(this, preferred_movetype);
2273                 }
2274         } else {
2275                 if (!(PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_JUMP(this))) {
2276                         this.flags |= FL_JUMPRELEASED;
2277                         if(this.flags & FL_SPAWNING)
2278                         {
2279                                 this.flags &= ~FL_SPAWNING;
2280                                 if(joinAllowed(this))
2281                                         Join(this);
2282                                 return;
2283                         }
2284                 }
2285         }
2286 }
2287
2288 void SpectatorThink(entity this)
2289 {
2290         if ( CS(this).impulse )
2291         {
2292                 if(MinigameImpulse(this, CS(this).impulse))
2293                         CS(this).impulse = 0;
2294
2295                 if (CS(this).impulse == IMP_weapon_drop.impulse)
2296                 {
2297                         STAT(CAMERA_SPECTATOR, this) = (STAT(CAMERA_SPECTATOR, this) + 1) % 3;
2298                         CS(this).impulse = 0;
2299                         return;
2300                 }
2301         }
2302
2303         if (this.flags & FL_JUMPRELEASED) {
2304                 if (PHYS_INPUT_BUTTON_JUMP(this) && joinAllowed(this)) {
2305                         this.flags &= ~FL_JUMPRELEASED;
2306                         this.flags |= FL_SPAWNING;
2307                 } else if(PHYS_INPUT_BUTTON_ATCK(this) || CS(this).impulse == 10 || CS(this).impulse == 15 || CS(this).impulse == 18 || (CS(this).impulse >= 200 && CS(this).impulse <= 209)) {
2308                         this.flags &= ~FL_JUMPRELEASED;
2309                         if(SpectateNext(this)) {
2310                                 TRANSMUTE(Spectator, this);
2311                         } else {
2312                                 TRANSMUTE(Observer, this);
2313                                 PutClientInServer(this);
2314                         }
2315                         CS(this).impulse = 0;
2316                 } else if(CS(this).impulse == 12 || CS(this).impulse == 16  || CS(this).impulse == 19 || (CS(this).impulse >= 220 && CS(this).impulse <= 229)) {
2317                         this.flags &= ~FL_JUMPRELEASED;
2318                         if(SpectatePrev(this)) {
2319                                 TRANSMUTE(Spectator, this);
2320                         } else {
2321                                 TRANSMUTE(Observer, this);
2322                                 PutClientInServer(this);
2323                         }
2324                         CS(this).impulse = 0;
2325                 } else if (PHYS_INPUT_BUTTON_ATCK2(this)) {
2326                         this.would_spectate = false;
2327                         this.flags &= ~FL_JUMPRELEASED;
2328                         TRANSMUTE(Observer, this);
2329                         PutClientInServer(this);
2330                 } else {
2331                         if(!SpectateUpdate(this))
2332                         {
2333                                 if(!SpectateNext(this))
2334                                 {
2335                                         PutObserverInServer(this);
2336                                         this.would_spectate = true;
2337                                 }
2338                         }
2339                 }
2340         } else {
2341                 if (!(PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_ATCK2(this))) {
2342                         this.flags |= FL_JUMPRELEASED;
2343                         if(this.flags & FL_SPAWNING)
2344                         {
2345                                 this.flags &= ~FL_SPAWNING;
2346                                 Join(this);
2347                                 return;
2348                         }
2349                 }
2350                 if(!SpectateUpdate(this))
2351                         PutObserverInServer(this);
2352         }
2353
2354         this.flags |= FL_CLIENT | FL_NOTARGET;
2355 }
2356
2357 void PlayerUseKey(entity this)
2358 {
2359         if (!IS_PLAYER(this))
2360                 return;
2361
2362         if(this.vehicle)
2363         {
2364                 if(!game_stopped)
2365                 {
2366                         vehicles_exit(this.vehicle, VHEF_NORMAL);
2367                         return;
2368                 }
2369         }
2370         else if(autocvar_g_vehicles_enter)
2371         {
2372                 if(!game_stopped && !STAT(FROZEN, this) && !IS_DEAD(this) && !IS_INDEPENDENT_PLAYER(this))
2373                 {
2374                         entity head, closest_target = NULL;
2375                         head = WarpZone_FindRadius(this.origin, autocvar_g_vehicles_enter_radius, true);
2376
2377                         while(head) // find the closest acceptable target to enter
2378                         {
2379                                 if(IS_VEHICLE(head) && !IS_DEAD(head) && head.takedamage != DAMAGE_NO)
2380                                 if(!head.owner || ((head.vehicle_flags & VHF_MULTISLOT) && SAME_TEAM(head.owner, this)))
2381                                 {
2382                                         if(closest_target)
2383                                         {
2384                                                 if(vlen2(this.origin - head.origin) < vlen2(this.origin - closest_target.origin))
2385                                                 { closest_target = head; }
2386                                         }
2387                                         else { closest_target = head; }
2388                                 }
2389
2390                                 head = head.chain;
2391                         }
2392
2393                         if(closest_target) { vehicles_enter(this, closest_target); return; }
2394                 }
2395         }
2396
2397         // a use key was pressed; call handlers
2398         MUTATOR_CALLHOOK(PlayerUseKey, this);
2399 }
2400
2401
2402 /*
2403 =============
2404 PlayerPreThink
2405
2406 Called every frame for each client before the physics are run
2407 =============
2408 */
2409 .float last_vehiclecheck;
2410 void PlayerPreThink (entity this)
2411 {
2412         STAT(GUNALIGN, this) = CS(this).cvar_cl_gunalign; // TODO
2413         STAT(MOVEVARS_CL_TRACK_CANJUMP, this) = CS(this).cvar_cl_movement_track_canjump;
2414
2415         WarpZone_PlayerPhysics_FixVAngle(this);
2416
2417         if (frametime) {
2418                 // physics frames: update anticheat stuff
2419                 anticheat_prethink(this);
2420         }
2421
2422         if (blockSpectators && frametime) {
2423                 // WORKAROUND: only use dropclient in server frames (frametime set).
2424                 // Never use it in cl_movement frames (frametime zero).
2425                 checkSpectatorBlock(this);
2426         }
2427
2428         zoomstate_set = false;
2429
2430         // Check for nameless players
2431         if (this.netname == "" || this.netname != CS(this).netname_previous)
2432         {
2433                 bool assume_unchanged = (CS(this).netname_previous == "");
2434                 if (autocvar_sv_name_maxlength > 0 && strlennocol(this.netname) > autocvar_sv_name_maxlength)
2435                 {
2436                         int new_length = textLengthUpToLength(this.netname, autocvar_sv_name_maxlength, strlennocol);
2437                         this.netname = strzone(strcat(substring(this.netname, 0, new_length), "^7"));
2438                         sprint(this, sprintf("Warning: your name is longer than %d characters, it has been truncated.\n", autocvar_sv_name_maxlength));
2439                         assume_unchanged = false;
2440                         // stuffcmd(this, strcat("name ", this.netname, "\n")); // maybe?
2441                 }
2442                 if (isInvisibleString(this.netname))
2443                 {
2444                         this.netname = strzone(sprintf("Player#%d", this.playerid));
2445                         sprint(this, "Warning: invisible names are not allowed.\n");
2446                         assume_unchanged = false;
2447                         // stuffcmd(this, strcat("name ", this.netname, "\n")); // maybe?
2448                 }
2449                 if (!assume_unchanged && autocvar_sv_eventlog)
2450                         GameLogEcho(strcat(":name:", ftos(this.playerid), ":", playername(this, false)));
2451                 strcpy(CS(this).netname_previous, this.netname);
2452         }
2453
2454         // version nagging
2455         if (CS(this).version_nagtime && CS(this).cvar_g_xonoticversion && time > CS(this).version_nagtime) {
2456         CS(this).version_nagtime = 0;
2457         if (strstrofs(CS(this).cvar_g_xonoticversion, "git", 0) >= 0 || strstrofs(CS(this).cvar_g_xonoticversion, "autobuild", 0) >= 0) {
2458             // git client
2459         } else if (strstrofs(autocvar_g_xonoticversion, "git", 0) >= 0 || strstrofs(autocvar_g_xonoticversion, "autobuild", 0) >= 0) {
2460             // git server
2461             Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_BETA, autocvar_g_xonoticversion, CS(this).cvar_g_xonoticversion);
2462         } else {
2463             int r = vercmp(CS(this).cvar_g_xonoticversion, autocvar_g_xonoticversion);
2464             if (r < 0) { // old client
2465                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_OUTDATED, autocvar_g_xonoticversion, CS(this).cvar_g_xonoticversion);
2466             } else if (r > 0) { // old server
2467                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_OLD, autocvar_g_xonoticversion, CS(this).cvar_g_xonoticversion);
2468             }
2469         }
2470     }
2471
2472         // GOD MODE info
2473         if (!(this.flags & FL_GODMODE) && this.max_armorvalue)
2474         {
2475                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_GODMODE_OFF, this.max_armorvalue);
2476                 this.max_armorvalue = 0;
2477         }
2478
2479         if (frametime && IS_PLAYER(this))
2480         {
2481                 if (STAT(FROZEN, this) == FROZEN_TEMP_REVIVING)
2482                 {
2483                         STAT(REVIVE_PROGRESS, this) = bound(0, STAT(REVIVE_PROGRESS, this) + frametime * this.revive_speed, 1);
2484                         SetResourceExplicit(this, RES_HEALTH, max(1, STAT(REVIVE_PROGRESS, this) * start_health));
2485                         this.iceblock.alpha = bound(0.2, 1 - STAT(REVIVE_PROGRESS, this), 1);
2486
2487                         if (STAT(REVIVE_PROGRESS, this) >= 1)
2488                                 Unfreeze(this, false);
2489                 }
2490                 else if (STAT(FROZEN, this) == FROZEN_TEMP_DYING)
2491                 {
2492                         STAT(REVIVE_PROGRESS, this) = bound(0, STAT(REVIVE_PROGRESS, this) - frametime * this.revive_speed, 1);
2493                         SetResourceExplicit(this, RES_HEALTH, max(0, autocvar_g_nades_ice_health + (start_health-autocvar_g_nades_ice_health) * STAT(REVIVE_PROGRESS, this)));
2494
2495                         if (GetResource(this, RES_HEALTH) < 1)
2496                         {
2497                                 if (this.vehicle)
2498                                         vehicles_exit(this.vehicle, VHEF_RELEASE);
2499                                 if(this.event_damage)
2500                                         this.event_damage(this, this, this.frozen_by, 1, DEATH_NADE_ICE_FREEZE.m_id, DMG_NOWEP, this.origin, '0 0 0');
2501                         }
2502                         else if (STAT(REVIVE_PROGRESS, this) <= 0)
2503                                 Unfreeze(this, false);
2504                 }
2505         }
2506
2507         MUTATOR_CALLHOOK(PlayerPreThink, this);
2508
2509         if(autocvar_g_vehicles_enter && (time > this.last_vehiclecheck) && !game_stopped && !this.vehicle)
2510         if(IS_PLAYER(this) && !STAT(FROZEN, this) && !IS_DEAD(this) && !IS_INDEPENDENT_PLAYER(this))
2511         {
2512                 FOREACH_ENTITY_RADIUS(this.origin, autocvar_g_vehicles_enter_radius, IS_VEHICLE(it) && !IS_DEAD(it) && it.takedamage != DAMAGE_NO,
2513                 {
2514                         if(!it.owner)
2515                         {
2516                                 if(!it.team || SAME_TEAM(this, it))
2517                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER);
2518                                 else if(autocvar_g_vehicles_steal)
2519                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER_STEAL);
2520                         }
2521                         else if((it.vehicle_flags & VHF_MULTISLOT) && SAME_TEAM(it.owner, this))
2522                         {
2523                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER_GUNNER);
2524                         }
2525                 });
2526
2527                 this.last_vehiclecheck = time + 1;
2528         }
2529
2530         if(!CS(this).cvar_cl_newusekeysupported) // FIXME remove this - it was a stupid idea to begin with, we can JUST use the button
2531         {
2532                 if(PHYS_INPUT_BUTTON_USE(this) && !CS(this).usekeypressed)
2533                         PlayerUseKey(this);
2534                 CS(this).usekeypressed = PHYS_INPUT_BUTTON_USE(this);
2535         }
2536
2537         if (IS_REAL_CLIENT(this))
2538                 PrintWelcomeMessage(this);
2539
2540         if (IS_PLAYER(this)) {
2541                 if (IS_REAL_CLIENT(this) && time < CS(this).jointime + MIN_SPEC_TIME)
2542                         error("Client can't be spawned as player on connection!");
2543                 if(!PlayerThink(this))
2544                         return;
2545         }
2546         else if (game_stopped || intermission_running) {
2547                 if(intermission_running)
2548                         IntermissionThink(this);
2549                 return;
2550         }
2551         else if (IS_REAL_CLIENT(this) && !CS(this).autojoin_checked && time >= CS(this).jointime + MIN_SPEC_TIME)
2552         {
2553                 CS(this).autojoin_checked = true;
2554                 // don't do this in ClientConnect
2555                 // many things can go wrong if a client is spawned as player on connection
2556                 if (MUTATOR_CALLHOOK(AutoJoinOnConnection, this)
2557                         || (!(autocvar_sv_spectate || autocvar_g_campaign || (Player_GetForcedTeamIndex(this) == TEAM_FORCE_SPECTATOR))
2558                                 && (!teamplay || autocvar_g_balance_teams)))
2559                 {
2560                         campaign_bots_may_start = true;
2561                         Join(this);
2562                         return;
2563                 }
2564         }
2565         else if (IS_OBSERVER(this)) {
2566                 ObserverThink(this);
2567         }
2568         else if (IS_SPEC(this)) {
2569                 SpectatorThink(this);
2570         }
2571
2572         // WEAPONTODO: Add weapon request for this
2573         if (!zoomstate_set) {
2574                 bool wep_zoomed = false;
2575                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2576                 {
2577                         .entity weaponentity = weaponentities[slot];
2578                         Weapon thiswep = this.(weaponentity).m_weapon;
2579                         if(thiswep != WEP_Null && thiswep.wr_zoom)
2580                                 wep_zoomed += thiswep.wr_zoom(thiswep, this);
2581                 }
2582                 SetZoomState(this, PHYS_INPUT_BUTTON_ZOOM(this) || PHYS_INPUT_BUTTON_ZOOMSCRIPT(this) || wep_zoomed);
2583     }
2584
2585         if (CS(this).teamkill_soundtime && time > CS(this).teamkill_soundtime)
2586         {
2587                 CS(this).teamkill_soundtime = 0;
2588
2589                 entity e = CS(this).teamkill_soundsource;
2590                 entity oldpusher = e.pusher;
2591                 e.pusher = this;
2592                 PlayerSound(e, playersound_teamshoot, CH_VOICE, VOL_BASEVOICE, VOICETYPE_LASTATTACKER_ONLY);
2593                 e.pusher = oldpusher;
2594         }
2595
2596         if (CS(this).taunt_soundtime && time > CS(this).taunt_soundtime) {
2597                 CS(this).taunt_soundtime = 0;
2598                 PlayerSound(this, playersound_taunt, CH_VOICE, VOL_BASEVOICE, VOICETYPE_AUTOTAUNT);
2599         }
2600
2601         target_voicescript_next(this);
2602
2603         // WEAPONTODO: Move into weaponsystem somehow
2604         // if a player goes unarmed after holding a loaded weapon, empty his clip size and remove the crosshair ammo ring
2605         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2606         {
2607                 .entity weaponentity = weaponentities[slot];
2608                 if(this.(weaponentity).m_weapon == WEP_Null)
2609                         this.(weaponentity).clip_load = this.(weaponentity).clip_size = 0;
2610         }
2611 }
2612
2613 void DrownPlayer(entity this)
2614 {
2615         if(IS_DEAD(this) || game_stopped || time < game_starttime || this.vehicle
2616                 || STAT(FROZEN, this) || this.watertype != CONTENT_WATER)
2617         {
2618                 this.air_finished = 0;
2619                 return;
2620         }
2621
2622         if (this.waterlevel != WATERLEVEL_SUBMERGED)
2623         {
2624                 if(this.air_finished && this.air_finished < time)
2625                         PlayerSound(this, playersound_gasp, CH_PLAYER, VOL_BASE, VOICETYPE_PLAYERSOUND);
2626                 this.air_finished = 0;
2627         }
2628         else
2629         {
2630                 if (!this.air_finished)
2631                         this.air_finished = time + autocvar_g_balance_contents_drowndelay;
2632                 if (this.air_finished < time)
2633                 {       // drown!
2634                         if (this.pain_finished < time)
2635                         {
2636                                 Damage (this, NULL, NULL, autocvar_g_balance_contents_playerdamage_drowning * autocvar_g_balance_contents_damagerate, DEATH_DROWN.m_id, DMG_NOWEP, this.origin, '0 0 0');
2637                                 this.pain_finished = time + 0.5;
2638                         }
2639                 }
2640         }
2641 }
2642
2643 .bool move_qcphysics;
2644
2645 void Player_Physics(entity this)
2646 {
2647         this.movetype = (this.move_qcphysics) ? MOVETYPE_QCPLAYER : this.move_movetype;
2648
2649         if(!this.move_qcphysics)
2650                 return;
2651
2652         if(!frametime && !CS(this).pm_frametime)
2653                 return;
2654
2655         Movetype_Physics_NoMatchTicrate(this, CS(this).pm_frametime, true);
2656
2657         CS(this).pm_frametime = 0;
2658 }
2659
2660 /*
2661 =============
2662 PlayerPostThink
2663
2664 Called every frame for each client after the physics are run
2665 =============
2666 */
2667 void PlayerPostThink (entity this)
2668 {
2669         Player_Physics(this);
2670
2671         if (sv_maxidle > 0)
2672         if (frametime) // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2673         if (IS_REAL_CLIENT(this))
2674         if (IS_PLAYER(this) || sv_maxidle_spectatorsareidle)
2675         {
2676                 int totalClients = 0;
2677                 if(sv_maxidle_slots > 0)
2678                 {
2679                         FOREACH_CLIENT(IS_REAL_CLIENT(it) || sv_maxidle_slots_countbots,
2680                         {
2681                                 ++totalClients;
2682                         });
2683                 }
2684
2685                 if (sv_maxidle_slots > 0 && (maxclients - totalClients) > sv_maxidle_slots)
2686                 { /* do nothing */ }
2687                 else if (time - CS(this).parm_idlesince < 1) // instead of (time == this.parm_idlesince) to support sv_maxidle <= 10
2688                 {
2689                         if (CS(this).idlekick_lasttimeleft)
2690                         {
2691                                 CS(this).idlekick_lasttimeleft = 0;
2692                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_IDLING);
2693                         }
2694                 }
2695                 else
2696                 {
2697                         float timeleft = ceil(sv_maxidle - (time - CS(this).parm_idlesince));
2698                         if (timeleft == min(10, sv_maxidle - 1)) { // - 1 to support sv_maxidle <= 10
2699                                 if (!CS(this).idlekick_lasttimeleft)
2700                                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_DISCONNECT_IDLING, timeleft);
2701                         }
2702                         if (timeleft <= 0) {
2703                                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_QUIT_KICK_IDLING, this.netname);
2704                                 dropclient(this);
2705                                 return;
2706                         }
2707                         else if (timeleft <= 10) {
2708                                 if (timeleft != CS(this).idlekick_lasttimeleft) {
2709                                     Send_Notification(NOTIF_ONE, this, MSG_ANNCE, Announcer_PickNumber(CNT_IDLE, timeleft));
2710                 }
2711                                 CS(this).idlekick_lasttimeleft = timeleft;
2712                         }
2713                 }
2714         }
2715
2716         CheatFrame(this);
2717
2718         if (game_stopped)
2719         {
2720                 this.solid = SOLID_NOT;
2721                 this.takedamage = DAMAGE_NO;
2722                 set_movetype(this, MOVETYPE_NONE);
2723         }
2724
2725         if (IS_PLAYER(this)) {
2726                 if(this.death_time == time && IS_DEAD(this))
2727                 {
2728                         // player's bbox gets resized now, instead of in the damage event that killed the player,
2729                         // once all the damage events of this frame have been processed with normal size
2730                         this.maxs.z = 5;
2731                         setsize(this, this.mins, this.maxs);
2732                 }
2733                 DrownPlayer(this);
2734                 UpdateChatBubble(this);
2735                 if (CS(this).impulse) ImpulseCommands(this);
2736                 if (game_stopped)
2737                 {
2738                         CSQCMODEL_AUTOUPDATE(this);
2739                         return;
2740                 }
2741                 GetPressedKeys(this);
2742         }
2743         else if (IS_OBSERVER(this) && STAT(PRESSED_KEYS, this))
2744         {
2745                 CS(this).pressedkeys = 0;
2746                 STAT(PRESSED_KEYS, this) = 0;
2747         }
2748
2749         if (this.waypointsprite_attachedforcarrier) {
2750                 float hp = healtharmor_maxdamage(GetResource(this, RES_HEALTH), GetResource(this, RES_ARMOR), autocvar_g_balance_armor_blockpercent, DEATH_WEAPON.m_id).x;
2751                 WaypointSprite_UpdateHealth(this.waypointsprite_attachedforcarrier, hp);
2752         }
2753
2754         CSQCMODEL_AUTOUPDATE(this);
2755 }
2756
2757 /**
2758  * message "": do not say, just test flood control
2759  * return value:
2760  *   1 = accept
2761  *   0 = reject
2762  *  -1 = fake accept
2763  */
2764 int Say(entity source, int teamsay, entity privatesay, string msgin, bool floodcontrol)
2765 {
2766         if (!teamsay && !privatesay && substring(msgin, 0, 1) == " ")
2767                 msgin = substring(msgin, 1, -1); // work around DP say bug (say_team does not have this!)
2768
2769         if (source)
2770                 msgin = formatmessage(source, msgin);
2771
2772         string colorstr;
2773         if (!(IS_PLAYER(source) || source.caplayer))
2774                 colorstr = "^0"; // black for spectators
2775         else if(teamplay)
2776                 colorstr = Team_ColorCode(source.team);
2777         else
2778         {
2779                 colorstr = "";
2780                 teamsay = false;
2781         }
2782
2783         if (!source) {
2784                 colorstr = "";
2785                 teamsay = false;
2786         }
2787
2788         if(msgin != "")
2789                 msgin = trigger_magicear_processmessage_forallears(source, teamsay, privatesay, msgin);
2790
2791         /*
2792          * using bprint solves this... me stupid
2793         // how can we prevent the message from appearing in a listen server?
2794         // for now, just give "say" back and only handle say_team
2795         if(!teamsay)
2796         {
2797                 clientcommand(source, strcat("say ", msgin));
2798                 return;
2799         }
2800         */
2801
2802         string namestr = "";
2803         if (source)
2804                 namestr = playername(source, autocvar_g_chat_teamcolors);
2805
2806         string colorprefix = (strdecolorize(namestr) == namestr) ? "^3" : "^7";
2807
2808         string msgstr = "", cmsgstr = "";
2809         string privatemsgprefix = string_null;
2810         int privatemsgprefixlen = 0;
2811         if (msgin != "")
2812         {
2813                 bool found_me = false;
2814                 if(strstrofs(msgin, "/me", 0) >= 0)
2815                 {
2816                         string newmsgin = "";
2817                         string newnamestr = ((teamsay) ? strcat(colorstr, "(", colorprefix, namestr, colorstr, ")", "^7") : strcat(colorprefix, namestr, "^7"));
2818                         FOREACH_WORD(msgin, true,
2819                         {
2820                                 if(strdecolorize(it) == "/me")
2821                                 {
2822                                         found_me = true;
2823                                         newmsgin = cons(newmsgin, newnamestr);
2824                                 }
2825                                 else
2826                                         newmsgin = cons(newmsgin, it);
2827                         });
2828                         msgin = newmsgin;
2829                 }
2830
2831                 if(privatesay)
2832                 {
2833                         msgstr = strcat("\{1}\{13}* ", colorprefix, namestr, "^3 tells you: ^7");
2834                         privatemsgprefixlen = strlen(msgstr);
2835                         msgstr = strcat(msgstr, msgin);
2836                         cmsgstr = strcat(colorstr, colorprefix, namestr, "^3 tells you:\n^7", msgin);
2837                         privatemsgprefix = strcat("\{1}\{13}* ^3You tell ", playername(privatesay, autocvar_g_chat_teamcolors), ": ^7");
2838                 }
2839                 else if(teamsay)
2840                 {
2841                         if(found_me)
2842                         {
2843                                 //msgin = strreplace("/me", "", msgin);
2844                                 //msgin = substring(msgin, 3, strlen(msgin));
2845                                 //msgin = strreplace("/me", strcat(colorstr, "(", colorprefix, namestr, colorstr, ")^7"), msgin);
2846                                 msgstr = strcat("\{1}\{13}^4* ", "^7", msgin);
2847                         }
2848                         else
2849                                 msgstr = strcat("\{1}\{13}", colorstr, "(", colorprefix, namestr, colorstr, ") ^7", msgin);
2850                         cmsgstr = strcat(colorstr, "(", colorprefix, namestr, colorstr, ")\n^7", msgin);
2851                 }
2852                 else
2853                 {
2854                         if(found_me)
2855                         {
2856                                 //msgin = strreplace("/me", "", msgin);
2857                                 //msgin = substring(msgin, 3, strlen(msgin));
2858                                 //msgin = strreplace("/me", strcat(colorprefix, namestr), msgin);
2859                                 msgstr = strcat("\{1}^4* ^7", msgin);
2860                         }
2861                         else {
2862                                 msgstr = "\{1}";
2863                                 msgstr = strcat(msgstr, (namestr != "") ? strcat(colorprefix, namestr, "^7: ") : "^7");
2864                                 msgstr = strcat(msgstr, msgin);
2865                         }
2866                         cmsgstr = "";
2867                 }
2868                 msgstr = strcat(strreplace("\n", " ", msgstr), "\n"); // newlines only are good for centerprint
2869         }
2870
2871         string fullmsgstr = msgstr;
2872         string fullcmsgstr = cmsgstr;
2873
2874         // FLOOD CONTROL
2875         int flood = 0;
2876         var .float flood_field = floodcontrol_chat;
2877         if(floodcontrol && source)
2878         {
2879                 float flood_spl;
2880                 float flood_burst;
2881                 float flood_lmax;
2882                 float lines;
2883                 if(privatesay)
2884                 {
2885                         flood_spl = autocvar_g_chat_flood_spl_tell;
2886                         flood_burst = autocvar_g_chat_flood_burst_tell;
2887                         flood_lmax = autocvar_g_chat_flood_lmax_tell;
2888                         flood_field = floodcontrol_chattell;
2889                 }
2890                 else if(teamsay)
2891                 {
2892                         flood_spl = autocvar_g_chat_flood_spl_team;
2893                         flood_burst = autocvar_g_chat_flood_burst_team;
2894                         flood_lmax = autocvar_g_chat_flood_lmax_team;
2895                         flood_field = floodcontrol_chatteam;
2896                 }
2897                 else
2898                 {
2899                         flood_spl = autocvar_g_chat_flood_spl;
2900                         flood_burst = autocvar_g_chat_flood_burst;
2901                         flood_lmax = autocvar_g_chat_flood_lmax;
2902                         flood_field = floodcontrol_chat;
2903                 }
2904                 flood_burst = max(0, flood_burst - 1);
2905                 // to match explanation in default.cfg, a value of 3 must allow three-line bursts and not four!
2906
2907                 // do flood control for the default line size
2908                 if(msgstr != "")
2909                 {
2910                         getWrappedLine_remaining = msgstr;
2911                         msgstr = "";
2912                         lines = 0;
2913                         while(getWrappedLine_remaining && (!flood_lmax || lines <= flood_lmax))
2914                         {
2915                                 msgstr = strcat(msgstr, " ", getWrappedLineLen(82.4289758859709, strlennocol)); // perl averagewidth.pl < gfx/vera-sans.width
2916                                 ++lines;
2917                         }
2918                         msgstr = substring(msgstr, 1, strlen(msgstr) - 1);
2919
2920                         if(getWrappedLine_remaining != "")
2921                         {
2922                                 msgstr = strcat(msgstr, "\n");
2923                                 flood = 2;
2924                         }
2925
2926                         if (time >= source.(flood_field))
2927                         {
2928                                 source.(flood_field) = max(time - flood_burst * flood_spl, source.(flood_field)) + lines * flood_spl;
2929                         }
2930                         else
2931                         {
2932                                 flood = 1;
2933                                 msgstr = fullmsgstr;
2934                         }
2935                 }
2936                 else
2937                 {
2938                         if (time >= source.(flood_field))
2939                                 source.(flood_field) = max(time - flood_burst * flood_spl, source.(flood_field)) + flood_spl;
2940                         else
2941                                 flood = 1;
2942                 }
2943
2944                 if (timeout_status == TIMEOUT_ACTIVE) // when game is paused, no flood protection
2945                         source.(flood_field) = flood = 0;
2946         }
2947
2948         string sourcemsgstr, sourcecmsgstr;
2949         if(flood == 2) // cannot happen for empty msgstr
2950         {
2951                 if(autocvar_g_chat_flood_notify_flooder)
2952                 {
2953                         sourcemsgstr = strcat(msgstr, "\n^3FLOOD CONTROL: ^7message too long, trimmed\n");
2954                         sourcecmsgstr = "";
2955                 }
2956                 else
2957                 {
2958                         sourcemsgstr = fullmsgstr;
2959                         sourcecmsgstr = fullcmsgstr;
2960                 }
2961                 cmsgstr = "";
2962         }
2963         else
2964         {
2965                 sourcemsgstr = msgstr;
2966                 sourcecmsgstr = cmsgstr;
2967         }
2968
2969         if (!privatesay && source && !(IS_PLAYER(source) || source.caplayer))
2970         {
2971                 if (!game_stopped)
2972                 if (teamsay || (autocvar_g_chat_nospectators == 1) || (autocvar_g_chat_nospectators == 2 && !warmup_stage))
2973                         teamsay = -1; // spectators
2974         }
2975
2976         if(flood)
2977                 LOG_INFO("NOTE: ", playername(source, true), "^7 is flooding.");
2978
2979         // build sourcemsgstr by cutting off a prefix and replacing it by the other one
2980         if(privatesay)
2981                 sourcemsgstr = strcat(privatemsgprefix, substring(sourcemsgstr, privatemsgprefixlen, -1));
2982
2983         int ret;
2984         if(source && CS(source).muted)
2985         {
2986                 // always fake the message
2987                 ret = -1;
2988         }
2989         else if(flood == 1)
2990         {
2991                 if (autocvar_g_chat_flood_notify_flooder)
2992                 {
2993                         sprint(source, strcat("^3FLOOD CONTROL: ^7wait ^1", ftos(source.(flood_field) - time), "^3 seconds\n"));
2994                         ret = 0;
2995                 }
2996                 else
2997                         ret = -1;
2998         }
2999         else
3000         {
3001                 ret = 1;
3002         }
3003
3004         if (privatesay && source && !(IS_PLAYER(source) || source.caplayer))
3005         {
3006                 if (!game_stopped)
3007                 if ((privatesay && (IS_PLAYER(privatesay) || privatesay.caplayer)) && ((autocvar_g_chat_nospectators == 1) || (autocvar_g_chat_nospectators == 2 && !warmup_stage)))
3008                         ret = -1; // just hide the message completely
3009         }
3010
3011         MUTATOR_CALLHOOK(ChatMessage, source, ret);
3012         ret = M_ARGV(1, int);
3013
3014         string event_log_msg = "";
3015
3016         if(sourcemsgstr != "" && ret != 0)
3017         {
3018                 if(ret < 0) // faked message, because the player is muted
3019                 {
3020                         sprint(source, sourcemsgstr);
3021                         if(sourcecmsgstr != "" && !privatesay)
3022                                 centerprint(source, sourcecmsgstr);
3023                 }
3024                 else if(privatesay) // private message, between 2 people only
3025                 {
3026                         sprint(source, sourcemsgstr);
3027                         if (!autocvar_g_chat_tellprivacy) { dedicated_print(msgstr); } // send to server console too if "tellprivacy" is disabled
3028                         if(!MUTATOR_CALLHOOK(ChatMessageTo, privatesay, source))
3029                         {
3030                                 sprint(privatesay, msgstr);
3031                                 if(cmsgstr != "")
3032                                         centerprint(privatesay, cmsgstr);
3033                         }
3034                 }
3035                 else if ( teamsay && CS(source).active_minigame )
3036                 {
3037                         sprint(source, sourcemsgstr);
3038                         dedicated_print(msgstr); // send to server console too
3039                         FOREACH_CLIENT(IS_REAL_CLIENT(it) && it != source && CS(it).active_minigame == CS(source).active_minigame && !MUTATOR_CALLHOOK(ChatMessageTo, it, source), {
3040                                 sprint(it, msgstr);
3041                         });
3042                         event_log_msg = sprintf(":chat_minigame:%d:%s:%s", source.playerid, CS(source).active_minigame.netname, msgin);
3043
3044                 }
3045                 else if(teamsay > 0) // team message, only sent to team mates
3046                 {
3047                         sprint(source, sourcemsgstr);
3048                         dedicated_print(msgstr); // send to server console too
3049                         if(sourcecmsgstr != "")
3050                                 centerprint(source, sourcecmsgstr);
3051                         FOREACH_CLIENT((IS_PLAYER(it) || it.caplayer) && IS_REAL_CLIENT(it) && it != source && it.team == source.team && !MUTATOR_CALLHOOK(ChatMessageTo, it, source), {
3052                                 sprint(it, msgstr);
3053                                 if(cmsgstr != "")
3054                                         centerprint(it, cmsgstr);
3055                         });
3056                         event_log_msg = sprintf(":chat_team:%d:%d:%s", source.playerid, source.team, strreplace("\n", " ", msgin));
3057                 }
3058                 else if(teamsay < 0) // spectator message, only sent to spectators
3059                 {
3060                         sprint(source, sourcemsgstr);
3061                         dedicated_print(msgstr); // send to server console too
3062                         FOREACH_CLIENT(!(IS_PLAYER(it) || it.caplayer) && IS_REAL_CLIENT(it) && it != source && !MUTATOR_CALLHOOK(ChatMessageTo, it, source), {
3063                                 sprint(it, msgstr);
3064                         });
3065                         event_log_msg = sprintf(":chat_spec:%d:%s", source.playerid, strreplace("\n", " ", msgin));
3066                 }
3067                 else
3068                 {
3069                         if (source) {
3070                                 sprint(source, sourcemsgstr);
3071                                 dedicated_print(msgstr); // send to server console too
3072                                 MX_Say(strcat(playername(source, true), "^7: ", msgin));
3073                         }
3074                         FOREACH_CLIENT(IS_REAL_CLIENT(it) && it != source && !MUTATOR_CALLHOOK(ChatMessageTo, it, source), {
3075                                 sprint(it, msgstr);
3076                         });
3077                         event_log_msg = sprintf(":chat:%d:%s", source.playerid, strreplace("\n", " ", msgin));
3078                 }
3079         }
3080
3081         if (autocvar_sv_eventlog && (event_log_msg != "")) {
3082                 GameLogEcho(event_log_msg);
3083         }
3084
3085         return ret;
3086 }
3087
3088 // hack to copy the button fields from the client entity to the Client State
3089 void PM_UpdateButtons(entity this, entity store)
3090 {
3091         if(this.impulse)
3092                 store.impulse = this.impulse;
3093         this.impulse = 0;
3094
3095         bool typing = this.buttonchat || this.button12;
3096
3097         store.button0 = (typing) ? 0 : this.button0;
3098         //button1?!
3099         store.button2 = (typing) ? 0 : this.button2;
3100         store.button3 = (typing) ? 0 : this.button3;
3101         store.button4 = this.button4;
3102         store.button5 = (typing) ? 0 : this.button5;
3103         store.button6 = this.button6;
3104         store.button7 = this.button7;
3105         store.button8 = this.button8;
3106         store.button9 = this.button9;
3107         store.button10 = this.button10;
3108         store.button11 = this.button11;
3109         store.button12 = this.button12;
3110         store.button13 = this.button13;
3111         store.button14 = this.button14;
3112         store.button15 = this.button15;
3113         store.button16 = this.button16;
3114         store.buttonuse = this.buttonuse;
3115         store.buttonchat = this.buttonchat;
3116
3117         store.cursor_active = this.cursor_active;
3118         store.cursor_screen = this.cursor_screen;
3119         store.cursor_trace_start = this.cursor_trace_start;
3120         store.cursor_trace_endpos = this.cursor_trace_endpos;
3121         store.cursor_trace_ent = this.cursor_trace_ent;
3122
3123         store.ping = this.ping;
3124         store.ping_packetloss = this.ping_packetloss;
3125         store.ping_movementloss = this.ping_movementloss;
3126
3127         store.v_angle = this.v_angle;
3128         store.movement = (typing) ? '0 0 0' : this.movement;
3129 }
3130
3131 NET_HANDLE(fpsreport, bool)
3132 {
3133         int fps = ReadShort();
3134         PlayerScore_Set(sender, SP_FPS, fps);
3135         return true;
3136 }