qcsrc/server/command/cmd.qc

   1 // =========================================================
   2 //  Server side networked commands code, reworked by Samual
   3 //  Last updated: December 28th, 2011
   4 // =========================================================
   5
   6 float SV_ParseClientCommand_floodcheck()
   7 {
   8         if not(timeout_status) // not while paused
   9         {
  10                 if(time <= (self.cmd_floodtime + autocvar_sv_clientcommand_antispam_time))
  11                 {
  12                         self.cmd_floodcount += 1;
  13                         if(self.cmd_floodcount > autocvar_sv_clientcommand_antispam_count) { return FALSE; } // too much spam, halt
  14                 }
  15                 else
  16                 {
  17                         self.cmd_floodtime = time;
  18                         self.cmd_floodcount = 1;
  19                 }
  20         }
  21         return TRUE; // continue, as we're not flooding yet
  22 }
  23
  24
  25 // =======================
  26 //  Command Sub-Functions
  27 // =======================
  28
  29 void ClientCommand_autoswitch(float request, float argc)
  30 {
  31         switch(request)
  32         {
  33                 case CMD_REQUEST_COMMAND:
  34                 {
  35                         if(argv(1) != "")
  36                         {
  37                                 self.autoswitch = InterpretBoolean(argv(1));
  38                                 sprint(self, strcat("^1autoswitch is currently turned ", (self.autoswitch ? "on" : "off"), ".\n"));
  39                                 return;
  40                         }
  41                 }
  42
  43                 default:
  44                         sprint(self, "Incorrect parameters for ^2autoswitch^7\n");
  45                 case CMD_REQUEST_USAGE:
  46                 {
  47                         sprint(self, "\nUsage:^3 cmd autoswitch selection\n");
  48                         sprint(self, "  Where 'selection' controls if autoswitch is on or off.\n");
  49                         return;
  50                 }
  51         }
  52 }
  53
  54 void ClientCommand_checkfail(float request, string command) // internal command, used only by code
  55 {
  56         switch(request)
  57         {
  58                 case CMD_REQUEST_COMMAND:
  59                 {
  60                         print(sprintf("CHECKFAIL: %s (%s) epically failed check %s\n", self.netname, self.netaddress, substring(command, argv_start_index(1), argv_end_index(-1) - argv_start_index(1))));
  61                         self.checkfail = 1;
  62                         return; // never fall through to usage
  63                 }
  64
  65                 default:
  66                         sprint(self, "Incorrect parameters for ^2checkfail^7\n");
  67                 case CMD_REQUEST_USAGE:
  68                 {
  69                         sprint(self, "\nUsage:^3 cmd checkfail <message>\n");
  70                         sprint(self, "  Where 'message' is the message reported by client about the fail.\n");
  71                         return;
  72                 }
  73         }
  74 }
  75
  76 void ClientCommand_clientversion(float request, float argc) // internal command, used only by code
  77 {
  78         switch(request)
  79         {
  80                 case CMD_REQUEST_COMMAND:
  81                 {
  82                         if(argv(1) != "")
  83                         {
  84                                 if(self.flags & FL_CLIENT)
  85                                 {
  86                                         self.version = ((argv(1) == "$gameversion") ? 1 : stof(argv(1)));
  87
  88                                         if(self.version < autocvar_gameversion_min || self.version > autocvar_gameversion_max)
  89                                         {
  90                                                 self.version_mismatch = 1;
  91                                                 ClientKill_TeamChange(-2); // observe
  92                                         }
  93                                         else if(autocvar_g_campaign || autocvar_g_balance_teams)
  94                                         {
  95                                                 //JoinBestTeam(self, FALSE, TRUE);
  96                                         }
  97                                         else if(teamplay && !autocvar_sv_spectate && !(self.team_forced > 0))
  98                                         {
  99                                                 self.classname = "observer"; // really?
 100                                                 stuffcmd(self, "menu_showteamselect\n");
 101                                         }
 102                                 }
 103
 104                                 return;
 105                         }
 106                 }
 107
 108                 default:
 109                         sprint(self, "Incorrect parameters for ^2clientversion^7\n");
 110                 case CMD_REQUEST_USAGE:
 111                 {
 112                         sprint(self, "\nUsage:^3 cmd clientversion version\n");
 113                         sprint(self, "  Where 'version' is the game version reported by self.\n");
 114                         return;
 115                 }
 116         }
 117 }
 118
 119 void ClientCommand_mv_getpicture(float request, float argc) // internal command, used only by code
 120 {
 121         switch(request)
 122         {
 123                 case CMD_REQUEST_COMMAND:
 124                 {
 125                         if(argv(1) != "")
 126                         {
 127                                 if(intermission_running)
 128                                         MapVote_SendPicture(stof(argv(1)));
 129
 130                                 return;
 131                         }
 132                 }
 133
 134                 default:
 135                         sprint(self, "Incorrect parameters for ^2mv_getpicture^7\n");
 136                 case CMD_REQUEST_USAGE:
 137                 {
 138                         sprint(self, "\nUsage:^3 cmd mv_getpicture mapid\n");
 139                         sprint(self, "  Where 'mapid' is the id number of the map to request an image of on the map vote selection menu.\n");
 140                         return;
 141                 }
 142         }
 143 }
 144
 145 void ClientCommand_join(float request)
 146 {
 147         switch(request)
 148         {
 149                 case CMD_REQUEST_COMMAND:
 150                 {
 151                         if(self.flags & FL_CLIENT)
 152                         {
 153                                 if(self.classname != "player" && !lockteams && !g_arena)
 154                                 {
 155                                         if(nJoinAllowed(self))
 156                                         {
 157                                                 if(g_ca) { self.caplayer = 1; }
 158                                                 if(autocvar_g_campaign) { campaign_bots_may_start = 1; }
 159
 160                                                 self.classname = "player";
 161                                                 PlayerScore_Clear(self);
 162                                                 Kill_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER_CPID, CPID_MOTD);
 163                                                 Kill_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER_CPID, CPID_PREVENT_JOIN);
 164                                                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_JOIN_PLAY, self.netname);
 165                                                 PutClientInServer();
 166                                         }
 167                                         else
 168                                         {
 169                                                 //player may not join because of g_maxplayers is set
 170                                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER_CPID, CPID_PREVENT_JOIN);
 171                                         }
 172                                 }
 173                         }
 174                         return; // never fall through to usage
 175                 }
 176
 177                 default:
 178                 case CMD_REQUEST_USAGE:
 179                 {
 180                         sprint(self, "\nUsage:^3 cmd join\n");
 181                         sprint(self, "  No arguments required.\n");
 182                         return;
 183                 }
 184         }
 185 }
 186
 187 void ClientCommand_mobedit(float request, float argc)
 188 {
 189         switch(request)
 190         {
 191                 case CMD_REQUEST_COMMAND:
 192                 {
 193                         makevectors(self.v_angle);
 194                         WarpZone_TraceLine(self.origin + self.view_ofs, self.origin + self.view_ofs + v_forward * 100, MOVE_NORMAL, self);
 195
 196                         if not(trace_ent.flags & FL_MONSTER) { sprint(self, "You need to aim at your monster to edit its properties.\n"); return; }
 197                         if(trace_ent.realowner != self) { sprint(self, "That monster does not belong to you.\n"); return; }
 198
 199                         switch(argv(1))
 200                         {
 201                                 case "name": trace_ent.netname = strzone(strdecolorize(argv(2))); if(trace_ent.sprite) WaypointSprite_UpdateSprites(trace_ent.sprite, trace_ent.netname, "", ""); break;
 202                                 case "skin": trace_ent.skin = stof(argv(2)); trace_ent.SendFlags |= MSF_STATUS; break;
 203                                 case "movetarget": trace_ent.monster_moveflags = stof(argv(2)); break;
 204                                 default: sprint(self, "Unknown parameter\n"); break;
 205                         }
 206
 207                         return; // never fall through to usage
 208                 }
 209                 default:
 210                         sprint(self, "Incorrect parameters for ^2mobedit^7\n");
 211                 case CMD_REQUEST_USAGE:
 212                 {
 213                         sprint(self, "\nUsage:^3 cmd mobedit [argument]\n");
 214                         sprint(self, "  Where 'argument' can be name, skin, color or movetarget.\n");
 215                         return;
 216                 }
 217         }
 218 }
 219
 220 void ClientCommand_mobkill(float request)
 221 {
 222         switch(request)
 223         {
 224                 case CMD_REQUEST_COMMAND:
 225                 {
 226                         makevectors(self.v_angle);
 227                         WarpZone_TraceLine(self.origin + self.view_ofs, self.origin + self.view_ofs + v_forward * 100, MOVE_NORMAL, self);
 228
 229                         if(trace_ent.flags & FL_MONSTER)
 230                         {
 231                                 if(trace_ent.realowner != self)
 232                                 {
 233                                         sprint(self, "That monster does not belong to you.\n");
 234                                         return;
 235                                 }
 236                                 sprint(self, strcat("Your pet '", trace_ent.netname, "' has been brutally mutilated.\n"));
 237                                 Damage (trace_ent, world, world, trace_ent.health + trace_ent.max_health + 200, DEATH_KILL, trace_ent.origin, '0 0 0');
 238                                 return;
 239                         }
 240                         else
 241                                 sprint(self, "You need to aim at your monster to kill it.\n");
 242
 243                         return;
 244                 }
 245
 246                 default:
 247                         sprint(self, "Incorrect parameters for ^2mobkill^7\n");
 248                 case CMD_REQUEST_USAGE:
 249                 {
 250                         sprint(self, "\nUsage:^3 cmd mobkill\n");
 251                         sprint(self, "  Aim at your monster to kill it.\n");
 252                         return;
 253                 }
 254         }
 255 }
 256
 257 void ClientCommand_mobspawn(float request, float argc)
 258 {
 259         switch(request)
 260         {
 261                 case CMD_REQUEST_COMMAND:
 262                 {
 263                         entity e;
 264                         string tospawn, mname;
 265                         float moveflag;
 266
 267                         moveflag = (argv(2) ? stof(argv(2)) : 1); // follow owner if not defined
 268                         tospawn = strtolower(argv(1));
 269                         mname = argv(3);
 270
 271                         if(tospawn == "list")
 272                         {
 273                                 sprint(self, "Available monsters:\n");
 274                                 sprint(self, strcat(autocvar_g_monsters_spawn_list, "\n"));
 275                                 return;
 276                         }
 277
 278                         if(autocvar_g_monsters_max <= 0 || autocvar_g_monsters_max_perplayer <= 0) { sprint(self, "Monster spawning is disabled.\n"); }
 279                         else if(!IS_PLAYER(self)) { sprint(self, "You can't spawn monsters while spectating.\n"); }
 280                         else if not(autocvar_g_monsters) { Send_Notification(NOTIF_ONE, self, MSG_INFO, INFO_MONSTERS_DISABLED); }
 281                         else if(self.vehicle) { sprint(self, "You can't spawn monsters while driving a vehicle.\n"); }
 282                         else if(autocvar_g_campaign) { sprint(self, "You can't spawn monsters in campaign mode.\n"); }
 283                         else if(g_td) { sprint(self, "You can't spawn monsters in Tower Defense mode.\n"); }
 284                         else if(self.deadflag) { sprint(self, "You can't spawn monsters while dead.\n"); }
 285                         else if(self.monstercount >= autocvar_g_monsters_max_perplayer) { sprint(self, "You have spawned too many monsters, kill some before trying to spawn any more.\n"); }
 286                         else if(totalspawned >= autocvar_g_monsters_max) { sprint(self, "The global maximum monster count has been reached, kill some before trying to spawn any more.\n"); }
 287                         else // all worked out, so continue
 288                         {
 289                                 self.monstercount += 1;
 290                                 totalspawned += 1;
 291
 292                                 makevectors(self.v_angle);
 293                                 WarpZone_TraceLine(self.origin + self.view_ofs, self.origin + self.view_ofs + v_forward * 150, MOVE_NORMAL, self);
 294
 295                                 e = spawnmonster(tospawn, self, self, trace_endpos, FALSE, moveflag);
 296                                 if(mname) e.netname = strzone(mname);
 297
 298                                 sprint(self, strcat("Spawned 1 ", tospawn, "\n"));
 299                         }
 300
 301                         return;
 302                 }
 303
 304                 default:
 305                         sprint(self, "Incorrect parameters for ^2mobspawn^7\n");
 306                 case CMD_REQUEST_USAGE:
 307                 {
 308                         sprint(self, "\nUsage:^3 cmd mobspawn monster\n");
 309                         sprint(self, "  See 'cmd mobspawn list' for available arguments.\n");
 310                         return;
 311                 }
 312         }
 313 }
 314
 315 void ClientCommand_ready(float request) // todo: anti-spam for toggling readyness
 316 {
 317         switch(request)
 318         {
 319                 case CMD_REQUEST_COMMAND:
 320                 {
 321                         if(self.flags & FL_CLIENT)
 322                         {
 323                                 if(inWarmupStage || autocvar_sv_ready_restart || g_race_qualifying == 2)
 324                                 {
 325                                         if(!readyrestart_happened || autocvar_sv_ready_restart_repeatable)
 326                                         {
 327                                                 if (self.ready) // toggle
 328                                                 {
 329                                                         self.ready = FALSE;
 330                                                         bprint(self.netname, "^2 is ^1NOT^2 ready\n");
 331                                                 }
 332                                                 else
 333                                                 {
 334                                                         self.ready = TRUE;
 335                                                         bprint(self.netname, "^2 is ready\n");
 336                                                 }
 337
 338                                                 // cannot reset the game while a timeout is active!
 339                                                 if not(timeout_status)
 340                                                         ReadyCount();
 341                                         } else {
 342                                                 sprint(self, "^1Game has already been restarted\n");
 343                                         }
 344                                 }
 345                         }
 346                         return; // never fall through to usage
 347                 }
 348
 349                 default:
 350                 case CMD_REQUEST_USAGE:
 351                 {
 352                         sprint(self, "\nUsage:^3 cmd ready\n");
 353                         sprint(self, "  No arguments required.\n");
 354                         return;
 355                 }
 356         }
 357 }
 358
 359 void ClientCommand_say(float request, float argc, string command)
 360 {
 361         switch(request)
 362         {
 363                 case CMD_REQUEST_COMMAND:
 364                 {
 365                         if(argc >= 2) { Say(self, FALSE, world, substring(command, argv_start_index(1), argv_end_index(-1) - argv_start_index(1)), 1); }
 366                         return; // never fall through to usage
 367                 }
 368
 369                 default:
 370                 case CMD_REQUEST_USAGE:
 371                 {
 372                         sprint(self, "\nUsage:^3 cmd say <message>\n");
 373                         sprint(self, "  Where 'message' is the string of text to say.\n");
 374                         return;
 375                 }
 376         }
 377 }
 378
 379 void ClientCommand_say_team(float request, float argc, string command)
 380 {
 381         switch(request)
 382         {
 383                 case CMD_REQUEST_COMMAND:
 384                 {
 385                         if(argc >= 2) { Say(self, TRUE, world, substring(command, argv_start_index(1), argv_end_index(-1) - argv_start_index(1)), 1); }
 386                         return; // never fall through to usage
 387                 }
 388
 389                 default:
 390                 case CMD_REQUEST_USAGE:
 391                 {
 392                         sprint(self, "\nUsage:^3 cmd say_team <message>\n");
 393                         sprint(self, "  Where 'message' is the string of text to say.\n");
 394                         return;
 395                 }
 396         }
 397 }
 398
 399 void ClientCommand_selectteam(float request, float argc)
 400 {
 401         switch(request)
 402         {
 403                 case CMD_REQUEST_COMMAND:
 404                 {
 405                         if(argv(1) != "")
 406                         {
 407                                 if(self.flags & FL_CLIENT)
 408                                 {
 409                                         if(teamplay)
 410                                                 if not(self.team_forced > 0)
 411                                                         if not(lockteams)
 412                                                         {
 413                                                                 float selection;
 414
 415                                                                 switch(argv(1))
 416                                                                 {
 417                                                                         case "red": selection = NUM_TEAM_1; break;
 418                                                                         case "blue": selection = NUM_TEAM_2; break;
 419                                                                         case "yellow": selection = NUM_TEAM_3; break;
 420                                                                         case "pink": selection = NUM_TEAM_4; break;
 421                                                                         case "auto": selection = (-1); break;
 422
 423                                                                         default: selection = 0; break;
 424                                                                 }
 425
 426                                                                 if(selection)
 427                                                                 {
 428                                                                         if(self.team == selection && self.deadflag == DEAD_NO)
 429                                                                                 sprint(self, "^7You already are on that team.\n");
 430                                                                         else if(self.wasplayer && autocvar_g_changeteam_banned)
 431                                                                                 sprint(self, "^1You cannot change team, forbidden by the server.\n");
 432                                                                         else
 433                                                                                 ClientKill_TeamChange(selection);
 434                                                                 }
 435                                                         }
 436                                                         else
 437                                                                 sprint(self, "^7The game has already begun, you must wait until the next map to be able to join a team.\n");
 438                                                 else
 439                                                         sprint(self, "^7selectteam can not be used as your team is forced\n");
 440                                         else
 441                                                 sprint(self, "^7selectteam can only be used in teamgames\n");
 442                                 }
 443                                 return;
 444                         }
 445                 }
 446
 447                 default:
 448                         sprint(self, "Incorrect parameters for ^2selectteam^7\n");
 449                 case CMD_REQUEST_USAGE:
 450                 {
 451                         sprint(self, "\nUsage:^3 cmd selectteam team\n");
 452                         sprint(self, "  Where 'team' is the prefered team to try and join.\n");
 453                         sprint(self, "  Full list of options here: \"red, blue, yellow, pink, auto\"\n");
 454                         return;
 455                 }
 456         }
 457 }
 458
 459 void ClientCommand_selfstuff(float request, string command)
 460 {
 461         switch(request)
 462         {
 463                 case CMD_REQUEST_COMMAND:
 464                 {
 465                         if(argv(1) != "")
 466                         {
 467                                 stuffcmd(self, substring(command, argv_start_index(1), argv_end_index(-1) - argv_start_index(1)));
 468                                 return;
 469                         }
 470                 }
 471
 472                 default:
 473                         sprint(self, "Incorrect parameters for ^2selectteam^7\n");
 474                 case CMD_REQUEST_USAGE:
 475                 {
 476                         sprint(self, "\nUsage:^3 cmd selfstuff <command>\n");
 477                         sprint(self, "  Where 'command' is the string to be stuffed to your client.\n");
 478                         return;
 479                 }
 480         }
 481 }
 482
 483 void ClientCommand_sentcvar(float request, float argc, string command)
 484 {
 485         switch(request)
 486         {
 487                 case CMD_REQUEST_COMMAND:
 488                 {
 489                         if(argv(1) != "")
 490                         {
 491                                 //float tokens;
 492                                 string s;
 493
 494                                 if(argc == 2) // undefined cvar: use the default value on the server then
 495                                 {
 496                                         s = strcat(substring(command, argv_start_index(0), argv_end_index(1) - argv_start_index(0)), " \"", cvar_defstring(argv(1)), "\"");
 497                                         tokenize_console(s);
 498                                 }
 499
 500                                 GetCvars(1);
 501
 502                                 return;
 503                         }
 504                 }
 505
 506                 default:
 507                         sprint(self, "Incorrect parameters for ^2sentcvar^7\n");
 508                 case CMD_REQUEST_USAGE:
 509                 {
 510                         sprint(self, "\nUsage:^3 cmd sentcvar <cvar>\n");
 511                         sprint(self, "  Where 'cvar' is the cvar plus arguments to send to the server.\n");
 512                         return;
 513                 }
 514         }
 515 }
 516
 517 void ClientCommand_spectate(float request)
 518 {
 519         switch(request)
 520         {
 521                 case CMD_REQUEST_COMMAND:
 522                 {
 523                         if(self.flags & FL_CLIENT)
 524                         {
 525                                 if(g_arena) { return; }
 526                                 if(g_lms)
 527                                 {
 528                                         if(self.lms_spectate_warning)
 529                                         {
 530                                                 // for the forfeit message...
 531                                                 self.lms_spectate_warning = 2;
 532                                                 // mark player as spectator
 533                                                 PlayerScore_Add(self, SP_LMS_RANK, 666 - PlayerScore_Add(self, SP_LMS_RANK, 0));
 534                                         }
 535                                         else
 536                                         {
 537                                                 self.lms_spectate_warning = 1;
 538                                                 sprint(self, "WARNING: you won't be able to enter the game again after spectating in LMS. Use the same command again to spectate anyway.\n");
 539                                                 return;
 540                                         }
 541                                 }
 542
 543                                 if(self.classname == "player" && autocvar_sv_spectate == 1)
 544                                         ClientKill_TeamChange(-2); // observe
 545
 546                                 // in CA, allow a dead player to move to spectators (without that, caplayer!=0 will be moved back to the player list)
 547                                 // note: if arena game mode is ever done properly, this needs to be removed.
 548                                 if(g_ca && self.caplayer && (self.classname == "spectator" || self.classname == "observer"))
 549                                 {
 550                                         sprint(self, "WARNING: you will spectate in the next round.\n");
 551                                         self.caplayer = 0;
 552                                 }
 553                         }
 554                         return; // never fall through to usage
 555                 }
 556
 557                 default:
 558                 case CMD_REQUEST_USAGE:
 559                 {
 560                         sprint(self, "\nUsage:^3 cmd spectate\n");
 561                         sprint(self, "  No arguments required.\n");
 562                         return;
 563                 }
 564         }
 565 }
 566
 567 void ClientCommand_suggestmap(float request, float argc)
 568 {
 569         switch(request)
 570         {
 571                 case CMD_REQUEST_COMMAND:
 572                 {
 573                         if(argv(1) != "")
 574                         {
 575                                 sprint(self, strcat(MapVote_Suggest(argv(1)), "\n"));
 576                                 return;
 577                         }
 578                 }
 579
 580                 default:
 581                         sprint(self, "Incorrect parameters for ^2suggestmap^7\n");
 582                 case CMD_REQUEST_USAGE:
 583                 {
 584                         sprint(self, "\nUsage:^3 cmd suggestmap map\n");
 585                         sprint(self, "  Where 'map' is the name of the map to suggest.\n");
 586                         return;
 587                 }
 588         }
 589 }
 590
 591 void ClientCommand_tell(float request, float argc, string command)
 592 {
 593         switch(request)
 594         {
 595                 case CMD_REQUEST_COMMAND:
 596                 {
 597                         if(argc >= 3)
 598                         {
 599                                 entity tell_to = GetIndexedEntity(argc, 1);
 600                                 float tell_accepted = VerifyClientEntity(tell_to, TRUE, FALSE);
 601
 602                                 if(tell_accepted > 0) // the target is a real client
 603                                 {
 604                                         if(tell_to != self) // and we're allowed to send to them :D
 605                                         {
 606                                                 Say(self, FALSE, tell_to, substring(command, argv_start_index(next_token), argv_end_index(-1) - argv_start_index(next_token)), TRUE);
 607                                                 return;
 608                                         }
 609                                         else { print_to(self, "You can't ^2tell^7 a message to yourself."); return; }
 610                                 }
 611                                 else if(argv(1) == "#0")
 612                                 {
 613                                         trigger_magicear_processmessage_forallears(self, -1, world, substring(command, argv_start_index(next_token), argv_end_index(-1) - argv_start_index(next_token)));
 614                                         return;
 615                                 }
 616                                 else { print_to(self, strcat("tell: ", GetClientErrorString(tell_accepted, argv(1)), ".")); return; }
 617                         }
 618                 }
 619
 620                 default:
 621                         sprint(self, "Incorrect parameters for ^2tell^7\n");
 622                 case CMD_REQUEST_USAGE:
 623                 {
 624                         sprint(self, "\nUsage:^3 cmd tell client <message>\n");
 625                         sprint(self, "  Where 'client' is the entity number or name of the player to send 'message' to.\n");
 626                         return;
 627                 }
 628         }
 629 }
 630
 631 void ClientCommand_voice(float request, float argc, string command)
 632 {
 633         switch(request)
 634         {
 635                 case CMD_REQUEST_COMMAND:
 636                 {
 637                         if(argv(1) != "")
 638                         {
 639                                 if(argc >= 3)
 640                                         VoiceMessage(argv(1), substring(command, argv_start_index(2), argv_end_index(-1) - argv_start_index(2)));
 641                                 else
 642                                         VoiceMessage(argv(1), "");
 643
 644                                 return;
 645                         }
 646                 }
 647
 648                 default:
 649                         sprint(self, "Incorrect parameters for ^2voice^7\n");
 650                 case CMD_REQUEST_USAGE:
 651                 {
 652                         sprint(self, "\nUsage:^3 cmd voice messagetype <soundname>\n");
 653                         sprint(self, "  'messagetype' is the type of broadcast to do, like team only or such,\n");
 654                         sprint(self, "  and 'soundname' is the string/filename of the sound/voice message to play.\n");
 655                         return;
 656                 }
 657         }
 658 }
 659
 660 /* use this when creating a new command, making sure to place it in alphabetical order... also,
 661 ** ADD ALL NEW COMMANDS TO commands.cfg WITH PROPER ALIASES IN THE SAME FASHION!
 662 void ClientCommand_(float request)
 663 {
 664         switch(request)
 665         {
 666                 case CMD_REQUEST_COMMAND:
 667                 {
 668
 669                         return; // never fall through to usage
 670                 }
 671
 672                 default:
 673                 case CMD_REQUEST_USAGE:
 674                 {
 675                         sprint(self, "\nUsage:^3 cmd \n");
 676                         sprint(self, "  No arguments required.\n");
 677                         return;
 678                 }
 679         }
 680 }
 681 */
 682
 683
 684 // =====================================
 685 //  Macro system for networked commands
 686 // =====================================
 687
 688 // Do not hard code aliases for these, instead create them in commands.cfg... also: keep in alphabetical order, please ;)
 689 #define CLIENT_COMMANDS(request,arguments,command) \
 690         CLIENT_COMMAND("autoswitch", ClientCommand_autoswitch(request, arguments), "Whether or not to switch automatically when getting a better weapon") \
 691         CLIENT_COMMAND("checkfail", ClientCommand_checkfail(request, command), "Report if a client-side check failed") \
 692         CLIENT_COMMAND("clientversion", ClientCommand_clientversion(request, arguments), "Release version of the game") \
 693         CLIENT_COMMAND("mv_getpicture", ClientCommand_mv_getpicture(request, arguments), "Retrieve mapshot picture from the server") \
 694         CLIENT_COMMAND("join", ClientCommand_join(request), "Become a player in the game") \
 695         CLIENT_COMMAND("mobedit", ClientCommand_mobedit(request, arguments), "Edit your monster's properties") \
 696         CLIENT_COMMAND("mobkill", ClientCommand_mobkill(request), "Kills your monster") \
 697         CLIENT_COMMAND("mobspawn", ClientCommand_mobspawn(request, arguments), "Spawn monsters infront of yourself") \
 698         CLIENT_COMMAND("ready", ClientCommand_ready(request), "Qualify as ready to end warmup stage (or restart server if allowed)") \
 699         CLIENT_COMMAND("say", ClientCommand_say(request, arguments, command), "Print a message to chat to all players") \
 700         CLIENT_COMMAND("say_team", ClientCommand_say_team(request, arguments, command), "Print a message to chat to all team mates") \
 701         CLIENT_COMMAND("selectteam", ClientCommand_selectteam(request, arguments), "Attempt to choose a team to join into") \
 702         CLIENT_COMMAND("selfstuff", ClientCommand_selfstuff(request, command), "Stuffcmd a command to your own client") \
 703         CLIENT_COMMAND("sentcvar", ClientCommand_sentcvar(request, arguments, command), "New system for sending a client cvar to the server") \
 704         CLIENT_COMMAND("spectate", ClientCommand_spectate(request), "Become an observer") \
 705         CLIENT_COMMAND("suggestmap", ClientCommand_suggestmap(request, arguments), "Suggest a map to the mapvote at match end") \
 706         CLIENT_COMMAND("tell", ClientCommand_tell(request, arguments, command), "Send a message directly to a player") \
 707         CLIENT_COMMAND("voice", ClientCommand_voice(request, arguments, command), "Send voice message via sound") \
 708         /* nothing */
 709
 710 void ClientCommand_macro_help()
 711 {
 712         #define CLIENT_COMMAND(name,function,description) \
 713                 { sprint(self, "  ^2", name, "^7: ", description, "\n"); }
 714
 715         CLIENT_COMMANDS(0, 0, "")
 716         #undef CLIENT_COMMAND
 717
 718         return;
 719 }
 720
 721 float ClientCommand_macro_command(float argc, string command)
 722 {
 723         #define CLIENT_COMMAND(name,function,description) \
 724                 { if(name == strtolower(argv(0))) { function; return TRUE; } }
 725
 726         CLIENT_COMMANDS(CMD_REQUEST_COMMAND, argc, command)
 727         #undef CLIENT_COMMAND
 728
 729         return FALSE;
 730 }
 731
 732 float ClientCommand_macro_usage(float argc)
 733 {
 734         #define CLIENT_COMMAND(name,function,description) \
 735                 { if(name == strtolower(argv(1))) { function; return TRUE; } }
 736
 737         CLIENT_COMMANDS(CMD_REQUEST_USAGE, argc, "")
 738         #undef CLIENT_COMMAND
 739
 740         return FALSE;
 741 }
 742
 743 void ClientCommand_macro_write_aliases(float fh)
 744 {
 745         #define CLIENT_COMMAND(name,function,description) \
 746                 { CMD_Write_Alias("qc_cmd_cmd", name, description); }
 747
 748         CLIENT_COMMANDS(0, 0, "")
 749         #undef CLIENT_COMMAND
 750
 751         return;
 752 }
 753
 754 // ======================================
 755 //  Main Function Called By Engine (cmd)
 756 // ======================================
 757 // If this function exists, server game code parses clientcommand before the engine code gets it.
 758
 759 void SV_ParseClientCommand(string command)
 760 {
 761         // if we're banned, don't even parse the command
 762         if(Ban_MaybeEnforceBanOnce(self))
 763                 return;
 764
 765         float argc = tokenize_console(command);
 766
 767         // for the mutator hook system
 768         cmd_name = strtolower(argv(0));
 769         cmd_argc = argc;
 770         cmd_string = command;
 771
 772         // Guide for working with argc arguments by example:
 773         // argc:   1    - 2      - 3     - 4
 774         // argv:   0    - 1      - 2     - 3
 775         // cmd     vote - master - login - password
 776
 777         // for floodcheck
 778         switch(strtolower(argv(0)))
 779         {
 780                 // exempt commands which are not subject to floodcheck
 781                 case "begin": break; // handled by engine in host_cmd.c
 782                 case "download": break; // handled by engine in cl_parse.c
 783                 case "mv_getpicture": break; // handled by server in this file
 784                 case "pause": break; // handled by engine in host_cmd.c
 785                 case "prespawn": break; // handled by engine in host_cmd.c
 786                 case "sentcvar": break; // handled by server in this file
 787                 case "spawn": break; // handled by engine in host_cmd.c
 788
 789                 default:
 790                         if(SV_ParseClientCommand_floodcheck())
 791                                 break; // "TRUE": continue, as we're not flooding yet
 792                         else
 793                                 return; // "FALSE": not allowed to continue, halt // print("^1ERROR: ^7ANTISPAM CAUGHT: ", command, ".\n");
 794         }
 795
 796         /* NOTE: should this be disabled? It can be spammy perhaps, but hopefully it's okay for now */
 797         if(argv(0) == "help")
 798         {
 799                 if(argc == 1)
 800                 {
 801                         sprint(self, "\nClient networked commands:\n");
 802                         ClientCommand_macro_help();
 803
 804                         sprint(self, "\nCommon networked commands:\n");
 805                         CommonCommand_macro_help(self);
 806
 807                         sprint(self, "\nUsage:^3 cmd COMMAND...^7, where possible commands are listed above.\n");
 808                         sprint(self, "For help about a specific command, type cmd help COMMAND\n");
 809                         return;
 810                 }
 811                 else if(CommonCommand_macro_usage(argc, self)) // Instead of trying to call a command, we're going to see detailed information about it
 812                 {
 813                         return;
 814                 }
 815                 else if(ClientCommand_macro_usage(argc)) // same, but for normal commands now
 816                 {
 817                         return;
 818                 }
 819         }
 820         else if(MUTATOR_CALLHOOK(SV_ParseClientCommand))
 821         {
 822                 return; // handled by a mutator
 823         }
 824         else if(CheatCommand(argc))
 825         {
 826                 return; // handled by server/cheats.qc
 827         }
 828         else if(CommonCommand_macro_command(argc, self, command))
 829         {
 830                 return; // handled by server/command/common.qc
 831         }
 832         else if(ClientCommand_macro_command(argc, command)) // continue as usual and scan for normal commands
 833         {
 834                 return; // handled by one of the above ClientCommand_* functions
 835         }
 836         else
 837                 clientcommand(self, command);
 838 }