qcsrc/server/client.qc

   1 #include "client.qh"
   2
   3 #include <server/defs.qh>
   4 #include <server/miscfunctions.qh>
   5 #include <common/effects/all.qh>
   6 #include "anticheat.qh"
   7 #include "impulse.qh"
   8 #include "player.qh"
   9 #include "ipban.qh"
  10 #include "miscfunctions.qh"
  11 #include "portals.qh"
  12 #include "teamplay.qh"
  13 #include "spawnpoints.qh"
  14 #include "resources.qh"
  15 #include "g_damage.qh"
  16 #include "handicap.qh"
  17 #include "g_hook.qh"
  18 #include "command/common.qh"
  19 #include "command/vote.qh"
  20 #include "clientkill.qh"
  21 #include "cheats.qh"
  22 #include "g_world.qh"
  23 #include "race.qh"
  24 #include "antilag.qh"
  25 #include "campaign.qh"
  26 #include "command/common.qh"
  27 #include "scores_rules.qh"
  28 #include "weapons/common.qh"
  29
  30 #include "bot/api.qh"
  31
  32 #include "../common/ent_cs.qh"
  33 #include "../common/wepent.qh"
  34 #include <common/state.qh>
  35
  36 #include "compat/quake3.qh"
  37
  38 #include <common/effects/qc/globalsound.qh>
  39
  40 #include "../common/mapobjects/func/conveyor.qh"
  41 #include "../common/mapobjects/teleporters.qh"
  42 #include "../common/mapobjects/target/spawnpoint.qh"
  43 #include <common/mapobjects/trigger/counter.qh>
  44 #include <common/mapobjects/trigger/swamp.qh>
  45
  46 #include "../common/vehicles/all.qh"
  47
  48 #include "weapons/hitplot.qh"
  49 #include "weapons/weaponsystem.qh"
  50
  51 #include "../common/net_notice.qh"
  52 #include "../common/net_linked.qh"
  53 #include "../common/physics/player.qh"
  54
  55 #include <common/vehicles/sv_vehicles.qh>
  56
  57 #include "../common/items/_mod.qh"
  58
  59 #include "../common/mutators/mutator/waypoints/all.qh"
  60 #include "../common/mutators/mutator/instagib/sv_instagib.qh"
  61 #include <common/gamemodes/_mod.qh>
  62
  63 #include "../common/mapobjects/subs.qh"
  64 #include "../common/mapobjects/triggers.qh"
  65 #include "../common/mapobjects/trigger/secret.qh"
  66
  67 #include "../common/minigames/sv_minigames.qh"
  68
  69 #include "../common/items/inventory.qh"
  70
  71 #include "../common/monsters/sv_monsters.qh"
  72
  73 #include "../lib/warpzone/server.qh"
  74
  75 #include <common/mutators/mutator/overkill/oknex.qh>
  76
  77 STATIC_METHOD(Client, Add, void(Client this, int _team))
  78 {
  79     ClientConnect(this);
  80     TRANSMUTE(Player, this);
  81     this.frame = 12; // 7
  82     this.team = _team;
  83     PutClientInServer(this);
  84 }
  85
  86 STATIC_METHOD(Client, Remove, void(Client this))
  87 {
  88     TRANSMUTE(Observer, this);
  89     PutClientInServer(this);
  90     ClientDisconnect(this);
  91 }
  92
  93 void send_CSQC_teamnagger() {
  94         WriteHeader(MSG_BROADCAST, TE_CSQC_TEAMNAGGER);
  95 }
  96
  97 int CountSpectators(entity player, entity to)
  98 {
  99         if(!player) { return 0; } // not sure how, but best to be safe
 100
 101         int spec_count = 0;
 102
 103         FOREACH_CLIENT(IS_REAL_CLIENT(it) && IS_SPEC(it) && it != to && it.enemy == player,
 104         {
 105                 spec_count++;
 106         });
 107
 108         return spec_count;
 109 }
 110
 111 void WriteSpectators(entity player, entity to)
 112 {
 113         if(!player) { return; } // not sure how, but best to be safe
 114
 115         FOREACH_CLIENT(IS_REAL_CLIENT(it) && IS_SPEC(it) && it != to && it.enemy == player,
 116         {
 117                 WriteByte(MSG_ENTITY, num_for_edict(it));
 118         });
 119 }
 120
 121 bool ClientData_Send(entity this, entity to, int sf)
 122 {
 123         assert(to == this.owner, return false);
 124
 125         entity e = to;
 126         if (IS_SPEC(e)) e = e.enemy;
 127
 128         sf = 0;
 129         if (CS(e).race_completed)       sf |= BIT(0); // forced scoreboard
 130         if (CS(to).spectatee_status)    sf |= BIT(1); // spectator ent number follows
 131         if (CS(e).zoomstate)            sf |= BIT(2); // zoomed
 132         if (autocvar_sv_showspectators) sf |= BIT(4); // show spectators
 133
 134         WriteHeader(MSG_ENTITY, ENT_CLIENT_CLIENTDATA);
 135         WriteByte(MSG_ENTITY, sf);
 136
 137         if (sf & BIT(1))
 138                 WriteByte(MSG_ENTITY, CS(to).spectatee_status);
 139
 140         if(sf & BIT(4))
 141         {
 142                 float specs = CountSpectators(e, to);
 143                 WriteByte(MSG_ENTITY, specs);
 144                 WriteSpectators(e, to);
 145         }
 146
 147         return true;
 148 }
 149
 150 void ClientData_Attach(entity this)
 151 {
 152         Net_LinkEntity(CS(this).clientdata = new_pure(clientdata), false, 0, ClientData_Send);
 153         CS(this).clientdata.drawonlytoclient = this;
 154         CS(this).clientdata.owner = this;
 155 }
 156
 157 void ClientData_Detach(entity this)
 158 {
 159         delete(CS(this).clientdata);
 160         CS(this).clientdata = NULL;
 161 }
 162
 163 void ClientData_Touch(entity e)
 164 {
 165         entity cd = CS(e).clientdata;
 166         if (cd) { cd.SendFlags = 1; }
 167
 168         // make it spectatable
 169         FOREACH_CLIENT(IS_REAL_CLIENT(it) && it != e && IS_SPEC(it) && it.enemy == e,
 170         {
 171                 entity cd = CS(it).clientdata;
 172                 if (cd) { cd.SendFlags = 1; }
 173         });
 174 }
 175
 176
 177 /*
 178 =============
 179 CheckPlayerModel
 180
 181 Checks if the argument string can be a valid playermodel.
 182 Returns a valid one in doubt.
 183 =============
 184 */
 185 string FallbackPlayerModel;
 186 string CheckPlayerModel(string plyermodel) {
 187         if(FallbackPlayerModel != cvar_defstring("_cl_playermodel"))
 188         {
 189                 // note: we cannot summon Don Strunzone here, some player may
 190                 // still have the model string set. In case anyone manages how
 191                 // to change a cvar default, we'll have a small leak here.
 192                 FallbackPlayerModel = strzone(cvar_defstring("_cl_playermodel"));
 193         }
 194         // only in right path
 195         if( substring(plyermodel,0,14) != "models/player/")
 196                 return FallbackPlayerModel;
 197         // only good file extensions
 198         if(substring(plyermodel,-4,4) != ".zym")
 199         if(substring(plyermodel,-4,4) != ".dpm")
 200         if(substring(plyermodel,-4,4) != ".iqm")
 201         if(substring(plyermodel,-4,4) != ".md3")
 202         if(substring(plyermodel,-4,4) != ".psk")
 203                 return FallbackPlayerModel;
 204         // forbid the LOD models
 205         if(substring(plyermodel, -9,5) == "_lod1")
 206                 return FallbackPlayerModel;
 207         if(substring(plyermodel, -9,5) == "_lod2")
 208                 return FallbackPlayerModel;
 209         if(plyermodel != strtolower(plyermodel))
 210                 return FallbackPlayerModel;
 211         // also, restrict to server models
 212         if(autocvar_sv_servermodelsonly)
 213         {
 214                 if(!fexists(plyermodel))
 215                         return FallbackPlayerModel;
 216         }
 217         return plyermodel;
 218 }
 219
 220 void setplayermodel(entity e, string modelname)
 221 {
 222         precache_model(modelname);
 223         _setmodel(e, modelname);
 224         player_setupanimsformodel(e);
 225         if(!autocvar_g_debug_globalsounds)
 226                 UpdatePlayerSounds(e);
 227 }
 228
 229 /** putting a client as observer in the server */
 230 void PutObserverInServer(entity this)
 231 {
 232     bool mutator_returnvalue = MUTATOR_CALLHOOK(MakePlayerObserver, this);
 233         PlayerState_detach(this);
 234
 235         if (IS_PLAYER(this))
 236         {
 237                 if(GetResource(this, RES_HEALTH) >= 1)
 238                 {
 239                         // despawn effect
 240                         Send_Effect(EFFECT_SPAWN_NEUTRAL, this.origin, '0 0 0', 1);
 241                 }
 242
 243                 // was a player, recount votes and ready status
 244                 if(IS_REAL_CLIENT(this))
 245                 {
 246                         if (vote_called) { VoteCount(false); }
 247                         ReadyCount();
 248                 }
 249     }
 250
 251     {
 252         entity spot = SelectSpawnPoint(this, true);
 253         if (!spot) LOG_FATAL("No spawnpoints for observers?!?");
 254         this.angles = vec2(spot.angles);
 255         this.fixangle = true;
 256         // offset it so that the spectator spawns higher off the ground, looks better this way
 257         setorigin(this, spot.origin + STAT(PL_VIEW_OFS, this));
 258         if (IS_REAL_CLIENT(this))
 259         {
 260             msg_entity = this;
 261             WriteByte(MSG_ONE, SVC_SETVIEW);
 262             WriteEntity(MSG_ONE, this);
 263         }
 264         // give the spectator some space between walls for MOVETYPE_FLY_WORLDONLY
 265         // so that your view doesn't go into the ceiling with MOVETYPE_FLY_WORLDONLY, previously "PL_VIEW_OFS"
 266         if(!autocvar_g_debug_globalsounds)
 267         {
 268                 // needed for player sounds
 269                 this.model = "";
 270                 FixPlayermodel(this);
 271         }
 272         setmodel(this, MDL_Null);
 273         setsize(this, STAT(PL_CROUCH_MIN, this), STAT(PL_CROUCH_MAX, this));
 274         this.view_ofs = '0 0 0';
 275     }
 276
 277     RemoveGrapplingHooks(this);
 278         Portal_ClearAll(this);
 279         Unfreeze(this, false);
 280         SetSpectatee(this, NULL);
 281
 282         if (this.alivetime)
 283         {
 284                 if (!warmup_stage)
 285                         PlayerStats_GameReport_Event_Player(this, PLAYERSTATS_ALIVETIME, time - this.alivetime);
 286                 this.alivetime = 0;
 287         }
 288
 289         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
 290
 291         WaypointSprite_PlayerDead(this);
 292
 293         if (CS(this).killcount != FRAGS_SPECTATOR)
 294         {
 295                 if(!game_stopped)
 296                 if(autocvar_g_chat_nospectators == 1 || (!warmup_stage && autocvar_g_chat_nospectators == 2))
 297                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_CHAT_NOSPECTATORS);
 298         }
 299
 300         accuracy_resend(this);
 301
 302         CS(this).spectatortime = time;
 303         if(this.bot_attack)
 304                 IL_REMOVE(g_bot_targets, this);
 305         this.bot_attack = false;
 306         if(this.monster_attack)
 307                 IL_REMOVE(g_monster_targets, this);
 308         this.monster_attack = false;
 309     STAT(HUD, this) = HUD_NORMAL;
 310         TRANSMUTE(Observer, this);
 311         this.iscreature = false;
 312         this.teleportable = TELEPORT_SIMPLE;
 313         if(this.damagedbycontents)
 314                 IL_REMOVE(g_damagedbycontents, this);
 315         this.damagedbycontents = false;
 316         SetResourceExplicit(this, RES_HEALTH, FRAGS_SPECTATOR);
 317         SetSpectatee_status(this, etof(this));
 318         this.takedamage = DAMAGE_NO;
 319         this.solid = SOLID_NOT;
 320         set_movetype(this, MOVETYPE_FLY_WORLDONLY); // user preference is controlled by playerprethink
 321         this.flags = FL_CLIENT | FL_NOTARGET;
 322         this.effects = 0;
 323         SetResourceExplicit(this, RES_ARMOR, autocvar_g_balance_armor_start); // was 666?!
 324         this.pauserotarmor_finished = 0;
 325         this.pauserothealth_finished = 0;
 326         this.pauseregen_finished = 0;
 327         this.damageforcescale = 0;
 328         this.death_time = 0;
 329         this.respawn_flags = 0;
 330         this.respawn_time = 0;
 331         STAT(RESPAWN_TIME, this) = 0;
 332         this.alpha = 0;
 333         this.scale = 0;
 334         this.fade_time = 0;
 335         this.pain_frame = 0;
 336         this.pain_finished = 0;
 337         STAT(STRENGTH_FINISHED, this) = 0;
 338         STAT(INVINCIBLE_FINISHED, this) = 0;
 339         STAT(SUPERWEAPONS_FINISHED, this) = 0;
 340         this.air_finished = 0;
 341         //this.dphitcontentsmask = 0;
 342         this.dphitcontentsmask = DPCONTENTS_SOLID;
 343         if (autocvar_g_playerclip_collisions)
 344                 this.dphitcontentsmask |= DPCONTENTS_PLAYERCLIP;
 345         this.pushltime = 0;
 346         this.istypefrag = 0;
 347         setthink(this, func_null);
 348         this.nextthink = 0;
 349         this.deadflag = DEAD_NO;
 350         this.crouch = false;
 351         STAT(REVIVE_PROGRESS, this) = 0;
 352         this.revival_time = 0;
 353         this.draggable = drag_undraggable;
 354
 355         this.items = 0;
 356         STAT(WEAPONS, this) = '0 0 0';
 357         this.drawonlytoclient = this;
 358
 359         this.viewloc = NULL;
 360
 361         //this.spawnpoint_targ = NULL; // keep it so they can return to where they were?
 362
 363         this.weaponmodel = "";
 364         for (int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 365         {
 366                 this.weaponentities[slot] = NULL;
 367         }
 368         this.exteriorweaponentity = NULL;
 369         CS(this).killcount = FRAGS_SPECTATOR;
 370         this.velocity = '0 0 0';
 371         this.avelocity = '0 0 0';
 372         this.punchangle = '0 0 0';
 373         this.punchvector = '0 0 0';
 374         this.oldvelocity = this.velocity;
 375         this.fire_endtime = -1;
 376         this.event_damage = func_null;
 377         this.event_heal = func_null;
 378
 379         for(int slot = 0; slot < MAX_AXH; ++slot)
 380         {
 381                 entity axh = this.(AuxiliaryXhair[slot]);
 382                 this.(AuxiliaryXhair[slot]) = NULL;
 383
 384                 if(axh.owner == this && axh != NULL && !wasfreed(axh))
 385                         delete(axh);
 386         }
 387
 388         if (mutator_returnvalue)
 389         {
 390                 // mutator prevents resetting teams+score
 391         }
 392         else
 393         {
 394                 SetPlayerTeam(this, -1, TEAM_CHANGE_SPECTATOR);
 395                 this.frags = FRAGS_SPECTATOR;
 396         }
 397         if (CS(this).just_joined)
 398                 CS(this).just_joined = false;
 399 }
 400
 401 int player_getspecies(entity this)
 402 {
 403         get_model_parameters(this.model, this.skin);
 404         int s = get_model_parameters_species;
 405         get_model_parameters(string_null, 0);
 406         if (s < 0) return SPECIES_HUMAN;
 407         return s;
 408 }
 409
 410 .float model_randomizer;
 411 void FixPlayermodel(entity player)
 412 {
 413         string defaultmodel = "";
 414         int defaultskin = 0;
 415         if(autocvar_sv_defaultcharacter)
 416         {
 417                 if(teamplay)
 418                 {
 419                         switch(player.team)
 420                         {
 421                                 case NUM_TEAM_1: defaultmodel = autocvar_sv_defaultplayermodel_red; defaultskin = autocvar_sv_defaultplayerskin_red; break;
 422                                 case NUM_TEAM_2: defaultmodel = autocvar_sv_defaultplayermodel_blue; defaultskin = autocvar_sv_defaultplayerskin_blue; break;
 423                                 case NUM_TEAM_3: defaultmodel = autocvar_sv_defaultplayermodel_yellow; defaultskin = autocvar_sv_defaultplayerskin_yellow; break;
 424                                 case NUM_TEAM_4: defaultmodel = autocvar_sv_defaultplayermodel_pink; defaultskin = autocvar_sv_defaultplayerskin_pink; break;
 425                         }
 426                 }
 427
 428                 if(defaultmodel == "")
 429                 {
 430                         defaultmodel = autocvar_sv_defaultplayermodel;
 431                         defaultskin = autocvar_sv_defaultplayerskin;
 432                 }
 433
 434                 int n = tokenize_console(defaultmodel);
 435                 if(n > 0)
 436                 {
 437                         defaultmodel = argv(floor(n * CS(player).model_randomizer));
 438                         // However, do NOT randomize if the player-selected model is in the list.
 439                         for (int i = 0; i < n; ++i)
 440                                 if ((argv(i) == player.playermodel && defaultskin == stof(player.playerskin)) || argv(i) == strcat(player.playermodel, ":", player.playerskin))
 441                                         defaultmodel = argv(i);
 442                 }
 443
 444                 int i = strstrofs(defaultmodel, ":", 0);
 445                 if(i >= 0)
 446                 {
 447                         defaultskin = stof(substring(defaultmodel, i+1, -1));
 448                         defaultmodel = substring(defaultmodel, 0, i);
 449                 }
 450         }
 451         if(autocvar_sv_defaultcharacterskin && !defaultskin)
 452         {
 453                 if(teamplay)
 454                 {
 455                         switch(player.team)
 456                         {
 457                                 case NUM_TEAM_1: defaultskin = autocvar_sv_defaultplayerskin_red; break;
 458                                 case NUM_TEAM_2: defaultskin = autocvar_sv_defaultplayerskin_blue; break;
 459                                 case NUM_TEAM_3: defaultskin = autocvar_sv_defaultplayerskin_yellow; break;
 460                                 case NUM_TEAM_4: defaultskin = autocvar_sv_defaultplayerskin_pink; break;
 461                         }
 462                 }
 463
 464                 if(!defaultskin)
 465                         defaultskin = autocvar_sv_defaultplayerskin;
 466         }
 467
 468         MUTATOR_CALLHOOK(FixPlayermodel, defaultmodel, defaultskin, player);
 469         defaultmodel = M_ARGV(0, string);
 470         defaultskin = M_ARGV(1, int);
 471
 472         bool chmdl = false;
 473         int oldskin;
 474         if(defaultmodel != "")
 475         {
 476                 if (defaultmodel != player.model)
 477                 {
 478                         vector m1 = player.mins;
 479                         vector m2 = player.maxs;
 480                         setplayermodel (player, defaultmodel);
 481                         setsize (player, m1, m2);
 482                         chmdl = true;
 483                 }
 484
 485                 oldskin = player.skin;
 486                 player.skin = defaultskin;
 487         } else {
 488                 if (player.playermodel != player.model || player.playermodel == "")
 489                 {
 490                         player.playermodel = CheckPlayerModel(player.playermodel); // this is never "", so no endless loop
 491                         vector m1 = player.mins;
 492                         vector m2 = player.maxs;
 493                         setplayermodel (player, player.playermodel);
 494                         setsize (player, m1, m2);
 495                         chmdl = true;
 496                 }
 497
 498                 if(!autocvar_sv_defaultcharacterskin)
 499                 {
 500                         oldskin = player.skin;
 501                         player.skin = stof(player.playerskin);
 502                 }
 503                 else
 504                 {
 505                         oldskin = player.skin;
 506                         player.skin = defaultskin;
 507                 }
 508         }
 509
 510         if(chmdl || oldskin != player.skin) // model or skin has changed
 511         {
 512                 player.species = player_getspecies(player); // update species
 513                 if(!autocvar_g_debug_globalsounds)
 514                         UpdatePlayerSounds(player); // update skin sounds
 515         }
 516
 517         if(!teamplay)
 518                 if(strlen(autocvar_sv_defaultplayercolors))
 519                         if(player.clientcolors != stof(autocvar_sv_defaultplayercolors))
 520                                 setcolor(player, stof(autocvar_sv_defaultplayercolors));
 521 }
 522
 523 void PutPlayerInServer(entity this)
 524 {
 525         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
 526
 527         PlayerState_attach(this);
 528         accuracy_resend(this);
 529
 530         if (this.team < 0)
 531                 TeamBalance_JoinBestTeam(this);
 532
 533         entity spot = SelectSpawnPoint(this, false);
 534         if (!spot) {
 535                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_JOIN_NOSPAWNS);
 536                 return; // spawn failed
 537         }
 538
 539         TRANSMUTE(Player, this);
 540
 541         CS(this).wasplayer = true;
 542         this.iscreature = true;
 543         this.teleportable = TELEPORT_NORMAL;
 544         if(!this.damagedbycontents)
 545                 IL_PUSH(g_damagedbycontents, this);
 546         this.damagedbycontents = true;
 547         set_movetype(this, MOVETYPE_WALK);
 548         this.solid = SOLID_SLIDEBOX;
 549         this.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_SOLID;
 550         if (autocvar_g_playerclip_collisions)
 551                 this.dphitcontentsmask |= DPCONTENTS_PLAYERCLIP;
 552         if (IS_BOT_CLIENT(this) && autocvar_g_botclip_collisions)
 553                 this.dphitcontentsmask |= DPCONTENTS_BOTCLIP;
 554         this.frags = FRAGS_PLAYER;
 555         if (INDEPENDENT_PLAYERS) MAKE_INDEPENDENT_PLAYER(this);
 556         this.flags = FL_CLIENT | FL_PICKUPITEMS;
 557         if (autocvar__notarget)
 558                 this.flags |= FL_NOTARGET;
 559         this.takedamage = DAMAGE_AIM;
 560         this.effects = EF_TELEPORT_BIT | EF_RESTARTANIM_BIT;
 561
 562         if (warmup_stage) {
 563                 SetResource(this, RES_SHELLS, warmup_start_ammo_shells);
 564                 SetResource(this, RES_BULLETS, warmup_start_ammo_nails);
 565                 SetResource(this, RES_ROCKETS, warmup_start_ammo_rockets);
 566                 SetResource(this, RES_CELLS, warmup_start_ammo_cells);
 567                 SetResource(this, RES_PLASMA, warmup_start_ammo_plasma);
 568                 SetResource(this, RES_FUEL, warmup_start_ammo_fuel);
 569                 SetResource(this, RES_HEALTH, warmup_start_health);
 570                 SetResource(this, RES_ARMOR, warmup_start_armorvalue);
 571                 STAT(WEAPONS, this) = WARMUP_START_WEAPONS;
 572         } else {
 573                 SetResource(this, RES_SHELLS, start_ammo_shells);
 574                 SetResource(this, RES_BULLETS, start_ammo_nails);
 575                 SetResource(this, RES_ROCKETS, start_ammo_rockets);
 576                 SetResource(this, RES_CELLS, start_ammo_cells);
 577                 SetResource(this, RES_PLASMA, start_ammo_plasma);
 578                 SetResource(this, RES_FUEL, start_ammo_fuel);
 579                 SetResource(this, RES_HEALTH, start_health);
 580                 SetResource(this, RES_ARMOR, start_armorvalue);
 581                 STAT(WEAPONS, this) = start_weapons;
 582                 if (MUTATOR_CALLHOOK(ForbidRandomStartWeapons, this) == false)
 583                 {
 584                         GiveRandomWeapons(this, random_start_weapons_count,
 585                                 autocvar_g_random_start_weapons, random_start_ammo);
 586                 }
 587         }
 588         SetSpectatee_status(this, 0);
 589
 590         PS(this).dual_weapons = '0 0 0';
 591
 592         STAT(SUPERWEAPONS_FINISHED, this) = (STAT(WEAPONS, this) & WEPSET_SUPERWEAPONS) ? time + autocvar_g_balance_superweapons_time : 0;
 593
 594         this.items = start_items;
 595
 596         this.spawnshieldtime = time + autocvar_g_spawnshieldtime;
 597         this.pauserotarmor_finished = time + autocvar_g_balance_pause_armor_rot_spawn;
 598         this.pauserothealth_finished = time + autocvar_g_balance_pause_health_rot_spawn;
 599         this.pauserotfuel_finished = time + autocvar_g_balance_pause_fuel_rot_spawn;
 600         this.pauseregen_finished = time + autocvar_g_balance_pause_health_regen_spawn;
 601         if (!sv_ready_restart_after_countdown && time < game_starttime)
 602         {
 603                 float f = game_starttime - time;
 604                 this.spawnshieldtime += f;
 605                 this.pauserotarmor_finished += f;
 606                 this.pauserothealth_finished += f;
 607                 this.pauseregen_finished += f;
 608         }
 609
 610         this.damageforcescale = autocvar_g_player_damageforcescale;
 611         this.death_time = 0;
 612         this.respawn_flags = 0;
 613         this.respawn_time = 0;
 614         STAT(RESPAWN_TIME, this) = 0;
 615         bool q3dfcompat = autocvar_sv_q3defragcompat && autocvar_sv_q3defragcompat_changehitbox;
 616         this.scale = ((q3dfcompat) ? 0.9 : autocvar_sv_player_scale);
 617         this.fade_time = 0;
 618         this.pain_frame = 0;
 619         this.pain_finished = 0;
 620         this.pushltime = 0;
 621         setthink(this, func_null); // players have no think function
 622         this.nextthink = 0;
 623         this.dmg_team = 0;
 624         PS(this).ballistics_density = autocvar_g_ballistics_density_player;
 625
 626         this.deadflag = DEAD_NO;
 627
 628         this.angles = spot.angles;
 629         this.angles_z = 0; // never spawn tilted even if the spot says to
 630         if (IS_BOT_CLIENT(this))
 631         {
 632                 this.v_angle = this.angles;
 633                 bot_aim_reset(this);
 634         }
 635         this.fixangle = true; // turn this way immediately
 636         this.oldvelocity = this.velocity = '0 0 0';
 637         this.avelocity = '0 0 0';
 638         this.punchangle = '0 0 0';
 639         this.punchvector = '0 0 0';
 640
 641         STAT(STRENGTH_FINISHED, this) = 0;
 642         STAT(INVINCIBLE_FINISHED, this) = 0;
 643         this.fire_endtime = -1;
 644         STAT(REVIVE_PROGRESS, this) = 0;
 645         this.revival_time = 0;
 646
 647         // TODO: we can't set these in the PlayerSpawn hook since the target code is called before it!
 648         STAT(BUFFS, this) = 0;
 649         STAT(BUFF_TIME, this) = 0;
 650
 651         this.air_finished = 0;
 652         this.waterlevel = WATERLEVEL_NONE;
 653         this.watertype = CONTENT_EMPTY;
 654
 655         entity spawnevent = new_pure(spawnevent);
 656         spawnevent.owner = this;
 657         Net_LinkEntity(spawnevent, false, 0.5, SpawnEvent_Send);
 658
 659         // Cut off any still running player sounds.
 660         stopsound(this, CH_PLAYER_SINGLE);
 661
 662         this.model = "";
 663         FixPlayermodel(this);
 664         this.drawonlytoclient = NULL;
 665
 666         this.viewloc = NULL;
 667
 668         for(int slot = 0; slot < MAX_AXH; ++slot)
 669         {
 670                 entity axh = this.(AuxiliaryXhair[slot]);
 671                 this.(AuxiliaryXhair[slot]) = NULL;
 672
 673                 if(axh.owner == this && axh != NULL && !wasfreed(axh))
 674                         delete(axh);
 675         }
 676
 677         this.spawnpoint_targ = NULL;
 678
 679         this.crouch = false;
 680         this.view_ofs = STAT(PL_VIEW_OFS, this);
 681         setsize(this, STAT(PL_MIN, this), STAT(PL_MAX, this));
 682         this.spawnorigin = spot.origin;
 683         setorigin(this, spot.origin + '0 0 1' * (1 - this.mins.z - 24));
 684         // don't reset back to last position, even if new position is stuck in solid
 685         this.oldorigin = this.origin;
 686         if(this.conveyor)
 687                 IL_REMOVE(g_conveyed, this);
 688         this.conveyor = NULL; // prevent conveyors at the previous location from moving a freshly spawned player
 689         if(this.swampslug)
 690                 IL_REMOVE(g_swamped, this);
 691         this.swampslug = NULL;
 692         this.swamp_interval = 0;
 693         IL_EACH(g_counters, it.realowner == this,
 694         {
 695                 delete(it);
 696         });
 697         STAT(HUD, this) = HUD_NORMAL;
 698
 699         this.event_damage = PlayerDamage;
 700         this.event_heal = PlayerHeal;
 701
 702         this.draggable = func_null;
 703
 704         if(!this.bot_attack)
 705                 IL_PUSH(g_bot_targets, this);
 706         this.bot_attack = true;
 707         if(!this.monster_attack)
 708                 IL_PUSH(g_monster_targets, this);
 709         this.monster_attack = true;
 710         navigation_dynamicgoal_init(this, false);
 711
 712         PHYS_INPUT_BUTTON_ATCK(this) = PHYS_INPUT_BUTTON_JUMP(this) = PHYS_INPUT_BUTTON_ATCK2(this) = false;
 713
 714         // player was spectator
 715         if (CS(this).killcount == FRAGS_SPECTATOR) {
 716                 PlayerScore_Clear(this);
 717                 CS(this).killcount = 0;
 718                 CS(this).startplaytime = time;
 719         }
 720
 721         for (int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 722         {
 723                 .entity weaponentity = weaponentities[slot];
 724                 CL_SpawnWeaponentity(this, weaponentity);
 725         }
 726         this.alpha = default_player_alpha;
 727         this.colormod = '1 1 1' * autocvar_g_player_brightness;
 728         this.exteriorweaponentity.alpha = default_weapon_alpha;
 729
 730         this.speedrunning = false;
 731
 732         this.counter_cnt = 0;
 733         this.fragsfilter_cnt = 0;
 734
 735         target_voicescript_clear(this);
 736
 737         // reset fields the weapons may use
 738         FOREACH(Weapons, true, {
 739                 it.wr_resetplayer(it, this);
 740                         // reload all reloadable weapons
 741                 if (it.spawnflags & WEP_FLAG_RELOADABLE) {
 742                         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 743                         {
 744                                 .entity weaponentity = weaponentities[slot];
 745                                 this.(weaponentity).weapon_load[it.m_id] = it.reloading_ammo;
 746                         }
 747                 }
 748         });
 749
 750         {
 751                 string s = spot.target;
 752                 if(g_assault || g_race) // TODO: make targeting work in assault & race without this hack
 753                         spot.target = string_null;
 754                 SUB_UseTargets(spot, this, NULL);
 755                 if(g_assault || g_race)
 756                         spot.target = s;
 757         }
 758
 759         Unfreeze(this, false);
 760
 761         MUTATOR_CALLHOOK(PlayerSpawn, this, spot);
 762
 763         if (autocvar_spawn_debug)
 764         {
 765                 sprint(this, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
 766                 delete(spot); // usefull for checking if there are spawnpoints, that let drop through the floor
 767         }
 768
 769         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 770         {
 771                 .entity weaponentity = weaponentities[slot];
 772                 if(slot == 0 || autocvar_g_weaponswitch_debug == 1)
 773                         this.(weaponentity).m_switchweapon = w_getbestweapon(this, weaponentity);
 774                 else
 775                         this.(weaponentity).m_switchweapon = WEP_Null;
 776                 this.(weaponentity).m_weapon = WEP_Null;
 777                 this.(weaponentity).weaponname = "";
 778                 this.(weaponentity).m_switchingweapon = WEP_Null;
 779                 this.(weaponentity).cnt = -1;
 780         }
 781
 782         MUTATOR_CALLHOOK(PlayerWeaponSelect, this);
 783
 784         if (CS(this).impulse) ImpulseCommands(this);
 785
 786         W_ResetGunAlign(this, CS(this).cvar_cl_gunalign);
 787         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 788         {
 789                 .entity weaponentity = weaponentities[slot];
 790                 W_WeaponFrame(this, weaponentity);
 791         }
 792
 793         if (!warmup_stage && !this.alivetime)
 794                 this.alivetime = time;
 795
 796         antilag_clear(this, CS(this));
 797 }
 798
 799 /** Called when a client spawns in the server */
 800 void PutClientInServer(entity this)
 801 {
 802         if (IS_BOT_CLIENT(this)) {
 803                 TRANSMUTE(Player, this);
 804         } else if (IS_REAL_CLIENT(this)) {
 805                 msg_entity = this;
 806                 WriteByte(MSG_ONE, SVC_SETVIEW);
 807                 WriteEntity(MSG_ONE, this);
 808         }
 809         if (game_stopped)
 810                 TRANSMUTE(Observer, this);
 811
 812         SetSpectatee(this, NULL);
 813
 814         // reset player keys
 815         if(PS(this))
 816                 PS(this).itemkeys = 0;
 817
 818         MUTATOR_CALLHOOK(PutClientInServer, this);
 819
 820         if (IS_OBSERVER(this)) {
 821                 PutObserverInServer(this);
 822         } else if (IS_PLAYER(this)) {
 823                 PutPlayerInServer(this);
 824         }
 825 }
 826
 827 // TODO do we need all these fields, or should we stop autodetecting runtime
 828 // changes and just have a console command to update this?
 829 bool ClientInit_SendEntity(entity this, entity to, int sf)
 830 {
 831         WriteHeader(MSG_ENTITY, _ENT_CLIENT_INIT);
 832         return = true;
 833         msg_entity = to;
 834         // MSG_INIT replacement
 835         // TODO: make easier to use
 836         Registry_send_all();
 837         W_PROP_reload(MSG_ONE, to);
 838         ClientInit_misc(this);
 839         MUTATOR_CALLHOOK(Ent_Init);
 840 }
 841 void ClientInit_misc(entity this)
 842 {
 843         int channel = MSG_ONE;
 844         WriteHeader(channel, ENT_CLIENT_INIT);
 845         WriteByte(channel, g_nexball_meter_period * 32);
 846         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[0]));
 847         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[1]));
 848         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[2]));
 849         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[3]));
 850         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[0]));
 851         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[1]));
 852         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[2]));
 853         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[3]));
 854
 855         if(sv_foginterval && world.fog != "")
 856                 WriteString(channel, world.fog);
 857         else
 858                 WriteString(channel, "");
 859         WriteByte(channel, this.count * 255.0); // g_balance_armor_blockpercent
 860         WriteByte(channel, this.cnt * 255.0); // g_balance_damagepush_speedfactor
 861         WriteByte(channel, serverflags);
 862         WriteCoord(channel, autocvar_g_trueaim_minrange);
 863 }
 864
 865 void ClientInit_CheckUpdate(entity this)
 866 {
 867         this.nextthink = time;
 868         if(this.count != autocvar_g_balance_armor_blockpercent)
 869         {
 870                 this.count = autocvar_g_balance_armor_blockpercent;
 871                 this.SendFlags |= 1;
 872         }
 873         if(this.cnt != autocvar_g_balance_damagepush_speedfactor)
 874         {
 875                 this.cnt = autocvar_g_balance_damagepush_speedfactor;
 876                 this.SendFlags |= 1;
 877         }
 878 }
 879
 880 void ClientInit_Spawn()
 881 {
 882         entity e = new_pure(clientinit);
 883         setthink(e, ClientInit_CheckUpdate);
 884         Net_LinkEntity(e, false, 0, ClientInit_SendEntity);
 885
 886         ClientInit_CheckUpdate(e);
 887 }
 888
 889 /*
 890 =============
 891 SetNewParms
 892 =============
 893 */
 894 void SetNewParms ()
 895 {
 896         // initialize parms for a new player
 897         parm1 = -(86400 * 366);
 898
 899         MUTATOR_CALLHOOK(SetNewParms);
 900 }
 901
 902 /*
 903 =============
 904 SetChangeParms
 905 =============
 906 */
 907 void SetChangeParms (entity this)
 908 {
 909         // save parms for level change
 910         parm1 = CS(this).parm_idlesince - time;
 911
 912         MUTATOR_CALLHOOK(SetChangeParms);
 913 }
 914
 915 /*
 916 =============
 917 DecodeLevelParms
 918 =============
 919 */
 920 void DecodeLevelParms(entity this)
 921 {
 922         // load parms
 923         CS(this).parm_idlesince = parm1;
 924         if (CS(this).parm_idlesince == -(86400 * 366))
 925                 CS(this).parm_idlesince = time;
 926
 927         // whatever happens, allow 60 seconds of idling directly after connect for map loading
 928         CS(this).parm_idlesince = max(CS(this).parm_idlesince, time - sv_maxidle + 60);
 929
 930         MUTATOR_CALLHOOK(DecodeLevelParms);
 931 }
 932
 933 void FixClientCvars(entity e)
 934 {
 935         // send prediction settings to the client
 936         stuffcmd(e, "\nin_bindmap 0 0\n");
 937         if(autocvar_g_antilag == 3) // client side hitscan
 938                 stuffcmd(e, "cl_cmd settemp cl_prydoncursor_notrace 0\n");
 939         if(autocvar_sv_gentle)
 940                 stuffcmd(e, "cl_cmd settemp cl_gentle 1\n");
 941
 942         stuffcmd(e, sprintf("\ncl_jumpspeedcap_min \"%s\"\n", autocvar_sv_jumpspeedcap_min));
 943         stuffcmd(e, sprintf("\ncl_jumpspeedcap_max \"%s\"\n", autocvar_sv_jumpspeedcap_max));
 944
 945         stuffcmd(e, sprintf("\ncl_shootfromfixedorigin \"%s\"\n", autocvar_g_shootfromfixedorigin));
 946
 947         MUTATOR_CALLHOOK(FixClientCvars, e);
 948 }
 949
 950 bool findinlist_abbrev(string tofind, string list)
 951 {
 952         if(list == "" || tofind == "")
 953                 return false; // empty list or search, just return
 954
 955         // this function allows abbreviated strings!
 956         FOREACH_WORD(list, it == substring(tofind, 0, strlen(it)),
 957         {
 958                 return true;
 959         });
 960
 961         return false;
 962 }
 963
 964 bool PlayerInIPList(entity p, string iplist)
 965 {
 966         // some safety checks (never allow local?)
 967         if(p.netaddress == "local" || p.netaddress == "" || !IS_REAL_CLIENT(p))
 968                 return false;
 969
 970         return findinlist_abbrev(p.netaddress, iplist);
 971 }
 972
 973 bool PlayerInIDList(entity p, string idlist)
 974 {
 975         // NOTE: we do NOT check crypto_idfp_signed here, an unsigned ID is fine too for this
 976         if(!p.crypto_idfp)
 977                 return false;
 978
 979         return findinlist_abbrev(p.crypto_idfp, idlist);
 980 }
 981
 982 bool PlayerInList(entity player, string list)
 983 {
 984         return boolean(PlayerInIDList(player, list) || PlayerInIPList(player, list));
 985 }
 986
 987 #ifdef DP_EXT_PRECONNECT
 988 /*
 989 =============
 990 ClientPreConnect
 991
 992 Called once (not at each match start) when a client begins a connection to the server
 993 =============
 994 */
 995 void ClientPreConnect(entity this)
 996 {
 997         if(autocvar_sv_eventlog)
 998         {
 999                 GameLogEcho(sprintf(":connect:%d:%d:%s",
1000                         this.playerid,
1001                         etof(this),
1002                         ((IS_REAL_CLIENT(this)) ? this.netaddress : "bot")
1003                 ));
1004         }
1005 }
1006 #endif
1007
1008 string GetClientVersionMessage(entity this)
1009 {
1010         if (CS(this).version_mismatch) {
1011                 if(CS(this).version < autocvar_gameversion) {
1012                         return strcat("This is Xonotic ", autocvar_g_xonoticversion,
1013                                 "\n^3Your client version is outdated.\n\n\n### YOU WON'T BE ABLE TO PLAY ON THIS SERVER ###\n\n\nPlease update!!!^8");
1014                 } else {
1015                         return strcat("This is Xonotic ", autocvar_g_xonoticversion,
1016                                 "\n^3This server is using an outdated Xonotic version.\n\n\n ### THIS SERVER IS INCOMPATIBLE AND THUS YOU CANNOT JOIN ###.^8");
1017                 }
1018         } else {
1019                 return strcat("Welcome to Xonotic ", autocvar_g_xonoticversion);
1020         }
1021 }
1022
1023 string getwelcomemessage(entity this)
1024 {
1025         MUTATOR_CALLHOOK(BuildMutatorsPrettyString, "");
1026         string modifications = M_ARGV(0, string);
1027
1028         if(g_weaponarena)
1029         {
1030                 if(g_weaponarena_random)
1031                         modifications = strcat(modifications, ", ", ftos(g_weaponarena_random), " of ", g_weaponarena_list, " Arena");
1032                 else
1033                         modifications = strcat(modifications, ", ", g_weaponarena_list, " Arena");
1034         }
1035         else if(cvar("g_balance_blaster_weaponstartoverride") == 0)
1036                 modifications = strcat(modifications, ", No start weapons");
1037         if(cvar("sv_gravity") < stof(cvar_defstring("sv_gravity")))
1038                 modifications = strcat(modifications, ", Low gravity");
1039         if(g_weapon_stay && !g_cts)
1040                 modifications = strcat(modifications, ", Weapons stay");
1041         if(g_jetpack)
1042                 modifications = strcat(modifications, ", Jet pack");
1043         if(autocvar_g_powerups == 0)
1044                 modifications = strcat(modifications, ", No powerups");
1045         if(autocvar_g_powerups > 0)
1046                 modifications = strcat(modifications, ", Powerups");
1047         modifications = substring(modifications, 2, strlen(modifications) - 2);
1048
1049         string versionmessage = GetClientVersionMessage(this);
1050         string s = strcat(versionmessage, "^8\n^8\nhost is ^9", autocvar_hostname, "^8\n");
1051
1052         s = strcat(s, "^8\nmatch type is ^1", gamemode_name, "^8\n");
1053
1054         if(modifications != "")
1055                 s = strcat(s, "^8\nactive modifications: ^3", modifications, "^8\n");
1056
1057         if(cache_lastmutatormsg != autocvar_g_mutatormsg)
1058         {
1059                 strcpy(cache_lastmutatormsg, autocvar_g_mutatormsg);
1060                 strcpy(cache_mutatormsg, cache_lastmutatormsg);
1061         }
1062
1063         if (cache_mutatormsg != "") {
1064                 s = strcat(s, "\n\n^8special gameplay tips: ^7", cache_mutatormsg);
1065         }
1066
1067         string mutator_msg = "";
1068         MUTATOR_CALLHOOK(BuildGameplayTipsString, mutator_msg);
1069         mutator_msg = M_ARGV(0, string);
1070
1071         s = strcat(s, mutator_msg); // trust that the mutator will do proper formatting
1072
1073         string motd = autocvar_sv_motd;
1074         if (motd != "") {
1075                 s = strcat(s, "\n\n^8MOTD: ^7", strreplace("\\n", "\n", motd));
1076         }
1077         return s;
1078 }
1079
1080 bool autocvar_sv_qcphysics = true; // TODO this is for testing - remove when qcphysics work
1081
1082 /**
1083 =============
1084 ClientConnect
1085
1086 Called when a client connects to the server
1087 =============
1088 */
1089 void ClientConnect(entity this)
1090 {
1091         if (Ban_MaybeEnforceBanOnce(this)) return;
1092         assert(!IS_CLIENT(this), return);
1093         this.flags |= FL_CLIENT;
1094         assert(player_count >= 0, player_count = 0);
1095
1096 #ifdef WATERMARK
1097         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_WATERMARK, WATERMARK);
1098 #endif
1099         TRANSMUTE(Client, this);
1100         CS(this).version_nagtime = time + 10 + random() * 10;
1101
1102         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_JOIN_CONNECT, this.netname);
1103
1104         bot_clientconnect(this);
1105
1106         Player_DetermineForcedTeam(this);
1107
1108         TRANSMUTE(Observer, this);
1109
1110         PlayerStats_GameReport_AddEvent(sprintf("kills-%d", this.playerid));
1111
1112         // always track bots, don't ask for cl_allow_uidtracking
1113         if (IS_BOT_CLIENT(this))
1114                 PlayerStats_GameReport_AddPlayer(this);
1115         else
1116                 CS(this).allowed_timeouts = autocvar_sv_timeout_number;
1117
1118         if (autocvar_sv_eventlog)
1119                 GameLogEcho(strcat(":join:", ftos(this.playerid), ":", ftos(etof(this)), ":", ((IS_REAL_CLIENT(this)) ? GameLog_ProcessIP(this.netaddress) : "bot"), ":", playername(this, false)));
1120
1121         CS(this).just_joined = true;  // stop spamming the eventlog with additional lines when the client connects
1122
1123         stuffcmd(this, clientstuff, "\n");
1124         stuffcmd(this, "cl_particles_reloadeffects\n"); // TODO do we still need this?
1125
1126         FixClientCvars(this);
1127
1128         // get version info from player
1129         stuffcmd(this, "cmd clientversion $gameversion\n");
1130
1131         // notify about available teams
1132         if (teamplay)
1133         {
1134                 entity balance = TeamBalance_CheckAllowedTeams(this);
1135                 int t = TeamBalance_GetAllowedTeams(balance);
1136                 TeamBalance_Destroy(balance);
1137                 stuffcmd(this, sprintf("set _teams_available %d\n", t));
1138         }
1139         else
1140         {
1141                 stuffcmd(this, "set _teams_available 0\n");
1142         }
1143
1144         bot_relinkplayerlist();
1145
1146         CS(this).spectatortime = time;
1147         if (blockSpectators)
1148         {
1149                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
1150         }
1151
1152         CS(this).jointime = time;
1153
1154         if (IS_REAL_CLIENT(this))
1155         {
1156                 if (g_weaponarena_weapons == WEPSET(TUBA))
1157                         stuffcmd(this, "cl_cmd settemp chase_active 1\n");
1158         }
1159
1160         if (!sv_foginterval && world.fog != "")
1161                 stuffcmd(this, strcat("\nfog ", world.fog, "\nr_fog_exp2 0\nr_drawfog 1\n"));
1162
1163         if (autocvar_sv_teamnagger && !(autocvar_bot_vs_human && AvailableTeams() == 2))
1164                 if(!MUTATOR_CALLHOOK(HideTeamNagger, this))
1165                         send_CSQC_teamnagger();
1166
1167         CSQCMODEL_AUTOINIT(this);
1168
1169         CS(this).model_randomizer = random();
1170
1171         if (IS_REAL_CLIENT(this))
1172                 sv_notice_join(this);
1173
1174         this.move_qcphysics = autocvar_sv_qcphysics;
1175
1176         // update physics stats (players can spawn before physics runs)
1177         Physics_UpdateStats(this);
1178
1179         IL_EACH(g_initforplayer, it.init_for_player, {
1180                 it.init_for_player(it, this);
1181         });
1182
1183         Handicap_Initialize(this);
1184
1185         MUTATOR_CALLHOOK(ClientConnect, this);
1186
1187         if (IS_REAL_CLIENT(this))
1188         {
1189                 if (!autocvar_g_campaign && !IS_PLAYER(this))
1190                 {
1191                         CS(this).motd_actived_time = -1;
1192                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOTD, getwelcomemessage(this));
1193                 }
1194         }
1195 }
1196 /*
1197 =============
1198 ClientDisconnect
1199
1200 Called when a client disconnects from the server
1201 =============
1202 */
1203 .entity chatbubbleentity;
1204 void ClientDisconnect(entity this)
1205 {
1206         assert(IS_CLIENT(this), return);
1207
1208         PlayerStats_GameReport_FinalizePlayer(this);
1209         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
1210         if (CS(this).active_minigame) part_minigame(this);
1211         if (IS_PLAYER(this)) Send_Effect(EFFECT_SPAWN_NEUTRAL, this.origin, '0 0 0', 1);
1212
1213         if (autocvar_sv_eventlog)
1214                 GameLogEcho(strcat(":part:", ftos(this.playerid)));
1215
1216         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_QUIT_DISCONNECT, this.netname);
1217
1218         if(IS_SPEC(this))
1219                 SetSpectatee(this, NULL);
1220
1221     MUTATOR_CALLHOOK(ClientDisconnect, this);
1222
1223         strfree(CS(this).netname_previous); // needs to be before the CS entity is removed!
1224         strfree(CS(this).weaponorder_byimpulse);
1225         ClientState_detach(this);
1226
1227         Portal_ClearAll(this);
1228
1229         Unfreeze(this, false);
1230
1231         RemoveGrapplingHooks(this);
1232
1233         // Here, everything has been done that requires this player to be a client.
1234
1235         this.flags &= ~FL_CLIENT;
1236
1237         if (this.chatbubbleentity) delete(this.chatbubbleentity);
1238         if (this.killindicator) delete(this.killindicator);
1239
1240         IL_EACH(g_counters, it.realowner == this,
1241         {
1242                 delete(it);
1243         });
1244
1245         WaypointSprite_PlayerGone(this);
1246
1247         bot_relinkplayerlist();
1248
1249         strfree(this.clientstatus);
1250         if (this.personal) delete(this.personal);
1251
1252         this.playerid = 0;
1253         ReadyCount();
1254         if (vote_called && IS_REAL_CLIENT(this)) VoteCount(false);
1255
1256         ONREMOVE(this);
1257 }
1258
1259 void ChatBubbleThink(entity this)
1260 {
1261         this.nextthink = time;
1262         if ((this.owner.alpha < 0) || this.owner.chatbubbleentity != this)
1263         {
1264                 if(this.owner) // but why can that ever be NULL?
1265                         this.owner.chatbubbleentity = NULL;
1266                 delete(this);
1267                 return;
1268         }
1269
1270         this.mdl = "";
1271
1272         if ( !IS_DEAD(this.owner) && IS_PLAYER(this.owner) )
1273         {
1274                 if ( CS(this.owner).active_minigame && PHYS_INPUT_BUTTON_MINIGAME(this.owner) )
1275                         this.mdl = "models/sprites/minigame_busy.iqm";
1276                 else if (PHYS_INPUT_BUTTON_CHAT(this.owner))
1277                         this.mdl = "models/misc/chatbubble.spr";
1278         }
1279
1280         if ( this.model != this.mdl )
1281                 _setmodel(this, this.mdl);
1282
1283 }
1284
1285 void UpdateChatBubble(entity this)
1286 {
1287         if (this.alpha < 0)
1288                 return;
1289         // spawn a chatbubble entity if needed
1290         if (!this.chatbubbleentity)
1291         {
1292                 this.chatbubbleentity = new(chatbubbleentity);
1293                 this.chatbubbleentity.owner = this;
1294                 this.chatbubbleentity.exteriormodeltoclient = this;
1295                 setthink(this.chatbubbleentity, ChatBubbleThink);
1296                 this.chatbubbleentity.nextthink = time;
1297                 setmodel(this.chatbubbleentity, MDL_CHAT); // precision set below
1298                 //setorigin(this.chatbubbleentity, this.origin + '0 0 15' + this.maxs_z * '0 0 1');
1299                 setorigin(this.chatbubbleentity, '0 0 15' + this.maxs_z * '0 0 1');
1300                 setattachment(this.chatbubbleentity, this, "");  // sticks to moving player better, also conserves bandwidth
1301                 this.chatbubbleentity.mdl = this.chatbubbleentity.model;
1302                 //this.chatbubbleentity.model = "";
1303                 this.chatbubbleentity.effects = EF_LOWPRECISION;
1304         }
1305 }
1306
1307
1308 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
1309 // added to the model skins
1310 /*void UpdateColorModHack()
1311 {
1312         float c;
1313         c = this.clientcolors & 15;
1314         // LordHavoc: only bothering to support white, green, red, yellow, blue
1315              if (!teamplay) this.colormod = '0 0 0';
1316         else if (c ==  0) this.colormod = '1.00 1.00 1.00';
1317         else if (c ==  3) this.colormod = '0.10 1.73 0.10';
1318         else if (c ==  4) this.colormod = '1.73 0.10 0.10';
1319         else if (c == 12) this.colormod = '1.22 1.22 0.10';
1320         else if (c == 13) this.colormod = '0.10 0.10 1.73';
1321         else this.colormod = '1 1 1';
1322 }*/
1323
1324 void respawn(entity this)
1325 {
1326         if(this.alpha >= 0 && autocvar_g_respawn_ghosts)
1327         {
1328                 this.solid = SOLID_NOT;
1329                 this.takedamage = DAMAGE_NO;
1330                 set_movetype(this, MOVETYPE_FLY);
1331                 this.velocity = '0 0 1' * autocvar_g_respawn_ghosts_speed;
1332                 this.avelocity = randomvec() * autocvar_g_respawn_ghosts_speed * 3 - randomvec() * autocvar_g_respawn_ghosts_speed * 3;
1333                 this.effects |= CSQCMODEL_EF_RESPAWNGHOST;
1334                 Send_Effect(EFFECT_RESPAWN_GHOST, this.origin, '0 0 0', 1);
1335                 if(autocvar_g_respawn_ghosts_maxtime)
1336                         SUB_SetFade (this, time + autocvar_g_respawn_ghosts_maxtime / 2 + random () * (autocvar_g_respawn_ghosts_maxtime - autocvar_g_respawn_ghosts_maxtime / 2), 1.5);
1337         }
1338
1339         CopyBody(this, 1);
1340
1341         this.effects |= EF_NODRAW; // prevent another CopyBody
1342         PutClientInServer(this);
1343 }
1344
1345 ERASEABLE
1346 void PrintToChat(entity client, string text)
1347 {
1348         text = strcat("\{1}^7", text, "\n");
1349         sprint(client, text);
1350 }
1351
1352 ERASEABLE
1353 void DebugPrintToChat(entity client, string text)
1354 {
1355         if (autocvar_developer > 0)
1356         {
1357                 PrintToChat(client, text);
1358         }
1359 }
1360
1361 ERASEABLE
1362 void PrintToChatAll(string text)
1363 {
1364         text = strcat("\{1}^7", text, "\n");
1365         bprint(text);
1366 }
1367
1368 ERASEABLE
1369 void DebugPrintToChatAll(string text)
1370 {
1371         if (autocvar_developer > 0)
1372         {
1373                 PrintToChatAll(text);
1374         }
1375 }
1376
1377 ERASEABLE
1378 void PrintToChatTeam(int team_num, string text)
1379 {
1380         text = strcat("\{1}^7", text, "\n");
1381         FOREACH_CLIENT(IS_REAL_CLIENT(it),
1382         {
1383                 if (it.team == team_num)
1384                 {
1385                         sprint(it, text);
1386                 }
1387         });
1388 }
1389
1390 ERASEABLE
1391 void DebugPrintToChatTeam(int team_num, string text)
1392 {
1393         if (autocvar_developer > 0)
1394         {
1395                 PrintToChatTeam(team_num, text);
1396         }
1397 }
1398
1399 void play_countdown(entity this, float finished, Sound samp)
1400 {
1401         TC(Sound, samp);
1402         if(IS_REAL_CLIENT(this))
1403                 if(floor(finished - time - frametime) != floor(finished - time))
1404                         if(finished - time < 6)
1405                                 sound (this, CH_INFO, samp, VOL_BASE, ATTEN_NORM);
1406 }
1407
1408 void player_powerups(entity this)
1409 {
1410         // add a way to see what the items were BEFORE all of these checks for the mutator hook
1411         int items_prev = this.items;
1412
1413         if((this.items & IT_USING_JETPACK) && !IS_DEAD(this) && !game_stopped)
1414                 this.modelflags |= MF_ROCKET;
1415         else
1416                 this.modelflags &= ~MF_ROCKET;
1417
1418         this.effects &= ~(EF_RED | EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT | EF_FLAME | EF_NODEPTHTEST);
1419
1420         if((this.alpha < 0 || IS_DEAD(this)) && !this.vehicle) // don't apply the flags if the player is gibbed
1421                 return;
1422
1423         Fire_ApplyDamage(this);
1424         Fire_ApplyEffect(this);
1425
1426         if (!MUTATOR_IS_ENABLED(mutator_instagib))
1427         {
1428                 if (this.items & ITEM_Strength.m_itemid)
1429                 {
1430                         play_countdown(this, STAT(STRENGTH_FINISHED, this), SND_POWEROFF);
1431                         this.effects = this.effects | (EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT);
1432                         if (time > STAT(STRENGTH_FINISHED, this))
1433                         {
1434                                 this.items = this.items - (this.items & ITEM_Strength.m_itemid);
1435                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERDOWN_STRENGTH, this.netname);
1436                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERDOWN_STRENGTH);
1437                         }
1438                 }
1439                 else
1440                 {
1441                         if (time < STAT(STRENGTH_FINISHED, this))
1442                         {
1443                                 this.items = this.items | ITEM_Strength.m_itemid;
1444                                 if(!g_cts)
1445                                         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERUP_STRENGTH, this.netname);
1446                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERUP_STRENGTH);
1447                         }
1448                 }
1449                 if (this.items & ITEM_Shield.m_itemid)
1450                 {
1451                         play_countdown(this, STAT(INVINCIBLE_FINISHED, this), SND_POWEROFF);
1452                         this.effects = this.effects | (EF_RED | EF_ADDITIVE | EF_FULLBRIGHT);
1453                         if (time > STAT(INVINCIBLE_FINISHED, this))
1454                         {
1455                                 this.items = this.items - (this.items & ITEM_Shield.m_itemid);
1456                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERDOWN_SHIELD, this.netname);
1457                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERDOWN_SHIELD);
1458                         }
1459                 }
1460                 else
1461                 {
1462                         if (time < STAT(INVINCIBLE_FINISHED, this))
1463                         {
1464                                 this.items = this.items | ITEM_Shield.m_itemid;
1465                                 if(!g_cts)
1466                                         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERUP_SHIELD, this.netname);
1467                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERUP_SHIELD);
1468                         }
1469                 }
1470                 if (this.items & IT_SUPERWEAPON)
1471                 {
1472                         if (!(STAT(WEAPONS, this) & WEPSET_SUPERWEAPONS))
1473                         {
1474                                 STAT(SUPERWEAPONS_FINISHED, this) = 0;
1475                                 this.items = this.items - (this.items & IT_SUPERWEAPON);
1476                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_LOST, this.netname);
1477                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_LOST);
1478                         }
1479                         else if (this.items & IT_UNLIMITED_SUPERWEAPONS)
1480                         {
1481                                 // don't let them run out
1482                         }
1483                         else
1484                         {
1485                                 play_countdown(this, STAT(SUPERWEAPONS_FINISHED, this), SND_POWEROFF);
1486                                 if (time > STAT(SUPERWEAPONS_FINISHED, this))
1487                                 {
1488                                         this.items = this.items - (this.items & IT_SUPERWEAPON);
1489                                         STAT(WEAPONS, this) &= ~WEPSET_SUPERWEAPONS;
1490                                         //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_BROKEN, this.netname);
1491                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_BROKEN);
1492                                 }
1493                         }
1494                 }
1495                 else if(STAT(WEAPONS, this) & WEPSET_SUPERWEAPONS)
1496                 {
1497                         if (time < STAT(SUPERWEAPONS_FINISHED, this) || (this.items & IT_UNLIMITED_SUPERWEAPONS))
1498                         {
1499                                 this.items = this.items | IT_SUPERWEAPON;
1500                                 if(!(this.items & IT_UNLIMITED_SUPERWEAPONS))
1501                                 {
1502                                         if(!g_cts)
1503                                                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_PICKUP, this.netname);
1504                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_PICKUP);
1505                                 }
1506                         }
1507                         else
1508                         {
1509                                 STAT(SUPERWEAPONS_FINISHED, this) = 0;
1510                                 STAT(WEAPONS, this) &= ~WEPSET_SUPERWEAPONS;
1511                         }
1512                 }
1513                 else
1514                 {
1515                         STAT(SUPERWEAPONS_FINISHED, this) = 0;
1516                 }
1517         }
1518
1519         if(autocvar_g_nodepthtestplayers)
1520                 this.effects = this.effects | EF_NODEPTHTEST;
1521
1522         if(autocvar_g_fullbrightplayers)
1523                 this.effects = this.effects | EF_FULLBRIGHT;
1524
1525         if (time >= game_starttime)
1526         if (time < this.spawnshieldtime)
1527                 this.effects = this.effects | (EF_ADDITIVE | EF_FULLBRIGHT);
1528
1529         MUTATOR_CALLHOOK(PlayerPowerups, this, items_prev);
1530 }
1531
1532 float CalcRegen(float current, float stable, float regenfactor, float regenframetime)
1533 {
1534         if(current > stable)
1535                 return current;
1536         else if(current > stable - 0.25) // when close enough, "snap"
1537                 return stable;
1538         else
1539                 return min(stable, current + (stable - current) * regenfactor * regenframetime);
1540 }
1541
1542 float CalcRot(float current, float stable, float rotfactor, float rotframetime)
1543 {
1544         if(current < stable)
1545                 return current;
1546         else if(current < stable + 0.25) // when close enough, "snap"
1547                 return stable;
1548         else
1549                 return max(stable, current + (stable - current) * rotfactor * rotframetime);
1550 }
1551
1552 void RotRegen(entity this, int res, float regenstable, float regenfactor, float regenlinear, float regenframetime, float rotstable, float rotfactor, float rotlinear, float rotframetime, float limit_mod)
1553 {
1554         float old = GetResource(this, res);
1555         float current = old;
1556         if(current > rotstable)
1557         {
1558                 if(rotframetime > 0)
1559                 {
1560                         current = CalcRot(current, rotstable, rotfactor, rotframetime);
1561                         current = max(rotstable, current - rotlinear * rotframetime);
1562                 }
1563         }
1564         else if(current < regenstable)
1565         {
1566                 if(regenframetime > 0)
1567                 {
1568                         current = CalcRegen(current, regenstable, regenfactor, regenframetime);
1569                         current = min(regenstable, current + regenlinear * regenframetime);
1570                 }
1571         }
1572
1573         float limit = GetResourceLimit(this, res) * limit_mod;
1574         if(current > limit)
1575                 current = limit;
1576
1577         if (current != old)
1578                 SetResource(this, res, current);
1579 }
1580
1581 void player_regen(entity this)
1582 {
1583         float max_mod, regen_mod, rot_mod, limit_mod;
1584         max_mod = regen_mod = rot_mod = limit_mod = 1;
1585
1586         float regen_health = autocvar_g_balance_health_regen;
1587         float regen_health_linear = autocvar_g_balance_health_regenlinear;
1588         float regen_health_rot = autocvar_g_balance_health_rot;
1589         float regen_health_rotlinear = autocvar_g_balance_health_rotlinear;
1590         float regen_health_stable = autocvar_g_balance_health_regenstable;
1591         float regen_health_rotstable = autocvar_g_balance_health_rotstable;
1592         bool mutator_returnvalue = MUTATOR_CALLHOOK(PlayerRegen, this, max_mod, regen_mod, rot_mod, limit_mod, regen_health, regen_health_linear, regen_health_rot,
1593                 regen_health_rotlinear, regen_health_stable, regen_health_rotstable);
1594         max_mod = M_ARGV(1, float);
1595         regen_mod = M_ARGV(2, float);
1596         rot_mod = M_ARGV(3, float);
1597         limit_mod = M_ARGV(4, float);
1598         regen_health = M_ARGV(5, float);
1599         regen_health_linear = M_ARGV(6, float);
1600         regen_health_rot = M_ARGV(7, float);
1601         regen_health_rotlinear = M_ARGV(8, float);
1602         regen_health_stable = M_ARGV(9, float);
1603         regen_health_rotstable = M_ARGV(10, float);
1604
1605         if(!mutator_returnvalue)
1606         if(!STAT(FROZEN, this))
1607         {
1608                 float maxa = autocvar_g_balance_armor_rotstable;
1609                 float mina = autocvar_g_balance_armor_regenstable;
1610
1611                 RotRegen(this, RES_ARMOR, mina, autocvar_g_balance_armor_regen, autocvar_g_balance_armor_regenlinear,
1612                         regen_mod * frametime * (time > this.pauseregen_finished), maxa, autocvar_g_balance_armor_rot, autocvar_g_balance_armor_rotlinear,
1613                         rot_mod * frametime * (time > this.pauserotarmor_finished), limit_mod);
1614
1615                 RotRegen(this, RES_HEALTH, regen_health_stable * max_mod, regen_health, regen_health_linear,
1616                         regen_mod * frametime * (time > this.pauseregen_finished), regen_health_rotstable * max_mod, regen_health_rot, regen_health_rotlinear,
1617                         rot_mod * frametime * (time > this.pauserothealth_finished), limit_mod);
1618         }
1619
1620         // if player rotted to death...  die!
1621         // check this outside above checks, as player may still be able to rot to death
1622         if(GetResource(this, RES_HEALTH) < 1)
1623         {
1624                 if(this.vehicle)
1625                         vehicles_exit(this.vehicle, VHEF_RELEASE);
1626                 if(this.event_damage)
1627                         this.event_damage(this, this, this, 1, DEATH_ROT.m_id, DMG_NOWEP, this.origin, '0 0 0');
1628         }
1629
1630         if (!(this.items & IT_UNLIMITED_AMMO))
1631         {
1632                 float maxf = autocvar_g_balance_fuel_rotstable;
1633                 float minf = autocvar_g_balance_fuel_regenstable;
1634
1635                 RotRegen(this, RES_FUEL, minf, autocvar_g_balance_fuel_regen, autocvar_g_balance_fuel_regenlinear,
1636                         frametime * (time > this.pauseregen_finished) * ((this.items & ITEM_JetpackRegen.m_itemid) != 0),
1637                         maxf, autocvar_g_balance_fuel_rot, autocvar_g_balance_fuel_rotlinear, frametime * (time > this.pauserotfuel_finished), 1);
1638         }
1639 }
1640
1641 bool zoomstate_set;
1642 void SetZoomState(entity this, float newzoom)
1643 {
1644         if(newzoom != CS(this).zoomstate)
1645         {
1646                 CS(this).zoomstate = newzoom;
1647                 ClientData_Touch(this);
1648         }
1649         zoomstate_set = true;
1650 }
1651
1652 void GetPressedKeys(entity this)
1653 {
1654         MUTATOR_CALLHOOK(GetPressedKeys, this);
1655         int keys = STAT(PRESSED_KEYS, this);
1656         keys = BITSET(keys, KEY_FORWARD,        CS(this).movement.x > 0);
1657         keys = BITSET(keys, KEY_BACKWARD,       CS(this).movement.x < 0);
1658         keys = BITSET(keys, KEY_RIGHT,          CS(this).movement.y > 0);
1659         keys = BITSET(keys, KEY_LEFT,           CS(this).movement.y < 0);
1660
1661         keys = BITSET(keys, KEY_JUMP,           PHYS_INPUT_BUTTON_JUMP(this));
1662         keys = BITSET(keys, KEY_CROUCH,         IS_DUCKED(this)); // workaround: player can't un-crouch until their path is clear, so we keep the button held here
1663         keys = BITSET(keys, KEY_ATCK,           PHYS_INPUT_BUTTON_ATCK(this));
1664         keys = BITSET(keys, KEY_ATCK2,          PHYS_INPUT_BUTTON_ATCK2(this));
1665         CS(this).pressedkeys = keys; // store for other users
1666
1667         STAT(PRESSED_KEYS, this) = keys;
1668 }
1669
1670 /*
1671 ======================
1672 spectate mode routines
1673 ======================
1674 */
1675
1676 void SpectateCopy(entity this, entity spectatee)
1677 {
1678         TC(Client, this); TC(Client, spectatee);
1679
1680         MUTATOR_CALLHOOK(SpectateCopy, spectatee, this);
1681         PS(this) = PS(spectatee);
1682         this.armortype = spectatee.armortype;
1683         SetResourceExplicit(this, RES_ARMOR, GetResource(spectatee, RES_ARMOR));
1684         SetResourceExplicit(this, RES_CELLS, GetResource(spectatee, RES_CELLS));
1685         SetResourceExplicit(this, RES_PLASMA, GetResource(spectatee, RES_PLASMA));
1686         SetResourceExplicit(this, RES_SHELLS, GetResource(spectatee, RES_SHELLS));
1687         SetResourceExplicit(this, RES_BULLETS, GetResource(spectatee, RES_BULLETS));
1688         SetResourceExplicit(this, RES_ROCKETS, GetResource(spectatee, RES_ROCKETS));
1689         SetResourceExplicit(this, RES_FUEL, GetResource(spectatee, RES_FUEL));
1690         this.effects = spectatee.effects & EFMASK_CHEAP; // eat performance
1691         SetResourceExplicit(this, RES_HEALTH, GetResource(spectatee, RES_HEALTH));
1692         CS(this).impulse = 0;
1693         this.disableclientprediction = 1; // no need to run prediction on a spectator
1694         this.items = spectatee.items;
1695         STAT(LAST_PICKUP, this) = STAT(LAST_PICKUP, spectatee);
1696         STAT(HIT_TIME, this) = STAT(HIT_TIME, spectatee);
1697         STAT(STRENGTH_FINISHED, this) = STAT(STRENGTH_FINISHED, spectatee);
1698         STAT(INVINCIBLE_FINISHED, this) = STAT(INVINCIBLE_FINISHED, spectatee);
1699         STAT(SUPERWEAPONS_FINISHED, this) = STAT(SUPERWEAPONS_FINISHED, spectatee);
1700         this.air_finished = spectatee.air_finished;
1701         STAT(PRESSED_KEYS, this) = STAT(PRESSED_KEYS, spectatee);
1702         STAT(WEAPONS, this) = STAT(WEAPONS, spectatee);
1703         this.punchangle = spectatee.punchangle;
1704         this.view_ofs = spectatee.view_ofs;
1705         this.velocity = spectatee.velocity;
1706         this.dmg_take = spectatee.dmg_take;
1707         this.dmg_save = spectatee.dmg_save;
1708         this.dmg_inflictor = spectatee.dmg_inflictor;
1709         this.v_angle = spectatee.v_angle;
1710         this.angles = spectatee.v_angle;
1711         STAT(FROZEN, this) = STAT(FROZEN, spectatee);
1712         STAT(REVIVE_PROGRESS, this) = STAT(REVIVE_PROGRESS, spectatee);
1713         this.viewloc = spectatee.viewloc;
1714         if(!PHYS_INPUT_BUTTON_USE(this) && STAT(CAMERA_SPECTATOR, this) != 2)
1715                 this.fixangle = true;
1716         setorigin(this, spectatee.origin);
1717         setsize(this, spectatee.mins, spectatee.maxs);
1718         SetZoomState(this, CS(spectatee).zoomstate);
1719
1720     anticheat_spectatecopy(this, spectatee);
1721         STAT(HUD, this) = STAT(HUD, spectatee);
1722         if(spectatee.vehicle)
1723     {
1724         this.angles = spectatee.v_angle;
1725
1726         //this.fixangle = false;
1727         //this.velocity = spectatee.vehicle.velocity;
1728         this.vehicle_health = spectatee.vehicle_health;
1729         this.vehicle_shield = spectatee.vehicle_shield;
1730         this.vehicle_energy = spectatee.vehicle_energy;
1731         this.vehicle_ammo1 = spectatee.vehicle_ammo1;
1732         this.vehicle_ammo2 = spectatee.vehicle_ammo2;
1733         this.vehicle_reload1 = spectatee.vehicle_reload1;
1734         this.vehicle_reload2 = spectatee.vehicle_reload2;
1735
1736         //msg_entity = this;
1737
1738        // WriteByte (MSG_ONE, SVC_SETVIEWANGLES);
1739             //WriteAngle(MSG_ONE,  spectatee.v_angle.x);
1740            // WriteAngle(MSG_ONE,  spectatee.v_angle.y);
1741            // WriteAngle(MSG_ONE,  spectatee.v_angle.z);
1742
1743         //WriteByte (MSG_ONE, SVC_SETVIEW);
1744         //    WriteEntity(MSG_ONE, this);
1745         //makevectors(spectatee.v_angle);
1746         //setorigin(this, spectatee.origin - v_forward * 400 + v_up * 300);*/
1747     }
1748 }
1749
1750 bool SpectateUpdate(entity this)
1751 {
1752         if(!this.enemy)
1753                 return false;
1754
1755         if(!IS_PLAYER(this.enemy) || this == this.enemy)
1756         {
1757                 SetSpectatee(this, NULL);
1758                 return false;
1759         }
1760
1761         SpectateCopy(this, this.enemy);
1762
1763         return true;
1764 }
1765
1766 bool SpectateSet(entity this)
1767 {
1768         if(!IS_PLAYER(this.enemy))
1769                 return false;
1770
1771         ClientData_Touch(this.enemy);
1772
1773         msg_entity = this;
1774         WriteByte(MSG_ONE, SVC_SETVIEW);
1775         WriteEntity(MSG_ONE, this.enemy);
1776         set_movetype(this, MOVETYPE_NONE);
1777         accuracy_resend(this);
1778
1779         if(!SpectateUpdate(this))
1780                 PutObserverInServer(this);
1781
1782         return true;
1783 }
1784
1785 void SetSpectatee_status(entity this, int spectatee_num)
1786 {
1787         int oldspectatee_status = CS(this).spectatee_status;
1788         CS(this).spectatee_status = spectatee_num;
1789
1790         if (CS(this).spectatee_status != oldspectatee_status)
1791         {
1792                 if (STAT(PRESSED_KEYS, this))
1793                 {
1794                         CS(this).pressedkeys = 0;
1795                         STAT(PRESSED_KEYS, this) = 0;
1796                 }
1797                 ClientData_Touch(this);
1798                 if (g_race || g_cts) race_InitSpectator();
1799         }
1800 }
1801
1802 void SetSpectatee(entity this, entity spectatee)
1803 {
1804         if(IS_BOT_CLIENT(this))
1805                 return; // bots abuse .enemy, this code is useless to them
1806
1807         entity old_spectatee = this.enemy;
1808
1809         this.enemy = spectatee;
1810
1811         // WEAPONTODO
1812         // these are required to fix the spectator bug with arc
1813         if(old_spectatee)
1814         {
1815                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1816                 {
1817                         .entity weaponentity = weaponentities[slot];
1818                         if(old_spectatee.(weaponentity).arc_beam)
1819                                 old_spectatee.(weaponentity).arc_beam.SendFlags |= ARC_SF_SETTINGS;
1820                 }
1821         }
1822         if(this.enemy)
1823         {
1824                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1825                 {
1826                         .entity weaponentity = weaponentities[slot];
1827                         if(this.enemy.(weaponentity).arc_beam)
1828                                 this.enemy.(weaponentity).arc_beam.SendFlags |= ARC_SF_SETTINGS;
1829                 }
1830         }
1831
1832         if (this.enemy)
1833                 SetSpectatee_status(this, etof(this.enemy));
1834
1835         // needed to update spectator list
1836         if(old_spectatee) { ClientData_Touch(old_spectatee); }
1837 }
1838
1839 bool Spectate(entity this, entity pl)
1840 {
1841         if(MUTATOR_CALLHOOK(SpectateSet, this, pl))
1842                 return false;
1843         pl = M_ARGV(1, entity);
1844
1845         SetSpectatee(this, pl);
1846         return SpectateSet(this);
1847 }
1848
1849 bool SpectateNext(entity this)
1850 {
1851         entity ent = find(this.enemy, classname, STR_PLAYER);
1852
1853         if (MUTATOR_CALLHOOK(SpectateNext, this, ent))
1854                 ent = M_ARGV(1, entity);
1855         else if (!ent)
1856                 ent = find(ent, classname, STR_PLAYER);
1857
1858         if(ent) { SetSpectatee(this, ent); }
1859
1860         return SpectateSet(this);
1861 }
1862
1863 bool SpectatePrev(entity this)
1864 {
1865         // NOTE: chain order is from the highest to the lower entnum (unlike find)
1866         entity ent = findchain(classname, STR_PLAYER);
1867         if (!ent) // no player
1868                 return false;
1869
1870         entity first = ent;
1871         // skip players until current spectated player
1872         if(this.enemy)
1873         while(ent && ent != this.enemy)
1874                 ent = ent.chain;
1875
1876         switch (MUTATOR_CALLHOOK(SpectatePrev, this, ent, first))
1877         {
1878                 case MUT_SPECPREV_FOUND:
1879                     ent = M_ARGV(1, entity);
1880                     break;
1881                 case MUT_SPECPREV_RETURN:
1882                     return true;
1883                 case MUT_SPECPREV_CONTINUE:
1884                 default:
1885                 {
1886                         if(ent.chain)
1887                                 ent = ent.chain;
1888                         else
1889                                 ent = first;
1890                         break;
1891                 }
1892         }
1893
1894         SetSpectatee(this, ent);
1895         return SpectateSet(this);
1896 }
1897
1898 /*
1899 =============
1900 ShowRespawnCountdown()
1901
1902 Update a respawn countdown display.
1903 =============
1904 */
1905 void ShowRespawnCountdown(entity this)
1906 {
1907         float number;
1908         if(!IS_DEAD(this)) // just respawned?
1909                 return;
1910         else
1911         {
1912                 number = ceil(this.respawn_time - time);
1913                 if(number <= 0)
1914                         return;
1915                 if(number <= this.respawn_countdown)
1916                 {
1917                         this.respawn_countdown = number - 1;
1918                         if(ceil(this.respawn_time - (time + 0.5)) == number) // only say it if it is the same number even in 0.5s; to prevent overlapping sounds
1919                                 { Send_Notification(NOTIF_ONE, this, MSG_ANNCE, Announcer_PickNumber(CNT_RESPAWN, number)); }
1920                 }
1921         }
1922 }
1923
1924 .bool team_selected;
1925 bool ShowTeamSelection(entity this)
1926 {
1927         if (!teamplay || autocvar_g_campaign || autocvar_g_balance_teams || this.team_selected || (CS(this).wasplayer && autocvar_g_changeteam_banned) || Player_HasRealForcedTeam(this))
1928                 return false;
1929         stuffcmd(this, "menu_showteamselect\n");
1930         return true;
1931 }
1932 void Join(entity this)
1933 {
1934         TRANSMUTE(Player, this);
1935
1936         if(!this.team_selected)
1937         if(autocvar_g_campaign || autocvar_g_balance_teams)
1938                 TeamBalance_JoinBestTeam(this);
1939
1940         if(autocvar_g_campaign)
1941                 campaign_bots_may_start = true;
1942
1943         Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_PREVENT_JOIN);
1944
1945         PutClientInServer(this);
1946
1947         if(IS_PLAYER(this))
1948         if(teamplay && this.team != -1)
1949         {
1950         }
1951         else
1952                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_JOIN_PLAY, this.netname);
1953         this.team_selected = false;
1954 }
1955
1956 int GetPlayerLimit()
1957 {
1958         if(g_duel)
1959                 return 2; // TODO: this workaround is needed since the mutator hook from duel can't be activated before the gametype is loaded (e.g. switching modes via gametype vote screen)
1960         int player_limit = autocvar_g_maxplayers;
1961         MUTATOR_CALLHOOK(GetPlayerLimit, player_limit);
1962         player_limit = M_ARGV(0, int);
1963         return player_limit;
1964 }
1965
1966 /**
1967  * Determines whether the player is allowed to join. This depends on cvar
1968  * g_maxplayers, if it isn't used this function always return true, otherwise
1969  * it checks whether the number of currently playing players exceeds g_maxplayers.
1970  * @return int number of free slots for players, 0 if none
1971  */
1972 int nJoinAllowed(entity this, entity ignore)
1973 {
1974         if(!ignore)
1975         // this is called that way when checking if anyone may be able to join (to build qcstatus)
1976         // so report 0 free slots if restricted
1977         {
1978                 if(autocvar_g_forced_team_otherwise == "spectate")
1979                         return 0;
1980                 if(autocvar_g_forced_team_otherwise == "spectator")
1981                         return 0;
1982         }
1983
1984         if(this && (Player_GetForcedTeamIndex(this) == TEAM_FORCE_SPECTATOR))
1985                 return 0; // forced spectators can never join
1986
1987         // TODO simplify this
1988         int totalClients = 0;
1989         int currentlyPlaying = 0;
1990         FOREACH_CLIENT(true, {
1991                 if(it != ignore)
1992                         ++totalClients;
1993                 if(IS_REAL_CLIENT(it))
1994                 if(IS_PLAYER(it) || it.caplayer)
1995                         ++currentlyPlaying;
1996         });
1997
1998         int player_limit = GetPlayerLimit();
1999
2000         float free_slots = 0;
2001         if (!player_limit)
2002                 free_slots = maxclients - totalClients;
2003         else if(currentlyPlaying < player_limit)
2004                 free_slots = min(maxclients - totalClients, player_limit - currentlyPlaying);
2005
2006         static float msg_time = 0;
2007         if(this && !this.caplayer && ignore && !free_slots && time > msg_time)
2008         {
2009                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_JOIN_PREVENT);
2010                 msg_time = time + 0.5;
2011         }
2012
2013         return free_slots;
2014 }
2015
2016 /**
2017  * Checks whether the client is an observer or spectator, if so, he will get kicked after
2018  * g_maxplayers_spectator_blocktime seconds
2019  */
2020 void checkSpectatorBlock(entity this)
2021 {
2022         if(IS_SPEC(this) || IS_OBSERVER(this))
2023         if(!this.caplayer)
2024         if(IS_REAL_CLIENT(this))
2025         {
2026                 if( time > (CS(this).spectatortime + autocvar_g_maxplayers_spectator_blocktime) ) {
2027                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_QUIT_KICK_SPECTATING);
2028                         dropclient(this);
2029                 }
2030         }
2031 }
2032
2033 void PrintWelcomeMessage(entity this)
2034 {
2035         if(CS(this).motd_actived_time == 0)
2036         {
2037                 if (autocvar_g_campaign) {
2038                         if ((IS_PLAYER(this) && PHYS_INPUT_BUTTON_INFO(this)) || (!IS_PLAYER(this))) {
2039                                 CS(this).motd_actived_time = time;
2040                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_CAMPAIGN_MESSAGE, Campaign_GetMessage(), Campaign_GetLevelNum());
2041                         }
2042                 } else {
2043                         if (PHYS_INPUT_BUTTON_INFO(this)) {
2044                                 CS(this).motd_actived_time = time;
2045                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOTD, getwelcomemessage(this));
2046                         }
2047                 }
2048         }
2049         else if(CS(this).motd_actived_time > 0) // showing MOTD or campaign message
2050         {
2051                 if (autocvar_g_campaign) {
2052                         if (PHYS_INPUT_BUTTON_INFO(this))
2053                                 CS(this).motd_actived_time = time;
2054                         else if ((time - CS(this).motd_actived_time > 2) && IS_PLAYER(this)) { // hide it some seconds after BUTTON_INFO has been released
2055                                 CS(this).motd_actived_time = 0;
2056                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_CAMPAIGN_MESSAGE);
2057                         }
2058                 } else {
2059                         if (PHYS_INPUT_BUTTON_INFO(this))
2060                                 CS(this).motd_actived_time = time;
2061                         else if (time - CS(this).motd_actived_time > 2) { // hide it some seconds after BUTTON_INFO has been released
2062                                 CS(this).motd_actived_time = 0;
2063                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_MOTD);
2064                         }
2065                 }
2066         }
2067         else //if(CS(this).motd_actived_time < 0) // just connected, motd is active
2068         {
2069                 if(PHYS_INPUT_BUTTON_INFO(this)) // BUTTON_INFO hides initial MOTD
2070                         CS(this).motd_actived_time = -2; // wait until BUTTON_INFO gets released
2071                 else if (CS(this).motd_actived_time == -2)
2072                 {
2073                         // instantly hide MOTD
2074                         CS(this).motd_actived_time = 0;
2075                         if (autocvar_g_campaign)
2076                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_CAMPAIGN_MESSAGE);
2077                         else
2078                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_MOTD);
2079                 }
2080                 else if (IS_PLAYER(this) || IS_SPEC(this))
2081                 {
2082                         // FIXME occasionally for some reason MOTD never goes away
2083                         // delay MOTD removal a little bit in the hope it fixes this bug
2084                         if (CS(this).motd_actived_time == -1) // MOTD marked to fade away as soon as client becomes player or spectator
2085                                 CS(this).motd_actived_time = -(5 + floor(random() * 10)); // add small delay
2086                         else //if (CS(this).motd_actived_time < -2)
2087                                 CS(this).motd_actived_time++;
2088                 }
2089         }
2090 }
2091
2092 const int MIN_SPEC_TIME = 1;
2093 bool joinAllowed(entity this)
2094 {
2095         if (CS(this).version_mismatch) return false;
2096         if (time < CS(this).jointime + MIN_SPEC_TIME) return false;
2097         if (!nJoinAllowed(this, this)) return false;
2098         if (teamplay && lockteams) return false;
2099         if (MUTATOR_CALLHOOK(ForbidSpawn, this)) return false;
2100         if (ShowTeamSelection(this)) return false;
2101         return true;
2102 }
2103
2104 .int items_added;
2105 .string shootfromfixedorigin;
2106 .bool dualwielding_prev;
2107 bool PlayerThink(entity this)
2108 {
2109         if (game_stopped || intermission_running) {
2110                 this.modelflags &= ~MF_ROCKET;
2111                 if(intermission_running)
2112                         IntermissionThink(this);
2113                 return false;
2114         }
2115
2116         if (timeout_status == TIMEOUT_ACTIVE) {
2117         // don't allow the player to turn around while game is paused
2118                 // FIXME turn this into CSQC stuff
2119                 this.v_angle = this.lastV_angle;
2120                 this.angles = this.lastV_angle;
2121                 this.fixangle = true;
2122         }
2123
2124         if (frametime) player_powerups(this);
2125
2126         if (IS_DEAD(this)) {
2127                 if (this.personal && g_race_qualifying) {
2128                         if (time > this.respawn_time) {
2129                                 STAT(RESPAWN_TIME, this) = this.respawn_time = time + 1; // only retry once a second
2130                                 respawn(this);
2131                                 CS(this).impulse = CHIMPULSE_SPEEDRUN.impulse;
2132                         }
2133                 } else {
2134                         if (frametime) player_anim(this);
2135
2136                         if (this.respawn_flags & RESPAWN_DENY)
2137                         {
2138                                 STAT(RESPAWN_TIME, this) = 0;
2139                                 return false;
2140                         }
2141
2142                         bool button_pressed = (PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_JUMP(this) || PHYS_INPUT_BUTTON_ATCK2(this) || PHYS_INPUT_BUTTON_HOOK(this) || PHYS_INPUT_BUTTON_USE(this));
2143
2144                         switch(this.deadflag)
2145                         {
2146                                 case DEAD_DYING:
2147                                 {
2148                                         if ((this.respawn_flags & RESPAWN_FORCE) && !(this.respawn_time < this.respawn_time_max))
2149                                                 this.deadflag = DEAD_RESPAWNING;
2150                                         else if (!button_pressed || (time >= this.respawn_time_max && (this.respawn_flags & RESPAWN_FORCE)))
2151                                                 this.deadflag = DEAD_DEAD;
2152                                         break;
2153                                 }
2154                                 case DEAD_DEAD:
2155                                 {
2156                                         if (button_pressed)
2157                                                 this.deadflag = DEAD_RESPAWNABLE;
2158                                         else if (time >= this.respawn_time_max && (this.respawn_flags & RESPAWN_FORCE))
2159                                                 this.deadflag = DEAD_RESPAWNING;
2160                                         break;
2161                                 }
2162                                 case DEAD_RESPAWNABLE:
2163                                 {
2164                                         if (!button_pressed || (this.respawn_flags & RESPAWN_FORCE))
2165                                                 this.deadflag = DEAD_RESPAWNING;
2166                                         break;
2167                                 }
2168                                 case DEAD_RESPAWNING:
2169                                 {
2170                                         if (time > this.respawn_time)
2171                                         {
2172                                                 this.respawn_time = time + 1; // only retry once a second
2173                                                 this.respawn_time_max = this.respawn_time;
2174                                                 respawn(this);
2175                                         }
2176                                         break;
2177                                 }
2178                         }
2179
2180                         ShowRespawnCountdown(this);
2181
2182                         if (this.respawn_flags & RESPAWN_SILENT)
2183                                 STAT(RESPAWN_TIME, this) = 0;
2184                         else if ((this.respawn_flags & RESPAWN_FORCE) && this.respawn_time < this.respawn_time_max)
2185                         {
2186                                 if (time < this.respawn_time)
2187                                         STAT(RESPAWN_TIME, this) = this.respawn_time;
2188                                 else if (this.deadflag != DEAD_RESPAWNING)
2189                                         STAT(RESPAWN_TIME, this) = -this.respawn_time_max;
2190                         }
2191                         else
2192                                 STAT(RESPAWN_TIME, this) = this.respawn_time;
2193                 }
2194
2195                 // if respawning, invert stat_respawn_time to indicate this, the client translates it
2196                 if (this.deadflag == DEAD_RESPAWNING && STAT(RESPAWN_TIME, this) > 0)
2197                         STAT(RESPAWN_TIME, this) *= -1;
2198
2199                 return false;
2200         }
2201
2202         FixPlayermodel(this);
2203
2204         if (this.shootfromfixedorigin != autocvar_g_shootfromfixedorigin) {
2205                 this.shootfromfixedorigin = autocvar_g_shootfromfixedorigin;
2206                 stuffcmd(this, sprintf("\ncl_shootfromfixedorigin \"%s\"\n", autocvar_g_shootfromfixedorigin));
2207         }
2208
2209         // reset gun alignment when dual wielding status changes
2210         // to ensure guns are always aligned right and left
2211         bool dualwielding = W_DualWielding(this);
2212         if(this.dualwielding_prev != dualwielding)
2213         {
2214                 W_ResetGunAlign(this, CS(this).cvar_cl_gunalign);
2215                 this.dualwielding_prev = dualwielding;
2216         }
2217
2218         // LordHavoc: allow firing on move frames (sub-ticrate), this gives better timing on slow servers
2219         //if(frametime)
2220         {
2221                 this.items &= ~this.items_added;
2222
2223                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2224                 {
2225                         .entity weaponentity = weaponentities[slot];
2226                         if(WEP_CVAR(vortex, charge_always))
2227                                 W_Vortex_Charge(this, weaponentity, frametime);
2228                         W_WeaponFrame(this, weaponentity);
2229                 }
2230
2231                 this.items_added = 0;
2232                 if ((this.items & ITEM_Jetpack.m_itemid) && ((this.items & ITEM_JetpackRegen.m_itemid) || GetResource(this, RES_FUEL) >= 0.01))
2233             this.items_added |= IT_FUEL;
2234
2235                 this.items |= this.items_added;
2236         }
2237
2238         if (frametime)
2239         {
2240                 // WEAPONTODO: Add a weapon request for this
2241                 // rot vortex charge to the charge limit
2242                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2243                 {
2244                         .entity weaponentity = weaponentities[slot];
2245                         if (WEP_CVAR(vortex, charge_rot_rate) && this.(weaponentity).vortex_charge > WEP_CVAR(vortex, charge_limit) && this.(weaponentity).vortex_charge_rottime < time)
2246                                 this.(weaponentity).vortex_charge = bound(WEP_CVAR(vortex, charge_limit), this.(weaponentity).vortex_charge - WEP_CVAR(vortex, charge_rot_rate) * frametime / W_TICSPERFRAME, 1);
2247                 }
2248
2249                 player_regen(this);
2250                 player_anim(this);
2251                 this.dmg_team = max(0, this.dmg_team - autocvar_g_teamdamage_resetspeed * frametime);
2252         }
2253
2254         secrets_setstatus(this);
2255         monsters_setstatus(this);
2256
2257         return true;
2258 }
2259
2260 .bool would_spectate;
2261 void ObserverThink(entity this)
2262 {
2263         if ( CS(this).impulse )
2264         {
2265                 MinigameImpulse(this, CS(this).impulse);
2266                 CS(this).impulse = 0;
2267         }
2268
2269         if (this.flags & FL_JUMPRELEASED) {
2270                 if (PHYS_INPUT_BUTTON_JUMP(this) && joinAllowed(this)) {
2271                         this.flags &= ~FL_JUMPRELEASED;
2272                         this.flags |= FL_SPAWNING;
2273                 } else if(PHYS_INPUT_BUTTON_ATCK(this) && !CS(this).version_mismatch || this.would_spectate) {
2274                         this.flags &= ~FL_JUMPRELEASED;
2275                         if(SpectateNext(this)) {
2276                                 TRANSMUTE(Spectator, this);
2277                         }
2278                 } else {
2279                         int preferred_movetype = ((!PHYS_INPUT_BUTTON_USE(this) ? CS(this).cvar_cl_clippedspectating : !CS(this).cvar_cl_clippedspectating) ? MOVETYPE_FLY_WORLDONLY : MOVETYPE_NOCLIP);
2280                         set_movetype(this, preferred_movetype);
2281                 }
2282         } else {
2283                 if (!(PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_JUMP(this))) {
2284                         this.flags |= FL_JUMPRELEASED;
2285                         if(this.flags & FL_SPAWNING)
2286                         {
2287                                 this.flags &= ~FL_SPAWNING;
2288                                 if(joinAllowed(this))
2289                                         Join(this);
2290                                 return;
2291                         }
2292                 }
2293         }
2294 }
2295
2296 void SpectatorThink(entity this)
2297 {
2298         if ( CS(this).impulse )
2299         {
2300                 if(MinigameImpulse(this, CS(this).impulse))
2301                         CS(this).impulse = 0;
2302
2303                 if (CS(this).impulse == IMP_weapon_drop.impulse)
2304                 {
2305                         STAT(CAMERA_SPECTATOR, this) = (STAT(CAMERA_SPECTATOR, this) + 1) % 3;
2306                         CS(this).impulse = 0;
2307                         return;
2308                 }
2309         }
2310
2311         if (this.flags & FL_JUMPRELEASED) {
2312                 if (PHYS_INPUT_BUTTON_JUMP(this) && joinAllowed(this)) {
2313                         this.flags &= ~FL_JUMPRELEASED;
2314                         this.flags |= FL_SPAWNING;
2315                 } else if(PHYS_INPUT_BUTTON_ATCK(this) || CS(this).impulse == 10 || CS(this).impulse == 15 || CS(this).impulse == 18 || (CS(this).impulse >= 200 && CS(this).impulse <= 209)) {
2316                         this.flags &= ~FL_JUMPRELEASED;
2317                         if(SpectateNext(this)) {
2318                                 TRANSMUTE(Spectator, this);
2319                         } else {
2320                                 TRANSMUTE(Observer, this);
2321                                 PutClientInServer(this);
2322                         }
2323                         CS(this).impulse = 0;
2324                 } else if(CS(this).impulse == 12 || CS(this).impulse == 16  || CS(this).impulse == 19 || (CS(this).impulse >= 220 && CS(this).impulse <= 229)) {
2325                         this.flags &= ~FL_JUMPRELEASED;
2326                         if(SpectatePrev(this)) {
2327                                 TRANSMUTE(Spectator, this);
2328                         } else {
2329                                 TRANSMUTE(Observer, this);
2330                                 PutClientInServer(this);
2331                         }
2332                         CS(this).impulse = 0;
2333                 } else if (PHYS_INPUT_BUTTON_ATCK2(this)) {
2334                         this.would_spectate = false;
2335                         this.flags &= ~FL_JUMPRELEASED;
2336                         TRANSMUTE(Observer, this);
2337                         PutClientInServer(this);
2338                 } else {
2339                         if(!SpectateUpdate(this))
2340                         {
2341                                 if(!SpectateNext(this))
2342                                 {
2343                                         PutObserverInServer(this);
2344                                         this.would_spectate = true;
2345                                 }
2346                         }
2347                 }
2348         } else {
2349                 if (!(PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_ATCK2(this))) {
2350                         this.flags |= FL_JUMPRELEASED;
2351                         if(this.flags & FL_SPAWNING)
2352                         {
2353                                 this.flags &= ~FL_SPAWNING;
2354                                 Join(this);
2355                                 return;
2356                         }
2357                 }
2358                 if(!SpectateUpdate(this))
2359                         PutObserverInServer(this);
2360         }
2361
2362         this.flags |= FL_CLIENT | FL_NOTARGET;
2363 }
2364
2365 void PlayerUseKey(entity this)
2366 {
2367         if (!IS_PLAYER(this))
2368                 return;
2369
2370         if(this.vehicle)
2371         {
2372                 if(!game_stopped)
2373                 {
2374                         vehicles_exit(this.vehicle, VHEF_NORMAL);
2375                         return;
2376                 }
2377         }
2378         else if(autocvar_g_vehicles_enter)
2379         {
2380                 if(!game_stopped && !STAT(FROZEN, this) && !IS_DEAD(this) && !IS_INDEPENDENT_PLAYER(this))
2381                 {
2382                         entity head, closest_target = NULL;
2383                         head = WarpZone_FindRadius(this.origin, autocvar_g_vehicles_enter_radius, true);
2384
2385                         while(head) // find the closest acceptable target to enter
2386                         {
2387                                 if(IS_VEHICLE(head) && !IS_DEAD(head) && head.takedamage != DAMAGE_NO)
2388                                 if(!head.owner || ((head.vehicle_flags & VHF_MULTISLOT) && SAME_TEAM(head.owner, this)))
2389                                 {
2390                                         if(closest_target)
2391                                         {
2392                                                 if(vlen2(this.origin - head.origin) < vlen2(this.origin - closest_target.origin))
2393                                                 { closest_target = head; }
2394                                         }
2395                                         else { closest_target = head; }
2396                                 }
2397
2398                                 head = head.chain;
2399                         }
2400
2401                         if(closest_target) { vehicles_enter(this, closest_target); return; }
2402                 }
2403         }
2404
2405         // a use key was pressed; call handlers
2406         MUTATOR_CALLHOOK(PlayerUseKey, this);
2407 }
2408
2409
2410 /*
2411 =============
2412 PlayerPreThink
2413
2414 Called every frame for each client before the physics are run
2415 =============
2416 */
2417 .float last_vehiclecheck;
2418 void PlayerPreThink (entity this)
2419 {
2420         STAT(GUNALIGN, this) = CS(this).cvar_cl_gunalign; // TODO
2421         STAT(MOVEVARS_CL_TRACK_CANJUMP, this) = CS(this).cvar_cl_movement_track_canjump;
2422
2423         WarpZone_PlayerPhysics_FixVAngle(this);
2424
2425         if (frametime) {
2426                 // physics frames: update anticheat stuff
2427                 anticheat_prethink(this);
2428         }
2429
2430         if (blockSpectators && frametime) {
2431                 // WORKAROUND: only use dropclient in server frames (frametime set).
2432                 // Never use it in cl_movement frames (frametime zero).
2433                 checkSpectatorBlock(this);
2434         }
2435
2436         zoomstate_set = false;
2437
2438         // Check for nameless players
2439         if (this.netname == "" || this.netname != CS(this).netname_previous)
2440         {
2441                 bool assume_unchanged = (CS(this).netname_previous == "");
2442                 if (autocvar_sv_name_maxlength > 0 && strlennocol(this.netname) > autocvar_sv_name_maxlength)
2443                 {
2444                         int new_length = textLengthUpToLength(this.netname, autocvar_sv_name_maxlength, strlennocol);
2445                         this.netname = strzone(strcat(substring(this.netname, 0, new_length), "^7"));
2446                         sprint(this, sprintf("Warning: your name is longer than %d characters, it has been truncated.\n", autocvar_sv_name_maxlength));
2447                         assume_unchanged = false;
2448                         // stuffcmd(this, strcat("name ", this.netname, "\n")); // maybe?
2449                 }
2450                 if (isInvisibleString(this.netname))
2451                 {
2452                         this.netname = strzone(sprintf("Player#%d", this.playerid));
2453                         sprint(this, "Warning: invisible names are not allowed.\n");
2454                         assume_unchanged = false;
2455                         // stuffcmd(this, strcat("name ", this.netname, "\n")); // maybe?
2456                 }
2457                 if (!assume_unchanged && autocvar_sv_eventlog)
2458                         GameLogEcho(strcat(":name:", ftos(this.playerid), ":", playername(this, false)));
2459                 strcpy(CS(this).netname_previous, this.netname);
2460         }
2461
2462         // version nagging
2463         if (CS(this).version_nagtime && CS(this).cvar_g_xonoticversion && time > CS(this).version_nagtime) {
2464         CS(this).version_nagtime = 0;
2465         if (strstrofs(CS(this).cvar_g_xonoticversion, "git", 0) >= 0 || strstrofs(CS(this).cvar_g_xonoticversion, "autobuild", 0) >= 0) {
2466             // git client
2467         } else if (strstrofs(autocvar_g_xonoticversion, "git", 0) >= 0 || strstrofs(autocvar_g_xonoticversion, "autobuild", 0) >= 0) {
2468             // git server
2469             Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_BETA, autocvar_g_xonoticversion, CS(this).cvar_g_xonoticversion);
2470         } else {
2471             int r = vercmp(CS(this).cvar_g_xonoticversion, autocvar_g_xonoticversion);
2472             if (r < 0) { // old client
2473                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_OUTDATED, autocvar_g_xonoticversion, CS(this).cvar_g_xonoticversion);
2474             } else if (r > 0) { // old server
2475                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_OLD, autocvar_g_xonoticversion, CS(this).cvar_g_xonoticversion);
2476             }
2477         }
2478     }
2479
2480         // GOD MODE info
2481         if (!(this.flags & FL_GODMODE) && this.max_armorvalue)
2482         {
2483                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_GODMODE_OFF, this.max_armorvalue);
2484                 this.max_armorvalue = 0;
2485         }
2486
2487         if (frametime && IS_PLAYER(this))
2488         {
2489                 if (STAT(FROZEN, this) == FROZEN_TEMP_REVIVING)
2490                 {
2491                         STAT(REVIVE_PROGRESS, this) = bound(0, STAT(REVIVE_PROGRESS, this) + frametime * this.revive_speed, 1);
2492                         SetResourceExplicit(this, RES_HEALTH, max(1, STAT(REVIVE_PROGRESS, this) * start_health));
2493                         this.iceblock.alpha = bound(0.2, 1 - STAT(REVIVE_PROGRESS, this), 1);
2494
2495                         if (STAT(REVIVE_PROGRESS, this) >= 1)
2496                                 Unfreeze(this, false);
2497                 }
2498                 else if (STAT(FROZEN, this) == FROZEN_TEMP_DYING)
2499                 {
2500                         STAT(REVIVE_PROGRESS, this) = bound(0, STAT(REVIVE_PROGRESS, this) - frametime * this.revive_speed, 1);
2501                         SetResourceExplicit(this, RES_HEALTH, max(0, autocvar_g_nades_ice_health + (start_health-autocvar_g_nades_ice_health) * STAT(REVIVE_PROGRESS, this)));
2502
2503                         if (GetResource(this, RES_HEALTH) < 1)
2504                         {
2505                                 if (this.vehicle)
2506                                         vehicles_exit(this.vehicle, VHEF_RELEASE);
2507                                 if(this.event_damage)
2508                                         this.event_damage(this, this, this.frozen_by, 1, DEATH_NADE_ICE_FREEZE.m_id, DMG_NOWEP, this.origin, '0 0 0');
2509                         }
2510                         else if (STAT(REVIVE_PROGRESS, this) <= 0)
2511                                 Unfreeze(this, false);
2512                 }
2513         }
2514
2515         MUTATOR_CALLHOOK(PlayerPreThink, this);
2516
2517         if(autocvar_g_vehicles_enter && (time > this.last_vehiclecheck) && !game_stopped && !this.vehicle)
2518         if(IS_PLAYER(this) && !STAT(FROZEN, this) && !IS_DEAD(this) && !IS_INDEPENDENT_PLAYER(this))
2519         {
2520                 FOREACH_ENTITY_RADIUS(this.origin, autocvar_g_vehicles_enter_radius, IS_VEHICLE(it) && !IS_DEAD(it) && it.takedamage != DAMAGE_NO,
2521                 {
2522                         if(!it.owner)
2523                         {
2524                                 if(!it.team || SAME_TEAM(this, it))
2525                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER);
2526                                 else if(autocvar_g_vehicles_steal)
2527                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER_STEAL);
2528                         }
2529                         else if((it.vehicle_flags & VHF_MULTISLOT) && SAME_TEAM(it.owner, this))
2530                         {
2531                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER_GUNNER);
2532                         }
2533                 });
2534
2535                 this.last_vehiclecheck = time + 1;
2536         }
2537
2538         if(!CS(this).cvar_cl_newusekeysupported) // FIXME remove this - it was a stupid idea to begin with, we can JUST use the button
2539         {
2540                 if(PHYS_INPUT_BUTTON_USE(this) && !CS(this).usekeypressed)
2541                         PlayerUseKey(this);
2542                 CS(this).usekeypressed = PHYS_INPUT_BUTTON_USE(this);
2543         }
2544
2545         if (IS_REAL_CLIENT(this))
2546                 PrintWelcomeMessage(this);
2547
2548         if (IS_PLAYER(this)) {
2549                 if (IS_REAL_CLIENT(this) && time < CS(this).jointime + MIN_SPEC_TIME)
2550                         error("Client can't be spawned as player on connection!");
2551                 if(!PlayerThink(this))
2552                         return;
2553         }
2554         else if (game_stopped || intermission_running) {
2555                 if(intermission_running)
2556                         IntermissionThink(this);
2557                 return;
2558         }
2559         else if (IS_REAL_CLIENT(this) && !CS(this).autojoin_checked && time >= CS(this).jointime + MIN_SPEC_TIME)
2560         {
2561                 CS(this).autojoin_checked = true;
2562                 // don't do this in ClientConnect
2563                 // many things can go wrong if a client is spawned as player on connection
2564                 if (MUTATOR_CALLHOOK(AutoJoinOnConnection, this)
2565                         || (!(autocvar_sv_spectate || autocvar_g_campaign || (Player_GetForcedTeamIndex(this) == TEAM_FORCE_SPECTATOR))
2566                                 && (!teamplay || autocvar_g_balance_teams)))
2567                 {
2568                         campaign_bots_may_start = true;
2569                         Join(this);
2570                         return;
2571                 }
2572         }
2573         else if (IS_OBSERVER(this)) {
2574                 ObserverThink(this);
2575         }
2576         else if (IS_SPEC(this)) {
2577                 SpectatorThink(this);
2578         }
2579
2580         // WEAPONTODO: Add weapon request for this
2581         if (!zoomstate_set) {
2582                 bool wep_zoomed = false;
2583                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2584                 {
2585                         .entity weaponentity = weaponentities[slot];
2586                         Weapon thiswep = this.(weaponentity).m_weapon;
2587                         if(thiswep != WEP_Null && thiswep.wr_zoom)
2588                                 wep_zoomed += thiswep.wr_zoom(thiswep, this);
2589                 }
2590                 SetZoomState(this, PHYS_INPUT_BUTTON_ZOOM(this) || PHYS_INPUT_BUTTON_ZOOMSCRIPT(this) || wep_zoomed);
2591     }
2592
2593         if (CS(this).teamkill_soundtime && time > CS(this).teamkill_soundtime)
2594         {
2595                 CS(this).teamkill_soundtime = 0;
2596
2597                 entity e = CS(this).teamkill_soundsource;
2598                 entity oldpusher = e.pusher;
2599                 e.pusher = this;
2600                 PlayerSound(e, playersound_teamshoot, CH_VOICE, VOL_BASEVOICE, VOICETYPE_LASTATTACKER_ONLY);
2601                 e.pusher = oldpusher;
2602         }
2603
2604         if (CS(this).taunt_soundtime && time > CS(this).taunt_soundtime) {
2605                 CS(this).taunt_soundtime = 0;
2606                 PlayerSound(this, playersound_taunt, CH_VOICE, VOL_BASEVOICE, VOICETYPE_AUTOTAUNT);
2607         }
2608
2609         target_voicescript_next(this);
2610
2611         // WEAPONTODO: Move into weaponsystem somehow
2612         // if a player goes unarmed after holding a loaded weapon, empty his clip size and remove the crosshair ammo ring
2613         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2614         {
2615                 .entity weaponentity = weaponentities[slot];
2616                 if(this.(weaponentity).m_weapon == WEP_Null)
2617                         this.(weaponentity).clip_load = this.(weaponentity).clip_size = 0;
2618         }
2619 }
2620
2621 void DrownPlayer(entity this)
2622 {
2623         if(IS_DEAD(this) || game_stopped || time < game_starttime || this.vehicle
2624                 || STAT(FROZEN, this) || this.watertype != CONTENT_WATER)
2625         {
2626                 this.air_finished = 0;
2627                 return;
2628         }
2629
2630         if (this.waterlevel != WATERLEVEL_SUBMERGED)
2631         {
2632                 if(this.air_finished && this.air_finished < time)
2633                         PlayerSound(this, playersound_gasp, CH_PLAYER, VOL_BASE, VOICETYPE_PLAYERSOUND);
2634                 this.air_finished = 0;
2635         }
2636         else
2637         {
2638                 if (!this.air_finished)
2639                         this.air_finished = time + autocvar_g_balance_contents_drowndelay;
2640                 if (this.air_finished < time)
2641                 {       // drown!
2642                         if (this.pain_finished < time)
2643                         {
2644                                 Damage (this, NULL, NULL, autocvar_g_balance_contents_playerdamage_drowning * autocvar_g_balance_contents_damagerate, DEATH_DROWN.m_id, DMG_NOWEP, this.origin, '0 0 0');
2645                                 this.pain_finished = time + 0.5;
2646                         }
2647                 }
2648         }
2649 }
2650
2651 .bool move_qcphysics;
2652
2653 void Player_Physics(entity this)
2654 {
2655         this.movetype = (this.move_qcphysics) ? MOVETYPE_QCPLAYER : this.move_movetype;
2656
2657         if(!this.move_qcphysics)
2658                 return;
2659
2660         if(!frametime && !CS(this).pm_frametime)
2661                 return;
2662
2663         Movetype_Physics_NoMatchTicrate(this, CS(this).pm_frametime, true);
2664
2665         CS(this).pm_frametime = 0;
2666 }
2667
2668 /*
2669 =============
2670 PlayerPostThink
2671
2672 Called every frame for each client after the physics are run
2673 =============
2674 */
2675 void PlayerPostThink (entity this)
2676 {
2677         Player_Physics(this);
2678
2679         if (sv_maxidle > 0)
2680         if (frametime) // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2681         if (IS_REAL_CLIENT(this))
2682         if (IS_PLAYER(this) || sv_maxidle_spectatorsareidle)
2683         {
2684                 int totalClients = 0;
2685                 if(sv_maxidle_slots > 0)
2686                 {
2687                         FOREACH_CLIENT(IS_REAL_CLIENT(it) || sv_maxidle_slots_countbots,
2688                         {
2689                                 ++totalClients;
2690                         });
2691                 }
2692
2693                 if (sv_maxidle_slots > 0 && (maxclients - totalClients) > sv_maxidle_slots)
2694                 { /* do nothing */ }
2695                 else if (time - CS(this).parm_idlesince < 1) // instead of (time == this.parm_idlesince) to support sv_maxidle <= 10
2696                 {
2697                         if (CS(this).idlekick_lasttimeleft)
2698                         {
2699                                 CS(this).idlekick_lasttimeleft = 0;
2700                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_IDLING);
2701                         }
2702                 }
2703                 else
2704                 {
2705                         float timeleft = ceil(sv_maxidle - (time - CS(this).parm_idlesince));
2706                         if (timeleft == min(10, sv_maxidle - 1)) { // - 1 to support sv_maxidle <= 10
2707                                 if (!CS(this).idlekick_lasttimeleft)
2708                                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_DISCONNECT_IDLING, timeleft);
2709                         }
2710                         if (timeleft <= 0) {
2711                                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_QUIT_KICK_IDLING, this.netname);
2712                                 dropclient(this);
2713                                 return;
2714                         }
2715                         else if (timeleft <= 10) {
2716                                 if (timeleft != CS(this).idlekick_lasttimeleft) {
2717                                     Send_Notification(NOTIF_ONE, this, MSG_ANNCE, Announcer_PickNumber(CNT_IDLE, timeleft));
2718                 }
2719                                 CS(this).idlekick_lasttimeleft = timeleft;
2720                         }
2721                 }
2722         }
2723
2724         CheatFrame(this);
2725
2726         if (game_stopped)
2727         {
2728                 this.solid = SOLID_NOT;
2729                 this.takedamage = DAMAGE_NO;
2730                 set_movetype(this, MOVETYPE_NONE);
2731         }
2732
2733         if (IS_PLAYER(this)) {
2734                 if(this.death_time == time && IS_DEAD(this))
2735                 {
2736                         // player's bbox gets resized now, instead of in the damage event that killed the player,
2737                         // once all the damage events of this frame have been processed with normal size
2738                         this.maxs.z = 5;
2739                         setsize(this, this.mins, this.maxs);
2740                 }
2741                 DrownPlayer(this);
2742                 UpdateChatBubble(this);
2743                 if (CS(this).impulse) ImpulseCommands(this);
2744                 if (game_stopped)
2745                 {
2746                         CSQCMODEL_AUTOUPDATE(this);
2747                         return;
2748                 }
2749                 GetPressedKeys(this);
2750         }
2751         else if (IS_OBSERVER(this) && STAT(PRESSED_KEYS, this))
2752         {
2753                 CS(this).pressedkeys = 0;
2754                 STAT(PRESSED_KEYS, this) = 0;
2755         }
2756
2757         if (this.waypointsprite_attachedforcarrier) {
2758                 float hp = healtharmor_maxdamage(GetResource(this, RES_HEALTH), GetResource(this, RES_ARMOR), autocvar_g_balance_armor_blockpercent, DEATH_WEAPON.m_id).x;
2759                 WaypointSprite_UpdateHealth(this.waypointsprite_attachedforcarrier, hp);
2760         }
2761
2762         CSQCMODEL_AUTOUPDATE(this);
2763 }
2764
2765 /**
2766  * message "": do not say, just test flood control
2767  * return value:
2768  *   1 = accept
2769  *   0 = reject
2770  *  -1 = fake accept
2771  */
2772 int Say(entity source, int teamsay, entity privatesay, string msgin, bool floodcontrol)
2773 {
2774         if (!teamsay && !privatesay && substring(msgin, 0, 1) == " ")
2775                 msgin = substring(msgin, 1, -1); // work around DP say bug (say_team does not have this!)
2776
2777         if (source)
2778                 msgin = formatmessage(source, msgin);
2779
2780         string colorstr;
2781         if (!(IS_PLAYER(source) || source.caplayer))
2782                 colorstr = "^0"; // black for spectators
2783         else if(teamplay)
2784                 colorstr = Team_ColorCode(source.team);
2785         else
2786         {
2787                 colorstr = "";
2788                 teamsay = false;
2789         }
2790
2791         if (!source) {
2792                 colorstr = "";
2793                 teamsay = false;
2794         }
2795
2796         if(msgin != "")
2797                 msgin = trigger_magicear_processmessage_forallears(source, teamsay, privatesay, msgin);
2798
2799         /*
2800          * using bprint solves this... me stupid
2801         // how can we prevent the message from appearing in a listen server?
2802         // for now, just give "say" back and only handle say_team
2803         if(!teamsay)
2804         {
2805                 clientcommand(source, strcat("say ", msgin));
2806                 return;
2807         }
2808         */
2809
2810         string namestr = "";
2811         if (source)
2812                 namestr = playername(source, autocvar_g_chat_teamcolors);
2813
2814         string colorprefix = (strdecolorize(namestr) == namestr) ? "^3" : "^7";
2815
2816         string msgstr = "", cmsgstr = "";
2817         string privatemsgprefix = string_null;
2818         int privatemsgprefixlen = 0;
2819         if (msgin != "")
2820         {
2821                 bool found_me = false;
2822                 if(strstrofs(msgin, "/me", 0) >= 0)
2823                 {
2824                         string newmsgin = "";
2825                         string newnamestr = ((teamsay) ? strcat(colorstr, "(", colorprefix, namestr, colorstr, ")", "^7") : strcat(colorprefix, namestr, "^7"));
2826                         FOREACH_WORD(msgin, true,
2827                         {
2828                                 if(strdecolorize(it) == "/me")
2829                                 {
2830                                         found_me = true;
2831                                         newmsgin = cons(newmsgin, newnamestr);
2832                                 }
2833                                 else
2834                                         newmsgin = cons(newmsgin, it);
2835                         });
2836                         msgin = newmsgin;
2837                 }
2838
2839                 if(privatesay)
2840                 {
2841                         msgstr = strcat("\{1}\{13}* ", colorprefix, namestr, "^3 tells you: ^7");
2842                         privatemsgprefixlen = strlen(msgstr);
2843                         msgstr = strcat(msgstr, msgin);
2844                         cmsgstr = strcat(colorstr, colorprefix, namestr, "^3 tells you:\n^7", msgin);
2845                         privatemsgprefix = strcat("\{1}\{13}* ^3You tell ", playername(privatesay, autocvar_g_chat_teamcolors), ": ^7");
2846                 }
2847                 else if(teamsay)
2848                 {
2849                         if(found_me)
2850                         {
2851                                 //msgin = strreplace("/me", "", msgin);
2852                                 //msgin = substring(msgin, 3, strlen(msgin));
2853                                 //msgin = strreplace("/me", strcat(colorstr, "(", colorprefix, namestr, colorstr, ")^7"), msgin);
2854                                 msgstr = strcat("\{1}\{13}^4* ", "^7", msgin);
2855                         }
2856                         else
2857                                 msgstr = strcat("\{1}\{13}", colorstr, "(", colorprefix, namestr, colorstr, ") ^7", msgin);
2858                         cmsgstr = strcat(colorstr, "(", colorprefix, namestr, colorstr, ")\n^7", msgin);
2859                 }
2860                 else
2861                 {
2862                         if(found_me)
2863                         {
2864                                 //msgin = strreplace("/me", "", msgin);
2865                                 //msgin = substring(msgin, 3, strlen(msgin));
2866                                 //msgin = strreplace("/me", strcat(colorprefix, namestr), msgin);
2867                                 msgstr = strcat("\{1}^4* ^7", msgin);
2868                         }
2869                         else {
2870                                 msgstr = "\{1}";
2871                                 msgstr = strcat(msgstr, (namestr != "") ? strcat(colorprefix, namestr, "^7: ") : "^7");
2872                                 msgstr = strcat(msgstr, msgin);
2873                         }
2874                         cmsgstr = "";
2875                 }
2876                 msgstr = strcat(strreplace("\n", " ", msgstr), "\n"); // newlines only are good for centerprint
2877         }
2878
2879         string fullmsgstr = msgstr;
2880         string fullcmsgstr = cmsgstr;
2881
2882         // FLOOD CONTROL
2883         int flood = 0;
2884         var .float flood_field = floodcontrol_chat;
2885         if(floodcontrol && source)
2886         {
2887                 float flood_spl;
2888                 float flood_burst;
2889                 float flood_lmax;
2890                 float lines;
2891                 if(privatesay)
2892                 {
2893                         flood_spl = autocvar_g_chat_flood_spl_tell;
2894                         flood_burst = autocvar_g_chat_flood_burst_tell;
2895                         flood_lmax = autocvar_g_chat_flood_lmax_tell;
2896                         flood_field = floodcontrol_chattell;
2897                 }
2898                 else if(teamsay)
2899                 {
2900                         flood_spl = autocvar_g_chat_flood_spl_team;
2901                         flood_burst = autocvar_g_chat_flood_burst_team;
2902                         flood_lmax = autocvar_g_chat_flood_lmax_team;
2903                         flood_field = floodcontrol_chatteam;
2904                 }
2905                 else
2906                 {
2907                         flood_spl = autocvar_g_chat_flood_spl;
2908                         flood_burst = autocvar_g_chat_flood_burst;
2909                         flood_lmax = autocvar_g_chat_flood_lmax;
2910                         flood_field = floodcontrol_chat;
2911                 }
2912                 flood_burst = max(0, flood_burst - 1);
2913                 // to match explanation in default.cfg, a value of 3 must allow three-line bursts and not four!
2914
2915                 // do flood control for the default line size
2916                 if(msgstr != "")
2917                 {
2918                         getWrappedLine_remaining = msgstr;
2919                         msgstr = "";
2920                         lines = 0;
2921                         while(getWrappedLine_remaining && (!flood_lmax || lines <= flood_lmax))
2922                         {
2923                                 msgstr = strcat(msgstr, " ", getWrappedLineLen(82.4289758859709, strlennocol)); // perl averagewidth.pl < gfx/vera-sans.width
2924                                 ++lines;
2925                         }
2926                         msgstr = substring(msgstr, 1, strlen(msgstr) - 1);
2927
2928                         if(getWrappedLine_remaining != "")
2929                         {
2930                                 msgstr = strcat(msgstr, "\n");
2931                                 flood = 2;
2932                         }
2933
2934                         if (time >= source.(flood_field))
2935                         {
2936                                 source.(flood_field) = max(time - flood_burst * flood_spl, source.(flood_field)) + lines * flood_spl;
2937                         }
2938                         else
2939                         {
2940                                 flood = 1;
2941                                 msgstr = fullmsgstr;
2942                         }
2943                 }
2944                 else
2945                 {
2946                         if (time >= source.(flood_field))
2947                                 source.(flood_field) = max(time - flood_burst * flood_spl, source.(flood_field)) + flood_spl;
2948                         else
2949                                 flood = 1;
2950                 }
2951
2952                 if (timeout_status == TIMEOUT_ACTIVE) // when game is paused, no flood protection
2953                         source.(flood_field) = flood = 0;
2954         }
2955
2956         string sourcemsgstr, sourcecmsgstr;
2957         if(flood == 2) // cannot happen for empty msgstr
2958         {
2959                 if(autocvar_g_chat_flood_notify_flooder)
2960                 {
2961                         sourcemsgstr = strcat(msgstr, "\n^3FLOOD CONTROL: ^7message too long, trimmed\n");
2962                         sourcecmsgstr = "";
2963                 }
2964                 else
2965                 {
2966                         sourcemsgstr = fullmsgstr;
2967                         sourcecmsgstr = fullcmsgstr;
2968                 }
2969                 cmsgstr = "";
2970         }
2971         else
2972         {
2973                 sourcemsgstr = msgstr;
2974                 sourcecmsgstr = cmsgstr;
2975         }
2976
2977         if (!privatesay && source && !(IS_PLAYER(source) || source.caplayer))
2978         {
2979                 if (!game_stopped)
2980                 if (teamsay || (autocvar_g_chat_nospectators == 1) || (autocvar_g_chat_nospectators == 2 && !warmup_stage))
2981                         teamsay = -1; // spectators
2982         }
2983
2984         if(flood)
2985                 LOG_INFO("NOTE: ", playername(source, true), "^7 is flooding.");
2986
2987         // build sourcemsgstr by cutting off a prefix and replacing it by the other one
2988         if(privatesay)
2989                 sourcemsgstr = strcat(privatemsgprefix, substring(sourcemsgstr, privatemsgprefixlen, -1));
2990
2991         int ret;
2992         if(source && CS(source).muted)
2993         {
2994                 // always fake the message
2995                 ret = -1;
2996         }
2997         else if(flood == 1)
2998         {
2999                 if (autocvar_g_chat_flood_notify_flooder)
3000                 {
3001                         sprint(source, strcat("^3FLOOD CONTROL: ^7wait ^1", ftos(source.(flood_field) - time), "^3 seconds\n"));
3002                         ret = 0;
3003                 }
3004                 else
3005                         ret = -1;
3006         }
3007         else
3008         {
3009                 ret = 1;
3010         }
3011
3012         if (privatesay && source && !(IS_PLAYER(source) || source.caplayer))
3013         {
3014                 if (!game_stopped)
3015                 if ((privatesay && (IS_PLAYER(privatesay) || privatesay.caplayer)) && ((autocvar_g_chat_nospectators == 1) || (autocvar_g_chat_nospectators == 2 && !warmup_stage)))
3016                         ret = -1; // just hide the message completely
3017         }
3018
3019         MUTATOR_CALLHOOK(ChatMessage, source, ret);
3020         ret = M_ARGV(1, int);
3021
3022         string event_log_msg = "";
3023
3024         if(sourcemsgstr != "" && ret != 0)
3025         {
3026                 if(ret < 0) // faked message, because the player is muted
3027                 {
3028                         sprint(source, sourcemsgstr);
3029                         if(sourcecmsgstr != "" && !privatesay)
3030                                 centerprint(source, sourcecmsgstr);
3031                 }
3032                 else if(privatesay) // private message, between 2 people only
3033                 {
3034                         sprint(source, sourcemsgstr);
3035                         if (!autocvar_g_chat_tellprivacy) { dedicated_print(msgstr); } // send to server console too if "tellprivacy" is disabled
3036                         if(!MUTATOR_CALLHOOK(ChatMessageTo, privatesay, source))
3037                         {
3038                                 sprint(privatesay, msgstr);
3039                                 if(cmsgstr != "")
3040                                         centerprint(privatesay, cmsgstr);
3041                         }
3042                 }
3043                 else if ( teamsay && CS(source).active_minigame )
3044                 {
3045                         sprint(source, sourcemsgstr);
3046                         dedicated_print(msgstr); // send to server console too
3047                         FOREACH_CLIENT(IS_REAL_CLIENT(it) && it != source && CS(it).active_minigame == CS(source).active_minigame && !MUTATOR_CALLHOOK(ChatMessageTo, it, source), {
3048                                 sprint(it, msgstr);
3049                         });
3050                         event_log_msg = sprintf(":chat_minigame:%d:%s:%s", source.playerid, CS(source).active_minigame.netname, msgin);
3051
3052                 }
3053                 else if(teamsay > 0) // team message, only sent to team mates
3054                 {
3055                         sprint(source, sourcemsgstr);
3056                         dedicated_print(msgstr); // send to server console too
3057                         if(sourcecmsgstr != "")
3058                                 centerprint(source, sourcecmsgstr);
3059                         FOREACH_CLIENT((IS_PLAYER(it) || it.caplayer) && IS_REAL_CLIENT(it) && it != source && it.team == source.team && !MUTATOR_CALLHOOK(ChatMessageTo, it, source), {
3060                                 sprint(it, msgstr);
3061                                 if(cmsgstr != "")
3062                                         centerprint(it, cmsgstr);
3063                         });
3064                         event_log_msg = sprintf(":chat_team:%d:%d:%s", source.playerid, source.team, strreplace("\n", " ", msgin));
3065                 }
3066                 else if(teamsay < 0) // spectator message, only sent to spectators
3067                 {
3068                         sprint(source, sourcemsgstr);
3069                         dedicated_print(msgstr); // send to server console too
3070                         FOREACH_CLIENT(!(IS_PLAYER(it) || it.caplayer) && IS_REAL_CLIENT(it) && it != source && !MUTATOR_CALLHOOK(ChatMessageTo, it, source), {
3071                                 sprint(it, msgstr);
3072                         });
3073                         event_log_msg = sprintf(":chat_spec:%d:%s", source.playerid, strreplace("\n", " ", msgin));
3074                 }
3075                 else
3076                 {
3077                         if (source) {
3078                                 sprint(source, sourcemsgstr);
3079                                 dedicated_print(msgstr); // send to server console too
3080                                 MX_Say(strcat(playername(source, true), "^7: ", msgin));
3081                         }
3082                         FOREACH_CLIENT(IS_REAL_CLIENT(it) && it != source && !MUTATOR_CALLHOOK(ChatMessageTo, it, source), {
3083                                 sprint(it, msgstr);
3084                         });
3085                         event_log_msg = sprintf(":chat:%d:%s", source.playerid, strreplace("\n", " ", msgin));
3086                 }
3087         }
3088
3089         if (autocvar_sv_eventlog && (event_log_msg != "")) {
3090                 GameLogEcho(event_log_msg);
3091         }
3092
3093         return ret;
3094 }
3095
3096 // hack to copy the button fields from the client entity to the Client State
3097 void PM_UpdateButtons(entity this, entity store)
3098 {
3099         if(this.impulse)
3100                 store.impulse = this.impulse;
3101         this.impulse = 0;
3102
3103         bool typing = this.buttonchat || this.button12;
3104
3105         store.button0 = (typing) ? 0 : this.button0;
3106         //button1?!
3107         store.button2 = (typing) ? 0 : this.button2;
3108         store.button3 = (typing) ? 0 : this.button3;
3109         store.button4 = this.button4;
3110         store.button5 = (typing) ? 0 : this.button5;
3111         store.button6 = this.button6;
3112         store.button7 = this.button7;
3113         store.button8 = this.button8;
3114         store.button9 = this.button9;
3115         store.button10 = this.button10;
3116         store.button11 = this.button11;
3117         store.button12 = this.button12;
3118         store.button13 = this.button13;
3119         store.button14 = this.button14;
3120         store.button15 = this.button15;
3121         store.button16 = this.button16;
3122         store.buttonuse = this.buttonuse;
3123         store.buttonchat = this.buttonchat;
3124
3125         store.cursor_active = this.cursor_active;
3126         store.cursor_screen = this.cursor_screen;
3127         store.cursor_trace_start = this.cursor_trace_start;
3128         store.cursor_trace_endpos = this.cursor_trace_endpos;
3129         store.cursor_trace_ent = this.cursor_trace_ent;
3130
3131         store.ping = this.ping;
3132         store.ping_packetloss = this.ping_packetloss;
3133         store.ping_movementloss = this.ping_movementloss;
3134
3135         store.v_angle = this.v_angle;
3136         store.movement = (typing) ? '0 0 0' : this.movement;
3137 }
3138
3139 NET_HANDLE(fpsreport, bool)
3140 {
3141         int fps = ReadShort();
3142         PlayerScore_Set(sender, SP_FPS, fps);
3143         return true;
3144 }