qcsrc/server/client.qc

   1 #include "client.qh"
   2
   3 #include <server/defs.qh>
   4 #include <server/miscfunctions.qh>
   5 #include <common/effects/all.qh>
   6 #include "anticheat.qh"
   7 #include "impulse.qh"
   8 #include "player.qh"
   9 #include "ipban.qh"
  10 #include "miscfunctions.qh"
  11 #include "portals.qh"
  12 #include "teamplay.qh"
  13 #include "playerdemo.qh"
  14 #include "spawnpoints.qh"
  15 #include "resources.qh"
  16 #include "g_damage.qh"
  17 #include "handicap.qh"
  18 #include "g_hook.qh"
  19 #include "command/common.qh"
  20 #include "cheats.qh"
  21 #include "g_world.qh"
  22 #include "race.qh"
  23 #include "antilag.qh"
  24 #include "campaign.qh"
  25 #include "command/common.qh"
  26 #include "scores_rules.qh"
  27
  28 #include "bot/api.qh"
  29
  30 #include "../common/ent_cs.qh"
  31 #include "../common/wepent.qh"
  32 #include <common/state.qh>
  33
  34 #include <common/effects/qc/globalsound.qh>
  35
  36 #include "../common/triggers/func/conveyor.qh"
  37 #include "../common/triggers/teleporters.qh"
  38 #include "../common/triggers/target/spawnpoint.qh"
  39
  40 #include "../common/vehicles/all.qh"
  41
  42 #include "weapons/hitplot.qh"
  43 #include "weapons/weaponsystem.qh"
  44
  45 #include "../common/net_notice.qh"
  46 #include "../common/net_linked.qh"
  47 #include "../common/physics/player.qh"
  48
  49 #include "../common/items/_mod.qh"
  50
  51 #include "../common/mutators/mutator/waypoints/all.qh"
  52
  53 #include "../common/triggers/subs.qh"
  54 #include "../common/triggers/triggers.qh"
  55 #include "../common/triggers/trigger/secret.qh"
  56
  57 #include "../common/minigames/sv_minigames.qh"
  58
  59 #include "../common/items/inventory.qh"
  60
  61 #include "../common/monsters/sv_monsters.qh"
  62
  63 #include "../lib/warpzone/server.qh"
  64
  65 STATIC_METHOD(Client, Add, void(Client this, int _team))
  66 {
  67     ClientConnect(this);
  68     TRANSMUTE(Player, this);
  69     this.frame = 12; // 7
  70     this.team = _team;
  71     PutClientInServer(this);
  72 }
  73
  74 void PutObserverInServer(entity this);
  75
  76 STATIC_METHOD(Client, Remove, void(Client this))
  77 {
  78     TRANSMUTE(Observer, this);
  79     PutClientInServer(this);
  80     ClientDisconnect(this);
  81 }
  82
  83 void send_CSQC_teamnagger() {
  84         WriteHeader(MSG_BROADCAST, TE_CSQC_TEAMNAGGER);
  85 }
  86
  87 int CountSpectators(entity player, entity to)
  88 {
  89         if(!player) { return 0; } // not sure how, but best to be safe
  90
  91         int spec_count = 0;
  92
  93         FOREACH_CLIENT(IS_REAL_CLIENT(it) && IS_SPEC(it) && it != to && it.enemy == player,
  94         {
  95                 spec_count++;
  96         });
  97
  98         return spec_count;
  99 }
 100
 101 void WriteSpectators(entity player, entity to)
 102 {
 103         if(!player) { return; } // not sure how, but best to be safe
 104
 105         FOREACH_CLIENT(IS_REAL_CLIENT(it) && IS_SPEC(it) && it != to && it.enemy == player,
 106         {
 107                 WriteByte(MSG_ENTITY, num_for_edict(it));
 108         });
 109 }
 110
 111 bool ClientData_Send(entity this, entity to, int sf)
 112 {
 113         assert(to == this.owner, return false);
 114
 115         entity e = to;
 116         if (IS_SPEC(e)) e = e.enemy;
 117
 118         sf = 0;
 119         if (CS(e).race_completed)       sf |= BIT(0); // forced scoreboard
 120         if (CS(to).spectatee_status)    sf |= BIT(1); // spectator ent number follows
 121         if (CS(e).zoomstate)            sf |= BIT(2); // zoomed
 122         if (autocvar_sv_showspectators) sf |= BIT(4); // show spectators
 123
 124         WriteHeader(MSG_ENTITY, ENT_CLIENT_CLIENTDATA);
 125         WriteByte(MSG_ENTITY, sf);
 126
 127         if (sf & BIT(1))
 128                 WriteByte(MSG_ENTITY, CS(to).spectatee_status);
 129
 130         if(sf & BIT(4))
 131         {
 132                 float specs = CountSpectators(e, to);
 133                 WriteByte(MSG_ENTITY, specs);
 134                 WriteSpectators(e, to);
 135         }
 136
 137         return true;
 138 }
 139
 140 void ClientData_Attach(entity this)
 141 {
 142         Net_LinkEntity(CS(this).clientdata = new_pure(clientdata), false, 0, ClientData_Send);
 143         CS(this).clientdata.drawonlytoclient = this;
 144         CS(this).clientdata.owner = this;
 145 }
 146
 147 void ClientData_Detach(entity this)
 148 {
 149         delete(CS(this).clientdata);
 150         CS(this).clientdata = NULL;
 151 }
 152
 153 void ClientData_Touch(entity e)
 154 {
 155         CS(e).clientdata.SendFlags = 1;
 156
 157         // make it spectatable
 158         FOREACH_CLIENT(IS_REAL_CLIENT(it) && it != e && IS_SPEC(it) && it.enemy == e, { CS(it).clientdata.SendFlags = 1; });
 159 }
 160
 161 void SetSpectatee(entity this, entity spectatee);
 162 void SetSpectatee_status(entity this, int spectatee_num);
 163
 164
 165 /*
 166 =============
 167 CheckPlayerModel
 168
 169 Checks if the argument string can be a valid playermodel.
 170 Returns a valid one in doubt.
 171 =============
 172 */
 173 string FallbackPlayerModel;
 174 string CheckPlayerModel(string plyermodel) {
 175         if(FallbackPlayerModel != cvar_defstring("_cl_playermodel"))
 176         {
 177                 // note: we cannot summon Don Strunzone here, some player may
 178                 // still have the model string set. In case anyone manages how
 179                 // to change a cvar default, we'll have a small leak here.
 180                 FallbackPlayerModel = strzone(cvar_defstring("_cl_playermodel"));
 181         }
 182         // only in right path
 183         if( substring(plyermodel,0,14) != "models/player/")
 184                 return FallbackPlayerModel;
 185         // only good file extensions
 186         if(substring(plyermodel,-4,4) != ".zym")
 187         if(substring(plyermodel,-4,4) != ".dpm")
 188         if(substring(plyermodel,-4,4) != ".iqm")
 189         if(substring(plyermodel,-4,4) != ".md3")
 190         if(substring(plyermodel,-4,4) != ".psk")
 191                 return FallbackPlayerModel;
 192         // forbid the LOD models
 193         if(substring(plyermodel, -9,5) == "_lod1")
 194                 return FallbackPlayerModel;
 195         if(substring(plyermodel, -9,5) == "_lod2")
 196                 return FallbackPlayerModel;
 197         if(plyermodel != strtolower(plyermodel))
 198                 return FallbackPlayerModel;
 199         // also, restrict to server models
 200         if(autocvar_sv_servermodelsonly)
 201         {
 202                 if(!fexists(plyermodel))
 203                         return FallbackPlayerModel;
 204         }
 205         return plyermodel;
 206 }
 207
 208 void setplayermodel(entity e, string modelname)
 209 {
 210         precache_model(modelname);
 211         _setmodel(e, modelname);
 212         player_setupanimsformodel(e);
 213         if(!autocvar_g_debug_globalsounds)
 214                 UpdatePlayerSounds(e);
 215 }
 216
 217 void FixPlayermodel(entity player);
 218 /** putting a client as observer in the server */
 219 void PutObserverInServer(entity this)
 220 {
 221     bool mutator_returnvalue = MUTATOR_CALLHOOK(MakePlayerObserver, this);
 222         PlayerState_detach(this);
 223
 224         if (IS_PLAYER(this))
 225         {
 226                 if(this.health >= 1)
 227                 {
 228                         // despawn effect
 229                         Send_Effect(EFFECT_SPAWN_NEUTRAL, this.origin, '0 0 0', 1);
 230                 }
 231
 232                 // was a player, recount votes and ready status
 233                 if(IS_REAL_CLIENT(this))
 234                 {
 235                         if (vote_called) { VoteCount(false); }
 236                         ReadyCount();
 237                 }
 238     }
 239
 240     {
 241         entity spot = SelectSpawnPoint(this, true);
 242         if (!spot) LOG_FATAL("No spawnpoints for observers?!?");
 243         this.angles = vec2(spot.angles);
 244         this.fixangle = true;
 245         // offset it so that the spectator spawns higher off the ground, looks better this way
 246         setorigin(this, spot.origin + STAT(PL_VIEW_OFS, this));
 247         if (IS_REAL_CLIENT(this))
 248         {
 249             msg_entity = this;
 250             WriteByte(MSG_ONE, SVC_SETVIEW);
 251             WriteEntity(MSG_ONE, this);
 252         }
 253         // give the spectator some space between walls for MOVETYPE_FLY_WORLDONLY
 254         // so that your view doesn't go into the ceiling with MOVETYPE_FLY_WORLDONLY, previously "PL_VIEW_OFS"
 255         if(!autocvar_g_debug_globalsounds)
 256         {
 257                 // needed for player sounds
 258                 this.model = "";
 259                 FixPlayermodel(this);
 260         }
 261         setmodel(this, MDL_Null);
 262         setsize(this, STAT(PL_CROUCH_MIN, this), STAT(PL_CROUCH_MAX, this));
 263         this.view_ofs = '0 0 0';
 264     }
 265
 266     RemoveGrapplingHooks(this);
 267         Portal_ClearAll(this);
 268         Unfreeze(this);
 269         SetSpectatee(this, NULL);
 270
 271         if (this.alivetime)
 272         {
 273                 if (!warmup_stage)
 274                         PlayerStats_GameReport_Event_Player(this, PLAYERSTATS_ALIVETIME, time - this.alivetime);
 275                 this.alivetime = 0;
 276         }
 277
 278         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
 279
 280         WaypointSprite_PlayerDead(this);
 281
 282         if (mutator_returnvalue) {
 283             // mutator prevents resetting teams+score
 284         } else {
 285                 int oldteam = this.team;
 286                 this.team = -1;  // move this as it is needed to log the player spectating in eventlog
 287                 MUTATOR_CALLHOOK(Player_ChangedTeam, this, oldteam, this.team);
 288         this.frags = FRAGS_SPECTATOR;
 289         PlayerScore_Clear(this);  // clear scores when needed
 290     }
 291
 292         if (CS(this).killcount != FRAGS_SPECTATOR)
 293         {
 294                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_QUIT_SPECTATE, this.netname);
 295                 if(!game_stopped)
 296                 if(autocvar_g_chat_nospectators == 1 || (!warmup_stage && autocvar_g_chat_nospectators == 2))
 297                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_CHAT_NOSPECTATORS);
 298
 299                 if(!CS(this).just_joined)
 300                         LogTeamchange(this.playerid, -1, 4);
 301                 else
 302                         CS(this).just_joined = false;
 303         }
 304
 305         accuracy_resend(this);
 306
 307         CS(this).spectatortime = time;
 308         if(this.bot_attack)
 309                 IL_REMOVE(g_bot_targets, this);
 310         this.bot_attack = false;
 311         if(this.monster_attack)
 312                 IL_REMOVE(g_monster_targets, this);
 313         this.monster_attack = false;
 314     STAT(HUD, this) = HUD_NORMAL;
 315         TRANSMUTE(Observer, this);
 316         this.iscreature = false;
 317         this.teleportable = TELEPORT_SIMPLE;
 318         if(this.damagedbycontents)
 319                 IL_REMOVE(g_damagedbycontents, this);
 320         this.damagedbycontents = false;
 321         this.health = FRAGS_SPECTATOR;
 322         SetSpectatee_status(this, etof(this));
 323         this.takedamage = DAMAGE_NO;
 324         this.solid = SOLID_NOT;
 325         set_movetype(this, MOVETYPE_FLY_WORLDONLY); // user preference is controlled by playerprethink
 326         this.flags = FL_CLIENT | FL_NOTARGET;
 327         this.armorvalue = 666;
 328         this.effects = 0;
 329         this.armorvalue = autocvar_g_balance_armor_start;
 330         this.pauserotarmor_finished = 0;
 331         this.pauserothealth_finished = 0;
 332         this.pauseregen_finished = 0;
 333         this.damageforcescale = 0;
 334         this.death_time = 0;
 335         this.respawn_flags = 0;
 336         this.respawn_time = 0;
 337         STAT(RESPAWN_TIME, this) = 0;
 338         this.alpha = 0;
 339         this.scale = 0;
 340         this.fade_time = 0;
 341         this.pain_frame = 0;
 342         this.pain_finished = 0;
 343         this.strength_finished = 0;
 344         this.invincible_finished = 0;
 345         this.superweapons_finished = 0;
 346         this.dphitcontentsmask = 0;
 347         this.pushltime = 0;
 348         this.istypefrag = 0;
 349         setthink(this, func_null);
 350         this.nextthink = 0;
 351         this.deadflag = DEAD_NO;
 352         this.crouch = false;
 353         STAT(REVIVE_PROGRESS, this) = 0;
 354         this.revival_time = 0;
 355
 356         this.items = 0;
 357         this.weapons = '0 0 0';
 358         this.drawonlytoclient = this;
 359
 360         this.viewloc = NULL;
 361
 362         //this.spawnpoint_targ = NULL; // keep it so they can return to where they were?
 363
 364         this.weaponmodel = "";
 365         for (int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 366         {
 367                 this.weaponentities[slot] = NULL;
 368         }
 369         this.exteriorweaponentity = NULL;
 370         CS(this).killcount = FRAGS_SPECTATOR;
 371         this.velocity = '0 0 0';
 372         this.avelocity = '0 0 0';
 373         this.punchangle = '0 0 0';
 374         this.punchvector = '0 0 0';
 375         this.oldvelocity = this.velocity;
 376         this.fire_endtime = -1;
 377         this.event_damage = func_null;
 378
 379         for(int slot = 0; slot < MAX_AXH; ++slot)
 380         {
 381                 entity axh = this.(AuxiliaryXhair[slot]);
 382                 this.(AuxiliaryXhair[slot]) = NULL;
 383
 384                 if(axh.owner == this && axh != NULL && !wasfreed(axh))
 385                         delete(axh);
 386         }
 387 }
 388
 389 int player_getspecies(entity this)
 390 {
 391         get_model_parameters(this.model, this.skin);
 392         int s = get_model_parameters_species;
 393         get_model_parameters(string_null, 0);
 394         if (s < 0) return SPECIES_HUMAN;
 395         return s;
 396 }
 397
 398 .float model_randomizer;
 399 void FixPlayermodel(entity player)
 400 {
 401         string defaultmodel = "";
 402         int defaultskin = 0;
 403         if(autocvar_sv_defaultcharacter)
 404         {
 405                 if(teamplay)
 406                 {
 407                         switch(player.team)
 408                         {
 409                                 case NUM_TEAM_1: defaultmodel = autocvar_sv_defaultplayermodel_red; defaultskin = autocvar_sv_defaultplayerskin_red; break;
 410                                 case NUM_TEAM_2: defaultmodel = autocvar_sv_defaultplayermodel_blue; defaultskin = autocvar_sv_defaultplayerskin_blue; break;
 411                                 case NUM_TEAM_3: defaultmodel = autocvar_sv_defaultplayermodel_yellow; defaultskin = autocvar_sv_defaultplayerskin_yellow; break;
 412                                 case NUM_TEAM_4: defaultmodel = autocvar_sv_defaultplayermodel_pink; defaultskin = autocvar_sv_defaultplayerskin_pink; break;
 413                         }
 414                 }
 415
 416                 if(defaultmodel == "")
 417                 {
 418                         defaultmodel = autocvar_sv_defaultplayermodel;
 419                         defaultskin = autocvar_sv_defaultplayerskin;
 420                 }
 421
 422                 int n = tokenize_console(defaultmodel);
 423                 if(n > 0)
 424                 {
 425                         defaultmodel = argv(floor(n * CS(player).model_randomizer));
 426                         // However, do NOT randomize if the player-selected model is in the list.
 427                         for (int i = 0; i < n; ++i)
 428                                 if ((argv(i) == player.playermodel && defaultskin == stof(player.playerskin)) || argv(i) == strcat(player.playermodel, ":", player.playerskin))
 429                                         defaultmodel = argv(i);
 430                 }
 431
 432                 int i = strstrofs(defaultmodel, ":", 0);
 433                 if(i >= 0)
 434                 {
 435                         defaultskin = stof(substring(defaultmodel, i+1, -1));
 436                         defaultmodel = substring(defaultmodel, 0, i);
 437                 }
 438         }
 439         if(autocvar_sv_defaultcharacterskin && !defaultskin)
 440         {
 441                 if(teamplay)
 442                 {
 443                         switch(player.team)
 444                         {
 445                                 case NUM_TEAM_1: defaultskin = autocvar_sv_defaultplayerskin_red; break;
 446                                 case NUM_TEAM_2: defaultskin = autocvar_sv_defaultplayerskin_blue; break;
 447                                 case NUM_TEAM_3: defaultskin = autocvar_sv_defaultplayerskin_yellow; break;
 448                                 case NUM_TEAM_4: defaultskin = autocvar_sv_defaultplayerskin_pink; break;
 449                         }
 450                 }
 451
 452                 if(!defaultskin)
 453                         defaultskin = autocvar_sv_defaultplayerskin;
 454         }
 455
 456         MUTATOR_CALLHOOK(FixPlayermodel, defaultmodel, defaultskin, player);
 457         defaultmodel = M_ARGV(0, string);
 458         defaultskin = M_ARGV(1, int);
 459
 460         bool chmdl = false;
 461         int oldskin;
 462         if(defaultmodel != "")
 463         {
 464                 if (defaultmodel != player.model)
 465                 {
 466                         vector m1 = player.mins;
 467                         vector m2 = player.maxs;
 468                         setplayermodel (player, defaultmodel);
 469                         setsize (player, m1, m2);
 470                         chmdl = true;
 471                 }
 472
 473                 oldskin = player.skin;
 474                 player.skin = defaultskin;
 475         } else {
 476                 if (player.playermodel != player.model || player.playermodel == "")
 477                 {
 478                         player.playermodel = CheckPlayerModel(player.playermodel); // this is never "", so no endless loop
 479                         vector m1 = player.mins;
 480                         vector m2 = player.maxs;
 481                         setplayermodel (player, player.playermodel);
 482                         setsize (player, m1, m2);
 483                         chmdl = true;
 484                 }
 485
 486                 if(!autocvar_sv_defaultcharacterskin)
 487                 {
 488                         oldskin = player.skin;
 489                         player.skin = stof(player.playerskin);
 490                 }
 491                 else
 492                 {
 493                         oldskin = player.skin;
 494                         player.skin = defaultskin;
 495                 }
 496         }
 497
 498         if(chmdl || oldskin != player.skin) // model or skin has changed
 499         {
 500                 player.species = player_getspecies(player); // update species
 501                 if(!autocvar_g_debug_globalsounds)
 502                         UpdatePlayerSounds(player); // update skin sounds
 503         }
 504
 505         if(!teamplay)
 506                 if(strlen(autocvar_sv_defaultplayercolors))
 507                         if(player.clientcolors != stof(autocvar_sv_defaultplayercolors))
 508                                 setcolor(player, stof(autocvar_sv_defaultplayercolors));
 509 }
 510
 511 void PutPlayerInServer(entity this)
 512 {
 513         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
 514
 515         PlayerState_attach(this);
 516         accuracy_resend(this);
 517
 518         if (this.team < 0)
 519                 JoinBestTeam(this, true);
 520
 521         entity spot = SelectSpawnPoint(this, false);
 522         if (!spot) {
 523                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_JOIN_NOSPAWNS);
 524                 return; // spawn failed
 525         }
 526
 527         TRANSMUTE(Player, this);
 528
 529         CS(this).wasplayer = true;
 530         this.iscreature = true;
 531         this.teleportable = TELEPORT_NORMAL;
 532         if(!this.damagedbycontents)
 533                 IL_PUSH(g_damagedbycontents, this);
 534         this.damagedbycontents = true;
 535         set_movetype(this, MOVETYPE_WALK);
 536         this.solid = SOLID_SLIDEBOX;
 537         this.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_SOLID;
 538         if (autocvar_g_playerclip_collisions)
 539                 this.dphitcontentsmask |= DPCONTENTS_PLAYERCLIP;
 540         if (IS_BOT_CLIENT(this) && autocvar_g_botclip_collisions)
 541                 this.dphitcontentsmask |= DPCONTENTS_BOTCLIP;
 542         this.frags = FRAGS_PLAYER;
 543         if (INDEPENDENT_PLAYERS) MAKE_INDEPENDENT_PLAYER(this);
 544         this.flags = FL_CLIENT | FL_PICKUPITEMS;
 545         if (autocvar__notarget)
 546                 this.flags |= FL_NOTARGET;
 547         this.takedamage = DAMAGE_AIM;
 548         this.effects = EF_TELEPORT_BIT | EF_RESTARTANIM_BIT;
 549
 550         if (warmup_stage) {
 551                 this.ammo_shells = warmup_start_ammo_shells;
 552                 this.ammo_nails = warmup_start_ammo_nails;
 553                 this.ammo_rockets = warmup_start_ammo_rockets;
 554                 this.ammo_cells = warmup_start_ammo_cells;
 555                 this.ammo_plasma = warmup_start_ammo_plasma;
 556                 this.ammo_fuel = warmup_start_ammo_fuel;
 557                 this.health = warmup_start_health;
 558                 this.armorvalue = warmup_start_armorvalue;
 559                 this.weapons = WARMUP_START_WEAPONS;
 560         } else {
 561                 this.ammo_shells = start_ammo_shells;
 562                 this.ammo_nails = start_ammo_nails;
 563                 this.ammo_rockets = start_ammo_rockets;
 564                 this.ammo_cells = start_ammo_cells;
 565                 this.ammo_plasma = start_ammo_plasma;
 566                 this.ammo_fuel = start_ammo_fuel;
 567                 this.health = start_health;
 568                 this.armorvalue = start_armorvalue;
 569                 this.weapons = start_weapons;
 570                 if (MUTATOR_CALLHOOK(ForbidRandomStartWeapons, this) == false)
 571                 {
 572                         GiveRandomWeapons(this, random_start_weapons_count,
 573                                 autocvar_g_random_start_weapons, random_start_ammo);
 574                 }
 575         }
 576         SetSpectatee_status(this, 0);
 577
 578         PS(this).dual_weapons = '0 0 0';
 579
 580         this.superweapons_finished = (this.weapons & WEPSET_SUPERWEAPONS) ? time + autocvar_g_balance_superweapons_time : 0;
 581
 582         this.items = start_items;
 583
 584         this.spawnshieldtime = time + autocvar_g_spawnshieldtime;
 585         this.pauserotarmor_finished = time + autocvar_g_balance_pause_armor_rot_spawn;
 586         this.pauserothealth_finished = time + autocvar_g_balance_pause_health_rot_spawn;
 587         this.pauserotfuel_finished = time + autocvar_g_balance_pause_fuel_rot_spawn;
 588         this.pauseregen_finished = time + autocvar_g_balance_pause_health_regen_spawn;
 589         if (!sv_ready_restart_after_countdown && time < game_starttime)
 590         {
 591                 float f = game_starttime - time;
 592                 this.spawnshieldtime += f;
 593                 this.pauserotarmor_finished += f;
 594                 this.pauserothealth_finished += f;
 595                 this.pauseregen_finished += f;
 596         }
 597
 598         this.damageforcescale = 2;
 599         this.death_time = 0;
 600         this.respawn_flags = 0;
 601         this.respawn_time = 0;
 602         STAT(RESPAWN_TIME, this) = 0;
 603         this.scale = autocvar_sv_player_scale;
 604         this.fade_time = 0;
 605         this.pain_frame = 0;
 606         this.pain_finished = 0;
 607         this.pushltime = 0;
 608         setthink(this, func_null); // players have no think function
 609         this.nextthink = 0;
 610         this.dmg_team = 0;
 611         PS(this).ballistics_density = autocvar_g_ballistics_density_player;
 612
 613         this.deadflag = DEAD_NO;
 614
 615         this.angles = spot.angles;
 616         this.angles_z = 0; // never spawn tilted even if the spot says to
 617         if (IS_BOT_CLIENT(this))
 618                 this.v_angle = this.angles;
 619         this.fixangle = true; // turn this way immediately
 620         this.oldvelocity = this.velocity = '0 0 0';
 621         this.avelocity = '0 0 0';
 622         this.punchangle = '0 0 0';
 623         this.punchvector = '0 0 0';
 624
 625         this.strength_finished = 0;
 626         this.invincible_finished = 0;
 627         this.fire_endtime = -1;
 628         STAT(REVIVE_PROGRESS, this) = 0;
 629         this.revival_time = 0;
 630
 631         this.air_finished = time + 12;
 632         this.waterlevel = WATERLEVEL_NONE;
 633         this.watertype = CONTENT_EMPTY;
 634
 635         entity spawnevent = new_pure(spawnevent);
 636         spawnevent.owner = this;
 637         Net_LinkEntity(spawnevent, false, 0.5, SpawnEvent_Send);
 638
 639         // Cut off any still running player sounds.
 640         stopsound(this, CH_PLAYER_SINGLE);
 641
 642         this.model = "";
 643         FixPlayermodel(this);
 644         this.drawonlytoclient = NULL;
 645
 646         this.viewloc = NULL;
 647
 648         for(int slot = 0; slot < MAX_AXH; ++slot)
 649         {
 650                 entity axh = this.(AuxiliaryXhair[slot]);
 651                 this.(AuxiliaryXhair[slot]) = NULL;
 652
 653                 if(axh.owner == this && axh != NULL && !wasfreed(axh))
 654                         delete(axh);
 655         }
 656
 657         this.spawnpoint_targ = NULL;
 658
 659         this.crouch = false;
 660         this.view_ofs = STAT(PL_VIEW_OFS, this);
 661         setsize(this, STAT(PL_MIN, this), STAT(PL_MAX, this));
 662         this.spawnorigin = spot.origin;
 663         setorigin(this, spot.origin + '0 0 1' * (1 - this.mins.z - 24));
 664         // don't reset back to last position, even if new position is stuck in solid
 665         this.oldorigin = this.origin;
 666         if(this.conveyor)
 667                 IL_REMOVE(g_conveyed, this);
 668         this.conveyor = NULL; // prevent conveyors at the previous location from moving a freshly spawned player
 669         STAT(HUD, this) = HUD_NORMAL;
 670
 671         this.event_damage = PlayerDamage;
 672
 673         if(!this.bot_attack)
 674                 IL_PUSH(g_bot_targets, this);
 675         this.bot_attack = true;
 676         if(!this.monster_attack)
 677                 IL_PUSH(g_monster_targets, this);
 678         this.monster_attack = true;
 679         navigation_dynamicgoal_init(this, false);
 680
 681         PHYS_INPUT_BUTTON_ATCK(this) = PHYS_INPUT_BUTTON_JUMP(this) = PHYS_INPUT_BUTTON_ATCK2(this) = false;
 682
 683         // player was spectator
 684         if (CS(this).killcount == FRAGS_SPECTATOR) {
 685                 PlayerScore_Clear(this);
 686                 CS(this).killcount = 0;
 687                 CS(this).startplaytime = time;
 688         }
 689
 690         for (int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 691         {
 692                 .entity weaponentity = weaponentities[slot];
 693                 entity oldwep = this.(weaponentity);
 694                 CL_SpawnWeaponentity(this, weaponentity);
 695                 if(oldwep && oldwep.owner == this)
 696                         this.(weaponentity).m_gunalign = oldwep.m_gunalign;
 697         }
 698         this.alpha = default_player_alpha;
 699         this.colormod = '1 1 1' * autocvar_g_player_brightness;
 700         this.exteriorweaponentity.alpha = default_weapon_alpha;
 701
 702         this.speedrunning = false;
 703
 704         target_voicescript_clear(this);
 705
 706         // reset fields the weapons may use
 707         FOREACH(Weapons, true, {
 708                 it.wr_resetplayer(it, this);
 709                         // reload all reloadable weapons
 710                 if (it.spawnflags & WEP_FLAG_RELOADABLE) {
 711                         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 712                         {
 713                                 .entity weaponentity = weaponentities[slot];
 714                                 this.(weaponentity).weapon_load[it.m_id] = it.reloading_ammo;
 715                         }
 716                 }
 717         });
 718
 719         {
 720                 string s = spot.target;
 721                 spot.target = string_null;
 722                 SUB_UseTargets(spot, this, NULL);
 723                 spot.target = s;
 724         }
 725
 726         Unfreeze(this);
 727
 728         MUTATOR_CALLHOOK(PlayerSpawn, this, spot);
 729
 730         if (autocvar_spawn_debug)
 731         {
 732                 sprint(this, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
 733                 delete(spot); // usefull for checking if there are spawnpoints, that let drop through the floor
 734         }
 735
 736         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 737         {
 738                 .entity weaponentity = weaponentities[slot];
 739                 if(slot == 0 || autocvar_g_weaponswitch_debug == 1)
 740                         this.(weaponentity).m_switchweapon = w_getbestweapon(this, weaponentity);
 741                 else
 742                         this.(weaponentity).m_switchweapon = WEP_Null;
 743                 this.(weaponentity).m_weapon = WEP_Null;
 744                 this.(weaponentity).weaponname = "";
 745                 this.(weaponentity).m_switchingweapon = WEP_Null;
 746                 this.(weaponentity).cnt = -1;
 747         }
 748
 749         MUTATOR_CALLHOOK(PlayerWeaponSelect, this);
 750
 751         if (!warmup_stage && !this.alivetime)
 752                 this.alivetime = time;
 753
 754         antilag_clear(this, CS(this));
 755 }
 756
 757 /** Called when a client spawns in the server */
 758 void PutClientInServer(entity this)
 759 {
 760         if (IS_BOT_CLIENT(this)) {
 761                 TRANSMUTE(Player, this);
 762         } else if (IS_REAL_CLIENT(this)) {
 763                 msg_entity = this;
 764                 WriteByte(MSG_ONE, SVC_SETVIEW);
 765                 WriteEntity(MSG_ONE, this);
 766         }
 767         if (game_stopped)
 768                 TRANSMUTE(Observer, this);
 769
 770         SetSpectatee(this, NULL);
 771
 772         // reset player keys
 773         if(PS(this))
 774                 PS(this).itemkeys = 0;
 775
 776         MUTATOR_CALLHOOK(PutClientInServer, this);
 777
 778         if (IS_OBSERVER(this)) {
 779                 PutObserverInServer(this);
 780         } else if (IS_PLAYER(this)) {
 781                 PutPlayerInServer(this);
 782         }
 783 }
 784
 785 void ClientInit_misc(entity this);
 786
 787 // TODO do we need all these fields, or should we stop autodetecting runtime
 788 // changes and just have a console command to update this?
 789 bool ClientInit_SendEntity(entity this, entity to, int sf)
 790 {
 791         WriteHeader(MSG_ENTITY, _ENT_CLIENT_INIT);
 792         return = true;
 793         msg_entity = to;
 794         // MSG_INIT replacement
 795         // TODO: make easier to use
 796         Registry_send_all();
 797         W_PROP_reload(MSG_ONE, to);
 798         ClientInit_misc(this);
 799         MUTATOR_CALLHOOK(Ent_Init);
 800 }
 801 void ClientInit_misc(entity this)
 802 {
 803         int channel = MSG_ONE;
 804         WriteHeader(channel, ENT_CLIENT_INIT);
 805         WriteByte(channel, g_nexball_meter_period * 32);
 806         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[0]));
 807         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[1]));
 808         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[2]));
 809         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[3]));
 810         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[0]));
 811         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[1]));
 812         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[2]));
 813         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[3]));
 814
 815         if(sv_foginterval && world.fog != "")
 816                 WriteString(channel, world.fog);
 817         else
 818                 WriteString(channel, "");
 819         WriteByte(channel, this.count * 255.0); // g_balance_armor_blockpercent
 820         WriteByte(channel, this.cnt * 255.0); // g_balance_damagepush_speedfactor
 821         WriteByte(channel, serverflags);
 822         WriteCoord(channel, autocvar_g_trueaim_minrange);
 823 }
 824
 825 void ClientInit_CheckUpdate(entity this)
 826 {
 827         this.nextthink = time;
 828         if(this.count != autocvar_g_balance_armor_blockpercent)
 829         {
 830                 this.count = autocvar_g_balance_armor_blockpercent;
 831                 this.SendFlags |= 1;
 832         }
 833         if(this.cnt != autocvar_g_balance_damagepush_speedfactor)
 834         {
 835                 this.cnt = autocvar_g_balance_damagepush_speedfactor;
 836                 this.SendFlags |= 1;
 837         }
 838 }
 839
 840 void ClientInit_Spawn()
 841 {
 842         entity e = new_pure(clientinit);
 843         setthink(e, ClientInit_CheckUpdate);
 844         Net_LinkEntity(e, false, 0, ClientInit_SendEntity);
 845
 846         ClientInit_CheckUpdate(e);
 847 }
 848
 849 /*
 850 =============
 851 SetNewParms
 852 =============
 853 */
 854 void SetNewParms ()
 855 {
 856         // initialize parms for a new player
 857         parm1 = -(86400 * 366);
 858
 859         MUTATOR_CALLHOOK(SetNewParms);
 860 }
 861
 862 /*
 863 =============
 864 SetChangeParms
 865 =============
 866 */
 867 void SetChangeParms (entity this)
 868 {
 869         // save parms for level change
 870         parm1 = CS(this).parm_idlesince - time;
 871
 872         MUTATOR_CALLHOOK(SetChangeParms);
 873 }
 874
 875 /*
 876 =============
 877 DecodeLevelParms
 878 =============
 879 */
 880 void DecodeLevelParms(entity this)
 881 {
 882         // load parms
 883         CS(this).parm_idlesince = parm1;
 884         if (CS(this).parm_idlesince == -(86400 * 366))
 885                 CS(this).parm_idlesince = time;
 886
 887         // whatever happens, allow 60 seconds of idling directly after connect for map loading
 888         CS(this).parm_idlesince = max(CS(this).parm_idlesince, time - sv_maxidle + 60);
 889
 890         MUTATOR_CALLHOOK(DecodeLevelParms);
 891 }
 892
 893 /*
 894 =============
 895 ClientKill
 896
 897 Called when a client types 'kill' in the console
 898 =============
 899 */
 900
 901 .float clientkill_nexttime;
 902 void ClientKill_Now_TeamChange(entity this)
 903 {
 904         if(this.killindicator_teamchange == -1)
 905         {
 906                 JoinBestTeam( this, true );
 907         }
 908         else if(this.killindicator_teamchange == -2)
 909         {
 910                 if(blockSpectators)
 911                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
 912                 PutObserverInServer(this);
 913         }
 914         else
 915                 SV_ChangeTeam(this, this.killindicator_teamchange - 1);
 916         this.killindicator_teamchange = 0;
 917 }
 918
 919 void ClientKill_Now(entity this)
 920 {
 921         if(this.vehicle)
 922         {
 923             vehicles_exit(this.vehicle, VHEF_RELEASE);
 924             if(!this.killindicator_teamchange)
 925             {
 926             this.vehicle_health = -1;
 927             Damage(this, this, this, 1 , DEATH_KILL.m_id, DMG_NOWEP, this.origin, '0 0 0');
 928             }
 929         }
 930
 931         if(this.killindicator && !wasfreed(this.killindicator))
 932                 delete(this.killindicator);
 933
 934         this.killindicator = NULL;
 935
 936         if(this.killindicator_teamchange)
 937                 ClientKill_Now_TeamChange(this);
 938
 939         if (!IS_SPEC(this) && !IS_OBSERVER(this) && MUTATOR_CALLHOOK(ClientKill_Now, this) == false)
 940         {
 941                 Damage(this, this, this, 100000, DEATH_KILL.m_id, DMG_NOWEP, this.origin, '0 0 0');
 942         }
 943
 944         // now I am sure the player IS dead
 945 }
 946 void KillIndicator_Think(entity this)
 947 {
 948         if (game_stopped)
 949         {
 950                 this.owner.killindicator = NULL;
 951                 delete(this);
 952                 return;
 953         }
 954
 955         if (this.owner.alpha < 0 && !this.owner.vehicle)
 956         {
 957                 this.owner.killindicator = NULL;
 958                 delete(this);
 959                 return;
 960         }
 961
 962         if(this.cnt <= 0)
 963         {
 964                 ClientKill_Now(this.owner);
 965                 return;
 966         }
 967     else if(this.health == 1) // health == 1 means that it's silent
 968     {
 969         this.nextthink = time + 1;
 970         this.cnt -= 1;
 971     }
 972         else
 973         {
 974                 if(this.cnt <= 10)
 975                         setmodel(this, MDL_NUM(this.cnt));
 976                 if(IS_REAL_CLIENT(this.owner))
 977                 {
 978                         if(this.cnt <= 10)
 979                                 { Send_Notification(NOTIF_ONE, this.owner, MSG_ANNCE, Announcer_PickNumber(CNT_KILL, this.cnt)); }
 980                 }
 981                 this.nextthink = time + 1;
 982                 this.cnt -= 1;
 983         }
 984 }
 985
 986 float clientkilltime;
 987 void ClientKill_TeamChange (entity this, float targetteam) // 0 = don't change, -1 = auto, -2 = spec
 988 {
 989         float killtime;
 990         float starttime;
 991
 992         if (game_stopped)
 993                 return;
 994
 995         killtime = autocvar_g_balance_kill_delay;
 996
 997     if(MUTATOR_CALLHOOK(ClientKill, this, killtime))
 998         return;
 999     killtime = M_ARGV(1, float);
1000
1001         this.killindicator_teamchange = targetteam;
1002
1003     if(!this.killindicator)
1004         {
1005                 if(!IS_DEAD(this))
1006                 {
1007                         killtime = max(killtime, this.clientkill_nexttime - time);
1008                         this.clientkill_nexttime = time + killtime + autocvar_g_balance_kill_antispam;
1009                 }
1010
1011                 if(killtime <= 0 || !IS_PLAYER(this) || IS_DEAD(this))
1012                 {
1013                         ClientKill_Now(this);
1014                 }
1015                 else
1016                 {
1017                         starttime = max(time, clientkilltime);
1018
1019                         this.killindicator = spawn();
1020                         this.killindicator.owner = this;
1021                         this.killindicator.scale = 0.5;
1022                         setattachment(this.killindicator, this, "");
1023                         setorigin(this.killindicator, '0 0 52');
1024                         setthink(this.killindicator, KillIndicator_Think);
1025                         this.killindicator.nextthink = starttime + (this.lip) * 0.05;
1026                         clientkilltime = max(clientkilltime, this.killindicator.nextthink + 0.05);
1027                         this.killindicator.cnt = ceil(killtime);
1028                         this.killindicator.count = bound(0, ceil(killtime), 10);
1029                         //sprint(this, strcat("^1You'll be dead in ", ftos(this.killindicator.cnt), " seconds\n"));
1030
1031                         IL_EACH(g_clones, it.enemy == this && !(it.effects & CSQCMODEL_EF_RESPAWNGHOST),
1032                         {
1033                                 it.killindicator = spawn();
1034                                 it.killindicator.owner = it;
1035                                 it.killindicator.scale = 0.5;
1036                                 setattachment(it.killindicator, it, "");
1037                                 setorigin(it.killindicator, '0 0 52');
1038                                 setthink(it.killindicator, KillIndicator_Think);
1039                                 it.killindicator.nextthink = starttime + (it.lip) * 0.05;
1040                                 //clientkilltime = max(clientkilltime, it.killindicator.nextthink + 0.05);
1041                                 it.killindicator.cnt = ceil(killtime);
1042                         });
1043                         this.lip = 0;
1044                 }
1045         }
1046         if(this.killindicator)
1047         {
1048                 if(targetteam == 0) // just die
1049                 {
1050                         this.killindicator.colormod = '0 0 0';
1051                         if(IS_REAL_CLIENT(this))
1052                         if(this.killindicator.cnt > 0)
1053                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_TEAMCHANGE_SUICIDE, this.killindicator.cnt);
1054                 }
1055                 else if(targetteam == -1) // auto
1056                 {
1057                         this.killindicator.colormod = '0 1 0';
1058                         if(IS_REAL_CLIENT(this))
1059                         if(this.killindicator.cnt > 0)
1060                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_TEAMCHANGE_AUTO, this.killindicator.cnt);
1061                 }
1062                 else if(targetteam == -2) // spectate
1063                 {
1064                         this.killindicator.colormod = '0.5 0.5 0.5';
1065                         if(IS_REAL_CLIENT(this))
1066                         if(this.killindicator.cnt > 0)
1067                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_TEAMCHANGE_SPECTATE, this.killindicator.cnt);
1068                 }
1069                 else
1070                 {
1071                         this.killindicator.colormod = Team_ColorRGB(targetteam);
1072                         if(IS_REAL_CLIENT(this))
1073                         if(this.killindicator.cnt > 0)
1074                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, APP_TEAM_NUM(targetteam, CENTER_TEAMCHANGE), this.killindicator.cnt);
1075                 }
1076         }
1077
1078 }
1079
1080 void ClientKill (entity this)
1081 {
1082         if(game_stopped) return;
1083         if(this.player_blocked) return;
1084         if(STAT(FROZEN, this)) return;
1085
1086         ClientKill_TeamChange(this, 0);
1087 }
1088
1089 void FixClientCvars(entity e)
1090 {
1091         // send prediction settings to the client
1092         stuffcmd(e, "\nin_bindmap 0 0\n");
1093         if(autocvar_g_antilag == 3) // client side hitscan
1094                 stuffcmd(e, "cl_cmd settemp cl_prydoncursor_notrace 0\n");
1095         if(autocvar_sv_gentle)
1096                 stuffcmd(e, "cl_cmd settemp cl_gentle 1\n");
1097
1098         stuffcmd(e, sprintf("\ncl_jumpspeedcap_min \"%s\"\n", autocvar_sv_jumpspeedcap_min));
1099         stuffcmd(e, sprintf("\ncl_jumpspeedcap_max \"%s\"\n", autocvar_sv_jumpspeedcap_max));
1100
1101         stuffcmd(e, sprintf("\ncl_shootfromfixedorigin \"%s\"\n", autocvar_g_shootfromfixedorigin));
1102
1103         MUTATOR_CALLHOOK(FixClientCvars, e);
1104 }
1105
1106 bool findinlist_abbrev(string tofind, string list)
1107 {
1108         if(list == "" || tofind == "")
1109                 return false; // empty list or search, just return
1110
1111         // this function allows abbreviated strings!
1112         FOREACH_WORD(list, it == substring(tofind, 0, strlen(it)),
1113         {
1114                 return true;
1115         });
1116
1117         return false;
1118 }
1119
1120 bool PlayerInIPList(entity p, string iplist)
1121 {
1122         // some safety checks (never allow local?)
1123         if(p.netaddress == "local" || p.netaddress == "" || !IS_REAL_CLIENT(p))
1124                 return false;
1125
1126         return findinlist_abbrev(p.netaddress, iplist);
1127 }
1128
1129 bool PlayerInIDList(entity p, string idlist)
1130 {
1131         // NOTE: we do NOT check crypto_idfp_signed here, an unsigned ID is fine too for this
1132         if(!p.crypto_idfp)
1133                 return false;
1134
1135         return findinlist_abbrev(p.crypto_idfp, idlist);
1136 }
1137
1138 bool PlayerInList(entity player, string list)
1139 {
1140         return boolean(PlayerInIDList(player, list) || PlayerInIPList(player, list));
1141 }
1142
1143 #ifdef DP_EXT_PRECONNECT
1144 /*
1145 =============
1146 ClientPreConnect
1147
1148 Called once (not at each match start) when a client begins a connection to the server
1149 =============
1150 */
1151 void ClientPreConnect(entity this)
1152 {
1153         if(autocvar_sv_eventlog)
1154         {
1155                 GameLogEcho(sprintf(":connect:%d:%d:%s",
1156                         this.playerid,
1157                         etof(this),
1158                         ((IS_REAL_CLIENT(this)) ? this.netaddress : "bot")
1159                 ));
1160         }
1161 }
1162 #endif
1163
1164 /**
1165 =============
1166 ClientConnect
1167
1168 Called when a client connects to the server
1169 =============
1170 */
1171 void ClientConnect(entity this)
1172 {
1173         if (Ban_MaybeEnforceBanOnce(this)) return;
1174         assert(!IS_CLIENT(this), return);
1175         this.flags |= FL_CLIENT;
1176         assert(player_count >= 0, player_count = 0);
1177
1178 #ifdef WATERMARK
1179         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_WATERMARK, WATERMARK);
1180 #endif
1181         TRANSMUTE(Client, this);
1182         CS(this).version_nagtime = time + 10 + random() * 10;
1183
1184         // identify the right forced team
1185         if (autocvar_g_campaign)
1186         {
1187                 if (IS_REAL_CLIENT(this)) // only players, not bots
1188                 {
1189                         switch (autocvar_g_campaign_forceteam)
1190                         {
1191                                 case 1: this.team_forced = NUM_TEAM_1; break;
1192                                 case 2: this.team_forced = NUM_TEAM_2; break;
1193                                 case 3: this.team_forced = NUM_TEAM_3; break;
1194                                 case 4: this.team_forced = NUM_TEAM_4; break;
1195                                 default: this.team_forced = 0;
1196                         }
1197                 }
1198         }
1199         else if (PlayerInList(this, autocvar_g_forced_team_red))    this.team_forced = NUM_TEAM_1;
1200         else if (PlayerInList(this, autocvar_g_forced_team_blue))   this.team_forced = NUM_TEAM_2;
1201         else if (PlayerInList(this, autocvar_g_forced_team_yellow)) this.team_forced = NUM_TEAM_3;
1202         else if (PlayerInList(this, autocvar_g_forced_team_pink))   this.team_forced = NUM_TEAM_4;
1203         else switch (autocvar_g_forced_team_otherwise)
1204         {
1205                 default: this.team_forced = 0; break;
1206                 case "red": this.team_forced = NUM_TEAM_1; break;
1207                 case "blue": this.team_forced = NUM_TEAM_2; break;
1208                 case "yellow": this.team_forced = NUM_TEAM_3; break;
1209                 case "pink": this.team_forced = NUM_TEAM_4; break;
1210                 case "spectate":
1211                 case "spectator":
1212                         this.team_forced = -1;
1213                         break;
1214         }
1215         if (!teamplay && this.team_forced > 0) this.team_forced = 0;
1216
1217         int playerid_save = this.playerid;
1218         this.playerid = 0; // silent
1219         JoinBestTeam(this, false); // if the team number is valid, keep it
1220         this.playerid = playerid_save;
1221
1222         if (autocvar_sv_spectate || autocvar_g_campaign || this.team_forced < 0) {
1223                 TRANSMUTE(Observer, this);
1224         } else {
1225                 if (!teamplay || autocvar_g_balance_teams) {
1226                         TRANSMUTE(Player, this);
1227                         campaign_bots_may_start = true;
1228                 } else {
1229                         TRANSMUTE(Observer, this); // do it anyway
1230                 }
1231         }
1232
1233         PlayerStats_GameReport_AddEvent(sprintf("kills-%d", this.playerid));
1234
1235         // always track bots, don't ask for cl_allow_uidtracking
1236         if (IS_BOT_CLIENT(this))
1237                 PlayerStats_GameReport_AddPlayer(this);
1238         else
1239                 CS(this).allowed_timeouts = autocvar_sv_timeout_number;
1240
1241         if (autocvar_sv_eventlog)
1242                 GameLogEcho(strcat(":join:", ftos(this.playerid), ":", ftos(etof(this)), ":", ((IS_REAL_CLIENT(this)) ? this.netaddress : "bot"), ":", playername(this, false)));
1243
1244         LogTeamchange(this.playerid, this.team, 1);
1245
1246         CS(this).just_joined = true;  // stop spamming the eventlog with additional lines when the client connects
1247
1248         if(teamplay && IS_PLAYER(this))
1249                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, APP_TEAM_NUM(this.team, INFO_JOIN_CONNECT_TEAM), this.netname);
1250         else
1251                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_JOIN_CONNECT, this.netname);
1252
1253         stuffcmd(this, clientstuff, "\n");
1254         stuffcmd(this, "cl_particles_reloadeffects\n"); // TODO do we still need this?
1255
1256         FixClientCvars(this);
1257
1258         // get version info from player
1259         stuffcmd(this, "cmd clientversion $gameversion\n");
1260
1261         // notify about available teams
1262         if (teamplay)
1263         {
1264                 CheckAllowedTeams(this);
1265                 int t = 0;
1266                 if (c1 >= 0) t |= BIT(0);
1267                 if (c2 >= 0) t |= BIT(1);
1268                 if (c3 >= 0) t |= BIT(2);
1269                 if (c4 >= 0) t |= BIT(3);
1270                 stuffcmd(this, sprintf("set _teams_available %d\n", t));
1271         }
1272         else
1273         {
1274                 stuffcmd(this, "set _teams_available 0\n");
1275         }
1276
1277         bot_relinkplayerlist();
1278
1279         CS(this).spectatortime = time;
1280         if (blockSpectators)
1281         {
1282                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
1283         }
1284
1285         CS(this).jointime = time;
1286
1287         if (IS_REAL_CLIENT(this))
1288         {
1289                 if (g_weaponarena_weapons == WEPSET(TUBA))
1290                         stuffcmd(this, "cl_cmd settemp chase_active 1\n");
1291         }
1292
1293         if (!sv_foginterval && world.fog != "")
1294                 stuffcmd(this, strcat("\nfog ", world.fog, "\nr_fog_exp2 0\nr_drawfog 1\n"));
1295
1296         if (autocvar_sv_teamnagger && !(autocvar_bot_vs_human && AvailableTeams() == 2))
1297                 if(!MUTATOR_CALLHOOK(HideTeamNagger, this))
1298                         send_CSQC_teamnagger();
1299
1300         CSQCMODEL_AUTOINIT(this);
1301
1302         CS(this).model_randomizer = random();
1303
1304         if (IS_REAL_CLIENT(this))
1305                 sv_notice_join(this);
1306
1307         // update physics stats (players can spawn before physics runs)
1308         Physics_UpdateStats(this);
1309
1310         IL_EACH(g_initforplayer, it.init_for_player, {
1311                 it.init_for_player(it, this);
1312         });
1313
1314         Handicap_Initialize(this);
1315
1316         MUTATOR_CALLHOOK(ClientConnect, this);
1317
1318         if (IS_REAL_CLIENT(this))
1319         {
1320                 if (!autocvar_g_campaign && !IS_PLAYER(this))
1321                 {
1322                         CS(this).motd_actived_time = -1;
1323                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOTD, getwelcomemessage(this));
1324                 }
1325         }
1326 }
1327 /*
1328 =============
1329 ClientDisconnect
1330
1331 Called when a client disconnects from the server
1332 =============
1333 */
1334 .entity chatbubbleentity;
1335 void ReadyCount();
1336 void ClientDisconnect(entity this)
1337 {
1338         assert(IS_CLIENT(this), return);
1339
1340         PlayerStats_GameReport_FinalizePlayer(this);
1341         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
1342         if (CS(this).active_minigame) part_minigame(this);
1343         if (IS_PLAYER(this)) Send_Effect(EFFECT_SPAWN_NEUTRAL, this.origin, '0 0 0', 1);
1344
1345         if (autocvar_sv_eventlog)
1346                 GameLogEcho(strcat(":part:", ftos(this.playerid)));
1347
1348         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_QUIT_DISCONNECT, this.netname);
1349
1350         if(IS_SPEC(this))
1351                 SetSpectatee(this, NULL);
1352
1353     MUTATOR_CALLHOOK(ClientDisconnect, this);
1354
1355         strfree(CS(this).netname_previous); // needs to be before the CS entity is removed!
1356         strfree(CS(this).weaponorder_byimpulse);
1357         ClientState_detach(this);
1358
1359         Portal_ClearAll(this);
1360
1361         Unfreeze(this);
1362
1363         RemoveGrapplingHooks(this);
1364
1365         // Here, everything has been done that requires this player to be a client.
1366
1367         this.flags &= ~FL_CLIENT;
1368
1369         if (this.chatbubbleentity) delete(this.chatbubbleentity);
1370         if (this.killindicator) delete(this.killindicator);
1371
1372         WaypointSprite_PlayerGone(this);
1373
1374         bot_relinkplayerlist();
1375
1376         strfree(this.clientstatus);
1377         if (this.personal) delete(this.personal);
1378
1379         this.playerid = 0;
1380         ReadyCount();
1381         if (vote_called && IS_REAL_CLIENT(this)) VoteCount(false);
1382
1383         ONREMOVE(this);
1384 }
1385
1386 void ChatBubbleThink(entity this)
1387 {
1388         this.nextthink = time;
1389         if ((this.owner.alpha < 0) || this.owner.chatbubbleentity != this)
1390         {
1391                 if(this.owner) // but why can that ever be NULL?
1392                         this.owner.chatbubbleentity = NULL;
1393                 delete(this);
1394                 return;
1395         }
1396
1397         this.mdl = "";
1398
1399         if ( !IS_DEAD(this.owner) && IS_PLAYER(this.owner) )
1400         {
1401                 if ( CS(this.owner).active_minigame )
1402                         this.mdl = "models/sprites/minigame_busy.iqm";
1403                 else if (PHYS_INPUT_BUTTON_CHAT(this.owner))
1404                         this.mdl = "models/misc/chatbubble.spr";
1405         }
1406
1407         if ( this.model != this.mdl )
1408                 _setmodel(this, this.mdl);
1409
1410 }
1411
1412 void UpdateChatBubble(entity this)
1413 {
1414         if (this.alpha < 0)
1415                 return;
1416         // spawn a chatbubble entity if needed
1417         if (!this.chatbubbleentity)
1418         {
1419                 this.chatbubbleentity = new(chatbubbleentity);
1420                 this.chatbubbleentity.owner = this;
1421                 this.chatbubbleentity.exteriormodeltoclient = this;
1422                 setthink(this.chatbubbleentity, ChatBubbleThink);
1423                 this.chatbubbleentity.nextthink = time;
1424                 setmodel(this.chatbubbleentity, MDL_CHAT); // precision set below
1425                 //setorigin(this.chatbubbleentity, this.origin + '0 0 15' + this.maxs_z * '0 0 1');
1426                 setorigin(this.chatbubbleentity, '0 0 15' + this.maxs_z * '0 0 1');
1427                 setattachment(this.chatbubbleentity, this, "");  // sticks to moving player better, also conserves bandwidth
1428                 this.chatbubbleentity.mdl = this.chatbubbleentity.model;
1429                 //this.chatbubbleentity.model = "";
1430                 this.chatbubbleentity.effects = EF_LOWPRECISION;
1431         }
1432 }
1433
1434
1435 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
1436 // added to the model skins
1437 /*void UpdateColorModHack()
1438 {
1439         float c;
1440         c = this.clientcolors & 15;
1441         // LordHavoc: only bothering to support white, green, red, yellow, blue
1442              if (!teamplay) this.colormod = '0 0 0';
1443         else if (c ==  0) this.colormod = '1.00 1.00 1.00';
1444         else if (c ==  3) this.colormod = '0.10 1.73 0.10';
1445         else if (c ==  4) this.colormod = '1.73 0.10 0.10';
1446         else if (c == 12) this.colormod = '1.22 1.22 0.10';
1447         else if (c == 13) this.colormod = '0.10 0.10 1.73';
1448         else this.colormod = '1 1 1';
1449 }*/
1450
1451 void respawn(entity this)
1452 {
1453         if(this.alpha >= 0 && autocvar_g_respawn_ghosts)
1454         {
1455                 this.solid = SOLID_NOT;
1456                 this.takedamage = DAMAGE_NO;
1457                 set_movetype(this, MOVETYPE_FLY);
1458                 this.velocity = '0 0 1' * autocvar_g_respawn_ghosts_speed;
1459                 this.avelocity = randomvec() * autocvar_g_respawn_ghosts_speed * 3 - randomvec() * autocvar_g_respawn_ghosts_speed * 3;
1460                 this.effects |= CSQCMODEL_EF_RESPAWNGHOST;
1461                 Send_Effect(EFFECT_RESPAWN_GHOST, this.origin, '0 0 0', 1);
1462                 if(autocvar_g_respawn_ghosts_maxtime)
1463                         SUB_SetFade (this, time + autocvar_g_respawn_ghosts_maxtime / 2 + random () * (autocvar_g_respawn_ghosts_maxtime - autocvar_g_respawn_ghosts_maxtime / 2), 1.5);
1464         }
1465
1466         CopyBody(this, 1);
1467
1468         this.effects |= EF_NODRAW; // prevent another CopyBody
1469         PutClientInServer(this);
1470 }
1471
1472 void dedicated_print(string input)
1473 {
1474         if (server_is_dedicated) print(input);
1475 }
1476
1477 void PrintToChat(entity player, string text)
1478 {
1479         text = strcat("\{1}^7", text, "\n");
1480         sprint(player, text);
1481 }
1482
1483 void DebugPrintToChat(entity player, string text)
1484 {
1485         if (autocvar_developer)
1486         {
1487                 PrintToChat(player, text);
1488         }
1489 }
1490
1491 void PrintToChatAll(string text)
1492 {
1493         text = strcat("\{1}^7", text, "\n");
1494         bprint(text);
1495 }
1496
1497 void DebugPrintToChatAll(string text)
1498 {
1499         if (autocvar_developer)
1500         {
1501                 PrintToChatAll(text);
1502         }
1503 }
1504
1505 void PrintToChatTeam(int teamnum, string text)
1506 {
1507         text = strcat("\{1}^7", text, "\n");
1508         FOREACH_CLIENT(IS_REAL_CLIENT(it),
1509         {
1510                 if (it.team == teamnum)
1511                 {
1512                         sprint(it, text);
1513                 }
1514         });
1515 }
1516
1517 void DebugPrintToChatTeam(int teamnum, string text)
1518 {
1519         if (autocvar_developer)
1520         {
1521                 PrintToChatTeam(teamnum, text);
1522         }
1523 }
1524
1525 void play_countdown(entity this, float finished, Sound samp)
1526 {
1527     TC(Sound, samp);
1528         if(IS_REAL_CLIENT(this))
1529                 if(floor(finished - time - frametime) != floor(finished - time))
1530                         if(finished - time < 6)
1531                                 sound (this, CH_INFO, samp, VOL_BASE, ATTEN_NORM);
1532 }
1533
1534 void player_powerups(entity this)
1535 {
1536         // add a way to see what the items were BEFORE all of these checks for the mutator hook
1537         int items_prev = this.items;
1538
1539         if((this.items & IT_USING_JETPACK) && !IS_DEAD(this) && !game_stopped)
1540                 this.modelflags |= MF_ROCKET;
1541         else
1542                 this.modelflags &= ~MF_ROCKET;
1543
1544         this.effects &= ~(EF_RED | EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT | EF_FLAME | EF_NODEPTHTEST);
1545
1546         if((this.alpha < 0 || IS_DEAD(this)) && !this.vehicle) // don't apply the flags if the player is gibbed
1547                 return;
1548
1549         Fire_ApplyDamage(this);
1550         Fire_ApplyEffect(this);
1551
1552         if (!autocvar_g_instagib)
1553         {
1554                 if (this.items & ITEM_Strength.m_itemid)
1555                 {
1556                         play_countdown(this, this.strength_finished, SND_POWEROFF);
1557                         this.effects = this.effects | (EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT);
1558                         if (time > this.strength_finished)
1559                         {
1560                                 this.items = this.items - (this.items & ITEM_Strength.m_itemid);
1561                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERDOWN_STRENGTH, this.netname);
1562                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERDOWN_STRENGTH);
1563                         }
1564                 }
1565                 else
1566                 {
1567                         if (time < this.strength_finished)
1568                         {
1569                                 this.items = this.items | ITEM_Strength.m_itemid;
1570                                 if(!g_cts)
1571                                         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERUP_STRENGTH, this.netname);
1572                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERUP_STRENGTH);
1573                         }
1574                 }
1575                 if (this.items & ITEM_Shield.m_itemid)
1576                 {
1577                         play_countdown(this, this.invincible_finished, SND_POWEROFF);
1578                         this.effects = this.effects | (EF_RED | EF_ADDITIVE | EF_FULLBRIGHT);
1579                         if (time > this.invincible_finished)
1580                         {
1581                                 this.items = this.items - (this.items & ITEM_Shield.m_itemid);
1582                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERDOWN_SHIELD, this.netname);
1583                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERDOWN_SHIELD);
1584                         }
1585                 }
1586                 else
1587                 {
1588                         if (time < this.invincible_finished)
1589                         {
1590                                 this.items = this.items | ITEM_Shield.m_itemid;
1591                                 if(!g_cts)
1592                                         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERUP_SHIELD, this.netname);
1593                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERUP_SHIELD);
1594                         }
1595                 }
1596                 if (this.items & IT_SUPERWEAPON)
1597                 {
1598                         if (!(this.weapons & WEPSET_SUPERWEAPONS))
1599                         {
1600                                 this.superweapons_finished = 0;
1601                                 this.items = this.items - (this.items & IT_SUPERWEAPON);
1602                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_LOST, this.netname);
1603                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_LOST);
1604                         }
1605                         else if (this.items & IT_UNLIMITED_SUPERWEAPONS)
1606                         {
1607                                 // don't let them run out
1608                         }
1609                         else
1610                         {
1611                                 play_countdown(this, this.superweapons_finished, SND_POWEROFF);
1612                                 if (time > this.superweapons_finished)
1613                                 {
1614                                         this.items = this.items - (this.items & IT_SUPERWEAPON);
1615                                         this.weapons &= ~WEPSET_SUPERWEAPONS;
1616                                         //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_BROKEN, this.netname);
1617                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_BROKEN);
1618                                 }
1619                         }
1620                 }
1621                 else if(this.weapons & WEPSET_SUPERWEAPONS)
1622                 {
1623                         if (time < this.superweapons_finished || (this.items & IT_UNLIMITED_SUPERWEAPONS))
1624                         {
1625                                 this.items = this.items | IT_SUPERWEAPON;
1626                                 if(!g_cts)
1627                                         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_PICKUP, this.netname);
1628                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_PICKUP);
1629                         }
1630                         else
1631                         {
1632                                 this.superweapons_finished = 0;
1633                                 this.weapons &= ~WEPSET_SUPERWEAPONS;
1634                         }
1635                 }
1636                 else
1637                 {
1638                         this.superweapons_finished = 0;
1639                 }
1640         }
1641
1642         if(autocvar_g_nodepthtestplayers)
1643                 this.effects = this.effects | EF_NODEPTHTEST;
1644
1645         if(autocvar_g_fullbrightplayers)
1646                 this.effects = this.effects | EF_FULLBRIGHT;
1647
1648         if (time >= game_starttime)
1649         if (time < this.spawnshieldtime)
1650                 this.effects = this.effects | (EF_ADDITIVE | EF_FULLBRIGHT);
1651
1652         MUTATOR_CALLHOOK(PlayerPowerups, this, items_prev);
1653 }
1654
1655 float CalcRegen(float current, float stable, float regenfactor, float regenframetime)
1656 {
1657         if(current > stable)
1658                 return current;
1659         else if(current > stable - 0.25) // when close enough, "snap"
1660                 return stable;
1661         else
1662                 return min(stable, current + (stable - current) * regenfactor * regenframetime);
1663 }
1664
1665 float CalcRot(float current, float stable, float rotfactor, float rotframetime)
1666 {
1667         if(current < stable)
1668                 return current;
1669         else if(current < stable + 0.25) // when close enough, "snap"
1670                 return stable;
1671         else
1672                 return max(stable, current + (stable - current) * rotfactor * rotframetime);
1673 }
1674
1675 float CalcRotRegen(float current, float regenstable, float regenfactor, float regenlinear, float regenframetime, float rotstable, float rotfactor, float rotlinear, float rotframetime, float limit)
1676 {
1677         if(current > rotstable)
1678         {
1679                 if(rotframetime > 0)
1680                 {
1681                         current = CalcRot(current, rotstable, rotfactor, rotframetime);
1682                         current = max(rotstable, current - rotlinear * rotframetime);
1683                 }
1684         }
1685         else if(current < regenstable)
1686         {
1687                 if(regenframetime > 0)
1688                 {
1689                         current = CalcRegen(current, regenstable, regenfactor, regenframetime);
1690                         current = min(regenstable, current + regenlinear * regenframetime);
1691                 }
1692         }
1693
1694         if(current > limit)
1695                 current = limit;
1696
1697         return current;
1698 }
1699
1700 void player_regen(entity this)
1701 {
1702         float max_mod, regen_mod, rot_mod, limit_mod;
1703         max_mod = regen_mod = rot_mod = limit_mod = 1;
1704
1705         float regen_health = autocvar_g_balance_health_regen;
1706         float regen_health_linear = autocvar_g_balance_health_regenlinear;
1707         float regen_health_rot = autocvar_g_balance_health_rot;
1708         float regen_health_rotlinear = autocvar_g_balance_health_rotlinear;
1709         float regen_health_stable = autocvar_g_balance_health_regenstable;
1710         float regen_health_rotstable = autocvar_g_balance_health_rotstable;
1711         bool mutator_returnvalue = MUTATOR_CALLHOOK(PlayerRegen, this, max_mod, regen_mod, rot_mod, limit_mod, regen_health, regen_health_linear, regen_health_rot,
1712                 regen_health_rotlinear, regen_health_stable, regen_health_rotstable);
1713         max_mod = M_ARGV(1, float);
1714         regen_mod = M_ARGV(2, float);
1715         rot_mod = M_ARGV(3, float);
1716         limit_mod = M_ARGV(4, float);
1717         regen_health = M_ARGV(5, float);
1718         regen_health_linear = M_ARGV(6, float);
1719         regen_health_rot = M_ARGV(7, float);
1720         regen_health_rotlinear = M_ARGV(8, float);
1721         regen_health_stable = M_ARGV(9, float);
1722         regen_health_rotstable = M_ARGV(10, float);
1723
1724         if(!mutator_returnvalue)
1725         if(!STAT(FROZEN, this))
1726         {
1727                 float mina, maxa, limith, limita;
1728                 maxa = autocvar_g_balance_armor_rotstable;
1729                 mina = autocvar_g_balance_armor_regenstable;
1730                 limith = GetResourceLimit(this, RESOURCE_HEALTH);
1731                 limita = GetResourceLimit(this, RESOURCE_ARMOR);
1732
1733                 regen_health_rotstable = regen_health_rotstable * max_mod;
1734                 regen_health_stable = regen_health_stable * max_mod;
1735                 limith = limith * limit_mod;
1736                 limita = limita * limit_mod;
1737
1738                 this.armorvalue = CalcRotRegen(this.armorvalue, mina, autocvar_g_balance_armor_regen, autocvar_g_balance_armor_regenlinear, regen_mod * frametime * (time > this.pauseregen_finished), maxa, autocvar_g_balance_armor_rot, autocvar_g_balance_armor_rotlinear, rot_mod * frametime * (time > this.pauserotarmor_finished), limita);
1739                 this.health = CalcRotRegen(this.health, regen_health_stable, regen_health, regen_health_linear, regen_mod * frametime * (time > this.pauseregen_finished), regen_health_rotstable, regen_health_rot, regen_health_rotlinear, rot_mod * frametime * (time > this.pauserothealth_finished), limith);
1740         }
1741
1742         // if player rotted to death...  die!
1743         // check this outside above checks, as player may still be able to rot to death
1744         if(this.health < 1)
1745         {
1746                 if(this.vehicle)
1747                         vehicles_exit(this.vehicle, VHEF_RELEASE);
1748                 if(this.event_damage)
1749                         this.event_damage(this, this, this, 1, DEATH_ROT.m_id, DMG_NOWEP, this.origin, '0 0 0');
1750         }
1751
1752         if (!(this.items & IT_UNLIMITED_WEAPON_AMMO))
1753         {
1754                 float minf, maxf, limitf;
1755
1756                 maxf = autocvar_g_balance_fuel_rotstable;
1757                 minf = autocvar_g_balance_fuel_regenstable;
1758                 limitf = GetResourceLimit(this, RESOURCE_FUEL);
1759
1760                 this.ammo_fuel = CalcRotRegen(this.ammo_fuel, minf, autocvar_g_balance_fuel_regen, autocvar_g_balance_fuel_regenlinear, frametime * (time > this.pauseregen_finished) * ((this.items & ITEM_JetpackRegen.m_itemid) != 0), maxf, autocvar_g_balance_fuel_rot, autocvar_g_balance_fuel_rotlinear, frametime * (time > this.pauserotfuel_finished), limitf);
1761         }
1762         // Ugly hack to make sure the health and armor don't go beyond hard limit.
1763         // TODO: Remove this hack when all code uses GivePlayerHealth and
1764         // GivePlayerArmor.
1765         if (this.health > RESOURCE_AMOUNT_HARD_LIMIT)
1766         {
1767                 this.health = RESOURCE_AMOUNT_HARD_LIMIT;
1768         }
1769         if (this.armorvalue > RESOURCE_AMOUNT_HARD_LIMIT)
1770         {
1771                 this.armorvalue = RESOURCE_AMOUNT_HARD_LIMIT;
1772         }
1773         // End hack.
1774 }
1775
1776 bool zoomstate_set;
1777 void SetZoomState(entity this, float newzoom)
1778 {
1779         if(newzoom != CS(this).zoomstate)
1780         {
1781                 CS(this).zoomstate = newzoom;
1782                 ClientData_Touch(this);
1783         }
1784         zoomstate_set = true;
1785 }
1786
1787 void GetPressedKeys(entity this)
1788 {
1789         MUTATOR_CALLHOOK(GetPressedKeys, this);
1790         int keys = STAT(PRESSED_KEYS, this);
1791         keys = BITSET(keys, KEY_FORWARD,        CS(this).movement.x > 0);
1792         keys = BITSET(keys, KEY_BACKWARD,       CS(this).movement.x < 0);
1793         keys = BITSET(keys, KEY_RIGHT,          CS(this).movement.y > 0);
1794         keys = BITSET(keys, KEY_LEFT,           CS(this).movement.y < 0);
1795
1796         keys = BITSET(keys, KEY_JUMP,           PHYS_INPUT_BUTTON_JUMP(this));
1797         keys = BITSET(keys, KEY_CROUCH,         PHYS_INPUT_BUTTON_CROUCH(this));
1798         keys = BITSET(keys, KEY_ATCK,           PHYS_INPUT_BUTTON_ATCK(this));
1799         keys = BITSET(keys, KEY_ATCK2,          PHYS_INPUT_BUTTON_ATCK2(this));
1800         CS(this).pressedkeys = keys; // store for other users
1801
1802         STAT(PRESSED_KEYS, this) = keys;
1803 }
1804
1805 /*
1806 ======================
1807 spectate mode routines
1808 ======================
1809 */
1810
1811 void SpectateCopy(entity this, entity spectatee)
1812 {
1813     TC(Client, this); TC(Client, spectatee);
1814
1815         MUTATOR_CALLHOOK(SpectateCopy, spectatee, this);
1816         PS(this) = PS(spectatee);
1817         this.armortype = spectatee.armortype;
1818         this.armorvalue = spectatee.armorvalue;
1819         this.ammo_cells = spectatee.ammo_cells;
1820         this.ammo_plasma = spectatee.ammo_plasma;
1821         this.ammo_shells = spectatee.ammo_shells;
1822         this.ammo_nails = spectatee.ammo_nails;
1823         this.ammo_rockets = spectatee.ammo_rockets;
1824         this.ammo_fuel = spectatee.ammo_fuel;
1825         this.effects = spectatee.effects & EFMASK_CHEAP; // eat performance
1826         this.health = spectatee.health;
1827         CS(this).impulse = 0;
1828         this.items = spectatee.items;
1829         STAT(LAST_PICKUP, this) = STAT(LAST_PICKUP, spectatee);
1830         STAT(HIT_TIME, this) = STAT(HIT_TIME, spectatee);
1831         this.strength_finished = spectatee.strength_finished;
1832         this.invincible_finished = spectatee.invincible_finished;
1833         this.superweapons_finished = spectatee.superweapons_finished;
1834         STAT(PRESSED_KEYS, this) = STAT(PRESSED_KEYS, spectatee);
1835         this.weapons = spectatee.weapons;
1836         this.punchangle = spectatee.punchangle;
1837         this.view_ofs = spectatee.view_ofs;
1838         this.velocity = spectatee.velocity;
1839         this.dmg_take = spectatee.dmg_take;
1840         this.dmg_save = spectatee.dmg_save;
1841         this.dmg_inflictor = spectatee.dmg_inflictor;
1842         this.v_angle = spectatee.v_angle;
1843         this.angles = spectatee.v_angle;
1844         STAT(FROZEN, this) = STAT(FROZEN, spectatee);
1845         STAT(REVIVE_PROGRESS, this) = STAT(REVIVE_PROGRESS, spectatee);
1846         this.viewloc = spectatee.viewloc;
1847         if(!PHYS_INPUT_BUTTON_USE(this) && STAT(CAMERA_SPECTATOR, this) != 2)
1848                 this.fixangle = true;
1849         setorigin(this, spectatee.origin);
1850         setsize(this, spectatee.mins, spectatee.maxs);
1851         SetZoomState(this, CS(spectatee).zoomstate);
1852
1853     anticheat_spectatecopy(this, spectatee);
1854         STAT(HUD, this) = STAT(HUD, spectatee);
1855         if(spectatee.vehicle)
1856     {
1857         this.angles = spectatee.v_angle;
1858
1859         //this.fixangle = false;
1860         //this.velocity = spectatee.vehicle.velocity;
1861         this.vehicle_health = spectatee.vehicle_health;
1862         this.vehicle_shield = spectatee.vehicle_shield;
1863         this.vehicle_energy = spectatee.vehicle_energy;
1864         this.vehicle_ammo1 = spectatee.vehicle_ammo1;
1865         this.vehicle_ammo2 = spectatee.vehicle_ammo2;
1866         this.vehicle_reload1 = spectatee.vehicle_reload1;
1867         this.vehicle_reload2 = spectatee.vehicle_reload2;
1868
1869         //msg_entity = this;
1870
1871        // WriteByte (MSG_ONE, SVC_SETVIEWANGLES);
1872             //WriteAngle(MSG_ONE,  spectatee.v_angle.x);
1873            // WriteAngle(MSG_ONE,  spectatee.v_angle.y);
1874            // WriteAngle(MSG_ONE,  spectatee.v_angle.z);
1875
1876         //WriteByte (MSG_ONE, SVC_SETVIEW);
1877         //    WriteEntity(MSG_ONE, this);
1878         //makevectors(spectatee.v_angle);
1879         //setorigin(this, spectatee.origin - v_forward * 400 + v_up * 300);*/
1880     }
1881 }
1882
1883 bool SpectateUpdate(entity this)
1884 {
1885         if(!this.enemy)
1886                 return false;
1887
1888         if(!IS_PLAYER(this.enemy) || this == this.enemy)
1889         {
1890                 SetSpectatee(this, NULL);
1891                 return false;
1892         }
1893
1894         SpectateCopy(this, this.enemy);
1895
1896         return true;
1897 }
1898
1899 bool SpectateSet(entity this)
1900 {
1901         if(!IS_PLAYER(this.enemy))
1902                 return false;
1903
1904         ClientData_Touch(this.enemy);
1905
1906         msg_entity = this;
1907         WriteByte(MSG_ONE, SVC_SETVIEW);
1908         WriteEntity(MSG_ONE, this.enemy);
1909         set_movetype(this, MOVETYPE_NONE);
1910         accuracy_resend(this);
1911
1912         if(!SpectateUpdate(this))
1913                 PutObserverInServer(this);
1914
1915         return true;
1916 }
1917
1918 void SetSpectatee_status(entity this, int spectatee_num)
1919 {
1920         int oldspectatee_status = CS(this).spectatee_status;
1921         CS(this).spectatee_status = spectatee_num;
1922
1923         if (CS(this).spectatee_status != oldspectatee_status)
1924         {
1925                 ClientData_Touch(this);
1926                 if (g_race || g_cts) race_InitSpectator();
1927         }
1928 }
1929
1930 void SetSpectatee(entity this, entity spectatee)
1931 {
1932         if(IS_BOT_CLIENT(this))
1933                 return; // bots abuse .enemy, this code is useless to them
1934
1935         entity old_spectatee = this.enemy;
1936
1937         this.enemy = spectatee;
1938
1939         // WEAPONTODO
1940         // these are required to fix the spectator bug with arc
1941         if(old_spectatee)
1942         {
1943                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1944                 {
1945                         .entity weaponentity = weaponentities[slot];
1946                         if(old_spectatee.(weaponentity).arc_beam)
1947                                 old_spectatee.(weaponentity).arc_beam.SendFlags |= ARC_SF_SETTINGS;
1948                 }
1949         }
1950         if(this.enemy)
1951         {
1952                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1953                 {
1954                         .entity weaponentity = weaponentities[slot];
1955                         if(this.enemy.(weaponentity).arc_beam)
1956                                 this.enemy.(weaponentity).arc_beam.SendFlags |= ARC_SF_SETTINGS;
1957                 }
1958         }
1959
1960         if (this.enemy)
1961                 SetSpectatee_status(this, etof(this.enemy));
1962
1963         // needed to update spectator list
1964         if(old_spectatee) { ClientData_Touch(old_spectatee); }
1965 }
1966
1967 bool Spectate(entity this, entity pl)
1968 {
1969         if(MUTATOR_CALLHOOK(SpectateSet, this, pl))
1970                 return false;
1971         pl = M_ARGV(1, entity);
1972
1973         SetSpectatee(this, pl);
1974         return SpectateSet(this);
1975 }
1976
1977 bool SpectateNext(entity this)
1978 {
1979         entity ent = find(this.enemy, classname, STR_PLAYER);
1980
1981         if (MUTATOR_CALLHOOK(SpectateNext, this, ent))
1982                 ent = M_ARGV(1, entity);
1983         else if (!ent)
1984                 ent = find(ent, classname, STR_PLAYER);
1985
1986         if(ent) { SetSpectatee(this, ent); }
1987
1988         return SpectateSet(this);
1989 }
1990
1991 bool SpectatePrev(entity this)
1992 {
1993         // NOTE: chain order is from the highest to the lower entnum (unlike find)
1994         entity ent = findchain(classname, STR_PLAYER);
1995         if (!ent) // no player
1996                 return false;
1997
1998         entity first = ent;
1999         // skip players until current spectated player
2000         if(this.enemy)
2001         while(ent && ent != this.enemy)
2002                 ent = ent.chain;
2003
2004         switch (MUTATOR_CALLHOOK(SpectatePrev, this, ent, first))
2005         {
2006                 case MUT_SPECPREV_FOUND:
2007                     ent = M_ARGV(1, entity);
2008                     break;
2009                 case MUT_SPECPREV_RETURN:
2010                     return true;
2011                 case MUT_SPECPREV_CONTINUE:
2012                 default:
2013                 {
2014                         if(ent.chain)
2015                                 ent = ent.chain;
2016                         else
2017                                 ent = first;
2018                         break;
2019                 }
2020         }
2021
2022         SetSpectatee(this, ent);
2023         return SpectateSet(this);
2024 }
2025
2026 /*
2027 =============
2028 ShowRespawnCountdown()
2029
2030 Update a respawn countdown display.
2031 =============
2032 */
2033 void ShowRespawnCountdown(entity this)
2034 {
2035         float number;
2036         if(!IS_DEAD(this)) // just respawned?
2037                 return;
2038         else
2039         {
2040                 number = ceil(this.respawn_time - time);
2041                 if(number <= 0)
2042                         return;
2043                 if(number <= this.respawn_countdown)
2044                 {
2045                         this.respawn_countdown = number - 1;
2046                         if(ceil(this.respawn_time - (time + 0.5)) == number) // only say it if it is the same number even in 0.5s; to prevent overlapping sounds
2047                                 { Send_Notification(NOTIF_ONE, this, MSG_ANNCE, Announcer_PickNumber(CNT_RESPAWN, number)); }
2048                 }
2049         }
2050 }
2051
2052 .bool team_selected;
2053 bool ShowTeamSelection(entity this)
2054 {
2055         if(!teamplay || autocvar_g_campaign || autocvar_g_balance_teams || this.team_selected || (CS(this).wasplayer && autocvar_g_changeteam_banned) || this.team_forced > 0)
2056                 return false;
2057         stuffcmd(this, "menu_showteamselect\n");
2058         return true;
2059 }
2060 void Join(entity this)
2061 {
2062         TRANSMUTE(Player, this);
2063
2064         if(!this.team_selected)
2065         if(autocvar_g_campaign || autocvar_g_balance_teams)
2066                 JoinBestTeam(this, true);
2067
2068         if(autocvar_g_campaign)
2069                 campaign_bots_may_start = true;
2070
2071         Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_PREVENT_JOIN);
2072
2073         PutClientInServer(this);
2074
2075         if(IS_PLAYER(this))
2076         if(teamplay && this.team != -1)
2077                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, APP_TEAM_NUM(this.team, INFO_JOIN_PLAY_TEAM), this.netname);
2078         else
2079                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_JOIN_PLAY, this.netname);
2080         this.team_selected = false;
2081 }
2082
2083 /**
2084  * Determines whether the player is allowed to join. This depends on cvar
2085  * g_maxplayers, if it isn't used this function always return true, otherwise
2086  * it checks whether the number of currently playing players exceeds g_maxplayers.
2087  * @return int number of free slots for players, 0 if none
2088  */
2089 int nJoinAllowed(entity this, entity ignore)
2090 {
2091         if(!ignore)
2092         // this is called that way when checking if anyone may be able to join (to build qcstatus)
2093         // so report 0 free slots if restricted
2094         {
2095                 if(autocvar_g_forced_team_otherwise == "spectate")
2096                         return 0;
2097                 if(autocvar_g_forced_team_otherwise == "spectator")
2098                         return 0;
2099         }
2100
2101         if(this && this.team_forced < 0)
2102                 return 0; // forced spectators can never join
2103
2104         // TODO simplify this
2105         int totalClients = 0;
2106         int currentlyPlaying = 0;
2107         FOREACH_CLIENT(true, {
2108                 if(it != ignore)
2109                         ++totalClients;
2110                 if(IS_REAL_CLIENT(it))
2111                 if(IS_PLAYER(it) || it.caplayer)
2112                         ++currentlyPlaying;
2113         });
2114
2115         float free_slots = 0;
2116         if (!autocvar_g_maxplayers)
2117                 free_slots = maxclients - totalClients;
2118         else if(currentlyPlaying < autocvar_g_maxplayers)
2119                 free_slots = min(maxclients - totalClients, autocvar_g_maxplayers - currentlyPlaying);
2120
2121         static float join_prevent_msg_time = 0;
2122         if(this && ignore && !free_slots && time > join_prevent_msg_time)
2123         {
2124                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_JOIN_PREVENT);
2125                 join_prevent_msg_time = time + 3;
2126         }
2127
2128         return free_slots;
2129 }
2130
2131 /**
2132  * Checks whether the client is an observer or spectator, if so, he will get kicked after
2133  * g_maxplayers_spectator_blocktime seconds
2134  */
2135 void checkSpectatorBlock(entity this)
2136 {
2137         if(IS_SPEC(this) || IS_OBSERVER(this))
2138         if(!this.caplayer)
2139         if(IS_REAL_CLIENT(this))
2140         {
2141                 if( time > (CS(this).spectatortime + autocvar_g_maxplayers_spectator_blocktime) ) {
2142                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_QUIT_KICK_SPECTATING);
2143                         dropclient(this);
2144                 }
2145         }
2146 }
2147
2148 void PrintWelcomeMessage(entity this)
2149 {
2150         if(CS(this).motd_actived_time == 0)
2151         {
2152                 if (autocvar_g_campaign) {
2153                         if ((IS_PLAYER(this) && PHYS_INPUT_BUTTON_INFO(this)) || (!IS_PLAYER(this))) {
2154                                 CS(this).motd_actived_time = time;
2155                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOTD, campaign_message);
2156                         }
2157                 } else {
2158                         if (PHYS_INPUT_BUTTON_INFO(this)) {
2159                                 CS(this).motd_actived_time = time;
2160                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOTD, getwelcomemessage(this));
2161                         }
2162                 }
2163         }
2164         else if(CS(this).motd_actived_time > 0) // showing MOTD or campaign message
2165         {
2166                 if (autocvar_g_campaign) {
2167                         if (PHYS_INPUT_BUTTON_INFO(this))
2168                                 CS(this).motd_actived_time = time;
2169                         else if ((time - CS(this).motd_actived_time > 2) && IS_PLAYER(this)) { // hide it some seconds after BUTTON_INFO has been released
2170                                 CS(this).motd_actived_time = 0;
2171                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_MOTD);
2172                         }
2173                 } else {
2174                         if (PHYS_INPUT_BUTTON_INFO(this))
2175                                 CS(this).motd_actived_time = time;
2176                         else if (time - CS(this).motd_actived_time > 2) { // hide it some seconds after BUTTON_INFO has been released
2177                                 CS(this).motd_actived_time = 0;
2178                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_MOTD);
2179                         }
2180                 }
2181         }
2182         else //if(CS(this).motd_actived_time < 0) // just connected, motd is active
2183         {
2184                 if(PHYS_INPUT_BUTTON_INFO(this)) // BUTTON_INFO hides initial MOTD
2185                         CS(this).motd_actived_time = -2; // wait until BUTTON_INFO gets released
2186                 else if(CS(this).motd_actived_time == -2 || IS_PLAYER(this) || IS_SPEC(this))
2187                 {
2188                         // instanctly hide MOTD
2189                         CS(this).motd_actived_time = 0;
2190                         Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_MOTD);
2191                 }
2192         }
2193 }
2194
2195 bool joinAllowed(entity this)
2196 {
2197         if (CS(this).version_mismatch) return false;
2198         if (!nJoinAllowed(this, this)) return false;
2199         if (teamplay && lockteams) return false;
2200         if (ShowTeamSelection(this)) return false;
2201         if (MUTATOR_CALLHOOK(ForbidSpawn, this)) return false;
2202         return true;
2203 }
2204
2205 .int items_added;
2206 .string shootfromfixedorigin;
2207 bool PlayerThink(entity this)
2208 {
2209         if (game_stopped || intermission_running) {
2210                 this.modelflags &= ~MF_ROCKET;
2211                 if(intermission_running)
2212                         IntermissionThink(this);
2213                 return false;
2214         }
2215
2216         if (timeout_status == TIMEOUT_ACTIVE) {
2217         // don't allow the player to turn around while game is paused
2218                 // FIXME turn this into CSQC stuff
2219                 this.v_angle = this.lastV_angle;
2220                 this.angles = this.lastV_angle;
2221                 this.fixangle = true;
2222         }
2223
2224         if (frametime) player_powerups(this);
2225
2226         if (IS_DEAD(this)) {
2227                 if (this.personal && g_race_qualifying) {
2228                         if (time > this.respawn_time) {
2229                                 STAT(RESPAWN_TIME, this) = this.respawn_time = time + 1; // only retry once a second
2230                                 respawn(this);
2231                                 CS(this).impulse = CHIMPULSE_SPEEDRUN.impulse;
2232                         }
2233                 } else {
2234                         if (frametime) player_anim(this);
2235
2236                         if (this.respawn_flags & RESPAWN_DENY)
2237                         {
2238                                 STAT(RESPAWN_TIME, this) = 0;
2239                                 return false;
2240                         }
2241
2242                         bool button_pressed = (PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_JUMP(this) || PHYS_INPUT_BUTTON_ATCK2(this) || PHYS_INPUT_BUTTON_HOOK(this) || PHYS_INPUT_BUTTON_USE(this));
2243
2244                         switch(this.deadflag)
2245                         {
2246                                 case DEAD_DYING:
2247                                 {
2248                                         if ((this.respawn_flags & RESPAWN_FORCE) && !(this.respawn_time < this.respawn_time_max))
2249                                                 this.deadflag = DEAD_RESPAWNING;
2250                                         else if (!button_pressed || (time >= this.respawn_time_max && (this.respawn_flags & RESPAWN_FORCE)))
2251                                                 this.deadflag = DEAD_DEAD;
2252                                         break;
2253                                 }
2254                                 case DEAD_DEAD:
2255                                 {
2256                                         if (button_pressed)
2257                                                 this.deadflag = DEAD_RESPAWNABLE;
2258                                         else if (time >= this.respawn_time_max && (this.respawn_flags & RESPAWN_FORCE))
2259                                                 this.deadflag = DEAD_RESPAWNING;
2260                                         break;
2261                                 }
2262                                 case DEAD_RESPAWNABLE:
2263                                 {
2264                                         if (!button_pressed || (this.respawn_flags & RESPAWN_FORCE))
2265                                                 this.deadflag = DEAD_RESPAWNING;
2266                                         break;
2267                                 }
2268                                 case DEAD_RESPAWNING:
2269                                 {
2270                                         if (time > this.respawn_time)
2271                                         {
2272                                                 this.respawn_time = time + 1; // only retry once a second
2273                                                 this.respawn_time_max = this.respawn_time;
2274                                                 respawn(this);
2275                                         }
2276                                         break;
2277                                 }
2278                         }
2279
2280                         ShowRespawnCountdown(this);
2281
2282                         if (this.respawn_flags & RESPAWN_SILENT)
2283                                 STAT(RESPAWN_TIME, this) = 0;
2284                         else if ((this.respawn_flags & RESPAWN_FORCE) && this.respawn_time < this.respawn_time_max)
2285                         {
2286                                 if (time < this.respawn_time)
2287                                         STAT(RESPAWN_TIME, this) = this.respawn_time;
2288                                 else if (this.deadflag != DEAD_RESPAWNING)
2289                                         STAT(RESPAWN_TIME, this) = -this.respawn_time_max;
2290                         }
2291                         else
2292                                 STAT(RESPAWN_TIME, this) = this.respawn_time;
2293                 }
2294
2295                 // if respawning, invert stat_respawn_time to indicate this, the client translates it
2296                 if (this.deadflag == DEAD_RESPAWNING && STAT(RESPAWN_TIME, this) > 0)
2297                         STAT(RESPAWN_TIME, this) *= -1;
2298
2299                 return false;
2300         }
2301
2302         FixPlayermodel(this);
2303
2304         if (this.shootfromfixedorigin != autocvar_g_shootfromfixedorigin) {
2305                 this.shootfromfixedorigin = autocvar_g_shootfromfixedorigin;
2306                 stuffcmd(this, sprintf("\ncl_shootfromfixedorigin \"%s\"\n", autocvar_g_shootfromfixedorigin));
2307         }
2308
2309         // LordHavoc: allow firing on move frames (sub-ticrate), this gives better timing on slow servers
2310         //if(frametime)
2311         {
2312                 this.items &= ~this.items_added;
2313
2314                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2315                 {
2316                         .entity weaponentity = weaponentities[slot];
2317                         W_WeaponFrame(this, weaponentity);
2318                 }
2319
2320                 this.items_added = 0;
2321                 if ((this.items & ITEM_Jetpack.m_itemid) && ((this.items & ITEM_JetpackRegen.m_itemid) || this.ammo_fuel >= 0.01))
2322             this.items_added |= IT_FUEL;
2323
2324                 this.items |= this.items_added;
2325         }
2326
2327         player_regen(this);
2328
2329         // WEAPONTODO: Add a weapon request for this
2330         // rot vortex charge to the charge limit
2331         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2332         {
2333                 .entity weaponentity = weaponentities[slot];
2334                 if (WEP_CVAR(vortex, charge_rot_rate) && this.(weaponentity).vortex_charge > WEP_CVAR(vortex, charge_limit) && this.(weaponentity).vortex_charge_rottime < time)
2335                         this.(weaponentity).vortex_charge = bound(WEP_CVAR(vortex, charge_limit), this.(weaponentity).vortex_charge - WEP_CVAR(vortex, charge_rot_rate) * frametime / W_TICSPERFRAME, 1);
2336         }
2337
2338         if (frametime) player_anim(this);
2339
2340         // secret status
2341         secrets_setstatus(this);
2342
2343         // monsters status
2344         monsters_setstatus(this);
2345
2346         this.dmg_team = max(0, this.dmg_team - autocvar_g_teamdamage_resetspeed * frametime);
2347
2348         return true;
2349 }
2350
2351 void ObserverThink(entity this)
2352 {
2353         if ( CS(this).impulse )
2354         {
2355                 MinigameImpulse(this, CS(this).impulse);
2356                 CS(this).impulse = 0;
2357         }
2358
2359         if (this.flags & FL_JUMPRELEASED) {
2360                 if (PHYS_INPUT_BUTTON_JUMP(this) && joinAllowed(this)) {
2361                         this.flags &= ~FL_JUMPRELEASED;
2362                         this.flags |= FL_SPAWNING;
2363                 } else if(PHYS_INPUT_BUTTON_ATCK(this) && !CS(this).version_mismatch) {
2364                         this.flags &= ~FL_JUMPRELEASED;
2365                         if(SpectateNext(this)) {
2366                                 TRANSMUTE(Spectator, this);
2367                         }
2368                 } else {
2369                         int preferred_movetype = ((!PHYS_INPUT_BUTTON_USE(this) ? CS(this).cvar_cl_clippedspectating : !CS(this).cvar_cl_clippedspectating) ? MOVETYPE_FLY_WORLDONLY : MOVETYPE_NOCLIP);
2370                         set_movetype(this, preferred_movetype);
2371                 }
2372         } else {
2373                 if (!(PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_JUMP(this))) {
2374                         this.flags |= FL_JUMPRELEASED;
2375                         if(this.flags & FL_SPAWNING)
2376                         {
2377                                 this.flags &= ~FL_SPAWNING;
2378                                 Join(this);
2379                                 return;
2380                         }
2381                 }
2382         }
2383 }
2384
2385 void SpectatorThink(entity this)
2386 {
2387         if ( CS(this).impulse )
2388         {
2389                 if(MinigameImpulse(this, CS(this).impulse))
2390                         CS(this).impulse = 0;
2391
2392                 if (CS(this).impulse == IMP_weapon_drop.impulse)
2393                 {
2394                         STAT(CAMERA_SPECTATOR, this) = (STAT(CAMERA_SPECTATOR, this) + 1) % 3;
2395                         CS(this).impulse = 0;
2396                         return;
2397                 }
2398         }
2399
2400         if (this.flags & FL_JUMPRELEASED) {
2401                 if (PHYS_INPUT_BUTTON_JUMP(this) && joinAllowed(this)) {
2402                         this.flags &= ~FL_JUMPRELEASED;
2403                         this.flags |= FL_SPAWNING;
2404                 } else if(PHYS_INPUT_BUTTON_ATCK(this) || CS(this).impulse == 10 || CS(this).impulse == 15 || CS(this).impulse == 18 || (CS(this).impulse >= 200 && CS(this).impulse <= 209)) {
2405                         this.flags &= ~FL_JUMPRELEASED;
2406                         if(SpectateNext(this)) {
2407                                 TRANSMUTE(Spectator, this);
2408                         } else {
2409                                 TRANSMUTE(Observer, this);
2410                                 PutClientInServer(this);
2411                         }
2412                         CS(this).impulse = 0;
2413                 } else if(CS(this).impulse == 12 || CS(this).impulse == 16  || CS(this).impulse == 19 || (CS(this).impulse >= 220 && CS(this).impulse <= 229)) {
2414                         this.flags &= ~FL_JUMPRELEASED;
2415                         if(SpectatePrev(this)) {
2416                                 TRANSMUTE(Spectator, this);
2417                         } else {
2418                                 TRANSMUTE(Observer, this);
2419                                 PutClientInServer(this);
2420                         }
2421                         CS(this).impulse = 0;
2422                 } else if (PHYS_INPUT_BUTTON_ATCK2(this)) {
2423                         this.flags &= ~FL_JUMPRELEASED;
2424                         TRANSMUTE(Observer, this);
2425                         PutClientInServer(this);
2426                 } else {
2427                         if(!SpectateUpdate(this))
2428                                 PutObserverInServer(this);
2429                 }
2430         } else {
2431                 if (!(PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_ATCK2(this))) {
2432                         this.flags |= FL_JUMPRELEASED;
2433                         if(this.flags & FL_SPAWNING)
2434                         {
2435                                 this.flags &= ~FL_SPAWNING;
2436                                 Join(this);
2437                                 return;
2438                         }
2439                 }
2440                 if(!SpectateUpdate(this))
2441                         PutObserverInServer(this);
2442         }
2443
2444         this.flags |= FL_CLIENT | FL_NOTARGET;
2445 }
2446
2447 void vehicles_enter (entity pl, entity veh);
2448 void PlayerUseKey(entity this)
2449 {
2450         if (!IS_PLAYER(this))
2451                 return;
2452
2453         if(this.vehicle)
2454         {
2455                 if(!game_stopped)
2456                 {
2457                         vehicles_exit(this.vehicle, VHEF_NORMAL);
2458                         return;
2459                 }
2460         }
2461         else if(autocvar_g_vehicles_enter)
2462         {
2463                 if(!STAT(FROZEN, this))
2464                 if(!IS_DEAD(this))
2465                 if(!game_stopped)
2466                 {
2467                         entity head, closest_target = NULL;
2468                         head = WarpZone_FindRadius(this.origin, autocvar_g_vehicles_enter_radius, true);
2469
2470                         while(head) // find the closest acceptable target to enter
2471                         {
2472                                 if(IS_VEHICLE(head))
2473                                 if(!IS_DEAD(head))
2474                                 if(!head.owner || ((head.vehicle_flags & VHF_MULTISLOT) && SAME_TEAM(head.owner, this)))
2475                                 if(head.takedamage != DAMAGE_NO)
2476                                 {
2477                                         if(closest_target)
2478                                         {
2479                                                 if(vlen2(this.origin - head.origin) < vlen2(this.origin - closest_target.origin))
2480                                                 { closest_target = head; }
2481                                         }
2482                                         else { closest_target = head; }
2483                                 }
2484
2485                                 head = head.chain;
2486                         }
2487
2488                         if(closest_target) { vehicles_enter(this, closest_target); return; }
2489                 }
2490         }
2491
2492         // a use key was pressed; call handlers
2493         MUTATOR_CALLHOOK(PlayerUseKey, this);
2494 }
2495
2496
2497 /*
2498 =============
2499 PlayerPreThink
2500
2501 Called every frame for each client before the physics are run
2502 =============
2503 */
2504 .float last_vehiclecheck;
2505 void PlayerPreThink (entity this)
2506 {
2507         STAT(GUNALIGN, this) = CS(this).cvar_cl_gunalign; // TODO
2508         STAT(MOVEVARS_CL_TRACK_CANJUMP, this) = CS(this).cvar_cl_movement_track_canjump;
2509
2510         WarpZone_PlayerPhysics_FixVAngle(this);
2511
2512         if (frametime) {
2513                 // physics frames: update anticheat stuff
2514                 anticheat_prethink(this);
2515         }
2516
2517         if (blockSpectators && frametime) {
2518                 // WORKAROUND: only use dropclient in server frames (frametime set).
2519                 // Never use it in cl_movement frames (frametime zero).
2520                 checkSpectatorBlock(this);
2521         }
2522
2523         zoomstate_set = false;
2524
2525         // Check for nameless players
2526         if (this.netname == "" || this.netname != CS(this).netname_previous)
2527         {
2528                 bool assume_unchanged = (CS(this).netname_previous == "");
2529                 if (isInvisibleString(this.netname))
2530                 {
2531                         this.netname = strzone(sprintf("Player#%d", this.playerid));
2532                         assume_unchanged = false;
2533                         // stuffcmd(this, strcat("name ", this.netname, "\n")); // maybe?
2534                 }
2535                 if (!assume_unchanged && autocvar_sv_eventlog)
2536                         GameLogEcho(strcat(":name:", ftos(this.playerid), ":", playername(this, false)));
2537                 strcpy(CS(this).netname_previous, this.netname);
2538         }
2539
2540         // version nagging
2541         if (CS(this).version_nagtime && CS(this).cvar_g_xonoticversion && time > CS(this).version_nagtime) {
2542         CS(this).version_nagtime = 0;
2543         if (strstrofs(CS(this).cvar_g_xonoticversion, "git", 0) >= 0 || strstrofs(CS(this).cvar_g_xonoticversion, "autobuild", 0) >= 0) {
2544             // git client
2545         } else if (strstrofs(autocvar_g_xonoticversion, "git", 0) >= 0 || strstrofs(autocvar_g_xonoticversion, "autobuild", 0) >= 0) {
2546             // git server
2547             Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_BETA, autocvar_g_xonoticversion, CS(this).cvar_g_xonoticversion);
2548         } else {
2549             int r = vercmp(CS(this).cvar_g_xonoticversion, autocvar_g_xonoticversion);
2550             if (r < 0) { // old client
2551                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_OUTDATED, autocvar_g_xonoticversion, CS(this).cvar_g_xonoticversion);
2552             } else if (r > 0) { // old server
2553                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_OLD, autocvar_g_xonoticversion, CS(this).cvar_g_xonoticversion);
2554             }
2555         }
2556     }
2557
2558         // GOD MODE info
2559         if (!(this.flags & FL_GODMODE) && this.max_armorvalue)
2560         {
2561                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_GODMODE_OFF, this.max_armorvalue);
2562                 this.max_armorvalue = 0;
2563         }
2564
2565         if(IS_PLAYER(this))
2566         {
2567                 if (STAT(FROZEN, this) == 2)
2568                 {
2569                         STAT(REVIVE_PROGRESS, this) = bound(0, STAT(REVIVE_PROGRESS, this) + frametime * this.revive_speed, 1);
2570                         this.health = max(1, STAT(REVIVE_PROGRESS, this) * start_health);
2571                         this.iceblock.alpha = bound(0.2, 1 - STAT(REVIVE_PROGRESS, this), 1);
2572
2573                         if (STAT(REVIVE_PROGRESS, this) >= 1)
2574                                 Unfreeze(this);
2575                 }
2576                 else if (STAT(FROZEN, this) == 3)
2577                 {
2578                         STAT(REVIVE_PROGRESS, this) = bound(0, STAT(REVIVE_PROGRESS, this) - frametime * this.revive_speed, 1);
2579                         this.health = max(0, autocvar_g_nades_ice_health + (start_health-autocvar_g_nades_ice_health) * STAT(REVIVE_PROGRESS, this) );
2580
2581                         if (this.health < 1)
2582                         {
2583                                 if (this.vehicle)
2584                                         vehicles_exit(this.vehicle, VHEF_RELEASE);
2585                                 if(this.event_damage)
2586                                         this.event_damage(this, this, this.frozen_by, 1, DEATH_NADE_ICE_FREEZE.m_id, DMG_NOWEP, this.origin, '0 0 0');
2587                         }
2588                         else if (STAT(REVIVE_PROGRESS, this) <= 0)
2589                                 Unfreeze(this);
2590                 }
2591         }
2592
2593         MUTATOR_CALLHOOK(PlayerPreThink, this);
2594
2595         if(autocvar_g_vehicles_enter && (time > this.last_vehiclecheck) && !game_stopped && !this.vehicle)
2596         if(IS_PLAYER(this) && !STAT(FROZEN, this) && !IS_DEAD(this))
2597         {
2598                 FOREACH_ENTITY_RADIUS(this.origin, autocvar_g_vehicles_enter_radius, IS_VEHICLE(it),
2599                 {
2600                         if(!IS_DEAD(it) && it.takedamage != DAMAGE_NO)
2601                         if((it.vehicle_flags & VHF_MULTISLOT) && SAME_TEAM(it.owner, this))
2602                         {
2603                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER_GUNNER);
2604                         }
2605                         else if(!it.owner)
2606                         {
2607                                 if(!it.team || SAME_TEAM(this, it))
2608                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER);
2609                                 else if(autocvar_g_vehicles_steal)
2610                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER_STEAL);
2611                         }
2612                 });
2613
2614                 this.last_vehiclecheck = time + 1;
2615         }
2616
2617         if(!CS(this).cvar_cl_newusekeysupported) // FIXME remove this - it was a stupid idea to begin with, we can JUST use the button
2618         {
2619                 if(PHYS_INPUT_BUTTON_USE(this) && !CS(this).usekeypressed)
2620                         PlayerUseKey(this);
2621                 CS(this).usekeypressed = PHYS_INPUT_BUTTON_USE(this);
2622         }
2623
2624         if (IS_REAL_CLIENT(this))
2625                 PrintWelcomeMessage(this);
2626
2627         if (IS_PLAYER(this)) {
2628                 if(!PlayerThink(this))
2629                         return;
2630         }
2631         else if (game_stopped || intermission_running) {
2632                 if(intermission_running)
2633                         IntermissionThink(this);
2634                 return;
2635         }
2636         else if (IS_OBSERVER(this)) {
2637                 ObserverThink(this);
2638         }
2639         else if (IS_SPEC(this)) {
2640                 SpectatorThink(this);
2641         }
2642
2643         // WEAPONTODO: Add weapon request for this
2644         if (!zoomstate_set) {
2645                 bool wep_zoomed = false;
2646                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2647                 {
2648                         .entity weaponentity = weaponentities[slot];
2649                         Weapon thiswep = this.(weaponentity).m_weapon;
2650                         if(thiswep != WEP_Null && thiswep.wr_zoom)
2651                                 wep_zoomed += thiswep.wr_zoom(thiswep, this);
2652                 }
2653                 SetZoomState(this, PHYS_INPUT_BUTTON_ZOOM(this) || PHYS_INPUT_BUTTON_ZOOMSCRIPT(this) || wep_zoomed);
2654     }
2655
2656         if (CS(this).teamkill_soundtime && time > CS(this).teamkill_soundtime)
2657         {
2658                 CS(this).teamkill_soundtime = 0;
2659
2660                 entity e = CS(this).teamkill_soundsource;
2661                 entity oldpusher = e.pusher;
2662                 e.pusher = this;
2663                 PlayerSound(e, playersound_teamshoot, CH_VOICE, VOL_BASEVOICE, VOICETYPE_LASTATTACKER_ONLY);
2664                 e.pusher = oldpusher;
2665         }
2666
2667         if (CS(this).taunt_soundtime && time > CS(this).taunt_soundtime) {
2668                 CS(this).taunt_soundtime = 0;
2669                 PlayerSound(this, playersound_taunt, CH_VOICE, VOL_BASEVOICE, VOICETYPE_AUTOTAUNT);
2670         }
2671
2672         target_voicescript_next(this);
2673
2674         // WEAPONTODO: Move into weaponsystem somehow
2675         // if a player goes unarmed after holding a loaded weapon, empty his clip size and remove the crosshair ammo ring
2676         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2677         {
2678                 .entity weaponentity = weaponentities[slot];
2679                 if(this.(weaponentity).m_weapon == WEP_Null)
2680                         this.(weaponentity).clip_load = this.(weaponentity).clip_size = 0;
2681         }
2682 }
2683
2684 void DrownPlayer(entity this)
2685 {
2686         if(IS_DEAD(this) || game_stopped || time < game_starttime)
2687                 return;
2688
2689         if (this.waterlevel != WATERLEVEL_SUBMERGED || this.vehicle)
2690         {
2691                 if(this.air_finished < time)
2692                         PlayerSound(this, playersound_gasp, CH_PLAYER, VOL_BASE, VOICETYPE_PLAYERSOUND);
2693                 this.air_finished = time + autocvar_g_balance_contents_drowndelay;
2694         }
2695         else if (this.air_finished < time)
2696         {       // drown!
2697                 if (this.pain_finished < time)
2698                 {
2699                         Damage (this, NULL, NULL, autocvar_g_balance_contents_playerdamage_drowning * autocvar_g_balance_contents_damagerate, DEATH_DROWN.m_id, DMG_NOWEP, this.origin, '0 0 0');
2700                         this.pain_finished = time + 0.5;
2701                 }
2702         }
2703 }
2704
2705 .bool move_qcphysics;
2706
2707 void Player_Physics(entity this)
2708 {
2709         set_movetype(this, this.move_movetype);
2710
2711         if(!this.move_qcphysics)
2712                 return;
2713
2714         if(!frametime && !CS(this).pm_frametime)
2715                 return;
2716
2717         Movetype_Physics_NoMatchTicrate(this, CS(this).pm_frametime, true);
2718
2719         CS(this).pm_frametime = 0;
2720 }
2721
2722 /*
2723 =============
2724 PlayerPostThink
2725
2726 Called every frame for each client after the physics are run
2727 =============
2728 */
2729 void PlayerPostThink (entity this)
2730 {
2731         Player_Physics(this);
2732
2733         if (sv_maxidle > 0)
2734         if (frametime) // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2735         if (IS_REAL_CLIENT(this))
2736         if (IS_PLAYER(this) || sv_maxidle_spectatorsareidle)
2737         {
2738                 int totalClients = 0;
2739                 if(sv_maxidle_slots > 0)
2740                 {
2741                         FOREACH_CLIENT(IS_REAL_CLIENT(it) || sv_maxidle_slots_countbots,
2742                         {
2743                                 ++totalClients;
2744                         });
2745                 }
2746
2747                 if (sv_maxidle_slots > 0 && (maxclients - totalClients) > sv_maxidle_slots)
2748                 { /* do nothing */ }
2749                 else if (time - CS(this).parm_idlesince < 1) // instead of (time == this.parm_idlesince) to support sv_maxidle <= 10
2750                 {
2751                         if (CS(this).idlekick_lasttimeleft)
2752                         {
2753                                 CS(this).idlekick_lasttimeleft = 0;
2754                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_IDLING);
2755                         }
2756                 }
2757                 else
2758                 {
2759                         float timeleft = ceil(sv_maxidle - (time - CS(this).parm_idlesince));
2760                         if (timeleft == min(10, sv_maxidle - 1)) { // - 1 to support sv_maxidle <= 10
2761                                 if (!CS(this).idlekick_lasttimeleft)
2762                                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_DISCONNECT_IDLING, timeleft);
2763                         }
2764                         if (timeleft <= 0) {
2765                                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_QUIT_KICK_IDLING, this.netname);
2766                                 dropclient(this);
2767                                 return;
2768                         }
2769                         else if (timeleft <= 10) {
2770                                 if (timeleft != CS(this).idlekick_lasttimeleft) {
2771                                     Send_Notification(NOTIF_ONE, this, MSG_ANNCE, Announcer_PickNumber(CNT_IDLE, timeleft));
2772                 }
2773                                 CS(this).idlekick_lasttimeleft = timeleft;
2774                         }
2775                 }
2776         }
2777
2778         CheatFrame(this);
2779
2780         if (game_stopped)
2781         {
2782                 this.solid = SOLID_NOT;
2783                 this.takedamage = DAMAGE_NO;
2784                 set_movetype(this, MOVETYPE_NONE);
2785         }
2786
2787         if (IS_PLAYER(this)) {
2788                 if(this.death_time == time && IS_DEAD(this))
2789                 {
2790                         // player's bbox gets resized now, instead of in the damage event that killed the player,
2791                         // once all the damage events of this frame have been processed with normal size
2792                         this.maxs.z = 5;
2793                         setsize(this, this.mins, this.maxs);
2794                 }
2795                 DrownPlayer(this);
2796                 UpdateChatBubble(this);
2797                 if (CS(this).impulse) ImpulseCommands(this);
2798                 if (game_stopped)
2799                 {
2800                         CSQCMODEL_AUTOUPDATE(this);
2801                         return;
2802                 }
2803                 GetPressedKeys(this);
2804         }
2805
2806         if (this.waypointsprite_attachedforcarrier) {
2807             vector v = healtharmor_maxdamage(this.health, this.armorvalue, autocvar_g_balance_armor_blockpercent, DEATH_WEAPON.m_id);
2808                 WaypointSprite_UpdateHealth(this.waypointsprite_attachedforcarrier, '1 0 0' * v);
2809     }
2810
2811         playerdemo_write(this);
2812
2813         CSQCMODEL_AUTOUPDATE(this);
2814 }
2815
2816 // hack to copy the button fields from the client entity to the Client State
2817 void PM_UpdateButtons(entity this, entity store)
2818 {
2819         if(this.impulse)
2820                 store.impulse = this.impulse;
2821         this.impulse = 0;
2822
2823         bool typing = this.buttonchat;
2824
2825         store.button0 = (typing) ? 0 : this.button0;
2826         //button1?!
2827         store.button2 = (typing) ? 0 : this.button2;
2828         store.button3 = (typing) ? 0 : this.button3;
2829         store.button4 = this.button4;
2830         store.button5 = (typing) ? 0 : this.button5;
2831         store.button6 = this.button6;
2832         store.button7 = this.button7;
2833         store.button8 = this.button8;
2834         store.button9 = this.button9;
2835         store.button10 = this.button10;
2836         store.button11 = this.button11;
2837         store.button12 = this.button12;
2838         store.button13 = this.button13;
2839         store.button14 = this.button14;
2840         store.button15 = this.button15;
2841         store.button16 = this.button16;
2842         store.buttonuse = this.buttonuse;
2843         store.buttonchat = this.buttonchat;
2844
2845         store.cursor_active = this.cursor_active;
2846         store.cursor_screen = this.cursor_screen;
2847         store.cursor_trace_start = this.cursor_trace_start;
2848         store.cursor_trace_endpos = this.cursor_trace_endpos;
2849         store.cursor_trace_ent = this.cursor_trace_ent;
2850
2851         store.ping = this.ping;
2852         store.ping_packetloss = this.ping_packetloss;
2853         store.ping_movementloss = this.ping_movementloss;
2854
2855         store.v_angle = this.v_angle;
2856         store.movement = (typing) ? '0 0 0' : this.movement;
2857 }
2858
2859 NET_HANDLE(fpsreport, bool)
2860 {
2861         int fps = ReadShort();
2862         PlayerScore_Set(sender, SP_FPS, fps);
2863         return true;
2864 }