qcsrc/server/command/cmd.qc

   1 #include "cmd.qh"
   2
   3 #include <server/defs.qh>
   4 #include <server/miscfunctions.qh>
   5
   6 #include <common/command/_mod.qh>
   7
   8 #include "common.qh"
   9 #include "vote.qh"
  10
  11 #include "../bot/api.qh"
  12
  13 #include "../campaign.qh"
  14 #include "../cheats.qh"
  15 #include "../client.qh"
  16 #include "../clientkill.qh"
  17 #include "../player.qh"
  18 #include "../ipban.qh"
  19 #include "../mapvoting.qh"
  20 #include "../scores.qh"
  21 #include "../teamplay.qh"
  22
  23 #include <server/mutators/_mod.qh>
  24 #include <common/gamemodes/_mod.qh>
  25
  26 #ifdef SVQC
  27         #include <common/vehicles/all.qh>
  28 #endif
  29
  30 #include <common/constants.qh>
  31 #include <common/deathtypes/all.qh>
  32 #include <common/effects/all.qh>
  33 #include <common/mapinfo.qh>
  34 #include <common/notifications/all.qh>
  35 #include <common/physics/player.qh>
  36 #include <common/teams.qh>
  37 #include <common/util.qh>
  38 #include <common/mapobjects/triggers.qh>
  39
  40 #include <common/minigames/sv_minigames.qh>
  41
  42 #include <common/monsters/_mod.qh>
  43 #include <common/monsters/sv_spawn.qh>
  44 #include <common/monsters/sv_monsters.qh>
  45
  46 #include <lib/warpzone/common.qh>
  47
  48 // =========================================================
  49 //  Server side networked commands code, reworked by Samual
  50 //  Last updated: December 28th, 2011
  51 // =========================================================
  52
  53 bool SV_ParseClientCommand_floodcheck(entity this)
  54 {
  55         entity store = IS_CLIENT(this) ? CS(this) : this; // unfortunately, we need to store these on the client initially
  56
  57         if (!timeout_status)  // not while paused
  58         {
  59                 if (time <= (store.cmd_floodtime + autocvar_sv_clientcommand_antispam_time))
  60                 {
  61                         store.cmd_floodcount += 1;
  62                         if (store.cmd_floodcount > autocvar_sv_clientcommand_antispam_count)   return false;  // too much spam, halt
  63                 }
  64                 else
  65                 {
  66                         store.cmd_floodtime = time;
  67                         store.cmd_floodcount = 1;
  68                 }
  69         }
  70         return true;  // continue, as we're not flooding yet
  71 }
  72
  73
  74 // =======================
  75 //  Command Sub-Functions
  76 // =======================
  77
  78 void ClientCommand_autoswitch(entity caller, int request, int argc)
  79 {
  80         switch (request)
  81         {
  82                 case CMD_REQUEST_COMMAND:
  83                 {
  84                         if (argv(1) != "")
  85                         {
  86                                 CS(caller).autoswitch = InterpretBoolean(argv(1));
  87                                 sprint(caller, strcat("^1autoswitch is currently turned ", (CS(caller).autoswitch ? "on" : "off"), ".\n"));
  88                                 return;
  89                         }
  90                 }
  91
  92                 default:
  93                         sprint(caller, "Incorrect parameters for ^2autoswitch^7\n");
  94                 case CMD_REQUEST_USAGE:
  95                 {
  96                         sprint(caller, "\nUsage:^3 cmd autoswitch selection\n");
  97                         sprint(caller, "  Where 'selection' controls if autoswitch is on or off.\n");
  98                         return;
  99                 }
 100         }
 101 }
 102
 103 void ClientCommand_clientversion(entity caller, int request, int argc)  // internal command, used only by code
 104 {
 105         switch (request)
 106         {
 107                 case CMD_REQUEST_COMMAND:
 108                 {
 109                         if (argv(1) != "")
 110                         {
 111                                 if (IS_CLIENT(caller))
 112                                 {
 113                                         CS(caller).version = ((argv(1) == "$gameversion") ? 1 : stof(argv(1)));
 114
 115                                         if (CS(caller).version < autocvar_gameversion_min || CS(caller).version > autocvar_gameversion_max)
 116                                         {
 117                                                 CS(caller).version_mismatch = true;
 118                                                 ClientKill_TeamChange(caller, -2);  // observe
 119                                         }
 120                                         else if (autocvar_g_campaign || autocvar_g_balance_teams)
 121                                         {
 122                                                 // JoinBestTeam(caller, false, true);
 123                                         }
 124                                         else if (teamplay && !autocvar_sv_spectate && !(Player_GetForcedTeamIndex(caller) > 0))
 125                                         {
 126                                                 TRANSMUTE(Observer, caller);  // really?
 127                                                 stuffcmd(caller, "menu_showteamselect\n");
 128                                         }
 129                                 }
 130
 131                                 return;
 132                         }
 133                 }
 134
 135                 default:
 136                         sprint(caller, "Incorrect parameters for ^2clientversion^7\n");
 137                 case CMD_REQUEST_USAGE:
 138                 {
 139                         sprint(caller, "\nUsage:^3 cmd clientversion version\n");
 140                         sprint(caller, "  Where 'version' is the game version reported by caller.\n");
 141                         return;
 142                 }
 143         }
 144 }
 145
 146 void ClientCommand_mv_getpicture(entity caller, int request, int argc)  // internal command, used only by code
 147 {
 148         switch (request)
 149         {
 150                 case CMD_REQUEST_COMMAND:
 151                 {
 152                         if (argv(1) != "")
 153                         {
 154                                 if (intermission_running) MapVote_SendPicture(caller, stof(argv(1)));
 155
 156                                 return;
 157                         }
 158                 }
 159
 160                 default:
 161                         sprint(caller, "Incorrect parameters for ^2mv_getpicture^7\n");
 162                 case CMD_REQUEST_USAGE:
 163                 {
 164                         sprint(caller, "\nUsage:^3 cmd mv_getpicture mapid\n");
 165                         sprint(caller, "  Where 'mapid' is the id number of the map to request an image of on the map vote selection menu.\n");
 166                         return;
 167                 }
 168         }
 169 }
 170
 171 void ClientCommand_wpeditor(entity caller, int request, int argc)
 172 {
 173         switch (request)
 174         {
 175                 case CMD_REQUEST_COMMAND:
 176                 {
 177                         if (!autocvar_g_waypointeditor)
 178                         {
 179                                 sprint(caller, "ERROR: this command works only if the waypoint editor is on\n");
 180                                 return;
 181                         }
 182
 183                         if (argv(1) != "")
 184                         {
 185                                 if (argv(1) == "spawn")
 186                                 {
 187                                         string s = argv(2);
 188                                         if (!IS_PLAYER(caller))
 189                                                 sprint(caller, "ERROR: this command works only if you are player\n");
 190                                         else
 191                                                 waypoint_spawn_fromeditor(caller, (s == "crosshair"), (s == "jump"), (s == "crouch"), (s == "support"));
 192                                         return;
 193                                 }
 194                                 else if (argv(1) == "remove")
 195                                 {
 196                                         if (!IS_PLAYER(caller))
 197                                                 sprint(caller, "ERROR: this command works only if you are player\n");
 198                                         else
 199                                                 waypoint_remove_fromeditor(caller);
 200                                         return;
 201                                 }
 202                                 else if (argv(1) == "hardwire")
 203                                 {
 204                                         waypoint_start_hardwiredlink(caller);
 205                                         return;
 206                                 }
 207                                 else if (argv(1) == "unreachable")
 208                                 {
 209                                         if (!IS_PLAYER(caller))
 210                                                 sprint(caller, "ERROR: this command works only if you are player\n");
 211                                         else
 212                                                 waypoint_unreachable(caller);
 213                                         return;
 214                                 }
 215                                 else if (argv(1) == "saveall")
 216                                 {
 217                                         waypoint_saveall();
 218                                         return;
 219                                 }
 220                                 else if (argv(1) == "relinkall")
 221                                 {
 222                                         waypoint_schedulerelinkall();
 223                                         return;
 224                                 }
 225                                 else if (argv(1) == "symaxis")
 226                                 {
 227                                         if (argv(2) == "set" || argv(2) == "get")
 228                                         {
 229                                                 waypoint_getSymmetricalAxis_cmd(caller, (argv(2) == "set"), 3);
 230                                                 return;
 231                                         }
 232                                 }
 233                                 else if (argv(1) == "symorigin")
 234                                 {
 235                                         if (argv(2) == "set" || argv(2) == "get")
 236                                         {
 237                                                 waypoint_getSymmetricalOrigin_cmd(caller, (argv(2) == "set"), 3);
 238                                                 return;
 239                                         }
 240                                 }
 241                         }
 242                 }
 243
 244                 default:
 245                         sprint(caller, "Incorrect parameters for ^2wpeditor^7\n");
 246                 case CMD_REQUEST_USAGE:
 247                 {
 248                         sprint(caller, "\nUsage:^3 cmd wpeditor action\n");
 249                         sprint(caller, "  Where 'action' can be:\n");
 250                         sprint(caller, "   ^5spawn^7: spawns a waypoint at player's position\n");
 251                         sprint(caller, "   ^5remove^7: remove player's nearest waypoint\n");
 252                         sprint(caller, "   ^5unreachable^7: useful to reveal waypoints and items unreachable from the current position and spawnpoints without a nearest waypoint\n");
 253                         sprint(caller, "   ^5saveall^7: saves all waypoints and links to file\n");
 254                         sprint(caller, "   ^5relinkall^7: relink all waypoints as if they were respawned\n");
 255                         sprint(caller, "   ^5spawn crosshair^7: spawns a waypoint at crosshair's position (useful to spawn custom jumppad waypoints (spawn another waypoint to create destination))\n");
 256                         sprint(caller, "   ^5spawn jump^7: spawns a jump waypoint (spawn another waypoint to create destination)\n");
 257                         sprint(caller, "   ^5spawn crouch^7: spawns a crouch waypoint\n");
 258                         sprint(caller, "   ^5spawn support^7: spawns a support waypoint (spawn another waypoint to create destination from which all incoming links are removed), useful to replace links to preblematic jumppad/teleport waypoints\n");
 259                         sprint(caller, "   ^5hardwire^7: marks the nearest waypoint as origin of a new hardwired link (spawn another waypoint over an existing one to create destination)\n");
 260                         sprint(caller, "   ^5symorigin get|set\n");
 261                         sprint(caller, "   ^5symorigin get|set p1 p2 ... pX\n");
 262                         sprint(caller, "   ^5symaxis get|set p1 p2\n");
 263                         sprint(caller, "   ^7 where p1 p2 ... pX are positions (\"x y z\", z can be omitted) that you know are perfectly symmetrical");
 264                         sprint(caller, "   ^7 so you can determine origin/axis of symmetry of maps without ctf flags or where flags aren't perfectly symmetrical\n");
 265                         return;
 266                 }
 267         }
 268 }
 269
 270 void ClientCommand_join(entity caller, int request)
 271 {
 272         switch (request)
 273         {
 274                 case CMD_REQUEST_COMMAND:
 275                 {
 276                         if (!game_stopped)
 277                         if (IS_CLIENT(caller) && !IS_PLAYER(caller))
 278                         if (joinAllowed(caller))
 279                                 Join(caller);
 280
 281                         return;  // never fall through to usage
 282                 }
 283
 284                 default:
 285                 case CMD_REQUEST_USAGE:
 286                 {
 287                         sprint(caller, "\nUsage:^3 cmd join\n");
 288                         sprint(caller, "  No arguments required.\n");
 289                         return;
 290                 }
 291         }
 292 }
 293
 294 void ClientCommand_kill(entity caller, int request)
 295 {
 296         switch (request)
 297         {
 298                 case CMD_REQUEST_COMMAND:
 299                 {
 300                         if(IS_SPEC(caller) || IS_OBSERVER(caller))
 301                                 return; // no point warning about this, command does nothing
 302
 303                         if(GetResource(caller, RES_HEALTH) <= 0)
 304                         {
 305                                 sprint(caller, "Can't die - you are already dead!\n");
 306                                 return;
 307                         }
 308
 309                         ClientKill(caller);
 310
 311                         return;  // never fall through to usage
 312                 }
 313
 314                 default:
 315                 case CMD_REQUEST_USAGE:
 316                 {
 317                         sprint(caller, "\nUsage:^3 cmd kill\n");
 318                         sprint(caller, "  No arguments required.\n");
 319                         return;
 320                 }
 321         }
 322 }
 323
 324 void ClientCommand_physics(entity caller, int request, int argc)
 325 {
 326         switch (request)
 327         {
 328                 case CMD_REQUEST_COMMAND:
 329                 {
 330                         string command = strtolower(argv(1));
 331
 332                         if (!autocvar_g_physics_clientselect)
 333                         {
 334                                 sprint(caller, "Client physics selection is currently disabled.\n");
 335                                 return;
 336                         }
 337
 338                         if (command == "list" || command == "help")
 339                         {
 340                                 sprint(caller, strcat("Available physics sets: \n\n", autocvar_g_physics_clientselect_options, " default\n"));
 341                                 return;
 342                         }
 343
 344                         if (Physics_Valid(command) || command == "default")
 345                         {
 346                                 stuffcmd(caller, strcat("\nseta cl_physics ", command, "\nsendcvar cl_physics\n"));
 347                                 sprint(caller, strcat("^2Physics set successfully changed to ^3", command, "\n"));
 348                                 return;
 349                         }
 350                 }
 351
 352                 default:
 353                         sprint(caller, strcat("Current physics set: ^3", CS(caller).cvar_cl_physics, "\n"));
 354                 case CMD_REQUEST_USAGE:
 355                 {
 356                         sprint(caller, "\nUsage:^3 cmd physics <physics>\n");
 357                         sprint(caller, "  See 'cmd physics list' for available physics sets.\n");
 358                         sprint(caller, "  Argument 'default' resets to standard physics.\n");
 359                         return;
 360                 }
 361         }
 362 }
 363
 364 void ClientCommand_ready(entity caller, int request)  // todo: anti-spam for toggling readyness
 365 {
 366         switch (request)
 367         {
 368                 case CMD_REQUEST_COMMAND:
 369                 {
 370                         if (IS_CLIENT(caller))
 371                         {
 372                                 if (warmup_stage || sv_ready_restart || g_race_qualifying == 2)
 373                                 {
 374                                         if (!readyrestart_happened || sv_ready_restart_repeatable)
 375                                         {
 376                                                 if (time < game_starttime) // game is already restarting
 377                                                         return;
 378                                                 if (caller.ready)            // toggle
 379                                                 {
 380                                                         caller.ready = false;
 381                                                         if(IS_PLAYER(caller) || caller.caplayer == 1)
 382                                                                 bprint(playername(caller, false), "^2 is ^1NOT^2 ready\n");
 383                                                 }
 384                                                 else
 385                                                 {
 386                                                         caller.ready = true;
 387                                                         if(IS_PLAYER(caller) || caller.caplayer == 1)
 388                                                                 bprint(playername(caller, false), "^2 is ready\n");
 389                                                 }
 390
 391                                                 // cannot reset the game while a timeout is active!
 392                                                 if (!timeout_status) ReadyCount();
 393                                         }
 394                                         else
 395                                         {
 396                                                 sprint(caller, "^1Game has already been restarted\n");
 397                                         }
 398                                 }
 399                         }
 400                         return;  // never fall through to usage
 401                 }
 402
 403                 default:
 404                 case CMD_REQUEST_USAGE:
 405                 {
 406                         sprint(caller, "\nUsage:^3 cmd ready\n");
 407                         sprint(caller, "  No arguments required.\n");
 408                         return;
 409                 }
 410         }
 411 }
 412
 413 void ClientCommand_say(entity caller, int request, int argc, string command)
 414 {
 415         switch (request)
 416         {
 417                 case CMD_REQUEST_COMMAND:
 418                 {
 419                         if (argc >= 2)   Say(caller, false, NULL, substring(command, argv_start_index(1), argv_end_index(-1) - argv_start_index(1)), 1);
 420                         return;  // never fall through to usage
 421                 }
 422
 423                 default:
 424                 case CMD_REQUEST_USAGE:
 425                 {
 426                         sprint(caller, "\nUsage:^3 cmd say <message>\n");
 427                         sprint(caller, "  Where 'message' is the string of text to say.\n");
 428                         return;
 429                 }
 430         }
 431 }
 432
 433 void ClientCommand_say_team(entity caller, int request, int argc, string command)
 434 {
 435         switch (request)
 436         {
 437                 case CMD_REQUEST_COMMAND:
 438                 {
 439                         if (argc >= 2)
 440                                 Say(caller, true, NULL, substring(command, argv_start_index(1), argv_end_index(-1) - argv_start_index(1)), 1);
 441                         return;  // never fall through to usage
 442                 }
 443
 444                 default:
 445                 case CMD_REQUEST_USAGE:
 446                 {
 447                         sprint(caller, "\nUsage:^3 cmd say_team <message>\n");
 448                         sprint(caller, "  Where 'message' is the string of text to say.\n");
 449                         return;
 450                 }
 451         }
 452 }
 453
 454 .bool team_selected;
 455 void ClientCommand_selectteam(entity caller, int request, int argc)
 456 {
 457         switch (request)
 458         {
 459                 case CMD_REQUEST_COMMAND:
 460                 {
 461                         if (argv(1) == "")
 462                         {
 463                                 return;
 464                         }
 465                         if (!IS_CLIENT(caller))
 466                         {
 467                                 return;
 468                         }
 469                         if (!teamplay)
 470                         {
 471                                 sprint(caller, "^7selectteam can only be used in teamgames\n");
 472                                 return;
 473                         }
 474                         if (Player_GetForcedTeamIndex(caller) > 0)
 475                         {
 476                                 sprint(caller, "^7selectteam can not be used as your team is forced\n");
 477                                 return;
 478                         }
 479                         if (lockteams)
 480                         {
 481                                 sprint(caller, "^7The game has already begun, you must wait until the next map to be able to join a team.\n");
 482                                 return;
 483                         }
 484                         float selection;
 485                         switch (argv(1))
 486                         {
 487                                 case "red":
 488                                 {
 489                                         selection = NUM_TEAM_1;
 490                                         break;
 491                                 }
 492                                 case "blue":
 493                                 {
 494                                         selection = NUM_TEAM_2;
 495                                         break;
 496                                 }
 497                                 case "yellow":
 498                                 {
 499                                         selection = NUM_TEAM_3;
 500                                         break;
 501                                 }
 502                                 case "pink":
 503                                 {
 504                                         selection = NUM_TEAM_4;
 505                                         break;
 506                                 }
 507                                 case "auto":
 508                                 {
 509                                         selection = (-1);
 510                                         break;
 511                                 }
 512                                 default:
 513                                 {
 514                                         return;
 515                                 }
 516                         }
 517                         if (caller.team == selection && selection != -1 && !IS_DEAD(caller))
 518                         {
 519                                 sprint(caller, "^7You already are on that team.\n");
 520                                 return;
 521                         }
 522                         if (CS(caller).wasplayer && autocvar_g_changeteam_banned)
 523                         {
 524                                 sprint(caller, "^1You cannot change team, forbidden by the server.\n");
 525                                 return;
 526                         }
 527                         if ((selection != -1) && autocvar_g_balance_teams &&
 528                                 autocvar_g_balance_teams_prevent_imbalance)
 529                         {
 530                                 entity balance = TeamBalance_CheckAllowedTeams(caller);
 531                                 TeamBalance_GetTeamCounts(balance, caller);
 532                                 if ((Team_IndexToBit(Team_TeamToIndex(selection)) &
 533                                         TeamBalance_FindBestTeams(balance, caller, false)) == 0)
 534                                 {
 535                                         Send_Notification(NOTIF_ONE, caller, MSG_INFO, INFO_TEAMCHANGE_LARGERTEAM);
 536                                         TeamBalance_Destroy(balance);
 537                                         return;
 538                                 }
 539                                 TeamBalance_Destroy(balance);
 540                         }
 541                         ClientKill_TeamChange(caller, selection);
 542                         if (!IS_PLAYER(caller))
 543                         {
 544                                 caller.team_selected = true; // avoids asking again for team selection on join
 545                         }
 546                         return;
 547                 }
 548                 default:
 549                         sprint(caller, "Incorrect parameters for ^2selectteam^7\n");
 550                 case CMD_REQUEST_USAGE:
 551                 {
 552                         sprint(caller, "\nUsage:^3 cmd selectteam team\n");
 553                         sprint(caller, "  Where 'team' is the prefered team to try and join.\n");
 554                         sprint(caller, "  Full list of options here: \"red, blue, yellow, pink, auto\"\n");
 555                         return;
 556                 }
 557         }
 558 }
 559
 560 void ClientCommand_selfstuff(entity caller, int request, string command)
 561 {
 562         switch (request)
 563         {
 564                 case CMD_REQUEST_COMMAND:
 565                 {
 566                         if (argv(1) != "")
 567                         {
 568                                 stuffcmd(caller, substring(command, argv_start_index(1), argv_end_index(-1) - argv_start_index(1)));
 569                                 return;
 570                         }
 571                 }
 572
 573                 default:
 574                         sprint(caller, "Incorrect parameters for ^2selfstuff^7\n");
 575                 case CMD_REQUEST_USAGE:
 576                 {
 577                         sprint(caller, "\nUsage:^3 cmd selfstuff <command>\n");
 578                         sprint(caller, "  Where 'command' is the string to be stuffed to your client.\n");
 579                         return;
 580                 }
 581         }
 582 }
 583
 584 void ClientCommand_sentcvar(entity caller, int request, int argc, string command)
 585 {
 586         switch (request)
 587         {
 588                 case CMD_REQUEST_COMMAND:
 589                 {
 590                         if (argv(1) != "")
 591                         {
 592                                 // float tokens;
 593                                 string s;
 594
 595                                 if (argc == 2)  // undefined cvar: use the default value on the server then
 596                                 {
 597                                         s = strcat(substring(command, argv_start_index(0), argv_end_index(1) - argv_start_index(0)), " \"", cvar_defstring(argv(1)), "\"");
 598                                         tokenize_console(s);
 599                                 }
 600
 601                                 GetCvars(caller, CS(caller), 1);
 602
 603                                 return;
 604                         }
 605                 }
 606
 607                 default:
 608                         sprint(caller, "Incorrect parameters for ^2sentcvar^7\n");
 609                 case CMD_REQUEST_USAGE:
 610                 {
 611                         sprint(caller, "\nUsage:^3 cmd sentcvar <cvar>\n");
 612                         sprint(caller, "  Where 'cvar' is the cvar plus arguments to send to the server.\n");
 613                         return;
 614                 }
 615         }
 616 }
 617
 618 void ClientCommand_spectate(entity caller, int request)
 619 {
 620         switch (request)
 621         {
 622                 case CMD_REQUEST_COMMAND:
 623                 {
 624                         if (!intermission_running && IS_CLIENT(caller))
 625                         {
 626                                 if((IS_SPEC(caller) || IS_OBSERVER(caller)) && argv(1) != "")
 627                                 {
 628                                         entity client = GetFilteredEntity(argv(1));
 629                                         int spec_accepted = VerifyClientEntity(client, false, false);
 630                                         if(spec_accepted > 0 && IS_PLAYER(client))
 631                                         {
 632                                                 if(Spectate(caller, client))
 633                                                         return; // fall back to regular handling
 634                                         }
 635                                 }
 636
 637                                 int mutator_returnvalue = MUTATOR_CALLHOOK(ClientCommand_Spectate, caller);
 638
 639                                 if (mutator_returnvalue == MUT_SPECCMD_RETURN) return;
 640
 641                                 if ((IS_PLAYER(caller) || mutator_returnvalue == MUT_SPECCMD_FORCE))
 642                                 if (autocvar_sv_spectate == 1)
 643                                         ClientKill_TeamChange(caller, -2); // observe
 644                         }
 645                         return; // never fall through to usage
 646                 }
 647
 648                 default:
 649                 case CMD_REQUEST_USAGE:
 650                 {
 651                         sprint(caller, "\nUsage:^3 cmd spectate <client>\n");
 652                         sprint(caller, "  Where 'client' can be the player to spectate.\n");
 653                         return;
 654                 }
 655         }
 656 }
 657
 658 void ClientCommand_suggestmap(entity caller, int request, int argc)
 659 {
 660         switch (request)
 661         {
 662                 case CMD_REQUEST_COMMAND:
 663                 {
 664                         if (argv(1) != "")
 665                         {
 666                                 sprint(caller, strcat(MapVote_Suggest(caller, argv(1)), "\n"));
 667                                 return;
 668                         }
 669                 }
 670
 671                 default:
 672                         sprint(caller, "Incorrect parameters for ^2suggestmap^7\n");
 673                 case CMD_REQUEST_USAGE:
 674                 {
 675                         sprint(caller, "\nUsage:^3 cmd suggestmap map\n");
 676                         sprint(caller, "  Where 'map' is the name of the map to suggest.\n");
 677                         return;
 678                 }
 679         }
 680 }
 681
 682 void ClientCommand_tell(entity caller, int request, int argc, string command)
 683 {
 684         switch (request)
 685         {
 686                 case CMD_REQUEST_COMMAND:
 687                 {
 688                         if (argc >= 3)
 689                         {
 690                                 if(!IS_CLIENT(caller) && IS_REAL_CLIENT(caller)) // connecting
 691                                 {
 692                                         print_to(caller, "You can't ^2tell^7 a message while connecting.");
 693                                         return;
 694                                 }
 695
 696                                 entity tell_to = GetIndexedEntity(argc, 1);
 697                                 float tell_accepted = VerifyClientEntity(tell_to, true, false);
 698
 699                                 if (tell_accepted > 0)   // the target is a real client
 700                                 {
 701                                         if (tell_to != caller) // and we're allowed to send to them :D
 702                                         {
 703                                                 // workaround for argv indexes indexing ascii chars instead of utf8 chars
 704                                                 // In this case when the player name contains utf8 chars
 705                                                 // the message gets partially trimmed in the beginning.
 706                                                 // Potentially this bug affects any substring call that uses
 707                                                 // argv_start_index and argv_end_index.
 708
 709                                                 string utf8_enable_save = cvar_string("utf8_enable");
 710                                                 cvar_set("utf8_enable", "0");
 711                                                 string msg = substring(command, argv_start_index(next_token), argv_end_index(-1) - argv_start_index(next_token));
 712                                                 cvar_set("utf8_enable", utf8_enable_save);
 713
 714                                                 Say(caller, false, tell_to, msg, true);
 715                                                 return;
 716                                         }
 717                                         else { print_to(caller, "You can't ^2tell^7 a message to yourself."); return; }
 718                                 }
 719                                 else if (argv(1) == "#0")
 720                                 {
 721                                         trigger_magicear_processmessage_forallears(caller, -1, NULL, substring(command, argv_start_index(next_token), argv_end_index(-1) - argv_start_index(next_token)));
 722                                         return;
 723                                 }
 724                                 else { print_to(caller, strcat("tell: ", GetClientErrorString(tell_accepted, argv(1)), ".")); return; }
 725                         }
 726                 }
 727
 728                 default:
 729                         sprint(caller, "Incorrect parameters for ^2tell^7\n");
 730                 case CMD_REQUEST_USAGE:
 731                 {
 732                         sprint(caller, "\nUsage:^3 cmd tell client <message>\n");
 733                         sprint(caller, "  Where 'client' is the entity number or name of the player to send 'message' to.\n");
 734                         return;
 735                 }
 736         }
 737 }
 738
 739 void ClientCommand_voice(entity caller, int request, int argc, string command)
 740 {
 741         switch (request)
 742         {
 743                 case CMD_REQUEST_COMMAND:
 744                 {
 745                         if (argv(1) != "")
 746                         {
 747                                 entity e = GetVoiceMessage(argv(1));
 748                                 if (!e)
 749                                 {
 750                                         sprint(caller, sprintf("Invalid voice. Use one of: %s\n", allvoicesamples));
 751                                         return;
 752                                 }
 753                                 string msg = "";
 754                                 if (argc >= 3)
 755                                         msg = substring(command, argv_start_index(2), argv_end_index(-1) - argv_start_index(2));
 756                                 VoiceMessage(caller, e, msg);
 757
 758                                 return;
 759                         }
 760                 }
 761
 762                 default:
 763                         sprint(caller, "Incorrect parameters for ^2voice^7\n");
 764                 case CMD_REQUEST_USAGE:
 765                 {
 766                         sprint(caller, "\nUsage:^3 cmd voice messagetype <soundname>\n");
 767                         sprint(caller, "  'messagetype' is the type of broadcast to do, like team only or such,\n");
 768                         sprint(caller, "  and 'soundname' is the string/filename of the sound/voice message to play.\n");
 769                         return;
 770                 }
 771         }
 772 }
 773
 774 /* use this when creating a new command, making sure to place it in alphabetical order... also,
 775 ** ADD ALL NEW COMMANDS TO commands.cfg WITH PROPER ALIASES IN THE SAME FASHION!
 776 void ClientCommand_(entity caller, int request)
 777 {
 778     switch(request)
 779     {
 780         case CMD_REQUEST_COMMAND:
 781         {
 782
 783             return; // never fall through to usage
 784         }
 785
 786         default:
 787         case CMD_REQUEST_USAGE:
 788         {
 789             sprint(caller, "\nUsage:^3 cmd \n");
 790             sprint(caller, "  No arguments required.\n");
 791             return;
 792         }
 793     }
 794 }
 795 */
 796
 797
 798 // =====================================
 799 //  Macro system for networked commands
 800 // =====================================
 801
 802 // Do not hard code aliases for these, instead create them in commands.cfg... also: keep in alphabetical order, please ;)
 803 #define CLIENT_COMMANDS(ent, request, arguments, command) \
 804         CLIENT_COMMAND("autoswitch", ClientCommand_autoswitch(ent, request, arguments), "Whether or not to switch automatically when getting a better weapon") \
 805         CLIENT_COMMAND("clientversion", ClientCommand_clientversion(ent, request, arguments), "Release version of the game") \
 806         CLIENT_COMMAND("join", ClientCommand_join(ent, request), "Become a player in the game") \
 807         CLIENT_COMMAND("kill", ClientCommand_kill(ent, request), "Become a member of the dead") \
 808         CLIENT_COMMAND("minigame", ClientCommand_minigame(ent, request, arguments, command), "Start a minigame") \
 809         CLIENT_COMMAND("mv_getpicture", ClientCommand_mv_getpicture(ent, request, arguments), "Retrieve mapshot picture from the server") \
 810         CLIENT_COMMAND("physics", ClientCommand_physics(ent, request, arguments), "Change physics set") \
 811         CLIENT_COMMAND("ready", ClientCommand_ready(ent, request), "Qualify as ready to end warmup stage (or restart server if allowed)") \
 812         CLIENT_COMMAND("say", ClientCommand_say(ent, request, arguments, command), "Print a message to chat to all players") \
 813         CLIENT_COMMAND("say_team", ClientCommand_say_team(ent, request, arguments, command), "Print a message to chat to all team mates") \
 814         CLIENT_COMMAND("selectteam", ClientCommand_selectteam(ent, request, arguments), "Attempt to choose a team to join into") \
 815         CLIENT_COMMAND("selfstuff", ClientCommand_selfstuff(ent, request, command), "Stuffcmd a command to your own client") \
 816         CLIENT_COMMAND("sentcvar", ClientCommand_sentcvar(ent, request, arguments, command), "New system for sending a client cvar to the server") \
 817         CLIENT_COMMAND("spectate", ClientCommand_spectate(ent, request), "Become an observer") \
 818         CLIENT_COMMAND("suggestmap", ClientCommand_suggestmap(ent, request, arguments), "Suggest a map to the mapvote at match end") \
 819         CLIENT_COMMAND("tell", ClientCommand_tell(ent, request, arguments, command), "Send a message directly to a player") \
 820         CLIENT_COMMAND("voice", ClientCommand_voice(ent, request, arguments, command), "Send voice message via sound") \
 821         CLIENT_COMMAND("wpeditor", ClientCommand_wpeditor(ent, request, arguments), "Waypoint editor commands") \
 822         /* nothing */
 823
 824 void ClientCommand_macro_help(entity caller)
 825 {
 826         #define CLIENT_COMMAND(name, function, description) \
 827                 { sprint(caller, "  ^2", name, "^7: ", description, "\n"); }
 828
 829         CLIENT_COMMANDS(NULL, 0, 0, "");
 830 #undef CLIENT_COMMAND
 831 }
 832
 833 float ClientCommand_macro_command(int argc, entity caller, string command)
 834 {
 835         #define CLIENT_COMMAND(name, function, description) \
 836                 { if (name == strtolower(argv(0))) { function; return true; } }
 837
 838         CLIENT_COMMANDS(caller, CMD_REQUEST_COMMAND, argc, command);
 839 #undef CLIENT_COMMAND
 840
 841         return false;
 842 }
 843
 844 float ClientCommand_macro_usage(int argc, entity caller)
 845 {
 846         #define CLIENT_COMMAND(name, function, description) \
 847                 { if (name == strtolower(argv(1))) { function; return true; } }
 848
 849         CLIENT_COMMANDS(caller, CMD_REQUEST_USAGE, argc, "");
 850 #undef CLIENT_COMMAND
 851
 852         return false;
 853 }
 854
 855 void ClientCommand_macro_write_aliases(float fh)
 856 {
 857         #define CLIENT_COMMAND(name, function, description) \
 858                 { CMD_Write_Alias("qc_cmd_cmd", name, description); }
 859
 860         CLIENT_COMMANDS(NULL, 0, 0, "");
 861 #undef CLIENT_COMMAND
 862 }
 863
 864 // ======================================
 865 //  Main Function Called By Engine (cmd)
 866 // ======================================
 867 // If this function exists, server game code parses clientcommand before the engine code gets it.
 868
 869 void SV_ParseClientCommand(entity this, string command)
 870 {
 871         // If invalid UTF-8, don't even parse it
 872         string command2 = "";
 873         float len = strlen(command);
 874         float i;
 875         for (i = 0; i < len; ++i)
 876                 command2 = strcat(command2, chr2str(str2chr(command, i)));
 877         if (command != command2) return;
 878
 879         // if we're banned, don't even parse the command
 880         if (Ban_MaybeEnforceBanOnce(this)) return;
 881
 882         int argc = tokenize_console(command);
 883
 884         // Guide for working with argc arguments by example:
 885         // argc:   1    - 2      - 3     - 4
 886         // argv:   0    - 1      - 2     - 3
 887         // cmd     vote - master - login - password
 888
 889         // for floodcheck
 890         switch (strtolower(argv(0)))
 891         {
 892                 // exempt commands which are not subject to floodcheck
 893                 case "begin": break;                               // handled by engine in host_cmd.c
 894                 case "download": break;                            // handled by engine in cl_parse.c
 895                 case "mv_getpicture": break;                       // handled by server in this file
 896                 case "wpeditor": break;                            // handled by server in this file
 897                 case "pause": break;                               // handled by engine in host_cmd.c
 898                 case "prespawn": break;                            // handled by engine in host_cmd.c
 899                 case "sentcvar": break;                            // handled by server in this file
 900                 case "spawn": break;                               // handled by engine in host_cmd.c
 901                 case "c2s": Net_ClientCommand(this, command); return; // handled by net.qh
 902
 903                 default:
 904                         if (SV_ParseClientCommand_floodcheck(this)) break; // "true": continue, as we're not flooding yet
 905                         else return;                                   // "false": not allowed to continue, halt // print("^1ERROR: ^7ANTISPAM CAUGHT: ", command, ".\n");
 906         }
 907
 908         /* NOTE: should this be disabled? It can be spammy perhaps, but hopefully it's okay for now */
 909         if (argv(0) == "help")
 910         {
 911                 if (argc == 1)
 912                 {
 913                         sprint(this, "\nClient networked commands:\n");
 914                         ClientCommand_macro_help(this);
 915
 916                         sprint(this, "\nCommon networked commands:\n");
 917                         CommonCommand_macro_help(this);
 918
 919                         sprint(this, "\nUsage:^3 cmd COMMAND...^7, where possible commands are listed above.\n");
 920                         sprint(this, "For help about a specific command, type cmd help COMMAND\n");
 921                         return;
 922                 }
 923                 else if (CommonCommand_macro_usage(argc, this))  // Instead of trying to call a command, we're going to see detailed information about it
 924                 {
 925                         return;
 926                 }
 927                 else if (ClientCommand_macro_usage(argc, this))  // same, but for normal commands now
 928                 {
 929                         return;
 930                 }
 931         }
 932         else if (MUTATOR_CALLHOOK(SV_ParseClientCommand, this, strtolower(argv(0)), argc, command))
 933         {
 934                 return;  // handled by a mutator
 935         }
 936         else if (CheatCommand(this, argc))
 937         {
 938                 return;  // handled by server/cheats.qc
 939         }
 940         else if (CommonCommand_macro_command(argc, this, command))
 941         {
 942                 return;                                          // handled by server/command/common.qc
 943         }
 944         else if (ClientCommand_macro_command(argc, this, command)) // continue as usual and scan for normal commands
 945         {
 946                 return;                                          // handled by one of the above ClientCommand_* functions
 947         }
 948         else
 949         {
 950                 clientcommand(this, command);
 951         }
 952 }