Merge branch 'master' into terencehill/bot_AI_improvements
[xonotic/xonotic-data.pk3dir.git] / qcsrc / server / command / cmd.qc
1 #include "cmd.qh"
2 #include <common/command/_mod.qh>
3
4 #include "common.qh"
5 #include "vote.qh"
6
7 #include "../campaign.qh"
8 #include "../cheats.qh"
9 #include "../player.qh"
10 #include "../ipban.qh"
11 #include "../mapvoting.qh"
12 #include "../scores.qh"
13 #include "../teamplay.qh"
14
15 #include "../mutators/_mod.qh"
16
17 #ifdef SVQC
18         #include <common/vehicles/all.qh>
19 #endif
20
21 #include <common/constants.qh>
22 #include <common/deathtypes/all.qh>
23 #include <common/effects/all.qh>
24 #include <common/mapinfo.qh>
25 #include <common/notifications/all.qh>
26 #include <common/physics/player.qh>
27 #include <common/teams.qh>
28 #include <common/util.qh>
29 #include <common/triggers/triggers.qh>
30
31 #include <common/minigames/sv_minigames.qh>
32
33 #include <common/monsters/_mod.qh>
34 #include <common/monsters/sv_spawn.qh>
35 #include <common/monsters/sv_monsters.qh>
36
37 #include <lib/warpzone/common.qh>
38
39 void ClientKill_TeamChange(entity this, float targetteam);  // 0 = don't change, -1 = auto, -2 = spec
40
41 // =========================================================
42 //  Server side networked commands code, reworked by Samual
43 //  Last updated: December 28th, 2011
44 // =========================================================
45
46 bool SV_ParseClientCommand_floodcheck(entity this)
47 {
48         if (!timeout_status)  // not while paused
49         {
50                 if (time <= (this.cmd_floodtime + autocvar_sv_clientcommand_antispam_time))
51                 {
52                         this.cmd_floodcount += 1;
53                         if (this.cmd_floodcount > autocvar_sv_clientcommand_antispam_count)   return false;  // too much spam, halt
54                 }
55                 else
56                 {
57                         this.cmd_floodtime = time;
58                         this.cmd_floodcount = 1;
59                 }
60         }
61         return true;  // continue, as we're not flooding yet
62 }
63
64
65 // =======================
66 //  Command Sub-Functions
67 // =======================
68
69 void ClientCommand_autoswitch(entity caller, float request, float argc)
70 {
71         switch (request)
72         {
73                 case CMD_REQUEST_COMMAND:
74                 {
75                         if (argv(1) != "")
76                         {
77                                 caller.autoswitch = InterpretBoolean(argv(1));
78                                 sprint(caller, strcat("^1autoswitch is currently turned ", (caller.autoswitch ? "on" : "off"), ".\n"));
79                                 return;
80                         }
81                 }
82
83                 default:
84                         sprint(caller, "Incorrect parameters for ^2autoswitch^7\n");
85                 case CMD_REQUEST_USAGE:
86                 {
87                         sprint(caller, "\nUsage:^3 cmd autoswitch selection\n");
88                         sprint(caller, "  Where 'selection' controls if autoswitch is on or off.\n");
89                         return;
90                 }
91         }
92 }
93
94 void ClientCommand_clientversion(entity caller, float request, float argc)  // internal command, used only by code
95 {
96         switch (request)
97         {
98                 case CMD_REQUEST_COMMAND:
99                 {
100                         if (argv(1) != "")
101                         {
102                                 if (IS_CLIENT(caller))
103                                 {
104                                         caller.version = ((argv(1) == "$gameversion") ? 1 : stof(argv(1)));
105
106                                         if (caller.version < autocvar_gameversion_min || caller.version > autocvar_gameversion_max)
107                                         {
108                                                 caller.version_mismatch = 1;
109                                                 ClientKill_TeamChange(caller, -2);  // observe
110                                         }
111                                         else if (autocvar_g_campaign || autocvar_g_balance_teams)
112                                         {
113                                                 // JoinBestTeam(caller, false, true);
114                                         }
115                                         else if (teamplay && !autocvar_sv_spectate && !(caller.team_forced > 0))
116                                         {
117                                                 TRANSMUTE(Observer, caller);  // really?
118                                                 stuffcmd(caller, "menu_showteamselect\n");
119                                         }
120                                 }
121
122                                 return;
123                         }
124                 }
125
126                 default:
127                         sprint(caller, "Incorrect parameters for ^2clientversion^7\n");
128                 case CMD_REQUEST_USAGE:
129                 {
130                         sprint(caller, "\nUsage:^3 cmd clientversion version\n");
131                         sprint(caller, "  Where 'version' is the game version reported by caller.\n");
132                         return;
133                 }
134         }
135 }
136
137 void ClientCommand_mv_getpicture(entity caller, float request, float argc)  // internal command, used only by code
138 {
139         switch (request)
140         {
141                 case CMD_REQUEST_COMMAND:
142                 {
143                         if (argv(1) != "")
144                         {
145                                 if (intermission_running) MapVote_SendPicture(caller, stof(argv(1)));
146
147                                 return;
148                         }
149                 }
150
151                 default:
152                         sprint(caller, "Incorrect parameters for ^2mv_getpicture^7\n");
153                 case CMD_REQUEST_USAGE:
154                 {
155                         sprint(caller, "\nUsage:^3 cmd mv_getpicture mapid\n");
156                         sprint(caller, "  Where 'mapid' is the id number of the map to request an image of on the map vote selection menu.\n");
157                         return;
158                 }
159         }
160 }
161
162 bool joinAllowed(entity this);
163 void Join(entity this);
164 void ClientCommand_join(entity caller, float request)
165 {
166         switch (request)
167         {
168                 case CMD_REQUEST_COMMAND:
169                 {
170                         if (!game_stopped)
171                         if (IS_CLIENT(caller) && !IS_PLAYER(caller))
172                         if (joinAllowed(caller))
173                                 Join(caller);
174
175                         return;  // never fall through to usage
176                 }
177
178                 default:
179                 case CMD_REQUEST_USAGE:
180                 {
181                         sprint(caller, "\nUsage:^3 cmd join\n");
182                         sprint(caller, "  No arguments required.\n");
183                         return;
184                 }
185         }
186 }
187
188 void ClientCommand_physics(entity caller, float request, float argc)
189 {
190         switch (request)
191         {
192                 case CMD_REQUEST_COMMAND:
193                 {
194                         string command = strtolower(argv(1));
195
196                         if (!autocvar_g_physics_clientselect)
197                         {
198                                 sprint(caller, "Client physics selection is currently disabled.\n");
199                                 return;
200                         }
201
202                         if (command == "list" || command == "help")
203                         {
204                                 sprint(caller, strcat("Available physics sets: \n\n", autocvar_g_physics_clientselect_options, " default\n"));
205                                 return;
206                         }
207
208                         if (Physics_Valid(command) || command == "default")
209                         {
210                                 stuffcmd(caller, strcat("\nseta cl_physics ", command, "\nsendcvar cl_physics\n"));
211                                 sprint(caller, strcat("^2Physics set successfully changed to ^3", command, "\n"));
212                                 return;
213                         }
214                 }
215
216                 default:
217                         sprint(caller, strcat("Current physics set: ^3", caller.cvar_cl_physics, "\n"));
218                 case CMD_REQUEST_USAGE:
219                 {
220                         sprint(caller, "\nUsage:^3 cmd physics <physics>\n");
221                         sprint(caller, "  See 'cmd physics list' for available physics sets.\n");
222                         sprint(caller, "  Argument 'default' resets to standard physics.\n");
223                         return;
224                 }
225         }
226 }
227
228 void ClientCommand_ready(entity caller, float request)  // todo: anti-spam for toggling readyness
229 {
230         switch (request)
231         {
232                 case CMD_REQUEST_COMMAND:
233                 {
234                         if (IS_CLIENT(caller))
235                         {
236                                 if (warmup_stage || autocvar_sv_ready_restart || g_race_qualifying == 2)
237                                 {
238                                         if (!readyrestart_happened || autocvar_sv_ready_restart_repeatable)
239                                         {
240                                                 if (time < game_starttime) // game is already restarting
241                                                         return;
242                                                 if (caller.ready)            // toggle
243                                                 {
244                                                         caller.ready = false;
245                                                         bprint(caller.netname, "^2 is ^1NOT^2 ready\n");
246                                                 }
247                                                 else
248                                                 {
249                                                         caller.ready = true;
250                                                         bprint(caller.netname, "^2 is ready\n");
251                                                 }
252
253                                                 // cannot reset the game while a timeout is active!
254                                                 if (!timeout_status) ReadyCount();
255                                         }
256                                         else
257                                         {
258                                                 sprint(caller, "^1Game has already been restarted\n");
259                                         }
260                                 }
261                         }
262                         return;  // never fall through to usage
263                 }
264
265                 default:
266                 case CMD_REQUEST_USAGE:
267                 {
268                         sprint(caller, "\nUsage:^3 cmd ready\n");
269                         sprint(caller, "  No arguments required.\n");
270                         return;
271                 }
272         }
273 }
274
275 void ClientCommand_say(entity caller, float request, float argc, string command)
276 {
277         switch (request)
278         {
279                 case CMD_REQUEST_COMMAND:
280                 {
281                         if (argc >= 2)   Say(caller, false, NULL, substring(command, argv_start_index(1), argv_end_index(-1) - argv_start_index(1)), 1);
282                         return;  // never fall through to usage
283                 }
284
285                 default:
286                 case CMD_REQUEST_USAGE:
287                 {
288                         sprint(caller, "\nUsage:^3 cmd say <message>\n");
289                         sprint(caller, "  Where 'message' is the string of text to say.\n");
290                         return;
291                 }
292         }
293 }
294
295 void ClientCommand_say_team(entity caller, float request, float argc, string command)
296 {
297         switch (request)
298         {
299                 case CMD_REQUEST_COMMAND:
300                 {
301                         if (argc >= 2)   Say(caller, true, NULL, substring(command, argv_start_index(1), argv_end_index(-1) - argv_start_index(1)), 1);
302                         return;  // never fall through to usage
303                 }
304
305                 default:
306                 case CMD_REQUEST_USAGE:
307                 {
308                         sprint(caller, "\nUsage:^3 cmd say_team <message>\n");
309                         sprint(caller, "  Where 'message' is the string of text to say.\n");
310                         return;
311                 }
312         }
313 }
314
315 .bool team_selected;
316 void ClientCommand_selectteam(entity caller, float request, float argc)
317 {
318         switch (request)
319         {
320                 case CMD_REQUEST_COMMAND:
321                 {
322                         if (argv(1) != "")
323                         {
324                                 if (IS_CLIENT(caller))
325                                 {
326                                         if (teamplay)
327                                         {
328                                                 if (caller.team_forced <= 0)
329                                                 {
330                                                         if (!lockteams)
331                                                         {
332                                                                 float selection;
333
334                                                                 switch (argv(1))
335                                                                 {
336                                                                         case "red": selection = NUM_TEAM_1;
337                                                                                 break;
338                                                                         case "blue": selection = NUM_TEAM_2;
339                                                                                 break;
340                                                                         case "yellow": selection = NUM_TEAM_3;
341                                                                                 break;
342                                                                         case "pink": selection = NUM_TEAM_4;
343                                                                                 break;
344                                                                         case "auto": selection = (-1);
345                                                                                 break;
346
347                                                                         default: selection = 0;
348                                                                                 break;
349                                                                 }
350
351                                                                 if (selection)
352                                                                 {
353                                                                         if (caller.team == selection && selection != -1 && !IS_DEAD(caller))
354                                                                         {
355                                                                                 sprint(caller, "^7You already are on that team.\n");
356                                                                         }
357                                                                         else if (caller.wasplayer && autocvar_g_changeteam_banned)
358                                                                         {
359                                                                                 sprint(caller, "^1You cannot change team, forbidden by the server.\n");
360                                                                         }
361                                                                         else
362                                                                         {
363                                                                                 if (autocvar_g_balance_teams && autocvar_g_balance_teams_prevent_imbalance)
364                                                                                 {
365                                                                                         CheckAllowedTeams(caller);
366                                                                                         GetTeamCounts(caller);
367                                                                                         if (!TeamSmallerEqThanTeam(Team_TeamToNumber(selection), Team_TeamToNumber(caller.team), caller))
368                                                                                         {
369                                                                                                 Send_Notification(NOTIF_ONE, caller, MSG_INFO, INFO_TEAMCHANGE_LARGERTEAM);
370                                                                                                 return;
371                                                                                         }
372                                                                                 }
373                                                                                 ClientKill_TeamChange(caller, selection);
374                                                                         }
375                                                                         if(!IS_PLAYER(caller))
376                                                                                 caller.team_selected = true; // avoids asking again for team selection on join
377                                                                 }
378                                                         }
379                                                         else
380                                                         {
381                                                                 sprint(caller, "^7The game has already begun, you must wait until the next map to be able to join a team.\n");
382                                                         }
383                                                 }
384                                                 else
385                                                 {
386                                                         sprint(caller, "^7selectteam can not be used as your team is forced\n");
387                                                 }
388                                         }
389                                         else
390                                         {
391                                                 sprint(caller, "^7selectteam can only be used in teamgames\n");
392                                         }
393                                 }
394                                 return;
395                         }
396                 }
397
398                 default:
399                         sprint(caller, "Incorrect parameters for ^2selectteam^7\n");
400                 case CMD_REQUEST_USAGE:
401                 {
402                         sprint(caller, "\nUsage:^3 cmd selectteam team\n");
403                         sprint(caller, "  Where 'team' is the prefered team to try and join.\n");
404                         sprint(caller, "  Full list of options here: \"red, blue, yellow, pink, auto\"\n");
405                         return;
406                 }
407         }
408 }
409
410 void ClientCommand_selfstuff(entity caller, float request, string command)
411 {
412         switch (request)
413         {
414                 case CMD_REQUEST_COMMAND:
415                 {
416                         if (argv(1) != "")
417                         {
418                                 stuffcmd(caller, substring(command, argv_start_index(1), argv_end_index(-1) - argv_start_index(1)));
419                                 return;
420                         }
421                 }
422
423                 default:
424                         sprint(caller, "Incorrect parameters for ^2selfstuff^7\n");
425                 case CMD_REQUEST_USAGE:
426                 {
427                         sprint(caller, "\nUsage:^3 cmd selfstuff <command>\n");
428                         sprint(caller, "  Where 'command' is the string to be stuffed to your client.\n");
429                         return;
430                 }
431         }
432 }
433
434 void ClientCommand_sentcvar(entity caller, float request, float argc, string command)
435 {
436         switch (request)
437         {
438                 case CMD_REQUEST_COMMAND:
439                 {
440                         if (argv(1) != "")
441                         {
442                                 // float tokens;
443                                 string s;
444
445                                 if (argc == 2)  // undefined cvar: use the default value on the server then
446                                 {
447                                         s = strcat(substring(command, argv_start_index(0), argv_end_index(1) - argv_start_index(0)), " \"", cvar_defstring(argv(1)), "\"");
448                                         tokenize_console(s);
449                                 }
450
451                                 GetCvars(caller, 1);
452
453                                 return;
454                         }
455                 }
456
457                 default:
458                         sprint(caller, "Incorrect parameters for ^2sentcvar^7\n");
459                 case CMD_REQUEST_USAGE:
460                 {
461                         sprint(caller, "\nUsage:^3 cmd sentcvar <cvar>\n");
462                         sprint(caller, "  Where 'cvar' is the cvar plus arguments to send to the server.\n");
463                         return;
464                 }
465         }
466 }
467
468 void ClientCommand_spectate(entity caller, float request)
469 {
470         switch (request)
471         {
472                 case CMD_REQUEST_COMMAND:
473                 {
474                         if (!intermission_running && IS_CLIENT(caller))
475                         {
476                                 if((IS_SPEC(caller) || IS_OBSERVER(caller)) && argv(1) != "")
477                                 {
478                                         entity client = GetFilteredEntity(argv(1));
479                                         int spec_accepted = VerifyClientEntity(client, false, false);
480                                         if(spec_accepted > 0 && IS_PLAYER(client))
481                                         {
482                                                 if(Spectate(caller, client))
483                                                         return; // fall back to regular handling
484                                         }
485                                 }
486
487                                 int mutator_returnvalue = MUTATOR_CALLHOOK(ClientCommand_Spectate, caller);
488
489                                 if (mutator_returnvalue == MUT_SPECCMD_RETURN) return;
490
491                                 if ((IS_PLAYER(caller) || mutator_returnvalue == MUT_SPECCMD_FORCE))
492                                 if (autocvar_sv_spectate == 1)
493                                         ClientKill_TeamChange(caller, -2); // observe
494                         }
495                         return; // never fall through to usage
496                 }
497
498                 default:
499                 case CMD_REQUEST_USAGE:
500                 {
501                         sprint(caller, "\nUsage:^3 cmd spectate <client>\n");
502                         sprint(caller, "  Where 'client' can be the player to spectate.\n");
503                         return;
504                 }
505         }
506 }
507
508 void ClientCommand_suggestmap(entity caller, float request, float argc)
509 {
510         switch (request)
511         {
512                 case CMD_REQUEST_COMMAND:
513                 {
514                         if (argv(1) != "")
515                         {
516                                 sprint(caller, strcat(MapVote_Suggest(caller, argv(1)), "\n"));
517                                 return;
518                         }
519                 }
520
521                 default:
522                         sprint(caller, "Incorrect parameters for ^2suggestmap^7\n");
523                 case CMD_REQUEST_USAGE:
524                 {
525                         sprint(caller, "\nUsage:^3 cmd suggestmap map\n");
526                         sprint(caller, "  Where 'map' is the name of the map to suggest.\n");
527                         return;
528                 }
529         }
530 }
531
532 void ClientCommand_tell(entity caller, float request, float argc, string command)
533 {
534         switch (request)
535         {
536                 case CMD_REQUEST_COMMAND:
537                 {
538                         if (argc >= 3)
539                         {
540                                 entity tell_to = GetIndexedEntity(argc, 1);
541                                 float tell_accepted = VerifyClientEntity(tell_to, true, false);
542
543                                 if (tell_accepted > 0)   // the target is a real client
544                                 {
545                                         if (tell_to != caller) // and we're allowed to send to them :D
546                                         {
547                                                 // workaround for argv indexes indexing ascii chars instead of utf8 chars
548                                                 // In this case when the player name contains utf8 chars
549                                                 // the message gets partially trimmed in the beginning.
550                                                 // Potentially this bug affects any substring call that uses
551                                                 // argv_start_index and argv_end_index.
552
553                                                 string utf8_enable_save = cvar_string("utf8_enable");
554                                                 cvar_set("utf8_enable", "0");
555                                                 string msg = substring(command, argv_start_index(next_token), argv_end_index(-1) - argv_start_index(next_token));
556                                                 cvar_set("utf8_enable", utf8_enable_save);
557
558                                                 Say(caller, false, tell_to, msg, true);
559                                                 return;
560                                         }
561                                         else { print_to(caller, "You can't ^2tell^7 a message to yourself."); return; }
562                                 }
563                                 else if (argv(1) == "#0")
564                                 {
565                                         trigger_magicear_processmessage_forallears(caller, -1, NULL, substring(command, argv_start_index(next_token), argv_end_index(-1) - argv_start_index(next_token)));
566                                         return;
567                                 }
568                                 else { print_to(caller, strcat("tell: ", GetClientErrorString(tell_accepted, argv(1)), ".")); return; }
569                         }
570                 }
571
572                 default:
573                         sprint(caller, "Incorrect parameters for ^2tell^7\n");
574                 case CMD_REQUEST_USAGE:
575                 {
576                         sprint(caller, "\nUsage:^3 cmd tell client <message>\n");
577                         sprint(caller, "  Where 'client' is the entity number or name of the player to send 'message' to.\n");
578                         return;
579                 }
580         }
581 }
582
583 void ClientCommand_voice(entity caller, float request, float argc, string command)
584 {
585         switch (request)
586         {
587                 case CMD_REQUEST_COMMAND:
588                 {
589                         if (argv(1) != "")
590                         {
591                                 entity e = GetVoiceMessage(argv(1));
592                                 if (!e)
593                                 {
594                                         sprint(caller, sprintf("Invalid voice. Use one of: %s\n", allvoicesamples));
595                                         return;
596                                 }
597                                 if (argc >= 3) VoiceMessage(caller, e, substring(command, argv_start_index(2), argv_end_index(-1) - argv_start_index(2)));
598                                 else VoiceMessage(caller, e, "");
599
600                                 return;
601                         }
602                 }
603
604                 default:
605                         sprint(caller, "Incorrect parameters for ^2voice^7\n");
606                 case CMD_REQUEST_USAGE:
607                 {
608                         sprint(caller, "\nUsage:^3 cmd voice messagetype <soundname>\n");
609                         sprint(caller, "  'messagetype' is the type of broadcast to do, like team only or such,\n");
610                         sprint(caller, "  and 'soundname' is the string/filename of the sound/voice message to play.\n");
611                         return;
612                 }
613         }
614 }
615
616 /* use this when creating a new command, making sure to place it in alphabetical order... also,
617 ** ADD ALL NEW COMMANDS TO commands.cfg WITH PROPER ALIASES IN THE SAME FASHION!
618 void ClientCommand_(entity caller, float request)
619 {
620     switch(request)
621     {
622         case CMD_REQUEST_COMMAND:
623         {
624
625             return; // never fall through to usage
626         }
627
628         default:
629         case CMD_REQUEST_USAGE:
630         {
631             sprint(caller, "\nUsage:^3 cmd \n");
632             sprint(caller, "  No arguments required.\n");
633             return;
634         }
635     }
636 }
637 */
638
639
640 // =====================================
641 //  Macro system for networked commands
642 // =====================================
643
644 // Do not hard code aliases for these, instead create them in commands.cfg... also: keep in alphabetical order, please ;)
645 #define CLIENT_COMMANDS(ent, request, arguments, command) \
646         CLIENT_COMMAND("autoswitch", ClientCommand_autoswitch(ent, request, arguments), "Whether or not to switch automatically when getting a better weapon") \
647         CLIENT_COMMAND("clientversion", ClientCommand_clientversion(ent, request, arguments), "Release version of the game") \
648         CLIENT_COMMAND("mv_getpicture", ClientCommand_mv_getpicture(ent, request, arguments), "Retrieve mapshot picture from the server") \
649         CLIENT_COMMAND("join", ClientCommand_join(ent, request), "Become a player in the game") \
650         CLIENT_COMMAND("physics", ClientCommand_physics(ent, request, arguments), "Change physics set") \
651         CLIENT_COMMAND("ready", ClientCommand_ready(ent, request), "Qualify as ready to end warmup stage (or restart server if allowed)") \
652         CLIENT_COMMAND("say", ClientCommand_say(ent, request, arguments, command), "Print a message to chat to all players") \
653         CLIENT_COMMAND("say_team", ClientCommand_say_team(ent, request, arguments, command), "Print a message to chat to all team mates") \
654         CLIENT_COMMAND("selectteam", ClientCommand_selectteam(ent, request, arguments), "Attempt to choose a team to join into") \
655         CLIENT_COMMAND("selfstuff", ClientCommand_selfstuff(ent, request, command), "Stuffcmd a command to your own client") \
656         CLIENT_COMMAND("sentcvar", ClientCommand_sentcvar(ent, request, arguments, command), "New system for sending a client cvar to the server") \
657         CLIENT_COMMAND("spectate", ClientCommand_spectate(ent, request), "Become an observer") \
658         CLIENT_COMMAND("suggestmap", ClientCommand_suggestmap(ent, request, arguments), "Suggest a map to the mapvote at match end") \
659         CLIENT_COMMAND("tell", ClientCommand_tell(ent, request, arguments, command), "Send a message directly to a player") \
660         CLIENT_COMMAND("voice", ClientCommand_voice(ent, request, arguments, command), "Send voice message via sound") \
661         CLIENT_COMMAND("minigame", ClientCommand_minigame(ent, request, arguments, command), "Start a minigame") \
662         /* nothing */
663
664 void ClientCommand_macro_help(entity caller)
665 {
666         #define CLIENT_COMMAND(name, function, description) \
667                 { sprint(caller, "  ^2", name, "^7: ", description, "\n"); }
668
669         CLIENT_COMMANDS(NULL, 0, 0, "");
670 #undef CLIENT_COMMAND
671 }
672
673 float ClientCommand_macro_command(float argc, entity caller, string command)
674 {
675         #define CLIENT_COMMAND(name, function, description) \
676                 { if (name == strtolower(argv(0))) { function; return true; } }
677
678         CLIENT_COMMANDS(caller, CMD_REQUEST_COMMAND, argc, command);
679 #undef CLIENT_COMMAND
680
681         return false;
682 }
683
684 float ClientCommand_macro_usage(float argc, entity caller)
685 {
686         #define CLIENT_COMMAND(name, function, description) \
687                 { if (name == strtolower(argv(1))) { function; return true; } }
688
689         CLIENT_COMMANDS(caller, CMD_REQUEST_USAGE, argc, "");
690 #undef CLIENT_COMMAND
691
692         return false;
693 }
694
695 void ClientCommand_macro_write_aliases(float fh)
696 {
697         #define CLIENT_COMMAND(name, function, description) \
698                 { CMD_Write_Alias("qc_cmd_cmd", name, description); }
699
700         CLIENT_COMMANDS(NULL, 0, 0, "");
701 #undef CLIENT_COMMAND
702 }
703
704 // ======================================
705 //  Main Function Called By Engine (cmd)
706 // ======================================
707 // If this function exists, server game code parses clientcommand before the engine code gets it.
708
709 void SV_ParseClientCommand(entity this, string command)
710 {
711         // If invalid UTF-8, don't even parse it
712         string command2 = "";
713         float len = strlen(command);
714         float i;
715         for (i = 0; i < len; ++i)
716                 command2 = strcat(command2, chr2str(str2chr(command, i)));
717         if (command != command2) return;
718
719         // if we're banned, don't even parse the command
720         if (Ban_MaybeEnforceBanOnce(this)) return;
721
722         float argc = tokenize_console(command);
723
724         // Guide for working with argc arguments by example:
725         // argc:   1    - 2      - 3     - 4
726         // argv:   0    - 1      - 2     - 3
727         // cmd     vote - master - login - password
728
729         // for floodcheck
730         switch (strtolower(argv(0)))
731         {
732                 // exempt commands which are not subject to floodcheck
733                 case "begin": break;                               // handled by engine in host_cmd.c
734                 case "download": break;                            // handled by engine in cl_parse.c
735                 case "mv_getpicture": break;                       // handled by server in this file
736                 case "pause": break;                               // handled by engine in host_cmd.c
737                 case "prespawn": break;                            // handled by engine in host_cmd.c
738                 case "sentcvar": break;                            // handled by server in this file
739                 case "spawn": break;                               // handled by engine in host_cmd.c
740                 case "c2s": Net_ClientCommand(this, command); return; // handled by net.qh
741
742                 default:
743                         if (SV_ParseClientCommand_floodcheck(this)) break; // "true": continue, as we're not flooding yet
744                         else return;                                   // "false": not allowed to continue, halt // print("^1ERROR: ^7ANTISPAM CAUGHT: ", command, ".\n");
745         }
746
747         /* NOTE: should this be disabled? It can be spammy perhaps, but hopefully it's okay for now */
748         if (argv(0) == "help")
749         {
750                 if (argc == 1)
751                 {
752                         sprint(this, "\nClient networked commands:\n");
753                         ClientCommand_macro_help(this);
754
755                         sprint(this, "\nCommon networked commands:\n");
756                         CommonCommand_macro_help(this);
757
758                         sprint(this, "\nUsage:^3 cmd COMMAND...^7, where possible commands are listed above.\n");
759                         sprint(this, "For help about a specific command, type cmd help COMMAND\n");
760                         return;
761                 }
762                 else if (CommonCommand_macro_usage(argc, this))  // Instead of trying to call a command, we're going to see detailed information about it
763                 {
764                         return;
765                 }
766                 else if (ClientCommand_macro_usage(argc, this))  // same, but for normal commands now
767                 {
768                         return;
769                 }
770         }
771         else if (MUTATOR_CALLHOOK(SV_ParseClientCommand, this, strtolower(argv(0)), argc, command))
772         {
773                 return;  // handled by a mutator
774         }
775         else if (CheatCommand(this, argc))
776         {
777                 return;  // handled by server/cheats.qc
778         }
779         else if (CommonCommand_macro_command(argc, this, command))
780         {
781                 return;                                          // handled by server/command/common.qc
782         }
783         else if (ClientCommand_macro_command(argc, this, command)) // continue as usual and scan for normal commands
784         {
785                 return;                                          // handled by one of the above ClientCommand_* functions
786         }
787         else
788         {
789                 clientcommand(this, command);
790         }
791 }