qcsrc/server/command/cmd.qc

   1 #include "../../common/command/command.qh"
   2 #include "cmd.qh"
   3 #include "../_.qh"
   4
   5 #include "common.qh"
   6 #include "vote.qh"
   7
   8 #include "../campaign.qh"
   9 #include "../cheats.qh"
  10 #include "../cl_player.qh"
  11 #include "../g_triggers.qh"
  12 #include "../ipban.qh"
  13 #include "../mapvoting.qh"
  14 #include "../scores.qh"
  15 #include "../teamplay.qh"
  16
  17 #include "../mutators/mutators_include.qh"
  18
  19 #include "../vehicles/vehicles_def.qh"
  20
  21 #include "../../common/constants.qh"
  22 #include "../../common/deathtypes.qh"
  23 #include "../../common/mapinfo.qh"
  24 #include "../../common/notifications.qh"
  25 #include "../../common/teams.qh"
  26 #include "../../common/util.qh"
  27
  28 #include "../../common/monsters/monsters.qh"
  29 #include "../../common/monsters/spawn.qh"
  30 #include "../../common/monsters/sv_monsters.qh"
  31
  32 #include "../../warpzonelib/common.qh"
  33
  34 void ClientKill_TeamChange (float targetteam); // 0 = don't change, -1 = auto, -2 = spec
  35
  36 // =========================================================
  37 //  Server side networked commands code, reworked by Samual
  38 //  Last updated: December 28th, 2011
  39 // =========================================================
  40
  41 float SV_ParseClientCommand_floodcheck()
  42 {
  43         if (!timeout_status) // not while paused
  44         {
  45                 if(time <= (self.cmd_floodtime + autocvar_sv_clientcommand_antispam_time))
  46                 {
  47                         self.cmd_floodcount += 1;
  48                         if(self.cmd_floodcount > autocvar_sv_clientcommand_antispam_count) { return false; } // too much spam, halt
  49                 }
  50                 else
  51                 {
  52                         self.cmd_floodtime = time;
  53                         self.cmd_floodcount = 1;
  54                 }
  55         }
  56         return true; // continue, as we're not flooding yet
  57 }
  58
  59
  60 // =======================
  61 //  Command Sub-Functions
  62 // =======================
  63
  64 void ClientCommand_autoswitch(float request, float argc)
  65 {
  66         switch(request)
  67         {
  68                 case CMD_REQUEST_COMMAND:
  69                 {
  70                         if(argv(1) != "")
  71                         {
  72                                 self.autoswitch = InterpretBoolean(argv(1));
  73                                 sprint(self, strcat("^1autoswitch is currently turned ", (self.autoswitch ? "on" : "off"), ".\n"));
  74                                 return;
  75                         }
  76                 }
  77
  78                 default:
  79                         sprint(self, "Incorrect parameters for ^2autoswitch^7\n");
  80                 case CMD_REQUEST_USAGE:
  81                 {
  82                         sprint(self, "\nUsage:^3 cmd autoswitch selection\n");
  83                         sprint(self, "  Where 'selection' controls if autoswitch is on or off.\n");
  84                         return;
  85                 }
  86         }
  87 }
  88
  89 void ClientCommand_checkfail(float request, string command) // internal command, used only by code
  90 {
  91         switch(request)
  92         {
  93                 case CMD_REQUEST_COMMAND:
  94                 {
  95                         printf("CHECKFAIL: %s (%s) epically failed check %s\n", self.netname, self.netaddress, substring(command, argv_start_index(1), argv_end_index(-1) - argv_start_index(1)));
  96                         self.checkfail = 1;
  97                         return; // never fall through to usage
  98                 }
  99
 100                 default:
 101                         sprint(self, "Incorrect parameters for ^2checkfail^7\n");
 102                 case CMD_REQUEST_USAGE:
 103                 {
 104                         sprint(self, "\nUsage:^3 cmd checkfail <message>\n");
 105                         sprint(self, "  Where 'message' is the message reported by client about the fail.\n");
 106                         return;
 107                 }
 108         }
 109 }
 110
 111 void ClientCommand_clientversion(float request, float argc) // internal command, used only by code
 112 {
 113         switch(request)
 114         {
 115                 case CMD_REQUEST_COMMAND:
 116                 {
 117                         if(argv(1) != "")
 118                         {
 119                                 if(IS_CLIENT(self))
 120                                 {
 121                                         self.version = ((argv(1) == "$gameversion") ? 1 : stof(argv(1)));
 122
 123                                         if(self.version < autocvar_gameversion_min || self.version > autocvar_gameversion_max)
 124                                         {
 125                                                 self.version_mismatch = 1;
 126                                                 ClientKill_TeamChange(-2); // observe
 127                                         }
 128                                         else if(autocvar_g_campaign || autocvar_g_balance_teams)
 129                                         {
 130                                                 //JoinBestTeam(self, false, true);
 131                                         }
 132                                         else if(teamplay && !autocvar_sv_spectate && !(self.team_forced > 0))
 133                                         {
 134                                                 self.classname = "observer"; // really?
 135                                                 stuffcmd(self, "menu_showteamselect\n");
 136                                         }
 137                                 }
 138
 139                                 return;
 140                         }
 141                 }
 142
 143                 default:
 144                         sprint(self, "Incorrect parameters for ^2clientversion^7\n");
 145                 case CMD_REQUEST_USAGE:
 146                 {
 147                         sprint(self, "\nUsage:^3 cmd clientversion version\n");
 148                         sprint(self, "  Where 'version' is the game version reported by self.\n");
 149                         return;
 150                 }
 151         }
 152 }
 153
 154 void ClientCommand_mv_getpicture(float request, float argc) // internal command, used only by code
 155 {
 156         switch(request)
 157         {
 158                 case CMD_REQUEST_COMMAND:
 159                 {
 160                         if(argv(1) != "")
 161                         {
 162                                 if(intermission_running)
 163                                         MapVote_SendPicture(stof(argv(1)));
 164
 165                                 return;
 166                         }
 167                 }
 168
 169                 default:
 170                         sprint(self, "Incorrect parameters for ^2mv_getpicture^7\n");
 171                 case CMD_REQUEST_USAGE:
 172                 {
 173                         sprint(self, "\nUsage:^3 cmd mv_getpicture mapid\n");
 174                         sprint(self, "  Where 'mapid' is the id number of the map to request an image of on the map vote selection menu.\n");
 175                         return;
 176                 }
 177         }
 178 }
 179
 180 void ClientCommand_join(float request)
 181 {
 182         switch(request)
 183         {
 184                 case CMD_REQUEST_COMMAND:
 185                 {
 186                         if(IS_CLIENT(self))
 187                         {
 188                                 if(!IS_PLAYER(self) && !lockteams && !gameover)
 189                                 {
 190                                         if(self.caplayer)
 191                                                 return;
 192                                         if(nJoinAllowed(self))
 193                                         {
 194                                                 if(autocvar_g_campaign) { campaign_bots_may_start = 1; }
 195
 196                                                 self.classname = "player";
 197                                                 PlayerScore_Clear(self);
 198                                                 Kill_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER_CPID, CPID_PREVENT_JOIN);
 199                                                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_JOIN_PLAY, self.netname);
 200                                                 PutClientInServer();
 201                                         }
 202                                         else
 203                                         {
 204                                                 //player may not join because of g_maxplayers is set
 205                                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_JOIN_PREVENT);
 206                                         }
 207                                 }
 208                         }
 209                         return; // never fall through to usage
 210                 }
 211
 212                 default:
 213                 case CMD_REQUEST_USAGE:
 214                 {
 215                         sprint(self, "\nUsage:^3 cmd join\n");
 216                         sprint(self, "  No arguments required.\n");
 217                         return;
 218                 }
 219         }
 220 }
 221
 222 void ClientCommand_mobedit(float request, float argc)
 223 {
 224         switch(request)
 225         {
 226                 case CMD_REQUEST_COMMAND:
 227                 {
 228                         if(argv(1) && argv(2))
 229                         {
 230                                 makevectors(self.v_angle);
 231                                 WarpZone_TraceLine(self.origin + self.view_ofs, self.origin + self.view_ofs + v_forward * 100, MOVE_NORMAL, self);
 232
 233                                 if(!autocvar_g_monsters_edit) { sprint(self, "Monster property editing is not enabled.\n"); return; }
 234                                 if(trace_ent.flags & FL_MONSTER)
 235                                 {
 236                                         if(trace_ent.realowner != self) { sprint(self, "That monster does not belong to you.\n"); return; }
 237                                         switch(argv(1))
 238                                         {
 239                                                 case "skin":
 240                                                 {
 241                                                         if(trace_ent.monsterid != MON_MAGE)
 242                                                                 trace_ent.skin = stof(argv(2));
 243                                                         return;
 244                                                 }
 245                                                 case "movetarget":
 246                                                 {
 247                                                         trace_ent.monster_moveflags = stof(argv(2));
 248                                                         return;
 249                                                 }
 250                                         }
 251                                 }
 252                         }
 253                 }
 254                 default:
 255                         sprint(self, "Incorrect parameters for ^2mobedit^7\n");
 256                 case CMD_REQUEST_USAGE:
 257                 {
 258                         sprint(self, "\nUsage:^3 cmd mobedit [argument]\n");
 259                         sprint(self, "  Where 'argument' can be skin or movetarget.\n");
 260                         sprint(self, "  Aim at your monster to edit its properties.\n");
 261                         return;
 262                 }
 263         }
 264 }
 265
 266 void ClientCommand_mobkill(float request)
 267 {
 268         switch(request)
 269         {
 270                 case CMD_REQUEST_COMMAND:
 271                 {
 272                         makevectors(self.v_angle);
 273                         WarpZone_TraceLine(self.origin + self.view_ofs, self.origin + self.view_ofs + v_forward * 100, MOVE_NORMAL, self);
 274
 275                         if(trace_ent.flags & FL_MONSTER)
 276                         {
 277                                 if(trace_ent.realowner != self)
 278                                 {
 279                                         sprint(self, "That monster does not belong to you.\n");
 280                                         return;
 281                                 }
 282                                 sprint(self, strcat("Your pet '", trace_ent.monster_name, "' has been brutally mutilated.\n"));
 283                                 Damage (trace_ent, world, world, trace_ent.health + trace_ent.max_health + 200, DEATH_KILL, trace_ent.origin, '0 0 0');
 284                                 return;
 285                         }
 286                 }
 287
 288                 default:
 289                         sprint(self, "Incorrect parameters for ^2mobkill^7\n");
 290                 case CMD_REQUEST_USAGE:
 291                 {
 292                         sprint(self, "\nUsage:^3 cmd mobkill\n");
 293                         sprint(self, "  Aim at your monster to kill it.\n");
 294                         return;
 295                 }
 296         }
 297 }
 298
 299 void ClientCommand_mobspawn(float request, float argc)
 300 {
 301         switch(request)
 302         {
 303                 case CMD_REQUEST_COMMAND:
 304                 {
 305                         entity e;
 306                         string tospawn;
 307                         float moveflag, monstercount = 0;
 308
 309                         moveflag = (argv(2) ? stof(argv(2)) : 1); // follow owner if not defined
 310                         tospawn = strtolower(argv(1));
 311
 312                         if(tospawn == "list")
 313                         {
 314                                 sprint(self, monsterlist_reply);
 315                                 return;
 316                         }
 317
 318                         FOR_EACH_MONSTER(e)
 319                         {
 320                                 if(e.realowner == self)
 321                                         ++monstercount;
 322                         }
 323
 324                         if(autocvar_g_monsters_max <= 0 || autocvar_g_monsters_max_perplayer <= 0) { sprint(self, "Monster spawning is disabled.\n"); return; }
 325                         else if(!IS_PLAYER(self)) { sprint(self, "You can't spawn monsters while spectating.\n"); return; }
 326                         else if(MUTATOR_CALLHOOK(AllowMobSpawning)) { sprint(self, "Monster spawning is currently disabled by a mutator.\n"); return; }
 327                         else if(!autocvar_g_monsters) { Send_Notification(NOTIF_ONE, self, MSG_INFO, INFO_MONSTERS_DISABLED); return; }
 328                         else if(self.vehicle) { sprint(self, "You can't spawn monsters while driving a vehicle.\n"); return; }
 329                         else if(self.frozen) { sprint(self, "You can't spawn monsters while frozen.\n"); return; }
 330                         else if(autocvar_g_campaign) { sprint(self, "You can't spawn monsters in campaign mode.\n"); return; }
 331                         else if(self.deadflag != DEAD_NO) { sprint(self, "You can't spawn monsters while dead.\n"); return; }
 332                         else if(monstercount >= autocvar_g_monsters_max_perplayer) { sprint(self, "You have spawned too many monsters, kill some before trying to spawn any more.\n"); return; }
 333                         else if(totalspawned >= autocvar_g_monsters_max) { sprint(self, "The global maximum monster count has been reached, kill some before trying to spawn any more.\n"); return; }
 334                         else if(tospawn != "")
 335                         {
 336                                 float found = 0, i;
 337                                 entity mon;
 338
 339                                 for(i = MON_FIRST; i <= MON_LAST; ++i)
 340                                 {
 341                                         mon = get_monsterinfo(i);
 342                                         if(mon.netname == tospawn)
 343                                         {
 344                                                 found = true;
 345                                                 break;
 346                                         }
 347                                 }
 348
 349                                 if(found || tospawn == "random")
 350                                 {
 351                                         totalspawned += 1;
 352
 353                                         makevectors(self.v_angle);
 354                                         WarpZone_TraceBox (CENTER_OR_VIEWOFS(self), PL_MIN, PL_MAX, CENTER_OR_VIEWOFS(self) + v_forward * 150, true, self);
 355                                         //WarpZone_TraceLine(self.origin + self.view_ofs, self.origin + self.view_ofs + v_forward * 150, MOVE_NORMAL, self);
 356
 357                                         e = spawnmonster(tospawn, 0, self, self, trace_endpos, false, false, moveflag);
 358
 359                                         sprint(self, strcat("Spawned ", e.monster_name, "\n"));
 360
 361                                         return;
 362                                 }
 363                         }
 364                 }
 365
 366                 default:
 367                         sprint(self, "Incorrect parameters for ^2mobspawn^7\n");
 368                 case CMD_REQUEST_USAGE:
 369                 {
 370                         sprint(self, "\nUsage:^3 cmd mobspawn <random> <monster> [movetype]\n");
 371                         sprint(self, "  See 'cmd mobspawn list' for available monsters.\n");
 372                         sprint(self, "  Argument 'random' spawns a random monster.\n");
 373                         sprint(self, "  Monster will follow the owner if second argument is not defined.\n");
 374                         return;
 375                 }
 376         }
 377 }
 378
 379 void ClientCommand_ready(float request) // todo: anti-spam for toggling readyness
 380 {
 381         switch(request)
 382         {
 383                 case CMD_REQUEST_COMMAND:
 384                 {
 385                         if(IS_CLIENT(self))
 386                         {
 387                                 if(warmup_stage || autocvar_sv_ready_restart || g_race_qualifying == 2)
 388                                 {
 389                                         if(!readyrestart_happened || autocvar_sv_ready_restart_repeatable)
 390                                         {
 391                                                 if(time < game_starttime) // game is already restarting
 392                                                         return;
 393                                                 if (self.ready) // toggle
 394                                                 {
 395                                                         self.ready = false;
 396                                                         bprint(self.netname, "^2 is ^1NOT^2 ready\n");
 397                                                 }
 398                                                 else
 399                                                 {
 400                                                         self.ready = true;
 401                                                         bprint(self.netname, "^2 is ready\n");
 402                                                 }
 403
 404                                                 // cannot reset the game while a timeout is active!
 405                                                 if (!timeout_status)
 406                                                         ReadyCount();
 407                                         } else {
 408                                                 sprint(self, "^1Game has already been restarted\n");
 409                                         }
 410                                 }
 411                         }
 412                         return; // never fall through to usage
 413                 }
 414
 415                 default:
 416                 case CMD_REQUEST_USAGE:
 417                 {
 418                         sprint(self, "\nUsage:^3 cmd ready\n");
 419                         sprint(self, "  No arguments required.\n");
 420                         return;
 421                 }
 422         }
 423 }
 424
 425 void ClientCommand_say(float request, float argc, string command)
 426 {
 427         switch(request)
 428         {
 429                 case CMD_REQUEST_COMMAND:
 430                 {
 431                         if(argc >= 2) { Say(self, false, world, substring(command, argv_start_index(1), argv_end_index(-1) - argv_start_index(1)), 1); }
 432                         return; // never fall through to usage
 433                 }
 434
 435                 default:
 436                 case CMD_REQUEST_USAGE:
 437                 {
 438                         sprint(self, "\nUsage:^3 cmd say <message>\n");
 439                         sprint(self, "  Where 'message' is the string of text to say.\n");
 440                         return;
 441                 }
 442         }
 443 }
 444
 445 void ClientCommand_say_team(float request, float argc, string command)
 446 {
 447         switch(request)
 448         {
 449                 case CMD_REQUEST_COMMAND:
 450                 {
 451                         if(argc >= 2) { Say(self, true, world, substring(command, argv_start_index(1), argv_end_index(-1) - argv_start_index(1)), 1); }
 452                         return; // never fall through to usage
 453                 }
 454
 455                 default:
 456                 case CMD_REQUEST_USAGE:
 457                 {
 458                         sprint(self, "\nUsage:^3 cmd say_team <message>\n");
 459                         sprint(self, "  Where 'message' is the string of text to say.\n");
 460                         return;
 461                 }
 462         }
 463 }
 464
 465 void ClientCommand_selectteam(float request, float argc)
 466 {
 467         switch(request)
 468         {
 469                 case CMD_REQUEST_COMMAND:
 470                 {
 471                         if(argv(1) != "")
 472                         {
 473                                 if(IS_CLIENT(self))
 474                                 {
 475                                         if(teamplay)
 476                                                 if(self.team_forced <= 0)
 477                                                         if (!lockteams)
 478                                                         {
 479                                                                 float selection;
 480
 481                                                                 switch(argv(1))
 482                                                                 {
 483                                                                         case "red": selection = NUM_TEAM_1; break;
 484                                                                         case "blue": selection = NUM_TEAM_2; break;
 485                                                                         case "yellow": selection = NUM_TEAM_3; break;
 486                                                                         case "pink": selection = NUM_TEAM_4; break;
 487                                                                         case "auto": selection = (-1); break;
 488
 489                                                                         default: selection = 0; break;
 490                                                                 }
 491
 492                                                                 if(selection)
 493                                                                 {
 494                                                                         if(self.team == selection && self.deadflag == DEAD_NO)
 495                                                                                 sprint(self, "^7You already are on that team.\n");
 496                                                                         else if(self.wasplayer && autocvar_g_changeteam_banned)
 497                                                                                 sprint(self, "^1You cannot change team, forbidden by the server.\n");
 498                                                                         else
 499                                                                         {
 500                                                                                 if(autocvar_g_balance_teams && autocvar_g_balance_teams_prevent_imbalance)
 501                                                                                 {
 502                                                                                         CheckAllowedTeams(self);
 503                                                                                         GetTeamCounts(self);
 504                                                                                         if(!TeamSmallerEqThanTeam(Team_TeamToNumber(selection), Team_TeamToNumber(self.team), self))
 505                                                                                         {
 506                                                                                                 Send_Notification(NOTIF_ONE, self, MSG_INFO, INFO_TEAMCHANGE_LARGERTEAM);
 507                                                                                                 return;
 508                                                                                         }
 509                                                                                 }
 510                                                                                 ClientKill_TeamChange(selection);
 511                                                                         }
 512                                                                 }
 513                                                         }
 514                                                         else
 515                                                                 sprint(self, "^7The game has already begun, you must wait until the next map to be able to join a team.\n");
 516                                                 else
 517                                                         sprint(self, "^7selectteam can not be used as your team is forced\n");
 518                                         else
 519                                                 sprint(self, "^7selectteam can only be used in teamgames\n");
 520                                 }
 521                                 return;
 522                         }
 523                 }
 524
 525                 default:
 526                         sprint(self, "Incorrect parameters for ^2selectteam^7\n");
 527                 case CMD_REQUEST_USAGE:
 528                 {
 529                         sprint(self, "\nUsage:^3 cmd selectteam team\n");
 530                         sprint(self, "  Where 'team' is the prefered team to try and join.\n");
 531                         sprint(self, "  Full list of options here: \"red, blue, yellow, pink, auto\"\n");
 532                         return;
 533                 }
 534         }
 535 }
 536
 537 void ClientCommand_selfstuff(float request, string command)
 538 {
 539         switch(request)
 540         {
 541                 case CMD_REQUEST_COMMAND:
 542                 {
 543                         if(argv(1) != "")
 544                         {
 545                                 stuffcmd(self, substring(command, argv_start_index(1), argv_end_index(-1) - argv_start_index(1)));
 546                                 return;
 547                         }
 548                 }
 549
 550                 default:
 551                         sprint(self, "Incorrect parameters for ^2selectteam^7\n");
 552                 case CMD_REQUEST_USAGE:
 553                 {
 554                         sprint(self, "\nUsage:^3 cmd selfstuff <command>\n");
 555                         sprint(self, "  Where 'command' is the string to be stuffed to your client.\n");
 556                         return;
 557                 }
 558         }
 559 }
 560
 561 void ClientCommand_sentcvar(float request, float argc, string command)
 562 {
 563         switch(request)
 564         {
 565                 case CMD_REQUEST_COMMAND:
 566                 {
 567                         if(argv(1) != "")
 568                         {
 569                                 //float tokens;
 570                                 string s;
 571
 572                                 if(argc == 2) // undefined cvar: use the default value on the server then
 573                                 {
 574                                         s = strcat(substring(command, argv_start_index(0), argv_end_index(1) - argv_start_index(0)), " \"", cvar_defstring(argv(1)), "\"");
 575                                         tokenize_console(s);
 576                                 }
 577
 578                                 GetCvars(1);
 579
 580                                 return;
 581                         }
 582                 }
 583
 584                 default:
 585                         sprint(self, "Incorrect parameters for ^2sentcvar^7\n");
 586                 case CMD_REQUEST_USAGE:
 587                 {
 588                         sprint(self, "\nUsage:^3 cmd sentcvar <cvar>\n");
 589                         sprint(self, "  Where 'cvar' is the cvar plus arguments to send to the server.\n");
 590                         return;
 591                 }
 592         }
 593 }
 594
 595 void ClientCommand_spectate(float request)
 596 {
 597         switch(request)
 598         {
 599                 case CMD_REQUEST_COMMAND:
 600                 {
 601                         if(IS_CLIENT(self))
 602                         {
 603                                 if(g_lms)
 604                                 {
 605                                         if(self.lms_spectate_warning)
 606                                         {
 607                                                 // for the forfeit message...
 608                                                 self.lms_spectate_warning = 2;
 609                                                 // mark player as spectator
 610                                                 PlayerScore_Add(self, SP_LMS_RANK, 666 - PlayerScore_Add(self, SP_LMS_RANK, 0));
 611                                         }
 612                                         else
 613                                         {
 614                                                 self.lms_spectate_warning = 1;
 615                                                 sprint(self, "WARNING: you won't be able to enter the game again after spectating in LMS. Use the same command again to spectate anyway.\n");
 616                                                 return;
 617                                         }
 618                                 }
 619
 620                                 if((IS_PLAYER(self) || self.caplayer) && autocvar_sv_spectate == 1)
 621                                 {
 622                                         if(self.caplayer && (IS_SPEC(self) || IS_OBSERVER(self)))
 623                                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_CA_LEAVE);
 624                                         ClientKill_TeamChange(-2); // observe
 625                                 }
 626                         }
 627                         return; // never fall through to usage
 628                 }
 629
 630                 default:
 631                 case CMD_REQUEST_USAGE:
 632                 {
 633                         sprint(self, "\nUsage:^3 cmd spectate\n");
 634                         sprint(self, "  No arguments required.\n");
 635                         return;
 636                 }
 637         }
 638 }
 639
 640 void ClientCommand_suggestmap(float request, float argc)
 641 {
 642         switch(request)
 643         {
 644                 case CMD_REQUEST_COMMAND:
 645                 {
 646                         if(argv(1) != "")
 647                         {
 648                                 sprint(self, strcat(MapVote_Suggest(argv(1)), "\n"));
 649                                 return;
 650                         }
 651                 }
 652
 653                 default:
 654                         sprint(self, "Incorrect parameters for ^2suggestmap^7\n");
 655                 case CMD_REQUEST_USAGE:
 656                 {
 657                         sprint(self, "\nUsage:^3 cmd suggestmap map\n");
 658                         sprint(self, "  Where 'map' is the name of the map to suggest.\n");
 659                         return;
 660                 }
 661         }
 662 }
 663
 664 void ClientCommand_tell(float request, float argc, string command)
 665 {
 666         switch(request)
 667         {
 668                 case CMD_REQUEST_COMMAND:
 669                 {
 670                         if(argc >= 3)
 671                         {
 672                                 entity tell_to = GetIndexedEntity(argc, 1);
 673                                 float tell_accepted = VerifyClientEntity(tell_to, true, false);
 674
 675                                 if(tell_accepted > 0) // the target is a real client
 676                                 {
 677                                         if(tell_to != self) // and we're allowed to send to them :D
 678                                         {
 679                                                 Say(self, false, tell_to, substring(command, argv_start_index(next_token), argv_end_index(-1) - argv_start_index(next_token)), true);
 680                                                 return;
 681                                         }
 682                                         else { print_to(self, "You can't ^2tell^7 a message to yourself."); return; }
 683                                 }
 684                                 else if(argv(1) == "#0")
 685                                 {
 686                                         trigger_magicear_processmessage_forallears(self, -1, world, substring(command, argv_start_index(next_token), argv_end_index(-1) - argv_start_index(next_token)));
 687                                         return;
 688                                 }
 689                                 else { print_to(self, strcat("tell: ", GetClientErrorString(tell_accepted, argv(1)), ".")); return; }
 690                         }
 691                 }
 692
 693                 default:
 694                         sprint(self, "Incorrect parameters for ^2tell^7\n");
 695                 case CMD_REQUEST_USAGE:
 696                 {
 697                         sprint(self, "\nUsage:^3 cmd tell client <message>\n");
 698                         sprint(self, "  Where 'client' is the entity number or name of the player to send 'message' to.\n");
 699                         return;
 700                 }
 701         }
 702 }
 703
 704 void ClientCommand_voice(float request, float argc, string command)
 705 {
 706         switch(request)
 707         {
 708                 case CMD_REQUEST_COMMAND:
 709                 {
 710                         if(argv(1) != "")
 711                         {
 712                                 if(argc >= 3)
 713                                         VoiceMessage(argv(1), substring(command, argv_start_index(2), argv_end_index(-1) - argv_start_index(2)));
 714                                 else
 715                                         VoiceMessage(argv(1), "");
 716
 717                                 return;
 718                         }
 719                 }
 720
 721                 default:
 722                         sprint(self, "Incorrect parameters for ^2voice^7\n");
 723                 case CMD_REQUEST_USAGE:
 724                 {
 725                         sprint(self, "\nUsage:^3 cmd voice messagetype <soundname>\n");
 726                         sprint(self, "  'messagetype' is the type of broadcast to do, like team only or such,\n");
 727                         sprint(self, "  and 'soundname' is the string/filename of the sound/voice message to play.\n");
 728                         return;
 729                 }
 730         }
 731 }
 732
 733 /* use this when creating a new command, making sure to place it in alphabetical order... also,
 734 ** ADD ALL NEW COMMANDS TO commands.cfg WITH PROPER ALIASES IN THE SAME FASHION!
 735 void ClientCommand_(float request)
 736 {
 737         switch(request)
 738         {
 739                 case CMD_REQUEST_COMMAND:
 740                 {
 741
 742                         return; // never fall through to usage
 743                 }
 744
 745                 default:
 746                 case CMD_REQUEST_USAGE:
 747                 {
 748                         sprint(self, "\nUsage:^3 cmd \n");
 749                         sprint(self, "  No arguments required.\n");
 750                         return;
 751                 }
 752         }
 753 }
 754 */
 755
 756
 757 // =====================================
 758 //  Macro system for networked commands
 759 // =====================================
 760
 761 // Do not hard code aliases for these, instead create them in commands.cfg... also: keep in alphabetical order, please ;)
 762 #define CLIENT_COMMANDS(request,arguments,command) \
 763         CLIENT_COMMAND("autoswitch", ClientCommand_autoswitch(request, arguments), "Whether or not to switch automatically when getting a better weapon") \
 764         CLIENT_COMMAND("checkfail", ClientCommand_checkfail(request, command), "Report if a client-side check failed") \
 765         CLIENT_COMMAND("clientversion", ClientCommand_clientversion(request, arguments), "Release version of the game") \
 766         CLIENT_COMMAND("mv_getpicture", ClientCommand_mv_getpicture(request, arguments), "Retrieve mapshot picture from the server") \
 767         CLIENT_COMMAND("join", ClientCommand_join(request), "Become a player in the game") \
 768         CLIENT_COMMAND("mobedit", ClientCommand_mobedit(request, arguments), "Edit your monster's properties") \
 769         CLIENT_COMMAND("mobkill", ClientCommand_mobkill(request), "Kills your monster") \
 770         CLIENT_COMMAND("mobspawn", ClientCommand_mobspawn(request, arguments), "Spawn monsters infront of yourself") \
 771         CLIENT_COMMAND("ready", ClientCommand_ready(request), "Qualify as ready to end warmup stage (or restart server if allowed)") \
 772         CLIENT_COMMAND("say", ClientCommand_say(request, arguments, command), "Print a message to chat to all players") \
 773         CLIENT_COMMAND("say_team", ClientCommand_say_team(request, arguments, command), "Print a message to chat to all team mates") \
 774         CLIENT_COMMAND("selectteam", ClientCommand_selectteam(request, arguments), "Attempt to choose a team to join into") \
 775         CLIENT_COMMAND("selfstuff", ClientCommand_selfstuff(request, command), "Stuffcmd a command to your own client") \
 776         CLIENT_COMMAND("sentcvar", ClientCommand_sentcvar(request, arguments, command), "New system for sending a client cvar to the server") \
 777         CLIENT_COMMAND("spectate", ClientCommand_spectate(request), "Become an observer") \
 778         CLIENT_COMMAND("suggestmap", ClientCommand_suggestmap(request, arguments), "Suggest a map to the mapvote at match end") \
 779         CLIENT_COMMAND("tell", ClientCommand_tell(request, arguments, command), "Send a message directly to a player") \
 780         CLIENT_COMMAND("voice", ClientCommand_voice(request, arguments, command), "Send voice message via sound") \
 781         /* nothing */
 782
 783 void ClientCommand_macro_help()
 784 {
 785         #define CLIENT_COMMAND(name,function,description) \
 786                 { sprint(self, "  ^2", name, "^7: ", description, "\n"); }
 787
 788         CLIENT_COMMANDS(0, 0, "");
 789         #undef CLIENT_COMMAND
 790
 791         return;
 792 }
 793
 794 float ClientCommand_macro_command(float argc, string command)
 795 {
 796         #define CLIENT_COMMAND(name,function,description) \
 797                 { if(name == strtolower(argv(0))) { function; return true; } }
 798
 799         CLIENT_COMMANDS(CMD_REQUEST_COMMAND, argc, command);
 800         #undef CLIENT_COMMAND
 801
 802         return false;
 803 }
 804
 805 float ClientCommand_macro_usage(float argc)
 806 {
 807         #define CLIENT_COMMAND(name,function,description) \
 808                 { if(name == strtolower(argv(1))) { function; return true; } }
 809
 810         CLIENT_COMMANDS(CMD_REQUEST_USAGE, argc, "");
 811         #undef CLIENT_COMMAND
 812
 813         return false;
 814 }
 815
 816 void ClientCommand_macro_write_aliases(float fh)
 817 {
 818         #define CLIENT_COMMAND(name,function,description) \
 819                 { CMD_Write_Alias("qc_cmd_cmd", name, description); }
 820
 821         CLIENT_COMMANDS(0, 0, "");
 822         #undef CLIENT_COMMAND
 823
 824         return;
 825 }
 826
 827 // ======================================
 828 //  Main Function Called By Engine (cmd)
 829 // ======================================
 830 // If this function exists, server game code parses clientcommand before the engine code gets it.
 831
 832 void SV_ParseClientCommand(string command)
 833 {
 834         // If invalid UTF-8, don't even parse it
 835         string command2 = "";
 836         float len = strlen(command);
 837         float i;
 838         for (i = 0; i < len; ++i)
 839                 command2 = strcat(command2, chr2str(str2chr(command, i)));
 840         if (command != command2)
 841                 return;
 842
 843         // if we're banned, don't even parse the command
 844         if(Ban_MaybeEnforceBanOnce(self))
 845                 return;
 846
 847         float argc = tokenize_console(command);
 848
 849         // for the mutator hook system
 850         cmd_name = strtolower(argv(0));
 851         cmd_argc = argc;
 852         cmd_string = command;
 853
 854         // Guide for working with argc arguments by example:
 855         // argc:   1    - 2      - 3     - 4
 856         // argv:   0    - 1      - 2     - 3
 857         // cmd     vote - master - login - password
 858
 859         // for floodcheck
 860         switch(strtolower(argv(0)))
 861         {
 862                 // exempt commands which are not subject to floodcheck
 863                 case "begin": break; // handled by engine in host_cmd.c
 864                 case "download": break; // handled by engine in cl_parse.c
 865                 case "mv_getpicture": break; // handled by server in this file
 866                 case "pause": break; // handled by engine in host_cmd.c
 867                 case "prespawn": break; // handled by engine in host_cmd.c
 868                 case "sentcvar": break; // handled by server in this file
 869                 case "spawn": break; // handled by engine in host_cmd.c
 870
 871                 default:
 872                         if(SV_ParseClientCommand_floodcheck())
 873                                 break; // "true": continue, as we're not flooding yet
 874                         else
 875                                 return; // "false": not allowed to continue, halt // print("^1ERROR: ^7ANTISPAM CAUGHT: ", command, ".\n");
 876         }
 877
 878         /* NOTE: should this be disabled? It can be spammy perhaps, but hopefully it's okay for now */
 879         if(argv(0) == "help")
 880         {
 881                 if(argc == 1)
 882                 {
 883                         sprint(self, "\nClient networked commands:\n");
 884                         ClientCommand_macro_help();
 885
 886                         sprint(self, "\nCommon networked commands:\n");
 887                         CommonCommand_macro_help(self);
 888
 889                         sprint(self, "\nUsage:^3 cmd COMMAND...^7, where possible commands are listed above.\n");
 890                         sprint(self, "For help about a specific command, type cmd help COMMAND\n");
 891                         return;
 892                 }
 893                 else if(CommonCommand_macro_usage(argc, self)) // Instead of trying to call a command, we're going to see detailed information about it
 894                 {
 895                         return;
 896                 }
 897                 else if(ClientCommand_macro_usage(argc)) // same, but for normal commands now
 898                 {
 899                         return;
 900                 }
 901         }
 902         else if(MUTATOR_CALLHOOK(SV_ParseClientCommand))
 903         {
 904                 return; // handled by a mutator
 905         }
 906         else if(CheatCommand(argc))
 907         {
 908                 return; // handled by server/cheats.qc
 909         }
 910         else if(CommonCommand_macro_command(argc, self, command))
 911         {
 912                 return; // handled by server/command/common.qc
 913         }
 914         else if(ClientCommand_macro_command(argc, command)) // continue as usual and scan for normal commands
 915         {
 916                 return; // handled by one of the above ClientCommand_* functions
 917         }
 918         else
 919                 clientcommand(self, command);
 920 }