qcsrc/server/command/banning.qc

   1 // =====================================================
   2 //  Banning and kicking command code, written by Samual
   3 //  Last updated: December 29th, 2011
   4 // =====================================================
   5
   6 void BanCommand_ban(float request, float argc, string command)
   7 {
   8         switch(request)
   9         {
  10                 case CMD_REQUEST_COMMAND:
  11                 {
  12                         if(argc >= 2)
  13                         {
  14                                 string ip = argv(1);
  15                                 float reason_arg, bantime;
  16                                 string reason;
  17
  18                                 reason_arg = 2;
  19
  20                                 GET_BAN_ARG(bantime, autocvar_g_ban_default_bantime);
  21                                 GET_BAN_REASON(reason, "No reason provided");
  22
  23                                 Ban_Insert(ip, bantime, reason, 1);
  24                                 return;
  25                         }
  26                 }
  27
  28                 default:
  29                         print("Incorrect parameters for ^2ban^7\n");
  30                 case CMD_REQUEST_USAGE:
  31                 {
  32                         print("\nUsage:^3 sv_cmd ban address [bantime] [reason]\n");
  33                         print("  'address' is the IP address or range of the player to ban,\n");
  34                         print("  'bantime' is the amount of time that the ban is active (default if not provided),\n");
  35                         print("  and 'reason' is the string to label the ban with as reason for banning.\n");
  36                         print("See also: ^2banlist, kickban, unban^7\n");
  37                         return;
  38                 }
  39         }
  40 }
  41
  42 void BanCommand_banlist(float request)
  43 {
  44         switch(request)
  45         {
  46                 case CMD_REQUEST_COMMAND:
  47                 {
  48                         Ban_View();
  49                         return;
  50                 }
  51
  52                 default:
  53                 case CMD_REQUEST_USAGE:
  54                 {
  55                         print("\nUsage:^3 sv_cmd banlist\n");
  56                         print("  No arguments required.\n");
  57                         print("See also: ^2ban, kickban, unban^7\n");
  58                         return;
  59                 }
  60         }
  61 }
  62
  63 void BanCommand_kickban(float request, float argc, string command)
  64 {
  65         switch(request)
  66         {
  67                 case CMD_REQUEST_COMMAND:
  68                 {
  69                         if(argc >= 2)
  70                         {
  71                                 entity client = GetIndexedEntity(argc, 1);
  72                                 float accepted = VerifyClientEntity(client, TRUE, FALSE);
  73                                 float reason_arg, bantime, masksize;
  74                                 string reason;
  75
  76                                 if(accepted > 0)
  77                                 {
  78                                         reason_arg = next_token;
  79
  80                                         GET_BAN_ARG(bantime, autocvar_g_ban_default_bantime);
  81                                         GET_BAN_ARG(masksize, autocvar_g_ban_default_masksize);
  82                                         GET_BAN_REASON(reason, "No reason provided");
  83
  84                                         Ban_KickBanClient(client, bantime, masksize, reason);
  85
  86                                         return;
  87                                 }
  88                                 else
  89                                 {
  90                                         print("kickban: ", GetClientErrorString(accepted, argv(1)), ".\n");
  91                                 }
  92                         }
  93                 }
  94
  95                 default:
  96                         print("Incorrect parameters for ^2kickban^7\n");
  97                 case CMD_REQUEST_USAGE:
  98                 {
  99                         print("\nUsage:^3 sv_cmd kickban client [bantime] [masksize] [reason]\n");
 100                         print("  'client' is the entity number or name of the player to ban,\n");
 101                         print("  'bantime' is the amount of time that the ban is active (default if not provided),\n");
 102                         print("  'masksize' is the range of the IP address (1-thru-4, default if not provided),\n");
 103                         print("  and 'reason' is the string to label the ban with as reason for banning.\n");
 104                         print("See also: ^2ban, banlist, unban^7\n");
 105                         return;
 106                 }
 107         }
 108 }
 109
 110 void BanCommand_unban(float request, float argc)
 111 {
 112         switch(request)
 113         {
 114                 case CMD_REQUEST_COMMAND:
 115                 {
 116                         if(argv(1))
 117                         {
 118                                 float tmp_number = -1;
 119                                 string tmp_string;
 120
 121                                 if(substring(argv(1), 0, 1) == "#")
 122                                 {
 123                                         tmp_string = substring(argv(1), 1, -1);
 124
 125                                         if(tmp_string != "") // is it all one token? like #1
 126                                         {
 127                                                 tmp_number = stof(tmp_string);
 128                                         }
 129                                         else if(argc > 2) // no, it's two tokens? # 1
 130                                         {
 131                                                 tmp_number = stof(argv(2));
 132                                         }
 133                                         else
 134                                                 tmp_number = -1;
 135                                 }
 136                                 else // maybe it's ONLY a number?
 137                                 {
 138                                         tmp_number = stof(argv(1));
 139
 140                                         if((tmp_number == 0) && (argv(1) != "0"))
 141                                                 { tmp_number = -1; }
 142                                 }
 143
 144                                 if(tmp_number >= 0)
 145                                 {
 146                                         Ban_Delete(tmp_number);
 147                                         return;
 148                                 }
 149                         }
 150                 }
 151
 152                 default:
 153                 case CMD_REQUEST_USAGE:
 154                 {
 155                         print("\nUsage:^3 sv_cmd unban banid\n");
 156                         print("  Where 'banid' is the ID of the ban of which to remove.\n");
 157                         print("See also: ^2ban, banlist, kickban^7\n");
 158                         return;
 159                 }
 160         }
 161 }
 162
 163 /* use this when creating a new command, making sure to place it in alphabetical order... also,
 164 ** ADD ALL NEW COMMANDS TO commands.cfg WITH PROPER ALIASES IN THE SAME FASHION!
 165 void BanCommand_(float request)
 166 {
 167         switch(request)
 168         {
 169                 case CMD_REQUEST_COMMAND:
 170                 {
 171
 172                         return;
 173                 }
 174
 175                 default:
 176                 case CMD_REQUEST_USAGE:
 177                 {
 178                         print("\nUsage:^3 sv_cmd \n");
 179                         print("  No arguments required.\n");
 180                         return;
 181                 }
 182         }
 183 }
 184 */
 185
 186
 187 // ==================================
 188 //  Macro system for server commands
 189 // ==================================
 190
 191 // Do not hard code aliases for these, instead create them in commands.cfg... also: keep in alphabetical order, please ;)
 192 // but for 0.5 compat, we need "bans" here as it was replaced... REMOVE IT AFTER 0.6 RELEASE!!!!
 193 #define BAN_COMMANDS(request,arguments,command) \
 194         BAN_COMMAND("ban", BanCommand_ban(request, arguments, command), "Ban an IP address or a range of addresses (like 1.2.3)") \
 195         BAN_COMMAND("banlist", BanCommand_banlist(request), "List all existing bans") \
 196         BAN_COMMAND("bans", BanCommand_banlist(request), "") \
 197         BAN_COMMAND("kickban", BanCommand_kickban(request, arguments, command), "Disconnect a client and ban it at the same time") \
 198         BAN_COMMAND("unban", BanCommand_unban(request, arguments), "Remove an existing ban") \
 199         /* nothing */
 200
 201 void BanCommand_macro_help()
 202 {
 203         #define BAN_COMMAND(name,function,description) \
 204                 { if(strtolower(description) != "") { print("  ^2", name, "^7: ", description, "\n"); } }
 205
 206         BAN_COMMANDS(0, 0, "")
 207         #undef BAN_COMMAND
 208
 209         return;
 210 }
 211
 212 float BanCommand_macro_command(float argc, string command)
 213 {
 214         #define BAN_COMMAND(name,function,description) \
 215                 { if(name == strtolower(argv(0))) { function; return TRUE; } }
 216
 217         BAN_COMMANDS(CMD_REQUEST_COMMAND, argc, command)
 218         #undef BAN_COMMAND
 219
 220         return FALSE;
 221 }
 222
 223 float BanCommand_macro_usage(float argc)
 224 {
 225         #define BAN_COMMAND(name,function,description) \
 226                 { if(name == strtolower(argv(1))) { function; return TRUE; } }
 227
 228         BAN_COMMANDS(CMD_REQUEST_USAGE, argc, "")
 229         #undef BAN_COMMAND
 230
 231         return FALSE;
 232 }
 233
 234 void BanCommand_macro_write_aliases(float fh)
 235 {
 236         #define BAN_COMMAND(name,function,description) \
 237                 { if(strtolower(description) != "") { CMD_Write_Alias("qc_cmd_sv", name, description); } }
 238
 239         BAN_COMMANDS(0, 0, "")
 240         #undef BAN_COMMAND
 241
 242         return;
 243 }
 244
 245 float BanCommand(string command)
 246 {
 247         float argc = tokenize_console(command);
 248
 249         // Guide for working with argc arguments by example:
 250         // argc:   1    - 2      - 3     - 4
 251         // argv:   0    - 1      - 2     - 3
 252         // cmd     vote - master - login - password
 253
 254         if(BanCommand_macro_command(argc, command)) // continue as usual and scan for normal commands
 255         {
 256                 return TRUE; // handled by one of the above GenericCommand_* functions
 257         }
 258
 259         return FALSE;
 260 }