qcsrc/server/client.qc

   1 #include "client.qh"
   2
   3 #include <server/defs.qh>
   4 #include <server/miscfunctions.qh>
   5 #include <common/effects/all.qh>
   6 #include "anticheat.qh"
   7 #include "impulse.qh"
   8 #include "player.qh"
   9 #include "ipban.qh"
  10 #include "miscfunctions.qh"
  11 #include "portals.qh"
  12 #include "teamplay.qh"
  13 #include "spawnpoints.qh"
  14 #include "resources.qh"
  15 #include "g_damage.qh"
  16 #include "handicap.qh"
  17 #include "g_hook.qh"
  18 #include "command/common.qh"
  19 #include "command/vote.qh"
  20 #include "clientkill.qh"
  21 #include "cheats.qh"
  22 #include "g_world.qh"
  23 #include "race.qh"
  24 #include "antilag.qh"
  25 #include "campaign.qh"
  26 #include "command/common.qh"
  27 #include "scores_rules.qh"
  28 #include "weapons/common.qh"
  29
  30 #include "bot/api.qh"
  31
  32 #include "../common/ent_cs.qh"
  33 #include "../common/wepent.qh"
  34 #include <common/state.qh>
  35
  36 #include "compat/quake3.qh"
  37
  38 #include <common/effects/qc/globalsound.qh>
  39
  40 #include "../common/mapobjects/func/conveyor.qh"
  41 #include "../common/mapobjects/teleporters.qh"
  42 #include "../common/mapobjects/target/spawnpoint.qh"
  43 #include <common/mapobjects/trigger/counter.qh>
  44 #include <common/mapobjects/trigger/swamp.qh>
  45
  46 #include "../common/vehicles/all.qh"
  47
  48 #include "weapons/hitplot.qh"
  49 #include "weapons/weaponsystem.qh"
  50
  51 #include "../common/net_notice.qh"
  52 #include "../common/net_linked.qh"
  53 #include "../common/physics/player.qh"
  54
  55 #include <common/vehicles/sv_vehicles.qh>
  56
  57 #include "../common/items/_mod.qh"
  58
  59 #include "../common/mutators/mutator/waypoints/all.qh"
  60 #include "../common/mutators/mutator/instagib/sv_instagib.qh"
  61 #include <common/gamemodes/_mod.qh>
  62
  63 #include "../common/mapobjects/subs.qh"
  64 #include "../common/mapobjects/triggers.qh"
  65 #include "../common/mapobjects/trigger/secret.qh"
  66
  67 #include "../common/minigames/sv_minigames.qh"
  68
  69 #include "../common/items/inventory.qh"
  70
  71 #include "../common/monsters/sv_monsters.qh"
  72
  73 #include "../lib/warpzone/server.qh"
  74
  75 #include <common/mutators/mutator/overkill/oknex.qh>
  76
  77 STATIC_METHOD(Client, Add, void(Client this, int _team))
  78 {
  79     ClientConnect(this);
  80     TRANSMUTE(Player, this);
  81     this.frame = 12; // 7
  82     this.team = _team;
  83     PutClientInServer(this);
  84 }
  85
  86 STATIC_METHOD(Client, Remove, void(Client this))
  87 {
  88     TRANSMUTE(Observer, this);
  89     PutClientInServer(this);
  90     ClientDisconnect(this);
  91 }
  92
  93 void send_CSQC_teamnagger() {
  94         WriteHeader(MSG_BROADCAST, TE_CSQC_TEAMNAGGER);
  95 }
  96
  97 int CountSpectators(entity player, entity to)
  98 {
  99         if(!player) { return 0; } // not sure how, but best to be safe
 100
 101         int spec_count = 0;
 102
 103         FOREACH_CLIENT(IS_REAL_CLIENT(it) && IS_SPEC(it) && it != to && it.enemy == player,
 104         {
 105                 spec_count++;
 106         });
 107
 108         return spec_count;
 109 }
 110
 111 void WriteSpectators(entity player, entity to)
 112 {
 113         if(!player) { return; } // not sure how, but best to be safe
 114
 115         FOREACH_CLIENT(IS_REAL_CLIENT(it) && IS_SPEC(it) && it != to && it.enemy == player,
 116         {
 117                 WriteByte(MSG_ENTITY, num_for_edict(it));
 118         });
 119 }
 120
 121 bool ClientData_Send(entity this, entity to, int sf)
 122 {
 123         assert(to == this.owner, return false);
 124
 125         entity e = to;
 126         if (IS_SPEC(e)) e = e.enemy;
 127
 128         sf = 0;
 129         if (CS(e).race_completed)       sf |= BIT(0); // forced scoreboard
 130         if (CS(to).spectatee_status)    sf |= BIT(1); // spectator ent number follows
 131         if (CS(e).zoomstate)            sf |= BIT(2); // zoomed
 132         if (autocvar_sv_showspectators) sf |= BIT(4); // show spectators
 133
 134         WriteHeader(MSG_ENTITY, ENT_CLIENT_CLIENTDATA);
 135         WriteByte(MSG_ENTITY, sf);
 136
 137         if (sf & BIT(1))
 138                 WriteByte(MSG_ENTITY, CS(to).spectatee_status);
 139
 140         if(sf & BIT(4))
 141         {
 142                 float specs = CountSpectators(e, to);
 143                 WriteByte(MSG_ENTITY, specs);
 144                 WriteSpectators(e, to);
 145         }
 146
 147         return true;
 148 }
 149
 150 void ClientData_Attach(entity this)
 151 {
 152         Net_LinkEntity(CS(this).clientdata = new_pure(clientdata), false, 0, ClientData_Send);
 153         CS(this).clientdata.drawonlytoclient = this;
 154         CS(this).clientdata.owner = this;
 155 }
 156
 157 void ClientData_Detach(entity this)
 158 {
 159         delete(CS(this).clientdata);
 160         CS(this).clientdata = NULL;
 161 }
 162
 163 void ClientData_Touch(entity e)
 164 {
 165         entity cd = CS(e).clientdata;
 166         if (cd) { cd.SendFlags = 1; }
 167
 168         // make it spectatable
 169         FOREACH_CLIENT(IS_REAL_CLIENT(it) && it != e && IS_SPEC(it) && it.enemy == e,
 170         {
 171                 entity cd = CS(it).clientdata;
 172                 if (cd) { cd.SendFlags = 1; }
 173         });
 174 }
 175
 176
 177 /*
 178 =============
 179 CheckPlayerModel
 180
 181 Checks if the argument string can be a valid playermodel.
 182 Returns a valid one in doubt.
 183 =============
 184 */
 185 string FallbackPlayerModel;
 186 string CheckPlayerModel(string plyermodel) {
 187         if(FallbackPlayerModel != cvar_defstring("_cl_playermodel"))
 188         {
 189                 // note: we cannot summon Don Strunzone here, some player may
 190                 // still have the model string set. In case anyone manages how
 191                 // to change a cvar default, we'll have a small leak here.
 192                 FallbackPlayerModel = strzone(cvar_defstring("_cl_playermodel"));
 193         }
 194         // only in right path
 195         if( substring(plyermodel,0,14) != "models/player/")
 196                 return FallbackPlayerModel;
 197         // only good file extensions
 198         if(substring(plyermodel,-4,4) != ".zym")
 199         if(substring(plyermodel,-4,4) != ".dpm")
 200         if(substring(plyermodel,-4,4) != ".iqm")
 201         if(substring(plyermodel,-4,4) != ".md3")
 202         if(substring(plyermodel,-4,4) != ".psk")
 203                 return FallbackPlayerModel;
 204         // forbid the LOD models
 205         if(substring(plyermodel, -9,5) == "_lod1")
 206                 return FallbackPlayerModel;
 207         if(substring(plyermodel, -9,5) == "_lod2")
 208                 return FallbackPlayerModel;
 209         if(plyermodel != strtolower(plyermodel))
 210                 return FallbackPlayerModel;
 211         // also, restrict to server models
 212         if(autocvar_sv_servermodelsonly)
 213         {
 214                 if(!fexists(plyermodel))
 215                         return FallbackPlayerModel;
 216         }
 217         return plyermodel;
 218 }
 219
 220 void setplayermodel(entity e, string modelname)
 221 {
 222         precache_model(modelname);
 223         _setmodel(e, modelname);
 224         player_setupanimsformodel(e);
 225         if(!autocvar_g_debug_globalsounds)
 226                 UpdatePlayerSounds(e);
 227 }
 228
 229 /** putting a client as observer in the server */
 230 void PutObserverInServer(entity this)
 231 {
 232     bool mutator_returnvalue = MUTATOR_CALLHOOK(MakePlayerObserver, this);
 233         PlayerState_detach(this);
 234
 235         if (IS_PLAYER(this))
 236         {
 237                 if(GetResource(this, RES_HEALTH) >= 1)
 238                 {
 239                         // despawn effect
 240                         Send_Effect(EFFECT_SPAWN_NEUTRAL, this.origin, '0 0 0', 1);
 241                 }
 242
 243                 // was a player, recount votes and ready status
 244                 if(IS_REAL_CLIENT(this))
 245                 {
 246                         if (vote_called) { VoteCount(false); }
 247                         ReadyCount();
 248                 }
 249     }
 250
 251     {
 252         entity spot = SelectSpawnPoint(this, true);
 253         if (!spot) LOG_FATAL("No spawnpoints for observers?!?");
 254         this.angles = vec2(spot.angles);
 255         this.fixangle = true;
 256         // offset it so that the spectator spawns higher off the ground, looks better this way
 257         setorigin(this, spot.origin + STAT(PL_VIEW_OFS, this));
 258         if (IS_REAL_CLIENT(this))
 259         {
 260             msg_entity = this;
 261             WriteByte(MSG_ONE, SVC_SETVIEW);
 262             WriteEntity(MSG_ONE, this);
 263         }
 264         // give the spectator some space between walls for MOVETYPE_FLY_WORLDONLY
 265         // so that your view doesn't go into the ceiling with MOVETYPE_FLY_WORLDONLY, previously "PL_VIEW_OFS"
 266         if(!autocvar_g_debug_globalsounds)
 267         {
 268                 // needed for player sounds
 269                 this.model = "";
 270                 FixPlayermodel(this);
 271         }
 272         setmodel(this, MDL_Null);
 273         setsize(this, STAT(PL_CROUCH_MIN, this), STAT(PL_CROUCH_MAX, this));
 274         this.view_ofs = '0 0 0';
 275     }
 276
 277     RemoveGrapplingHooks(this);
 278         Portal_ClearAll(this);
 279         Unfreeze(this, false);
 280         SetSpectatee(this, NULL);
 281
 282         if (this.alivetime)
 283         {
 284                 if (!warmup_stage)
 285                         PlayerStats_GameReport_Event_Player(this, PLAYERSTATS_ALIVETIME, time - this.alivetime);
 286                 this.alivetime = 0;
 287         }
 288
 289         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
 290
 291         WaypointSprite_PlayerDead(this);
 292
 293         if (CS(this).killcount != FRAGS_SPECTATOR)
 294         {
 295                 if(!game_stopped)
 296                 if(autocvar_g_chat_nospectators == 1 || (!warmup_stage && autocvar_g_chat_nospectators == 2))
 297                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_CHAT_NOSPECTATORS);
 298         }
 299
 300         accuracy_resend(this);
 301
 302         CS(this).spectatortime = time;
 303         if(this.bot_attack)
 304                 IL_REMOVE(g_bot_targets, this);
 305         this.bot_attack = false;
 306         if(this.monster_attack)
 307                 IL_REMOVE(g_monster_targets, this);
 308         this.monster_attack = false;
 309     STAT(HUD, this) = HUD_NORMAL;
 310         TRANSMUTE(Observer, this);
 311         this.iscreature = false;
 312         this.teleportable = TELEPORT_SIMPLE;
 313         if(this.damagedbycontents)
 314                 IL_REMOVE(g_damagedbycontents, this);
 315         this.damagedbycontents = false;
 316         SetResourceExplicit(this, RES_HEALTH, FRAGS_SPECTATOR);
 317         SetSpectatee_status(this, etof(this));
 318         this.takedamage = DAMAGE_NO;
 319         this.solid = SOLID_NOT;
 320         set_movetype(this, MOVETYPE_FLY_WORLDONLY); // user preference is controlled by playerprethink
 321         this.flags = FL_CLIENT | FL_NOTARGET;
 322         this.effects = 0;
 323         SetResourceExplicit(this, RES_ARMOR, autocvar_g_balance_armor_start); // was 666?!
 324         this.pauserotarmor_finished = 0;
 325         this.pauserothealth_finished = 0;
 326         this.pauseregen_finished = 0;
 327         this.damageforcescale = 0;
 328         this.death_time = 0;
 329         this.respawn_flags = 0;
 330         this.respawn_time = 0;
 331         STAT(RESPAWN_TIME, this) = 0;
 332         this.alpha = 0;
 333         this.scale = 0;
 334         this.fade_time = 0;
 335         this.pain_frame = 0;
 336         this.pain_finished = 0;
 337         this.strength_finished = 0;
 338         this.invincible_finished = 0;
 339         this.superweapons_finished = 0;
 340         this.air_finished_stat = 0;
 341         //this.dphitcontentsmask = 0;
 342         this.dphitcontentsmask = DPCONTENTS_SOLID;
 343         if (autocvar_g_playerclip_collisions)
 344                 this.dphitcontentsmask |= DPCONTENTS_PLAYERCLIP;
 345         this.pushltime = 0;
 346         this.istypefrag = 0;
 347         setthink(this, func_null);
 348         this.nextthink = 0;
 349         this.deadflag = DEAD_NO;
 350         this.crouch = false;
 351         STAT(REVIVE_PROGRESS, this) = 0;
 352         this.revival_time = 0;
 353         this.draggable = drag_undraggable;
 354
 355         this.items = 0;
 356         STAT(WEAPONS, this) = '0 0 0';
 357         this.drawonlytoclient = this;
 358
 359         this.viewloc = NULL;
 360
 361         //this.spawnpoint_targ = NULL; // keep it so they can return to where they were?
 362
 363         this.weaponmodel = "";
 364         for (int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 365         {
 366                 this.weaponentities[slot] = NULL;
 367         }
 368         this.exteriorweaponentity = NULL;
 369         CS(this).killcount = FRAGS_SPECTATOR;
 370         this.velocity = '0 0 0';
 371         this.avelocity = '0 0 0';
 372         this.punchangle = '0 0 0';
 373         this.punchvector = '0 0 0';
 374         this.oldvelocity = this.velocity;
 375         this.fire_endtime = -1;
 376         this.event_damage = func_null;
 377         this.event_heal = func_null;
 378
 379         for(int slot = 0; slot < MAX_AXH; ++slot)
 380         {
 381                 entity axh = this.(AuxiliaryXhair[slot]);
 382                 this.(AuxiliaryXhair[slot]) = NULL;
 383
 384                 if(axh.owner == this && axh != NULL && !wasfreed(axh))
 385                         delete(axh);
 386         }
 387
 388         if (mutator_returnvalue)
 389         {
 390                 // mutator prevents resetting teams+score
 391         }
 392         else
 393         {
 394                 SetPlayerTeam(this, -1, TEAM_CHANGE_SPECTATOR);
 395                 this.frags = FRAGS_SPECTATOR;
 396         }
 397         if (CS(this).just_joined)
 398                 CS(this).just_joined = false;
 399 }
 400
 401 int player_getspecies(entity this)
 402 {
 403         get_model_parameters(this.model, this.skin);
 404         int s = get_model_parameters_species;
 405         get_model_parameters(string_null, 0);
 406         if (s < 0) return SPECIES_HUMAN;
 407         return s;
 408 }
 409
 410 .float model_randomizer;
 411 void FixPlayermodel(entity player)
 412 {
 413         string defaultmodel = "";
 414         int defaultskin = 0;
 415         if(autocvar_sv_defaultcharacter)
 416         {
 417                 if(teamplay)
 418                 {
 419                         switch(player.team)
 420                         {
 421                                 case NUM_TEAM_1: defaultmodel = autocvar_sv_defaultplayermodel_red; defaultskin = autocvar_sv_defaultplayerskin_red; break;
 422                                 case NUM_TEAM_2: defaultmodel = autocvar_sv_defaultplayermodel_blue; defaultskin = autocvar_sv_defaultplayerskin_blue; break;
 423                                 case NUM_TEAM_3: defaultmodel = autocvar_sv_defaultplayermodel_yellow; defaultskin = autocvar_sv_defaultplayerskin_yellow; break;
 424                                 case NUM_TEAM_4: defaultmodel = autocvar_sv_defaultplayermodel_pink; defaultskin = autocvar_sv_defaultplayerskin_pink; break;
 425                         }
 426                 }
 427
 428                 if(defaultmodel == "")
 429                 {
 430                         defaultmodel = autocvar_sv_defaultplayermodel;
 431                         defaultskin = autocvar_sv_defaultplayerskin;
 432                 }
 433
 434                 int n = tokenize_console(defaultmodel);
 435                 if(n > 0)
 436                 {
 437                         defaultmodel = argv(floor(n * CS(player).model_randomizer));
 438                         // However, do NOT randomize if the player-selected model is in the list.
 439                         for (int i = 0; i < n; ++i)
 440                                 if ((argv(i) == player.playermodel && defaultskin == stof(player.playerskin)) || argv(i) == strcat(player.playermodel, ":", player.playerskin))
 441                                         defaultmodel = argv(i);
 442                 }
 443
 444                 int i = strstrofs(defaultmodel, ":", 0);
 445                 if(i >= 0)
 446                 {
 447                         defaultskin = stof(substring(defaultmodel, i+1, -1));
 448                         defaultmodel = substring(defaultmodel, 0, i);
 449                 }
 450         }
 451         if(autocvar_sv_defaultcharacterskin && !defaultskin)
 452         {
 453                 if(teamplay)
 454                 {
 455                         switch(player.team)
 456                         {
 457                                 case NUM_TEAM_1: defaultskin = autocvar_sv_defaultplayerskin_red; break;
 458                                 case NUM_TEAM_2: defaultskin = autocvar_sv_defaultplayerskin_blue; break;
 459                                 case NUM_TEAM_3: defaultskin = autocvar_sv_defaultplayerskin_yellow; break;
 460                                 case NUM_TEAM_4: defaultskin = autocvar_sv_defaultplayerskin_pink; break;
 461                         }
 462                 }
 463
 464                 if(!defaultskin)
 465                         defaultskin = autocvar_sv_defaultplayerskin;
 466         }
 467
 468         MUTATOR_CALLHOOK(FixPlayermodel, defaultmodel, defaultskin, player);
 469         defaultmodel = M_ARGV(0, string);
 470         defaultskin = M_ARGV(1, int);
 471
 472         bool chmdl = false;
 473         int oldskin;
 474         if(defaultmodel != "")
 475         {
 476                 if (defaultmodel != player.model)
 477                 {
 478                         vector m1 = player.mins;
 479                         vector m2 = player.maxs;
 480                         setplayermodel (player, defaultmodel);
 481                         setsize (player, m1, m2);
 482                         chmdl = true;
 483                 }
 484
 485                 oldskin = player.skin;
 486                 player.skin = defaultskin;
 487         } else {
 488                 if (player.playermodel != player.model || player.playermodel == "")
 489                 {
 490                         player.playermodel = CheckPlayerModel(player.playermodel); // this is never "", so no endless loop
 491                         vector m1 = player.mins;
 492                         vector m2 = player.maxs;
 493                         setplayermodel (player, player.playermodel);
 494                         setsize (player, m1, m2);
 495                         chmdl = true;
 496                 }
 497
 498                 if(!autocvar_sv_defaultcharacterskin)
 499                 {
 500                         oldskin = player.skin;
 501                         player.skin = stof(player.playerskin);
 502                 }
 503                 else
 504                 {
 505                         oldskin = player.skin;
 506                         player.skin = defaultskin;
 507                 }
 508         }
 509
 510         if(chmdl || oldskin != player.skin) // model or skin has changed
 511         {
 512                 player.species = player_getspecies(player); // update species
 513                 if(!autocvar_g_debug_globalsounds)
 514                         UpdatePlayerSounds(player); // update skin sounds
 515         }
 516
 517         if(!teamplay)
 518                 if(strlen(autocvar_sv_defaultplayercolors))
 519                         if(player.clientcolors != stof(autocvar_sv_defaultplayercolors))
 520                                 setcolor(player, stof(autocvar_sv_defaultplayercolors));
 521 }
 522
 523 void PutPlayerInServer(entity this)
 524 {
 525         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
 526
 527         PlayerState_attach(this);
 528         accuracy_resend(this);
 529
 530         if (this.team < 0)
 531                 TeamBalance_JoinBestTeam(this);
 532
 533         entity spot = SelectSpawnPoint(this, false);
 534         if (!spot) {
 535                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_JOIN_NOSPAWNS);
 536                 return; // spawn failed
 537         }
 538
 539         TRANSMUTE(Player, this);
 540
 541         CS(this).wasplayer = true;
 542         this.iscreature = true;
 543         this.teleportable = TELEPORT_NORMAL;
 544         if(!this.damagedbycontents)
 545                 IL_PUSH(g_damagedbycontents, this);
 546         this.damagedbycontents = true;
 547         set_movetype(this, MOVETYPE_WALK);
 548         this.solid = SOLID_SLIDEBOX;
 549         this.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_SOLID;
 550         if (autocvar_g_playerclip_collisions)
 551                 this.dphitcontentsmask |= DPCONTENTS_PLAYERCLIP;
 552         if (IS_BOT_CLIENT(this) && autocvar_g_botclip_collisions)
 553                 this.dphitcontentsmask |= DPCONTENTS_BOTCLIP;
 554         this.frags = FRAGS_PLAYER;
 555         if (INDEPENDENT_PLAYERS) MAKE_INDEPENDENT_PLAYER(this);
 556         this.flags = FL_CLIENT | FL_PICKUPITEMS;
 557         if (autocvar__notarget)
 558                 this.flags |= FL_NOTARGET;
 559         this.takedamage = DAMAGE_AIM;
 560         this.effects = EF_TELEPORT_BIT | EF_RESTARTANIM_BIT;
 561
 562         if (warmup_stage) {
 563                 SetResource(this, RES_SHELLS, warmup_start_ammo_shells);
 564                 SetResource(this, RES_BULLETS, warmup_start_ammo_nails);
 565                 SetResource(this, RES_ROCKETS, warmup_start_ammo_rockets);
 566                 SetResource(this, RES_CELLS, warmup_start_ammo_cells);
 567                 SetResource(this, RES_PLASMA, warmup_start_ammo_plasma);
 568                 SetResource(this, RES_FUEL, warmup_start_ammo_fuel);
 569                 SetResource(this, RES_HEALTH, warmup_start_health);
 570                 SetResource(this, RES_ARMOR, warmup_start_armorvalue);
 571                 STAT(WEAPONS, this) = WARMUP_START_WEAPONS;
 572         } else {
 573                 SetResource(this, RES_SHELLS, start_ammo_shells);
 574                 SetResource(this, RES_BULLETS, start_ammo_nails);
 575                 SetResource(this, RES_ROCKETS, start_ammo_rockets);
 576                 SetResource(this, RES_CELLS, start_ammo_cells);
 577                 SetResource(this, RES_PLASMA, start_ammo_plasma);
 578                 SetResource(this, RES_FUEL, start_ammo_fuel);
 579                 SetResource(this, RES_HEALTH, start_health);
 580                 SetResource(this, RES_ARMOR, start_armorvalue);
 581                 STAT(WEAPONS, this) = start_weapons;
 582                 if (MUTATOR_CALLHOOK(ForbidRandomStartWeapons, this) == false)
 583                 {
 584                         GiveRandomWeapons(this, random_start_weapons_count,
 585                                 autocvar_g_random_start_weapons, random_start_ammo);
 586                 }
 587         }
 588         SetSpectatee_status(this, 0);
 589
 590         PS(this).dual_weapons = '0 0 0';
 591
 592         this.superweapons_finished = (STAT(WEAPONS, this) & WEPSET_SUPERWEAPONS) ? time + autocvar_g_balance_superweapons_time : 0;
 593
 594         this.items = start_items;
 595
 596         this.spawnshieldtime = time + autocvar_g_spawnshieldtime;
 597         this.pauserotarmor_finished = time + autocvar_g_balance_pause_armor_rot_spawn;
 598         this.pauserothealth_finished = time + autocvar_g_balance_pause_health_rot_spawn;
 599         this.pauserotfuel_finished = time + autocvar_g_balance_pause_fuel_rot_spawn;
 600         this.pauseregen_finished = time + autocvar_g_balance_pause_health_regen_spawn;
 601         if (!sv_ready_restart_after_countdown && time < game_starttime)
 602         {
 603                 float f = game_starttime - time;
 604                 this.spawnshieldtime += f;
 605                 this.pauserotarmor_finished += f;
 606                 this.pauserothealth_finished += f;
 607                 this.pauseregen_finished += f;
 608         }
 609
 610         this.damageforcescale = autocvar_g_player_damageforcescale;
 611         this.death_time = 0;
 612         this.respawn_flags = 0;
 613         this.respawn_time = 0;
 614         STAT(RESPAWN_TIME, this) = 0;
 615         bool q3dfcompat = autocvar_sv_q3defragcompat && autocvar_sv_q3defragcompat_changehitbox;
 616         this.scale = ((q3dfcompat) ? 0.9 : autocvar_sv_player_scale);
 617         this.fade_time = 0;
 618         this.pain_frame = 0;
 619         this.pain_finished = 0;
 620         this.pushltime = 0;
 621         setthink(this, func_null); // players have no think function
 622         this.nextthink = 0;
 623         this.dmg_team = 0;
 624         PS(this).ballistics_density = autocvar_g_ballistics_density_player;
 625
 626         this.deadflag = DEAD_NO;
 627
 628         this.angles = spot.angles;
 629         this.angles_z = 0; // never spawn tilted even if the spot says to
 630         if (IS_BOT_CLIENT(this))
 631         {
 632                 this.v_angle = this.angles;
 633                 bot_aim_reset(this);
 634         }
 635         this.fixangle = true; // turn this way immediately
 636         this.oldvelocity = this.velocity = '0 0 0';
 637         this.avelocity = '0 0 0';
 638         this.punchangle = '0 0 0';
 639         this.punchvector = '0 0 0';
 640
 641         this.strength_finished = 0;
 642         this.invincible_finished = 0;
 643         this.fire_endtime = -1;
 644         STAT(REVIVE_PROGRESS, this) = 0;
 645         this.revival_time = 0;
 646
 647         // TODO: we can't set these in the PlayerSpawn hook since the target code is called before it!
 648         STAT(BUFFS, this) = 0;
 649         STAT(BUFF_TIME, this) = 0;
 650
 651         this.air_finished = time + autocvar_g_balance_contents_drowndelay;
 652         this.waterlevel = WATERLEVEL_NONE;
 653         this.watertype = CONTENT_EMPTY;
 654
 655         entity spawnevent = new_pure(spawnevent);
 656         spawnevent.owner = this;
 657         Net_LinkEntity(spawnevent, false, 0.5, SpawnEvent_Send);
 658
 659         // Cut off any still running player sounds.
 660         stopsound(this, CH_PLAYER_SINGLE);
 661
 662         this.model = "";
 663         FixPlayermodel(this);
 664         this.drawonlytoclient = NULL;
 665
 666         this.viewloc = NULL;
 667
 668         for(int slot = 0; slot < MAX_AXH; ++slot)
 669         {
 670                 entity axh = this.(AuxiliaryXhair[slot]);
 671                 this.(AuxiliaryXhair[slot]) = NULL;
 672
 673                 if(axh.owner == this && axh != NULL && !wasfreed(axh))
 674                         delete(axh);
 675         }
 676
 677         this.spawnpoint_targ = NULL;
 678
 679         this.crouch = false;
 680         this.view_ofs = STAT(PL_VIEW_OFS, this);
 681         setsize(this, STAT(PL_MIN, this), STAT(PL_MAX, this));
 682         this.spawnorigin = spot.origin;
 683         setorigin(this, spot.origin + '0 0 1' * (1 - this.mins.z - 24));
 684         // don't reset back to last position, even if new position is stuck in solid
 685         this.oldorigin = this.origin;
 686         if(this.conveyor)
 687                 IL_REMOVE(g_conveyed, this);
 688         this.conveyor = NULL; // prevent conveyors at the previous location from moving a freshly spawned player
 689         if(this.swampslug)
 690                 delete(this.swampslug);
 691         this.in_swamp = false;
 692         STAT(HUD, this) = HUD_NORMAL;
 693
 694         this.event_damage = PlayerDamage;
 695         this.event_heal = PlayerHeal;
 696
 697         this.draggable = func_null;
 698
 699         if(!this.bot_attack)
 700                 IL_PUSH(g_bot_targets, this);
 701         this.bot_attack = true;
 702         if(!this.monster_attack)
 703                 IL_PUSH(g_monster_targets, this);
 704         this.monster_attack = true;
 705         navigation_dynamicgoal_init(this, false);
 706
 707         PHYS_INPUT_BUTTON_ATCK(this) = PHYS_INPUT_BUTTON_JUMP(this) = PHYS_INPUT_BUTTON_ATCK2(this) = false;
 708
 709         // player was spectator
 710         if (CS(this).killcount == FRAGS_SPECTATOR) {
 711                 PlayerScore_Clear(this);
 712                 CS(this).killcount = 0;
 713                 CS(this).startplaytime = time;
 714         }
 715
 716         for (int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 717         {
 718                 .entity weaponentity = weaponentities[slot];
 719                 CL_SpawnWeaponentity(this, weaponentity);
 720         }
 721         this.alpha = default_player_alpha;
 722         this.colormod = '1 1 1' * autocvar_g_player_brightness;
 723         this.exteriorweaponentity.alpha = default_weapon_alpha;
 724
 725         this.speedrunning = false;
 726
 727         this.counter_cnt = 0;
 728         this.fragsfilter_cnt = 0;
 729
 730         target_voicescript_clear(this);
 731
 732         // reset fields the weapons may use
 733         FOREACH(Weapons, true, {
 734                 it.wr_resetplayer(it, this);
 735                         // reload all reloadable weapons
 736                 if (it.spawnflags & WEP_FLAG_RELOADABLE) {
 737                         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 738                         {
 739                                 .entity weaponentity = weaponentities[slot];
 740                                 this.(weaponentity).weapon_load[it.m_id] = it.reloading_ammo;
 741                         }
 742                 }
 743         });
 744
 745         {
 746                 string s = spot.target;
 747                 if(g_assault || g_race) // TODO: make targeting work in assault & race without this hack
 748                         spot.target = string_null;
 749                 SUB_UseTargets(spot, this, NULL);
 750                 if(g_assault || g_race)
 751                         spot.target = s;
 752         }
 753
 754         Unfreeze(this, false);
 755
 756         MUTATOR_CALLHOOK(PlayerSpawn, this, spot);
 757
 758         if (autocvar_spawn_debug)
 759         {
 760                 sprint(this, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
 761                 delete(spot); // usefull for checking if there are spawnpoints, that let drop through the floor
 762         }
 763
 764         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 765         {
 766                 .entity weaponentity = weaponentities[slot];
 767                 if(slot == 0 || autocvar_g_weaponswitch_debug == 1)
 768                         this.(weaponentity).m_switchweapon = w_getbestweapon(this, weaponentity);
 769                 else
 770                         this.(weaponentity).m_switchweapon = WEP_Null;
 771                 this.(weaponentity).m_weapon = WEP_Null;
 772                 this.(weaponentity).weaponname = "";
 773                 this.(weaponentity).m_switchingweapon = WEP_Null;
 774                 this.(weaponentity).cnt = -1;
 775         }
 776
 777         MUTATOR_CALLHOOK(PlayerWeaponSelect, this);
 778
 779         if (CS(this).impulse) ImpulseCommands(this);
 780
 781         W_ResetGunAlign(this, CS(this).cvar_cl_gunalign);
 782         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 783         {
 784                 .entity weaponentity = weaponentities[slot];
 785                 W_WeaponFrame(this, weaponentity);
 786         }
 787
 788         if (!warmup_stage && !this.alivetime)
 789                 this.alivetime = time;
 790
 791         antilag_clear(this, CS(this));
 792 }
 793
 794 /** Called when a client spawns in the server */
 795 void PutClientInServer(entity this)
 796 {
 797         if (IS_BOT_CLIENT(this)) {
 798                 TRANSMUTE(Player, this);
 799         } else if (IS_REAL_CLIENT(this)) {
 800                 msg_entity = this;
 801                 WriteByte(MSG_ONE, SVC_SETVIEW);
 802                 WriteEntity(MSG_ONE, this);
 803         }
 804         if (game_stopped)
 805                 TRANSMUTE(Observer, this);
 806
 807         SetSpectatee(this, NULL);
 808
 809         // reset player keys
 810         if(PS(this))
 811                 PS(this).itemkeys = 0;
 812
 813         MUTATOR_CALLHOOK(PutClientInServer, this);
 814
 815         if (IS_OBSERVER(this)) {
 816                 PutObserverInServer(this);
 817         } else if (IS_PLAYER(this)) {
 818                 PutPlayerInServer(this);
 819         }
 820 }
 821
 822 // TODO do we need all these fields, or should we stop autodetecting runtime
 823 // changes and just have a console command to update this?
 824 bool ClientInit_SendEntity(entity this, entity to, int sf)
 825 {
 826         WriteHeader(MSG_ENTITY, _ENT_CLIENT_INIT);
 827         return = true;
 828         msg_entity = to;
 829         // MSG_INIT replacement
 830         // TODO: make easier to use
 831         Registry_send_all();
 832         W_PROP_reload(MSG_ONE, to);
 833         ClientInit_misc(this);
 834         MUTATOR_CALLHOOK(Ent_Init);
 835 }
 836 void ClientInit_misc(entity this)
 837 {
 838         int channel = MSG_ONE;
 839         WriteHeader(channel, ENT_CLIENT_INIT);
 840         WriteByte(channel, g_nexball_meter_period * 32);
 841         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[0]));
 842         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[1]));
 843         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[2]));
 844         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[3]));
 845         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[0]));
 846         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[1]));
 847         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[2]));
 848         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[3]));
 849
 850         if(sv_foginterval && world.fog != "")
 851                 WriteString(channel, world.fog);
 852         else
 853                 WriteString(channel, "");
 854         WriteByte(channel, this.count * 255.0); // g_balance_armor_blockpercent
 855         WriteByte(channel, this.cnt * 255.0); // g_balance_damagepush_speedfactor
 856         WriteByte(channel, serverflags);
 857         WriteCoord(channel, autocvar_g_trueaim_minrange);
 858 }
 859
 860 void ClientInit_CheckUpdate(entity this)
 861 {
 862         this.nextthink = time;
 863         if(this.count != autocvar_g_balance_armor_blockpercent)
 864         {
 865                 this.count = autocvar_g_balance_armor_blockpercent;
 866                 this.SendFlags |= 1;
 867         }
 868         if(this.cnt != autocvar_g_balance_damagepush_speedfactor)
 869         {
 870                 this.cnt = autocvar_g_balance_damagepush_speedfactor;
 871                 this.SendFlags |= 1;
 872         }
 873 }
 874
 875 void ClientInit_Spawn()
 876 {
 877         entity e = new_pure(clientinit);
 878         setthink(e, ClientInit_CheckUpdate);
 879         Net_LinkEntity(e, false, 0, ClientInit_SendEntity);
 880
 881         ClientInit_CheckUpdate(e);
 882 }
 883
 884 /*
 885 =============
 886 SetNewParms
 887 =============
 888 */
 889 void SetNewParms ()
 890 {
 891         // initialize parms for a new player
 892         parm1 = -(86400 * 366);
 893
 894         MUTATOR_CALLHOOK(SetNewParms);
 895 }
 896
 897 /*
 898 =============
 899 SetChangeParms
 900 =============
 901 */
 902 void SetChangeParms (entity this)
 903 {
 904         // save parms for level change
 905         parm1 = CS(this).parm_idlesince - time;
 906
 907         MUTATOR_CALLHOOK(SetChangeParms);
 908 }
 909
 910 /*
 911 =============
 912 DecodeLevelParms
 913 =============
 914 */
 915 void DecodeLevelParms(entity this)
 916 {
 917         // load parms
 918         CS(this).parm_idlesince = parm1;
 919         if (CS(this).parm_idlesince == -(86400 * 366))
 920                 CS(this).parm_idlesince = time;
 921
 922         // whatever happens, allow 60 seconds of idling directly after connect for map loading
 923         CS(this).parm_idlesince = max(CS(this).parm_idlesince, time - sv_maxidle + 60);
 924
 925         MUTATOR_CALLHOOK(DecodeLevelParms);
 926 }
 927
 928 void FixClientCvars(entity e)
 929 {
 930         // send prediction settings to the client
 931         stuffcmd(e, "\nin_bindmap 0 0\n");
 932         if(autocvar_g_antilag == 3) // client side hitscan
 933                 stuffcmd(e, "cl_cmd settemp cl_prydoncursor_notrace 0\n");
 934         if(autocvar_sv_gentle)
 935                 stuffcmd(e, "cl_cmd settemp cl_gentle 1\n");
 936
 937         stuffcmd(e, sprintf("\ncl_jumpspeedcap_min \"%s\"\n", autocvar_sv_jumpspeedcap_min));
 938         stuffcmd(e, sprintf("\ncl_jumpspeedcap_max \"%s\"\n", autocvar_sv_jumpspeedcap_max));
 939
 940         stuffcmd(e, sprintf("\ncl_shootfromfixedorigin \"%s\"\n", autocvar_g_shootfromfixedorigin));
 941
 942         MUTATOR_CALLHOOK(FixClientCvars, e);
 943 }
 944
 945 bool findinlist_abbrev(string tofind, string list)
 946 {
 947         if(list == "" || tofind == "")
 948                 return false; // empty list or search, just return
 949
 950         // this function allows abbreviated strings!
 951         FOREACH_WORD(list, it == substring(tofind, 0, strlen(it)),
 952         {
 953                 return true;
 954         });
 955
 956         return false;
 957 }
 958
 959 bool PlayerInIPList(entity p, string iplist)
 960 {
 961         // some safety checks (never allow local?)
 962         if(p.netaddress == "local" || p.netaddress == "" || !IS_REAL_CLIENT(p))
 963                 return false;
 964
 965         return findinlist_abbrev(p.netaddress, iplist);
 966 }
 967
 968 bool PlayerInIDList(entity p, string idlist)
 969 {
 970         // NOTE: we do NOT check crypto_idfp_signed here, an unsigned ID is fine too for this
 971         if(!p.crypto_idfp)
 972                 return false;
 973
 974         return findinlist_abbrev(p.crypto_idfp, idlist);
 975 }
 976
 977 bool PlayerInList(entity player, string list)
 978 {
 979         return boolean(PlayerInIDList(player, list) || PlayerInIPList(player, list));
 980 }
 981
 982 #ifdef DP_EXT_PRECONNECT
 983 /*
 984 =============
 985 ClientPreConnect
 986
 987 Called once (not at each match start) when a client begins a connection to the server
 988 =============
 989 */
 990 void ClientPreConnect(entity this)
 991 {
 992         if(autocvar_sv_eventlog)
 993         {
 994                 GameLogEcho(sprintf(":connect:%d:%d:%s",
 995                         this.playerid,
 996                         etof(this),
 997                         ((IS_REAL_CLIENT(this)) ? this.netaddress : "bot")
 998                 ));
 999         }
1000 }
1001 #endif
1002
1003 string GetClientVersionMessage(entity this)
1004 {
1005         if (CS(this).version_mismatch) {
1006                 if(CS(this).version < autocvar_gameversion) {
1007                         return strcat("This is Xonotic ", autocvar_g_xonoticversion,
1008                                 "\n^3Your client version is outdated.\n\n\n### YOU WON'T BE ABLE TO PLAY ON THIS SERVER ###\n\n\nPlease update!!!^8");
1009                 } else {
1010                         return strcat("This is Xonotic ", autocvar_g_xonoticversion,
1011                                 "\n^3This server is using an outdated Xonotic version.\n\n\n ### THIS SERVER IS INCOMPATIBLE AND THUS YOU CANNOT JOIN ###.^8");
1012                 }
1013         } else {
1014                 return strcat("Welcome to Xonotic ", autocvar_g_xonoticversion);
1015         }
1016 }
1017
1018 string getwelcomemessage(entity this)
1019 {
1020         MUTATOR_CALLHOOK(BuildMutatorsPrettyString, "");
1021         string modifications = M_ARGV(0, string);
1022
1023         if(g_weaponarena)
1024         {
1025                 if(g_weaponarena_random)
1026                         modifications = strcat(modifications, ", ", ftos(g_weaponarena_random), " of ", g_weaponarena_list, " Arena");
1027                 else
1028                         modifications = strcat(modifications, ", ", g_weaponarena_list, " Arena");
1029         }
1030         else if(cvar("g_balance_blaster_weaponstartoverride") == 0)
1031                 modifications = strcat(modifications, ", No start weapons");
1032         if(cvar("sv_gravity") < stof(cvar_defstring("sv_gravity")))
1033                 modifications = strcat(modifications, ", Low gravity");
1034         if(g_weapon_stay && !g_cts)
1035                 modifications = strcat(modifications, ", Weapons stay");
1036         if(g_jetpack)
1037                 modifications = strcat(modifications, ", Jet pack");
1038         if(autocvar_g_powerups == 0)
1039                 modifications = strcat(modifications, ", No powerups");
1040         if(autocvar_g_powerups > 0)
1041                 modifications = strcat(modifications, ", Powerups");
1042         modifications = substring(modifications, 2, strlen(modifications) - 2);
1043
1044         string versionmessage = GetClientVersionMessage(this);
1045         string s = strcat(versionmessage, "^8\n^8\nmatch type is ^1", gamemode_name, "^8\n");
1046
1047         if(modifications != "")
1048                 s = strcat(s, "^8\nactive modifications: ^3", modifications, "^8\n");
1049
1050         if(cache_lastmutatormsg != autocvar_g_mutatormsg)
1051         {
1052                 strcpy(cache_lastmutatormsg, autocvar_g_mutatormsg);
1053                 strcpy(cache_mutatormsg, cache_lastmutatormsg);
1054         }
1055
1056         if (cache_mutatormsg != "") {
1057                 s = strcat(s, "\n\n^8special gameplay tips: ^7", cache_mutatormsg);
1058         }
1059
1060         string mutator_msg = "";
1061         MUTATOR_CALLHOOK(BuildGameplayTipsString, mutator_msg);
1062         mutator_msg = M_ARGV(0, string);
1063
1064         s = strcat(s, mutator_msg); // trust that the mutator will do proper formatting
1065
1066         string motd = autocvar_sv_motd;
1067         if (motd != "") {
1068                 s = strcat(s, "\n\n^8MOTD: ^7", strreplace("\\n", "\n", motd));
1069         }
1070         return s;
1071 }
1072
1073 bool autocvar_sv_qcphysics = true; // TODO this is for testing - remove when qcphysics work
1074
1075 /**
1076 =============
1077 ClientConnect
1078
1079 Called when a client connects to the server
1080 =============
1081 */
1082 void ClientConnect(entity this)
1083 {
1084         if (Ban_MaybeEnforceBanOnce(this)) return;
1085         assert(!IS_CLIENT(this), return);
1086         this.flags |= FL_CLIENT;
1087         assert(player_count >= 0, player_count = 0);
1088
1089 #ifdef WATERMARK
1090         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_WATERMARK, WATERMARK);
1091 #endif
1092         TRANSMUTE(Client, this);
1093         CS(this).version_nagtime = time + 10 + random() * 10;
1094
1095         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_JOIN_CONNECT, this.netname);
1096
1097         bot_clientconnect(this);
1098
1099         Player_DetermineForcedTeam(this);
1100
1101         TRANSMUTE(Observer, this);
1102
1103         PlayerStats_GameReport_AddEvent(sprintf("kills-%d", this.playerid));
1104
1105         // always track bots, don't ask for cl_allow_uidtracking
1106         if (IS_BOT_CLIENT(this))
1107                 PlayerStats_GameReport_AddPlayer(this);
1108         else
1109                 CS(this).allowed_timeouts = autocvar_sv_timeout_number;
1110
1111         if (autocvar_sv_eventlog)
1112                 GameLogEcho(strcat(":join:", ftos(this.playerid), ":", ftos(etof(this)), ":", ((IS_REAL_CLIENT(this)) ? GameLog_ProcessIP(this.netaddress) : "bot"), ":", playername(this, false)));
1113
1114         CS(this).just_joined = true;  // stop spamming the eventlog with additional lines when the client connects
1115
1116         stuffcmd(this, clientstuff, "\n");
1117         stuffcmd(this, "cl_particles_reloadeffects\n"); // TODO do we still need this?
1118
1119         FixClientCvars(this);
1120
1121         // get version info from player
1122         stuffcmd(this, "cmd clientversion $gameversion\n");
1123
1124         // notify about available teams
1125         if (teamplay)
1126         {
1127                 entity balance = TeamBalance_CheckAllowedTeams(this);
1128                 int t = TeamBalance_GetAllowedTeams(balance);
1129                 TeamBalance_Destroy(balance);
1130                 stuffcmd(this, sprintf("set _teams_available %d\n", t));
1131         }
1132         else
1133         {
1134                 stuffcmd(this, "set _teams_available 0\n");
1135         }
1136
1137         bot_relinkplayerlist();
1138
1139         CS(this).spectatortime = time;
1140         if (blockSpectators)
1141         {
1142                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
1143         }
1144
1145         CS(this).jointime = time;
1146
1147         if (IS_REAL_CLIENT(this))
1148         {
1149                 if (g_weaponarena_weapons == WEPSET(TUBA))
1150                         stuffcmd(this, "cl_cmd settemp chase_active 1\n");
1151         }
1152
1153         if (!sv_foginterval && world.fog != "")
1154                 stuffcmd(this, strcat("\nfog ", world.fog, "\nr_fog_exp2 0\nr_drawfog 1\n"));
1155
1156         if (autocvar_sv_teamnagger && !(autocvar_bot_vs_human && AvailableTeams() == 2))
1157                 if(!MUTATOR_CALLHOOK(HideTeamNagger, this))
1158                         send_CSQC_teamnagger();
1159
1160         CSQCMODEL_AUTOINIT(this);
1161
1162         CS(this).model_randomizer = random();
1163
1164         if (IS_REAL_CLIENT(this))
1165                 sv_notice_join(this);
1166
1167         this.move_qcphysics = autocvar_sv_qcphysics;
1168
1169         // update physics stats (players can spawn before physics runs)
1170         Physics_UpdateStats(this);
1171
1172         IL_EACH(g_initforplayer, it.init_for_player, {
1173                 it.init_for_player(it, this);
1174         });
1175
1176         Handicap_Initialize(this);
1177
1178         MUTATOR_CALLHOOK(ClientConnect, this);
1179
1180         if (IS_REAL_CLIENT(this))
1181         {
1182                 if (!autocvar_g_campaign && !IS_PLAYER(this))
1183                 {
1184                         CS(this).motd_actived_time = -1;
1185                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOTD, getwelcomemessage(this));
1186                 }
1187         }
1188 }
1189 /*
1190 =============
1191 ClientDisconnect
1192
1193 Called when a client disconnects from the server
1194 =============
1195 */
1196 .entity chatbubbleentity;
1197 void ClientDisconnect(entity this)
1198 {
1199         assert(IS_CLIENT(this), return);
1200
1201         PlayerStats_GameReport_FinalizePlayer(this);
1202         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
1203         if (CS(this).active_minigame) part_minigame(this);
1204         if (IS_PLAYER(this)) Send_Effect(EFFECT_SPAWN_NEUTRAL, this.origin, '0 0 0', 1);
1205
1206         if (autocvar_sv_eventlog)
1207                 GameLogEcho(strcat(":part:", ftos(this.playerid)));
1208
1209         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_QUIT_DISCONNECT, this.netname);
1210
1211         if(IS_SPEC(this))
1212                 SetSpectatee(this, NULL);
1213
1214     MUTATOR_CALLHOOK(ClientDisconnect, this);
1215
1216         strfree(CS(this).netname_previous); // needs to be before the CS entity is removed!
1217         strfree(CS(this).weaponorder_byimpulse);
1218         ClientState_detach(this);
1219
1220         Portal_ClearAll(this);
1221
1222         Unfreeze(this, false);
1223
1224         RemoveGrapplingHooks(this);
1225
1226         // Here, everything has been done that requires this player to be a client.
1227
1228         this.flags &= ~FL_CLIENT;
1229
1230         if (this.chatbubbleentity) delete(this.chatbubbleentity);
1231         if (this.killindicator) delete(this.killindicator);
1232
1233         WaypointSprite_PlayerGone(this);
1234
1235         bot_relinkplayerlist();
1236
1237         strfree(this.clientstatus);
1238         if (this.personal) delete(this.personal);
1239
1240         this.playerid = 0;
1241         ReadyCount();
1242         if (vote_called && IS_REAL_CLIENT(this)) VoteCount(false);
1243
1244         ONREMOVE(this);
1245 }
1246
1247 void ChatBubbleThink(entity this)
1248 {
1249         this.nextthink = time;
1250         if ((this.owner.alpha < 0) || this.owner.chatbubbleentity != this)
1251         {
1252                 if(this.owner) // but why can that ever be NULL?
1253                         this.owner.chatbubbleentity = NULL;
1254                 delete(this);
1255                 return;
1256         }
1257
1258         this.mdl = "";
1259
1260         if ( !IS_DEAD(this.owner) && IS_PLAYER(this.owner) )
1261         {
1262                 if ( CS(this.owner).active_minigame && PHYS_INPUT_BUTTON_MINIGAME(this.owner) )
1263                         this.mdl = "models/sprites/minigame_busy.iqm";
1264                 else if (PHYS_INPUT_BUTTON_CHAT(this.owner))
1265                         this.mdl = "models/misc/chatbubble.spr";
1266         }
1267
1268         if ( this.model != this.mdl )
1269                 _setmodel(this, this.mdl);
1270
1271 }
1272
1273 void UpdateChatBubble(entity this)
1274 {
1275         if (this.alpha < 0)
1276                 return;
1277         // spawn a chatbubble entity if needed
1278         if (!this.chatbubbleentity)
1279         {
1280                 this.chatbubbleentity = new(chatbubbleentity);
1281                 this.chatbubbleentity.owner = this;
1282                 this.chatbubbleentity.exteriormodeltoclient = this;
1283                 setthink(this.chatbubbleentity, ChatBubbleThink);
1284                 this.chatbubbleentity.nextthink = time;
1285                 setmodel(this.chatbubbleentity, MDL_CHAT); // precision set below
1286                 //setorigin(this.chatbubbleentity, this.origin + '0 0 15' + this.maxs_z * '0 0 1');
1287                 setorigin(this.chatbubbleentity, '0 0 15' + this.maxs_z * '0 0 1');
1288                 setattachment(this.chatbubbleentity, this, "");  // sticks to moving player better, also conserves bandwidth
1289                 this.chatbubbleentity.mdl = this.chatbubbleentity.model;
1290                 //this.chatbubbleentity.model = "";
1291                 this.chatbubbleentity.effects = EF_LOWPRECISION;
1292         }
1293 }
1294
1295
1296 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
1297 // added to the model skins
1298 /*void UpdateColorModHack()
1299 {
1300         float c;
1301         c = this.clientcolors & 15;
1302         // LordHavoc: only bothering to support white, green, red, yellow, blue
1303              if (!teamplay) this.colormod = '0 0 0';
1304         else if (c ==  0) this.colormod = '1.00 1.00 1.00';
1305         else if (c ==  3) this.colormod = '0.10 1.73 0.10';
1306         else if (c ==  4) this.colormod = '1.73 0.10 0.10';
1307         else if (c == 12) this.colormod = '1.22 1.22 0.10';
1308         else if (c == 13) this.colormod = '0.10 0.10 1.73';
1309         else this.colormod = '1 1 1';
1310 }*/
1311
1312 void respawn(entity this)
1313 {
1314         if(this.alpha >= 0 && autocvar_g_respawn_ghosts)
1315         {
1316                 this.solid = SOLID_NOT;
1317                 this.takedamage = DAMAGE_NO;
1318                 set_movetype(this, MOVETYPE_FLY);
1319                 this.velocity = '0 0 1' * autocvar_g_respawn_ghosts_speed;
1320                 this.avelocity = randomvec() * autocvar_g_respawn_ghosts_speed * 3 - randomvec() * autocvar_g_respawn_ghosts_speed * 3;
1321                 this.effects |= CSQCMODEL_EF_RESPAWNGHOST;
1322                 Send_Effect(EFFECT_RESPAWN_GHOST, this.origin, '0 0 0', 1);
1323                 if(autocvar_g_respawn_ghosts_maxtime)
1324                         SUB_SetFade (this, time + autocvar_g_respawn_ghosts_maxtime / 2 + random () * (autocvar_g_respawn_ghosts_maxtime - autocvar_g_respawn_ghosts_maxtime / 2), 1.5);
1325         }
1326
1327         CopyBody(this, 1);
1328
1329         this.effects |= EF_NODRAW; // prevent another CopyBody
1330         PutClientInServer(this);
1331 }
1332
1333 ERASEABLE
1334 void PrintToChat(entity client, string text)
1335 {
1336         text = strcat("\{1}^7", text, "\n");
1337         sprint(client, text);
1338 }
1339
1340 ERASEABLE
1341 void DebugPrintToChat(entity client, string text)
1342 {
1343         if (autocvar_developer > 0)
1344         {
1345                 PrintToChat(client, text);
1346         }
1347 }
1348
1349 ERASEABLE
1350 void PrintToChatAll(string text)
1351 {
1352         text = strcat("\{1}^7", text, "\n");
1353         bprint(text);
1354 }
1355
1356 ERASEABLE
1357 void DebugPrintToChatAll(string text)
1358 {
1359         if (autocvar_developer > 0)
1360         {
1361                 PrintToChatAll(text);
1362         }
1363 }
1364
1365 ERASEABLE
1366 void PrintToChatTeam(int team_num, string text)
1367 {
1368         text = strcat("\{1}^7", text, "\n");
1369         FOREACH_CLIENT(IS_REAL_CLIENT(it),
1370         {
1371                 if (it.team == team_num)
1372                 {
1373                         sprint(it, text);
1374                 }
1375         });
1376 }
1377
1378 ERASEABLE
1379 void DebugPrintToChatTeam(int team_num, string text)
1380 {
1381         if (autocvar_developer > 0)
1382         {
1383                 PrintToChatTeam(team_num, text);
1384         }
1385 }
1386
1387 void play_countdown(entity this, float finished, Sound samp)
1388 {
1389         TC(Sound, samp);
1390         if(IS_REAL_CLIENT(this))
1391                 if(floor(finished - time - frametime) != floor(finished - time))
1392                         if(finished - time < 6)
1393                                 sound (this, CH_INFO, samp, VOL_BASE, ATTEN_NORM);
1394 }
1395
1396 void player_powerups(entity this)
1397 {
1398         // add a way to see what the items were BEFORE all of these checks for the mutator hook
1399         int items_prev = this.items;
1400
1401         if((this.items & IT_USING_JETPACK) && !IS_DEAD(this) && !game_stopped)
1402                 this.modelflags |= MF_ROCKET;
1403         else
1404                 this.modelflags &= ~MF_ROCKET;
1405
1406         this.effects &= ~(EF_RED | EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT | EF_FLAME | EF_NODEPTHTEST);
1407
1408         if((this.alpha < 0 || IS_DEAD(this)) && !this.vehicle) // don't apply the flags if the player is gibbed
1409                 return;
1410
1411         Fire_ApplyDamage(this);
1412         Fire_ApplyEffect(this);
1413
1414         if (!MUTATOR_IS_ENABLED(mutator_instagib))
1415         {
1416                 if (this.items & ITEM_Strength.m_itemid)
1417                 {
1418                         play_countdown(this, this.strength_finished, SND_POWEROFF);
1419                         this.effects = this.effects | (EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT);
1420                         if (time > this.strength_finished)
1421                         {
1422                                 this.items = this.items - (this.items & ITEM_Strength.m_itemid);
1423                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERDOWN_STRENGTH, this.netname);
1424                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERDOWN_STRENGTH);
1425                         }
1426                 }
1427                 else
1428                 {
1429                         if (time < this.strength_finished)
1430                         {
1431                                 this.items = this.items | ITEM_Strength.m_itemid;
1432                                 if(!g_cts)
1433                                         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERUP_STRENGTH, this.netname);
1434                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERUP_STRENGTH);
1435                         }
1436                 }
1437                 if (this.items & ITEM_Shield.m_itemid)
1438                 {
1439                         play_countdown(this, this.invincible_finished, SND_POWEROFF);
1440                         this.effects = this.effects | (EF_RED | EF_ADDITIVE | EF_FULLBRIGHT);
1441                         if (time > this.invincible_finished)
1442                         {
1443                                 this.items = this.items - (this.items & ITEM_Shield.m_itemid);
1444                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERDOWN_SHIELD, this.netname);
1445                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERDOWN_SHIELD);
1446                         }
1447                 }
1448                 else
1449                 {
1450                         if (time < this.invincible_finished)
1451                         {
1452                                 this.items = this.items | ITEM_Shield.m_itemid;
1453                                 if(!g_cts)
1454                                         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERUP_SHIELD, this.netname);
1455                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERUP_SHIELD);
1456                         }
1457                 }
1458                 if (this.items & IT_SUPERWEAPON)
1459                 {
1460                         if (!(STAT(WEAPONS, this) & WEPSET_SUPERWEAPONS))
1461                         {
1462                                 this.superweapons_finished = 0;
1463                                 this.items = this.items - (this.items & IT_SUPERWEAPON);
1464                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_LOST, this.netname);
1465                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_LOST);
1466                         }
1467                         else if (this.items & IT_UNLIMITED_SUPERWEAPONS)
1468                         {
1469                                 // don't let them run out
1470                         }
1471                         else
1472                         {
1473                                 play_countdown(this, this.superweapons_finished, SND_POWEROFF);
1474                                 if (time > this.superweapons_finished)
1475                                 {
1476                                         this.items = this.items - (this.items & IT_SUPERWEAPON);
1477                                         STAT(WEAPONS, this) &= ~WEPSET_SUPERWEAPONS;
1478                                         //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_BROKEN, this.netname);
1479                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_BROKEN);
1480                                 }
1481                         }
1482                 }
1483                 else if(STAT(WEAPONS, this) & WEPSET_SUPERWEAPONS)
1484                 {
1485                         if (time < this.superweapons_finished || (this.items & IT_UNLIMITED_SUPERWEAPONS))
1486                         {
1487                                 this.items = this.items | IT_SUPERWEAPON;
1488                                 if(!(this.items & IT_UNLIMITED_SUPERWEAPONS))
1489                                 {
1490                                         if(!g_cts)
1491                                                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_PICKUP, this.netname);
1492                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_PICKUP);
1493                                 }
1494                         }
1495                         else
1496                         {
1497                                 this.superweapons_finished = 0;
1498                                 STAT(WEAPONS, this) &= ~WEPSET_SUPERWEAPONS;
1499                         }
1500                 }
1501                 else
1502                 {
1503                         this.superweapons_finished = 0;
1504                 }
1505         }
1506
1507         if(autocvar_g_nodepthtestplayers)
1508                 this.effects = this.effects | EF_NODEPTHTEST;
1509
1510         if(autocvar_g_fullbrightplayers)
1511                 this.effects = this.effects | EF_FULLBRIGHT;
1512
1513         if (time >= game_starttime)
1514         if (time < this.spawnshieldtime)
1515                 this.effects = this.effects | (EF_ADDITIVE | EF_FULLBRIGHT);
1516
1517         MUTATOR_CALLHOOK(PlayerPowerups, this, items_prev);
1518 }
1519
1520 float CalcRegen(float current, float stable, float regenfactor, float regenframetime)
1521 {
1522         if(current > stable)
1523                 return current;
1524         else if(current > stable - 0.25) // when close enough, "snap"
1525                 return stable;
1526         else
1527                 return min(stable, current + (stable - current) * regenfactor * regenframetime);
1528 }
1529
1530 float CalcRot(float current, float stable, float rotfactor, float rotframetime)
1531 {
1532         if(current < stable)
1533                 return current;
1534         else if(current < stable + 0.25) // when close enough, "snap"
1535                 return stable;
1536         else
1537                 return max(stable, current + (stable - current) * rotfactor * rotframetime);
1538 }
1539
1540 float CalcRotRegen(float current, float regenstable, float regenfactor, float regenlinear, float regenframetime, float rotstable, float rotfactor, float rotlinear, float rotframetime, float limit)
1541 {
1542         if(current > rotstable)
1543         {
1544                 if(rotframetime > 0)
1545                 {
1546                         current = CalcRot(current, rotstable, rotfactor, rotframetime);
1547                         current = max(rotstable, current - rotlinear * rotframetime);
1548                 }
1549         }
1550         else if(current < regenstable)
1551         {
1552                 if(regenframetime > 0)
1553                 {
1554                         current = CalcRegen(current, regenstable, regenfactor, regenframetime);
1555                         current = min(regenstable, current + regenlinear * regenframetime);
1556                 }
1557         }
1558
1559         if(current > limit)
1560                 current = limit;
1561
1562         return current;
1563 }
1564
1565 void player_regen(entity this)
1566 {
1567         float max_mod, regen_mod, rot_mod, limit_mod;
1568         max_mod = regen_mod = rot_mod = limit_mod = 1;
1569
1570         float regen_health = autocvar_g_balance_health_regen;
1571         float regen_health_linear = autocvar_g_balance_health_regenlinear;
1572         float regen_health_rot = autocvar_g_balance_health_rot;
1573         float regen_health_rotlinear = autocvar_g_balance_health_rotlinear;
1574         float regen_health_stable = autocvar_g_balance_health_regenstable;
1575         float regen_health_rotstable = autocvar_g_balance_health_rotstable;
1576         bool mutator_returnvalue = MUTATOR_CALLHOOK(PlayerRegen, this, max_mod, regen_mod, rot_mod, limit_mod, regen_health, regen_health_linear, regen_health_rot,
1577                 regen_health_rotlinear, regen_health_stable, regen_health_rotstable);
1578         max_mod = M_ARGV(1, float);
1579         regen_mod = M_ARGV(2, float);
1580         rot_mod = M_ARGV(3, float);
1581         limit_mod = M_ARGV(4, float);
1582         regen_health = M_ARGV(5, float);
1583         regen_health_linear = M_ARGV(6, float);
1584         regen_health_rot = M_ARGV(7, float);
1585         regen_health_rotlinear = M_ARGV(8, float);
1586         regen_health_stable = M_ARGV(9, float);
1587         regen_health_rotstable = M_ARGV(10, float);
1588
1589         if(!mutator_returnvalue)
1590         if(!STAT(FROZEN, this))
1591         {
1592                 float mina, maxa, limith, limita;
1593                 maxa = autocvar_g_balance_armor_rotstable;
1594                 mina = autocvar_g_balance_armor_regenstable;
1595                 limith = GetResourceLimit(this, RES_HEALTH);
1596                 limita = GetResourceLimit(this, RES_ARMOR);
1597
1598                 regen_health_rotstable = regen_health_rotstable * max_mod;
1599                 regen_health_stable = regen_health_stable * max_mod;
1600                 limith = limith * limit_mod;
1601                 limita = limita * limit_mod;
1602
1603                 SetResource(this, RES_ARMOR, CalcRotRegen(GetResource(this, RES_ARMOR), mina, autocvar_g_balance_armor_regen, autocvar_g_balance_armor_regenlinear,
1604                                                                         regen_mod * frametime * (time > this.pauseregen_finished), maxa, autocvar_g_balance_armor_rot, autocvar_g_balance_armor_rotlinear,
1605                                                                         rot_mod * frametime * (time > this.pauserotarmor_finished), limita));
1606                 SetResource(this, RES_HEALTH, CalcRotRegen(GetResource(this, RES_HEALTH), regen_health_stable, regen_health, regen_health_linear,
1607                                                                         regen_mod * frametime * (time > this.pauseregen_finished), regen_health_rotstable, regen_health_rot, regen_health_rotlinear,
1608                                                                         rot_mod * frametime * (time > this.pauserothealth_finished), limith));
1609         }
1610
1611         // if player rotted to death...  die!
1612         // check this outside above checks, as player may still be able to rot to death
1613         if(GetResource(this, RES_HEALTH) < 1)
1614         {
1615                 if(this.vehicle)
1616                         vehicles_exit(this.vehicle, VHEF_RELEASE);
1617                 if(this.event_damage)
1618                         this.event_damage(this, this, this, 1, DEATH_ROT.m_id, DMG_NOWEP, this.origin, '0 0 0');
1619         }
1620
1621         if (!(this.items & IT_UNLIMITED_AMMO))
1622         {
1623                 float minf, maxf, limitf;
1624
1625                 maxf = autocvar_g_balance_fuel_rotstable;
1626                 minf = autocvar_g_balance_fuel_regenstable;
1627                 limitf = GetResourceLimit(this, RES_FUEL);
1628
1629                 SetResource(this, RES_FUEL, CalcRotRegen(GetResource(this, RES_FUEL), minf, autocvar_g_balance_fuel_regen, autocvar_g_balance_fuel_regenlinear,
1630                                                                                 frametime * (time > this.pauseregen_finished) * ((this.items & ITEM_JetpackRegen.m_itemid) != 0),
1631                                                                                 maxf, autocvar_g_balance_fuel_rot, autocvar_g_balance_fuel_rotlinear, frametime * (time > this.pauserotfuel_finished), limitf));
1632         }
1633 }
1634
1635 bool zoomstate_set;
1636 void SetZoomState(entity this, float newzoom)
1637 {
1638         if(newzoom != CS(this).zoomstate)
1639         {
1640                 CS(this).zoomstate = newzoom;
1641                 ClientData_Touch(this);
1642         }
1643         zoomstate_set = true;
1644 }
1645
1646 void GetPressedKeys(entity this)
1647 {
1648         MUTATOR_CALLHOOK(GetPressedKeys, this);
1649         int keys = STAT(PRESSED_KEYS, this);
1650         keys = BITSET(keys, KEY_FORWARD,        CS(this).movement.x > 0);
1651         keys = BITSET(keys, KEY_BACKWARD,       CS(this).movement.x < 0);
1652         keys = BITSET(keys, KEY_RIGHT,          CS(this).movement.y > 0);
1653         keys = BITSET(keys, KEY_LEFT,           CS(this).movement.y < 0);
1654
1655         keys = BITSET(keys, KEY_JUMP,           PHYS_INPUT_BUTTON_JUMP(this));
1656         keys = BITSET(keys, KEY_CROUCH,         IS_DUCKED(this)); // workaround: player can't un-crouch until their path is clear, so we keep the button held here
1657         keys = BITSET(keys, KEY_ATCK,           PHYS_INPUT_BUTTON_ATCK(this));
1658         keys = BITSET(keys, KEY_ATCK2,          PHYS_INPUT_BUTTON_ATCK2(this));
1659         CS(this).pressedkeys = keys; // store for other users
1660
1661         STAT(PRESSED_KEYS, this) = keys;
1662 }
1663
1664 /*
1665 ======================
1666 spectate mode routines
1667 ======================
1668 */
1669
1670 void SpectateCopy(entity this, entity spectatee)
1671 {
1672         TC(Client, this); TC(Client, spectatee);
1673
1674         MUTATOR_CALLHOOK(SpectateCopy, spectatee, this);
1675         PS(this) = PS(spectatee);
1676         this.armortype = spectatee.armortype;
1677         SetResourceExplicit(this, RES_ARMOR, GetResource(spectatee, RES_ARMOR));
1678         SetResourceExplicit(this, RES_CELLS, GetResource(spectatee, RES_CELLS));
1679         SetResourceExplicit(this, RES_PLASMA, GetResource(spectatee, RES_PLASMA));
1680         SetResourceExplicit(this, RES_SHELLS, GetResource(spectatee, RES_SHELLS));
1681         SetResourceExplicit(this, RES_BULLETS, GetResource(spectatee, RES_BULLETS));
1682         SetResourceExplicit(this, RES_ROCKETS, GetResource(spectatee, RES_ROCKETS));
1683         SetResourceExplicit(this, RES_FUEL, GetResource(spectatee, RES_FUEL));
1684         this.effects = spectatee.effects & EFMASK_CHEAP; // eat performance
1685         SetResourceExplicit(this, RES_HEALTH, GetResource(spectatee, RES_HEALTH));
1686         CS(this).impulse = 0;
1687         this.disableclientprediction = 1; // no need to run prediction on a spectator
1688         this.items = spectatee.items;
1689         STAT(LAST_PICKUP, this) = STAT(LAST_PICKUP, spectatee);
1690         STAT(HIT_TIME, this) = STAT(HIT_TIME, spectatee);
1691         this.strength_finished = spectatee.strength_finished;
1692         this.invincible_finished = spectatee.invincible_finished;
1693         this.superweapons_finished = spectatee.superweapons_finished;
1694         this.air_finished_stat = spectatee.air_finished_stat;
1695         STAT(PRESSED_KEYS, this) = STAT(PRESSED_KEYS, spectatee);
1696         STAT(WEAPONS, this) = STAT(WEAPONS, spectatee);
1697         this.punchangle = spectatee.punchangle;
1698         this.view_ofs = spectatee.view_ofs;
1699         this.velocity = spectatee.velocity;
1700         this.dmg_take = spectatee.dmg_take;
1701         this.dmg_save = spectatee.dmg_save;
1702         this.dmg_inflictor = spectatee.dmg_inflictor;
1703         this.v_angle = spectatee.v_angle;
1704         this.angles = spectatee.v_angle;
1705         STAT(FROZEN, this) = STAT(FROZEN, spectatee);
1706         STAT(REVIVE_PROGRESS, this) = STAT(REVIVE_PROGRESS, spectatee);
1707         this.viewloc = spectatee.viewloc;
1708         if(!PHYS_INPUT_BUTTON_USE(this) && STAT(CAMERA_SPECTATOR, this) != 2)
1709                 this.fixangle = true;
1710         setorigin(this, spectatee.origin);
1711         setsize(this, spectatee.mins, spectatee.maxs);
1712         SetZoomState(this, CS(spectatee).zoomstate);
1713
1714     anticheat_spectatecopy(this, spectatee);
1715         STAT(HUD, this) = STAT(HUD, spectatee);
1716         if(spectatee.vehicle)
1717     {
1718         this.angles = spectatee.v_angle;
1719
1720         //this.fixangle = false;
1721         //this.velocity = spectatee.vehicle.velocity;
1722         this.vehicle_health = spectatee.vehicle_health;
1723         this.vehicle_shield = spectatee.vehicle_shield;
1724         this.vehicle_energy = spectatee.vehicle_energy;
1725         this.vehicle_ammo1 = spectatee.vehicle_ammo1;
1726         this.vehicle_ammo2 = spectatee.vehicle_ammo2;
1727         this.vehicle_reload1 = spectatee.vehicle_reload1;
1728         this.vehicle_reload2 = spectatee.vehicle_reload2;
1729
1730         //msg_entity = this;
1731
1732        // WriteByte (MSG_ONE, SVC_SETVIEWANGLES);
1733             //WriteAngle(MSG_ONE,  spectatee.v_angle.x);
1734            // WriteAngle(MSG_ONE,  spectatee.v_angle.y);
1735            // WriteAngle(MSG_ONE,  spectatee.v_angle.z);
1736
1737         //WriteByte (MSG_ONE, SVC_SETVIEW);
1738         //    WriteEntity(MSG_ONE, this);
1739         //makevectors(spectatee.v_angle);
1740         //setorigin(this, spectatee.origin - v_forward * 400 + v_up * 300);*/
1741     }
1742 }
1743
1744 bool SpectateUpdate(entity this)
1745 {
1746         if(!this.enemy)
1747                 return false;
1748
1749         if(!IS_PLAYER(this.enemy) || this == this.enemy)
1750         {
1751                 SetSpectatee(this, NULL);
1752                 return false;
1753         }
1754
1755         SpectateCopy(this, this.enemy);
1756
1757         return true;
1758 }
1759
1760 bool SpectateSet(entity this)
1761 {
1762         if(!IS_PLAYER(this.enemy))
1763                 return false;
1764
1765         ClientData_Touch(this.enemy);
1766
1767         msg_entity = this;
1768         WriteByte(MSG_ONE, SVC_SETVIEW);
1769         WriteEntity(MSG_ONE, this.enemy);
1770         set_movetype(this, MOVETYPE_NONE);
1771         accuracy_resend(this);
1772
1773         if(!SpectateUpdate(this))
1774                 PutObserverInServer(this);
1775
1776         return true;
1777 }
1778
1779 void SetSpectatee_status(entity this, int spectatee_num)
1780 {
1781         int oldspectatee_status = CS(this).spectatee_status;
1782         CS(this).spectatee_status = spectatee_num;
1783
1784         if (CS(this).spectatee_status != oldspectatee_status)
1785         {
1786                 if (STAT(PRESSED_KEYS, this))
1787                 {
1788                         CS(this).pressedkeys = 0;
1789                         STAT(PRESSED_KEYS, this) = 0;
1790                 }
1791                 ClientData_Touch(this);
1792                 if (g_race || g_cts) race_InitSpectator();
1793         }
1794 }
1795
1796 void SetSpectatee(entity this, entity spectatee)
1797 {
1798         if(IS_BOT_CLIENT(this))
1799                 return; // bots abuse .enemy, this code is useless to them
1800
1801         entity old_spectatee = this.enemy;
1802
1803         this.enemy = spectatee;
1804
1805         // WEAPONTODO
1806         // these are required to fix the spectator bug with arc
1807         if(old_spectatee)
1808         {
1809                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1810                 {
1811                         .entity weaponentity = weaponentities[slot];
1812                         if(old_spectatee.(weaponentity).arc_beam)
1813                                 old_spectatee.(weaponentity).arc_beam.SendFlags |= ARC_SF_SETTINGS;
1814                 }
1815         }
1816         if(this.enemy)
1817         {
1818                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1819                 {
1820                         .entity weaponentity = weaponentities[slot];
1821                         if(this.enemy.(weaponentity).arc_beam)
1822                                 this.enemy.(weaponentity).arc_beam.SendFlags |= ARC_SF_SETTINGS;
1823                 }
1824         }
1825
1826         if (this.enemy)
1827                 SetSpectatee_status(this, etof(this.enemy));
1828
1829         // needed to update spectator list
1830         if(old_spectatee) { ClientData_Touch(old_spectatee); }
1831 }
1832
1833 bool Spectate(entity this, entity pl)
1834 {
1835         if(MUTATOR_CALLHOOK(SpectateSet, this, pl))
1836                 return false;
1837         pl = M_ARGV(1, entity);
1838
1839         SetSpectatee(this, pl);
1840         return SpectateSet(this);
1841 }
1842
1843 bool SpectateNext(entity this)
1844 {
1845         entity ent = find(this.enemy, classname, STR_PLAYER);
1846
1847         if (MUTATOR_CALLHOOK(SpectateNext, this, ent))
1848                 ent = M_ARGV(1, entity);
1849         else if (!ent)
1850                 ent = find(ent, classname, STR_PLAYER);
1851
1852         if(ent) { SetSpectatee(this, ent); }
1853
1854         return SpectateSet(this);
1855 }
1856
1857 bool SpectatePrev(entity this)
1858 {
1859         // NOTE: chain order is from the highest to the lower entnum (unlike find)
1860         entity ent = findchain(classname, STR_PLAYER);
1861         if (!ent) // no player
1862                 return false;
1863
1864         entity first = ent;
1865         // skip players until current spectated player
1866         if(this.enemy)
1867         while(ent && ent != this.enemy)
1868                 ent = ent.chain;
1869
1870         switch (MUTATOR_CALLHOOK(SpectatePrev, this, ent, first))
1871         {
1872                 case MUT_SPECPREV_FOUND:
1873                     ent = M_ARGV(1, entity);
1874                     break;
1875                 case MUT_SPECPREV_RETURN:
1876                     return true;
1877                 case MUT_SPECPREV_CONTINUE:
1878                 default:
1879                 {
1880                         if(ent.chain)
1881                                 ent = ent.chain;
1882                         else
1883                                 ent = first;
1884                         break;
1885                 }
1886         }
1887
1888         SetSpectatee(this, ent);
1889         return SpectateSet(this);
1890 }
1891
1892 /*
1893 =============
1894 ShowRespawnCountdown()
1895
1896 Update a respawn countdown display.
1897 =============
1898 */
1899 void ShowRespawnCountdown(entity this)
1900 {
1901         float number;
1902         if(!IS_DEAD(this)) // just respawned?
1903                 return;
1904         else
1905         {
1906                 number = ceil(this.respawn_time - time);
1907                 if(number <= 0)
1908                         return;
1909                 if(number <= this.respawn_countdown)
1910                 {
1911                         this.respawn_countdown = number - 1;
1912                         if(ceil(this.respawn_time - (time + 0.5)) == number) // only say it if it is the same number even in 0.5s; to prevent overlapping sounds
1913                                 { Send_Notification(NOTIF_ONE, this, MSG_ANNCE, Announcer_PickNumber(CNT_RESPAWN, number)); }
1914                 }
1915         }
1916 }
1917
1918 .bool team_selected;
1919 bool ShowTeamSelection(entity this)
1920 {
1921         if (!teamplay || autocvar_g_campaign || autocvar_g_balance_teams || this.team_selected || (CS(this).wasplayer && autocvar_g_changeteam_banned) || Player_HasRealForcedTeam(this))
1922                 return false;
1923         stuffcmd(this, "menu_showteamselect\n");
1924         return true;
1925 }
1926 void Join(entity this)
1927 {
1928         TRANSMUTE(Player, this);
1929
1930         if(!this.team_selected)
1931         if(autocvar_g_campaign || autocvar_g_balance_teams)
1932                 TeamBalance_JoinBestTeam(this);
1933
1934         if(autocvar_g_campaign)
1935                 campaign_bots_may_start = true;
1936
1937         Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_PREVENT_JOIN);
1938
1939         PutClientInServer(this);
1940
1941         if(IS_PLAYER(this))
1942         if(teamplay && this.team != -1)
1943         {
1944         }
1945         else
1946                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_JOIN_PLAY, this.netname);
1947         this.team_selected = false;
1948 }
1949
1950 int GetPlayerLimit()
1951 {
1952         int player_limit = autocvar_g_maxplayers;
1953         MUTATOR_CALLHOOK(GetPlayerLimit, player_limit);
1954         player_limit = M_ARGV(0, int);
1955         return player_limit;
1956 }
1957
1958 /**
1959  * Determines whether the player is allowed to join. This depends on cvar
1960  * g_maxplayers, if it isn't used this function always return true, otherwise
1961  * it checks whether the number of currently playing players exceeds g_maxplayers.
1962  * @return int number of free slots for players, 0 if none
1963  */
1964 int nJoinAllowed(entity this, entity ignore)
1965 {
1966         if(!ignore)
1967         // this is called that way when checking if anyone may be able to join (to build qcstatus)
1968         // so report 0 free slots if restricted
1969         {
1970                 if(autocvar_g_forced_team_otherwise == "spectate")
1971                         return 0;
1972                 if(autocvar_g_forced_team_otherwise == "spectator")
1973                         return 0;
1974         }
1975
1976         if(this && (Player_GetForcedTeamIndex(this) == TEAM_FORCE_SPECTATOR))
1977                 return 0; // forced spectators can never join
1978
1979         // TODO simplify this
1980         int totalClients = 0;
1981         int currentlyPlaying = 0;
1982         FOREACH_CLIENT(true, {
1983                 if(it != ignore)
1984                         ++totalClients;
1985                 if(IS_REAL_CLIENT(it))
1986                 if(IS_PLAYER(it) || it.caplayer)
1987                         ++currentlyPlaying;
1988         });
1989
1990         int player_limit = GetPlayerLimit();
1991
1992         float free_slots = 0;
1993         if (!player_limit)
1994                 free_slots = maxclients - totalClients;
1995         else if(currentlyPlaying < player_limit)
1996                 free_slots = min(maxclients - totalClients, player_limit - currentlyPlaying);
1997
1998         static float join_prevent_msg_time = 0;
1999         if(this && ignore && !free_slots && time > join_prevent_msg_time)
2000         {
2001                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_JOIN_PREVENT);
2002                 join_prevent_msg_time = time + 3;
2003         }
2004
2005         return free_slots;
2006 }
2007
2008 /**
2009  * Checks whether the client is an observer or spectator, if so, he will get kicked after
2010  * g_maxplayers_spectator_blocktime seconds
2011  */
2012 void checkSpectatorBlock(entity this)
2013 {
2014         if(IS_SPEC(this) || IS_OBSERVER(this))
2015         if(!this.caplayer)
2016         if(IS_REAL_CLIENT(this))
2017         {
2018                 if( time > (CS(this).spectatortime + autocvar_g_maxplayers_spectator_blocktime) ) {
2019                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_QUIT_KICK_SPECTATING);
2020                         dropclient(this);
2021                 }
2022         }
2023 }
2024
2025 void PrintWelcomeMessage(entity this)
2026 {
2027         if(CS(this).motd_actived_time == 0)
2028         {
2029                 if (autocvar_g_campaign) {
2030                         if ((IS_PLAYER(this) && PHYS_INPUT_BUTTON_INFO(this)) || (!IS_PLAYER(this))) {
2031                                 CS(this).motd_actived_time = time;
2032                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_CAMPAIGN_MESSAGE, Campaign_GetMessage(), Campaign_GetLevelNum());
2033                         }
2034                 } else {
2035                         if (PHYS_INPUT_BUTTON_INFO(this)) {
2036                                 CS(this).motd_actived_time = time;
2037                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOTD, getwelcomemessage(this));
2038                         }
2039                 }
2040         }
2041         else if(CS(this).motd_actived_time > 0) // showing MOTD or campaign message
2042         {
2043                 if (autocvar_g_campaign) {
2044                         if (PHYS_INPUT_BUTTON_INFO(this))
2045                                 CS(this).motd_actived_time = time;
2046                         else if ((time - CS(this).motd_actived_time > 2) && IS_PLAYER(this)) { // hide it some seconds after BUTTON_INFO has been released
2047                                 CS(this).motd_actived_time = 0;
2048                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_CAMPAIGN_MESSAGE);
2049                         }
2050                 } else {
2051                         if (PHYS_INPUT_BUTTON_INFO(this))
2052                                 CS(this).motd_actived_time = time;
2053                         else if (time - CS(this).motd_actived_time > 2) { // hide it some seconds after BUTTON_INFO has been released
2054                                 CS(this).motd_actived_time = 0;
2055                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_MOTD);
2056                         }
2057                 }
2058         }
2059         else //if(CS(this).motd_actived_time < 0) // just connected, motd is active
2060         {
2061                 if(PHYS_INPUT_BUTTON_INFO(this)) // BUTTON_INFO hides initial MOTD
2062                         CS(this).motd_actived_time = -2; // wait until BUTTON_INFO gets released
2063                 else if (CS(this).motd_actived_time == -2)
2064                 {
2065                         // instantly hide MOTD
2066                         CS(this).motd_actived_time = 0;
2067                         if (autocvar_g_campaign)
2068                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_CAMPAIGN_MESSAGE);
2069                         else
2070                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_MOTD);
2071                 }
2072                 else if (IS_PLAYER(this) || IS_SPEC(this))
2073                 {
2074                         // FIXME occasionally for some reason MOTD never goes away
2075                         // delay MOTD removal a little bit in the hope it fixes this bug
2076                         if (CS(this).motd_actived_time == -1) // MOTD marked to fade away as soon as client becomes player or spectator
2077                                 CS(this).motd_actived_time = -(5 + floor(random() * 10)); // add small delay
2078                         else //if (CS(this).motd_actived_time < -2)
2079                                 CS(this).motd_actived_time++;
2080                 }
2081         }
2082 }
2083
2084 const int MIN_SPEC_TIME = 1;
2085 bool joinAllowed(entity this)
2086 {
2087         if (CS(this).version_mismatch) return false;
2088         if (time < CS(this).jointime + MIN_SPEC_TIME) return false;
2089         if (!nJoinAllowed(this, this)) return false;
2090         if (teamplay && lockteams) return false;
2091         if (MUTATOR_CALLHOOK(ForbidSpawn, this)) return false;
2092         if (ShowTeamSelection(this)) return false;
2093         return true;
2094 }
2095
2096 .int items_added;
2097 .string shootfromfixedorigin;
2098 .bool dualwielding_prev;
2099 bool PlayerThink(entity this)
2100 {
2101         if (game_stopped || intermission_running) {
2102                 this.modelflags &= ~MF_ROCKET;
2103                 if(intermission_running)
2104                         IntermissionThink(this);
2105                 return false;
2106         }
2107
2108         if (timeout_status == TIMEOUT_ACTIVE) {
2109         // don't allow the player to turn around while game is paused
2110                 // FIXME turn this into CSQC stuff
2111                 this.v_angle = this.lastV_angle;
2112                 this.angles = this.lastV_angle;
2113                 this.fixangle = true;
2114         }
2115
2116         if (frametime) player_powerups(this);
2117
2118         if (IS_DEAD(this)) {
2119                 if (this.personal && g_race_qualifying) {
2120                         if (time > this.respawn_time) {
2121                                 STAT(RESPAWN_TIME, this) = this.respawn_time = time + 1; // only retry once a second
2122                                 respawn(this);
2123                                 CS(this).impulse = CHIMPULSE_SPEEDRUN.impulse;
2124                         }
2125                 } else {
2126                         if (frametime) player_anim(this);
2127
2128                         if (this.respawn_flags & RESPAWN_DENY)
2129                         {
2130                                 STAT(RESPAWN_TIME, this) = 0;
2131                                 return false;
2132                         }
2133
2134                         bool button_pressed = (PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_JUMP(this) || PHYS_INPUT_BUTTON_ATCK2(this) || PHYS_INPUT_BUTTON_HOOK(this) || PHYS_INPUT_BUTTON_USE(this));
2135
2136                         switch(this.deadflag)
2137                         {
2138                                 case DEAD_DYING:
2139                                 {
2140                                         if ((this.respawn_flags & RESPAWN_FORCE) && !(this.respawn_time < this.respawn_time_max))
2141                                                 this.deadflag = DEAD_RESPAWNING;
2142                                         else if (!button_pressed || (time >= this.respawn_time_max && (this.respawn_flags & RESPAWN_FORCE)))
2143                                                 this.deadflag = DEAD_DEAD;
2144                                         break;
2145                                 }
2146                                 case DEAD_DEAD:
2147                                 {
2148                                         if (button_pressed)
2149                                                 this.deadflag = DEAD_RESPAWNABLE;
2150                                         else if (time >= this.respawn_time_max && (this.respawn_flags & RESPAWN_FORCE))
2151                                                 this.deadflag = DEAD_RESPAWNING;
2152                                         break;
2153                                 }
2154                                 case DEAD_RESPAWNABLE:
2155                                 {
2156                                         if (!button_pressed || (this.respawn_flags & RESPAWN_FORCE))
2157                                                 this.deadflag = DEAD_RESPAWNING;
2158                                         break;
2159                                 }
2160                                 case DEAD_RESPAWNING:
2161                                 {
2162                                         if (time > this.respawn_time)
2163                                         {
2164                                                 this.respawn_time = time + 1; // only retry once a second
2165                                                 this.respawn_time_max = this.respawn_time;
2166                                                 respawn(this);
2167                                         }
2168                                         break;
2169                                 }
2170                         }
2171
2172                         ShowRespawnCountdown(this);
2173
2174                         if (this.respawn_flags & RESPAWN_SILENT)
2175                                 STAT(RESPAWN_TIME, this) = 0;
2176                         else if ((this.respawn_flags & RESPAWN_FORCE) && this.respawn_time < this.respawn_time_max)
2177                         {
2178                                 if (time < this.respawn_time)
2179                                         STAT(RESPAWN_TIME, this) = this.respawn_time;
2180                                 else if (this.deadflag != DEAD_RESPAWNING)
2181                                         STAT(RESPAWN_TIME, this) = -this.respawn_time_max;
2182                         }
2183                         else
2184                                 STAT(RESPAWN_TIME, this) = this.respawn_time;
2185                 }
2186
2187                 // if respawning, invert stat_respawn_time to indicate this, the client translates it
2188                 if (this.deadflag == DEAD_RESPAWNING && STAT(RESPAWN_TIME, this) > 0)
2189                         STAT(RESPAWN_TIME, this) *= -1;
2190
2191                 return false;
2192         }
2193
2194         FixPlayermodel(this);
2195
2196         if (this.shootfromfixedorigin != autocvar_g_shootfromfixedorigin) {
2197                 this.shootfromfixedorigin = autocvar_g_shootfromfixedorigin;
2198                 stuffcmd(this, sprintf("\ncl_shootfromfixedorigin \"%s\"\n", autocvar_g_shootfromfixedorigin));
2199         }
2200
2201         // reset gun alignment when dual wielding status changes
2202         // to ensure guns are always aligned right and left
2203         bool dualwielding = W_DualWielding(this);
2204         if(this.dualwielding_prev != dualwielding)
2205         {
2206                 W_ResetGunAlign(this, CS(this).cvar_cl_gunalign);
2207                 this.dualwielding_prev = dualwielding;
2208         }
2209
2210         // LordHavoc: allow firing on move frames (sub-ticrate), this gives better timing on slow servers
2211         //if(frametime)
2212         {
2213                 this.items &= ~this.items_added;
2214
2215                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2216                 {
2217                         .entity weaponentity = weaponentities[slot];
2218                         if(WEP_CVAR(vortex, charge_always))
2219                                 W_Vortex_Charge(this, weaponentity, frametime);
2220                         W_WeaponFrame(this, weaponentity);
2221                 }
2222
2223                 this.items_added = 0;
2224                 if ((this.items & ITEM_Jetpack.m_itemid) && ((this.items & ITEM_JetpackRegen.m_itemid) || GetResource(this, RES_FUEL) >= 0.01))
2225             this.items_added |= IT_FUEL;
2226
2227                 this.items |= this.items_added;
2228         }
2229
2230         if (frametime)
2231         {
2232                 // WEAPONTODO: Add a weapon request for this
2233                 // rot vortex charge to the charge limit
2234                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2235                 {
2236                         .entity weaponentity = weaponentities[slot];
2237                         if (WEP_CVAR(vortex, charge_rot_rate) && this.(weaponentity).vortex_charge > WEP_CVAR(vortex, charge_limit) && this.(weaponentity).vortex_charge_rottime < time)
2238                                 this.(weaponentity).vortex_charge = bound(WEP_CVAR(vortex, charge_limit), this.(weaponentity).vortex_charge - WEP_CVAR(vortex, charge_rot_rate) * frametime / W_TICSPERFRAME, 1);
2239                 }
2240
2241                 player_regen(this);
2242                 player_anim(this);
2243                 this.dmg_team = max(0, this.dmg_team - autocvar_g_teamdamage_resetspeed * frametime);
2244         }
2245
2246         secrets_setstatus(this);
2247         monsters_setstatus(this);
2248
2249         return true;
2250 }
2251
2252 .bool would_spectate;
2253 void ObserverThink(entity this)
2254 {
2255         if ( CS(this).impulse )
2256         {
2257                 MinigameImpulse(this, CS(this).impulse);
2258                 CS(this).impulse = 0;
2259         }
2260
2261         if (this.flags & FL_JUMPRELEASED) {
2262                 if (PHYS_INPUT_BUTTON_JUMP(this) && joinAllowed(this)) {
2263                         this.flags &= ~FL_JUMPRELEASED;
2264                         this.flags |= FL_SPAWNING;
2265                 } else if(PHYS_INPUT_BUTTON_ATCK(this) && !CS(this).version_mismatch || this.would_spectate) {
2266                         this.flags &= ~FL_JUMPRELEASED;
2267                         if(SpectateNext(this)) {
2268                                 TRANSMUTE(Spectator, this);
2269                         }
2270                 } else {
2271                         int preferred_movetype = ((!PHYS_INPUT_BUTTON_USE(this) ? CS(this).cvar_cl_clippedspectating : !CS(this).cvar_cl_clippedspectating) ? MOVETYPE_FLY_WORLDONLY : MOVETYPE_NOCLIP);
2272                         set_movetype(this, preferred_movetype);
2273                 }
2274         } else {
2275                 if (!(PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_JUMP(this))) {
2276                         this.flags |= FL_JUMPRELEASED;
2277                         if(this.flags & FL_SPAWNING)
2278                         {
2279                                 this.flags &= ~FL_SPAWNING;
2280                                 Join(this);
2281                                 return;
2282                         }
2283                 }
2284         }
2285 }
2286
2287 void SpectatorThink(entity this)
2288 {
2289         if ( CS(this).impulse )
2290         {
2291                 if(MinigameImpulse(this, CS(this).impulse))
2292                         CS(this).impulse = 0;
2293
2294                 if (CS(this).impulse == IMP_weapon_drop.impulse)
2295                 {
2296                         STAT(CAMERA_SPECTATOR, this) = (STAT(CAMERA_SPECTATOR, this) + 1) % 3;
2297                         CS(this).impulse = 0;
2298                         return;
2299                 }
2300         }
2301
2302         if (this.flags & FL_JUMPRELEASED) {
2303                 if (PHYS_INPUT_BUTTON_JUMP(this) && joinAllowed(this)) {
2304                         this.flags &= ~FL_JUMPRELEASED;
2305                         this.flags |= FL_SPAWNING;
2306                 } else if(PHYS_INPUT_BUTTON_ATCK(this) || CS(this).impulse == 10 || CS(this).impulse == 15 || CS(this).impulse == 18 || (CS(this).impulse >= 200 && CS(this).impulse <= 209)) {
2307                         this.flags &= ~FL_JUMPRELEASED;
2308                         if(SpectateNext(this)) {
2309                                 TRANSMUTE(Spectator, this);
2310                         } else {
2311                                 TRANSMUTE(Observer, this);
2312                                 PutClientInServer(this);
2313                         }
2314                         CS(this).impulse = 0;
2315                 } else if(CS(this).impulse == 12 || CS(this).impulse == 16  || CS(this).impulse == 19 || (CS(this).impulse >= 220 && CS(this).impulse <= 229)) {
2316                         this.flags &= ~FL_JUMPRELEASED;
2317                         if(SpectatePrev(this)) {
2318                                 TRANSMUTE(Spectator, this);
2319                         } else {
2320                                 TRANSMUTE(Observer, this);
2321                                 PutClientInServer(this);
2322                         }
2323                         CS(this).impulse = 0;
2324                 } else if (PHYS_INPUT_BUTTON_ATCK2(this)) {
2325                         this.would_spectate = false;
2326                         this.flags &= ~FL_JUMPRELEASED;
2327                         TRANSMUTE(Observer, this);
2328                         PutClientInServer(this);
2329                 } else {
2330                         if(!SpectateUpdate(this))
2331                         {
2332                                 if(!SpectateNext(this))
2333                                 {
2334                                         PutObserverInServer(this);
2335                                         this.would_spectate = true;
2336                                 }
2337                         }
2338                 }
2339         } else {
2340                 if (!(PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_ATCK2(this))) {
2341                         this.flags |= FL_JUMPRELEASED;
2342                         if(this.flags & FL_SPAWNING)
2343                         {
2344                                 this.flags &= ~FL_SPAWNING;
2345                                 Join(this);
2346                                 return;
2347                         }
2348                 }
2349                 if(!SpectateUpdate(this))
2350                         PutObserverInServer(this);
2351         }
2352
2353         this.flags |= FL_CLIENT | FL_NOTARGET;
2354 }
2355
2356 void PlayerUseKey(entity this)
2357 {
2358         if (!IS_PLAYER(this))
2359                 return;
2360
2361         if(this.vehicle)
2362         {
2363                 if(!game_stopped)
2364                 {
2365                         vehicles_exit(this.vehicle, VHEF_NORMAL);
2366                         return;
2367                 }
2368         }
2369         else if(autocvar_g_vehicles_enter)
2370         {
2371                 if(!game_stopped && !STAT(FROZEN, this) && !IS_DEAD(this) && !IS_INDEPENDENT_PLAYER(this))
2372                 {
2373                         entity head, closest_target = NULL;
2374                         head = WarpZone_FindRadius(this.origin, autocvar_g_vehicles_enter_radius, true);
2375
2376                         while(head) // find the closest acceptable target to enter
2377                         {
2378                                 if(IS_VEHICLE(head) && !IS_DEAD(head) && head.takedamage != DAMAGE_NO)
2379                                 if(!head.owner || ((head.vehicle_flags & VHF_MULTISLOT) && SAME_TEAM(head.owner, this)))
2380                                 {
2381                                         if(closest_target)
2382                                         {
2383                                                 if(vlen2(this.origin - head.origin) < vlen2(this.origin - closest_target.origin))
2384                                                 { closest_target = head; }
2385                                         }
2386                                         else { closest_target = head; }
2387                                 }
2388
2389                                 head = head.chain;
2390                         }
2391
2392                         if(closest_target) { vehicles_enter(this, closest_target); return; }
2393                 }
2394         }
2395
2396         // a use key was pressed; call handlers
2397         MUTATOR_CALLHOOK(PlayerUseKey, this);
2398 }
2399
2400
2401 /*
2402 =============
2403 PlayerPreThink
2404
2405 Called every frame for each client before the physics are run
2406 =============
2407 */
2408 .float last_vehiclecheck;
2409 void PlayerPreThink (entity this)
2410 {
2411         STAT(GUNALIGN, this) = CS(this).cvar_cl_gunalign; // TODO
2412         STAT(MOVEVARS_CL_TRACK_CANJUMP, this) = CS(this).cvar_cl_movement_track_canjump;
2413
2414         WarpZone_PlayerPhysics_FixVAngle(this);
2415
2416         if (frametime) {
2417                 // physics frames: update anticheat stuff
2418                 anticheat_prethink(this);
2419         }
2420
2421         if (blockSpectators && frametime) {
2422                 // WORKAROUND: only use dropclient in server frames (frametime set).
2423                 // Never use it in cl_movement frames (frametime zero).
2424                 checkSpectatorBlock(this);
2425         }
2426
2427         zoomstate_set = false;
2428
2429         // Check for nameless players
2430         if (this.netname == "" || this.netname != CS(this).netname_previous)
2431         {
2432                 bool assume_unchanged = (CS(this).netname_previous == "");
2433                 if (autocvar_sv_name_maxlength > 0 && strlennocol(this.netname) > autocvar_sv_name_maxlength)
2434                 {
2435                         int new_length = textLengthUpToLength(this.netname, autocvar_sv_name_maxlength, strlennocol);
2436                         this.netname = strzone(strcat(substring(this.netname, 0, new_length), "^7"));
2437                         sprint(this, sprintf("Warning: your name is longer than %d characters, it has been truncated.\n", autocvar_sv_name_maxlength));
2438                         assume_unchanged = false;
2439                         // stuffcmd(this, strcat("name ", this.netname, "\n")); // maybe?
2440                 }
2441                 if (isInvisibleString(this.netname))
2442                 {
2443                         this.netname = strzone(sprintf("Player#%d", this.playerid));
2444                         sprint(this, "Warning: invisible names are not allowed.\n");
2445                         assume_unchanged = false;
2446                         // stuffcmd(this, strcat("name ", this.netname, "\n")); // maybe?
2447                 }
2448                 if (!assume_unchanged && autocvar_sv_eventlog)
2449                         GameLogEcho(strcat(":name:", ftos(this.playerid), ":", playername(this, false)));
2450                 strcpy(CS(this).netname_previous, this.netname);
2451         }
2452
2453         // version nagging
2454         if (CS(this).version_nagtime && CS(this).cvar_g_xonoticversion && time > CS(this).version_nagtime) {
2455         CS(this).version_nagtime = 0;
2456         if (strstrofs(CS(this).cvar_g_xonoticversion, "git", 0) >= 0 || strstrofs(CS(this).cvar_g_xonoticversion, "autobuild", 0) >= 0) {
2457             // git client
2458         } else if (strstrofs(autocvar_g_xonoticversion, "git", 0) >= 0 || strstrofs(autocvar_g_xonoticversion, "autobuild", 0) >= 0) {
2459             // git server
2460             Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_BETA, autocvar_g_xonoticversion, CS(this).cvar_g_xonoticversion);
2461         } else {
2462             int r = vercmp(CS(this).cvar_g_xonoticversion, autocvar_g_xonoticversion);
2463             if (r < 0) { // old client
2464                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_OUTDATED, autocvar_g_xonoticversion, CS(this).cvar_g_xonoticversion);
2465             } else if (r > 0) { // old server
2466                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_OLD, autocvar_g_xonoticversion, CS(this).cvar_g_xonoticversion);
2467             }
2468         }
2469     }
2470
2471         // GOD MODE info
2472         if (!(this.flags & FL_GODMODE) && this.max_armorvalue)
2473         {
2474                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_GODMODE_OFF, this.max_armorvalue);
2475                 this.max_armorvalue = 0;
2476         }
2477
2478         if (frametime && IS_PLAYER(this))
2479         {
2480                 if (STAT(FROZEN, this) == FROZEN_TEMP_REVIVING)
2481                 {
2482                         STAT(REVIVE_PROGRESS, this) = bound(0, STAT(REVIVE_PROGRESS, this) + frametime * this.revive_speed, 1);
2483                         SetResourceExplicit(this, RES_HEALTH, max(1, STAT(REVIVE_PROGRESS, this) * start_health));
2484                         this.iceblock.alpha = bound(0.2, 1 - STAT(REVIVE_PROGRESS, this), 1);
2485
2486                         if (STAT(REVIVE_PROGRESS, this) >= 1)
2487                                 Unfreeze(this, false);
2488                 }
2489                 else if (STAT(FROZEN, this) == FROZEN_TEMP_DYING)
2490                 {
2491                         STAT(REVIVE_PROGRESS, this) = bound(0, STAT(REVIVE_PROGRESS, this) - frametime * this.revive_speed, 1);
2492                         SetResourceExplicit(this, RES_HEALTH, max(0, autocvar_g_nades_ice_health + (start_health-autocvar_g_nades_ice_health) * STAT(REVIVE_PROGRESS, this)));
2493
2494                         if (GetResource(this, RES_HEALTH) < 1)
2495                         {
2496                                 if (this.vehicle)
2497                                         vehicles_exit(this.vehicle, VHEF_RELEASE);
2498                                 if(this.event_damage)
2499                                         this.event_damage(this, this, this.frozen_by, 1, DEATH_NADE_ICE_FREEZE.m_id, DMG_NOWEP, this.origin, '0 0 0');
2500                         }
2501                         else if (STAT(REVIVE_PROGRESS, this) <= 0)
2502                                 Unfreeze(this, false);
2503                 }
2504         }
2505
2506         MUTATOR_CALLHOOK(PlayerPreThink, this);
2507
2508         if(autocvar_g_vehicles_enter && (time > this.last_vehiclecheck) && !game_stopped && !this.vehicle)
2509         if(IS_PLAYER(this) && !STAT(FROZEN, this) && !IS_DEAD(this) && !IS_INDEPENDENT_PLAYER(this))
2510         {
2511                 FOREACH_ENTITY_RADIUS(this.origin, autocvar_g_vehicles_enter_radius, IS_VEHICLE(it) && !IS_DEAD(it) && it.takedamage != DAMAGE_NO,
2512                 {
2513                         if(!it.owner)
2514                         {
2515                                 if(!it.team || SAME_TEAM(this, it))
2516                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER);
2517                                 else if(autocvar_g_vehicles_steal)
2518                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER_STEAL);
2519                         }
2520                         else if((it.vehicle_flags & VHF_MULTISLOT) && SAME_TEAM(it.owner, this))
2521                         {
2522                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER_GUNNER);
2523                         }
2524                 });
2525
2526                 this.last_vehiclecheck = time + 1;
2527         }
2528
2529         if(!CS(this).cvar_cl_newusekeysupported) // FIXME remove this - it was a stupid idea to begin with, we can JUST use the button
2530         {
2531                 if(PHYS_INPUT_BUTTON_USE(this) && !CS(this).usekeypressed)
2532                         PlayerUseKey(this);
2533                 CS(this).usekeypressed = PHYS_INPUT_BUTTON_USE(this);
2534         }
2535
2536         if (IS_REAL_CLIENT(this))
2537                 PrintWelcomeMessage(this);
2538
2539         if (IS_PLAYER(this)) {
2540                 if (IS_REAL_CLIENT(this) && time < CS(this).jointime + MIN_SPEC_TIME)
2541                         error("Client can't be spawned as player on connection!");
2542                 if(!PlayerThink(this))
2543                         return;
2544         }
2545         else if (game_stopped || intermission_running) {
2546                 if(intermission_running)
2547                         IntermissionThink(this);
2548                 return;
2549         }
2550         else if (IS_REAL_CLIENT(this) && !CS(this).autojoin_checked && time >= CS(this).jointime + MIN_SPEC_TIME)
2551         {
2552                 CS(this).autojoin_checked = true;
2553                 // don't do this in ClientConnect
2554                 // many things can go wrong if a client is spawned as player on connection
2555                 if (MUTATOR_CALLHOOK(AutoJoinOnConnection, this)
2556                         || (!(autocvar_sv_spectate || autocvar_g_campaign || (Player_GetForcedTeamIndex(this) == TEAM_FORCE_SPECTATOR))
2557                                 && (!teamplay || autocvar_g_balance_teams)))
2558                 {
2559                         campaign_bots_may_start = true;
2560                         Join(this);
2561                         return;
2562                 }
2563         }
2564         else if (IS_OBSERVER(this)) {
2565                 ObserverThink(this);
2566         }
2567         else if (IS_SPEC(this)) {
2568                 SpectatorThink(this);
2569         }
2570
2571         // WEAPONTODO: Add weapon request for this
2572         if (!zoomstate_set) {
2573                 bool wep_zoomed = false;
2574                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2575                 {
2576                         .entity weaponentity = weaponentities[slot];
2577                         Weapon thiswep = this.(weaponentity).m_weapon;
2578                         if(thiswep != WEP_Null && thiswep.wr_zoom)
2579                                 wep_zoomed += thiswep.wr_zoom(thiswep, this);
2580                 }
2581                 SetZoomState(this, PHYS_INPUT_BUTTON_ZOOM(this) || PHYS_INPUT_BUTTON_ZOOMSCRIPT(this) || wep_zoomed);
2582     }
2583
2584         if (CS(this).teamkill_soundtime && time > CS(this).teamkill_soundtime)
2585         {
2586                 CS(this).teamkill_soundtime = 0;
2587
2588                 entity e = CS(this).teamkill_soundsource;
2589                 entity oldpusher = e.pusher;
2590                 e.pusher = this;
2591                 PlayerSound(e, playersound_teamshoot, CH_VOICE, VOL_BASEVOICE, VOICETYPE_LASTATTACKER_ONLY);
2592                 e.pusher = oldpusher;
2593         }
2594
2595         if (CS(this).taunt_soundtime && time > CS(this).taunt_soundtime) {
2596                 CS(this).taunt_soundtime = 0;
2597                 PlayerSound(this, playersound_taunt, CH_VOICE, VOL_BASEVOICE, VOICETYPE_AUTOTAUNT);
2598         }
2599
2600         target_voicescript_next(this);
2601
2602         // WEAPONTODO: Move into weaponsystem somehow
2603         // if a player goes unarmed after holding a loaded weapon, empty his clip size and remove the crosshair ammo ring
2604         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2605         {
2606                 .entity weaponentity = weaponentities[slot];
2607                 if(this.(weaponentity).m_weapon == WEP_Null)
2608                         this.(weaponentity).clip_load = this.(weaponentity).clip_size = 0;
2609         }
2610 }
2611
2612 void DrownPlayer(entity this)
2613 {
2614         if(IS_DEAD(this) || game_stopped || time < game_starttime)
2615                 return;
2616
2617         if (this.waterlevel != WATERLEVEL_SUBMERGED || this.vehicle)
2618         {
2619                 if(this.air_finished < time)
2620                         PlayerSound(this, playersound_gasp, CH_PLAYER, VOL_BASE, VOICETYPE_PLAYERSOUND);
2621                 this.air_finished = time + autocvar_g_balance_contents_drowndelay;
2622                 this.air_finished_stat = 0;
2623         }
2624         else if (this.air_finished < time)
2625         {       // drown!
2626                 if (this.pain_finished < time)
2627                 {
2628                         Damage (this, NULL, NULL, autocvar_g_balance_contents_playerdamage_drowning * autocvar_g_balance_contents_damagerate, DEATH_DROWN.m_id, DMG_NOWEP, this.origin, '0 0 0');
2629                         this.pain_finished = time + 0.5;
2630                 }
2631                 this.air_finished_stat = this.air_finished;
2632         }
2633         else
2634                 this.air_finished_stat = this.air_finished;
2635 }
2636
2637 .bool move_qcphysics;
2638
2639 void Player_Physics(entity this)
2640 {
2641         this.movetype = (this.move_qcphysics) ? MOVETYPE_QCPLAYER : this.move_movetype;
2642
2643         if(!this.move_qcphysics)
2644                 return;
2645
2646         if(!frametime && !CS(this).pm_frametime)
2647                 return;
2648
2649         Movetype_Physics_NoMatchTicrate(this, CS(this).pm_frametime, true);
2650
2651         CS(this).pm_frametime = 0;
2652 }
2653
2654 /*
2655 =============
2656 PlayerPostThink
2657
2658 Called every frame for each client after the physics are run
2659 =============
2660 */
2661 void PlayerPostThink (entity this)
2662 {
2663         Player_Physics(this);
2664
2665         if (sv_maxidle > 0)
2666         if (frametime) // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2667         if (IS_REAL_CLIENT(this))
2668         if (IS_PLAYER(this) || sv_maxidle_spectatorsareidle)
2669         {
2670                 int totalClients = 0;
2671                 if(sv_maxidle_slots > 0)
2672                 {
2673                         FOREACH_CLIENT(IS_REAL_CLIENT(it) || sv_maxidle_slots_countbots,
2674                         {
2675                                 ++totalClients;
2676                         });
2677                 }
2678
2679                 if (sv_maxidle_slots > 0 && (maxclients - totalClients) > sv_maxidle_slots)
2680                 { /* do nothing */ }
2681                 else if (time - CS(this).parm_idlesince < 1) // instead of (time == this.parm_idlesince) to support sv_maxidle <= 10
2682                 {
2683                         if (CS(this).idlekick_lasttimeleft)
2684                         {
2685                                 CS(this).idlekick_lasttimeleft = 0;
2686                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_IDLING);
2687                         }
2688                 }
2689                 else
2690                 {
2691                         float timeleft = ceil(sv_maxidle - (time - CS(this).parm_idlesince));
2692                         if (timeleft == min(10, sv_maxidle - 1)) { // - 1 to support sv_maxidle <= 10
2693                                 if (!CS(this).idlekick_lasttimeleft)
2694                                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_DISCONNECT_IDLING, timeleft);
2695                         }
2696                         if (timeleft <= 0) {
2697                                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_QUIT_KICK_IDLING, this.netname);
2698                                 dropclient(this);
2699                                 return;
2700                         }
2701                         else if (timeleft <= 10) {
2702                                 if (timeleft != CS(this).idlekick_lasttimeleft) {
2703                                     Send_Notification(NOTIF_ONE, this, MSG_ANNCE, Announcer_PickNumber(CNT_IDLE, timeleft));
2704                 }
2705                                 CS(this).idlekick_lasttimeleft = timeleft;
2706                         }
2707                 }
2708         }
2709
2710         CheatFrame(this);
2711
2712         if (game_stopped)
2713         {
2714                 this.solid = SOLID_NOT;
2715                 this.takedamage = DAMAGE_NO;
2716                 set_movetype(this, MOVETYPE_NONE);
2717         }
2718
2719         if (IS_PLAYER(this)) {
2720                 if(this.death_time == time && IS_DEAD(this))
2721                 {
2722                         // player's bbox gets resized now, instead of in the damage event that killed the player,
2723                         // once all the damage events of this frame have been processed with normal size
2724                         this.maxs.z = 5;
2725                         setsize(this, this.mins, this.maxs);
2726                 }
2727                 DrownPlayer(this);
2728                 UpdateChatBubble(this);
2729                 if (CS(this).impulse) ImpulseCommands(this);
2730                 if (game_stopped)
2731                 {
2732                         CSQCMODEL_AUTOUPDATE(this);
2733                         return;
2734                 }
2735                 GetPressedKeys(this);
2736         }
2737         else if (IS_OBSERVER(this) && STAT(PRESSED_KEYS, this))
2738         {
2739                 CS(this).pressedkeys = 0;
2740                 STAT(PRESSED_KEYS, this) = 0;
2741         }
2742
2743         if (this.waypointsprite_attachedforcarrier) {
2744                 float hp = healtharmor_maxdamage(GetResource(this, RES_HEALTH), GetResource(this, RES_ARMOR), autocvar_g_balance_armor_blockpercent, DEATH_WEAPON.m_id).x;
2745                 WaypointSprite_UpdateHealth(this.waypointsprite_attachedforcarrier, hp);
2746         }
2747
2748         CSQCMODEL_AUTOUPDATE(this);
2749 }
2750
2751 /**
2752  * message "": do not say, just test flood control
2753  * return value:
2754  *   1 = accept
2755  *   0 = reject
2756  *  -1 = fake accept
2757  */
2758 int Say(entity source, int teamsay, entity privatesay, string msgin, bool floodcontrol)
2759 {
2760         if (!teamsay && !privatesay && substring(msgin, 0, 1) == " ")
2761                 msgin = substring(msgin, 1, -1); // work around DP say bug (say_team does not have this!)
2762
2763         if (source)
2764                 msgin = formatmessage(source, msgin);
2765
2766         string colorstr;
2767         if (!(IS_PLAYER(source) || source.caplayer))
2768                 colorstr = "^0"; // black for spectators
2769         else if(teamplay)
2770                 colorstr = Team_ColorCode(source.team);
2771         else
2772         {
2773                 colorstr = "";
2774                 teamsay = false;
2775         }
2776
2777         if (!source) {
2778                 colorstr = "";
2779                 teamsay = false;
2780         }
2781
2782         if(msgin != "")
2783                 msgin = trigger_magicear_processmessage_forallears(source, teamsay, privatesay, msgin);
2784
2785         /*
2786          * using bprint solves this... me stupid
2787         // how can we prevent the message from appearing in a listen server?
2788         // for now, just give "say" back and only handle say_team
2789         if(!teamsay)
2790         {
2791                 clientcommand(source, strcat("say ", msgin));
2792                 return;
2793         }
2794         */
2795
2796         string namestr = "";
2797         if (source)
2798                 namestr = playername(source, autocvar_g_chat_teamcolors);
2799
2800         string colorprefix = (strdecolorize(namestr) == namestr) ? "^3" : "^7";
2801
2802         string msgstr = "", cmsgstr = "";
2803         string privatemsgprefix = string_null;
2804         int privatemsgprefixlen = 0;
2805         if (msgin != "")
2806         {
2807                 bool found_me = false;
2808                 if(strstrofs(msgin, "/me", 0) >= 0)
2809                 {
2810                         string newmsgin = "";
2811                         string newnamestr = ((teamsay) ? strcat(colorstr, "(", colorprefix, namestr, colorstr, ")", "^7") : strcat(colorprefix, namestr, "^7"));
2812                         FOREACH_WORD(msgin, true,
2813                         {
2814                                 if(strdecolorize(it) == "/me")
2815                                 {
2816                                         found_me = true;
2817                                         newmsgin = cons(newmsgin, newnamestr);
2818                                 }
2819                                 else
2820                                         newmsgin = cons(newmsgin, it);
2821                         });
2822                         msgin = newmsgin;
2823                 }
2824
2825                 if(privatesay)
2826                 {
2827                         msgstr = strcat("\{1}\{13}* ", colorprefix, namestr, "^3 tells you: ^7");
2828                         privatemsgprefixlen = strlen(msgstr);
2829                         msgstr = strcat(msgstr, msgin);
2830                         cmsgstr = strcat(colorstr, colorprefix, namestr, "^3 tells you:\n^7", msgin);
2831                         privatemsgprefix = strcat("\{1}\{13}* ^3You tell ", playername(privatesay, autocvar_g_chat_teamcolors), ": ^7");
2832                 }
2833                 else if(teamsay)
2834                 {
2835                         if(found_me)
2836                         {
2837                                 //msgin = strreplace("/me", "", msgin);
2838                                 //msgin = substring(msgin, 3, strlen(msgin));
2839                                 //msgin = strreplace("/me", strcat(colorstr, "(", colorprefix, namestr, colorstr, ")^7"), msgin);
2840                                 msgstr = strcat("\{1}\{13}^4* ", "^7", msgin);
2841                         }
2842                         else
2843                                 msgstr = strcat("\{1}\{13}", colorstr, "(", colorprefix, namestr, colorstr, ") ^7", msgin);
2844                         cmsgstr = strcat(colorstr, "(", colorprefix, namestr, colorstr, ")\n^7", msgin);
2845                 }
2846                 else
2847                 {
2848                         if(found_me)
2849                         {
2850                                 //msgin = strreplace("/me", "", msgin);
2851                                 //msgin = substring(msgin, 3, strlen(msgin));
2852                                 //msgin = strreplace("/me", strcat(colorprefix, namestr), msgin);
2853                                 msgstr = strcat("\{1}^4* ^7", msgin);
2854                         }
2855                         else {
2856                                 msgstr = "\{1}";
2857                                 msgstr = strcat(msgstr, (namestr != "") ? strcat(colorprefix, namestr, "^7: ") : "^7");
2858                                 msgstr = strcat(msgstr, msgin);
2859                         }
2860                         cmsgstr = "";
2861                 }
2862                 msgstr = strcat(strreplace("\n", " ", msgstr), "\n"); // newlines only are good for centerprint
2863         }
2864
2865         string fullmsgstr = msgstr;
2866         string fullcmsgstr = cmsgstr;
2867
2868         // FLOOD CONTROL
2869         int flood = 0;
2870         var .float flood_field = floodcontrol_chat;
2871         if(floodcontrol && source)
2872         {
2873                 float flood_spl;
2874                 float flood_burst;
2875                 float flood_lmax;
2876                 float lines;
2877                 if(privatesay)
2878                 {
2879                         flood_spl = autocvar_g_chat_flood_spl_tell;
2880                         flood_burst = autocvar_g_chat_flood_burst_tell;
2881                         flood_lmax = autocvar_g_chat_flood_lmax_tell;
2882                         flood_field = floodcontrol_chattell;
2883                 }
2884                 else if(teamsay)
2885                 {
2886                         flood_spl = autocvar_g_chat_flood_spl_team;
2887                         flood_burst = autocvar_g_chat_flood_burst_team;
2888                         flood_lmax = autocvar_g_chat_flood_lmax_team;
2889                         flood_field = floodcontrol_chatteam;
2890                 }
2891                 else
2892                 {
2893                         flood_spl = autocvar_g_chat_flood_spl;
2894                         flood_burst = autocvar_g_chat_flood_burst;
2895                         flood_lmax = autocvar_g_chat_flood_lmax;
2896                         flood_field = floodcontrol_chat;
2897                 }
2898                 flood_burst = max(0, flood_burst - 1);
2899                 // to match explanation in default.cfg, a value of 3 must allow three-line bursts and not four!
2900
2901                 // do flood control for the default line size
2902                 if(msgstr != "")
2903                 {
2904                         getWrappedLine_remaining = msgstr;
2905                         msgstr = "";
2906                         lines = 0;
2907                         while(getWrappedLine_remaining && (!flood_lmax || lines <= flood_lmax))
2908                         {
2909                                 msgstr = strcat(msgstr, " ", getWrappedLineLen(82.4289758859709, strlennocol)); // perl averagewidth.pl < gfx/vera-sans.width
2910                                 ++lines;
2911                         }
2912                         msgstr = substring(msgstr, 1, strlen(msgstr) - 1);
2913
2914                         if(getWrappedLine_remaining != "")
2915                         {
2916                                 msgstr = strcat(msgstr, "\n");
2917                                 flood = 2;
2918                         }
2919
2920                         if (time >= source.(flood_field))
2921                         {
2922                                 source.(flood_field) = max(time - flood_burst * flood_spl, source.(flood_field)) + lines * flood_spl;
2923                         }
2924                         else
2925                         {
2926                                 flood = 1;
2927                                 msgstr = fullmsgstr;
2928                         }
2929                 }
2930                 else
2931                 {
2932                         if (time >= source.(flood_field))
2933                                 source.(flood_field) = max(time - flood_burst * flood_spl, source.(flood_field)) + flood_spl;
2934                         else
2935                                 flood = 1;
2936                 }
2937
2938                 if (timeout_status == TIMEOUT_ACTIVE) // when game is paused, no flood protection
2939                         source.(flood_field) = flood = 0;
2940         }
2941
2942         string sourcemsgstr, sourcecmsgstr;
2943         if(flood == 2) // cannot happen for empty msgstr
2944         {
2945                 if(autocvar_g_chat_flood_notify_flooder)
2946                 {
2947                         sourcemsgstr = strcat(msgstr, "\n^3FLOOD CONTROL: ^7message too long, trimmed\n");
2948                         sourcecmsgstr = "";
2949                 }
2950                 else
2951                 {
2952                         sourcemsgstr = fullmsgstr;
2953                         sourcecmsgstr = fullcmsgstr;
2954                 }
2955                 cmsgstr = "";
2956         }
2957         else
2958         {
2959                 sourcemsgstr = msgstr;
2960                 sourcecmsgstr = cmsgstr;
2961         }
2962
2963         if (!privatesay && source && !(IS_PLAYER(source) || source.caplayer))
2964         {
2965                 if (!game_stopped)
2966                 if (teamsay || (autocvar_g_chat_nospectators == 1) || (autocvar_g_chat_nospectators == 2 && !warmup_stage))
2967                         teamsay = -1; // spectators
2968         }
2969
2970         if(flood)
2971                 LOG_INFO("NOTE: ", playername(source, true), "^7 is flooding.");
2972
2973         // build sourcemsgstr by cutting off a prefix and replacing it by the other one
2974         if(privatesay)
2975                 sourcemsgstr = strcat(privatemsgprefix, substring(sourcemsgstr, privatemsgprefixlen, -1));
2976
2977         int ret;
2978         if(source && CS(source).muted)
2979         {
2980                 // always fake the message
2981                 ret = -1;
2982         }
2983         else if(flood == 1)
2984         {
2985                 if (autocvar_g_chat_flood_notify_flooder)
2986                 {
2987                         sprint(source, strcat("^3FLOOD CONTROL: ^7wait ^1", ftos(source.(flood_field) - time), "^3 seconds\n"));
2988                         ret = 0;
2989                 }
2990                 else
2991                         ret = -1;
2992         }
2993         else
2994         {
2995                 ret = 1;
2996         }
2997
2998         if (privatesay && source && !(IS_PLAYER(source) || source.caplayer))
2999         {
3000                 if (!game_stopped)
3001                 if ((privatesay && (IS_PLAYER(privatesay) || privatesay.caplayer)) && ((autocvar_g_chat_nospectators == 1) || (autocvar_g_chat_nospectators == 2 && !warmup_stage)))
3002                         ret = -1; // just hide the message completely
3003         }
3004
3005         MUTATOR_CALLHOOK(ChatMessage, source, ret);
3006         ret = M_ARGV(1, int);
3007
3008         string event_log_msg = "";
3009
3010         if(sourcemsgstr != "" && ret != 0)
3011         {
3012                 if(ret < 0) // faked message, because the player is muted
3013                 {
3014                         sprint(source, sourcemsgstr);
3015                         if(sourcecmsgstr != "" && !privatesay)
3016                                 centerprint(source, sourcecmsgstr);
3017                 }
3018                 else if(privatesay) // private message, between 2 people only
3019                 {
3020                         sprint(source, sourcemsgstr);
3021                         if (!autocvar_g_chat_tellprivacy) { dedicated_print(msgstr); } // send to server console too if "tellprivacy" is disabled
3022                         if(!MUTATOR_CALLHOOK(ChatMessageTo, privatesay, source))
3023                         {
3024                                 sprint(privatesay, msgstr);
3025                                 if(cmsgstr != "")
3026                                         centerprint(privatesay, cmsgstr);
3027                         }
3028                 }
3029                 else if ( teamsay && CS(source).active_minigame )
3030                 {
3031                         sprint(source, sourcemsgstr);
3032                         dedicated_print(msgstr); // send to server console too
3033                         FOREACH_CLIENT(IS_REAL_CLIENT(it) && it != source && CS(it).active_minigame == CS(source).active_minigame && !MUTATOR_CALLHOOK(ChatMessageTo, it, source), {
3034                                 sprint(it, msgstr);
3035                         });
3036                         event_log_msg = sprintf(":chat_minigame:%d:%s:%s", source.playerid, CS(source).active_minigame.netname, msgin);
3037
3038                 }
3039                 else if(teamsay > 0) // team message, only sent to team mates
3040                 {
3041                         sprint(source, sourcemsgstr);
3042                         dedicated_print(msgstr); // send to server console too
3043                         if(sourcecmsgstr != "")
3044                                 centerprint(source, sourcecmsgstr);
3045                         FOREACH_CLIENT((IS_PLAYER(it) || it.caplayer) && IS_REAL_CLIENT(it) && it != source && it.team == source.team && !MUTATOR_CALLHOOK(ChatMessageTo, it, source), {
3046                                 sprint(it, msgstr);
3047                                 if(cmsgstr != "")
3048                                         centerprint(it, cmsgstr);
3049                         });
3050                         event_log_msg = sprintf(":chat_team:%d:%d:%s", source.playerid, source.team, strreplace("\n", " ", msgin));
3051                 }
3052                 else if(teamsay < 0) // spectator message, only sent to spectators
3053                 {
3054                         sprint(source, sourcemsgstr);
3055                         dedicated_print(msgstr); // send to server console too
3056                         FOREACH_CLIENT(!(IS_PLAYER(it) || it.caplayer) && IS_REAL_CLIENT(it) && it != source && !MUTATOR_CALLHOOK(ChatMessageTo, it, source), {
3057                                 sprint(it, msgstr);
3058                         });
3059                         event_log_msg = sprintf(":chat_spec:%d:%s", source.playerid, strreplace("\n", " ", msgin));
3060                 }
3061                 else
3062                 {
3063                         if (source) {
3064                                 sprint(source, sourcemsgstr);
3065                                 dedicated_print(msgstr); // send to server console too
3066                                 MX_Say(strcat(playername(source, true), "^7: ", msgin));
3067                         }
3068                         FOREACH_CLIENT(IS_REAL_CLIENT(it) && it != source && !MUTATOR_CALLHOOK(ChatMessageTo, it, source), {
3069                                 sprint(it, msgstr);
3070                         });
3071                         event_log_msg = sprintf(":chat:%d:%s", source.playerid, strreplace("\n", " ", msgin));
3072                 }
3073         }
3074
3075         if (autocvar_sv_eventlog && (event_log_msg != "")) {
3076                 GameLogEcho(event_log_msg);
3077         }
3078
3079         return ret;
3080 }
3081
3082 // hack to copy the button fields from the client entity to the Client State
3083 void PM_UpdateButtons(entity this, entity store)
3084 {
3085         if(this.impulse)
3086                 store.impulse = this.impulse;
3087         this.impulse = 0;
3088
3089         bool typing = this.buttonchat || this.button12;
3090
3091         store.button0 = (typing) ? 0 : this.button0;
3092         //button1?!
3093         store.button2 = (typing) ? 0 : this.button2;
3094         store.button3 = (typing) ? 0 : this.button3;
3095         store.button4 = this.button4;
3096         store.button5 = (typing) ? 0 : this.button5;
3097         store.button6 = this.button6;
3098         store.button7 = this.button7;
3099         store.button8 = this.button8;
3100         store.button9 = this.button9;
3101         store.button10 = this.button10;
3102         store.button11 = this.button11;
3103         store.button12 = this.button12;
3104         store.button13 = this.button13;
3105         store.button14 = this.button14;
3106         store.button15 = this.button15;
3107         store.button16 = this.button16;
3108         store.buttonuse = this.buttonuse;
3109         store.buttonchat = this.buttonchat;
3110
3111         store.cursor_active = this.cursor_active;
3112         store.cursor_screen = this.cursor_screen;
3113         store.cursor_trace_start = this.cursor_trace_start;
3114         store.cursor_trace_endpos = this.cursor_trace_endpos;
3115         store.cursor_trace_ent = this.cursor_trace_ent;
3116
3117         store.ping = this.ping;
3118         store.ping_packetloss = this.ping_packetloss;
3119         store.ping_movementloss = this.ping_movementloss;
3120
3121         store.v_angle = this.v_angle;
3122         store.movement = (typing) ? '0 0 0' : this.movement;
3123 }
3124
3125 NET_HANDLE(fpsreport, bool)
3126 {
3127         int fps = ReadShort();
3128         PlayerScore_Set(sender, SP_FPS, fps);
3129         return true;
3130 }