qcsrc/server/command/cmd.qc

   1 // =========================================================
   2 //  Server side networked commands code, reworked by Samual
   3 //  Last updated: December 28th, 2011
   4 // =========================================================
   5
   6 float SV_ParseClientCommand_floodcheck()
   7 {
   8         if (!timeout_status) // not while paused
   9         {
  10                 if(time <= (self.cmd_floodtime + autocvar_sv_clientcommand_antispam_time))
  11                 {
  12                         self.cmd_floodcount += 1;
  13                         if(self.cmd_floodcount > autocvar_sv_clientcommand_antispam_count) { return FALSE; } // too much spam, halt
  14                 }
  15                 else
  16                 {
  17                         self.cmd_floodtime = time;
  18                         self.cmd_floodcount = 1;
  19                 }
  20         }
  21         return TRUE; // continue, as we're not flooding yet
  22 }
  23
  24
  25 // =======================
  26 //  Command Sub-Functions
  27 // =======================
  28
  29 void ClientCommand_autoswitch(float request, float argc)
  30 {
  31         switch(request)
  32         {
  33                 case CMD_REQUEST_COMMAND:
  34                 {
  35                         if(argv(1) != "")
  36                         {
  37                                 self.autoswitch = InterpretBoolean(argv(1));
  38                                 sprint(self, strcat("^1autoswitch is currently turned ", (self.autoswitch ? "on" : "off"), ".\n"));
  39                                 return;
  40                         }
  41                 }
  42
  43                 default:
  44                         sprint(self, "Incorrect parameters for ^2autoswitch^7\n");
  45                 case CMD_REQUEST_USAGE:
  46                 {
  47                         sprint(self, "\nUsage:^3 cmd autoswitch selection\n");
  48                         sprint(self, "  Where 'selection' controls if autoswitch is on or off.\n");
  49                         return;
  50                 }
  51         }
  52 }
  53
  54 void ClientCommand_checkfail(float request, string command) // internal command, used only by code
  55 {
  56         switch(request)
  57         {
  58                 case CMD_REQUEST_COMMAND:
  59                 {
  60                         printf("CHECKFAIL: %s (%s) epically failed check %s\n", self.netname, self.netaddress, substring(command, argv_start_index(1), argv_end_index(-1) - argv_start_index(1)));
  61                         self.checkfail = 1;
  62                         return; // never fall through to usage
  63                 }
  64
  65                 default:
  66                         sprint(self, "Incorrect parameters for ^2checkfail^7\n");
  67                 case CMD_REQUEST_USAGE:
  68                 {
  69                         sprint(self, "\nUsage:^3 cmd checkfail <message>\n");
  70                         sprint(self, "  Where 'message' is the message reported by client about the fail.\n");
  71                         return;
  72                 }
  73         }
  74 }
  75
  76 void ClientCommand_clientversion(float request, float argc) // internal command, used only by code
  77 {
  78         switch(request)
  79         {
  80                 case CMD_REQUEST_COMMAND:
  81                 {
  82                         if(argv(1) != "")
  83                         {
  84                                 if(IS_CLIENT(self))
  85                                 {
  86                                         self.version = ((argv(1) == "$gameversion") ? 1 : stof(argv(1)));
  87
  88                                         if(self.version < autocvar_gameversion_min || self.version > autocvar_gameversion_max)
  89                                         {
  90                                                 self.version_mismatch = 1;
  91                                                 ClientKill_TeamChange(-2); // observe
  92                                         }
  93                                         else if(autocvar_g_campaign || autocvar_g_balance_teams)
  94                                         {
  95                                                 //JoinBestTeam(self, FALSE, TRUE);
  96                                         }
  97                                         else if(teamplay && !autocvar_sv_spectate && !(self.team_forced > 0))
  98                                         {
  99                                                 self.classname = "observer"; // really?
 100                                                 stuffcmd(self, "menu_showteamselect\n");
 101                                         }
 102                                 }
 103
 104                                 return;
 105                         }
 106                 }
 107
 108                 default:
 109                         sprint(self, "Incorrect parameters for ^2clientversion^7\n");
 110                 case CMD_REQUEST_USAGE:
 111                 {
 112                         sprint(self, "\nUsage:^3 cmd clientversion version\n");
 113                         sprint(self, "  Where 'version' is the game version reported by self.\n");
 114                         return;
 115                 }
 116         }
 117 }
 118
 119 void ClientCommand_mv_getpicture(float request, float argc) // internal command, used only by code
 120 {
 121         switch(request)
 122         {
 123                 case CMD_REQUEST_COMMAND:
 124                 {
 125                         if(argv(1) != "")
 126                         {
 127                                 if(intermission_running)
 128                                         MapVote_SendPicture(stof(argv(1)));
 129
 130                                 return;
 131                         }
 132                 }
 133
 134                 default:
 135                         sprint(self, "Incorrect parameters for ^2mv_getpicture^7\n");
 136                 case CMD_REQUEST_USAGE:
 137                 {
 138                         sprint(self, "\nUsage:^3 cmd mv_getpicture mapid\n");
 139                         sprint(self, "  Where 'mapid' is the id number of the map to request an image of on the map vote selection menu.\n");
 140                         return;
 141                 }
 142         }
 143 }
 144
 145 void ClientCommand_join(float request)
 146 {
 147         switch(request)
 148         {
 149                 case CMD_REQUEST_COMMAND:
 150                 {
 151                         if(IS_CLIENT(self))
 152                         {
 153                                 if(!IS_PLAYER(self) && !lockteams)
 154                                 {
 155                                         if(self.caplayer)
 156                                                 return;
 157                                         if(nJoinAllowed(self))
 158                                         {
 159                                                 if(autocvar_g_campaign) { campaign_bots_may_start = 1; }
 160
 161                                                 self.classname = "player";
 162                                                 PlayerScore_Clear(self);
 163                                                 Kill_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER_CPID, CPID_PREVENT_JOIN);
 164                                                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_JOIN_PLAY, self.netname);
 165                                                 PutClientInServer();
 166                                         }
 167                                         else
 168                                         {
 169                                                 //player may not join because of g_maxplayers is set
 170                                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_JOIN_PREVENT);
 171                                         }
 172                                 }
 173                         }
 174                         return; // never fall through to usage
 175                 }
 176
 177                 default:
 178                 case CMD_REQUEST_USAGE:
 179                 {
 180                         sprint(self, "\nUsage:^3 cmd join\n");
 181                         sprint(self, "  No arguments required.\n");
 182                         return;
 183                 }
 184         }
 185 }
 186
 187 void ClientCommand_mobedit(float request, float argc)
 188 {
 189         switch(request)
 190         {
 191                 case CMD_REQUEST_COMMAND:
 192                 {
 193                         if(argv(1) && argv(2))
 194                         {
 195                                 makevectors(self.v_angle);
 196                                 WarpZone_TraceLine(self.origin + self.view_ofs, self.origin + self.view_ofs + v_forward * 100, MOVE_NORMAL, self);
 197
 198                                 if(!autocvar_g_monsters_edit) { sprint(self, "Monster property editing is not enabled.\n"); return; }
 199                                 if(trace_ent.flags & FL_MONSTER)
 200                                 {
 201                                         if(trace_ent.realowner != self) { sprint(self, "That monster does not belong to you.\n"); return; }
 202                                         switch(argv(1))
 203                                         {
 204                                                 case "skin":
 205                                                 {
 206                                                         if(trace_ent.monsterid != MON_MAGE)
 207                                                                 trace_ent.skin = stof(argv(2));
 208                                                         return;
 209                                                 }
 210                                                 case "movetarget":
 211                                                 {
 212                                                         trace_ent.monster_moveflags = stof(argv(2));
 213                                                         return;
 214                                                 }
 215                                         }
 216                                 }
 217                         }
 218                 }
 219                 default:
 220                         sprint(self, "Incorrect parameters for ^2mobedit^7\n");
 221                 case CMD_REQUEST_USAGE:
 222                 {
 223                         sprint(self, "\nUsage:^3 cmd mobedit [argument]\n");
 224                         sprint(self, "  Where 'argument' can be skin or movetarget.\n");
 225                         sprint(self, "  Aim at your monster to edit its properties.\n");
 226                         return;
 227                 }
 228         }
 229 }
 230
 231 void ClientCommand_mobkill(float request)
 232 {
 233         switch(request)
 234         {
 235                 case CMD_REQUEST_COMMAND:
 236                 {
 237                         makevectors(self.v_angle);
 238                         WarpZone_TraceLine(self.origin + self.view_ofs, self.origin + self.view_ofs + v_forward * 100, MOVE_NORMAL, self);
 239
 240                         if(trace_ent.flags & FL_MONSTER)
 241                         {
 242                                 if(trace_ent.realowner != self)
 243                                 {
 244                                         sprint(self, "That monster does not belong to you.\n");
 245                                         return;
 246                                 }
 247                                 sprint(self, strcat("Your pet '", trace_ent.monster_name, "' has been brutally mutilated.\n"));
 248                                 Damage (trace_ent, world, world, trace_ent.health + trace_ent.max_health + 200, DEATH_KILL, trace_ent.origin, '0 0 0');
 249                                 return;
 250                         }
 251                 }
 252
 253                 default:
 254                         sprint(self, "Incorrect parameters for ^2mobkill^7\n");
 255                 case CMD_REQUEST_USAGE:
 256                 {
 257                         sprint(self, "\nUsage:^3 cmd mobkill\n");
 258                         sprint(self, "  Aim at your monster to kill it.\n");
 259                         return;
 260                 }
 261         }
 262 }
 263
 264 void ClientCommand_mobspawn(float request, float argc)
 265 {
 266         switch(request)
 267         {
 268                 case CMD_REQUEST_COMMAND:
 269                 {
 270                         entity e;
 271                         string tospawn;
 272                         float moveflag;
 273
 274                         moveflag = (argv(2) ? stof(argv(2)) : 1); // follow owner if not defined
 275                         tospawn = strtolower(argv(1));
 276
 277                         if(tospawn == "list")
 278                         {
 279                                 sprint(self, monsterlist_reply);
 280                                 return;
 281                         }
 282
 283                         if(autocvar_g_monsters_max <= 0 || autocvar_g_monsters_max_perplayer <= 0) { sprint(self, "Monster spawning is disabled.\n"); return; }
 284                         else if(!IS_PLAYER(self)) { sprint(self, "You can't spawn monsters while spectating.\n"); return; }
 285                         else if(MUTATOR_CALLHOOK(AllowMobSpawning)) { sprint(self, "Monster spawning is currently disabled by a mutator.\n"); return; }
 286                         else if(!autocvar_g_monsters) { Send_Notification(NOTIF_ONE, self, MSG_INFO, INFO_MONSTERS_DISABLED); return; }
 287                         else if(self.vehicle) { sprint(self, "You can't spawn monsters while driving a vehicle.\n"); return; }
 288                         else if(autocvar_g_campaign) { sprint(self, "You can't spawn monsters in campaign mode.\n"); return; }
 289                         else if(self.deadflag != DEAD_NO) { sprint(self, "You can't spawn monsters while dead.\n"); return; }
 290                         else if(self.monstercount >= autocvar_g_monsters_max_perplayer) { sprint(self, "You have spawned too many monsters, kill some before trying to spawn any more.\n"); return; }
 291                         else if(totalspawned >= autocvar_g_monsters_max) { sprint(self, "The global maximum monster count has been reached, kill some before trying to spawn any more.\n"); return; }
 292                         else if(tospawn != "")
 293                         {
 294                                 float found = 0, i;
 295                                 entity mon;
 296
 297                                 for(i = MON_FIRST; i <= MON_LAST; ++i)
 298                                 {
 299                                         mon = get_monsterinfo(i);
 300                                         if(mon.netname == tospawn)
 301                                         {
 302                                                 found = TRUE;
 303                                                 break;
 304                                         }
 305                                 }
 306
 307                                 if(found)
 308                                 {
 309                                         self.monstercount += 1;
 310                                         totalspawned += 1;
 311
 312                                         makevectors(self.v_angle);
 313                                         WarpZone_TraceBox (CENTER_OR_VIEWOFS(self), PL_MIN, PL_MAX, CENTER_OR_VIEWOFS(self) + v_forward * 150, TRUE, self);
 314                                         //WarpZone_TraceLine(self.origin + self.view_ofs, self.origin + self.view_ofs + v_forward * 150, MOVE_NORMAL, self);
 315
 316                                         e = spawnmonster(tospawn, 0, self, self, trace_endpos, FALSE, moveflag);
 317
 318                                         sprint(self, strcat("Spawned ", e.monster_name, "\n"));
 319
 320                                         return;
 321                                 }
 322                         }
 323                 }
 324
 325                 default:
 326                         sprint(self, "Incorrect parameters for ^2mobspawn^7\n");
 327                 case CMD_REQUEST_USAGE:
 328                 {
 329                         sprint(self, "\nUsage:^3 cmd mobspawn <random> <monster> [movetype]\n");
 330                         sprint(self, "  See 'cmd mobspawn list' for available monsters.\n");
 331                         sprint(self, "  Argument 'random' spawns a random monster.\n");
 332                         sprint(self, "  Monster will follow the owner if second argument is not defined.\n");
 333                         return;
 334                 }
 335         }
 336 }
 337
 338 void ClientCommand_ready(float request) // todo: anti-spam for toggling readyness
 339 {
 340         switch(request)
 341         {
 342                 case CMD_REQUEST_COMMAND:
 343                 {
 344                         if(IS_CLIENT(self))
 345                         {
 346                                 if(warmup_stage || autocvar_sv_ready_restart || g_race_qualifying == 2)
 347                                 {
 348                                         if(!readyrestart_happened || autocvar_sv_ready_restart_repeatable)
 349                                         {
 350                                                 if(time < game_starttime) // game is already restarting
 351                                                         return;
 352                                                 if (self.ready) // toggle
 353                                                 {
 354                                                         self.ready = FALSE;
 355                                                         bprint(self.netname, "^2 is ^1NOT^2 ready\n");
 356                                                 }
 357                                                 else
 358                                                 {
 359                                                         self.ready = TRUE;
 360                                                         bprint(self.netname, "^2 is ready\n");
 361                                                 }
 362
 363                                                 // cannot reset the game while a timeout is active!
 364                                                 if (!timeout_status)
 365                                                         ReadyCount();
 366                                         } else {
 367                                                 sprint(self, "^1Game has already been restarted\n");
 368                                         }
 369                                 }
 370                         }
 371                         return; // never fall through to usage
 372                 }
 373
 374                 default:
 375                 case CMD_REQUEST_USAGE:
 376                 {
 377                         sprint(self, "\nUsage:^3 cmd ready\n");
 378                         sprint(self, "  No arguments required.\n");
 379                         return;
 380                 }
 381         }
 382 }
 383
 384 void ClientCommand_say(float request, float argc, string command)
 385 {
 386         switch(request)
 387         {
 388                 case CMD_REQUEST_COMMAND:
 389                 {
 390                         if(argc >= 2) { Say(self, FALSE, world, substring(command, argv_start_index(1), argv_end_index(-1) - argv_start_index(1)), 1); }
 391                         return; // never fall through to usage
 392                 }
 393
 394                 default:
 395                 case CMD_REQUEST_USAGE:
 396                 {
 397                         sprint(self, "\nUsage:^3 cmd say <message>\n");
 398                         sprint(self, "  Where 'message' is the string of text to say.\n");
 399                         return;
 400                 }
 401         }
 402 }
 403
 404 void ClientCommand_say_team(float request, float argc, string command)
 405 {
 406         switch(request)
 407         {
 408                 case CMD_REQUEST_COMMAND:
 409                 {
 410                         if(argc >= 2) { Say(self, TRUE, world, substring(command, argv_start_index(1), argv_end_index(-1) - argv_start_index(1)), 1); }
 411                         return; // never fall through to usage
 412                 }
 413
 414                 default:
 415                 case CMD_REQUEST_USAGE:
 416                 {
 417                         sprint(self, "\nUsage:^3 cmd say_team <message>\n");
 418                         sprint(self, "  Where 'message' is the string of text to say.\n");
 419                         return;
 420                 }
 421         }
 422 }
 423
 424 void ClientCommand_selectteam(float request, float argc)
 425 {
 426         switch(request)
 427         {
 428                 case CMD_REQUEST_COMMAND:
 429                 {
 430                         if(argv(1) != "")
 431                         {
 432                                 if(IS_CLIENT(self))
 433                                 {
 434                                         if(teamplay)
 435                                                 if(self.team_forced <= 0)
 436                                                         if (!lockteams)
 437                                                         {
 438                                                                 float selection;
 439
 440                                                                 switch(argv(1))
 441                                                                 {
 442                                                                         case "red": selection = NUM_TEAM_1; break;
 443                                                                         case "blue": selection = NUM_TEAM_2; break;
 444                                                                         case "yellow": selection = NUM_TEAM_3; break;
 445                                                                         case "pink": selection = NUM_TEAM_4; break;
 446                                                                         case "auto": selection = (-1); break;
 447
 448                                                                         default: selection = 0; break;
 449                                                                 }
 450
 451                                                                 if(selection)
 452                                                                 {
 453                                                                         if(self.team == selection && self.deadflag == DEAD_NO)
 454                                                                                 sprint(self, "^7You already are on that team.\n");
 455                                                                         else if(self.wasplayer && autocvar_g_changeteam_banned)
 456                                                                                 sprint(self, "^1You cannot change team, forbidden by the server.\n");
 457                                                                         else
 458                                                                         {
 459                                                                                 if(autocvar_g_balance_teams && autocvar_g_balance_teams_prevent_imbalance)
 460                                                                                 {
 461                                                                                         GetTeamCounts(self);
 462                                                                                         if(!TeamSmallerEqThanTeam(selection, self.team, self))
 463                                                                                         {
 464                                                                                                 sprint(self, "Cannot change to a larger/better/shinier team\n");
 465                                                                                                 return;
 466                                                                                         }
 467                                                                                 }
 468                                                                                 ClientKill_TeamChange(selection);
 469                                                                         }
 470                                                                 }
 471                                                         }
 472                                                         else
 473                                                                 sprint(self, "^7The game has already begun, you must wait until the next map to be able to join a team.\n");
 474                                                 else
 475                                                         sprint(self, "^7selectteam can not be used as your team is forced\n");
 476                                         else
 477                                                 sprint(self, "^7selectteam can only be used in teamgames\n");
 478                                 }
 479                                 return;
 480                         }
 481                 }
 482
 483                 default:
 484                         sprint(self, "Incorrect parameters for ^2selectteam^7\n");
 485                 case CMD_REQUEST_USAGE:
 486                 {
 487                         sprint(self, "\nUsage:^3 cmd selectteam team\n");
 488                         sprint(self, "  Where 'team' is the prefered team to try and join.\n");
 489                         sprint(self, "  Full list of options here: \"red, blue, yellow, pink, auto\"\n");
 490                         return;
 491                 }
 492         }
 493 }
 494
 495 void ClientCommand_selfstuff(float request, string command)
 496 {
 497         switch(request)
 498         {
 499                 case CMD_REQUEST_COMMAND:
 500                 {
 501                         if(argv(1) != "")
 502                         {
 503                                 stuffcmd(self, substring(command, argv_start_index(1), argv_end_index(-1) - argv_start_index(1)));
 504                                 return;
 505                         }
 506                 }
 507
 508                 default:
 509                         sprint(self, "Incorrect parameters for ^2selectteam^7\n");
 510                 case CMD_REQUEST_USAGE:
 511                 {
 512                         sprint(self, "\nUsage:^3 cmd selfstuff <command>\n");
 513                         sprint(self, "  Where 'command' is the string to be stuffed to your client.\n");
 514                         return;
 515                 }
 516         }
 517 }
 518
 519 void ClientCommand_sentcvar(float request, float argc, string command)
 520 {
 521         switch(request)
 522         {
 523                 case CMD_REQUEST_COMMAND:
 524                 {
 525                         if(argv(1) != "")
 526                         {
 527                                 //float tokens;
 528                                 string s;
 529
 530                                 if(argc == 2) // undefined cvar: use the default value on the server then
 531                                 {
 532                                         s = strcat(substring(command, argv_start_index(0), argv_end_index(1) - argv_start_index(0)), " \"", cvar_defstring(argv(1)), "\"");
 533                                         tokenize_console(s);
 534                                 }
 535
 536                                 GetCvars(1);
 537
 538                                 return;
 539                         }
 540                 }
 541
 542                 default:
 543                         sprint(self, "Incorrect parameters for ^2sentcvar^7\n");
 544                 case CMD_REQUEST_USAGE:
 545                 {
 546                         sprint(self, "\nUsage:^3 cmd sentcvar <cvar>\n");
 547                         sprint(self, "  Where 'cvar' is the cvar plus arguments to send to the server.\n");
 548                         return;
 549                 }
 550         }
 551 }
 552
 553 void ClientCommand_spectate(float request)
 554 {
 555         switch(request)
 556         {
 557                 case CMD_REQUEST_COMMAND:
 558                 {
 559                         if(IS_CLIENT(self))
 560                         {
 561                                 if(g_lms)
 562                                 {
 563                                         if(self.lms_spectate_warning)
 564                                         {
 565                                                 // for the forfeit message...
 566                                                 self.lms_spectate_warning = 2;
 567                                                 // mark player as spectator
 568                                                 PlayerScore_Add(self, SP_LMS_RANK, 666 - PlayerScore_Add(self, SP_LMS_RANK, 0));
 569                                         }
 570                                         else
 571                                         {
 572                                                 self.lms_spectate_warning = 1;
 573                                                 sprint(self, "WARNING: you won't be able to enter the game again after spectating in LMS. Use the same command again to spectate anyway.\n");
 574                                                 return;
 575                                         }
 576                                 }
 577
 578                                 if((IS_PLAYER(self) || self.caplayer) && autocvar_sv_spectate == 1)
 579                                 {
 580                                         if(self.caplayer && (IS_SPEC(self) || IS_OBSERVER(self)))
 581                                                 sprint(self, "WARNING: you will spectate in the next round.\n");
 582                                         ClientKill_TeamChange(-2); // observe
 583                                 }
 584                         }
 585                         return; // never fall through to usage
 586                 }
 587
 588                 default:
 589                 case CMD_REQUEST_USAGE:
 590                 {
 591                         sprint(self, "\nUsage:^3 cmd spectate\n");
 592                         sprint(self, "  No arguments required.\n");
 593                         return;
 594                 }
 595         }
 596 }
 597
 598 void ClientCommand_suggestmap(float request, float argc)
 599 {
 600         switch(request)
 601         {
 602                 case CMD_REQUEST_COMMAND:
 603                 {
 604                         if(argv(1) != "")
 605                         {
 606                                 sprint(self, strcat(MapVote_Suggest(argv(1)), "\n"));
 607                                 return;
 608                         }
 609                 }
 610
 611                 default:
 612                         sprint(self, "Incorrect parameters for ^2suggestmap^7\n");
 613                 case CMD_REQUEST_USAGE:
 614                 {
 615                         sprint(self, "\nUsage:^3 cmd suggestmap map\n");
 616                         sprint(self, "  Where 'map' is the name of the map to suggest.\n");
 617                         return;
 618                 }
 619         }
 620 }
 621
 622 void ClientCommand_tell(float request, float argc, string command)
 623 {
 624         switch(request)
 625         {
 626                 case CMD_REQUEST_COMMAND:
 627                 {
 628                         if(argc >= 3)
 629                         {
 630                                 entity tell_to = GetIndexedEntity(argc, 1);
 631                                 float tell_accepted = VerifyClientEntity(tell_to, TRUE, FALSE);
 632
 633                                 if(tell_accepted > 0) // the target is a real client
 634                                 {
 635                                         if(tell_to != self) // and we're allowed to send to them :D
 636                                         {
 637                                                 Say(self, FALSE, tell_to, substring(command, argv_start_index(next_token), argv_end_index(-1) - argv_start_index(next_token)), TRUE);
 638                                                 return;
 639                                         }
 640                                         else { print_to(self, "You can't ^2tell^7 a message to yourself."); return; }
 641                                 }
 642                                 else if(argv(1) == "#0")
 643                                 {
 644                                         trigger_magicear_processmessage_forallears(self, -1, world, substring(command, argv_start_index(next_token), argv_end_index(-1) - argv_start_index(next_token)));
 645                                         return;
 646                                 }
 647                                 else { print_to(self, strcat("tell: ", GetClientErrorString(tell_accepted, argv(1)), ".")); return; }
 648                         }
 649                 }
 650
 651                 default:
 652                         sprint(self, "Incorrect parameters for ^2tell^7\n");
 653                 case CMD_REQUEST_USAGE:
 654                 {
 655                         sprint(self, "\nUsage:^3 cmd tell client <message>\n");
 656                         sprint(self, "  Where 'client' is the entity number or name of the player to send 'message' to.\n");
 657                         return;
 658                 }
 659         }
 660 }
 661
 662 void ClientCommand_voice(float request, float argc, string command)
 663 {
 664         switch(request)
 665         {
 666                 case CMD_REQUEST_COMMAND:
 667                 {
 668                         if(argv(1) != "")
 669                         {
 670                                 if(argc >= 3)
 671                                         VoiceMessage(argv(1), substring(command, argv_start_index(2), argv_end_index(-1) - argv_start_index(2)));
 672                                 else
 673                                         VoiceMessage(argv(1), "");
 674
 675                                 return;
 676                         }
 677                 }
 678
 679                 default:
 680                         sprint(self, "Incorrect parameters for ^2voice^7\n");
 681                 case CMD_REQUEST_USAGE:
 682                 {
 683                         sprint(self, "\nUsage:^3 cmd voice messagetype <soundname>\n");
 684                         sprint(self, "  'messagetype' is the type of broadcast to do, like team only or such,\n");
 685                         sprint(self, "  and 'soundname' is the string/filename of the sound/voice message to play.\n");
 686                         return;
 687                 }
 688         }
 689 }
 690
 691 /* use this when creating a new command, making sure to place it in alphabetical order... also,
 692 ** ADD ALL NEW COMMANDS TO commands.cfg WITH PROPER ALIASES IN THE SAME FASHION!
 693 void ClientCommand_(float request)
 694 {
 695         switch(request)
 696         {
 697                 case CMD_REQUEST_COMMAND:
 698                 {
 699
 700                         return; // never fall through to usage
 701                 }
 702
 703                 default:
 704                 case CMD_REQUEST_USAGE:
 705                 {
 706                         sprint(self, "\nUsage:^3 cmd \n");
 707                         sprint(self, "  No arguments required.\n");
 708                         return;
 709                 }
 710         }
 711 }
 712 */
 713
 714
 715 // =====================================
 716 //  Macro system for networked commands
 717 // =====================================
 718
 719 // Do not hard code aliases for these, instead create them in commands.cfg... also: keep in alphabetical order, please ;)
 720 #define CLIENT_COMMANDS(request,arguments,command) \
 721         CLIENT_COMMAND("autoswitch", ClientCommand_autoswitch(request, arguments), "Whether or not to switch automatically when getting a better weapon") \
 722         CLIENT_COMMAND("checkfail", ClientCommand_checkfail(request, command), "Report if a client-side check failed") \
 723         CLIENT_COMMAND("clientversion", ClientCommand_clientversion(request, arguments), "Release version of the game") \
 724         CLIENT_COMMAND("mv_getpicture", ClientCommand_mv_getpicture(request, arguments), "Retrieve mapshot picture from the server") \
 725         CLIENT_COMMAND("join", ClientCommand_join(request), "Become a player in the game") \
 726         CLIENT_COMMAND("mobedit", ClientCommand_mobedit(request, arguments), "Edit your monster's properties") \
 727         CLIENT_COMMAND("mobkill", ClientCommand_mobkill(request), "Kills your monster") \
 728         CLIENT_COMMAND("mobspawn", ClientCommand_mobspawn(request, arguments), "Spawn monsters infront of yourself") \
 729         CLIENT_COMMAND("ready", ClientCommand_ready(request), "Qualify as ready to end warmup stage (or restart server if allowed)") \
 730         CLIENT_COMMAND("say", ClientCommand_say(request, arguments, command), "Print a message to chat to all players") \
 731         CLIENT_COMMAND("say_team", ClientCommand_say_team(request, arguments, command), "Print a message to chat to all team mates") \
 732         CLIENT_COMMAND("selectteam", ClientCommand_selectteam(request, arguments), "Attempt to choose a team to join into") \
 733         CLIENT_COMMAND("selfstuff", ClientCommand_selfstuff(request, command), "Stuffcmd a command to your own client") \
 734         CLIENT_COMMAND("sentcvar", ClientCommand_sentcvar(request, arguments, command), "New system for sending a client cvar to the server") \
 735         CLIENT_COMMAND("spectate", ClientCommand_spectate(request), "Become an observer") \
 736         CLIENT_COMMAND("suggestmap", ClientCommand_suggestmap(request, arguments), "Suggest a map to the mapvote at match end") \
 737         CLIENT_COMMAND("tell", ClientCommand_tell(request, arguments, command), "Send a message directly to a player") \
 738         CLIENT_COMMAND("voice", ClientCommand_voice(request, arguments, command), "Send voice message via sound") \
 739         /* nothing */
 740
 741 void ClientCommand_macro_help()
 742 {
 743         #define CLIENT_COMMAND(name,function,description) \
 744                 { sprint(self, "  ^2", name, "^7: ", description, "\n"); }
 745
 746         CLIENT_COMMANDS(0, 0, "")
 747         #undef CLIENT_COMMAND
 748
 749         return;
 750 }
 751
 752 float ClientCommand_macro_command(float argc, string command)
 753 {
 754         #define CLIENT_COMMAND(name,function,description) \
 755                 { if(name == strtolower(argv(0))) { function; return TRUE; } }
 756
 757         CLIENT_COMMANDS(CMD_REQUEST_COMMAND, argc, command)
 758         #undef CLIENT_COMMAND
 759
 760         return FALSE;
 761 }
 762
 763 float ClientCommand_macro_usage(float argc)
 764 {
 765         #define CLIENT_COMMAND(name,function,description) \
 766                 { if(name == strtolower(argv(1))) { function; return TRUE; } }
 767
 768         CLIENT_COMMANDS(CMD_REQUEST_USAGE, argc, "")
 769         #undef CLIENT_COMMAND
 770
 771         return FALSE;
 772 }
 773
 774 void ClientCommand_macro_write_aliases(float fh)
 775 {
 776         #define CLIENT_COMMAND(name,function,description) \
 777                 { CMD_Write_Alias("qc_cmd_cmd", name, description); }
 778
 779         CLIENT_COMMANDS(0, 0, "")
 780         #undef CLIENT_COMMAND
 781
 782         return;
 783 }
 784
 785 // ======================================
 786 //  Main Function Called By Engine (cmd)
 787 // ======================================
 788 // If this function exists, server game code parses clientcommand before the engine code gets it.
 789
 790 void SV_ParseClientCommand(string command)
 791 {
 792         // if we're banned, don't even parse the command
 793         if(Ban_MaybeEnforceBanOnce(self))
 794                 return;
 795
 796         float argc = tokenize_console(command);
 797
 798         // for the mutator hook system
 799         cmd_name = strtolower(argv(0));
 800         cmd_argc = argc;
 801         cmd_string = command;
 802
 803         // Guide for working with argc arguments by example:
 804         // argc:   1    - 2      - 3     - 4
 805         // argv:   0    - 1      - 2     - 3
 806         // cmd     vote - master - login - password
 807
 808         // for floodcheck
 809         switch(strtolower(argv(0)))
 810         {
 811                 // exempt commands which are not subject to floodcheck
 812                 case "begin": break; // handled by engine in host_cmd.c
 813                 case "download": break; // handled by engine in cl_parse.c
 814                 case "mv_getpicture": break; // handled by server in this file
 815                 case "pause": break; // handled by engine in host_cmd.c
 816                 case "prespawn": break; // handled by engine in host_cmd.c
 817                 case "sentcvar": break; // handled by server in this file
 818                 case "spawn": break; // handled by engine in host_cmd.c
 819
 820                 default:
 821                         if(SV_ParseClientCommand_floodcheck())
 822                                 break; // "TRUE": continue, as we're not flooding yet
 823                         else
 824                                 return; // "FALSE": not allowed to continue, halt // print("^1ERROR: ^7ANTISPAM CAUGHT: ", command, ".\n");
 825         }
 826
 827         /* NOTE: should this be disabled? It can be spammy perhaps, but hopefully it's okay for now */
 828         if(argv(0) == "help")
 829         {
 830                 if(argc == 1)
 831                 {
 832                         sprint(self, "\nClient networked commands:\n");
 833                         ClientCommand_macro_help();
 834
 835                         sprint(self, "\nCommon networked commands:\n");
 836                         CommonCommand_macro_help(self);
 837
 838                         sprint(self, "\nUsage:^3 cmd COMMAND...^7, where possible commands are listed above.\n");
 839                         sprint(self, "For help about a specific command, type cmd help COMMAND\n");
 840                         return;
 841                 }
 842                 else if(CommonCommand_macro_usage(argc, self)) // Instead of trying to call a command, we're going to see detailed information about it
 843                 {
 844                         return;
 845                 }
 846                 else if(ClientCommand_macro_usage(argc)) // same, but for normal commands now
 847                 {
 848                         return;
 849                 }
 850         }
 851         else if(MUTATOR_CALLHOOK(SV_ParseClientCommand))
 852         {
 853                 return; // handled by a mutator
 854         }
 855         else if(CheatCommand(argc))
 856         {
 857                 return; // handled by server/cheats.qc
 858         }
 859         else if(CommonCommand_macro_command(argc, self, command))
 860         {
 861                 return; // handled by server/command/common.qc
 862         }
 863         else if(ClientCommand_macro_command(argc, command)) // continue as usual and scan for normal commands
 864         {
 865                 return; // handled by one of the above ClientCommand_* functions
 866         }
 867         else
 868                 clientcommand(self, command);
 869 }