qcsrc/server/client.qc

   1 #include "client.qh"
   2
   3 #include <server/defs.qh>
   4 #include <server/miscfunctions.qh>
   5 #include <common/effects/all.qh>
   6 #include "anticheat.qh"
   7 #include "impulse.qh"
   8 #include "player.qh"
   9 #include "ipban.qh"
  10 #include "miscfunctions.qh"
  11 #include "portals.qh"
  12 #include "teamplay.qh"
  13 #include "spawnpoints.qh"
  14 #include "resources.qh"
  15 #include "g_damage.qh"
  16 #include "handicap.qh"
  17 #include "g_hook.qh"
  18 #include "command/common.qh"
  19 #include "command/vote.qh"
  20 #include "clientkill.qh"
  21 #include "cheats.qh"
  22 #include "g_world.qh"
  23 #include "race.qh"
  24 #include "antilag.qh"
  25 #include "campaign.qh"
  26 #include "command/common.qh"
  27 #include "scores_rules.qh"
  28
  29 #include "bot/api.qh"
  30
  31 #include "../common/ent_cs.qh"
  32 #include "../common/wepent.qh"
  33 #include <common/state.qh>
  34
  35 #include "compat/quake3.qh"
  36
  37 #include <common/effects/qc/globalsound.qh>
  38
  39 #include "../common/mapobjects/func/conveyor.qh"
  40 #include "../common/mapobjects/teleporters.qh"
  41 #include "../common/mapobjects/target/spawnpoint.qh"
  42 #include <common/mapobjects/trigger/counter.qh>
  43
  44 #include "../common/vehicles/all.qh"
  45
  46 #include "weapons/hitplot.qh"
  47 #include "weapons/weaponsystem.qh"
  48
  49 #include "../common/net_notice.qh"
  50 #include "../common/net_linked.qh"
  51 #include "../common/physics/player.qh"
  52
  53 #include <common/vehicles/sv_vehicles.qh>
  54
  55 #include "../common/items/_mod.qh"
  56
  57 #include "../common/mutators/mutator/waypoints/all.qh"
  58 #include "../common/mutators/mutator/instagib/sv_instagib.qh"
  59 #include <common/gamemodes/_mod.qh>
  60
  61 #include "../common/mapobjects/subs.qh"
  62 #include "../common/mapobjects/triggers.qh"
  63 #include "../common/mapobjects/trigger/secret.qh"
  64
  65 #include "../common/minigames/sv_minigames.qh"
  66
  67 #include "../common/items/inventory.qh"
  68
  69 #include "../common/monsters/sv_monsters.qh"
  70
  71 #include "../lib/warpzone/server.qh"
  72
  73 #include <common/mutators/mutator/overkill/oknex.qh>
  74
  75 STATIC_METHOD(Client, Add, void(Client this, int _team))
  76 {
  77     ClientConnect(this);
  78     TRANSMUTE(Player, this);
  79     this.frame = 12; // 7
  80     this.team = _team;
  81     PutClientInServer(this);
  82 }
  83
  84 STATIC_METHOD(Client, Remove, void(Client this))
  85 {
  86     TRANSMUTE(Observer, this);
  87     PutClientInServer(this);
  88     ClientDisconnect(this);
  89 }
  90
  91 void send_CSQC_teamnagger() {
  92         WriteHeader(MSG_BROADCAST, TE_CSQC_TEAMNAGGER);
  93 }
  94
  95 int CountSpectators(entity player, entity to)
  96 {
  97         if(!player) { return 0; } // not sure how, but best to be safe
  98
  99         int spec_count = 0;
 100
 101         FOREACH_CLIENT(IS_REAL_CLIENT(it) && IS_SPEC(it) && it != to && it.enemy == player,
 102         {
 103                 spec_count++;
 104         });
 105
 106         return spec_count;
 107 }
 108
 109 void WriteSpectators(entity player, entity to)
 110 {
 111         if(!player) { return; } // not sure how, but best to be safe
 112
 113         FOREACH_CLIENT(IS_REAL_CLIENT(it) && IS_SPEC(it) && it != to && it.enemy == player,
 114         {
 115                 WriteByte(MSG_ENTITY, num_for_edict(it));
 116         });
 117 }
 118
 119 bool ClientData_Send(entity this, entity to, int sf)
 120 {
 121         assert(to == this.owner, return false);
 122
 123         entity e = to;
 124         if (IS_SPEC(e)) e = e.enemy;
 125
 126         sf = 0;
 127         if (CS(e).race_completed)       sf |= BIT(0); // forced scoreboard
 128         if (CS(to).spectatee_status)    sf |= BIT(1); // spectator ent number follows
 129         if (CS(e).zoomstate)            sf |= BIT(2); // zoomed
 130         if (autocvar_sv_showspectators) sf |= BIT(4); // show spectators
 131
 132         WriteHeader(MSG_ENTITY, ENT_CLIENT_CLIENTDATA);
 133         WriteByte(MSG_ENTITY, sf);
 134
 135         if (sf & BIT(1))
 136                 WriteByte(MSG_ENTITY, CS(to).spectatee_status);
 137
 138         if(sf & BIT(4))
 139         {
 140                 float specs = CountSpectators(e, to);
 141                 WriteByte(MSG_ENTITY, specs);
 142                 WriteSpectators(e, to);
 143         }
 144
 145         return true;
 146 }
 147
 148 void ClientData_Attach(entity this)
 149 {
 150         Net_LinkEntity(CS(this).clientdata = new_pure(clientdata), false, 0, ClientData_Send);
 151         CS(this).clientdata.drawonlytoclient = this;
 152         CS(this).clientdata.owner = this;
 153 }
 154
 155 void ClientData_Detach(entity this)
 156 {
 157         delete(CS(this).clientdata);
 158         CS(this).clientdata = NULL;
 159 }
 160
 161 void ClientData_Touch(entity e)
 162 {
 163         entity cd = CS(e).clientdata;
 164         if (cd) { cd.SendFlags = 1; }
 165
 166         // make it spectatable
 167         FOREACH_CLIENT(IS_REAL_CLIENT(it) && it != e && IS_SPEC(it) && it.enemy == e,
 168         {
 169                 entity cd = CS(it).clientdata;
 170                 if (cd) { cd.SendFlags = 1; }
 171         });
 172 }
 173
 174
 175 /*
 176 =============
 177 CheckPlayerModel
 178
 179 Checks if the argument string can be a valid playermodel.
 180 Returns a valid one in doubt.
 181 =============
 182 */
 183 string FallbackPlayerModel;
 184 string CheckPlayerModel(string plyermodel) {
 185         if(FallbackPlayerModel != cvar_defstring("_cl_playermodel"))
 186         {
 187                 // note: we cannot summon Don Strunzone here, some player may
 188                 // still have the model string set. In case anyone manages how
 189                 // to change a cvar default, we'll have a small leak here.
 190                 FallbackPlayerModel = strzone(cvar_defstring("_cl_playermodel"));
 191         }
 192         // only in right path
 193         if( substring(plyermodel,0,14) != "models/player/")
 194                 return FallbackPlayerModel;
 195         // only good file extensions
 196         if(substring(plyermodel,-4,4) != ".zym")
 197         if(substring(plyermodel,-4,4) != ".dpm")
 198         if(substring(plyermodel,-4,4) != ".iqm")
 199         if(substring(plyermodel,-4,4) != ".md3")
 200         if(substring(plyermodel,-4,4) != ".psk")
 201                 return FallbackPlayerModel;
 202         // forbid the LOD models
 203         if(substring(plyermodel, -9,5) == "_lod1")
 204                 return FallbackPlayerModel;
 205         if(substring(plyermodel, -9,5) == "_lod2")
 206                 return FallbackPlayerModel;
 207         if(plyermodel != strtolower(plyermodel))
 208                 return FallbackPlayerModel;
 209         // also, restrict to server models
 210         if(autocvar_sv_servermodelsonly)
 211         {
 212                 if(!fexists(plyermodel))
 213                         return FallbackPlayerModel;
 214         }
 215         return plyermodel;
 216 }
 217
 218 void setplayermodel(entity e, string modelname)
 219 {
 220         precache_model(modelname);
 221         _setmodel(e, modelname);
 222         player_setupanimsformodel(e);
 223         if(!autocvar_g_debug_globalsounds)
 224                 UpdatePlayerSounds(e);
 225 }
 226
 227 /** putting a client as observer in the server */
 228 void PutObserverInServer(entity this)
 229 {
 230     bool mutator_returnvalue = MUTATOR_CALLHOOK(MakePlayerObserver, this);
 231         PlayerState_detach(this);
 232
 233         if (IS_PLAYER(this))
 234         {
 235                 if(GetResourceAmount(this, RESOURCE_HEALTH) >= 1)
 236                 {
 237                         // despawn effect
 238                         Send_Effect(EFFECT_SPAWN_NEUTRAL, this.origin, '0 0 0', 1);
 239                 }
 240
 241                 // was a player, recount votes and ready status
 242                 if(IS_REAL_CLIENT(this))
 243                 {
 244                         if (vote_called) { VoteCount(false); }
 245                         ReadyCount();
 246                 }
 247     }
 248
 249     {
 250         entity spot = SelectSpawnPoint(this, true);
 251         if (!spot) LOG_FATAL("No spawnpoints for observers?!?");
 252         this.angles = vec2(spot.angles);
 253         this.fixangle = true;
 254         // offset it so that the spectator spawns higher off the ground, looks better this way
 255         setorigin(this, spot.origin + STAT(PL_VIEW_OFS, this));
 256         if (IS_REAL_CLIENT(this))
 257         {
 258             msg_entity = this;
 259             WriteByte(MSG_ONE, SVC_SETVIEW);
 260             WriteEntity(MSG_ONE, this);
 261         }
 262         // give the spectator some space between walls for MOVETYPE_FLY_WORLDONLY
 263         // so that your view doesn't go into the ceiling with MOVETYPE_FLY_WORLDONLY, previously "PL_VIEW_OFS"
 264         if(!autocvar_g_debug_globalsounds)
 265         {
 266                 // needed for player sounds
 267                 this.model = "";
 268                 FixPlayermodel(this);
 269         }
 270         setmodel(this, MDL_Null);
 271         setsize(this, STAT(PL_CROUCH_MIN, this), STAT(PL_CROUCH_MAX, this));
 272         this.view_ofs = '0 0 0';
 273     }
 274
 275     RemoveGrapplingHooks(this);
 276         Portal_ClearAll(this);
 277         Unfreeze(this, false);
 278         SetSpectatee(this, NULL);
 279
 280         if (this.alivetime)
 281         {
 282                 if (!warmup_stage)
 283                         PlayerStats_GameReport_Event_Player(this, PLAYERSTATS_ALIVETIME, time - this.alivetime);
 284                 this.alivetime = 0;
 285         }
 286
 287         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
 288
 289         WaypointSprite_PlayerDead(this);
 290
 291         if (CS(this).killcount != FRAGS_SPECTATOR)
 292         {
 293                 if(!game_stopped)
 294                 if(autocvar_g_chat_nospectators == 1 || (!warmup_stage && autocvar_g_chat_nospectators == 2))
 295                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_CHAT_NOSPECTATORS);
 296         }
 297
 298         accuracy_resend(this);
 299
 300         CS(this).spectatortime = time;
 301         if(this.bot_attack)
 302                 IL_REMOVE(g_bot_targets, this);
 303         this.bot_attack = false;
 304         if(this.monster_attack)
 305                 IL_REMOVE(g_monster_targets, this);
 306         this.monster_attack = false;
 307     STAT(HUD, this) = HUD_NORMAL;
 308         TRANSMUTE(Observer, this);
 309         this.iscreature = false;
 310         this.teleportable = TELEPORT_SIMPLE;
 311         if(this.damagedbycontents)
 312                 IL_REMOVE(g_damagedbycontents, this);
 313         this.damagedbycontents = false;
 314         SetResourceAmountExplicit(this, RESOURCE_HEALTH, FRAGS_SPECTATOR);
 315         SetSpectatee_status(this, etof(this));
 316         this.takedamage = DAMAGE_NO;
 317         this.solid = SOLID_NOT;
 318         set_movetype(this, MOVETYPE_FLY_WORLDONLY); // user preference is controlled by playerprethink
 319         this.flags = FL_CLIENT | FL_NOTARGET;
 320         this.effects = 0;
 321         SetResourceAmountExplicit(this, RESOURCE_ARMOR, autocvar_g_balance_armor_start); // was 666?!
 322         this.pauserotarmor_finished = 0;
 323         this.pauserothealth_finished = 0;
 324         this.pauseregen_finished = 0;
 325         this.damageforcescale = 0;
 326         this.death_time = 0;
 327         this.respawn_flags = 0;
 328         this.respawn_time = 0;
 329         STAT(RESPAWN_TIME, this) = 0;
 330         this.alpha = 0;
 331         this.scale = 0;
 332         this.fade_time = 0;
 333         this.pain_frame = 0;
 334         this.pain_finished = 0;
 335         this.strength_finished = 0;
 336         this.invincible_finished = 0;
 337         this.superweapons_finished = 0;
 338         //this.dphitcontentsmask = 0;
 339         this.dphitcontentsmask = DPCONTENTS_SOLID;
 340         if (autocvar_g_playerclip_collisions)
 341                 this.dphitcontentsmask |= DPCONTENTS_PLAYERCLIP;
 342         this.pushltime = 0;
 343         this.istypefrag = 0;
 344         setthink(this, func_null);
 345         this.nextthink = 0;
 346         this.deadflag = DEAD_NO;
 347         this.crouch = false;
 348         STAT(REVIVE_PROGRESS, this) = 0;
 349         this.revival_time = 0;
 350         this.draggable = drag_undraggable;
 351
 352         this.items = 0;
 353         STAT(WEAPONS, this) = '0 0 0';
 354         this.drawonlytoclient = this;
 355
 356         this.viewloc = NULL;
 357
 358         //this.spawnpoint_targ = NULL; // keep it so they can return to where they were?
 359
 360         this.weaponmodel = "";
 361         for (int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 362         {
 363                 this.weaponentities[slot] = NULL;
 364         }
 365         this.exteriorweaponentity = NULL;
 366         CS(this).killcount = FRAGS_SPECTATOR;
 367         this.velocity = '0 0 0';
 368         this.avelocity = '0 0 0';
 369         this.punchangle = '0 0 0';
 370         this.punchvector = '0 0 0';
 371         this.oldvelocity = this.velocity;
 372         this.fire_endtime = -1;
 373         this.event_damage = func_null;
 374         this.event_heal = func_null;
 375
 376         for(int slot = 0; slot < MAX_AXH; ++slot)
 377         {
 378                 entity axh = this.(AuxiliaryXhair[slot]);
 379                 this.(AuxiliaryXhair[slot]) = NULL;
 380
 381                 if(axh.owner == this && axh != NULL && !wasfreed(axh))
 382                         delete(axh);
 383         }
 384
 385         if (mutator_returnvalue)
 386         {
 387                 // mutator prevents resetting teams+score
 388         }
 389         else
 390         {
 391                 SetPlayerTeam(this, -1, TEAM_CHANGE_SPECTATOR);
 392                 this.frags = FRAGS_SPECTATOR;
 393     }
 394 }
 395
 396 int player_getspecies(entity this)
 397 {
 398         get_model_parameters(this.model, this.skin);
 399         int s = get_model_parameters_species;
 400         get_model_parameters(string_null, 0);
 401         if (s < 0) return SPECIES_HUMAN;
 402         return s;
 403 }
 404
 405 .float model_randomizer;
 406 void FixPlayermodel(entity player)
 407 {
 408         string defaultmodel = "";
 409         int defaultskin = 0;
 410         if(autocvar_sv_defaultcharacter)
 411         {
 412                 if(teamplay)
 413                 {
 414                         switch(player.team)
 415                         {
 416                                 case NUM_TEAM_1: defaultmodel = autocvar_sv_defaultplayermodel_red; defaultskin = autocvar_sv_defaultplayerskin_red; break;
 417                                 case NUM_TEAM_2: defaultmodel = autocvar_sv_defaultplayermodel_blue; defaultskin = autocvar_sv_defaultplayerskin_blue; break;
 418                                 case NUM_TEAM_3: defaultmodel = autocvar_sv_defaultplayermodel_yellow; defaultskin = autocvar_sv_defaultplayerskin_yellow; break;
 419                                 case NUM_TEAM_4: defaultmodel = autocvar_sv_defaultplayermodel_pink; defaultskin = autocvar_sv_defaultplayerskin_pink; break;
 420                         }
 421                 }
 422
 423                 if(defaultmodel == "")
 424                 {
 425                         defaultmodel = autocvar_sv_defaultplayermodel;
 426                         defaultskin = autocvar_sv_defaultplayerskin;
 427                 }
 428
 429                 int n = tokenize_console(defaultmodel);
 430                 if(n > 0)
 431                 {
 432                         defaultmodel = argv(floor(n * CS(player).model_randomizer));
 433                         // However, do NOT randomize if the player-selected model is in the list.
 434                         for (int i = 0; i < n; ++i)
 435                                 if ((argv(i) == player.playermodel && defaultskin == stof(player.playerskin)) || argv(i) == strcat(player.playermodel, ":", player.playerskin))
 436                                         defaultmodel = argv(i);
 437                 }
 438
 439                 int i = strstrofs(defaultmodel, ":", 0);
 440                 if(i >= 0)
 441                 {
 442                         defaultskin = stof(substring(defaultmodel, i+1, -1));
 443                         defaultmodel = substring(defaultmodel, 0, i);
 444                 }
 445         }
 446         if(autocvar_sv_defaultcharacterskin && !defaultskin)
 447         {
 448                 if(teamplay)
 449                 {
 450                         switch(player.team)
 451                         {
 452                                 case NUM_TEAM_1: defaultskin = autocvar_sv_defaultplayerskin_red; break;
 453                                 case NUM_TEAM_2: defaultskin = autocvar_sv_defaultplayerskin_blue; break;
 454                                 case NUM_TEAM_3: defaultskin = autocvar_sv_defaultplayerskin_yellow; break;
 455                                 case NUM_TEAM_4: defaultskin = autocvar_sv_defaultplayerskin_pink; break;
 456                         }
 457                 }
 458
 459                 if(!defaultskin)
 460                         defaultskin = autocvar_sv_defaultplayerskin;
 461         }
 462
 463         MUTATOR_CALLHOOK(FixPlayermodel, defaultmodel, defaultskin, player);
 464         defaultmodel = M_ARGV(0, string);
 465         defaultskin = M_ARGV(1, int);
 466
 467         bool chmdl = false;
 468         int oldskin;
 469         if(defaultmodel != "")
 470         {
 471                 if (defaultmodel != player.model)
 472                 {
 473                         vector m1 = player.mins;
 474                         vector m2 = player.maxs;
 475                         setplayermodel (player, defaultmodel);
 476                         setsize (player, m1, m2);
 477                         chmdl = true;
 478                 }
 479
 480                 oldskin = player.skin;
 481                 player.skin = defaultskin;
 482         } else {
 483                 if (player.playermodel != player.model || player.playermodel == "")
 484                 {
 485                         player.playermodel = CheckPlayerModel(player.playermodel); // this is never "", so no endless loop
 486                         vector m1 = player.mins;
 487                         vector m2 = player.maxs;
 488                         setplayermodel (player, player.playermodel);
 489                         setsize (player, m1, m2);
 490                         chmdl = true;
 491                 }
 492
 493                 if(!autocvar_sv_defaultcharacterskin)
 494                 {
 495                         oldskin = player.skin;
 496                         player.skin = stof(player.playerskin);
 497                 }
 498                 else
 499                 {
 500                         oldskin = player.skin;
 501                         player.skin = defaultskin;
 502                 }
 503         }
 504
 505         if(chmdl || oldskin != player.skin) // model or skin has changed
 506         {
 507                 player.species = player_getspecies(player); // update species
 508                 if(!autocvar_g_debug_globalsounds)
 509                         UpdatePlayerSounds(player); // update skin sounds
 510         }
 511
 512         if(!teamplay)
 513                 if(strlen(autocvar_sv_defaultplayercolors))
 514                         if(player.clientcolors != stof(autocvar_sv_defaultplayercolors))
 515                                 setcolor(player, stof(autocvar_sv_defaultplayercolors));
 516 }
 517
 518 void PutPlayerInServer(entity this)
 519 {
 520         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
 521
 522         PlayerState_attach(this);
 523         accuracy_resend(this);
 524
 525         if (this.team < 0)
 526                 TeamBalance_JoinBestTeam(this);
 527
 528         entity spot = SelectSpawnPoint(this, false);
 529         if (!spot) {
 530                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_JOIN_NOSPAWNS);
 531                 return; // spawn failed
 532         }
 533
 534         TRANSMUTE(Player, this);
 535
 536         CS(this).wasplayer = true;
 537         this.iscreature = true;
 538         this.teleportable = TELEPORT_NORMAL;
 539         if(!this.damagedbycontents)
 540                 IL_PUSH(g_damagedbycontents, this);
 541         this.damagedbycontents = true;
 542         set_movetype(this, MOVETYPE_WALK);
 543         this.solid = SOLID_SLIDEBOX;
 544         this.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_SOLID;
 545         if (autocvar_g_playerclip_collisions)
 546                 this.dphitcontentsmask |= DPCONTENTS_PLAYERCLIP;
 547         if (IS_BOT_CLIENT(this) && autocvar_g_botclip_collisions)
 548                 this.dphitcontentsmask |= DPCONTENTS_BOTCLIP;
 549         this.frags = FRAGS_PLAYER;
 550         if (INDEPENDENT_PLAYERS) MAKE_INDEPENDENT_PLAYER(this);
 551         this.flags = FL_CLIENT | FL_PICKUPITEMS;
 552         if (autocvar__notarget)
 553                 this.flags |= FL_NOTARGET;
 554         this.takedamage = DAMAGE_AIM;
 555         this.effects = EF_TELEPORT_BIT | EF_RESTARTANIM_BIT;
 556
 557         if (warmup_stage) {
 558                 SetResourceAmount(this, RESOURCE_SHELLS, warmup_start_ammo_shells);
 559                 SetResourceAmount(this, RESOURCE_BULLETS, warmup_start_ammo_nails);
 560                 SetResourceAmount(this, RESOURCE_ROCKETS, warmup_start_ammo_rockets);
 561                 SetResourceAmount(this, RESOURCE_CELLS, warmup_start_ammo_cells);
 562                 SetResourceAmount(this, RESOURCE_PLASMA, warmup_start_ammo_plasma);
 563                 SetResourceAmount(this, RESOURCE_FUEL, warmup_start_ammo_fuel);
 564                 SetResourceAmount(this, RESOURCE_HEALTH, warmup_start_health);
 565                 SetResourceAmount(this, RESOURCE_ARMOR, warmup_start_armorvalue);
 566                 STAT(WEAPONS, this) = WARMUP_START_WEAPONS;
 567         } else {
 568                 SetResourceAmount(this, RESOURCE_SHELLS, start_ammo_shells);
 569                 SetResourceAmount(this, RESOURCE_BULLETS, start_ammo_nails);
 570                 SetResourceAmount(this, RESOURCE_ROCKETS, start_ammo_rockets);
 571                 SetResourceAmount(this, RESOURCE_CELLS, start_ammo_cells);
 572                 SetResourceAmount(this, RESOURCE_PLASMA, start_ammo_plasma);
 573                 SetResourceAmount(this, RESOURCE_FUEL, start_ammo_fuel);
 574                 SetResourceAmount(this, RESOURCE_HEALTH, start_health);
 575                 SetResourceAmount(this, RESOURCE_ARMOR, start_armorvalue);
 576                 STAT(WEAPONS, this) = start_weapons;
 577                 if (MUTATOR_CALLHOOK(ForbidRandomStartWeapons, this) == false)
 578                 {
 579                         GiveRandomWeapons(this, random_start_weapons_count,
 580                                 autocvar_g_random_start_weapons, random_start_ammo);
 581                 }
 582         }
 583         SetSpectatee_status(this, 0);
 584
 585         PS(this).dual_weapons = '0 0 0';
 586
 587         this.superweapons_finished = (STAT(WEAPONS, this) & WEPSET_SUPERWEAPONS) ? time + autocvar_g_balance_superweapons_time : 0;
 588
 589         this.items = start_items;
 590
 591         this.spawnshieldtime = time + autocvar_g_spawnshieldtime;
 592         this.pauserotarmor_finished = time + autocvar_g_balance_pause_armor_rot_spawn;
 593         this.pauserothealth_finished = time + autocvar_g_balance_pause_health_rot_spawn;
 594         this.pauserotfuel_finished = time + autocvar_g_balance_pause_fuel_rot_spawn;
 595         this.pauseregen_finished = time + autocvar_g_balance_pause_health_regen_spawn;
 596         if (!sv_ready_restart_after_countdown && time < game_starttime)
 597         {
 598                 float f = game_starttime - time;
 599                 this.spawnshieldtime += f;
 600                 this.pauserotarmor_finished += f;
 601                 this.pauserothealth_finished += f;
 602                 this.pauseregen_finished += f;
 603         }
 604
 605         this.damageforcescale = 2;
 606         this.death_time = 0;
 607         this.respawn_flags = 0;
 608         this.respawn_time = 0;
 609         STAT(RESPAWN_TIME, this) = 0;
 610         this.scale = autocvar_sv_player_scale;
 611         this.fade_time = 0;
 612         this.pain_frame = 0;
 613         this.pain_finished = 0;
 614         this.pushltime = 0;
 615         setthink(this, func_null); // players have no think function
 616         this.nextthink = 0;
 617         this.dmg_team = 0;
 618         PS(this).ballistics_density = autocvar_g_ballistics_density_player;
 619
 620         this.deadflag = DEAD_NO;
 621
 622         this.angles = spot.angles;
 623         this.angles_z = 0; // never spawn tilted even if the spot says to
 624         if (IS_BOT_CLIENT(this))
 625                 this.v_angle = this.angles;
 626         this.fixangle = true; // turn this way immediately
 627         this.oldvelocity = this.velocity = '0 0 0';
 628         this.avelocity = '0 0 0';
 629         this.punchangle = '0 0 0';
 630         this.punchvector = '0 0 0';
 631
 632         this.strength_finished = 0;
 633         this.invincible_finished = 0;
 634         this.fire_endtime = -1;
 635         STAT(REVIVE_PROGRESS, this) = 0;
 636         this.revival_time = 0;
 637
 638         this.air_finished = time + 12;
 639         this.waterlevel = WATERLEVEL_NONE;
 640         this.watertype = CONTENT_EMPTY;
 641
 642         entity spawnevent = new_pure(spawnevent);
 643         spawnevent.owner = this;
 644         Net_LinkEntity(spawnevent, false, 0.5, SpawnEvent_Send);
 645
 646         // Cut off any still running player sounds.
 647         stopsound(this, CH_PLAYER_SINGLE);
 648
 649         this.model = "";
 650         FixPlayermodel(this);
 651         this.drawonlytoclient = NULL;
 652
 653         this.viewloc = NULL;
 654
 655         for(int slot = 0; slot < MAX_AXH; ++slot)
 656         {
 657                 entity axh = this.(AuxiliaryXhair[slot]);
 658                 this.(AuxiliaryXhair[slot]) = NULL;
 659
 660                 if(axh.owner == this && axh != NULL && !wasfreed(axh))
 661                         delete(axh);
 662         }
 663
 664         this.spawnpoint_targ = NULL;
 665
 666         this.crouch = false;
 667         this.view_ofs = STAT(PL_VIEW_OFS, this);
 668         setsize(this, STAT(PL_MIN, this), STAT(PL_MAX, this));
 669         this.spawnorigin = spot.origin;
 670         setorigin(this, spot.origin + '0 0 1' * (1 - this.mins.z - 24));
 671         // don't reset back to last position, even if new position is stuck in solid
 672         this.oldorigin = this.origin;
 673         if(this.conveyor)
 674                 IL_REMOVE(g_conveyed, this);
 675         this.conveyor = NULL; // prevent conveyors at the previous location from moving a freshly spawned player
 676         STAT(HUD, this) = HUD_NORMAL;
 677
 678         this.event_damage = PlayerDamage;
 679         this.event_heal = PlayerHeal;
 680
 681         this.draggable = func_null;
 682
 683         if(!this.bot_attack)
 684                 IL_PUSH(g_bot_targets, this);
 685         this.bot_attack = true;
 686         if(!this.monster_attack)
 687                 IL_PUSH(g_monster_targets, this);
 688         this.monster_attack = true;
 689         navigation_dynamicgoal_init(this, false);
 690
 691         PHYS_INPUT_BUTTON_ATCK(this) = PHYS_INPUT_BUTTON_JUMP(this) = PHYS_INPUT_BUTTON_ATCK2(this) = false;
 692
 693         // player was spectator
 694         if (CS(this).killcount == FRAGS_SPECTATOR) {
 695                 PlayerScore_Clear(this);
 696                 CS(this).killcount = 0;
 697                 CS(this).startplaytime = time;
 698         }
 699
 700         for (int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 701         {
 702                 .entity weaponentity = weaponentities[slot];
 703                 entity oldwep = this.(weaponentity);
 704                 CL_SpawnWeaponentity(this, weaponentity);
 705                 if(oldwep && oldwep.owner == this)
 706                         this.(weaponentity).m_gunalign = oldwep.m_gunalign;
 707         }
 708         this.alpha = default_player_alpha;
 709         this.colormod = '1 1 1' * autocvar_g_player_brightness;
 710         this.exteriorweaponentity.alpha = default_weapon_alpha;
 711
 712         this.speedrunning = false;
 713
 714         this.counter_cnt = 0;
 715         this.fragsfilter_cnt = 0;
 716
 717         target_voicescript_clear(this);
 718
 719         // reset fields the weapons may use
 720         FOREACH(Weapons, true, {
 721                 it.wr_resetplayer(it, this);
 722                         // reload all reloadable weapons
 723                 if (it.spawnflags & WEP_FLAG_RELOADABLE) {
 724                         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 725                         {
 726                                 .entity weaponentity = weaponentities[slot];
 727                                 this.(weaponentity).weapon_load[it.m_id] = it.reloading_ammo;
 728                         }
 729                 }
 730         });
 731
 732         {
 733                 //string s = spot.target;
 734                 //spot.target = string_null;
 735                 SUB_UseTargets(spot, this, NULL);
 736                 //spot.target = s;
 737         }
 738
 739         Unfreeze(this, false);
 740
 741         MUTATOR_CALLHOOK(PlayerSpawn, this, spot);
 742
 743         if (autocvar_spawn_debug)
 744         {
 745                 sprint(this, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
 746                 delete(spot); // usefull for checking if there are spawnpoints, that let drop through the floor
 747         }
 748
 749         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 750         {
 751                 .entity weaponentity = weaponentities[slot];
 752                 if(slot == 0 || autocvar_g_weaponswitch_debug == 1)
 753                         this.(weaponentity).m_switchweapon = w_getbestweapon(this, weaponentity);
 754                 else
 755                         this.(weaponentity).m_switchweapon = WEP_Null;
 756                 this.(weaponentity).m_weapon = WEP_Null;
 757                 this.(weaponentity).weaponname = "";
 758                 this.(weaponentity).m_switchingweapon = WEP_Null;
 759                 this.(weaponentity).cnt = -1;
 760         }
 761
 762         MUTATOR_CALLHOOK(PlayerWeaponSelect, this);
 763
 764         if (CS(this).impulse) ImpulseCommands(this);
 765
 766         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 767         {
 768                 .entity weaponentity = weaponentities[slot];
 769                 W_WeaponFrame(this, weaponentity);
 770         }
 771
 772         if (!warmup_stage && !this.alivetime)
 773                 this.alivetime = time;
 774
 775         antilag_clear(this, CS(this));
 776 }
 777
 778 /** Called when a client spawns in the server */
 779 void PutClientInServer(entity this)
 780 {
 781         if (IS_BOT_CLIENT(this)) {
 782                 TRANSMUTE(Player, this);
 783         } else if (IS_REAL_CLIENT(this)) {
 784                 msg_entity = this;
 785                 WriteByte(MSG_ONE, SVC_SETVIEW);
 786                 WriteEntity(MSG_ONE, this);
 787         }
 788         if (game_stopped)
 789                 TRANSMUTE(Observer, this);
 790
 791         SetSpectatee(this, NULL);
 792
 793         // reset player keys
 794         if(PS(this))
 795                 PS(this).itemkeys = 0;
 796
 797         MUTATOR_CALLHOOK(PutClientInServer, this);
 798
 799         if (IS_OBSERVER(this)) {
 800                 PutObserverInServer(this);
 801         } else if (IS_PLAYER(this)) {
 802                 PutPlayerInServer(this);
 803         }
 804 }
 805
 806 // TODO do we need all these fields, or should we stop autodetecting runtime
 807 // changes and just have a console command to update this?
 808 bool ClientInit_SendEntity(entity this, entity to, int sf)
 809 {
 810         WriteHeader(MSG_ENTITY, _ENT_CLIENT_INIT);
 811         return = true;
 812         msg_entity = to;
 813         // MSG_INIT replacement
 814         // TODO: make easier to use
 815         Registry_send_all();
 816         W_PROP_reload(MSG_ONE, to);
 817         ClientInit_misc(this);
 818         MUTATOR_CALLHOOK(Ent_Init);
 819 }
 820 void ClientInit_misc(entity this)
 821 {
 822         int channel = MSG_ONE;
 823         WriteHeader(channel, ENT_CLIENT_INIT);
 824         WriteByte(channel, g_nexball_meter_period * 32);
 825         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[0]));
 826         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[1]));
 827         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[2]));
 828         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[3]));
 829         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[0]));
 830         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[1]));
 831         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[2]));
 832         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[3]));
 833
 834         if(sv_foginterval && world.fog != "")
 835                 WriteString(channel, world.fog);
 836         else
 837                 WriteString(channel, "");
 838         WriteByte(channel, this.count * 255.0); // g_balance_armor_blockpercent
 839         WriteByte(channel, this.cnt * 255.0); // g_balance_damagepush_speedfactor
 840         WriteByte(channel, serverflags);
 841         WriteCoord(channel, autocvar_g_trueaim_minrange);
 842 }
 843
 844 void ClientInit_CheckUpdate(entity this)
 845 {
 846         this.nextthink = time;
 847         if(this.count != autocvar_g_balance_armor_blockpercent)
 848         {
 849                 this.count = autocvar_g_balance_armor_blockpercent;
 850                 this.SendFlags |= 1;
 851         }
 852         if(this.cnt != autocvar_g_balance_damagepush_speedfactor)
 853         {
 854                 this.cnt = autocvar_g_balance_damagepush_speedfactor;
 855                 this.SendFlags |= 1;
 856         }
 857 }
 858
 859 void ClientInit_Spawn()
 860 {
 861         entity e = new_pure(clientinit);
 862         setthink(e, ClientInit_CheckUpdate);
 863         Net_LinkEntity(e, false, 0, ClientInit_SendEntity);
 864
 865         ClientInit_CheckUpdate(e);
 866 }
 867
 868 /*
 869 =============
 870 SetNewParms
 871 =============
 872 */
 873 void SetNewParms ()
 874 {
 875         // initialize parms for a new player
 876         parm1 = -(86400 * 366);
 877
 878         MUTATOR_CALLHOOK(SetNewParms);
 879 }
 880
 881 /*
 882 =============
 883 SetChangeParms
 884 =============
 885 */
 886 void SetChangeParms (entity this)
 887 {
 888         // save parms for level change
 889         parm1 = CS(this).parm_idlesince - time;
 890
 891         MUTATOR_CALLHOOK(SetChangeParms);
 892 }
 893
 894 /*
 895 =============
 896 DecodeLevelParms
 897 =============
 898 */
 899 void DecodeLevelParms(entity this)
 900 {
 901         // load parms
 902         CS(this).parm_idlesince = parm1;
 903         if (CS(this).parm_idlesince == -(86400 * 366))
 904                 CS(this).parm_idlesince = time;
 905
 906         // whatever happens, allow 60 seconds of idling directly after connect for map loading
 907         CS(this).parm_idlesince = max(CS(this).parm_idlesince, time - sv_maxidle + 60);
 908
 909         MUTATOR_CALLHOOK(DecodeLevelParms);
 910 }
 911
 912 void FixClientCvars(entity e)
 913 {
 914         // send prediction settings to the client
 915         stuffcmd(e, "\nin_bindmap 0 0\n");
 916         if(autocvar_g_antilag == 3) // client side hitscan
 917                 stuffcmd(e, "cl_cmd settemp cl_prydoncursor_notrace 0\n");
 918         if(autocvar_sv_gentle)
 919                 stuffcmd(e, "cl_cmd settemp cl_gentle 1\n");
 920
 921         stuffcmd(e, sprintf("\ncl_jumpspeedcap_min \"%s\"\n", autocvar_sv_jumpspeedcap_min));
 922         stuffcmd(e, sprintf("\ncl_jumpspeedcap_max \"%s\"\n", autocvar_sv_jumpspeedcap_max));
 923
 924         stuffcmd(e, sprintf("\ncl_shootfromfixedorigin \"%s\"\n", autocvar_g_shootfromfixedorigin));
 925
 926         MUTATOR_CALLHOOK(FixClientCvars, e);
 927 }
 928
 929 bool findinlist_abbrev(string tofind, string list)
 930 {
 931         if(list == "" || tofind == "")
 932                 return false; // empty list or search, just return
 933
 934         // this function allows abbreviated strings!
 935         FOREACH_WORD(list, it == substring(tofind, 0, strlen(it)),
 936         {
 937                 return true;
 938         });
 939
 940         return false;
 941 }
 942
 943 bool PlayerInIPList(entity p, string iplist)
 944 {
 945         // some safety checks (never allow local?)
 946         if(p.netaddress == "local" || p.netaddress == "" || !IS_REAL_CLIENT(p))
 947                 return false;
 948
 949         return findinlist_abbrev(p.netaddress, iplist);
 950 }
 951
 952 bool PlayerInIDList(entity p, string idlist)
 953 {
 954         // NOTE: we do NOT check crypto_idfp_signed here, an unsigned ID is fine too for this
 955         if(!p.crypto_idfp)
 956                 return false;
 957
 958         return findinlist_abbrev(p.crypto_idfp, idlist);
 959 }
 960
 961 bool PlayerInList(entity player, string list)
 962 {
 963         return boolean(PlayerInIDList(player, list) || PlayerInIPList(player, list));
 964 }
 965
 966 #ifdef DP_EXT_PRECONNECT
 967 /*
 968 =============
 969 ClientPreConnect
 970
 971 Called once (not at each match start) when a client begins a connection to the server
 972 =============
 973 */
 974 void ClientPreConnect(entity this)
 975 {
 976         if(autocvar_sv_eventlog)
 977         {
 978                 GameLogEcho(sprintf(":connect:%d:%d:%s",
 979                         this.playerid,
 980                         etof(this),
 981                         ((IS_REAL_CLIENT(this)) ? this.netaddress : "bot")
 982                 ));
 983         }
 984 }
 985 #endif
 986
 987 string GetClientVersionMessage(entity this)
 988 {
 989         if (CS(this).version_mismatch) {
 990                 if(CS(this).version < autocvar_gameversion) {
 991                         return strcat("This is Xonotic ", autocvar_g_xonoticversion,
 992                                 "\n^3Your client version is outdated.\n\n\n### YOU WON'T BE ABLE TO PLAY ON THIS SERVER ###\n\n\nPlease update!!!^8");
 993                 } else {
 994                         return strcat("This is Xonotic ", autocvar_g_xonoticversion,
 995                                 "\n^3This server is using an outdated Xonotic version.\n\n\n ### THIS SERVER IS INCOMPATIBLE AND THUS YOU CANNOT JOIN ###.^8");
 996                 }
 997         } else {
 998                 return strcat("Welcome to Xonotic ", autocvar_g_xonoticversion);
 999         }
1000 }
1001
1002 string getwelcomemessage(entity this)
1003 {
1004         MUTATOR_CALLHOOK(BuildMutatorsPrettyString, "");
1005         string modifications = M_ARGV(0, string);
1006
1007         if(g_weaponarena)
1008         {
1009                 if(g_weaponarena_random)
1010                         modifications = strcat(modifications, ", ", ftos(g_weaponarena_random), " of ", g_weaponarena_list, " Arena");
1011                 else
1012                         modifications = strcat(modifications, ", ", g_weaponarena_list, " Arena");
1013         }
1014         else if(cvar("g_balance_blaster_weaponstartoverride") == 0)
1015                 modifications = strcat(modifications, ", No start weapons");
1016         if(cvar("sv_gravity") < stof(cvar_defstring("sv_gravity")))
1017                 modifications = strcat(modifications, ", Low gravity");
1018         if(g_weapon_stay && !g_cts)
1019                 modifications = strcat(modifications, ", Weapons stay");
1020         if(g_jetpack)
1021                 modifications = strcat(modifications, ", Jet pack");
1022         if(autocvar_g_powerups == 0)
1023                 modifications = strcat(modifications, ", No powerups");
1024         if(autocvar_g_powerups > 0)
1025                 modifications = strcat(modifications, ", Powerups");
1026         modifications = substring(modifications, 2, strlen(modifications) - 2);
1027
1028         string versionmessage = GetClientVersionMessage(this);
1029         string s = strcat(versionmessage, "^8\n^8\nmatch type is ^1", gamemode_name, "^8\n");
1030
1031         if(modifications != "")
1032                 s = strcat(s, "^8\nactive modifications: ^3", modifications, "^8\n");
1033
1034         if(cache_lastmutatormsg != autocvar_g_mutatormsg)
1035         {
1036                 strcpy(cache_lastmutatormsg, autocvar_g_mutatormsg);
1037                 strcpy(cache_mutatormsg, cache_lastmutatormsg);
1038         }
1039
1040         if (cache_mutatormsg != "") {
1041                 s = strcat(s, "\n\n^8special gameplay tips: ^7", cache_mutatormsg);
1042         }
1043
1044         string mutator_msg = "";
1045         MUTATOR_CALLHOOK(BuildGameplayTipsString, mutator_msg);
1046         mutator_msg = M_ARGV(0, string);
1047
1048         s = strcat(s, mutator_msg); // trust that the mutator will do proper formatting
1049
1050         string motd = autocvar_sv_motd;
1051         if (motd != "") {
1052                 s = strcat(s, "\n\n^8MOTD: ^7", strreplace("\\n", "\n", motd));
1053         }
1054         return s;
1055 }
1056
1057 bool autocvar_sv_qcphysics = false; // TODO this is for testing - remove when qcphysics work
1058
1059 /**
1060 =============
1061 ClientConnect
1062
1063 Called when a client connects to the server
1064 =============
1065 */
1066 void ClientConnect(entity this)
1067 {
1068         if (Ban_MaybeEnforceBanOnce(this)) return;
1069         assert(!IS_CLIENT(this), return);
1070         this.flags |= FL_CLIENT;
1071         assert(player_count >= 0, player_count = 0);
1072
1073 #ifdef WATERMARK
1074         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_WATERMARK, WATERMARK);
1075 #endif
1076         TRANSMUTE(Client, this);
1077         CS(this).version_nagtime = time + 10 + random() * 10;
1078
1079         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_JOIN_CONNECT, this.netname);
1080
1081         bot_clientconnect(this);
1082
1083         Player_DetermineForcedTeam(this);
1084
1085         TRANSMUTE(Observer, this);
1086
1087         PlayerStats_GameReport_AddEvent(sprintf("kills-%d", this.playerid));
1088
1089         // always track bots, don't ask for cl_allow_uidtracking
1090         if (IS_BOT_CLIENT(this))
1091                 PlayerStats_GameReport_AddPlayer(this);
1092         else
1093                 CS(this).allowed_timeouts = autocvar_sv_timeout_number;
1094
1095         if (autocvar_sv_eventlog)
1096                 GameLogEcho(strcat(":join:", ftos(this.playerid), ":", ftos(etof(this)), ":", ((IS_REAL_CLIENT(this)) ? this.netaddress : "bot"), ":", playername(this, false)));
1097
1098         CS(this).just_joined = true;  // stop spamming the eventlog with additional lines when the client connects
1099
1100         stuffcmd(this, clientstuff, "\n");
1101         stuffcmd(this, "cl_particles_reloadeffects\n"); // TODO do we still need this?
1102
1103         FixClientCvars(this);
1104
1105         // get version info from player
1106         stuffcmd(this, "cmd clientversion $gameversion\n");
1107
1108         // notify about available teams
1109         if (teamplay)
1110         {
1111                 entity balance = TeamBalance_CheckAllowedTeams(this);
1112                 int t = TeamBalance_GetAllowedTeams(balance);
1113                 TeamBalance_Destroy(balance);
1114                 stuffcmd(this, sprintf("set _teams_available %d\n", t));
1115         }
1116         else
1117         {
1118                 stuffcmd(this, "set _teams_available 0\n");
1119         }
1120
1121         bot_relinkplayerlist();
1122
1123         CS(this).spectatortime = time;
1124         if (blockSpectators)
1125         {
1126                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
1127         }
1128
1129         CS(this).jointime = time;
1130
1131         if (IS_REAL_CLIENT(this))
1132         {
1133                 if (g_weaponarena_weapons == WEPSET(TUBA))
1134                         stuffcmd(this, "cl_cmd settemp chase_active 1\n");
1135         }
1136
1137         if (!sv_foginterval && world.fog != "")
1138                 stuffcmd(this, strcat("\nfog ", world.fog, "\nr_fog_exp2 0\nr_drawfog 1\n"));
1139
1140         if (autocvar_sv_teamnagger && !(autocvar_bot_vs_human && AvailableTeams() == 2))
1141                 if(!MUTATOR_CALLHOOK(HideTeamNagger, this))
1142                         send_CSQC_teamnagger();
1143
1144         CSQCMODEL_AUTOINIT(this);
1145
1146         CS(this).model_randomizer = random();
1147
1148         if (IS_REAL_CLIENT(this))
1149                 sv_notice_join(this);
1150
1151         this.move_qcphysics = autocvar_sv_qcphysics;
1152
1153         // update physics stats (players can spawn before physics runs)
1154         Physics_UpdateStats(this);
1155
1156         IL_EACH(g_initforplayer, it.init_for_player, {
1157                 it.init_for_player(it, this);
1158         });
1159
1160         Handicap_Initialize(this);
1161
1162         MUTATOR_CALLHOOK(ClientConnect, this);
1163
1164         if (IS_REAL_CLIENT(this))
1165         {
1166                 if (!autocvar_g_campaign && !IS_PLAYER(this))
1167                 {
1168                         CS(this).motd_actived_time = -1;
1169                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOTD, getwelcomemessage(this));
1170                 }
1171         }
1172 }
1173 /*
1174 =============
1175 ClientDisconnect
1176
1177 Called when a client disconnects from the server
1178 =============
1179 */
1180 .entity chatbubbleentity;
1181 void ClientDisconnect(entity this)
1182 {
1183         assert(IS_CLIENT(this), return);
1184
1185         PlayerStats_GameReport_FinalizePlayer(this);
1186         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
1187         if (CS(this).active_minigame) part_minigame(this);
1188         if (IS_PLAYER(this)) Send_Effect(EFFECT_SPAWN_NEUTRAL, this.origin, '0 0 0', 1);
1189
1190         if (autocvar_sv_eventlog)
1191                 GameLogEcho(strcat(":part:", ftos(this.playerid)));
1192
1193         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_QUIT_DISCONNECT, this.netname);
1194
1195         if(IS_SPEC(this))
1196                 SetSpectatee(this, NULL);
1197
1198     MUTATOR_CALLHOOK(ClientDisconnect, this);
1199
1200         strfree(CS(this).netname_previous); // needs to be before the CS entity is removed!
1201         strfree(CS(this).weaponorder_byimpulse);
1202         ClientState_detach(this);
1203
1204         Portal_ClearAll(this);
1205
1206         Unfreeze(this, false);
1207
1208         RemoveGrapplingHooks(this);
1209
1210         // Here, everything has been done that requires this player to be a client.
1211
1212         this.flags &= ~FL_CLIENT;
1213
1214         if (this.chatbubbleentity) delete(this.chatbubbleentity);
1215         if (this.killindicator) delete(this.killindicator);
1216
1217         WaypointSprite_PlayerGone(this);
1218
1219         bot_relinkplayerlist();
1220
1221         strfree(this.clientstatus);
1222         if (this.personal) delete(this.personal);
1223
1224         this.playerid = 0;
1225         ReadyCount();
1226         if (vote_called && IS_REAL_CLIENT(this)) VoteCount(false);
1227
1228         ONREMOVE(this);
1229 }
1230
1231 void ChatBubbleThink(entity this)
1232 {
1233         this.nextthink = time;
1234         if ((this.owner.alpha < 0) || this.owner.chatbubbleentity != this)
1235         {
1236                 if(this.owner) // but why can that ever be NULL?
1237                         this.owner.chatbubbleentity = NULL;
1238                 delete(this);
1239                 return;
1240         }
1241
1242         this.mdl = "";
1243
1244         if ( !IS_DEAD(this.owner) && IS_PLAYER(this.owner) )
1245         {
1246                 if ( CS(this.owner).active_minigame && PHYS_INPUT_BUTTON_MINIGAME(this.owner) )
1247                         this.mdl = "models/sprites/minigame_busy.iqm";
1248                 else if (PHYS_INPUT_BUTTON_CHAT(this.owner))
1249                         this.mdl = "models/misc/chatbubble.spr";
1250         }
1251
1252         if ( this.model != this.mdl )
1253                 _setmodel(this, this.mdl);
1254
1255 }
1256
1257 void UpdateChatBubble(entity this)
1258 {
1259         if (this.alpha < 0)
1260                 return;
1261         // spawn a chatbubble entity if needed
1262         if (!this.chatbubbleentity)
1263         {
1264                 this.chatbubbleentity = new(chatbubbleentity);
1265                 this.chatbubbleentity.owner = this;
1266                 this.chatbubbleentity.exteriormodeltoclient = this;
1267                 setthink(this.chatbubbleentity, ChatBubbleThink);
1268                 this.chatbubbleentity.nextthink = time;
1269                 setmodel(this.chatbubbleentity, MDL_CHAT); // precision set below
1270                 //setorigin(this.chatbubbleentity, this.origin + '0 0 15' + this.maxs_z * '0 0 1');
1271                 setorigin(this.chatbubbleentity, '0 0 15' + this.maxs_z * '0 0 1');
1272                 setattachment(this.chatbubbleentity, this, "");  // sticks to moving player better, also conserves bandwidth
1273                 this.chatbubbleentity.mdl = this.chatbubbleentity.model;
1274                 //this.chatbubbleentity.model = "";
1275                 this.chatbubbleentity.effects = EF_LOWPRECISION;
1276         }
1277 }
1278
1279
1280 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
1281 // added to the model skins
1282 /*void UpdateColorModHack()
1283 {
1284         float c;
1285         c = this.clientcolors & 15;
1286         // LordHavoc: only bothering to support white, green, red, yellow, blue
1287              if (!teamplay) this.colormod = '0 0 0';
1288         else if (c ==  0) this.colormod = '1.00 1.00 1.00';
1289         else if (c ==  3) this.colormod = '0.10 1.73 0.10';
1290         else if (c ==  4) this.colormod = '1.73 0.10 0.10';
1291         else if (c == 12) this.colormod = '1.22 1.22 0.10';
1292         else if (c == 13) this.colormod = '0.10 0.10 1.73';
1293         else this.colormod = '1 1 1';
1294 }*/
1295
1296 void respawn(entity this)
1297 {
1298         if(this.alpha >= 0 && autocvar_g_respawn_ghosts)
1299         {
1300                 this.solid = SOLID_NOT;
1301                 this.takedamage = DAMAGE_NO;
1302                 set_movetype(this, MOVETYPE_FLY);
1303                 this.velocity = '0 0 1' * autocvar_g_respawn_ghosts_speed;
1304                 this.avelocity = randomvec() * autocvar_g_respawn_ghosts_speed * 3 - randomvec() * autocvar_g_respawn_ghosts_speed * 3;
1305                 this.effects |= CSQCMODEL_EF_RESPAWNGHOST;
1306                 Send_Effect(EFFECT_RESPAWN_GHOST, this.origin, '0 0 0', 1);
1307                 if(autocvar_g_respawn_ghosts_maxtime)
1308                         SUB_SetFade (this, time + autocvar_g_respawn_ghosts_maxtime / 2 + random () * (autocvar_g_respawn_ghosts_maxtime - autocvar_g_respawn_ghosts_maxtime / 2), 1.5);
1309         }
1310
1311         CopyBody(this, 1);
1312
1313         this.effects |= EF_NODRAW; // prevent another CopyBody
1314         PutClientInServer(this);
1315 }
1316
1317 void PrintToChat(entity client, string text)
1318 {
1319         text = strcat("\{1}^7", text, "\n");
1320         sprint(client, text);
1321 }
1322
1323 void DebugPrintToChat(entity client, string text)
1324 {
1325         if (autocvar_developer)
1326         {
1327                 PrintToChat(client, text);
1328         }
1329 }
1330
1331 void PrintToChatAll(string text)
1332 {
1333         text = strcat("\{1}^7", text, "\n");
1334         bprint(text);
1335 }
1336
1337 void DebugPrintToChatAll(string text)
1338 {
1339         if (autocvar_developer)
1340         {
1341                 PrintToChatAll(text);
1342         }
1343 }
1344
1345 void PrintToChatTeam(int team_num, string text)
1346 {
1347         text = strcat("\{1}^7", text, "\n");
1348         FOREACH_CLIENT(IS_REAL_CLIENT(it),
1349         {
1350                 if (it.team == team_num)
1351                 {
1352                         sprint(it, text);
1353                 }
1354         });
1355 }
1356
1357 void DebugPrintToChatTeam(int team_num, string text)
1358 {
1359         if (autocvar_developer)
1360         {
1361                 PrintToChatTeam(team_num, text);
1362         }
1363 }
1364
1365 void play_countdown(entity this, float finished, Sound samp)
1366 {
1367         TC(Sound, samp);
1368         if(IS_REAL_CLIENT(this))
1369                 if(floor(finished - time - frametime) != floor(finished - time))
1370                         if(finished - time < 6)
1371                                 sound (this, CH_INFO, samp, VOL_BASE, ATTEN_NORM);
1372 }
1373
1374 void player_powerups(entity this)
1375 {
1376         // add a way to see what the items were BEFORE all of these checks for the mutator hook
1377         int items_prev = this.items;
1378
1379         if((this.items & IT_USING_JETPACK) && !IS_DEAD(this) && !game_stopped)
1380                 this.modelflags |= MF_ROCKET;
1381         else
1382                 this.modelflags &= ~MF_ROCKET;
1383
1384         this.effects &= ~(EF_RED | EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT | EF_FLAME | EF_NODEPTHTEST);
1385
1386         if((this.alpha < 0 || IS_DEAD(this)) && !this.vehicle) // don't apply the flags if the player is gibbed
1387                 return;
1388
1389         Fire_ApplyDamage(this);
1390         Fire_ApplyEffect(this);
1391
1392         if (!MUTATOR_IS_ENABLED(mutator_instagib))
1393         {
1394                 if (this.items & ITEM_Strength.m_itemid)
1395                 {
1396                         play_countdown(this, this.strength_finished, SND_POWEROFF);
1397                         this.effects = this.effects | (EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT);
1398                         if (time > this.strength_finished)
1399                         {
1400                                 this.items = this.items - (this.items & ITEM_Strength.m_itemid);
1401                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERDOWN_STRENGTH, this.netname);
1402                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERDOWN_STRENGTH);
1403                         }
1404                 }
1405                 else
1406                 {
1407                         if (time < this.strength_finished)
1408                         {
1409                                 this.items = this.items | ITEM_Strength.m_itemid;
1410                                 if(!g_cts)
1411                                         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERUP_STRENGTH, this.netname);
1412                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERUP_STRENGTH);
1413                         }
1414                 }
1415                 if (this.items & ITEM_Shield.m_itemid)
1416                 {
1417                         play_countdown(this, this.invincible_finished, SND_POWEROFF);
1418                         this.effects = this.effects | (EF_RED | EF_ADDITIVE | EF_FULLBRIGHT);
1419                         if (time > this.invincible_finished)
1420                         {
1421                                 this.items = this.items - (this.items & ITEM_Shield.m_itemid);
1422                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERDOWN_SHIELD, this.netname);
1423                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERDOWN_SHIELD);
1424                         }
1425                 }
1426                 else
1427                 {
1428                         if (time < this.invincible_finished)
1429                         {
1430                                 this.items = this.items | ITEM_Shield.m_itemid;
1431                                 if(!g_cts)
1432                                         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERUP_SHIELD, this.netname);
1433                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERUP_SHIELD);
1434                         }
1435                 }
1436                 if (this.items & IT_SUPERWEAPON)
1437                 {
1438                         if (!(STAT(WEAPONS, this) & WEPSET_SUPERWEAPONS))
1439                         {
1440                                 this.superweapons_finished = 0;
1441                                 this.items = this.items - (this.items & IT_SUPERWEAPON);
1442                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_LOST, this.netname);
1443                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_LOST);
1444                         }
1445                         else if (this.items & IT_UNLIMITED_SUPERWEAPONS)
1446                         {
1447                                 // don't let them run out
1448                         }
1449                         else
1450                         {
1451                                 play_countdown(this, this.superweapons_finished, SND_POWEROFF);
1452                                 if (time > this.superweapons_finished)
1453                                 {
1454                                         this.items = this.items - (this.items & IT_SUPERWEAPON);
1455                                         STAT(WEAPONS, this) &= ~WEPSET_SUPERWEAPONS;
1456                                         //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_BROKEN, this.netname);
1457                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_BROKEN);
1458                                 }
1459                         }
1460                 }
1461                 else if(STAT(WEAPONS, this) & WEPSET_SUPERWEAPONS)
1462                 {
1463                         if (time < this.superweapons_finished || (this.items & IT_UNLIMITED_SUPERWEAPONS))
1464                         {
1465                                 this.items = this.items | IT_SUPERWEAPON;
1466                                 if(!(this.items & IT_UNLIMITED_SUPERWEAPONS))
1467                                 {
1468                                         if(!g_cts)
1469                                                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_PICKUP, this.netname);
1470                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_PICKUP);
1471                                 }
1472                         }
1473                         else
1474                         {
1475                                 this.superweapons_finished = 0;
1476                                 STAT(WEAPONS, this) &= ~WEPSET_SUPERWEAPONS;
1477                         }
1478                 }
1479                 else
1480                 {
1481                         this.superweapons_finished = 0;
1482                 }
1483         }
1484
1485         if(autocvar_g_nodepthtestplayers)
1486                 this.effects = this.effects | EF_NODEPTHTEST;
1487
1488         if(autocvar_g_fullbrightplayers)
1489                 this.effects = this.effects | EF_FULLBRIGHT;
1490
1491         if (time >= game_starttime)
1492         if (time < this.spawnshieldtime)
1493                 this.effects = this.effects | (EF_ADDITIVE | EF_FULLBRIGHT);
1494
1495         MUTATOR_CALLHOOK(PlayerPowerups, this, items_prev);
1496 }
1497
1498 float CalcRegen(float current, float stable, float regenfactor, float regenframetime)
1499 {
1500         if(current > stable)
1501                 return current;
1502         else if(current > stable - 0.25) // when close enough, "snap"
1503                 return stable;
1504         else
1505                 return min(stable, current + (stable - current) * regenfactor * regenframetime);
1506 }
1507
1508 float CalcRot(float current, float stable, float rotfactor, float rotframetime)
1509 {
1510         if(current < stable)
1511                 return current;
1512         else if(current < stable + 0.25) // when close enough, "snap"
1513                 return stable;
1514         else
1515                 return max(stable, current + (stable - current) * rotfactor * rotframetime);
1516 }
1517
1518 float CalcRotRegen(float current, float regenstable, float regenfactor, float regenlinear, float regenframetime, float rotstable, float rotfactor, float rotlinear, float rotframetime, float limit)
1519 {
1520         if(current > rotstable)
1521         {
1522                 if(rotframetime > 0)
1523                 {
1524                         current = CalcRot(current, rotstable, rotfactor, rotframetime);
1525                         current = max(rotstable, current - rotlinear * rotframetime);
1526                 }
1527         }
1528         else if(current < regenstable)
1529         {
1530                 if(regenframetime > 0)
1531                 {
1532                         current = CalcRegen(current, regenstable, regenfactor, regenframetime);
1533                         current = min(regenstable, current + regenlinear * regenframetime);
1534                 }
1535         }
1536
1537         if(current > limit)
1538                 current = limit;
1539
1540         return current;
1541 }
1542
1543 void player_regen(entity this)
1544 {
1545         float max_mod, regen_mod, rot_mod, limit_mod;
1546         max_mod = regen_mod = rot_mod = limit_mod = 1;
1547
1548         float regen_health = autocvar_g_balance_health_regen;
1549         float regen_health_linear = autocvar_g_balance_health_regenlinear;
1550         float regen_health_rot = autocvar_g_balance_health_rot;
1551         float regen_health_rotlinear = autocvar_g_balance_health_rotlinear;
1552         float regen_health_stable = autocvar_g_balance_health_regenstable;
1553         float regen_health_rotstable = autocvar_g_balance_health_rotstable;
1554         bool mutator_returnvalue = MUTATOR_CALLHOOK(PlayerRegen, this, max_mod, regen_mod, rot_mod, limit_mod, regen_health, regen_health_linear, regen_health_rot,
1555                 regen_health_rotlinear, regen_health_stable, regen_health_rotstable);
1556         max_mod = M_ARGV(1, float);
1557         regen_mod = M_ARGV(2, float);
1558         rot_mod = M_ARGV(3, float);
1559         limit_mod = M_ARGV(4, float);
1560         regen_health = M_ARGV(5, float);
1561         regen_health_linear = M_ARGV(6, float);
1562         regen_health_rot = M_ARGV(7, float);
1563         regen_health_rotlinear = M_ARGV(8, float);
1564         regen_health_stable = M_ARGV(9, float);
1565         regen_health_rotstable = M_ARGV(10, float);
1566
1567         if(!mutator_returnvalue)
1568         if(!STAT(FROZEN, this))
1569         {
1570                 float mina, maxa, limith, limita;
1571                 maxa = autocvar_g_balance_armor_rotstable;
1572                 mina = autocvar_g_balance_armor_regenstable;
1573                 limith = GetResourceLimit(this, RESOURCE_HEALTH);
1574                 limita = GetResourceLimit(this, RESOURCE_ARMOR);
1575
1576                 regen_health_rotstable = regen_health_rotstable * max_mod;
1577                 regen_health_stable = regen_health_stable * max_mod;
1578                 limith = limith * limit_mod;
1579                 limita = limita * limit_mod;
1580
1581                 SetResourceAmount(this, RESOURCE_ARMOR, CalcRotRegen(GetResourceAmount(this, RESOURCE_ARMOR), mina, autocvar_g_balance_armor_regen, autocvar_g_balance_armor_regenlinear,
1582                                                                         regen_mod * frametime * (time > this.pauseregen_finished), maxa, autocvar_g_balance_armor_rot, autocvar_g_balance_armor_rotlinear,
1583                                                                         rot_mod * frametime * (time > this.pauserotarmor_finished), limita));
1584                 SetResourceAmount(this, RESOURCE_HEALTH, CalcRotRegen(GetResourceAmount(this, RESOURCE_HEALTH), regen_health_stable, regen_health, regen_health_linear,
1585                                                                         regen_mod * frametime * (time > this.pauseregen_finished), regen_health_rotstable, regen_health_rot, regen_health_rotlinear,
1586                                                                         rot_mod * frametime * (time > this.pauserothealth_finished), limith));
1587         }
1588
1589         // if player rotted to death...  die!
1590         // check this outside above checks, as player may still be able to rot to death
1591         if(GetResourceAmount(this, RESOURCE_HEALTH) < 1)
1592         {
1593                 if(this.vehicle)
1594                         vehicles_exit(this.vehicle, VHEF_RELEASE);
1595                 if(this.event_damage)
1596                         this.event_damage(this, this, this, 1, DEATH_ROT.m_id, DMG_NOWEP, this.origin, '0 0 0');
1597         }
1598
1599         if (!(this.items & IT_UNLIMITED_WEAPON_AMMO))
1600         {
1601                 float minf, maxf, limitf;
1602
1603                 maxf = autocvar_g_balance_fuel_rotstable;
1604                 minf = autocvar_g_balance_fuel_regenstable;
1605                 limitf = GetResourceLimit(this, RESOURCE_FUEL);
1606
1607                 SetResourceAmount(this, RESOURCE_FUEL, CalcRotRegen(GetResourceAmount(this, RESOURCE_FUEL), minf, autocvar_g_balance_fuel_regen, autocvar_g_balance_fuel_regenlinear,
1608                                                                                 frametime * (time > this.pauseregen_finished) * ((this.items & ITEM_JetpackRegen.m_itemid) != 0),
1609                                                                                 maxf, autocvar_g_balance_fuel_rot, autocvar_g_balance_fuel_rotlinear, frametime * (time > this.pauserotfuel_finished), limitf));
1610         }
1611 }
1612
1613 bool zoomstate_set;
1614 void SetZoomState(entity this, float newzoom)
1615 {
1616         if(newzoom != CS(this).zoomstate)
1617         {
1618                 CS(this).zoomstate = newzoom;
1619                 ClientData_Touch(this);
1620         }
1621         zoomstate_set = true;
1622 }
1623
1624 void GetPressedKeys(entity this)
1625 {
1626         MUTATOR_CALLHOOK(GetPressedKeys, this);
1627         int keys = STAT(PRESSED_KEYS, this);
1628         keys = BITSET(keys, KEY_FORWARD,        CS(this).movement.x > 0);
1629         keys = BITSET(keys, KEY_BACKWARD,       CS(this).movement.x < 0);
1630         keys = BITSET(keys, KEY_RIGHT,          CS(this).movement.y > 0);
1631         keys = BITSET(keys, KEY_LEFT,           CS(this).movement.y < 0);
1632
1633         keys = BITSET(keys, KEY_JUMP,           PHYS_INPUT_BUTTON_JUMP(this));
1634         keys = BITSET(keys, KEY_CROUCH,         IS_DUCKED(this)); // workaround: player can't un-crouch until their path is clear, so we keep the button held here
1635         keys = BITSET(keys, KEY_ATCK,           PHYS_INPUT_BUTTON_ATCK(this));
1636         keys = BITSET(keys, KEY_ATCK2,          PHYS_INPUT_BUTTON_ATCK2(this));
1637         CS(this).pressedkeys = keys; // store for other users
1638
1639         STAT(PRESSED_KEYS, this) = keys;
1640 }
1641
1642 /*
1643 ======================
1644 spectate mode routines
1645 ======================
1646 */
1647
1648 void SpectateCopy(entity this, entity spectatee)
1649 {
1650         TC(Client, this); TC(Client, spectatee);
1651
1652         MUTATOR_CALLHOOK(SpectateCopy, spectatee, this);
1653         PS(this) = PS(spectatee);
1654         this.armortype = spectatee.armortype;
1655         SetResourceAmountExplicit(this, RESOURCE_ARMOR, GetResourceAmount(spectatee, RESOURCE_ARMOR));
1656         SetResourceAmountExplicit(this, RESOURCE_CELLS, GetResourceAmount(spectatee, RESOURCE_CELLS));
1657         SetResourceAmountExplicit(this, RESOURCE_PLASMA, GetResourceAmount(spectatee, RESOURCE_PLASMA));
1658         SetResourceAmountExplicit(this, RESOURCE_SHELLS, GetResourceAmount(spectatee, RESOURCE_SHELLS));
1659         SetResourceAmountExplicit(this, RESOURCE_BULLETS, GetResourceAmount(spectatee, RESOURCE_BULLETS));
1660         SetResourceAmountExplicit(this, RESOURCE_ROCKETS, GetResourceAmount(spectatee, RESOURCE_ROCKETS));
1661         SetResourceAmountExplicit(this, RESOURCE_FUEL, GetResourceAmount(spectatee, RESOURCE_FUEL));
1662         this.effects = spectatee.effects & EFMASK_CHEAP; // eat performance
1663         SetResourceAmountExplicit(this, RESOURCE_HEALTH, GetResourceAmount(spectatee, RESOURCE_HEALTH));
1664         CS(this).impulse = 0;
1665         this.items = spectatee.items;
1666         STAT(LAST_PICKUP, this) = STAT(LAST_PICKUP, spectatee);
1667         STAT(HIT_TIME, this) = STAT(HIT_TIME, spectatee);
1668         this.strength_finished = spectatee.strength_finished;
1669         this.invincible_finished = spectatee.invincible_finished;
1670         this.superweapons_finished = spectatee.superweapons_finished;
1671         STAT(PRESSED_KEYS, this) = STAT(PRESSED_KEYS, spectatee);
1672         STAT(WEAPONS, this) = STAT(WEAPONS, spectatee);
1673         this.punchangle = spectatee.punchangle;
1674         this.view_ofs = spectatee.view_ofs;
1675         this.velocity = spectatee.velocity;
1676         this.dmg_take = spectatee.dmg_take;
1677         this.dmg_save = spectatee.dmg_save;
1678         this.dmg_inflictor = spectatee.dmg_inflictor;
1679         this.v_angle = spectatee.v_angle;
1680         this.angles = spectatee.v_angle;
1681         STAT(FROZEN, this) = STAT(FROZEN, spectatee);
1682         STAT(REVIVE_PROGRESS, this) = STAT(REVIVE_PROGRESS, spectatee);
1683         this.viewloc = spectatee.viewloc;
1684         if(!PHYS_INPUT_BUTTON_USE(this) && STAT(CAMERA_SPECTATOR, this) != 2)
1685                 this.fixangle = true;
1686         setorigin(this, spectatee.origin);
1687         setsize(this, spectatee.mins, spectatee.maxs);
1688         SetZoomState(this, CS(spectatee).zoomstate);
1689
1690     anticheat_spectatecopy(this, spectatee);
1691         STAT(HUD, this) = STAT(HUD, spectatee);
1692         if(spectatee.vehicle)
1693     {
1694         this.angles = spectatee.v_angle;
1695
1696         //this.fixangle = false;
1697         //this.velocity = spectatee.vehicle.velocity;
1698         this.vehicle_health = spectatee.vehicle_health;
1699         this.vehicle_shield = spectatee.vehicle_shield;
1700         this.vehicle_energy = spectatee.vehicle_energy;
1701         this.vehicle_ammo1 = spectatee.vehicle_ammo1;
1702         this.vehicle_ammo2 = spectatee.vehicle_ammo2;
1703         this.vehicle_reload1 = spectatee.vehicle_reload1;
1704         this.vehicle_reload2 = spectatee.vehicle_reload2;
1705
1706         //msg_entity = this;
1707
1708        // WriteByte (MSG_ONE, SVC_SETVIEWANGLES);
1709             //WriteAngle(MSG_ONE,  spectatee.v_angle.x);
1710            // WriteAngle(MSG_ONE,  spectatee.v_angle.y);
1711            // WriteAngle(MSG_ONE,  spectatee.v_angle.z);
1712
1713         //WriteByte (MSG_ONE, SVC_SETVIEW);
1714         //    WriteEntity(MSG_ONE, this);
1715         //makevectors(spectatee.v_angle);
1716         //setorigin(this, spectatee.origin - v_forward * 400 + v_up * 300);*/
1717     }
1718 }
1719
1720 bool SpectateUpdate(entity this)
1721 {
1722         if(!this.enemy)
1723                 return false;
1724
1725         if(!IS_PLAYER(this.enemy) || this == this.enemy)
1726         {
1727                 SetSpectatee(this, NULL);
1728                 return false;
1729         }
1730
1731         SpectateCopy(this, this.enemy);
1732
1733         return true;
1734 }
1735
1736 bool SpectateSet(entity this)
1737 {
1738         if(!IS_PLAYER(this.enemy))
1739                 return false;
1740
1741         ClientData_Touch(this.enemy);
1742
1743         msg_entity = this;
1744         WriteByte(MSG_ONE, SVC_SETVIEW);
1745         WriteEntity(MSG_ONE, this.enemy);
1746         set_movetype(this, MOVETYPE_NONE);
1747         accuracy_resend(this);
1748
1749         if(!SpectateUpdate(this))
1750                 PutObserverInServer(this);
1751
1752         return true;
1753 }
1754
1755 void SetSpectatee_status(entity this, int spectatee_num)
1756 {
1757         int oldspectatee_status = CS(this).spectatee_status;
1758         CS(this).spectatee_status = spectatee_num;
1759
1760         if (CS(this).spectatee_status != oldspectatee_status)
1761         {
1762                 ClientData_Touch(this);
1763                 if (g_race || g_cts) race_InitSpectator();
1764         }
1765 }
1766
1767 void SetSpectatee(entity this, entity spectatee)
1768 {
1769         if(IS_BOT_CLIENT(this))
1770                 return; // bots abuse .enemy, this code is useless to them
1771
1772         entity old_spectatee = this.enemy;
1773
1774         this.enemy = spectatee;
1775
1776         // WEAPONTODO
1777         // these are required to fix the spectator bug with arc
1778         if(old_spectatee)
1779         {
1780                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1781                 {
1782                         .entity weaponentity = weaponentities[slot];
1783                         if(old_spectatee.(weaponentity).arc_beam)
1784                                 old_spectatee.(weaponentity).arc_beam.SendFlags |= ARC_SF_SETTINGS;
1785                 }
1786         }
1787         if(this.enemy)
1788         {
1789                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1790                 {
1791                         .entity weaponentity = weaponentities[slot];
1792                         if(this.enemy.(weaponentity).arc_beam)
1793                                 this.enemy.(weaponentity).arc_beam.SendFlags |= ARC_SF_SETTINGS;
1794                 }
1795         }
1796
1797         if (this.enemy)
1798                 SetSpectatee_status(this, etof(this.enemy));
1799
1800         // needed to update spectator list
1801         if(old_spectatee) { ClientData_Touch(old_spectatee); }
1802 }
1803
1804 bool Spectate(entity this, entity pl)
1805 {
1806         if(MUTATOR_CALLHOOK(SpectateSet, this, pl))
1807                 return false;
1808         pl = M_ARGV(1, entity);
1809
1810         SetSpectatee(this, pl);
1811         return SpectateSet(this);
1812 }
1813
1814 bool SpectateNext(entity this)
1815 {
1816         entity ent = find(this.enemy, classname, STR_PLAYER);
1817
1818         if (MUTATOR_CALLHOOK(SpectateNext, this, ent))
1819                 ent = M_ARGV(1, entity);
1820         else if (!ent)
1821                 ent = find(ent, classname, STR_PLAYER);
1822
1823         if(ent) { SetSpectatee(this, ent); }
1824
1825         return SpectateSet(this);
1826 }
1827
1828 bool SpectatePrev(entity this)
1829 {
1830         // NOTE: chain order is from the highest to the lower entnum (unlike find)
1831         entity ent = findchain(classname, STR_PLAYER);
1832         if (!ent) // no player
1833                 return false;
1834
1835         entity first = ent;
1836         // skip players until current spectated player
1837         if(this.enemy)
1838         while(ent && ent != this.enemy)
1839                 ent = ent.chain;
1840
1841         switch (MUTATOR_CALLHOOK(SpectatePrev, this, ent, first))
1842         {
1843                 case MUT_SPECPREV_FOUND:
1844                     ent = M_ARGV(1, entity);
1845                     break;
1846                 case MUT_SPECPREV_RETURN:
1847                     return true;
1848                 case MUT_SPECPREV_CONTINUE:
1849                 default:
1850                 {
1851                         if(ent.chain)
1852                                 ent = ent.chain;
1853                         else
1854                                 ent = first;
1855                         break;
1856                 }
1857         }
1858
1859         SetSpectatee(this, ent);
1860         return SpectateSet(this);
1861 }
1862
1863 /*
1864 =============
1865 ShowRespawnCountdown()
1866
1867 Update a respawn countdown display.
1868 =============
1869 */
1870 void ShowRespawnCountdown(entity this)
1871 {
1872         float number;
1873         if(!IS_DEAD(this)) // just respawned?
1874                 return;
1875         else
1876         {
1877                 number = ceil(this.respawn_time - time);
1878                 if(number <= 0)
1879                         return;
1880                 if(number <= this.respawn_countdown)
1881                 {
1882                         this.respawn_countdown = number - 1;
1883                         if(ceil(this.respawn_time - (time + 0.5)) == number) // only say it if it is the same number even in 0.5s; to prevent overlapping sounds
1884                                 { Send_Notification(NOTIF_ONE, this, MSG_ANNCE, Announcer_PickNumber(CNT_RESPAWN, number)); }
1885                 }
1886         }
1887 }
1888
1889 .bool team_selected;
1890 bool ShowTeamSelection(entity this)
1891 {
1892         if (!teamplay || autocvar_g_campaign || autocvar_g_balance_teams || this.team_selected || (CS(this).wasplayer && autocvar_g_changeteam_banned) || Player_HasRealForcedTeam(this))
1893                 return false;
1894         stuffcmd(this, "menu_showteamselect\n");
1895         return true;
1896 }
1897 void Join(entity this)
1898 {
1899         TRANSMUTE(Player, this);
1900
1901         if(!this.team_selected)
1902         if(autocvar_g_campaign || autocvar_g_balance_teams)
1903                 TeamBalance_JoinBestTeam(this);
1904
1905         if(autocvar_g_campaign)
1906                 campaign_bots_may_start = true;
1907
1908         Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_PREVENT_JOIN);
1909
1910         PutClientInServer(this);
1911
1912         if(IS_PLAYER(this))
1913         if(teamplay && this.team != -1)
1914         {
1915         }
1916         else
1917                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_JOIN_PLAY, this.netname);
1918         this.team_selected = false;
1919 }
1920
1921 int GetPlayerLimit()
1922 {
1923         int player_limit = autocvar_g_maxplayers;
1924         MUTATOR_CALLHOOK(GetPlayerLimit, player_limit);
1925         player_limit = M_ARGV(0, int);
1926         return player_limit;
1927 }
1928
1929 /**
1930  * Determines whether the player is allowed to join. This depends on cvar
1931  * g_maxplayers, if it isn't used this function always return true, otherwise
1932  * it checks whether the number of currently playing players exceeds g_maxplayers.
1933  * @return int number of free slots for players, 0 if none
1934  */
1935 int nJoinAllowed(entity this, entity ignore)
1936 {
1937         if(!ignore)
1938         // this is called that way when checking if anyone may be able to join (to build qcstatus)
1939         // so report 0 free slots if restricted
1940         {
1941                 if(autocvar_g_forced_team_otherwise == "spectate")
1942                         return 0;
1943                 if(autocvar_g_forced_team_otherwise == "spectator")
1944                         return 0;
1945         }
1946
1947         if(this && (Player_GetForcedTeamIndex(this) == TEAM_FORCE_SPECTATOR))
1948                 return 0; // forced spectators can never join
1949
1950         // TODO simplify this
1951         int totalClients = 0;
1952         int currentlyPlaying = 0;
1953         FOREACH_CLIENT(true, {
1954                 if(it != ignore)
1955                         ++totalClients;
1956                 if(IS_REAL_CLIENT(it))
1957                 if(IS_PLAYER(it) || it.caplayer)
1958                         ++currentlyPlaying;
1959         });
1960
1961         int player_limit = GetPlayerLimit();
1962
1963         float free_slots = 0;
1964         if (!player_limit)
1965                 free_slots = maxclients - totalClients;
1966         else if(currentlyPlaying < player_limit)
1967                 free_slots = min(maxclients - totalClients, player_limit - currentlyPlaying);
1968
1969         static float join_prevent_msg_time = 0;
1970         if(this && ignore && !free_slots && time > join_prevent_msg_time)
1971         {
1972                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_JOIN_PREVENT);
1973                 join_prevent_msg_time = time + 3;
1974         }
1975
1976         return free_slots;
1977 }
1978
1979 /**
1980  * Checks whether the client is an observer or spectator, if so, he will get kicked after
1981  * g_maxplayers_spectator_blocktime seconds
1982  */
1983 void checkSpectatorBlock(entity this)
1984 {
1985         if(IS_SPEC(this) || IS_OBSERVER(this))
1986         if(!this.caplayer)
1987         if(IS_REAL_CLIENT(this))
1988         {
1989                 if( time > (CS(this).spectatortime + autocvar_g_maxplayers_spectator_blocktime) ) {
1990                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_QUIT_KICK_SPECTATING);
1991                         dropclient(this);
1992                 }
1993         }
1994 }
1995
1996 void PrintWelcomeMessage(entity this)
1997 {
1998         if(CS(this).motd_actived_time == 0)
1999         {
2000                 if (autocvar_g_campaign) {
2001                         if ((IS_PLAYER(this) && PHYS_INPUT_BUTTON_INFO(this)) || (!IS_PLAYER(this))) {
2002                                 CS(this).motd_actived_time = time;
2003                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOTD, campaign_message);
2004                         }
2005                 } else {
2006                         if (PHYS_INPUT_BUTTON_INFO(this)) {
2007                                 CS(this).motd_actived_time = time;
2008                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOTD, getwelcomemessage(this));
2009                         }
2010                 }
2011         }
2012         else if(CS(this).motd_actived_time > 0) // showing MOTD or campaign message
2013         {
2014                 if (autocvar_g_campaign) {
2015                         if (PHYS_INPUT_BUTTON_INFO(this))
2016                                 CS(this).motd_actived_time = time;
2017                         else if ((time - CS(this).motd_actived_time > 2) && IS_PLAYER(this)) { // hide it some seconds after BUTTON_INFO has been released
2018                                 CS(this).motd_actived_time = 0;
2019                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_MOTD);
2020                         }
2021                 } else {
2022                         if (PHYS_INPUT_BUTTON_INFO(this))
2023                                 CS(this).motd_actived_time = time;
2024                         else if (time - CS(this).motd_actived_time > 2) { // hide it some seconds after BUTTON_INFO has been released
2025                                 CS(this).motd_actived_time = 0;
2026                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_MOTD);
2027                         }
2028                 }
2029         }
2030         else //if(CS(this).motd_actived_time < 0) // just connected, motd is active
2031         {
2032                 if(PHYS_INPUT_BUTTON_INFO(this)) // BUTTON_INFO hides initial MOTD
2033                         CS(this).motd_actived_time = -2; // wait until BUTTON_INFO gets released
2034                 else if(CS(this).motd_actived_time == -2 || IS_PLAYER(this) || IS_SPEC(this))
2035                 {
2036                         // instanctly hide MOTD
2037                         CS(this).motd_actived_time = 0;
2038                         Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_MOTD);
2039                 }
2040         }
2041 }
2042
2043 const int MIN_SPEC_TIME = 1;
2044 bool joinAllowed(entity this)
2045 {
2046         if (CS(this).version_mismatch) return false;
2047         if (time < CS(this).jointime + MIN_SPEC_TIME) return false;
2048         if (!nJoinAllowed(this, this)) return false;
2049         if (teamplay && lockteams) return false;
2050         if (MUTATOR_CALLHOOK(ForbidSpawn, this)) return false;
2051         if (ShowTeamSelection(this)) return false;
2052         return true;
2053 }
2054
2055 .int items_added;
2056 .string shootfromfixedorigin;
2057 bool PlayerThink(entity this)
2058 {
2059         if (game_stopped || intermission_running) {
2060                 this.modelflags &= ~MF_ROCKET;
2061                 if(intermission_running)
2062                         IntermissionThink(this);
2063                 return false;
2064         }
2065
2066         if (timeout_status == TIMEOUT_ACTIVE) {
2067         // don't allow the player to turn around while game is paused
2068                 // FIXME turn this into CSQC stuff
2069                 this.v_angle = this.lastV_angle;
2070                 this.angles = this.lastV_angle;
2071                 this.fixangle = true;
2072         }
2073
2074         if (frametime) player_powerups(this);
2075
2076         if (IS_DEAD(this)) {
2077                 if (this.personal && g_race_qualifying) {
2078                         if (time > this.respawn_time) {
2079                                 STAT(RESPAWN_TIME, this) = this.respawn_time = time + 1; // only retry once a second
2080                                 respawn(this);
2081                                 CS(this).impulse = CHIMPULSE_SPEEDRUN.impulse;
2082                         }
2083                 } else {
2084                         if (frametime) player_anim(this);
2085
2086                         if (this.respawn_flags & RESPAWN_DENY)
2087                         {
2088                                 STAT(RESPAWN_TIME, this) = 0;
2089                                 return false;
2090                         }
2091
2092                         bool button_pressed = (PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_JUMP(this) || PHYS_INPUT_BUTTON_ATCK2(this) || PHYS_INPUT_BUTTON_HOOK(this) || PHYS_INPUT_BUTTON_USE(this));
2093
2094                         switch(this.deadflag)
2095                         {
2096                                 case DEAD_DYING:
2097                                 {
2098                                         if ((this.respawn_flags & RESPAWN_FORCE) && !(this.respawn_time < this.respawn_time_max))
2099                                                 this.deadflag = DEAD_RESPAWNING;
2100                                         else if (!button_pressed || (time >= this.respawn_time_max && (this.respawn_flags & RESPAWN_FORCE)))
2101                                                 this.deadflag = DEAD_DEAD;
2102                                         break;
2103                                 }
2104                                 case DEAD_DEAD:
2105                                 {
2106                                         if (button_pressed)
2107                                                 this.deadflag = DEAD_RESPAWNABLE;
2108                                         else if (time >= this.respawn_time_max && (this.respawn_flags & RESPAWN_FORCE))
2109                                                 this.deadflag = DEAD_RESPAWNING;
2110                                         break;
2111                                 }
2112                                 case DEAD_RESPAWNABLE:
2113                                 {
2114                                         if (!button_pressed || (this.respawn_flags & RESPAWN_FORCE))
2115                                                 this.deadflag = DEAD_RESPAWNING;
2116                                         break;
2117                                 }
2118                                 case DEAD_RESPAWNING:
2119                                 {
2120                                         if (time > this.respawn_time)
2121                                         {
2122                                                 this.respawn_time = time + 1; // only retry once a second
2123                                                 this.respawn_time_max = this.respawn_time;
2124                                                 respawn(this);
2125                                         }
2126                                         break;
2127                                 }
2128                         }
2129
2130                         ShowRespawnCountdown(this);
2131
2132                         if (this.respawn_flags & RESPAWN_SILENT)
2133                                 STAT(RESPAWN_TIME, this) = 0;
2134                         else if ((this.respawn_flags & RESPAWN_FORCE) && this.respawn_time < this.respawn_time_max)
2135                         {
2136                                 if (time < this.respawn_time)
2137                                         STAT(RESPAWN_TIME, this) = this.respawn_time;
2138                                 else if (this.deadflag != DEAD_RESPAWNING)
2139                                         STAT(RESPAWN_TIME, this) = -this.respawn_time_max;
2140                         }
2141                         else
2142                                 STAT(RESPAWN_TIME, this) = this.respawn_time;
2143                 }
2144
2145                 // if respawning, invert stat_respawn_time to indicate this, the client translates it
2146                 if (this.deadflag == DEAD_RESPAWNING && STAT(RESPAWN_TIME, this) > 0)
2147                         STAT(RESPAWN_TIME, this) *= -1;
2148
2149                 return false;
2150         }
2151
2152         FixPlayermodel(this);
2153
2154         if (this.shootfromfixedorigin != autocvar_g_shootfromfixedorigin) {
2155                 this.shootfromfixedorigin = autocvar_g_shootfromfixedorigin;
2156                 stuffcmd(this, sprintf("\ncl_shootfromfixedorigin \"%s\"\n", autocvar_g_shootfromfixedorigin));
2157         }
2158
2159         // LordHavoc: allow firing on move frames (sub-ticrate), this gives better timing on slow servers
2160         //if(frametime)
2161         {
2162                 this.items &= ~this.items_added;
2163
2164                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2165                 {
2166                         .entity weaponentity = weaponentities[slot];
2167                         W_WeaponFrame(this, weaponentity);
2168                 }
2169
2170                 this.items_added = 0;
2171                 if ((this.items & ITEM_Jetpack.m_itemid) && ((this.items & ITEM_JetpackRegen.m_itemid) || GetResourceAmount(this, RESOURCE_FUEL) >= 0.01))
2172             this.items_added |= IT_FUEL;
2173
2174                 this.items |= this.items_added;
2175         }
2176
2177         player_regen(this);
2178
2179         // WEAPONTODO: Add a weapon request for this
2180         // rot vortex charge to the charge limit
2181         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2182         {
2183                 .entity weaponentity = weaponentities[slot];
2184                 if (WEP_CVAR(vortex, charge_rot_rate) && this.(weaponentity).vortex_charge > WEP_CVAR(vortex, charge_limit) && this.(weaponentity).vortex_charge_rottime < time)
2185                         this.(weaponentity).vortex_charge = bound(WEP_CVAR(vortex, charge_limit), this.(weaponentity).vortex_charge - WEP_CVAR(vortex, charge_rot_rate) * frametime / W_TICSPERFRAME, 1);
2186         }
2187
2188         if (frametime) player_anim(this);
2189
2190         // secret status
2191         secrets_setstatus(this);
2192
2193         // monsters status
2194         monsters_setstatus(this);
2195
2196         this.dmg_team = max(0, this.dmg_team - autocvar_g_teamdamage_resetspeed * frametime);
2197
2198         return true;
2199 }
2200
2201 .bool would_spectate;
2202 void ObserverThink(entity this)
2203 {
2204         if ( CS(this).impulse )
2205         {
2206                 MinigameImpulse(this, CS(this).impulse);
2207                 CS(this).impulse = 0;
2208         }
2209
2210         if (this.flags & FL_JUMPRELEASED) {
2211                 if (PHYS_INPUT_BUTTON_JUMP(this) && joinAllowed(this)) {
2212                         this.flags &= ~FL_JUMPRELEASED;
2213                         this.flags |= FL_SPAWNING;
2214                 } else if(PHYS_INPUT_BUTTON_ATCK(this) && !CS(this).version_mismatch || this.would_spectate) {
2215                         this.flags &= ~FL_JUMPRELEASED;
2216                         if(SpectateNext(this)) {
2217                                 TRANSMUTE(Spectator, this);
2218                         }
2219                 } else {
2220                         int preferred_movetype = ((!PHYS_INPUT_BUTTON_USE(this) ? CS(this).cvar_cl_clippedspectating : !CS(this).cvar_cl_clippedspectating) ? MOVETYPE_FLY_WORLDONLY : MOVETYPE_NOCLIP);
2221                         set_movetype(this, preferred_movetype);
2222                 }
2223         } else {
2224                 if (!(PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_JUMP(this))) {
2225                         this.flags |= FL_JUMPRELEASED;
2226                         if(this.flags & FL_SPAWNING)
2227                         {
2228                                 this.flags &= ~FL_SPAWNING;
2229                                 Join(this);
2230                                 return;
2231                         }
2232                 }
2233         }
2234 }
2235
2236 void SpectatorThink(entity this)
2237 {
2238         if ( CS(this).impulse )
2239         {
2240                 if(MinigameImpulse(this, CS(this).impulse))
2241                         CS(this).impulse = 0;
2242
2243                 if (CS(this).impulse == IMP_weapon_drop.impulse)
2244                 {
2245                         STAT(CAMERA_SPECTATOR, this) = (STAT(CAMERA_SPECTATOR, this) + 1) % 3;
2246                         CS(this).impulse = 0;
2247                         return;
2248                 }
2249         }
2250
2251         if (this.flags & FL_JUMPRELEASED) {
2252                 if (PHYS_INPUT_BUTTON_JUMP(this) && joinAllowed(this)) {
2253                         this.flags &= ~FL_JUMPRELEASED;
2254                         this.flags |= FL_SPAWNING;
2255                 } else if(PHYS_INPUT_BUTTON_ATCK(this) || CS(this).impulse == 10 || CS(this).impulse == 15 || CS(this).impulse == 18 || (CS(this).impulse >= 200 && CS(this).impulse <= 209)) {
2256                         this.flags &= ~FL_JUMPRELEASED;
2257                         if(SpectateNext(this)) {
2258                                 TRANSMUTE(Spectator, this);
2259                         } else {
2260                                 TRANSMUTE(Observer, this);
2261                                 PutClientInServer(this);
2262                         }
2263                         CS(this).impulse = 0;
2264                 } else if(CS(this).impulse == 12 || CS(this).impulse == 16  || CS(this).impulse == 19 || (CS(this).impulse >= 220 && CS(this).impulse <= 229)) {
2265                         this.flags &= ~FL_JUMPRELEASED;
2266                         if(SpectatePrev(this)) {
2267                                 TRANSMUTE(Spectator, this);
2268                         } else {
2269                                 TRANSMUTE(Observer, this);
2270                                 PutClientInServer(this);
2271                         }
2272                         CS(this).impulse = 0;
2273                 } else if (PHYS_INPUT_BUTTON_ATCK2(this)) {
2274                         this.would_spectate = false;
2275                         this.flags &= ~FL_JUMPRELEASED;
2276                         TRANSMUTE(Observer, this);
2277                         PutClientInServer(this);
2278                 } else {
2279                         if(!SpectateUpdate(this))
2280                         {
2281                                 if(!SpectateNext(this))
2282                                 {
2283                                         PutObserverInServer(this);
2284                                         this.would_spectate = true;
2285                                 }
2286                         }
2287                 }
2288         } else {
2289                 if (!(PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_ATCK2(this))) {
2290                         this.flags |= FL_JUMPRELEASED;
2291                         if(this.flags & FL_SPAWNING)
2292                         {
2293                                 this.flags &= ~FL_SPAWNING;
2294                                 Join(this);
2295                                 return;
2296                         }
2297                 }
2298                 if(!SpectateUpdate(this))
2299                         PutObserverInServer(this);
2300         }
2301
2302         this.flags |= FL_CLIENT | FL_NOTARGET;
2303 }
2304
2305 void PlayerUseKey(entity this)
2306 {
2307         if (!IS_PLAYER(this))
2308                 return;
2309
2310         if(this.vehicle)
2311         {
2312                 if(!game_stopped)
2313                 {
2314                         vehicles_exit(this.vehicle, VHEF_NORMAL);
2315                         return;
2316                 }
2317         }
2318         else if(autocvar_g_vehicles_enter)
2319         {
2320                 if(!STAT(FROZEN, this))
2321                 if(!IS_DEAD(this))
2322                 if(!game_stopped)
2323                 {
2324                         entity head, closest_target = NULL;
2325                         head = WarpZone_FindRadius(this.origin, autocvar_g_vehicles_enter_radius, true);
2326
2327                         while(head) // find the closest acceptable target to enter
2328                         {
2329                                 if(IS_VEHICLE(head))
2330                                 if(!IS_DEAD(head))
2331                                 if(!head.owner || ((head.vehicle_flags & VHF_MULTISLOT) && SAME_TEAM(head.owner, this)))
2332                                 if(head.takedamage != DAMAGE_NO)
2333                                 {
2334                                         if(closest_target)
2335                                         {
2336                                                 if(vlen2(this.origin - head.origin) < vlen2(this.origin - closest_target.origin))
2337                                                 { closest_target = head; }
2338                                         }
2339                                         else { closest_target = head; }
2340                                 }
2341
2342                                 head = head.chain;
2343                         }
2344
2345                         if(closest_target) { vehicles_enter(this, closest_target); return; }
2346                 }
2347         }
2348
2349         // a use key was pressed; call handlers
2350         MUTATOR_CALLHOOK(PlayerUseKey, this);
2351 }
2352
2353
2354 /*
2355 =============
2356 PlayerPreThink
2357
2358 Called every frame for each client before the physics are run
2359 =============
2360 */
2361 .float last_vehiclecheck;
2362 void PlayerPreThink (entity this)
2363 {
2364         STAT(GUNALIGN, this) = CS(this).cvar_cl_gunalign; // TODO
2365         STAT(MOVEVARS_CL_TRACK_CANJUMP, this) = CS(this).cvar_cl_movement_track_canjump;
2366
2367         WarpZone_PlayerPhysics_FixVAngle(this);
2368
2369         if (frametime) {
2370                 // physics frames: update anticheat stuff
2371                 anticheat_prethink(this);
2372         }
2373
2374         if (blockSpectators && frametime) {
2375                 // WORKAROUND: only use dropclient in server frames (frametime set).
2376                 // Never use it in cl_movement frames (frametime zero).
2377                 checkSpectatorBlock(this);
2378         }
2379
2380         zoomstate_set = false;
2381
2382         // Check for nameless players
2383         if (this.netname == "" || this.netname != CS(this).netname_previous)
2384         {
2385                 bool assume_unchanged = (CS(this).netname_previous == "");
2386                 if (isInvisibleString(this.netname))
2387                 {
2388                         this.netname = strzone(sprintf("Player#%d", this.playerid));
2389                         assume_unchanged = false;
2390                         // stuffcmd(this, strcat("name ", this.netname, "\n")); // maybe?
2391                 }
2392                 if (!assume_unchanged && autocvar_sv_eventlog)
2393                         GameLogEcho(strcat(":name:", ftos(this.playerid), ":", playername(this, false)));
2394                 strcpy(CS(this).netname_previous, this.netname);
2395         }
2396
2397         // version nagging
2398         if (CS(this).version_nagtime && CS(this).cvar_g_xonoticversion && time > CS(this).version_nagtime) {
2399         CS(this).version_nagtime = 0;
2400         if (strstrofs(CS(this).cvar_g_xonoticversion, "git", 0) >= 0 || strstrofs(CS(this).cvar_g_xonoticversion, "autobuild", 0) >= 0) {
2401             // git client
2402         } else if (strstrofs(autocvar_g_xonoticversion, "git", 0) >= 0 || strstrofs(autocvar_g_xonoticversion, "autobuild", 0) >= 0) {
2403             // git server
2404             Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_BETA, autocvar_g_xonoticversion, CS(this).cvar_g_xonoticversion);
2405         } else {
2406             int r = vercmp(CS(this).cvar_g_xonoticversion, autocvar_g_xonoticversion);
2407             if (r < 0) { // old client
2408                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_OUTDATED, autocvar_g_xonoticversion, CS(this).cvar_g_xonoticversion);
2409             } else if (r > 0) { // old server
2410                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_OLD, autocvar_g_xonoticversion, CS(this).cvar_g_xonoticversion);
2411             }
2412         }
2413     }
2414
2415         // GOD MODE info
2416         if (!(this.flags & FL_GODMODE) && this.max_armorvalue)
2417         {
2418                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_GODMODE_OFF, this.max_armorvalue);
2419                 this.max_armorvalue = 0;
2420         }
2421
2422         if(IS_PLAYER(this))
2423         {
2424                 if (STAT(FROZEN, this) == FROZEN_TEMP_REVIVING)
2425                 {
2426                         STAT(REVIVE_PROGRESS, this) = bound(0, STAT(REVIVE_PROGRESS, this) + frametime * this.revive_speed, 1);
2427                         SetResourceAmountExplicit(this, RESOURCE_HEALTH, max(1, STAT(REVIVE_PROGRESS, this) * start_health));
2428                         this.iceblock.alpha = bound(0.2, 1 - STAT(REVIVE_PROGRESS, this), 1);
2429
2430                         if (STAT(REVIVE_PROGRESS, this) >= 1)
2431                                 Unfreeze(this, false);
2432                 }
2433                 else if (STAT(FROZEN, this) == FROZEN_TEMP_DYING)
2434                 {
2435                         STAT(REVIVE_PROGRESS, this) = bound(0, STAT(REVIVE_PROGRESS, this) - frametime * this.revive_speed, 1);
2436                         SetResourceAmountExplicit(this, RESOURCE_HEALTH, max(0, autocvar_g_nades_ice_health + (start_health-autocvar_g_nades_ice_health) * STAT(REVIVE_PROGRESS, this)));
2437
2438                         if (GetResourceAmount(this, RESOURCE_HEALTH) < 1)
2439                         {
2440                                 if (this.vehicle)
2441                                         vehicles_exit(this.vehicle, VHEF_RELEASE);
2442                                 if(this.event_damage)
2443                                         this.event_damage(this, this, this.frozen_by, 1, DEATH_NADE_ICE_FREEZE.m_id, DMG_NOWEP, this.origin, '0 0 0');
2444                         }
2445                         else if (STAT(REVIVE_PROGRESS, this) <= 0)
2446                                 Unfreeze(this, false);
2447                 }
2448         }
2449
2450         MUTATOR_CALLHOOK(PlayerPreThink, this);
2451
2452         if(autocvar_g_vehicles_enter && (time > this.last_vehiclecheck) && !game_stopped && !this.vehicle)
2453         if(IS_PLAYER(this) && !STAT(FROZEN, this) && !IS_DEAD(this))
2454         {
2455                 FOREACH_ENTITY_RADIUS(this.origin, autocvar_g_vehicles_enter_radius, IS_VEHICLE(it),
2456                 {
2457                         if(!IS_DEAD(it) && it.takedamage != DAMAGE_NO)
2458                         if((it.vehicle_flags & VHF_MULTISLOT) && SAME_TEAM(it.owner, this))
2459                         {
2460                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER_GUNNER);
2461                         }
2462                         else if(!it.owner)
2463                         {
2464                                 if(!it.team || SAME_TEAM(this, it))
2465                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER);
2466                                 else if(autocvar_g_vehicles_steal)
2467                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER_STEAL);
2468                         }
2469                 });
2470
2471                 this.last_vehiclecheck = time + 1;
2472         }
2473
2474         if(!CS(this).cvar_cl_newusekeysupported) // FIXME remove this - it was a stupid idea to begin with, we can JUST use the button
2475         {
2476                 if(PHYS_INPUT_BUTTON_USE(this) && !CS(this).usekeypressed)
2477                         PlayerUseKey(this);
2478                 CS(this).usekeypressed = PHYS_INPUT_BUTTON_USE(this);
2479         }
2480
2481         if (IS_REAL_CLIENT(this))
2482                 PrintWelcomeMessage(this);
2483
2484         if (IS_PLAYER(this)) {
2485                 if (IS_REAL_CLIENT(this) && time < CS(this).jointime + MIN_SPEC_TIME)
2486                         error("Client can't be spawned as player on connection!");
2487                 if(!PlayerThink(this))
2488                         return;
2489         }
2490         else if (game_stopped || intermission_running) {
2491                 if(intermission_running)
2492                         IntermissionThink(this);
2493                 return;
2494         }
2495         else if (IS_REAL_CLIENT(this) && !CS(this).autojoin_checked && time >= CS(this).jointime + MIN_SPEC_TIME)
2496         {
2497                 CS(this).autojoin_checked = true;
2498                 // don't do this in ClientConnect
2499                 // many things can go wrong if a client is spawned as player on connection
2500                 if (MUTATOR_CALLHOOK(AutoJoinOnConnection, this)
2501                         || (!(autocvar_sv_spectate || autocvar_g_campaign || (Player_GetForcedTeamIndex(this) == TEAM_FORCE_SPECTATOR))
2502                                 && (!teamplay || autocvar_g_balance_teams)))
2503                 {
2504                         campaign_bots_may_start = true;
2505                         Join(this);
2506                         return;
2507                 }
2508         }
2509         else if (IS_OBSERVER(this)) {
2510                 ObserverThink(this);
2511         }
2512         else if (IS_SPEC(this)) {
2513                 SpectatorThink(this);
2514         }
2515
2516         // WEAPONTODO: Add weapon request for this
2517         if (!zoomstate_set) {
2518                 bool wep_zoomed = false;
2519                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2520                 {
2521                         .entity weaponentity = weaponentities[slot];
2522                         Weapon thiswep = this.(weaponentity).m_weapon;
2523                         if(thiswep != WEP_Null && thiswep.wr_zoom)
2524                                 wep_zoomed += thiswep.wr_zoom(thiswep, this);
2525                 }
2526                 SetZoomState(this, PHYS_INPUT_BUTTON_ZOOM(this) || PHYS_INPUT_BUTTON_ZOOMSCRIPT(this) || wep_zoomed);
2527     }
2528
2529         if (CS(this).teamkill_soundtime && time > CS(this).teamkill_soundtime)
2530         {
2531                 CS(this).teamkill_soundtime = 0;
2532
2533                 entity e = CS(this).teamkill_soundsource;
2534                 entity oldpusher = e.pusher;
2535                 e.pusher = this;
2536                 PlayerSound(e, playersound_teamshoot, CH_VOICE, VOL_BASEVOICE, VOICETYPE_LASTATTACKER_ONLY);
2537                 e.pusher = oldpusher;
2538         }
2539
2540         if (CS(this).taunt_soundtime && time > CS(this).taunt_soundtime) {
2541                 CS(this).taunt_soundtime = 0;
2542                 PlayerSound(this, playersound_taunt, CH_VOICE, VOL_BASEVOICE, VOICETYPE_AUTOTAUNT);
2543         }
2544
2545         target_voicescript_next(this);
2546
2547         // WEAPONTODO: Move into weaponsystem somehow
2548         // if a player goes unarmed after holding a loaded weapon, empty his clip size and remove the crosshair ammo ring
2549         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2550         {
2551                 .entity weaponentity = weaponentities[slot];
2552                 if(this.(weaponentity).m_weapon == WEP_Null)
2553                         this.(weaponentity).clip_load = this.(weaponentity).clip_size = 0;
2554         }
2555 }
2556
2557 void DrownPlayer(entity this)
2558 {
2559         if(IS_DEAD(this) || game_stopped || time < game_starttime)
2560                 return;
2561
2562         if (this.waterlevel != WATERLEVEL_SUBMERGED || this.vehicle)
2563         {
2564                 if(this.air_finished < time)
2565                         PlayerSound(this, playersound_gasp, CH_PLAYER, VOL_BASE, VOICETYPE_PLAYERSOUND);
2566                 this.air_finished = time + autocvar_g_balance_contents_drowndelay;
2567         }
2568         else if (this.air_finished < time)
2569         {       // drown!
2570                 if (this.pain_finished < time)
2571                 {
2572                         Damage (this, NULL, NULL, autocvar_g_balance_contents_playerdamage_drowning * autocvar_g_balance_contents_damagerate, DEATH_DROWN.m_id, DMG_NOWEP, this.origin, '0 0 0');
2573                         this.pain_finished = time + 0.5;
2574                 }
2575         }
2576 }
2577
2578 .bool move_qcphysics;
2579
2580 void Player_Physics(entity this)
2581 {
2582         this.movetype = (this.move_qcphysics) ? MOVETYPE_QCPLAYER : this.move_movetype;
2583
2584         if(!this.move_qcphysics)
2585                 return;
2586
2587         if(!frametime && !CS(this).pm_frametime)
2588                 return;
2589
2590         Movetype_Physics_NoMatchTicrate(this, CS(this).pm_frametime, true);
2591
2592         CS(this).pm_frametime = 0;
2593 }
2594
2595 /*
2596 =============
2597 PlayerPostThink
2598
2599 Called every frame for each client after the physics are run
2600 =============
2601 */
2602 void PlayerPostThink (entity this)
2603 {
2604         Player_Physics(this);
2605
2606         if (sv_maxidle > 0)
2607         if (frametime) // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2608         if (IS_REAL_CLIENT(this))
2609         if (IS_PLAYER(this) || sv_maxidle_spectatorsareidle)
2610         {
2611                 int totalClients = 0;
2612                 if(sv_maxidle_slots > 0)
2613                 {
2614                         FOREACH_CLIENT(IS_REAL_CLIENT(it) || sv_maxidle_slots_countbots,
2615                         {
2616                                 ++totalClients;
2617                         });
2618                 }
2619
2620                 if (sv_maxidle_slots > 0 && (maxclients - totalClients) > sv_maxidle_slots)
2621                 { /* do nothing */ }
2622                 else if (time - CS(this).parm_idlesince < 1) // instead of (time == this.parm_idlesince) to support sv_maxidle <= 10
2623                 {
2624                         if (CS(this).idlekick_lasttimeleft)
2625                         {
2626                                 CS(this).idlekick_lasttimeleft = 0;
2627                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_IDLING);
2628                         }
2629                 }
2630                 else
2631                 {
2632                         float timeleft = ceil(sv_maxidle - (time - CS(this).parm_idlesince));
2633                         if (timeleft == min(10, sv_maxidle - 1)) { // - 1 to support sv_maxidle <= 10
2634                                 if (!CS(this).idlekick_lasttimeleft)
2635                                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_DISCONNECT_IDLING, timeleft);
2636                         }
2637                         if (timeleft <= 0) {
2638                                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_QUIT_KICK_IDLING, this.netname);
2639                                 dropclient(this);
2640                                 return;
2641                         }
2642                         else if (timeleft <= 10) {
2643                                 if (timeleft != CS(this).idlekick_lasttimeleft) {
2644                                     Send_Notification(NOTIF_ONE, this, MSG_ANNCE, Announcer_PickNumber(CNT_IDLE, timeleft));
2645                 }
2646                                 CS(this).idlekick_lasttimeleft = timeleft;
2647                         }
2648                 }
2649         }
2650
2651         CheatFrame(this);
2652
2653         if (game_stopped)
2654         {
2655                 this.solid = SOLID_NOT;
2656                 this.takedamage = DAMAGE_NO;
2657                 set_movetype(this, MOVETYPE_NONE);
2658         }
2659
2660         if (IS_PLAYER(this)) {
2661                 if(this.death_time == time && IS_DEAD(this))
2662                 {
2663                         // player's bbox gets resized now, instead of in the damage event that killed the player,
2664                         // once all the damage events of this frame have been processed with normal size
2665                         this.maxs.z = 5;
2666                         setsize(this, this.mins, this.maxs);
2667                 }
2668                 DrownPlayer(this);
2669                 UpdateChatBubble(this);
2670                 if (CS(this).impulse) ImpulseCommands(this);
2671                 if (game_stopped)
2672                 {
2673                         CSQCMODEL_AUTOUPDATE(this);
2674                         return;
2675                 }
2676                 GetPressedKeys(this);
2677         }
2678
2679         if (this.waypointsprite_attachedforcarrier) {
2680             vector v = healtharmor_maxdamage(GetResourceAmount(this, RESOURCE_HEALTH), GetResourceAmount(this, RESOURCE_ARMOR), autocvar_g_balance_armor_blockpercent, DEATH_WEAPON.m_id);
2681                 WaypointSprite_UpdateHealth(this.waypointsprite_attachedforcarrier, '1 0 0' * v);
2682     }
2683
2684         CSQCMODEL_AUTOUPDATE(this);
2685 }
2686
2687 /**
2688  * message "": do not say, just test flood control
2689  * return value:
2690  *   1 = accept
2691  *   0 = reject
2692  *  -1 = fake accept
2693  */
2694 int Say(entity source, int teamsay, entity privatesay, string msgin, bool floodcontrol)
2695 {
2696         if (!teamsay && !privatesay && substring(msgin, 0, 1) == " ")
2697                 msgin = substring(msgin, 1, -1); // work around DP say bug (say_team does not have this!)
2698
2699         if (source)
2700                 msgin = formatmessage(source, msgin);
2701
2702         string colorstr;
2703         if (!(IS_PLAYER(source) || source.caplayer))
2704                 colorstr = "^0"; // black for spectators
2705         else if(teamplay)
2706                 colorstr = Team_ColorCode(source.team);
2707         else
2708         {
2709                 colorstr = "";
2710                 teamsay = false;
2711         }
2712
2713         if(game_stopped)
2714                 teamsay = false;
2715
2716         if (!source) {
2717                 colorstr = "";
2718                 teamsay = false;
2719         }
2720
2721         if(msgin != "")
2722                 msgin = trigger_magicear_processmessage_forallears(source, teamsay, privatesay, msgin);
2723
2724         /*
2725          * using bprint solves this... me stupid
2726         // how can we prevent the message from appearing in a listen server?
2727         // for now, just give "say" back and only handle say_team
2728         if(!teamsay)
2729         {
2730                 clientcommand(source, strcat("say ", msgin));
2731                 return;
2732         }
2733         */
2734
2735         string namestr = "";
2736         if (source)
2737                 namestr = playername(source, autocvar_g_chat_teamcolors);
2738
2739         string colorprefix = (strdecolorize(namestr) == namestr) ? "^3" : "^7";
2740
2741         string msgstr = "", cmsgstr = "";
2742         string privatemsgprefix = string_null;
2743         int privatemsgprefixlen = 0;
2744         if (msgin != "")
2745         {
2746                 if(privatesay)
2747                 {
2748                         msgstr = strcat("\{1}\{13}* ", colorprefix, namestr, "^3 tells you: ^7");
2749                         privatemsgprefixlen = strlen(msgstr);
2750                         msgstr = strcat(msgstr, msgin);
2751                         cmsgstr = strcat(colorstr, colorprefix, namestr, "^3 tells you:\n^7", msgin);
2752                         privatemsgprefix = strcat("\{1}\{13}* ^3You tell ", playername(privatesay, autocvar_g_chat_teamcolors), ": ^7");
2753                 }
2754                 else if(teamsay)
2755                 {
2756                         if(strstrofs(msgin, "/me", 0) >= 0)
2757                         {
2758                                 //msgin = strreplace("/me", "", msgin);
2759                                 //msgin = substring(msgin, 3, strlen(msgin));
2760                                 msgin = strreplace("/me", strcat(colorstr, "(", colorprefix, namestr, colorstr, ")^7"), msgin);
2761                                 msgstr = strcat("\{1}\{13}^4* ", "^7", msgin);
2762                         }
2763                         else
2764                                 msgstr = strcat("\{1}\{13}", colorstr, "(", colorprefix, namestr, colorstr, ") ^7", msgin);
2765                         cmsgstr = strcat(colorstr, "(", colorprefix, namestr, colorstr, ")\n^7", msgin);
2766                 }
2767                 else
2768                 {
2769                         if(strstrofs(msgin, "/me", 0) >= 0)
2770                         {
2771                                 //msgin = strreplace("/me", "", msgin);
2772                                 //msgin = substring(msgin, 3, strlen(msgin));
2773                                 msgin = strreplace("/me", strcat(colorprefix, namestr), msgin);
2774                                 msgstr = strcat("\{1}^4* ", "^7", msgin);
2775                         }
2776                         else {
2777                                 msgstr = "\{1}";
2778                                 msgstr = strcat(msgstr, (namestr != "") ? strcat(colorprefix, namestr, "^7: ") : "^7");
2779                                 msgstr = strcat(msgstr, msgin);
2780                         }
2781                         cmsgstr = "";
2782                 }
2783                 msgstr = strcat(strreplace("\n", " ", msgstr), "\n"); // newlines only are good for centerprint
2784         }
2785
2786         string fullmsgstr = msgstr;
2787         string fullcmsgstr = cmsgstr;
2788
2789         // FLOOD CONTROL
2790         int flood = 0;
2791         var .float flood_field = floodcontrol_chat;
2792         if(floodcontrol && source)
2793         {
2794                 float flood_spl;
2795                 float flood_burst;
2796                 float flood_lmax;
2797                 float lines;
2798                 if(privatesay)
2799                 {
2800                         flood_spl = autocvar_g_chat_flood_spl_tell;
2801                         flood_burst = autocvar_g_chat_flood_burst_tell;
2802                         flood_lmax = autocvar_g_chat_flood_lmax_tell;
2803                         flood_field = floodcontrol_chattell;
2804                 }
2805                 else if(teamsay)
2806                 {
2807                         flood_spl = autocvar_g_chat_flood_spl_team;
2808                         flood_burst = autocvar_g_chat_flood_burst_team;
2809                         flood_lmax = autocvar_g_chat_flood_lmax_team;
2810                         flood_field = floodcontrol_chatteam;
2811                 }
2812                 else
2813                 {
2814                         flood_spl = autocvar_g_chat_flood_spl;
2815                         flood_burst = autocvar_g_chat_flood_burst;
2816                         flood_lmax = autocvar_g_chat_flood_lmax;
2817                         flood_field = floodcontrol_chat;
2818                 }
2819                 flood_burst = max(0, flood_burst - 1);
2820                 // to match explanation in default.cfg, a value of 3 must allow three-line bursts and not four!
2821
2822                 // do flood control for the default line size
2823                 if(msgstr != "")
2824                 {
2825                         getWrappedLine_remaining = msgstr;
2826                         msgstr = "";
2827                         lines = 0;
2828                         while(getWrappedLine_remaining && (!flood_lmax || lines <= flood_lmax))
2829                         {
2830                                 msgstr = strcat(msgstr, " ", getWrappedLineLen(82.4289758859709, strlennocol)); // perl averagewidth.pl < gfx/vera-sans.width
2831                                 ++lines;
2832                         }
2833                         msgstr = substring(msgstr, 1, strlen(msgstr) - 1);
2834
2835                         if(getWrappedLine_remaining != "")
2836                         {
2837                                 msgstr = strcat(msgstr, "\n");
2838                                 flood = 2;
2839                         }
2840
2841                         if (time >= source.(flood_field))
2842                         {
2843                                 source.(flood_field) = max(time - flood_burst * flood_spl, source.(flood_field)) + lines * flood_spl;
2844                         }
2845                         else
2846                         {
2847                                 flood = 1;
2848                                 msgstr = fullmsgstr;
2849                         }
2850                 }
2851                 else
2852                 {
2853                         if (time >= source.(flood_field))
2854                                 source.(flood_field) = max(time - flood_burst * flood_spl, source.(flood_field)) + flood_spl;
2855                         else
2856                                 flood = 1;
2857                 }
2858
2859                 if (timeout_status == TIMEOUT_ACTIVE) // when game is paused, no flood protection
2860                         source.(flood_field) = flood = 0;
2861         }
2862
2863         string sourcemsgstr, sourcecmsgstr;
2864         if(flood == 2) // cannot happen for empty msgstr
2865         {
2866                 if(autocvar_g_chat_flood_notify_flooder)
2867                 {
2868                         sourcemsgstr = strcat(msgstr, "\n^3FLOOD CONTROL: ^7message too long, trimmed\n");
2869                         sourcecmsgstr = "";
2870                 }
2871                 else
2872                 {
2873                         sourcemsgstr = fullmsgstr;
2874                         sourcecmsgstr = fullcmsgstr;
2875                 }
2876                 cmsgstr = "";
2877         }
2878         else
2879         {
2880                 sourcemsgstr = msgstr;
2881                 sourcecmsgstr = cmsgstr;
2882         }
2883
2884         if (!privatesay && source && !(IS_PLAYER(source) || source.caplayer))
2885         {
2886                 if (!game_stopped)
2887                 if (teamsay || (autocvar_g_chat_nospectators == 1) || (autocvar_g_chat_nospectators == 2 && !warmup_stage))
2888                         teamsay = -1; // spectators
2889         }
2890
2891         if(flood)
2892                 LOG_INFO("NOTE: ", playername(source, true), "^7 is flooding.");
2893
2894         // build sourcemsgstr by cutting off a prefix and replacing it by the other one
2895         if(privatesay)
2896                 sourcemsgstr = strcat(privatemsgprefix, substring(sourcemsgstr, privatemsgprefixlen, -1));
2897
2898         int ret;
2899         if(source && CS(source).muted)
2900         {
2901                 // always fake the message
2902                 ret = -1;
2903         }
2904         else if(flood == 1)
2905         {
2906                 if (autocvar_g_chat_flood_notify_flooder)
2907                 {
2908                         sprint(source, strcat("^3FLOOD CONTROL: ^7wait ^1", ftos(source.(flood_field) - time), "^3 seconds\n"));
2909                         ret = 0;
2910                 }
2911                 else
2912                         ret = -1;
2913         }
2914         else
2915         {
2916                 ret = 1;
2917         }
2918
2919         if (privatesay && source && !(IS_PLAYER(source) || source.caplayer))
2920         {
2921                 if (!game_stopped)
2922                 if ((privatesay && (IS_PLAYER(privatesay) || privatesay.caplayer)) && ((autocvar_g_chat_nospectators == 1) || (autocvar_g_chat_nospectators == 2 && !warmup_stage)))
2923                         ret = -1; // just hide the message completely
2924         }
2925
2926         MUTATOR_CALLHOOK(ChatMessage, source, ret);
2927         ret = M_ARGV(1, int);
2928
2929         if(sourcemsgstr != "" && ret != 0)
2930         {
2931                 if(ret < 0) // faked message, because the player is muted
2932                 {
2933                         sprint(source, sourcemsgstr);
2934                         if(sourcecmsgstr != "" && !privatesay)
2935                                 centerprint(source, sourcecmsgstr);
2936                 }
2937                 else if(privatesay) // private message, between 2 people only
2938                 {
2939                         sprint(source, sourcemsgstr);
2940                         if (!autocvar_g_chat_tellprivacy) { dedicated_print(msgstr); } // send to server console too if "tellprivacy" is disabled
2941                         if(!MUTATOR_CALLHOOK(ChatMessageTo, privatesay, source))
2942                         {
2943                                 sprint(privatesay, msgstr);
2944                                 if(cmsgstr != "")
2945                                         centerprint(privatesay, cmsgstr);
2946                         }
2947                 }
2948                 else if ( teamsay && CS(source).active_minigame )
2949                 {
2950                         sprint(source, sourcemsgstr);
2951                         dedicated_print(msgstr); // send to server console too
2952                         FOREACH_CLIENT(IS_REAL_CLIENT(it) && it != source && CS(it).active_minigame == CS(source).active_minigame && !MUTATOR_CALLHOOK(ChatMessageTo, it, source), {
2953                                 sprint(it, msgstr);
2954                         });
2955                 }
2956                 else if(teamsay > 0) // team message, only sent to team mates
2957                 {
2958                         sprint(source, sourcemsgstr);
2959                         dedicated_print(msgstr); // send to server console too
2960                         if(sourcecmsgstr != "")
2961                                 centerprint(source, sourcecmsgstr);
2962                         FOREACH_CLIENT((IS_PLAYER(it) || it.caplayer) && IS_REAL_CLIENT(it) && it != source && it.team == source.team && !MUTATOR_CALLHOOK(ChatMessageTo, it, source), {
2963                                 sprint(it, msgstr);
2964                                 if(cmsgstr != "")
2965                                         centerprint(it, cmsgstr);
2966                         });
2967                 }
2968                 else if(teamsay < 0) // spectator message, only sent to spectators
2969                 {
2970                         sprint(source, sourcemsgstr);
2971                         dedicated_print(msgstr); // send to server console too
2972                         FOREACH_CLIENT(!(IS_PLAYER(it) || it.caplayer) && IS_REAL_CLIENT(it) && it != source && !MUTATOR_CALLHOOK(ChatMessageTo, it, source), {
2973                                 sprint(it, msgstr);
2974                         });
2975                 }
2976                 else
2977                 {
2978                         if (source) {
2979                                 sprint(source, sourcemsgstr);
2980                                 dedicated_print(msgstr); // send to server console too
2981                                 MX_Say(strcat(playername(source, true), "^7: ", msgin));
2982                         }
2983                         FOREACH_CLIENT(IS_REAL_CLIENT(it) && it != source && !MUTATOR_CALLHOOK(ChatMessageTo, it, source), {
2984                                 sprint(it, msgstr);
2985                         });
2986                 }
2987         }
2988
2989         return ret;
2990 }
2991
2992 // hack to copy the button fields from the client entity to the Client State
2993 void PM_UpdateButtons(entity this, entity store)
2994 {
2995         if(this.impulse)
2996                 store.impulse = this.impulse;
2997         this.impulse = 0;
2998
2999         bool typing = this.buttonchat || this.button14;
3000
3001         store.button0 = (typing) ? 0 : this.button0;
3002         //button1?!
3003         store.button2 = (typing) ? 0 : this.button2;
3004         store.button3 = (typing) ? 0 : this.button3;
3005         store.button4 = this.button4;
3006         store.button5 = (typing) ? 0 : this.button5;
3007         store.button6 = this.button6;
3008         store.button7 = this.button7;
3009         store.button8 = this.button8;
3010         store.button9 = this.button9;
3011         store.button10 = this.button10;
3012         store.button11 = this.button11;
3013         store.button12 = this.button12;
3014         store.button13 = this.button13;
3015         store.button14 = this.button14;
3016         store.button15 = this.button15;
3017         store.button16 = this.button16;
3018         store.buttonuse = this.buttonuse;
3019         store.buttonchat = this.buttonchat;
3020
3021         store.cursor_active = this.cursor_active;
3022         store.cursor_screen = this.cursor_screen;
3023         store.cursor_trace_start = this.cursor_trace_start;
3024         store.cursor_trace_endpos = this.cursor_trace_endpos;
3025         store.cursor_trace_ent = this.cursor_trace_ent;
3026
3027         store.ping = this.ping;
3028         store.ping_packetloss = this.ping_packetloss;
3029         store.ping_movementloss = this.ping_movementloss;
3030
3031         store.v_angle = this.v_angle;
3032         store.movement = (typing) ? '0 0 0' : this.movement;
3033 }
3034
3035 NET_HANDLE(fpsreport, bool)
3036 {
3037         int fps = ReadShort();
3038         PlayerScore_Set(sender, SP_FPS, fps);
3039         return true;
3040 }