qcsrc/server/command/cmd.qc

   1 // =========================================================
   2 //  Server side networked commands code, reworked by Samual
   3 //  Last updated: December 28th, 2011
   4 // =========================================================
   5
   6 float SV_ParseClientCommand_floodcheck()
   7 {
   8         if not(timeout_status) // not while paused
   9         {
  10                 if(time <= (self.cmd_floodtime + autocvar_sv_clientcommand_antispam_time))
  11                 {
  12                         self.cmd_floodcount += 1;
  13                         if(self.cmd_floodcount > autocvar_sv_clientcommand_antispam_count) { return FALSE; } // too much spam, halt
  14                 }
  15                 else
  16                 {
  17                         self.cmd_floodtime = time;
  18                         self.cmd_floodcount = 1;
  19                 }
  20         }
  21         return TRUE; // continue, as we're not flooding yet
  22 }
  23
  24
  25 // =======================
  26 //  Command Sub-Functions
  27 // =======================
  28
  29 void ClientCommand_autoswitch(float request, float argc)
  30 {
  31         switch(request)
  32         {
  33                 case CMD_REQUEST_COMMAND:
  34                 {
  35                         if(argv(1) != "")
  36                         {
  37                                 self.autoswitch = InterpretBoolean(argv(1));
  38                                 sprint(self, strcat("^1autoswitch is currently turned ", (self.autoswitch ? "on" : "off"), ".\n"));
  39                                 return;
  40                         }
  41                 }
  42
  43                 default:
  44                         sprint(self, "Incorrect parameters for ^2autoswitch^7\n");
  45                 case CMD_REQUEST_USAGE:
  46                 {
  47                         sprint(self, "\nUsage:^3 cmd autoswitch selection\n");
  48                         sprint(self, "  Where 'selection' controls if autoswitch is on or off.\n");
  49                         return;
  50                 }
  51         }
  52 }
  53
  54 void ClientCommand_checkfail(float request, string command) // internal command, used only by code
  55 {
  56         switch(request)
  57         {
  58                 case CMD_REQUEST_COMMAND:
  59                 {
  60                         print(sprintf("CHECKFAIL: %s (%s) epically failed check %s\n", self.netname, self.netaddress, substring(command, argv_start_index(1), argv_end_index(-1) - argv_start_index(1))));
  61                         self.checkfail = 1;
  62                         return; // never fall through to usage
  63                 }
  64
  65                 default:
  66                         sprint(self, "Incorrect parameters for ^2checkfail^7\n");
  67                 case CMD_REQUEST_USAGE:
  68                 {
  69                         sprint(self, "\nUsage:^3 cmd checkfail <message>\n");
  70                         sprint(self, "  Where 'message' is the message reported by client about the fail.\n");
  71                         return;
  72                 }
  73         }
  74 }
  75
  76 void ClientCommand_clientversion(float request, float argc) // internal command, used only by code
  77 {
  78         switch(request)
  79         {
  80                 case CMD_REQUEST_COMMAND:
  81                 {
  82                         if(argv(1) != "")
  83                         {
  84                                 if(IS_CLIENT(self))
  85                                 {
  86                                         self.version = ((argv(1) == "$gameversion") ? 1 : stof(argv(1)));
  87
  88                                         if(self.version < autocvar_gameversion_min || self.version > autocvar_gameversion_max)
  89                                         {
  90                                                 self.version_mismatch = 1;
  91                                                 ClientKill_TeamChange(-2); // observe
  92                                         }
  93                                         else if(autocvar_g_campaign || autocvar_g_balance_teams)
  94                                         {
  95                                                 //JoinBestTeam(self, FALSE, TRUE);
  96                                         }
  97                                         else if(teamplay && !autocvar_sv_spectate && !(self.team_forced > 0))
  98                                         {
  99                                                 self.classname = "observer"; // really?
 100                                                 stuffcmd(self, "menu_showteamselect\n");
 101                                         }
 102                                 }
 103
 104                                 return;
 105                         }
 106                 }
 107
 108                 default:
 109                         sprint(self, "Incorrect parameters for ^2clientversion^7\n");
 110                 case CMD_REQUEST_USAGE:
 111                 {
 112                         sprint(self, "\nUsage:^3 cmd clientversion version\n");
 113                         sprint(self, "  Where 'version' is the game version reported by self.\n");
 114                         return;
 115                 }
 116         }
 117 }
 118
 119 void ClientCommand_mv_getpicture(float request, float argc) // internal command, used only by code
 120 {
 121         switch(request)
 122         {
 123                 case CMD_REQUEST_COMMAND:
 124                 {
 125                         if(argv(1) != "")
 126                         {
 127                                 if(intermission_running)
 128                                         MapVote_SendPicture(stof(argv(1)));
 129
 130                                 return;
 131                         }
 132                 }
 133
 134                 default:
 135                         sprint(self, "Incorrect parameters for ^2mv_getpicture^7\n");
 136                 case CMD_REQUEST_USAGE:
 137                 {
 138                         sprint(self, "\nUsage:^3 cmd mv_getpicture mapid\n");
 139                         sprint(self, "  Where 'mapid' is the id number of the map to request an image of on the map vote selection menu.\n");
 140                         return;
 141                 }
 142         }
 143 }
 144
 145 void ClientCommand_join(float request)
 146 {
 147         switch(request)
 148         {
 149                 case CMD_REQUEST_COMMAND:
 150                 {
 151                         if(IS_CLIENT(self))
 152                         {
 153                                 if(!IS_PLAYER(self) && !lockteams && !g_arena)
 154                                 {
 155                                         if(nJoinAllowed(self))
 156                                         {
 157                                                 if(autocvar_g_campaign) { campaign_bots_may_start = 1; }
 158
 159                                                 self.classname = "player";
 160                                                 PlayerScore_Clear(self);
 161                                                 Kill_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER_CPID, CPID_PREVENT_JOIN);
 162                                                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_JOIN_PLAY, self.netname);
 163                                                 PutClientInServer();
 164                                         }
 165                                         else
 166                                         {
 167                                                 //player may not join because of g_maxplayers is set
 168                                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_JOIN_PREVENT);
 169                                         }
 170                                 }
 171                         }
 172                         return; // never fall through to usage
 173                 }
 174
 175                 default:
 176                 case CMD_REQUEST_USAGE:
 177                 {
 178                         sprint(self, "\nUsage:^3 cmd join\n");
 179                         sprint(self, "  No arguments required.\n");
 180                         return;
 181                 }
 182         }
 183 }
 184
 185 void ClientCommand_mobedit(float request, float argc)
 186 {
 187         switch(request)
 188         {
 189                 case CMD_REQUEST_COMMAND:
 190                 {
 191                         makevectors(self.v_angle);
 192                         WarpZone_TraceLine(self.origin + self.view_ofs, self.origin + self.view_ofs + v_forward * 100, MOVE_NORMAL, self);
 193
 194                         if not(trace_ent.flags & FL_MONSTER) { sprint(self, "You need to aim at your monster to edit its properties.\n"); return; }
 195                         if(trace_ent.realowner != self) { sprint(self, "That monster does not belong to you.\n"); return; }
 196
 197                         switch(argv(1))
 198                         {
 199                                 case "name": trace_ent.netname = strzone(strdecolorize(argv(2))); if(trace_ent.sprite) WaypointSprite_UpdateSprites(trace_ent.sprite, trace_ent.netname, "", ""); return;
 200                                 case "skin": if(trace_ent.monsterid != MONSTER_MAGE) { trace_ent.skin = stof(argv(2)); trace_ent.SendFlags |= MSF_STATUS; } return;
 201                                 case "movetarget": trace_ent.monster_moveflags = stof(argv(2)); return;
 202                         }
 203                 }
 204                 default:
 205                         sprint(self, "Incorrect parameters for ^2mobedit^7\n");
 206                 case CMD_REQUEST_USAGE:
 207                 {
 208                         sprint(self, "\nUsage:^3 cmd mobedit [argument]\n");
 209                         sprint(self, "  Where 'argument' can be name, color or movetarget.\n");
 210                         return;
 211                 }
 212         }
 213 }
 214
 215 void ClientCommand_mobkill(float request)
 216 {
 217         switch(request)
 218         {
 219                 case CMD_REQUEST_COMMAND:
 220                 {
 221                         makevectors(self.v_angle);
 222                         WarpZone_TraceLine(self.origin + self.view_ofs, self.origin + self.view_ofs + v_forward * 100, MOVE_NORMAL, self);
 223
 224                         if(trace_ent.flags & FL_MONSTER)
 225                         {
 226                                 if(trace_ent.realowner != self)
 227                                 {
 228                                         sprint(self, "That monster does not belong to you.\n");
 229                                         return;
 230                                 }
 231                                 sprint(self, strcat("Your pet '", trace_ent.netname, "' has been brutally mutilated.\n"));
 232                                 Damage (trace_ent, world, world, trace_ent.health + trace_ent.max_health + 200, DEATH_KILL, trace_ent.origin, '0 0 0');
 233                                 return;
 234                         }
 235                         else
 236                                 sprint(self, "You need to aim at your monster to kill it.\n");
 237
 238                         return;
 239                 }
 240
 241                 default:
 242                         sprint(self, "Incorrect parameters for ^2mobkill^7\n");
 243                 case CMD_REQUEST_USAGE:
 244                 {
 245                         sprint(self, "\nUsage:^3 cmd mobkill\n");
 246                         sprint(self, "  Aim at your monster to kill it.\n");
 247                         return;
 248                 }
 249         }
 250 }
 251
 252 void ClientCommand_mobspawn(float request, float argc)
 253 {
 254         switch(request)
 255         {
 256                 case CMD_REQUEST_COMMAND:
 257                 {
 258                         entity e;
 259                         string tospawn, mname;
 260                         float moveflag;
 261
 262                         moveflag = (argv(2) ? stof(argv(2)) : 1); // follow owner if not defined
 263                         tospawn = strtolower(argv(1));
 264                         mname = argv(3);
 265
 266                         if(tospawn == "list")
 267                         {
 268                                 float i;
 269                                 string list = "Available monsters:";
 270
 271                                 for(i = MONSTER_FIRST + 1; i < MONSTER_LAST; ++i)
 272                                         list = strcat(list, " ", monster_id2string(i));
 273
 274                                 sprint(self, strcat(list, "\n"));
 275
 276                                 return;
 277                         }
 278
 279                         if(autocvar_g_monsters_max <= 0 || autocvar_g_monsters_max_perplayer <= 0) { sprint(self, "Monster spawning is disabled.\n"); }
 280                         else if(!IS_PLAYER(self)) { sprint(self, "You can't spawn monsters while spectating.\n"); }
 281                         else if(g_invasion) { sprint(self, "You can't spawn monsters during an invasion!\n"); }
 282                         else if not(autocvar_g_monsters) { Send_Notification(NOTIF_ONE, self, MSG_INFO, INFO_MONSTERS_DISABLED); }
 283                         else if(self.vehicle) { sprint(self, "You can't spawn monsters while driving a vehicle.\n"); }
 284                         else if(autocvar_g_campaign) { sprint(self, "You can't spawn monsters in campaign mode.\n"); }
 285                         else if(self.deadflag) { sprint(self, "You can't spawn monsters while dead.\n"); }
 286                         else if(self.monstercount >= autocvar_g_monsters_max_perplayer) { sprint(self, "You have spawned too many monsters, kill some before trying to spawn any more.\n"); }
 287                         else if(totalspawned >= autocvar_g_monsters_max) { sprint(self, "The global maximum monster count has been reached, kill some before trying to spawn any more.\n"); }
 288                         else // all worked out, so continue
 289                         {
 290                                 self.monstercount += 1;
 291                                 totalspawned += 1;
 292
 293                                 makevectors(self.v_angle);
 294                                 WarpZone_TraceBox (CENTER_OR_VIEWOFS(self), PL_MIN, PL_MAX, CENTER_OR_VIEWOFS(self) + v_forward * 150, TRUE, self);
 295                                 //WarpZone_TraceLine(self.origin + self.view_ofs, self.origin + self.view_ofs + v_forward * 150, MOVE_NORMAL, self);
 296
 297                                 e = spawnmonster(tospawn, 0, self, self, trace_endpos, FALSE, moveflag);
 298                                 if(mname) e.netname = strzone(mname);
 299
 300                                 sprint(self, strcat("Spawned ", e.netname, "\n"));
 301                         }
 302
 303                         return;
 304                 }
 305
 306                 default:
 307                         sprint(self, "Incorrect parameters for ^2mobspawn^7\n");
 308                 case CMD_REQUEST_USAGE:
 309                 {
 310                         sprint(self, "\nUsage:^3 cmd mobspawn monster\n");
 311                         sprint(self, "  See 'cmd mobspawn list' for available arguments.\n");
 312                         return;
 313                 }
 314         }
 315 }
 316
 317 void ClientCommand_ready(float request) // todo: anti-spam for toggling readyness
 318 {
 319         switch(request)
 320         {
 321                 case CMD_REQUEST_COMMAND:
 322                 {
 323                         if(IS_CLIENT(self))
 324                         {
 325                                 if(inWarmupStage || autocvar_sv_ready_restart || g_race_qualifying == 2)
 326                                 {
 327                                         if(!readyrestart_happened || autocvar_sv_ready_restart_repeatable)
 328                                         {
 329                                                 if(time < game_starttime) // game is already restarting
 330                                                         return;
 331                                                 if (self.ready) // toggle
 332                                                 {
 333                                                         self.ready = FALSE;
 334                                                         bprint(self.netname, "^2 is ^1NOT^2 ready\n");
 335                                                 }
 336                                                 else
 337                                                 {
 338                                                         self.ready = TRUE;
 339                                                         bprint(self.netname, "^2 is ready\n");
 340                                                 }
 341
 342                                                 // cannot reset the game while a timeout is active!
 343                                                 if not(timeout_status)
 344                                                         ReadyCount();
 345                                         } else {
 346                                                 sprint(self, "^1Game has already been restarted\n");
 347                                         }
 348                                 }
 349                         }
 350                         return; // never fall through to usage
 351                 }
 352
 353                 default:
 354                 case CMD_REQUEST_USAGE:
 355                 {
 356                         sprint(self, "\nUsage:^3 cmd ready\n");
 357                         sprint(self, "  No arguments required.\n");
 358                         return;
 359                 }
 360         }
 361 }
 362
 363 void ClientCommand_say(float request, float argc, string command)
 364 {
 365         switch(request)
 366         {
 367                 case CMD_REQUEST_COMMAND:
 368                 {
 369                         if(argc >= 2) { Say(self, FALSE, world, substring(command, argv_start_index(1), argv_end_index(-1) - argv_start_index(1)), 1); }
 370                         return; // never fall through to usage
 371                 }
 372
 373                 default:
 374                 case CMD_REQUEST_USAGE:
 375                 {
 376                         sprint(self, "\nUsage:^3 cmd say <message>\n");
 377                         sprint(self, "  Where 'message' is the string of text to say.\n");
 378                         return;
 379                 }
 380         }
 381 }
 382
 383 void ClientCommand_say_team(float request, float argc, string command)
 384 {
 385         switch(request)
 386         {
 387                 case CMD_REQUEST_COMMAND:
 388                 {
 389                         if(argc >= 2) { Say(self, TRUE, world, substring(command, argv_start_index(1), argv_end_index(-1) - argv_start_index(1)), 1); }
 390                         return; // never fall through to usage
 391                 }
 392
 393                 default:
 394                 case CMD_REQUEST_USAGE:
 395                 {
 396                         sprint(self, "\nUsage:^3 cmd say_team <message>\n");
 397                         sprint(self, "  Where 'message' is the string of text to say.\n");
 398                         return;
 399                 }
 400         }
 401 }
 402
 403 void ClientCommand_selectteam(float request, float argc)
 404 {
 405         switch(request)
 406         {
 407                 case CMD_REQUEST_COMMAND:
 408                 {
 409                         if(argv(1) != "")
 410                         {
 411                                 if(IS_CLIENT(self))
 412                                 {
 413                                         if(teamplay)
 414                                                 if not(self.team_forced > 0)
 415                                                         if not(lockteams)
 416                                                         {
 417                                                                 float selection;
 418
 419                                                                 switch(argv(1))
 420                                                                 {
 421                                                                         case "red": selection = NUM_TEAM_1; break;
 422                                                                         case "blue": selection = NUM_TEAM_2; break;
 423                                                                         case "yellow": selection = NUM_TEAM_3; break;
 424                                                                         case "pink": selection = NUM_TEAM_4; break;
 425                                                                         case "auto": selection = (-1); break;
 426
 427                                                                         default: selection = 0; break;
 428                                                                 }
 429
 430                                                                 if(selection)
 431                                                                 {
 432                                                                         if(self.team == selection && self.deadflag == DEAD_NO)
 433                                                                                 sprint(self, "^7You already are on that team.\n");
 434                                                                         else if(self.wasplayer && autocvar_g_changeteam_banned)
 435                                                                                 sprint(self, "^1You cannot change team, forbidden by the server.\n");
 436                                                                         else
 437                                                                                 ClientKill_TeamChange(selection);
 438                                                                 }
 439                                                         }
 440                                                         else
 441                                                                 sprint(self, "^7The game has already begun, you must wait until the next map to be able to join a team.\n");
 442                                                 else
 443                                                         sprint(self, "^7selectteam can not be used as your team is forced\n");
 444                                         else
 445                                                 sprint(self, "^7selectteam can only be used in teamgames\n");
 446                                 }
 447                                 return;
 448                         }
 449                 }
 450
 451                 default:
 452                         sprint(self, "Incorrect parameters for ^2selectteam^7\n");
 453                 case CMD_REQUEST_USAGE:
 454                 {
 455                         sprint(self, "\nUsage:^3 cmd selectteam team\n");
 456                         sprint(self, "  Where 'team' is the prefered team to try and join.\n");
 457                         sprint(self, "  Full list of options here: \"red, blue, yellow, pink, auto\"\n");
 458                         return;
 459                 }
 460         }
 461 }
 462
 463 void ClientCommand_selfstuff(float request, string command)
 464 {
 465         switch(request)
 466         {
 467                 case CMD_REQUEST_COMMAND:
 468                 {
 469                         if(argv(1) != "")
 470                         {
 471                                 stuffcmd(self, substring(command, argv_start_index(1), argv_end_index(-1) - argv_start_index(1)));
 472                                 return;
 473                         }
 474                 }
 475
 476                 default:
 477                         sprint(self, "Incorrect parameters for ^2selectteam^7\n");
 478                 case CMD_REQUEST_USAGE:
 479                 {
 480                         sprint(self, "\nUsage:^3 cmd selfstuff <command>\n");
 481                         sprint(self, "  Where 'command' is the string to be stuffed to your client.\n");
 482                         return;
 483                 }
 484         }
 485 }
 486
 487 void ClientCommand_sentcvar(float request, float argc, string command)
 488 {
 489         switch(request)
 490         {
 491                 case CMD_REQUEST_COMMAND:
 492                 {
 493                         if(argv(1) != "")
 494                         {
 495                                 //float tokens;
 496                                 string s;
 497
 498                                 if(argc == 2) // undefined cvar: use the default value on the server then
 499                                 {
 500                                         s = strcat(substring(command, argv_start_index(0), argv_end_index(1) - argv_start_index(0)), " \"", cvar_defstring(argv(1)), "\"");
 501                                         tokenize_console(s);
 502                                 }
 503
 504                                 GetCvars(1);
 505
 506                                 return;
 507                         }
 508                 }
 509
 510                 default:
 511                         sprint(self, "Incorrect parameters for ^2sentcvar^7\n");
 512                 case CMD_REQUEST_USAGE:
 513                 {
 514                         sprint(self, "\nUsage:^3 cmd sentcvar <cvar>\n");
 515                         sprint(self, "  Where 'cvar' is the cvar plus arguments to send to the server.\n");
 516                         return;
 517                 }
 518         }
 519 }
 520
 521 void ClientCommand_spectate(float request)
 522 {
 523         switch(request)
 524         {
 525                 case CMD_REQUEST_COMMAND:
 526                 {
 527                         if(IS_CLIENT(self))
 528                         {
 529                                 if(g_arena) { return; }
 530                                 if(g_lms)
 531                                 {
 532                                         if(self.lms_spectate_warning)
 533                                         {
 534                                                 // for the forfeit message...
 535                                                 self.lms_spectate_warning = 2;
 536                                                 // mark player as spectator
 537                                                 PlayerScore_Add(self, SP_LMS_RANK, 666 - PlayerScore_Add(self, SP_LMS_RANK, 0));
 538                                         }
 539                                         else
 540                                         {
 541                                                 self.lms_spectate_warning = 1;
 542                                                 sprint(self, "WARNING: you won't be able to enter the game again after spectating in LMS. Use the same command again to spectate anyway.\n");
 543                                                 return;
 544                                         }
 545                                 }
 546
 547                                 if(IS_PLAYER(self) && autocvar_sv_spectate == 1)
 548                                         ClientKill_TeamChange(-2); // observe
 549
 550                                 // in CA, allow a dead player to move to spectators (without that, caplayer!=0 will be moved back to the player list)
 551                                 // note: if arena game mode is ever done properly, this needs to be removed.
 552                                 if(self.caplayer && (IS_SPEC(self) || IS_OBSERVER(self)))
 553                                 {
 554                                         sprint(self, "WARNING: you will spectate in the next round.\n");
 555                                         self.caplayer = 0;
 556                                 }
 557                         }
 558                         return; // never fall through to usage
 559                 }
 560
 561                 default:
 562                 case CMD_REQUEST_USAGE:
 563                 {
 564                         sprint(self, "\nUsage:^3 cmd spectate\n");
 565                         sprint(self, "  No arguments required.\n");
 566                         return;
 567                 }
 568         }
 569 }
 570
 571 void ClientCommand_suggestmap(float request, float argc)
 572 {
 573         switch(request)
 574         {
 575                 case CMD_REQUEST_COMMAND:
 576                 {
 577                         if(argv(1) != "")
 578                         {
 579                                 sprint(self, strcat(MapVote_Suggest(argv(1)), "\n"));
 580                                 return;
 581                         }
 582                 }
 583
 584                 default:
 585                         sprint(self, "Incorrect parameters for ^2suggestmap^7\n");
 586                 case CMD_REQUEST_USAGE:
 587                 {
 588                         sprint(self, "\nUsage:^3 cmd suggestmap map\n");
 589                         sprint(self, "  Where 'map' is the name of the map to suggest.\n");
 590                         return;
 591                 }
 592         }
 593 }
 594
 595 void ClientCommand_tell(float request, float argc, string command)
 596 {
 597         switch(request)
 598         {
 599                 case CMD_REQUEST_COMMAND:
 600                 {
 601                         if(argc >= 3)
 602                         {
 603                                 entity tell_to = GetIndexedEntity(argc, 1);
 604                                 float tell_accepted = VerifyClientEntity(tell_to, TRUE, FALSE);
 605
 606                                 if(tell_accepted > 0) // the target is a real client
 607                                 {
 608                                         if(tell_to != self) // and we're allowed to send to them :D
 609                                         {
 610                                                 Say(self, FALSE, tell_to, substring(command, argv_start_index(next_token), argv_end_index(-1) - argv_start_index(next_token)), TRUE);
 611                                                 return;
 612                                         }
 613                                         else { print_to(self, "You can't ^2tell^7 a message to yourself."); return; }
 614                                 }
 615                                 else if(argv(1) == "#0")
 616                                 {
 617                                         trigger_magicear_processmessage_forallears(self, -1, world, substring(command, argv_start_index(next_token), argv_end_index(-1) - argv_start_index(next_token)));
 618                                         return;
 619                                 }
 620                                 else { print_to(self, strcat("tell: ", GetClientErrorString(tell_accepted, argv(1)), ".")); return; }
 621                         }
 622                 }
 623
 624                 default:
 625                         sprint(self, "Incorrect parameters for ^2tell^7\n");
 626                 case CMD_REQUEST_USAGE:
 627                 {
 628                         sprint(self, "\nUsage:^3 cmd tell client <message>\n");
 629                         sprint(self, "  Where 'client' is the entity number or name of the player to send 'message' to.\n");
 630                         return;
 631                 }
 632         }
 633 }
 634
 635 void ClientCommand_voice(float request, float argc, string command)
 636 {
 637         switch(request)
 638         {
 639                 case CMD_REQUEST_COMMAND:
 640                 {
 641                         if(argv(1) != "")
 642                         {
 643                                 if(argc >= 3)
 644                                         VoiceMessage(argv(1), substring(command, argv_start_index(2), argv_end_index(-1) - argv_start_index(2)));
 645                                 else
 646                                         VoiceMessage(argv(1), "");
 647
 648                                 return;
 649                         }
 650                 }
 651
 652                 default:
 653                         sprint(self, "Incorrect parameters for ^2voice^7\n");
 654                 case CMD_REQUEST_USAGE:
 655                 {
 656                         sprint(self, "\nUsage:^3 cmd voice messagetype <soundname>\n");
 657                         sprint(self, "  'messagetype' is the type of broadcast to do, like team only or such,\n");
 658                         sprint(self, "  and 'soundname' is the string/filename of the sound/voice message to play.\n");
 659                         return;
 660                 }
 661         }
 662 }
 663
 664 /* use this when creating a new command, making sure to place it in alphabetical order... also,
 665 ** ADD ALL NEW COMMANDS TO commands.cfg WITH PROPER ALIASES IN THE SAME FASHION!
 666 void ClientCommand_(float request)
 667 {
 668         switch(request)
 669         {
 670                 case CMD_REQUEST_COMMAND:
 671                 {
 672
 673                         return; // never fall through to usage
 674                 }
 675
 676                 default:
 677                 case CMD_REQUEST_USAGE:
 678                 {
 679                         sprint(self, "\nUsage:^3 cmd \n");
 680                         sprint(self, "  No arguments required.\n");
 681                         return;
 682                 }
 683         }
 684 }
 685 */
 686
 687
 688 // =====================================
 689 //  Macro system for networked commands
 690 // =====================================
 691
 692 // Do not hard code aliases for these, instead create them in commands.cfg... also: keep in alphabetical order, please ;)
 693 #define CLIENT_COMMANDS(request,arguments,command) \
 694         CLIENT_COMMAND("autoswitch", ClientCommand_autoswitch(request, arguments), "Whether or not to switch automatically when getting a better weapon") \
 695         CLIENT_COMMAND("checkfail", ClientCommand_checkfail(request, command), "Report if a client-side check failed") \
 696         CLIENT_COMMAND("clientversion", ClientCommand_clientversion(request, arguments), "Release version of the game") \
 697         CLIENT_COMMAND("mv_getpicture", ClientCommand_mv_getpicture(request, arguments), "Retrieve mapshot picture from the server") \
 698         CLIENT_COMMAND("join", ClientCommand_join(request), "Become a player in the game") \
 699         CLIENT_COMMAND("mobedit", ClientCommand_mobedit(request, arguments), "Edit your monster's properties") \
 700         CLIENT_COMMAND("mobkill", ClientCommand_mobkill(request), "Kills your monster") \
 701         CLIENT_COMMAND("mobspawn", ClientCommand_mobspawn(request, arguments), "Spawn monsters infront of yourself") \
 702         CLIENT_COMMAND("ready", ClientCommand_ready(request), "Qualify as ready to end warmup stage (or restart server if allowed)") \
 703         CLIENT_COMMAND("say", ClientCommand_say(request, arguments, command), "Print a message to chat to all players") \
 704         CLIENT_COMMAND("say_team", ClientCommand_say_team(request, arguments, command), "Print a message to chat to all team mates") \
 705         CLIENT_COMMAND("selectteam", ClientCommand_selectteam(request, arguments), "Attempt to choose a team to join into") \
 706         CLIENT_COMMAND("selfstuff", ClientCommand_selfstuff(request, command), "Stuffcmd a command to your own client") \
 707         CLIENT_COMMAND("sentcvar", ClientCommand_sentcvar(request, arguments, command), "New system for sending a client cvar to the server") \
 708         CLIENT_COMMAND("spectate", ClientCommand_spectate(request), "Become an observer") \
 709         CLIENT_COMMAND("suggestmap", ClientCommand_suggestmap(request, arguments), "Suggest a map to the mapvote at match end") \
 710         CLIENT_COMMAND("tell", ClientCommand_tell(request, arguments, command), "Send a message directly to a player") \
 711         CLIENT_COMMAND("voice", ClientCommand_voice(request, arguments, command), "Send voice message via sound") \
 712         /* nothing */
 713
 714 void ClientCommand_macro_help()
 715 {
 716         #define CLIENT_COMMAND(name,function,description) \
 717                 { sprint(self, "  ^2", name, "^7: ", description, "\n"); }
 718
 719         CLIENT_COMMANDS(0, 0, "")
 720         #undef CLIENT_COMMAND
 721
 722         return;
 723 }
 724
 725 float ClientCommand_macro_command(float argc, string command)
 726 {
 727         #define CLIENT_COMMAND(name,function,description) \
 728                 { if(name == strtolower(argv(0))) { function; return TRUE; } }
 729
 730         CLIENT_COMMANDS(CMD_REQUEST_COMMAND, argc, command)
 731         #undef CLIENT_COMMAND
 732
 733         return FALSE;
 734 }
 735
 736 float ClientCommand_macro_usage(float argc)
 737 {
 738         #define CLIENT_COMMAND(name,function,description) \
 739                 { if(name == strtolower(argv(1))) { function; return TRUE; } }
 740
 741         CLIENT_COMMANDS(CMD_REQUEST_USAGE, argc, "")
 742         #undef CLIENT_COMMAND
 743
 744         return FALSE;
 745 }
 746
 747 void ClientCommand_macro_write_aliases(float fh)
 748 {
 749         #define CLIENT_COMMAND(name,function,description) \
 750                 { CMD_Write_Alias("qc_cmd_cmd", name, description); }
 751
 752         CLIENT_COMMANDS(0, 0, "")
 753         #undef CLIENT_COMMAND
 754
 755         return;
 756 }
 757
 758 // ======================================
 759 //  Main Function Called By Engine (cmd)
 760 // ======================================
 761 // If this function exists, server game code parses clientcommand before the engine code gets it.
 762
 763 void SV_ParseClientCommand(string command)
 764 {
 765         // if we're banned, don't even parse the command
 766         if(Ban_MaybeEnforceBanOnce(self))
 767                 return;
 768
 769         float argc = tokenize_console(command);
 770
 771         // for the mutator hook system
 772         cmd_name = strtolower(argv(0));
 773         cmd_argc = argc;
 774         cmd_string = command;
 775
 776         // Guide for working with argc arguments by example:
 777         // argc:   1    - 2      - 3     - 4
 778         // argv:   0    - 1      - 2     - 3
 779         // cmd     vote - master - login - password
 780
 781         // for floodcheck
 782         switch(strtolower(argv(0)))
 783         {
 784                 // exempt commands which are not subject to floodcheck
 785                 case "begin": break; // handled by engine in host_cmd.c
 786                 case "download": break; // handled by engine in cl_parse.c
 787                 case "mv_getpicture": break; // handled by server in this file
 788                 case "pause": break; // handled by engine in host_cmd.c
 789                 case "prespawn": break; // handled by engine in host_cmd.c
 790                 case "sentcvar": break; // handled by server in this file
 791                 case "spawn": break; // handled by engine in host_cmd.c
 792
 793                 default:
 794                         if(SV_ParseClientCommand_floodcheck())
 795                                 break; // "TRUE": continue, as we're not flooding yet
 796                         else
 797                                 return; // "FALSE": not allowed to continue, halt // print("^1ERROR: ^7ANTISPAM CAUGHT: ", command, ".\n");
 798         }
 799
 800         /* NOTE: should this be disabled? It can be spammy perhaps, but hopefully it's okay for now */
 801         if(argv(0) == "help")
 802         {
 803                 if(argc == 1)
 804                 {
 805                         sprint(self, "\nClient networked commands:\n");
 806                         ClientCommand_macro_help();
 807
 808                         sprint(self, "\nCommon networked commands:\n");
 809                         CommonCommand_macro_help(self);
 810
 811                         sprint(self, "\nUsage:^3 cmd COMMAND...^7, where possible commands are listed above.\n");
 812                         sprint(self, "For help about a specific command, type cmd help COMMAND\n");
 813                         return;
 814                 }
 815                 else if(CommonCommand_macro_usage(argc, self)) // Instead of trying to call a command, we're going to see detailed information about it
 816                 {
 817                         return;
 818                 }
 819                 else if(ClientCommand_macro_usage(argc)) // same, but for normal commands now
 820                 {
 821                         return;
 822                 }
 823         }
 824         else if(MUTATOR_CALLHOOK(SV_ParseClientCommand))
 825         {
 826                 return; // handled by a mutator
 827         }
 828         else if(CheatCommand(argc))
 829         {
 830                 return; // handled by server/cheats.qc
 831         }
 832         else if(CommonCommand_macro_command(argc, self, command))
 833         {
 834                 return; // handled by server/command/common.qc
 835         }
 836         else if(ClientCommand_macro_command(argc, command)) // continue as usual and scan for normal commands
 837         {
 838                 return; // handled by one of the above ClientCommand_* functions
 839         }
 840         else
 841                 clientcommand(self, command);
 842 }