qcsrc/server/client.qc

   1 #include "client.qh"
   2
   3 #include <server/defs.qh>
   4 #include <server/miscfunctions.qh>
   5 #include <common/effects/all.qh>
   6 #include "anticheat.qh"
   7 #include "impulse.qh"
   8 #include "player.qh"
   9 #include "ipban.qh"
  10 #include "miscfunctions.qh"
  11 #include "portals.qh"
  12 #include "teamplay.qh"
  13 #include "playerdemo.qh"
  14 #include "spawnpoints.qh"
  15 #include "resources.qh"
  16 #include "g_damage.qh"
  17 #include "handicap.qh"
  18 #include "g_hook.qh"
  19 #include "command/common.qh"
  20 #include "cheats.qh"
  21 #include "g_world.qh"
  22 #include "race.qh"
  23 #include "antilag.qh"
  24 #include "campaign.qh"
  25 #include "command/common.qh"
  26 #include "scores_rules.qh"
  27
  28 #include "bot/api.qh"
  29
  30 #include "../common/ent_cs.qh"
  31 #include "../common/wepent.qh"
  32 #include <common/state.qh>
  33
  34 #include <common/effects/qc/globalsound.qh>
  35
  36 #include "../common/triggers/func/conveyor.qh"
  37 #include "../common/triggers/teleporters.qh"
  38 #include "../common/triggers/target/spawnpoint.qh"
  39
  40 #include "../common/vehicles/all.qh"
  41
  42 #include "weapons/hitplot.qh"
  43 #include "weapons/weaponsystem.qh"
  44
  45 #include "../common/net_notice.qh"
  46 #include "../common/net_linked.qh"
  47 #include "../common/physics/player.qh"
  48
  49 #include "../common/items/_mod.qh"
  50
  51 #include "../common/mutators/mutator/waypoints/all.qh"
  52
  53 #include "../common/triggers/subs.qh"
  54 #include "../common/triggers/triggers.qh"
  55 #include "../common/triggers/trigger/secret.qh"
  56
  57 #include "../common/minigames/sv_minigames.qh"
  58
  59 #include "../common/items/inventory.qh"
  60
  61 #include "../common/monsters/sv_monsters.qh"
  62
  63 #include "../lib/warpzone/server.qh"
  64
  65 STATIC_METHOD(Client, Add, void(Client this, int _team))
  66 {
  67     ClientConnect(this);
  68     TRANSMUTE(Player, this);
  69     this.frame = 12; // 7
  70     this.team = _team;
  71     PutClientInServer(this);
  72 }
  73
  74 void PutObserverInServer(entity this);
  75
  76 STATIC_METHOD(Client, Remove, void(Client this))
  77 {
  78     TRANSMUTE(Observer, this);
  79     PutClientInServer(this);
  80     ClientDisconnect(this);
  81 }
  82
  83 void send_CSQC_teamnagger() {
  84         WriteHeader(MSG_BROADCAST, TE_CSQC_TEAMNAGGER);
  85 }
  86
  87 int CountSpectators(entity player, entity to)
  88 {
  89         if(!player) { return 0; } // not sure how, but best to be safe
  90
  91         int spec_count = 0;
  92
  93         FOREACH_CLIENT(IS_REAL_CLIENT(it) && IS_SPEC(it) && it != to && it.enemy == player,
  94         {
  95                 spec_count++;
  96         });
  97
  98         return spec_count;
  99 }
 100
 101 void WriteSpectators(entity player, entity to)
 102 {
 103         if(!player) { return; } // not sure how, but best to be safe
 104
 105         FOREACH_CLIENT(IS_REAL_CLIENT(it) && IS_SPEC(it) && it != to && it.enemy == player,
 106         {
 107                 WriteByte(MSG_ENTITY, num_for_edict(it));
 108         });
 109 }
 110
 111 bool ClientData_Send(entity this, entity to, int sf)
 112 {
 113         assert(to == this.owner, return false);
 114
 115         entity e = to;
 116         if (IS_SPEC(e)) e = e.enemy;
 117
 118         sf = 0;
 119         if (CS(e).race_completed)       sf |= BIT(0); // forced scoreboard
 120         if (CS(to).spectatee_status)    sf |= BIT(1); // spectator ent number follows
 121         if (CS(e).zoomstate)            sf |= BIT(2); // zoomed
 122         if (autocvar_sv_showspectators) sf |= BIT(4); // show spectators
 123
 124         WriteHeader(MSG_ENTITY, ENT_CLIENT_CLIENTDATA);
 125         WriteByte(MSG_ENTITY, sf);
 126
 127         if (sf & BIT(1))
 128                 WriteByte(MSG_ENTITY, CS(to).spectatee_status);
 129
 130         if(sf & BIT(4))
 131         {
 132                 float specs = CountSpectators(e, to);
 133                 WriteByte(MSG_ENTITY, specs);
 134                 WriteSpectators(e, to);
 135         }
 136
 137         return true;
 138 }
 139
 140 void ClientData_Attach(entity this)
 141 {
 142         Net_LinkEntity(CS(this).clientdata = new_pure(clientdata), false, 0, ClientData_Send);
 143         CS(this).clientdata.drawonlytoclient = this;
 144         CS(this).clientdata.owner = this;
 145 }
 146
 147 void ClientData_Detach(entity this)
 148 {
 149         delete(CS(this).clientdata);
 150         CS(this).clientdata = NULL;
 151 }
 152
 153 void ClientData_Touch(entity e)
 154 {
 155         CS(e).clientdata.SendFlags = 1;
 156
 157         // make it spectatable
 158         FOREACH_CLIENT(IS_REAL_CLIENT(it) && it != e && IS_SPEC(it) && it.enemy == e, { CS(it).clientdata.SendFlags = 1; });
 159 }
 160
 161 void SetSpectatee(entity this, entity spectatee);
 162 void SetSpectatee_status(entity this, int spectatee_num);
 163
 164
 165 /*
 166 =============
 167 CheckPlayerModel
 168
 169 Checks if the argument string can be a valid playermodel.
 170 Returns a valid one in doubt.
 171 =============
 172 */
 173 string FallbackPlayerModel;
 174 string CheckPlayerModel(string plyermodel) {
 175         if(FallbackPlayerModel != cvar_defstring("_cl_playermodel"))
 176         {
 177                 // note: we cannot summon Don Strunzone here, some player may
 178                 // still have the model string set. In case anyone manages how
 179                 // to change a cvar default, we'll have a small leak here.
 180                 FallbackPlayerModel = strzone(cvar_defstring("_cl_playermodel"));
 181         }
 182         // only in right path
 183         if( substring(plyermodel,0,14) != "models/player/")
 184                 return FallbackPlayerModel;
 185         // only good file extensions
 186         if(substring(plyermodel,-4,4) != ".zym")
 187         if(substring(plyermodel,-4,4) != ".dpm")
 188         if(substring(plyermodel,-4,4) != ".iqm")
 189         if(substring(plyermodel,-4,4) != ".md3")
 190         if(substring(plyermodel,-4,4) != ".psk")
 191                 return FallbackPlayerModel;
 192         // forbid the LOD models
 193         if(substring(plyermodel, -9,5) == "_lod1")
 194                 return FallbackPlayerModel;
 195         if(substring(plyermodel, -9,5) == "_lod2")
 196                 return FallbackPlayerModel;
 197         if(plyermodel != strtolower(plyermodel))
 198                 return FallbackPlayerModel;
 199         // also, restrict to server models
 200         if(autocvar_sv_servermodelsonly)
 201         {
 202                 if(!fexists(plyermodel))
 203                         return FallbackPlayerModel;
 204         }
 205         return plyermodel;
 206 }
 207
 208 void setplayermodel(entity e, string modelname)
 209 {
 210         precache_model(modelname);
 211         _setmodel(e, modelname);
 212         player_setupanimsformodel(e);
 213         if(!autocvar_g_debug_globalsounds)
 214                 UpdatePlayerSounds(e);
 215 }
 216
 217 void FixPlayermodel(entity player);
 218 /** putting a client as observer in the server */
 219 void PutObserverInServer(entity this)
 220 {
 221     bool mutator_returnvalue = MUTATOR_CALLHOOK(MakePlayerObserver, this);
 222         PlayerState_detach(this);
 223
 224         if (IS_PLAYER(this))
 225         {
 226                 if(this.health >= 1)
 227                 {
 228                         // despawn effect
 229                         Send_Effect(EFFECT_SPAWN_NEUTRAL, this.origin, '0 0 0', 1);
 230                 }
 231
 232                 // was a player, recount votes and ready status
 233                 if(IS_REAL_CLIENT(this))
 234                 {
 235                         if (vote_called) { VoteCount(false); }
 236                         ReadyCount();
 237                 }
 238     }
 239
 240     {
 241         entity spot = SelectSpawnPoint(this, true);
 242         if (!spot) LOG_FATAL("No spawnpoints for observers?!?");
 243         this.angles = vec2(spot.angles);
 244         this.fixangle = true;
 245         // offset it so that the spectator spawns higher off the ground, looks better this way
 246         setorigin(this, spot.origin + STAT(PL_VIEW_OFS, this));
 247         if (IS_REAL_CLIENT(this))
 248         {
 249             msg_entity = this;
 250             WriteByte(MSG_ONE, SVC_SETVIEW);
 251             WriteEntity(MSG_ONE, this);
 252         }
 253         // give the spectator some space between walls for MOVETYPE_FLY_WORLDONLY
 254         // so that your view doesn't go into the ceiling with MOVETYPE_FLY_WORLDONLY, previously "PL_VIEW_OFS"
 255         if(!autocvar_g_debug_globalsounds)
 256         {
 257                 // needed for player sounds
 258                 this.model = "";
 259                 FixPlayermodel(this);
 260         }
 261         setmodel(this, MDL_Null);
 262         setsize(this, STAT(PL_CROUCH_MIN, this), STAT(PL_CROUCH_MAX, this));
 263         this.view_ofs = '0 0 0';
 264     }
 265
 266     RemoveGrapplingHooks(this);
 267         Portal_ClearAll(this);
 268         Unfreeze(this);
 269         SetSpectatee(this, NULL);
 270
 271         if (this.alivetime)
 272         {
 273                 if (!warmup_stage)
 274                         PlayerStats_GameReport_Event_Player(this, PLAYERSTATS_ALIVETIME, time - this.alivetime);
 275                 this.alivetime = 0;
 276         }
 277
 278         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
 279
 280         WaypointSprite_PlayerDead(this);
 281
 282         if (mutator_returnvalue) {
 283             // mutator prevents resetting teams+score
 284         } else {
 285                 int oldteam = this.team;
 286                 this.team = -1;  // move this as it is needed to log the player spectating in eventlog
 287                 MUTATOR_CALLHOOK(Player_ChangedTeam, this, oldteam, this.team);
 288         this.frags = FRAGS_SPECTATOR;
 289         PlayerScore_Clear(this);  // clear scores when needed
 290     }
 291
 292         if (CS(this).killcount != FRAGS_SPECTATOR)
 293         {
 294                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_QUIT_SPECTATE, this.netname);
 295                 if(!game_stopped)
 296                 if(autocvar_g_chat_nospectators == 1 || (!warmup_stage && autocvar_g_chat_nospectators == 2))
 297                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_CHAT_NOSPECTATORS);
 298
 299                 if(!CS(this).just_joined)
 300                         LogTeamchange(this.playerid, -1, 4);
 301                 else
 302                         CS(this).just_joined = false;
 303         }
 304
 305         accuracy_resend(this);
 306
 307         CS(this).spectatortime = time;
 308         if(this.bot_attack)
 309                 IL_REMOVE(g_bot_targets, this);
 310         this.bot_attack = false;
 311         if(this.monster_attack)
 312                 IL_REMOVE(g_monster_targets, this);
 313         this.monster_attack = false;
 314     STAT(HUD, this) = HUD_NORMAL;
 315         TRANSMUTE(Observer, this);
 316         this.iscreature = false;
 317         this.teleportable = TELEPORT_SIMPLE;
 318         if(this.damagedbycontents)
 319                 IL_REMOVE(g_damagedbycontents, this);
 320         this.damagedbycontents = false;
 321         this.health = FRAGS_SPECTATOR;
 322         SetSpectatee_status(this, etof(this));
 323         this.takedamage = DAMAGE_NO;
 324         this.solid = SOLID_NOT;
 325         set_movetype(this, MOVETYPE_FLY_WORLDONLY); // user preference is controlled by playerprethink
 326         this.flags = FL_CLIENT | FL_NOTARGET;
 327         this.armorvalue = 666;
 328         this.effects = 0;
 329         this.armorvalue = autocvar_g_balance_armor_start;
 330         this.pauserotarmor_finished = 0;
 331         this.pauserothealth_finished = 0;
 332         this.pauseregen_finished = 0;
 333         this.damageforcescale = 0;
 334         this.death_time = 0;
 335         this.respawn_flags = 0;
 336         this.respawn_time = 0;
 337         STAT(RESPAWN_TIME, this) = 0;
 338         this.alpha = 0;
 339         this.scale = 0;
 340         this.fade_time = 0;
 341         this.pain_frame = 0;
 342         this.pain_finished = 0;
 343         this.strength_finished = 0;
 344         this.invincible_finished = 0;
 345         this.superweapons_finished = 0;
 346         this.dphitcontentsmask = 0;
 347         this.pushltime = 0;
 348         this.istypefrag = 0;
 349         setthink(this, func_null);
 350         this.nextthink = 0;
 351         this.deadflag = DEAD_NO;
 352         this.crouch = false;
 353         STAT(REVIVE_PROGRESS, this) = 0;
 354         this.revival_time = 0;
 355
 356         this.items = 0;
 357         this.weapons = '0 0 0';
 358         this.drawonlytoclient = this;
 359
 360         this.viewloc = NULL;
 361
 362         //this.spawnpoint_targ = NULL; // keep it so they can return to where they were?
 363
 364         this.weaponmodel = "";
 365         for (int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 366         {
 367                 this.weaponentities[slot] = NULL;
 368         }
 369         this.exteriorweaponentity = NULL;
 370         CS(this).killcount = FRAGS_SPECTATOR;
 371         this.velocity = '0 0 0';
 372         this.avelocity = '0 0 0';
 373         this.punchangle = '0 0 0';
 374         this.punchvector = '0 0 0';
 375         this.oldvelocity = this.velocity;
 376         this.fire_endtime = -1;
 377         this.event_damage = func_null;
 378
 379         for(int slot = 0; slot < MAX_AXH; ++slot)
 380         {
 381                 entity axh = this.(AuxiliaryXhair[slot]);
 382                 this.(AuxiliaryXhair[slot]) = NULL;
 383
 384                 if(axh.owner == this && axh != NULL && !wasfreed(axh))
 385                         delete(axh);
 386         }
 387 }
 388
 389 int player_getspecies(entity this)
 390 {
 391         get_model_parameters(this.model, this.skin);
 392         int s = get_model_parameters_species;
 393         get_model_parameters(string_null, 0);
 394         if (s < 0) return SPECIES_HUMAN;
 395         return s;
 396 }
 397
 398 .float model_randomizer;
 399 void FixPlayermodel(entity player)
 400 {
 401         string defaultmodel = "";
 402         int defaultskin = 0;
 403         if(autocvar_sv_defaultcharacter)
 404         {
 405                 if(teamplay)
 406                 {
 407                         switch(player.team)
 408                         {
 409                                 case NUM_TEAM_1: defaultmodel = autocvar_sv_defaultplayermodel_red; defaultskin = autocvar_sv_defaultplayerskin_red; break;
 410                                 case NUM_TEAM_2: defaultmodel = autocvar_sv_defaultplayermodel_blue; defaultskin = autocvar_sv_defaultplayerskin_blue; break;
 411                                 case NUM_TEAM_3: defaultmodel = autocvar_sv_defaultplayermodel_yellow; defaultskin = autocvar_sv_defaultplayerskin_yellow; break;
 412                                 case NUM_TEAM_4: defaultmodel = autocvar_sv_defaultplayermodel_pink; defaultskin = autocvar_sv_defaultplayerskin_pink; break;
 413                         }
 414                 }
 415
 416                 if(defaultmodel == "")
 417                 {
 418                         defaultmodel = autocvar_sv_defaultplayermodel;
 419                         defaultskin = autocvar_sv_defaultplayerskin;
 420                 }
 421
 422                 int n = tokenize_console(defaultmodel);
 423                 if(n > 0)
 424                 {
 425                         defaultmodel = argv(floor(n * CS(player).model_randomizer));
 426                         // However, do NOT randomize if the player-selected model is in the list.
 427                         for (int i = 0; i < n; ++i)
 428                                 if ((argv(i) == player.playermodel && defaultskin == stof(player.playerskin)) || argv(i) == strcat(player.playermodel, ":", player.playerskin))
 429                                         defaultmodel = argv(i);
 430                 }
 431
 432                 int i = strstrofs(defaultmodel, ":", 0);
 433                 if(i >= 0)
 434                 {
 435                         defaultskin = stof(substring(defaultmodel, i+1, -1));
 436                         defaultmodel = substring(defaultmodel, 0, i);
 437                 }
 438         }
 439         if(autocvar_sv_defaultcharacterskin && !defaultskin)
 440         {
 441                 if(teamplay)
 442                 {
 443                         switch(player.team)
 444                         {
 445                                 case NUM_TEAM_1: defaultskin = autocvar_sv_defaultplayerskin_red; break;
 446                                 case NUM_TEAM_2: defaultskin = autocvar_sv_defaultplayerskin_blue; break;
 447                                 case NUM_TEAM_3: defaultskin = autocvar_sv_defaultplayerskin_yellow; break;
 448                                 case NUM_TEAM_4: defaultskin = autocvar_sv_defaultplayerskin_pink; break;
 449                         }
 450                 }
 451
 452                 if(!defaultskin)
 453                         defaultskin = autocvar_sv_defaultplayerskin;
 454         }
 455
 456         MUTATOR_CALLHOOK(FixPlayermodel, defaultmodel, defaultskin, player);
 457         defaultmodel = M_ARGV(0, string);
 458         defaultskin = M_ARGV(1, int);
 459
 460         bool chmdl = false;
 461         int oldskin;
 462         if(defaultmodel != "")
 463         {
 464                 if (defaultmodel != player.model)
 465                 {
 466                         vector m1 = player.mins;
 467                         vector m2 = player.maxs;
 468                         setplayermodel (player, defaultmodel);
 469                         setsize (player, m1, m2);
 470                         chmdl = true;
 471                 }
 472
 473                 oldskin = player.skin;
 474                 player.skin = defaultskin;
 475         } else {
 476                 if (player.playermodel != player.model || player.playermodel == "")
 477                 {
 478                         player.playermodel = CheckPlayerModel(player.playermodel); // this is never "", so no endless loop
 479                         vector m1 = player.mins;
 480                         vector m2 = player.maxs;
 481                         setplayermodel (player, player.playermodel);
 482                         setsize (player, m1, m2);
 483                         chmdl = true;
 484                 }
 485
 486                 if(!autocvar_sv_defaultcharacterskin)
 487                 {
 488                         oldskin = player.skin;
 489                         player.skin = stof(player.playerskin);
 490                 }
 491                 else
 492                 {
 493                         oldskin = player.skin;
 494                         player.skin = defaultskin;
 495                 }
 496         }
 497
 498         if(chmdl || oldskin != player.skin) // model or skin has changed
 499         {
 500                 player.species = player_getspecies(player); // update species
 501                 if(!autocvar_g_debug_globalsounds)
 502                         UpdatePlayerSounds(player); // update skin sounds
 503         }
 504
 505         if(!teamplay)
 506                 if(strlen(autocvar_sv_defaultplayercolors))
 507                         if(player.clientcolors != stof(autocvar_sv_defaultplayercolors))
 508                                 setcolor(player, stof(autocvar_sv_defaultplayercolors));
 509 }
 510
 511 void PutPlayerInServer(entity this)
 512 {
 513         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
 514
 515         PlayerState_attach(this);
 516         accuracy_resend(this);
 517
 518         if (this.team < 0)
 519                 JoinBestTeam(this, true);
 520
 521         entity spot = SelectSpawnPoint(this, false);
 522         if (!spot) {
 523                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_JOIN_NOSPAWNS);
 524                 return; // spawn failed
 525         }
 526
 527         TRANSMUTE(Player, this);
 528
 529         CS(this).wasplayer = true;
 530         this.iscreature = true;
 531         this.teleportable = TELEPORT_NORMAL;
 532         if(!this.damagedbycontents)
 533                 IL_PUSH(g_damagedbycontents, this);
 534         this.damagedbycontents = true;
 535         set_movetype(this, MOVETYPE_WALK);
 536         this.solid = SOLID_SLIDEBOX;
 537         this.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_SOLID;
 538         if (autocvar_g_playerclip_collisions)
 539                 this.dphitcontentsmask |= DPCONTENTS_PLAYERCLIP;
 540         if (IS_BOT_CLIENT(this) && autocvar_g_botclip_collisions)
 541                 this.dphitcontentsmask |= DPCONTENTS_BOTCLIP;
 542         this.frags = FRAGS_PLAYER;
 543         if (INDEPENDENT_PLAYERS) MAKE_INDEPENDENT_PLAYER(this);
 544         this.flags = FL_CLIENT | FL_PICKUPITEMS;
 545         if (autocvar__notarget)
 546                 this.flags |= FL_NOTARGET;
 547         this.takedamage = DAMAGE_AIM;
 548         this.effects = EF_TELEPORT_BIT | EF_RESTARTANIM_BIT;
 549
 550         if (warmup_stage) {
 551                 this.ammo_shells = warmup_start_ammo_shells;
 552                 this.ammo_nails = warmup_start_ammo_nails;
 553                 this.ammo_rockets = warmup_start_ammo_rockets;
 554                 this.ammo_cells = warmup_start_ammo_cells;
 555                 this.ammo_plasma = warmup_start_ammo_plasma;
 556                 this.ammo_fuel = warmup_start_ammo_fuel;
 557                 this.health = warmup_start_health;
 558                 this.armorvalue = warmup_start_armorvalue;
 559                 this.weapons = WARMUP_START_WEAPONS;
 560         } else {
 561                 this.ammo_shells = start_ammo_shells;
 562                 this.ammo_nails = start_ammo_nails;
 563                 this.ammo_rockets = start_ammo_rockets;
 564                 this.ammo_cells = start_ammo_cells;
 565                 this.ammo_plasma = start_ammo_plasma;
 566                 this.ammo_fuel = start_ammo_fuel;
 567                 this.health = start_health;
 568                 this.armorvalue = start_armorvalue;
 569                 this.weapons = start_weapons;
 570                 if (MUTATOR_CALLHOOK(ForbidRandomStartWeapons, this) == false)
 571                 {
 572                         GiveRandomWeapons(this, random_start_weapons_count,
 573                                 autocvar_g_random_start_weapons, random_start_ammo);
 574                 }
 575         }
 576         SetSpectatee_status(this, 0);
 577
 578         PS(this).dual_weapons = '0 0 0';
 579
 580         this.superweapons_finished = (this.weapons & WEPSET_SUPERWEAPONS) ? time + autocvar_g_balance_superweapons_time : 0;
 581
 582         this.items = start_items;
 583
 584         this.spawnshieldtime = time + autocvar_g_spawnshieldtime;
 585         this.pauserotarmor_finished = time + autocvar_g_balance_pause_armor_rot_spawn;
 586         this.pauserothealth_finished = time + autocvar_g_balance_pause_health_rot_spawn;
 587         this.pauserotfuel_finished = time + autocvar_g_balance_pause_fuel_rot_spawn;
 588         this.pauseregen_finished = time + autocvar_g_balance_pause_health_regen_spawn;
 589         if (!sv_ready_restart_after_countdown && time < game_starttime)
 590         {
 591                 float f = game_starttime - time;
 592                 this.spawnshieldtime += f;
 593                 this.pauserotarmor_finished += f;
 594                 this.pauserothealth_finished += f;
 595                 this.pauseregen_finished += f;
 596         }
 597
 598         this.damageforcescale = 2;
 599         this.death_time = 0;
 600         this.respawn_flags = 0;
 601         this.respawn_time = 0;
 602         STAT(RESPAWN_TIME, this) = 0;
 603         this.scale = autocvar_sv_player_scale;
 604         this.fade_time = 0;
 605         this.pain_frame = 0;
 606         this.pain_finished = 0;
 607         this.pushltime = 0;
 608         setthink(this, func_null); // players have no think function
 609         this.nextthink = 0;
 610         this.dmg_team = 0;
 611         PS(this).ballistics_density = autocvar_g_ballistics_density_player;
 612
 613         this.deadflag = DEAD_NO;
 614
 615         this.angles = spot.angles;
 616         this.angles_z = 0; // never spawn tilted even if the spot says to
 617         if (IS_BOT_CLIENT(this))
 618                 this.v_angle = this.angles;
 619         this.fixangle = true; // turn this way immediately
 620         this.oldvelocity = this.velocity = '0 0 0';
 621         this.avelocity = '0 0 0';
 622         this.punchangle = '0 0 0';
 623         this.punchvector = '0 0 0';
 624
 625         this.strength_finished = 0;
 626         this.invincible_finished = 0;
 627         this.fire_endtime = -1;
 628         STAT(REVIVE_PROGRESS, this) = 0;
 629         this.revival_time = 0;
 630
 631         this.air_finished = time + 12;
 632         this.waterlevel = WATERLEVEL_NONE;
 633         this.watertype = CONTENT_EMPTY;
 634
 635         entity spawnevent = new_pure(spawnevent);
 636         spawnevent.owner = this;
 637         Net_LinkEntity(spawnevent, false, 0.5, SpawnEvent_Send);
 638
 639         // Cut off any still running player sounds.
 640         stopsound(this, CH_PLAYER_SINGLE);
 641
 642         this.model = "";
 643         FixPlayermodel(this);
 644         this.drawonlytoclient = NULL;
 645
 646         this.viewloc = NULL;
 647
 648         for(int slot = 0; slot < MAX_AXH; ++slot)
 649         {
 650                 entity axh = this.(AuxiliaryXhair[slot]);
 651                 this.(AuxiliaryXhair[slot]) = NULL;
 652
 653                 if(axh.owner == this && axh != NULL && !wasfreed(axh))
 654                         delete(axh);
 655         }
 656
 657         this.spawnpoint_targ = NULL;
 658
 659         this.crouch = false;
 660         this.view_ofs = STAT(PL_VIEW_OFS, this);
 661         setsize(this, STAT(PL_MIN, this), STAT(PL_MAX, this));
 662         this.spawnorigin = spot.origin;
 663         setorigin(this, spot.origin + '0 0 1' * (1 - this.mins.z - 24));
 664         // don't reset back to last position, even if new position is stuck in solid
 665         this.oldorigin = this.origin;
 666         if(this.conveyor)
 667                 IL_REMOVE(g_conveyed, this);
 668         this.conveyor = NULL; // prevent conveyors at the previous location from moving a freshly spawned player
 669         STAT(HUD, this) = HUD_NORMAL;
 670
 671         this.event_damage = PlayerDamage;
 672
 673         if(!this.bot_attack)
 674                 IL_PUSH(g_bot_targets, this);
 675         this.bot_attack = true;
 676         if(!this.monster_attack)
 677                 IL_PUSH(g_monster_targets, this);
 678         this.monster_attack = true;
 679         navigation_dynamicgoal_init(this, false);
 680
 681         PHYS_INPUT_BUTTON_ATCK(this) = PHYS_INPUT_BUTTON_JUMP(this) = PHYS_INPUT_BUTTON_ATCK2(this) = false;
 682
 683         // player was spectator
 684         if (CS(this).killcount == FRAGS_SPECTATOR) {
 685                 PlayerScore_Clear(this);
 686                 CS(this).killcount = 0;
 687                 CS(this).startplaytime = time;
 688         }
 689
 690         for (int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 691         {
 692                 .entity weaponentity = weaponentities[slot];
 693                 entity oldwep = this.(weaponentity);
 694                 CL_SpawnWeaponentity(this, weaponentity);
 695                 if(oldwep && oldwep.owner == this)
 696                         this.(weaponentity).m_gunalign = oldwep.m_gunalign;
 697         }
 698         this.alpha = default_player_alpha;
 699         this.colormod = '1 1 1' * autocvar_g_player_brightness;
 700         this.exteriorweaponentity.alpha = default_weapon_alpha;
 701
 702         this.speedrunning = false;
 703
 704         target_voicescript_clear(this);
 705
 706         // reset fields the weapons may use
 707         FOREACH(Weapons, true, {
 708                 it.wr_resetplayer(it, this);
 709                         // reload all reloadable weapons
 710                 if (it.spawnflags & WEP_FLAG_RELOADABLE) {
 711                         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 712                         {
 713                                 .entity weaponentity = weaponentities[slot];
 714                                 this.(weaponentity).weapon_load[it.m_id] = it.reloading_ammo;
 715                         }
 716                 }
 717         });
 718
 719         {
 720                 string s = spot.target;
 721                 spot.target = string_null;
 722                 SUB_UseTargets(spot, this, NULL);
 723                 spot.target = s;
 724         }
 725
 726         Unfreeze(this);
 727
 728         MUTATOR_CALLHOOK(PlayerSpawn, this, spot);
 729
 730         if (autocvar_spawn_debug)
 731         {
 732                 sprint(this, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
 733                 delete(spot); // usefull for checking if there are spawnpoints, that let drop through the floor
 734         }
 735
 736         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 737         {
 738                 .entity weaponentity = weaponentities[slot];
 739                 if(slot == 0 || autocvar_g_weaponswitch_debug == 1)
 740                         this.(weaponentity).m_switchweapon = w_getbestweapon(this, weaponentity);
 741                 else
 742                         this.(weaponentity).m_switchweapon = WEP_Null;
 743                 this.(weaponentity).m_weapon = WEP_Null;
 744                 this.(weaponentity).weaponname = "";
 745                 this.(weaponentity).m_switchingweapon = WEP_Null;
 746                 this.(weaponentity).cnt = -1;
 747         }
 748
 749         MUTATOR_CALLHOOK(PlayerWeaponSelect, this);
 750
 751         if (!warmup_stage && !this.alivetime)
 752                 this.alivetime = time;
 753
 754         antilag_clear(this, CS(this));
 755 }
 756
 757 /** Called when a client spawns in the server */
 758 void PutClientInServer(entity this)
 759 {
 760         if (IS_BOT_CLIENT(this)) {
 761                 TRANSMUTE(Player, this);
 762         } else if (IS_REAL_CLIENT(this)) {
 763                 msg_entity = this;
 764                 WriteByte(MSG_ONE, SVC_SETVIEW);
 765                 WriteEntity(MSG_ONE, this);
 766         }
 767         if (game_stopped)
 768                 TRANSMUTE(Observer, this);
 769
 770         SetSpectatee(this, NULL);
 771
 772         // reset player keys
 773         if(PS(this))
 774                 PS(this).itemkeys = 0;
 775
 776         MUTATOR_CALLHOOK(PutClientInServer, this);
 777
 778         if (IS_OBSERVER(this)) {
 779                 PutObserverInServer(this);
 780         } else if (IS_PLAYER(this)) {
 781                 PutPlayerInServer(this);
 782         }
 783 }
 784
 785 void ClientInit_misc(entity this);
 786
 787 // TODO do we need all these fields, or should we stop autodetecting runtime
 788 // changes and just have a console command to update this?
 789 bool ClientInit_SendEntity(entity this, entity to, int sf)
 790 {
 791         WriteHeader(MSG_ENTITY, _ENT_CLIENT_INIT);
 792         return = true;
 793         msg_entity = to;
 794         // MSG_INIT replacement
 795         // TODO: make easier to use
 796         Registry_send_all();
 797         W_PROP_reload(MSG_ONE, to);
 798         ClientInit_misc(this);
 799         MUTATOR_CALLHOOK(Ent_Init);
 800 }
 801 void ClientInit_misc(entity this)
 802 {
 803         int channel = MSG_ONE;
 804         WriteHeader(channel, ENT_CLIENT_INIT);
 805         WriteByte(channel, g_nexball_meter_period * 32);
 806         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[0]));
 807         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[1]));
 808         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[2]));
 809         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[3]));
 810         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[0]));
 811         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[1]));
 812         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[2]));
 813         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[3]));
 814
 815         if(sv_foginterval && world.fog != "")
 816                 WriteString(channel, world.fog);
 817         else
 818                 WriteString(channel, "");
 819         WriteByte(channel, this.count * 255.0); // g_balance_armor_blockpercent
 820         WriteByte(channel, this.cnt * 255.0); // g_balance_damagepush_speedfactor
 821         WriteByte(channel, serverflags);
 822         WriteCoord(channel, autocvar_g_trueaim_minrange);
 823 }
 824
 825 void ClientInit_CheckUpdate(entity this)
 826 {
 827         this.nextthink = time;
 828         if(this.count != autocvar_g_balance_armor_blockpercent)
 829         {
 830                 this.count = autocvar_g_balance_armor_blockpercent;
 831                 this.SendFlags |= 1;
 832         }
 833         if(this.cnt != autocvar_g_balance_damagepush_speedfactor)
 834         {
 835                 this.cnt = autocvar_g_balance_damagepush_speedfactor;
 836                 this.SendFlags |= 1;
 837         }
 838 }
 839
 840 void ClientInit_Spawn()
 841 {
 842         entity e = new_pure(clientinit);
 843         setthink(e, ClientInit_CheckUpdate);
 844         Net_LinkEntity(e, false, 0, ClientInit_SendEntity);
 845
 846         ClientInit_CheckUpdate(e);
 847 }
 848
 849 /*
 850 =============
 851 SetNewParms
 852 =============
 853 */
 854 void SetNewParms ()
 855 {
 856         // initialize parms for a new player
 857         parm1 = -(86400 * 366);
 858
 859         MUTATOR_CALLHOOK(SetNewParms);
 860 }
 861
 862 /*
 863 =============
 864 SetChangeParms
 865 =============
 866 */
 867 void SetChangeParms (entity this)
 868 {
 869         // save parms for level change
 870         parm1 = CS(this).parm_idlesince - time;
 871
 872         MUTATOR_CALLHOOK(SetChangeParms);
 873 }
 874
 875 /*
 876 =============
 877 DecodeLevelParms
 878 =============
 879 */
 880 void DecodeLevelParms(entity this)
 881 {
 882         // load parms
 883         CS(this).parm_idlesince = parm1;
 884         if (CS(this).parm_idlesince == -(86400 * 366))
 885                 CS(this).parm_idlesince = time;
 886
 887         // whatever happens, allow 60 seconds of idling directly after connect for map loading
 888         CS(this).parm_idlesince = max(CS(this).parm_idlesince, time - sv_maxidle + 60);
 889
 890         MUTATOR_CALLHOOK(DecodeLevelParms);
 891 }
 892
 893 /*
 894 =============
 895 ClientKill
 896
 897 Called when a client types 'kill' in the console
 898 =============
 899 */
 900
 901 .float clientkill_nexttime;
 902 void ClientKill_Now_TeamChange(entity this)
 903 {
 904         if(this.killindicator_teamchange == -1)
 905         {
 906                 JoinBestTeam( this, true );
 907         }
 908         else if(this.killindicator_teamchange == -2)
 909         {
 910                 if(blockSpectators)
 911                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
 912                 PutObserverInServer(this);
 913         }
 914         else
 915                 SV_ChangeTeam(this, this.killindicator_teamchange - 1);
 916         this.killindicator_teamchange = 0;
 917 }
 918
 919 void ClientKill_Now(entity this)
 920 {
 921         if(this.vehicle)
 922         {
 923             vehicles_exit(this.vehicle, VHEF_RELEASE);
 924             if(!this.killindicator_teamchange)
 925             {
 926             this.vehicle_health = -1;
 927             Damage(this, this, this, 1 , DEATH_KILL.m_id, DMG_NOWEP, this.origin, '0 0 0');
 928             }
 929         }
 930
 931         if(this.killindicator && !wasfreed(this.killindicator))
 932                 delete(this.killindicator);
 933
 934         this.killindicator = NULL;
 935
 936         if(this.killindicator_teamchange)
 937                 ClientKill_Now_TeamChange(this);
 938
 939         if (!IS_SPEC(this) && !IS_OBSERVER(this) && MUTATOR_CALLHOOK(ClientKill_Now, this) == false)
 940         {
 941                 Damage(this, this, this, 100000, DEATH_KILL.m_id, DMG_NOWEP, this.origin, '0 0 0');
 942         }
 943
 944         // now I am sure the player IS dead
 945 }
 946 void KillIndicator_Think(entity this)
 947 {
 948         if (game_stopped)
 949         {
 950                 this.owner.killindicator = NULL;
 951                 delete(this);
 952                 return;
 953         }
 954
 955         if (this.owner.alpha < 0 && !this.owner.vehicle)
 956         {
 957                 this.owner.killindicator = NULL;
 958                 delete(this);
 959                 return;
 960         }
 961
 962         if(this.cnt <= 0)
 963         {
 964                 ClientKill_Now(this.owner);
 965                 return;
 966         }
 967     else if(this.health == 1) // health == 1 means that it's silent
 968     {
 969         this.nextthink = time + 1;
 970         this.cnt -= 1;
 971     }
 972         else
 973         {
 974                 if(this.cnt <= 10)
 975                         setmodel(this, MDL_NUM(this.cnt));
 976                 if(IS_REAL_CLIENT(this.owner))
 977                 {
 978                         if(this.cnt <= 10)
 979                                 { Send_Notification(NOTIF_ONE, this.owner, MSG_ANNCE, Announcer_PickNumber(CNT_KILL, this.cnt)); }
 980                 }
 981                 this.nextthink = time + 1;
 982                 this.cnt -= 1;
 983         }
 984 }
 985
 986 float clientkilltime;
 987 void ClientKill_TeamChange (entity this, float targetteam) // 0 = don't change, -1 = auto, -2 = spec
 988 {
 989         float killtime;
 990         float starttime;
 991
 992         if (game_stopped)
 993                 return;
 994
 995         killtime = autocvar_g_balance_kill_delay;
 996
 997     if(MUTATOR_CALLHOOK(ClientKill, this, killtime))
 998         return;
 999     killtime = M_ARGV(1, float);
1000
1001         this.killindicator_teamchange = targetteam;
1002
1003     if(!this.killindicator)
1004         {
1005                 if(!IS_DEAD(this))
1006                 {
1007                         killtime = max(killtime, this.clientkill_nexttime - time);
1008                         this.clientkill_nexttime = time + killtime + autocvar_g_balance_kill_antispam;
1009                 }
1010
1011                 if(killtime <= 0 || !IS_PLAYER(this) || IS_DEAD(this))
1012                 {
1013                         ClientKill_Now(this);
1014                 }
1015                 else
1016                 {
1017                         starttime = max(time, clientkilltime);
1018
1019                         this.killindicator = spawn();
1020                         this.killindicator.owner = this;
1021                         this.killindicator.scale = 0.5;
1022                         setattachment(this.killindicator, this, "");
1023                         setorigin(this.killindicator, '0 0 52');
1024                         setthink(this.killindicator, KillIndicator_Think);
1025                         this.killindicator.nextthink = starttime + (this.lip) * 0.05;
1026                         clientkilltime = max(clientkilltime, this.killindicator.nextthink + 0.05);
1027                         this.killindicator.cnt = ceil(killtime);
1028                         this.killindicator.count = bound(0, ceil(killtime), 10);
1029                         //sprint(this, strcat("^1You'll be dead in ", ftos(this.killindicator.cnt), " seconds\n"));
1030
1031                         IL_EACH(g_clones, it.enemy == this && !(it.effects & CSQCMODEL_EF_RESPAWNGHOST),
1032                         {
1033                                 it.killindicator = spawn();
1034                                 it.killindicator.owner = it;
1035                                 it.killindicator.scale = 0.5;
1036                                 setattachment(it.killindicator, it, "");
1037                                 setorigin(it.killindicator, '0 0 52');
1038                                 setthink(it.killindicator, KillIndicator_Think);
1039                                 it.killindicator.nextthink = starttime + (it.lip) * 0.05;
1040                                 //clientkilltime = max(clientkilltime, it.killindicator.nextthink + 0.05);
1041                                 it.killindicator.cnt = ceil(killtime);
1042                         });
1043                         this.lip = 0;
1044                 }
1045         }
1046         if(this.killindicator)
1047         {
1048                 if(targetteam == 0) // just die
1049                 {
1050                         this.killindicator.colormod = '0 0 0';
1051                         if(IS_REAL_CLIENT(this))
1052                         if(this.killindicator.cnt > 0)
1053                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_TEAMCHANGE_SUICIDE, this.killindicator.cnt);
1054                 }
1055                 else if(targetteam == -1) // auto
1056                 {
1057                         this.killindicator.colormod = '0 1 0';
1058                         if(IS_REAL_CLIENT(this))
1059                         if(this.killindicator.cnt > 0)
1060                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_TEAMCHANGE_AUTO, this.killindicator.cnt);
1061                 }
1062                 else if(targetteam == -2) // spectate
1063                 {
1064                         this.killindicator.colormod = '0.5 0.5 0.5';
1065                         if(IS_REAL_CLIENT(this))
1066                         if(this.killindicator.cnt > 0)
1067                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_TEAMCHANGE_SPECTATE, this.killindicator.cnt);
1068                 }
1069                 else
1070                 {
1071                         this.killindicator.colormod = Team_ColorRGB(targetteam);
1072                         if(IS_REAL_CLIENT(this))
1073                         if(this.killindicator.cnt > 0)
1074                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, APP_TEAM_NUM(targetteam, CENTER_TEAMCHANGE), this.killindicator.cnt);
1075                 }
1076         }
1077
1078 }
1079
1080 void ClientKill (entity this)
1081 {
1082         if(game_stopped) return;
1083         if(this.player_blocked) return;
1084         if(STAT(FROZEN, this)) return;
1085
1086         ClientKill_TeamChange(this, 0);
1087 }
1088
1089 void FixClientCvars(entity e)
1090 {
1091         // send prediction settings to the client
1092         stuffcmd(e, "\nin_bindmap 0 0\n");
1093         if(autocvar_g_antilag == 3) // client side hitscan
1094                 stuffcmd(e, "cl_cmd settemp cl_prydoncursor_notrace 0\n");
1095         if(autocvar_sv_gentle)
1096                 stuffcmd(e, "cl_cmd settemp cl_gentle 1\n");
1097
1098         stuffcmd(e, sprintf("\ncl_jumpspeedcap_min \"%s\"\n", autocvar_sv_jumpspeedcap_min));
1099         stuffcmd(e, sprintf("\ncl_jumpspeedcap_max \"%s\"\n", autocvar_sv_jumpspeedcap_max));
1100
1101         stuffcmd(e, sprintf("\ncl_shootfromfixedorigin \"%s\"\n", autocvar_g_shootfromfixedorigin));
1102
1103         MUTATOR_CALLHOOK(FixClientCvars, e);
1104 }
1105
1106 bool findinlist_abbrev(string tofind, string list)
1107 {
1108         if(list == "" || tofind == "")
1109                 return false; // empty list or search, just return
1110
1111         // this function allows abbreviated strings!
1112         FOREACH_WORD(list, it == substring(tofind, 0, strlen(it)),
1113         {
1114                 return true;
1115         });
1116
1117         return false;
1118 }
1119
1120 bool PlayerInIPList(entity p, string iplist)
1121 {
1122         // some safety checks (never allow local?)
1123         if(p.netaddress == "local" || p.netaddress == "" || !IS_REAL_CLIENT(p))
1124                 return false;
1125
1126         return findinlist_abbrev(p.netaddress, iplist);
1127 }
1128
1129 bool PlayerInIDList(entity p, string idlist)
1130 {
1131         // NOTE: we do NOT check crypto_idfp_signed here, an unsigned ID is fine too for this
1132         if(!p.crypto_idfp)
1133                 return false;
1134
1135         return findinlist_abbrev(p.crypto_idfp, idlist);
1136 }
1137
1138 bool PlayerInList(entity player, string list)
1139 {
1140         return boolean(PlayerInIDList(player, list) || PlayerInIPList(player, list));
1141 }
1142
1143 #ifdef DP_EXT_PRECONNECT
1144 /*
1145 =============
1146 ClientPreConnect
1147
1148 Called once (not at each match start) when a client begins a connection to the server
1149 =============
1150 */
1151 void ClientPreConnect(entity this)
1152 {
1153         if(autocvar_sv_eventlog)
1154         {
1155                 GameLogEcho(sprintf(":connect:%d:%d:%s",
1156                         this.playerid,
1157                         etof(this),
1158                         ((IS_REAL_CLIENT(this)) ? this.netaddress : "bot")
1159                 ));
1160         }
1161 }
1162 #endif
1163
1164 /**
1165 =============
1166 ClientConnect
1167
1168 Called when a client connects to the server
1169 =============
1170 */
1171 void ClientConnect(entity this)
1172 {
1173         if (Ban_MaybeEnforceBanOnce(this)) return;
1174         assert(!IS_CLIENT(this), return);
1175         this.flags |= FL_CLIENT;
1176         assert(player_count >= 0, player_count = 0);
1177
1178 #ifdef WATERMARK
1179         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_WATERMARK, WATERMARK);
1180 #endif
1181         TRANSMUTE(Client, this);
1182         CS(this).version_nagtime = time + 10 + random() * 10;
1183
1184         // identify the right forced team
1185         if (autocvar_g_campaign)
1186         {
1187                 if (IS_REAL_CLIENT(this)) // only players, not bots
1188                 {
1189                         switch (autocvar_g_campaign_forceteam)
1190                         {
1191                                 case 1: this.team_forced = NUM_TEAM_1; break;
1192                                 case 2: this.team_forced = NUM_TEAM_2; break;
1193                                 case 3: this.team_forced = NUM_TEAM_3; break;
1194                                 case 4: this.team_forced = NUM_TEAM_4; break;
1195                                 default: this.team_forced = 0;
1196                         }
1197                 }
1198         }
1199         else if (PlayerInList(this, autocvar_g_forced_team_red))    this.team_forced = NUM_TEAM_1;
1200         else if (PlayerInList(this, autocvar_g_forced_team_blue))   this.team_forced = NUM_TEAM_2;
1201         else if (PlayerInList(this, autocvar_g_forced_team_yellow)) this.team_forced = NUM_TEAM_3;
1202         else if (PlayerInList(this, autocvar_g_forced_team_pink))   this.team_forced = NUM_TEAM_4;
1203         else switch (autocvar_g_forced_team_otherwise)
1204         {
1205                 default: this.team_forced = 0; break;
1206                 case "red": this.team_forced = NUM_TEAM_1; break;
1207                 case "blue": this.team_forced = NUM_TEAM_2; break;
1208                 case "yellow": this.team_forced = NUM_TEAM_3; break;
1209                 case "pink": this.team_forced = NUM_TEAM_4; break;
1210                 case "spectate":
1211                 case "spectator":
1212                         this.team_forced = -1;
1213                         break;
1214         }
1215         if (!teamplay && this.team_forced > 0) this.team_forced = 0;
1216
1217         int playerid_save = this.playerid;
1218         this.playerid = 0; // silent
1219         JoinBestTeam(this, false); // if the team number is valid, keep it
1220         this.playerid = playerid_save;
1221
1222         TRANSMUTE(Observer, this);
1223
1224         PlayerStats_GameReport_AddEvent(sprintf("kills-%d", this.playerid));
1225
1226         // always track bots, don't ask for cl_allow_uidtracking
1227         if (IS_BOT_CLIENT(this))
1228                 PlayerStats_GameReport_AddPlayer(this);
1229         else
1230                 CS(this).allowed_timeouts = autocvar_sv_timeout_number;
1231
1232         if (autocvar_sv_eventlog)
1233                 GameLogEcho(strcat(":join:", ftos(this.playerid), ":", ftos(etof(this)), ":", ((IS_REAL_CLIENT(this)) ? this.netaddress : "bot"), ":", playername(this, false)));
1234
1235         LogTeamchange(this.playerid, this.team, 1);
1236
1237         CS(this).just_joined = true;  // stop spamming the eventlog with additional lines when the client connects
1238
1239         if(teamplay && IS_PLAYER(this))
1240                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, APP_TEAM_NUM(this.team, INFO_JOIN_CONNECT_TEAM), this.netname);
1241         else
1242                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_JOIN_CONNECT, this.netname);
1243
1244         stuffcmd(this, clientstuff, "\n");
1245         stuffcmd(this, "cl_particles_reloadeffects\n"); // TODO do we still need this?
1246
1247         FixClientCvars(this);
1248
1249         // get version info from player
1250         stuffcmd(this, "cmd clientversion $gameversion\n");
1251
1252         // notify about available teams
1253         if (teamplay)
1254         {
1255                 CheckAllowedTeams(this);
1256                 int t = 0;
1257                 if (c1 >= 0) t |= BIT(0);
1258                 if (c2 >= 0) t |= BIT(1);
1259                 if (c3 >= 0) t |= BIT(2);
1260                 if (c4 >= 0) t |= BIT(3);
1261                 stuffcmd(this, sprintf("set _teams_available %d\n", t));
1262         }
1263         else
1264         {
1265                 stuffcmd(this, "set _teams_available 0\n");
1266         }
1267
1268         bot_relinkplayerlist();
1269
1270         CS(this).spectatortime = time;
1271         if (blockSpectators)
1272         {
1273                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
1274         }
1275
1276         CS(this).jointime = time;
1277
1278         if (IS_REAL_CLIENT(this))
1279         {
1280                 if (g_weaponarena_weapons == WEPSET(TUBA))
1281                         stuffcmd(this, "cl_cmd settemp chase_active 1\n");
1282         }
1283
1284         if (!sv_foginterval && world.fog != "")
1285                 stuffcmd(this, strcat("\nfog ", world.fog, "\nr_fog_exp2 0\nr_drawfog 1\n"));
1286
1287         if (autocvar_sv_teamnagger && !(autocvar_bot_vs_human && AvailableTeams() == 2))
1288                 if(!MUTATOR_CALLHOOK(HideTeamNagger, this))
1289                         send_CSQC_teamnagger();
1290
1291         CSQCMODEL_AUTOINIT(this);
1292
1293         CS(this).model_randomizer = random();
1294
1295         if (IS_REAL_CLIENT(this))
1296                 sv_notice_join(this);
1297
1298         // update physics stats (players can spawn before physics runs)
1299         Physics_UpdateStats(this);
1300
1301         IL_EACH(g_initforplayer, it.init_for_player, {
1302                 it.init_for_player(it, this);
1303         });
1304
1305         Handicap_Initialize(this);
1306
1307         MUTATOR_CALLHOOK(ClientConnect, this);
1308
1309         if (IS_REAL_CLIENT(this))
1310         {
1311                 if (!autocvar_g_campaign && !IS_PLAYER(this))
1312                 {
1313                         CS(this).motd_actived_time = -1;
1314                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOTD, getwelcomemessage(this));
1315                 }
1316         }
1317 }
1318 /*
1319 =============
1320 ClientDisconnect
1321
1322 Called when a client disconnects from the server
1323 =============
1324 */
1325 .entity chatbubbleentity;
1326 void ReadyCount();
1327 void ClientDisconnect(entity this)
1328 {
1329         assert(IS_CLIENT(this), return);
1330
1331         PlayerStats_GameReport_FinalizePlayer(this);
1332         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
1333         if (CS(this).active_minigame) part_minigame(this);
1334         if (IS_PLAYER(this)) Send_Effect(EFFECT_SPAWN_NEUTRAL, this.origin, '0 0 0', 1);
1335
1336         if (autocvar_sv_eventlog)
1337                 GameLogEcho(strcat(":part:", ftos(this.playerid)));
1338
1339         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_QUIT_DISCONNECT, this.netname);
1340
1341         if(IS_SPEC(this))
1342                 SetSpectatee(this, NULL);
1343
1344     MUTATOR_CALLHOOK(ClientDisconnect, this);
1345
1346         if (CS(this).netname_previous) strunzone(CS(this).netname_previous); // needs to be before the CS entity is removed!
1347         if (CS(this).weaponorder_byimpulse) strunzone(CS(this).weaponorder_byimpulse);
1348         ClientState_detach(this);
1349
1350         Portal_ClearAll(this);
1351
1352         Unfreeze(this);
1353
1354         RemoveGrapplingHooks(this);
1355
1356         // Here, everything has been done that requires this player to be a client.
1357
1358         this.flags &= ~FL_CLIENT;
1359
1360         if (this.chatbubbleentity) delete(this.chatbubbleentity);
1361         if (this.killindicator) delete(this.killindicator);
1362
1363         WaypointSprite_PlayerGone(this);
1364
1365         bot_relinkplayerlist();
1366
1367         if (this.clientstatus) strunzone(this.clientstatus);
1368         if (this.personal) delete(this.personal);
1369
1370         this.playerid = 0;
1371         ReadyCount();
1372         if (vote_called && IS_REAL_CLIENT(this)) VoteCount(false);
1373
1374         ONREMOVE(this);
1375 }
1376
1377 void ChatBubbleThink(entity this)
1378 {
1379         this.nextthink = time;
1380         if ((this.owner.alpha < 0) || this.owner.chatbubbleentity != this)
1381         {
1382                 if(this.owner) // but why can that ever be NULL?
1383                         this.owner.chatbubbleentity = NULL;
1384                 delete(this);
1385                 return;
1386         }
1387
1388         this.mdl = "";
1389
1390         if ( !IS_DEAD(this.owner) && IS_PLAYER(this.owner) )
1391         {
1392                 if ( CS(this.owner).active_minigame )
1393                         this.mdl = "models/sprites/minigame_busy.iqm";
1394                 else if (PHYS_INPUT_BUTTON_CHAT(this.owner))
1395                         this.mdl = "models/misc/chatbubble.spr";
1396         }
1397
1398         if ( this.model != this.mdl )
1399                 _setmodel(this, this.mdl);
1400
1401 }
1402
1403 void UpdateChatBubble(entity this)
1404 {
1405         if (this.alpha < 0)
1406                 return;
1407         // spawn a chatbubble entity if needed
1408         if (!this.chatbubbleentity)
1409         {
1410                 this.chatbubbleentity = new(chatbubbleentity);
1411                 this.chatbubbleentity.owner = this;
1412                 this.chatbubbleentity.exteriormodeltoclient = this;
1413                 setthink(this.chatbubbleentity, ChatBubbleThink);
1414                 this.chatbubbleentity.nextthink = time;
1415                 setmodel(this.chatbubbleentity, MDL_CHAT); // precision set below
1416                 //setorigin(this.chatbubbleentity, this.origin + '0 0 15' + this.maxs_z * '0 0 1');
1417                 setorigin(this.chatbubbleentity, '0 0 15' + this.maxs_z * '0 0 1');
1418                 setattachment(this.chatbubbleentity, this, "");  // sticks to moving player better, also conserves bandwidth
1419                 this.chatbubbleentity.mdl = this.chatbubbleentity.model;
1420                 //this.chatbubbleentity.model = "";
1421                 this.chatbubbleentity.effects = EF_LOWPRECISION;
1422         }
1423 }
1424
1425
1426 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
1427 // added to the model skins
1428 /*void UpdateColorModHack()
1429 {
1430         float c;
1431         c = this.clientcolors & 15;
1432         // LordHavoc: only bothering to support white, green, red, yellow, blue
1433              if (!teamplay) this.colormod = '0 0 0';
1434         else if (c ==  0) this.colormod = '1.00 1.00 1.00';
1435         else if (c ==  3) this.colormod = '0.10 1.73 0.10';
1436         else if (c ==  4) this.colormod = '1.73 0.10 0.10';
1437         else if (c == 12) this.colormod = '1.22 1.22 0.10';
1438         else if (c == 13) this.colormod = '0.10 0.10 1.73';
1439         else this.colormod = '1 1 1';
1440 }*/
1441
1442 void respawn(entity this)
1443 {
1444         if(this.alpha >= 0 && autocvar_g_respawn_ghosts)
1445         {
1446                 this.solid = SOLID_NOT;
1447                 this.takedamage = DAMAGE_NO;
1448                 set_movetype(this, MOVETYPE_FLY);
1449                 this.velocity = '0 0 1' * autocvar_g_respawn_ghosts_speed;
1450                 this.avelocity = randomvec() * autocvar_g_respawn_ghosts_speed * 3 - randomvec() * autocvar_g_respawn_ghosts_speed * 3;
1451                 this.effects |= CSQCMODEL_EF_RESPAWNGHOST;
1452                 Send_Effect(EFFECT_RESPAWN_GHOST, this.origin, '0 0 0', 1);
1453                 if(autocvar_g_respawn_ghosts_maxtime)
1454                         SUB_SetFade (this, time + autocvar_g_respawn_ghosts_maxtime / 2 + random () * (autocvar_g_respawn_ghosts_maxtime - autocvar_g_respawn_ghosts_maxtime / 2), 1.5);
1455         }
1456
1457         CopyBody(this, 1);
1458
1459         this.effects |= EF_NODRAW; // prevent another CopyBody
1460         PutClientInServer(this);
1461 }
1462
1463 void play_countdown(entity this, float finished, Sound samp)
1464 {
1465     TC(Sound, samp);
1466         if(IS_REAL_CLIENT(this))
1467                 if(floor(finished - time - frametime) != floor(finished - time))
1468                         if(finished - time < 6)
1469                                 sound (this, CH_INFO, samp, VOL_BASE, ATTEN_NORM);
1470 }
1471
1472 void player_powerups(entity this)
1473 {
1474         // add a way to see what the items were BEFORE all of these checks for the mutator hook
1475         int items_prev = this.items;
1476
1477         if((this.items & IT_USING_JETPACK) && !IS_DEAD(this) && !game_stopped)
1478                 this.modelflags |= MF_ROCKET;
1479         else
1480                 this.modelflags &= ~MF_ROCKET;
1481
1482         this.effects &= ~(EF_RED | EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT | EF_FLAME | EF_NODEPTHTEST);
1483
1484         if((this.alpha < 0 || IS_DEAD(this)) && !this.vehicle) // don't apply the flags if the player is gibbed
1485                 return;
1486
1487         Fire_ApplyDamage(this);
1488         Fire_ApplyEffect(this);
1489
1490         if (!g_instagib)
1491         {
1492                 if (this.items & ITEM_Strength.m_itemid)
1493                 {
1494                         play_countdown(this, this.strength_finished, SND_POWEROFF);
1495                         this.effects = this.effects | (EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT);
1496                         if (time > this.strength_finished)
1497                         {
1498                                 this.items = this.items - (this.items & ITEM_Strength.m_itemid);
1499                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERDOWN_STRENGTH, this.netname);
1500                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERDOWN_STRENGTH);
1501                         }
1502                 }
1503                 else
1504                 {
1505                         if (time < this.strength_finished)
1506                         {
1507                                 this.items = this.items | ITEM_Strength.m_itemid;
1508                                 if(!g_cts)
1509                                         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERUP_STRENGTH, this.netname);
1510                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERUP_STRENGTH);
1511                         }
1512                 }
1513                 if (this.items & ITEM_Shield.m_itemid)
1514                 {
1515                         play_countdown(this, this.invincible_finished, SND_POWEROFF);
1516                         this.effects = this.effects | (EF_RED | EF_ADDITIVE | EF_FULLBRIGHT);
1517                         if (time > this.invincible_finished)
1518                         {
1519                                 this.items = this.items - (this.items & ITEM_Shield.m_itemid);
1520                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERDOWN_SHIELD, this.netname);
1521                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERDOWN_SHIELD);
1522                         }
1523                 }
1524                 else
1525                 {
1526                         if (time < this.invincible_finished)
1527                         {
1528                                 this.items = this.items | ITEM_Shield.m_itemid;
1529                                 if(!g_cts)
1530                                         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERUP_SHIELD, this.netname);
1531                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERUP_SHIELD);
1532                         }
1533                 }
1534                 if (this.items & IT_SUPERWEAPON)
1535                 {
1536                         if (!(this.weapons & WEPSET_SUPERWEAPONS))
1537                         {
1538                                 this.superweapons_finished = 0;
1539                                 this.items = this.items - (this.items & IT_SUPERWEAPON);
1540                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_LOST, this.netname);
1541                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_LOST);
1542                         }
1543                         else if (this.items & IT_UNLIMITED_SUPERWEAPONS)
1544                         {
1545                                 // don't let them run out
1546                         }
1547                         else
1548                         {
1549                                 play_countdown(this, this.superweapons_finished, SND_POWEROFF);
1550                                 if (time > this.superweapons_finished)
1551                                 {
1552                                         this.items = this.items - (this.items & IT_SUPERWEAPON);
1553                                         this.weapons &= ~WEPSET_SUPERWEAPONS;
1554                                         //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_BROKEN, this.netname);
1555                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_BROKEN);
1556                                 }
1557                         }
1558                 }
1559                 else if(this.weapons & WEPSET_SUPERWEAPONS)
1560                 {
1561                         if (time < this.superweapons_finished || (this.items & IT_UNLIMITED_SUPERWEAPONS))
1562                         {
1563                                 this.items = this.items | IT_SUPERWEAPON;
1564                                 if(!g_cts)
1565                                         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_PICKUP, this.netname);
1566                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_PICKUP);
1567                         }
1568                         else
1569                         {
1570                                 this.superweapons_finished = 0;
1571                                 this.weapons &= ~WEPSET_SUPERWEAPONS;
1572                         }
1573                 }
1574                 else
1575                 {
1576                         this.superweapons_finished = 0;
1577                 }
1578         }
1579
1580         if(autocvar_g_nodepthtestplayers)
1581                 this.effects = this.effects | EF_NODEPTHTEST;
1582
1583         if(autocvar_g_fullbrightplayers)
1584                 this.effects = this.effects | EF_FULLBRIGHT;
1585
1586         if (time >= game_starttime)
1587         if (time < this.spawnshieldtime)
1588                 this.effects = this.effects | (EF_ADDITIVE | EF_FULLBRIGHT);
1589
1590         MUTATOR_CALLHOOK(PlayerPowerups, this, items_prev);
1591 }
1592
1593 float CalcRegen(float current, float stable, float regenfactor, float regenframetime)
1594 {
1595         if(current > stable)
1596                 return current;
1597         else if(current > stable - 0.25) // when close enough, "snap"
1598                 return stable;
1599         else
1600                 return min(stable, current + (stable - current) * regenfactor * regenframetime);
1601 }
1602
1603 float CalcRot(float current, float stable, float rotfactor, float rotframetime)
1604 {
1605         if(current < stable)
1606                 return current;
1607         else if(current < stable + 0.25) // when close enough, "snap"
1608                 return stable;
1609         else
1610                 return max(stable, current + (stable - current) * rotfactor * rotframetime);
1611 }
1612
1613 float CalcRotRegen(float current, float regenstable, float regenfactor, float regenlinear, float regenframetime, float rotstable, float rotfactor, float rotlinear, float rotframetime, float limit)
1614 {
1615         if(current > rotstable)
1616         {
1617                 if(rotframetime > 0)
1618                 {
1619                         current = CalcRot(current, rotstable, rotfactor, rotframetime);
1620                         current = max(rotstable, current - rotlinear * rotframetime);
1621                 }
1622         }
1623         else if(current < regenstable)
1624         {
1625                 if(regenframetime > 0)
1626                 {
1627                         current = CalcRegen(current, regenstable, regenfactor, regenframetime);
1628                         current = min(regenstable, current + regenlinear * regenframetime);
1629                 }
1630         }
1631
1632         if(current > limit)
1633                 current = limit;
1634
1635         return current;
1636 }
1637
1638 void player_regen(entity this)
1639 {
1640         float max_mod, regen_mod, rot_mod, limit_mod;
1641         max_mod = regen_mod = rot_mod = limit_mod = 1;
1642
1643         float regen_health = autocvar_g_balance_health_regen;
1644         float regen_health_linear = autocvar_g_balance_health_regenlinear;
1645         float regen_health_rot = autocvar_g_balance_health_rot;
1646         float regen_health_rotlinear = autocvar_g_balance_health_rotlinear;
1647         float regen_health_stable = autocvar_g_balance_health_regenstable;
1648         float regen_health_rotstable = autocvar_g_balance_health_rotstable;
1649         bool mutator_returnvalue = MUTATOR_CALLHOOK(PlayerRegen, this, max_mod, regen_mod, rot_mod, limit_mod, regen_health, regen_health_linear, regen_health_rot,
1650                 regen_health_rotlinear, regen_health_stable, regen_health_rotstable);
1651         max_mod = M_ARGV(1, float);
1652         regen_mod = M_ARGV(2, float);
1653         rot_mod = M_ARGV(3, float);
1654         limit_mod = M_ARGV(4, float);
1655         regen_health = M_ARGV(5, float);
1656         regen_health_linear = M_ARGV(6, float);
1657         regen_health_rot = M_ARGV(7, float);
1658         regen_health_rotlinear = M_ARGV(8, float);
1659         regen_health_stable = M_ARGV(9, float);
1660         regen_health_rotstable = M_ARGV(10, float);
1661
1662         if(!mutator_returnvalue)
1663         if(!STAT(FROZEN, this))
1664         {
1665                 float mina, maxa, limith, limita;
1666                 maxa = autocvar_g_balance_armor_rotstable;
1667                 mina = autocvar_g_balance_armor_regenstable;
1668                 limith = GetResourceLimit(this, RESOURCE_HEALTH);
1669                 limita = GetResourceLimit(this, RESOURCE_ARMOR);
1670
1671                 regen_health_rotstable = regen_health_rotstable * max_mod;
1672                 regen_health_stable = regen_health_stable * max_mod;
1673                 limith = limith * limit_mod;
1674                 limita = limita * limit_mod;
1675
1676                 this.armorvalue = CalcRotRegen(this.armorvalue, mina, autocvar_g_balance_armor_regen, autocvar_g_balance_armor_regenlinear, regen_mod * frametime * (time > this.pauseregen_finished), maxa, autocvar_g_balance_armor_rot, autocvar_g_balance_armor_rotlinear, rot_mod * frametime * (time > this.pauserotarmor_finished), limita);
1677                 this.health = CalcRotRegen(this.health, regen_health_stable, regen_health, regen_health_linear, regen_mod * frametime * (time > this.pauseregen_finished), regen_health_rotstable, regen_health_rot, regen_health_rotlinear, rot_mod * frametime * (time > this.pauserothealth_finished), limith);
1678         }
1679
1680         // if player rotted to death...  die!
1681         // check this outside above checks, as player may still be able to rot to death
1682         if(this.health < 1)
1683         {
1684                 if(this.vehicle)
1685                         vehicles_exit(this.vehicle, VHEF_RELEASE);
1686                 if(this.event_damage)
1687                         this.event_damage(this, this, this, 1, DEATH_ROT.m_id, DMG_NOWEP, this.origin, '0 0 0');
1688         }
1689
1690         if (!(this.items & IT_UNLIMITED_WEAPON_AMMO))
1691         {
1692                 float minf, maxf, limitf;
1693
1694                 maxf = autocvar_g_balance_fuel_rotstable;
1695                 minf = autocvar_g_balance_fuel_regenstable;
1696                 limitf = GetResourceLimit(this, RESOURCE_FUEL);
1697
1698                 this.ammo_fuel = CalcRotRegen(this.ammo_fuel, minf, autocvar_g_balance_fuel_regen, autocvar_g_balance_fuel_regenlinear, frametime * (time > this.pauseregen_finished) * ((this.items & ITEM_JetpackRegen.m_itemid) != 0), maxf, autocvar_g_balance_fuel_rot, autocvar_g_balance_fuel_rotlinear, frametime * (time > this.pauserotfuel_finished), limitf);
1699         }
1700         // Ugly hack to make sure the health and armor don't go beyond hard limit.
1701         // TODO: Remove this hack when all code uses GivePlayerHealth and
1702         // GivePlayerArmor.
1703         if (this.health > RESOURCE_AMOUNT_HARD_LIMIT)
1704         {
1705                 this.health = RESOURCE_AMOUNT_HARD_LIMIT;
1706         }
1707         if (this.armorvalue > RESOURCE_AMOUNT_HARD_LIMIT)
1708         {
1709                 this.armorvalue = RESOURCE_AMOUNT_HARD_LIMIT;
1710         }
1711         // End hack.
1712 }
1713
1714 bool zoomstate_set;
1715 void SetZoomState(entity this, float newzoom)
1716 {
1717         if(newzoom != CS(this).zoomstate)
1718         {
1719                 CS(this).zoomstate = newzoom;
1720                 ClientData_Touch(this);
1721         }
1722         zoomstate_set = true;
1723 }
1724
1725 void GetPressedKeys(entity this)
1726 {
1727         MUTATOR_CALLHOOK(GetPressedKeys, this);
1728         int keys = STAT(PRESSED_KEYS, this);
1729         keys = BITSET(keys, KEY_FORWARD,        CS(this).movement.x > 0);
1730         keys = BITSET(keys, KEY_BACKWARD,       CS(this).movement.x < 0);
1731         keys = BITSET(keys, KEY_RIGHT,          CS(this).movement.y > 0);
1732         keys = BITSET(keys, KEY_LEFT,           CS(this).movement.y < 0);
1733
1734         keys = BITSET(keys, KEY_JUMP,           PHYS_INPUT_BUTTON_JUMP(this));
1735         keys = BITSET(keys, KEY_CROUCH,         PHYS_INPUT_BUTTON_CROUCH(this));
1736         keys = BITSET(keys, KEY_ATCK,           PHYS_INPUT_BUTTON_ATCK(this));
1737         keys = BITSET(keys, KEY_ATCK2,          PHYS_INPUT_BUTTON_ATCK2(this));
1738         CS(this).pressedkeys = keys; // store for other users
1739
1740         STAT(PRESSED_KEYS, this) = keys;
1741 }
1742
1743 /*
1744 ======================
1745 spectate mode routines
1746 ======================
1747 */
1748
1749 void SpectateCopy(entity this, entity spectatee)
1750 {
1751     TC(Client, this); TC(Client, spectatee);
1752
1753         MUTATOR_CALLHOOK(SpectateCopy, spectatee, this);
1754         PS(this) = PS(spectatee);
1755         this.armortype = spectatee.armortype;
1756         this.armorvalue = spectatee.armorvalue;
1757         this.ammo_cells = spectatee.ammo_cells;
1758         this.ammo_plasma = spectatee.ammo_plasma;
1759         this.ammo_shells = spectatee.ammo_shells;
1760         this.ammo_nails = spectatee.ammo_nails;
1761         this.ammo_rockets = spectatee.ammo_rockets;
1762         this.ammo_fuel = spectatee.ammo_fuel;
1763         this.effects = spectatee.effects & EFMASK_CHEAP; // eat performance
1764         this.health = spectatee.health;
1765         CS(this).impulse = 0;
1766         this.items = spectatee.items;
1767         STAT(LAST_PICKUP, this) = STAT(LAST_PICKUP, spectatee);
1768         STAT(HIT_TIME, this) = STAT(HIT_TIME, spectatee);
1769         this.strength_finished = spectatee.strength_finished;
1770         this.invincible_finished = spectatee.invincible_finished;
1771         this.superweapons_finished = spectatee.superweapons_finished;
1772         STAT(PRESSED_KEYS, this) = STAT(PRESSED_KEYS, spectatee);
1773         this.weapons = spectatee.weapons;
1774         this.punchangle = spectatee.punchangle;
1775         this.view_ofs = spectatee.view_ofs;
1776         this.velocity = spectatee.velocity;
1777         this.dmg_take = spectatee.dmg_take;
1778         this.dmg_save = spectatee.dmg_save;
1779         this.dmg_inflictor = spectatee.dmg_inflictor;
1780         this.v_angle = spectatee.v_angle;
1781         this.angles = spectatee.v_angle;
1782         STAT(FROZEN, this) = STAT(FROZEN, spectatee);
1783         STAT(REVIVE_PROGRESS, this) = STAT(REVIVE_PROGRESS, spectatee);
1784         this.viewloc = spectatee.viewloc;
1785         if(!PHYS_INPUT_BUTTON_USE(this) && STAT(CAMERA_SPECTATOR, this) != 2)
1786                 this.fixangle = true;
1787         setorigin(this, spectatee.origin);
1788         setsize(this, spectatee.mins, spectatee.maxs);
1789         SetZoomState(this, CS(spectatee).zoomstate);
1790
1791     anticheat_spectatecopy(this, spectatee);
1792         STAT(HUD, this) = STAT(HUD, spectatee);
1793         if(spectatee.vehicle)
1794     {
1795         this.angles = spectatee.v_angle;
1796
1797         //this.fixangle = false;
1798         //this.velocity = spectatee.vehicle.velocity;
1799         this.vehicle_health = spectatee.vehicle_health;
1800         this.vehicle_shield = spectatee.vehicle_shield;
1801         this.vehicle_energy = spectatee.vehicle_energy;
1802         this.vehicle_ammo1 = spectatee.vehicle_ammo1;
1803         this.vehicle_ammo2 = spectatee.vehicle_ammo2;
1804         this.vehicle_reload1 = spectatee.vehicle_reload1;
1805         this.vehicle_reload2 = spectatee.vehicle_reload2;
1806
1807         //msg_entity = this;
1808
1809        // WriteByte (MSG_ONE, SVC_SETVIEWANGLES);
1810             //WriteAngle(MSG_ONE,  spectatee.v_angle.x);
1811            // WriteAngle(MSG_ONE,  spectatee.v_angle.y);
1812            // WriteAngle(MSG_ONE,  spectatee.v_angle.z);
1813
1814         //WriteByte (MSG_ONE, SVC_SETVIEW);
1815         //    WriteEntity(MSG_ONE, this);
1816         //makevectors(spectatee.v_angle);
1817         //setorigin(this, spectatee.origin - v_forward * 400 + v_up * 300);*/
1818     }
1819 }
1820
1821 bool SpectateUpdate(entity this)
1822 {
1823         if(!this.enemy)
1824                 return false;
1825
1826         if(!IS_PLAYER(this.enemy) || this == this.enemy)
1827         {
1828                 SetSpectatee(this, NULL);
1829                 return false;
1830         }
1831
1832         SpectateCopy(this, this.enemy);
1833
1834         return true;
1835 }
1836
1837 bool SpectateSet(entity this)
1838 {
1839         if(!IS_PLAYER(this.enemy))
1840                 return false;
1841
1842         ClientData_Touch(this.enemy);
1843
1844         msg_entity = this;
1845         WriteByte(MSG_ONE, SVC_SETVIEW);
1846         WriteEntity(MSG_ONE, this.enemy);
1847         set_movetype(this, MOVETYPE_NONE);
1848         accuracy_resend(this);
1849
1850         if(!SpectateUpdate(this))
1851                 PutObserverInServer(this);
1852
1853         return true;
1854 }
1855
1856 void SetSpectatee_status(entity this, int spectatee_num)
1857 {
1858         int oldspectatee_status = CS(this).spectatee_status;
1859         CS(this).spectatee_status = spectatee_num;
1860
1861         if (CS(this).spectatee_status != oldspectatee_status)
1862         {
1863                 ClientData_Touch(this);
1864                 if (g_race || g_cts) race_InitSpectator();
1865         }
1866 }
1867
1868 void SetSpectatee(entity this, entity spectatee)
1869 {
1870         if(IS_BOT_CLIENT(this))
1871                 return; // bots abuse .enemy, this code is useless to them
1872
1873         entity old_spectatee = this.enemy;
1874
1875         this.enemy = spectatee;
1876
1877         // WEAPONTODO
1878         // these are required to fix the spectator bug with arc
1879         if(old_spectatee)
1880         {
1881                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1882                 {
1883                         .entity weaponentity = weaponentities[slot];
1884                         if(old_spectatee.(weaponentity).arc_beam)
1885                                 old_spectatee.(weaponentity).arc_beam.SendFlags |= ARC_SF_SETTINGS;
1886                 }
1887         }
1888         if(this.enemy)
1889         {
1890                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1891                 {
1892                         .entity weaponentity = weaponentities[slot];
1893                         if(this.enemy.(weaponentity).arc_beam)
1894                                 this.enemy.(weaponentity).arc_beam.SendFlags |= ARC_SF_SETTINGS;
1895                 }
1896         }
1897
1898         if (this.enemy)
1899                 SetSpectatee_status(this, etof(this.enemy));
1900
1901         // needed to update spectator list
1902         if(old_spectatee) { ClientData_Touch(old_spectatee); }
1903 }
1904
1905 bool Spectate(entity this, entity pl)
1906 {
1907         if(MUTATOR_CALLHOOK(SpectateSet, this, pl))
1908                 return false;
1909         pl = M_ARGV(1, entity);
1910
1911         SetSpectatee(this, pl);
1912         return SpectateSet(this);
1913 }
1914
1915 bool SpectateNext(entity this)
1916 {
1917         entity ent = find(this.enemy, classname, STR_PLAYER);
1918
1919         if (MUTATOR_CALLHOOK(SpectateNext, this, ent))
1920                 ent = M_ARGV(1, entity);
1921         else if (!ent)
1922                 ent = find(ent, classname, STR_PLAYER);
1923
1924         if(ent) { SetSpectatee(this, ent); }
1925
1926         return SpectateSet(this);
1927 }
1928
1929 bool SpectatePrev(entity this)
1930 {
1931         // NOTE: chain order is from the highest to the lower entnum (unlike find)
1932         entity ent = findchain(classname, STR_PLAYER);
1933         if (!ent) // no player
1934                 return false;
1935
1936         entity first = ent;
1937         // skip players until current spectated player
1938         if(this.enemy)
1939         while(ent && ent != this.enemy)
1940                 ent = ent.chain;
1941
1942         switch (MUTATOR_CALLHOOK(SpectatePrev, this, ent, first))
1943         {
1944                 case MUT_SPECPREV_FOUND:
1945                     ent = M_ARGV(1, entity);
1946                     break;
1947                 case MUT_SPECPREV_RETURN:
1948                     return true;
1949                 case MUT_SPECPREV_CONTINUE:
1950                 default:
1951                 {
1952                         if(ent.chain)
1953                                 ent = ent.chain;
1954                         else
1955                                 ent = first;
1956                         break;
1957                 }
1958         }
1959
1960         SetSpectatee(this, ent);
1961         return SpectateSet(this);
1962 }
1963
1964 /*
1965 =============
1966 ShowRespawnCountdown()
1967
1968 Update a respawn countdown display.
1969 =============
1970 */
1971 void ShowRespawnCountdown(entity this)
1972 {
1973         float number;
1974         if(!IS_DEAD(this)) // just respawned?
1975                 return;
1976         else
1977         {
1978                 number = ceil(this.respawn_time - time);
1979                 if(number <= 0)
1980                         return;
1981                 if(number <= this.respawn_countdown)
1982                 {
1983                         this.respawn_countdown = number - 1;
1984                         if(ceil(this.respawn_time - (time + 0.5)) == number) // only say it if it is the same number even in 0.5s; to prevent overlapping sounds
1985                                 { Send_Notification(NOTIF_ONE, this, MSG_ANNCE, Announcer_PickNumber(CNT_RESPAWN, number)); }
1986                 }
1987         }
1988 }
1989
1990 .bool team_selected;
1991 bool ShowTeamSelection(entity this)
1992 {
1993         if(!teamplay || autocvar_g_campaign || autocvar_g_balance_teams || this.team_selected || (CS(this).wasplayer && autocvar_g_changeteam_banned) || this.team_forced > 0)
1994                 return false;
1995         stuffcmd(this, "menu_showteamselect\n");
1996         return true;
1997 }
1998 void Join(entity this)
1999 {
2000         TRANSMUTE(Player, this);
2001
2002         if(!this.team_selected)
2003         if(autocvar_g_campaign || autocvar_g_balance_teams)
2004                 JoinBestTeam(this, true);
2005
2006         if(autocvar_g_campaign)
2007                 campaign_bots_may_start = true;
2008
2009         Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_PREVENT_JOIN);
2010
2011         PutClientInServer(this);
2012
2013         if(IS_PLAYER(this))
2014         if(teamplay && this.team != -1)
2015                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, APP_TEAM_NUM(this.team, INFO_JOIN_PLAY_TEAM), this.netname);
2016         else
2017                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_JOIN_PLAY, this.netname);
2018         this.team_selected = false;
2019 }
2020
2021 /**
2022  * Determines whether the player is allowed to join. This depends on cvar
2023  * g_maxplayers, if it isn't used this function always return true, otherwise
2024  * it checks whether the number of currently playing players exceeds g_maxplayers.
2025  * @return int number of free slots for players, 0 if none
2026  */
2027 int nJoinAllowed(entity this, entity ignore)
2028 {
2029         if(!ignore)
2030         // this is called that way when checking if anyone may be able to join (to build qcstatus)
2031         // so report 0 free slots if restricted
2032         {
2033                 if(autocvar_g_forced_team_otherwise == "spectate")
2034                         return 0;
2035                 if(autocvar_g_forced_team_otherwise == "spectator")
2036                         return 0;
2037         }
2038
2039         if(this && this.team_forced < 0)
2040                 return 0; // forced spectators can never join
2041
2042         // TODO simplify this
2043         int totalClients = 0;
2044         int currentlyPlaying = 0;
2045         FOREACH_CLIENT(true, {
2046                 if(it != ignore)
2047                         ++totalClients;
2048                 if(IS_REAL_CLIENT(it))
2049                 if(IS_PLAYER(it) || it.caplayer)
2050                         ++currentlyPlaying;
2051         });
2052
2053         float free_slots = 0;
2054         if (!autocvar_g_maxplayers)
2055                 free_slots = maxclients - totalClients;
2056         else if(currentlyPlaying < autocvar_g_maxplayers)
2057                 free_slots = min(maxclients - totalClients, autocvar_g_maxplayers - currentlyPlaying);
2058
2059         static float join_prevent_msg_time = 0;
2060         if(this && ignore && !free_slots && time > join_prevent_msg_time)
2061         {
2062                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_JOIN_PREVENT);
2063                 join_prevent_msg_time = time + 3;
2064         }
2065
2066         return free_slots;
2067 }
2068
2069 /**
2070  * Checks whether the client is an observer or spectator, if so, he will get kicked after
2071  * g_maxplayers_spectator_blocktime seconds
2072  */
2073 void checkSpectatorBlock(entity this)
2074 {
2075         if(IS_SPEC(this) || IS_OBSERVER(this))
2076         if(!this.caplayer)
2077         if(IS_REAL_CLIENT(this))
2078         {
2079                 if( time > (CS(this).spectatortime + autocvar_g_maxplayers_spectator_blocktime) ) {
2080                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_QUIT_KICK_SPECTATING);
2081                         dropclient(this);
2082                 }
2083         }
2084 }
2085
2086 void PrintWelcomeMessage(entity this)
2087 {
2088         if(CS(this).motd_actived_time == 0)
2089         {
2090                 if (autocvar_g_campaign) {
2091                         if ((IS_PLAYER(this) && PHYS_INPUT_BUTTON_INFO(this)) || (!IS_PLAYER(this))) {
2092                                 CS(this).motd_actived_time = time;
2093                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOTD, campaign_message);
2094                         }
2095                 } else {
2096                         if (PHYS_INPUT_BUTTON_INFO(this)) {
2097                                 CS(this).motd_actived_time = time;
2098                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOTD, getwelcomemessage(this));
2099                         }
2100                 }
2101         }
2102         else if(CS(this).motd_actived_time > 0) // showing MOTD or campaign message
2103         {
2104                 if (autocvar_g_campaign) {
2105                         if (PHYS_INPUT_BUTTON_INFO(this))
2106                                 CS(this).motd_actived_time = time;
2107                         else if ((time - CS(this).motd_actived_time > 2) && IS_PLAYER(this)) { // hide it some seconds after BUTTON_INFO has been released
2108                                 CS(this).motd_actived_time = 0;
2109                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_MOTD);
2110                         }
2111                 } else {
2112                         if (PHYS_INPUT_BUTTON_INFO(this))
2113                                 CS(this).motd_actived_time = time;
2114                         else if (time - CS(this).motd_actived_time > 2) { // hide it some seconds after BUTTON_INFO has been released
2115                                 CS(this).motd_actived_time = 0;
2116                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_MOTD);
2117                         }
2118                 }
2119         }
2120         else //if(CS(this).motd_actived_time < 0) // just connected, motd is active
2121         {
2122                 if(PHYS_INPUT_BUTTON_INFO(this)) // BUTTON_INFO hides initial MOTD
2123                         CS(this).motd_actived_time = -2; // wait until BUTTON_INFO gets released
2124                 else if(CS(this).motd_actived_time == -2 || IS_PLAYER(this) || IS_SPEC(this))
2125                 {
2126                         // instanctly hide MOTD
2127                         CS(this).motd_actived_time = 0;
2128                         Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_MOTD);
2129                 }
2130         }
2131 }
2132
2133 bool joinAllowed(entity this)
2134 {
2135         if (CS(this).version_mismatch) return false;
2136         if (!nJoinAllowed(this, this)) return false;
2137         if (teamplay && lockteams) return false;
2138         if (ShowTeamSelection(this)) return false;
2139         if (MUTATOR_CALLHOOK(ForbidSpawn, this)) return false;
2140         return true;
2141 }
2142
2143 .int items_added;
2144 .string shootfromfixedorigin;
2145 bool PlayerThink(entity this)
2146 {
2147         if (game_stopped || intermission_running) {
2148                 this.modelflags &= ~MF_ROCKET;
2149                 if(intermission_running)
2150                         IntermissionThink(this);
2151                 return false;
2152         }
2153
2154         if (timeout_status == TIMEOUT_ACTIVE) {
2155         // don't allow the player to turn around while game is paused
2156                 // FIXME turn this into CSQC stuff
2157                 this.v_angle = this.lastV_angle;
2158                 this.angles = this.lastV_angle;
2159                 this.fixangle = true;
2160         }
2161
2162         if (frametime) player_powerups(this);
2163
2164         if (IS_DEAD(this)) {
2165                 if (this.personal && g_race_qualifying) {
2166                         if (time > this.respawn_time) {
2167                                 STAT(RESPAWN_TIME, this) = this.respawn_time = time + 1; // only retry once a second
2168                                 respawn(this);
2169                                 CS(this).impulse = CHIMPULSE_SPEEDRUN.impulse;
2170                         }
2171                 } else {
2172                         if (frametime) player_anim(this);
2173
2174                         if (this.respawn_flags & RESPAWN_DENY)
2175                         {
2176                                 STAT(RESPAWN_TIME, this) = 0;
2177                                 return false;
2178                         }
2179
2180                         bool button_pressed = (PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_JUMP(this) || PHYS_INPUT_BUTTON_ATCK2(this) || PHYS_INPUT_BUTTON_HOOK(this) || PHYS_INPUT_BUTTON_USE(this));
2181
2182                         switch(this.deadflag)
2183                         {
2184                                 case DEAD_DYING:
2185                                 {
2186                                         if ((this.respawn_flags & RESPAWN_FORCE) && !(this.respawn_time < this.respawn_time_max))
2187                                                 this.deadflag = DEAD_RESPAWNING;
2188                                         else if (!button_pressed || (time >= this.respawn_time_max && (this.respawn_flags & RESPAWN_FORCE)))
2189                                                 this.deadflag = DEAD_DEAD;
2190                                         break;
2191                                 }
2192                                 case DEAD_DEAD:
2193                                 {
2194                                         if (button_pressed)
2195                                                 this.deadflag = DEAD_RESPAWNABLE;
2196                                         else if (time >= this.respawn_time_max && (this.respawn_flags & RESPAWN_FORCE))
2197                                                 this.deadflag = DEAD_RESPAWNING;
2198                                         break;
2199                                 }
2200                                 case DEAD_RESPAWNABLE:
2201                                 {
2202                                         if (!button_pressed || (this.respawn_flags & RESPAWN_FORCE))
2203                                                 this.deadflag = DEAD_RESPAWNING;
2204                                         break;
2205                                 }
2206                                 case DEAD_RESPAWNING:
2207                                 {
2208                                         if (time > this.respawn_time)
2209                                         {
2210                                                 this.respawn_time = time + 1; // only retry once a second
2211                                                 this.respawn_time_max = this.respawn_time;
2212                                                 respawn(this);
2213                                         }
2214                                         break;
2215                                 }
2216                         }
2217
2218                         ShowRespawnCountdown(this);
2219
2220                         if (this.respawn_flags & RESPAWN_SILENT)
2221                                 STAT(RESPAWN_TIME, this) = 0;
2222                         else if ((this.respawn_flags & RESPAWN_FORCE) && this.respawn_time < this.respawn_time_max)
2223                         {
2224                                 if (time < this.respawn_time)
2225                                         STAT(RESPAWN_TIME, this) = this.respawn_time;
2226                                 else if (this.deadflag != DEAD_RESPAWNING)
2227                                         STAT(RESPAWN_TIME, this) = -this.respawn_time_max;
2228                         }
2229                         else
2230                                 STAT(RESPAWN_TIME, this) = this.respawn_time;
2231                 }
2232
2233                 // if respawning, invert stat_respawn_time to indicate this, the client translates it
2234                 if (this.deadflag == DEAD_RESPAWNING && STAT(RESPAWN_TIME, this) > 0)
2235                         STAT(RESPAWN_TIME, this) *= -1;
2236
2237                 return false;
2238         }
2239
2240         FixPlayermodel(this);
2241
2242         if (this.shootfromfixedorigin != autocvar_g_shootfromfixedorigin) {
2243                 this.shootfromfixedorigin = autocvar_g_shootfromfixedorigin;
2244                 stuffcmd(this, sprintf("\ncl_shootfromfixedorigin \"%s\"\n", autocvar_g_shootfromfixedorigin));
2245         }
2246
2247         // LordHavoc: allow firing on move frames (sub-ticrate), this gives better timing on slow servers
2248         //if(frametime)
2249         {
2250                 this.items &= ~this.items_added;
2251
2252                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2253                 {
2254                         .entity weaponentity = weaponentities[slot];
2255                         W_WeaponFrame(this, weaponentity);
2256                 }
2257
2258                 this.items_added = 0;
2259                 if ((this.items & ITEM_Jetpack.m_itemid) && ((this.items & ITEM_JetpackRegen.m_itemid) || this.ammo_fuel >= 0.01))
2260             this.items_added |= IT_FUEL;
2261
2262                 this.items |= this.items_added;
2263         }
2264
2265         player_regen(this);
2266
2267         // WEAPONTODO: Add a weapon request for this
2268         // rot vortex charge to the charge limit
2269         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2270         {
2271                 .entity weaponentity = weaponentities[slot];
2272                 if (WEP_CVAR(vortex, charge_rot_rate) && this.(weaponentity).vortex_charge > WEP_CVAR(vortex, charge_limit) && this.(weaponentity).vortex_charge_rottime < time)
2273                         this.(weaponentity).vortex_charge = bound(WEP_CVAR(vortex, charge_limit), this.(weaponentity).vortex_charge - WEP_CVAR(vortex, charge_rot_rate) * frametime / W_TICSPERFRAME, 1);
2274         }
2275
2276         if (frametime) player_anim(this);
2277
2278         // secret status
2279         secrets_setstatus(this);
2280
2281         // monsters status
2282         monsters_setstatus(this);
2283
2284         this.dmg_team = max(0, this.dmg_team - autocvar_g_teamdamage_resetspeed * frametime);
2285
2286         return true;
2287 }
2288
2289 void ObserverThink(entity this)
2290 {
2291         if ( CS(this).impulse )
2292         {
2293                 MinigameImpulse(this, CS(this).impulse);
2294                 CS(this).impulse = 0;
2295         }
2296
2297         if (this.flags & FL_JUMPRELEASED) {
2298                 if (PHYS_INPUT_BUTTON_JUMP(this) && joinAllowed(this)) {
2299                         this.flags &= ~FL_JUMPRELEASED;
2300                         this.flags |= FL_SPAWNING;
2301                 } else if(PHYS_INPUT_BUTTON_ATCK(this) && !CS(this).version_mismatch) {
2302                         this.flags &= ~FL_JUMPRELEASED;
2303                         if(SpectateNext(this)) {
2304                                 TRANSMUTE(Spectator, this);
2305                         }
2306                 } else {
2307                         int preferred_movetype = ((!PHYS_INPUT_BUTTON_USE(this) ? CS(this).cvar_cl_clippedspectating : !CS(this).cvar_cl_clippedspectating) ? MOVETYPE_FLY_WORLDONLY : MOVETYPE_NOCLIP);
2308                         set_movetype(this, preferred_movetype);
2309                 }
2310         } else {
2311                 if (!(PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_JUMP(this))) {
2312                         this.flags |= FL_JUMPRELEASED;
2313                         if(this.flags & FL_SPAWNING)
2314                         {
2315                                 this.flags &= ~FL_SPAWNING;
2316                                 Join(this);
2317                                 return;
2318                         }
2319                 }
2320         }
2321 }
2322
2323 void SpectatorThink(entity this)
2324 {
2325         if ( CS(this).impulse )
2326         {
2327                 if(MinigameImpulse(this, CS(this).impulse))
2328                         CS(this).impulse = 0;
2329
2330                 if (CS(this).impulse == IMP_weapon_drop.impulse)
2331                 {
2332                         STAT(CAMERA_SPECTATOR, this) = (STAT(CAMERA_SPECTATOR, this) + 1) % 3;
2333                         CS(this).impulse = 0;
2334                         return;
2335                 }
2336         }
2337
2338         if (this.flags & FL_JUMPRELEASED) {
2339                 if (PHYS_INPUT_BUTTON_JUMP(this) && joinAllowed(this)) {
2340                         this.flags &= ~FL_JUMPRELEASED;
2341                         this.flags |= FL_SPAWNING;
2342                 } else if(PHYS_INPUT_BUTTON_ATCK(this) || CS(this).impulse == 10 || CS(this).impulse == 15 || CS(this).impulse == 18 || (CS(this).impulse >= 200 && CS(this).impulse <= 209)) {
2343                         this.flags &= ~FL_JUMPRELEASED;
2344                         if(SpectateNext(this)) {
2345                                 TRANSMUTE(Spectator, this);
2346                         } else {
2347                                 TRANSMUTE(Observer, this);
2348                                 PutClientInServer(this);
2349                         }
2350                         CS(this).impulse = 0;
2351                 } else if(CS(this).impulse == 12 || CS(this).impulse == 16  || CS(this).impulse == 19 || (CS(this).impulse >= 220 && CS(this).impulse <= 229)) {
2352                         this.flags &= ~FL_JUMPRELEASED;
2353                         if(SpectatePrev(this)) {
2354                                 TRANSMUTE(Spectator, this);
2355                         } else {
2356                                 TRANSMUTE(Observer, this);
2357                                 PutClientInServer(this);
2358                         }
2359                         CS(this).impulse = 0;
2360                 } else if (PHYS_INPUT_BUTTON_ATCK2(this)) {
2361                         this.flags &= ~FL_JUMPRELEASED;
2362                         TRANSMUTE(Observer, this);
2363                         PutClientInServer(this);
2364                 } else {
2365                         if(!SpectateUpdate(this))
2366                                 PutObserverInServer(this);
2367                 }
2368         } else {
2369                 if (!(PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_ATCK2(this))) {
2370                         this.flags |= FL_JUMPRELEASED;
2371                         if(this.flags & FL_SPAWNING)
2372                         {
2373                                 this.flags &= ~FL_SPAWNING;
2374                                 Join(this);
2375                                 return;
2376                         }
2377                 }
2378                 if(!SpectateUpdate(this))
2379                         PutObserverInServer(this);
2380         }
2381
2382         this.flags |= FL_CLIENT | FL_NOTARGET;
2383 }
2384
2385 void vehicles_enter (entity pl, entity veh);
2386 void PlayerUseKey(entity this)
2387 {
2388         if (!IS_PLAYER(this))
2389                 return;
2390
2391         if(this.vehicle)
2392         {
2393                 if(!game_stopped)
2394                 {
2395                         vehicles_exit(this.vehicle, VHEF_NORMAL);
2396                         return;
2397                 }
2398         }
2399         else if(autocvar_g_vehicles_enter)
2400         {
2401                 if(!STAT(FROZEN, this))
2402                 if(!IS_DEAD(this))
2403                 if(!game_stopped)
2404                 {
2405                         entity head, closest_target = NULL;
2406                         head = WarpZone_FindRadius(this.origin, autocvar_g_vehicles_enter_radius, true);
2407
2408                         while(head) // find the closest acceptable target to enter
2409                         {
2410                                 if(IS_VEHICLE(head))
2411                                 if(!IS_DEAD(head))
2412                                 if(!head.owner || ((head.vehicle_flags & VHF_MULTISLOT) && SAME_TEAM(head.owner, this)))
2413                                 if(head.takedamage != DAMAGE_NO)
2414                                 {
2415                                         if(closest_target)
2416                                         {
2417                                                 if(vlen2(this.origin - head.origin) < vlen2(this.origin - closest_target.origin))
2418                                                 { closest_target = head; }
2419                                         }
2420                                         else { closest_target = head; }
2421                                 }
2422
2423                                 head = head.chain;
2424                         }
2425
2426                         if(closest_target) { vehicles_enter(this, closest_target); return; }
2427                 }
2428         }
2429
2430         // a use key was pressed; call handlers
2431         MUTATOR_CALLHOOK(PlayerUseKey, this);
2432 }
2433
2434
2435 /*
2436 =============
2437 PlayerPreThink
2438
2439 Called every frame for each client before the physics are run
2440 =============
2441 */
2442 .float last_vehiclecheck;
2443 void PlayerPreThink (entity this)
2444 {
2445         STAT(GUNALIGN, this) = CS(this).cvar_cl_gunalign; // TODO
2446         STAT(MOVEVARS_CL_TRACK_CANJUMP, this) = CS(this).cvar_cl_movement_track_canjump;
2447
2448         WarpZone_PlayerPhysics_FixVAngle(this);
2449
2450         if (frametime) {
2451                 // physics frames: update anticheat stuff
2452                 anticheat_prethink(this);
2453         }
2454
2455         if (blockSpectators && frametime) {
2456                 // WORKAROUND: only use dropclient in server frames (frametime set).
2457                 // Never use it in cl_movement frames (frametime zero).
2458                 checkSpectatorBlock(this);
2459         }
2460
2461         zoomstate_set = false;
2462
2463         // Check for nameless players
2464         if (this.netname == "" || this.netname != CS(this).netname_previous)
2465         {
2466                 bool assume_unchanged = (CS(this).netname_previous == "");
2467                 if (isInvisibleString(this.netname))
2468                 {
2469                         this.netname = strzone(sprintf("Player#%d", this.playerid));
2470                         assume_unchanged = false;
2471                         // stuffcmd(this, strcat("name ", this.netname, "\n")); // maybe?
2472                 }
2473                 if (!assume_unchanged && autocvar_sv_eventlog)
2474                         GameLogEcho(strcat(":name:", ftos(this.playerid), ":", playername(this, false)));
2475                 if (CS(this).netname_previous) strunzone(CS(this).netname_previous);
2476                 CS(this).netname_previous = strzone(this.netname);
2477         }
2478
2479         // version nagging
2480         if (CS(this).version_nagtime && CS(this).cvar_g_xonoticversion && time > CS(this).version_nagtime) {
2481         CS(this).version_nagtime = 0;
2482         if (strstrofs(CS(this).cvar_g_xonoticversion, "git", 0) >= 0 || strstrofs(CS(this).cvar_g_xonoticversion, "autobuild", 0) >= 0) {
2483             // git client
2484         } else if (strstrofs(autocvar_g_xonoticversion, "git", 0) >= 0 || strstrofs(autocvar_g_xonoticversion, "autobuild", 0) >= 0) {
2485             // git server
2486             Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_BETA, autocvar_g_xonoticversion, CS(this).cvar_g_xonoticversion);
2487         } else {
2488             int r = vercmp(CS(this).cvar_g_xonoticversion, autocvar_g_xonoticversion);
2489             if (r < 0) { // old client
2490                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_OUTDATED, autocvar_g_xonoticversion, CS(this).cvar_g_xonoticversion);
2491             } else if (r > 0) { // old server
2492                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_OLD, autocvar_g_xonoticversion, CS(this).cvar_g_xonoticversion);
2493             }
2494         }
2495     }
2496
2497         // GOD MODE info
2498         if (!(this.flags & FL_GODMODE) && this.max_armorvalue)
2499         {
2500                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_GODMODE_OFF, this.max_armorvalue);
2501                 this.max_armorvalue = 0;
2502         }
2503
2504         if(IS_PLAYER(this))
2505         {
2506                 if (STAT(FROZEN, this) == 2)
2507                 {
2508                         STAT(REVIVE_PROGRESS, this) = bound(0, STAT(REVIVE_PROGRESS, this) + frametime * this.revive_speed, 1);
2509                         this.health = max(1, STAT(REVIVE_PROGRESS, this) * start_health);
2510                         this.iceblock.alpha = bound(0.2, 1 - STAT(REVIVE_PROGRESS, this), 1);
2511
2512                         if (STAT(REVIVE_PROGRESS, this) >= 1)
2513                                 Unfreeze(this);
2514                 }
2515                 else if (STAT(FROZEN, this) == 3)
2516                 {
2517                         STAT(REVIVE_PROGRESS, this) = bound(0, STAT(REVIVE_PROGRESS, this) - frametime * this.revive_speed, 1);
2518                         this.health = max(0, autocvar_g_nades_ice_health + (start_health-autocvar_g_nades_ice_health) * STAT(REVIVE_PROGRESS, this) );
2519
2520                         if (this.health < 1)
2521                         {
2522                                 if (this.vehicle)
2523                                         vehicles_exit(this.vehicle, VHEF_RELEASE);
2524                                 if(this.event_damage)
2525                                         this.event_damage(this, this, this.frozen_by, 1, DEATH_NADE_ICE_FREEZE.m_id, DMG_NOWEP, this.origin, '0 0 0');
2526                         }
2527                         else if (STAT(REVIVE_PROGRESS, this) <= 0)
2528                                 Unfreeze(this);
2529                 }
2530         }
2531
2532         MUTATOR_CALLHOOK(PlayerPreThink, this);
2533
2534         if(autocvar_g_vehicles_enter && (time > this.last_vehiclecheck) && !game_stopped && !this.vehicle)
2535         if(IS_PLAYER(this) && !STAT(FROZEN, this) && !IS_DEAD(this))
2536         {
2537                 FOREACH_ENTITY_RADIUS(this.origin, autocvar_g_vehicles_enter_radius, IS_VEHICLE(it),
2538                 {
2539                         if(!IS_DEAD(it) && it.takedamage != DAMAGE_NO)
2540                         if((it.vehicle_flags & VHF_MULTISLOT) && SAME_TEAM(it.owner, this))
2541                         {
2542                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER_GUNNER);
2543                         }
2544                         else if(!it.owner)
2545                         {
2546                                 if(!it.team || SAME_TEAM(this, it))
2547                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER);
2548                                 else if(autocvar_g_vehicles_steal)
2549                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER_STEAL);
2550                         }
2551                 });
2552
2553                 this.last_vehiclecheck = time + 1;
2554         }
2555
2556         if(!CS(this).cvar_cl_newusekeysupported) // FIXME remove this - it was a stupid idea to begin with, we can JUST use the button
2557         {
2558                 if(PHYS_INPUT_BUTTON_USE(this) && !CS(this).usekeypressed)
2559                         PlayerUseKey(this);
2560                 CS(this).usekeypressed = PHYS_INPUT_BUTTON_USE(this);
2561         }
2562
2563         if (IS_REAL_CLIENT(this))
2564                 PrintWelcomeMessage(this);
2565
2566         local const int MIN_SPEC_TIME = 1;
2567         if (IS_PLAYER(this)) {
2568                 if (IS_REAL_CLIENT(this) && time < CS(this).jointime + MIN_SPEC_TIME)
2569                         error("Client can't be spawned as player on connection!");
2570                 if(!PlayerThink(this))
2571                         return;
2572         }
2573         else if (game_stopped || intermission_running) {
2574                 if(intermission_running)
2575                         IntermissionThink(this);
2576                 return;
2577         }
2578         else if (IS_REAL_CLIENT(this) && !CS(this).autojoin_checked && time >= CS(this).jointime + MIN_SPEC_TIME)
2579         {
2580                 CS(this).autojoin_checked = true;
2581                 // don't do this in ClientConnect
2582                 // many things can go wrong if a client is spawned as player on connection
2583                 if (MUTATOR_CALLHOOK(AutoJoinOnConnection, this)
2584                         || (!(autocvar_sv_spectate || autocvar_g_campaign || this.team_forced < 0)
2585                                 && (!teamplay || autocvar_g_balance_teams)))
2586                 {
2587                         campaign_bots_may_start = true;
2588                         Join(this);
2589                         return;
2590                 }
2591         }
2592         else if (IS_OBSERVER(this)) {
2593                 ObserverThink(this);
2594         }
2595         else if (IS_SPEC(this)) {
2596                 SpectatorThink(this);
2597         }
2598
2599         // WEAPONTODO: Add weapon request for this
2600         if (!zoomstate_set) {
2601                 bool wep_zoomed = false;
2602                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2603                 {
2604                         .entity weaponentity = weaponentities[slot];
2605                         Weapon thiswep = this.(weaponentity).m_weapon;
2606                         if(thiswep != WEP_Null && thiswep.wr_zoom)
2607                                 wep_zoomed += thiswep.wr_zoom(thiswep, this);
2608                 }
2609                 SetZoomState(this, PHYS_INPUT_BUTTON_ZOOM(this) || PHYS_INPUT_BUTTON_ZOOMSCRIPT(this) || wep_zoomed);
2610     }
2611
2612         if (CS(this).teamkill_soundtime && time > CS(this).teamkill_soundtime)
2613         {
2614                 CS(this).teamkill_soundtime = 0;
2615
2616                 entity e = CS(this).teamkill_soundsource;
2617                 entity oldpusher = e.pusher;
2618                 e.pusher = this;
2619                 PlayerSound(e, playersound_teamshoot, CH_VOICE, VOL_BASEVOICE, VOICETYPE_LASTATTACKER_ONLY);
2620                 e.pusher = oldpusher;
2621         }
2622
2623         if (CS(this).taunt_soundtime && time > CS(this).taunt_soundtime) {
2624                 CS(this).taunt_soundtime = 0;
2625                 PlayerSound(this, playersound_taunt, CH_VOICE, VOL_BASEVOICE, VOICETYPE_AUTOTAUNT);
2626         }
2627
2628         target_voicescript_next(this);
2629
2630         // WEAPONTODO: Move into weaponsystem somehow
2631         // if a player goes unarmed after holding a loaded weapon, empty his clip size and remove the crosshair ammo ring
2632         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2633         {
2634                 .entity weaponentity = weaponentities[slot];
2635                 if(this.(weaponentity).m_weapon == WEP_Null)
2636                         this.(weaponentity).clip_load = this.(weaponentity).clip_size = 0;
2637         }
2638 }
2639
2640 void DrownPlayer(entity this)
2641 {
2642         if(IS_DEAD(this) || game_stopped || time < game_starttime)
2643                 return;
2644
2645         if (this.waterlevel != WATERLEVEL_SUBMERGED || this.vehicle)
2646         {
2647                 if(this.air_finished < time)
2648                         PlayerSound(this, playersound_gasp, CH_PLAYER, VOL_BASE, VOICETYPE_PLAYERSOUND);
2649                 this.air_finished = time + autocvar_g_balance_contents_drowndelay;
2650         }
2651         else if (this.air_finished < time)
2652         {       // drown!
2653                 if (this.pain_finished < time)
2654                 {
2655                         Damage (this, NULL, NULL, autocvar_g_balance_contents_playerdamage_drowning * autocvar_g_balance_contents_damagerate, DEATH_DROWN.m_id, DMG_NOWEP, this.origin, '0 0 0');
2656                         this.pain_finished = time + 0.5;
2657                 }
2658         }
2659 }
2660
2661 .bool move_qcphysics;
2662
2663 void Player_Physics(entity this)
2664 {
2665         set_movetype(this, this.move_movetype);
2666
2667         if(!this.move_qcphysics)
2668                 return;
2669
2670         if(!frametime && !CS(this).pm_frametime)
2671                 return;
2672
2673         Movetype_Physics_NoMatchTicrate(this, CS(this).pm_frametime, true);
2674
2675         CS(this).pm_frametime = 0;
2676 }
2677
2678 /*
2679 =============
2680 PlayerPostThink
2681
2682 Called every frame for each client after the physics are run
2683 =============
2684 */
2685 void PlayerPostThink (entity this)
2686 {
2687         Player_Physics(this);
2688
2689         if (sv_maxidle > 0)
2690         if (frametime) // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2691         if (IS_REAL_CLIENT(this))
2692         if (IS_PLAYER(this) || sv_maxidle_spectatorsareidle)
2693         {
2694                 int totalClients = 0;
2695                 if(sv_maxidle_slots > 0)
2696                 {
2697                         FOREACH_CLIENT(IS_REAL_CLIENT(it) || sv_maxidle_slots_countbots,
2698                         {
2699                                 ++totalClients;
2700                         });
2701                 }
2702
2703                 if (sv_maxidle_slots > 0 && (maxclients - totalClients) > sv_maxidle_slots)
2704                 { /* do nothing */ }
2705                 else if (time - CS(this).parm_idlesince < 1) // instead of (time == this.parm_idlesince) to support sv_maxidle <= 10
2706                 {
2707                         if (CS(this).idlekick_lasttimeleft)
2708                         {
2709                                 CS(this).idlekick_lasttimeleft = 0;
2710                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_IDLING);
2711                         }
2712                 }
2713                 else
2714                 {
2715                         float timeleft = ceil(sv_maxidle - (time - CS(this).parm_idlesince));
2716                         if (timeleft == min(10, sv_maxidle - 1)) { // - 1 to support sv_maxidle <= 10
2717                                 if (!CS(this).idlekick_lasttimeleft)
2718                                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_DISCONNECT_IDLING, timeleft);
2719                         }
2720                         if (timeleft <= 0) {
2721                                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_QUIT_KICK_IDLING, this.netname);
2722                                 dropclient(this);
2723                                 return;
2724                         }
2725                         else if (timeleft <= 10) {
2726                                 if (timeleft != CS(this).idlekick_lasttimeleft) {
2727                                     Send_Notification(NOTIF_ONE, this, MSG_ANNCE, Announcer_PickNumber(CNT_IDLE, timeleft));
2728                 }
2729                                 CS(this).idlekick_lasttimeleft = timeleft;
2730                         }
2731                 }
2732         }
2733
2734         CheatFrame(this);
2735
2736         if (game_stopped)
2737         {
2738                 this.solid = SOLID_NOT;
2739                 this.takedamage = DAMAGE_NO;
2740                 set_movetype(this, MOVETYPE_NONE);
2741         }
2742
2743         if (IS_PLAYER(this)) {
2744                 if(this.death_time == time && IS_DEAD(this))
2745                 {
2746                         // player's bbox gets resized now, instead of in the damage event that killed the player,
2747                         // once all the damage events of this frame have been processed with normal size
2748                         this.maxs.z = 5;
2749                         setsize(this, this.mins, this.maxs);
2750                 }
2751                 DrownPlayer(this);
2752                 UpdateChatBubble(this);
2753                 if (CS(this).impulse) ImpulseCommands(this);
2754                 if (game_stopped)
2755                 {
2756                         CSQCMODEL_AUTOUPDATE(this);
2757                         return;
2758                 }
2759                 GetPressedKeys(this);
2760         }
2761
2762         if (this.waypointsprite_attachedforcarrier) {
2763             vector v = healtharmor_maxdamage(this.health, this.armorvalue, autocvar_g_balance_armor_blockpercent, DEATH_WEAPON.m_id);
2764                 WaypointSprite_UpdateHealth(this.waypointsprite_attachedforcarrier, '1 0 0' * v);
2765     }
2766
2767         playerdemo_write(this);
2768
2769         CSQCMODEL_AUTOUPDATE(this);
2770 }
2771
2772 // hack to copy the button fields from the client entity to the Client State
2773 void PM_UpdateButtons(entity this, entity store)
2774 {
2775         if(this.impulse)
2776                 store.impulse = this.impulse;
2777         this.impulse = 0;
2778
2779         bool typing = this.buttonchat;
2780
2781         store.button0 = (typing) ? 0 : this.button0;
2782         //button1?!
2783         store.button2 = (typing) ? 0 : this.button2;
2784         store.button3 = (typing) ? 0 : this.button3;
2785         store.button4 = this.button4;
2786         store.button5 = (typing) ? 0 : this.button5;
2787         store.button6 = this.button6;
2788         store.button7 = this.button7;
2789         store.button8 = this.button8;
2790         store.button9 = this.button9;
2791         store.button10 = this.button10;
2792         store.button11 = this.button11;
2793         store.button12 = this.button12;
2794         store.button13 = this.button13;
2795         store.button14 = this.button14;
2796         store.button15 = this.button15;
2797         store.button16 = this.button16;
2798         store.buttonuse = this.buttonuse;
2799         store.buttonchat = this.buttonchat;
2800
2801         store.cursor_active = this.cursor_active;
2802         store.cursor_screen = this.cursor_screen;
2803         store.cursor_trace_start = this.cursor_trace_start;
2804         store.cursor_trace_endpos = this.cursor_trace_endpos;
2805         store.cursor_trace_ent = this.cursor_trace_ent;
2806
2807         store.ping = this.ping;
2808         store.ping_packetloss = this.ping_packetloss;
2809         store.ping_movementloss = this.ping_movementloss;
2810
2811         store.v_angle = this.v_angle;
2812         store.movement = (typing) ? '0 0 0' : this.movement;
2813 }
2814
2815 NET_HANDLE(fpsreport, bool)
2816 {
2817         int fps = ReadShort();
2818         PlayerScore_Set(sender, SP_FPS, fps);
2819         return true;
2820 }