qcsrc/server/command/cmd.qc

   1 // =========================================================
   2 //  Server side networked commands code, reworked by Samual
   3 //  Last updated: December 28th, 2011
   4 // =========================================================
   5
   6 float SV_ParseClientCommand_floodcheck()
   7 {
   8         if not(timeout_status) // not while paused
   9         {
  10                 if(time <= (self.cmd_floodtime + autocvar_sv_clientcommand_antispam_time))
  11                 {
  12                         self.cmd_floodcount += 1;
  13                         if(self.cmd_floodcount > autocvar_sv_clientcommand_antispam_count) { return FALSE; } // too much spam, halt
  14                 }
  15                 else
  16                 {
  17                         self.cmd_floodtime = time;
  18                         self.cmd_floodcount = 1;
  19                 }
  20         }
  21         return TRUE; // continue, as we're not flooding yet
  22 }
  23
  24
  25 // =======================
  26 //  Command Sub-Functions
  27 // =======================
  28
  29 void ClientCommand_autoswitch(float request, float argc)
  30 {
  31         switch(request)
  32         {
  33                 case CMD_REQUEST_COMMAND:
  34                 {
  35                         if(argv(1) != "")
  36                         {
  37                                 self.autoswitch = InterpretBoolean(argv(1));
  38                                 sprint(self, strcat("^1autoswitch is currently turned ", (self.autoswitch ? "on" : "off"), ".\n"));
  39                                 return;
  40                         }
  41                 }
  42
  43                 default:
  44                         sprint(self, "Incorrect parameters for ^2autoswitch^7\n");
  45                 case CMD_REQUEST_USAGE:
  46                 {
  47                         sprint(self, "\nUsage:^3 cmd autoswitch selection\n");
  48                         sprint(self, "  Where 'selection' controls if autoswitch is on or off.\n");
  49                         return;
  50                 }
  51         }
  52 }
  53
  54 void ClientCommand_checkfail(float request, string command) // internal command, used only by code
  55 {
  56         switch(request)
  57         {
  58                 case CMD_REQUEST_COMMAND:
  59                 {
  60                         print(sprintf("CHECKFAIL: %s (%s) epically failed check %s\n", self.netname, self.netaddress, substring(command, argv_start_index(1), argv_end_index(-1) - argv_start_index(1))));
  61                         self.checkfail = 1;
  62                         return; // never fall through to usage
  63                 }
  64
  65                 default:
  66                         sprint(self, "Incorrect parameters for ^2checkfail^7\n");
  67                 case CMD_REQUEST_USAGE:
  68                 {
  69                         sprint(self, "\nUsage:^3 cmd checkfail <message>\n");
  70                         sprint(self, "  Where 'message' is the message reported by client about the fail.\n");
  71                         return;
  72                 }
  73         }
  74 }
  75
  76 void ClientCommand_clientversion(float request, float argc) // internal command, used only by code
  77 {
  78         switch(request)
  79         {
  80                 case CMD_REQUEST_COMMAND:
  81                 {
  82                         if(argv(1) != "")
  83                         {
  84                                 if(self.flags & FL_CLIENT)
  85                                 {
  86                                         self.version = ((argv(1) == "$gameversion") ? 1 : stof(argv(1)));
  87
  88                                         if(self.version < autocvar_gameversion_min || self.version > autocvar_gameversion_max)
  89                                         {
  90                                                 self.version_mismatch = 1;
  91                                                 ClientKill_TeamChange(-2); // observe
  92                                         }
  93                                         else if(autocvar_g_campaign || autocvar_g_balance_teams)
  94                                         {
  95                                                 //JoinBestTeam(self, FALSE, TRUE);
  96                                         }
  97                                         else if(teamplay && !autocvar_sv_spectate && !(self.team_forced > 0))
  98                                         {
  99                                                 self.classname = "observer"; // really?
 100                                                 stuffcmd(self, "menu_showteamselect\n");
 101                                         }
 102                                 }
 103
 104                                 return;
 105                         }
 106                 }
 107
 108                 default:
 109                         sprint(self, "Incorrect parameters for ^2clientversion^7\n");
 110                 case CMD_REQUEST_USAGE:
 111                 {
 112                         sprint(self, "\nUsage:^3 cmd clientversion version\n");
 113                         sprint(self, "  Where 'version' is the game version reported by self.\n");
 114                         return;
 115                 }
 116         }
 117 }
 118
 119 void ClientCommand_mv_getpicture(float request, float argc) // internal command, used only by code
 120 {
 121         switch(request)
 122         {
 123                 case CMD_REQUEST_COMMAND:
 124                 {
 125                         if(argv(1) != "")
 126                         {
 127                                 if(intermission_running)
 128                                         MapVote_SendPicture(stof(argv(1)));
 129
 130                                 return;
 131                         }
 132                 }
 133
 134                 default:
 135                         sprint(self, "Incorrect parameters for ^2mv_getpicture^7\n");
 136                 case CMD_REQUEST_USAGE:
 137                 {
 138                         sprint(self, "\nUsage:^3 cmd mv_getpicture mapid\n");
 139                         sprint(self, "  Where 'mapid' is the id number of the map to request an image of on the map vote selection menu.\n");
 140                         return;
 141                 }
 142         }
 143 }
 144
 145 void ClientCommand_join(float request)
 146 {
 147         switch(request)
 148         {
 149                 case CMD_REQUEST_COMMAND:
 150                 {
 151                         if(self.flags & FL_CLIENT)
 152                         {
 153                                 if(self.classname != "player" && !lockteams && !g_arena)
 154                                 {
 155                                         if(nJoinAllowed(self))
 156                                         {
 157                                                 if(g_ca) { self.caplayer = 1; }
 158                                                 if(autocvar_g_campaign) { campaign_bots_may_start = 1; }
 159
 160                                                 self.classname = "player";
 161                                                 PlayerScore_Clear(self);
 162                                                 bprint ("^4", self.netname, "^4 is playing now\n");
 163                                                 PutClientInServer();
 164                                         }
 165                                         else
 166                                         {
 167                                                 //player may not join because of g_maxplayers is set
 168                                                 centerprint(self, PREVENT_JOIN_TEXT);
 169                                         }
 170                                 }
 171                         }
 172                         return; // never fall through to usage
 173                 }
 174
 175                 default:
 176                 case CMD_REQUEST_USAGE:
 177                 {
 178                         sprint(self, "\nUsage:^3 cmd join\n");
 179                         sprint(self, "  No arguments required.\n");
 180                         return;
 181                 }
 182         }
 183 }
 184
 185 void ClientCommand_ready(float request) // todo: anti-spam for toggling readyness
 186 {
 187         switch(request)
 188         {
 189                 case CMD_REQUEST_COMMAND:
 190                 {
 191                         if(self.flags & FL_CLIENT)
 192                         {
 193                                 if(inWarmupStage || autocvar_sv_ready_restart || g_race_qualifying == 2)
 194                                 {
 195                                         if(!readyrestart_happened || autocvar_sv_ready_restart_repeatable)
 196                                         {
 197                                                 if (self.ready) // toggle
 198                                                 {
 199                                                         self.ready = FALSE;
 200                                                         bprint(self.netname, "^2 is ^1NOT^2 ready\n");
 201                                                 }
 202                                                 else
 203                                                 {
 204                                                         self.ready = TRUE;
 205                                                         bprint(self.netname, "^2 is ready\n");
 206                                                 }
 207
 208                                                 // cannot reset the game while a timeout is active!
 209                                                 if not(timeout_status)
 210                                                         ReadyCount();
 211                                         } else {
 212                                                 sprint(self, "^1Game has already been restarted\n");
 213                                         }
 214                                 }
 215                         }
 216                         return; // never fall through to usage
 217                 }
 218
 219                 default:
 220                 case CMD_REQUEST_USAGE:
 221                 {
 222                         sprint(self, "\nUsage:^3 cmd ready\n");
 223                         sprint(self, "  No arguments required.\n");
 224                         return;
 225                 }
 226         }
 227 }
 228
 229 void ClientCommand_say(float request, float argc, string command)
 230 {
 231         switch(request)
 232         {
 233                 case CMD_REQUEST_COMMAND:
 234                 {
 235                         if(argc >= 2) { Say(self, FALSE, world, substring(command, argv_start_index(1), argv_end_index(-1) - argv_start_index(1)), 1); }
 236                         return; // never fall through to usage
 237                 }
 238
 239                 default:
 240                 case CMD_REQUEST_USAGE:
 241                 {
 242                         sprint(self, "\nUsage:^3 cmd say <message>\n");
 243                         sprint(self, "  Where 'message' is the string of text to say.\n");
 244                         return;
 245                 }
 246         }
 247 }
 248
 249 void ClientCommand_say_team(float request, float argc, string command)
 250 {
 251         switch(request)
 252         {
 253                 case CMD_REQUEST_COMMAND:
 254                 {
 255                         if(argc >= 2) { Say(self, TRUE, world, substring(command, argv_start_index(1), argv_end_index(-1) - argv_start_index(1)), 1); }
 256                         return; // never fall through to usage
 257                 }
 258
 259                 default:
 260                 case CMD_REQUEST_USAGE:
 261                 {
 262                         sprint(self, "\nUsage:^3 cmd say_team <message>\n");
 263                         sprint(self, "  Where 'message' is the string of text to say.\n");
 264                         return;
 265                 }
 266         }
 267 }
 268
 269 void ClientCommand_selectteam(float request, float argc)
 270 {
 271         switch(request)
 272         {
 273                 case CMD_REQUEST_COMMAND:
 274                 {
 275                         if(argv(1) != "")
 276                         {
 277                                 if(self.flags & FL_CLIENT)
 278                                 {
 279                                         if(teamplay)
 280                                                 if not(self.team_forced > 0)
 281                                                         if not(lockteams)
 282                                                         {
 283                                                                 float selection;
 284
 285                                                                 switch(argv(1))
 286                                                                 {
 287                                                                         case "red": selection = FL_TEAM_1; break;
 288                                                                         case "blue": selection = FL_TEAM_2; break;
 289                                                                         case "yellow": selection = FL_TEAM_3; break;
 290                                                                         case "pink": selection = FL_TEAM_4; break;
 291                                                                         case "auto": selection = (-1); break;
 292
 293                                                                         default: selection = 0; break;
 294                                                                 }
 295
 296                                                                 if(selection)
 297                                                                 {
 298                                                                         if(self.team == selection && self.deadflag == DEAD_NO)
 299                                                                                 sprint(self, "^7You already are on that team.\n");
 300                                                                         else if(self.wasplayer && autocvar_g_changeteam_banned)
 301                                                                                 sprint(self, "^1You cannot change team, forbidden by the server.\n");
 302                                                                         else
 303                                                                                 ClientKill_TeamChange(selection);
 304                                                                 }
 305                                                         }
 306                                                         else
 307                                                                 sprint(self, "^7The game has already begun, you must wait until the next map to be able to join a team.\n");
 308                                                 else
 309                                                         sprint(self, "^7selectteam can not be used as your team is forced\n");
 310                                         else
 311                                                 sprint(self, "^7selectteam can only be used in teamgames\n");
 312                                 }
 313                                 return;
 314                         }
 315                 }
 316
 317                 default:
 318                         sprint(self, "Incorrect parameters for ^2selectteam^7\n");
 319                 case CMD_REQUEST_USAGE:
 320                 {
 321                         sprint(self, "\nUsage:^3 cmd selectteam team\n");
 322                         sprint(self, "  Where 'team' is the prefered team to try and join.\n");
 323                         sprint(self, "  Full list of options here: \"red, blue, yellow, pink, auto\"\n");
 324                         return;
 325                 }
 326         }
 327 }
 328
 329 void ClientCommand_selfstuff(float request, string command)
 330 {
 331         switch(request)
 332         {
 333                 case CMD_REQUEST_COMMAND:
 334                 {
 335                         if(argv(1) != "")
 336                         {
 337                                 stuffcmd(self, substring(command, argv_start_index(1), argv_end_index(-1) - argv_start_index(1)));
 338                                 return;
 339                         }
 340                 }
 341
 342                 default:
 343                         sprint(self, "Incorrect parameters for ^2selectteam^7\n");
 344                 case CMD_REQUEST_USAGE:
 345                 {
 346                         sprint(self, "\nUsage:^3 cmd selfstuff <command>\n");
 347                         sprint(self, "  Where 'command' is the string to be stuffed to your client.\n");
 348                         return;
 349                 }
 350         }
 351 }
 352
 353 void ClientCommand_sentcvar(float request, float argc, string command)
 354 {
 355         switch(request)
 356         {
 357                 case CMD_REQUEST_COMMAND:
 358                 {
 359                         if(argv(1) != "")
 360                         {
 361                                 //float tokens;
 362                                 string s;
 363
 364                                 if(argc == 2) // undefined cvar: use the default value on the server then
 365                                 {
 366                                         s = strcat(substring(command, argv_start_index(0), argv_end_index(1) - argv_start_index(0)), " \"", cvar_defstring(argv(1)), "\"");
 367                                         tokenize_console(s);
 368                                 }
 369
 370                                 GetCvars(1);
 371
 372                                 return;
 373                         }
 374                 }
 375
 376                 default:
 377                         sprint(self, "Incorrect parameters for ^2sentcvar^7\n");
 378                 case CMD_REQUEST_USAGE:
 379                 {
 380                         sprint(self, "\nUsage:^3 cmd sentcvar <cvar>\n");
 381                         sprint(self, "  Where 'cvar' is the cvar plus arguments to send to the server.\n");
 382                         return;
 383                 }
 384         }
 385 }
 386
 387 void ClientCommand_spectate(float request)
 388 {
 389         switch(request)
 390         {
 391                 case CMD_REQUEST_COMMAND:
 392                 {
 393                         if(self.flags & FL_CLIENT)
 394                         {
 395                                 if(g_arena) { return; }
 396                                 if(g_lms)
 397                                 {
 398                                         if(self.lms_spectate_warning)
 399                                         {
 400                                                 // for the forfeit message...
 401                                                 self.lms_spectate_warning = 2;
 402                                                 // mark player as spectator
 403                                                 PlayerScore_Add(self, SP_LMS_RANK, 666 - PlayerScore_Add(self, SP_LMS_RANK, 0));
 404                                         }
 405                                         else
 406                                         {
 407                                                 self.lms_spectate_warning = 1;
 408                                                 sprint(self, "WARNING: you won't be able to enter the game again after spectating in LMS. Use the same command again to spectate anyway.\n");
 409                                                 return;
 410                                         }
 411                                 }
 412
 413                                 if(self.classname == "player" && autocvar_sv_spectate == 1)
 414                                         ClientKill_TeamChange(-2); // observe
 415
 416                                 // in CA, allow a dead player to move to spectators (without that, caplayer!=0 will be moved back to the player list)
 417                                 // note: if arena game mode is ever done properly, this needs to be removed.
 418                                 if(g_ca && self.caplayer && (self.classname == "spectator" || self.classname == "observer"))
 419                                 {
 420                                         sprint(self, "WARNING: you will spectate in the next round.\n");
 421                                         self.caplayer = 0;
 422                                 }
 423                         }
 424                         return; // never fall through to usage
 425                 }
 426
 427                 default:
 428                 case CMD_REQUEST_USAGE:
 429                 {
 430                         sprint(self, "\nUsage:^3 cmd spectate\n");
 431                         sprint(self, "  No arguments required.\n");
 432                         return;
 433                 }
 434         }
 435 }
 436
 437 void ClientCommand_suggestmap(float request, float argc)
 438 {
 439         switch(request)
 440         {
 441                 case CMD_REQUEST_COMMAND:
 442                 {
 443                         if(argv(1) != "")
 444                         {
 445                                 sprint(self, strcat(MapVote_Suggest(argv(1)), "\n"));
 446                                 return;
 447                         }
 448                 }
 449
 450                 default:
 451                         sprint(self, "Incorrect parameters for ^2suggestmap^7\n");
 452                 case CMD_REQUEST_USAGE:
 453                 {
 454                         sprint(self, "\nUsage:^3 cmd suggestmap map\n");
 455                         sprint(self, "  Where 'map' is the name of the map to suggest.\n");
 456                         return;
 457                 }
 458         }
 459 }
 460
 461 void ClientCommand_tell(float request, float argc, string command)
 462 {
 463         switch(request)
 464         {
 465                 case CMD_REQUEST_COMMAND:
 466                 {
 467                         if(argc >= 3)
 468                         {
 469                                 entity tell_to = GetIndexedEntity(argc, 1);
 470                                 float tell_accepted = VerifyClientEntity(tell_to, TRUE, FALSE);
 471
 472                                 if(tell_accepted > 0) // the target is a real client
 473                                 {
 474                                         if(tell_to != self) // and we're allowed to send to them :D
 475                                         {
 476                                                 Say(self, FALSE, tell_to, substring(command, argv_start_index(next_token), argv_end_index(-1) - argv_start_index(next_token)), TRUE);
 477                                                 return;
 478                                         }
 479                                         else { print_to(self, "You can't ^2tell^7 a message to yourself."); return; }
 480                                 }
 481                                 else if(argv(1) == "#0")
 482                                 {
 483                                         trigger_magicear_processmessage_forallears(self, -1, world, substring(command, argv_start_index(next_token), argv_end_index(-1) - argv_start_index(next_token)));
 484                                         return;
 485                                 }
 486                                 else { print_to(self, strcat("tell: ", GetClientErrorString(tell_accepted, argv(1)), ".")); return; }
 487                         }
 488                 }
 489
 490                 default:
 491                         sprint(self, "Incorrect parameters for ^2tell^7\n");
 492                 case CMD_REQUEST_USAGE:
 493                 {
 494                         sprint(self, "\nUsage:^3 cmd tell client <message>\n");
 495                         sprint(self, "  Where 'client' is the entity number or name of the player to send 'message' to.\n");
 496                         return;
 497                 }
 498         }
 499 }
 500
 501 void ClientCommand_voice(float request, float argc, string command)
 502 {
 503         switch(request)
 504         {
 505                 case CMD_REQUEST_COMMAND:
 506                 {
 507                         if(argv(1) != "")
 508                         {
 509                                 if(argc >= 3)
 510                                         VoiceMessage(argv(1), substring(command, argv_start_index(2), argv_end_index(-1) - argv_start_index(2)));
 511                                 else
 512                                         VoiceMessage(argv(1), "");
 513
 514                                 return;
 515                         }
 516                 }
 517
 518                 default:
 519                         sprint(self, "Incorrect parameters for ^2voice^7\n");
 520                 case CMD_REQUEST_USAGE:
 521                 {
 522                         sprint(self, "\nUsage:^3 cmd voice messagetype <soundname>\n");
 523                         sprint(self, "  'messagetype' is the type of broadcast to do, like team only or such,\n");
 524                         sprint(self, "  and 'soundname' is the string/filename of the sound/voice message to play.\n");
 525                         return;
 526                 }
 527         }
 528 }
 529
 530 /* use this when creating a new command, making sure to place it in alphabetical order... also,
 531 ** ADD ALL NEW COMMANDS TO commands.cfg WITH PROPER ALIASES IN THE SAME FASHION!
 532 void ClientCommand_(float request)
 533 {
 534         switch(request)
 535         {
 536                 case CMD_REQUEST_COMMAND:
 537                 {
 538
 539                         return; // never fall through to usage
 540                 }
 541
 542                 default:
 543                 case CMD_REQUEST_USAGE:
 544                 {
 545                         sprint(self, "\nUsage:^3 cmd \n");
 546                         sprint(self, "  No arguments required.\n");
 547                         return;
 548                 }
 549         }
 550 }
 551 */
 552
 553
 554 // =====================================
 555 //  Macro system for networked commands
 556 // =====================================
 557
 558 // Do not hard code aliases for these, instead create them in commands.cfg... also: keep in alphabetical order, please ;)
 559 #define CLIENT_COMMANDS(request,arguments,command) \
 560         CLIENT_COMMAND("autoswitch", ClientCommand_autoswitch(request, arguments), "Whether or not to switch automatically when getting a better weapon") \
 561         CLIENT_COMMAND("checkfail", ClientCommand_checkfail(request, command), "Report if a client-side check failed") \
 562         CLIENT_COMMAND("clientversion", ClientCommand_clientversion(request, arguments), "Release version of the game") \
 563         CLIENT_COMMAND("mv_getpicture", ClientCommand_mv_getpicture(request, arguments), "Retrieve mapshot picture from the server") \
 564         CLIENT_COMMAND("join", ClientCommand_join(request), "Become a player in the game") \
 565         CLIENT_COMMAND("ready", ClientCommand_ready(request), "Qualify as ready to end warmup stage (or restart server if allowed)") \
 566         CLIENT_COMMAND("say", ClientCommand_say(request, arguments, command), "Print a message to chat to all players") \
 567         CLIENT_COMMAND("say_team", ClientCommand_say_team(request, arguments, command), "Print a message to chat to all team mates") \
 568         CLIENT_COMMAND("selectteam", ClientCommand_selectteam(request, arguments), "Attempt to choose a team to join into") \
 569         CLIENT_COMMAND("selfstuff", ClientCommand_selfstuff(request, command), "Stuffcmd a command to your own client") \
 570         CLIENT_COMMAND("sentcvar", ClientCommand_sentcvar(request, arguments, command), "New system for sending a client cvar to the server") \
 571         CLIENT_COMMAND("spectate", ClientCommand_spectate(request), "Become an observer") \
 572         CLIENT_COMMAND("suggestmap", ClientCommand_suggestmap(request, arguments), "Suggest a map to the mapvote at match end") \
 573         CLIENT_COMMAND("tell", ClientCommand_tell(request, arguments, command), "Send a message directly to a player") \
 574         CLIENT_COMMAND("voice", ClientCommand_voice(request, arguments, command), "Send voice message via sound") \
 575         /* nothing */
 576
 577 void ClientCommand_macro_help()
 578 {
 579         #define CLIENT_COMMAND(name,function,description) \
 580                 { sprint(self, "  ^2", name, "^7: ", description, "\n"); }
 581
 582         CLIENT_COMMANDS(0, 0, "")
 583         #undef CLIENT_COMMAND
 584
 585         return;
 586 }
 587
 588 float ClientCommand_macro_command(float argc, string command)
 589 {
 590         #define CLIENT_COMMAND(name,function,description) \
 591                 { if(name == strtolower(argv(0))) { function; return TRUE; } }
 592
 593         CLIENT_COMMANDS(CMD_REQUEST_COMMAND, argc, command)
 594         #undef CLIENT_COMMAND
 595
 596         return FALSE;
 597 }
 598
 599 float ClientCommand_macro_usage(float argc)
 600 {
 601         #define CLIENT_COMMAND(name,function,description) \
 602                 { if(name == strtolower(argv(1))) { function; return TRUE; } }
 603
 604         CLIENT_COMMANDS(CMD_REQUEST_USAGE, argc, "")
 605         #undef CLIENT_COMMAND
 606
 607         return FALSE;
 608 }
 609
 610 void ClientCommand_macro_write_aliases(float fh)
 611 {
 612         #define CLIENT_COMMAND(name,function,description) \
 613                 { CMD_Write_Alias("qc_cmd_cmd", name, description); }
 614
 615         CLIENT_COMMANDS(0, 0, "")
 616         #undef CLIENT_COMMAND
 617
 618         return;
 619 }
 620
 621 // ======================================
 622 //  Main Function Called By Engine (cmd)
 623 // ======================================
 624 // If this function exists, server game code parses clientcommand before the engine code gets it.
 625
 626 void SV_ParseClientCommand(string command)
 627 {
 628         // if we're banned, don't even parse the command
 629         if(Ban_MaybeEnforceBanOnce(self))
 630                 return;
 631
 632         float argc = tokenize_console(command);
 633
 634         // for the mutator hook system
 635         cmd_name = strtolower(argv(0));
 636         cmd_argc = argc;
 637         cmd_string = command;
 638
 639         // Guide for working with argc arguments by example:
 640         // argc:   1    - 2      - 3     - 4
 641         // argv:   0    - 1      - 2     - 3
 642         // cmd     vote - master - login - password
 643
 644         // for floodcheck
 645         switch(strtolower(argv(0)))
 646         {
 647                 // exempt commands which are not subject to floodcheck
 648                 case "begin": break; // handled by engine in host_cmd.c
 649                 case "download": break; // handled by engine in cl_parse.c
 650                 case "mv_getpicture": break; // handled by server in this file
 651                 case "pause": break; // handled by engine in host_cmd.c
 652                 case "prespawn": break; // handled by engine in host_cmd.c
 653                 case "sentcvar": break; // handled by server in this file
 654                 case "spawn": break; // handled by engine in host_cmd.c
 655
 656                 default:
 657                         if(SV_ParseClientCommand_floodcheck())
 658                                 break; // "TRUE": continue, as we're not flooding yet
 659                         else
 660                                 return; // "FALSE": not allowed to continue, halt // print("^1ERROR: ^7ANTISPAM CAUGHT: ", command, ".\n");
 661         }
 662
 663         /* NOTE: should this be disabled? It can be spammy perhaps, but hopefully it's okay for now */
 664         if(argv(0) == "help")
 665         {
 666                 if(argc == 1)
 667                 {
 668                         sprint(self, "\nClient networked commands:\n");
 669                         ClientCommand_macro_help();
 670
 671                         sprint(self, "\nCommon networked commands:\n");
 672                         CommonCommand_macro_help(self);
 673
 674                         sprint(self, "\nUsage:^3 cmd COMMAND...^7, where possible commands are listed above.\n");
 675                         sprint(self, "For help about a specific command, type cmd help COMMAND\n");
 676                         return;
 677                 }
 678                 else if(CommonCommand_macro_usage(argc, self)) // Instead of trying to call a command, we're going to see detailed information about it
 679                 {
 680                         return;
 681                 }
 682                 else if(ClientCommand_macro_usage(argc)) // same, but for normal commands now
 683                 {
 684                         return;
 685                 }
 686         }
 687         else if(MUTATOR_CALLHOOK(SV_ParseClientCommand))
 688         {
 689                 return; // handled by a mutator
 690         }
 691         else if(CheatCommand(argc))
 692         {
 693                 return; // handled by server/cheats.qc
 694         }
 695         else if(CommonCommand_macro_command(argc, self, command))
 696         {
 697                 return; // handled by server/command/common.qc
 698         }
 699         else if(ClientCommand_macro_command(argc, command)) // continue as usual and scan for normal commands
 700         {
 701                 return; // handled by one of the above ClientCommand_* functions
 702         }
 703         else
 704                 clientcommand(self, command);
 705 }