qcsrc/server/client.qc

   1 #include "client.qh"
   2
   3 #include "anticheat.qh"
   4 #include "impulse.qh"
   5 #include "player.qh"
   6 #include "ipban.qh"
   7 #include "miscfunctions.qh"
   8 #include "portals.qh"
   9 #include "teamplay.qh"
  10 #include "playerdemo.qh"
  11 #include "spawnpoints.qh"
  12 #include "g_damage.qh"
  13 #include "g_hook.qh"
  14 #include "command/common.qh"
  15 #include "cheats.qh"
  16 #include "g_world.qh"
  17 #include "race.qh"
  18 #include "antilag.qh"
  19 #include "campaign.qh"
  20 #include "command/common.qh"
  21 #include "scores_rules.qh"
  22
  23 #include "bot/api.qh"
  24
  25 #include "../common/ent_cs.qh"
  26 #include "../common/wepent.qh"
  27 #include <common/state.qh>
  28
  29 #include <common/effects/qc/globalsound.qh>
  30
  31 #include "../common/triggers/func/conveyor.qh"
  32 #include "../common/triggers/teleporters.qh"
  33
  34 #include "../common/vehicles/all.qh"
  35
  36 #include "weapons/hitplot.qh"
  37 #include "weapons/weaponsystem.qh"
  38
  39 #include "../common/net_notice.qh"
  40 #include "../common/net_linked.qh"
  41 #include "../common/physics/player.qh"
  42
  43 #include "../common/items/_mod.qh"
  44
  45 #include "../common/mutators/mutator/waypoints/all.qh"
  46
  47 #include "../common/triggers/subs.qh"
  48 #include "../common/triggers/triggers.qh"
  49 #include "../common/triggers/trigger/secret.qh"
  50
  51 #include "../common/minigames/sv_minigames.qh"
  52
  53 #include "../common/items/inventory.qh"
  54
  55 #include "../common/monsters/sv_monsters.qh"
  56
  57 #include "../lib/warpzone/server.qh"
  58
  59 STATIC_METHOD(Client, Add, void(Client this, int _team))
  60 {
  61     ClientConnect(this);
  62     TRANSMUTE(Player, this);
  63     this.frame = 12; // 7
  64     this.team = _team;
  65     PutClientInServer(this);
  66 }
  67
  68 void PutObserverInServer(entity this);
  69
  70 STATIC_METHOD(Client, Remove, void(Client this))
  71 {
  72     TRANSMUTE(Observer, this);
  73     PutClientInServer(this);
  74     ClientDisconnect(this);
  75 }
  76
  77 void send_CSQC_teamnagger() {
  78         WriteHeader(MSG_BROADCAST, TE_CSQC_TEAMNAGGER);
  79 }
  80
  81 int CountSpectators(entity player, entity to)
  82 {
  83         if(!player) { return 0; } // not sure how, but best to be safe
  84
  85         int spec_count = 0;
  86
  87         FOREACH_CLIENT(IS_REAL_CLIENT(it) && IS_SPEC(it) && it != to && it.enemy == player,
  88         {
  89                 spec_count++;
  90         });
  91
  92         return spec_count;
  93 }
  94
  95 void WriteSpectators(entity player, entity to)
  96 {
  97         if(!player) { return; } // not sure how, but best to be safe
  98
  99         FOREACH_CLIENT(IS_REAL_CLIENT(it) && IS_SPEC(it) && it != to && it.enemy == player,
 100         {
 101                 WriteByte(MSG_ENTITY, num_for_edict(it));
 102         });
 103 }
 104
 105 bool ClientData_Send(entity this, entity to, int sf)
 106 {
 107         assert(to == this.owner, return false);
 108
 109         entity e = to;
 110         if (IS_SPEC(e)) e = e.enemy;
 111
 112         sf = 0;
 113         if (CS(e).race_completed)       sf |= 1; // forced scoreboard
 114         if (CS(to).spectatee_status)    sf |= 2; // spectator ent number follows
 115         if (CS(e).zoomstate)            sf |= 4; // zoomed
 116         if (autocvar_sv_showspectators) sf |= 16; // show spectators
 117
 118         WriteHeader(MSG_ENTITY, ENT_CLIENT_CLIENTDATA);
 119         WriteByte(MSG_ENTITY, sf);
 120
 121         if (sf & 2)
 122         {
 123                 WriteByte(MSG_ENTITY, CS(to).spectatee_status);
 124         }
 125
 126         if(sf & 16)
 127         {
 128                 float specs = CountSpectators(e, to);
 129                 WriteByte(MSG_ENTITY, specs);
 130                 WriteSpectators(e, to);
 131         }
 132
 133         return true;
 134 }
 135
 136 void ClientData_Attach(entity this)
 137 {
 138         Net_LinkEntity(CS(this).clientdata = new_pure(clientdata), false, 0, ClientData_Send);
 139         CS(this).clientdata.drawonlytoclient = this;
 140         CS(this).clientdata.owner = this;
 141 }
 142
 143 void ClientData_Detach(entity this)
 144 {
 145         delete(CS(this).clientdata);
 146         CS(this).clientdata = NULL;
 147 }
 148
 149 void ClientData_Touch(entity e)
 150 {
 151         CS(e).clientdata.SendFlags = 1;
 152
 153         // make it spectatable
 154         FOREACH_CLIENT(IS_REAL_CLIENT(it) && it != e && IS_SPEC(it) && it.enemy == e, LAMBDA(CS(it).clientdata.SendFlags = 1));
 155 }
 156
 157 void SetSpectatee(entity this, entity spectatee);
 158 void SetSpectatee_status(entity this, int spectatee_num);
 159
 160
 161 /*
 162 =============
 163 CheckPlayerModel
 164
 165 Checks if the argument string can be a valid playermodel.
 166 Returns a valid one in doubt.
 167 =============
 168 */
 169 string FallbackPlayerModel;
 170 string CheckPlayerModel(string plyermodel) {
 171         if(FallbackPlayerModel != cvar_defstring("_cl_playermodel"))
 172         {
 173                 // note: we cannot summon Don Strunzone here, some player may
 174                 // still have the model string set. In case anyone manages how
 175                 // to change a cvar default, we'll have a small leak here.
 176                 FallbackPlayerModel = strzone(cvar_defstring("_cl_playermodel"));
 177         }
 178         // only in right path
 179         if( substring(plyermodel,0,14) != "models/player/")
 180                 return FallbackPlayerModel;
 181         // only good file extensions
 182         if(substring(plyermodel,-4,4) != ".zym")
 183         if(substring(plyermodel,-4,4) != ".dpm")
 184         if(substring(plyermodel,-4,4) != ".iqm")
 185         if(substring(plyermodel,-4,4) != ".md3")
 186         if(substring(plyermodel,-4,4) != ".psk")
 187                 return FallbackPlayerModel;
 188         // forbid the LOD models
 189         if(substring(plyermodel, -9,5) == "_lod1")
 190                 return FallbackPlayerModel;
 191         if(substring(plyermodel, -9,5) == "_lod2")
 192                 return FallbackPlayerModel;
 193         if(plyermodel != strtolower(plyermodel))
 194                 return FallbackPlayerModel;
 195         // also, restrict to server models
 196         if(autocvar_sv_servermodelsonly)
 197         {
 198                 if(!fexists(plyermodel))
 199                         return FallbackPlayerModel;
 200         }
 201         return plyermodel;
 202 }
 203
 204 void setplayermodel(entity e, string modelname)
 205 {
 206         precache_model(modelname);
 207         _setmodel(e, modelname);
 208         player_setupanimsformodel(e);
 209         if(!autocvar_g_debug_globalsounds)
 210                 UpdatePlayerSounds(e);
 211 }
 212
 213 void FixPlayermodel(entity player);
 214 /** putting a client as observer in the server */
 215 void PutObserverInServer(entity this)
 216 {
 217     bool mutator_returnvalue = MUTATOR_CALLHOOK(MakePlayerObserver, this);
 218         PlayerState_detach(this);
 219
 220         if (IS_PLAYER(this) && this.health >= 1) {
 221         // despawn effect
 222                 Send_Effect(EFFECT_SPAWN_NEUTRAL, this.origin, '0 0 0', 1);
 223     }
 224
 225     {
 226         entity spot = SelectSpawnPoint(this, true);
 227         if (!spot) LOG_FATAL("No spawnpoints for observers?!?");
 228         this.angles = vec2(spot.angles);
 229         this.fixangle = true;
 230         // offset it so that the spectator spawns higher off the ground, looks better this way
 231         setorigin(this, spot.origin + STAT(PL_VIEW_OFS, this));
 232         if (IS_REAL_CLIENT(this))
 233         {
 234             msg_entity = this;
 235             WriteByte(MSG_ONE, SVC_SETVIEW);
 236             WriteEntity(MSG_ONE, this);
 237         }
 238         // give the spectator some space between walls for MOVETYPE_FLY_WORLDONLY
 239         // so that your view doesn't go into the ceiling with MOVETYPE_FLY_WORLDONLY, previously "PL_VIEW_OFS"
 240         if(!autocvar_g_debug_globalsounds)
 241         {
 242                 // needed for player sounds
 243                 this.model = "";
 244                 FixPlayermodel(this);
 245         }
 246         setmodel(this, MDL_Null);
 247         setsize(this, STAT(PL_CROUCH_MIN, this), STAT(PL_CROUCH_MAX, this));
 248         this.view_ofs = '0 0 0';
 249     }
 250
 251     RemoveGrapplingHooks(this);
 252         Portal_ClearAll(this);
 253         Unfreeze(this);
 254         SetSpectatee(this, NULL);
 255
 256         if (this.alivetime)
 257         {
 258                 if (!warmup_stage)
 259                         PS_GR_P_ADDVAL(this, PLAYERSTATS_ALIVETIME, time - this.alivetime);
 260                 this.alivetime = 0;
 261         }
 262
 263         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
 264
 265         WaypointSprite_PlayerDead(this);
 266
 267         if (mutator_returnvalue) {
 268             // mutator prevents resetting teams+score
 269         } else {
 270                 this.team = -1;  // move this as it is needed to log the player spectating in eventlog
 271         this.frags = FRAGS_SPECTATOR;
 272         PlayerScore_Clear(this);  // clear scores when needed
 273     }
 274
 275         if (CS(this).killcount != FRAGS_SPECTATOR)
 276         {
 277                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_QUIT_SPECTATE, this.netname);
 278                 if(!game_stopped)
 279                 if(autocvar_g_chat_nospectators == 1 || (!warmup_stage && autocvar_g_chat_nospectators == 2))
 280                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_CHAT_NOSPECTATORS);
 281
 282                 if(!CS(this).just_joined)
 283                         LogTeamchange(this.playerid, -1, 4);
 284                 else
 285                         CS(this).just_joined = false;
 286         }
 287
 288         accuracy_resend(this);
 289
 290         CS(this).spectatortime = time;
 291         if(this.bot_attack)
 292                 IL_REMOVE(g_bot_targets, this);
 293         this.bot_attack = false;
 294     this.hud = HUD_NORMAL;
 295         TRANSMUTE(Observer, this);
 296         this.iscreature = false;
 297         this.teleportable = TELEPORT_SIMPLE;
 298         if(this.damagedbycontents)
 299                 IL_REMOVE(g_damagedbycontents, this);
 300         this.damagedbycontents = false;
 301         this.health = FRAGS_SPECTATOR;
 302         SetSpectatee_status(this, etof(this));
 303         this.takedamage = DAMAGE_NO;
 304         this.solid = SOLID_NOT;
 305         set_movetype(this, MOVETYPE_FLY_WORLDONLY); // user preference is controlled by playerprethink
 306         this.flags = FL_CLIENT | FL_NOTARGET;
 307         this.armorvalue = 666;
 308         this.effects = 0;
 309         this.armorvalue = autocvar_g_balance_armor_start;
 310         this.pauserotarmor_finished = 0;
 311         this.pauserothealth_finished = 0;
 312         this.pauseregen_finished = 0;
 313         this.damageforcescale = 0;
 314         this.death_time = 0;
 315         this.respawn_flags = 0;
 316         this.respawn_time = 0;
 317         this.stat_respawn_time = 0;
 318         this.alpha = 0;
 319         this.scale = 0;
 320         this.fade_time = 0;
 321         this.pain_frame = 0;
 322         this.pain_finished = 0;
 323         this.strength_finished = 0;
 324         this.invincible_finished = 0;
 325         this.superweapons_finished = 0;
 326         this.pushltime = 0;
 327         this.istypefrag = 0;
 328         setthink(this, func_null);
 329         this.nextthink = 0;
 330         this.deadflag = DEAD_NO;
 331         this.crouch = false;
 332         this.revive_progress = 0;
 333         this.revival_time = 0;
 334
 335         this.items = 0;
 336         this.weapons = '0 0 0';
 337         this.drawonlytoclient = this;
 338
 339         this.weaponmodel = "";
 340         for (int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 341         {
 342                 this.weaponentities[slot] = NULL;
 343         }
 344         this.exteriorweaponentity = NULL;
 345         CS(this).killcount = FRAGS_SPECTATOR;
 346         this.velocity = '0 0 0';
 347         this.avelocity = '0 0 0';
 348         this.punchangle = '0 0 0';
 349         this.punchvector = '0 0 0';
 350         this.oldvelocity = this.velocity;
 351         this.fire_endtime = -1;
 352         this.event_damage = func_null;
 353
 354         for(int slot = 0; slot < MAX_AXH; ++slot)
 355         {
 356                 entity axh = this.(AuxiliaryXhair[slot]);
 357                 this.(AuxiliaryXhair[slot]) = NULL;
 358
 359                 if(axh.owner == this && axh != NULL && !wasfreed(axh))
 360                         delete(axh);
 361         }
 362 }
 363
 364 int player_getspecies(entity this)
 365 {
 366         get_model_parameters(this.model, this.skin);
 367         int s = get_model_parameters_species;
 368         get_model_parameters(string_null, 0);
 369         if (s < 0) return SPECIES_HUMAN;
 370         return s;
 371 }
 372
 373 .float model_randomizer;
 374 void FixPlayermodel(entity player)
 375 {
 376         string defaultmodel = "";
 377         int defaultskin = 0;
 378         if(autocvar_sv_defaultcharacter)
 379         {
 380                 if(teamplay)
 381                 {
 382                         switch(player.team)
 383                         {
 384                                 case NUM_TEAM_1: defaultmodel = autocvar_sv_defaultplayermodel_red; defaultskin = autocvar_sv_defaultplayerskin_red; break;
 385                                 case NUM_TEAM_2: defaultmodel = autocvar_sv_defaultplayermodel_blue; defaultskin = autocvar_sv_defaultplayerskin_blue; break;
 386                                 case NUM_TEAM_3: defaultmodel = autocvar_sv_defaultplayermodel_yellow; defaultskin = autocvar_sv_defaultplayerskin_yellow; break;
 387                                 case NUM_TEAM_4: defaultmodel = autocvar_sv_defaultplayermodel_pink; defaultskin = autocvar_sv_defaultplayerskin_pink; break;
 388                         }
 389                 }
 390
 391                 if(defaultmodel == "")
 392                 {
 393                         defaultmodel = autocvar_sv_defaultplayermodel;
 394                         defaultskin = autocvar_sv_defaultplayerskin;
 395                 }
 396
 397                 int n = tokenize_console(defaultmodel);
 398                 if(n > 0)
 399                 {
 400                         defaultmodel = argv(floor(n * CS(player).model_randomizer));
 401                         // However, do NOT randomize if the player-selected model is in the list.
 402                         for (int i = 0; i < n; ++i)
 403                                 if ((argv(i) == player.playermodel && defaultskin == stof(player.playerskin)) || argv(i) == strcat(player.playermodel, ":", player.playerskin))
 404                                         defaultmodel = argv(i);
 405                 }
 406
 407                 int i = strstrofs(defaultmodel, ":", 0);
 408                 if(i >= 0)
 409                 {
 410                         defaultskin = stof(substring(defaultmodel, i+1, -1));
 411                         defaultmodel = substring(defaultmodel, 0, i);
 412                 }
 413         }
 414         if(autocvar_sv_defaultcharacterskin && !defaultskin)
 415         {
 416                 if(teamplay)
 417                 {
 418                         switch(player.team)
 419                         {
 420                                 case NUM_TEAM_1: defaultskin = autocvar_sv_defaultplayerskin_red; break;
 421                                 case NUM_TEAM_2: defaultskin = autocvar_sv_defaultplayerskin_blue; break;
 422                                 case NUM_TEAM_3: defaultskin = autocvar_sv_defaultplayerskin_yellow; break;
 423                                 case NUM_TEAM_4: defaultskin = autocvar_sv_defaultplayerskin_pink; break;
 424                         }
 425                 }
 426
 427                 if(!defaultskin)
 428                         defaultskin = autocvar_sv_defaultplayerskin;
 429         }
 430
 431         MUTATOR_CALLHOOK(FixPlayermodel, defaultmodel, defaultskin, player);
 432         defaultmodel = M_ARGV(0, string);
 433         defaultskin = M_ARGV(1, int);
 434
 435         bool chmdl = false;
 436         int oldskin;
 437         if(defaultmodel != "")
 438         {
 439                 if (defaultmodel != player.model)
 440                 {
 441                         vector m1 = player.mins;
 442                         vector m2 = player.maxs;
 443                         setplayermodel (player, defaultmodel);
 444                         setsize (player, m1, m2);
 445                         chmdl = true;
 446                 }
 447
 448                 oldskin = player.skin;
 449                 player.skin = defaultskin;
 450         } else {
 451                 if (player.playermodel != player.model || player.playermodel == "")
 452                 {
 453                         player.playermodel = CheckPlayerModel(player.playermodel); // this is never "", so no endless loop
 454                         vector m1 = player.mins;
 455                         vector m2 = player.maxs;
 456                         setplayermodel (player, player.playermodel);
 457                         setsize (player, m1, m2);
 458                         chmdl = true;
 459                 }
 460
 461                 if(!autocvar_sv_defaultcharacterskin)
 462                 {
 463                         oldskin = player.skin;
 464                         player.skin = stof(player.playerskin);
 465                 }
 466                 else
 467                 {
 468                         oldskin = player.skin;
 469                         player.skin = defaultskin;
 470                 }
 471         }
 472
 473         if(chmdl || oldskin != player.skin) // model or skin has changed
 474         {
 475                 player.species = player_getspecies(player); // update species
 476                 if(!autocvar_g_debug_globalsounds)
 477                         UpdatePlayerSounds(player); // update skin sounds
 478         }
 479
 480         if(!teamplay)
 481                 if(strlen(autocvar_sv_defaultplayercolors))
 482                         if(player.clientcolors != stof(autocvar_sv_defaultplayercolors))
 483                                 setcolor(player, stof(autocvar_sv_defaultplayercolors));
 484 }
 485
 486 void PutPlayerInServer(entity this)
 487 {
 488         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
 489
 490         PlayerState_attach(this);
 491         accuracy_resend(this);
 492
 493         if (this.team < 0)
 494                 JoinBestTeam(this, false, true);
 495
 496         entity spot = SelectSpawnPoint(this, false);
 497         if (!spot) {
 498                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_JOIN_NOSPAWNS);
 499                 return; // spawn failed
 500         }
 501
 502         TRANSMUTE(Player, this);
 503
 504         CS(this).wasplayer = true;
 505         this.iscreature = true;
 506         this.teleportable = TELEPORT_NORMAL;
 507         if(!this.damagedbycontents)
 508                 IL_PUSH(g_damagedbycontents, this);
 509         this.damagedbycontents = true;
 510         set_movetype(this, MOVETYPE_WALK);
 511         this.solid = SOLID_SLIDEBOX;
 512         this.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_SOLID;
 513         if (autocvar_g_playerclip_collisions)
 514                 this.dphitcontentsmask |= DPCONTENTS_PLAYERCLIP;
 515         if (IS_BOT_CLIENT(this) && autocvar_g_botclip_collisions)
 516                 this.dphitcontentsmask |= DPCONTENTS_BOTCLIP;
 517         this.frags = FRAGS_PLAYER;
 518         if (INDEPENDENT_PLAYERS) MAKE_INDEPENDENT_PLAYER(this);
 519         this.flags = FL_CLIENT | FL_PICKUPITEMS;
 520         if (autocvar__notarget)
 521                 this.flags |= FL_NOTARGET;
 522         this.takedamage = DAMAGE_AIM;
 523         this.effects = EF_TELEPORT_BIT | EF_RESTARTANIM_BIT;
 524         this.dmg = 2; // WTF
 525
 526         if (warmup_stage) {
 527                 this.ammo_shells = warmup_start_ammo_shells;
 528                 this.ammo_nails = warmup_start_ammo_nails;
 529                 this.ammo_rockets = warmup_start_ammo_rockets;
 530                 this.ammo_cells = warmup_start_ammo_cells;
 531                 this.ammo_plasma = warmup_start_ammo_plasma;
 532                 this.ammo_fuel = warmup_start_ammo_fuel;
 533                 this.health = warmup_start_health;
 534                 this.armorvalue = warmup_start_armorvalue;
 535                 this.weapons = WARMUP_START_WEAPONS;
 536         } else {
 537                 this.ammo_shells = start_ammo_shells;
 538                 this.ammo_nails = start_ammo_nails;
 539                 this.ammo_rockets = start_ammo_rockets;
 540                 this.ammo_cells = start_ammo_cells;
 541                 this.ammo_plasma = start_ammo_plasma;
 542                 this.ammo_fuel = start_ammo_fuel;
 543                 this.health = start_health;
 544                 this.armorvalue = start_armorvalue;
 545                 this.weapons = start_weapons;
 546         }
 547         SetSpectatee_status(this, 0);
 548
 549         PS(this).dual_weapons = '0 0 0';
 550
 551         this.superweapons_finished = (this.weapons & WEPSET_SUPERWEAPONS) ? time + autocvar_g_balance_superweapons_time : 0;
 552
 553         this.items = start_items;
 554
 555         this.spawnshieldtime = time + autocvar_g_spawnshieldtime;
 556         this.pauserotarmor_finished = time + autocvar_g_balance_pause_armor_rot_spawn;
 557         this.pauserothealth_finished = time + autocvar_g_balance_pause_health_rot_spawn;
 558         this.pauserotfuel_finished = time + autocvar_g_balance_pause_fuel_rot_spawn;
 559         this.pauseregen_finished = time + autocvar_g_balance_pause_health_regen_spawn;
 560         // extend the pause of rotting if client was reset at the beginning of the countdown
 561         if (!autocvar_sv_ready_restart_after_countdown && time < game_starttime) { // TODO why is this cvar NOTted?
 562                 float f = game_starttime - time;
 563                 this.spawnshieldtime += f;
 564                 this.pauserotarmor_finished += f;
 565                 this.pauserothealth_finished += f;
 566                 this.pauseregen_finished += f;
 567         }
 568         this.damageforcescale = 2;
 569         this.death_time = 0;
 570         this.respawn_flags = 0;
 571         this.respawn_time = 0;
 572         this.stat_respawn_time = 0;
 573         this.scale = autocvar_sv_player_scale;
 574         this.fade_time = 0;
 575         this.pain_frame = 0;
 576         this.pain_finished = 0;
 577         this.pushltime = 0;
 578         setthink(this, func_null); // players have no think function
 579         this.nextthink = 0;
 580         this.dmg_team = 0;
 581         PS(this).ballistics_density = autocvar_g_ballistics_density_player;
 582
 583         this.deadflag = DEAD_NO;
 584
 585         this.angles = spot.angles;
 586         this.angles_z = 0; // never spawn tilted even if the spot says to
 587         if (IS_BOT_CLIENT(this))
 588                 this.v_angle = this.angles;
 589         this.fixangle = true; // turn this way immediately
 590         this.oldvelocity = this.velocity = '0 0 0';
 591         this.avelocity = '0 0 0';
 592         this.punchangle = '0 0 0';
 593         this.punchvector = '0 0 0';
 594
 595         this.strength_finished = 0;
 596         this.invincible_finished = 0;
 597         this.fire_endtime = -1;
 598         this.revive_progress = 0;
 599         this.revival_time = 0;
 600         this.air_finished = time + 12;
 601
 602         entity spawnevent = new_pure(spawnevent);
 603         spawnevent.owner = this;
 604         Net_LinkEntity(spawnevent, false, 0.5, SpawnEvent_Send);
 605
 606         // Cut off any still running player sounds.
 607         stopsound(this, CH_PLAYER_SINGLE);
 608
 609         this.model = "";
 610         FixPlayermodel(this);
 611         this.drawonlytoclient = NULL;
 612
 613         this.viewloc = NULL;
 614
 615         this.crouch = false;
 616         this.view_ofs = STAT(PL_VIEW_OFS, this);
 617         setsize(this, STAT(PL_MIN, this), STAT(PL_MAX, this));
 618         this.spawnorigin = spot.origin;
 619         setorigin(this, spot.origin + '0 0 1' * (1 - this.mins.z - 24));
 620         // don't reset back to last position, even if new position is stuck in solid
 621         this.oldorigin = this.origin;
 622         this.lastteleporttime = time; // prevent insane speeds due to changing origin
 623         if(this.conveyor)
 624                 IL_REMOVE(g_conveyed, this);
 625         this.conveyor = NULL; // prevent conveyors at the previous location from moving a freshly spawned player
 626         this.hud = HUD_NORMAL;
 627
 628         this.event_damage = PlayerDamage;
 629
 630         if(!this.bot_attack)
 631                 IL_PUSH(g_bot_targets, this);
 632         this.bot_attack = true;
 633         if(!this.monster_attack)
 634                 IL_PUSH(g_monster_targets, this);
 635         this.monster_attack = true;
 636         navigation_dynamicgoal_init(this, false);
 637
 638         PHYS_INPUT_BUTTON_ATCK(this) = PHYS_INPUT_BUTTON_JUMP(this) = PHYS_INPUT_BUTTON_ATCK2(this) = false;
 639
 640         if (CS(this).killcount == FRAGS_SPECTATOR) {
 641                 PlayerScore_Clear(this);
 642                 CS(this).killcount = 0;
 643         }
 644
 645         for (int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 646         {
 647                 .entity weaponentity = weaponentities[slot];
 648                 entity oldwep = this.(weaponentity);
 649                 CL_SpawnWeaponentity(this, weaponentity);
 650                 if(oldwep && oldwep.owner == this)
 651                         this.(weaponentity).m_gunalign = oldwep.m_gunalign;
 652         }
 653         this.alpha = default_player_alpha;
 654         this.colormod = '1 1 1' * autocvar_g_player_brightness;
 655         this.exteriorweaponentity.alpha = default_weapon_alpha;
 656
 657         this.speedrunning = false;
 658
 659         target_voicescript_clear(this);
 660
 661         // reset fields the weapons may use
 662         FOREACH(Weapons, true, LAMBDA(
 663                 it.wr_resetplayer(it, this);
 664                         // reload all reloadable weapons
 665                 if (it.spawnflags & WEP_FLAG_RELOADABLE) {
 666                         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 667                         {
 668                                 .entity weaponentity = weaponentities[slot];
 669                                 this.(weaponentity).weapon_load[it.m_id] = it.reloading_ammo;
 670                         }
 671                 }
 672         ));
 673
 674         {
 675                 string s = spot.target;
 676                 spot.target = string_null;
 677                 SUB_UseTargets(spot, this, NULL);
 678                 spot.target = s;
 679         }
 680
 681         Unfreeze(this);
 682
 683         MUTATOR_CALLHOOK(PlayerSpawn, this, spot);
 684
 685         if (autocvar_spawn_debug)
 686         {
 687                 sprint(this, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
 688                 delete(spot); // usefull for checking if there are spawnpoints, that let drop through the floor
 689         }
 690
 691         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 692         {
 693                 .entity weaponentity = weaponentities[slot];
 694                 if(slot == 0 || autocvar_g_weaponswitch_debug == 1)
 695                         this.(weaponentity).m_switchweapon = w_getbestweapon(this, weaponentity);
 696                 else
 697                         this.(weaponentity).m_switchweapon = WEP_Null;
 698                 this.(weaponentity).m_weapon = WEP_Null;
 699                 this.(weaponentity).weaponname = "";
 700                 this.(weaponentity).m_switchingweapon = WEP_Null;
 701                 this.(weaponentity).cnt = -1;
 702         }
 703
 704         MUTATOR_CALLHOOK(PlayerWeaponSelect, this);
 705
 706         if (!warmup_stage && !this.alivetime)
 707                 this.alivetime = time;
 708
 709         antilag_clear(this, CS(this));
 710 }
 711
 712 /** Called when a client spawns in the server */
 713 void PutClientInServer(entity this)
 714 {
 715         if (IS_BOT_CLIENT(this)) {
 716                 TRANSMUTE(Player, this);
 717         } else if (IS_REAL_CLIENT(this)) {
 718                 msg_entity = this;
 719                 WriteByte(MSG_ONE, SVC_SETVIEW);
 720                 WriteEntity(MSG_ONE, this);
 721         }
 722         if (game_stopped)
 723                 TRANSMUTE(Observer, this);
 724
 725         SetSpectatee(this, NULL);
 726
 727         // reset player keys
 728         if(PS(this))
 729                 PS(this).itemkeys = 0;
 730
 731         MUTATOR_CALLHOOK(PutClientInServer, this);
 732
 733         if (IS_OBSERVER(this)) {
 734                 PutObserverInServer(this);
 735         } else if (IS_PLAYER(this)) {
 736                 PutPlayerInServer(this);
 737         }
 738 }
 739
 740 void ClientInit_misc(entity this);
 741
 742 // TODO do we need all these fields, or should we stop autodetecting runtime
 743 // changes and just have a console command to update this?
 744 bool ClientInit_SendEntity(entity this, entity to, int sf)
 745 {
 746         WriteHeader(MSG_ENTITY, _ENT_CLIENT_INIT);
 747         return = true;
 748         msg_entity = to;
 749         // MSG_INIT replacement
 750         // TODO: make easier to use
 751         Registry_send_all();
 752         W_PROP_reload(MSG_ONE, to);
 753         ClientInit_misc(this);
 754         MUTATOR_CALLHOOK(Ent_Init);
 755 }
 756 void ClientInit_misc(entity this)
 757 {
 758         int channel = MSG_ONE;
 759         WriteHeader(channel, ENT_CLIENT_INIT);
 760         WriteByte(channel, g_nexball_meter_period * 32);
 761         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[0]));
 762         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[1]));
 763         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[2]));
 764         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[3]));
 765         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[0]));
 766         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[1]));
 767         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[2]));
 768         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[3]));
 769
 770         if(sv_foginterval && world.fog != "")
 771                 WriteString(channel, world.fog);
 772         else
 773                 WriteString(channel, "");
 774         WriteByte(channel, this.count * 255.0); // g_balance_armor_blockpercent
 775         WriteByte(channel, this.cnt * 255.0); // g_balance_damagepush_speedfactor
 776         WriteByte(channel, serverflags);
 777         WriteCoord(channel, autocvar_g_trueaim_minrange);
 778 }
 779
 780 void ClientInit_CheckUpdate(entity this)
 781 {
 782         this.nextthink = time;
 783         if(this.count != autocvar_g_balance_armor_blockpercent)
 784         {
 785                 this.count = autocvar_g_balance_armor_blockpercent;
 786                 this.SendFlags |= 1;
 787         }
 788         if(this.cnt != autocvar_g_balance_damagepush_speedfactor)
 789         {
 790                 this.cnt = autocvar_g_balance_damagepush_speedfactor;
 791                 this.SendFlags |= 1;
 792         }
 793 }
 794
 795 void ClientInit_Spawn()
 796 {
 797         entity e = new_pure(clientinit);
 798         setthink(e, ClientInit_CheckUpdate);
 799         Net_LinkEntity(e, false, 0, ClientInit_SendEntity);
 800
 801         ClientInit_CheckUpdate(e);
 802 }
 803
 804 /*
 805 =============
 806 SetNewParms
 807 =============
 808 */
 809 void SetNewParms ()
 810 {
 811         // initialize parms for a new player
 812         parm1 = -(86400 * 366);
 813
 814         MUTATOR_CALLHOOK(SetNewParms);
 815 }
 816
 817 /*
 818 =============
 819 SetChangeParms
 820 =============
 821 */
 822 void SetChangeParms (entity this)
 823 {
 824         // save parms for level change
 825         parm1 = CS(this).parm_idlesince - time;
 826
 827         MUTATOR_CALLHOOK(SetChangeParms);
 828 }
 829
 830 /*
 831 =============
 832 DecodeLevelParms
 833 =============
 834 */
 835 void DecodeLevelParms(entity this)
 836 {
 837         // load parms
 838         CS(this).parm_idlesince = parm1;
 839         if (CS(this).parm_idlesince == -(86400 * 366))
 840                 CS(this).parm_idlesince = time;
 841
 842         // whatever happens, allow 60 seconds of idling directly after connect for map loading
 843         CS(this).parm_idlesince = max(CS(this).parm_idlesince, time - sv_maxidle + 60);
 844
 845         MUTATOR_CALLHOOK(DecodeLevelParms);
 846 }
 847
 848 /*
 849 =============
 850 ClientKill
 851
 852 Called when a client types 'kill' in the console
 853 =============
 854 */
 855
 856 .float clientkill_nexttime;
 857 void ClientKill_Now_TeamChange(entity this)
 858 {
 859         if(CS(this).killindicator_teamchange == -1)
 860         {
 861                 JoinBestTeam( this, false, true );
 862         }
 863         else if(CS(this).killindicator_teamchange == -2)
 864         {
 865                 if(blockSpectators)
 866                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
 867                 PutObserverInServer(this);
 868         }
 869         else
 870                 SV_ChangeTeam(this, CS(this).killindicator_teamchange - 1);
 871         CS(this).killindicator_teamchange = 0;
 872 }
 873
 874 void ClientKill_Now(entity this)
 875 {
 876         if(this.vehicle)
 877         {
 878             vehicles_exit(this.vehicle, VHEF_RELEASE);
 879             if(!CS(this).killindicator_teamchange)
 880             {
 881             this.vehicle_health = -1;
 882             Damage(this, this, this, 1 , DEATH_KILL.m_id, this.origin, '0 0 0');
 883             }
 884         }
 885
 886         if(this.killindicator && !wasfreed(this.killindicator))
 887                 delete(this.killindicator);
 888
 889         this.killindicator = NULL;
 890
 891         if(CS(this).killindicator_teamchange)
 892                 ClientKill_Now_TeamChange(this);
 893
 894         if(!IS_SPEC(this) && !IS_OBSERVER(this))
 895                 Damage(this, this, this, 100000, DEATH_KILL.m_id, this.origin, '0 0 0');
 896
 897         // now I am sure the player IS dead
 898 }
 899 void KillIndicator_Think(entity this)
 900 {
 901         if (game_stopped)
 902         {
 903                 this.owner.killindicator = NULL;
 904                 delete(this);
 905                 return;
 906         }
 907
 908         if (this.owner.alpha < 0 && !this.owner.vehicle)
 909         {
 910                 this.owner.killindicator = NULL;
 911                 delete(this);
 912                 return;
 913         }
 914
 915         if(this.cnt <= 0)
 916         {
 917                 ClientKill_Now(this.owner);
 918                 return;
 919         }
 920     else if(this.health == 1) // health == 1 means that it's silent
 921     {
 922         this.nextthink = time + 1;
 923         this.cnt -= 1;
 924     }
 925         else
 926         {
 927                 if(this.cnt <= 10)
 928                         setmodel(this, MDL_NUM(this.cnt));
 929                 if(IS_REAL_CLIENT(this.owner))
 930                 {
 931                         if(this.cnt <= 10)
 932                                 { Send_Notification(NOTIF_ONE, this.owner, MSG_ANNCE, Announcer_PickNumber(CNT_KILL, this.cnt)); }
 933                 }
 934                 this.nextthink = time + 1;
 935                 this.cnt -= 1;
 936         }
 937 }
 938
 939 float clientkilltime;
 940 void ClientKill_TeamChange (entity this, float targetteam) // 0 = don't change, -1 = auto, -2 = spec
 941 {
 942         float killtime;
 943         float starttime;
 944
 945         if (game_stopped)
 946                 return;
 947
 948         killtime = autocvar_g_balance_kill_delay;
 949
 950     if(MUTATOR_CALLHOOK(ClientKill, this, killtime))
 951         return;
 952     killtime = M_ARGV(1, float);
 953
 954         CS(this).killindicator_teamchange = targetteam;
 955
 956     if(!this.killindicator)
 957         {
 958                 if(!IS_DEAD(this))
 959                 {
 960                         killtime = max(killtime, this.clientkill_nexttime - time);
 961                         this.clientkill_nexttime = time + killtime + autocvar_g_balance_kill_antispam;
 962                 }
 963
 964                 if(killtime <= 0 || !IS_PLAYER(this) || IS_DEAD(this))
 965                 {
 966                         ClientKill_Now(this);
 967                 }
 968                 else
 969                 {
 970                         starttime = max(time, clientkilltime);
 971
 972                         this.killindicator = spawn();
 973                         this.killindicator.owner = this;
 974                         this.killindicator.scale = 0.5;
 975                         setattachment(this.killindicator, this, "");
 976                         setorigin(this.killindicator, '0 0 52');
 977                         setthink(this.killindicator, KillIndicator_Think);
 978                         this.killindicator.nextthink = starttime + (this.lip) * 0.05;
 979                         clientkilltime = max(clientkilltime, this.killindicator.nextthink + 0.05);
 980                         this.killindicator.cnt = ceil(killtime);
 981                         this.killindicator.count = bound(0, ceil(killtime), 10);
 982                         //sprint(this, strcat("^1You'll be dead in ", ftos(this.killindicator.cnt), " seconds\n"));
 983
 984                         IL_EACH(g_clones, it.enemy == this && !(it.effects & CSQCMODEL_EF_RESPAWNGHOST),
 985                         {
 986                                 it.killindicator = spawn();
 987                                 it.killindicator.owner = it;
 988                                 it.killindicator.scale = 0.5;
 989                                 setattachment(it.killindicator, it, "");
 990                                 setorigin(it.killindicator, '0 0 52');
 991                                 setthink(it.killindicator, KillIndicator_Think);
 992                                 it.killindicator.nextthink = starttime + (it.lip) * 0.05;
 993                                 //clientkilltime = max(clientkilltime, it.killindicator.nextthink + 0.05);
 994                                 it.killindicator.cnt = ceil(killtime);
 995                         });
 996                         this.lip = 0;
 997                 }
 998         }
 999         if(this.killindicator)
1000         {
1001                 if(targetteam == 0) // just die
1002                 {
1003                         this.killindicator.colormod = '0 0 0';
1004                         if(IS_REAL_CLIENT(this))
1005                         if(this.killindicator.cnt > 0)
1006                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_TEAMCHANGE_SUICIDE, this.killindicator.cnt);
1007                 }
1008                 else if(targetteam == -1) // auto
1009                 {
1010                         this.killindicator.colormod = '0 1 0';
1011                         if(IS_REAL_CLIENT(this))
1012                         if(this.killindicator.cnt > 0)
1013                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_TEAMCHANGE_AUTO, this.killindicator.cnt);
1014                 }
1015                 else if(targetteam == -2) // spectate
1016                 {
1017                         this.killindicator.colormod = '0.5 0.5 0.5';
1018                         if(IS_REAL_CLIENT(this))
1019                         if(this.killindicator.cnt > 0)
1020                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_TEAMCHANGE_SPECTATE, this.killindicator.cnt);
1021                 }
1022                 else
1023                 {
1024                         this.killindicator.colormod = Team_ColorRGB(targetteam);
1025                         if(IS_REAL_CLIENT(this))
1026                         if(this.killindicator.cnt > 0)
1027                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, APP_TEAM_NUM(targetteam, CENTER_TEAMCHANGE), this.killindicator.cnt);
1028                 }
1029         }
1030
1031 }
1032
1033 void ClientKill (entity this)
1034 {
1035         if(game_stopped) return;
1036         if(this.player_blocked) return;
1037         if(STAT(FROZEN, this)) return;
1038
1039         ClientKill_TeamChange(this, 0);
1040 }
1041
1042 void FixClientCvars(entity e)
1043 {
1044         // send prediction settings to the client
1045         stuffcmd(e, "\nin_bindmap 0 0\n");
1046         if(autocvar_g_antilag == 3) // client side hitscan
1047                 stuffcmd(e, "cl_cmd settemp cl_prydoncursor_notrace 0\n");
1048         if(autocvar_sv_gentle)
1049                 stuffcmd(e, "cl_cmd settemp cl_gentle 1\n");
1050
1051         stuffcmd(e, sprintf("\ncl_jumpspeedcap_min \"%s\"\n", autocvar_sv_jumpspeedcap_min));
1052         stuffcmd(e, sprintf("\ncl_jumpspeedcap_max \"%s\"\n", autocvar_sv_jumpspeedcap_max));
1053
1054         MUTATOR_CALLHOOK(FixClientCvars, e);
1055 }
1056
1057 bool findinlist_abbrev(string tofind, string list)
1058 {
1059         if(list == "" || tofind == "")
1060                 return false; // empty list or search, just return
1061
1062         // this function allows abbreviated strings!
1063         FOREACH_WORD(list, it == substring(tofind, 0, strlen(it)),
1064         {
1065                 return true;
1066         });
1067
1068         return false;
1069 }
1070
1071 bool PlayerInIPList(entity p, string iplist)
1072 {
1073         // some safety checks (never allow local?)
1074         if(p.netaddress == "local" || p.netaddress == "" || !IS_REAL_CLIENT(p))
1075                 return false;
1076
1077         return findinlist_abbrev(p.netaddress, iplist);
1078 }
1079
1080 bool PlayerInIDList(entity p, string idlist)
1081 {
1082         // NOTE: we do NOT check crypto_idfp_signed here, an unsigned ID is fine too for this
1083         if(!p.crypto_idfp)
1084                 return false;
1085
1086         return findinlist_abbrev(p.crypto_idfp, idlist);
1087 }
1088
1089 bool PlayerInList(entity player, string list)
1090 {
1091         return boolean(PlayerInIDList(player, list) || PlayerInIPList(player, list));
1092 }
1093
1094 #ifdef DP_EXT_PRECONNECT
1095 /*
1096 =============
1097 ClientPreConnect
1098
1099 Called once (not at each match start) when a client begins a connection to the server
1100 =============
1101 */
1102 void ClientPreConnect(entity this)
1103 {
1104         if(autocvar_sv_eventlog)
1105         {
1106                 GameLogEcho(sprintf(":connect:%d:%d:%s",
1107                         this.playerid,
1108                         etof(this),
1109                         ((IS_REAL_CLIENT(this)) ? this.netaddress : "bot")
1110                 ));
1111         }
1112 }
1113 #endif
1114
1115 /**
1116 =============
1117 ClientConnect
1118
1119 Called when a client connects to the server
1120 =============
1121 */
1122 void ClientConnect(entity this)
1123 {
1124         if (Ban_MaybeEnforceBanOnce(this)) return;
1125         assert(!IS_CLIENT(this), return);
1126         this.flags |= FL_CLIENT;
1127         assert(player_count >= 0, player_count = 0);
1128
1129 #ifdef WATERMARK
1130         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_WATERMARK, WATERMARK);
1131 #endif
1132         TRANSMUTE(Client, this);
1133         CS(this).version_nagtime = time + 10 + random() * 10;
1134
1135         // identify the right forced team
1136         if (autocvar_g_campaign)
1137         {
1138                 if (IS_REAL_CLIENT(this)) // only players, not bots
1139                 {
1140                         switch (autocvar_g_campaign_forceteam)
1141                         {
1142                                 case 1: this.team_forced = NUM_TEAM_1; break;
1143                                 case 2: this.team_forced = NUM_TEAM_2; break;
1144                                 case 3: this.team_forced = NUM_TEAM_3; break;
1145                                 case 4: this.team_forced = NUM_TEAM_4; break;
1146                                 default: this.team_forced = 0;
1147                         }
1148                 }
1149         }
1150         else if (PlayerInList(this, autocvar_g_forced_team_red))    this.team_forced = NUM_TEAM_1;
1151         else if (PlayerInList(this, autocvar_g_forced_team_blue))   this.team_forced = NUM_TEAM_2;
1152         else if (PlayerInList(this, autocvar_g_forced_team_yellow)) this.team_forced = NUM_TEAM_3;
1153         else if (PlayerInList(this, autocvar_g_forced_team_pink))   this.team_forced = NUM_TEAM_4;
1154         else switch (autocvar_g_forced_team_otherwise)
1155         {
1156                 default: this.team_forced = 0; break;
1157                 case "red": this.team_forced = NUM_TEAM_1; break;
1158                 case "blue": this.team_forced = NUM_TEAM_2; break;
1159                 case "yellow": this.team_forced = NUM_TEAM_3; break;
1160                 case "pink": this.team_forced = NUM_TEAM_4; break;
1161                 case "spectate":
1162                 case "spectator":
1163                         this.team_forced = -1;
1164                         break;
1165         }
1166         if (!teamplay && this.team_forced > 0) this.team_forced = 0;
1167
1168     {
1169         int id = this.playerid;
1170         this.playerid = 0; // silent
1171             JoinBestTeam(this, false, false); // if the team number is valid, keep it
1172             this.playerid = id;
1173     }
1174
1175         if (autocvar_sv_spectate || autocvar_g_campaign || this.team_forced < 0) {
1176                 TRANSMUTE(Observer, this);
1177         } else {
1178                 if (!teamplay || autocvar_g_balance_teams) {
1179                         TRANSMUTE(Player, this);
1180                         campaign_bots_may_start = true;
1181                 } else {
1182                         TRANSMUTE(Observer, this); // do it anyway
1183                 }
1184         }
1185
1186         PlayerStats_GameReport_AddEvent(sprintf("kills-%d", this.playerid));
1187
1188         // always track bots, don't ask for cl_allow_uidtracking
1189     if (IS_BOT_CLIENT(this)) PlayerStats_GameReport_AddPlayer(this);
1190
1191         if (autocvar_sv_eventlog)
1192                 GameLogEcho(strcat(":join:", ftos(this.playerid), ":", ftos(etof(this)), ":", ((IS_REAL_CLIENT(this)) ? this.netaddress : "bot"), ":", playername(this, false)));
1193
1194         LogTeamchange(this.playerid, this.team, 1);
1195
1196         CS(this).just_joined = true;  // stop spamming the eventlog with additional lines when the client connects
1197
1198         CS(this).netname_previous = strzone(this.netname);
1199
1200         if(teamplay && IS_PLAYER(this))
1201                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, APP_TEAM_NUM(this.team, INFO_JOIN_CONNECT_TEAM), this.netname);
1202         else
1203                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_JOIN_CONNECT, this.netname);
1204
1205         stuffcmd(this, clientstuff, "\n");
1206         stuffcmd(this, "cl_particles_reloadeffects\n"); // TODO do we still need this?
1207
1208         FixClientCvars(this);
1209
1210         // get version info from player
1211         stuffcmd(this, "cmd clientversion $gameversion\n");
1212
1213         // notify about available teams
1214         if (teamplay)
1215         {
1216                 CheckAllowedTeams(this);
1217                 int t = 0;
1218                 if (c1 >= 0) t |= BIT(0);
1219                 if (c2 >= 0) t |= BIT(1);
1220                 if (c3 >= 0) t |= BIT(2);
1221                 if (c4 >= 0) t |= BIT(3);
1222                 stuffcmd(this, sprintf("set _teams_available %d\n", t));
1223         }
1224         else
1225         {
1226                 stuffcmd(this, "set _teams_available 0\n");
1227         }
1228
1229         bot_relinkplayerlist();
1230
1231         CS(this).spectatortime = time;
1232         if (blockSpectators)
1233         {
1234                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
1235         }
1236
1237         CS(this).jointime = time;
1238         CS(this).allowed_timeouts = autocvar_sv_timeout_number;
1239
1240         if (IS_REAL_CLIENT(this))
1241         {
1242                 if (g_weaponarena_weapons == WEPSET(TUBA))
1243                         stuffcmd(this, "cl_cmd settemp chase_active 1\n");
1244         }
1245
1246         if (!sv_foginterval && world.fog != "")
1247                 stuffcmd(this, strcat("\nfog ", world.fog, "\nr_fog_exp2 0\nr_drawfog 1\n"));
1248
1249         if (autocvar_sv_teamnagger && !(autocvar_bot_vs_human && AvailableTeams() == 2))
1250                 if(!MUTATOR_CALLHOOK(HideTeamNagger, this))
1251                         send_CSQC_teamnagger();
1252
1253         CSQCMODEL_AUTOINIT(this);
1254
1255         CS(this).model_randomizer = random();
1256
1257         if (IS_REAL_CLIENT(this))
1258                 sv_notice_join(this);
1259
1260         // update physics stats (players can spawn before physics runs)
1261         Physics_UpdateStats(this);
1262
1263         IL_EACH(g_initforplayer, it.init_for_player, {
1264                 it.init_for_player(it, this);
1265         });
1266
1267         MUTATOR_CALLHOOK(ClientConnect, this);
1268
1269         if (IS_REAL_CLIENT(this))
1270         {
1271                 if (!autocvar_g_campaign && !IS_PLAYER(this))
1272                 {
1273                         CS(this).motd_actived_time = -1;
1274                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOTD, getwelcomemessage(this));
1275                 }
1276         }
1277 }
1278 /*
1279 =============
1280 ClientDisconnect
1281
1282 Called when a client disconnects from the server
1283 =============
1284 */
1285 .entity chatbubbleentity;
1286 void ReadyCount();
1287 void ClientDisconnect(entity this)
1288 {
1289         assert(IS_CLIENT(this), return);
1290
1291         PlayerStats_GameReport_FinalizePlayer(this);
1292         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
1293         if (CS(this).active_minigame) part_minigame(this);
1294         if (IS_PLAYER(this)) Send_Effect(EFFECT_SPAWN_NEUTRAL, this.origin, '0 0 0', 1);
1295
1296         if (autocvar_sv_eventlog)
1297                 GameLogEcho(strcat(":part:", ftos(this.playerid)));
1298
1299         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_QUIT_DISCONNECT, this.netname);
1300
1301         if(IS_SPEC(this))
1302                 SetSpectatee(this, NULL);
1303
1304     MUTATOR_CALLHOOK(ClientDisconnect, this);
1305
1306         if (CS(this).netname_previous) strunzone(CS(this).netname_previous); // needs to be before the CS entity is removed!
1307         ClientState_detach(this);
1308
1309         Portal_ClearAll(this);
1310
1311         Unfreeze(this);
1312
1313         RemoveGrapplingHooks(this);
1314
1315         // Here, everything has been done that requires this player to be a client.
1316
1317         this.flags &= ~FL_CLIENT;
1318
1319         if (this.chatbubbleentity) delete(this.chatbubbleentity);
1320         if (this.killindicator) delete(this.killindicator);
1321
1322         WaypointSprite_PlayerGone(this);
1323
1324         bot_relinkplayerlist();
1325
1326         if (this.clientstatus) strunzone(this.clientstatus);
1327         if (this.weaponorder_byimpulse) strunzone(this.weaponorder_byimpulse);
1328         if (this.personal) delete(this.personal);
1329
1330         this.playerid = 0;
1331         ReadyCount();
1332         if (vote_called && IS_REAL_CLIENT(this)) VoteCount(false);
1333
1334         ONREMOVE(this);
1335 }
1336
1337 void ChatBubbleThink(entity this)
1338 {
1339         this.nextthink = time;
1340         if ((this.owner.alpha < 0) || this.owner.chatbubbleentity != this)
1341         {
1342                 if(this.owner) // but why can that ever be NULL?
1343                         this.owner.chatbubbleentity = NULL;
1344                 delete(this);
1345                 return;
1346         }
1347
1348         this.mdl = "";
1349
1350         if ( !IS_DEAD(this.owner) && IS_PLAYER(this.owner) )
1351         {
1352                 if ( CS(this.owner).active_minigame )
1353                         this.mdl = "models/sprites/minigame_busy.iqm";
1354                 else if (PHYS_INPUT_BUTTON_CHAT(this.owner))
1355                         this.mdl = "models/misc/chatbubble.spr";
1356         }
1357
1358         if ( this.model != this.mdl )
1359                 _setmodel(this, this.mdl);
1360
1361 }
1362
1363 void UpdateChatBubble(entity this)
1364 {
1365         if (this.alpha < 0)
1366                 return;
1367         // spawn a chatbubble entity if needed
1368         if (!this.chatbubbleentity)
1369         {
1370                 this.chatbubbleentity = new(chatbubbleentity);
1371                 this.chatbubbleentity.owner = this;
1372                 this.chatbubbleentity.exteriormodeltoclient = this;
1373                 setthink(this.chatbubbleentity, ChatBubbleThink);
1374                 this.chatbubbleentity.nextthink = time;
1375                 setmodel(this.chatbubbleentity, MDL_CHAT); // precision set below
1376                 //setorigin(this.chatbubbleentity, this.origin + '0 0 15' + this.maxs_z * '0 0 1');
1377                 setorigin(this.chatbubbleentity, '0 0 15' + this.maxs_z * '0 0 1');
1378                 setattachment(this.chatbubbleentity, this, "");  // sticks to moving player better, also conserves bandwidth
1379                 this.chatbubbleentity.mdl = this.chatbubbleentity.model;
1380                 //this.chatbubbleentity.model = "";
1381                 this.chatbubbleentity.effects = EF_LOWPRECISION;
1382         }
1383 }
1384
1385
1386 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
1387 // added to the model skins
1388 /*void UpdateColorModHack()
1389 {
1390         float c;
1391         c = this.clientcolors & 15;
1392         // LordHavoc: only bothering to support white, green, red, yellow, blue
1393              if (!teamplay) this.colormod = '0 0 0';
1394         else if (c ==  0) this.colormod = '1.00 1.00 1.00';
1395         else if (c ==  3) this.colormod = '0.10 1.73 0.10';
1396         else if (c ==  4) this.colormod = '1.73 0.10 0.10';
1397         else if (c == 12) this.colormod = '1.22 1.22 0.10';
1398         else if (c == 13) this.colormod = '0.10 0.10 1.73';
1399         else this.colormod = '1 1 1';
1400 }*/
1401
1402 void respawn(entity this)
1403 {
1404         if(this.alpha >= 0 && autocvar_g_respawn_ghosts)
1405         {
1406                 this.solid = SOLID_NOT;
1407                 this.takedamage = DAMAGE_NO;
1408                 set_movetype(this, MOVETYPE_FLY);
1409                 this.velocity = '0 0 1' * autocvar_g_respawn_ghosts_speed;
1410                 this.avelocity = randomvec() * autocvar_g_respawn_ghosts_speed * 3 - randomvec() * autocvar_g_respawn_ghosts_speed * 3;
1411                 this.effects |= CSQCMODEL_EF_RESPAWNGHOST;
1412                 Send_Effect(EFFECT_RESPAWN_GHOST, this.origin, '0 0 0', 1);
1413                 if(autocvar_g_respawn_ghosts_maxtime)
1414                         SUB_SetFade (this, time + autocvar_g_respawn_ghosts_maxtime / 2 + random () * (autocvar_g_respawn_ghosts_maxtime - autocvar_g_respawn_ghosts_maxtime / 2), 1.5);
1415         }
1416
1417         CopyBody(this, 1);
1418
1419         this.effects |= EF_NODRAW; // prevent another CopyBody
1420         PutClientInServer(this);
1421 }
1422
1423 void play_countdown(entity this, float finished, Sound samp)
1424 {
1425     TC(Sound, samp);
1426         if(IS_REAL_CLIENT(this))
1427                 if(floor(finished - time - frametime) != floor(finished - time))
1428                         if(finished - time < 6)
1429                                 sound (this, CH_INFO, samp, VOL_BASE, ATTEN_NORM);
1430 }
1431
1432 void player_powerups(entity this)
1433 {
1434         // add a way to see what the items were BEFORE all of these checks for the mutator hook
1435         int items_prev = this.items;
1436
1437         if((this.items & IT_USING_JETPACK) && !IS_DEAD(this) && !game_stopped)
1438                 this.modelflags |= MF_ROCKET;
1439         else
1440                 this.modelflags &= ~MF_ROCKET;
1441
1442         this.effects &= ~(EF_RED | EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT | EF_FLAME | EF_NODEPTHTEST);
1443
1444         if((this.alpha < 0 || IS_DEAD(this)) && !this.vehicle) // don't apply the flags if the player is gibbed
1445                 return;
1446
1447         Fire_ApplyDamage(this);
1448         Fire_ApplyEffect(this);
1449
1450         if (!g_instagib)
1451         {
1452                 if (this.items & ITEM_Strength.m_itemid)
1453                 {
1454                         play_countdown(this, this.strength_finished, SND_POWEROFF);
1455                         this.effects = this.effects | (EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT);
1456                         if (time > this.strength_finished)
1457                         {
1458                                 this.items = this.items - (this.items & ITEM_Strength.m_itemid);
1459                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERDOWN_STRENGTH, this.netname);
1460                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERDOWN_STRENGTH);
1461                         }
1462                 }
1463                 else
1464                 {
1465                         if (time < this.strength_finished)
1466                         {
1467                                 this.items = this.items | ITEM_Strength.m_itemid;
1468                                 if(!g_cts)
1469                                         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERUP_STRENGTH, this.netname);
1470                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERUP_STRENGTH);
1471                         }
1472                 }
1473                 if (this.items & ITEM_Shield.m_itemid)
1474                 {
1475                         play_countdown(this, this.invincible_finished, SND_POWEROFF);
1476                         this.effects = this.effects | (EF_RED | EF_ADDITIVE | EF_FULLBRIGHT);
1477                         if (time > this.invincible_finished)
1478                         {
1479                                 this.items = this.items - (this.items & ITEM_Shield.m_itemid);
1480                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERDOWN_SHIELD, this.netname);
1481                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERDOWN_SHIELD);
1482                         }
1483                 }
1484                 else
1485                 {
1486                         if (time < this.invincible_finished)
1487                         {
1488                                 this.items = this.items | ITEM_Shield.m_itemid;
1489                                 if(!g_cts)
1490                                         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERUP_SHIELD, this.netname);
1491                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERUP_SHIELD);
1492                         }
1493                 }
1494                 if (this.items & IT_SUPERWEAPON)
1495                 {
1496                         if (!(this.weapons & WEPSET_SUPERWEAPONS))
1497                         {
1498                                 this.superweapons_finished = 0;
1499                                 this.items = this.items - (this.items & IT_SUPERWEAPON);
1500                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_LOST, this.netname);
1501                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_LOST);
1502                         }
1503                         else if (this.items & IT_UNLIMITED_SUPERWEAPONS)
1504                         {
1505                                 // don't let them run out
1506                         }
1507                         else
1508                         {
1509                                 play_countdown(this, this.superweapons_finished, SND_POWEROFF);
1510                                 if (time > this.superweapons_finished)
1511                                 {
1512                                         this.items = this.items - (this.items & IT_SUPERWEAPON);
1513                                         this.weapons &= ~WEPSET_SUPERWEAPONS;
1514                                         //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_BROKEN, this.netname);
1515                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_BROKEN);
1516                                 }
1517                         }
1518                 }
1519                 else if(this.weapons & WEPSET_SUPERWEAPONS)
1520                 {
1521                         if (time < this.superweapons_finished || (this.items & IT_UNLIMITED_SUPERWEAPONS))
1522                         {
1523                                 this.items = this.items | IT_SUPERWEAPON;
1524                                 if(!g_cts)
1525                                         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_PICKUP, this.netname);
1526                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_PICKUP);
1527                         }
1528                         else
1529                         {
1530                                 this.superweapons_finished = 0;
1531                                 this.weapons &= ~WEPSET_SUPERWEAPONS;
1532                         }
1533                 }
1534                 else
1535                 {
1536                         this.superweapons_finished = 0;
1537                 }
1538         }
1539
1540         if(autocvar_g_nodepthtestplayers)
1541                 this.effects = this.effects | EF_NODEPTHTEST;
1542
1543         if(autocvar_g_fullbrightplayers)
1544                 this.effects = this.effects | EF_FULLBRIGHT;
1545
1546         if (time >= game_starttime)
1547         if (time < this.spawnshieldtime)
1548                 this.effects = this.effects | (EF_ADDITIVE | EF_FULLBRIGHT);
1549
1550         MUTATOR_CALLHOOK(PlayerPowerups, this, items_prev);
1551 }
1552
1553 float CalcRegen(float current, float stable, float regenfactor, float regenframetime)
1554 {
1555         if(current > stable)
1556                 return current;
1557         else if(current > stable - 0.25) // when close enough, "snap"
1558                 return stable;
1559         else
1560                 return min(stable, current + (stable - current) * regenfactor * regenframetime);
1561 }
1562
1563 float CalcRot(float current, float stable, float rotfactor, float rotframetime)
1564 {
1565         if(current < stable)
1566                 return current;
1567         else if(current < stable + 0.25) // when close enough, "snap"
1568                 return stable;
1569         else
1570                 return max(stable, current + (stable - current) * rotfactor * rotframetime);
1571 }
1572
1573 float CalcRotRegen(float current, float regenstable, float regenfactor, float regenlinear, float regenframetime, float rotstable, float rotfactor, float rotlinear, float rotframetime, float limit)
1574 {
1575         if(current > rotstable)
1576         {
1577                 if(rotframetime > 0)
1578                 {
1579                         current = CalcRot(current, rotstable, rotfactor, rotframetime);
1580                         current = max(rotstable, current - rotlinear * rotframetime);
1581                 }
1582         }
1583         else if(current < regenstable)
1584         {
1585                 if(regenframetime > 0)
1586                 {
1587                         current = CalcRegen(current, regenstable, regenfactor, regenframetime);
1588                         current = min(regenstable, current + regenlinear * regenframetime);
1589                 }
1590         }
1591
1592         if(current > limit)
1593                 current = limit;
1594
1595         return current;
1596 }
1597
1598 void player_regen(entity this)
1599 {
1600         float max_mod, regen_mod, rot_mod, limit_mod;
1601         max_mod = regen_mod = rot_mod = limit_mod = 1;
1602
1603         float regen_health = autocvar_g_balance_health_regen;
1604         float regen_health_linear = autocvar_g_balance_health_regenlinear;
1605         float regen_health_rot = autocvar_g_balance_health_rot;
1606         float regen_health_rotlinear = autocvar_g_balance_health_rotlinear;
1607         float regen_health_stable = autocvar_g_balance_health_regenstable;
1608         float regen_health_rotstable = autocvar_g_balance_health_rotstable;
1609         bool mutator_returnvalue = MUTATOR_CALLHOOK(PlayerRegen, this, max_mod, regen_mod, rot_mod, limit_mod, regen_health, regen_health_linear, regen_health_rot,
1610                 regen_health_rotlinear, regen_health_stable, regen_health_rotstable);
1611         max_mod = M_ARGV(1, float);
1612         regen_mod = M_ARGV(2, float);
1613         rot_mod = M_ARGV(3, float);
1614         limit_mod = M_ARGV(4, float);
1615         regen_health = M_ARGV(5, float);
1616         regen_health_linear = M_ARGV(6, float);
1617         regen_health_rot = M_ARGV(7, float);
1618         regen_health_rotlinear = M_ARGV(8, float);
1619         regen_health_stable = M_ARGV(9, float);
1620         regen_health_rotstable = M_ARGV(10, float);
1621
1622
1623         if(!mutator_returnvalue)
1624         if(!STAT(FROZEN, this))
1625         {
1626                 float mina, maxa, limith, limita;
1627                 maxa = autocvar_g_balance_armor_rotstable;
1628                 mina = autocvar_g_balance_armor_regenstable;
1629                 limith = autocvar_g_balance_health_limit;
1630                 limita = autocvar_g_balance_armor_limit;
1631
1632                 regen_health_rotstable = regen_health_rotstable * max_mod;
1633                 regen_health_stable = regen_health_stable * max_mod;
1634                 limith = limith * limit_mod;
1635                 limita = limita * limit_mod;
1636
1637                 this.armorvalue = CalcRotRegen(this.armorvalue, mina, autocvar_g_balance_armor_regen, autocvar_g_balance_armor_regenlinear, regen_mod * frametime * (time > this.pauseregen_finished), maxa, autocvar_g_balance_armor_rot, autocvar_g_balance_armor_rotlinear, rot_mod * frametime * (time > this.pauserotarmor_finished), limita);
1638                 this.health = CalcRotRegen(this.health, regen_health_stable, regen_health, regen_health_linear, regen_mod * frametime * (time > this.pauseregen_finished), regen_health_rotstable, regen_health_rot, regen_health_rotlinear, rot_mod * frametime * (time > this.pauserothealth_finished), limith);
1639         }
1640
1641         // if player rotted to death...  die!
1642         // check this outside above checks, as player may still be able to rot to death
1643         if(this.health < 1)
1644         {
1645                 if(this.vehicle)
1646                         vehicles_exit(this.vehicle, VHEF_RELEASE);
1647                 if(this.event_damage)
1648                         this.event_damage(this, this, this, 1, DEATH_ROT.m_id, this.origin, '0 0 0');
1649         }
1650
1651         if (!(this.items & IT_UNLIMITED_WEAPON_AMMO))
1652         {
1653                 float minf, maxf, limitf;
1654
1655                 maxf = autocvar_g_balance_fuel_rotstable;
1656                 minf = autocvar_g_balance_fuel_regenstable;
1657                 limitf = autocvar_g_balance_fuel_limit;
1658
1659                 this.ammo_fuel = CalcRotRegen(this.ammo_fuel, minf, autocvar_g_balance_fuel_regen, autocvar_g_balance_fuel_regenlinear, frametime * (time > this.pauseregen_finished) * ((this.items & ITEM_JetpackRegen.m_itemid) != 0), maxf, autocvar_g_balance_fuel_rot, autocvar_g_balance_fuel_rotlinear, frametime * (time > this.pauserotfuel_finished), limitf);
1660         }
1661 }
1662
1663 bool zoomstate_set;
1664 void SetZoomState(entity this, float newzoom)
1665 {
1666         if(newzoom != CS(this).zoomstate)
1667         {
1668                 CS(this).zoomstate = newzoom;
1669                 ClientData_Touch(this);
1670         }
1671         zoomstate_set = true;
1672 }
1673
1674 void GetPressedKeys(entity this)
1675 {
1676         MUTATOR_CALLHOOK(GetPressedKeys, this);
1677         int keys = STAT(PRESSED_KEYS, this);
1678         keys = BITSET(keys, KEY_FORWARD,        CS(this).movement.x > 0);
1679         keys = BITSET(keys, KEY_BACKWARD,       CS(this).movement.x < 0);
1680         keys = BITSET(keys, KEY_RIGHT,          CS(this).movement.y > 0);
1681         keys = BITSET(keys, KEY_LEFT,           CS(this).movement.y < 0);
1682
1683         keys = BITSET(keys, KEY_JUMP,           PHYS_INPUT_BUTTON_JUMP(this));
1684         keys = BITSET(keys, KEY_CROUCH,         PHYS_INPUT_BUTTON_CROUCH(this));
1685         keys = BITSET(keys, KEY_ATCK,           PHYS_INPUT_BUTTON_ATCK(this));
1686         keys = BITSET(keys, KEY_ATCK2,          PHYS_INPUT_BUTTON_ATCK2(this));
1687         CS(this).pressedkeys = keys; // store for other users
1688
1689         STAT(PRESSED_KEYS, this) = keys;
1690 }
1691
1692 /*
1693 ======================
1694 spectate mode routines
1695 ======================
1696 */
1697
1698 void SpectateCopy(entity this, entity spectatee)
1699 {
1700     TC(Client, this); TC(Client, spectatee);
1701
1702         MUTATOR_CALLHOOK(SpectateCopy, spectatee, this);
1703         PS(this) = PS(spectatee);
1704         this.armortype = spectatee.armortype;
1705         this.armorvalue = spectatee.armorvalue;
1706         this.ammo_cells = spectatee.ammo_cells;
1707         this.ammo_plasma = spectatee.ammo_plasma;
1708         this.ammo_shells = spectatee.ammo_shells;
1709         this.ammo_nails = spectatee.ammo_nails;
1710         this.ammo_rockets = spectatee.ammo_rockets;
1711         this.ammo_fuel = spectatee.ammo_fuel;
1712         this.clip_load = spectatee.clip_load;
1713         this.clip_size = spectatee.clip_size;
1714         this.effects = spectatee.effects & EFMASK_CHEAP; // eat performance
1715         this.health = spectatee.health;
1716         CS(this).impulse = 0;
1717         this.items = spectatee.items;
1718         this.last_pickup = spectatee.last_pickup;
1719         this.hit_time = spectatee.hit_time;
1720         this.strength_finished = spectatee.strength_finished;
1721         this.invincible_finished = spectatee.invincible_finished;
1722         this.superweapons_finished = spectatee.superweapons_finished;
1723         STAT(PRESSED_KEYS, this) = STAT(PRESSED_KEYS, spectatee);
1724         this.weapons = spectatee.weapons;
1725         this.vortex_charge = spectatee.vortex_charge;
1726         this.vortex_chargepool_ammo = spectatee.vortex_chargepool_ammo;
1727         this.hagar_load = spectatee.hagar_load;
1728         this.arc_heat_percent = spectatee.arc_heat_percent;
1729         this.minelayer_mines = spectatee.minelayer_mines;
1730         this.punchangle = spectatee.punchangle;
1731         this.view_ofs = spectatee.view_ofs;
1732         this.velocity = spectatee.velocity;
1733         this.dmg_take = spectatee.dmg_take;
1734         this.dmg_save = spectatee.dmg_save;
1735         this.dmg_inflictor = spectatee.dmg_inflictor;
1736         this.v_angle = spectatee.v_angle;
1737         this.angles = spectatee.v_angle;
1738         STAT(FROZEN, this) = STAT(FROZEN, spectatee);
1739         this.revive_progress = spectatee.revive_progress;
1740         this.viewloc = spectatee.viewloc;
1741         if(!PHYS_INPUT_BUTTON_USE(this) && STAT(CAMERA_SPECTATOR, this) != 2)
1742                 this.fixangle = true;
1743         setorigin(this, spectatee.origin);
1744         setsize(this, spectatee.mins, spectatee.maxs);
1745         SetZoomState(this, CS(spectatee).zoomstate);
1746
1747         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1748         {
1749                 .entity weaponentity = weaponentities[slot];
1750                 this.(weaponentity) = spectatee.(weaponentity);
1751         }
1752
1753         for(int slot = 0; slot < MAX_AXH; ++slot)
1754         {
1755                 this.(AuxiliaryXhair[slot]) = spectatee.(AuxiliaryXhair[slot]);
1756         }
1757
1758     anticheat_spectatecopy(this, spectatee);
1759         this.hud = spectatee.hud;
1760         if(spectatee.vehicle)
1761     {
1762         this.angles = spectatee.v_angle;
1763
1764         //this.fixangle = false;
1765         //this.velocity = spectatee.vehicle.velocity;
1766         this.vehicle_health = spectatee.vehicle_health;
1767         this.vehicle_shield = spectatee.vehicle_shield;
1768         this.vehicle_energy = spectatee.vehicle_energy;
1769         this.vehicle_ammo1 = spectatee.vehicle_ammo1;
1770         this.vehicle_ammo2 = spectatee.vehicle_ammo2;
1771         this.vehicle_reload1 = spectatee.vehicle_reload1;
1772         this.vehicle_reload2 = spectatee.vehicle_reload2;
1773
1774         //msg_entity = this;
1775
1776        // WriteByte (MSG_ONE, SVC_SETVIEWANGLES);
1777             //WriteAngle(MSG_ONE,  spectatee.v_angle.x);
1778            // WriteAngle(MSG_ONE,  spectatee.v_angle.y);
1779            // WriteAngle(MSG_ONE,  spectatee.v_angle.z);
1780
1781         //WriteByte (MSG_ONE, SVC_SETVIEW);
1782         //    WriteEntity(MSG_ONE, this);
1783         //makevectors(spectatee.v_angle);
1784         //setorigin(this, spectatee.origin - v_forward * 400 + v_up * 300);*/
1785     }
1786 }
1787
1788 bool SpectateUpdate(entity this)
1789 {
1790         if(!this.enemy)
1791                 return false;
1792
1793         if(!IS_PLAYER(this.enemy) || this == this.enemy)
1794         {
1795                 SetSpectatee(this, NULL);
1796                 return false;
1797         }
1798
1799         SpectateCopy(this, this.enemy);
1800
1801         return true;
1802 }
1803
1804 bool SpectateSet(entity this)
1805 {
1806         if(!IS_PLAYER(this.enemy))
1807                 return false;
1808
1809         ClientData_Touch(this.enemy);
1810
1811         msg_entity = this;
1812         WriteByte(MSG_ONE, SVC_SETVIEW);
1813         WriteEntity(MSG_ONE, this.enemy);
1814         set_movetype(this, MOVETYPE_NONE);
1815         accuracy_resend(this);
1816
1817         if(!SpectateUpdate(this))
1818                 PutObserverInServer(this);
1819
1820         return true;
1821 }
1822
1823 void SetSpectatee_status(entity this, int spectatee_num)
1824 {
1825         int oldspectatee_status = CS(this).spectatee_status;
1826         CS(this).spectatee_status = spectatee_num;
1827
1828         if (CS(this).spectatee_status != oldspectatee_status)
1829         {
1830                 ClientData_Touch(this);
1831                 if (g_race || g_cts) race_InitSpectator();
1832         }
1833 }
1834
1835 void SetSpectatee(entity this, entity spectatee)
1836 {
1837         if(IS_BOT_CLIENT(this))
1838                 return; // bots abuse .enemy, this code is useless to them
1839
1840         entity old_spectatee = this.enemy;
1841
1842         this.enemy = spectatee;
1843
1844         // WEAPONTODO
1845         // these are required to fix the spectator bug with arc
1846         if(old_spectatee)
1847         {
1848                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1849                 {
1850                         .entity weaponentity = weaponentities[slot];
1851                         if(old_spectatee.(weaponentity).arc_beam)
1852                                 old_spectatee.(weaponentity).arc_beam.SendFlags |= ARC_SF_SETTINGS;
1853                 }
1854         }
1855         if(this.enemy)
1856         {
1857                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1858                 {
1859                         .entity weaponentity = weaponentities[slot];
1860                         if(this.enemy.(weaponentity).arc_beam)
1861                                 this.enemy.(weaponentity).arc_beam.SendFlags |= ARC_SF_SETTINGS;
1862                 }
1863         }
1864
1865         if (this.enemy)
1866                 SetSpectatee_status(this, etof(this.enemy));
1867
1868         // needed to update spectator list
1869         if(old_spectatee) { ClientData_Touch(old_spectatee); }
1870 }
1871
1872 bool Spectate(entity this, entity pl)
1873 {
1874         if(MUTATOR_CALLHOOK(SpectateSet, this, pl))
1875                 return false;
1876         pl = M_ARGV(1, entity);
1877
1878         SetSpectatee(this, pl);
1879         return SpectateSet(this);
1880 }
1881
1882 bool SpectateNext(entity this)
1883 {
1884         entity ent = find(this.enemy, classname, STR_PLAYER);
1885
1886         if (MUTATOR_CALLHOOK(SpectateNext, this, ent))
1887                 ent = M_ARGV(1, entity);
1888         else if (!ent)
1889                 ent = find(ent, classname, STR_PLAYER);
1890
1891         if(ent) { SetSpectatee(this, ent); }
1892
1893         return SpectateSet(this);
1894 }
1895
1896 bool SpectatePrev(entity this)
1897 {
1898         // NOTE: chain order is from the highest to the lower entnum (unlike find)
1899         entity ent = findchain(classname, STR_PLAYER);
1900         if (!ent) // no player
1901                 return false;
1902
1903         entity first = ent;
1904         // skip players until current spectated player
1905         if(this.enemy)
1906         while(ent && ent != this.enemy)
1907                 ent = ent.chain;
1908
1909         switch (MUTATOR_CALLHOOK(SpectatePrev, this, ent, first))
1910         {
1911                 case MUT_SPECPREV_FOUND:
1912                     ent = M_ARGV(1, entity);
1913                     break;
1914                 case MUT_SPECPREV_RETURN:
1915                     return true;
1916                 case MUT_SPECPREV_CONTINUE:
1917                 default:
1918                 {
1919                         if(ent.chain)
1920                                 ent = ent.chain;
1921                         else
1922                                 ent = first;
1923                         break;
1924                 }
1925         }
1926
1927         SetSpectatee(this, ent);
1928         return SpectateSet(this);
1929 }
1930
1931 /*
1932 =============
1933 ShowRespawnCountdown()
1934
1935 Update a respawn countdown display.
1936 =============
1937 */
1938 void ShowRespawnCountdown(entity this)
1939 {
1940         float number;
1941         if(!IS_DEAD(this)) // just respawned?
1942                 return;
1943         else
1944         {
1945                 number = ceil(this.respawn_time - time);
1946                 if(number <= 0)
1947                         return;
1948                 if(number <= this.respawn_countdown)
1949                 {
1950                         this.respawn_countdown = number - 1;
1951                         if(ceil(this.respawn_time - (time + 0.5)) == number) // only say it if it is the same number even in 0.5s; to prevent overlapping sounds
1952                                 { Send_Notification(NOTIF_ONE, this, MSG_ANNCE, Announcer_PickNumber(CNT_RESPAWN, number)); }
1953                 }
1954         }
1955 }
1956
1957 .bool team_selected;
1958 bool ShowTeamSelection(entity this)
1959 {
1960         if(!teamplay || autocvar_g_campaign || autocvar_g_balance_teams || this.team_selected || (CS(this).wasplayer && autocvar_g_changeteam_banned) || this.team_forced > 0)
1961                 return false;
1962         stuffcmd(this, "menu_showteamselect\n");
1963         return true;
1964 }
1965 void Join(entity this)
1966 {
1967         TRANSMUTE(Player, this);
1968
1969         if(!this.team_selected)
1970         if(autocvar_g_campaign || autocvar_g_balance_teams)
1971                 JoinBestTeam(this, false, true);
1972
1973         if(autocvar_g_campaign)
1974                 campaign_bots_may_start = true;
1975
1976         Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_PREVENT_JOIN);
1977
1978         PutClientInServer(this);
1979
1980         if(IS_PLAYER(this))
1981         if(teamplay && this.team != -1)
1982                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, APP_TEAM_NUM(this.team, INFO_JOIN_PLAY_TEAM), this.netname);
1983         else
1984                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_JOIN_PLAY, this.netname);
1985         this.team_selected = false;
1986 }
1987
1988 /**
1989  * Determines whether the player is allowed to join. This depends on cvar
1990  * g_maxplayers, if it isn't used this function always return true, otherwise
1991  * it checks whether the number of currently playing players exceeds g_maxplayers.
1992  * @return int number of free slots for players, 0 if none
1993  */
1994 int nJoinAllowed(entity this, entity ignore)
1995 {
1996         if(!ignore)
1997         // this is called that way when checking if anyone may be able to join (to build qcstatus)
1998         // so report 0 free slots if restricted
1999         {
2000                 if(autocvar_g_forced_team_otherwise == "spectate")
2001                         return 0;
2002                 if(autocvar_g_forced_team_otherwise == "spectator")
2003                         return 0;
2004         }
2005
2006         if(this && this.team_forced < 0)
2007                 return 0; // forced spectators can never join
2008
2009         // TODO simplify this
2010         int totalClients = 0;
2011         int currentlyPlaying = 0;
2012         FOREACH_CLIENT(true, LAMBDA(
2013                 if(it != ignore)
2014                         ++totalClients;
2015                 if(IS_REAL_CLIENT(it))
2016                 if(IS_PLAYER(it) || it.caplayer)
2017                         ++currentlyPlaying;
2018         ));
2019
2020         float free_slots = 0;
2021         if (!autocvar_g_maxplayers)
2022                 free_slots = maxclients - totalClients;
2023         else if(currentlyPlaying < autocvar_g_maxplayers)
2024                 free_slots = min(maxclients - totalClients, autocvar_g_maxplayers - currentlyPlaying);
2025
2026         static float join_prevent_msg_time = 0;
2027         if(this && ignore && !free_slots && time > join_prevent_msg_time)
2028         {
2029                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_JOIN_PREVENT);
2030                 join_prevent_msg_time = time + 3;
2031         }
2032
2033         return free_slots;
2034 }
2035
2036 /**
2037  * Checks whether the client is an observer or spectator, if so, he will get kicked after
2038  * g_maxplayers_spectator_blocktime seconds
2039  */
2040 void checkSpectatorBlock(entity this)
2041 {
2042         if(IS_SPEC(this) || IS_OBSERVER(this))
2043         if(!this.caplayer)
2044         if(IS_REAL_CLIENT(this))
2045         {
2046                 if( time > (CS(this).spectatortime + autocvar_g_maxplayers_spectator_blocktime) ) {
2047                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_QUIT_KICK_SPECTATING);
2048                         dropclient(this);
2049                 }
2050         }
2051 }
2052
2053 void PrintWelcomeMessage(entity this)
2054 {
2055         if(CS(this).motd_actived_time == 0)
2056         {
2057                 if (autocvar_g_campaign) {
2058                         if ((IS_PLAYER(this) && PHYS_INPUT_BUTTON_INFO(this)) || (!IS_PLAYER(this))) {
2059                                 CS(this).motd_actived_time = time;
2060                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOTD, campaign_message);
2061                         }
2062                 } else {
2063                         if (PHYS_INPUT_BUTTON_INFO(this)) {
2064                                 CS(this).motd_actived_time = time;
2065                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOTD, getwelcomemessage(this));
2066                         }
2067                 }
2068         }
2069         else if(CS(this).motd_actived_time > 0) // showing MOTD or campaign message
2070         {
2071                 if (autocvar_g_campaign) {
2072                         if (PHYS_INPUT_BUTTON_INFO(this))
2073                                 CS(this).motd_actived_time = time;
2074                         else if ((time - CS(this).motd_actived_time > 2) && IS_PLAYER(this)) { // hide it some seconds after BUTTON_INFO has been released
2075                                 CS(this).motd_actived_time = 0;
2076                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_MOTD);
2077                         }
2078                 } else {
2079                         if (PHYS_INPUT_BUTTON_INFO(this))
2080                                 CS(this).motd_actived_time = time;
2081                         else if (time - CS(this).motd_actived_time > 2) { // hide it some seconds after BUTTON_INFO has been released
2082                                 CS(this).motd_actived_time = 0;
2083                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_MOTD);
2084                         }
2085                 }
2086         }
2087         else //if(CS(this).motd_actived_time < 0) // just connected, motd is active
2088         {
2089                 if(PHYS_INPUT_BUTTON_INFO(this)) // BUTTON_INFO hides initial MOTD
2090                         CS(this).motd_actived_time = -2; // wait until BUTTON_INFO gets released
2091                 else if(CS(this).motd_actived_time == -2 || IS_PLAYER(this) || IS_SPEC(this))
2092                 {
2093                         // instanctly hide MOTD
2094                         CS(this).motd_actived_time = 0;
2095                         Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_MOTD);
2096                 }
2097         }
2098 }
2099
2100 bool joinAllowed(entity this)
2101 {
2102         if (CS(this).version_mismatch) return false;
2103         if (!nJoinAllowed(this, this)) return false;
2104         if (teamplay && lockteams) return false;
2105         if (ShowTeamSelection(this)) return false;
2106         if (MUTATOR_CALLHOOK(ForbidSpawn, this)) return false;
2107         return true;
2108 }
2109
2110 .int items_added;
2111 bool PlayerThink(entity this)
2112 {
2113         if (game_stopped || intermission_running) {
2114                 this.modelflags &= ~MF_ROCKET;
2115                 if(intermission_running)
2116                         IntermissionThink(this);
2117                 return false;
2118         }
2119
2120         if (timeout_status == TIMEOUT_ACTIVE) {
2121         // don't allow the player to turn around while game is paused
2122                 // FIXME turn this into CSQC stuff
2123                 this.v_angle = this.lastV_angle;
2124                 this.angles = this.lastV_angle;
2125                 this.fixangle = true;
2126         }
2127
2128         if (frametime) player_powerups(this);
2129
2130         if (IS_DEAD(this)) {
2131                 if (this.personal && g_race_qualifying) {
2132                         if (time > this.respawn_time) {
2133                                 STAT(RESPAWN_TIME, this) = this.respawn_time = time + 1; // only retry once a second
2134                                 respawn(this);
2135                                 CS(this).impulse = CHIMPULSE_SPEEDRUN.impulse;
2136                         }
2137                 } else {
2138                         if (frametime) player_anim(this);
2139
2140                         if (this.respawn_flags & RESPAWN_DENY)
2141                         {
2142                                 STAT(RESPAWN_TIME, this) = 0;
2143                                 return false;
2144                         }
2145
2146                         bool button_pressed = (PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_JUMP(this) || PHYS_INPUT_BUTTON_ATCK2(this) || PHYS_INPUT_BUTTON_HOOK(this) || PHYS_INPUT_BUTTON_USE(this));
2147
2148                         switch(this.deadflag)
2149                         {
2150                                 case DEAD_DYING:
2151                                 {
2152                                         if ((this.respawn_flags & RESPAWN_FORCE) && !(this.respawn_time < this.respawn_time_max))
2153                                                 this.deadflag = DEAD_RESPAWNING;
2154                                         else if (!button_pressed || (time >= this.respawn_time_max && (this.respawn_flags & RESPAWN_FORCE)))
2155                                                 this.deadflag = DEAD_DEAD;
2156                                         break;
2157                                 }
2158                                 case DEAD_DEAD:
2159                                 {
2160                                         if (button_pressed)
2161                                                 this.deadflag = DEAD_RESPAWNABLE;
2162                                         else if (time >= this.respawn_time_max && (this.respawn_flags & RESPAWN_FORCE))
2163                                                 this.deadflag = DEAD_RESPAWNING;
2164                                         break;
2165                                 }
2166                                 case DEAD_RESPAWNABLE:
2167                                 {
2168                                         if (!button_pressed || (this.respawn_flags & RESPAWN_FORCE))
2169                                                 this.deadflag = DEAD_RESPAWNING;
2170                                         break;
2171                                 }
2172                                 case DEAD_RESPAWNING:
2173                                 {
2174                                         if (time > this.respawn_time)
2175                                         {
2176                                                 this.respawn_time = time + 1; // only retry once a second
2177                                                 this.respawn_time_max = this.respawn_time;
2178                                                 respawn(this);
2179                                         }
2180                                         break;
2181                                 }
2182                         }
2183
2184                         ShowRespawnCountdown(this);
2185
2186                         if (this.respawn_flags & RESPAWN_SILENT)
2187                                 STAT(RESPAWN_TIME, this) = 0;
2188                         else if ((this.respawn_flags & RESPAWN_FORCE) && this.respawn_time < this.respawn_time_max)
2189                         {
2190                                 if (time < this.respawn_time)
2191                                         STAT(RESPAWN_TIME, this) = this.respawn_time;
2192                                 else if (this.deadflag != DEAD_RESPAWNING)
2193                                         STAT(RESPAWN_TIME, this) = -this.respawn_time_max;
2194                         }
2195                         else
2196                                 STAT(RESPAWN_TIME, this) = this.respawn_time;
2197                 }
2198
2199                 // if respawning, invert stat_respawn_time to indicate this, the client translates it
2200                 if (this.deadflag == DEAD_RESPAWNING && STAT(RESPAWN_TIME, this) > 0)
2201                         STAT(RESPAWN_TIME, this) *= -1;
2202
2203                 return false;
2204         }
2205
2206         bool have_hook = false;
2207         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2208         {
2209                 .entity weaponentity = weaponentities[slot];
2210                 if(this.(weaponentity).hook.state)
2211                 {
2212                         have_hook = true;
2213                         break;
2214                 }
2215         }
2216         bool do_crouch = PHYS_INPUT_BUTTON_CROUCH(this);
2217         if (have_hook) {
2218                 do_crouch = false;
2219         } else if (this.waterlevel >= WATERLEVEL_SWIMMING) {
2220                 do_crouch = false;
2221         } else if (this.vehicle) {
2222                 do_crouch = false;
2223         } else if (STAT(FROZEN, this)) {
2224                 do_crouch = false;
2225     }
2226
2227         if (do_crouch) {
2228                 if (!this.crouch) {
2229                         this.crouch = true;
2230                         this.view_ofs = STAT(PL_CROUCH_VIEW_OFS, this);
2231                         setsize(this, STAT(PL_CROUCH_MIN, this), STAT(PL_CROUCH_MAX, this));
2232                         // setanim(this, this.anim_duck, false, true, true); // this anim is BROKEN anyway
2233                 }
2234         } else if (this.crouch) {
2235         tracebox(this.origin, STAT(PL_MIN, this), STAT(PL_MAX, this), this.origin, false, this);
2236         if (!trace_startsolid) {
2237             this.crouch = false;
2238             this.view_ofs = STAT(PL_VIEW_OFS, this);
2239             setsize(this, STAT(PL_MIN, this), STAT(PL_MAX, this));
2240         }
2241         }
2242
2243         FixPlayermodel(this);
2244
2245         // LordHavoc: allow firing on move frames (sub-ticrate), this gives better timing on slow servers
2246         //if(frametime)
2247         {
2248                 this.items &= ~this.items_added;
2249
2250                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2251                 {
2252                         .entity weaponentity = weaponentities[slot];
2253                         W_WeaponFrame(this, weaponentity);
2254
2255                         if(slot == 0)
2256                         {
2257                                 this.clip_load = this.(weaponentity).clip_load;
2258                                 this.clip_size = this.(weaponentity).clip_size;
2259                         }
2260                 }
2261
2262                 this.items_added = 0;
2263                 if ((this.items & ITEM_Jetpack.m_itemid) && ((this.items & ITEM_JetpackRegen.m_itemid) || this.ammo_fuel >= 0.01))
2264             this.items_added |= IT_FUEL;
2265
2266                 this.items |= this.items_added;
2267         }
2268
2269         player_regen(this);
2270
2271         // WEAPONTODO: Add a weapon request for this
2272         // rot vortex charge to the charge limit
2273         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2274         {
2275                 .entity weaponentity = weaponentities[slot];
2276                 if (WEP_CVAR(vortex, charge_rot_rate) && this.(weaponentity).vortex_charge > WEP_CVAR(vortex, charge_limit) && this.(weaponentity).vortex_charge_rottime < time)
2277                         this.(weaponentity).vortex_charge = bound(WEP_CVAR(vortex, charge_limit), this.(weaponentity).vortex_charge - WEP_CVAR(vortex, charge_rot_rate) * frametime / W_TICSPERFRAME, 1);
2278         }
2279
2280         if (frametime) player_anim(this);
2281
2282         // secret status
2283         secrets_setstatus(this);
2284
2285         // monsters status
2286         monsters_setstatus(this);
2287
2288         this.dmg_team = max(0, this.dmg_team - autocvar_g_teamdamage_resetspeed * frametime);
2289
2290         return true;
2291 }
2292
2293 void ObserverThink(entity this)
2294 {
2295         if ( CS(this).impulse )
2296         {
2297                 MinigameImpulse(this, CS(this).impulse);
2298                 CS(this).impulse = 0;
2299         }
2300
2301         if (this.flags & FL_JUMPRELEASED) {
2302                 if (PHYS_INPUT_BUTTON_JUMP(this) && joinAllowed(this)) {
2303                         this.flags &= ~FL_JUMPRELEASED;
2304                         this.flags |= FL_SPAWNING;
2305                 } else if(PHYS_INPUT_BUTTON_ATCK(this) && !CS(this).version_mismatch) {
2306                         this.flags &= ~FL_JUMPRELEASED;
2307                         if(SpectateNext(this)) {
2308                                 TRANSMUTE(Spectator, this);
2309                         }
2310                 } else {
2311                         int preferred_movetype = ((!PHYS_INPUT_BUTTON_USE(this) ? this.cvar_cl_clippedspectating : !this.cvar_cl_clippedspectating) ? MOVETYPE_FLY_WORLDONLY : MOVETYPE_NOCLIP);
2312                         set_movetype(this, preferred_movetype);
2313                 }
2314         } else {
2315                 if (!(PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_JUMP(this))) {
2316                         this.flags |= FL_JUMPRELEASED;
2317                         if(this.flags & FL_SPAWNING)
2318                         {
2319                                 this.flags &= ~FL_SPAWNING;
2320                                 Join(this);
2321                                 return;
2322                         }
2323                 }
2324         }
2325 }
2326
2327 void SpectatorThink(entity this)
2328 {
2329         if ( CS(this).impulse )
2330         {
2331                 if(MinigameImpulse(this, CS(this).impulse))
2332                         CS(this).impulse = 0;
2333
2334                 if (CS(this).impulse == IMP_weapon_drop.impulse)
2335                 {
2336                         STAT(CAMERA_SPECTATOR, this) = (STAT(CAMERA_SPECTATOR, this) + 1) % 3;
2337                         CS(this).impulse = 0;
2338                         return;
2339                 }
2340         }
2341
2342         if (this.flags & FL_JUMPRELEASED) {
2343                 if (PHYS_INPUT_BUTTON_JUMP(this) && joinAllowed(this)) {
2344                         this.flags &= ~FL_JUMPRELEASED;
2345                         this.flags |= FL_SPAWNING;
2346                 } else if(PHYS_INPUT_BUTTON_ATCK(this) || CS(this).impulse == 10 || CS(this).impulse == 15 || CS(this).impulse == 18 || (CS(this).impulse >= 200 && CS(this).impulse <= 209)) {
2347                         this.flags &= ~FL_JUMPRELEASED;
2348                         if(SpectateNext(this)) {
2349                                 TRANSMUTE(Spectator, this);
2350                         } else {
2351                                 TRANSMUTE(Observer, this);
2352                                 PutClientInServer(this);
2353                         }
2354                         CS(this).impulse = 0;
2355                 } else if(CS(this).impulse == 12 || CS(this).impulse == 16  || CS(this).impulse == 19 || (CS(this).impulse >= 220 && CS(this).impulse <= 229)) {
2356                         this.flags &= ~FL_JUMPRELEASED;
2357                         if(SpectatePrev(this)) {
2358                                 TRANSMUTE(Spectator, this);
2359                         } else {
2360                                 TRANSMUTE(Observer, this);
2361                                 PutClientInServer(this);
2362                         }
2363                         CS(this).impulse = 0;
2364                 } else if (PHYS_INPUT_BUTTON_ATCK2(this)) {
2365                         this.flags &= ~FL_JUMPRELEASED;
2366                         TRANSMUTE(Observer, this);
2367                         PutClientInServer(this);
2368                 } else {
2369                         if(!SpectateUpdate(this))
2370                                 PutObserverInServer(this);
2371                 }
2372         } else {
2373                 if (!(PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_ATCK2(this))) {
2374                         this.flags |= FL_JUMPRELEASED;
2375                         if(this.flags & FL_SPAWNING)
2376                         {
2377                                 this.flags &= ~FL_SPAWNING;
2378                                 Join(this);
2379                                 return;
2380                         }
2381                 }
2382                 if(!SpectateUpdate(this))
2383                         PutObserverInServer(this);
2384         }
2385
2386         this.flags |= FL_CLIENT | FL_NOTARGET;
2387 }
2388
2389 void vehicles_enter (entity pl, entity veh);
2390 void PlayerUseKey(entity this)
2391 {
2392         if (!IS_PLAYER(this))
2393                 return;
2394
2395         if(this.vehicle)
2396         {
2397                 if(!game_stopped)
2398                 {
2399                         vehicles_exit(this.vehicle, VHEF_NORMAL);
2400                         return;
2401                 }
2402         }
2403         else if(autocvar_g_vehicles_enter)
2404         {
2405                 if(!STAT(FROZEN, this))
2406                 if(!IS_DEAD(this))
2407                 if(!game_stopped)
2408                 {
2409                         entity head, closest_target = NULL;
2410                         head = WarpZone_FindRadius(this.origin, autocvar_g_vehicles_enter_radius, true);
2411
2412                         while(head) // find the closest acceptable target to enter
2413                         {
2414                                 if(IS_VEHICLE(head))
2415                                 if(!IS_DEAD(head))
2416                                 if(!head.owner || ((head.vehicle_flags & VHF_MULTISLOT) && SAME_TEAM(head.owner, this)))
2417                                 if(head.takedamage != DAMAGE_NO)
2418                                 {
2419                                         if(closest_target)
2420                                         {
2421                                                 if(vlen2(this.origin - head.origin) < vlen2(this.origin - closest_target.origin))
2422                                                 { closest_target = head; }
2423                                         }
2424                                         else { closest_target = head; }
2425                                 }
2426
2427                                 head = head.chain;
2428                         }
2429
2430                         if(closest_target) { vehicles_enter(this, closest_target); return; }
2431                 }
2432         }
2433
2434         // a use key was pressed; call handlers
2435         MUTATOR_CALLHOOK(PlayerUseKey, this);
2436 }
2437
2438
2439 /*
2440 =============
2441 PlayerPreThink
2442
2443 Called every frame for each client before the physics are run
2444 =============
2445 */
2446 .float last_vehiclecheck;
2447 void PlayerPreThink (entity this)
2448 {
2449         WarpZone_PlayerPhysics_FixVAngle(this);
2450
2451         if (frametime) {
2452                 // physics frames: update anticheat stuff
2453                 anticheat_prethink(this);
2454         }
2455
2456         if (blockSpectators && frametime) {
2457                 // WORKAROUND: only use dropclient in server frames (frametime set).
2458                 // Never use it in cl_movement frames (frametime zero).
2459                 checkSpectatorBlock(this);
2460     }
2461
2462         zoomstate_set = false;
2463
2464         // Check for nameless players
2465         if (isInvisibleString(this.netname)) {
2466                 this.netname = strzone(sprintf("Player#%d", this.playerid));
2467                 // stuffcmd(this, strcat("name ", this.netname, "\n")); // maybe?
2468         }
2469         if (this.netname != CS(this).netname_previous) {
2470                 if (autocvar_sv_eventlog) {
2471                         GameLogEcho(strcat(":name:", ftos(this.playerid), ":", playername(this, false)));
2472         }
2473                 if (CS(this).netname_previous) strunzone(CS(this).netname_previous);
2474                 CS(this).netname_previous = strzone(this.netname);
2475         }
2476
2477         // version nagging
2478         if (CS(this).version_nagtime && this.cvar_g_xonoticversion && time > CS(this).version_nagtime) {
2479         CS(this).version_nagtime = 0;
2480         if (strstrofs(this.cvar_g_xonoticversion, "git", 0) >= 0 || strstrofs(this.cvar_g_xonoticversion, "autobuild", 0) >= 0) {
2481             // git client
2482         } else if (strstrofs(autocvar_g_xonoticversion, "git", 0) >= 0 || strstrofs(autocvar_g_xonoticversion, "autobuild", 0) >= 0) {
2483             // git server
2484             Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_BETA, autocvar_g_xonoticversion, this.cvar_g_xonoticversion);
2485         } else {
2486             int r = vercmp(this.cvar_g_xonoticversion, autocvar_g_xonoticversion);
2487             if (r < 0) { // old client
2488                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_OUTDATED, autocvar_g_xonoticversion, this.cvar_g_xonoticversion);
2489             } else if (r > 0) { // old server
2490                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_OLD, autocvar_g_xonoticversion, this.cvar_g_xonoticversion);
2491             }
2492         }
2493     }
2494
2495         // GOD MODE info
2496         if (!(this.flags & FL_GODMODE) && this.max_armorvalue)
2497         {
2498                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_GODMODE_OFF, this.max_armorvalue);
2499                 this.max_armorvalue = 0;
2500         }
2501
2502         if(IS_PLAYER(this))
2503         {
2504                 if (STAT(FROZEN, this) == 2)
2505                 {
2506                         this.revive_progress = bound(0, this.revive_progress + frametime * this.revive_speed, 1);
2507                         this.health = max(1, this.revive_progress * start_health);
2508                         this.iceblock.alpha = bound(0.2, 1 - this.revive_progress, 1);
2509
2510                         if (this.revive_progress >= 1)
2511                                 Unfreeze(this);
2512                 }
2513                 else if (STAT(FROZEN, this) == 3)
2514                 {
2515                         this.revive_progress = bound(0, this.revive_progress - frametime * this.revive_speed, 1);
2516                         this.health = max(0, autocvar_g_nades_ice_health + (start_health-autocvar_g_nades_ice_health) * this.revive_progress );
2517
2518                         if (this.health < 1)
2519                         {
2520                                 if (this.vehicle)
2521                                         vehicles_exit(this.vehicle, VHEF_RELEASE);
2522                                 if(this.event_damage)
2523                                         this.event_damage(this, this, this.frozen_by, 1, DEATH_NADE_ICE_FREEZE.m_id, this.origin, '0 0 0');
2524                         }
2525                         else if (this.revive_progress <= 0)
2526                                 Unfreeze(this);
2527                 }
2528         }
2529
2530         MUTATOR_CALLHOOK(PlayerPreThink, this);
2531
2532         if(autocvar_g_vehicles_enter && (time > this.last_vehiclecheck) && !game_stopped && !this.vehicle)
2533         if(IS_PLAYER(this) && !STAT(FROZEN, this) && !IS_DEAD(this))
2534         {
2535                 FOREACH_ENTITY_RADIUS(this.origin, autocvar_g_vehicles_enter_radius, IS_VEHICLE(it),
2536                 {
2537                         if(!IS_DEAD(it) && it.takedamage != DAMAGE_NO)
2538                         if((it.vehicle_flags & VHF_MULTISLOT) && SAME_TEAM(it.owner, this))
2539                         {
2540                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER_GUNNER);
2541                         }
2542                         else if(!it.owner)
2543                         {
2544                                 if(!it.team || SAME_TEAM(this, it))
2545                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER);
2546                                 else if(autocvar_g_vehicles_steal)
2547                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER_STEAL);
2548                         }
2549                 });
2550
2551                 this.last_vehiclecheck = time + 1;
2552         }
2553
2554         if(!this.cvar_cl_newusekeysupported) // FIXME remove this - it was a stupid idea to begin with, we can JUST use the button
2555         {
2556                 if(PHYS_INPUT_BUTTON_USE(this) && !CS(this).usekeypressed)
2557                         PlayerUseKey(this);
2558                 CS(this).usekeypressed = PHYS_INPUT_BUTTON_USE(this);
2559         }
2560
2561         if (IS_REAL_CLIENT(this))
2562                 PrintWelcomeMessage(this);
2563
2564         if (IS_PLAYER(this)) {
2565                 if(!PlayerThink(this))
2566                         return;
2567         }
2568         else if (game_stopped || intermission_running) {
2569                 if(intermission_running)
2570                         IntermissionThink(this);
2571                 return;
2572         }
2573         else if (IS_OBSERVER(this)) {
2574                 ObserverThink(this);
2575         }
2576         else if (IS_SPEC(this)) {
2577                 SpectatorThink(this);
2578         }
2579
2580         // WEAPONTODO: Add weapon request for this
2581         if (!zoomstate_set) {
2582                 bool wep_zoomed = false;
2583                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2584                 {
2585                         .entity weaponentity = weaponentities[slot];
2586                         Weapon thiswep = this.(weaponentity).m_weapon;
2587                         if(thiswep != WEP_Null && thiswep.wr_zoom)
2588                                 wep_zoomed += thiswep.wr_zoom(thiswep, this);
2589                 }
2590                 SetZoomState(this, PHYS_INPUT_BUTTON_ZOOM(this) || PHYS_INPUT_BUTTON_ZOOMSCRIPT(this) || wep_zoomed);
2591     }
2592
2593         if (CS(this).teamkill_soundtime && time > CS(this).teamkill_soundtime)
2594         {
2595                 CS(this).teamkill_soundtime = 0;
2596
2597                 entity e = CS(this).teamkill_soundsource;
2598                 entity oldpusher = e.pusher;
2599                 e.pusher = this;
2600                 PlayerSound(e, playersound_teamshoot, CH_VOICE, VOL_BASEVOICE, VOICETYPE_LASTATTACKER_ONLY);
2601                 e.pusher = oldpusher;
2602         }
2603
2604         if (CS(this).taunt_soundtime && time > CS(this).taunt_soundtime) {
2605                 CS(this).taunt_soundtime = 0;
2606                 PlayerSound(this, playersound_taunt, CH_VOICE, VOL_BASEVOICE, VOICETYPE_AUTOTAUNT);
2607         }
2608
2609         target_voicescript_next(this);
2610
2611         // WEAPONTODO: Move into weaponsystem somehow
2612         // if a player goes unarmed after holding a loaded weapon, empty his clip size and remove the crosshair ammo ring
2613         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2614         {
2615                 .entity weaponentity = weaponentities[slot];
2616                 if(this.(weaponentity).m_weapon == WEP_Null)
2617                         this.(weaponentity).clip_load = this.(weaponentity).clip_size = 0;
2618         }
2619 }
2620
2621 void DrownPlayer(entity this)
2622 {
2623         if(IS_DEAD(this))
2624                 return;
2625
2626         if (this.waterlevel != WATERLEVEL_SUBMERGED || this.vehicle)
2627         {
2628                 if(this.air_finished < time)
2629                         PlayerSound(this, playersound_gasp, CH_PLAYER, VOL_BASE, VOICETYPE_PLAYERSOUND);
2630                 this.air_finished = time + autocvar_g_balance_contents_drowndelay;
2631                 this.dmg = 2;
2632         }
2633         else if (this.air_finished < time)
2634         {       // drown!
2635                 if (this.pain_finished < time)
2636                 {
2637                         Damage (this, NULL, NULL, autocvar_g_balance_contents_playerdamage_drowning * autocvar_g_balance_contents_damagerate, DEATH_DROWN.m_id, this.origin, '0 0 0');
2638                         this.pain_finished = time + 0.5;
2639                 }
2640         }
2641 }
2642
2643 .bool move_qcphysics;
2644
2645 void Player_Physics(entity this)
2646 {
2647         set_movetype(this, this.move_movetype);
2648
2649         if(!this.move_qcphysics)
2650                 return;
2651
2652         if(!frametime && !CS(this).pm_frametime)
2653                 return;
2654
2655         Movetype_Physics_NoMatchTicrate(this, CS(this).pm_frametime, true);
2656
2657         CS(this).pm_frametime = 0;
2658 }
2659
2660 /*
2661 =============
2662 PlayerPostThink
2663
2664 Called every frame for each client after the physics are run
2665 =============
2666 */
2667 void PlayerPostThink (entity this)
2668 {
2669         Player_Physics(this);
2670
2671         if (sv_maxidle > 0)
2672         if (frametime) // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2673         if (IS_REAL_CLIENT(this))
2674         if (IS_PLAYER(this) || sv_maxidle_spectatorsareidle)
2675         {
2676                 int totalClients = 0;
2677                 if(sv_maxidle_slots > 0)
2678                 {
2679                         FOREACH_CLIENT(IS_REAL_CLIENT(it) || sv_maxidle_slots_countbots,
2680                         {
2681                                 ++totalClients;
2682                         });
2683                 }
2684
2685                 if (sv_maxidle_slots > 0 && (maxclients - totalClients) > sv_maxidle_slots)
2686                 { /* do nothing */ }
2687                 else if (time - CS(this).parm_idlesince < 1) // instead of (time == this.parm_idlesince) to support sv_maxidle <= 10
2688                 {
2689                         if (CS(this).idlekick_lasttimeleft)
2690                         {
2691                                 CS(this).idlekick_lasttimeleft = 0;
2692                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_IDLING);
2693                         }
2694                 }
2695                 else
2696                 {
2697                         float timeleft = ceil(sv_maxidle - (time - CS(this).parm_idlesince));
2698                         if (timeleft == min(10, sv_maxidle - 1)) { // - 1 to support sv_maxidle <= 10
2699                                 if (!CS(this).idlekick_lasttimeleft)
2700                                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_DISCONNECT_IDLING, timeleft);
2701                         }
2702                         if (timeleft <= 0) {
2703                                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_QUIT_KICK_IDLING, this.netname);
2704                                 dropclient(this);
2705                                 return;
2706                         }
2707                         else if (timeleft <= 10) {
2708                                 if (timeleft != CS(this).idlekick_lasttimeleft) {
2709                                     Send_Notification(NOTIF_ONE, this, MSG_ANNCE, Announcer_PickNumber(CNT_IDLE, timeleft));
2710                 }
2711                                 CS(this).idlekick_lasttimeleft = timeleft;
2712                         }
2713                 }
2714         }
2715
2716         CheatFrame(this);
2717
2718         if (game_stopped)
2719         {
2720                 this.solid = SOLID_NOT;
2721                 this.takedamage = DAMAGE_NO;
2722                 set_movetype(this, MOVETYPE_NONE);
2723         }
2724
2725         if (IS_PLAYER(this)) {
2726                 DrownPlayer(this);
2727                 UpdateChatBubble(this);
2728                 if (CS(this).impulse) ImpulseCommands(this);
2729                 if (game_stopped)
2730                 {
2731                         CSQCMODEL_AUTOUPDATE(this);
2732                         return;
2733                 }
2734                 GetPressedKeys(this);
2735         }
2736
2737         if (this.waypointsprite_attachedforcarrier) {
2738             vector v = healtharmor_maxdamage(this.health, this.armorvalue, autocvar_g_balance_armor_blockpercent, DEATH_WEAPON.m_id);
2739                 WaypointSprite_UpdateHealth(this.waypointsprite_attachedforcarrier, '1 0 0' * v);
2740     }
2741
2742         playerdemo_write(this);
2743
2744         CSQCMODEL_AUTOUPDATE(this);
2745 }
2746
2747 // hack to copy the button fields from the client entity to the Client State
2748 void PM_UpdateButtons(entity this, entity store)
2749 {
2750         if(this.impulse)
2751                 store.impulse = this.impulse;
2752         this.impulse = 0;
2753
2754         store.button0 = this.button0;
2755         store.button2 = this.button2;
2756         store.button3 = this.button3;
2757         store.button4 = this.button4;
2758         store.button5 = this.button5;
2759         store.button6 = this.button6;
2760         store.button7 = this.button7;
2761         store.button8 = this.button8;
2762         store.button9 = this.button9;
2763         store.button10 = this.button10;
2764         store.button11 = this.button11;
2765         store.button12 = this.button12;
2766         store.button13 = this.button13;
2767         store.button14 = this.button14;
2768         store.button15 = this.button15;
2769         store.button16 = this.button16;
2770         store.buttonuse = this.buttonuse;
2771         store.buttonchat = this.buttonchat;
2772
2773         store.cursor_active = this.cursor_active;
2774         store.cursor_screen = this.cursor_screen;
2775         store.cursor_trace_start = this.cursor_trace_start;
2776         store.cursor_trace_endpos = this.cursor_trace_endpos;
2777         store.cursor_trace_ent = this.cursor_trace_ent;
2778
2779         store.ping = this.ping;
2780         store.ping_packetloss = this.ping_packetloss;
2781         store.ping_movementloss = this.ping_movementloss;
2782
2783         store.v_angle = this.v_angle;
2784         store.movement = this.movement;
2785 }