qcsrc/server/client.qc

   1 #include "client.qh"
   2
   3 #include <server/defs.qh>
   4 #include <server/miscfunctions.qh>
   5 #include <common/effects/all.qh>
   6 #include "anticheat.qh"
   7 #include "impulse.qh"
   8 #include "player.qh"
   9 #include "ipban.qh"
  10 #include "miscfunctions.qh"
  11 #include "portals.qh"
  12 #include "teamplay.qh"
  13 #include "playerdemo.qh"
  14 #include "spawnpoints.qh"
  15 #include "resources.qh"
  16 #include "g_damage.qh"
  17 #include "g_hook.qh"
  18 #include "command/common.qh"
  19 #include "cheats.qh"
  20 #include "g_world.qh"
  21 #include "race.qh"
  22 #include "antilag.qh"
  23 #include "campaign.qh"
  24 #include "command/common.qh"
  25 #include "scores_rules.qh"
  26
  27 #include "bot/api.qh"
  28
  29 #include "../common/ent_cs.qh"
  30 #include "../common/wepent.qh"
  31 #include <common/state.qh>
  32
  33 #include <common/effects/qc/globalsound.qh>
  34
  35 #include "../common/triggers/func/conveyor.qh"
  36 #include "../common/triggers/teleporters.qh"
  37
  38 #include "../common/vehicles/all.qh"
  39
  40 #include "weapons/hitplot.qh"
  41 #include "weapons/weaponsystem.qh"
  42
  43 #include "../common/net_notice.qh"
  44 #include "../common/net_linked.qh"
  45 #include "../common/physics/player.qh"
  46
  47 #include "../common/items/_mod.qh"
  48
  49 #include "../common/mutators/mutator/waypoints/all.qh"
  50
  51 #include "../common/triggers/subs.qh"
  52 #include "../common/triggers/triggers.qh"
  53 #include "../common/triggers/trigger/secret.qh"
  54
  55 #include "../common/minigames/sv_minigames.qh"
  56
  57 #include "../common/items/inventory.qh"
  58
  59 #include "../common/monsters/sv_monsters.qh"
  60
  61 #include "../lib/warpzone/server.qh"
  62
  63 STATIC_METHOD(Client, Add, void(Client this, int _team))
  64 {
  65     ClientConnect(this);
  66     TRANSMUTE(Player, this);
  67     this.frame = 12; // 7
  68     this.team = _team;
  69     PutClientInServer(this);
  70 }
  71
  72 void PutObserverInServer(entity this);
  73
  74 STATIC_METHOD(Client, Remove, void(Client this))
  75 {
  76     TRANSMUTE(Observer, this);
  77     PutClientInServer(this);
  78     ClientDisconnect(this);
  79 }
  80
  81 void send_CSQC_teamnagger() {
  82         WriteHeader(MSG_BROADCAST, TE_CSQC_TEAMNAGGER);
  83 }
  84
  85 int CountSpectators(entity player, entity to)
  86 {
  87         if(!player) { return 0; } // not sure how, but best to be safe
  88
  89         int spec_count = 0;
  90
  91         FOREACH_CLIENT(IS_REAL_CLIENT(it) && IS_SPEC(it) && it != to && it.enemy == player,
  92         {
  93                 spec_count++;
  94         });
  95
  96         return spec_count;
  97 }
  98
  99 void WriteSpectators(entity player, entity to)
 100 {
 101         if(!player) { return; } // not sure how, but best to be safe
 102
 103         FOREACH_CLIENT(IS_REAL_CLIENT(it) && IS_SPEC(it) && it != to && it.enemy == player,
 104         {
 105                 WriteByte(MSG_ENTITY, num_for_edict(it));
 106         });
 107 }
 108
 109 bool ClientData_Send(entity this, entity to, int sf)
 110 {
 111         assert(to == this.owner, return false);
 112
 113         entity e = to;
 114         if (IS_SPEC(e)) e = e.enemy;
 115
 116         sf = 0;
 117         if (CS(e).race_completed)       sf |= BIT(0); // forced scoreboard
 118         if (CS(to).spectatee_status)    sf |= BIT(1); // spectator ent number follows
 119         if (CS(e).zoomstate)            sf |= BIT(2); // zoomed
 120         if (autocvar_sv_showspectators) sf |= BIT(4); // show spectators
 121
 122         WriteHeader(MSG_ENTITY, ENT_CLIENT_CLIENTDATA);
 123         WriteByte(MSG_ENTITY, sf);
 124
 125         if (sf & BIT(1))
 126                 WriteByte(MSG_ENTITY, CS(to).spectatee_status);
 127
 128         if(sf & BIT(4))
 129         {
 130                 float specs = CountSpectators(e, to);
 131                 WriteByte(MSG_ENTITY, specs);
 132                 WriteSpectators(e, to);
 133         }
 134
 135         return true;
 136 }
 137
 138 void ClientData_Attach(entity this)
 139 {
 140         Net_LinkEntity(CS(this).clientdata = new_pure(clientdata), false, 0, ClientData_Send);
 141         CS(this).clientdata.drawonlytoclient = this;
 142         CS(this).clientdata.owner = this;
 143 }
 144
 145 void ClientData_Detach(entity this)
 146 {
 147         delete(CS(this).clientdata);
 148         CS(this).clientdata = NULL;
 149 }
 150
 151 void ClientData_Touch(entity e)
 152 {
 153         CS(e).clientdata.SendFlags = 1;
 154
 155         // make it spectatable
 156         FOREACH_CLIENT(IS_REAL_CLIENT(it) && it != e && IS_SPEC(it) && it.enemy == e, { CS(it).clientdata.SendFlags = 1; });
 157 }
 158
 159 void SetSpectatee(entity this, entity spectatee);
 160 void SetSpectatee_status(entity this, int spectatee_num);
 161
 162
 163 /*
 164 =============
 165 CheckPlayerModel
 166
 167 Checks if the argument string can be a valid playermodel.
 168 Returns a valid one in doubt.
 169 =============
 170 */
 171 string FallbackPlayerModel;
 172 string CheckPlayerModel(string plyermodel) {
 173         if(FallbackPlayerModel != cvar_defstring("_cl_playermodel"))
 174         {
 175                 // note: we cannot summon Don Strunzone here, some player may
 176                 // still have the model string set. In case anyone manages how
 177                 // to change a cvar default, we'll have a small leak here.
 178                 FallbackPlayerModel = strzone(cvar_defstring("_cl_playermodel"));
 179         }
 180         // only in right path
 181         if( substring(plyermodel,0,14) != "models/player/")
 182                 return FallbackPlayerModel;
 183         // only good file extensions
 184         if(substring(plyermodel,-4,4) != ".zym")
 185         if(substring(plyermodel,-4,4) != ".dpm")
 186         if(substring(plyermodel,-4,4) != ".iqm")
 187         if(substring(plyermodel,-4,4) != ".md3")
 188         if(substring(plyermodel,-4,4) != ".psk")
 189                 return FallbackPlayerModel;
 190         // forbid the LOD models
 191         if(substring(plyermodel, -9,5) == "_lod1")
 192                 return FallbackPlayerModel;
 193         if(substring(plyermodel, -9,5) == "_lod2")
 194                 return FallbackPlayerModel;
 195         if(plyermodel != strtolower(plyermodel))
 196                 return FallbackPlayerModel;
 197         // also, restrict to server models
 198         if(autocvar_sv_servermodelsonly)
 199         {
 200                 if(!fexists(plyermodel))
 201                         return FallbackPlayerModel;
 202         }
 203         return plyermodel;
 204 }
 205
 206 void setplayermodel(entity e, string modelname)
 207 {
 208         precache_model(modelname);
 209         _setmodel(e, modelname);
 210         player_setupanimsformodel(e);
 211         if(!autocvar_g_debug_globalsounds)
 212                 UpdatePlayerSounds(e);
 213 }
 214
 215 void FixPlayermodel(entity player);
 216 /** putting a client as observer in the server */
 217 void PutObserverInServer(entity this)
 218 {
 219     bool mutator_returnvalue = MUTATOR_CALLHOOK(MakePlayerObserver, this);
 220         PlayerState_detach(this);
 221
 222         if (IS_PLAYER(this) && this.health >= 1) {
 223         // despawn effect
 224                 Send_Effect(EFFECT_SPAWN_NEUTRAL, this.origin, '0 0 0', 1);
 225     }
 226
 227     {
 228         entity spot = SelectSpawnPoint(this, true);
 229         if (!spot) LOG_FATAL("No spawnpoints for observers?!?");
 230         this.angles = vec2(spot.angles);
 231         this.fixangle = true;
 232         // offset it so that the spectator spawns higher off the ground, looks better this way
 233         setorigin(this, spot.origin + STAT(PL_VIEW_OFS, this));
 234         if (IS_REAL_CLIENT(this))
 235         {
 236             msg_entity = this;
 237             WriteByte(MSG_ONE, SVC_SETVIEW);
 238             WriteEntity(MSG_ONE, this);
 239         }
 240         // give the spectator some space between walls for MOVETYPE_FLY_WORLDONLY
 241         // so that your view doesn't go into the ceiling with MOVETYPE_FLY_WORLDONLY, previously "PL_VIEW_OFS"
 242         if(!autocvar_g_debug_globalsounds)
 243         {
 244                 // needed for player sounds
 245                 this.model = "";
 246                 FixPlayermodel(this);
 247         }
 248         setmodel(this, MDL_Null);
 249         setsize(this, STAT(PL_CROUCH_MIN, this), STAT(PL_CROUCH_MAX, this));
 250         this.view_ofs = '0 0 0';
 251     }
 252
 253     RemoveGrapplingHooks(this);
 254         Portal_ClearAll(this);
 255         Unfreeze(this);
 256         SetSpectatee(this, NULL);
 257
 258         if (this.alivetime)
 259         {
 260                 if (!warmup_stage)
 261                         PS_GR_P_ADDVAL(this, PLAYERSTATS_ALIVETIME, time - this.alivetime);
 262                 this.alivetime = 0;
 263         }
 264
 265         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
 266
 267         WaypointSprite_PlayerDead(this);
 268
 269         if (mutator_returnvalue) {
 270             // mutator prevents resetting teams+score
 271         } else {
 272                 int oldteam = this.team;
 273                 this.team = -1;  // move this as it is needed to log the player spectating in eventlog
 274                 MUTATOR_CALLHOOK(Player_ChangedTeam, this, oldteam, this.team);
 275         this.frags = FRAGS_SPECTATOR;
 276         PlayerScore_Clear(this);  // clear scores when needed
 277     }
 278
 279         if (CS(this).killcount != FRAGS_SPECTATOR)
 280         {
 281                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_QUIT_SPECTATE, this.netname);
 282                 if(!game_stopped)
 283                 if(autocvar_g_chat_nospectators == 1 || (!warmup_stage && autocvar_g_chat_nospectators == 2))
 284                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_CHAT_NOSPECTATORS);
 285
 286                 if(!CS(this).just_joined)
 287                         LogTeamchange(this.playerid, -1, 4);
 288                 else
 289                         CS(this).just_joined = false;
 290         }
 291
 292         accuracy_resend(this);
 293
 294         CS(this).spectatortime = time;
 295         if(this.bot_attack)
 296                 IL_REMOVE(g_bot_targets, this);
 297         this.bot_attack = false;
 298     this.hud = HUD_NORMAL;
 299         TRANSMUTE(Observer, this);
 300         this.iscreature = false;
 301         this.teleportable = TELEPORT_SIMPLE;
 302         if(this.damagedbycontents)
 303                 IL_REMOVE(g_damagedbycontents, this);
 304         this.damagedbycontents = false;
 305         this.health = FRAGS_SPECTATOR;
 306         SetSpectatee_status(this, etof(this));
 307         this.takedamage = DAMAGE_NO;
 308         this.solid = SOLID_NOT;
 309         set_movetype(this, MOVETYPE_FLY_WORLDONLY); // user preference is controlled by playerprethink
 310         this.flags = FL_CLIENT | FL_NOTARGET;
 311         this.armorvalue = 666;
 312         this.effects = 0;
 313         this.armorvalue = autocvar_g_balance_armor_start;
 314         this.pauserotarmor_finished = 0;
 315         this.pauserothealth_finished = 0;
 316         this.pauseregen_finished = 0;
 317         this.damageforcescale = 0;
 318         this.death_time = 0;
 319         this.respawn_flags = 0;
 320         this.respawn_time = 0;
 321         this.stat_respawn_time = 0;
 322         this.alpha = 0;
 323         this.scale = 0;
 324         this.fade_time = 0;
 325         this.pain_frame = 0;
 326         this.pain_finished = 0;
 327         this.strength_finished = 0;
 328         this.invincible_finished = 0;
 329         this.superweapons_finished = 0;
 330         this.pushltime = 0;
 331         this.istypefrag = 0;
 332         setthink(this, func_null);
 333         this.nextthink = 0;
 334         this.deadflag = DEAD_NO;
 335         this.crouch = false;
 336         this.revive_progress = 0;
 337         this.revival_time = 0;
 338
 339         this.items = 0;
 340         this.weapons = '0 0 0';
 341         this.drawonlytoclient = this;
 342
 343         this.weaponmodel = "";
 344         for (int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 345         {
 346                 this.weaponentities[slot] = NULL;
 347         }
 348         this.exteriorweaponentity = NULL;
 349         CS(this).killcount = FRAGS_SPECTATOR;
 350         this.velocity = '0 0 0';
 351         this.avelocity = '0 0 0';
 352         this.punchangle = '0 0 0';
 353         this.punchvector = '0 0 0';
 354         this.oldvelocity = this.velocity;
 355         this.fire_endtime = -1;
 356         this.event_damage = func_null;
 357
 358         for(int slot = 0; slot < MAX_AXH; ++slot)
 359         {
 360                 entity axh = this.(AuxiliaryXhair[slot]);
 361                 this.(AuxiliaryXhair[slot]) = NULL;
 362
 363                 if(axh.owner == this && axh != NULL && !wasfreed(axh))
 364                         delete(axh);
 365         }
 366 }
 367
 368 int player_getspecies(entity this)
 369 {
 370         get_model_parameters(this.model, this.skin);
 371         int s = get_model_parameters_species;
 372         get_model_parameters(string_null, 0);
 373         if (s < 0) return SPECIES_HUMAN;
 374         return s;
 375 }
 376
 377 .float model_randomizer;
 378 void FixPlayermodel(entity player)
 379 {
 380         string defaultmodel = "";
 381         int defaultskin = 0;
 382         if(autocvar_sv_defaultcharacter)
 383         {
 384                 if(teamplay)
 385                 {
 386                         switch(player.team)
 387                         {
 388                                 case NUM_TEAM_1: defaultmodel = autocvar_sv_defaultplayermodel_red; defaultskin = autocvar_sv_defaultplayerskin_red; break;
 389                                 case NUM_TEAM_2: defaultmodel = autocvar_sv_defaultplayermodel_blue; defaultskin = autocvar_sv_defaultplayerskin_blue; break;
 390                                 case NUM_TEAM_3: defaultmodel = autocvar_sv_defaultplayermodel_yellow; defaultskin = autocvar_sv_defaultplayerskin_yellow; break;
 391                                 case NUM_TEAM_4: defaultmodel = autocvar_sv_defaultplayermodel_pink; defaultskin = autocvar_sv_defaultplayerskin_pink; break;
 392                         }
 393                 }
 394
 395                 if(defaultmodel == "")
 396                 {
 397                         defaultmodel = autocvar_sv_defaultplayermodel;
 398                         defaultskin = autocvar_sv_defaultplayerskin;
 399                 }
 400
 401                 int n = tokenize_console(defaultmodel);
 402                 if(n > 0)
 403                 {
 404                         defaultmodel = argv(floor(n * CS(player).model_randomizer));
 405                         // However, do NOT randomize if the player-selected model is in the list.
 406                         for (int i = 0; i < n; ++i)
 407                                 if ((argv(i) == player.playermodel && defaultskin == stof(player.playerskin)) || argv(i) == strcat(player.playermodel, ":", player.playerskin))
 408                                         defaultmodel = argv(i);
 409                 }
 410
 411                 int i = strstrofs(defaultmodel, ":", 0);
 412                 if(i >= 0)
 413                 {
 414                         defaultskin = stof(substring(defaultmodel, i+1, -1));
 415                         defaultmodel = substring(defaultmodel, 0, i);
 416                 }
 417         }
 418         if(autocvar_sv_defaultcharacterskin && !defaultskin)
 419         {
 420                 if(teamplay)
 421                 {
 422                         switch(player.team)
 423                         {
 424                                 case NUM_TEAM_1: defaultskin = autocvar_sv_defaultplayerskin_red; break;
 425                                 case NUM_TEAM_2: defaultskin = autocvar_sv_defaultplayerskin_blue; break;
 426                                 case NUM_TEAM_3: defaultskin = autocvar_sv_defaultplayerskin_yellow; break;
 427                                 case NUM_TEAM_4: defaultskin = autocvar_sv_defaultplayerskin_pink; break;
 428                         }
 429                 }
 430
 431                 if(!defaultskin)
 432                         defaultskin = autocvar_sv_defaultplayerskin;
 433         }
 434
 435         MUTATOR_CALLHOOK(FixPlayermodel, defaultmodel, defaultskin, player);
 436         defaultmodel = M_ARGV(0, string);
 437         defaultskin = M_ARGV(1, int);
 438
 439         bool chmdl = false;
 440         int oldskin;
 441         if(defaultmodel != "")
 442         {
 443                 if (defaultmodel != player.model)
 444                 {
 445                         vector m1 = player.mins;
 446                         vector m2 = player.maxs;
 447                         setplayermodel (player, defaultmodel);
 448                         setsize (player, m1, m2);
 449                         chmdl = true;
 450                 }
 451
 452                 oldskin = player.skin;
 453                 player.skin = defaultskin;
 454         } else {
 455                 if (player.playermodel != player.model || player.playermodel == "")
 456                 {
 457                         player.playermodel = CheckPlayerModel(player.playermodel); // this is never "", so no endless loop
 458                         vector m1 = player.mins;
 459                         vector m2 = player.maxs;
 460                         setplayermodel (player, player.playermodel);
 461                         setsize (player, m1, m2);
 462                         chmdl = true;
 463                 }
 464
 465                 if(!autocvar_sv_defaultcharacterskin)
 466                 {
 467                         oldskin = player.skin;
 468                         player.skin = stof(player.playerskin);
 469                 }
 470                 else
 471                 {
 472                         oldskin = player.skin;
 473                         player.skin = defaultskin;
 474                 }
 475         }
 476
 477         if(chmdl || oldskin != player.skin) // model or skin has changed
 478         {
 479                 player.species = player_getspecies(player); // update species
 480                 if(!autocvar_g_debug_globalsounds)
 481                         UpdatePlayerSounds(player); // update skin sounds
 482         }
 483
 484         if(!teamplay)
 485                 if(strlen(autocvar_sv_defaultplayercolors))
 486                         if(player.clientcolors != stof(autocvar_sv_defaultplayercolors))
 487                                 setcolor(player, stof(autocvar_sv_defaultplayercolors));
 488 }
 489
 490 void PutPlayerInServer(entity this)
 491 {
 492         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
 493
 494         PlayerState_attach(this);
 495         accuracy_resend(this);
 496
 497         if (this.team < 0)
 498                 JoinBestTeam(this, false, true);
 499
 500         entity spot = SelectSpawnPoint(this, false);
 501         if (!spot) {
 502                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_JOIN_NOSPAWNS);
 503                 return; // spawn failed
 504         }
 505
 506         TRANSMUTE(Player, this);
 507
 508         CS(this).wasplayer = true;
 509         this.iscreature = true;
 510         this.teleportable = TELEPORT_NORMAL;
 511         if(!this.damagedbycontents)
 512                 IL_PUSH(g_damagedbycontents, this);
 513         this.damagedbycontents = true;
 514         set_movetype(this, MOVETYPE_WALK);
 515         this.solid = SOLID_SLIDEBOX;
 516         this.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_SOLID;
 517         if (autocvar_g_playerclip_collisions)
 518                 this.dphitcontentsmask |= DPCONTENTS_PLAYERCLIP;
 519         if (IS_BOT_CLIENT(this) && autocvar_g_botclip_collisions)
 520                 this.dphitcontentsmask |= DPCONTENTS_BOTCLIP;
 521         this.frags = FRAGS_PLAYER;
 522         if (INDEPENDENT_PLAYERS) MAKE_INDEPENDENT_PLAYER(this);
 523         this.flags = FL_CLIENT | FL_PICKUPITEMS;
 524         if (autocvar__notarget)
 525                 this.flags |= FL_NOTARGET;
 526         this.takedamage = DAMAGE_AIM;
 527         this.effects = EF_TELEPORT_BIT | EF_RESTARTANIM_BIT;
 528         this.dmg = 2; // WTF
 529
 530         if (warmup_stage) {
 531                 this.ammo_shells = warmup_start_ammo_shells;
 532                 this.ammo_nails = warmup_start_ammo_nails;
 533                 this.ammo_rockets = warmup_start_ammo_rockets;
 534                 this.ammo_cells = warmup_start_ammo_cells;
 535                 this.ammo_plasma = warmup_start_ammo_plasma;
 536                 this.ammo_fuel = warmup_start_ammo_fuel;
 537                 this.health = warmup_start_health;
 538                 this.armorvalue = warmup_start_armorvalue;
 539                 this.weapons = WARMUP_START_WEAPONS;
 540         } else {
 541                 this.ammo_shells = start_ammo_shells;
 542                 this.ammo_nails = start_ammo_nails;
 543                 this.ammo_rockets = start_ammo_rockets;
 544                 this.ammo_cells = start_ammo_cells;
 545                 this.ammo_plasma = start_ammo_plasma;
 546                 this.ammo_fuel = start_ammo_fuel;
 547                 this.health = start_health;
 548                 this.armorvalue = start_armorvalue;
 549                 this.weapons = start_weapons;
 550                 GiveRandomWeapons(this, random_start_weapons_count,
 551                         cvar_string("g_random_start_weapons"), random_start_ammo);
 552         }
 553         SetSpectatee_status(this, 0);
 554
 555         PS(this).dual_weapons = '0 0 0';
 556
 557         this.superweapons_finished = (this.weapons & WEPSET_SUPERWEAPONS) ? time + autocvar_g_balance_superweapons_time : 0;
 558
 559         this.items = start_items;
 560
 561         this.spawnshieldtime = time + autocvar_g_spawnshieldtime;
 562         this.pauserotarmor_finished = time + autocvar_g_balance_pause_armor_rot_spawn;
 563         this.pauserothealth_finished = time + autocvar_g_balance_pause_health_rot_spawn;
 564         this.pauserotfuel_finished = time + autocvar_g_balance_pause_fuel_rot_spawn;
 565         this.pauseregen_finished = time + autocvar_g_balance_pause_health_regen_spawn;
 566         // extend the pause of rotting if client was reset at the beginning of the countdown
 567         if (!autocvar_sv_ready_restart_after_countdown && time < game_starttime) { // TODO why is this cvar NOTted?
 568                 float f = game_starttime - time;
 569                 this.spawnshieldtime += f;
 570                 this.pauserotarmor_finished += f;
 571                 this.pauserothealth_finished += f;
 572                 this.pauseregen_finished += f;
 573         }
 574         this.damageforcescale = 2;
 575         this.death_time = 0;
 576         this.respawn_flags = 0;
 577         this.respawn_time = 0;
 578         this.stat_respawn_time = 0;
 579         this.scale = autocvar_sv_player_scale;
 580         this.fade_time = 0;
 581         this.pain_frame = 0;
 582         this.pain_finished = 0;
 583         this.pushltime = 0;
 584         setthink(this, func_null); // players have no think function
 585         this.nextthink = 0;
 586         this.dmg_team = 0;
 587         PS(this).ballistics_density = autocvar_g_ballistics_density_player;
 588
 589         this.deadflag = DEAD_NO;
 590
 591         this.angles = spot.angles;
 592         this.angles_z = 0; // never spawn tilted even if the spot says to
 593         if (IS_BOT_CLIENT(this))
 594                 this.v_angle = this.angles;
 595         this.fixangle = true; // turn this way immediately
 596         this.oldvelocity = this.velocity = '0 0 0';
 597         this.avelocity = '0 0 0';
 598         this.punchangle = '0 0 0';
 599         this.punchvector = '0 0 0';
 600
 601         this.strength_finished = 0;
 602         this.invincible_finished = 0;
 603         this.fire_endtime = -1;
 604         this.revive_progress = 0;
 605         this.revival_time = 0;
 606         this.air_finished = time + 12;
 607
 608         entity spawnevent = new_pure(spawnevent);
 609         spawnevent.owner = this;
 610         Net_LinkEntity(spawnevent, false, 0.5, SpawnEvent_Send);
 611
 612         // Cut off any still running player sounds.
 613         stopsound(this, CH_PLAYER_SINGLE);
 614
 615         this.model = "";
 616         FixPlayermodel(this);
 617         this.drawonlytoclient = NULL;
 618
 619         this.viewloc = NULL;
 620
 621         this.crouch = false;
 622         this.view_ofs = STAT(PL_VIEW_OFS, this);
 623         setsize(this, STAT(PL_MIN, this), STAT(PL_MAX, this));
 624         this.spawnorigin = spot.origin;
 625         setorigin(this, spot.origin + '0 0 1' * (1 - this.mins.z - 24));
 626         // don't reset back to last position, even if new position is stuck in solid
 627         this.oldorigin = this.origin;
 628         this.lastteleporttime = time; // prevent insane speeds due to changing origin
 629         if(this.conveyor)
 630                 IL_REMOVE(g_conveyed, this);
 631         this.conveyor = NULL; // prevent conveyors at the previous location from moving a freshly spawned player
 632         this.hud = HUD_NORMAL;
 633
 634         this.event_damage = PlayerDamage;
 635
 636         if(!this.bot_attack)
 637                 IL_PUSH(g_bot_targets, this);
 638         this.bot_attack = true;
 639         if(!this.monster_attack)
 640                 IL_PUSH(g_monster_targets, this);
 641         this.monster_attack = true;
 642         navigation_dynamicgoal_init(this, false);
 643
 644         PHYS_INPUT_BUTTON_ATCK(this) = PHYS_INPUT_BUTTON_JUMP(this) = PHYS_INPUT_BUTTON_ATCK2(this) = false;
 645
 646         if (CS(this).killcount == FRAGS_SPECTATOR) {
 647                 PlayerScore_Clear(this);
 648                 CS(this).killcount = 0;
 649         }
 650
 651         for (int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 652         {
 653                 .entity weaponentity = weaponentities[slot];
 654                 entity oldwep = this.(weaponentity);
 655                 CL_SpawnWeaponentity(this, weaponentity);
 656                 if(oldwep && oldwep.owner == this)
 657                         this.(weaponentity).m_gunalign = oldwep.m_gunalign;
 658         }
 659         this.alpha = default_player_alpha;
 660         this.colormod = '1 1 1' * autocvar_g_player_brightness;
 661         this.exteriorweaponentity.alpha = default_weapon_alpha;
 662
 663         this.speedrunning = false;
 664
 665         target_voicescript_clear(this);
 666
 667         // reset fields the weapons may use
 668         FOREACH(Weapons, true, {
 669                 it.wr_resetplayer(it, this);
 670                         // reload all reloadable weapons
 671                 if (it.spawnflags & WEP_FLAG_RELOADABLE) {
 672                         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 673                         {
 674                                 .entity weaponentity = weaponentities[slot];
 675                                 this.(weaponentity).weapon_load[it.m_id] = it.reloading_ammo;
 676                         }
 677                 }
 678         });
 679
 680         {
 681                 string s = spot.target;
 682                 spot.target = string_null;
 683                 SUB_UseTargets(spot, this, NULL);
 684                 spot.target = s;
 685         }
 686
 687         Unfreeze(this);
 688
 689         MUTATOR_CALLHOOK(PlayerSpawn, this, spot);
 690
 691         if (autocvar_spawn_debug)
 692         {
 693                 sprint(this, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
 694                 delete(spot); // usefull for checking if there are spawnpoints, that let drop through the floor
 695         }
 696
 697         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 698         {
 699                 .entity weaponentity = weaponentities[slot];
 700                 if(slot == 0 || autocvar_g_weaponswitch_debug == 1)
 701                         this.(weaponentity).m_switchweapon = w_getbestweapon(this, weaponentity);
 702                 else
 703                         this.(weaponentity).m_switchweapon = WEP_Null;
 704                 this.(weaponentity).m_weapon = WEP_Null;
 705                 this.(weaponentity).weaponname = "";
 706                 this.(weaponentity).m_switchingweapon = WEP_Null;
 707                 this.(weaponentity).cnt = -1;
 708         }
 709
 710         MUTATOR_CALLHOOK(PlayerWeaponSelect, this);
 711
 712         if (!warmup_stage && !this.alivetime)
 713                 this.alivetime = time;
 714
 715         antilag_clear(this, CS(this));
 716 }
 717
 718 /** Called when a client spawns in the server */
 719 void PutClientInServer(entity this)
 720 {
 721         if (IS_BOT_CLIENT(this)) {
 722                 TRANSMUTE(Player, this);
 723         } else if (IS_REAL_CLIENT(this)) {
 724                 msg_entity = this;
 725                 WriteByte(MSG_ONE, SVC_SETVIEW);
 726                 WriteEntity(MSG_ONE, this);
 727         }
 728         if (game_stopped)
 729                 TRANSMUTE(Observer, this);
 730
 731         SetSpectatee(this, NULL);
 732
 733         // reset player keys
 734         if(PS(this))
 735                 PS(this).itemkeys = 0;
 736
 737         MUTATOR_CALLHOOK(PutClientInServer, this);
 738
 739         if (IS_OBSERVER(this)) {
 740                 PutObserverInServer(this);
 741         } else if (IS_PLAYER(this)) {
 742                 PutPlayerInServer(this);
 743         }
 744 }
 745
 746 void ClientInit_misc(entity this);
 747
 748 // TODO do we need all these fields, or should we stop autodetecting runtime
 749 // changes and just have a console command to update this?
 750 bool ClientInit_SendEntity(entity this, entity to, int sf)
 751 {
 752         WriteHeader(MSG_ENTITY, _ENT_CLIENT_INIT);
 753         return = true;
 754         msg_entity = to;
 755         // MSG_INIT replacement
 756         // TODO: make easier to use
 757         Registry_send_all();
 758         W_PROP_reload(MSG_ONE, to);
 759         ClientInit_misc(this);
 760         MUTATOR_CALLHOOK(Ent_Init);
 761 }
 762 void ClientInit_misc(entity this)
 763 {
 764         int channel = MSG_ONE;
 765         WriteHeader(channel, ENT_CLIENT_INIT);
 766         WriteByte(channel, g_nexball_meter_period * 32);
 767         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[0]));
 768         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[1]));
 769         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[2]));
 770         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[3]));
 771         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[0]));
 772         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[1]));
 773         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[2]));
 774         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[3]));
 775
 776         if(sv_foginterval && world.fog != "")
 777                 WriteString(channel, world.fog);
 778         else
 779                 WriteString(channel, "");
 780         WriteByte(channel, this.count * 255.0); // g_balance_armor_blockpercent
 781         WriteByte(channel, this.cnt * 255.0); // g_balance_damagepush_speedfactor
 782         WriteByte(channel, serverflags);
 783         WriteCoord(channel, autocvar_g_trueaim_minrange);
 784 }
 785
 786 void ClientInit_CheckUpdate(entity this)
 787 {
 788         this.nextthink = time;
 789         if(this.count != autocvar_g_balance_armor_blockpercent)
 790         {
 791                 this.count = autocvar_g_balance_armor_blockpercent;
 792                 this.SendFlags |= 1;
 793         }
 794         if(this.cnt != autocvar_g_balance_damagepush_speedfactor)
 795         {
 796                 this.cnt = autocvar_g_balance_damagepush_speedfactor;
 797                 this.SendFlags |= 1;
 798         }
 799 }
 800
 801 void ClientInit_Spawn()
 802 {
 803         entity e = new_pure(clientinit);
 804         setthink(e, ClientInit_CheckUpdate);
 805         Net_LinkEntity(e, false, 0, ClientInit_SendEntity);
 806
 807         ClientInit_CheckUpdate(e);
 808 }
 809
 810 /*
 811 =============
 812 SetNewParms
 813 =============
 814 */
 815 void SetNewParms ()
 816 {
 817         // initialize parms for a new player
 818         parm1 = -(86400 * 366);
 819
 820         MUTATOR_CALLHOOK(SetNewParms);
 821 }
 822
 823 /*
 824 =============
 825 SetChangeParms
 826 =============
 827 */
 828 void SetChangeParms (entity this)
 829 {
 830         // save parms for level change
 831         parm1 = CS(this).parm_idlesince - time;
 832
 833         MUTATOR_CALLHOOK(SetChangeParms);
 834 }
 835
 836 /*
 837 =============
 838 DecodeLevelParms
 839 =============
 840 */
 841 void DecodeLevelParms(entity this)
 842 {
 843         // load parms
 844         CS(this).parm_idlesince = parm1;
 845         if (CS(this).parm_idlesince == -(86400 * 366))
 846                 CS(this).parm_idlesince = time;
 847
 848         // whatever happens, allow 60 seconds of idling directly after connect for map loading
 849         CS(this).parm_idlesince = max(CS(this).parm_idlesince, time - sv_maxidle + 60);
 850
 851         MUTATOR_CALLHOOK(DecodeLevelParms);
 852 }
 853
 854 /*
 855 =============
 856 ClientKill
 857
 858 Called when a client types 'kill' in the console
 859 =============
 860 */
 861
 862 .float clientkill_nexttime;
 863 void ClientKill_Now_TeamChange(entity this)
 864 {
 865         if(CS(this).killindicator_teamchange == -1)
 866         {
 867                 JoinBestTeam( this, false, true );
 868         }
 869         else if(CS(this).killindicator_teamchange == -2)
 870         {
 871                 if(blockSpectators)
 872                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
 873                 PutObserverInServer(this);
 874         }
 875         else
 876                 SV_ChangeTeam(this, CS(this).killindicator_teamchange - 1);
 877         CS(this).killindicator_teamchange = 0;
 878 }
 879
 880 void ClientKill_Now(entity this)
 881 {
 882         if(this.vehicle)
 883         {
 884             vehicles_exit(this.vehicle, VHEF_RELEASE);
 885             if(!CS(this).killindicator_teamchange)
 886             {
 887             this.vehicle_health = -1;
 888             Damage(this, this, this, 1 , DEATH_KILL.m_id, this.origin, '0 0 0');
 889             }
 890         }
 891
 892         if(this.killindicator && !wasfreed(this.killindicator))
 893                 delete(this.killindicator);
 894
 895         this.killindicator = NULL;
 896
 897         if(CS(this).killindicator_teamchange)
 898                 ClientKill_Now_TeamChange(this);
 899
 900         if (!IS_SPEC(this) && !IS_OBSERVER(this) && MUTATOR_CALLHOOK(ClientKill_Now, this) == false)
 901         {
 902                 Damage(this, this, this, 100000, DEATH_KILL.m_id, this.origin, '0 0 0');
 903         }
 904
 905         // now I am sure the player IS dead
 906 }
 907 void KillIndicator_Think(entity this)
 908 {
 909         if (game_stopped)
 910         {
 911                 this.owner.killindicator = NULL;
 912                 delete(this);
 913                 return;
 914         }
 915
 916         if (this.owner.alpha < 0 && !this.owner.vehicle)
 917         {
 918                 this.owner.killindicator = NULL;
 919                 delete(this);
 920                 return;
 921         }
 922
 923         if(this.cnt <= 0)
 924         {
 925                 ClientKill_Now(this.owner);
 926                 return;
 927         }
 928     else if(this.health == 1) // health == 1 means that it's silent
 929     {
 930         this.nextthink = time + 1;
 931         this.cnt -= 1;
 932     }
 933         else
 934         {
 935                 if(this.cnt <= 10)
 936                         setmodel(this, MDL_NUM(this.cnt));
 937                 if(IS_REAL_CLIENT(this.owner))
 938                 {
 939                         if(this.cnt <= 10)
 940                                 { Send_Notification(NOTIF_ONE, this.owner, MSG_ANNCE, Announcer_PickNumber(CNT_KILL, this.cnt)); }
 941                 }
 942                 this.nextthink = time + 1;
 943                 this.cnt -= 1;
 944         }
 945 }
 946
 947 float clientkilltime;
 948 void ClientKill_TeamChange (entity this, float targetteam) // 0 = don't change, -1 = auto, -2 = spec
 949 {
 950         float killtime;
 951         float starttime;
 952
 953         if (game_stopped)
 954                 return;
 955
 956         killtime = autocvar_g_balance_kill_delay;
 957
 958     if(MUTATOR_CALLHOOK(ClientKill, this, killtime))
 959         return;
 960     killtime = M_ARGV(1, float);
 961
 962         CS(this).killindicator_teamchange = targetteam;
 963
 964     if(!this.killindicator)
 965         {
 966                 if(!IS_DEAD(this))
 967                 {
 968                         killtime = max(killtime, this.clientkill_nexttime - time);
 969                         this.clientkill_nexttime = time + killtime + autocvar_g_balance_kill_antispam;
 970                 }
 971
 972                 if(killtime <= 0 || !IS_PLAYER(this) || IS_DEAD(this))
 973                 {
 974                         ClientKill_Now(this);
 975                 }
 976                 else
 977                 {
 978                         starttime = max(time, clientkilltime);
 979
 980                         this.killindicator = spawn();
 981                         this.killindicator.owner = this;
 982                         this.killindicator.scale = 0.5;
 983                         setattachment(this.killindicator, this, "");
 984                         setorigin(this.killindicator, '0 0 52');
 985                         setthink(this.killindicator, KillIndicator_Think);
 986                         this.killindicator.nextthink = starttime + (this.lip) * 0.05;
 987                         clientkilltime = max(clientkilltime, this.killindicator.nextthink + 0.05);
 988                         this.killindicator.cnt = ceil(killtime);
 989                         this.killindicator.count = bound(0, ceil(killtime), 10);
 990                         //sprint(this, strcat("^1You'll be dead in ", ftos(this.killindicator.cnt), " seconds\n"));
 991
 992                         IL_EACH(g_clones, it.enemy == this && !(it.effects & CSQCMODEL_EF_RESPAWNGHOST),
 993                         {
 994                                 it.killindicator = spawn();
 995                                 it.killindicator.owner = it;
 996                                 it.killindicator.scale = 0.5;
 997                                 setattachment(it.killindicator, it, "");
 998                                 setorigin(it.killindicator, '0 0 52');
 999                                 setthink(it.killindicator, KillIndicator_Think);
1000                                 it.killindicator.nextthink = starttime + (it.lip) * 0.05;
1001                                 //clientkilltime = max(clientkilltime, it.killindicator.nextthink + 0.05);
1002                                 it.killindicator.cnt = ceil(killtime);
1003                         });
1004                         this.lip = 0;
1005                 }
1006         }
1007         if(this.killindicator)
1008         {
1009                 if(targetteam == 0) // just die
1010                 {
1011                         this.killindicator.colormod = '0 0 0';
1012                         if(IS_REAL_CLIENT(this))
1013                         if(this.killindicator.cnt > 0)
1014                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_TEAMCHANGE_SUICIDE, this.killindicator.cnt);
1015                 }
1016                 else if(targetteam == -1) // auto
1017                 {
1018                         this.killindicator.colormod = '0 1 0';
1019                         if(IS_REAL_CLIENT(this))
1020                         if(this.killindicator.cnt > 0)
1021                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_TEAMCHANGE_AUTO, this.killindicator.cnt);
1022                 }
1023                 else if(targetteam == -2) // spectate
1024                 {
1025                         this.killindicator.colormod = '0.5 0.5 0.5';
1026                         if(IS_REAL_CLIENT(this))
1027                         if(this.killindicator.cnt > 0)
1028                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_TEAMCHANGE_SPECTATE, this.killindicator.cnt);
1029                 }
1030                 else
1031                 {
1032                         this.killindicator.colormod = Team_ColorRGB(targetteam);
1033                         if(IS_REAL_CLIENT(this))
1034                         if(this.killindicator.cnt > 0)
1035                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, APP_TEAM_NUM(targetteam, CENTER_TEAMCHANGE), this.killindicator.cnt);
1036                 }
1037         }
1038
1039 }
1040
1041 void ClientKill (entity this)
1042 {
1043         if(game_stopped) return;
1044         if(this.player_blocked) return;
1045         if(STAT(FROZEN, this)) return;
1046
1047         ClientKill_TeamChange(this, 0);
1048 }
1049
1050 void FixClientCvars(entity e)
1051 {
1052         // send prediction settings to the client
1053         stuffcmd(e, "\nin_bindmap 0 0\n");
1054         if(autocvar_g_antilag == 3) // client side hitscan
1055                 stuffcmd(e, "cl_cmd settemp cl_prydoncursor_notrace 0\n");
1056         if(autocvar_sv_gentle)
1057                 stuffcmd(e, "cl_cmd settemp cl_gentle 1\n");
1058
1059         stuffcmd(e, sprintf("\ncl_jumpspeedcap_min \"%s\"\n", autocvar_sv_jumpspeedcap_min));
1060         stuffcmd(e, sprintf("\ncl_jumpspeedcap_max \"%s\"\n", autocvar_sv_jumpspeedcap_max));
1061
1062         MUTATOR_CALLHOOK(FixClientCvars, e);
1063 }
1064
1065 bool findinlist_abbrev(string tofind, string list)
1066 {
1067         if(list == "" || tofind == "")
1068                 return false; // empty list or search, just return
1069
1070         // this function allows abbreviated strings!
1071         FOREACH_WORD(list, it == substring(tofind, 0, strlen(it)),
1072         {
1073                 return true;
1074         });
1075
1076         return false;
1077 }
1078
1079 bool PlayerInIPList(entity p, string iplist)
1080 {
1081         // some safety checks (never allow local?)
1082         if(p.netaddress == "local" || p.netaddress == "" || !IS_REAL_CLIENT(p))
1083                 return false;
1084
1085         return findinlist_abbrev(p.netaddress, iplist);
1086 }
1087
1088 bool PlayerInIDList(entity p, string idlist)
1089 {
1090         // NOTE: we do NOT check crypto_idfp_signed here, an unsigned ID is fine too for this
1091         if(!p.crypto_idfp)
1092                 return false;
1093
1094         return findinlist_abbrev(p.crypto_idfp, idlist);
1095 }
1096
1097 bool PlayerInList(entity player, string list)
1098 {
1099         return boolean(PlayerInIDList(player, list) || PlayerInIPList(player, list));
1100 }
1101
1102 #ifdef DP_EXT_PRECONNECT
1103 /*
1104 =============
1105 ClientPreConnect
1106
1107 Called once (not at each match start) when a client begins a connection to the server
1108 =============
1109 */
1110 void ClientPreConnect(entity this)
1111 {
1112         if(autocvar_sv_eventlog)
1113         {
1114                 GameLogEcho(sprintf(":connect:%d:%d:%s",
1115                         this.playerid,
1116                         etof(this),
1117                         ((IS_REAL_CLIENT(this)) ? this.netaddress : "bot")
1118                 ));
1119         }
1120 }
1121 #endif
1122
1123 /**
1124 =============
1125 ClientConnect
1126
1127 Called when a client connects to the server
1128 =============
1129 */
1130 void ClientConnect(entity this)
1131 {
1132         if (Ban_MaybeEnforceBanOnce(this)) return;
1133         assert(!IS_CLIENT(this), return);
1134         this.flags |= FL_CLIENT;
1135         assert(player_count >= 0, player_count = 0);
1136
1137 #ifdef WATERMARK
1138         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_WATERMARK, WATERMARK);
1139 #endif
1140         TRANSMUTE(Client, this);
1141         CS(this).version_nagtime = time + 10 + random() * 10;
1142
1143         // identify the right forced team
1144         if (autocvar_g_campaign)
1145         {
1146                 if (IS_REAL_CLIENT(this)) // only players, not bots
1147                 {
1148                         switch (autocvar_g_campaign_forceteam)
1149                         {
1150                                 case 1: this.team_forced = NUM_TEAM_1; break;
1151                                 case 2: this.team_forced = NUM_TEAM_2; break;
1152                                 case 3: this.team_forced = NUM_TEAM_3; break;
1153                                 case 4: this.team_forced = NUM_TEAM_4; break;
1154                                 default: this.team_forced = 0;
1155                         }
1156                 }
1157         }
1158         else if (PlayerInList(this, autocvar_g_forced_team_red))    this.team_forced = NUM_TEAM_1;
1159         else if (PlayerInList(this, autocvar_g_forced_team_blue))   this.team_forced = NUM_TEAM_2;
1160         else if (PlayerInList(this, autocvar_g_forced_team_yellow)) this.team_forced = NUM_TEAM_3;
1161         else if (PlayerInList(this, autocvar_g_forced_team_pink))   this.team_forced = NUM_TEAM_4;
1162         else switch (autocvar_g_forced_team_otherwise)
1163         {
1164                 default: this.team_forced = 0; break;
1165                 case "red": this.team_forced = NUM_TEAM_1; break;
1166                 case "blue": this.team_forced = NUM_TEAM_2; break;
1167                 case "yellow": this.team_forced = NUM_TEAM_3; break;
1168                 case "pink": this.team_forced = NUM_TEAM_4; break;
1169                 case "spectate":
1170                 case "spectator":
1171                         this.team_forced = -1;
1172                         break;
1173         }
1174         if (!teamplay && this.team_forced > 0) this.team_forced = 0;
1175
1176     {
1177         int id = this.playerid;
1178         this.playerid = 0; // silent
1179             JoinBestTeam(this, false, false); // if the team number is valid, keep it
1180             this.playerid = id;
1181     }
1182
1183         if (autocvar_sv_spectate || autocvar_g_campaign || this.team_forced < 0) {
1184                 TRANSMUTE(Observer, this);
1185         } else {
1186                 if (!teamplay || autocvar_g_balance_teams) {
1187                         TRANSMUTE(Player, this);
1188                         campaign_bots_may_start = true;
1189                 } else {
1190                         TRANSMUTE(Observer, this); // do it anyway
1191                 }
1192         }
1193
1194         PlayerStats_GameReport_AddEvent(sprintf("kills-%d", this.playerid));
1195
1196         // always track bots, don't ask for cl_allow_uidtracking
1197         if (IS_BOT_CLIENT(this))
1198                 PlayerStats_GameReport_AddPlayer(this);
1199         else
1200                 CS(this).allowed_timeouts = autocvar_sv_timeout_number;
1201
1202         if (autocvar_sv_eventlog)
1203                 GameLogEcho(strcat(":join:", ftos(this.playerid), ":", ftos(etof(this)), ":", ((IS_REAL_CLIENT(this)) ? this.netaddress : "bot"), ":", playername(this, false)));
1204
1205         LogTeamchange(this.playerid, this.team, 1);
1206
1207         CS(this).just_joined = true;  // stop spamming the eventlog with additional lines when the client connects
1208
1209         CS(this).netname_previous = strzone(this.netname);
1210
1211         if(teamplay && IS_PLAYER(this))
1212                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, APP_TEAM_NUM(this.team, INFO_JOIN_CONNECT_TEAM), this.netname);
1213         else
1214                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_JOIN_CONNECT, this.netname);
1215
1216         stuffcmd(this, clientstuff, "\n");
1217         stuffcmd(this, "cl_particles_reloadeffects\n"); // TODO do we still need this?
1218
1219         FixClientCvars(this);
1220
1221         // get version info from player
1222         stuffcmd(this, "cmd clientversion $gameversion\n");
1223
1224         // notify about available teams
1225         if (teamplay)
1226         {
1227                 CheckAllowedTeams(this);
1228                 int t = 0;
1229                 if (c1 >= 0) t |= BIT(0);
1230                 if (c2 >= 0) t |= BIT(1);
1231                 if (c3 >= 0) t |= BIT(2);
1232                 if (c4 >= 0) t |= BIT(3);
1233                 stuffcmd(this, sprintf("set _teams_available %d\n", t));
1234         }
1235         else
1236         {
1237                 stuffcmd(this, "set _teams_available 0\n");
1238         }
1239
1240         bot_relinkplayerlist();
1241
1242         CS(this).spectatortime = time;
1243         if (blockSpectators)
1244         {
1245                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
1246         }
1247
1248         CS(this).jointime = time;
1249
1250         if (IS_REAL_CLIENT(this))
1251         {
1252                 if (g_weaponarena_weapons == WEPSET(TUBA))
1253                         stuffcmd(this, "cl_cmd settemp chase_active 1\n");
1254         }
1255
1256         if (!sv_foginterval && world.fog != "")
1257                 stuffcmd(this, strcat("\nfog ", world.fog, "\nr_fog_exp2 0\nr_drawfog 1\n"));
1258
1259         if (autocvar_sv_teamnagger && !(autocvar_bot_vs_human && AvailableTeams() == 2))
1260                 if(!MUTATOR_CALLHOOK(HideTeamNagger, this))
1261                         send_CSQC_teamnagger();
1262
1263         CSQCMODEL_AUTOINIT(this);
1264
1265         CS(this).model_randomizer = random();
1266
1267         if (IS_REAL_CLIENT(this))
1268                 sv_notice_join(this);
1269
1270         // update physics stats (players can spawn before physics runs)
1271         Physics_UpdateStats(this);
1272
1273         IL_EACH(g_initforplayer, it.init_for_player, {
1274                 it.init_for_player(it, this);
1275         });
1276
1277         MUTATOR_CALLHOOK(ClientConnect, this);
1278
1279         if (IS_REAL_CLIENT(this))
1280         {
1281                 if (!autocvar_g_campaign && !IS_PLAYER(this))
1282                 {
1283                         CS(this).motd_actived_time = -1;
1284                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOTD, getwelcomemessage(this));
1285                 }
1286         }
1287 }
1288 /*
1289 =============
1290 ClientDisconnect
1291
1292 Called when a client disconnects from the server
1293 =============
1294 */
1295 .entity chatbubbleentity;
1296 void ReadyCount();
1297 void ClientDisconnect(entity this)
1298 {
1299         assert(IS_CLIENT(this), return);
1300
1301         PlayerStats_GameReport_FinalizePlayer(this);
1302         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
1303         if (CS(this).active_minigame) part_minigame(this);
1304         if (IS_PLAYER(this)) Send_Effect(EFFECT_SPAWN_NEUTRAL, this.origin, '0 0 0', 1);
1305
1306         if (autocvar_sv_eventlog)
1307                 GameLogEcho(strcat(":part:", ftos(this.playerid)));
1308
1309         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_QUIT_DISCONNECT, this.netname);
1310
1311         if(IS_SPEC(this))
1312                 SetSpectatee(this, NULL);
1313
1314     MUTATOR_CALLHOOK(ClientDisconnect, this);
1315
1316         if (CS(this).netname_previous) strunzone(CS(this).netname_previous); // needs to be before the CS entity is removed!
1317         ClientState_detach(this);
1318
1319         Portal_ClearAll(this);
1320
1321         Unfreeze(this);
1322
1323         RemoveGrapplingHooks(this);
1324
1325         // Here, everything has been done that requires this player to be a client.
1326
1327         this.flags &= ~FL_CLIENT;
1328
1329         if (this.chatbubbleentity) delete(this.chatbubbleentity);
1330         if (this.killindicator) delete(this.killindicator);
1331
1332         WaypointSprite_PlayerGone(this);
1333
1334         bot_relinkplayerlist();
1335
1336         if (this.clientstatus) strunzone(this.clientstatus);
1337         if (this.weaponorder_byimpulse) strunzone(this.weaponorder_byimpulse);
1338         if (this.personal) delete(this.personal);
1339
1340         this.playerid = 0;
1341         ReadyCount();
1342         if (vote_called && IS_REAL_CLIENT(this)) VoteCount(false);
1343
1344         ONREMOVE(this);
1345 }
1346
1347 void ChatBubbleThink(entity this)
1348 {
1349         this.nextthink = time;
1350         if ((this.owner.alpha < 0) || this.owner.chatbubbleentity != this)
1351         {
1352                 if(this.owner) // but why can that ever be NULL?
1353                         this.owner.chatbubbleentity = NULL;
1354                 delete(this);
1355                 return;
1356         }
1357
1358         this.mdl = "";
1359
1360         if ( !IS_DEAD(this.owner) && IS_PLAYER(this.owner) )
1361         {
1362                 if ( CS(this.owner).active_minigame )
1363                         this.mdl = "models/sprites/minigame_busy.iqm";
1364                 else if (PHYS_INPUT_BUTTON_CHAT(this.owner))
1365                         this.mdl = "models/misc/chatbubble.spr";
1366         }
1367
1368         if ( this.model != this.mdl )
1369                 _setmodel(this, this.mdl);
1370
1371 }
1372
1373 void UpdateChatBubble(entity this)
1374 {
1375         if (this.alpha < 0)
1376                 return;
1377         // spawn a chatbubble entity if needed
1378         if (!this.chatbubbleentity)
1379         {
1380                 this.chatbubbleentity = new(chatbubbleentity);
1381                 this.chatbubbleentity.owner = this;
1382                 this.chatbubbleentity.exteriormodeltoclient = this;
1383                 setthink(this.chatbubbleentity, ChatBubbleThink);
1384                 this.chatbubbleentity.nextthink = time;
1385                 setmodel(this.chatbubbleentity, MDL_CHAT); // precision set below
1386                 //setorigin(this.chatbubbleentity, this.origin + '0 0 15' + this.maxs_z * '0 0 1');
1387                 setorigin(this.chatbubbleentity, '0 0 15' + this.maxs_z * '0 0 1');
1388                 setattachment(this.chatbubbleentity, this, "");  // sticks to moving player better, also conserves bandwidth
1389                 this.chatbubbleentity.mdl = this.chatbubbleentity.model;
1390                 //this.chatbubbleentity.model = "";
1391                 this.chatbubbleentity.effects = EF_LOWPRECISION;
1392         }
1393 }
1394
1395
1396 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
1397 // added to the model skins
1398 /*void UpdateColorModHack()
1399 {
1400         float c;
1401         c = this.clientcolors & 15;
1402         // LordHavoc: only bothering to support white, green, red, yellow, blue
1403              if (!teamplay) this.colormod = '0 0 0';
1404         else if (c ==  0) this.colormod = '1.00 1.00 1.00';
1405         else if (c ==  3) this.colormod = '0.10 1.73 0.10';
1406         else if (c ==  4) this.colormod = '1.73 0.10 0.10';
1407         else if (c == 12) this.colormod = '1.22 1.22 0.10';
1408         else if (c == 13) this.colormod = '0.10 0.10 1.73';
1409         else this.colormod = '1 1 1';
1410 }*/
1411
1412 void respawn(entity this)
1413 {
1414         if(this.alpha >= 0 && autocvar_g_respawn_ghosts)
1415         {
1416                 this.solid = SOLID_NOT;
1417                 this.takedamage = DAMAGE_NO;
1418                 set_movetype(this, MOVETYPE_FLY);
1419                 this.velocity = '0 0 1' * autocvar_g_respawn_ghosts_speed;
1420                 this.avelocity = randomvec() * autocvar_g_respawn_ghosts_speed * 3 - randomvec() * autocvar_g_respawn_ghosts_speed * 3;
1421                 this.effects |= CSQCMODEL_EF_RESPAWNGHOST;
1422                 Send_Effect(EFFECT_RESPAWN_GHOST, this.origin, '0 0 0', 1);
1423                 if(autocvar_g_respawn_ghosts_maxtime)
1424                         SUB_SetFade (this, time + autocvar_g_respawn_ghosts_maxtime / 2 + random () * (autocvar_g_respawn_ghosts_maxtime - autocvar_g_respawn_ghosts_maxtime / 2), 1.5);
1425         }
1426
1427         CopyBody(this, 1);
1428
1429         this.effects |= EF_NODRAW; // prevent another CopyBody
1430         PutClientInServer(this);
1431 }
1432
1433 void play_countdown(entity this, float finished, Sound samp)
1434 {
1435     TC(Sound, samp);
1436         if(IS_REAL_CLIENT(this))
1437                 if(floor(finished - time - frametime) != floor(finished - time))
1438                         if(finished - time < 6)
1439                                 sound (this, CH_INFO, samp, VOL_BASE, ATTEN_NORM);
1440 }
1441
1442 void player_powerups(entity this)
1443 {
1444         // add a way to see what the items were BEFORE all of these checks for the mutator hook
1445         int items_prev = this.items;
1446
1447         if((this.items & IT_USING_JETPACK) && !IS_DEAD(this) && !game_stopped)
1448                 this.modelflags |= MF_ROCKET;
1449         else
1450                 this.modelflags &= ~MF_ROCKET;
1451
1452         this.effects &= ~(EF_RED | EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT | EF_FLAME | EF_NODEPTHTEST);
1453
1454         if((this.alpha < 0 || IS_DEAD(this)) && !this.vehicle) // don't apply the flags if the player is gibbed
1455                 return;
1456
1457         Fire_ApplyDamage(this);
1458         Fire_ApplyEffect(this);
1459
1460         if (!g_instagib)
1461         {
1462                 if (this.items & ITEM_Strength.m_itemid)
1463                 {
1464                         play_countdown(this, this.strength_finished, SND_POWEROFF);
1465                         this.effects = this.effects | (EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT);
1466                         if (time > this.strength_finished)
1467                         {
1468                                 this.items = this.items - (this.items & ITEM_Strength.m_itemid);
1469                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERDOWN_STRENGTH, this.netname);
1470                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERDOWN_STRENGTH);
1471                         }
1472                 }
1473                 else
1474                 {
1475                         if (time < this.strength_finished)
1476                         {
1477                                 this.items = this.items | ITEM_Strength.m_itemid;
1478                                 if(!g_cts)
1479                                         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERUP_STRENGTH, this.netname);
1480                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERUP_STRENGTH);
1481                         }
1482                 }
1483                 if (this.items & ITEM_Shield.m_itemid)
1484                 {
1485                         play_countdown(this, this.invincible_finished, SND_POWEROFF);
1486                         this.effects = this.effects | (EF_RED | EF_ADDITIVE | EF_FULLBRIGHT);
1487                         if (time > this.invincible_finished)
1488                         {
1489                                 this.items = this.items - (this.items & ITEM_Shield.m_itemid);
1490                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERDOWN_SHIELD, this.netname);
1491                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERDOWN_SHIELD);
1492                         }
1493                 }
1494                 else
1495                 {
1496                         if (time < this.invincible_finished)
1497                         {
1498                                 this.items = this.items | ITEM_Shield.m_itemid;
1499                                 if(!g_cts)
1500                                         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERUP_SHIELD, this.netname);
1501                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERUP_SHIELD);
1502                         }
1503                 }
1504                 if (this.items & IT_SUPERWEAPON)
1505                 {
1506                         if (!(this.weapons & WEPSET_SUPERWEAPONS))
1507                         {
1508                                 this.superweapons_finished = 0;
1509                                 this.items = this.items - (this.items & IT_SUPERWEAPON);
1510                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_LOST, this.netname);
1511                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_LOST);
1512                         }
1513                         else if (this.items & IT_UNLIMITED_SUPERWEAPONS)
1514                         {
1515                                 // don't let them run out
1516                         }
1517                         else
1518                         {
1519                                 play_countdown(this, this.superweapons_finished, SND_POWEROFF);
1520                                 if (time > this.superweapons_finished)
1521                                 {
1522                                         this.items = this.items - (this.items & IT_SUPERWEAPON);
1523                                         this.weapons &= ~WEPSET_SUPERWEAPONS;
1524                                         //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_BROKEN, this.netname);
1525                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_BROKEN);
1526                                 }
1527                         }
1528                 }
1529                 else if(this.weapons & WEPSET_SUPERWEAPONS)
1530                 {
1531                         if (time < this.superweapons_finished || (this.items & IT_UNLIMITED_SUPERWEAPONS))
1532                         {
1533                                 this.items = this.items | IT_SUPERWEAPON;
1534                                 if(!g_cts)
1535                                         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_PICKUP, this.netname);
1536                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_PICKUP);
1537                         }
1538                         else
1539                         {
1540                                 this.superweapons_finished = 0;
1541                                 this.weapons &= ~WEPSET_SUPERWEAPONS;
1542                         }
1543                 }
1544                 else
1545                 {
1546                         this.superweapons_finished = 0;
1547                 }
1548         }
1549
1550         if(autocvar_g_nodepthtestplayers)
1551                 this.effects = this.effects | EF_NODEPTHTEST;
1552
1553         if(autocvar_g_fullbrightplayers)
1554                 this.effects = this.effects | EF_FULLBRIGHT;
1555
1556         if (time >= game_starttime)
1557         if (time < this.spawnshieldtime)
1558                 this.effects = this.effects | (EF_ADDITIVE | EF_FULLBRIGHT);
1559
1560         MUTATOR_CALLHOOK(PlayerPowerups, this, items_prev);
1561 }
1562
1563 float CalcRegen(float current, float stable, float regenfactor, float regenframetime)
1564 {
1565         if(current > stable)
1566                 return current;
1567         else if(current > stable - 0.25) // when close enough, "snap"
1568                 return stable;
1569         else
1570                 return min(stable, current + (stable - current) * regenfactor * regenframetime);
1571 }
1572
1573 float CalcRot(float current, float stable, float rotfactor, float rotframetime)
1574 {
1575         if(current < stable)
1576                 return current;
1577         else if(current < stable + 0.25) // when close enough, "snap"
1578                 return stable;
1579         else
1580                 return max(stable, current + (stable - current) * rotfactor * rotframetime);
1581 }
1582
1583 float CalcRotRegen(float current, float regenstable, float regenfactor, float regenlinear, float regenframetime, float rotstable, float rotfactor, float rotlinear, float rotframetime, float limit)
1584 {
1585         if(current > rotstable)
1586         {
1587                 if(rotframetime > 0)
1588                 {
1589                         current = CalcRot(current, rotstable, rotfactor, rotframetime);
1590                         current = max(rotstable, current - rotlinear * rotframetime);
1591                 }
1592         }
1593         else if(current < regenstable)
1594         {
1595                 if(regenframetime > 0)
1596                 {
1597                         current = CalcRegen(current, regenstable, regenfactor, regenframetime);
1598                         current = min(regenstable, current + regenlinear * regenframetime);
1599                 }
1600         }
1601
1602         if(current > limit)
1603                 current = limit;
1604
1605         return current;
1606 }
1607
1608 void player_regen(entity this)
1609 {
1610         float max_mod, regen_mod, rot_mod, limit_mod;
1611         max_mod = regen_mod = rot_mod = limit_mod = 1;
1612
1613         float regen_health = autocvar_g_balance_health_regen;
1614         float regen_health_linear = autocvar_g_balance_health_regenlinear;
1615         float regen_health_rot = autocvar_g_balance_health_rot;
1616         float regen_health_rotlinear = autocvar_g_balance_health_rotlinear;
1617         float regen_health_stable = autocvar_g_balance_health_regenstable;
1618         float regen_health_rotstable = autocvar_g_balance_health_rotstable;
1619         bool mutator_returnvalue = MUTATOR_CALLHOOK(PlayerRegen, this, max_mod, regen_mod, rot_mod, limit_mod, regen_health, regen_health_linear, regen_health_rot,
1620                 regen_health_rotlinear, regen_health_stable, regen_health_rotstable);
1621         max_mod = M_ARGV(1, float);
1622         regen_mod = M_ARGV(2, float);
1623         rot_mod = M_ARGV(3, float);
1624         limit_mod = M_ARGV(4, float);
1625         regen_health = M_ARGV(5, float);
1626         regen_health_linear = M_ARGV(6, float);
1627         regen_health_rot = M_ARGV(7, float);
1628         regen_health_rotlinear = M_ARGV(8, float);
1629         regen_health_stable = M_ARGV(9, float);
1630         regen_health_rotstable = M_ARGV(10, float);
1631
1632         if(!mutator_returnvalue)
1633         if(!STAT(FROZEN, this))
1634         {
1635                 float mina, maxa, limith, limita;
1636                 maxa = autocvar_g_balance_armor_rotstable;
1637                 mina = autocvar_g_balance_armor_regenstable;
1638                 limith = GetResourceLimit(this, RESOURCE_HEALTH);
1639                 limita = GetResourceLimit(this, RESOURCE_ARMOR);
1640
1641                 regen_health_rotstable = regen_health_rotstable * max_mod;
1642                 regen_health_stable = regen_health_stable * max_mod;
1643                 limith = limith * limit_mod;
1644                 limita = limita * limit_mod;
1645
1646                 this.armorvalue = CalcRotRegen(this.armorvalue, mina, autocvar_g_balance_armor_regen, autocvar_g_balance_armor_regenlinear, regen_mod * frametime * (time > this.pauseregen_finished), maxa, autocvar_g_balance_armor_rot, autocvar_g_balance_armor_rotlinear, rot_mod * frametime * (time > this.pauserotarmor_finished), limita);
1647                 this.health = CalcRotRegen(this.health, regen_health_stable, regen_health, regen_health_linear, regen_mod * frametime * (time > this.pauseregen_finished), regen_health_rotstable, regen_health_rot, regen_health_rotlinear, rot_mod * frametime * (time > this.pauserothealth_finished), limith);
1648         }
1649
1650         // if player rotted to death...  die!
1651         // check this outside above checks, as player may still be able to rot to death
1652         if(this.health < 1)
1653         {
1654                 if(this.vehicle)
1655                         vehicles_exit(this.vehicle, VHEF_RELEASE);
1656                 if(this.event_damage)
1657                         this.event_damage(this, this, this, 1, DEATH_ROT.m_id, this.origin, '0 0 0');
1658         }
1659
1660         if (!(this.items & IT_UNLIMITED_WEAPON_AMMO))
1661         {
1662                 float minf, maxf, limitf;
1663
1664                 maxf = autocvar_g_balance_fuel_rotstable;
1665                 minf = autocvar_g_balance_fuel_regenstable;
1666                 limitf = GetResourceLimit(this, RESOURCE_FUEL);
1667
1668                 this.ammo_fuel = CalcRotRegen(this.ammo_fuel, minf, autocvar_g_balance_fuel_regen, autocvar_g_balance_fuel_regenlinear, frametime * (time > this.pauseregen_finished) * ((this.items & ITEM_JetpackRegen.m_itemid) != 0), maxf, autocvar_g_balance_fuel_rot, autocvar_g_balance_fuel_rotlinear, frametime * (time > this.pauserotfuel_finished), limitf);
1669         }
1670         // Ugly hack to make sure the health and armor don't go beyond hard limit.
1671         // TODO: Remove this hack when all code uses GivePlayerHealth and
1672         // GivePlayerArmor.
1673         if (this.health > RESOURCE_AMOUNT_HARD_LIMIT)
1674         {
1675                 this.health = RESOURCE_AMOUNT_HARD_LIMIT;
1676         }
1677         if (this.armorvalue > RESOURCE_AMOUNT_HARD_LIMIT)
1678         {
1679                 this.armorvalue = RESOURCE_AMOUNT_HARD_LIMIT;
1680         }
1681         // End hack.
1682 }
1683
1684 bool zoomstate_set;
1685 void SetZoomState(entity this, float newzoom)
1686 {
1687         if(newzoom != CS(this).zoomstate)
1688         {
1689                 CS(this).zoomstate = newzoom;
1690                 ClientData_Touch(this);
1691         }
1692         zoomstate_set = true;
1693 }
1694
1695 void GetPressedKeys(entity this)
1696 {
1697         MUTATOR_CALLHOOK(GetPressedKeys, this);
1698         int keys = STAT(PRESSED_KEYS, this);
1699         keys = BITSET(keys, KEY_FORWARD,        CS(this).movement.x > 0);
1700         keys = BITSET(keys, KEY_BACKWARD,       CS(this).movement.x < 0);
1701         keys = BITSET(keys, KEY_RIGHT,          CS(this).movement.y > 0);
1702         keys = BITSET(keys, KEY_LEFT,           CS(this).movement.y < 0);
1703
1704         keys = BITSET(keys, KEY_JUMP,           PHYS_INPUT_BUTTON_JUMP(this));
1705         keys = BITSET(keys, KEY_CROUCH,         PHYS_INPUT_BUTTON_CROUCH(this));
1706         keys = BITSET(keys, KEY_ATCK,           PHYS_INPUT_BUTTON_ATCK(this));
1707         keys = BITSET(keys, KEY_ATCK2,          PHYS_INPUT_BUTTON_ATCK2(this));
1708         CS(this).pressedkeys = keys; // store for other users
1709
1710         STAT(PRESSED_KEYS, this) = keys;
1711 }
1712
1713 /*
1714 ======================
1715 spectate mode routines
1716 ======================
1717 */
1718
1719 void SpectateCopy(entity this, entity spectatee)
1720 {
1721     TC(Client, this); TC(Client, spectatee);
1722
1723         MUTATOR_CALLHOOK(SpectateCopy, spectatee, this);
1724         PS(this) = PS(spectatee);
1725         this.armortype = spectatee.armortype;
1726         this.armorvalue = spectatee.armorvalue;
1727         this.ammo_cells = spectatee.ammo_cells;
1728         this.ammo_plasma = spectatee.ammo_plasma;
1729         this.ammo_shells = spectatee.ammo_shells;
1730         this.ammo_nails = spectatee.ammo_nails;
1731         this.ammo_rockets = spectatee.ammo_rockets;
1732         this.ammo_fuel = spectatee.ammo_fuel;
1733         this.clip_load = spectatee.clip_load;
1734         this.clip_size = spectatee.clip_size;
1735         this.effects = spectatee.effects & EFMASK_CHEAP; // eat performance
1736         this.health = spectatee.health;
1737         CS(this).impulse = 0;
1738         this.items = spectatee.items;
1739         this.last_pickup = spectatee.last_pickup;
1740         this.hit_time = spectatee.hit_time;
1741         this.strength_finished = spectatee.strength_finished;
1742         this.invincible_finished = spectatee.invincible_finished;
1743         this.superweapons_finished = spectatee.superweapons_finished;
1744         STAT(PRESSED_KEYS, this) = STAT(PRESSED_KEYS, spectatee);
1745         this.weapons = spectatee.weapons;
1746         this.vortex_charge = spectatee.vortex_charge;
1747         this.vortex_chargepool_ammo = spectatee.vortex_chargepool_ammo;
1748         this.hagar_load = spectatee.hagar_load;
1749         this.arc_heat_percent = spectatee.arc_heat_percent;
1750         this.minelayer_mines = spectatee.minelayer_mines;
1751         this.punchangle = spectatee.punchangle;
1752         this.view_ofs = spectatee.view_ofs;
1753         this.velocity = spectatee.velocity;
1754         this.dmg_take = spectatee.dmg_take;
1755         this.dmg_save = spectatee.dmg_save;
1756         this.dmg_inflictor = spectatee.dmg_inflictor;
1757         this.v_angle = spectatee.v_angle;
1758         this.angles = spectatee.v_angle;
1759         STAT(FROZEN, this) = STAT(FROZEN, spectatee);
1760         this.revive_progress = spectatee.revive_progress;
1761         this.viewloc = spectatee.viewloc;
1762         if(!PHYS_INPUT_BUTTON_USE(this) && STAT(CAMERA_SPECTATOR, this) != 2)
1763                 this.fixangle = true;
1764         setorigin(this, spectatee.origin);
1765         setsize(this, spectatee.mins, spectatee.maxs);
1766         SetZoomState(this, CS(spectatee).zoomstate);
1767
1768         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1769         {
1770                 .entity weaponentity = weaponentities[slot];
1771                 this.(weaponentity) = spectatee.(weaponentity);
1772         }
1773
1774         for(int slot = 0; slot < MAX_AXH; ++slot)
1775         {
1776                 this.(AuxiliaryXhair[slot]) = spectatee.(AuxiliaryXhair[slot]);
1777         }
1778
1779     anticheat_spectatecopy(this, spectatee);
1780         this.hud = spectatee.hud;
1781         if(spectatee.vehicle)
1782     {
1783         this.angles = spectatee.v_angle;
1784
1785         //this.fixangle = false;
1786         //this.velocity = spectatee.vehicle.velocity;
1787         this.vehicle_health = spectatee.vehicle_health;
1788         this.vehicle_shield = spectatee.vehicle_shield;
1789         this.vehicle_energy = spectatee.vehicle_energy;
1790         this.vehicle_ammo1 = spectatee.vehicle_ammo1;
1791         this.vehicle_ammo2 = spectatee.vehicle_ammo2;
1792         this.vehicle_reload1 = spectatee.vehicle_reload1;
1793         this.vehicle_reload2 = spectatee.vehicle_reload2;
1794
1795         //msg_entity = this;
1796
1797        // WriteByte (MSG_ONE, SVC_SETVIEWANGLES);
1798             //WriteAngle(MSG_ONE,  spectatee.v_angle.x);
1799            // WriteAngle(MSG_ONE,  spectatee.v_angle.y);
1800            // WriteAngle(MSG_ONE,  spectatee.v_angle.z);
1801
1802         //WriteByte (MSG_ONE, SVC_SETVIEW);
1803         //    WriteEntity(MSG_ONE, this);
1804         //makevectors(spectatee.v_angle);
1805         //setorigin(this, spectatee.origin - v_forward * 400 + v_up * 300);*/
1806     }
1807 }
1808
1809 bool SpectateUpdate(entity this)
1810 {
1811         if(!this.enemy)
1812                 return false;
1813
1814         if(!IS_PLAYER(this.enemy) || this == this.enemy)
1815         {
1816                 SetSpectatee(this, NULL);
1817                 return false;
1818         }
1819
1820         SpectateCopy(this, this.enemy);
1821
1822         return true;
1823 }
1824
1825 bool SpectateSet(entity this)
1826 {
1827         if(!IS_PLAYER(this.enemy))
1828                 return false;
1829
1830         ClientData_Touch(this.enemy);
1831
1832         msg_entity = this;
1833         WriteByte(MSG_ONE, SVC_SETVIEW);
1834         WriteEntity(MSG_ONE, this.enemy);
1835         set_movetype(this, MOVETYPE_NONE);
1836         accuracy_resend(this);
1837
1838         if(!SpectateUpdate(this))
1839                 PutObserverInServer(this);
1840
1841         return true;
1842 }
1843
1844 void SetSpectatee_status(entity this, int spectatee_num)
1845 {
1846         int oldspectatee_status = CS(this).spectatee_status;
1847         CS(this).spectatee_status = spectatee_num;
1848
1849         if (CS(this).spectatee_status != oldspectatee_status)
1850         {
1851                 ClientData_Touch(this);
1852                 if (g_race || g_cts) race_InitSpectator();
1853         }
1854 }
1855
1856 void SetSpectatee(entity this, entity spectatee)
1857 {
1858         if(IS_BOT_CLIENT(this))
1859                 return; // bots abuse .enemy, this code is useless to them
1860
1861         entity old_spectatee = this.enemy;
1862
1863         this.enemy = spectatee;
1864
1865         // WEAPONTODO
1866         // these are required to fix the spectator bug with arc
1867         if(old_spectatee)
1868         {
1869                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1870                 {
1871                         .entity weaponentity = weaponentities[slot];
1872                         if(old_spectatee.(weaponentity).arc_beam)
1873                                 old_spectatee.(weaponentity).arc_beam.SendFlags |= ARC_SF_SETTINGS;
1874                 }
1875         }
1876         if(this.enemy)
1877         {
1878                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1879                 {
1880                         .entity weaponentity = weaponentities[slot];
1881                         if(this.enemy.(weaponentity).arc_beam)
1882                                 this.enemy.(weaponentity).arc_beam.SendFlags |= ARC_SF_SETTINGS;
1883                 }
1884         }
1885
1886         if (this.enemy)
1887                 SetSpectatee_status(this, etof(this.enemy));
1888
1889         // needed to update spectator list
1890         if(old_spectatee) { ClientData_Touch(old_spectatee); }
1891 }
1892
1893 bool Spectate(entity this, entity pl)
1894 {
1895         if(MUTATOR_CALLHOOK(SpectateSet, this, pl))
1896                 return false;
1897         pl = M_ARGV(1, entity);
1898
1899         SetSpectatee(this, pl);
1900         return SpectateSet(this);
1901 }
1902
1903 bool SpectateNext(entity this)
1904 {
1905         entity ent = find(this.enemy, classname, STR_PLAYER);
1906
1907         if (MUTATOR_CALLHOOK(SpectateNext, this, ent))
1908                 ent = M_ARGV(1, entity);
1909         else if (!ent)
1910                 ent = find(ent, classname, STR_PLAYER);
1911
1912         if(ent) { SetSpectatee(this, ent); }
1913
1914         return SpectateSet(this);
1915 }
1916
1917 bool SpectatePrev(entity this)
1918 {
1919         // NOTE: chain order is from the highest to the lower entnum (unlike find)
1920         entity ent = findchain(classname, STR_PLAYER);
1921         if (!ent) // no player
1922                 return false;
1923
1924         entity first = ent;
1925         // skip players until current spectated player
1926         if(this.enemy)
1927         while(ent && ent != this.enemy)
1928                 ent = ent.chain;
1929
1930         switch (MUTATOR_CALLHOOK(SpectatePrev, this, ent, first))
1931         {
1932                 case MUT_SPECPREV_FOUND:
1933                     ent = M_ARGV(1, entity);
1934                     break;
1935                 case MUT_SPECPREV_RETURN:
1936                     return true;
1937                 case MUT_SPECPREV_CONTINUE:
1938                 default:
1939                 {
1940                         if(ent.chain)
1941                                 ent = ent.chain;
1942                         else
1943                                 ent = first;
1944                         break;
1945                 }
1946         }
1947
1948         SetSpectatee(this, ent);
1949         return SpectateSet(this);
1950 }
1951
1952 /*
1953 =============
1954 ShowRespawnCountdown()
1955
1956 Update a respawn countdown display.
1957 =============
1958 */
1959 void ShowRespawnCountdown(entity this)
1960 {
1961         float number;
1962         if(!IS_DEAD(this)) // just respawned?
1963                 return;
1964         else
1965         {
1966                 number = ceil(this.respawn_time - time);
1967                 if(number <= 0)
1968                         return;
1969                 if(number <= this.respawn_countdown)
1970                 {
1971                         this.respawn_countdown = number - 1;
1972                         if(ceil(this.respawn_time - (time + 0.5)) == number) // only say it if it is the same number even in 0.5s; to prevent overlapping sounds
1973                                 { Send_Notification(NOTIF_ONE, this, MSG_ANNCE, Announcer_PickNumber(CNT_RESPAWN, number)); }
1974                 }
1975         }
1976 }
1977
1978 .bool team_selected;
1979 bool ShowTeamSelection(entity this)
1980 {
1981         if(!teamplay || autocvar_g_campaign || autocvar_g_balance_teams || this.team_selected || (CS(this).wasplayer && autocvar_g_changeteam_banned) || this.team_forced > 0)
1982                 return false;
1983         stuffcmd(this, "menu_showteamselect\n");
1984         return true;
1985 }
1986 void Join(entity this)
1987 {
1988         TRANSMUTE(Player, this);
1989
1990         if(!this.team_selected)
1991         if(autocvar_g_campaign || autocvar_g_balance_teams)
1992                 JoinBestTeam(this, false, true);
1993
1994         if(autocvar_g_campaign)
1995                 campaign_bots_may_start = true;
1996
1997         Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_PREVENT_JOIN);
1998
1999         PutClientInServer(this);
2000
2001         if(IS_PLAYER(this))
2002         if(teamplay && this.team != -1)
2003                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, APP_TEAM_NUM(this.team, INFO_JOIN_PLAY_TEAM), this.netname);
2004         else
2005                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_JOIN_PLAY, this.netname);
2006         this.team_selected = false;
2007 }
2008
2009 /**
2010  * Determines whether the player is allowed to join. This depends on cvar
2011  * g_maxplayers, if it isn't used this function always return true, otherwise
2012  * it checks whether the number of currently playing players exceeds g_maxplayers.
2013  * @return int number of free slots for players, 0 if none
2014  */
2015 int nJoinAllowed(entity this, entity ignore)
2016 {
2017         if(!ignore)
2018         // this is called that way when checking if anyone may be able to join (to build qcstatus)
2019         // so report 0 free slots if restricted
2020         {
2021                 if(autocvar_g_forced_team_otherwise == "spectate")
2022                         return 0;
2023                 if(autocvar_g_forced_team_otherwise == "spectator")
2024                         return 0;
2025         }
2026
2027         if(this && this.team_forced < 0)
2028                 return 0; // forced spectators can never join
2029
2030         // TODO simplify this
2031         int totalClients = 0;
2032         int currentlyPlaying = 0;
2033         FOREACH_CLIENT(true, {
2034                 if(it != ignore)
2035                         ++totalClients;
2036                 if(IS_REAL_CLIENT(it))
2037                 if(IS_PLAYER(it) || it.caplayer)
2038                         ++currentlyPlaying;
2039         });
2040
2041         float free_slots = 0;
2042         if (!autocvar_g_maxplayers)
2043                 free_slots = maxclients - totalClients;
2044         else if(currentlyPlaying < autocvar_g_maxplayers)
2045                 free_slots = min(maxclients - totalClients, autocvar_g_maxplayers - currentlyPlaying);
2046
2047         static float join_prevent_msg_time = 0;
2048         if(this && ignore && !free_slots && time > join_prevent_msg_time)
2049         {
2050                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_JOIN_PREVENT);
2051                 join_prevent_msg_time = time + 3;
2052         }
2053
2054         return free_slots;
2055 }
2056
2057 /**
2058  * Checks whether the client is an observer or spectator, if so, he will get kicked after
2059  * g_maxplayers_spectator_blocktime seconds
2060  */
2061 void checkSpectatorBlock(entity this)
2062 {
2063         if(IS_SPEC(this) || IS_OBSERVER(this))
2064         if(!this.caplayer)
2065         if(IS_REAL_CLIENT(this))
2066         {
2067                 if( time > (CS(this).spectatortime + autocvar_g_maxplayers_spectator_blocktime) ) {
2068                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_QUIT_KICK_SPECTATING);
2069                         dropclient(this);
2070                 }
2071         }
2072 }
2073
2074 void PrintWelcomeMessage(entity this)
2075 {
2076         if(CS(this).motd_actived_time == 0)
2077         {
2078                 if (autocvar_g_campaign) {
2079                         if ((IS_PLAYER(this) && PHYS_INPUT_BUTTON_INFO(this)) || (!IS_PLAYER(this))) {
2080                                 CS(this).motd_actived_time = time;
2081                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOTD, campaign_message);
2082                         }
2083                 } else {
2084                         if (PHYS_INPUT_BUTTON_INFO(this)) {
2085                                 CS(this).motd_actived_time = time;
2086                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOTD, getwelcomemessage(this));
2087                         }
2088                 }
2089         }
2090         else if(CS(this).motd_actived_time > 0) // showing MOTD or campaign message
2091         {
2092                 if (autocvar_g_campaign) {
2093                         if (PHYS_INPUT_BUTTON_INFO(this))
2094                                 CS(this).motd_actived_time = time;
2095                         else if ((time - CS(this).motd_actived_time > 2) && IS_PLAYER(this)) { // hide it some seconds after BUTTON_INFO has been released
2096                                 CS(this).motd_actived_time = 0;
2097                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_MOTD);
2098                         }
2099                 } else {
2100                         if (PHYS_INPUT_BUTTON_INFO(this))
2101                                 CS(this).motd_actived_time = time;
2102                         else if (time - CS(this).motd_actived_time > 2) { // hide it some seconds after BUTTON_INFO has been released
2103                                 CS(this).motd_actived_time = 0;
2104                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_MOTD);
2105                         }
2106                 }
2107         }
2108         else //if(CS(this).motd_actived_time < 0) // just connected, motd is active
2109         {
2110                 if(PHYS_INPUT_BUTTON_INFO(this)) // BUTTON_INFO hides initial MOTD
2111                         CS(this).motd_actived_time = -2; // wait until BUTTON_INFO gets released
2112                 else if(CS(this).motd_actived_time == -2 || IS_PLAYER(this) || IS_SPEC(this))
2113                 {
2114                         // instanctly hide MOTD
2115                         CS(this).motd_actived_time = 0;
2116                         Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_MOTD);
2117                 }
2118         }
2119 }
2120
2121 bool joinAllowed(entity this)
2122 {
2123         if (CS(this).version_mismatch) return false;
2124         if (!nJoinAllowed(this, this)) return false;
2125         if (teamplay && lockteams) return false;
2126         if (ShowTeamSelection(this)) return false;
2127         if (MUTATOR_CALLHOOK(ForbidSpawn, this)) return false;
2128         return true;
2129 }
2130
2131 .int items_added;
2132 bool PlayerThink(entity this)
2133 {
2134         if (game_stopped || intermission_running) {
2135                 this.modelflags &= ~MF_ROCKET;
2136                 if(intermission_running)
2137                         IntermissionThink(this);
2138                 return false;
2139         }
2140
2141         if (timeout_status == TIMEOUT_ACTIVE) {
2142         // don't allow the player to turn around while game is paused
2143                 // FIXME turn this into CSQC stuff
2144                 this.v_angle = this.lastV_angle;
2145                 this.angles = this.lastV_angle;
2146                 this.fixangle = true;
2147         }
2148
2149         if (frametime) player_powerups(this);
2150
2151         if (IS_DEAD(this)) {
2152                 if (this.personal && g_race_qualifying) {
2153                         if (time > this.respawn_time) {
2154                                 STAT(RESPAWN_TIME, this) = this.respawn_time = time + 1; // only retry once a second
2155                                 respawn(this);
2156                                 CS(this).impulse = CHIMPULSE_SPEEDRUN.impulse;
2157                         }
2158                 } else {
2159                         if (frametime) player_anim(this);
2160
2161                         if (this.respawn_flags & RESPAWN_DENY)
2162                         {
2163                                 STAT(RESPAWN_TIME, this) = 0;
2164                                 return false;
2165                         }
2166
2167                         bool button_pressed = (PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_JUMP(this) || PHYS_INPUT_BUTTON_ATCK2(this) || PHYS_INPUT_BUTTON_HOOK(this) || PHYS_INPUT_BUTTON_USE(this));
2168
2169                         switch(this.deadflag)
2170                         {
2171                                 case DEAD_DYING:
2172                                 {
2173                                         if ((this.respawn_flags & RESPAWN_FORCE) && !(this.respawn_time < this.respawn_time_max))
2174                                                 this.deadflag = DEAD_RESPAWNING;
2175                                         else if (!button_pressed || (time >= this.respawn_time_max && (this.respawn_flags & RESPAWN_FORCE)))
2176                                                 this.deadflag = DEAD_DEAD;
2177                                         break;
2178                                 }
2179                                 case DEAD_DEAD:
2180                                 {
2181                                         if (button_pressed)
2182                                                 this.deadflag = DEAD_RESPAWNABLE;
2183                                         else if (time >= this.respawn_time_max && (this.respawn_flags & RESPAWN_FORCE))
2184                                                 this.deadflag = DEAD_RESPAWNING;
2185                                         break;
2186                                 }
2187                                 case DEAD_RESPAWNABLE:
2188                                 {
2189                                         if (!button_pressed || (this.respawn_flags & RESPAWN_FORCE))
2190                                                 this.deadflag = DEAD_RESPAWNING;
2191                                         break;
2192                                 }
2193                                 case DEAD_RESPAWNING:
2194                                 {
2195                                         if (time > this.respawn_time)
2196                                         {
2197                                                 this.respawn_time = time + 1; // only retry once a second
2198                                                 this.respawn_time_max = this.respawn_time;
2199                                                 respawn(this);
2200                                         }
2201                                         break;
2202                                 }
2203                         }
2204
2205                         ShowRespawnCountdown(this);
2206
2207                         if (this.respawn_flags & RESPAWN_SILENT)
2208                                 STAT(RESPAWN_TIME, this) = 0;
2209                         else if ((this.respawn_flags & RESPAWN_FORCE) && this.respawn_time < this.respawn_time_max)
2210                         {
2211                                 if (time < this.respawn_time)
2212                                         STAT(RESPAWN_TIME, this) = this.respawn_time;
2213                                 else if (this.deadflag != DEAD_RESPAWNING)
2214                                         STAT(RESPAWN_TIME, this) = -this.respawn_time_max;
2215                         }
2216                         else
2217                                 STAT(RESPAWN_TIME, this) = this.respawn_time;
2218                 }
2219
2220                 // if respawning, invert stat_respawn_time to indicate this, the client translates it
2221                 if (this.deadflag == DEAD_RESPAWNING && STAT(RESPAWN_TIME, this) > 0)
2222                         STAT(RESPAWN_TIME, this) *= -1;
2223
2224                 return false;
2225         }
2226
2227         bool have_hook = false;
2228         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2229         {
2230                 .entity weaponentity = weaponentities[slot];
2231                 if(this.(weaponentity).hook.state)
2232                 {
2233                         have_hook = true;
2234                         break;
2235                 }
2236         }
2237         bool do_crouch = PHYS_INPUT_BUTTON_CROUCH(this);
2238         if (have_hook) {
2239                 do_crouch = false;
2240         } else if (this.waterlevel >= WATERLEVEL_SWIMMING) {
2241                 do_crouch = false;
2242         } else if (this.vehicle) {
2243                 do_crouch = false;
2244         } else if (STAT(FROZEN, this)) {
2245                 do_crouch = false;
2246     }
2247
2248         if (do_crouch) {
2249                 if (!this.crouch) {
2250                         this.crouch = true;
2251                         this.view_ofs = STAT(PL_CROUCH_VIEW_OFS, this);
2252                         setsize(this, STAT(PL_CROUCH_MIN, this), STAT(PL_CROUCH_MAX, this));
2253                         // setanim(this, this.anim_duck, false, true, true); // this anim is BROKEN anyway
2254                 }
2255         } else if (this.crouch) {
2256         tracebox(this.origin, STAT(PL_MIN, this), STAT(PL_MAX, this), this.origin, false, this);
2257         if (!trace_startsolid) {
2258             this.crouch = false;
2259             this.view_ofs = STAT(PL_VIEW_OFS, this);
2260             setsize(this, STAT(PL_MIN, this), STAT(PL_MAX, this));
2261         }
2262         }
2263
2264         FixPlayermodel(this);
2265
2266         // LordHavoc: allow firing on move frames (sub-ticrate), this gives better timing on slow servers
2267         //if(frametime)
2268         {
2269                 this.items &= ~this.items_added;
2270
2271                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2272                 {
2273                         .entity weaponentity = weaponentities[slot];
2274                         W_WeaponFrame(this, weaponentity);
2275
2276                         if(slot == 0)
2277                         {
2278                                 this.clip_load = this.(weaponentity).clip_load;
2279                                 this.clip_size = this.(weaponentity).clip_size;
2280                         }
2281                 }
2282
2283                 this.items_added = 0;
2284                 if ((this.items & ITEM_Jetpack.m_itemid) && ((this.items & ITEM_JetpackRegen.m_itemid) || this.ammo_fuel >= 0.01))
2285             this.items_added |= IT_FUEL;
2286
2287                 this.items |= this.items_added;
2288         }
2289
2290         player_regen(this);
2291
2292         // WEAPONTODO: Add a weapon request for this
2293         // rot vortex charge to the charge limit
2294         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2295         {
2296                 .entity weaponentity = weaponentities[slot];
2297                 if (WEP_CVAR(vortex, charge_rot_rate) && this.(weaponentity).vortex_charge > WEP_CVAR(vortex, charge_limit) && this.(weaponentity).vortex_charge_rottime < time)
2298                         this.(weaponentity).vortex_charge = bound(WEP_CVAR(vortex, charge_limit), this.(weaponentity).vortex_charge - WEP_CVAR(vortex, charge_rot_rate) * frametime / W_TICSPERFRAME, 1);
2299         }
2300
2301         if (frametime) player_anim(this);
2302
2303         // secret status
2304         secrets_setstatus(this);
2305
2306         // monsters status
2307         monsters_setstatus(this);
2308
2309         this.dmg_team = max(0, this.dmg_team - autocvar_g_teamdamage_resetspeed * frametime);
2310
2311         return true;
2312 }
2313
2314 void ObserverThink(entity this)
2315 {
2316         if ( CS(this).impulse )
2317         {
2318                 MinigameImpulse(this, CS(this).impulse);
2319                 CS(this).impulse = 0;
2320         }
2321
2322         if (this.flags & FL_JUMPRELEASED) {
2323                 if (PHYS_INPUT_BUTTON_JUMP(this) && joinAllowed(this)) {
2324                         this.flags &= ~FL_JUMPRELEASED;
2325                         this.flags |= FL_SPAWNING;
2326                 } else if(PHYS_INPUT_BUTTON_ATCK(this) && !CS(this).version_mismatch) {
2327                         this.flags &= ~FL_JUMPRELEASED;
2328                         if(SpectateNext(this)) {
2329                                 TRANSMUTE(Spectator, this);
2330                         }
2331                 } else {
2332                         int preferred_movetype = ((!PHYS_INPUT_BUTTON_USE(this) ? CS(this).cvar_cl_clippedspectating : !CS(this).cvar_cl_clippedspectating) ? MOVETYPE_FLY_WORLDONLY : MOVETYPE_NOCLIP);
2333                         set_movetype(this, preferred_movetype);
2334                 }
2335         } else {
2336                 if (!(PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_JUMP(this))) {
2337                         this.flags |= FL_JUMPRELEASED;
2338                         if(this.flags & FL_SPAWNING)
2339                         {
2340                                 this.flags &= ~FL_SPAWNING;
2341                                 Join(this);
2342                                 return;
2343                         }
2344                 }
2345         }
2346 }
2347
2348 void SpectatorThink(entity this)
2349 {
2350         if ( CS(this).impulse )
2351         {
2352                 if(MinigameImpulse(this, CS(this).impulse))
2353                         CS(this).impulse = 0;
2354
2355                 if (CS(this).impulse == IMP_weapon_drop.impulse)
2356                 {
2357                         STAT(CAMERA_SPECTATOR, this) = (STAT(CAMERA_SPECTATOR, this) + 1) % 3;
2358                         CS(this).impulse = 0;
2359                         return;
2360                 }
2361         }
2362
2363         if (this.flags & FL_JUMPRELEASED) {
2364                 if (PHYS_INPUT_BUTTON_JUMP(this) && joinAllowed(this)) {
2365                         this.flags &= ~FL_JUMPRELEASED;
2366                         this.flags |= FL_SPAWNING;
2367                 } else if(PHYS_INPUT_BUTTON_ATCK(this) || CS(this).impulse == 10 || CS(this).impulse == 15 || CS(this).impulse == 18 || (CS(this).impulse >= 200 && CS(this).impulse <= 209)) {
2368                         this.flags &= ~FL_JUMPRELEASED;
2369                         if(SpectateNext(this)) {
2370                                 TRANSMUTE(Spectator, this);
2371                         } else {
2372                                 TRANSMUTE(Observer, this);
2373                                 PutClientInServer(this);
2374                         }
2375                         CS(this).impulse = 0;
2376                 } else if(CS(this).impulse == 12 || CS(this).impulse == 16  || CS(this).impulse == 19 || (CS(this).impulse >= 220 && CS(this).impulse <= 229)) {
2377                         this.flags &= ~FL_JUMPRELEASED;
2378                         if(SpectatePrev(this)) {
2379                                 TRANSMUTE(Spectator, this);
2380                         } else {
2381                                 TRANSMUTE(Observer, this);
2382                                 PutClientInServer(this);
2383                         }
2384                         CS(this).impulse = 0;
2385                 } else if (PHYS_INPUT_BUTTON_ATCK2(this)) {
2386                         this.flags &= ~FL_JUMPRELEASED;
2387                         TRANSMUTE(Observer, this);
2388                         PutClientInServer(this);
2389                 } else {
2390                         if(!SpectateUpdate(this))
2391                                 PutObserverInServer(this);
2392                 }
2393         } else {
2394                 if (!(PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_ATCK2(this))) {
2395                         this.flags |= FL_JUMPRELEASED;
2396                         if(this.flags & FL_SPAWNING)
2397                         {
2398                                 this.flags &= ~FL_SPAWNING;
2399                                 Join(this);
2400                                 return;
2401                         }
2402                 }
2403                 if(!SpectateUpdate(this))
2404                         PutObserverInServer(this);
2405         }
2406
2407         this.flags |= FL_CLIENT | FL_NOTARGET;
2408 }
2409
2410 void vehicles_enter (entity pl, entity veh);
2411 void PlayerUseKey(entity this)
2412 {
2413         if (!IS_PLAYER(this))
2414                 return;
2415
2416         if(this.vehicle)
2417         {
2418                 if(!game_stopped)
2419                 {
2420                         vehicles_exit(this.vehicle, VHEF_NORMAL);
2421                         return;
2422                 }
2423         }
2424         else if(autocvar_g_vehicles_enter)
2425         {
2426                 if(!STAT(FROZEN, this))
2427                 if(!IS_DEAD(this))
2428                 if(!game_stopped)
2429                 {
2430                         entity head, closest_target = NULL;
2431                         head = WarpZone_FindRadius(this.origin, autocvar_g_vehicles_enter_radius, true);
2432
2433                         while(head) // find the closest acceptable target to enter
2434                         {
2435                                 if(IS_VEHICLE(head))
2436                                 if(!IS_DEAD(head))
2437                                 if(!head.owner || ((head.vehicle_flags & VHF_MULTISLOT) && SAME_TEAM(head.owner, this)))
2438                                 if(head.takedamage != DAMAGE_NO)
2439                                 {
2440                                         if(closest_target)
2441                                         {
2442                                                 if(vlen2(this.origin - head.origin) < vlen2(this.origin - closest_target.origin))
2443                                                 { closest_target = head; }
2444                                         }
2445                                         else { closest_target = head; }
2446                                 }
2447
2448                                 head = head.chain;
2449                         }
2450
2451                         if(closest_target) { vehicles_enter(this, closest_target); return; }
2452                 }
2453         }
2454
2455         // a use key was pressed; call handlers
2456         MUTATOR_CALLHOOK(PlayerUseKey, this);
2457 }
2458
2459
2460 /*
2461 =============
2462 PlayerPreThink
2463
2464 Called every frame for each client before the physics are run
2465 =============
2466 */
2467 .float last_vehiclecheck;
2468 void PlayerPreThink (entity this)
2469 {
2470         STAT(GUNALIGN, this) = CS(this).cvar_cl_gunalign; // TODO
2471         STAT(MOVEVARS_CL_TRACK_CANJUMP, this) = CS(this).cvar_cl_movement_track_canjump;
2472
2473         WarpZone_PlayerPhysics_FixVAngle(this);
2474
2475         if (frametime) {
2476                 // physics frames: update anticheat stuff
2477                 anticheat_prethink(this);
2478         }
2479
2480         if (blockSpectators && frametime) {
2481                 // WORKAROUND: only use dropclient in server frames (frametime set).
2482                 // Never use it in cl_movement frames (frametime zero).
2483                 checkSpectatorBlock(this);
2484     }
2485
2486         zoomstate_set = false;
2487
2488         // Check for nameless players
2489         if (isInvisibleString(this.netname)) {
2490                 this.netname = strzone(sprintf("Player#%d", this.playerid));
2491                 // stuffcmd(this, strcat("name ", this.netname, "\n")); // maybe?
2492         }
2493         if (this.netname != CS(this).netname_previous) {
2494                 if (autocvar_sv_eventlog) {
2495                         GameLogEcho(strcat(":name:", ftos(this.playerid), ":", playername(this, false)));
2496         }
2497                 if (CS(this).netname_previous) strunzone(CS(this).netname_previous);
2498                 CS(this).netname_previous = strzone(this.netname);
2499         }
2500
2501         // version nagging
2502         if (CS(this).version_nagtime && CS(this).cvar_g_xonoticversion && time > CS(this).version_nagtime) {
2503         CS(this).version_nagtime = 0;
2504         if (strstrofs(CS(this).cvar_g_xonoticversion, "git", 0) >= 0 || strstrofs(CS(this).cvar_g_xonoticversion, "autobuild", 0) >= 0) {
2505             // git client
2506         } else if (strstrofs(autocvar_g_xonoticversion, "git", 0) >= 0 || strstrofs(autocvar_g_xonoticversion, "autobuild", 0) >= 0) {
2507             // git server
2508             Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_BETA, autocvar_g_xonoticversion, CS(this).cvar_g_xonoticversion);
2509         } else {
2510             int r = vercmp(CS(this).cvar_g_xonoticversion, autocvar_g_xonoticversion);
2511             if (r < 0) { // old client
2512                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_OUTDATED, autocvar_g_xonoticversion, CS(this).cvar_g_xonoticversion);
2513             } else if (r > 0) { // old server
2514                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_OLD, autocvar_g_xonoticversion, CS(this).cvar_g_xonoticversion);
2515             }
2516         }
2517     }
2518
2519         // GOD MODE info
2520         if (!(this.flags & FL_GODMODE) && this.max_armorvalue)
2521         {
2522                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_GODMODE_OFF, this.max_armorvalue);
2523                 this.max_armorvalue = 0;
2524         }
2525
2526         if(IS_PLAYER(this))
2527         {
2528                 if (STAT(FROZEN, this) == 2)
2529                 {
2530                         this.revive_progress = bound(0, this.revive_progress + frametime * this.revive_speed, 1);
2531                         this.health = max(1, this.revive_progress * start_health);
2532                         this.iceblock.alpha = bound(0.2, 1 - this.revive_progress, 1);
2533
2534                         if (this.revive_progress >= 1)
2535                                 Unfreeze(this);
2536                 }
2537                 else if (STAT(FROZEN, this) == 3)
2538                 {
2539                         this.revive_progress = bound(0, this.revive_progress - frametime * this.revive_speed, 1);
2540                         this.health = max(0, autocvar_g_nades_ice_health + (start_health-autocvar_g_nades_ice_health) * this.revive_progress );
2541
2542                         if (this.health < 1)
2543                         {
2544                                 if (this.vehicle)
2545                                         vehicles_exit(this.vehicle, VHEF_RELEASE);
2546                                 if(this.event_damage)
2547                                         this.event_damage(this, this, this.frozen_by, 1, DEATH_NADE_ICE_FREEZE.m_id, this.origin, '0 0 0');
2548                         }
2549                         else if (this.revive_progress <= 0)
2550                                 Unfreeze(this);
2551                 }
2552         }
2553
2554         MUTATOR_CALLHOOK(PlayerPreThink, this);
2555
2556         if(autocvar_g_vehicles_enter && (time > this.last_vehiclecheck) && !game_stopped && !this.vehicle)
2557         if(IS_PLAYER(this) && !STAT(FROZEN, this) && !IS_DEAD(this))
2558         {
2559                 FOREACH_ENTITY_RADIUS(this.origin, autocvar_g_vehicles_enter_radius, IS_VEHICLE(it),
2560                 {
2561                         if(!IS_DEAD(it) && it.takedamage != DAMAGE_NO)
2562                         if((it.vehicle_flags & VHF_MULTISLOT) && SAME_TEAM(it.owner, this))
2563                         {
2564                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER_GUNNER);
2565                         }
2566                         else if(!it.owner)
2567                         {
2568                                 if(!it.team || SAME_TEAM(this, it))
2569                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER);
2570                                 else if(autocvar_g_vehicles_steal)
2571                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER_STEAL);
2572                         }
2573                 });
2574
2575                 this.last_vehiclecheck = time + 1;
2576         }
2577
2578         if(!CS(this).cvar_cl_newusekeysupported) // FIXME remove this - it was a stupid idea to begin with, we can JUST use the button
2579         {
2580                 if(PHYS_INPUT_BUTTON_USE(this) && !CS(this).usekeypressed)
2581                         PlayerUseKey(this);
2582                 CS(this).usekeypressed = PHYS_INPUT_BUTTON_USE(this);
2583         }
2584
2585         if (IS_REAL_CLIENT(this))
2586                 PrintWelcomeMessage(this);
2587
2588         if (IS_PLAYER(this)) {
2589                 if(!PlayerThink(this))
2590                         return;
2591         }
2592         else if (game_stopped || intermission_running) {
2593                 if(intermission_running)
2594                         IntermissionThink(this);
2595                 return;
2596         }
2597         else if (IS_OBSERVER(this)) {
2598                 ObserverThink(this);
2599         }
2600         else if (IS_SPEC(this)) {
2601                 SpectatorThink(this);
2602         }
2603
2604         // WEAPONTODO: Add weapon request for this
2605         if (!zoomstate_set) {
2606                 bool wep_zoomed = false;
2607                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2608                 {
2609                         .entity weaponentity = weaponentities[slot];
2610                         Weapon thiswep = this.(weaponentity).m_weapon;
2611                         if(thiswep != WEP_Null && thiswep.wr_zoom)
2612                                 wep_zoomed += thiswep.wr_zoom(thiswep, this);
2613                 }
2614                 SetZoomState(this, PHYS_INPUT_BUTTON_ZOOM(this) || PHYS_INPUT_BUTTON_ZOOMSCRIPT(this) || wep_zoomed);
2615     }
2616
2617         if (CS(this).teamkill_soundtime && time > CS(this).teamkill_soundtime)
2618         {
2619                 CS(this).teamkill_soundtime = 0;
2620
2621                 entity e = CS(this).teamkill_soundsource;
2622                 entity oldpusher = e.pusher;
2623                 e.pusher = this;
2624                 PlayerSound(e, playersound_teamshoot, CH_VOICE, VOL_BASEVOICE, VOICETYPE_LASTATTACKER_ONLY);
2625                 e.pusher = oldpusher;
2626         }
2627
2628         if (CS(this).taunt_soundtime && time > CS(this).taunt_soundtime) {
2629                 CS(this).taunt_soundtime = 0;
2630                 PlayerSound(this, playersound_taunt, CH_VOICE, VOL_BASEVOICE, VOICETYPE_AUTOTAUNT);
2631         }
2632
2633         target_voicescript_next(this);
2634
2635         // WEAPONTODO: Move into weaponsystem somehow
2636         // if a player goes unarmed after holding a loaded weapon, empty his clip size and remove the crosshair ammo ring
2637         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2638         {
2639                 .entity weaponentity = weaponentities[slot];
2640                 if(this.(weaponentity).m_weapon == WEP_Null)
2641                         this.(weaponentity).clip_load = this.(weaponentity).clip_size = 0;
2642         }
2643 }
2644
2645 void DrownPlayer(entity this)
2646 {
2647         if(IS_DEAD(this))
2648                 return;
2649
2650         if (this.waterlevel != WATERLEVEL_SUBMERGED || this.vehicle)
2651         {
2652                 if(this.air_finished < time)
2653                         PlayerSound(this, playersound_gasp, CH_PLAYER, VOL_BASE, VOICETYPE_PLAYERSOUND);
2654                 this.air_finished = time + autocvar_g_balance_contents_drowndelay;
2655                 this.dmg = 2;
2656         }
2657         else if (this.air_finished < time)
2658         {       // drown!
2659                 if (this.pain_finished < time)
2660                 {
2661                         Damage (this, NULL, NULL, autocvar_g_balance_contents_playerdamage_drowning * autocvar_g_balance_contents_damagerate, DEATH_DROWN.m_id, this.origin, '0 0 0');
2662                         this.pain_finished = time + 0.5;
2663                 }
2664         }
2665 }
2666
2667 .bool move_qcphysics;
2668
2669 void Player_Physics(entity this)
2670 {
2671         set_movetype(this, this.move_movetype);
2672
2673         if(!this.move_qcphysics)
2674                 return;
2675
2676         if(!frametime && !CS(this).pm_frametime)
2677                 return;
2678
2679         Movetype_Physics_NoMatchTicrate(this, CS(this).pm_frametime, true);
2680
2681         CS(this).pm_frametime = 0;
2682 }
2683
2684 /*
2685 =============
2686 PlayerPostThink
2687
2688 Called every frame for each client after the physics are run
2689 =============
2690 */
2691 void PlayerPostThink (entity this)
2692 {
2693         Player_Physics(this);
2694
2695         if (sv_maxidle > 0)
2696         if (frametime) // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2697         if (IS_REAL_CLIENT(this))
2698         if (IS_PLAYER(this) || sv_maxidle_spectatorsareidle)
2699         {
2700                 int totalClients = 0;
2701                 if(sv_maxidle_slots > 0)
2702                 {
2703                         FOREACH_CLIENT(IS_REAL_CLIENT(it) || sv_maxidle_slots_countbots,
2704                         {
2705                                 ++totalClients;
2706                         });
2707                 }
2708
2709                 if (sv_maxidle_slots > 0 && (maxclients - totalClients) > sv_maxidle_slots)
2710                 { /* do nothing */ }
2711                 else if (time - CS(this).parm_idlesince < 1) // instead of (time == this.parm_idlesince) to support sv_maxidle <= 10
2712                 {
2713                         if (CS(this).idlekick_lasttimeleft)
2714                         {
2715                                 CS(this).idlekick_lasttimeleft = 0;
2716                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_IDLING);
2717                         }
2718                 }
2719                 else
2720                 {
2721                         float timeleft = ceil(sv_maxidle - (time - CS(this).parm_idlesince));
2722                         if (timeleft == min(10, sv_maxidle - 1)) { // - 1 to support sv_maxidle <= 10
2723                                 if (!CS(this).idlekick_lasttimeleft)
2724                                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_DISCONNECT_IDLING, timeleft);
2725                         }
2726                         if (timeleft <= 0) {
2727                                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_QUIT_KICK_IDLING, this.netname);
2728                                 dropclient(this);
2729                                 return;
2730                         }
2731                         else if (timeleft <= 10) {
2732                                 if (timeleft != CS(this).idlekick_lasttimeleft) {
2733                                     Send_Notification(NOTIF_ONE, this, MSG_ANNCE, Announcer_PickNumber(CNT_IDLE, timeleft));
2734                 }
2735                                 CS(this).idlekick_lasttimeleft = timeleft;
2736                         }
2737                 }
2738         }
2739
2740         CheatFrame(this);
2741
2742         if (game_stopped)
2743         {
2744                 this.solid = SOLID_NOT;
2745                 this.takedamage = DAMAGE_NO;
2746                 set_movetype(this, MOVETYPE_NONE);
2747         }
2748
2749         if (IS_PLAYER(this)) {
2750                 DrownPlayer(this);
2751                 UpdateChatBubble(this);
2752                 if (CS(this).impulse) ImpulseCommands(this);
2753                 if (game_stopped)
2754                 {
2755                         CSQCMODEL_AUTOUPDATE(this);
2756                         return;
2757                 }
2758                 GetPressedKeys(this);
2759         }
2760
2761         if (this.waypointsprite_attachedforcarrier) {
2762             vector v = healtharmor_maxdamage(this.health, this.armorvalue, autocvar_g_balance_armor_blockpercent, DEATH_WEAPON.m_id);
2763                 WaypointSprite_UpdateHealth(this.waypointsprite_attachedforcarrier, '1 0 0' * v);
2764     }
2765
2766         playerdemo_write(this);
2767
2768         CSQCMODEL_AUTOUPDATE(this);
2769 }
2770
2771 // hack to copy the button fields from the client entity to the Client State
2772 void PM_UpdateButtons(entity this, entity store)
2773 {
2774         if(this.impulse)
2775                 store.impulse = this.impulse;
2776         this.impulse = 0;
2777
2778         store.button0 = this.button0;
2779         store.button2 = this.button2;
2780         store.button3 = this.button3;
2781         store.button4 = this.button4;
2782         store.button5 = this.button5;
2783         store.button6 = this.button6;
2784         store.button7 = this.button7;
2785         store.button8 = this.button8;
2786         store.button9 = this.button9;
2787         store.button10 = this.button10;
2788         store.button11 = this.button11;
2789         store.button12 = this.button12;
2790         store.button13 = this.button13;
2791         store.button14 = this.button14;
2792         store.button15 = this.button15;
2793         store.button16 = this.button16;
2794         store.buttonuse = this.buttonuse;
2795         store.buttonchat = this.buttonchat;
2796
2797         store.cursor_active = this.cursor_active;
2798         store.cursor_screen = this.cursor_screen;
2799         store.cursor_trace_start = this.cursor_trace_start;
2800         store.cursor_trace_endpos = this.cursor_trace_endpos;
2801         store.cursor_trace_ent = this.cursor_trace_ent;
2802
2803         store.ping = this.ping;
2804         store.ping_packetloss = this.ping_packetloss;
2805         store.ping_movementloss = this.ping_movementloss;
2806
2807         store.v_angle = this.v_angle;
2808         store.movement = this.movement;
2809 }