Merge branch 'master' into Mario/vaporizer_damage
[xonotic/xonotic-data.pk3dir.git] / qcsrc / server / command / cmd.qc
1 #include "../../common/command/command.qh"
2 #include "cmd.qh"
3 #include "../_all.qh"
4
5 #include "common.qh"
6 #include "vote.qh"
7
8 #include "../campaign.qh"
9 #include "../cheats.qh"
10 #include "../cl_player.qh"
11 #include "../ipban.qh"
12 #include "../mapvoting.qh"
13 #include "../scores.qh"
14 #include "../teamplay.qh"
15
16 #include "../mutators/mutators_include.qh"
17
18 #ifdef SVQC
19         #include "../../common/vehicles/all.qh"
20 #endif
21
22 #include "../../common/constants.qh"
23 #include "../../common/deathtypes.qh"
24 #include "../../common/mapinfo.qh"
25 #include "../../common/notifications.qh"
26 #include "../../common/teams.qh"
27 #include "../../common/util.qh"
28
29 #include "../../common/monsters/all.qc"
30 #include "../../common/monsters/spawn.qh"
31 #include "../../common/monsters/sv_monsters.qh"
32
33 #include "../../warpzonelib/common.qh"
34
35 void ClientKill_TeamChange (float targetteam); // 0 = don't change, -1 = auto, -2 = spec
36
37 // =========================================================
38 //  Server side networked commands code, reworked by Samual
39 //  Last updated: December 28th, 2011
40 // =========================================================
41
42 float SV_ParseClientCommand_floodcheck()
43 {
44         if (!timeout_status) // not while paused
45         {
46                 if(time <= (self.cmd_floodtime + autocvar_sv_clientcommand_antispam_time))
47                 {
48                         self.cmd_floodcount += 1;
49                         if(self.cmd_floodcount > autocvar_sv_clientcommand_antispam_count) { return false; } // too much spam, halt
50                 }
51                 else
52                 {
53                         self.cmd_floodtime = time;
54                         self.cmd_floodcount = 1;
55                 }
56         }
57         return true; // continue, as we're not flooding yet
58 }
59
60
61 // =======================
62 //  Command Sub-Functions
63 // =======================
64
65 void ClientCommand_autoswitch(float request, float argc)
66 {
67         switch(request)
68         {
69                 case CMD_REQUEST_COMMAND:
70                 {
71                         if(argv(1) != "")
72                         {
73                                 self.autoswitch = InterpretBoolean(argv(1));
74                                 sprint(self, strcat("^1autoswitch is currently turned ", (self.autoswitch ? "on" : "off"), ".\n"));
75                                 return;
76                         }
77                 }
78
79                 default:
80                         sprint(self, "Incorrect parameters for ^2autoswitch^7\n");
81                 case CMD_REQUEST_USAGE:
82                 {
83                         sprint(self, "\nUsage:^3 cmd autoswitch selection\n");
84                         sprint(self, "  Where 'selection' controls if autoswitch is on or off.\n");
85                         return;
86                 }
87         }
88 }
89
90 void ClientCommand_clientversion(float request, float argc) // internal command, used only by code
91 {
92         switch(request)
93         {
94                 case CMD_REQUEST_COMMAND:
95                 {
96                         if(argv(1) != "")
97                         {
98                                 if(IS_CLIENT(self))
99                                 {
100                                         self.version = ((argv(1) == "$gameversion") ? 1 : stof(argv(1)));
101
102                                         if(self.version < autocvar_gameversion_min || self.version > autocvar_gameversion_max)
103                                         {
104                                                 self.version_mismatch = 1;
105                                                 ClientKill_TeamChange(-2); // observe
106                                         }
107                                         else if(autocvar_g_campaign || autocvar_g_balance_teams)
108                                         {
109                                                 //JoinBestTeam(self, false, true);
110                                         }
111                                         else if(teamplay && !autocvar_sv_spectate && !(self.team_forced > 0))
112                                         {
113                                                 self.classname = "observer"; // really?
114                                                 stuffcmd(self, "menu_showteamselect\n");
115                                         }
116                                 }
117
118                                 return;
119                         }
120                 }
121
122                 default:
123                         sprint(self, "Incorrect parameters for ^2clientversion^7\n");
124                 case CMD_REQUEST_USAGE:
125                 {
126                         sprint(self, "\nUsage:^3 cmd clientversion version\n");
127                         sprint(self, "  Where 'version' is the game version reported by self.\n");
128                         return;
129                 }
130         }
131 }
132
133 void ClientCommand_mv_getpicture(float request, float argc) // internal command, used only by code
134 {
135         switch(request)
136         {
137                 case CMD_REQUEST_COMMAND:
138                 {
139                         if(argv(1) != "")
140                         {
141                                 if(intermission_running)
142                                         MapVote_SendPicture(stof(argv(1)));
143
144                                 return;
145                         }
146                 }
147
148                 default:
149                         sprint(self, "Incorrect parameters for ^2mv_getpicture^7\n");
150                 case CMD_REQUEST_USAGE:
151                 {
152                         sprint(self, "\nUsage:^3 cmd mv_getpicture mapid\n");
153                         sprint(self, "  Where 'mapid' is the id number of the map to request an image of on the map vote selection menu.\n");
154                         return;
155                 }
156         }
157 }
158
159 void ClientCommand_join(float request)
160 {
161         switch(request)
162         {
163                 case CMD_REQUEST_COMMAND:
164                 {
165                         if(IS_CLIENT(self))
166                         {
167                                 if(!IS_PLAYER(self) && !lockteams && !gameover)
168                                 {
169                                         if(self.caplayer)
170                                                 return;
171                                         if(nJoinAllowed(self))
172                                         {
173                                                 if(autocvar_g_campaign) { campaign_bots_may_start = 1; }
174
175                                                 self.classname = "player";
176                                                 PlayerScore_Clear(self);
177                                                 Kill_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER_CPID, CPID_PREVENT_JOIN);
178                                                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_JOIN_PLAY, self.netname);
179                                                 PutClientInServer();
180                                         }
181                                         else
182                                         {
183                                                 //player may not join because of g_maxplayers is set
184                                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_JOIN_PREVENT);
185                                         }
186                                 }
187                         }
188                         return; // never fall through to usage
189                 }
190
191                 default:
192                 case CMD_REQUEST_USAGE:
193                 {
194                         sprint(self, "\nUsage:^3 cmd join\n");
195                         sprint(self, "  No arguments required.\n");
196                         return;
197                 }
198         }
199 }
200
201 void ClientCommand_physics(float request, float argc)
202 {
203         switch(request)
204         {
205                 case CMD_REQUEST_COMMAND:
206                 {
207                         string command = strtolower(argv(1));
208
209                         if(!autocvar_g_physics_clientselect)
210                         {
211                                 sprint(self, "Client physics selection is currently disabled.\n");
212                                 return;
213                         }
214
215                         if(command == "list" || command == "help")
216                         {
217                                 sprint(self, strcat("Available physics sets: \n\n", autocvar_g_physics_clientselect_options, " default\n"));
218                                 return;
219                         }
220
221                         if(Physics_Valid(command) || command == "default")
222                         {
223                                 stuffcmd(self, strcat("\nseta cl_physics ", command, "\nsendcvar cl_physics\n"));
224                                 sprint(self, strcat("^2Physics set successfully changed to ^3", command, "\n"));
225                                 return;
226                         }
227                 }
228
229                 default:
230                         sprint(self, strcat("Current physics set: ^3", self.cvar_cl_physics, "\n"));
231                 case CMD_REQUEST_USAGE:
232                 {
233                         sprint(self, "\nUsage:^3 cmd physics <physics>\n");
234                         sprint(self, "  See 'cmd physics list' for available physics sets.\n");
235                         sprint(self, "  Argument 'default' resets to standard physics.\n");
236                         return;
237                 }
238         }
239 }
240
241 void ClientCommand_ready(float request) // todo: anti-spam for toggling readyness
242 {
243         switch(request)
244         {
245                 case CMD_REQUEST_COMMAND:
246                 {
247                         if(IS_CLIENT(self))
248                         {
249                                 if(warmup_stage || autocvar_sv_ready_restart || g_race_qualifying == 2)
250                                 {
251                                         if(!readyrestart_happened || autocvar_sv_ready_restart_repeatable)
252                                         {
253                                                 if(time < game_starttime) // game is already restarting
254                                                         return;
255                                                 if (self.ready) // toggle
256                                                 {
257                                                         self.ready = false;
258                                                         bprint(self.netname, "^2 is ^1NOT^2 ready\n");
259                                                 }
260                                                 else
261                                                 {
262                                                         self.ready = true;
263                                                         bprint(self.netname, "^2 is ready\n");
264                                                 }
265
266                                                 // cannot reset the game while a timeout is active!
267                                                 if (!timeout_status)
268                                                         ReadyCount();
269                                         } else {
270                                                 sprint(self, "^1Game has already been restarted\n");
271                                         }
272                                 }
273                         }
274                         return; // never fall through to usage
275                 }
276
277                 default:
278                 case CMD_REQUEST_USAGE:
279                 {
280                         sprint(self, "\nUsage:^3 cmd ready\n");
281                         sprint(self, "  No arguments required.\n");
282                         return;
283                 }
284         }
285 }
286
287 void ClientCommand_say(float request, float argc, string command)
288 {
289         switch(request)
290         {
291                 case CMD_REQUEST_COMMAND:
292                 {
293                         if(argc >= 2) { Say(self, false, world, substring(command, argv_start_index(1), argv_end_index(-1) - argv_start_index(1)), 1); }
294                         return; // never fall through to usage
295                 }
296
297                 default:
298                 case CMD_REQUEST_USAGE:
299                 {
300                         sprint(self, "\nUsage:^3 cmd say <message>\n");
301                         sprint(self, "  Where 'message' is the string of text to say.\n");
302                         return;
303                 }
304         }
305 }
306
307 void ClientCommand_say_team(float request, float argc, string command)
308 {
309         switch(request)
310         {
311                 case CMD_REQUEST_COMMAND:
312                 {
313                         if(argc >= 2) { Say(self, true, world, substring(command, argv_start_index(1), argv_end_index(-1) - argv_start_index(1)), 1); }
314                         return; // never fall through to usage
315                 }
316
317                 default:
318                 case CMD_REQUEST_USAGE:
319                 {
320                         sprint(self, "\nUsage:^3 cmd say_team <message>\n");
321                         sprint(self, "  Where 'message' is the string of text to say.\n");
322                         return;
323                 }
324         }
325 }
326
327 void ClientCommand_selectteam(float request, float argc)
328 {
329         switch(request)
330         {
331                 case CMD_REQUEST_COMMAND:
332                 {
333                         if(argv(1) != "")
334                         {
335                                 if(IS_CLIENT(self))
336                                 {
337                                         if(teamplay)
338                                                 if(self.team_forced <= 0)
339                                                         if (!lockteams)
340                                                         {
341                                                                 float selection;
342
343                                                                 switch(argv(1))
344                                                                 {
345                                                                         case "red": selection = NUM_TEAM_1; break;
346                                                                         case "blue": selection = NUM_TEAM_2; break;
347                                                                         case "yellow": selection = NUM_TEAM_3; break;
348                                                                         case "pink": selection = NUM_TEAM_4; break;
349                                                                         case "auto": selection = (-1); break;
350
351                                                                         default: selection = 0; break;
352                                                                 }
353
354                                                                 if(selection)
355                                                                 {
356                                                                         if(self.team == selection && self.deadflag == DEAD_NO)
357                                                                                 sprint(self, "^7You already are on that team.\n");
358                                                                         else if(self.wasplayer && autocvar_g_changeteam_banned)
359                                                                                 sprint(self, "^1You cannot change team, forbidden by the server.\n");
360                                                                         else
361                                                                         {
362                                                                                 if(autocvar_g_balance_teams && autocvar_g_balance_teams_prevent_imbalance)
363                                                                                 {
364                                                                                         CheckAllowedTeams(self);
365                                                                                         GetTeamCounts(self);
366                                                                                         if(!TeamSmallerEqThanTeam(Team_TeamToNumber(selection), Team_TeamToNumber(self.team), self))
367                                                                                         {
368                                                                                                 Send_Notification(NOTIF_ONE, self, MSG_INFO, INFO_TEAMCHANGE_LARGERTEAM);
369                                                                                                 return;
370                                                                                         }
371                                                                                 }
372                                                                                 ClientKill_TeamChange(selection);
373                                                                         }
374                                                                 }
375                                                         }
376                                                         else
377                                                                 sprint(self, "^7The game has already begun, you must wait until the next map to be able to join a team.\n");
378                                                 else
379                                                         sprint(self, "^7selectteam can not be used as your team is forced\n");
380                                         else
381                                                 sprint(self, "^7selectteam can only be used in teamgames\n");
382                                 }
383                                 return;
384                         }
385                 }
386
387                 default:
388                         sprint(self, "Incorrect parameters for ^2selectteam^7\n");
389                 case CMD_REQUEST_USAGE:
390                 {
391                         sprint(self, "\nUsage:^3 cmd selectteam team\n");
392                         sprint(self, "  Where 'team' is the prefered team to try and join.\n");
393                         sprint(self, "  Full list of options here: \"red, blue, yellow, pink, auto\"\n");
394                         return;
395                 }
396         }
397 }
398
399 void ClientCommand_selfstuff(float request, string command)
400 {
401         switch(request)
402         {
403                 case CMD_REQUEST_COMMAND:
404                 {
405                         if(argv(1) != "")
406                         {
407                                 stuffcmd(self, substring(command, argv_start_index(1), argv_end_index(-1) - argv_start_index(1)));
408                                 return;
409                         }
410                 }
411
412                 default:
413                         sprint(self, "Incorrect parameters for ^2selectteam^7\n");
414                 case CMD_REQUEST_USAGE:
415                 {
416                         sprint(self, "\nUsage:^3 cmd selfstuff <command>\n");
417                         sprint(self, "  Where 'command' is the string to be stuffed to your client.\n");
418                         return;
419                 }
420         }
421 }
422
423 void ClientCommand_sentcvar(float request, float argc, string command)
424 {
425         switch(request)
426         {
427                 case CMD_REQUEST_COMMAND:
428                 {
429                         if(argv(1) != "")
430                         {
431                                 //float tokens;
432                                 string s;
433
434                                 if(argc == 2) // undefined cvar: use the default value on the server then
435                                 {
436                                         s = strcat(substring(command, argv_start_index(0), argv_end_index(1) - argv_start_index(0)), " \"", cvar_defstring(argv(1)), "\"");
437                                         tokenize_console(s);
438                                 }
439
440                                 GetCvars(1);
441
442                                 return;
443                         }
444                 }
445
446                 default:
447                         sprint(self, "Incorrect parameters for ^2sentcvar^7\n");
448                 case CMD_REQUEST_USAGE:
449                 {
450                         sprint(self, "\nUsage:^3 cmd sentcvar <cvar>\n");
451                         sprint(self, "  Where 'cvar' is the cvar plus arguments to send to the server.\n");
452                         return;
453                 }
454         }
455 }
456
457 void ClientCommand_spectate(float request)
458 {
459         switch(request)
460         {
461                 case CMD_REQUEST_COMMAND:
462                 {
463                         if(IS_CLIENT(self))
464                         {
465                                 if(g_lms)
466                                 {
467                                         if(self.lms_spectate_warning)
468                                         {
469                                                 // for the forfeit message...
470                                                 self.lms_spectate_warning = 2;
471                                                 // mark player as spectator
472                                                 PlayerScore_Add(self, SP_LMS_RANK, 666 - PlayerScore_Add(self, SP_LMS_RANK, 0));
473                                         }
474                                         else
475                                         {
476                                                 self.lms_spectate_warning = 1;
477                                                 sprint(self, "WARNING: you won't be able to enter the game again after spectating in LMS. Use the same command again to spectate anyway.\n");
478                                                 return;
479                                         }
480                                 }
481
482                                 if((IS_PLAYER(self) || self.caplayer) && autocvar_sv_spectate == 1)
483                                 {
484                                         if(self.caplayer && (IS_SPEC(self) || IS_OBSERVER(self)))
485                                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_CA_LEAVE);
486                                         ClientKill_TeamChange(-2); // observe
487                                 }
488                         }
489                         return; // never fall through to usage
490                 }
491
492                 default:
493                 case CMD_REQUEST_USAGE:
494                 {
495                         sprint(self, "\nUsage:^3 cmd spectate\n");
496                         sprint(self, "  No arguments required.\n");
497                         return;
498                 }
499         }
500 }
501
502 void ClientCommand_suggestmap(float request, float argc)
503 {
504         switch(request)
505         {
506                 case CMD_REQUEST_COMMAND:
507                 {
508                         if(argv(1) != "")
509                         {
510                                 sprint(self, strcat(MapVote_Suggest(argv(1)), "\n"));
511                                 return;
512                         }
513                 }
514
515                 default:
516                         sprint(self, "Incorrect parameters for ^2suggestmap^7\n");
517                 case CMD_REQUEST_USAGE:
518                 {
519                         sprint(self, "\nUsage:^3 cmd suggestmap map\n");
520                         sprint(self, "  Where 'map' is the name of the map to suggest.\n");
521                         return;
522                 }
523         }
524 }
525
526 void ClientCommand_tell(float request, float argc, string command)
527 {
528         switch(request)
529         {
530                 case CMD_REQUEST_COMMAND:
531                 {
532                         if(argc >= 3)
533                         {
534                                 entity tell_to = GetIndexedEntity(argc, 1);
535                                 float tell_accepted = VerifyClientEntity(tell_to, true, false);
536
537                                 if(tell_accepted > 0) // the target is a real client
538                                 {
539                                         if(tell_to != self) // and we're allowed to send to them :D
540                                         {
541                                                 // workaround for argv indexes indexing ascii chars instead of utf8 chars
542                                                 // In this case when the player name contains utf8 chars
543                                                 // the message gets partially trimmed in the beginning.
544                                                 // Potentially this bug affects any substring call that uses
545                                                 // argv_start_index and argv_end_index.
546
547                                                 string utf8_enable_save = cvar_string("utf8_enable");
548                                                 cvar_set("utf8_enable", "0");
549                                                 string msg = substring(command, argv_start_index(next_token), argv_end_index(-1) - argv_start_index(next_token));
550                                                 cvar_set("utf8_enable", utf8_enable_save);
551
552                                                 Say(self, false, tell_to, msg, true);
553                                                 return;
554                                         }
555                                         else { print_to(self, "You can't ^2tell^7 a message to yourself."); return; }
556                                 }
557                                 else if(argv(1) == "#0")
558                                 {
559                                         trigger_magicear_processmessage_forallears(self, -1, world, substring(command, argv_start_index(next_token), argv_end_index(-1) - argv_start_index(next_token)));
560                                         return;
561                                 }
562                                 else { print_to(self, strcat("tell: ", GetClientErrorString(tell_accepted, argv(1)), ".")); return; }
563                         }
564                 }
565
566                 default:
567                         sprint(self, "Incorrect parameters for ^2tell^7\n");
568                 case CMD_REQUEST_USAGE:
569                 {
570                         sprint(self, "\nUsage:^3 cmd tell client <message>\n");
571                         sprint(self, "  Where 'client' is the entity number or name of the player to send 'message' to.\n");
572                         return;
573                 }
574         }
575 }
576
577 void ClientCommand_voice(float request, float argc, string command)
578 {
579         switch(request)
580         {
581                 case CMD_REQUEST_COMMAND:
582                 {
583                         if(argv(1) != "")
584                         {
585                                 if(argc >= 3)
586                                         VoiceMessage(argv(1), substring(command, argv_start_index(2), argv_end_index(-1) - argv_start_index(2)));
587                                 else
588                                         VoiceMessage(argv(1), "");
589
590                                 return;
591                         }
592                 }
593
594                 default:
595                         sprint(self, "Incorrect parameters for ^2voice^7\n");
596                 case CMD_REQUEST_USAGE:
597                 {
598                         sprint(self, "\nUsage:^3 cmd voice messagetype <soundname>\n");
599                         sprint(self, "  'messagetype' is the type of broadcast to do, like team only or such,\n");
600                         sprint(self, "  and 'soundname' is the string/filename of the sound/voice message to play.\n");
601                         return;
602                 }
603         }
604 }
605
606 /* use this when creating a new command, making sure to place it in alphabetical order... also,
607 ** ADD ALL NEW COMMANDS TO commands.cfg WITH PROPER ALIASES IN THE SAME FASHION!
608 void ClientCommand_(float request)
609 {
610         switch(request)
611         {
612                 case CMD_REQUEST_COMMAND:
613                 {
614
615                         return; // never fall through to usage
616                 }
617
618                 default:
619                 case CMD_REQUEST_USAGE:
620                 {
621                         sprint(self, "\nUsage:^3 cmd \n");
622                         sprint(self, "  No arguments required.\n");
623                         return;
624                 }
625         }
626 }
627 */
628
629
630 // =====================================
631 //  Macro system for networked commands
632 // =====================================
633
634 // Do not hard code aliases for these, instead create them in commands.cfg... also: keep in alphabetical order, please ;)
635 #define CLIENT_COMMANDS(request,arguments,command) \
636         CLIENT_COMMAND("autoswitch", ClientCommand_autoswitch(request, arguments), "Whether or not to switch automatically when getting a better weapon") \
637         CLIENT_COMMAND("clientversion", ClientCommand_clientversion(request, arguments), "Release version of the game") \
638         CLIENT_COMMAND("mv_getpicture", ClientCommand_mv_getpicture(request, arguments), "Retrieve mapshot picture from the server") \
639         CLIENT_COMMAND("join", ClientCommand_join(request), "Become a player in the game") \
640         CLIENT_COMMAND("physics", ClientCommand_physics(request, arguments), "Change physics set") \
641         CLIENT_COMMAND("ready", ClientCommand_ready(request), "Qualify as ready to end warmup stage (or restart server if allowed)") \
642         CLIENT_COMMAND("say", ClientCommand_say(request, arguments, command), "Print a message to chat to all players") \
643         CLIENT_COMMAND("say_team", ClientCommand_say_team(request, arguments, command), "Print a message to chat to all team mates") \
644         CLIENT_COMMAND("selectteam", ClientCommand_selectteam(request, arguments), "Attempt to choose a team to join into") \
645         CLIENT_COMMAND("selfstuff", ClientCommand_selfstuff(request, command), "Stuffcmd a command to your own client") \
646         CLIENT_COMMAND("sentcvar", ClientCommand_sentcvar(request, arguments, command), "New system for sending a client cvar to the server") \
647         CLIENT_COMMAND("spectate", ClientCommand_spectate(request), "Become an observer") \
648         CLIENT_COMMAND("suggestmap", ClientCommand_suggestmap(request, arguments), "Suggest a map to the mapvote at match end") \
649         CLIENT_COMMAND("tell", ClientCommand_tell(request, arguments, command), "Send a message directly to a player") \
650         CLIENT_COMMAND("voice", ClientCommand_voice(request, arguments, command), "Send voice message via sound") \
651         CLIENT_COMMAND("minigame", ClientCommand_minigame(request, arguments, command), "Start a minigame") \
652         /* nothing */
653
654 void ClientCommand_macro_help()
655 {
656         #define CLIENT_COMMAND(name,function,description) \
657                 { sprint(self, "  ^2", name, "^7: ", description, "\n"); }
658
659         CLIENT_COMMANDS(0, 0, "");
660         #undef CLIENT_COMMAND
661
662         return;
663 }
664
665 float ClientCommand_macro_command(float argc, string command)
666 {
667         #define CLIENT_COMMAND(name,function,description) \
668                 { if(name == strtolower(argv(0))) { function; return true; } }
669
670         CLIENT_COMMANDS(CMD_REQUEST_COMMAND, argc, command);
671         #undef CLIENT_COMMAND
672
673         return false;
674 }
675
676 float ClientCommand_macro_usage(float argc)
677 {
678         #define CLIENT_COMMAND(name,function,description) \
679                 { if(name == strtolower(argv(1))) { function; return true; } }
680
681         CLIENT_COMMANDS(CMD_REQUEST_USAGE, argc, "");
682         #undef CLIENT_COMMAND
683
684         return false;
685 }
686
687 void ClientCommand_macro_write_aliases(float fh)
688 {
689         #define CLIENT_COMMAND(name,function,description) \
690                 { CMD_Write_Alias("qc_cmd_cmd", name, description); }
691
692         CLIENT_COMMANDS(0, 0, "");
693         #undef CLIENT_COMMAND
694
695         return;
696 }
697
698 // ======================================
699 //  Main Function Called By Engine (cmd)
700 // ======================================
701 // If this function exists, server game code parses clientcommand before the engine code gets it.
702
703 void SV_ParseClientCommand(string command)
704 {
705         // If invalid UTF-8, don't even parse it
706         string command2 = "";
707         float len = strlen(command);
708         float i;
709         for (i = 0; i < len; ++i)
710                 command2 = strcat(command2, chr2str(str2chr(command, i)));
711         if (command != command2)
712                 return;
713
714         // if we're banned, don't even parse the command
715         if(Ban_MaybeEnforceBanOnce(self))
716                 return;
717
718         float argc = tokenize_console(command);
719
720         // Guide for working with argc arguments by example:
721         // argc:   1    - 2      - 3     - 4
722         // argv:   0    - 1      - 2     - 3
723         // cmd     vote - master - login - password
724
725         // for floodcheck
726         switch(strtolower(argv(0)))
727         {
728                 // exempt commands which are not subject to floodcheck
729                 case "begin": break; // handled by engine in host_cmd.c
730                 case "download": break; // handled by engine in cl_parse.c
731                 case "mv_getpicture": break; // handled by server in this file
732                 case "pause": break; // handled by engine in host_cmd.c
733                 case "prespawn": break; // handled by engine in host_cmd.c
734                 case "sentcvar": break; // handled by server in this file
735                 case "spawn": break; // handled by engine in host_cmd.c
736
737                 default:
738                         if(SV_ParseClientCommand_floodcheck())
739                                 break; // "true": continue, as we're not flooding yet
740                         else
741                                 return; // "false": not allowed to continue, halt // print("^1ERROR: ^7ANTISPAM CAUGHT: ", command, ".\n");
742         }
743
744         /* NOTE: should this be disabled? It can be spammy perhaps, but hopefully it's okay for now */
745         if(argv(0) == "help")
746         {
747                 if(argc == 1)
748                 {
749                         sprint(self, "\nClient networked commands:\n");
750                         ClientCommand_macro_help();
751
752                         sprint(self, "\nCommon networked commands:\n");
753                         CommonCommand_macro_help(self);
754
755                         sprint(self, "\nUsage:^3 cmd COMMAND...^7, where possible commands are listed above.\n");
756                         sprint(self, "For help about a specific command, type cmd help COMMAND\n");
757                         return;
758                 }
759                 else if(CommonCommand_macro_usage(argc, self)) // Instead of trying to call a command, we're going to see detailed information about it
760                 {
761                         return;
762                 }
763                 else if(ClientCommand_macro_usage(argc)) // same, but for normal commands now
764                 {
765                         return;
766                 }
767         }
768         else if(MUTATOR_CALLHOOK(SV_ParseClientCommand, strtolower(argv(0)), argc, command))
769         {
770                 return; // handled by a mutator
771         }
772         else if(CheatCommand(argc))
773         {
774                 return; // handled by server/cheats.qc
775         }
776         else if(CommonCommand_macro_command(argc, self, command))
777         {
778                 return; // handled by server/command/common.qc
779         }
780         else if(ClientCommand_macro_command(argc, command)) // continue as usual and scan for normal commands
781         {
782                 return; // handled by one of the above ClientCommand_* functions
783         }
784         else
785                 clientcommand(self, command);
786 }