qcsrc/server/client.qc

   1 #include "client.qh"
   2
   3 #include <server/defs.qh>
   4 #include <server/miscfunctions.qh>
   5 #include <common/effects/all.qh>
   6 #include "anticheat.qh"
   7 #include "impulse.qh"
   8 #include "player.qh"
   9 #include "ipban.qh"
  10 #include "miscfunctions.qh"
  11 #include "portals.qh"
  12 #include "teamplay.qh"
  13 #include "spawnpoints.qh"
  14 #include "resources.qh"
  15 #include "g_damage.qh"
  16 #include "handicap.qh"
  17 #include "g_hook.qh"
  18 #include "command/common.qh"
  19 #include "command/vote.qh"
  20 #include "clientkill.qh"
  21 #include "cheats.qh"
  22 #include "g_world.qh"
  23 #include "race.qh"
  24 #include "antilag.qh"
  25 #include "campaign.qh"
  26 #include "command/common.qh"
  27 #include "scores_rules.qh"
  28
  29 #include "bot/api.qh"
  30
  31 #include "../common/ent_cs.qh"
  32 #include "../common/wepent.qh"
  33 #include <common/state.qh>
  34
  35 #include <common/effects/qc/globalsound.qh>
  36
  37 #include "../common/mapobjects/func/conveyor.qh"
  38 #include "../common/mapobjects/teleporters.qh"
  39 #include "../common/mapobjects/target/spawnpoint.qh"
  40
  41 #include "../common/vehicles/all.qh"
  42
  43 #include "weapons/hitplot.qh"
  44 #include "weapons/weaponsystem.qh"
  45
  46 #include "../common/net_notice.qh"
  47 #include "../common/net_linked.qh"
  48 #include "../common/physics/player.qh"
  49
  50 #include <common/vehicles/sv_vehicles.qh>
  51
  52 #include "../common/items/_mod.qh"
  53
  54 #include "../common/mutators/mutator/waypoints/all.qh"
  55 #include "../common/mutators/mutator/instagib/sv_instagib.qh"
  56 #include <common/gamemodes/_mod.qh>
  57
  58 #include "../common/mapobjects/subs.qh"
  59 #include "../common/mapobjects/triggers.qh"
  60 #include "../common/mapobjects/trigger/secret.qh"
  61
  62 #include "../common/minigames/sv_minigames.qh"
  63
  64 #include "../common/items/inventory.qh"
  65
  66 #include "../common/monsters/sv_monsters.qh"
  67
  68 #include "../lib/warpzone/server.qh"
  69
  70 #include <common/mutators/mutator/overkill/oknex.qh>
  71
  72 STATIC_METHOD(Client, Add, void(Client this, int _team))
  73 {
  74     ClientConnect(this);
  75     TRANSMUTE(Player, this);
  76     this.frame = 12; // 7
  77     this.team = _team;
  78     PutClientInServer(this);
  79 }
  80
  81 STATIC_METHOD(Client, Remove, void(Client this))
  82 {
  83     TRANSMUTE(Observer, this);
  84     PutClientInServer(this);
  85     ClientDisconnect(this);
  86 }
  87
  88 void send_CSQC_teamnagger() {
  89         WriteHeader(MSG_BROADCAST, TE_CSQC_TEAMNAGGER);
  90 }
  91
  92 int CountSpectators(entity player, entity to)
  93 {
  94         if(!player) { return 0; } // not sure how, but best to be safe
  95
  96         int spec_count = 0;
  97
  98         FOREACH_CLIENT(IS_REAL_CLIENT(it) && IS_SPEC(it) && it != to && it.enemy == player,
  99         {
 100                 spec_count++;
 101         });
 102
 103         return spec_count;
 104 }
 105
 106 void WriteSpectators(entity player, entity to)
 107 {
 108         if(!player) { return; } // not sure how, but best to be safe
 109
 110         FOREACH_CLIENT(IS_REAL_CLIENT(it) && IS_SPEC(it) && it != to && it.enemy == player,
 111         {
 112                 WriteByte(MSG_ENTITY, num_for_edict(it));
 113         });
 114 }
 115
 116 bool ClientData_Send(entity this, entity to, int sf)
 117 {
 118         assert(to == this.owner, return false);
 119
 120         entity e = to;
 121         if (IS_SPEC(e)) e = e.enemy;
 122
 123         sf = 0;
 124         if (CS(e).race_completed)       sf |= BIT(0); // forced scoreboard
 125         if (CS(to).spectatee_status)    sf |= BIT(1); // spectator ent number follows
 126         if (CS(e).zoomstate)            sf |= BIT(2); // zoomed
 127         if (autocvar_sv_showspectators) sf |= BIT(4); // show spectators
 128
 129         WriteHeader(MSG_ENTITY, ENT_CLIENT_CLIENTDATA);
 130         WriteByte(MSG_ENTITY, sf);
 131
 132         if (sf & BIT(1))
 133                 WriteByte(MSG_ENTITY, CS(to).spectatee_status);
 134
 135         if(sf & BIT(4))
 136         {
 137                 float specs = CountSpectators(e, to);
 138                 WriteByte(MSG_ENTITY, specs);
 139                 WriteSpectators(e, to);
 140         }
 141
 142         return true;
 143 }
 144
 145 void ClientData_Attach(entity this)
 146 {
 147         Net_LinkEntity(CS(this).clientdata = new_pure(clientdata), false, 0, ClientData_Send);
 148         CS(this).clientdata.drawonlytoclient = this;
 149         CS(this).clientdata.owner = this;
 150 }
 151
 152 void ClientData_Detach(entity this)
 153 {
 154         delete(CS(this).clientdata);
 155         CS(this).clientdata = NULL;
 156 }
 157
 158 void ClientData_Touch(entity e)
 159 {
 160         entity cd = CS(e).clientdata;
 161         if (cd) { cd.SendFlags = 1; }
 162
 163         // make it spectatable
 164         FOREACH_CLIENT(IS_REAL_CLIENT(it) && it != e && IS_SPEC(it) && it.enemy == e,
 165         {
 166                 entity cd = CS(it).clientdata;
 167                 if (cd) { cd.SendFlags = 1; }
 168         });
 169 }
 170
 171
 172 /*
 173 =============
 174 CheckPlayerModel
 175
 176 Checks if the argument string can be a valid playermodel.
 177 Returns a valid one in doubt.
 178 =============
 179 */
 180 string FallbackPlayerModel;
 181 string CheckPlayerModel(string plyermodel) {
 182         if(FallbackPlayerModel != cvar_defstring("_cl_playermodel"))
 183         {
 184                 // note: we cannot summon Don Strunzone here, some player may
 185                 // still have the model string set. In case anyone manages how
 186                 // to change a cvar default, we'll have a small leak here.
 187                 FallbackPlayerModel = strzone(cvar_defstring("_cl_playermodel"));
 188         }
 189         // only in right path
 190         if( substring(plyermodel,0,14) != "models/player/")
 191                 return FallbackPlayerModel;
 192         // only good file extensions
 193         if(substring(plyermodel,-4,4) != ".zym")
 194         if(substring(plyermodel,-4,4) != ".dpm")
 195         if(substring(plyermodel,-4,4) != ".iqm")
 196         if(substring(plyermodel,-4,4) != ".md3")
 197         if(substring(plyermodel,-4,4) != ".psk")
 198                 return FallbackPlayerModel;
 199         // forbid the LOD models
 200         if(substring(plyermodel, -9,5) == "_lod1")
 201                 return FallbackPlayerModel;
 202         if(substring(plyermodel, -9,5) == "_lod2")
 203                 return FallbackPlayerModel;
 204         if(plyermodel != strtolower(plyermodel))
 205                 return FallbackPlayerModel;
 206         // also, restrict to server models
 207         if(autocvar_sv_servermodelsonly)
 208         {
 209                 if(!fexists(plyermodel))
 210                         return FallbackPlayerModel;
 211         }
 212         return plyermodel;
 213 }
 214
 215 void setplayermodel(entity e, string modelname)
 216 {
 217         precache_model(modelname);
 218         _setmodel(e, modelname);
 219         player_setupanimsformodel(e);
 220         if(!autocvar_g_debug_globalsounds)
 221                 UpdatePlayerSounds(e);
 222 }
 223
 224 /** putting a client as observer in the server */
 225 void PutObserverInServer(entity this)
 226 {
 227     bool mutator_returnvalue = MUTATOR_CALLHOOK(MakePlayerObserver, this);
 228         PlayerState_detach(this);
 229
 230         if (IS_PLAYER(this))
 231         {
 232                 if(GetResourceAmount(this, RESOURCE_HEALTH) >= 1)
 233                 {
 234                         // despawn effect
 235                         Send_Effect(EFFECT_SPAWN_NEUTRAL, this.origin, '0 0 0', 1);
 236                 }
 237
 238                 // was a player, recount votes and ready status
 239                 if(IS_REAL_CLIENT(this))
 240                 {
 241                         if (vote_called) { VoteCount(false); }
 242                         ReadyCount();
 243                 }
 244     }
 245
 246     {
 247         entity spot = SelectSpawnPoint(this, true);
 248         if (!spot) LOG_FATAL("No spawnpoints for observers?!?");
 249         this.angles = vec2(spot.angles);
 250         this.fixangle = true;
 251         // offset it so that the spectator spawns higher off the ground, looks better this way
 252         setorigin(this, spot.origin + STAT(PL_VIEW_OFS, this));
 253         if (IS_REAL_CLIENT(this))
 254         {
 255             msg_entity = this;
 256             WriteByte(MSG_ONE, SVC_SETVIEW);
 257             WriteEntity(MSG_ONE, this);
 258         }
 259         // give the spectator some space between walls for MOVETYPE_FLY_WORLDONLY
 260         // so that your view doesn't go into the ceiling with MOVETYPE_FLY_WORLDONLY, previously "PL_VIEW_OFS"
 261         if(!autocvar_g_debug_globalsounds)
 262         {
 263                 // needed for player sounds
 264                 this.model = "";
 265                 FixPlayermodel(this);
 266         }
 267         setmodel(this, MDL_Null);
 268         setsize(this, STAT(PL_CROUCH_MIN, this), STAT(PL_CROUCH_MAX, this));
 269         this.view_ofs = '0 0 0';
 270     }
 271
 272     RemoveGrapplingHooks(this);
 273         Portal_ClearAll(this);
 274         Unfreeze(this);
 275         SetSpectatee(this, NULL);
 276
 277         if (this.alivetime)
 278         {
 279                 if (!warmup_stage)
 280                         PlayerStats_GameReport_Event_Player(this, PLAYERSTATS_ALIVETIME, time - this.alivetime);
 281                 this.alivetime = 0;
 282         }
 283
 284         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
 285
 286         WaypointSprite_PlayerDead(this);
 287
 288         if (CS(this).killcount != FRAGS_SPECTATOR)
 289         {
 290                 if(!game_stopped)
 291                 if(autocvar_g_chat_nospectators == 1 || (!warmup_stage && autocvar_g_chat_nospectators == 2))
 292                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_CHAT_NOSPECTATORS);
 293         }
 294
 295         accuracy_resend(this);
 296
 297         CS(this).spectatortime = time;
 298         if(this.bot_attack)
 299                 IL_REMOVE(g_bot_targets, this);
 300         this.bot_attack = false;
 301         if(this.monster_attack)
 302                 IL_REMOVE(g_monster_targets, this);
 303         this.monster_attack = false;
 304     STAT(HUD, this) = HUD_NORMAL;
 305         TRANSMUTE(Observer, this);
 306         this.iscreature = false;
 307         this.teleportable = TELEPORT_SIMPLE;
 308         if(this.damagedbycontents)
 309                 IL_REMOVE(g_damagedbycontents, this);
 310         this.damagedbycontents = false;
 311         SetResourceAmountExplicit(this, RESOURCE_HEALTH, FRAGS_SPECTATOR);
 312         SetSpectatee_status(this, etof(this));
 313         this.takedamage = DAMAGE_NO;
 314         this.solid = SOLID_NOT;
 315         set_movetype(this, MOVETYPE_FLY_WORLDONLY); // user preference is controlled by playerprethink
 316         this.flags = FL_CLIENT | FL_NOTARGET;
 317         this.effects = 0;
 318         SetResourceAmountExplicit(this, RESOURCE_ARMOR, autocvar_g_balance_armor_start); // was 666?!
 319         this.pauserotarmor_finished = 0;
 320         this.pauserothealth_finished = 0;
 321         this.pauseregen_finished = 0;
 322         this.damageforcescale = 0;
 323         this.death_time = 0;
 324         this.respawn_flags = 0;
 325         this.respawn_time = 0;
 326         STAT(RESPAWN_TIME, this) = 0;
 327         this.alpha = 0;
 328         this.scale = 0;
 329         this.fade_time = 0;
 330         this.pain_frame = 0;
 331         this.pain_finished = 0;
 332         this.strength_finished = 0;
 333         this.invincible_finished = 0;
 334         this.superweapons_finished = 0;
 335         this.dphitcontentsmask = 0;
 336         this.pushltime = 0;
 337         this.istypefrag = 0;
 338         setthink(this, func_null);
 339         this.nextthink = 0;
 340         this.deadflag = DEAD_NO;
 341         this.crouch = false;
 342         STAT(REVIVE_PROGRESS, this) = 0;
 343         this.revival_time = 0;
 344
 345         this.items = 0;
 346         STAT(WEAPONS, this) = '0 0 0';
 347         this.drawonlytoclient = this;
 348
 349         this.viewloc = NULL;
 350
 351         //this.spawnpoint_targ = NULL; // keep it so they can return to where they were?
 352
 353         this.weaponmodel = "";
 354         for (int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 355         {
 356                 this.weaponentities[slot] = NULL;
 357         }
 358         this.exteriorweaponentity = NULL;
 359         CS(this).killcount = FRAGS_SPECTATOR;
 360         this.velocity = '0 0 0';
 361         this.avelocity = '0 0 0';
 362         this.punchangle = '0 0 0';
 363         this.punchvector = '0 0 0';
 364         this.oldvelocity = this.velocity;
 365         this.fire_endtime = -1;
 366         this.event_damage = func_null;
 367         this.event_heal = func_null;
 368
 369         for(int slot = 0; slot < MAX_AXH; ++slot)
 370         {
 371                 entity axh = this.(AuxiliaryXhair[slot]);
 372                 this.(AuxiliaryXhair[slot]) = NULL;
 373
 374                 if(axh.owner == this && axh != NULL && !wasfreed(axh))
 375                         delete(axh);
 376         }
 377
 378         if (mutator_returnvalue)
 379         {
 380                 // mutator prevents resetting teams+score
 381         }
 382         else
 383         {
 384                 SetPlayerTeam(this, -1, TEAM_CHANGE_SPECTATOR);
 385                 this.frags = FRAGS_SPECTATOR;
 386     }
 387 }
 388
 389 int player_getspecies(entity this)
 390 {
 391         get_model_parameters(this.model, this.skin);
 392         int s = get_model_parameters_species;
 393         get_model_parameters(string_null, 0);
 394         if (s < 0) return SPECIES_HUMAN;
 395         return s;
 396 }
 397
 398 .float model_randomizer;
 399 void FixPlayermodel(entity player)
 400 {
 401         string defaultmodel = "";
 402         int defaultskin = 0;
 403         if(autocvar_sv_defaultcharacter)
 404         {
 405                 if(teamplay)
 406                 {
 407                         switch(player.team)
 408                         {
 409                                 case NUM_TEAM_1: defaultmodel = autocvar_sv_defaultplayermodel_red; defaultskin = autocvar_sv_defaultplayerskin_red; break;
 410                                 case NUM_TEAM_2: defaultmodel = autocvar_sv_defaultplayermodel_blue; defaultskin = autocvar_sv_defaultplayerskin_blue; break;
 411                                 case NUM_TEAM_3: defaultmodel = autocvar_sv_defaultplayermodel_yellow; defaultskin = autocvar_sv_defaultplayerskin_yellow; break;
 412                                 case NUM_TEAM_4: defaultmodel = autocvar_sv_defaultplayermodel_pink; defaultskin = autocvar_sv_defaultplayerskin_pink; break;
 413                         }
 414                 }
 415
 416                 if(defaultmodel == "")
 417                 {
 418                         defaultmodel = autocvar_sv_defaultplayermodel;
 419                         defaultskin = autocvar_sv_defaultplayerskin;
 420                 }
 421
 422                 int n = tokenize_console(defaultmodel);
 423                 if(n > 0)
 424                 {
 425                         defaultmodel = argv(floor(n * CS(player).model_randomizer));
 426                         // However, do NOT randomize if the player-selected model is in the list.
 427                         for (int i = 0; i < n; ++i)
 428                                 if ((argv(i) == player.playermodel && defaultskin == stof(player.playerskin)) || argv(i) == strcat(player.playermodel, ":", player.playerskin))
 429                                         defaultmodel = argv(i);
 430                 }
 431
 432                 int i = strstrofs(defaultmodel, ":", 0);
 433                 if(i >= 0)
 434                 {
 435                         defaultskin = stof(substring(defaultmodel, i+1, -1));
 436                         defaultmodel = substring(defaultmodel, 0, i);
 437                 }
 438         }
 439         if(autocvar_sv_defaultcharacterskin && !defaultskin)
 440         {
 441                 if(teamplay)
 442                 {
 443                         switch(player.team)
 444                         {
 445                                 case NUM_TEAM_1: defaultskin = autocvar_sv_defaultplayerskin_red; break;
 446                                 case NUM_TEAM_2: defaultskin = autocvar_sv_defaultplayerskin_blue; break;
 447                                 case NUM_TEAM_3: defaultskin = autocvar_sv_defaultplayerskin_yellow; break;
 448                                 case NUM_TEAM_4: defaultskin = autocvar_sv_defaultplayerskin_pink; break;
 449                         }
 450                 }
 451
 452                 if(!defaultskin)
 453                         defaultskin = autocvar_sv_defaultplayerskin;
 454         }
 455
 456         MUTATOR_CALLHOOK(FixPlayermodel, defaultmodel, defaultskin, player);
 457         defaultmodel = M_ARGV(0, string);
 458         defaultskin = M_ARGV(1, int);
 459
 460         bool chmdl = false;
 461         int oldskin;
 462         if(defaultmodel != "")
 463         {
 464                 if (defaultmodel != player.model)
 465                 {
 466                         vector m1 = player.mins;
 467                         vector m2 = player.maxs;
 468                         setplayermodel (player, defaultmodel);
 469                         setsize (player, m1, m2);
 470                         chmdl = true;
 471                 }
 472
 473                 oldskin = player.skin;
 474                 player.skin = defaultskin;
 475         } else {
 476                 if (player.playermodel != player.model || player.playermodel == "")
 477                 {
 478                         player.playermodel = CheckPlayerModel(player.playermodel); // this is never "", so no endless loop
 479                         vector m1 = player.mins;
 480                         vector m2 = player.maxs;
 481                         setplayermodel (player, player.playermodel);
 482                         setsize (player, m1, m2);
 483                         chmdl = true;
 484                 }
 485
 486                 if(!autocvar_sv_defaultcharacterskin)
 487                 {
 488                         oldskin = player.skin;
 489                         player.skin = stof(player.playerskin);
 490                 }
 491                 else
 492                 {
 493                         oldskin = player.skin;
 494                         player.skin = defaultskin;
 495                 }
 496         }
 497
 498         if(chmdl || oldskin != player.skin) // model or skin has changed
 499         {
 500                 player.species = player_getspecies(player); // update species
 501                 if(!autocvar_g_debug_globalsounds)
 502                         UpdatePlayerSounds(player); // update skin sounds
 503         }
 504
 505         if(!teamplay)
 506                 if(strlen(autocvar_sv_defaultplayercolors))
 507                         if(player.clientcolors != stof(autocvar_sv_defaultplayercolors))
 508                                 setcolor(player, stof(autocvar_sv_defaultplayercolors));
 509 }
 510
 511 void PutPlayerInServer(entity this)
 512 {
 513         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
 514
 515         PlayerState_attach(this);
 516         accuracy_resend(this);
 517
 518         if (this.team < 0)
 519                 TeamBalance_JoinBestTeam(this);
 520
 521         entity spot = SelectSpawnPoint(this, false);
 522         if (!spot) {
 523                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_JOIN_NOSPAWNS);
 524                 return; // spawn failed
 525         }
 526
 527         TRANSMUTE(Player, this);
 528
 529         CS(this).wasplayer = true;
 530         this.iscreature = true;
 531         this.teleportable = TELEPORT_NORMAL;
 532         if(!this.damagedbycontents)
 533                 IL_PUSH(g_damagedbycontents, this);
 534         this.damagedbycontents = true;
 535         set_movetype(this, MOVETYPE_WALK);
 536         this.solid = SOLID_SLIDEBOX;
 537         this.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_SOLID;
 538         if (autocvar_g_playerclip_collisions)
 539                 this.dphitcontentsmask |= DPCONTENTS_PLAYERCLIP;
 540         if (IS_BOT_CLIENT(this) && autocvar_g_botclip_collisions)
 541                 this.dphitcontentsmask |= DPCONTENTS_BOTCLIP;
 542         this.frags = FRAGS_PLAYER;
 543         if (INDEPENDENT_PLAYERS) MAKE_INDEPENDENT_PLAYER(this);
 544         this.flags = FL_CLIENT | FL_PICKUPITEMS;
 545         if (autocvar__notarget)
 546                 this.flags |= FL_NOTARGET;
 547         this.takedamage = DAMAGE_AIM;
 548         this.effects = EF_TELEPORT_BIT | EF_RESTARTANIM_BIT;
 549
 550         if (warmup_stage) {
 551                 SetResourceAmount(this, RESOURCE_SHELLS, warmup_start_ammo_shells);
 552                 SetResourceAmount(this, RESOURCE_BULLETS, warmup_start_ammo_nails);
 553                 SetResourceAmount(this, RESOURCE_ROCKETS, warmup_start_ammo_rockets);
 554                 SetResourceAmount(this, RESOURCE_CELLS, warmup_start_ammo_cells);
 555                 SetResourceAmount(this, RESOURCE_PLASMA, warmup_start_ammo_plasma);
 556                 SetResourceAmount(this, RESOURCE_FUEL, warmup_start_ammo_fuel);
 557                 SetResourceAmount(this, RESOURCE_HEALTH, warmup_start_health);
 558                 SetResourceAmount(this, RESOURCE_ARMOR, warmup_start_armorvalue);
 559                 STAT(WEAPONS, this) = WARMUP_START_WEAPONS;
 560         } else {
 561                 SetResourceAmount(this, RESOURCE_SHELLS, start_ammo_shells);
 562                 SetResourceAmount(this, RESOURCE_BULLETS, start_ammo_nails);
 563                 SetResourceAmount(this, RESOURCE_ROCKETS, start_ammo_rockets);
 564                 SetResourceAmount(this, RESOURCE_CELLS, start_ammo_cells);
 565                 SetResourceAmount(this, RESOURCE_PLASMA, start_ammo_plasma);
 566                 SetResourceAmount(this, RESOURCE_FUEL, start_ammo_fuel);
 567                 SetResourceAmount(this, RESOURCE_HEALTH, start_health);
 568                 SetResourceAmount(this, RESOURCE_ARMOR, start_armorvalue);
 569                 STAT(WEAPONS, this) = start_weapons;
 570                 if (MUTATOR_CALLHOOK(ForbidRandomStartWeapons, this) == false)
 571                 {
 572                         GiveRandomWeapons(this, random_start_weapons_count,
 573                                 autocvar_g_random_start_weapons, random_start_ammo);
 574                 }
 575         }
 576         SetSpectatee_status(this, 0);
 577
 578         PS(this).dual_weapons = '0 0 0';
 579
 580         this.superweapons_finished = (STAT(WEAPONS, this) & WEPSET_SUPERWEAPONS) ? time + autocvar_g_balance_superweapons_time : 0;
 581
 582         this.items = start_items;
 583
 584         this.spawnshieldtime = time + autocvar_g_spawnshieldtime;
 585         this.pauserotarmor_finished = time + autocvar_g_balance_pause_armor_rot_spawn;
 586         this.pauserothealth_finished = time + autocvar_g_balance_pause_health_rot_spawn;
 587         this.pauserotfuel_finished = time + autocvar_g_balance_pause_fuel_rot_spawn;
 588         this.pauseregen_finished = time + autocvar_g_balance_pause_health_regen_spawn;
 589         if (!sv_ready_restart_after_countdown && time < game_starttime)
 590         {
 591                 float f = game_starttime - time;
 592                 this.spawnshieldtime += f;
 593                 this.pauserotarmor_finished += f;
 594                 this.pauserothealth_finished += f;
 595                 this.pauseregen_finished += f;
 596         }
 597
 598         this.damageforcescale = 2;
 599         this.death_time = 0;
 600         this.respawn_flags = 0;
 601         this.respawn_time = 0;
 602         STAT(RESPAWN_TIME, this) = 0;
 603         this.scale = autocvar_sv_player_scale;
 604         this.fade_time = 0;
 605         this.pain_frame = 0;
 606         this.pain_finished = 0;
 607         this.pushltime = 0;
 608         setthink(this, func_null); // players have no think function
 609         this.nextthink = 0;
 610         this.dmg_team = 0;
 611         PS(this).ballistics_density = autocvar_g_ballistics_density_player;
 612
 613         this.deadflag = DEAD_NO;
 614
 615         this.angles = spot.angles;
 616         this.angles_z = 0; // never spawn tilted even if the spot says to
 617         if (IS_BOT_CLIENT(this))
 618                 this.v_angle = this.angles;
 619         this.fixangle = true; // turn this way immediately
 620         this.oldvelocity = this.velocity = '0 0 0';
 621         this.avelocity = '0 0 0';
 622         this.punchangle = '0 0 0';
 623         this.punchvector = '0 0 0';
 624
 625         this.strength_finished = 0;
 626         this.invincible_finished = 0;
 627         this.fire_endtime = -1;
 628         STAT(REVIVE_PROGRESS, this) = 0;
 629         this.revival_time = 0;
 630
 631         this.air_finished = time + 12;
 632         this.waterlevel = WATERLEVEL_NONE;
 633         this.watertype = CONTENT_EMPTY;
 634
 635         entity spawnevent = new_pure(spawnevent);
 636         spawnevent.owner = this;
 637         Net_LinkEntity(spawnevent, false, 0.5, SpawnEvent_Send);
 638
 639         // Cut off any still running player sounds.
 640         stopsound(this, CH_PLAYER_SINGLE);
 641
 642         this.model = "";
 643         FixPlayermodel(this);
 644         this.drawonlytoclient = NULL;
 645
 646         this.viewloc = NULL;
 647
 648         for(int slot = 0; slot < MAX_AXH; ++slot)
 649         {
 650                 entity axh = this.(AuxiliaryXhair[slot]);
 651                 this.(AuxiliaryXhair[slot]) = NULL;
 652
 653                 if(axh.owner == this && axh != NULL && !wasfreed(axh))
 654                         delete(axh);
 655         }
 656
 657         this.spawnpoint_targ = NULL;
 658
 659         this.crouch = false;
 660         this.view_ofs = STAT(PL_VIEW_OFS, this);
 661         setsize(this, STAT(PL_MIN, this), STAT(PL_MAX, this));
 662         this.spawnorigin = spot.origin;
 663         setorigin(this, spot.origin + '0 0 1' * (1 - this.mins.z - 24));
 664         // don't reset back to last position, even if new position is stuck in solid
 665         this.oldorigin = this.origin;
 666         if(this.conveyor)
 667                 IL_REMOVE(g_conveyed, this);
 668         this.conveyor = NULL; // prevent conveyors at the previous location from moving a freshly spawned player
 669         STAT(HUD, this) = HUD_NORMAL;
 670
 671         this.event_damage = PlayerDamage;
 672         this.event_heal = PlayerHeal;
 673
 674         if(!this.bot_attack)
 675                 IL_PUSH(g_bot_targets, this);
 676         this.bot_attack = true;
 677         if(!this.monster_attack)
 678                 IL_PUSH(g_monster_targets, this);
 679         this.monster_attack = true;
 680         navigation_dynamicgoal_init(this, false);
 681
 682         PHYS_INPUT_BUTTON_ATCK(this) = PHYS_INPUT_BUTTON_JUMP(this) = PHYS_INPUT_BUTTON_ATCK2(this) = false;
 683
 684         // player was spectator
 685         if (CS(this).killcount == FRAGS_SPECTATOR) {
 686                 PlayerScore_Clear(this);
 687                 CS(this).killcount = 0;
 688                 CS(this).startplaytime = time;
 689         }
 690
 691         for (int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 692         {
 693                 .entity weaponentity = weaponentities[slot];
 694                 entity oldwep = this.(weaponentity);
 695                 CL_SpawnWeaponentity(this, weaponentity);
 696                 if(oldwep && oldwep.owner == this)
 697                         this.(weaponentity).m_gunalign = oldwep.m_gunalign;
 698         }
 699         this.alpha = default_player_alpha;
 700         this.colormod = '1 1 1' * autocvar_g_player_brightness;
 701         this.exteriorweaponentity.alpha = default_weapon_alpha;
 702
 703         this.speedrunning = false;
 704
 705         target_voicescript_clear(this);
 706
 707         // reset fields the weapons may use
 708         FOREACH(Weapons, true, {
 709                 it.wr_resetplayer(it, this);
 710                         // reload all reloadable weapons
 711                 if (it.spawnflags & WEP_FLAG_RELOADABLE) {
 712                         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 713                         {
 714                                 .entity weaponentity = weaponentities[slot];
 715                                 this.(weaponentity).weapon_load[it.m_id] = it.reloading_ammo;
 716                         }
 717                 }
 718         });
 719
 720         {
 721                 string s = spot.target;
 722                 spot.target = string_null;
 723                 SUB_UseTargets(spot, this, NULL);
 724                 spot.target = s;
 725         }
 726
 727         Unfreeze(this);
 728
 729         MUTATOR_CALLHOOK(PlayerSpawn, this, spot);
 730
 731         if (autocvar_spawn_debug)
 732         {
 733                 sprint(this, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
 734                 delete(spot); // usefull for checking if there are spawnpoints, that let drop through the floor
 735         }
 736
 737         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 738         {
 739                 .entity weaponentity = weaponentities[slot];
 740                 if(slot == 0 || autocvar_g_weaponswitch_debug == 1)
 741                         this.(weaponentity).m_switchweapon = w_getbestweapon(this, weaponentity);
 742                 else
 743                         this.(weaponentity).m_switchweapon = WEP_Null;
 744                 this.(weaponentity).m_weapon = WEP_Null;
 745                 this.(weaponentity).weaponname = "";
 746                 this.(weaponentity).m_switchingweapon = WEP_Null;
 747                 this.(weaponentity).cnt = -1;
 748         }
 749
 750         MUTATOR_CALLHOOK(PlayerWeaponSelect, this);
 751
 752         if (CS(this).impulse) ImpulseCommands(this);
 753
 754         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 755         {
 756                 .entity weaponentity = weaponentities[slot];
 757                 W_WeaponFrame(this, weaponentity);
 758         }
 759
 760         if (!warmup_stage && !this.alivetime)
 761                 this.alivetime = time;
 762
 763         antilag_clear(this, CS(this));
 764 }
 765
 766 /** Called when a client spawns in the server */
 767 void PutClientInServer(entity this)
 768 {
 769         if (IS_BOT_CLIENT(this)) {
 770                 TRANSMUTE(Player, this);
 771         } else if (IS_REAL_CLIENT(this)) {
 772                 msg_entity = this;
 773                 WriteByte(MSG_ONE, SVC_SETVIEW);
 774                 WriteEntity(MSG_ONE, this);
 775         }
 776         if (game_stopped)
 777                 TRANSMUTE(Observer, this);
 778
 779         SetSpectatee(this, NULL);
 780
 781         // reset player keys
 782         if(PS(this))
 783                 PS(this).itemkeys = 0;
 784
 785         MUTATOR_CALLHOOK(PutClientInServer, this);
 786
 787         if (IS_OBSERVER(this)) {
 788                 PutObserverInServer(this);
 789         } else if (IS_PLAYER(this)) {
 790                 PutPlayerInServer(this);
 791         }
 792 }
 793
 794 // TODO do we need all these fields, or should we stop autodetecting runtime
 795 // changes and just have a console command to update this?
 796 bool ClientInit_SendEntity(entity this, entity to, int sf)
 797 {
 798         WriteHeader(MSG_ENTITY, _ENT_CLIENT_INIT);
 799         return = true;
 800         msg_entity = to;
 801         // MSG_INIT replacement
 802         // TODO: make easier to use
 803         Registry_send_all();
 804         W_PROP_reload(MSG_ONE, to);
 805         ClientInit_misc(this);
 806         MUTATOR_CALLHOOK(Ent_Init);
 807 }
 808 void ClientInit_misc(entity this)
 809 {
 810         int channel = MSG_ONE;
 811         WriteHeader(channel, ENT_CLIENT_INIT);
 812         WriteByte(channel, g_nexball_meter_period * 32);
 813         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[0]));
 814         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[1]));
 815         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[2]));
 816         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[3]));
 817         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[0]));
 818         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[1]));
 819         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[2]));
 820         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[3]));
 821
 822         if(sv_foginterval && world.fog != "")
 823                 WriteString(channel, world.fog);
 824         else
 825                 WriteString(channel, "");
 826         WriteByte(channel, this.count * 255.0); // g_balance_armor_blockpercent
 827         WriteByte(channel, this.cnt * 255.0); // g_balance_damagepush_speedfactor
 828         WriteByte(channel, serverflags);
 829         WriteCoord(channel, autocvar_g_trueaim_minrange);
 830 }
 831
 832 void ClientInit_CheckUpdate(entity this)
 833 {
 834         this.nextthink = time;
 835         if(this.count != autocvar_g_balance_armor_blockpercent)
 836         {
 837                 this.count = autocvar_g_balance_armor_blockpercent;
 838                 this.SendFlags |= 1;
 839         }
 840         if(this.cnt != autocvar_g_balance_damagepush_speedfactor)
 841         {
 842                 this.cnt = autocvar_g_balance_damagepush_speedfactor;
 843                 this.SendFlags |= 1;
 844         }
 845 }
 846
 847 void ClientInit_Spawn()
 848 {
 849         entity e = new_pure(clientinit);
 850         setthink(e, ClientInit_CheckUpdate);
 851         Net_LinkEntity(e, false, 0, ClientInit_SendEntity);
 852
 853         ClientInit_CheckUpdate(e);
 854 }
 855
 856 /*
 857 =============
 858 SetNewParms
 859 =============
 860 */
 861 void SetNewParms ()
 862 {
 863         // initialize parms for a new player
 864         parm1 = -(86400 * 366);
 865
 866         MUTATOR_CALLHOOK(SetNewParms);
 867 }
 868
 869 /*
 870 =============
 871 SetChangeParms
 872 =============
 873 */
 874 void SetChangeParms (entity this)
 875 {
 876         // save parms for level change
 877         parm1 = CS(this).parm_idlesince - time;
 878
 879         MUTATOR_CALLHOOK(SetChangeParms);
 880 }
 881
 882 /*
 883 =============
 884 DecodeLevelParms
 885 =============
 886 */
 887 void DecodeLevelParms(entity this)
 888 {
 889         // load parms
 890         CS(this).parm_idlesince = parm1;
 891         if (CS(this).parm_idlesince == -(86400 * 366))
 892                 CS(this).parm_idlesince = time;
 893
 894         // whatever happens, allow 60 seconds of idling directly after connect for map loading
 895         CS(this).parm_idlesince = max(CS(this).parm_idlesince, time - sv_maxidle + 60);
 896
 897         MUTATOR_CALLHOOK(DecodeLevelParms);
 898 }
 899
 900 void FixClientCvars(entity e)
 901 {
 902         // send prediction settings to the client
 903         stuffcmd(e, "\nin_bindmap 0 0\n");
 904         if(autocvar_g_antilag == 3) // client side hitscan
 905                 stuffcmd(e, "cl_cmd settemp cl_prydoncursor_notrace 0\n");
 906         if(autocvar_sv_gentle)
 907                 stuffcmd(e, "cl_cmd settemp cl_gentle 1\n");
 908
 909         stuffcmd(e, sprintf("\ncl_jumpspeedcap_min \"%s\"\n", autocvar_sv_jumpspeedcap_min));
 910         stuffcmd(e, sprintf("\ncl_jumpspeedcap_max \"%s\"\n", autocvar_sv_jumpspeedcap_max));
 911
 912         stuffcmd(e, sprintf("\ncl_shootfromfixedorigin \"%s\"\n", autocvar_g_shootfromfixedorigin));
 913
 914         MUTATOR_CALLHOOK(FixClientCvars, e);
 915 }
 916
 917 bool findinlist_abbrev(string tofind, string list)
 918 {
 919         if(list == "" || tofind == "")
 920                 return false; // empty list or search, just return
 921
 922         // this function allows abbreviated strings!
 923         FOREACH_WORD(list, it == substring(tofind, 0, strlen(it)),
 924         {
 925                 return true;
 926         });
 927
 928         return false;
 929 }
 930
 931 bool PlayerInIPList(entity p, string iplist)
 932 {
 933         // some safety checks (never allow local?)
 934         if(p.netaddress == "local" || p.netaddress == "" || !IS_REAL_CLIENT(p))
 935                 return false;
 936
 937         return findinlist_abbrev(p.netaddress, iplist);
 938 }
 939
 940 bool PlayerInIDList(entity p, string idlist)
 941 {
 942         // NOTE: we do NOT check crypto_idfp_signed here, an unsigned ID is fine too for this
 943         if(!p.crypto_idfp)
 944                 return false;
 945
 946         return findinlist_abbrev(p.crypto_idfp, idlist);
 947 }
 948
 949 bool PlayerInList(entity player, string list)
 950 {
 951         return boolean(PlayerInIDList(player, list) || PlayerInIPList(player, list));
 952 }
 953
 954 #ifdef DP_EXT_PRECONNECT
 955 /*
 956 =============
 957 ClientPreConnect
 958
 959 Called once (not at each match start) when a client begins a connection to the server
 960 =============
 961 */
 962 void ClientPreConnect(entity this)
 963 {
 964         if(autocvar_sv_eventlog)
 965         {
 966                 GameLogEcho(sprintf(":connect:%d:%d:%s",
 967                         this.playerid,
 968                         etof(this),
 969                         ((IS_REAL_CLIENT(this)) ? this.netaddress : "bot")
 970                 ));
 971         }
 972 }
 973 #endif
 974
 975 string GetClientVersionMessage(entity this)
 976 {
 977         if (CS(this).version_mismatch) {
 978                 if(CS(this).version < autocvar_gameversion) {
 979                         return strcat("This is Xonotic ", autocvar_g_xonoticversion,
 980                                 "\n^3Your client version is outdated.\n\n\n### YOU WON'T BE ABLE TO PLAY ON THIS SERVER ###\n\n\nPlease update!!!^8");
 981                 } else {
 982                         return strcat("This is Xonotic ", autocvar_g_xonoticversion,
 983                                 "\n^3This server is using an outdated Xonotic version.\n\n\n ### THIS SERVER IS INCOMPATIBLE AND THUS YOU CANNOT JOIN ###.^8");
 984                 }
 985         } else {
 986                 return strcat("Welcome to Xonotic ", autocvar_g_xonoticversion);
 987         }
 988 }
 989
 990 string getwelcomemessage(entity this)
 991 {
 992         MUTATOR_CALLHOOK(BuildMutatorsPrettyString, "");
 993         string modifications = M_ARGV(0, string);
 994
 995         if(g_weaponarena)
 996         {
 997                 if(g_weaponarena_random)
 998                         modifications = strcat(modifications, ", ", ftos(g_weaponarena_random), " of ", g_weaponarena_list, " Arena");
 999                 else
1000                         modifications = strcat(modifications, ", ", g_weaponarena_list, " Arena");
1001         }
1002         else if(cvar("g_balance_blaster_weaponstartoverride") == 0)
1003                 modifications = strcat(modifications, ", No start weapons");
1004         if(cvar("sv_gravity") < stof(cvar_defstring("sv_gravity")))
1005                 modifications = strcat(modifications, ", Low gravity");
1006         if(g_weapon_stay && !g_cts)
1007                 modifications = strcat(modifications, ", Weapons stay");
1008         if(g_jetpack)
1009                 modifications = strcat(modifications, ", Jet pack");
1010         if(autocvar_g_powerups == 0)
1011                 modifications = strcat(modifications, ", No powerups");
1012         if(autocvar_g_powerups > 0)
1013                 modifications = strcat(modifications, ", Powerups");
1014         modifications = substring(modifications, 2, strlen(modifications) - 2);
1015
1016         string versionmessage = GetClientVersionMessage(this);
1017         string s = strcat(versionmessage, "^8\n^8\nmatch type is ^1", gamemode_name, "^8\n");
1018
1019         if(modifications != "")
1020                 s = strcat(s, "^8\nactive modifications: ^3", modifications, "^8\n");
1021
1022         if(cache_lastmutatormsg != autocvar_g_mutatormsg)
1023         {
1024                 strcpy(cache_lastmutatormsg, autocvar_g_mutatormsg);
1025                 strcpy(cache_mutatormsg, cache_lastmutatormsg);
1026         }
1027
1028         if (cache_mutatormsg != "") {
1029                 s = strcat(s, "\n\n^8special gameplay tips: ^7", cache_mutatormsg);
1030         }
1031
1032         string mutator_msg = "";
1033         MUTATOR_CALLHOOK(BuildGameplayTipsString, mutator_msg);
1034         mutator_msg = M_ARGV(0, string);
1035
1036         s = strcat(s, mutator_msg); // trust that the mutator will do proper formatting
1037
1038         string motd = autocvar_sv_motd;
1039         if (motd != "") {
1040                 s = strcat(s, "\n\n^8MOTD: ^7", strreplace("\\n", "\n", motd));
1041         }
1042         return s;
1043 }
1044
1045 /**
1046 =============
1047 ClientConnect
1048
1049 Called when a client connects to the server
1050 =============
1051 */
1052 void ClientConnect(entity this)
1053 {
1054         if (Ban_MaybeEnforceBanOnce(this)) return;
1055         assert(!IS_CLIENT(this), return);
1056         this.flags |= FL_CLIENT;
1057         assert(player_count >= 0, player_count = 0);
1058
1059 #ifdef WATERMARK
1060         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_WATERMARK, WATERMARK);
1061 #endif
1062         TRANSMUTE(Client, this);
1063         CS(this).version_nagtime = time + 10 + random() * 10;
1064
1065         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_JOIN_CONNECT, this.netname);
1066
1067         bot_clientconnect(this);
1068
1069         Player_DetermineForcedTeam(this);
1070
1071         TRANSMUTE(Observer, this);
1072
1073         PlayerStats_GameReport_AddEvent(sprintf("kills-%d", this.playerid));
1074
1075         // always track bots, don't ask for cl_allow_uidtracking
1076         if (IS_BOT_CLIENT(this))
1077                 PlayerStats_GameReport_AddPlayer(this);
1078         else
1079                 CS(this).allowed_timeouts = autocvar_sv_timeout_number;
1080
1081         if (autocvar_sv_eventlog)
1082                 GameLogEcho(strcat(":join:", ftos(this.playerid), ":", ftos(etof(this)), ":", ((IS_REAL_CLIENT(this)) ? this.netaddress : "bot"), ":", playername(this, false)));
1083
1084         CS(this).just_joined = true;  // stop spamming the eventlog with additional lines when the client connects
1085
1086         stuffcmd(this, clientstuff, "\n");
1087         stuffcmd(this, "cl_particles_reloadeffects\n"); // TODO do we still need this?
1088
1089         FixClientCvars(this);
1090
1091         // get version info from player
1092         stuffcmd(this, "cmd clientversion $gameversion\n");
1093
1094         // notify about available teams
1095         if (teamplay)
1096         {
1097                 entity balance = TeamBalance_CheckAllowedTeams(this);
1098                 int t = TeamBalance_GetAllowedTeams(balance);
1099                 TeamBalance_Destroy(balance);
1100                 stuffcmd(this, sprintf("set _teams_available %d\n", t));
1101         }
1102         else
1103         {
1104                 stuffcmd(this, "set _teams_available 0\n");
1105         }
1106
1107         bot_relinkplayerlist();
1108
1109         CS(this).spectatortime = time;
1110         if (blockSpectators)
1111         {
1112                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
1113         }
1114
1115         CS(this).jointime = time;
1116
1117         if (IS_REAL_CLIENT(this))
1118         {
1119                 if (g_weaponarena_weapons == WEPSET(TUBA))
1120                         stuffcmd(this, "cl_cmd settemp chase_active 1\n");
1121         }
1122
1123         if (!sv_foginterval && world.fog != "")
1124                 stuffcmd(this, strcat("\nfog ", world.fog, "\nr_fog_exp2 0\nr_drawfog 1\n"));
1125
1126         if (autocvar_sv_teamnagger && !(autocvar_bot_vs_human && AvailableTeams() == 2))
1127                 if(!MUTATOR_CALLHOOK(HideTeamNagger, this))
1128                         send_CSQC_teamnagger();
1129
1130         CSQCMODEL_AUTOINIT(this);
1131
1132         CS(this).model_randomizer = random();
1133
1134         if (IS_REAL_CLIENT(this))
1135                 sv_notice_join(this);
1136
1137         // update physics stats (players can spawn before physics runs)
1138         Physics_UpdateStats(this);
1139
1140         IL_EACH(g_initforplayer, it.init_for_player, {
1141                 it.init_for_player(it, this);
1142         });
1143
1144         Handicap_Initialize(this);
1145
1146         MUTATOR_CALLHOOK(ClientConnect, this);
1147
1148         if (IS_REAL_CLIENT(this))
1149         {
1150                 if (!autocvar_g_campaign && !IS_PLAYER(this))
1151                 {
1152                         CS(this).motd_actived_time = -1;
1153                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOTD, getwelcomemessage(this));
1154                 }
1155         }
1156 }
1157 /*
1158 =============
1159 ClientDisconnect
1160
1161 Called when a client disconnects from the server
1162 =============
1163 */
1164 .entity chatbubbleentity;
1165 void ClientDisconnect(entity this)
1166 {
1167         assert(IS_CLIENT(this), return);
1168
1169         PlayerStats_GameReport_FinalizePlayer(this);
1170         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
1171         if (CS(this).active_minigame) part_minigame(this);
1172         if (IS_PLAYER(this)) Send_Effect(EFFECT_SPAWN_NEUTRAL, this.origin, '0 0 0', 1);
1173
1174         if (autocvar_sv_eventlog)
1175                 GameLogEcho(strcat(":part:", ftos(this.playerid)));
1176
1177         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_QUIT_DISCONNECT, this.netname);
1178
1179         if(IS_SPEC(this))
1180                 SetSpectatee(this, NULL);
1181
1182     MUTATOR_CALLHOOK(ClientDisconnect, this);
1183
1184         strfree(CS(this).netname_previous); // needs to be before the CS entity is removed!
1185         strfree(CS(this).weaponorder_byimpulse);
1186         ClientState_detach(this);
1187
1188         Portal_ClearAll(this);
1189
1190         Unfreeze(this);
1191
1192         RemoveGrapplingHooks(this);
1193
1194         // Here, everything has been done that requires this player to be a client.
1195
1196         this.flags &= ~FL_CLIENT;
1197
1198         if (this.chatbubbleentity) delete(this.chatbubbleentity);
1199         if (this.killindicator) delete(this.killindicator);
1200
1201         WaypointSprite_PlayerGone(this);
1202
1203         bot_relinkplayerlist();
1204
1205         strfree(this.clientstatus);
1206         if (this.personal) delete(this.personal);
1207
1208         this.playerid = 0;
1209         ReadyCount();
1210         if (vote_called && IS_REAL_CLIENT(this)) VoteCount(false);
1211
1212         ONREMOVE(this);
1213 }
1214
1215 void ChatBubbleThink(entity this)
1216 {
1217         this.nextthink = time;
1218         if ((this.owner.alpha < 0) || this.owner.chatbubbleentity != this)
1219         {
1220                 if(this.owner) // but why can that ever be NULL?
1221                         this.owner.chatbubbleentity = NULL;
1222                 delete(this);
1223                 return;
1224         }
1225
1226         this.mdl = "";
1227
1228         if ( !IS_DEAD(this.owner) && IS_PLAYER(this.owner) )
1229         {
1230                 if ( CS(this.owner).active_minigame )
1231                         this.mdl = "models/sprites/minigame_busy.iqm";
1232                 else if (PHYS_INPUT_BUTTON_CHAT(this.owner))
1233                         this.mdl = "models/misc/chatbubble.spr";
1234         }
1235
1236         if ( this.model != this.mdl )
1237                 _setmodel(this, this.mdl);
1238
1239 }
1240
1241 void UpdateChatBubble(entity this)
1242 {
1243         if (this.alpha < 0)
1244                 return;
1245         // spawn a chatbubble entity if needed
1246         if (!this.chatbubbleentity)
1247         {
1248                 this.chatbubbleentity = new(chatbubbleentity);
1249                 this.chatbubbleentity.owner = this;
1250                 this.chatbubbleentity.exteriormodeltoclient = this;
1251                 setthink(this.chatbubbleentity, ChatBubbleThink);
1252                 this.chatbubbleentity.nextthink = time;
1253                 setmodel(this.chatbubbleentity, MDL_CHAT); // precision set below
1254                 //setorigin(this.chatbubbleentity, this.origin + '0 0 15' + this.maxs_z * '0 0 1');
1255                 setorigin(this.chatbubbleentity, '0 0 15' + this.maxs_z * '0 0 1');
1256                 setattachment(this.chatbubbleentity, this, "");  // sticks to moving player better, also conserves bandwidth
1257                 this.chatbubbleentity.mdl = this.chatbubbleentity.model;
1258                 //this.chatbubbleentity.model = "";
1259                 this.chatbubbleentity.effects = EF_LOWPRECISION;
1260         }
1261 }
1262
1263
1264 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
1265 // added to the model skins
1266 /*void UpdateColorModHack()
1267 {
1268         float c;
1269         c = this.clientcolors & 15;
1270         // LordHavoc: only bothering to support white, green, red, yellow, blue
1271              if (!teamplay) this.colormod = '0 0 0';
1272         else if (c ==  0) this.colormod = '1.00 1.00 1.00';
1273         else if (c ==  3) this.colormod = '0.10 1.73 0.10';
1274         else if (c ==  4) this.colormod = '1.73 0.10 0.10';
1275         else if (c == 12) this.colormod = '1.22 1.22 0.10';
1276         else if (c == 13) this.colormod = '0.10 0.10 1.73';
1277         else this.colormod = '1 1 1';
1278 }*/
1279
1280 void respawn(entity this)
1281 {
1282         if(this.alpha >= 0 && autocvar_g_respawn_ghosts)
1283         {
1284                 this.solid = SOLID_NOT;
1285                 this.takedamage = DAMAGE_NO;
1286                 set_movetype(this, MOVETYPE_FLY);
1287                 this.velocity = '0 0 1' * autocvar_g_respawn_ghosts_speed;
1288                 this.avelocity = randomvec() * autocvar_g_respawn_ghosts_speed * 3 - randomvec() * autocvar_g_respawn_ghosts_speed * 3;
1289                 this.effects |= CSQCMODEL_EF_RESPAWNGHOST;
1290                 Send_Effect(EFFECT_RESPAWN_GHOST, this.origin, '0 0 0', 1);
1291                 if(autocvar_g_respawn_ghosts_maxtime)
1292                         SUB_SetFade (this, time + autocvar_g_respawn_ghosts_maxtime / 2 + random () * (autocvar_g_respawn_ghosts_maxtime - autocvar_g_respawn_ghosts_maxtime / 2), 1.5);
1293         }
1294
1295         CopyBody(this, 1);
1296
1297         this.effects |= EF_NODRAW; // prevent another CopyBody
1298         PutClientInServer(this);
1299 }
1300
1301 void PrintToChat(entity client, string text)
1302 {
1303         text = strcat("\{1}^7", text, "\n");
1304         sprint(client, text);
1305 }
1306
1307 void DebugPrintToChat(entity client, string text)
1308 {
1309         if (autocvar_developer)
1310         {
1311                 PrintToChat(client, text);
1312         }
1313 }
1314
1315 void PrintToChatAll(string text)
1316 {
1317         text = strcat("\{1}^7", text, "\n");
1318         bprint(text);
1319 }
1320
1321 void DebugPrintToChatAll(string text)
1322 {
1323         if (autocvar_developer)
1324         {
1325                 PrintToChatAll(text);
1326         }
1327 }
1328
1329 void PrintToChatTeam(int team_num, string text)
1330 {
1331         text = strcat("\{1}^7", text, "\n");
1332         FOREACH_CLIENT(IS_REAL_CLIENT(it),
1333         {
1334                 if (it.team == team_num)
1335                 {
1336                         sprint(it, text);
1337                 }
1338         });
1339 }
1340
1341 void DebugPrintToChatTeam(int team_num, string text)
1342 {
1343         if (autocvar_developer)
1344         {
1345                 PrintToChatTeam(team_num, text);
1346         }
1347 }
1348
1349 void play_countdown(entity this, float finished, Sound samp)
1350 {
1351         TC(Sound, samp);
1352         if(IS_REAL_CLIENT(this))
1353                 if(floor(finished - time - frametime) != floor(finished - time))
1354                         if(finished - time < 6)
1355                                 sound (this, CH_INFO, samp, VOL_BASE, ATTEN_NORM);
1356 }
1357
1358 void player_powerups(entity this)
1359 {
1360         // add a way to see what the items were BEFORE all of these checks for the mutator hook
1361         int items_prev = this.items;
1362
1363         if((this.items & IT_USING_JETPACK) && !IS_DEAD(this) && !game_stopped)
1364                 this.modelflags |= MF_ROCKET;
1365         else
1366                 this.modelflags &= ~MF_ROCKET;
1367
1368         this.effects &= ~(EF_RED | EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT | EF_FLAME | EF_NODEPTHTEST);
1369
1370         if((this.alpha < 0 || IS_DEAD(this)) && !this.vehicle) // don't apply the flags if the player is gibbed
1371                 return;
1372
1373         Fire_ApplyDamage(this);
1374         Fire_ApplyEffect(this);
1375
1376         if (!MUTATOR_IS_ENABLED(mutator_instagib))
1377         {
1378                 if (this.items & ITEM_Strength.m_itemid)
1379                 {
1380                         play_countdown(this, this.strength_finished, SND_POWEROFF);
1381                         this.effects = this.effects | (EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT);
1382                         if (time > this.strength_finished)
1383                         {
1384                                 this.items = this.items - (this.items & ITEM_Strength.m_itemid);
1385                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERDOWN_STRENGTH, this.netname);
1386                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERDOWN_STRENGTH);
1387                         }
1388                 }
1389                 else
1390                 {
1391                         if (time < this.strength_finished)
1392                         {
1393                                 this.items = this.items | ITEM_Strength.m_itemid;
1394                                 if(!g_cts)
1395                                         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERUP_STRENGTH, this.netname);
1396                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERUP_STRENGTH);
1397                         }
1398                 }
1399                 if (this.items & ITEM_Shield.m_itemid)
1400                 {
1401                         play_countdown(this, this.invincible_finished, SND_POWEROFF);
1402                         this.effects = this.effects | (EF_RED | EF_ADDITIVE | EF_FULLBRIGHT);
1403                         if (time > this.invincible_finished)
1404                         {
1405                                 this.items = this.items - (this.items & ITEM_Shield.m_itemid);
1406                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERDOWN_SHIELD, this.netname);
1407                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERDOWN_SHIELD);
1408                         }
1409                 }
1410                 else
1411                 {
1412                         if (time < this.invincible_finished)
1413                         {
1414                                 this.items = this.items | ITEM_Shield.m_itemid;
1415                                 if(!g_cts)
1416                                         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERUP_SHIELD, this.netname);
1417                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERUP_SHIELD);
1418                         }
1419                 }
1420                 if (this.items & IT_SUPERWEAPON)
1421                 {
1422                         if (!(STAT(WEAPONS, this) & WEPSET_SUPERWEAPONS))
1423                         {
1424                                 this.superweapons_finished = 0;
1425                                 this.items = this.items - (this.items & IT_SUPERWEAPON);
1426                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_LOST, this.netname);
1427                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_LOST);
1428                         }
1429                         else if (this.items & IT_UNLIMITED_SUPERWEAPONS)
1430                         {
1431                                 // don't let them run out
1432                         }
1433                         else
1434                         {
1435                                 play_countdown(this, this.superweapons_finished, SND_POWEROFF);
1436                                 if (time > this.superweapons_finished)
1437                                 {
1438                                         this.items = this.items - (this.items & IT_SUPERWEAPON);
1439                                         STAT(WEAPONS, this) &= ~WEPSET_SUPERWEAPONS;
1440                                         //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_BROKEN, this.netname);
1441                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_BROKEN);
1442                                 }
1443                         }
1444                 }
1445                 else if(STAT(WEAPONS, this) & WEPSET_SUPERWEAPONS)
1446                 {
1447                         if (time < this.superweapons_finished || (this.items & IT_UNLIMITED_SUPERWEAPONS))
1448                         {
1449                                 this.items = this.items | IT_SUPERWEAPON;
1450                                 if(!g_cts)
1451                                         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_PICKUP, this.netname);
1452                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_PICKUP);
1453                         }
1454                         else
1455                         {
1456                                 this.superweapons_finished = 0;
1457                                 STAT(WEAPONS, this) &= ~WEPSET_SUPERWEAPONS;
1458                         }
1459                 }
1460                 else
1461                 {
1462                         this.superweapons_finished = 0;
1463                 }
1464         }
1465
1466         if(autocvar_g_nodepthtestplayers)
1467                 this.effects = this.effects | EF_NODEPTHTEST;
1468
1469         if(autocvar_g_fullbrightplayers)
1470                 this.effects = this.effects | EF_FULLBRIGHT;
1471
1472         if (time >= game_starttime)
1473         if (time < this.spawnshieldtime)
1474                 this.effects = this.effects | (EF_ADDITIVE | EF_FULLBRIGHT);
1475
1476         MUTATOR_CALLHOOK(PlayerPowerups, this, items_prev);
1477 }
1478
1479 float CalcRegen(float current, float stable, float regenfactor, float regenframetime)
1480 {
1481         if(current > stable)
1482                 return current;
1483         else if(current > stable - 0.25) // when close enough, "snap"
1484                 return stable;
1485         else
1486                 return min(stable, current + (stable - current) * regenfactor * regenframetime);
1487 }
1488
1489 float CalcRot(float current, float stable, float rotfactor, float rotframetime)
1490 {
1491         if(current < stable)
1492                 return current;
1493         else if(current < stable + 0.25) // when close enough, "snap"
1494                 return stable;
1495         else
1496                 return max(stable, current + (stable - current) * rotfactor * rotframetime);
1497 }
1498
1499 float CalcRotRegen(float current, float regenstable, float regenfactor, float regenlinear, float regenframetime, float rotstable, float rotfactor, float rotlinear, float rotframetime, float limit)
1500 {
1501         if(current > rotstable)
1502         {
1503                 if(rotframetime > 0)
1504                 {
1505                         current = CalcRot(current, rotstable, rotfactor, rotframetime);
1506                         current = max(rotstable, current - rotlinear * rotframetime);
1507                 }
1508         }
1509         else if(current < regenstable)
1510         {
1511                 if(regenframetime > 0)
1512                 {
1513                         current = CalcRegen(current, regenstable, regenfactor, regenframetime);
1514                         current = min(regenstable, current + regenlinear * regenframetime);
1515                 }
1516         }
1517
1518         if(current > limit)
1519                 current = limit;
1520
1521         return current;
1522 }
1523
1524 void player_regen(entity this)
1525 {
1526         float max_mod, regen_mod, rot_mod, limit_mod;
1527         max_mod = regen_mod = rot_mod = limit_mod = 1;
1528
1529         float regen_health = autocvar_g_balance_health_regen;
1530         float regen_health_linear = autocvar_g_balance_health_regenlinear;
1531         float regen_health_rot = autocvar_g_balance_health_rot;
1532         float regen_health_rotlinear = autocvar_g_balance_health_rotlinear;
1533         float regen_health_stable = autocvar_g_balance_health_regenstable;
1534         float regen_health_rotstable = autocvar_g_balance_health_rotstable;
1535         bool mutator_returnvalue = MUTATOR_CALLHOOK(PlayerRegen, this, max_mod, regen_mod, rot_mod, limit_mod, regen_health, regen_health_linear, regen_health_rot,
1536                 regen_health_rotlinear, regen_health_stable, regen_health_rotstable);
1537         max_mod = M_ARGV(1, float);
1538         regen_mod = M_ARGV(2, float);
1539         rot_mod = M_ARGV(3, float);
1540         limit_mod = M_ARGV(4, float);
1541         regen_health = M_ARGV(5, float);
1542         regen_health_linear = M_ARGV(6, float);
1543         regen_health_rot = M_ARGV(7, float);
1544         regen_health_rotlinear = M_ARGV(8, float);
1545         regen_health_stable = M_ARGV(9, float);
1546         regen_health_rotstable = M_ARGV(10, float);
1547
1548         if(!mutator_returnvalue)
1549         if(!STAT(FROZEN, this))
1550         {
1551                 float mina, maxa, limith, limita;
1552                 maxa = autocvar_g_balance_armor_rotstable;
1553                 mina = autocvar_g_balance_armor_regenstable;
1554                 limith = GetResourceLimit(this, RESOURCE_HEALTH);
1555                 limita = GetResourceLimit(this, RESOURCE_ARMOR);
1556
1557                 regen_health_rotstable = regen_health_rotstable * max_mod;
1558                 regen_health_stable = regen_health_stable * max_mod;
1559                 limith = limith * limit_mod;
1560                 limita = limita * limit_mod;
1561
1562                 SetResourceAmount(this, RESOURCE_ARMOR, CalcRotRegen(GetResourceAmount(this, RESOURCE_ARMOR), mina, autocvar_g_balance_armor_regen, autocvar_g_balance_armor_regenlinear,
1563                                                                         regen_mod * frametime * (time > this.pauseregen_finished), maxa, autocvar_g_balance_armor_rot, autocvar_g_balance_armor_rotlinear,
1564                                                                         rot_mod * frametime * (time > this.pauserotarmor_finished), limita));
1565                 SetResourceAmount(this, RESOURCE_HEALTH, CalcRotRegen(GetResourceAmount(this, RESOURCE_HEALTH), regen_health_stable, regen_health, regen_health_linear,
1566                                                                         regen_mod * frametime * (time > this.pauseregen_finished), regen_health_rotstable, regen_health_rot, regen_health_rotlinear,
1567                                                                         rot_mod * frametime * (time > this.pauserothealth_finished), limith));
1568         }
1569
1570         // if player rotted to death...  die!
1571         // check this outside above checks, as player may still be able to rot to death
1572         if(GetResourceAmount(this, RESOURCE_HEALTH) < 1)
1573         {
1574                 if(this.vehicle)
1575                         vehicles_exit(this.vehicle, VHEF_RELEASE);
1576                 if(this.event_damage)
1577                         this.event_damage(this, this, this, 1, DEATH_ROT.m_id, DMG_NOWEP, this.origin, '0 0 0');
1578         }
1579
1580         if (!(this.items & IT_UNLIMITED_WEAPON_AMMO))
1581         {
1582                 float minf, maxf, limitf;
1583
1584                 maxf = autocvar_g_balance_fuel_rotstable;
1585                 minf = autocvar_g_balance_fuel_regenstable;
1586                 limitf = GetResourceLimit(this, RESOURCE_FUEL);
1587
1588                 SetResourceAmount(this, RESOURCE_FUEL, CalcRotRegen(GetResourceAmount(this, RESOURCE_FUEL), minf, autocvar_g_balance_fuel_regen, autocvar_g_balance_fuel_regenlinear,
1589                                                                                 frametime * (time > this.pauseregen_finished) * ((this.items & ITEM_JetpackRegen.m_itemid) != 0),
1590                                                                                 maxf, autocvar_g_balance_fuel_rot, autocvar_g_balance_fuel_rotlinear, frametime * (time > this.pauserotfuel_finished), limitf));
1591         }
1592 }
1593
1594 bool zoomstate_set;
1595 void SetZoomState(entity this, float newzoom)
1596 {
1597         if(newzoom != CS(this).zoomstate)
1598         {
1599                 CS(this).zoomstate = newzoom;
1600                 ClientData_Touch(this);
1601         }
1602         zoomstate_set = true;
1603 }
1604
1605 void GetPressedKeys(entity this)
1606 {
1607         MUTATOR_CALLHOOK(GetPressedKeys, this);
1608         int keys = STAT(PRESSED_KEYS, this);
1609         keys = BITSET(keys, KEY_FORWARD,        CS(this).movement.x > 0);
1610         keys = BITSET(keys, KEY_BACKWARD,       CS(this).movement.x < 0);
1611         keys = BITSET(keys, KEY_RIGHT,          CS(this).movement.y > 0);
1612         keys = BITSET(keys, KEY_LEFT,           CS(this).movement.y < 0);
1613
1614         keys = BITSET(keys, KEY_JUMP,           PHYS_INPUT_BUTTON_JUMP(this));
1615         keys = BITSET(keys, KEY_CROUCH,         IS_DUCKED(this)); // workaround: player can't un-crouch until their path is clear, so we keep the button held here
1616         keys = BITSET(keys, KEY_ATCK,           PHYS_INPUT_BUTTON_ATCK(this));
1617         keys = BITSET(keys, KEY_ATCK2,          PHYS_INPUT_BUTTON_ATCK2(this));
1618         CS(this).pressedkeys = keys; // store for other users
1619
1620         STAT(PRESSED_KEYS, this) = keys;
1621 }
1622
1623 /*
1624 ======================
1625 spectate mode routines
1626 ======================
1627 */
1628
1629 void SpectateCopy(entity this, entity spectatee)
1630 {
1631         TC(Client, this); TC(Client, spectatee);
1632
1633         MUTATOR_CALLHOOK(SpectateCopy, spectatee, this);
1634         PS(this) = PS(spectatee);
1635         this.armortype = spectatee.armortype;
1636         SetResourceAmountExplicit(this, RESOURCE_ARMOR, GetResourceAmount(spectatee, RESOURCE_ARMOR));
1637         SetResourceAmountExplicit(this, RESOURCE_CELLS, GetResourceAmount(spectatee, RESOURCE_CELLS));
1638         SetResourceAmountExplicit(this, RESOURCE_PLASMA, GetResourceAmount(spectatee, RESOURCE_PLASMA));
1639         SetResourceAmountExplicit(this, RESOURCE_SHELLS, GetResourceAmount(spectatee, RESOURCE_SHELLS));
1640         SetResourceAmountExplicit(this, RESOURCE_BULLETS, GetResourceAmount(spectatee, RESOURCE_BULLETS));
1641         SetResourceAmountExplicit(this, RESOURCE_ROCKETS, GetResourceAmount(spectatee, RESOURCE_ROCKETS));
1642         SetResourceAmountExplicit(this, RESOURCE_FUEL, GetResourceAmount(spectatee, RESOURCE_FUEL));
1643         this.effects = spectatee.effects & EFMASK_CHEAP; // eat performance
1644         SetResourceAmountExplicit(this, RESOURCE_HEALTH, GetResourceAmount(spectatee, RESOURCE_HEALTH));
1645         CS(this).impulse = 0;
1646         this.items = spectatee.items;
1647         STAT(LAST_PICKUP, this) = STAT(LAST_PICKUP, spectatee);
1648         STAT(HIT_TIME, this) = STAT(HIT_TIME, spectatee);
1649         this.strength_finished = spectatee.strength_finished;
1650         this.invincible_finished = spectatee.invincible_finished;
1651         this.superweapons_finished = spectatee.superweapons_finished;
1652         STAT(PRESSED_KEYS, this) = STAT(PRESSED_KEYS, spectatee);
1653         STAT(WEAPONS, this) = STAT(WEAPONS, spectatee);
1654         this.punchangle = spectatee.punchangle;
1655         this.view_ofs = spectatee.view_ofs;
1656         this.velocity = spectatee.velocity;
1657         this.dmg_take = spectatee.dmg_take;
1658         this.dmg_save = spectatee.dmg_save;
1659         this.dmg_inflictor = spectatee.dmg_inflictor;
1660         this.v_angle = spectatee.v_angle;
1661         this.angles = spectatee.v_angle;
1662         STAT(FROZEN, this) = STAT(FROZEN, spectatee);
1663         STAT(REVIVE_PROGRESS, this) = STAT(REVIVE_PROGRESS, spectatee);
1664         this.viewloc = spectatee.viewloc;
1665         if(!PHYS_INPUT_BUTTON_USE(this) && STAT(CAMERA_SPECTATOR, this) != 2)
1666                 this.fixangle = true;
1667         setorigin(this, spectatee.origin);
1668         setsize(this, spectatee.mins, spectatee.maxs);
1669         SetZoomState(this, CS(spectatee).zoomstate);
1670
1671     anticheat_spectatecopy(this, spectatee);
1672         STAT(HUD, this) = STAT(HUD, spectatee);
1673         if(spectatee.vehicle)
1674     {
1675         this.angles = spectatee.v_angle;
1676
1677         //this.fixangle = false;
1678         //this.velocity = spectatee.vehicle.velocity;
1679         this.vehicle_health = spectatee.vehicle_health;
1680         this.vehicle_shield = spectatee.vehicle_shield;
1681         this.vehicle_energy = spectatee.vehicle_energy;
1682         this.vehicle_ammo1 = spectatee.vehicle_ammo1;
1683         this.vehicle_ammo2 = spectatee.vehicle_ammo2;
1684         this.vehicle_reload1 = spectatee.vehicle_reload1;
1685         this.vehicle_reload2 = spectatee.vehicle_reload2;
1686
1687         //msg_entity = this;
1688
1689        // WriteByte (MSG_ONE, SVC_SETVIEWANGLES);
1690             //WriteAngle(MSG_ONE,  spectatee.v_angle.x);
1691            // WriteAngle(MSG_ONE,  spectatee.v_angle.y);
1692            // WriteAngle(MSG_ONE,  spectatee.v_angle.z);
1693
1694         //WriteByte (MSG_ONE, SVC_SETVIEW);
1695         //    WriteEntity(MSG_ONE, this);
1696         //makevectors(spectatee.v_angle);
1697         //setorigin(this, spectatee.origin - v_forward * 400 + v_up * 300);*/
1698     }
1699 }
1700
1701 bool SpectateUpdate(entity this)
1702 {
1703         if(!this.enemy)
1704                 return false;
1705
1706         if(!IS_PLAYER(this.enemy) || this == this.enemy)
1707         {
1708                 SetSpectatee(this, NULL);
1709                 return false;
1710         }
1711
1712         SpectateCopy(this, this.enemy);
1713
1714         return true;
1715 }
1716
1717 bool SpectateSet(entity this)
1718 {
1719         if(!IS_PLAYER(this.enemy))
1720                 return false;
1721
1722         ClientData_Touch(this.enemy);
1723
1724         msg_entity = this;
1725         WriteByte(MSG_ONE, SVC_SETVIEW);
1726         WriteEntity(MSG_ONE, this.enemy);
1727         set_movetype(this, MOVETYPE_NONE);
1728         accuracy_resend(this);
1729
1730         if(!SpectateUpdate(this))
1731                 PutObserverInServer(this);
1732
1733         return true;
1734 }
1735
1736 void SetSpectatee_status(entity this, int spectatee_num)
1737 {
1738         int oldspectatee_status = CS(this).spectatee_status;
1739         CS(this).spectatee_status = spectatee_num;
1740
1741         if (CS(this).spectatee_status != oldspectatee_status)
1742         {
1743                 ClientData_Touch(this);
1744                 if (g_race || g_cts) race_InitSpectator();
1745         }
1746 }
1747
1748 void SetSpectatee(entity this, entity spectatee)
1749 {
1750         if(IS_BOT_CLIENT(this))
1751                 return; // bots abuse .enemy, this code is useless to them
1752
1753         entity old_spectatee = this.enemy;
1754
1755         this.enemy = spectatee;
1756
1757         // WEAPONTODO
1758         // these are required to fix the spectator bug with arc
1759         if(old_spectatee)
1760         {
1761                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1762                 {
1763                         .entity weaponentity = weaponentities[slot];
1764                         if(old_spectatee.(weaponentity).arc_beam)
1765                                 old_spectatee.(weaponentity).arc_beam.SendFlags |= ARC_SF_SETTINGS;
1766                 }
1767         }
1768         if(this.enemy)
1769         {
1770                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1771                 {
1772                         .entity weaponentity = weaponentities[slot];
1773                         if(this.enemy.(weaponentity).arc_beam)
1774                                 this.enemy.(weaponentity).arc_beam.SendFlags |= ARC_SF_SETTINGS;
1775                 }
1776         }
1777
1778         if (this.enemy)
1779                 SetSpectatee_status(this, etof(this.enemy));
1780
1781         // needed to update spectator list
1782         if(old_spectatee) { ClientData_Touch(old_spectatee); }
1783 }
1784
1785 bool Spectate(entity this, entity pl)
1786 {
1787         if(MUTATOR_CALLHOOK(SpectateSet, this, pl))
1788                 return false;
1789         pl = M_ARGV(1, entity);
1790
1791         SetSpectatee(this, pl);
1792         return SpectateSet(this);
1793 }
1794
1795 bool SpectateNext(entity this)
1796 {
1797         entity ent = find(this.enemy, classname, STR_PLAYER);
1798
1799         if (MUTATOR_CALLHOOK(SpectateNext, this, ent))
1800                 ent = M_ARGV(1, entity);
1801         else if (!ent)
1802                 ent = find(ent, classname, STR_PLAYER);
1803
1804         if(ent) { SetSpectatee(this, ent); }
1805
1806         return SpectateSet(this);
1807 }
1808
1809 bool SpectatePrev(entity this)
1810 {
1811         // NOTE: chain order is from the highest to the lower entnum (unlike find)
1812         entity ent = findchain(classname, STR_PLAYER);
1813         if (!ent) // no player
1814                 return false;
1815
1816         entity first = ent;
1817         // skip players until current spectated player
1818         if(this.enemy)
1819         while(ent && ent != this.enemy)
1820                 ent = ent.chain;
1821
1822         switch (MUTATOR_CALLHOOK(SpectatePrev, this, ent, first))
1823         {
1824                 case MUT_SPECPREV_FOUND:
1825                     ent = M_ARGV(1, entity);
1826                     break;
1827                 case MUT_SPECPREV_RETURN:
1828                     return true;
1829                 case MUT_SPECPREV_CONTINUE:
1830                 default:
1831                 {
1832                         if(ent.chain)
1833                                 ent = ent.chain;
1834                         else
1835                                 ent = first;
1836                         break;
1837                 }
1838         }
1839
1840         SetSpectatee(this, ent);
1841         return SpectateSet(this);
1842 }
1843
1844 /*
1845 =============
1846 ShowRespawnCountdown()
1847
1848 Update a respawn countdown display.
1849 =============
1850 */
1851 void ShowRespawnCountdown(entity this)
1852 {
1853         float number;
1854         if(!IS_DEAD(this)) // just respawned?
1855                 return;
1856         else
1857         {
1858                 number = ceil(this.respawn_time - time);
1859                 if(number <= 0)
1860                         return;
1861                 if(number <= this.respawn_countdown)
1862                 {
1863                         this.respawn_countdown = number - 1;
1864                         if(ceil(this.respawn_time - (time + 0.5)) == number) // only say it if it is the same number even in 0.5s; to prevent overlapping sounds
1865                                 { Send_Notification(NOTIF_ONE, this, MSG_ANNCE, Announcer_PickNumber(CNT_RESPAWN, number)); }
1866                 }
1867         }
1868 }
1869
1870 .bool team_selected;
1871 bool ShowTeamSelection(entity this)
1872 {
1873         if (!teamplay || autocvar_g_campaign || autocvar_g_balance_teams || this.team_selected || (CS(this).wasplayer && autocvar_g_changeteam_banned) || Player_HasRealForcedTeam(this))
1874                 return false;
1875         stuffcmd(this, "menu_showteamselect\n");
1876         return true;
1877 }
1878 void Join(entity this)
1879 {
1880         TRANSMUTE(Player, this);
1881
1882         if(!this.team_selected)
1883         if(autocvar_g_campaign || autocvar_g_balance_teams)
1884                 TeamBalance_JoinBestTeam(this);
1885
1886         if(autocvar_g_campaign)
1887                 campaign_bots_may_start = true;
1888
1889         Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_PREVENT_JOIN);
1890
1891         PutClientInServer(this);
1892
1893         if(IS_PLAYER(this))
1894         if(teamplay && this.team != -1)
1895         {
1896         }
1897         else
1898                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_JOIN_PLAY, this.netname);
1899         this.team_selected = false;
1900 }
1901
1902 /**
1903  * Determines whether the player is allowed to join. This depends on cvar
1904  * g_maxplayers, if it isn't used this function always return true, otherwise
1905  * it checks whether the number of currently playing players exceeds g_maxplayers.
1906  * @return int number of free slots for players, 0 if none
1907  */
1908 int nJoinAllowed(entity this, entity ignore)
1909 {
1910         if(!ignore)
1911         // this is called that way when checking if anyone may be able to join (to build qcstatus)
1912         // so report 0 free slots if restricted
1913         {
1914                 if(autocvar_g_forced_team_otherwise == "spectate")
1915                         return 0;
1916                 if(autocvar_g_forced_team_otherwise == "spectator")
1917                         return 0;
1918         }
1919
1920         if(this && (Player_GetForcedTeamIndex(this) == TEAM_FORCE_SPECTATOR))
1921                 return 0; // forced spectators can never join
1922
1923         // TODO simplify this
1924         int totalClients = 0;
1925         int currentlyPlaying = 0;
1926         FOREACH_CLIENT(true, {
1927                 if(it != ignore)
1928                         ++totalClients;
1929                 if(IS_REAL_CLIENT(it))
1930                 if(IS_PLAYER(it) || it.caplayer)
1931                         ++currentlyPlaying;
1932         });
1933
1934         float free_slots = 0;
1935         if (!autocvar_g_maxplayers)
1936                 free_slots = maxclients - totalClients;
1937         else if(currentlyPlaying < autocvar_g_maxplayers)
1938                 free_slots = min(maxclients - totalClients, autocvar_g_maxplayers - currentlyPlaying);
1939
1940         static float join_prevent_msg_time = 0;
1941         if(this && ignore && !free_slots && time > join_prevent_msg_time)
1942         {
1943                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_JOIN_PREVENT);
1944                 join_prevent_msg_time = time + 3;
1945         }
1946
1947         return free_slots;
1948 }
1949
1950 /**
1951  * Checks whether the client is an observer or spectator, if so, he will get kicked after
1952  * g_maxplayers_spectator_blocktime seconds
1953  */
1954 void checkSpectatorBlock(entity this)
1955 {
1956         if(IS_SPEC(this) || IS_OBSERVER(this))
1957         if(!this.caplayer)
1958         if(IS_REAL_CLIENT(this))
1959         {
1960                 if( time > (CS(this).spectatortime + autocvar_g_maxplayers_spectator_blocktime) ) {
1961                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_QUIT_KICK_SPECTATING);
1962                         dropclient(this);
1963                 }
1964         }
1965 }
1966
1967 void PrintWelcomeMessage(entity this)
1968 {
1969         if(CS(this).motd_actived_time == 0)
1970         {
1971                 if (autocvar_g_campaign) {
1972                         if ((IS_PLAYER(this) && PHYS_INPUT_BUTTON_INFO(this)) || (!IS_PLAYER(this))) {
1973                                 CS(this).motd_actived_time = time;
1974                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOTD, campaign_message);
1975                         }
1976                 } else {
1977                         if (PHYS_INPUT_BUTTON_INFO(this)) {
1978                                 CS(this).motd_actived_time = time;
1979                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOTD, getwelcomemessage(this));
1980                         }
1981                 }
1982         }
1983         else if(CS(this).motd_actived_time > 0) // showing MOTD or campaign message
1984         {
1985                 if (autocvar_g_campaign) {
1986                         if (PHYS_INPUT_BUTTON_INFO(this))
1987                                 CS(this).motd_actived_time = time;
1988                         else if ((time - CS(this).motd_actived_time > 2) && IS_PLAYER(this)) { // hide it some seconds after BUTTON_INFO has been released
1989                                 CS(this).motd_actived_time = 0;
1990                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_MOTD);
1991                         }
1992                 } else {
1993                         if (PHYS_INPUT_BUTTON_INFO(this))
1994                                 CS(this).motd_actived_time = time;
1995                         else if (time - CS(this).motd_actived_time > 2) { // hide it some seconds after BUTTON_INFO has been released
1996                                 CS(this).motd_actived_time = 0;
1997                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_MOTD);
1998                         }
1999                 }
2000         }
2001         else //if(CS(this).motd_actived_time < 0) // just connected, motd is active
2002         {
2003                 if(PHYS_INPUT_BUTTON_INFO(this)) // BUTTON_INFO hides initial MOTD
2004                         CS(this).motd_actived_time = -2; // wait until BUTTON_INFO gets released
2005                 else if(CS(this).motd_actived_time == -2 || IS_PLAYER(this) || IS_SPEC(this))
2006                 {
2007                         // instanctly hide MOTD
2008                         CS(this).motd_actived_time = 0;
2009                         Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_MOTD);
2010                 }
2011         }
2012 }
2013
2014 const int MIN_SPEC_TIME = 1;
2015 bool joinAllowed(entity this)
2016 {
2017         if (CS(this).version_mismatch) return false;
2018         if (time < CS(this).jointime + MIN_SPEC_TIME) return false;
2019         if (!nJoinAllowed(this, this)) return false;
2020         if (teamplay && lockteams) return false;
2021         if (MUTATOR_CALLHOOK(ForbidSpawn, this)) return false;
2022         if (ShowTeamSelection(this)) return false;
2023         return true;
2024 }
2025
2026 .int items_added;
2027 .string shootfromfixedorigin;
2028 bool PlayerThink(entity this)
2029 {
2030         if (game_stopped || intermission_running) {
2031                 this.modelflags &= ~MF_ROCKET;
2032                 if(intermission_running)
2033                         IntermissionThink(this);
2034                 return false;
2035         }
2036
2037         if (timeout_status == TIMEOUT_ACTIVE) {
2038         // don't allow the player to turn around while game is paused
2039                 // FIXME turn this into CSQC stuff
2040                 this.v_angle = this.lastV_angle;
2041                 this.angles = this.lastV_angle;
2042                 this.fixangle = true;
2043         }
2044
2045         if (frametime) player_powerups(this);
2046
2047         if (IS_DEAD(this)) {
2048                 if (this.personal && g_race_qualifying) {
2049                         if (time > this.respawn_time) {
2050                                 STAT(RESPAWN_TIME, this) = this.respawn_time = time + 1; // only retry once a second
2051                                 respawn(this);
2052                                 CS(this).impulse = CHIMPULSE_SPEEDRUN.impulse;
2053                         }
2054                 } else {
2055                         if (frametime) player_anim(this);
2056
2057                         if (this.respawn_flags & RESPAWN_DENY)
2058                         {
2059                                 STAT(RESPAWN_TIME, this) = 0;
2060                                 return false;
2061                         }
2062
2063                         bool button_pressed = (PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_JUMP(this) || PHYS_INPUT_BUTTON_ATCK2(this) || PHYS_INPUT_BUTTON_HOOK(this) || PHYS_INPUT_BUTTON_USE(this));
2064
2065                         switch(this.deadflag)
2066                         {
2067                                 case DEAD_DYING:
2068                                 {
2069                                         if ((this.respawn_flags & RESPAWN_FORCE) && !(this.respawn_time < this.respawn_time_max))
2070                                                 this.deadflag = DEAD_RESPAWNING;
2071                                         else if (!button_pressed || (time >= this.respawn_time_max && (this.respawn_flags & RESPAWN_FORCE)))
2072                                                 this.deadflag = DEAD_DEAD;
2073                                         break;
2074                                 }
2075                                 case DEAD_DEAD:
2076                                 {
2077                                         if (button_pressed)
2078                                                 this.deadflag = DEAD_RESPAWNABLE;
2079                                         else if (time >= this.respawn_time_max && (this.respawn_flags & RESPAWN_FORCE))
2080                                                 this.deadflag = DEAD_RESPAWNING;
2081                                         break;
2082                                 }
2083                                 case DEAD_RESPAWNABLE:
2084                                 {
2085                                         if (!button_pressed || (this.respawn_flags & RESPAWN_FORCE))
2086                                                 this.deadflag = DEAD_RESPAWNING;
2087                                         break;
2088                                 }
2089                                 case DEAD_RESPAWNING:
2090                                 {
2091                                         if (time > this.respawn_time)
2092                                         {
2093                                                 this.respawn_time = time + 1; // only retry once a second
2094                                                 this.respawn_time_max = this.respawn_time;
2095                                                 respawn(this);
2096                                         }
2097                                         break;
2098                                 }
2099                         }
2100
2101                         ShowRespawnCountdown(this);
2102
2103                         if (this.respawn_flags & RESPAWN_SILENT)
2104                                 STAT(RESPAWN_TIME, this) = 0;
2105                         else if ((this.respawn_flags & RESPAWN_FORCE) && this.respawn_time < this.respawn_time_max)
2106                         {
2107                                 if (time < this.respawn_time)
2108                                         STAT(RESPAWN_TIME, this) = this.respawn_time;
2109                                 else if (this.deadflag != DEAD_RESPAWNING)
2110                                         STAT(RESPAWN_TIME, this) = -this.respawn_time_max;
2111                         }
2112                         else
2113                                 STAT(RESPAWN_TIME, this) = this.respawn_time;
2114                 }
2115
2116                 // if respawning, invert stat_respawn_time to indicate this, the client translates it
2117                 if (this.deadflag == DEAD_RESPAWNING && STAT(RESPAWN_TIME, this) > 0)
2118                         STAT(RESPAWN_TIME, this) *= -1;
2119
2120                 return false;
2121         }
2122
2123         FixPlayermodel(this);
2124
2125         if (this.shootfromfixedorigin != autocvar_g_shootfromfixedorigin) {
2126                 this.shootfromfixedorigin = autocvar_g_shootfromfixedorigin;
2127                 stuffcmd(this, sprintf("\ncl_shootfromfixedorigin \"%s\"\n", autocvar_g_shootfromfixedorigin));
2128         }
2129
2130         // LordHavoc: allow firing on move frames (sub-ticrate), this gives better timing on slow servers
2131         //if(frametime)
2132         {
2133                 this.items &= ~this.items_added;
2134
2135                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2136                 {
2137                         .entity weaponentity = weaponentities[slot];
2138                         W_WeaponFrame(this, weaponentity);
2139                 }
2140
2141                 this.items_added = 0;
2142                 if ((this.items & ITEM_Jetpack.m_itemid) && ((this.items & ITEM_JetpackRegen.m_itemid) || GetResourceAmount(this, RESOURCE_FUEL) >= 0.01))
2143             this.items_added |= IT_FUEL;
2144
2145                 this.items |= this.items_added;
2146         }
2147
2148         player_regen(this);
2149
2150         // WEAPONTODO: Add a weapon request for this
2151         // rot vortex charge to the charge limit
2152         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2153         {
2154                 .entity weaponentity = weaponentities[slot];
2155                 if (WEP_CVAR(vortex, charge_rot_rate) && this.(weaponentity).vortex_charge > WEP_CVAR(vortex, charge_limit) && this.(weaponentity).vortex_charge_rottime < time)
2156                         this.(weaponentity).vortex_charge = bound(WEP_CVAR(vortex, charge_limit), this.(weaponentity).vortex_charge - WEP_CVAR(vortex, charge_rot_rate) * frametime / W_TICSPERFRAME, 1);
2157         }
2158
2159         if (frametime) player_anim(this);
2160
2161         // secret status
2162         secrets_setstatus(this);
2163
2164         // monsters status
2165         monsters_setstatus(this);
2166
2167         this.dmg_team = max(0, this.dmg_team - autocvar_g_teamdamage_resetspeed * frametime);
2168
2169         return true;
2170 }
2171
2172 .bool would_spectate;
2173 void ObserverThink(entity this)
2174 {
2175         if ( CS(this).impulse )
2176         {
2177                 MinigameImpulse(this, CS(this).impulse);
2178                 CS(this).impulse = 0;
2179         }
2180
2181         if (this.flags & FL_JUMPRELEASED) {
2182                 if (PHYS_INPUT_BUTTON_JUMP(this) && joinAllowed(this)) {
2183                         this.flags &= ~FL_JUMPRELEASED;
2184                         this.flags |= FL_SPAWNING;
2185                 } else if(PHYS_INPUT_BUTTON_ATCK(this) && !CS(this).version_mismatch || this.would_spectate) {
2186                         this.flags &= ~FL_JUMPRELEASED;
2187                         if(SpectateNext(this)) {
2188                                 TRANSMUTE(Spectator, this);
2189                         }
2190                 } else {
2191                         int preferred_movetype = ((!PHYS_INPUT_BUTTON_USE(this) ? CS(this).cvar_cl_clippedspectating : !CS(this).cvar_cl_clippedspectating) ? MOVETYPE_FLY_WORLDONLY : MOVETYPE_NOCLIP);
2192                         set_movetype(this, preferred_movetype);
2193                 }
2194         } else {
2195                 if (!(PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_JUMP(this))) {
2196                         this.flags |= FL_JUMPRELEASED;
2197                         if(this.flags & FL_SPAWNING)
2198                         {
2199                                 this.flags &= ~FL_SPAWNING;
2200                                 Join(this);
2201                                 return;
2202                         }
2203                 }
2204         }
2205 }
2206
2207 void SpectatorThink(entity this)
2208 {
2209         if ( CS(this).impulse )
2210         {
2211                 if(MinigameImpulse(this, CS(this).impulse))
2212                         CS(this).impulse = 0;
2213
2214                 if (CS(this).impulse == IMP_weapon_drop.impulse)
2215                 {
2216                         STAT(CAMERA_SPECTATOR, this) = (STAT(CAMERA_SPECTATOR, this) + 1) % 3;
2217                         CS(this).impulse = 0;
2218                         return;
2219                 }
2220         }
2221
2222         if (this.flags & FL_JUMPRELEASED) {
2223                 if (PHYS_INPUT_BUTTON_JUMP(this) && joinAllowed(this)) {
2224                         this.flags &= ~FL_JUMPRELEASED;
2225                         this.flags |= FL_SPAWNING;
2226                 } else if(PHYS_INPUT_BUTTON_ATCK(this) || CS(this).impulse == 10 || CS(this).impulse == 15 || CS(this).impulse == 18 || (CS(this).impulse >= 200 && CS(this).impulse <= 209)) {
2227                         this.flags &= ~FL_JUMPRELEASED;
2228                         if(SpectateNext(this)) {
2229                                 TRANSMUTE(Spectator, this);
2230                         } else {
2231                                 TRANSMUTE(Observer, this);
2232                                 PutClientInServer(this);
2233                         }
2234                         CS(this).impulse = 0;
2235                 } else if(CS(this).impulse == 12 || CS(this).impulse == 16  || CS(this).impulse == 19 || (CS(this).impulse >= 220 && CS(this).impulse <= 229)) {
2236                         this.flags &= ~FL_JUMPRELEASED;
2237                         if(SpectatePrev(this)) {
2238                                 TRANSMUTE(Spectator, this);
2239                         } else {
2240                                 TRANSMUTE(Observer, this);
2241                                 PutClientInServer(this);
2242                         }
2243                         CS(this).impulse = 0;
2244                 } else if (PHYS_INPUT_BUTTON_ATCK2(this)) {
2245                         this.would_spectate = false;
2246                         this.flags &= ~FL_JUMPRELEASED;
2247                         TRANSMUTE(Observer, this);
2248                         PutClientInServer(this);
2249                 } else {
2250                         if(!SpectateUpdate(this))
2251                         {
2252                                 if(!SpectateNext(this))
2253                                 {
2254                                         PutObserverInServer(this);
2255                                         this.would_spectate = true;
2256                                 }
2257                         }
2258                 }
2259         } else {
2260                 if (!(PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_ATCK2(this))) {
2261                         this.flags |= FL_JUMPRELEASED;
2262                         if(this.flags & FL_SPAWNING)
2263                         {
2264                                 this.flags &= ~FL_SPAWNING;
2265                                 Join(this);
2266                                 return;
2267                         }
2268                 }
2269                 if(!SpectateUpdate(this))
2270                         PutObserverInServer(this);
2271         }
2272
2273         this.flags |= FL_CLIENT | FL_NOTARGET;
2274 }
2275
2276 void PlayerUseKey(entity this)
2277 {
2278         if (!IS_PLAYER(this))
2279                 return;
2280
2281         if(this.vehicle)
2282         {
2283                 if(!game_stopped)
2284                 {
2285                         vehicles_exit(this.vehicle, VHEF_NORMAL);
2286                         return;
2287                 }
2288         }
2289         else if(autocvar_g_vehicles_enter)
2290         {
2291                 if(!STAT(FROZEN, this))
2292                 if(!IS_DEAD(this))
2293                 if(!game_stopped)
2294                 {
2295                         entity head, closest_target = NULL;
2296                         head = WarpZone_FindRadius(this.origin, autocvar_g_vehicles_enter_radius, true);
2297
2298                         while(head) // find the closest acceptable target to enter
2299                         {
2300                                 if(IS_VEHICLE(head))
2301                                 if(!IS_DEAD(head))
2302                                 if(!head.owner || ((head.vehicle_flags & VHF_MULTISLOT) && SAME_TEAM(head.owner, this)))
2303                                 if(head.takedamage != DAMAGE_NO)
2304                                 {
2305                                         if(closest_target)
2306                                         {
2307                                                 if(vlen2(this.origin - head.origin) < vlen2(this.origin - closest_target.origin))
2308                                                 { closest_target = head; }
2309                                         }
2310                                         else { closest_target = head; }
2311                                 }
2312
2313                                 head = head.chain;
2314                         }
2315
2316                         if(closest_target) { vehicles_enter(this, closest_target); return; }
2317                 }
2318         }
2319
2320         // a use key was pressed; call handlers
2321         MUTATOR_CALLHOOK(PlayerUseKey, this);
2322 }
2323
2324
2325 /*
2326 =============
2327 PlayerPreThink
2328
2329 Called every frame for each client before the physics are run
2330 =============
2331 */
2332 .float last_vehiclecheck;
2333 void PlayerPreThink (entity this)
2334 {
2335         STAT(GUNALIGN, this) = CS(this).cvar_cl_gunalign; // TODO
2336         STAT(MOVEVARS_CL_TRACK_CANJUMP, this) = CS(this).cvar_cl_movement_track_canjump;
2337
2338         WarpZone_PlayerPhysics_FixVAngle(this);
2339
2340         if (frametime) {
2341                 // physics frames: update anticheat stuff
2342                 anticheat_prethink(this);
2343         }
2344
2345         if (blockSpectators && frametime) {
2346                 // WORKAROUND: only use dropclient in server frames (frametime set).
2347                 // Never use it in cl_movement frames (frametime zero).
2348                 checkSpectatorBlock(this);
2349         }
2350
2351         zoomstate_set = false;
2352
2353         // Check for nameless players
2354         if (this.netname == "" || this.netname != CS(this).netname_previous)
2355         {
2356                 bool assume_unchanged = (CS(this).netname_previous == "");
2357                 if (isInvisibleString(this.netname))
2358                 {
2359                         this.netname = strzone(sprintf("Player#%d", this.playerid));
2360                         assume_unchanged = false;
2361                         // stuffcmd(this, strcat("name ", this.netname, "\n")); // maybe?
2362                 }
2363                 if (!assume_unchanged && autocvar_sv_eventlog)
2364                         GameLogEcho(strcat(":name:", ftos(this.playerid), ":", playername(this, false)));
2365                 strcpy(CS(this).netname_previous, this.netname);
2366         }
2367
2368         // version nagging
2369         if (CS(this).version_nagtime && CS(this).cvar_g_xonoticversion && time > CS(this).version_nagtime) {
2370         CS(this).version_nagtime = 0;
2371         if (strstrofs(CS(this).cvar_g_xonoticversion, "git", 0) >= 0 || strstrofs(CS(this).cvar_g_xonoticversion, "autobuild", 0) >= 0) {
2372             // git client
2373         } else if (strstrofs(autocvar_g_xonoticversion, "git", 0) >= 0 || strstrofs(autocvar_g_xonoticversion, "autobuild", 0) >= 0) {
2374             // git server
2375             Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_BETA, autocvar_g_xonoticversion, CS(this).cvar_g_xonoticversion);
2376         } else {
2377             int r = vercmp(CS(this).cvar_g_xonoticversion, autocvar_g_xonoticversion);
2378             if (r < 0) { // old client
2379                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_OUTDATED, autocvar_g_xonoticversion, CS(this).cvar_g_xonoticversion);
2380             } else if (r > 0) { // old server
2381                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_OLD, autocvar_g_xonoticversion, CS(this).cvar_g_xonoticversion);
2382             }
2383         }
2384     }
2385
2386         // GOD MODE info
2387         if (!(this.flags & FL_GODMODE) && this.max_armorvalue)
2388         {
2389                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_GODMODE_OFF, this.max_armorvalue);
2390                 this.max_armorvalue = 0;
2391         }
2392
2393         if(IS_PLAYER(this))
2394         {
2395                 if (STAT(FROZEN, this) == 2)
2396                 {
2397                         STAT(REVIVE_PROGRESS, this) = bound(0, STAT(REVIVE_PROGRESS, this) + frametime * this.revive_speed, 1);
2398                         SetResourceAmountExplicit(this, RESOURCE_HEALTH, max(1, STAT(REVIVE_PROGRESS, this) * start_health));
2399                         this.iceblock.alpha = bound(0.2, 1 - STAT(REVIVE_PROGRESS, this), 1);
2400
2401                         if (STAT(REVIVE_PROGRESS, this) >= 1)
2402                                 Unfreeze(this);
2403                 }
2404                 else if (STAT(FROZEN, this) == 3)
2405                 {
2406                         STAT(REVIVE_PROGRESS, this) = bound(0, STAT(REVIVE_PROGRESS, this) - frametime * this.revive_speed, 1);
2407                         SetResourceAmountExplicit(this, RESOURCE_HEALTH, max(0, autocvar_g_nades_ice_health + (start_health-autocvar_g_nades_ice_health) * STAT(REVIVE_PROGRESS, this)));
2408
2409                         if (GetResourceAmount(this, RESOURCE_HEALTH) < 1)
2410                         {
2411                                 if (this.vehicle)
2412                                         vehicles_exit(this.vehicle, VHEF_RELEASE);
2413                                 if(this.event_damage)
2414                                         this.event_damage(this, this, this.frozen_by, 1, DEATH_NADE_ICE_FREEZE.m_id, DMG_NOWEP, this.origin, '0 0 0');
2415                         }
2416                         else if (STAT(REVIVE_PROGRESS, this) <= 0)
2417                                 Unfreeze(this);
2418                 }
2419         }
2420
2421         MUTATOR_CALLHOOK(PlayerPreThink, this);
2422
2423         if(autocvar_g_vehicles_enter && (time > this.last_vehiclecheck) && !game_stopped && !this.vehicle)
2424         if(IS_PLAYER(this) && !STAT(FROZEN, this) && !IS_DEAD(this))
2425         {
2426                 FOREACH_ENTITY_RADIUS(this.origin, autocvar_g_vehicles_enter_radius, IS_VEHICLE(it),
2427                 {
2428                         if(!IS_DEAD(it) && it.takedamage != DAMAGE_NO)
2429                         if((it.vehicle_flags & VHF_MULTISLOT) && SAME_TEAM(it.owner, this))
2430                         {
2431                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER_GUNNER);
2432                         }
2433                         else if(!it.owner)
2434                         {
2435                                 if(!it.team || SAME_TEAM(this, it))
2436                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER);
2437                                 else if(autocvar_g_vehicles_steal)
2438                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER_STEAL);
2439                         }
2440                 });
2441
2442                 this.last_vehiclecheck = time + 1;
2443         }
2444
2445         if(!CS(this).cvar_cl_newusekeysupported) // FIXME remove this - it was a stupid idea to begin with, we can JUST use the button
2446         {
2447                 if(PHYS_INPUT_BUTTON_USE(this) && !CS(this).usekeypressed)
2448                         PlayerUseKey(this);
2449                 CS(this).usekeypressed = PHYS_INPUT_BUTTON_USE(this);
2450         }
2451
2452         if (IS_REAL_CLIENT(this))
2453                 PrintWelcomeMessage(this);
2454
2455         if (IS_PLAYER(this)) {
2456                 if (IS_REAL_CLIENT(this) && time < CS(this).jointime + MIN_SPEC_TIME)
2457                         error("Client can't be spawned as player on connection!");
2458                 if(!PlayerThink(this))
2459                         return;
2460         }
2461         else if (game_stopped || intermission_running) {
2462                 if(intermission_running)
2463                         IntermissionThink(this);
2464                 return;
2465         }
2466         else if (IS_REAL_CLIENT(this) && !CS(this).autojoin_checked && time >= CS(this).jointime + MIN_SPEC_TIME)
2467         {
2468                 CS(this).autojoin_checked = true;
2469                 // don't do this in ClientConnect
2470                 // many things can go wrong if a client is spawned as player on connection
2471                 if (MUTATOR_CALLHOOK(AutoJoinOnConnection, this)
2472                         || (!(autocvar_sv_spectate || autocvar_g_campaign || (Player_GetForcedTeamIndex(this) == TEAM_FORCE_SPECTATOR))
2473                                 && (!teamplay || autocvar_g_balance_teams)))
2474                 {
2475                         campaign_bots_may_start = true;
2476                         Join(this);
2477                         return;
2478                 }
2479         }
2480         else if (IS_OBSERVER(this)) {
2481                 ObserverThink(this);
2482         }
2483         else if (IS_SPEC(this)) {
2484                 SpectatorThink(this);
2485         }
2486
2487         // WEAPONTODO: Add weapon request for this
2488         if (!zoomstate_set) {
2489                 bool wep_zoomed = false;
2490                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2491                 {
2492                         .entity weaponentity = weaponentities[slot];
2493                         Weapon thiswep = this.(weaponentity).m_weapon;
2494                         if(thiswep != WEP_Null && thiswep.wr_zoom)
2495                                 wep_zoomed += thiswep.wr_zoom(thiswep, this);
2496                 }
2497                 SetZoomState(this, PHYS_INPUT_BUTTON_ZOOM(this) || PHYS_INPUT_BUTTON_ZOOMSCRIPT(this) || wep_zoomed);
2498     }
2499
2500         if (CS(this).teamkill_soundtime && time > CS(this).teamkill_soundtime)
2501         {
2502                 CS(this).teamkill_soundtime = 0;
2503
2504                 entity e = CS(this).teamkill_soundsource;
2505                 entity oldpusher = e.pusher;
2506                 e.pusher = this;
2507                 PlayerSound(e, playersound_teamshoot, CH_VOICE, VOL_BASEVOICE, VOICETYPE_LASTATTACKER_ONLY);
2508                 e.pusher = oldpusher;
2509         }
2510
2511         if (CS(this).taunt_soundtime && time > CS(this).taunt_soundtime) {
2512                 CS(this).taunt_soundtime = 0;
2513                 PlayerSound(this, playersound_taunt, CH_VOICE, VOL_BASEVOICE, VOICETYPE_AUTOTAUNT);
2514         }
2515
2516         target_voicescript_next(this);
2517
2518         // WEAPONTODO: Move into weaponsystem somehow
2519         // if a player goes unarmed after holding a loaded weapon, empty his clip size and remove the crosshair ammo ring
2520         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2521         {
2522                 .entity weaponentity = weaponentities[slot];
2523                 if(this.(weaponentity).m_weapon == WEP_Null)
2524                         this.(weaponentity).clip_load = this.(weaponentity).clip_size = 0;
2525         }
2526 }
2527
2528 void DrownPlayer(entity this)
2529 {
2530         if(IS_DEAD(this) || game_stopped || time < game_starttime)
2531                 return;
2532
2533         if (this.waterlevel != WATERLEVEL_SUBMERGED || this.vehicle)
2534         {
2535                 if(this.air_finished < time)
2536                         PlayerSound(this, playersound_gasp, CH_PLAYER, VOL_BASE, VOICETYPE_PLAYERSOUND);
2537                 this.air_finished = time + autocvar_g_balance_contents_drowndelay;
2538         }
2539         else if (this.air_finished < time)
2540         {       // drown!
2541                 if (this.pain_finished < time)
2542                 {
2543                         Damage (this, NULL, NULL, autocvar_g_balance_contents_playerdamage_drowning * autocvar_g_balance_contents_damagerate, DEATH_DROWN.m_id, DMG_NOWEP, this.origin, '0 0 0');
2544                         this.pain_finished = time + 0.5;
2545                 }
2546         }
2547 }
2548
2549 .bool move_qcphysics;
2550
2551 void Player_Physics(entity this)
2552 {
2553         set_movetype(this, this.move_movetype);
2554
2555         if(!this.move_qcphysics)
2556                 return;
2557
2558         if(!frametime && !CS(this).pm_frametime)
2559                 return;
2560
2561         Movetype_Physics_NoMatchTicrate(this, CS(this).pm_frametime, true);
2562
2563         CS(this).pm_frametime = 0;
2564 }
2565
2566 /*
2567 =============
2568 PlayerPostThink
2569
2570 Called every frame for each client after the physics are run
2571 =============
2572 */
2573 void PlayerPostThink (entity this)
2574 {
2575         Player_Physics(this);
2576
2577         if (sv_maxidle > 0)
2578         if (frametime) // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2579         if (IS_REAL_CLIENT(this))
2580         if (IS_PLAYER(this) || sv_maxidle_spectatorsareidle)
2581         {
2582                 int totalClients = 0;
2583                 if(sv_maxidle_slots > 0)
2584                 {
2585                         FOREACH_CLIENT(IS_REAL_CLIENT(it) || sv_maxidle_slots_countbots,
2586                         {
2587                                 ++totalClients;
2588                         });
2589                 }
2590
2591                 if (sv_maxidle_slots > 0 && (maxclients - totalClients) > sv_maxidle_slots)
2592                 { /* do nothing */ }
2593                 else if (time - CS(this).parm_idlesince < 1) // instead of (time == this.parm_idlesince) to support sv_maxidle <= 10
2594                 {
2595                         if (CS(this).idlekick_lasttimeleft)
2596                         {
2597                                 CS(this).idlekick_lasttimeleft = 0;
2598                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_IDLING);
2599                         }
2600                 }
2601                 else
2602                 {
2603                         float timeleft = ceil(sv_maxidle - (time - CS(this).parm_idlesince));
2604                         if (timeleft == min(10, sv_maxidle - 1)) { // - 1 to support sv_maxidle <= 10
2605                                 if (!CS(this).idlekick_lasttimeleft)
2606                                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_DISCONNECT_IDLING, timeleft);
2607                         }
2608                         if (timeleft <= 0) {
2609                                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_QUIT_KICK_IDLING, this.netname);
2610                                 dropclient(this);
2611                                 return;
2612                         }
2613                         else if (timeleft <= 10) {
2614                                 if (timeleft != CS(this).idlekick_lasttimeleft) {
2615                                     Send_Notification(NOTIF_ONE, this, MSG_ANNCE, Announcer_PickNumber(CNT_IDLE, timeleft));
2616                 }
2617                                 CS(this).idlekick_lasttimeleft = timeleft;
2618                         }
2619                 }
2620         }
2621
2622         CheatFrame(this);
2623
2624         if (game_stopped)
2625         {
2626                 this.solid = SOLID_NOT;
2627                 this.takedamage = DAMAGE_NO;
2628                 set_movetype(this, MOVETYPE_NONE);
2629         }
2630
2631         if (IS_PLAYER(this)) {
2632                 if(this.death_time == time && IS_DEAD(this))
2633                 {
2634                         // player's bbox gets resized now, instead of in the damage event that killed the player,
2635                         // once all the damage events of this frame have been processed with normal size
2636                         this.maxs.z = 5;
2637                         setsize(this, this.mins, this.maxs);
2638                 }
2639                 DrownPlayer(this);
2640                 UpdateChatBubble(this);
2641                 if (CS(this).impulse) ImpulseCommands(this);
2642                 if (game_stopped)
2643                 {
2644                         CSQCMODEL_AUTOUPDATE(this);
2645                         return;
2646                 }
2647                 GetPressedKeys(this);
2648         }
2649
2650         if (this.waypointsprite_attachedforcarrier) {
2651             vector v = healtharmor_maxdamage(GetResourceAmount(this, RESOURCE_HEALTH), GetResourceAmount(this, RESOURCE_ARMOR), autocvar_g_balance_armor_blockpercent, DEATH_WEAPON.m_id);
2652                 WaypointSprite_UpdateHealth(this.waypointsprite_attachedforcarrier, '1 0 0' * v);
2653     }
2654
2655         CSQCMODEL_AUTOUPDATE(this);
2656 }
2657
2658 // hack to copy the button fields from the client entity to the Client State
2659 void PM_UpdateButtons(entity this, entity store)
2660 {
2661         if(this.impulse)
2662                 store.impulse = this.impulse;
2663         this.impulse = 0;
2664
2665         bool typing = this.buttonchat;
2666
2667         store.button0 = (typing) ? 0 : this.button0;
2668         //button1?!
2669         store.button2 = (typing) ? 0 : this.button2;
2670         store.button3 = (typing) ? 0 : this.button3;
2671         store.button4 = this.button4;
2672         store.button5 = (typing) ? 0 : this.button5;
2673         store.button6 = this.button6;
2674         store.button7 = this.button7;
2675         store.button8 = this.button8;
2676         store.button9 = this.button9;
2677         store.button10 = this.button10;
2678         store.button11 = this.button11;
2679         store.button12 = this.button12;
2680         store.button13 = this.button13;
2681         store.button14 = this.button14;
2682         store.button15 = this.button15;
2683         store.button16 = this.button16;
2684         store.buttonuse = this.buttonuse;
2685         store.buttonchat = this.buttonchat;
2686
2687         store.cursor_active = this.cursor_active;
2688         store.cursor_screen = this.cursor_screen;
2689         store.cursor_trace_start = this.cursor_trace_start;
2690         store.cursor_trace_endpos = this.cursor_trace_endpos;
2691         store.cursor_trace_ent = this.cursor_trace_ent;
2692
2693         store.ping = this.ping;
2694         store.ping_packetloss = this.ping_packetloss;
2695         store.ping_movementloss = this.ping_movementloss;
2696
2697         store.v_angle = this.v_angle;
2698         store.movement = (typing) ? '0 0 0' : this.movement;
2699 }
2700
2701 NET_HANDLE(fpsreport, bool)
2702 {
2703         int fps = ReadShort();
2704         PlayerScore_Set(sender, SP_FPS, fps);
2705         return true;
2706 }