qcsrc/server/command/cmd.qc

   1 // =========================================================
   2 //  Server side networked commands code, reworked by Samual
   3 //  Last updated: December 28th, 2011
   4 // =========================================================
   5
   6 float SV_ParseClientCommand_floodcheck()
   7 {
   8         if (!timeout_status) // not while paused
   9         {
  10                 if(time <= (self.cmd_floodtime + autocvar_sv_clientcommand_antispam_time))
  11                 {
  12                         self.cmd_floodcount += 1;
  13                         if(self.cmd_floodcount > autocvar_sv_clientcommand_antispam_count) { return FALSE; } // too much spam, halt
  14                 }
  15                 else
  16                 {
  17                         self.cmd_floodtime = time;
  18                         self.cmd_floodcount = 1;
  19                 }
  20         }
  21         return TRUE; // continue, as we're not flooding yet
  22 }
  23
  24
  25 // =======================
  26 //  Command Sub-Functions
  27 // =======================
  28
  29 void ClientCommand_autoswitch(float request, float argc)
  30 {
  31         switch(request)
  32         {
  33                 case CMD_REQUEST_COMMAND:
  34                 {
  35                         if(argv(1) != "")
  36                         {
  37                                 self.autoswitch = InterpretBoolean(argv(1));
  38                                 sprint(self, strcat("^1autoswitch is currently turned ", (self.autoswitch ? "on" : "off"), ".\n"));
  39                                 return;
  40                         }
  41                 }
  42
  43                 default:
  44                         sprint(self, "Incorrect parameters for ^2autoswitch^7\n");
  45                 case CMD_REQUEST_USAGE:
  46                 {
  47                         sprint(self, "\nUsage:^3 cmd autoswitch selection\n");
  48                         sprint(self, "  Where 'selection' controls if autoswitch is on or off.\n");
  49                         return;
  50                 }
  51         }
  52 }
  53
  54 void ClientCommand_checkfail(float request, string command) // internal command, used only by code
  55 {
  56         switch(request)
  57         {
  58                 case CMD_REQUEST_COMMAND:
  59                 {
  60                         printf("CHECKFAIL: %s (%s) epically failed check %s\n", self.netname, self.netaddress, substring(command, argv_start_index(1), argv_end_index(-1) - argv_start_index(1)));
  61                         self.checkfail = 1;
  62                         return; // never fall through to usage
  63                 }
  64
  65                 default:
  66                         sprint(self, "Incorrect parameters for ^2checkfail^7\n");
  67                 case CMD_REQUEST_USAGE:
  68                 {
  69                         sprint(self, "\nUsage:^3 cmd checkfail <message>\n");
  70                         sprint(self, "  Where 'message' is the message reported by client about the fail.\n");
  71                         return;
  72                 }
  73         }
  74 }
  75
  76 void ClientCommand_clientversion(float request, float argc) // internal command, used only by code
  77 {
  78         switch(request)
  79         {
  80                 case CMD_REQUEST_COMMAND:
  81                 {
  82                         if(argv(1) != "")
  83                         {
  84                                 if(IS_CLIENT(self))
  85                                 {
  86                                         self.version = ((argv(1) == "$gameversion") ? 1 : stof(argv(1)));
  87
  88                                         if(self.version < autocvar_gameversion_min || self.version > autocvar_gameversion_max)
  89                                         {
  90                                                 self.version_mismatch = 1;
  91                                                 ClientKill_TeamChange(-2); // observe
  92                                         }
  93                                         else if(autocvar_g_campaign || autocvar_g_balance_teams)
  94                                         {
  95                                                 //JoinBestTeam(self, FALSE, TRUE);
  96                                         }
  97                                         else if(teamplay && !autocvar_sv_spectate && !(self.team_forced > 0))
  98                                         {
  99                                                 self.classname = "observer"; // really?
 100                                                 stuffcmd(self, "menu_showteamselect\n");
 101                                         }
 102                                 }
 103
 104                                 return;
 105                         }
 106                 }
 107
 108                 default:
 109                         sprint(self, "Incorrect parameters for ^2clientversion^7\n");
 110                 case CMD_REQUEST_USAGE:
 111                 {
 112                         sprint(self, "\nUsage:^3 cmd clientversion version\n");
 113                         sprint(self, "  Where 'version' is the game version reported by self.\n");
 114                         return;
 115                 }
 116         }
 117 }
 118
 119 void ClientCommand_mv_getpicture(float request, float argc) // internal command, used only by code
 120 {
 121         switch(request)
 122         {
 123                 case CMD_REQUEST_COMMAND:
 124                 {
 125                         if(argv(1) != "")
 126                         {
 127                                 if(intermission_running)
 128                                         MapVote_SendPicture(stof(argv(1)));
 129
 130                                 return;
 131                         }
 132                 }
 133
 134                 default:
 135                         sprint(self, "Incorrect parameters for ^2mv_getpicture^7\n");
 136                 case CMD_REQUEST_USAGE:
 137                 {
 138                         sprint(self, "\nUsage:^3 cmd mv_getpicture mapid\n");
 139                         sprint(self, "  Where 'mapid' is the id number of the map to request an image of on the map vote selection menu.\n");
 140                         return;
 141                 }
 142         }
 143 }
 144
 145 void ClientCommand_join(float request)
 146 {
 147         switch(request)
 148         {
 149                 case CMD_REQUEST_COMMAND:
 150                 {
 151                         if(IS_CLIENT(self))
 152                         {
 153                                 if(!IS_PLAYER(self) && !lockteams)
 154                                 {
 155                                         if(nJoinAllowed(self))
 156                                         {
 157                                                 if(autocvar_g_campaign) { campaign_bots_may_start = 1; }
 158
 159                                                 self.classname = "player";
 160                                                 PlayerScore_Clear(self);
 161                                                 Kill_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER_CPID, CPID_PREVENT_JOIN);
 162                                                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_JOIN_PLAY, self.netname);
 163                                                 PutClientInServer();
 164                                         }
 165                                         else
 166                                         {
 167                                                 //player may not join because of g_maxplayers is set
 168                                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_JOIN_PREVENT);
 169                                         }
 170                                 }
 171                         }
 172                         return; // never fall through to usage
 173                 }
 174
 175                 default:
 176                 case CMD_REQUEST_USAGE:
 177                 {
 178                         sprint(self, "\nUsage:^3 cmd join\n");
 179                         sprint(self, "  No arguments required.\n");
 180                         return;
 181                 }
 182         }
 183 }
 184
 185 void ClientCommand_mobedit(float request, float argc)
 186 {
 187         switch(request)
 188         {
 189                 case CMD_REQUEST_COMMAND:
 190                 {
 191                         if(argv(1) && argv(2))
 192                         {
 193                                 makevectors(self.v_angle);
 194                                 WarpZone_TraceLine(self.origin + self.view_ofs, self.origin + self.view_ofs + v_forward * 100, MOVE_NORMAL, self);
 195
 196                                 if(!autocvar_g_monsters_edit) { sprint(self, "Monster property editing is not enabled.\n"); return; }
 197                                 if(trace_ent.flags & FL_MONSTER)
 198                                 {
 199                                         if(trace_ent.realowner != self) { sprint(self, "That monster does not belong to you.\n"); return; }
 200                                         switch(argv(1))
 201                                         {
 202                                                 case "skin":
 203                                                 {
 204                                                         if(trace_ent.monsterid != MON_MAGE)
 205                                                                 trace_ent.skin = stof(argv(2));
 206                                                         return;
 207                                                 }
 208                                                 case "movetarget":
 209                                                 {
 210                                                         trace_ent.monster_moveflags = stof(argv(2));
 211                                                         return;
 212                                                 }
 213                                         }
 214                                 }
 215                         }
 216                 }
 217                 default:
 218                         sprint(self, "Incorrect parameters for ^2mobedit^7\n");
 219                 case CMD_REQUEST_USAGE:
 220                 {
 221                         sprint(self, "\nUsage:^3 cmd mobedit [argument]\n");
 222                         sprint(self, "  Where 'argument' can be skin or movetarget.\n");
 223                         sprint(self, "  Aim at your monster to edit its properties.\n");
 224                         return;
 225                 }
 226         }
 227 }
 228
 229 void ClientCommand_mobkill(float request)
 230 {
 231         switch(request)
 232         {
 233                 case CMD_REQUEST_COMMAND:
 234                 {
 235                         makevectors(self.v_angle);
 236                         WarpZone_TraceLine(self.origin + self.view_ofs, self.origin + self.view_ofs + v_forward * 100, MOVE_NORMAL, self);
 237
 238                         if(trace_ent.flags & FL_MONSTER)
 239                         {
 240                                 if(trace_ent.realowner != self)
 241                                 {
 242                                         sprint(self, "That monster does not belong to you.\n");
 243                                         return;
 244                                 }
 245                                 sprint(self, strcat("Your pet '", trace_ent.monster_name, "' has been brutally mutilated.\n"));
 246                                 Damage (trace_ent, world, world, trace_ent.health + trace_ent.max_health + 200, DEATH_KILL, trace_ent.origin, '0 0 0');
 247                                 return;
 248                         }
 249                 }
 250
 251                 default:
 252                         sprint(self, "Incorrect parameters for ^2mobkill^7\n");
 253                 case CMD_REQUEST_USAGE:
 254                 {
 255                         sprint(self, "\nUsage:^3 cmd mobkill\n");
 256                         sprint(self, "  Aim at your monster to kill it.\n");
 257                         return;
 258                 }
 259         }
 260 }
 261
 262 void ClientCommand_mobspawn(float request, float argc)
 263 {
 264         switch(request)
 265         {
 266                 case CMD_REQUEST_COMMAND:
 267                 {
 268                         entity e;
 269                         string tospawn;
 270                         float moveflag, monstercount = 0;
 271
 272                         moveflag = (argv(2) ? stof(argv(2)) : 1); // follow owner if not defined
 273                         tospawn = strtolower(argv(1));
 274
 275                         if(tospawn == "list")
 276                         {
 277                                 sprint(self, monsterlist_reply);
 278                                 return;
 279                         }
 280
 281                         FOR_EACH_MONSTER(e)
 282                         {
 283                                 if(e.realowner == self)
 284                                         ++monstercount;
 285                         }
 286
 287                         if(autocvar_g_monsters_max <= 0 || autocvar_g_monsters_max_perplayer <= 0) { sprint(self, "Monster spawning is disabled.\n"); return; }
 288                         else if(!IS_PLAYER(self)) { sprint(self, "You can't spawn monsters while spectating.\n"); return; }
 289                         else if(MUTATOR_CALLHOOK(AllowMobSpawning)) { sprint(self, "Monster spawning is currently disabled by a mutator.\n"); return; }
 290                         else if(!autocvar_g_monsters) { Send_Notification(NOTIF_ONE, self, MSG_INFO, INFO_MONSTERS_DISABLED); return; }
 291                         else if(self.vehicle) { sprint(self, "You can't spawn monsters while driving a vehicle.\n"); return; }
 292                         else if(self.frozen) { sprint(self, "You can't spawn monsters while frozen.\n"); return; }
 293                         else if(autocvar_g_campaign) { sprint(self, "You can't spawn monsters in campaign mode.\n"); return; }
 294                         else if(self.deadflag != DEAD_NO) { sprint(self, "You can't spawn monsters while dead.\n"); return; }
 295                         else if(monstercount >= autocvar_g_monsters_max_perplayer) { sprint(self, "You have spawned too many monsters, kill some before trying to spawn any more.\n"); return; }
 296                         else if(totalspawned >= autocvar_g_monsters_max) { sprint(self, "The global maximum monster count has been reached, kill some before trying to spawn any more.\n"); return; }
 297                         else if(tospawn != "")
 298                         {
 299                                 float found = 0, i;
 300                                 entity mon;
 301
 302                                 for(i = MON_FIRST; i <= MON_LAST; ++i)
 303                                 {
 304                                         mon = get_monsterinfo(i);
 305                                         if(mon.netname == tospawn)
 306                                         {
 307                                                 found = TRUE;
 308                                                 break;
 309                                         }
 310                                 }
 311
 312                                 if(found || tospawn == "random")
 313                                 {
 314                                         totalspawned += 1;
 315
 316                                         makevectors(self.v_angle);
 317                                         WarpZone_TraceBox (CENTER_OR_VIEWOFS(self), PL_MIN, PL_MAX, CENTER_OR_VIEWOFS(self) + v_forward * 150, TRUE, self);
 318                                         //WarpZone_TraceLine(self.origin + self.view_ofs, self.origin + self.view_ofs + v_forward * 150, MOVE_NORMAL, self);
 319
 320                                         e = spawnmonster(tospawn, 0, self, self, trace_endpos, FALSE, FALSE, moveflag);
 321
 322                                         sprint(self, strcat("Spawned ", e.monster_name, "\n"));
 323
 324                                         return;
 325                                 }
 326                         }
 327                 }
 328
 329                 default:
 330                         sprint(self, "Incorrect parameters for ^2mobspawn^7\n");
 331                 case CMD_REQUEST_USAGE:
 332                 {
 333                         sprint(self, "\nUsage:^3 cmd mobspawn <random> <monster> [movetype]\n");
 334                         sprint(self, "  See 'cmd mobspawn list' for available monsters.\n");
 335                         sprint(self, "  Argument 'random' spawns a random monster.\n");
 336                         sprint(self, "  Monster will follow the owner if second argument is not defined.\n");
 337                         return;
 338                 }
 339         }
 340 }
 341
 342 void ClientCommand_ready(float request) // todo: anti-spam for toggling readyness
 343 {
 344         switch(request)
 345         {
 346                 case CMD_REQUEST_COMMAND:
 347                 {
 348                         if(IS_CLIENT(self))
 349                         {
 350                                 if(warmup_stage || autocvar_sv_ready_restart || g_race_qualifying == 2)
 351                                 {
 352                                         if(!readyrestart_happened || autocvar_sv_ready_restart_repeatable)
 353                                         {
 354                                                 if(time < game_starttime) // game is already restarting
 355                                                         return;
 356                                                 if (self.ready) // toggle
 357                                                 {
 358                                                         self.ready = FALSE;
 359                                                         bprint(self.netname, "^2 is ^1NOT^2 ready\n");
 360                                                 }
 361                                                 else
 362                                                 {
 363                                                         self.ready = TRUE;
 364                                                         bprint(self.netname, "^2 is ready\n");
 365                                                 }
 366
 367                                                 // cannot reset the game while a timeout is active!
 368                                                 if (!timeout_status)
 369                                                         ReadyCount();
 370                                         } else {
 371                                                 sprint(self, "^1Game has already been restarted\n");
 372                                         }
 373                                 }
 374                         }
 375                         return; // never fall through to usage
 376                 }
 377
 378                 default:
 379                 case CMD_REQUEST_USAGE:
 380                 {
 381                         sprint(self, "\nUsage:^3 cmd ready\n");
 382                         sprint(self, "  No arguments required.\n");
 383                         return;
 384                 }
 385         }
 386 }
 387
 388 void ClientCommand_say(float request, float argc, string command)
 389 {
 390         switch(request)
 391         {
 392                 case CMD_REQUEST_COMMAND:
 393                 {
 394                         if(argc >= 2) { Say(self, FALSE, world, substring(command, argv_start_index(1), argv_end_index(-1) - argv_start_index(1)), 1); }
 395                         return; // never fall through to usage
 396                 }
 397
 398                 default:
 399                 case CMD_REQUEST_USAGE:
 400                 {
 401                         sprint(self, "\nUsage:^3 cmd say <message>\n");
 402                         sprint(self, "  Where 'message' is the string of text to say.\n");
 403                         return;
 404                 }
 405         }
 406 }
 407
 408 void ClientCommand_say_team(float request, float argc, string command)
 409 {
 410         switch(request)
 411         {
 412                 case CMD_REQUEST_COMMAND:
 413                 {
 414                         if(argc >= 2) { Say(self, TRUE, world, substring(command, argv_start_index(1), argv_end_index(-1) - argv_start_index(1)), 1); }
 415                         return; // never fall through to usage
 416                 }
 417
 418                 default:
 419                 case CMD_REQUEST_USAGE:
 420                 {
 421                         sprint(self, "\nUsage:^3 cmd say_team <message>\n");
 422                         sprint(self, "  Where 'message' is the string of text to say.\n");
 423                         return;
 424                 }
 425         }
 426 }
 427
 428 void ClientCommand_selectteam(float request, float argc)
 429 {
 430         switch(request)
 431         {
 432                 case CMD_REQUEST_COMMAND:
 433                 {
 434                         if(argv(1) != "")
 435                         {
 436                                 if(IS_CLIENT(self))
 437                                 {
 438                                         if(teamplay)
 439                                                 if(self.team_forced <= 0)
 440                                                         if (!lockteams)
 441                                                         {
 442                                                                 float selection;
 443
 444                                                                 switch(argv(1))
 445                                                                 {
 446                                                                         case "red": selection = NUM_TEAM_1; break;
 447                                                                         case "blue": selection = NUM_TEAM_2; break;
 448                                                                         case "yellow": selection = NUM_TEAM_3; break;
 449                                                                         case "pink": selection = NUM_TEAM_4; break;
 450                                                                         case "auto": selection = (-1); break;
 451
 452                                                                         default: selection = 0; break;
 453                                                                 }
 454
 455                                                                 if(selection)
 456                                                                 {
 457                                                                         if(self.team == selection && self.deadflag == DEAD_NO)
 458                                                                                 sprint(self, "^7You already are on that team.\n");
 459                                                                         else if(self.wasplayer && autocvar_g_changeteam_banned)
 460                                                                                 sprint(self, "^1You cannot change team, forbidden by the server.\n");
 461                                                                         else
 462                                                                         {
 463                                                                                 if(autocvar_g_balance_teams && autocvar_g_balance_teams_prevent_imbalance)
 464                                                                                 {
 465                                                                                         CheckAllowedTeams(self);
 466                                                                                         GetTeamCounts(self);
 467                                                                                         if(!TeamSmallerEqThanTeam(Team_TeamToNumber(selection), Team_TeamToNumber(self.team), self))
 468                                                                                         {
 469                                                                                                 sprint(self, "Cannot change to a larger/better/shinier team\n");
 470                                                                                                 return;
 471                                                                                         }
 472                                                                                 }
 473                                                                                 ClientKill_TeamChange(selection);
 474                                                                         }
 475                                                                 }
 476                                                         }
 477                                                         else
 478                                                                 sprint(self, "^7The game has already begun, you must wait until the next map to be able to join a team.\n");
 479                                                 else
 480                                                         sprint(self, "^7selectteam can not be used as your team is forced\n");
 481                                         else
 482                                                 sprint(self, "^7selectteam can only be used in teamgames\n");
 483                                 }
 484                                 return;
 485                         }
 486                 }
 487
 488                 default:
 489                         sprint(self, "Incorrect parameters for ^2selectteam^7\n");
 490                 case CMD_REQUEST_USAGE:
 491                 {
 492                         sprint(self, "\nUsage:^3 cmd selectteam team\n");
 493                         sprint(self, "  Where 'team' is the prefered team to try and join.\n");
 494                         sprint(self, "  Full list of options here: \"red, blue, yellow, pink, auto\"\n");
 495                         return;
 496                 }
 497         }
 498 }
 499
 500 void ClientCommand_selfstuff(float request, string command)
 501 {
 502         switch(request)
 503         {
 504                 case CMD_REQUEST_COMMAND:
 505                 {
 506                         if(argv(1) != "")
 507                         {
 508                                 stuffcmd(self, substring(command, argv_start_index(1), argv_end_index(-1) - argv_start_index(1)));
 509                                 return;
 510                         }
 511                 }
 512
 513                 default:
 514                         sprint(self, "Incorrect parameters for ^2selectteam^7\n");
 515                 case CMD_REQUEST_USAGE:
 516                 {
 517                         sprint(self, "\nUsage:^3 cmd selfstuff <command>\n");
 518                         sprint(self, "  Where 'command' is the string to be stuffed to your client.\n");
 519                         return;
 520                 }
 521         }
 522 }
 523
 524 void ClientCommand_sentcvar(float request, float argc, string command)
 525 {
 526         switch(request)
 527         {
 528                 case CMD_REQUEST_COMMAND:
 529                 {
 530                         if(argv(1) != "")
 531                         {
 532                                 //float tokens;
 533                                 string s;
 534
 535                                 if(argc == 2) // undefined cvar: use the default value on the server then
 536                                 {
 537                                         s = strcat(substring(command, argv_start_index(0), argv_end_index(1) - argv_start_index(0)), " \"", cvar_defstring(argv(1)), "\"");
 538                                         tokenize_console(s);
 539                                 }
 540
 541                                 GetCvars(1);
 542
 543                                 return;
 544                         }
 545                 }
 546
 547                 default:
 548                         sprint(self, "Incorrect parameters for ^2sentcvar^7\n");
 549                 case CMD_REQUEST_USAGE:
 550                 {
 551                         sprint(self, "\nUsage:^3 cmd sentcvar <cvar>\n");
 552                         sprint(self, "  Where 'cvar' is the cvar plus arguments to send to the server.\n");
 553                         return;
 554                 }
 555         }
 556 }
 557
 558 void ClientCommand_spectate(float request)
 559 {
 560         switch(request)
 561         {
 562                 case CMD_REQUEST_COMMAND:
 563                 {
 564                         if(IS_CLIENT(self))
 565                         {
 566                                 if(g_lms)
 567                                 {
 568                                         if(self.lms_spectate_warning)
 569                                         {
 570                                                 // for the forfeit message...
 571                                                 self.lms_spectate_warning = 2;
 572                                                 // mark player as spectator
 573                                                 PlayerScore_Add(self, SP_LMS_RANK, 666 - PlayerScore_Add(self, SP_LMS_RANK, 0));
 574                                         }
 575                                         else
 576                                         {
 577                                                 self.lms_spectate_warning = 1;
 578                                                 sprint(self, "WARNING: you won't be able to enter the game again after spectating in LMS. Use the same command again to spectate anyway.\n");
 579                                                 return;
 580                                         }
 581                                 }
 582
 583                                 if(IS_PLAYER(self) && autocvar_sv_spectate == 1)
 584                                         ClientKill_TeamChange(-2); // observe
 585
 586                                 // in CA, allow a dead player to move to spectators (without that, caplayer!=0 will be moved back to the player list)
 587                                 // note: if arena game mode is ever done properly, this needs to be removed.
 588                                 if(self.caplayer && (IS_SPEC(self) || IS_OBSERVER(self)))
 589                                 {
 590                                         sprint(self, "WARNING: you will spectate in the next round.\n");
 591                                         self.caplayer = 0;
 592                                 }
 593                         }
 594                         return; // never fall through to usage
 595                 }
 596
 597                 default:
 598                 case CMD_REQUEST_USAGE:
 599                 {
 600                         sprint(self, "\nUsage:^3 cmd spectate\n");
 601                         sprint(self, "  No arguments required.\n");
 602                         return;
 603                 }
 604         }
 605 }
 606
 607 void ClientCommand_suggestmap(float request, float argc)
 608 {
 609         switch(request)
 610         {
 611                 case CMD_REQUEST_COMMAND:
 612                 {
 613                         if(argv(1) != "")
 614                         {
 615                                 sprint(self, strcat(MapVote_Suggest(argv(1)), "\n"));
 616                                 return;
 617                         }
 618                 }
 619
 620                 default:
 621                         sprint(self, "Incorrect parameters for ^2suggestmap^7\n");
 622                 case CMD_REQUEST_USAGE:
 623                 {
 624                         sprint(self, "\nUsage:^3 cmd suggestmap map\n");
 625                         sprint(self, "  Where 'map' is the name of the map to suggest.\n");
 626                         return;
 627                 }
 628         }
 629 }
 630
 631 void ClientCommand_tell(float request, float argc, string command)
 632 {
 633         switch(request)
 634         {
 635                 case CMD_REQUEST_COMMAND:
 636                 {
 637                         if(argc >= 3)
 638                         {
 639                                 entity tell_to = GetIndexedEntity(argc, 1);
 640                                 float tell_accepted = VerifyClientEntity(tell_to, TRUE, FALSE);
 641
 642                                 if(tell_accepted > 0) // the target is a real client
 643                                 {
 644                                         if(tell_to != self) // and we're allowed to send to them :D
 645                                         {
 646                                                 Say(self, FALSE, tell_to, substring(command, argv_start_index(next_token), argv_end_index(-1) - argv_start_index(next_token)), TRUE);
 647                                                 return;
 648                                         }
 649                                         else { print_to(self, "You can't ^2tell^7 a message to yourself."); return; }
 650                                 }
 651                                 else if(argv(1) == "#0")
 652                                 {
 653                                         trigger_magicear_processmessage_forallears(self, -1, world, substring(command, argv_start_index(next_token), argv_end_index(-1) - argv_start_index(next_token)));
 654                                         return;
 655                                 }
 656                                 else { print_to(self, strcat("tell: ", GetClientErrorString(tell_accepted, argv(1)), ".")); return; }
 657                         }
 658                 }
 659
 660                 default:
 661                         sprint(self, "Incorrect parameters for ^2tell^7\n");
 662                 case CMD_REQUEST_USAGE:
 663                 {
 664                         sprint(self, "\nUsage:^3 cmd tell client <message>\n");
 665                         sprint(self, "  Where 'client' is the entity number or name of the player to send 'message' to.\n");
 666                         return;
 667                 }
 668         }
 669 }
 670
 671 void ClientCommand_voice(float request, float argc, string command)
 672 {
 673         switch(request)
 674         {
 675                 case CMD_REQUEST_COMMAND:
 676                 {
 677                         if(argv(1) != "")
 678                         {
 679                                 if(argc >= 3)
 680                                         VoiceMessage(argv(1), substring(command, argv_start_index(2), argv_end_index(-1) - argv_start_index(2)));
 681                                 else
 682                                         VoiceMessage(argv(1), "");
 683
 684                                 return;
 685                         }
 686                 }
 687
 688                 default:
 689                         sprint(self, "Incorrect parameters for ^2voice^7\n");
 690                 case CMD_REQUEST_USAGE:
 691                 {
 692                         sprint(self, "\nUsage:^3 cmd voice messagetype <soundname>\n");
 693                         sprint(self, "  'messagetype' is the type of broadcast to do, like team only or such,\n");
 694                         sprint(self, "  and 'soundname' is the string/filename of the sound/voice message to play.\n");
 695                         return;
 696                 }
 697         }
 698 }
 699
 700 /* use this when creating a new command, making sure to place it in alphabetical order... also,
 701 ** ADD ALL NEW COMMANDS TO commands.cfg WITH PROPER ALIASES IN THE SAME FASHION!
 702 void ClientCommand_(float request)
 703 {
 704         switch(request)
 705         {
 706                 case CMD_REQUEST_COMMAND:
 707                 {
 708
 709                         return; // never fall through to usage
 710                 }
 711
 712                 default:
 713                 case CMD_REQUEST_USAGE:
 714                 {
 715                         sprint(self, "\nUsage:^3 cmd \n");
 716                         sprint(self, "  No arguments required.\n");
 717                         return;
 718                 }
 719         }
 720 }
 721 */
 722
 723
 724 // =====================================
 725 //  Macro system for networked commands
 726 // =====================================
 727
 728 // Do not hard code aliases for these, instead create them in commands.cfg... also: keep in alphabetical order, please ;)
 729 #define CLIENT_COMMANDS(request,arguments,command) \
 730         CLIENT_COMMAND("autoswitch", ClientCommand_autoswitch(request, arguments), "Whether or not to switch automatically when getting a better weapon") \
 731         CLIENT_COMMAND("checkfail", ClientCommand_checkfail(request, command), "Report if a client-side check failed") \
 732         CLIENT_COMMAND("clientversion", ClientCommand_clientversion(request, arguments), "Release version of the game") \
 733         CLIENT_COMMAND("mv_getpicture", ClientCommand_mv_getpicture(request, arguments), "Retrieve mapshot picture from the server") \
 734         CLIENT_COMMAND("join", ClientCommand_join(request), "Become a player in the game") \
 735         CLIENT_COMMAND("mobedit", ClientCommand_mobedit(request, arguments), "Edit your monster's properties") \
 736         CLIENT_COMMAND("mobkill", ClientCommand_mobkill(request), "Kills your monster") \
 737         CLIENT_COMMAND("mobspawn", ClientCommand_mobspawn(request, arguments), "Spawn monsters infront of yourself") \
 738         CLIENT_COMMAND("ready", ClientCommand_ready(request), "Qualify as ready to end warmup stage (or restart server if allowed)") \
 739         CLIENT_COMMAND("say", ClientCommand_say(request, arguments, command), "Print a message to chat to all players") \
 740         CLIENT_COMMAND("say_team", ClientCommand_say_team(request, arguments, command), "Print a message to chat to all team mates") \
 741         CLIENT_COMMAND("selectteam", ClientCommand_selectteam(request, arguments), "Attempt to choose a team to join into") \
 742         CLIENT_COMMAND("selfstuff", ClientCommand_selfstuff(request, command), "Stuffcmd a command to your own client") \
 743         CLIENT_COMMAND("sentcvar", ClientCommand_sentcvar(request, arguments, command), "New system for sending a client cvar to the server") \
 744         CLIENT_COMMAND("spectate", ClientCommand_spectate(request), "Become an observer") \
 745         CLIENT_COMMAND("suggestmap", ClientCommand_suggestmap(request, arguments), "Suggest a map to the mapvote at match end") \
 746         CLIENT_COMMAND("tell", ClientCommand_tell(request, arguments, command), "Send a message directly to a player") \
 747         CLIENT_COMMAND("voice", ClientCommand_voice(request, arguments, command), "Send voice message via sound") \
 748         /* nothing */
 749
 750 void ClientCommand_macro_help()
 751 {
 752         #define CLIENT_COMMAND(name,function,description) \
 753                 { sprint(self, "  ^2", name, "^7: ", description, "\n"); }
 754
 755         CLIENT_COMMANDS(0, 0, "")
 756         #undef CLIENT_COMMAND
 757
 758         return;
 759 }
 760
 761 float ClientCommand_macro_command(float argc, string command)
 762 {
 763         #define CLIENT_COMMAND(name,function,description) \
 764                 { if(name == strtolower(argv(0))) { function; return TRUE; } }
 765
 766         CLIENT_COMMANDS(CMD_REQUEST_COMMAND, argc, command)
 767         #undef CLIENT_COMMAND
 768
 769         return FALSE;
 770 }
 771
 772 float ClientCommand_macro_usage(float argc)
 773 {
 774         #define CLIENT_COMMAND(name,function,description) \
 775                 { if(name == strtolower(argv(1))) { function; return TRUE; } }
 776
 777         CLIENT_COMMANDS(CMD_REQUEST_USAGE, argc, "")
 778         #undef CLIENT_COMMAND
 779
 780         return FALSE;
 781 }
 782
 783 void ClientCommand_macro_write_aliases(float fh)
 784 {
 785         #define CLIENT_COMMAND(name,function,description) \
 786                 { CMD_Write_Alias("qc_cmd_cmd", name, description); }
 787
 788         CLIENT_COMMANDS(0, 0, "")
 789         #undef CLIENT_COMMAND
 790
 791         return;
 792 }
 793
 794 // ======================================
 795 //  Main Function Called By Engine (cmd)
 796 // ======================================
 797 // If this function exists, server game code parses clientcommand before the engine code gets it.
 798
 799 void SV_ParseClientCommand(string command)
 800 {
 801         // if we're banned, don't even parse the command
 802         if(Ban_MaybeEnforceBanOnce(self))
 803                 return;
 804
 805         float argc = tokenize_console(command);
 806
 807         // for the mutator hook system
 808         cmd_name = strtolower(argv(0));
 809         cmd_argc = argc;
 810         cmd_string = command;
 811
 812         // Guide for working with argc arguments by example:
 813         // argc:   1    - 2      - 3     - 4
 814         // argv:   0    - 1      - 2     - 3
 815         // cmd     vote - master - login - password
 816
 817         // for floodcheck
 818         switch(strtolower(argv(0)))
 819         {
 820                 // exempt commands which are not subject to floodcheck
 821                 case "begin": break; // handled by engine in host_cmd.c
 822                 case "download": break; // handled by engine in cl_parse.c
 823                 case "mv_getpicture": break; // handled by server in this file
 824                 case "pause": break; // handled by engine in host_cmd.c
 825                 case "prespawn": break; // handled by engine in host_cmd.c
 826                 case "sentcvar": break; // handled by server in this file
 827                 case "spawn": break; // handled by engine in host_cmd.c
 828
 829                 default:
 830                         if(SV_ParseClientCommand_floodcheck())
 831                                 break; // "TRUE": continue, as we're not flooding yet
 832                         else
 833                                 return; // "FALSE": not allowed to continue, halt // print("^1ERROR: ^7ANTISPAM CAUGHT: ", command, ".\n");
 834         }
 835
 836         /* NOTE: should this be disabled? It can be spammy perhaps, but hopefully it's okay for now */
 837         if(argv(0) == "help")
 838         {
 839                 if(argc == 1)
 840                 {
 841                         sprint(self, "\nClient networked commands:\n");
 842                         ClientCommand_macro_help();
 843
 844                         sprint(self, "\nCommon networked commands:\n");
 845                         CommonCommand_macro_help(self);
 846
 847                         sprint(self, "\nUsage:^3 cmd COMMAND...^7, where possible commands are listed above.\n");
 848                         sprint(self, "For help about a specific command, type cmd help COMMAND\n");
 849                         return;
 850                 }
 851                 else if(CommonCommand_macro_usage(argc, self)) // Instead of trying to call a command, we're going to see detailed information about it
 852                 {
 853                         return;
 854                 }
 855                 else if(ClientCommand_macro_usage(argc)) // same, but for normal commands now
 856                 {
 857                         return;
 858                 }
 859         }
 860         else if(MUTATOR_CALLHOOK(SV_ParseClientCommand))
 861         {
 862                 return; // handled by a mutator
 863         }
 864         else if(CheatCommand(argc))
 865         {
 866                 return; // handled by server/cheats.qc
 867         }
 868         else if(CommonCommand_macro_command(argc, self, command))
 869         {
 870                 return; // handled by server/command/common.qc
 871         }
 872         else if(ClientCommand_macro_command(argc, command)) // continue as usual and scan for normal commands
 873         {
 874                 return; // handled by one of the above ClientCommand_* functions
 875         }
 876         else
 877                 clientcommand(self, command);
 878 }