Merge branch 'master' into Mario/monsters
[xonotic/xonotic-data.pk3dir.git] / qcsrc / server / command / cmd.qc
1 // =========================================================
2 //  Server side networked commands code, reworked by Samual
3 //  Last updated: December 28th, 2011
4 // =========================================================
5
6 float SV_ParseClientCommand_floodcheck()
7 {
8         if not(timeout_status) // not while paused
9         {
10                 if(time <= (self.cmd_floodtime + autocvar_sv_clientcommand_antispam_time))
11                 {
12                         self.cmd_floodcount += 1;
13                         if(self.cmd_floodcount > autocvar_sv_clientcommand_antispam_count) { return FALSE; } // too much spam, halt
14                 }
15                 else
16                 {
17                         self.cmd_floodtime = time;
18                         self.cmd_floodcount = 1;
19                 }
20         }
21         return TRUE; // continue, as we're not flooding yet
22 }
23
24
25 // =======================
26 //  Command Sub-Functions
27 // =======================
28
29 void ClientCommand_autoswitch(float request, float argc)
30 {
31         switch(request)
32         {
33                 case CMD_REQUEST_COMMAND:
34                 {
35                         if(argv(1) != "")
36                         {
37                                 self.autoswitch = InterpretBoolean(argv(1));
38                                 sprint(self, strcat("^1autoswitch is currently turned ", (self.autoswitch ? "on" : "off"), ".\n"));
39                                 return;
40                         }
41                 }
42                         
43                 default:
44                         sprint(self, "Incorrect parameters for ^2autoswitch^7\n");
45                 case CMD_REQUEST_USAGE:
46                 {
47                         sprint(self, "\nUsage:^3 cmd autoswitch selection\n");
48                         sprint(self, "  Where 'selection' controls if autoswitch is on or off.\n"); 
49                         return;
50                 }
51         }
52 }
53
54 void ClientCommand_checkfail(float request, string command) // internal command, used only by code
55 {
56         switch(request)
57         {
58                 case CMD_REQUEST_COMMAND:
59                 {
60                         print(sprintf("CHECKFAIL: %s (%s) epically failed check %s\n", self.netname, self.netaddress, substring(command, argv_start_index(1), argv_end_index(-1) - argv_start_index(1))));
61                         self.checkfail = 1;
62                         return; // never fall through to usage
63                 }
64                         
65                 default:
66                         sprint(self, "Incorrect parameters for ^2checkfail^7\n");
67                 case CMD_REQUEST_USAGE:
68                 {
69                         sprint(self, "\nUsage:^3 cmd checkfail <message>\n");
70                         sprint(self, "  Where 'message' is the message reported by client about the fail.\n");
71                         return;
72                 }
73         }
74 }
75
76 void ClientCommand_clientversion(float request, float argc) // internal command, used only by code
77 {
78         switch(request)
79         {
80                 case CMD_REQUEST_COMMAND:
81                 {
82                         if(argv(1) != "")
83                         {
84                                 if(IS_CLIENT(self))
85                                 {
86                                         self.version = ((argv(1) == "$gameversion") ? 1 : stof(argv(1)));
87                                         
88                                         if(self.version < autocvar_gameversion_min || self.version > autocvar_gameversion_max)
89                                         {
90                                                 self.version_mismatch = 1;
91                                                 ClientKill_TeamChange(-2); // observe
92                                         } 
93                                         else if(autocvar_g_campaign || autocvar_g_balance_teams) 
94                                         {
95                                                 //JoinBestTeam(self, FALSE, TRUE);
96                                         } 
97                                         else if(teamplay && !autocvar_sv_spectate && !(self.team_forced > 0)) 
98                                         {
99                                                 self.classname = "observer"; // really?
100                                                 stuffcmd(self, "menu_showteamselect\n");
101                                         }
102                                 }
103                                 
104                                 return;
105                         }
106                 }
107                         
108                 default:
109                         sprint(self, "Incorrect parameters for ^2clientversion^7\n");
110                 case CMD_REQUEST_USAGE:
111                 {
112                         sprint(self, "\nUsage:^3 cmd clientversion version\n");
113                         sprint(self, "  Where 'version' is the game version reported by self.\n");
114                         return;
115                 }
116         }
117 }
118
119 void ClientCommand_mv_getpicture(float request, float argc) // internal command, used only by code
120 {
121         switch(request)
122         {
123                 case CMD_REQUEST_COMMAND:
124                 {
125                         if(argv(1) != "")
126                         {
127                                 if(intermission_running)                                
128                                         MapVote_SendPicture(stof(argv(1)));
129
130                                 return;
131                         }
132                 }
133                         
134                 default:
135                         sprint(self, "Incorrect parameters for ^2mv_getpicture^7\n");
136                 case CMD_REQUEST_USAGE:
137                 {
138                         sprint(self, "\nUsage:^3 cmd mv_getpicture mapid\n");
139                         sprint(self, "  Where 'mapid' is the id number of the map to request an image of on the map vote selection menu.\n");
140                         return;
141                 }
142         }
143 }
144
145 void ClientCommand_join(float request) 
146 {
147         switch(request)
148         {
149                 case CMD_REQUEST_COMMAND:
150                 {
151                         if(IS_CLIENT(self))
152                         {
153                                 if(!IS_PLAYER(self) && !lockteams && !g_arena)
154                                 {
155                                         if(nJoinAllowed(self)) 
156                                         {
157                                                 if(autocvar_g_campaign) { campaign_bots_may_start = 1; }
158
159                                                 self.classname = "player";
160                                                 PlayerScore_Clear(self);
161                                                 Kill_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER_CPID, CPID_PREVENT_JOIN);
162                                                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_JOIN_PLAY, self.netname);
163                                                 PutClientInServer();
164                                         }
165                                         else 
166                                         {
167                                                 //player may not join because of g_maxplayers is set
168                                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_JOIN_PREVENT);
169                                         }
170                                 }
171                         }
172                         return; // never fall through to usage
173                 }
174                         
175                 default:
176                 case CMD_REQUEST_USAGE:
177                 {
178                         sprint(self, "\nUsage:^3 cmd join\n");
179                         sprint(self, "  No arguments required.\n");
180                         return;
181                 }
182         }
183 }
184
185 void ClientCommand_mobedit(float request, float argc)
186 {
187         switch(request)
188         {
189                 case CMD_REQUEST_COMMAND:
190                 {
191                         makevectors(self.v_angle);
192                         WarpZone_TraceLine(self.origin + self.view_ofs, self.origin + self.view_ofs + v_forward * 100, MOVE_NORMAL, self);
193                         
194                         if not(trace_ent.flags & FL_MONSTER) { sprint(self, "You need to aim at your monster to edit its properties.\n"); return; }
195                         if(trace_ent.realowner != self) { sprint(self, "That monster does not belong to you.\n"); return; }
196                         
197                         switch(argv(1))
198                         {
199                                 case "skin": if(trace_ent.monsterid != MON_MAGE) { trace_ent.skin = stof(argv(2)); trace_ent.SendFlags |= MSF_STATUS; } return;
200                                 case "movetarget": trace_ent.monster_moveflags = stof(argv(2)); return;
201                         }
202                 }
203                 default:
204                         sprint(self, "Incorrect parameters for ^2mobedit^7\n");
205                 case CMD_REQUEST_USAGE:
206                 {
207                         sprint(self, "\nUsage:^3 cmd mobedit [argument]\n");
208                         sprint(self, "  Where 'argument' can be skin or movetarget.\n");
209                         return;
210                 }
211         }
212 }
213         
214 void ClientCommand_mobkill(float request)
215 {
216         switch(request)
217         {
218                 case CMD_REQUEST_COMMAND:
219                 {
220                         makevectors(self.v_angle);
221                         WarpZone_TraceLine(self.origin + self.view_ofs, self.origin + self.view_ofs + v_forward * 100, MOVE_NORMAL, self);
222                         
223                         if(trace_ent.flags & FL_MONSTER)
224                         {
225                                 if(trace_ent.realowner != self)
226                                 {
227                                         sprint(self, "That monster does not belong to you.\n");
228                                         return;
229                                 }
230                                 sprint(self, strcat("Your pet '", trace_ent.monster_name, "' has been brutally mutilated.\n"));
231                                 Damage (trace_ent, world, world, trace_ent.health + trace_ent.max_health + 200, DEATH_KILL, trace_ent.origin, '0 0 0');
232                                 return;
233                         }
234                         else
235                                 sprint(self, "You need to aim at your monster to kill it.\n");
236                         
237                         return;
238                 }
239         
240                 default:
241                         sprint(self, "Incorrect parameters for ^2mobkill^7\n");
242                 case CMD_REQUEST_USAGE:
243                 {
244                         sprint(self, "\nUsage:^3 cmd mobkill\n");
245                         sprint(self, "  Aim at your monster to kill it.\n");
246                         return;
247                 }
248         }
249 }
250
251 void ClientCommand_mobspawn(float request, float argc)
252 {
253         switch(request)
254         {
255                 case CMD_REQUEST_COMMAND:
256                 {
257                         entity e;
258                         string tospawn;
259                         float moveflag;
260                         
261                         moveflag = (argv(2) ? stof(argv(2)) : 1); // follow owner if not defined
262                         tospawn = strtolower(argv(1));
263                         
264                         if(tospawn == "list")
265                         {
266                                 float i;
267                                 string list = "Available monsters:";
268                                 
269                                 for(i = MON_FIRST; i <= MON_LAST; ++i)
270                                         list = strcat(list, " ", (get_monsterinfo(i)).netname);
271                                 
272                                 sprint(self, strcat(list, "\n"));
273                                 
274                                 return;
275                         }
276                         
277                         if(autocvar_g_monsters_max <= 0 || autocvar_g_monsters_max_perplayer <= 0) { sprint(self, "Monster spawning is disabled.\n"); }
278                         else if(!IS_PLAYER(self)) { sprint(self, "You can't spawn monsters while spectating.\n"); }
279                         else if(g_invasion) { sprint(self, "You can't spawn monsters during an invasion!\n"); }
280                         else if not(autocvar_g_monsters) { Send_Notification(NOTIF_ONE, self, MSG_INFO, INFO_MONSTERS_DISABLED); }
281                         else if(self.vehicle) { sprint(self, "You can't spawn monsters while driving a vehicle.\n"); }
282                         else if(autocvar_g_campaign) { sprint(self, "You can't spawn monsters in campaign mode.\n"); }
283                         else if(self.deadflag != DEAD_NO) { sprint(self, "You can't spawn monsters while dead.\n"); }
284                         else if(self.monstercount >= autocvar_g_monsters_max_perplayer) { sprint(self, "You have spawned too many monsters, kill some before trying to spawn any more.\n"); }
285                         else if(totalspawned >= autocvar_g_monsters_max) { sprint(self, "The global maximum monster count has been reached, kill some before trying to spawn any more.\n"); }
286                         else // all worked out, so continue
287                         {
288                                 self.monstercount += 1;
289                                 totalspawned += 1;
290                         
291                                 makevectors(self.v_angle);
292                                 WarpZone_TraceBox (CENTER_OR_VIEWOFS(self), PL_MIN, PL_MAX, CENTER_OR_VIEWOFS(self) + v_forward * 150, TRUE, self);
293                                 //WarpZone_TraceLine(self.origin + self.view_ofs, self.origin + self.view_ofs + v_forward * 150, MOVE_NORMAL, self);
294                         
295                                 e = spawnmonster(tospawn, 0, self, self, trace_endpos, FALSE, moveflag);
296                                 
297                                 sprint(self, strcat("Spawned ", e.monster_name, "\n"));
298                         }
299                         
300                         return;
301                 }
302         
303                 default:
304                         sprint(self, "Incorrect parameters for ^2mobspawn^7\n");
305                 case CMD_REQUEST_USAGE:
306                 {
307                         sprint(self, "\nUsage:^3 cmd mobspawn monster\n");
308                         sprint(self, "  See 'cmd mobspawn list' for available arguments.\n");
309                         return;
310                 }
311         }
312 }
313
314 void ClientCommand_ready(float request) // todo: anti-spam for toggling readyness
315 {
316         switch(request)
317         {
318                 case CMD_REQUEST_COMMAND:
319                 {
320                         if(IS_CLIENT(self))
321                         {
322                                 if(warmup_stage || autocvar_sv_ready_restart || g_race_qualifying == 2)
323                                 {
324                                         if(!readyrestart_happened || autocvar_sv_ready_restart_repeatable)
325                                         {
326                                                 if(time < game_starttime) // game is already restarting
327                                                         return;
328                                                 if (self.ready) // toggle
329                                                 {
330                                                         self.ready = FALSE;
331                                                         bprint(self.netname, "^2 is ^1NOT^2 ready\n");
332                                                 }
333                                                 else
334                                                 {
335                                                         self.ready = TRUE;
336                                                         bprint(self.netname, "^2 is ready\n");
337                                                 }
338
339                                                 // cannot reset the game while a timeout is active!
340                                                 if not(timeout_status)
341                                                         ReadyCount();
342                                         } else {
343                                                 sprint(self, "^1Game has already been restarted\n");
344                                         }
345                                 }
346                         }
347                         return; // never fall through to usage
348                 }
349                         
350                 default:
351                 case CMD_REQUEST_USAGE:
352                 {
353                         sprint(self, "\nUsage:^3 cmd ready\n");
354                         sprint(self, "  No arguments required.\n");
355                         return;
356                 }
357         }
358 }
359
360 void ClientCommand_say(float request, float argc, string command)
361 {
362         switch(request)
363         {
364                 case CMD_REQUEST_COMMAND:
365                 {
366                         if(argc >= 2) { Say(self, FALSE, world, substring(command, argv_start_index(1), argv_end_index(-1) - argv_start_index(1)), 1); }
367                         return; // never fall through to usage
368                 }
369                         
370                 default:
371                 case CMD_REQUEST_USAGE:
372                 {
373                         sprint(self, "\nUsage:^3 cmd say <message>\n");
374                         sprint(self, "  Where 'message' is the string of text to say.\n");
375                         return;
376                 }
377         }
378 }
379
380 void ClientCommand_say_team(float request, float argc, string command)
381 {
382         switch(request)
383         {
384                 case CMD_REQUEST_COMMAND:
385                 {
386                         if(argc >= 2) { Say(self, TRUE, world, substring(command, argv_start_index(1), argv_end_index(-1) - argv_start_index(1)), 1); }
387                         return; // never fall through to usage
388                 }
389                         
390                 default:
391                 case CMD_REQUEST_USAGE:
392                 {
393                         sprint(self, "\nUsage:^3 cmd say_team <message>\n");
394                         sprint(self, "  Where 'message' is the string of text to say.\n");
395                         return;
396                 }
397         }
398 }
399
400 void ClientCommand_selectteam(float request, float argc)
401 {
402         switch(request)
403         {
404                 case CMD_REQUEST_COMMAND:
405                 {
406                         if(argv(1) != "")
407                         {
408                                 if(IS_CLIENT(self))
409                                 {
410                                         if(teamplay)
411                                                 if not(self.team_forced > 0) 
412                                                         if not(lockteams) 
413                                                         {
414                                                                 float selection;
415                                                                 
416                                                                 switch(argv(1))
417                                                                 {
418                                                                         case "red": selection = NUM_TEAM_1; break;
419                                                                         case "blue": selection = NUM_TEAM_2; break;
420                                                                         case "yellow": selection = NUM_TEAM_3; break;
421                                                                         case "pink": selection = NUM_TEAM_4; break;
422                                                                         case "auto": selection = (-1); break;
423                                                                         
424                                                                         default: selection = 0; break;
425                                                                 }
426                                                                 
427                                                                 if(selection)
428                                                                 {
429                                                                         if(self.team == selection && self.deadflag == DEAD_NO)
430                                                                                 sprint(self, "^7You already are on that team.\n");
431                                                                         else if(self.wasplayer && autocvar_g_changeteam_banned)
432                                                                                 sprint(self, "^1You cannot change team, forbidden by the server.\n");
433                                                                         else
434                                                                                 ClientKill_TeamChange(selection);
435                                                                 }
436                                                         }
437                                                         else
438                                                                 sprint(self, "^7The game has already begun, you must wait until the next map to be able to join a team.\n");
439                                                 else
440                                                         sprint(self, "^7selectteam can not be used as your team is forced\n");
441                                         else
442                                                 sprint(self, "^7selectteam can only be used in teamgames\n");
443                                 }
444                                 return; 
445                         }
446                 }
447
448                 default:
449                         sprint(self, "Incorrect parameters for ^2selectteam^7\n");
450                 case CMD_REQUEST_USAGE:
451                 {
452                         sprint(self, "\nUsage:^3 cmd selectteam team\n");
453                         sprint(self, "  Where 'team' is the prefered team to try and join.\n");
454                         sprint(self, "  Full list of options here: \"red, blue, yellow, pink, auto\"\n");
455                         return;
456                 }
457         }
458 }
459
460 void ClientCommand_selfstuff(float request, string command)
461 {
462         switch(request)
463         {
464                 case CMD_REQUEST_COMMAND:
465                 {
466                         if(argv(1) != "")
467                         {
468                                 stuffcmd(self, substring(command, argv_start_index(1), argv_end_index(-1) - argv_start_index(1)));
469                                 return;
470                         }
471                 }
472                         
473                 default:
474                         sprint(self, "Incorrect parameters for ^2selectteam^7\n");
475                 case CMD_REQUEST_USAGE:
476                 {
477                         sprint(self, "\nUsage:^3 cmd selfstuff <command>\n");
478                         sprint(self, "  Where 'command' is the string to be stuffed to your client.\n");
479                         return;
480                 }
481         }
482 }
483
484 void ClientCommand_sentcvar(float request, float argc, string command)
485 {
486         switch(request)
487         {
488                 case CMD_REQUEST_COMMAND:
489                 {
490                         if(argv(1) != "")
491                         {
492                                 //float tokens;
493                                 string s;
494                                 
495                                 if(argc == 2) // undefined cvar: use the default value on the server then
496                                 {
497                                         s = strcat(substring(command, argv_start_index(0), argv_end_index(1) - argv_start_index(0)), " \"", cvar_defstring(argv(1)), "\"");
498                                         tokenize_console(s);
499                                 }
500                                 
501                                 GetCvars(1);
502                                 
503                                 return;
504                         }
505                 }
506                         
507                 default:
508                         sprint(self, "Incorrect parameters for ^2sentcvar^7\n");
509                 case CMD_REQUEST_USAGE:
510                 {
511                         sprint(self, "\nUsage:^3 cmd sentcvar <cvar>\n");
512                         sprint(self, "  Where 'cvar' is the cvar plus arguments to send to the server.\n");
513                         return;
514                 }
515         }
516 }
517
518 void ClientCommand_spectate(float request) 
519 {
520         switch(request)
521         {
522                 case CMD_REQUEST_COMMAND:
523                 {
524                         if(IS_CLIENT(self))
525                         {
526                                 if(g_arena) { return; } 
527                                 if(g_lms)
528                                 {
529                                         if(self.lms_spectate_warning)
530                                         {
531                                                 // for the forfeit message...
532                                                 self.lms_spectate_warning = 2;
533                                                 // mark player as spectator
534                                                 PlayerScore_Add(self, SP_LMS_RANK, 666 - PlayerScore_Add(self, SP_LMS_RANK, 0));
535                                         }
536                                         else
537                                         {
538                                                 self.lms_spectate_warning = 1;
539                                                 sprint(self, "WARNING: you won't be able to enter the game again after spectating in LMS. Use the same command again to spectate anyway.\n");
540                                                 return;
541                                         }
542                                 }
543                                 
544                                 if(IS_PLAYER(self) && autocvar_sv_spectate == 1) 
545                                         ClientKill_TeamChange(-2); // observe
546
547                                 // in CA, allow a dead player to move to spectators (without that, caplayer!=0 will be moved back to the player list)
548                                 // note: if arena game mode is ever done properly, this needs to be removed.
549                                 if(self.caplayer && (IS_SPEC(self) || IS_OBSERVER(self)))
550                                 {
551                                         sprint(self, "WARNING: you will spectate in the next round.\n");
552                                         self.caplayer = 0;
553                                 }
554                         }
555                         return; // never fall through to usage
556                 }
557                         
558                 default:
559                 case CMD_REQUEST_USAGE:
560                 {
561                         sprint(self, "\nUsage:^3 cmd spectate\n");
562                         sprint(self, "  No arguments required.\n");
563                         return;
564                 }
565         }
566 }
567
568 void ClientCommand_suggestmap(float request, float argc)
569 {
570         switch(request)
571         {
572                 case CMD_REQUEST_COMMAND:
573                 {
574                         if(argv(1) != "")
575                         {
576                                 sprint(self, strcat(MapVote_Suggest(argv(1)), "\n"));
577                                 return;
578                         }
579                 }
580                         
581                 default:
582                         sprint(self, "Incorrect parameters for ^2suggestmap^7\n");
583                 case CMD_REQUEST_USAGE:
584                 {
585                         sprint(self, "\nUsage:^3 cmd suggestmap map\n");
586                         sprint(self, "  Where 'map' is the name of the map to suggest.\n");
587                         return;
588                 }
589         }
590 }
591
592 void ClientCommand_tell(float request, float argc, string command)
593 {
594         switch(request)
595         {
596                 case CMD_REQUEST_COMMAND:
597                 {
598                         if(argc >= 3)
599                         {
600                                 entity tell_to = GetIndexedEntity(argc, 1);
601                                 float tell_accepted = VerifyClientEntity(tell_to, TRUE, FALSE);
602                                 
603                                 if(tell_accepted > 0) // the target is a real client
604                                 {
605                                         if(tell_to != self) // and we're allowed to send to them :D
606                                         {
607                                                 Say(self, FALSE, tell_to, substring(command, argv_start_index(next_token), argv_end_index(-1) - argv_start_index(next_token)), TRUE);
608                                                 return;
609                                         }
610                                         else { print_to(self, "You can't ^2tell^7 a message to yourself."); return; }
611                                 }
612                                 else if(argv(1) == "#0") 
613                                 { 
614                                         trigger_magicear_processmessage_forallears(self, -1, world, substring(command, argv_start_index(next_token), argv_end_index(-1) - argv_start_index(next_token)));
615                                         return;
616                                 }
617                                 else { print_to(self, strcat("tell: ", GetClientErrorString(tell_accepted, argv(1)), ".")); return; }
618                         }
619                 }
620                         
621                 default:
622                         sprint(self, "Incorrect parameters for ^2tell^7\n");
623                 case CMD_REQUEST_USAGE:
624                 {
625                         sprint(self, "\nUsage:^3 cmd tell client <message>\n");
626                         sprint(self, "  Where 'client' is the entity number or name of the player to send 'message' to.\n");
627                         return;
628                 }
629         }
630 }
631
632 void ClientCommand_voice(float request, float argc, string command) 
633 {
634         switch(request)
635         {
636                 case CMD_REQUEST_COMMAND:
637                 {
638                         if(argv(1) != "")
639                         {
640                                 if(argc >= 3)
641                                         VoiceMessage(argv(1), substring(command, argv_start_index(2), argv_end_index(-1) - argv_start_index(2)));
642                                 else
643                                         VoiceMessage(argv(1), "");
644                                         
645                                 return;
646                         }
647                 }
648                         
649                 default:
650                         sprint(self, "Incorrect parameters for ^2voice^7\n");
651                 case CMD_REQUEST_USAGE:
652                 {
653                         sprint(self, "\nUsage:^3 cmd voice messagetype <soundname>\n");
654                         sprint(self, "  'messagetype' is the type of broadcast to do, like team only or such,\n");
655                         sprint(self, "  and 'soundname' is the string/filename of the sound/voice message to play.\n");
656                         return;
657                 }
658         }
659 }
660
661 /* use this when creating a new command, making sure to place it in alphabetical order... also,
662 ** ADD ALL NEW COMMANDS TO commands.cfg WITH PROPER ALIASES IN THE SAME FASHION!
663 void ClientCommand_(float request)
664 {
665         switch(request)
666         {
667                 case CMD_REQUEST_COMMAND:
668                 {
669                         
670                         return; // never fall through to usage
671                 }
672                         
673                 default:
674                 case CMD_REQUEST_USAGE:
675                 {
676                         sprint(self, "\nUsage:^3 cmd \n");
677                         sprint(self, "  No arguments required.\n");
678                         return;
679                 }
680         }
681 }
682 */
683
684
685 // =====================================
686 //  Macro system for networked commands
687 // =====================================
688
689 // Do not hard code aliases for these, instead create them in commands.cfg... also: keep in alphabetical order, please ;)
690 #define CLIENT_COMMANDS(request,arguments,command) \
691         CLIENT_COMMAND("autoswitch", ClientCommand_autoswitch(request, arguments), "Whether or not to switch automatically when getting a better weapon") \
692         CLIENT_COMMAND("checkfail", ClientCommand_checkfail(request, command), "Report if a client-side check failed") \
693         CLIENT_COMMAND("clientversion", ClientCommand_clientversion(request, arguments), "Release version of the game") \
694         CLIENT_COMMAND("mv_getpicture", ClientCommand_mv_getpicture(request, arguments), "Retrieve mapshot picture from the server") \
695         CLIENT_COMMAND("join", ClientCommand_join(request), "Become a player in the game") \
696         CLIENT_COMMAND("mobedit", ClientCommand_mobedit(request, arguments), "Edit your monster's properties") \
697         CLIENT_COMMAND("mobkill", ClientCommand_mobkill(request), "Kills your monster") \
698         CLIENT_COMMAND("mobspawn", ClientCommand_mobspawn(request, arguments), "Spawn monsters infront of yourself") \
699         CLIENT_COMMAND("ready", ClientCommand_ready(request), "Qualify as ready to end warmup stage (or restart server if allowed)") \
700         CLIENT_COMMAND("say", ClientCommand_say(request, arguments, command), "Print a message to chat to all players") \
701         CLIENT_COMMAND("say_team", ClientCommand_say_team(request, arguments, command), "Print a message to chat to all team mates") \
702         CLIENT_COMMAND("selectteam", ClientCommand_selectteam(request, arguments), "Attempt to choose a team to join into") \
703         CLIENT_COMMAND("selfstuff", ClientCommand_selfstuff(request, command), "Stuffcmd a command to your own client") \
704         CLIENT_COMMAND("sentcvar", ClientCommand_sentcvar(request, arguments, command), "New system for sending a client cvar to the server") \
705         CLIENT_COMMAND("spectate", ClientCommand_spectate(request), "Become an observer") \
706         CLIENT_COMMAND("suggestmap", ClientCommand_suggestmap(request, arguments), "Suggest a map to the mapvote at match end") \
707         CLIENT_COMMAND("tell", ClientCommand_tell(request, arguments, command), "Send a message directly to a player") \
708         CLIENT_COMMAND("voice", ClientCommand_voice(request, arguments, command), "Send voice message via sound") \
709         /* nothing */
710         
711 void ClientCommand_macro_help()
712 {
713         #define CLIENT_COMMAND(name,function,description) \
714                 { sprint(self, "  ^2", name, "^7: ", description, "\n"); }
715                 
716         CLIENT_COMMANDS(0, 0, "")
717         #undef CLIENT_COMMAND
718         
719         return;
720 }
721
722 float ClientCommand_macro_command(float argc, string command)
723 {
724         #define CLIENT_COMMAND(name,function,description) \
725                 { if(name == strtolower(argv(0))) { function; return TRUE; } }
726                 
727         CLIENT_COMMANDS(CMD_REQUEST_COMMAND, argc, command)
728         #undef CLIENT_COMMAND
729         
730         return FALSE;
731 }
732
733 float ClientCommand_macro_usage(float argc)
734 {
735         #define CLIENT_COMMAND(name,function,description) \
736                 { if(name == strtolower(argv(1))) { function; return TRUE; } }
737                 
738         CLIENT_COMMANDS(CMD_REQUEST_USAGE, argc, "")
739         #undef CLIENT_COMMAND
740         
741         return FALSE;
742 }
743
744 void ClientCommand_macro_write_aliases(float fh)
745 {
746         #define CLIENT_COMMAND(name,function,description) \
747                 { CMD_Write_Alias("qc_cmd_cmd", name, description); } 
748                 
749         CLIENT_COMMANDS(0, 0, "")
750         #undef CLIENT_COMMAND
751         
752         return;
753 }
754
755 // ======================================
756 //  Main Function Called By Engine (cmd)
757 // ======================================
758 // If this function exists, server game code parses clientcommand before the engine code gets it.
759
760 void SV_ParseClientCommand(string command)
761 {
762         // if we're banned, don't even parse the command
763         if(Ban_MaybeEnforceBanOnce(self))
764                 return;
765
766         float argc = tokenize_console(command);
767         
768         // for the mutator hook system
769         cmd_name = strtolower(argv(0));
770         cmd_argc = argc;
771         cmd_string = command;
772         
773         // Guide for working with argc arguments by example:
774         // argc:   1    - 2      - 3     - 4
775         // argv:   0    - 1      - 2     - 3 
776         // cmd     vote - master - login - password
777         
778         // for floodcheck
779         switch(strtolower(argv(0)))
780         {
781                 // exempt commands which are not subject to floodcheck
782                 case "begin": break; // handled by engine in host_cmd.c
783                 case "download": break; // handled by engine in cl_parse.c
784                 case "mv_getpicture": break; // handled by server in this file
785                 case "pause": break; // handled by engine in host_cmd.c
786                 case "prespawn": break; // handled by engine in host_cmd.c
787                 case "sentcvar": break; // handled by server in this file
788                 case "spawn": break; // handled by engine in host_cmd.c
789                 
790                 default: 
791                         if(SV_ParseClientCommand_floodcheck())
792                                 break; // "TRUE": continue, as we're not flooding yet
793                         else
794                                 return; // "FALSE": not allowed to continue, halt // print("^1ERROR: ^7ANTISPAM CAUGHT: ", command, ".\n");
795         }
796         
797         /* NOTE: should this be disabled? It can be spammy perhaps, but hopefully it's okay for now */
798         if(argv(0) == "help") 
799         {
800                 if(argc == 1) 
801                 {
802                         sprint(self, "\nClient networked commands:\n");
803                         ClientCommand_macro_help();
804                         
805                         sprint(self, "\nCommon networked commands:\n");
806                         CommonCommand_macro_help(self);
807                         
808                         sprint(self, "\nUsage:^3 cmd COMMAND...^7, where possible commands are listed above.\n");
809                         sprint(self, "For help about a specific command, type cmd help COMMAND\n");
810                         return;
811                 } 
812                 else if(CommonCommand_macro_usage(argc, self)) // Instead of trying to call a command, we're going to see detailed information about it
813                 {
814                         return;
815                 }
816                 else if(ClientCommand_macro_usage(argc)) // same, but for normal commands now
817                 {
818                         return;
819                 }
820         } 
821         else if(MUTATOR_CALLHOOK(SV_ParseClientCommand))
822         {
823                 return; // handled by a mutator
824         }
825         else if(CheatCommand(argc)) 
826         {
827                 return; // handled by server/cheats.qc
828         }
829         else if(CommonCommand_macro_command(argc, self, command))
830         {
831                 return; // handled by server/command/common.qc
832         }
833         else if(ClientCommand_macro_command(argc, command)) // continue as usual and scan for normal commands
834         {
835                 return; // handled by one of the above ClientCommand_* functions
836         }
837         else
838                 clientcommand(self, command);
839 }