qcsrc/server/command/cmd.qc

   1 #include "cmd.qh"
   2
   3 #include <server/defs.qh>
   4 #include <server/miscfunctions.qh>
   5
   6 #include <common/command/_mod.qh>
   7
   8 #include "common.qh"
   9 #include "vote.qh"
  10
  11 #include "../campaign.qh"
  12 #include "../cheats.qh"
  13 #include "../player.qh"
  14 #include "../ipban.qh"
  15 #include "../mapvoting.qh"
  16 #include "../scores.qh"
  17 #include "../teamplay.qh"
  18
  19 #include <server/mutators/_mod.qh>
  20 #include <common/gamemodes/_mod.qh>
  21
  22 #ifdef SVQC
  23         #include <common/vehicles/all.qh>
  24 #endif
  25
  26 #include <common/constants.qh>
  27 #include <common/deathtypes/all.qh>
  28 #include <common/effects/all.qh>
  29 #include <common/mapinfo.qh>
  30 #include <common/notifications/all.qh>
  31 #include <common/physics/player.qh>
  32 #include <common/teams.qh>
  33 #include <common/util.qh>
  34 #include <common/mapobjects/triggers.qh>
  35
  36 #include <common/minigames/sv_minigames.qh>
  37
  38 #include <common/monsters/_mod.qh>
  39 #include <common/monsters/sv_spawn.qh>
  40 #include <common/monsters/sv_monsters.qh>
  41
  42 #include <lib/warpzone/common.qh>
  43
  44 void ClientKill_TeamChange(entity this, float targetteam);  // 0 = don't change, -1 = auto, -2 = spec
  45
  46 // =========================================================
  47 //  Server side networked commands code, reworked by Samual
  48 //  Last updated: December 28th, 2011
  49 // =========================================================
  50
  51 bool SV_ParseClientCommand_floodcheck(entity this)
  52 {
  53         entity store = IS_CLIENT(this) ? CS(this) : this; // unfortunately, we need to store these on the client initially
  54
  55         if (!timeout_status)  // not while paused
  56         {
  57                 if (time <= (store.cmd_floodtime + autocvar_sv_clientcommand_antispam_time))
  58                 {
  59                         store.cmd_floodcount += 1;
  60                         if (store.cmd_floodcount > autocvar_sv_clientcommand_antispam_count)   return false;  // too much spam, halt
  61                 }
  62                 else
  63                 {
  64                         store.cmd_floodtime = time;
  65                         store.cmd_floodcount = 1;
  66                 }
  67         }
  68         return true;  // continue, as we're not flooding yet
  69 }
  70
  71
  72 // =======================
  73 //  Command Sub-Functions
  74 // =======================
  75
  76 void ClientCommand_autoswitch(entity caller, float request, float argc)
  77 {
  78         switch (request)
  79         {
  80                 case CMD_REQUEST_COMMAND:
  81                 {
  82                         if (argv(1) != "")
  83                         {
  84                                 CS(caller).autoswitch = InterpretBoolean(argv(1));
  85                                 sprint(caller, strcat("^1autoswitch is currently turned ", (CS(caller).autoswitch ? "on" : "off"), ".\n"));
  86                                 return;
  87                         }
  88                 }
  89
  90                 default:
  91                         sprint(caller, "Incorrect parameters for ^2autoswitch^7\n");
  92                 case CMD_REQUEST_USAGE:
  93                 {
  94                         sprint(caller, "\nUsage:^3 cmd autoswitch selection\n");
  95                         sprint(caller, "  Where 'selection' controls if autoswitch is on or off.\n");
  96                         return;
  97                 }
  98         }
  99 }
 100
 101 void ClientCommand_clientversion(entity caller, float request, float argc)  // internal command, used only by code
 102 {
 103         switch (request)
 104         {
 105                 case CMD_REQUEST_COMMAND:
 106                 {
 107                         if (argv(1) != "")
 108                         {
 109                                 if (IS_CLIENT(caller))
 110                                 {
 111                                         CS(caller).version = ((argv(1) == "$gameversion") ? 1 : stof(argv(1)));
 112
 113                                         if (CS(caller).version < autocvar_gameversion_min || CS(caller).version > autocvar_gameversion_max)
 114                                         {
 115                                                 CS(caller).version_mismatch = true;
 116                                                 ClientKill_TeamChange(caller, -2);  // observe
 117                                         }
 118                                         else if (autocvar_g_campaign || autocvar_g_balance_teams)
 119                                         {
 120                                                 // JoinBestTeam(caller, false, true);
 121                                         }
 122                                         else if (teamplay && !autocvar_sv_spectate && !(caller.team_forced > 0))
 123                                         {
 124                                                 TRANSMUTE(Observer, caller);  // really?
 125                                                 stuffcmd(caller, "menu_showteamselect\n");
 126                                         }
 127                                 }
 128
 129                                 return;
 130                         }
 131                 }
 132
 133                 default:
 134                         sprint(caller, "Incorrect parameters for ^2clientversion^7\n");
 135                 case CMD_REQUEST_USAGE:
 136                 {
 137                         sprint(caller, "\nUsage:^3 cmd clientversion version\n");
 138                         sprint(caller, "  Where 'version' is the game version reported by caller.\n");
 139                         return;
 140                 }
 141         }
 142 }
 143
 144 void ClientCommand_mv_getpicture(entity caller, float request, float argc)  // internal command, used only by code
 145 {
 146         switch (request)
 147         {
 148                 case CMD_REQUEST_COMMAND:
 149                 {
 150                         if (argv(1) != "")
 151                         {
 152                                 if (intermission_running) MapVote_SendPicture(caller, stof(argv(1)));
 153
 154                                 return;
 155                         }
 156                 }
 157
 158                 default:
 159                         sprint(caller, "Incorrect parameters for ^2mv_getpicture^7\n");
 160                 case CMD_REQUEST_USAGE:
 161                 {
 162                         sprint(caller, "\nUsage:^3 cmd mv_getpicture mapid\n");
 163                         sprint(caller, "  Where 'mapid' is the id number of the map to request an image of on the map vote selection menu.\n");
 164                         return;
 165                 }
 166         }
 167 }
 168
 169 bool joinAllowed(entity this);
 170 void Join(entity this);
 171 void ClientCommand_join(entity caller, float request)
 172 {
 173         switch (request)
 174         {
 175                 case CMD_REQUEST_COMMAND:
 176                 {
 177                         if (!game_stopped)
 178                         if (IS_CLIENT(caller) && !IS_PLAYER(caller))
 179                         if (joinAllowed(caller))
 180                                 Join(caller);
 181
 182                         return;  // never fall through to usage
 183                 }
 184
 185                 default:
 186                 case CMD_REQUEST_USAGE:
 187                 {
 188                         sprint(caller, "\nUsage:^3 cmd join\n");
 189                         sprint(caller, "  No arguments required.\n");
 190                         return;
 191                 }
 192         }
 193 }
 194
 195 void ClientCommand_physics(entity caller, float request, float argc)
 196 {
 197         switch (request)
 198         {
 199                 case CMD_REQUEST_COMMAND:
 200                 {
 201                         string command = strtolower(argv(1));
 202
 203                         if (!autocvar_g_physics_clientselect)
 204                         {
 205                                 sprint(caller, "Client physics selection is currently disabled.\n");
 206                                 return;
 207                         }
 208
 209                         if (command == "list" || command == "help")
 210                         {
 211                                 sprint(caller, strcat("Available physics sets: \n\n", autocvar_g_physics_clientselect_options, " default\n"));
 212                                 return;
 213                         }
 214
 215                         if (Physics_Valid(command) || command == "default")
 216                         {
 217                                 stuffcmd(caller, strcat("\nseta cl_physics ", command, "\nsendcvar cl_physics\n"));
 218                                 sprint(caller, strcat("^2Physics set successfully changed to ^3", command, "\n"));
 219                                 return;
 220                         }
 221                 }
 222
 223                 default:
 224                         sprint(caller, strcat("Current physics set: ^3", CS(caller).cvar_cl_physics, "\n"));
 225                 case CMD_REQUEST_USAGE:
 226                 {
 227                         sprint(caller, "\nUsage:^3 cmd physics <physics>\n");
 228                         sprint(caller, "  See 'cmd physics list' for available physics sets.\n");
 229                         sprint(caller, "  Argument 'default' resets to standard physics.\n");
 230                         return;
 231                 }
 232         }
 233 }
 234
 235 void ClientCommand_ready(entity caller, float request)  // todo: anti-spam for toggling readyness
 236 {
 237         switch (request)
 238         {
 239                 case CMD_REQUEST_COMMAND:
 240                 {
 241                         if (IS_CLIENT(caller))
 242                         {
 243                                 if (warmup_stage || sv_ready_restart || g_race_qualifying == 2)
 244                                 {
 245                                         if (!readyrestart_happened || sv_ready_restart_repeatable)
 246                                         {
 247                                                 if (time < game_starttime) // game is already restarting
 248                                                         return;
 249                                                 if (caller.ready)            // toggle
 250                                                 {
 251                                                         caller.ready = false;
 252                                                         if(IS_PLAYER(caller) || caller.caplayer == 1)
 253                                                                 bprint(playername(caller, false), "^2 is ^1NOT^2 ready\n");
 254                                                 }
 255                                                 else
 256                                                 {
 257                                                         caller.ready = true;
 258                                                         if(IS_PLAYER(caller) || caller.caplayer == 1)
 259                                                                 bprint(playername(caller, false), "^2 is ready\n");
 260                                                 }
 261
 262                                                 // cannot reset the game while a timeout is active!
 263                                                 if (!timeout_status) ReadyCount();
 264                                         }
 265                                         else
 266                                         {
 267                                                 sprint(caller, "^1Game has already been restarted\n");
 268                                         }
 269                                 }
 270                         }
 271                         return;  // never fall through to usage
 272                 }
 273
 274                 default:
 275                 case CMD_REQUEST_USAGE:
 276                 {
 277                         sprint(caller, "\nUsage:^3 cmd ready\n");
 278                         sprint(caller, "  No arguments required.\n");
 279                         return;
 280                 }
 281         }
 282 }
 283
 284 void ClientCommand_say(entity caller, float request, float argc, string command)
 285 {
 286         switch (request)
 287         {
 288                 case CMD_REQUEST_COMMAND:
 289                 {
 290                         if (argc >= 2)   Say(caller, false, NULL, substring(command, argv_start_index(1), argv_end_index(-1) - argv_start_index(1)), 1);
 291                         return;  // never fall through to usage
 292                 }
 293
 294                 default:
 295                 case CMD_REQUEST_USAGE:
 296                 {
 297                         sprint(caller, "\nUsage:^3 cmd say <message>\n");
 298                         sprint(caller, "  Where 'message' is the string of text to say.\n");
 299                         return;
 300                 }
 301         }
 302 }
 303
 304 void ClientCommand_say_team(entity caller, float request, float argc, string command)
 305 {
 306         switch (request)
 307         {
 308                 case CMD_REQUEST_COMMAND:
 309                 {
 310                         if (argc >= 2)   Say(caller, true, NULL, substring(command, argv_start_index(1), argv_end_index(-1) - argv_start_index(1)), 1);
 311                         return;  // never fall through to usage
 312                 }
 313
 314                 default:
 315                 case CMD_REQUEST_USAGE:
 316                 {
 317                         sprint(caller, "\nUsage:^3 cmd say_team <message>\n");
 318                         sprint(caller, "  Where 'message' is the string of text to say.\n");
 319                         return;
 320                 }
 321         }
 322 }
 323
 324 .bool team_selected;
 325 void ClientCommand_selectteam(entity caller, float request, float argc)
 326 {
 327         switch (request)
 328         {
 329                 case CMD_REQUEST_COMMAND:
 330                 {
 331                         if (argv(1) == "")
 332                         {
 333                                 return;
 334                         }
 335                         if (!IS_CLIENT(caller))
 336                         {
 337                                 return;
 338                         }
 339                         if (!teamplay)
 340                         {
 341                                 sprint(caller, "^7selectteam can only be used in teamgames\n");
 342                                 return;
 343                         }
 344                         if (caller.team_forced > 0)
 345                         {
 346                                 sprint(caller, "^7selectteam can not be used as your team is forced\n");
 347                                 return;
 348                         }
 349                         if (lockteams)
 350                         {
 351                                 sprint(caller, "^7The game has already begun, you must wait until the next map to be able to join a team.\n");
 352                                 return;
 353                         }
 354                         float selection;
 355                         switch (argv(1))
 356                         {
 357                                 case "red":
 358                                 {
 359                                         selection = NUM_TEAM_1;
 360                                         break;
 361                                 }
 362                                 case "blue":
 363                                 {
 364                                         selection = NUM_TEAM_2;
 365                                         break;
 366                                 }
 367                                 case "yellow":
 368                                 {
 369                                         selection = NUM_TEAM_3;
 370                                         break;
 371                                 }
 372                                 case "pink":
 373                                 {
 374                                         selection = NUM_TEAM_4;
 375                                         break;
 376                                 }
 377                                 case "auto":
 378                                 {
 379                                         selection = (-1);
 380                                         break;
 381                                 }
 382                                 default:
 383                                 {
 384                                         return;
 385                                 }
 386                         }
 387                         if (caller.team == selection && selection != -1 && !IS_DEAD(caller))
 388                         {
 389                                 sprint(caller, "^7You already are on that team.\n");
 390                                 return;
 391                         }
 392                         if (CS(caller).wasplayer && autocvar_g_changeteam_banned)
 393                         {
 394                                 sprint(caller, "^1You cannot change team, forbidden by the server.\n");
 395                                 return;
 396                         }
 397                         if ((selection != -1) && autocvar_g_balance_teams &&
 398                                 autocvar_g_balance_teams_prevent_imbalance)
 399                         {
 400                                 entity balance = TeamBalance_CheckAllowedTeams(caller);
 401                                 TeamBalance_GetTeamCounts(balance, caller);
 402                                 if ((Team_IndexToBit(Team_TeamToIndex(selection)) &
 403                                         TeamBalance_FindBestTeams(balance, caller, false)) == 0)
 404                                 {
 405                                         Send_Notification(NOTIF_ONE, caller, MSG_INFO, INFO_TEAMCHANGE_LARGERTEAM);
 406                                         TeamBalance_Destroy(balance);
 407                                         return;
 408                                 }
 409                                 TeamBalance_Destroy(balance);
 410                         }
 411                         ClientKill_TeamChange(caller, selection);
 412                         if (!IS_PLAYER(caller))
 413                         {
 414                                 caller.team_selected = true; // avoids asking again for team selection on join
 415                         }
 416                         return;
 417                 }
 418                 default:
 419                         sprint(caller, "Incorrect parameters for ^2selectteam^7\n");
 420                 case CMD_REQUEST_USAGE:
 421                 {
 422                         sprint(caller, "\nUsage:^3 cmd selectteam team\n");
 423                         sprint(caller, "  Where 'team' is the prefered team to try and join.\n");
 424                         sprint(caller, "  Full list of options here: \"red, blue, yellow, pink, auto\"\n");
 425                         return;
 426                 }
 427         }
 428 }
 429
 430 void ClientCommand_selfstuff(entity caller, float request, string command)
 431 {
 432         switch (request)
 433         {
 434                 case CMD_REQUEST_COMMAND:
 435                 {
 436                         if (argv(1) != "")
 437                         {
 438                                 stuffcmd(caller, substring(command, argv_start_index(1), argv_end_index(-1) - argv_start_index(1)));
 439                                 return;
 440                         }
 441                 }
 442
 443                 default:
 444                         sprint(caller, "Incorrect parameters for ^2selfstuff^7\n");
 445                 case CMD_REQUEST_USAGE:
 446                 {
 447                         sprint(caller, "\nUsage:^3 cmd selfstuff <command>\n");
 448                         sprint(caller, "  Where 'command' is the string to be stuffed to your client.\n");
 449                         return;
 450                 }
 451         }
 452 }
 453
 454 void ClientCommand_sentcvar(entity caller, float request, float argc, string command)
 455 {
 456         switch (request)
 457         {
 458                 case CMD_REQUEST_COMMAND:
 459                 {
 460                         if (argv(1) != "")
 461                         {
 462                                 // float tokens;
 463                                 string s;
 464
 465                                 if (argc == 2)  // undefined cvar: use the default value on the server then
 466                                 {
 467                                         s = strcat(substring(command, argv_start_index(0), argv_end_index(1) - argv_start_index(0)), " \"", cvar_defstring(argv(1)), "\"");
 468                                         tokenize_console(s);
 469                                 }
 470
 471                                 GetCvars(caller, CS(caller), 1);
 472
 473                                 return;
 474                         }
 475                 }
 476
 477                 default:
 478                         sprint(caller, "Incorrect parameters for ^2sentcvar^7\n");
 479                 case CMD_REQUEST_USAGE:
 480                 {
 481                         sprint(caller, "\nUsage:^3 cmd sentcvar <cvar>\n");
 482                         sprint(caller, "  Where 'cvar' is the cvar plus arguments to send to the server.\n");
 483                         return;
 484                 }
 485         }
 486 }
 487
 488 void ClientCommand_spectate(entity caller, float request)
 489 {
 490         switch (request)
 491         {
 492                 case CMD_REQUEST_COMMAND:
 493                 {
 494                         if (!intermission_running && IS_CLIENT(caller))
 495                         {
 496                                 if((IS_SPEC(caller) || IS_OBSERVER(caller)) && argv(1) != "")
 497                                 {
 498                                         entity client = GetFilteredEntity(argv(1));
 499                                         int spec_accepted = VerifyClientEntity(client, false, false);
 500                                         if(spec_accepted > 0 && IS_PLAYER(client))
 501                                         {
 502                                                 if(Spectate(caller, client))
 503                                                         return; // fall back to regular handling
 504                                         }
 505                                 }
 506
 507                                 int mutator_returnvalue = MUTATOR_CALLHOOK(ClientCommand_Spectate, caller);
 508
 509                                 if (mutator_returnvalue == MUT_SPECCMD_RETURN) return;
 510
 511                                 if ((IS_PLAYER(caller) || mutator_returnvalue == MUT_SPECCMD_FORCE))
 512                                 if (autocvar_sv_spectate == 1)
 513                                         ClientKill_TeamChange(caller, -2); // observe
 514                         }
 515                         return; // never fall through to usage
 516                 }
 517
 518                 default:
 519                 case CMD_REQUEST_USAGE:
 520                 {
 521                         sprint(caller, "\nUsage:^3 cmd spectate <client>\n");
 522                         sprint(caller, "  Where 'client' can be the player to spectate.\n");
 523                         return;
 524                 }
 525         }
 526 }
 527
 528 void ClientCommand_suggestmap(entity caller, float request, float argc)
 529 {
 530         switch (request)
 531         {
 532                 case CMD_REQUEST_COMMAND:
 533                 {
 534                         if (argv(1) != "")
 535                         {
 536                                 sprint(caller, strcat(MapVote_Suggest(caller, argv(1)), "\n"));
 537                                 return;
 538                         }
 539                 }
 540
 541                 default:
 542                         sprint(caller, "Incorrect parameters for ^2suggestmap^7\n");
 543                 case CMD_REQUEST_USAGE:
 544                 {
 545                         sprint(caller, "\nUsage:^3 cmd suggestmap map\n");
 546                         sprint(caller, "  Where 'map' is the name of the map to suggest.\n");
 547                         return;
 548                 }
 549         }
 550 }
 551
 552 void ClientCommand_tell(entity caller, float request, float argc, string command)
 553 {
 554         switch (request)
 555         {
 556                 case CMD_REQUEST_COMMAND:
 557                 {
 558                         if (argc >= 3)
 559                         {
 560                                 if(!IS_CLIENT(caller) && IS_REAL_CLIENT(caller)) // connecting
 561                                 {
 562                                         print_to(caller, "You can't ^2tell^7 a message while connecting.");
 563                                         return;
 564                                 }
 565
 566                                 entity tell_to = GetIndexedEntity(argc, 1);
 567                                 float tell_accepted = VerifyClientEntity(tell_to, true, false);
 568
 569                                 if (tell_accepted > 0)   // the target is a real client
 570                                 {
 571                                         if (tell_to != caller) // and we're allowed to send to them :D
 572                                         {
 573                                                 // workaround for argv indexes indexing ascii chars instead of utf8 chars
 574                                                 // In this case when the player name contains utf8 chars
 575                                                 // the message gets partially trimmed in the beginning.
 576                                                 // Potentially this bug affects any substring call that uses
 577                                                 // argv_start_index and argv_end_index.
 578
 579                                                 string utf8_enable_save = cvar_string("utf8_enable");
 580                                                 cvar_set("utf8_enable", "0");
 581                                                 string msg = substring(command, argv_start_index(next_token), argv_end_index(-1) - argv_start_index(next_token));
 582                                                 cvar_set("utf8_enable", utf8_enable_save);
 583
 584                                                 Say(caller, false, tell_to, msg, true);
 585                                                 return;
 586                                         }
 587                                         else { print_to(caller, "You can't ^2tell^7 a message to yourself."); return; }
 588                                 }
 589                                 else if (argv(1) == "#0")
 590                                 {
 591                                         trigger_magicear_processmessage_forallears(caller, -1, NULL, substring(command, argv_start_index(next_token), argv_end_index(-1) - argv_start_index(next_token)));
 592                                         return;
 593                                 }
 594                                 else { print_to(caller, strcat("tell: ", GetClientErrorString(tell_accepted, argv(1)), ".")); return; }
 595                         }
 596                 }
 597
 598                 default:
 599                         sprint(caller, "Incorrect parameters for ^2tell^7\n");
 600                 case CMD_REQUEST_USAGE:
 601                 {
 602                         sprint(caller, "\nUsage:^3 cmd tell client <message>\n");
 603                         sprint(caller, "  Where 'client' is the entity number or name of the player to send 'message' to.\n");
 604                         return;
 605                 }
 606         }
 607 }
 608
 609 void ClientCommand_voice(entity caller, float request, float argc, string command)
 610 {
 611         switch (request)
 612         {
 613                 case CMD_REQUEST_COMMAND:
 614                 {
 615                         if (argv(1) != "")
 616                         {
 617                                 entity e = GetVoiceMessage(argv(1));
 618                                 if (!e)
 619                                 {
 620                                         sprint(caller, sprintf("Invalid voice. Use one of: %s\n", allvoicesamples));
 621                                         return;
 622                                 }
 623                                 string msg = "";
 624                                 if (argc >= 3)
 625                                         msg = substring(command, argv_start_index(2), argv_end_index(-1) - argv_start_index(2));
 626                                 VoiceMessage(caller, e, msg);
 627
 628                                 return;
 629                         }
 630                 }
 631
 632                 default:
 633                         sprint(caller, "Incorrect parameters for ^2voice^7\n");
 634                 case CMD_REQUEST_USAGE:
 635                 {
 636                         sprint(caller, "\nUsage:^3 cmd voice messagetype <soundname>\n");
 637                         sprint(caller, "  'messagetype' is the type of broadcast to do, like team only or such,\n");
 638                         sprint(caller, "  and 'soundname' is the string/filename of the sound/voice message to play.\n");
 639                         return;
 640                 }
 641         }
 642 }
 643
 644 /* use this when creating a new command, making sure to place it in alphabetical order... also,
 645 ** ADD ALL NEW COMMANDS TO commands.cfg WITH PROPER ALIASES IN THE SAME FASHION!
 646 void ClientCommand_(entity caller, float request)
 647 {
 648     switch(request)
 649     {
 650         case CMD_REQUEST_COMMAND:
 651         {
 652
 653             return; // never fall through to usage
 654         }
 655
 656         default:
 657         case CMD_REQUEST_USAGE:
 658         {
 659             sprint(caller, "\nUsage:^3 cmd \n");
 660             sprint(caller, "  No arguments required.\n");
 661             return;
 662         }
 663     }
 664 }
 665 */
 666
 667
 668 // =====================================
 669 //  Macro system for networked commands
 670 // =====================================
 671
 672 // Do not hard code aliases for these, instead create them in commands.cfg... also: keep in alphabetical order, please ;)
 673 #define CLIENT_COMMANDS(ent, request, arguments, command) \
 674         CLIENT_COMMAND("autoswitch", ClientCommand_autoswitch(ent, request, arguments), "Whether or not to switch automatically when getting a better weapon") \
 675         CLIENT_COMMAND("clientversion", ClientCommand_clientversion(ent, request, arguments), "Release version of the game") \
 676         CLIENT_COMMAND("mv_getpicture", ClientCommand_mv_getpicture(ent, request, arguments), "Retrieve mapshot picture from the server") \
 677         CLIENT_COMMAND("join", ClientCommand_join(ent, request), "Become a player in the game") \
 678         CLIENT_COMMAND("physics", ClientCommand_physics(ent, request, arguments), "Change physics set") \
 679         CLIENT_COMMAND("ready", ClientCommand_ready(ent, request), "Qualify as ready to end warmup stage (or restart server if allowed)") \
 680         CLIENT_COMMAND("say", ClientCommand_say(ent, request, arguments, command), "Print a message to chat to all players") \
 681         CLIENT_COMMAND("say_team", ClientCommand_say_team(ent, request, arguments, command), "Print a message to chat to all team mates") \
 682         CLIENT_COMMAND("selectteam", ClientCommand_selectteam(ent, request, arguments), "Attempt to choose a team to join into") \
 683         CLIENT_COMMAND("selfstuff", ClientCommand_selfstuff(ent, request, command), "Stuffcmd a command to your own client") \
 684         CLIENT_COMMAND("sentcvar", ClientCommand_sentcvar(ent, request, arguments, command), "New system for sending a client cvar to the server") \
 685         CLIENT_COMMAND("spectate", ClientCommand_spectate(ent, request), "Become an observer") \
 686         CLIENT_COMMAND("suggestmap", ClientCommand_suggestmap(ent, request, arguments), "Suggest a map to the mapvote at match end") \
 687         CLIENT_COMMAND("tell", ClientCommand_tell(ent, request, arguments, command), "Send a message directly to a player") \
 688         CLIENT_COMMAND("voice", ClientCommand_voice(ent, request, arguments, command), "Send voice message via sound") \
 689         CLIENT_COMMAND("minigame", ClientCommand_minigame(ent, request, arguments, command), "Start a minigame") \
 690         /* nothing */
 691
 692 void ClientCommand_macro_help(entity caller)
 693 {
 694         #define CLIENT_COMMAND(name, function, description) \
 695                 { sprint(caller, "  ^2", name, "^7: ", description, "\n"); }
 696
 697         CLIENT_COMMANDS(NULL, 0, 0, "");
 698 #undef CLIENT_COMMAND
 699 }
 700
 701 float ClientCommand_macro_command(float argc, entity caller, string command)
 702 {
 703         #define CLIENT_COMMAND(name, function, description) \
 704                 { if (name == strtolower(argv(0))) { function; return true; } }
 705
 706         CLIENT_COMMANDS(caller, CMD_REQUEST_COMMAND, argc, command);
 707 #undef CLIENT_COMMAND
 708
 709         return false;
 710 }
 711
 712 float ClientCommand_macro_usage(float argc, entity caller)
 713 {
 714         #define CLIENT_COMMAND(name, function, description) \
 715                 { if (name == strtolower(argv(1))) { function; return true; } }
 716
 717         CLIENT_COMMANDS(caller, CMD_REQUEST_USAGE, argc, "");
 718 #undef CLIENT_COMMAND
 719
 720         return false;
 721 }
 722
 723 void ClientCommand_macro_write_aliases(float fh)
 724 {
 725         #define CLIENT_COMMAND(name, function, description) \
 726                 { CMD_Write_Alias("qc_cmd_cmd", name, description); }
 727
 728         CLIENT_COMMANDS(NULL, 0, 0, "");
 729 #undef CLIENT_COMMAND
 730 }
 731
 732 // ======================================
 733 //  Main Function Called By Engine (cmd)
 734 // ======================================
 735 // If this function exists, server game code parses clientcommand before the engine code gets it.
 736
 737 void SV_ParseClientCommand(entity this, string command)
 738 {
 739         // If invalid UTF-8, don't even parse it
 740         string command2 = "";
 741         float len = strlen(command);
 742         float i;
 743         for (i = 0; i < len; ++i)
 744                 command2 = strcat(command2, chr2str(str2chr(command, i)));
 745         if (command != command2) return;
 746
 747         // if we're banned, don't even parse the command
 748         if (Ban_MaybeEnforceBanOnce(this)) return;
 749
 750         float argc = tokenize_console(command);
 751
 752         // Guide for working with argc arguments by example:
 753         // argc:   1    - 2      - 3     - 4
 754         // argv:   0    - 1      - 2     - 3
 755         // cmd     vote - master - login - password
 756
 757         // for floodcheck
 758         switch (strtolower(argv(0)))
 759         {
 760                 // exempt commands which are not subject to floodcheck
 761                 case "begin": break;                               // handled by engine in host_cmd.c
 762                 case "download": break;                            // handled by engine in cl_parse.c
 763                 case "mv_getpicture": break;                       // handled by server in this file
 764                 case "pause": break;                               // handled by engine in host_cmd.c
 765                 case "prespawn": break;                            // handled by engine in host_cmd.c
 766                 case "sentcvar": break;                            // handled by server in this file
 767                 case "spawn": break;                               // handled by engine in host_cmd.c
 768                 case "c2s": Net_ClientCommand(this, command); return; // handled by net.qh
 769
 770                 default:
 771                         if (SV_ParseClientCommand_floodcheck(this)) break; // "true": continue, as we're not flooding yet
 772                         else return;                                   // "false": not allowed to continue, halt // print("^1ERROR: ^7ANTISPAM CAUGHT: ", command, ".\n");
 773         }
 774
 775         /* NOTE: should this be disabled? It can be spammy perhaps, but hopefully it's okay for now */
 776         if (argv(0) == "help")
 777         {
 778                 if (argc == 1)
 779                 {
 780                         sprint(this, "\nClient networked commands:\n");
 781                         ClientCommand_macro_help(this);
 782
 783                         sprint(this, "\nCommon networked commands:\n");
 784                         CommonCommand_macro_help(this);
 785
 786                         sprint(this, "\nUsage:^3 cmd COMMAND...^7, where possible commands are listed above.\n");
 787                         sprint(this, "For help about a specific command, type cmd help COMMAND\n");
 788                         return;
 789                 }
 790                 else if (CommonCommand_macro_usage(argc, this))  // Instead of trying to call a command, we're going to see detailed information about it
 791                 {
 792                         return;
 793                 }
 794                 else if (ClientCommand_macro_usage(argc, this))  // same, but for normal commands now
 795                 {
 796                         return;
 797                 }
 798         }
 799         else if (MUTATOR_CALLHOOK(SV_ParseClientCommand, this, strtolower(argv(0)), argc, command))
 800         {
 801                 return;  // handled by a mutator
 802         }
 803         else if (CheatCommand(this, argc))
 804         {
 805                 return;  // handled by server/cheats.qc
 806         }
 807         else if (CommonCommand_macro_command(argc, this, command))
 808         {
 809                 return;                                          // handled by server/command/common.qc
 810         }
 811         else if (ClientCommand_macro_command(argc, this, command)) // continue as usual and scan for normal commands
 812         {
 813                 return;                                          // handled by one of the above ClientCommand_* functions
 814         }
 815         else
 816         {
 817                 clientcommand(this, command);
 818         }
 819 }