qcsrc/server/client.qc

   1 #include "client.qh"
   2
   3 #include <server/defs.qh>
   4 #include <server/miscfunctions.qh>
   5 #include <common/effects/all.qh>
   6 #include "anticheat.qh"
   7 #include "impulse.qh"
   8 #include "player.qh"
   9 #include "ipban.qh"
  10 #include "miscfunctions.qh"
  11 #include "portals.qh"
  12 #include "teamplay.qh"
  13 #include "playerdemo.qh"
  14 #include "spawnpoints.qh"
  15 #include "resources.qh"
  16 #include "g_damage.qh"
  17 #include "handicap.qh"
  18 #include "g_hook.qh"
  19 #include "command/common.qh"
  20 #include "cheats.qh"
  21 #include "g_world.qh"
  22 #include "race.qh"
  23 #include "antilag.qh"
  24 #include "campaign.qh"
  25 #include "command/common.qh"
  26 #include "scores_rules.qh"
  27
  28 #include "bot/api.qh"
  29
  30 #include "../common/ent_cs.qh"
  31 #include "../common/wepent.qh"
  32 #include <common/state.qh>
  33
  34 #include <common/effects/qc/globalsound.qh>
  35
  36 #include "../common/triggers/func/conveyor.qh"
  37 #include "../common/triggers/teleporters.qh"
  38 #include "../common/triggers/target/spawnpoint.qh"
  39
  40 #include "../common/vehicles/all.qh"
  41
  42 #include "weapons/hitplot.qh"
  43 #include "weapons/weaponsystem.qh"
  44
  45 #include "../common/net_notice.qh"
  46 #include "../common/net_linked.qh"
  47 #include "../common/physics/player.qh"
  48
  49 #include "../common/items/_mod.qh"
  50
  51 #include "../common/mutators/mutator/waypoints/all.qh"
  52
  53 #include "../common/triggers/subs.qh"
  54 #include "../common/triggers/triggers.qh"
  55 #include "../common/triggers/trigger/secret.qh"
  56
  57 #include "../common/minigames/sv_minigames.qh"
  58
  59 #include "../common/items/inventory.qh"
  60
  61 #include "../common/monsters/sv_monsters.qh"
  62
  63 #include "../lib/warpzone/server.qh"
  64
  65 STATIC_METHOD(Client, Add, void(Client this, int _team))
  66 {
  67     ClientConnect(this);
  68     TRANSMUTE(Player, this);
  69     this.frame = 12; // 7
  70     this.team = _team;
  71     PutClientInServer(this);
  72 }
  73
  74 void PutObserverInServer(entity this);
  75
  76 STATIC_METHOD(Client, Remove, void(Client this))
  77 {
  78     TRANSMUTE(Observer, this);
  79     PutClientInServer(this);
  80     ClientDisconnect(this);
  81 }
  82
  83 void send_CSQC_teamnagger() {
  84         WriteHeader(MSG_BROADCAST, TE_CSQC_TEAMNAGGER);
  85 }
  86
  87 int CountSpectators(entity player, entity to)
  88 {
  89         if(!player) { return 0; } // not sure how, but best to be safe
  90
  91         int spec_count = 0;
  92
  93         FOREACH_CLIENT(IS_REAL_CLIENT(it) && IS_SPEC(it) && it != to && it.enemy == player,
  94         {
  95                 spec_count++;
  96         });
  97
  98         return spec_count;
  99 }
 100
 101 void WriteSpectators(entity player, entity to)
 102 {
 103         if(!player) { return; } // not sure how, but best to be safe
 104
 105         FOREACH_CLIENT(IS_REAL_CLIENT(it) && IS_SPEC(it) && it != to && it.enemy == player,
 106         {
 107                 WriteByte(MSG_ENTITY, num_for_edict(it));
 108         });
 109 }
 110
 111 bool ClientData_Send(entity this, entity to, int sf)
 112 {
 113         assert(to == this.owner, return false);
 114
 115         entity e = to;
 116         if (IS_SPEC(e)) e = e.enemy;
 117
 118         sf = 0;
 119         if (CS(e).race_completed)       sf |= BIT(0); // forced scoreboard
 120         if (CS(to).spectatee_status)    sf |= BIT(1); // spectator ent number follows
 121         if (CS(e).zoomstate)            sf |= BIT(2); // zoomed
 122         if (autocvar_sv_showspectators) sf |= BIT(4); // show spectators
 123
 124         WriteHeader(MSG_ENTITY, ENT_CLIENT_CLIENTDATA);
 125         WriteByte(MSG_ENTITY, sf);
 126
 127         if (sf & BIT(1))
 128                 WriteByte(MSG_ENTITY, CS(to).spectatee_status);
 129
 130         if(sf & BIT(4))
 131         {
 132                 float specs = CountSpectators(e, to);
 133                 WriteByte(MSG_ENTITY, specs);
 134                 WriteSpectators(e, to);
 135         }
 136
 137         return true;
 138 }
 139
 140 void ClientData_Attach(entity this)
 141 {
 142         Net_LinkEntity(CS(this).clientdata = new_pure(clientdata), false, 0, ClientData_Send);
 143         CS(this).clientdata.drawonlytoclient = this;
 144         CS(this).clientdata.owner = this;
 145 }
 146
 147 void ClientData_Detach(entity this)
 148 {
 149         delete(CS(this).clientdata);
 150         CS(this).clientdata = NULL;
 151 }
 152
 153 void ClientData_Touch(entity e)
 154 {
 155         CS(e).clientdata.SendFlags = 1;
 156
 157         // make it spectatable
 158         FOREACH_CLIENT(IS_REAL_CLIENT(it) && it != e && IS_SPEC(it) && it.enemy == e, { CS(it).clientdata.SendFlags = 1; });
 159 }
 160
 161 void SetSpectatee(entity this, entity spectatee);
 162 void SetSpectatee_status(entity this, int spectatee_num);
 163
 164
 165 /*
 166 =============
 167 CheckPlayerModel
 168
 169 Checks if the argument string can be a valid playermodel.
 170 Returns a valid one in doubt.
 171 =============
 172 */
 173 string FallbackPlayerModel;
 174 string CheckPlayerModel(string plyermodel) {
 175         if(FallbackPlayerModel != cvar_defstring("_cl_playermodel"))
 176         {
 177                 // note: we cannot summon Don Strunzone here, some player may
 178                 // still have the model string set. In case anyone manages how
 179                 // to change a cvar default, we'll have a small leak here.
 180                 FallbackPlayerModel = strzone(cvar_defstring("_cl_playermodel"));
 181         }
 182         // only in right path
 183         if( substring(plyermodel,0,14) != "models/player/")
 184                 return FallbackPlayerModel;
 185         // only good file extensions
 186         if(substring(plyermodel,-4,4) != ".zym")
 187         if(substring(plyermodel,-4,4) != ".dpm")
 188         if(substring(plyermodel,-4,4) != ".iqm")
 189         if(substring(plyermodel,-4,4) != ".md3")
 190         if(substring(plyermodel,-4,4) != ".psk")
 191                 return FallbackPlayerModel;
 192         // forbid the LOD models
 193         if(substring(plyermodel, -9,5) == "_lod1")
 194                 return FallbackPlayerModel;
 195         if(substring(plyermodel, -9,5) == "_lod2")
 196                 return FallbackPlayerModel;
 197         if(plyermodel != strtolower(plyermodel))
 198                 return FallbackPlayerModel;
 199         // also, restrict to server models
 200         if(autocvar_sv_servermodelsonly)
 201         {
 202                 if(!fexists(plyermodel))
 203                         return FallbackPlayerModel;
 204         }
 205         return plyermodel;
 206 }
 207
 208 void setplayermodel(entity e, string modelname)
 209 {
 210         precache_model(modelname);
 211         _setmodel(e, modelname);
 212         player_setupanimsformodel(e);
 213         if(!autocvar_g_debug_globalsounds)
 214                 UpdatePlayerSounds(e);
 215 }
 216
 217 void FixPlayermodel(entity player);
 218 /** putting a client as observer in the server */
 219 void PutObserverInServer(entity this)
 220 {
 221     bool mutator_returnvalue = MUTATOR_CALLHOOK(MakePlayerObserver, this);
 222         PlayerState_detach(this);
 223
 224         if (IS_PLAYER(this))
 225         {
 226                 if(this.health >= 1)
 227                 {
 228                         // despawn effect
 229                         Send_Effect(EFFECT_SPAWN_NEUTRAL, this.origin, '0 0 0', 1);
 230                 }
 231
 232                 // was a player, recount votes and ready status
 233                 if(IS_REAL_CLIENT(this))
 234                 {
 235                         if (vote_called) { VoteCount(false); }
 236                         ReadyCount();
 237                 }
 238     }
 239
 240     {
 241         entity spot = SelectSpawnPoint(this, true);
 242         if (!spot) LOG_FATAL("No spawnpoints for observers?!?");
 243         this.angles = vec2(spot.angles);
 244         this.fixangle = true;
 245         // offset it so that the spectator spawns higher off the ground, looks better this way
 246         setorigin(this, spot.origin + STAT(PL_VIEW_OFS, this));
 247         if (IS_REAL_CLIENT(this))
 248         {
 249             msg_entity = this;
 250             WriteByte(MSG_ONE, SVC_SETVIEW);
 251             WriteEntity(MSG_ONE, this);
 252         }
 253         // give the spectator some space between walls for MOVETYPE_FLY_WORLDONLY
 254         // so that your view doesn't go into the ceiling with MOVETYPE_FLY_WORLDONLY, previously "PL_VIEW_OFS"
 255         if(!autocvar_g_debug_globalsounds)
 256         {
 257                 // needed for player sounds
 258                 this.model = "";
 259                 FixPlayermodel(this);
 260         }
 261         setmodel(this, MDL_Null);
 262         setsize(this, STAT(PL_CROUCH_MIN, this), STAT(PL_CROUCH_MAX, this));
 263         this.view_ofs = '0 0 0';
 264     }
 265
 266     RemoveGrapplingHooks(this);
 267         Portal_ClearAll(this);
 268         Unfreeze(this);
 269         SetSpectatee(this, NULL);
 270
 271         if (this.alivetime)
 272         {
 273                 if (!warmup_stage)
 274                         PlayerStats_GameReport_Event_Player(this, PLAYERSTATS_ALIVETIME, time - this.alivetime);
 275                 this.alivetime = 0;
 276         }
 277
 278         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
 279
 280         WaypointSprite_PlayerDead(this);
 281
 282         if (mutator_returnvalue) {
 283             // mutator prevents resetting teams+score
 284         } else {
 285                 int oldteam = this.team;
 286                 this.team = -1;  // move this as it is needed to log the player spectating in eventlog
 287                 MUTATOR_CALLHOOK(Player_ChangedTeam, this, oldteam, this.team);
 288         this.frags = FRAGS_SPECTATOR;
 289         PlayerScore_Clear(this);  // clear scores when needed
 290     }
 291
 292         if (CS(this).killcount != FRAGS_SPECTATOR)
 293         {
 294                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_QUIT_SPECTATE, this.netname);
 295                 if(!game_stopped)
 296                 if(autocvar_g_chat_nospectators == 1 || (!warmup_stage && autocvar_g_chat_nospectators == 2))
 297                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_CHAT_NOSPECTATORS);
 298
 299                 if(!CS(this).just_joined)
 300                         LogTeamchange(this.playerid, -1, 4);
 301                 else
 302                         CS(this).just_joined = false;
 303         }
 304
 305         accuracy_resend(this);
 306
 307         CS(this).spectatortime = time;
 308         if(this.bot_attack)
 309                 IL_REMOVE(g_bot_targets, this);
 310         this.bot_attack = false;
 311     STAT(HUD, this) = HUD_NORMAL;
 312         TRANSMUTE(Observer, this);
 313         this.iscreature = false;
 314         this.teleportable = TELEPORT_SIMPLE;
 315         if(this.damagedbycontents)
 316                 IL_REMOVE(g_damagedbycontents, this);
 317         this.damagedbycontents = false;
 318         this.health = FRAGS_SPECTATOR;
 319         SetSpectatee_status(this, etof(this));
 320         this.takedamage = DAMAGE_NO;
 321         this.solid = SOLID_NOT;
 322         set_movetype(this, MOVETYPE_FLY_WORLDONLY); // user preference is controlled by playerprethink
 323         this.flags = FL_CLIENT | FL_NOTARGET;
 324         this.armorvalue = 666;
 325         this.effects = 0;
 326         this.armorvalue = autocvar_g_balance_armor_start;
 327         this.pauserotarmor_finished = 0;
 328         this.pauserothealth_finished = 0;
 329         this.pauseregen_finished = 0;
 330         this.damageforcescale = 0;
 331         this.death_time = 0;
 332         this.respawn_flags = 0;
 333         this.respawn_time = 0;
 334         STAT(RESPAWN_TIME, this) = 0;
 335         this.alpha = 0;
 336         this.scale = 0;
 337         this.fade_time = 0;
 338         this.pain_frame = 0;
 339         this.pain_finished = 0;
 340         this.strength_finished = 0;
 341         this.invincible_finished = 0;
 342         this.superweapons_finished = 0;
 343         this.pushltime = 0;
 344         this.istypefrag = 0;
 345         setthink(this, func_null);
 346         this.nextthink = 0;
 347         this.deadflag = DEAD_NO;
 348         this.crouch = false;
 349         STAT(REVIVE_PROGRESS, this) = 0;
 350         this.revival_time = 0;
 351
 352         this.items = 0;
 353         this.weapons = '0 0 0';
 354         this.drawonlytoclient = this;
 355
 356         this.viewloc = NULL;
 357
 358         //this.spawnpoint_targ = NULL; // keep it so they can return to where they were?
 359
 360         this.weaponmodel = "";
 361         for (int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 362         {
 363                 this.weaponentities[slot] = NULL;
 364         }
 365         this.exteriorweaponentity = NULL;
 366         CS(this).killcount = FRAGS_SPECTATOR;
 367         this.velocity = '0 0 0';
 368         this.avelocity = '0 0 0';
 369         this.punchangle = '0 0 0';
 370         this.punchvector = '0 0 0';
 371         this.oldvelocity = this.velocity;
 372         this.fire_endtime = -1;
 373         this.event_damage = func_null;
 374
 375         for(int slot = 0; slot < MAX_AXH; ++slot)
 376         {
 377                 entity axh = this.(AuxiliaryXhair[slot]);
 378                 this.(AuxiliaryXhair[slot]) = NULL;
 379
 380                 if(axh.owner == this && axh != NULL && !wasfreed(axh))
 381                         delete(axh);
 382         }
 383 }
 384
 385 int player_getspecies(entity this)
 386 {
 387         get_model_parameters(this.model, this.skin);
 388         int s = get_model_parameters_species;
 389         get_model_parameters(string_null, 0);
 390         if (s < 0) return SPECIES_HUMAN;
 391         return s;
 392 }
 393
 394 .float model_randomizer;
 395 void FixPlayermodel(entity player)
 396 {
 397         string defaultmodel = "";
 398         int defaultskin = 0;
 399         if(autocvar_sv_defaultcharacter)
 400         {
 401                 if(teamplay)
 402                 {
 403                         switch(player.team)
 404                         {
 405                                 case NUM_TEAM_1: defaultmodel = autocvar_sv_defaultplayermodel_red; defaultskin = autocvar_sv_defaultplayerskin_red; break;
 406                                 case NUM_TEAM_2: defaultmodel = autocvar_sv_defaultplayermodel_blue; defaultskin = autocvar_sv_defaultplayerskin_blue; break;
 407                                 case NUM_TEAM_3: defaultmodel = autocvar_sv_defaultplayermodel_yellow; defaultskin = autocvar_sv_defaultplayerskin_yellow; break;
 408                                 case NUM_TEAM_4: defaultmodel = autocvar_sv_defaultplayermodel_pink; defaultskin = autocvar_sv_defaultplayerskin_pink; break;
 409                         }
 410                 }
 411
 412                 if(defaultmodel == "")
 413                 {
 414                         defaultmodel = autocvar_sv_defaultplayermodel;
 415                         defaultskin = autocvar_sv_defaultplayerskin;
 416                 }
 417
 418                 int n = tokenize_console(defaultmodel);
 419                 if(n > 0)
 420                 {
 421                         defaultmodel = argv(floor(n * CS(player).model_randomizer));
 422                         // However, do NOT randomize if the player-selected model is in the list.
 423                         for (int i = 0; i < n; ++i)
 424                                 if ((argv(i) == player.playermodel && defaultskin == stof(player.playerskin)) || argv(i) == strcat(player.playermodel, ":", player.playerskin))
 425                                         defaultmodel = argv(i);
 426                 }
 427
 428                 int i = strstrofs(defaultmodel, ":", 0);
 429                 if(i >= 0)
 430                 {
 431                         defaultskin = stof(substring(defaultmodel, i+1, -1));
 432                         defaultmodel = substring(defaultmodel, 0, i);
 433                 }
 434         }
 435         if(autocvar_sv_defaultcharacterskin && !defaultskin)
 436         {
 437                 if(teamplay)
 438                 {
 439                         switch(player.team)
 440                         {
 441                                 case NUM_TEAM_1: defaultskin = autocvar_sv_defaultplayerskin_red; break;
 442                                 case NUM_TEAM_2: defaultskin = autocvar_sv_defaultplayerskin_blue; break;
 443                                 case NUM_TEAM_3: defaultskin = autocvar_sv_defaultplayerskin_yellow; break;
 444                                 case NUM_TEAM_4: defaultskin = autocvar_sv_defaultplayerskin_pink; break;
 445                         }
 446                 }
 447
 448                 if(!defaultskin)
 449                         defaultskin = autocvar_sv_defaultplayerskin;
 450         }
 451
 452         MUTATOR_CALLHOOK(FixPlayermodel, defaultmodel, defaultskin, player);
 453         defaultmodel = M_ARGV(0, string);
 454         defaultskin = M_ARGV(1, int);
 455
 456         bool chmdl = false;
 457         int oldskin;
 458         if(defaultmodel != "")
 459         {
 460                 if (defaultmodel != player.model)
 461                 {
 462                         vector m1 = player.mins;
 463                         vector m2 = player.maxs;
 464                         setplayermodel (player, defaultmodel);
 465                         setsize (player, m1, m2);
 466                         chmdl = true;
 467                 }
 468
 469                 oldskin = player.skin;
 470                 player.skin = defaultskin;
 471         } else {
 472                 if (player.playermodel != player.model || player.playermodel == "")
 473                 {
 474                         player.playermodel = CheckPlayerModel(player.playermodel); // this is never "", so no endless loop
 475                         vector m1 = player.mins;
 476                         vector m2 = player.maxs;
 477                         setplayermodel (player, player.playermodel);
 478                         setsize (player, m1, m2);
 479                         chmdl = true;
 480                 }
 481
 482                 if(!autocvar_sv_defaultcharacterskin)
 483                 {
 484                         oldskin = player.skin;
 485                         player.skin = stof(player.playerskin);
 486                 }
 487                 else
 488                 {
 489                         oldskin = player.skin;
 490                         player.skin = defaultskin;
 491                 }
 492         }
 493
 494         if(chmdl || oldskin != player.skin) // model or skin has changed
 495         {
 496                 player.species = player_getspecies(player); // update species
 497                 if(!autocvar_g_debug_globalsounds)
 498                         UpdatePlayerSounds(player); // update skin sounds
 499         }
 500
 501         if(!teamplay)
 502                 if(strlen(autocvar_sv_defaultplayercolors))
 503                         if(player.clientcolors != stof(autocvar_sv_defaultplayercolors))
 504                                 setcolor(player, stof(autocvar_sv_defaultplayercolors));
 505 }
 506
 507 void PutPlayerInServer(entity this)
 508 {
 509         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
 510
 511         PlayerState_attach(this);
 512         accuracy_resend(this);
 513
 514         if (this.team < 0)
 515                 JoinBestTeam(this, true);
 516
 517         entity spot = SelectSpawnPoint(this, false);
 518         if (!spot) {
 519                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_JOIN_NOSPAWNS);
 520                 return; // spawn failed
 521         }
 522
 523         TRANSMUTE(Player, this);
 524
 525         CS(this).wasplayer = true;
 526         this.iscreature = true;
 527         this.teleportable = TELEPORT_NORMAL;
 528         if(!this.damagedbycontents)
 529                 IL_PUSH(g_damagedbycontents, this);
 530         this.damagedbycontents = true;
 531         set_movetype(this, MOVETYPE_WALK);
 532         this.solid = SOLID_SLIDEBOX;
 533         this.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_SOLID;
 534         if (autocvar_g_playerclip_collisions)
 535                 this.dphitcontentsmask |= DPCONTENTS_PLAYERCLIP;
 536         if (IS_BOT_CLIENT(this) && autocvar_g_botclip_collisions)
 537                 this.dphitcontentsmask |= DPCONTENTS_BOTCLIP;
 538         this.frags = FRAGS_PLAYER;
 539         if (INDEPENDENT_PLAYERS) MAKE_INDEPENDENT_PLAYER(this);
 540         this.flags = FL_CLIENT | FL_PICKUPITEMS;
 541         if (autocvar__notarget)
 542                 this.flags |= FL_NOTARGET;
 543         this.takedamage = DAMAGE_AIM;
 544         this.effects = EF_TELEPORT_BIT | EF_RESTARTANIM_BIT;
 545
 546         if (warmup_stage) {
 547                 this.ammo_shells = warmup_start_ammo_shells;
 548                 this.ammo_nails = warmup_start_ammo_nails;
 549                 this.ammo_rockets = warmup_start_ammo_rockets;
 550                 this.ammo_cells = warmup_start_ammo_cells;
 551                 this.ammo_plasma = warmup_start_ammo_plasma;
 552                 this.ammo_fuel = warmup_start_ammo_fuel;
 553                 this.health = warmup_start_health;
 554                 this.armorvalue = warmup_start_armorvalue;
 555                 this.weapons = WARMUP_START_WEAPONS;
 556         } else {
 557                 this.ammo_shells = start_ammo_shells;
 558                 this.ammo_nails = start_ammo_nails;
 559                 this.ammo_rockets = start_ammo_rockets;
 560                 this.ammo_cells = start_ammo_cells;
 561                 this.ammo_plasma = start_ammo_plasma;
 562                 this.ammo_fuel = start_ammo_fuel;
 563                 this.health = start_health;
 564                 this.armorvalue = start_armorvalue;
 565                 this.weapons = start_weapons;
 566                 if (MUTATOR_CALLHOOK(ForbidRandomStartWeapons, this) == false)
 567                 {
 568                         GiveRandomWeapons(this, random_start_weapons_count,
 569                                 autocvar_g_random_start_weapons, random_start_ammo);
 570                 }
 571         }
 572         SetSpectatee_status(this, 0);
 573
 574         PS(this).dual_weapons = '0 0 0';
 575
 576         this.superweapons_finished = (this.weapons & WEPSET_SUPERWEAPONS) ? time + autocvar_g_balance_superweapons_time : 0;
 577
 578         this.items = start_items;
 579
 580         this.spawnshieldtime = time + autocvar_g_spawnshieldtime;
 581         this.pauserotarmor_finished = time + autocvar_g_balance_pause_armor_rot_spawn;
 582         this.pauserothealth_finished = time + autocvar_g_balance_pause_health_rot_spawn;
 583         this.pauserotfuel_finished = time + autocvar_g_balance_pause_fuel_rot_spawn;
 584         this.pauseregen_finished = time + autocvar_g_balance_pause_health_regen_spawn;
 585         if (!sv_ready_restart_after_countdown && time < game_starttime)
 586         {
 587                 float f = game_starttime - time;
 588                 this.spawnshieldtime += f;
 589                 this.pauserotarmor_finished += f;
 590                 this.pauserothealth_finished += f;
 591                 this.pauseregen_finished += f;
 592         }
 593
 594         this.damageforcescale = 2;
 595         this.death_time = 0;
 596         this.respawn_flags = 0;
 597         this.respawn_time = 0;
 598         STAT(RESPAWN_TIME, this) = 0;
 599         this.scale = autocvar_sv_player_scale;
 600         this.fade_time = 0;
 601         this.pain_frame = 0;
 602         this.pain_finished = 0;
 603         this.pushltime = 0;
 604         setthink(this, func_null); // players have no think function
 605         this.nextthink = 0;
 606         this.dmg_team = 0;
 607         PS(this).ballistics_density = autocvar_g_ballistics_density_player;
 608
 609         this.deadflag = DEAD_NO;
 610
 611         this.angles = spot.angles;
 612         this.angles_z = 0; // never spawn tilted even if the spot says to
 613         if (IS_BOT_CLIENT(this))
 614                 this.v_angle = this.angles;
 615         this.fixangle = true; // turn this way immediately
 616         this.oldvelocity = this.velocity = '0 0 0';
 617         this.avelocity = '0 0 0';
 618         this.punchangle = '0 0 0';
 619         this.punchvector = '0 0 0';
 620
 621         this.strength_finished = 0;
 622         this.invincible_finished = 0;
 623         this.fire_endtime = -1;
 624         STAT(REVIVE_PROGRESS, this) = 0;
 625         this.revival_time = 0;
 626
 627         this.air_finished = time + 12;
 628         this.waterlevel = WATERLEVEL_NONE;
 629         this.watertype = CONTENT_EMPTY;
 630
 631         entity spawnevent = new_pure(spawnevent);
 632         spawnevent.owner = this;
 633         Net_LinkEntity(spawnevent, false, 0.5, SpawnEvent_Send);
 634
 635         // Cut off any still running player sounds.
 636         stopsound(this, CH_PLAYER_SINGLE);
 637
 638         this.model = "";
 639         FixPlayermodel(this);
 640         this.drawonlytoclient = NULL;
 641
 642         this.viewloc = NULL;
 643
 644         for(int slot = 0; slot < MAX_AXH; ++slot)
 645         {
 646                 entity axh = this.(AuxiliaryXhair[slot]);
 647                 this.(AuxiliaryXhair[slot]) = NULL;
 648
 649                 if(axh.owner == this && axh != NULL && !wasfreed(axh))
 650                         delete(axh);
 651         }
 652
 653         this.spawnpoint_targ = NULL;
 654
 655         this.crouch = false;
 656         this.view_ofs = STAT(PL_VIEW_OFS, this);
 657         setsize(this, STAT(PL_MIN, this), STAT(PL_MAX, this));
 658         this.spawnorigin = spot.origin;
 659         setorigin(this, spot.origin + '0 0 1' * (1 - this.mins.z - 24));
 660         // don't reset back to last position, even if new position is stuck in solid
 661         this.oldorigin = this.origin;
 662         if(this.conveyor)
 663                 IL_REMOVE(g_conveyed, this);
 664         this.conveyor = NULL; // prevent conveyors at the previous location from moving a freshly spawned player
 665         STAT(HUD, this) = HUD_NORMAL;
 666
 667         this.event_damage = PlayerDamage;
 668
 669         if(!this.bot_attack)
 670                 IL_PUSH(g_bot_targets, this);
 671         this.bot_attack = true;
 672         if(!this.monster_attack)
 673                 IL_PUSH(g_monster_targets, this);
 674         this.monster_attack = true;
 675         navigation_dynamicgoal_init(this, false);
 676
 677         PHYS_INPUT_BUTTON_ATCK(this) = PHYS_INPUT_BUTTON_JUMP(this) = PHYS_INPUT_BUTTON_ATCK2(this) = false;
 678
 679         // player was spectator
 680         if (CS(this).killcount == FRAGS_SPECTATOR) {
 681                 PlayerScore_Clear(this);
 682                 CS(this).killcount = 0;
 683                 CS(this).startplaytime = time;
 684         }
 685
 686         for (int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 687         {
 688                 .entity weaponentity = weaponentities[slot];
 689                 entity oldwep = this.(weaponentity);
 690                 CL_SpawnWeaponentity(this, weaponentity);
 691                 if(oldwep && oldwep.owner == this)
 692                         this.(weaponentity).m_gunalign = oldwep.m_gunalign;
 693         }
 694         this.alpha = default_player_alpha;
 695         this.colormod = '1 1 1' * autocvar_g_player_brightness;
 696         this.exteriorweaponentity.alpha = default_weapon_alpha;
 697
 698         this.speedrunning = false;
 699
 700         target_voicescript_clear(this);
 701
 702         // reset fields the weapons may use
 703         FOREACH(Weapons, true, {
 704                 it.wr_resetplayer(it, this);
 705                         // reload all reloadable weapons
 706                 if (it.spawnflags & WEP_FLAG_RELOADABLE) {
 707                         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 708                         {
 709                                 .entity weaponentity = weaponentities[slot];
 710                                 this.(weaponentity).weapon_load[it.m_id] = it.reloading_ammo;
 711                         }
 712                 }
 713         });
 714
 715         {
 716                 string s = spot.target;
 717                 spot.target = string_null;
 718                 SUB_UseTargets(spot, this, NULL);
 719                 spot.target = s;
 720         }
 721
 722         Unfreeze(this);
 723
 724         MUTATOR_CALLHOOK(PlayerSpawn, this, spot);
 725
 726         if (autocvar_spawn_debug)
 727         {
 728                 sprint(this, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
 729                 delete(spot); // usefull for checking if there are spawnpoints, that let drop through the floor
 730         }
 731
 732         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 733         {
 734                 .entity weaponentity = weaponentities[slot];
 735                 if(slot == 0 || autocvar_g_weaponswitch_debug == 1)
 736                         this.(weaponentity).m_switchweapon = w_getbestweapon(this, weaponentity);
 737                 else
 738                         this.(weaponentity).m_switchweapon = WEP_Null;
 739                 this.(weaponentity).m_weapon = WEP_Null;
 740                 this.(weaponentity).weaponname = "";
 741                 this.(weaponentity).m_switchingweapon = WEP_Null;
 742                 this.(weaponentity).cnt = -1;
 743         }
 744
 745         MUTATOR_CALLHOOK(PlayerWeaponSelect, this);
 746
 747         if (!warmup_stage && !this.alivetime)
 748                 this.alivetime = time;
 749
 750         antilag_clear(this, CS(this));
 751 }
 752
 753 /** Called when a client spawns in the server */
 754 void PutClientInServer(entity this)
 755 {
 756         if (IS_BOT_CLIENT(this)) {
 757                 TRANSMUTE(Player, this);
 758         } else if (IS_REAL_CLIENT(this)) {
 759                 msg_entity = this;
 760                 WriteByte(MSG_ONE, SVC_SETVIEW);
 761                 WriteEntity(MSG_ONE, this);
 762         }
 763         if (game_stopped)
 764                 TRANSMUTE(Observer, this);
 765
 766         SetSpectatee(this, NULL);
 767
 768         // reset player keys
 769         if(PS(this))
 770                 PS(this).itemkeys = 0;
 771
 772         MUTATOR_CALLHOOK(PutClientInServer, this);
 773
 774         if (IS_OBSERVER(this)) {
 775                 PutObserverInServer(this);
 776         } else if (IS_PLAYER(this)) {
 777                 PutPlayerInServer(this);
 778         }
 779 }
 780
 781 void ClientInit_misc(entity this);
 782
 783 // TODO do we need all these fields, or should we stop autodetecting runtime
 784 // changes and just have a console command to update this?
 785 bool ClientInit_SendEntity(entity this, entity to, int sf)
 786 {
 787         WriteHeader(MSG_ENTITY, _ENT_CLIENT_INIT);
 788         return = true;
 789         msg_entity = to;
 790         // MSG_INIT replacement
 791         // TODO: make easier to use
 792         Registry_send_all();
 793         W_PROP_reload(MSG_ONE, to);
 794         ClientInit_misc(this);
 795         MUTATOR_CALLHOOK(Ent_Init);
 796 }
 797 void ClientInit_misc(entity this)
 798 {
 799         int channel = MSG_ONE;
 800         WriteHeader(channel, ENT_CLIENT_INIT);
 801         WriteByte(channel, g_nexball_meter_period * 32);
 802         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[0]));
 803         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[1]));
 804         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[2]));
 805         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[3]));
 806         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[0]));
 807         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[1]));
 808         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[2]));
 809         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[3]));
 810
 811         if(sv_foginterval && world.fog != "")
 812                 WriteString(channel, world.fog);
 813         else
 814                 WriteString(channel, "");
 815         WriteByte(channel, this.count * 255.0); // g_balance_armor_blockpercent
 816         WriteByte(channel, this.cnt * 255.0); // g_balance_damagepush_speedfactor
 817         WriteByte(channel, serverflags);
 818         WriteCoord(channel, autocvar_g_trueaim_minrange);
 819 }
 820
 821 void ClientInit_CheckUpdate(entity this)
 822 {
 823         this.nextthink = time;
 824         if(this.count != autocvar_g_balance_armor_blockpercent)
 825         {
 826                 this.count = autocvar_g_balance_armor_blockpercent;
 827                 this.SendFlags |= 1;
 828         }
 829         if(this.cnt != autocvar_g_balance_damagepush_speedfactor)
 830         {
 831                 this.cnt = autocvar_g_balance_damagepush_speedfactor;
 832                 this.SendFlags |= 1;
 833         }
 834 }
 835
 836 void ClientInit_Spawn()
 837 {
 838         entity e = new_pure(clientinit);
 839         setthink(e, ClientInit_CheckUpdate);
 840         Net_LinkEntity(e, false, 0, ClientInit_SendEntity);
 841
 842         ClientInit_CheckUpdate(e);
 843 }
 844
 845 /*
 846 =============
 847 SetNewParms
 848 =============
 849 */
 850 void SetNewParms ()
 851 {
 852         // initialize parms for a new player
 853         parm1 = -(86400 * 366);
 854
 855         MUTATOR_CALLHOOK(SetNewParms);
 856 }
 857
 858 /*
 859 =============
 860 SetChangeParms
 861 =============
 862 */
 863 void SetChangeParms (entity this)
 864 {
 865         // save parms for level change
 866         parm1 = CS(this).parm_idlesince - time;
 867
 868         MUTATOR_CALLHOOK(SetChangeParms);
 869 }
 870
 871 /*
 872 =============
 873 DecodeLevelParms
 874 =============
 875 */
 876 void DecodeLevelParms(entity this)
 877 {
 878         // load parms
 879         CS(this).parm_idlesince = parm1;
 880         if (CS(this).parm_idlesince == -(86400 * 366))
 881                 CS(this).parm_idlesince = time;
 882
 883         // whatever happens, allow 60 seconds of idling directly after connect for map loading
 884         CS(this).parm_idlesince = max(CS(this).parm_idlesince, time - sv_maxidle + 60);
 885
 886         MUTATOR_CALLHOOK(DecodeLevelParms);
 887 }
 888
 889 /*
 890 =============
 891 ClientKill
 892
 893 Called when a client types 'kill' in the console
 894 =============
 895 */
 896
 897 .float clientkill_nexttime;
 898 void ClientKill_Now_TeamChange(entity this)
 899 {
 900         if(this.killindicator_teamchange == -1)
 901         {
 902                 JoinBestTeam( this, true );
 903         }
 904         else if(this.killindicator_teamchange == -2)
 905         {
 906                 if(blockSpectators)
 907                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
 908                 PutObserverInServer(this);
 909         }
 910         else
 911                 SV_ChangeTeam(this, this.killindicator_teamchange - 1);
 912         this.killindicator_teamchange = 0;
 913 }
 914
 915 void ClientKill_Now(entity this)
 916 {
 917         if(this.vehicle)
 918         {
 919             vehicles_exit(this.vehicle, VHEF_RELEASE);
 920             if(!this.killindicator_teamchange)
 921             {
 922             this.vehicle_health = -1;
 923             Damage(this, this, this, 1 , DEATH_KILL.m_id, DMG_NOWEP, this.origin, '0 0 0');
 924             }
 925         }
 926
 927         if(this.killindicator && !wasfreed(this.killindicator))
 928                 delete(this.killindicator);
 929
 930         this.killindicator = NULL;
 931
 932         if(this.killindicator_teamchange)
 933                 ClientKill_Now_TeamChange(this);
 934
 935         if (!IS_SPEC(this) && !IS_OBSERVER(this) && MUTATOR_CALLHOOK(ClientKill_Now, this) == false)
 936         {
 937                 Damage(this, this, this, 100000, DEATH_KILL.m_id, DMG_NOWEP, this.origin, '0 0 0');
 938         }
 939
 940         // now I am sure the player IS dead
 941 }
 942 void KillIndicator_Think(entity this)
 943 {
 944         if (game_stopped)
 945         {
 946                 this.owner.killindicator = NULL;
 947                 delete(this);
 948                 return;
 949         }
 950
 951         if (this.owner.alpha < 0 && !this.owner.vehicle)
 952         {
 953                 this.owner.killindicator = NULL;
 954                 delete(this);
 955                 return;
 956         }
 957
 958         if(this.cnt <= 0)
 959         {
 960                 ClientKill_Now(this.owner);
 961                 return;
 962         }
 963     else if(this.health == 1) // health == 1 means that it's silent
 964     {
 965         this.nextthink = time + 1;
 966         this.cnt -= 1;
 967     }
 968         else
 969         {
 970                 if(this.cnt <= 10)
 971                         setmodel(this, MDL_NUM(this.cnt));
 972                 if(IS_REAL_CLIENT(this.owner))
 973                 {
 974                         if(this.cnt <= 10)
 975                                 { Send_Notification(NOTIF_ONE, this.owner, MSG_ANNCE, Announcer_PickNumber(CNT_KILL, this.cnt)); }
 976                 }
 977                 this.nextthink = time + 1;
 978                 this.cnt -= 1;
 979         }
 980 }
 981
 982 float clientkilltime;
 983 void ClientKill_TeamChange (entity this, float targetteam) // 0 = don't change, -1 = auto, -2 = spec
 984 {
 985         float killtime;
 986         float starttime;
 987
 988         if (game_stopped)
 989                 return;
 990
 991         killtime = autocvar_g_balance_kill_delay;
 992
 993     if(MUTATOR_CALLHOOK(ClientKill, this, killtime))
 994         return;
 995     killtime = M_ARGV(1, float);
 996
 997         this.killindicator_teamchange = targetteam;
 998
 999     if(!this.killindicator)
1000         {
1001                 if(!IS_DEAD(this))
1002                 {
1003                         killtime = max(killtime, this.clientkill_nexttime - time);
1004                         this.clientkill_nexttime = time + killtime + autocvar_g_balance_kill_antispam;
1005                 }
1006
1007                 if(killtime <= 0 || !IS_PLAYER(this) || IS_DEAD(this))
1008                 {
1009                         ClientKill_Now(this);
1010                 }
1011                 else
1012                 {
1013                         starttime = max(time, clientkilltime);
1014
1015                         this.killindicator = spawn();
1016                         this.killindicator.owner = this;
1017                         this.killindicator.scale = 0.5;
1018                         setattachment(this.killindicator, this, "");
1019                         setorigin(this.killindicator, '0 0 52');
1020                         setthink(this.killindicator, KillIndicator_Think);
1021                         this.killindicator.nextthink = starttime + (this.lip) * 0.05;
1022                         clientkilltime = max(clientkilltime, this.killindicator.nextthink + 0.05);
1023                         this.killindicator.cnt = ceil(killtime);
1024                         this.killindicator.count = bound(0, ceil(killtime), 10);
1025                         //sprint(this, strcat("^1You'll be dead in ", ftos(this.killindicator.cnt), " seconds\n"));
1026
1027                         IL_EACH(g_clones, it.enemy == this && !(it.effects & CSQCMODEL_EF_RESPAWNGHOST),
1028                         {
1029                                 it.killindicator = spawn();
1030                                 it.killindicator.owner = it;
1031                                 it.killindicator.scale = 0.5;
1032                                 setattachment(it.killindicator, it, "");
1033                                 setorigin(it.killindicator, '0 0 52');
1034                                 setthink(it.killindicator, KillIndicator_Think);
1035                                 it.killindicator.nextthink = starttime + (it.lip) * 0.05;
1036                                 //clientkilltime = max(clientkilltime, it.killindicator.nextthink + 0.05);
1037                                 it.killindicator.cnt = ceil(killtime);
1038                         });
1039                         this.lip = 0;
1040                 }
1041         }
1042         if(this.killindicator)
1043         {
1044                 if(targetteam == 0) // just die
1045                 {
1046                         this.killindicator.colormod = '0 0 0';
1047                         if(IS_REAL_CLIENT(this))
1048                         if(this.killindicator.cnt > 0)
1049                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_TEAMCHANGE_SUICIDE, this.killindicator.cnt);
1050                 }
1051                 else if(targetteam == -1) // auto
1052                 {
1053                         this.killindicator.colormod = '0 1 0';
1054                         if(IS_REAL_CLIENT(this))
1055                         if(this.killindicator.cnt > 0)
1056                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_TEAMCHANGE_AUTO, this.killindicator.cnt);
1057                 }
1058                 else if(targetteam == -2) // spectate
1059                 {
1060                         this.killindicator.colormod = '0.5 0.5 0.5';
1061                         if(IS_REAL_CLIENT(this))
1062                         if(this.killindicator.cnt > 0)
1063                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_TEAMCHANGE_SPECTATE, this.killindicator.cnt);
1064                 }
1065                 else
1066                 {
1067                         this.killindicator.colormod = Team_ColorRGB(targetteam);
1068                         if(IS_REAL_CLIENT(this))
1069                         if(this.killindicator.cnt > 0)
1070                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, APP_TEAM_NUM(targetteam, CENTER_TEAMCHANGE), this.killindicator.cnt);
1071                 }
1072         }
1073
1074 }
1075
1076 void ClientKill (entity this)
1077 {
1078         if(game_stopped) return;
1079         if(this.player_blocked) return;
1080         if(STAT(FROZEN, this)) return;
1081
1082         ClientKill_TeamChange(this, 0);
1083 }
1084
1085 void FixClientCvars(entity e)
1086 {
1087         // send prediction settings to the client
1088         stuffcmd(e, "\nin_bindmap 0 0\n");
1089         if(autocvar_g_antilag == 3) // client side hitscan
1090                 stuffcmd(e, "cl_cmd settemp cl_prydoncursor_notrace 0\n");
1091         if(autocvar_sv_gentle)
1092                 stuffcmd(e, "cl_cmd settemp cl_gentle 1\n");
1093
1094         stuffcmd(e, sprintf("\ncl_jumpspeedcap_min \"%s\"\n", autocvar_sv_jumpspeedcap_min));
1095         stuffcmd(e, sprintf("\ncl_jumpspeedcap_max \"%s\"\n", autocvar_sv_jumpspeedcap_max));
1096
1097         MUTATOR_CALLHOOK(FixClientCvars, e);
1098 }
1099
1100 bool findinlist_abbrev(string tofind, string list)
1101 {
1102         if(list == "" || tofind == "")
1103                 return false; // empty list or search, just return
1104
1105         // this function allows abbreviated strings!
1106         FOREACH_WORD(list, it == substring(tofind, 0, strlen(it)),
1107         {
1108                 return true;
1109         });
1110
1111         return false;
1112 }
1113
1114 bool PlayerInIPList(entity p, string iplist)
1115 {
1116         // some safety checks (never allow local?)
1117         if(p.netaddress == "local" || p.netaddress == "" || !IS_REAL_CLIENT(p))
1118                 return false;
1119
1120         return findinlist_abbrev(p.netaddress, iplist);
1121 }
1122
1123 bool PlayerInIDList(entity p, string idlist)
1124 {
1125         // NOTE: we do NOT check crypto_idfp_signed here, an unsigned ID is fine too for this
1126         if(!p.crypto_idfp)
1127                 return false;
1128
1129         return findinlist_abbrev(p.crypto_idfp, idlist);
1130 }
1131
1132 bool PlayerInList(entity player, string list)
1133 {
1134         return boolean(PlayerInIDList(player, list) || PlayerInIPList(player, list));
1135 }
1136
1137 #ifdef DP_EXT_PRECONNECT
1138 /*
1139 =============
1140 ClientPreConnect
1141
1142 Called once (not at each match start) when a client begins a connection to the server
1143 =============
1144 */
1145 void ClientPreConnect(entity this)
1146 {
1147         if(autocvar_sv_eventlog)
1148         {
1149                 GameLogEcho(sprintf(":connect:%d:%d:%s",
1150                         this.playerid,
1151                         etof(this),
1152                         ((IS_REAL_CLIENT(this)) ? this.netaddress : "bot")
1153                 ));
1154         }
1155 }
1156 #endif
1157
1158 /**
1159 =============
1160 ClientConnect
1161
1162 Called when a client connects to the server
1163 =============
1164 */
1165 void ClientConnect(entity this)
1166 {
1167         if (Ban_MaybeEnforceBanOnce(this)) return;
1168         assert(!IS_CLIENT(this), return);
1169         this.flags |= FL_CLIENT;
1170         assert(player_count >= 0, player_count = 0);
1171
1172 #ifdef WATERMARK
1173         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_WATERMARK, WATERMARK);
1174 #endif
1175         TRANSMUTE(Client, this);
1176         CS(this).version_nagtime = time + 10 + random() * 10;
1177
1178         // identify the right forced team
1179         if (autocvar_g_campaign)
1180         {
1181                 if (IS_REAL_CLIENT(this)) // only players, not bots
1182                 {
1183                         switch (autocvar_g_campaign_forceteam)
1184                         {
1185                                 case 1: this.team_forced = NUM_TEAM_1; break;
1186                                 case 2: this.team_forced = NUM_TEAM_2; break;
1187                                 case 3: this.team_forced = NUM_TEAM_3; break;
1188                                 case 4: this.team_forced = NUM_TEAM_4; break;
1189                                 default: this.team_forced = 0;
1190                         }
1191                 }
1192         }
1193         else if (PlayerInList(this, autocvar_g_forced_team_red))    this.team_forced = NUM_TEAM_1;
1194         else if (PlayerInList(this, autocvar_g_forced_team_blue))   this.team_forced = NUM_TEAM_2;
1195         else if (PlayerInList(this, autocvar_g_forced_team_yellow)) this.team_forced = NUM_TEAM_3;
1196         else if (PlayerInList(this, autocvar_g_forced_team_pink))   this.team_forced = NUM_TEAM_4;
1197         else switch (autocvar_g_forced_team_otherwise)
1198         {
1199                 default: this.team_forced = 0; break;
1200                 case "red": this.team_forced = NUM_TEAM_1; break;
1201                 case "blue": this.team_forced = NUM_TEAM_2; break;
1202                 case "yellow": this.team_forced = NUM_TEAM_3; break;
1203                 case "pink": this.team_forced = NUM_TEAM_4; break;
1204                 case "spectate":
1205                 case "spectator":
1206                         this.team_forced = -1;
1207                         break;
1208         }
1209         if (!teamplay && this.team_forced > 0) this.team_forced = 0;
1210
1211         int playerid_save = this.playerid;
1212         this.playerid = 0; // silent
1213         JoinBestTeam(this, false); // if the team number is valid, keep it
1214         this.playerid = playerid_save;
1215
1216         if (autocvar_sv_spectate || autocvar_g_campaign || this.team_forced < 0) {
1217                 TRANSMUTE(Observer, this);
1218         } else {
1219                 if (!teamplay || autocvar_g_balance_teams) {
1220                         TRANSMUTE(Player, this);
1221                         campaign_bots_may_start = true;
1222                 } else {
1223                         TRANSMUTE(Observer, this); // do it anyway
1224                 }
1225         }
1226
1227         PlayerStats_GameReport_AddEvent(sprintf("kills-%d", this.playerid));
1228
1229         // always track bots, don't ask for cl_allow_uidtracking
1230         if (IS_BOT_CLIENT(this))
1231                 PlayerStats_GameReport_AddPlayer(this);
1232         else
1233                 CS(this).allowed_timeouts = autocvar_sv_timeout_number;
1234
1235         if (autocvar_sv_eventlog)
1236                 GameLogEcho(strcat(":join:", ftos(this.playerid), ":", ftos(etof(this)), ":", ((IS_REAL_CLIENT(this)) ? this.netaddress : "bot"), ":", playername(this, false)));
1237
1238         LogTeamchange(this.playerid, this.team, 1);
1239
1240         CS(this).just_joined = true;  // stop spamming the eventlog with additional lines when the client connects
1241
1242         if(teamplay && IS_PLAYER(this))
1243                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, APP_TEAM_NUM(this.team, INFO_JOIN_CONNECT_TEAM), this.netname);
1244         else
1245                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_JOIN_CONNECT, this.netname);
1246
1247         stuffcmd(this, clientstuff, "\n");
1248         stuffcmd(this, "cl_particles_reloadeffects\n"); // TODO do we still need this?
1249
1250         FixClientCvars(this);
1251
1252         // get version info from player
1253         stuffcmd(this, "cmd clientversion $gameversion\n");
1254
1255         // notify about available teams
1256         if (teamplay)
1257         {
1258                 CheckAllowedTeams(this);
1259                 int t = 0;
1260                 if (c1 >= 0) t |= BIT(0);
1261                 if (c2 >= 0) t |= BIT(1);
1262                 if (c3 >= 0) t |= BIT(2);
1263                 if (c4 >= 0) t |= BIT(3);
1264                 stuffcmd(this, sprintf("set _teams_available %d\n", t));
1265         }
1266         else
1267         {
1268                 stuffcmd(this, "set _teams_available 0\n");
1269         }
1270
1271         bot_relinkplayerlist();
1272
1273         CS(this).spectatortime = time;
1274         if (blockSpectators)
1275         {
1276                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
1277         }
1278
1279         CS(this).jointime = time;
1280
1281         if (IS_REAL_CLIENT(this))
1282         {
1283                 if (g_weaponarena_weapons == WEPSET(TUBA))
1284                         stuffcmd(this, "cl_cmd settemp chase_active 1\n");
1285         }
1286
1287         if (!sv_foginterval && world.fog != "")
1288                 stuffcmd(this, strcat("\nfog ", world.fog, "\nr_fog_exp2 0\nr_drawfog 1\n"));
1289
1290         if (autocvar_sv_teamnagger && !(autocvar_bot_vs_human && AvailableTeams() == 2))
1291                 if(!MUTATOR_CALLHOOK(HideTeamNagger, this))
1292                         send_CSQC_teamnagger();
1293
1294         CSQCMODEL_AUTOINIT(this);
1295
1296         CS(this).model_randomizer = random();
1297
1298         if (IS_REAL_CLIENT(this))
1299                 sv_notice_join(this);
1300
1301         // update physics stats (players can spawn before physics runs)
1302         Physics_UpdateStats(this);
1303
1304         IL_EACH(g_initforplayer, it.init_for_player, {
1305                 it.init_for_player(it, this);
1306         });
1307
1308         Handicap_Initialize(this);
1309
1310         MUTATOR_CALLHOOK(ClientConnect, this);
1311
1312         if (IS_REAL_CLIENT(this))
1313         {
1314                 if (!autocvar_g_campaign && !IS_PLAYER(this))
1315                 {
1316                         CS(this).motd_actived_time = -1;
1317                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOTD, getwelcomemessage(this));
1318                 }
1319         }
1320 }
1321 /*
1322 =============
1323 ClientDisconnect
1324
1325 Called when a client disconnects from the server
1326 =============
1327 */
1328 .entity chatbubbleentity;
1329 void ReadyCount();
1330 void ClientDisconnect(entity this)
1331 {
1332         assert(IS_CLIENT(this), return);
1333
1334         PlayerStats_GameReport_FinalizePlayer(this);
1335         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
1336         if (CS(this).active_minigame) part_minigame(this);
1337         if (IS_PLAYER(this)) Send_Effect(EFFECT_SPAWN_NEUTRAL, this.origin, '0 0 0', 1);
1338
1339         if (autocvar_sv_eventlog)
1340                 GameLogEcho(strcat(":part:", ftos(this.playerid)));
1341
1342         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_QUIT_DISCONNECT, this.netname);
1343
1344         if(IS_SPEC(this))
1345                 SetSpectatee(this, NULL);
1346
1347     MUTATOR_CALLHOOK(ClientDisconnect, this);
1348
1349         if (CS(this).netname_previous) strunzone(CS(this).netname_previous); // needs to be before the CS entity is removed!
1350         ClientState_detach(this);
1351
1352         Portal_ClearAll(this);
1353
1354         Unfreeze(this);
1355
1356         RemoveGrapplingHooks(this);
1357
1358         // Here, everything has been done that requires this player to be a client.
1359
1360         this.flags &= ~FL_CLIENT;
1361
1362         if (this.chatbubbleentity) delete(this.chatbubbleentity);
1363         if (this.killindicator) delete(this.killindicator);
1364
1365         WaypointSprite_PlayerGone(this);
1366
1367         bot_relinkplayerlist();
1368
1369         if (this.clientstatus) strunzone(this.clientstatus);
1370         if (this.weaponorder_byimpulse) strunzone(this.weaponorder_byimpulse);
1371         if (this.personal) delete(this.personal);
1372
1373         this.playerid = 0;
1374         ReadyCount();
1375         if (vote_called && IS_REAL_CLIENT(this)) VoteCount(false);
1376
1377         ONREMOVE(this);
1378 }
1379
1380 void ChatBubbleThink(entity this)
1381 {
1382         this.nextthink = time;
1383         if ((this.owner.alpha < 0) || this.owner.chatbubbleentity != this)
1384         {
1385                 if(this.owner) // but why can that ever be NULL?
1386                         this.owner.chatbubbleentity = NULL;
1387                 delete(this);
1388                 return;
1389         }
1390
1391         this.mdl = "";
1392
1393         if ( !IS_DEAD(this.owner) && IS_PLAYER(this.owner) )
1394         {
1395                 if ( CS(this.owner).active_minigame )
1396                         this.mdl = "models/sprites/minigame_busy.iqm";
1397                 else if (PHYS_INPUT_BUTTON_CHAT(this.owner))
1398                         this.mdl = "models/misc/chatbubble.spr";
1399         }
1400
1401         if ( this.model != this.mdl )
1402                 _setmodel(this, this.mdl);
1403
1404 }
1405
1406 void UpdateChatBubble(entity this)
1407 {
1408         if (this.alpha < 0)
1409                 return;
1410         // spawn a chatbubble entity if needed
1411         if (!this.chatbubbleentity)
1412         {
1413                 this.chatbubbleentity = new(chatbubbleentity);
1414                 this.chatbubbleentity.owner = this;
1415                 this.chatbubbleentity.exteriormodeltoclient = this;
1416                 setthink(this.chatbubbleentity, ChatBubbleThink);
1417                 this.chatbubbleentity.nextthink = time;
1418                 setmodel(this.chatbubbleentity, MDL_CHAT); // precision set below
1419                 //setorigin(this.chatbubbleentity, this.origin + '0 0 15' + this.maxs_z * '0 0 1');
1420                 setorigin(this.chatbubbleentity, '0 0 15' + this.maxs_z * '0 0 1');
1421                 setattachment(this.chatbubbleentity, this, "");  // sticks to moving player better, also conserves bandwidth
1422                 this.chatbubbleentity.mdl = this.chatbubbleentity.model;
1423                 //this.chatbubbleentity.model = "";
1424                 this.chatbubbleentity.effects = EF_LOWPRECISION;
1425         }
1426 }
1427
1428
1429 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
1430 // added to the model skins
1431 /*void UpdateColorModHack()
1432 {
1433         float c;
1434         c = this.clientcolors & 15;
1435         // LordHavoc: only bothering to support white, green, red, yellow, blue
1436              if (!teamplay) this.colormod = '0 0 0';
1437         else if (c ==  0) this.colormod = '1.00 1.00 1.00';
1438         else if (c ==  3) this.colormod = '0.10 1.73 0.10';
1439         else if (c ==  4) this.colormod = '1.73 0.10 0.10';
1440         else if (c == 12) this.colormod = '1.22 1.22 0.10';
1441         else if (c == 13) this.colormod = '0.10 0.10 1.73';
1442         else this.colormod = '1 1 1';
1443 }*/
1444
1445 void respawn(entity this)
1446 {
1447         if(this.alpha >= 0 && autocvar_g_respawn_ghosts)
1448         {
1449                 this.solid = SOLID_NOT;
1450                 this.takedamage = DAMAGE_NO;
1451                 set_movetype(this, MOVETYPE_FLY);
1452                 this.velocity = '0 0 1' * autocvar_g_respawn_ghosts_speed;
1453                 this.avelocity = randomvec() * autocvar_g_respawn_ghosts_speed * 3 - randomvec() * autocvar_g_respawn_ghosts_speed * 3;
1454                 this.effects |= CSQCMODEL_EF_RESPAWNGHOST;
1455                 Send_Effect(EFFECT_RESPAWN_GHOST, this.origin, '0 0 0', 1);
1456                 if(autocvar_g_respawn_ghosts_maxtime)
1457                         SUB_SetFade (this, time + autocvar_g_respawn_ghosts_maxtime / 2 + random () * (autocvar_g_respawn_ghosts_maxtime - autocvar_g_respawn_ghosts_maxtime / 2), 1.5);
1458         }
1459
1460         CopyBody(this, 1);
1461
1462         this.effects |= EF_NODRAW; // prevent another CopyBody
1463         PutClientInServer(this);
1464 }
1465
1466 void play_countdown(entity this, float finished, Sound samp)
1467 {
1468     TC(Sound, samp);
1469         if(IS_REAL_CLIENT(this))
1470                 if(floor(finished - time - frametime) != floor(finished - time))
1471                         if(finished - time < 6)
1472                                 sound (this, CH_INFO, samp, VOL_BASE, ATTEN_NORM);
1473 }
1474
1475 void player_powerups(entity this)
1476 {
1477         // add a way to see what the items were BEFORE all of these checks for the mutator hook
1478         int items_prev = this.items;
1479
1480         if((this.items & IT_USING_JETPACK) && !IS_DEAD(this) && !game_stopped)
1481                 this.modelflags |= MF_ROCKET;
1482         else
1483                 this.modelflags &= ~MF_ROCKET;
1484
1485         this.effects &= ~(EF_RED | EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT | EF_FLAME | EF_NODEPTHTEST);
1486
1487         if((this.alpha < 0 || IS_DEAD(this)) && !this.vehicle) // don't apply the flags if the player is gibbed
1488                 return;
1489
1490         Fire_ApplyDamage(this);
1491         Fire_ApplyEffect(this);
1492
1493         if (!g_instagib)
1494         {
1495                 if (this.items & ITEM_Strength.m_itemid)
1496                 {
1497                         play_countdown(this, this.strength_finished, SND_POWEROFF);
1498                         this.effects = this.effects | (EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT);
1499                         if (time > this.strength_finished)
1500                         {
1501                                 this.items = this.items - (this.items & ITEM_Strength.m_itemid);
1502                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERDOWN_STRENGTH, this.netname);
1503                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERDOWN_STRENGTH);
1504                         }
1505                 }
1506                 else
1507                 {
1508                         if (time < this.strength_finished)
1509                         {
1510                                 this.items = this.items | ITEM_Strength.m_itemid;
1511                                 if(!g_cts)
1512                                         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERUP_STRENGTH, this.netname);
1513                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERUP_STRENGTH);
1514                         }
1515                 }
1516                 if (this.items & ITEM_Shield.m_itemid)
1517                 {
1518                         play_countdown(this, this.invincible_finished, SND_POWEROFF);
1519                         this.effects = this.effects | (EF_RED | EF_ADDITIVE | EF_FULLBRIGHT);
1520                         if (time > this.invincible_finished)
1521                         {
1522                                 this.items = this.items - (this.items & ITEM_Shield.m_itemid);
1523                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERDOWN_SHIELD, this.netname);
1524                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERDOWN_SHIELD);
1525                         }
1526                 }
1527                 else
1528                 {
1529                         if (time < this.invincible_finished)
1530                         {
1531                                 this.items = this.items | ITEM_Shield.m_itemid;
1532                                 if(!g_cts)
1533                                         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERUP_SHIELD, this.netname);
1534                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERUP_SHIELD);
1535                         }
1536                 }
1537                 if (this.items & IT_SUPERWEAPON)
1538                 {
1539                         if (!(this.weapons & WEPSET_SUPERWEAPONS))
1540                         {
1541                                 this.superweapons_finished = 0;
1542                                 this.items = this.items - (this.items & IT_SUPERWEAPON);
1543                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_LOST, this.netname);
1544                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_LOST);
1545                         }
1546                         else if (this.items & IT_UNLIMITED_SUPERWEAPONS)
1547                         {
1548                                 // don't let them run out
1549                         }
1550                         else
1551                         {
1552                                 play_countdown(this, this.superweapons_finished, SND_POWEROFF);
1553                                 if (time > this.superweapons_finished)
1554                                 {
1555                                         this.items = this.items - (this.items & IT_SUPERWEAPON);
1556                                         this.weapons &= ~WEPSET_SUPERWEAPONS;
1557                                         //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_BROKEN, this.netname);
1558                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_BROKEN);
1559                                 }
1560                         }
1561                 }
1562                 else if(this.weapons & WEPSET_SUPERWEAPONS)
1563                 {
1564                         if (time < this.superweapons_finished || (this.items & IT_UNLIMITED_SUPERWEAPONS))
1565                         {
1566                                 this.items = this.items | IT_SUPERWEAPON;
1567                                 if(!g_cts)
1568                                         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_PICKUP, this.netname);
1569                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_PICKUP);
1570                         }
1571                         else
1572                         {
1573                                 this.superweapons_finished = 0;
1574                                 this.weapons &= ~WEPSET_SUPERWEAPONS;
1575                         }
1576                 }
1577                 else
1578                 {
1579                         this.superweapons_finished = 0;
1580                 }
1581         }
1582
1583         if(autocvar_g_nodepthtestplayers)
1584                 this.effects = this.effects | EF_NODEPTHTEST;
1585
1586         if(autocvar_g_fullbrightplayers)
1587                 this.effects = this.effects | EF_FULLBRIGHT;
1588
1589         if (time >= game_starttime)
1590         if (time < this.spawnshieldtime)
1591                 this.effects = this.effects | (EF_ADDITIVE | EF_FULLBRIGHT);
1592
1593         MUTATOR_CALLHOOK(PlayerPowerups, this, items_prev);
1594 }
1595
1596 float CalcRegen(float current, float stable, float regenfactor, float regenframetime)
1597 {
1598         if(current > stable)
1599                 return current;
1600         else if(current > stable - 0.25) // when close enough, "snap"
1601                 return stable;
1602         else
1603                 return min(stable, current + (stable - current) * regenfactor * regenframetime);
1604 }
1605
1606 float CalcRot(float current, float stable, float rotfactor, float rotframetime)
1607 {
1608         if(current < stable)
1609                 return current;
1610         else if(current < stable + 0.25) // when close enough, "snap"
1611                 return stable;
1612         else
1613                 return max(stable, current + (stable - current) * rotfactor * rotframetime);
1614 }
1615
1616 float CalcRotRegen(float current, float regenstable, float regenfactor, float regenlinear, float regenframetime, float rotstable, float rotfactor, float rotlinear, float rotframetime, float limit)
1617 {
1618         if(current > rotstable)
1619         {
1620                 if(rotframetime > 0)
1621                 {
1622                         current = CalcRot(current, rotstable, rotfactor, rotframetime);
1623                         current = max(rotstable, current - rotlinear * rotframetime);
1624                 }
1625         }
1626         else if(current < regenstable)
1627         {
1628                 if(regenframetime > 0)
1629                 {
1630                         current = CalcRegen(current, regenstable, regenfactor, regenframetime);
1631                         current = min(regenstable, current + regenlinear * regenframetime);
1632                 }
1633         }
1634
1635         if(current > limit)
1636                 current = limit;
1637
1638         return current;
1639 }
1640
1641 void player_regen(entity this)
1642 {
1643         float max_mod, regen_mod, rot_mod, limit_mod;
1644         max_mod = regen_mod = rot_mod = limit_mod = 1;
1645
1646         float regen_health = autocvar_g_balance_health_regen;
1647         float regen_health_linear = autocvar_g_balance_health_regenlinear;
1648         float regen_health_rot = autocvar_g_balance_health_rot;
1649         float regen_health_rotlinear = autocvar_g_balance_health_rotlinear;
1650         float regen_health_stable = autocvar_g_balance_health_regenstable;
1651         float regen_health_rotstable = autocvar_g_balance_health_rotstable;
1652         bool mutator_returnvalue = MUTATOR_CALLHOOK(PlayerRegen, this, max_mod, regen_mod, rot_mod, limit_mod, regen_health, regen_health_linear, regen_health_rot,
1653                 regen_health_rotlinear, regen_health_stable, regen_health_rotstable);
1654         max_mod = M_ARGV(1, float);
1655         regen_mod = M_ARGV(2, float);
1656         rot_mod = M_ARGV(3, float);
1657         limit_mod = M_ARGV(4, float);
1658         regen_health = M_ARGV(5, float);
1659         regen_health_linear = M_ARGV(6, float);
1660         regen_health_rot = M_ARGV(7, float);
1661         regen_health_rotlinear = M_ARGV(8, float);
1662         regen_health_stable = M_ARGV(9, float);
1663         regen_health_rotstable = M_ARGV(10, float);
1664
1665         if(!mutator_returnvalue)
1666         if(!STAT(FROZEN, this))
1667         {
1668                 float mina, maxa, limith, limita;
1669                 maxa = autocvar_g_balance_armor_rotstable;
1670                 mina = autocvar_g_balance_armor_regenstable;
1671                 limith = GetResourceLimit(this, RESOURCE_HEALTH);
1672                 limita = GetResourceLimit(this, RESOURCE_ARMOR);
1673
1674                 regen_health_rotstable = regen_health_rotstable * max_mod;
1675                 regen_health_stable = regen_health_stable * max_mod;
1676                 limith = limith * limit_mod;
1677                 limita = limita * limit_mod;
1678
1679                 this.armorvalue = CalcRotRegen(this.armorvalue, mina, autocvar_g_balance_armor_regen, autocvar_g_balance_armor_regenlinear, regen_mod * frametime * (time > this.pauseregen_finished), maxa, autocvar_g_balance_armor_rot, autocvar_g_balance_armor_rotlinear, rot_mod * frametime * (time > this.pauserotarmor_finished), limita);
1680                 this.health = CalcRotRegen(this.health, regen_health_stable, regen_health, regen_health_linear, regen_mod * frametime * (time > this.pauseregen_finished), regen_health_rotstable, regen_health_rot, regen_health_rotlinear, rot_mod * frametime * (time > this.pauserothealth_finished), limith);
1681         }
1682
1683         // if player rotted to death...  die!
1684         // check this outside above checks, as player may still be able to rot to death
1685         if(this.health < 1)
1686         {
1687                 if(this.vehicle)
1688                         vehicles_exit(this.vehicle, VHEF_RELEASE);
1689                 if(this.event_damage)
1690                         this.event_damage(this, this, this, 1, DEATH_ROT.m_id, DMG_NOWEP, this.origin, '0 0 0');
1691         }
1692
1693         if (!(this.items & IT_UNLIMITED_WEAPON_AMMO))
1694         {
1695                 float minf, maxf, limitf;
1696
1697                 maxf = autocvar_g_balance_fuel_rotstable;
1698                 minf = autocvar_g_balance_fuel_regenstable;
1699                 limitf = GetResourceLimit(this, RESOURCE_FUEL);
1700
1701                 this.ammo_fuel = CalcRotRegen(this.ammo_fuel, minf, autocvar_g_balance_fuel_regen, autocvar_g_balance_fuel_regenlinear, frametime * (time > this.pauseregen_finished) * ((this.items & ITEM_JetpackRegen.m_itemid) != 0), maxf, autocvar_g_balance_fuel_rot, autocvar_g_balance_fuel_rotlinear, frametime * (time > this.pauserotfuel_finished), limitf);
1702         }
1703         // Ugly hack to make sure the health and armor don't go beyond hard limit.
1704         // TODO: Remove this hack when all code uses GivePlayerHealth and
1705         // GivePlayerArmor.
1706         if (this.health > RESOURCE_AMOUNT_HARD_LIMIT)
1707         {
1708                 this.health = RESOURCE_AMOUNT_HARD_LIMIT;
1709         }
1710         if (this.armorvalue > RESOURCE_AMOUNT_HARD_LIMIT)
1711         {
1712                 this.armorvalue = RESOURCE_AMOUNT_HARD_LIMIT;
1713         }
1714         // End hack.
1715 }
1716
1717 bool zoomstate_set;
1718 void SetZoomState(entity this, float newzoom)
1719 {
1720         if(newzoom != CS(this).zoomstate)
1721         {
1722                 CS(this).zoomstate = newzoom;
1723                 ClientData_Touch(this);
1724         }
1725         zoomstate_set = true;
1726 }
1727
1728 void GetPressedKeys(entity this)
1729 {
1730         MUTATOR_CALLHOOK(GetPressedKeys, this);
1731         int keys = STAT(PRESSED_KEYS, this);
1732         keys = BITSET(keys, KEY_FORWARD,        CS(this).movement.x > 0);
1733         keys = BITSET(keys, KEY_BACKWARD,       CS(this).movement.x < 0);
1734         keys = BITSET(keys, KEY_RIGHT,          CS(this).movement.y > 0);
1735         keys = BITSET(keys, KEY_LEFT,           CS(this).movement.y < 0);
1736
1737         keys = BITSET(keys, KEY_JUMP,           PHYS_INPUT_BUTTON_JUMP(this));
1738         keys = BITSET(keys, KEY_CROUCH,         PHYS_INPUT_BUTTON_CROUCH(this));
1739         keys = BITSET(keys, KEY_ATCK,           PHYS_INPUT_BUTTON_ATCK(this));
1740         keys = BITSET(keys, KEY_ATCK2,          PHYS_INPUT_BUTTON_ATCK2(this));
1741         CS(this).pressedkeys = keys; // store for other users
1742
1743         STAT(PRESSED_KEYS, this) = keys;
1744 }
1745
1746 /*
1747 ======================
1748 spectate mode routines
1749 ======================
1750 */
1751
1752 void SpectateCopy(entity this, entity spectatee)
1753 {
1754     TC(Client, this); TC(Client, spectatee);
1755
1756         MUTATOR_CALLHOOK(SpectateCopy, spectatee, this);
1757         PS(this) = PS(spectatee);
1758         this.armortype = spectatee.armortype;
1759         this.armorvalue = spectatee.armorvalue;
1760         this.ammo_cells = spectatee.ammo_cells;
1761         this.ammo_plasma = spectatee.ammo_plasma;
1762         this.ammo_shells = spectatee.ammo_shells;
1763         this.ammo_nails = spectatee.ammo_nails;
1764         this.ammo_rockets = spectatee.ammo_rockets;
1765         this.ammo_fuel = spectatee.ammo_fuel;
1766         this.effects = spectatee.effects & EFMASK_CHEAP; // eat performance
1767         this.health = spectatee.health;
1768         CS(this).impulse = 0;
1769         this.items = spectatee.items;
1770         STAT(LAST_PICKUP, this) = STAT(LAST_PICKUP, spectatee);
1771         STAT(HIT_TIME, this) = STAT(HIT_TIME, spectatee);
1772         this.strength_finished = spectatee.strength_finished;
1773         this.invincible_finished = spectatee.invincible_finished;
1774         this.superweapons_finished = spectatee.superweapons_finished;
1775         STAT(PRESSED_KEYS, this) = STAT(PRESSED_KEYS, spectatee);
1776         this.weapons = spectatee.weapons;
1777         this.punchangle = spectatee.punchangle;
1778         this.view_ofs = spectatee.view_ofs;
1779         this.velocity = spectatee.velocity;
1780         this.dmg_take = spectatee.dmg_take;
1781         this.dmg_save = spectatee.dmg_save;
1782         this.dmg_inflictor = spectatee.dmg_inflictor;
1783         this.v_angle = spectatee.v_angle;
1784         this.angles = spectatee.v_angle;
1785         STAT(FROZEN, this) = STAT(FROZEN, spectatee);
1786         STAT(REVIVE_PROGRESS, this) = STAT(REVIVE_PROGRESS, spectatee);
1787         this.viewloc = spectatee.viewloc;
1788         if(!PHYS_INPUT_BUTTON_USE(this) && STAT(CAMERA_SPECTATOR, this) != 2)
1789                 this.fixangle = true;
1790         setorigin(this, spectatee.origin);
1791         setsize(this, spectatee.mins, spectatee.maxs);
1792         SetZoomState(this, CS(spectatee).zoomstate);
1793
1794     anticheat_spectatecopy(this, spectatee);
1795         STAT(HUD, this) = STAT(HUD, spectatee);
1796         if(spectatee.vehicle)
1797     {
1798         this.angles = spectatee.v_angle;
1799
1800         //this.fixangle = false;
1801         //this.velocity = spectatee.vehicle.velocity;
1802         this.vehicle_health = spectatee.vehicle_health;
1803         this.vehicle_shield = spectatee.vehicle_shield;
1804         this.vehicle_energy = spectatee.vehicle_energy;
1805         this.vehicle_ammo1 = spectatee.vehicle_ammo1;
1806         this.vehicle_ammo2 = spectatee.vehicle_ammo2;
1807         this.vehicle_reload1 = spectatee.vehicle_reload1;
1808         this.vehicle_reload2 = spectatee.vehicle_reload2;
1809
1810         //msg_entity = this;
1811
1812        // WriteByte (MSG_ONE, SVC_SETVIEWANGLES);
1813             //WriteAngle(MSG_ONE,  spectatee.v_angle.x);
1814            // WriteAngle(MSG_ONE,  spectatee.v_angle.y);
1815            // WriteAngle(MSG_ONE,  spectatee.v_angle.z);
1816
1817         //WriteByte (MSG_ONE, SVC_SETVIEW);
1818         //    WriteEntity(MSG_ONE, this);
1819         //makevectors(spectatee.v_angle);
1820         //setorigin(this, spectatee.origin - v_forward * 400 + v_up * 300);*/
1821     }
1822 }
1823
1824 bool SpectateUpdate(entity this)
1825 {
1826         if(!this.enemy)
1827                 return false;
1828
1829         if(!IS_PLAYER(this.enemy) || this == this.enemy)
1830         {
1831                 SetSpectatee(this, NULL);
1832                 return false;
1833         }
1834
1835         SpectateCopy(this, this.enemy);
1836
1837         return true;
1838 }
1839
1840 bool SpectateSet(entity this)
1841 {
1842         if(!IS_PLAYER(this.enemy))
1843                 return false;
1844
1845         ClientData_Touch(this.enemy);
1846
1847         msg_entity = this;
1848         WriteByte(MSG_ONE, SVC_SETVIEW);
1849         WriteEntity(MSG_ONE, this.enemy);
1850         set_movetype(this, MOVETYPE_NONE);
1851         accuracy_resend(this);
1852
1853         if(!SpectateUpdate(this))
1854                 PutObserverInServer(this);
1855
1856         return true;
1857 }
1858
1859 void SetSpectatee_status(entity this, int spectatee_num)
1860 {
1861         int oldspectatee_status = CS(this).spectatee_status;
1862         CS(this).spectatee_status = spectatee_num;
1863
1864         if (CS(this).spectatee_status != oldspectatee_status)
1865         {
1866                 ClientData_Touch(this);
1867                 if (g_race || g_cts) race_InitSpectator();
1868         }
1869 }
1870
1871 void SetSpectatee(entity this, entity spectatee)
1872 {
1873         if(IS_BOT_CLIENT(this))
1874                 return; // bots abuse .enemy, this code is useless to them
1875
1876         entity old_spectatee = this.enemy;
1877
1878         this.enemy = spectatee;
1879
1880         // WEAPONTODO
1881         // these are required to fix the spectator bug with arc
1882         if(old_spectatee)
1883         {
1884                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1885                 {
1886                         .entity weaponentity = weaponentities[slot];
1887                         if(old_spectatee.(weaponentity).arc_beam)
1888                                 old_spectatee.(weaponentity).arc_beam.SendFlags |= ARC_SF_SETTINGS;
1889                 }
1890         }
1891         if(this.enemy)
1892         {
1893                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1894                 {
1895                         .entity weaponentity = weaponentities[slot];
1896                         if(this.enemy.(weaponentity).arc_beam)
1897                                 this.enemy.(weaponentity).arc_beam.SendFlags |= ARC_SF_SETTINGS;
1898                 }
1899         }
1900
1901         if (this.enemy)
1902                 SetSpectatee_status(this, etof(this.enemy));
1903
1904         // needed to update spectator list
1905         if(old_spectatee) { ClientData_Touch(old_spectatee); }
1906 }
1907
1908 bool Spectate(entity this, entity pl)
1909 {
1910         if(MUTATOR_CALLHOOK(SpectateSet, this, pl))
1911                 return false;
1912         pl = M_ARGV(1, entity);
1913
1914         SetSpectatee(this, pl);
1915         return SpectateSet(this);
1916 }
1917
1918 bool SpectateNext(entity this)
1919 {
1920         entity ent = find(this.enemy, classname, STR_PLAYER);
1921
1922         if (MUTATOR_CALLHOOK(SpectateNext, this, ent))
1923                 ent = M_ARGV(1, entity);
1924         else if (!ent)
1925                 ent = find(ent, classname, STR_PLAYER);
1926
1927         if(ent) { SetSpectatee(this, ent); }
1928
1929         return SpectateSet(this);
1930 }
1931
1932 bool SpectatePrev(entity this)
1933 {
1934         // NOTE: chain order is from the highest to the lower entnum (unlike find)
1935         entity ent = findchain(classname, STR_PLAYER);
1936         if (!ent) // no player
1937                 return false;
1938
1939         entity first = ent;
1940         // skip players until current spectated player
1941         if(this.enemy)
1942         while(ent && ent != this.enemy)
1943                 ent = ent.chain;
1944
1945         switch (MUTATOR_CALLHOOK(SpectatePrev, this, ent, first))
1946         {
1947                 case MUT_SPECPREV_FOUND:
1948                     ent = M_ARGV(1, entity);
1949                     break;
1950                 case MUT_SPECPREV_RETURN:
1951                     return true;
1952                 case MUT_SPECPREV_CONTINUE:
1953                 default:
1954                 {
1955                         if(ent.chain)
1956                                 ent = ent.chain;
1957                         else
1958                                 ent = first;
1959                         break;
1960                 }
1961         }
1962
1963         SetSpectatee(this, ent);
1964         return SpectateSet(this);
1965 }
1966
1967 /*
1968 =============
1969 ShowRespawnCountdown()
1970
1971 Update a respawn countdown display.
1972 =============
1973 */
1974 void ShowRespawnCountdown(entity this)
1975 {
1976         float number;
1977         if(!IS_DEAD(this)) // just respawned?
1978                 return;
1979         else
1980         {
1981                 number = ceil(this.respawn_time - time);
1982                 if(number <= 0)
1983                         return;
1984                 if(number <= this.respawn_countdown)
1985                 {
1986                         this.respawn_countdown = number - 1;
1987                         if(ceil(this.respawn_time - (time + 0.5)) == number) // only say it if it is the same number even in 0.5s; to prevent overlapping sounds
1988                                 { Send_Notification(NOTIF_ONE, this, MSG_ANNCE, Announcer_PickNumber(CNT_RESPAWN, number)); }
1989                 }
1990         }
1991 }
1992
1993 .bool team_selected;
1994 bool ShowTeamSelection(entity this)
1995 {
1996         if(!teamplay || autocvar_g_campaign || autocvar_g_balance_teams || this.team_selected || (CS(this).wasplayer && autocvar_g_changeteam_banned) || this.team_forced > 0)
1997                 return false;
1998         stuffcmd(this, "menu_showteamselect\n");
1999         return true;
2000 }
2001 void Join(entity this)
2002 {
2003         TRANSMUTE(Player, this);
2004
2005         if(!this.team_selected)
2006         if(autocvar_g_campaign || autocvar_g_balance_teams)
2007                 JoinBestTeam(this, true);
2008
2009         if(autocvar_g_campaign)
2010                 campaign_bots_may_start = true;
2011
2012         Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_PREVENT_JOIN);
2013
2014         PutClientInServer(this);
2015
2016         if(IS_PLAYER(this))
2017         if(teamplay && this.team != -1)
2018                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, APP_TEAM_NUM(this.team, INFO_JOIN_PLAY_TEAM), this.netname);
2019         else
2020                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_JOIN_PLAY, this.netname);
2021         this.team_selected = false;
2022 }
2023
2024 /**
2025  * Determines whether the player is allowed to join. This depends on cvar
2026  * g_maxplayers, if it isn't used this function always return true, otherwise
2027  * it checks whether the number of currently playing players exceeds g_maxplayers.
2028  * @return int number of free slots for players, 0 if none
2029  */
2030 int nJoinAllowed(entity this, entity ignore)
2031 {
2032         if(!ignore)
2033         // this is called that way when checking if anyone may be able to join (to build qcstatus)
2034         // so report 0 free slots if restricted
2035         {
2036                 if(autocvar_g_forced_team_otherwise == "spectate")
2037                         return 0;
2038                 if(autocvar_g_forced_team_otherwise == "spectator")
2039                         return 0;
2040         }
2041
2042         if(this && this.team_forced < 0)
2043                 return 0; // forced spectators can never join
2044
2045         // TODO simplify this
2046         int totalClients = 0;
2047         int currentlyPlaying = 0;
2048         FOREACH_CLIENT(true, {
2049                 if(it != ignore)
2050                         ++totalClients;
2051                 if(IS_REAL_CLIENT(it))
2052                 if(IS_PLAYER(it) || it.caplayer)
2053                         ++currentlyPlaying;
2054         });
2055
2056         float free_slots = 0;
2057         if (!autocvar_g_maxplayers)
2058                 free_slots = maxclients - totalClients;
2059         else if(currentlyPlaying < autocvar_g_maxplayers)
2060                 free_slots = min(maxclients - totalClients, autocvar_g_maxplayers - currentlyPlaying);
2061
2062         static float join_prevent_msg_time = 0;
2063         if(this && ignore && !free_slots && time > join_prevent_msg_time)
2064         {
2065                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_JOIN_PREVENT);
2066                 join_prevent_msg_time = time + 3;
2067         }
2068
2069         return free_slots;
2070 }
2071
2072 /**
2073  * Checks whether the client is an observer or spectator, if so, he will get kicked after
2074  * g_maxplayers_spectator_blocktime seconds
2075  */
2076 void checkSpectatorBlock(entity this)
2077 {
2078         if(IS_SPEC(this) || IS_OBSERVER(this))
2079         if(!this.caplayer)
2080         if(IS_REAL_CLIENT(this))
2081         {
2082                 if( time > (CS(this).spectatortime + autocvar_g_maxplayers_spectator_blocktime) ) {
2083                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_QUIT_KICK_SPECTATING);
2084                         dropclient(this);
2085                 }
2086         }
2087 }
2088
2089 void PrintWelcomeMessage(entity this)
2090 {
2091         if(CS(this).motd_actived_time == 0)
2092         {
2093                 if (autocvar_g_campaign) {
2094                         if ((IS_PLAYER(this) && PHYS_INPUT_BUTTON_INFO(this)) || (!IS_PLAYER(this))) {
2095                                 CS(this).motd_actived_time = time;
2096                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOTD, campaign_message);
2097                         }
2098                 } else {
2099                         if (PHYS_INPUT_BUTTON_INFO(this)) {
2100                                 CS(this).motd_actived_time = time;
2101                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOTD, getwelcomemessage(this));
2102                         }
2103                 }
2104         }
2105         else if(CS(this).motd_actived_time > 0) // showing MOTD or campaign message
2106         {
2107                 if (autocvar_g_campaign) {
2108                         if (PHYS_INPUT_BUTTON_INFO(this))
2109                                 CS(this).motd_actived_time = time;
2110                         else if ((time - CS(this).motd_actived_time > 2) && IS_PLAYER(this)) { // hide it some seconds after BUTTON_INFO has been released
2111                                 CS(this).motd_actived_time = 0;
2112                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_MOTD);
2113                         }
2114                 } else {
2115                         if (PHYS_INPUT_BUTTON_INFO(this))
2116                                 CS(this).motd_actived_time = time;
2117                         else if (time - CS(this).motd_actived_time > 2) { // hide it some seconds after BUTTON_INFO has been released
2118                                 CS(this).motd_actived_time = 0;
2119                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_MOTD);
2120                         }
2121                 }
2122         }
2123         else //if(CS(this).motd_actived_time < 0) // just connected, motd is active
2124         {
2125                 if(PHYS_INPUT_BUTTON_INFO(this)) // BUTTON_INFO hides initial MOTD
2126                         CS(this).motd_actived_time = -2; // wait until BUTTON_INFO gets released
2127                 else if(CS(this).motd_actived_time == -2 || IS_PLAYER(this) || IS_SPEC(this))
2128                 {
2129                         // instanctly hide MOTD
2130                         CS(this).motd_actived_time = 0;
2131                         Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_MOTD);
2132                 }
2133         }
2134 }
2135
2136 bool joinAllowed(entity this)
2137 {
2138         if (CS(this).version_mismatch) return false;
2139         if (!nJoinAllowed(this, this)) return false;
2140         if (teamplay && lockteams) return false;
2141         if (ShowTeamSelection(this)) return false;
2142         if (MUTATOR_CALLHOOK(ForbidSpawn, this)) return false;
2143         return true;
2144 }
2145
2146 .int items_added;
2147 bool PlayerThink(entity this)
2148 {
2149         if (game_stopped || intermission_running) {
2150                 this.modelflags &= ~MF_ROCKET;
2151                 if(intermission_running)
2152                         IntermissionThink(this);
2153                 return false;
2154         }
2155
2156         if (timeout_status == TIMEOUT_ACTIVE) {
2157         // don't allow the player to turn around while game is paused
2158                 // FIXME turn this into CSQC stuff
2159                 this.v_angle = this.lastV_angle;
2160                 this.angles = this.lastV_angle;
2161                 this.fixangle = true;
2162         }
2163
2164         if (frametime) player_powerups(this);
2165
2166         if (IS_DEAD(this)) {
2167                 if (this.personal && g_race_qualifying) {
2168                         if (time > this.respawn_time) {
2169                                 STAT(RESPAWN_TIME, this) = this.respawn_time = time + 1; // only retry once a second
2170                                 respawn(this);
2171                                 CS(this).impulse = CHIMPULSE_SPEEDRUN.impulse;
2172                         }
2173                 } else {
2174                         if (frametime) player_anim(this);
2175
2176                         if (this.respawn_flags & RESPAWN_DENY)
2177                         {
2178                                 STAT(RESPAWN_TIME, this) = 0;
2179                                 return false;
2180                         }
2181
2182                         bool button_pressed = (PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_JUMP(this) || PHYS_INPUT_BUTTON_ATCK2(this) || PHYS_INPUT_BUTTON_HOOK(this) || PHYS_INPUT_BUTTON_USE(this));
2183
2184                         switch(this.deadflag)
2185                         {
2186                                 case DEAD_DYING:
2187                                 {
2188                                         if ((this.respawn_flags & RESPAWN_FORCE) && !(this.respawn_time < this.respawn_time_max))
2189                                                 this.deadflag = DEAD_RESPAWNING;
2190                                         else if (!button_pressed || (time >= this.respawn_time_max && (this.respawn_flags & RESPAWN_FORCE)))
2191                                                 this.deadflag = DEAD_DEAD;
2192                                         break;
2193                                 }
2194                                 case DEAD_DEAD:
2195                                 {
2196                                         if (button_pressed)
2197                                                 this.deadflag = DEAD_RESPAWNABLE;
2198                                         else if (time >= this.respawn_time_max && (this.respawn_flags & RESPAWN_FORCE))
2199                                                 this.deadflag = DEAD_RESPAWNING;
2200                                         break;
2201                                 }
2202                                 case DEAD_RESPAWNABLE:
2203                                 {
2204                                         if (!button_pressed || (this.respawn_flags & RESPAWN_FORCE))
2205                                                 this.deadflag = DEAD_RESPAWNING;
2206                                         break;
2207                                 }
2208                                 case DEAD_RESPAWNING:
2209                                 {
2210                                         if (time > this.respawn_time)
2211                                         {
2212                                                 this.respawn_time = time + 1; // only retry once a second
2213                                                 this.respawn_time_max = this.respawn_time;
2214                                                 respawn(this);
2215                                         }
2216                                         break;
2217                                 }
2218                         }
2219
2220                         ShowRespawnCountdown(this);
2221
2222                         if (this.respawn_flags & RESPAWN_SILENT)
2223                                 STAT(RESPAWN_TIME, this) = 0;
2224                         else if ((this.respawn_flags & RESPAWN_FORCE) && this.respawn_time < this.respawn_time_max)
2225                         {
2226                                 if (time < this.respawn_time)
2227                                         STAT(RESPAWN_TIME, this) = this.respawn_time;
2228                                 else if (this.deadflag != DEAD_RESPAWNING)
2229                                         STAT(RESPAWN_TIME, this) = -this.respawn_time_max;
2230                         }
2231                         else
2232                                 STAT(RESPAWN_TIME, this) = this.respawn_time;
2233                 }
2234
2235                 // if respawning, invert stat_respawn_time to indicate this, the client translates it
2236                 if (this.deadflag == DEAD_RESPAWNING && STAT(RESPAWN_TIME, this) > 0)
2237                         STAT(RESPAWN_TIME, this) *= -1;
2238
2239                 return false;
2240         }
2241
2242         bool have_hook = false;
2243         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2244         {
2245                 .entity weaponentity = weaponentities[slot];
2246                 if(this.(weaponentity).hook.state)
2247                 {
2248                         have_hook = true;
2249                         break;
2250                 }
2251         }
2252         bool do_crouch = PHYS_INPUT_BUTTON_CROUCH(this);
2253         if (have_hook) {
2254                 do_crouch = false;
2255         } else if (this.waterlevel >= WATERLEVEL_SWIMMING) {
2256                 do_crouch = false;
2257         } else if (this.vehicle) {
2258                 do_crouch = false;
2259         } else if (STAT(FROZEN, this)) {
2260                 do_crouch = false;
2261     }
2262
2263         if (do_crouch) {
2264                 if (!this.crouch) {
2265                         this.crouch = true;
2266                         this.view_ofs = STAT(PL_CROUCH_VIEW_OFS, this);
2267                         setsize(this, STAT(PL_CROUCH_MIN, this), STAT(PL_CROUCH_MAX, this));
2268                         // setanim(this, this.anim_duck, false, true, true); // this anim is BROKEN anyway
2269                 }
2270         } else if (this.crouch) {
2271         tracebox(this.origin, STAT(PL_MIN, this), STAT(PL_MAX, this), this.origin, false, this);
2272         if (!trace_startsolid) {
2273             this.crouch = false;
2274             this.view_ofs = STAT(PL_VIEW_OFS, this);
2275             setsize(this, STAT(PL_MIN, this), STAT(PL_MAX, this));
2276         }
2277         }
2278
2279         FixPlayermodel(this);
2280
2281         // LordHavoc: allow firing on move frames (sub-ticrate), this gives better timing on slow servers
2282         //if(frametime)
2283         {
2284                 this.items &= ~this.items_added;
2285
2286                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2287                 {
2288                         .entity weaponentity = weaponentities[slot];
2289                         W_WeaponFrame(this, weaponentity);
2290                 }
2291
2292                 this.items_added = 0;
2293                 if ((this.items & ITEM_Jetpack.m_itemid) && ((this.items & ITEM_JetpackRegen.m_itemid) || this.ammo_fuel >= 0.01))
2294             this.items_added |= IT_FUEL;
2295
2296                 this.items |= this.items_added;
2297         }
2298
2299         player_regen(this);
2300
2301         // WEAPONTODO: Add a weapon request for this
2302         // rot vortex charge to the charge limit
2303         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2304         {
2305                 .entity weaponentity = weaponentities[slot];
2306                 if (WEP_CVAR(vortex, charge_rot_rate) && this.(weaponentity).vortex_charge > WEP_CVAR(vortex, charge_limit) && this.(weaponentity).vortex_charge_rottime < time)
2307                         this.(weaponentity).vortex_charge = bound(WEP_CVAR(vortex, charge_limit), this.(weaponentity).vortex_charge - WEP_CVAR(vortex, charge_rot_rate) * frametime / W_TICSPERFRAME, 1);
2308         }
2309
2310         if (frametime) player_anim(this);
2311
2312         // secret status
2313         secrets_setstatus(this);
2314
2315         // monsters status
2316         monsters_setstatus(this);
2317
2318         this.dmg_team = max(0, this.dmg_team - autocvar_g_teamdamage_resetspeed * frametime);
2319
2320         return true;
2321 }
2322
2323 void ObserverThink(entity this)
2324 {
2325         if ( CS(this).impulse )
2326         {
2327                 MinigameImpulse(this, CS(this).impulse);
2328                 CS(this).impulse = 0;
2329         }
2330
2331         if (this.flags & FL_JUMPRELEASED) {
2332                 if (PHYS_INPUT_BUTTON_JUMP(this) && joinAllowed(this)) {
2333                         this.flags &= ~FL_JUMPRELEASED;
2334                         this.flags |= FL_SPAWNING;
2335                 } else if(PHYS_INPUT_BUTTON_ATCK(this) && !CS(this).version_mismatch) {
2336                         this.flags &= ~FL_JUMPRELEASED;
2337                         if(SpectateNext(this)) {
2338                                 TRANSMUTE(Spectator, this);
2339                         }
2340                 } else {
2341                         int preferred_movetype = ((!PHYS_INPUT_BUTTON_USE(this) ? CS(this).cvar_cl_clippedspectating : !CS(this).cvar_cl_clippedspectating) ? MOVETYPE_FLY_WORLDONLY : MOVETYPE_NOCLIP);
2342                         set_movetype(this, preferred_movetype);
2343                 }
2344         } else {
2345                 if (!(PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_JUMP(this))) {
2346                         this.flags |= FL_JUMPRELEASED;
2347                         if(this.flags & FL_SPAWNING)
2348                         {
2349                                 this.flags &= ~FL_SPAWNING;
2350                                 Join(this);
2351                                 return;
2352                         }
2353                 }
2354         }
2355 }
2356
2357 void SpectatorThink(entity this)
2358 {
2359         if ( CS(this).impulse )
2360         {
2361                 if(MinigameImpulse(this, CS(this).impulse))
2362                         CS(this).impulse = 0;
2363
2364                 if (CS(this).impulse == IMP_weapon_drop.impulse)
2365                 {
2366                         STAT(CAMERA_SPECTATOR, this) = (STAT(CAMERA_SPECTATOR, this) + 1) % 3;
2367                         CS(this).impulse = 0;
2368                         return;
2369                 }
2370         }
2371
2372         if (this.flags & FL_JUMPRELEASED) {
2373                 if (PHYS_INPUT_BUTTON_JUMP(this) && joinAllowed(this)) {
2374                         this.flags &= ~FL_JUMPRELEASED;
2375                         this.flags |= FL_SPAWNING;
2376                 } else if(PHYS_INPUT_BUTTON_ATCK(this) || CS(this).impulse == 10 || CS(this).impulse == 15 || CS(this).impulse == 18 || (CS(this).impulse >= 200 && CS(this).impulse <= 209)) {
2377                         this.flags &= ~FL_JUMPRELEASED;
2378                         if(SpectateNext(this)) {
2379                                 TRANSMUTE(Spectator, this);
2380                         } else {
2381                                 TRANSMUTE(Observer, this);
2382                                 PutClientInServer(this);
2383                         }
2384                         CS(this).impulse = 0;
2385                 } else if(CS(this).impulse == 12 || CS(this).impulse == 16  || CS(this).impulse == 19 || (CS(this).impulse >= 220 && CS(this).impulse <= 229)) {
2386                         this.flags &= ~FL_JUMPRELEASED;
2387                         if(SpectatePrev(this)) {
2388                                 TRANSMUTE(Spectator, this);
2389                         } else {
2390                                 TRANSMUTE(Observer, this);
2391                                 PutClientInServer(this);
2392                         }
2393                         CS(this).impulse = 0;
2394                 } else if (PHYS_INPUT_BUTTON_ATCK2(this)) {
2395                         this.flags &= ~FL_JUMPRELEASED;
2396                         TRANSMUTE(Observer, this);
2397                         PutClientInServer(this);
2398                 } else {
2399                         if(!SpectateUpdate(this))
2400                                 PutObserverInServer(this);
2401                 }
2402         } else {
2403                 if (!(PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_ATCK2(this))) {
2404                         this.flags |= FL_JUMPRELEASED;
2405                         if(this.flags & FL_SPAWNING)
2406                         {
2407                                 this.flags &= ~FL_SPAWNING;
2408                                 Join(this);
2409                                 return;
2410                         }
2411                 }
2412                 if(!SpectateUpdate(this))
2413                         PutObserverInServer(this);
2414         }
2415
2416         this.flags |= FL_CLIENT | FL_NOTARGET;
2417 }
2418
2419 void vehicles_enter (entity pl, entity veh);
2420 void PlayerUseKey(entity this)
2421 {
2422         if (!IS_PLAYER(this))
2423                 return;
2424
2425         if(this.vehicle)
2426         {
2427                 if(!game_stopped)
2428                 {
2429                         vehicles_exit(this.vehicle, VHEF_NORMAL);
2430                         return;
2431                 }
2432         }
2433         else if(autocvar_g_vehicles_enter)
2434         {
2435                 if(!STAT(FROZEN, this))
2436                 if(!IS_DEAD(this))
2437                 if(!game_stopped)
2438                 {
2439                         entity head, closest_target = NULL;
2440                         head = WarpZone_FindRadius(this.origin, autocvar_g_vehicles_enter_radius, true);
2441
2442                         while(head) // find the closest acceptable target to enter
2443                         {
2444                                 if(IS_VEHICLE(head))
2445                                 if(!IS_DEAD(head))
2446                                 if(!head.owner || ((head.vehicle_flags & VHF_MULTISLOT) && SAME_TEAM(head.owner, this)))
2447                                 if(head.takedamage != DAMAGE_NO)
2448                                 {
2449                                         if(closest_target)
2450                                         {
2451                                                 if(vlen2(this.origin - head.origin) < vlen2(this.origin - closest_target.origin))
2452                                                 { closest_target = head; }
2453                                         }
2454                                         else { closest_target = head; }
2455                                 }
2456
2457                                 head = head.chain;
2458                         }
2459
2460                         if(closest_target) { vehicles_enter(this, closest_target); return; }
2461                 }
2462         }
2463
2464         // a use key was pressed; call handlers
2465         MUTATOR_CALLHOOK(PlayerUseKey, this);
2466 }
2467
2468
2469 /*
2470 =============
2471 PlayerPreThink
2472
2473 Called every frame for each client before the physics are run
2474 =============
2475 */
2476 .float last_vehiclecheck;
2477 void PlayerPreThink (entity this)
2478 {
2479         STAT(GUNALIGN, this) = CS(this).cvar_cl_gunalign; // TODO
2480         STAT(MOVEVARS_CL_TRACK_CANJUMP, this) = CS(this).cvar_cl_movement_track_canjump;
2481
2482         WarpZone_PlayerPhysics_FixVAngle(this);
2483
2484         if (frametime) {
2485                 // physics frames: update anticheat stuff
2486                 anticheat_prethink(this);
2487         }
2488
2489         if (blockSpectators && frametime) {
2490                 // WORKAROUND: only use dropclient in server frames (frametime set).
2491                 // Never use it in cl_movement frames (frametime zero).
2492                 checkSpectatorBlock(this);
2493         }
2494
2495         zoomstate_set = false;
2496
2497         // Check for nameless players
2498         if (this.netname == "" || this.netname != CS(this).netname_previous)
2499         {
2500                 bool assume_unchanged = (CS(this).netname_previous == "");
2501                 if (isInvisibleString(this.netname))
2502                 {
2503                         this.netname = strzone(sprintf("Player#%d", this.playerid));
2504                         assume_unchanged = false;
2505                         // stuffcmd(this, strcat("name ", this.netname, "\n")); // maybe?
2506                 }
2507                 if (!assume_unchanged && autocvar_sv_eventlog)
2508                         GameLogEcho(strcat(":name:", ftos(this.playerid), ":", playername(this, false)));
2509                 if (CS(this).netname_previous) strunzone(CS(this).netname_previous);
2510                 CS(this).netname_previous = strzone(this.netname);
2511         }
2512
2513         // version nagging
2514         if (CS(this).version_nagtime && CS(this).cvar_g_xonoticversion && time > CS(this).version_nagtime) {
2515         CS(this).version_nagtime = 0;
2516         if (strstrofs(CS(this).cvar_g_xonoticversion, "git", 0) >= 0 || strstrofs(CS(this).cvar_g_xonoticversion, "autobuild", 0) >= 0) {
2517             // git client
2518         } else if (strstrofs(autocvar_g_xonoticversion, "git", 0) >= 0 || strstrofs(autocvar_g_xonoticversion, "autobuild", 0) >= 0) {
2519             // git server
2520             Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_BETA, autocvar_g_xonoticversion, CS(this).cvar_g_xonoticversion);
2521         } else {
2522             int r = vercmp(CS(this).cvar_g_xonoticversion, autocvar_g_xonoticversion);
2523             if (r < 0) { // old client
2524                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_OUTDATED, autocvar_g_xonoticversion, CS(this).cvar_g_xonoticversion);
2525             } else if (r > 0) { // old server
2526                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_OLD, autocvar_g_xonoticversion, CS(this).cvar_g_xonoticversion);
2527             }
2528         }
2529     }
2530
2531         // GOD MODE info
2532         if (!(this.flags & FL_GODMODE) && this.max_armorvalue)
2533         {
2534                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_GODMODE_OFF, this.max_armorvalue);
2535                 this.max_armorvalue = 0;
2536         }
2537
2538         if(IS_PLAYER(this))
2539         {
2540                 if (STAT(FROZEN, this) == 2)
2541                 {
2542                         STAT(REVIVE_PROGRESS, this) = bound(0, STAT(REVIVE_PROGRESS, this) + frametime * this.revive_speed, 1);
2543                         this.health = max(1, STAT(REVIVE_PROGRESS, this) * start_health);
2544                         this.iceblock.alpha = bound(0.2, 1 - STAT(REVIVE_PROGRESS, this), 1);
2545
2546                         if (STAT(REVIVE_PROGRESS, this) >= 1)
2547                                 Unfreeze(this);
2548                 }
2549                 else if (STAT(FROZEN, this) == 3)
2550                 {
2551                         STAT(REVIVE_PROGRESS, this) = bound(0, STAT(REVIVE_PROGRESS, this) - frametime * this.revive_speed, 1);
2552                         this.health = max(0, autocvar_g_nades_ice_health + (start_health-autocvar_g_nades_ice_health) * STAT(REVIVE_PROGRESS, this) );
2553
2554                         if (this.health < 1)
2555                         {
2556                                 if (this.vehicle)
2557                                         vehicles_exit(this.vehicle, VHEF_RELEASE);
2558                                 if(this.event_damage)
2559                                         this.event_damage(this, this, this.frozen_by, 1, DEATH_NADE_ICE_FREEZE.m_id, DMG_NOWEP, this.origin, '0 0 0');
2560                         }
2561                         else if (STAT(REVIVE_PROGRESS, this) <= 0)
2562                                 Unfreeze(this);
2563                 }
2564         }
2565
2566         MUTATOR_CALLHOOK(PlayerPreThink, this);
2567
2568         if(autocvar_g_vehicles_enter && (time > this.last_vehiclecheck) && !game_stopped && !this.vehicle)
2569         if(IS_PLAYER(this) && !STAT(FROZEN, this) && !IS_DEAD(this))
2570         {
2571                 FOREACH_ENTITY_RADIUS(this.origin, autocvar_g_vehicles_enter_radius, IS_VEHICLE(it),
2572                 {
2573                         if(!IS_DEAD(it) && it.takedamage != DAMAGE_NO)
2574                         if((it.vehicle_flags & VHF_MULTISLOT) && SAME_TEAM(it.owner, this))
2575                         {
2576                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER_GUNNER);
2577                         }
2578                         else if(!it.owner)
2579                         {
2580                                 if(!it.team || SAME_TEAM(this, it))
2581                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER);
2582                                 else if(autocvar_g_vehicles_steal)
2583                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER_STEAL);
2584                         }
2585                 });
2586
2587                 this.last_vehiclecheck = time + 1;
2588         }
2589
2590         if(!CS(this).cvar_cl_newusekeysupported) // FIXME remove this - it was a stupid idea to begin with, we can JUST use the button
2591         {
2592                 if(PHYS_INPUT_BUTTON_USE(this) && !CS(this).usekeypressed)
2593                         PlayerUseKey(this);
2594                 CS(this).usekeypressed = PHYS_INPUT_BUTTON_USE(this);
2595         }
2596
2597         if (IS_REAL_CLIENT(this))
2598                 PrintWelcomeMessage(this);
2599
2600         if (IS_PLAYER(this)) {
2601                 if(!PlayerThink(this))
2602                         return;
2603         }
2604         else if (game_stopped || intermission_running) {
2605                 if(intermission_running)
2606                         IntermissionThink(this);
2607                 return;
2608         }
2609         else if (IS_OBSERVER(this)) {
2610                 ObserverThink(this);
2611         }
2612         else if (IS_SPEC(this)) {
2613                 SpectatorThink(this);
2614         }
2615
2616         // WEAPONTODO: Add weapon request for this
2617         if (!zoomstate_set) {
2618                 bool wep_zoomed = false;
2619                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2620                 {
2621                         .entity weaponentity = weaponentities[slot];
2622                         Weapon thiswep = this.(weaponentity).m_weapon;
2623                         if(thiswep != WEP_Null && thiswep.wr_zoom)
2624                                 wep_zoomed += thiswep.wr_zoom(thiswep, this);
2625                 }
2626                 SetZoomState(this, PHYS_INPUT_BUTTON_ZOOM(this) || PHYS_INPUT_BUTTON_ZOOMSCRIPT(this) || wep_zoomed);
2627     }
2628
2629         if (CS(this).teamkill_soundtime && time > CS(this).teamkill_soundtime)
2630         {
2631                 CS(this).teamkill_soundtime = 0;
2632
2633                 entity e = CS(this).teamkill_soundsource;
2634                 entity oldpusher = e.pusher;
2635                 e.pusher = this;
2636                 PlayerSound(e, playersound_teamshoot, CH_VOICE, VOL_BASEVOICE, VOICETYPE_LASTATTACKER_ONLY);
2637                 e.pusher = oldpusher;
2638         }
2639
2640         if (CS(this).taunt_soundtime && time > CS(this).taunt_soundtime) {
2641                 CS(this).taunt_soundtime = 0;
2642                 PlayerSound(this, playersound_taunt, CH_VOICE, VOL_BASEVOICE, VOICETYPE_AUTOTAUNT);
2643         }
2644
2645         target_voicescript_next(this);
2646
2647         // WEAPONTODO: Move into weaponsystem somehow
2648         // if a player goes unarmed after holding a loaded weapon, empty his clip size and remove the crosshair ammo ring
2649         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2650         {
2651                 .entity weaponentity = weaponentities[slot];
2652                 if(this.(weaponentity).m_weapon == WEP_Null)
2653                         this.(weaponentity).clip_load = this.(weaponentity).clip_size = 0;
2654         }
2655 }
2656
2657 void DrownPlayer(entity this)
2658 {
2659         if(IS_DEAD(this) || game_stopped || time < game_starttime)
2660                 return;
2661
2662         if (this.waterlevel != WATERLEVEL_SUBMERGED || this.vehicle)
2663         {
2664                 if(this.air_finished < time)
2665                         PlayerSound(this, playersound_gasp, CH_PLAYER, VOL_BASE, VOICETYPE_PLAYERSOUND);
2666                 this.air_finished = time + autocvar_g_balance_contents_drowndelay;
2667         }
2668         else if (this.air_finished < time)
2669         {       // drown!
2670                 if (this.pain_finished < time)
2671                 {
2672                         Damage (this, NULL, NULL, autocvar_g_balance_contents_playerdamage_drowning * autocvar_g_balance_contents_damagerate, DEATH_DROWN.m_id, DMG_NOWEP, this.origin, '0 0 0');
2673                         this.pain_finished = time + 0.5;
2674                 }
2675         }
2676 }
2677
2678 .bool move_qcphysics;
2679
2680 void Player_Physics(entity this)
2681 {
2682         set_movetype(this, this.move_movetype);
2683
2684         if(!this.move_qcphysics)
2685                 return;
2686
2687         if(!frametime && !CS(this).pm_frametime)
2688                 return;
2689
2690         Movetype_Physics_NoMatchTicrate(this, CS(this).pm_frametime, true);
2691
2692         CS(this).pm_frametime = 0;
2693 }
2694
2695 /*
2696 =============
2697 PlayerPostThink
2698
2699 Called every frame for each client after the physics are run
2700 =============
2701 */
2702 void PlayerPostThink (entity this)
2703 {
2704         Player_Physics(this);
2705
2706         if (sv_maxidle > 0)
2707         if (frametime) // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2708         if (IS_REAL_CLIENT(this))
2709         if (IS_PLAYER(this) || sv_maxidle_spectatorsareidle)
2710         {
2711                 int totalClients = 0;
2712                 if(sv_maxidle_slots > 0)
2713                 {
2714                         FOREACH_CLIENT(IS_REAL_CLIENT(it) || sv_maxidle_slots_countbots,
2715                         {
2716                                 ++totalClients;
2717                         });
2718                 }
2719
2720                 if (sv_maxidle_slots > 0 && (maxclients - totalClients) > sv_maxidle_slots)
2721                 { /* do nothing */ }
2722                 else if (time - CS(this).parm_idlesince < 1) // instead of (time == this.parm_idlesince) to support sv_maxidle <= 10
2723                 {
2724                         if (CS(this).idlekick_lasttimeleft)
2725                         {
2726                                 CS(this).idlekick_lasttimeleft = 0;
2727                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_IDLING);
2728                         }
2729                 }
2730                 else
2731                 {
2732                         float timeleft = ceil(sv_maxidle - (time - CS(this).parm_idlesince));
2733                         if (timeleft == min(10, sv_maxidle - 1)) { // - 1 to support sv_maxidle <= 10
2734                                 if (!CS(this).idlekick_lasttimeleft)
2735                                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_DISCONNECT_IDLING, timeleft);
2736                         }
2737                         if (timeleft <= 0) {
2738                                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_QUIT_KICK_IDLING, this.netname);
2739                                 dropclient(this);
2740                                 return;
2741                         }
2742                         else if (timeleft <= 10) {
2743                                 if (timeleft != CS(this).idlekick_lasttimeleft) {
2744                                     Send_Notification(NOTIF_ONE, this, MSG_ANNCE, Announcer_PickNumber(CNT_IDLE, timeleft));
2745                 }
2746                                 CS(this).idlekick_lasttimeleft = timeleft;
2747                         }
2748                 }
2749         }
2750
2751         CheatFrame(this);
2752
2753         if (game_stopped)
2754         {
2755                 this.solid = SOLID_NOT;
2756                 this.takedamage = DAMAGE_NO;
2757                 set_movetype(this, MOVETYPE_NONE);
2758         }
2759
2760         if (IS_PLAYER(this)) {
2761                 DrownPlayer(this);
2762                 UpdateChatBubble(this);
2763                 if (CS(this).impulse) ImpulseCommands(this);
2764                 if (game_stopped)
2765                 {
2766                         CSQCMODEL_AUTOUPDATE(this);
2767                         return;
2768                 }
2769                 GetPressedKeys(this);
2770         }
2771
2772         if (this.waypointsprite_attachedforcarrier) {
2773             vector v = healtharmor_maxdamage(this.health, this.armorvalue, autocvar_g_balance_armor_blockpercent, DEATH_WEAPON.m_id);
2774                 WaypointSprite_UpdateHealth(this.waypointsprite_attachedforcarrier, '1 0 0' * v);
2775     }
2776
2777         playerdemo_write(this);
2778
2779         CSQCMODEL_AUTOUPDATE(this);
2780 }
2781
2782 // hack to copy the button fields from the client entity to the Client State
2783 void PM_UpdateButtons(entity this, entity store)
2784 {
2785         if(this.impulse)
2786                 store.impulse = this.impulse;
2787         this.impulse = 0;
2788
2789         store.button0 = this.button0;
2790         store.button2 = this.button2;
2791         store.button3 = this.button3;
2792         store.button4 = this.button4;
2793         store.button5 = this.button5;
2794         store.button6 = this.button6;
2795         store.button7 = this.button7;
2796         store.button8 = this.button8;
2797         store.button9 = this.button9;
2798         store.button10 = this.button10;
2799         store.button11 = this.button11;
2800         store.button12 = this.button12;
2801         store.button13 = this.button13;
2802         store.button14 = this.button14;
2803         store.button15 = this.button15;
2804         store.button16 = this.button16;
2805         store.buttonuse = this.buttonuse;
2806         store.buttonchat = this.buttonchat;
2807
2808         store.cursor_active = this.cursor_active;
2809         store.cursor_screen = this.cursor_screen;
2810         store.cursor_trace_start = this.cursor_trace_start;
2811         store.cursor_trace_endpos = this.cursor_trace_endpos;
2812         store.cursor_trace_ent = this.cursor_trace_ent;
2813
2814         store.ping = this.ping;
2815         store.ping_packetloss = this.ping_packetloss;
2816         store.ping_movementloss = this.ping_movementloss;
2817
2818         store.v_angle = this.v_angle;
2819         store.movement = this.movement;
2820 }