qcsrc/server/clientcommands.qc

   1 entity nagger;
   2 float readycount;
   3 float Nagger_SendEntity(entity to, float sendflags)
   4 {
   5         float nags, i, f, b;
   6         entity e;
   7         WriteByte(MSG_ENTITY, ENT_CLIENT_NAGGER);
   8
   9         nags = 0;
  10         if(readycount)
  11         {
  12                 nags |= 1;
  13                 if(to.ready == 0)
  14                         nags |= 2;
  15         }
  16         if(votecalled)
  17         {
  18                 nags |= 4;
  19                 if(to.vote_vote == 0)
  20                         nags |= 8;
  21         }
  22         if(inWarmupStage)
  23                 nags |= 16;
  24
  25         if(sendflags & 128)
  26                 nags |= 128;
  27
  28         WriteByte(MSG_ENTITY, nags);
  29
  30         if(nags & 128)
  31         {
  32                 WriteString(MSG_ENTITY, votecalledvote_display);
  33         }
  34
  35         if(nags & 1)
  36         {
  37                 for(i = 1; i <= maxclients; i += 8)
  38                 {
  39                         for(f = 0, e = edict_num(i), b = 1; b < 256; b *= 2, e = nextent(e))
  40                                 if(clienttype(e) != CLIENTTYPE_REAL || e.ready)
  41                                         f |= b;
  42                         WriteByte(MSG_ENTITY, f);
  43                 }
  44         }
  45
  46         return TRUE;
  47 }
  48 void Nagger_Init()
  49 {
  50         Net_LinkEntity(nagger = spawn(), FALSE, 0, Nagger_SendEntity);
  51 }
  52 void Nagger_VoteChanged()
  53 {
  54         if(nagger)
  55                 nagger.SendFlags |= 128;
  56 }
  57 void Nagger_VoteCountChanged()
  58 {
  59         if(nagger)
  60                 nagger.SendFlags |= 1;
  61 }
  62 void Nagger_ReadyCounted()
  63 {
  64         if(nagger)
  65                 nagger.SendFlags |= 1;
  66 }
  67
  68 void ReadyCount();
  69 string MapVote_Suggest(string m);
  70
  71 entity GetPlayer(string name)
  72 {
  73         float num;
  74         entity e;
  75         string ns;
  76
  77         if(substring(name, 0, 1) == "#") {
  78                 num = stof(substring(name, 1, 999));
  79                 if(num >= 1 && num <= maxclients) {
  80                         for((e = world); num > 0; --num, (e = nextent(e)))
  81                                 ;
  82                         //if(clienttype(e) == CLIENTTYPE_REAL)
  83                         if(e.classname == "player")
  84                                 return e;
  85                 }
  86         } else {
  87                 ns = strdecolorize(name);
  88                 FOR_EACH_REALPLAYER(e) {
  89                         if(!strcasecmp(strdecolorize(e.netname), ns)) {
  90                                 return e;
  91                         }
  92                 }
  93         }
  94         return world;
  95 }
  96
  97 //float ctf_clientcommand();
  98 float readyrestart_happened;
  99 .float lms_spectate_warning;
 100 void spawnfunc_func_breakable();
 101
 102 .float cmd_floodtime;
 103 .float cmd_floodcount;
 104 float cmd_floodcheck()
 105 {
 106         if (timeoutStatus != 2)
 107         {
 108                 if(time == self.cmd_floodtime)
 109                 {
 110                         self.cmd_floodcount += 1;
 111                         if(self.cmd_floodcount > 8)
 112                                 return TRUE;
 113                 }
 114                 else
 115                 {
 116                         self.cmd_floodtime = time;
 117                         self.cmd_floodcount = 1;
 118                 }
 119         }
 120         return FALSE;
 121 }
 122
 123 void SV_ParseClientCommand(string s) {
 124         string cmd;
 125         float tokens;
 126         float i;
 127         entity e;
 128
 129         tokens = tokenize_console(s);
 130
 131         cmd = argv(0);
 132         if(cmd != "reportcvar")
 133         if(cmd != "sentcvar")
 134         if(cmd != "pause")
 135         if(cmd != "prespawn")
 136         if(cmd != "spawn")
 137         if(cmd != "begin")
 138         {
 139                 if(cmd_floodcheck())
 140                         return;
 141         }
 142
 143         if(GameCommand_Vote(s, self)) {
 144                 return;
 145         } else if(GameCommand_MapVote(argv(0))) {
 146                 return;
 147         } else if(cmd == "autoswitch") {
 148                 // be backwards compatible with older clients (enabled)
 149                 self.autoswitch = ("0" != argv(1));
 150                 local string autoswitchmsg;
 151                 if (self.autoswitch) {
 152                         autoswitchmsg = "on";
 153                 } else {
 154                         autoswitchmsg = "off";
 155                 }
 156                 sprint(self, strcat("^1autoswitch turned ", autoswitchmsg, "\n"));
 157         } else if(cmd == "clientversion") {
 158                 if not(self.flags & FL_CLIENT)
 159                         return;
 160                 if (argv(1) == "$gameversion") {
 161                         //versionmsg = "^1client is too old to get versioninfo.\nUPDATE!!! (http://www.xonotic.com)^8";
 162                         // either that or someone wants to be funny
 163                         self.version = 1;
 164                 } else {
 165                         self.version = stof(argv(1));
 166                 }
 167                 if(self.version != cvar("gameversion"))
 168                 {
 169                         self.classname = "observer";
 170                         self.version_mismatch = 1;
 171                         PutClientInServer();
 172                 } else if(cvar("g_campaign") || cvar("g_balance_teams") || cvar("g_balance_teams_force")) {
 173                         //JoinBestTeam(self, FALSE, TRUE);
 174                 } else if(teams_matter && !cvar("sv_spectate")) {
 175                         self.classname = "observer";
 176                         stuffcmd(self,"menu_showteamselect\n");
 177                 }
 178         } else if(cmd == "reportcvar") { // old system
 179                 if(substring(argv(2), 0, 1) == "$") // undefined cvar: use the default value on the server then
 180                 {
 181                         s = strcat(substring(s, argv_start_index(0), argv_end_index(1) - argv_start_index(0)), " \"", cvar_defstring(argv(1)), "\"");
 182                         tokens = tokenize_console(s);
 183                 }
 184                 GetCvars(1);
 185         } else if(cmd == "sentcvar") { // new system
 186                 if(tokens == 2) // undefined cvar: use the default value on the server then
 187                 {
 188                         s = strcat(substring(s, argv_start_index(0), argv_end_index(1) - argv_start_index(0)), " \"", cvar_defstring(argv(1)), "\"");
 189                         tokens = tokenize_console(s);
 190                 }
 191                 GetCvars(1);
 192         } else if(cmd == "spectate") {
 193                 if(cmd_floodcheck())
 194                         return;
 195                 if not(self.flags & FL_CLIENT)
 196                         return;
 197                 if(g_arena)
 198                         return;
 199                 if(g_lms)
 200                 {
 201                         if(self.lms_spectate_warning)
 202                         {
 203                                 // mark player as spectator
 204                                 PlayerScore_Add(self, SP_LMS_RANK, 666 - PlayerScore_Add(self, SP_LMS_RANK, 0));
 205                         }
 206                         else
 207                         {
 208                                 self.lms_spectate_warning = 1;
 209                                 sprint(self, "WARNING: you won't be able to enter the game again after spectating in LMS. Use the same command again to spectate anyway.\n");
 210                                 return;
 211                         }
 212                 }
 213                 if(self.classname == "player" && cvar("sv_spectate") == 1) {
 214                         if(self.flagcarried)
 215                                 DropFlag(self.flagcarried, world, world);
 216                         if(self.ballcarried)
 217                                 DropBall(self.ballcarried, self.origin, self.velocity);
 218                         WaypointSprite_PlayerDead();
 219                         self.classname = "observer";
 220                         if(g_ca)
 221                                 self.caplayer = 0;
 222                         if(blockSpectators)
 223                                 sprint(self, strcat("^7You have to become a player within the next ", ftos(cvar("g_maxplayers_spectator_blocktime")), " seconds, otherwise you will be kicked, because spectators aren't allowed at this time!\n"));
 224                         PutClientInServer();
 225                 }
 226         } else if(cmd == "join") {
 227                 if not(self.flags & FL_CLIENT)
 228                         return;
 229                 if(!g_arena)
 230                 if (self.classname != "player" && !lockteams)
 231                 {
 232                         if(isJoinAllowed()) {
 233                                 self.classname = "player";
 234                                 if(g_ca)
 235                                         self.caplayer = 1;
 236                                 PlayerScore_Clear(self);
 237                                 bprint ("^4", self.netname, "^4 is playing now\n");
 238                                 self.stat_count = WEP_LAST;
 239                                 PutClientInServer();
 240                                 if(cvar("g_campaign"))
 241                                         campaign_bots_may_start = 1;
 242                         }
 243                         else {
 244                                 //player may not join because of g_maxplayers is set
 245                                 centerprint_atprio(self, CENTERPRIO_MAPVOTE, PREVENT_JOIN_TEXT);
 246                         }
 247                 }
 248         } else if( cmd == "selectteam" ) {
 249                 if not(self.flags & FL_CLIENT)
 250                         return;
 251                 if( !teams_matter ) {
 252                         sprint( self, "selecteam can only be used in teamgames\n");
 253                 } else if(cvar("g_campaign")) {
 254                         //JoinBestTeam(self, 0);
 255                 } else if(lockteams) {
 256                         sprint( self, "^7The game has already begun, you must wait until the next map to be able to join a team.\n");
 257                 } else if( argv(1) == "red" ) {
 258                         DoTeamChange(COLOR_TEAM1);
 259                 } else if( argv(1) == "blue" ) {
 260                         DoTeamChange(COLOR_TEAM2);
 261                 } else if( argv(1) == "yellow" ) {
 262                         DoTeamChange(COLOR_TEAM3);
 263                 } else if( argv(1) == "pink" ) {
 264                         DoTeamChange(COLOR_TEAM4);
 265                 } else if( argv(1) == "auto" ) {
 266                         DoTeamChange(-1);
 267                 } else {
 268                         sprint( self, strcat( "selectteam none/red/blue/yellow/pink/auto - \"", argv(1), "\" not recognised\n" ) );
 269                 }
 270         } else if(cmd == "ready") {
 271                 if not(self.flags & FL_CLIENT)
 272                         return;
 273
 274                 if((inWarmupStage && 0 >= g_warmup_limit) // with unlimited warmup players have to be able to restart
 275                    || cvar("sv_ready_restart") || g_race_qualifying == 2)
 276                 {
 277                         if(!readyrestart_happened || cvar("sv_ready_restart_repeatable"))
 278                         {
 279                                 if (self.ready) // toggle
 280                                 {
 281                                         self.ready = FALSE;
 282                                         bprint(self.netname, "^2 is ^1NOT^2 ready\n");
 283                                 }
 284                                 else
 285                                 {
 286                                         self.ready = TRUE;
 287                                         bprint(self.netname, "^2 is ready\n");
 288                                 }
 289
 290                                 // cannot reset the game while a timeout is active!
 291                                 if(!timeoutStatus)
 292                                         ReadyCount();
 293                         } else {
 294                                 sprint(self, "^1Game has already been restarted\n");
 295                         }
 296                 }
 297         } else if(cmd == "maplist") {
 298                 sprint(self, maplist_reply);
 299         } else if(cmd == "lsmaps") {
 300                 sprint(self, lsmaps_reply);
 301         } else if(cmd == "lsnewmaps") {
 302                 sprint(self, lsnewmaps_reply);
 303         } else if(cmd == "records") {
 304                 for(i = 0; i < 10; ++i)
 305                         sprint(self, records_reply[i]);
 306         } else if(cmd == "rankings") {
 307                 sprint(self, rankings_reply);
 308         } else if(cmd == "voice") {
 309                 if(tokens >= 3)
 310                         VoiceMessage(argv(1), substring(s, argv_start_index(2), argv_end_index(-1) - argv_start_index(2)));
 311                 else
 312                         VoiceMessage(argv(1), "");
 313         } else if(cmd == "say") {
 314                 if(tokens >= 2)
 315                         Say(self, FALSE, world, substring(s, argv_start_index(1), argv_end_index(-1) - argv_start_index(1)), 1);
 316                 //clientcommand(self, formatmessage(s));
 317         } else if(cmd == "say_team") {
 318                 if(tokens >= 2)
 319                         Say(self, TRUE, world, substring(s, argv_start_index(1), argv_end_index(-1) - argv_start_index(1)), 1);
 320                 //clientcommand(self, formatmessage(s));
 321         } else if(cmd == "tell") {
 322                 e = GetCommandPlayerSlotTargetFromTokenizedCommand(tokens, 1);
 323                 if(e && tokens > ParseCommandPlayerSlotTarget_firsttoken)
 324                 {
 325                         Say(self, FALSE, e, substring(s, argv_start_index(ParseCommandPlayerSlotTarget_firsttoken), argv_end_index(-1) - argv_start_index(ParseCommandPlayerSlotTarget_firsttoken)), TRUE);
 326                 }
 327                 else
 328                 {
 329                         if(tokens > ParseCommandPlayerSlotTarget_firsttoken)
 330                                 trigger_magicear_processmessage_forallears(self, -1, world, substring(s, argv_start_index(ParseCommandPlayerSlotTarget_firsttoken), argv_end_index(-1) - argv_start_index(ParseCommandPlayerSlotTarget_firsttoken)));
 331                         sprint(self, "ERROR: usage: tell # playerid text...\n");
 332                 }
 333                 //clientcommand(self, formatmessage(s));
 334         } else if(cmd == "info") {
 335                 cmd = cvar_string_builtin(strcat("sv_info_", argv(1))); // This needed fixed for the cvar check
 336                 if(cmd == "")
 337                         sprint(self, "ERROR: unsupported info command\n");
 338                 else
 339                         wordwrap_sprint(cmd, 1111);
 340         } else if(cmd == "suggestmap") {
 341                 sprint(self, strcat(MapVote_Suggest(argv(1)), "\n"));
 342         } else if(cmd == "timeout") {
 343                 if not(self.flags & FL_CLIENT)
 344                         return;
 345                 if(cvar("sv_timeout")) {
 346                         if(self.classname == "player") {
 347                                 if(votecalled)
 348                                         sprint(self, "^7Error: you can not call a timeout while a vote is active!\n");
 349                                 else
 350                                         evaluateTimeout();
 351                         }
 352                         else
 353                                 sprint(self, "^7Error: only players can call a timeout!\n");
 354                 }
 355         } else if(cmd == "timein") {
 356                 if not(self.flags & FL_CLIENT)
 357                         return;
 358                 if(cvar("sv_timeout")) {
 359                         evaluateTimein();
 360                 }
 361         } else if(cmd == "teamstatus") {
 362                 Score_NicePrint(self);
 363         } else if(cmd == "cvar_changes") {
 364                 sprint(self, cvar_changes);
 365         } else if(cmd == "cvar_purechanges") {
 366                 sprint(self, cvar_purechanges);
 367         } else if(CheatCommand(tokens)) {
 368         } else {
 369                 //if(ctf_clientcommand())
 370                 //      return;
 371                 // grep for Cmd_AddCommand_WithClientCommand to find them all
 372                 if(cmd != "status")
 373                 //if(cmd != "say") // handled above
 374                 //if(cmd != "say_team") // handled above
 375                 if(cmd != "kill")
 376                 if(cmd != "pause")
 377                 if(cmd != "ping")
 378                 if(cmd != "name")
 379                 if(cmd != "color")
 380                 if(cmd != "rate")
 381                 if(cmd != "pmodel")
 382                 if(cmd != "playermodel")
 383                 if(cmd != "playerskin")
 384                 if(cmd != "prespawn")
 385                 if(cmd != "spawn")
 386                 if(cmd != "begin")
 387                 if(cmd != "pings")
 388                 if(cmd != "sv_startdownload")
 389                 if(cmd != "download")
 390                 {
 391                         print("WARNING: Invalid clientcommand by ", self.netname, ": ", s, "\n");
 392                         return;
 393                 }
 394
 395                 if(self.jointime > 0 && time > self.jointime + 10 && time > self.nickspamtime) // allow any changes in the first 10 seconds since joining
 396                 if(cmd == "name" || cmd == "playermodel") // TODO also playerskin and color?
 397                 {
 398                         if(self.nickspamtime == 0 || time > self.nickspamtime + cvar("g_nick_flood_timeout"))
 399                                 // good, no serious flood
 400                                 self.nickspamcount = 1;
 401                         else
 402                                 self.nickspamcount += 1;
 403                         self.nickspamtime = time + cvar("g_nick_flood_penalty");
 404
 405                         if (timeoutStatus == 2) //when game is paused, no flood protection
 406                                 self.nickspamcount = self.nickspamtime = 0;
 407                 }
 408
 409                 clientcommand(self,s);
 410         }
 411 }
 412
 413 void ReadyRestartForce()
 414 {
 415         local entity e;
 416
 417         bprint("^1Server is restarting...\n");
 418
 419         VoteReset();
 420
 421         // clear overtime
 422         if (checkrules_overtimesadded > 0 && g_race_qualifying != 2) {
 423                 //we have to decrease timelimit to its original value again!!
 424                 float newTL;
 425                 newTL = cvar("timelimit");
 426                 newTL -= checkrules_overtimesadded * cvar("timelimit_overtime");
 427                 cvar_set("timelimit", ftos(newTL));
 428         }
 429
 430         checkrules_suddendeathend = checkrules_overtimesadded = checkrules_suddendeathwarning = 0;
 431
 432
 433         readyrestart_happened = 1;
 434         game_starttime = time;
 435         if(!g_ca && !g_arena)
 436                 game_starttime += RESTART_COUNTDOWN;
 437         restart_mapalreadyrestarted = 0; //reset this var, needed when cvar sv_ready_restart_repeatable is in use
 438
 439         inWarmupStage = 0; //once the game is restarted the game is in match stage
 440
 441         //reset the .ready status of all players (also spectators)
 442         FOR_EACH_CLIENTSLOT(e)
 443                 e.ready = 0;
 444         readycount = 0;
 445         Nagger_ReadyCounted(); // NOTE: this causes a resend of that entity, and will also turn off warmup state on the client
 446
 447         if(cvar("teamplay_lockonrestart") && teams_matter) {
 448                 lockteams = 1;
 449                 bprint("^1The teams are now locked.\n");
 450         }
 451
 452         //initiate the restart-countdown-announcer entity
 453         if(cvar("sv_ready_restart_after_countdown") && !g_ca && !g_arena)
 454         {
 455                 restartTimer = spawn();
 456                 restartTimer.think = restartTimer_Think;
 457                 restartTimer.nextthink = game_starttime;
 458         }
 459
 460         //after a restart every players number of allowed timeouts gets reset, too
 461         if(cvar("sv_timeout"))
 462         {
 463                 FOR_EACH_REALPLAYER(e)
 464                         e.allowedTimeouts = cvar("sv_timeout_number");
 465         }
 466
 467         //reset map immediately if this cvar is not set
 468         if (!cvar("sv_ready_restart_after_countdown"))
 469                 reset_map(TRUE);
 470
 471         if(cvar("sv_eventlog"))
 472                 GameLogEcho(":restart");
 473 }
 474
 475 void ReadyRestart()
 476 {
 477         // no arena, assault support yet...
 478         if(g_arena | g_assault | gameover | intermission_running | race_completing)
 479                 localcmd("restart\n");
 480         else
 481                 localcmd("\nsv_hook_gamerestart\n");
 482
 483         ReadyRestartForce();
 484
 485         // reset ALL scores, but only do that at the beginning
 486         //of the countdown if sv_ready_restart_after_countdown is off!
 487         //Otherwise scores could be manipulated during the countdown!
 488         if (!cvar("sv_ready_restart_after_countdown"))
 489                 Score_ClearAll();
 490 }
 491
 492 /**
 493  * Counts how many players are ready. If not enough players are ready, the function
 494  * does nothing. If all players are ready, the timelimit will be extended and the
 495  * restart_countdown variable is set to allow other functions like PlayerPostThink
 496  * to detect that the countdown is now active. If the cvar sv_ready_restart_after_countdown
 497  * is not set the map will be resetted.
 498  *
 499  * Function is called after the server receives a 'ready' sign from a player.
 500  */
 501 void ReadyCount()
 502 {
 503         local entity e;
 504         local float r, p;
 505
 506         r = p = 0;
 507
 508         FOR_EACH_REALPLAYER(e)
 509         {
 510                 p += 1;
 511                 if(e.ready)
 512                         r += 1;
 513         }
 514
 515         readycount = r;
 516
 517         Nagger_ReadyCounted();
 518
 519         if(r) // at least one is ready
 520         if(r == p) // and, everyone is ready
 521                 ReadyRestart();
 522 }
 523
 524 /**
 525  * Restarts the map after the countdown is over (and cvar sv_ready_restart_after_countdown
 526  * is set)
 527  */
 528 void restartTimer_Think() {
 529         restart_mapalreadyrestarted = 1;
 530         reset_map(TRUE);
 531         Score_ClearAll();
 532         remove(self);
 533         return;
 534 }
 535
 536 /**
 537  * Checks whether the player who calls the timeout is allowed to do so.
 538  * If so, it initializes the timeout countdown. It also checks whether another
 539  * timeout was already running at this time and reacts correspondingly.
 540  *
 541  * affected globals/fields: .allowedTimeouts, remainingTimeoutTime, remainingLeadTime,
 542  *                          timeoutInitiator, timeoutStatus, timeoutHandler
 543  *
 544  * This function is called when a player issues the calltimeout command.
 545  */
 546 void evaluateTimeout() {
 547         if (inWarmupStage && !g_warmup_allow_timeout)
 548                 return sprint(self, "^7Error: You can not call a timeout in warmup-stage!\n");
 549         if (time < game_starttime )
 550                 return sprint(self, "^7Error: You can not call a timeout while the map is being restarted!\n");
 551         if (timeoutStatus != 2) {
 552                 //if the map uses a timelimit make sure that timeout cannot be called right before the map ends
 553                 if (cvar("timelimit")) {
 554                         //a timelimit was used
 555                         local float myTl;
 556                         myTl = cvar("timelimit");
 557
 558                         local float lastPossibleTimeout;
 559                         lastPossibleTimeout = (myTl*60) - cvar("sv_timeout_leadtime") - 1;
 560
 561                         if (lastPossibleTimeout < time - game_starttime)
 562                                 return sprint(self, "^7Error: It is too late to call a timeout now!\n");
 563                 }
 564         }
 565         //player may not call a timeout if he has no calls left
 566         if (self.allowedTimeouts < 1)
 567                 return sprint(self, "^7Error: You already used all your timeout calls for this map!\n");
 568         //now all required checks are passed
 569         self.allowedTimeouts -= 1;
 570         bprint(self.netname, " ^7called a timeout (", ftos(self.allowedTimeouts), " timeouts left)!\n"); //write a bprint who started the timeout (and how many he has left)
 571         remainingTimeoutTime = cvar("sv_timeout_length");
 572         remainingLeadTime = cvar("sv_timeout_leadtime");
 573         timeoutInitiator = self;
 574         if (timeoutStatus == 0) { //if another timeout was already active, don't change its status (which was 1 or 2) to 1, only change it to 1 if no timeout was active yet
 575                 timeoutStatus = 1;
 576                 //create the timeout indicator which centerprints the information to all players and takes care of pausing/unpausing
 577                 timeoutHandler = spawn();
 578                 timeoutHandler.think = timeoutHandler_Think;
 579         }
 580         timeoutHandler.nextthink = time; //always let the entity think asap
 581
 582         //inform all connected clients about the timeout call
 583         Announce("timeoutcalled");
 584 }
 585
 586 /**
 587  * Checks whether a player is allowed to resume the game. If he is allowed to do it,
 588  * and the lead time for the timeout is still active, this countdown just will be aborted (the
 589  * game will never be paused). Otherwise the remainingTimeoutTime will be set to the corresponding
 590  * value of the cvar sv_timeout_resumetime.
 591  *
 592  * This function is called when a player issues the resumegame command.
 593  */
 594 void evaluateTimein() {
 595         if (!timeoutStatus)
 596                 return sprint(self, "^7Error: There is no active timeout which could be aborted!\n");
 597         if (self != timeoutInitiator)
 598                 return sprint(self, "^7Error: You may not abort the active timeout. Only the player who called it can do that!\n");
 599         if (timeoutStatus == 1) {
 600                 remainingTimeoutTime = timeoutStatus = 0;
 601                 timeoutHandler.nextthink = time; //timeoutHandler has to take care of it immediately
 602                 bprint(strcat("^7The timeout was aborted by ", self.netname, " !\n"));
 603         }
 604         else if (timeoutStatus == 2) {
 605                 //only shorten the remainingTimeoutTime if it makes sense
 606                 if( remainingTimeoutTime > (cvar("sv_timeout_resumetime") + 1) ) {
 607                         bprint(strcat("^1Attention: ^7", self.netname, " resumed the game! Prepare for battle!\n"));
 608                         remainingTimeoutTime = cvar("sv_timeout_resumetime");
 609                         timeoutHandler.nextthink = time; //timeoutHandler has to take care of it immediately
 610                 }
 611                 else
 612                         sprint(self, "^7Error: Your resumegame call was discarded!\n");
 613
 614         }
 615 }