Merge branch 'Mario/crouch' into 'master'
[xonotic/xonotic-data.pk3dir.git] / qcsrc / server / client.qc
1 #include "client.qh"
2
3 #include <server/defs.qh>
4 #include <server/miscfunctions.qh>
5 #include <common/effects/all.qh>
6 #include "anticheat.qh"
7 #include "impulse.qh"
8 #include "player.qh"
9 #include "ipban.qh"
10 #include "miscfunctions.qh"
11 #include "portals.qh"
12 #include "teamplay.qh"
13 #include "playerdemo.qh"
14 #include "spawnpoints.qh"
15 #include "resources.qh"
16 #include "g_damage.qh"
17 #include "handicap.qh"
18 #include "g_hook.qh"
19 #include "command/common.qh"
20 #include "cheats.qh"
21 #include "g_world.qh"
22 #include "race.qh"
23 #include "antilag.qh"
24 #include "campaign.qh"
25 #include "command/common.qh"
26 #include "scores_rules.qh"
27
28 #include "bot/api.qh"
29
30 #include "../common/ent_cs.qh"
31 #include "../common/wepent.qh"
32 #include <common/state.qh>
33
34 #include <common/effects/qc/globalsound.qh>
35
36 #include "../common/triggers/func/conveyor.qh"
37 #include "../common/triggers/teleporters.qh"
38 #include "../common/triggers/target/spawnpoint.qh"
39
40 #include "../common/vehicles/all.qh"
41
42 #include "weapons/hitplot.qh"
43 #include "weapons/weaponsystem.qh"
44
45 #include "../common/net_notice.qh"
46 #include "../common/net_linked.qh"
47 #include "../common/physics/player.qh"
48
49 #include "../common/items/_mod.qh"
50
51 #include "../common/mutators/mutator/waypoints/all.qh"
52
53 #include "../common/triggers/subs.qh"
54 #include "../common/triggers/triggers.qh"
55 #include "../common/triggers/trigger/secret.qh"
56
57 #include "../common/minigames/sv_minigames.qh"
58
59 #include "../common/items/inventory.qh"
60
61 #include "../common/monsters/sv_monsters.qh"
62
63 #include "../lib/warpzone/server.qh"
64
65 STATIC_METHOD(Client, Add, void(Client this, int _team))
66 {
67     ClientConnect(this);
68     TRANSMUTE(Player, this);
69     this.frame = 12; // 7
70     this.team = _team;
71     PutClientInServer(this);
72 }
73
74 void PutObserverInServer(entity this);
75
76 STATIC_METHOD(Client, Remove, void(Client this))
77 {
78     TRANSMUTE(Observer, this);
79     PutClientInServer(this);
80     ClientDisconnect(this);
81 }
82
83 void send_CSQC_teamnagger() {
84         WriteHeader(MSG_BROADCAST, TE_CSQC_TEAMNAGGER);
85 }
86
87 int CountSpectators(entity player, entity to)
88 {
89         if(!player) { return 0; } // not sure how, but best to be safe
90
91         int spec_count = 0;
92
93         FOREACH_CLIENT(IS_REAL_CLIENT(it) && IS_SPEC(it) && it != to && it.enemy == player,
94         {
95                 spec_count++;
96         });
97
98         return spec_count;
99 }
100
101 void WriteSpectators(entity player, entity to)
102 {
103         if(!player) { return; } // not sure how, but best to be safe
104
105         FOREACH_CLIENT(IS_REAL_CLIENT(it) && IS_SPEC(it) && it != to && it.enemy == player,
106         {
107                 WriteByte(MSG_ENTITY, num_for_edict(it));
108         });
109 }
110
111 bool ClientData_Send(entity this, entity to, int sf)
112 {
113         assert(to == this.owner, return false);
114
115         entity e = to;
116         if (IS_SPEC(e)) e = e.enemy;
117
118         sf = 0;
119         if (CS(e).race_completed)       sf |= BIT(0); // forced scoreboard
120         if (CS(to).spectatee_status)    sf |= BIT(1); // spectator ent number follows
121         if (CS(e).zoomstate)            sf |= BIT(2); // zoomed
122         if (autocvar_sv_showspectators) sf |= BIT(4); // show spectators
123
124         WriteHeader(MSG_ENTITY, ENT_CLIENT_CLIENTDATA);
125         WriteByte(MSG_ENTITY, sf);
126
127         if (sf & BIT(1))
128                 WriteByte(MSG_ENTITY, CS(to).spectatee_status);
129
130         if(sf & BIT(4))
131         {
132                 float specs = CountSpectators(e, to);
133                 WriteByte(MSG_ENTITY, specs);
134                 WriteSpectators(e, to);
135         }
136
137         return true;
138 }
139
140 void ClientData_Attach(entity this)
141 {
142         Net_LinkEntity(CS(this).clientdata = new_pure(clientdata), false, 0, ClientData_Send);
143         CS(this).clientdata.drawonlytoclient = this;
144         CS(this).clientdata.owner = this;
145 }
146
147 void ClientData_Detach(entity this)
148 {
149         delete(CS(this).clientdata);
150         CS(this).clientdata = NULL;
151 }
152
153 void ClientData_Touch(entity e)
154 {
155         CS(e).clientdata.SendFlags = 1;
156
157         // make it spectatable
158         FOREACH_CLIENT(IS_REAL_CLIENT(it) && it != e && IS_SPEC(it) && it.enemy == e, { CS(it).clientdata.SendFlags = 1; });
159 }
160
161 void SetSpectatee(entity this, entity spectatee);
162 void SetSpectatee_status(entity this, int spectatee_num);
163
164
165 /*
166 =============
167 CheckPlayerModel
168
169 Checks if the argument string can be a valid playermodel.
170 Returns a valid one in doubt.
171 =============
172 */
173 string FallbackPlayerModel;
174 string CheckPlayerModel(string plyermodel) {
175         if(FallbackPlayerModel != cvar_defstring("_cl_playermodel"))
176         {
177                 // note: we cannot summon Don Strunzone here, some player may
178                 // still have the model string set. In case anyone manages how
179                 // to change a cvar default, we'll have a small leak here.
180                 FallbackPlayerModel = strzone(cvar_defstring("_cl_playermodel"));
181         }
182         // only in right path
183         if( substring(plyermodel,0,14) != "models/player/")
184                 return FallbackPlayerModel;
185         // only good file extensions
186         if(substring(plyermodel,-4,4) != ".zym")
187         if(substring(plyermodel,-4,4) != ".dpm")
188         if(substring(plyermodel,-4,4) != ".iqm")
189         if(substring(plyermodel,-4,4) != ".md3")
190         if(substring(plyermodel,-4,4) != ".psk")
191                 return FallbackPlayerModel;
192         // forbid the LOD models
193         if(substring(plyermodel, -9,5) == "_lod1")
194                 return FallbackPlayerModel;
195         if(substring(plyermodel, -9,5) == "_lod2")
196                 return FallbackPlayerModel;
197         if(plyermodel != strtolower(plyermodel))
198                 return FallbackPlayerModel;
199         // also, restrict to server models
200         if(autocvar_sv_servermodelsonly)
201         {
202                 if(!fexists(plyermodel))
203                         return FallbackPlayerModel;
204         }
205         return plyermodel;
206 }
207
208 void setplayermodel(entity e, string modelname)
209 {
210         precache_model(modelname);
211         _setmodel(e, modelname);
212         player_setupanimsformodel(e);
213         if(!autocvar_g_debug_globalsounds)
214                 UpdatePlayerSounds(e);
215 }
216
217 void FixPlayermodel(entity player);
218 /** putting a client as observer in the server */
219 void PutObserverInServer(entity this)
220 {
221     bool mutator_returnvalue = MUTATOR_CALLHOOK(MakePlayerObserver, this);
222         PlayerState_detach(this);
223
224         if (IS_PLAYER(this))
225         {
226                 if(this.health >= 1)
227                 {
228                         // despawn effect
229                         Send_Effect(EFFECT_SPAWN_NEUTRAL, this.origin, '0 0 0', 1);
230                 }
231
232                 // was a player, recount votes and ready status
233                 if(IS_REAL_CLIENT(this))
234                 {
235                         if (vote_called) { VoteCount(false); }
236                         ReadyCount();
237                 }
238     }
239
240     {
241         entity spot = SelectSpawnPoint(this, true);
242         if (!spot) LOG_FATAL("No spawnpoints for observers?!?");
243         this.angles = vec2(spot.angles);
244         this.fixangle = true;
245         // offset it so that the spectator spawns higher off the ground, looks better this way
246         setorigin(this, spot.origin + STAT(PL_VIEW_OFS, this));
247         if (IS_REAL_CLIENT(this))
248         {
249             msg_entity = this;
250             WriteByte(MSG_ONE, SVC_SETVIEW);
251             WriteEntity(MSG_ONE, this);
252         }
253         // give the spectator some space between walls for MOVETYPE_FLY_WORLDONLY
254         // so that your view doesn't go into the ceiling with MOVETYPE_FLY_WORLDONLY, previously "PL_VIEW_OFS"
255         if(!autocvar_g_debug_globalsounds)
256         {
257                 // needed for player sounds
258                 this.model = "";
259                 FixPlayermodel(this);
260         }
261         setmodel(this, MDL_Null);
262         setsize(this, STAT(PL_CROUCH_MIN, this), STAT(PL_CROUCH_MAX, this));
263         this.view_ofs = '0 0 0';
264     }
265
266     RemoveGrapplingHooks(this);
267         Portal_ClearAll(this);
268         Unfreeze(this);
269         SetSpectatee(this, NULL);
270
271         if (this.alivetime)
272         {
273                 if (!warmup_stage)
274                         PlayerStats_GameReport_Event_Player(this, PLAYERSTATS_ALIVETIME, time - this.alivetime);
275                 this.alivetime = 0;
276         }
277
278         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
279
280         WaypointSprite_PlayerDead(this);
281
282         if (mutator_returnvalue) {
283             // mutator prevents resetting teams+score
284         } else {
285                 int oldteam = this.team;
286                 this.team = -1;  // move this as it is needed to log the player spectating in eventlog
287                 MUTATOR_CALLHOOK(Player_ChangedTeam, this, oldteam, this.team);
288         this.frags = FRAGS_SPECTATOR;
289         PlayerScore_Clear(this);  // clear scores when needed
290     }
291
292         if (CS(this).killcount != FRAGS_SPECTATOR)
293         {
294                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_QUIT_SPECTATE, this.netname);
295                 if(!game_stopped)
296                 if(autocvar_g_chat_nospectators == 1 || (!warmup_stage && autocvar_g_chat_nospectators == 2))
297                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_CHAT_NOSPECTATORS);
298
299                 if(!CS(this).just_joined)
300                         LogTeamchange(this.playerid, -1, 4);
301                 else
302                         CS(this).just_joined = false;
303         }
304
305         accuracy_resend(this);
306
307         CS(this).spectatortime = time;
308         if(this.bot_attack)
309                 IL_REMOVE(g_bot_targets, this);
310         this.bot_attack = false;
311         if(this.monster_attack)
312                 IL_REMOVE(g_monster_targets, this);
313         this.monster_attack = false;
314     STAT(HUD, this) = HUD_NORMAL;
315         TRANSMUTE(Observer, this);
316         this.iscreature = false;
317         this.teleportable = TELEPORT_SIMPLE;
318         if(this.damagedbycontents)
319                 IL_REMOVE(g_damagedbycontents, this);
320         this.damagedbycontents = false;
321         this.health = FRAGS_SPECTATOR;
322         SetSpectatee_status(this, etof(this));
323         this.takedamage = DAMAGE_NO;
324         this.solid = SOLID_NOT;
325         set_movetype(this, MOVETYPE_FLY_WORLDONLY); // user preference is controlled by playerprethink
326         this.flags = FL_CLIENT | FL_NOTARGET;
327         this.armorvalue = 666;
328         this.effects = 0;
329         this.armorvalue = autocvar_g_balance_armor_start;
330         this.pauserotarmor_finished = 0;
331         this.pauserothealth_finished = 0;
332         this.pauseregen_finished = 0;
333         this.damageforcescale = 0;
334         this.death_time = 0;
335         this.respawn_flags = 0;
336         this.respawn_time = 0;
337         STAT(RESPAWN_TIME, this) = 0;
338         this.alpha = 0;
339         this.scale = 0;
340         this.fade_time = 0;
341         this.pain_frame = 0;
342         this.pain_finished = 0;
343         this.strength_finished = 0;
344         this.invincible_finished = 0;
345         this.superweapons_finished = 0;
346         this.dphitcontentsmask = 0;
347         this.pushltime = 0;
348         this.istypefrag = 0;
349         setthink(this, func_null);
350         this.nextthink = 0;
351         this.deadflag = DEAD_NO;
352         this.crouch = false;
353         STAT(REVIVE_PROGRESS, this) = 0;
354         this.revival_time = 0;
355
356         this.items = 0;
357         this.weapons = '0 0 0';
358         this.drawonlytoclient = this;
359
360         this.viewloc = NULL;
361
362         //this.spawnpoint_targ = NULL; // keep it so they can return to where they were?
363
364         this.weaponmodel = "";
365         for (int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
366         {
367                 this.weaponentities[slot] = NULL;
368         }
369         this.exteriorweaponentity = NULL;
370         CS(this).killcount = FRAGS_SPECTATOR;
371         this.velocity = '0 0 0';
372         this.avelocity = '0 0 0';
373         this.punchangle = '0 0 0';
374         this.punchvector = '0 0 0';
375         this.oldvelocity = this.velocity;
376         this.fire_endtime = -1;
377         this.event_damage = func_null;
378
379         for(int slot = 0; slot < MAX_AXH; ++slot)
380         {
381                 entity axh = this.(AuxiliaryXhair[slot]);
382                 this.(AuxiliaryXhair[slot]) = NULL;
383
384                 if(axh.owner == this && axh != NULL && !wasfreed(axh))
385                         delete(axh);
386         }
387 }
388
389 int player_getspecies(entity this)
390 {
391         get_model_parameters(this.model, this.skin);
392         int s = get_model_parameters_species;
393         get_model_parameters(string_null, 0);
394         if (s < 0) return SPECIES_HUMAN;
395         return s;
396 }
397
398 .float model_randomizer;
399 void FixPlayermodel(entity player)
400 {
401         string defaultmodel = "";
402         int defaultskin = 0;
403         if(autocvar_sv_defaultcharacter)
404         {
405                 if(teamplay)
406                 {
407                         switch(player.team)
408                         {
409                                 case NUM_TEAM_1: defaultmodel = autocvar_sv_defaultplayermodel_red; defaultskin = autocvar_sv_defaultplayerskin_red; break;
410                                 case NUM_TEAM_2: defaultmodel = autocvar_sv_defaultplayermodel_blue; defaultskin = autocvar_sv_defaultplayerskin_blue; break;
411                                 case NUM_TEAM_3: defaultmodel = autocvar_sv_defaultplayermodel_yellow; defaultskin = autocvar_sv_defaultplayerskin_yellow; break;
412                                 case NUM_TEAM_4: defaultmodel = autocvar_sv_defaultplayermodel_pink; defaultskin = autocvar_sv_defaultplayerskin_pink; break;
413                         }
414                 }
415
416                 if(defaultmodel == "")
417                 {
418                         defaultmodel = autocvar_sv_defaultplayermodel;
419                         defaultskin = autocvar_sv_defaultplayerskin;
420                 }
421
422                 int n = tokenize_console(defaultmodel);
423                 if(n > 0)
424                 {
425                         defaultmodel = argv(floor(n * CS(player).model_randomizer));
426                         // However, do NOT randomize if the player-selected model is in the list.
427                         for (int i = 0; i < n; ++i)
428                                 if ((argv(i) == player.playermodel && defaultskin == stof(player.playerskin)) || argv(i) == strcat(player.playermodel, ":", player.playerskin))
429                                         defaultmodel = argv(i);
430                 }
431
432                 int i = strstrofs(defaultmodel, ":", 0);
433                 if(i >= 0)
434                 {
435                         defaultskin = stof(substring(defaultmodel, i+1, -1));
436                         defaultmodel = substring(defaultmodel, 0, i);
437                 }
438         }
439         if(autocvar_sv_defaultcharacterskin && !defaultskin)
440         {
441                 if(teamplay)
442                 {
443                         switch(player.team)
444                         {
445                                 case NUM_TEAM_1: defaultskin = autocvar_sv_defaultplayerskin_red; break;
446                                 case NUM_TEAM_2: defaultskin = autocvar_sv_defaultplayerskin_blue; break;
447                                 case NUM_TEAM_3: defaultskin = autocvar_sv_defaultplayerskin_yellow; break;
448                                 case NUM_TEAM_4: defaultskin = autocvar_sv_defaultplayerskin_pink; break;
449                         }
450                 }
451
452                 if(!defaultskin)
453                         defaultskin = autocvar_sv_defaultplayerskin;
454         }
455
456         MUTATOR_CALLHOOK(FixPlayermodel, defaultmodel, defaultskin, player);
457         defaultmodel = M_ARGV(0, string);
458         defaultskin = M_ARGV(1, int);
459
460         bool chmdl = false;
461         int oldskin;
462         if(defaultmodel != "")
463         {
464                 if (defaultmodel != player.model)
465                 {
466                         vector m1 = player.mins;
467                         vector m2 = player.maxs;
468                         setplayermodel (player, defaultmodel);
469                         setsize (player, m1, m2);
470                         chmdl = true;
471                 }
472
473                 oldskin = player.skin;
474                 player.skin = defaultskin;
475         } else {
476                 if (player.playermodel != player.model || player.playermodel == "")
477                 {
478                         player.playermodel = CheckPlayerModel(player.playermodel); // this is never "", so no endless loop
479                         vector m1 = player.mins;
480                         vector m2 = player.maxs;
481                         setplayermodel (player, player.playermodel);
482                         setsize (player, m1, m2);
483                         chmdl = true;
484                 }
485
486                 if(!autocvar_sv_defaultcharacterskin)
487                 {
488                         oldskin = player.skin;
489                         player.skin = stof(player.playerskin);
490                 }
491                 else
492                 {
493                         oldskin = player.skin;
494                         player.skin = defaultskin;
495                 }
496         }
497
498         if(chmdl || oldskin != player.skin) // model or skin has changed
499         {
500                 player.species = player_getspecies(player); // update species
501                 if(!autocvar_g_debug_globalsounds)
502                         UpdatePlayerSounds(player); // update skin sounds
503         }
504
505         if(!teamplay)
506                 if(strlen(autocvar_sv_defaultplayercolors))
507                         if(player.clientcolors != stof(autocvar_sv_defaultplayercolors))
508                                 setcolor(player, stof(autocvar_sv_defaultplayercolors));
509 }
510
511 void PutPlayerInServer(entity this)
512 {
513         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
514
515         PlayerState_attach(this);
516         accuracy_resend(this);
517
518         if (this.team < 0)
519                 JoinBestTeam(this, true);
520
521         entity spot = SelectSpawnPoint(this, false);
522         if (!spot) {
523                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_JOIN_NOSPAWNS);
524                 return; // spawn failed
525         }
526
527         TRANSMUTE(Player, this);
528
529         CS(this).wasplayer = true;
530         this.iscreature = true;
531         this.teleportable = TELEPORT_NORMAL;
532         if(!this.damagedbycontents)
533                 IL_PUSH(g_damagedbycontents, this);
534         this.damagedbycontents = true;
535         set_movetype(this, MOVETYPE_WALK);
536         this.solid = SOLID_SLIDEBOX;
537         this.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_SOLID;
538         if (autocvar_g_playerclip_collisions)
539                 this.dphitcontentsmask |= DPCONTENTS_PLAYERCLIP;
540         if (IS_BOT_CLIENT(this) && autocvar_g_botclip_collisions)
541                 this.dphitcontentsmask |= DPCONTENTS_BOTCLIP;
542         this.frags = FRAGS_PLAYER;
543         if (INDEPENDENT_PLAYERS) MAKE_INDEPENDENT_PLAYER(this);
544         this.flags = FL_CLIENT | FL_PICKUPITEMS;
545         if (autocvar__notarget)
546                 this.flags |= FL_NOTARGET;
547         this.takedamage = DAMAGE_AIM;
548         this.effects = EF_TELEPORT_BIT | EF_RESTARTANIM_BIT;
549
550         if (warmup_stage) {
551                 this.ammo_shells = warmup_start_ammo_shells;
552                 this.ammo_nails = warmup_start_ammo_nails;
553                 this.ammo_rockets = warmup_start_ammo_rockets;
554                 this.ammo_cells = warmup_start_ammo_cells;
555                 this.ammo_plasma = warmup_start_ammo_plasma;
556                 this.ammo_fuel = warmup_start_ammo_fuel;
557                 this.health = warmup_start_health;
558                 this.armorvalue = warmup_start_armorvalue;
559                 this.weapons = WARMUP_START_WEAPONS;
560         } else {
561                 this.ammo_shells = start_ammo_shells;
562                 this.ammo_nails = start_ammo_nails;
563                 this.ammo_rockets = start_ammo_rockets;
564                 this.ammo_cells = start_ammo_cells;
565                 this.ammo_plasma = start_ammo_plasma;
566                 this.ammo_fuel = start_ammo_fuel;
567                 this.health = start_health;
568                 this.armorvalue = start_armorvalue;
569                 this.weapons = start_weapons;
570                 if (MUTATOR_CALLHOOK(ForbidRandomStartWeapons, this) == false)
571                 {
572                         GiveRandomWeapons(this, random_start_weapons_count,
573                                 autocvar_g_random_start_weapons, random_start_ammo);
574                 }
575         }
576         SetSpectatee_status(this, 0);
577
578         PS(this).dual_weapons = '0 0 0';
579
580         this.superweapons_finished = (this.weapons & WEPSET_SUPERWEAPONS) ? time + autocvar_g_balance_superweapons_time : 0;
581
582         this.items = start_items;
583
584         this.spawnshieldtime = time + autocvar_g_spawnshieldtime;
585         this.pauserotarmor_finished = time + autocvar_g_balance_pause_armor_rot_spawn;
586         this.pauserothealth_finished = time + autocvar_g_balance_pause_health_rot_spawn;
587         this.pauserotfuel_finished = time + autocvar_g_balance_pause_fuel_rot_spawn;
588         this.pauseregen_finished = time + autocvar_g_balance_pause_health_regen_spawn;
589         if (!sv_ready_restart_after_countdown && time < game_starttime)
590         {
591                 float f = game_starttime - time;
592                 this.spawnshieldtime += f;
593                 this.pauserotarmor_finished += f;
594                 this.pauserothealth_finished += f;
595                 this.pauseregen_finished += f;
596         }
597
598         this.damageforcescale = 2;
599         this.death_time = 0;
600         this.respawn_flags = 0;
601         this.respawn_time = 0;
602         STAT(RESPAWN_TIME, this) = 0;
603         this.scale = autocvar_sv_player_scale;
604         this.fade_time = 0;
605         this.pain_frame = 0;
606         this.pain_finished = 0;
607         this.pushltime = 0;
608         setthink(this, func_null); // players have no think function
609         this.nextthink = 0;
610         this.dmg_team = 0;
611         PS(this).ballistics_density = autocvar_g_ballistics_density_player;
612
613         this.deadflag = DEAD_NO;
614
615         this.angles = spot.angles;
616         this.angles_z = 0; // never spawn tilted even if the spot says to
617         if (IS_BOT_CLIENT(this))
618                 this.v_angle = this.angles;
619         this.fixangle = true; // turn this way immediately
620         this.oldvelocity = this.velocity = '0 0 0';
621         this.avelocity = '0 0 0';
622         this.punchangle = '0 0 0';
623         this.punchvector = '0 0 0';
624
625         this.strength_finished = 0;
626         this.invincible_finished = 0;
627         this.fire_endtime = -1;
628         STAT(REVIVE_PROGRESS, this) = 0;
629         this.revival_time = 0;
630
631         this.air_finished = time + 12;
632         this.waterlevel = WATERLEVEL_NONE;
633         this.watertype = CONTENT_EMPTY;
634
635         entity spawnevent = new_pure(spawnevent);
636         spawnevent.owner = this;
637         Net_LinkEntity(spawnevent, false, 0.5, SpawnEvent_Send);
638
639         // Cut off any still running player sounds.
640         stopsound(this, CH_PLAYER_SINGLE);
641
642         this.model = "";
643         FixPlayermodel(this);
644         this.drawonlytoclient = NULL;
645
646         this.viewloc = NULL;
647
648         for(int slot = 0; slot < MAX_AXH; ++slot)
649         {
650                 entity axh = this.(AuxiliaryXhair[slot]);
651                 this.(AuxiliaryXhair[slot]) = NULL;
652
653                 if(axh.owner == this && axh != NULL && !wasfreed(axh))
654                         delete(axh);
655         }
656
657         this.spawnpoint_targ = NULL;
658
659         this.crouch = false;
660         this.view_ofs = STAT(PL_VIEW_OFS, this);
661         setsize(this, STAT(PL_MIN, this), STAT(PL_MAX, this));
662         this.spawnorigin = spot.origin;
663         setorigin(this, spot.origin + '0 0 1' * (1 - this.mins.z - 24));
664         // don't reset back to last position, even if new position is stuck in solid
665         this.oldorigin = this.origin;
666         if(this.conveyor)
667                 IL_REMOVE(g_conveyed, this);
668         this.conveyor = NULL; // prevent conveyors at the previous location from moving a freshly spawned player
669         STAT(HUD, this) = HUD_NORMAL;
670
671         this.event_damage = PlayerDamage;
672
673         if(!this.bot_attack)
674                 IL_PUSH(g_bot_targets, this);
675         this.bot_attack = true;
676         if(!this.monster_attack)
677                 IL_PUSH(g_monster_targets, this);
678         this.monster_attack = true;
679         navigation_dynamicgoal_init(this, false);
680
681         PHYS_INPUT_BUTTON_ATCK(this) = PHYS_INPUT_BUTTON_JUMP(this) = PHYS_INPUT_BUTTON_ATCK2(this) = false;
682
683         // player was spectator
684         if (CS(this).killcount == FRAGS_SPECTATOR) {
685                 PlayerScore_Clear(this);
686                 CS(this).killcount = 0;
687                 CS(this).startplaytime = time;
688         }
689
690         for (int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
691         {
692                 .entity weaponentity = weaponentities[slot];
693                 entity oldwep = this.(weaponentity);
694                 CL_SpawnWeaponentity(this, weaponentity);
695                 if(oldwep && oldwep.owner == this)
696                         this.(weaponentity).m_gunalign = oldwep.m_gunalign;
697         }
698         this.alpha = default_player_alpha;
699         this.colormod = '1 1 1' * autocvar_g_player_brightness;
700         this.exteriorweaponentity.alpha = default_weapon_alpha;
701
702         this.speedrunning = false;
703
704         target_voicescript_clear(this);
705
706         // reset fields the weapons may use
707         FOREACH(Weapons, true, {
708                 it.wr_resetplayer(it, this);
709                         // reload all reloadable weapons
710                 if (it.spawnflags & WEP_FLAG_RELOADABLE) {
711                         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
712                         {
713                                 .entity weaponentity = weaponentities[slot];
714                                 this.(weaponentity).weapon_load[it.m_id] = it.reloading_ammo;
715                         }
716                 }
717         });
718
719         {
720                 string s = spot.target;
721                 spot.target = string_null;
722                 SUB_UseTargets(spot, this, NULL);
723                 spot.target = s;
724         }
725
726         Unfreeze(this);
727
728         MUTATOR_CALLHOOK(PlayerSpawn, this, spot);
729
730         if (autocvar_spawn_debug)
731         {
732                 sprint(this, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
733                 delete(spot); // usefull for checking if there are spawnpoints, that let drop through the floor
734         }
735
736         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
737         {
738                 .entity weaponentity = weaponentities[slot];
739                 if(slot == 0 || autocvar_g_weaponswitch_debug == 1)
740                         this.(weaponentity).m_switchweapon = w_getbestweapon(this, weaponentity);
741                 else
742                         this.(weaponentity).m_switchweapon = WEP_Null;
743                 this.(weaponentity).m_weapon = WEP_Null;
744                 this.(weaponentity).weaponname = "";
745                 this.(weaponentity).m_switchingweapon = WEP_Null;
746                 this.(weaponentity).cnt = -1;
747         }
748
749         MUTATOR_CALLHOOK(PlayerWeaponSelect, this);
750
751         if (!warmup_stage && !this.alivetime)
752                 this.alivetime = time;
753
754         antilag_clear(this, CS(this));
755 }
756
757 /** Called when a client spawns in the server */
758 void PutClientInServer(entity this)
759 {
760         if (IS_BOT_CLIENT(this)) {
761                 TRANSMUTE(Player, this);
762         } else if (IS_REAL_CLIENT(this)) {
763                 msg_entity = this;
764                 WriteByte(MSG_ONE, SVC_SETVIEW);
765                 WriteEntity(MSG_ONE, this);
766         }
767         if (game_stopped)
768                 TRANSMUTE(Observer, this);
769
770         SetSpectatee(this, NULL);
771
772         // reset player keys
773         if(PS(this))
774                 PS(this).itemkeys = 0;
775
776         MUTATOR_CALLHOOK(PutClientInServer, this);
777
778         if (IS_OBSERVER(this)) {
779                 PutObserverInServer(this);
780         } else if (IS_PLAYER(this)) {
781                 PutPlayerInServer(this);
782         }
783 }
784
785 void ClientInit_misc(entity this);
786
787 // TODO do we need all these fields, or should we stop autodetecting runtime
788 // changes and just have a console command to update this?
789 bool ClientInit_SendEntity(entity this, entity to, int sf)
790 {
791         WriteHeader(MSG_ENTITY, _ENT_CLIENT_INIT);
792         return = true;
793         msg_entity = to;
794         // MSG_INIT replacement
795         // TODO: make easier to use
796         Registry_send_all();
797         W_PROP_reload(MSG_ONE, to);
798         ClientInit_misc(this);
799         MUTATOR_CALLHOOK(Ent_Init);
800 }
801 void ClientInit_misc(entity this)
802 {
803         int channel = MSG_ONE;
804         WriteHeader(channel, ENT_CLIENT_INIT);
805         WriteByte(channel, g_nexball_meter_period * 32);
806         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[0]));
807         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[1]));
808         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[2]));
809         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[3]));
810         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[0]));
811         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[1]));
812         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[2]));
813         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[3]));
814
815         if(sv_foginterval && world.fog != "")
816                 WriteString(channel, world.fog);
817         else
818                 WriteString(channel, "");
819         WriteByte(channel, this.count * 255.0); // g_balance_armor_blockpercent
820         WriteByte(channel, this.cnt * 255.0); // g_balance_damagepush_speedfactor
821         WriteByte(channel, serverflags);
822         WriteCoord(channel, autocvar_g_trueaim_minrange);
823 }
824
825 void ClientInit_CheckUpdate(entity this)
826 {
827         this.nextthink = time;
828         if(this.count != autocvar_g_balance_armor_blockpercent)
829         {
830                 this.count = autocvar_g_balance_armor_blockpercent;
831                 this.SendFlags |= 1;
832         }
833         if(this.cnt != autocvar_g_balance_damagepush_speedfactor)
834         {
835                 this.cnt = autocvar_g_balance_damagepush_speedfactor;
836                 this.SendFlags |= 1;
837         }
838 }
839
840 void ClientInit_Spawn()
841 {
842         entity e = new_pure(clientinit);
843         setthink(e, ClientInit_CheckUpdate);
844         Net_LinkEntity(e, false, 0, ClientInit_SendEntity);
845
846         ClientInit_CheckUpdate(e);
847 }
848
849 /*
850 =============
851 SetNewParms
852 =============
853 */
854 void SetNewParms ()
855 {
856         // initialize parms for a new player
857         parm1 = -(86400 * 366);
858
859         MUTATOR_CALLHOOK(SetNewParms);
860 }
861
862 /*
863 =============
864 SetChangeParms
865 =============
866 */
867 void SetChangeParms (entity this)
868 {
869         // save parms for level change
870         parm1 = CS(this).parm_idlesince - time;
871
872         MUTATOR_CALLHOOK(SetChangeParms);
873 }
874
875 /*
876 =============
877 DecodeLevelParms
878 =============
879 */
880 void DecodeLevelParms(entity this)
881 {
882         // load parms
883         CS(this).parm_idlesince = parm1;
884         if (CS(this).parm_idlesince == -(86400 * 366))
885                 CS(this).parm_idlesince = time;
886
887         // whatever happens, allow 60 seconds of idling directly after connect for map loading
888         CS(this).parm_idlesince = max(CS(this).parm_idlesince, time - sv_maxidle + 60);
889
890         MUTATOR_CALLHOOK(DecodeLevelParms);
891 }
892
893 /*
894 =============
895 ClientKill
896
897 Called when a client types 'kill' in the console
898 =============
899 */
900
901 .float clientkill_nexttime;
902 void ClientKill_Now_TeamChange(entity this)
903 {
904         if(this.killindicator_teamchange == -1)
905         {
906                 JoinBestTeam( this, true );
907         }
908         else if(this.killindicator_teamchange == -2)
909         {
910                 if(blockSpectators)
911                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
912                 PutObserverInServer(this);
913         }
914         else
915                 SV_ChangeTeam(this, this.killindicator_teamchange - 1);
916         this.killindicator_teamchange = 0;
917 }
918
919 void ClientKill_Now(entity this)
920 {
921         if(this.vehicle)
922         {
923             vehicles_exit(this.vehicle, VHEF_RELEASE);
924             if(!this.killindicator_teamchange)
925             {
926             this.vehicle_health = -1;
927             Damage(this, this, this, 1 , DEATH_KILL.m_id, DMG_NOWEP, this.origin, '0 0 0');
928             }
929         }
930
931         if(this.killindicator && !wasfreed(this.killindicator))
932                 delete(this.killindicator);
933
934         this.killindicator = NULL;
935
936         if(this.killindicator_teamchange)
937                 ClientKill_Now_TeamChange(this);
938
939         if (!IS_SPEC(this) && !IS_OBSERVER(this) && MUTATOR_CALLHOOK(ClientKill_Now, this) == false)
940         {
941                 Damage(this, this, this, 100000, DEATH_KILL.m_id, DMG_NOWEP, this.origin, '0 0 0');
942         }
943
944         // now I am sure the player IS dead
945 }
946 void KillIndicator_Think(entity this)
947 {
948         if (game_stopped)
949         {
950                 this.owner.killindicator = NULL;
951                 delete(this);
952                 return;
953         }
954
955         if (this.owner.alpha < 0 && !this.owner.vehicle)
956         {
957                 this.owner.killindicator = NULL;
958                 delete(this);
959                 return;
960         }
961
962         if(this.cnt <= 0)
963         {
964                 ClientKill_Now(this.owner);
965                 return;
966         }
967     else if(this.health == 1) // health == 1 means that it's silent
968     {
969         this.nextthink = time + 1;
970         this.cnt -= 1;
971     }
972         else
973         {
974                 if(this.cnt <= 10)
975                         setmodel(this, MDL_NUM(this.cnt));
976                 if(IS_REAL_CLIENT(this.owner))
977                 {
978                         if(this.cnt <= 10)
979                                 { Send_Notification(NOTIF_ONE, this.owner, MSG_ANNCE, Announcer_PickNumber(CNT_KILL, this.cnt)); }
980                 }
981                 this.nextthink = time + 1;
982                 this.cnt -= 1;
983         }
984 }
985
986 float clientkilltime;
987 void ClientKill_TeamChange (entity this, float targetteam) // 0 = don't change, -1 = auto, -2 = spec
988 {
989         float killtime;
990         float starttime;
991
992         if (game_stopped)
993                 return;
994
995         killtime = autocvar_g_balance_kill_delay;
996
997     if(MUTATOR_CALLHOOK(ClientKill, this, killtime))
998         return;
999     killtime = M_ARGV(1, float);
1000
1001         this.killindicator_teamchange = targetteam;
1002
1003     if(!this.killindicator)
1004         {
1005                 if(!IS_DEAD(this))
1006                 {
1007                         killtime = max(killtime, this.clientkill_nexttime - time);
1008                         this.clientkill_nexttime = time + killtime + autocvar_g_balance_kill_antispam;
1009                 }
1010
1011                 if(killtime <= 0 || !IS_PLAYER(this) || IS_DEAD(this))
1012                 {
1013                         ClientKill_Now(this);
1014                 }
1015                 else
1016                 {
1017                         starttime = max(time, clientkilltime);
1018
1019                         this.killindicator = spawn();
1020                         this.killindicator.owner = this;
1021                         this.killindicator.scale = 0.5;
1022                         setattachment(this.killindicator, this, "");
1023                         setorigin(this.killindicator, '0 0 52');
1024                         setthink(this.killindicator, KillIndicator_Think);
1025                         this.killindicator.nextthink = starttime + (this.lip) * 0.05;
1026                         clientkilltime = max(clientkilltime, this.killindicator.nextthink + 0.05);
1027                         this.killindicator.cnt = ceil(killtime);
1028                         this.killindicator.count = bound(0, ceil(killtime), 10);
1029                         //sprint(this, strcat("^1You'll be dead in ", ftos(this.killindicator.cnt), " seconds\n"));
1030
1031                         IL_EACH(g_clones, it.enemy == this && !(it.effects & CSQCMODEL_EF_RESPAWNGHOST),
1032                         {
1033                                 it.killindicator = spawn();
1034                                 it.killindicator.owner = it;
1035                                 it.killindicator.scale = 0.5;
1036                                 setattachment(it.killindicator, it, "");
1037                                 setorigin(it.killindicator, '0 0 52');
1038                                 setthink(it.killindicator, KillIndicator_Think);
1039                                 it.killindicator.nextthink = starttime + (it.lip) * 0.05;
1040                                 //clientkilltime = max(clientkilltime, it.killindicator.nextthink + 0.05);
1041                                 it.killindicator.cnt = ceil(killtime);
1042                         });
1043                         this.lip = 0;
1044                 }
1045         }
1046         if(this.killindicator)
1047         {
1048                 if(targetteam == 0) // just die
1049                 {
1050                         this.killindicator.colormod = '0 0 0';
1051                         if(IS_REAL_CLIENT(this))
1052                         if(this.killindicator.cnt > 0)
1053                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_TEAMCHANGE_SUICIDE, this.killindicator.cnt);
1054                 }
1055                 else if(targetteam == -1) // auto
1056                 {
1057                         this.killindicator.colormod = '0 1 0';
1058                         if(IS_REAL_CLIENT(this))
1059                         if(this.killindicator.cnt > 0)
1060                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_TEAMCHANGE_AUTO, this.killindicator.cnt);
1061                 }
1062                 else if(targetteam == -2) // spectate
1063                 {
1064                         this.killindicator.colormod = '0.5 0.5 0.5';
1065                         if(IS_REAL_CLIENT(this))
1066                         if(this.killindicator.cnt > 0)
1067                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_TEAMCHANGE_SPECTATE, this.killindicator.cnt);
1068                 }
1069                 else
1070                 {
1071                         this.killindicator.colormod = Team_ColorRGB(targetteam);
1072                         if(IS_REAL_CLIENT(this))
1073                         if(this.killindicator.cnt > 0)
1074                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, APP_TEAM_NUM(targetteam, CENTER_TEAMCHANGE), this.killindicator.cnt);
1075                 }
1076         }
1077
1078 }
1079
1080 void ClientKill (entity this)
1081 {
1082         if(game_stopped) return;
1083         if(this.player_blocked) return;
1084         if(STAT(FROZEN, this)) return;
1085
1086         ClientKill_TeamChange(this, 0);
1087 }
1088
1089 void FixClientCvars(entity e)
1090 {
1091         // send prediction settings to the client
1092         stuffcmd(e, "\nin_bindmap 0 0\n");
1093         if(autocvar_g_antilag == 3) // client side hitscan
1094                 stuffcmd(e, "cl_cmd settemp cl_prydoncursor_notrace 0\n");
1095         if(autocvar_sv_gentle)
1096                 stuffcmd(e, "cl_cmd settemp cl_gentle 1\n");
1097
1098         stuffcmd(e, sprintf("\ncl_jumpspeedcap_min \"%s\"\n", autocvar_sv_jumpspeedcap_min));
1099         stuffcmd(e, sprintf("\ncl_jumpspeedcap_max \"%s\"\n", autocvar_sv_jumpspeedcap_max));
1100
1101         stuffcmd(e, sprintf("\ncl_shootfromfixedorigin \"%s\"\n", autocvar_g_shootfromfixedorigin));
1102
1103         MUTATOR_CALLHOOK(FixClientCvars, e);
1104 }
1105
1106 bool findinlist_abbrev(string tofind, string list)
1107 {
1108         if(list == "" || tofind == "")
1109                 return false; // empty list or search, just return
1110
1111         // this function allows abbreviated strings!
1112         FOREACH_WORD(list, it == substring(tofind, 0, strlen(it)),
1113         {
1114                 return true;
1115         });
1116
1117         return false;
1118 }
1119
1120 bool PlayerInIPList(entity p, string iplist)
1121 {
1122         // some safety checks (never allow local?)
1123         if(p.netaddress == "local" || p.netaddress == "" || !IS_REAL_CLIENT(p))
1124                 return false;
1125
1126         return findinlist_abbrev(p.netaddress, iplist);
1127 }
1128
1129 bool PlayerInIDList(entity p, string idlist)
1130 {
1131         // NOTE: we do NOT check crypto_idfp_signed here, an unsigned ID is fine too for this
1132         if(!p.crypto_idfp)
1133                 return false;
1134
1135         return findinlist_abbrev(p.crypto_idfp, idlist);
1136 }
1137
1138 bool PlayerInList(entity player, string list)
1139 {
1140         return boolean(PlayerInIDList(player, list) || PlayerInIPList(player, list));
1141 }
1142
1143 #ifdef DP_EXT_PRECONNECT
1144 /*
1145 =============
1146 ClientPreConnect
1147
1148 Called once (not at each match start) when a client begins a connection to the server
1149 =============
1150 */
1151 void ClientPreConnect(entity this)
1152 {
1153         if(autocvar_sv_eventlog)
1154         {
1155                 GameLogEcho(sprintf(":connect:%d:%d:%s",
1156                         this.playerid,
1157                         etof(this),
1158                         ((IS_REAL_CLIENT(this)) ? this.netaddress : "bot")
1159                 ));
1160         }
1161 }
1162 #endif
1163
1164 /**
1165 =============
1166 ClientConnect
1167
1168 Called when a client connects to the server
1169 =============
1170 */
1171 void ClientConnect(entity this)
1172 {
1173         if (Ban_MaybeEnforceBanOnce(this)) return;
1174         assert(!IS_CLIENT(this), return);
1175         this.flags |= FL_CLIENT;
1176         assert(player_count >= 0, player_count = 0);
1177
1178 #ifdef WATERMARK
1179         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_WATERMARK, WATERMARK);
1180 #endif
1181         TRANSMUTE(Client, this);
1182         CS(this).version_nagtime = time + 10 + random() * 10;
1183
1184         // identify the right forced team
1185         if (autocvar_g_campaign)
1186         {
1187                 if (IS_REAL_CLIENT(this)) // only players, not bots
1188                 {
1189                         switch (autocvar_g_campaign_forceteam)
1190                         {
1191                                 case 1: this.team_forced = NUM_TEAM_1; break;
1192                                 case 2: this.team_forced = NUM_TEAM_2; break;
1193                                 case 3: this.team_forced = NUM_TEAM_3; break;
1194                                 case 4: this.team_forced = NUM_TEAM_4; break;
1195                                 default: this.team_forced = 0;
1196                         }
1197                 }
1198         }
1199         else if (PlayerInList(this, autocvar_g_forced_team_red))    this.team_forced = NUM_TEAM_1;
1200         else if (PlayerInList(this, autocvar_g_forced_team_blue))   this.team_forced = NUM_TEAM_2;
1201         else if (PlayerInList(this, autocvar_g_forced_team_yellow)) this.team_forced = NUM_TEAM_3;
1202         else if (PlayerInList(this, autocvar_g_forced_team_pink))   this.team_forced = NUM_TEAM_4;
1203         else switch (autocvar_g_forced_team_otherwise)
1204         {
1205                 default: this.team_forced = 0; break;
1206                 case "red": this.team_forced = NUM_TEAM_1; break;
1207                 case "blue": this.team_forced = NUM_TEAM_2; break;
1208                 case "yellow": this.team_forced = NUM_TEAM_3; break;
1209                 case "pink": this.team_forced = NUM_TEAM_4; break;
1210                 case "spectate":
1211                 case "spectator":
1212                         this.team_forced = -1;
1213                         break;
1214         }
1215         if (!teamplay && this.team_forced > 0) this.team_forced = 0;
1216
1217         int playerid_save = this.playerid;
1218         this.playerid = 0; // silent
1219         JoinBestTeam(this, false); // if the team number is valid, keep it
1220         this.playerid = playerid_save;
1221
1222         if (autocvar_sv_spectate || autocvar_g_campaign || this.team_forced < 0) {
1223                 TRANSMUTE(Observer, this);
1224         } else {
1225                 if (!teamplay || autocvar_g_balance_teams) {
1226                         TRANSMUTE(Player, this);
1227                         campaign_bots_may_start = true;
1228                 } else {
1229                         TRANSMUTE(Observer, this); // do it anyway
1230                 }
1231         }
1232
1233         PlayerStats_GameReport_AddEvent(sprintf("kills-%d", this.playerid));
1234
1235         // always track bots, don't ask for cl_allow_uidtracking
1236         if (IS_BOT_CLIENT(this))
1237                 PlayerStats_GameReport_AddPlayer(this);
1238         else
1239                 CS(this).allowed_timeouts = autocvar_sv_timeout_number;
1240
1241         if (autocvar_sv_eventlog)
1242                 GameLogEcho(strcat(":join:", ftos(this.playerid), ":", ftos(etof(this)), ":", ((IS_REAL_CLIENT(this)) ? this.netaddress : "bot"), ":", playername(this, false)));
1243
1244         LogTeamchange(this.playerid, this.team, 1);
1245
1246         CS(this).just_joined = true;  // stop spamming the eventlog with additional lines when the client connects
1247
1248         if(teamplay && IS_PLAYER(this))
1249                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, APP_TEAM_NUM(this.team, INFO_JOIN_CONNECT_TEAM), this.netname);
1250         else
1251                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_JOIN_CONNECT, this.netname);
1252
1253         stuffcmd(this, clientstuff, "\n");
1254         stuffcmd(this, "cl_particles_reloadeffects\n"); // TODO do we still need this?
1255
1256         FixClientCvars(this);
1257
1258         // get version info from player
1259         stuffcmd(this, "cmd clientversion $gameversion\n");
1260
1261         // notify about available teams
1262         if (teamplay)
1263         {
1264                 CheckAllowedTeams(this);
1265                 int t = 0;
1266                 if (c1 >= 0) t |= BIT(0);
1267                 if (c2 >= 0) t |= BIT(1);
1268                 if (c3 >= 0) t |= BIT(2);
1269                 if (c4 >= 0) t |= BIT(3);
1270                 stuffcmd(this, sprintf("set _teams_available %d\n", t));
1271         }
1272         else
1273         {
1274                 stuffcmd(this, "set _teams_available 0\n");
1275         }
1276
1277         bot_relinkplayerlist();
1278
1279         CS(this).spectatortime = time;
1280         if (blockSpectators)
1281         {
1282                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
1283         }
1284
1285         CS(this).jointime = time;
1286
1287         if (IS_REAL_CLIENT(this))
1288         {
1289                 if (g_weaponarena_weapons == WEPSET(TUBA))
1290                         stuffcmd(this, "cl_cmd settemp chase_active 1\n");
1291         }
1292
1293         if (!sv_foginterval && world.fog != "")
1294                 stuffcmd(this, strcat("\nfog ", world.fog, "\nr_fog_exp2 0\nr_drawfog 1\n"));
1295
1296         if (autocvar_sv_teamnagger && !(autocvar_bot_vs_human && AvailableTeams() == 2))
1297                 if(!MUTATOR_CALLHOOK(HideTeamNagger, this))
1298                         send_CSQC_teamnagger();
1299
1300         CSQCMODEL_AUTOINIT(this);
1301
1302         CS(this).model_randomizer = random();
1303
1304         if (IS_REAL_CLIENT(this))
1305                 sv_notice_join(this);
1306
1307         // update physics stats (players can spawn before physics runs)
1308         Physics_UpdateStats(this);
1309
1310         IL_EACH(g_initforplayer, it.init_for_player, {
1311                 it.init_for_player(it, this);
1312         });
1313
1314         Handicap_Initialize(this);
1315
1316         MUTATOR_CALLHOOK(ClientConnect, this);
1317
1318         if (IS_REAL_CLIENT(this))
1319         {
1320                 if (!autocvar_g_campaign && !IS_PLAYER(this))
1321                 {
1322                         CS(this).motd_actived_time = -1;
1323                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOTD, getwelcomemessage(this));
1324                 }
1325         }
1326 }
1327 /*
1328 =============
1329 ClientDisconnect
1330
1331 Called when a client disconnects from the server
1332 =============
1333 */
1334 .entity chatbubbleentity;
1335 void ReadyCount();
1336 void ClientDisconnect(entity this)
1337 {
1338         assert(IS_CLIENT(this), return);
1339
1340         PlayerStats_GameReport_FinalizePlayer(this);
1341         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
1342         if (CS(this).active_minigame) part_minigame(this);
1343         if (IS_PLAYER(this)) Send_Effect(EFFECT_SPAWN_NEUTRAL, this.origin, '0 0 0', 1);
1344
1345         if (autocvar_sv_eventlog)
1346                 GameLogEcho(strcat(":part:", ftos(this.playerid)));
1347
1348         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_QUIT_DISCONNECT, this.netname);
1349
1350         if(IS_SPEC(this))
1351                 SetSpectatee(this, NULL);
1352
1353     MUTATOR_CALLHOOK(ClientDisconnect, this);
1354
1355         if (CS(this).netname_previous) strunzone(CS(this).netname_previous); // needs to be before the CS entity is removed!
1356         if (CS(this).weaponorder_byimpulse) strunzone(CS(this).weaponorder_byimpulse);
1357         ClientState_detach(this);
1358
1359         Portal_ClearAll(this);
1360
1361         Unfreeze(this);
1362
1363         RemoveGrapplingHooks(this);
1364
1365         // Here, everything has been done that requires this player to be a client.
1366
1367         this.flags &= ~FL_CLIENT;
1368
1369         if (this.chatbubbleentity) delete(this.chatbubbleentity);
1370         if (this.killindicator) delete(this.killindicator);
1371
1372         WaypointSprite_PlayerGone(this);
1373
1374         bot_relinkplayerlist();
1375
1376         if (this.clientstatus) strunzone(this.clientstatus);
1377         if (this.personal) delete(this.personal);
1378
1379         this.playerid = 0;
1380         ReadyCount();
1381         if (vote_called && IS_REAL_CLIENT(this)) VoteCount(false);
1382
1383         ONREMOVE(this);
1384 }
1385
1386 void ChatBubbleThink(entity this)
1387 {
1388         this.nextthink = time;
1389         if ((this.owner.alpha < 0) || this.owner.chatbubbleentity != this)
1390         {
1391                 if(this.owner) // but why can that ever be NULL?
1392                         this.owner.chatbubbleentity = NULL;
1393                 delete(this);
1394                 return;
1395         }
1396
1397         this.mdl = "";
1398
1399         if ( !IS_DEAD(this.owner) && IS_PLAYER(this.owner) )
1400         {
1401                 if ( CS(this.owner).active_minigame )
1402                         this.mdl = "models/sprites/minigame_busy.iqm";
1403                 else if (PHYS_INPUT_BUTTON_CHAT(this.owner))
1404                         this.mdl = "models/misc/chatbubble.spr";
1405         }
1406
1407         if ( this.model != this.mdl )
1408                 _setmodel(this, this.mdl);
1409
1410 }
1411
1412 void UpdateChatBubble(entity this)
1413 {
1414         if (this.alpha < 0)
1415                 return;
1416         // spawn a chatbubble entity if needed
1417         if (!this.chatbubbleentity)
1418         {
1419                 this.chatbubbleentity = new(chatbubbleentity);
1420                 this.chatbubbleentity.owner = this;
1421                 this.chatbubbleentity.exteriormodeltoclient = this;
1422                 setthink(this.chatbubbleentity, ChatBubbleThink);
1423                 this.chatbubbleentity.nextthink = time;
1424                 setmodel(this.chatbubbleentity, MDL_CHAT); // precision set below
1425                 //setorigin(this.chatbubbleentity, this.origin + '0 0 15' + this.maxs_z * '0 0 1');
1426                 setorigin(this.chatbubbleentity, '0 0 15' + this.maxs_z * '0 0 1');
1427                 setattachment(this.chatbubbleentity, this, "");  // sticks to moving player better, also conserves bandwidth
1428                 this.chatbubbleentity.mdl = this.chatbubbleentity.model;
1429                 //this.chatbubbleentity.model = "";
1430                 this.chatbubbleentity.effects = EF_LOWPRECISION;
1431         }
1432 }
1433
1434
1435 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
1436 // added to the model skins
1437 /*void UpdateColorModHack()
1438 {
1439         float c;
1440         c = this.clientcolors & 15;
1441         // LordHavoc: only bothering to support white, green, red, yellow, blue
1442              if (!teamplay) this.colormod = '0 0 0';
1443         else if (c ==  0) this.colormod = '1.00 1.00 1.00';
1444         else if (c ==  3) this.colormod = '0.10 1.73 0.10';
1445         else if (c ==  4) this.colormod = '1.73 0.10 0.10';
1446         else if (c == 12) this.colormod = '1.22 1.22 0.10';
1447         else if (c == 13) this.colormod = '0.10 0.10 1.73';
1448         else this.colormod = '1 1 1';
1449 }*/
1450
1451 void respawn(entity this)
1452 {
1453         if(this.alpha >= 0 && autocvar_g_respawn_ghosts)
1454         {
1455                 this.solid = SOLID_NOT;
1456                 this.takedamage = DAMAGE_NO;
1457                 set_movetype(this, MOVETYPE_FLY);
1458                 this.velocity = '0 0 1' * autocvar_g_respawn_ghosts_speed;
1459                 this.avelocity = randomvec() * autocvar_g_respawn_ghosts_speed * 3 - randomvec() * autocvar_g_respawn_ghosts_speed * 3;
1460                 this.effects |= CSQCMODEL_EF_RESPAWNGHOST;
1461                 Send_Effect(EFFECT_RESPAWN_GHOST, this.origin, '0 0 0', 1);
1462                 if(autocvar_g_respawn_ghosts_maxtime)
1463                         SUB_SetFade (this, time + autocvar_g_respawn_ghosts_maxtime / 2 + random () * (autocvar_g_respawn_ghosts_maxtime - autocvar_g_respawn_ghosts_maxtime / 2), 1.5);
1464         }
1465
1466         CopyBody(this, 1);
1467
1468         this.effects |= EF_NODRAW; // prevent another CopyBody
1469         PutClientInServer(this);
1470 }
1471
1472 void play_countdown(entity this, float finished, Sound samp)
1473 {
1474     TC(Sound, samp);
1475         if(IS_REAL_CLIENT(this))
1476                 if(floor(finished - time - frametime) != floor(finished - time))
1477                         if(finished - time < 6)
1478                                 sound (this, CH_INFO, samp, VOL_BASE, ATTEN_NORM);
1479 }
1480
1481 void player_powerups(entity this)
1482 {
1483         // add a way to see what the items were BEFORE all of these checks for the mutator hook
1484         int items_prev = this.items;
1485
1486         if((this.items & IT_USING_JETPACK) && !IS_DEAD(this) && !game_stopped)
1487                 this.modelflags |= MF_ROCKET;
1488         else
1489                 this.modelflags &= ~MF_ROCKET;
1490
1491         this.effects &= ~(EF_RED | EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT | EF_FLAME | EF_NODEPTHTEST);
1492
1493         if((this.alpha < 0 || IS_DEAD(this)) && !this.vehicle) // don't apply the flags if the player is gibbed
1494                 return;
1495
1496         Fire_ApplyDamage(this);
1497         Fire_ApplyEffect(this);
1498
1499         if (!g_instagib)
1500         {
1501                 if (this.items & ITEM_Strength.m_itemid)
1502                 {
1503                         play_countdown(this, this.strength_finished, SND_POWEROFF);
1504                         this.effects = this.effects | (EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT);
1505                         if (time > this.strength_finished)
1506                         {
1507                                 this.items = this.items - (this.items & ITEM_Strength.m_itemid);
1508                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERDOWN_STRENGTH, this.netname);
1509                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERDOWN_STRENGTH);
1510                         }
1511                 }
1512                 else
1513                 {
1514                         if (time < this.strength_finished)
1515                         {
1516                                 this.items = this.items | ITEM_Strength.m_itemid;
1517                                 if(!g_cts)
1518                                         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERUP_STRENGTH, this.netname);
1519                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERUP_STRENGTH);
1520                         }
1521                 }
1522                 if (this.items & ITEM_Shield.m_itemid)
1523                 {
1524                         play_countdown(this, this.invincible_finished, SND_POWEROFF);
1525                         this.effects = this.effects | (EF_RED | EF_ADDITIVE | EF_FULLBRIGHT);
1526                         if (time > this.invincible_finished)
1527                         {
1528                                 this.items = this.items - (this.items & ITEM_Shield.m_itemid);
1529                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERDOWN_SHIELD, this.netname);
1530                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERDOWN_SHIELD);
1531                         }
1532                 }
1533                 else
1534                 {
1535                         if (time < this.invincible_finished)
1536                         {
1537                                 this.items = this.items | ITEM_Shield.m_itemid;
1538                                 if(!g_cts)
1539                                         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERUP_SHIELD, this.netname);
1540                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERUP_SHIELD);
1541                         }
1542                 }
1543                 if (this.items & IT_SUPERWEAPON)
1544                 {
1545                         if (!(this.weapons & WEPSET_SUPERWEAPONS))
1546                         {
1547                                 this.superweapons_finished = 0;
1548                                 this.items = this.items - (this.items & IT_SUPERWEAPON);
1549                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_LOST, this.netname);
1550                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_LOST);
1551                         }
1552                         else if (this.items & IT_UNLIMITED_SUPERWEAPONS)
1553                         {
1554                                 // don't let them run out
1555                         }
1556                         else
1557                         {
1558                                 play_countdown(this, this.superweapons_finished, SND_POWEROFF);
1559                                 if (time > this.superweapons_finished)
1560                                 {
1561                                         this.items = this.items - (this.items & IT_SUPERWEAPON);
1562                                         this.weapons &= ~WEPSET_SUPERWEAPONS;
1563                                         //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_BROKEN, this.netname);
1564                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_BROKEN);
1565                                 }
1566                         }
1567                 }
1568                 else if(this.weapons & WEPSET_SUPERWEAPONS)
1569                 {
1570                         if (time < this.superweapons_finished || (this.items & IT_UNLIMITED_SUPERWEAPONS))
1571                         {
1572                                 this.items = this.items | IT_SUPERWEAPON;
1573                                 if(!g_cts)
1574                                         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_PICKUP, this.netname);
1575                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_PICKUP);
1576                         }
1577                         else
1578                         {
1579                                 this.superweapons_finished = 0;
1580                                 this.weapons &= ~WEPSET_SUPERWEAPONS;
1581                         }
1582                 }
1583                 else
1584                 {
1585                         this.superweapons_finished = 0;
1586                 }
1587         }
1588
1589         if(autocvar_g_nodepthtestplayers)
1590                 this.effects = this.effects | EF_NODEPTHTEST;
1591
1592         if(autocvar_g_fullbrightplayers)
1593                 this.effects = this.effects | EF_FULLBRIGHT;
1594
1595         if (time >= game_starttime)
1596         if (time < this.spawnshieldtime)
1597                 this.effects = this.effects | (EF_ADDITIVE | EF_FULLBRIGHT);
1598
1599         MUTATOR_CALLHOOK(PlayerPowerups, this, items_prev);
1600 }
1601
1602 float CalcRegen(float current, float stable, float regenfactor, float regenframetime)
1603 {
1604         if(current > stable)
1605                 return current;
1606         else if(current > stable - 0.25) // when close enough, "snap"
1607                 return stable;
1608         else
1609                 return min(stable, current + (stable - current) * regenfactor * regenframetime);
1610 }
1611
1612 float CalcRot(float current, float stable, float rotfactor, float rotframetime)
1613 {
1614         if(current < stable)
1615                 return current;
1616         else if(current < stable + 0.25) // when close enough, "snap"
1617                 return stable;
1618         else
1619                 return max(stable, current + (stable - current) * rotfactor * rotframetime);
1620 }
1621
1622 float CalcRotRegen(float current, float regenstable, float regenfactor, float regenlinear, float regenframetime, float rotstable, float rotfactor, float rotlinear, float rotframetime, float limit)
1623 {
1624         if(current > rotstable)
1625         {
1626                 if(rotframetime > 0)
1627                 {
1628                         current = CalcRot(current, rotstable, rotfactor, rotframetime);
1629                         current = max(rotstable, current - rotlinear * rotframetime);
1630                 }
1631         }
1632         else if(current < regenstable)
1633         {
1634                 if(regenframetime > 0)
1635                 {
1636                         current = CalcRegen(current, regenstable, regenfactor, regenframetime);
1637                         current = min(regenstable, current + regenlinear * regenframetime);
1638                 }
1639         }
1640
1641         if(current > limit)
1642                 current = limit;
1643
1644         return current;
1645 }
1646
1647 void player_regen(entity this)
1648 {
1649         float max_mod, regen_mod, rot_mod, limit_mod;
1650         max_mod = regen_mod = rot_mod = limit_mod = 1;
1651
1652         float regen_health = autocvar_g_balance_health_regen;
1653         float regen_health_linear = autocvar_g_balance_health_regenlinear;
1654         float regen_health_rot = autocvar_g_balance_health_rot;
1655         float regen_health_rotlinear = autocvar_g_balance_health_rotlinear;
1656         float regen_health_stable = autocvar_g_balance_health_regenstable;
1657         float regen_health_rotstable = autocvar_g_balance_health_rotstable;
1658         bool mutator_returnvalue = MUTATOR_CALLHOOK(PlayerRegen, this, max_mod, regen_mod, rot_mod, limit_mod, regen_health, regen_health_linear, regen_health_rot,
1659                 regen_health_rotlinear, regen_health_stable, regen_health_rotstable);
1660         max_mod = M_ARGV(1, float);
1661         regen_mod = M_ARGV(2, float);
1662         rot_mod = M_ARGV(3, float);
1663         limit_mod = M_ARGV(4, float);
1664         regen_health = M_ARGV(5, float);
1665         regen_health_linear = M_ARGV(6, float);
1666         regen_health_rot = M_ARGV(7, float);
1667         regen_health_rotlinear = M_ARGV(8, float);
1668         regen_health_stable = M_ARGV(9, float);
1669         regen_health_rotstable = M_ARGV(10, float);
1670
1671         if(!mutator_returnvalue)
1672         if(!STAT(FROZEN, this))
1673         {
1674                 float mina, maxa, limith, limita;
1675                 maxa = autocvar_g_balance_armor_rotstable;
1676                 mina = autocvar_g_balance_armor_regenstable;
1677                 limith = GetResourceLimit(this, RESOURCE_HEALTH);
1678                 limita = GetResourceLimit(this, RESOURCE_ARMOR);
1679
1680                 regen_health_rotstable = regen_health_rotstable * max_mod;
1681                 regen_health_stable = regen_health_stable * max_mod;
1682                 limith = limith * limit_mod;
1683                 limita = limita * limit_mod;
1684
1685                 this.armorvalue = CalcRotRegen(this.armorvalue, mina, autocvar_g_balance_armor_regen, autocvar_g_balance_armor_regenlinear, regen_mod * frametime * (time > this.pauseregen_finished), maxa, autocvar_g_balance_armor_rot, autocvar_g_balance_armor_rotlinear, rot_mod * frametime * (time > this.pauserotarmor_finished), limita);
1686                 this.health = CalcRotRegen(this.health, regen_health_stable, regen_health, regen_health_linear, regen_mod * frametime * (time > this.pauseregen_finished), regen_health_rotstable, regen_health_rot, regen_health_rotlinear, rot_mod * frametime * (time > this.pauserothealth_finished), limith);
1687         }
1688
1689         // if player rotted to death...  die!
1690         // check this outside above checks, as player may still be able to rot to death
1691         if(this.health < 1)
1692         {
1693                 if(this.vehicle)
1694                         vehicles_exit(this.vehicle, VHEF_RELEASE);
1695                 if(this.event_damage)
1696                         this.event_damage(this, this, this, 1, DEATH_ROT.m_id, DMG_NOWEP, this.origin, '0 0 0');
1697         }
1698
1699         if (!(this.items & IT_UNLIMITED_WEAPON_AMMO))
1700         {
1701                 float minf, maxf, limitf;
1702
1703                 maxf = autocvar_g_balance_fuel_rotstable;
1704                 minf = autocvar_g_balance_fuel_regenstable;
1705                 limitf = GetResourceLimit(this, RESOURCE_FUEL);
1706
1707                 this.ammo_fuel = CalcRotRegen(this.ammo_fuel, minf, autocvar_g_balance_fuel_regen, autocvar_g_balance_fuel_regenlinear, frametime * (time > this.pauseregen_finished) * ((this.items & ITEM_JetpackRegen.m_itemid) != 0), maxf, autocvar_g_balance_fuel_rot, autocvar_g_balance_fuel_rotlinear, frametime * (time > this.pauserotfuel_finished), limitf);
1708         }
1709         // Ugly hack to make sure the health and armor don't go beyond hard limit.
1710         // TODO: Remove this hack when all code uses GivePlayerHealth and
1711         // GivePlayerArmor.
1712         if (this.health > RESOURCE_AMOUNT_HARD_LIMIT)
1713         {
1714                 this.health = RESOURCE_AMOUNT_HARD_LIMIT;
1715         }
1716         if (this.armorvalue > RESOURCE_AMOUNT_HARD_LIMIT)
1717         {
1718                 this.armorvalue = RESOURCE_AMOUNT_HARD_LIMIT;
1719         }
1720         // End hack.
1721 }
1722
1723 bool zoomstate_set;
1724 void SetZoomState(entity this, float newzoom)
1725 {
1726         if(newzoom != CS(this).zoomstate)
1727         {
1728                 CS(this).zoomstate = newzoom;
1729                 ClientData_Touch(this);
1730         }
1731         zoomstate_set = true;
1732 }
1733
1734 void GetPressedKeys(entity this)
1735 {
1736         MUTATOR_CALLHOOK(GetPressedKeys, this);
1737         int keys = STAT(PRESSED_KEYS, this);
1738         keys = BITSET(keys, KEY_FORWARD,        CS(this).movement.x > 0);
1739         keys = BITSET(keys, KEY_BACKWARD,       CS(this).movement.x < 0);
1740         keys = BITSET(keys, KEY_RIGHT,          CS(this).movement.y > 0);
1741         keys = BITSET(keys, KEY_LEFT,           CS(this).movement.y < 0);
1742
1743         keys = BITSET(keys, KEY_JUMP,           PHYS_INPUT_BUTTON_JUMP(this));
1744         keys = BITSET(keys, KEY_CROUCH,         PHYS_INPUT_BUTTON_CROUCH(this));
1745         keys = BITSET(keys, KEY_ATCK,           PHYS_INPUT_BUTTON_ATCK(this));
1746         keys = BITSET(keys, KEY_ATCK2,          PHYS_INPUT_BUTTON_ATCK2(this));
1747         CS(this).pressedkeys = keys; // store for other users
1748
1749         STAT(PRESSED_KEYS, this) = keys;
1750 }
1751
1752 /*
1753 ======================
1754 spectate mode routines
1755 ======================
1756 */
1757
1758 void SpectateCopy(entity this, entity spectatee)
1759 {
1760     TC(Client, this); TC(Client, spectatee);
1761
1762         MUTATOR_CALLHOOK(SpectateCopy, spectatee, this);
1763         PS(this) = PS(spectatee);
1764         this.armortype = spectatee.armortype;
1765         this.armorvalue = spectatee.armorvalue;
1766         this.ammo_cells = spectatee.ammo_cells;
1767         this.ammo_plasma = spectatee.ammo_plasma;
1768         this.ammo_shells = spectatee.ammo_shells;
1769         this.ammo_nails = spectatee.ammo_nails;
1770         this.ammo_rockets = spectatee.ammo_rockets;
1771         this.ammo_fuel = spectatee.ammo_fuel;
1772         this.effects = spectatee.effects & EFMASK_CHEAP; // eat performance
1773         this.health = spectatee.health;
1774         CS(this).impulse = 0;
1775         this.items = spectatee.items;
1776         STAT(LAST_PICKUP, this) = STAT(LAST_PICKUP, spectatee);
1777         STAT(HIT_TIME, this) = STAT(HIT_TIME, spectatee);
1778         this.strength_finished = spectatee.strength_finished;
1779         this.invincible_finished = spectatee.invincible_finished;
1780         this.superweapons_finished = spectatee.superweapons_finished;
1781         STAT(PRESSED_KEYS, this) = STAT(PRESSED_KEYS, spectatee);
1782         this.weapons = spectatee.weapons;
1783         this.punchangle = spectatee.punchangle;
1784         this.view_ofs = spectatee.view_ofs;
1785         this.velocity = spectatee.velocity;
1786         this.dmg_take = spectatee.dmg_take;
1787         this.dmg_save = spectatee.dmg_save;
1788         this.dmg_inflictor = spectatee.dmg_inflictor;
1789         this.v_angle = spectatee.v_angle;
1790         this.angles = spectatee.v_angle;
1791         STAT(FROZEN, this) = STAT(FROZEN, spectatee);
1792         STAT(REVIVE_PROGRESS, this) = STAT(REVIVE_PROGRESS, spectatee);
1793         this.viewloc = spectatee.viewloc;
1794         if(!PHYS_INPUT_BUTTON_USE(this) && STAT(CAMERA_SPECTATOR, this) != 2)
1795                 this.fixangle = true;
1796         setorigin(this, spectatee.origin);
1797         setsize(this, spectatee.mins, spectatee.maxs);
1798         SetZoomState(this, CS(spectatee).zoomstate);
1799
1800     anticheat_spectatecopy(this, spectatee);
1801         STAT(HUD, this) = STAT(HUD, spectatee);
1802         if(spectatee.vehicle)
1803     {
1804         this.angles = spectatee.v_angle;
1805
1806         //this.fixangle = false;
1807         //this.velocity = spectatee.vehicle.velocity;
1808         this.vehicle_health = spectatee.vehicle_health;
1809         this.vehicle_shield = spectatee.vehicle_shield;
1810         this.vehicle_energy = spectatee.vehicle_energy;
1811         this.vehicle_ammo1 = spectatee.vehicle_ammo1;
1812         this.vehicle_ammo2 = spectatee.vehicle_ammo2;
1813         this.vehicle_reload1 = spectatee.vehicle_reload1;
1814         this.vehicle_reload2 = spectatee.vehicle_reload2;
1815
1816         //msg_entity = this;
1817
1818        // WriteByte (MSG_ONE, SVC_SETVIEWANGLES);
1819             //WriteAngle(MSG_ONE,  spectatee.v_angle.x);
1820            // WriteAngle(MSG_ONE,  spectatee.v_angle.y);
1821            // WriteAngle(MSG_ONE,  spectatee.v_angle.z);
1822
1823         //WriteByte (MSG_ONE, SVC_SETVIEW);
1824         //    WriteEntity(MSG_ONE, this);
1825         //makevectors(spectatee.v_angle);
1826         //setorigin(this, spectatee.origin - v_forward * 400 + v_up * 300);*/
1827     }
1828 }
1829
1830 bool SpectateUpdate(entity this)
1831 {
1832         if(!this.enemy)
1833                 return false;
1834
1835         if(!IS_PLAYER(this.enemy) || this == this.enemy)
1836         {
1837                 SetSpectatee(this, NULL);
1838                 return false;
1839         }
1840
1841         SpectateCopy(this, this.enemy);
1842
1843         return true;
1844 }
1845
1846 bool SpectateSet(entity this)
1847 {
1848         if(!IS_PLAYER(this.enemy))
1849                 return false;
1850
1851         ClientData_Touch(this.enemy);
1852
1853         msg_entity = this;
1854         WriteByte(MSG_ONE, SVC_SETVIEW);
1855         WriteEntity(MSG_ONE, this.enemy);
1856         set_movetype(this, MOVETYPE_NONE);
1857         accuracy_resend(this);
1858
1859         if(!SpectateUpdate(this))
1860                 PutObserverInServer(this);
1861
1862         return true;
1863 }
1864
1865 void SetSpectatee_status(entity this, int spectatee_num)
1866 {
1867         int oldspectatee_status = CS(this).spectatee_status;
1868         CS(this).spectatee_status = spectatee_num;
1869
1870         if (CS(this).spectatee_status != oldspectatee_status)
1871         {
1872                 ClientData_Touch(this);
1873                 if (g_race || g_cts) race_InitSpectator();
1874         }
1875 }
1876
1877 void SetSpectatee(entity this, entity spectatee)
1878 {
1879         if(IS_BOT_CLIENT(this))
1880                 return; // bots abuse .enemy, this code is useless to them
1881
1882         entity old_spectatee = this.enemy;
1883
1884         this.enemy = spectatee;
1885
1886         // WEAPONTODO
1887         // these are required to fix the spectator bug with arc
1888         if(old_spectatee)
1889         {
1890                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1891                 {
1892                         .entity weaponentity = weaponentities[slot];
1893                         if(old_spectatee.(weaponentity).arc_beam)
1894                                 old_spectatee.(weaponentity).arc_beam.SendFlags |= ARC_SF_SETTINGS;
1895                 }
1896         }
1897         if(this.enemy)
1898         {
1899                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1900                 {
1901                         .entity weaponentity = weaponentities[slot];
1902                         if(this.enemy.(weaponentity).arc_beam)
1903                                 this.enemy.(weaponentity).arc_beam.SendFlags |= ARC_SF_SETTINGS;
1904                 }
1905         }
1906
1907         if (this.enemy)
1908                 SetSpectatee_status(this, etof(this.enemy));
1909
1910         // needed to update spectator list
1911         if(old_spectatee) { ClientData_Touch(old_spectatee); }
1912 }
1913
1914 bool Spectate(entity this, entity pl)
1915 {
1916         if(MUTATOR_CALLHOOK(SpectateSet, this, pl))
1917                 return false;
1918         pl = M_ARGV(1, entity);
1919
1920         SetSpectatee(this, pl);
1921         return SpectateSet(this);
1922 }
1923
1924 bool SpectateNext(entity this)
1925 {
1926         entity ent = find(this.enemy, classname, STR_PLAYER);
1927
1928         if (MUTATOR_CALLHOOK(SpectateNext, this, ent))
1929                 ent = M_ARGV(1, entity);
1930         else if (!ent)
1931                 ent = find(ent, classname, STR_PLAYER);
1932
1933         if(ent) { SetSpectatee(this, ent); }
1934
1935         return SpectateSet(this);
1936 }
1937
1938 bool SpectatePrev(entity this)
1939 {
1940         // NOTE: chain order is from the highest to the lower entnum (unlike find)
1941         entity ent = findchain(classname, STR_PLAYER);
1942         if (!ent) // no player
1943                 return false;
1944
1945         entity first = ent;
1946         // skip players until current spectated player
1947         if(this.enemy)
1948         while(ent && ent != this.enemy)
1949                 ent = ent.chain;
1950
1951         switch (MUTATOR_CALLHOOK(SpectatePrev, this, ent, first))
1952         {
1953                 case MUT_SPECPREV_FOUND:
1954                     ent = M_ARGV(1, entity);
1955                     break;
1956                 case MUT_SPECPREV_RETURN:
1957                     return true;
1958                 case MUT_SPECPREV_CONTINUE:
1959                 default:
1960                 {
1961                         if(ent.chain)
1962                                 ent = ent.chain;
1963                         else
1964                                 ent = first;
1965                         break;
1966                 }
1967         }
1968
1969         SetSpectatee(this, ent);
1970         return SpectateSet(this);
1971 }
1972
1973 /*
1974 =============
1975 ShowRespawnCountdown()
1976
1977 Update a respawn countdown display.
1978 =============
1979 */
1980 void ShowRespawnCountdown(entity this)
1981 {
1982         float number;
1983         if(!IS_DEAD(this)) // just respawned?
1984                 return;
1985         else
1986         {
1987                 number = ceil(this.respawn_time - time);
1988                 if(number <= 0)
1989                         return;
1990                 if(number <= this.respawn_countdown)
1991                 {
1992                         this.respawn_countdown = number - 1;
1993                         if(ceil(this.respawn_time - (time + 0.5)) == number) // only say it if it is the same number even in 0.5s; to prevent overlapping sounds
1994                                 { Send_Notification(NOTIF_ONE, this, MSG_ANNCE, Announcer_PickNumber(CNT_RESPAWN, number)); }
1995                 }
1996         }
1997 }
1998
1999 .bool team_selected;
2000 bool ShowTeamSelection(entity this)
2001 {
2002         if(!teamplay || autocvar_g_campaign || autocvar_g_balance_teams || this.team_selected || (CS(this).wasplayer && autocvar_g_changeteam_banned) || this.team_forced > 0)
2003                 return false;
2004         stuffcmd(this, "menu_showteamselect\n");
2005         return true;
2006 }
2007 void Join(entity this)
2008 {
2009         TRANSMUTE(Player, this);
2010
2011         if(!this.team_selected)
2012         if(autocvar_g_campaign || autocvar_g_balance_teams)
2013                 JoinBestTeam(this, true);
2014
2015         if(autocvar_g_campaign)
2016                 campaign_bots_may_start = true;
2017
2018         Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_PREVENT_JOIN);
2019
2020         PutClientInServer(this);
2021
2022         if(IS_PLAYER(this))
2023         if(teamplay && this.team != -1)
2024                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, APP_TEAM_NUM(this.team, INFO_JOIN_PLAY_TEAM), this.netname);
2025         else
2026                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_JOIN_PLAY, this.netname);
2027         this.team_selected = false;
2028 }
2029
2030 /**
2031  * Determines whether the player is allowed to join. This depends on cvar
2032  * g_maxplayers, if it isn't used this function always return true, otherwise
2033  * it checks whether the number of currently playing players exceeds g_maxplayers.
2034  * @return int number of free slots for players, 0 if none
2035  */
2036 int nJoinAllowed(entity this, entity ignore)
2037 {
2038         if(!ignore)
2039         // this is called that way when checking if anyone may be able to join (to build qcstatus)
2040         // so report 0 free slots if restricted
2041         {
2042                 if(autocvar_g_forced_team_otherwise == "spectate")
2043                         return 0;
2044                 if(autocvar_g_forced_team_otherwise == "spectator")
2045                         return 0;
2046         }
2047
2048         if(this && this.team_forced < 0)
2049                 return 0; // forced spectators can never join
2050
2051         // TODO simplify this
2052         int totalClients = 0;
2053         int currentlyPlaying = 0;
2054         FOREACH_CLIENT(true, {
2055                 if(it != ignore)
2056                         ++totalClients;
2057                 if(IS_REAL_CLIENT(it))
2058                 if(IS_PLAYER(it) || it.caplayer)
2059                         ++currentlyPlaying;
2060         });
2061
2062         float free_slots = 0;
2063         if (!autocvar_g_maxplayers)
2064                 free_slots = maxclients - totalClients;
2065         else if(currentlyPlaying < autocvar_g_maxplayers)
2066                 free_slots = min(maxclients - totalClients, autocvar_g_maxplayers - currentlyPlaying);
2067
2068         static float join_prevent_msg_time = 0;
2069         if(this && ignore && !free_slots && time > join_prevent_msg_time)
2070         {
2071                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_JOIN_PREVENT);
2072                 join_prevent_msg_time = time + 3;
2073         }
2074
2075         return free_slots;
2076 }
2077
2078 /**
2079  * Checks whether the client is an observer or spectator, if so, he will get kicked after
2080  * g_maxplayers_spectator_blocktime seconds
2081  */
2082 void checkSpectatorBlock(entity this)
2083 {
2084         if(IS_SPEC(this) || IS_OBSERVER(this))
2085         if(!this.caplayer)
2086         if(IS_REAL_CLIENT(this))
2087         {
2088                 if( time > (CS(this).spectatortime + autocvar_g_maxplayers_spectator_blocktime) ) {
2089                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_QUIT_KICK_SPECTATING);
2090                         dropclient(this);
2091                 }
2092         }
2093 }
2094
2095 void PrintWelcomeMessage(entity this)
2096 {
2097         if(CS(this).motd_actived_time == 0)
2098         {
2099                 if (autocvar_g_campaign) {
2100                         if ((IS_PLAYER(this) && PHYS_INPUT_BUTTON_INFO(this)) || (!IS_PLAYER(this))) {
2101                                 CS(this).motd_actived_time = time;
2102                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOTD, campaign_message);
2103                         }
2104                 } else {
2105                         if (PHYS_INPUT_BUTTON_INFO(this)) {
2106                                 CS(this).motd_actived_time = time;
2107                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOTD, getwelcomemessage(this));
2108                         }
2109                 }
2110         }
2111         else if(CS(this).motd_actived_time > 0) // showing MOTD or campaign message
2112         {
2113                 if (autocvar_g_campaign) {
2114                         if (PHYS_INPUT_BUTTON_INFO(this))
2115                                 CS(this).motd_actived_time = time;
2116                         else if ((time - CS(this).motd_actived_time > 2) && IS_PLAYER(this)) { // hide it some seconds after BUTTON_INFO has been released
2117                                 CS(this).motd_actived_time = 0;
2118                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_MOTD);
2119                         }
2120                 } else {
2121                         if (PHYS_INPUT_BUTTON_INFO(this))
2122                                 CS(this).motd_actived_time = time;
2123                         else if (time - CS(this).motd_actived_time > 2) { // hide it some seconds after BUTTON_INFO has been released
2124                                 CS(this).motd_actived_time = 0;
2125                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_MOTD);
2126                         }
2127                 }
2128         }
2129         else //if(CS(this).motd_actived_time < 0) // just connected, motd is active
2130         {
2131                 if(PHYS_INPUT_BUTTON_INFO(this)) // BUTTON_INFO hides initial MOTD
2132                         CS(this).motd_actived_time = -2; // wait until BUTTON_INFO gets released
2133                 else if(CS(this).motd_actived_time == -2 || IS_PLAYER(this) || IS_SPEC(this))
2134                 {
2135                         // instanctly hide MOTD
2136                         CS(this).motd_actived_time = 0;
2137                         Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_MOTD);
2138                 }
2139         }
2140 }
2141
2142 bool joinAllowed(entity this)
2143 {
2144         if (CS(this).version_mismatch) return false;
2145         if (!nJoinAllowed(this, this)) return false;
2146         if (teamplay && lockteams) return false;
2147         if (ShowTeamSelection(this)) return false;
2148         if (MUTATOR_CALLHOOK(ForbidSpawn, this)) return false;
2149         return true;
2150 }
2151
2152 .int items_added;
2153 .string shootfromfixedorigin;
2154 bool PlayerThink(entity this)
2155 {
2156         if (game_stopped || intermission_running) {
2157                 this.modelflags &= ~MF_ROCKET;
2158                 if(intermission_running)
2159                         IntermissionThink(this);
2160                 return false;
2161         }
2162
2163         if (timeout_status == TIMEOUT_ACTIVE) {
2164         // don't allow the player to turn around while game is paused
2165                 // FIXME turn this into CSQC stuff
2166                 this.v_angle = this.lastV_angle;
2167                 this.angles = this.lastV_angle;
2168                 this.fixangle = true;
2169         }
2170
2171         if (frametime) player_powerups(this);
2172
2173         if (IS_DEAD(this)) {
2174                 if (this.personal && g_race_qualifying) {
2175                         if (time > this.respawn_time) {
2176                                 STAT(RESPAWN_TIME, this) = this.respawn_time = time + 1; // only retry once a second
2177                                 respawn(this);
2178                                 CS(this).impulse = CHIMPULSE_SPEEDRUN.impulse;
2179                         }
2180                 } else {
2181                         if (frametime) player_anim(this);
2182
2183                         if (this.respawn_flags & RESPAWN_DENY)
2184                         {
2185                                 STAT(RESPAWN_TIME, this) = 0;
2186                                 return false;
2187                         }
2188
2189                         bool button_pressed = (PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_JUMP(this) || PHYS_INPUT_BUTTON_ATCK2(this) || PHYS_INPUT_BUTTON_HOOK(this) || PHYS_INPUT_BUTTON_USE(this));
2190
2191                         switch(this.deadflag)
2192                         {
2193                                 case DEAD_DYING:
2194                                 {
2195                                         if ((this.respawn_flags & RESPAWN_FORCE) && !(this.respawn_time < this.respawn_time_max))
2196                                                 this.deadflag = DEAD_RESPAWNING;
2197                                         else if (!button_pressed || (time >= this.respawn_time_max && (this.respawn_flags & RESPAWN_FORCE)))
2198                                                 this.deadflag = DEAD_DEAD;
2199                                         break;
2200                                 }
2201                                 case DEAD_DEAD:
2202                                 {
2203                                         if (button_pressed)
2204                                                 this.deadflag = DEAD_RESPAWNABLE;
2205                                         else if (time >= this.respawn_time_max && (this.respawn_flags & RESPAWN_FORCE))
2206                                                 this.deadflag = DEAD_RESPAWNING;
2207                                         break;
2208                                 }
2209                                 case DEAD_RESPAWNABLE:
2210                                 {
2211                                         if (!button_pressed || (this.respawn_flags & RESPAWN_FORCE))
2212                                                 this.deadflag = DEAD_RESPAWNING;
2213                                         break;
2214                                 }
2215                                 case DEAD_RESPAWNING:
2216                                 {
2217                                         if (time > this.respawn_time)
2218                                         {
2219                                                 this.respawn_time = time + 1; // only retry once a second
2220                                                 this.respawn_time_max = this.respawn_time;
2221                                                 respawn(this);
2222                                         }
2223                                         break;
2224                                 }
2225                         }
2226
2227                         ShowRespawnCountdown(this);
2228
2229                         if (this.respawn_flags & RESPAWN_SILENT)
2230                                 STAT(RESPAWN_TIME, this) = 0;
2231                         else if ((this.respawn_flags & RESPAWN_FORCE) && this.respawn_time < this.respawn_time_max)
2232                         {
2233                                 if (time < this.respawn_time)
2234                                         STAT(RESPAWN_TIME, this) = this.respawn_time;
2235                                 else if (this.deadflag != DEAD_RESPAWNING)
2236                                         STAT(RESPAWN_TIME, this) = -this.respawn_time_max;
2237                         }
2238                         else
2239                                 STAT(RESPAWN_TIME, this) = this.respawn_time;
2240                 }
2241
2242                 // if respawning, invert stat_respawn_time to indicate this, the client translates it
2243                 if (this.deadflag == DEAD_RESPAWNING && STAT(RESPAWN_TIME, this) > 0)
2244                         STAT(RESPAWN_TIME, this) *= -1;
2245
2246                 return false;
2247         }
2248
2249         FixPlayermodel(this);
2250
2251         if (this.shootfromfixedorigin != autocvar_g_shootfromfixedorigin) {
2252                 this.shootfromfixedorigin = autocvar_g_shootfromfixedorigin;
2253                 stuffcmd(this, sprintf("\ncl_shootfromfixedorigin \"%s\"\n", autocvar_g_shootfromfixedorigin));
2254         }
2255
2256         // LordHavoc: allow firing on move frames (sub-ticrate), this gives better timing on slow servers
2257         //if(frametime)
2258         {
2259                 this.items &= ~this.items_added;
2260
2261                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2262                 {
2263                         .entity weaponentity = weaponentities[slot];
2264                         W_WeaponFrame(this, weaponentity);
2265                 }
2266
2267                 this.items_added = 0;
2268                 if ((this.items & ITEM_Jetpack.m_itemid) && ((this.items & ITEM_JetpackRegen.m_itemid) || this.ammo_fuel >= 0.01))
2269             this.items_added |= IT_FUEL;
2270
2271                 this.items |= this.items_added;
2272         }
2273
2274         player_regen(this);
2275
2276         // WEAPONTODO: Add a weapon request for this
2277         // rot vortex charge to the charge limit
2278         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2279         {
2280                 .entity weaponentity = weaponentities[slot];
2281                 if (WEP_CVAR(vortex, charge_rot_rate) && this.(weaponentity).vortex_charge > WEP_CVAR(vortex, charge_limit) && this.(weaponentity).vortex_charge_rottime < time)
2282                         this.(weaponentity).vortex_charge = bound(WEP_CVAR(vortex, charge_limit), this.(weaponentity).vortex_charge - WEP_CVAR(vortex, charge_rot_rate) * frametime / W_TICSPERFRAME, 1);
2283         }
2284
2285         if (frametime) player_anim(this);
2286
2287         // secret status
2288         secrets_setstatus(this);
2289
2290         // monsters status
2291         monsters_setstatus(this);
2292
2293         this.dmg_team = max(0, this.dmg_team - autocvar_g_teamdamage_resetspeed * frametime);
2294
2295         return true;
2296 }
2297
2298 void ObserverThink(entity this)
2299 {
2300         if ( CS(this).impulse )
2301         {
2302                 MinigameImpulse(this, CS(this).impulse);
2303                 CS(this).impulse = 0;
2304         }
2305
2306         if (this.flags & FL_JUMPRELEASED) {
2307                 if (PHYS_INPUT_BUTTON_JUMP(this) && joinAllowed(this)) {
2308                         this.flags &= ~FL_JUMPRELEASED;
2309                         this.flags |= FL_SPAWNING;
2310                 } else if(PHYS_INPUT_BUTTON_ATCK(this) && !CS(this).version_mismatch) {
2311                         this.flags &= ~FL_JUMPRELEASED;
2312                         if(SpectateNext(this)) {
2313                                 TRANSMUTE(Spectator, this);
2314                         }
2315                 } else {
2316                         int preferred_movetype = ((!PHYS_INPUT_BUTTON_USE(this) ? CS(this).cvar_cl_clippedspectating : !CS(this).cvar_cl_clippedspectating) ? MOVETYPE_FLY_WORLDONLY : MOVETYPE_NOCLIP);
2317                         set_movetype(this, preferred_movetype);
2318                 }
2319         } else {
2320                 if (!(PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_JUMP(this))) {
2321                         this.flags |= FL_JUMPRELEASED;
2322                         if(this.flags & FL_SPAWNING)
2323                         {
2324                                 this.flags &= ~FL_SPAWNING;
2325                                 Join(this);
2326                                 return;
2327                         }
2328                 }
2329         }
2330 }
2331
2332 void SpectatorThink(entity this)
2333 {
2334         if ( CS(this).impulse )
2335         {
2336                 if(MinigameImpulse(this, CS(this).impulse))
2337                         CS(this).impulse = 0;
2338
2339                 if (CS(this).impulse == IMP_weapon_drop.impulse)
2340                 {
2341                         STAT(CAMERA_SPECTATOR, this) = (STAT(CAMERA_SPECTATOR, this) + 1) % 3;
2342                         CS(this).impulse = 0;
2343                         return;
2344                 }
2345         }
2346
2347         if (this.flags & FL_JUMPRELEASED) {
2348                 if (PHYS_INPUT_BUTTON_JUMP(this) && joinAllowed(this)) {
2349                         this.flags &= ~FL_JUMPRELEASED;
2350                         this.flags |= FL_SPAWNING;
2351                 } else if(PHYS_INPUT_BUTTON_ATCK(this) || CS(this).impulse == 10 || CS(this).impulse == 15 || CS(this).impulse == 18 || (CS(this).impulse >= 200 && CS(this).impulse <= 209)) {
2352                         this.flags &= ~FL_JUMPRELEASED;
2353                         if(SpectateNext(this)) {
2354                                 TRANSMUTE(Spectator, this);
2355                         } else {
2356                                 TRANSMUTE(Observer, this);
2357                                 PutClientInServer(this);
2358                         }
2359                         CS(this).impulse = 0;
2360                 } else if(CS(this).impulse == 12 || CS(this).impulse == 16  || CS(this).impulse == 19 || (CS(this).impulse >= 220 && CS(this).impulse <= 229)) {
2361                         this.flags &= ~FL_JUMPRELEASED;
2362                         if(SpectatePrev(this)) {
2363                                 TRANSMUTE(Spectator, this);
2364                         } else {
2365                                 TRANSMUTE(Observer, this);
2366                                 PutClientInServer(this);
2367                         }
2368                         CS(this).impulse = 0;
2369                 } else if (PHYS_INPUT_BUTTON_ATCK2(this)) {
2370                         this.flags &= ~FL_JUMPRELEASED;
2371                         TRANSMUTE(Observer, this);
2372                         PutClientInServer(this);
2373                 } else {
2374                         if(!SpectateUpdate(this))
2375                                 PutObserverInServer(this);
2376                 }
2377         } else {
2378                 if (!(PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_ATCK2(this))) {
2379                         this.flags |= FL_JUMPRELEASED;
2380                         if(this.flags & FL_SPAWNING)
2381                         {
2382                                 this.flags &= ~FL_SPAWNING;
2383                                 Join(this);
2384                                 return;
2385                         }
2386                 }
2387                 if(!SpectateUpdate(this))
2388                         PutObserverInServer(this);
2389         }
2390
2391         this.flags |= FL_CLIENT | FL_NOTARGET;
2392 }
2393
2394 void vehicles_enter (entity pl, entity veh);
2395 void PlayerUseKey(entity this)
2396 {
2397         if (!IS_PLAYER(this))
2398                 return;
2399
2400         if(this.vehicle)
2401         {
2402                 if(!game_stopped)
2403                 {
2404                         vehicles_exit(this.vehicle, VHEF_NORMAL);
2405                         return;
2406                 }
2407         }
2408         else if(autocvar_g_vehicles_enter)
2409         {
2410                 if(!STAT(FROZEN, this))
2411                 if(!IS_DEAD(this))
2412                 if(!game_stopped)
2413                 {
2414                         entity head, closest_target = NULL;
2415                         head = WarpZone_FindRadius(this.origin, autocvar_g_vehicles_enter_radius, true);
2416
2417                         while(head) // find the closest acceptable target to enter
2418                         {
2419                                 if(IS_VEHICLE(head))
2420                                 if(!IS_DEAD(head))
2421                                 if(!head.owner || ((head.vehicle_flags & VHF_MULTISLOT) && SAME_TEAM(head.owner, this)))
2422                                 if(head.takedamage != DAMAGE_NO)
2423                                 {
2424                                         if(closest_target)
2425                                         {
2426                                                 if(vlen2(this.origin - head.origin) < vlen2(this.origin - closest_target.origin))
2427                                                 { closest_target = head; }
2428                                         }
2429                                         else { closest_target = head; }
2430                                 }
2431
2432                                 head = head.chain;
2433                         }
2434
2435                         if(closest_target) { vehicles_enter(this, closest_target); return; }
2436                 }
2437         }
2438
2439         // a use key was pressed; call handlers
2440         MUTATOR_CALLHOOK(PlayerUseKey, this);
2441 }
2442
2443
2444 /*
2445 =============
2446 PlayerPreThink
2447
2448 Called every frame for each client before the physics are run
2449 =============
2450 */
2451 .float last_vehiclecheck;
2452 void PlayerPreThink (entity this)
2453 {
2454         STAT(GUNALIGN, this) = CS(this).cvar_cl_gunalign; // TODO
2455         STAT(MOVEVARS_CL_TRACK_CANJUMP, this) = CS(this).cvar_cl_movement_track_canjump;
2456
2457         WarpZone_PlayerPhysics_FixVAngle(this);
2458
2459         if (frametime) {
2460                 // physics frames: update anticheat stuff
2461                 anticheat_prethink(this);
2462         }
2463
2464         if (blockSpectators && frametime) {
2465                 // WORKAROUND: only use dropclient in server frames (frametime set).
2466                 // Never use it in cl_movement frames (frametime zero).
2467                 checkSpectatorBlock(this);
2468         }
2469
2470         zoomstate_set = false;
2471
2472         // Check for nameless players
2473         if (this.netname == "" || this.netname != CS(this).netname_previous)
2474         {
2475                 bool assume_unchanged = (CS(this).netname_previous == "");
2476                 if (isInvisibleString(this.netname))
2477                 {
2478                         this.netname = strzone(sprintf("Player#%d", this.playerid));
2479                         assume_unchanged = false;
2480                         // stuffcmd(this, strcat("name ", this.netname, "\n")); // maybe?
2481                 }
2482                 if (!assume_unchanged && autocvar_sv_eventlog)
2483                         GameLogEcho(strcat(":name:", ftos(this.playerid), ":", playername(this, false)));
2484                 if (CS(this).netname_previous) strunzone(CS(this).netname_previous);
2485                 CS(this).netname_previous = strzone(this.netname);
2486         }
2487
2488         // version nagging
2489         if (CS(this).version_nagtime && CS(this).cvar_g_xonoticversion && time > CS(this).version_nagtime) {
2490         CS(this).version_nagtime = 0;
2491         if (strstrofs(CS(this).cvar_g_xonoticversion, "git", 0) >= 0 || strstrofs(CS(this).cvar_g_xonoticversion, "autobuild", 0) >= 0) {
2492             // git client
2493         } else if (strstrofs(autocvar_g_xonoticversion, "git", 0) >= 0 || strstrofs(autocvar_g_xonoticversion, "autobuild", 0) >= 0) {
2494             // git server
2495             Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_BETA, autocvar_g_xonoticversion, CS(this).cvar_g_xonoticversion);
2496         } else {
2497             int r = vercmp(CS(this).cvar_g_xonoticversion, autocvar_g_xonoticversion);
2498             if (r < 0) { // old client
2499                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_OUTDATED, autocvar_g_xonoticversion, CS(this).cvar_g_xonoticversion);
2500             } else if (r > 0) { // old server
2501                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_OLD, autocvar_g_xonoticversion, CS(this).cvar_g_xonoticversion);
2502             }
2503         }
2504     }
2505
2506         // GOD MODE info
2507         if (!(this.flags & FL_GODMODE) && this.max_armorvalue)
2508         {
2509                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_GODMODE_OFF, this.max_armorvalue);
2510                 this.max_armorvalue = 0;
2511         }
2512
2513         if(IS_PLAYER(this))
2514         {
2515                 if (STAT(FROZEN, this) == 2)
2516                 {
2517                         STAT(REVIVE_PROGRESS, this) = bound(0, STAT(REVIVE_PROGRESS, this) + frametime * this.revive_speed, 1);
2518                         this.health = max(1, STAT(REVIVE_PROGRESS, this) * start_health);
2519                         this.iceblock.alpha = bound(0.2, 1 - STAT(REVIVE_PROGRESS, this), 1);
2520
2521                         if (STAT(REVIVE_PROGRESS, this) >= 1)
2522                                 Unfreeze(this);
2523                 }
2524                 else if (STAT(FROZEN, this) == 3)
2525                 {
2526                         STAT(REVIVE_PROGRESS, this) = bound(0, STAT(REVIVE_PROGRESS, this) - frametime * this.revive_speed, 1);
2527                         this.health = max(0, autocvar_g_nades_ice_health + (start_health-autocvar_g_nades_ice_health) * STAT(REVIVE_PROGRESS, this) );
2528
2529                         if (this.health < 1)
2530                         {
2531                                 if (this.vehicle)
2532                                         vehicles_exit(this.vehicle, VHEF_RELEASE);
2533                                 if(this.event_damage)
2534                                         this.event_damage(this, this, this.frozen_by, 1, DEATH_NADE_ICE_FREEZE.m_id, DMG_NOWEP, this.origin, '0 0 0');
2535                         }
2536                         else if (STAT(REVIVE_PROGRESS, this) <= 0)
2537                                 Unfreeze(this);
2538                 }
2539         }
2540
2541         MUTATOR_CALLHOOK(PlayerPreThink, this);
2542
2543         if(autocvar_g_vehicles_enter && (time > this.last_vehiclecheck) && !game_stopped && !this.vehicle)
2544         if(IS_PLAYER(this) && !STAT(FROZEN, this) && !IS_DEAD(this))
2545         {
2546                 FOREACH_ENTITY_RADIUS(this.origin, autocvar_g_vehicles_enter_radius, IS_VEHICLE(it),
2547                 {
2548                         if(!IS_DEAD(it) && it.takedamage != DAMAGE_NO)
2549                         if((it.vehicle_flags & VHF_MULTISLOT) && SAME_TEAM(it.owner, this))
2550                         {
2551                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER_GUNNER);
2552                         }
2553                         else if(!it.owner)
2554                         {
2555                                 if(!it.team || SAME_TEAM(this, it))
2556                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER);
2557                                 else if(autocvar_g_vehicles_steal)
2558                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER_STEAL);
2559                         }
2560                 });
2561
2562                 this.last_vehiclecheck = time + 1;
2563         }
2564
2565         if(!CS(this).cvar_cl_newusekeysupported) // FIXME remove this - it was a stupid idea to begin with, we can JUST use the button
2566         {
2567                 if(PHYS_INPUT_BUTTON_USE(this) && !CS(this).usekeypressed)
2568                         PlayerUseKey(this);
2569                 CS(this).usekeypressed = PHYS_INPUT_BUTTON_USE(this);
2570         }
2571
2572         if (IS_REAL_CLIENT(this))
2573                 PrintWelcomeMessage(this);
2574
2575         if (IS_PLAYER(this)) {
2576                 if(!PlayerThink(this))
2577                         return;
2578         }
2579         else if (game_stopped || intermission_running) {
2580                 if(intermission_running)
2581                         IntermissionThink(this);
2582                 return;
2583         }
2584         else if (IS_OBSERVER(this)) {
2585                 ObserverThink(this);
2586         }
2587         else if (IS_SPEC(this)) {
2588                 SpectatorThink(this);
2589         }
2590
2591         // WEAPONTODO: Add weapon request for this
2592         if (!zoomstate_set) {
2593                 bool wep_zoomed = false;
2594                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2595                 {
2596                         .entity weaponentity = weaponentities[slot];
2597                         Weapon thiswep = this.(weaponentity).m_weapon;
2598                         if(thiswep != WEP_Null && thiswep.wr_zoom)
2599                                 wep_zoomed += thiswep.wr_zoom(thiswep, this);
2600                 }
2601                 SetZoomState(this, PHYS_INPUT_BUTTON_ZOOM(this) || PHYS_INPUT_BUTTON_ZOOMSCRIPT(this) || wep_zoomed);
2602     }
2603
2604         if (CS(this).teamkill_soundtime && time > CS(this).teamkill_soundtime)
2605         {
2606                 CS(this).teamkill_soundtime = 0;
2607
2608                 entity e = CS(this).teamkill_soundsource;
2609                 entity oldpusher = e.pusher;
2610                 e.pusher = this;
2611                 PlayerSound(e, playersound_teamshoot, CH_VOICE, VOL_BASEVOICE, VOICETYPE_LASTATTACKER_ONLY);
2612                 e.pusher = oldpusher;
2613         }
2614
2615         if (CS(this).taunt_soundtime && time > CS(this).taunt_soundtime) {
2616                 CS(this).taunt_soundtime = 0;
2617                 PlayerSound(this, playersound_taunt, CH_VOICE, VOL_BASEVOICE, VOICETYPE_AUTOTAUNT);
2618         }
2619
2620         target_voicescript_next(this);
2621
2622         // WEAPONTODO: Move into weaponsystem somehow
2623         // if a player goes unarmed after holding a loaded weapon, empty his clip size and remove the crosshair ammo ring
2624         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2625         {
2626                 .entity weaponentity = weaponentities[slot];
2627                 if(this.(weaponentity).m_weapon == WEP_Null)
2628                         this.(weaponentity).clip_load = this.(weaponentity).clip_size = 0;
2629         }
2630 }
2631
2632 void DrownPlayer(entity this)
2633 {
2634         if(IS_DEAD(this) || game_stopped || time < game_starttime)
2635                 return;
2636
2637         if (this.waterlevel != WATERLEVEL_SUBMERGED || this.vehicle)
2638         {
2639                 if(this.air_finished < time)
2640                         PlayerSound(this, playersound_gasp, CH_PLAYER, VOL_BASE, VOICETYPE_PLAYERSOUND);
2641                 this.air_finished = time + autocvar_g_balance_contents_drowndelay;
2642         }
2643         else if (this.air_finished < time)
2644         {       // drown!
2645                 if (this.pain_finished < time)
2646                 {
2647                         Damage (this, NULL, NULL, autocvar_g_balance_contents_playerdamage_drowning * autocvar_g_balance_contents_damagerate, DEATH_DROWN.m_id, DMG_NOWEP, this.origin, '0 0 0');
2648                         this.pain_finished = time + 0.5;
2649                 }
2650         }
2651 }
2652
2653 .bool move_qcphysics;
2654
2655 void Player_Physics(entity this)
2656 {
2657         set_movetype(this, this.move_movetype);
2658
2659         if(!this.move_qcphysics)
2660                 return;
2661
2662         if(!frametime && !CS(this).pm_frametime)
2663                 return;
2664
2665         Movetype_Physics_NoMatchTicrate(this, CS(this).pm_frametime, true);
2666
2667         CS(this).pm_frametime = 0;
2668 }
2669
2670 /*
2671 =============
2672 PlayerPostThink
2673
2674 Called every frame for each client after the physics are run
2675 =============
2676 */
2677 void PlayerPostThink (entity this)
2678 {
2679         Player_Physics(this);
2680
2681         if (sv_maxidle > 0)
2682         if (frametime) // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2683         if (IS_REAL_CLIENT(this))
2684         if (IS_PLAYER(this) || sv_maxidle_spectatorsareidle)
2685         {
2686                 int totalClients = 0;
2687                 if(sv_maxidle_slots > 0)
2688                 {
2689                         FOREACH_CLIENT(IS_REAL_CLIENT(it) || sv_maxidle_slots_countbots,
2690                         {
2691                                 ++totalClients;
2692                         });
2693                 }
2694
2695                 if (sv_maxidle_slots > 0 && (maxclients - totalClients) > sv_maxidle_slots)
2696                 { /* do nothing */ }
2697                 else if (time - CS(this).parm_idlesince < 1) // instead of (time == this.parm_idlesince) to support sv_maxidle <= 10
2698                 {
2699                         if (CS(this).idlekick_lasttimeleft)
2700                         {
2701                                 CS(this).idlekick_lasttimeleft = 0;
2702                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_IDLING);
2703                         }
2704                 }
2705                 else
2706                 {
2707                         float timeleft = ceil(sv_maxidle - (time - CS(this).parm_idlesince));
2708                         if (timeleft == min(10, sv_maxidle - 1)) { // - 1 to support sv_maxidle <= 10
2709                                 if (!CS(this).idlekick_lasttimeleft)
2710                                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_DISCONNECT_IDLING, timeleft);
2711                         }
2712                         if (timeleft <= 0) {
2713                                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_QUIT_KICK_IDLING, this.netname);
2714                                 dropclient(this);
2715                                 return;
2716                         }
2717                         else if (timeleft <= 10) {
2718                                 if (timeleft != CS(this).idlekick_lasttimeleft) {
2719                                     Send_Notification(NOTIF_ONE, this, MSG_ANNCE, Announcer_PickNumber(CNT_IDLE, timeleft));
2720                 }
2721                                 CS(this).idlekick_lasttimeleft = timeleft;
2722                         }
2723                 }
2724         }
2725
2726         CheatFrame(this);
2727
2728         if (game_stopped)
2729         {
2730                 this.solid = SOLID_NOT;
2731                 this.takedamage = DAMAGE_NO;
2732                 set_movetype(this, MOVETYPE_NONE);
2733         }
2734
2735         if (IS_PLAYER(this)) {
2736                 if(this.death_time == time && IS_DEAD(this))
2737                 {
2738                         // player's bbox gets resized now, instead of in the damage event that killed the player,
2739                         // once all the damage events of this frame have been processed with normal size
2740                         this.maxs.z = 5;
2741                         setsize(this, this.mins, this.maxs);
2742                 }
2743                 DrownPlayer(this);
2744                 UpdateChatBubble(this);
2745                 if (CS(this).impulse) ImpulseCommands(this);
2746                 if (game_stopped)
2747                 {
2748                         CSQCMODEL_AUTOUPDATE(this);
2749                         return;
2750                 }
2751                 GetPressedKeys(this);
2752         }
2753
2754         if (this.waypointsprite_attachedforcarrier) {
2755             vector v = healtharmor_maxdamage(this.health, this.armorvalue, autocvar_g_balance_armor_blockpercent, DEATH_WEAPON.m_id);
2756                 WaypointSprite_UpdateHealth(this.waypointsprite_attachedforcarrier, '1 0 0' * v);
2757     }
2758
2759         playerdemo_write(this);
2760
2761         CSQCMODEL_AUTOUPDATE(this);
2762 }
2763
2764 // hack to copy the button fields from the client entity to the Client State
2765 void PM_UpdateButtons(entity this, entity store)
2766 {
2767         if(this.impulse)
2768                 store.impulse = this.impulse;
2769         this.impulse = 0;
2770
2771         bool typing = this.buttonchat;
2772
2773         store.button0 = (typing) ? 0 : this.button0;
2774         //button1?!
2775         store.button2 = (typing) ? 0 : this.button2;
2776         store.button3 = (typing) ? 0 : this.button3;
2777         store.button4 = this.button4;
2778         store.button5 = (typing) ? 0 : this.button5;
2779         store.button6 = this.button6;
2780         store.button7 = this.button7;
2781         store.button8 = this.button8;
2782         store.button9 = this.button9;
2783         store.button10 = this.button10;
2784         store.button11 = this.button11;
2785         store.button12 = this.button12;
2786         store.button13 = this.button13;
2787         store.button14 = this.button14;
2788         store.button15 = this.button15;
2789         store.button16 = this.button16;
2790         store.buttonuse = this.buttonuse;
2791         store.buttonchat = this.buttonchat;
2792
2793         store.cursor_active = this.cursor_active;
2794         store.cursor_screen = this.cursor_screen;
2795         store.cursor_trace_start = this.cursor_trace_start;
2796         store.cursor_trace_endpos = this.cursor_trace_endpos;
2797         store.cursor_trace_ent = this.cursor_trace_ent;
2798
2799         store.ping = this.ping;
2800         store.ping_packetloss = this.ping_packetloss;
2801         store.ping_movementloss = this.ping_movementloss;
2802
2803         store.v_angle = this.v_angle;
2804         store.movement = (typing) ? '0 0 0' : this.movement;
2805 }
2806
2807 NET_HANDLE(fpsreport, bool)
2808 {
2809         int fps = ReadShort();
2810         PlayerScore_Set(sender, SP_FPS, fps);
2811         return true;
2812 }