Accuracy stats: also count damage dealt by projectiles hitting the enemy after the...
[xonotic/xonotic-data.pk3dir.git] / qcsrc / server / client.qc
1 #include "client.qh"
2
3 #include "anticheat.qh"
4 #include "impulse.qh"
5 #include "player.qh"
6 #include "ipban.qh"
7 #include "miscfunctions.qh"
8 #include "portals.qh"
9 #include "teamplay.qh"
10 #include "playerdemo.qh"
11 #include "spawnpoints.qh"
12 #include "g_damage.qh"
13 #include "g_hook.qh"
14 #include "command/common.qh"
15 #include "cheats.qh"
16 #include "g_world.qh"
17 #include "race.qh"
18 #include "antilag.qh"
19 #include "campaign.qh"
20 #include "command/common.qh"
21 #include "scores_rules.qh"
22
23 #include "bot/api.qh"
24
25 #include "../common/ent_cs.qh"
26 #include "../common/wepent.qh"
27 #include <common/state.qh>
28
29 #include <common/effects/qc/globalsound.qh>
30
31 #include "../common/triggers/func/conveyor.qh"
32 #include "../common/triggers/teleporters.qh"
33
34 #include "../common/vehicles/all.qh"
35
36 #include "weapons/hitplot.qh"
37 #include "weapons/weaponsystem.qh"
38
39 #include "../common/net_notice.qh"
40 #include "../common/net_linked.qh"
41 #include "../common/physics/player.qh"
42
43 #include "../common/items/_mod.qh"
44
45 #include "../common/mutators/mutator/waypoints/all.qh"
46
47 #include "../common/triggers/subs.qh"
48 #include "../common/triggers/triggers.qh"
49 #include "../common/triggers/trigger/secret.qh"
50
51 #include "../common/minigames/sv_minigames.qh"
52
53 #include "../common/items/inventory.qh"
54
55 #include "../common/monsters/sv_monsters.qh"
56
57 #include "../lib/warpzone/server.qh"
58
59 STATIC_METHOD(Client, Add, void(Client this, int _team))
60 {
61     ClientConnect(this);
62     TRANSMUTE(Player, this);
63     this.frame = 12; // 7
64     this.team = _team;
65     PutClientInServer(this);
66 }
67
68 void PutObserverInServer(entity this);
69
70 STATIC_METHOD(Client, Remove, void(Client this))
71 {
72     TRANSMUTE(Observer, this);
73     PutClientInServer(this);
74     ClientDisconnect(this);
75 }
76
77 void send_CSQC_teamnagger() {
78         WriteHeader(MSG_BROADCAST, TE_CSQC_TEAMNAGGER);
79 }
80
81 int CountSpectators(entity player, entity to)
82 {
83         if(!player) { return 0; } // not sure how, but best to be safe
84
85         int spec_count = 0;
86
87         FOREACH_CLIENT(IS_REAL_CLIENT(it) && IS_SPEC(it) && it != to && it.enemy == player,
88         {
89                 spec_count++;
90         });
91
92         return spec_count;
93 }
94
95 void WriteSpectators(entity player, entity to)
96 {
97         if(!player) { return; } // not sure how, but best to be safe
98
99         FOREACH_CLIENT(IS_REAL_CLIENT(it) && IS_SPEC(it) && it != to && it.enemy == player,
100         {
101                 WriteByte(MSG_ENTITY, num_for_edict(it));
102         });
103 }
104
105 bool ClientData_Send(entity this, entity to, int sf)
106 {
107         assert(to == this.owner, return false);
108
109         entity e = to;
110         if (IS_SPEC(e)) e = e.enemy;
111
112         sf = 0;
113         if (e.race_completed)       sf |= 1; // forced scoreboard
114         if (to.spectatee_status)    sf |= 2; // spectator ent number follows
115         if (e.zoomstate)            sf |= 4; // zoomed
116         if (autocvar_sv_showspectators) sf |= 16; // show spectators
117
118         WriteHeader(MSG_ENTITY, ENT_CLIENT_CLIENTDATA);
119         WriteByte(MSG_ENTITY, sf);
120
121         if (sf & 2)
122         {
123                 WriteByte(MSG_ENTITY, to.spectatee_status);
124         }
125
126         if(sf & 16)
127         {
128                 float specs = CountSpectators(e, to);
129                 WriteByte(MSG_ENTITY, specs);
130                 WriteSpectators(e, to);
131         }
132
133         return true;
134 }
135
136 void ClientData_Attach(entity this)
137 {
138         Net_LinkEntity(this.clientdata = new_pure(clientdata), false, 0, ClientData_Send);
139         this.clientdata.drawonlytoclient = this;
140         this.clientdata.owner = this;
141 }
142
143 void ClientData_Detach(entity this)
144 {
145         delete(this.clientdata);
146         this.clientdata = NULL;
147 }
148
149 void ClientData_Touch(entity e)
150 {
151         e.clientdata.SendFlags = 1;
152
153         // make it spectatable
154         FOREACH_CLIENT(IS_REAL_CLIENT(it) && it != e && IS_SPEC(it) && it.enemy == e, LAMBDA(it.clientdata.SendFlags = 1));
155 }
156
157 .string netname_previous;
158
159 void SetSpectatee(entity this, entity spectatee);
160 void SetSpectatee_status(entity this, int spectatee_num);
161
162
163 /*
164 =============
165 CheckPlayerModel
166
167 Checks if the argument string can be a valid playermodel.
168 Returns a valid one in doubt.
169 =============
170 */
171 string FallbackPlayerModel;
172 string CheckPlayerModel(string plyermodel) {
173         if(FallbackPlayerModel != cvar_defstring("_cl_playermodel"))
174         {
175                 // note: we cannot summon Don Strunzone here, some player may
176                 // still have the model string set. In case anyone manages how
177                 // to change a cvar default, we'll have a small leak here.
178                 FallbackPlayerModel = strzone(cvar_defstring("_cl_playermodel"));
179         }
180         // only in right path
181         if( substring(plyermodel,0,14) != "models/player/")
182                 return FallbackPlayerModel;
183         // only good file extensions
184         if(substring(plyermodel,-4,4) != ".zym")
185         if(substring(plyermodel,-4,4) != ".dpm")
186         if(substring(plyermodel,-4,4) != ".iqm")
187         if(substring(plyermodel,-4,4) != ".md3")
188         if(substring(plyermodel,-4,4) != ".psk")
189                 return FallbackPlayerModel;
190         // forbid the LOD models
191         if(substring(plyermodel, -9,5) == "_lod1")
192                 return FallbackPlayerModel;
193         if(substring(plyermodel, -9,5) == "_lod2")
194                 return FallbackPlayerModel;
195         if(plyermodel != strtolower(plyermodel))
196                 return FallbackPlayerModel;
197         // also, restrict to server models
198         if(autocvar_sv_servermodelsonly)
199         {
200                 if(!fexists(plyermodel))
201                         return FallbackPlayerModel;
202         }
203         return plyermodel;
204 }
205
206 void setplayermodel(entity e, string modelname)
207 {
208         precache_model(modelname);
209         _setmodel(e, modelname);
210         player_setupanimsformodel(e);
211         if(!autocvar_g_debug_globalsounds)
212                 UpdatePlayerSounds(e);
213 }
214
215 void FixPlayermodel(entity player);
216 /** putting a client as observer in the server */
217 void PutObserverInServer(entity this)
218 {
219     bool mutator_returnvalue = MUTATOR_CALLHOOK(MakePlayerObserver, this);
220         PlayerState_detach(this);
221
222         if (IS_PLAYER(this) && this.health >= 1) {
223         // despawn effect
224                 Send_Effect(EFFECT_SPAWN_NEUTRAL, this.origin, '0 0 0', 1);
225     }
226
227     {
228         entity spot = SelectSpawnPoint(this, true);
229         if (!spot) LOG_FATAL("No spawnpoints for observers?!?");
230         this.angles = spot.angles;
231         this.angles_z = 0;
232         this.fixangle = true;
233         // offset it so that the spectator spawns higher off the ground, looks better this way
234         setorigin(this, spot.origin + STAT(PL_VIEW_OFS, this));
235         this.prevorigin = this.origin;
236         if (IS_REAL_CLIENT(this))
237         {
238             msg_entity = this;
239             WriteByte(MSG_ONE, SVC_SETVIEW);
240             WriteEntity(MSG_ONE, this);
241         }
242         // give the spectator some space between walls for MOVETYPE_FLY_WORLDONLY
243         // so that your view doesn't go into the ceiling with MOVETYPE_FLY_WORLDONLY, previously "PL_VIEW_OFS"
244         if(!autocvar_g_debug_globalsounds)
245         {
246                 // needed for player sounds
247                 this.model = "";
248                 FixPlayermodel(this);
249         }
250         setmodel(this, MDL_Null);
251         setsize(this, STAT(PL_CROUCH_MIN, this), STAT(PL_CROUCH_MAX, this));
252         this.view_ofs = '0 0 0';
253     }
254
255     RemoveGrapplingHooks(this);
256         Portal_ClearAll(this);
257         Unfreeze(this);
258         SetSpectatee(this, NULL);
259
260         if (this.alivetime)
261         {
262                 if (!warmup_stage)
263                         PS_GR_P_ADDVAL(this, PLAYERSTATS_ALIVETIME, time - this.alivetime);
264                 this.alivetime = 0;
265         }
266
267         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
268
269         WaypointSprite_PlayerDead(this);
270
271         if (mutator_returnvalue) {
272             // mutator prevents resetting teams+score
273         } else {
274                 this.team = -1;  // move this as it is needed to log the player spectating in eventlog
275         this.frags = FRAGS_SPECTATOR;
276         PlayerScore_Clear(this);  // clear scores when needed
277     }
278
279         if (this.killcount != FRAGS_SPECTATOR)
280         {
281                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_QUIT_SPECTATE, this.netname);
282                 if(!game_stopped)
283                 if(autocvar_g_chat_nospectators == 1 || (!warmup_stage && autocvar_g_chat_nospectators == 2))
284                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_CHAT_NOSPECTATORS);
285
286                 if(this.just_joined == false) {
287                         LogTeamchange(this.playerid, -1, 4);
288                 } else
289                         this.just_joined = false;
290         }
291
292         accuracy_resend(this);
293
294         this.spectatortime = time;
295         if(this.bot_attack)
296                 IL_REMOVE(g_bot_targets, this);
297         this.bot_attack = false;
298     this.hud = HUD_NORMAL;
299         TRANSMUTE(Observer, this);
300         this.iscreature = false;
301         this.teleportable = TELEPORT_SIMPLE;
302         if(this.damagedbycontents)
303                 IL_REMOVE(g_damagedbycontents, this);
304         this.damagedbycontents = false;
305         this.health = FRAGS_SPECTATOR;
306         SetSpectatee_status(this, etof(this));
307         this.takedamage = DAMAGE_NO;
308         this.solid = SOLID_NOT;
309         set_movetype(this, MOVETYPE_FLY_WORLDONLY); // user preference is controlled by playerprethink
310         this.flags = FL_CLIENT | FL_NOTARGET;
311         this.armorvalue = 666;
312         this.effects = 0;
313         this.armorvalue = autocvar_g_balance_armor_start;
314         this.pauserotarmor_finished = 0;
315         this.pauserothealth_finished = 0;
316         this.pauseregen_finished = 0;
317         this.damageforcescale = 0;
318         this.death_time = 0;
319         this.respawn_flags = 0;
320         this.respawn_time = 0;
321         this.stat_respawn_time = 0;
322         this.alpha = 0;
323         this.scale = 0;
324         this.fade_time = 0;
325         this.pain_frame = 0;
326         this.pain_finished = 0;
327         this.strength_finished = 0;
328         this.invincible_finished = 0;
329         this.superweapons_finished = 0;
330         this.pushltime = 0;
331         this.istypefrag = 0;
332         setthink(this, func_null);
333         this.nextthink = 0;
334         this.deadflag = DEAD_NO;
335         this.crouch = false;
336         this.revive_progress = 0;
337         this.revival_time = 0;
338
339         this.items = 0;
340         this.weapons = '0 0 0';
341         this.dual_weapons = '0 0 0';
342         this.drawonlytoclient = this;
343
344         this.weaponmodel = "";
345         for (int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
346         {
347                 this.weaponentities[slot] = NULL;
348         }
349         this.exteriorweaponentity = NULL;
350         this.killcount = FRAGS_SPECTATOR;
351         this.velocity = '0 0 0';
352         this.avelocity = '0 0 0';
353         this.punchangle = '0 0 0';
354         this.punchvector = '0 0 0';
355         this.oldvelocity = this.velocity;
356         this.fire_endtime = -1;
357         this.event_damage = func_null;
358
359         for(int slot = 0; slot < MAX_AXH; ++slot)
360         {
361                 entity axh = this.(AuxiliaryXhair[slot]);
362                 this.(AuxiliaryXhair[slot]) = NULL;
363
364                 if(axh.owner == this && axh != NULL && !wasfreed(axh))
365                         delete(axh);
366         }
367 }
368
369 int player_getspecies(entity this)
370 {
371         get_model_parameters(this.model, this.skin);
372         int s = get_model_parameters_species;
373         get_model_parameters(string_null, 0);
374         if (s < 0) return SPECIES_HUMAN;
375         return s;
376 }
377
378 .float model_randomizer;
379 void FixPlayermodel(entity player)
380 {
381         string defaultmodel = "";
382         int defaultskin = 0;
383         if(autocvar_sv_defaultcharacter)
384         {
385                 if(teamplay)
386                 {
387                         switch(player.team)
388                         {
389                                 case NUM_TEAM_1: defaultmodel = autocvar_sv_defaultplayermodel_red; defaultskin = autocvar_sv_defaultplayerskin_red; break;
390                                 case NUM_TEAM_2: defaultmodel = autocvar_sv_defaultplayermodel_blue; defaultskin = autocvar_sv_defaultplayerskin_blue; break;
391                                 case NUM_TEAM_3: defaultmodel = autocvar_sv_defaultplayermodel_yellow; defaultskin = autocvar_sv_defaultplayerskin_yellow; break;
392                                 case NUM_TEAM_4: defaultmodel = autocvar_sv_defaultplayermodel_pink; defaultskin = autocvar_sv_defaultplayerskin_pink; break;
393                         }
394                 }
395
396                 if(defaultmodel == "")
397                 {
398                         defaultmodel = autocvar_sv_defaultplayermodel;
399                         defaultskin = autocvar_sv_defaultplayerskin;
400                 }
401
402                 int n = tokenize_console(defaultmodel);
403                 if(n > 0)
404                 {
405                         defaultmodel = argv(floor(n * player.model_randomizer));
406                         // However, do NOT randomize if the player-selected model is in the list.
407                         for (int i = 0; i < n; ++i)
408                                 if ((argv(i) == player.playermodel && defaultskin == stof(player.playerskin)) || argv(i) == strcat(player.playermodel, ":", player.playerskin))
409                                         defaultmodel = argv(i);
410                 }
411
412                 int i = strstrofs(defaultmodel, ":", 0);
413                 if(i >= 0)
414                 {
415                         defaultskin = stof(substring(defaultmodel, i+1, -1));
416                         defaultmodel = substring(defaultmodel, 0, i);
417                 }
418         }
419         if(autocvar_sv_defaultcharacterskin && !defaultskin)
420         {
421                 if(teamplay)
422                 {
423                         switch(player.team)
424                         {
425                                 case NUM_TEAM_1: defaultskin = autocvar_sv_defaultplayerskin_red; break;
426                                 case NUM_TEAM_2: defaultskin = autocvar_sv_defaultplayerskin_blue; break;
427                                 case NUM_TEAM_3: defaultskin = autocvar_sv_defaultplayerskin_yellow; break;
428                                 case NUM_TEAM_4: defaultskin = autocvar_sv_defaultplayerskin_pink; break;
429                         }
430                 }
431
432                 if(!defaultskin)
433                         defaultskin = autocvar_sv_defaultplayerskin;
434         }
435
436         MUTATOR_CALLHOOK(FixPlayermodel, defaultmodel, defaultskin, player);
437         defaultmodel = M_ARGV(0, string);
438         defaultskin = M_ARGV(1, int);
439
440         bool chmdl = false;
441         int oldskin;
442         if(defaultmodel != "")
443         {
444                 if (defaultmodel != player.model)
445                 {
446                         vector m1 = player.mins;
447                         vector m2 = player.maxs;
448                         setplayermodel (player, defaultmodel);
449                         setsize (player, m1, m2);
450                         chmdl = true;
451                 }
452
453                 oldskin = player.skin;
454                 player.skin = defaultskin;
455         } else {
456                 if (player.playermodel != player.model || player.playermodel == "")
457                 {
458                         player.playermodel = CheckPlayerModel(player.playermodel); // this is never "", so no endless loop
459                         vector m1 = player.mins;
460                         vector m2 = player.maxs;
461                         setplayermodel (player, player.playermodel);
462                         setsize (player, m1, m2);
463                         chmdl = true;
464                 }
465
466                 if(!autocvar_sv_defaultcharacterskin)
467                 {
468                         oldskin = player.skin;
469                         player.skin = stof(player.playerskin);
470                 }
471                 else
472                 {
473                         oldskin = player.skin;
474                         player.skin = defaultskin;
475                 }
476         }
477
478         if(chmdl || oldskin != player.skin) // model or skin has changed
479         {
480                 player.species = player_getspecies(player); // update species
481                 if(!autocvar_g_debug_globalsounds)
482                         UpdatePlayerSounds(player); // update skin sounds
483         }
484
485         if(!teamplay)
486                 if(strlen(autocvar_sv_defaultplayercolors))
487                         if(player.clientcolors != stof(autocvar_sv_defaultplayercolors))
488                                 setcolor(player, stof(autocvar_sv_defaultplayercolors));
489 }
490
491
492 /** Called when a client spawns in the server */
493 void PutClientInServer(entity this)
494 {
495         if (IS_BOT_CLIENT(this)) {
496                 TRANSMUTE(Player, this);
497         } else if (IS_REAL_CLIENT(this)) {
498                 msg_entity = this;
499                 WriteByte(MSG_ONE, SVC_SETVIEW);
500                 WriteEntity(MSG_ONE, this);
501         }
502         if (game_stopped)
503                 TRANSMUTE(Observer, this);
504
505         SetSpectatee(this, NULL);
506
507         // reset player keys
508         this.itemkeys = 0;
509
510         MUTATOR_CALLHOOK(PutClientInServer, this);
511
512         if (IS_OBSERVER(this)) {
513                 PutObserverInServer(this);
514         } else if (IS_PLAYER(this)) {
515                 if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
516
517                 PlayerState_attach(this);
518                 accuracy_resend(this);
519
520                 if (this.team < 0)
521                         JoinBestTeam(this, false, true);
522
523                 entity spot = SelectSpawnPoint(this, false);
524                 if (!spot) {
525                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_JOIN_NOSPAWNS);
526                         return; // spawn failed
527                 }
528
529                 TRANSMUTE(Player, this);
530
531                 this.wasplayer = true;
532                 this.iscreature = true;
533                 this.teleportable = TELEPORT_NORMAL;
534                 if(!this.damagedbycontents)
535                         IL_PUSH(g_damagedbycontents, this);
536                 this.damagedbycontents = true;
537                 set_movetype(this, MOVETYPE_WALK);
538                 this.solid = SOLID_SLIDEBOX;
539                 this.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_SOLID;
540                 if (autocvar_g_playerclip_collisions)
541                         this.dphitcontentsmask |= DPCONTENTS_PLAYERCLIP;
542                 if (IS_BOT_CLIENT(this) && autocvar_g_botclip_collisions)
543                         this.dphitcontentsmask |= DPCONTENTS_BOTCLIP;
544                 this.frags = FRAGS_PLAYER;
545                 if (INDEPENDENT_PLAYERS) MAKE_INDEPENDENT_PLAYER(this);
546                 this.flags = FL_CLIENT | FL_PICKUPITEMS;
547                 if (autocvar__notarget)
548                         this.flags |= FL_NOTARGET;
549                 this.takedamage = DAMAGE_AIM;
550                 this.effects = EF_TELEPORT_BIT | EF_RESTARTANIM_BIT;
551                 this.dmg = 2; // WTF
552
553                 if (warmup_stage) {
554                         this.ammo_shells = warmup_start_ammo_shells;
555                         this.ammo_nails = warmup_start_ammo_nails;
556                         this.ammo_rockets = warmup_start_ammo_rockets;
557                         this.ammo_cells = warmup_start_ammo_cells;
558                         this.ammo_plasma = warmup_start_ammo_plasma;
559                         this.ammo_fuel = warmup_start_ammo_fuel;
560                         this.health = warmup_start_health;
561                         this.armorvalue = warmup_start_armorvalue;
562                         this.weapons = WARMUP_START_WEAPONS;
563                 } else {
564                         this.ammo_shells = start_ammo_shells;
565                         this.ammo_nails = start_ammo_nails;
566                         this.ammo_rockets = start_ammo_rockets;
567                         this.ammo_cells = start_ammo_cells;
568                         this.ammo_plasma = start_ammo_plasma;
569                         this.ammo_fuel = start_ammo_fuel;
570                         this.health = start_health;
571                         this.armorvalue = start_armorvalue;
572                         this.weapons = start_weapons;
573                 }
574                 SetSpectatee_status(this, 0);
575
576                 this.dual_weapons = '0 0 0';
577
578                 this.superweapons_finished = (this.weapons & WEPSET_SUPERWEAPONS) ? time + autocvar_g_balance_superweapons_time : 0;
579
580                 this.items = start_items;
581
582                 this.spawnshieldtime = time + autocvar_g_spawnshieldtime;
583                 this.pauserotarmor_finished = time + autocvar_g_balance_pause_armor_rot_spawn;
584                 this.pauserothealth_finished = time + autocvar_g_balance_pause_health_rot_spawn;
585                 this.pauserotfuel_finished = time + autocvar_g_balance_pause_fuel_rot_spawn;
586                 this.pauseregen_finished = time + autocvar_g_balance_pause_health_regen_spawn;
587                 // extend the pause of rotting if client was reset at the beginning of the countdown
588                 if (!autocvar_sv_ready_restart_after_countdown && time < game_starttime) { // TODO why is this cvar NOTted?
589                         float f = game_starttime - time;
590                         this.spawnshieldtime += f;
591                         this.pauserotarmor_finished += f;
592                         this.pauserothealth_finished += f;
593                         this.pauseregen_finished += f;
594                 }
595                 this.damageforcescale = 2;
596                 this.death_time = 0;
597                 this.respawn_flags = 0;
598                 this.respawn_time = 0;
599                 this.stat_respawn_time = 0;
600                 this.scale = autocvar_sv_player_scale;
601                 this.fade_time = 0;
602                 this.pain_frame = 0;
603                 this.pain_finished = 0;
604                 this.pushltime = 0;
605                 setthink(this, func_null); // players have no think function
606                 this.nextthink = 0;
607                 this.dmg_team = 0;
608                 this.ballistics_density = autocvar_g_ballistics_density_player;
609
610                 this.deadflag = DEAD_NO;
611
612                 this.angles = spot.angles;
613                 this.angles_z = 0; // never spawn tilted even if the spot says to
614                 if (IS_BOT_CLIENT(this))
615                         this.v_angle = this.angles;
616                 this.fixangle = true; // turn this way immediately
617                 this.oldvelocity = this.velocity = '0 0 0';
618                 this.avelocity = '0 0 0';
619                 this.punchangle = '0 0 0';
620                 this.punchvector = '0 0 0';
621
622                 this.strength_finished = 0;
623                 this.invincible_finished = 0;
624                 this.fire_endtime = -1;
625                 this.revive_progress = 0;
626                 this.revival_time = 0;
627                 this.air_finished = time + 12;
628
629                 entity spawnevent = new_pure(spawnevent);
630                 spawnevent.owner = this;
631                 Net_LinkEntity(spawnevent, false, 0.5, SpawnEvent_Send);
632
633                 // Cut off any still running player sounds.
634                 stopsound(this, CH_PLAYER_SINGLE);
635
636                 this.model = "";
637                 FixPlayermodel(this);
638                 this.drawonlytoclient = NULL;
639
640                 this.viewloc = NULL;
641
642                 this.crouch = false;
643                 this.view_ofs = STAT(PL_VIEW_OFS, this);
644                 setsize(this, STAT(PL_MIN, this), STAT(PL_MAX, this));
645                 this.spawnorigin = spot.origin;
646                 setorigin(this, spot.origin + '0 0 1' * (1 - this.mins.z - 24));
647                 // don't reset back to last position, even if new position is stuck in solid
648                 this.oldorigin = this.origin;
649                 this.prevorigin = this.origin;
650                 this.lastteleporttime = time; // prevent insane speeds due to changing origin
651                 if(this.conveyor)
652                         IL_REMOVE(g_conveyed, this);
653                 this.conveyor = NULL; // prevent conveyors at the previous location from moving a freshly spawned player
654                 this.hud = HUD_NORMAL;
655
656                 this.event_damage = PlayerDamage;
657
658                 if(!this.bot_attack)
659                         IL_PUSH(g_bot_targets, this);
660                 this.bot_attack = true;
661                 if(!this.monster_attack)
662                         IL_PUSH(g_monster_targets, this);
663                 this.monster_attack = true;
664                 navigation_dynamicgoal_init(this, false);
665
666                 PHYS_INPUT_BUTTON_ATCK(this) = PHYS_INPUT_BUTTON_JUMP(this) = PHYS_INPUT_BUTTON_ATCK2(this) = false;
667
668                 if (this.killcount == FRAGS_SPECTATOR) {
669                         PlayerScore_Clear(this);
670                         this.killcount = 0;
671                 }
672
673                 for (int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
674                 {
675                         .entity weaponentity = weaponentities[slot];
676                         entity oldwep = this.(weaponentity);
677                         CL_SpawnWeaponentity(this, weaponentity);
678                         if(oldwep && oldwep.owner == this)
679                                 this.(weaponentity).m_gunalign = oldwep.m_gunalign;
680                 }
681                 this.alpha = default_player_alpha;
682                 this.colormod = '1 1 1' * autocvar_g_player_brightness;
683                 this.exteriorweaponentity.alpha = default_weapon_alpha;
684
685                 this.speedrunning = false;
686
687                 target_voicescript_clear(this);
688
689                 // reset fields the weapons may use
690                 FOREACH(Weapons, true, LAMBDA(
691                         it.wr_resetplayer(it, this);
692                         // reload all reloadable weapons
693                         if (it.spawnflags & WEP_FLAG_RELOADABLE) {
694                                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
695                                 {
696                                         .entity weaponentity = weaponentities[slot];
697                                         this.(weaponentity).weapon_load[it.m_id] = it.reloading_ammo;
698                                 }
699                         }
700                 ));
701
702                 {
703                         string s = spot.target;
704                         spot.target = string_null;
705                         SUB_UseTargets(spot, this, NULL);
706                         spot.target = s;
707                 }
708
709                 Unfreeze(this);
710
711                 MUTATOR_CALLHOOK(PlayerSpawn, this, spot);
712
713                 if (autocvar_spawn_debug)
714                 {
715                         sprint(this, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
716                         delete(spot); // usefull for checking if there are spawnpoints, that let drop through the floor
717                 }
718
719                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
720                 {
721                         .entity weaponentity = weaponentities[slot];
722                         if(slot == 0 || autocvar_g_weaponswitch_debug == 1)
723                                 this.(weaponentity).m_switchweapon = w_getbestweapon(this, weaponentity);
724                         else
725                                 this.(weaponentity).m_switchweapon = WEP_Null;
726                         this.(weaponentity).m_weapon = WEP_Null;
727                         this.(weaponentity).weaponname = "";
728                         this.(weaponentity).m_switchingweapon = WEP_Null;
729                         this.(weaponentity).cnt = -1;
730                 }
731
732                 MUTATOR_CALLHOOK(PlayerWeaponSelect, this);
733
734                 if (!warmup_stage && !this.alivetime)
735                         this.alivetime = time;
736
737                 antilag_clear(this, CS(this));
738         }
739 }
740
741 void ClientInit_misc(entity this);
742
743 // TODO do we need all these fields, or should we stop autodetecting runtime
744 // changes and just have a console command to update this?
745 bool ClientInit_SendEntity(entity this, entity to, int sf)
746 {
747         WriteHeader(MSG_ENTITY, _ENT_CLIENT_INIT);
748         return = true;
749         msg_entity = to;
750         // MSG_INIT replacement
751         // TODO: make easier to use
752         Registry_send_all();
753         W_PROP_reload(MSG_ONE, to);
754         ClientInit_misc(this);
755         MUTATOR_CALLHOOK(Ent_Init);
756 }
757 void ClientInit_misc(entity this)
758 {
759         int channel = MSG_ONE;
760         WriteHeader(channel, ENT_CLIENT_INIT);
761         WriteByte(channel, g_nexball_meter_period * 32);
762         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[0]));
763         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[1]));
764         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[2]));
765         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[3]));
766         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[0]));
767         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[1]));
768         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[2]));
769         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[3]));
770
771         if(sv_foginterval && world.fog != "")
772                 WriteString(channel, world.fog);
773         else
774                 WriteString(channel, "");
775         WriteByte(channel, this.count * 255.0); // g_balance_armor_blockpercent
776         WriteByte(channel, serverflags);
777         WriteCoord(channel, autocvar_g_trueaim_minrange);
778 }
779
780 void ClientInit_CheckUpdate(entity this)
781 {
782         this.nextthink = time;
783         if(this.count != autocvar_g_balance_armor_blockpercent)
784         {
785                 this.count = autocvar_g_balance_armor_blockpercent;
786                 this.SendFlags |= 1;
787         }
788 }
789
790 void ClientInit_Spawn()
791 {
792         entity e = new_pure(clientinit);
793         setthink(e, ClientInit_CheckUpdate);
794         Net_LinkEntity(e, false, 0, ClientInit_SendEntity);
795
796         ClientInit_CheckUpdate(e);
797 }
798
799 /*
800 =============
801 SetNewParms
802 =============
803 */
804 void SetNewParms ()
805 {
806         // initialize parms for a new player
807         parm1 = -(86400 * 366);
808
809         MUTATOR_CALLHOOK(SetNewParms);
810 }
811
812 /*
813 =============
814 SetChangeParms
815 =============
816 */
817 void SetChangeParms (entity this)
818 {
819         // save parms for level change
820         parm1 = this.parm_idlesince - time;
821
822         MUTATOR_CALLHOOK(SetChangeParms);
823 }
824
825 /*
826 =============
827 DecodeLevelParms
828 =============
829 */
830 void DecodeLevelParms(entity this)
831 {
832         // load parms
833         this.parm_idlesince = parm1;
834         if (this.parm_idlesince == -(86400 * 366))
835                 this.parm_idlesince = time;
836
837         // whatever happens, allow 60 seconds of idling directly after connect for map loading
838         this.parm_idlesince = max(this.parm_idlesince, time - sv_maxidle + 60);
839
840         MUTATOR_CALLHOOK(DecodeLevelParms);
841 }
842
843 /*
844 =============
845 ClientKill
846
847 Called when a client types 'kill' in the console
848 =============
849 */
850
851 .float clientkill_nexttime;
852 void ClientKill_Now_TeamChange(entity this)
853 {
854         if(this.killindicator_teamchange == -1)
855         {
856                 JoinBestTeam( this, false, true );
857         }
858         else if(this.killindicator_teamchange == -2)
859         {
860                 if(blockSpectators)
861                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
862                 PutObserverInServer(this);
863         }
864         else
865                 SV_ChangeTeam(this, this.killindicator_teamchange - 1);
866         this.killindicator_teamchange = 0;
867 }
868
869 void ClientKill_Now(entity this)
870 {
871         if(this.vehicle)
872         {
873             vehicles_exit(this.vehicle, VHEF_RELEASE);
874             if(!this.killindicator_teamchange)
875             {
876             this.vehicle_health = -1;
877             Damage(this, this, this, 1 , DEATH_KILL.m_id, this.origin, '0 0 0');
878             }
879         }
880
881         if(this.killindicator && !wasfreed(this.killindicator))
882                 delete(this.killindicator);
883
884         this.killindicator = NULL;
885
886         if(this.killindicator_teamchange)
887                 ClientKill_Now_TeamChange(this);
888
889         if(!IS_SPEC(this) && !IS_OBSERVER(this))
890                 Damage(this, this, this, 100000, DEATH_KILL.m_id, this.origin, '0 0 0');
891
892         // now I am sure the player IS dead
893 }
894 void KillIndicator_Think(entity this)
895 {
896         if (game_stopped)
897         {
898                 this.owner.killindicator = NULL;
899                 delete(this);
900                 return;
901         }
902
903         if (this.owner.alpha < 0 && !this.owner.vehicle)
904         {
905                 this.owner.killindicator = NULL;
906                 delete(this);
907                 return;
908         }
909
910         if(this.cnt <= 0)
911         {
912                 ClientKill_Now(this.owner);
913                 return;
914         }
915     else if(this.health == 1) // health == 1 means that it's silent
916     {
917         this.nextthink = time + 1;
918         this.cnt -= 1;
919     }
920         else
921         {
922                 if(this.cnt <= 10)
923                         setmodel(this, MDL_NUM(this.cnt));
924                 if(IS_REAL_CLIENT(this.owner))
925                 {
926                         if(this.cnt <= 10)
927                                 { Send_Notification(NOTIF_ONE, this.owner, MSG_ANNCE, Announcer_PickNumber(CNT_KILL, this.cnt)); }
928                 }
929                 this.nextthink = time + 1;
930                 this.cnt -= 1;
931         }
932 }
933
934 float clientkilltime;
935 void ClientKill_TeamChange (entity this, float targetteam) // 0 = don't change, -1 = auto, -2 = spec
936 {
937         float killtime;
938         float starttime;
939
940         if (game_stopped)
941                 return;
942
943         killtime = autocvar_g_balance_kill_delay;
944
945     if(MUTATOR_CALLHOOK(ClientKill, this, killtime))
946         return;
947     killtime = M_ARGV(1, float);
948
949         this.killindicator_teamchange = targetteam;
950
951     if(!this.killindicator)
952         {
953                 if(!IS_DEAD(this))
954                 {
955                         killtime = max(killtime, this.clientkill_nexttime - time);
956                         this.clientkill_nexttime = time + killtime + autocvar_g_balance_kill_antispam;
957                 }
958
959                 if(killtime <= 0 || !IS_PLAYER(this) || IS_DEAD(this))
960                 {
961                         ClientKill_Now(this);
962                 }
963                 else
964                 {
965                         starttime = max(time, clientkilltime);
966
967                         this.killindicator = spawn();
968                         this.killindicator.owner = this;
969                         this.killindicator.scale = 0.5;
970                         setattachment(this.killindicator, this, "");
971                         setorigin(this.killindicator, '0 0 52');
972                         setthink(this.killindicator, KillIndicator_Think);
973                         this.killindicator.nextthink = starttime + (this.lip) * 0.05;
974                         clientkilltime = max(clientkilltime, this.killindicator.nextthink + 0.05);
975                         this.killindicator.cnt = ceil(killtime);
976                         this.killindicator.count = bound(0, ceil(killtime), 10);
977                         //sprint(this, strcat("^1You'll be dead in ", ftos(this.killindicator.cnt), " seconds\n"));
978
979                         IL_EACH(g_clones, it.enemy == this && !(it.effects & CSQCMODEL_EF_RESPAWNGHOST),
980                         {
981                                 it.killindicator = spawn();
982                                 it.killindicator.owner = it;
983                                 it.killindicator.scale = 0.5;
984                                 setattachment(it.killindicator, it, "");
985                                 setorigin(it.killindicator, '0 0 52');
986                                 setthink(it.killindicator, KillIndicator_Think);
987                                 it.killindicator.nextthink = starttime + (it.lip) * 0.05;
988                                 //clientkilltime = max(clientkilltime, it.killindicator.nextthink + 0.05);
989                                 it.killindicator.cnt = ceil(killtime);
990                         });
991                         this.lip = 0;
992                 }
993         }
994         if(this.killindicator)
995         {
996                 if(targetteam == 0) // just die
997                 {
998                         this.killindicator.colormod = '0 0 0';
999                         if(IS_REAL_CLIENT(this))
1000                         if(this.killindicator.cnt > 0)
1001                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_TEAMCHANGE_SUICIDE, this.killindicator.cnt);
1002                 }
1003                 else if(targetteam == -1) // auto
1004                 {
1005                         this.killindicator.colormod = '0 1 0';
1006                         if(IS_REAL_CLIENT(this))
1007                         if(this.killindicator.cnt > 0)
1008                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_TEAMCHANGE_AUTO, this.killindicator.cnt);
1009                 }
1010                 else if(targetteam == -2) // spectate
1011                 {
1012                         this.killindicator.colormod = '0.5 0.5 0.5';
1013                         if(IS_REAL_CLIENT(this))
1014                         if(this.killindicator.cnt > 0)
1015                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_TEAMCHANGE_SPECTATE, this.killindicator.cnt);
1016                 }
1017                 else
1018                 {
1019                         this.killindicator.colormod = Team_ColorRGB(targetteam);
1020                         if(IS_REAL_CLIENT(this))
1021                         if(this.killindicator.cnt > 0)
1022                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, APP_TEAM_NUM(targetteam, CENTER_TEAMCHANGE), this.killindicator.cnt);
1023                 }
1024         }
1025
1026 }
1027
1028 void ClientKill (entity this)
1029 {
1030         if(game_stopped) return;
1031         if(this.player_blocked) return;
1032         if(STAT(FROZEN, this)) return;
1033
1034         ClientKill_TeamChange(this, 0);
1035 }
1036
1037 void FixClientCvars(entity e)
1038 {
1039         // send prediction settings to the client
1040         stuffcmd(e, "\nin_bindmap 0 0\n");
1041         if(autocvar_g_antilag == 3) // client side hitscan
1042                 stuffcmd(e, "cl_cmd settemp cl_prydoncursor_notrace 0\n");
1043         if(autocvar_sv_gentle)
1044                 stuffcmd(e, "cl_cmd settemp cl_gentle 1\n");
1045
1046         stuffcmd(e, sprintf("\ncl_jumpspeedcap_min \"%s\"\n", autocvar_sv_jumpspeedcap_min));
1047         stuffcmd(e, sprintf("\ncl_jumpspeedcap_max \"%s\"\n", autocvar_sv_jumpspeedcap_max));
1048
1049         MUTATOR_CALLHOOK(FixClientCvars, e);
1050 }
1051
1052 float PlayerInIDList(entity p, string idlist)
1053 {
1054         float n, i;
1055         string s;
1056
1057         // NOTE: we do NOT check crypto_idfp_signed here, an unsigned ID is fine too for this
1058         if (!p.crypto_idfp)
1059                 return 0;
1060
1061         // this function allows abbreviated player IDs too!
1062         n = tokenize_console(idlist);
1063         for(i = 0; i < n; ++i)
1064         {
1065                 s = argv(i);
1066                 if(s == substring(p.crypto_idfp, 0, strlen(s)))
1067                         return 1;
1068         }
1069
1070         return 0;
1071 }
1072
1073 #ifdef DP_EXT_PRECONNECT
1074 /*
1075 =============
1076 ClientPreConnect
1077
1078 Called once (not at each match start) when a client begins a connection to the server
1079 =============
1080 */
1081 void ClientPreConnect(entity this)
1082 {
1083         if(autocvar_sv_eventlog)
1084         {
1085                 GameLogEcho(sprintf(":connect:%d:%d:%s",
1086                         this.playerid,
1087                         etof(this),
1088                         ((IS_REAL_CLIENT(this)) ? this.netaddress : "bot")
1089                 ));
1090         }
1091 }
1092 #endif
1093
1094 /**
1095 =============
1096 ClientConnect
1097
1098 Called when a client connects to the server
1099 =============
1100 */
1101 void ClientConnect(entity this)
1102 {
1103         if (Ban_MaybeEnforceBanOnce(this)) return;
1104         assert(!IS_CLIENT(this), return);
1105         this.flags |= FL_CLIENT;
1106         assert(player_count >= 0, player_count = 0);
1107
1108 #ifdef WATERMARK
1109         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_WATERMARK, WATERMARK);
1110 #endif
1111         this.version_nagtime = time + 10 + random() * 10;
1112         TRANSMUTE(Client, this);
1113
1114         // identify the right forced team
1115         if (autocvar_g_campaign)
1116         {
1117                 if (IS_REAL_CLIENT(this)) // only players, not bots
1118                 {
1119                         switch (autocvar_g_campaign_forceteam)
1120                         {
1121                                 case 1: this.team_forced = NUM_TEAM_1; break;
1122                                 case 2: this.team_forced = NUM_TEAM_2; break;
1123                                 case 3: this.team_forced = NUM_TEAM_3; break;
1124                                 case 4: this.team_forced = NUM_TEAM_4; break;
1125                                 default: this.team_forced = 0;
1126                         }
1127                 }
1128         }
1129         else if (PlayerInIDList(this, autocvar_g_forced_team_red))    this.team_forced = NUM_TEAM_1;
1130         else if (PlayerInIDList(this, autocvar_g_forced_team_blue))   this.team_forced = NUM_TEAM_2;
1131         else if (PlayerInIDList(this, autocvar_g_forced_team_yellow)) this.team_forced = NUM_TEAM_3;
1132         else if (PlayerInIDList(this, autocvar_g_forced_team_pink))   this.team_forced = NUM_TEAM_4;
1133         else switch (autocvar_g_forced_team_otherwise)
1134         {
1135                 default: this.team_forced = 0; break;
1136                 case "red": this.team_forced = NUM_TEAM_1; break;
1137                 case "blue": this.team_forced = NUM_TEAM_2; break;
1138                 case "yellow": this.team_forced = NUM_TEAM_3; break;
1139                 case "pink": this.team_forced = NUM_TEAM_4; break;
1140                 case "spectate":
1141                 case "spectator":
1142                         this.team_forced = -1;
1143                         break;
1144         }
1145         if (!teamplay && this.team_forced > 0) this.team_forced = 0;
1146
1147     {
1148         int id = this.playerid;
1149         this.playerid = 0; // silent
1150             JoinBestTeam(this, false, false); // if the team number is valid, keep it
1151             this.playerid = id;
1152     }
1153
1154         if (autocvar_sv_spectate || autocvar_g_campaign || this.team_forced < 0) {
1155                 TRANSMUTE(Observer, this);
1156         } else {
1157                 if (!teamplay || autocvar_g_balance_teams) {
1158                         TRANSMUTE(Player, this);
1159                         campaign_bots_may_start = true;
1160                 } else {
1161                         TRANSMUTE(Observer, this); // do it anyway
1162                 }
1163         }
1164
1165         PlayerStats_GameReport_AddEvent(sprintf("kills-%d", this.playerid));
1166
1167         // always track bots, don't ask for cl_allow_uidtracking
1168     if (IS_BOT_CLIENT(this)) PlayerStats_GameReport_AddPlayer(this);
1169
1170         if (autocvar_sv_eventlog)
1171                 GameLogEcho(strcat(":join:", ftos(this.playerid), ":", ftos(etof(this)), ":", ((IS_REAL_CLIENT(this)) ? this.netaddress : "bot"), ":", playername(this, false)));
1172
1173         LogTeamchange(this.playerid, this.team, 1);
1174
1175         this.just_joined = true;  // stop spamming the eventlog with additional lines when the client connects
1176
1177         this.netname_previous = strzone(this.netname);
1178
1179         if(teamplay && IS_PLAYER(this))
1180                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, APP_TEAM_NUM(this.team, INFO_JOIN_CONNECT_TEAM), this.netname);
1181         else
1182                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_JOIN_CONNECT, this.netname);
1183
1184         stuffcmd(this, clientstuff, "\n");
1185         stuffcmd(this, "cl_particles_reloadeffects\n"); // TODO do we still need this?
1186
1187         FixClientCvars(this);
1188
1189         // get version info from player
1190         stuffcmd(this, "cmd clientversion $gameversion\n");
1191
1192         // notify about available teams
1193         if (teamplay)
1194         {
1195                 CheckAllowedTeams(this);
1196                 int t = 0;
1197                 if (c1 >= 0) t |= BIT(0);
1198                 if (c2 >= 0) t |= BIT(1);
1199                 if (c3 >= 0) t |= BIT(2);
1200                 if (c4 >= 0) t |= BIT(3);
1201                 stuffcmd(this, sprintf("set _teams_available %d\n", t));
1202         }
1203         else
1204         {
1205                 stuffcmd(this, "set _teams_available 0\n");
1206         }
1207
1208         bot_relinkplayerlist();
1209
1210         this.spectatortime = time;
1211         if (blockSpectators)
1212         {
1213                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
1214         }
1215
1216         this.jointime = time;
1217         this.allowed_timeouts = autocvar_sv_timeout_number;
1218
1219         if (IS_REAL_CLIENT(this))
1220         {
1221                 if (g_weaponarena_weapons == WEPSET(TUBA))
1222                         stuffcmd(this, "cl_cmd settemp chase_active 1\n");
1223         }
1224
1225         if (!sv_foginterval && world.fog != "")
1226                 stuffcmd(this, strcat("\nfog ", world.fog, "\nr_fog_exp2 0\nr_drawfog 1\n"));
1227
1228         if (autocvar_sv_teamnagger && !(autocvar_bot_vs_human && AvailableTeams() == 2))
1229                 if(!MUTATOR_CALLHOOK(HideTeamNagger, this))
1230                         send_CSQC_teamnagger();
1231
1232         CSQCMODEL_AUTOINIT(this);
1233
1234         this.model_randomizer = random();
1235
1236         if (IS_REAL_CLIENT(this))
1237                 sv_notice_join(this);
1238
1239         // update physics stats (players can spawn before physics runs)
1240         STAT(MOVEVARS_HIGHSPEED, this) = autocvar_g_movement_highspeed;
1241         MUTATOR_CALLHOOK(PlayerPhysics_UpdateStats, this); // do it BEFORE the function so we can modify highspeed!
1242         Physics_UpdateStats(this, PHYS_HIGHSPEED(this));
1243
1244         IL_EACH(g_initforplayer, it.init_for_player, {
1245                 it.init_for_player(it, this);
1246         });
1247
1248         MUTATOR_CALLHOOK(ClientConnect, this);
1249
1250         if (IS_REAL_CLIENT(this))
1251         {
1252                 if (!autocvar_g_campaign && !IS_PLAYER(this))
1253                 {
1254                         this.motd_actived_time = -1;
1255                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOTD, getwelcomemessage(this));
1256                 }
1257         }
1258 }
1259 /*
1260 =============
1261 ClientDisconnect
1262
1263 Called when a client disconnects from the server
1264 =============
1265 */
1266 .entity chatbubbleentity;
1267 void ReadyCount();
1268 void ClientDisconnect(entity this)
1269 {
1270         assert(IS_CLIENT(this), return);
1271
1272         PlayerStats_GameReport_FinalizePlayer(this);
1273         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
1274         if (this.active_minigame) part_minigame(this);
1275         if (IS_PLAYER(this)) Send_Effect(EFFECT_SPAWN_NEUTRAL, this.origin, '0 0 0', 1);
1276
1277         if (autocvar_sv_eventlog)
1278                 GameLogEcho(strcat(":part:", ftos(this.playerid)));
1279
1280         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_QUIT_DISCONNECT, this.netname);
1281
1282         if(IS_SPEC(this))
1283                 SetSpectatee(this, NULL);
1284
1285     MUTATOR_CALLHOOK(ClientDisconnect, this);
1286
1287         ClientState_detach(this);
1288
1289         Portal_ClearAll(this);
1290
1291         Unfreeze(this);
1292
1293         RemoveGrapplingHooks(this);
1294
1295         // Here, everything has been done that requires this player to be a client.
1296
1297         this.flags &= ~FL_CLIENT;
1298
1299         if (this.chatbubbleentity) delete(this.chatbubbleentity);
1300         if (this.killindicator) delete(this.killindicator);
1301
1302         WaypointSprite_PlayerGone(this);
1303
1304         bot_relinkplayerlist();
1305
1306         if (this.netname_previous) strunzone(this.netname_previous);
1307         if (this.clientstatus) strunzone(this.clientstatus);
1308         if (this.weaponorder_byimpulse) strunzone(this.weaponorder_byimpulse);
1309         if (this.personal) delete(this.personal);
1310
1311         this.playerid = 0;
1312         ReadyCount();
1313         if (vote_called && IS_REAL_CLIENT(this)) VoteCount(false);
1314
1315         ONREMOVE(this);
1316 }
1317
1318 void ChatBubbleThink(entity this)
1319 {
1320         this.nextthink = time;
1321         if ((this.owner.alpha < 0) || this.owner.chatbubbleentity != this)
1322         {
1323                 if(this.owner) // but why can that ever be NULL?
1324                         this.owner.chatbubbleentity = NULL;
1325                 delete(this);
1326                 return;
1327         }
1328
1329         this.mdl = "";
1330
1331         if ( !IS_DEAD(this.owner) && IS_PLAYER(this.owner) )
1332         {
1333                 if ( this.owner.active_minigame )
1334                         this.mdl = "models/sprites/minigame_busy.iqm";
1335                 else if (PHYS_INPUT_BUTTON_CHAT(this.owner))
1336                         this.mdl = "models/misc/chatbubble.spr";
1337         }
1338
1339         if ( this.model != this.mdl )
1340                 _setmodel(this, this.mdl);
1341
1342 }
1343
1344 void UpdateChatBubble(entity this)
1345 {
1346         if (this.alpha < 0)
1347                 return;
1348         // spawn a chatbubble entity if needed
1349         if (!this.chatbubbleentity)
1350         {
1351                 this.chatbubbleentity = new(chatbubbleentity);
1352                 this.chatbubbleentity.owner = this;
1353                 this.chatbubbleentity.exteriormodeltoclient = this;
1354                 setthink(this.chatbubbleentity, ChatBubbleThink);
1355                 this.chatbubbleentity.nextthink = time;
1356                 setmodel(this.chatbubbleentity, MDL_CHAT); // precision set below
1357                 //setorigin(this.chatbubbleentity, this.origin + '0 0 15' + this.maxs_z * '0 0 1');
1358                 setorigin(this.chatbubbleentity, '0 0 15' + this.maxs_z * '0 0 1');
1359                 setattachment(this.chatbubbleentity, this, "");  // sticks to moving player better, also conserves bandwidth
1360                 this.chatbubbleentity.mdl = this.chatbubbleentity.model;
1361                 //this.chatbubbleentity.model = "";
1362                 this.chatbubbleentity.effects = EF_LOWPRECISION;
1363         }
1364 }
1365
1366
1367 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
1368 // added to the model skins
1369 /*void UpdateColorModHack()
1370 {
1371         float c;
1372         c = this.clientcolors & 15;
1373         // LordHavoc: only bothering to support white, green, red, yellow, blue
1374              if (!teamplay) this.colormod = '0 0 0';
1375         else if (c ==  0) this.colormod = '1.00 1.00 1.00';
1376         else if (c ==  3) this.colormod = '0.10 1.73 0.10';
1377         else if (c ==  4) this.colormod = '1.73 0.10 0.10';
1378         else if (c == 12) this.colormod = '1.22 1.22 0.10';
1379         else if (c == 13) this.colormod = '0.10 0.10 1.73';
1380         else this.colormod = '1 1 1';
1381 }*/
1382
1383 void respawn(entity this)
1384 {
1385         if(this.alpha >= 0 && autocvar_g_respawn_ghosts)
1386         {
1387                 this.solid = SOLID_NOT;
1388                 this.takedamage = DAMAGE_NO;
1389                 set_movetype(this, MOVETYPE_FLY);
1390                 this.velocity = '0 0 1' * autocvar_g_respawn_ghosts_speed;
1391                 this.avelocity = randomvec() * autocvar_g_respawn_ghosts_speed * 3 - randomvec() * autocvar_g_respawn_ghosts_speed * 3;
1392                 this.effects |= CSQCMODEL_EF_RESPAWNGHOST;
1393                 Send_Effect(EFFECT_RESPAWN_GHOST, this.origin, '0 0 0', 1);
1394                 if(autocvar_g_respawn_ghosts_maxtime)
1395                         SUB_SetFade (this, time + autocvar_g_respawn_ghosts_maxtime / 2 + random () * (autocvar_g_respawn_ghosts_maxtime - autocvar_g_respawn_ghosts_maxtime / 2), 1.5);
1396         }
1397
1398         CopyBody(this, 1);
1399
1400         this.effects |= EF_NODRAW; // prevent another CopyBody
1401         PutClientInServer(this);
1402 }
1403
1404 void play_countdown(entity this, float finished, Sound samp)
1405 {
1406     TC(Sound, samp);
1407         if(IS_REAL_CLIENT(this))
1408                 if(floor(finished - time - frametime) != floor(finished - time))
1409                         if(finished - time < 6)
1410                                 sound (this, CH_INFO, samp, VOL_BASE, ATTEN_NORM);
1411 }
1412
1413 void player_powerups(entity this)
1414 {
1415         // add a way to see what the items were BEFORE all of these checks for the mutator hook
1416         int items_prev = this.items;
1417
1418         if((this.items & IT_USING_JETPACK) && !IS_DEAD(this) && !game_stopped)
1419                 this.modelflags |= MF_ROCKET;
1420         else
1421                 this.modelflags &= ~MF_ROCKET;
1422
1423         this.effects &= ~(EF_RED | EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT | EF_FLAME | EF_NODEPTHTEST);
1424
1425         if((this.alpha < 0 || IS_DEAD(this)) && !this.vehicle) // don't apply the flags if the player is gibbed
1426                 return;
1427
1428         Fire_ApplyDamage(this);
1429         Fire_ApplyEffect(this);
1430
1431         if (!g_instagib)
1432         {
1433                 if (this.items & ITEM_Strength.m_itemid)
1434                 {
1435                         play_countdown(this, this.strength_finished, SND_POWEROFF);
1436                         this.effects = this.effects | (EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT);
1437                         if (time > this.strength_finished)
1438                         {
1439                                 this.items = this.items - (this.items & ITEM_Strength.m_itemid);
1440                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERDOWN_STRENGTH, this.netname);
1441                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERDOWN_STRENGTH);
1442                         }
1443                 }
1444                 else
1445                 {
1446                         if (time < this.strength_finished)
1447                         {
1448                                 this.items = this.items | ITEM_Strength.m_itemid;
1449                                 if(!g_cts)
1450                                         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERUP_STRENGTH, this.netname);
1451                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERUP_STRENGTH);
1452                         }
1453                 }
1454                 if (this.items & ITEM_Shield.m_itemid)
1455                 {
1456                         play_countdown(this, this.invincible_finished, SND_POWEROFF);
1457                         this.effects = this.effects | (EF_RED | EF_ADDITIVE | EF_FULLBRIGHT);
1458                         if (time > this.invincible_finished)
1459                         {
1460                                 this.items = this.items - (this.items & ITEM_Shield.m_itemid);
1461                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERDOWN_SHIELD, this.netname);
1462                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERDOWN_SHIELD);
1463                         }
1464                 }
1465                 else
1466                 {
1467                         if (time < this.invincible_finished)
1468                         {
1469                                 this.items = this.items | ITEM_Shield.m_itemid;
1470                                 if(!g_cts)
1471                                         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERUP_SHIELD, this.netname);
1472                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERUP_SHIELD);
1473                         }
1474                 }
1475                 if (this.items & IT_SUPERWEAPON)
1476                 {
1477                         if (!(this.weapons & WEPSET_SUPERWEAPONS))
1478                         {
1479                                 this.superweapons_finished = 0;
1480                                 this.items = this.items - (this.items & IT_SUPERWEAPON);
1481                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_LOST, this.netname);
1482                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_LOST);
1483                         }
1484                         else if (this.items & IT_UNLIMITED_SUPERWEAPONS)
1485                         {
1486                                 // don't let them run out
1487                         }
1488                         else
1489                         {
1490                                 play_countdown(this, this.superweapons_finished, SND_POWEROFF);
1491                                 if (time > this.superweapons_finished)
1492                                 {
1493                                         this.items = this.items - (this.items & IT_SUPERWEAPON);
1494                                         this.weapons &= ~WEPSET_SUPERWEAPONS;
1495                                         //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_BROKEN, this.netname);
1496                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_BROKEN);
1497                                 }
1498                         }
1499                 }
1500                 else if(this.weapons & WEPSET_SUPERWEAPONS)
1501                 {
1502                         if (time < this.superweapons_finished || (this.items & IT_UNLIMITED_SUPERWEAPONS))
1503                         {
1504                                 this.items = this.items | IT_SUPERWEAPON;
1505                                 if(!g_cts)
1506                                         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_PICKUP, this.netname);
1507                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_PICKUP);
1508                         }
1509                         else
1510                         {
1511                                 this.superweapons_finished = 0;
1512                                 this.weapons &= ~WEPSET_SUPERWEAPONS;
1513                         }
1514                 }
1515                 else
1516                 {
1517                         this.superweapons_finished = 0;
1518                 }
1519         }
1520
1521         if(autocvar_g_nodepthtestplayers)
1522                 this.effects = this.effects | EF_NODEPTHTEST;
1523
1524         if(autocvar_g_fullbrightplayers)
1525                 this.effects = this.effects | EF_FULLBRIGHT;
1526
1527         if (time >= game_starttime)
1528         if (time < this.spawnshieldtime)
1529                 this.effects = this.effects | (EF_ADDITIVE | EF_FULLBRIGHT);
1530
1531         MUTATOR_CALLHOOK(PlayerPowerups, this, items_prev);
1532 }
1533
1534 float CalcRegen(float current, float stable, float regenfactor, float regenframetime)
1535 {
1536         if(current > stable)
1537                 return current;
1538         else if(current > stable - 0.25) // when close enough, "snap"
1539                 return stable;
1540         else
1541                 return min(stable, current + (stable - current) * regenfactor * regenframetime);
1542 }
1543
1544 float CalcRot(float current, float stable, float rotfactor, float rotframetime)
1545 {
1546         if(current < stable)
1547                 return current;
1548         else if(current < stable + 0.25) // when close enough, "snap"
1549                 return stable;
1550         else
1551                 return max(stable, current + (stable - current) * rotfactor * rotframetime);
1552 }
1553
1554 float CalcRotRegen(float current, float regenstable, float regenfactor, float regenlinear, float regenframetime, float rotstable, float rotfactor, float rotlinear, float rotframetime, float limit)
1555 {
1556         if(current > rotstable)
1557         {
1558                 if(rotframetime > 0)
1559                 {
1560                         current = CalcRot(current, rotstable, rotfactor, rotframetime);
1561                         current = max(rotstable, current - rotlinear * rotframetime);
1562                 }
1563         }
1564         else if(current < regenstable)
1565         {
1566                 if(regenframetime > 0)
1567                 {
1568                         current = CalcRegen(current, regenstable, regenfactor, regenframetime);
1569                         current = min(regenstable, current + regenlinear * regenframetime);
1570                 }
1571         }
1572
1573         if(current > limit)
1574                 current = limit;
1575
1576         return current;
1577 }
1578
1579 void player_regen(entity this)
1580 {
1581         float max_mod, regen_mod, rot_mod, limit_mod;
1582         max_mod = regen_mod = rot_mod = limit_mod = 1;
1583
1584         float regen_health = autocvar_g_balance_health_regen;
1585         float regen_health_linear = autocvar_g_balance_health_regenlinear;
1586         float regen_health_rot = autocvar_g_balance_health_rot;
1587         float regen_health_rotlinear = autocvar_g_balance_health_rotlinear;
1588         float regen_health_stable = autocvar_g_balance_health_regenstable;
1589         float regen_health_rotstable = autocvar_g_balance_health_rotstable;
1590         bool mutator_returnvalue = MUTATOR_CALLHOOK(PlayerRegen, this, max_mod, regen_mod, rot_mod, limit_mod, regen_health, regen_health_linear, regen_health_rot,
1591                 regen_health_rotlinear, regen_health_stable, regen_health_rotstable);
1592         max_mod = M_ARGV(1, float);
1593         regen_mod = M_ARGV(2, float);
1594         rot_mod = M_ARGV(3, float);
1595         limit_mod = M_ARGV(4, float);
1596         regen_health = M_ARGV(5, float);
1597         regen_health_linear = M_ARGV(6, float);
1598         regen_health_rot = M_ARGV(7, float);
1599         regen_health_rotlinear = M_ARGV(8, float);
1600         regen_health_stable = M_ARGV(9, float);
1601         regen_health_rotstable = M_ARGV(10, float);
1602
1603
1604         if(!mutator_returnvalue)
1605         if(!STAT(FROZEN, this))
1606         {
1607                 float mina, maxa, limith, limita;
1608                 maxa = autocvar_g_balance_armor_rotstable;
1609                 mina = autocvar_g_balance_armor_regenstable;
1610                 limith = autocvar_g_balance_health_limit;
1611                 limita = autocvar_g_balance_armor_limit;
1612
1613                 regen_health_rotstable = regen_health_rotstable * max_mod;
1614                 regen_health_stable = regen_health_stable * max_mod;
1615                 limith = limith * limit_mod;
1616                 limita = limita * limit_mod;
1617
1618                 this.armorvalue = CalcRotRegen(this.armorvalue, mina, autocvar_g_balance_armor_regen, autocvar_g_balance_armor_regenlinear, regen_mod * frametime * (time > this.pauseregen_finished), maxa, autocvar_g_balance_armor_rot, autocvar_g_balance_armor_rotlinear, rot_mod * frametime * (time > this.pauserotarmor_finished), limita);
1619                 this.health = CalcRotRegen(this.health, regen_health_stable, regen_health, regen_health_linear, regen_mod * frametime * (time > this.pauseregen_finished), regen_health_rotstable, regen_health_rot, regen_health_rotlinear, rot_mod * frametime * (time > this.pauserothealth_finished), limith);
1620         }
1621
1622         // if player rotted to death...  die!
1623         // check this outside above checks, as player may still be able to rot to death
1624         if(this.health < 1)
1625         {
1626                 if(this.vehicle)
1627                         vehicles_exit(this.vehicle, VHEF_RELEASE);
1628                 if(this.event_damage)
1629                         this.event_damage(this, this, this, 1, DEATH_ROT.m_id, this.origin, '0 0 0');
1630         }
1631
1632         if (!(this.items & IT_UNLIMITED_WEAPON_AMMO))
1633         {
1634                 float minf, maxf, limitf;
1635
1636                 maxf = autocvar_g_balance_fuel_rotstable;
1637                 minf = autocvar_g_balance_fuel_regenstable;
1638                 limitf = autocvar_g_balance_fuel_limit;
1639
1640                 this.ammo_fuel = CalcRotRegen(this.ammo_fuel, minf, autocvar_g_balance_fuel_regen, autocvar_g_balance_fuel_regenlinear, frametime * (time > this.pauseregen_finished) * ((this.items & ITEM_JetpackRegen.m_itemid) != 0), maxf, autocvar_g_balance_fuel_rot, autocvar_g_balance_fuel_rotlinear, frametime * (time > this.pauserotfuel_finished), limitf);
1641         }
1642 }
1643
1644 bool zoomstate_set;
1645 void SetZoomState(entity this, float newzoom)
1646 {
1647         if(newzoom != this.zoomstate)
1648         {
1649                 this.zoomstate = newzoom;
1650                 ClientData_Touch(this);
1651         }
1652         zoomstate_set = true;
1653 }
1654
1655 void GetPressedKeys(entity this)
1656 {
1657         MUTATOR_CALLHOOK(GetPressedKeys, this);
1658         int keys = STAT(PRESSED_KEYS, this);
1659         keys = BITSET(keys, KEY_FORWARD,        this.movement.x > 0);
1660         keys = BITSET(keys, KEY_BACKWARD,       this.movement.x < 0);
1661         keys = BITSET(keys, KEY_RIGHT,          this.movement.y > 0);
1662         keys = BITSET(keys, KEY_LEFT,           this.movement.y < 0);
1663
1664         keys = BITSET(keys, KEY_JUMP,           PHYS_INPUT_BUTTON_JUMP(this));
1665         keys = BITSET(keys, KEY_CROUCH,         PHYS_INPUT_BUTTON_CROUCH(this));
1666         keys = BITSET(keys, KEY_ATCK,           PHYS_INPUT_BUTTON_ATCK(this));
1667         keys = BITSET(keys, KEY_ATCK2,          PHYS_INPUT_BUTTON_ATCK2(this));
1668         this.pressedkeys = keys; // store for other users
1669
1670         STAT(PRESSED_KEYS, this) = keys;
1671 }
1672
1673 /*
1674 ======================
1675 spectate mode routines
1676 ======================
1677 */
1678
1679 void SpectateCopy(entity this, entity spectatee)
1680 {
1681     TC(Client, this); TC(Client, spectatee);
1682
1683         MUTATOR_CALLHOOK(SpectateCopy, spectatee, this);
1684         PS(this) = PS(spectatee);
1685         this.armortype = spectatee.armortype;
1686         this.armorvalue = spectatee.armorvalue;
1687         this.ammo_cells = spectatee.ammo_cells;
1688         this.ammo_plasma = spectatee.ammo_plasma;
1689         this.ammo_shells = spectatee.ammo_shells;
1690         this.ammo_nails = spectatee.ammo_nails;
1691         this.ammo_rockets = spectatee.ammo_rockets;
1692         this.ammo_fuel = spectatee.ammo_fuel;
1693         this.clip_load = spectatee.clip_load;
1694         this.clip_size = spectatee.clip_size;
1695         this.effects = spectatee.effects & EFMASK_CHEAP; // eat performance
1696         this.health = spectatee.health;
1697         this.impulse = 0;
1698         this.items = spectatee.items;
1699         this.last_pickup = spectatee.last_pickup;
1700         this.hit_time = spectatee.hit_time;
1701         this.strength_finished = spectatee.strength_finished;
1702         this.invincible_finished = spectatee.invincible_finished;
1703         this.superweapons_finished = spectatee.superweapons_finished;
1704         STAT(PRESSED_KEYS, this) = STAT(PRESSED_KEYS, spectatee);
1705         this.weapons = spectatee.weapons;
1706         this.dual_weapons = spectatee.dual_weapons;
1707         this.vortex_charge = spectatee.vortex_charge;
1708         this.vortex_chargepool_ammo = spectatee.vortex_chargepool_ammo;
1709         this.hagar_load = spectatee.hagar_load;
1710         this.arc_heat_percent = spectatee.arc_heat_percent;
1711         this.minelayer_mines = spectatee.minelayer_mines;
1712         this.punchangle = spectatee.punchangle;
1713         this.view_ofs = spectatee.view_ofs;
1714         this.velocity = spectatee.velocity;
1715         this.dmg_take = spectatee.dmg_take;
1716         this.dmg_save = spectatee.dmg_save;
1717         this.dmg_inflictor = spectatee.dmg_inflictor;
1718         this.v_angle = spectatee.v_angle;
1719         this.angles = spectatee.v_angle;
1720         STAT(FROZEN, this) = STAT(FROZEN, spectatee);
1721         this.revive_progress = spectatee.revive_progress;
1722         this.viewloc = spectatee.viewloc;
1723         if(!PHYS_INPUT_BUTTON_USE(this) && STAT(CAMERA_SPECTATOR, this) != 2)
1724                 this.fixangle = true;
1725         setorigin(this, spectatee.origin);
1726         setsize(this, spectatee.mins, spectatee.maxs);
1727         SetZoomState(this, spectatee.zoomstate);
1728
1729         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1730         {
1731                 .entity weaponentity = weaponentities[slot];
1732                 this.(weaponentity) = spectatee.(weaponentity);
1733         }
1734
1735         for(int slot = 0; slot < MAX_AXH; ++slot)
1736         {
1737                 this.(AuxiliaryXhair[slot]) = spectatee.(AuxiliaryXhair[slot]);
1738         }
1739
1740     anticheat_spectatecopy(this, spectatee);
1741         this.hud = spectatee.hud;
1742         if(spectatee.vehicle)
1743     {
1744         this.angles = spectatee.v_angle;
1745
1746         //this.fixangle = false;
1747         //this.velocity = spectatee.vehicle.velocity;
1748         this.vehicle_health = spectatee.vehicle_health;
1749         this.vehicle_shield = spectatee.vehicle_shield;
1750         this.vehicle_energy = spectatee.vehicle_energy;
1751         this.vehicle_ammo1 = spectatee.vehicle_ammo1;
1752         this.vehicle_ammo2 = spectatee.vehicle_ammo2;
1753         this.vehicle_reload1 = spectatee.vehicle_reload1;
1754         this.vehicle_reload2 = spectatee.vehicle_reload2;
1755
1756         //msg_entity = this;
1757
1758        // WriteByte (MSG_ONE, SVC_SETVIEWANGLES);
1759             //WriteAngle(MSG_ONE,  spectatee.v_angle.x);
1760            // WriteAngle(MSG_ONE,  spectatee.v_angle.y);
1761            // WriteAngle(MSG_ONE,  spectatee.v_angle.z);
1762
1763         //WriteByte (MSG_ONE, SVC_SETVIEW);
1764         //    WriteEntity(MSG_ONE, this);
1765         //makevectors(spectatee.v_angle);
1766         //setorigin(this, spectatee.origin - v_forward * 400 + v_up * 300);*/
1767     }
1768 }
1769
1770 bool SpectateUpdate(entity this)
1771 {
1772         if(!this.enemy)
1773                 return false;
1774
1775         if(!IS_PLAYER(this.enemy) || this == this.enemy)
1776         {
1777                 SetSpectatee(this, NULL);
1778                 return false;
1779         }
1780
1781         SpectateCopy(this, this.enemy);
1782
1783         return true;
1784 }
1785
1786 bool SpectateSet(entity this)
1787 {
1788         if(!IS_PLAYER(this.enemy))
1789                 return false;
1790
1791         ClientData_Touch(this.enemy);
1792
1793         msg_entity = this;
1794         WriteByte(MSG_ONE, SVC_SETVIEW);
1795         WriteEntity(MSG_ONE, this.enemy);
1796         set_movetype(this, MOVETYPE_NONE);
1797         accuracy_resend(this);
1798
1799         if(!SpectateUpdate(this))
1800                 PutObserverInServer(this);
1801
1802         return true;
1803 }
1804
1805 void SetSpectatee_status(entity this, int spectatee_num)
1806 {
1807         int oldspectatee_status = this.spectatee_status;
1808         this.spectatee_status = spectatee_num;
1809
1810         if (this.spectatee_status != oldspectatee_status)
1811         {
1812                 ClientData_Touch(this);
1813                 if (g_race || g_cts) race_InitSpectator();
1814         }
1815 }
1816
1817 void SetSpectatee(entity this, entity spectatee)
1818 {
1819         if(IS_BOT_CLIENT(this))
1820                 return; // bots abuse .enemy, this code is useless to them
1821
1822         entity old_spectatee = this.enemy;
1823
1824         this.enemy = spectatee;
1825
1826         // WEAPONTODO
1827         // these are required to fix the spectator bug with arc
1828         if(old_spectatee)
1829         {
1830                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1831                 {
1832                         .entity weaponentity = weaponentities[slot];
1833                         if(old_spectatee.(weaponentity).arc_beam)
1834                                 old_spectatee.(weaponentity).arc_beam.SendFlags |= ARC_SF_SETTINGS;
1835                 }
1836         }
1837         if(this.enemy)
1838         {
1839                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1840                 {
1841                         .entity weaponentity = weaponentities[slot];
1842                         if(this.enemy.(weaponentity).arc_beam)
1843                                 this.enemy.(weaponentity).arc_beam.SendFlags |= ARC_SF_SETTINGS;
1844                 }
1845         }
1846
1847         if (this.enemy)
1848                 SetSpectatee_status(this, etof(this.enemy));
1849
1850         // needed to update spectator list
1851         if(old_spectatee) { ClientData_Touch(old_spectatee); }
1852 }
1853
1854 bool Spectate(entity this, entity pl)
1855 {
1856         if(MUTATOR_CALLHOOK(SpectateSet, this, pl))
1857                 return false;
1858         pl = M_ARGV(1, entity);
1859
1860         SetSpectatee(this, pl);
1861         return SpectateSet(this);
1862 }
1863
1864 bool SpectateNext(entity this)
1865 {
1866         entity ent = find(this.enemy, classname, STR_PLAYER);
1867
1868         if (MUTATOR_CALLHOOK(SpectateNext, this, ent))
1869                 ent = M_ARGV(1, entity);
1870         else if (!ent)
1871                 ent = find(ent, classname, STR_PLAYER);
1872
1873         if(ent) { SetSpectatee(this, ent); }
1874
1875         return SpectateSet(this);
1876 }
1877
1878 bool SpectatePrev(entity this)
1879 {
1880         // NOTE: chain order is from the highest to the lower entnum (unlike find)
1881         entity ent = findchain(classname, STR_PLAYER);
1882         if (!ent) // no player
1883                 return false;
1884
1885         entity first = ent;
1886         // skip players until current spectated player
1887         if(this.enemy)
1888         while(ent && ent != this.enemy)
1889                 ent = ent.chain;
1890
1891         switch (MUTATOR_CALLHOOK(SpectatePrev, this, ent, first))
1892         {
1893                 case MUT_SPECPREV_FOUND:
1894                     ent = M_ARGV(1, entity);
1895                     break;
1896                 case MUT_SPECPREV_RETURN:
1897                     return true;
1898                 case MUT_SPECPREV_CONTINUE:
1899                 default:
1900                 {
1901                         if(ent.chain)
1902                                 ent = ent.chain;
1903                         else
1904                                 ent = first;
1905                         break;
1906                 }
1907         }
1908
1909         SetSpectatee(this, ent);
1910         return SpectateSet(this);
1911 }
1912
1913 /*
1914 =============
1915 ShowRespawnCountdown()
1916
1917 Update a respawn countdown display.
1918 =============
1919 */
1920 void ShowRespawnCountdown(entity this)
1921 {
1922         float number;
1923         if(!IS_DEAD(this)) // just respawned?
1924                 return;
1925         else
1926         {
1927                 number = ceil(this.respawn_time - time);
1928                 if(number <= 0)
1929                         return;
1930                 if(number <= this.respawn_countdown)
1931                 {
1932                         this.respawn_countdown = number - 1;
1933                         if(ceil(this.respawn_time - (time + 0.5)) == number) // only say it if it is the same number even in 0.5s; to prevent overlapping sounds
1934                                 { Send_Notification(NOTIF_ONE, this, MSG_ANNCE, Announcer_PickNumber(CNT_RESPAWN, number)); }
1935                 }
1936         }
1937 }
1938
1939 .bool team_selected;
1940 bool ShowTeamSelection(entity this)
1941 {
1942         if(!teamplay || autocvar_g_campaign || autocvar_g_balance_teams || this.team_selected || (this.wasplayer && autocvar_g_changeteam_banned) || this.team_forced > 0)
1943                 return false;
1944         stuffcmd(this, "menu_showteamselect\n");
1945         return true;
1946 }
1947 void Join(entity this)
1948 {
1949         TRANSMUTE(Player, this);
1950
1951         if(!this.team_selected)
1952         if(autocvar_g_campaign || autocvar_g_balance_teams)
1953                 JoinBestTeam(this, false, true);
1954
1955         if(autocvar_g_campaign)
1956                 campaign_bots_may_start = true;
1957
1958         Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_PREVENT_JOIN);
1959
1960         PutClientInServer(this);
1961
1962         if(IS_PLAYER(this))
1963         if(teamplay && this.team != -1)
1964                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, APP_TEAM_NUM(this.team, INFO_JOIN_PLAY_TEAM), this.netname);
1965         else
1966                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_JOIN_PLAY, this.netname);
1967         this.team_selected = false;
1968 }
1969
1970 /**
1971  * Determines whether the player is allowed to join. This depends on cvar
1972  * g_maxplayers, if it isn't used this function always return true, otherwise
1973  * it checks whether the number of currently playing players exceeds g_maxplayers.
1974  * @return int number of free slots for players, 0 if none
1975  */
1976 int nJoinAllowed(entity this, entity ignore)
1977 {
1978         if(!ignore)
1979         // this is called that way when checking if anyone may be able to join (to build qcstatus)
1980         // so report 0 free slots if restricted
1981         {
1982                 if(autocvar_g_forced_team_otherwise == "spectate")
1983                         return 0;
1984                 if(autocvar_g_forced_team_otherwise == "spectator")
1985                         return 0;
1986         }
1987
1988         if(this && this.team_forced < 0)
1989                 return 0; // forced spectators can never join
1990
1991         // TODO simplify this
1992         int totalClients = 0;
1993         int currentlyPlaying = 0;
1994         FOREACH_CLIENT(true, LAMBDA(
1995                 if(it != ignore)
1996                         ++totalClients;
1997                 if(IS_REAL_CLIENT(it))
1998                 if(IS_PLAYER(it) || it.caplayer)
1999                         ++currentlyPlaying;
2000         ));
2001
2002         float free_slots = 0;
2003         if (!autocvar_g_maxplayers)
2004                 free_slots = maxclients - totalClients;
2005         else if(currentlyPlaying < autocvar_g_maxplayers)
2006                 free_slots = min(maxclients - totalClients, autocvar_g_maxplayers - currentlyPlaying);
2007
2008         static float join_prevent_msg_time = 0;
2009         if(this && ignore && !free_slots && time > join_prevent_msg_time)
2010         {
2011                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_JOIN_PREVENT);
2012                 join_prevent_msg_time = time + 3;
2013         }
2014
2015         return free_slots;
2016 }
2017
2018 /**
2019  * Checks whether the client is an observer or spectator, if so, he will get kicked after
2020  * g_maxplayers_spectator_blocktime seconds
2021  */
2022 void checkSpectatorBlock(entity this)
2023 {
2024         if(IS_SPEC(this) || IS_OBSERVER(this))
2025         if(!this.caplayer)
2026         if(IS_REAL_CLIENT(this))
2027         {
2028                 if( time > (this.spectatortime + autocvar_g_maxplayers_spectator_blocktime) ) {
2029                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_QUIT_KICK_SPECTATING);
2030                         dropclient(this);
2031                 }
2032         }
2033 }
2034
2035 void PrintWelcomeMessage(entity this)
2036 {
2037         if(this.motd_actived_time == 0)
2038         {
2039                 if (autocvar_g_campaign) {
2040                         if ((IS_PLAYER(this) && PHYS_INPUT_BUTTON_INFO(this)) || (!IS_PLAYER(this))) {
2041                                 this.motd_actived_time = time;
2042                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOTD, campaign_message);
2043                         }
2044                 } else {
2045                         if (PHYS_INPUT_BUTTON_INFO(this)) {
2046                                 this.motd_actived_time = time;
2047                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOTD, getwelcomemessage(this));
2048                         }
2049                 }
2050         }
2051         else if(this.motd_actived_time > 0) // showing MOTD or campaign message
2052         {
2053                 if (autocvar_g_campaign) {
2054                         if (PHYS_INPUT_BUTTON_INFO(this))
2055                                 this.motd_actived_time = time;
2056                         else if ((time - this.motd_actived_time > 2) && IS_PLAYER(this)) { // hide it some seconds after BUTTON_INFO has been released
2057                                 this.motd_actived_time = 0;
2058                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_MOTD);
2059                         }
2060                 } else {
2061                         if (PHYS_INPUT_BUTTON_INFO(this))
2062                                 this.motd_actived_time = time;
2063                         else if (time - this.motd_actived_time > 2) { // hide it some seconds after BUTTON_INFO has been released
2064                                 this.motd_actived_time = 0;
2065                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_MOTD);
2066                         }
2067                 }
2068         }
2069         else //if(this.motd_actived_time < 0) // just connected, motd is active
2070         {
2071                 if(PHYS_INPUT_BUTTON_INFO(this)) // BUTTON_INFO hides initial MOTD
2072                         this.motd_actived_time = -2; // wait until BUTTON_INFO gets released
2073                 else if(this.motd_actived_time == -2 || IS_PLAYER(this) || IS_SPEC(this))
2074                 {
2075                         // instanctly hide MOTD
2076                         this.motd_actived_time = 0;
2077                         Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_MOTD);
2078                 }
2079         }
2080 }
2081
2082 bool joinAllowed(entity this)
2083 {
2084         if (this.version_mismatch) return false;
2085         if (!nJoinAllowed(this, this)) return false;
2086         if (teamplay && lockteams) return false;
2087         if (ShowTeamSelection(this)) return false;
2088         if (MUTATOR_CALLHOOK(ForbidSpawn, this)) return false;
2089         return true;
2090 }
2091
2092 void ObserverThink(entity this)
2093 {
2094         if ( this.impulse )
2095         {
2096                 MinigameImpulse(this, this.impulse);
2097                 this.impulse = 0;
2098         }
2099
2100         if (this.flags & FL_JUMPRELEASED) {
2101                 if (PHYS_INPUT_BUTTON_JUMP(this) && joinAllowed(this)) {
2102                         this.flags &= ~FL_JUMPRELEASED;
2103                         this.flags |= FL_SPAWNING;
2104                 } else if(PHYS_INPUT_BUTTON_ATCK(this) && !this.version_mismatch) {
2105                         this.flags &= ~FL_JUMPRELEASED;
2106                         if(SpectateNext(this)) {
2107                                 TRANSMUTE(Spectator, this);
2108                         }
2109                 } else {
2110                         int preferred_movetype = ((!PHYS_INPUT_BUTTON_USE(this) ? this.cvar_cl_clippedspectating : !this.cvar_cl_clippedspectating) ? MOVETYPE_FLY_WORLDONLY : MOVETYPE_NOCLIP);
2111                         set_movetype(this, preferred_movetype);
2112                 }
2113         } else {
2114                 if (!(PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_JUMP(this))) {
2115                         this.flags |= FL_JUMPRELEASED;
2116                         if(this.flags & FL_SPAWNING)
2117                         {
2118                                 this.flags &= ~FL_SPAWNING;
2119                                 Join(this);
2120                                 return;
2121                         }
2122                 }
2123         }
2124 }
2125
2126 void SpectatorThink(entity this)
2127 {
2128         if ( this.impulse )
2129         {
2130                 if(MinigameImpulse(this, this.impulse))
2131                         this.impulse = 0;
2132
2133                 if (this.impulse == IMP_weapon_drop.impulse)
2134                 {
2135                         STAT(CAMERA_SPECTATOR, this) = (STAT(CAMERA_SPECTATOR, this) + 1) % 3;
2136                         this.impulse = 0;
2137                         return;
2138                 }
2139         }
2140
2141         if (this.flags & FL_JUMPRELEASED) {
2142                 if (PHYS_INPUT_BUTTON_JUMP(this) && joinAllowed(this)) {
2143                         this.flags &= ~FL_JUMPRELEASED;
2144                         this.flags |= FL_SPAWNING;
2145                 } else if(PHYS_INPUT_BUTTON_ATCK(this) || this.impulse == 10 || this.impulse == 15 || this.impulse == 18 || (this.impulse >= 200 && this.impulse <= 209)) {
2146                         this.flags &= ~FL_JUMPRELEASED;
2147                         if(SpectateNext(this)) {
2148                                 TRANSMUTE(Spectator, this);
2149                         } else {
2150                                 TRANSMUTE(Observer, this);
2151                                 PutClientInServer(this);
2152                         }
2153                         this.impulse = 0;
2154                 } else if(this.impulse == 12 || this.impulse == 16  || this.impulse == 19 || (this.impulse >= 220 && this.impulse <= 229)) {
2155                         this.flags &= ~FL_JUMPRELEASED;
2156                         if(SpectatePrev(this)) {
2157                                 TRANSMUTE(Spectator, this);
2158                         } else {
2159                                 TRANSMUTE(Observer, this);
2160                                 PutClientInServer(this);
2161                         }
2162                         this.impulse = 0;
2163                 } else if (PHYS_INPUT_BUTTON_ATCK2(this)) {
2164                         this.flags &= ~FL_JUMPRELEASED;
2165                         TRANSMUTE(Observer, this);
2166                         PutClientInServer(this);
2167                 } else {
2168                         if(!SpectateUpdate(this))
2169                                 PutObserverInServer(this);
2170                 }
2171         } else {
2172                 if (!(PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_ATCK2(this))) {
2173                         this.flags |= FL_JUMPRELEASED;
2174                         if(this.flags & FL_SPAWNING)
2175                         {
2176                                 this.flags &= ~FL_SPAWNING;
2177                                 Join(this);
2178                                 return;
2179                         }
2180                 }
2181                 if(!SpectateUpdate(this))
2182                         PutObserverInServer(this);
2183         }
2184
2185         this.flags |= FL_CLIENT | FL_NOTARGET;
2186 }
2187
2188 void vehicles_enter (entity pl, entity veh);
2189 void PlayerUseKey(entity this)
2190 {
2191         if (!IS_PLAYER(this))
2192                 return;
2193
2194         if(this.vehicle)
2195         {
2196                 if(!game_stopped)
2197                 {
2198                         vehicles_exit(this.vehicle, VHEF_NORMAL);
2199                         return;
2200                 }
2201         }
2202         else if(autocvar_g_vehicles_enter)
2203         {
2204                 if(!STAT(FROZEN, this))
2205                 if(!IS_DEAD(this))
2206                 if(!game_stopped)
2207                 {
2208                         entity head, closest_target = NULL;
2209                         head = WarpZone_FindRadius(this.origin, autocvar_g_vehicles_enter_radius, true);
2210
2211                         while(head) // find the closest acceptable target to enter
2212                         {
2213                                 if(IS_VEHICLE(head))
2214                                 if(!IS_DEAD(head))
2215                                 if(!head.owner || ((head.vehicle_flags & VHF_MULTISLOT) && SAME_TEAM(head.owner, this)))
2216                                 if(head.takedamage != DAMAGE_NO)
2217                                 {
2218                                         if(closest_target)
2219                                         {
2220                                                 if(vlen2(this.origin - head.origin) < vlen2(this.origin - closest_target.origin))
2221                                                 { closest_target = head; }
2222                                         }
2223                                         else { closest_target = head; }
2224                                 }
2225
2226                                 head = head.chain;
2227                         }
2228
2229                         if(closest_target) { vehicles_enter(this, closest_target); return; }
2230                 }
2231         }
2232
2233         // a use key was pressed; call handlers
2234         MUTATOR_CALLHOOK(PlayerUseKey, this);
2235 }
2236
2237
2238 /*
2239 =============
2240 PlayerPreThink
2241
2242 Called every frame for each client before the physics are run
2243 =============
2244 */
2245 .float usekeypressed;
2246 .float last_vehiclecheck;
2247 .int items_added;
2248 void PlayerPreThink (entity this)
2249 {
2250         WarpZone_PlayerPhysics_FixVAngle(this);
2251
2252     STAT(GAMESTARTTIME, this) = game_starttime;
2253         STAT(ROUNDSTARTTIME, this) = round_starttime;
2254         STAT(ALLOW_OLDVORTEXBEAM, this) = autocvar_g_allow_oldvortexbeam;
2255         STAT(LEADLIMIT, this) = autocvar_leadlimit;
2256
2257         STAT(WEAPONSINMAP, this) = weaponsInMap;
2258
2259         if (frametime) {
2260                 // physics frames: update anticheat stuff
2261                 anticheat_prethink(this);
2262         }
2263
2264         if (blockSpectators && frametime) {
2265                 // WORKAROUND: only use dropclient in server frames (frametime set).
2266                 // Never use it in cl_movement frames (frametime zero).
2267                 checkSpectatorBlock(this);
2268     }
2269
2270         zoomstate_set = false;
2271
2272         // Check for nameless players
2273         if (isInvisibleString(this.netname)) {
2274                 this.netname = strzone(sprintf("Player#%d", this.playerid));
2275                 // stuffcmd(this, strcat("name ", this.netname, "\n")); // maybe?
2276         }
2277         if (this.netname != this.netname_previous) {
2278                 if (autocvar_sv_eventlog) {
2279                         GameLogEcho(strcat(":name:", ftos(this.playerid), ":", playername(this, false)));
2280         }
2281                 if (this.netname_previous) strunzone(this.netname_previous);
2282                 this.netname_previous = strzone(this.netname);
2283         }
2284
2285         // version nagging
2286         if (this.version_nagtime && this.cvar_g_xonoticversion && time > this.version_nagtime) {
2287         this.version_nagtime = 0;
2288         if (strstrofs(this.cvar_g_xonoticversion, "git", 0) >= 0 || strstrofs(this.cvar_g_xonoticversion, "autobuild", 0) >= 0) {
2289             // git client
2290         } else if (strstrofs(autocvar_g_xonoticversion, "git", 0) >= 0 || strstrofs(autocvar_g_xonoticversion, "autobuild", 0) >= 0) {
2291             // git server
2292             Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_BETA, autocvar_g_xonoticversion, this.cvar_g_xonoticversion);
2293         } else {
2294             int r = vercmp(this.cvar_g_xonoticversion, autocvar_g_xonoticversion);
2295             if (r < 0) { // old client
2296                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_OUTDATED, autocvar_g_xonoticversion, this.cvar_g_xonoticversion);
2297             } else if (r > 0) { // old server
2298                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_OLD, autocvar_g_xonoticversion, this.cvar_g_xonoticversion);
2299             }
2300         }
2301     }
2302
2303         // GOD MODE info
2304         if (!(this.flags & FL_GODMODE) && this.max_armorvalue)
2305         {
2306                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_GODMODE_OFF, this.max_armorvalue);
2307                 this.max_armorvalue = 0;
2308         }
2309
2310         if (STAT(FROZEN, this) == 2)
2311         {
2312                 this.revive_progress = bound(0, this.revive_progress + frametime * this.revive_speed, 1);
2313                 this.health = max(1, this.revive_progress * start_health);
2314                 this.iceblock.alpha = bound(0.2, 1 - this.revive_progress, 1);
2315
2316                 if (this.revive_progress >= 1)
2317                         Unfreeze(this);
2318         }
2319         else if (STAT(FROZEN, this) == 3)
2320         {
2321                 this.revive_progress = bound(0, this.revive_progress - frametime * this.revive_speed, 1);
2322                 this.health = max(0, autocvar_g_nades_ice_health + (start_health-autocvar_g_nades_ice_health) * this.revive_progress );
2323
2324                 if (this.health < 1)
2325                 {
2326                         if (this.vehicle)
2327                                 vehicles_exit(this.vehicle, VHEF_RELEASE);
2328                         if(this.event_damage)
2329                                 this.event_damage(this, this, this.frozen_by, 1, DEATH_NADE_ICE_FREEZE.m_id, this.origin, '0 0 0');
2330                 }
2331                 else if (this.revive_progress <= 0)
2332                         Unfreeze(this);
2333         }
2334
2335         MUTATOR_CALLHOOK(PlayerPreThink, this);
2336
2337         if(autocvar_g_vehicles_enter && (time > this.last_vehiclecheck) && !game_stopped && !this.vehicle)
2338         if(IS_PLAYER(this) && !STAT(FROZEN, this) && !IS_DEAD(this))
2339         {
2340                 FOREACH_ENTITY_RADIUS(this.origin, autocvar_g_vehicles_enter_radius, IS_VEHICLE(it),
2341                 {
2342                         if(!IS_DEAD(it) && it.takedamage != DAMAGE_NO)
2343                         if((it.vehicle_flags & VHF_MULTISLOT) && SAME_TEAM(it.owner, this))
2344                         {
2345                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER_GUNNER);
2346                         }
2347                         else if(!it.owner)
2348                         {
2349                                 if(!it.team || SAME_TEAM(this, it))
2350                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER);
2351                                 else if(autocvar_g_vehicles_steal)
2352                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER_STEAL);
2353                         }
2354                 });
2355
2356                 this.last_vehiclecheck = time + 1;
2357         }
2358
2359         if(!this.cvar_cl_newusekeysupported) // FIXME remove this - it was a stupid idea to begin with, we can JUST use the button
2360         {
2361                 if(PHYS_INPUT_BUTTON_USE(this) && !this.usekeypressed)
2362                         PlayerUseKey(this);
2363                 this.usekeypressed = PHYS_INPUT_BUTTON_USE(this);
2364         }
2365
2366         if (IS_REAL_CLIENT(this))
2367                 PrintWelcomeMessage(this);
2368
2369         if (IS_PLAYER(this)) {
2370                 CheckRules_Player(this);
2371
2372                 if (game_stopped || intermission_running) {
2373                         this.modelflags &= ~MF_ROCKET;
2374                         if(intermission_running)
2375                                 IntermissionThink(this);
2376                         return;
2377                 }
2378
2379                 if (timeout_status == TIMEOUT_ACTIVE) {
2380             // don't allow the player to turn around while game is paused
2381                         // FIXME turn this into CSQC stuff
2382                         this.v_angle = this.lastV_angle;
2383                         this.angles = this.lastV_angle;
2384                         this.fixangle = true;
2385                 }
2386
2387                 if (frametime) player_powerups(this);
2388
2389                 if (IS_DEAD(this)) {
2390                         if (this.personal && g_race_qualifying) {
2391                                 if (time > this.respawn_time) {
2392                                         STAT(RESPAWN_TIME, this) = this.respawn_time = time + 1; // only retry once a second
2393                                         respawn(this);
2394                                         this.impulse = CHIMPULSE_SPEEDRUN.impulse;
2395                                 }
2396                         } else {
2397                                 if (frametime) player_anim(this);
2398
2399                                 if (this.respawn_flags & RESPAWN_DENY)
2400                                 {
2401                                         STAT(RESPAWN_TIME, this) = 0;
2402                                         return;
2403                                 }
2404
2405                                 bool button_pressed = (PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_JUMP(this) || PHYS_INPUT_BUTTON_ATCK2(this) || PHYS_INPUT_BUTTON_HOOK(this) || PHYS_INPUT_BUTTON_USE(this));
2406
2407                                 switch(this.deadflag)
2408                                 {
2409                                         case DEAD_DYING:
2410                                         {
2411                                                 if ((this.respawn_flags & RESPAWN_FORCE) && !(this.respawn_time < this.respawn_time_max))
2412                                                         this.deadflag = DEAD_RESPAWNING;
2413                                                 else if (!button_pressed || (time >= this.respawn_time_max && (this.respawn_flags & RESPAWN_FORCE)))
2414                                                         this.deadflag = DEAD_DEAD;
2415                                                 break;
2416                                         }
2417                                         case DEAD_DEAD:
2418                                         {
2419                                                 if (button_pressed)
2420                                                         this.deadflag = DEAD_RESPAWNABLE;
2421                                                 else if (time >= this.respawn_time_max && (this.respawn_flags & RESPAWN_FORCE))
2422                                                         this.deadflag = DEAD_RESPAWNING;
2423                                                 break;
2424                                         }
2425                                         case DEAD_RESPAWNABLE:
2426                                         {
2427                                                 if (!button_pressed || (this.respawn_flags & RESPAWN_FORCE))
2428                                                         this.deadflag = DEAD_RESPAWNING;
2429                                                 break;
2430                                         }
2431                                         case DEAD_RESPAWNING:
2432                                         {
2433                                                 if (time > this.respawn_time)
2434                                                 {
2435                                                         this.respawn_time = time + 1; // only retry once a second
2436                                                         this.respawn_time_max = this.respawn_time;
2437                                                         respawn(this);
2438                                                 }
2439                                                 break;
2440                                         }
2441                                 }
2442
2443                                 ShowRespawnCountdown(this);
2444
2445                                 if (this.respawn_flags & RESPAWN_SILENT)
2446                                         STAT(RESPAWN_TIME, this) = 0;
2447                                 else if ((this.respawn_flags & RESPAWN_FORCE) && this.respawn_time < this.respawn_time_max)
2448                                 {
2449                                         if (time < this.respawn_time)
2450                                                 STAT(RESPAWN_TIME, this) = this.respawn_time;
2451                                         else if (this.deadflag != DEAD_RESPAWNING)
2452                                                 STAT(RESPAWN_TIME, this) = -this.respawn_time_max;
2453                                 }
2454                                 else
2455                                         STAT(RESPAWN_TIME, this) = this.respawn_time;
2456                         }
2457
2458                         // if respawning, invert stat_respawn_time to indicate this, the client translates it
2459                         if (this.deadflag == DEAD_RESPAWNING && STAT(RESPAWN_TIME, this) > 0)
2460                                 STAT(RESPAWN_TIME, this) *= -1;
2461
2462                         return;
2463                 }
2464
2465                 this.prevorigin = this.origin;
2466
2467                 bool have_hook = false;
2468                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2469                 {
2470                         .entity weaponentity = weaponentities[slot];
2471                         if(this.(weaponentity).hook.state)
2472                         {
2473                                 have_hook = true;
2474                                 break;
2475                         }
2476                 }
2477                 bool do_crouch = PHYS_INPUT_BUTTON_CROUCH(this);
2478                 if (have_hook) {
2479                         do_crouch = false;
2480                 } else if (this.waterlevel >= WATERLEVEL_SWIMMING) {
2481                         do_crouch = false;
2482                 } else if (this.vehicle) {
2483                         do_crouch = false;
2484                 } else if (STAT(FROZEN, this)) {
2485                         do_crouch = false;
2486         }
2487
2488                 if (do_crouch) {
2489                         if (!this.crouch) {
2490                                 this.crouch = true;
2491                                 this.view_ofs = STAT(PL_CROUCH_VIEW_OFS, this);
2492                                 setsize(this, STAT(PL_CROUCH_MIN, this), STAT(PL_CROUCH_MAX, this));
2493                                 // setanim(this, this.anim_duck, false, true, true); // this anim is BROKEN anyway
2494                         }
2495                 } else if (this.crouch) {
2496             tracebox(this.origin, STAT(PL_MIN, this), STAT(PL_MAX, this), this.origin, false, this);
2497             if (!trace_startsolid) {
2498                 this.crouch = false;
2499                 this.view_ofs = STAT(PL_VIEW_OFS, this);
2500                 setsize(this, STAT(PL_MIN, this), STAT(PL_MAX, this));
2501             }
2502                 }
2503
2504                 FixPlayermodel(this);
2505
2506                 // LordHavoc: allow firing on move frames (sub-ticrate), this gives better timing on slow servers
2507                 //if(frametime)
2508                 {
2509                         this.items &= ~this.items_added;
2510
2511                         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2512                         {
2513                                 .entity weaponentity = weaponentities[slot];
2514                                 W_WeaponFrame(this, weaponentity);
2515
2516                                 if(slot == 0)
2517                                 {
2518                                         this.clip_load = this.(weaponentity).clip_load;
2519                                         this.clip_size = this.(weaponentity).clip_size;
2520                                 }
2521                         }
2522
2523                         this.items_added = 0;
2524                         if (this.items & ITEM_Jetpack.m_itemid && (this.items & ITEM_JetpackRegen.m_itemid || this.ammo_fuel >= 0.01))
2525                 this.items_added |= IT_FUEL;
2526
2527                         this.items |= this.items_added;
2528                 }
2529
2530                 player_regen(this);
2531
2532                 // WEAPONTODO: Add a weapon request for this
2533                 // rot vortex charge to the charge limit
2534                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2535                 {
2536                         .entity weaponentity = weaponentities[slot];
2537                         if (WEP_CVAR(vortex, charge_rot_rate) && this.(weaponentity).vortex_charge > WEP_CVAR(vortex, charge_limit) && this.(weaponentity).vortex_charge_rottime < time)
2538                                 this.(weaponentity).vortex_charge = bound(WEP_CVAR(vortex, charge_limit), this.(weaponentity).vortex_charge - WEP_CVAR(vortex, charge_rot_rate) * frametime / W_TICSPERFRAME, 1);
2539                 }
2540
2541                 if (frametime) player_anim(this);
2542
2543                 // secret status
2544                 secrets_setstatus(this);
2545
2546                 // monsters status
2547                 monsters_setstatus(this);
2548
2549                 this.dmg_team = max(0, this.dmg_team - autocvar_g_teamdamage_resetspeed * frametime);
2550         }
2551         else if (game_stopped || intermission_running) {
2552                 if(intermission_running)
2553                         IntermissionThink(this);
2554                 return;
2555         }
2556         else if (IS_OBSERVER(this)) {
2557                 ObserverThink(this);
2558         }
2559         else if (IS_SPEC(this)) {
2560                 SpectatorThink(this);
2561         }
2562
2563         // WEAPONTODO: Add weapon request for this
2564         if (!zoomstate_set) {
2565                 bool wep_zoomed = false;
2566                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2567                 {
2568                         .entity weaponentity = weaponentities[slot];
2569                         Weapon thiswep = this.(weaponentity).m_weapon;
2570                         if(thiswep != WEP_Null && thiswep.wr_zoom)
2571                                 wep_zoomed += thiswep.wr_zoom(thiswep, this);
2572                 }
2573                 SetZoomState(this, PHYS_INPUT_BUTTON_ZOOM(this) || PHYS_INPUT_BUTTON_ZOOMSCRIPT(this) || wep_zoomed);
2574     }
2575
2576         if (this.teamkill_soundtime && time > this.teamkill_soundtime)
2577         {
2578                 this.teamkill_soundtime = 0;
2579
2580                 entity e = this.teamkill_soundsource;
2581                 entity oldpusher = e.pusher;
2582                 e.pusher = this;
2583                 PlayerSound(e, playersound_teamshoot, CH_VOICE, VOL_BASEVOICE, VOICETYPE_LASTATTACKER_ONLY);
2584                 e.pusher = oldpusher;
2585         }
2586
2587         if (this.taunt_soundtime && time > this.taunt_soundtime) {
2588                 this.taunt_soundtime = 0;
2589                 PlayerSound(this, playersound_taunt, CH_VOICE, VOL_BASEVOICE, VOICETYPE_AUTOTAUNT);
2590         }
2591
2592         target_voicescript_next(this);
2593
2594         // WEAPONTODO: Move into weaponsystem somehow
2595         // if a player goes unarmed after holding a loaded weapon, empty his clip size and remove the crosshair ammo ring
2596         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2597         {
2598                 .entity weaponentity = weaponentities[slot];
2599                 if(this.(weaponentity).m_weapon == WEP_Null)
2600                         this.(weaponentity).clip_load = this.(weaponentity).clip_size = 0;
2601         }
2602 }
2603
2604 void DrownPlayer(entity this)
2605 {
2606         if(IS_DEAD(this))
2607                 return;
2608
2609         if (this.waterlevel != WATERLEVEL_SUBMERGED || this.vehicle)
2610         {
2611                 if(this.air_finished < time)
2612                         PlayerSound(this, playersound_gasp, CH_PLAYER, VOL_BASE, VOICETYPE_PLAYERSOUND);
2613                 this.air_finished = time + autocvar_g_balance_contents_drowndelay;
2614                 this.dmg = 2;
2615         }
2616         else if (this.air_finished < time)
2617         {       // drown!
2618                 if (this.pain_finished < time)
2619                 {
2620                         Damage (this, NULL, NULL, autocvar_g_balance_contents_playerdamage_drowning * autocvar_g_balance_contents_damagerate, DEATH_DROWN.m_id, this.origin, '0 0 0');
2621                         this.pain_finished = time + 0.5;
2622                 }
2623         }
2624 }
2625
2626 .bool move_qcphysics;
2627
2628 void Player_Physics(entity this)
2629 {
2630         set_movetype(this, this.move_movetype);
2631
2632         if(!this.move_qcphysics)
2633                 return;
2634
2635         if(!frametime && !this.pm_frametime)
2636                 return;
2637
2638         Movetype_Physics_NoMatchTicrate(this, this.pm_frametime, true);
2639
2640         this.pm_frametime = 0;
2641 }
2642
2643 /*
2644 =============
2645 PlayerPostThink
2646
2647 Called every frame for each client after the physics are run
2648 =============
2649 */
2650 .float idlekick_lasttimeleft;
2651 void PlayerPostThink (entity this)
2652 {
2653         Player_Physics(this);
2654
2655         if (sv_maxidle > 0)
2656         if (frametime) // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2657         if (IS_REAL_CLIENT(this))
2658         if (IS_PLAYER(this) || sv_maxidle_spectatorsareidle)
2659         {
2660                 int totalClients = 0;
2661                 if(sv_maxidle_slots > 0)
2662                 {
2663                         FOREACH_CLIENT(IS_REAL_CLIENT(it) || sv_maxidle_slots_countbots,
2664                         {
2665                                 ++totalClients;
2666                         });
2667                 }
2668
2669                 if (sv_maxidle_slots > 0 && (maxclients - totalClients) > sv_maxidle_slots)
2670                 { /* do nothing */ }
2671                 else if (time - this.parm_idlesince < 1) // instead of (time == this.parm_idlesince) to support sv_maxidle <= 10
2672                 {
2673                         if (this.idlekick_lasttimeleft)
2674                         {
2675                                 this.idlekick_lasttimeleft = 0;
2676                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_IDLING);
2677                         }
2678                 }
2679                 else
2680                 {
2681                         float timeleft = ceil(sv_maxidle - (time - this.parm_idlesince));
2682                         if (timeleft == min(10, sv_maxidle - 1)) { // - 1 to support sv_maxidle <= 10
2683                                 if (!this.idlekick_lasttimeleft)
2684                                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_DISCONNECT_IDLING, timeleft);
2685                         }
2686                         if (timeleft <= 0) {
2687                                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_QUIT_KICK_IDLING, this.netname);
2688                                 dropclient(this);
2689                                 return;
2690                         }
2691                         else if (timeleft <= 10) {
2692                                 if (timeleft != this.idlekick_lasttimeleft) {
2693                                     Send_Notification(NOTIF_ONE, this, MSG_ANNCE, Announcer_PickNumber(CNT_IDLE, timeleft));
2694                 }
2695                                 this.idlekick_lasttimeleft = timeleft;
2696                         }
2697                 }
2698         }
2699
2700         CheatFrame(this);
2701
2702         //CheckPlayerJump();
2703         if (game_stopped)
2704         {
2705                 this.solid = SOLID_NOT;
2706                 this.takedamage = DAMAGE_NO;
2707                 set_movetype(this, MOVETYPE_NONE);
2708         }
2709
2710         if (IS_PLAYER(this)) {
2711                 if(this.death_time == time && IS_DEAD(this))
2712                 {
2713                         this.maxs.z = 5;
2714                         setsize(this, this.mins, this.maxs);
2715                 }
2716                 DrownPlayer(this);
2717                 CheckRules_Player(this);
2718                 UpdateChatBubble(this);
2719                 if (this.impulse) ImpulseCommands(this);
2720                 if (game_stopped)
2721                 {
2722                         CSQCMODEL_AUTOUPDATE(this);
2723                         return;
2724                 }
2725                 GetPressedKeys(this);
2726         }
2727
2728         if (this.waypointsprite_attachedforcarrier) {
2729             vector v = healtharmor_maxdamage(this.health, this.armorvalue, autocvar_g_balance_armor_blockpercent, DEATH_WEAPON.m_id);
2730                 WaypointSprite_UpdateHealth(this.waypointsprite_attachedforcarrier, '1 0 0' * v);
2731     }
2732
2733         playerdemo_write(this);
2734
2735         CSQCMODEL_AUTOUPDATE(this);
2736 }