Revert alignment of bots.txt (it uses the \t character to sort), also bring back...
[xonotic/xonotic-data.pk3dir.git] / qcsrc / server / client.qh
1 #pragma once
2
3 void ClientState_attach(entity this);
4
5 IntrusiveList g_players;
6 STATIC_INIT(g_players) { g_players = IL_NEW(); }
7
8 CLASS(Client, Object)
9     /** Client name */
10     ATTRIB(Client, netname, string, this.netname);
11     ATTRIB(Client, colormap, int, this.colormap);
12     ATTRIB(Client, team, int, this.team);
13     ATTRIB(Client, clientcolors, int, this.clientcolors);
14     /** Client IP */
15     ATTRIB(Client, netaddress, string, this.netaddress);
16     ATTRIB(Client, playermodel, string, this.playermodel);
17     ATTRIB(Client, playerskin, int, this.playerskin);
18
19     /** fingerprint of CA key the player used to authenticate */
20     ATTRIB(Client, crypto_keyfp, string, this.crypto_keyfp);
21     /** fingerprint of CA key the server used to authenticate to the player */
22     ATTRIB(Client, crypto_mykeyfp, string, this.crypto_mykeyfp);
23     /** fingerprint of ID used by the player entity, or string_null if not identified */
24     ATTRIB(Client, crypto_idfp, string, this.crypto_idfp);
25     /** set if the player's ID has been signed */
26     ATTRIB(Client, crypto_idfp_signed, bool, this.crypto_idfp_signed);
27     /** the string "AES128" if encrypting, and string_null if plaintext */
28     ATTRIB(Client, crypto_encryptmethod, string, this.crypto_encryptmethod);
29     /** the string "HMAC-SHA256" if signing, and string_null if plaintext */
30     ATTRIB(Client, crypto_signmethod, string, this.crypto_signmethod);
31
32     // custom
33
34     ATTRIB(Client, playerid, int, this.playerid);
35
36     METHOD(Client, m_unwind, bool(Client this));
37
38     STATIC_METHOD(Client, Add, void(Client this, int _team));
39     STATIC_METHOD(Client, Remove, void(Client this));
40
41     INIT(Client) {
42         if (this.m_unwind(this)) return this;
43         make_impure(this);
44         this.classname = "player_joining";
45         static int playerid_last;
46         this.playerid = ++playerid_last;
47         ClientState_attach(this);
48     }
49     DESTRUCTOR(Client) {
50         Client_Remove(this);
51     }
52     CONSTRUCTOR(Client, string name) {
53         CONSTRUCT(Client);
54         this.netname = name;
55         this.netaddress = "local";
56         this.playermodel = cvar_defstring("sv_defaultplayermodel");
57     }
58 ENDCLASS(Client)
59
60 CLASS(Observer, Client)
61     INIT(Observer) {
62         this.classname = STR_OBSERVER;
63     }
64     DESTRUCTOR(Observer) { }
65 ENDCLASS(Observer)
66
67 CLASS(Spectator, Client)
68     INIT(Spectator) {
69         this.classname = STR_SPECTATOR;
70     }
71     DESTRUCTOR(Spectator) { }
72 ENDCLASS(Spectator)
73
74 CLASS(Player, Client)
75     INIT(Player) {
76         this.classname = STR_PLAYER;
77         IL_PUSH(g_players, this);
78     }
79     DESTRUCTOR(Player) {
80         IL_REMOVE(g_players, this);
81     }
82 ENDCLASS(Player)
83
84 METHOD(Client, m_unwind, bool(Client this))
85 {
86     TC(Client, this);
87     #define UNWIND(class) MACRO_BEGIN if (this.instanceOf##class) { METHOD_REFERENCE(class, dtorimpl)(this); } MACRO_END
88     switch (this.classname) {
89         case "Observer":
90             UNWIND(Spectator);
91             UNWIND(Player);
92             return true;
93         case "Spectator":
94             UNWIND(Observer);
95             UNWIND(Player);
96             return true;
97         case "Player":
98             UNWIND(Observer);
99             UNWIND(Spectator);
100             return true;
101     }
102     #undef UNWIND
103     return false;
104 }
105
106 float c1, c2, c3, c4;
107
108 void play_countdown(entity this, float finished, Sound samp);
109
110 float CalcRotRegen(float current, float regenstable, float regenfactor, float regenlinear, float regenframetime, float rotstable, float rotfactor, float rotlinear, float rotframetime, float limit);
111
112 bool Spectate(entity this, entity pl);
113
114 #define SPECTATE_COPY() [[accumulate]] void SpectateCopy(entity this, entity spectatee)
115 #define SPECTATE_COPYFIELD(fld) SPECTATE_COPY() { this.(fld) = spectatee.(fld); }