Merge branch 'master' into Lyberta/StandaloneOverkillWeapons
[xonotic/xonotic-data.pk3dir.git] / qcsrc / server / client.qc
1 #include "client.qh"
2
3 #include "anticheat.qh"
4 #include "impulse.qh"
5 #include "player.qh"
6 #include "ipban.qh"
7 #include "miscfunctions.qh"
8 #include "portals.qh"
9 #include "teamplay.qh"
10 #include "playerdemo.qh"
11 #include "spawnpoints.qh"
12 #include "g_damage.qh"
13 #include "g_hook.qh"
14 #include "command/common.qh"
15 #include "cheats.qh"
16 #include "g_world.qh"
17 #include "race.qh"
18 #include "antilag.qh"
19 #include "campaign.qh"
20 #include "command/common.qh"
21 #include "scores_rules.qh"
22
23 #include "bot/api.qh"
24
25 #include "../common/ent_cs.qh"
26 #include "../common/wepent.qh"
27 #include <common/state.qh>
28
29 #include <common/effects/qc/globalsound.qh>
30
31 #include "../common/triggers/func/conveyor.qh"
32 #include "../common/triggers/teleporters.qh"
33
34 #include "../common/vehicles/all.qh"
35
36 #include "weapons/hitplot.qh"
37 #include "weapons/weaponsystem.qh"
38
39 #include "../common/net_notice.qh"
40 #include "../common/net_linked.qh"
41 #include "../common/physics/player.qh"
42
43 #include "../common/items/_mod.qh"
44
45 #include "../common/mutators/mutator/waypoints/all.qh"
46
47 #include "../common/triggers/subs.qh"
48 #include "../common/triggers/triggers.qh"
49 #include "../common/triggers/trigger/secret.qh"
50
51 #include "../common/minigames/sv_minigames.qh"
52
53 #include "../common/items/inventory.qh"
54
55 #include "../common/monsters/sv_monsters.qh"
56
57 #include "../lib/warpzone/server.qh"
58
59 #include <common/mutators/mutator/overkill/okvortex.qh>
60
61 STATIC_METHOD(Client, Add, void(Client this, int _team))
62 {
63     ClientConnect(this);
64     TRANSMUTE(Player, this);
65     this.frame = 12; // 7
66     this.team = _team;
67     PutClientInServer(this);
68 }
69
70 void PutObserverInServer(entity this);
71
72 STATIC_METHOD(Client, Remove, void(Client this))
73 {
74     TRANSMUTE(Observer, this);
75     PutClientInServer(this);
76     ClientDisconnect(this);
77 }
78
79 void send_CSQC_teamnagger() {
80         WriteHeader(MSG_BROADCAST, TE_CSQC_TEAMNAGGER);
81 }
82
83 int CountSpectators(entity player, entity to)
84 {
85         if(!player) { return 0; } // not sure how, but best to be safe
86
87         int spec_count = 0;
88
89         FOREACH_CLIENT(IS_REAL_CLIENT(it) && IS_SPEC(it) && it != to && it.enemy == player,
90         {
91                 spec_count++;
92         });
93
94         return spec_count;
95 }
96
97 void WriteSpectators(entity player, entity to)
98 {
99         if(!player) { return; } // not sure how, but best to be safe
100
101         FOREACH_CLIENT(IS_REAL_CLIENT(it) && IS_SPEC(it) && it != to && it.enemy == player,
102         {
103                 WriteByte(MSG_ENTITY, num_for_edict(it));
104         });
105 }
106
107 bool ClientData_Send(entity this, entity to, int sf)
108 {
109         assert(to == this.owner, return false);
110
111         entity e = to;
112         if (IS_SPEC(e)) e = e.enemy;
113
114         sf = 0;
115         if (e.race_completed)       sf |= 1; // forced scoreboard
116         if (to.spectatee_status)    sf |= 2; // spectator ent number follows
117         if (e.zoomstate)            sf |= 4; // zoomed
118         if (autocvar_sv_showspectators) sf |= 16; // show spectators
119
120         WriteHeader(MSG_ENTITY, ENT_CLIENT_CLIENTDATA);
121         WriteByte(MSG_ENTITY, sf);
122
123         if (sf & 2)
124         {
125                 WriteByte(MSG_ENTITY, to.spectatee_status);
126         }
127
128         if(sf & 16)
129         {
130                 float specs = CountSpectators(e, to);
131                 WriteByte(MSG_ENTITY, specs);
132                 WriteSpectators(e, to);
133         }
134
135         return true;
136 }
137
138 void ClientData_Attach(entity this)
139 {
140         Net_LinkEntity(this.clientdata = new_pure(clientdata), false, 0, ClientData_Send);
141         this.clientdata.drawonlytoclient = this;
142         this.clientdata.owner = this;
143 }
144
145 void ClientData_Detach(entity this)
146 {
147         delete(this.clientdata);
148         this.clientdata = NULL;
149 }
150
151 void ClientData_Touch(entity e)
152 {
153         e.clientdata.SendFlags = 1;
154
155         // make it spectatable
156         FOREACH_CLIENT(IS_REAL_CLIENT(it) && it != e && IS_SPEC(it) && it.enemy == e, LAMBDA(it.clientdata.SendFlags = 1));
157 }
158
159 .string netname_previous;
160
161 void SetSpectatee(entity this, entity spectatee);
162 void SetSpectatee_status(entity this, int spectatee_num);
163
164
165 /*
166 =============
167 CheckPlayerModel
168
169 Checks if the argument string can be a valid playermodel.
170 Returns a valid one in doubt.
171 =============
172 */
173 string FallbackPlayerModel;
174 string CheckPlayerModel(string plyermodel) {
175         if(FallbackPlayerModel != cvar_defstring("_cl_playermodel"))
176         {
177                 // note: we cannot summon Don Strunzone here, some player may
178                 // still have the model string set. In case anyone manages how
179                 // to change a cvar default, we'll have a small leak here.
180                 FallbackPlayerModel = strzone(cvar_defstring("_cl_playermodel"));
181         }
182         // only in right path
183         if( substring(plyermodel,0,14) != "models/player/")
184                 return FallbackPlayerModel;
185         // only good file extensions
186         if(substring(plyermodel,-4,4) != ".zym")
187         if(substring(plyermodel,-4,4) != ".dpm")
188         if(substring(plyermodel,-4,4) != ".iqm")
189         if(substring(plyermodel,-4,4) != ".md3")
190         if(substring(plyermodel,-4,4) != ".psk")
191                 return FallbackPlayerModel;
192         // forbid the LOD models
193         if(substring(plyermodel, -9,5) == "_lod1")
194                 return FallbackPlayerModel;
195         if(substring(plyermodel, -9,5) == "_lod2")
196                 return FallbackPlayerModel;
197         if(plyermodel != strtolower(plyermodel))
198                 return FallbackPlayerModel;
199         // also, restrict to server models
200         if(autocvar_sv_servermodelsonly)
201         {
202                 if(!fexists(plyermodel))
203                         return FallbackPlayerModel;
204         }
205         return plyermodel;
206 }
207
208 void setplayermodel(entity e, string modelname)
209 {
210         precache_model(modelname);
211         _setmodel(e, modelname);
212         player_setupanimsformodel(e);
213         if(!autocvar_g_debug_globalsounds)
214                 UpdatePlayerSounds(e);
215 }
216
217 void FixPlayermodel(entity player);
218 /** putting a client as observer in the server */
219 void PutObserverInServer(entity this)
220 {
221     bool mutator_returnvalue = MUTATOR_CALLHOOK(MakePlayerObserver, this);
222         PlayerState_detach(this);
223
224         if (IS_PLAYER(this) && this.health >= 1) {
225         // despawn effect
226                 Send_Effect(EFFECT_SPAWN_NEUTRAL, this.origin, '0 0 0', 1);
227     }
228
229     {
230         entity spot = SelectSpawnPoint(this, true);
231         if (!spot) LOG_FATAL("No spawnpoints for observers?!?");
232         this.angles = spot.angles;
233         this.angles_z = 0;
234         this.fixangle = true;
235         // offset it so that the spectator spawns higher off the ground, looks better this way
236         setorigin(this, spot.origin + STAT(PL_VIEW_OFS, this));
237         this.prevorigin = this.origin;
238         if (IS_REAL_CLIENT(this))
239         {
240             msg_entity = this;
241             WriteByte(MSG_ONE, SVC_SETVIEW);
242             WriteEntity(MSG_ONE, this);
243         }
244         // give the spectator some space between walls for MOVETYPE_FLY_WORLDONLY
245         // so that your view doesn't go into the ceiling with MOVETYPE_FLY_WORLDONLY, previously "PL_VIEW_OFS"
246         if(!autocvar_g_debug_globalsounds)
247         {
248                 // needed for player sounds
249                 this.model = "";
250                 FixPlayermodel(this);
251         }
252         setmodel(this, MDL_Null);
253         setsize(this, STAT(PL_CROUCH_MIN, this), STAT(PL_CROUCH_MAX, this));
254         this.view_ofs = '0 0 0';
255     }
256
257     RemoveGrapplingHooks(this);
258         Portal_ClearAll(this);
259         Unfreeze(this);
260         SetSpectatee(this, NULL);
261
262         if (this.alivetime)
263         {
264                 if (!warmup_stage)
265                         PS_GR_P_ADDVAL(this, PLAYERSTATS_ALIVETIME, time - this.alivetime);
266                 this.alivetime = 0;
267         }
268
269         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
270
271         WaypointSprite_PlayerDead(this);
272
273         if (mutator_returnvalue) {
274             // mutator prevents resetting teams+score
275         } else {
276                 this.team = -1;  // move this as it is needed to log the player spectating in eventlog
277         this.frags = FRAGS_SPECTATOR;
278         PlayerScore_Clear(this);  // clear scores when needed
279     }
280
281         if (this.killcount != FRAGS_SPECTATOR)
282         {
283                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_QUIT_SPECTATE, this.netname);
284                 if(!game_stopped)
285                 if(autocvar_g_chat_nospectators == 1 || (!warmup_stage && autocvar_g_chat_nospectators == 2))
286                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_CHAT_NOSPECTATORS);
287
288                 if(this.just_joined == false) {
289                         LogTeamchange(this.playerid, -1, 4);
290                 } else
291                         this.just_joined = false;
292         }
293
294         accuracy_resend(this);
295
296         this.spectatortime = time;
297         if(this.bot_attack)
298                 IL_REMOVE(g_bot_targets, this);
299         this.bot_attack = false;
300     this.hud = HUD_NORMAL;
301         TRANSMUTE(Observer, this);
302         this.iscreature = false;
303         this.teleportable = TELEPORT_SIMPLE;
304         if(this.damagedbycontents)
305                 IL_REMOVE(g_damagedbycontents, this);
306         this.damagedbycontents = false;
307         this.health = FRAGS_SPECTATOR;
308         SetSpectatee_status(this, etof(this));
309         this.takedamage = DAMAGE_NO;
310         this.solid = SOLID_NOT;
311         set_movetype(this, MOVETYPE_FLY_WORLDONLY); // user preference is controlled by playerprethink
312         this.flags = FL_CLIENT | FL_NOTARGET;
313         this.armorvalue = 666;
314         this.effects = 0;
315         this.armorvalue = autocvar_g_balance_armor_start;
316         this.pauserotarmor_finished = 0;
317         this.pauserothealth_finished = 0;
318         this.pauseregen_finished = 0;
319         this.damageforcescale = 0;
320         this.death_time = 0;
321         this.respawn_flags = 0;
322         this.respawn_time = 0;
323         this.stat_respawn_time = 0;
324         this.alpha = 0;
325         this.scale = 0;
326         this.fade_time = 0;
327         this.pain_frame = 0;
328         this.pain_finished = 0;
329         this.strength_finished = 0;
330         this.invincible_finished = 0;
331         this.superweapons_finished = 0;
332         this.pushltime = 0;
333         this.istypefrag = 0;
334         setthink(this, func_null);
335         this.nextthink = 0;
336         this.deadflag = DEAD_NO;
337         this.crouch = false;
338         this.revive_progress = 0;
339         this.revival_time = 0;
340
341         this.items = 0;
342         this.weapons = '0 0 0';
343         this.dual_weapons = '0 0 0';
344         this.drawonlytoclient = this;
345
346         this.weaponmodel = "";
347         for (int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
348         {
349                 this.weaponentities[slot] = NULL;
350         }
351         this.exteriorweaponentity = NULL;
352         this.killcount = FRAGS_SPECTATOR;
353         this.velocity = '0 0 0';
354         this.avelocity = '0 0 0';
355         this.punchangle = '0 0 0';
356         this.punchvector = '0 0 0';
357         this.oldvelocity = this.velocity;
358         this.fire_endtime = -1;
359         this.event_damage = func_null;
360
361         for(int slot = 0; slot < MAX_AXH; ++slot)
362         {
363                 entity axh = this.(AuxiliaryXhair[slot]);
364                 this.(AuxiliaryXhair[slot]) = NULL;
365
366                 if(axh.owner == this && axh != NULL && !wasfreed(axh))
367                         delete(axh);
368         }
369 }
370
371 int player_getspecies(entity this)
372 {
373         get_model_parameters(this.model, this.skin);
374         int s = get_model_parameters_species;
375         get_model_parameters(string_null, 0);
376         if (s < 0) return SPECIES_HUMAN;
377         return s;
378 }
379
380 .float model_randomizer;
381 void FixPlayermodel(entity player)
382 {
383         string defaultmodel = "";
384         int defaultskin = 0;
385         if(autocvar_sv_defaultcharacter)
386         {
387                 if(teamplay)
388                 {
389                         switch(player.team)
390                         {
391                                 case NUM_TEAM_1: defaultmodel = autocvar_sv_defaultplayermodel_red; defaultskin = autocvar_sv_defaultplayerskin_red; break;
392                                 case NUM_TEAM_2: defaultmodel = autocvar_sv_defaultplayermodel_blue; defaultskin = autocvar_sv_defaultplayerskin_blue; break;
393                                 case NUM_TEAM_3: defaultmodel = autocvar_sv_defaultplayermodel_yellow; defaultskin = autocvar_sv_defaultplayerskin_yellow; break;
394                                 case NUM_TEAM_4: defaultmodel = autocvar_sv_defaultplayermodel_pink; defaultskin = autocvar_sv_defaultplayerskin_pink; break;
395                         }
396                 }
397
398                 if(defaultmodel == "")
399                 {
400                         defaultmodel = autocvar_sv_defaultplayermodel;
401                         defaultskin = autocvar_sv_defaultplayerskin;
402                 }
403
404                 int n = tokenize_console(defaultmodel);
405                 if(n > 0)
406                 {
407                         defaultmodel = argv(floor(n * player.model_randomizer));
408                         // However, do NOT randomize if the player-selected model is in the list.
409                         for (int i = 0; i < n; ++i)
410                                 if ((argv(i) == player.playermodel && defaultskin == stof(player.playerskin)) || argv(i) == strcat(player.playermodel, ":", player.playerskin))
411                                         defaultmodel = argv(i);
412                 }
413
414                 int i = strstrofs(defaultmodel, ":", 0);
415                 if(i >= 0)
416                 {
417                         defaultskin = stof(substring(defaultmodel, i+1, -1));
418                         defaultmodel = substring(defaultmodel, 0, i);
419                 }
420         }
421         if(autocvar_sv_defaultcharacterskin && !defaultskin)
422         {
423                 if(teamplay)
424                 {
425                         switch(player.team)
426                         {
427                                 case NUM_TEAM_1: defaultskin = autocvar_sv_defaultplayerskin_red; break;
428                                 case NUM_TEAM_2: defaultskin = autocvar_sv_defaultplayerskin_blue; break;
429                                 case NUM_TEAM_3: defaultskin = autocvar_sv_defaultplayerskin_yellow; break;
430                                 case NUM_TEAM_4: defaultskin = autocvar_sv_defaultplayerskin_pink; break;
431                         }
432                 }
433
434                 if(!defaultskin)
435                         defaultskin = autocvar_sv_defaultplayerskin;
436         }
437
438         MUTATOR_CALLHOOK(FixPlayermodel, defaultmodel, defaultskin, player);
439         defaultmodel = M_ARGV(0, string);
440         defaultskin = M_ARGV(1, int);
441
442         bool chmdl = false;
443         int oldskin;
444         if(defaultmodel != "")
445         {
446                 if (defaultmodel != player.model)
447                 {
448                         vector m1 = player.mins;
449                         vector m2 = player.maxs;
450                         setplayermodel (player, defaultmodel);
451                         setsize (player, m1, m2);
452                         chmdl = true;
453                 }
454
455                 oldskin = player.skin;
456                 player.skin = defaultskin;
457         } else {
458                 if (player.playermodel != player.model || player.playermodel == "")
459                 {
460                         player.playermodel = CheckPlayerModel(player.playermodel); // this is never "", so no endless loop
461                         vector m1 = player.mins;
462                         vector m2 = player.maxs;
463                         setplayermodel (player, player.playermodel);
464                         setsize (player, m1, m2);
465                         chmdl = true;
466                 }
467
468                 if(!autocvar_sv_defaultcharacterskin)
469                 {
470                         oldskin = player.skin;
471                         player.skin = stof(player.playerskin);
472                 }
473                 else
474                 {
475                         oldskin = player.skin;
476                         player.skin = defaultskin;
477                 }
478         }
479
480         if(chmdl || oldskin != player.skin) // model or skin has changed
481         {
482                 player.species = player_getspecies(player); // update species
483                 if(!autocvar_g_debug_globalsounds)
484                         UpdatePlayerSounds(player); // update skin sounds
485         }
486
487         if(!teamplay)
488                 if(strlen(autocvar_sv_defaultplayercolors))
489                         if(player.clientcolors != stof(autocvar_sv_defaultplayercolors))
490                                 setcolor(player, stof(autocvar_sv_defaultplayercolors));
491 }
492
493
494 /** Called when a client spawns in the server */
495 void PutClientInServer(entity this)
496 {
497         if (IS_BOT_CLIENT(this)) {
498                 TRANSMUTE(Player, this);
499         } else if (IS_REAL_CLIENT(this)) {
500                 msg_entity = this;
501                 WriteByte(MSG_ONE, SVC_SETVIEW);
502                 WriteEntity(MSG_ONE, this);
503         }
504         if (game_stopped)
505                 TRANSMUTE(Observer, this);
506
507         SetSpectatee(this, NULL);
508
509         // reset player keys
510         this.itemkeys = 0;
511
512         MUTATOR_CALLHOOK(PutClientInServer, this);
513
514         if (IS_OBSERVER(this)) {
515                 PutObserverInServer(this);
516         } else if (IS_PLAYER(this)) {
517                 if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
518
519                 PlayerState_attach(this);
520                 accuracy_resend(this);
521
522                 if (this.team < 0)
523                         JoinBestTeam(this, false, true);
524
525                 entity spot = SelectSpawnPoint(this, false);
526                 if (!spot) {
527                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_JOIN_NOSPAWNS);
528                         return; // spawn failed
529                 }
530
531                 TRANSMUTE(Player, this);
532
533                 this.wasplayer = true;
534                 this.iscreature = true;
535                 this.teleportable = TELEPORT_NORMAL;
536                 if(!this.damagedbycontents)
537                         IL_PUSH(g_damagedbycontents, this);
538                 this.damagedbycontents = true;
539                 set_movetype(this, MOVETYPE_WALK);
540                 this.solid = SOLID_SLIDEBOX;
541                 this.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_SOLID;
542                 if (autocvar_g_playerclip_collisions)
543                         this.dphitcontentsmask |= DPCONTENTS_PLAYERCLIP;
544                 if (IS_BOT_CLIENT(this) && autocvar_g_botclip_collisions)
545                         this.dphitcontentsmask |= DPCONTENTS_BOTCLIP;
546                 this.frags = FRAGS_PLAYER;
547                 if (INDEPENDENT_PLAYERS) MAKE_INDEPENDENT_PLAYER(this);
548                 this.flags = FL_CLIENT | FL_PICKUPITEMS;
549                 if (autocvar__notarget)
550                         this.flags |= FL_NOTARGET;
551                 this.takedamage = DAMAGE_AIM;
552                 this.effects = EF_TELEPORT_BIT | EF_RESTARTANIM_BIT;
553                 this.dmg = 2; // WTF
554
555                 if (warmup_stage) {
556                         this.ammo_shells = warmup_start_ammo_shells;
557                         this.ammo_nails = warmup_start_ammo_nails;
558                         this.ammo_rockets = warmup_start_ammo_rockets;
559                         this.ammo_cells = warmup_start_ammo_cells;
560                         this.ammo_plasma = warmup_start_ammo_plasma;
561                         this.ammo_fuel = warmup_start_ammo_fuel;
562                         this.health = warmup_start_health;
563                         this.armorvalue = warmup_start_armorvalue;
564                         this.weapons = WARMUP_START_WEAPONS;
565                 } else {
566                         this.ammo_shells = start_ammo_shells;
567                         this.ammo_nails = start_ammo_nails;
568                         this.ammo_rockets = start_ammo_rockets;
569                         this.ammo_cells = start_ammo_cells;
570                         this.ammo_plasma = start_ammo_plasma;
571                         this.ammo_fuel = start_ammo_fuel;
572                         this.health = start_health;
573                         this.armorvalue = start_armorvalue;
574                         this.weapons = start_weapons;
575                 }
576                 SetSpectatee_status(this, 0);
577
578                 this.dual_weapons = '0 0 0';
579
580                 this.superweapons_finished = (this.weapons & WEPSET_SUPERWEAPONS) ? time + autocvar_g_balance_superweapons_time : 0;
581
582                 this.items = start_items;
583
584                 this.spawnshieldtime = time + autocvar_g_spawnshieldtime;
585                 this.pauserotarmor_finished = time + autocvar_g_balance_pause_armor_rot_spawn;
586                 this.pauserothealth_finished = time + autocvar_g_balance_pause_health_rot_spawn;
587                 this.pauserotfuel_finished = time + autocvar_g_balance_pause_fuel_rot_spawn;
588                 this.pauseregen_finished = time + autocvar_g_balance_pause_health_regen_spawn;
589                 // extend the pause of rotting if client was reset at the beginning of the countdown
590                 if (!autocvar_sv_ready_restart_after_countdown && time < game_starttime) { // TODO why is this cvar NOTted?
591                         float f = game_starttime - time;
592                         this.spawnshieldtime += f;
593                         this.pauserotarmor_finished += f;
594                         this.pauserothealth_finished += f;
595                         this.pauseregen_finished += f;
596                 }
597                 this.damageforcescale = 2;
598                 this.death_time = 0;
599                 this.respawn_flags = 0;
600                 this.respawn_time = 0;
601                 this.stat_respawn_time = 0;
602                 this.scale = autocvar_sv_player_scale;
603                 this.fade_time = 0;
604                 this.pain_frame = 0;
605                 this.pain_finished = 0;
606                 this.pushltime = 0;
607                 setthink(this, func_null); // players have no think function
608                 this.nextthink = 0;
609                 this.dmg_team = 0;
610                 this.ballistics_density = autocvar_g_ballistics_density_player;
611
612                 this.deadflag = DEAD_NO;
613
614                 this.angles = spot.angles;
615                 this.angles_z = 0; // never spawn tilted even if the spot says to
616                 if (IS_BOT_CLIENT(this))
617                         this.v_angle = this.angles;
618                 this.fixangle = true; // turn this way immediately
619                 this.oldvelocity = this.velocity = '0 0 0';
620                 this.avelocity = '0 0 0';
621                 this.punchangle = '0 0 0';
622                 this.punchvector = '0 0 0';
623
624                 this.strength_finished = 0;
625                 this.invincible_finished = 0;
626                 this.fire_endtime = -1;
627                 this.revive_progress = 0;
628                 this.revival_time = 0;
629                 this.air_finished = time + 12;
630
631                 entity spawnevent = new_pure(spawnevent);
632                 spawnevent.owner = this;
633                 Net_LinkEntity(spawnevent, false, 0.5, SpawnEvent_Send);
634
635                 // Cut off any still running player sounds.
636                 stopsound(this, CH_PLAYER_SINGLE);
637
638                 this.model = "";
639                 FixPlayermodel(this);
640                 this.drawonlytoclient = NULL;
641
642                 this.viewloc = NULL;
643
644                 this.crouch = false;
645                 this.view_ofs = STAT(PL_VIEW_OFS, this);
646                 setsize(this, STAT(PL_MIN, this), STAT(PL_MAX, this));
647                 this.spawnorigin = spot.origin;
648                 setorigin(this, spot.origin + '0 0 1' * (1 - this.mins.z - 24));
649                 // don't reset back to last position, even if new position is stuck in solid
650                 this.oldorigin = this.origin;
651                 this.prevorigin = this.origin;
652                 this.lastteleporttime = time; // prevent insane speeds due to changing origin
653                 if(this.conveyor)
654                         IL_REMOVE(g_conveyed, this);
655                 this.conveyor = NULL; // prevent conveyors at the previous location from moving a freshly spawned player
656                 this.hud = HUD_NORMAL;
657
658                 this.event_damage = PlayerDamage;
659
660                 if(!this.bot_attack)
661                         IL_PUSH(g_bot_targets, this);
662                 this.bot_attack = true;
663                 this.monster_attack = true;
664                 navigation_dynamicgoal_init(this, false);
665
666                 PHYS_INPUT_BUTTON_ATCK(this) = PHYS_INPUT_BUTTON_JUMP(this) = PHYS_INPUT_BUTTON_ATCK2(this) = false;
667
668                 if (this.killcount == FRAGS_SPECTATOR) {
669                         PlayerScore_Clear(this);
670                         this.killcount = 0;
671                 }
672
673                 for (int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
674                 {
675                         .entity weaponentity = weaponentities[slot];
676                         entity oldwep = this.(weaponentity);
677                         CL_SpawnWeaponentity(this, weaponentity);
678                         if(oldwep && oldwep.owner == this)
679                                 this.(weaponentity).m_gunalign = oldwep.m_gunalign;
680                 }
681                 this.alpha = default_player_alpha;
682                 this.colormod = '1 1 1' * autocvar_g_player_brightness;
683                 this.exteriorweaponentity.alpha = default_weapon_alpha;
684
685                 this.speedrunning = false;
686
687                 target_voicescript_clear(this);
688
689                 // reset fields the weapons may use
690                 FOREACH(Weapons, true, LAMBDA(
691                         it.wr_resetplayer(it, this);
692                         // reload all reloadable weapons
693                         if (it.spawnflags & WEP_FLAG_RELOADABLE) {
694                                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
695                                 {
696                                         .entity weaponentity = weaponentities[slot];
697                                         this.(weaponentity).weapon_load[it.m_id] = it.reloading_ammo;
698                                 }
699                         }
700                 ));
701
702                 {
703                         string s = spot.target;
704                         spot.target = string_null;
705                         SUB_UseTargets(spot, this, NULL);
706                         spot.target = s;
707                 }
708
709                 Unfreeze(this);
710
711                 MUTATOR_CALLHOOK(PlayerSpawn, this, spot);
712
713                 if (autocvar_spawn_debug)
714                 {
715                         sprint(this, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
716                         delete(spot); // usefull for checking if there are spawnpoints, that let drop through the floor
717                 }
718
719                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
720                 {
721                         .entity weaponentity = weaponentities[slot];
722                         if(slot == 0 || autocvar_g_weaponswitch_debug == 1)
723                                 this.(weaponentity).m_switchweapon = w_getbestweapon(this, weaponentity);
724                         else
725                                 this.(weaponentity).m_switchweapon = WEP_Null;
726                         this.(weaponentity).m_weapon = WEP_Null;
727                         this.(weaponentity).weaponname = "";
728                         this.(weaponentity).m_switchingweapon = WEP_Null;
729                         this.(weaponentity).cnt = -1;
730                 }
731
732                 MUTATOR_CALLHOOK(PlayerWeaponSelect, this);
733
734                 if (!warmup_stage && !this.alivetime)
735                         this.alivetime = time;
736
737                 antilag_clear(this, CS(this));
738         }
739 }
740
741 void ClientInit_misc(entity this);
742
743 // TODO do we need all these fields, or should we stop autodetecting runtime
744 // changes and just have a console command to update this?
745 bool ClientInit_SendEntity(entity this, entity to, int sf)
746 {
747         WriteHeader(MSG_ENTITY, _ENT_CLIENT_INIT);
748         return = true;
749         msg_entity = to;
750         // MSG_INIT replacement
751         // TODO: make easier to use
752         Registry_send_all();
753         W_PROP_reload(MSG_ONE, to);
754         ClientInit_misc(this);
755         MUTATOR_CALLHOOK(Ent_Init);
756 }
757 void ClientInit_misc(entity this)
758 {
759         int channel = MSG_ONE;
760         WriteHeader(channel, ENT_CLIENT_INIT);
761         WriteByte(channel, g_nexball_meter_period * 32);
762         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[0]));
763         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[1]));
764         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[2]));
765         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[3]));
766         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[0]));
767         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[1]));
768         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[2]));
769         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[3]));
770
771         if(sv_foginterval && world.fog != "")
772                 WriteString(channel, world.fog);
773         else
774                 WriteString(channel, "");
775         WriteByte(channel, this.count * 255.0); // g_balance_armor_blockpercent
776         WriteByte(channel, serverflags);
777         WriteCoord(channel, autocvar_g_trueaim_minrange);
778 }
779
780 void ClientInit_CheckUpdate(entity this)
781 {
782         this.nextthink = time;
783         if(this.count != autocvar_g_balance_armor_blockpercent)
784         {
785                 this.count = autocvar_g_balance_armor_blockpercent;
786                 this.SendFlags |= 1;
787         }
788 }
789
790 void ClientInit_Spawn()
791 {
792         entity e = new_pure(clientinit);
793         setthink(e, ClientInit_CheckUpdate);
794         Net_LinkEntity(e, false, 0, ClientInit_SendEntity);
795
796         ClientInit_CheckUpdate(e);
797 }
798
799 /*
800 =============
801 SetNewParms
802 =============
803 */
804 void SetNewParms ()
805 {
806         // initialize parms for a new player
807         parm1 = -(86400 * 366);
808
809         MUTATOR_CALLHOOK(SetNewParms);
810 }
811
812 /*
813 =============
814 SetChangeParms
815 =============
816 */
817 void SetChangeParms (entity this)
818 {
819         // save parms for level change
820         parm1 = this.parm_idlesince - time;
821
822         MUTATOR_CALLHOOK(SetChangeParms);
823 }
824
825 /*
826 =============
827 DecodeLevelParms
828 =============
829 */
830 void DecodeLevelParms(entity this)
831 {
832         // load parms
833         this.parm_idlesince = parm1;
834         if (this.parm_idlesince == -(86400 * 366))
835                 this.parm_idlesince = time;
836
837         // whatever happens, allow 60 seconds of idling directly after connect for map loading
838         this.parm_idlesince = max(this.parm_idlesince, time - sv_maxidle + 60);
839
840         MUTATOR_CALLHOOK(DecodeLevelParms);
841 }
842
843 /*
844 =============
845 ClientKill
846
847 Called when a client types 'kill' in the console
848 =============
849 */
850
851 .float clientkill_nexttime;
852 void ClientKill_Now_TeamChange(entity this)
853 {
854         if(this.killindicator_teamchange == -1)
855         {
856                 JoinBestTeam( this, false, true );
857         }
858         else if(this.killindicator_teamchange == -2)
859         {
860                 if(blockSpectators)
861                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
862                 PutObserverInServer(this);
863         }
864         else
865                 SV_ChangeTeam(this, this.killindicator_teamchange - 1);
866         this.killindicator_teamchange = 0;
867 }
868
869 void ClientKill_Now(entity this)
870 {
871         if(this.vehicle)
872         {
873             vehicles_exit(this.vehicle, VHEF_RELEASE);
874             if(!this.killindicator_teamchange)
875             {
876             this.vehicle_health = -1;
877             Damage(this, this, this, 1 , DEATH_KILL.m_id, this.origin, '0 0 0');
878             }
879         }
880
881         if(this.killindicator && !wasfreed(this.killindicator))
882                 delete(this.killindicator);
883
884         this.killindicator = NULL;
885
886         if(this.killindicator_teamchange)
887                 ClientKill_Now_TeamChange(this);
888
889         if(!IS_SPEC(this) && !IS_OBSERVER(this))
890                 Damage(this, this, this, 100000, DEATH_KILL.m_id, this.origin, '0 0 0');
891
892         // now I am sure the player IS dead
893 }
894 void KillIndicator_Think(entity this)
895 {
896         if (game_stopped)
897         {
898                 this.owner.killindicator = NULL;
899                 delete(this);
900                 return;
901         }
902
903         if (this.owner.alpha < 0 && !this.owner.vehicle)
904         {
905                 this.owner.killindicator = NULL;
906                 delete(this);
907                 return;
908         }
909
910         if(this.cnt <= 0)
911         {
912                 ClientKill_Now(this.owner);
913                 return;
914         }
915     else if(this.health == 1) // health == 1 means that it's silent
916     {
917         this.nextthink = time + 1;
918         this.cnt -= 1;
919     }
920         else
921         {
922                 if(this.cnt <= 10)
923                         setmodel(this, MDL_NUM(this.cnt));
924                 if(IS_REAL_CLIENT(this.owner))
925                 {
926                         if(this.cnt <= 10)
927                                 { Send_Notification(NOTIF_ONE, this.owner, MSG_ANNCE, Announcer_PickNumber(CNT_KILL, this.cnt)); }
928                 }
929                 this.nextthink = time + 1;
930                 this.cnt -= 1;
931         }
932 }
933
934 float clientkilltime;
935 void ClientKill_TeamChange (entity this, float targetteam) // 0 = don't change, -1 = auto, -2 = spec
936 {
937         float killtime;
938         float starttime;
939
940         if (game_stopped)
941                 return;
942
943         killtime = autocvar_g_balance_kill_delay;
944
945     if(MUTATOR_CALLHOOK(ClientKill, this, killtime))
946         return;
947     killtime = M_ARGV(1, float);
948
949         this.killindicator_teamchange = targetteam;
950
951     if(!this.killindicator)
952         {
953                 if(!IS_DEAD(this))
954                 {
955                         killtime = max(killtime, this.clientkill_nexttime - time);
956                         this.clientkill_nexttime = time + killtime + autocvar_g_balance_kill_antispam;
957                 }
958
959                 if(killtime <= 0 || !IS_PLAYER(this) || IS_DEAD(this))
960                 {
961                         ClientKill_Now(this);
962                 }
963                 else
964                 {
965                         starttime = max(time, clientkilltime);
966
967                         this.killindicator = spawn();
968                         this.killindicator.owner = this;
969                         this.killindicator.scale = 0.5;
970                         setattachment(this.killindicator, this, "");
971                         setorigin(this.killindicator, '0 0 52');
972                         setthink(this.killindicator, KillIndicator_Think);
973                         this.killindicator.nextthink = starttime + (this.lip) * 0.05;
974                         clientkilltime = max(clientkilltime, this.killindicator.nextthink + 0.05);
975                         this.killindicator.cnt = ceil(killtime);
976                         this.killindicator.count = bound(0, ceil(killtime), 10);
977                         //sprint(this, strcat("^1You'll be dead in ", ftos(this.killindicator.cnt), " seconds\n"));
978
979                         IL_EACH(g_clones, it.enemy == this && !(it.effects & CSQCMODEL_EF_RESPAWNGHOST),
980                         {
981                                 it.killindicator = spawn();
982                                 it.killindicator.owner = it;
983                                 it.killindicator.scale = 0.5;
984                                 setattachment(it.killindicator, it, "");
985                                 setorigin(it.killindicator, '0 0 52');
986                                 setthink(it.killindicator, KillIndicator_Think);
987                                 it.killindicator.nextthink = starttime + (it.lip) * 0.05;
988                                 //clientkilltime = max(clientkilltime, it.killindicator.nextthink + 0.05);
989                                 it.killindicator.cnt = ceil(killtime);
990                         });
991                         this.lip = 0;
992                 }
993         }
994         if(this.killindicator)
995         {
996                 if(targetteam == 0) // just die
997                 {
998                         this.killindicator.colormod = '0 0 0';
999                         if(IS_REAL_CLIENT(this))
1000                         if(this.killindicator.cnt > 0)
1001                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_TEAMCHANGE_SUICIDE, this.killindicator.cnt);
1002                 }
1003                 else if(targetteam == -1) // auto
1004                 {
1005                         this.killindicator.colormod = '0 1 0';
1006                         if(IS_REAL_CLIENT(this))
1007                         if(this.killindicator.cnt > 0)
1008                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_TEAMCHANGE_AUTO, this.killindicator.cnt);
1009                 }
1010                 else if(targetteam == -2) // spectate
1011                 {
1012                         this.killindicator.colormod = '0.5 0.5 0.5';
1013                         if(IS_REAL_CLIENT(this))
1014                         if(this.killindicator.cnt > 0)
1015                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_TEAMCHANGE_SPECTATE, this.killindicator.cnt);
1016                 }
1017                 else
1018                 {
1019                         this.killindicator.colormod = Team_ColorRGB(targetteam);
1020                         if(IS_REAL_CLIENT(this))
1021                         if(this.killindicator.cnt > 0)
1022                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, APP_TEAM_NUM(targetteam, CENTER_TEAMCHANGE), this.killindicator.cnt);
1023                 }
1024         }
1025
1026 }
1027
1028 void ClientKill (entity this)
1029 {
1030         if(game_stopped) return;
1031         if(this.player_blocked) return;
1032         if(STAT(FROZEN, this)) return;
1033
1034         ClientKill_TeamChange(this, 0);
1035 }
1036
1037 void FixClientCvars(entity e)
1038 {
1039         // send prediction settings to the client
1040         stuffcmd(e, "\nin_bindmap 0 0\n");
1041         if(autocvar_g_antilag == 3) // client side hitscan
1042                 stuffcmd(e, "cl_cmd settemp cl_prydoncursor_notrace 0\n");
1043         if(autocvar_sv_gentle)
1044                 stuffcmd(e, "cl_cmd settemp cl_gentle 1\n");
1045
1046         stuffcmd(e, sprintf("\ncl_jumpspeedcap_min \"%s\"\n", autocvar_sv_jumpspeedcap_min));
1047         stuffcmd(e, sprintf("\ncl_jumpspeedcap_max \"%s\"\n", autocvar_sv_jumpspeedcap_max));
1048
1049         MUTATOR_CALLHOOK(FixClientCvars, e);
1050 }
1051
1052 float PlayerInIDList(entity p, string idlist)
1053 {
1054         float n, i;
1055         string s;
1056
1057         // NOTE: we do NOT check crypto_idfp_signed here, an unsigned ID is fine too for this
1058         if (!p.crypto_idfp)
1059                 return 0;
1060
1061         // this function allows abbreviated player IDs too!
1062         n = tokenize_console(idlist);
1063         for(i = 0; i < n; ++i)
1064         {
1065                 s = argv(i);
1066                 if(s == substring(p.crypto_idfp, 0, strlen(s)))
1067                         return 1;
1068         }
1069
1070         return 0;
1071 }
1072
1073 #ifdef DP_EXT_PRECONNECT
1074 /*
1075 =============
1076 ClientPreConnect
1077
1078 Called once (not at each match start) when a client begins a connection to the server
1079 =============
1080 */
1081 void ClientPreConnect(entity this)
1082 {
1083         if(autocvar_sv_eventlog)
1084         {
1085                 GameLogEcho(sprintf(":connect:%d:%d:%s",
1086                         this.playerid,
1087                         etof(this),
1088                         ((IS_REAL_CLIENT(this)) ? this.netaddress : "bot")
1089                 ));
1090         }
1091 }
1092 #endif
1093
1094 /**
1095 =============
1096 ClientConnect
1097
1098 Called when a client connects to the server
1099 =============
1100 */
1101 void ClientConnect(entity this)
1102 {
1103         if (Ban_MaybeEnforceBanOnce(this)) return;
1104         assert(!IS_CLIENT(this), return);
1105         this.flags |= FL_CLIENT;
1106         assert(player_count >= 0, player_count = 0);
1107
1108 #ifdef WATERMARK
1109         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_WATERMARK, WATERMARK);
1110 #endif
1111         this.version_nagtime = time + 10 + random() * 10;
1112         TRANSMUTE(Client, this);
1113
1114         // identify the right forced team
1115         if (autocvar_g_campaign)
1116         {
1117                 if (IS_REAL_CLIENT(this)) // only players, not bots
1118                 {
1119                         switch (autocvar_g_campaign_forceteam)
1120                         {
1121                                 case 1: this.team_forced = NUM_TEAM_1; break;
1122                                 case 2: this.team_forced = NUM_TEAM_2; break;
1123                                 case 3: this.team_forced = NUM_TEAM_3; break;
1124                                 case 4: this.team_forced = NUM_TEAM_4; break;
1125                                 default: this.team_forced = 0;
1126                         }
1127                 }
1128         }
1129         else if (PlayerInIDList(this, autocvar_g_forced_team_red))    this.team_forced = NUM_TEAM_1;
1130         else if (PlayerInIDList(this, autocvar_g_forced_team_blue))   this.team_forced = NUM_TEAM_2;
1131         else if (PlayerInIDList(this, autocvar_g_forced_team_yellow)) this.team_forced = NUM_TEAM_3;
1132         else if (PlayerInIDList(this, autocvar_g_forced_team_pink))   this.team_forced = NUM_TEAM_4;
1133         else switch (autocvar_g_forced_team_otherwise)
1134         {
1135                 default: this.team_forced = 0; break;
1136                 case "red": this.team_forced = NUM_TEAM_1; break;
1137                 case "blue": this.team_forced = NUM_TEAM_2; break;
1138                 case "yellow": this.team_forced = NUM_TEAM_3; break;
1139                 case "pink": this.team_forced = NUM_TEAM_4; break;
1140                 case "spectate":
1141                 case "spectator":
1142                         this.team_forced = -1;
1143                         break;
1144         }
1145         if (!teamplay && this.team_forced > 0) this.team_forced = 0;
1146
1147     {
1148         int id = this.playerid;
1149         this.playerid = 0; // silent
1150             JoinBestTeam(this, false, false); // if the team number is valid, keep it
1151             this.playerid = id;
1152     }
1153
1154         if (autocvar_sv_spectate || autocvar_g_campaign || this.team_forced < 0) {
1155                 TRANSMUTE(Observer, this);
1156         } else {
1157                 if (!teamplay || autocvar_g_balance_teams) {
1158                         TRANSMUTE(Player, this);
1159                         campaign_bots_may_start = true;
1160                 } else {
1161                         TRANSMUTE(Observer, this); // do it anyway
1162                 }
1163         }
1164
1165         PlayerStats_GameReport_AddEvent(sprintf("kills-%d", this.playerid));
1166
1167         // always track bots, don't ask for cl_allow_uidtracking
1168     if (IS_BOT_CLIENT(this)) PlayerStats_GameReport_AddPlayer(this);
1169
1170         if (autocvar_sv_eventlog)
1171                 GameLogEcho(strcat(":join:", ftos(this.playerid), ":", ftos(etof(this)), ":", ((IS_REAL_CLIENT(this)) ? this.netaddress : "bot"), ":", playername(this, false)));
1172
1173         LogTeamchange(this.playerid, this.team, 1);
1174
1175         this.just_joined = true;  // stop spamming the eventlog with additional lines when the client connects
1176
1177         this.netname_previous = strzone(this.netname);
1178
1179         if(teamplay && IS_PLAYER(this))
1180                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, APP_TEAM_NUM(this.team, INFO_JOIN_CONNECT_TEAM), this.netname);
1181         else
1182                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_JOIN_CONNECT, this.netname);
1183
1184         stuffcmd(this, clientstuff, "\n");
1185         stuffcmd(this, "cl_particles_reloadeffects\n"); // TODO do we still need this?
1186
1187         FixClientCvars(this);
1188
1189         // get version info from player
1190         stuffcmd(this, "cmd clientversion $gameversion\n");
1191
1192         // notify about available teams
1193         if (teamplay)
1194         {
1195                 CheckAllowedTeams(this);
1196                 int t = 0;
1197                 if (c1 >= 0) t |= BIT(0);
1198                 if (c2 >= 0) t |= BIT(1);
1199                 if (c3 >= 0) t |= BIT(2);
1200                 if (c4 >= 0) t |= BIT(3);
1201                 stuffcmd(this, sprintf("set _teams_available %d\n", t));
1202         }
1203         else
1204         {
1205                 stuffcmd(this, "set _teams_available 0\n");
1206         }
1207
1208         bot_relinkplayerlist();
1209
1210         this.spectatortime = time;
1211         if (blockSpectators)
1212         {
1213                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
1214         }
1215
1216         this.jointime = time;
1217         this.allowed_timeouts = autocvar_sv_timeout_number;
1218
1219         if (IS_REAL_CLIENT(this))
1220         {
1221                 if (g_weaponarena_weapons == WEPSET(TUBA))
1222                         stuffcmd(this, "cl_cmd settemp chase_active 1\n");
1223         }
1224
1225         if (!sv_foginterval && world.fog != "")
1226                 stuffcmd(this, strcat("\nfog ", world.fog, "\nr_fog_exp2 0\nr_drawfog 1\n"));
1227
1228         if (autocvar_sv_teamnagger && !(autocvar_bot_vs_human && AvailableTeams() == 2))
1229                 if(!MUTATOR_CALLHOOK(HideTeamNagger, this))
1230                         send_CSQC_teamnagger();
1231
1232         CSQCMODEL_AUTOINIT(this);
1233
1234         this.model_randomizer = random();
1235
1236         if (IS_REAL_CLIENT(this))
1237                 sv_notice_join(this);
1238
1239         // update physics stats (players can spawn before physics runs)
1240         STAT(MOVEVARS_HIGHSPEED, this) = autocvar_g_movement_highspeed;
1241         MUTATOR_CALLHOOK(PlayerPhysics_UpdateStats, this); // do it BEFORE the function so we can modify highspeed!
1242         Physics_UpdateStats(this, PHYS_HIGHSPEED(this));
1243
1244         IL_EACH(g_initforplayer, it.init_for_player, {
1245                 it.init_for_player(it, this);
1246         });
1247
1248         MUTATOR_CALLHOOK(ClientConnect, this);
1249
1250         if (IS_REAL_CLIENT(this))
1251         {
1252                 if (!autocvar_g_campaign && !IS_PLAYER(this))
1253                 {
1254                         this.motd_actived_time = -1;
1255                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOTD, getwelcomemessage(this));
1256                 }
1257         }
1258 }
1259 /*
1260 =============
1261 ClientDisconnect
1262
1263 Called when a client disconnects from the server
1264 =============
1265 */
1266 .entity chatbubbleentity;
1267 void ReadyCount();
1268 void ClientDisconnect(entity this)
1269 {
1270         assert(IS_CLIENT(this), return);
1271
1272         PlayerStats_GameReport_FinalizePlayer(this);
1273         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
1274         if (this.active_minigame) part_minigame(this);
1275         if (IS_PLAYER(this)) Send_Effect(EFFECT_SPAWN_NEUTRAL, this.origin, '0 0 0', 1);
1276
1277         if (autocvar_sv_eventlog)
1278                 GameLogEcho(strcat(":part:", ftos(this.playerid)));
1279
1280         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_QUIT_DISCONNECT, this.netname);
1281
1282         if(IS_SPEC(this))
1283                 SetSpectatee(this, NULL);
1284
1285     MUTATOR_CALLHOOK(ClientDisconnect, this);
1286
1287         ClientState_detach(this);
1288
1289         Portal_ClearAll(this);
1290
1291         Unfreeze(this);
1292
1293         RemoveGrapplingHooks(this);
1294
1295         // Here, everything has been done that requires this player to be a client.
1296
1297         this.flags &= ~FL_CLIENT;
1298
1299         if (this.chatbubbleentity) delete(this.chatbubbleentity);
1300         if (this.killindicator) delete(this.killindicator);
1301
1302         WaypointSprite_PlayerGone(this);
1303
1304         bot_relinkplayerlist();
1305
1306         if (this.netname_previous) strunzone(this.netname_previous);
1307         if (this.clientstatus) strunzone(this.clientstatus);
1308         if (this.weaponorder_byimpulse) strunzone(this.weaponorder_byimpulse);
1309         if (this.personal) delete(this.personal);
1310
1311         this.playerid = 0;
1312         ReadyCount();
1313         if (vote_called && IS_REAL_CLIENT(this)) VoteCount(false);
1314
1315         ONREMOVE(this);
1316 }
1317
1318 void ChatBubbleThink(entity this)
1319 {
1320         this.nextthink = time;
1321         if ((this.owner.alpha < 0) || this.owner.chatbubbleentity != this)
1322         {
1323                 if(this.owner) // but why can that ever be NULL?
1324                         this.owner.chatbubbleentity = NULL;
1325                 delete(this);
1326                 return;
1327         }
1328
1329         this.mdl = "";
1330
1331         if ( !IS_DEAD(this.owner) && IS_PLAYER(this.owner) )
1332         {
1333                 if ( this.owner.active_minigame )
1334                         this.mdl = "models/sprites/minigame_busy.iqm";
1335                 else if (PHYS_INPUT_BUTTON_CHAT(this.owner))
1336                         this.mdl = "models/misc/chatbubble.spr";
1337         }
1338
1339         if ( this.model != this.mdl )
1340                 _setmodel(this, this.mdl);
1341
1342 }
1343
1344 void UpdateChatBubble(entity this)
1345 {
1346         if (this.alpha < 0)
1347                 return;
1348         // spawn a chatbubble entity if needed
1349         if (!this.chatbubbleentity)
1350         {
1351                 this.chatbubbleentity = new(chatbubbleentity);
1352                 this.chatbubbleentity.owner = this;
1353                 this.chatbubbleentity.exteriormodeltoclient = this;
1354                 setthink(this.chatbubbleentity, ChatBubbleThink);
1355                 this.chatbubbleentity.nextthink = time;
1356                 setmodel(this.chatbubbleentity, MDL_CHAT); // precision set below
1357                 //setorigin(this.chatbubbleentity, this.origin + '0 0 15' + this.maxs_z * '0 0 1');
1358                 setorigin(this.chatbubbleentity, '0 0 15' + this.maxs_z * '0 0 1');
1359                 setattachment(this.chatbubbleentity, this, "");  // sticks to moving player better, also conserves bandwidth
1360                 this.chatbubbleentity.mdl = this.chatbubbleentity.model;
1361                 //this.chatbubbleentity.model = "";
1362                 this.chatbubbleentity.effects = EF_LOWPRECISION;
1363         }
1364 }
1365
1366
1367 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
1368 // added to the model skins
1369 /*void UpdateColorModHack()
1370 {
1371         float c;
1372         c = this.clientcolors & 15;
1373         // LordHavoc: only bothering to support white, green, red, yellow, blue
1374              if (!teamplay) this.colormod = '0 0 0';
1375         else if (c ==  0) this.colormod = '1.00 1.00 1.00';
1376         else if (c ==  3) this.colormod = '0.10 1.73 0.10';
1377         else if (c ==  4) this.colormod = '1.73 0.10 0.10';
1378         else if (c == 12) this.colormod = '1.22 1.22 0.10';
1379         else if (c == 13) this.colormod = '0.10 0.10 1.73';
1380         else this.colormod = '1 1 1';
1381 }*/
1382
1383 void respawn(entity this)
1384 {
1385         if(this.alpha >= 0 && autocvar_g_respawn_ghosts)
1386         {
1387                 this.solid = SOLID_NOT;
1388                 this.takedamage = DAMAGE_NO;
1389                 set_movetype(this, MOVETYPE_FLY);
1390                 this.velocity = '0 0 1' * autocvar_g_respawn_ghosts_speed;
1391                 this.avelocity = randomvec() * autocvar_g_respawn_ghosts_speed * 3 - randomvec() * autocvar_g_respawn_ghosts_speed * 3;
1392                 this.effects |= CSQCMODEL_EF_RESPAWNGHOST;
1393                 Send_Effect(EFFECT_RESPAWN_GHOST, this.origin, '0 0 0', 1);
1394                 if(autocvar_g_respawn_ghosts_maxtime)
1395                         SUB_SetFade (this, time + autocvar_g_respawn_ghosts_maxtime / 2 + random () * (autocvar_g_respawn_ghosts_maxtime - autocvar_g_respawn_ghosts_maxtime / 2), 1.5);
1396         }
1397
1398         CopyBody(this, 1);
1399
1400         this.effects |= EF_NODRAW; // prevent another CopyBody
1401         PutClientInServer(this);
1402 }
1403
1404 void play_countdown(entity this, float finished, Sound samp)
1405 {
1406     TC(Sound, samp);
1407         if(IS_REAL_CLIENT(this))
1408                 if(floor(finished - time - frametime) != floor(finished - time))
1409                         if(finished - time < 6)
1410                                 sound (this, CH_INFO, samp, VOL_BASE, ATTEN_NORM);
1411 }
1412
1413 void player_powerups(entity this)
1414 {
1415         // add a way to see what the items were BEFORE all of these checks for the mutator hook
1416         int items_prev = this.items;
1417
1418         if((this.items & IT_USING_JETPACK) && !IS_DEAD(this) && !game_stopped)
1419                 this.modelflags |= MF_ROCKET;
1420         else
1421                 this.modelflags &= ~MF_ROCKET;
1422
1423         this.effects &= ~(EF_RED | EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT | EF_FLAME | EF_NODEPTHTEST);
1424
1425         if((this.alpha < 0 || IS_DEAD(this)) && !this.vehicle) // don't apply the flags if the player is gibbed
1426                 return;
1427
1428         Fire_ApplyDamage(this);
1429         Fire_ApplyEffect(this);
1430
1431         if (!g_instagib)
1432         {
1433                 if (this.items & ITEM_Strength.m_itemid)
1434                 {
1435                         play_countdown(this, this.strength_finished, SND_POWEROFF);
1436                         this.effects = this.effects | (EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT);
1437                         if (time > this.strength_finished)
1438                         {
1439                                 this.items = this.items - (this.items & ITEM_Strength.m_itemid);
1440                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERDOWN_STRENGTH, this.netname);
1441                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERDOWN_STRENGTH);
1442                         }
1443                 }
1444                 else
1445                 {
1446                         if (time < this.strength_finished)
1447                         {
1448                                 this.items = this.items | ITEM_Strength.m_itemid;
1449                                 if(!g_cts)
1450                                         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERUP_STRENGTH, this.netname);
1451                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERUP_STRENGTH);
1452                         }
1453                 }
1454                 if (this.items & ITEM_Shield.m_itemid)
1455                 {
1456                         play_countdown(this, this.invincible_finished, SND_POWEROFF);
1457                         this.effects = this.effects | (EF_RED | EF_ADDITIVE | EF_FULLBRIGHT);
1458                         if (time > this.invincible_finished)
1459                         {
1460                                 this.items = this.items - (this.items & ITEM_Shield.m_itemid);
1461                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERDOWN_SHIELD, this.netname);
1462                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERDOWN_SHIELD);
1463                         }
1464                 }
1465                 else
1466                 {
1467                         if (time < this.invincible_finished)
1468                         {
1469                                 this.items = this.items | ITEM_Shield.m_itemid;
1470                                 if(!g_cts)
1471                                         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERUP_SHIELD, this.netname);
1472                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERUP_SHIELD);
1473                         }
1474                 }
1475                 if (this.items & IT_SUPERWEAPON)
1476                 {
1477                         if (!(this.weapons & WEPSET_SUPERWEAPONS))
1478                         {
1479                                 this.superweapons_finished = 0;
1480                                 this.items = this.items - (this.items & IT_SUPERWEAPON);
1481                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_LOST, this.netname);
1482                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_LOST);
1483                         }
1484                         else if (this.items & IT_UNLIMITED_SUPERWEAPONS)
1485                         {
1486                                 // don't let them run out
1487                         }
1488                         else
1489                         {
1490                                 play_countdown(this, this.superweapons_finished, SND_POWEROFF);
1491                                 if (time > this.superweapons_finished)
1492                                 {
1493                                         this.items = this.items - (this.items & IT_SUPERWEAPON);
1494                                         this.weapons &= ~WEPSET_SUPERWEAPONS;
1495                                         //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_BROKEN, this.netname);
1496                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_BROKEN);
1497                                 }
1498                         }
1499                 }
1500                 else if(this.weapons & WEPSET_SUPERWEAPONS)
1501                 {
1502                         if (time < this.superweapons_finished || (this.items & IT_UNLIMITED_SUPERWEAPONS))
1503                         {
1504                                 this.items = this.items | IT_SUPERWEAPON;
1505                                 if(!g_cts)
1506                                         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_PICKUP, this.netname);
1507                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_PICKUP);
1508                         }
1509                         else
1510                         {
1511                                 this.superweapons_finished = 0;
1512                                 this.weapons &= ~WEPSET_SUPERWEAPONS;
1513                         }
1514                 }
1515                 else
1516                 {
1517                         this.superweapons_finished = 0;
1518                 }
1519         }
1520
1521         if(autocvar_g_nodepthtestplayers)
1522                 this.effects = this.effects | EF_NODEPTHTEST;
1523
1524         if(autocvar_g_fullbrightplayers)
1525                 this.effects = this.effects | EF_FULLBRIGHT;
1526
1527         if (time >= game_starttime)
1528         if (time < this.spawnshieldtime)
1529                 this.effects = this.effects | (EF_ADDITIVE | EF_FULLBRIGHT);
1530
1531         MUTATOR_CALLHOOK(PlayerPowerups, this, items_prev);
1532 }
1533
1534 float CalcRegen(float current, float stable, float regenfactor, float regenframetime)
1535 {
1536         if(current > stable)
1537                 return current;
1538         else if(current > stable - 0.25) // when close enough, "snap"
1539                 return stable;
1540         else
1541                 return min(stable, current + (stable - current) * regenfactor * regenframetime);
1542 }
1543
1544 float CalcRot(float current, float stable, float rotfactor, float rotframetime)
1545 {
1546         if(current < stable)
1547                 return current;
1548         else if(current < stable + 0.25) // when close enough, "snap"
1549                 return stable;
1550         else
1551                 return max(stable, current + (stable - current) * rotfactor * rotframetime);
1552 }
1553
1554 float CalcRotRegen(float current, float regenstable, float regenfactor, float regenlinear, float regenframetime, float rotstable, float rotfactor, float rotlinear, float rotframetime, float limit)
1555 {
1556         if(current > rotstable)
1557         {
1558                 if(rotframetime > 0)
1559                 {
1560                         current = CalcRot(current, rotstable, rotfactor, rotframetime);
1561                         current = max(rotstable, current - rotlinear * rotframetime);
1562                 }
1563         }
1564         else if(current < regenstable)
1565         {
1566                 if(regenframetime > 0)
1567                 {
1568                         current = CalcRegen(current, regenstable, regenfactor, regenframetime);
1569                         current = min(regenstable, current + regenlinear * regenframetime);
1570                 }
1571         }
1572
1573         if(current > limit)
1574                 current = limit;
1575
1576         return current;
1577 }
1578
1579 void player_regen(entity this)
1580 {
1581         float max_mod, regen_mod, rot_mod, limit_mod;
1582         max_mod = regen_mod = rot_mod = limit_mod = 1;
1583
1584         float regen_health = autocvar_g_balance_health_regen;
1585         float regen_health_linear = autocvar_g_balance_health_regenlinear;
1586         float regen_health_rot = autocvar_g_balance_health_rot;
1587         float regen_health_rotlinear = autocvar_g_balance_health_rotlinear;
1588         float regen_health_stable = autocvar_g_balance_health_regenstable;
1589         float regen_health_rotstable = autocvar_g_balance_health_rotstable;
1590         bool mutator_returnvalue = MUTATOR_CALLHOOK(PlayerRegen, this, max_mod, regen_mod, rot_mod, limit_mod, regen_health, regen_health_linear, regen_health_rot,
1591                 regen_health_rotlinear, regen_health_stable, regen_health_rotstable);
1592         max_mod = M_ARGV(1, float);
1593         regen_mod = M_ARGV(2, float);
1594         rot_mod = M_ARGV(3, float);
1595         limit_mod = M_ARGV(4, float);
1596         regen_health = M_ARGV(5, float);
1597         regen_health_linear = M_ARGV(6, float);
1598         regen_health_rot = M_ARGV(7, float);
1599         regen_health_rotlinear = M_ARGV(8, float);
1600         regen_health_stable = M_ARGV(9, float);
1601         regen_health_rotstable = M_ARGV(10, float);
1602
1603
1604         if(!mutator_returnvalue)
1605         if(!STAT(FROZEN, this))
1606         {
1607                 float mina, maxa, limith, limita;
1608                 maxa = autocvar_g_balance_armor_rotstable;
1609                 mina = autocvar_g_balance_armor_regenstable;
1610                 limith = autocvar_g_balance_health_limit;
1611                 limita = autocvar_g_balance_armor_limit;
1612
1613                 regen_health_rotstable = regen_health_rotstable * max_mod;
1614                 regen_health_stable = regen_health_stable * max_mod;
1615                 limith = limith * limit_mod;
1616                 limita = limita * limit_mod;
1617
1618                 this.armorvalue = CalcRotRegen(this.armorvalue, mina, autocvar_g_balance_armor_regen, autocvar_g_balance_armor_regenlinear, regen_mod * frametime * (time > this.pauseregen_finished), maxa, autocvar_g_balance_armor_rot, autocvar_g_balance_armor_rotlinear, rot_mod * frametime * (time > this.pauserotarmor_finished), limita);
1619                 this.health = CalcRotRegen(this.health, regen_health_stable, regen_health, regen_health_linear, regen_mod * frametime * (time > this.pauseregen_finished), regen_health_rotstable, regen_health_rot, regen_health_rotlinear, rot_mod * frametime * (time > this.pauserothealth_finished), limith);
1620         }
1621
1622         // if player rotted to death...  die!
1623         // check this outside above checks, as player may still be able to rot to death
1624         if(this.health < 1)
1625         {
1626                 if(this.vehicle)
1627                         vehicles_exit(this.vehicle, VHEF_RELEASE);
1628                 if(this.event_damage)
1629                         this.event_damage(this, this, this, 1, DEATH_ROT.m_id, this.origin, '0 0 0');
1630         }
1631
1632         if (!(this.items & IT_UNLIMITED_WEAPON_AMMO))
1633         {
1634                 float minf, maxf, limitf;
1635
1636                 maxf = autocvar_g_balance_fuel_rotstable;
1637                 minf = autocvar_g_balance_fuel_regenstable;
1638                 limitf = autocvar_g_balance_fuel_limit;
1639
1640                 this.ammo_fuel = CalcRotRegen(this.ammo_fuel, minf, autocvar_g_balance_fuel_regen, autocvar_g_balance_fuel_regenlinear, frametime * (time > this.pauseregen_finished) * ((this.items & ITEM_JetpackRegen.m_itemid) != 0), maxf, autocvar_g_balance_fuel_rot, autocvar_g_balance_fuel_rotlinear, frametime * (time > this.pauserotfuel_finished), limitf);
1641         }
1642 }
1643
1644 bool zoomstate_set;
1645 void SetZoomState(entity this, float newzoom)
1646 {
1647         if(newzoom != this.zoomstate)
1648         {
1649                 this.zoomstate = newzoom;
1650                 ClientData_Touch(this);
1651         }
1652         zoomstate_set = true;
1653 }
1654
1655 void GetPressedKeys(entity this)
1656 {
1657         MUTATOR_CALLHOOK(GetPressedKeys, this);
1658         int keys = STAT(PRESSED_KEYS, this);
1659         keys = BITSET(keys, KEY_FORWARD,        this.movement.x > 0);
1660         keys = BITSET(keys, KEY_BACKWARD,       this.movement.x < 0);
1661         keys = BITSET(keys, KEY_RIGHT,          this.movement.y > 0);
1662         keys = BITSET(keys, KEY_LEFT,           this.movement.y < 0);
1663
1664         keys = BITSET(keys, KEY_JUMP,           PHYS_INPUT_BUTTON_JUMP(this));
1665         keys = BITSET(keys, KEY_CROUCH,         PHYS_INPUT_BUTTON_CROUCH(this));
1666         keys = BITSET(keys, KEY_ATCK,           PHYS_INPUT_BUTTON_ATCK(this));
1667         keys = BITSET(keys, KEY_ATCK2,          PHYS_INPUT_BUTTON_ATCK2(this));
1668         this.pressedkeys = keys; // store for other users
1669
1670         STAT(PRESSED_KEYS, this) = keys;
1671 }
1672
1673 /*
1674 ======================
1675 spectate mode routines
1676 ======================
1677 */
1678
1679 void SpectateCopy(entity this, entity spectatee)
1680 {
1681     TC(Client, this); TC(Client, spectatee);
1682
1683         MUTATOR_CALLHOOK(SpectateCopy, spectatee, this);
1684         PS(this) = PS(spectatee);
1685         this.armortype = spectatee.armortype;
1686         this.armorvalue = spectatee.armorvalue;
1687         this.ammo_cells = spectatee.ammo_cells;
1688         this.ammo_plasma = spectatee.ammo_plasma;
1689         this.ammo_shells = spectatee.ammo_shells;
1690         this.ammo_nails = spectatee.ammo_nails;
1691         this.ammo_rockets = spectatee.ammo_rockets;
1692         this.ammo_fuel = spectatee.ammo_fuel;
1693         this.clip_load = spectatee.clip_load;
1694         this.clip_size = spectatee.clip_size;
1695         this.effects = spectatee.effects & EFMASK_CHEAP; // eat performance
1696         this.health = spectatee.health;
1697         this.impulse = 0;
1698         this.items = spectatee.items;
1699         this.last_pickup = spectatee.last_pickup;
1700         this.hit_time = spectatee.hit_time;
1701         this.strength_finished = spectatee.strength_finished;
1702         this.invincible_finished = spectatee.invincible_finished;
1703         this.superweapons_finished = spectatee.superweapons_finished;
1704         STAT(PRESSED_KEYS, this) = STAT(PRESSED_KEYS, spectatee);
1705         this.weapons = spectatee.weapons;
1706         this.dual_weapons = spectatee.dual_weapons;
1707         this.vortex_charge = spectatee.vortex_charge;
1708         this.vortex_chargepool_ammo = spectatee.vortex_chargepool_ammo;
1709         this.okvortex_charge = spectatee.okvortex_charge;
1710         this.okvortex_chargepool_ammo = spectatee.okvortex_chargepool_ammo;
1711         this.hagar_load = spectatee.hagar_load;
1712         this.arc_heat_percent = spectatee.arc_heat_percent;
1713         this.minelayer_mines = spectatee.minelayer_mines;
1714         this.punchangle = spectatee.punchangle;
1715         this.view_ofs = spectatee.view_ofs;
1716         this.velocity = spectatee.velocity;
1717         this.dmg_take = spectatee.dmg_take;
1718         this.dmg_save = spectatee.dmg_save;
1719         this.dmg_inflictor = spectatee.dmg_inflictor;
1720         this.v_angle = spectatee.v_angle;
1721         this.angles = spectatee.v_angle;
1722         STAT(FROZEN, this) = STAT(FROZEN, spectatee);
1723         this.revive_progress = spectatee.revive_progress;
1724         this.viewloc = spectatee.viewloc;
1725         if(!PHYS_INPUT_BUTTON_USE(this) && STAT(CAMERA_SPECTATOR, this) != 2)
1726                 this.fixangle = true;
1727         setorigin(this, spectatee.origin);
1728         setsize(this, spectatee.mins, spectatee.maxs);
1729         SetZoomState(this, spectatee.zoomstate);
1730
1731         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1732         {
1733                 .entity weaponentity = weaponentities[slot];
1734                 this.(weaponentity) = spectatee.(weaponentity);
1735         }
1736
1737         for(int slot = 0; slot < MAX_AXH; ++slot)
1738         {
1739                 this.(AuxiliaryXhair[slot]) = spectatee.(AuxiliaryXhair[slot]);
1740         }
1741
1742     anticheat_spectatecopy(this, spectatee);
1743         this.hud = spectatee.hud;
1744         if(spectatee.vehicle)
1745     {
1746         this.angles = spectatee.v_angle;
1747
1748         //this.fixangle = false;
1749         //this.velocity = spectatee.vehicle.velocity;
1750         this.vehicle_health = spectatee.vehicle_health;
1751         this.vehicle_shield = spectatee.vehicle_shield;
1752         this.vehicle_energy = spectatee.vehicle_energy;
1753         this.vehicle_ammo1 = spectatee.vehicle_ammo1;
1754         this.vehicle_ammo2 = spectatee.vehicle_ammo2;
1755         this.vehicle_reload1 = spectatee.vehicle_reload1;
1756         this.vehicle_reload2 = spectatee.vehicle_reload2;
1757
1758         //msg_entity = this;
1759
1760        // WriteByte (MSG_ONE, SVC_SETVIEWANGLES);
1761             //WriteAngle(MSG_ONE,  spectatee.v_angle.x);
1762            // WriteAngle(MSG_ONE,  spectatee.v_angle.y);
1763            // WriteAngle(MSG_ONE,  spectatee.v_angle.z);
1764
1765         //WriteByte (MSG_ONE, SVC_SETVIEW);
1766         //    WriteEntity(MSG_ONE, this);
1767         //makevectors(spectatee.v_angle);
1768         //setorigin(this, spectatee.origin - v_forward * 400 + v_up * 300);*/
1769     }
1770 }
1771
1772 bool SpectateUpdate(entity this)
1773 {
1774         if(!this.enemy)
1775                 return false;
1776
1777         if(!IS_PLAYER(this.enemy) || this == this.enemy)
1778         {
1779                 SetSpectatee(this, NULL);
1780                 return false;
1781         }
1782
1783         SpectateCopy(this, this.enemy);
1784
1785         return true;
1786 }
1787
1788 bool SpectateSet(entity this)
1789 {
1790         if(!IS_PLAYER(this.enemy))
1791                 return false;
1792
1793         ClientData_Touch(this.enemy);
1794
1795         msg_entity = this;
1796         WriteByte(MSG_ONE, SVC_SETVIEW);
1797         WriteEntity(MSG_ONE, this.enemy);
1798         set_movetype(this, MOVETYPE_NONE);
1799         accuracy_resend(this);
1800
1801         if(!SpectateUpdate(this))
1802                 PutObserverInServer(this);
1803
1804         return true;
1805 }
1806
1807 void SetSpectatee_status(entity this, int spectatee_num)
1808 {
1809         int oldspectatee_status = this.spectatee_status;
1810         this.spectatee_status = spectatee_num;
1811
1812         if (this.spectatee_status != oldspectatee_status)
1813         {
1814                 ClientData_Touch(this);
1815                 if (g_race || g_cts) race_InitSpectator();
1816         }
1817 }
1818
1819 void SetSpectatee(entity this, entity spectatee)
1820 {
1821         if(IS_BOT_CLIENT(this))
1822                 return; // bots abuse .enemy, this code is useless to them
1823
1824         entity old_spectatee = this.enemy;
1825
1826         this.enemy = spectatee;
1827
1828         // WEAPONTODO
1829         // these are required to fix the spectator bug with arc
1830         if(old_spectatee)
1831         {
1832                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1833                 {
1834                         .entity weaponentity = weaponentities[slot];
1835                         if(old_spectatee.(weaponentity).arc_beam)
1836                                 old_spectatee.(weaponentity).arc_beam.SendFlags |= ARC_SF_SETTINGS;
1837                 }
1838         }
1839         if(this.enemy)
1840         {
1841                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1842                 {
1843                         .entity weaponentity = weaponentities[slot];
1844                         if(this.enemy.(weaponentity).arc_beam)
1845                                 this.enemy.(weaponentity).arc_beam.SendFlags |= ARC_SF_SETTINGS;
1846                 }
1847         }
1848
1849         if (this.enemy)
1850                 SetSpectatee_status(this, etof(this.enemy));
1851
1852         // needed to update spectator list
1853         if(old_spectatee) { ClientData_Touch(old_spectatee); }
1854 }
1855
1856 bool Spectate(entity this, entity pl)
1857 {
1858         if(MUTATOR_CALLHOOK(SpectateSet, this, pl))
1859                 return false;
1860         pl = M_ARGV(1, entity);
1861
1862         SetSpectatee(this, pl);
1863         return SpectateSet(this);
1864 }
1865
1866 bool SpectateNext(entity this)
1867 {
1868         entity ent = find(this.enemy, classname, STR_PLAYER);
1869
1870         if (MUTATOR_CALLHOOK(SpectateNext, this, ent))
1871                 ent = M_ARGV(1, entity);
1872         else if (!ent)
1873                 ent = find(ent, classname, STR_PLAYER);
1874
1875         if(ent) { SetSpectatee(this, ent); }
1876
1877         return SpectateSet(this);
1878 }
1879
1880 bool SpectatePrev(entity this)
1881 {
1882         // NOTE: chain order is from the highest to the lower entnum (unlike find)
1883         entity ent = findchain(classname, STR_PLAYER);
1884         if (!ent) // no player
1885                 return false;
1886
1887         entity first = ent;
1888         // skip players until current spectated player
1889         if(this.enemy)
1890         while(ent && ent != this.enemy)
1891                 ent = ent.chain;
1892
1893         switch (MUTATOR_CALLHOOK(SpectatePrev, this, ent, first))
1894         {
1895                 case MUT_SPECPREV_FOUND:
1896                     ent = M_ARGV(1, entity);
1897                     break;
1898                 case MUT_SPECPREV_RETURN:
1899                     return true;
1900                 case MUT_SPECPREV_CONTINUE:
1901                 default:
1902                 {
1903                         if(ent.chain)
1904                                 ent = ent.chain;
1905                         else
1906                                 ent = first;
1907                         break;
1908                 }
1909         }
1910
1911         SetSpectatee(this, ent);
1912         return SpectateSet(this);
1913 }
1914
1915 /*
1916 =============
1917 ShowRespawnCountdown()
1918
1919 Update a respawn countdown display.
1920 =============
1921 */
1922 void ShowRespawnCountdown(entity this)
1923 {
1924         float number;
1925         if(!IS_DEAD(this)) // just respawned?
1926                 return;
1927         else
1928         {
1929                 number = ceil(this.respawn_time - time);
1930                 if(number <= 0)
1931                         return;
1932                 if(number <= this.respawn_countdown)
1933                 {
1934                         this.respawn_countdown = number - 1;
1935                         if(ceil(this.respawn_time - (time + 0.5)) == number) // only say it if it is the same number even in 0.5s; to prevent overlapping sounds
1936                                 { Send_Notification(NOTIF_ONE, this, MSG_ANNCE, Announcer_PickNumber(CNT_RESPAWN, number)); }
1937                 }
1938         }
1939 }
1940
1941 .bool team_selected;
1942 bool ShowTeamSelection(entity this)
1943 {
1944         if(!teamplay || autocvar_g_campaign || autocvar_g_balance_teams || this.team_selected || (this.wasplayer && autocvar_g_changeteam_banned) || this.team_forced > 0)
1945                 return false;
1946         stuffcmd(this, "menu_showteamselect\n");
1947         return true;
1948 }
1949 void Join(entity this)
1950 {
1951         TRANSMUTE(Player, this);
1952
1953         if(!this.team_selected)
1954         if(autocvar_g_campaign || autocvar_g_balance_teams)
1955                 JoinBestTeam(this, false, true);
1956
1957         if(autocvar_g_campaign)
1958                 campaign_bots_may_start = true;
1959
1960         Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_PREVENT_JOIN);
1961
1962         PutClientInServer(this);
1963
1964         if(IS_PLAYER(this))
1965         if(teamplay && this.team != -1)
1966                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, APP_TEAM_NUM(this.team, INFO_JOIN_PLAY_TEAM), this.netname);
1967         else
1968                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_JOIN_PLAY, this.netname);
1969         this.team_selected = false;
1970 }
1971
1972 /**
1973  * Determines whether the player is allowed to join. This depends on cvar
1974  * g_maxplayers, if it isn't used this function always return true, otherwise
1975  * it checks whether the number of currently playing players exceeds g_maxplayers.
1976  * @return int number of free slots for players, 0 if none
1977  */
1978 int nJoinAllowed(entity this, entity ignore)
1979 {
1980         if(!ignore)
1981         // this is called that way when checking if anyone may be able to join (to build qcstatus)
1982         // so report 0 free slots if restricted
1983         {
1984                 if(autocvar_g_forced_team_otherwise == "spectate")
1985                         return 0;
1986                 if(autocvar_g_forced_team_otherwise == "spectator")
1987                         return 0;
1988         }
1989
1990         if(this && this.team_forced < 0)
1991                 return 0; // forced spectators can never join
1992
1993         // TODO simplify this
1994         int totalClients = 0;
1995         int currentlyPlaying = 0;
1996         FOREACH_CLIENT(true, LAMBDA(
1997                 if(it != ignore)
1998                         ++totalClients;
1999                 if(IS_REAL_CLIENT(it))
2000                 if(IS_PLAYER(it) || it.caplayer)
2001                         ++currentlyPlaying;
2002         ));
2003
2004         float free_slots = 0;
2005         if (!autocvar_g_maxplayers)
2006                 free_slots = maxclients - totalClients;
2007         else if(currentlyPlaying < autocvar_g_maxplayers)
2008                 free_slots = min(maxclients - totalClients, autocvar_g_maxplayers - currentlyPlaying);
2009
2010         static float join_prevent_msg_time = 0;
2011         if(this && ignore && !free_slots && time > join_prevent_msg_time)
2012         {
2013                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_JOIN_PREVENT);
2014                 join_prevent_msg_time = time + 3;
2015         }
2016
2017         return free_slots;
2018 }
2019
2020 /**
2021  * Checks whether the client is an observer or spectator, if so, he will get kicked after
2022  * g_maxplayers_spectator_blocktime seconds
2023  */
2024 void checkSpectatorBlock(entity this)
2025 {
2026         if(IS_SPEC(this) || IS_OBSERVER(this))
2027         if(!this.caplayer)
2028         if(IS_REAL_CLIENT(this))
2029         {
2030                 if( time > (this.spectatortime + autocvar_g_maxplayers_spectator_blocktime) ) {
2031                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_QUIT_KICK_SPECTATING);
2032                         dropclient(this);
2033                 }
2034         }
2035 }
2036
2037 void PrintWelcomeMessage(entity this)
2038 {
2039         if(this.motd_actived_time == 0)
2040         {
2041                 if (autocvar_g_campaign) {
2042                         if ((IS_PLAYER(this) && PHYS_INPUT_BUTTON_INFO(this)) || (!IS_PLAYER(this))) {
2043                                 this.motd_actived_time = time;
2044                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOTD, campaign_message);
2045                         }
2046                 } else {
2047                         if (PHYS_INPUT_BUTTON_INFO(this)) {
2048                                 this.motd_actived_time = time;
2049                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOTD, getwelcomemessage(this));
2050                         }
2051                 }
2052         }
2053         else if(this.motd_actived_time > 0) // showing MOTD or campaign message
2054         {
2055                 if (autocvar_g_campaign) {
2056                         if (PHYS_INPUT_BUTTON_INFO(this))
2057                                 this.motd_actived_time = time;
2058                         else if ((time - this.motd_actived_time > 2) && IS_PLAYER(this)) { // hide it some seconds after BUTTON_INFO has been released
2059                                 this.motd_actived_time = 0;
2060                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_MOTD);
2061                         }
2062                 } else {
2063                         if (PHYS_INPUT_BUTTON_INFO(this))
2064                                 this.motd_actived_time = time;
2065                         else if (time - this.motd_actived_time > 2) { // hide it some seconds after BUTTON_INFO has been released
2066                                 this.motd_actived_time = 0;
2067                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_MOTD);
2068                         }
2069                 }
2070         }
2071         else //if(this.motd_actived_time < 0) // just connected, motd is active
2072         {
2073                 if(PHYS_INPUT_BUTTON_INFO(this)) // BUTTON_INFO hides initial MOTD
2074                         this.motd_actived_time = -2; // wait until BUTTON_INFO gets released
2075                 else if(this.motd_actived_time == -2 || IS_PLAYER(this) || IS_SPEC(this))
2076                 {
2077                         // instanctly hide MOTD
2078                         this.motd_actived_time = 0;
2079                         Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_MOTD);
2080                 }
2081         }
2082 }
2083
2084 bool joinAllowed(entity this)
2085 {
2086         if (this.version_mismatch) return false;
2087         if (!nJoinAllowed(this, this)) return false;
2088         if (teamplay && lockteams) return false;
2089         if (ShowTeamSelection(this)) return false;
2090         if (MUTATOR_CALLHOOK(ForbidSpawn, this)) return false;
2091         return true;
2092 }
2093
2094 void ObserverThink(entity this)
2095 {
2096         if ( this.impulse )
2097         {
2098                 MinigameImpulse(this, this.impulse);
2099                 this.impulse = 0;
2100         }
2101
2102         if (this.flags & FL_JUMPRELEASED) {
2103                 if (PHYS_INPUT_BUTTON_JUMP(this) && joinAllowed(this)) {
2104                         this.flags &= ~FL_JUMPRELEASED;
2105                         this.flags |= FL_SPAWNING;
2106                 } else if(PHYS_INPUT_BUTTON_ATCK(this) && !this.version_mismatch) {
2107                         this.flags &= ~FL_JUMPRELEASED;
2108                         if(SpectateNext(this)) {
2109                                 TRANSMUTE(Spectator, this);
2110                         }
2111                 } else {
2112                         int preferred_movetype = ((!PHYS_INPUT_BUTTON_USE(this) ? this.cvar_cl_clippedspectating : !this.cvar_cl_clippedspectating) ? MOVETYPE_FLY_WORLDONLY : MOVETYPE_NOCLIP);
2113                         set_movetype(this, preferred_movetype);
2114                 }
2115         } else {
2116                 if (!(PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_JUMP(this))) {
2117                         this.flags |= FL_JUMPRELEASED;
2118                         if(this.flags & FL_SPAWNING)
2119                         {
2120                                 this.flags &= ~FL_SPAWNING;
2121                                 Join(this);
2122                                 return;
2123                         }
2124                 }
2125         }
2126 }
2127
2128 void SpectatorThink(entity this)
2129 {
2130         if ( this.impulse )
2131         {
2132                 if(MinigameImpulse(this, this.impulse))
2133                         this.impulse = 0;
2134
2135                 if (this.impulse == IMP_weapon_drop.impulse)
2136                 {
2137                         STAT(CAMERA_SPECTATOR, this) = (STAT(CAMERA_SPECTATOR, this) + 1) % 3;
2138                         this.impulse = 0;
2139                         return;
2140                 }
2141         }
2142
2143         if (this.flags & FL_JUMPRELEASED) {
2144                 if (PHYS_INPUT_BUTTON_JUMP(this) && joinAllowed(this)) {
2145                         this.flags &= ~FL_JUMPRELEASED;
2146                         this.flags |= FL_SPAWNING;
2147                 } else if(PHYS_INPUT_BUTTON_ATCK(this) || this.impulse == 10 || this.impulse == 15 || this.impulse == 18 || (this.impulse >= 200 && this.impulse <= 209)) {
2148                         this.flags &= ~FL_JUMPRELEASED;
2149                         if(SpectateNext(this)) {
2150                                 TRANSMUTE(Spectator, this);
2151                         } else {
2152                                 TRANSMUTE(Observer, this);
2153                                 PutClientInServer(this);
2154                         }
2155                         this.impulse = 0;
2156                 } else if(this.impulse == 12 || this.impulse == 16  || this.impulse == 19 || (this.impulse >= 220 && this.impulse <= 229)) {
2157                         this.flags &= ~FL_JUMPRELEASED;
2158                         if(SpectatePrev(this)) {
2159                                 TRANSMUTE(Spectator, this);
2160                         } else {
2161                                 TRANSMUTE(Observer, this);
2162                                 PutClientInServer(this);
2163                         }
2164                         this.impulse = 0;
2165                 } else if (PHYS_INPUT_BUTTON_ATCK2(this)) {
2166                         this.flags &= ~FL_JUMPRELEASED;
2167                         TRANSMUTE(Observer, this);
2168                         PutClientInServer(this);
2169                 } else {
2170                         if(!SpectateUpdate(this))
2171                                 PutObserverInServer(this);
2172                 }
2173         } else {
2174                 if (!(PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_ATCK2(this))) {
2175                         this.flags |= FL_JUMPRELEASED;
2176                         if(this.flags & FL_SPAWNING)
2177                         {
2178                                 this.flags &= ~FL_SPAWNING;
2179                                 Join(this);
2180                                 return;
2181                         }
2182                 }
2183                 if(!SpectateUpdate(this))
2184                         PutObserverInServer(this);
2185         }
2186
2187         this.flags |= FL_CLIENT | FL_NOTARGET;
2188 }
2189
2190 void vehicles_enter (entity pl, entity veh);
2191 void PlayerUseKey(entity this)
2192 {
2193         if (!IS_PLAYER(this))
2194                 return;
2195
2196         if(this.vehicle)
2197         {
2198                 if(!game_stopped)
2199                 {
2200                         vehicles_exit(this.vehicle, VHEF_NORMAL);
2201                         return;
2202                 }
2203         }
2204         else if(autocvar_g_vehicles_enter)
2205         {
2206                 if(!STAT(FROZEN, this))
2207                 if(!IS_DEAD(this))
2208                 if(!game_stopped)
2209                 {
2210                         entity head, closest_target = NULL;
2211                         head = WarpZone_FindRadius(this.origin, autocvar_g_vehicles_enter_radius, true);
2212
2213                         while(head) // find the closest acceptable target to enter
2214                         {
2215                                 if(IS_VEHICLE(head))
2216                                 if(!IS_DEAD(head))
2217                                 if(!head.owner || ((head.vehicle_flags & VHF_MULTISLOT) && SAME_TEAM(head.owner, this)))
2218                                 if(head.takedamage != DAMAGE_NO)
2219                                 {
2220                                         if(closest_target)
2221                                         {
2222                                                 if(vlen2(this.origin - head.origin) < vlen2(this.origin - closest_target.origin))
2223                                                 { closest_target = head; }
2224                                         }
2225                                         else { closest_target = head; }
2226                                 }
2227
2228                                 head = head.chain;
2229                         }
2230
2231                         if(closest_target) { vehicles_enter(this, closest_target); return; }
2232                 }
2233         }
2234
2235         // a use key was pressed; call handlers
2236         MUTATOR_CALLHOOK(PlayerUseKey, this);
2237 }
2238
2239
2240 /*
2241 =============
2242 PlayerPreThink
2243
2244 Called every frame for each client before the physics are run
2245 =============
2246 */
2247 .float usekeypressed;
2248 .float last_vehiclecheck;
2249 .int items_added;
2250 void PlayerPreThink (entity this)
2251 {
2252         WarpZone_PlayerPhysics_FixVAngle(this);
2253
2254     STAT(GAMESTARTTIME, this) = game_starttime;
2255         STAT(ROUNDSTARTTIME, this) = round_starttime;
2256         STAT(ALLOW_OLDVORTEXBEAM, this) = autocvar_g_allow_oldvortexbeam;
2257         STAT(LEADLIMIT, this) = autocvar_leadlimit;
2258
2259         STAT(WEAPONSINMAP, this) = weaponsInMap;
2260
2261         if (frametime) {
2262                 // physics frames: update anticheat stuff
2263                 anticheat_prethink(this);
2264         }
2265
2266         if (blockSpectators && frametime) {
2267                 // WORKAROUND: only use dropclient in server frames (frametime set).
2268                 // Never use it in cl_movement frames (frametime zero).
2269                 checkSpectatorBlock(this);
2270     }
2271
2272         zoomstate_set = false;
2273
2274         // Check for nameless players
2275         if (isInvisibleString(this.netname)) {
2276                 this.netname = strzone(sprintf("Player#%d", this.playerid));
2277                 // stuffcmd(this, strcat("name ", this.netname, "\n")); // maybe?
2278         }
2279         if (this.netname != this.netname_previous) {
2280                 if (autocvar_sv_eventlog) {
2281                         GameLogEcho(strcat(":name:", ftos(this.playerid), ":", playername(this, false)));
2282         }
2283                 if (this.netname_previous) strunzone(this.netname_previous);
2284                 this.netname_previous = strzone(this.netname);
2285         }
2286
2287         // version nagging
2288         if (this.version_nagtime && this.cvar_g_xonoticversion && time > this.version_nagtime) {
2289         this.version_nagtime = 0;
2290         if (strstrofs(this.cvar_g_xonoticversion, "git", 0) >= 0 || strstrofs(this.cvar_g_xonoticversion, "autobuild", 0) >= 0) {
2291             // git client
2292         } else if (strstrofs(autocvar_g_xonoticversion, "git", 0) >= 0 || strstrofs(autocvar_g_xonoticversion, "autobuild", 0) >= 0) {
2293             // git server
2294             Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_BETA, autocvar_g_xonoticversion, this.cvar_g_xonoticversion);
2295         } else {
2296             int r = vercmp(this.cvar_g_xonoticversion, autocvar_g_xonoticversion);
2297             if (r < 0) { // old client
2298                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_OUTDATED, autocvar_g_xonoticversion, this.cvar_g_xonoticversion);
2299             } else if (r > 0) { // old server
2300                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_OLD, autocvar_g_xonoticversion, this.cvar_g_xonoticversion);
2301             }
2302         }
2303     }
2304
2305         // GOD MODE info
2306         if (!(this.flags & FL_GODMODE) && this.max_armorvalue)
2307         {
2308                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_GODMODE_OFF, this.max_armorvalue);
2309                 this.max_armorvalue = 0;
2310         }
2311
2312         if (STAT(FROZEN, this) == 2)
2313         {
2314                 this.revive_progress = bound(0, this.revive_progress + frametime * this.revive_speed, 1);
2315                 this.health = max(1, this.revive_progress * start_health);
2316                 this.iceblock.alpha = bound(0.2, 1 - this.revive_progress, 1);
2317
2318                 if (this.revive_progress >= 1)
2319                         Unfreeze(this);
2320         }
2321         else if (STAT(FROZEN, this) == 3)
2322         {
2323                 this.revive_progress = bound(0, this.revive_progress - frametime * this.revive_speed, 1);
2324                 this.health = max(0, autocvar_g_nades_ice_health + (start_health-autocvar_g_nades_ice_health) * this.revive_progress );
2325
2326                 if (this.health < 1)
2327                 {
2328                         if (this.vehicle)
2329                                 vehicles_exit(this.vehicle, VHEF_RELEASE);
2330                         if(this.event_damage)
2331                                 this.event_damage(this, this, this.frozen_by, 1, DEATH_NADE_ICE_FREEZE.m_id, this.origin, '0 0 0');
2332                 }
2333                 else if (this.revive_progress <= 0)
2334                         Unfreeze(this);
2335         }
2336
2337         MUTATOR_CALLHOOK(PlayerPreThink, this);
2338
2339         if(autocvar_g_vehicles_enter && (time > this.last_vehiclecheck) && !game_stopped && !this.vehicle)
2340         if(IS_PLAYER(this) && !STAT(FROZEN, this) && !IS_DEAD(this))
2341         {
2342                 FOREACH_ENTITY_RADIUS(this.origin, autocvar_g_vehicles_enter_radius, IS_VEHICLE(it),
2343                 {
2344                         if(!IS_DEAD(it) && it.takedamage != DAMAGE_NO)
2345                         if((it.vehicle_flags & VHF_MULTISLOT) && SAME_TEAM(it.owner, this))
2346                         {
2347                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER_GUNNER);
2348                         }
2349                         else if(!it.owner)
2350                         {
2351                                 if(!it.team || SAME_TEAM(this, it))
2352                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER);
2353                                 else if(autocvar_g_vehicles_steal)
2354                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER_STEAL);
2355                         }
2356                 });
2357
2358                 this.last_vehiclecheck = time + 1;
2359         }
2360
2361         if(!this.cvar_cl_newusekeysupported) // FIXME remove this - it was a stupid idea to begin with, we can JUST use the button
2362         {
2363                 if(PHYS_INPUT_BUTTON_USE(this) && !this.usekeypressed)
2364                         PlayerUseKey(this);
2365                 this.usekeypressed = PHYS_INPUT_BUTTON_USE(this);
2366         }
2367
2368         if (IS_REAL_CLIENT(this))
2369                 PrintWelcomeMessage(this);
2370
2371         if (IS_PLAYER(this)) {
2372                 CheckRules_Player(this);
2373
2374                 if (game_stopped || intermission_running) {
2375                         this.modelflags &= ~MF_ROCKET;
2376                         if(intermission_running)
2377                                 IntermissionThink(this);
2378                         return;
2379                 }
2380
2381                 if (timeout_status == TIMEOUT_ACTIVE) {
2382             // don't allow the player to turn around while game is paused
2383                         // FIXME turn this into CSQC stuff
2384                         this.v_angle = this.lastV_angle;
2385                         this.angles = this.lastV_angle;
2386                         this.fixangle = true;
2387                 }
2388
2389                 if (frametime) player_powerups(this);
2390
2391                 if (IS_DEAD(this)) {
2392                         if (this.personal && g_race_qualifying) {
2393                                 if (time > this.respawn_time) {
2394                                         STAT(RESPAWN_TIME, this) = this.respawn_time = time + 1; // only retry once a second
2395                                         respawn(this);
2396                                         this.impulse = CHIMPULSE_SPEEDRUN.impulse;
2397                                 }
2398                         } else {
2399                                 if (frametime) player_anim(this);
2400
2401                                 if (this.respawn_flags & RESPAWN_DENY)
2402                                 {
2403                                         STAT(RESPAWN_TIME, this) = 0;
2404                                         return;
2405                                 }
2406
2407                                 bool button_pressed = (PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_JUMP(this) || PHYS_INPUT_BUTTON_ATCK2(this) || PHYS_INPUT_BUTTON_HOOK(this) || PHYS_INPUT_BUTTON_USE(this));
2408
2409                                 switch(this.deadflag)
2410                                 {
2411                                         case DEAD_DYING:
2412                                         {
2413                                                 if ((this.respawn_flags & RESPAWN_FORCE) && !(this.respawn_time < this.respawn_time_max))
2414                                                         this.deadflag = DEAD_RESPAWNING;
2415                                                 else if (!button_pressed || (time >= this.respawn_time_max && (this.respawn_flags & RESPAWN_FORCE)))
2416                                                         this.deadflag = DEAD_DEAD;
2417                                                 break;
2418                                         }
2419                                         case DEAD_DEAD:
2420                                         {
2421                                                 if (button_pressed)
2422                                                         this.deadflag = DEAD_RESPAWNABLE;
2423                                                 else if (time >= this.respawn_time_max && (this.respawn_flags & RESPAWN_FORCE))
2424                                                         this.deadflag = DEAD_RESPAWNING;
2425                                                 break;
2426                                         }
2427                                         case DEAD_RESPAWNABLE:
2428                                         {
2429                                                 if (!button_pressed || (this.respawn_flags & RESPAWN_FORCE))
2430                                                         this.deadflag = DEAD_RESPAWNING;
2431                                                 break;
2432                                         }
2433                                         case DEAD_RESPAWNING:
2434                                         {
2435                                                 if (time > this.respawn_time)
2436                                                 {
2437                                                         this.respawn_time = time + 1; // only retry once a second
2438                                                         this.respawn_time_max = this.respawn_time;
2439                                                         respawn(this);
2440                                                 }
2441                                                 break;
2442                                         }
2443                                 }
2444
2445                                 ShowRespawnCountdown(this);
2446
2447                                 if (this.respawn_flags & RESPAWN_SILENT)
2448                                         STAT(RESPAWN_TIME, this) = 0;
2449                                 else if ((this.respawn_flags & RESPAWN_FORCE) && this.respawn_time < this.respawn_time_max)
2450                                 {
2451                                         if (time < this.respawn_time)
2452                                                 STAT(RESPAWN_TIME, this) = this.respawn_time;
2453                                         else if (this.deadflag != DEAD_RESPAWNING)
2454                                                 STAT(RESPAWN_TIME, this) = -this.respawn_time_max;
2455                                 }
2456                                 else
2457                                         STAT(RESPAWN_TIME, this) = this.respawn_time;
2458                         }
2459
2460                         // if respawning, invert stat_respawn_time to indicate this, the client translates it
2461                         if (this.deadflag == DEAD_RESPAWNING && STAT(RESPAWN_TIME, this) > 0)
2462                                 STAT(RESPAWN_TIME, this) *= -1;
2463
2464                         return;
2465                 }
2466
2467                 this.prevorigin = this.origin;
2468
2469                 bool have_hook = false;
2470                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2471                 {
2472                         .entity weaponentity = weaponentities[slot];
2473                         if(this.(weaponentity).hook.state)
2474                         {
2475                                 have_hook = true;
2476                                 break;
2477                         }
2478                 }
2479                 bool do_crouch = PHYS_INPUT_BUTTON_CROUCH(this);
2480                 if (have_hook) {
2481                         do_crouch = false;
2482                 } else if (this.waterlevel >= WATERLEVEL_SWIMMING) {
2483                         do_crouch = false;
2484                 } else if (this.vehicle) {
2485                         do_crouch = false;
2486                 } else if (STAT(FROZEN, this)) {
2487                         do_crouch = false;
2488         }
2489
2490                 if (do_crouch) {
2491                         if (!this.crouch) {
2492                                 this.crouch = true;
2493                                 this.view_ofs = STAT(PL_CROUCH_VIEW_OFS, this);
2494                                 setsize(this, STAT(PL_CROUCH_MIN, this), STAT(PL_CROUCH_MAX, this));
2495                                 // setanim(this, this.anim_duck, false, true, true); // this anim is BROKEN anyway
2496                         }
2497                 } else if (this.crouch) {
2498             tracebox(this.origin, STAT(PL_MIN, this), STAT(PL_MAX, this), this.origin, false, this);
2499             if (!trace_startsolid) {
2500                 this.crouch = false;
2501                 this.view_ofs = STAT(PL_VIEW_OFS, this);
2502                 setsize(this, STAT(PL_MIN, this), STAT(PL_MAX, this));
2503             }
2504                 }
2505
2506                 FixPlayermodel(this);
2507
2508                 // LordHavoc: allow firing on move frames (sub-ticrate), this gives better timing on slow servers
2509                 //if(frametime)
2510                 {
2511                         this.items &= ~this.items_added;
2512
2513                         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2514                         {
2515                                 .entity weaponentity = weaponentities[slot];
2516                                 W_WeaponFrame(this, weaponentity);
2517
2518                                 if(slot == 0)
2519                                 {
2520                                         this.clip_load = this.(weaponentity).clip_load;
2521                                         this.clip_size = this.(weaponentity).clip_size;
2522                                 }
2523                         }
2524
2525                         this.items_added = 0;
2526                         if (this.items & ITEM_Jetpack.m_itemid && (this.items & ITEM_JetpackRegen.m_itemid || this.ammo_fuel >= 0.01))
2527                 this.items_added |= IT_FUEL;
2528
2529                         this.items |= this.items_added;
2530                 }
2531
2532                 player_regen(this);
2533
2534                 // WEAPONTODO: Add a weapon request for this
2535                 // rot vortex charge to the charge limit
2536                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2537                 {
2538                         .entity weaponentity = weaponentities[slot];
2539                         if (WEP_CVAR(vortex, charge_rot_rate) && this.(weaponentity).vortex_charge > WEP_CVAR(vortex, charge_limit) && this.(weaponentity).vortex_charge_rottime < time)
2540                         {
2541                                 this.(weaponentity).vortex_charge = bound(WEP_CVAR(vortex, charge_limit), this.(weaponentity).vortex_charge - WEP_CVAR(vortex, charge_rot_rate) * frametime / W_TICSPERFRAME, 1);
2542                         }
2543                         if (WEP_CVAR(okvortex, charge_rot_rate) && this.(weaponentity).okvortex_charge > WEP_CVAR(okvortex, charge_limit) && this.(weaponentity).okvortex_charge_rottime < time)
2544                         {
2545                                 this.(weaponentity).okvortex_charge = bound(WEP_CVAR(okvortex, charge_limit), this.(weaponentity).okvortex_charge - WEP_CVAR(okvortex, charge_rot_rate) * frametime / W_TICSPERFRAME, 1);
2546                         }
2547                 }
2548
2549                 if (frametime) player_anim(this);
2550
2551                 // secret status
2552                 secrets_setstatus(this);
2553
2554                 // monsters status
2555                 monsters_setstatus(this);
2556
2557                 this.dmg_team = max(0, this.dmg_team - autocvar_g_teamdamage_resetspeed * frametime);
2558         }
2559         else if (game_stopped || intermission_running) {
2560                 if(intermission_running)
2561                         IntermissionThink(this);
2562                 return;
2563         }
2564         else if (IS_OBSERVER(this)) {
2565                 ObserverThink(this);
2566         }
2567         else if (IS_SPEC(this)) {
2568                 SpectatorThink(this);
2569         }
2570
2571         // WEAPONTODO: Add weapon request for this
2572         if (!zoomstate_set) {
2573                 bool wep_zoomed = false;
2574                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2575                 {
2576                         .entity weaponentity = weaponentities[slot];
2577                         Weapon thiswep = this.(weaponentity).m_weapon;
2578                         if(thiswep != WEP_Null && thiswep.wr_zoom)
2579                                 wep_zoomed += thiswep.wr_zoom(thiswep, this);
2580                 }
2581                 SetZoomState(this, PHYS_INPUT_BUTTON_ZOOM(this) || PHYS_INPUT_BUTTON_ZOOMSCRIPT(this) || wep_zoomed);
2582     }
2583
2584         if (this.teamkill_soundtime && time > this.teamkill_soundtime)
2585         {
2586                 this.teamkill_soundtime = 0;
2587
2588                 entity e = this.teamkill_soundsource;
2589                 entity oldpusher = e.pusher;
2590                 e.pusher = this;
2591                 PlayerSound(e, playersound_teamshoot, CH_VOICE, VOL_BASEVOICE, VOICETYPE_LASTATTACKER_ONLY);
2592                 e.pusher = oldpusher;
2593         }
2594
2595         if (this.taunt_soundtime && time > this.taunt_soundtime) {
2596                 this.taunt_soundtime = 0;
2597                 PlayerSound(this, playersound_taunt, CH_VOICE, VOL_BASEVOICE, VOICETYPE_AUTOTAUNT);
2598         }
2599
2600         target_voicescript_next(this);
2601
2602         // WEAPONTODO: Move into weaponsystem somehow
2603         // if a player goes unarmed after holding a loaded weapon, empty his clip size and remove the crosshair ammo ring
2604         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2605         {
2606                 .entity weaponentity = weaponentities[slot];
2607                 if(this.(weaponentity).m_weapon == WEP_Null)
2608                         this.(weaponentity).clip_load = this.(weaponentity).clip_size = 0;
2609         }
2610 }
2611
2612 void DrownPlayer(entity this)
2613 {
2614         if(IS_DEAD(this))
2615                 return;
2616
2617         if (this.waterlevel != WATERLEVEL_SUBMERGED || this.vehicle)
2618         {
2619                 if(this.air_finished < time)
2620                         PlayerSound(this, playersound_gasp, CH_PLAYER, VOL_BASE, VOICETYPE_PLAYERSOUND);
2621                 this.air_finished = time + autocvar_g_balance_contents_drowndelay;
2622                 this.dmg = 2;
2623         }
2624         else if (this.air_finished < time)
2625         {       // drown!
2626                 if (this.pain_finished < time)
2627                 {
2628                         Damage (this, NULL, NULL, autocvar_g_balance_contents_playerdamage_drowning * autocvar_g_balance_contents_damagerate, DEATH_DROWN.m_id, this.origin, '0 0 0');
2629                         this.pain_finished = time + 0.5;
2630                 }
2631         }
2632 }
2633
2634 .bool move_qcphysics;
2635
2636 void Player_Physics(entity this)
2637 {
2638         set_movetype(this, this.move_movetype);
2639
2640         if(!this.move_qcphysics)
2641                 return;
2642
2643         if(!frametime && !this.pm_frametime)
2644                 return;
2645
2646         Movetype_Physics_NoMatchTicrate(this, this.pm_frametime, true);
2647
2648         this.pm_frametime = 0;
2649 }
2650
2651 /*
2652 =============
2653 PlayerPostThink
2654
2655 Called every frame for each client after the physics are run
2656 =============
2657 */
2658 .float idlekick_lasttimeleft;
2659 void PlayerPostThink (entity this)
2660 {
2661         Player_Physics(this);
2662
2663         if (sv_maxidle > 0)
2664         if (frametime) // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2665         if (IS_REAL_CLIENT(this))
2666         if (IS_PLAYER(this) || sv_maxidle_spectatorsareidle)
2667         {
2668                 int totalClients = 0;
2669                 if(sv_maxidle_slots > 0)
2670                 {
2671                         FOREACH_CLIENT(IS_REAL_CLIENT(it) || sv_maxidle_slots_countbots,
2672                         {
2673                                 ++totalClients;
2674                         });
2675                 }
2676
2677                 if (sv_maxidle_slots > 0 && (maxclients - totalClients) > sv_maxidle_slots)
2678                 { /* do nothing */ }
2679                 else if (time - this.parm_idlesince < 1) // instead of (time == this.parm_idlesince) to support sv_maxidle <= 10
2680                 {
2681                         if (this.idlekick_lasttimeleft)
2682                         {
2683                                 this.idlekick_lasttimeleft = 0;
2684                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_IDLING);
2685                         }
2686                 }
2687                 else
2688                 {
2689                         float timeleft = ceil(sv_maxidle - (time - this.parm_idlesince));
2690                         if (timeleft == min(10, sv_maxidle - 1)) { // - 1 to support sv_maxidle <= 10
2691                                 if (!this.idlekick_lasttimeleft)
2692                                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_DISCONNECT_IDLING, timeleft);
2693                         }
2694                         if (timeleft <= 0) {
2695                                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_QUIT_KICK_IDLING, this.netname);
2696                                 dropclient(this);
2697                                 return;
2698                         }
2699                         else if (timeleft <= 10) {
2700                                 if (timeleft != this.idlekick_lasttimeleft) {
2701                                     Send_Notification(NOTIF_ONE, this, MSG_ANNCE, Announcer_PickNumber(CNT_IDLE, timeleft));
2702                 }
2703                                 this.idlekick_lasttimeleft = timeleft;
2704                         }
2705                 }
2706         }
2707
2708         CheatFrame(this);
2709
2710         //CheckPlayerJump();
2711         if (game_stopped)
2712         {
2713                 this.solid = SOLID_NOT;
2714                 this.takedamage = DAMAGE_NO;
2715                 set_movetype(this, MOVETYPE_NONE);
2716         }
2717
2718         if (IS_PLAYER(this)) {
2719                 DrownPlayer(this);
2720                 CheckRules_Player(this);
2721                 UpdateChatBubble(this);
2722                 if (this.impulse) ImpulseCommands(this);
2723                 if (game_stopped)
2724                 {
2725                         CSQCMODEL_AUTOUPDATE(this);
2726                         return;
2727                 }
2728                 GetPressedKeys(this);
2729         }
2730
2731         if (this.waypointsprite_attachedforcarrier) {
2732             vector v = healtharmor_maxdamage(this.health, this.armorvalue, autocvar_g_balance_armor_blockpercent, DEATH_WEAPON.m_id);
2733                 WaypointSprite_UpdateHealth(this.waypointsprite_attachedforcarrier, '1 0 0' * v);
2734     }
2735
2736         playerdemo_write(this);
2737
2738         CSQCMODEL_AUTOUPDATE(this);
2739 }