qcsrc/server/command/cmd.qc

   1 #include "../../common/command/command.qh"
   2 #include "cmd.qh"
   3 #include "../_all.qh"
   4
   5 #include "common.qh"
   6 #include "vote.qh"
   7
   8 #include "../campaign.qh"
   9 #include "../cheats.qh"
  10 #include "../cl_player.qh"
  11 #include "../g_triggers.qh"
  12 #include "../ipban.qh"
  13 #include "../mapvoting.qh"
  14 #include "../scores.qh"
  15 #include "../teamplay.qh"
  16
  17 #include "../mutators/mutators_include.qh"
  18
  19 #ifdef SVQC
  20         #include "../vehicles/vehicle.qh"
  21 #endif
  22
  23 #include "../../common/constants.qh"
  24 #include "../../common/deathtypes.qh"
  25 #include "../../common/mapinfo.qh"
  26 #include "../../common/notifications.qh"
  27 #include "../../common/teams.qh"
  28 #include "../../common/util.qh"
  29
  30 #include "../../common/monsters/all.qh"
  31 #include "../../common/monsters/spawn.qh"
  32 #include "../../common/monsters/sv_monsters.qh"
  33
  34 #include "../../warpzonelib/common.qh"
  35
  36 void ClientKill_TeamChange (float targetteam); // 0 = don't change, -1 = auto, -2 = spec
  37
  38 // =========================================================
  39 //  Server side networked commands code, reworked by Samual
  40 //  Last updated: December 28th, 2011
  41 // =========================================================
  42
  43 float SV_ParseClientCommand_floodcheck()
  44 {
  45         if (!timeout_status) // not while paused
  46         {
  47                 if(time <= (self.cmd_floodtime + autocvar_sv_clientcommand_antispam_time))
  48                 {
  49                         self.cmd_floodcount += 1;
  50                         if(self.cmd_floodcount > autocvar_sv_clientcommand_antispam_count) { return false; } // too much spam, halt
  51                 }
  52                 else
  53                 {
  54                         self.cmd_floodtime = time;
  55                         self.cmd_floodcount = 1;
  56                 }
  57         }
  58         return true; // continue, as we're not flooding yet
  59 }
  60
  61
  62 // =======================
  63 //  Command Sub-Functions
  64 // =======================
  65
  66 void ClientCommand_autoswitch(float request, float argc)
  67 {
  68         switch(request)
  69         {
  70                 case CMD_REQUEST_COMMAND:
  71                 {
  72                         if(argv(1) != "")
  73                         {
  74                                 self.autoswitch = InterpretBoolean(argv(1));
  75                                 sprint(self, strcat("^1autoswitch is currently turned ", (self.autoswitch ? "on" : "off"), ".\n"));
  76                                 return;
  77                         }
  78                 }
  79
  80                 default:
  81                         sprint(self, "Incorrect parameters for ^2autoswitch^7\n");
  82                 case CMD_REQUEST_USAGE:
  83                 {
  84                         sprint(self, "\nUsage:^3 cmd autoswitch selection\n");
  85                         sprint(self, "  Where 'selection' controls if autoswitch is on or off.\n");
  86                         return;
  87                 }
  88         }
  89 }
  90
  91 void ClientCommand_checkfail(float request, string command) // internal command, used only by code
  92 {
  93         switch(request)
  94         {
  95                 case CMD_REQUEST_COMMAND:
  96                 {
  97                         printf("CHECKFAIL: %s (%s) epically failed check %s\n", self.netname, self.netaddress, substring(command, argv_start_index(1), argv_end_index(-1) - argv_start_index(1)));
  98                         self.checkfail = 1;
  99                         return; // never fall through to usage
 100                 }
 101
 102                 default:
 103                         sprint(self, "Incorrect parameters for ^2checkfail^7\n");
 104                 case CMD_REQUEST_USAGE:
 105                 {
 106                         sprint(self, "\nUsage:^3 cmd checkfail <message>\n");
 107                         sprint(self, "  Where 'message' is the message reported by client about the fail.\n");
 108                         return;
 109                 }
 110         }
 111 }
 112
 113 void ClientCommand_clientversion(float request, float argc) // internal command, used only by code
 114 {
 115         switch(request)
 116         {
 117                 case CMD_REQUEST_COMMAND:
 118                 {
 119                         if(argv(1) != "")
 120                         {
 121                                 if(IS_CLIENT(self))
 122                                 {
 123                                         self.version = ((argv(1) == "$gameversion") ? 1 : stof(argv(1)));
 124
 125                                         if(self.version < autocvar_gameversion_min || self.version > autocvar_gameversion_max)
 126                                         {
 127                                                 self.version_mismatch = 1;
 128                                                 ClientKill_TeamChange(-2); // observe
 129                                         }
 130                                         else if(autocvar_g_campaign || autocvar_g_balance_teams)
 131                                         {
 132                                                 //JoinBestTeam(self, false, true);
 133                                         }
 134                                         else if(teamplay && !autocvar_sv_spectate && !(self.team_forced > 0))
 135                                         {
 136                                                 self.classname = "observer"; // really?
 137                                                 stuffcmd(self, "menu_showteamselect\n");
 138                                         }
 139                                 }
 140
 141                                 return;
 142                         }
 143                 }
 144
 145                 default:
 146                         sprint(self, "Incorrect parameters for ^2clientversion^7\n");
 147                 case CMD_REQUEST_USAGE:
 148                 {
 149                         sprint(self, "\nUsage:^3 cmd clientversion version\n");
 150                         sprint(self, "  Where 'version' is the game version reported by self.\n");
 151                         return;
 152                 }
 153         }
 154 }
 155
 156 void ClientCommand_mv_getpicture(float request, float argc) // internal command, used only by code
 157 {
 158         switch(request)
 159         {
 160                 case CMD_REQUEST_COMMAND:
 161                 {
 162                         if(argv(1) != "")
 163                         {
 164                                 if(intermission_running)
 165                                         MapVote_SendPicture(stof(argv(1)));
 166
 167                                 return;
 168                         }
 169                 }
 170
 171                 default:
 172                         sprint(self, "Incorrect parameters for ^2mv_getpicture^7\n");
 173                 case CMD_REQUEST_USAGE:
 174                 {
 175                         sprint(self, "\nUsage:^3 cmd mv_getpicture mapid\n");
 176                         sprint(self, "  Where 'mapid' is the id number of the map to request an image of on the map vote selection menu.\n");
 177                         return;
 178                 }
 179         }
 180 }
 181
 182 void ClientCommand_join(float request)
 183 {
 184         switch(request)
 185         {
 186                 case CMD_REQUEST_COMMAND:
 187                 {
 188                         if(IS_CLIENT(self))
 189                         {
 190                                 if(!IS_PLAYER(self) && !lockteams && !gameover)
 191                                 {
 192                                         if(self.caplayer)
 193                                                 return;
 194                                         if(nJoinAllowed(self))
 195                                         {
 196                                                 if(autocvar_g_campaign) { campaign_bots_may_start = 1; }
 197
 198                                                 self.classname = "player";
 199                                                 PlayerScore_Clear(self);
 200                                                 Kill_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER_CPID, CPID_PREVENT_JOIN);
 201                                                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_JOIN_PLAY, self.netname);
 202                                                 PutClientInServer();
 203                                         }
 204                                         else
 205                                         {
 206                                                 //player may not join because of g_maxplayers is set
 207                                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_JOIN_PREVENT);
 208                                         }
 209                                 }
 210                         }
 211                         return; // never fall through to usage
 212                 }
 213
 214                 default:
 215                 case CMD_REQUEST_USAGE:
 216                 {
 217                         sprint(self, "\nUsage:^3 cmd join\n");
 218                         sprint(self, "  No arguments required.\n");
 219                         return;
 220                 }
 221         }
 222 }
 223
 224 void ClientCommand_mobedit(float request, float argc)
 225 {
 226         switch(request)
 227         {
 228                 case CMD_REQUEST_COMMAND:
 229                 {
 230                         if(argv(1) && argv(2))
 231                         {
 232                                 makevectors(self.v_angle);
 233                                 WarpZone_TraceLine(self.origin + self.view_ofs, self.origin + self.view_ofs + v_forward * 100, MOVE_NORMAL, self);
 234
 235                                 if(!autocvar_g_monsters_edit) { sprint(self, "Monster property editing is not enabled.\n"); return; }
 236                                 if(trace_ent.flags & FL_MONSTER)
 237                                 {
 238                                         if(trace_ent.realowner != self) { sprint(self, "That monster does not belong to you.\n"); return; }
 239                                         switch(argv(1))
 240                                         {
 241                                                 case "skin":
 242                                                 {
 243                                                         if(trace_ent.monsterid != MON_MAGE)
 244                                                                 trace_ent.skin = stof(argv(2));
 245                                                         return;
 246                                                 }
 247                                                 case "movetarget":
 248                                                 {
 249                                                         trace_ent.monster_moveflags = stof(argv(2));
 250                                                         return;
 251                                                 }
 252                                         }
 253                                 }
 254                         }
 255                 }
 256                 default:
 257                         sprint(self, "Incorrect parameters for ^2mobedit^7\n");
 258                 case CMD_REQUEST_USAGE:
 259                 {
 260                         sprint(self, "\nUsage:^3 cmd mobedit [argument]\n");
 261                         sprint(self, "  Where 'argument' can be skin or movetarget.\n");
 262                         sprint(self, "  Aim at your monster to edit its properties.\n");
 263                         return;
 264                 }
 265         }
 266 }
 267
 268 void ClientCommand_mobkill(float request)
 269 {
 270         switch(request)
 271         {
 272                 case CMD_REQUEST_COMMAND:
 273                 {
 274                         makevectors(self.v_angle);
 275                         WarpZone_TraceLine(self.origin + self.view_ofs, self.origin + self.view_ofs + v_forward * 100, MOVE_NORMAL, self);
 276
 277                         if(trace_ent.flags & FL_MONSTER)
 278                         {
 279                                 if(trace_ent.realowner != self)
 280                                 {
 281                                         sprint(self, "That monster does not belong to you.\n");
 282                                         return;
 283                                 }
 284                                 sprint(self, strcat("Your pet '", trace_ent.monster_name, "' has been brutally mutilated.\n"));
 285                                 Damage (trace_ent, world, world, trace_ent.health + trace_ent.max_health + 200, DEATH_KILL, trace_ent.origin, '0 0 0');
 286                                 return;
 287                         }
 288                 }
 289
 290                 default:
 291                         sprint(self, "Incorrect parameters for ^2mobkill^7\n");
 292                 case CMD_REQUEST_USAGE:
 293                 {
 294                         sprint(self, "\nUsage:^3 cmd mobkill\n");
 295                         sprint(self, "  Aim at your monster to kill it.\n");
 296                         return;
 297                 }
 298         }
 299 }
 300
 301 void ClientCommand_mobspawn(float request, float argc)
 302 {
 303         switch(request)
 304         {
 305                 case CMD_REQUEST_COMMAND:
 306                 {
 307                         entity e;
 308                         string tospawn;
 309                         float moveflag, monstercount = 0;
 310
 311                         moveflag = (argv(2) ? stof(argv(2)) : 1); // follow owner if not defined
 312                         tospawn = strtolower(argv(1));
 313
 314                         if(tospawn == "list")
 315                         {
 316                                 sprint(self, monsterlist_reply);
 317                                 return;
 318                         }
 319
 320                         FOR_EACH_MONSTER(e)
 321                         {
 322                                 if(e.realowner == self)
 323                                         ++monstercount;
 324                         }
 325
 326                         if(autocvar_g_monsters_max <= 0 || autocvar_g_monsters_max_perplayer <= 0) { sprint(self, "Monster spawning is disabled.\n"); return; }
 327                         else if(!IS_PLAYER(self)) { sprint(self, "You can't spawn monsters while spectating.\n"); return; }
 328                         else if(MUTATOR_CALLHOOK(AllowMobSpawning)) { sprint(self, "Monster spawning is currently disabled by a mutator.\n"); return; }
 329                         else if(!autocvar_g_monsters) { Send_Notification(NOTIF_ONE, self, MSG_INFO, INFO_MONSTERS_DISABLED); return; }
 330                         else if(self.vehicle) { sprint(self, "You can't spawn monsters while driving a vehicle.\n"); return; }
 331                         else if(self.frozen) { sprint(self, "You can't spawn monsters while frozen.\n"); return; }
 332                         else if(autocvar_g_campaign) { sprint(self, "You can't spawn monsters in campaign mode.\n"); return; }
 333                         else if(self.deadflag != DEAD_NO) { sprint(self, "You can't spawn monsters while dead.\n"); return; }
 334                         else if(monstercount >= autocvar_g_monsters_max_perplayer) { sprint(self, "You have spawned too many monsters, kill some before trying to spawn any more.\n"); return; }
 335                         else if(totalspawned >= autocvar_g_monsters_max) { sprint(self, "The global maximum monster count has been reached, kill some before trying to spawn any more.\n"); return; }
 336                         else if(tospawn != "")
 337                         {
 338                                 float found = 0, i;
 339                                 entity mon;
 340
 341                                 for(i = MON_FIRST; i <= MON_LAST; ++i)
 342                                 {
 343                                         mon = get_monsterinfo(i);
 344                                         if(mon.netname == tospawn)
 345                                         {
 346                                                 found = true;
 347                                                 break;
 348                                         }
 349                                 }
 350
 351                                 if(found || tospawn == "random")
 352                                 {
 353                                         totalspawned += 1;
 354
 355                                         makevectors(self.v_angle);
 356                                         WarpZone_TraceBox (CENTER_OR_VIEWOFS(self), PL_MIN, PL_MAX, CENTER_OR_VIEWOFS(self) + v_forward * 150, true, self);
 357                                         //WarpZone_TraceLine(self.origin + self.view_ofs, self.origin + self.view_ofs + v_forward * 150, MOVE_NORMAL, self);
 358
 359                                         e = spawnmonster(tospawn, 0, self, self, trace_endpos, false, false, moveflag);
 360
 361                                         sprint(self, strcat("Spawned ", e.monster_name, "\n"));
 362
 363                                         return;
 364                                 }
 365                         }
 366                 }
 367
 368                 default:
 369                         sprint(self, "Incorrect parameters for ^2mobspawn^7\n");
 370                 case CMD_REQUEST_USAGE:
 371                 {
 372                         sprint(self, "\nUsage:^3 cmd mobspawn <random> <monster> [movetype]\n");
 373                         sprint(self, "  See 'cmd mobspawn list' for available monsters.\n");
 374                         sprint(self, "  Argument 'random' spawns a random monster.\n");
 375                         sprint(self, "  Monster will follow the owner if second argument is not defined.\n");
 376                         return;
 377                 }
 378         }
 379 }
 380
 381 void ClientCommand_physics(float request, float argc)
 382 {
 383         switch(request)
 384         {
 385                 case CMD_REQUEST_COMMAND:
 386                 {
 387                         string command = strtolower(argv(1));
 388
 389                         if(!autocvar_g_physics_clientselect)
 390                         {
 391                                 sprint(self, "Client physics selection is currently disabled.\n");
 392                                 return;
 393                         }
 394
 395                         if(command == "list" || command == "help")
 396                         {
 397                                 sprint(self, strcat("Available physics sets: \n\n", autocvar_g_physics_clientselect_options, " default\n"));
 398                                 return;
 399                         }
 400
 401                         if(Physics_Valid(command) || command == "default")
 402                         {
 403                                 stuffcmd(self, strcat("\nseta cl_physics ", command, "\nsendcvar cl_physics\n"));
 404                                 sprint(self, strcat("^2Physics set successfully changed to ^3", command, "\n"));
 405                                 return;
 406                         }
 407                 }
 408
 409                 default:
 410                         sprint(self, strcat("Current physics set: ^3", self.cvar_cl_physics, "\n"));
 411                 case CMD_REQUEST_USAGE:
 412                 {
 413                         sprint(self, "\nUsage:^3 cmd physics <physics>\n");
 414                         sprint(self, "  See 'cmd physics list' for available physics sets.\n");
 415                         sprint(self, "  Argument 'default' resets to standard physics.\n");
 416                         return;
 417                 }
 418         }
 419 }
 420
 421 void ClientCommand_ready(float request) // todo: anti-spam for toggling readyness
 422 {
 423         switch(request)
 424         {
 425                 case CMD_REQUEST_COMMAND:
 426                 {
 427                         if(IS_CLIENT(self))
 428                         {
 429                                 if(warmup_stage || autocvar_sv_ready_restart || g_race_qualifying == 2)
 430                                 {
 431                                         if(!readyrestart_happened || autocvar_sv_ready_restart_repeatable)
 432                                         {
 433                                                 if(time < game_starttime) // game is already restarting
 434                                                         return;
 435                                                 if (self.ready) // toggle
 436                                                 {
 437                                                         self.ready = false;
 438                                                         bprint(self.netname, "^2 is ^1NOT^2 ready\n");
 439                                                 }
 440                                                 else
 441                                                 {
 442                                                         self.ready = true;
 443                                                         bprint(self.netname, "^2 is ready\n");
 444                                                 }
 445
 446                                                 // cannot reset the game while a timeout is active!
 447                                                 if (!timeout_status)
 448                                                         ReadyCount();
 449                                         } else {
 450                                                 sprint(self, "^1Game has already been restarted\n");
 451                                         }
 452                                 }
 453                         }
 454                         return; // never fall through to usage
 455                 }
 456
 457                 default:
 458                 case CMD_REQUEST_USAGE:
 459                 {
 460                         sprint(self, "\nUsage:^3 cmd ready\n");
 461                         sprint(self, "  No arguments required.\n");
 462                         return;
 463                 }
 464         }
 465 }
 466
 467 void ClientCommand_say(float request, float argc, string command)
 468 {
 469         switch(request)
 470         {
 471                 case CMD_REQUEST_COMMAND:
 472                 {
 473                         if(argc >= 2) { Say(self, false, world, substring(command, argv_start_index(1), argv_end_index(-1) - argv_start_index(1)), 1); }
 474                         return; // never fall through to usage
 475                 }
 476
 477                 default:
 478                 case CMD_REQUEST_USAGE:
 479                 {
 480                         sprint(self, "\nUsage:^3 cmd say <message>\n");
 481                         sprint(self, "  Where 'message' is the string of text to say.\n");
 482                         return;
 483                 }
 484         }
 485 }
 486
 487 void ClientCommand_say_team(float request, float argc, string command)
 488 {
 489         switch(request)
 490         {
 491                 case CMD_REQUEST_COMMAND:
 492                 {
 493                         if(argc >= 2) { Say(self, true, world, substring(command, argv_start_index(1), argv_end_index(-1) - argv_start_index(1)), 1); }
 494                         return; // never fall through to usage
 495                 }
 496
 497                 default:
 498                 case CMD_REQUEST_USAGE:
 499                 {
 500                         sprint(self, "\nUsage:^3 cmd say_team <message>\n");
 501                         sprint(self, "  Where 'message' is the string of text to say.\n");
 502                         return;
 503                 }
 504         }
 505 }
 506
 507 void ClientCommand_selectteam(float request, float argc)
 508 {
 509         switch(request)
 510         {
 511                 case CMD_REQUEST_COMMAND:
 512                 {
 513                         if(argv(1) != "")
 514                         {
 515                                 if(IS_CLIENT(self))
 516                                 {
 517                                         if(teamplay)
 518                                                 if(self.team_forced <= 0)
 519                                                         if (!lockteams)
 520                                                         {
 521                                                                 float selection;
 522
 523                                                                 switch(argv(1))
 524                                                                 {
 525                                                                         case "red": selection = NUM_TEAM_1; break;
 526                                                                         case "blue": selection = NUM_TEAM_2; break;
 527                                                                         case "yellow": selection = NUM_TEAM_3; break;
 528                                                                         case "pink": selection = NUM_TEAM_4; break;
 529                                                                         case "auto": selection = (-1); break;
 530
 531                                                                         default: selection = 0; break;
 532                                                                 }
 533
 534                                                                 if(selection)
 535                                                                 {
 536                                                                         if(self.team == selection && self.deadflag == DEAD_NO)
 537                                                                                 sprint(self, "^7You already are on that team.\n");
 538                                                                         else if(self.wasplayer && autocvar_g_changeteam_banned)
 539                                                                                 sprint(self, "^1You cannot change team, forbidden by the server.\n");
 540                                                                         else
 541                                                                         {
 542                                                                                 if(autocvar_g_balance_teams && autocvar_g_balance_teams_prevent_imbalance)
 543                                                                                 {
 544                                                                                         CheckAllowedTeams(self);
 545                                                                                         GetTeamCounts(self);
 546                                                                                         if(!TeamSmallerEqThanTeam(Team_TeamToNumber(selection), Team_TeamToNumber(self.team), self))
 547                                                                                         {
 548                                                                                                 Send_Notification(NOTIF_ONE, self, MSG_INFO, INFO_TEAMCHANGE_LARGERTEAM);
 549                                                                                                 return;
 550                                                                                         }
 551                                                                                 }
 552                                                                                 ClientKill_TeamChange(selection);
 553                                                                         }
 554                                                                 }
 555                                                         }
 556                                                         else
 557                                                                 sprint(self, "^7The game has already begun, you must wait until the next map to be able to join a team.\n");
 558                                                 else
 559                                                         sprint(self, "^7selectteam can not be used as your team is forced\n");
 560                                         else
 561                                                 sprint(self, "^7selectteam can only be used in teamgames\n");
 562                                 }
 563                                 return;
 564                         }
 565                 }
 566
 567                 default:
 568                         sprint(self, "Incorrect parameters for ^2selectteam^7\n");
 569                 case CMD_REQUEST_USAGE:
 570                 {
 571                         sprint(self, "\nUsage:^3 cmd selectteam team\n");
 572                         sprint(self, "  Where 'team' is the prefered team to try and join.\n");
 573                         sprint(self, "  Full list of options here: \"red, blue, yellow, pink, auto\"\n");
 574                         return;
 575                 }
 576         }
 577 }
 578
 579 void ClientCommand_selfstuff(float request, string command)
 580 {
 581         switch(request)
 582         {
 583                 case CMD_REQUEST_COMMAND:
 584                 {
 585                         if(argv(1) != "")
 586                         {
 587                                 stuffcmd(self, substring(command, argv_start_index(1), argv_end_index(-1) - argv_start_index(1)));
 588                                 return;
 589                         }
 590                 }
 591
 592                 default:
 593                         sprint(self, "Incorrect parameters for ^2selectteam^7\n");
 594                 case CMD_REQUEST_USAGE:
 595                 {
 596                         sprint(self, "\nUsage:^3 cmd selfstuff <command>\n");
 597                         sprint(self, "  Where 'command' is the string to be stuffed to your client.\n");
 598                         return;
 599                 }
 600         }
 601 }
 602
 603 void ClientCommand_sentcvar(float request, float argc, string command)
 604 {
 605         switch(request)
 606         {
 607                 case CMD_REQUEST_COMMAND:
 608                 {
 609                         if(argv(1) != "")
 610                         {
 611                                 //float tokens;
 612                                 string s;
 613
 614                                 if(argc == 2) // undefined cvar: use the default value on the server then
 615                                 {
 616                                         s = strcat(substring(command, argv_start_index(0), argv_end_index(1) - argv_start_index(0)), " \"", cvar_defstring(argv(1)), "\"");
 617                                         tokenize_console(s);
 618                                 }
 619
 620                                 GetCvars(1);
 621
 622                                 return;
 623                         }
 624                 }
 625
 626                 default:
 627                         sprint(self, "Incorrect parameters for ^2sentcvar^7\n");
 628                 case CMD_REQUEST_USAGE:
 629                 {
 630                         sprint(self, "\nUsage:^3 cmd sentcvar <cvar>\n");
 631                         sprint(self, "  Where 'cvar' is the cvar plus arguments to send to the server.\n");
 632                         return;
 633                 }
 634         }
 635 }
 636
 637 void ClientCommand_spectate(float request)
 638 {
 639         switch(request)
 640         {
 641                 case CMD_REQUEST_COMMAND:
 642                 {
 643                         if(IS_CLIENT(self))
 644                         {
 645                                 if(g_lms)
 646                                 {
 647                                         if(self.lms_spectate_warning)
 648                                         {
 649                                                 // for the forfeit message...
 650                                                 self.lms_spectate_warning = 2;
 651                                                 // mark player as spectator
 652                                                 PlayerScore_Add(self, SP_LMS_RANK, 666 - PlayerScore_Add(self, SP_LMS_RANK, 0));
 653                                         }
 654                                         else
 655                                         {
 656                                                 self.lms_spectate_warning = 1;
 657                                                 sprint(self, "WARNING: you won't be able to enter the game again after spectating in LMS. Use the same command again to spectate anyway.\n");
 658                                                 return;
 659                                         }
 660                                 }
 661
 662                                 if((IS_PLAYER(self) || self.caplayer) && autocvar_sv_spectate == 1)
 663                                 {
 664                                         if(self.caplayer && (IS_SPEC(self) || IS_OBSERVER(self)))
 665                                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_CA_LEAVE);
 666                                         ClientKill_TeamChange(-2); // observe
 667                                 }
 668                         }
 669                         return; // never fall through to usage
 670                 }
 671
 672                 default:
 673                 case CMD_REQUEST_USAGE:
 674                 {
 675                         sprint(self, "\nUsage:^3 cmd spectate\n");
 676                         sprint(self, "  No arguments required.\n");
 677                         return;
 678                 }
 679         }
 680 }
 681
 682 void ClientCommand_suggestmap(float request, float argc)
 683 {
 684         switch(request)
 685         {
 686                 case CMD_REQUEST_COMMAND:
 687                 {
 688                         if(argv(1) != "")
 689                         {
 690                                 sprint(self, strcat(MapVote_Suggest(argv(1)), "\n"));
 691                                 return;
 692                         }
 693                 }
 694
 695                 default:
 696                         sprint(self, "Incorrect parameters for ^2suggestmap^7\n");
 697                 case CMD_REQUEST_USAGE:
 698                 {
 699                         sprint(self, "\nUsage:^3 cmd suggestmap map\n");
 700                         sprint(self, "  Where 'map' is the name of the map to suggest.\n");
 701                         return;
 702                 }
 703         }
 704 }
 705
 706 void ClientCommand_tell(float request, float argc, string command)
 707 {
 708         switch(request)
 709         {
 710                 case CMD_REQUEST_COMMAND:
 711                 {
 712                         if(argc >= 3)
 713                         {
 714                                 entity tell_to = GetIndexedEntity(argc, 1);
 715                                 float tell_accepted = VerifyClientEntity(tell_to, true, false);
 716
 717                                 if(tell_accepted > 0) // the target is a real client
 718                                 {
 719                                         if(tell_to != self) // and we're allowed to send to them :D
 720                                         {
 721                                                 Say(self, false, tell_to, substring(command, argv_start_index(next_token), argv_end_index(-1) - argv_start_index(next_token)), true);
 722                                                 return;
 723                                         }
 724                                         else { print_to(self, "You can't ^2tell^7 a message to yourself."); return; }
 725                                 }
 726                                 else if(argv(1) == "#0")
 727                                 {
 728                                         trigger_magicear_processmessage_forallears(self, -1, world, substring(command, argv_start_index(next_token), argv_end_index(-1) - argv_start_index(next_token)));
 729                                         return;
 730                                 }
 731                                 else { print_to(self, strcat("tell: ", GetClientErrorString(tell_accepted, argv(1)), ".")); return; }
 732                         }
 733                 }
 734
 735                 default:
 736                         sprint(self, "Incorrect parameters for ^2tell^7\n");
 737                 case CMD_REQUEST_USAGE:
 738                 {
 739                         sprint(self, "\nUsage:^3 cmd tell client <message>\n");
 740                         sprint(self, "  Where 'client' is the entity number or name of the player to send 'message' to.\n");
 741                         return;
 742                 }
 743         }
 744 }
 745
 746 void ClientCommand_voice(float request, float argc, string command)
 747 {
 748         switch(request)
 749         {
 750                 case CMD_REQUEST_COMMAND:
 751                 {
 752                         if(argv(1) != "")
 753                         {
 754                                 if(argc >= 3)
 755                                         VoiceMessage(argv(1), substring(command, argv_start_index(2), argv_end_index(-1) - argv_start_index(2)));
 756                                 else
 757                                         VoiceMessage(argv(1), "");
 758
 759                                 return;
 760                         }
 761                 }
 762
 763                 default:
 764                         sprint(self, "Incorrect parameters for ^2voice^7\n");
 765                 case CMD_REQUEST_USAGE:
 766                 {
 767                         sprint(self, "\nUsage:^3 cmd voice messagetype <soundname>\n");
 768                         sprint(self, "  'messagetype' is the type of broadcast to do, like team only or such,\n");
 769                         sprint(self, "  and 'soundname' is the string/filename of the sound/voice message to play.\n");
 770                         return;
 771                 }
 772         }
 773 }
 774
 775 /* use this when creating a new command, making sure to place it in alphabetical order... also,
 776 ** ADD ALL NEW COMMANDS TO commands.cfg WITH PROPER ALIASES IN THE SAME FASHION!
 777 void ClientCommand_(float request)
 778 {
 779         switch(request)
 780         {
 781                 case CMD_REQUEST_COMMAND:
 782                 {
 783
 784                         return; // never fall through to usage
 785                 }
 786
 787                 default:
 788                 case CMD_REQUEST_USAGE:
 789                 {
 790                         sprint(self, "\nUsage:^3 cmd \n");
 791                         sprint(self, "  No arguments required.\n");
 792                         return;
 793                 }
 794         }
 795 }
 796 */
 797
 798
 799 // =====================================
 800 //  Macro system for networked commands
 801 // =====================================
 802
 803 // Do not hard code aliases for these, instead create them in commands.cfg... also: keep in alphabetical order, please ;)
 804 #define CLIENT_COMMANDS(request,arguments,command) \
 805         CLIENT_COMMAND("autoswitch", ClientCommand_autoswitch(request, arguments), "Whether or not to switch automatically when getting a better weapon") \
 806         CLIENT_COMMAND("checkfail", ClientCommand_checkfail(request, command), "Report if a client-side check failed") \
 807         CLIENT_COMMAND("clientversion", ClientCommand_clientversion(request, arguments), "Release version of the game") \
 808         CLIENT_COMMAND("mv_getpicture", ClientCommand_mv_getpicture(request, arguments), "Retrieve mapshot picture from the server") \
 809         CLIENT_COMMAND("join", ClientCommand_join(request), "Become a player in the game") \
 810         CLIENT_COMMAND("mobedit", ClientCommand_mobedit(request, arguments), "Edit your monster's properties") \
 811         CLIENT_COMMAND("mobkill", ClientCommand_mobkill(request), "Kills your monster") \
 812         CLIENT_COMMAND("mobspawn", ClientCommand_mobspawn(request, arguments), "Spawn monsters infront of yourself") \
 813         CLIENT_COMMAND("physics", ClientCommand_physics(request, arguments), "Change physics set") \
 814         CLIENT_COMMAND("ready", ClientCommand_ready(request), "Qualify as ready to end warmup stage (or restart server if allowed)") \
 815         CLIENT_COMMAND("say", ClientCommand_say(request, arguments, command), "Print a message to chat to all players") \
 816         CLIENT_COMMAND("say_team", ClientCommand_say_team(request, arguments, command), "Print a message to chat to all team mates") \
 817         CLIENT_COMMAND("selectteam", ClientCommand_selectteam(request, arguments), "Attempt to choose a team to join into") \
 818         CLIENT_COMMAND("selfstuff", ClientCommand_selfstuff(request, command), "Stuffcmd a command to your own client") \
 819         CLIENT_COMMAND("sentcvar", ClientCommand_sentcvar(request, arguments, command), "New system for sending a client cvar to the server") \
 820         CLIENT_COMMAND("spectate", ClientCommand_spectate(request), "Become an observer") \
 821         CLIENT_COMMAND("suggestmap", ClientCommand_suggestmap(request, arguments), "Suggest a map to the mapvote at match end") \
 822         CLIENT_COMMAND("tell", ClientCommand_tell(request, arguments, command), "Send a message directly to a player") \
 823         CLIENT_COMMAND("voice", ClientCommand_voice(request, arguments, command), "Send voice message via sound") \
 824         /* nothing */
 825
 826 void ClientCommand_macro_help()
 827 {
 828         #define CLIENT_COMMAND(name,function,description) \
 829                 { sprint(self, "  ^2", name, "^7: ", description, "\n"); }
 830
 831         CLIENT_COMMANDS(0, 0, "");
 832         #undef CLIENT_COMMAND
 833
 834         return;
 835 }
 836
 837 float ClientCommand_macro_command(float argc, string command)
 838 {
 839         #define CLIENT_COMMAND(name,function,description) \
 840                 { if(name == strtolower(argv(0))) { function; return true; } }
 841
 842         CLIENT_COMMANDS(CMD_REQUEST_COMMAND, argc, command);
 843         #undef CLIENT_COMMAND
 844
 845         return false;
 846 }
 847
 848 float ClientCommand_macro_usage(float argc)
 849 {
 850         #define CLIENT_COMMAND(name,function,description) \
 851                 { if(name == strtolower(argv(1))) { function; return true; } }
 852
 853         CLIENT_COMMANDS(CMD_REQUEST_USAGE, argc, "");
 854         #undef CLIENT_COMMAND
 855
 856         return false;
 857 }
 858
 859 void ClientCommand_macro_write_aliases(float fh)
 860 {
 861         #define CLIENT_COMMAND(name,function,description) \
 862                 { CMD_Write_Alias("qc_cmd_cmd", name, description); }
 863
 864         CLIENT_COMMANDS(0, 0, "");
 865         #undef CLIENT_COMMAND
 866
 867         return;
 868 }
 869
 870 // ======================================
 871 //  Main Function Called By Engine (cmd)
 872 // ======================================
 873 // If this function exists, server game code parses clientcommand before the engine code gets it.
 874
 875 void SV_ParseClientCommand(string command)
 876 {
 877         // If invalid UTF-8, don't even parse it
 878         string command2 = "";
 879         float len = strlen(command);
 880         float i;
 881         for (i = 0; i < len; ++i)
 882                 command2 = strcat(command2, chr2str(str2chr(command, i)));
 883         if (command != command2)
 884                 return;
 885
 886         // if we're banned, don't even parse the command
 887         if(Ban_MaybeEnforceBanOnce(self))
 888                 return;
 889
 890         float argc = tokenize_console(command);
 891
 892         // for the mutator hook system
 893         cmd_name = strtolower(argv(0));
 894         cmd_argc = argc;
 895         cmd_string = command;
 896
 897         // Guide for working with argc arguments by example:
 898         // argc:   1    - 2      - 3     - 4
 899         // argv:   0    - 1      - 2     - 3
 900         // cmd     vote - master - login - password
 901
 902         // for floodcheck
 903         switch(strtolower(argv(0)))
 904         {
 905                 // exempt commands which are not subject to floodcheck
 906                 case "begin": break; // handled by engine in host_cmd.c
 907                 case "download": break; // handled by engine in cl_parse.c
 908                 case "mv_getpicture": break; // handled by server in this file
 909                 case "pause": break; // handled by engine in host_cmd.c
 910                 case "prespawn": break; // handled by engine in host_cmd.c
 911                 case "sentcvar": break; // handled by server in this file
 912                 case "spawn": break; // handled by engine in host_cmd.c
 913
 914                 default:
 915                         if(SV_ParseClientCommand_floodcheck())
 916                                 break; // "true": continue, as we're not flooding yet
 917                         else
 918                                 return; // "false": not allowed to continue, halt // print("^1ERROR: ^7ANTISPAM CAUGHT: ", command, ".\n");
 919         }
 920
 921         /* NOTE: should this be disabled? It can be spammy perhaps, but hopefully it's okay for now */
 922         if(argv(0) == "help")
 923         {
 924                 if(argc == 1)
 925                 {
 926                         sprint(self, "\nClient networked commands:\n");
 927                         ClientCommand_macro_help();
 928
 929                         sprint(self, "\nCommon networked commands:\n");
 930                         CommonCommand_macro_help(self);
 931
 932                         sprint(self, "\nUsage:^3 cmd COMMAND...^7, where possible commands are listed above.\n");
 933                         sprint(self, "For help about a specific command, type cmd help COMMAND\n");
 934                         return;
 935                 }
 936                 else if(CommonCommand_macro_usage(argc, self)) // Instead of trying to call a command, we're going to see detailed information about it
 937                 {
 938                         return;
 939                 }
 940                 else if(ClientCommand_macro_usage(argc)) // same, but for normal commands now
 941                 {
 942                         return;
 943                 }
 944         }
 945         else if(MUTATOR_CALLHOOK(SV_ParseClientCommand))
 946         {
 947                 return; // handled by a mutator
 948         }
 949         else if(CheatCommand(argc))
 950         {
 951                 return; // handled by server/cheats.qc
 952         }
 953         else if(CommonCommand_macro_command(argc, self, command))
 954         {
 955                 return; // handled by server/command/common.qc
 956         }
 957         else if(ClientCommand_macro_command(argc, command)) // continue as usual and scan for normal commands
 958         {
 959                 return; // handled by one of the above ClientCommand_* functions
 960         }
 961         else
 962                 clientcommand(self, command);
 963 }