qcsrc/server/command/cmd.qc

   1 #include "cmd.qh"
   2
   3 #include <server/defs.qh>
   4 #include <server/miscfunctions.qh>
   5
   6 #include <common/command/_mod.qh>
   7
   8 #include "common.qh"
   9 #include "vote.qh"
  10
  11 #include "../campaign.qh"
  12 #include "../cheats.qh"
  13 #include "../client.qh"
  14 #include "../clientkill.qh"
  15 #include "../player.qh"
  16 #include "../ipban.qh"
  17 #include "../mapvoting.qh"
  18 #include "../scores.qh"
  19 #include "../teamplay.qh"
  20
  21 #include <server/mutators/_mod.qh>
  22 #include <common/gamemodes/_mod.qh>
  23
  24 #ifdef SVQC
  25         #include <common/vehicles/all.qh>
  26 #endif
  27
  28 #include <common/constants.qh>
  29 #include <common/deathtypes/all.qh>
  30 #include <common/effects/all.qh>
  31 #include <common/mapinfo.qh>
  32 #include <common/notifications/all.qh>
  33 #include <common/physics/player.qh>
  34 #include <common/teams.qh>
  35 #include <common/util.qh>
  36 #include <common/mapobjects/triggers.qh>
  37
  38 #include <common/minigames/sv_minigames.qh>
  39
  40 #include <common/monsters/_mod.qh>
  41 #include <common/monsters/sv_spawn.qh>
  42 #include <common/monsters/sv_monsters.qh>
  43
  44 #include <lib/warpzone/common.qh>
  45
  46 // =========================================================
  47 //  Server side networked commands code, reworked by Samual
  48 //  Last updated: December 28th, 2011
  49 // =========================================================
  50
  51 bool SV_ParseClientCommand_floodcheck(entity this)
  52 {
  53         entity store = IS_CLIENT(this) ? CS(this) : this; // unfortunately, we need to store these on the client initially
  54
  55         if (!timeout_status)  // not while paused
  56         {
  57                 if (time <= (store.cmd_floodtime + autocvar_sv_clientcommand_antispam_time))
  58                 {
  59                         store.cmd_floodcount += 1;
  60                         if (store.cmd_floodcount > autocvar_sv_clientcommand_antispam_count)   return false;  // too much spam, halt
  61                 }
  62                 else
  63                 {
  64                         store.cmd_floodtime = time;
  65                         store.cmd_floodcount = 1;
  66                 }
  67         }
  68         return true;  // continue, as we're not flooding yet
  69 }
  70
  71
  72 // =======================
  73 //  Command Sub-Functions
  74 // =======================
  75
  76 void ClientCommand_autoswitch(entity caller, float request, float argc)
  77 {
  78         switch (request)
  79         {
  80                 case CMD_REQUEST_COMMAND:
  81                 {
  82                         if (argv(1) != "")
  83                         {
  84                                 CS(caller).autoswitch = InterpretBoolean(argv(1));
  85                                 sprint(caller, strcat("^1autoswitch is currently turned ", (CS(caller).autoswitch ? "on" : "off"), ".\n"));
  86                                 return;
  87                         }
  88                 }
  89
  90                 default:
  91                         sprint(caller, "Incorrect parameters for ^2autoswitch^7\n");
  92                 case CMD_REQUEST_USAGE:
  93                 {
  94                         sprint(caller, "\nUsage:^3 cmd autoswitch selection\n");
  95                         sprint(caller, "  Where 'selection' controls if autoswitch is on or off.\n");
  96                         return;
  97                 }
  98         }
  99 }
 100
 101 void ClientCommand_clientversion(entity caller, float request, float argc)  // internal command, used only by code
 102 {
 103         switch (request)
 104         {
 105                 case CMD_REQUEST_COMMAND:
 106                 {
 107                         if (argv(1) != "")
 108                         {
 109                                 if (IS_CLIENT(caller))
 110                                 {
 111                                         CS(caller).version = ((argv(1) == "$gameversion") ? 1 : stof(argv(1)));
 112
 113                                         if (CS(caller).version < autocvar_gameversion_min || CS(caller).version > autocvar_gameversion_max)
 114                                         {
 115                                                 CS(caller).version_mismatch = true;
 116                                                 ClientKill_TeamChange(caller, -2);  // observe
 117                                         }
 118                                         else if (autocvar_g_campaign || autocvar_g_balance_teams)
 119                                         {
 120                                                 // JoinBestTeam(caller, false, true);
 121                                         }
 122                                         else if (teamplay && !autocvar_sv_spectate && !(caller.team_forced > 0))
 123                                         {
 124                                                 TRANSMUTE(Observer, caller);  // really?
 125                                                 stuffcmd(caller, "menu_showteamselect\n");
 126                                         }
 127                                 }
 128
 129                                 return;
 130                         }
 131                 }
 132
 133                 default:
 134                         sprint(caller, "Incorrect parameters for ^2clientversion^7\n");
 135                 case CMD_REQUEST_USAGE:
 136                 {
 137                         sprint(caller, "\nUsage:^3 cmd clientversion version\n");
 138                         sprint(caller, "  Where 'version' is the game version reported by caller.\n");
 139                         return;
 140                 }
 141         }
 142 }
 143
 144 void ClientCommand_mv_getpicture(entity caller, float request, float argc)  // internal command, used only by code
 145 {
 146         switch (request)
 147         {
 148                 case CMD_REQUEST_COMMAND:
 149                 {
 150                         if (argv(1) != "")
 151                         {
 152                                 if (intermission_running) MapVote_SendPicture(caller, stof(argv(1)));
 153
 154                                 return;
 155                         }
 156                 }
 157
 158                 default:
 159                         sprint(caller, "Incorrect parameters for ^2mv_getpicture^7\n");
 160                 case CMD_REQUEST_USAGE:
 161                 {
 162                         sprint(caller, "\nUsage:^3 cmd mv_getpicture mapid\n");
 163                         sprint(caller, "  Where 'mapid' is the id number of the map to request an image of on the map vote selection menu.\n");
 164                         return;
 165                 }
 166         }
 167 }
 168
 169 void ClientCommand_join(entity caller, float request)
 170 {
 171         switch (request)
 172         {
 173                 case CMD_REQUEST_COMMAND:
 174                 {
 175                         if (!game_stopped)
 176                         if (IS_CLIENT(caller) && !IS_PLAYER(caller))
 177                         if (joinAllowed(caller))
 178                                 Join(caller);
 179
 180                         return;  // never fall through to usage
 181                 }
 182
 183                 default:
 184                 case CMD_REQUEST_USAGE:
 185                 {
 186                         sprint(caller, "\nUsage:^3 cmd join\n");
 187                         sprint(caller, "  No arguments required.\n");
 188                         return;
 189                 }
 190         }
 191 }
 192
 193 void ClientCommand_physics(entity caller, float request, float argc)
 194 {
 195         switch (request)
 196         {
 197                 case CMD_REQUEST_COMMAND:
 198                 {
 199                         string command = strtolower(argv(1));
 200
 201                         if (!autocvar_g_physics_clientselect)
 202                         {
 203                                 sprint(caller, "Client physics selection is currently disabled.\n");
 204                                 return;
 205                         }
 206
 207                         if (command == "list" || command == "help")
 208                         {
 209                                 sprint(caller, strcat("Available physics sets: \n\n", autocvar_g_physics_clientselect_options, " default\n"));
 210                                 return;
 211                         }
 212
 213                         if (Physics_Valid(command) || command == "default")
 214                         {
 215                                 stuffcmd(caller, strcat("\nseta cl_physics ", command, "\nsendcvar cl_physics\n"));
 216                                 sprint(caller, strcat("^2Physics set successfully changed to ^3", command, "\n"));
 217                                 return;
 218                         }
 219                 }
 220
 221                 default:
 222                         sprint(caller, strcat("Current physics set: ^3", CS(caller).cvar_cl_physics, "\n"));
 223                 case CMD_REQUEST_USAGE:
 224                 {
 225                         sprint(caller, "\nUsage:^3 cmd physics <physics>\n");
 226                         sprint(caller, "  See 'cmd physics list' for available physics sets.\n");
 227                         sprint(caller, "  Argument 'default' resets to standard physics.\n");
 228                         return;
 229                 }
 230         }
 231 }
 232
 233 void ClientCommand_ready(entity caller, float request)  // todo: anti-spam for toggling readyness
 234 {
 235         switch (request)
 236         {
 237                 case CMD_REQUEST_COMMAND:
 238                 {
 239                         if (IS_CLIENT(caller))
 240                         {
 241                                 if (warmup_stage || sv_ready_restart || g_race_qualifying == 2)
 242                                 {
 243                                         if (!readyrestart_happened || sv_ready_restart_repeatable)
 244                                         {
 245                                                 if (time < game_starttime) // game is already restarting
 246                                                         return;
 247                                                 if (caller.ready)            // toggle
 248                                                 {
 249                                                         caller.ready = false;
 250                                                         if(IS_PLAYER(caller) || caller.caplayer == 1)
 251                                                                 bprint(playername(caller, false), "^2 is ^1NOT^2 ready\n");
 252                                                 }
 253                                                 else
 254                                                 {
 255                                                         caller.ready = true;
 256                                                         if(IS_PLAYER(caller) || caller.caplayer == 1)
 257                                                                 bprint(playername(caller, false), "^2 is ready\n");
 258                                                 }
 259
 260                                                 // cannot reset the game while a timeout is active!
 261                                                 if (!timeout_status) ReadyCount();
 262                                         }
 263                                         else
 264                                         {
 265                                                 sprint(caller, "^1Game has already been restarted\n");
 266                                         }
 267                                 }
 268                         }
 269                         return;  // never fall through to usage
 270                 }
 271
 272                 default:
 273                 case CMD_REQUEST_USAGE:
 274                 {
 275                         sprint(caller, "\nUsage:^3 cmd ready\n");
 276                         sprint(caller, "  No arguments required.\n");
 277                         return;
 278                 }
 279         }
 280 }
 281
 282 void ClientCommand_say(entity caller, float request, float argc, string command)
 283 {
 284         switch (request)
 285         {
 286                 case CMD_REQUEST_COMMAND:
 287                 {
 288                         if (argc >= 2)   Say(caller, false, NULL, substring(command, argv_start_index(1), argv_end_index(-1) - argv_start_index(1)), 1);
 289                         return;  // never fall through to usage
 290                 }
 291
 292                 default:
 293                 case CMD_REQUEST_USAGE:
 294                 {
 295                         sprint(caller, "\nUsage:^3 cmd say <message>\n");
 296                         sprint(caller, "  Where 'message' is the string of text to say.\n");
 297                         return;
 298                 }
 299         }
 300 }
 301
 302 void ClientCommand_say_team(entity caller, float request, float argc, string command)
 303 {
 304         switch (request)
 305         {
 306                 case CMD_REQUEST_COMMAND:
 307                 {
 308                         if (argc >= 2)   Say(caller, true, NULL, substring(command, argv_start_index(1), argv_end_index(-1) - argv_start_index(1)), 1);
 309                         return;  // never fall through to usage
 310                 }
 311
 312                 default:
 313                 case CMD_REQUEST_USAGE:
 314                 {
 315                         sprint(caller, "\nUsage:^3 cmd say_team <message>\n");
 316                         sprint(caller, "  Where 'message' is the string of text to say.\n");
 317                         return;
 318                 }
 319         }
 320 }
 321
 322 .bool team_selected;
 323 void ClientCommand_selectteam(entity caller, float request, float argc)
 324 {
 325         switch (request)
 326         {
 327                 case CMD_REQUEST_COMMAND:
 328                 {
 329                         if (argv(1) == "")
 330                         {
 331                                 return;
 332                         }
 333                         if (!IS_CLIENT(caller))
 334                         {
 335                                 return;
 336                         }
 337                         if (!teamplay)
 338                         {
 339                                 sprint(caller, "^7selectteam can only be used in teamgames\n");
 340                                 return;
 341                         }
 342                         if (caller.team_forced > 0)
 343                         {
 344                                 sprint(caller, "^7selectteam can not be used as your team is forced\n");
 345                                 return;
 346                         }
 347                         if (lockteams)
 348                         {
 349                                 sprint(caller, "^7The game has already begun, you must wait until the next map to be able to join a team.\n");
 350                                 return;
 351                         }
 352                         float selection;
 353                         switch (argv(1))
 354                         {
 355                                 case "red":
 356                                 {
 357                                         selection = NUM_TEAM_1;
 358                                         break;
 359                                 }
 360                                 case "blue":
 361                                 {
 362                                         selection = NUM_TEAM_2;
 363                                         break;
 364                                 }
 365                                 case "yellow":
 366                                 {
 367                                         selection = NUM_TEAM_3;
 368                                         break;
 369                                 }
 370                                 case "pink":
 371                                 {
 372                                         selection = NUM_TEAM_4;
 373                                         break;
 374                                 }
 375                                 case "auto":
 376                                 {
 377                                         selection = (-1);
 378                                         break;
 379                                 }
 380                                 default:
 381                                 {
 382                                         return;
 383                                 }
 384                         }
 385                         if (caller.team == selection && selection != -1 && !IS_DEAD(caller))
 386                         {
 387                                 sprint(caller, "^7You already are on that team.\n");
 388                                 return;
 389                         }
 390                         if (CS(caller).wasplayer && autocvar_g_changeteam_banned)
 391                         {
 392                                 sprint(caller, "^1You cannot change team, forbidden by the server.\n");
 393                                 return;
 394                         }
 395                         if ((selection != -1) && autocvar_g_balance_teams &&
 396                                 autocvar_g_balance_teams_prevent_imbalance)
 397                         {
 398                                 entity balance = TeamBalance_CheckAllowedTeams(caller);
 399                                 TeamBalance_GetTeamCounts(balance, caller);
 400                                 if ((Team_IndexToBit(Team_TeamToIndex(selection)) &
 401                                         TeamBalance_FindBestTeams(balance, caller, false)) == 0)
 402                                 {
 403                                         Send_Notification(NOTIF_ONE, caller, MSG_INFO, INFO_TEAMCHANGE_LARGERTEAM);
 404                                         TeamBalance_Destroy(balance);
 405                                         return;
 406                                 }
 407                                 TeamBalance_Destroy(balance);
 408                         }
 409                         ClientKill_TeamChange(caller, selection);
 410                         if (!IS_PLAYER(caller))
 411                         {
 412                                 caller.team_selected = true; // avoids asking again for team selection on join
 413                         }
 414                         return;
 415                 }
 416                 default:
 417                         sprint(caller, "Incorrect parameters for ^2selectteam^7\n");
 418                 case CMD_REQUEST_USAGE:
 419                 {
 420                         sprint(caller, "\nUsage:^3 cmd selectteam team\n");
 421                         sprint(caller, "  Where 'team' is the prefered team to try and join.\n");
 422                         sprint(caller, "  Full list of options here: \"red, blue, yellow, pink, auto\"\n");
 423                         return;
 424                 }
 425         }
 426 }
 427
 428 void ClientCommand_selfstuff(entity caller, float request, string command)
 429 {
 430         switch (request)
 431         {
 432                 case CMD_REQUEST_COMMAND:
 433                 {
 434                         if (argv(1) != "")
 435                         {
 436                                 stuffcmd(caller, substring(command, argv_start_index(1), argv_end_index(-1) - argv_start_index(1)));
 437                                 return;
 438                         }
 439                 }
 440
 441                 default:
 442                         sprint(caller, "Incorrect parameters for ^2selfstuff^7\n");
 443                 case CMD_REQUEST_USAGE:
 444                 {
 445                         sprint(caller, "\nUsage:^3 cmd selfstuff <command>\n");
 446                         sprint(caller, "  Where 'command' is the string to be stuffed to your client.\n");
 447                         return;
 448                 }
 449         }
 450 }
 451
 452 void ClientCommand_sentcvar(entity caller, float request, float argc, string command)
 453 {
 454         switch (request)
 455         {
 456                 case CMD_REQUEST_COMMAND:
 457                 {
 458                         if (argv(1) != "")
 459                         {
 460                                 // float tokens;
 461                                 string s;
 462
 463                                 if (argc == 2)  // undefined cvar: use the default value on the server then
 464                                 {
 465                                         s = strcat(substring(command, argv_start_index(0), argv_end_index(1) - argv_start_index(0)), " \"", cvar_defstring(argv(1)), "\"");
 466                                         tokenize_console(s);
 467                                 }
 468
 469                                 GetCvars(caller, CS(caller), 1);
 470
 471                                 return;
 472                         }
 473                 }
 474
 475                 default:
 476                         sprint(caller, "Incorrect parameters for ^2sentcvar^7\n");
 477                 case CMD_REQUEST_USAGE:
 478                 {
 479                         sprint(caller, "\nUsage:^3 cmd sentcvar <cvar>\n");
 480                         sprint(caller, "  Where 'cvar' is the cvar plus arguments to send to the server.\n");
 481                         return;
 482                 }
 483         }
 484 }
 485
 486 void ClientCommand_spectate(entity caller, float request)
 487 {
 488         switch (request)
 489         {
 490                 case CMD_REQUEST_COMMAND:
 491                 {
 492                         if (!intermission_running && IS_CLIENT(caller))
 493                         {
 494                                 if((IS_SPEC(caller) || IS_OBSERVER(caller)) && argv(1) != "")
 495                                 {
 496                                         entity client = GetFilteredEntity(argv(1));
 497                                         int spec_accepted = VerifyClientEntity(client, false, false);
 498                                         if(spec_accepted > 0 && IS_PLAYER(client))
 499                                         {
 500                                                 if(Spectate(caller, client))
 501                                                         return; // fall back to regular handling
 502                                         }
 503                                 }
 504
 505                                 int mutator_returnvalue = MUTATOR_CALLHOOK(ClientCommand_Spectate, caller);
 506
 507                                 if (mutator_returnvalue == MUT_SPECCMD_RETURN) return;
 508
 509                                 if ((IS_PLAYER(caller) || mutator_returnvalue == MUT_SPECCMD_FORCE))
 510                                 if (autocvar_sv_spectate == 1)
 511                                         ClientKill_TeamChange(caller, -2); // observe
 512                         }
 513                         return; // never fall through to usage
 514                 }
 515
 516                 default:
 517                 case CMD_REQUEST_USAGE:
 518                 {
 519                         sprint(caller, "\nUsage:^3 cmd spectate <client>\n");
 520                         sprint(caller, "  Where 'client' can be the player to spectate.\n");
 521                         return;
 522                 }
 523         }
 524 }
 525
 526 void ClientCommand_suggestmap(entity caller, float request, float argc)
 527 {
 528         switch (request)
 529         {
 530                 case CMD_REQUEST_COMMAND:
 531                 {
 532                         if (argv(1) != "")
 533                         {
 534                                 sprint(caller, strcat(MapVote_Suggest(caller, argv(1)), "\n"));
 535                                 return;
 536                         }
 537                 }
 538
 539                 default:
 540                         sprint(caller, "Incorrect parameters for ^2suggestmap^7\n");
 541                 case CMD_REQUEST_USAGE:
 542                 {
 543                         sprint(caller, "\nUsage:^3 cmd suggestmap map\n");
 544                         sprint(caller, "  Where 'map' is the name of the map to suggest.\n");
 545                         return;
 546                 }
 547         }
 548 }
 549
 550 void ClientCommand_tell(entity caller, float request, float argc, string command)
 551 {
 552         switch (request)
 553         {
 554                 case CMD_REQUEST_COMMAND:
 555                 {
 556                         if (argc >= 3)
 557                         {
 558                                 if(!IS_CLIENT(caller) && IS_REAL_CLIENT(caller)) // connecting
 559                                 {
 560                                         print_to(caller, "You can't ^2tell^7 a message while connecting.");
 561                                         return;
 562                                 }
 563
 564                                 entity tell_to = GetIndexedEntity(argc, 1);
 565                                 float tell_accepted = VerifyClientEntity(tell_to, true, false);
 566
 567                                 if (tell_accepted > 0)   // the target is a real client
 568                                 {
 569                                         if (tell_to != caller) // and we're allowed to send to them :D
 570                                         {
 571                                                 // workaround for argv indexes indexing ascii chars instead of utf8 chars
 572                                                 // In this case when the player name contains utf8 chars
 573                                                 // the message gets partially trimmed in the beginning.
 574                                                 // Potentially this bug affects any substring call that uses
 575                                                 // argv_start_index and argv_end_index.
 576
 577                                                 string utf8_enable_save = cvar_string("utf8_enable");
 578                                                 cvar_set("utf8_enable", "0");
 579                                                 string msg = substring(command, argv_start_index(next_token), argv_end_index(-1) - argv_start_index(next_token));
 580                                                 cvar_set("utf8_enable", utf8_enable_save);
 581
 582                                                 Say(caller, false, tell_to, msg, true);
 583                                                 return;
 584                                         }
 585                                         else { print_to(caller, "You can't ^2tell^7 a message to yourself."); return; }
 586                                 }
 587                                 else if (argv(1) == "#0")
 588                                 {
 589                                         trigger_magicear_processmessage_forallears(caller, -1, NULL, substring(command, argv_start_index(next_token), argv_end_index(-1) - argv_start_index(next_token)));
 590                                         return;
 591                                 }
 592                                 else { print_to(caller, strcat("tell: ", GetClientErrorString(tell_accepted, argv(1)), ".")); return; }
 593                         }
 594                 }
 595
 596                 default:
 597                         sprint(caller, "Incorrect parameters for ^2tell^7\n");
 598                 case CMD_REQUEST_USAGE:
 599                 {
 600                         sprint(caller, "\nUsage:^3 cmd tell client <message>\n");
 601                         sprint(caller, "  Where 'client' is the entity number or name of the player to send 'message' to.\n");
 602                         return;
 603                 }
 604         }
 605 }
 606
 607 void ClientCommand_voice(entity caller, float request, float argc, string command)
 608 {
 609         switch (request)
 610         {
 611                 case CMD_REQUEST_COMMAND:
 612                 {
 613                         if (argv(1) != "")
 614                         {
 615                                 entity e = GetVoiceMessage(argv(1));
 616                                 if (!e)
 617                                 {
 618                                         sprint(caller, sprintf("Invalid voice. Use one of: %s\n", allvoicesamples));
 619                                         return;
 620                                 }
 621                                 string msg = "";
 622                                 if (argc >= 3)
 623                                         msg = substring(command, argv_start_index(2), argv_end_index(-1) - argv_start_index(2));
 624                                 VoiceMessage(caller, e, msg);
 625
 626                                 return;
 627                         }
 628                 }
 629
 630                 default:
 631                         sprint(caller, "Incorrect parameters for ^2voice^7\n");
 632                 case CMD_REQUEST_USAGE:
 633                 {
 634                         sprint(caller, "\nUsage:^3 cmd voice messagetype <soundname>\n");
 635                         sprint(caller, "  'messagetype' is the type of broadcast to do, like team only or such,\n");
 636                         sprint(caller, "  and 'soundname' is the string/filename of the sound/voice message to play.\n");
 637                         return;
 638                 }
 639         }
 640 }
 641
 642 /* use this when creating a new command, making sure to place it in alphabetical order... also,
 643 ** ADD ALL NEW COMMANDS TO commands.cfg WITH PROPER ALIASES IN THE SAME FASHION!
 644 void ClientCommand_(entity caller, float request)
 645 {
 646     switch(request)
 647     {
 648         case CMD_REQUEST_COMMAND:
 649         {
 650
 651             return; // never fall through to usage
 652         }
 653
 654         default:
 655         case CMD_REQUEST_USAGE:
 656         {
 657             sprint(caller, "\nUsage:^3 cmd \n");
 658             sprint(caller, "  No arguments required.\n");
 659             return;
 660         }
 661     }
 662 }
 663 */
 664
 665
 666 // =====================================
 667 //  Macro system for networked commands
 668 // =====================================
 669
 670 // Do not hard code aliases for these, instead create them in commands.cfg... also: keep in alphabetical order, please ;)
 671 #define CLIENT_COMMANDS(ent, request, arguments, command) \
 672         CLIENT_COMMAND("autoswitch", ClientCommand_autoswitch(ent, request, arguments), "Whether or not to switch automatically when getting a better weapon") \
 673         CLIENT_COMMAND("clientversion", ClientCommand_clientversion(ent, request, arguments), "Release version of the game") \
 674         CLIENT_COMMAND("join", ClientCommand_join(ent, request), "Become a player in the game") \
 675         CLIENT_COMMAND("minigame", ClientCommand_minigame(ent, request, arguments, command), "Start a minigame") \
 676         CLIENT_COMMAND("mv_getpicture", ClientCommand_mv_getpicture(ent, request, arguments), "Retrieve mapshot picture from the server") \
 677         CLIENT_COMMAND("physics", ClientCommand_physics(ent, request, arguments), "Change physics set") \
 678         CLIENT_COMMAND("ready", ClientCommand_ready(ent, request), "Qualify as ready to end warmup stage (or restart server if allowed)") \
 679         CLIENT_COMMAND("say", ClientCommand_say(ent, request, arguments, command), "Print a message to chat to all players") \
 680         CLIENT_COMMAND("say_team", ClientCommand_say_team(ent, request, arguments, command), "Print a message to chat to all team mates") \
 681         CLIENT_COMMAND("selectteam", ClientCommand_selectteam(ent, request, arguments), "Attempt to choose a team to join into") \
 682         CLIENT_COMMAND("selfstuff", ClientCommand_selfstuff(ent, request, command), "Stuffcmd a command to your own client") \
 683         CLIENT_COMMAND("sentcvar", ClientCommand_sentcvar(ent, request, arguments, command), "New system for sending a client cvar to the server") \
 684         CLIENT_COMMAND("spectate", ClientCommand_spectate(ent, request), "Become an observer") \
 685         CLIENT_COMMAND("suggestmap", ClientCommand_suggestmap(ent, request, arguments), "Suggest a map to the mapvote at match end") \
 686         CLIENT_COMMAND("tell", ClientCommand_tell(ent, request, arguments, command), "Send a message directly to a player") \
 687         CLIENT_COMMAND("voice", ClientCommand_voice(ent, request, arguments, command), "Send voice message via sound") \
 688         /* nothing */
 689
 690 void ClientCommand_macro_help(entity caller)
 691 {
 692         #define CLIENT_COMMAND(name, function, description) \
 693                 { sprint(caller, "  ^2", name, "^7: ", description, "\n"); }
 694
 695         CLIENT_COMMANDS(NULL, 0, 0, "");
 696 #undef CLIENT_COMMAND
 697 }
 698
 699 float ClientCommand_macro_command(float argc, entity caller, string command)
 700 {
 701         #define CLIENT_COMMAND(name, function, description) \
 702                 { if (name == strtolower(argv(0))) { function; return true; } }
 703
 704         CLIENT_COMMANDS(caller, CMD_REQUEST_COMMAND, argc, command);
 705 #undef CLIENT_COMMAND
 706
 707         return false;
 708 }
 709
 710 float ClientCommand_macro_usage(float argc, entity caller)
 711 {
 712         #define CLIENT_COMMAND(name, function, description) \
 713                 { if (name == strtolower(argv(1))) { function; return true; } }
 714
 715         CLIENT_COMMANDS(caller, CMD_REQUEST_USAGE, argc, "");
 716 #undef CLIENT_COMMAND
 717
 718         return false;
 719 }
 720
 721 void ClientCommand_macro_write_aliases(float fh)
 722 {
 723         #define CLIENT_COMMAND(name, function, description) \
 724                 { CMD_Write_Alias("qc_cmd_cmd", name, description); }
 725
 726         CLIENT_COMMANDS(NULL, 0, 0, "");
 727 #undef CLIENT_COMMAND
 728 }
 729
 730 // ======================================
 731 //  Main Function Called By Engine (cmd)
 732 // ======================================
 733 // If this function exists, server game code parses clientcommand before the engine code gets it.
 734
 735 void SV_ParseClientCommand(entity this, string command)
 736 {
 737         // If invalid UTF-8, don't even parse it
 738         string command2 = "";
 739         float len = strlen(command);
 740         float i;
 741         for (i = 0; i < len; ++i)
 742                 command2 = strcat(command2, chr2str(str2chr(command, i)));
 743         if (command != command2) return;
 744
 745         // if we're banned, don't even parse the command
 746         if (Ban_MaybeEnforceBanOnce(this)) return;
 747
 748         float argc = tokenize_console(command);
 749
 750         // Guide for working with argc arguments by example:
 751         // argc:   1    - 2      - 3     - 4
 752         // argv:   0    - 1      - 2     - 3
 753         // cmd     vote - master - login - password
 754
 755         // for floodcheck
 756         switch (strtolower(argv(0)))
 757         {
 758                 // exempt commands which are not subject to floodcheck
 759                 case "begin": break;                               // handled by engine in host_cmd.c
 760                 case "download": break;                            // handled by engine in cl_parse.c
 761                 case "mv_getpicture": break;                       // handled by server in this file
 762                 case "pause": break;                               // handled by engine in host_cmd.c
 763                 case "prespawn": break;                            // handled by engine in host_cmd.c
 764                 case "sentcvar": break;                            // handled by server in this file
 765                 case "spawn": break;                               // handled by engine in host_cmd.c
 766                 case "c2s": Net_ClientCommand(this, command); return; // handled by net.qh
 767
 768                 default:
 769                         if (SV_ParseClientCommand_floodcheck(this)) break; // "true": continue, as we're not flooding yet
 770                         else return;                                   // "false": not allowed to continue, halt // print("^1ERROR: ^7ANTISPAM CAUGHT: ", command, ".\n");
 771         }
 772
 773         /* NOTE: should this be disabled? It can be spammy perhaps, but hopefully it's okay for now */
 774         if (argv(0) == "help")
 775         {
 776                 if (argc == 1)
 777                 {
 778                         sprint(this, "\nClient networked commands:\n");
 779                         ClientCommand_macro_help(this);
 780
 781                         sprint(this, "\nCommon networked commands:\n");
 782                         CommonCommand_macro_help(this);
 783
 784                         sprint(this, "\nUsage:^3 cmd COMMAND...^7, where possible commands are listed above.\n");
 785                         sprint(this, "For help about a specific command, type cmd help COMMAND\n");
 786                         return;
 787                 }
 788                 else if (CommonCommand_macro_usage(argc, this))  // Instead of trying to call a command, we're going to see detailed information about it
 789                 {
 790                         return;
 791                 }
 792                 else if (ClientCommand_macro_usage(argc, this))  // same, but for normal commands now
 793                 {
 794                         return;
 795                 }
 796         }
 797         else if (MUTATOR_CALLHOOK(SV_ParseClientCommand, this, strtolower(argv(0)), argc, command))
 798         {
 799                 return;  // handled by a mutator
 800         }
 801         else if (CheatCommand(this, argc))
 802         {
 803                 return;  // handled by server/cheats.qc
 804         }
 805         else if (CommonCommand_macro_command(argc, this, command))
 806         {
 807                 return;                                          // handled by server/command/common.qc
 808         }
 809         else if (ClientCommand_macro_command(argc, this, command)) // continue as usual and scan for normal commands
 810         {
 811                 return;                                          // handled by one of the above ClientCommand_* functions
 812         }
 813         else
 814         {
 815                 clientcommand(this, command);
 816         }
 817 }