qcsrc/server/client.qc

   1 #include "client.qh"
   2
   3 #include "anticheat.qh"
   4 #include "impulse.qh"
   5 #include "player.qh"
   6 #include "ipban.qh"
   7 #include "miscfunctions.qh"
   8 #include "portals.qh"
   9 #include "teamplay.qh"
  10 #include "playerdemo.qh"
  11 #include "spawnpoints.qh"
  12 #include "g_damage.qh"
  13 #include "g_hook.qh"
  14 #include "command/common.qh"
  15 #include "cheats.qh"
  16 #include "g_world.qh"
  17 #include "race.qh"
  18 #include "antilag.qh"
  19 #include "campaign.qh"
  20 #include "command/common.qh"
  21 #include "scores_rules.qh"
  22
  23 #include "bot/api.qh"
  24
  25 #include "../common/ent_cs.qh"
  26 #include "../common/wepent.qh"
  27 #include <common/state.qh>
  28
  29 #include <common/effects/qc/globalsound.qh>
  30
  31 #include "../common/triggers/func/conveyor.qh"
  32 #include "../common/triggers/teleporters.qh"
  33
  34 #include "../common/vehicles/all.qh"
  35
  36 #include "weapons/hitplot.qh"
  37 #include "weapons/weaponsystem.qh"
  38
  39 #include "../common/net_notice.qh"
  40 #include "../common/net_linked.qh"
  41 #include "../common/physics/player.qh"
  42
  43 #include "../common/items/_mod.qh"
  44
  45 #include "../common/mutators/mutator/waypoints/all.qh"
  46
  47 #include "../common/triggers/subs.qh"
  48 #include "../common/triggers/triggers.qh"
  49 #include "../common/triggers/trigger/secret.qh"
  50
  51 #include "../common/minigames/sv_minigames.qh"
  52
  53 #include "../common/items/inventory.qh"
  54
  55 #include "../common/monsters/sv_monsters.qh"
  56
  57 #include "../lib/warpzone/server.qh"
  58
  59 STATIC_METHOD(Client, Add, void(Client this, int _team))
  60 {
  61     ClientConnect(this);
  62     TRANSMUTE(Player, this);
  63     this.frame = 12; // 7
  64     this.team = _team;
  65     PutClientInServer(this);
  66 }
  67
  68 void PutObserverInServer(entity this);
  69
  70 STATIC_METHOD(Client, Remove, void(Client this))
  71 {
  72     TRANSMUTE(Observer, this);
  73     PutClientInServer(this);
  74     ClientDisconnect(this);
  75 }
  76
  77 void send_CSQC_teamnagger() {
  78         WriteHeader(MSG_BROADCAST, TE_CSQC_TEAMNAGGER);
  79 }
  80
  81 int CountSpectators(entity player, entity to)
  82 {
  83         if(!player) { return 0; } // not sure how, but best to be safe
  84
  85         int spec_count = 0;
  86
  87         FOREACH_CLIENT(IS_REAL_CLIENT(it) && IS_SPEC(it) && it != to && it.enemy == player,
  88         {
  89                 spec_count++;
  90         });
  91
  92         return spec_count;
  93 }
  94
  95 void WriteSpectators(entity player, entity to)
  96 {
  97         if(!player) { return; } // not sure how, but best to be safe
  98
  99         FOREACH_CLIENT(IS_REAL_CLIENT(it) && IS_SPEC(it) && it != to && it.enemy == player,
 100         {
 101                 WriteByte(MSG_ENTITY, num_for_edict(it));
 102         });
 103 }
 104
 105 bool ClientData_Send(entity this, entity to, int sf)
 106 {
 107         assert(to == this.owner, return false);
 108
 109         entity e = to;
 110         if (IS_SPEC(e)) e = e.enemy;
 111
 112         sf = 0;
 113         if (e.race_completed)       sf |= 1; // forced scoreboard
 114         if (to.spectatee_status)    sf |= 2; // spectator ent number follows
 115         if (e.zoomstate)            sf |= 4; // zoomed
 116         if (autocvar_sv_showspectators) sf |= 16; // show spectators
 117
 118         WriteHeader(MSG_ENTITY, ENT_CLIENT_CLIENTDATA);
 119         WriteByte(MSG_ENTITY, sf);
 120
 121         if (sf & 2)
 122         {
 123                 WriteByte(MSG_ENTITY, to.spectatee_status);
 124         }
 125
 126         if(sf & 16)
 127         {
 128                 float specs = CountSpectators(e, to);
 129                 WriteByte(MSG_ENTITY, specs);
 130                 WriteSpectators(e, to);
 131         }
 132
 133         return true;
 134 }
 135
 136 void ClientData_Attach(entity this)
 137 {
 138         Net_LinkEntity(this.clientdata = new_pure(clientdata), false, 0, ClientData_Send);
 139         this.clientdata.drawonlytoclient = this;
 140         this.clientdata.owner = this;
 141 }
 142
 143 void ClientData_Detach(entity this)
 144 {
 145         delete(this.clientdata);
 146         this.clientdata = NULL;
 147 }
 148
 149 void ClientData_Touch(entity e)
 150 {
 151         e.clientdata.SendFlags = 1;
 152
 153         // make it spectatable
 154         FOREACH_CLIENT(IS_REAL_CLIENT(it) && it != e && IS_SPEC(it) && it.enemy == e, LAMBDA(it.clientdata.SendFlags = 1));
 155 }
 156
 157 .string netname_previous;
 158
 159 void SetSpectatee(entity this, entity spectatee);
 160 void SetSpectatee_status(entity this, int spectatee_num);
 161
 162
 163 /*
 164 =============
 165 CheckPlayerModel
 166
 167 Checks if the argument string can be a valid playermodel.
 168 Returns a valid one in doubt.
 169 =============
 170 */
 171 string FallbackPlayerModel;
 172 string CheckPlayerModel(string plyermodel) {
 173         if(FallbackPlayerModel != cvar_defstring("_cl_playermodel"))
 174         {
 175                 // note: we cannot summon Don Strunzone here, some player may
 176                 // still have the model string set. In case anyone manages how
 177                 // to change a cvar default, we'll have a small leak here.
 178                 FallbackPlayerModel = strzone(cvar_defstring("_cl_playermodel"));
 179         }
 180         // only in right path
 181         if( substring(plyermodel,0,14) != "models/player/")
 182                 return FallbackPlayerModel;
 183         // only good file extensions
 184         if(substring(plyermodel,-4,4) != ".zym")
 185         if(substring(plyermodel,-4,4) != ".dpm")
 186         if(substring(plyermodel,-4,4) != ".iqm")
 187         if(substring(plyermodel,-4,4) != ".md3")
 188         if(substring(plyermodel,-4,4) != ".psk")
 189                 return FallbackPlayerModel;
 190         // forbid the LOD models
 191         if(substring(plyermodel, -9,5) == "_lod1")
 192                 return FallbackPlayerModel;
 193         if(substring(plyermodel, -9,5) == "_lod2")
 194                 return FallbackPlayerModel;
 195         if(plyermodel != strtolower(plyermodel))
 196                 return FallbackPlayerModel;
 197         // also, restrict to server models
 198         if(autocvar_sv_servermodelsonly)
 199         {
 200                 if(!fexists(plyermodel))
 201                         return FallbackPlayerModel;
 202         }
 203         return plyermodel;
 204 }
 205
 206 void setplayermodel(entity e, string modelname)
 207 {
 208         precache_model(modelname);
 209         _setmodel(e, modelname);
 210         player_setupanimsformodel(e);
 211         if(!autocvar_g_debug_globalsounds)
 212                 UpdatePlayerSounds(e);
 213 }
 214
 215 void FixPlayermodel(entity player);
 216 /** putting a client as observer in the server */
 217 void PutObserverInServer(entity this)
 218 {
 219     bool mutator_returnvalue = MUTATOR_CALLHOOK(MakePlayerObserver, this);
 220         PlayerState_detach(this);
 221
 222         if (IS_PLAYER(this) && this.health >= 1) {
 223         // despawn effect
 224                 Send_Effect(EFFECT_SPAWN_NEUTRAL, this.origin, '0 0 0', 1);
 225     }
 226
 227     {
 228         entity spot = SelectSpawnPoint(this, true);
 229         if (!spot) LOG_FATAL("No spawnpoints for observers?!?");
 230         this.angles = spot.angles;
 231         this.angles_z = 0;
 232         this.fixangle = true;
 233         // offset it so that the spectator spawns higher off the ground, looks better this way
 234         setorigin(this, spot.origin + STAT(PL_VIEW_OFS, NULL));
 235         this.prevorigin = this.origin;
 236         if (IS_REAL_CLIENT(this))
 237         {
 238             msg_entity = this;
 239             WriteByte(MSG_ONE, SVC_SETVIEW);
 240             WriteEntity(MSG_ONE, this);
 241         }
 242         // give the spectator some space between walls for MOVETYPE_FLY_WORLDONLY
 243         // so that your view doesn't go into the ceiling with MOVETYPE_FLY_WORLDONLY, previously "PL_VIEW_OFS"
 244         if(!autocvar_g_debug_globalsounds)
 245         {
 246                 // needed for player sounds
 247                 this.model = "";
 248                 FixPlayermodel(this);
 249         }
 250         setmodel(this, MDL_Null);
 251         setsize(this, STAT(PL_CROUCH_MIN, NULL), STAT(PL_CROUCH_MAX, NULL));
 252         this.view_ofs = '0 0 0';
 253     }
 254
 255     RemoveGrapplingHooks(this);
 256         Portal_ClearAll(this);
 257         Unfreeze(this);
 258         SetSpectatee(this, NULL);
 259
 260         if (this.alivetime)
 261         {
 262                 if (!warmup_stage)
 263                         PS_GR_P_ADDVAL(this, PLAYERSTATS_ALIVETIME, time - this.alivetime);
 264                 this.alivetime = 0;
 265         }
 266
 267         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
 268
 269         WaypointSprite_PlayerDead(this);
 270
 271         if (mutator_returnvalue) {
 272             // mutator prevents resetting teams+score
 273         } else {
 274                 this.team = -1;  // move this as it is needed to log the player spectating in eventlog
 275         this.frags = FRAGS_SPECTATOR;
 276         PlayerScore_Clear(this);  // clear scores when needed
 277     }
 278
 279         if (this.killcount != FRAGS_SPECTATOR)
 280         {
 281                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_QUIT_SPECTATE, this.netname);
 282                 if(!intermission_running)
 283                 if(autocvar_g_chat_nospectators == 1 || (!(warmup_stage || gameover) && autocvar_g_chat_nospectators == 2))
 284                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_CHAT_NOSPECTATORS);
 285
 286                 if(this.just_joined == false) {
 287                         LogTeamchange(this.playerid, -1, 4);
 288                 } else
 289                         this.just_joined = false;
 290         }
 291
 292         accuracy_resend(this);
 293
 294         this.spectatortime = time;
 295         if(this.bot_attack)
 296                 IL_REMOVE(g_bot_targets, this);
 297         this.bot_attack = false;
 298     this.hud = HUD_NORMAL;
 299         TRANSMUTE(Observer, this);
 300         this.iscreature = false;
 301         this.teleportable = TELEPORT_SIMPLE;
 302         if(this.damagedbycontents)
 303                 IL_REMOVE(g_damagedbycontents, this);
 304         this.damagedbycontents = false;
 305         this.health = FRAGS_SPECTATOR;
 306         SetSpectatee_status(this, etof(this));
 307         this.takedamage = DAMAGE_NO;
 308         this.solid = SOLID_NOT;
 309         set_movetype(this, MOVETYPE_FLY_WORLDONLY); // user preference is controlled by playerprethink
 310         this.flags = FL_CLIENT | FL_NOTARGET;
 311         this.armorvalue = 666;
 312         this.effects = 0;
 313         this.armorvalue = autocvar_g_balance_armor_start;
 314         this.pauserotarmor_finished = 0;
 315         this.pauserothealth_finished = 0;
 316         this.pauseregen_finished = 0;
 317         this.damageforcescale = 0;
 318         this.death_time = 0;
 319         this.respawn_flags = 0;
 320         this.respawn_time = 0;
 321         this.stat_respawn_time = 0;
 322         this.alpha = 0;
 323         this.scale = 0;
 324         this.fade_time = 0;
 325         this.pain_frame = 0;
 326         this.pain_finished = 0;
 327         this.strength_finished = 0;
 328         this.invincible_finished = 0;
 329         this.superweapons_finished = 0;
 330         this.pushltime = 0;
 331         this.istypefrag = 0;
 332         setthink(this, func_null);
 333         this.nextthink = 0;
 334         this.deadflag = DEAD_NO;
 335         this.crouch = false;
 336         this.revival_time = 0;
 337
 338         this.items = 0;
 339         this.weapons = '0 0 0';
 340         this.drawonlytoclient = this;
 341
 342         this.weaponmodel = "";
 343         for (int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 344         {
 345                 if(!this.weaponentities[slot])
 346                         continue; // first load
 347                 this.weaponentities[slot].hook_time = 0;
 348                 this.weaponentities[slot].weaponname = "";
 349                 this.weaponentities[slot] = NULL;
 350         }
 351         this.exteriorweaponentity = NULL;
 352         this.killcount = FRAGS_SPECTATOR;
 353         this.velocity = '0 0 0';
 354         this.avelocity = '0 0 0';
 355         this.punchangle = '0 0 0';
 356         this.punchvector = '0 0 0';
 357         this.oldvelocity = this.velocity;
 358         this.fire_endtime = -1;
 359         this.event_damage = func_null;
 360 }
 361
 362 int player_getspecies(entity this)
 363 {
 364         get_model_parameters(this.model, this.skin);
 365         int s = get_model_parameters_species;
 366         get_model_parameters(string_null, 0);
 367         if (s < 0) return SPECIES_HUMAN;
 368         return s;
 369 }
 370
 371 .float model_randomizer;
 372 void FixPlayermodel(entity player)
 373 {
 374         string defaultmodel = "";
 375         int defaultskin = 0;
 376         if(autocvar_sv_defaultcharacter)
 377         {
 378                 if(teamplay)
 379                 {
 380                         string s = Static_Team_ColorName_Lower(player.team);
 381                         if (s != "neutral")
 382                         {
 383                                 defaultmodel = cvar_string(strcat("sv_defaultplayermodel_", s));
 384                                 defaultskin = cvar(strcat("sv_defaultplayerskin_", s));
 385                         }
 386                 }
 387
 388                 if(defaultmodel == "")
 389                 {
 390                         defaultmodel = autocvar_sv_defaultplayermodel;
 391                         defaultskin = autocvar_sv_defaultplayerskin;
 392                 }
 393
 394                 int n = tokenize_console(defaultmodel);
 395                 if(n > 0)
 396                 {
 397                         defaultmodel = argv(floor(n * player.model_randomizer));
 398                         // However, do NOT randomize if the player-selected model is in the list.
 399                         for (int i = 0; i < n; ++i)
 400                                 if ((argv(i) == player.playermodel && defaultskin == stof(player.playerskin)) || argv(i) == strcat(player.playermodel, ":", player.playerskin))
 401                                         defaultmodel = argv(i);
 402                 }
 403
 404                 int i = strstrofs(defaultmodel, ":", 0);
 405                 if(i >= 0)
 406                 {
 407                         defaultskin = stof(substring(defaultmodel, i+1, -1));
 408                         defaultmodel = substring(defaultmodel, 0, i);
 409                 }
 410         }
 411         if(autocvar_sv_defaultcharacterskin && !defaultskin)
 412         {
 413                 if(teamplay)
 414                 {
 415                         string s = Static_Team_ColorName_Lower(player.team);
 416                         if (s != "neutral")
 417                                 defaultskin = cvar(strcat("sv_defaultplayerskin_", s));
 418                 }
 419
 420                 if(!defaultskin)
 421                         defaultskin = autocvar_sv_defaultplayerskin;
 422         }
 423
 424         MUTATOR_CALLHOOK(FixPlayermodel, defaultmodel, defaultskin, player);
 425         defaultmodel = M_ARGV(0, string);
 426         defaultskin = M_ARGV(1, int);
 427
 428         bool chmdl = false;
 429         int oldskin;
 430         if(defaultmodel != "")
 431         {
 432                 if (defaultmodel != player.model)
 433                 {
 434                         vector m1 = player.mins;
 435                         vector m2 = player.maxs;
 436                         setplayermodel (player, defaultmodel);
 437                         setsize (player, m1, m2);
 438                         chmdl = true;
 439                 }
 440
 441                 oldskin = player.skin;
 442                 player.skin = defaultskin;
 443         } else {
 444                 if (player.playermodel != player.model || player.playermodel == "")
 445                 {
 446                         player.playermodel = CheckPlayerModel(player.playermodel); // this is never "", so no endless loop
 447                         vector m1 = player.mins;
 448                         vector m2 = player.maxs;
 449                         setplayermodel (player, player.playermodel);
 450                         setsize (player, m1, m2);
 451                         chmdl = true;
 452                 }
 453
 454                 if(!autocvar_sv_defaultcharacterskin)
 455                 {
 456                         oldskin = player.skin;
 457                         player.skin = stof(player.playerskin);
 458                 }
 459                 else
 460                 {
 461                         oldskin = player.skin;
 462                         player.skin = defaultskin;
 463                 }
 464         }
 465
 466         if(chmdl || oldskin != player.skin) // model or skin has changed
 467         {
 468                 player.species = player_getspecies(player); // update species
 469                 if(!autocvar_g_debug_globalsounds)
 470                         UpdatePlayerSounds(player); // update skin sounds
 471         }
 472
 473         if(!teamplay)
 474                 if(strlen(autocvar_sv_defaultplayercolors))
 475                         if(player.clientcolors != stof(autocvar_sv_defaultplayercolors))
 476                                 setcolor(player, stof(autocvar_sv_defaultplayercolors));
 477 }
 478
 479
 480 /** Called when a client spawns in the server */
 481 void PutClientInServer(entity this)
 482 {
 483         if (IS_BOT_CLIENT(this)) {
 484                 TRANSMUTE(Player, this);
 485         } else if (IS_REAL_CLIENT(this)) {
 486                 msg_entity = this;
 487                 WriteByte(MSG_ONE, SVC_SETVIEW);
 488                 WriteEntity(MSG_ONE, this);
 489         }
 490         if (gameover) {
 491                 TRANSMUTE(Observer, this);
 492         }
 493
 494         SetSpectatee(this, NULL);
 495
 496         // reset player keys
 497         this.itemkeys = 0;
 498
 499         MUTATOR_CALLHOOK(PutClientInServer, this);
 500
 501         if (IS_OBSERVER(this)) {
 502                 PutObserverInServer(this);
 503         } else if (IS_PLAYER(this)) {
 504                 if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
 505
 506                 PlayerState_attach(this);
 507                 accuracy_resend(this);
 508
 509                 if (this.team < 0)
 510                         JoinBestTeam(this, false, true);
 511
 512                 entity spot = SelectSpawnPoint(this, false);
 513                 if (!spot) {
 514                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_JOIN_NOSPAWNS);
 515                         return; // spawn failed
 516                 }
 517
 518                 TRANSMUTE(Player, this);
 519
 520                 this.wasplayer = true;
 521                 this.iscreature = true;
 522                 this.teleportable = TELEPORT_NORMAL;
 523                 if(!this.damagedbycontents)
 524                         IL_PUSH(g_damagedbycontents, this);
 525                 this.damagedbycontents = true;
 526                 set_movetype(this, MOVETYPE_WALK);
 527                 this.solid = SOLID_SLIDEBOX;
 528                 this.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_SOLID;
 529                 if (autocvar_g_playerclip_collisions)
 530                         this.dphitcontentsmask |= DPCONTENTS_PLAYERCLIP;
 531                 if (IS_BOT_CLIENT(this) && autocvar_g_botclip_collisions)
 532                         this.dphitcontentsmask |= DPCONTENTS_BOTCLIP;
 533                 this.frags = FRAGS_PLAYER;
 534                 if (INDEPENDENT_PLAYERS) MAKE_INDEPENDENT_PLAYER(this);
 535                 this.flags = FL_CLIENT | FL_PICKUPITEMS;
 536                 if (autocvar__notarget)
 537                         this.flags |= FL_NOTARGET;
 538                 this.takedamage = DAMAGE_AIM;
 539                 this.effects = EF_TELEPORT_BIT | EF_RESTARTANIM_BIT;
 540                 this.dmg = 2; // WTF
 541
 542                 if (warmup_stage) {
 543                         this.ammo_shells = warmup_start_ammo_shells;
 544                         this.ammo_nails = warmup_start_ammo_nails;
 545                         this.ammo_rockets = warmup_start_ammo_rockets;
 546                         this.ammo_cells = warmup_start_ammo_cells;
 547                         this.ammo_plasma = warmup_start_ammo_plasma;
 548                         this.ammo_fuel = warmup_start_ammo_fuel;
 549                         this.health = warmup_start_health;
 550                         this.armorvalue = warmup_start_armorvalue;
 551                         this.weapons = WARMUP_START_WEAPONS;
 552                 } else {
 553                         this.ammo_shells = start_ammo_shells;
 554                         this.ammo_nails = start_ammo_nails;
 555                         this.ammo_rockets = start_ammo_rockets;
 556                         this.ammo_cells = start_ammo_cells;
 557                         this.ammo_plasma = start_ammo_plasma;
 558                         this.ammo_fuel = start_ammo_fuel;
 559                         this.health = start_health;
 560                         this.armorvalue = start_armorvalue;
 561                         this.weapons = start_weapons;
 562                 }
 563                 SetSpectatee_status(this, 0);
 564
 565                 this.superweapons_finished = (this.weapons & WEPSET_SUPERWEAPONS) ? time + autocvar_g_balance_superweapons_time : 0;
 566
 567                 this.items = start_items;
 568
 569                 this.spawnshieldtime = time + autocvar_g_spawnshieldtime;
 570                 this.pauserotarmor_finished = time + autocvar_g_balance_pause_armor_rot_spawn;
 571                 this.pauserothealth_finished = time + autocvar_g_balance_pause_health_rot_spawn;
 572                 this.pauserotfuel_finished = time + autocvar_g_balance_pause_fuel_rot_spawn;
 573                 this.pauseregen_finished = time + autocvar_g_balance_pause_health_regen_spawn;
 574                 // extend the pause of rotting if client was reset at the beginning of the countdown
 575                 if (!autocvar_sv_ready_restart_after_countdown && time < game_starttime) { // TODO why is this cvar NOTted?
 576                         float f = game_starttime - time;
 577                         this.spawnshieldtime += f;
 578                         this.pauserotarmor_finished += f;
 579                         this.pauserothealth_finished += f;
 580                         this.pauseregen_finished += f;
 581                 }
 582                 this.damageforcescale = 2;
 583                 this.death_time = 0;
 584                 this.respawn_flags = 0;
 585                 this.respawn_time = 0;
 586                 this.stat_respawn_time = 0;
 587                 this.scale = autocvar_sv_player_scale;
 588                 this.fade_time = 0;
 589                 this.pain_frame = 0;
 590                 this.pain_finished = 0;
 591                 this.pushltime = 0;
 592                 setthink(this, func_null); // players have no think function
 593                 this.nextthink = 0;
 594                 this.dmg_team = 0;
 595                 this.ballistics_density = autocvar_g_ballistics_density_player;
 596
 597                 this.deadflag = DEAD_NO;
 598
 599                 this.angles = spot.angles;
 600                 this.angles_z = 0; // never spawn tilted even if the spot says to
 601                 if (IS_BOT_CLIENT(this))
 602                         this.v_angle = this.angles;
 603                 this.fixangle = true; // turn this way immediately
 604                 this.oldvelocity = this.velocity = '0 0 0';
 605                 this.avelocity = '0 0 0';
 606                 this.punchangle = '0 0 0';
 607                 this.punchvector = '0 0 0';
 608
 609                 this.strength_finished = 0;
 610                 this.invincible_finished = 0;
 611                 this.fire_endtime = -1;
 612                 this.revival_time = 0;
 613                 this.air_finished = time + 12;
 614
 615                 entity spawnevent = new_pure(spawnevent);
 616                 spawnevent.owner = this;
 617                 Net_LinkEntity(spawnevent, false, 0.5, SpawnEvent_Send);
 618
 619                 // Cut off any still running player sounds.
 620                 stopsound(this, CH_PLAYER_SINGLE);
 621
 622                 this.model = "";
 623                 FixPlayermodel(this);
 624                 this.drawonlytoclient = NULL;
 625
 626                 this.viewloc = NULL;
 627
 628                 this.crouch = false;
 629                 this.view_ofs = STAT(PL_VIEW_OFS, this);
 630                 setsize(this, STAT(PL_MIN, this), STAT(PL_MAX, this));
 631                 this.spawnorigin = spot.origin;
 632                 setorigin(this, spot.origin + '0 0 1' * (1 - this.mins.z - 24));
 633                 // don't reset back to last position, even if new position is stuck in solid
 634                 this.oldorigin = this.origin;
 635                 this.prevorigin = this.origin;
 636                 this.lastteleporttime = time; // prevent insane speeds due to changing origin
 637                 if(this.conveyor)
 638                         IL_REMOVE(g_conveyed, this);
 639                 this.conveyor = NULL; // prevent conveyors at the previous location from moving a freshly spawned player
 640                 this.hud = HUD_NORMAL;
 641
 642                 this.event_damage = PlayerDamage;
 643
 644                 if(!this.bot_attack)
 645                         IL_PUSH(g_bot_targets, this);
 646                 this.bot_attack = true;
 647                 this.monster_attack = true;
 648
 649                 PHYS_INPUT_BUTTON_ATCK(this) = PHYS_INPUT_BUTTON_JUMP(this) = PHYS_INPUT_BUTTON_ATCK2(this) = false;
 650
 651                 if (this.killcount == FRAGS_SPECTATOR) {
 652                         PlayerScore_Clear(this);
 653                         this.killcount = 0;
 654                 }
 655
 656                 for (int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 657                 {
 658                         .entity weaponentity = weaponentities[slot];
 659                         CL_SpawnWeaponentity(this, weaponentity);
 660                 }
 661                 this.alpha = default_player_alpha;
 662                 this.colormod = '1 1 1' * autocvar_g_player_brightness;
 663                 this.exteriorweaponentity.alpha = default_weapon_alpha;
 664
 665                 this.speedrunning = false;
 666
 667                 target_voicescript_clear(this);
 668
 669                 // reset fields the weapons may use
 670                 FOREACH(Weapons, true, LAMBDA(
 671                         it.wr_resetplayer(it, this);
 672                         // reload all reloadable weapons
 673                         if (it.spawnflags & WEP_FLAG_RELOADABLE) {
 674                                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 675                                 {
 676                                         .entity weaponentity = weaponentities[slot];
 677                                         this.(weaponentity).weapon_load[it.m_id] = it.reloading_ammo;
 678                                 }
 679                         }
 680                 ));
 681
 682                 {
 683                         string s = spot.target;
 684                         spot.target = string_null;
 685                         SUB_UseTargets(spot, this, NULL);
 686                         spot.target = s;
 687                 }
 688
 689                 Unfreeze(this);
 690
 691                 MUTATOR_CALLHOOK(PlayerSpawn, this, spot);
 692
 693                 if (autocvar_spawn_debug)
 694                 {
 695                         sprint(this, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
 696                         delete(spot); // usefull for checking if there are spawnpoints, that let drop through the floor
 697                 }
 698
 699                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 700                 {
 701                         .entity weaponentity = weaponentities[slot];
 702                         if(slot == 0)
 703                                 this.(weaponentity).m_switchweapon = w_getbestweapon(this, weaponentity);
 704                         else
 705                                 this.(weaponentity).m_switchweapon = WEP_Null;
 706                         this.(weaponentity).m_weapon = WEP_Null;
 707                         this.(weaponentity).weaponname = "";
 708                         this.(weaponentity).m_switchingweapon = WEP_Null;
 709                         this.(weaponentity).cnt = -1;
 710                 }
 711
 712                 if (!warmup_stage && !this.alivetime)
 713                         this.alivetime = time;
 714
 715                 antilag_clear(this, CS(this));
 716         }
 717 }
 718
 719 void ClientInit_misc(entity this);
 720
 721 // TODO do we need all these fields, or should we stop autodetecting runtime
 722 // changes and just have a console command to update this?
 723 bool ClientInit_SendEntity(entity this, entity to, int sf)
 724 {
 725         WriteHeader(MSG_ENTITY, _ENT_CLIENT_INIT);
 726         return = true;
 727         msg_entity = to;
 728         // MSG_INIT replacement
 729         // TODO: make easier to use
 730         Registry_send_all();
 731         W_PROP_reload(MSG_ONE, to);
 732         ClientInit_misc(this);
 733         MUTATOR_CALLHOOK(Ent_Init);
 734 }
 735 void ClientInit_misc(entity this)
 736 {
 737         int channel = MSG_ONE;
 738         WriteHeader(channel, ENT_CLIENT_INIT);
 739         WriteByte(channel, g_nexball_meter_period * 32);
 740         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[0]));
 741         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[1]));
 742         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[2]));
 743         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[3]));
 744         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[0]));
 745         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[1]));
 746         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[2]));
 747         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[3]));
 748
 749         if(sv_foginterval && world.fog != "")
 750                 WriteString(channel, world.fog);
 751         else
 752                 WriteString(channel, "");
 753         WriteByte(channel, this.count * 255.0); // g_balance_armor_blockpercent
 754         WriteByte(channel, serverflags);
 755         WriteCoord(channel, autocvar_g_trueaim_minrange);
 756 }
 757
 758 void ClientInit_CheckUpdate(entity this)
 759 {
 760         this.nextthink = time;
 761         if(this.count != autocvar_g_balance_armor_blockpercent)
 762         {
 763                 this.count = autocvar_g_balance_armor_blockpercent;
 764                 this.SendFlags |= 1;
 765         }
 766 }
 767
 768 void ClientInit_Spawn()
 769 {
 770         entity e = new_pure(clientinit);
 771         setthink(e, ClientInit_CheckUpdate);
 772         Net_LinkEntity(e, false, 0, ClientInit_SendEntity);
 773
 774         ClientInit_CheckUpdate(e);
 775 }
 776
 777 /*
 778 =============
 779 SetNewParms
 780 =============
 781 */
 782 void SetNewParms ()
 783 {
 784         // initialize parms for a new player
 785         parm1 = -(86400 * 366);
 786
 787         MUTATOR_CALLHOOK(SetNewParms);
 788 }
 789
 790 /*
 791 =============
 792 SetChangeParms
 793 =============
 794 */
 795 void SetChangeParms (entity this)
 796 {
 797         // save parms for level change
 798         parm1 = this.parm_idlesince - time;
 799
 800         MUTATOR_CALLHOOK(SetChangeParms);
 801 }
 802
 803 /*
 804 =============
 805 DecodeLevelParms
 806 =============
 807 */
 808 void DecodeLevelParms(entity this)
 809 {
 810         // load parms
 811         this.parm_idlesince = parm1;
 812         if (this.parm_idlesince == -(86400 * 366))
 813                 this.parm_idlesince = time;
 814
 815         // whatever happens, allow 60 seconds of idling directly after connect for map loading
 816         this.parm_idlesince = max(this.parm_idlesince, time - sv_maxidle + 60);
 817
 818         MUTATOR_CALLHOOK(DecodeLevelParms);
 819 }
 820
 821 /*
 822 =============
 823 ClientKill
 824
 825 Called when a client types 'kill' in the console
 826 =============
 827 */
 828
 829 .float clientkill_nexttime;
 830 void ClientKill_Now_TeamChange(entity this)
 831 {
 832         if(this.killindicator_teamchange == -1)
 833         {
 834                 JoinBestTeam( this, false, true );
 835         }
 836         else if(this.killindicator_teamchange == -2)
 837         {
 838                 if(blockSpectators)
 839                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
 840                 PutObserverInServer(this);
 841         }
 842         else
 843                 SV_ChangeTeam(this, this.killindicator_teamchange - 1);
 844         this.killindicator_teamchange = 0;
 845 }
 846
 847 void ClientKill_Now(entity this)
 848 {
 849         if(this.vehicle)
 850         {
 851             vehicles_exit(this.vehicle, VHEF_RELEASE);
 852             if(!this.killindicator_teamchange)
 853             {
 854             this.vehicle_health = -1;
 855             Damage(this, this, this, 1 , DEATH_KILL.m_id, this.origin, '0 0 0');
 856             }
 857         }
 858
 859         if(this.killindicator && !wasfreed(this.killindicator))
 860                 delete(this.killindicator);
 861
 862         this.killindicator = NULL;
 863
 864         if(this.killindicator_teamchange)
 865                 ClientKill_Now_TeamChange(this);
 866
 867         if(!IS_SPEC(this) && !IS_OBSERVER(this))
 868                 Damage(this, this, this, 100000, DEATH_KILL.m_id, this.origin, '0 0 0');
 869
 870         // now I am sure the player IS dead
 871 }
 872 void KillIndicator_Think(entity this)
 873 {
 874         if (gameover)
 875         {
 876                 this.owner.killindicator = NULL;
 877                 delete(this);
 878                 return;
 879         }
 880
 881         if (this.owner.alpha < 0 && !this.owner.vehicle)
 882         {
 883                 this.owner.killindicator = NULL;
 884                 delete(this);
 885                 return;
 886         }
 887
 888         if(this.cnt <= 0)
 889         {
 890                 ClientKill_Now(this.owner);
 891                 return;
 892         }
 893     else if(g_cts && this.health == 1) // health == 1 means that it's silent
 894     {
 895         this.nextthink = time + 1;
 896         this.cnt -= 1;
 897     }
 898         else
 899         {
 900                 if(this.cnt <= 10)
 901                         setmodel(this, MDL_NUM(this.cnt));
 902                 if(IS_REAL_CLIENT(this.owner))
 903                 {
 904                         if(this.cnt <= 10)
 905                                 { Send_Notification(NOTIF_ONE, this.owner, MSG_ANNCE, Announcer_PickNumber(CNT_KILL, this.cnt)); }
 906                 }
 907                 this.nextthink = time + 1;
 908                 this.cnt -= 1;
 909         }
 910 }
 911
 912 float clientkilltime;
 913 void ClientKill_TeamChange (entity this, float targetteam) // 0 = don't change, -1 = auto, -2 = spec
 914 {
 915         float killtime;
 916         float starttime;
 917
 918         if (gameover)
 919                 return;
 920
 921         killtime = autocvar_g_balance_kill_delay;
 922
 923         if(g_race_qualifying || g_cts)
 924                 killtime = 0;
 925
 926     if(MUTATOR_CALLHOOK(ClientKill, this, killtime))
 927         return;
 928
 929         this.killindicator_teamchange = targetteam;
 930
 931     if(!this.killindicator)
 932         {
 933                 if(!IS_DEAD(this))
 934                 {
 935                         killtime = max(killtime, this.clientkill_nexttime - time);
 936                         this.clientkill_nexttime = time + killtime + autocvar_g_balance_kill_antispam;
 937                 }
 938
 939                 if(killtime <= 0 || !IS_PLAYER(this) || IS_DEAD(this))
 940                 {
 941                         ClientKill_Now(this);
 942                 }
 943                 else
 944                 {
 945                         starttime = max(time, clientkilltime);
 946
 947                         this.killindicator = spawn();
 948                         this.killindicator.owner = this;
 949                         this.killindicator.scale = 0.5;
 950                         setattachment(this.killindicator, this, "");
 951                         setorigin(this.killindicator, '0 0 52');
 952                         setthink(this.killindicator, KillIndicator_Think);
 953                         this.killindicator.nextthink = starttime + (this.lip) * 0.05;
 954                         clientkilltime = max(clientkilltime, this.killindicator.nextthink + 0.05);
 955                         this.killindicator.cnt = ceil(killtime);
 956                         this.killindicator.count = bound(0, ceil(killtime), 10);
 957                         //sprint(this, strcat("^1You'll be dead in ", ftos(this.killindicator.cnt), " seconds\n"));
 958
 959                         IL_EACH(g_clones, it.enemy == this && !(it.effects & CSQCMODEL_EF_RESPAWNGHOST),
 960                         {
 961                                 it.killindicator = spawn();
 962                                 it.killindicator.owner = it;
 963                                 it.killindicator.scale = 0.5;
 964                                 setattachment(it.killindicator, it, "");
 965                                 setorigin(it.killindicator, '0 0 52');
 966                                 setthink(it.killindicator, KillIndicator_Think);
 967                                 it.killindicator.nextthink = starttime + (it.lip) * 0.05;
 968                                 //clientkilltime = max(clientkilltime, it.killindicator.nextthink + 0.05);
 969                                 it.killindicator.cnt = ceil(killtime);
 970                         });
 971                         this.lip = 0;
 972                 }
 973         }
 974         if(this.killindicator)
 975         {
 976                 if(targetteam == 0) // just die
 977                 {
 978                         this.killindicator.colormod = '0 0 0';
 979                         if(IS_REAL_CLIENT(this))
 980                         if(this.killindicator.cnt > 0)
 981                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_TEAMCHANGE_SUICIDE, this.killindicator.cnt);
 982                 }
 983                 else if(targetteam == -1) // auto
 984                 {
 985                         this.killindicator.colormod = '0 1 0';
 986                         if(IS_REAL_CLIENT(this))
 987                         if(this.killindicator.cnt > 0)
 988                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_TEAMCHANGE_AUTO, this.killindicator.cnt);
 989                 }
 990                 else if(targetteam == -2) // spectate
 991                 {
 992                         this.killindicator.colormod = '0.5 0.5 0.5';
 993                         if(IS_REAL_CLIENT(this))
 994                         if(this.killindicator.cnt > 0)
 995                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_TEAMCHANGE_SPECTATE, this.killindicator.cnt);
 996                 }
 997                 else
 998                 {
 999                         this.killindicator.colormod = Team_ColorRGB(targetteam);
1000                         if(IS_REAL_CLIENT(this))
1001                         if(this.killindicator.cnt > 0)
1002                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, APP_TEAM_NUM(targetteam, CENTER_TEAMCHANGE), this.killindicator.cnt);
1003                 }
1004         }
1005
1006 }
1007
1008 void ClientKill (entity this)
1009 {
1010         if(gameover) return;
1011         if(this.player_blocked) return;
1012         if(STAT(FROZEN, this)) return;
1013
1014         ClientKill_TeamChange(this, 0);
1015 }
1016
1017 void FixClientCvars(entity e)
1018 {
1019         // send prediction settings to the client
1020         stuffcmd(e, "\nin_bindmap 0 0\n");
1021         if(autocvar_g_antilag == 3) // client side hitscan
1022                 stuffcmd(e, "cl_cmd settemp cl_prydoncursor_notrace 0\n");
1023         if(autocvar_sv_gentle)
1024                 stuffcmd(e, "cl_cmd settemp cl_gentle 1\n");
1025
1026         MUTATOR_CALLHOOK(FixClientCvars, e);
1027 }
1028
1029 float PlayerInIDList(entity p, string idlist)
1030 {
1031         float n, i;
1032         string s;
1033
1034         // NOTE: we do NOT check crypto_idfp_signed here, an unsigned ID is fine too for this
1035         if (!p.crypto_idfp)
1036                 return 0;
1037
1038         // this function allows abbreviated player IDs too!
1039         n = tokenize_console(idlist);
1040         for(i = 0; i < n; ++i)
1041         {
1042                 s = argv(i);
1043                 if(s == substring(p.crypto_idfp, 0, strlen(s)))
1044                         return 1;
1045         }
1046
1047         return 0;
1048 }
1049
1050 #ifdef DP_EXT_PRECONNECT
1051 /*
1052 =============
1053 ClientPreConnect
1054
1055 Called once (not at each match start) when a client begins a connection to the server
1056 =============
1057 */
1058 void ClientPreConnect ()
1059 {ENGINE_EVENT();
1060         if(autocvar_sv_eventlog)
1061         {
1062                 GameLogEcho(sprintf(":connect:%d:%d:%s",
1063                         this.playerid,
1064                         etof(this),
1065                         ((IS_REAL_CLIENT(this)) ? this.netaddress : "bot")
1066                 ));
1067         }
1068 }
1069 #endif
1070
1071 /**
1072 =============
1073 ClientConnect
1074
1075 Called when a client connects to the server
1076 =============
1077 */
1078 void ClientConnect(entity this)
1079 {
1080         if (Ban_MaybeEnforceBanOnce(this)) return;
1081         assert(!IS_CLIENT(this), return);
1082         this.flags |= FL_CLIENT;
1083         assert(player_count >= 0, player_count = 0);
1084
1085 #ifdef WATERMARK
1086         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_WATERMARK, WATERMARK);
1087 #endif
1088         this.version_nagtime = time + 10 + random() * 10;
1089         TRANSMUTE(Client, this);
1090
1091         // identify the right forced team
1092         if (autocvar_g_campaign)
1093         {
1094                 if (IS_REAL_CLIENT(this)) // only players, not bots
1095                 {
1096                         switch (autocvar_g_campaign_forceteam)
1097                         {
1098                                 case 1: this.team_forced = NUM_TEAM_1; break;
1099                                 case 2: this.team_forced = NUM_TEAM_2; break;
1100                                 case 3: this.team_forced = NUM_TEAM_3; break;
1101                                 case 4: this.team_forced = NUM_TEAM_4; break;
1102                                 default: this.team_forced = 0;
1103                         }
1104                 }
1105         }
1106         else if (PlayerInIDList(this, autocvar_g_forced_team_red))    this.team_forced = NUM_TEAM_1;
1107         else if (PlayerInIDList(this, autocvar_g_forced_team_blue))   this.team_forced = NUM_TEAM_2;
1108         else if (PlayerInIDList(this, autocvar_g_forced_team_yellow)) this.team_forced = NUM_TEAM_3;
1109         else if (PlayerInIDList(this, autocvar_g_forced_team_pink))   this.team_forced = NUM_TEAM_4;
1110         else switch (autocvar_g_forced_team_otherwise)
1111         {
1112                 default: this.team_forced = 0; break;
1113                 case "red": this.team_forced = NUM_TEAM_1; break;
1114                 case "blue": this.team_forced = NUM_TEAM_2; break;
1115                 case "yellow": this.team_forced = NUM_TEAM_3; break;
1116                 case "pink": this.team_forced = NUM_TEAM_4; break;
1117                 case "spectate":
1118                 case "spectator":
1119                         this.team_forced = -1;
1120                         break;
1121         }
1122         if (!teamplay && this.team_forced > 0) this.team_forced = 0;
1123
1124     {
1125         int id = this.playerid;
1126         this.playerid = 0; // silent
1127             JoinBestTeam(this, false, false); // if the team number is valid, keep it
1128             this.playerid = id;
1129     }
1130
1131         if (autocvar_sv_spectate || autocvar_g_campaign || this.team_forced < 0) {
1132                 TRANSMUTE(Observer, this);
1133         } else {
1134                 if (!teamplay || autocvar_g_balance_teams) {
1135                         TRANSMUTE(Player, this);
1136                         campaign_bots_may_start = true;
1137                 } else {
1138                         TRANSMUTE(Observer, this); // do it anyway
1139                 }
1140         }
1141
1142         PlayerStats_GameReport_AddEvent(sprintf("kills-%d", this.playerid));
1143
1144         // always track bots, don't ask for cl_allow_uidtracking
1145     if (IS_BOT_CLIENT(this)) PlayerStats_GameReport_AddPlayer(this);
1146
1147         if (autocvar_sv_eventlog)
1148                 GameLogEcho(strcat(":join:", ftos(this.playerid), ":", ftos(etof(this)), ":", ((IS_REAL_CLIENT(this)) ? this.netaddress : "bot"), ":", this.netname));
1149
1150         LogTeamchange(this.playerid, this.team, 1);
1151
1152         this.just_joined = true;  // stop spamming the eventlog with additional lines when the client connects
1153
1154         this.netname_previous = strzone(this.netname);
1155
1156         if(teamplay && IS_PLAYER(this))
1157                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, APP_TEAM_NUM(this.team, INFO_JOIN_CONNECT_TEAM), this.netname);
1158         else
1159                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_JOIN_CONNECT, this.netname);
1160
1161         stuffcmd(this, clientstuff, "\n");
1162         stuffcmd(this, "cl_particles_reloadeffects\n"); // TODO do we still need this?
1163
1164         FixClientCvars(this);
1165
1166         // get version info from player
1167         stuffcmd(this, "cmd clientversion $gameversion\n");
1168
1169         // notify about available teams
1170         if (teamplay)
1171         {
1172                 CheckAllowedTeams(this);
1173                 int t = 0;
1174                 if (c1 >= 0) t |= BIT(0);
1175                 if (c2 >= 0) t |= BIT(1);
1176                 if (c3 >= 0) t |= BIT(2);
1177                 if (c4 >= 0) t |= BIT(3);
1178                 stuffcmd(this, sprintf("set _teams_available %d\n", t));
1179         }
1180         else
1181         {
1182                 stuffcmd(this, "set _teams_available 0\n");
1183         }
1184
1185         bot_relinkplayerlist();
1186
1187         this.spectatortime = time;
1188         if (blockSpectators)
1189         {
1190                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
1191         }
1192
1193         this.jointime = time;
1194         this.allowed_timeouts = autocvar_sv_timeout_number;
1195
1196         if (IS_REAL_CLIENT(this))
1197         {
1198                 if (!autocvar_g_campaign)
1199                 {
1200                         this.motd_actived_time = -1;
1201                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOTD, getwelcomemessage(this));
1202                 }
1203
1204                 if (g_weaponarena_weapons == WEPSET(TUBA))
1205                         stuffcmd(this, "cl_cmd settemp chase_active 1\n");
1206         }
1207
1208         if (!sv_foginterval && world.fog != "")
1209                 stuffcmd(this, strcat("\nfog ", world.fog, "\nr_fog_exp2 0\nr_drawfog 1\n"));
1210
1211         if (autocvar_sv_teamnagger && !(autocvar_bot_vs_human && AvailableTeams() == 2))
1212                 if (!g_ca && !g_cts && !g_race) // teamnagger is currently bad for ca, race & cts
1213                         send_CSQC_teamnagger();
1214
1215         CSQCMODEL_AUTOINIT(this);
1216
1217         this.model_randomizer = random();
1218
1219         if (IS_REAL_CLIENT(this))
1220                 sv_notice_join(this);
1221
1222         // update physics stats (players can spawn before physics runs)
1223         Physics_UpdateStats(this, PHYS_HIGHSPEED(this));
1224
1225         IL_EACH(g_initforplayer, it.init_for_player, {
1226                 it.init_for_player(it, this);
1227         });
1228
1229         MUTATOR_CALLHOOK(ClientConnect, this);
1230 }
1231 /*
1232 =============
1233 ClientDisconnect
1234
1235 Called when a client disconnects from the server
1236 =============
1237 */
1238 .entity chatbubbleentity;
1239 void ReadyCount();
1240 void ClientDisconnect(entity this)
1241 {
1242         assert(IS_CLIENT(this), return);
1243
1244         PlayerStats_GameReport_FinalizePlayer(this);
1245         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
1246         if (this.active_minigame) part_minigame(this);
1247         if (IS_PLAYER(this)) Send_Effect(EFFECT_SPAWN_NEUTRAL, this.origin, '0 0 0', 1);
1248
1249         if (autocvar_sv_eventlog)
1250                 GameLogEcho(strcat(":part:", ftos(this.playerid)));
1251
1252         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_QUIT_DISCONNECT, this.netname);
1253
1254         SetSpectatee(this, NULL);
1255
1256     MUTATOR_CALLHOOK(ClientDisconnect, this);
1257
1258         ClientState_detach(this);
1259
1260         Portal_ClearAll(this);
1261
1262         Unfreeze(this);
1263
1264         RemoveGrapplingHooks(this);
1265
1266         // Here, everything has been done that requires this player to be a client.
1267
1268         this.flags &= ~FL_CLIENT;
1269
1270         if (this.chatbubbleentity) delete(this.chatbubbleentity);
1271         if (this.killindicator) delete(this.killindicator);
1272
1273         WaypointSprite_PlayerGone(this);
1274
1275         bot_relinkplayerlist();
1276
1277         if (this.netname_previous) strunzone(this.netname_previous);
1278         if (this.clientstatus) strunzone(this.clientstatus);
1279         if (this.weaponorder_byimpulse) strunzone(this.weaponorder_byimpulse);
1280         if (this.personal) delete(this.personal);
1281
1282         this.playerid = 0;
1283         ReadyCount();
1284         if (vote_called && IS_REAL_CLIENT(this)) VoteCount(false);
1285
1286         ONREMOVE(this);
1287 }
1288
1289 void ChatBubbleThink(entity this)
1290 {
1291         this.nextthink = time;
1292         if ((this.owner.alpha < 0) || this.owner.chatbubbleentity != this)
1293         {
1294                 if(this.owner) // but why can that ever be NULL?
1295                         this.owner.chatbubbleentity = NULL;
1296                 delete(this);
1297                 return;
1298         }
1299
1300         this.mdl = "";
1301
1302         if ( !IS_DEAD(this.owner) && IS_PLAYER(this.owner) )
1303         {
1304                 if ( this.owner.active_minigame )
1305                         this.mdl = "models/sprites/minigame_busy.iqm";
1306                 else if (PHYS_INPUT_BUTTON_CHAT(this.owner))
1307                         this.mdl = "models/misc/chatbubble.spr";
1308         }
1309
1310         if ( this.model != this.mdl )
1311                 _setmodel(this, this.mdl);
1312
1313 }
1314
1315 void UpdateChatBubble(entity this)
1316 {
1317         if (this.alpha < 0)
1318                 return;
1319         // spawn a chatbubble entity if needed
1320         if (!this.chatbubbleentity)
1321         {
1322                 this.chatbubbleentity = new(chatbubbleentity);
1323                 this.chatbubbleentity.owner = this;
1324                 this.chatbubbleentity.exteriormodeltoclient = this;
1325                 setthink(this.chatbubbleentity, ChatBubbleThink);
1326                 this.chatbubbleentity.nextthink = time;
1327                 setmodel(this.chatbubbleentity, MDL_CHAT); // precision set below
1328                 //setorigin(this.chatbubbleentity, this.origin + '0 0 15' + this.maxs_z * '0 0 1');
1329                 setorigin(this.chatbubbleentity, '0 0 15' + this.maxs_z * '0 0 1');
1330                 setattachment(this.chatbubbleentity, this, "");  // sticks to moving player better, also conserves bandwidth
1331                 this.chatbubbleentity.mdl = this.chatbubbleentity.model;
1332                 //this.chatbubbleentity.model = "";
1333                 this.chatbubbleentity.effects = EF_LOWPRECISION;
1334         }
1335 }
1336
1337
1338 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
1339 // added to the model skins
1340 /*void UpdateColorModHack()
1341 {
1342         float c;
1343         c = this.clientcolors & 15;
1344         // LordHavoc: only bothering to support white, green, red, yellow, blue
1345              if (!teamplay) this.colormod = '0 0 0';
1346         else if (c ==  0) this.colormod = '1.00 1.00 1.00';
1347         else if (c ==  3) this.colormod = '0.10 1.73 0.10';
1348         else if (c ==  4) this.colormod = '1.73 0.10 0.10';
1349         else if (c == 12) this.colormod = '1.22 1.22 0.10';
1350         else if (c == 13) this.colormod = '0.10 0.10 1.73';
1351         else this.colormod = '1 1 1';
1352 }*/
1353
1354 void respawn(entity this)
1355 {
1356         if(this.alpha >= 0 && autocvar_g_respawn_ghosts)
1357         {
1358                 this.solid = SOLID_NOT;
1359                 this.takedamage = DAMAGE_NO;
1360                 set_movetype(this, MOVETYPE_FLY);
1361                 this.velocity = '0 0 1' * autocvar_g_respawn_ghosts_speed;
1362                 this.avelocity = randomvec() * autocvar_g_respawn_ghosts_speed * 3 - randomvec() * autocvar_g_respawn_ghosts_speed * 3;
1363                 this.effects |= CSQCMODEL_EF_RESPAWNGHOST;
1364                 Send_Effect(EFFECT_RESPAWN_GHOST, this.origin, '0 0 0', 1);
1365                 if(autocvar_g_respawn_ghosts_maxtime)
1366                         SUB_SetFade (this, time + autocvar_g_respawn_ghosts_maxtime / 2 + random () * (autocvar_g_respawn_ghosts_maxtime - autocvar_g_respawn_ghosts_maxtime / 2), 1.5);
1367         }
1368
1369         CopyBody(this, 1);
1370
1371         this.effects |= EF_NODRAW; // prevent another CopyBody
1372         PutClientInServer(this);
1373 }
1374
1375 void play_countdown(entity this, float finished, Sound samp)
1376 {
1377     TC(Sound, samp);
1378         if(IS_REAL_CLIENT(this))
1379                 if(floor(finished - time - frametime) != floor(finished - time))
1380                         if(finished - time < 6)
1381                                 sound (this, CH_INFO, samp, VOL_BASE, ATTEN_NORM);
1382 }
1383
1384 void player_powerups(entity this)
1385 {
1386         // add a way to see what the items were BEFORE all of these checks for the mutator hook
1387         int items_prev = this.items;
1388
1389         if((this.items & IT_USING_JETPACK) && !IS_DEAD(this) && !gameover)
1390                 this.modelflags |= MF_ROCKET;
1391         else
1392                 this.modelflags &= ~MF_ROCKET;
1393
1394         this.effects &= ~(EF_RED | EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT | EF_FLAME | EF_NODEPTHTEST);
1395
1396         if((this.alpha < 0 || IS_DEAD(this)) && !this.vehicle) // don't apply the flags if the player is gibbed
1397                 return;
1398
1399         Fire_ApplyDamage(this);
1400         Fire_ApplyEffect(this);
1401
1402         if (!g_instagib)
1403         {
1404                 if (this.items & ITEM_Strength.m_itemid)
1405                 {
1406                         play_countdown(this, this.strength_finished, SND_POWEROFF);
1407                         this.effects = this.effects | (EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT);
1408                         if (time > this.strength_finished)
1409                         {
1410                                 this.items = this.items - (this.items & ITEM_Strength.m_itemid);
1411                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERDOWN_STRENGTH, this.netname);
1412                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERDOWN_STRENGTH);
1413                         }
1414                 }
1415                 else
1416                 {
1417                         if (time < this.strength_finished)
1418                         {
1419                                 this.items = this.items | ITEM_Strength.m_itemid;
1420                                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERUP_STRENGTH, this.netname);
1421                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERUP_STRENGTH);
1422                         }
1423                 }
1424                 if (this.items & ITEM_Shield.m_itemid)
1425                 {
1426                         play_countdown(this, this.invincible_finished, SND_POWEROFF);
1427                         this.effects = this.effects | (EF_RED | EF_ADDITIVE | EF_FULLBRIGHT);
1428                         if (time > this.invincible_finished)
1429                         {
1430                                 this.items = this.items - (this.items & ITEM_Shield.m_itemid);
1431                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERDOWN_SHIELD, this.netname);
1432                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERDOWN_SHIELD);
1433                         }
1434                 }
1435                 else
1436                 {
1437                         if (time < this.invincible_finished)
1438                         {
1439                                 this.items = this.items | ITEM_Shield.m_itemid;
1440                                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERUP_SHIELD, this.netname);
1441                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERUP_SHIELD);
1442                         }
1443                 }
1444                 if (this.items & IT_SUPERWEAPON)
1445                 {
1446                         if (!(this.weapons & WEPSET_SUPERWEAPONS))
1447                         {
1448                                 this.superweapons_finished = 0;
1449                                 this.items = this.items - (this.items & IT_SUPERWEAPON);
1450                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_LOST, this.netname);
1451                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_LOST);
1452                         }
1453                         else if (this.items & IT_UNLIMITED_SUPERWEAPONS)
1454                         {
1455                                 // don't let them run out
1456                         }
1457                         else
1458                         {
1459                                 play_countdown(this, this.superweapons_finished, SND_POWEROFF);
1460                                 if (time > this.superweapons_finished)
1461                                 {
1462                                         this.items = this.items - (this.items & IT_SUPERWEAPON);
1463                                         this.weapons &= ~WEPSET_SUPERWEAPONS;
1464                                         //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_BROKEN, this.netname);
1465                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_BROKEN);
1466                                 }
1467                         }
1468                 }
1469                 else if(this.weapons & WEPSET_SUPERWEAPONS)
1470                 {
1471                         if (time < this.superweapons_finished || (this.items & IT_UNLIMITED_SUPERWEAPONS))
1472                         {
1473                                 this.items = this.items | IT_SUPERWEAPON;
1474                                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_PICKUP, this.netname);
1475                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_PICKUP);
1476                         }
1477                         else
1478                         {
1479                                 this.superweapons_finished = 0;
1480                                 this.weapons &= ~WEPSET_SUPERWEAPONS;
1481                         }
1482                 }
1483                 else
1484                 {
1485                         this.superweapons_finished = 0;
1486                 }
1487         }
1488
1489         if(autocvar_g_nodepthtestplayers)
1490                 this.effects = this.effects | EF_NODEPTHTEST;
1491
1492         if(autocvar_g_fullbrightplayers)
1493                 this.effects = this.effects | EF_FULLBRIGHT;
1494
1495         if (time >= game_starttime)
1496         if (time < this.spawnshieldtime)
1497                 this.effects = this.effects | (EF_ADDITIVE | EF_FULLBRIGHT);
1498
1499         MUTATOR_CALLHOOK(PlayerPowerups, this, items_prev);
1500 }
1501
1502 float CalcRegen(float current, float stable, float regenfactor, float regenframetime)
1503 {
1504         if(current > stable)
1505                 return current;
1506         else if(current > stable - 0.25) // when close enough, "snap"
1507                 return stable;
1508         else
1509                 return min(stable, current + (stable - current) * regenfactor * regenframetime);
1510 }
1511
1512 float CalcRot(float current, float stable, float rotfactor, float rotframetime)
1513 {
1514         if(current < stable)
1515                 return current;
1516         else if(current < stable + 0.25) // when close enough, "snap"
1517                 return stable;
1518         else
1519                 return max(stable, current + (stable - current) * rotfactor * rotframetime);
1520 }
1521
1522 float CalcRotRegen(float current, float regenstable, float regenfactor, float regenlinear, float regenframetime, float rotstable, float rotfactor, float rotlinear, float rotframetime, float limit)
1523 {
1524         if(current > rotstable)
1525         {
1526                 if(rotframetime > 0)
1527                 {
1528                         current = CalcRot(current, rotstable, rotfactor, rotframetime);
1529                         current = max(rotstable, current - rotlinear * rotframetime);
1530                 }
1531         }
1532         else if(current < regenstable)
1533         {
1534                 if(regenframetime > 0)
1535                 {
1536                         current = CalcRegen(current, regenstable, regenfactor, regenframetime);
1537                         current = min(regenstable, current + regenlinear * regenframetime);
1538                 }
1539         }
1540
1541         if(current > limit)
1542                 current = limit;
1543
1544         return current;
1545 }
1546
1547 void player_regen(entity this)
1548 {
1549         float max_mod, regen_mod, rot_mod, limit_mod;
1550         max_mod = regen_mod = rot_mod = limit_mod = 1;
1551
1552         float regen_health = autocvar_g_balance_health_regen;
1553         float regen_health_linear = autocvar_g_balance_health_regenlinear;
1554         float regen_health_rot = autocvar_g_balance_health_rot;
1555         float regen_health_rotlinear = autocvar_g_balance_health_rotlinear;
1556         float regen_health_stable = autocvar_g_balance_health_regenstable;
1557         float regen_health_rotstable = autocvar_g_balance_health_rotstable;
1558         bool mutator_returnvalue = MUTATOR_CALLHOOK(PlayerRegen, this, max_mod, regen_mod, rot_mod, limit_mod, regen_health, regen_health_linear, regen_health_rot,
1559                 regen_health_rotlinear, regen_health_stable, regen_health_rotstable);
1560         max_mod = M_ARGV(1, float);
1561         regen_mod = M_ARGV(2, float);
1562         rot_mod = M_ARGV(3, float);
1563         limit_mod = M_ARGV(4, float);
1564         regen_health = M_ARGV(5, float);
1565         regen_health_linear = M_ARGV(6, float);
1566         regen_health_rot = M_ARGV(7, float);
1567         regen_health_rotlinear = M_ARGV(8, float);
1568         regen_health_stable = M_ARGV(9, float);
1569         regen_health_rotstable = M_ARGV(10, float);
1570
1571
1572         if(!mutator_returnvalue)
1573         if(!STAT(FROZEN, this))
1574         {
1575                 float mina, maxa, limith, limita;
1576                 maxa = autocvar_g_balance_armor_rotstable;
1577                 mina = autocvar_g_balance_armor_regenstable;
1578                 limith = autocvar_g_balance_health_limit;
1579                 limita = autocvar_g_balance_armor_limit;
1580
1581                 regen_health_rotstable = regen_health_rotstable * max_mod;
1582                 regen_health_stable = regen_health_stable * max_mod;
1583                 limith = limith * limit_mod;
1584                 limita = limita * limit_mod;
1585
1586                 this.armorvalue = CalcRotRegen(this.armorvalue, mina, autocvar_g_balance_armor_regen, autocvar_g_balance_armor_regenlinear, regen_mod * frametime * (time > this.pauseregen_finished), maxa, autocvar_g_balance_armor_rot, autocvar_g_balance_armor_rotlinear, rot_mod * frametime * (time > this.pauserotarmor_finished), limita);
1587                 this.health = CalcRotRegen(this.health, regen_health_stable, regen_health, regen_health_linear, regen_mod * frametime * (time > this.pauseregen_finished), regen_health_rotstable, regen_health_rot, regen_health_rotlinear, rot_mod * frametime * (time > this.pauserothealth_finished), limith);
1588         }
1589
1590         // if player rotted to death...  die!
1591         // check this outside above checks, as player may still be able to rot to death
1592         if(this.health < 1)
1593         {
1594                 if(this.vehicle)
1595                         vehicles_exit(this.vehicle, VHEF_RELEASE);
1596                 if(this.event_damage)
1597                         this.event_damage(this, this, this, 1, DEATH_ROT.m_id, this.origin, '0 0 0');
1598         }
1599
1600         if (!(this.items & IT_UNLIMITED_WEAPON_AMMO))
1601         {
1602                 float minf, maxf, limitf;
1603
1604                 maxf = autocvar_g_balance_fuel_rotstable;
1605                 minf = autocvar_g_balance_fuel_regenstable;
1606                 limitf = autocvar_g_balance_fuel_limit;
1607
1608                 this.ammo_fuel = CalcRotRegen(this.ammo_fuel, minf, autocvar_g_balance_fuel_regen, autocvar_g_balance_fuel_regenlinear, frametime * (time > this.pauseregen_finished) * ((this.items & ITEM_JetpackRegen.m_itemid) != 0), maxf, autocvar_g_balance_fuel_rot, autocvar_g_balance_fuel_rotlinear, frametime * (time > this.pauserotfuel_finished), limitf);
1609         }
1610 }
1611
1612 bool zoomstate_set;
1613 void SetZoomState(entity this, float z)
1614 {
1615         if(z != this.zoomstate)
1616         {
1617                 this.zoomstate = z;
1618                 ClientData_Touch(this);
1619         }
1620         zoomstate_set = true;
1621 }
1622
1623 void GetPressedKeys(entity this)
1624 {
1625         MUTATOR_CALLHOOK(GetPressedKeys, this);
1626         int keys = STAT(PRESSED_KEYS, this);
1627         keys = BITSET(keys, KEY_FORWARD,        this.movement.x > 0);
1628         keys = BITSET(keys, KEY_BACKWARD,       this.movement.x < 0);
1629         keys = BITSET(keys, KEY_RIGHT,          this.movement.y > 0);
1630         keys = BITSET(keys, KEY_LEFT,           this.movement.y < 0);
1631
1632         keys = BITSET(keys, KEY_JUMP,           PHYS_INPUT_BUTTON_JUMP(this));
1633         keys = BITSET(keys, KEY_CROUCH,         PHYS_INPUT_BUTTON_CROUCH(this));
1634         keys = BITSET(keys, KEY_ATCK,           PHYS_INPUT_BUTTON_ATCK(this));
1635         keys = BITSET(keys, KEY_ATCK2,          PHYS_INPUT_BUTTON_ATCK2(this));
1636         this.pressedkeys = keys; // store for other users
1637
1638         STAT(PRESSED_KEYS, this) = keys;
1639 }
1640
1641 /*
1642 ======================
1643 spectate mode routines
1644 ======================
1645 */
1646
1647 void SpectateCopy(entity this, entity spectatee)
1648 {
1649     TC(Client, this); TC(Client, spectatee);
1650
1651         MUTATOR_CALLHOOK(SpectateCopy, spectatee, this);
1652         PS(this) = PS(spectatee);
1653         this.armortype = spectatee.armortype;
1654         this.armorvalue = spectatee.armorvalue;
1655         this.ammo_cells = spectatee.ammo_cells;
1656         this.ammo_plasma = spectatee.ammo_plasma;
1657         this.ammo_shells = spectatee.ammo_shells;
1658         this.ammo_nails = spectatee.ammo_nails;
1659         this.ammo_rockets = spectatee.ammo_rockets;
1660         this.ammo_fuel = spectatee.ammo_fuel;
1661         this.clip_load = spectatee.clip_load;
1662         this.clip_size = spectatee.clip_size;
1663         this.effects = spectatee.effects & EFMASK_CHEAP; // eat performance
1664         this.health = spectatee.health;
1665         this.impulse = 0;
1666         this.items = spectatee.items;
1667         this.last_pickup = spectatee.last_pickup;
1668         this.hit_time = spectatee.hit_time;
1669         this.strength_finished = spectatee.strength_finished;
1670         this.invincible_finished = spectatee.invincible_finished;
1671         STAT(PRESSED_KEYS, this) = STAT(PRESSED_KEYS, spectatee);
1672         this.weapons = spectatee.weapons;
1673         this.vortex_charge = spectatee.vortex_charge;
1674         this.vortex_chargepool_ammo = spectatee.vortex_chargepool_ammo;
1675         this.hagar_load = spectatee.hagar_load;
1676         this.arc_heat_percent = spectatee.arc_heat_percent;
1677         this.minelayer_mines = spectatee.minelayer_mines;
1678         this.punchangle = spectatee.punchangle;
1679         this.view_ofs = spectatee.view_ofs;
1680         this.velocity = spectatee.velocity;
1681         this.dmg_take = spectatee.dmg_take;
1682         this.dmg_save = spectatee.dmg_save;
1683         this.dmg_inflictor = spectatee.dmg_inflictor;
1684         this.v_angle = spectatee.v_angle;
1685         this.angles = spectatee.v_angle;
1686         STAT(FROZEN, this) = STAT(FROZEN, spectatee);
1687         this.revive_progress = spectatee.revive_progress;
1688         this.viewloc = spectatee.viewloc;
1689         if(!PHYS_INPUT_BUTTON_USE(this) && STAT(CAMERA_SPECTATOR, this) != 2)
1690                 this.fixangle = true;
1691         setorigin(this, spectatee.origin);
1692         setsize(this, spectatee.mins, spectatee.maxs);
1693         SetZoomState(this, spectatee.zoomstate);
1694
1695         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1696         {
1697                 .entity weaponentity = weaponentities[slot];
1698                 this.(weaponentity) = spectatee.(weaponentity);
1699         }
1700
1701     anticheat_spectatecopy(this, spectatee);
1702         this.hud = spectatee.hud;
1703         if(spectatee.vehicle)
1704     {
1705         this.angles = spectatee.v_angle;
1706
1707         //this.fixangle = false;
1708         //this.velocity = spectatee.vehicle.velocity;
1709         this.vehicle_health = spectatee.vehicle_health;
1710         this.vehicle_shield = spectatee.vehicle_shield;
1711         this.vehicle_energy = spectatee.vehicle_energy;
1712         this.vehicle_ammo1 = spectatee.vehicle_ammo1;
1713         this.vehicle_ammo2 = spectatee.vehicle_ammo2;
1714         this.vehicle_reload1 = spectatee.vehicle_reload1;
1715         this.vehicle_reload2 = spectatee.vehicle_reload2;
1716
1717         //msg_entity = this;
1718
1719        // WriteByte (MSG_ONE, SVC_SETVIEWANGLES);
1720             //WriteAngle(MSG_ONE,  spectatee.v_angle.x);
1721            // WriteAngle(MSG_ONE,  spectatee.v_angle.y);
1722            // WriteAngle(MSG_ONE,  spectatee.v_angle.z);
1723
1724         //WriteByte (MSG_ONE, SVC_SETVIEW);
1725         //    WriteEntity(MSG_ONE, this);
1726         //makevectors(spectatee.v_angle);
1727         //setorigin(this, spectatee.origin - v_forward * 400 + v_up * 300);*/
1728     }
1729 }
1730
1731 bool SpectateUpdate(entity this)
1732 {
1733         if(!this.enemy)
1734                 return false;
1735
1736         if(!IS_PLAYER(this.enemy) || this == this.enemy)
1737         {
1738                 SetSpectatee(this, NULL);
1739                 return false;
1740         }
1741
1742         SpectateCopy(this, this.enemy);
1743
1744         return true;
1745 }
1746
1747 bool SpectateSet(entity this)
1748 {
1749         if(!IS_PLAYER(this.enemy))
1750                 return false;
1751
1752         ClientData_Touch(this.enemy);
1753
1754         msg_entity = this;
1755         WriteByte(MSG_ONE, SVC_SETVIEW);
1756         WriteEntity(MSG_ONE, this.enemy);
1757         set_movetype(this, MOVETYPE_NONE);
1758         accuracy_resend(this);
1759
1760         if(!SpectateUpdate(this))
1761                 PutObserverInServer(this);
1762
1763         return true;
1764 }
1765
1766 void SetSpectatee_status(entity this, int spectatee_num)
1767 {
1768         int oldspectatee_status = this.spectatee_status;
1769         this.spectatee_status = spectatee_num;
1770
1771         if (this.spectatee_status != oldspectatee_status)
1772         {
1773                 ClientData_Touch(this);
1774                 if (g_race || g_cts) race_InitSpectator();
1775         }
1776 }
1777
1778 void SetSpectatee(entity this, entity spectatee)
1779 {
1780         entity old_spectatee = this.enemy;
1781
1782         this.enemy = spectatee;
1783
1784         // WEAPONTODO
1785         // these are required to fix the spectator bug with arc
1786         if(old_spectatee)
1787         {
1788                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1789                 {
1790                         .entity weaponentity = weaponentities[slot];
1791                         if(old_spectatee.(weaponentity).arc_beam)
1792                                 old_spectatee.(weaponentity).arc_beam.SendFlags |= ARC_SF_SETTINGS;
1793                 }
1794         }
1795         if(this.enemy)
1796         {
1797                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1798                 {
1799                         .entity weaponentity = weaponentities[slot];
1800                         if(this.enemy.(weaponentity).arc_beam)
1801                                 this.enemy.(weaponentity).arc_beam.SendFlags |= ARC_SF_SETTINGS;
1802                 }
1803         }
1804
1805         if (this.enemy)
1806                 SetSpectatee_status(this, etof(this.enemy));
1807
1808         // needed to update spectator list
1809         if(old_spectatee) { ClientData_Touch(old_spectatee); }
1810 }
1811
1812 bool Spectate(entity this, entity pl)
1813 {
1814         if(MUTATOR_CALLHOOK(SpectateSet, this, pl))
1815                 return false;
1816         pl = M_ARGV(1, entity);
1817
1818         SetSpectatee(this, pl);
1819         return SpectateSet(this);
1820 }
1821
1822 bool SpectateNext(entity this)
1823 {
1824         entity ent = find(this.enemy, classname, STR_PLAYER);
1825
1826         if (MUTATOR_CALLHOOK(SpectateNext, this, ent))
1827                 ent = M_ARGV(1, entity);
1828         else if (!ent)
1829                 ent = find(ent, classname, STR_PLAYER);
1830
1831         if(ent) { SetSpectatee(this, ent); }
1832
1833         return SpectateSet(this);
1834 }
1835
1836 bool SpectatePrev(entity this)
1837 {
1838         // NOTE: chain order is from the highest to the lower entnum (unlike find)
1839         entity ent = findchain(classname, STR_PLAYER);
1840         if (!ent) // no player
1841                 return false;
1842
1843         entity first = ent;
1844         // skip players until current spectated player
1845         if(this.enemy)
1846         while(ent && ent != this.enemy)
1847                 ent = ent.chain;
1848
1849         switch (MUTATOR_CALLHOOK(SpectatePrev, this, ent, first))
1850         {
1851                 case MUT_SPECPREV_FOUND:
1852                     ent = M_ARGV(1, entity);
1853                     break;
1854                 case MUT_SPECPREV_RETURN:
1855                     return true;
1856                 case MUT_SPECPREV_CONTINUE:
1857                 default:
1858                 {
1859                         if(ent.chain)
1860                                 ent = ent.chain;
1861                         else
1862                                 ent = first;
1863                         break;
1864                 }
1865         }
1866
1867         SetSpectatee(this, ent);
1868         return SpectateSet(this);
1869 }
1870
1871 /*
1872 =============
1873 ShowRespawnCountdown()
1874
1875 Update a respawn countdown display.
1876 =============
1877 */
1878 void ShowRespawnCountdown(entity this)
1879 {
1880         float number;
1881         if(!IS_DEAD(this)) // just respawned?
1882                 return;
1883         else
1884         {
1885                 number = ceil(this.respawn_time - time);
1886                 if(number <= 0)
1887                         return;
1888                 if(number <= this.respawn_countdown)
1889                 {
1890                         this.respawn_countdown = number - 1;
1891                         if(ceil(this.respawn_time - (time + 0.5)) == number) // only say it if it is the same number even in 0.5s; to prevent overlapping sounds
1892                                 { Send_Notification(NOTIF_ONE, this, MSG_ANNCE, Announcer_PickNumber(CNT_RESPAWN, number)); }
1893                 }
1894         }
1895 }
1896
1897 .bool team_selected;
1898 bool ShowTeamSelection(entity this)
1899 {
1900         if(!teamplay || autocvar_g_campaign || autocvar_g_balance_teams || this.team_selected || (this.wasplayer && autocvar_g_changeteam_banned) || this.team_forced > 0)
1901                 return false;
1902         stuffcmd(this, "menu_showteamselect\n");
1903         return true;
1904 }
1905 void Join(entity this)
1906 {
1907         TRANSMUTE(Player, this);
1908
1909         if(!this.team_selected)
1910         if(autocvar_g_campaign || autocvar_g_balance_teams)
1911                 JoinBestTeam(this, false, true);
1912
1913         if(autocvar_g_campaign)
1914                 campaign_bots_may_start = true;
1915
1916         Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_PREVENT_JOIN);
1917
1918         PutClientInServer(this);
1919
1920         if(teamplay && this.team != -1)
1921                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, APP_TEAM_NUM(this.team, INFO_JOIN_PLAY_TEAM), this.netname);
1922         else
1923                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_JOIN_PLAY, this.netname);
1924         this.team_selected = false;
1925 }
1926
1927 /**
1928  * Determines whether the player is allowed to join. This depends on cvar
1929  * g_maxplayers, if it isn't used this function always return true, otherwise
1930  * it checks whether the number of currently playing players exceeds g_maxplayers.
1931  * @return int number of free slots for players, 0 if none
1932  */
1933 int nJoinAllowed(entity this, entity ignore)
1934 {
1935         if(!ignore)
1936         // this is called that way when checking if anyone may be able to join (to build qcstatus)
1937         // so report 0 free slots if restricted
1938         {
1939                 if(autocvar_g_forced_team_otherwise == "spectate")
1940                         return 0;
1941                 if(autocvar_g_forced_team_otherwise == "spectator")
1942                         return 0;
1943         }
1944
1945         if(this && this.team_forced < 0)
1946                 return 0; // forced spectators can never join
1947
1948         // TODO simplify this
1949         int totalClients = 0;
1950         int currentlyPlaying = 0;
1951         FOREACH_CLIENT(true, LAMBDA(
1952                 if(it != ignore)
1953                         ++totalClients;
1954                 if(IS_REAL_CLIENT(it))
1955                 if(IS_PLAYER(it) || it.caplayer)
1956                         ++currentlyPlaying;
1957         ));
1958
1959         float free_slots = 0;
1960         if (!autocvar_g_maxplayers)
1961                 free_slots = maxclients - totalClients;
1962         else if(currentlyPlaying < autocvar_g_maxplayers)
1963                 free_slots = min(maxclients - totalClients, autocvar_g_maxplayers - currentlyPlaying);
1964
1965         static float join_prevent_msg_time = 0;
1966         if(this && ignore && !free_slots && time > join_prevent_msg_time)
1967         {
1968                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_JOIN_PREVENT);
1969                 join_prevent_msg_time = time + 3;
1970         }
1971
1972         return free_slots;
1973 }
1974
1975 /**
1976  * Checks whether the client is an observer or spectator, if so, he will get kicked after
1977  * g_maxplayers_spectator_blocktime seconds
1978  */
1979 void checkSpectatorBlock(entity this)
1980 {
1981         if(IS_SPEC(this) || IS_OBSERVER(this))
1982         if(!this.caplayer)
1983         if(IS_REAL_CLIENT(this))
1984         {
1985                 if( time > (this.spectatortime + autocvar_g_maxplayers_spectator_blocktime) ) {
1986                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_QUIT_KICK_SPECTATING);
1987                         dropclient(this);
1988                 }
1989         }
1990 }
1991
1992 void PrintWelcomeMessage(entity this)
1993 {
1994         if(this.motd_actived_time == 0)
1995         {
1996                 if (autocvar_g_campaign) {
1997                         if ((IS_PLAYER(this) && PHYS_INPUT_BUTTON_INFO(this)) || (!IS_PLAYER(this))) {
1998                                 this.motd_actived_time = time;
1999                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOTD, campaign_message);
2000                         }
2001                 } else {
2002                         if (PHYS_INPUT_BUTTON_INFO(this)) {
2003                                 this.motd_actived_time = time;
2004                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOTD, getwelcomemessage(this));
2005                         }
2006                 }
2007         }
2008         else if(this.motd_actived_time > 0) // showing MOTD or campaign message
2009         {
2010                 if (autocvar_g_campaign) {
2011                         if (PHYS_INPUT_BUTTON_INFO(this))
2012                                 this.motd_actived_time = time;
2013                         else if ((time - this.motd_actived_time > 2) && IS_PLAYER(this)) { // hide it some seconds after BUTTON_INFO has been released
2014                                 this.motd_actived_time = 0;
2015                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_MOTD);
2016                         }
2017                 } else {
2018                         if (PHYS_INPUT_BUTTON_INFO(this))
2019                                 this.motd_actived_time = time;
2020                         else if (time - this.motd_actived_time > 2) { // hide it some seconds after BUTTON_INFO has been released
2021                                 this.motd_actived_time = 0;
2022                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_MOTD);
2023                         }
2024                 }
2025         }
2026         else //if(this.motd_actived_time < 0) // just connected, motd is active
2027         {
2028                 if(PHYS_INPUT_BUTTON_INFO(this)) // BUTTON_INFO hides initial MOTD
2029                         this.motd_actived_time = -2; // wait until BUTTON_INFO gets released
2030                 else if(this.motd_actived_time == -2 || IS_PLAYER(this) || IS_SPEC(this))
2031                 {
2032                         // instanctly hide MOTD
2033                         this.motd_actived_time = 0;
2034                         Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_MOTD);
2035                 }
2036         }
2037 }
2038
2039 bool joinAllowed(entity this)
2040 {
2041         if (this.version_mismatch) return false;
2042         if (!nJoinAllowed(this, this)) return false;
2043         if (teamplay && lockteams) return false;
2044         if (ShowTeamSelection(this)) return false;
2045         if (MUTATOR_CALLHOOK(ForbidSpawn, this)) return false;
2046         return true;
2047 }
2048
2049 void ObserverThink(entity this)
2050 {
2051         if ( this.impulse )
2052         {
2053                 MinigameImpulse(this, this.impulse);
2054                 this.impulse = 0;
2055         }
2056
2057         if (this.flags & FL_JUMPRELEASED) {
2058                 if (PHYS_INPUT_BUTTON_JUMP(this) && joinAllowed(this)) {
2059                         this.flags &= ~FL_JUMPRELEASED;
2060                         this.flags |= FL_SPAWNING;
2061                 } else if(PHYS_INPUT_BUTTON_ATCK(this) && !this.version_mismatch) {
2062                         this.flags &= ~FL_JUMPRELEASED;
2063                         if(SpectateNext(this)) {
2064                                 TRANSMUTE(Spectator, this);
2065                         }
2066                 } else {
2067                         int preferred_movetype = ((!PHYS_INPUT_BUTTON_USE(this) ? this.cvar_cl_clippedspectating : !this.cvar_cl_clippedspectating) ? MOVETYPE_FLY_WORLDONLY : MOVETYPE_NOCLIP);
2068                         set_movetype(this, preferred_movetype);
2069                 }
2070         } else {
2071                 if (!(PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_JUMP(this))) {
2072                         this.flags |= FL_JUMPRELEASED;
2073                         if(this.flags & FL_SPAWNING)
2074                         {
2075                                 this.flags &= ~FL_SPAWNING;
2076                                 Join(this);
2077                                 return;
2078                         }
2079                 }
2080         }
2081 }
2082
2083 void SpectatorThink(entity this)
2084 {
2085         if ( this.impulse )
2086         {
2087                 if(MinigameImpulse(this, this.impulse))
2088                         this.impulse = 0;
2089
2090                 if (this.impulse == IMP_weapon_drop.impulse)
2091                 {
2092                         STAT(CAMERA_SPECTATOR, this) = (STAT(CAMERA_SPECTATOR, this) + 1) % 3;
2093                         this.impulse = 0;
2094                         return;
2095                 }
2096         }
2097
2098         if (this.flags & FL_JUMPRELEASED) {
2099                 if (PHYS_INPUT_BUTTON_JUMP(this) && joinAllowed(this)) {
2100                         this.flags &= ~FL_JUMPRELEASED;
2101                         this.flags |= FL_SPAWNING;
2102                 } else if(PHYS_INPUT_BUTTON_ATCK(this) || this.impulse == 10 || this.impulse == 15 || this.impulse == 18 || (this.impulse >= 200 && this.impulse <= 209)) {
2103                         this.flags &= ~FL_JUMPRELEASED;
2104                         if(SpectateNext(this)) {
2105                                 TRANSMUTE(Spectator, this);
2106                         } else {
2107                                 TRANSMUTE(Observer, this);
2108                                 PutClientInServer(this);
2109                         }
2110                         this.impulse = 0;
2111                 } else if(this.impulse == 12 || this.impulse == 16  || this.impulse == 19 || (this.impulse >= 220 && this.impulse <= 229)) {
2112                         this.flags &= ~FL_JUMPRELEASED;
2113                         if(SpectatePrev(this)) {
2114                                 TRANSMUTE(Spectator, this);
2115                         } else {
2116                                 TRANSMUTE(Observer, this);
2117                                 PutClientInServer(this);
2118                         }
2119                         this.impulse = 0;
2120                 } else if (PHYS_INPUT_BUTTON_ATCK2(this)) {
2121                         this.flags &= ~FL_JUMPRELEASED;
2122                         TRANSMUTE(Observer, this);
2123                         PutClientInServer(this);
2124                 } else {
2125                         if(!SpectateUpdate(this))
2126                                 PutObserverInServer(this);
2127                 }
2128         } else {
2129                 if (!(PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_ATCK2(this))) {
2130                         this.flags |= FL_JUMPRELEASED;
2131                         if(this.flags & FL_SPAWNING)
2132                         {
2133                                 this.flags &= ~FL_SPAWNING;
2134                                 Join(this);
2135                                 return;
2136                         }
2137                 }
2138                 if(!SpectateUpdate(this))
2139                         PutObserverInServer(this);
2140         }
2141
2142         this.flags |= FL_CLIENT | FL_NOTARGET;
2143 }
2144
2145 void vehicles_enter (entity pl, entity veh);
2146 void PlayerUseKey(entity this)
2147 {
2148         if (!IS_PLAYER(this))
2149                 return;
2150
2151         if(this.vehicle)
2152         {
2153                 if(!gameover)
2154                 {
2155                         vehicles_exit(this.vehicle, VHEF_NORMAL);
2156                         return;
2157                 }
2158         }
2159         else if(autocvar_g_vehicles_enter)
2160         {
2161                 if(!STAT(FROZEN, this))
2162                 if(!IS_DEAD(this))
2163                 if(!gameover)
2164                 {
2165                         entity head, closest_target = NULL;
2166                         head = WarpZone_FindRadius(this.origin, autocvar_g_vehicles_enter_radius, true);
2167
2168                         while(head) // find the closest acceptable target to enter
2169                         {
2170                                 if(IS_VEHICLE(head))
2171                                 if(!IS_DEAD(head))
2172                                 if(!head.owner || ((head.vehicle_flags & VHF_MULTISLOT) && SAME_TEAM(head.owner, this)))
2173                                 if(head.takedamage != DAMAGE_NO)
2174                                 {
2175                                         if(closest_target)
2176                                         {
2177                                                 if(vlen2(this.origin - head.origin) < vlen2(this.origin - closest_target.origin))
2178                                                 { closest_target = head; }
2179                                         }
2180                                         else { closest_target = head; }
2181                                 }
2182
2183                                 head = head.chain;
2184                         }
2185
2186                         if(closest_target) { vehicles_enter(this, closest_target); return; }
2187                 }
2188         }
2189
2190         // a use key was pressed; call handlers
2191         MUTATOR_CALLHOOK(PlayerUseKey, this);
2192 }
2193
2194
2195 /*
2196 =============
2197 PlayerPreThink
2198
2199 Called every frame for each client before the physics are run
2200 =============
2201 */
2202 .float usekeypressed;
2203 .float last_vehiclecheck;
2204 .int items_added;
2205 void PlayerPreThink (entity this)
2206 {
2207         WarpZone_PlayerPhysics_FixVAngle(this);
2208
2209     STAT(GAMESTARTTIME, this) = game_starttime;
2210         STAT(ROUNDSTARTTIME, this) = round_starttime;
2211         STAT(ALLOW_OLDVORTEXBEAM, this) = autocvar_g_allow_oldvortexbeam;
2212         STAT(LEADLIMIT, this) = autocvar_leadlimit;
2213
2214         STAT(WEAPONSINMAP, this) = weaponsInMap;
2215
2216         if (frametime) {
2217                 // physics frames: update anticheat stuff
2218                 anticheat_prethink(this);
2219         }
2220
2221         if (blockSpectators && frametime) {
2222                 // WORKAROUND: only use dropclient in server frames (frametime set).
2223                 // Never use it in cl_movement frames (frametime zero).
2224                 checkSpectatorBlock(this);
2225     }
2226
2227         zoomstate_set = false;
2228
2229         // Check for nameless players
2230         if (isInvisibleString(this.netname)) {
2231                 this.netname = strzone(sprintf("Player#%d", this.playerid));
2232                 // stuffcmd(this, strcat("name ", this.netname, "\n")); // maybe?
2233         }
2234         if (this.netname != this.netname_previous) {
2235                 if (autocvar_sv_eventlog) {
2236                         GameLogEcho(strcat(":name:", ftos(this.playerid), ":", this.netname));
2237         }
2238                 if (this.netname_previous) strunzone(this.netname_previous);
2239                 this.netname_previous = strzone(this.netname);
2240         }
2241
2242         // version nagging
2243         if (this.version_nagtime && this.cvar_g_xonoticversion && time > this.version_nagtime) {
2244         this.version_nagtime = 0;
2245         if (strstrofs(this.cvar_g_xonoticversion, "git", 0) >= 0 || strstrofs(this.cvar_g_xonoticversion, "autobuild", 0) >= 0) {
2246             // git client
2247         } else if (strstrofs(autocvar_g_xonoticversion, "git", 0) >= 0 || strstrofs(autocvar_g_xonoticversion, "autobuild", 0) >= 0) {
2248             // git server
2249             Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_BETA, autocvar_g_xonoticversion, this.cvar_g_xonoticversion);
2250         } else {
2251             int r = vercmp(this.cvar_g_xonoticversion, autocvar_g_xonoticversion);
2252             if (r < 0) { // old client
2253                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_OUTDATED, autocvar_g_xonoticversion, this.cvar_g_xonoticversion);
2254             } else if (r > 0) { // old server
2255                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_OLD, autocvar_g_xonoticversion, this.cvar_g_xonoticversion);
2256             }
2257         }
2258     }
2259
2260         // GOD MODE info
2261         if (!(this.flags & FL_GODMODE) && this.max_armorvalue)
2262         {
2263                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_GODMODE_OFF, this.max_armorvalue);
2264                 this.max_armorvalue = 0;
2265         }
2266
2267         if (STAT(FROZEN, this) == 2)
2268         {
2269                 this.revive_progress = bound(0, this.revive_progress + frametime * this.revive_speed, 1);
2270                 this.health = max(1, this.revive_progress * start_health);
2271                 this.iceblock.alpha = bound(0.2, 1 - this.revive_progress, 1);
2272
2273                 if (this.revive_progress >= 1)
2274                         Unfreeze(this);
2275         }
2276         else if (STAT(FROZEN, this) == 3)
2277         {
2278                 this.revive_progress = bound(0, this.revive_progress - frametime * this.revive_speed, 1);
2279                 this.health = max(0, autocvar_g_nades_ice_health + (start_health-autocvar_g_nades_ice_health) * this.revive_progress );
2280
2281                 if (this.health < 1)
2282                 {
2283                         if (this.vehicle)
2284                                 vehicles_exit(this.vehicle, VHEF_RELEASE);
2285                         if(this.event_damage)
2286                                 this.event_damage(this, this, this.frozen_by, 1, DEATH_NADE_ICE_FREEZE.m_id, this.origin, '0 0 0');
2287                 }
2288                 else if (this.revive_progress <= 0)
2289                         Unfreeze(this);
2290         }
2291
2292         MUTATOR_CALLHOOK(PlayerPreThink, this);
2293
2294         if(autocvar_g_vehicles_enter && (time > this.last_vehiclecheck) && !gameover && !this.vehicle)
2295         if(IS_PLAYER(this) && !STAT(FROZEN, this) && !IS_DEAD(this))
2296         {
2297                 FOREACH_ENTITY_RADIUS(this.origin, autocvar_g_vehicles_enter_radius, IS_VEHICLE(it),
2298                 {
2299                         if(!IS_DEAD(it) && it.takedamage != DAMAGE_NO)
2300                         if((it.vehicle_flags & VHF_MULTISLOT) && SAME_TEAM(it.owner, this))
2301                         {
2302                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER_GUNNER);
2303                         }
2304                         else if(!it.owner)
2305                         {
2306                                 if(!it.team || SAME_TEAM(this, it))
2307                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER);
2308                                 else if(autocvar_g_vehicles_steal)
2309                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER_STEAL);
2310                         }
2311                 });
2312
2313                 this.last_vehiclecheck = time + 1;
2314         }
2315
2316         if(!this.cvar_cl_newusekeysupported) // FIXME remove this - it was a stupid idea to begin with, we can JUST use the button
2317         {
2318                 if(PHYS_INPUT_BUTTON_USE(this) && !this.usekeypressed)
2319                         PlayerUseKey(this);
2320                 this.usekeypressed = PHYS_INPUT_BUTTON_USE(this);
2321         }
2322
2323         if (IS_REAL_CLIENT(this))
2324                 PrintWelcomeMessage(this);
2325
2326         if (IS_PLAYER(this)) {
2327                 CheckRules_Player(this);
2328
2329                 if (intermission_running) {
2330                         IntermissionThink(this);
2331                         return;
2332                 }
2333
2334                 if (timeout_status == TIMEOUT_ACTIVE) {
2335             // don't allow the player to turn around while game is paused
2336                         // FIXME turn this into CSQC stuff
2337                         this.v_angle = this.lastV_angle;
2338                         this.angles = this.lastV_angle;
2339                         this.fixangle = true;
2340                 }
2341
2342                 if (frametime) player_powerups(this);
2343
2344                 if (IS_DEAD(this)) {
2345                         if (this.personal && g_race_qualifying) {
2346                                 if (time > this.respawn_time) {
2347                                         STAT(RESPAWN_TIME, this) = this.respawn_time = time + 1; // only retry once a second
2348                                         respawn(this);
2349                                         this.impulse = CHIMPULSE_SPEEDRUN.impulse;
2350                                 }
2351                         } else {
2352                                 if (frametime) player_anim(this);
2353                                 bool button_pressed = (PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_JUMP(this) || PHYS_INPUT_BUTTON_ATCK2(this) || PHYS_INPUT_BUTTON_HOOK(this) || PHYS_INPUT_BUTTON_USE(this));
2354
2355                                 switch(this.deadflag)
2356                                 {
2357                                         case DEAD_DYING:
2358                                         {
2359                                                 if ((this.respawn_flags & RESPAWN_FORCE) && !(this.respawn_time < this.respawn_time_max))
2360                                                         this.deadflag = DEAD_RESPAWNING;
2361                                                 else if (!button_pressed || (time >= this.respawn_time_max && (this.respawn_flags & RESPAWN_FORCE)))
2362                                                         this.deadflag = DEAD_DEAD;
2363                                                 break;
2364                                         }
2365                                         case DEAD_DEAD:
2366                                         {
2367                                                 if (button_pressed)
2368                                                         this.deadflag = DEAD_RESPAWNABLE;
2369                                                 else if (time >= this.respawn_time_max && (this.respawn_flags & RESPAWN_FORCE))
2370                                                         this.deadflag = DEAD_RESPAWNING;
2371                                                 break;
2372                                         }
2373                                         case DEAD_RESPAWNABLE:
2374                                         {
2375                                                 if (!button_pressed || (this.respawn_flags & RESPAWN_FORCE))
2376                                                         this.deadflag = DEAD_RESPAWNING;
2377                                                 break;
2378                                         }
2379                                         case DEAD_RESPAWNING:
2380                                         {
2381                                                 if (time > this.respawn_time)
2382                                                 {
2383                                                         this.respawn_time = time + 1; // only retry once a second
2384                                                         this.respawn_time_max = this.respawn_time;
2385                                                         respawn(this);
2386                                                 }
2387                                                 break;
2388                                         }
2389                                 }
2390
2391                                 ShowRespawnCountdown(this);
2392
2393                                 if (this.respawn_flags & RESPAWN_SILENT)
2394                                         STAT(RESPAWN_TIME, this) = 0;
2395                                 else if ((this.respawn_flags & RESPAWN_FORCE) && this.respawn_time < this.respawn_time_max)
2396                                 {
2397                                         if (time < this.respawn_time)
2398                                                 STAT(RESPAWN_TIME, this) = this.respawn_time;
2399                                         else if (this.deadflag != DEAD_RESPAWNING)
2400                                                 STAT(RESPAWN_TIME, this) = -this.respawn_time_max;
2401                                 }
2402                                 else
2403                                         STAT(RESPAWN_TIME, this) = this.respawn_time;
2404                         }
2405
2406                         // if respawning, invert stat_respawn_time to indicate this, the client translates it
2407                         if (this.deadflag == DEAD_RESPAWNING && STAT(RESPAWN_TIME, this) > 0)
2408                                 STAT(RESPAWN_TIME, this) *= -1;
2409
2410                         return;
2411                 }
2412
2413                 this.prevorigin = this.origin;
2414
2415                 bool do_crouch = PHYS_INPUT_BUTTON_CROUCH(this);
2416                 if (this.hook.state) {
2417                         do_crouch = false;
2418                 } else if (this.waterlevel >= WATERLEVEL_SWIMMING) {
2419                         do_crouch = false;
2420                 } else if (this.vehicle) {
2421                         do_crouch = false;
2422                 } else if (STAT(FROZEN, this)) {
2423                         do_crouch = false;
2424         }
2425
2426                 if (do_crouch) {
2427                         if (!this.crouch) {
2428                                 this.crouch = true;
2429                                 this.view_ofs = STAT(PL_CROUCH_VIEW_OFS, this);
2430                                 setsize(this, STAT(PL_CROUCH_MIN, this), STAT(PL_CROUCH_MAX, this));
2431                                 // setanim(this, this.anim_duck, false, true, true); // this anim is BROKEN anyway
2432                         }
2433                 } else if (this.crouch) {
2434             tracebox(this.origin, STAT(PL_MIN, this), STAT(PL_MAX, this), this.origin, false, this);
2435             if (!trace_startsolid) {
2436                 this.crouch = false;
2437                 this.view_ofs = STAT(PL_VIEW_OFS, this);
2438                 setsize(this, STAT(PL_MIN, this), STAT(PL_MAX, this));
2439             }
2440                 }
2441
2442                 FixPlayermodel(this);
2443
2444                 // LordHavoc: allow firing on move frames (sub-ticrate), this gives better timing on slow servers
2445                 //if(frametime)
2446                 {
2447                         this.items &= ~this.items_added;
2448
2449                         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2450                         {
2451                                 .entity weaponentity = weaponentities[slot];
2452                                 W_WeaponFrame(this, weaponentity);
2453
2454                                 if(slot == 0)
2455                                 {
2456                                         this.clip_load = this.(weaponentity).clip_load;
2457                                         this.clip_size = this.(weaponentity).clip_size;
2458                                 }
2459                         }
2460
2461                         this.items_added = 0;
2462                         if (this.items & ITEM_Jetpack.m_itemid && (this.items & ITEM_JetpackRegen.m_itemid || this.ammo_fuel >= 0.01))
2463                 this.items_added |= IT_FUEL;
2464
2465                         this.items |= this.items_added;
2466                 }
2467
2468                 player_regen(this);
2469
2470                 // WEAPONTODO: Add a weapon request for this
2471                 // rot vortex charge to the charge limit
2472                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2473                 {
2474                         .entity weaponentity = weaponentities[slot];
2475                         if (WEP_CVAR(vortex, charge_rot_rate) && this.(weaponentity).vortex_charge > WEP_CVAR(vortex, charge_limit) && this.(weaponentity).vortex_charge_rottime < time)
2476                                 this.(weaponentity).vortex_charge = bound(WEP_CVAR(vortex, charge_limit), this.(weaponentity).vortex_charge - WEP_CVAR(vortex, charge_rot_rate) * frametime / W_TICSPERFRAME, 1);
2477                 }
2478
2479                 if (frametime) player_anim(this);
2480
2481                 // secret status
2482                 secrets_setstatus(this);
2483
2484                 // monsters status
2485                 monsters_setstatus(this);
2486
2487                 this.dmg_team = max(0, this.dmg_team - autocvar_g_teamdamage_resetspeed * frametime);
2488         }
2489         else if (gameover) {
2490                 if (intermission_running) IntermissionThink(this);
2491                 return;
2492         }
2493         else if (IS_OBSERVER(this)) {
2494                 ObserverThink(this);
2495         }
2496         else if (IS_SPEC(this)) {
2497                 SpectatorThink(this);
2498         }
2499
2500         // WEAPONTODO: Add weapon request for this
2501         if (!zoomstate_set) {
2502                 bool wep_zoomed = false;
2503                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2504                 {
2505                         .entity weaponentity = weaponentities[slot];
2506                         Weapon thiswep = this.(weaponentity).m_weapon;
2507                         if(thiswep != WEP_Null && thiswep.wr_zoom)
2508                                 wep_zoomed += thiswep.wr_zoom(thiswep, this);
2509                 }
2510                 SetZoomState(this, PHYS_INPUT_BUTTON_ZOOM(this) || PHYS_INPUT_BUTTON_ZOOMSCRIPT(this) || wep_zoomed);
2511     }
2512
2513         if (this.teamkill_soundtime && time > this.teamkill_soundtime)
2514         {
2515                 this.teamkill_soundtime = 0;
2516
2517                 entity e = this.teamkill_soundsource;
2518                 entity oldpusher = e.pusher;
2519                 e.pusher = this;
2520                 PlayerSound(e, playersound_teamshoot, CH_VOICE, VOL_BASEVOICE, VOICETYPE_LASTATTACKER_ONLY);
2521                 e.pusher = oldpusher;
2522         }
2523
2524         if (this.taunt_soundtime && time > this.taunt_soundtime) {
2525                 this.taunt_soundtime = 0;
2526                 PlayerSound(this, playersound_taunt, CH_VOICE, VOL_BASEVOICE, VOICETYPE_AUTOTAUNT);
2527         }
2528
2529         target_voicescript_next(this);
2530
2531         // WEAPONTODO: Move into weaponsystem somehow
2532         // if a player goes unarmed after holding a loaded weapon, empty his clip size and remove the crosshair ammo ring
2533         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2534         {
2535                 .entity weaponentity = weaponentities[slot];
2536                 if(this.(weaponentity).m_weapon == WEP_Null)
2537                         this.(weaponentity).clip_load = this.(weaponentity).clip_size = 0;
2538         }
2539 }
2540
2541 void DrownPlayer(entity this)
2542 {
2543         if(IS_DEAD(this))
2544                 return;
2545
2546         if (this.waterlevel != WATERLEVEL_SUBMERGED || this.vehicle)
2547         {
2548                 if(this.air_finished < time)
2549                         PlayerSound(this, playersound_gasp, CH_PLAYER, VOL_BASE, VOICETYPE_PLAYERSOUND);
2550                 this.air_finished = time + autocvar_g_balance_contents_drowndelay;
2551                 this.dmg = 2;
2552         }
2553         else if (this.air_finished < time)
2554         {       // drown!
2555                 if (this.pain_finished < time)
2556                 {
2557                         Damage (this, NULL, NULL, autocvar_g_balance_contents_playerdamage_drowning * autocvar_g_balance_contents_damagerate, DEATH_DROWN.m_id, this.origin, '0 0 0');
2558                         this.pain_finished = time + 0.5;
2559                 }
2560         }
2561 }
2562
2563 .bool move_qcphysics;
2564
2565 void Player_Physics(entity this)
2566 {
2567         set_movetype(this, this.move_movetype);
2568
2569         if(!this.move_qcphysics)
2570                 return;
2571
2572         if(!frametime && !this.pm_frametime)
2573                 return;
2574
2575         Movetype_Physics_NoMatchTicrate(this, this.pm_frametime, true);
2576
2577         this.pm_frametime = 0;
2578 }
2579
2580 /*
2581 =============
2582 PlayerPostThink
2583
2584 Called every frame for each client after the physics are run
2585 =============
2586 */
2587 .float idlekick_lasttimeleft;
2588 void PlayerPostThink (entity this)
2589 {
2590         Player_Physics(this);
2591
2592         if (sv_maxidle > 0)
2593         if (frametime) // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2594         if (IS_REAL_CLIENT(this))
2595         if (IS_PLAYER(this) || sv_maxidle_spectatorsareidle)
2596         {
2597                 int totalClients = 0;
2598                 if(sv_maxidle_slots > 0)
2599                 {
2600                         FOREACH_CLIENT(IS_REAL_CLIENT(it) || sv_maxidle_slots_countbots,
2601                         {
2602                                 ++totalClients;
2603                         });
2604                 }
2605
2606                 if (sv_maxidle_slots > 0 && (maxclients - totalClients) > sv_maxidle_slots)
2607                 { /* do nothing */ }
2608                 else if (time - this.parm_idlesince < 1) // instead of (time == this.parm_idlesince) to support sv_maxidle <= 10
2609                 {
2610                         if (this.idlekick_lasttimeleft)
2611                         {
2612                                 this.idlekick_lasttimeleft = 0;
2613                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_IDLING);
2614                         }
2615                 }
2616                 else
2617                 {
2618                         float timeleft = ceil(sv_maxidle - (time - this.parm_idlesince));
2619                         if (timeleft == min(10, sv_maxidle - 1)) { // - 1 to support sv_maxidle <= 10
2620                                 if (!this.idlekick_lasttimeleft)
2621                                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_DISCONNECT_IDLING, timeleft);
2622                         }
2623                         if (timeleft <= 0) {
2624                                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_QUIT_KICK_IDLING, this.netname);
2625                                 dropclient(this);
2626                                 return;
2627                         }
2628                         else if (timeleft <= 10) {
2629                                 if (timeleft != this.idlekick_lasttimeleft) {
2630                                     Send_Notification(NOTIF_ONE, this, MSG_ANNCE, Announcer_PickNumber(CNT_IDLE, timeleft));
2631                 }
2632                                 this.idlekick_lasttimeleft = timeleft;
2633                         }
2634                 }
2635         }
2636
2637         CheatFrame(this);
2638
2639         //CheckPlayerJump();
2640
2641         if (IS_PLAYER(this)) {
2642                 DrownPlayer(this);
2643                 CheckRules_Player(this);
2644                 UpdateChatBubble(this);
2645                 if (this.impulse) ImpulseCommands(this);
2646                 if (intermission_running) return; // intermission or finale
2647                 GetPressedKeys(this);
2648         }
2649
2650         if (this.waypointsprite_attachedforcarrier) {
2651             vector v = healtharmor_maxdamage(this.health, this.armorvalue, autocvar_g_balance_armor_blockpercent, DEATH_WEAPON.m_id);
2652                 WaypointSprite_UpdateHealth(this.waypointsprite_attachedforcarrier, '1 0 0' * v);
2653     }
2654
2655         playerdemo_write(this);
2656
2657         CSQCMODEL_AUTOUPDATE(this);
2658 }