qcsrc/server/command/cmd.qc

   1 // =========================================================
   2 //  Server side networked commands code, reworked by Samual
   3 //  Last updated: December 28th, 2011
   4 // =========================================================
   5
   6 float SV_ParseClientCommand_floodcheck()
   7 {
   8         if not(timeout_status) // not while paused
   9         {
  10                 if(time <= (self.cmd_floodtime + autocvar_sv_clientcommand_antispam_time))
  11                 {
  12                         self.cmd_floodcount += 1;
  13                         if(self.cmd_floodcount > autocvar_sv_clientcommand_antispam_count) { return FALSE; } // too much spam, halt
  14                 }
  15                 else
  16                 {
  17                         self.cmd_floodtime = time;
  18                         self.cmd_floodcount = 1;
  19                 }
  20         }
  21         return TRUE; // continue, as we're not flooding yet
  22 }
  23
  24
  25 // =======================
  26 //  Command Sub-Functions
  27 // =======================
  28
  29 void ClientCommand_autoswitch(float request, float argc)
  30 {
  31         switch(request)
  32         {
  33                 case CMD_REQUEST_COMMAND:
  34                 {
  35                         if(argv(1) != "")
  36                         {
  37                                 self.autoswitch = InterpretBoolean(argv(1));
  38                                 sprint(self, strcat("^1autoswitch is currently turned ", (self.autoswitch ? "on" : "off"), ".\n"));
  39                                 return;
  40                         }
  41                 }
  42
  43                 default:
  44                         sprint(self, "Incorrect parameters for ^2autoswitch^7\n");
  45                 case CMD_REQUEST_USAGE:
  46                 {
  47                         sprint(self, "\nUsage:^3 cmd autoswitch selection\n");
  48                         sprint(self, "  Where 'selection' controls if autoswitch is on or off.\n");
  49                         return;
  50                 }
  51         }
  52 }
  53
  54 void ClientCommand_checkfail(float request, string command) // internal command, used only by code
  55 {
  56         switch(request)
  57         {
  58                 case CMD_REQUEST_COMMAND:
  59                 {
  60                         print(sprintf("CHECKFAIL: %s (%s) epically failed check %s\n", self.netname, self.netaddress, substring(command, argv_start_index(1), argv_end_index(-1) - argv_start_index(1))));
  61                         self.checkfail = 1;
  62                         return; // never fall through to usage
  63                 }
  64
  65                 default:
  66                         sprint(self, "Incorrect parameters for ^2checkfail^7\n");
  67                 case CMD_REQUEST_USAGE:
  68                 {
  69                         sprint(self, "\nUsage:^3 cmd checkfail <message>\n");
  70                         sprint(self, "  Where 'message' is the message reported by client about the fail.\n");
  71                         return;
  72                 }
  73         }
  74 }
  75
  76 void ClientCommand_clientversion(float request, float argc) // internal command, used only by code
  77 {
  78         switch(request)
  79         {
  80                 case CMD_REQUEST_COMMAND:
  81                 {
  82                         if(argv(1) != "")
  83                         {
  84                                 if(self.flags & FL_CLIENT)
  85                                 {
  86                                         self.version = ((argv(1) == "$gameversion") ? 1 : stof(argv(1)));
  87
  88                                         if(self.version < autocvar_gameversion_min || self.version > autocvar_gameversion_max)
  89                                         {
  90                                                 self.version_mismatch = 1;
  91                                                 ClientKill_TeamChange(-2); // observe
  92                                         }
  93                                         else if(autocvar_g_campaign || autocvar_g_balance_teams)
  94                                         {
  95                                                 //JoinBestTeam(self, FALSE, TRUE);
  96                                         }
  97                                         else if(teamplay && !autocvar_sv_spectate && !(self.team_forced > 0))
  98                                         {
  99                                                 self.classname = "observer"; // really?
 100                                                 stuffcmd(self, "menu_showteamselect\n");
 101                                         }
 102                                 }
 103
 104                                 return;
 105                         }
 106                 }
 107
 108                 default:
 109                         sprint(self, "Incorrect parameters for ^2clientversion^7\n");
 110                 case CMD_REQUEST_USAGE:
 111                 {
 112                         sprint(self, "\nUsage:^3 cmd clientversion version\n");
 113                         sprint(self, "  Where 'version' is the game version reported by self.\n");
 114                         return;
 115                 }
 116         }
 117 }
 118
 119 void ClientCommand_mv_getpicture(float request, float argc) // internal command, used only by code
 120 {
 121         switch(request)
 122         {
 123                 case CMD_REQUEST_COMMAND:
 124                 {
 125                         if(argv(1) != "")
 126                         {
 127                                 if(intermission_running)
 128                                         MapVote_SendPicture(stof(argv(1)));
 129
 130                                 return;
 131                         }
 132                 }
 133
 134                 default:
 135                         sprint(self, "Incorrect parameters for ^2mv_getpicture^7\n");
 136                 case CMD_REQUEST_USAGE:
 137                 {
 138                         sprint(self, "\nUsage:^3 cmd mv_getpicture mapid\n");
 139                         sprint(self, "  Where 'mapid' is the id number of the map to request an image of on the map vote selection menu.\n");
 140                         return;
 141                 }
 142         }
 143 }
 144
 145 void ClientCommand_join(float request)
 146 {
 147         switch(request)
 148         {
 149                 case CMD_REQUEST_COMMAND:
 150                 {
 151                         if(self.flags & FL_CLIENT)
 152                         {
 153                                 if(self.classname != "player" && !lockteams && !g_arena)
 154                                 {
 155                                         if(nJoinAllowed(self))
 156                                         {
 157                                                 if(autocvar_g_campaign) { campaign_bots_may_start = 1; }
 158
 159                                                 self.classname = "player";
 160                                                 PlayerScore_Clear(self);
 161                                                 Kill_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER_CPID, CPID_MOTD);
 162                                                 Kill_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER_CPID, CPID_PREVENT_JOIN);
 163                                                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_JOIN_PLAY, self.netname);
 164                                                 PutClientInServer();
 165                                         }
 166                                         else
 167                                         {
 168                                                 //player may not join because of g_maxplayers is set
 169                                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER_CPID, CPID_PREVENT_JOIN);
 170                                         }
 171                                 }
 172                         }
 173                         return; // never fall through to usage
 174                 }
 175
 176                 default:
 177                 case CMD_REQUEST_USAGE:
 178                 {
 179                         sprint(self, "\nUsage:^3 cmd join\n");
 180                         sprint(self, "  No arguments required.\n");
 181                         return;
 182                 }
 183         }
 184 }
 185
 186 void ClientCommand_ready(float request) // todo: anti-spam for toggling readyness
 187 {
 188         switch(request)
 189         {
 190                 case CMD_REQUEST_COMMAND:
 191                 {
 192                         if(self.flags & FL_CLIENT)
 193                         {
 194                                 if(inWarmupStage || autocvar_sv_ready_restart || g_race_qualifying == 2)
 195                                 {
 196                                         if(!readyrestart_happened || autocvar_sv_ready_restart_repeatable)
 197                                         {
 198                                                 if(time < game_starttime) // game is already restarting
 199                                                         return;
 200                                                 if (self.ready) // toggle
 201                                                 {
 202                                                         self.ready = FALSE;
 203                                                         bprint(self.netname, "^2 is ^1NOT^2 ready\n");
 204                                                 }
 205                                                 else
 206                                                 {
 207                                                         self.ready = TRUE;
 208                                                         bprint(self.netname, "^2 is ready\n");
 209                                                 }
 210
 211                                                 // cannot reset the game while a timeout is active!
 212                                                 if not(timeout_status)
 213                                                         ReadyCount();
 214                                         } else {
 215                                                 sprint(self, "^1Game has already been restarted\n");
 216                                         }
 217                                 }
 218                         }
 219                         return; // never fall through to usage
 220                 }
 221
 222                 default:
 223                 case CMD_REQUEST_USAGE:
 224                 {
 225                         sprint(self, "\nUsage:^3 cmd ready\n");
 226                         sprint(self, "  No arguments required.\n");
 227                         return;
 228                 }
 229         }
 230 }
 231
 232 void ClientCommand_say(float request, float argc, string command)
 233 {
 234         switch(request)
 235         {
 236                 case CMD_REQUEST_COMMAND:
 237                 {
 238                         if(argc >= 2) { Say(self, FALSE, world, substring(command, argv_start_index(1), argv_end_index(-1) - argv_start_index(1)), 1); }
 239                         return; // never fall through to usage
 240                 }
 241
 242                 default:
 243                 case CMD_REQUEST_USAGE:
 244                 {
 245                         sprint(self, "\nUsage:^3 cmd say <message>\n");
 246                         sprint(self, "  Where 'message' is the string of text to say.\n");
 247                         return;
 248                 }
 249         }
 250 }
 251
 252 void ClientCommand_say_team(float request, float argc, string command)
 253 {
 254         switch(request)
 255         {
 256                 case CMD_REQUEST_COMMAND:
 257                 {
 258                         if(argc >= 2) { Say(self, TRUE, world, substring(command, argv_start_index(1), argv_end_index(-1) - argv_start_index(1)), 1); }
 259                         return; // never fall through to usage
 260                 }
 261
 262                 default:
 263                 case CMD_REQUEST_USAGE:
 264                 {
 265                         sprint(self, "\nUsage:^3 cmd say_team <message>\n");
 266                         sprint(self, "  Where 'message' is the string of text to say.\n");
 267                         return;
 268                 }
 269         }
 270 }
 271
 272 void ClientCommand_selectteam(float request, float argc)
 273 {
 274         switch(request)
 275         {
 276                 case CMD_REQUEST_COMMAND:
 277                 {
 278                         if(argv(1) != "")
 279                         {
 280                                 if(self.flags & FL_CLIENT)
 281                                 {
 282                                         if(teamplay)
 283                                                 if not(self.team_forced > 0)
 284                                                         if not(lockteams)
 285                                                         {
 286                                                                 float selection;
 287
 288                                                                 switch(argv(1))
 289                                                                 {
 290                                                                         case "red": selection = NUM_TEAM_1; break;
 291                                                                         case "blue": selection = NUM_TEAM_2; break;
 292                                                                         case "yellow": selection = NUM_TEAM_3; break;
 293                                                                         case "pink": selection = NUM_TEAM_4; break;
 294                                                                         case "auto": selection = (-1); break;
 295
 296                                                                         default: selection = 0; break;
 297                                                                 }
 298
 299                                                                 if(selection)
 300                                                                 {
 301                                                                         if(self.team == selection && self.deadflag == DEAD_NO)
 302                                                                                 sprint(self, "^7You already are on that team.\n");
 303                                                                         else if(self.wasplayer && autocvar_g_changeteam_banned)
 304                                                                                 sprint(self, "^1You cannot change team, forbidden by the server.\n");
 305                                                                         else
 306                                                                                 ClientKill_TeamChange(selection);
 307                                                                 }
 308                                                         }
 309                                                         else
 310                                                                 sprint(self, "^7The game has already begun, you must wait until the next map to be able to join a team.\n");
 311                                                 else
 312                                                         sprint(self, "^7selectteam can not be used as your team is forced\n");
 313                                         else
 314                                                 sprint(self, "^7selectteam can only be used in teamgames\n");
 315                                 }
 316                                 return;
 317                         }
 318                 }
 319
 320                 default:
 321                         sprint(self, "Incorrect parameters for ^2selectteam^7\n");
 322                 case CMD_REQUEST_USAGE:
 323                 {
 324                         sprint(self, "\nUsage:^3 cmd selectteam team\n");
 325                         sprint(self, "  Where 'team' is the prefered team to try and join.\n");
 326                         sprint(self, "  Full list of options here: \"red, blue, yellow, pink, auto\"\n");
 327                         return;
 328                 }
 329         }
 330 }
 331
 332 void ClientCommand_selfstuff(float request, string command)
 333 {
 334         switch(request)
 335         {
 336                 case CMD_REQUEST_COMMAND:
 337                 {
 338                         if(argv(1) != "")
 339                         {
 340                                 stuffcmd(self, substring(command, argv_start_index(1), argv_end_index(-1) - argv_start_index(1)));
 341                                 return;
 342                         }
 343                 }
 344
 345                 default:
 346                         sprint(self, "Incorrect parameters for ^2selectteam^7\n");
 347                 case CMD_REQUEST_USAGE:
 348                 {
 349                         sprint(self, "\nUsage:^3 cmd selfstuff <command>\n");
 350                         sprint(self, "  Where 'command' is the string to be stuffed to your client.\n");
 351                         return;
 352                 }
 353         }
 354 }
 355
 356 void ClientCommand_sentcvar(float request, float argc, string command)
 357 {
 358         switch(request)
 359         {
 360                 case CMD_REQUEST_COMMAND:
 361                 {
 362                         if(argv(1) != "")
 363                         {
 364                                 //float tokens;
 365                                 string s;
 366
 367                                 if(argc == 2) // undefined cvar: use the default value on the server then
 368                                 {
 369                                         s = strcat(substring(command, argv_start_index(0), argv_end_index(1) - argv_start_index(0)), " \"", cvar_defstring(argv(1)), "\"");
 370                                         tokenize_console(s);
 371                                 }
 372
 373                                 GetCvars(1);
 374
 375                                 return;
 376                         }
 377                 }
 378
 379                 default:
 380                         sprint(self, "Incorrect parameters for ^2sentcvar^7\n");
 381                 case CMD_REQUEST_USAGE:
 382                 {
 383                         sprint(self, "\nUsage:^3 cmd sentcvar <cvar>\n");
 384                         sprint(self, "  Where 'cvar' is the cvar plus arguments to send to the server.\n");
 385                         return;
 386                 }
 387         }
 388 }
 389
 390 void ClientCommand_spectate(float request)
 391 {
 392         switch(request)
 393         {
 394                 case CMD_REQUEST_COMMAND:
 395                 {
 396                         if(self.flags & FL_CLIENT)
 397                         {
 398                                 if(g_arena) { return; }
 399                                 if(g_lms)
 400                                 {
 401                                         if(self.lms_spectate_warning)
 402                                         {
 403                                                 // for the forfeit message...
 404                                                 self.lms_spectate_warning = 2;
 405                                                 // mark player as spectator
 406                                                 PlayerScore_Add(self, SP_LMS_RANK, 666 - PlayerScore_Add(self, SP_LMS_RANK, 0));
 407                                         }
 408                                         else
 409                                         {
 410                                                 self.lms_spectate_warning = 1;
 411                                                 sprint(self, "WARNING: you won't be able to enter the game again after spectating in LMS. Use the same command again to spectate anyway.\n");
 412                                                 return;
 413                                         }
 414                                 }
 415
 416                                 if(self.classname == "player" && autocvar_sv_spectate == 1)
 417                                         ClientKill_TeamChange(-2); // observe
 418
 419                                 // in CA, allow a dead player to move to spectators (without that, caplayer!=0 will be moved back to the player list)
 420                                 // note: if arena game mode is ever done properly, this needs to be removed.
 421                                 if(self.caplayer && (self.classname == "spectator" || self.classname == "observer"))
 422                                 {
 423                                         sprint(self, "WARNING: you will spectate in the next round.\n");
 424                                         self.caplayer = 0;
 425                                 }
 426                         }
 427                         return; // never fall through to usage
 428                 }
 429
 430                 default:
 431                 case CMD_REQUEST_USAGE:
 432                 {
 433                         sprint(self, "\nUsage:^3 cmd spectate\n");
 434                         sprint(self, "  No arguments required.\n");
 435                         return;
 436                 }
 437         }
 438 }
 439
 440 void ClientCommand_suggestmap(float request, float argc)
 441 {
 442         switch(request)
 443         {
 444                 case CMD_REQUEST_COMMAND:
 445                 {
 446                         if(argv(1) != "")
 447                         {
 448                                 sprint(self, strcat(MapVote_Suggest(argv(1)), "\n"));
 449                                 return;
 450                         }
 451                 }
 452
 453                 default:
 454                         sprint(self, "Incorrect parameters for ^2suggestmap^7\n");
 455                 case CMD_REQUEST_USAGE:
 456                 {
 457                         sprint(self, "\nUsage:^3 cmd suggestmap map\n");
 458                         sprint(self, "  Where 'map' is the name of the map to suggest.\n");
 459                         return;
 460                 }
 461         }
 462 }
 463
 464 void ClientCommand_tell(float request, float argc, string command)
 465 {
 466         switch(request)
 467         {
 468                 case CMD_REQUEST_COMMAND:
 469                 {
 470                         if(argc >= 3)
 471                         {
 472                                 entity tell_to = GetIndexedEntity(argc, 1);
 473                                 float tell_accepted = VerifyClientEntity(tell_to, TRUE, FALSE);
 474
 475                                 if(tell_accepted > 0) // the target is a real client
 476                                 {
 477                                         if(tell_to != self) // and we're allowed to send to them :D
 478                                         {
 479                                                 Say(self, FALSE, tell_to, substring(command, argv_start_index(next_token), argv_end_index(-1) - argv_start_index(next_token)), TRUE);
 480                                                 return;
 481                                         }
 482                                         else { print_to(self, "You can't ^2tell^7 a message to yourself."); return; }
 483                                 }
 484                                 else if(argv(1) == "#0")
 485                                 {
 486                                         trigger_magicear_processmessage_forallears(self, -1, world, substring(command, argv_start_index(next_token), argv_end_index(-1) - argv_start_index(next_token)));
 487                                         return;
 488                                 }
 489                                 else { print_to(self, strcat("tell: ", GetClientErrorString(tell_accepted, argv(1)), ".")); return; }
 490                         }
 491                 }
 492
 493                 default:
 494                         sprint(self, "Incorrect parameters for ^2tell^7\n");
 495                 case CMD_REQUEST_USAGE:
 496                 {
 497                         sprint(self, "\nUsage:^3 cmd tell client <message>\n");
 498                         sprint(self, "  Where 'client' is the entity number or name of the player to send 'message' to.\n");
 499                         return;
 500                 }
 501         }
 502 }
 503
 504 void ClientCommand_voice(float request, float argc, string command)
 505 {
 506         switch(request)
 507         {
 508                 case CMD_REQUEST_COMMAND:
 509                 {
 510                         if(argv(1) != "")
 511                         {
 512                                 if(argc >= 3)
 513                                         VoiceMessage(argv(1), substring(command, argv_start_index(2), argv_end_index(-1) - argv_start_index(2)));
 514                                 else
 515                                         VoiceMessage(argv(1), "");
 516
 517                                 return;
 518                         }
 519                 }
 520
 521                 default:
 522                         sprint(self, "Incorrect parameters for ^2voice^7\n");
 523                 case CMD_REQUEST_USAGE:
 524                 {
 525                         sprint(self, "\nUsage:^3 cmd voice messagetype <soundname>\n");
 526                         sprint(self, "  'messagetype' is the type of broadcast to do, like team only or such,\n");
 527                         sprint(self, "  and 'soundname' is the string/filename of the sound/voice message to play.\n");
 528                         return;
 529                 }
 530         }
 531 }
 532
 533 /* use this when creating a new command, making sure to place it in alphabetical order... also,
 534 ** ADD ALL NEW COMMANDS TO commands.cfg WITH PROPER ALIASES IN THE SAME FASHION!
 535 void ClientCommand_(float request)
 536 {
 537         switch(request)
 538         {
 539                 case CMD_REQUEST_COMMAND:
 540                 {
 541
 542                         return; // never fall through to usage
 543                 }
 544
 545                 default:
 546                 case CMD_REQUEST_USAGE:
 547                 {
 548                         sprint(self, "\nUsage:^3 cmd \n");
 549                         sprint(self, "  No arguments required.\n");
 550                         return;
 551                 }
 552         }
 553 }
 554 */
 555
 556
 557 // =====================================
 558 //  Macro system for networked commands
 559 // =====================================
 560
 561 // Do not hard code aliases for these, instead create them in commands.cfg... also: keep in alphabetical order, please ;)
 562 #define CLIENT_COMMANDS(request,arguments,command) \
 563         CLIENT_COMMAND("autoswitch", ClientCommand_autoswitch(request, arguments), "Whether or not to switch automatically when getting a better weapon") \
 564         CLIENT_COMMAND("checkfail", ClientCommand_checkfail(request, command), "Report if a client-side check failed") \
 565         CLIENT_COMMAND("clientversion", ClientCommand_clientversion(request, arguments), "Release version of the game") \
 566         CLIENT_COMMAND("mv_getpicture", ClientCommand_mv_getpicture(request, arguments), "Retrieve mapshot picture from the server") \
 567         CLIENT_COMMAND("join", ClientCommand_join(request), "Become a player in the game") \
 568         CLIENT_COMMAND("ready", ClientCommand_ready(request), "Qualify as ready to end warmup stage (or restart server if allowed)") \
 569         CLIENT_COMMAND("say", ClientCommand_say(request, arguments, command), "Print a message to chat to all players") \
 570         CLIENT_COMMAND("say_team", ClientCommand_say_team(request, arguments, command), "Print a message to chat to all team mates") \
 571         CLIENT_COMMAND("selectteam", ClientCommand_selectteam(request, arguments), "Attempt to choose a team to join into") \
 572         CLIENT_COMMAND("selfstuff", ClientCommand_selfstuff(request, command), "Stuffcmd a command to your own client") \
 573         CLIENT_COMMAND("sentcvar", ClientCommand_sentcvar(request, arguments, command), "New system for sending a client cvar to the server") \
 574         CLIENT_COMMAND("spectate", ClientCommand_spectate(request), "Become an observer") \
 575         CLIENT_COMMAND("suggestmap", ClientCommand_suggestmap(request, arguments), "Suggest a map to the mapvote at match end") \
 576         CLIENT_COMMAND("tell", ClientCommand_tell(request, arguments, command), "Send a message directly to a player") \
 577         CLIENT_COMMAND("voice", ClientCommand_voice(request, arguments, command), "Send voice message via sound") \
 578         /* nothing */
 579
 580 void ClientCommand_macro_help()
 581 {
 582         #define CLIENT_COMMAND(name,function,description) \
 583                 { sprint(self, "  ^2", name, "^7: ", description, "\n"); }
 584
 585         CLIENT_COMMANDS(0, 0, "")
 586         #undef CLIENT_COMMAND
 587
 588         return;
 589 }
 590
 591 float ClientCommand_macro_command(float argc, string command)
 592 {
 593         #define CLIENT_COMMAND(name,function,description) \
 594                 { if(name == strtolower(argv(0))) { function; return TRUE; } }
 595
 596         CLIENT_COMMANDS(CMD_REQUEST_COMMAND, argc, command)
 597         #undef CLIENT_COMMAND
 598
 599         return FALSE;
 600 }
 601
 602 float ClientCommand_macro_usage(float argc)
 603 {
 604         #define CLIENT_COMMAND(name,function,description) \
 605                 { if(name == strtolower(argv(1))) { function; return TRUE; } }
 606
 607         CLIENT_COMMANDS(CMD_REQUEST_USAGE, argc, "")
 608         #undef CLIENT_COMMAND
 609
 610         return FALSE;
 611 }
 612
 613 void ClientCommand_macro_write_aliases(float fh)
 614 {
 615         #define CLIENT_COMMAND(name,function,description) \
 616                 { CMD_Write_Alias("qc_cmd_cmd", name, description); }
 617
 618         CLIENT_COMMANDS(0, 0, "")
 619         #undef CLIENT_COMMAND
 620
 621         return;
 622 }
 623
 624 // ======================================
 625 //  Main Function Called By Engine (cmd)
 626 // ======================================
 627 // If this function exists, server game code parses clientcommand before the engine code gets it.
 628
 629 void SV_ParseClientCommand(string command)
 630 {
 631         // if we're banned, don't even parse the command
 632         if(Ban_MaybeEnforceBanOnce(self))
 633                 return;
 634
 635         float argc = tokenize_console(command);
 636
 637         // for the mutator hook system
 638         cmd_name = strtolower(argv(0));
 639         cmd_argc = argc;
 640         cmd_string = command;
 641
 642         // Guide for working with argc arguments by example:
 643         // argc:   1    - 2      - 3     - 4
 644         // argv:   0    - 1      - 2     - 3
 645         // cmd     vote - master - login - password
 646
 647         // for floodcheck
 648         switch(strtolower(argv(0)))
 649         {
 650                 // exempt commands which are not subject to floodcheck
 651                 case "begin": break; // handled by engine in host_cmd.c
 652                 case "download": break; // handled by engine in cl_parse.c
 653                 case "mv_getpicture": break; // handled by server in this file
 654                 case "pause": break; // handled by engine in host_cmd.c
 655                 case "prespawn": break; // handled by engine in host_cmd.c
 656                 case "sentcvar": break; // handled by server in this file
 657                 case "spawn": break; // handled by engine in host_cmd.c
 658
 659                 default:
 660                         if(SV_ParseClientCommand_floodcheck())
 661                                 break; // "TRUE": continue, as we're not flooding yet
 662                         else
 663                                 return; // "FALSE": not allowed to continue, halt // print("^1ERROR: ^7ANTISPAM CAUGHT: ", command, ".\n");
 664         }
 665
 666         /* NOTE: should this be disabled? It can be spammy perhaps, but hopefully it's okay for now */
 667         if(argv(0) == "help")
 668         {
 669                 if(argc == 1)
 670                 {
 671                         sprint(self, "\nClient networked commands:\n");
 672                         ClientCommand_macro_help();
 673
 674                         sprint(self, "\nCommon networked commands:\n");
 675                         CommonCommand_macro_help(self);
 676
 677                         sprint(self, "\nUsage:^3 cmd COMMAND...^7, where possible commands are listed above.\n");
 678                         sprint(self, "For help about a specific command, type cmd help COMMAND\n");
 679                         return;
 680                 }
 681                 else if(CommonCommand_macro_usage(argc, self)) // Instead of trying to call a command, we're going to see detailed information about it
 682                 {
 683                         return;
 684                 }
 685                 else if(ClientCommand_macro_usage(argc)) // same, but for normal commands now
 686                 {
 687                         return;
 688                 }
 689         }
 690         else if(MUTATOR_CALLHOOK(SV_ParseClientCommand))
 691         {
 692                 return; // handled by a mutator
 693         }
 694         else if(CheatCommand(argc))
 695         {
 696                 return; // handled by server/cheats.qc
 697         }
 698         else if(CommonCommand_macro_command(argc, self, command))
 699         {
 700                 return; // handled by server/command/common.qc
 701         }
 702         else if(ClientCommand_macro_command(argc, command)) // continue as usual and scan for normal commands
 703         {
 704                 return; // handled by one of the above ClientCommand_* functions
 705         }
 706         else
 707                 clientcommand(self, command);
 708 }