qcsrc/server/command/cmd.qc

   1 // =========================================================
   2 //  Server side networked commands code, reworked by Samual
   3 //  Last updated: December 28th, 2011
   4 // =========================================================
   5
   6 float SV_ParseClientCommand_floodcheck()
   7 {
   8         if (!timeout_status) // not while paused
   9         {
  10                 if(time <= (self.cmd_floodtime + autocvar_sv_clientcommand_antispam_time))
  11                 {
  12                         self.cmd_floodcount += 1;
  13                         if(self.cmd_floodcount > autocvar_sv_clientcommand_antispam_count) { return FALSE; } // too much spam, halt
  14                 }
  15                 else
  16                 {
  17                         self.cmd_floodtime = time;
  18                         self.cmd_floodcount = 1;
  19                 }
  20         }
  21         return TRUE; // continue, as we're not flooding yet
  22 }
  23
  24
  25 // =======================
  26 //  Command Sub-Functions
  27 // =======================
  28
  29 void ClientCommand_autoswitch(float request, float argc)
  30 {
  31         switch(request)
  32         {
  33                 case CMD_REQUEST_COMMAND:
  34                 {
  35                         if(argv(1) != "")
  36                         {
  37                                 self.autoswitch = InterpretBoolean(argv(1));
  38                                 sprint(self, strcat("^1autoswitch is currently turned ", (self.autoswitch ? "on" : "off"), ".\n"));
  39                                 return;
  40                         }
  41                 }
  42
  43                 default:
  44                         sprint(self, "Incorrect parameters for ^2autoswitch^7\n");
  45                 case CMD_REQUEST_USAGE:
  46                 {
  47                         sprint(self, "\nUsage:^3 cmd autoswitch selection\n");
  48                         sprint(self, "  Where 'selection' controls if autoswitch is on or off.\n");
  49                         return;
  50                 }
  51         }
  52 }
  53
  54 void ClientCommand_checkfail(float request, string command) // internal command, used only by code
  55 {
  56         switch(request)
  57         {
  58                 case CMD_REQUEST_COMMAND:
  59                 {
  60                         printf("CHECKFAIL: %s (%s) epically failed check %s\n", self.netname, self.netaddress, substring(command, argv_start_index(1), argv_end_index(-1) - argv_start_index(1)));
  61                         self.checkfail = 1;
  62                         return; // never fall through to usage
  63                 }
  64
  65                 default:
  66                         sprint(self, "Incorrect parameters for ^2checkfail^7\n");
  67                 case CMD_REQUEST_USAGE:
  68                 {
  69                         sprint(self, "\nUsage:^3 cmd checkfail <message>\n");
  70                         sprint(self, "  Where 'message' is the message reported by client about the fail.\n");
  71                         return;
  72                 }
  73         }
  74 }
  75
  76 void ClientCommand_clientversion(float request, float argc) // internal command, used only by code
  77 {
  78         switch(request)
  79         {
  80                 case CMD_REQUEST_COMMAND:
  81                 {
  82                         if(argv(1) != "")
  83                         {
  84                                 if(IS_CLIENT(self))
  85                                 {
  86                                         self.version = ((argv(1) == "$gameversion") ? 1 : stof(argv(1)));
  87
  88                                         if(self.version < autocvar_gameversion_min || self.version > autocvar_gameversion_max)
  89                                         {
  90                                                 self.version_mismatch = 1;
  91                                                 ClientKill_TeamChange(-2); // observe
  92                                         }
  93                                         else if(autocvar_g_campaign || autocvar_g_balance_teams)
  94                                         {
  95                                                 //JoinBestTeam(self, FALSE, TRUE);
  96                                         }
  97                                         else if(teamplay && !autocvar_sv_spectate && !(self.team_forced > 0))
  98                                         {
  99                                                 self.classname = "observer"; // really?
 100                                                 stuffcmd(self, "menu_showteamselect\n");
 101                                         }
 102                                 }
 103
 104                                 return;
 105                         }
 106                 }
 107
 108                 default:
 109                         sprint(self, "Incorrect parameters for ^2clientversion^7\n");
 110                 case CMD_REQUEST_USAGE:
 111                 {
 112                         sprint(self, "\nUsage:^3 cmd clientversion version\n");
 113                         sprint(self, "  Where 'version' is the game version reported by self.\n");
 114                         return;
 115                 }
 116         }
 117 }
 118
 119 void ClientCommand_mv_getpicture(float request, float argc) // internal command, used only by code
 120 {
 121         switch(request)
 122         {
 123                 case CMD_REQUEST_COMMAND:
 124                 {
 125                         if(argv(1) != "")
 126                         {
 127                                 if(intermission_running)
 128                                         MapVote_SendPicture(stof(argv(1)));
 129
 130                                 return;
 131                         }
 132                 }
 133
 134                 default:
 135                         sprint(self, "Incorrect parameters for ^2mv_getpicture^7\n");
 136                 case CMD_REQUEST_USAGE:
 137                 {
 138                         sprint(self, "\nUsage:^3 cmd mv_getpicture mapid\n");
 139                         sprint(self, "  Where 'mapid' is the id number of the map to request an image of on the map vote selection menu.\n");
 140                         return;
 141                 }
 142         }
 143 }
 144
 145 void ClientCommand_join(float request)
 146 {
 147         switch(request)
 148         {
 149                 case CMD_REQUEST_COMMAND:
 150                 {
 151                         if(IS_CLIENT(self))
 152                         {
 153                                 if(!IS_PLAYER(self) && !lockteams && !gameover)
 154                                 {
 155                                         if(self.caplayer)
 156                                                 return;
 157                                         if(nJoinAllowed(self))
 158                                         {
 159                                                 if(autocvar_g_campaign) { campaign_bots_may_start = 1; }
 160
 161                                                 self.classname = "player";
 162                                                 PlayerScore_Clear(self);
 163                                                 Kill_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER_CPID, CPID_PREVENT_JOIN);
 164                                                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_JOIN_PLAY, self.netname);
 165                                                 PutClientInServer();
 166                                         }
 167                                         else
 168                                         {
 169                                                 //player may not join because of g_maxplayers is set
 170                                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_JOIN_PREVENT);
 171                                         }
 172                                 }
 173                         }
 174                         return; // never fall through to usage
 175                 }
 176
 177                 default:
 178                 case CMD_REQUEST_USAGE:
 179                 {
 180                         sprint(self, "\nUsage:^3 cmd join\n");
 181                         sprint(self, "  No arguments required.\n");
 182                         return;
 183                 }
 184         }
 185 }
 186
 187 void ClientCommand_mobedit(float request, float argc)
 188 {
 189         switch(request)
 190         {
 191                 case CMD_REQUEST_COMMAND:
 192                 {
 193                         if(argv(1) && argv(2))
 194                         {
 195                                 makevectors(self.v_angle);
 196                                 WarpZone_TraceLine(self.origin + self.view_ofs, self.origin + self.view_ofs + v_forward * 100, MOVE_NORMAL, self);
 197
 198                                 if(!autocvar_g_monsters_edit) { sprint(self, "Monster property editing is not enabled.\n"); return; }
 199                                 if(trace_ent.flags & FL_MONSTER)
 200                                 {
 201                                         if(trace_ent.realowner != self) { sprint(self, "That monster does not belong to you.\n"); return; }
 202                                         switch(argv(1))
 203                                         {
 204                                                 case "skin":
 205                                                 {
 206                                                         if(trace_ent.monsterid != MON_MAGE)
 207                                                                 trace_ent.skin = stof(argv(2));
 208                                                         return;
 209                                                 }
 210                                                 case "movetarget":
 211                                                 {
 212                                                         trace_ent.monster_moveflags = stof(argv(2));
 213                                                         return;
 214                                                 }
 215                                         }
 216                                 }
 217                         }
 218                 }
 219                 default:
 220                         sprint(self, "Incorrect parameters for ^2mobedit^7\n");
 221                 case CMD_REQUEST_USAGE:
 222                 {
 223                         sprint(self, "\nUsage:^3 cmd mobedit [argument]\n");
 224                         sprint(self, "  Where 'argument' can be skin or movetarget.\n");
 225                         sprint(self, "  Aim at your monster to edit its properties.\n");
 226                         return;
 227                 }
 228         }
 229 }
 230
 231 void ClientCommand_mobkill(float request)
 232 {
 233         switch(request)
 234         {
 235                 case CMD_REQUEST_COMMAND:
 236                 {
 237                         makevectors(self.v_angle);
 238                         WarpZone_TraceLine(self.origin + self.view_ofs, self.origin + self.view_ofs + v_forward * 100, MOVE_NORMAL, self);
 239
 240                         if(trace_ent.flags & FL_MONSTER)
 241                         {
 242                                 if(trace_ent.realowner != self)
 243                                 {
 244                                         sprint(self, "That monster does not belong to you.\n");
 245                                         return;
 246                                 }
 247                                 sprint(self, strcat("Your pet '", trace_ent.monster_name, "' has been brutally mutilated.\n"));
 248                                 Damage (trace_ent, world, world, trace_ent.health + trace_ent.max_health + 200, DEATH_KILL, trace_ent.origin, '0 0 0');
 249                                 return;
 250                         }
 251                 }
 252
 253                 default:
 254                         sprint(self, "Incorrect parameters for ^2mobkill^7\n");
 255                 case CMD_REQUEST_USAGE:
 256                 {
 257                         sprint(self, "\nUsage:^3 cmd mobkill\n");
 258                         sprint(self, "  Aim at your monster to kill it.\n");
 259                         return;
 260                 }
 261         }
 262 }
 263
 264 void ClientCommand_mobspawn(float request, float argc)
 265 {
 266         switch(request)
 267         {
 268                 case CMD_REQUEST_COMMAND:
 269                 {
 270                         entity e;
 271                         string tospawn;
 272                         float moveflag, monstercount = 0;
 273
 274                         moveflag = (argv(2) ? stof(argv(2)) : 1); // follow owner if not defined
 275                         tospawn = strtolower(argv(1));
 276
 277                         if(tospawn == "list")
 278                         {
 279                                 sprint(self, monsterlist_reply);
 280                                 return;
 281                         }
 282
 283                         FOR_EACH_MONSTER(e)
 284                         {
 285                                 if(e.realowner == self)
 286                                         ++monstercount;
 287                         }
 288
 289                         if(autocvar_g_monsters_max <= 0 || autocvar_g_monsters_max_perplayer <= 0) { sprint(self, "Monster spawning is disabled.\n"); return; }
 290                         else if(!IS_PLAYER(self)) { sprint(self, "You can't spawn monsters while spectating.\n"); return; }
 291                         else if(MUTATOR_CALLHOOK(AllowMobSpawning)) { sprint(self, "Monster spawning is currently disabled by a mutator.\n"); return; }
 292                         else if(!autocvar_g_monsters) { Send_Notification(NOTIF_ONE, self, MSG_INFO, INFO_MONSTERS_DISABLED); return; }
 293                         else if(self.vehicle) { sprint(self, "You can't spawn monsters while driving a vehicle.\n"); return; }
 294                         else if(self.frozen) { sprint(self, "You can't spawn monsters while frozen.\n"); return; }
 295                         else if(autocvar_g_campaign) { sprint(self, "You can't spawn monsters in campaign mode.\n"); return; }
 296                         else if(self.deadflag != DEAD_NO) { sprint(self, "You can't spawn monsters while dead.\n"); return; }
 297                         else if(monstercount >= autocvar_g_monsters_max_perplayer) { sprint(self, "You have spawned too many monsters, kill some before trying to spawn any more.\n"); return; }
 298                         else if(totalspawned >= autocvar_g_monsters_max) { sprint(self, "The global maximum monster count has been reached, kill some before trying to spawn any more.\n"); return; }
 299                         else if(tospawn != "")
 300                         {
 301                                 float found = 0, i;
 302                                 entity mon;
 303
 304                                 for(i = MON_FIRST; i <= MON_LAST; ++i)
 305                                 {
 306                                         mon = get_monsterinfo(i);
 307                                         if(mon.netname == tospawn)
 308                                         {
 309                                                 found = TRUE;
 310                                                 break;
 311                                         }
 312                                 }
 313
 314                                 if(found || tospawn == "random")
 315                                 {
 316                                         totalspawned += 1;
 317
 318                                         makevectors(self.v_angle);
 319                                         WarpZone_TraceBox (CENTER_OR_VIEWOFS(self), PL_MIN, PL_MAX, CENTER_OR_VIEWOFS(self) + v_forward * 150, TRUE, self);
 320                                         //WarpZone_TraceLine(self.origin + self.view_ofs, self.origin + self.view_ofs + v_forward * 150, MOVE_NORMAL, self);
 321
 322                                         e = spawnmonster(tospawn, 0, self, self, trace_endpos, FALSE, FALSE, moveflag);
 323
 324                                         sprint(self, strcat("Spawned ", e.monster_name, "\n"));
 325
 326                                         return;
 327                                 }
 328                         }
 329                 }
 330
 331                 default:
 332                         sprint(self, "Incorrect parameters for ^2mobspawn^7\n");
 333                 case CMD_REQUEST_USAGE:
 334                 {
 335                         sprint(self, "\nUsage:^3 cmd mobspawn <random> <monster> [movetype]\n");
 336                         sprint(self, "  See 'cmd mobspawn list' for available monsters.\n");
 337                         sprint(self, "  Argument 'random' spawns a random monster.\n");
 338                         sprint(self, "  Monster will follow the owner if second argument is not defined.\n");
 339                         return;
 340                 }
 341         }
 342 }
 343
 344 void ClientCommand_ready(float request) // todo: anti-spam for toggling readyness
 345 {
 346         switch(request)
 347         {
 348                 case CMD_REQUEST_COMMAND:
 349                 {
 350                         if(IS_CLIENT(self))
 351                         {
 352                                 if(warmup_stage || autocvar_sv_ready_restart || g_race_qualifying == 2)
 353                                 {
 354                                         if(!readyrestart_happened || autocvar_sv_ready_restart_repeatable)
 355                                         {
 356                                                 if(time < game_starttime) // game is already restarting
 357                                                         return;
 358                                                 if (self.ready) // toggle
 359                                                 {
 360                                                         self.ready = FALSE;
 361                                                         bprint(self.netname, "^2 is ^1NOT^2 ready\n");
 362                                                 }
 363                                                 else
 364                                                 {
 365                                                         self.ready = TRUE;
 366                                                         bprint(self.netname, "^2 is ready\n");
 367                                                 }
 368
 369                                                 // cannot reset the game while a timeout is active!
 370                                                 if (!timeout_status)
 371                                                         ReadyCount();
 372                                         } else {
 373                                                 sprint(self, "^1Game has already been restarted\n");
 374                                         }
 375                                 }
 376                         }
 377                         return; // never fall through to usage
 378                 }
 379
 380                 default:
 381                 case CMD_REQUEST_USAGE:
 382                 {
 383                         sprint(self, "\nUsage:^3 cmd ready\n");
 384                         sprint(self, "  No arguments required.\n");
 385                         return;
 386                 }
 387         }
 388 }
 389
 390 void ClientCommand_say(float request, float argc, string command)
 391 {
 392         switch(request)
 393         {
 394                 case CMD_REQUEST_COMMAND:
 395                 {
 396                         if(argc >= 2) { Say(self, FALSE, world, substring(command, argv_start_index(1), argv_end_index(-1) - argv_start_index(1)), 1); }
 397                         return; // never fall through to usage
 398                 }
 399
 400                 default:
 401                 case CMD_REQUEST_USAGE:
 402                 {
 403                         sprint(self, "\nUsage:^3 cmd say <message>\n");
 404                         sprint(self, "  Where 'message' is the string of text to say.\n");
 405                         return;
 406                 }
 407         }
 408 }
 409
 410 void ClientCommand_say_team(float request, float argc, string command)
 411 {
 412         switch(request)
 413         {
 414                 case CMD_REQUEST_COMMAND:
 415                 {
 416                         if(argc >= 2) { Say(self, TRUE, world, substring(command, argv_start_index(1), argv_end_index(-1) - argv_start_index(1)), 1); }
 417                         return; // never fall through to usage
 418                 }
 419
 420                 default:
 421                 case CMD_REQUEST_USAGE:
 422                 {
 423                         sprint(self, "\nUsage:^3 cmd say_team <message>\n");
 424                         sprint(self, "  Where 'message' is the string of text to say.\n");
 425                         return;
 426                 }
 427         }
 428 }
 429
 430 void ClientCommand_selectteam(float request, float argc)
 431 {
 432         switch(request)
 433         {
 434                 case CMD_REQUEST_COMMAND:
 435                 {
 436                         if(argv(1) != "")
 437                         {
 438                                 if(IS_CLIENT(self))
 439                                 {
 440                                         if(teamplay)
 441                                                 if(self.team_forced <= 0)
 442                                                         if (!lockteams)
 443                                                         {
 444                                                                 float selection;
 445
 446                                                                 switch(argv(1))
 447                                                                 {
 448                                                                         case "red": selection = NUM_TEAM_1; break;
 449                                                                         case "blue": selection = NUM_TEAM_2; break;
 450                                                                         case "yellow": selection = NUM_TEAM_3; break;
 451                                                                         case "pink": selection = NUM_TEAM_4; break;
 452                                                                         case "auto": selection = (-1); break;
 453
 454                                                                         default: selection = 0; break;
 455                                                                 }
 456
 457                                                                 if(selection)
 458                                                                 {
 459                                                                         if(self.team == selection && self.deadflag == DEAD_NO)
 460                                                                                 sprint(self, "^7You already are on that team.\n");
 461                                                                         else if(self.wasplayer && autocvar_g_changeteam_banned)
 462                                                                                 sprint(self, "^1You cannot change team, forbidden by the server.\n");
 463                                                                         else
 464                                                                         {
 465                                                                                 if(autocvar_g_balance_teams && autocvar_g_balance_teams_prevent_imbalance)
 466                                                                                 {
 467                                                                                         CheckAllowedTeams(self);
 468                                                                                         GetTeamCounts(self);
 469                                                                                         if(!TeamSmallerEqThanTeam(Team_TeamToNumber(selection), Team_TeamToNumber(self.team), self))
 470                                                                                         {
 471                                                                                                 Send_Notification(NOTIF_ONE, self, MSG_INFO, INFO_TEAMCHANGE_LARGERTEAM);
 472                                                                                                 return;
 473                                                                                         }
 474                                                                                 }
 475                                                                                 ClientKill_TeamChange(selection);
 476                                                                         }
 477                                                                 }
 478                                                         }
 479                                                         else
 480                                                                 sprint(self, "^7The game has already begun, you must wait until the next map to be able to join a team.\n");
 481                                                 else
 482                                                         sprint(self, "^7selectteam can not be used as your team is forced\n");
 483                                         else
 484                                                 sprint(self, "^7selectteam can only be used in teamgames\n");
 485                                 }
 486                                 return;
 487                         }
 488                 }
 489
 490                 default:
 491                         sprint(self, "Incorrect parameters for ^2selectteam^7\n");
 492                 case CMD_REQUEST_USAGE:
 493                 {
 494                         sprint(self, "\nUsage:^3 cmd selectteam team\n");
 495                         sprint(self, "  Where 'team' is the prefered team to try and join.\n");
 496                         sprint(self, "  Full list of options here: \"red, blue, yellow, pink, auto\"\n");
 497                         return;
 498                 }
 499         }
 500 }
 501
 502 void ClientCommand_selfstuff(float request, string command)
 503 {
 504         switch(request)
 505         {
 506                 case CMD_REQUEST_COMMAND:
 507                 {
 508                         if(argv(1) != "")
 509                         {
 510                                 stuffcmd(self, substring(command, argv_start_index(1), argv_end_index(-1) - argv_start_index(1)));
 511                                 return;
 512                         }
 513                 }
 514
 515                 default:
 516                         sprint(self, "Incorrect parameters for ^2selectteam^7\n");
 517                 case CMD_REQUEST_USAGE:
 518                 {
 519                         sprint(self, "\nUsage:^3 cmd selfstuff <command>\n");
 520                         sprint(self, "  Where 'command' is the string to be stuffed to your client.\n");
 521                         return;
 522                 }
 523         }
 524 }
 525
 526 void ClientCommand_sentcvar(float request, float argc, string command)
 527 {
 528         switch(request)
 529         {
 530                 case CMD_REQUEST_COMMAND:
 531                 {
 532                         if(argv(1) != "")
 533                         {
 534                                 //float tokens;
 535                                 string s;
 536
 537                                 if(argc == 2) // undefined cvar: use the default value on the server then
 538                                 {
 539                                         s = strcat(substring(command, argv_start_index(0), argv_end_index(1) - argv_start_index(0)), " \"", cvar_defstring(argv(1)), "\"");
 540                                         tokenize_console(s);
 541                                 }
 542
 543                                 GetCvars(1);
 544
 545                                 return;
 546                         }
 547                 }
 548
 549                 default:
 550                         sprint(self, "Incorrect parameters for ^2sentcvar^7\n");
 551                 case CMD_REQUEST_USAGE:
 552                 {
 553                         sprint(self, "\nUsage:^3 cmd sentcvar <cvar>\n");
 554                         sprint(self, "  Where 'cvar' is the cvar plus arguments to send to the server.\n");
 555                         return;
 556                 }
 557         }
 558 }
 559
 560 void ClientCommand_spectate(float request)
 561 {
 562         switch(request)
 563         {
 564                 case CMD_REQUEST_COMMAND:
 565                 {
 566                         if(IS_CLIENT(self))
 567                         {
 568                                 if(g_lms)
 569                                 {
 570                                         if(self.lms_spectate_warning)
 571                                         {
 572                                                 // for the forfeit message...
 573                                                 self.lms_spectate_warning = 2;
 574                                                 // mark player as spectator
 575                                                 PlayerScore_Add(self, SP_LMS_RANK, 666 - PlayerScore_Add(self, SP_LMS_RANK, 0));
 576                                         }
 577                                         else
 578                                         {
 579                                                 self.lms_spectate_warning = 1;
 580                                                 sprint(self, "WARNING: you won't be able to enter the game again after spectating in LMS. Use the same command again to spectate anyway.\n");
 581                                                 return;
 582                                         }
 583                                 }
 584
 585                                 if((IS_PLAYER(self) || self.caplayer) && autocvar_sv_spectate == 1)
 586                                 {
 587                                         if(self.caplayer && (IS_SPEC(self) || IS_OBSERVER(self)))
 588                                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_CA_LEAVE);
 589                                         ClientKill_TeamChange(-2); // observe
 590                                 }
 591                         }
 592                         return; // never fall through to usage
 593                 }
 594
 595                 default:
 596                 case CMD_REQUEST_USAGE:
 597                 {
 598                         sprint(self, "\nUsage:^3 cmd spectate\n");
 599                         sprint(self, "  No arguments required.\n");
 600                         return;
 601                 }
 602         }
 603 }
 604
 605 void ClientCommand_suggestmap(float request, float argc)
 606 {
 607         switch(request)
 608         {
 609                 case CMD_REQUEST_COMMAND:
 610                 {
 611                         if(argv(1) != "")
 612                         {
 613                                 sprint(self, strcat(MapVote_Suggest(argv(1)), "\n"));
 614                                 return;
 615                         }
 616                 }
 617
 618                 default:
 619                         sprint(self, "Incorrect parameters for ^2suggestmap^7\n");
 620                 case CMD_REQUEST_USAGE:
 621                 {
 622                         sprint(self, "\nUsage:^3 cmd suggestmap map\n");
 623                         sprint(self, "  Where 'map' is the name of the map to suggest.\n");
 624                         return;
 625                 }
 626         }
 627 }
 628
 629 void ClientCommand_tell(float request, float argc, string command)
 630 {
 631         switch(request)
 632         {
 633                 case CMD_REQUEST_COMMAND:
 634                 {
 635                         if(argc >= 3)
 636                         {
 637                                 entity tell_to = GetIndexedEntity(argc, 1);
 638                                 float tell_accepted = VerifyClientEntity(tell_to, TRUE, FALSE);
 639
 640                                 if(tell_accepted > 0) // the target is a real client
 641                                 {
 642                                         if(tell_to != self) // and we're allowed to send to them :D
 643                                         {
 644                                                 Say(self, FALSE, tell_to, substring(command, argv_start_index(next_token), argv_end_index(-1) - argv_start_index(next_token)), TRUE);
 645                                                 return;
 646                                         }
 647                                         else { print_to(self, "You can't ^2tell^7 a message to yourself."); return; }
 648                                 }
 649                                 else if(argv(1) == "#0")
 650                                 {
 651                                         trigger_magicear_processmessage_forallears(self, -1, world, substring(command, argv_start_index(next_token), argv_end_index(-1) - argv_start_index(next_token)));
 652                                         return;
 653                                 }
 654                                 else { print_to(self, strcat("tell: ", GetClientErrorString(tell_accepted, argv(1)), ".")); return; }
 655                         }
 656                 }
 657
 658                 default:
 659                         sprint(self, "Incorrect parameters for ^2tell^7\n");
 660                 case CMD_REQUEST_USAGE:
 661                 {
 662                         sprint(self, "\nUsage:^3 cmd tell client <message>\n");
 663                         sprint(self, "  Where 'client' is the entity number or name of the player to send 'message' to.\n");
 664                         return;
 665                 }
 666         }
 667 }
 668
 669 void ClientCommand_voice(float request, float argc, string command)
 670 {
 671         switch(request)
 672         {
 673                 case CMD_REQUEST_COMMAND:
 674                 {
 675                         if(argv(1) != "")
 676                         {
 677                                 if(argc >= 3)
 678                                         VoiceMessage(argv(1), substring(command, argv_start_index(2), argv_end_index(-1) - argv_start_index(2)));
 679                                 else
 680                                         VoiceMessage(argv(1), "");
 681
 682                                 return;
 683                         }
 684                 }
 685
 686                 default:
 687                         sprint(self, "Incorrect parameters for ^2voice^7\n");
 688                 case CMD_REQUEST_USAGE:
 689                 {
 690                         sprint(self, "\nUsage:^3 cmd voice messagetype <soundname>\n");
 691                         sprint(self, "  'messagetype' is the type of broadcast to do, like team only or such,\n");
 692                         sprint(self, "  and 'soundname' is the string/filename of the sound/voice message to play.\n");
 693                         return;
 694                 }
 695         }
 696 }
 697
 698 /* use this when creating a new command, making sure to place it in alphabetical order... also,
 699 ** ADD ALL NEW COMMANDS TO commands.cfg WITH PROPER ALIASES IN THE SAME FASHION!
 700 void ClientCommand_(float request)
 701 {
 702         switch(request)
 703         {
 704                 case CMD_REQUEST_COMMAND:
 705                 {
 706
 707                         return; // never fall through to usage
 708                 }
 709
 710                 default:
 711                 case CMD_REQUEST_USAGE:
 712                 {
 713                         sprint(self, "\nUsage:^3 cmd \n");
 714                         sprint(self, "  No arguments required.\n");
 715                         return;
 716                 }
 717         }
 718 }
 719 */
 720
 721
 722 // =====================================
 723 //  Macro system for networked commands
 724 // =====================================
 725
 726 // Do not hard code aliases for these, instead create them in commands.cfg... also: keep in alphabetical order, please ;)
 727 #define CLIENT_COMMANDS(request,arguments,command) \
 728         CLIENT_COMMAND("autoswitch", ClientCommand_autoswitch(request, arguments), "Whether or not to switch automatically when getting a better weapon") \
 729         CLIENT_COMMAND("checkfail", ClientCommand_checkfail(request, command), "Report if a client-side check failed") \
 730         CLIENT_COMMAND("clientversion", ClientCommand_clientversion(request, arguments), "Release version of the game") \
 731         CLIENT_COMMAND("mv_getpicture", ClientCommand_mv_getpicture(request, arguments), "Retrieve mapshot picture from the server") \
 732         CLIENT_COMMAND("join", ClientCommand_join(request), "Become a player in the game") \
 733         CLIENT_COMMAND("mobedit", ClientCommand_mobedit(request, arguments), "Edit your monster's properties") \
 734         CLIENT_COMMAND("mobkill", ClientCommand_mobkill(request), "Kills your monster") \
 735         CLIENT_COMMAND("mobspawn", ClientCommand_mobspawn(request, arguments), "Spawn monsters infront of yourself") \
 736         CLIENT_COMMAND("ready", ClientCommand_ready(request), "Qualify as ready to end warmup stage (or restart server if allowed)") \
 737         CLIENT_COMMAND("say", ClientCommand_say(request, arguments, command), "Print a message to chat to all players") \
 738         CLIENT_COMMAND("say_team", ClientCommand_say_team(request, arguments, command), "Print a message to chat to all team mates") \
 739         CLIENT_COMMAND("selectteam", ClientCommand_selectteam(request, arguments), "Attempt to choose a team to join into") \
 740         CLIENT_COMMAND("selfstuff", ClientCommand_selfstuff(request, command), "Stuffcmd a command to your own client") \
 741         CLIENT_COMMAND("sentcvar", ClientCommand_sentcvar(request, arguments, command), "New system for sending a client cvar to the server") \
 742         CLIENT_COMMAND("spectate", ClientCommand_spectate(request), "Become an observer") \
 743         CLIENT_COMMAND("suggestmap", ClientCommand_suggestmap(request, arguments), "Suggest a map to the mapvote at match end") \
 744         CLIENT_COMMAND("tell", ClientCommand_tell(request, arguments, command), "Send a message directly to a player") \
 745         CLIENT_COMMAND("voice", ClientCommand_voice(request, arguments, command), "Send voice message via sound") \
 746         /* nothing */
 747
 748 void ClientCommand_macro_help()
 749 {
 750         #define CLIENT_COMMAND(name,function,description) \
 751                 { sprint(self, "  ^2", name, "^7: ", description, "\n"); }
 752
 753         CLIENT_COMMANDS(0, 0, "")
 754         #undef CLIENT_COMMAND
 755
 756         return;
 757 }
 758
 759 float ClientCommand_macro_command(float argc, string command)
 760 {
 761         #define CLIENT_COMMAND(name,function,description) \
 762                 { if(name == strtolower(argv(0))) { function; return TRUE; } }
 763
 764         CLIENT_COMMANDS(CMD_REQUEST_COMMAND, argc, command)
 765         #undef CLIENT_COMMAND
 766
 767         return FALSE;
 768 }
 769
 770 float ClientCommand_macro_usage(float argc)
 771 {
 772         #define CLIENT_COMMAND(name,function,description) \
 773                 { if(name == strtolower(argv(1))) { function; return TRUE; } }
 774
 775         CLIENT_COMMANDS(CMD_REQUEST_USAGE, argc, "")
 776         #undef CLIENT_COMMAND
 777
 778         return FALSE;
 779 }
 780
 781 void ClientCommand_macro_write_aliases(float fh)
 782 {
 783         #define CLIENT_COMMAND(name,function,description) \
 784                 { CMD_Write_Alias("qc_cmd_cmd", name, description); }
 785
 786         CLIENT_COMMANDS(0, 0, "")
 787         #undef CLIENT_COMMAND
 788
 789         return;
 790 }
 791
 792 // ======================================
 793 //  Main Function Called By Engine (cmd)
 794 // ======================================
 795 // If this function exists, server game code parses clientcommand before the engine code gets it.
 796
 797 void SV_ParseClientCommand(string command)
 798 {
 799         // if we're banned, don't even parse the command
 800         if(Ban_MaybeEnforceBanOnce(self))
 801                 return;
 802
 803         float argc = tokenize_console(command);
 804
 805         // for the mutator hook system
 806         cmd_name = strtolower(argv(0));
 807         cmd_argc = argc;
 808         cmd_string = command;
 809
 810         // Guide for working with argc arguments by example:
 811         // argc:   1    - 2      - 3     - 4
 812         // argv:   0    - 1      - 2     - 3
 813         // cmd     vote - master - login - password
 814
 815         // for floodcheck
 816         switch(strtolower(argv(0)))
 817         {
 818                 // exempt commands which are not subject to floodcheck
 819                 case "begin": break; // handled by engine in host_cmd.c
 820                 case "download": break; // handled by engine in cl_parse.c
 821                 case "mv_getpicture": break; // handled by server in this file
 822                 case "pause": break; // handled by engine in host_cmd.c
 823                 case "prespawn": break; // handled by engine in host_cmd.c
 824                 case "sentcvar": break; // handled by server in this file
 825                 case "spawn": break; // handled by engine in host_cmd.c
 826
 827                 default:
 828                         if(SV_ParseClientCommand_floodcheck())
 829                                 break; // "TRUE": continue, as we're not flooding yet
 830                         else
 831                                 return; // "FALSE": not allowed to continue, halt // print("^1ERROR: ^7ANTISPAM CAUGHT: ", command, ".\n");
 832         }
 833
 834         /* NOTE: should this be disabled? It can be spammy perhaps, but hopefully it's okay for now */
 835         if(argv(0) == "help")
 836         {
 837                 if(argc == 1)
 838                 {
 839                         sprint(self, "\nClient networked commands:\n");
 840                         ClientCommand_macro_help();
 841
 842                         sprint(self, "\nCommon networked commands:\n");
 843                         CommonCommand_macro_help(self);
 844
 845                         sprint(self, "\nUsage:^3 cmd COMMAND...^7, where possible commands are listed above.\n");
 846                         sprint(self, "For help about a specific command, type cmd help COMMAND\n");
 847                         return;
 848                 }
 849                 else if(CommonCommand_macro_usage(argc, self)) // Instead of trying to call a command, we're going to see detailed information about it
 850                 {
 851                         return;
 852                 }
 853                 else if(ClientCommand_macro_usage(argc)) // same, but for normal commands now
 854                 {
 855                         return;
 856                 }
 857         }
 858         else if(MUTATOR_CALLHOOK(SV_ParseClientCommand))
 859         {
 860                 return; // handled by a mutator
 861         }
 862         else if(CheatCommand(argc))
 863         {
 864                 return; // handled by server/cheats.qc
 865         }
 866         else if(CommonCommand_macro_command(argc, self, command))
 867         {
 868                 return; // handled by server/command/common.qc
 869         }
 870         else if(ClientCommand_macro_command(argc, command)) // continue as usual and scan for normal commands
 871         {
 872                 return; // handled by one of the above ClientCommand_* functions
 873         }
 874         else
 875                 clientcommand(self, command);
 876 }