qcsrc/server/client.qc

   1 #include "client.qh"
   2
   3 #include <common/csqcmodel_settings.qh>
   4 #include <common/deathtypes/all.qh>
   5 #include <common/effects/all.qh>
   6 #include <common/effects/qc/globalsound.qh>
   7 #include <common/ent_cs.qh>
   8 #include <common/gamemodes/_mod.qh>
   9 #include <common/gamemodes/gamemode/nexball/sv_nexball.qh>
  10 #include <common/items/_mod.qh>
  11 #include <common/items/inventory.qh>
  12 #include <common/mapobjects/func/conveyor.qh>
  13 #include <common/mapobjects/func/ladder.qh>
  14 #include <common/mapobjects/subs.qh>
  15 #include <common/mapobjects/target/spawnpoint.qh>
  16 #include <common/mapobjects/teleporters.qh>
  17 #include <common/mapobjects/trigger/counter.qh>
  18 #include <common/mapobjects/trigger/secret.qh>
  19 #include <common/mapobjects/trigger/swamp.qh>
  20 #include <common/mapobjects/triggers.qh>
  21 #include <common/minigames/sv_minigames.qh>
  22 #include <common/monsters/sv_monsters.qh>
  23 #include <common/mutators/mutator/instagib/sv_instagib.qh>
  24 #include <common/mutators/mutator/nades/nades.qh>
  25 #include <common/mutators/mutator/overkill/oknex.qh>
  26 #include <common/mutators/mutator/waypoints/all.qh>
  27 #include <common/net_linked.qh>
  28 #include <common/net_notice.qh>
  29 #include <common/notifications/all.qh>
  30 #include <common/physics/player.qh>
  31 #include <common/playerstats.qh>
  32 #include <common/state.qh>
  33 #include <common/stats.qh>
  34 #include <common/vehicles/all.qh>
  35 #include <common/vehicles/sv_vehicles.qh>
  36 #include <common/viewloc.qh>
  37 #include <common/weapons/_all.qh>
  38 #include <common/weapons/weapon/vortex.qh>
  39 #include <common/wepent.qh>
  40 #include <lib/csqcmodel/sv_model.qh>
  41 #include <lib/warpzone/common.qh>
  42 #include <lib/warpzone/server.qh>
  43 #include <server/anticheat.qh>
  44 #include <server/antilag.qh>
  45 #include <server/bot/api.qh>
  46 #include <server/bot/default/cvars.qh>
  47 #include <server/campaign.qh>
  48 #include <server/chat.qh>
  49 #include <server/cheats.qh>
  50 #include <server/clientkill.qh>
  51 #include <server/command/common.qh>
  52 #include <server/command/common.qh>
  53 #include <server/command/vote.qh>
  54 #include <server/compat/quake3.qh>
  55 #include <server/damage.qh>
  56 #include <server/gamelog.qh>
  57 #include <server/handicap.qh>
  58 #include <server/hook.qh>
  59 #include <server/impulse.qh>
  60 #include <server/intermission.qh>
  61 #include <server/ipban.qh>
  62 #include <server/main.qh>
  63 #include <server/mutators/_mod.qh>
  64 #include <server/player.qh>
  65 #include <server/portals.qh>
  66 #include <server/race.qh>
  67 #include <server/resources.qh>
  68 #include <server/scores.qh>
  69 #include <server/scores_rules.qh>
  70 #include <server/spawnpoints.qh>
  71 #include <server/teamplay.qh>
  72 #include <server/weapons/accuracy.qh>
  73 #include <server/weapons/common.qh>
  74 #include <server/weapons/hitplot.qh>
  75 #include <server/weapons/selection.qh>
  76 #include <server/weapons/tracing.qh>
  77 #include <server/weapons/weaponsystem.qh>
  78 #include <server/world.qh>
  79
  80 STATIC_METHOD(Client, Add, void(Client this, int _team))
  81 {
  82     ClientConnect(this);
  83     TRANSMUTE(Player, this);
  84     this.frame = 12; // 7
  85     this.team = _team;
  86     PutClientInServer(this);
  87 }
  88
  89 STATIC_METHOD(Client, Remove, void(Client this))
  90 {
  91     TRANSMUTE(Observer, this);
  92     PutClientInServer(this);
  93     ClientDisconnect(this);
  94 }
  95
  96 void send_CSQC_teamnagger() {
  97         WriteHeader(MSG_BROADCAST, TE_CSQC_TEAMNAGGER);
  98 }
  99
 100 int CountSpectators(entity player, entity to)
 101 {
 102         if(!player) { return 0; } // not sure how, but best to be safe
 103
 104         int spec_count = 0;
 105
 106         FOREACH_CLIENT(IS_REAL_CLIENT(it) && IS_SPEC(it) && it != to && it.enemy == player,
 107         {
 108                 spec_count++;
 109         });
 110
 111         return spec_count;
 112 }
 113
 114 void WriteSpectators(entity player, entity to)
 115 {
 116         if(!player) { return; } // not sure how, but best to be safe
 117
 118         int spec_count = 0;
 119         FOREACH_CLIENT(IS_REAL_CLIENT(it) && IS_SPEC(it) && it != to && it.enemy == player,
 120         {
 121                 if(spec_count >= MAX_SPECTATORS)
 122                         break;
 123                 WriteByte(MSG_ENTITY, num_for_edict(it));
 124                 ++spec_count;
 125         });
 126 }
 127
 128 bool ClientData_Send(entity this, entity to, int sf)
 129 {
 130         assert(to == this.owner, return false);
 131
 132         entity e = to;
 133         if (IS_SPEC(e)) e = e.enemy;
 134
 135         sf = 0;
 136         if (CS(e).race_completed)       sf |= BIT(0); // forced scoreboard
 137         if (CS(to).spectatee_status)    sf |= BIT(1); // spectator ent number follows
 138         if (CS(e).zoomstate)            sf |= BIT(2); // zoomed
 139         if (autocvar_sv_showspectators) sf |= BIT(4); // show spectators
 140
 141         WriteHeader(MSG_ENTITY, ENT_CLIENT_CLIENTDATA);
 142         WriteByte(MSG_ENTITY, sf);
 143
 144         if (sf & BIT(1))
 145                 WriteByte(MSG_ENTITY, CS(to).spectatee_status);
 146
 147         if(sf & BIT(4))
 148         {
 149                 float specs = CountSpectators(e, to);
 150                 WriteByte(MSG_ENTITY, specs);
 151                 WriteSpectators(e, to);
 152         }
 153
 154         return true;
 155 }
 156
 157 void ClientData_Attach(entity this)
 158 {
 159         Net_LinkEntity(CS(this).clientdata = new_pure(clientdata), false, 0, ClientData_Send);
 160         CS(this).clientdata.drawonlytoclient = this;
 161         CS(this).clientdata.owner = this;
 162 }
 163
 164 void ClientData_Detach(entity this)
 165 {
 166         delete(CS(this).clientdata);
 167         CS(this).clientdata = NULL;
 168 }
 169
 170 void ClientData_Touch(entity e)
 171 {
 172         entity cd = CS(e).clientdata;
 173         if (cd) { cd.SendFlags = 1; }
 174
 175         // make it spectatable
 176         FOREACH_CLIENT(IS_REAL_CLIENT(it) && it != e && IS_SPEC(it) && it.enemy == e,
 177         {
 178                 entity cd = CS(it).clientdata;
 179                 if (cd) { cd.SendFlags = 1; }
 180         });
 181 }
 182
 183
 184 /*
 185 =============
 186 CheckPlayerModel
 187
 188 Checks if the argument string can be a valid playermodel.
 189 Returns a valid one in doubt.
 190 =============
 191 */
 192 string FallbackPlayerModel;
 193 string CheckPlayerModel(string plyermodel) {
 194         if(FallbackPlayerModel != cvar_defstring("_cl_playermodel"))
 195         {
 196                 // note: we cannot summon Don Strunzone here, some player may
 197                 // still have the model string set. In case anyone manages how
 198                 // to change a cvar default, we'll have a small leak here.
 199                 FallbackPlayerModel = strzone(cvar_defstring("_cl_playermodel"));
 200         }
 201         // only in right path
 202         if(substring(plyermodel, 0, 14) != "models/player/")
 203                 return FallbackPlayerModel;
 204         // only good file extensions
 205         if(substring(plyermodel, -4, 4) != ".iqm"
 206                 && substring(plyermodel, -4, 4) != ".zym"
 207                 && substring(plyermodel, -4, 4) != ".dpm"
 208                 && substring(plyermodel, -4, 4) != ".md3"
 209                 && substring(plyermodel, -4, 4) != ".psk")
 210         {
 211                 return FallbackPlayerModel;
 212         }
 213         // forbid the LOD models
 214         if(substring(plyermodel, -9, 5) == "_lod1" || substring(plyermodel, -9, 5) == "_lod2")
 215                 return FallbackPlayerModel;
 216         if(plyermodel != strtolower(plyermodel))
 217                 return FallbackPlayerModel;
 218         // also, restrict to server models
 219         if(autocvar_sv_servermodelsonly)
 220         {
 221                 if(!fexists(plyermodel))
 222                         return FallbackPlayerModel;
 223         }
 224         return plyermodel;
 225 }
 226
 227 void setplayermodel(entity e, string modelname)
 228 {
 229         precache_model(modelname);
 230         _setmodel(e, modelname);
 231         player_setupanimsformodel(e);
 232         if(!autocvar_g_debug_globalsounds)
 233                 UpdatePlayerSounds(e);
 234 }
 235
 236 /** putting a client as observer in the server */
 237 void PutObserverInServer(entity this)
 238 {
 239         bool mutator_returnvalue = MUTATOR_CALLHOOK(MakePlayerObserver, this);
 240         PlayerState_detach(this);
 241
 242         if (IS_PLAYER(this))
 243         {
 244                 if(GetResource(this, RES_HEALTH) >= 1)
 245                 {
 246                         // despawn effect
 247                         Send_Effect(EFFECT_SPAWN_NEUTRAL, this.origin, '0 0 0', 1);
 248                 }
 249
 250                 // was a player, recount votes and ready status
 251                 if(IS_REAL_CLIENT(this))
 252                 {
 253                         if (vote_called) { VoteCount(false); }
 254                         ReadyCount();
 255                 }
 256                 entcs_update_players(this);
 257         }
 258
 259         entity spot = SelectSpawnPoint(this, true);
 260         if (!spot) LOG_FATAL("No spawnpoints for observers?!?");
 261         this.angles = vec2(spot.angles);
 262         this.fixangle = true;
 263         // offset it so that the spectator spawns higher off the ground, looks better this way
 264         setorigin(this, spot.origin + STAT(PL_VIEW_OFS, this));
 265         if (IS_REAL_CLIENT(this))
 266         {
 267                 msg_entity = this;
 268                 WriteByte(MSG_ONE, SVC_SETVIEW);
 269                 WriteEntity(MSG_ONE, this);
 270         }
 271         // give the spectator some space between walls for MOVETYPE_FLY_WORLDONLY
 272         // so that your view doesn't go into the ceiling with MOVETYPE_FLY_WORLDONLY, previously "PL_VIEW_OFS"
 273         if(!autocvar_g_debug_globalsounds)
 274         {
 275                 // needed for player sounds
 276                 this.model = "";
 277                 FixPlayermodel(this);
 278         }
 279         setmodel(this, MDL_Null);
 280         setsize(this, STAT(PL_CROUCH_MIN, this), STAT(PL_CROUCH_MAX, this));
 281         this.view_ofs = '0 0 0';
 282
 283         RemoveGrapplingHooks(this);
 284         Portal_ClearAll(this);
 285         Unfreeze(this, false);
 286         SetSpectatee(this, NULL);
 287
 288         if (this.alivetime)
 289         {
 290                 if (!warmup_stage)
 291                         PlayerStats_GameReport_Event_Player(this, PLAYERSTATS_ALIVETIME, time - this.alivetime);
 292                 this.alivetime = 0;
 293         }
 294
 295         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
 296
 297         WaypointSprite_PlayerDead(this);
 298
 299         if (CS(this).killcount != FRAGS_SPECTATOR && !game_stopped && CHAT_NOSPECTATORS())
 300                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_CHAT_NOSPECTATORS);
 301
 302         accuracy_resend(this);
 303
 304         CS(this).spectatortime = time;
 305         if(this.bot_attack)
 306                 IL_REMOVE(g_bot_targets, this);
 307         this.bot_attack = false;
 308         if(this.monster_attack)
 309                 IL_REMOVE(g_monster_targets, this);
 310         this.monster_attack = false;
 311         STAT(HUD, this) = HUD_NORMAL;
 312         TRANSMUTE(Observer, this);
 313         this.iscreature = false;
 314         this.teleportable = TELEPORT_SIMPLE;
 315         if(this.damagedbycontents)
 316                 IL_REMOVE(g_damagedbycontents, this);
 317         this.damagedbycontents = false;
 318         SetResourceExplicit(this, RES_HEALTH, FRAGS_SPECTATOR);
 319         SetSpectatee_status(this, etof(this));
 320         this.takedamage = DAMAGE_NO;
 321         this.solid = SOLID_NOT;
 322         set_movetype(this, MOVETYPE_FLY_WORLDONLY); // user preference is controlled by playerprethink
 323         this.flags = FL_CLIENT | FL_NOTARGET;
 324         this.effects = 0;
 325         SetResourceExplicit(this, RES_ARMOR, autocvar_g_balance_armor_start); // was 666?!
 326         this.pauserotarmor_finished = 0;
 327         this.pauserothealth_finished = 0;
 328         this.pauseregen_finished = 0;
 329         this.damageforcescale = 0;
 330         this.death_time = 0;
 331         this.respawn_flags = 0;
 332         this.respawn_time = 0;
 333         STAT(RESPAWN_TIME, this) = 0;
 334         this.alpha = 0;
 335         this.scale = 0;
 336         this.fade_time = 0;
 337         this.pain_finished = 0;
 338         STAT(STRENGTH_FINISHED, this) = 0;
 339         STAT(INVINCIBLE_FINISHED, this) = 0;
 340         STAT(SUPERWEAPONS_FINISHED, this) = 0;
 341         STAT(AIR_FINISHED, this) = 0;
 342         //this.dphitcontentsmask = 0;
 343         this.dphitcontentsmask = DPCONTENTS_SOLID;
 344         if (autocvar_g_playerclip_collisions)
 345                 this.dphitcontentsmask |= DPCONTENTS_PLAYERCLIP;
 346         this.pushltime = 0;
 347         this.istypefrag = 0;
 348         setthink(this, func_null);
 349         this.nextthink = 0;
 350         this.deadflag = DEAD_NO;
 351         UNSET_DUCKED(this);
 352         STAT(REVIVE_PROGRESS, this) = 0;
 353         this.revival_time = 0;
 354         this.draggable = drag_undraggable;
 355
 356         this.items = 0;
 357         STAT(WEAPONS, this) = '0 0 0';
 358         this.drawonlytoclient = this;
 359
 360         this.viewloc = NULL;
 361
 362         //this.spawnpoint_targ = NULL; // keep it so they can return to where they were?
 363
 364         this.weaponmodel = "";
 365         for (int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 366         {
 367                 this.weaponentities[slot] = NULL;
 368         }
 369         this.exteriorweaponentity = NULL;
 370         CS(this).killcount = FRAGS_SPECTATOR;
 371         this.velocity = '0 0 0';
 372         this.avelocity = '0 0 0';
 373         this.punchangle = '0 0 0';
 374         this.punchvector = '0 0 0';
 375         this.oldvelocity = this.velocity;
 376         this.fire_endtime = -1;
 377         this.event_damage = func_null;
 378         this.event_heal = func_null;
 379
 380         for(int slot = 0; slot < MAX_AXH; ++slot)
 381         {
 382                 entity axh = this.(AuxiliaryXhair[slot]);
 383                 this.(AuxiliaryXhair[slot]) = NULL;
 384
 385                 if(axh.owner == this && axh != NULL && !wasfreed(axh))
 386                         delete(axh);
 387         }
 388
 389         if (mutator_returnvalue)
 390         {
 391                 // mutator prevents resetting teams+score
 392         }
 393         else
 394         {
 395                 SetPlayerTeam(this, -1, TEAM_CHANGE_SPECTATOR);
 396                 this.frags = FRAGS_SPECTATOR;
 397         }
 398
 399         bot_relinkplayerlist();
 400
 401         if (CS(this).just_joined)
 402                 CS(this).just_joined = false;
 403 }
 404
 405 int player_getspecies(entity this)
 406 {
 407         get_model_parameters(this.model, this.skin);
 408         int s = get_model_parameters_species;
 409         get_model_parameters(string_null, 0);
 410         if (s < 0) return SPECIES_HUMAN;
 411         return s;
 412 }
 413
 414 .float model_randomizer;
 415 void FixPlayermodel(entity player)
 416 {
 417         string defaultmodel = "";
 418         int defaultskin = 0;
 419         if(autocvar_sv_defaultcharacter)
 420         {
 421                 if(teamplay)
 422                 {
 423                         switch(player.team)
 424                         {
 425                                 case NUM_TEAM_1: defaultmodel = autocvar_sv_defaultplayermodel_red; defaultskin = autocvar_sv_defaultplayerskin_red; break;
 426                                 case NUM_TEAM_2: defaultmodel = autocvar_sv_defaultplayermodel_blue; defaultskin = autocvar_sv_defaultplayerskin_blue; break;
 427                                 case NUM_TEAM_3: defaultmodel = autocvar_sv_defaultplayermodel_yellow; defaultskin = autocvar_sv_defaultplayerskin_yellow; break;
 428                                 case NUM_TEAM_4: defaultmodel = autocvar_sv_defaultplayermodel_pink; defaultskin = autocvar_sv_defaultplayerskin_pink; break;
 429                         }
 430                 }
 431
 432                 if(defaultmodel == "")
 433                 {
 434                         defaultmodel = autocvar_sv_defaultplayermodel;
 435                         defaultskin = autocvar_sv_defaultplayerskin;
 436                 }
 437
 438                 int n = tokenize_console(defaultmodel);
 439                 if(n > 0)
 440                 {
 441                         defaultmodel = argv(floor(n * CS(player).model_randomizer));
 442                         // However, do NOT randomize if the player-selected model is in the list.
 443                         for (int i = 0; i < n; ++i)
 444                                 if ((argv(i) == player.playermodel && defaultskin == stof(player.playerskin)) || argv(i) == strcat(player.playermodel, ":", player.playerskin))
 445                                         defaultmodel = argv(i);
 446                 }
 447
 448                 int i = strstrofs(defaultmodel, ":", 0);
 449                 if(i >= 0)
 450                 {
 451                         defaultskin = stof(substring(defaultmodel, i+1, -1));
 452                         defaultmodel = substring(defaultmodel, 0, i);
 453                 }
 454         }
 455         if(autocvar_sv_defaultcharacterskin && !defaultskin)
 456         {
 457                 if(teamplay)
 458                 {
 459                         switch(player.team)
 460                         {
 461                                 case NUM_TEAM_1: defaultskin = autocvar_sv_defaultplayerskin_red; break;
 462                                 case NUM_TEAM_2: defaultskin = autocvar_sv_defaultplayerskin_blue; break;
 463                                 case NUM_TEAM_3: defaultskin = autocvar_sv_defaultplayerskin_yellow; break;
 464                                 case NUM_TEAM_4: defaultskin = autocvar_sv_defaultplayerskin_pink; break;
 465                         }
 466                 }
 467
 468                 if(!defaultskin)
 469                         defaultskin = autocvar_sv_defaultplayerskin;
 470         }
 471
 472         MUTATOR_CALLHOOK(FixPlayermodel, defaultmodel, defaultskin, player);
 473         defaultmodel = M_ARGV(0, string);
 474         defaultskin = M_ARGV(1, int);
 475
 476         bool chmdl = false;
 477         int oldskin;
 478         if(defaultmodel != "")
 479         {
 480                 if (defaultmodel != player.model)
 481                 {
 482                         vector m1 = player.mins;
 483                         vector m2 = player.maxs;
 484                         setplayermodel (player, defaultmodel);
 485                         setsize (player, m1, m2);
 486                         chmdl = true;
 487                 }
 488
 489                 oldskin = player.skin;
 490                 player.skin = defaultskin;
 491         } else {
 492                 if (player.playermodel != player.model || player.playermodel == "")
 493                 {
 494                         player.playermodel = CheckPlayerModel(player.playermodel); // this is never "", so no endless loop
 495                         vector m1 = player.mins;
 496                         vector m2 = player.maxs;
 497                         setplayermodel (player, player.playermodel);
 498                         setsize (player, m1, m2);
 499                         chmdl = true;
 500                 }
 501
 502                 if(!autocvar_sv_defaultcharacterskin)
 503                 {
 504                         oldskin = player.skin;
 505                         player.skin = stof(player.playerskin);
 506                 }
 507                 else
 508                 {
 509                         oldskin = player.skin;
 510                         player.skin = defaultskin;
 511                 }
 512         }
 513
 514         if(chmdl || oldskin != player.skin) // model or skin has changed
 515         {
 516                 player.species = player_getspecies(player); // update species
 517                 if(!autocvar_g_debug_globalsounds)
 518                         UpdatePlayerSounds(player); // update skin sounds
 519         }
 520
 521         if(!teamplay)
 522                 if(strlen(autocvar_sv_defaultplayercolors))
 523                         if(player.clientcolors != stof(autocvar_sv_defaultplayercolors))
 524                                 setcolor(player, stof(autocvar_sv_defaultplayercolors));
 525 }
 526
 527 void PutPlayerInServer(entity this)
 528 {
 529         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
 530
 531         PlayerState_attach(this);
 532         accuracy_resend(this);
 533
 534         if (this.team < 0)
 535                 TeamBalance_JoinBestTeam(this);
 536
 537         entity spot = SelectSpawnPoint(this, false);
 538         if (!spot) {
 539                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_JOIN_NOSPAWNS);
 540                 return; // spawn failed
 541         }
 542
 543         TRANSMUTE(Player, this);
 544
 545         CS(this).wasplayer = true;
 546         this.iscreature = true;
 547         this.teleportable = TELEPORT_NORMAL;
 548         if(!this.damagedbycontents)
 549                 IL_PUSH(g_damagedbycontents, this);
 550         this.damagedbycontents = true;
 551         set_movetype(this, MOVETYPE_WALK);
 552         this.solid = SOLID_SLIDEBOX;
 553         this.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_SOLID;
 554         if (autocvar_g_playerclip_collisions)
 555                 this.dphitcontentsmask |= DPCONTENTS_PLAYERCLIP;
 556         if (IS_BOT_CLIENT(this) && autocvar_g_botclip_collisions)
 557                 this.dphitcontentsmask |= DPCONTENTS_BOTCLIP;
 558         this.frags = FRAGS_PLAYER;
 559         if (INDEPENDENT_PLAYERS) MAKE_INDEPENDENT_PLAYER(this);
 560         this.flags = FL_CLIENT | FL_PICKUPITEMS;
 561         if (autocvar__notarget)
 562                 this.flags |= FL_NOTARGET;
 563         this.takedamage = DAMAGE_AIM;
 564         this.effects = EF_TELEPORT_BIT | EF_RESTARTANIM_BIT;
 565
 566         if (warmup_stage) {
 567                 SetResource(this, RES_SHELLS, warmup_start_ammo_shells);
 568                 SetResource(this, RES_BULLETS, warmup_start_ammo_nails);
 569                 SetResource(this, RES_ROCKETS, warmup_start_ammo_rockets);
 570                 SetResource(this, RES_CELLS, warmup_start_ammo_cells);
 571                 SetResource(this, RES_PLASMA, warmup_start_ammo_plasma);
 572                 SetResource(this, RES_FUEL, warmup_start_ammo_fuel);
 573                 SetResource(this, RES_HEALTH, warmup_start_health);
 574                 SetResource(this, RES_ARMOR, warmup_start_armorvalue);
 575                 STAT(WEAPONS, this) = WARMUP_START_WEAPONS;
 576         } else {
 577                 SetResource(this, RES_SHELLS, start_ammo_shells);
 578                 SetResource(this, RES_BULLETS, start_ammo_nails);
 579                 SetResource(this, RES_ROCKETS, start_ammo_rockets);
 580                 SetResource(this, RES_CELLS, start_ammo_cells);
 581                 SetResource(this, RES_PLASMA, start_ammo_plasma);
 582                 SetResource(this, RES_FUEL, start_ammo_fuel);
 583                 SetResource(this, RES_HEALTH, start_health);
 584                 SetResource(this, RES_ARMOR, start_armorvalue);
 585                 STAT(WEAPONS, this) = start_weapons;
 586                 if (MUTATOR_CALLHOOK(ForbidRandomStartWeapons, this) == false)
 587                 {
 588                         GiveRandomWeapons(this, random_start_weapons_count,
 589                                 autocvar_g_random_start_weapons, random_start_ammo);
 590                 }
 591         }
 592         SetSpectatee_status(this, 0);
 593
 594         PS(this).dual_weapons = '0 0 0';
 595
 596         STAT(SUPERWEAPONS_FINISHED, this) = (STAT(WEAPONS, this) & WEPSET_SUPERWEAPONS) ? time + autocvar_g_balance_superweapons_time : 0;
 597
 598         this.items = start_items;
 599
 600         this.spawnshieldtime = time + autocvar_g_spawnshieldtime;
 601         this.pauserotarmor_finished = time + autocvar_g_balance_pause_armor_rot_spawn;
 602         this.pauserothealth_finished = time + autocvar_g_balance_pause_health_rot_spawn;
 603         this.pauserotfuel_finished = time + autocvar_g_balance_pause_fuel_rot_spawn;
 604         this.pauseregen_finished = time + autocvar_g_balance_pause_health_regen_spawn;
 605         if (!sv_ready_restart_after_countdown && time < game_starttime)
 606         {
 607                 float f = game_starttime - time;
 608                 this.spawnshieldtime += f;
 609                 this.pauserotarmor_finished += f;
 610                 this.pauserothealth_finished += f;
 611                 this.pauseregen_finished += f;
 612         }
 613
 614         this.damageforcescale = autocvar_g_player_damageforcescale;
 615         this.death_time = 0;
 616         this.respawn_flags = 0;
 617         this.respawn_time = 0;
 618         STAT(RESPAWN_TIME, this) = 0;
 619         bool q3dfcompat = autocvar_sv_q3defragcompat && autocvar_sv_q3defragcompat_changehitbox;
 620         this.scale = ((q3dfcompat) ? 0.9 : autocvar_sv_player_scale);
 621         this.fade_time = 0;
 622         this.pain_finished = 0;
 623         this.pushltime = 0;
 624         setthink(this, func_null); // players have no think function
 625         this.nextthink = 0;
 626         this.dmg_team = 0;
 627         PS(this).ballistics_density = autocvar_g_ballistics_density_player;
 628
 629         this.deadflag = DEAD_NO;
 630
 631         this.angles = spot.angles;
 632         this.angles_z = 0; // never spawn tilted even if the spot says to
 633         if (IS_BOT_CLIENT(this))
 634         {
 635                 this.v_angle = this.angles;
 636                 bot_aim_reset(this);
 637         }
 638         this.fixangle = true; // turn this way immediately
 639         this.oldvelocity = this.velocity = '0 0 0';
 640         this.avelocity = '0 0 0';
 641         this.punchangle = '0 0 0';
 642         this.punchvector = '0 0 0';
 643
 644         STAT(STRENGTH_FINISHED, this) = 0;
 645         STAT(INVINCIBLE_FINISHED, this) = 0;
 646         this.fire_endtime = -1;
 647         STAT(REVIVE_PROGRESS, this) = 0;
 648         this.revival_time = 0;
 649
 650         // TODO: we can't set these in the PlayerSpawn hook since the target code is called before it!
 651         STAT(BUFFS, this) = 0;
 652         STAT(BUFF_TIME, this) = 0;
 653
 654         STAT(AIR_FINISHED, this) = 0;
 655         this.waterlevel = WATERLEVEL_NONE;
 656         this.watertype = CONTENT_EMPTY;
 657
 658         entity spawnevent = new_pure(spawnevent);
 659         spawnevent.owner = this;
 660         Net_LinkEntity(spawnevent, false, 0.5, SpawnEvent_Send);
 661
 662         // Cut off any still running player sounds.
 663         stopsound(this, CH_PLAYER_SINGLE);
 664
 665         this.model = "";
 666         FixPlayermodel(this);
 667         this.drawonlytoclient = NULL;
 668
 669         this.viewloc = NULL;
 670
 671         for(int slot = 0; slot < MAX_AXH; ++slot)
 672         {
 673                 entity axh = this.(AuxiliaryXhair[slot]);
 674                 this.(AuxiliaryXhair[slot]) = NULL;
 675
 676                 if(axh.owner == this && axh != NULL && !wasfreed(axh))
 677                         delete(axh);
 678         }
 679
 680         this.spawnpoint_targ = NULL;
 681
 682         UNSET_DUCKED(this);
 683         this.view_ofs = STAT(PL_VIEW_OFS, this);
 684         setsize(this, STAT(PL_MIN, this), STAT(PL_MAX, this));
 685         this.spawnorigin = spot.origin;
 686         setorigin(this, spot.origin + '0 0 1' * (1 - this.mins.z - 24));
 687         // don't reset back to last position, even if new position is stuck in solid
 688         this.oldorigin = this.origin;
 689         if(this.conveyor)
 690                 IL_REMOVE(g_conveyed, this);
 691         this.conveyor = NULL; // prevent conveyors at the previous location from moving a freshly spawned player
 692         if(this.swampslug)
 693                 IL_REMOVE(g_swamped, this);
 694         this.swampslug = NULL;
 695         this.swamp_interval = 0;
 696         if(this.ladder_entity)
 697                 IL_REMOVE(g_ladderents, this);
 698         this.ladder_entity = NULL;
 699         IL_EACH(g_counters, it.realowner == this,
 700         {
 701                 delete(it);
 702         });
 703         STAT(HUD, this) = HUD_NORMAL;
 704
 705         this.event_damage = PlayerDamage;
 706         this.event_heal = PlayerHeal;
 707
 708         this.draggable = func_null;
 709
 710         if(!this.bot_attack)
 711                 IL_PUSH(g_bot_targets, this);
 712         this.bot_attack = true;
 713         if(!this.monster_attack)
 714                 IL_PUSH(g_monster_targets, this);
 715         this.monster_attack = true;
 716         navigation_dynamicgoal_init(this, false);
 717
 718         PHYS_INPUT_BUTTON_ATCK(this) = PHYS_INPUT_BUTTON_JUMP(this) = PHYS_INPUT_BUTTON_ATCK2(this) = false;
 719
 720         // player was spectator
 721         if (CS(this).killcount == FRAGS_SPECTATOR) {
 722                 PlayerScore_Clear(this);
 723                 CS(this).killcount = 0;
 724                 CS(this).startplaytime = time;
 725         }
 726
 727         for (int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 728         {
 729                 .entity weaponentity = weaponentities[slot];
 730                 CL_SpawnWeaponentity(this, weaponentity);
 731         }
 732         this.alpha = default_player_alpha;
 733         this.colormod = '1 1 1' * autocvar_g_player_brightness;
 734         this.exteriorweaponentity.alpha = default_weapon_alpha;
 735
 736         this.speedrunning = false;
 737
 738         this.counter_cnt = 0;
 739         this.fragsfilter_cnt = 0;
 740
 741         target_voicescript_clear(this);
 742
 743         // reset fields the weapons may use
 744         FOREACH(Weapons, true, {
 745                 it.wr_resetplayer(it, this);
 746                         // reload all reloadable weapons
 747                 if (it.spawnflags & WEP_FLAG_RELOADABLE) {
 748                         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 749                         {
 750                                 .entity weaponentity = weaponentities[slot];
 751                                 this.(weaponentity).weapon_load[it.m_id] = it.reloading_ammo;
 752                         }
 753                 }
 754         });
 755
 756         {
 757                 string s = spot.target;
 758                 if(g_assault || g_race) // TODO: make targeting work in assault & race without this hack
 759                         spot.target = string_null;
 760                 SUB_UseTargets(spot, this, NULL);
 761                 if(g_assault || g_race)
 762                         spot.target = s;
 763         }
 764
 765         Unfreeze(this, false);
 766
 767         MUTATOR_CALLHOOK(PlayerSpawn, this, spot);
 768
 769         if (autocvar_spawn_debug)
 770         {
 771                 sprint(this, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
 772                 delete(spot); // usefull for checking if there are spawnpoints, that let drop through the floor
 773         }
 774
 775         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 776         {
 777                 .entity weaponentity = weaponentities[slot];
 778                 entity w_ent = this.(weaponentity);
 779                 if(slot == 0 || autocvar_g_weaponswitch_debug == 1)
 780                         w_ent.m_switchweapon = w_getbestweapon(this, weaponentity);
 781                 else
 782                         w_ent.m_switchweapon = WEP_Null;
 783                 w_ent.m_weapon = WEP_Null;
 784                 w_ent.weaponname = "";
 785                 w_ent.m_switchingweapon = WEP_Null;
 786                 w_ent.cnt = -1;
 787         }
 788
 789         MUTATOR_CALLHOOK(PlayerWeaponSelect, this);
 790
 791         if (CS(this).impulse) ImpulseCommands(this);
 792
 793         W_ResetGunAlign(this, CS_CVAR(this).cvar_cl_gunalign);
 794         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 795         {
 796                 .entity weaponentity = weaponentities[slot];
 797                 W_WeaponFrame(this, weaponentity);
 798         }
 799
 800         if (!warmup_stage && !this.alivetime)
 801                 this.alivetime = time;
 802
 803         antilag_clear(this, CS(this));
 804 }
 805
 806 /** Called when a client spawns in the server */
 807 void PutClientInServer(entity this)
 808 {
 809         if (IS_BOT_CLIENT(this)) {
 810                 TRANSMUTE(Player, this);
 811         } else if (IS_REAL_CLIENT(this)) {
 812                 msg_entity = this;
 813                 WriteByte(MSG_ONE, SVC_SETVIEW);
 814                 WriteEntity(MSG_ONE, this);
 815         }
 816         if (game_stopped)
 817                 TRANSMUTE(Observer, this);
 818
 819         SetSpectatee(this, NULL);
 820
 821         // reset player keys
 822         if(PS(this))
 823                 PS(this).itemkeys = 0;
 824
 825         MUTATOR_CALLHOOK(PutClientInServer, this);
 826
 827         if (IS_OBSERVER(this)) {
 828                 PutObserverInServer(this);
 829         } else if (IS_PLAYER(this)) {
 830                 PutPlayerInServer(this);
 831         }
 832
 833         bot_relinkplayerlist();
 834 }
 835
 836 // TODO do we need all these fields, or should we stop autodetecting runtime
 837 // changes and just have a console command to update this?
 838 bool ClientInit_SendEntity(entity this, entity to, int sf)
 839 {
 840         WriteHeader(MSG_ENTITY, _ENT_CLIENT_INIT);
 841         return = true;
 842         msg_entity = to;
 843         // MSG_INIT replacement
 844         // TODO: make easier to use
 845         Registry_send_all();
 846         W_PROP_reload(MSG_ONE, to);
 847         ClientInit_misc(this);
 848         MUTATOR_CALLHOOK(Ent_Init);
 849 }
 850 void ClientInit_misc(entity this)
 851 {
 852         int channel = MSG_ONE;
 853         WriteHeader(channel, ENT_CLIENT_INIT);
 854         WriteByte(channel, g_nexball_meter_period * 32);
 855         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[0]));
 856         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[1]));
 857         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[2]));
 858         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[3]));
 859         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[0]));
 860         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[1]));
 861         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[2]));
 862         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[3]));
 863
 864         if(autocvar_sv_foginterval && world.fog != "")
 865                 WriteString(channel, world.fog);
 866         else
 867                 WriteString(channel, "");
 868         WriteByte(channel, this.count * 255.0); // g_balance_armor_blockpercent
 869         WriteByte(channel, this.cnt * 255.0); // g_balance_damagepush_speedfactor
 870         WriteByte(channel, serverflags);
 871         WriteCoord(channel, autocvar_g_trueaim_minrange);
 872 }
 873
 874 void ClientInit_CheckUpdate(entity this)
 875 {
 876         this.nextthink = time;
 877         if(this.count != autocvar_g_balance_armor_blockpercent)
 878         {
 879                 this.count = autocvar_g_balance_armor_blockpercent;
 880                 this.SendFlags |= 1;
 881         }
 882         if(this.cnt != autocvar_g_balance_damagepush_speedfactor)
 883         {
 884                 this.cnt = autocvar_g_balance_damagepush_speedfactor;
 885                 this.SendFlags |= 1;
 886         }
 887 }
 888
 889 void ClientInit_Spawn()
 890 {
 891         entity e = new_pure(clientinit);
 892         setthink(e, ClientInit_CheckUpdate);
 893         Net_LinkEntity(e, false, 0, ClientInit_SendEntity);
 894
 895         ClientInit_CheckUpdate(e);
 896 }
 897
 898 /*
 899 =============
 900 SetNewParms
 901 =============
 902 */
 903 void SetNewParms ()
 904 {
 905         // initialize parms for a new player
 906         parm1 = -(86400 * 366);
 907
 908         MUTATOR_CALLHOOK(SetNewParms);
 909 }
 910
 911 /*
 912 =============
 913 SetChangeParms
 914 =============
 915 */
 916 void SetChangeParms (entity this)
 917 {
 918         // save parms for level change
 919         parm1 = CS(this).parm_idlesince - time;
 920
 921         MUTATOR_CALLHOOK(SetChangeParms);
 922 }
 923
 924 /*
 925 =============
 926 DecodeLevelParms
 927 =============
 928 */
 929 void DecodeLevelParms(entity this)
 930 {
 931         // load parms
 932         CS(this).parm_idlesince = parm1;
 933         if (CS(this).parm_idlesince == -(86400 * 366))
 934                 CS(this).parm_idlesince = time;
 935
 936         // whatever happens, allow 60 seconds of idling directly after connect for map loading
 937         CS(this).parm_idlesince = max(CS(this).parm_idlesince, time - autocvar_sv_maxidle + 60);
 938
 939         MUTATOR_CALLHOOK(DecodeLevelParms);
 940 }
 941
 942 void FixClientCvars(entity e)
 943 {
 944         // send prediction settings to the client
 945         stuffcmd(e, "\nin_bindmap 0 0\n");
 946         if(autocvar_g_antilag == 3) // client side hitscan
 947                 stuffcmd(e, "cl_cmd settemp cl_prydoncursor_notrace 0\n");
 948         if(autocvar_sv_gentle)
 949                 stuffcmd(e, "cl_cmd settemp cl_gentle 1\n");
 950
 951         stuffcmd(e, sprintf("\ncl_jumpspeedcap_min \"%s\"\n", autocvar_sv_jumpspeedcap_min));
 952         stuffcmd(e, sprintf("\ncl_jumpspeedcap_max \"%s\"\n", autocvar_sv_jumpspeedcap_max));
 953
 954         stuffcmd(e, sprintf("\ncl_shootfromfixedorigin \"%s\"\n", autocvar_g_shootfromfixedorigin));
 955
 956         MUTATOR_CALLHOOK(FixClientCvars, e);
 957 }
 958
 959 bool findinlist_abbrev(string tofind, string list)
 960 {
 961         if(list == "" || tofind == "")
 962                 return false; // empty list or search, just return
 963
 964         // this function allows abbreviated strings!
 965         FOREACH_WORD(list, it == substring(tofind, 0, strlen(it)),
 966         {
 967                 return true;
 968         });
 969
 970         return false;
 971 }
 972
 973 bool PlayerInIPList(entity p, string iplist)
 974 {
 975         // some safety checks (never allow local?)
 976         if(p.netaddress == "local" || p.netaddress == "" || !IS_REAL_CLIENT(p))
 977                 return false;
 978
 979         return findinlist_abbrev(p.netaddress, iplist);
 980 }
 981
 982 bool PlayerInIDList(entity p, string idlist)
 983 {
 984         // NOTE: we do NOT check crypto_idfp_signed here, an unsigned ID is fine too for this
 985         if(!p.crypto_idfp)
 986                 return false;
 987
 988         return findinlist_abbrev(p.crypto_idfp, idlist);
 989 }
 990
 991 bool PlayerInList(entity player, string list)
 992 {
 993         return boolean(PlayerInIDList(player, list) || PlayerInIPList(player, list));
 994 }
 995
 996 #ifdef DP_EXT_PRECONNECT
 997 /*
 998 =============
 999 ClientPreConnect
1000
1001 Called once (not at each match start) when a client begins a connection to the server
1002 =============
1003 */
1004 void ClientPreConnect(entity this)
1005 {
1006         if(autocvar_sv_eventlog)
1007         {
1008                 GameLogEcho(sprintf(":connect:%d:%d:%s",
1009                         this.playerid,
1010                         etof(this),
1011                         ((IS_REAL_CLIENT(this)) ? this.netaddress : "bot")
1012                 ));
1013         }
1014 }
1015 #endif
1016
1017 string GetClientVersionMessage(entity this)
1018 {
1019         if (CS(this).version_mismatch) {
1020                 if(CS(this).version < autocvar_gameversion) {
1021                         return strcat("This is Xonotic ", autocvar_g_xonoticversion,
1022                                 "\n^3Your client version is outdated.\n\n\n### YOU WON'T BE ABLE TO PLAY ON THIS SERVER ###\n\n\nPlease update!!!^8");
1023                 } else {
1024                         return strcat("This is Xonotic ", autocvar_g_xonoticversion,
1025                                 "\n^3This server is using an outdated Xonotic version.\n\n\n ### THIS SERVER IS INCOMPATIBLE AND THUS YOU CANNOT JOIN ###.^8");
1026                 }
1027         } else {
1028                 return strcat("Welcome to Xonotic ", autocvar_g_xonoticversion);
1029         }
1030 }
1031
1032 string getwelcomemessage(entity this)
1033 {
1034         MUTATOR_CALLHOOK(BuildMutatorsPrettyString, "");
1035         string modifications = M_ARGV(0, string);
1036
1037         if(g_weaponarena)
1038         {
1039                 if(g_weaponarena_random)
1040                         modifications = strcat(modifications, ", ", ftos(g_weaponarena_random), " of ", g_weaponarena_list, " Arena");
1041                 else
1042                         modifications = strcat(modifications, ", ", g_weaponarena_list, " Arena");
1043         }
1044         else if(cvar("g_balance_blaster_weaponstartoverride") == 0)
1045                 modifications = strcat(modifications, ", No start weapons");
1046         if(cvar("sv_gravity") < stof(cvar_defstring("sv_gravity")))
1047                 modifications = strcat(modifications, ", Low gravity");
1048         if(g_weapon_stay && !g_cts)
1049                 modifications = strcat(modifications, ", Weapons stay");
1050         if(autocvar_g_jetpack)
1051                 modifications = strcat(modifications, ", Jet pack");
1052         if(autocvar_g_powerups == 0)
1053                 modifications = strcat(modifications, ", No powerups");
1054         if(autocvar_g_powerups > 0)
1055                 modifications = strcat(modifications, ", Powerups");
1056         modifications = substring(modifications, 2, strlen(modifications) - 2);
1057
1058         string versionmessage = GetClientVersionMessage(this);
1059         string s = strcat(versionmessage, "^8\n^8\nserver is ^9", autocvar_hostname, "^8\n");
1060
1061         s = strcat(s, "^8\nmatch type is ^1", gamemode_name, "^8\n");
1062
1063         if(modifications != "")
1064                 s = strcat(s, "^8\nactive modifications: ^3", modifications, "^8\n");
1065
1066         if(cache_lastmutatormsg != autocvar_g_mutatormsg)
1067         {
1068                 strcpy(cache_lastmutatormsg, autocvar_g_mutatormsg);
1069                 strcpy(cache_mutatormsg, cache_lastmutatormsg);
1070         }
1071
1072         if (cache_mutatormsg != "") {
1073                 s = strcat(s, "\n\n^8special gameplay tips: ^7", cache_mutatormsg);
1074         }
1075
1076         string mutator_msg = "";
1077         MUTATOR_CALLHOOK(BuildGameplayTipsString, mutator_msg);
1078         mutator_msg = M_ARGV(0, string);
1079
1080         s = strcat(s, mutator_msg); // trust that the mutator will do proper formatting
1081
1082         string motd = autocvar_sv_motd;
1083         if (motd != "") {
1084                 s = strcat(s, "\n\n^8MOTD: ^7", strreplace("\\n", "\n", motd));
1085         }
1086         return s;
1087 }
1088
1089 bool autocvar_sv_qcphysics = true; // TODO this is for testing - remove when qcphysics work
1090
1091 /**
1092 =============
1093 ClientConnect
1094
1095 Called when a client connects to the server
1096 =============
1097 */
1098 void ClientConnect(entity this)
1099 {
1100         if (Ban_MaybeEnforceBanOnce(this)) return;
1101         assert(!IS_CLIENT(this), return);
1102         this.flags |= FL_CLIENT;
1103         assert(player_count >= 0, player_count = 0);
1104
1105         TRANSMUTE(Client, this);
1106         CS(this).version_nagtime = time + 10 + random() * 10;
1107
1108         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_JOIN_CONNECT, this.netname);
1109
1110         bot_clientconnect(this);
1111
1112         Player_DetermineForcedTeam(this);
1113
1114         TRANSMUTE(Observer, this);
1115
1116         PlayerStats_GameReport_AddEvent(sprintf("kills-%d", this.playerid));
1117
1118         // always track bots, don't ask for cl_allow_uidtracking
1119         if (IS_BOT_CLIENT(this))
1120                 PlayerStats_GameReport_AddPlayer(this);
1121         else
1122                 CS(this).allowed_timeouts = autocvar_sv_timeout_number;
1123
1124         if (autocvar_sv_eventlog)
1125                 GameLogEcho(strcat(":join:", ftos(this.playerid), ":", ftos(etof(this)), ":", ((IS_REAL_CLIENT(this)) ? GameLog_ProcessIP(this.netaddress) : "bot"), ":", playername(this.netname, this.team, false)));
1126
1127         CS(this).just_joined = true;  // stop spamming the eventlog with additional lines when the client connects
1128
1129         stuffcmd(this, clientstuff, "\n");
1130         stuffcmd(this, "cl_particles_reloadeffects\n"); // TODO do we still need this?
1131
1132         FixClientCvars(this);
1133
1134         // get version info from player
1135         stuffcmd(this, "cmd clientversion $gameversion\n");
1136
1137         // notify about available teams
1138         if (teamplay)
1139         {
1140                 entity balance = TeamBalance_CheckAllowedTeams(this);
1141                 int t = TeamBalance_GetAllowedTeams(balance);
1142                 TeamBalance_Destroy(balance);
1143                 stuffcmd(this, sprintf("set _teams_available %d\n", t));
1144         }
1145         else
1146         {
1147                 stuffcmd(this, "set _teams_available 0\n");
1148         }
1149
1150         bot_relinkplayerlist();
1151
1152         CS(this).spectatortime = time;
1153         if (blockSpectators)
1154         {
1155                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
1156         }
1157
1158         CS(this).jointime = time;
1159
1160         if (IS_REAL_CLIENT(this))
1161         {
1162                 if (g_weaponarena_weapons == WEPSET(TUBA))
1163                         stuffcmd(this, "cl_cmd settemp chase_active 1\n");
1164         }
1165
1166         if (!autocvar_sv_foginterval && world.fog != "")
1167                 stuffcmd(this, strcat("\nfog ", world.fog, "\nr_fog_exp2 0\nr_drawfog 1\n"));
1168
1169         if (autocvar_sv_teamnagger && !(autocvar_bot_vs_human && AvailableTeams() == 2))
1170                 if(!MUTATOR_CALLHOOK(HideTeamNagger, this))
1171                         send_CSQC_teamnagger();
1172
1173         CSQCMODEL_AUTOINIT(this);
1174
1175         CS(this).model_randomizer = random();
1176
1177         if (IS_REAL_CLIENT(this))
1178                 sv_notice_join(this);
1179
1180         this.move_qcphysics = autocvar_sv_qcphysics;
1181
1182         // update physics stats (players can spawn before physics runs)
1183         Physics_UpdateStats(this);
1184
1185         IL_EACH(g_initforplayer, it.init_for_player, {
1186                 it.init_for_player(it, this);
1187         });
1188
1189         Handicap_Initialize(this);
1190
1191         MUTATOR_CALLHOOK(ClientConnect, this);
1192
1193         if (IS_REAL_CLIENT(this))
1194         {
1195                 if (!autocvar_g_campaign && !IS_PLAYER(this))
1196                 {
1197                         CS(this).motd_actived_time = -1;
1198                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOTD, getwelcomemessage(this));
1199                 }
1200         }
1201 }
1202 /*
1203 =============
1204 ClientDisconnect
1205
1206 Called when a client disconnects from the server
1207 =============
1208 */
1209 .entity chatbubbleentity;
1210 void player_powerups_remove_all(entity this);
1211
1212 void ClientDisconnect(entity this)
1213 {
1214         assert(IS_CLIENT(this), return);
1215
1216         PlayerStats_GameReport_FinalizePlayer(this);
1217         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
1218         if (CS(this).active_minigame) part_minigame(this);
1219         if (IS_PLAYER(this)) Send_Effect(EFFECT_SPAWN_NEUTRAL, this.origin, '0 0 0', 1);
1220
1221         if (autocvar_sv_eventlog)
1222                 GameLogEcho(strcat(":part:", ftos(this.playerid)));
1223
1224         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_QUIT_DISCONNECT, this.netname);
1225
1226         if(IS_SPEC(this))
1227                 SetSpectatee(this, NULL);
1228
1229         MUTATOR_CALLHOOK(ClientDisconnect, this);
1230
1231         strfree(CS(this).netname_previous); // needs to be before the CS entity is removed!
1232         strfree(CS_CVAR(this).weaponorder_byimpulse);
1233         ClientState_detach(this);
1234
1235         Portal_ClearAll(this);
1236
1237         Unfreeze(this, false);
1238
1239         RemoveGrapplingHooks(this);
1240
1241         // Here, everything has been done that requires this player to be a client.
1242
1243         this.flags &= ~FL_CLIENT;
1244
1245         if (this.chatbubbleentity) delete(this.chatbubbleentity);
1246         if (this.killindicator) delete(this.killindicator);
1247
1248         IL_EACH(g_counters, it.realowner == this,
1249         {
1250                 delete(it);
1251         });
1252
1253         WaypointSprite_PlayerGone(this);
1254
1255         bot_relinkplayerlist();
1256
1257         strfree(this.clientstatus);
1258         if (this.personal) delete(this.personal);
1259
1260         this.playerid = 0;
1261         ReadyCount();
1262         if (vote_called && IS_REAL_CLIENT(this)) VoteCount(false);
1263
1264         player_powerups_remove_all(this); // stop powerup sound
1265
1266         ONREMOVE(this);
1267 }
1268
1269 void ChatBubbleThink(entity this)
1270 {
1271         this.nextthink = time;
1272         if ((this.owner.alpha < 0) || this.owner.chatbubbleentity != this)
1273         {
1274                 if(this.owner) // but why can that ever be NULL?
1275                         this.owner.chatbubbleentity = NULL;
1276                 delete(this);
1277                 return;
1278         }
1279
1280         this.mdl = "";
1281
1282         if ( !IS_DEAD(this.owner) && IS_PLAYER(this.owner) )
1283         {
1284                 if ( CS(this.owner).active_minigame && PHYS_INPUT_BUTTON_MINIGAME(this.owner) )
1285                         this.mdl = "models/sprites/minigame_busy.iqm";
1286                 else if (PHYS_INPUT_BUTTON_CHAT(this.owner))
1287                         this.mdl = "models/misc/chatbubble.spr";
1288         }
1289
1290         if ( this.model != this.mdl )
1291                 _setmodel(this, this.mdl);
1292
1293 }
1294
1295 void UpdateChatBubble(entity this)
1296 {
1297         if (this.alpha < 0)
1298                 return;
1299         // spawn a chatbubble entity if needed
1300         if (!this.chatbubbleentity)
1301         {
1302                 this.chatbubbleentity = new(chatbubbleentity);
1303                 this.chatbubbleentity.owner = this;
1304                 this.chatbubbleentity.exteriormodeltoclient = this;
1305                 setthink(this.chatbubbleentity, ChatBubbleThink);
1306                 this.chatbubbleentity.nextthink = time;
1307                 setmodel(this.chatbubbleentity, MDL_CHAT); // precision set below
1308                 //setorigin(this.chatbubbleentity, this.origin + '0 0 15' + this.maxs_z * '0 0 1');
1309                 setorigin(this.chatbubbleentity, '0 0 15' + this.maxs_z * '0 0 1');
1310                 setattachment(this.chatbubbleentity, this, "");  // sticks to moving player better, also conserves bandwidth
1311                 this.chatbubbleentity.mdl = this.chatbubbleentity.model;
1312                 //this.chatbubbleentity.model = "";
1313                 this.chatbubbleentity.effects = EF_LOWPRECISION;
1314         }
1315 }
1316
1317 void calculate_player_respawn_time(entity this)
1318 {
1319         if(MUTATOR_CALLHOOK(CalculateRespawnTime, this))
1320                 return;
1321
1322         float gametype_setting_tmp;
1323         float sdelay_max = GAMETYPE_DEFAULTED_SETTING(respawn_delay_max);
1324         float sdelay_small = GAMETYPE_DEFAULTED_SETTING(respawn_delay_small);
1325         float sdelay_large = GAMETYPE_DEFAULTED_SETTING(respawn_delay_large);
1326         float sdelay_small_count = GAMETYPE_DEFAULTED_SETTING(respawn_delay_small_count);
1327         float sdelay_large_count = GAMETYPE_DEFAULTED_SETTING(respawn_delay_large_count);
1328         float waves = GAMETYPE_DEFAULTED_SETTING(respawn_waves);
1329
1330         float pcount = 1;  // Include myself whether or not team is already set right and I'm a "player".
1331         if (teamplay)
1332         {
1333                 FOREACH_CLIENT(IS_PLAYER(it) && it != this, {
1334                         if(it.team == this.team)
1335                                 ++pcount;
1336                 });
1337                 if (sdelay_small_count == 0)
1338                         sdelay_small_count = 1;
1339                 if (sdelay_large_count == 0)
1340                         sdelay_large_count = 1;
1341         }
1342         else
1343         {
1344                 FOREACH_CLIENT(IS_PLAYER(it) && it != this, {
1345                         ++pcount;
1346                 });
1347                 if (sdelay_small_count == 0)
1348                 {
1349                         if (IS_INDEPENDENT_PLAYER(this))
1350                         {
1351                                 // Players play independently. No point in requiring enemies.
1352                                 sdelay_small_count = 1;
1353                         }
1354                         else
1355                         {
1356                                 // Players play AGAINST each other. Enemies required.
1357                                 sdelay_small_count = 2;
1358                         }
1359                 }
1360                 if (sdelay_large_count == 0)
1361                 {
1362                         if (IS_INDEPENDENT_PLAYER(this))
1363                         {
1364                                 // Players play independently. No point in requiring enemies.
1365                                 sdelay_large_count = 1;
1366                         }
1367                         else
1368                         {
1369                                 // Players play AGAINST each other. Enemies required.
1370                                 sdelay_large_count = 2;
1371                         }
1372                 }
1373         }
1374
1375         float sdelay;
1376
1377         if (pcount <= sdelay_small_count)
1378                 sdelay = sdelay_small;
1379         else if (pcount >= sdelay_large_count)
1380                 sdelay = sdelay_large;
1381         else  // NOTE: this case implies sdelay_large_count > sdelay_small_count.
1382                 sdelay = sdelay_small + (sdelay_large - sdelay_small) * (pcount - sdelay_small_count) / (sdelay_large_count - sdelay_small_count);
1383
1384         if(waves)
1385                 this.respawn_time = ceil((time + sdelay) / waves) * waves;
1386         else
1387                 this.respawn_time = time + sdelay;
1388
1389         if(sdelay < sdelay_max)
1390                 this.respawn_time_max = time + sdelay_max;
1391         else
1392                 this.respawn_time_max = this.respawn_time;
1393
1394         if((sdelay + waves >= 5.0) && (this.respawn_time - time > 1.75))
1395                 this.respawn_countdown = 10; // first number to count down from is 10
1396         else
1397                 this.respawn_countdown = -1; // do not count down
1398
1399         if(autocvar_g_forced_respawn)
1400                 this.respawn_flags = this.respawn_flags | RESPAWN_FORCE;
1401 }
1402
1403 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
1404 // added to the model skins
1405 /*void UpdateColorModHack()
1406 {
1407         float c;
1408         c = this.clientcolors & 15;
1409         // LordHavoc: only bothering to support white, green, red, yellow, blue
1410              if (!teamplay) this.colormod = '0 0 0';
1411         else if (c ==  0) this.colormod = '1.00 1.00 1.00';
1412         else if (c ==  3) this.colormod = '0.10 1.73 0.10';
1413         else if (c ==  4) this.colormod = '1.73 0.10 0.10';
1414         else if (c == 12) this.colormod = '1.22 1.22 0.10';
1415         else if (c == 13) this.colormod = '0.10 0.10 1.73';
1416         else this.colormod = '1 1 1';
1417 }*/
1418
1419 void respawn(entity this)
1420 {
1421         bool damagedbycontents_prev = this.damagedbycontents;
1422         if(this.alpha >= 0)
1423         {
1424                 if(autocvar_g_respawn_ghosts)
1425                 {
1426                         this.solid = SOLID_NOT;
1427                         this.takedamage = DAMAGE_NO;
1428                         this.damagedbycontents = false;
1429                         set_movetype(this, MOVETYPE_FLY);
1430                         this.velocity = '0 0 1' * autocvar_g_respawn_ghosts_speed;
1431                         this.avelocity = randomvec() * autocvar_g_respawn_ghosts_speed * 3 - randomvec() * autocvar_g_respawn_ghosts_speed * 3;
1432                         this.effects |= CSQCMODEL_EF_RESPAWNGHOST;
1433                         this.alpha = min(this.alpha, autocvar_g_respawn_ghosts_alpha);
1434                         Send_Effect(EFFECT_RESPAWN_GHOST, this.origin, '0 0 0', 1);
1435                         if(autocvar_g_respawn_ghosts_time > 0)
1436                                 SUB_SetFade(this, time + autocvar_g_respawn_ghosts_time, autocvar_g_respawn_ghosts_fadetime);
1437                 }
1438                 else
1439                         SUB_SetFade (this, time, 1); // fade out the corpse immediately
1440         }
1441
1442         CopyBody(this, 1);
1443         this.damagedbycontents = damagedbycontents_prev;
1444
1445         this.effects |= EF_NODRAW; // prevent another CopyBody
1446         PutClientInServer(this);
1447 }
1448
1449 void play_countdown(entity this, float finished, Sound samp)
1450 {
1451         TC(Sound, samp);
1452         if(IS_REAL_CLIENT(this))
1453                 if(floor(finished - time - frametime) != floor(finished - time))
1454                         if(finished - time < 6)
1455                                 sound (this, CH_INFO, samp, VOL_BASE, ATTEN_NORM);
1456 }
1457
1458 void player_powerups_remove_all(entity this)
1459 {
1460         if (this.items & (ITEM_Strength.m_itemid | ITEM_Shield.m_itemid | IT_SUPERWEAPON))
1461         {
1462                 // don't play the poweroff sound when the game restarts or the player disconnects
1463                 if (time > game_starttime + 1 && IS_CLIENT(this))
1464                         sound(this, CH_INFO, SND_POWEROFF, VOL_BASE, ATTEN_NORM);
1465                 stopsound(this, CH_TRIGGER_SINGLE); // get rid of the pickup sound
1466                 this.items &= ~ITEM_Strength.m_itemid;
1467                 this.items &= ~ITEM_Shield.m_itemid;
1468                 this.items -= (this.items & IT_SUPERWEAPON);
1469         }
1470 }
1471
1472 void player_powerups(entity this)
1473 {
1474         if((this.items & IT_USING_JETPACK) && !IS_DEAD(this) && !game_stopped)
1475                 this.modelflags |= MF_ROCKET;
1476         else
1477                 this.modelflags &= ~MF_ROCKET;
1478
1479         this.effects &= ~(EF_RED | EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT | EF_FLAME | EF_NODEPTHTEST);
1480
1481         if (IS_DEAD(this))
1482                 player_powerups_remove_all(this);
1483
1484         if((this.alpha < 0 || IS_DEAD(this)) && !this.vehicle) // don't apply the flags if the player is gibbed
1485                 return;
1486
1487         // add a way to see what the items were BEFORE all of these checks for the mutator hook
1488         int items_prev = this.items;
1489
1490         Fire_ApplyDamage(this);
1491         Fire_ApplyEffect(this);
1492
1493         if (!MUTATOR_IS_ENABLED(mutator_instagib))
1494         {
1495                 if (this.items & ITEM_Strength.m_itemid)
1496                 {
1497                         play_countdown(this, STAT(STRENGTH_FINISHED, this), SND_POWEROFF);
1498                         this.effects = this.effects | (EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT);
1499                         if (time > STAT(STRENGTH_FINISHED, this))
1500                         {
1501                                 this.items = this.items - (this.items & ITEM_Strength.m_itemid);
1502                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERDOWN_STRENGTH, this.netname);
1503                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERDOWN_STRENGTH);
1504                         }
1505                 }
1506                 else
1507                 {
1508                         if (time < STAT(STRENGTH_FINISHED, this))
1509                         {
1510                                 this.items = this.items | ITEM_Strength.m_itemid;
1511                                 if(!g_cts)
1512                                         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERUP_STRENGTH, this.netname);
1513                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERUP_STRENGTH);
1514                         }
1515                 }
1516                 if (this.items & ITEM_Shield.m_itemid)
1517                 {
1518                         play_countdown(this, STAT(INVINCIBLE_FINISHED, this), SND_POWEROFF);
1519                         this.effects = this.effects | (EF_RED | EF_ADDITIVE | EF_FULLBRIGHT);
1520                         if (time > STAT(INVINCIBLE_FINISHED, this))
1521                         {
1522                                 this.items = this.items - (this.items & ITEM_Shield.m_itemid);
1523                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERDOWN_SHIELD, this.netname);
1524                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERDOWN_SHIELD);
1525                         }
1526                 }
1527                 else
1528                 {
1529                         if (time < STAT(INVINCIBLE_FINISHED, this))
1530                         {
1531                                 this.items = this.items | ITEM_Shield.m_itemid;
1532                                 if(!g_cts)
1533                                         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERUP_SHIELD, this.netname);
1534                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERUP_SHIELD);
1535                         }
1536                 }
1537                 if (this.items & IT_SUPERWEAPON)
1538                 {
1539                         if (!(STAT(WEAPONS, this) & WEPSET_SUPERWEAPONS))
1540                         {
1541                                 STAT(SUPERWEAPONS_FINISHED, this) = 0;
1542                                 this.items = this.items - (this.items & IT_SUPERWEAPON);
1543                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_LOST, this.netname);
1544                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_LOST);
1545                         }
1546                         else if (this.items & IT_UNLIMITED_SUPERWEAPONS)
1547                         {
1548                                 // don't let them run out
1549                         }
1550                         else
1551                         {
1552                                 play_countdown(this, STAT(SUPERWEAPONS_FINISHED, this), SND_POWEROFF);
1553                                 if (time > STAT(SUPERWEAPONS_FINISHED, this))
1554                                 {
1555                                         this.items = this.items - (this.items & IT_SUPERWEAPON);
1556                                         STAT(WEAPONS, this) &= ~WEPSET_SUPERWEAPONS;
1557                                         //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_BROKEN, this.netname);
1558                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_BROKEN);
1559                                 }
1560                         }
1561                 }
1562                 else if(STAT(WEAPONS, this) & WEPSET_SUPERWEAPONS)
1563                 {
1564                         if (time < STAT(SUPERWEAPONS_FINISHED, this) || (this.items & IT_UNLIMITED_SUPERWEAPONS))
1565                         {
1566                                 this.items = this.items | IT_SUPERWEAPON;
1567                                 if(!(this.items & IT_UNLIMITED_SUPERWEAPONS))
1568                                 {
1569                                         if(!g_cts)
1570                                                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_PICKUP, this.netname);
1571                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_PICKUP);
1572                                 }
1573                         }
1574                         else
1575                         {
1576                                 STAT(SUPERWEAPONS_FINISHED, this) = 0;
1577                                 STAT(WEAPONS, this) &= ~WEPSET_SUPERWEAPONS;
1578                         }
1579                 }
1580                 else
1581                 {
1582                         STAT(SUPERWEAPONS_FINISHED, this) = 0;
1583                 }
1584         }
1585
1586         if(autocvar_g_nodepthtestplayers)
1587                 this.effects = this.effects | EF_NODEPTHTEST;
1588
1589         if(autocvar_g_fullbrightplayers)
1590                 this.effects = this.effects | EF_FULLBRIGHT;
1591
1592         if (time >= game_starttime)
1593         if (time < this.spawnshieldtime)
1594                 this.effects = this.effects | (EF_ADDITIVE | EF_FULLBRIGHT);
1595
1596         MUTATOR_CALLHOOK(PlayerPowerups, this, items_prev);
1597 }
1598
1599 float CalcRegen(float current, float stable, float regenfactor, float regenframetime)
1600 {
1601         if(current > stable)
1602                 return current;
1603         else if(current > stable - 0.25) // when close enough, "snap"
1604                 return stable;
1605         else
1606                 return min(stable, current + (stable - current) * regenfactor * regenframetime);
1607 }
1608
1609 float CalcRot(float current, float stable, float rotfactor, float rotframetime)
1610 {
1611         if(current < stable)
1612                 return current;
1613         else if(current < stable + 0.25) // when close enough, "snap"
1614                 return stable;
1615         else
1616                 return max(stable, current + (stable - current) * rotfactor * rotframetime);
1617 }
1618
1619 void RotRegen(entity this, int res, float regenstable, float regenfactor, float regenlinear, float regenframetime, float rotstable, float rotfactor, float rotlinear, float rotframetime, float limit_mod)
1620 {
1621         float old = GetResource(this, res);
1622         float current = old;
1623         if(current > rotstable)
1624         {
1625                 if(rotframetime > 0)
1626                 {
1627                         current = CalcRot(current, rotstable, rotfactor, rotframetime);
1628                         current = max(rotstable, current - rotlinear * rotframetime);
1629                 }
1630         }
1631         else if(current < regenstable)
1632         {
1633                 if(regenframetime > 0)
1634                 {
1635                         current = CalcRegen(current, regenstable, regenfactor, regenframetime);
1636                         current = min(regenstable, current + regenlinear * regenframetime);
1637                 }
1638         }
1639
1640         float limit = GetResourceLimit(this, res) * limit_mod;
1641         if(current > limit)
1642                 current = limit;
1643
1644         if (current != old)
1645                 SetResource(this, res, current);
1646 }
1647
1648 void player_regen(entity this)
1649 {
1650         float max_mod, regen_mod, rot_mod, limit_mod;
1651         max_mod = regen_mod = rot_mod = limit_mod = 1;
1652
1653         float regen_health = autocvar_g_balance_health_regen;
1654         float regen_health_linear = autocvar_g_balance_health_regenlinear;
1655         float regen_health_rot = autocvar_g_balance_health_rot;
1656         float regen_health_rotlinear = autocvar_g_balance_health_rotlinear;
1657         float regen_health_stable = autocvar_g_balance_health_regenstable;
1658         float regen_health_rotstable = autocvar_g_balance_health_rotstable;
1659         bool mutator_returnvalue = MUTATOR_CALLHOOK(PlayerRegen, this, max_mod, regen_mod, rot_mod, limit_mod, regen_health, regen_health_linear, regen_health_rot,
1660                 regen_health_rotlinear, regen_health_stable, regen_health_rotstable);
1661         max_mod = M_ARGV(1, float);
1662         regen_mod = M_ARGV(2, float);
1663         rot_mod = M_ARGV(3, float);
1664         limit_mod = M_ARGV(4, float);
1665         regen_health = M_ARGV(5, float);
1666         regen_health_linear = M_ARGV(6, float);
1667         regen_health_rot = M_ARGV(7, float);
1668         regen_health_rotlinear = M_ARGV(8, float);
1669         regen_health_stable = M_ARGV(9, float);
1670         regen_health_rotstable = M_ARGV(10, float);
1671
1672         if(!mutator_returnvalue)
1673         if(!STAT(FROZEN, this))
1674         {
1675                 float maxa = autocvar_g_balance_armor_rotstable;
1676                 float mina = autocvar_g_balance_armor_regenstable;
1677
1678                 RotRegen(this, RES_ARMOR, mina, autocvar_g_balance_armor_regen, autocvar_g_balance_armor_regenlinear,
1679                         regen_mod * frametime * (time > this.pauseregen_finished), maxa, autocvar_g_balance_armor_rot, autocvar_g_balance_armor_rotlinear,
1680                         rot_mod * frametime * (time > this.pauserotarmor_finished), limit_mod);
1681
1682                 RotRegen(this, RES_HEALTH, regen_health_stable * max_mod, regen_health, regen_health_linear,
1683                         regen_mod * frametime * (time > this.pauseregen_finished), regen_health_rotstable * max_mod, regen_health_rot, regen_health_rotlinear,
1684                         rot_mod * frametime * (time > this.pauserothealth_finished), limit_mod);
1685         }
1686
1687         // if player rotted to death...  die!
1688         // check this outside above checks, as player may still be able to rot to death
1689         if(GetResource(this, RES_HEALTH) < 1)
1690         {
1691                 if(this.vehicle)
1692                         vehicles_exit(this.vehicle, VHEF_RELEASE);
1693                 if(this.event_damage)
1694                         this.event_damage(this, this, this, 1, DEATH_ROT.m_id, DMG_NOWEP, this.origin, '0 0 0');
1695         }
1696
1697         if (!(this.items & IT_UNLIMITED_AMMO))
1698         {
1699                 float maxf = autocvar_g_balance_fuel_rotstable;
1700                 float minf = autocvar_g_balance_fuel_regenstable;
1701
1702                 RotRegen(this, RES_FUEL, minf, autocvar_g_balance_fuel_regen, autocvar_g_balance_fuel_regenlinear,
1703                         frametime * (time > this.pauseregen_finished) * ((this.items & ITEM_JetpackRegen.m_itemid) != 0),
1704                         maxf, autocvar_g_balance_fuel_rot, autocvar_g_balance_fuel_rotlinear, frametime * (time > this.pauserotfuel_finished), 1);
1705         }
1706 }
1707
1708 bool zoomstate_set;
1709 void SetZoomState(entity this, float newzoom)
1710 {
1711         if(newzoom != CS(this).zoomstate)
1712         {
1713                 CS(this).zoomstate = newzoom;
1714                 ClientData_Touch(this);
1715         }
1716         zoomstate_set = true;
1717 }
1718
1719 void GetPressedKeys(entity this)
1720 {
1721         MUTATOR_CALLHOOK(GetPressedKeys, this);
1722         if (game_stopped)
1723         {
1724                 CS(this).pressedkeys = 0;
1725                 STAT(PRESSED_KEYS, this) = 0;
1726                 return;
1727         }
1728
1729         // NOTE: GetPressedKeys and PM_dodging_GetPressedKeys use similar code
1730         int keys = STAT(PRESSED_KEYS, this);
1731         keys = BITSET(keys, KEY_FORWARD,        CS(this).movement.x > 0);
1732         keys = BITSET(keys, KEY_BACKWARD,       CS(this).movement.x < 0);
1733         keys = BITSET(keys, KEY_RIGHT,          CS(this).movement.y > 0);
1734         keys = BITSET(keys, KEY_LEFT,           CS(this).movement.y < 0);
1735
1736         keys = BITSET(keys, KEY_JUMP,           PHYS_INPUT_BUTTON_JUMP(this));
1737         keys = BITSET(keys, KEY_CROUCH,         IS_DUCKED(this)); // workaround: player can't un-crouch until their path is clear, so we keep the button held here
1738         keys = BITSET(keys, KEY_ATCK,           PHYS_INPUT_BUTTON_ATCK(this));
1739         keys = BITSET(keys, KEY_ATCK2,          PHYS_INPUT_BUTTON_ATCK2(this));
1740         CS(this).pressedkeys = keys; // store for other users
1741
1742         STAT(PRESSED_KEYS, this) = keys;
1743 }
1744
1745 /*
1746 ======================
1747 spectate mode routines
1748 ======================
1749 */
1750
1751 void SpectateCopy(entity this, entity spectatee)
1752 {
1753         TC(Client, this); TC(Client, spectatee);
1754
1755         MUTATOR_CALLHOOK(SpectateCopy, spectatee, this);
1756         PS(this) = PS(spectatee);
1757         this.armortype = spectatee.armortype;
1758         SetResourceExplicit(this, RES_ARMOR, GetResource(spectatee, RES_ARMOR));
1759         SetResourceExplicit(this, RES_CELLS, GetResource(spectatee, RES_CELLS));
1760         SetResourceExplicit(this, RES_PLASMA, GetResource(spectatee, RES_PLASMA));
1761         SetResourceExplicit(this, RES_SHELLS, GetResource(spectatee, RES_SHELLS));
1762         SetResourceExplicit(this, RES_BULLETS, GetResource(spectatee, RES_BULLETS));
1763         SetResourceExplicit(this, RES_ROCKETS, GetResource(spectatee, RES_ROCKETS));
1764         SetResourceExplicit(this, RES_FUEL, GetResource(spectatee, RES_FUEL));
1765         this.effects = spectatee.effects & EFMASK_CHEAP; // eat performance
1766         SetResourceExplicit(this, RES_HEALTH, GetResource(spectatee, RES_HEALTH));
1767         CS(this).impulse = 0;
1768         this.disableclientprediction = 1; // no need to run prediction on a spectator
1769         this.items = spectatee.items;
1770         STAT(LAST_PICKUP, this) = STAT(LAST_PICKUP, spectatee);
1771         STAT(HIT_TIME, this) = STAT(HIT_TIME, spectatee);
1772         STAT(STRENGTH_FINISHED, this) = STAT(STRENGTH_FINISHED, spectatee);
1773         STAT(INVINCIBLE_FINISHED, this) = STAT(INVINCIBLE_FINISHED, spectatee);
1774         STAT(SUPERWEAPONS_FINISHED, this) = STAT(SUPERWEAPONS_FINISHED, spectatee);
1775         STAT(AIR_FINISHED, this) = STAT(AIR_FINISHED, spectatee);
1776         STAT(PRESSED_KEYS, this) = STAT(PRESSED_KEYS, spectatee);
1777         STAT(WEAPONS, this) = STAT(WEAPONS, spectatee);
1778         this.punchangle = spectatee.punchangle;
1779         this.view_ofs = spectatee.view_ofs;
1780         this.velocity = spectatee.velocity;
1781         this.dmg_take = spectatee.dmg_take;
1782         this.dmg_save = spectatee.dmg_save;
1783         this.dmg_inflictor = spectatee.dmg_inflictor;
1784         this.v_angle = spectatee.v_angle;
1785         this.angles = spectatee.v_angle;
1786         STAT(FROZEN, this) = STAT(FROZEN, spectatee);
1787         STAT(REVIVE_PROGRESS, this) = STAT(REVIVE_PROGRESS, spectatee);
1788         this.viewloc = spectatee.viewloc;
1789         if(!PHYS_INPUT_BUTTON_USE(this) && STAT(CAMERA_SPECTATOR, this) != 2)
1790                 this.fixangle = true;
1791         setorigin(this, spectatee.origin);
1792         setsize(this, spectatee.mins, spectatee.maxs);
1793         SetZoomState(this, CS(spectatee).zoomstate);
1794
1795     anticheat_spectatecopy(this, spectatee);
1796         STAT(HUD, this) = STAT(HUD, spectatee);
1797         if(spectatee.vehicle)
1798     {
1799         this.angles = spectatee.v_angle;
1800
1801         //this.fixangle = false;
1802         //this.velocity = spectatee.vehicle.velocity;
1803         this.vehicle_health = spectatee.vehicle_health;
1804         this.vehicle_shield = spectatee.vehicle_shield;
1805         this.vehicle_energy = spectatee.vehicle_energy;
1806         this.vehicle_ammo1 = spectatee.vehicle_ammo1;
1807         this.vehicle_ammo2 = spectatee.vehicle_ammo2;
1808         this.vehicle_reload1 = spectatee.vehicle_reload1;
1809         this.vehicle_reload2 = spectatee.vehicle_reload2;
1810
1811         //msg_entity = this;
1812
1813        // WriteByte (MSG_ONE, SVC_SETVIEWANGLES);
1814             //WriteAngle(MSG_ONE,  spectatee.v_angle.x);
1815            // WriteAngle(MSG_ONE,  spectatee.v_angle.y);
1816            // WriteAngle(MSG_ONE,  spectatee.v_angle.z);
1817
1818         //WriteByte (MSG_ONE, SVC_SETVIEW);
1819         //    WriteEntity(MSG_ONE, this);
1820         //makevectors(spectatee.v_angle);
1821         //setorigin(this, spectatee.origin - v_forward * 400 + v_up * 300);*/
1822     }
1823 }
1824
1825 bool SpectateUpdate(entity this)
1826 {
1827         if(!this.enemy)
1828                 return false;
1829
1830         if(!IS_PLAYER(this.enemy) || this == this.enemy)
1831         {
1832                 SetSpectatee(this, NULL);
1833                 return false;
1834         }
1835
1836         SpectateCopy(this, this.enemy);
1837
1838         return true;
1839 }
1840
1841 bool SpectateSet(entity this)
1842 {
1843         if(!IS_PLAYER(this.enemy))
1844                 return false;
1845
1846         ClientData_Touch(this.enemy);
1847
1848         msg_entity = this;
1849         WriteByte(MSG_ONE, SVC_SETVIEW);
1850         WriteEntity(MSG_ONE, this.enemy);
1851         set_movetype(this, MOVETYPE_NONE);
1852         accuracy_resend(this);
1853
1854         if(!SpectateUpdate(this))
1855                 PutObserverInServer(this);
1856
1857         return true;
1858 }
1859
1860 void SetSpectatee_status(entity this, int spectatee_num)
1861 {
1862         int oldspectatee_status = CS(this).spectatee_status;
1863         CS(this).spectatee_status = spectatee_num;
1864
1865         if (CS(this).spectatee_status != oldspectatee_status)
1866         {
1867                 if (STAT(PRESSED_KEYS, this))
1868                 {
1869                         CS(this).pressedkeys = 0;
1870                         STAT(PRESSED_KEYS, this) = 0;
1871                 }
1872                 ClientData_Touch(this);
1873                 if (g_race || g_cts) race_InitSpectator();
1874         }
1875 }
1876
1877 void SetSpectatee(entity this, entity spectatee)
1878 {
1879         if(IS_BOT_CLIENT(this))
1880                 return; // bots abuse .enemy, this code is useless to them
1881
1882         entity old_spectatee = this.enemy;
1883
1884         this.enemy = spectatee;
1885
1886         // WEAPONTODO
1887         // these are required to fix the spectator bug with arc
1888         if(old_spectatee)
1889         {
1890                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1891                 {
1892                         .entity weaponentity = weaponentities[slot];
1893                         if(old_spectatee.(weaponentity).arc_beam)
1894                                 old_spectatee.(weaponentity).arc_beam.SendFlags |= ARC_SF_SETTINGS;
1895                 }
1896         }
1897         if(this.enemy)
1898         {
1899                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1900                 {
1901                         .entity weaponentity = weaponentities[slot];
1902                         if(this.enemy.(weaponentity).arc_beam)
1903                                 this.enemy.(weaponentity).arc_beam.SendFlags |= ARC_SF_SETTINGS;
1904                 }
1905         }
1906
1907         if (this.enemy)
1908                 SetSpectatee_status(this, etof(this.enemy));
1909
1910         // needed to update spectator list
1911         if(old_spectatee) { ClientData_Touch(old_spectatee); }
1912 }
1913
1914 bool Spectate(entity this, entity pl)
1915 {
1916         if(MUTATOR_CALLHOOK(SpectateSet, this, pl))
1917                 return false;
1918         pl = M_ARGV(1, entity);
1919
1920         SetSpectatee(this, pl);
1921         return SpectateSet(this);
1922 }
1923
1924 bool SpectateNext(entity this)
1925 {
1926         entity ent = find(this.enemy, classname, STR_PLAYER);
1927
1928         if (MUTATOR_CALLHOOK(SpectateNext, this, ent))
1929                 ent = M_ARGV(1, entity);
1930         else if (!ent)
1931                 ent = find(ent, classname, STR_PLAYER);
1932
1933         if(ent) { SetSpectatee(this, ent); }
1934
1935         return SpectateSet(this);
1936 }
1937
1938 bool SpectatePrev(entity this)
1939 {
1940         // NOTE: chain order is from the highest to the lower entnum (unlike find)
1941         entity ent = findchain(classname, STR_PLAYER);
1942         if (!ent) // no player
1943                 return false;
1944
1945         entity first = ent;
1946         // skip players until current spectated player
1947         if(this.enemy)
1948         while(ent && ent != this.enemy)
1949                 ent = ent.chain;
1950
1951         switch (MUTATOR_CALLHOOK(SpectatePrev, this, ent, first))
1952         {
1953                 case MUT_SPECPREV_FOUND:
1954                         ent = M_ARGV(1, entity);
1955                         break;
1956                 case MUT_SPECPREV_RETURN:
1957                         return true;
1958                 case MUT_SPECPREV_CONTINUE:
1959                 default:
1960                 {
1961                         if(ent.chain)
1962                                 ent = ent.chain;
1963                         else
1964                                 ent = first;
1965                         break;
1966                 }
1967         }
1968
1969         SetSpectatee(this, ent);
1970         return SpectateSet(this);
1971 }
1972
1973 /*
1974 =============
1975 ShowRespawnCountdown()
1976
1977 Update a respawn countdown display.
1978 =============
1979 */
1980 void ShowRespawnCountdown(entity this)
1981 {
1982         float number;
1983         if(!IS_DEAD(this)) // just respawned?
1984                 return;
1985         else
1986         {
1987                 number = ceil(this.respawn_time - time);
1988                 if(number <= 0)
1989                         return;
1990                 if(number <= this.respawn_countdown)
1991                 {
1992                         this.respawn_countdown = number - 1;
1993                         if(ceil(this.respawn_time - (time + 0.5)) == number) // only say it if it is the same number even in 0.5s; to prevent overlapping sounds
1994                                 { Send_Notification(NOTIF_ONE, this, MSG_ANNCE, Announcer_PickNumber(CNT_RESPAWN, number)); }
1995                 }
1996         }
1997 }
1998
1999 .bool team_selected;
2000 bool ShowTeamSelection(entity this)
2001 {
2002         if (!teamplay || autocvar_g_campaign || autocvar_g_balance_teams || this.team_selected || (CS(this).wasplayer && autocvar_g_changeteam_banned) || Player_HasRealForcedTeam(this))
2003                 return false;
2004         stuffcmd(this, "menu_showteamselect\n");
2005         return true;
2006 }
2007 void Join(entity this)
2008 {
2009         TRANSMUTE(Player, this);
2010
2011         if(!this.team_selected)
2012         if(autocvar_g_campaign || autocvar_g_balance_teams)
2013                 TeamBalance_JoinBestTeam(this);
2014
2015         if(autocvar_g_campaign)
2016                 campaign_bots_may_start = true;
2017
2018         Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_PREVENT_JOIN);
2019
2020         PutClientInServer(this);
2021
2022         if(IS_PLAYER(this))
2023         if(teamplay && this.team != -1)
2024         {
2025         }
2026         else
2027                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_JOIN_PLAY, this.netname);
2028         this.team_selected = false;
2029 }
2030
2031 int GetPlayerLimit()
2032 {
2033         if(g_duel)
2034                 return 2; // TODO: this workaround is needed since the mutator hook from duel can't be activated before the gametype is loaded (e.g. switching modes via gametype vote screen)
2035         int player_limit = autocvar_g_maxplayers;
2036         MUTATOR_CALLHOOK(GetPlayerLimit, player_limit);
2037         player_limit = M_ARGV(0, int);
2038         return player_limit;
2039 }
2040
2041 /**
2042  * Determines whether the player is allowed to join. This depends on cvar
2043  * g_maxplayers, if it isn't used this function always return true, otherwise
2044  * it checks whether the number of currently playing players exceeds g_maxplayers.
2045  * @return int number of free slots for players, 0 if none
2046  */
2047 int nJoinAllowed(entity this, entity ignore)
2048 {
2049         if(!ignore)
2050         // this is called that way when checking if anyone may be able to join (to build qcstatus)
2051         // so report 0 free slots if restricted
2052         {
2053                 if(autocvar_g_forced_team_otherwise == "spectate")
2054                         return 0;
2055                 if(autocvar_g_forced_team_otherwise == "spectator")
2056                         return 0;
2057         }
2058
2059         if(this && (Player_GetForcedTeamIndex(this) == TEAM_FORCE_SPECTATOR))
2060                 return 0; // forced spectators can never join
2061
2062         // TODO simplify this
2063         int totalClients = 0;
2064         int currentlyPlaying = 0;
2065         FOREACH_CLIENT(true, {
2066                 if(it != ignore)
2067                         ++totalClients;
2068                 if(IS_REAL_CLIENT(it))
2069                 if(IS_PLAYER(it) || it.caplayer)
2070                         ++currentlyPlaying;
2071         });
2072
2073         int player_limit = GetPlayerLimit();
2074
2075         int free_slots = 0;
2076         if (!player_limit)
2077                 free_slots = maxclients - totalClients;
2078         else if(player_limit > 0 && currentlyPlaying < player_limit)
2079                 free_slots = min(maxclients - totalClients, player_limit - currentlyPlaying);
2080
2081         static float msg_time = 0;
2082         if(this && !this.caplayer && ignore && !free_slots && time > msg_time)
2083         {
2084                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_JOIN_PREVENT);
2085                 msg_time = time + 0.5;
2086         }
2087
2088         return free_slots;
2089 }
2090
2091 void PrintWelcomeMessage(entity this)
2092 {
2093         if(CS(this).motd_actived_time == 0)
2094         {
2095                 if (autocvar_g_campaign) {
2096                         if ((IS_PLAYER(this) && PHYS_INPUT_BUTTON_INFO(this)) || (!IS_PLAYER(this))) {
2097                                 CS(this).motd_actived_time = time;
2098                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_CAMPAIGN_MESSAGE, Campaign_GetMessage(), Campaign_GetLevelNum());
2099                         }
2100                 } else {
2101                         if (PHYS_INPUT_BUTTON_INFO(this)) {
2102                                 CS(this).motd_actived_time = time;
2103                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOTD, getwelcomemessage(this));
2104                         }
2105                 }
2106         }
2107         else if(CS(this).motd_actived_time > 0) // showing MOTD or campaign message
2108         {
2109                 if (autocvar_g_campaign) {
2110                         if (PHYS_INPUT_BUTTON_INFO(this))
2111                                 CS(this).motd_actived_time = time;
2112                         else if ((time - CS(this).motd_actived_time > 2) && IS_PLAYER(this)) { // hide it some seconds after BUTTON_INFO has been released
2113                                 CS(this).motd_actived_time = 0;
2114                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_CAMPAIGN_MESSAGE);
2115                         }
2116                 } else {
2117                         if (PHYS_INPUT_BUTTON_INFO(this))
2118                                 CS(this).motd_actived_time = time;
2119                         else if (time - CS(this).motd_actived_time > 2) { // hide it some seconds after BUTTON_INFO has been released
2120                                 CS(this).motd_actived_time = 0;
2121                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_MOTD);
2122                         }
2123                 }
2124         }
2125         else //if(CS(this).motd_actived_time < 0) // just connected, motd is active
2126         {
2127                 if(PHYS_INPUT_BUTTON_INFO(this)) // BUTTON_INFO hides initial MOTD
2128                         CS(this).motd_actived_time = -2; // wait until BUTTON_INFO gets released
2129                 else if (CS(this).motd_actived_time == -2)
2130                 {
2131                         // instantly hide MOTD
2132                         CS(this).motd_actived_time = 0;
2133                         if (autocvar_g_campaign)
2134                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_CAMPAIGN_MESSAGE);
2135                         else
2136                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_MOTD);
2137                 }
2138                 else if (IS_PLAYER(this) || IS_SPEC(this))
2139                 {
2140                         // FIXME occasionally for some reason MOTD never goes away
2141                         // delay MOTD removal a little bit in the hope it fixes this bug
2142                         if (CS(this).motd_actived_time == -1) // MOTD marked to fade away as soon as client becomes player or spectator
2143                                 CS(this).motd_actived_time = -(5 + floor(random() * 10)); // add small delay
2144                         else //if (CS(this).motd_actived_time < -2)
2145                                 CS(this).motd_actived_time++;
2146                 }
2147         }
2148 }
2149
2150 bool joinAllowed(entity this)
2151 {
2152         if (CS(this).version_mismatch) return false;
2153         if (time < CS(this).jointime + MIN_SPEC_TIME) return false;
2154         if (!nJoinAllowed(this, this)) return false;
2155         if (teamplay && lockteams) return false;
2156         if (MUTATOR_CALLHOOK(ForbidSpawn, this)) return false;
2157         if (ShowTeamSelection(this)) return false;
2158         return true;
2159 }
2160
2161 .string shootfromfixedorigin;
2162 .bool dualwielding_prev;
2163 bool PlayerThink(entity this)
2164 {
2165         if (game_stopped || intermission_running) {
2166                 this.modelflags &= ~MF_ROCKET;
2167                 if(intermission_running)
2168                         IntermissionThink(this);
2169                 return false;
2170         }
2171
2172         if (timeout_status == TIMEOUT_ACTIVE) {
2173                 // don't allow the player to turn around while game is paused
2174                 // FIXME turn this into CSQC stuff
2175                 this.v_angle = this.lastV_angle;
2176                 this.angles = this.lastV_angle;
2177                 this.fixangle = true;
2178         }
2179
2180         if (frametime) player_powerups(this);
2181
2182         if (IS_DEAD(this)) {
2183                 if (this.personal && g_race_qualifying) {
2184                         if (time > this.respawn_time) {
2185                                 STAT(RESPAWN_TIME, this) = this.respawn_time = time + 1; // only retry once a second
2186                                 respawn(this);
2187                                 CS(this).impulse = CHIMPULSE_SPEEDRUN.impulse;
2188                         }
2189                 } else {
2190                         if (frametime) player_anim(this);
2191
2192                         if (this.respawn_flags & RESPAWN_DENY)
2193                         {
2194                                 STAT(RESPAWN_TIME, this) = 0;
2195                                 return false;
2196                         }
2197
2198                         bool button_pressed = (PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_JUMP(this) || PHYS_INPUT_BUTTON_ATCK2(this) || PHYS_INPUT_BUTTON_HOOK(this) || PHYS_INPUT_BUTTON_USE(this));
2199
2200                         switch(this.deadflag)
2201                         {
2202                                 case DEAD_DYING:
2203                                 {
2204                                         if ((this.respawn_flags & RESPAWN_FORCE) && !(this.respawn_time < this.respawn_time_max))
2205                                                 this.deadflag = DEAD_RESPAWNING;
2206                                         else if (!button_pressed || (time >= this.respawn_time_max && (this.respawn_flags & RESPAWN_FORCE)))
2207                                                 this.deadflag = DEAD_DEAD;
2208                                         break;
2209                                 }
2210                                 case DEAD_DEAD:
2211                                 {
2212                                         if (button_pressed)
2213                                                 this.deadflag = DEAD_RESPAWNABLE;
2214                                         else if (time >= this.respawn_time_max && (this.respawn_flags & RESPAWN_FORCE))
2215                                                 this.deadflag = DEAD_RESPAWNING;
2216                                         break;
2217                                 }
2218                                 case DEAD_RESPAWNABLE:
2219                                 {
2220                                         if (!button_pressed || (this.respawn_flags & RESPAWN_FORCE))
2221                                                 this.deadflag = DEAD_RESPAWNING;
2222                                         break;
2223                                 }
2224                                 case DEAD_RESPAWNING:
2225                                 {
2226                                         if (time > this.respawn_time)
2227                                         {
2228                                                 this.respawn_time = time + 1; // only retry once a second
2229                                                 this.respawn_time_max = this.respawn_time;
2230                                                 respawn(this);
2231                                         }
2232                                         break;
2233                                 }
2234                         }
2235
2236                         ShowRespawnCountdown(this);
2237
2238                         if (this.respawn_flags & RESPAWN_SILENT)
2239                                 STAT(RESPAWN_TIME, this) = 0;
2240                         else if ((this.respawn_flags & RESPAWN_FORCE) && this.respawn_time < this.respawn_time_max)
2241                         {
2242                                 if (time < this.respawn_time)
2243                                         STAT(RESPAWN_TIME, this) = this.respawn_time;
2244                                 else if (this.deadflag != DEAD_RESPAWNING)
2245                                         STAT(RESPAWN_TIME, this) = -this.respawn_time_max;
2246                         }
2247                         else
2248                                 STAT(RESPAWN_TIME, this) = this.respawn_time;
2249                 }
2250
2251                 // if respawning, invert stat_respawn_time to indicate this, the client translates it
2252                 if (this.deadflag == DEAD_RESPAWNING && STAT(RESPAWN_TIME, this) > 0)
2253                         STAT(RESPAWN_TIME, this) *= -1;
2254
2255                 return false;
2256         }
2257
2258         FixPlayermodel(this);
2259
2260         if (this.shootfromfixedorigin != autocvar_g_shootfromfixedorigin) {
2261                 this.shootfromfixedorigin = autocvar_g_shootfromfixedorigin;
2262                 stuffcmd(this, sprintf("\ncl_shootfromfixedorigin \"%s\"\n", autocvar_g_shootfromfixedorigin));
2263         }
2264
2265         // reset gun alignment when dual wielding status changes
2266         // to ensure guns are always aligned right and left
2267         bool dualwielding = W_DualWielding(this);
2268         if(this.dualwielding_prev != dualwielding)
2269         {
2270                 W_ResetGunAlign(this, CS_CVAR(this).cvar_cl_gunalign);
2271                 this.dualwielding_prev = dualwielding;
2272         }
2273
2274         // LordHavoc: allow firing on move frames (sub-ticrate), this gives better timing on slow servers
2275         //if(frametime)
2276         {
2277                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2278                 {
2279                         .entity weaponentity = weaponentities[slot];
2280                         if(WEP_CVAR(vortex, charge_always))
2281                                 W_Vortex_Charge(this, weaponentity, frametime);
2282                         W_WeaponFrame(this, weaponentity);
2283                 }
2284         }
2285
2286         if (frametime)
2287         {
2288                 // WEAPONTODO: Add a weapon request for this
2289                 // rot vortex charge to the charge limit
2290                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2291                 {
2292                         .entity weaponentity = weaponentities[slot];
2293                         if (WEP_CVAR(vortex, charge_rot_rate) && this.(weaponentity).vortex_charge > WEP_CVAR(vortex, charge_limit) && this.(weaponentity).vortex_charge_rottime < time)
2294                                 this.(weaponentity).vortex_charge = bound(WEP_CVAR(vortex, charge_limit), this.(weaponentity).vortex_charge - WEP_CVAR(vortex, charge_rot_rate) * frametime / W_TICSPERFRAME, 1);
2295                 }
2296
2297                 player_regen(this);
2298                 player_anim(this);
2299                 this.dmg_team = max(0, this.dmg_team - autocvar_g_teamdamage_resetspeed * frametime);
2300         }
2301
2302         monsters_setstatus(this);
2303
2304         return true;
2305 }
2306
2307 .bool would_spectate;
2308 // merged SpectatorThink and ObserverThink (old names are here so you can grep for them)
2309 void ObserverOrSpectatorThink(entity this)
2310 {
2311         bool is_spec = IS_SPEC(this);
2312         if ( CS(this).impulse )
2313         {
2314                 int r = MinigameImpulse(this, CS(this).impulse);
2315                 if (!is_spec || r)
2316                         CS(this).impulse = 0;
2317
2318                 if (is_spec && CS(this).impulse == IMP_weapon_drop.impulse)
2319                 {
2320                         STAT(CAMERA_SPECTATOR, this) = (STAT(CAMERA_SPECTATOR, this) + 1) % 3;
2321                         CS(this).impulse = 0;
2322                         return;
2323                 }
2324         }
2325
2326         if (this.flags & FL_JUMPRELEASED) {
2327                 if (PHYS_INPUT_BUTTON_JUMP(this) && (joinAllowed(this) || time < CS(this).jointime + MIN_SPEC_TIME)) {
2328                         this.flags &= ~FL_JUMPRELEASED;
2329                         this.flags |= FL_SPAWNING;
2330                 } else if((is_spec && (PHYS_INPUT_BUTTON_ATCK(this) || CS(this).impulse == 10 || CS(this).impulse == 15 || CS(this).impulse == 18 || (CS(this).impulse >= 200 && CS(this).impulse <= 209)))
2331                         || (!is_spec && ((PHYS_INPUT_BUTTON_ATCK(this) && !CS(this).version_mismatch) || this.would_spectate))) {
2332                         this.flags &= ~FL_JUMPRELEASED;
2333                         if(SpectateNext(this)) {
2334                                 TRANSMUTE(Spectator, this);
2335                         } else if (is_spec) {
2336                                 TRANSMUTE(Observer, this);
2337                                 PutClientInServer(this);
2338                         }
2339                         else
2340                                 this.would_spectate = false; // unable to spectate anyone
2341                         if (is_spec)
2342                                 CS(this).impulse = 0;
2343                 } else if (is_spec) {
2344                         if(CS(this).impulse == 12 || CS(this).impulse == 16  || CS(this).impulse == 19 || (CS(this).impulse >= 220 && CS(this).impulse <= 229)) {
2345                                 this.flags &= ~FL_JUMPRELEASED;
2346                                 if(SpectatePrev(this)) {
2347                                         TRANSMUTE(Spectator, this);
2348                                 } else {
2349                                         TRANSMUTE(Observer, this);
2350                                         PutClientInServer(this);
2351                                 }
2352                                 CS(this).impulse = 0;
2353                         } else if(PHYS_INPUT_BUTTON_ATCK2(this)) {
2354                                 this.would_spectate = false;
2355                                 this.flags &= ~FL_JUMPRELEASED;
2356                                 TRANSMUTE(Observer, this);
2357                                 PutClientInServer(this);
2358                         } else if(!SpectateUpdate(this) && !SpectateNext(this)) {
2359                                 PutObserverInServer(this);
2360                                 this.would_spectate = true;
2361                         }
2362                 }
2363                 else {
2364                         bool wouldclip = CS_CVAR(this).cvar_cl_clippedspectating;
2365                         if (PHYS_INPUT_BUTTON_USE(this))
2366                                 wouldclip = !wouldclip;
2367                         int preferred_movetype = (wouldclip ? MOVETYPE_FLY_WORLDONLY : MOVETYPE_NOCLIP);
2368                         set_movetype(this, preferred_movetype);
2369                 }
2370         } else { // jump pressed
2371                 if ((is_spec && !(PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_ATCK2(this)))
2372                         || (!is_spec && !(PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_JUMP(this)))) {
2373                         this.flags |= FL_JUMPRELEASED;
2374                         if(this.flags & FL_SPAWNING)
2375                         {
2376                                 this.flags &= ~FL_SPAWNING;
2377                                 if(joinAllowed(this))
2378                                         Join(this);
2379                                 else if(time < CS(this).jointime + MIN_SPEC_TIME)
2380                                         CS(this).autojoin_checked = -1;
2381                                 return;
2382                         }
2383                 }
2384                 if(is_spec && !SpectateUpdate(this))
2385                         PutObserverInServer(this);
2386         }
2387         if (is_spec)
2388                 this.flags |= FL_CLIENT | FL_NOTARGET;
2389 }
2390
2391 void PlayerUseKey(entity this)
2392 {
2393         if (!IS_PLAYER(this))
2394                 return;
2395
2396         if(this.vehicle)
2397         {
2398                 if(!game_stopped)
2399                 {
2400                         vehicles_exit(this.vehicle, VHEF_NORMAL);
2401                         return;
2402                 }
2403         }
2404         else if(autocvar_g_vehicles_enter)
2405         {
2406                 if(!game_stopped && !STAT(FROZEN, this) && !IS_DEAD(this) && !IS_INDEPENDENT_PLAYER(this))
2407                 {
2408                         entity head, closest_target = NULL;
2409                         head = WarpZone_FindRadius(this.origin, autocvar_g_vehicles_enter_radius, true);
2410
2411                         while(head) // find the closest acceptable target to enter
2412                         {
2413                                 if(IS_VEHICLE(head) && !IS_DEAD(head) && head.takedamage != DAMAGE_NO)
2414                                 if(!head.owner || ((head.vehicle_flags & VHF_MULTISLOT) && SAME_TEAM(head.owner, this)))
2415                                 {
2416                                         if(closest_target)
2417                                         {
2418                                                 if(vlen2(this.origin - head.origin) < vlen2(this.origin - closest_target.origin))
2419                                                 { closest_target = head; }
2420                                         }
2421                                         else { closest_target = head; }
2422                                 }
2423
2424                                 head = head.chain;
2425                         }
2426
2427                         if(closest_target) { vehicles_enter(this, closest_target); return; }
2428                 }
2429         }
2430
2431         // a use key was pressed; call handlers
2432         MUTATOR_CALLHOOK(PlayerUseKey, this);
2433 }
2434
2435
2436 /*
2437 =============
2438 PlayerPreThink
2439
2440 Called every frame for each client before the physics are run
2441 =============
2442 */
2443 .float last_vehiclecheck;
2444 void PlayerPreThink (entity this)
2445 {
2446         STAT(GUNALIGN, this) = CS_CVAR(this).cvar_cl_gunalign; // TODO
2447         STAT(MOVEVARS_CL_TRACK_CANJUMP, this) = CS_CVAR(this).cvar_cl_movement_track_canjump;
2448
2449         WarpZone_PlayerPhysics_FixVAngle(this);
2450
2451         if (frametime) {
2452                 // physics frames: update anticheat stuff
2453                 anticheat_prethink(this);
2454
2455                 // WORKAROUND: only use dropclient in server frames (frametime set).
2456                 // Never use it in cl_movement frames (frametime zero).
2457                 if (blockSpectators && IS_REAL_CLIENT(this)
2458                         && (IS_SPEC(this) || IS_OBSERVER(this)) && !this.caplayer
2459                         && time > (CS(this).spectatortime + autocvar_g_maxplayers_spectator_blocktime))
2460                 {
2461                         if (dropclient_schedule(this))
2462                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_QUIT_KICK_SPECTATING);
2463                 }
2464         }
2465
2466         zoomstate_set = false;
2467
2468         // Check for nameless players
2469         if (this.netname == "" || this.netname != CS(this).netname_previous)
2470         {
2471                 bool assume_unchanged = (CS(this).netname_previous == "");
2472                 if (autocvar_sv_name_maxlength > 0 && strlennocol(this.netname) > autocvar_sv_name_maxlength)
2473                 {
2474                         int new_length = textLengthUpToLength(this.netname, autocvar_sv_name_maxlength, strlennocol);
2475                         this.netname = strzone(strcat(substring(this.netname, 0, new_length), "^7"));
2476                         sprint(this, sprintf("Warning: your name is longer than %d characters, it has been truncated.\n", autocvar_sv_name_maxlength));
2477                         assume_unchanged = false;
2478                         // stuffcmd(this, strcat("name ", this.netname, "\n")); // maybe?
2479                 }
2480                 if (isInvisibleString(this.netname))
2481                 {
2482                         this.netname = strzone(sprintf("Player#%d", this.playerid));
2483                         sprint(this, "Warning: invisible names are not allowed.\n");
2484                         assume_unchanged = false;
2485                         // stuffcmd(this, strcat("name ", this.netname, "\n")); // maybe?
2486                 }
2487                 if (!assume_unchanged && autocvar_sv_eventlog)
2488                         GameLogEcho(strcat(":name:", ftos(this.playerid), ":", playername(this.netname, this.team, false)));
2489                 strcpy(CS(this).netname_previous, this.netname);
2490         }
2491
2492         // version nagging
2493         if (CS(this).version_nagtime && CS_CVAR(this).cvar_g_xonoticversion && time > CS(this).version_nagtime) {
2494         CS(this).version_nagtime = 0;
2495         if (strstrofs(CS_CVAR(this).cvar_g_xonoticversion, "git", 0) >= 0 || strstrofs(CS_CVAR(this).cvar_g_xonoticversion, "autobuild", 0) >= 0) {
2496             // git client
2497         } else if (strstrofs(autocvar_g_xonoticversion, "git", 0) >= 0 || strstrofs(autocvar_g_xonoticversion, "autobuild", 0) >= 0) {
2498             // git server
2499             Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_BETA, autocvar_g_xonoticversion, CS_CVAR(this).cvar_g_xonoticversion);
2500         } else {
2501             int r = vercmp(CS_CVAR(this).cvar_g_xonoticversion, autocvar_g_xonoticversion);
2502             if (r < 0) { // old client
2503                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_OUTDATED, autocvar_g_xonoticversion, CS_CVAR(this).cvar_g_xonoticversion);
2504             } else if (r > 0) { // old server
2505                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_OLD, autocvar_g_xonoticversion, CS_CVAR(this).cvar_g_xonoticversion);
2506             }
2507         }
2508     }
2509
2510         // GOD MODE info
2511         if (!(this.flags & FL_GODMODE) && this.max_armorvalue)
2512         {
2513                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_GODMODE_OFF, this.max_armorvalue);
2514                 this.max_armorvalue = 0;
2515         }
2516
2517         if (frametime && IS_PLAYER(this) && time >= game_starttime)
2518         {
2519                 if (STAT(FROZEN, this) == FROZEN_TEMP_REVIVING)
2520                 {
2521                         STAT(REVIVE_PROGRESS, this) = bound(0, STAT(REVIVE_PROGRESS, this) + frametime * this.revive_speed, 1);
2522                         SetResourceExplicit(this, RES_HEALTH, max(1, STAT(REVIVE_PROGRESS, this) * start_health));
2523                         if (this.iceblock)
2524                                 this.iceblock.alpha = bound(0.2, 1 - STAT(REVIVE_PROGRESS, this), 1);
2525
2526                         if (STAT(REVIVE_PROGRESS, this) >= 1)
2527                                 Unfreeze(this, false);
2528                 }
2529                 else if (STAT(FROZEN, this) == FROZEN_TEMP_DYING)
2530                 {
2531                         STAT(REVIVE_PROGRESS, this) = bound(0, STAT(REVIVE_PROGRESS, this) - frametime * this.revive_speed, 1);
2532                         SetResourceExplicit(this, RES_HEALTH, max(0, autocvar_g_nades_ice_health + (start_health-autocvar_g_nades_ice_health) * STAT(REVIVE_PROGRESS, this)));
2533
2534                         if (GetResource(this, RES_HEALTH) < 1)
2535                         {
2536                                 if (this.vehicle)
2537                                         vehicles_exit(this.vehicle, VHEF_RELEASE);
2538                                 if(this.event_damage)
2539                                         this.event_damage(this, this, this.frozen_by, 1, DEATH_NADE_ICE_FREEZE.m_id, DMG_NOWEP, this.origin, '0 0 0');
2540                         }
2541                         else if (STAT(REVIVE_PROGRESS, this) <= 0)
2542                                 Unfreeze(this, false);
2543                 }
2544         }
2545
2546         MUTATOR_CALLHOOK(PlayerPreThink, this);
2547
2548         if(autocvar_g_vehicles_enter && (time > this.last_vehiclecheck) && !game_stopped && !this.vehicle)
2549         if(IS_PLAYER(this) && !STAT(FROZEN, this) && !IS_DEAD(this) && !IS_INDEPENDENT_PLAYER(this))
2550         {
2551                 FOREACH_ENTITY_RADIUS(this.origin, autocvar_g_vehicles_enter_radius, IS_VEHICLE(it) && !IS_DEAD(it) && it.takedamage != DAMAGE_NO,
2552                 {
2553                         if(!it.owner)
2554                         {
2555                                 if(!it.team || SAME_TEAM(this, it))
2556                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER);
2557                                 else if(autocvar_g_vehicles_steal)
2558                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER_STEAL);
2559                         }
2560                         else if((it.vehicle_flags & VHF_MULTISLOT) && SAME_TEAM(it.owner, this))
2561                         {
2562                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER_GUNNER);
2563                         }
2564                 });
2565
2566                 this.last_vehiclecheck = time + 1;
2567         }
2568
2569         if(!CS_CVAR(this).cvar_cl_newusekeysupported) // FIXME remove this - it was a stupid idea to begin with, we can JUST use the button
2570         {
2571                 if(PHYS_INPUT_BUTTON_USE(this) && !CS(this).usekeypressed)
2572                         PlayerUseKey(this);
2573                 CS(this).usekeypressed = PHYS_INPUT_BUTTON_USE(this);
2574         }
2575
2576         if (IS_REAL_CLIENT(this))
2577                 PrintWelcomeMessage(this);
2578
2579         if (IS_PLAYER(this)) {
2580                 if (IS_REAL_CLIENT(this) && time < CS(this).jointime + MIN_SPEC_TIME)
2581                         error("Client can't be spawned as player on connection!");
2582                 if(!PlayerThink(this))
2583                         return;
2584         }
2585         else if (game_stopped || intermission_running) {
2586                 if(intermission_running)
2587                         IntermissionThink(this);
2588                 return;
2589         }
2590         else if (IS_REAL_CLIENT(this) && CS(this).autojoin_checked <= 0 && time >= CS(this).jointime + MIN_SPEC_TIME)
2591         {
2592                 bool early_join_requested = (CS(this).autojoin_checked < 0);
2593                 CS(this).autojoin_checked = 1;
2594                 // don't do this in ClientConnect
2595                 // many things can go wrong if a client is spawned as player on connection
2596                 if (early_join_requested || MUTATOR_CALLHOOK(AutoJoinOnConnection, this)
2597                         || (!(autocvar_sv_spectate || autocvar_g_campaign || (Player_GetForcedTeamIndex(this) == TEAM_FORCE_SPECTATOR))
2598                                 && (!teamplay || autocvar_g_balance_teams)))
2599                 {
2600                         campaign_bots_may_start = true;
2601                         if(joinAllowed(this))
2602                                 Join(this);
2603                         return;
2604                 }
2605         }
2606         else if (IS_OBSERVER(this) || IS_SPEC(this)) {
2607                 ObserverOrSpectatorThink(this);
2608         }
2609
2610         // WEAPONTODO: Add weapon request for this
2611         if (!zoomstate_set) {
2612                 bool wep_zoomed = false;
2613                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2614                 {
2615                         .entity weaponentity = weaponentities[slot];
2616                         Weapon thiswep = this.(weaponentity).m_weapon;
2617                         if(thiswep != WEP_Null && thiswep.wr_zoom)
2618                                 wep_zoomed += thiswep.wr_zoom(thiswep, this);
2619                 }
2620                 SetZoomState(this, PHYS_INPUT_BUTTON_ZOOM(this) || PHYS_INPUT_BUTTON_ZOOMSCRIPT(this) || wep_zoomed);
2621         }
2622
2623         if (CS(this).teamkill_soundtime && time > CS(this).teamkill_soundtime)
2624         {
2625                 CS(this).teamkill_soundtime = 0;
2626
2627                 entity e = CS(this).teamkill_soundsource;
2628                 entity oldpusher = e.pusher;
2629                 e.pusher = this;
2630                 PlayerSound(e, playersound_teamshoot, CH_VOICE, VOL_BASEVOICE, VOICETYPE_LASTATTACKER_ONLY);
2631                 e.pusher = oldpusher;
2632         }
2633
2634         if (CS(this).taunt_soundtime && time > CS(this).taunt_soundtime) {
2635                 CS(this).taunt_soundtime = 0;
2636                 PlayerSound(this, playersound_taunt, CH_VOICE, VOL_BASEVOICE, VOICETYPE_AUTOTAUNT);
2637         }
2638
2639         target_voicescript_next(this);
2640 }
2641
2642 void DrownPlayer(entity this)
2643 {
2644         if(IS_DEAD(this) || game_stopped || time < game_starttime || this.vehicle
2645                 || STAT(FROZEN, this) || this.watertype != CONTENT_WATER)
2646         {
2647                 STAT(AIR_FINISHED, this) = 0;
2648                 return;
2649         }
2650
2651         if (this.waterlevel != WATERLEVEL_SUBMERGED)
2652         {
2653                 if(STAT(AIR_FINISHED, this) && STAT(AIR_FINISHED, this) < time)
2654                         PlayerSound(this, playersound_gasp, CH_PLAYER, VOL_BASE, VOICETYPE_PLAYERSOUND);
2655                 STAT(AIR_FINISHED, this) = 0;
2656         }
2657         else
2658         {
2659                 if (!STAT(AIR_FINISHED, this))
2660                         STAT(AIR_FINISHED, this) = time + autocvar_g_balance_contents_drowndelay;
2661                 if (STAT(AIR_FINISHED, this) < time)
2662                 {       // drown!
2663                         if (this.pain_finished < time)
2664                         {
2665                                 Damage (this, NULL, NULL, autocvar_g_balance_contents_playerdamage_drowning * autocvar_g_balance_contents_damagerate, DEATH_DROWN.m_id, DMG_NOWEP, this.origin, '0 0 0');
2666                                 this.pain_finished = time + 0.5;
2667                         }
2668                 }
2669         }
2670 }
2671
2672 .bool move_qcphysics;
2673
2674 void Player_Physics(entity this)
2675 {
2676         this.movetype = (this.move_qcphysics) ? MOVETYPE_QCPLAYER : this.move_movetype;
2677
2678         if(!this.move_qcphysics)
2679                 return;
2680
2681         if(!frametime && !CS(this).pm_frametime)
2682                 return;
2683
2684         Movetype_Physics_NoMatchTicrate(this, CS(this).pm_frametime, true);
2685
2686         CS(this).pm_frametime = 0;
2687 }
2688
2689 /*
2690 =============
2691 PlayerPostThink
2692
2693 Called every frame for each client after the physics are run
2694 =============
2695 */
2696 void PlayerPostThink (entity this)
2697 {
2698         Player_Physics(this);
2699
2700         if (autocvar_sv_maxidle > 0 || (IS_PLAYER(this) && autocvar_sv_maxidle_playertospectator > 0))
2701         if (frametime) // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2702         if (IS_REAL_CLIENT(this))
2703         if (IS_PLAYER(this) || autocvar_sv_maxidle_alsokickspectators)
2704         if (!intermission_running) // NextLevel() kills all centerprints after setting this true
2705         {
2706                 int totalClients = 0;
2707                 if(autocvar_sv_maxidle > 0 && autocvar_sv_maxidle_slots > 0)
2708                 {
2709                         FOREACH_CLIENT(IS_REAL_CLIENT(it) || autocvar_sv_maxidle_slots_countbots,
2710                         {
2711                                 ++totalClients;
2712                         });
2713                 }
2714
2715                 if (autocvar_sv_maxidle > 0 && autocvar_sv_maxidle_slots > 0 && (maxclients - totalClients) > autocvar_sv_maxidle_slots)
2716                 { /* do nothing */ }
2717                 else if (time - CS(this).parm_idlesince < 1) // instead of (time == this.parm_idlesince) to support sv_maxidle <= 10
2718                 {
2719                         if (CS(this).idlekick_lasttimeleft)
2720                         {
2721                                 CS(this).idlekick_lasttimeleft = 0;
2722                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_IDLING);
2723                         }
2724                 }
2725                 else
2726                 {
2727                         float maxidle_time = autocvar_sv_maxidle;
2728                         if (IS_PLAYER(this) && autocvar_sv_maxidle_playertospectator > 0)
2729                                 maxidle_time = autocvar_sv_maxidle_playertospectator;
2730                         float timeleft = ceil(maxidle_time - (time - CS(this).parm_idlesince));
2731                         float countdown_time = max(min(10, maxidle_time - 1), ceil(maxidle_time * 0.33)); // - 1 to support maxidle_time <= 10
2732                         if (timeleft == countdown_time && !CS(this).idlekick_lasttimeleft)
2733                         {
2734                                 if (IS_PLAYER(this) && autocvar_sv_maxidle_playertospectator > 0)
2735                                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOVETOSPEC_IDLING, timeleft);
2736                                 else
2737                                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_DISCONNECT_IDLING, timeleft);
2738                         }
2739                         if (timeleft <= 0) {
2740                                 if (IS_PLAYER(this) && autocvar_sv_maxidle_playertospectator > 0)
2741                                 {
2742                                         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_MOVETOSPEC_IDLING, this.netname, maxidle_time);
2743                                         if (this.caplayer)
2744                                                 this.caplayer = 0;
2745                                         PutObserverInServer(this);
2746                                 }
2747                                 else
2748                                 {
2749                                         if (dropclient_schedule(this))
2750                                                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_QUIT_KICK_IDLING, this.netname, maxidle_time);
2751                                 }
2752                                 return;
2753                         }
2754                         else if (timeleft <= countdown_time) {
2755                                 if (timeleft != CS(this).idlekick_lasttimeleft)
2756                                         play2(this, SND(TALK2));
2757                                 CS(this).idlekick_lasttimeleft = timeleft;
2758                         }
2759                 }
2760         }
2761
2762         CheatFrame(this);
2763
2764         if (game_stopped)
2765         {
2766                 this.solid = SOLID_NOT;
2767                 this.takedamage = DAMAGE_NO;
2768                 set_movetype(this, MOVETYPE_NONE);
2769                 CS(this).teamkill_complain = 0;
2770                 CS(this).teamkill_soundtime = 0;
2771                 CS(this).teamkill_soundsource = NULL;
2772         }
2773
2774         if (IS_PLAYER(this)) {
2775                 if(this.death_time == time && IS_DEAD(this))
2776                 {
2777                         // player's bbox gets resized now, instead of in the damage event that killed the player,
2778                         // once all the damage events of this frame have been processed with normal size
2779                         this.maxs.z = 5;
2780                         setsize(this, this.mins, this.maxs);
2781                 }
2782                 DrownPlayer(this);
2783                 UpdateChatBubble(this);
2784                 if (CS(this).impulse) ImpulseCommands(this);
2785                 GetPressedKeys(this);
2786                 if (game_stopped)
2787                 {
2788                         CSQCMODEL_AUTOUPDATE(this);
2789                         return;
2790                 }
2791         }
2792         else if (IS_OBSERVER(this) && STAT(PRESSED_KEYS, this))
2793         {
2794                 CS(this).pressedkeys = 0;
2795                 STAT(PRESSED_KEYS, this) = 0;
2796         }
2797
2798         if (this.waypointsprite_attachedforcarrier) {
2799                 float hp = healtharmor_maxdamage(GetResource(this, RES_HEALTH), GetResource(this, RES_ARMOR), autocvar_g_balance_armor_blockpercent, DEATH_WEAPON.m_id).x;
2800                 WaypointSprite_UpdateHealth(this.waypointsprite_attachedforcarrier, hp);
2801         }
2802
2803         CSQCMODEL_AUTOUPDATE(this);
2804 }
2805
2806 // hack to copy the button fields from the client entity to the Client State
2807 void PM_UpdateButtons(entity this, entity store)
2808 {
2809         if(this.impulse)
2810                 store.impulse = this.impulse;
2811         this.impulse = 0;
2812
2813         bool typing = this.buttonchat || this.button12;
2814
2815         store.button0 = (typing) ? 0 : this.button0;
2816         //button1?!
2817         store.button2 = (typing) ? 0 : this.button2;
2818         store.button3 = (typing) ? 0 : this.button3;
2819         store.button4 = this.button4;
2820         store.button5 = (typing) ? 0 : this.button5;
2821         store.button6 = this.button6;
2822         store.button7 = this.button7;
2823         store.button8 = this.button8;
2824         store.button9 = this.button9;
2825         store.button10 = this.button10;
2826         store.button11 = this.button11;
2827         store.button12 = this.button12;
2828         store.button13 = this.button13;
2829         store.button14 = this.button14;
2830         store.button15 = this.button15;
2831         store.button16 = this.button16;
2832         store.buttonuse = this.buttonuse;
2833         store.buttonchat = this.buttonchat;
2834
2835         store.cursor_active = this.cursor_active;
2836         store.cursor_screen = this.cursor_screen;
2837         store.cursor_trace_start = this.cursor_trace_start;
2838         store.cursor_trace_endpos = this.cursor_trace_endpos;
2839         store.cursor_trace_ent = this.cursor_trace_ent;
2840
2841         store.ping = this.ping;
2842         store.ping_packetloss = this.ping_packetloss;
2843         store.ping_movementloss = this.ping_movementloss;
2844
2845         store.v_angle = this.v_angle;
2846         store.movement = this.movement;
2847 }
2848
2849 NET_HANDLE(fpsreport, bool)
2850 {
2851         int fps = ReadShort();
2852         PlayerScore_Set(sender, SP_FPS, fps);
2853         return true;
2854 }