qcsrc/server/client.qc

   1 #include "client.qh"
   2
   3 #include "anticheat.qh"
   4 #include "impulse.qh"
   5 #include "player.qh"
   6 #include "ipban.qh"
   7 #include "miscfunctions.qh"
   8 #include "portals.qh"
   9 #include "teamplay.qh"
  10 #include "playerdemo.qh"
  11 #include "spawnpoints.qh"
  12 #include "g_damage.qh"
  13 #include "g_hook.qh"
  14 #include "command/common.qh"
  15 #include "cheats.qh"
  16 #include "g_world.qh"
  17 #include "race.qh"
  18 #include "antilag.qh"
  19 #include "campaign.qh"
  20 #include "command/common.qh"
  21 #include "scores_rules.qh"
  22
  23 #include "bot/api.qh"
  24
  25 #include "../common/ent_cs.qh"
  26 #include "../common/wepent.qh"
  27 #include <common/state.qh>
  28
  29 #include <common/effects/qc/globalsound.qh>
  30
  31 #include "../common/triggers/func/conveyor.qh"
  32 #include "../common/triggers/teleporters.qh"
  33
  34 #include "../common/vehicles/all.qh"
  35
  36 #include "weapons/hitplot.qh"
  37 #include "weapons/weaponsystem.qh"
  38
  39 #include "../common/net_notice.qh"
  40 #include "../common/physics/player.qh"
  41
  42 #include "../common/items/_mod.qh"
  43
  44 #include "../common/mutators/mutator/waypoints/all.qh"
  45
  46 #include "../common/triggers/subs.qh"
  47 #include "../common/triggers/triggers.qh"
  48 #include "../common/triggers/trigger/secret.qh"
  49
  50 #include "../common/minigames/sv_minigames.qh"
  51
  52 #include "../common/items/inventory.qh"
  53
  54 #include "../common/monsters/sv_monsters.qh"
  55
  56 #include "../lib/warpzone/server.qh"
  57
  58 STATIC_METHOD(Client, Add, void(Client this, int _team))
  59 {
  60     ClientConnect(this);
  61     TRANSMUTE(Player, this);
  62     this.frame = 12; // 7
  63     this.team = _team;
  64     PutClientInServer(this);
  65 }
  66
  67 void PutObserverInServer(entity this);
  68
  69 STATIC_METHOD(Client, Remove, void(Client this))
  70 {
  71     TRANSMUTE(Observer, this);
  72     PutClientInServer(this);
  73     ClientDisconnect(this);
  74 }
  75
  76 void send_CSQC_teamnagger() {
  77         WriteHeader(MSG_BROADCAST, TE_CSQC_TEAMNAGGER);
  78 }
  79
  80 int CountSpectators(entity player, entity to)
  81 {
  82         if(!player) { return 0; } // not sure how, but best to be safe
  83
  84         int spec_count = 0;
  85
  86         FOREACH_CLIENT(IS_REAL_CLIENT(it) && IS_SPEC(it) && it != to && it.enemy == player,
  87         {
  88                 spec_count++;
  89         });
  90
  91         return spec_count;
  92 }
  93
  94 void WriteSpectators(entity player, entity to)
  95 {
  96         if(!player) { return; } // not sure how, but best to be safe
  97
  98         FOREACH_CLIENT(IS_REAL_CLIENT(it) && IS_SPEC(it) && it != to && it.enemy == player,
  99         {
 100                 WriteByte(MSG_ENTITY, num_for_edict(it));
 101         });
 102 }
 103
 104 bool ClientData_Send(entity this, entity to, int sf)
 105 {
 106         assert(to == this.owner, return false);
 107
 108         entity e = to;
 109         if (IS_SPEC(e)) e = e.enemy;
 110
 111         sf = 0;
 112         if (e.race_completed)       sf |= 1; // forced scoreboard
 113         if (to.spectatee_status)    sf |= 2; // spectator ent number follows
 114         if (e.zoomstate)            sf |= 4; // zoomed
 115         if (e.porto_v_angle_held)   sf |= 8; // angles held
 116         if (autocvar_sv_showspectators) sf |= 16; // show spectators
 117
 118         WriteHeader(MSG_ENTITY, ENT_CLIENT_CLIENTDATA);
 119         WriteByte(MSG_ENTITY, sf);
 120
 121         if (sf & 2)
 122         {
 123                 WriteByte(MSG_ENTITY, to.spectatee_status);
 124         }
 125         if (sf & 8)
 126         {
 127                 WriteAngle(MSG_ENTITY, e.v_angle.x);
 128                 WriteAngle(MSG_ENTITY, e.v_angle.y);
 129         }
 130
 131         if(sf & 16)
 132         {
 133                 float specs = CountSpectators(e, to);
 134                 WriteByte(MSG_ENTITY, specs);
 135                 WriteSpectators(e, to);
 136         }
 137
 138         return true;
 139 }
 140
 141 void ClientData_Attach(entity this)
 142 {
 143         Net_LinkEntity(this.clientdata = new_pure(clientdata), false, 0, ClientData_Send);
 144         this.clientdata.drawonlytoclient = this;
 145         this.clientdata.owner = this;
 146 }
 147
 148 void ClientData_Detach(entity this)
 149 {
 150         delete(this.clientdata);
 151         this.clientdata = NULL;
 152 }
 153
 154 void ClientData_Touch(entity e)
 155 {
 156         e.clientdata.SendFlags = 1;
 157
 158         // make it spectatable
 159         FOREACH_CLIENT(IS_REAL_CLIENT(it) && it != e && IS_SPEC(it) && it.enemy == e, LAMBDA(it.clientdata.SendFlags = 1));
 160 }
 161
 162 .string netname_previous;
 163
 164 void SetSpectatee(entity this, entity spectatee);
 165 void SetSpectatee_status(entity this, int spectatee_num);
 166
 167
 168 /*
 169 =============
 170 CheckPlayerModel
 171
 172 Checks if the argument string can be a valid playermodel.
 173 Returns a valid one in doubt.
 174 =============
 175 */
 176 string FallbackPlayerModel;
 177 string CheckPlayerModel(string plyermodel) {
 178         if(FallbackPlayerModel != cvar_defstring("_cl_playermodel"))
 179         {
 180                 // note: we cannot summon Don Strunzone here, some player may
 181                 // still have the model string set. In case anyone manages how
 182                 // to change a cvar default, we'll have a small leak here.
 183                 FallbackPlayerModel = strzone(cvar_defstring("_cl_playermodel"));
 184         }
 185         // only in right path
 186         if( substring(plyermodel,0,14) != "models/player/")
 187                 return FallbackPlayerModel;
 188         // only good file extensions
 189         if(substring(plyermodel,-4,4) != ".zym")
 190         if(substring(plyermodel,-4,4) != ".dpm")
 191         if(substring(plyermodel,-4,4) != ".iqm")
 192         if(substring(plyermodel,-4,4) != ".md3")
 193         if(substring(plyermodel,-4,4) != ".psk")
 194                 return FallbackPlayerModel;
 195         // forbid the LOD models
 196         if(substring(plyermodel, -9,5) == "_lod1")
 197                 return FallbackPlayerModel;
 198         if(substring(plyermodel, -9,5) == "_lod2")
 199                 return FallbackPlayerModel;
 200         if(plyermodel != strtolower(plyermodel))
 201                 return FallbackPlayerModel;
 202         // also, restrict to server models
 203         if(autocvar_sv_servermodelsonly)
 204         {
 205                 if(!fexists(plyermodel))
 206                         return FallbackPlayerModel;
 207         }
 208         return plyermodel;
 209 }
 210
 211 void setplayermodel(entity e, string modelname)
 212 {
 213         precache_model(modelname);
 214         _setmodel(e, modelname);
 215         player_setupanimsformodel(e);
 216         if(!autocvar_g_debug_globalsounds)
 217                 UpdatePlayerSounds(e);
 218 }
 219
 220 void FixPlayermodel(entity player);
 221 /** putting a client as observer in the server */
 222 void PutObserverInServer(entity this)
 223 {
 224     bool mutator_returnvalue = MUTATOR_CALLHOOK(MakePlayerObserver, this);
 225         PlayerState_detach(this);
 226
 227         if (IS_PLAYER(this) && this.health >= 1) {
 228         // despawn effect
 229                 Send_Effect(EFFECT_SPAWN_NEUTRAL, this.origin, '0 0 0', 1);
 230     }
 231
 232     {
 233         entity spot = SelectSpawnPoint(this, true);
 234         if (!spot) LOG_FATAL("No spawnpoints for observers?!?");
 235         this.angles = spot.angles;
 236         this.angles_z = 0;
 237         this.fixangle = true;
 238         // offset it so that the spectator spawns higher off the ground, looks better this way
 239         setorigin(this, spot.origin + STAT(PL_VIEW_OFS, NULL));
 240         this.prevorigin = this.origin;
 241         if (IS_REAL_CLIENT(this))
 242         {
 243             msg_entity = this;
 244             WriteByte(MSG_ONE, SVC_SETVIEW);
 245             WriteEntity(MSG_ONE, this);
 246         }
 247         // give the spectator some space between walls for MOVETYPE_FLY_WORLDONLY
 248         // so that your view doesn't go into the ceiling with MOVETYPE_FLY_WORLDONLY, previously "PL_VIEW_OFS"
 249         if(!autocvar_g_debug_globalsounds)
 250         {
 251                 // needed for player sounds
 252                 this.model = "";
 253                 FixPlayermodel(this);
 254         }
 255         setmodel(this, MDL_Null);
 256         setsize(this, STAT(PL_CROUCH_MIN, NULL), STAT(PL_CROUCH_MAX, NULL));
 257         this.view_ofs = '0 0 0';
 258     }
 259
 260     RemoveGrapplingHook(this);
 261         Portal_ClearAll(this);
 262         Unfreeze(this);
 263         SetSpectatee(this, NULL);
 264
 265         if (this.alivetime)
 266         {
 267                 if (!warmup_stage)
 268                         PS_GR_P_ADDVAL(this, PLAYERSTATS_ALIVETIME, time - this.alivetime);
 269                 this.alivetime = 0;
 270         }
 271
 272         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
 273
 274         WaypointSprite_PlayerDead(this);
 275
 276         if (mutator_returnvalue) {
 277             // mutator prevents resetting teams+score
 278         } else {
 279                 this.team = -1;  // move this as it is needed to log the player spectating in eventlog
 280         this.frags = FRAGS_SPECTATOR;
 281         PlayerScore_Clear(this);  // clear scores when needed
 282     }
 283
 284         if (this.killcount != FRAGS_SPECTATOR)
 285         {
 286                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_QUIT_SPECTATE, this.netname);
 287                 if(!intermission_running)
 288                 if(autocvar_g_chat_nospectators == 1 || (!(warmup_stage || gameover) && autocvar_g_chat_nospectators == 2))
 289                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_CHAT_NOSPECTATORS);
 290
 291                 if(this.just_joined == false) {
 292                         LogTeamchange(this.playerid, -1, 4);
 293                 } else
 294                         this.just_joined = false;
 295         }
 296
 297         accuracy_resend(this);
 298
 299         this.spectatortime = time;
 300         if(this.bot_attack)
 301                 IL_REMOVE(g_bot_targets, this);
 302         this.bot_attack = false;
 303     this.hud = HUD_NORMAL;
 304         TRANSMUTE(Observer, this);
 305         this.iscreature = false;
 306         this.teleportable = TELEPORT_SIMPLE;
 307         this.damagedbycontents = false;
 308         this.health = FRAGS_SPECTATOR;
 309         SetSpectatee_status(this, etof(this));
 310         this.takedamage = DAMAGE_NO;
 311         this.solid = SOLID_NOT;
 312         set_movetype(this, MOVETYPE_FLY_WORLDONLY); // user preference is controlled by playerprethink
 313         this.flags = FL_CLIENT | FL_NOTARGET;
 314         this.armorvalue = 666;
 315         this.effects = 0;
 316         this.armorvalue = autocvar_g_balance_armor_start;
 317         this.pauserotarmor_finished = 0;
 318         this.pauserothealth_finished = 0;
 319         this.pauseregen_finished = 0;
 320         this.damageforcescale = 0;
 321         this.death_time = 0;
 322         this.respawn_flags = 0;
 323         this.respawn_time = 0;
 324         this.stat_respawn_time = 0;
 325         this.alpha = 0;
 326         this.scale = 0;
 327         this.fade_time = 0;
 328         this.pain_frame = 0;
 329         this.pain_finished = 0;
 330         this.strength_finished = 0;
 331         this.invincible_finished = 0;
 332         this.superweapons_finished = 0;
 333         this.pushltime = 0;
 334         this.istypefrag = 0;
 335         setthink(this, func_null);
 336         this.nextthink = 0;
 337         this.hook_time = 0;
 338         this.deadflag = DEAD_NO;
 339         this.crouch = false;
 340         this.revival_time = 0;
 341
 342         this.items = 0;
 343         this.weapons = '0 0 0';
 344         this.drawonlytoclient = this;
 345
 346         this.weaponmodel = "";
 347         for (int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 348         {
 349                 this.weaponentities[slot].weaponname = "";
 350                 this.weaponentities[slot] = NULL;
 351         }
 352         this.exteriorweaponentity = NULL;
 353         this.killcount = FRAGS_SPECTATOR;
 354         this.velocity = '0 0 0';
 355         this.avelocity = '0 0 0';
 356         this.punchangle = '0 0 0';
 357         this.punchvector = '0 0 0';
 358         this.oldvelocity = this.velocity;
 359         this.fire_endtime = -1;
 360         this.event_damage = func_null;
 361
 362         STAT(ACTIVEWEAPON, this) = WEP_Null.m_id;
 363         STAT(SWITCHINGWEAPON, this) = WEP_Null.m_id;
 364         STAT(SWITCHWEAPON, this) = WEP_Null.m_id;
 365 }
 366
 367 int player_getspecies(entity this)
 368 {
 369         get_model_parameters(this.model, this.skin);
 370         int s = get_model_parameters_species;
 371         get_model_parameters(string_null, 0);
 372         if (s < 0) return SPECIES_HUMAN;
 373         return s;
 374 }
 375
 376 .float model_randomizer;
 377 void FixPlayermodel(entity player)
 378 {
 379         string defaultmodel = "";
 380         int defaultskin = 0;
 381         if(autocvar_sv_defaultcharacter)
 382         {
 383                 if(teamplay)
 384                 {
 385                         string s = Static_Team_ColorName_Lower(player.team);
 386                         if (s != "neutral")
 387                         {
 388                                 defaultmodel = cvar_string(strcat("sv_defaultplayermodel_", s));
 389                                 defaultskin = cvar(strcat("sv_defaultplayerskin_", s));
 390                         }
 391                 }
 392
 393                 if(defaultmodel == "")
 394                 {
 395                         defaultmodel = autocvar_sv_defaultplayermodel;
 396                         defaultskin = autocvar_sv_defaultplayerskin;
 397                 }
 398
 399                 int n = tokenize_console(defaultmodel);
 400                 if(n > 0)
 401                 {
 402                         defaultmodel = argv(floor(n * player.model_randomizer));
 403                         // However, do NOT randomize if the player-selected model is in the list.
 404                         for (int i = 0; i < n; ++i)
 405                                 if ((argv(i) == player.playermodel && defaultskin == stof(player.playerskin)) || argv(i) == strcat(player.playermodel, ":", player.playerskin))
 406                                         defaultmodel = argv(i);
 407                 }
 408
 409                 int i = strstrofs(defaultmodel, ":", 0);
 410                 if(i >= 0)
 411                 {
 412                         defaultskin = stof(substring(defaultmodel, i+1, -1));
 413                         defaultmodel = substring(defaultmodel, 0, i);
 414                 }
 415         }
 416         if(autocvar_sv_defaultcharacterskin && !defaultskin)
 417         {
 418                 if(teamplay)
 419                 {
 420                         string s = Static_Team_ColorName_Lower(player.team);
 421                         if (s != "neutral")
 422                                 defaultskin = cvar(strcat("sv_defaultplayerskin_", s));
 423                 }
 424
 425                 if(!defaultskin)
 426                         defaultskin = autocvar_sv_defaultplayerskin;
 427         }
 428
 429         MUTATOR_CALLHOOK(FixPlayermodel, defaultmodel, defaultskin, player);
 430         defaultmodel = M_ARGV(0, string);
 431         defaultskin = M_ARGV(1, int);
 432
 433         bool chmdl = false;
 434         int oldskin;
 435         if(defaultmodel != "")
 436         {
 437                 if (defaultmodel != player.model)
 438                 {
 439                         vector m1 = player.mins;
 440                         vector m2 = player.maxs;
 441                         setplayermodel (player, defaultmodel);
 442                         setsize (player, m1, m2);
 443                         chmdl = true;
 444                 }
 445
 446                 oldskin = player.skin;
 447                 player.skin = defaultskin;
 448         } else {
 449                 if (player.playermodel != player.model || player.playermodel == "")
 450                 {
 451                         player.playermodel = CheckPlayerModel(player.playermodel); // this is never "", so no endless loop
 452                         vector m1 = player.mins;
 453                         vector m2 = player.maxs;
 454                         setplayermodel (player, player.playermodel);
 455                         setsize (player, m1, m2);
 456                         chmdl = true;
 457                 }
 458
 459                 if(!autocvar_sv_defaultcharacterskin)
 460                 {
 461                         oldskin = player.skin;
 462                         player.skin = stof(player.playerskin);
 463                 }
 464                 else
 465                 {
 466                         oldskin = player.skin;
 467                         player.skin = defaultskin;
 468                 }
 469         }
 470
 471         if(chmdl || oldskin != player.skin) // model or skin has changed
 472         {
 473                 player.species = player_getspecies(player); // update species
 474                 if(!autocvar_g_debug_globalsounds)
 475                         UpdatePlayerSounds(player); // update skin sounds
 476         }
 477
 478         if(!teamplay)
 479                 if(strlen(autocvar_sv_defaultplayercolors))
 480                         if(player.clientcolors != stof(autocvar_sv_defaultplayercolors))
 481                                 setcolor(player, stof(autocvar_sv_defaultplayercolors));
 482 }
 483
 484
 485 /** Called when a client spawns in the server */
 486 void PutClientInServer(entity this)
 487 {
 488         if (IS_BOT_CLIENT(this)) {
 489                 TRANSMUTE(Player, this);
 490         } else if (IS_REAL_CLIENT(this)) {
 491                 msg_entity = this;
 492                 WriteByte(MSG_ONE, SVC_SETVIEW);
 493                 WriteEntity(MSG_ONE, this);
 494         }
 495         if (gameover) {
 496                 TRANSMUTE(Observer, this);
 497         }
 498
 499         SetSpectatee(this, NULL);
 500
 501         // reset player keys
 502         this.itemkeys = 0;
 503
 504         MUTATOR_CALLHOOK(PutClientInServer, this);
 505
 506         if (IS_OBSERVER(this)) {
 507                 PutObserverInServer(this);
 508         } else if (IS_PLAYER(this)) {
 509                 if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
 510
 511                 PlayerState_attach(this);
 512                 accuracy_resend(this);
 513
 514                 if (this.team < 0)
 515                         JoinBestTeam(this, false, true);
 516
 517                 entity spot = SelectSpawnPoint(this, false);
 518                 if (!spot) {
 519                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_JOIN_NOSPAWNS);
 520                         return; // spawn failed
 521                 }
 522
 523                 TRANSMUTE(Player, this);
 524
 525                 this.wasplayer = true;
 526                 this.iscreature = true;
 527                 this.teleportable = TELEPORT_NORMAL;
 528                 this.damagedbycontents = true;
 529                 set_movetype(this, MOVETYPE_WALK);
 530                 this.solid = SOLID_SLIDEBOX;
 531                 this.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_SOLID;
 532                 if (autocvar_g_playerclip_collisions)
 533                         this.dphitcontentsmask |= DPCONTENTS_PLAYERCLIP;
 534                 if (IS_BOT_CLIENT(this) && autocvar_g_botclip_collisions)
 535                         this.dphitcontentsmask |= DPCONTENTS_BOTCLIP;
 536                 this.frags = FRAGS_PLAYER;
 537                 if (INDEPENDENT_PLAYERS) MAKE_INDEPENDENT_PLAYER(this);
 538                 this.flags = FL_CLIENT | FL_PICKUPITEMS;
 539                 if (autocvar__notarget)
 540                         this.flags |= FL_NOTARGET;
 541                 this.takedamage = DAMAGE_AIM;
 542                 this.effects = EF_TELEPORT_BIT | EF_RESTARTANIM_BIT;
 543                 this.dmg = 2; // WTF
 544
 545                 if (warmup_stage) {
 546                         this.ammo_shells = warmup_start_ammo_shells;
 547                         this.ammo_nails = warmup_start_ammo_nails;
 548                         this.ammo_rockets = warmup_start_ammo_rockets;
 549                         this.ammo_cells = warmup_start_ammo_cells;
 550                         this.ammo_plasma = warmup_start_ammo_plasma;
 551                         this.ammo_fuel = warmup_start_ammo_fuel;
 552                         this.health = warmup_start_health;
 553                         this.armorvalue = warmup_start_armorvalue;
 554                         this.weapons = WARMUP_START_WEAPONS;
 555                 } else {
 556                         this.ammo_shells = start_ammo_shells;
 557                         this.ammo_nails = start_ammo_nails;
 558                         this.ammo_rockets = start_ammo_rockets;
 559                         this.ammo_cells = start_ammo_cells;
 560                         this.ammo_plasma = start_ammo_plasma;
 561                         this.ammo_fuel = start_ammo_fuel;
 562                         this.health = start_health;
 563                         this.armorvalue = start_armorvalue;
 564                         this.weapons = start_weapons;
 565                 }
 566                 SetSpectatee_status(this, 0);
 567
 568                 this.superweapons_finished = (this.weapons & WEPSET_SUPERWEAPONS) ? time + autocvar_g_balance_superweapons_time : 0;
 569
 570                 this.items = start_items;
 571
 572                 this.spawnshieldtime = time + autocvar_g_spawnshieldtime;
 573                 this.pauserotarmor_finished = time + autocvar_g_balance_pause_armor_rot_spawn;
 574                 this.pauserothealth_finished = time + autocvar_g_balance_pause_health_rot_spawn;
 575                 this.pauserotfuel_finished = time + autocvar_g_balance_pause_fuel_rot_spawn;
 576                 this.pauseregen_finished = time + autocvar_g_balance_pause_health_regen_spawn;
 577                 // extend the pause of rotting if client was reset at the beginning of the countdown
 578                 if (!autocvar_sv_ready_restart_after_countdown && time < game_starttime) { // TODO why is this cvar NOTted?
 579                         float f = game_starttime - time;
 580                         this.spawnshieldtime += f;
 581                         this.pauserotarmor_finished += f;
 582                         this.pauserothealth_finished += f;
 583                         this.pauseregen_finished += f;
 584                 }
 585                 this.damageforcescale = 2;
 586                 this.death_time = 0;
 587                 this.respawn_flags = 0;
 588                 this.respawn_time = 0;
 589                 this.stat_respawn_time = 0;
 590                 this.scale = autocvar_sv_player_scale;
 591                 this.fade_time = 0;
 592                 this.pain_frame = 0;
 593                 this.pain_finished = 0;
 594                 this.pushltime = 0;
 595                 setthink(this, func_null); // players have no think function
 596                 this.nextthink = 0;
 597                 this.dmg_team = 0;
 598                 this.ballistics_density = autocvar_g_ballistics_density_player;
 599
 600                 this.deadflag = DEAD_NO;
 601
 602                 this.angles = spot.angles;
 603                 this.angles_z = 0; // never spawn tilted even if the spot says to
 604                 if (IS_BOT_CLIENT(this))
 605                         this.v_angle = this.angles;
 606                 this.fixangle = true; // turn this way immediately
 607                 this.oldvelocity = this.velocity = '0 0 0';
 608                 this.avelocity = '0 0 0';
 609                 this.punchangle = '0 0 0';
 610                 this.punchvector = '0 0 0';
 611
 612                 this.strength_finished = 0;
 613                 this.invincible_finished = 0;
 614                 this.fire_endtime = -1;
 615                 this.revival_time = 0;
 616                 this.air_finished = time + 12;
 617
 618                 entity spawnevent = new_pure(spawnevent);
 619                 spawnevent.owner = this;
 620                 Net_LinkEntity(spawnevent, false, 0.5, SpawnEvent_Send);
 621
 622                 // Cut off any still running player sounds.
 623                 stopsound(this, CH_PLAYER_SINGLE);
 624
 625                 this.model = "";
 626                 FixPlayermodel(this);
 627                 this.drawonlytoclient = NULL;
 628
 629                 this.crouch = false;
 630                 this.view_ofs = STAT(PL_VIEW_OFS, NULL);
 631                 setsize(this, STAT(PL_MIN, NULL), STAT(PL_MAX, NULL));
 632                 this.spawnorigin = spot.origin;
 633                 setorigin(this, spot.origin + '0 0 1' * (1 - this.mins.z - 24));
 634                 // don't reset back to last position, even if new position is stuck in solid
 635                 this.oldorigin = this.origin;
 636                 this.prevorigin = this.origin;
 637                 this.lastteleporttime = time; // prevent insane speeds due to changing origin
 638                 if(this.conveyor)
 639                         IL_REMOVE(g_conveyed, this);
 640                 this.conveyor = NULL; // prevent conveyors at the previous location from moving a freshly spawned player
 641                 this.hud = HUD_NORMAL;
 642
 643                 this.event_damage = PlayerDamage;
 644
 645                 if(!this.bot_attack)
 646                         IL_PUSH(g_bot_targets, this);
 647                 this.bot_attack = true;
 648                 this.monster_attack = true;
 649
 650                 PHYS_INPUT_BUTTON_ATCK(this) = PHYS_INPUT_BUTTON_JUMP(this) = PHYS_INPUT_BUTTON_ATCK2(this) = false;
 651
 652                 if (this.killcount == FRAGS_SPECTATOR) {
 653                         PlayerScore_Clear(this);
 654                         this.killcount = 0;
 655                 }
 656
 657                 for (int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 658                 {
 659                         CL_SpawnWeaponentity(this, weaponentities[slot]);
 660                 }
 661                 this.alpha = default_player_alpha;
 662                 this.colormod = '1 1 1' * autocvar_g_player_brightness;
 663                 this.exteriorweaponentity.alpha = default_weapon_alpha;
 664
 665                 this.speedrunning = false;
 666
 667                 target_voicescript_clear(this);
 668
 669                 // reset fields the weapons may use
 670                 FOREACH(Weapons, true, LAMBDA(
 671                         it.wr_resetplayer(it, this);
 672                         // reload all reloadable weapons
 673                         if (it.spawnflags & WEP_FLAG_RELOADABLE) {
 674                                 this.weapon_load[it.m_id] = it.reloading_ammo;
 675                         }
 676                 ));
 677
 678                 {
 679                         string s = spot.target;
 680                         spot.target = string_null;
 681                         SUB_UseTargets(spot, this, NULL);
 682                         spot.target = s;
 683                 }
 684
 685                 Unfreeze(this);
 686
 687                 MUTATOR_CALLHOOK(PlayerSpawn, this, spot);
 688
 689                 if (autocvar_spawn_debug)
 690                 {
 691                         sprint(this, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
 692                         delete(spot); // usefull for checking if there are spawnpoints, that let drop through the floor
 693                 }
 694
 695                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 696                 {
 697                         .entity weaponentity = weaponentities[slot];
 698                         if(slot == 0)
 699                                 this.(weaponentity).m_switchweapon = w_getbestweapon(this);
 700                         else
 701                                 this.(weaponentity).m_switchweapon = WEP_Null;
 702                         this.(weaponentity).weaponname = "";
 703                         this.(weaponentity).m_switchingweapon = WEP_Null;
 704                 }
 705
 706                 this.cnt = -1; // TODO
 707
 708                 if (!warmup_stage && !this.alivetime)
 709                         this.alivetime = time;
 710
 711                 antilag_clear(this, CS(this));
 712         }
 713 }
 714
 715 void ClientInit_misc(entity this);
 716
 717 .float ebouncefactor, ebouncestop; // electro's values
 718 // TODO do we need all these fields, or should we stop autodetecting runtime
 719 // changes and just have a console command to update this?
 720 bool ClientInit_SendEntity(entity this, entity to, int sf)
 721 {
 722         WriteHeader(MSG_ENTITY, _ENT_CLIENT_INIT);
 723         return = true;
 724         msg_entity = to;
 725         // MSG_INIT replacement
 726         // TODO: make easier to use
 727         Registry_send_all();
 728         W_PROP_reload(MSG_ONE, to);
 729         ClientInit_misc(this);
 730         MUTATOR_CALLHOOK(Ent_Init);
 731 }
 732 void ClientInit_misc(entity this)
 733 {
 734         int channel = MSG_ONE;
 735         WriteHeader(channel, ENT_CLIENT_INIT);
 736         WriteByte(channel, g_nexball_meter_period * 32);
 737         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[0]));
 738         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[1]));
 739         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[2]));
 740         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[3]));
 741         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[0]));
 742         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[1]));
 743         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[2]));
 744         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[3]));
 745
 746         if(sv_foginterval && world.fog != "")
 747                 WriteString(channel, world.fog);
 748         else
 749                 WriteString(channel, "");
 750         WriteByte(channel, this.count * 255.0); // g_balance_armor_blockpercent
 751         WriteByte(channel, serverflags);
 752         WriteCoord(channel, autocvar_g_trueaim_minrange);
 753 }
 754
 755 void ClientInit_CheckUpdate(entity this)
 756 {
 757         this.nextthink = time;
 758         if(this.count != autocvar_g_balance_armor_blockpercent)
 759         {
 760                 this.count = autocvar_g_balance_armor_blockpercent;
 761                 this.SendFlags |= 1;
 762         }
 763 }
 764
 765 void ClientInit_Spawn()
 766 {
 767         entity e = new_pure(clientinit);
 768         setthink(e, ClientInit_CheckUpdate);
 769         Net_LinkEntity(e, false, 0, ClientInit_SendEntity);
 770
 771         ClientInit_CheckUpdate(e);
 772 }
 773
 774 /*
 775 =============
 776 SetNewParms
 777 =============
 778 */
 779 void SetNewParms ()
 780 {
 781         // initialize parms for a new player
 782         parm1 = -(86400 * 366);
 783
 784         MUTATOR_CALLHOOK(SetNewParms);
 785 }
 786
 787 /*
 788 =============
 789 SetChangeParms
 790 =============
 791 */
 792 void SetChangeParms (entity this)
 793 {
 794         // save parms for level change
 795         parm1 = this.parm_idlesince - time;
 796
 797         MUTATOR_CALLHOOK(SetChangeParms);
 798 }
 799
 800 /*
 801 =============
 802 DecodeLevelParms
 803 =============
 804 */
 805 void DecodeLevelParms(entity this)
 806 {
 807         // load parms
 808         this.parm_idlesince = parm1;
 809         if (this.parm_idlesince == -(86400 * 366))
 810                 this.parm_idlesince = time;
 811
 812         // whatever happens, allow 60 seconds of idling directly after connect for map loading
 813         this.parm_idlesince = max(this.parm_idlesince, time - sv_maxidle + 60);
 814
 815         MUTATOR_CALLHOOK(DecodeLevelParms);
 816 }
 817
 818 /*
 819 =============
 820 ClientKill
 821
 822 Called when a client types 'kill' in the console
 823 =============
 824 */
 825
 826 .float clientkill_nexttime;
 827 void ClientKill_Now_TeamChange(entity this)
 828 {
 829         if(this.killindicator_teamchange == -1)
 830         {
 831                 JoinBestTeam( this, false, true );
 832         }
 833         else if(this.killindicator_teamchange == -2)
 834         {
 835                 if(blockSpectators)
 836                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
 837                 PutObserverInServer(this);
 838         }
 839         else
 840                 SV_ChangeTeam(this, this.killindicator_teamchange - 1);
 841         this.killindicator_teamchange = 0;
 842 }
 843
 844 void ClientKill_Now(entity this)
 845 {
 846         if(this.vehicle)
 847         {
 848             vehicles_exit(this.vehicle, VHEF_RELEASE);
 849             if(!this.killindicator_teamchange)
 850             {
 851             this.vehicle_health = -1;
 852             Damage(this, this, this, 1 , DEATH_KILL.m_id, this.origin, '0 0 0');
 853             }
 854         }
 855
 856         if(this.killindicator && !wasfreed(this.killindicator))
 857                 delete(this.killindicator);
 858
 859         this.killindicator = NULL;
 860
 861         if(this.killindicator_teamchange)
 862                 ClientKill_Now_TeamChange(this);
 863
 864         if(!IS_SPEC(this) && !IS_OBSERVER(this))
 865                 Damage(this, this, this, 100000, DEATH_KILL.m_id, this.origin, '0 0 0');
 866
 867         // now I am sure the player IS dead
 868 }
 869 void KillIndicator_Think(entity this)
 870 {
 871         if (gameover)
 872         {
 873                 this.owner.killindicator = NULL;
 874                 delete(this);
 875                 return;
 876         }
 877
 878         if (this.owner.alpha < 0 && !this.owner.vehicle)
 879         {
 880                 this.owner.killindicator = NULL;
 881                 delete(this);
 882                 return;
 883         }
 884
 885         if(this.cnt <= 0)
 886         {
 887                 ClientKill_Now(this.owner);
 888                 return;
 889         }
 890     else if(g_cts && this.health == 1) // health == 1 means that it's silent
 891     {
 892         this.nextthink = time + 1;
 893         this.cnt -= 1;
 894     }
 895         else
 896         {
 897                 if(this.cnt <= 10)
 898                         setmodel(this, MDL_NUM(this.cnt));
 899                 if(IS_REAL_CLIENT(this.owner))
 900                 {
 901                         if(this.cnt <= 10)
 902                                 { Send_Notification(NOTIF_ONE, this.owner, MSG_ANNCE, Announcer_PickNumber(CNT_KILL, this.cnt)); }
 903                 }
 904                 this.nextthink = time + 1;
 905                 this.cnt -= 1;
 906         }
 907 }
 908
 909 float clientkilltime;
 910 void ClientKill_TeamChange (entity this, float targetteam) // 0 = don't change, -1 = auto, -2 = spec
 911 {
 912         float killtime;
 913         float starttime;
 914
 915         if (gameover)
 916                 return;
 917
 918         killtime = autocvar_g_balance_kill_delay;
 919
 920         if(g_race_qualifying || g_cts)
 921                 killtime = 0;
 922
 923     if(MUTATOR_CALLHOOK(ClientKill, this, killtime))
 924         return;
 925
 926         this.killindicator_teamchange = targetteam;
 927
 928     if(!this.killindicator)
 929         {
 930                 if(!IS_DEAD(this))
 931                 {
 932                         killtime = max(killtime, this.clientkill_nexttime - time);
 933                         this.clientkill_nexttime = time + killtime + autocvar_g_balance_kill_antispam;
 934                 }
 935
 936                 if(killtime <= 0 || !IS_PLAYER(this) || IS_DEAD(this))
 937                 {
 938                         ClientKill_Now(this);
 939                 }
 940                 else
 941                 {
 942                         starttime = max(time, clientkilltime);
 943
 944                         this.killindicator = spawn();
 945                         this.killindicator.owner = this;
 946                         this.killindicator.scale = 0.5;
 947                         setattachment(this.killindicator, this, "");
 948                         setorigin(this.killindicator, '0 0 52');
 949                         setthink(this.killindicator, KillIndicator_Think);
 950                         this.killindicator.nextthink = starttime + (this.lip) * 0.05;
 951                         clientkilltime = max(clientkilltime, this.killindicator.nextthink + 0.05);
 952                         this.killindicator.cnt = ceil(killtime);
 953                         this.killindicator.count = bound(0, ceil(killtime), 10);
 954                         //sprint(this, strcat("^1You'll be dead in ", ftos(this.killindicator.cnt), " seconds\n"));
 955
 956                         IL_EACH(g_clones, it.enemy == this && !(it.effects & CSQCMODEL_EF_RESPAWNGHOST),
 957                         {
 958                                 it.killindicator = spawn();
 959                                 it.killindicator.owner = it;
 960                                 it.killindicator.scale = 0.5;
 961                                 setattachment(it.killindicator, it, "");
 962                                 setorigin(it.killindicator, '0 0 52');
 963                                 setthink(it.killindicator, KillIndicator_Think);
 964                                 it.killindicator.nextthink = starttime + (it.lip) * 0.05;
 965                                 //clientkilltime = max(clientkilltime, it.killindicator.nextthink + 0.05);
 966                                 it.killindicator.cnt = ceil(killtime);
 967                         });
 968                         this.lip = 0;
 969                 }
 970         }
 971         if(this.killindicator)
 972         {
 973                 if(targetteam == 0) // just die
 974                 {
 975                         this.killindicator.colormod = '0 0 0';
 976                         if(IS_REAL_CLIENT(this))
 977                         if(this.killindicator.cnt > 0)
 978                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_TEAMCHANGE_SUICIDE, this.killindicator.cnt);
 979                 }
 980                 else if(targetteam == -1) // auto
 981                 {
 982                         this.killindicator.colormod = '0 1 0';
 983                         if(IS_REAL_CLIENT(this))
 984                         if(this.killindicator.cnt > 0)
 985                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_TEAMCHANGE_AUTO, this.killindicator.cnt);
 986                 }
 987                 else if(targetteam == -2) // spectate
 988                 {
 989                         this.killindicator.colormod = '0.5 0.5 0.5';
 990                         if(IS_REAL_CLIENT(this))
 991                         if(this.killindicator.cnt > 0)
 992                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_TEAMCHANGE_SPECTATE, this.killindicator.cnt);
 993                 }
 994                 else
 995                 {
 996                         this.killindicator.colormod = Team_ColorRGB(targetteam);
 997                         if(IS_REAL_CLIENT(this))
 998                         if(this.killindicator.cnt > 0)
 999                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, APP_TEAM_NUM(targetteam, CENTER_TEAMCHANGE), this.killindicator.cnt);
1000                 }
1001         }
1002
1003 }
1004
1005 void ClientKill (entity this)
1006 {
1007         if(gameover) return;
1008         if(this.player_blocked) return;
1009         if(STAT(FROZEN, this)) return;
1010
1011         ClientKill_TeamChange(this, 0);
1012 }
1013
1014 void FixClientCvars(entity e)
1015 {
1016         // send prediction settings to the client
1017         stuffcmd(e, "\nin_bindmap 0 0\n");
1018         if(autocvar_g_antilag == 3) // client side hitscan
1019                 stuffcmd(e, "cl_cmd settemp cl_prydoncursor_notrace 0\n");
1020         if(autocvar_sv_gentle)
1021                 stuffcmd(e, "cl_cmd settemp cl_gentle 1\n");
1022
1023         MUTATOR_CALLHOOK(FixClientCvars, e);
1024 }
1025
1026 float PlayerInIDList(entity p, string idlist)
1027 {
1028         float n, i;
1029         string s;
1030
1031         // NOTE: we do NOT check crypto_idfp_signed here, an unsigned ID is fine too for this
1032         if (!p.crypto_idfp)
1033                 return 0;
1034
1035         // this function allows abbreviated player IDs too!
1036         n = tokenize_console(idlist);
1037         for(i = 0; i < n; ++i)
1038         {
1039                 s = argv(i);
1040                 if(s == substring(p.crypto_idfp, 0, strlen(s)))
1041                         return 1;
1042         }
1043
1044         return 0;
1045 }
1046
1047 #ifdef DP_EXT_PRECONNECT
1048 /*
1049 =============
1050 ClientPreConnect
1051
1052 Called once (not at each match start) when a client begins a connection to the server
1053 =============
1054 */
1055 void ClientPreConnect ()
1056 {ENGINE_EVENT();
1057         if(autocvar_sv_eventlog)
1058         {
1059                 GameLogEcho(sprintf(":connect:%d:%d:%s",
1060                         this.playerid,
1061                         etof(this),
1062                         ((IS_REAL_CLIENT(this)) ? this.netaddress : "bot")
1063                 ));
1064         }
1065 }
1066 #endif
1067
1068 /**
1069 =============
1070 ClientConnect
1071
1072 Called when a client connects to the server
1073 =============
1074 */
1075 void ClientConnect(entity this)
1076 {
1077         if (Ban_MaybeEnforceBanOnce(this)) return;
1078         assert(!IS_CLIENT(this), return);
1079         this.flags |= FL_CLIENT;
1080         assert(player_count >= 0, player_count = 0);
1081
1082 #ifdef WATERMARK
1083         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_WATERMARK, WATERMARK);
1084 #endif
1085         this.version_nagtime = time + 10 + random() * 10;
1086         TRANSMUTE(Client, this);
1087
1088         // identify the right forced team
1089         if (autocvar_g_campaign)
1090         {
1091                 if (IS_REAL_CLIENT(this)) // only players, not bots
1092                 {
1093                         switch (autocvar_g_campaign_forceteam)
1094                         {
1095                                 case 1: this.team_forced = NUM_TEAM_1; break;
1096                                 case 2: this.team_forced = NUM_TEAM_2; break;
1097                                 case 3: this.team_forced = NUM_TEAM_3; break;
1098                                 case 4: this.team_forced = NUM_TEAM_4; break;
1099                                 default: this.team_forced = 0;
1100                         }
1101                 }
1102         }
1103         else if (PlayerInIDList(this, autocvar_g_forced_team_red))    this.team_forced = NUM_TEAM_1;
1104         else if (PlayerInIDList(this, autocvar_g_forced_team_blue))   this.team_forced = NUM_TEAM_2;
1105         else if (PlayerInIDList(this, autocvar_g_forced_team_yellow)) this.team_forced = NUM_TEAM_3;
1106         else if (PlayerInIDList(this, autocvar_g_forced_team_pink))   this.team_forced = NUM_TEAM_4;
1107         else switch (autocvar_g_forced_team_otherwise)
1108         {
1109                 default: this.team_forced = 0; break;
1110                 case "red": this.team_forced = NUM_TEAM_1; break;
1111                 case "blue": this.team_forced = NUM_TEAM_2; break;
1112                 case "yellow": this.team_forced = NUM_TEAM_3; break;
1113                 case "pink": this.team_forced = NUM_TEAM_4; break;
1114                 case "spectate":
1115                 case "spectator":
1116                         this.team_forced = -1;
1117                         break;
1118         }
1119         if (!teamplay && this.team_forced > 0) this.team_forced = 0;
1120
1121     {
1122         int id = this.playerid;
1123         this.playerid = 0; // silent
1124             JoinBestTeam(this, false, false); // if the team number is valid, keep it
1125             this.playerid = id;
1126     }
1127
1128         if (autocvar_sv_spectate || autocvar_g_campaign || this.team_forced < 0) {
1129                 TRANSMUTE(Observer, this);
1130         } else {
1131                 if (!teamplay || autocvar_g_balance_teams) {
1132                         TRANSMUTE(Player, this);
1133                         campaign_bots_may_start = true;
1134                 } else {
1135                         TRANSMUTE(Observer, this); // do it anyway
1136                 }
1137         }
1138
1139         PlayerStats_GameReport_AddEvent(sprintf("kills-%d", this.playerid));
1140
1141         // always track bots, don't ask for cl_allow_uidtracking
1142     if (IS_BOT_CLIENT(this)) PlayerStats_GameReport_AddPlayer(this);
1143
1144         if (autocvar_sv_eventlog)
1145                 GameLogEcho(strcat(":join:", ftos(this.playerid), ":", ftos(etof(this)), ":", ((IS_REAL_CLIENT(this)) ? this.netaddress : "bot"), ":", this.netname));
1146
1147         LogTeamchange(this.playerid, this.team, 1);
1148
1149         this.just_joined = true;  // stop spamming the eventlog with additional lines when the client connects
1150
1151         this.netname_previous = strzone(this.netname);
1152
1153         if(teamplay && IS_PLAYER(this))
1154                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, APP_TEAM_NUM(this.team, INFO_JOIN_CONNECT_TEAM), this.netname);
1155         else
1156                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_JOIN_CONNECT, this.netname);
1157
1158         stuffcmd(this, clientstuff, "\n");
1159         stuffcmd(this, "cl_particles_reloadeffects\n"); // TODO do we still need this?
1160
1161         FixClientCvars(this);
1162
1163         // get version info from player
1164         stuffcmd(this, "cmd clientversion $gameversion\n");
1165
1166         // notify about available teams
1167         if (teamplay)
1168         {
1169                 CheckAllowedTeams(this);
1170                 int t = 0;
1171                 if (c1 >= 0) t |= BIT(0);
1172                 if (c2 >= 0) t |= BIT(1);
1173                 if (c3 >= 0) t |= BIT(2);
1174                 if (c4 >= 0) t |= BIT(3);
1175                 stuffcmd(this, sprintf("set _teams_available %d\n", t));
1176         }
1177         else
1178         {
1179                 stuffcmd(this, "set _teams_available 0\n");
1180         }
1181
1182         bot_relinkplayerlist();
1183
1184         this.spectatortime = time;
1185         if (blockSpectators)
1186         {
1187                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
1188         }
1189
1190         this.jointime = time;
1191         this.allowed_timeouts = autocvar_sv_timeout_number;
1192
1193         if (IS_REAL_CLIENT(this))
1194         {
1195                 if (!autocvar_g_campaign)
1196                 {
1197                         this.motd_actived_time = -1;
1198                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOTD, getwelcomemessage(this));
1199                 }
1200
1201                 if (g_weaponarena_weapons == WEPSET(TUBA))
1202                         stuffcmd(this, "cl_cmd settemp chase_active 1\n");
1203         }
1204
1205         if (!sv_foginterval && world.fog != "")
1206                 stuffcmd(this, strcat("\nfog ", world.fog, "\nr_fog_exp2 0\nr_drawfog 1\n"));
1207
1208         if (autocvar_sv_teamnagger && !(autocvar_bot_vs_human && AvailableTeams() == 2))
1209                 if (!g_ca && !g_cts && !g_race) // teamnagger is currently bad for ca, race & cts
1210                         send_CSQC_teamnagger();
1211
1212         CSQCMODEL_AUTOINIT(this);
1213
1214         this.model_randomizer = random();
1215
1216         if (IS_REAL_CLIENT(this))
1217                 sv_notice_join(this);
1218
1219         IL_EACH(g_initforplayer, it.init_for_player, {
1220                 it.init_for_player(it, this);
1221         });
1222
1223         MUTATOR_CALLHOOK(ClientConnect, this);
1224 }
1225 /*
1226 =============
1227 ClientDisconnect
1228
1229 Called when a client disconnects from the server
1230 =============
1231 */
1232 .entity chatbubbleentity;
1233 void ReadyCount();
1234 void ClientDisconnect(entity this)
1235 {
1236         assert(IS_CLIENT(this), return);
1237
1238         PlayerStats_GameReport_FinalizePlayer(this);
1239         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
1240         if (this.active_minigame) part_minigame(this);
1241         if (IS_PLAYER(this)) Send_Effect(EFFECT_SPAWN_NEUTRAL, this.origin, '0 0 0', 1);
1242
1243         if (autocvar_sv_eventlog)
1244                 GameLogEcho(strcat(":part:", ftos(this.playerid)));
1245
1246         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_QUIT_DISCONNECT, this.netname);
1247
1248         SetSpectatee(this, NULL);
1249
1250     MUTATOR_CALLHOOK(ClientDisconnect, this);
1251
1252         ClientState_detach(this);
1253
1254         Portal_ClearAll(this);
1255
1256         Unfreeze(this);
1257
1258         RemoveGrapplingHook(this);
1259
1260         // Here, everything has been done that requires this player to be a client.
1261
1262         this.flags &= ~FL_CLIENT;
1263
1264         if (this.chatbubbleentity) delete(this.chatbubbleentity);
1265         if (this.killindicator) delete(this.killindicator);
1266
1267         WaypointSprite_PlayerGone(this);
1268
1269         bot_relinkplayerlist();
1270
1271         if (this.netname_previous) strunzone(this.netname_previous);
1272         if (this.clientstatus) strunzone(this.clientstatus);
1273         if (this.weaponorder_byimpulse) strunzone(this.weaponorder_byimpulse);
1274         if (this.personal) delete(this.personal);
1275
1276         this.playerid = 0;
1277         ReadyCount();
1278         if (vote_called && IS_REAL_CLIENT(this)) VoteCount(false);
1279 }
1280
1281 void ChatBubbleThink(entity this)
1282 {
1283         this.nextthink = time;
1284         if ((this.owner.alpha < 0) || this.owner.chatbubbleentity != this)
1285         {
1286                 if(this.owner) // but why can that ever be NULL?
1287                         this.owner.chatbubbleentity = NULL;
1288                 delete(this);
1289                 return;
1290         }
1291
1292         this.mdl = "";
1293
1294         if ( !IS_DEAD(this.owner) && IS_PLAYER(this.owner) )
1295         {
1296                 if ( this.owner.active_minigame )
1297                         this.mdl = "models/sprites/minigame_busy.iqm";
1298                 else if (PHYS_INPUT_BUTTON_CHAT(this.owner))
1299                         this.mdl = "models/misc/chatbubble.spr";
1300         }
1301
1302         if ( this.model != this.mdl )
1303                 _setmodel(this, this.mdl);
1304
1305 }
1306
1307 void UpdateChatBubble(entity this)
1308 {
1309         if (this.alpha < 0)
1310                 return;
1311         // spawn a chatbubble entity if needed
1312         if (!this.chatbubbleentity)
1313         {
1314                 this.chatbubbleentity = new(chatbubbleentity);
1315                 this.chatbubbleentity.owner = this;
1316                 this.chatbubbleentity.exteriormodeltoclient = this;
1317                 setthink(this.chatbubbleentity, ChatBubbleThink);
1318                 this.chatbubbleentity.nextthink = time;
1319                 setmodel(this.chatbubbleentity, MDL_CHAT); // precision set below
1320                 //setorigin(this.chatbubbleentity, this.origin + '0 0 15' + this.maxs_z * '0 0 1');
1321                 setorigin(this.chatbubbleentity, '0 0 15' + this.maxs_z * '0 0 1');
1322                 setattachment(this.chatbubbleentity, this, "");  // sticks to moving player better, also conserves bandwidth
1323                 this.chatbubbleentity.mdl = this.chatbubbleentity.model;
1324                 //this.chatbubbleentity.model = "";
1325                 this.chatbubbleentity.effects = EF_LOWPRECISION;
1326         }
1327 }
1328
1329
1330 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
1331 // added to the model skins
1332 /*void UpdateColorModHack()
1333 {
1334         float c;
1335         c = this.clientcolors & 15;
1336         // LordHavoc: only bothering to support white, green, red, yellow, blue
1337              if (!teamplay) this.colormod = '0 0 0';
1338         else if (c ==  0) this.colormod = '1.00 1.00 1.00';
1339         else if (c ==  3) this.colormod = '0.10 1.73 0.10';
1340         else if (c ==  4) this.colormod = '1.73 0.10 0.10';
1341         else if (c == 12) this.colormod = '1.22 1.22 0.10';
1342         else if (c == 13) this.colormod = '0.10 0.10 1.73';
1343         else this.colormod = '1 1 1';
1344 }*/
1345
1346 void respawn(entity this)
1347 {
1348         if(this.alpha >= 0 && autocvar_g_respawn_ghosts)
1349         {
1350                 this.solid = SOLID_NOT;
1351                 this.takedamage = DAMAGE_NO;
1352                 set_movetype(this, MOVETYPE_FLY);
1353                 this.velocity = '0 0 1' * autocvar_g_respawn_ghosts_speed;
1354                 this.avelocity = randomvec() * autocvar_g_respawn_ghosts_speed * 3 - randomvec() * autocvar_g_respawn_ghosts_speed * 3;
1355                 this.effects |= CSQCMODEL_EF_RESPAWNGHOST;
1356                 Send_Effect(EFFECT_RESPAWN_GHOST, this.origin, '0 0 0', 1);
1357                 if(autocvar_g_respawn_ghosts_maxtime)
1358                         SUB_SetFade (this, time + autocvar_g_respawn_ghosts_maxtime / 2 + random () * (autocvar_g_respawn_ghosts_maxtime - autocvar_g_respawn_ghosts_maxtime / 2), 1.5);
1359         }
1360
1361         CopyBody(this, 1);
1362
1363         this.effects |= EF_NODRAW; // prevent another CopyBody
1364         PutClientInServer(this);
1365 }
1366
1367 void play_countdown(entity this, float finished, Sound samp)
1368 {
1369     TC(Sound, samp);
1370         if(IS_REAL_CLIENT(this))
1371                 if(floor(finished - time - frametime) != floor(finished - time))
1372                         if(finished - time < 6)
1373                                 sound (this, CH_INFO, samp, VOL_BASE, ATTEN_NORM);
1374 }
1375
1376 void player_powerups(entity this)
1377 {
1378         // add a way to see what the items were BEFORE all of these checks for the mutator hook
1379         int items_prev = this.items;
1380
1381         if((this.items & IT_USING_JETPACK) && !IS_DEAD(this) && !gameover)
1382                 this.modelflags |= MF_ROCKET;
1383         else
1384                 this.modelflags &= ~MF_ROCKET;
1385
1386         this.effects &= ~(EF_RED | EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT | EF_FLAME | EF_NODEPTHTEST);
1387
1388         if((this.alpha < 0 || IS_DEAD(this)) && !this.vehicle) // don't apply the flags if the player is gibbed
1389                 return;
1390
1391         Fire_ApplyDamage(this);
1392         Fire_ApplyEffect(this);
1393
1394         if (!g_instagib)
1395         {
1396                 if (this.items & ITEM_Strength.m_itemid)
1397                 {
1398                         play_countdown(this, this.strength_finished, SND_POWEROFF);
1399                         this.effects = this.effects | (EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT);
1400                         if (time > this.strength_finished)
1401                         {
1402                                 this.items = this.items - (this.items & ITEM_Strength.m_itemid);
1403                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERDOWN_STRENGTH, this.netname);
1404                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERDOWN_STRENGTH);
1405                         }
1406                 }
1407                 else
1408                 {
1409                         if (time < this.strength_finished)
1410                         {
1411                                 this.items = this.items | ITEM_Strength.m_itemid;
1412                                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERUP_STRENGTH, this.netname);
1413                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERUP_STRENGTH);
1414                         }
1415                 }
1416                 if (this.items & ITEM_Shield.m_itemid)
1417                 {
1418                         play_countdown(this, this.invincible_finished, SND_POWEROFF);
1419                         this.effects = this.effects | (EF_RED | EF_ADDITIVE | EF_FULLBRIGHT);
1420                         if (time > this.invincible_finished)
1421                         {
1422                                 this.items = this.items - (this.items & ITEM_Shield.m_itemid);
1423                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERDOWN_SHIELD, this.netname);
1424                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERDOWN_SHIELD);
1425                         }
1426                 }
1427                 else
1428                 {
1429                         if (time < this.invincible_finished)
1430                         {
1431                                 this.items = this.items | ITEM_Shield.m_itemid;
1432                                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERUP_SHIELD, this.netname);
1433                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERUP_SHIELD);
1434                         }
1435                 }
1436                 if (this.items & IT_SUPERWEAPON)
1437                 {
1438                         if (!(this.weapons & WEPSET_SUPERWEAPONS))
1439                         {
1440                                 this.superweapons_finished = 0;
1441                                 this.items = this.items - (this.items & IT_SUPERWEAPON);
1442                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_LOST, this.netname);
1443                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_LOST);
1444                         }
1445                         else if (this.items & IT_UNLIMITED_SUPERWEAPONS)
1446                         {
1447                                 // don't let them run out
1448                         }
1449                         else
1450                         {
1451                                 play_countdown(this, this.superweapons_finished, SND_POWEROFF);
1452                                 if (time > this.superweapons_finished)
1453                                 {
1454                                         this.items = this.items - (this.items & IT_SUPERWEAPON);
1455                                         this.weapons &= ~WEPSET_SUPERWEAPONS;
1456                                         //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_BROKEN, this.netname);
1457                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_BROKEN);
1458                                 }
1459                         }
1460                 }
1461                 else if(this.weapons & WEPSET_SUPERWEAPONS)
1462                 {
1463                         if (time < this.superweapons_finished || (this.items & IT_UNLIMITED_SUPERWEAPONS))
1464                         {
1465                                 this.items = this.items | IT_SUPERWEAPON;
1466                                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_PICKUP, this.netname);
1467                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_PICKUP);
1468                         }
1469                         else
1470                         {
1471                                 this.superweapons_finished = 0;
1472                                 this.weapons &= ~WEPSET_SUPERWEAPONS;
1473                         }
1474                 }
1475                 else
1476                 {
1477                         this.superweapons_finished = 0;
1478                 }
1479         }
1480
1481         if(autocvar_g_nodepthtestplayers)
1482                 this.effects = this.effects | EF_NODEPTHTEST;
1483
1484         if(autocvar_g_fullbrightplayers)
1485                 this.effects = this.effects | EF_FULLBRIGHT;
1486
1487         if (time >= game_starttime)
1488         if (time < this.spawnshieldtime)
1489                 this.effects = this.effects | (EF_ADDITIVE | EF_FULLBRIGHT);
1490
1491         MUTATOR_CALLHOOK(PlayerPowerups, this, items_prev);
1492 }
1493
1494 float CalcRegen(float current, float stable, float regenfactor, float regenframetime)
1495 {
1496         if(current > stable)
1497                 return current;
1498         else if(current > stable - 0.25) // when close enough, "snap"
1499                 return stable;
1500         else
1501                 return min(stable, current + (stable - current) * regenfactor * regenframetime);
1502 }
1503
1504 float CalcRot(float current, float stable, float rotfactor, float rotframetime)
1505 {
1506         if(current < stable)
1507                 return current;
1508         else if(current < stable + 0.25) // when close enough, "snap"
1509                 return stable;
1510         else
1511                 return max(stable, current + (stable - current) * rotfactor * rotframetime);
1512 }
1513
1514 float CalcRotRegen(float current, float regenstable, float regenfactor, float regenlinear, float regenframetime, float rotstable, float rotfactor, float rotlinear, float rotframetime, float limit)
1515 {
1516         if(current > rotstable)
1517         {
1518                 if(rotframetime > 0)
1519                 {
1520                         current = CalcRot(current, rotstable, rotfactor, rotframetime);
1521                         current = max(rotstable, current - rotlinear * rotframetime);
1522                 }
1523         }
1524         else if(current < regenstable)
1525         {
1526                 if(regenframetime > 0)
1527                 {
1528                         current = CalcRegen(current, regenstable, regenfactor, regenframetime);
1529                         current = min(regenstable, current + regenlinear * regenframetime);
1530                 }
1531         }
1532
1533         if(current > limit)
1534                 current = limit;
1535
1536         return current;
1537 }
1538
1539 void player_regen(entity this)
1540 {
1541         float max_mod, regen_mod, rot_mod, limit_mod;
1542         max_mod = regen_mod = rot_mod = limit_mod = 1;
1543
1544         float regen_health = autocvar_g_balance_health_regen;
1545         float regen_health_linear = autocvar_g_balance_health_regenlinear;
1546         float regen_health_rot = autocvar_g_balance_health_rot;
1547         float regen_health_rotlinear = autocvar_g_balance_health_rotlinear;
1548         float regen_health_stable = autocvar_g_balance_health_regenstable;
1549         float regen_health_rotstable = autocvar_g_balance_health_rotstable;
1550         bool mutator_returnvalue = MUTATOR_CALLHOOK(PlayerRegen, this, max_mod, regen_mod, rot_mod, limit_mod, regen_health, regen_health_linear, regen_health_rot,
1551                 regen_health_rotlinear, regen_health_stable, regen_health_rotstable);
1552         max_mod = M_ARGV(1, float);
1553         regen_mod = M_ARGV(2, float);
1554         rot_mod = M_ARGV(3, float);
1555         limit_mod = M_ARGV(4, float);
1556         regen_health = M_ARGV(5, float);
1557         regen_health_linear = M_ARGV(6, float);
1558         regen_health_rot = M_ARGV(7, float);
1559         regen_health_rotlinear = M_ARGV(8, float);
1560         regen_health_stable = M_ARGV(9, float);
1561         regen_health_rotstable = M_ARGV(10, float);
1562
1563
1564         if(!mutator_returnvalue)
1565         if(!STAT(FROZEN, this))
1566         {
1567                 float mina, maxa, limith, limita;
1568                 maxa = autocvar_g_balance_armor_rotstable;
1569                 mina = autocvar_g_balance_armor_regenstable;
1570                 limith = autocvar_g_balance_health_limit;
1571                 limita = autocvar_g_balance_armor_limit;
1572
1573                 regen_health_rotstable = regen_health_rotstable * max_mod;
1574                 regen_health_stable = regen_health_stable * max_mod;
1575                 limith = limith * limit_mod;
1576                 limita = limita * limit_mod;
1577
1578                 this.armorvalue = CalcRotRegen(this.armorvalue, mina, autocvar_g_balance_armor_regen, autocvar_g_balance_armor_regenlinear, regen_mod * frametime * (time > this.pauseregen_finished), maxa, autocvar_g_balance_armor_rot, autocvar_g_balance_armor_rotlinear, rot_mod * frametime * (time > this.pauserotarmor_finished), limita);
1579                 this.health = CalcRotRegen(this.health, regen_health_stable, regen_health, regen_health_linear, regen_mod * frametime * (time > this.pauseregen_finished), regen_health_rotstable, regen_health_rot, regen_health_rotlinear, rot_mod * frametime * (time > this.pauserothealth_finished), limith);
1580         }
1581
1582         // if player rotted to death...  die!
1583         // check this outside above checks, as player may still be able to rot to death
1584         if(this.health < 1)
1585         {
1586                 if(this.vehicle)
1587                         vehicles_exit(this.vehicle, VHEF_RELEASE);
1588                 if(this.event_damage)
1589                         this.event_damage(this, this, this, 1, DEATH_ROT.m_id, this.origin, '0 0 0');
1590         }
1591
1592         if (!(this.items & IT_UNLIMITED_WEAPON_AMMO))
1593         {
1594                 float minf, maxf, limitf;
1595
1596                 maxf = autocvar_g_balance_fuel_rotstable;
1597                 minf = autocvar_g_balance_fuel_regenstable;
1598                 limitf = autocvar_g_balance_fuel_limit;
1599
1600                 this.ammo_fuel = CalcRotRegen(this.ammo_fuel, minf, autocvar_g_balance_fuel_regen, autocvar_g_balance_fuel_regenlinear, frametime * (time > this.pauseregen_finished) * ((this.items & ITEM_JetpackRegen.m_itemid) != 0), maxf, autocvar_g_balance_fuel_rot, autocvar_g_balance_fuel_rotlinear, frametime * (time > this.pauserotfuel_finished), limitf);
1601         }
1602 }
1603
1604 bool zoomstate_set;
1605 void SetZoomState(entity this, float z)
1606 {
1607         if(z != this.zoomstate)
1608         {
1609                 this.zoomstate = z;
1610                 ClientData_Touch(this);
1611         }
1612         zoomstate_set = true;
1613 }
1614
1615 void GetPressedKeys(entity this)
1616 {
1617         MUTATOR_CALLHOOK(GetPressedKeys, this);
1618         int keys = this.pressedkeys;
1619         keys = BITSET(keys, KEY_FORWARD,        this.movement.x > 0);
1620         keys = BITSET(keys, KEY_BACKWARD,       this.movement.x < 0);
1621         keys = BITSET(keys, KEY_RIGHT,          this.movement.y > 0);
1622         keys = BITSET(keys, KEY_LEFT,           this.movement.y < 0);
1623
1624         keys = BITSET(keys, KEY_JUMP,           PHYS_INPUT_BUTTON_JUMP(this));
1625         keys = BITSET(keys, KEY_CROUCH,         PHYS_INPUT_BUTTON_CROUCH(this));
1626         keys = BITSET(keys, KEY_ATCK,           PHYS_INPUT_BUTTON_ATCK(this));
1627         keys = BITSET(keys, KEY_ATCK2,          PHYS_INPUT_BUTTON_ATCK2(this));
1628         this.pressedkeys = keys;
1629 }
1630
1631 /*
1632 ======================
1633 spectate mode routines
1634 ======================
1635 */
1636
1637 void SpectateCopy(entity this, entity spectatee)
1638 {
1639     TC(Client, this); TC(Client, spectatee);
1640
1641         MUTATOR_CALLHOOK(SpectateCopy, spectatee, this);
1642         PS(this) = PS(spectatee);
1643         this.armortype = spectatee.armortype;
1644         this.armorvalue = spectatee.armorvalue;
1645         this.ammo_cells = spectatee.ammo_cells;
1646         this.ammo_plasma = spectatee.ammo_plasma;
1647         this.ammo_shells = spectatee.ammo_shells;
1648         this.ammo_nails = spectatee.ammo_nails;
1649         this.ammo_rockets = spectatee.ammo_rockets;
1650         this.ammo_fuel = spectatee.ammo_fuel;
1651         this.clip_load = spectatee.clip_load;
1652         this.clip_size = spectatee.clip_size;
1653         this.effects = spectatee.effects & EFMASK_CHEAP; // eat performance
1654         this.health = spectatee.health;
1655         this.impulse = 0;
1656         this.items = spectatee.items;
1657         this.last_pickup = spectatee.last_pickup;
1658         this.hit_time = spectatee.hit_time;
1659         this.strength_finished = spectatee.strength_finished;
1660         this.invincible_finished = spectatee.invincible_finished;
1661         this.pressedkeys = spectatee.pressedkeys;
1662         this.weapons = spectatee.weapons;
1663         this.vortex_charge = spectatee.vortex_charge;
1664         this.vortex_chargepool_ammo = spectatee.vortex_chargepool_ammo;
1665         this.hagar_load = spectatee.hagar_load;
1666         this.arc_heat_percent = spectatee.arc_heat_percent;
1667         this.minelayer_mines = spectatee.minelayer_mines;
1668         this.punchangle = spectatee.punchangle;
1669         this.view_ofs = spectatee.view_ofs;
1670         this.velocity = spectatee.velocity;
1671         this.dmg_take = spectatee.dmg_take;
1672         this.dmg_save = spectatee.dmg_save;
1673         this.dmg_inflictor = spectatee.dmg_inflictor;
1674         this.v_angle = spectatee.v_angle;
1675         this.angles = spectatee.v_angle;
1676         STAT(FROZEN, this) = STAT(FROZEN, spectatee);
1677         this.revive_progress = spectatee.revive_progress;
1678         if(!PHYS_INPUT_BUTTON_USE(this) && STAT(CAMERA_SPECTATOR, this) != 2)
1679                 this.fixangle = true;
1680         setorigin(this, spectatee.origin);
1681         setsize(this, spectatee.mins, spectatee.maxs);
1682         SetZoomState(this, spectatee.zoomstate);
1683
1684     anticheat_spectatecopy(this, spectatee);
1685         this.hud = spectatee.hud;
1686         if(spectatee.vehicle)
1687     {
1688         this.angles = spectatee.v_angle;
1689
1690         //this.fixangle = false;
1691         //this.velocity = spectatee.vehicle.velocity;
1692         this.vehicle_health = spectatee.vehicle_health;
1693         this.vehicle_shield = spectatee.vehicle_shield;
1694         this.vehicle_energy = spectatee.vehicle_energy;
1695         this.vehicle_ammo1 = spectatee.vehicle_ammo1;
1696         this.vehicle_ammo2 = spectatee.vehicle_ammo2;
1697         this.vehicle_reload1 = spectatee.vehicle_reload1;
1698         this.vehicle_reload2 = spectatee.vehicle_reload2;
1699
1700         //msg_entity = this;
1701
1702        // WriteByte (MSG_ONE, SVC_SETVIEWANGLES);
1703             //WriteAngle(MSG_ONE,  spectatee.v_angle.x);
1704            // WriteAngle(MSG_ONE,  spectatee.v_angle.y);
1705            // WriteAngle(MSG_ONE,  spectatee.v_angle.z);
1706
1707         //WriteByte (MSG_ONE, SVC_SETVIEW);
1708         //    WriteEntity(MSG_ONE, this);
1709         //makevectors(spectatee.v_angle);
1710         //setorigin(this, spectatee.origin - v_forward * 400 + v_up * 300);*/
1711     }
1712 }
1713
1714 bool SpectateUpdate(entity this)
1715 {
1716         if(!this.enemy)
1717                 return false;
1718
1719         if(!IS_PLAYER(this.enemy) || this == this.enemy)
1720         {
1721                 SetSpectatee(this, NULL);
1722                 return false;
1723         }
1724
1725         SpectateCopy(this, this.enemy);
1726
1727         return true;
1728 }
1729
1730 bool SpectateSet(entity this)
1731 {
1732         if(!IS_PLAYER(this.enemy))
1733                 return false;
1734
1735         ClientData_Touch(this.enemy);
1736
1737         msg_entity = this;
1738         WriteByte(MSG_ONE, SVC_SETVIEW);
1739         WriteEntity(MSG_ONE, this.enemy);
1740         set_movetype(this, MOVETYPE_NONE);
1741         accuracy_resend(this);
1742
1743         if(!SpectateUpdate(this))
1744                 PutObserverInServer(this);
1745
1746         return true;
1747 }
1748
1749 void SetSpectatee_status(entity this, int spectatee_num)
1750 {
1751         int oldspectatee_status = this.spectatee_status;
1752         this.spectatee_status = spectatee_num;
1753
1754         if (this.spectatee_status != oldspectatee_status)
1755         {
1756                 ClientData_Touch(this);
1757                 if (g_race || g_cts) race_InitSpectator();
1758         }
1759 }
1760
1761 void SetSpectatee(entity this, entity spectatee)
1762 {
1763         entity old_spectatee = this.enemy;
1764
1765         this.enemy = spectatee;
1766
1767         // WEAPONTODO
1768         // these are required to fix the spectator bug with arc
1769         if(old_spectatee)
1770         {
1771                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1772                 {
1773                         .entity weaponentity = weaponentities[slot];
1774                         if(old_spectatee.(weaponentity).arc_beam)
1775                                 old_spectatee.(weaponentity).arc_beam.SendFlags |= ARC_SF_SETTINGS;
1776                 }
1777         }
1778         if(this.enemy)
1779         {
1780                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1781                 {
1782                         .entity weaponentity = weaponentities[slot];
1783                         if(this.enemy.(weaponentity).arc_beam)
1784                                 this.enemy.(weaponentity).arc_beam.SendFlags |= ARC_SF_SETTINGS;
1785                 }
1786         }
1787
1788         if (this.enemy)
1789                 SetSpectatee_status(this, etof(this.enemy));
1790
1791         // needed to update spectator list
1792         if(old_spectatee) { ClientData_Touch(old_spectatee); }
1793 }
1794
1795 bool Spectate(entity this, entity pl)
1796 {
1797         if(MUTATOR_CALLHOOK(SpectateSet, this, pl))
1798                 return false;
1799         pl = M_ARGV(1, entity);
1800
1801         SetSpectatee(this, pl);
1802         return SpectateSet(this);
1803 }
1804
1805 bool SpectateNext(entity this)
1806 {
1807         entity ent = find(this.enemy, classname, STR_PLAYER);
1808
1809         if (MUTATOR_CALLHOOK(SpectateNext, this, ent))
1810                 ent = M_ARGV(1, entity);
1811         else if (!ent)
1812                 ent = find(ent, classname, STR_PLAYER);
1813
1814         if(ent) { SetSpectatee(this, ent); }
1815
1816         return SpectateSet(this);
1817 }
1818
1819 bool SpectatePrev(entity this)
1820 {
1821         // NOTE: chain order is from the highest to the lower entnum (unlike find)
1822         entity ent = findchain(classname, STR_PLAYER);
1823         if (!ent) // no player
1824                 return false;
1825
1826         entity first = ent;
1827         // skip players until current spectated player
1828         if(this.enemy)
1829         while(ent && ent != this.enemy)
1830                 ent = ent.chain;
1831
1832         switch (MUTATOR_CALLHOOK(SpectatePrev, this, ent, first))
1833         {
1834                 case MUT_SPECPREV_FOUND:
1835                     ent = M_ARGV(1, entity);
1836                     break;
1837                 case MUT_SPECPREV_RETURN:
1838                     return true;
1839                 case MUT_SPECPREV_CONTINUE:
1840                 default:
1841                 {
1842                         if(ent.chain)
1843                                 ent = ent.chain;
1844                         else
1845                                 ent = first;
1846                         break;
1847                 }
1848         }
1849
1850         SetSpectatee(this, ent);
1851         return SpectateSet(this);
1852 }
1853
1854 /*
1855 =============
1856 ShowRespawnCountdown()
1857
1858 Update a respawn countdown display.
1859 =============
1860 */
1861 void ShowRespawnCountdown(entity this)
1862 {
1863         float number;
1864         if(!IS_DEAD(this)) // just respawned?
1865                 return;
1866         else
1867         {
1868                 number = ceil(this.respawn_time - time);
1869                 if(number <= 0)
1870                         return;
1871                 if(number <= this.respawn_countdown)
1872                 {
1873                         this.respawn_countdown = number - 1;
1874                         if(ceil(this.respawn_time - (time + 0.5)) == number) // only say it if it is the same number even in 0.5s; to prevent overlapping sounds
1875                                 { Send_Notification(NOTIF_ONE, this, MSG_ANNCE, Announcer_PickNumber(CNT_RESPAWN, number)); }
1876                 }
1877         }
1878 }
1879
1880 .bool team_selected;
1881 bool ShowTeamSelection(entity this)
1882 {
1883         if(!teamplay || autocvar_g_campaign || autocvar_g_balance_teams || this.team_selected || (this.wasplayer && autocvar_g_changeteam_banned) || this.team_forced > 0)
1884                 return false;
1885         stuffcmd(this, "menu_showteamselect\n");
1886         return true;
1887 }
1888 void Join(entity this)
1889 {
1890         TRANSMUTE(Player, this);
1891
1892         if(!this.team_selected)
1893         if(autocvar_g_campaign || autocvar_g_balance_teams)
1894                 JoinBestTeam(this, false, true);
1895
1896         if(autocvar_g_campaign)
1897                 campaign_bots_may_start = true;
1898
1899         Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_PREVENT_JOIN);
1900
1901         PutClientInServer(this);
1902
1903         if(teamplay && this.team != -1)
1904                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, APP_TEAM_NUM(this.team, INFO_JOIN_PLAY_TEAM), this.netname);
1905         else
1906                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_JOIN_PLAY, this.netname);
1907         this.team_selected = false;
1908 }
1909
1910 /**
1911  * Determines whether the player is allowed to join. This depends on cvar
1912  * g_maxplayers, if it isn't used this function always return true, otherwise
1913  * it checks whether the number of currently playing players exceeds g_maxplayers.
1914  * @return int number of free slots for players, 0 if none
1915  */
1916 int nJoinAllowed(entity this, entity ignore)
1917 {
1918         if(!ignore)
1919         // this is called that way when checking if anyone may be able to join (to build qcstatus)
1920         // so report 0 free slots if restricted
1921         {
1922                 if(autocvar_g_forced_team_otherwise == "spectate")
1923                         return 0;
1924                 if(autocvar_g_forced_team_otherwise == "spectator")
1925                         return 0;
1926         }
1927
1928         if(this && this.team_forced < 0)
1929                 return 0; // forced spectators can never join
1930
1931         // TODO simplify this
1932         int totalClients = 0;
1933         int currentlyPlaying = 0;
1934         FOREACH_CLIENT(true, LAMBDA(
1935                 if(it != ignore)
1936                         ++totalClients;
1937                 if(IS_REAL_CLIENT(it))
1938                 if(IS_PLAYER(it) || it.caplayer)
1939                         ++currentlyPlaying;
1940         ));
1941
1942         float free_slots = 0;
1943         if (!autocvar_g_maxplayers)
1944                 free_slots = maxclients - totalClients;
1945         else if(currentlyPlaying < autocvar_g_maxplayers)
1946                 free_slots = min(maxclients - totalClients, autocvar_g_maxplayers - currentlyPlaying);
1947
1948         static float join_prevent_msg_time = 0;
1949         if(this && ignore && !free_slots && time > join_prevent_msg_time)
1950         {
1951                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_JOIN_PREVENT);
1952                 join_prevent_msg_time = time + 3;
1953         }
1954
1955         return free_slots;
1956 }
1957
1958 /**
1959  * Checks whether the client is an observer or spectator, if so, he will get kicked after
1960  * g_maxplayers_spectator_blocktime seconds
1961  */
1962 void checkSpectatorBlock(entity this)
1963 {
1964         if(IS_SPEC(this) || IS_OBSERVER(this))
1965         if(!this.caplayer)
1966         if(IS_REAL_CLIENT(this))
1967         {
1968                 if( time > (this.spectatortime + autocvar_g_maxplayers_spectator_blocktime) ) {
1969                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_QUIT_KICK_SPECTATING);
1970                         dropclient(this);
1971                 }
1972         }
1973 }
1974
1975 void PrintWelcomeMessage(entity this)
1976 {
1977         if(this.motd_actived_time == 0)
1978         {
1979                 if (autocvar_g_campaign) {
1980                         if ((IS_PLAYER(this) && PHYS_INPUT_BUTTON_INFO(this)) || (!IS_PLAYER(this))) {
1981                                 this.motd_actived_time = time;
1982                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOTD, campaign_message);
1983                         }
1984                 } else {
1985                         if (PHYS_INPUT_BUTTON_INFO(this)) {
1986                                 this.motd_actived_time = time;
1987                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOTD, getwelcomemessage(this));
1988                         }
1989                 }
1990         }
1991         else if(this.motd_actived_time > 0) // showing MOTD or campaign message
1992         {
1993                 if (autocvar_g_campaign) {
1994                         if (PHYS_INPUT_BUTTON_INFO(this))
1995                                 this.motd_actived_time = time;
1996                         else if ((time - this.motd_actived_time > 2) && IS_PLAYER(this)) { // hide it some seconds after BUTTON_INFO has been released
1997                                 this.motd_actived_time = 0;
1998                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_MOTD);
1999                         }
2000                 } else {
2001                         if (PHYS_INPUT_BUTTON_INFO(this))
2002                                 this.motd_actived_time = time;
2003                         else if (time - this.motd_actived_time > 2) { // hide it some seconds after BUTTON_INFO has been released
2004                                 this.motd_actived_time = 0;
2005                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_MOTD);
2006                         }
2007                 }
2008         }
2009         else //if(this.motd_actived_time < 0) // just connected, motd is active
2010         {
2011                 if(PHYS_INPUT_BUTTON_INFO(this)) // BUTTON_INFO hides initial MOTD
2012                         this.motd_actived_time = -2; // wait until BUTTON_INFO gets released
2013                 else if(this.motd_actived_time == -2 || IS_PLAYER(this) || IS_SPEC(this))
2014                 {
2015                         // instanctly hide MOTD
2016                         this.motd_actived_time = 0;
2017                         Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_MOTD);
2018                 }
2019         }
2020 }
2021
2022 bool joinAllowed(entity this)
2023 {
2024         if (this.version_mismatch) return false;
2025         if (!nJoinAllowed(this, this)) return false;
2026         if (teamplay && lockteams) return false;
2027         if (ShowTeamSelection(this)) return false;
2028         if (MUTATOR_CALLHOOK(ForbidSpawn, this)) return false;
2029         return true;
2030 }
2031
2032 void ObserverThink(entity this)
2033 {
2034         if ( this.impulse )
2035         {
2036                 MinigameImpulse(this, this.impulse);
2037                 this.impulse = 0;
2038         }
2039
2040         if (this.flags & FL_JUMPRELEASED) {
2041                 if (PHYS_INPUT_BUTTON_JUMP(this) && joinAllowed(this)) {
2042                         this.flags &= ~FL_JUMPRELEASED;
2043                         this.flags |= FL_SPAWNING;
2044                 } else if(PHYS_INPUT_BUTTON_ATCK(this) && !this.version_mismatch) {
2045                         this.flags &= ~FL_JUMPRELEASED;
2046                         if(SpectateNext(this)) {
2047                                 TRANSMUTE(Spectator, this);
2048                         }
2049                 } else {
2050                         int preferred_movetype = ((!PHYS_INPUT_BUTTON_USE(this) ? this.cvar_cl_clippedspectating : !this.cvar_cl_clippedspectating) ? MOVETYPE_FLY_WORLDONLY : MOVETYPE_NOCLIP);
2051                         set_movetype(this, preferred_movetype);
2052                 }
2053         } else {
2054                 if (!(PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_JUMP(this))) {
2055                         this.flags |= FL_JUMPRELEASED;
2056                         if(this.flags & FL_SPAWNING)
2057                         {
2058                                 this.flags &= ~FL_SPAWNING;
2059                                 Join(this);
2060                                 return;
2061                         }
2062                 }
2063         }
2064 }
2065
2066 void SpectatorThink(entity this)
2067 {
2068         if ( this.impulse )
2069         {
2070                 if(MinigameImpulse(this, this.impulse))
2071                         this.impulse = 0;
2072
2073                 if (this.impulse == IMP_weapon_drop.impulse)
2074                 {
2075                         STAT(CAMERA_SPECTATOR, this) = (STAT(CAMERA_SPECTATOR, this) + 1) % 3;
2076                         this.impulse = 0;
2077                         return;
2078                 }
2079         }
2080
2081         if (this.flags & FL_JUMPRELEASED) {
2082                 if (PHYS_INPUT_BUTTON_JUMP(this) && joinAllowed(this)) {
2083                         this.flags &= ~FL_JUMPRELEASED;
2084                         this.flags |= FL_SPAWNING;
2085                 } else if(PHYS_INPUT_BUTTON_ATCK(this) || this.impulse == 10 || this.impulse == 15 || this.impulse == 18 || (this.impulse >= 200 && this.impulse <= 209)) {
2086                         this.flags &= ~FL_JUMPRELEASED;
2087                         if(SpectateNext(this)) {
2088                                 TRANSMUTE(Spectator, this);
2089                         } else {
2090                                 TRANSMUTE(Observer, this);
2091                                 PutClientInServer(this);
2092                         }
2093                         this.impulse = 0;
2094                 } else if(this.impulse == 12 || this.impulse == 16  || this.impulse == 19 || (this.impulse >= 220 && this.impulse <= 229)) {
2095                         this.flags &= ~FL_JUMPRELEASED;
2096                         if(SpectatePrev(this)) {
2097                                 TRANSMUTE(Spectator, this);
2098                         } else {
2099                                 TRANSMUTE(Observer, this);
2100                                 PutClientInServer(this);
2101                         }
2102                         this.impulse = 0;
2103                 } else if (PHYS_INPUT_BUTTON_ATCK2(this)) {
2104                         this.flags &= ~FL_JUMPRELEASED;
2105                         TRANSMUTE(Observer, this);
2106                         PutClientInServer(this);
2107                 } else {
2108                         if(!SpectateUpdate(this))
2109                                 PutObserverInServer(this);
2110                 }
2111         } else {
2112                 if (!(PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_ATCK2(this))) {
2113                         this.flags |= FL_JUMPRELEASED;
2114                         if(this.flags & FL_SPAWNING)
2115                         {
2116                                 this.flags &= ~FL_SPAWNING;
2117                                 Join(this);
2118                                 return;
2119                         }
2120                 }
2121                 if(!SpectateUpdate(this))
2122                         PutObserverInServer(this);
2123         }
2124
2125         this.flags |= FL_CLIENT | FL_NOTARGET;
2126 }
2127
2128 void vehicles_enter (entity pl, entity veh);
2129 void PlayerUseKey(entity this)
2130 {
2131         if (!IS_PLAYER(this))
2132                 return;
2133
2134         if(this.vehicle)
2135         {
2136                 if(!gameover)
2137                 {
2138                         vehicles_exit(this.vehicle, VHEF_NORMAL);
2139                         return;
2140                 }
2141         }
2142         else if(autocvar_g_vehicles_enter)
2143         {
2144                 if(!STAT(FROZEN, this))
2145                 if(!IS_DEAD(this))
2146                 if(!gameover)
2147                 {
2148                         entity head, closest_target = NULL;
2149                         head = WarpZone_FindRadius(this.origin, autocvar_g_vehicles_enter_radius, true);
2150
2151                         while(head) // find the closest acceptable target to enter
2152                         {
2153                                 if(IS_VEHICLE(head))
2154                                 if(!IS_DEAD(head))
2155                                 if(!head.owner || ((head.vehicle_flags & VHF_MULTISLOT) && SAME_TEAM(head.owner, this)))
2156                                 if(head.takedamage != DAMAGE_NO)
2157                                 {
2158                                         if(closest_target)
2159                                         {
2160                                                 if(vlen2(this.origin - head.origin) < vlen2(this.origin - closest_target.origin))
2161                                                 { closest_target = head; }
2162                                         }
2163                                         else { closest_target = head; }
2164                                 }
2165
2166                                 head = head.chain;
2167                         }
2168
2169                         if(closest_target) { vehicles_enter(this, closest_target); return; }
2170                 }
2171         }
2172
2173         // a use key was pressed; call handlers
2174         MUTATOR_CALLHOOK(PlayerUseKey, this);
2175 }
2176
2177
2178 /*
2179 =============
2180 PlayerPreThink
2181
2182 Called every frame for each client before the physics are run
2183 =============
2184 */
2185 .float usekeypressed;
2186 .float last_vehiclecheck;
2187 .int items_added;
2188 void PlayerPreThink (entity this)
2189 {
2190         WarpZone_PlayerPhysics_FixVAngle(this);
2191
2192     STAT(GAMESTARTTIME, this) = game_starttime;
2193         STAT(ROUNDSTARTTIME, this) = round_starttime;
2194         STAT(ALLOW_OLDVORTEXBEAM, this) = autocvar_g_allow_oldvortexbeam;
2195         STAT(LEADLIMIT, this) = autocvar_leadlimit;
2196
2197         STAT(WEAPONSINMAP, this) = weaponsInMap;
2198
2199         if (frametime) {
2200                 // physics frames: update anticheat stuff
2201                 anticheat_prethink(this);
2202         }
2203
2204         if (blockSpectators && frametime) {
2205                 // WORKAROUND: only use dropclient in server frames (frametime set).
2206                 // Never use it in cl_movement frames (frametime zero).
2207                 checkSpectatorBlock(this);
2208     }
2209
2210         zoomstate_set = false;
2211
2212         // Check for nameless players
2213         if (isInvisibleString(this.netname)) {
2214                 this.netname = strzone(sprintf("Player#%d", this.playerid));
2215                 // stuffcmd(this, strcat("name ", this.netname, "\n")); // maybe?
2216         }
2217         if (this.netname != this.netname_previous) {
2218                 if (autocvar_sv_eventlog) {
2219                         GameLogEcho(strcat(":name:", ftos(this.playerid), ":", this.netname));
2220         }
2221                 if (this.netname_previous) strunzone(this.netname_previous);
2222                 this.netname_previous = strzone(this.netname);
2223         }
2224
2225         // version nagging
2226         if (this.version_nagtime && this.cvar_g_xonoticversion && time > this.version_nagtime) {
2227         this.version_nagtime = 0;
2228         if (strstrofs(this.cvar_g_xonoticversion, "git", 0) >= 0 || strstrofs(this.cvar_g_xonoticversion, "autobuild", 0) >= 0) {
2229             // git client
2230         } else if (strstrofs(autocvar_g_xonoticversion, "git", 0) >= 0 || strstrofs(autocvar_g_xonoticversion, "autobuild", 0) >= 0) {
2231             // git server
2232             Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_BETA, autocvar_g_xonoticversion, this.cvar_g_xonoticversion);
2233         } else {
2234             int r = vercmp(this.cvar_g_xonoticversion, autocvar_g_xonoticversion);
2235             if (r < 0) { // old client
2236                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_OUTDATED, autocvar_g_xonoticversion, this.cvar_g_xonoticversion);
2237             } else if (r > 0) { // old server
2238                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_OLD, autocvar_g_xonoticversion, this.cvar_g_xonoticversion);
2239             }
2240         }
2241     }
2242
2243         // GOD MODE info
2244         if (!(this.flags & FL_GODMODE) && this.max_armorvalue)
2245         {
2246                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_GODMODE_OFF, this.max_armorvalue);
2247                 this.max_armorvalue = 0;
2248         }
2249
2250         if (STAT(FROZEN, this) == 2)
2251         {
2252                 this.revive_progress = bound(0, this.revive_progress + frametime * this.revive_speed, 1);
2253                 this.health = max(1, this.revive_progress * start_health);
2254                 this.iceblock.alpha = bound(0.2, 1 - this.revive_progress, 1);
2255
2256                 if (this.revive_progress >= 1)
2257                         Unfreeze(this);
2258         }
2259         else if (STAT(FROZEN, this) == 3)
2260         {
2261                 this.revive_progress = bound(0, this.revive_progress - frametime * this.revive_speed, 1);
2262                 this.health = max(0, autocvar_g_nades_ice_health + (start_health-autocvar_g_nades_ice_health) * this.revive_progress );
2263
2264                 if (this.health < 1)
2265                 {
2266                         if (this.vehicle)
2267                                 vehicles_exit(this.vehicle, VHEF_RELEASE);
2268                         if(this.event_damage)
2269                                 this.event_damage(this, this, this.frozen_by, 1, DEATH_NADE_ICE_FREEZE.m_id, this.origin, '0 0 0');
2270                 }
2271                 else if (this.revive_progress <= 0)
2272                         Unfreeze(this);
2273         }
2274
2275         MUTATOR_CALLHOOK(PlayerPreThink, this);
2276
2277         if(autocvar_g_vehicles_enter && (time > this.last_vehiclecheck) && !gameover && !this.vehicle)
2278         if(IS_PLAYER(this) && !STAT(FROZEN, this) && !IS_DEAD(this))
2279         {
2280                 FOREACH_ENTITY_RADIUS(this.origin, autocvar_g_vehicles_enter_radius, IS_VEHICLE(it),
2281                 {
2282                         if(!IS_DEAD(it) && it.takedamage != DAMAGE_NO)
2283                         if((it.vehicle_flags & VHF_MULTISLOT) && SAME_TEAM(it.owner, this))
2284                         {
2285                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER_GUNNER);
2286                         }
2287                         else if(!it.owner)
2288                         {
2289                                 if(!it.team || SAME_TEAM(this, it))
2290                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER);
2291                                 else if(autocvar_g_vehicles_steal)
2292                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER_STEAL);
2293                         }
2294                 });
2295
2296                 this.last_vehiclecheck = time + 1;
2297         }
2298
2299         if(!this.cvar_cl_newusekeysupported) // FIXME remove this - it was a stupid idea to begin with, we can JUST use the button
2300         {
2301                 if(PHYS_INPUT_BUTTON_USE(this) && !this.usekeypressed)
2302                         PlayerUseKey(this);
2303                 this.usekeypressed = PHYS_INPUT_BUTTON_USE(this);
2304         }
2305
2306         if (IS_REAL_CLIENT(this))
2307                 PrintWelcomeMessage(this);
2308
2309         if (IS_PLAYER(this)) {
2310                 CheckRules_Player(this);
2311
2312                 if (intermission_running) {
2313                         IntermissionThink(this);
2314                         return;
2315                 }
2316
2317                 if (timeout_status == TIMEOUT_ACTIVE) {
2318             // don't allow the player to turn around while game is paused
2319                         // FIXME turn this into CSQC stuff
2320                         this.v_angle = this.lastV_angle;
2321                         this.angles = this.lastV_angle;
2322                         this.fixangle = true;
2323                 }
2324
2325                 if (frametime) player_powerups(this);
2326
2327                 if (IS_DEAD(this)) {
2328                         if (this.personal && g_race_qualifying) {
2329                                 if (time > this.respawn_time) {
2330                                         STAT(RESPAWN_TIME, this) = this.respawn_time = time + 1; // only retry once a second
2331                                         respawn(this);
2332                                         this.impulse = CHIMPULSE_SPEEDRUN.impulse;
2333                                 }
2334                         } else {
2335                                 if (frametime) player_anim(this);
2336                                 bool button_pressed = (PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_JUMP(this) || PHYS_INPUT_BUTTON_ATCK2(this) || PHYS_INPUT_BUTTON_HOOK(this) || PHYS_INPUT_BUTTON_USE(this));
2337
2338                                 switch(this.deadflag)
2339                                 {
2340                                         case DEAD_DYING:
2341                                         {
2342                                                 if ((this.respawn_flags & RESPAWN_FORCE) && !(this.respawn_time < this.respawn_time_max))
2343                                                         this.deadflag = DEAD_RESPAWNING;
2344                                                 else if (!button_pressed || (time >= this.respawn_time_max && (this.respawn_flags & RESPAWN_FORCE)))
2345                                                         this.deadflag = DEAD_DEAD;
2346                                                 break;
2347                                         }
2348                                         case DEAD_DEAD:
2349                                         {
2350                                                 if (button_pressed)
2351                                                         this.deadflag = DEAD_RESPAWNABLE;
2352                                                 else if (time >= this.respawn_time_max && (this.respawn_flags & RESPAWN_FORCE))
2353                                                         this.deadflag = DEAD_RESPAWNING;
2354                                                 break;
2355                                         }
2356                                         case DEAD_RESPAWNABLE:
2357                                         {
2358                                                 if (!button_pressed || (this.respawn_flags & RESPAWN_FORCE))
2359                                                         this.deadflag = DEAD_RESPAWNING;
2360                                                 break;
2361                                         }
2362                                         case DEAD_RESPAWNING:
2363                                         {
2364                                                 if (time > this.respawn_time)
2365                                                 {
2366                                                         this.respawn_time = time + 1; // only retry once a second
2367                                                         this.respawn_time_max = this.respawn_time;
2368                                                         respawn(this);
2369                                                 }
2370                                                 break;
2371                                         }
2372                                 }
2373
2374                                 ShowRespawnCountdown(this);
2375
2376                                 if (this.respawn_flags & RESPAWN_SILENT)
2377                                         STAT(RESPAWN_TIME, this) = 0;
2378                                 else if ((this.respawn_flags & RESPAWN_FORCE) && this.respawn_time < this.respawn_time_max)
2379                                 {
2380                                         if (time < this.respawn_time)
2381                                                 STAT(RESPAWN_TIME, this) = this.respawn_time;
2382                                         else if (this.deadflag != DEAD_RESPAWNING)
2383                                                 STAT(RESPAWN_TIME, this) = -this.respawn_time_max;
2384                                 }
2385                                 else
2386                                         STAT(RESPAWN_TIME, this) = this.respawn_time;
2387                         }
2388
2389                         // if respawning, invert stat_respawn_time to indicate this, the client translates it
2390                         if (this.deadflag == DEAD_RESPAWNING && STAT(RESPAWN_TIME, this) > 0)
2391                                 STAT(RESPAWN_TIME, this) *= -1;
2392
2393                         return;
2394                 }
2395
2396                 this.prevorigin = this.origin;
2397
2398                 bool do_crouch = PHYS_INPUT_BUTTON_CROUCH(this);
2399                 if (this.hook.state) {
2400                         do_crouch = false;
2401                 } else if (this.waterlevel >= WATERLEVEL_SWIMMING) {
2402                         do_crouch = false;
2403                 } else if (this.vehicle) {
2404                         do_crouch = false;
2405                 } else if (STAT(FROZEN, this)) {
2406                         do_crouch = false;
2407         }
2408
2409                 if (do_crouch) {
2410                         if (!this.crouch) {
2411                                 this.crouch = true;
2412                                 this.view_ofs = STAT(PL_CROUCH_VIEW_OFS, this);
2413                                 setsize(this, STAT(PL_CROUCH_MIN, this), STAT(PL_CROUCH_MAX, this));
2414                                 // setanim(this, this.anim_duck, false, true, true); // this anim is BROKEN anyway
2415                         }
2416                 } else if (this.crouch) {
2417             tracebox(this.origin, STAT(PL_MIN, this), STAT(PL_MAX, this), this.origin, false, this);
2418             if (!trace_startsolid) {
2419                 this.crouch = false;
2420                 this.view_ofs = STAT(PL_VIEW_OFS, this);
2421                 setsize(this, STAT(PL_MIN, this), STAT(PL_MAX, this));
2422             }
2423                 }
2424
2425                 FixPlayermodel(this);
2426
2427                 // LordHavoc: allow firing on move frames (sub-ticrate), this gives better timing on slow servers
2428                 //if(frametime)
2429                 {
2430                         this.items &= ~this.items_added;
2431
2432                         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2433                         {
2434                                 .entity weaponentity = weaponentities[slot];
2435                                 W_WeaponFrame(this, weaponentity);
2436                         }
2437
2438                         this.items_added = 0;
2439                         if (this.items & ITEM_Jetpack.m_itemid && (this.items & ITEM_JetpackRegen.m_itemid || this.ammo_fuel >= 0.01))
2440                 this.items_added |= IT_FUEL;
2441
2442                         this.items |= this.items_added;
2443                 }
2444
2445                 player_regen(this);
2446
2447                 // WEAPONTODO: Add a weapon request for this
2448                 // rot vortex charge to the charge limit
2449                 if (WEP_CVAR(vortex, charge_rot_rate) && this.vortex_charge > WEP_CVAR(vortex, charge_limit) && this.vortex_charge_rottime < time)
2450                         this.vortex_charge = bound(WEP_CVAR(vortex, charge_limit), this.vortex_charge - WEP_CVAR(vortex, charge_rot_rate) * frametime / W_TICSPERFRAME, 1);
2451
2452                 if (frametime) player_anim(this);
2453
2454                 // secret status
2455                 secrets_setstatus(this);
2456
2457                 // monsters status
2458                 monsters_setstatus(this);
2459
2460                 this.dmg_team = max(0, this.dmg_team - autocvar_g_teamdamage_resetspeed * frametime);
2461         }
2462         else if (gameover) {
2463                 if (intermission_running) IntermissionThink(this);
2464                 return;
2465         }
2466         else if (IS_OBSERVER(this)) {
2467                 ObserverThink(this);
2468         }
2469         else if (IS_SPEC(this)) {
2470                 SpectatorThink(this);
2471         }
2472
2473         // WEAPONTODO: Add weapon request for this
2474         .entity weaponentity = weaponentities[0]; // TODO: unhardcode
2475         if (!zoomstate_set) {
2476                 SetZoomState(this,
2477                         PHYS_INPUT_BUTTON_ZOOM(this) || PHYS_INPUT_BUTTON_ZOOMSCRIPT(this)
2478                         || (PHYS_INPUT_BUTTON_ATCK2(this) && this.(weaponentity).m_weapon == WEP_VORTEX)
2479                         || (PHYS_INPUT_BUTTON_ATCK2(this) && this.(weaponentity).m_weapon == WEP_RIFLE && WEP_CVAR(rifle, secondary) == 0)
2480                 );
2481     }
2482
2483         if (this.teamkill_soundtime && time > this.teamkill_soundtime)
2484         {
2485                 this.teamkill_soundtime = 0;
2486
2487                 entity e = this.teamkill_soundsource;
2488                 entity oldpusher = e.pusher;
2489                 e.pusher = this;
2490                 PlayerSound(e, playersound_teamshoot, CH_VOICE, VOL_BASEVOICE, VOICETYPE_LASTATTACKER_ONLY);
2491                 e.pusher = oldpusher;
2492         }
2493
2494         if (this.taunt_soundtime && time > this.taunt_soundtime) {
2495                 this.taunt_soundtime = 0;
2496                 PlayerSound(this, playersound_taunt, CH_VOICE, VOL_BASEVOICE, VOICETYPE_AUTOTAUNT);
2497         }
2498
2499         target_voicescript_next(this);
2500
2501         // WEAPONTODO: Move into weaponsystem somehow
2502         // if a player goes unarmed after holding a loaded weapon, empty his clip size and remove the crosshair ammo ring
2503         if (this.(weaponentity).m_weapon == WEP_Null)
2504                 this.clip_load = this.clip_size = 0;
2505 }
2506
2507 void DrownPlayer(entity this)
2508 {
2509         if(IS_DEAD(this))
2510                 return;
2511
2512         if (this.waterlevel != WATERLEVEL_SUBMERGED || this.vehicle)
2513         {
2514                 if(this.air_finished < time)
2515                         PlayerSound(this, playersound_gasp, CH_PLAYER, VOL_BASE, VOICETYPE_PLAYERSOUND);
2516                 this.air_finished = time + autocvar_g_balance_contents_drowndelay;
2517                 this.dmg = 2;
2518         }
2519         else if (this.air_finished < time)
2520         {       // drown!
2521                 if (this.pain_finished < time)
2522                 {
2523                         Damage (this, NULL, NULL, autocvar_g_balance_contents_playerdamage_drowning * autocvar_g_balance_contents_damagerate, DEATH_DROWN.m_id, this.origin, '0 0 0');
2524                         this.pain_finished = time + 0.5;
2525                 }
2526         }
2527 }
2528
2529 .bool move_qcphysics;
2530
2531 void Player_Physics(entity this)
2532 {
2533         set_movetype(this, this.move_movetype);
2534
2535         if(!this.move_qcphysics)
2536                 return;
2537
2538         if(!frametime && !this.pm_frametime)
2539                 return;
2540
2541         Movetype_Physics_NoMatchTicrate(this, this.pm_frametime, true);
2542
2543         this.pm_frametime = 0;
2544 }
2545
2546 /*
2547 =============
2548 PlayerPostThink
2549
2550 Called every frame for each client after the physics are run
2551 =============
2552 */
2553 .float idlekick_lasttimeleft;
2554 void PlayerPostThink (entity this)
2555 {
2556         Player_Physics(this);
2557
2558         if (sv_maxidle > 0)
2559         if (frametime) // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2560         if (IS_REAL_CLIENT(this))
2561         if (IS_PLAYER(this) || sv_maxidle_spectatorsareidle)
2562         {
2563                 int totalClients = 0;
2564                 if(sv_maxidle_slots > 0)
2565                 {
2566                         FOREACH_CLIENT(IS_REAL_CLIENT(it) || sv_maxidle_slots_countbots,
2567                         {
2568                                 ++totalClients;
2569                         });
2570                 }
2571
2572                 if (sv_maxidle_slots > 0 && (maxclients - totalClients) > sv_maxidle_slots)
2573                 { /* do nothing */ }
2574                 else if (time - this.parm_idlesince < 1) // instead of (time == this.parm_idlesince) to support sv_maxidle <= 10
2575                 {
2576                         if (this.idlekick_lasttimeleft)
2577                         {
2578                                 this.idlekick_lasttimeleft = 0;
2579                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_IDLING);
2580                         }
2581                 }
2582                 else
2583                 {
2584                         float timeleft = ceil(sv_maxidle - (time - this.parm_idlesince));
2585                         if (timeleft == min(10, sv_maxidle - 1)) { // - 1 to support sv_maxidle <= 10
2586                                 if (!this.idlekick_lasttimeleft)
2587                                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_DISCONNECT_IDLING, timeleft);
2588                         }
2589                         if (timeleft <= 0) {
2590                                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_QUIT_KICK_IDLING, this.netname);
2591                                 dropclient(this);
2592                                 return;
2593                         }
2594                         else if (timeleft <= 10) {
2595                                 if (timeleft != this.idlekick_lasttimeleft) {
2596                                     Send_Notification(NOTIF_ONE, this, MSG_ANNCE, Announcer_PickNumber(CNT_IDLE, timeleft));
2597                 }
2598                                 this.idlekick_lasttimeleft = timeleft;
2599                         }
2600                 }
2601         }
2602
2603         CheatFrame(this);
2604
2605         //CheckPlayerJump();
2606
2607         if (IS_PLAYER(this)) {
2608                 DrownPlayer(this);
2609                 CheckRules_Player(this);
2610                 UpdateChatBubble(this);
2611                 if (this.impulse) ImpulseCommands(this);
2612                 if (intermission_running) return; // intermission or finale
2613                 GetPressedKeys(this);
2614         }
2615
2616         if (this.waypointsprite_attachedforcarrier) {
2617             vector v = healtharmor_maxdamage(this.health, this.armorvalue, autocvar_g_balance_armor_blockpercent, DEATH_WEAPON.m_id);
2618                 WaypointSprite_UpdateHealth(this.waypointsprite_attachedforcarrier, '1 0 0' * v);
2619     }
2620
2621         playerdemo_write(this);
2622
2623         CSQCMODEL_AUTOUPDATE(this);
2624 }