qcsrc/server/client.qc

   1 #include "client.qh"
   2
   3 #include <server/defs.qh>
   4 #include <server/miscfunctions.qh>
   5 #include <common/effects/all.qh>
   6 #include "anticheat.qh"
   7 #include "impulse.qh"
   8 #include "player.qh"
   9 #include "ipban.qh"
  10 #include "miscfunctions.qh"
  11 #include "portals.qh"
  12 #include "teamplay.qh"
  13 #include "playerdemo.qh"
  14 #include "spawnpoints.qh"
  15 #include "resources.qh"
  16 #include "g_damage.qh"
  17 #include "handicap.qh"
  18 #include "g_hook.qh"
  19 #include "command/common.qh"
  20 #include "cheats.qh"
  21 #include "g_world.qh"
  22 #include "race.qh"
  23 #include "antilag.qh"
  24 #include "campaign.qh"
  25 #include "command/common.qh"
  26 #include "scores_rules.qh"
  27
  28 #include "bot/api.qh"
  29
  30 #include "../common/ent_cs.qh"
  31 #include "../common/wepent.qh"
  32 #include <common/state.qh>
  33
  34 #include <common/effects/qc/globalsound.qh>
  35
  36 #include "../common/triggers/func/conveyor.qh"
  37 #include "../common/triggers/teleporters.qh"
  38
  39 #include "../common/vehicles/all.qh"
  40
  41 #include "weapons/hitplot.qh"
  42 #include "weapons/weaponsystem.qh"
  43
  44 #include "../common/net_notice.qh"
  45 #include "../common/net_linked.qh"
  46 #include "../common/physics/player.qh"
  47
  48 #include "../common/items/_mod.qh"
  49
  50 #include "../common/mutators/mutator/waypoints/all.qh"
  51
  52 #include "../common/triggers/subs.qh"
  53 #include "../common/triggers/triggers.qh"
  54 #include "../common/triggers/trigger/secret.qh"
  55
  56 #include "../common/minigames/sv_minigames.qh"
  57
  58 #include "../common/items/inventory.qh"
  59
  60 #include "../common/monsters/sv_monsters.qh"
  61
  62 #include "../lib/warpzone/server.qh"
  63
  64 STATIC_METHOD(Client, Add, void(Client this, int _team))
  65 {
  66     ClientConnect(this);
  67     TRANSMUTE(Player, this);
  68     this.frame = 12; // 7
  69     this.team = _team;
  70     PutClientInServer(this);
  71 }
  72
  73 void PutObserverInServer(entity this);
  74
  75 STATIC_METHOD(Client, Remove, void(Client this))
  76 {
  77     TRANSMUTE(Observer, this);
  78     PutClientInServer(this);
  79     ClientDisconnect(this);
  80 }
  81
  82 void send_CSQC_teamnagger() {
  83         WriteHeader(MSG_BROADCAST, TE_CSQC_TEAMNAGGER);
  84 }
  85
  86 int CountSpectators(entity player, entity to)
  87 {
  88         if(!player) { return 0; } // not sure how, but best to be safe
  89
  90         int spec_count = 0;
  91
  92         FOREACH_CLIENT(IS_REAL_CLIENT(it) && IS_SPEC(it) && it != to && it.enemy == player,
  93         {
  94                 spec_count++;
  95         });
  96
  97         return spec_count;
  98 }
  99
 100 void WriteSpectators(entity player, entity to)
 101 {
 102         if(!player) { return; } // not sure how, but best to be safe
 103
 104         FOREACH_CLIENT(IS_REAL_CLIENT(it) && IS_SPEC(it) && it != to && it.enemy == player,
 105         {
 106                 WriteByte(MSG_ENTITY, num_for_edict(it));
 107         });
 108 }
 109
 110 bool ClientData_Send(entity this, entity to, int sf)
 111 {
 112         assert(to == this.owner, return false);
 113
 114         entity e = to;
 115         if (IS_SPEC(e)) e = e.enemy;
 116
 117         sf = 0;
 118         if (CS(e).race_completed)       sf |= BIT(0); // forced scoreboard
 119         if (CS(to).spectatee_status)    sf |= BIT(1); // spectator ent number follows
 120         if (CS(e).zoomstate)            sf |= BIT(2); // zoomed
 121         if (autocvar_sv_showspectators) sf |= BIT(4); // show spectators
 122
 123         WriteHeader(MSG_ENTITY, ENT_CLIENT_CLIENTDATA);
 124         WriteByte(MSG_ENTITY, sf);
 125
 126         if (sf & BIT(1))
 127                 WriteByte(MSG_ENTITY, CS(to).spectatee_status);
 128
 129         if(sf & BIT(4))
 130         {
 131                 float specs = CountSpectators(e, to);
 132                 WriteByte(MSG_ENTITY, specs);
 133                 WriteSpectators(e, to);
 134         }
 135
 136         return true;
 137 }
 138
 139 void ClientData_Attach(entity this)
 140 {
 141         Net_LinkEntity(CS(this).clientdata = new_pure(clientdata), false, 0, ClientData_Send);
 142         CS(this).clientdata.drawonlytoclient = this;
 143         CS(this).clientdata.owner = this;
 144 }
 145
 146 void ClientData_Detach(entity this)
 147 {
 148         delete(CS(this).clientdata);
 149         CS(this).clientdata = NULL;
 150 }
 151
 152 void ClientData_Touch(entity e)
 153 {
 154         CS(e).clientdata.SendFlags = 1;
 155
 156         // make it spectatable
 157         FOREACH_CLIENT(IS_REAL_CLIENT(it) && it != e && IS_SPEC(it) && it.enemy == e, { CS(it).clientdata.SendFlags = 1; });
 158 }
 159
 160 void SetSpectatee(entity this, entity spectatee);
 161 void SetSpectatee_status(entity this, int spectatee_num);
 162
 163
 164 /*
 165 =============
 166 CheckPlayerModel
 167
 168 Checks if the argument string can be a valid playermodel.
 169 Returns a valid one in doubt.
 170 =============
 171 */
 172 string FallbackPlayerModel;
 173 string CheckPlayerModel(string plyermodel) {
 174         if(FallbackPlayerModel != cvar_defstring("_cl_playermodel"))
 175         {
 176                 // note: we cannot summon Don Strunzone here, some player may
 177                 // still have the model string set. In case anyone manages how
 178                 // to change a cvar default, we'll have a small leak here.
 179                 FallbackPlayerModel = strzone(cvar_defstring("_cl_playermodel"));
 180         }
 181         // only in right path
 182         if( substring(plyermodel,0,14) != "models/player/")
 183                 return FallbackPlayerModel;
 184         // only good file extensions
 185         if(substring(plyermodel,-4,4) != ".zym")
 186         if(substring(plyermodel,-4,4) != ".dpm")
 187         if(substring(plyermodel,-4,4) != ".iqm")
 188         if(substring(plyermodel,-4,4) != ".md3")
 189         if(substring(plyermodel,-4,4) != ".psk")
 190                 return FallbackPlayerModel;
 191         // forbid the LOD models
 192         if(substring(plyermodel, -9,5) == "_lod1")
 193                 return FallbackPlayerModel;
 194         if(substring(plyermodel, -9,5) == "_lod2")
 195                 return FallbackPlayerModel;
 196         if(plyermodel != strtolower(plyermodel))
 197                 return FallbackPlayerModel;
 198         // also, restrict to server models
 199         if(autocvar_sv_servermodelsonly)
 200         {
 201                 if(!fexists(plyermodel))
 202                         return FallbackPlayerModel;
 203         }
 204         return plyermodel;
 205 }
 206
 207 void setplayermodel(entity e, string modelname)
 208 {
 209         precache_model(modelname);
 210         _setmodel(e, modelname);
 211         player_setupanimsformodel(e);
 212         if(!autocvar_g_debug_globalsounds)
 213                 UpdatePlayerSounds(e);
 214 }
 215
 216 void FixPlayermodel(entity player);
 217 /** putting a client as observer in the server */
 218 void PutObserverInServer(entity this)
 219 {
 220     bool mutator_returnvalue = MUTATOR_CALLHOOK(MakePlayerObserver, this);
 221         PlayerState_detach(this);
 222
 223         if (IS_PLAYER(this))
 224         {
 225                 if(this.health >= 1)
 226                 {
 227                         // despawn effect
 228                         Send_Effect(EFFECT_SPAWN_NEUTRAL, this.origin, '0 0 0', 1);
 229                 }
 230
 231                 // was a player, recount votes and ready status
 232                 if(IS_REAL_CLIENT(this))
 233                 {
 234                         if (vote_called) { VoteCount(false); }
 235                         ReadyCount();
 236                 }
 237     }
 238
 239     {
 240         entity spot = SelectSpawnPoint(this, true);
 241         if (!spot) LOG_FATAL("No spawnpoints for observers?!?");
 242         this.angles = vec2(spot.angles);
 243         this.fixangle = true;
 244         // offset it so that the spectator spawns higher off the ground, looks better this way
 245         setorigin(this, spot.origin + STAT(PL_VIEW_OFS, this));
 246         if (IS_REAL_CLIENT(this))
 247         {
 248             msg_entity = this;
 249             WriteByte(MSG_ONE, SVC_SETVIEW);
 250             WriteEntity(MSG_ONE, this);
 251         }
 252         // give the spectator some space between walls for MOVETYPE_FLY_WORLDONLY
 253         // so that your view doesn't go into the ceiling with MOVETYPE_FLY_WORLDONLY, previously "PL_VIEW_OFS"
 254         if(!autocvar_g_debug_globalsounds)
 255         {
 256                 // needed for player sounds
 257                 this.model = "";
 258                 FixPlayermodel(this);
 259         }
 260         setmodel(this, MDL_Null);
 261         setsize(this, STAT(PL_CROUCH_MIN, this), STAT(PL_CROUCH_MAX, this));
 262         this.view_ofs = '0 0 0';
 263     }
 264
 265     RemoveGrapplingHooks(this);
 266         Portal_ClearAll(this);
 267         Unfreeze(this);
 268         SetSpectatee(this, NULL);
 269
 270         if (this.alivetime)
 271         {
 272                 if (!warmup_stage)
 273                         PlayerStats_GameReport_Event_Player(this, PLAYERSTATS_ALIVETIME, time - this.alivetime);
 274                 this.alivetime = 0;
 275         }
 276
 277         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
 278
 279         WaypointSprite_PlayerDead(this);
 280
 281         if (mutator_returnvalue) {
 282             // mutator prevents resetting teams+score
 283         } else {
 284                 int oldteam = this.team;
 285                 this.team = -1;  // move this as it is needed to log the player spectating in eventlog
 286                 MUTATOR_CALLHOOK(Player_ChangedTeam, this, oldteam, this.team);
 287         this.frags = FRAGS_SPECTATOR;
 288         PlayerScore_Clear(this);  // clear scores when needed
 289     }
 290
 291         if (CS(this).killcount != FRAGS_SPECTATOR)
 292         {
 293                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_QUIT_SPECTATE, this.netname);
 294                 if(!game_stopped)
 295                 if(autocvar_g_chat_nospectators == 1 || (!warmup_stage && autocvar_g_chat_nospectators == 2))
 296                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_CHAT_NOSPECTATORS);
 297
 298                 if(!CS(this).just_joined)
 299                         LogTeamchange(this.playerid, -1, 4);
 300                 else
 301                         CS(this).just_joined = false;
 302         }
 303
 304         accuracy_resend(this);
 305
 306         CS(this).spectatortime = time;
 307         if(this.bot_attack)
 308                 IL_REMOVE(g_bot_targets, this);
 309         this.bot_attack = false;
 310     this.hud = HUD_NORMAL;
 311         TRANSMUTE(Observer, this);
 312         this.iscreature = false;
 313         this.teleportable = TELEPORT_SIMPLE;
 314         if(this.damagedbycontents)
 315                 IL_REMOVE(g_damagedbycontents, this);
 316         this.damagedbycontents = false;
 317         this.health = FRAGS_SPECTATOR;
 318         SetSpectatee_status(this, etof(this));
 319         this.takedamage = DAMAGE_NO;
 320         this.solid = SOLID_NOT;
 321         set_movetype(this, MOVETYPE_FLY_WORLDONLY); // user preference is controlled by playerprethink
 322         this.flags = FL_CLIENT | FL_NOTARGET;
 323         this.armorvalue = 666;
 324         this.effects = 0;
 325         this.armorvalue = autocvar_g_balance_armor_start;
 326         this.pauserotarmor_finished = 0;
 327         this.pauserothealth_finished = 0;
 328         this.pauseregen_finished = 0;
 329         this.damageforcescale = 0;
 330         this.death_time = 0;
 331         this.respawn_flags = 0;
 332         this.respawn_time = 0;
 333         this.stat_respawn_time = 0;
 334         this.alpha = 0;
 335         this.scale = 0;
 336         this.fade_time = 0;
 337         this.pain_frame = 0;
 338         this.pain_finished = 0;
 339         this.strength_finished = 0;
 340         this.invincible_finished = 0;
 341         this.superweapons_finished = 0;
 342         this.pushltime = 0;
 343         this.istypefrag = 0;
 344         setthink(this, func_null);
 345         this.nextthink = 0;
 346         this.deadflag = DEAD_NO;
 347         this.crouch = false;
 348         this.revive_progress = 0;
 349         this.revival_time = 0;
 350
 351         this.items = 0;
 352         this.weapons = '0 0 0';
 353         this.drawonlytoclient = this;
 354
 355         this.weaponmodel = "";
 356         for (int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 357         {
 358                 this.weaponentities[slot] = NULL;
 359         }
 360         this.exteriorweaponentity = NULL;
 361         CS(this).killcount = FRAGS_SPECTATOR;
 362         this.velocity = '0 0 0';
 363         this.avelocity = '0 0 0';
 364         this.punchangle = '0 0 0';
 365         this.punchvector = '0 0 0';
 366         this.oldvelocity = this.velocity;
 367         this.fire_endtime = -1;
 368         this.event_damage = func_null;
 369
 370         for(int slot = 0; slot < MAX_AXH; ++slot)
 371         {
 372                 entity axh = this.(AuxiliaryXhair[slot]);
 373                 this.(AuxiliaryXhair[slot]) = NULL;
 374
 375                 if(axh.owner == this && axh != NULL && !wasfreed(axh))
 376                         delete(axh);
 377         }
 378 }
 379
 380 int player_getspecies(entity this)
 381 {
 382         get_model_parameters(this.model, this.skin);
 383         int s = get_model_parameters_species;
 384         get_model_parameters(string_null, 0);
 385         if (s < 0) return SPECIES_HUMAN;
 386         return s;
 387 }
 388
 389 .float model_randomizer;
 390 void FixPlayermodel(entity player)
 391 {
 392         string defaultmodel = "";
 393         int defaultskin = 0;
 394         if(autocvar_sv_defaultcharacter)
 395         {
 396                 if(teamplay)
 397                 {
 398                         switch(player.team)
 399                         {
 400                                 case NUM_TEAM_1: defaultmodel = autocvar_sv_defaultplayermodel_red; defaultskin = autocvar_sv_defaultplayerskin_red; break;
 401                                 case NUM_TEAM_2: defaultmodel = autocvar_sv_defaultplayermodel_blue; defaultskin = autocvar_sv_defaultplayerskin_blue; break;
 402                                 case NUM_TEAM_3: defaultmodel = autocvar_sv_defaultplayermodel_yellow; defaultskin = autocvar_sv_defaultplayerskin_yellow; break;
 403                                 case NUM_TEAM_4: defaultmodel = autocvar_sv_defaultplayermodel_pink; defaultskin = autocvar_sv_defaultplayerskin_pink; break;
 404                         }
 405                 }
 406
 407                 if(defaultmodel == "")
 408                 {
 409                         defaultmodel = autocvar_sv_defaultplayermodel;
 410                         defaultskin = autocvar_sv_defaultplayerskin;
 411                 }
 412
 413                 int n = tokenize_console(defaultmodel);
 414                 if(n > 0)
 415                 {
 416                         defaultmodel = argv(floor(n * CS(player).model_randomizer));
 417                         // However, do NOT randomize if the player-selected model is in the list.
 418                         for (int i = 0; i < n; ++i)
 419                                 if ((argv(i) == player.playermodel && defaultskin == stof(player.playerskin)) || argv(i) == strcat(player.playermodel, ":", player.playerskin))
 420                                         defaultmodel = argv(i);
 421                 }
 422
 423                 int i = strstrofs(defaultmodel, ":", 0);
 424                 if(i >= 0)
 425                 {
 426                         defaultskin = stof(substring(defaultmodel, i+1, -1));
 427                         defaultmodel = substring(defaultmodel, 0, i);
 428                 }
 429         }
 430         if(autocvar_sv_defaultcharacterskin && !defaultskin)
 431         {
 432                 if(teamplay)
 433                 {
 434                         switch(player.team)
 435                         {
 436                                 case NUM_TEAM_1: defaultskin = autocvar_sv_defaultplayerskin_red; break;
 437                                 case NUM_TEAM_2: defaultskin = autocvar_sv_defaultplayerskin_blue; break;
 438                                 case NUM_TEAM_3: defaultskin = autocvar_sv_defaultplayerskin_yellow; break;
 439                                 case NUM_TEAM_4: defaultskin = autocvar_sv_defaultplayerskin_pink; break;
 440                         }
 441                 }
 442
 443                 if(!defaultskin)
 444                         defaultskin = autocvar_sv_defaultplayerskin;
 445         }
 446
 447         MUTATOR_CALLHOOK(FixPlayermodel, defaultmodel, defaultskin, player);
 448         defaultmodel = M_ARGV(0, string);
 449         defaultskin = M_ARGV(1, int);
 450
 451         bool chmdl = false;
 452         int oldskin;
 453         if(defaultmodel != "")
 454         {
 455                 if (defaultmodel != player.model)
 456                 {
 457                         vector m1 = player.mins;
 458                         vector m2 = player.maxs;
 459                         setplayermodel (player, defaultmodel);
 460                         setsize (player, m1, m2);
 461                         chmdl = true;
 462                 }
 463
 464                 oldskin = player.skin;
 465                 player.skin = defaultskin;
 466         } else {
 467                 if (player.playermodel != player.model || player.playermodel == "")
 468                 {
 469                         player.playermodel = CheckPlayerModel(player.playermodel); // this is never "", so no endless loop
 470                         vector m1 = player.mins;
 471                         vector m2 = player.maxs;
 472                         setplayermodel (player, player.playermodel);
 473                         setsize (player, m1, m2);
 474                         chmdl = true;
 475                 }
 476
 477                 if(!autocvar_sv_defaultcharacterskin)
 478                 {
 479                         oldskin = player.skin;
 480                         player.skin = stof(player.playerskin);
 481                 }
 482                 else
 483                 {
 484                         oldskin = player.skin;
 485                         player.skin = defaultskin;
 486                 }
 487         }
 488
 489         if(chmdl || oldskin != player.skin) // model or skin has changed
 490         {
 491                 player.species = player_getspecies(player); // update species
 492                 if(!autocvar_g_debug_globalsounds)
 493                         UpdatePlayerSounds(player); // update skin sounds
 494         }
 495
 496         if(!teamplay)
 497                 if(strlen(autocvar_sv_defaultplayercolors))
 498                         if(player.clientcolors != stof(autocvar_sv_defaultplayercolors))
 499                                 setcolor(player, stof(autocvar_sv_defaultplayercolors));
 500 }
 501
 502 void PutPlayerInServer(entity this)
 503 {
 504         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
 505
 506         PlayerState_attach(this);
 507         accuracy_resend(this);
 508
 509         if (this.team < 0)
 510                 JoinBestTeam(this, true);
 511
 512         entity spot = SelectSpawnPoint(this, false);
 513         if (!spot) {
 514                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_JOIN_NOSPAWNS);
 515                 return; // spawn failed
 516         }
 517
 518         TRANSMUTE(Player, this);
 519
 520         CS(this).wasplayer = true;
 521         this.iscreature = true;
 522         this.teleportable = TELEPORT_NORMAL;
 523         if(!this.damagedbycontents)
 524                 IL_PUSH(g_damagedbycontents, this);
 525         this.damagedbycontents = true;
 526         set_movetype(this, MOVETYPE_WALK);
 527         this.solid = SOLID_SLIDEBOX;
 528         this.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_SOLID;
 529         if (autocvar_g_playerclip_collisions)
 530                 this.dphitcontentsmask |= DPCONTENTS_PLAYERCLIP;
 531         if (IS_BOT_CLIENT(this) && autocvar_g_botclip_collisions)
 532                 this.dphitcontentsmask |= DPCONTENTS_BOTCLIP;
 533         this.frags = FRAGS_PLAYER;
 534         if (INDEPENDENT_PLAYERS) MAKE_INDEPENDENT_PLAYER(this);
 535         this.flags = FL_CLIENT | FL_PICKUPITEMS;
 536         if (autocvar__notarget)
 537                 this.flags |= FL_NOTARGET;
 538         this.takedamage = DAMAGE_AIM;
 539         this.effects = EF_TELEPORT_BIT | EF_RESTARTANIM_BIT;
 540
 541         if (warmup_stage) {
 542                 this.ammo_shells = warmup_start_ammo_shells;
 543                 this.ammo_nails = warmup_start_ammo_nails;
 544                 this.ammo_rockets = warmup_start_ammo_rockets;
 545                 this.ammo_cells = warmup_start_ammo_cells;
 546                 this.ammo_plasma = warmup_start_ammo_plasma;
 547                 this.ammo_fuel = warmup_start_ammo_fuel;
 548                 this.health = warmup_start_health;
 549                 this.armorvalue = warmup_start_armorvalue;
 550                 this.weapons = WARMUP_START_WEAPONS;
 551         } else {
 552                 this.ammo_shells = start_ammo_shells;
 553                 this.ammo_nails = start_ammo_nails;
 554                 this.ammo_rockets = start_ammo_rockets;
 555                 this.ammo_cells = start_ammo_cells;
 556                 this.ammo_plasma = start_ammo_plasma;
 557                 this.ammo_fuel = start_ammo_fuel;
 558                 this.health = start_health;
 559                 this.armorvalue = start_armorvalue;
 560                 this.weapons = start_weapons;
 561                 if (MUTATOR_CALLHOOK(ForbidRandomStartWeapons, this) == false)
 562                 {
 563                         GiveRandomWeapons(this, random_start_weapons_count,
 564                                 autocvar_g_random_start_weapons, random_start_ammo);
 565                 }
 566         }
 567         SetSpectatee_status(this, 0);
 568
 569         PS(this).dual_weapons = '0 0 0';
 570
 571         this.superweapons_finished = (this.weapons & WEPSET_SUPERWEAPONS) ? time + autocvar_g_balance_superweapons_time : 0;
 572
 573         this.items = start_items;
 574
 575         this.spawnshieldtime = time + autocvar_g_spawnshieldtime;
 576         this.pauserotarmor_finished = time + autocvar_g_balance_pause_armor_rot_spawn;
 577         this.pauserothealth_finished = time + autocvar_g_balance_pause_health_rot_spawn;
 578         this.pauserotfuel_finished = time + autocvar_g_balance_pause_fuel_rot_spawn;
 579         this.pauseregen_finished = time + autocvar_g_balance_pause_health_regen_spawn;
 580         // extend the pause of rotting if client was reset at the beginning of the countdown
 581         if (!autocvar_sv_ready_restart_after_countdown && time < game_starttime) { // TODO why is this cvar NOTted?
 582                 float f = game_starttime - time;
 583                 this.spawnshieldtime += f;
 584                 this.pauserotarmor_finished += f;
 585                 this.pauserothealth_finished += f;
 586                 this.pauseregen_finished += f;
 587         }
 588         this.damageforcescale = 2;
 589         this.death_time = 0;
 590         this.respawn_flags = 0;
 591         this.respawn_time = 0;
 592         this.stat_respawn_time = 0;
 593         this.scale = autocvar_sv_player_scale;
 594         this.fade_time = 0;
 595         this.pain_frame = 0;
 596         this.pain_finished = 0;
 597         this.pushltime = 0;
 598         setthink(this, func_null); // players have no think function
 599         this.nextthink = 0;
 600         this.dmg_team = 0;
 601         PS(this).ballistics_density = autocvar_g_ballistics_density_player;
 602
 603         this.deadflag = DEAD_NO;
 604
 605         this.angles = spot.angles;
 606         this.angles_z = 0; // never spawn tilted even if the spot says to
 607         if (IS_BOT_CLIENT(this))
 608                 this.v_angle = this.angles;
 609         this.fixangle = true; // turn this way immediately
 610         this.oldvelocity = this.velocity = '0 0 0';
 611         this.avelocity = '0 0 0';
 612         this.punchangle = '0 0 0';
 613         this.punchvector = '0 0 0';
 614
 615         this.strength_finished = 0;
 616         this.invincible_finished = 0;
 617         this.fire_endtime = -1;
 618         this.revive_progress = 0;
 619         this.revival_time = 0;
 620         this.air_finished = time + 12;
 621
 622         entity spawnevent = new_pure(spawnevent);
 623         spawnevent.owner = this;
 624         Net_LinkEntity(spawnevent, false, 0.5, SpawnEvent_Send);
 625
 626         // Cut off any still running player sounds.
 627         stopsound(this, CH_PLAYER_SINGLE);
 628
 629         this.model = "";
 630         FixPlayermodel(this);
 631         this.drawonlytoclient = NULL;
 632
 633         this.viewloc = NULL;
 634
 635         this.crouch = false;
 636         this.view_ofs = STAT(PL_VIEW_OFS, this);
 637         setsize(this, STAT(PL_MIN, this), STAT(PL_MAX, this));
 638         this.spawnorigin = spot.origin;
 639         setorigin(this, spot.origin + '0 0 1' * (1 - this.mins.z - 24));
 640         // don't reset back to last position, even if new position is stuck in solid
 641         this.oldorigin = this.origin;
 642         if(this.conveyor)
 643                 IL_REMOVE(g_conveyed, this);
 644         this.conveyor = NULL; // prevent conveyors at the previous location from moving a freshly spawned player
 645         this.hud = HUD_NORMAL;
 646
 647         this.event_damage = PlayerDamage;
 648
 649         if(!this.bot_attack)
 650                 IL_PUSH(g_bot_targets, this);
 651         this.bot_attack = true;
 652         if(!this.monster_attack)
 653                 IL_PUSH(g_monster_targets, this);
 654         this.monster_attack = true;
 655         navigation_dynamicgoal_init(this, false);
 656
 657         PHYS_INPUT_BUTTON_ATCK(this) = PHYS_INPUT_BUTTON_JUMP(this) = PHYS_INPUT_BUTTON_ATCK2(this) = false;
 658
 659         // player was spectator
 660         if (CS(this).killcount == FRAGS_SPECTATOR) {
 661                 PlayerScore_Clear(this);
 662                 CS(this).killcount = 0;
 663                 CS(this).startplaytime = time;
 664         }
 665
 666         for (int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 667         {
 668                 .entity weaponentity = weaponentities[slot];
 669                 entity oldwep = this.(weaponentity);
 670                 CL_SpawnWeaponentity(this, weaponentity);
 671                 if(oldwep && oldwep.owner == this)
 672                         this.(weaponentity).m_gunalign = oldwep.m_gunalign;
 673         }
 674         this.alpha = default_player_alpha;
 675         this.colormod = '1 1 1' * autocvar_g_player_brightness;
 676         this.exteriorweaponentity.alpha = default_weapon_alpha;
 677
 678         this.speedrunning = false;
 679
 680         target_voicescript_clear(this);
 681
 682         // reset fields the weapons may use
 683         FOREACH(Weapons, true, {
 684                 it.wr_resetplayer(it, this);
 685                         // reload all reloadable weapons
 686                 if (it.spawnflags & WEP_FLAG_RELOADABLE) {
 687                         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 688                         {
 689                                 .entity weaponentity = weaponentities[slot];
 690                                 this.(weaponentity).weapon_load[it.m_id] = it.reloading_ammo;
 691                         }
 692                 }
 693         });
 694
 695         {
 696                 string s = spot.target;
 697                 spot.target = string_null;
 698                 SUB_UseTargets(spot, this, NULL);
 699                 spot.target = s;
 700         }
 701
 702         Unfreeze(this);
 703
 704         MUTATOR_CALLHOOK(PlayerSpawn, this, spot);
 705
 706         if (autocvar_spawn_debug)
 707         {
 708                 sprint(this, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
 709                 delete(spot); // usefull for checking if there are spawnpoints, that let drop through the floor
 710         }
 711
 712         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 713         {
 714                 .entity weaponentity = weaponentities[slot];
 715                 if(slot == 0 || autocvar_g_weaponswitch_debug == 1)
 716                         this.(weaponentity).m_switchweapon = w_getbestweapon(this, weaponentity);
 717                 else
 718                         this.(weaponentity).m_switchweapon = WEP_Null;
 719                 this.(weaponentity).m_weapon = WEP_Null;
 720                 this.(weaponentity).weaponname = "";
 721                 this.(weaponentity).m_switchingweapon = WEP_Null;
 722                 this.(weaponentity).cnt = -1;
 723         }
 724
 725         MUTATOR_CALLHOOK(PlayerWeaponSelect, this);
 726
 727         if (!warmup_stage && !this.alivetime)
 728                 this.alivetime = time;
 729
 730         antilag_clear(this, CS(this));
 731 }
 732
 733 /** Called when a client spawns in the server */
 734 void PutClientInServer(entity this)
 735 {
 736         if (IS_BOT_CLIENT(this)) {
 737                 TRANSMUTE(Player, this);
 738         } else if (IS_REAL_CLIENT(this)) {
 739                 msg_entity = this;
 740                 WriteByte(MSG_ONE, SVC_SETVIEW);
 741                 WriteEntity(MSG_ONE, this);
 742         }
 743         if (game_stopped)
 744                 TRANSMUTE(Observer, this);
 745
 746         SetSpectatee(this, NULL);
 747
 748         // reset player keys
 749         if(PS(this))
 750                 PS(this).itemkeys = 0;
 751
 752         MUTATOR_CALLHOOK(PutClientInServer, this);
 753
 754         if (IS_OBSERVER(this)) {
 755                 PutObserverInServer(this);
 756         } else if (IS_PLAYER(this)) {
 757                 PutPlayerInServer(this);
 758         }
 759 }
 760
 761 void ClientInit_misc(entity this);
 762
 763 // TODO do we need all these fields, or should we stop autodetecting runtime
 764 // changes and just have a console command to update this?
 765 bool ClientInit_SendEntity(entity this, entity to, int sf)
 766 {
 767         WriteHeader(MSG_ENTITY, _ENT_CLIENT_INIT);
 768         return = true;
 769         msg_entity = to;
 770         // MSG_INIT replacement
 771         // TODO: make easier to use
 772         Registry_send_all();
 773         W_PROP_reload(MSG_ONE, to);
 774         ClientInit_misc(this);
 775         MUTATOR_CALLHOOK(Ent_Init);
 776 }
 777 void ClientInit_misc(entity this)
 778 {
 779         int channel = MSG_ONE;
 780         WriteHeader(channel, ENT_CLIENT_INIT);
 781         WriteByte(channel, g_nexball_meter_period * 32);
 782         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[0]));
 783         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[1]));
 784         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[2]));
 785         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[3]));
 786         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[0]));
 787         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[1]));
 788         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[2]));
 789         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[3]));
 790
 791         if(sv_foginterval && world.fog != "")
 792                 WriteString(channel, world.fog);
 793         else
 794                 WriteString(channel, "");
 795         WriteByte(channel, this.count * 255.0); // g_balance_armor_blockpercent
 796         WriteByte(channel, this.cnt * 255.0); // g_balance_damagepush_speedfactor
 797         WriteByte(channel, serverflags);
 798         WriteCoord(channel, autocvar_g_trueaim_minrange);
 799 }
 800
 801 void ClientInit_CheckUpdate(entity this)
 802 {
 803         this.nextthink = time;
 804         if(this.count != autocvar_g_balance_armor_blockpercent)
 805         {
 806                 this.count = autocvar_g_balance_armor_blockpercent;
 807                 this.SendFlags |= 1;
 808         }
 809         if(this.cnt != autocvar_g_balance_damagepush_speedfactor)
 810         {
 811                 this.cnt = autocvar_g_balance_damagepush_speedfactor;
 812                 this.SendFlags |= 1;
 813         }
 814 }
 815
 816 void ClientInit_Spawn()
 817 {
 818         entity e = new_pure(clientinit);
 819         setthink(e, ClientInit_CheckUpdate);
 820         Net_LinkEntity(e, false, 0, ClientInit_SendEntity);
 821
 822         ClientInit_CheckUpdate(e);
 823 }
 824
 825 /*
 826 =============
 827 SetNewParms
 828 =============
 829 */
 830 void SetNewParms ()
 831 {
 832         // initialize parms for a new player
 833         parm1 = -(86400 * 366);
 834
 835         MUTATOR_CALLHOOK(SetNewParms);
 836 }
 837
 838 /*
 839 =============
 840 SetChangeParms
 841 =============
 842 */
 843 void SetChangeParms (entity this)
 844 {
 845         // save parms for level change
 846         parm1 = CS(this).parm_idlesince - time;
 847
 848         MUTATOR_CALLHOOK(SetChangeParms);
 849 }
 850
 851 /*
 852 =============
 853 DecodeLevelParms
 854 =============
 855 */
 856 void DecodeLevelParms(entity this)
 857 {
 858         // load parms
 859         CS(this).parm_idlesince = parm1;
 860         if (CS(this).parm_idlesince == -(86400 * 366))
 861                 CS(this).parm_idlesince = time;
 862
 863         // whatever happens, allow 60 seconds of idling directly after connect for map loading
 864         CS(this).parm_idlesince = max(CS(this).parm_idlesince, time - sv_maxidle + 60);
 865
 866         MUTATOR_CALLHOOK(DecodeLevelParms);
 867 }
 868
 869 /*
 870 =============
 871 ClientKill
 872
 873 Called when a client types 'kill' in the console
 874 =============
 875 */
 876
 877 .float clientkill_nexttime;
 878 void ClientKill_Now_TeamChange(entity this)
 879 {
 880         if(this.killindicator_teamchange == -1)
 881         {
 882                 JoinBestTeam( this, true );
 883         }
 884         else if(this.killindicator_teamchange == -2)
 885         {
 886                 if(blockSpectators)
 887                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
 888                 PutObserverInServer(this);
 889         }
 890         else
 891                 SV_ChangeTeam(this, this.killindicator_teamchange - 1);
 892         this.killindicator_teamchange = 0;
 893 }
 894
 895 void ClientKill_Now(entity this)
 896 {
 897         if(this.vehicle)
 898         {
 899             vehicles_exit(this.vehicle, VHEF_RELEASE);
 900             if(!this.killindicator_teamchange)
 901             {
 902             this.vehicle_health = -1;
 903             Damage(this, this, this, 1 , DEATH_KILL.m_id, this.origin, '0 0 0');
 904             }
 905         }
 906
 907         if(this.killindicator && !wasfreed(this.killindicator))
 908                 delete(this.killindicator);
 909
 910         this.killindicator = NULL;
 911
 912         if(this.killindicator_teamchange)
 913                 ClientKill_Now_TeamChange(this);
 914
 915         if (!IS_SPEC(this) && !IS_OBSERVER(this) && MUTATOR_CALLHOOK(ClientKill_Now, this) == false)
 916         {
 917                 Damage(this, this, this, 100000, DEATH_KILL.m_id, this.origin, '0 0 0');
 918         }
 919
 920         // now I am sure the player IS dead
 921 }
 922 void KillIndicator_Think(entity this)
 923 {
 924         if (game_stopped)
 925         {
 926                 this.owner.killindicator = NULL;
 927                 delete(this);
 928                 return;
 929         }
 930
 931         if (this.owner.alpha < 0 && !this.owner.vehicle)
 932         {
 933                 this.owner.killindicator = NULL;
 934                 delete(this);
 935                 return;
 936         }
 937
 938         if(this.cnt <= 0)
 939         {
 940                 ClientKill_Now(this.owner);
 941                 return;
 942         }
 943     else if(this.health == 1) // health == 1 means that it's silent
 944     {
 945         this.nextthink = time + 1;
 946         this.cnt -= 1;
 947     }
 948         else
 949         {
 950                 if(this.cnt <= 10)
 951                         setmodel(this, MDL_NUM(this.cnt));
 952                 if(IS_REAL_CLIENT(this.owner))
 953                 {
 954                         if(this.cnt <= 10)
 955                                 { Send_Notification(NOTIF_ONE, this.owner, MSG_ANNCE, Announcer_PickNumber(CNT_KILL, this.cnt)); }
 956                 }
 957                 this.nextthink = time + 1;
 958                 this.cnt -= 1;
 959         }
 960 }
 961
 962 float clientkilltime;
 963 void ClientKill_TeamChange (entity this, float targetteam) // 0 = don't change, -1 = auto, -2 = spec
 964 {
 965         float killtime;
 966         float starttime;
 967
 968         if (game_stopped)
 969                 return;
 970
 971         killtime = autocvar_g_balance_kill_delay;
 972
 973     if(MUTATOR_CALLHOOK(ClientKill, this, killtime))
 974         return;
 975     killtime = M_ARGV(1, float);
 976
 977         this.killindicator_teamchange = targetteam;
 978
 979     if(!this.killindicator)
 980         {
 981                 if(!IS_DEAD(this))
 982                 {
 983                         killtime = max(killtime, this.clientkill_nexttime - time);
 984                         this.clientkill_nexttime = time + killtime + autocvar_g_balance_kill_antispam;
 985                 }
 986
 987                 if(killtime <= 0 || !IS_PLAYER(this) || IS_DEAD(this))
 988                 {
 989                         ClientKill_Now(this);
 990                 }
 991                 else
 992                 {
 993                         starttime = max(time, clientkilltime);
 994
 995                         this.killindicator = spawn();
 996                         this.killindicator.owner = this;
 997                         this.killindicator.scale = 0.5;
 998                         setattachment(this.killindicator, this, "");
 999                         setorigin(this.killindicator, '0 0 52');
1000                         setthink(this.killindicator, KillIndicator_Think);
1001                         this.killindicator.nextthink = starttime + (this.lip) * 0.05;
1002                         clientkilltime = max(clientkilltime, this.killindicator.nextthink + 0.05);
1003                         this.killindicator.cnt = ceil(killtime);
1004                         this.killindicator.count = bound(0, ceil(killtime), 10);
1005                         //sprint(this, strcat("^1You'll be dead in ", ftos(this.killindicator.cnt), " seconds\n"));
1006
1007                         IL_EACH(g_clones, it.enemy == this && !(it.effects & CSQCMODEL_EF_RESPAWNGHOST),
1008                         {
1009                                 it.killindicator = spawn();
1010                                 it.killindicator.owner = it;
1011                                 it.killindicator.scale = 0.5;
1012                                 setattachment(it.killindicator, it, "");
1013                                 setorigin(it.killindicator, '0 0 52');
1014                                 setthink(it.killindicator, KillIndicator_Think);
1015                                 it.killindicator.nextthink = starttime + (it.lip) * 0.05;
1016                                 //clientkilltime = max(clientkilltime, it.killindicator.nextthink + 0.05);
1017                                 it.killindicator.cnt = ceil(killtime);
1018                         });
1019                         this.lip = 0;
1020                 }
1021         }
1022         if(this.killindicator)
1023         {
1024                 if(targetteam == 0) // just die
1025                 {
1026                         this.killindicator.colormod = '0 0 0';
1027                         if(IS_REAL_CLIENT(this))
1028                         if(this.killindicator.cnt > 0)
1029                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_TEAMCHANGE_SUICIDE, this.killindicator.cnt);
1030                 }
1031                 else if(targetteam == -1) // auto
1032                 {
1033                         this.killindicator.colormod = '0 1 0';
1034                         if(IS_REAL_CLIENT(this))
1035                         if(this.killindicator.cnt > 0)
1036                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_TEAMCHANGE_AUTO, this.killindicator.cnt);
1037                 }
1038                 else if(targetteam == -2) // spectate
1039                 {
1040                         this.killindicator.colormod = '0.5 0.5 0.5';
1041                         if(IS_REAL_CLIENT(this))
1042                         if(this.killindicator.cnt > 0)
1043                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_TEAMCHANGE_SPECTATE, this.killindicator.cnt);
1044                 }
1045                 else
1046                 {
1047                         this.killindicator.colormod = Team_ColorRGB(targetteam);
1048                         if(IS_REAL_CLIENT(this))
1049                         if(this.killindicator.cnt > 0)
1050                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, APP_TEAM_NUM(targetteam, CENTER_TEAMCHANGE), this.killindicator.cnt);
1051                 }
1052         }
1053
1054 }
1055
1056 void ClientKill (entity this)
1057 {
1058         if(game_stopped) return;
1059         if(this.player_blocked) return;
1060         if(STAT(FROZEN, this)) return;
1061
1062         ClientKill_TeamChange(this, 0);
1063 }
1064
1065 void FixClientCvars(entity e)
1066 {
1067         // send prediction settings to the client
1068         stuffcmd(e, "\nin_bindmap 0 0\n");
1069         if(autocvar_g_antilag == 3) // client side hitscan
1070                 stuffcmd(e, "cl_cmd settemp cl_prydoncursor_notrace 0\n");
1071         if(autocvar_sv_gentle)
1072                 stuffcmd(e, "cl_cmd settemp cl_gentle 1\n");
1073
1074         stuffcmd(e, sprintf("\ncl_jumpspeedcap_min \"%s\"\n", autocvar_sv_jumpspeedcap_min));
1075         stuffcmd(e, sprintf("\ncl_jumpspeedcap_max \"%s\"\n", autocvar_sv_jumpspeedcap_max));
1076
1077         MUTATOR_CALLHOOK(FixClientCvars, e);
1078 }
1079
1080 bool findinlist_abbrev(string tofind, string list)
1081 {
1082         if(list == "" || tofind == "")
1083                 return false; // empty list or search, just return
1084
1085         // this function allows abbreviated strings!
1086         FOREACH_WORD(list, it == substring(tofind, 0, strlen(it)),
1087         {
1088                 return true;
1089         });
1090
1091         return false;
1092 }
1093
1094 bool PlayerInIPList(entity p, string iplist)
1095 {
1096         // some safety checks (never allow local?)
1097         if(p.netaddress == "local" || p.netaddress == "" || !IS_REAL_CLIENT(p))
1098                 return false;
1099
1100         return findinlist_abbrev(p.netaddress, iplist);
1101 }
1102
1103 bool PlayerInIDList(entity p, string idlist)
1104 {
1105         // NOTE: we do NOT check crypto_idfp_signed here, an unsigned ID is fine too for this
1106         if(!p.crypto_idfp)
1107                 return false;
1108
1109         return findinlist_abbrev(p.crypto_idfp, idlist);
1110 }
1111
1112 bool PlayerInList(entity player, string list)
1113 {
1114         return boolean(PlayerInIDList(player, list) || PlayerInIPList(player, list));
1115 }
1116
1117 #ifdef DP_EXT_PRECONNECT
1118 /*
1119 =============
1120 ClientPreConnect
1121
1122 Called once (not at each match start) when a client begins a connection to the server
1123 =============
1124 */
1125 void ClientPreConnect(entity this)
1126 {
1127         if(autocvar_sv_eventlog)
1128         {
1129                 GameLogEcho(sprintf(":connect:%d:%d:%s",
1130                         this.playerid,
1131                         etof(this),
1132                         ((IS_REAL_CLIENT(this)) ? this.netaddress : "bot")
1133                 ));
1134         }
1135 }
1136 #endif
1137
1138 /**
1139 =============
1140 ClientConnect
1141
1142 Called when a client connects to the server
1143 =============
1144 */
1145 void ClientConnect(entity this)
1146 {
1147         if (Ban_MaybeEnforceBanOnce(this)) return;
1148         assert(!IS_CLIENT(this), return);
1149         this.flags |= FL_CLIENT;
1150         assert(player_count >= 0, player_count = 0);
1151
1152 #ifdef WATERMARK
1153         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_WATERMARK, WATERMARK);
1154 #endif
1155         TRANSMUTE(Client, this);
1156         CS(this).version_nagtime = time + 10 + random() * 10;
1157
1158         // identify the right forced team
1159         if (autocvar_g_campaign)
1160         {
1161                 if (IS_REAL_CLIENT(this)) // only players, not bots
1162                 {
1163                         switch (autocvar_g_campaign_forceteam)
1164                         {
1165                                 case 1: this.team_forced = NUM_TEAM_1; break;
1166                                 case 2: this.team_forced = NUM_TEAM_2; break;
1167                                 case 3: this.team_forced = NUM_TEAM_3; break;
1168                                 case 4: this.team_forced = NUM_TEAM_4; break;
1169                                 default: this.team_forced = 0;
1170                         }
1171                 }
1172         }
1173         else if (PlayerInList(this, autocvar_g_forced_team_red))    this.team_forced = NUM_TEAM_1;
1174         else if (PlayerInList(this, autocvar_g_forced_team_blue))   this.team_forced = NUM_TEAM_2;
1175         else if (PlayerInList(this, autocvar_g_forced_team_yellow)) this.team_forced = NUM_TEAM_3;
1176         else if (PlayerInList(this, autocvar_g_forced_team_pink))   this.team_forced = NUM_TEAM_4;
1177         else switch (autocvar_g_forced_team_otherwise)
1178         {
1179                 default: this.team_forced = 0; break;
1180                 case "red": this.team_forced = NUM_TEAM_1; break;
1181                 case "blue": this.team_forced = NUM_TEAM_2; break;
1182                 case "yellow": this.team_forced = NUM_TEAM_3; break;
1183                 case "pink": this.team_forced = NUM_TEAM_4; break;
1184                 case "spectate":
1185                 case "spectator":
1186                         this.team_forced = -1;
1187                         break;
1188         }
1189         if (!teamplay && this.team_forced > 0) this.team_forced = 0;
1190
1191     {
1192         int id = this.playerid;
1193         this.playerid = 0; // silent
1194             JoinBestTeam(this, false); // if the team number is valid, keep it
1195             this.playerid = id;
1196     }
1197
1198         if (autocvar_sv_spectate || autocvar_g_campaign || this.team_forced < 0) {
1199                 TRANSMUTE(Observer, this);
1200         } else {
1201                 if (!teamplay || autocvar_g_balance_teams) {
1202                         TRANSMUTE(Player, this);
1203                         campaign_bots_may_start = true;
1204                 } else {
1205                         TRANSMUTE(Observer, this); // do it anyway
1206                 }
1207         }
1208
1209         PlayerStats_GameReport_AddEvent(sprintf("kills-%d", this.playerid));
1210
1211         // always track bots, don't ask for cl_allow_uidtracking
1212         if (IS_BOT_CLIENT(this))
1213                 PlayerStats_GameReport_AddPlayer(this);
1214         else
1215                 CS(this).allowed_timeouts = autocvar_sv_timeout_number;
1216
1217         if (autocvar_sv_eventlog)
1218                 GameLogEcho(strcat(":join:", ftos(this.playerid), ":", ftos(etof(this)), ":", ((IS_REAL_CLIENT(this)) ? this.netaddress : "bot"), ":", playername(this, false)));
1219
1220         LogTeamchange(this.playerid, this.team, 1);
1221
1222         CS(this).just_joined = true;  // stop spamming the eventlog with additional lines when the client connects
1223
1224         if(teamplay && IS_PLAYER(this))
1225                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, APP_TEAM_NUM(this.team, INFO_JOIN_CONNECT_TEAM), this.netname);
1226         else
1227                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_JOIN_CONNECT, this.netname);
1228
1229         stuffcmd(this, clientstuff, "\n");
1230         stuffcmd(this, "cl_particles_reloadeffects\n"); // TODO do we still need this?
1231
1232         FixClientCvars(this);
1233
1234         // get version info from player
1235         stuffcmd(this, "cmd clientversion $gameversion\n");
1236
1237         // notify about available teams
1238         if (teamplay)
1239         {
1240                 CheckAllowedTeams(this);
1241                 int t = 0;
1242                 if (c1 >= 0) t |= BIT(0);
1243                 if (c2 >= 0) t |= BIT(1);
1244                 if (c3 >= 0) t |= BIT(2);
1245                 if (c4 >= 0) t |= BIT(3);
1246                 stuffcmd(this, sprintf("set _teams_available %d\n", t));
1247         }
1248         else
1249         {
1250                 stuffcmd(this, "set _teams_available 0\n");
1251         }
1252
1253         bot_relinkplayerlist();
1254
1255         CS(this).spectatortime = time;
1256         if (blockSpectators)
1257         {
1258                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
1259         }
1260
1261         CS(this).jointime = time;
1262
1263         if (IS_REAL_CLIENT(this))
1264         {
1265                 if (g_weaponarena_weapons == WEPSET(TUBA))
1266                         stuffcmd(this, "cl_cmd settemp chase_active 1\n");
1267         }
1268
1269         if (!sv_foginterval && world.fog != "")
1270                 stuffcmd(this, strcat("\nfog ", world.fog, "\nr_fog_exp2 0\nr_drawfog 1\n"));
1271
1272         if (autocvar_sv_teamnagger && !(autocvar_bot_vs_human && AvailableTeams() == 2))
1273                 if(!MUTATOR_CALLHOOK(HideTeamNagger, this))
1274                         send_CSQC_teamnagger();
1275
1276         CSQCMODEL_AUTOINIT(this);
1277
1278         CS(this).model_randomizer = random();
1279
1280         if (IS_REAL_CLIENT(this))
1281                 sv_notice_join(this);
1282
1283         // update physics stats (players can spawn before physics runs)
1284         Physics_UpdateStats(this);
1285
1286         IL_EACH(g_initforplayer, it.init_for_player, {
1287                 it.init_for_player(it, this);
1288         });
1289
1290         Handicap_Initialize(this);
1291
1292         MUTATOR_CALLHOOK(ClientConnect, this);
1293
1294         if (IS_REAL_CLIENT(this))
1295         {
1296                 if (!autocvar_g_campaign && !IS_PLAYER(this))
1297                 {
1298                         CS(this).motd_actived_time = -1;
1299                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOTD, getwelcomemessage(this));
1300                 }
1301         }
1302 }
1303 /*
1304 =============
1305 ClientDisconnect
1306
1307 Called when a client disconnects from the server
1308 =============
1309 */
1310 .entity chatbubbleentity;
1311 void ReadyCount();
1312 void ClientDisconnect(entity this)
1313 {
1314         assert(IS_CLIENT(this), return);
1315
1316         PlayerStats_GameReport_FinalizePlayer(this);
1317         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
1318         if (CS(this).active_minigame) part_minigame(this);
1319         if (IS_PLAYER(this)) Send_Effect(EFFECT_SPAWN_NEUTRAL, this.origin, '0 0 0', 1);
1320
1321         if (autocvar_sv_eventlog)
1322                 GameLogEcho(strcat(":part:", ftos(this.playerid)));
1323
1324         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_QUIT_DISCONNECT, this.netname);
1325
1326         if(IS_SPEC(this))
1327                 SetSpectatee(this, NULL);
1328
1329     MUTATOR_CALLHOOK(ClientDisconnect, this);
1330
1331         if (CS(this).netname_previous) strunzone(CS(this).netname_previous); // needs to be before the CS entity is removed!
1332         ClientState_detach(this);
1333
1334         Portal_ClearAll(this);
1335
1336         Unfreeze(this);
1337
1338         RemoveGrapplingHooks(this);
1339
1340         // Here, everything has been done that requires this player to be a client.
1341
1342         this.flags &= ~FL_CLIENT;
1343
1344         if (this.chatbubbleentity) delete(this.chatbubbleentity);
1345         if (this.killindicator) delete(this.killindicator);
1346
1347         WaypointSprite_PlayerGone(this);
1348
1349         bot_relinkplayerlist();
1350
1351         if (this.clientstatus) strunzone(this.clientstatus);
1352         if (this.weaponorder_byimpulse) strunzone(this.weaponorder_byimpulse);
1353         if (this.personal) delete(this.personal);
1354
1355         this.playerid = 0;
1356         ReadyCount();
1357         if (vote_called && IS_REAL_CLIENT(this)) VoteCount(false);
1358
1359         ONREMOVE(this);
1360 }
1361
1362 void ChatBubbleThink(entity this)
1363 {
1364         this.nextthink = time;
1365         if ((this.owner.alpha < 0) || this.owner.chatbubbleentity != this)
1366         {
1367                 if(this.owner) // but why can that ever be NULL?
1368                         this.owner.chatbubbleentity = NULL;
1369                 delete(this);
1370                 return;
1371         }
1372
1373         this.mdl = "";
1374
1375         if ( !IS_DEAD(this.owner) && IS_PLAYER(this.owner) )
1376         {
1377                 if ( CS(this.owner).active_minigame )
1378                         this.mdl = "models/sprites/minigame_busy.iqm";
1379                 else if (PHYS_INPUT_BUTTON_CHAT(this.owner))
1380                         this.mdl = "models/misc/chatbubble.spr";
1381         }
1382
1383         if ( this.model != this.mdl )
1384                 _setmodel(this, this.mdl);
1385
1386 }
1387
1388 void UpdateChatBubble(entity this)
1389 {
1390         if (this.alpha < 0)
1391                 return;
1392         // spawn a chatbubble entity if needed
1393         if (!this.chatbubbleentity)
1394         {
1395                 this.chatbubbleentity = new(chatbubbleentity);
1396                 this.chatbubbleentity.owner = this;
1397                 this.chatbubbleentity.exteriormodeltoclient = this;
1398                 setthink(this.chatbubbleentity, ChatBubbleThink);
1399                 this.chatbubbleentity.nextthink = time;
1400                 setmodel(this.chatbubbleentity, MDL_CHAT); // precision set below
1401                 //setorigin(this.chatbubbleentity, this.origin + '0 0 15' + this.maxs_z * '0 0 1');
1402                 setorigin(this.chatbubbleentity, '0 0 15' + this.maxs_z * '0 0 1');
1403                 setattachment(this.chatbubbleentity, this, "");  // sticks to moving player better, also conserves bandwidth
1404                 this.chatbubbleentity.mdl = this.chatbubbleentity.model;
1405                 //this.chatbubbleentity.model = "";
1406                 this.chatbubbleentity.effects = EF_LOWPRECISION;
1407         }
1408 }
1409
1410
1411 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
1412 // added to the model skins
1413 /*void UpdateColorModHack()
1414 {
1415         float c;
1416         c = this.clientcolors & 15;
1417         // LordHavoc: only bothering to support white, green, red, yellow, blue
1418              if (!teamplay) this.colormod = '0 0 0';
1419         else if (c ==  0) this.colormod = '1.00 1.00 1.00';
1420         else if (c ==  3) this.colormod = '0.10 1.73 0.10';
1421         else if (c ==  4) this.colormod = '1.73 0.10 0.10';
1422         else if (c == 12) this.colormod = '1.22 1.22 0.10';
1423         else if (c == 13) this.colormod = '0.10 0.10 1.73';
1424         else this.colormod = '1 1 1';
1425 }*/
1426
1427 void respawn(entity this)
1428 {
1429         if(this.alpha >= 0 && autocvar_g_respawn_ghosts)
1430         {
1431                 this.solid = SOLID_NOT;
1432                 this.takedamage = DAMAGE_NO;
1433                 set_movetype(this, MOVETYPE_FLY);
1434                 this.velocity = '0 0 1' * autocvar_g_respawn_ghosts_speed;
1435                 this.avelocity = randomvec() * autocvar_g_respawn_ghosts_speed * 3 - randomvec() * autocvar_g_respawn_ghosts_speed * 3;
1436                 this.effects |= CSQCMODEL_EF_RESPAWNGHOST;
1437                 Send_Effect(EFFECT_RESPAWN_GHOST, this.origin, '0 0 0', 1);
1438                 if(autocvar_g_respawn_ghosts_maxtime)
1439                         SUB_SetFade (this, time + autocvar_g_respawn_ghosts_maxtime / 2 + random () * (autocvar_g_respawn_ghosts_maxtime - autocvar_g_respawn_ghosts_maxtime / 2), 1.5);
1440         }
1441
1442         CopyBody(this, 1);
1443
1444         this.effects |= EF_NODRAW; // prevent another CopyBody
1445         PutClientInServer(this);
1446 }
1447
1448 void play_countdown(entity this, float finished, Sound samp)
1449 {
1450     TC(Sound, samp);
1451         if(IS_REAL_CLIENT(this))
1452                 if(floor(finished - time - frametime) != floor(finished - time))
1453                         if(finished - time < 6)
1454                                 sound (this, CH_INFO, samp, VOL_BASE, ATTEN_NORM);
1455 }
1456
1457 void player_powerups(entity this)
1458 {
1459         // add a way to see what the items were BEFORE all of these checks for the mutator hook
1460         int items_prev = this.items;
1461
1462         if((this.items & IT_USING_JETPACK) && !IS_DEAD(this) && !game_stopped)
1463                 this.modelflags |= MF_ROCKET;
1464         else
1465                 this.modelflags &= ~MF_ROCKET;
1466
1467         this.effects &= ~(EF_RED | EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT | EF_FLAME | EF_NODEPTHTEST);
1468
1469         if((this.alpha < 0 || IS_DEAD(this)) && !this.vehicle) // don't apply the flags if the player is gibbed
1470                 return;
1471
1472         Fire_ApplyDamage(this);
1473         Fire_ApplyEffect(this);
1474
1475         if (!g_instagib)
1476         {
1477                 if (this.items & ITEM_Strength.m_itemid)
1478                 {
1479                         play_countdown(this, this.strength_finished, SND_POWEROFF);
1480                         this.effects = this.effects | (EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT);
1481                         if (time > this.strength_finished)
1482                         {
1483                                 this.items = this.items - (this.items & ITEM_Strength.m_itemid);
1484                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERDOWN_STRENGTH, this.netname);
1485                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERDOWN_STRENGTH);
1486                         }
1487                 }
1488                 else
1489                 {
1490                         if (time < this.strength_finished)
1491                         {
1492                                 this.items = this.items | ITEM_Strength.m_itemid;
1493                                 if(!g_cts)
1494                                         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERUP_STRENGTH, this.netname);
1495                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERUP_STRENGTH);
1496                         }
1497                 }
1498                 if (this.items & ITEM_Shield.m_itemid)
1499                 {
1500                         play_countdown(this, this.invincible_finished, SND_POWEROFF);
1501                         this.effects = this.effects | (EF_RED | EF_ADDITIVE | EF_FULLBRIGHT);
1502                         if (time > this.invincible_finished)
1503                         {
1504                                 this.items = this.items - (this.items & ITEM_Shield.m_itemid);
1505                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERDOWN_SHIELD, this.netname);
1506                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERDOWN_SHIELD);
1507                         }
1508                 }
1509                 else
1510                 {
1511                         if (time < this.invincible_finished)
1512                         {
1513                                 this.items = this.items | ITEM_Shield.m_itemid;
1514                                 if(!g_cts)
1515                                         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERUP_SHIELD, this.netname);
1516                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERUP_SHIELD);
1517                         }
1518                 }
1519                 if (this.items & IT_SUPERWEAPON)
1520                 {
1521                         if (!(this.weapons & WEPSET_SUPERWEAPONS))
1522                         {
1523                                 this.superweapons_finished = 0;
1524                                 this.items = this.items - (this.items & IT_SUPERWEAPON);
1525                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_LOST, this.netname);
1526                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_LOST);
1527                         }
1528                         else if (this.items & IT_UNLIMITED_SUPERWEAPONS)
1529                         {
1530                                 // don't let them run out
1531                         }
1532                         else
1533                         {
1534                                 play_countdown(this, this.superweapons_finished, SND_POWEROFF);
1535                                 if (time > this.superweapons_finished)
1536                                 {
1537                                         this.items = this.items - (this.items & IT_SUPERWEAPON);
1538                                         this.weapons &= ~WEPSET_SUPERWEAPONS;
1539                                         //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_BROKEN, this.netname);
1540                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_BROKEN);
1541                                 }
1542                         }
1543                 }
1544                 else if(this.weapons & WEPSET_SUPERWEAPONS)
1545                 {
1546                         if (time < this.superweapons_finished || (this.items & IT_UNLIMITED_SUPERWEAPONS))
1547                         {
1548                                 this.items = this.items | IT_SUPERWEAPON;
1549                                 if(!g_cts)
1550                                         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_PICKUP, this.netname);
1551                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_PICKUP);
1552                         }
1553                         else
1554                         {
1555                                 this.superweapons_finished = 0;
1556                                 this.weapons &= ~WEPSET_SUPERWEAPONS;
1557                         }
1558                 }
1559                 else
1560                 {
1561                         this.superweapons_finished = 0;
1562                 }
1563         }
1564
1565         if(autocvar_g_nodepthtestplayers)
1566                 this.effects = this.effects | EF_NODEPTHTEST;
1567
1568         if(autocvar_g_fullbrightplayers)
1569                 this.effects = this.effects | EF_FULLBRIGHT;
1570
1571         if (time >= game_starttime)
1572         if (time < this.spawnshieldtime)
1573                 this.effects = this.effects | (EF_ADDITIVE | EF_FULLBRIGHT);
1574
1575         MUTATOR_CALLHOOK(PlayerPowerups, this, items_prev);
1576 }
1577
1578 float CalcRegen(float current, float stable, float regenfactor, float regenframetime)
1579 {
1580         if(current > stable)
1581                 return current;
1582         else if(current > stable - 0.25) // when close enough, "snap"
1583                 return stable;
1584         else
1585                 return min(stable, current + (stable - current) * regenfactor * regenframetime);
1586 }
1587
1588 float CalcRot(float current, float stable, float rotfactor, float rotframetime)
1589 {
1590         if(current < stable)
1591                 return current;
1592         else if(current < stable + 0.25) // when close enough, "snap"
1593                 return stable;
1594         else
1595                 return max(stable, current + (stable - current) * rotfactor * rotframetime);
1596 }
1597
1598 float CalcRotRegen(float current, float regenstable, float regenfactor, float regenlinear, float regenframetime, float rotstable, float rotfactor, float rotlinear, float rotframetime, float limit)
1599 {
1600         if(current > rotstable)
1601         {
1602                 if(rotframetime > 0)
1603                 {
1604                         current = CalcRot(current, rotstable, rotfactor, rotframetime);
1605                         current = max(rotstable, current - rotlinear * rotframetime);
1606                 }
1607         }
1608         else if(current < regenstable)
1609         {
1610                 if(regenframetime > 0)
1611                 {
1612                         current = CalcRegen(current, regenstable, regenfactor, regenframetime);
1613                         current = min(regenstable, current + regenlinear * regenframetime);
1614                 }
1615         }
1616
1617         if(current > limit)
1618                 current = limit;
1619
1620         return current;
1621 }
1622
1623 void player_regen(entity this)
1624 {
1625         float max_mod, regen_mod, rot_mod, limit_mod;
1626         max_mod = regen_mod = rot_mod = limit_mod = 1;
1627
1628         float regen_health = autocvar_g_balance_health_regen;
1629         float regen_health_linear = autocvar_g_balance_health_regenlinear;
1630         float regen_health_rot = autocvar_g_balance_health_rot;
1631         float regen_health_rotlinear = autocvar_g_balance_health_rotlinear;
1632         float regen_health_stable = autocvar_g_balance_health_regenstable;
1633         float regen_health_rotstable = autocvar_g_balance_health_rotstable;
1634         bool mutator_returnvalue = MUTATOR_CALLHOOK(PlayerRegen, this, max_mod, regen_mod, rot_mod, limit_mod, regen_health, regen_health_linear, regen_health_rot,
1635                 regen_health_rotlinear, regen_health_stable, regen_health_rotstable);
1636         max_mod = M_ARGV(1, float);
1637         regen_mod = M_ARGV(2, float);
1638         rot_mod = M_ARGV(3, float);
1639         limit_mod = M_ARGV(4, float);
1640         regen_health = M_ARGV(5, float);
1641         regen_health_linear = M_ARGV(6, float);
1642         regen_health_rot = M_ARGV(7, float);
1643         regen_health_rotlinear = M_ARGV(8, float);
1644         regen_health_stable = M_ARGV(9, float);
1645         regen_health_rotstable = M_ARGV(10, float);
1646
1647         if(!mutator_returnvalue)
1648         if(!STAT(FROZEN, this))
1649         {
1650                 float mina, maxa, limith, limita;
1651                 maxa = autocvar_g_balance_armor_rotstable;
1652                 mina = autocvar_g_balance_armor_regenstable;
1653                 limith = GetResourceLimit(this, RESOURCE_HEALTH);
1654                 limita = GetResourceLimit(this, RESOURCE_ARMOR);
1655
1656                 regen_health_rotstable = regen_health_rotstable * max_mod;
1657                 regen_health_stable = regen_health_stable * max_mod;
1658                 limith = limith * limit_mod;
1659                 limita = limita * limit_mod;
1660
1661                 this.armorvalue = CalcRotRegen(this.armorvalue, mina, autocvar_g_balance_armor_regen, autocvar_g_balance_armor_regenlinear, regen_mod * frametime * (time > this.pauseregen_finished), maxa, autocvar_g_balance_armor_rot, autocvar_g_balance_armor_rotlinear, rot_mod * frametime * (time > this.pauserotarmor_finished), limita);
1662                 this.health = CalcRotRegen(this.health, regen_health_stable, regen_health, regen_health_linear, regen_mod * frametime * (time > this.pauseregen_finished), regen_health_rotstable, regen_health_rot, regen_health_rotlinear, rot_mod * frametime * (time > this.pauserothealth_finished), limith);
1663         }
1664
1665         // if player rotted to death...  die!
1666         // check this outside above checks, as player may still be able to rot to death
1667         if(this.health < 1)
1668         {
1669                 if(this.vehicle)
1670                         vehicles_exit(this.vehicle, VHEF_RELEASE);
1671                 if(this.event_damage)
1672                         this.event_damage(this, this, this, 1, DEATH_ROT.m_id, this.origin, '0 0 0');
1673         }
1674
1675         if (!(this.items & IT_UNLIMITED_WEAPON_AMMO))
1676         {
1677                 float minf, maxf, limitf;
1678
1679                 maxf = autocvar_g_balance_fuel_rotstable;
1680                 minf = autocvar_g_balance_fuel_regenstable;
1681                 limitf = GetResourceLimit(this, RESOURCE_FUEL);
1682
1683                 this.ammo_fuel = CalcRotRegen(this.ammo_fuel, minf, autocvar_g_balance_fuel_regen, autocvar_g_balance_fuel_regenlinear, frametime * (time > this.pauseregen_finished) * ((this.items & ITEM_JetpackRegen.m_itemid) != 0), maxf, autocvar_g_balance_fuel_rot, autocvar_g_balance_fuel_rotlinear, frametime * (time > this.pauserotfuel_finished), limitf);
1684         }
1685         // Ugly hack to make sure the health and armor don't go beyond hard limit.
1686         // TODO: Remove this hack when all code uses GivePlayerHealth and
1687         // GivePlayerArmor.
1688         if (this.health > RESOURCE_AMOUNT_HARD_LIMIT)
1689         {
1690                 this.health = RESOURCE_AMOUNT_HARD_LIMIT;
1691         }
1692         if (this.armorvalue > RESOURCE_AMOUNT_HARD_LIMIT)
1693         {
1694                 this.armorvalue = RESOURCE_AMOUNT_HARD_LIMIT;
1695         }
1696         // End hack.
1697 }
1698
1699 bool zoomstate_set;
1700 void SetZoomState(entity this, float newzoom)
1701 {
1702         if(newzoom != CS(this).zoomstate)
1703         {
1704                 CS(this).zoomstate = newzoom;
1705                 ClientData_Touch(this);
1706         }
1707         zoomstate_set = true;
1708 }
1709
1710 void GetPressedKeys(entity this)
1711 {
1712         MUTATOR_CALLHOOK(GetPressedKeys, this);
1713         int keys = STAT(PRESSED_KEYS, this);
1714         keys = BITSET(keys, KEY_FORWARD,        CS(this).movement.x > 0);
1715         keys = BITSET(keys, KEY_BACKWARD,       CS(this).movement.x < 0);
1716         keys = BITSET(keys, KEY_RIGHT,          CS(this).movement.y > 0);
1717         keys = BITSET(keys, KEY_LEFT,           CS(this).movement.y < 0);
1718
1719         keys = BITSET(keys, KEY_JUMP,           PHYS_INPUT_BUTTON_JUMP(this));
1720         keys = BITSET(keys, KEY_CROUCH,         PHYS_INPUT_BUTTON_CROUCH(this));
1721         keys = BITSET(keys, KEY_ATCK,           PHYS_INPUT_BUTTON_ATCK(this));
1722         keys = BITSET(keys, KEY_ATCK2,          PHYS_INPUT_BUTTON_ATCK2(this));
1723         CS(this).pressedkeys = keys; // store for other users
1724
1725         STAT(PRESSED_KEYS, this) = keys;
1726 }
1727
1728 /*
1729 ======================
1730 spectate mode routines
1731 ======================
1732 */
1733
1734 void SpectateCopy(entity this, entity spectatee)
1735 {
1736     TC(Client, this); TC(Client, spectatee);
1737
1738         MUTATOR_CALLHOOK(SpectateCopy, spectatee, this);
1739         PS(this) = PS(spectatee);
1740         this.armortype = spectatee.armortype;
1741         this.armorvalue = spectatee.armorvalue;
1742         this.ammo_cells = spectatee.ammo_cells;
1743         this.ammo_plasma = spectatee.ammo_plasma;
1744         this.ammo_shells = spectatee.ammo_shells;
1745         this.ammo_nails = spectatee.ammo_nails;
1746         this.ammo_rockets = spectatee.ammo_rockets;
1747         this.ammo_fuel = spectatee.ammo_fuel;
1748         this.clip_load = spectatee.clip_load;
1749         this.clip_size = spectatee.clip_size;
1750         this.effects = spectatee.effects & EFMASK_CHEAP; // eat performance
1751         this.health = spectatee.health;
1752         CS(this).impulse = 0;
1753         this.items = spectatee.items;
1754         this.last_pickup = spectatee.last_pickup;
1755         this.hit_time = spectatee.hit_time;
1756         this.strength_finished = spectatee.strength_finished;
1757         this.invincible_finished = spectatee.invincible_finished;
1758         this.superweapons_finished = spectatee.superweapons_finished;
1759         STAT(PRESSED_KEYS, this) = STAT(PRESSED_KEYS, spectatee);
1760         this.weapons = spectatee.weapons;
1761         this.vortex_charge = spectatee.vortex_charge;
1762         this.vortex_chargepool_ammo = spectatee.vortex_chargepool_ammo;
1763         this.hagar_load = spectatee.hagar_load;
1764         this.arc_heat_percent = spectatee.arc_heat_percent;
1765         this.minelayer_mines = spectatee.minelayer_mines;
1766         this.punchangle = spectatee.punchangle;
1767         this.view_ofs = spectatee.view_ofs;
1768         this.velocity = spectatee.velocity;
1769         this.dmg_take = spectatee.dmg_take;
1770         this.dmg_save = spectatee.dmg_save;
1771         this.dmg_inflictor = spectatee.dmg_inflictor;
1772         this.v_angle = spectatee.v_angle;
1773         this.angles = spectatee.v_angle;
1774         STAT(FROZEN, this) = STAT(FROZEN, spectatee);
1775         this.revive_progress = spectatee.revive_progress;
1776         this.viewloc = spectatee.viewloc;
1777         if(!PHYS_INPUT_BUTTON_USE(this) && STAT(CAMERA_SPECTATOR, this) != 2)
1778                 this.fixangle = true;
1779         setorigin(this, spectatee.origin);
1780         setsize(this, spectatee.mins, spectatee.maxs);
1781         SetZoomState(this, CS(spectatee).zoomstate);
1782
1783         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1784         {
1785                 .entity weaponentity = weaponentities[slot];
1786                 this.(weaponentity) = spectatee.(weaponentity);
1787         }
1788
1789         for(int slot = 0; slot < MAX_AXH; ++slot)
1790         {
1791                 this.(AuxiliaryXhair[slot]) = spectatee.(AuxiliaryXhair[slot]);
1792         }
1793
1794     anticheat_spectatecopy(this, spectatee);
1795         this.hud = spectatee.hud;
1796         if(spectatee.vehicle)
1797     {
1798         this.angles = spectatee.v_angle;
1799
1800         //this.fixangle = false;
1801         //this.velocity = spectatee.vehicle.velocity;
1802         this.vehicle_health = spectatee.vehicle_health;
1803         this.vehicle_shield = spectatee.vehicle_shield;
1804         this.vehicle_energy = spectatee.vehicle_energy;
1805         this.vehicle_ammo1 = spectatee.vehicle_ammo1;
1806         this.vehicle_ammo2 = spectatee.vehicle_ammo2;
1807         this.vehicle_reload1 = spectatee.vehicle_reload1;
1808         this.vehicle_reload2 = spectatee.vehicle_reload2;
1809
1810         //msg_entity = this;
1811
1812        // WriteByte (MSG_ONE, SVC_SETVIEWANGLES);
1813             //WriteAngle(MSG_ONE,  spectatee.v_angle.x);
1814            // WriteAngle(MSG_ONE,  spectatee.v_angle.y);
1815            // WriteAngle(MSG_ONE,  spectatee.v_angle.z);
1816
1817         //WriteByte (MSG_ONE, SVC_SETVIEW);
1818         //    WriteEntity(MSG_ONE, this);
1819         //makevectors(spectatee.v_angle);
1820         //setorigin(this, spectatee.origin - v_forward * 400 + v_up * 300);*/
1821     }
1822 }
1823
1824 bool SpectateUpdate(entity this)
1825 {
1826         if(!this.enemy)
1827                 return false;
1828
1829         if(!IS_PLAYER(this.enemy) || this == this.enemy)
1830         {
1831                 SetSpectatee(this, NULL);
1832                 return false;
1833         }
1834
1835         SpectateCopy(this, this.enemy);
1836
1837         return true;
1838 }
1839
1840 bool SpectateSet(entity this)
1841 {
1842         if(!IS_PLAYER(this.enemy))
1843                 return false;
1844
1845         ClientData_Touch(this.enemy);
1846
1847         msg_entity = this;
1848         WriteByte(MSG_ONE, SVC_SETVIEW);
1849         WriteEntity(MSG_ONE, this.enemy);
1850         set_movetype(this, MOVETYPE_NONE);
1851         accuracy_resend(this);
1852
1853         if(!SpectateUpdate(this))
1854                 PutObserverInServer(this);
1855
1856         return true;
1857 }
1858
1859 void SetSpectatee_status(entity this, int spectatee_num)
1860 {
1861         int oldspectatee_status = CS(this).spectatee_status;
1862         CS(this).spectatee_status = spectatee_num;
1863
1864         if (CS(this).spectatee_status != oldspectatee_status)
1865         {
1866                 ClientData_Touch(this);
1867                 if (g_race || g_cts) race_InitSpectator();
1868         }
1869 }
1870
1871 void SetSpectatee(entity this, entity spectatee)
1872 {
1873         if(IS_BOT_CLIENT(this))
1874                 return; // bots abuse .enemy, this code is useless to them
1875
1876         entity old_spectatee = this.enemy;
1877
1878         this.enemy = spectatee;
1879
1880         // WEAPONTODO
1881         // these are required to fix the spectator bug with arc
1882         if(old_spectatee)
1883         {
1884                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1885                 {
1886                         .entity weaponentity = weaponentities[slot];
1887                         if(old_spectatee.(weaponentity).arc_beam)
1888                                 old_spectatee.(weaponentity).arc_beam.SendFlags |= ARC_SF_SETTINGS;
1889                 }
1890         }
1891         if(this.enemy)
1892         {
1893                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1894                 {
1895                         .entity weaponentity = weaponentities[slot];
1896                         if(this.enemy.(weaponentity).arc_beam)
1897                                 this.enemy.(weaponentity).arc_beam.SendFlags |= ARC_SF_SETTINGS;
1898                 }
1899         }
1900
1901         if (this.enemy)
1902                 SetSpectatee_status(this, etof(this.enemy));
1903
1904         // needed to update spectator list
1905         if(old_spectatee) { ClientData_Touch(old_spectatee); }
1906 }
1907
1908 bool Spectate(entity this, entity pl)
1909 {
1910         if(MUTATOR_CALLHOOK(SpectateSet, this, pl))
1911                 return false;
1912         pl = M_ARGV(1, entity);
1913
1914         SetSpectatee(this, pl);
1915         return SpectateSet(this);
1916 }
1917
1918 bool SpectateNext(entity this)
1919 {
1920         entity ent = find(this.enemy, classname, STR_PLAYER);
1921
1922         if (MUTATOR_CALLHOOK(SpectateNext, this, ent))
1923                 ent = M_ARGV(1, entity);
1924         else if (!ent)
1925                 ent = find(ent, classname, STR_PLAYER);
1926
1927         if(ent) { SetSpectatee(this, ent); }
1928
1929         return SpectateSet(this);
1930 }
1931
1932 bool SpectatePrev(entity this)
1933 {
1934         // NOTE: chain order is from the highest to the lower entnum (unlike find)
1935         entity ent = findchain(classname, STR_PLAYER);
1936         if (!ent) // no player
1937                 return false;
1938
1939         entity first = ent;
1940         // skip players until current spectated player
1941         if(this.enemy)
1942         while(ent && ent != this.enemy)
1943                 ent = ent.chain;
1944
1945         switch (MUTATOR_CALLHOOK(SpectatePrev, this, ent, first))
1946         {
1947                 case MUT_SPECPREV_FOUND:
1948                     ent = M_ARGV(1, entity);
1949                     break;
1950                 case MUT_SPECPREV_RETURN:
1951                     return true;
1952                 case MUT_SPECPREV_CONTINUE:
1953                 default:
1954                 {
1955                         if(ent.chain)
1956                                 ent = ent.chain;
1957                         else
1958                                 ent = first;
1959                         break;
1960                 }
1961         }
1962
1963         SetSpectatee(this, ent);
1964         return SpectateSet(this);
1965 }
1966
1967 /*
1968 =============
1969 ShowRespawnCountdown()
1970
1971 Update a respawn countdown display.
1972 =============
1973 */
1974 void ShowRespawnCountdown(entity this)
1975 {
1976         float number;
1977         if(!IS_DEAD(this)) // just respawned?
1978                 return;
1979         else
1980         {
1981                 number = ceil(this.respawn_time - time);
1982                 if(number <= 0)
1983                         return;
1984                 if(number <= this.respawn_countdown)
1985                 {
1986                         this.respawn_countdown = number - 1;
1987                         if(ceil(this.respawn_time - (time + 0.5)) == number) // only say it if it is the same number even in 0.5s; to prevent overlapping sounds
1988                                 { Send_Notification(NOTIF_ONE, this, MSG_ANNCE, Announcer_PickNumber(CNT_RESPAWN, number)); }
1989                 }
1990         }
1991 }
1992
1993 .bool team_selected;
1994 bool ShowTeamSelection(entity this)
1995 {
1996         if(!teamplay || autocvar_g_campaign || autocvar_g_balance_teams || this.team_selected || (CS(this).wasplayer && autocvar_g_changeteam_banned) || this.team_forced > 0)
1997                 return false;
1998         stuffcmd(this, "menu_showteamselect\n");
1999         return true;
2000 }
2001 void Join(entity this)
2002 {
2003         TRANSMUTE(Player, this);
2004
2005         if(!this.team_selected)
2006         if(autocvar_g_campaign || autocvar_g_balance_teams)
2007                 JoinBestTeam(this, true);
2008
2009         if(autocvar_g_campaign)
2010                 campaign_bots_may_start = true;
2011
2012         Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_PREVENT_JOIN);
2013
2014         PutClientInServer(this);
2015
2016         if(IS_PLAYER(this))
2017         if(teamplay && this.team != -1)
2018                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, APP_TEAM_NUM(this.team, INFO_JOIN_PLAY_TEAM), this.netname);
2019         else
2020                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_JOIN_PLAY, this.netname);
2021         this.team_selected = false;
2022 }
2023
2024 /**
2025  * Determines whether the player is allowed to join. This depends on cvar
2026  * g_maxplayers, if it isn't used this function always return true, otherwise
2027  * it checks whether the number of currently playing players exceeds g_maxplayers.
2028  * @return int number of free slots for players, 0 if none
2029  */
2030 int nJoinAllowed(entity this, entity ignore)
2031 {
2032         if(!ignore)
2033         // this is called that way when checking if anyone may be able to join (to build qcstatus)
2034         // so report 0 free slots if restricted
2035         {
2036                 if(autocvar_g_forced_team_otherwise == "spectate")
2037                         return 0;
2038                 if(autocvar_g_forced_team_otherwise == "spectator")
2039                         return 0;
2040         }
2041
2042         if(this && this.team_forced < 0)
2043                 return 0; // forced spectators can never join
2044
2045         // TODO simplify this
2046         int totalClients = 0;
2047         int currentlyPlaying = 0;
2048         FOREACH_CLIENT(true, {
2049                 if(it != ignore)
2050                         ++totalClients;
2051                 if(IS_REAL_CLIENT(it))
2052                 if(IS_PLAYER(it) || it.caplayer)
2053                         ++currentlyPlaying;
2054         });
2055
2056         float free_slots = 0;
2057         if (!autocvar_g_maxplayers)
2058                 free_slots = maxclients - totalClients;
2059         else if(currentlyPlaying < autocvar_g_maxplayers)
2060                 free_slots = min(maxclients - totalClients, autocvar_g_maxplayers - currentlyPlaying);
2061
2062         static float join_prevent_msg_time = 0;
2063         if(this && ignore && !free_slots && time > join_prevent_msg_time)
2064         {
2065                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_JOIN_PREVENT);
2066                 join_prevent_msg_time = time + 3;
2067         }
2068
2069         return free_slots;
2070 }
2071
2072 /**
2073  * Checks whether the client is an observer or spectator, if so, he will get kicked after
2074  * g_maxplayers_spectator_blocktime seconds
2075  */
2076 void checkSpectatorBlock(entity this)
2077 {
2078         if(IS_SPEC(this) || IS_OBSERVER(this))
2079         if(!this.caplayer)
2080         if(IS_REAL_CLIENT(this))
2081         {
2082                 if( time > (CS(this).spectatortime + autocvar_g_maxplayers_spectator_blocktime) ) {
2083                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_QUIT_KICK_SPECTATING);
2084                         dropclient(this);
2085                 }
2086         }
2087 }
2088
2089 void PrintWelcomeMessage(entity this)
2090 {
2091         if(CS(this).motd_actived_time == 0)
2092         {
2093                 if (autocvar_g_campaign) {
2094                         if ((IS_PLAYER(this) && PHYS_INPUT_BUTTON_INFO(this)) || (!IS_PLAYER(this))) {
2095                                 CS(this).motd_actived_time = time;
2096                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOTD, campaign_message);
2097                         }
2098                 } else {
2099                         if (PHYS_INPUT_BUTTON_INFO(this)) {
2100                                 CS(this).motd_actived_time = time;
2101                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOTD, getwelcomemessage(this));
2102                         }
2103                 }
2104         }
2105         else if(CS(this).motd_actived_time > 0) // showing MOTD or campaign message
2106         {
2107                 if (autocvar_g_campaign) {
2108                         if (PHYS_INPUT_BUTTON_INFO(this))
2109                                 CS(this).motd_actived_time = time;
2110                         else if ((time - CS(this).motd_actived_time > 2) && IS_PLAYER(this)) { // hide it some seconds after BUTTON_INFO has been released
2111                                 CS(this).motd_actived_time = 0;
2112                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_MOTD);
2113                         }
2114                 } else {
2115                         if (PHYS_INPUT_BUTTON_INFO(this))
2116                                 CS(this).motd_actived_time = time;
2117                         else if (time - CS(this).motd_actived_time > 2) { // hide it some seconds after BUTTON_INFO has been released
2118                                 CS(this).motd_actived_time = 0;
2119                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_MOTD);
2120                         }
2121                 }
2122         }
2123         else //if(CS(this).motd_actived_time < 0) // just connected, motd is active
2124         {
2125                 if(PHYS_INPUT_BUTTON_INFO(this)) // BUTTON_INFO hides initial MOTD
2126                         CS(this).motd_actived_time = -2; // wait until BUTTON_INFO gets released
2127                 else if(CS(this).motd_actived_time == -2 || IS_PLAYER(this) || IS_SPEC(this))
2128                 {
2129                         // instanctly hide MOTD
2130                         CS(this).motd_actived_time = 0;
2131                         Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_MOTD);
2132                 }
2133         }
2134 }
2135
2136 bool joinAllowed(entity this)
2137 {
2138         if (CS(this).version_mismatch) return false;
2139         if (!nJoinAllowed(this, this)) return false;
2140         if (teamplay && lockteams) return false;
2141         if (ShowTeamSelection(this)) return false;
2142         if (MUTATOR_CALLHOOK(ForbidSpawn, this)) return false;
2143         return true;
2144 }
2145
2146 .int items_added;
2147 bool PlayerThink(entity this)
2148 {
2149         if (game_stopped || intermission_running) {
2150                 this.modelflags &= ~MF_ROCKET;
2151                 if(intermission_running)
2152                         IntermissionThink(this);
2153                 return false;
2154         }
2155
2156         if (timeout_status == TIMEOUT_ACTIVE) {
2157         // don't allow the player to turn around while game is paused
2158                 // FIXME turn this into CSQC stuff
2159                 this.v_angle = this.lastV_angle;
2160                 this.angles = this.lastV_angle;
2161                 this.fixangle = true;
2162         }
2163
2164         if (frametime) player_powerups(this);
2165
2166         if (IS_DEAD(this)) {
2167                 if (this.personal && g_race_qualifying) {
2168                         if (time > this.respawn_time) {
2169                                 STAT(RESPAWN_TIME, this) = this.respawn_time = time + 1; // only retry once a second
2170                                 respawn(this);
2171                                 CS(this).impulse = CHIMPULSE_SPEEDRUN.impulse;
2172                         }
2173                 } else {
2174                         if (frametime) player_anim(this);
2175
2176                         if (this.respawn_flags & RESPAWN_DENY)
2177                         {
2178                                 STAT(RESPAWN_TIME, this) = 0;
2179                                 return false;
2180                         }
2181
2182                         bool button_pressed = (PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_JUMP(this) || PHYS_INPUT_BUTTON_ATCK2(this) || PHYS_INPUT_BUTTON_HOOK(this) || PHYS_INPUT_BUTTON_USE(this));
2183
2184                         switch(this.deadflag)
2185                         {
2186                                 case DEAD_DYING:
2187                                 {
2188                                         if ((this.respawn_flags & RESPAWN_FORCE) && !(this.respawn_time < this.respawn_time_max))
2189                                                 this.deadflag = DEAD_RESPAWNING;
2190                                         else if (!button_pressed || (time >= this.respawn_time_max && (this.respawn_flags & RESPAWN_FORCE)))
2191                                                 this.deadflag = DEAD_DEAD;
2192                                         break;
2193                                 }
2194                                 case DEAD_DEAD:
2195                                 {
2196                                         if (button_pressed)
2197                                                 this.deadflag = DEAD_RESPAWNABLE;
2198                                         else if (time >= this.respawn_time_max && (this.respawn_flags & RESPAWN_FORCE))
2199                                                 this.deadflag = DEAD_RESPAWNING;
2200                                         break;
2201                                 }
2202                                 case DEAD_RESPAWNABLE:
2203                                 {
2204                                         if (!button_pressed || (this.respawn_flags & RESPAWN_FORCE))
2205                                                 this.deadflag = DEAD_RESPAWNING;
2206                                         break;
2207                                 }
2208                                 case DEAD_RESPAWNING:
2209                                 {
2210                                         if (time > this.respawn_time)
2211                                         {
2212                                                 this.respawn_time = time + 1; // only retry once a second
2213                                                 this.respawn_time_max = this.respawn_time;
2214                                                 respawn(this);
2215                                         }
2216                                         break;
2217                                 }
2218                         }
2219
2220                         ShowRespawnCountdown(this);
2221
2222                         if (this.respawn_flags & RESPAWN_SILENT)
2223                                 STAT(RESPAWN_TIME, this) = 0;
2224                         else if ((this.respawn_flags & RESPAWN_FORCE) && this.respawn_time < this.respawn_time_max)
2225                         {
2226                                 if (time < this.respawn_time)
2227                                         STAT(RESPAWN_TIME, this) = this.respawn_time;
2228                                 else if (this.deadflag != DEAD_RESPAWNING)
2229                                         STAT(RESPAWN_TIME, this) = -this.respawn_time_max;
2230                         }
2231                         else
2232                                 STAT(RESPAWN_TIME, this) = this.respawn_time;
2233                 }
2234
2235                 // if respawning, invert stat_respawn_time to indicate this, the client translates it
2236                 if (this.deadflag == DEAD_RESPAWNING && STAT(RESPAWN_TIME, this) > 0)
2237                         STAT(RESPAWN_TIME, this) *= -1;
2238
2239                 return false;
2240         }
2241
2242         bool have_hook = false;
2243         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2244         {
2245                 .entity weaponentity = weaponentities[slot];
2246                 if(this.(weaponentity).hook.state)
2247                 {
2248                         have_hook = true;
2249                         break;
2250                 }
2251         }
2252         bool do_crouch = PHYS_INPUT_BUTTON_CROUCH(this);
2253         if (have_hook) {
2254                 do_crouch = false;
2255         } else if (this.waterlevel >= WATERLEVEL_SWIMMING) {
2256                 do_crouch = false;
2257         } else if (this.vehicle) {
2258                 do_crouch = false;
2259         } else if (STAT(FROZEN, this)) {
2260                 do_crouch = false;
2261     }
2262
2263         if (do_crouch) {
2264                 if (!this.crouch) {
2265                         this.crouch = true;
2266                         this.view_ofs = STAT(PL_CROUCH_VIEW_OFS, this);
2267                         setsize(this, STAT(PL_CROUCH_MIN, this), STAT(PL_CROUCH_MAX, this));
2268                         // setanim(this, this.anim_duck, false, true, true); // this anim is BROKEN anyway
2269                 }
2270         } else if (this.crouch) {
2271         tracebox(this.origin, STAT(PL_MIN, this), STAT(PL_MAX, this), this.origin, false, this);
2272         if (!trace_startsolid) {
2273             this.crouch = false;
2274             this.view_ofs = STAT(PL_VIEW_OFS, this);
2275             setsize(this, STAT(PL_MIN, this), STAT(PL_MAX, this));
2276         }
2277         }
2278
2279         FixPlayermodel(this);
2280
2281         // LordHavoc: allow firing on move frames (sub-ticrate), this gives better timing on slow servers
2282         //if(frametime)
2283         {
2284                 this.items &= ~this.items_added;
2285
2286                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2287                 {
2288                         .entity weaponentity = weaponentities[slot];
2289                         W_WeaponFrame(this, weaponentity);
2290
2291                         if(slot == 0)
2292                         {
2293                                 this.clip_load = this.(weaponentity).clip_load;
2294                                 this.clip_size = this.(weaponentity).clip_size;
2295                         }
2296                 }
2297
2298                 this.items_added = 0;
2299                 if ((this.items & ITEM_Jetpack.m_itemid) && ((this.items & ITEM_JetpackRegen.m_itemid) || this.ammo_fuel >= 0.01))
2300             this.items_added |= IT_FUEL;
2301
2302                 this.items |= this.items_added;
2303         }
2304
2305         player_regen(this);
2306
2307         // WEAPONTODO: Add a weapon request for this
2308         // rot vortex charge to the charge limit
2309         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2310         {
2311                 .entity weaponentity = weaponentities[slot];
2312                 if (WEP_CVAR(vortex, charge_rot_rate) && this.(weaponentity).vortex_charge > WEP_CVAR(vortex, charge_limit) && this.(weaponentity).vortex_charge_rottime < time)
2313                         this.(weaponentity).vortex_charge = bound(WEP_CVAR(vortex, charge_limit), this.(weaponentity).vortex_charge - WEP_CVAR(vortex, charge_rot_rate) * frametime / W_TICSPERFRAME, 1);
2314         }
2315
2316         if (frametime) player_anim(this);
2317
2318         // secret status
2319         secrets_setstatus(this);
2320
2321         // monsters status
2322         monsters_setstatus(this);
2323
2324         this.dmg_team = max(0, this.dmg_team - autocvar_g_teamdamage_resetspeed * frametime);
2325
2326         return true;
2327 }
2328
2329 void ObserverThink(entity this)
2330 {
2331         if ( CS(this).impulse )
2332         {
2333                 MinigameImpulse(this, CS(this).impulse);
2334                 CS(this).impulse = 0;
2335         }
2336
2337         if (this.flags & FL_JUMPRELEASED) {
2338                 if (PHYS_INPUT_BUTTON_JUMP(this) && joinAllowed(this)) {
2339                         this.flags &= ~FL_JUMPRELEASED;
2340                         this.flags |= FL_SPAWNING;
2341                 } else if(PHYS_INPUT_BUTTON_ATCK(this) && !CS(this).version_mismatch) {
2342                         this.flags &= ~FL_JUMPRELEASED;
2343                         if(SpectateNext(this)) {
2344                                 TRANSMUTE(Spectator, this);
2345                         }
2346                 } else {
2347                         int preferred_movetype = ((!PHYS_INPUT_BUTTON_USE(this) ? CS(this).cvar_cl_clippedspectating : !CS(this).cvar_cl_clippedspectating) ? MOVETYPE_FLY_WORLDONLY : MOVETYPE_NOCLIP);
2348                         set_movetype(this, preferred_movetype);
2349                 }
2350         } else {
2351                 if (!(PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_JUMP(this))) {
2352                         this.flags |= FL_JUMPRELEASED;
2353                         if(this.flags & FL_SPAWNING)
2354                         {
2355                                 this.flags &= ~FL_SPAWNING;
2356                                 Join(this);
2357                                 return;
2358                         }
2359                 }
2360         }
2361 }
2362
2363 void SpectatorThink(entity this)
2364 {
2365         if ( CS(this).impulse )
2366         {
2367                 if(MinigameImpulse(this, CS(this).impulse))
2368                         CS(this).impulse = 0;
2369
2370                 if (CS(this).impulse == IMP_weapon_drop.impulse)
2371                 {
2372                         STAT(CAMERA_SPECTATOR, this) = (STAT(CAMERA_SPECTATOR, this) + 1) % 3;
2373                         CS(this).impulse = 0;
2374                         return;
2375                 }
2376         }
2377
2378         if (this.flags & FL_JUMPRELEASED) {
2379                 if (PHYS_INPUT_BUTTON_JUMP(this) && joinAllowed(this)) {
2380                         this.flags &= ~FL_JUMPRELEASED;
2381                         this.flags |= FL_SPAWNING;
2382                 } else if(PHYS_INPUT_BUTTON_ATCK(this) || CS(this).impulse == 10 || CS(this).impulse == 15 || CS(this).impulse == 18 || (CS(this).impulse >= 200 && CS(this).impulse <= 209)) {
2383                         this.flags &= ~FL_JUMPRELEASED;
2384                         if(SpectateNext(this)) {
2385                                 TRANSMUTE(Spectator, this);
2386                         } else {
2387                                 TRANSMUTE(Observer, this);
2388                                 PutClientInServer(this);
2389                         }
2390                         CS(this).impulse = 0;
2391                 } else if(CS(this).impulse == 12 || CS(this).impulse == 16  || CS(this).impulse == 19 || (CS(this).impulse >= 220 && CS(this).impulse <= 229)) {
2392                         this.flags &= ~FL_JUMPRELEASED;
2393                         if(SpectatePrev(this)) {
2394                                 TRANSMUTE(Spectator, this);
2395                         } else {
2396                                 TRANSMUTE(Observer, this);
2397                                 PutClientInServer(this);
2398                         }
2399                         CS(this).impulse = 0;
2400                 } else if (PHYS_INPUT_BUTTON_ATCK2(this)) {
2401                         this.flags &= ~FL_JUMPRELEASED;
2402                         TRANSMUTE(Observer, this);
2403                         PutClientInServer(this);
2404                 } else {
2405                         if(!SpectateUpdate(this))
2406                                 PutObserverInServer(this);
2407                 }
2408         } else {
2409                 if (!(PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_ATCK2(this))) {
2410                         this.flags |= FL_JUMPRELEASED;
2411                         if(this.flags & FL_SPAWNING)
2412                         {
2413                                 this.flags &= ~FL_SPAWNING;
2414                                 Join(this);
2415                                 return;
2416                         }
2417                 }
2418                 if(!SpectateUpdate(this))
2419                         PutObserverInServer(this);
2420         }
2421
2422         this.flags |= FL_CLIENT | FL_NOTARGET;
2423 }
2424
2425 void vehicles_enter (entity pl, entity veh);
2426 void PlayerUseKey(entity this)
2427 {
2428         if (!IS_PLAYER(this))
2429                 return;
2430
2431         if(this.vehicle)
2432         {
2433                 if(!game_stopped)
2434                 {
2435                         vehicles_exit(this.vehicle, VHEF_NORMAL);
2436                         return;
2437                 }
2438         }
2439         else if(autocvar_g_vehicles_enter)
2440         {
2441                 if(!STAT(FROZEN, this))
2442                 if(!IS_DEAD(this))
2443                 if(!game_stopped)
2444                 {
2445                         entity head, closest_target = NULL;
2446                         head = WarpZone_FindRadius(this.origin, autocvar_g_vehicles_enter_radius, true);
2447
2448                         while(head) // find the closest acceptable target to enter
2449                         {
2450                                 if(IS_VEHICLE(head))
2451                                 if(!IS_DEAD(head))
2452                                 if(!head.owner || ((head.vehicle_flags & VHF_MULTISLOT) && SAME_TEAM(head.owner, this)))
2453                                 if(head.takedamage != DAMAGE_NO)
2454                                 {
2455                                         if(closest_target)
2456                                         {
2457                                                 if(vlen2(this.origin - head.origin) < vlen2(this.origin - closest_target.origin))
2458                                                 { closest_target = head; }
2459                                         }
2460                                         else { closest_target = head; }
2461                                 }
2462
2463                                 head = head.chain;
2464                         }
2465
2466                         if(closest_target) { vehicles_enter(this, closest_target); return; }
2467                 }
2468         }
2469
2470         // a use key was pressed; call handlers
2471         MUTATOR_CALLHOOK(PlayerUseKey, this);
2472 }
2473
2474
2475 /*
2476 =============
2477 PlayerPreThink
2478
2479 Called every frame for each client before the physics are run
2480 =============
2481 */
2482 .float last_vehiclecheck;
2483 void PlayerPreThink (entity this)
2484 {
2485         STAT(GUNALIGN, this) = CS(this).cvar_cl_gunalign; // TODO
2486         STAT(MOVEVARS_CL_TRACK_CANJUMP, this) = CS(this).cvar_cl_movement_track_canjump;
2487
2488         WarpZone_PlayerPhysics_FixVAngle(this);
2489
2490         if (frametime) {
2491                 // physics frames: update anticheat stuff
2492                 anticheat_prethink(this);
2493         }
2494
2495         if (blockSpectators && frametime) {
2496                 // WORKAROUND: only use dropclient in server frames (frametime set).
2497                 // Never use it in cl_movement frames (frametime zero).
2498                 checkSpectatorBlock(this);
2499         }
2500
2501         zoomstate_set = false;
2502
2503         // Check for nameless players
2504         if (this.netname == "" || this.netname != CS(this).netname_previous)
2505         {
2506                 bool assume_unchanged = (CS(this).netname_previous == "");
2507                 if (isInvisibleString(this.netname))
2508                 {
2509                         this.netname = strzone(sprintf("Player#%d", this.playerid));
2510                         assume_unchanged = false;
2511                         // stuffcmd(this, strcat("name ", this.netname, "\n")); // maybe?
2512                 }
2513                 if (!assume_unchanged && autocvar_sv_eventlog)
2514                         GameLogEcho(strcat(":name:", ftos(this.playerid), ":", playername(this, false)));
2515                 if (CS(this).netname_previous) strunzone(CS(this).netname_previous);
2516                 CS(this).netname_previous = strzone(this.netname);
2517         }
2518
2519         // version nagging
2520         if (CS(this).version_nagtime && CS(this).cvar_g_xonoticversion && time > CS(this).version_nagtime) {
2521         CS(this).version_nagtime = 0;
2522         if (strstrofs(CS(this).cvar_g_xonoticversion, "git", 0) >= 0 || strstrofs(CS(this).cvar_g_xonoticversion, "autobuild", 0) >= 0) {
2523             // git client
2524         } else if (strstrofs(autocvar_g_xonoticversion, "git", 0) >= 0 || strstrofs(autocvar_g_xonoticversion, "autobuild", 0) >= 0) {
2525             // git server
2526             Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_BETA, autocvar_g_xonoticversion, CS(this).cvar_g_xonoticversion);
2527         } else {
2528             int r = vercmp(CS(this).cvar_g_xonoticversion, autocvar_g_xonoticversion);
2529             if (r < 0) { // old client
2530                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_OUTDATED, autocvar_g_xonoticversion, CS(this).cvar_g_xonoticversion);
2531             } else if (r > 0) { // old server
2532                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_OLD, autocvar_g_xonoticversion, CS(this).cvar_g_xonoticversion);
2533             }
2534         }
2535     }
2536
2537         // GOD MODE info
2538         if (!(this.flags & FL_GODMODE) && this.max_armorvalue)
2539         {
2540                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_GODMODE_OFF, this.max_armorvalue);
2541                 this.max_armorvalue = 0;
2542         }
2543
2544         if(IS_PLAYER(this))
2545         {
2546                 if (STAT(FROZEN, this) == 2)
2547                 {
2548                         this.revive_progress = bound(0, this.revive_progress + frametime * this.revive_speed, 1);
2549                         this.health = max(1, this.revive_progress * start_health);
2550                         this.iceblock.alpha = bound(0.2, 1 - this.revive_progress, 1);
2551
2552                         if (this.revive_progress >= 1)
2553                                 Unfreeze(this);
2554                 }
2555                 else if (STAT(FROZEN, this) == 3)
2556                 {
2557                         this.revive_progress = bound(0, this.revive_progress - frametime * this.revive_speed, 1);
2558                         this.health = max(0, autocvar_g_nades_ice_health + (start_health-autocvar_g_nades_ice_health) * this.revive_progress );
2559
2560                         if (this.health < 1)
2561                         {
2562                                 if (this.vehicle)
2563                                         vehicles_exit(this.vehicle, VHEF_RELEASE);
2564                                 if(this.event_damage)
2565                                         this.event_damage(this, this, this.frozen_by, 1, DEATH_NADE_ICE_FREEZE.m_id, this.origin, '0 0 0');
2566                         }
2567                         else if (this.revive_progress <= 0)
2568                                 Unfreeze(this);
2569                 }
2570         }
2571
2572         MUTATOR_CALLHOOK(PlayerPreThink, this);
2573
2574         if(autocvar_g_vehicles_enter && (time > this.last_vehiclecheck) && !game_stopped && !this.vehicle)
2575         if(IS_PLAYER(this) && !STAT(FROZEN, this) && !IS_DEAD(this))
2576         {
2577                 FOREACH_ENTITY_RADIUS(this.origin, autocvar_g_vehicles_enter_radius, IS_VEHICLE(it),
2578                 {
2579                         if(!IS_DEAD(it) && it.takedamage != DAMAGE_NO)
2580                         if((it.vehicle_flags & VHF_MULTISLOT) && SAME_TEAM(it.owner, this))
2581                         {
2582                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER_GUNNER);
2583                         }
2584                         else if(!it.owner)
2585                         {
2586                                 if(!it.team || SAME_TEAM(this, it))
2587                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER);
2588                                 else if(autocvar_g_vehicles_steal)
2589                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER_STEAL);
2590                         }
2591                 });
2592
2593                 this.last_vehiclecheck = time + 1;
2594         }
2595
2596         if(!CS(this).cvar_cl_newusekeysupported) // FIXME remove this - it was a stupid idea to begin with, we can JUST use the button
2597         {
2598                 if(PHYS_INPUT_BUTTON_USE(this) && !CS(this).usekeypressed)
2599                         PlayerUseKey(this);
2600                 CS(this).usekeypressed = PHYS_INPUT_BUTTON_USE(this);
2601         }
2602
2603         if (IS_REAL_CLIENT(this))
2604                 PrintWelcomeMessage(this);
2605
2606         if (IS_PLAYER(this)) {
2607                 if(!PlayerThink(this))
2608                         return;
2609         }
2610         else if (game_stopped || intermission_running) {
2611                 if(intermission_running)
2612                         IntermissionThink(this);
2613                 return;
2614         }
2615         else if (IS_OBSERVER(this)) {
2616                 ObserverThink(this);
2617         }
2618         else if (IS_SPEC(this)) {
2619                 SpectatorThink(this);
2620         }
2621
2622         // WEAPONTODO: Add weapon request for this
2623         if (!zoomstate_set) {
2624                 bool wep_zoomed = false;
2625                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2626                 {
2627                         .entity weaponentity = weaponentities[slot];
2628                         Weapon thiswep = this.(weaponentity).m_weapon;
2629                         if(thiswep != WEP_Null && thiswep.wr_zoom)
2630                                 wep_zoomed += thiswep.wr_zoom(thiswep, this);
2631                 }
2632                 SetZoomState(this, PHYS_INPUT_BUTTON_ZOOM(this) || PHYS_INPUT_BUTTON_ZOOMSCRIPT(this) || wep_zoomed);
2633     }
2634
2635         if (CS(this).teamkill_soundtime && time > CS(this).teamkill_soundtime)
2636         {
2637                 CS(this).teamkill_soundtime = 0;
2638
2639                 entity e = CS(this).teamkill_soundsource;
2640                 entity oldpusher = e.pusher;
2641                 e.pusher = this;
2642                 PlayerSound(e, playersound_teamshoot, CH_VOICE, VOL_BASEVOICE, VOICETYPE_LASTATTACKER_ONLY);
2643                 e.pusher = oldpusher;
2644         }
2645
2646         if (CS(this).taunt_soundtime && time > CS(this).taunt_soundtime) {
2647                 CS(this).taunt_soundtime = 0;
2648                 PlayerSound(this, playersound_taunt, CH_VOICE, VOL_BASEVOICE, VOICETYPE_AUTOTAUNT);
2649         }
2650
2651         target_voicescript_next(this);
2652
2653         // WEAPONTODO: Move into weaponsystem somehow
2654         // if a player goes unarmed after holding a loaded weapon, empty his clip size and remove the crosshair ammo ring
2655         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2656         {
2657                 .entity weaponentity = weaponentities[slot];
2658                 if(this.(weaponentity).m_weapon == WEP_Null)
2659                         this.(weaponentity).clip_load = this.(weaponentity).clip_size = 0;
2660         }
2661 }
2662
2663 void DrownPlayer(entity this)
2664 {
2665         if(IS_DEAD(this))
2666                 return;
2667
2668         if (this.waterlevel != WATERLEVEL_SUBMERGED || this.vehicle)
2669         {
2670                 if(this.air_finished < time)
2671                         PlayerSound(this, playersound_gasp, CH_PLAYER, VOL_BASE, VOICETYPE_PLAYERSOUND);
2672                 this.air_finished = time + autocvar_g_balance_contents_drowndelay;
2673         }
2674         else if (this.air_finished < time)
2675         {       // drown!
2676                 if (this.pain_finished < time)
2677                 {
2678                         Damage (this, NULL, NULL, autocvar_g_balance_contents_playerdamage_drowning * autocvar_g_balance_contents_damagerate, DEATH_DROWN.m_id, this.origin, '0 0 0');
2679                         this.pain_finished = time + 0.5;
2680                 }
2681         }
2682 }
2683
2684 .bool move_qcphysics;
2685
2686 void Player_Physics(entity this)
2687 {
2688         set_movetype(this, this.move_movetype);
2689
2690         if(!this.move_qcphysics)
2691                 return;
2692
2693         if(!frametime && !CS(this).pm_frametime)
2694                 return;
2695
2696         Movetype_Physics_NoMatchTicrate(this, CS(this).pm_frametime, true);
2697
2698         CS(this).pm_frametime = 0;
2699 }
2700
2701 /*
2702 =============
2703 PlayerPostThink
2704
2705 Called every frame for each client after the physics are run
2706 =============
2707 */
2708 void PlayerPostThink (entity this)
2709 {
2710         Player_Physics(this);
2711
2712         if (sv_maxidle > 0)
2713         if (frametime) // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2714         if (IS_REAL_CLIENT(this))
2715         if (IS_PLAYER(this) || sv_maxidle_spectatorsareidle)
2716         {
2717                 int totalClients = 0;
2718                 if(sv_maxidle_slots > 0)
2719                 {
2720                         FOREACH_CLIENT(IS_REAL_CLIENT(it) || sv_maxidle_slots_countbots,
2721                         {
2722                                 ++totalClients;
2723                         });
2724                 }
2725
2726                 if (sv_maxidle_slots > 0 && (maxclients - totalClients) > sv_maxidle_slots)
2727                 { /* do nothing */ }
2728                 else if (time - CS(this).parm_idlesince < 1) // instead of (time == this.parm_idlesince) to support sv_maxidle <= 10
2729                 {
2730                         if (CS(this).idlekick_lasttimeleft)
2731                         {
2732                                 CS(this).idlekick_lasttimeleft = 0;
2733                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_IDLING);
2734                         }
2735                 }
2736                 else
2737                 {
2738                         float timeleft = ceil(sv_maxidle - (time - CS(this).parm_idlesince));
2739                         if (timeleft == min(10, sv_maxidle - 1)) { // - 1 to support sv_maxidle <= 10
2740                                 if (!CS(this).idlekick_lasttimeleft)
2741                                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_DISCONNECT_IDLING, timeleft);
2742                         }
2743                         if (timeleft <= 0) {
2744                                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_QUIT_KICK_IDLING, this.netname);
2745                                 dropclient(this);
2746                                 return;
2747                         }
2748                         else if (timeleft <= 10) {
2749                                 if (timeleft != CS(this).idlekick_lasttimeleft) {
2750                                     Send_Notification(NOTIF_ONE, this, MSG_ANNCE, Announcer_PickNumber(CNT_IDLE, timeleft));
2751                 }
2752                                 CS(this).idlekick_lasttimeleft = timeleft;
2753                         }
2754                 }
2755         }
2756
2757         CheatFrame(this);
2758
2759         if (game_stopped)
2760         {
2761                 this.solid = SOLID_NOT;
2762                 this.takedamage = DAMAGE_NO;
2763                 set_movetype(this, MOVETYPE_NONE);
2764         }
2765
2766         if (IS_PLAYER(this)) {
2767                 DrownPlayer(this);
2768                 UpdateChatBubble(this);
2769                 if (CS(this).impulse) ImpulseCommands(this);
2770                 if (game_stopped)
2771                 {
2772                         CSQCMODEL_AUTOUPDATE(this);
2773                         return;
2774                 }
2775                 GetPressedKeys(this);
2776         }
2777
2778         if (this.waypointsprite_attachedforcarrier) {
2779             vector v = healtharmor_maxdamage(this.health, this.armorvalue, autocvar_g_balance_armor_blockpercent, DEATH_WEAPON.m_id);
2780                 WaypointSprite_UpdateHealth(this.waypointsprite_attachedforcarrier, '1 0 0' * v);
2781     }
2782
2783         playerdemo_write(this);
2784
2785         CSQCMODEL_AUTOUPDATE(this);
2786 }
2787
2788 // hack to copy the button fields from the client entity to the Client State
2789 void PM_UpdateButtons(entity this, entity store)
2790 {
2791         if(this.impulse)
2792                 store.impulse = this.impulse;
2793         this.impulse = 0;
2794
2795         store.button0 = this.button0;
2796         store.button2 = this.button2;
2797         store.button3 = this.button3;
2798         store.button4 = this.button4;
2799         store.button5 = this.button5;
2800         store.button6 = this.button6;
2801         store.button7 = this.button7;
2802         store.button8 = this.button8;
2803         store.button9 = this.button9;
2804         store.button10 = this.button10;
2805         store.button11 = this.button11;
2806         store.button12 = this.button12;
2807         store.button13 = this.button13;
2808         store.button14 = this.button14;
2809         store.button15 = this.button15;
2810         store.button16 = this.button16;
2811         store.buttonuse = this.buttonuse;
2812         store.buttonchat = this.buttonchat;
2813
2814         store.cursor_active = this.cursor_active;
2815         store.cursor_screen = this.cursor_screen;
2816         store.cursor_trace_start = this.cursor_trace_start;
2817         store.cursor_trace_endpos = this.cursor_trace_endpos;
2818         store.cursor_trace_ent = this.cursor_trace_ent;
2819
2820         store.ping = this.ping;
2821         store.ping_packetloss = this.ping_packetloss;
2822         store.ping_movementloss = this.ping_movementloss;
2823
2824         store.v_angle = this.v_angle;
2825         store.movement = this.movement;
2826 }