qcsrc/server/client.qc

   1 #include "client.qh"
   2
   3 #include <server/defs.qh>
   4 #include <server/miscfunctions.qh>
   5 #include <common/effects/all.qh>
   6 #include "anticheat.qh"
   7 #include "impulse.qh"
   8 #include "player.qh"
   9 #include "ipban.qh"
  10 #include "miscfunctions.qh"
  11 #include "portals.qh"
  12 #include "teamplay.qh"
  13 #include "playerdemo.qh"
  14 #include "spawnpoints.qh"
  15 #include "resources.qh"
  16 #include "g_damage.qh"
  17 #include "handicap.qh"
  18 #include "g_hook.qh"
  19 #include "command/common.qh"
  20 #include "cheats.qh"
  21 #include "g_world.qh"
  22 #include "race.qh"
  23 #include "antilag.qh"
  24 #include "campaign.qh"
  25 #include "command/common.qh"
  26 #include "scores_rules.qh"
  27
  28 #include "bot/api.qh"
  29
  30 #include "../common/ent_cs.qh"
  31 #include "../common/wepent.qh"
  32 #include <common/state.qh>
  33
  34 #include <common/effects/qc/globalsound.qh>
  35
  36 #include "../common/mapobjects/func/conveyor.qh"
  37 #include "../common/mapobjects/teleporters.qh"
  38 #include "../common/mapobjects/target/spawnpoint.qh"
  39
  40 #include "../common/vehicles/all.qh"
  41
  42 #include "weapons/hitplot.qh"
  43 #include "weapons/weaponsystem.qh"
  44
  45 #include "../common/net_notice.qh"
  46 #include "../common/net_linked.qh"
  47 #include "../common/physics/player.qh"
  48
  49 #include "../common/items/_mod.qh"
  50
  51 #include "../common/mutators/mutator/waypoints/all.qh"
  52 #include "../common/mutators/mutator/instagib/sv_instagib.qh"
  53 #include <common/gamemodes/_mod.qh>
  54
  55 #include "../common/mapobjects/subs.qh"
  56 #include "../common/mapobjects/triggers.qh"
  57 #include "../common/mapobjects/trigger/secret.qh"
  58
  59 #include "../common/minigames/sv_minigames.qh"
  60
  61 #include "../common/items/inventory.qh"
  62
  63 #include "../common/monsters/sv_monsters.qh"
  64
  65 #include "../lib/warpzone/server.qh"
  66
  67 #include <common/mutators/mutator/overkill/oknex.qh>
  68
  69 STATIC_METHOD(Client, Add, void(Client this, int _team))
  70 {
  71     ClientConnect(this);
  72     TRANSMUTE(Player, this);
  73     this.frame = 12; // 7
  74     this.team = _team;
  75     PutClientInServer(this);
  76 }
  77
  78 void PutObserverInServer(entity this);
  79
  80 STATIC_METHOD(Client, Remove, void(Client this))
  81 {
  82     TRANSMUTE(Observer, this);
  83     PutClientInServer(this);
  84     ClientDisconnect(this);
  85 }
  86
  87 void send_CSQC_teamnagger() {
  88         WriteHeader(MSG_BROADCAST, TE_CSQC_TEAMNAGGER);
  89 }
  90
  91 int CountSpectators(entity player, entity to)
  92 {
  93         if(!player) { return 0; } // not sure how, but best to be safe
  94
  95         int spec_count = 0;
  96
  97         FOREACH_CLIENT(IS_REAL_CLIENT(it) && IS_SPEC(it) && it != to && it.enemy == player,
  98         {
  99                 spec_count++;
 100         });
 101
 102         return spec_count;
 103 }
 104
 105 void WriteSpectators(entity player, entity to)
 106 {
 107         if(!player) { return; } // not sure how, but best to be safe
 108
 109         FOREACH_CLIENT(IS_REAL_CLIENT(it) && IS_SPEC(it) && it != to && it.enemy == player,
 110         {
 111                 WriteByte(MSG_ENTITY, num_for_edict(it));
 112         });
 113 }
 114
 115 bool ClientData_Send(entity this, entity to, int sf)
 116 {
 117         assert(to == this.owner, return false);
 118
 119         entity e = to;
 120         if (IS_SPEC(e)) e = e.enemy;
 121
 122         sf = 0;
 123         if (CS(e).race_completed)       sf |= BIT(0); // forced scoreboard
 124         if (CS(to).spectatee_status)    sf |= BIT(1); // spectator ent number follows
 125         if (CS(e).zoomstate)            sf |= BIT(2); // zoomed
 126         if (autocvar_sv_showspectators) sf |= BIT(4); // show spectators
 127
 128         WriteHeader(MSG_ENTITY, ENT_CLIENT_CLIENTDATA);
 129         WriteByte(MSG_ENTITY, sf);
 130
 131         if (sf & BIT(1))
 132                 WriteByte(MSG_ENTITY, CS(to).spectatee_status);
 133
 134         if(sf & BIT(4))
 135         {
 136                 float specs = CountSpectators(e, to);
 137                 WriteByte(MSG_ENTITY, specs);
 138                 WriteSpectators(e, to);
 139         }
 140
 141         return true;
 142 }
 143
 144 void ClientData_Attach(entity this)
 145 {
 146         Net_LinkEntity(CS(this).clientdata = new_pure(clientdata), false, 0, ClientData_Send);
 147         CS(this).clientdata.drawonlytoclient = this;
 148         CS(this).clientdata.owner = this;
 149 }
 150
 151 void ClientData_Detach(entity this)
 152 {
 153         delete(CS(this).clientdata);
 154         CS(this).clientdata = NULL;
 155 }
 156
 157 void ClientData_Touch(entity e)
 158 {
 159         entity cd = CS(e).clientdata;
 160         if (cd) { cd.SendFlags = 1; }
 161
 162         // make it spectatable
 163         FOREACH_CLIENT(IS_REAL_CLIENT(it) && it != e && IS_SPEC(it) && it.enemy == e,
 164         {
 165                 entity cd = CS(it).clientdata;
 166                 if (cd) { cd.SendFlags = 1; }
 167         });
 168 }
 169
 170 void SetSpectatee(entity this, entity spectatee);
 171 void SetSpectatee_status(entity this, int spectatee_num);
 172
 173
 174 /*
 175 =============
 176 CheckPlayerModel
 177
 178 Checks if the argument string can be a valid playermodel.
 179 Returns a valid one in doubt.
 180 =============
 181 */
 182 string FallbackPlayerModel;
 183 string CheckPlayerModel(string plyermodel) {
 184         if(FallbackPlayerModel != cvar_defstring("_cl_playermodel"))
 185         {
 186                 // note: we cannot summon Don Strunzone here, some player may
 187                 // still have the model string set. In case anyone manages how
 188                 // to change a cvar default, we'll have a small leak here.
 189                 FallbackPlayerModel = strzone(cvar_defstring("_cl_playermodel"));
 190         }
 191         // only in right path
 192         if( substring(plyermodel,0,14) != "models/player/")
 193                 return FallbackPlayerModel;
 194         // only good file extensions
 195         if(substring(plyermodel,-4,4) != ".zym")
 196         if(substring(plyermodel,-4,4) != ".dpm")
 197         if(substring(plyermodel,-4,4) != ".iqm")
 198         if(substring(plyermodel,-4,4) != ".md3")
 199         if(substring(plyermodel,-4,4) != ".psk")
 200                 return FallbackPlayerModel;
 201         // forbid the LOD models
 202         if(substring(plyermodel, -9,5) == "_lod1")
 203                 return FallbackPlayerModel;
 204         if(substring(plyermodel, -9,5) == "_lod2")
 205                 return FallbackPlayerModel;
 206         if(plyermodel != strtolower(plyermodel))
 207                 return FallbackPlayerModel;
 208         // also, restrict to server models
 209         if(autocvar_sv_servermodelsonly)
 210         {
 211                 if(!fexists(plyermodel))
 212                         return FallbackPlayerModel;
 213         }
 214         return plyermodel;
 215 }
 216
 217 void setplayermodel(entity e, string modelname)
 218 {
 219         precache_model(modelname);
 220         _setmodel(e, modelname);
 221         player_setupanimsformodel(e);
 222         if(!autocvar_g_debug_globalsounds)
 223                 UpdatePlayerSounds(e);
 224 }
 225
 226 void FixPlayermodel(entity player);
 227 /** putting a client as observer in the server */
 228 void PutObserverInServer(entity this)
 229 {
 230     bool mutator_returnvalue = MUTATOR_CALLHOOK(MakePlayerObserver, this);
 231         PlayerState_detach(this);
 232
 233         if (IS_PLAYER(this))
 234         {
 235                 if(this.health >= 1)
 236                 {
 237                         // despawn effect
 238                         Send_Effect(EFFECT_SPAWN_NEUTRAL, this.origin, '0 0 0', 1);
 239                 }
 240
 241                 // was a player, recount votes and ready status
 242                 if(IS_REAL_CLIENT(this))
 243                 {
 244                         if (vote_called) { VoteCount(false); }
 245                         ReadyCount();
 246                 }
 247     }
 248
 249     {
 250         entity spot = SelectSpawnPoint(this, true);
 251         if (!spot) LOG_FATAL("No spawnpoints for observers?!?");
 252         this.angles = vec2(spot.angles);
 253         this.fixangle = true;
 254         // offset it so that the spectator spawns higher off the ground, looks better this way
 255         setorigin(this, spot.origin + STAT(PL_VIEW_OFS, this));
 256         if (IS_REAL_CLIENT(this))
 257         {
 258             msg_entity = this;
 259             WriteByte(MSG_ONE, SVC_SETVIEW);
 260             WriteEntity(MSG_ONE, this);
 261         }
 262         // give the spectator some space between walls for MOVETYPE_FLY_WORLDONLY
 263         // so that your view doesn't go into the ceiling with MOVETYPE_FLY_WORLDONLY, previously "PL_VIEW_OFS"
 264         if(!autocvar_g_debug_globalsounds)
 265         {
 266                 // needed for player sounds
 267                 this.model = "";
 268                 FixPlayermodel(this);
 269         }
 270         setmodel(this, MDL_Null);
 271         setsize(this, STAT(PL_CROUCH_MIN, this), STAT(PL_CROUCH_MAX, this));
 272         this.view_ofs = '0 0 0';
 273     }
 274
 275     RemoveGrapplingHooks(this);
 276         Portal_ClearAll(this);
 277         Unfreeze(this);
 278         SetSpectatee(this, NULL);
 279
 280         if (this.alivetime)
 281         {
 282                 if (!warmup_stage)
 283                         PlayerStats_GameReport_Event_Player(this, PLAYERSTATS_ALIVETIME, time - this.alivetime);
 284                 this.alivetime = 0;
 285         }
 286
 287         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
 288
 289         WaypointSprite_PlayerDead(this);
 290
 291         if (mutator_returnvalue) {
 292             // mutator prevents resetting teams+score
 293         } else {
 294                 int oldteam = this.team;
 295                 this.team = -1;  // move this as it is needed to log the player spectating in eventlog
 296                 MUTATOR_CALLHOOK(Player_ChangedTeam, this, oldteam, this.team);
 297         this.frags = FRAGS_SPECTATOR;
 298         PlayerScore_Clear(this);  // clear scores when needed
 299     }
 300
 301         if (CS(this).killcount != FRAGS_SPECTATOR)
 302         {
 303                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_QUIT_SPECTATE, this.netname);
 304                 if(!game_stopped)
 305                 if(autocvar_g_chat_nospectators == 1 || (!warmup_stage && autocvar_g_chat_nospectators == 2))
 306                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_CHAT_NOSPECTATORS);
 307
 308                 if(!CS(this).just_joined)
 309                         LogTeamchange(this.playerid, -1, 4);
 310                 else
 311                         CS(this).just_joined = false;
 312         }
 313
 314         accuracy_resend(this);
 315
 316         CS(this).spectatortime = time;
 317         if(this.bot_attack)
 318                 IL_REMOVE(g_bot_targets, this);
 319         this.bot_attack = false;
 320         if(this.monster_attack)
 321                 IL_REMOVE(g_monster_targets, this);
 322         this.monster_attack = false;
 323     STAT(HUD, this) = HUD_NORMAL;
 324         TRANSMUTE(Observer, this);
 325         this.iscreature = false;
 326         this.teleportable = TELEPORT_SIMPLE;
 327         if(this.damagedbycontents)
 328                 IL_REMOVE(g_damagedbycontents, this);
 329         this.damagedbycontents = false;
 330         this.health = FRAGS_SPECTATOR;
 331         SetSpectatee_status(this, etof(this));
 332         this.takedamage = DAMAGE_NO;
 333         this.solid = SOLID_NOT;
 334         set_movetype(this, MOVETYPE_FLY_WORLDONLY); // user preference is controlled by playerprethink
 335         this.flags = FL_CLIENT | FL_NOTARGET;
 336         this.armorvalue = 666;
 337         this.effects = 0;
 338         this.armorvalue = autocvar_g_balance_armor_start;
 339         this.pauserotarmor_finished = 0;
 340         this.pauserothealth_finished = 0;
 341         this.pauseregen_finished = 0;
 342         this.damageforcescale = 0;
 343         this.death_time = 0;
 344         this.respawn_flags = 0;
 345         this.respawn_time = 0;
 346         STAT(RESPAWN_TIME, this) = 0;
 347         this.alpha = 0;
 348         this.scale = 0;
 349         this.fade_time = 0;
 350         this.pain_frame = 0;
 351         this.pain_finished = 0;
 352         this.strength_finished = 0;
 353         this.invincible_finished = 0;
 354         this.superweapons_finished = 0;
 355         this.dphitcontentsmask = 0;
 356         this.pushltime = 0;
 357         this.istypefrag = 0;
 358         setthink(this, func_null);
 359         this.nextthink = 0;
 360         this.deadflag = DEAD_NO;
 361         this.crouch = false;
 362         STAT(REVIVE_PROGRESS, this) = 0;
 363         this.revival_time = 0;
 364
 365         this.items = 0;
 366         STAT(WEAPONS, this) = '0 0 0';
 367         this.drawonlytoclient = this;
 368
 369         this.viewloc = NULL;
 370
 371         //this.spawnpoint_targ = NULL; // keep it so they can return to where they were?
 372
 373         this.weaponmodel = "";
 374         for (int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 375         {
 376                 this.weaponentities[slot] = NULL;
 377         }
 378         this.exteriorweaponentity = NULL;
 379         CS(this).killcount = FRAGS_SPECTATOR;
 380         this.velocity = '0 0 0';
 381         this.avelocity = '0 0 0';
 382         this.punchangle = '0 0 0';
 383         this.punchvector = '0 0 0';
 384         this.oldvelocity = this.velocity;
 385         this.fire_endtime = -1;
 386         this.event_damage = func_null;
 387
 388         for(int slot = 0; slot < MAX_AXH; ++slot)
 389         {
 390                 entity axh = this.(AuxiliaryXhair[slot]);
 391                 this.(AuxiliaryXhair[slot]) = NULL;
 392
 393                 if(axh.owner == this && axh != NULL && !wasfreed(axh))
 394                         delete(axh);
 395         }
 396 }
 397
 398 int player_getspecies(entity this)
 399 {
 400         get_model_parameters(this.model, this.skin);
 401         int s = get_model_parameters_species;
 402         get_model_parameters(string_null, 0);
 403         if (s < 0) return SPECIES_HUMAN;
 404         return s;
 405 }
 406
 407 .float model_randomizer;
 408 void FixPlayermodel(entity player)
 409 {
 410         string defaultmodel = "";
 411         int defaultskin = 0;
 412         if(autocvar_sv_defaultcharacter)
 413         {
 414                 if(teamplay)
 415                 {
 416                         switch(player.team)
 417                         {
 418                                 case NUM_TEAM_1: defaultmodel = autocvar_sv_defaultplayermodel_red; defaultskin = autocvar_sv_defaultplayerskin_red; break;
 419                                 case NUM_TEAM_2: defaultmodel = autocvar_sv_defaultplayermodel_blue; defaultskin = autocvar_sv_defaultplayerskin_blue; break;
 420                                 case NUM_TEAM_3: defaultmodel = autocvar_sv_defaultplayermodel_yellow; defaultskin = autocvar_sv_defaultplayerskin_yellow; break;
 421                                 case NUM_TEAM_4: defaultmodel = autocvar_sv_defaultplayermodel_pink; defaultskin = autocvar_sv_defaultplayerskin_pink; break;
 422                         }
 423                 }
 424
 425                 if(defaultmodel == "")
 426                 {
 427                         defaultmodel = autocvar_sv_defaultplayermodel;
 428                         defaultskin = autocvar_sv_defaultplayerskin;
 429                 }
 430
 431                 int n = tokenize_console(defaultmodel);
 432                 if(n > 0)
 433                 {
 434                         defaultmodel = argv(floor(n * CS(player).model_randomizer));
 435                         // However, do NOT randomize if the player-selected model is in the list.
 436                         for (int i = 0; i < n; ++i)
 437                                 if ((argv(i) == player.playermodel && defaultskin == stof(player.playerskin)) || argv(i) == strcat(player.playermodel, ":", player.playerskin))
 438                                         defaultmodel = argv(i);
 439                 }
 440
 441                 int i = strstrofs(defaultmodel, ":", 0);
 442                 if(i >= 0)
 443                 {
 444                         defaultskin = stof(substring(defaultmodel, i+1, -1));
 445                         defaultmodel = substring(defaultmodel, 0, i);
 446                 }
 447         }
 448         if(autocvar_sv_defaultcharacterskin && !defaultskin)
 449         {
 450                 if(teamplay)
 451                 {
 452                         switch(player.team)
 453                         {
 454                                 case NUM_TEAM_1: defaultskin = autocvar_sv_defaultplayerskin_red; break;
 455                                 case NUM_TEAM_2: defaultskin = autocvar_sv_defaultplayerskin_blue; break;
 456                                 case NUM_TEAM_3: defaultskin = autocvar_sv_defaultplayerskin_yellow; break;
 457                                 case NUM_TEAM_4: defaultskin = autocvar_sv_defaultplayerskin_pink; break;
 458                         }
 459                 }
 460
 461                 if(!defaultskin)
 462                         defaultskin = autocvar_sv_defaultplayerskin;
 463         }
 464
 465         MUTATOR_CALLHOOK(FixPlayermodel, defaultmodel, defaultskin, player);
 466         defaultmodel = M_ARGV(0, string);
 467         defaultskin = M_ARGV(1, int);
 468
 469         bool chmdl = false;
 470         int oldskin;
 471         if(defaultmodel != "")
 472         {
 473                 if (defaultmodel != player.model)
 474                 {
 475                         vector m1 = player.mins;
 476                         vector m2 = player.maxs;
 477                         setplayermodel (player, defaultmodel);
 478                         setsize (player, m1, m2);
 479                         chmdl = true;
 480                 }
 481
 482                 oldskin = player.skin;
 483                 player.skin = defaultskin;
 484         } else {
 485                 if (player.playermodel != player.model || player.playermodel == "")
 486                 {
 487                         player.playermodel = CheckPlayerModel(player.playermodel); // this is never "", so no endless loop
 488                         vector m1 = player.mins;
 489                         vector m2 = player.maxs;
 490                         setplayermodel (player, player.playermodel);
 491                         setsize (player, m1, m2);
 492                         chmdl = true;
 493                 }
 494
 495                 if(!autocvar_sv_defaultcharacterskin)
 496                 {
 497                         oldskin = player.skin;
 498                         player.skin = stof(player.playerskin);
 499                 }
 500                 else
 501                 {
 502                         oldskin = player.skin;
 503                         player.skin = defaultskin;
 504                 }
 505         }
 506
 507         if(chmdl || oldskin != player.skin) // model or skin has changed
 508         {
 509                 player.species = player_getspecies(player); // update species
 510                 if(!autocvar_g_debug_globalsounds)
 511                         UpdatePlayerSounds(player); // update skin sounds
 512         }
 513
 514         if(!teamplay)
 515                 if(strlen(autocvar_sv_defaultplayercolors))
 516                         if(player.clientcolors != stof(autocvar_sv_defaultplayercolors))
 517                                 setcolor(player, stof(autocvar_sv_defaultplayercolors));
 518 }
 519
 520 void PutPlayerInServer(entity this)
 521 {
 522         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
 523
 524         PlayerState_attach(this);
 525         accuracy_resend(this);
 526
 527         if (this.team < 0)
 528                 JoinBestTeam(this, true);
 529
 530         entity spot = SelectSpawnPoint(this, false);
 531         if (!spot) {
 532                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_JOIN_NOSPAWNS);
 533                 return; // spawn failed
 534         }
 535
 536         TRANSMUTE(Player, this);
 537
 538         CS(this).wasplayer = true;
 539         this.iscreature = true;
 540         this.teleportable = TELEPORT_NORMAL;
 541         if(!this.damagedbycontents)
 542                 IL_PUSH(g_damagedbycontents, this);
 543         this.damagedbycontents = true;
 544         set_movetype(this, MOVETYPE_WALK);
 545         this.solid = SOLID_SLIDEBOX;
 546         this.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_SOLID;
 547         if (autocvar_g_playerclip_collisions)
 548                 this.dphitcontentsmask |= DPCONTENTS_PLAYERCLIP;
 549         if (IS_BOT_CLIENT(this) && autocvar_g_botclip_collisions)
 550                 this.dphitcontentsmask |= DPCONTENTS_BOTCLIP;
 551         this.frags = FRAGS_PLAYER;
 552         if (INDEPENDENT_PLAYERS) MAKE_INDEPENDENT_PLAYER(this);
 553         this.flags = FL_CLIENT | FL_PICKUPITEMS;
 554         if (autocvar__notarget)
 555                 this.flags |= FL_NOTARGET;
 556         this.takedamage = DAMAGE_AIM;
 557         this.effects = EF_TELEPORT_BIT | EF_RESTARTANIM_BIT;
 558
 559         if (warmup_stage) {
 560                 SetResourceAmount(this, RESOURCE_SHELLS, warmup_start_ammo_shells);
 561                 SetResourceAmount(this, RESOURCE_BULLETS, warmup_start_ammo_nails);
 562                 SetResourceAmount(this, RESOURCE_ROCKETS, warmup_start_ammo_rockets);
 563                 SetResourceAmount(this, RESOURCE_CELLS, warmup_start_ammo_cells);
 564                 SetResourceAmount(this, RESOURCE_PLASMA, warmup_start_ammo_plasma);
 565                 SetResourceAmount(this, RESOURCE_FUEL, warmup_start_ammo_fuel);
 566                 this.health = warmup_start_health;
 567                 this.armorvalue = warmup_start_armorvalue;
 568                 STAT(WEAPONS, this) = WARMUP_START_WEAPONS;
 569         } else {
 570                 SetResourceAmount(this, RESOURCE_SHELLS, start_ammo_shells);
 571                 SetResourceAmount(this, RESOURCE_BULLETS, start_ammo_nails);
 572                 SetResourceAmount(this, RESOURCE_ROCKETS, start_ammo_rockets);
 573                 SetResourceAmount(this, RESOURCE_CELLS, start_ammo_cells);
 574                 SetResourceAmount(this, RESOURCE_PLASMA, start_ammo_plasma);
 575                 SetResourceAmount(this, RESOURCE_FUEL, start_ammo_fuel);
 576                 this.health = start_health;
 577                 this.armorvalue = start_armorvalue;
 578                 STAT(WEAPONS, this) = start_weapons;
 579                 if (MUTATOR_CALLHOOK(ForbidRandomStartWeapons, this) == false)
 580                 {
 581                         GiveRandomWeapons(this, random_start_weapons_count,
 582                                 autocvar_g_random_start_weapons, random_start_ammo);
 583                 }
 584         }
 585         SetSpectatee_status(this, 0);
 586
 587         PS(this).dual_weapons = '0 0 0';
 588
 589         this.superweapons_finished = (STAT(WEAPONS, this) & WEPSET_SUPERWEAPONS) ? time + autocvar_g_balance_superweapons_time : 0;
 590
 591         this.items = start_items;
 592
 593         this.spawnshieldtime = time + autocvar_g_spawnshieldtime;
 594         this.pauserotarmor_finished = time + autocvar_g_balance_pause_armor_rot_spawn;
 595         this.pauserothealth_finished = time + autocvar_g_balance_pause_health_rot_spawn;
 596         this.pauserotfuel_finished = time + autocvar_g_balance_pause_fuel_rot_spawn;
 597         this.pauseregen_finished = time + autocvar_g_balance_pause_health_regen_spawn;
 598         if (!sv_ready_restart_after_countdown && time < game_starttime)
 599         {
 600                 float f = game_starttime - time;
 601                 this.spawnshieldtime += f;
 602                 this.pauserotarmor_finished += f;
 603                 this.pauserothealth_finished += f;
 604                 this.pauseregen_finished += f;
 605         }
 606
 607         this.damageforcescale = 2;
 608         this.death_time = 0;
 609         this.respawn_flags = 0;
 610         this.respawn_time = 0;
 611         STAT(RESPAWN_TIME, this) = 0;
 612         this.scale = autocvar_sv_player_scale;
 613         this.fade_time = 0;
 614         this.pain_frame = 0;
 615         this.pain_finished = 0;
 616         this.pushltime = 0;
 617         setthink(this, func_null); // players have no think function
 618         this.nextthink = 0;
 619         this.dmg_team = 0;
 620         PS(this).ballistics_density = autocvar_g_ballistics_density_player;
 621
 622         this.deadflag = DEAD_NO;
 623
 624         this.angles = spot.angles;
 625         this.angles_z = 0; // never spawn tilted even if the spot says to
 626         if (IS_BOT_CLIENT(this))
 627                 this.v_angle = this.angles;
 628         this.fixangle = true; // turn this way immediately
 629         this.oldvelocity = this.velocity = '0 0 0';
 630         this.avelocity = '0 0 0';
 631         this.punchangle = '0 0 0';
 632         this.punchvector = '0 0 0';
 633
 634         this.strength_finished = 0;
 635         this.invincible_finished = 0;
 636         this.fire_endtime = -1;
 637         STAT(REVIVE_PROGRESS, this) = 0;
 638         this.revival_time = 0;
 639
 640         this.air_finished = time + 12;
 641         this.waterlevel = WATERLEVEL_NONE;
 642         this.watertype = CONTENT_EMPTY;
 643
 644         entity spawnevent = new_pure(spawnevent);
 645         spawnevent.owner = this;
 646         Net_LinkEntity(spawnevent, false, 0.5, SpawnEvent_Send);
 647
 648         // Cut off any still running player sounds.
 649         stopsound(this, CH_PLAYER_SINGLE);
 650
 651         this.model = "";
 652         FixPlayermodel(this);
 653         this.drawonlytoclient = NULL;
 654
 655         this.viewloc = NULL;
 656
 657         for(int slot = 0; slot < MAX_AXH; ++slot)
 658         {
 659                 entity axh = this.(AuxiliaryXhair[slot]);
 660                 this.(AuxiliaryXhair[slot]) = NULL;
 661
 662                 if(axh.owner == this && axh != NULL && !wasfreed(axh))
 663                         delete(axh);
 664         }
 665
 666         this.spawnpoint_targ = NULL;
 667
 668         this.crouch = false;
 669         this.view_ofs = STAT(PL_VIEW_OFS, this);
 670         setsize(this, STAT(PL_MIN, this), STAT(PL_MAX, this));
 671         this.spawnorigin = spot.origin;
 672         setorigin(this, spot.origin + '0 0 1' * (1 - this.mins.z - 24));
 673         // don't reset back to last position, even if new position is stuck in solid
 674         this.oldorigin = this.origin;
 675         if(this.conveyor)
 676                 IL_REMOVE(g_conveyed, this);
 677         this.conveyor = NULL; // prevent conveyors at the previous location from moving a freshly spawned player
 678         STAT(HUD, this) = HUD_NORMAL;
 679
 680         this.event_damage = PlayerDamage;
 681
 682         if(!this.bot_attack)
 683                 IL_PUSH(g_bot_targets, this);
 684         this.bot_attack = true;
 685         if(!this.monster_attack)
 686                 IL_PUSH(g_monster_targets, this);
 687         this.monster_attack = true;
 688         navigation_dynamicgoal_init(this, false);
 689
 690         PHYS_INPUT_BUTTON_ATCK(this) = PHYS_INPUT_BUTTON_JUMP(this) = PHYS_INPUT_BUTTON_ATCK2(this) = false;
 691
 692         // player was spectator
 693         if (CS(this).killcount == FRAGS_SPECTATOR) {
 694                 PlayerScore_Clear(this);
 695                 CS(this).killcount = 0;
 696                 CS(this).startplaytime = time;
 697         }
 698
 699         for (int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 700         {
 701                 .entity weaponentity = weaponentities[slot];
 702                 entity oldwep = this.(weaponentity);
 703                 CL_SpawnWeaponentity(this, weaponentity);
 704                 if(oldwep && oldwep.owner == this)
 705                         this.(weaponentity).m_gunalign = oldwep.m_gunalign;
 706         }
 707         this.alpha = default_player_alpha;
 708         this.colormod = '1 1 1' * autocvar_g_player_brightness;
 709         this.exteriorweaponentity.alpha = default_weapon_alpha;
 710
 711         this.speedrunning = false;
 712
 713         target_voicescript_clear(this);
 714
 715         // reset fields the weapons may use
 716         FOREACH(Weapons, true, {
 717                 it.wr_resetplayer(it, this);
 718                         // reload all reloadable weapons
 719                 if (it.spawnflags & WEP_FLAG_RELOADABLE) {
 720                         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 721                         {
 722                                 .entity weaponentity = weaponentities[slot];
 723                                 this.(weaponentity).weapon_load[it.m_id] = it.reloading_ammo;
 724                         }
 725                 }
 726         });
 727
 728         {
 729                 string s = spot.target;
 730                 spot.target = string_null;
 731                 SUB_UseTargets(spot, this, NULL);
 732                 spot.target = s;
 733         }
 734
 735         Unfreeze(this);
 736
 737         MUTATOR_CALLHOOK(PlayerSpawn, this, spot);
 738
 739         if (autocvar_spawn_debug)
 740         {
 741                 sprint(this, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
 742                 delete(spot); // usefull for checking if there are spawnpoints, that let drop through the floor
 743         }
 744
 745         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 746         {
 747                 .entity weaponentity = weaponentities[slot];
 748                 if(slot == 0 || autocvar_g_weaponswitch_debug == 1)
 749                         this.(weaponentity).m_switchweapon = w_getbestweapon(this, weaponentity);
 750                 else
 751                         this.(weaponentity).m_switchweapon = WEP_Null;
 752                 this.(weaponentity).m_weapon = WEP_Null;
 753                 this.(weaponentity).weaponname = "";
 754                 this.(weaponentity).m_switchingweapon = WEP_Null;
 755                 this.(weaponentity).cnt = -1;
 756         }
 757
 758         MUTATOR_CALLHOOK(PlayerWeaponSelect, this);
 759
 760         if (!warmup_stage && !this.alivetime)
 761                 this.alivetime = time;
 762
 763         antilag_clear(this, CS(this));
 764 }
 765
 766 /** Called when a client spawns in the server */
 767 void PutClientInServer(entity this)
 768 {
 769         if (IS_BOT_CLIENT(this)) {
 770                 TRANSMUTE(Player, this);
 771         } else if (IS_REAL_CLIENT(this)) {
 772                 msg_entity = this;
 773                 WriteByte(MSG_ONE, SVC_SETVIEW);
 774                 WriteEntity(MSG_ONE, this);
 775         }
 776         if (game_stopped)
 777                 TRANSMUTE(Observer, this);
 778
 779         SetSpectatee(this, NULL);
 780
 781         // reset player keys
 782         if(PS(this))
 783                 PS(this).itemkeys = 0;
 784
 785         MUTATOR_CALLHOOK(PutClientInServer, this);
 786
 787         if (IS_OBSERVER(this)) {
 788                 PutObserverInServer(this);
 789         } else if (IS_PLAYER(this)) {
 790                 PutPlayerInServer(this);
 791         }
 792 }
 793
 794 void ClientInit_misc(entity this);
 795
 796 // TODO do we need all these fields, or should we stop autodetecting runtime
 797 // changes and just have a console command to update this?
 798 bool ClientInit_SendEntity(entity this, entity to, int sf)
 799 {
 800         WriteHeader(MSG_ENTITY, _ENT_CLIENT_INIT);
 801         return = true;
 802         msg_entity = to;
 803         // MSG_INIT replacement
 804         // TODO: make easier to use
 805         Registry_send_all();
 806         W_PROP_reload(MSG_ONE, to);
 807         ClientInit_misc(this);
 808         MUTATOR_CALLHOOK(Ent_Init);
 809 }
 810 void ClientInit_misc(entity this)
 811 {
 812         int channel = MSG_ONE;
 813         WriteHeader(channel, ENT_CLIENT_INIT);
 814         WriteByte(channel, g_nexball_meter_period * 32);
 815         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[0]));
 816         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[1]));
 817         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[2]));
 818         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[3]));
 819         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[0]));
 820         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[1]));
 821         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[2]));
 822         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[3]));
 823
 824         if(sv_foginterval && world.fog != "")
 825                 WriteString(channel, world.fog);
 826         else
 827                 WriteString(channel, "");
 828         WriteByte(channel, this.count * 255.0); // g_balance_armor_blockpercent
 829         WriteByte(channel, this.cnt * 255.0); // g_balance_damagepush_speedfactor
 830         WriteByte(channel, serverflags);
 831         WriteCoord(channel, autocvar_g_trueaim_minrange);
 832 }
 833
 834 void ClientInit_CheckUpdate(entity this)
 835 {
 836         this.nextthink = time;
 837         if(this.count != autocvar_g_balance_armor_blockpercent)
 838         {
 839                 this.count = autocvar_g_balance_armor_blockpercent;
 840                 this.SendFlags |= 1;
 841         }
 842         if(this.cnt != autocvar_g_balance_damagepush_speedfactor)
 843         {
 844                 this.cnt = autocvar_g_balance_damagepush_speedfactor;
 845                 this.SendFlags |= 1;
 846         }
 847 }
 848
 849 void ClientInit_Spawn()
 850 {
 851         entity e = new_pure(clientinit);
 852         setthink(e, ClientInit_CheckUpdate);
 853         Net_LinkEntity(e, false, 0, ClientInit_SendEntity);
 854
 855         ClientInit_CheckUpdate(e);
 856 }
 857
 858 /*
 859 =============
 860 SetNewParms
 861 =============
 862 */
 863 void SetNewParms ()
 864 {
 865         // initialize parms for a new player
 866         parm1 = -(86400 * 366);
 867
 868         MUTATOR_CALLHOOK(SetNewParms);
 869 }
 870
 871 /*
 872 =============
 873 SetChangeParms
 874 =============
 875 */
 876 void SetChangeParms (entity this)
 877 {
 878         // save parms for level change
 879         parm1 = CS(this).parm_idlesince - time;
 880
 881         MUTATOR_CALLHOOK(SetChangeParms);
 882 }
 883
 884 /*
 885 =============
 886 DecodeLevelParms
 887 =============
 888 */
 889 void DecodeLevelParms(entity this)
 890 {
 891         // load parms
 892         CS(this).parm_idlesince = parm1;
 893         if (CS(this).parm_idlesince == -(86400 * 366))
 894                 CS(this).parm_idlesince = time;
 895
 896         // whatever happens, allow 60 seconds of idling directly after connect for map loading
 897         CS(this).parm_idlesince = max(CS(this).parm_idlesince, time - sv_maxidle + 60);
 898
 899         MUTATOR_CALLHOOK(DecodeLevelParms);
 900 }
 901
 902 /*
 903 =============
 904 ClientKill
 905
 906 Called when a client types 'kill' in the console
 907 =============
 908 */
 909
 910 .float clientkill_nexttime;
 911 void ClientKill_Now_TeamChange(entity this)
 912 {
 913         if(this.killindicator_teamchange == -1)
 914         {
 915                 JoinBestTeam( this, true );
 916         }
 917         else if(this.killindicator_teamchange == -2)
 918         {
 919                 if(blockSpectators)
 920                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
 921                 PutObserverInServer(this);
 922         }
 923         else
 924                 SV_ChangeTeam(this, this.killindicator_teamchange - 1);
 925         this.killindicator_teamchange = 0;
 926 }
 927
 928 void ClientKill_Now(entity this)
 929 {
 930         if(this.vehicle)
 931         {
 932             vehicles_exit(this.vehicle, VHEF_RELEASE);
 933             if(!this.killindicator_teamchange)
 934             {
 935             this.vehicle_health = -1;
 936             Damage(this, this, this, 1 , DEATH_KILL.m_id, DMG_NOWEP, this.origin, '0 0 0');
 937             }
 938         }
 939
 940         if(this.killindicator && !wasfreed(this.killindicator))
 941                 delete(this.killindicator);
 942
 943         this.killindicator = NULL;
 944
 945         if(this.killindicator_teamchange)
 946                 ClientKill_Now_TeamChange(this);
 947
 948         if (!IS_SPEC(this) && !IS_OBSERVER(this) && MUTATOR_CALLHOOK(ClientKill_Now, this) == false)
 949         {
 950                 Damage(this, this, this, 100000, DEATH_KILL.m_id, DMG_NOWEP, this.origin, '0 0 0');
 951         }
 952
 953         // now I am sure the player IS dead
 954 }
 955 void KillIndicator_Think(entity this)
 956 {
 957         if (game_stopped)
 958         {
 959                 this.owner.killindicator = NULL;
 960                 delete(this);
 961                 return;
 962         }
 963
 964         if (this.owner.alpha < 0 && !this.owner.vehicle)
 965         {
 966                 this.owner.killindicator = NULL;
 967                 delete(this);
 968                 return;
 969         }
 970
 971         if(this.cnt <= 0)
 972         {
 973                 ClientKill_Now(this.owner);
 974                 return;
 975         }
 976     else if(this.health == 1) // health == 1 means that it's silent
 977     {
 978         this.nextthink = time + 1;
 979         this.cnt -= 1;
 980     }
 981         else
 982         {
 983                 if(this.cnt <= 10)
 984                         setmodel(this, MDL_NUM(this.cnt));
 985                 if(IS_REAL_CLIENT(this.owner))
 986                 {
 987                         if(this.cnt <= 10)
 988                                 { Send_Notification(NOTIF_ONE, this.owner, MSG_ANNCE, Announcer_PickNumber(CNT_KILL, this.cnt)); }
 989                 }
 990                 this.nextthink = time + 1;
 991                 this.cnt -= 1;
 992         }
 993 }
 994
 995 float clientkilltime;
 996 void ClientKill_TeamChange (entity this, float targetteam) // 0 = don't change, -1 = auto, -2 = spec
 997 {
 998         float killtime;
 999         float starttime;
1000
1001         if (game_stopped)
1002                 return;
1003
1004         killtime = autocvar_g_balance_kill_delay;
1005
1006     if(MUTATOR_CALLHOOK(ClientKill, this, killtime))
1007         return;
1008     killtime = M_ARGV(1, float);
1009
1010         this.killindicator_teamchange = targetteam;
1011
1012     if(!this.killindicator)
1013         {
1014                 if(!IS_DEAD(this))
1015                 {
1016                         killtime = max(killtime, this.clientkill_nexttime - time);
1017                         this.clientkill_nexttime = time + killtime + autocvar_g_balance_kill_antispam;
1018                 }
1019
1020                 if(killtime <= 0 || !IS_PLAYER(this) || IS_DEAD(this))
1021                 {
1022                         ClientKill_Now(this);
1023                 }
1024                 else
1025                 {
1026                         starttime = max(time, clientkilltime);
1027
1028                         this.killindicator = spawn();
1029                         this.killindicator.owner = this;
1030                         this.killindicator.scale = 0.5;
1031                         setattachment(this.killindicator, this, "");
1032                         setorigin(this.killindicator, '0 0 52');
1033                         setthink(this.killindicator, KillIndicator_Think);
1034                         this.killindicator.nextthink = starttime + (this.lip) * 0.05;
1035                         clientkilltime = max(clientkilltime, this.killindicator.nextthink + 0.05);
1036                         this.killindicator.cnt = ceil(killtime);
1037                         this.killindicator.count = bound(0, ceil(killtime), 10);
1038                         //sprint(this, strcat("^1You'll be dead in ", ftos(this.killindicator.cnt), " seconds\n"));
1039
1040                         IL_EACH(g_clones, it.enemy == this && !(it.effects & CSQCMODEL_EF_RESPAWNGHOST),
1041                         {
1042                                 it.killindicator = spawn();
1043                                 it.killindicator.owner = it;
1044                                 it.killindicator.scale = 0.5;
1045                                 setattachment(it.killindicator, it, "");
1046                                 setorigin(it.killindicator, '0 0 52');
1047                                 setthink(it.killindicator, KillIndicator_Think);
1048                                 it.killindicator.nextthink = starttime + (it.lip) * 0.05;
1049                                 //clientkilltime = max(clientkilltime, it.killindicator.nextthink + 0.05);
1050                                 it.killindicator.cnt = ceil(killtime);
1051                         });
1052                         this.lip = 0;
1053                 }
1054         }
1055         if(this.killindicator)
1056         {
1057                 if(targetteam == 0) // just die
1058                 {
1059                         this.killindicator.colormod = '0 0 0';
1060                         if(IS_REAL_CLIENT(this))
1061                         if(this.killindicator.cnt > 0)
1062                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_TEAMCHANGE_SUICIDE, this.killindicator.cnt);
1063                 }
1064                 else if(targetteam == -1) // auto
1065                 {
1066                         this.killindicator.colormod = '0 1 0';
1067                         if(IS_REAL_CLIENT(this))
1068                         if(this.killindicator.cnt > 0)
1069                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_TEAMCHANGE_AUTO, this.killindicator.cnt);
1070                 }
1071                 else if(targetteam == -2) // spectate
1072                 {
1073                         this.killindicator.colormod = '0.5 0.5 0.5';
1074                         if(IS_REAL_CLIENT(this))
1075                         if(this.killindicator.cnt > 0)
1076                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_TEAMCHANGE_SPECTATE, this.killindicator.cnt);
1077                 }
1078                 else
1079                 {
1080                         this.killindicator.colormod = Team_ColorRGB(targetteam);
1081                         if(IS_REAL_CLIENT(this))
1082                         if(this.killindicator.cnt > 0)
1083                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, APP_TEAM_NUM(targetteam, CENTER_TEAMCHANGE), this.killindicator.cnt);
1084                 }
1085         }
1086
1087 }
1088
1089 void ClientKill (entity this)
1090 {
1091         if(game_stopped) return;
1092         if(this.player_blocked) return;
1093         if(STAT(FROZEN, this)) return;
1094
1095         ClientKill_TeamChange(this, 0);
1096 }
1097
1098 void FixClientCvars(entity e)
1099 {
1100         // send prediction settings to the client
1101         stuffcmd(e, "\nin_bindmap 0 0\n");
1102         if(autocvar_g_antilag == 3) // client side hitscan
1103                 stuffcmd(e, "cl_cmd settemp cl_prydoncursor_notrace 0\n");
1104         if(autocvar_sv_gentle)
1105                 stuffcmd(e, "cl_cmd settemp cl_gentle 1\n");
1106
1107         stuffcmd(e, sprintf("\ncl_jumpspeedcap_min \"%s\"\n", autocvar_sv_jumpspeedcap_min));
1108         stuffcmd(e, sprintf("\ncl_jumpspeedcap_max \"%s\"\n", autocvar_sv_jumpspeedcap_max));
1109
1110         stuffcmd(e, sprintf("\ncl_shootfromfixedorigin \"%s\"\n", autocvar_g_shootfromfixedorigin));
1111
1112         MUTATOR_CALLHOOK(FixClientCvars, e);
1113 }
1114
1115 bool findinlist_abbrev(string tofind, string list)
1116 {
1117         if(list == "" || tofind == "")
1118                 return false; // empty list or search, just return
1119
1120         // this function allows abbreviated strings!
1121         FOREACH_WORD(list, it == substring(tofind, 0, strlen(it)),
1122         {
1123                 return true;
1124         });
1125
1126         return false;
1127 }
1128
1129 bool PlayerInIPList(entity p, string iplist)
1130 {
1131         // some safety checks (never allow local?)
1132         if(p.netaddress == "local" || p.netaddress == "" || !IS_REAL_CLIENT(p))
1133                 return false;
1134
1135         return findinlist_abbrev(p.netaddress, iplist);
1136 }
1137
1138 bool PlayerInIDList(entity p, string idlist)
1139 {
1140         // NOTE: we do NOT check crypto_idfp_signed here, an unsigned ID is fine too for this
1141         if(!p.crypto_idfp)
1142                 return false;
1143
1144         return findinlist_abbrev(p.crypto_idfp, idlist);
1145 }
1146
1147 bool PlayerInList(entity player, string list)
1148 {
1149         return boolean(PlayerInIDList(player, list) || PlayerInIPList(player, list));
1150 }
1151
1152 #ifdef DP_EXT_PRECONNECT
1153 /*
1154 =============
1155 ClientPreConnect
1156
1157 Called once (not at each match start) when a client begins a connection to the server
1158 =============
1159 */
1160 void ClientPreConnect(entity this)
1161 {
1162         if(autocvar_sv_eventlog)
1163         {
1164                 GameLogEcho(sprintf(":connect:%d:%d:%s",
1165                         this.playerid,
1166                         etof(this),
1167                         ((IS_REAL_CLIENT(this)) ? this.netaddress : "bot")
1168                 ));
1169         }
1170 }
1171 #endif
1172
1173 /**
1174 =============
1175 ClientConnect
1176
1177 Called when a client connects to the server
1178 =============
1179 */
1180 void ClientConnect(entity this)
1181 {
1182         if (Ban_MaybeEnforceBanOnce(this)) return;
1183         assert(!IS_CLIENT(this), return);
1184         this.flags |= FL_CLIENT;
1185         assert(player_count >= 0, player_count = 0);
1186
1187 #ifdef WATERMARK
1188         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_WATERMARK, WATERMARK);
1189 #endif
1190         TRANSMUTE(Client, this);
1191         CS(this).version_nagtime = time + 10 + random() * 10;
1192
1193         // identify the right forced team
1194         if (autocvar_g_campaign)
1195         {
1196                 if (IS_REAL_CLIENT(this)) // only players, not bots
1197                 {
1198                         switch (autocvar_g_campaign_forceteam)
1199                         {
1200                                 case 1: this.team_forced = NUM_TEAM_1; break;
1201                                 case 2: this.team_forced = NUM_TEAM_2; break;
1202                                 case 3: this.team_forced = NUM_TEAM_3; break;
1203                                 case 4: this.team_forced = NUM_TEAM_4; break;
1204                                 default: this.team_forced = 0;
1205                         }
1206                 }
1207         }
1208         else if (PlayerInList(this, autocvar_g_forced_team_red))    this.team_forced = NUM_TEAM_1;
1209         else if (PlayerInList(this, autocvar_g_forced_team_blue))   this.team_forced = NUM_TEAM_2;
1210         else if (PlayerInList(this, autocvar_g_forced_team_yellow)) this.team_forced = NUM_TEAM_3;
1211         else if (PlayerInList(this, autocvar_g_forced_team_pink))   this.team_forced = NUM_TEAM_4;
1212         else switch (autocvar_g_forced_team_otherwise)
1213         {
1214                 default: this.team_forced = 0; break;
1215                 case "red": this.team_forced = NUM_TEAM_1; break;
1216                 case "blue": this.team_forced = NUM_TEAM_2; break;
1217                 case "yellow": this.team_forced = NUM_TEAM_3; break;
1218                 case "pink": this.team_forced = NUM_TEAM_4; break;
1219                 case "spectate":
1220                 case "spectator":
1221                         this.team_forced = -1;
1222                         break;
1223         }
1224         if (!teamplay && this.team_forced > 0) this.team_forced = 0;
1225
1226         int playerid_save = this.playerid;
1227         this.playerid = 0; // silent
1228         JoinBestTeam(this, false); // if the team number is valid, keep it
1229         this.playerid = playerid_save;
1230
1231         if (autocvar_sv_spectate || autocvar_g_campaign || this.team_forced < 0) {
1232                 TRANSMUTE(Observer, this);
1233         } else {
1234                 if (!teamplay || autocvar_g_balance_teams) {
1235                         TRANSMUTE(Player, this);
1236                         campaign_bots_may_start = true;
1237                 } else {
1238                         TRANSMUTE(Observer, this); // do it anyway
1239                 }
1240         }
1241
1242         PlayerStats_GameReport_AddEvent(sprintf("kills-%d", this.playerid));
1243
1244         // always track bots, don't ask for cl_allow_uidtracking
1245         if (IS_BOT_CLIENT(this))
1246                 PlayerStats_GameReport_AddPlayer(this);
1247         else
1248                 CS(this).allowed_timeouts = autocvar_sv_timeout_number;
1249
1250         if (autocvar_sv_eventlog)
1251                 GameLogEcho(strcat(":join:", ftos(this.playerid), ":", ftos(etof(this)), ":", ((IS_REAL_CLIENT(this)) ? this.netaddress : "bot"), ":", playername(this, false)));
1252
1253         LogTeamchange(this.playerid, this.team, 1);
1254
1255         CS(this).just_joined = true;  // stop spamming the eventlog with additional lines when the client connects
1256
1257         if(teamplay && IS_PLAYER(this))
1258                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, APP_TEAM_NUM(this.team, INFO_JOIN_CONNECT_TEAM), this.netname);
1259         else
1260                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_JOIN_CONNECT, this.netname);
1261
1262         stuffcmd(this, clientstuff, "\n");
1263         stuffcmd(this, "cl_particles_reloadeffects\n"); // TODO do we still need this?
1264
1265         FixClientCvars(this);
1266
1267         // get version info from player
1268         stuffcmd(this, "cmd clientversion $gameversion\n");
1269
1270         // notify about available teams
1271         if (teamplay)
1272         {
1273                 CheckAllowedTeams(this);
1274                 int t = 0;
1275                 if (c1 >= 0) t |= BIT(0);
1276                 if (c2 >= 0) t |= BIT(1);
1277                 if (c3 >= 0) t |= BIT(2);
1278                 if (c4 >= 0) t |= BIT(3);
1279                 stuffcmd(this, sprintf("set _teams_available %d\n", t));
1280         }
1281         else
1282         {
1283                 stuffcmd(this, "set _teams_available 0\n");
1284         }
1285
1286         bot_relinkplayerlist();
1287
1288         CS(this).spectatortime = time;
1289         if (blockSpectators)
1290         {
1291                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
1292         }
1293
1294         CS(this).jointime = time;
1295
1296         if (IS_REAL_CLIENT(this))
1297         {
1298                 if (g_weaponarena_weapons == WEPSET(TUBA))
1299                         stuffcmd(this, "cl_cmd settemp chase_active 1\n");
1300         }
1301
1302         if (!sv_foginterval && world.fog != "")
1303                 stuffcmd(this, strcat("\nfog ", world.fog, "\nr_fog_exp2 0\nr_drawfog 1\n"));
1304
1305         if (autocvar_sv_teamnagger && !(autocvar_bot_vs_human && AvailableTeams() == 2))
1306                 if(!MUTATOR_CALLHOOK(HideTeamNagger, this))
1307                         send_CSQC_teamnagger();
1308
1309         CSQCMODEL_AUTOINIT(this);
1310
1311         CS(this).model_randomizer = random();
1312
1313         if (IS_REAL_CLIENT(this))
1314                 sv_notice_join(this);
1315
1316         // update physics stats (players can spawn before physics runs)
1317         Physics_UpdateStats(this);
1318
1319         IL_EACH(g_initforplayer, it.init_for_player, {
1320                 it.init_for_player(it, this);
1321         });
1322
1323         Handicap_Initialize(this);
1324
1325         MUTATOR_CALLHOOK(ClientConnect, this);
1326
1327         if (IS_REAL_CLIENT(this))
1328         {
1329                 if (!autocvar_g_campaign && !IS_PLAYER(this))
1330                 {
1331                         CS(this).motd_actived_time = -1;
1332                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOTD, getwelcomemessage(this));
1333                 }
1334         }
1335 }
1336 /*
1337 =============
1338 ClientDisconnect
1339
1340 Called when a client disconnects from the server
1341 =============
1342 */
1343 .entity chatbubbleentity;
1344 void ReadyCount();
1345 void ClientDisconnect(entity this)
1346 {
1347         assert(IS_CLIENT(this), return);
1348
1349         PlayerStats_GameReport_FinalizePlayer(this);
1350         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
1351         if (CS(this).active_minigame) part_minigame(this);
1352         if (IS_PLAYER(this)) Send_Effect(EFFECT_SPAWN_NEUTRAL, this.origin, '0 0 0', 1);
1353
1354         if (autocvar_sv_eventlog)
1355                 GameLogEcho(strcat(":part:", ftos(this.playerid)));
1356
1357         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_QUIT_DISCONNECT, this.netname);
1358
1359         if(IS_SPEC(this))
1360                 SetSpectatee(this, NULL);
1361
1362     MUTATOR_CALLHOOK(ClientDisconnect, this);
1363
1364         strfree(CS(this).netname_previous); // needs to be before the CS entity is removed!
1365         strfree(CS(this).weaponorder_byimpulse);
1366         ClientState_detach(this);
1367
1368         Portal_ClearAll(this);
1369
1370         Unfreeze(this);
1371
1372         RemoveGrapplingHooks(this);
1373
1374         // Here, everything has been done that requires this player to be a client.
1375
1376         this.flags &= ~FL_CLIENT;
1377
1378         if (this.chatbubbleentity) delete(this.chatbubbleentity);
1379         if (this.killindicator) delete(this.killindicator);
1380
1381         WaypointSprite_PlayerGone(this);
1382
1383         bot_relinkplayerlist();
1384
1385         strfree(this.clientstatus);
1386         if (this.personal) delete(this.personal);
1387
1388         this.playerid = 0;
1389         ReadyCount();
1390         if (vote_called && IS_REAL_CLIENT(this)) VoteCount(false);
1391
1392         ONREMOVE(this);
1393 }
1394
1395 void ChatBubbleThink(entity this)
1396 {
1397         this.nextthink = time;
1398         if ((this.owner.alpha < 0) || this.owner.chatbubbleentity != this)
1399         {
1400                 if(this.owner) // but why can that ever be NULL?
1401                         this.owner.chatbubbleentity = NULL;
1402                 delete(this);
1403                 return;
1404         }
1405
1406         this.mdl = "";
1407
1408         if ( !IS_DEAD(this.owner) && IS_PLAYER(this.owner) )
1409         {
1410                 if ( CS(this.owner).active_minigame )
1411                         this.mdl = "models/sprites/minigame_busy.iqm";
1412                 else if (PHYS_INPUT_BUTTON_CHAT(this.owner))
1413                         this.mdl = "models/misc/chatbubble.spr";
1414         }
1415
1416         if ( this.model != this.mdl )
1417                 _setmodel(this, this.mdl);
1418
1419 }
1420
1421 void UpdateChatBubble(entity this)
1422 {
1423         if (this.alpha < 0)
1424                 return;
1425         // spawn a chatbubble entity if needed
1426         if (!this.chatbubbleentity)
1427         {
1428                 this.chatbubbleentity = new(chatbubbleentity);
1429                 this.chatbubbleentity.owner = this;
1430                 this.chatbubbleentity.exteriormodeltoclient = this;
1431                 setthink(this.chatbubbleentity, ChatBubbleThink);
1432                 this.chatbubbleentity.nextthink = time;
1433                 setmodel(this.chatbubbleentity, MDL_CHAT); // precision set below
1434                 //setorigin(this.chatbubbleentity, this.origin + '0 0 15' + this.maxs_z * '0 0 1');
1435                 setorigin(this.chatbubbleentity, '0 0 15' + this.maxs_z * '0 0 1');
1436                 setattachment(this.chatbubbleentity, this, "");  // sticks to moving player better, also conserves bandwidth
1437                 this.chatbubbleentity.mdl = this.chatbubbleentity.model;
1438                 //this.chatbubbleentity.model = "";
1439                 this.chatbubbleentity.effects = EF_LOWPRECISION;
1440         }
1441 }
1442
1443
1444 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
1445 // added to the model skins
1446 /*void UpdateColorModHack()
1447 {
1448         float c;
1449         c = this.clientcolors & 15;
1450         // LordHavoc: only bothering to support white, green, red, yellow, blue
1451              if (!teamplay) this.colormod = '0 0 0';
1452         else if (c ==  0) this.colormod = '1.00 1.00 1.00';
1453         else if (c ==  3) this.colormod = '0.10 1.73 0.10';
1454         else if (c ==  4) this.colormod = '1.73 0.10 0.10';
1455         else if (c == 12) this.colormod = '1.22 1.22 0.10';
1456         else if (c == 13) this.colormod = '0.10 0.10 1.73';
1457         else this.colormod = '1 1 1';
1458 }*/
1459
1460 void respawn(entity this)
1461 {
1462         if(this.alpha >= 0 && autocvar_g_respawn_ghosts)
1463         {
1464                 this.solid = SOLID_NOT;
1465                 this.takedamage = DAMAGE_NO;
1466                 set_movetype(this, MOVETYPE_FLY);
1467                 this.velocity = '0 0 1' * autocvar_g_respawn_ghosts_speed;
1468                 this.avelocity = randomvec() * autocvar_g_respawn_ghosts_speed * 3 - randomvec() * autocvar_g_respawn_ghosts_speed * 3;
1469                 this.effects |= CSQCMODEL_EF_RESPAWNGHOST;
1470                 Send_Effect(EFFECT_RESPAWN_GHOST, this.origin, '0 0 0', 1);
1471                 if(autocvar_g_respawn_ghosts_maxtime)
1472                         SUB_SetFade (this, time + autocvar_g_respawn_ghosts_maxtime / 2 + random () * (autocvar_g_respawn_ghosts_maxtime - autocvar_g_respawn_ghosts_maxtime / 2), 1.5);
1473         }
1474
1475         CopyBody(this, 1);
1476
1477         this.effects |= EF_NODRAW; // prevent another CopyBody
1478         PutClientInServer(this);
1479 }
1480
1481 void PrintToChat(entity client, string text)
1482 {
1483         text = strcat("\{1}^7", text, "\n");
1484         sprint(client, text);
1485 }
1486
1487 void DebugPrintToChat(entity client, string text)
1488 {
1489         if (autocvar_developer)
1490         {
1491                 PrintToChat(client, text);
1492         }
1493 }
1494
1495 void PrintToChatAll(string text)
1496 {
1497         text = strcat("\{1}^7", text, "\n");
1498         bprint(text);
1499 }
1500
1501 void DebugPrintToChatAll(string text)
1502 {
1503         if (autocvar_developer)
1504         {
1505                 PrintToChatAll(text);
1506         }
1507 }
1508
1509 void PrintToChatTeam(int team_num, string text)
1510 {
1511         text = strcat("\{1}^7", text, "\n");
1512         FOREACH_CLIENT(IS_REAL_CLIENT(it),
1513         {
1514                 if (it.team == team_num)
1515                 {
1516                         sprint(it, text);
1517                 }
1518         });
1519 }
1520
1521 void DebugPrintToChatTeam(int team_num, string text)
1522 {
1523         if (autocvar_developer)
1524         {
1525                 PrintToChatTeam(team_num, text);
1526         }
1527 }
1528
1529 void play_countdown(entity this, float finished, Sound samp)
1530 {
1531     TC(Sound, samp);
1532         if(IS_REAL_CLIENT(this))
1533                 if(floor(finished - time - frametime) != floor(finished - time))
1534                         if(finished - time < 6)
1535                                 sound (this, CH_INFO, samp, VOL_BASE, ATTEN_NORM);
1536 }
1537
1538 void player_powerups(entity this)
1539 {
1540         // add a way to see what the items were BEFORE all of these checks for the mutator hook
1541         int items_prev = this.items;
1542
1543         if((this.items & IT_USING_JETPACK) && !IS_DEAD(this) && !game_stopped)
1544                 this.modelflags |= MF_ROCKET;
1545         else
1546                 this.modelflags &= ~MF_ROCKET;
1547
1548         this.effects &= ~(EF_RED | EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT | EF_FLAME | EF_NODEPTHTEST);
1549
1550         if((this.alpha < 0 || IS_DEAD(this)) && !this.vehicle) // don't apply the flags if the player is gibbed
1551                 return;
1552
1553         Fire_ApplyDamage(this);
1554         Fire_ApplyEffect(this);
1555
1556         if (!MUTATOR_IS_ENABLED(mutator_instagib))
1557         {
1558                 if (this.items & ITEM_Strength.m_itemid)
1559                 {
1560                         play_countdown(this, this.strength_finished, SND_POWEROFF);
1561                         this.effects = this.effects | (EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT);
1562                         if (time > this.strength_finished)
1563                         {
1564                                 this.items = this.items - (this.items & ITEM_Strength.m_itemid);
1565                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERDOWN_STRENGTH, this.netname);
1566                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERDOWN_STRENGTH);
1567                         }
1568                 }
1569                 else
1570                 {
1571                         if (time < this.strength_finished)
1572                         {
1573                                 this.items = this.items | ITEM_Strength.m_itemid;
1574                                 if(!g_cts)
1575                                         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERUP_STRENGTH, this.netname);
1576                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERUP_STRENGTH);
1577                         }
1578                 }
1579                 if (this.items & ITEM_Shield.m_itemid)
1580                 {
1581                         play_countdown(this, this.invincible_finished, SND_POWEROFF);
1582                         this.effects = this.effects | (EF_RED | EF_ADDITIVE | EF_FULLBRIGHT);
1583                         if (time > this.invincible_finished)
1584                         {
1585                                 this.items = this.items - (this.items & ITEM_Shield.m_itemid);
1586                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERDOWN_SHIELD, this.netname);
1587                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERDOWN_SHIELD);
1588                         }
1589                 }
1590                 else
1591                 {
1592                         if (time < this.invincible_finished)
1593                         {
1594                                 this.items = this.items | ITEM_Shield.m_itemid;
1595                                 if(!g_cts)
1596                                         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERUP_SHIELD, this.netname);
1597                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERUP_SHIELD);
1598                         }
1599                 }
1600                 if (this.items & IT_SUPERWEAPON)
1601                 {
1602                         if (!(STAT(WEAPONS, this) & WEPSET_SUPERWEAPONS))
1603                         {
1604                                 this.superweapons_finished = 0;
1605                                 this.items = this.items - (this.items & IT_SUPERWEAPON);
1606                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_LOST, this.netname);
1607                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_LOST);
1608                         }
1609                         else if (this.items & IT_UNLIMITED_SUPERWEAPONS)
1610                         {
1611                                 // don't let them run out
1612                         }
1613                         else
1614                         {
1615                                 play_countdown(this, this.superweapons_finished, SND_POWEROFF);
1616                                 if (time > this.superweapons_finished)
1617                                 {
1618                                         this.items = this.items - (this.items & IT_SUPERWEAPON);
1619                                         STAT(WEAPONS, this) &= ~WEPSET_SUPERWEAPONS;
1620                                         //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_BROKEN, this.netname);
1621                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_BROKEN);
1622                                 }
1623                         }
1624                 }
1625                 else if(STAT(WEAPONS, this) & WEPSET_SUPERWEAPONS)
1626                 {
1627                         if (time < this.superweapons_finished || (this.items & IT_UNLIMITED_SUPERWEAPONS))
1628                         {
1629                                 this.items = this.items | IT_SUPERWEAPON;
1630                                 if(!g_cts)
1631                                         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_PICKUP, this.netname);
1632                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_PICKUP);
1633                         }
1634                         else
1635                         {
1636                                 this.superweapons_finished = 0;
1637                                 STAT(WEAPONS, this) &= ~WEPSET_SUPERWEAPONS;
1638                         }
1639                 }
1640                 else
1641                 {
1642                         this.superweapons_finished = 0;
1643                 }
1644         }
1645
1646         if(autocvar_g_nodepthtestplayers)
1647                 this.effects = this.effects | EF_NODEPTHTEST;
1648
1649         if(autocvar_g_fullbrightplayers)
1650                 this.effects = this.effects | EF_FULLBRIGHT;
1651
1652         if (time >= game_starttime)
1653         if (time < this.spawnshieldtime)
1654                 this.effects = this.effects | (EF_ADDITIVE | EF_FULLBRIGHT);
1655
1656         MUTATOR_CALLHOOK(PlayerPowerups, this, items_prev);
1657 }
1658
1659 float CalcRegen(float current, float stable, float regenfactor, float regenframetime)
1660 {
1661         if(current > stable)
1662                 return current;
1663         else if(current > stable - 0.25) // when close enough, "snap"
1664                 return stable;
1665         else
1666                 return min(stable, current + (stable - current) * regenfactor * regenframetime);
1667 }
1668
1669 float CalcRot(float current, float stable, float rotfactor, float rotframetime)
1670 {
1671         if(current < stable)
1672                 return current;
1673         else if(current < stable + 0.25) // when close enough, "snap"
1674                 return stable;
1675         else
1676                 return max(stable, current + (stable - current) * rotfactor * rotframetime);
1677 }
1678
1679 float CalcRotRegen(float current, float regenstable, float regenfactor, float regenlinear, float regenframetime, float rotstable, float rotfactor, float rotlinear, float rotframetime, float limit)
1680 {
1681         if(current > rotstable)
1682         {
1683                 if(rotframetime > 0)
1684                 {
1685                         current = CalcRot(current, rotstable, rotfactor, rotframetime);
1686                         current = max(rotstable, current - rotlinear * rotframetime);
1687                 }
1688         }
1689         else if(current < regenstable)
1690         {
1691                 if(regenframetime > 0)
1692                 {
1693                         current = CalcRegen(current, regenstable, regenfactor, regenframetime);
1694                         current = min(regenstable, current + regenlinear * regenframetime);
1695                 }
1696         }
1697
1698         if(current > limit)
1699                 current = limit;
1700
1701         return current;
1702 }
1703
1704 void player_regen(entity this)
1705 {
1706         float max_mod, regen_mod, rot_mod, limit_mod;
1707         max_mod = regen_mod = rot_mod = limit_mod = 1;
1708
1709         float regen_health = autocvar_g_balance_health_regen;
1710         float regen_health_linear = autocvar_g_balance_health_regenlinear;
1711         float regen_health_rot = autocvar_g_balance_health_rot;
1712         float regen_health_rotlinear = autocvar_g_balance_health_rotlinear;
1713         float regen_health_stable = autocvar_g_balance_health_regenstable;
1714         float regen_health_rotstable = autocvar_g_balance_health_rotstable;
1715         bool mutator_returnvalue = MUTATOR_CALLHOOK(PlayerRegen, this, max_mod, regen_mod, rot_mod, limit_mod, regen_health, regen_health_linear, regen_health_rot,
1716                 regen_health_rotlinear, regen_health_stable, regen_health_rotstable);
1717         max_mod = M_ARGV(1, float);
1718         regen_mod = M_ARGV(2, float);
1719         rot_mod = M_ARGV(3, float);
1720         limit_mod = M_ARGV(4, float);
1721         regen_health = M_ARGV(5, float);
1722         regen_health_linear = M_ARGV(6, float);
1723         regen_health_rot = M_ARGV(7, float);
1724         regen_health_rotlinear = M_ARGV(8, float);
1725         regen_health_stable = M_ARGV(9, float);
1726         regen_health_rotstable = M_ARGV(10, float);
1727
1728         if(!mutator_returnvalue)
1729         if(!STAT(FROZEN, this))
1730         {
1731                 float mina, maxa, limith, limita;
1732                 maxa = autocvar_g_balance_armor_rotstable;
1733                 mina = autocvar_g_balance_armor_regenstable;
1734                 limith = GetResourceLimit(this, RESOURCE_HEALTH);
1735                 limita = GetResourceLimit(this, RESOURCE_ARMOR);
1736
1737                 regen_health_rotstable = regen_health_rotstable * max_mod;
1738                 regen_health_stable = regen_health_stable * max_mod;
1739                 limith = limith * limit_mod;
1740                 limita = limita * limit_mod;
1741
1742                 this.armorvalue = CalcRotRegen(this.armorvalue, mina, autocvar_g_balance_armor_regen, autocvar_g_balance_armor_regenlinear, regen_mod * frametime * (time > this.pauseregen_finished), maxa, autocvar_g_balance_armor_rot, autocvar_g_balance_armor_rotlinear, rot_mod * frametime * (time > this.pauserotarmor_finished), limita);
1743                 this.health = CalcRotRegen(this.health, regen_health_stable, regen_health, regen_health_linear, regen_mod * frametime * (time > this.pauseregen_finished), regen_health_rotstable, regen_health_rot, regen_health_rotlinear, rot_mod * frametime * (time > this.pauserothealth_finished), limith);
1744         }
1745
1746         // if player rotted to death...  die!
1747         // check this outside above checks, as player may still be able to rot to death
1748         if(this.health < 1)
1749         {
1750                 if(this.vehicle)
1751                         vehicles_exit(this.vehicle, VHEF_RELEASE);
1752                 if(this.event_damage)
1753                         this.event_damage(this, this, this, 1, DEATH_ROT.m_id, DMG_NOWEP, this.origin, '0 0 0');
1754         }
1755
1756         if (!(this.items & IT_UNLIMITED_WEAPON_AMMO))
1757         {
1758                 float minf, maxf, limitf;
1759
1760                 maxf = autocvar_g_balance_fuel_rotstable;
1761                 minf = autocvar_g_balance_fuel_regenstable;
1762                 limitf = GetResourceLimit(this, RESOURCE_FUEL);
1763
1764                 this.ammo_fuel = CalcRotRegen(this.ammo_fuel, minf, autocvar_g_balance_fuel_regen, autocvar_g_balance_fuel_regenlinear, frametime * (time > this.pauseregen_finished) * ((this.items & ITEM_JetpackRegen.m_itemid) != 0), maxf, autocvar_g_balance_fuel_rot, autocvar_g_balance_fuel_rotlinear, frametime * (time > this.pauserotfuel_finished), limitf);
1765         }
1766         // Ugly hack to make sure the health and armor don't go beyond hard limit.
1767         // TODO: Remove this hack when all code uses GivePlayerHealth and
1768         // GivePlayerArmor.
1769         if (this.health > RESOURCE_AMOUNT_HARD_LIMIT)
1770         {
1771                 this.health = RESOURCE_AMOUNT_HARD_LIMIT;
1772         }
1773         if (this.armorvalue > RESOURCE_AMOUNT_HARD_LIMIT)
1774         {
1775                 this.armorvalue = RESOURCE_AMOUNT_HARD_LIMIT;
1776         }
1777         // End hack.
1778 }
1779
1780 bool zoomstate_set;
1781 void SetZoomState(entity this, float newzoom)
1782 {
1783         if(newzoom != CS(this).zoomstate)
1784         {
1785                 CS(this).zoomstate = newzoom;
1786                 ClientData_Touch(this);
1787         }
1788         zoomstate_set = true;
1789 }
1790
1791 void GetPressedKeys(entity this)
1792 {
1793         MUTATOR_CALLHOOK(GetPressedKeys, this);
1794         int keys = STAT(PRESSED_KEYS, this);
1795         keys = BITSET(keys, KEY_FORWARD,        CS(this).movement.x > 0);
1796         keys = BITSET(keys, KEY_BACKWARD,       CS(this).movement.x < 0);
1797         keys = BITSET(keys, KEY_RIGHT,          CS(this).movement.y > 0);
1798         keys = BITSET(keys, KEY_LEFT,           CS(this).movement.y < 0);
1799
1800         keys = BITSET(keys, KEY_JUMP,           PHYS_INPUT_BUTTON_JUMP(this));
1801         keys = BITSET(keys, KEY_CROUCH,         PHYS_INPUT_BUTTON_CROUCH(this));
1802         keys = BITSET(keys, KEY_ATCK,           PHYS_INPUT_BUTTON_ATCK(this));
1803         keys = BITSET(keys, KEY_ATCK2,          PHYS_INPUT_BUTTON_ATCK2(this));
1804         CS(this).pressedkeys = keys; // store for other users
1805
1806         STAT(PRESSED_KEYS, this) = keys;
1807 }
1808
1809 /*
1810 ======================
1811 spectate mode routines
1812 ======================
1813 */
1814
1815 void SpectateCopy(entity this, entity spectatee)
1816 {
1817     TC(Client, this); TC(Client, spectatee);
1818
1819         MUTATOR_CALLHOOK(SpectateCopy, spectatee, this);
1820         PS(this) = PS(spectatee);
1821         this.armortype = spectatee.armortype;
1822         this.armorvalue = spectatee.armorvalue;
1823         this.ammo_cells = spectatee.ammo_cells; // TODO: these will be a part of inventory, so no need to worry about setting them later!
1824         this.ammo_plasma = spectatee.ammo_plasma;
1825         this.ammo_shells = spectatee.ammo_shells;
1826         this.ammo_nails = spectatee.ammo_nails;
1827         this.ammo_rockets = spectatee.ammo_rockets;
1828         this.ammo_fuel = spectatee.ammo_fuel;
1829         this.effects = spectatee.effects & EFMASK_CHEAP; // eat performance
1830         this.health = spectatee.health;
1831         CS(this).impulse = 0;
1832         this.items = spectatee.items;
1833         STAT(LAST_PICKUP, this) = STAT(LAST_PICKUP, spectatee);
1834         STAT(HIT_TIME, this) = STAT(HIT_TIME, spectatee);
1835         this.strength_finished = spectatee.strength_finished;
1836         this.invincible_finished = spectatee.invincible_finished;
1837         this.superweapons_finished = spectatee.superweapons_finished;
1838         STAT(PRESSED_KEYS, this) = STAT(PRESSED_KEYS, spectatee);
1839         STAT(WEAPONS, this) = STAT(WEAPONS, spectatee);
1840         this.punchangle = spectatee.punchangle;
1841         this.view_ofs = spectatee.view_ofs;
1842         this.velocity = spectatee.velocity;
1843         this.dmg_take = spectatee.dmg_take;
1844         this.dmg_save = spectatee.dmg_save;
1845         this.dmg_inflictor = spectatee.dmg_inflictor;
1846         this.v_angle = spectatee.v_angle;
1847         this.angles = spectatee.v_angle;
1848         STAT(FROZEN, this) = STAT(FROZEN, spectatee);
1849         STAT(REVIVE_PROGRESS, this) = STAT(REVIVE_PROGRESS, spectatee);
1850         this.viewloc = spectatee.viewloc;
1851         if(!PHYS_INPUT_BUTTON_USE(this) && STAT(CAMERA_SPECTATOR, this) != 2)
1852                 this.fixangle = true;
1853         setorigin(this, spectatee.origin);
1854         setsize(this, spectatee.mins, spectatee.maxs);
1855         SetZoomState(this, CS(spectatee).zoomstate);
1856
1857     anticheat_spectatecopy(this, spectatee);
1858         STAT(HUD, this) = STAT(HUD, spectatee);
1859         if(spectatee.vehicle)
1860     {
1861         this.angles = spectatee.v_angle;
1862
1863         //this.fixangle = false;
1864         //this.velocity = spectatee.vehicle.velocity;
1865         this.vehicle_health = spectatee.vehicle_health;
1866         this.vehicle_shield = spectatee.vehicle_shield;
1867         this.vehicle_energy = spectatee.vehicle_energy;
1868         this.vehicle_ammo1 = spectatee.vehicle_ammo1;
1869         this.vehicle_ammo2 = spectatee.vehicle_ammo2;
1870         this.vehicle_reload1 = spectatee.vehicle_reload1;
1871         this.vehicle_reload2 = spectatee.vehicle_reload2;
1872
1873         //msg_entity = this;
1874
1875        // WriteByte (MSG_ONE, SVC_SETVIEWANGLES);
1876             //WriteAngle(MSG_ONE,  spectatee.v_angle.x);
1877            // WriteAngle(MSG_ONE,  spectatee.v_angle.y);
1878            // WriteAngle(MSG_ONE,  spectatee.v_angle.z);
1879
1880         //WriteByte (MSG_ONE, SVC_SETVIEW);
1881         //    WriteEntity(MSG_ONE, this);
1882         //makevectors(spectatee.v_angle);
1883         //setorigin(this, spectatee.origin - v_forward * 400 + v_up * 300);*/
1884     }
1885 }
1886
1887 bool SpectateUpdate(entity this)
1888 {
1889         if(!this.enemy)
1890                 return false;
1891
1892         if(!IS_PLAYER(this.enemy) || this == this.enemy)
1893         {
1894                 SetSpectatee(this, NULL);
1895                 return false;
1896         }
1897
1898         SpectateCopy(this, this.enemy);
1899
1900         return true;
1901 }
1902
1903 bool SpectateSet(entity this)
1904 {
1905         if(!IS_PLAYER(this.enemy))
1906                 return false;
1907
1908         ClientData_Touch(this.enemy);
1909
1910         msg_entity = this;
1911         WriteByte(MSG_ONE, SVC_SETVIEW);
1912         WriteEntity(MSG_ONE, this.enemy);
1913         set_movetype(this, MOVETYPE_NONE);
1914         accuracy_resend(this);
1915
1916         if(!SpectateUpdate(this))
1917                 PutObserverInServer(this);
1918
1919         return true;
1920 }
1921
1922 void SetSpectatee_status(entity this, int spectatee_num)
1923 {
1924         int oldspectatee_status = CS(this).spectatee_status;
1925         CS(this).spectatee_status = spectatee_num;
1926
1927         if (CS(this).spectatee_status != oldspectatee_status)
1928         {
1929                 ClientData_Touch(this);
1930                 if (g_race || g_cts) race_InitSpectator();
1931         }
1932 }
1933
1934 void SetSpectatee(entity this, entity spectatee)
1935 {
1936         if(IS_BOT_CLIENT(this))
1937                 return; // bots abuse .enemy, this code is useless to them
1938
1939         entity old_spectatee = this.enemy;
1940
1941         this.enemy = spectatee;
1942
1943         // WEAPONTODO
1944         // these are required to fix the spectator bug with arc
1945         if(old_spectatee)
1946         {
1947                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1948                 {
1949                         .entity weaponentity = weaponentities[slot];
1950                         if(old_spectatee.(weaponentity).arc_beam)
1951                                 old_spectatee.(weaponentity).arc_beam.SendFlags |= ARC_SF_SETTINGS;
1952                 }
1953         }
1954         if(this.enemy)
1955         {
1956                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1957                 {
1958                         .entity weaponentity = weaponentities[slot];
1959                         if(this.enemy.(weaponentity).arc_beam)
1960                                 this.enemy.(weaponentity).arc_beam.SendFlags |= ARC_SF_SETTINGS;
1961                 }
1962         }
1963
1964         if (this.enemy)
1965                 SetSpectatee_status(this, etof(this.enemy));
1966
1967         // needed to update spectator list
1968         if(old_spectatee) { ClientData_Touch(old_spectatee); }
1969 }
1970
1971 bool Spectate(entity this, entity pl)
1972 {
1973         if(MUTATOR_CALLHOOK(SpectateSet, this, pl))
1974                 return false;
1975         pl = M_ARGV(1, entity);
1976
1977         SetSpectatee(this, pl);
1978         return SpectateSet(this);
1979 }
1980
1981 bool SpectateNext(entity this)
1982 {
1983         entity ent = find(this.enemy, classname, STR_PLAYER);
1984
1985         if (MUTATOR_CALLHOOK(SpectateNext, this, ent))
1986                 ent = M_ARGV(1, entity);
1987         else if (!ent)
1988                 ent = find(ent, classname, STR_PLAYER);
1989
1990         if(ent) { SetSpectatee(this, ent); }
1991
1992         return SpectateSet(this);
1993 }
1994
1995 bool SpectatePrev(entity this)
1996 {
1997         // NOTE: chain order is from the highest to the lower entnum (unlike find)
1998         entity ent = findchain(classname, STR_PLAYER);
1999         if (!ent) // no player
2000                 return false;
2001
2002         entity first = ent;
2003         // skip players until current spectated player
2004         if(this.enemy)
2005         while(ent && ent != this.enemy)
2006                 ent = ent.chain;
2007
2008         switch (MUTATOR_CALLHOOK(SpectatePrev, this, ent, first))
2009         {
2010                 case MUT_SPECPREV_FOUND:
2011                     ent = M_ARGV(1, entity);
2012                     break;
2013                 case MUT_SPECPREV_RETURN:
2014                     return true;
2015                 case MUT_SPECPREV_CONTINUE:
2016                 default:
2017                 {
2018                         if(ent.chain)
2019                                 ent = ent.chain;
2020                         else
2021                                 ent = first;
2022                         break;
2023                 }
2024         }
2025
2026         SetSpectatee(this, ent);
2027         return SpectateSet(this);
2028 }
2029
2030 /*
2031 =============
2032 ShowRespawnCountdown()
2033
2034 Update a respawn countdown display.
2035 =============
2036 */
2037 void ShowRespawnCountdown(entity this)
2038 {
2039         float number;
2040         if(!IS_DEAD(this)) // just respawned?
2041                 return;
2042         else
2043         {
2044                 number = ceil(this.respawn_time - time);
2045                 if(number <= 0)
2046                         return;
2047                 if(number <= this.respawn_countdown)
2048                 {
2049                         this.respawn_countdown = number - 1;
2050                         if(ceil(this.respawn_time - (time + 0.5)) == number) // only say it if it is the same number even in 0.5s; to prevent overlapping sounds
2051                                 { Send_Notification(NOTIF_ONE, this, MSG_ANNCE, Announcer_PickNumber(CNT_RESPAWN, number)); }
2052                 }
2053         }
2054 }
2055
2056 .bool team_selected;
2057 bool ShowTeamSelection(entity this)
2058 {
2059         if(!teamplay || autocvar_g_campaign || autocvar_g_balance_teams || this.team_selected || (CS(this).wasplayer && autocvar_g_changeteam_banned) || this.team_forced > 0)
2060                 return false;
2061         stuffcmd(this, "menu_showteamselect\n");
2062         return true;
2063 }
2064 void Join(entity this)
2065 {
2066         TRANSMUTE(Player, this);
2067
2068         if(!this.team_selected)
2069         if(autocvar_g_campaign || autocvar_g_balance_teams)
2070                 JoinBestTeam(this, true);
2071
2072         if(autocvar_g_campaign)
2073                 campaign_bots_may_start = true;
2074
2075         Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_PREVENT_JOIN);
2076
2077         PutClientInServer(this);
2078
2079         if(IS_PLAYER(this))
2080         if(teamplay && this.team != -1)
2081                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, APP_TEAM_NUM(this.team, INFO_JOIN_PLAY_TEAM), this.netname);
2082         else
2083                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_JOIN_PLAY, this.netname);
2084         this.team_selected = false;
2085 }
2086
2087 /**
2088  * Determines whether the player is allowed to join. This depends on cvar
2089  * g_maxplayers, if it isn't used this function always return true, otherwise
2090  * it checks whether the number of currently playing players exceeds g_maxplayers.
2091  * @return int number of free slots for players, 0 if none
2092  */
2093 int nJoinAllowed(entity this, entity ignore)
2094 {
2095         if(!ignore)
2096         // this is called that way when checking if anyone may be able to join (to build qcstatus)
2097         // so report 0 free slots if restricted
2098         {
2099                 if(autocvar_g_forced_team_otherwise == "spectate")
2100                         return 0;
2101                 if(autocvar_g_forced_team_otherwise == "spectator")
2102                         return 0;
2103         }
2104
2105         if(this && this.team_forced < 0)
2106                 return 0; // forced spectators can never join
2107
2108         // TODO simplify this
2109         int totalClients = 0;
2110         int currentlyPlaying = 0;
2111         FOREACH_CLIENT(true, {
2112                 if(it != ignore)
2113                         ++totalClients;
2114                 if(IS_REAL_CLIENT(it))
2115                 if(IS_PLAYER(it) || it.caplayer)
2116                         ++currentlyPlaying;
2117         });
2118
2119         float free_slots = 0;
2120         if (!autocvar_g_maxplayers)
2121                 free_slots = maxclients - totalClients;
2122         else if(currentlyPlaying < autocvar_g_maxplayers)
2123                 free_slots = min(maxclients - totalClients, autocvar_g_maxplayers - currentlyPlaying);
2124
2125         static float join_prevent_msg_time = 0;
2126         if(this && ignore && !free_slots && time > join_prevent_msg_time)
2127         {
2128                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_JOIN_PREVENT);
2129                 join_prevent_msg_time = time + 3;
2130         }
2131
2132         return free_slots;
2133 }
2134
2135 /**
2136  * Checks whether the client is an observer or spectator, if so, he will get kicked after
2137  * g_maxplayers_spectator_blocktime seconds
2138  */
2139 void checkSpectatorBlock(entity this)
2140 {
2141         if(IS_SPEC(this) || IS_OBSERVER(this))
2142         if(!this.caplayer)
2143         if(IS_REAL_CLIENT(this))
2144         {
2145                 if( time > (CS(this).spectatortime + autocvar_g_maxplayers_spectator_blocktime) ) {
2146                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_QUIT_KICK_SPECTATING);
2147                         dropclient(this);
2148                 }
2149         }
2150 }
2151
2152 void PrintWelcomeMessage(entity this)
2153 {
2154         if(CS(this).motd_actived_time == 0)
2155         {
2156                 if (autocvar_g_campaign) {
2157                         if ((IS_PLAYER(this) && PHYS_INPUT_BUTTON_INFO(this)) || (!IS_PLAYER(this))) {
2158                                 CS(this).motd_actived_time = time;
2159                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOTD, campaign_message);
2160                         }
2161                 } else {
2162                         if (PHYS_INPUT_BUTTON_INFO(this)) {
2163                                 CS(this).motd_actived_time = time;
2164                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOTD, getwelcomemessage(this));
2165                         }
2166                 }
2167         }
2168         else if(CS(this).motd_actived_time > 0) // showing MOTD or campaign message
2169         {
2170                 if (autocvar_g_campaign) {
2171                         if (PHYS_INPUT_BUTTON_INFO(this))
2172                                 CS(this).motd_actived_time = time;
2173                         else if ((time - CS(this).motd_actived_time > 2) && IS_PLAYER(this)) { // hide it some seconds after BUTTON_INFO has been released
2174                                 CS(this).motd_actived_time = 0;
2175                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_MOTD);
2176                         }
2177                 } else {
2178                         if (PHYS_INPUT_BUTTON_INFO(this))
2179                                 CS(this).motd_actived_time = time;
2180                         else if (time - CS(this).motd_actived_time > 2) { // hide it some seconds after BUTTON_INFO has been released
2181                                 CS(this).motd_actived_time = 0;
2182                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_MOTD);
2183                         }
2184                 }
2185         }
2186         else //if(CS(this).motd_actived_time < 0) // just connected, motd is active
2187         {
2188                 if(PHYS_INPUT_BUTTON_INFO(this)) // BUTTON_INFO hides initial MOTD
2189                         CS(this).motd_actived_time = -2; // wait until BUTTON_INFO gets released
2190                 else if(CS(this).motd_actived_time == -2 || IS_PLAYER(this) || IS_SPEC(this))
2191                 {
2192                         // instanctly hide MOTD
2193                         CS(this).motd_actived_time = 0;
2194                         Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_MOTD);
2195                 }
2196         }
2197 }
2198
2199 bool joinAllowed(entity this)
2200 {
2201         if (CS(this).version_mismatch) return false;
2202         if (!nJoinAllowed(this, this)) return false;
2203         if (teamplay && lockteams) return false;
2204         if (MUTATOR_CALLHOOK(ForbidSpawn, this)) return false;
2205         if (ShowTeamSelection(this)) return false;
2206         return true;
2207 }
2208
2209 .int items_added;
2210 .string shootfromfixedorigin;
2211 bool PlayerThink(entity this)
2212 {
2213         if (game_stopped || intermission_running) {
2214                 this.modelflags &= ~MF_ROCKET;
2215                 if(intermission_running)
2216                         IntermissionThink(this);
2217                 return false;
2218         }
2219
2220         if (timeout_status == TIMEOUT_ACTIVE) {
2221         // don't allow the player to turn around while game is paused
2222                 // FIXME turn this into CSQC stuff
2223                 this.v_angle = this.lastV_angle;
2224                 this.angles = this.lastV_angle;
2225                 this.fixangle = true;
2226         }
2227
2228         if (frametime) player_powerups(this);
2229
2230         if (IS_DEAD(this)) {
2231                 if (this.personal && g_race_qualifying) {
2232                         if (time > this.respawn_time) {
2233                                 STAT(RESPAWN_TIME, this) = this.respawn_time = time + 1; // only retry once a second
2234                                 respawn(this);
2235                                 CS(this).impulse = CHIMPULSE_SPEEDRUN.impulse;
2236                         }
2237                 } else {
2238                         if (frametime) player_anim(this);
2239
2240                         if (this.respawn_flags & RESPAWN_DENY)
2241                         {
2242                                 STAT(RESPAWN_TIME, this) = 0;
2243                                 return false;
2244                         }
2245
2246                         bool button_pressed = (PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_JUMP(this) || PHYS_INPUT_BUTTON_ATCK2(this) || PHYS_INPUT_BUTTON_HOOK(this) || PHYS_INPUT_BUTTON_USE(this));
2247
2248                         switch(this.deadflag)
2249                         {
2250                                 case DEAD_DYING:
2251                                 {
2252                                         if ((this.respawn_flags & RESPAWN_FORCE) && !(this.respawn_time < this.respawn_time_max))
2253                                                 this.deadflag = DEAD_RESPAWNING;
2254                                         else if (!button_pressed || (time >= this.respawn_time_max && (this.respawn_flags & RESPAWN_FORCE)))
2255                                                 this.deadflag = DEAD_DEAD;
2256                                         break;
2257                                 }
2258                                 case DEAD_DEAD:
2259                                 {
2260                                         if (button_pressed)
2261                                                 this.deadflag = DEAD_RESPAWNABLE;
2262                                         else if (time >= this.respawn_time_max && (this.respawn_flags & RESPAWN_FORCE))
2263                                                 this.deadflag = DEAD_RESPAWNING;
2264                                         break;
2265                                 }
2266                                 case DEAD_RESPAWNABLE:
2267                                 {
2268                                         if (!button_pressed || (this.respawn_flags & RESPAWN_FORCE))
2269                                                 this.deadflag = DEAD_RESPAWNING;
2270                                         break;
2271                                 }
2272                                 case DEAD_RESPAWNING:
2273                                 {
2274                                         if (time > this.respawn_time)
2275                                         {
2276                                                 this.respawn_time = time + 1; // only retry once a second
2277                                                 this.respawn_time_max = this.respawn_time;
2278                                                 respawn(this);
2279                                         }
2280                                         break;
2281                                 }
2282                         }
2283
2284                         ShowRespawnCountdown(this);
2285
2286                         if (this.respawn_flags & RESPAWN_SILENT)
2287                                 STAT(RESPAWN_TIME, this) = 0;
2288                         else if ((this.respawn_flags & RESPAWN_FORCE) && this.respawn_time < this.respawn_time_max)
2289                         {
2290                                 if (time < this.respawn_time)
2291                                         STAT(RESPAWN_TIME, this) = this.respawn_time;
2292                                 else if (this.deadflag != DEAD_RESPAWNING)
2293                                         STAT(RESPAWN_TIME, this) = -this.respawn_time_max;
2294                         }
2295                         else
2296                                 STAT(RESPAWN_TIME, this) = this.respawn_time;
2297                 }
2298
2299                 // if respawning, invert stat_respawn_time to indicate this, the client translates it
2300                 if (this.deadflag == DEAD_RESPAWNING && STAT(RESPAWN_TIME, this) > 0)
2301                         STAT(RESPAWN_TIME, this) *= -1;
2302
2303                 return false;
2304         }
2305
2306         FixPlayermodel(this);
2307
2308         if (this.shootfromfixedorigin != autocvar_g_shootfromfixedorigin) {
2309                 this.shootfromfixedorigin = autocvar_g_shootfromfixedorigin;
2310                 stuffcmd(this, sprintf("\ncl_shootfromfixedorigin \"%s\"\n", autocvar_g_shootfromfixedorigin));
2311         }
2312
2313         // LordHavoc: allow firing on move frames (sub-ticrate), this gives better timing on slow servers
2314         //if(frametime)
2315         {
2316                 this.items &= ~this.items_added;
2317
2318                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2319                 {
2320                         .entity weaponentity = weaponentities[slot];
2321                         W_WeaponFrame(this, weaponentity);
2322                 }
2323
2324                 this.items_added = 0;
2325                 if ((this.items & ITEM_Jetpack.m_itemid) && ((this.items & ITEM_JetpackRegen.m_itemid) || this.ammo_fuel >= 0.01))
2326             this.items_added |= IT_FUEL;
2327
2328                 this.items |= this.items_added;
2329         }
2330
2331         player_regen(this);
2332
2333         // WEAPONTODO: Add a weapon request for this
2334         // rot vortex charge to the charge limit
2335         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2336         {
2337                 .entity weaponentity = weaponentities[slot];
2338                 if (WEP_CVAR(vortex, charge_rot_rate) && this.(weaponentity).vortex_charge > WEP_CVAR(vortex, charge_limit) && this.(weaponentity).vortex_charge_rottime < time)
2339                         this.(weaponentity).vortex_charge = bound(WEP_CVAR(vortex, charge_limit), this.(weaponentity).vortex_charge - WEP_CVAR(vortex, charge_rot_rate) * frametime / W_TICSPERFRAME, 1);
2340         }
2341
2342         if (frametime) player_anim(this);
2343
2344         // secret status
2345         secrets_setstatus(this);
2346
2347         // monsters status
2348         monsters_setstatus(this);
2349
2350         this.dmg_team = max(0, this.dmg_team - autocvar_g_teamdamage_resetspeed * frametime);
2351
2352         return true;
2353 }
2354
2355 .bool would_spectate;
2356 void ObserverThink(entity this)
2357 {
2358         if ( CS(this).impulse )
2359         {
2360                 MinigameImpulse(this, CS(this).impulse);
2361                 CS(this).impulse = 0;
2362         }
2363
2364         if (this.flags & FL_JUMPRELEASED) {
2365                 if (PHYS_INPUT_BUTTON_JUMP(this) && joinAllowed(this)) {
2366                         this.flags &= ~FL_JUMPRELEASED;
2367                         this.flags |= FL_SPAWNING;
2368                 } else if(PHYS_INPUT_BUTTON_ATCK(this) && !CS(this).version_mismatch || this.would_spectate) {
2369                         this.flags &= ~FL_JUMPRELEASED;
2370                         if(SpectateNext(this)) {
2371                                 TRANSMUTE(Spectator, this);
2372                         }
2373                 } else {
2374                         int preferred_movetype = ((!PHYS_INPUT_BUTTON_USE(this) ? CS(this).cvar_cl_clippedspectating : !CS(this).cvar_cl_clippedspectating) ? MOVETYPE_FLY_WORLDONLY : MOVETYPE_NOCLIP);
2375                         set_movetype(this, preferred_movetype);
2376                 }
2377         } else {
2378                 if (!(PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_JUMP(this))) {
2379                         this.flags |= FL_JUMPRELEASED;
2380                         if(this.flags & FL_SPAWNING)
2381                         {
2382                                 this.flags &= ~FL_SPAWNING;
2383                                 Join(this);
2384                                 return;
2385                         }
2386                 }
2387         }
2388 }
2389
2390 void SpectatorThink(entity this)
2391 {
2392         if ( CS(this).impulse )
2393         {
2394                 if(MinigameImpulse(this, CS(this).impulse))
2395                         CS(this).impulse = 0;
2396
2397                 if (CS(this).impulse == IMP_weapon_drop.impulse)
2398                 {
2399                         STAT(CAMERA_SPECTATOR, this) = (STAT(CAMERA_SPECTATOR, this) + 1) % 3;
2400                         CS(this).impulse = 0;
2401                         return;
2402                 }
2403         }
2404
2405         if (this.flags & FL_JUMPRELEASED) {
2406                 if (PHYS_INPUT_BUTTON_JUMP(this) && joinAllowed(this)) {
2407                         this.flags &= ~FL_JUMPRELEASED;
2408                         this.flags |= FL_SPAWNING;
2409                 } else if(PHYS_INPUT_BUTTON_ATCK(this) || CS(this).impulse == 10 || CS(this).impulse == 15 || CS(this).impulse == 18 || (CS(this).impulse >= 200 && CS(this).impulse <= 209)) {
2410                         this.flags &= ~FL_JUMPRELEASED;
2411                         if(SpectateNext(this)) {
2412                                 TRANSMUTE(Spectator, this);
2413                         } else {
2414                                 TRANSMUTE(Observer, this);
2415                                 PutClientInServer(this);
2416                         }
2417                         CS(this).impulse = 0;
2418                 } else if(CS(this).impulse == 12 || CS(this).impulse == 16  || CS(this).impulse == 19 || (CS(this).impulse >= 220 && CS(this).impulse <= 229)) {
2419                         this.flags &= ~FL_JUMPRELEASED;
2420                         if(SpectatePrev(this)) {
2421                                 TRANSMUTE(Spectator, this);
2422                         } else {
2423                                 TRANSMUTE(Observer, this);
2424                                 PutClientInServer(this);
2425                         }
2426                         CS(this).impulse = 0;
2427                 } else if (PHYS_INPUT_BUTTON_ATCK2(this)) {
2428                         this.would_spectate = false;
2429                         this.flags &= ~FL_JUMPRELEASED;
2430                         TRANSMUTE(Observer, this);
2431                         PutClientInServer(this);
2432                 } else {
2433                         if(!SpectateUpdate(this))
2434                         {
2435                                 if(!SpectateNext(this))
2436                                 {
2437                                         PutObserverInServer(this);
2438                                         this.would_spectate = true;
2439                                 }
2440                         }
2441                 }
2442         } else {
2443                 if (!(PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_ATCK2(this))) {
2444                         this.flags |= FL_JUMPRELEASED;
2445                         if(this.flags & FL_SPAWNING)
2446                         {
2447                                 this.flags &= ~FL_SPAWNING;
2448                                 Join(this);
2449                                 return;
2450                         }
2451                 }
2452                 if(!SpectateUpdate(this))
2453                         PutObserverInServer(this);
2454         }
2455
2456         this.flags |= FL_CLIENT | FL_NOTARGET;
2457 }
2458
2459 void vehicles_enter (entity pl, entity veh);
2460 void PlayerUseKey(entity this)
2461 {
2462         if (!IS_PLAYER(this))
2463                 return;
2464
2465         if(this.vehicle)
2466         {
2467                 if(!game_stopped)
2468                 {
2469                         vehicles_exit(this.vehicle, VHEF_NORMAL);
2470                         return;
2471                 }
2472         }
2473         else if(autocvar_g_vehicles_enter)
2474         {
2475                 if(!STAT(FROZEN, this))
2476                 if(!IS_DEAD(this))
2477                 if(!game_stopped)
2478                 {
2479                         entity head, closest_target = NULL;
2480                         head = WarpZone_FindRadius(this.origin, autocvar_g_vehicles_enter_radius, true);
2481
2482                         while(head) // find the closest acceptable target to enter
2483                         {
2484                                 if(IS_VEHICLE(head))
2485                                 if(!IS_DEAD(head))
2486                                 if(!head.owner || ((head.vehicle_flags & VHF_MULTISLOT) && SAME_TEAM(head.owner, this)))
2487                                 if(head.takedamage != DAMAGE_NO)
2488                                 {
2489                                         if(closest_target)
2490                                         {
2491                                                 if(vlen2(this.origin - head.origin) < vlen2(this.origin - closest_target.origin))
2492                                                 { closest_target = head; }
2493                                         }
2494                                         else { closest_target = head; }
2495                                 }
2496
2497                                 head = head.chain;
2498                         }
2499
2500                         if(closest_target) { vehicles_enter(this, closest_target); return; }
2501                 }
2502         }
2503
2504         // a use key was pressed; call handlers
2505         MUTATOR_CALLHOOK(PlayerUseKey, this);
2506 }
2507
2508
2509 /*
2510 =============
2511 PlayerPreThink
2512
2513 Called every frame for each client before the physics are run
2514 =============
2515 */
2516 .float last_vehiclecheck;
2517 void PlayerPreThink (entity this)
2518 {
2519         STAT(GUNALIGN, this) = CS(this).cvar_cl_gunalign; // TODO
2520         STAT(MOVEVARS_CL_TRACK_CANJUMP, this) = CS(this).cvar_cl_movement_track_canjump;
2521
2522         WarpZone_PlayerPhysics_FixVAngle(this);
2523
2524         if (frametime) {
2525                 // physics frames: update anticheat stuff
2526                 anticheat_prethink(this);
2527         }
2528
2529         if (blockSpectators && frametime) {
2530                 // WORKAROUND: only use dropclient in server frames (frametime set).
2531                 // Never use it in cl_movement frames (frametime zero).
2532                 checkSpectatorBlock(this);
2533         }
2534
2535         zoomstate_set = false;
2536
2537         // Check for nameless players
2538         if (this.netname == "" || this.netname != CS(this).netname_previous)
2539         {
2540                 bool assume_unchanged = (CS(this).netname_previous == "");
2541                 if (isInvisibleString(this.netname))
2542                 {
2543                         this.netname = strzone(sprintf("Player#%d", this.playerid));
2544                         assume_unchanged = false;
2545                         // stuffcmd(this, strcat("name ", this.netname, "\n")); // maybe?
2546                 }
2547                 if (!assume_unchanged && autocvar_sv_eventlog)
2548                         GameLogEcho(strcat(":name:", ftos(this.playerid), ":", playername(this, false)));
2549                 strcpy(CS(this).netname_previous, this.netname);
2550         }
2551
2552         // version nagging
2553         if (CS(this).version_nagtime && CS(this).cvar_g_xonoticversion && time > CS(this).version_nagtime) {
2554         CS(this).version_nagtime = 0;
2555         if (strstrofs(CS(this).cvar_g_xonoticversion, "git", 0) >= 0 || strstrofs(CS(this).cvar_g_xonoticversion, "autobuild", 0) >= 0) {
2556             // git client
2557         } else if (strstrofs(autocvar_g_xonoticversion, "git", 0) >= 0 || strstrofs(autocvar_g_xonoticversion, "autobuild", 0) >= 0) {
2558             // git server
2559             Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_BETA, autocvar_g_xonoticversion, CS(this).cvar_g_xonoticversion);
2560         } else {
2561             int r = vercmp(CS(this).cvar_g_xonoticversion, autocvar_g_xonoticversion);
2562             if (r < 0) { // old client
2563                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_OUTDATED, autocvar_g_xonoticversion, CS(this).cvar_g_xonoticversion);
2564             } else if (r > 0) { // old server
2565                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_OLD, autocvar_g_xonoticversion, CS(this).cvar_g_xonoticversion);
2566             }
2567         }
2568     }
2569
2570         // GOD MODE info
2571         if (!(this.flags & FL_GODMODE) && this.max_armorvalue)
2572         {
2573                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_GODMODE_OFF, this.max_armorvalue);
2574                 this.max_armorvalue = 0;
2575         }
2576
2577         if(IS_PLAYER(this))
2578         {
2579                 if (STAT(FROZEN, this) == 2)
2580                 {
2581                         STAT(REVIVE_PROGRESS, this) = bound(0, STAT(REVIVE_PROGRESS, this) + frametime * this.revive_speed, 1);
2582                         this.health = max(1, STAT(REVIVE_PROGRESS, this) * start_health);
2583                         this.iceblock.alpha = bound(0.2, 1 - STAT(REVIVE_PROGRESS, this), 1);
2584
2585                         if (STAT(REVIVE_PROGRESS, this) >= 1)
2586                                 Unfreeze(this);
2587                 }
2588                 else if (STAT(FROZEN, this) == 3)
2589                 {
2590                         STAT(REVIVE_PROGRESS, this) = bound(0, STAT(REVIVE_PROGRESS, this) - frametime * this.revive_speed, 1);
2591                         this.health = max(0, autocvar_g_nades_ice_health + (start_health-autocvar_g_nades_ice_health) * STAT(REVIVE_PROGRESS, this) );
2592
2593                         if (this.health < 1)
2594                         {
2595                                 if (this.vehicle)
2596                                         vehicles_exit(this.vehicle, VHEF_RELEASE);
2597                                 if(this.event_damage)
2598                                         this.event_damage(this, this, this.frozen_by, 1, DEATH_NADE_ICE_FREEZE.m_id, DMG_NOWEP, this.origin, '0 0 0');
2599                         }
2600                         else if (STAT(REVIVE_PROGRESS, this) <= 0)
2601                                 Unfreeze(this);
2602                 }
2603         }
2604
2605         MUTATOR_CALLHOOK(PlayerPreThink, this);
2606
2607         if(autocvar_g_vehicles_enter && (time > this.last_vehiclecheck) && !game_stopped && !this.vehicle)
2608         if(IS_PLAYER(this) && !STAT(FROZEN, this) && !IS_DEAD(this))
2609         {
2610                 FOREACH_ENTITY_RADIUS(this.origin, autocvar_g_vehicles_enter_radius, IS_VEHICLE(it),
2611                 {
2612                         if(!IS_DEAD(it) && it.takedamage != DAMAGE_NO)
2613                         if((it.vehicle_flags & VHF_MULTISLOT) && SAME_TEAM(it.owner, this))
2614                         {
2615                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER_GUNNER);
2616                         }
2617                         else if(!it.owner)
2618                         {
2619                                 if(!it.team || SAME_TEAM(this, it))
2620                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER);
2621                                 else if(autocvar_g_vehicles_steal)
2622                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER_STEAL);
2623                         }
2624                 });
2625
2626                 this.last_vehiclecheck = time + 1;
2627         }
2628
2629         if(!CS(this).cvar_cl_newusekeysupported) // FIXME remove this - it was a stupid idea to begin with, we can JUST use the button
2630         {
2631                 if(PHYS_INPUT_BUTTON_USE(this) && !CS(this).usekeypressed)
2632                         PlayerUseKey(this);
2633                 CS(this).usekeypressed = PHYS_INPUT_BUTTON_USE(this);
2634         }
2635
2636         if (IS_REAL_CLIENT(this))
2637                 PrintWelcomeMessage(this);
2638
2639         if (IS_PLAYER(this)) {
2640                 if(!PlayerThink(this))
2641                         return;
2642         }
2643         else if (game_stopped || intermission_running) {
2644                 if(intermission_running)
2645                         IntermissionThink(this);
2646                 return;
2647         }
2648         else if (IS_OBSERVER(this)) {
2649                 ObserverThink(this);
2650         }
2651         else if (IS_SPEC(this)) {
2652                 SpectatorThink(this);
2653         }
2654
2655         // WEAPONTODO: Add weapon request for this
2656         if (!zoomstate_set) {
2657                 bool wep_zoomed = false;
2658                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2659                 {
2660                         .entity weaponentity = weaponentities[slot];
2661                         Weapon thiswep = this.(weaponentity).m_weapon;
2662                         if(thiswep != WEP_Null && thiswep.wr_zoom)
2663                                 wep_zoomed += thiswep.wr_zoom(thiswep, this);
2664                 }
2665                 SetZoomState(this, PHYS_INPUT_BUTTON_ZOOM(this) || PHYS_INPUT_BUTTON_ZOOMSCRIPT(this) || wep_zoomed);
2666     }
2667
2668         if (CS(this).teamkill_soundtime && time > CS(this).teamkill_soundtime)
2669         {
2670                 CS(this).teamkill_soundtime = 0;
2671
2672                 entity e = CS(this).teamkill_soundsource;
2673                 entity oldpusher = e.pusher;
2674                 e.pusher = this;
2675                 PlayerSound(e, playersound_teamshoot, CH_VOICE, VOL_BASEVOICE, VOICETYPE_LASTATTACKER_ONLY);
2676                 e.pusher = oldpusher;
2677         }
2678
2679         if (CS(this).taunt_soundtime && time > CS(this).taunt_soundtime) {
2680                 CS(this).taunt_soundtime = 0;
2681                 PlayerSound(this, playersound_taunt, CH_VOICE, VOL_BASEVOICE, VOICETYPE_AUTOTAUNT);
2682         }
2683
2684         target_voicescript_next(this);
2685
2686         // WEAPONTODO: Move into weaponsystem somehow
2687         // if a player goes unarmed after holding a loaded weapon, empty his clip size and remove the crosshair ammo ring
2688         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2689         {
2690                 .entity weaponentity = weaponentities[slot];
2691                 if(this.(weaponentity).m_weapon == WEP_Null)
2692                         this.(weaponentity).clip_load = this.(weaponentity).clip_size = 0;
2693         }
2694 }
2695
2696 void DrownPlayer(entity this)
2697 {
2698         if(IS_DEAD(this) || game_stopped || time < game_starttime)
2699                 return;
2700
2701         if (this.waterlevel != WATERLEVEL_SUBMERGED || this.vehicle)
2702         {
2703                 if(this.air_finished < time)
2704                         PlayerSound(this, playersound_gasp, CH_PLAYER, VOL_BASE, VOICETYPE_PLAYERSOUND);
2705                 this.air_finished = time + autocvar_g_balance_contents_drowndelay;
2706         }
2707         else if (this.air_finished < time)
2708         {       // drown!
2709                 if (this.pain_finished < time)
2710                 {
2711                         Damage (this, NULL, NULL, autocvar_g_balance_contents_playerdamage_drowning * autocvar_g_balance_contents_damagerate, DEATH_DROWN.m_id, DMG_NOWEP, this.origin, '0 0 0');
2712                         this.pain_finished = time + 0.5;
2713                 }
2714         }
2715 }
2716
2717 .bool move_qcphysics;
2718
2719 void Player_Physics(entity this)
2720 {
2721         set_movetype(this, this.move_movetype);
2722
2723         if(!this.move_qcphysics)
2724                 return;
2725
2726         if(!frametime && !CS(this).pm_frametime)
2727                 return;
2728
2729         Movetype_Physics_NoMatchTicrate(this, CS(this).pm_frametime, true);
2730
2731         CS(this).pm_frametime = 0;
2732 }
2733
2734 /*
2735 =============
2736 PlayerPostThink
2737
2738 Called every frame for each client after the physics are run
2739 =============
2740 */
2741 void PlayerPostThink (entity this)
2742 {
2743         Player_Physics(this);
2744
2745         if (sv_maxidle > 0)
2746         if (frametime) // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2747         if (IS_REAL_CLIENT(this))
2748         if (IS_PLAYER(this) || sv_maxidle_spectatorsareidle)
2749         {
2750                 int totalClients = 0;
2751                 if(sv_maxidle_slots > 0)
2752                 {
2753                         FOREACH_CLIENT(IS_REAL_CLIENT(it) || sv_maxidle_slots_countbots,
2754                         {
2755                                 ++totalClients;
2756                         });
2757                 }
2758
2759                 if (sv_maxidle_slots > 0 && (maxclients - totalClients) > sv_maxidle_slots)
2760                 { /* do nothing */ }
2761                 else if (time - CS(this).parm_idlesince < 1) // instead of (time == this.parm_idlesince) to support sv_maxidle <= 10
2762                 {
2763                         if (CS(this).idlekick_lasttimeleft)
2764                         {
2765                                 CS(this).idlekick_lasttimeleft = 0;
2766                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_IDLING);
2767                         }
2768                 }
2769                 else
2770                 {
2771                         float timeleft = ceil(sv_maxidle - (time - CS(this).parm_idlesince));
2772                         if (timeleft == min(10, sv_maxidle - 1)) { // - 1 to support sv_maxidle <= 10
2773                                 if (!CS(this).idlekick_lasttimeleft)
2774                                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_DISCONNECT_IDLING, timeleft);
2775                         }
2776                         if (timeleft <= 0) {
2777                                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_QUIT_KICK_IDLING, this.netname);
2778                                 dropclient(this);
2779                                 return;
2780                         }
2781                         else if (timeleft <= 10) {
2782                                 if (timeleft != CS(this).idlekick_lasttimeleft) {
2783                                     Send_Notification(NOTIF_ONE, this, MSG_ANNCE, Announcer_PickNumber(CNT_IDLE, timeleft));
2784                 }
2785                                 CS(this).idlekick_lasttimeleft = timeleft;
2786                         }
2787                 }
2788         }
2789
2790         CheatFrame(this);
2791
2792         if (game_stopped)
2793         {
2794                 this.solid = SOLID_NOT;
2795                 this.takedamage = DAMAGE_NO;
2796                 set_movetype(this, MOVETYPE_NONE);
2797         }
2798
2799         if (IS_PLAYER(this)) {
2800                 if(this.death_time == time && IS_DEAD(this))
2801                 {
2802                         // player's bbox gets resized now, instead of in the damage event that killed the player,
2803                         // once all the damage events of this frame have been processed with normal size
2804                         this.maxs.z = 5;
2805                         setsize(this, this.mins, this.maxs);
2806                 }
2807                 DrownPlayer(this);
2808                 UpdateChatBubble(this);
2809                 if (CS(this).impulse) ImpulseCommands(this);
2810                 if (game_stopped)
2811                 {
2812                         CSQCMODEL_AUTOUPDATE(this);
2813                         return;
2814                 }
2815                 GetPressedKeys(this);
2816         }
2817
2818         if (this.waypointsprite_attachedforcarrier) {
2819             vector v = healtharmor_maxdamage(this.health, this.armorvalue, autocvar_g_balance_armor_blockpercent, DEATH_WEAPON.m_id);
2820                 WaypointSprite_UpdateHealth(this.waypointsprite_attachedforcarrier, '1 0 0' * v);
2821     }
2822
2823         playerdemo_write(this);
2824
2825         CSQCMODEL_AUTOUPDATE(this);
2826 }
2827
2828 // hack to copy the button fields from the client entity to the Client State
2829 void PM_UpdateButtons(entity this, entity store)
2830 {
2831         if(this.impulse)
2832                 store.impulse = this.impulse;
2833         this.impulse = 0;
2834
2835         bool typing = this.buttonchat;
2836
2837         store.button0 = (typing) ? 0 : this.button0;
2838         //button1?!
2839         store.button2 = (typing) ? 0 : this.button2;
2840         store.button3 = (typing) ? 0 : this.button3;
2841         store.button4 = this.button4;
2842         store.button5 = (typing) ? 0 : this.button5;
2843         store.button6 = this.button6;
2844         store.button7 = this.button7;
2845         store.button8 = this.button8;
2846         store.button9 = this.button9;
2847         store.button10 = this.button10;
2848         store.button11 = this.button11;
2849         store.button12 = this.button12;
2850         store.button13 = this.button13;
2851         store.button14 = this.button14;
2852         store.button15 = this.button15;
2853         store.button16 = this.button16;
2854         store.buttonuse = this.buttonuse;
2855         store.buttonchat = this.buttonchat;
2856
2857         store.cursor_active = this.cursor_active;
2858         store.cursor_screen = this.cursor_screen;
2859         store.cursor_trace_start = this.cursor_trace_start;
2860         store.cursor_trace_endpos = this.cursor_trace_endpos;
2861         store.cursor_trace_ent = this.cursor_trace_ent;
2862
2863         store.ping = this.ping;
2864         store.ping_packetloss = this.ping_packetloss;
2865         store.ping_movementloss = this.ping_movementloss;
2866
2867         store.v_angle = this.v_angle;
2868         store.movement = (typing) ? '0 0 0' : this.movement;
2869 }
2870
2871 NET_HANDLE(fpsreport, bool)
2872 {
2873         int fps = ReadShort();
2874         PlayerScore_Set(sender, SP_FPS, fps);
2875         return true;
2876 }