qcsrc/server/client.qc

   1 #include "client.qh"
   2
   3 #include "anticheat.qh"
   4 #include "impulse.qh"
   5 #include "player.qh"
   6 #include "ipban.qh"
   7 #include "miscfunctions.qh"
   8 #include "portals.qh"
   9 #include "teamplay.qh"
  10 #include "playerdemo.qh"
  11 #include "spawnpoints.qh"
  12 #include "g_damage.qh"
  13 #include "g_hook.qh"
  14 #include "command/common.qh"
  15 #include "cheats.qh"
  16 #include "g_world.qh"
  17 #include "race.qh"
  18 #include "antilag.qh"
  19 #include "campaign.qh"
  20 #include "command/common.qh"
  21 #include "scores_rules.qh"
  22
  23 #include "bot/api.qh"
  24
  25 #include "../common/ent_cs.qh"
  26 #include "../common/wepent.qh"
  27 #include <common/state.qh>
  28
  29 #include <common/effects/qc/globalsound.qh>
  30
  31 #include "../common/triggers/func/conveyor.qh"
  32 #include "../common/triggers/teleporters.qh"
  33
  34 #include "../common/vehicles/all.qh"
  35
  36 #include "weapons/hitplot.qh"
  37 #include "weapons/weaponsystem.qh"
  38
  39 #include "../common/net_notice.qh"
  40 #include "../common/net_linked.qh"
  41 #include "../common/physics/player.qh"
  42
  43 #include "../common/items/_mod.qh"
  44
  45 #include "../common/mutators/mutator/waypoints/all.qh"
  46
  47 #include "../common/triggers/subs.qh"
  48 #include "../common/triggers/triggers.qh"
  49 #include "../common/triggers/trigger/secret.qh"
  50
  51 #include "../common/minigames/sv_minigames.qh"
  52
  53 #include "../common/items/inventory.qh"
  54
  55 #include "../common/monsters/sv_monsters.qh"
  56
  57 #include "../lib/warpzone/server.qh"
  58
  59 STATIC_METHOD(Client, Add, void(Client this, int _team))
  60 {
  61     ClientConnect(this);
  62     TRANSMUTE(Player, this);
  63     this.frame = 12; // 7
  64     this.team = _team;
  65     PutClientInServer(this);
  66 }
  67
  68 void PutObserverInServer(entity this);
  69
  70 STATIC_METHOD(Client, Remove, void(Client this))
  71 {
  72     TRANSMUTE(Observer, this);
  73     PutClientInServer(this);
  74     ClientDisconnect(this);
  75 }
  76
  77 void send_CSQC_teamnagger() {
  78         WriteHeader(MSG_BROADCAST, TE_CSQC_TEAMNAGGER);
  79 }
  80
  81 int CountSpectators(entity player, entity to)
  82 {
  83         if(!player) { return 0; } // not sure how, but best to be safe
  84
  85         int spec_count = 0;
  86
  87         FOREACH_CLIENT(IS_REAL_CLIENT(it) && IS_SPEC(it) && it != to && it.enemy == player,
  88         {
  89                 spec_count++;
  90         });
  91
  92         return spec_count;
  93 }
  94
  95 void WriteSpectators(entity player, entity to)
  96 {
  97         if(!player) { return; } // not sure how, but best to be safe
  98
  99         FOREACH_CLIENT(IS_REAL_CLIENT(it) && IS_SPEC(it) && it != to && it.enemy == player,
 100         {
 101                 WriteByte(MSG_ENTITY, num_for_edict(it));
 102         });
 103 }
 104
 105 bool ClientData_Send(entity this, entity to, int sf)
 106 {
 107         assert(to == this.owner, return false);
 108
 109         entity e = to;
 110         if (IS_SPEC(e)) e = e.enemy;
 111
 112         sf = 0;
 113         if (e.race_completed)       sf |= 1; // forced scoreboard
 114         if (to.spectatee_status)    sf |= 2; // spectator ent number follows
 115         if (e.zoomstate)            sf |= 4; // zoomed
 116         if (autocvar_sv_showspectators) sf |= 16; // show spectators
 117
 118         WriteHeader(MSG_ENTITY, ENT_CLIENT_CLIENTDATA);
 119         WriteByte(MSG_ENTITY, sf);
 120
 121         if (sf & 2)
 122         {
 123                 WriteByte(MSG_ENTITY, to.spectatee_status);
 124         }
 125
 126         if(sf & 16)
 127         {
 128                 float specs = CountSpectators(e, to);
 129                 WriteByte(MSG_ENTITY, specs);
 130                 WriteSpectators(e, to);
 131         }
 132
 133         return true;
 134 }
 135
 136 void ClientData_Attach(entity this)
 137 {
 138         Net_LinkEntity(this.clientdata = new_pure(clientdata), false, 0, ClientData_Send);
 139         this.clientdata.drawonlytoclient = this;
 140         this.clientdata.owner = this;
 141 }
 142
 143 void ClientData_Detach(entity this)
 144 {
 145         delete(this.clientdata);
 146         this.clientdata = NULL;
 147 }
 148
 149 void ClientData_Touch(entity e)
 150 {
 151         e.clientdata.SendFlags = 1;
 152
 153         // make it spectatable
 154         FOREACH_CLIENT(IS_REAL_CLIENT(it) && it != e && IS_SPEC(it) && it.enemy == e, LAMBDA(it.clientdata.SendFlags = 1));
 155 }
 156
 157 .string netname_previous;
 158
 159 void SetSpectatee(entity this, entity spectatee);
 160 void SetSpectatee_status(entity this, int spectatee_num);
 161
 162
 163 /*
 164 =============
 165 CheckPlayerModel
 166
 167 Checks if the argument string can be a valid playermodel.
 168 Returns a valid one in doubt.
 169 =============
 170 */
 171 string FallbackPlayerModel;
 172 string CheckPlayerModel(string plyermodel) {
 173         if(FallbackPlayerModel != cvar_defstring("_cl_playermodel"))
 174         {
 175                 // note: we cannot summon Don Strunzone here, some player may
 176                 // still have the model string set. In case anyone manages how
 177                 // to change a cvar default, we'll have a small leak here.
 178                 FallbackPlayerModel = strzone(cvar_defstring("_cl_playermodel"));
 179         }
 180         // only in right path
 181         if( substring(plyermodel,0,14) != "models/player/")
 182                 return FallbackPlayerModel;
 183         // only good file extensions
 184         if(substring(plyermodel,-4,4) != ".zym")
 185         if(substring(plyermodel,-4,4) != ".dpm")
 186         if(substring(plyermodel,-4,4) != ".iqm")
 187         if(substring(plyermodel,-4,4) != ".md3")
 188         if(substring(plyermodel,-4,4) != ".psk")
 189                 return FallbackPlayerModel;
 190         // forbid the LOD models
 191         if(substring(plyermodel, -9,5) == "_lod1")
 192                 return FallbackPlayerModel;
 193         if(substring(plyermodel, -9,5) == "_lod2")
 194                 return FallbackPlayerModel;
 195         if(plyermodel != strtolower(plyermodel))
 196                 return FallbackPlayerModel;
 197         // also, restrict to server models
 198         if(autocvar_sv_servermodelsonly)
 199         {
 200                 if(!fexists(plyermodel))
 201                         return FallbackPlayerModel;
 202         }
 203         return plyermodel;
 204 }
 205
 206 void setplayermodel(entity e, string modelname)
 207 {
 208         precache_model(modelname);
 209         _setmodel(e, modelname);
 210         player_setupanimsformodel(e);
 211         if(!autocvar_g_debug_globalsounds)
 212                 UpdatePlayerSounds(e);
 213 }
 214
 215 void FixPlayermodel(entity player);
 216 /** putting a client as observer in the server */
 217 void PutObserverInServer(entity this)
 218 {
 219     bool mutator_returnvalue = MUTATOR_CALLHOOK(MakePlayerObserver, this);
 220         PlayerState_detach(this);
 221
 222         if (IS_PLAYER(this) && this.health >= 1) {
 223         // despawn effect
 224                 Send_Effect(EFFECT_SPAWN_NEUTRAL, this.origin, '0 0 0', 1);
 225     }
 226
 227     {
 228         entity spot = SelectSpawnPoint(this, true);
 229         if (!spot) LOG_FATAL("No spawnpoints for observers?!?");
 230         this.angles = spot.angles;
 231         this.angles_z = 0;
 232         this.fixangle = true;
 233         // offset it so that the spectator spawns higher off the ground, looks better this way
 234         setorigin(this, spot.origin + STAT(PL_VIEW_OFS, this));
 235         this.prevorigin = this.origin;
 236         if (IS_REAL_CLIENT(this))
 237         {
 238             msg_entity = this;
 239             WriteByte(MSG_ONE, SVC_SETVIEW);
 240             WriteEntity(MSG_ONE, this);
 241         }
 242         // give the spectator some space between walls for MOVETYPE_FLY_WORLDONLY
 243         // so that your view doesn't go into the ceiling with MOVETYPE_FLY_WORLDONLY, previously "PL_VIEW_OFS"
 244         if(!autocvar_g_debug_globalsounds)
 245         {
 246                 // needed for player sounds
 247                 this.model = "";
 248                 FixPlayermodel(this);
 249         }
 250         setmodel(this, MDL_Null);
 251         setsize(this, STAT(PL_CROUCH_MIN, this), STAT(PL_CROUCH_MAX, this));
 252         this.view_ofs = '0 0 0';
 253     }
 254
 255     RemoveGrapplingHooks(this);
 256         Portal_ClearAll(this);
 257         Unfreeze(this);
 258         SetSpectatee(this, NULL);
 259
 260         if (this.alivetime)
 261         {
 262                 if (!warmup_stage)
 263                         PS_GR_P_ADDVAL(this, PLAYERSTATS_ALIVETIME, time - this.alivetime);
 264                 this.alivetime = 0;
 265         }
 266
 267         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
 268
 269         WaypointSprite_PlayerDead(this);
 270
 271         if (mutator_returnvalue) {
 272             // mutator prevents resetting teams+score
 273         } else {
 274                 this.team = -1;  // move this as it is needed to log the player spectating in eventlog
 275         this.frags = FRAGS_SPECTATOR;
 276         PlayerScore_Clear(this);  // clear scores when needed
 277     }
 278
 279         if (this.killcount != FRAGS_SPECTATOR)
 280         {
 281                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_QUIT_SPECTATE, this.netname);
 282                 if(!game_stopped)
 283                 if(autocvar_g_chat_nospectators == 1 || (!warmup_stage && autocvar_g_chat_nospectators == 2))
 284                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_CHAT_NOSPECTATORS);
 285
 286                 if(this.just_joined == false) {
 287                         LogTeamchange(this.playerid, -1, 4);
 288                 } else
 289                         this.just_joined = false;
 290         }
 291
 292         accuracy_resend(this);
 293
 294         this.spectatortime = time;
 295         if(this.bot_attack)
 296                 IL_REMOVE(g_bot_targets, this);
 297         this.bot_attack = false;
 298     this.hud = HUD_NORMAL;
 299         TRANSMUTE(Observer, this);
 300         this.iscreature = false;
 301         this.teleportable = TELEPORT_SIMPLE;
 302         if(this.damagedbycontents)
 303                 IL_REMOVE(g_damagedbycontents, this);
 304         this.damagedbycontents = false;
 305         this.health = FRAGS_SPECTATOR;
 306         SetSpectatee_status(this, etof(this));
 307         this.takedamage = DAMAGE_NO;
 308         this.solid = SOLID_NOT;
 309         set_movetype(this, MOVETYPE_FLY_WORLDONLY); // user preference is controlled by playerprethink
 310         this.flags = FL_CLIENT | FL_NOTARGET;
 311         this.armorvalue = 666;
 312         this.effects = 0;
 313         this.armorvalue = autocvar_g_balance_armor_start;
 314         this.pauserotarmor_finished = 0;
 315         this.pauserothealth_finished = 0;
 316         this.pauseregen_finished = 0;
 317         this.damageforcescale = 0;
 318         this.death_time = 0;
 319         this.respawn_flags = 0;
 320         this.respawn_time = 0;
 321         this.stat_respawn_time = 0;
 322         this.alpha = 0;
 323         this.scale = 0;
 324         this.fade_time = 0;
 325         this.pain_frame = 0;
 326         this.pain_finished = 0;
 327         this.strength_finished = 0;
 328         this.invincible_finished = 0;
 329         this.superweapons_finished = 0;
 330         this.pushltime = 0;
 331         this.istypefrag = 0;
 332         setthink(this, func_null);
 333         this.nextthink = 0;
 334         this.deadflag = DEAD_NO;
 335         this.crouch = false;
 336         this.revive_progress = 0;
 337         this.revival_time = 0;
 338
 339         this.items = 0;
 340         this.weapons = '0 0 0';
 341         this.dual_weapons = '0 0 0';
 342         this.drawonlytoclient = this;
 343
 344         this.weaponmodel = "";
 345         for (int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 346         {
 347                 this.weaponentities[slot] = NULL;
 348         }
 349         this.exteriorweaponentity = NULL;
 350         this.killcount = FRAGS_SPECTATOR;
 351         this.velocity = '0 0 0';
 352         this.avelocity = '0 0 0';
 353         this.punchangle = '0 0 0';
 354         this.punchvector = '0 0 0';
 355         this.oldvelocity = this.velocity;
 356         this.fire_endtime = -1;
 357         this.event_damage = func_null;
 358
 359         for(int slot = 0; slot < MAX_AXH; ++slot)
 360         {
 361                 entity axh = this.(AuxiliaryXhair[slot]);
 362                 this.(AuxiliaryXhair[slot]) = NULL;
 363
 364                 if(axh.owner == this && axh != NULL && !wasfreed(axh))
 365                         delete(axh);
 366         }
 367 }
 368
 369 int player_getspecies(entity this)
 370 {
 371         get_model_parameters(this.model, this.skin);
 372         int s = get_model_parameters_species;
 373         get_model_parameters(string_null, 0);
 374         if (s < 0) return SPECIES_HUMAN;
 375         return s;
 376 }
 377
 378 .float model_randomizer;
 379 void FixPlayermodel(entity player)
 380 {
 381         string defaultmodel = "";
 382         int defaultskin = 0;
 383         if(autocvar_sv_defaultcharacter)
 384         {
 385                 if(teamplay)
 386                 {
 387                         switch(player.team)
 388                         {
 389                                 case NUM_TEAM_1: defaultmodel = autocvar_sv_defaultplayermodel_red; defaultskin = autocvar_sv_defaultplayerskin_red; break;
 390                                 case NUM_TEAM_2: defaultmodel = autocvar_sv_defaultplayermodel_blue; defaultskin = autocvar_sv_defaultplayerskin_blue; break;
 391                                 case NUM_TEAM_3: defaultmodel = autocvar_sv_defaultplayermodel_yellow; defaultskin = autocvar_sv_defaultplayerskin_yellow; break;
 392                                 case NUM_TEAM_4: defaultmodel = autocvar_sv_defaultplayermodel_pink; defaultskin = autocvar_sv_defaultplayerskin_pink; break;
 393                         }
 394                 }
 395
 396                 if(defaultmodel == "")
 397                 {
 398                         defaultmodel = autocvar_sv_defaultplayermodel;
 399                         defaultskin = autocvar_sv_defaultplayerskin;
 400                 }
 401
 402                 int n = tokenize_console(defaultmodel);
 403                 if(n > 0)
 404                 {
 405                         defaultmodel = argv(floor(n * player.model_randomizer));
 406                         // However, do NOT randomize if the player-selected model is in the list.
 407                         for (int i = 0; i < n; ++i)
 408                                 if ((argv(i) == player.playermodel && defaultskin == stof(player.playerskin)) || argv(i) == strcat(player.playermodel, ":", player.playerskin))
 409                                         defaultmodel = argv(i);
 410                 }
 411
 412                 int i = strstrofs(defaultmodel, ":", 0);
 413                 if(i >= 0)
 414                 {
 415                         defaultskin = stof(substring(defaultmodel, i+1, -1));
 416                         defaultmodel = substring(defaultmodel, 0, i);
 417                 }
 418         }
 419         if(autocvar_sv_defaultcharacterskin && !defaultskin)
 420         {
 421                 if(teamplay)
 422                 {
 423                         switch(player.team)
 424                         {
 425                                 case NUM_TEAM_1: defaultskin = autocvar_sv_defaultplayerskin_red; break;
 426                                 case NUM_TEAM_2: defaultskin = autocvar_sv_defaultplayerskin_blue; break;
 427                                 case NUM_TEAM_3: defaultskin = autocvar_sv_defaultplayerskin_yellow; break;
 428                                 case NUM_TEAM_4: defaultskin = autocvar_sv_defaultplayerskin_pink; break;
 429                         }
 430                 }
 431
 432                 if(!defaultskin)
 433                         defaultskin = autocvar_sv_defaultplayerskin;
 434         }
 435
 436         MUTATOR_CALLHOOK(FixPlayermodel, defaultmodel, defaultskin, player);
 437         defaultmodel = M_ARGV(0, string);
 438         defaultskin = M_ARGV(1, int);
 439
 440         bool chmdl = false;
 441         int oldskin;
 442         if(defaultmodel != "")
 443         {
 444                 if (defaultmodel != player.model)
 445                 {
 446                         vector m1 = player.mins;
 447                         vector m2 = player.maxs;
 448                         setplayermodel (player, defaultmodel);
 449                         setsize (player, m1, m2);
 450                         chmdl = true;
 451                 }
 452
 453                 oldskin = player.skin;
 454                 player.skin = defaultskin;
 455         } else {
 456                 if (player.playermodel != player.model || player.playermodel == "")
 457                 {
 458                         player.playermodel = CheckPlayerModel(player.playermodel); // this is never "", so no endless loop
 459                         vector m1 = player.mins;
 460                         vector m2 = player.maxs;
 461                         setplayermodel (player, player.playermodel);
 462                         setsize (player, m1, m2);
 463                         chmdl = true;
 464                 }
 465
 466                 if(!autocvar_sv_defaultcharacterskin)
 467                 {
 468                         oldskin = player.skin;
 469                         player.skin = stof(player.playerskin);
 470                 }
 471                 else
 472                 {
 473                         oldskin = player.skin;
 474                         player.skin = defaultskin;
 475                 }
 476         }
 477
 478         if(chmdl || oldskin != player.skin) // model or skin has changed
 479         {
 480                 player.species = player_getspecies(player); // update species
 481                 if(!autocvar_g_debug_globalsounds)
 482                         UpdatePlayerSounds(player); // update skin sounds
 483         }
 484
 485         if(!teamplay)
 486                 if(strlen(autocvar_sv_defaultplayercolors))
 487                         if(player.clientcolors != stof(autocvar_sv_defaultplayercolors))
 488                                 setcolor(player, stof(autocvar_sv_defaultplayercolors));
 489 }
 490
 491
 492 /** Called when a client spawns in the server */
 493 void PutClientInServer(entity this)
 494 {
 495         if (IS_BOT_CLIENT(this)) {
 496                 TRANSMUTE(Player, this);
 497         } else if (IS_REAL_CLIENT(this)) {
 498                 msg_entity = this;
 499                 WriteByte(MSG_ONE, SVC_SETVIEW);
 500                 WriteEntity(MSG_ONE, this);
 501         }
 502         if (game_stopped)
 503                 TRANSMUTE(Observer, this);
 504
 505         SetSpectatee(this, NULL);
 506
 507         // reset player keys
 508         this.itemkeys = 0;
 509
 510         MUTATOR_CALLHOOK(PutClientInServer, this);
 511
 512         if (IS_OBSERVER(this)) {
 513                 PutObserverInServer(this);
 514         } else if (IS_PLAYER(this)) {
 515                 if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
 516
 517                 PlayerState_attach(this);
 518                 accuracy_resend(this);
 519
 520                 if (this.team < 0)
 521                         JoinBestTeam(this, false, true);
 522
 523                 entity spot = SelectSpawnPoint(this, false);
 524                 if (!spot) {
 525                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_JOIN_NOSPAWNS);
 526                         return; // spawn failed
 527                 }
 528
 529                 TRANSMUTE(Player, this);
 530
 531                 this.wasplayer = true;
 532                 this.iscreature = true;
 533                 this.teleportable = TELEPORT_NORMAL;
 534                 if(!this.damagedbycontents)
 535                         IL_PUSH(g_damagedbycontents, this);
 536                 this.damagedbycontents = true;
 537                 set_movetype(this, MOVETYPE_WALK);
 538                 this.solid = SOLID_SLIDEBOX;
 539                 this.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_SOLID;
 540                 if (autocvar_g_playerclip_collisions)
 541                         this.dphitcontentsmask |= DPCONTENTS_PLAYERCLIP;
 542                 if (IS_BOT_CLIENT(this) && autocvar_g_botclip_collisions)
 543                         this.dphitcontentsmask |= DPCONTENTS_BOTCLIP;
 544                 this.frags = FRAGS_PLAYER;
 545                 if (INDEPENDENT_PLAYERS) MAKE_INDEPENDENT_PLAYER(this);
 546                 this.flags = FL_CLIENT | FL_PICKUPITEMS;
 547                 if (autocvar__notarget)
 548                         this.flags |= FL_NOTARGET;
 549                 this.takedamage = DAMAGE_AIM;
 550                 this.effects = EF_TELEPORT_BIT | EF_RESTARTANIM_BIT;
 551                 this.dmg = 2; // WTF
 552
 553                 if (warmup_stage) {
 554                         this.ammo_shells = warmup_start_ammo_shells;
 555                         this.ammo_nails = warmup_start_ammo_nails;
 556                         this.ammo_rockets = warmup_start_ammo_rockets;
 557                         this.ammo_cells = warmup_start_ammo_cells;
 558                         this.ammo_plasma = warmup_start_ammo_plasma;
 559                         this.ammo_fuel = warmup_start_ammo_fuel;
 560                         this.health = warmup_start_health;
 561                         this.armorvalue = warmup_start_armorvalue;
 562                         this.weapons = WARMUP_START_WEAPONS;
 563                 } else {
 564                         this.ammo_shells = start_ammo_shells;
 565                         this.ammo_nails = start_ammo_nails;
 566                         this.ammo_rockets = start_ammo_rockets;
 567                         this.ammo_cells = start_ammo_cells;
 568                         this.ammo_plasma = start_ammo_plasma;
 569                         this.ammo_fuel = start_ammo_fuel;
 570                         this.health = start_health;
 571                         this.armorvalue = start_armorvalue;
 572                         this.weapons = start_weapons;
 573                 }
 574                 SetSpectatee_status(this, 0);
 575
 576                 this.superweapons_finished = (this.weapons & WEPSET_SUPERWEAPONS) ? time + autocvar_g_balance_superweapons_time : 0;
 577
 578                 this.items = start_items;
 579
 580                 this.spawnshieldtime = time + autocvar_g_spawnshieldtime;
 581                 this.pauserotarmor_finished = time + autocvar_g_balance_pause_armor_rot_spawn;
 582                 this.pauserothealth_finished = time + autocvar_g_balance_pause_health_rot_spawn;
 583                 this.pauserotfuel_finished = time + autocvar_g_balance_pause_fuel_rot_spawn;
 584                 this.pauseregen_finished = time + autocvar_g_balance_pause_health_regen_spawn;
 585                 // extend the pause of rotting if client was reset at the beginning of the countdown
 586                 if (!autocvar_sv_ready_restart_after_countdown && time < game_starttime) { // TODO why is this cvar NOTted?
 587                         float f = game_starttime - time;
 588                         this.spawnshieldtime += f;
 589                         this.pauserotarmor_finished += f;
 590                         this.pauserothealth_finished += f;
 591                         this.pauseregen_finished += f;
 592                 }
 593                 this.damageforcescale = 2;
 594                 this.death_time = 0;
 595                 this.respawn_flags = 0;
 596                 this.respawn_time = 0;
 597                 this.stat_respawn_time = 0;
 598                 this.scale = autocvar_sv_player_scale;
 599                 this.fade_time = 0;
 600                 this.pain_frame = 0;
 601                 this.pain_finished = 0;
 602                 this.pushltime = 0;
 603                 setthink(this, func_null); // players have no think function
 604                 this.nextthink = 0;
 605                 this.dmg_team = 0;
 606                 this.ballistics_density = autocvar_g_ballistics_density_player;
 607
 608                 this.deadflag = DEAD_NO;
 609
 610                 this.angles = spot.angles;
 611                 this.angles_z = 0; // never spawn tilted even if the spot says to
 612                 if (IS_BOT_CLIENT(this))
 613                         this.v_angle = this.angles;
 614                 this.fixangle = true; // turn this way immediately
 615                 this.oldvelocity = this.velocity = '0 0 0';
 616                 this.avelocity = '0 0 0';
 617                 this.punchangle = '0 0 0';
 618                 this.punchvector = '0 0 0';
 619
 620                 this.strength_finished = 0;
 621                 this.invincible_finished = 0;
 622                 this.fire_endtime = -1;
 623                 this.revive_progress = 0;
 624                 this.revival_time = 0;
 625                 this.air_finished = time + 12;
 626
 627                 entity spawnevent = new_pure(spawnevent);
 628                 spawnevent.owner = this;
 629                 Net_LinkEntity(spawnevent, false, 0.5, SpawnEvent_Send);
 630
 631                 // Cut off any still running player sounds.
 632                 stopsound(this, CH_PLAYER_SINGLE);
 633
 634                 this.model = "";
 635                 FixPlayermodel(this);
 636                 this.drawonlytoclient = NULL;
 637
 638                 this.viewloc = NULL;
 639
 640                 this.crouch = false;
 641                 this.view_ofs = STAT(PL_VIEW_OFS, this);
 642                 setsize(this, STAT(PL_MIN, this), STAT(PL_MAX, this));
 643                 this.spawnorigin = spot.origin;
 644                 setorigin(this, spot.origin + '0 0 1' * (1 - this.mins.z - 24));
 645                 // don't reset back to last position, even if new position is stuck in solid
 646                 this.oldorigin = this.origin;
 647                 this.prevorigin = this.origin;
 648                 this.lastteleporttime = time; // prevent insane speeds due to changing origin
 649                 if(this.conveyor)
 650                         IL_REMOVE(g_conveyed, this);
 651                 this.conveyor = NULL; // prevent conveyors at the previous location from moving a freshly spawned player
 652                 this.hud = HUD_NORMAL;
 653
 654                 this.event_damage = PlayerDamage;
 655
 656                 if(!this.bot_attack)
 657                         IL_PUSH(g_bot_targets, this);
 658                 this.bot_attack = true;
 659                 this.monster_attack = true;
 660                 navigation_dynamicgoal_init(this, false);
 661
 662                 PHYS_INPUT_BUTTON_ATCK(this) = PHYS_INPUT_BUTTON_JUMP(this) = PHYS_INPUT_BUTTON_ATCK2(this) = false;
 663
 664                 if (this.killcount == FRAGS_SPECTATOR) {
 665                         PlayerScore_Clear(this);
 666                         this.killcount = 0;
 667                 }
 668
 669                 for (int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 670                 {
 671                         .entity weaponentity = weaponentities[slot];
 672                         entity oldwep = this.(weaponentity);
 673                         CL_SpawnWeaponentity(this, weaponentity);
 674                         if(oldwep && oldwep.owner == this)
 675                                 this.(weaponentity).m_gunalign = oldwep.m_gunalign;
 676                 }
 677                 this.alpha = default_player_alpha;
 678                 this.colormod = '1 1 1' * autocvar_g_player_brightness;
 679                 this.exteriorweaponentity.alpha = default_weapon_alpha;
 680
 681                 this.speedrunning = false;
 682
 683                 target_voicescript_clear(this);
 684
 685                 // reset fields the weapons may use
 686                 FOREACH(Weapons, true, LAMBDA(
 687                         it.wr_resetplayer(it, this);
 688                         // reload all reloadable weapons
 689                         if (it.spawnflags & WEP_FLAG_RELOADABLE) {
 690                                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 691                                 {
 692                                         .entity weaponentity = weaponentities[slot];
 693                                         this.(weaponentity).weapon_load[it.m_id] = it.reloading_ammo;
 694                                 }
 695                         }
 696                 ));
 697
 698                 {
 699                         string s = spot.target;
 700                         spot.target = string_null;
 701                         SUB_UseTargets(spot, this, NULL);
 702                         spot.target = s;
 703                 }
 704
 705                 Unfreeze(this);
 706
 707                 MUTATOR_CALLHOOK(PlayerSpawn, this, spot);
 708
 709                 if (autocvar_spawn_debug)
 710                 {
 711                         sprint(this, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
 712                         delete(spot); // usefull for checking if there are spawnpoints, that let drop through the floor
 713                 }
 714
 715                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 716                 {
 717                         .entity weaponentity = weaponentities[slot];
 718                         if(slot == 0 || autocvar_g_weaponswitch_debug == 1)
 719                                 this.(weaponentity).m_switchweapon = w_getbestweapon(this, weaponentity);
 720                         else
 721                                 this.(weaponentity).m_switchweapon = WEP_Null;
 722                         this.(weaponentity).m_weapon = WEP_Null;
 723                         this.(weaponentity).weaponname = "";
 724                         this.(weaponentity).m_switchingweapon = WEP_Null;
 725                         this.(weaponentity).cnt = -1;
 726                 }
 727
 728                 MUTATOR_CALLHOOK(PlayerWeaponSelect, this);
 729
 730                 if (!warmup_stage && !this.alivetime)
 731                         this.alivetime = time;
 732
 733                 antilag_clear(this, CS(this));
 734         }
 735 }
 736
 737 void ClientInit_misc(entity this);
 738
 739 // TODO do we need all these fields, or should we stop autodetecting runtime
 740 // changes and just have a console command to update this?
 741 bool ClientInit_SendEntity(entity this, entity to, int sf)
 742 {
 743         WriteHeader(MSG_ENTITY, _ENT_CLIENT_INIT);
 744         return = true;
 745         msg_entity = to;
 746         // MSG_INIT replacement
 747         // TODO: make easier to use
 748         Registry_send_all();
 749         W_PROP_reload(MSG_ONE, to);
 750         ClientInit_misc(this);
 751         MUTATOR_CALLHOOK(Ent_Init);
 752 }
 753 void ClientInit_misc(entity this)
 754 {
 755         int channel = MSG_ONE;
 756         WriteHeader(channel, ENT_CLIENT_INIT);
 757         WriteByte(channel, g_nexball_meter_period * 32);
 758         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[0]));
 759         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[1]));
 760         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[2]));
 761         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[3]));
 762         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[0]));
 763         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[1]));
 764         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[2]));
 765         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[3]));
 766
 767         if(sv_foginterval && world.fog != "")
 768                 WriteString(channel, world.fog);
 769         else
 770                 WriteString(channel, "");
 771         WriteByte(channel, this.count * 255.0); // g_balance_armor_blockpercent
 772         WriteByte(channel, serverflags);
 773         WriteCoord(channel, autocvar_g_trueaim_minrange);
 774 }
 775
 776 void ClientInit_CheckUpdate(entity this)
 777 {
 778         this.nextthink = time;
 779         if(this.count != autocvar_g_balance_armor_blockpercent)
 780         {
 781                 this.count = autocvar_g_balance_armor_blockpercent;
 782                 this.SendFlags |= 1;
 783         }
 784 }
 785
 786 void ClientInit_Spawn()
 787 {
 788         entity e = new_pure(clientinit);
 789         setthink(e, ClientInit_CheckUpdate);
 790         Net_LinkEntity(e, false, 0, ClientInit_SendEntity);
 791
 792         ClientInit_CheckUpdate(e);
 793 }
 794
 795 /*
 796 =============
 797 SetNewParms
 798 =============
 799 */
 800 void SetNewParms ()
 801 {
 802         // initialize parms for a new player
 803         parm1 = -(86400 * 366);
 804
 805         MUTATOR_CALLHOOK(SetNewParms);
 806 }
 807
 808 /*
 809 =============
 810 SetChangeParms
 811 =============
 812 */
 813 void SetChangeParms (entity this)
 814 {
 815         // save parms for level change
 816         parm1 = this.parm_idlesince - time;
 817
 818         MUTATOR_CALLHOOK(SetChangeParms);
 819 }
 820
 821 /*
 822 =============
 823 DecodeLevelParms
 824 =============
 825 */
 826 void DecodeLevelParms(entity this)
 827 {
 828         // load parms
 829         this.parm_idlesince = parm1;
 830         if (this.parm_idlesince == -(86400 * 366))
 831                 this.parm_idlesince = time;
 832
 833         // whatever happens, allow 60 seconds of idling directly after connect for map loading
 834         this.parm_idlesince = max(this.parm_idlesince, time - sv_maxidle + 60);
 835
 836         MUTATOR_CALLHOOK(DecodeLevelParms);
 837 }
 838
 839 /*
 840 =============
 841 ClientKill
 842
 843 Called when a client types 'kill' in the console
 844 =============
 845 */
 846
 847 .float clientkill_nexttime;
 848 void ClientKill_Now_TeamChange(entity this)
 849 {
 850         if(this.killindicator_teamchange == -1)
 851         {
 852                 JoinBestTeam( this, false, true );
 853         }
 854         else if(this.killindicator_teamchange == -2)
 855         {
 856                 if(blockSpectators)
 857                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
 858                 PutObserverInServer(this);
 859         }
 860         else
 861                 SV_ChangeTeam(this, this.killindicator_teamchange - 1);
 862         this.killindicator_teamchange = 0;
 863 }
 864
 865 void ClientKill_Now(entity this)
 866 {
 867         if(this.vehicle)
 868         {
 869             vehicles_exit(this.vehicle, VHEF_RELEASE);
 870             if(!this.killindicator_teamchange)
 871             {
 872             this.vehicle_health = -1;
 873             Damage(this, this, this, 1 , DEATH_KILL.m_id, this.origin, '0 0 0');
 874             }
 875         }
 876
 877         if(this.killindicator && !wasfreed(this.killindicator))
 878                 delete(this.killindicator);
 879
 880         this.killindicator = NULL;
 881
 882         if(this.killindicator_teamchange)
 883                 ClientKill_Now_TeamChange(this);
 884
 885         if(!IS_SPEC(this) && !IS_OBSERVER(this))
 886                 Damage(this, this, this, 100000, DEATH_KILL.m_id, this.origin, '0 0 0');
 887
 888         // now I am sure the player IS dead
 889 }
 890 void KillIndicator_Think(entity this)
 891 {
 892         if (game_stopped)
 893         {
 894                 this.owner.killindicator = NULL;
 895                 delete(this);
 896                 return;
 897         }
 898
 899         if (this.owner.alpha < 0 && !this.owner.vehicle)
 900         {
 901                 this.owner.killindicator = NULL;
 902                 delete(this);
 903                 return;
 904         }
 905
 906         if(this.cnt <= 0)
 907         {
 908                 ClientKill_Now(this.owner);
 909                 return;
 910         }
 911     else if(g_cts && this.health == 1) // health == 1 means that it's silent
 912     {
 913         this.nextthink = time + 1;
 914         this.cnt -= 1;
 915     }
 916         else
 917         {
 918                 if(this.cnt <= 10)
 919                         setmodel(this, MDL_NUM(this.cnt));
 920                 if(IS_REAL_CLIENT(this.owner))
 921                 {
 922                         if(this.cnt <= 10)
 923                                 { Send_Notification(NOTIF_ONE, this.owner, MSG_ANNCE, Announcer_PickNumber(CNT_KILL, this.cnt)); }
 924                 }
 925                 this.nextthink = time + 1;
 926                 this.cnt -= 1;
 927         }
 928 }
 929
 930 float clientkilltime;
 931 void ClientKill_TeamChange (entity this, float targetteam) // 0 = don't change, -1 = auto, -2 = spec
 932 {
 933         float killtime;
 934         float starttime;
 935
 936         if (game_stopped)
 937                 return;
 938
 939         killtime = autocvar_g_balance_kill_delay;
 940
 941         if(g_race_qualifying || g_cts)
 942                 killtime = 0;
 943
 944     if(MUTATOR_CALLHOOK(ClientKill, this, killtime))
 945         return;
 946
 947         this.killindicator_teamchange = targetteam;
 948
 949     if(!this.killindicator)
 950         {
 951                 if(!IS_DEAD(this))
 952                 {
 953                         killtime = max(killtime, this.clientkill_nexttime - time);
 954                         this.clientkill_nexttime = time + killtime + autocvar_g_balance_kill_antispam;
 955                 }
 956
 957                 if(killtime <= 0 || !IS_PLAYER(this) || IS_DEAD(this))
 958                 {
 959                         ClientKill_Now(this);
 960                 }
 961                 else
 962                 {
 963                         starttime = max(time, clientkilltime);
 964
 965                         this.killindicator = spawn();
 966                         this.killindicator.owner = this;
 967                         this.killindicator.scale = 0.5;
 968                         setattachment(this.killindicator, this, "");
 969                         setorigin(this.killindicator, '0 0 52');
 970                         setthink(this.killindicator, KillIndicator_Think);
 971                         this.killindicator.nextthink = starttime + (this.lip) * 0.05;
 972                         clientkilltime = max(clientkilltime, this.killindicator.nextthink + 0.05);
 973                         this.killindicator.cnt = ceil(killtime);
 974                         this.killindicator.count = bound(0, ceil(killtime), 10);
 975                         //sprint(this, strcat("^1You'll be dead in ", ftos(this.killindicator.cnt), " seconds\n"));
 976
 977                         IL_EACH(g_clones, it.enemy == this && !(it.effects & CSQCMODEL_EF_RESPAWNGHOST),
 978                         {
 979                                 it.killindicator = spawn();
 980                                 it.killindicator.owner = it;
 981                                 it.killindicator.scale = 0.5;
 982                                 setattachment(it.killindicator, it, "");
 983                                 setorigin(it.killindicator, '0 0 52');
 984                                 setthink(it.killindicator, KillIndicator_Think);
 985                                 it.killindicator.nextthink = starttime + (it.lip) * 0.05;
 986                                 //clientkilltime = max(clientkilltime, it.killindicator.nextthink + 0.05);
 987                                 it.killindicator.cnt = ceil(killtime);
 988                         });
 989                         this.lip = 0;
 990                 }
 991         }
 992         if(this.killindicator)
 993         {
 994                 if(targetteam == 0) // just die
 995                 {
 996                         this.killindicator.colormod = '0 0 0';
 997                         if(IS_REAL_CLIENT(this))
 998                         if(this.killindicator.cnt > 0)
 999                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_TEAMCHANGE_SUICIDE, this.killindicator.cnt);
1000                 }
1001                 else if(targetteam == -1) // auto
1002                 {
1003                         this.killindicator.colormod = '0 1 0';
1004                         if(IS_REAL_CLIENT(this))
1005                         if(this.killindicator.cnt > 0)
1006                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_TEAMCHANGE_AUTO, this.killindicator.cnt);
1007                 }
1008                 else if(targetteam == -2) // spectate
1009                 {
1010                         this.killindicator.colormod = '0.5 0.5 0.5';
1011                         if(IS_REAL_CLIENT(this))
1012                         if(this.killindicator.cnt > 0)
1013                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_TEAMCHANGE_SPECTATE, this.killindicator.cnt);
1014                 }
1015                 else
1016                 {
1017                         this.killindicator.colormod = Team_ColorRGB(targetteam);
1018                         if(IS_REAL_CLIENT(this))
1019                         if(this.killindicator.cnt > 0)
1020                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, APP_TEAM_NUM(targetteam, CENTER_TEAMCHANGE), this.killindicator.cnt);
1021                 }
1022         }
1023
1024 }
1025
1026 void ClientKill (entity this)
1027 {
1028         if(game_stopped) return;
1029         if(this.player_blocked) return;
1030         if(STAT(FROZEN, this)) return;
1031
1032         ClientKill_TeamChange(this, 0);
1033 }
1034
1035 void FixClientCvars(entity e)
1036 {
1037         // send prediction settings to the client
1038         stuffcmd(e, "\nin_bindmap 0 0\n");
1039         if(autocvar_g_antilag == 3) // client side hitscan
1040                 stuffcmd(e, "cl_cmd settemp cl_prydoncursor_notrace 0\n");
1041         if(autocvar_sv_gentle)
1042                 stuffcmd(e, "cl_cmd settemp cl_gentle 1\n");
1043
1044         MUTATOR_CALLHOOK(FixClientCvars, e);
1045 }
1046
1047 float PlayerInIDList(entity p, string idlist)
1048 {
1049         float n, i;
1050         string s;
1051
1052         // NOTE: we do NOT check crypto_idfp_signed here, an unsigned ID is fine too for this
1053         if (!p.crypto_idfp)
1054                 return 0;
1055
1056         // this function allows abbreviated player IDs too!
1057         n = tokenize_console(idlist);
1058         for(i = 0; i < n; ++i)
1059         {
1060                 s = argv(i);
1061                 if(s == substring(p.crypto_idfp, 0, strlen(s)))
1062                         return 1;
1063         }
1064
1065         return 0;
1066 }
1067
1068 #ifdef DP_EXT_PRECONNECT
1069 /*
1070 =============
1071 ClientPreConnect
1072
1073 Called once (not at each match start) when a client begins a connection to the server
1074 =============
1075 */
1076 void ClientPreConnect(entity this)
1077 {
1078         if(autocvar_sv_eventlog)
1079         {
1080                 GameLogEcho(sprintf(":connect:%d:%d:%s",
1081                         this.playerid,
1082                         etof(this),
1083                         ((IS_REAL_CLIENT(this)) ? this.netaddress : "bot")
1084                 ));
1085         }
1086 }
1087 #endif
1088
1089 /**
1090 =============
1091 ClientConnect
1092
1093 Called when a client connects to the server
1094 =============
1095 */
1096 void ClientConnect(entity this)
1097 {
1098         if (Ban_MaybeEnforceBanOnce(this)) return;
1099         assert(!IS_CLIENT(this), return);
1100         this.flags |= FL_CLIENT;
1101         assert(player_count >= 0, player_count = 0);
1102
1103 #ifdef WATERMARK
1104         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_WATERMARK, WATERMARK);
1105 #endif
1106         this.version_nagtime = time + 10 + random() * 10;
1107         TRANSMUTE(Client, this);
1108
1109         // identify the right forced team
1110         if (autocvar_g_campaign)
1111         {
1112                 if (IS_REAL_CLIENT(this)) // only players, not bots
1113                 {
1114                         switch (autocvar_g_campaign_forceteam)
1115                         {
1116                                 case 1: this.team_forced = NUM_TEAM_1; break;
1117                                 case 2: this.team_forced = NUM_TEAM_2; break;
1118                                 case 3: this.team_forced = NUM_TEAM_3; break;
1119                                 case 4: this.team_forced = NUM_TEAM_4; break;
1120                                 default: this.team_forced = 0;
1121                         }
1122                 }
1123         }
1124         else if (PlayerInIDList(this, autocvar_g_forced_team_red))    this.team_forced = NUM_TEAM_1;
1125         else if (PlayerInIDList(this, autocvar_g_forced_team_blue))   this.team_forced = NUM_TEAM_2;
1126         else if (PlayerInIDList(this, autocvar_g_forced_team_yellow)) this.team_forced = NUM_TEAM_3;
1127         else if (PlayerInIDList(this, autocvar_g_forced_team_pink))   this.team_forced = NUM_TEAM_4;
1128         else switch (autocvar_g_forced_team_otherwise)
1129         {
1130                 default: this.team_forced = 0; break;
1131                 case "red": this.team_forced = NUM_TEAM_1; break;
1132                 case "blue": this.team_forced = NUM_TEAM_2; break;
1133                 case "yellow": this.team_forced = NUM_TEAM_3; break;
1134                 case "pink": this.team_forced = NUM_TEAM_4; break;
1135                 case "spectate":
1136                 case "spectator":
1137                         this.team_forced = -1;
1138                         break;
1139         }
1140         if (!teamplay && this.team_forced > 0) this.team_forced = 0;
1141
1142     {
1143         int id = this.playerid;
1144         this.playerid = 0; // silent
1145             JoinBestTeam(this, false, false); // if the team number is valid, keep it
1146             this.playerid = id;
1147     }
1148
1149         if (autocvar_sv_spectate || autocvar_g_campaign || this.team_forced < 0) {
1150                 TRANSMUTE(Observer, this);
1151         } else {
1152                 if (!teamplay || autocvar_g_balance_teams) {
1153                         TRANSMUTE(Player, this);
1154                         campaign_bots_may_start = true;
1155                 } else {
1156                         TRANSMUTE(Observer, this); // do it anyway
1157                 }
1158         }
1159
1160         PlayerStats_GameReport_AddEvent(sprintf("kills-%d", this.playerid));
1161
1162         // always track bots, don't ask for cl_allow_uidtracking
1163     if (IS_BOT_CLIENT(this)) PlayerStats_GameReport_AddPlayer(this);
1164
1165         if (autocvar_sv_eventlog)
1166                 GameLogEcho(strcat(":join:", ftos(this.playerid), ":", ftos(etof(this)), ":", ((IS_REAL_CLIENT(this)) ? this.netaddress : "bot"), ":", playername(this, false)));
1167
1168         LogTeamchange(this.playerid, this.team, 1);
1169
1170         this.just_joined = true;  // stop spamming the eventlog with additional lines when the client connects
1171
1172         this.netname_previous = strzone(this.netname);
1173
1174         if(teamplay && IS_PLAYER(this))
1175                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, APP_TEAM_NUM(this.team, INFO_JOIN_CONNECT_TEAM), this.netname);
1176         else
1177                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_JOIN_CONNECT, this.netname);
1178
1179         stuffcmd(this, clientstuff, "\n");
1180         stuffcmd(this, "cl_particles_reloadeffects\n"); // TODO do we still need this?
1181
1182         FixClientCvars(this);
1183
1184         // get version info from player
1185         stuffcmd(this, "cmd clientversion $gameversion\n");
1186
1187         // notify about available teams
1188         if (teamplay)
1189         {
1190                 CheckAllowedTeams(this);
1191                 int t = 0;
1192                 if (c1 >= 0) t |= BIT(0);
1193                 if (c2 >= 0) t |= BIT(1);
1194                 if (c3 >= 0) t |= BIT(2);
1195                 if (c4 >= 0) t |= BIT(3);
1196                 stuffcmd(this, sprintf("set _teams_available %d\n", t));
1197         }
1198         else
1199         {
1200                 stuffcmd(this, "set _teams_available 0\n");
1201         }
1202
1203         bot_relinkplayerlist();
1204
1205         this.spectatortime = time;
1206         if (blockSpectators)
1207         {
1208                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
1209         }
1210
1211         this.jointime = time;
1212         this.allowed_timeouts = autocvar_sv_timeout_number;
1213
1214         if (IS_REAL_CLIENT(this))
1215         {
1216                 if (g_weaponarena_weapons == WEPSET(TUBA))
1217                         stuffcmd(this, "cl_cmd settemp chase_active 1\n");
1218         }
1219
1220         if (!sv_foginterval && world.fog != "")
1221                 stuffcmd(this, strcat("\nfog ", world.fog, "\nr_fog_exp2 0\nr_drawfog 1\n"));
1222
1223         if (autocvar_sv_teamnagger && !(autocvar_bot_vs_human && AvailableTeams() == 2))
1224                 if(!MUTATOR_CALLHOOK(HideTeamNagger, this))
1225                         send_CSQC_teamnagger();
1226
1227         CSQCMODEL_AUTOINIT(this);
1228
1229         this.model_randomizer = random();
1230
1231         if (IS_REAL_CLIENT(this))
1232                 sv_notice_join(this);
1233
1234         // update physics stats (players can spawn before physics runs)
1235         STAT(MOVEVARS_HIGHSPEED, this) = autocvar_g_movement_highspeed;
1236         MUTATOR_CALLHOOK(PlayerPhysics_UpdateStats, this); // do it BEFORE the function so we can modify highspeed!
1237         Physics_UpdateStats(this, PHYS_HIGHSPEED(this));
1238
1239         IL_EACH(g_initforplayer, it.init_for_player, {
1240                 it.init_for_player(it, this);
1241         });
1242
1243         MUTATOR_CALLHOOK(ClientConnect, this);
1244
1245         if (IS_REAL_CLIENT(this))
1246         {
1247                 if (!autocvar_g_campaign && !IS_PLAYER(this))
1248                 {
1249                         this.motd_actived_time = -1;
1250                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOTD, getwelcomemessage(this));
1251                 }
1252         }
1253 }
1254 /*
1255 =============
1256 ClientDisconnect
1257
1258 Called when a client disconnects from the server
1259 =============
1260 */
1261 .entity chatbubbleentity;
1262 void ReadyCount();
1263 void ClientDisconnect(entity this)
1264 {
1265         assert(IS_CLIENT(this), return);
1266
1267         PlayerStats_GameReport_FinalizePlayer(this);
1268         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
1269         if (this.active_minigame) part_minigame(this);
1270         if (IS_PLAYER(this)) Send_Effect(EFFECT_SPAWN_NEUTRAL, this.origin, '0 0 0', 1);
1271
1272         if (autocvar_sv_eventlog)
1273                 GameLogEcho(strcat(":part:", ftos(this.playerid)));
1274
1275         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_QUIT_DISCONNECT, this.netname);
1276
1277         if(IS_SPEC(this))
1278                 SetSpectatee(this, NULL);
1279
1280     MUTATOR_CALLHOOK(ClientDisconnect, this);
1281
1282         ClientState_detach(this);
1283
1284         Portal_ClearAll(this);
1285
1286         Unfreeze(this);
1287
1288         RemoveGrapplingHooks(this);
1289
1290         // Here, everything has been done that requires this player to be a client.
1291
1292         this.flags &= ~FL_CLIENT;
1293
1294         if (this.chatbubbleentity) delete(this.chatbubbleentity);
1295         if (this.killindicator) delete(this.killindicator);
1296
1297         WaypointSprite_PlayerGone(this);
1298
1299         bot_relinkplayerlist();
1300
1301         if (this.netname_previous) strunzone(this.netname_previous);
1302         if (this.clientstatus) strunzone(this.clientstatus);
1303         if (this.weaponorder_byimpulse) strunzone(this.weaponorder_byimpulse);
1304         if (this.personal) delete(this.personal);
1305
1306         this.playerid = 0;
1307         ReadyCount();
1308         if (vote_called && IS_REAL_CLIENT(this)) VoteCount(false);
1309
1310         ONREMOVE(this);
1311 }
1312
1313 void ChatBubbleThink(entity this)
1314 {
1315         this.nextthink = time;
1316         if ((this.owner.alpha < 0) || this.owner.chatbubbleentity != this)
1317         {
1318                 if(this.owner) // but why can that ever be NULL?
1319                         this.owner.chatbubbleentity = NULL;
1320                 delete(this);
1321                 return;
1322         }
1323
1324         this.mdl = "";
1325
1326         if ( !IS_DEAD(this.owner) && IS_PLAYER(this.owner) )
1327         {
1328                 if ( this.owner.active_minigame )
1329                         this.mdl = "models/sprites/minigame_busy.iqm";
1330                 else if (PHYS_INPUT_BUTTON_CHAT(this.owner))
1331                         this.mdl = "models/misc/chatbubble.spr";
1332         }
1333
1334         if ( this.model != this.mdl )
1335                 _setmodel(this, this.mdl);
1336
1337 }
1338
1339 void UpdateChatBubble(entity this)
1340 {
1341         if (this.alpha < 0)
1342                 return;
1343         // spawn a chatbubble entity if needed
1344         if (!this.chatbubbleentity)
1345         {
1346                 this.chatbubbleentity = new(chatbubbleentity);
1347                 this.chatbubbleentity.owner = this;
1348                 this.chatbubbleentity.exteriormodeltoclient = this;
1349                 setthink(this.chatbubbleentity, ChatBubbleThink);
1350                 this.chatbubbleentity.nextthink = time;
1351                 setmodel(this.chatbubbleentity, MDL_CHAT); // precision set below
1352                 //setorigin(this.chatbubbleentity, this.origin + '0 0 15' + this.maxs_z * '0 0 1');
1353                 setorigin(this.chatbubbleentity, '0 0 15' + this.maxs_z * '0 0 1');
1354                 setattachment(this.chatbubbleentity, this, "");  // sticks to moving player better, also conserves bandwidth
1355                 this.chatbubbleentity.mdl = this.chatbubbleentity.model;
1356                 //this.chatbubbleentity.model = "";
1357                 this.chatbubbleentity.effects = EF_LOWPRECISION;
1358         }
1359 }
1360
1361
1362 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
1363 // added to the model skins
1364 /*void UpdateColorModHack()
1365 {
1366         float c;
1367         c = this.clientcolors & 15;
1368         // LordHavoc: only bothering to support white, green, red, yellow, blue
1369              if (!teamplay) this.colormod = '0 0 0';
1370         else if (c ==  0) this.colormod = '1.00 1.00 1.00';
1371         else if (c ==  3) this.colormod = '0.10 1.73 0.10';
1372         else if (c ==  4) this.colormod = '1.73 0.10 0.10';
1373         else if (c == 12) this.colormod = '1.22 1.22 0.10';
1374         else if (c == 13) this.colormod = '0.10 0.10 1.73';
1375         else this.colormod = '1 1 1';
1376 }*/
1377
1378 void respawn(entity this)
1379 {
1380         if(this.alpha >= 0 && autocvar_g_respawn_ghosts)
1381         {
1382                 this.solid = SOLID_NOT;
1383                 this.takedamage = DAMAGE_NO;
1384                 set_movetype(this, MOVETYPE_FLY);
1385                 this.velocity = '0 0 1' * autocvar_g_respawn_ghosts_speed;
1386                 this.avelocity = randomvec() * autocvar_g_respawn_ghosts_speed * 3 - randomvec() * autocvar_g_respawn_ghosts_speed * 3;
1387                 this.effects |= CSQCMODEL_EF_RESPAWNGHOST;
1388                 Send_Effect(EFFECT_RESPAWN_GHOST, this.origin, '0 0 0', 1);
1389                 if(autocvar_g_respawn_ghosts_maxtime)
1390                         SUB_SetFade (this, time + autocvar_g_respawn_ghosts_maxtime / 2 + random () * (autocvar_g_respawn_ghosts_maxtime - autocvar_g_respawn_ghosts_maxtime / 2), 1.5);
1391         }
1392
1393         CopyBody(this, 1);
1394
1395         this.effects |= EF_NODRAW; // prevent another CopyBody
1396         PutClientInServer(this);
1397 }
1398
1399 void play_countdown(entity this, float finished, Sound samp)
1400 {
1401     TC(Sound, samp);
1402         if(IS_REAL_CLIENT(this))
1403                 if(floor(finished - time - frametime) != floor(finished - time))
1404                         if(finished - time < 6)
1405                                 sound (this, CH_INFO, samp, VOL_BASE, ATTEN_NORM);
1406 }
1407
1408 void player_powerups(entity this)
1409 {
1410         // add a way to see what the items were BEFORE all of these checks for the mutator hook
1411         int items_prev = this.items;
1412
1413         if((this.items & IT_USING_JETPACK) && !IS_DEAD(this) && !game_stopped)
1414                 this.modelflags |= MF_ROCKET;
1415         else
1416                 this.modelflags &= ~MF_ROCKET;
1417
1418         this.effects &= ~(EF_RED | EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT | EF_FLAME | EF_NODEPTHTEST);
1419
1420         if((this.alpha < 0 || IS_DEAD(this)) && !this.vehicle) // don't apply the flags if the player is gibbed
1421                 return;
1422
1423         Fire_ApplyDamage(this);
1424         Fire_ApplyEffect(this);
1425
1426         if (!g_instagib)
1427         {
1428                 if (this.items & ITEM_Strength.m_itemid)
1429                 {
1430                         play_countdown(this, this.strength_finished, SND_POWEROFF);
1431                         this.effects = this.effects | (EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT);
1432                         if (time > this.strength_finished)
1433                         {
1434                                 this.items = this.items - (this.items & ITEM_Strength.m_itemid);
1435                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERDOWN_STRENGTH, this.netname);
1436                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERDOWN_STRENGTH);
1437                         }
1438                 }
1439                 else
1440                 {
1441                         if (time < this.strength_finished)
1442                         {
1443                                 this.items = this.items | ITEM_Strength.m_itemid;
1444                                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERUP_STRENGTH, this.netname);
1445                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERUP_STRENGTH);
1446                         }
1447                 }
1448                 if (this.items & ITEM_Shield.m_itemid)
1449                 {
1450                         play_countdown(this, this.invincible_finished, SND_POWEROFF);
1451                         this.effects = this.effects | (EF_RED | EF_ADDITIVE | EF_FULLBRIGHT);
1452                         if (time > this.invincible_finished)
1453                         {
1454                                 this.items = this.items - (this.items & ITEM_Shield.m_itemid);
1455                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERDOWN_SHIELD, this.netname);
1456                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERDOWN_SHIELD);
1457                         }
1458                 }
1459                 else
1460                 {
1461                         if (time < this.invincible_finished)
1462                         {
1463                                 this.items = this.items | ITEM_Shield.m_itemid;
1464                                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERUP_SHIELD, this.netname);
1465                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERUP_SHIELD);
1466                         }
1467                 }
1468                 if (this.items & IT_SUPERWEAPON)
1469                 {
1470                         if (!(this.weapons & WEPSET_SUPERWEAPONS))
1471                         {
1472                                 this.superweapons_finished = 0;
1473                                 this.items = this.items - (this.items & IT_SUPERWEAPON);
1474                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_LOST, this.netname);
1475                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_LOST);
1476                         }
1477                         else if (this.items & IT_UNLIMITED_SUPERWEAPONS)
1478                         {
1479                                 // don't let them run out
1480                         }
1481                         else
1482                         {
1483                                 play_countdown(this, this.superweapons_finished, SND_POWEROFF);
1484                                 if (time > this.superweapons_finished)
1485                                 {
1486                                         this.items = this.items - (this.items & IT_SUPERWEAPON);
1487                                         this.weapons &= ~WEPSET_SUPERWEAPONS;
1488                                         //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_BROKEN, this.netname);
1489                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_BROKEN);
1490                                 }
1491                         }
1492                 }
1493                 else if(this.weapons & WEPSET_SUPERWEAPONS)
1494                 {
1495                         if (time < this.superweapons_finished || (this.items & IT_UNLIMITED_SUPERWEAPONS))
1496                         {
1497                                 this.items = this.items | IT_SUPERWEAPON;
1498                                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_PICKUP, this.netname);
1499                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_PICKUP);
1500                         }
1501                         else
1502                         {
1503                                 this.superweapons_finished = 0;
1504                                 this.weapons &= ~WEPSET_SUPERWEAPONS;
1505                         }
1506                 }
1507                 else
1508                 {
1509                         this.superweapons_finished = 0;
1510                 }
1511         }
1512
1513         if(autocvar_g_nodepthtestplayers)
1514                 this.effects = this.effects | EF_NODEPTHTEST;
1515
1516         if(autocvar_g_fullbrightplayers)
1517                 this.effects = this.effects | EF_FULLBRIGHT;
1518
1519         if (time >= game_starttime)
1520         if (time < this.spawnshieldtime)
1521                 this.effects = this.effects | (EF_ADDITIVE | EF_FULLBRIGHT);
1522
1523         MUTATOR_CALLHOOK(PlayerPowerups, this, items_prev);
1524 }
1525
1526 float CalcRegen(float current, float stable, float regenfactor, float regenframetime)
1527 {
1528         if(current > stable)
1529                 return current;
1530         else if(current > stable - 0.25) // when close enough, "snap"
1531                 return stable;
1532         else
1533                 return min(stable, current + (stable - current) * regenfactor * regenframetime);
1534 }
1535
1536 float CalcRot(float current, float stable, float rotfactor, float rotframetime)
1537 {
1538         if(current < stable)
1539                 return current;
1540         else if(current < stable + 0.25) // when close enough, "snap"
1541                 return stable;
1542         else
1543                 return max(stable, current + (stable - current) * rotfactor * rotframetime);
1544 }
1545
1546 float CalcRotRegen(float current, float regenstable, float regenfactor, float regenlinear, float regenframetime, float rotstable, float rotfactor, float rotlinear, float rotframetime, float limit)
1547 {
1548         if(current > rotstable)
1549         {
1550                 if(rotframetime > 0)
1551                 {
1552                         current = CalcRot(current, rotstable, rotfactor, rotframetime);
1553                         current = max(rotstable, current - rotlinear * rotframetime);
1554                 }
1555         }
1556         else if(current < regenstable)
1557         {
1558                 if(regenframetime > 0)
1559                 {
1560                         current = CalcRegen(current, regenstable, regenfactor, regenframetime);
1561                         current = min(regenstable, current + regenlinear * regenframetime);
1562                 }
1563         }
1564
1565         if(current > limit)
1566                 current = limit;
1567
1568         return current;
1569 }
1570
1571 void player_regen(entity this)
1572 {
1573         float max_mod, regen_mod, rot_mod, limit_mod;
1574         max_mod = regen_mod = rot_mod = limit_mod = 1;
1575
1576         float regen_health = autocvar_g_balance_health_regen;
1577         float regen_health_linear = autocvar_g_balance_health_regenlinear;
1578         float regen_health_rot = autocvar_g_balance_health_rot;
1579         float regen_health_rotlinear = autocvar_g_balance_health_rotlinear;
1580         float regen_health_stable = autocvar_g_balance_health_regenstable;
1581         float regen_health_rotstable = autocvar_g_balance_health_rotstable;
1582         bool mutator_returnvalue = MUTATOR_CALLHOOK(PlayerRegen, this, max_mod, regen_mod, rot_mod, limit_mod, regen_health, regen_health_linear, regen_health_rot,
1583                 regen_health_rotlinear, regen_health_stable, regen_health_rotstable);
1584         max_mod = M_ARGV(1, float);
1585         regen_mod = M_ARGV(2, float);
1586         rot_mod = M_ARGV(3, float);
1587         limit_mod = M_ARGV(4, float);
1588         regen_health = M_ARGV(5, float);
1589         regen_health_linear = M_ARGV(6, float);
1590         regen_health_rot = M_ARGV(7, float);
1591         regen_health_rotlinear = M_ARGV(8, float);
1592         regen_health_stable = M_ARGV(9, float);
1593         regen_health_rotstable = M_ARGV(10, float);
1594
1595
1596         if(!mutator_returnvalue)
1597         if(!STAT(FROZEN, this))
1598         {
1599                 float mina, maxa, limith, limita;
1600                 maxa = autocvar_g_balance_armor_rotstable;
1601                 mina = autocvar_g_balance_armor_regenstable;
1602                 limith = autocvar_g_balance_health_limit;
1603                 limita = autocvar_g_balance_armor_limit;
1604
1605                 regen_health_rotstable = regen_health_rotstable * max_mod;
1606                 regen_health_stable = regen_health_stable * max_mod;
1607                 limith = limith * limit_mod;
1608                 limita = limita * limit_mod;
1609
1610                 this.armorvalue = CalcRotRegen(this.armorvalue, mina, autocvar_g_balance_armor_regen, autocvar_g_balance_armor_regenlinear, regen_mod * frametime * (time > this.pauseregen_finished), maxa, autocvar_g_balance_armor_rot, autocvar_g_balance_armor_rotlinear, rot_mod * frametime * (time > this.pauserotarmor_finished), limita);
1611                 this.health = CalcRotRegen(this.health, regen_health_stable, regen_health, regen_health_linear, regen_mod * frametime * (time > this.pauseregen_finished), regen_health_rotstable, regen_health_rot, regen_health_rotlinear, rot_mod * frametime * (time > this.pauserothealth_finished), limith);
1612         }
1613
1614         // if player rotted to death...  die!
1615         // check this outside above checks, as player may still be able to rot to death
1616         if(this.health < 1)
1617         {
1618                 if(this.vehicle)
1619                         vehicles_exit(this.vehicle, VHEF_RELEASE);
1620                 if(this.event_damage)
1621                         this.event_damage(this, this, this, 1, DEATH_ROT.m_id, this.origin, '0 0 0');
1622         }
1623
1624         if (!(this.items & IT_UNLIMITED_WEAPON_AMMO))
1625         {
1626                 float minf, maxf, limitf;
1627
1628                 maxf = autocvar_g_balance_fuel_rotstable;
1629                 minf = autocvar_g_balance_fuel_regenstable;
1630                 limitf = autocvar_g_balance_fuel_limit;
1631
1632                 this.ammo_fuel = CalcRotRegen(this.ammo_fuel, minf, autocvar_g_balance_fuel_regen, autocvar_g_balance_fuel_regenlinear, frametime * (time > this.pauseregen_finished) * ((this.items & ITEM_JetpackRegen.m_itemid) != 0), maxf, autocvar_g_balance_fuel_rot, autocvar_g_balance_fuel_rotlinear, frametime * (time > this.pauserotfuel_finished), limitf);
1633         }
1634 }
1635
1636 bool zoomstate_set;
1637 void SetZoomState(entity this, float newzoom)
1638 {
1639         if(newzoom != this.zoomstate)
1640         {
1641                 this.zoomstate = newzoom;
1642                 ClientData_Touch(this);
1643         }
1644         zoomstate_set = true;
1645 }
1646
1647 void GetPressedKeys(entity this)
1648 {
1649         MUTATOR_CALLHOOK(GetPressedKeys, this);
1650         int keys = STAT(PRESSED_KEYS, this);
1651         keys = BITSET(keys, KEY_FORWARD,        this.movement.x > 0);
1652         keys = BITSET(keys, KEY_BACKWARD,       this.movement.x < 0);
1653         keys = BITSET(keys, KEY_RIGHT,          this.movement.y > 0);
1654         keys = BITSET(keys, KEY_LEFT,           this.movement.y < 0);
1655
1656         keys = BITSET(keys, KEY_JUMP,           PHYS_INPUT_BUTTON_JUMP(this));
1657         keys = BITSET(keys, KEY_CROUCH,         PHYS_INPUT_BUTTON_CROUCH(this));
1658         keys = BITSET(keys, KEY_ATCK,           PHYS_INPUT_BUTTON_ATCK(this));
1659         keys = BITSET(keys, KEY_ATCK2,          PHYS_INPUT_BUTTON_ATCK2(this));
1660         this.pressedkeys = keys; // store for other users
1661
1662         STAT(PRESSED_KEYS, this) = keys;
1663 }
1664
1665 /*
1666 ======================
1667 spectate mode routines
1668 ======================
1669 */
1670
1671 void SpectateCopy(entity this, entity spectatee)
1672 {
1673     TC(Client, this); TC(Client, spectatee);
1674
1675         MUTATOR_CALLHOOK(SpectateCopy, spectatee, this);
1676         PS(this) = PS(spectatee);
1677         this.armortype = spectatee.armortype;
1678         this.armorvalue = spectatee.armorvalue;
1679         this.ammo_cells = spectatee.ammo_cells;
1680         this.ammo_plasma = spectatee.ammo_plasma;
1681         this.ammo_shells = spectatee.ammo_shells;
1682         this.ammo_nails = spectatee.ammo_nails;
1683         this.ammo_rockets = spectatee.ammo_rockets;
1684         this.ammo_fuel = spectatee.ammo_fuel;
1685         this.clip_load = spectatee.clip_load;
1686         this.clip_size = spectatee.clip_size;
1687         this.effects = spectatee.effects & EFMASK_CHEAP; // eat performance
1688         this.health = spectatee.health;
1689         this.impulse = 0;
1690         this.items = spectatee.items;
1691         this.last_pickup = spectatee.last_pickup;
1692         this.hit_time = spectatee.hit_time;
1693         this.strength_finished = spectatee.strength_finished;
1694         this.invincible_finished = spectatee.invincible_finished;
1695         this.superweapons_finished = spectatee.superweapons_finished;
1696         STAT(PRESSED_KEYS, this) = STAT(PRESSED_KEYS, spectatee);
1697         this.weapons = spectatee.weapons;
1698         this.dual_weapons = spectatee.dual_weapons;
1699         this.vortex_charge = spectatee.vortex_charge;
1700         this.vortex_chargepool_ammo = spectatee.vortex_chargepool_ammo;
1701         this.hagar_load = spectatee.hagar_load;
1702         this.arc_heat_percent = spectatee.arc_heat_percent;
1703         this.minelayer_mines = spectatee.minelayer_mines;
1704         this.punchangle = spectatee.punchangle;
1705         this.view_ofs = spectatee.view_ofs;
1706         this.velocity = spectatee.velocity;
1707         this.dmg_take = spectatee.dmg_take;
1708         this.dmg_save = spectatee.dmg_save;
1709         this.dmg_inflictor = spectatee.dmg_inflictor;
1710         this.v_angle = spectatee.v_angle;
1711         this.angles = spectatee.v_angle;
1712         STAT(FROZEN, this) = STAT(FROZEN, spectatee);
1713         this.revive_progress = spectatee.revive_progress;
1714         this.viewloc = spectatee.viewloc;
1715         if(!PHYS_INPUT_BUTTON_USE(this) && STAT(CAMERA_SPECTATOR, this) != 2)
1716                 this.fixangle = true;
1717         setorigin(this, spectatee.origin);
1718         setsize(this, spectatee.mins, spectatee.maxs);
1719         SetZoomState(this, spectatee.zoomstate);
1720
1721         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1722         {
1723                 .entity weaponentity = weaponentities[slot];
1724                 this.(weaponentity) = spectatee.(weaponentity);
1725         }
1726
1727         for(int slot = 0; slot < MAX_AXH; ++slot)
1728         {
1729                 this.(AuxiliaryXhair[slot]) = spectatee.(AuxiliaryXhair[slot]);
1730         }
1731
1732     anticheat_spectatecopy(this, spectatee);
1733         this.hud = spectatee.hud;
1734         if(spectatee.vehicle)
1735     {
1736         this.angles = spectatee.v_angle;
1737
1738         //this.fixangle = false;
1739         //this.velocity = spectatee.vehicle.velocity;
1740         this.vehicle_health = spectatee.vehicle_health;
1741         this.vehicle_shield = spectatee.vehicle_shield;
1742         this.vehicle_energy = spectatee.vehicle_energy;
1743         this.vehicle_ammo1 = spectatee.vehicle_ammo1;
1744         this.vehicle_ammo2 = spectatee.vehicle_ammo2;
1745         this.vehicle_reload1 = spectatee.vehicle_reload1;
1746         this.vehicle_reload2 = spectatee.vehicle_reload2;
1747
1748         //msg_entity = this;
1749
1750        // WriteByte (MSG_ONE, SVC_SETVIEWANGLES);
1751             //WriteAngle(MSG_ONE,  spectatee.v_angle.x);
1752            // WriteAngle(MSG_ONE,  spectatee.v_angle.y);
1753            // WriteAngle(MSG_ONE,  spectatee.v_angle.z);
1754
1755         //WriteByte (MSG_ONE, SVC_SETVIEW);
1756         //    WriteEntity(MSG_ONE, this);
1757         //makevectors(spectatee.v_angle);
1758         //setorigin(this, spectatee.origin - v_forward * 400 + v_up * 300);*/
1759     }
1760 }
1761
1762 bool SpectateUpdate(entity this)
1763 {
1764         if(!this.enemy)
1765                 return false;
1766
1767         if(!IS_PLAYER(this.enemy) || this == this.enemy)
1768         {
1769                 SetSpectatee(this, NULL);
1770                 return false;
1771         }
1772
1773         SpectateCopy(this, this.enemy);
1774
1775         return true;
1776 }
1777
1778 bool SpectateSet(entity this)
1779 {
1780         if(!IS_PLAYER(this.enemy))
1781                 return false;
1782
1783         ClientData_Touch(this.enemy);
1784
1785         msg_entity = this;
1786         WriteByte(MSG_ONE, SVC_SETVIEW);
1787         WriteEntity(MSG_ONE, this.enemy);
1788         set_movetype(this, MOVETYPE_NONE);
1789         accuracy_resend(this);
1790
1791         if(!SpectateUpdate(this))
1792                 PutObserverInServer(this);
1793
1794         return true;
1795 }
1796
1797 void SetSpectatee_status(entity this, int spectatee_num)
1798 {
1799         int oldspectatee_status = this.spectatee_status;
1800         this.spectatee_status = spectatee_num;
1801
1802         if (this.spectatee_status != oldspectatee_status)
1803         {
1804                 ClientData_Touch(this);
1805                 if (g_race || g_cts) race_InitSpectator();
1806         }
1807 }
1808
1809 void SetSpectatee(entity this, entity spectatee)
1810 {
1811         entity old_spectatee = this.enemy;
1812
1813         this.enemy = spectatee;
1814
1815         // WEAPONTODO
1816         // these are required to fix the spectator bug with arc
1817         if(old_spectatee)
1818         {
1819                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1820                 {
1821                         .entity weaponentity = weaponentities[slot];
1822                         if(old_spectatee.(weaponentity).arc_beam)
1823                                 old_spectatee.(weaponentity).arc_beam.SendFlags |= ARC_SF_SETTINGS;
1824                 }
1825         }
1826         if(this.enemy)
1827         {
1828                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1829                 {
1830                         .entity weaponentity = weaponentities[slot];
1831                         if(this.enemy.(weaponentity).arc_beam)
1832                                 this.enemy.(weaponentity).arc_beam.SendFlags |= ARC_SF_SETTINGS;
1833                 }
1834         }
1835
1836         if (this.enemy)
1837                 SetSpectatee_status(this, etof(this.enemy));
1838
1839         // needed to update spectator list
1840         if(old_spectatee) { ClientData_Touch(old_spectatee); }
1841 }
1842
1843 bool Spectate(entity this, entity pl)
1844 {
1845         if(MUTATOR_CALLHOOK(SpectateSet, this, pl))
1846                 return false;
1847         pl = M_ARGV(1, entity);
1848
1849         SetSpectatee(this, pl);
1850         return SpectateSet(this);
1851 }
1852
1853 bool SpectateNext(entity this)
1854 {
1855         entity ent = find(this.enemy, classname, STR_PLAYER);
1856
1857         if (MUTATOR_CALLHOOK(SpectateNext, this, ent))
1858                 ent = M_ARGV(1, entity);
1859         else if (!ent)
1860                 ent = find(ent, classname, STR_PLAYER);
1861
1862         if(ent) { SetSpectatee(this, ent); }
1863
1864         return SpectateSet(this);
1865 }
1866
1867 bool SpectatePrev(entity this)
1868 {
1869         // NOTE: chain order is from the highest to the lower entnum (unlike find)
1870         entity ent = findchain(classname, STR_PLAYER);
1871         if (!ent) // no player
1872                 return false;
1873
1874         entity first = ent;
1875         // skip players until current spectated player
1876         if(this.enemy)
1877         while(ent && ent != this.enemy)
1878                 ent = ent.chain;
1879
1880         switch (MUTATOR_CALLHOOK(SpectatePrev, this, ent, first))
1881         {
1882                 case MUT_SPECPREV_FOUND:
1883                     ent = M_ARGV(1, entity);
1884                     break;
1885                 case MUT_SPECPREV_RETURN:
1886                     return true;
1887                 case MUT_SPECPREV_CONTINUE:
1888                 default:
1889                 {
1890                         if(ent.chain)
1891                                 ent = ent.chain;
1892                         else
1893                                 ent = first;
1894                         break;
1895                 }
1896         }
1897
1898         SetSpectatee(this, ent);
1899         return SpectateSet(this);
1900 }
1901
1902 /*
1903 =============
1904 ShowRespawnCountdown()
1905
1906 Update a respawn countdown display.
1907 =============
1908 */
1909 void ShowRespawnCountdown(entity this)
1910 {
1911         float number;
1912         if(!IS_DEAD(this)) // just respawned?
1913                 return;
1914         else
1915         {
1916                 number = ceil(this.respawn_time - time);
1917                 if(number <= 0)
1918                         return;
1919                 if(number <= this.respawn_countdown)
1920                 {
1921                         this.respawn_countdown = number - 1;
1922                         if(ceil(this.respawn_time - (time + 0.5)) == number) // only say it if it is the same number even in 0.5s; to prevent overlapping sounds
1923                                 { Send_Notification(NOTIF_ONE, this, MSG_ANNCE, Announcer_PickNumber(CNT_RESPAWN, number)); }
1924                 }
1925         }
1926 }
1927
1928 .bool team_selected;
1929 bool ShowTeamSelection(entity this)
1930 {
1931         if(!teamplay || autocvar_g_campaign || autocvar_g_balance_teams || this.team_selected || (this.wasplayer && autocvar_g_changeteam_banned) || this.team_forced > 0)
1932                 return false;
1933         stuffcmd(this, "menu_showteamselect\n");
1934         return true;
1935 }
1936 void Join(entity this)
1937 {
1938         TRANSMUTE(Player, this);
1939
1940         if(!this.team_selected)
1941         if(autocvar_g_campaign || autocvar_g_balance_teams)
1942                 JoinBestTeam(this, false, true);
1943
1944         if(autocvar_g_campaign)
1945                 campaign_bots_may_start = true;
1946
1947         Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_PREVENT_JOIN);
1948
1949         PutClientInServer(this);
1950
1951         if(teamplay && this.team != -1)
1952                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, APP_TEAM_NUM(this.team, INFO_JOIN_PLAY_TEAM), this.netname);
1953         else
1954                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_JOIN_PLAY, this.netname);
1955         this.team_selected = false;
1956 }
1957
1958 /**
1959  * Determines whether the player is allowed to join. This depends on cvar
1960  * g_maxplayers, if it isn't used this function always return true, otherwise
1961  * it checks whether the number of currently playing players exceeds g_maxplayers.
1962  * @return int number of free slots for players, 0 if none
1963  */
1964 int nJoinAllowed(entity this, entity ignore)
1965 {
1966         if(!ignore)
1967         // this is called that way when checking if anyone may be able to join (to build qcstatus)
1968         // so report 0 free slots if restricted
1969         {
1970                 if(autocvar_g_forced_team_otherwise == "spectate")
1971                         return 0;
1972                 if(autocvar_g_forced_team_otherwise == "spectator")
1973                         return 0;
1974         }
1975
1976         if(this && this.team_forced < 0)
1977                 return 0; // forced spectators can never join
1978
1979         // TODO simplify this
1980         int totalClients = 0;
1981         int currentlyPlaying = 0;
1982         FOREACH_CLIENT(true, LAMBDA(
1983                 if(it != ignore)
1984                         ++totalClients;
1985                 if(IS_REAL_CLIENT(it))
1986                 if(IS_PLAYER(it) || it.caplayer)
1987                         ++currentlyPlaying;
1988         ));
1989
1990         float free_slots = 0;
1991         if (!autocvar_g_maxplayers)
1992                 free_slots = maxclients - totalClients;
1993         else if(currentlyPlaying < autocvar_g_maxplayers)
1994                 free_slots = min(maxclients - totalClients, autocvar_g_maxplayers - currentlyPlaying);
1995
1996         static float join_prevent_msg_time = 0;
1997         if(this && ignore && !free_slots && time > join_prevent_msg_time)
1998         {
1999                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_JOIN_PREVENT);
2000                 join_prevent_msg_time = time + 3;
2001         }
2002
2003         return free_slots;
2004 }
2005
2006 /**
2007  * Checks whether the client is an observer or spectator, if so, he will get kicked after
2008  * g_maxplayers_spectator_blocktime seconds
2009  */
2010 void checkSpectatorBlock(entity this)
2011 {
2012         if(IS_SPEC(this) || IS_OBSERVER(this))
2013         if(!this.caplayer)
2014         if(IS_REAL_CLIENT(this))
2015         {
2016                 if( time > (this.spectatortime + autocvar_g_maxplayers_spectator_blocktime) ) {
2017                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_QUIT_KICK_SPECTATING);
2018                         dropclient(this);
2019                 }
2020         }
2021 }
2022
2023 void PrintWelcomeMessage(entity this)
2024 {
2025         if(this.motd_actived_time == 0)
2026         {
2027                 if (autocvar_g_campaign) {
2028                         if ((IS_PLAYER(this) && PHYS_INPUT_BUTTON_INFO(this)) || (!IS_PLAYER(this))) {
2029                                 this.motd_actived_time = time;
2030                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOTD, campaign_message);
2031                         }
2032                 } else {
2033                         if (PHYS_INPUT_BUTTON_INFO(this)) {
2034                                 this.motd_actived_time = time;
2035                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOTD, getwelcomemessage(this));
2036                         }
2037                 }
2038         }
2039         else if(this.motd_actived_time > 0) // showing MOTD or campaign message
2040         {
2041                 if (autocvar_g_campaign) {
2042                         if (PHYS_INPUT_BUTTON_INFO(this))
2043                                 this.motd_actived_time = time;
2044                         else if ((time - this.motd_actived_time > 2) && IS_PLAYER(this)) { // hide it some seconds after BUTTON_INFO has been released
2045                                 this.motd_actived_time = 0;
2046                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_MOTD);
2047                         }
2048                 } else {
2049                         if (PHYS_INPUT_BUTTON_INFO(this))
2050                                 this.motd_actived_time = time;
2051                         else if (time - this.motd_actived_time > 2) { // hide it some seconds after BUTTON_INFO has been released
2052                                 this.motd_actived_time = 0;
2053                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_MOTD);
2054                         }
2055                 }
2056         }
2057         else //if(this.motd_actived_time < 0) // just connected, motd is active
2058         {
2059                 if(PHYS_INPUT_BUTTON_INFO(this)) // BUTTON_INFO hides initial MOTD
2060                         this.motd_actived_time = -2; // wait until BUTTON_INFO gets released
2061                 else if(this.motd_actived_time == -2 || IS_PLAYER(this) || IS_SPEC(this))
2062                 {
2063                         // instanctly hide MOTD
2064                         this.motd_actived_time = 0;
2065                         Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_MOTD);
2066                 }
2067         }
2068 }
2069
2070 bool joinAllowed(entity this)
2071 {
2072         if (this.version_mismatch) return false;
2073         if (!nJoinAllowed(this, this)) return false;
2074         if (teamplay && lockteams) return false;
2075         if (ShowTeamSelection(this)) return false;
2076         if (MUTATOR_CALLHOOK(ForbidSpawn, this)) return false;
2077         return true;
2078 }
2079
2080 void ObserverThink(entity this)
2081 {
2082         if ( this.impulse )
2083         {
2084                 MinigameImpulse(this, this.impulse);
2085                 this.impulse = 0;
2086         }
2087
2088         if (this.flags & FL_JUMPRELEASED) {
2089                 if (PHYS_INPUT_BUTTON_JUMP(this) && joinAllowed(this)) {
2090                         this.flags &= ~FL_JUMPRELEASED;
2091                         this.flags |= FL_SPAWNING;
2092                 } else if(PHYS_INPUT_BUTTON_ATCK(this) && !this.version_mismatch) {
2093                         this.flags &= ~FL_JUMPRELEASED;
2094                         if(SpectateNext(this)) {
2095                                 TRANSMUTE(Spectator, this);
2096                         }
2097                 } else {
2098                         int preferred_movetype = ((!PHYS_INPUT_BUTTON_USE(this) ? this.cvar_cl_clippedspectating : !this.cvar_cl_clippedspectating) ? MOVETYPE_FLY_WORLDONLY : MOVETYPE_NOCLIP);
2099                         set_movetype(this, preferred_movetype);
2100                 }
2101         } else {
2102                 if (!(PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_JUMP(this))) {
2103                         this.flags |= FL_JUMPRELEASED;
2104                         if(this.flags & FL_SPAWNING)
2105                         {
2106                                 this.flags &= ~FL_SPAWNING;
2107                                 Join(this);
2108                                 return;
2109                         }
2110                 }
2111         }
2112 }
2113
2114 void SpectatorThink(entity this)
2115 {
2116         if ( this.impulse )
2117         {
2118                 if(MinigameImpulse(this, this.impulse))
2119                         this.impulse = 0;
2120
2121                 if (this.impulse == IMP_weapon_drop.impulse)
2122                 {
2123                         STAT(CAMERA_SPECTATOR, this) = (STAT(CAMERA_SPECTATOR, this) + 1) % 3;
2124                         this.impulse = 0;
2125                         return;
2126                 }
2127         }
2128
2129         if (this.flags & FL_JUMPRELEASED) {
2130                 if (PHYS_INPUT_BUTTON_JUMP(this) && joinAllowed(this)) {
2131                         this.flags &= ~FL_JUMPRELEASED;
2132                         this.flags |= FL_SPAWNING;
2133                 } else if(PHYS_INPUT_BUTTON_ATCK(this) || this.impulse == 10 || this.impulse == 15 || this.impulse == 18 || (this.impulse >= 200 && this.impulse <= 209)) {
2134                         this.flags &= ~FL_JUMPRELEASED;
2135                         if(SpectateNext(this)) {
2136                                 TRANSMUTE(Spectator, this);
2137                         } else {
2138                                 TRANSMUTE(Observer, this);
2139                                 PutClientInServer(this);
2140                         }
2141                         this.impulse = 0;
2142                 } else if(this.impulse == 12 || this.impulse == 16  || this.impulse == 19 || (this.impulse >= 220 && this.impulse <= 229)) {
2143                         this.flags &= ~FL_JUMPRELEASED;
2144                         if(SpectatePrev(this)) {
2145                                 TRANSMUTE(Spectator, this);
2146                         } else {
2147                                 TRANSMUTE(Observer, this);
2148                                 PutClientInServer(this);
2149                         }
2150                         this.impulse = 0;
2151                 } else if (PHYS_INPUT_BUTTON_ATCK2(this)) {
2152                         this.flags &= ~FL_JUMPRELEASED;
2153                         TRANSMUTE(Observer, this);
2154                         PutClientInServer(this);
2155                 } else {
2156                         if(!SpectateUpdate(this))
2157                                 PutObserverInServer(this);
2158                 }
2159         } else {
2160                 if (!(PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_ATCK2(this))) {
2161                         this.flags |= FL_JUMPRELEASED;
2162                         if(this.flags & FL_SPAWNING)
2163                         {
2164                                 this.flags &= ~FL_SPAWNING;
2165                                 Join(this);
2166                                 return;
2167                         }
2168                 }
2169                 if(!SpectateUpdate(this))
2170                         PutObserverInServer(this);
2171         }
2172
2173         this.flags |= FL_CLIENT | FL_NOTARGET;
2174 }
2175
2176 void vehicles_enter (entity pl, entity veh);
2177 void PlayerUseKey(entity this)
2178 {
2179         if (!IS_PLAYER(this))
2180                 return;
2181
2182         if(this.vehicle)
2183         {
2184                 if(!game_stopped)
2185                 {
2186                         vehicles_exit(this.vehicle, VHEF_NORMAL);
2187                         return;
2188                 }
2189         }
2190         else if(autocvar_g_vehicles_enter)
2191         {
2192                 if(!STAT(FROZEN, this))
2193                 if(!IS_DEAD(this))
2194                 if(!game_stopped)
2195                 {
2196                         entity head, closest_target = NULL;
2197                         head = WarpZone_FindRadius(this.origin, autocvar_g_vehicles_enter_radius, true);
2198
2199                         while(head) // find the closest acceptable target to enter
2200                         {
2201                                 if(IS_VEHICLE(head))
2202                                 if(!IS_DEAD(head))
2203                                 if(!head.owner || ((head.vehicle_flags & VHF_MULTISLOT) && SAME_TEAM(head.owner, this)))
2204                                 if(head.takedamage != DAMAGE_NO)
2205                                 {
2206                                         if(closest_target)
2207                                         {
2208                                                 if(vlen2(this.origin - head.origin) < vlen2(this.origin - closest_target.origin))
2209                                                 { closest_target = head; }
2210                                         }
2211                                         else { closest_target = head; }
2212                                 }
2213
2214                                 head = head.chain;
2215                         }
2216
2217                         if(closest_target) { vehicles_enter(this, closest_target); return; }
2218                 }
2219         }
2220
2221         // a use key was pressed; call handlers
2222         MUTATOR_CALLHOOK(PlayerUseKey, this);
2223 }
2224
2225
2226 /*
2227 =============
2228 PlayerPreThink
2229
2230 Called every frame for each client before the physics are run
2231 =============
2232 */
2233 .float usekeypressed;
2234 .float last_vehiclecheck;
2235 .int items_added;
2236 void PlayerPreThink (entity this)
2237 {
2238         WarpZone_PlayerPhysics_FixVAngle(this);
2239
2240     STAT(GAMESTARTTIME, this) = game_starttime;
2241         STAT(ROUNDSTARTTIME, this) = round_starttime;
2242         STAT(ALLOW_OLDVORTEXBEAM, this) = autocvar_g_allow_oldvortexbeam;
2243         STAT(LEADLIMIT, this) = autocvar_leadlimit;
2244
2245         STAT(WEAPONSINMAP, this) = weaponsInMap;
2246
2247         if (frametime) {
2248                 // physics frames: update anticheat stuff
2249                 anticheat_prethink(this);
2250         }
2251
2252         if (blockSpectators && frametime) {
2253                 // WORKAROUND: only use dropclient in server frames (frametime set).
2254                 // Never use it in cl_movement frames (frametime zero).
2255                 checkSpectatorBlock(this);
2256     }
2257
2258         zoomstate_set = false;
2259
2260         // Check for nameless players
2261         if (isInvisibleString(this.netname)) {
2262                 this.netname = strzone(sprintf("Player#%d", this.playerid));
2263                 // stuffcmd(this, strcat("name ", this.netname, "\n")); // maybe?
2264         }
2265         if (this.netname != this.netname_previous) {
2266                 if (autocvar_sv_eventlog) {
2267                         GameLogEcho(strcat(":name:", ftos(this.playerid), ":", playername(this, false)));
2268         }
2269                 if (this.netname_previous) strunzone(this.netname_previous);
2270                 this.netname_previous = strzone(this.netname);
2271         }
2272
2273         // version nagging
2274         if (this.version_nagtime && this.cvar_g_xonoticversion && time > this.version_nagtime) {
2275         this.version_nagtime = 0;
2276         if (strstrofs(this.cvar_g_xonoticversion, "git", 0) >= 0 || strstrofs(this.cvar_g_xonoticversion, "autobuild", 0) >= 0) {
2277             // git client
2278         } else if (strstrofs(autocvar_g_xonoticversion, "git", 0) >= 0 || strstrofs(autocvar_g_xonoticversion, "autobuild", 0) >= 0) {
2279             // git server
2280             Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_BETA, autocvar_g_xonoticversion, this.cvar_g_xonoticversion);
2281         } else {
2282             int r = vercmp(this.cvar_g_xonoticversion, autocvar_g_xonoticversion);
2283             if (r < 0) { // old client
2284                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_OUTDATED, autocvar_g_xonoticversion, this.cvar_g_xonoticversion);
2285             } else if (r > 0) { // old server
2286                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_OLD, autocvar_g_xonoticversion, this.cvar_g_xonoticversion);
2287             }
2288         }
2289     }
2290
2291         // GOD MODE info
2292         if (!(this.flags & FL_GODMODE) && this.max_armorvalue)
2293         {
2294                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_GODMODE_OFF, this.max_armorvalue);
2295                 this.max_armorvalue = 0;
2296         }
2297
2298         if (STAT(FROZEN, this) == 2)
2299         {
2300                 this.revive_progress = bound(0, this.revive_progress + frametime * this.revive_speed, 1);
2301                 this.health = max(1, this.revive_progress * start_health);
2302                 this.iceblock.alpha = bound(0.2, 1 - this.revive_progress, 1);
2303
2304                 if (this.revive_progress >= 1)
2305                         Unfreeze(this);
2306         }
2307         else if (STAT(FROZEN, this) == 3)
2308         {
2309                 this.revive_progress = bound(0, this.revive_progress - frametime * this.revive_speed, 1);
2310                 this.health = max(0, autocvar_g_nades_ice_health + (start_health-autocvar_g_nades_ice_health) * this.revive_progress );
2311
2312                 if (this.health < 1)
2313                 {
2314                         if (this.vehicle)
2315                                 vehicles_exit(this.vehicle, VHEF_RELEASE);
2316                         if(this.event_damage)
2317                                 this.event_damage(this, this, this.frozen_by, 1, DEATH_NADE_ICE_FREEZE.m_id, this.origin, '0 0 0');
2318                 }
2319                 else if (this.revive_progress <= 0)
2320                         Unfreeze(this);
2321         }
2322
2323         MUTATOR_CALLHOOK(PlayerPreThink, this);
2324
2325         if(autocvar_g_vehicles_enter && (time > this.last_vehiclecheck) && !game_stopped && !this.vehicle)
2326         if(IS_PLAYER(this) && !STAT(FROZEN, this) && !IS_DEAD(this))
2327         {
2328                 FOREACH_ENTITY_RADIUS(this.origin, autocvar_g_vehicles_enter_radius, IS_VEHICLE(it),
2329                 {
2330                         if(!IS_DEAD(it) && it.takedamage != DAMAGE_NO)
2331                         if((it.vehicle_flags & VHF_MULTISLOT) && SAME_TEAM(it.owner, this))
2332                         {
2333                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER_GUNNER);
2334                         }
2335                         else if(!it.owner)
2336                         {
2337                                 if(!it.team || SAME_TEAM(this, it))
2338                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER);
2339                                 else if(autocvar_g_vehicles_steal)
2340                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER_STEAL);
2341                         }
2342                 });
2343
2344                 this.last_vehiclecheck = time + 1;
2345         }
2346
2347         if(!this.cvar_cl_newusekeysupported) // FIXME remove this - it was a stupid idea to begin with, we can JUST use the button
2348         {
2349                 if(PHYS_INPUT_BUTTON_USE(this) && !this.usekeypressed)
2350                         PlayerUseKey(this);
2351                 this.usekeypressed = PHYS_INPUT_BUTTON_USE(this);
2352         }
2353
2354         if (IS_REAL_CLIENT(this))
2355                 PrintWelcomeMessage(this);
2356
2357         if (IS_PLAYER(this)) {
2358                 CheckRules_Player(this);
2359
2360                 if (game_stopped || intermission_running) {
2361                         this.modelflags &= ~MF_ROCKET;
2362                         if(intermission_running)
2363                                 IntermissionThink(this);
2364                         return;
2365                 }
2366
2367                 if (timeout_status == TIMEOUT_ACTIVE) {
2368             // don't allow the player to turn around while game is paused
2369                         // FIXME turn this into CSQC stuff
2370                         this.v_angle = this.lastV_angle;
2371                         this.angles = this.lastV_angle;
2372                         this.fixangle = true;
2373                 }
2374
2375                 if (frametime) player_powerups(this);
2376
2377                 if (IS_DEAD(this)) {
2378                         if (this.personal && g_race_qualifying) {
2379                                 if (time > this.respawn_time) {
2380                                         STAT(RESPAWN_TIME, this) = this.respawn_time = time + 1; // only retry once a second
2381                                         respawn(this);
2382                                         this.impulse = CHIMPULSE_SPEEDRUN.impulse;
2383                                 }
2384                         } else {
2385                                 if (frametime) player_anim(this);
2386
2387                                 if (this.respawn_flags & RESPAWN_DENY)
2388                                 {
2389                                         STAT(RESPAWN_TIME, this) = 0;
2390                                         return;
2391                                 }
2392
2393                                 bool button_pressed = (PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_JUMP(this) || PHYS_INPUT_BUTTON_ATCK2(this) || PHYS_INPUT_BUTTON_HOOK(this) || PHYS_INPUT_BUTTON_USE(this));
2394
2395                                 switch(this.deadflag)
2396                                 {
2397                                         case DEAD_DYING:
2398                                         {
2399                                                 if ((this.respawn_flags & RESPAWN_FORCE) && !(this.respawn_time < this.respawn_time_max))
2400                                                         this.deadflag = DEAD_RESPAWNING;
2401                                                 else if (!button_pressed || (time >= this.respawn_time_max && (this.respawn_flags & RESPAWN_FORCE)))
2402                                                         this.deadflag = DEAD_DEAD;
2403                                                 break;
2404                                         }
2405                                         case DEAD_DEAD:
2406                                         {
2407                                                 if (button_pressed)
2408                                                         this.deadflag = DEAD_RESPAWNABLE;
2409                                                 else if (time >= this.respawn_time_max && (this.respawn_flags & RESPAWN_FORCE))
2410                                                         this.deadflag = DEAD_RESPAWNING;
2411                                                 break;
2412                                         }
2413                                         case DEAD_RESPAWNABLE:
2414                                         {
2415                                                 if (!button_pressed || (this.respawn_flags & RESPAWN_FORCE))
2416                                                         this.deadflag = DEAD_RESPAWNING;
2417                                                 break;
2418                                         }
2419                                         case DEAD_RESPAWNING:
2420                                         {
2421                                                 if (time > this.respawn_time)
2422                                                 {
2423                                                         this.respawn_time = time + 1; // only retry once a second
2424                                                         this.respawn_time_max = this.respawn_time;
2425                                                         respawn(this);
2426                                                 }
2427                                                 break;
2428                                         }
2429                                 }
2430
2431                                 ShowRespawnCountdown(this);
2432
2433                                 if (this.respawn_flags & RESPAWN_SILENT)
2434                                         STAT(RESPAWN_TIME, this) = 0;
2435                                 else if ((this.respawn_flags & RESPAWN_FORCE) && this.respawn_time < this.respawn_time_max)
2436                                 {
2437                                         if (time < this.respawn_time)
2438                                                 STAT(RESPAWN_TIME, this) = this.respawn_time;
2439                                         else if (this.deadflag != DEAD_RESPAWNING)
2440                                                 STAT(RESPAWN_TIME, this) = -this.respawn_time_max;
2441                                 }
2442                                 else
2443                                         STAT(RESPAWN_TIME, this) = this.respawn_time;
2444                         }
2445
2446                         // if respawning, invert stat_respawn_time to indicate this, the client translates it
2447                         if (this.deadflag == DEAD_RESPAWNING && STAT(RESPAWN_TIME, this) > 0)
2448                                 STAT(RESPAWN_TIME, this) *= -1;
2449
2450                         return;
2451                 }
2452
2453                 this.prevorigin = this.origin;
2454
2455                 bool have_hook = false;
2456                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2457                 {
2458                         .entity weaponentity = weaponentities[slot];
2459                         if(this.(weaponentity).hook.state)
2460                         {
2461                                 have_hook = true;
2462                                 break;
2463                         }
2464                 }
2465                 bool do_crouch = PHYS_INPUT_BUTTON_CROUCH(this);
2466                 if (have_hook) {
2467                         do_crouch = false;
2468                 } else if (this.waterlevel >= WATERLEVEL_SWIMMING) {
2469                         do_crouch = false;
2470                 } else if (this.vehicle) {
2471                         do_crouch = false;
2472                 } else if (STAT(FROZEN, this)) {
2473                         do_crouch = false;
2474         }
2475
2476                 if (do_crouch) {
2477                         if (!this.crouch) {
2478                                 this.crouch = true;
2479                                 this.view_ofs = STAT(PL_CROUCH_VIEW_OFS, this);
2480                                 setsize(this, STAT(PL_CROUCH_MIN, this), STAT(PL_CROUCH_MAX, this));
2481                                 // setanim(this, this.anim_duck, false, true, true); // this anim is BROKEN anyway
2482                         }
2483                 } else if (this.crouch) {
2484             tracebox(this.origin, STAT(PL_MIN, this), STAT(PL_MAX, this), this.origin, false, this);
2485             if (!trace_startsolid) {
2486                 this.crouch = false;
2487                 this.view_ofs = STAT(PL_VIEW_OFS, this);
2488                 setsize(this, STAT(PL_MIN, this), STAT(PL_MAX, this));
2489             }
2490                 }
2491
2492                 FixPlayermodel(this);
2493
2494                 // LordHavoc: allow firing on move frames (sub-ticrate), this gives better timing on slow servers
2495                 //if(frametime)
2496                 {
2497                         this.items &= ~this.items_added;
2498
2499                         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2500                         {
2501                                 .entity weaponentity = weaponentities[slot];
2502                                 W_WeaponFrame(this, weaponentity);
2503
2504                                 if(slot == 0)
2505                                 {
2506                                         this.clip_load = this.(weaponentity).clip_load;
2507                                         this.clip_size = this.(weaponentity).clip_size;
2508                                 }
2509                         }
2510
2511                         this.items_added = 0;
2512                         if (this.items & ITEM_Jetpack.m_itemid && (this.items & ITEM_JetpackRegen.m_itemid || this.ammo_fuel >= 0.01))
2513                 this.items_added |= IT_FUEL;
2514
2515                         this.items |= this.items_added;
2516                 }
2517
2518                 player_regen(this);
2519
2520                 // WEAPONTODO: Add a weapon request for this
2521                 // rot vortex charge to the charge limit
2522                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2523                 {
2524                         .entity weaponentity = weaponentities[slot];
2525                         if (WEP_CVAR(vortex, charge_rot_rate) && this.(weaponentity).vortex_charge > WEP_CVAR(vortex, charge_limit) && this.(weaponentity).vortex_charge_rottime < time)
2526                                 this.(weaponentity).vortex_charge = bound(WEP_CVAR(vortex, charge_limit), this.(weaponentity).vortex_charge - WEP_CVAR(vortex, charge_rot_rate) * frametime / W_TICSPERFRAME, 1);
2527                 }
2528
2529                 if (frametime) player_anim(this);
2530
2531                 // secret status
2532                 secrets_setstatus(this);
2533
2534                 // monsters status
2535                 monsters_setstatus(this);
2536
2537                 this.dmg_team = max(0, this.dmg_team - autocvar_g_teamdamage_resetspeed * frametime);
2538         }
2539         else if (game_stopped || intermission_running) {
2540                 if(intermission_running)
2541                         IntermissionThink(this);
2542                 return;
2543         }
2544         else if (IS_OBSERVER(this)) {
2545                 ObserverThink(this);
2546         }
2547         else if (IS_SPEC(this)) {
2548                 SpectatorThink(this);
2549         }
2550
2551         // WEAPONTODO: Add weapon request for this
2552         if (!zoomstate_set) {
2553                 bool wep_zoomed = false;
2554                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2555                 {
2556                         .entity weaponentity = weaponentities[slot];
2557                         Weapon thiswep = this.(weaponentity).m_weapon;
2558                         if(thiswep != WEP_Null && thiswep.wr_zoom)
2559                                 wep_zoomed += thiswep.wr_zoom(thiswep, this);
2560                 }
2561                 SetZoomState(this, PHYS_INPUT_BUTTON_ZOOM(this) || PHYS_INPUT_BUTTON_ZOOMSCRIPT(this) || wep_zoomed);
2562     }
2563
2564         if (this.teamkill_soundtime && time > this.teamkill_soundtime)
2565         {
2566                 this.teamkill_soundtime = 0;
2567
2568                 entity e = this.teamkill_soundsource;
2569                 entity oldpusher = e.pusher;
2570                 e.pusher = this;
2571                 PlayerSound(e, playersound_teamshoot, CH_VOICE, VOL_BASEVOICE, VOICETYPE_LASTATTACKER_ONLY);
2572                 e.pusher = oldpusher;
2573         }
2574
2575         if (this.taunt_soundtime && time > this.taunt_soundtime) {
2576                 this.taunt_soundtime = 0;
2577                 PlayerSound(this, playersound_taunt, CH_VOICE, VOL_BASEVOICE, VOICETYPE_AUTOTAUNT);
2578         }
2579
2580         target_voicescript_next(this);
2581
2582         // WEAPONTODO: Move into weaponsystem somehow
2583         // if a player goes unarmed after holding a loaded weapon, empty his clip size and remove the crosshair ammo ring
2584         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2585         {
2586                 .entity weaponentity = weaponentities[slot];
2587                 if(this.(weaponentity).m_weapon == WEP_Null)
2588                         this.(weaponentity).clip_load = this.(weaponentity).clip_size = 0;
2589         }
2590 }
2591
2592 void DrownPlayer(entity this)
2593 {
2594         if(IS_DEAD(this))
2595                 return;
2596
2597         if (this.waterlevel != WATERLEVEL_SUBMERGED || this.vehicle)
2598         {
2599                 if(this.air_finished < time)
2600                         PlayerSound(this, playersound_gasp, CH_PLAYER, VOL_BASE, VOICETYPE_PLAYERSOUND);
2601                 this.air_finished = time + autocvar_g_balance_contents_drowndelay;
2602                 this.dmg = 2;
2603         }
2604         else if (this.air_finished < time)
2605         {       // drown!
2606                 if (this.pain_finished < time)
2607                 {
2608                         Damage (this, NULL, NULL, autocvar_g_balance_contents_playerdamage_drowning * autocvar_g_balance_contents_damagerate, DEATH_DROWN.m_id, this.origin, '0 0 0');
2609                         this.pain_finished = time + 0.5;
2610                 }
2611         }
2612 }
2613
2614 .bool move_qcphysics;
2615
2616 void Player_Physics(entity this)
2617 {
2618         set_movetype(this, this.move_movetype);
2619
2620         if(!this.move_qcphysics)
2621                 return;
2622
2623         if(!frametime && !this.pm_frametime)
2624                 return;
2625
2626         Movetype_Physics_NoMatchTicrate(this, this.pm_frametime, true);
2627
2628         this.pm_frametime = 0;
2629 }
2630
2631 /*
2632 =============
2633 PlayerPostThink
2634
2635 Called every frame for each client after the physics are run
2636 =============
2637 */
2638 .float idlekick_lasttimeleft;
2639 void PlayerPostThink (entity this)
2640 {
2641         Player_Physics(this);
2642
2643         if (sv_maxidle > 0)
2644         if (frametime) // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2645         if (IS_REAL_CLIENT(this))
2646         if (IS_PLAYER(this) || sv_maxidle_spectatorsareidle)
2647         {
2648                 int totalClients = 0;
2649                 if(sv_maxidle_slots > 0)
2650                 {
2651                         FOREACH_CLIENT(IS_REAL_CLIENT(it) || sv_maxidle_slots_countbots,
2652                         {
2653                                 ++totalClients;
2654                         });
2655                 }
2656
2657                 if (sv_maxidle_slots > 0 && (maxclients - totalClients) > sv_maxidle_slots)
2658                 { /* do nothing */ }
2659                 else if (time - this.parm_idlesince < 1) // instead of (time == this.parm_idlesince) to support sv_maxidle <= 10
2660                 {
2661                         if (this.idlekick_lasttimeleft)
2662                         {
2663                                 this.idlekick_lasttimeleft = 0;
2664                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_IDLING);
2665                         }
2666                 }
2667                 else
2668                 {
2669                         float timeleft = ceil(sv_maxidle - (time - this.parm_idlesince));
2670                         if (timeleft == min(10, sv_maxidle - 1)) { // - 1 to support sv_maxidle <= 10
2671                                 if (!this.idlekick_lasttimeleft)
2672                                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_DISCONNECT_IDLING, timeleft);
2673                         }
2674                         if (timeleft <= 0) {
2675                                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_QUIT_KICK_IDLING, this.netname);
2676                                 dropclient(this);
2677                                 return;
2678                         }
2679                         else if (timeleft <= 10) {
2680                                 if (timeleft != this.idlekick_lasttimeleft) {
2681                                     Send_Notification(NOTIF_ONE, this, MSG_ANNCE, Announcer_PickNumber(CNT_IDLE, timeleft));
2682                 }
2683                                 this.idlekick_lasttimeleft = timeleft;
2684                         }
2685                 }
2686         }
2687
2688         CheatFrame(this);
2689
2690         //CheckPlayerJump();
2691         if (game_stopped)
2692         {
2693                 this.solid = SOLID_NOT;
2694                 this.takedamage = DAMAGE_NO;
2695                 set_movetype(this, MOVETYPE_NONE);
2696         }
2697
2698         if (IS_PLAYER(this)) {
2699                 DrownPlayer(this);
2700                 CheckRules_Player(this);
2701                 UpdateChatBubble(this);
2702                 if (this.impulse) ImpulseCommands(this);
2703                 if (game_stopped)
2704                 {
2705                         CSQCMODEL_AUTOUPDATE(this);
2706                         return;
2707                 }
2708                 GetPressedKeys(this);
2709         }
2710
2711         if (this.waypointsprite_attachedforcarrier) {
2712             vector v = healtharmor_maxdamage(this.health, this.armorvalue, autocvar_g_balance_armor_blockpercent, DEATH_WEAPON.m_id);
2713                 WaypointSprite_UpdateHealth(this.waypointsprite_attachedforcarrier, '1 0 0' * v);
2714     }
2715
2716         playerdemo_write(this);
2717
2718         CSQCMODEL_AUTOUPDATE(this);
2719 }