Allow deactivating trigger_relay_if, trigger_relay_teamcheck and trigger_disablerelay...
[xonotic/xonotic-data.pk3dir.git] / qcsrc / server / client.qc
1 #include "client.qh"
2
3 #include <server/defs.qh>
4 #include <server/miscfunctions.qh>
5 #include <common/effects/all.qh>
6 #include "anticheat.qh"
7 #include "impulse.qh"
8 #include "player.qh"
9 #include "ipban.qh"
10 #include "miscfunctions.qh"
11 #include "portals.qh"
12 #include "teamplay.qh"
13 #include "spawnpoints.qh"
14 #include "resources.qh"
15 #include "g_damage.qh"
16 #include "handicap.qh"
17 #include "g_hook.qh"
18 #include "command/common.qh"
19 #include "command/vote.qh"
20 #include "clientkill.qh"
21 #include "cheats.qh"
22 #include "g_world.qh"
23 #include "race.qh"
24 #include "antilag.qh"
25 #include "campaign.qh"
26 #include "command/common.qh"
27 #include "scores_rules.qh"
28 #include "weapons/common.qh"
29
30 #include "bot/api.qh"
31
32 #include "../common/ent_cs.qh"
33 #include "../common/wepent.qh"
34 #include <common/state.qh>
35
36 #include "compat/quake3.qh"
37
38 #include <common/effects/qc/globalsound.qh>
39
40 #include "../common/mapobjects/func/conveyor.qh"
41 #include "../common/mapobjects/teleporters.qh"
42 #include "../common/mapobjects/target/spawnpoint.qh"
43 #include <common/mapobjects/trigger/counter.qh>
44 #include <common/mapobjects/trigger/swamp.qh>
45
46 #include "../common/vehicles/all.qh"
47
48 #include "weapons/hitplot.qh"
49 #include "weapons/weaponsystem.qh"
50
51 #include "../common/net_notice.qh"
52 #include "../common/net_linked.qh"
53 #include "../common/physics/player.qh"
54
55 #include <common/vehicles/sv_vehicles.qh>
56
57 #include "../common/items/_mod.qh"
58
59 #include "../common/mutators/mutator/waypoints/all.qh"
60 #include "../common/mutators/mutator/instagib/sv_instagib.qh"
61 #include <common/gamemodes/_mod.qh>
62
63 #include "../common/mapobjects/subs.qh"
64 #include "../common/mapobjects/triggers.qh"
65 #include "../common/mapobjects/trigger/secret.qh"
66
67 #include "../common/minigames/sv_minigames.qh"
68
69 #include "../common/items/inventory.qh"
70
71 #include "../common/monsters/sv_monsters.qh"
72
73 #include "../lib/warpzone/server.qh"
74
75 #include <common/mutators/mutator/overkill/oknex.qh>
76
77 STATIC_METHOD(Client, Add, void(Client this, int _team))
78 {
79     ClientConnect(this);
80     TRANSMUTE(Player, this);
81     this.frame = 12; // 7
82     this.team = _team;
83     PutClientInServer(this);
84 }
85
86 STATIC_METHOD(Client, Remove, void(Client this))
87 {
88     TRANSMUTE(Observer, this);
89     PutClientInServer(this);
90     ClientDisconnect(this);
91 }
92
93 void send_CSQC_teamnagger() {
94         WriteHeader(MSG_BROADCAST, TE_CSQC_TEAMNAGGER);
95 }
96
97 int CountSpectators(entity player, entity to)
98 {
99         if(!player) { return 0; } // not sure how, but best to be safe
100
101         int spec_count = 0;
102
103         FOREACH_CLIENT(IS_REAL_CLIENT(it) && IS_SPEC(it) && it != to && it.enemy == player,
104         {
105                 spec_count++;
106         });
107
108         return spec_count;
109 }
110
111 void WriteSpectators(entity player, entity to)
112 {
113         if(!player) { return; } // not sure how, but best to be safe
114
115         FOREACH_CLIENT(IS_REAL_CLIENT(it) && IS_SPEC(it) && it != to && it.enemy == player,
116         {
117                 WriteByte(MSG_ENTITY, num_for_edict(it));
118         });
119 }
120
121 bool ClientData_Send(entity this, entity to, int sf)
122 {
123         assert(to == this.owner, return false);
124
125         entity e = to;
126         if (IS_SPEC(e)) e = e.enemy;
127
128         sf = 0;
129         if (CS(e).race_completed)       sf |= BIT(0); // forced scoreboard
130         if (CS(to).spectatee_status)    sf |= BIT(1); // spectator ent number follows
131         if (CS(e).zoomstate)            sf |= BIT(2); // zoomed
132         if (autocvar_sv_showspectators) sf |= BIT(4); // show spectators
133
134         WriteHeader(MSG_ENTITY, ENT_CLIENT_CLIENTDATA);
135         WriteByte(MSG_ENTITY, sf);
136
137         if (sf & BIT(1))
138                 WriteByte(MSG_ENTITY, CS(to).spectatee_status);
139
140         if(sf & BIT(4))
141         {
142                 float specs = CountSpectators(e, to);
143                 WriteByte(MSG_ENTITY, specs);
144                 WriteSpectators(e, to);
145         }
146
147         return true;
148 }
149
150 void ClientData_Attach(entity this)
151 {
152         Net_LinkEntity(CS(this).clientdata = new_pure(clientdata), false, 0, ClientData_Send);
153         CS(this).clientdata.drawonlytoclient = this;
154         CS(this).clientdata.owner = this;
155 }
156
157 void ClientData_Detach(entity this)
158 {
159         delete(CS(this).clientdata);
160         CS(this).clientdata = NULL;
161 }
162
163 void ClientData_Touch(entity e)
164 {
165         entity cd = CS(e).clientdata;
166         if (cd) { cd.SendFlags = 1; }
167
168         // make it spectatable
169         FOREACH_CLIENT(IS_REAL_CLIENT(it) && it != e && IS_SPEC(it) && it.enemy == e,
170         {
171                 entity cd = CS(it).clientdata;
172                 if (cd) { cd.SendFlags = 1; }
173         });
174 }
175
176
177 /*
178 =============
179 CheckPlayerModel
180
181 Checks if the argument string can be a valid playermodel.
182 Returns a valid one in doubt.
183 =============
184 */
185 string FallbackPlayerModel;
186 string CheckPlayerModel(string plyermodel) {
187         if(FallbackPlayerModel != cvar_defstring("_cl_playermodel"))
188         {
189                 // note: we cannot summon Don Strunzone here, some player may
190                 // still have the model string set. In case anyone manages how
191                 // to change a cvar default, we'll have a small leak here.
192                 FallbackPlayerModel = strzone(cvar_defstring("_cl_playermodel"));
193         }
194         // only in right path
195         if( substring(plyermodel,0,14) != "models/player/")
196                 return FallbackPlayerModel;
197         // only good file extensions
198         if(substring(plyermodel,-4,4) != ".zym")
199         if(substring(plyermodel,-4,4) != ".dpm")
200         if(substring(plyermodel,-4,4) != ".iqm")
201         if(substring(plyermodel,-4,4) != ".md3")
202         if(substring(plyermodel,-4,4) != ".psk")
203                 return FallbackPlayerModel;
204         // forbid the LOD models
205         if(substring(plyermodel, -9,5) == "_lod1")
206                 return FallbackPlayerModel;
207         if(substring(plyermodel, -9,5) == "_lod2")
208                 return FallbackPlayerModel;
209         if(plyermodel != strtolower(plyermodel))
210                 return FallbackPlayerModel;
211         // also, restrict to server models
212         if(autocvar_sv_servermodelsonly)
213         {
214                 if(!fexists(plyermodel))
215                         return FallbackPlayerModel;
216         }
217         return plyermodel;
218 }
219
220 void setplayermodel(entity e, string modelname)
221 {
222         precache_model(modelname);
223         _setmodel(e, modelname);
224         player_setupanimsformodel(e);
225         if(!autocvar_g_debug_globalsounds)
226                 UpdatePlayerSounds(e);
227 }
228
229 /** putting a client as observer in the server */
230 void PutObserverInServer(entity this)
231 {
232     bool mutator_returnvalue = MUTATOR_CALLHOOK(MakePlayerObserver, this);
233         PlayerState_detach(this);
234
235         if (IS_PLAYER(this))
236         {
237                 if(GetResource(this, RES_HEALTH) >= 1)
238                 {
239                         // despawn effect
240                         Send_Effect(EFFECT_SPAWN_NEUTRAL, this.origin, '0 0 0', 1);
241                 }
242
243                 // was a player, recount votes and ready status
244                 if(IS_REAL_CLIENT(this))
245                 {
246                         if (vote_called) { VoteCount(false); }
247                         ReadyCount();
248                 }
249     }
250
251     {
252         entity spot = SelectSpawnPoint(this, true);
253         if (!spot) LOG_FATAL("No spawnpoints for observers?!?");
254         this.angles = vec2(spot.angles);
255         this.fixangle = true;
256         // offset it so that the spectator spawns higher off the ground, looks better this way
257         setorigin(this, spot.origin + STAT(PL_VIEW_OFS, this));
258         if (IS_REAL_CLIENT(this))
259         {
260             msg_entity = this;
261             WriteByte(MSG_ONE, SVC_SETVIEW);
262             WriteEntity(MSG_ONE, this);
263         }
264         // give the spectator some space between walls for MOVETYPE_FLY_WORLDONLY
265         // so that your view doesn't go into the ceiling with MOVETYPE_FLY_WORLDONLY, previously "PL_VIEW_OFS"
266         if(!autocvar_g_debug_globalsounds)
267         {
268                 // needed for player sounds
269                 this.model = "";
270                 FixPlayermodel(this);
271         }
272         setmodel(this, MDL_Null);
273         setsize(this, STAT(PL_CROUCH_MIN, this), STAT(PL_CROUCH_MAX, this));
274         this.view_ofs = '0 0 0';
275     }
276
277     RemoveGrapplingHooks(this);
278         Portal_ClearAll(this);
279         Unfreeze(this, false);
280         SetSpectatee(this, NULL);
281
282         if (this.alivetime)
283         {
284                 if (!warmup_stage)
285                         PlayerStats_GameReport_Event_Player(this, PLAYERSTATS_ALIVETIME, time - this.alivetime);
286                 this.alivetime = 0;
287         }
288
289         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
290
291         WaypointSprite_PlayerDead(this);
292
293         if (CS(this).killcount != FRAGS_SPECTATOR)
294         {
295                 if(!game_stopped)
296                 if(autocvar_g_chat_nospectators == 1 || (!warmup_stage && autocvar_g_chat_nospectators == 2))
297                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_CHAT_NOSPECTATORS);
298         }
299
300         accuracy_resend(this);
301
302         CS(this).spectatortime = time;
303         if(this.bot_attack)
304                 IL_REMOVE(g_bot_targets, this);
305         this.bot_attack = false;
306         if(this.monster_attack)
307                 IL_REMOVE(g_monster_targets, this);
308         this.monster_attack = false;
309     STAT(HUD, this) = HUD_NORMAL;
310         TRANSMUTE(Observer, this);
311         this.iscreature = false;
312         this.teleportable = TELEPORT_SIMPLE;
313         if(this.damagedbycontents)
314                 IL_REMOVE(g_damagedbycontents, this);
315         this.damagedbycontents = false;
316         SetResourceExplicit(this, RES_HEALTH, FRAGS_SPECTATOR);
317         SetSpectatee_status(this, etof(this));
318         this.takedamage = DAMAGE_NO;
319         this.solid = SOLID_NOT;
320         set_movetype(this, MOVETYPE_FLY_WORLDONLY); // user preference is controlled by playerprethink
321         this.flags = FL_CLIENT | FL_NOTARGET;
322         this.effects = 0;
323         SetResourceExplicit(this, RES_ARMOR, autocvar_g_balance_armor_start); // was 666?!
324         this.pauserotarmor_finished = 0;
325         this.pauserothealth_finished = 0;
326         this.pauseregen_finished = 0;
327         this.damageforcescale = 0;
328         this.death_time = 0;
329         this.respawn_flags = 0;
330         this.respawn_time = 0;
331         STAT(RESPAWN_TIME, this) = 0;
332         this.alpha = 0;
333         this.scale = 0;
334         this.fade_time = 0;
335         this.pain_frame = 0;
336         this.pain_finished = 0;
337         STAT(STRENGTH_FINISHED, this) = 0;
338         STAT(INVINCIBLE_FINISHED, this) = 0;
339         STAT(SUPERWEAPONS_FINISHED, this) = 0;
340         this.air_finished = 0;
341         //this.dphitcontentsmask = 0;
342         this.dphitcontentsmask = DPCONTENTS_SOLID;
343         if (autocvar_g_playerclip_collisions)
344                 this.dphitcontentsmask |= DPCONTENTS_PLAYERCLIP;
345         this.pushltime = 0;
346         this.istypefrag = 0;
347         setthink(this, func_null);
348         this.nextthink = 0;
349         this.deadflag = DEAD_NO;
350         this.crouch = false;
351         STAT(REVIVE_PROGRESS, this) = 0;
352         this.revival_time = 0;
353         this.draggable = drag_undraggable;
354
355         this.items = 0;
356         STAT(WEAPONS, this) = '0 0 0';
357         this.drawonlytoclient = this;
358
359         this.viewloc = NULL;
360
361         //this.spawnpoint_targ = NULL; // keep it so they can return to where they were?
362
363         this.weaponmodel = "";
364         for (int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
365         {
366                 this.weaponentities[slot] = NULL;
367         }
368         this.exteriorweaponentity = NULL;
369         CS(this).killcount = FRAGS_SPECTATOR;
370         this.velocity = '0 0 0';
371         this.avelocity = '0 0 0';
372         this.punchangle = '0 0 0';
373         this.punchvector = '0 0 0';
374         this.oldvelocity = this.velocity;
375         this.fire_endtime = -1;
376         this.event_damage = func_null;
377         this.event_heal = func_null;
378
379         for(int slot = 0; slot < MAX_AXH; ++slot)
380         {
381                 entity axh = this.(AuxiliaryXhair[slot]);
382                 this.(AuxiliaryXhair[slot]) = NULL;
383
384                 if(axh.owner == this && axh != NULL && !wasfreed(axh))
385                         delete(axh);
386         }
387
388         if (mutator_returnvalue)
389         {
390                 // mutator prevents resetting teams+score
391         }
392         else
393         {
394                 SetPlayerTeam(this, -1, TEAM_CHANGE_SPECTATOR);
395                 this.frags = FRAGS_SPECTATOR;
396         }
397         if (CS(this).just_joined)
398                 CS(this).just_joined = false;
399 }
400
401 int player_getspecies(entity this)
402 {
403         get_model_parameters(this.model, this.skin);
404         int s = get_model_parameters_species;
405         get_model_parameters(string_null, 0);
406         if (s < 0) return SPECIES_HUMAN;
407         return s;
408 }
409
410 .float model_randomizer;
411 void FixPlayermodel(entity player)
412 {
413         string defaultmodel = "";
414         int defaultskin = 0;
415         if(autocvar_sv_defaultcharacter)
416         {
417                 if(teamplay)
418                 {
419                         switch(player.team)
420                         {
421                                 case NUM_TEAM_1: defaultmodel = autocvar_sv_defaultplayermodel_red; defaultskin = autocvar_sv_defaultplayerskin_red; break;
422                                 case NUM_TEAM_2: defaultmodel = autocvar_sv_defaultplayermodel_blue; defaultskin = autocvar_sv_defaultplayerskin_blue; break;
423                                 case NUM_TEAM_3: defaultmodel = autocvar_sv_defaultplayermodel_yellow; defaultskin = autocvar_sv_defaultplayerskin_yellow; break;
424                                 case NUM_TEAM_4: defaultmodel = autocvar_sv_defaultplayermodel_pink; defaultskin = autocvar_sv_defaultplayerskin_pink; break;
425                         }
426                 }
427
428                 if(defaultmodel == "")
429                 {
430                         defaultmodel = autocvar_sv_defaultplayermodel;
431                         defaultskin = autocvar_sv_defaultplayerskin;
432                 }
433
434                 int n = tokenize_console(defaultmodel);
435                 if(n > 0)
436                 {
437                         defaultmodel = argv(floor(n * CS(player).model_randomizer));
438                         // However, do NOT randomize if the player-selected model is in the list.
439                         for (int i = 0; i < n; ++i)
440                                 if ((argv(i) == player.playermodel && defaultskin == stof(player.playerskin)) || argv(i) == strcat(player.playermodel, ":", player.playerskin))
441                                         defaultmodel = argv(i);
442                 }
443
444                 int i = strstrofs(defaultmodel, ":", 0);
445                 if(i >= 0)
446                 {
447                         defaultskin = stof(substring(defaultmodel, i+1, -1));
448                         defaultmodel = substring(defaultmodel, 0, i);
449                 }
450         }
451         if(autocvar_sv_defaultcharacterskin && !defaultskin)
452         {
453                 if(teamplay)
454                 {
455                         switch(player.team)
456                         {
457                                 case NUM_TEAM_1: defaultskin = autocvar_sv_defaultplayerskin_red; break;
458                                 case NUM_TEAM_2: defaultskin = autocvar_sv_defaultplayerskin_blue; break;
459                                 case NUM_TEAM_3: defaultskin = autocvar_sv_defaultplayerskin_yellow; break;
460                                 case NUM_TEAM_4: defaultskin = autocvar_sv_defaultplayerskin_pink; break;
461                         }
462                 }
463
464                 if(!defaultskin)
465                         defaultskin = autocvar_sv_defaultplayerskin;
466         }
467
468         MUTATOR_CALLHOOK(FixPlayermodel, defaultmodel, defaultskin, player);
469         defaultmodel = M_ARGV(0, string);
470         defaultskin = M_ARGV(1, int);
471
472         bool chmdl = false;
473         int oldskin;
474         if(defaultmodel != "")
475         {
476                 if (defaultmodel != player.model)
477                 {
478                         vector m1 = player.mins;
479                         vector m2 = player.maxs;
480                         setplayermodel (player, defaultmodel);
481                         setsize (player, m1, m2);
482                         chmdl = true;
483                 }
484
485                 oldskin = player.skin;
486                 player.skin = defaultskin;
487         } else {
488                 if (player.playermodel != player.model || player.playermodel == "")
489                 {
490                         player.playermodel = CheckPlayerModel(player.playermodel); // this is never "", so no endless loop
491                         vector m1 = player.mins;
492                         vector m2 = player.maxs;
493                         setplayermodel (player, player.playermodel);
494                         setsize (player, m1, m2);
495                         chmdl = true;
496                 }
497
498                 if(!autocvar_sv_defaultcharacterskin)
499                 {
500                         oldskin = player.skin;
501                         player.skin = stof(player.playerskin);
502                 }
503                 else
504                 {
505                         oldskin = player.skin;
506                         player.skin = defaultskin;
507                 }
508         }
509
510         if(chmdl || oldskin != player.skin) // model or skin has changed
511         {
512                 player.species = player_getspecies(player); // update species
513                 if(!autocvar_g_debug_globalsounds)
514                         UpdatePlayerSounds(player); // update skin sounds
515         }
516
517         if(!teamplay)
518                 if(strlen(autocvar_sv_defaultplayercolors))
519                         if(player.clientcolors != stof(autocvar_sv_defaultplayercolors))
520                                 setcolor(player, stof(autocvar_sv_defaultplayercolors));
521 }
522
523 void PutPlayerInServer(entity this)
524 {
525         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
526
527         PlayerState_attach(this);
528         accuracy_resend(this);
529
530         if (this.team < 0)
531                 TeamBalance_JoinBestTeam(this);
532
533         entity spot = SelectSpawnPoint(this, false);
534         if (!spot) {
535                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_JOIN_NOSPAWNS);
536                 return; // spawn failed
537         }
538
539         TRANSMUTE(Player, this);
540
541         CS(this).wasplayer = true;
542         this.iscreature = true;
543         this.teleportable = TELEPORT_NORMAL;
544         if(!this.damagedbycontents)
545                 IL_PUSH(g_damagedbycontents, this);
546         this.damagedbycontents = true;
547         set_movetype(this, MOVETYPE_WALK);
548         this.solid = SOLID_SLIDEBOX;
549         this.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_SOLID;
550         if (autocvar_g_playerclip_collisions)
551                 this.dphitcontentsmask |= DPCONTENTS_PLAYERCLIP;
552         if (IS_BOT_CLIENT(this) && autocvar_g_botclip_collisions)
553                 this.dphitcontentsmask |= DPCONTENTS_BOTCLIP;
554         this.frags = FRAGS_PLAYER;
555         if (INDEPENDENT_PLAYERS) MAKE_INDEPENDENT_PLAYER(this);
556         this.flags = FL_CLIENT | FL_PICKUPITEMS;
557         if (autocvar__notarget)
558                 this.flags |= FL_NOTARGET;
559         this.takedamage = DAMAGE_AIM;
560         this.effects = EF_TELEPORT_BIT | EF_RESTARTANIM_BIT;
561
562         if (warmup_stage) {
563                 SetResource(this, RES_SHELLS, warmup_start_ammo_shells);
564                 SetResource(this, RES_BULLETS, warmup_start_ammo_nails);
565                 SetResource(this, RES_ROCKETS, warmup_start_ammo_rockets);
566                 SetResource(this, RES_CELLS, warmup_start_ammo_cells);
567                 SetResource(this, RES_PLASMA, warmup_start_ammo_plasma);
568                 SetResource(this, RES_FUEL, warmup_start_ammo_fuel);
569                 SetResource(this, RES_HEALTH, warmup_start_health);
570                 SetResource(this, RES_ARMOR, warmup_start_armorvalue);
571                 STAT(WEAPONS, this) = WARMUP_START_WEAPONS;
572         } else {
573                 SetResource(this, RES_SHELLS, start_ammo_shells);
574                 SetResource(this, RES_BULLETS, start_ammo_nails);
575                 SetResource(this, RES_ROCKETS, start_ammo_rockets);
576                 SetResource(this, RES_CELLS, start_ammo_cells);
577                 SetResource(this, RES_PLASMA, start_ammo_plasma);
578                 SetResource(this, RES_FUEL, start_ammo_fuel);
579                 SetResource(this, RES_HEALTH, start_health);
580                 SetResource(this, RES_ARMOR, start_armorvalue);
581                 STAT(WEAPONS, this) = start_weapons;
582                 if (MUTATOR_CALLHOOK(ForbidRandomStartWeapons, this) == false)
583                 {
584                         GiveRandomWeapons(this, random_start_weapons_count,
585                                 autocvar_g_random_start_weapons, random_start_ammo);
586                 }
587         }
588         SetSpectatee_status(this, 0);
589
590         PS(this).dual_weapons = '0 0 0';
591
592         STAT(SUPERWEAPONS_FINISHED, this) = (STAT(WEAPONS, this) & WEPSET_SUPERWEAPONS) ? time + autocvar_g_balance_superweapons_time : 0;
593
594         this.items = start_items;
595
596         this.spawnshieldtime = time + autocvar_g_spawnshieldtime;
597         this.pauserotarmor_finished = time + autocvar_g_balance_pause_armor_rot_spawn;
598         this.pauserothealth_finished = time + autocvar_g_balance_pause_health_rot_spawn;
599         this.pauserotfuel_finished = time + autocvar_g_balance_pause_fuel_rot_spawn;
600         this.pauseregen_finished = time + autocvar_g_balance_pause_health_regen_spawn;
601         if (!sv_ready_restart_after_countdown && time < game_starttime)
602         {
603                 float f = game_starttime - time;
604                 this.spawnshieldtime += f;
605                 this.pauserotarmor_finished += f;
606                 this.pauserothealth_finished += f;
607                 this.pauseregen_finished += f;
608         }
609
610         this.damageforcescale = autocvar_g_player_damageforcescale;
611         this.death_time = 0;
612         this.respawn_flags = 0;
613         this.respawn_time = 0;
614         STAT(RESPAWN_TIME, this) = 0;
615         bool q3dfcompat = autocvar_sv_q3defragcompat && autocvar_sv_q3defragcompat_changehitbox;
616         this.scale = ((q3dfcompat) ? 0.9 : autocvar_sv_player_scale);
617         this.fade_time = 0;
618         this.pain_frame = 0;
619         this.pain_finished = 0;
620         this.pushltime = 0;
621         setthink(this, func_null); // players have no think function
622         this.nextthink = 0;
623         this.dmg_team = 0;
624         PS(this).ballistics_density = autocvar_g_ballistics_density_player;
625
626         this.deadflag = DEAD_NO;
627
628         this.angles = spot.angles;
629         this.angles_z = 0; // never spawn tilted even if the spot says to
630         if (IS_BOT_CLIENT(this))
631         {
632                 this.v_angle = this.angles;
633                 bot_aim_reset(this);
634         }
635         this.fixangle = true; // turn this way immediately
636         this.oldvelocity = this.velocity = '0 0 0';
637         this.avelocity = '0 0 0';
638         this.punchangle = '0 0 0';
639         this.punchvector = '0 0 0';
640
641         STAT(STRENGTH_FINISHED, this) = 0;
642         STAT(INVINCIBLE_FINISHED, this) = 0;
643         this.fire_endtime = -1;
644         STAT(REVIVE_PROGRESS, this) = 0;
645         this.revival_time = 0;
646
647         // TODO: we can't set these in the PlayerSpawn hook since the target code is called before it!
648         STAT(BUFFS, this) = 0;
649         STAT(BUFF_TIME, this) = 0;
650
651         this.air_finished = 0;
652         this.waterlevel = WATERLEVEL_NONE;
653         this.watertype = CONTENT_EMPTY;
654
655         entity spawnevent = new_pure(spawnevent);
656         spawnevent.owner = this;
657         Net_LinkEntity(spawnevent, false, 0.5, SpawnEvent_Send);
658
659         // Cut off any still running player sounds.
660         stopsound(this, CH_PLAYER_SINGLE);
661
662         this.model = "";
663         FixPlayermodel(this);
664         this.drawonlytoclient = NULL;
665
666         this.viewloc = NULL;
667
668         for(int slot = 0; slot < MAX_AXH; ++slot)
669         {
670                 entity axh = this.(AuxiliaryXhair[slot]);
671                 this.(AuxiliaryXhair[slot]) = NULL;
672
673                 if(axh.owner == this && axh != NULL && !wasfreed(axh))
674                         delete(axh);
675         }
676
677         this.spawnpoint_targ = NULL;
678
679         this.crouch = false;
680         this.view_ofs = STAT(PL_VIEW_OFS, this);
681         setsize(this, STAT(PL_MIN, this), STAT(PL_MAX, this));
682         this.spawnorigin = spot.origin;
683         setorigin(this, spot.origin + '0 0 1' * (1 - this.mins.z - 24));
684         // don't reset back to last position, even if new position is stuck in solid
685         this.oldorigin = this.origin;
686         if(this.conveyor)
687                 IL_REMOVE(g_conveyed, this);
688         this.conveyor = NULL; // prevent conveyors at the previous location from moving a freshly spawned player
689         if(this.swampslug)
690                 delete(this.swampslug);
691         this.in_swamp = false;
692         STAT(HUD, this) = HUD_NORMAL;
693
694         this.event_damage = PlayerDamage;
695         this.event_heal = PlayerHeal;
696
697         this.draggable = func_null;
698
699         if(!this.bot_attack)
700                 IL_PUSH(g_bot_targets, this);
701         this.bot_attack = true;
702         if(!this.monster_attack)
703                 IL_PUSH(g_monster_targets, this);
704         this.monster_attack = true;
705         navigation_dynamicgoal_init(this, false);
706
707         PHYS_INPUT_BUTTON_ATCK(this) = PHYS_INPUT_BUTTON_JUMP(this) = PHYS_INPUT_BUTTON_ATCK2(this) = false;
708
709         // player was spectator
710         if (CS(this).killcount == FRAGS_SPECTATOR) {
711                 PlayerScore_Clear(this);
712                 CS(this).killcount = 0;
713                 CS(this).startplaytime = time;
714         }
715
716         for (int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
717         {
718                 .entity weaponentity = weaponentities[slot];
719                 CL_SpawnWeaponentity(this, weaponentity);
720         }
721         this.alpha = default_player_alpha;
722         this.colormod = '1 1 1' * autocvar_g_player_brightness;
723         this.exteriorweaponentity.alpha = default_weapon_alpha;
724
725         this.speedrunning = false;
726
727         this.counter_cnt = 0;
728         this.fragsfilter_cnt = 0;
729
730         target_voicescript_clear(this);
731
732         // reset fields the weapons may use
733         FOREACH(Weapons, true, {
734                 it.wr_resetplayer(it, this);
735                         // reload all reloadable weapons
736                 if (it.spawnflags & WEP_FLAG_RELOADABLE) {
737                         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
738                         {
739                                 .entity weaponentity = weaponentities[slot];
740                                 this.(weaponentity).weapon_load[it.m_id] = it.reloading_ammo;
741                         }
742                 }
743         });
744
745         {
746                 string s = spot.target;
747                 if(g_assault || g_race) // TODO: make targeting work in assault & race without this hack
748                         spot.target = string_null;
749                 SUB_UseTargets(spot, this, NULL);
750                 if(g_assault || g_race)
751                         spot.target = s;
752         }
753
754         Unfreeze(this, false);
755
756         MUTATOR_CALLHOOK(PlayerSpawn, this, spot);
757
758         if (autocvar_spawn_debug)
759         {
760                 sprint(this, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
761                 delete(spot); // usefull for checking if there are spawnpoints, that let drop through the floor
762         }
763
764         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
765         {
766                 .entity weaponentity = weaponentities[slot];
767                 if(slot == 0 || autocvar_g_weaponswitch_debug == 1)
768                         this.(weaponentity).m_switchweapon = w_getbestweapon(this, weaponentity);
769                 else
770                         this.(weaponentity).m_switchweapon = WEP_Null;
771                 this.(weaponentity).m_weapon = WEP_Null;
772                 this.(weaponentity).weaponname = "";
773                 this.(weaponentity).m_switchingweapon = WEP_Null;
774                 this.(weaponentity).cnt = -1;
775         }
776
777         MUTATOR_CALLHOOK(PlayerWeaponSelect, this);
778
779         if (CS(this).impulse) ImpulseCommands(this);
780
781         W_ResetGunAlign(this, CS(this).cvar_cl_gunalign);
782         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
783         {
784                 .entity weaponentity = weaponentities[slot];
785                 W_WeaponFrame(this, weaponentity);
786         }
787
788         if (!warmup_stage && !this.alivetime)
789                 this.alivetime = time;
790
791         antilag_clear(this, CS(this));
792 }
793
794 /** Called when a client spawns in the server */
795 void PutClientInServer(entity this)
796 {
797         if (IS_BOT_CLIENT(this)) {
798                 TRANSMUTE(Player, this);
799         } else if (IS_REAL_CLIENT(this)) {
800                 msg_entity = this;
801                 WriteByte(MSG_ONE, SVC_SETVIEW);
802                 WriteEntity(MSG_ONE, this);
803         }
804         if (game_stopped)
805                 TRANSMUTE(Observer, this);
806
807         SetSpectatee(this, NULL);
808
809         // reset player keys
810         if(PS(this))
811                 PS(this).itemkeys = 0;
812
813         MUTATOR_CALLHOOK(PutClientInServer, this);
814
815         if (IS_OBSERVER(this)) {
816                 PutObserverInServer(this);
817         } else if (IS_PLAYER(this)) {
818                 PutPlayerInServer(this);
819         }
820 }
821
822 // TODO do we need all these fields, or should we stop autodetecting runtime
823 // changes and just have a console command to update this?
824 bool ClientInit_SendEntity(entity this, entity to, int sf)
825 {
826         WriteHeader(MSG_ENTITY, _ENT_CLIENT_INIT);
827         return = true;
828         msg_entity = to;
829         // MSG_INIT replacement
830         // TODO: make easier to use
831         Registry_send_all();
832         W_PROP_reload(MSG_ONE, to);
833         ClientInit_misc(this);
834         MUTATOR_CALLHOOK(Ent_Init);
835 }
836 void ClientInit_misc(entity this)
837 {
838         int channel = MSG_ONE;
839         WriteHeader(channel, ENT_CLIENT_INIT);
840         WriteByte(channel, g_nexball_meter_period * 32);
841         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[0]));
842         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[1]));
843         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[2]));
844         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[3]));
845         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[0]));
846         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[1]));
847         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[2]));
848         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[3]));
849
850         if(sv_foginterval && world.fog != "")
851                 WriteString(channel, world.fog);
852         else
853                 WriteString(channel, "");
854         WriteByte(channel, this.count * 255.0); // g_balance_armor_blockpercent
855         WriteByte(channel, this.cnt * 255.0); // g_balance_damagepush_speedfactor
856         WriteByte(channel, serverflags);
857         WriteCoord(channel, autocvar_g_trueaim_minrange);
858 }
859
860 void ClientInit_CheckUpdate(entity this)
861 {
862         this.nextthink = time;
863         if(this.count != autocvar_g_balance_armor_blockpercent)
864         {
865                 this.count = autocvar_g_balance_armor_blockpercent;
866                 this.SendFlags |= 1;
867         }
868         if(this.cnt != autocvar_g_balance_damagepush_speedfactor)
869         {
870                 this.cnt = autocvar_g_balance_damagepush_speedfactor;
871                 this.SendFlags |= 1;
872         }
873 }
874
875 void ClientInit_Spawn()
876 {
877         entity e = new_pure(clientinit);
878         setthink(e, ClientInit_CheckUpdate);
879         Net_LinkEntity(e, false, 0, ClientInit_SendEntity);
880
881         ClientInit_CheckUpdate(e);
882 }
883
884 /*
885 =============
886 SetNewParms
887 =============
888 */
889 void SetNewParms ()
890 {
891         // initialize parms for a new player
892         parm1 = -(86400 * 366);
893
894         MUTATOR_CALLHOOK(SetNewParms);
895 }
896
897 /*
898 =============
899 SetChangeParms
900 =============
901 */
902 void SetChangeParms (entity this)
903 {
904         // save parms for level change
905         parm1 = CS(this).parm_idlesince - time;
906
907         MUTATOR_CALLHOOK(SetChangeParms);
908 }
909
910 /*
911 =============
912 DecodeLevelParms
913 =============
914 */
915 void DecodeLevelParms(entity this)
916 {
917         // load parms
918         CS(this).parm_idlesince = parm1;
919         if (CS(this).parm_idlesince == -(86400 * 366))
920                 CS(this).parm_idlesince = time;
921
922         // whatever happens, allow 60 seconds of idling directly after connect for map loading
923         CS(this).parm_idlesince = max(CS(this).parm_idlesince, time - sv_maxidle + 60);
924
925         MUTATOR_CALLHOOK(DecodeLevelParms);
926 }
927
928 void FixClientCvars(entity e)
929 {
930         // send prediction settings to the client
931         stuffcmd(e, "\nin_bindmap 0 0\n");
932         if(autocvar_g_antilag == 3) // client side hitscan
933                 stuffcmd(e, "cl_cmd settemp cl_prydoncursor_notrace 0\n");
934         if(autocvar_sv_gentle)
935                 stuffcmd(e, "cl_cmd settemp cl_gentle 1\n");
936
937         stuffcmd(e, sprintf("\ncl_jumpspeedcap_min \"%s\"\n", autocvar_sv_jumpspeedcap_min));
938         stuffcmd(e, sprintf("\ncl_jumpspeedcap_max \"%s\"\n", autocvar_sv_jumpspeedcap_max));
939
940         stuffcmd(e, sprintf("\ncl_shootfromfixedorigin \"%s\"\n", autocvar_g_shootfromfixedorigin));
941
942         MUTATOR_CALLHOOK(FixClientCvars, e);
943 }
944
945 bool findinlist_abbrev(string tofind, string list)
946 {
947         if(list == "" || tofind == "")
948                 return false; // empty list or search, just return
949
950         // this function allows abbreviated strings!
951         FOREACH_WORD(list, it == substring(tofind, 0, strlen(it)),
952         {
953                 return true;
954         });
955
956         return false;
957 }
958
959 bool PlayerInIPList(entity p, string iplist)
960 {
961         // some safety checks (never allow local?)
962         if(p.netaddress == "local" || p.netaddress == "" || !IS_REAL_CLIENT(p))
963                 return false;
964
965         return findinlist_abbrev(p.netaddress, iplist);
966 }
967
968 bool PlayerInIDList(entity p, string idlist)
969 {
970         // NOTE: we do NOT check crypto_idfp_signed here, an unsigned ID is fine too for this
971         if(!p.crypto_idfp)
972                 return false;
973
974         return findinlist_abbrev(p.crypto_idfp, idlist);
975 }
976
977 bool PlayerInList(entity player, string list)
978 {
979         return boolean(PlayerInIDList(player, list) || PlayerInIPList(player, list));
980 }
981
982 #ifdef DP_EXT_PRECONNECT
983 /*
984 =============
985 ClientPreConnect
986
987 Called once (not at each match start) when a client begins a connection to the server
988 =============
989 */
990 void ClientPreConnect(entity this)
991 {
992         if(autocvar_sv_eventlog)
993         {
994                 GameLogEcho(sprintf(":connect:%d:%d:%s",
995                         this.playerid,
996                         etof(this),
997                         ((IS_REAL_CLIENT(this)) ? this.netaddress : "bot")
998                 ));
999         }
1000 }
1001 #endif
1002
1003 string GetClientVersionMessage(entity this)
1004 {
1005         if (CS(this).version_mismatch) {
1006                 if(CS(this).version < autocvar_gameversion) {
1007                         return strcat("This is Xonotic ", autocvar_g_xonoticversion,
1008                                 "\n^3Your client version is outdated.\n\n\n### YOU WON'T BE ABLE TO PLAY ON THIS SERVER ###\n\n\nPlease update!!!^8");
1009                 } else {
1010                         return strcat("This is Xonotic ", autocvar_g_xonoticversion,
1011                                 "\n^3This server is using an outdated Xonotic version.\n\n\n ### THIS SERVER IS INCOMPATIBLE AND THUS YOU CANNOT JOIN ###.^8");
1012                 }
1013         } else {
1014                 return strcat("Welcome to Xonotic ", autocvar_g_xonoticversion);
1015         }
1016 }
1017
1018 string getwelcomemessage(entity this)
1019 {
1020         MUTATOR_CALLHOOK(BuildMutatorsPrettyString, "");
1021         string modifications = M_ARGV(0, string);
1022
1023         if(g_weaponarena)
1024         {
1025                 if(g_weaponarena_random)
1026                         modifications = strcat(modifications, ", ", ftos(g_weaponarena_random), " of ", g_weaponarena_list, " Arena");
1027                 else
1028                         modifications = strcat(modifications, ", ", g_weaponarena_list, " Arena");
1029         }
1030         else if(cvar("g_balance_blaster_weaponstartoverride") == 0)
1031                 modifications = strcat(modifications, ", No start weapons");
1032         if(cvar("sv_gravity") < stof(cvar_defstring("sv_gravity")))
1033                 modifications = strcat(modifications, ", Low gravity");
1034         if(g_weapon_stay && !g_cts)
1035                 modifications = strcat(modifications, ", Weapons stay");
1036         if(g_jetpack)
1037                 modifications = strcat(modifications, ", Jet pack");
1038         if(autocvar_g_powerups == 0)
1039                 modifications = strcat(modifications, ", No powerups");
1040         if(autocvar_g_powerups > 0)
1041                 modifications = strcat(modifications, ", Powerups");
1042         modifications = substring(modifications, 2, strlen(modifications) - 2);
1043
1044         string versionmessage = GetClientVersionMessage(this);
1045         string s = strcat(versionmessage, "^8\n^8\nmatch type is ^1", gamemode_name, "^8\n");
1046
1047         if(modifications != "")
1048                 s = strcat(s, "^8\nactive modifications: ^3", modifications, "^8\n");
1049
1050         if(cache_lastmutatormsg != autocvar_g_mutatormsg)
1051         {
1052                 strcpy(cache_lastmutatormsg, autocvar_g_mutatormsg);
1053                 strcpy(cache_mutatormsg, cache_lastmutatormsg);
1054         }
1055
1056         if (cache_mutatormsg != "") {
1057                 s = strcat(s, "\n\n^8special gameplay tips: ^7", cache_mutatormsg);
1058         }
1059
1060         string mutator_msg = "";
1061         MUTATOR_CALLHOOK(BuildGameplayTipsString, mutator_msg);
1062         mutator_msg = M_ARGV(0, string);
1063
1064         s = strcat(s, mutator_msg); // trust that the mutator will do proper formatting
1065
1066         string motd = autocvar_sv_motd;
1067         if (motd != "") {
1068                 s = strcat(s, "\n\n^8MOTD: ^7", strreplace("\\n", "\n", motd));
1069         }
1070         return s;
1071 }
1072
1073 bool autocvar_sv_qcphysics = true; // TODO this is for testing - remove when qcphysics work
1074
1075 /**
1076 =============
1077 ClientConnect
1078
1079 Called when a client connects to the server
1080 =============
1081 */
1082 void ClientConnect(entity this)
1083 {
1084         if (Ban_MaybeEnforceBanOnce(this)) return;
1085         assert(!IS_CLIENT(this), return);
1086         this.flags |= FL_CLIENT;
1087         assert(player_count >= 0, player_count = 0);
1088
1089 #ifdef WATERMARK
1090         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_WATERMARK, WATERMARK);
1091 #endif
1092         TRANSMUTE(Client, this);
1093         CS(this).version_nagtime = time + 10 + random() * 10;
1094
1095         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_JOIN_CONNECT, this.netname);
1096
1097         bot_clientconnect(this);
1098
1099         Player_DetermineForcedTeam(this);
1100
1101         TRANSMUTE(Observer, this);
1102
1103         PlayerStats_GameReport_AddEvent(sprintf("kills-%d", this.playerid));
1104
1105         // always track bots, don't ask for cl_allow_uidtracking
1106         if (IS_BOT_CLIENT(this))
1107                 PlayerStats_GameReport_AddPlayer(this);
1108         else
1109                 CS(this).allowed_timeouts = autocvar_sv_timeout_number;
1110
1111         if (autocvar_sv_eventlog)
1112                 GameLogEcho(strcat(":join:", ftos(this.playerid), ":", ftos(etof(this)), ":", ((IS_REAL_CLIENT(this)) ? GameLog_ProcessIP(this.netaddress) : "bot"), ":", playername(this, false)));
1113
1114         CS(this).just_joined = true;  // stop spamming the eventlog with additional lines when the client connects
1115
1116         stuffcmd(this, clientstuff, "\n");
1117         stuffcmd(this, "cl_particles_reloadeffects\n"); // TODO do we still need this?
1118
1119         FixClientCvars(this);
1120
1121         // get version info from player
1122         stuffcmd(this, "cmd clientversion $gameversion\n");
1123
1124         // notify about available teams
1125         if (teamplay)
1126         {
1127                 entity balance = TeamBalance_CheckAllowedTeams(this);
1128                 int t = TeamBalance_GetAllowedTeams(balance);
1129                 TeamBalance_Destroy(balance);
1130                 stuffcmd(this, sprintf("set _teams_available %d\n", t));
1131         }
1132         else
1133         {
1134                 stuffcmd(this, "set _teams_available 0\n");
1135         }
1136
1137         bot_relinkplayerlist();
1138
1139         CS(this).spectatortime = time;
1140         if (blockSpectators)
1141         {
1142                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
1143         }
1144
1145         CS(this).jointime = time;
1146
1147         if (IS_REAL_CLIENT(this))
1148         {
1149                 if (g_weaponarena_weapons == WEPSET(TUBA))
1150                         stuffcmd(this, "cl_cmd settemp chase_active 1\n");
1151         }
1152
1153         if (!sv_foginterval && world.fog != "")
1154                 stuffcmd(this, strcat("\nfog ", world.fog, "\nr_fog_exp2 0\nr_drawfog 1\n"));
1155
1156         if (autocvar_sv_teamnagger && !(autocvar_bot_vs_human && AvailableTeams() == 2))
1157                 if(!MUTATOR_CALLHOOK(HideTeamNagger, this))
1158                         send_CSQC_teamnagger();
1159
1160         CSQCMODEL_AUTOINIT(this);
1161
1162         CS(this).model_randomizer = random();
1163
1164         if (IS_REAL_CLIENT(this))
1165                 sv_notice_join(this);
1166
1167         this.move_qcphysics = autocvar_sv_qcphysics;
1168
1169         // update physics stats (players can spawn before physics runs)
1170         Physics_UpdateStats(this);
1171
1172         IL_EACH(g_initforplayer, it.init_for_player, {
1173                 it.init_for_player(it, this);
1174         });
1175
1176         Handicap_Initialize(this);
1177
1178         MUTATOR_CALLHOOK(ClientConnect, this);
1179
1180         if (IS_REAL_CLIENT(this))
1181         {
1182                 if (!autocvar_g_campaign && !IS_PLAYER(this))
1183                 {
1184                         CS(this).motd_actived_time = -1;
1185                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOTD, getwelcomemessage(this));
1186                 }
1187         }
1188 }
1189 /*
1190 =============
1191 ClientDisconnect
1192
1193 Called when a client disconnects from the server
1194 =============
1195 */
1196 .entity chatbubbleentity;
1197 void ClientDisconnect(entity this)
1198 {
1199         assert(IS_CLIENT(this), return);
1200
1201         PlayerStats_GameReport_FinalizePlayer(this);
1202         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
1203         if (CS(this).active_minigame) part_minigame(this);
1204         if (IS_PLAYER(this)) Send_Effect(EFFECT_SPAWN_NEUTRAL, this.origin, '0 0 0', 1);
1205
1206         if (autocvar_sv_eventlog)
1207                 GameLogEcho(strcat(":part:", ftos(this.playerid)));
1208
1209         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_QUIT_DISCONNECT, this.netname);
1210
1211         if(IS_SPEC(this))
1212                 SetSpectatee(this, NULL);
1213
1214     MUTATOR_CALLHOOK(ClientDisconnect, this);
1215
1216         strfree(CS(this).netname_previous); // needs to be before the CS entity is removed!
1217         strfree(CS(this).weaponorder_byimpulse);
1218         ClientState_detach(this);
1219
1220         Portal_ClearAll(this);
1221
1222         Unfreeze(this, false);
1223
1224         RemoveGrapplingHooks(this);
1225
1226         // Here, everything has been done that requires this player to be a client.
1227
1228         this.flags &= ~FL_CLIENT;
1229
1230         if (this.chatbubbleentity) delete(this.chatbubbleentity);
1231         if (this.killindicator) delete(this.killindicator);
1232
1233         WaypointSprite_PlayerGone(this);
1234
1235         bot_relinkplayerlist();
1236
1237         strfree(this.clientstatus);
1238         if (this.personal) delete(this.personal);
1239
1240         this.playerid = 0;
1241         ReadyCount();
1242         if (vote_called && IS_REAL_CLIENT(this)) VoteCount(false);
1243
1244         ONREMOVE(this);
1245 }
1246
1247 void ChatBubbleThink(entity this)
1248 {
1249         this.nextthink = time;
1250         if ((this.owner.alpha < 0) || this.owner.chatbubbleentity != this)
1251         {
1252                 if(this.owner) // but why can that ever be NULL?
1253                         this.owner.chatbubbleentity = NULL;
1254                 delete(this);
1255                 return;
1256         }
1257
1258         this.mdl = "";
1259
1260         if ( !IS_DEAD(this.owner) && IS_PLAYER(this.owner) )
1261         {
1262                 if ( CS(this.owner).active_minigame && PHYS_INPUT_BUTTON_MINIGAME(this.owner) )
1263                         this.mdl = "models/sprites/minigame_busy.iqm";
1264                 else if (PHYS_INPUT_BUTTON_CHAT(this.owner))
1265                         this.mdl = "models/misc/chatbubble.spr";
1266         }
1267
1268         if ( this.model != this.mdl )
1269                 _setmodel(this, this.mdl);
1270
1271 }
1272
1273 void UpdateChatBubble(entity this)
1274 {
1275         if (this.alpha < 0)
1276                 return;
1277         // spawn a chatbubble entity if needed
1278         if (!this.chatbubbleentity)
1279         {
1280                 this.chatbubbleentity = new(chatbubbleentity);
1281                 this.chatbubbleentity.owner = this;
1282                 this.chatbubbleentity.exteriormodeltoclient = this;
1283                 setthink(this.chatbubbleentity, ChatBubbleThink);
1284                 this.chatbubbleentity.nextthink = time;
1285                 setmodel(this.chatbubbleentity, MDL_CHAT); // precision set below
1286                 //setorigin(this.chatbubbleentity, this.origin + '0 0 15' + this.maxs_z * '0 0 1');
1287                 setorigin(this.chatbubbleentity, '0 0 15' + this.maxs_z * '0 0 1');
1288                 setattachment(this.chatbubbleentity, this, "");  // sticks to moving player better, also conserves bandwidth
1289                 this.chatbubbleentity.mdl = this.chatbubbleentity.model;
1290                 //this.chatbubbleentity.model = "";
1291                 this.chatbubbleentity.effects = EF_LOWPRECISION;
1292         }
1293 }
1294
1295
1296 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
1297 // added to the model skins
1298 /*void UpdateColorModHack()
1299 {
1300         float c;
1301         c = this.clientcolors & 15;
1302         // LordHavoc: only bothering to support white, green, red, yellow, blue
1303              if (!teamplay) this.colormod = '0 0 0';
1304         else if (c ==  0) this.colormod = '1.00 1.00 1.00';
1305         else if (c ==  3) this.colormod = '0.10 1.73 0.10';
1306         else if (c ==  4) this.colormod = '1.73 0.10 0.10';
1307         else if (c == 12) this.colormod = '1.22 1.22 0.10';
1308         else if (c == 13) this.colormod = '0.10 0.10 1.73';
1309         else this.colormod = '1 1 1';
1310 }*/
1311
1312 void respawn(entity this)
1313 {
1314         if(this.alpha >= 0 && autocvar_g_respawn_ghosts)
1315         {
1316                 this.solid = SOLID_NOT;
1317                 this.takedamage = DAMAGE_NO;
1318                 set_movetype(this, MOVETYPE_FLY);
1319                 this.velocity = '0 0 1' * autocvar_g_respawn_ghosts_speed;
1320                 this.avelocity = randomvec() * autocvar_g_respawn_ghosts_speed * 3 - randomvec() * autocvar_g_respawn_ghosts_speed * 3;
1321                 this.effects |= CSQCMODEL_EF_RESPAWNGHOST;
1322                 Send_Effect(EFFECT_RESPAWN_GHOST, this.origin, '0 0 0', 1);
1323                 if(autocvar_g_respawn_ghosts_maxtime)
1324                         SUB_SetFade (this, time + autocvar_g_respawn_ghosts_maxtime / 2 + random () * (autocvar_g_respawn_ghosts_maxtime - autocvar_g_respawn_ghosts_maxtime / 2), 1.5);
1325         }
1326
1327         CopyBody(this, 1);
1328
1329         this.effects |= EF_NODRAW; // prevent another CopyBody
1330         PutClientInServer(this);
1331 }
1332
1333 ERASEABLE
1334 void PrintToChat(entity client, string text)
1335 {
1336         text = strcat("\{1}^7", text, "\n");
1337         sprint(client, text);
1338 }
1339
1340 ERASEABLE
1341 void DebugPrintToChat(entity client, string text)
1342 {
1343         if (autocvar_developer > 0)
1344         {
1345                 PrintToChat(client, text);
1346         }
1347 }
1348
1349 ERASEABLE
1350 void PrintToChatAll(string text)
1351 {
1352         text = strcat("\{1}^7", text, "\n");
1353         bprint(text);
1354 }
1355
1356 ERASEABLE
1357 void DebugPrintToChatAll(string text)
1358 {
1359         if (autocvar_developer > 0)
1360         {
1361                 PrintToChatAll(text);
1362         }
1363 }
1364
1365 ERASEABLE
1366 void PrintToChatTeam(int team_num, string text)
1367 {
1368         text = strcat("\{1}^7", text, "\n");
1369         FOREACH_CLIENT(IS_REAL_CLIENT(it),
1370         {
1371                 if (it.team == team_num)
1372                 {
1373                         sprint(it, text);
1374                 }
1375         });
1376 }
1377
1378 ERASEABLE
1379 void DebugPrintToChatTeam(int team_num, string text)
1380 {
1381         if (autocvar_developer > 0)
1382         {
1383                 PrintToChatTeam(team_num, text);
1384         }
1385 }
1386
1387 void play_countdown(entity this, float finished, Sound samp)
1388 {
1389         TC(Sound, samp);
1390         if(IS_REAL_CLIENT(this))
1391                 if(floor(finished - time - frametime) != floor(finished - time))
1392                         if(finished - time < 6)
1393                                 sound (this, CH_INFO, samp, VOL_BASE, ATTEN_NORM);
1394 }
1395
1396 void player_powerups(entity this)
1397 {
1398         // add a way to see what the items were BEFORE all of these checks for the mutator hook
1399         int items_prev = this.items;
1400
1401         if((this.items & IT_USING_JETPACK) && !IS_DEAD(this) && !game_stopped)
1402                 this.modelflags |= MF_ROCKET;
1403         else
1404                 this.modelflags &= ~MF_ROCKET;
1405
1406         this.effects &= ~(EF_RED | EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT | EF_FLAME | EF_NODEPTHTEST);
1407
1408         if((this.alpha < 0 || IS_DEAD(this)) && !this.vehicle) // don't apply the flags if the player is gibbed
1409                 return;
1410
1411         Fire_ApplyDamage(this);
1412         Fire_ApplyEffect(this);
1413
1414         if (!MUTATOR_IS_ENABLED(mutator_instagib))
1415         {
1416                 if (this.items & ITEM_Strength.m_itemid)
1417                 {
1418                         play_countdown(this, STAT(STRENGTH_FINISHED, this), SND_POWEROFF);
1419                         this.effects = this.effects | (EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT);
1420                         if (time > STAT(STRENGTH_FINISHED, this))
1421                         {
1422                                 this.items = this.items - (this.items & ITEM_Strength.m_itemid);
1423                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERDOWN_STRENGTH, this.netname);
1424                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERDOWN_STRENGTH);
1425                         }
1426                 }
1427                 else
1428                 {
1429                         if (time < STAT(STRENGTH_FINISHED, this))
1430                         {
1431                                 this.items = this.items | ITEM_Strength.m_itemid;
1432                                 if(!g_cts)
1433                                         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERUP_STRENGTH, this.netname);
1434                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERUP_STRENGTH);
1435                         }
1436                 }
1437                 if (this.items & ITEM_Shield.m_itemid)
1438                 {
1439                         play_countdown(this, STAT(INVINCIBLE_FINISHED, this), SND_POWEROFF);
1440                         this.effects = this.effects | (EF_RED | EF_ADDITIVE | EF_FULLBRIGHT);
1441                         if (time > STAT(INVINCIBLE_FINISHED, this))
1442                         {
1443                                 this.items = this.items - (this.items & ITEM_Shield.m_itemid);
1444                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERDOWN_SHIELD, this.netname);
1445                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERDOWN_SHIELD);
1446                         }
1447                 }
1448                 else
1449                 {
1450                         if (time < STAT(INVINCIBLE_FINISHED, this))
1451                         {
1452                                 this.items = this.items | ITEM_Shield.m_itemid;
1453                                 if(!g_cts)
1454                                         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERUP_SHIELD, this.netname);
1455                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERUP_SHIELD);
1456                         }
1457                 }
1458                 if (this.items & IT_SUPERWEAPON)
1459                 {
1460                         if (!(STAT(WEAPONS, this) & WEPSET_SUPERWEAPONS))
1461                         {
1462                                 STAT(SUPERWEAPONS_FINISHED, this) = 0;
1463                                 this.items = this.items - (this.items & IT_SUPERWEAPON);
1464                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_LOST, this.netname);
1465                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_LOST);
1466                         }
1467                         else if (this.items & IT_UNLIMITED_SUPERWEAPONS)
1468                         {
1469                                 // don't let them run out
1470                         }
1471                         else
1472                         {
1473                                 play_countdown(this, STAT(SUPERWEAPONS_FINISHED, this), SND_POWEROFF);
1474                                 if (time > STAT(SUPERWEAPONS_FINISHED, this))
1475                                 {
1476                                         this.items = this.items - (this.items & IT_SUPERWEAPON);
1477                                         STAT(WEAPONS, this) &= ~WEPSET_SUPERWEAPONS;
1478                                         //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_BROKEN, this.netname);
1479                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_BROKEN);
1480                                 }
1481                         }
1482                 }
1483                 else if(STAT(WEAPONS, this) & WEPSET_SUPERWEAPONS)
1484                 {
1485                         if (time < STAT(SUPERWEAPONS_FINISHED, this) || (this.items & IT_UNLIMITED_SUPERWEAPONS))
1486                         {
1487                                 this.items = this.items | IT_SUPERWEAPON;
1488                                 if(!(this.items & IT_UNLIMITED_SUPERWEAPONS))
1489                                 {
1490                                         if(!g_cts)
1491                                                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_PICKUP, this.netname);
1492                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_PICKUP);
1493                                 }
1494                         }
1495                         else
1496                         {
1497                                 STAT(SUPERWEAPONS_FINISHED, this) = 0;
1498                                 STAT(WEAPONS, this) &= ~WEPSET_SUPERWEAPONS;
1499                         }
1500                 }
1501                 else
1502                 {
1503                         STAT(SUPERWEAPONS_FINISHED, this) = 0;
1504                 }
1505         }
1506
1507         if(autocvar_g_nodepthtestplayers)
1508                 this.effects = this.effects | EF_NODEPTHTEST;
1509
1510         if(autocvar_g_fullbrightplayers)
1511                 this.effects = this.effects | EF_FULLBRIGHT;
1512
1513         if (time >= game_starttime)
1514         if (time < this.spawnshieldtime)
1515                 this.effects = this.effects | (EF_ADDITIVE | EF_FULLBRIGHT);
1516
1517         MUTATOR_CALLHOOK(PlayerPowerups, this, items_prev);
1518 }
1519
1520 float CalcRegen(float current, float stable, float regenfactor, float regenframetime)
1521 {
1522         if(current > stable)
1523                 return current;
1524         else if(current > stable - 0.25) // when close enough, "snap"
1525                 return stable;
1526         else
1527                 return min(stable, current + (stable - current) * regenfactor * regenframetime);
1528 }
1529
1530 float CalcRot(float current, float stable, float rotfactor, float rotframetime)
1531 {
1532         if(current < stable)
1533                 return current;
1534         else if(current < stable + 0.25) // when close enough, "snap"
1535                 return stable;
1536         else
1537                 return max(stable, current + (stable - current) * rotfactor * rotframetime);
1538 }
1539
1540 void RotRegen(entity this, int res, float regenstable, float regenfactor, float regenlinear, float regenframetime, float rotstable, float rotfactor, float rotlinear, float rotframetime, float limit_mod)
1541 {
1542         float old = GetResource(this, res);
1543         float current = old;
1544         if(current > rotstable)
1545         {
1546                 if(rotframetime > 0)
1547                 {
1548                         current = CalcRot(current, rotstable, rotfactor, rotframetime);
1549                         current = max(rotstable, current - rotlinear * rotframetime);
1550                 }
1551         }
1552         else if(current < regenstable)
1553         {
1554                 if(regenframetime > 0)
1555                 {
1556                         current = CalcRegen(current, regenstable, regenfactor, regenframetime);
1557                         current = min(regenstable, current + regenlinear * regenframetime);
1558                 }
1559         }
1560
1561         float limit = GetResourceLimit(this, res) * limit_mod;
1562         if(current > limit)
1563                 current = limit;
1564
1565         if (current != old)
1566                 SetResource(this, res, current);
1567 }
1568
1569 void player_regen(entity this)
1570 {
1571         float max_mod, regen_mod, rot_mod, limit_mod;
1572         max_mod = regen_mod = rot_mod = limit_mod = 1;
1573
1574         float regen_health = autocvar_g_balance_health_regen;
1575         float regen_health_linear = autocvar_g_balance_health_regenlinear;
1576         float regen_health_rot = autocvar_g_balance_health_rot;
1577         float regen_health_rotlinear = autocvar_g_balance_health_rotlinear;
1578         float regen_health_stable = autocvar_g_balance_health_regenstable;
1579         float regen_health_rotstable = autocvar_g_balance_health_rotstable;
1580         bool mutator_returnvalue = MUTATOR_CALLHOOK(PlayerRegen, this, max_mod, regen_mod, rot_mod, limit_mod, regen_health, regen_health_linear, regen_health_rot,
1581                 regen_health_rotlinear, regen_health_stable, regen_health_rotstable);
1582         max_mod = M_ARGV(1, float);
1583         regen_mod = M_ARGV(2, float);
1584         rot_mod = M_ARGV(3, float);
1585         limit_mod = M_ARGV(4, float);
1586         regen_health = M_ARGV(5, float);
1587         regen_health_linear = M_ARGV(6, float);
1588         regen_health_rot = M_ARGV(7, float);
1589         regen_health_rotlinear = M_ARGV(8, float);
1590         regen_health_stable = M_ARGV(9, float);
1591         regen_health_rotstable = M_ARGV(10, float);
1592
1593         if(!mutator_returnvalue)
1594         if(!STAT(FROZEN, this))
1595         {
1596                 float maxa = autocvar_g_balance_armor_rotstable;
1597                 float mina = autocvar_g_balance_armor_regenstable;
1598
1599                 RotRegen(this, RES_ARMOR, mina, autocvar_g_balance_armor_regen, autocvar_g_balance_armor_regenlinear,
1600                         regen_mod * frametime * (time > this.pauseregen_finished), maxa, autocvar_g_balance_armor_rot, autocvar_g_balance_armor_rotlinear,
1601                         rot_mod * frametime * (time > this.pauserotarmor_finished), limit_mod);
1602
1603                 RotRegen(this, RES_HEALTH, regen_health_stable * max_mod, regen_health, regen_health_linear,
1604                         regen_mod * frametime * (time > this.pauseregen_finished), regen_health_rotstable * max_mod, regen_health_rot, regen_health_rotlinear,
1605                         rot_mod * frametime * (time > this.pauserothealth_finished), limit_mod);
1606         }
1607
1608         // if player rotted to death...  die!
1609         // check this outside above checks, as player may still be able to rot to death
1610         if(GetResource(this, RES_HEALTH) < 1)
1611         {
1612                 if(this.vehicle)
1613                         vehicles_exit(this.vehicle, VHEF_RELEASE);
1614                 if(this.event_damage)
1615                         this.event_damage(this, this, this, 1, DEATH_ROT.m_id, DMG_NOWEP, this.origin, '0 0 0');
1616         }
1617
1618         if (!(this.items & IT_UNLIMITED_AMMO))
1619         {
1620                 float maxf = autocvar_g_balance_fuel_rotstable;
1621                 float minf = autocvar_g_balance_fuel_regenstable;
1622
1623                 RotRegen(this, RES_FUEL, minf, autocvar_g_balance_fuel_regen, autocvar_g_balance_fuel_regenlinear,
1624                         frametime * (time > this.pauseregen_finished) * ((this.items & ITEM_JetpackRegen.m_itemid) != 0),
1625                         maxf, autocvar_g_balance_fuel_rot, autocvar_g_balance_fuel_rotlinear, frametime * (time > this.pauserotfuel_finished), 1);
1626         }
1627 }
1628
1629 bool zoomstate_set;
1630 void SetZoomState(entity this, float newzoom)
1631 {
1632         if(newzoom != CS(this).zoomstate)
1633         {
1634                 CS(this).zoomstate = newzoom;
1635                 ClientData_Touch(this);
1636         }
1637         zoomstate_set = true;
1638 }
1639
1640 void GetPressedKeys(entity this)
1641 {
1642         MUTATOR_CALLHOOK(GetPressedKeys, this);
1643         int keys = STAT(PRESSED_KEYS, this);
1644         keys = BITSET(keys, KEY_FORWARD,        CS(this).movement.x > 0);
1645         keys = BITSET(keys, KEY_BACKWARD,       CS(this).movement.x < 0);
1646         keys = BITSET(keys, KEY_RIGHT,          CS(this).movement.y > 0);
1647         keys = BITSET(keys, KEY_LEFT,           CS(this).movement.y < 0);
1648
1649         keys = BITSET(keys, KEY_JUMP,           PHYS_INPUT_BUTTON_JUMP(this));
1650         keys = BITSET(keys, KEY_CROUCH,         IS_DUCKED(this)); // workaround: player can't un-crouch until their path is clear, so we keep the button held here
1651         keys = BITSET(keys, KEY_ATCK,           PHYS_INPUT_BUTTON_ATCK(this));
1652         keys = BITSET(keys, KEY_ATCK2,          PHYS_INPUT_BUTTON_ATCK2(this));
1653         CS(this).pressedkeys = keys; // store for other users
1654
1655         STAT(PRESSED_KEYS, this) = keys;
1656 }
1657
1658 /*
1659 ======================
1660 spectate mode routines
1661 ======================
1662 */
1663
1664 void SpectateCopy(entity this, entity spectatee)
1665 {
1666         TC(Client, this); TC(Client, spectatee);
1667
1668         MUTATOR_CALLHOOK(SpectateCopy, spectatee, this);
1669         PS(this) = PS(spectatee);
1670         this.armortype = spectatee.armortype;
1671         SetResourceExplicit(this, RES_ARMOR, GetResource(spectatee, RES_ARMOR));
1672         SetResourceExplicit(this, RES_CELLS, GetResource(spectatee, RES_CELLS));
1673         SetResourceExplicit(this, RES_PLASMA, GetResource(spectatee, RES_PLASMA));
1674         SetResourceExplicit(this, RES_SHELLS, GetResource(spectatee, RES_SHELLS));
1675         SetResourceExplicit(this, RES_BULLETS, GetResource(spectatee, RES_BULLETS));
1676         SetResourceExplicit(this, RES_ROCKETS, GetResource(spectatee, RES_ROCKETS));
1677         SetResourceExplicit(this, RES_FUEL, GetResource(spectatee, RES_FUEL));
1678         this.effects = spectatee.effects & EFMASK_CHEAP; // eat performance
1679         SetResourceExplicit(this, RES_HEALTH, GetResource(spectatee, RES_HEALTH));
1680         CS(this).impulse = 0;
1681         this.disableclientprediction = 1; // no need to run prediction on a spectator
1682         this.items = spectatee.items;
1683         STAT(LAST_PICKUP, this) = STAT(LAST_PICKUP, spectatee);
1684         STAT(HIT_TIME, this) = STAT(HIT_TIME, spectatee);
1685         STAT(STRENGTH_FINISHED, this) = STAT(STRENGTH_FINISHED, spectatee);
1686         STAT(INVINCIBLE_FINISHED, this) = STAT(INVINCIBLE_FINISHED, spectatee);
1687         STAT(SUPERWEAPONS_FINISHED, this) = STAT(SUPERWEAPONS_FINISHED, spectatee);
1688         this.air_finished = spectatee.air_finished;
1689         STAT(PRESSED_KEYS, this) = STAT(PRESSED_KEYS, spectatee);
1690         STAT(WEAPONS, this) = STAT(WEAPONS, spectatee);
1691         this.punchangle = spectatee.punchangle;
1692         this.view_ofs = spectatee.view_ofs;
1693         this.velocity = spectatee.velocity;
1694         this.dmg_take = spectatee.dmg_take;
1695         this.dmg_save = spectatee.dmg_save;
1696         this.dmg_inflictor = spectatee.dmg_inflictor;
1697         this.v_angle = spectatee.v_angle;
1698         this.angles = spectatee.v_angle;
1699         STAT(FROZEN, this) = STAT(FROZEN, spectatee);
1700         STAT(REVIVE_PROGRESS, this) = STAT(REVIVE_PROGRESS, spectatee);
1701         this.viewloc = spectatee.viewloc;
1702         if(!PHYS_INPUT_BUTTON_USE(this) && STAT(CAMERA_SPECTATOR, this) != 2)
1703                 this.fixangle = true;
1704         setorigin(this, spectatee.origin);
1705         setsize(this, spectatee.mins, spectatee.maxs);
1706         SetZoomState(this, CS(spectatee).zoomstate);
1707
1708     anticheat_spectatecopy(this, spectatee);
1709         STAT(HUD, this) = STAT(HUD, spectatee);
1710         if(spectatee.vehicle)
1711     {
1712         this.angles = spectatee.v_angle;
1713
1714         //this.fixangle = false;
1715         //this.velocity = spectatee.vehicle.velocity;
1716         this.vehicle_health = spectatee.vehicle_health;
1717         this.vehicle_shield = spectatee.vehicle_shield;
1718         this.vehicle_energy = spectatee.vehicle_energy;
1719         this.vehicle_ammo1 = spectatee.vehicle_ammo1;
1720         this.vehicle_ammo2 = spectatee.vehicle_ammo2;
1721         this.vehicle_reload1 = spectatee.vehicle_reload1;
1722         this.vehicle_reload2 = spectatee.vehicle_reload2;
1723
1724         //msg_entity = this;
1725
1726        // WriteByte (MSG_ONE, SVC_SETVIEWANGLES);
1727             //WriteAngle(MSG_ONE,  spectatee.v_angle.x);
1728            // WriteAngle(MSG_ONE,  spectatee.v_angle.y);
1729            // WriteAngle(MSG_ONE,  spectatee.v_angle.z);
1730
1731         //WriteByte (MSG_ONE, SVC_SETVIEW);
1732         //    WriteEntity(MSG_ONE, this);
1733         //makevectors(spectatee.v_angle);
1734         //setorigin(this, spectatee.origin - v_forward * 400 + v_up * 300);*/
1735     }
1736 }
1737
1738 bool SpectateUpdate(entity this)
1739 {
1740         if(!this.enemy)
1741                 return false;
1742
1743         if(!IS_PLAYER(this.enemy) || this == this.enemy)
1744         {
1745                 SetSpectatee(this, NULL);
1746                 return false;
1747         }
1748
1749         SpectateCopy(this, this.enemy);
1750
1751         return true;
1752 }
1753
1754 bool SpectateSet(entity this)
1755 {
1756         if(!IS_PLAYER(this.enemy))
1757                 return false;
1758
1759         ClientData_Touch(this.enemy);
1760
1761         msg_entity = this;
1762         WriteByte(MSG_ONE, SVC_SETVIEW);
1763         WriteEntity(MSG_ONE, this.enemy);
1764         set_movetype(this, MOVETYPE_NONE);
1765         accuracy_resend(this);
1766
1767         if(!SpectateUpdate(this))
1768                 PutObserverInServer(this);
1769
1770         return true;
1771 }
1772
1773 void SetSpectatee_status(entity this, int spectatee_num)
1774 {
1775         int oldspectatee_status = CS(this).spectatee_status;
1776         CS(this).spectatee_status = spectatee_num;
1777
1778         if (CS(this).spectatee_status != oldspectatee_status)
1779         {
1780                 if (STAT(PRESSED_KEYS, this))
1781                 {
1782                         CS(this).pressedkeys = 0;
1783                         STAT(PRESSED_KEYS, this) = 0;
1784                 }
1785                 ClientData_Touch(this);
1786                 if (g_race || g_cts) race_InitSpectator();
1787         }
1788 }
1789
1790 void SetSpectatee(entity this, entity spectatee)
1791 {
1792         if(IS_BOT_CLIENT(this))
1793                 return; // bots abuse .enemy, this code is useless to them
1794
1795         entity old_spectatee = this.enemy;
1796
1797         this.enemy = spectatee;
1798
1799         // WEAPONTODO
1800         // these are required to fix the spectator bug with arc
1801         if(old_spectatee)
1802         {
1803                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1804                 {
1805                         .entity weaponentity = weaponentities[slot];
1806                         if(old_spectatee.(weaponentity).arc_beam)
1807                                 old_spectatee.(weaponentity).arc_beam.SendFlags |= ARC_SF_SETTINGS;
1808                 }
1809         }
1810         if(this.enemy)
1811         {
1812                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1813                 {
1814                         .entity weaponentity = weaponentities[slot];
1815                         if(this.enemy.(weaponentity).arc_beam)
1816                                 this.enemy.(weaponentity).arc_beam.SendFlags |= ARC_SF_SETTINGS;
1817                 }
1818         }
1819
1820         if (this.enemy)
1821                 SetSpectatee_status(this, etof(this.enemy));
1822
1823         // needed to update spectator list
1824         if(old_spectatee) { ClientData_Touch(old_spectatee); }
1825 }
1826
1827 bool Spectate(entity this, entity pl)
1828 {
1829         if(MUTATOR_CALLHOOK(SpectateSet, this, pl))
1830                 return false;
1831         pl = M_ARGV(1, entity);
1832
1833         SetSpectatee(this, pl);
1834         return SpectateSet(this);
1835 }
1836
1837 bool SpectateNext(entity this)
1838 {
1839         entity ent = find(this.enemy, classname, STR_PLAYER);
1840
1841         if (MUTATOR_CALLHOOK(SpectateNext, this, ent))
1842                 ent = M_ARGV(1, entity);
1843         else if (!ent)
1844                 ent = find(ent, classname, STR_PLAYER);
1845
1846         if(ent) { SetSpectatee(this, ent); }
1847
1848         return SpectateSet(this);
1849 }
1850
1851 bool SpectatePrev(entity this)
1852 {
1853         // NOTE: chain order is from the highest to the lower entnum (unlike find)
1854         entity ent = findchain(classname, STR_PLAYER);
1855         if (!ent) // no player
1856                 return false;
1857
1858         entity first = ent;
1859         // skip players until current spectated player
1860         if(this.enemy)
1861         while(ent && ent != this.enemy)
1862                 ent = ent.chain;
1863
1864         switch (MUTATOR_CALLHOOK(SpectatePrev, this, ent, first))
1865         {
1866                 case MUT_SPECPREV_FOUND:
1867                     ent = M_ARGV(1, entity);
1868                     break;
1869                 case MUT_SPECPREV_RETURN:
1870                     return true;
1871                 case MUT_SPECPREV_CONTINUE:
1872                 default:
1873                 {
1874                         if(ent.chain)
1875                                 ent = ent.chain;
1876                         else
1877                                 ent = first;
1878                         break;
1879                 }
1880         }
1881
1882         SetSpectatee(this, ent);
1883         return SpectateSet(this);
1884 }
1885
1886 /*
1887 =============
1888 ShowRespawnCountdown()
1889
1890 Update a respawn countdown display.
1891 =============
1892 */
1893 void ShowRespawnCountdown(entity this)
1894 {
1895         float number;
1896         if(!IS_DEAD(this)) // just respawned?
1897                 return;
1898         else
1899         {
1900                 number = ceil(this.respawn_time - time);
1901                 if(number <= 0)
1902                         return;
1903                 if(number <= this.respawn_countdown)
1904                 {
1905                         this.respawn_countdown = number - 1;
1906                         if(ceil(this.respawn_time - (time + 0.5)) == number) // only say it if it is the same number even in 0.5s; to prevent overlapping sounds
1907                                 { Send_Notification(NOTIF_ONE, this, MSG_ANNCE, Announcer_PickNumber(CNT_RESPAWN, number)); }
1908                 }
1909         }
1910 }
1911
1912 .bool team_selected;
1913 bool ShowTeamSelection(entity this)
1914 {
1915         if (!teamplay || autocvar_g_campaign || autocvar_g_balance_teams || this.team_selected || (CS(this).wasplayer && autocvar_g_changeteam_banned) || Player_HasRealForcedTeam(this))
1916                 return false;
1917         stuffcmd(this, "menu_showteamselect\n");
1918         return true;
1919 }
1920 void Join(entity this)
1921 {
1922         TRANSMUTE(Player, this);
1923
1924         if(!this.team_selected)
1925         if(autocvar_g_campaign || autocvar_g_balance_teams)
1926                 TeamBalance_JoinBestTeam(this);
1927
1928         if(autocvar_g_campaign)
1929                 campaign_bots_may_start = true;
1930
1931         Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_PREVENT_JOIN);
1932
1933         PutClientInServer(this);
1934
1935         if(IS_PLAYER(this))
1936         if(teamplay && this.team != -1)
1937         {
1938         }
1939         else
1940                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_JOIN_PLAY, this.netname);
1941         this.team_selected = false;
1942 }
1943
1944 int GetPlayerLimit()
1945 {
1946         int player_limit = autocvar_g_maxplayers;
1947         MUTATOR_CALLHOOK(GetPlayerLimit, player_limit);
1948         player_limit = M_ARGV(0, int);
1949         return player_limit;
1950 }
1951
1952 /**
1953  * Determines whether the player is allowed to join. This depends on cvar
1954  * g_maxplayers, if it isn't used this function always return true, otherwise
1955  * it checks whether the number of currently playing players exceeds g_maxplayers.
1956  * @return int number of free slots for players, 0 if none
1957  */
1958 int nJoinAllowed(entity this, entity ignore)
1959 {
1960         if(!ignore)
1961         // this is called that way when checking if anyone may be able to join (to build qcstatus)
1962         // so report 0 free slots if restricted
1963         {
1964                 if(autocvar_g_forced_team_otherwise == "spectate")
1965                         return 0;
1966                 if(autocvar_g_forced_team_otherwise == "spectator")
1967                         return 0;
1968         }
1969
1970         if(this && (Player_GetForcedTeamIndex(this) == TEAM_FORCE_SPECTATOR))
1971                 return 0; // forced spectators can never join
1972
1973         // TODO simplify this
1974         int totalClients = 0;
1975         int currentlyPlaying = 0;
1976         FOREACH_CLIENT(true, {
1977                 if(it != ignore)
1978                         ++totalClients;
1979                 if(IS_REAL_CLIENT(it))
1980                 if(IS_PLAYER(it) || it.caplayer)
1981                         ++currentlyPlaying;
1982         });
1983
1984         int player_limit = GetPlayerLimit();
1985
1986         float free_slots = 0;
1987         if (!player_limit)
1988                 free_slots = maxclients - totalClients;
1989         else if(currentlyPlaying < player_limit)
1990                 free_slots = min(maxclients - totalClients, player_limit - currentlyPlaying);
1991
1992         static float msg_time = 0;
1993         if(this && !this.caplayer && ignore && !free_slots && time > msg_time)
1994         {
1995                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_JOIN_PREVENT);
1996                 msg_time = time + 0.5;
1997         }
1998
1999         return free_slots;
2000 }
2001
2002 /**
2003  * Checks whether the client is an observer or spectator, if so, he will get kicked after
2004  * g_maxplayers_spectator_blocktime seconds
2005  */
2006 void checkSpectatorBlock(entity this)
2007 {
2008         if(IS_SPEC(this) || IS_OBSERVER(this))
2009         if(!this.caplayer)
2010         if(IS_REAL_CLIENT(this))
2011         {
2012                 if( time > (CS(this).spectatortime + autocvar_g_maxplayers_spectator_blocktime) ) {
2013                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_QUIT_KICK_SPECTATING);
2014                         dropclient(this);
2015                 }
2016         }
2017 }
2018
2019 void PrintWelcomeMessage(entity this)
2020 {
2021         if(CS(this).motd_actived_time == 0)
2022         {
2023                 if (autocvar_g_campaign) {
2024                         if ((IS_PLAYER(this) && PHYS_INPUT_BUTTON_INFO(this)) || (!IS_PLAYER(this))) {
2025                                 CS(this).motd_actived_time = time;
2026                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_CAMPAIGN_MESSAGE, Campaign_GetMessage(), Campaign_GetLevelNum());
2027                         }
2028                 } else {
2029                         if (PHYS_INPUT_BUTTON_INFO(this)) {
2030                                 CS(this).motd_actived_time = time;
2031                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOTD, getwelcomemessage(this));
2032                         }
2033                 }
2034         }
2035         else if(CS(this).motd_actived_time > 0) // showing MOTD or campaign message
2036         {
2037                 if (autocvar_g_campaign) {
2038                         if (PHYS_INPUT_BUTTON_INFO(this))
2039                                 CS(this).motd_actived_time = time;
2040                         else if ((time - CS(this).motd_actived_time > 2) && IS_PLAYER(this)) { // hide it some seconds after BUTTON_INFO has been released
2041                                 CS(this).motd_actived_time = 0;
2042                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_CAMPAIGN_MESSAGE);
2043                         }
2044                 } else {
2045                         if (PHYS_INPUT_BUTTON_INFO(this))
2046                                 CS(this).motd_actived_time = time;
2047                         else if (time - CS(this).motd_actived_time > 2) { // hide it some seconds after BUTTON_INFO has been released
2048                                 CS(this).motd_actived_time = 0;
2049                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_MOTD);
2050                         }
2051                 }
2052         }
2053         else //if(CS(this).motd_actived_time < 0) // just connected, motd is active
2054         {
2055                 if(PHYS_INPUT_BUTTON_INFO(this)) // BUTTON_INFO hides initial MOTD
2056                         CS(this).motd_actived_time = -2; // wait until BUTTON_INFO gets released
2057                 else if (CS(this).motd_actived_time == -2)
2058                 {
2059                         // instantly hide MOTD
2060                         CS(this).motd_actived_time = 0;
2061                         if (autocvar_g_campaign)
2062                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_CAMPAIGN_MESSAGE);
2063                         else
2064                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_MOTD);
2065                 }
2066                 else if (IS_PLAYER(this) || IS_SPEC(this))
2067                 {
2068                         // FIXME occasionally for some reason MOTD never goes away
2069                         // delay MOTD removal a little bit in the hope it fixes this bug
2070                         if (CS(this).motd_actived_time == -1) // MOTD marked to fade away as soon as client becomes player or spectator
2071                                 CS(this).motd_actived_time = -(5 + floor(random() * 10)); // add small delay
2072                         else //if (CS(this).motd_actived_time < -2)
2073                                 CS(this).motd_actived_time++;
2074                 }
2075         }
2076 }
2077
2078 const int MIN_SPEC_TIME = 1;
2079 bool joinAllowed(entity this)
2080 {
2081         if (CS(this).version_mismatch) return false;
2082         if (time < CS(this).jointime + MIN_SPEC_TIME) return false;
2083         if (!nJoinAllowed(this, this)) return false;
2084         if (teamplay && lockteams) return false;
2085         if (MUTATOR_CALLHOOK(ForbidSpawn, this)) return false;
2086         if (ShowTeamSelection(this)) return false;
2087         return true;
2088 }
2089
2090 .int items_added;
2091 .string shootfromfixedorigin;
2092 .bool dualwielding_prev;
2093 bool PlayerThink(entity this)
2094 {
2095         if (game_stopped || intermission_running) {
2096                 this.modelflags &= ~MF_ROCKET;
2097                 if(intermission_running)
2098                         IntermissionThink(this);
2099                 return false;
2100         }
2101
2102         if (timeout_status == TIMEOUT_ACTIVE) {
2103         // don't allow the player to turn around while game is paused
2104                 // FIXME turn this into CSQC stuff
2105                 this.v_angle = this.lastV_angle;
2106                 this.angles = this.lastV_angle;
2107                 this.fixangle = true;
2108         }
2109
2110         if (frametime) player_powerups(this);
2111
2112         if (IS_DEAD(this)) {
2113                 if (this.personal && g_race_qualifying) {
2114                         if (time > this.respawn_time) {
2115                                 STAT(RESPAWN_TIME, this) = this.respawn_time = time + 1; // only retry once a second
2116                                 respawn(this);
2117                                 CS(this).impulse = CHIMPULSE_SPEEDRUN.impulse;
2118                         }
2119                 } else {
2120                         if (frametime) player_anim(this);
2121
2122                         if (this.respawn_flags & RESPAWN_DENY)
2123                         {
2124                                 STAT(RESPAWN_TIME, this) = 0;
2125                                 return false;
2126                         }
2127
2128                         bool button_pressed = (PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_JUMP(this) || PHYS_INPUT_BUTTON_ATCK2(this) || PHYS_INPUT_BUTTON_HOOK(this) || PHYS_INPUT_BUTTON_USE(this));
2129
2130                         switch(this.deadflag)
2131                         {
2132                                 case DEAD_DYING:
2133                                 {
2134                                         if ((this.respawn_flags & RESPAWN_FORCE) && !(this.respawn_time < this.respawn_time_max))
2135                                                 this.deadflag = DEAD_RESPAWNING;
2136                                         else if (!button_pressed || (time >= this.respawn_time_max && (this.respawn_flags & RESPAWN_FORCE)))
2137                                                 this.deadflag = DEAD_DEAD;
2138                                         break;
2139                                 }
2140                                 case DEAD_DEAD:
2141                                 {
2142                                         if (button_pressed)
2143                                                 this.deadflag = DEAD_RESPAWNABLE;
2144                                         else if (time >= this.respawn_time_max && (this.respawn_flags & RESPAWN_FORCE))
2145                                                 this.deadflag = DEAD_RESPAWNING;
2146                                         break;
2147                                 }
2148                                 case DEAD_RESPAWNABLE:
2149                                 {
2150                                         if (!button_pressed || (this.respawn_flags & RESPAWN_FORCE))
2151                                                 this.deadflag = DEAD_RESPAWNING;
2152                                         break;
2153                                 }
2154                                 case DEAD_RESPAWNING:
2155                                 {
2156                                         if (time > this.respawn_time)
2157                                         {
2158                                                 this.respawn_time = time + 1; // only retry once a second
2159                                                 this.respawn_time_max = this.respawn_time;
2160                                                 respawn(this);
2161                                         }
2162                                         break;
2163                                 }
2164                         }
2165
2166                         ShowRespawnCountdown(this);
2167
2168                         if (this.respawn_flags & RESPAWN_SILENT)
2169                                 STAT(RESPAWN_TIME, this) = 0;
2170                         else if ((this.respawn_flags & RESPAWN_FORCE) && this.respawn_time < this.respawn_time_max)
2171                         {
2172                                 if (time < this.respawn_time)
2173                                         STAT(RESPAWN_TIME, this) = this.respawn_time;
2174                                 else if (this.deadflag != DEAD_RESPAWNING)
2175                                         STAT(RESPAWN_TIME, this) = -this.respawn_time_max;
2176                         }
2177                         else
2178                                 STAT(RESPAWN_TIME, this) = this.respawn_time;
2179                 }
2180
2181                 // if respawning, invert stat_respawn_time to indicate this, the client translates it
2182                 if (this.deadflag == DEAD_RESPAWNING && STAT(RESPAWN_TIME, this) > 0)
2183                         STAT(RESPAWN_TIME, this) *= -1;
2184
2185                 return false;
2186         }
2187
2188         FixPlayermodel(this);
2189
2190         if (this.shootfromfixedorigin != autocvar_g_shootfromfixedorigin) {
2191                 this.shootfromfixedorigin = autocvar_g_shootfromfixedorigin;
2192                 stuffcmd(this, sprintf("\ncl_shootfromfixedorigin \"%s\"\n", autocvar_g_shootfromfixedorigin));
2193         }
2194
2195         // reset gun alignment when dual wielding status changes
2196         // to ensure guns are always aligned right and left
2197         bool dualwielding = W_DualWielding(this);
2198         if(this.dualwielding_prev != dualwielding)
2199         {
2200                 W_ResetGunAlign(this, CS(this).cvar_cl_gunalign);
2201                 this.dualwielding_prev = dualwielding;
2202         }
2203
2204         // LordHavoc: allow firing on move frames (sub-ticrate), this gives better timing on slow servers
2205         //if(frametime)
2206         {
2207                 this.items &= ~this.items_added;
2208
2209                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2210                 {
2211                         .entity weaponentity = weaponentities[slot];
2212                         if(WEP_CVAR(vortex, charge_always))
2213                                 W_Vortex_Charge(this, weaponentity, frametime);
2214                         W_WeaponFrame(this, weaponentity);
2215                 }
2216
2217                 this.items_added = 0;
2218                 if ((this.items & ITEM_Jetpack.m_itemid) && ((this.items & ITEM_JetpackRegen.m_itemid) || GetResource(this, RES_FUEL) >= 0.01))
2219             this.items_added |= IT_FUEL;
2220
2221                 this.items |= this.items_added;
2222         }
2223
2224         if (frametime)
2225         {
2226                 // WEAPONTODO: Add a weapon request for this
2227                 // rot vortex charge to the charge limit
2228                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2229                 {
2230                         .entity weaponentity = weaponentities[slot];
2231                         if (WEP_CVAR(vortex, charge_rot_rate) && this.(weaponentity).vortex_charge > WEP_CVAR(vortex, charge_limit) && this.(weaponentity).vortex_charge_rottime < time)
2232                                 this.(weaponentity).vortex_charge = bound(WEP_CVAR(vortex, charge_limit), this.(weaponentity).vortex_charge - WEP_CVAR(vortex, charge_rot_rate) * frametime / W_TICSPERFRAME, 1);
2233                 }
2234
2235                 player_regen(this);
2236                 player_anim(this);
2237                 this.dmg_team = max(0, this.dmg_team - autocvar_g_teamdamage_resetspeed * frametime);
2238         }
2239
2240         secrets_setstatus(this);
2241         monsters_setstatus(this);
2242
2243         return true;
2244 }
2245
2246 .bool would_spectate;
2247 void ObserverThink(entity this)
2248 {
2249         if ( CS(this).impulse )
2250         {
2251                 MinigameImpulse(this, CS(this).impulse);
2252                 CS(this).impulse = 0;
2253         }
2254
2255         if (this.flags & FL_JUMPRELEASED) {
2256                 if (PHYS_INPUT_BUTTON_JUMP(this) && joinAllowed(this)) {
2257                         this.flags &= ~FL_JUMPRELEASED;
2258                         this.flags |= FL_SPAWNING;
2259                 } else if(PHYS_INPUT_BUTTON_ATCK(this) && !CS(this).version_mismatch || this.would_spectate) {
2260                         this.flags &= ~FL_JUMPRELEASED;
2261                         if(SpectateNext(this)) {
2262                                 TRANSMUTE(Spectator, this);
2263                         }
2264                 } else {
2265                         int preferred_movetype = ((!PHYS_INPUT_BUTTON_USE(this) ? CS(this).cvar_cl_clippedspectating : !CS(this).cvar_cl_clippedspectating) ? MOVETYPE_FLY_WORLDONLY : MOVETYPE_NOCLIP);
2266                         set_movetype(this, preferred_movetype);
2267                 }
2268         } else {
2269                 if (!(PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_JUMP(this))) {
2270                         this.flags |= FL_JUMPRELEASED;
2271                         if(this.flags & FL_SPAWNING)
2272                         {
2273                                 this.flags &= ~FL_SPAWNING;
2274                                 if(joinAllowed(this))
2275                                         Join(this);
2276                                 return;
2277                         }
2278                 }
2279         }
2280 }
2281
2282 void SpectatorThink(entity this)
2283 {
2284         if ( CS(this).impulse )
2285         {
2286                 if(MinigameImpulse(this, CS(this).impulse))
2287                         CS(this).impulse = 0;
2288
2289                 if (CS(this).impulse == IMP_weapon_drop.impulse)
2290                 {
2291                         STAT(CAMERA_SPECTATOR, this) = (STAT(CAMERA_SPECTATOR, this) + 1) % 3;
2292                         CS(this).impulse = 0;
2293                         return;
2294                 }
2295         }
2296
2297         if (this.flags & FL_JUMPRELEASED) {
2298                 if (PHYS_INPUT_BUTTON_JUMP(this) && joinAllowed(this)) {
2299                         this.flags &= ~FL_JUMPRELEASED;
2300                         this.flags |= FL_SPAWNING;
2301                 } else if(PHYS_INPUT_BUTTON_ATCK(this) || CS(this).impulse == 10 || CS(this).impulse == 15 || CS(this).impulse == 18 || (CS(this).impulse >= 200 && CS(this).impulse <= 209)) {
2302                         this.flags &= ~FL_JUMPRELEASED;
2303                         if(SpectateNext(this)) {
2304                                 TRANSMUTE(Spectator, this);
2305                         } else {
2306                                 TRANSMUTE(Observer, this);
2307                                 PutClientInServer(this);
2308                         }
2309                         CS(this).impulse = 0;
2310                 } else if(CS(this).impulse == 12 || CS(this).impulse == 16  || CS(this).impulse == 19 || (CS(this).impulse >= 220 && CS(this).impulse <= 229)) {
2311                         this.flags &= ~FL_JUMPRELEASED;
2312                         if(SpectatePrev(this)) {
2313                                 TRANSMUTE(Spectator, this);
2314                         } else {
2315                                 TRANSMUTE(Observer, this);
2316                                 PutClientInServer(this);
2317                         }
2318                         CS(this).impulse = 0;
2319                 } else if (PHYS_INPUT_BUTTON_ATCK2(this)) {
2320                         this.would_spectate = false;
2321                         this.flags &= ~FL_JUMPRELEASED;
2322                         TRANSMUTE(Observer, this);
2323                         PutClientInServer(this);
2324                 } else {
2325                         if(!SpectateUpdate(this))
2326                         {
2327                                 if(!SpectateNext(this))
2328                                 {
2329                                         PutObserverInServer(this);
2330                                         this.would_spectate = true;
2331                                 }
2332                         }
2333                 }
2334         } else {
2335                 if (!(PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_ATCK2(this))) {
2336                         this.flags |= FL_JUMPRELEASED;
2337                         if(this.flags & FL_SPAWNING)
2338                         {
2339                                 this.flags &= ~FL_SPAWNING;
2340                                 Join(this);
2341                                 return;
2342                         }
2343                 }
2344                 if(!SpectateUpdate(this))
2345                         PutObserverInServer(this);
2346         }
2347
2348         this.flags |= FL_CLIENT | FL_NOTARGET;
2349 }
2350
2351 void PlayerUseKey(entity this)
2352 {
2353         if (!IS_PLAYER(this))
2354                 return;
2355
2356         if(this.vehicle)
2357         {
2358                 if(!game_stopped)
2359                 {
2360                         vehicles_exit(this.vehicle, VHEF_NORMAL);
2361                         return;
2362                 }
2363         }
2364         else if(autocvar_g_vehicles_enter)
2365         {
2366                 if(!game_stopped && !STAT(FROZEN, this) && !IS_DEAD(this) && !IS_INDEPENDENT_PLAYER(this))
2367                 {
2368                         entity head, closest_target = NULL;
2369                         head = WarpZone_FindRadius(this.origin, autocvar_g_vehicles_enter_radius, true);
2370
2371                         while(head) // find the closest acceptable target to enter
2372                         {
2373                                 if(IS_VEHICLE(head) && !IS_DEAD(head) && head.takedamage != DAMAGE_NO)
2374                                 if(!head.owner || ((head.vehicle_flags & VHF_MULTISLOT) && SAME_TEAM(head.owner, this)))
2375                                 {
2376                                         if(closest_target)
2377                                         {
2378                                                 if(vlen2(this.origin - head.origin) < vlen2(this.origin - closest_target.origin))
2379                                                 { closest_target = head; }
2380                                         }
2381                                         else { closest_target = head; }
2382                                 }
2383
2384                                 head = head.chain;
2385                         }
2386
2387                         if(closest_target) { vehicles_enter(this, closest_target); return; }
2388                 }
2389         }
2390
2391         // a use key was pressed; call handlers
2392         MUTATOR_CALLHOOK(PlayerUseKey, this);
2393 }
2394
2395
2396 /*
2397 =============
2398 PlayerPreThink
2399
2400 Called every frame for each client before the physics are run
2401 =============
2402 */
2403 .float last_vehiclecheck;
2404 void PlayerPreThink (entity this)
2405 {
2406         STAT(GUNALIGN, this) = CS(this).cvar_cl_gunalign; // TODO
2407         STAT(MOVEVARS_CL_TRACK_CANJUMP, this) = CS(this).cvar_cl_movement_track_canjump;
2408
2409         WarpZone_PlayerPhysics_FixVAngle(this);
2410
2411         if (frametime) {
2412                 // physics frames: update anticheat stuff
2413                 anticheat_prethink(this);
2414         }
2415
2416         if (blockSpectators && frametime) {
2417                 // WORKAROUND: only use dropclient in server frames (frametime set).
2418                 // Never use it in cl_movement frames (frametime zero).
2419                 checkSpectatorBlock(this);
2420         }
2421
2422         zoomstate_set = false;
2423
2424         // Check for nameless players
2425         if (this.netname == "" || this.netname != CS(this).netname_previous)
2426         {
2427                 bool assume_unchanged = (CS(this).netname_previous == "");
2428                 if (autocvar_sv_name_maxlength > 0 && strlennocol(this.netname) > autocvar_sv_name_maxlength)
2429                 {
2430                         int new_length = textLengthUpToLength(this.netname, autocvar_sv_name_maxlength, strlennocol);
2431                         this.netname = strzone(strcat(substring(this.netname, 0, new_length), "^7"));
2432                         sprint(this, sprintf("Warning: your name is longer than %d characters, it has been truncated.\n", autocvar_sv_name_maxlength));
2433                         assume_unchanged = false;
2434                         // stuffcmd(this, strcat("name ", this.netname, "\n")); // maybe?
2435                 }
2436                 if (isInvisibleString(this.netname))
2437                 {
2438                         this.netname = strzone(sprintf("Player#%d", this.playerid));
2439                         sprint(this, "Warning: invisible names are not allowed.\n");
2440                         assume_unchanged = false;
2441                         // stuffcmd(this, strcat("name ", this.netname, "\n")); // maybe?
2442                 }
2443                 if (!assume_unchanged && autocvar_sv_eventlog)
2444                         GameLogEcho(strcat(":name:", ftos(this.playerid), ":", playername(this, false)));
2445                 strcpy(CS(this).netname_previous, this.netname);
2446         }
2447
2448         // version nagging
2449         if (CS(this).version_nagtime && CS(this).cvar_g_xonoticversion && time > CS(this).version_nagtime) {
2450         CS(this).version_nagtime = 0;
2451         if (strstrofs(CS(this).cvar_g_xonoticversion, "git", 0) >= 0 || strstrofs(CS(this).cvar_g_xonoticversion, "autobuild", 0) >= 0) {
2452             // git client
2453         } else if (strstrofs(autocvar_g_xonoticversion, "git", 0) >= 0 || strstrofs(autocvar_g_xonoticversion, "autobuild", 0) >= 0) {
2454             // git server
2455             Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_BETA, autocvar_g_xonoticversion, CS(this).cvar_g_xonoticversion);
2456         } else {
2457             int r = vercmp(CS(this).cvar_g_xonoticversion, autocvar_g_xonoticversion);
2458             if (r < 0) { // old client
2459                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_OUTDATED, autocvar_g_xonoticversion, CS(this).cvar_g_xonoticversion);
2460             } else if (r > 0) { // old server
2461                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_OLD, autocvar_g_xonoticversion, CS(this).cvar_g_xonoticversion);
2462             }
2463         }
2464     }
2465
2466         // GOD MODE info
2467         if (!(this.flags & FL_GODMODE) && this.max_armorvalue)
2468         {
2469                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_GODMODE_OFF, this.max_armorvalue);
2470                 this.max_armorvalue = 0;
2471         }
2472
2473         if (frametime && IS_PLAYER(this))
2474         {
2475                 if (STAT(FROZEN, this) == FROZEN_TEMP_REVIVING)
2476                 {
2477                         STAT(REVIVE_PROGRESS, this) = bound(0, STAT(REVIVE_PROGRESS, this) + frametime * this.revive_speed, 1);
2478                         SetResourceExplicit(this, RES_HEALTH, max(1, STAT(REVIVE_PROGRESS, this) * start_health));
2479                         this.iceblock.alpha = bound(0.2, 1 - STAT(REVIVE_PROGRESS, this), 1);
2480
2481                         if (STAT(REVIVE_PROGRESS, this) >= 1)
2482                                 Unfreeze(this, false);
2483                 }
2484                 else if (STAT(FROZEN, this) == FROZEN_TEMP_DYING)
2485                 {
2486                         STAT(REVIVE_PROGRESS, this) = bound(0, STAT(REVIVE_PROGRESS, this) - frametime * this.revive_speed, 1);
2487                         SetResourceExplicit(this, RES_HEALTH, max(0, autocvar_g_nades_ice_health + (start_health-autocvar_g_nades_ice_health) * STAT(REVIVE_PROGRESS, this)));
2488
2489                         if (GetResource(this, RES_HEALTH) < 1)
2490                         {
2491                                 if (this.vehicle)
2492                                         vehicles_exit(this.vehicle, VHEF_RELEASE);
2493                                 if(this.event_damage)
2494                                         this.event_damage(this, this, this.frozen_by, 1, DEATH_NADE_ICE_FREEZE.m_id, DMG_NOWEP, this.origin, '0 0 0');
2495                         }
2496                         else if (STAT(REVIVE_PROGRESS, this) <= 0)
2497                                 Unfreeze(this, false);
2498                 }
2499         }
2500
2501         MUTATOR_CALLHOOK(PlayerPreThink, this);
2502
2503         if(autocvar_g_vehicles_enter && (time > this.last_vehiclecheck) && !game_stopped && !this.vehicle)
2504         if(IS_PLAYER(this) && !STAT(FROZEN, this) && !IS_DEAD(this) && !IS_INDEPENDENT_PLAYER(this))
2505         {
2506                 FOREACH_ENTITY_RADIUS(this.origin, autocvar_g_vehicles_enter_radius, IS_VEHICLE(it) && !IS_DEAD(it) && it.takedamage != DAMAGE_NO,
2507                 {
2508                         if(!it.owner)
2509                         {
2510                                 if(!it.team || SAME_TEAM(this, it))
2511                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER);
2512                                 else if(autocvar_g_vehicles_steal)
2513                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER_STEAL);
2514                         }
2515                         else if((it.vehicle_flags & VHF_MULTISLOT) && SAME_TEAM(it.owner, this))
2516                         {
2517                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER_GUNNER);
2518                         }
2519                 });
2520
2521                 this.last_vehiclecheck = time + 1;
2522         }
2523
2524         if(!CS(this).cvar_cl_newusekeysupported) // FIXME remove this - it was a stupid idea to begin with, we can JUST use the button
2525         {
2526                 if(PHYS_INPUT_BUTTON_USE(this) && !CS(this).usekeypressed)
2527                         PlayerUseKey(this);
2528                 CS(this).usekeypressed = PHYS_INPUT_BUTTON_USE(this);
2529         }
2530
2531         if (IS_REAL_CLIENT(this))
2532                 PrintWelcomeMessage(this);
2533
2534         if (IS_PLAYER(this)) {
2535                 if (IS_REAL_CLIENT(this) && time < CS(this).jointime + MIN_SPEC_TIME)
2536                         error("Client can't be spawned as player on connection!");
2537                 if(!PlayerThink(this))
2538                         return;
2539         }
2540         else if (game_stopped || intermission_running) {
2541                 if(intermission_running)
2542                         IntermissionThink(this);
2543                 return;
2544         }
2545         else if (IS_REAL_CLIENT(this) && !CS(this).autojoin_checked && time >= CS(this).jointime + MIN_SPEC_TIME)
2546         {
2547                 CS(this).autojoin_checked = true;
2548                 // don't do this in ClientConnect
2549                 // many things can go wrong if a client is spawned as player on connection
2550                 if (MUTATOR_CALLHOOK(AutoJoinOnConnection, this)
2551                         || (!(autocvar_sv_spectate || autocvar_g_campaign || (Player_GetForcedTeamIndex(this) == TEAM_FORCE_SPECTATOR))
2552                                 && (!teamplay || autocvar_g_balance_teams)))
2553                 {
2554                         campaign_bots_may_start = true;
2555                         Join(this);
2556                         return;
2557                 }
2558         }
2559         else if (IS_OBSERVER(this)) {
2560                 ObserverThink(this);
2561         }
2562         else if (IS_SPEC(this)) {
2563                 SpectatorThink(this);
2564         }
2565
2566         // WEAPONTODO: Add weapon request for this
2567         if (!zoomstate_set) {
2568                 bool wep_zoomed = false;
2569                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2570                 {
2571                         .entity weaponentity = weaponentities[slot];
2572                         Weapon thiswep = this.(weaponentity).m_weapon;
2573                         if(thiswep != WEP_Null && thiswep.wr_zoom)
2574                                 wep_zoomed += thiswep.wr_zoom(thiswep, this);
2575                 }
2576                 SetZoomState(this, PHYS_INPUT_BUTTON_ZOOM(this) || PHYS_INPUT_BUTTON_ZOOMSCRIPT(this) || wep_zoomed);
2577     }
2578
2579         if (CS(this).teamkill_soundtime && time > CS(this).teamkill_soundtime)
2580         {
2581                 CS(this).teamkill_soundtime = 0;
2582
2583                 entity e = CS(this).teamkill_soundsource;
2584                 entity oldpusher = e.pusher;
2585                 e.pusher = this;
2586                 PlayerSound(e, playersound_teamshoot, CH_VOICE, VOL_BASEVOICE, VOICETYPE_LASTATTACKER_ONLY);
2587                 e.pusher = oldpusher;
2588         }
2589
2590         if (CS(this).taunt_soundtime && time > CS(this).taunt_soundtime) {
2591                 CS(this).taunt_soundtime = 0;
2592                 PlayerSound(this, playersound_taunt, CH_VOICE, VOL_BASEVOICE, VOICETYPE_AUTOTAUNT);
2593         }
2594
2595         target_voicescript_next(this);
2596
2597         // WEAPONTODO: Move into weaponsystem somehow
2598         // if a player goes unarmed after holding a loaded weapon, empty his clip size and remove the crosshair ammo ring
2599         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2600         {
2601                 .entity weaponentity = weaponentities[slot];
2602                 if(this.(weaponentity).m_weapon == WEP_Null)
2603                         this.(weaponentity).clip_load = this.(weaponentity).clip_size = 0;
2604         }
2605 }
2606
2607 void DrownPlayer(entity this)
2608 {
2609         if(IS_DEAD(this) || game_stopped || time < game_starttime || this.vehicle
2610                 || STAT(FROZEN, this) || this.watertype != CONTENT_WATER)
2611         {
2612                 this.air_finished = 0;
2613                 return;
2614         }
2615
2616         if (this.waterlevel != WATERLEVEL_SUBMERGED)
2617         {
2618                 if(this.air_finished && this.air_finished < time)
2619                         PlayerSound(this, playersound_gasp, CH_PLAYER, VOL_BASE, VOICETYPE_PLAYERSOUND);
2620                 this.air_finished = 0;
2621         }
2622         else
2623         {
2624                 if (!this.air_finished)
2625                         this.air_finished = time + autocvar_g_balance_contents_drowndelay;
2626                 if (this.air_finished < time)
2627                 {       // drown!
2628                         if (this.pain_finished < time)
2629                         {
2630                                 Damage (this, NULL, NULL, autocvar_g_balance_contents_playerdamage_drowning * autocvar_g_balance_contents_damagerate, DEATH_DROWN.m_id, DMG_NOWEP, this.origin, '0 0 0');
2631                                 this.pain_finished = time + 0.5;
2632                         }
2633                 }
2634         }
2635 }
2636
2637 .bool move_qcphysics;
2638
2639 void Player_Physics(entity this)
2640 {
2641         this.movetype = (this.move_qcphysics) ? MOVETYPE_QCPLAYER : this.move_movetype;
2642
2643         if(!this.move_qcphysics)
2644                 return;
2645
2646         if(!frametime && !CS(this).pm_frametime)
2647                 return;
2648
2649         Movetype_Physics_NoMatchTicrate(this, CS(this).pm_frametime, true);
2650
2651         CS(this).pm_frametime = 0;
2652 }
2653
2654 /*
2655 =============
2656 PlayerPostThink
2657
2658 Called every frame for each client after the physics are run
2659 =============
2660 */
2661 void PlayerPostThink (entity this)
2662 {
2663         Player_Physics(this);
2664
2665         if (sv_maxidle > 0)
2666         if (frametime) // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2667         if (IS_REAL_CLIENT(this))
2668         if (IS_PLAYER(this) || sv_maxidle_spectatorsareidle)
2669         {
2670                 int totalClients = 0;
2671                 if(sv_maxidle_slots > 0)
2672                 {
2673                         FOREACH_CLIENT(IS_REAL_CLIENT(it) || sv_maxidle_slots_countbots,
2674                         {
2675                                 ++totalClients;
2676                         });
2677                 }
2678
2679                 if (sv_maxidle_slots > 0 && (maxclients - totalClients) > sv_maxidle_slots)
2680                 { /* do nothing */ }
2681                 else if (time - CS(this).parm_idlesince < 1) // instead of (time == this.parm_idlesince) to support sv_maxidle <= 10
2682                 {
2683                         if (CS(this).idlekick_lasttimeleft)
2684                         {
2685                                 CS(this).idlekick_lasttimeleft = 0;
2686                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_IDLING);
2687                         }
2688                 }
2689                 else
2690                 {
2691                         float timeleft = ceil(sv_maxidle - (time - CS(this).parm_idlesince));
2692                         if (timeleft == min(10, sv_maxidle - 1)) { // - 1 to support sv_maxidle <= 10
2693                                 if (!CS(this).idlekick_lasttimeleft)
2694                                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_DISCONNECT_IDLING, timeleft);
2695                         }
2696                         if (timeleft <= 0) {
2697                                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_QUIT_KICK_IDLING, this.netname);
2698                                 dropclient(this);
2699                                 return;
2700                         }
2701                         else if (timeleft <= 10) {
2702                                 if (timeleft != CS(this).idlekick_lasttimeleft) {
2703                                     Send_Notification(NOTIF_ONE, this, MSG_ANNCE, Announcer_PickNumber(CNT_IDLE, timeleft));
2704                 }
2705                                 CS(this).idlekick_lasttimeleft = timeleft;
2706                         }
2707                 }
2708         }
2709
2710         CheatFrame(this);
2711
2712         if (game_stopped)
2713         {
2714                 this.solid = SOLID_NOT;
2715                 this.takedamage = DAMAGE_NO;
2716                 set_movetype(this, MOVETYPE_NONE);
2717         }
2718
2719         if (IS_PLAYER(this)) {
2720                 if(this.death_time == time && IS_DEAD(this))
2721                 {
2722                         // player's bbox gets resized now, instead of in the damage event that killed the player,
2723                         // once all the damage events of this frame have been processed with normal size
2724                         this.maxs.z = 5;
2725                         setsize(this, this.mins, this.maxs);
2726                 }
2727                 DrownPlayer(this);
2728                 UpdateChatBubble(this);
2729                 if (CS(this).impulse) ImpulseCommands(this);
2730                 if (game_stopped)
2731                 {
2732                         CSQCMODEL_AUTOUPDATE(this);
2733                         return;
2734                 }
2735                 GetPressedKeys(this);
2736         }
2737         else if (IS_OBSERVER(this) && STAT(PRESSED_KEYS, this))
2738         {
2739                 CS(this).pressedkeys = 0;
2740                 STAT(PRESSED_KEYS, this) = 0;
2741         }
2742
2743         if (this.waypointsprite_attachedforcarrier) {
2744                 float hp = healtharmor_maxdamage(GetResource(this, RES_HEALTH), GetResource(this, RES_ARMOR), autocvar_g_balance_armor_blockpercent, DEATH_WEAPON.m_id).x;
2745                 WaypointSprite_UpdateHealth(this.waypointsprite_attachedforcarrier, hp);
2746         }
2747
2748         CSQCMODEL_AUTOUPDATE(this);
2749 }
2750
2751 /**
2752  * message "": do not say, just test flood control
2753  * return value:
2754  *   1 = accept
2755  *   0 = reject
2756  *  -1 = fake accept
2757  */
2758 int Say(entity source, int teamsay, entity privatesay, string msgin, bool floodcontrol)
2759 {
2760         if (!teamsay && !privatesay && substring(msgin, 0, 1) == " ")
2761                 msgin = substring(msgin, 1, -1); // work around DP say bug (say_team does not have this!)
2762
2763         if (source)
2764                 msgin = formatmessage(source, msgin);
2765
2766         string colorstr;
2767         if (!(IS_PLAYER(source) || source.caplayer))
2768                 colorstr = "^0"; // black for spectators
2769         else if(teamplay)
2770                 colorstr = Team_ColorCode(source.team);
2771         else
2772         {
2773                 colorstr = "";
2774                 teamsay = false;
2775         }
2776
2777         if (!source) {
2778                 colorstr = "";
2779                 teamsay = false;
2780         }
2781
2782         if(msgin != "")
2783                 msgin = trigger_magicear_processmessage_forallears(source, teamsay, privatesay, msgin);
2784
2785         /*
2786          * using bprint solves this... me stupid
2787         // how can we prevent the message from appearing in a listen server?
2788         // for now, just give "say" back and only handle say_team
2789         if(!teamsay)
2790         {
2791                 clientcommand(source, strcat("say ", msgin));
2792                 return;
2793         }
2794         */
2795
2796         string namestr = "";
2797         if (source)
2798                 namestr = playername(source, autocvar_g_chat_teamcolors);
2799
2800         string colorprefix = (strdecolorize(namestr) == namestr) ? "^3" : "^7";
2801
2802         string msgstr = "", cmsgstr = "";
2803         string privatemsgprefix = string_null;
2804         int privatemsgprefixlen = 0;
2805         if (msgin != "")
2806         {
2807                 bool found_me = false;
2808                 if(strstrofs(msgin, "/me", 0) >= 0)
2809                 {
2810                         string newmsgin = "";
2811                         string newnamestr = ((teamsay) ? strcat(colorstr, "(", colorprefix, namestr, colorstr, ")", "^7") : strcat(colorprefix, namestr, "^7"));
2812                         FOREACH_WORD(msgin, true,
2813                         {
2814                                 if(strdecolorize(it) == "/me")
2815                                 {
2816                                         found_me = true;
2817                                         newmsgin = cons(newmsgin, newnamestr);
2818                                 }
2819                                 else
2820                                         newmsgin = cons(newmsgin, it);
2821                         });
2822                         msgin = newmsgin;
2823                 }
2824
2825                 if(privatesay)
2826                 {
2827                         msgstr = strcat("\{1}\{13}* ", colorprefix, namestr, "^3 tells you: ^7");
2828                         privatemsgprefixlen = strlen(msgstr);
2829                         msgstr = strcat(msgstr, msgin);
2830                         cmsgstr = strcat(colorstr, colorprefix, namestr, "^3 tells you:\n^7", msgin);
2831                         privatemsgprefix = strcat("\{1}\{13}* ^3You tell ", playername(privatesay, autocvar_g_chat_teamcolors), ": ^7");
2832                 }
2833                 else if(teamsay)
2834                 {
2835                         if(found_me)
2836                         {
2837                                 //msgin = strreplace("/me", "", msgin);
2838                                 //msgin = substring(msgin, 3, strlen(msgin));
2839                                 //msgin = strreplace("/me", strcat(colorstr, "(", colorprefix, namestr, colorstr, ")^7"), msgin);
2840                                 msgstr = strcat("\{1}\{13}^4* ", "^7", msgin);
2841                         }
2842                         else
2843                                 msgstr = strcat("\{1}\{13}", colorstr, "(", colorprefix, namestr, colorstr, ") ^7", msgin);
2844                         cmsgstr = strcat(colorstr, "(", colorprefix, namestr, colorstr, ")\n^7", msgin);
2845                 }
2846                 else
2847                 {
2848                         if(found_me)
2849                         {
2850                                 //msgin = strreplace("/me", "", msgin);
2851                                 //msgin = substring(msgin, 3, strlen(msgin));
2852                                 //msgin = strreplace("/me", strcat(colorprefix, namestr), msgin);
2853                                 msgstr = strcat("\{1}^4* ^7", msgin);
2854                         }
2855                         else {
2856                                 msgstr = "\{1}";
2857                                 msgstr = strcat(msgstr, (namestr != "") ? strcat(colorprefix, namestr, "^7: ") : "^7");
2858                                 msgstr = strcat(msgstr, msgin);
2859                         }
2860                         cmsgstr = "";
2861                 }
2862                 msgstr = strcat(strreplace("\n", " ", msgstr), "\n"); // newlines only are good for centerprint
2863         }
2864
2865         string fullmsgstr = msgstr;
2866         string fullcmsgstr = cmsgstr;
2867
2868         // FLOOD CONTROL
2869         int flood = 0;
2870         var .float flood_field = floodcontrol_chat;
2871         if(floodcontrol && source)
2872         {
2873                 float flood_spl;
2874                 float flood_burst;
2875                 float flood_lmax;
2876                 float lines;
2877                 if(privatesay)
2878                 {
2879                         flood_spl = autocvar_g_chat_flood_spl_tell;
2880                         flood_burst = autocvar_g_chat_flood_burst_tell;
2881                         flood_lmax = autocvar_g_chat_flood_lmax_tell;
2882                         flood_field = floodcontrol_chattell;
2883                 }
2884                 else if(teamsay)
2885                 {
2886                         flood_spl = autocvar_g_chat_flood_spl_team;
2887                         flood_burst = autocvar_g_chat_flood_burst_team;
2888                         flood_lmax = autocvar_g_chat_flood_lmax_team;
2889                         flood_field = floodcontrol_chatteam;
2890                 }
2891                 else
2892                 {
2893                         flood_spl = autocvar_g_chat_flood_spl;
2894                         flood_burst = autocvar_g_chat_flood_burst;
2895                         flood_lmax = autocvar_g_chat_flood_lmax;
2896                         flood_field = floodcontrol_chat;
2897                 }
2898                 flood_burst = max(0, flood_burst - 1);
2899                 // to match explanation in default.cfg, a value of 3 must allow three-line bursts and not four!
2900
2901                 // do flood control for the default line size
2902                 if(msgstr != "")
2903                 {
2904                         getWrappedLine_remaining = msgstr;
2905                         msgstr = "";
2906                         lines = 0;
2907                         while(getWrappedLine_remaining && (!flood_lmax || lines <= flood_lmax))
2908                         {
2909                                 msgstr = strcat(msgstr, " ", getWrappedLineLen(82.4289758859709, strlennocol)); // perl averagewidth.pl < gfx/vera-sans.width
2910                                 ++lines;
2911                         }
2912                         msgstr = substring(msgstr, 1, strlen(msgstr) - 1);
2913
2914                         if(getWrappedLine_remaining != "")
2915                         {
2916                                 msgstr = strcat(msgstr, "\n");
2917                                 flood = 2;
2918                         }
2919
2920                         if (time >= source.(flood_field))
2921                         {
2922                                 source.(flood_field) = max(time - flood_burst * flood_spl, source.(flood_field)) + lines * flood_spl;
2923                         }
2924                         else
2925                         {
2926                                 flood = 1;
2927                                 msgstr = fullmsgstr;
2928                         }
2929                 }
2930                 else
2931                 {
2932                         if (time >= source.(flood_field))
2933                                 source.(flood_field) = max(time - flood_burst * flood_spl, source.(flood_field)) + flood_spl;
2934                         else
2935                                 flood = 1;
2936                 }
2937
2938                 if (timeout_status == TIMEOUT_ACTIVE) // when game is paused, no flood protection
2939                         source.(flood_field) = flood = 0;
2940         }
2941
2942         string sourcemsgstr, sourcecmsgstr;
2943         if(flood == 2) // cannot happen for empty msgstr
2944         {
2945                 if(autocvar_g_chat_flood_notify_flooder)
2946                 {
2947                         sourcemsgstr = strcat(msgstr, "\n^3FLOOD CONTROL: ^7message too long, trimmed\n");
2948                         sourcecmsgstr = "";
2949                 }
2950                 else
2951                 {
2952                         sourcemsgstr = fullmsgstr;
2953                         sourcecmsgstr = fullcmsgstr;
2954                 }
2955                 cmsgstr = "";
2956         }
2957         else
2958         {
2959                 sourcemsgstr = msgstr;
2960                 sourcecmsgstr = cmsgstr;
2961         }
2962
2963         if (!privatesay && source && !(IS_PLAYER(source) || source.caplayer))
2964         {
2965                 if (!game_stopped)
2966                 if (teamsay || (autocvar_g_chat_nospectators == 1) || (autocvar_g_chat_nospectators == 2 && !warmup_stage))
2967                         teamsay = -1; // spectators
2968         }
2969
2970         if(flood)
2971                 LOG_INFO("NOTE: ", playername(source, true), "^7 is flooding.");
2972
2973         // build sourcemsgstr by cutting off a prefix and replacing it by the other one
2974         if(privatesay)
2975                 sourcemsgstr = strcat(privatemsgprefix, substring(sourcemsgstr, privatemsgprefixlen, -1));
2976
2977         int ret;
2978         if(source && CS(source).muted)
2979         {
2980                 // always fake the message
2981                 ret = -1;
2982         }
2983         else if(flood == 1)
2984         {
2985                 if (autocvar_g_chat_flood_notify_flooder)
2986                 {
2987                         sprint(source, strcat("^3FLOOD CONTROL: ^7wait ^1", ftos(source.(flood_field) - time), "^3 seconds\n"));
2988                         ret = 0;
2989                 }
2990                 else
2991                         ret = -1;
2992         }
2993         else
2994         {
2995                 ret = 1;
2996         }
2997
2998         if (privatesay && source && !(IS_PLAYER(source) || source.caplayer))
2999         {
3000                 if (!game_stopped)
3001                 if ((privatesay && (IS_PLAYER(privatesay) || privatesay.caplayer)) && ((autocvar_g_chat_nospectators == 1) || (autocvar_g_chat_nospectators == 2 && !warmup_stage)))
3002                         ret = -1; // just hide the message completely
3003         }
3004
3005         MUTATOR_CALLHOOK(ChatMessage, source, ret);
3006         ret = M_ARGV(1, int);
3007
3008         string event_log_msg = "";
3009
3010         if(sourcemsgstr != "" && ret != 0)
3011         {
3012                 if(ret < 0) // faked message, because the player is muted
3013                 {
3014                         sprint(source, sourcemsgstr);
3015                         if(sourcecmsgstr != "" && !privatesay)
3016                                 centerprint(source, sourcecmsgstr);
3017                 }
3018                 else if(privatesay) // private message, between 2 people only
3019                 {
3020                         sprint(source, sourcemsgstr);
3021                         if (!autocvar_g_chat_tellprivacy) { dedicated_print(msgstr); } // send to server console too if "tellprivacy" is disabled
3022                         if(!MUTATOR_CALLHOOK(ChatMessageTo, privatesay, source))
3023                         {
3024                                 sprint(privatesay, msgstr);
3025                                 if(cmsgstr != "")
3026                                         centerprint(privatesay, cmsgstr);
3027                         }
3028                 }
3029                 else if ( teamsay && CS(source).active_minigame )
3030                 {
3031                         sprint(source, sourcemsgstr);
3032                         dedicated_print(msgstr); // send to server console too
3033                         FOREACH_CLIENT(IS_REAL_CLIENT(it) && it != source && CS(it).active_minigame == CS(source).active_minigame && !MUTATOR_CALLHOOK(ChatMessageTo, it, source), {
3034                                 sprint(it, msgstr);
3035                         });
3036                         event_log_msg = sprintf(":chat_minigame:%d:%s:%s", source.playerid, CS(source).active_minigame.netname, msgin);
3037
3038                 }
3039                 else if(teamsay > 0) // team message, only sent to team mates
3040                 {
3041                         sprint(source, sourcemsgstr);
3042                         dedicated_print(msgstr); // send to server console too
3043                         if(sourcecmsgstr != "")
3044                                 centerprint(source, sourcecmsgstr);
3045                         FOREACH_CLIENT((IS_PLAYER(it) || it.caplayer) && IS_REAL_CLIENT(it) && it != source && it.team == source.team && !MUTATOR_CALLHOOK(ChatMessageTo, it, source), {
3046                                 sprint(it, msgstr);
3047                                 if(cmsgstr != "")
3048                                         centerprint(it, cmsgstr);
3049                         });
3050                         event_log_msg = sprintf(":chat_team:%d:%d:%s", source.playerid, source.team, strreplace("\n", " ", msgin));
3051                 }
3052                 else if(teamsay < 0) // spectator message, only sent to spectators
3053                 {
3054                         sprint(source, sourcemsgstr);
3055                         dedicated_print(msgstr); // send to server console too
3056                         FOREACH_CLIENT(!(IS_PLAYER(it) || it.caplayer) && IS_REAL_CLIENT(it) && it != source && !MUTATOR_CALLHOOK(ChatMessageTo, it, source), {
3057                                 sprint(it, msgstr);
3058                         });
3059                         event_log_msg = sprintf(":chat_spec:%d:%s", source.playerid, strreplace("\n", " ", msgin));
3060                 }
3061                 else
3062                 {
3063                         if (source) {
3064                                 sprint(source, sourcemsgstr);
3065                                 dedicated_print(msgstr); // send to server console too
3066                                 MX_Say(strcat(playername(source, true), "^7: ", msgin));
3067                         }
3068                         FOREACH_CLIENT(IS_REAL_CLIENT(it) && it != source && !MUTATOR_CALLHOOK(ChatMessageTo, it, source), {
3069                                 sprint(it, msgstr);
3070                         });
3071                         event_log_msg = sprintf(":chat:%d:%s", source.playerid, strreplace("\n", " ", msgin));
3072                 }
3073         }
3074
3075         if (autocvar_sv_eventlog && (event_log_msg != "")) {
3076                 GameLogEcho(event_log_msg);
3077         }
3078
3079         return ret;
3080 }
3081
3082 // hack to copy the button fields from the client entity to the Client State
3083 void PM_UpdateButtons(entity this, entity store)
3084 {
3085         if(this.impulse)
3086                 store.impulse = this.impulse;
3087         this.impulse = 0;
3088
3089         bool typing = this.buttonchat || this.button12;
3090
3091         store.button0 = (typing) ? 0 : this.button0;
3092         //button1?!
3093         store.button2 = (typing) ? 0 : this.button2;
3094         store.button3 = (typing) ? 0 : this.button3;
3095         store.button4 = this.button4;
3096         store.button5 = (typing) ? 0 : this.button5;
3097         store.button6 = this.button6;
3098         store.button7 = this.button7;
3099         store.button8 = this.button8;
3100         store.button9 = this.button9;
3101         store.button10 = this.button10;
3102         store.button11 = this.button11;
3103         store.button12 = this.button12;
3104         store.button13 = this.button13;
3105         store.button14 = this.button14;
3106         store.button15 = this.button15;
3107         store.button16 = this.button16;
3108         store.buttonuse = this.buttonuse;
3109         store.buttonchat = this.buttonchat;
3110
3111         store.cursor_active = this.cursor_active;
3112         store.cursor_screen = this.cursor_screen;
3113         store.cursor_trace_start = this.cursor_trace_start;
3114         store.cursor_trac