qcsrc/server/command/cmd.qc

   1 // =========================================================
   2 //  Server side networked commands code, reworked by Samual
   3 //  Last updated: December 28th, 2011
   4 // =========================================================
   5
   6 float SV_ParseClientCommand_floodcheck()
   7 {
   8         if not(timeout_status) // not while paused
   9         {
  10                 if(time <= (self.cmd_floodtime + autocvar_sv_clientcommand_antispam_time))
  11                 {
  12                         self.cmd_floodcount += 1;
  13                         if(self.cmd_floodcount > autocvar_sv_clientcommand_antispam_count) { return FALSE; } // too much spam, halt
  14                 }
  15                 else
  16                 {
  17                         self.cmd_floodtime = time;
  18                         self.cmd_floodcount = 1;
  19                 }
  20         }
  21         return TRUE; // continue, as we're not flooding yet
  22 }
  23
  24
  25 // =======================
  26 //  Command Sub-Functions
  27 // =======================
  28
  29 void ClientCommand_autoswitch(float request, float argc)
  30 {
  31         switch(request)
  32         {
  33                 case CMD_REQUEST_COMMAND:
  34                 {
  35                         if(argv(1) != "")
  36                         {
  37                                 self.autoswitch = InterpretBoolean(argv(1));
  38                                 sprint(self, strcat("^1autoswitch is currently turned ", (self.autoswitch ? "on" : "off"), ".\n"));
  39                                 return;
  40                         }
  41                 }
  42
  43                 default:
  44                         sprint(self, "Incorrect parameters for ^2autoswitch^7\n");
  45                 case CMD_REQUEST_USAGE:
  46                 {
  47                         sprint(self, "\nUsage:^3 cmd autoswitch selection\n");
  48                         sprint(self, "  Where 'selection' controls if autoswitch is on or off.\n");
  49                         return;
  50                 }
  51         }
  52 }
  53
  54 void ClientCommand_checkfail(float request, string command) // internal command, used only by code
  55 {
  56         switch(request)
  57         {
  58                 case CMD_REQUEST_COMMAND:
  59                 {
  60                         print(sprintf("CHECKFAIL: %s (%s) epically failed check %s\n", self.netname, self.netaddress, substring(command, argv_start_index(1), argv_end_index(-1) - argv_start_index(1))));
  61                         self.checkfail = 1;
  62                         return; // never fall through to usage
  63                 }
  64
  65                 default:
  66                         sprint(self, "Incorrect parameters for ^2checkfail^7\n");
  67                 case CMD_REQUEST_USAGE:
  68                 {
  69                         sprint(self, "\nUsage:^3 cmd checkfail <message>\n");
  70                         sprint(self, "  Where 'message' is the message reported by client about the fail.\n");
  71                         return;
  72                 }
  73         }
  74 }
  75
  76 void ClientCommand_clientversion(float request, float argc) // internal command, used only by code
  77 {
  78         switch(request)
  79         {
  80                 case CMD_REQUEST_COMMAND:
  81                 {
  82                         if(argv(1) != "")
  83                         {
  84                                 if(IS_CLIENT(self))
  85                                 {
  86                                         self.version = ((argv(1) == "$gameversion") ? 1 : stof(argv(1)));
  87
  88                                         if(self.version < autocvar_gameversion_min || self.version > autocvar_gameversion_max)
  89                                         {
  90                                                 self.version_mismatch = 1;
  91                                                 ClientKill_TeamChange(-2); // observe
  92                                         }
  93                                         else if(autocvar_g_campaign || autocvar_g_balance_teams)
  94                                         {
  95                                                 //JoinBestTeam(self, FALSE, TRUE);
  96                                         }
  97                                         else if(teamplay && !autocvar_sv_spectate && !(self.team_forced > 0))
  98                                         {
  99                                                 self.classname = "observer"; // really?
 100                                                 stuffcmd(self, "menu_showteamselect\n");
 101                                         }
 102                                 }
 103
 104                                 return;
 105                         }
 106                 }
 107
 108                 default:
 109                         sprint(self, "Incorrect parameters for ^2clientversion^7\n");
 110                 case CMD_REQUEST_USAGE:
 111                 {
 112                         sprint(self, "\nUsage:^3 cmd clientversion version\n");
 113                         sprint(self, "  Where 'version' is the game version reported by self.\n");
 114                         return;
 115                 }
 116         }
 117 }
 118
 119 void ClientCommand_mv_getpicture(float request, float argc) // internal command, used only by code
 120 {
 121         switch(request)
 122         {
 123                 case CMD_REQUEST_COMMAND:
 124                 {
 125                         if(argv(1) != "")
 126                         {
 127                                 if(intermission_running)
 128                                         MapVote_SendPicture(stof(argv(1)));
 129
 130                                 return;
 131                         }
 132                 }
 133
 134                 default:
 135                         sprint(self, "Incorrect parameters for ^2mv_getpicture^7\n");
 136                 case CMD_REQUEST_USAGE:
 137                 {
 138                         sprint(self, "\nUsage:^3 cmd mv_getpicture mapid\n");
 139                         sprint(self, "  Where 'mapid' is the id number of the map to request an image of on the map vote selection menu.\n");
 140                         return;
 141                 }
 142         }
 143 }
 144
 145 void ClientCommand_join(float request)
 146 {
 147         switch(request)
 148         {
 149                 case CMD_REQUEST_COMMAND:
 150                 {
 151                         if(IS_CLIENT(self))
 152                         {
 153                                 if(!IS_PLAYER(self) && !lockteams && !g_arena)
 154                                 {
 155                                         if(nJoinAllowed(self))
 156                                         {
 157                                                 if(autocvar_g_campaign) { campaign_bots_may_start = 1; }
 158
 159                                                 self.classname = "player";
 160                                                 PlayerScore_Clear(self);
 161                                                 Kill_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER_CPID, CPID_PREVENT_JOIN);
 162                                                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_JOIN_PLAY, self.netname);
 163                                                 PutClientInServer();
 164                                         }
 165                                         else
 166                                         {
 167                                                 //player may not join because of g_maxplayers is set
 168                                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_JOIN_PREVENT);
 169                                         }
 170                                 }
 171                         }
 172                         return; // never fall through to usage
 173                 }
 174
 175                 default:
 176                 case CMD_REQUEST_USAGE:
 177                 {
 178                         sprint(self, "\nUsage:^3 cmd join\n");
 179                         sprint(self, "  No arguments required.\n");
 180                         return;
 181                 }
 182         }
 183 }
 184
 185 void ClientCommand_ready(float request) // todo: anti-spam for toggling readyness
 186 {
 187         switch(request)
 188         {
 189                 case CMD_REQUEST_COMMAND:
 190                 {
 191                         if(IS_CLIENT(self))
 192                         {
 193                                 if(warmup_stage || autocvar_sv_ready_restart || g_race_qualifying == 2)
 194                                 {
 195                                         if(!readyrestart_happened || autocvar_sv_ready_restart_repeatable)
 196                                         {
 197                                                 if(time < game_starttime) // game is already restarting
 198                                                         return;
 199                                                 if (self.ready) // toggle
 200                                                 {
 201                                                         self.ready = FALSE;
 202                                                         bprint(self.netname, "^2 is ^1NOT^2 ready\n");
 203                                                 }
 204                                                 else
 205                                                 {
 206                                                         self.ready = TRUE;
 207                                                         bprint(self.netname, "^2 is ready\n");
 208                                                 }
 209
 210                                                 // cannot reset the game while a timeout is active!
 211                                                 if not(timeout_status)
 212                                                         ReadyCount();
 213                                         } else {
 214                                                 sprint(self, "^1Game has already been restarted\n");
 215                                         }
 216                                 }
 217                         }
 218                         return; // never fall through to usage
 219                 }
 220
 221                 default:
 222                 case CMD_REQUEST_USAGE:
 223                 {
 224                         sprint(self, "\nUsage:^3 cmd ready\n");
 225                         sprint(self, "  No arguments required.\n");
 226                         return;
 227                 }
 228         }
 229 }
 230
 231 void ClientCommand_say(float request, float argc, string command)
 232 {
 233         switch(request)
 234         {
 235                 case CMD_REQUEST_COMMAND:
 236                 {
 237                         if(argc >= 2) { Say(self, FALSE, world, substring(command, argv_start_index(1), argv_end_index(-1) - argv_start_index(1)), 1); }
 238                         return; // never fall through to usage
 239                 }
 240
 241                 default:
 242                 case CMD_REQUEST_USAGE:
 243                 {
 244                         sprint(self, "\nUsage:^3 cmd say <message>\n");
 245                         sprint(self, "  Where 'message' is the string of text to say.\n");
 246                         return;
 247                 }
 248         }
 249 }
 250
 251 void ClientCommand_say_team(float request, float argc, string command)
 252 {
 253         switch(request)
 254         {
 255                 case CMD_REQUEST_COMMAND:
 256                 {
 257                         if(argc >= 2) { Say(self, TRUE, world, substring(command, argv_start_index(1), argv_end_index(-1) - argv_start_index(1)), 1); }
 258                         return; // never fall through to usage
 259                 }
 260
 261                 default:
 262                 case CMD_REQUEST_USAGE:
 263                 {
 264                         sprint(self, "\nUsage:^3 cmd say_team <message>\n");
 265                         sprint(self, "  Where 'message' is the string of text to say.\n");
 266                         return;
 267                 }
 268         }
 269 }
 270
 271 void ClientCommand_selectteam(float request, float argc)
 272 {
 273         switch(request)
 274         {
 275                 case CMD_REQUEST_COMMAND:
 276                 {
 277                         if(argv(1) != "")
 278                         {
 279                                 if(IS_CLIENT(self))
 280                                 {
 281                                         if(teamplay)
 282                                                 if not(self.team_forced > 0)
 283                                                         if not(lockteams)
 284                                                         {
 285                                                                 float selection;
 286
 287                                                                 switch(argv(1))
 288                                                                 {
 289                                                                         case "red": selection = NUM_TEAM_1; break;
 290                                                                         case "blue": selection = NUM_TEAM_2; break;
 291                                                                         case "yellow": selection = NUM_TEAM_3; break;
 292                                                                         case "pink": selection = NUM_TEAM_4; break;
 293                                                                         case "auto": selection = (-1); break;
 294
 295                                                                         default: selection = 0; break;
 296                                                                 }
 297
 298                                                                 if(selection)
 299                                                                 {
 300                                                                         if(self.team == selection && self.deadflag == DEAD_NO)
 301                                                                                 sprint(self, "^7You already are on that team.\n");
 302                                                                         else if(self.wasplayer && autocvar_g_changeteam_banned)
 303                                                                                 sprint(self, "^1You cannot change team, forbidden by the server.\n");
 304                                                                         else
 305                                                                                 ClientKill_TeamChange(selection);
 306                                                                 }
 307                                                         }
 308                                                         else
 309                                                                 sprint(self, "^7The game has already begun, you must wait until the next map to be able to join a team.\n");
 310                                                 else
 311                                                         sprint(self, "^7selectteam can not be used as your team is forced\n");
 312                                         else
 313                                                 sprint(self, "^7selectteam can only be used in teamgames\n");
 314                                 }
 315                                 return;
 316                         }
 317                 }
 318
 319                 default:
 320                         sprint(self, "Incorrect parameters for ^2selectteam^7\n");
 321                 case CMD_REQUEST_USAGE:
 322                 {
 323                         sprint(self, "\nUsage:^3 cmd selectteam team\n");
 324                         sprint(self, "  Where 'team' is the prefered team to try and join.\n");
 325                         sprint(self, "  Full list of options here: \"red, blue, yellow, pink, auto\"\n");
 326                         return;
 327                 }
 328         }
 329 }
 330
 331 void ClientCommand_selfstuff(float request, string command)
 332 {
 333         switch(request)
 334         {
 335                 case CMD_REQUEST_COMMAND:
 336                 {
 337                         if(argv(1) != "")
 338                         {
 339                                 stuffcmd(self, substring(command, argv_start_index(1), argv_end_index(-1) - argv_start_index(1)));
 340                                 return;
 341                         }
 342                 }
 343
 344                 default:
 345                         sprint(self, "Incorrect parameters for ^2selectteam^7\n");
 346                 case CMD_REQUEST_USAGE:
 347                 {
 348                         sprint(self, "\nUsage:^3 cmd selfstuff <command>\n");
 349                         sprint(self, "  Where 'command' is the string to be stuffed to your client.\n");
 350                         return;
 351                 }
 352         }
 353 }
 354
 355 void ClientCommand_sentcvar(float request, float argc, string command)
 356 {
 357         switch(request)
 358         {
 359                 case CMD_REQUEST_COMMAND:
 360                 {
 361                         if(argv(1) != "")
 362                         {
 363                                 //float tokens;
 364                                 string s;
 365
 366                                 if(argc == 2) // undefined cvar: use the default value on the server then
 367                                 {
 368                                         s = strcat(substring(command, argv_start_index(0), argv_end_index(1) - argv_start_index(0)), " \"", cvar_defstring(argv(1)), "\"");
 369                                         tokenize_console(s);
 370                                 }
 371
 372                                 GetCvars(1);
 373
 374                                 return;
 375                         }
 376                 }
 377
 378                 default:
 379                         sprint(self, "Incorrect parameters for ^2sentcvar^7\n");
 380                 case CMD_REQUEST_USAGE:
 381                 {
 382                         sprint(self, "\nUsage:^3 cmd sentcvar <cvar>\n");
 383                         sprint(self, "  Where 'cvar' is the cvar plus arguments to send to the server.\n");
 384                         return;
 385                 }
 386         }
 387 }
 388
 389 void ClientCommand_spectate(float request)
 390 {
 391         switch(request)
 392         {
 393                 case CMD_REQUEST_COMMAND:
 394                 {
 395                         if(IS_CLIENT(self))
 396                         {
 397                                 if(g_arena) { return; }
 398                                 if(g_lms)
 399                                 {
 400                                         if(self.lms_spectate_warning)
 401                                         {
 402                                                 // for the forfeit message...
 403                                                 self.lms_spectate_warning = 2;
 404                                                 // mark player as spectator
 405                                                 PlayerScore_Add(self, SP_LMS_RANK, 666 - PlayerScore_Add(self, SP_LMS_RANK, 0));
 406                                         }
 407                                         else
 408                                         {
 409                                                 self.lms_spectate_warning = 1;
 410                                                 sprint(self, "WARNING: you won't be able to enter the game again after spectating in LMS. Use the same command again to spectate anyway.\n");
 411                                                 return;
 412                                         }
 413                                 }
 414
 415                                 if(IS_PLAYER(self) && autocvar_sv_spectate == 1)
 416                                         ClientKill_TeamChange(-2); // observe
 417
 418                                 // in CA, allow a dead player to move to spectators (without that, caplayer!=0 will be moved back to the player list)
 419                                 // note: if arena game mode is ever done properly, this needs to be removed.
 420                                 if(self.caplayer && (IS_SPEC(self) || IS_OBSERVER(self)))
 421                                 {
 422                                         sprint(self, "WARNING: you will spectate in the next round.\n");
 423                                         self.caplayer = 0;
 424                                 }
 425                         }
 426                         return; // never fall through to usage
 427                 }
 428
 429                 default:
 430                 case CMD_REQUEST_USAGE:
 431                 {
 432                         sprint(self, "\nUsage:^3 cmd spectate\n");
 433                         sprint(self, "  No arguments required.\n");
 434                         return;
 435                 }
 436         }
 437 }
 438
 439 void ClientCommand_suggestmap(float request, float argc)
 440 {
 441         switch(request)
 442         {
 443                 case CMD_REQUEST_COMMAND:
 444                 {
 445                         if(argv(1) != "")
 446                         {
 447                                 sprint(self, strcat(MapVote_Suggest(argv(1)), "\n"));
 448                                 return;
 449                         }
 450                 }
 451
 452                 default:
 453                         sprint(self, "Incorrect parameters for ^2suggestmap^7\n");
 454                 case CMD_REQUEST_USAGE:
 455                 {
 456                         sprint(self, "\nUsage:^3 cmd suggestmap map\n");
 457                         sprint(self, "  Where 'map' is the name of the map to suggest.\n");
 458                         return;
 459                 }
 460         }
 461 }
 462
 463 void ClientCommand_tell(float request, float argc, string command)
 464 {
 465         switch(request)
 466         {
 467                 case CMD_REQUEST_COMMAND:
 468                 {
 469                         if(argc >= 3)
 470                         {
 471                                 entity tell_to = GetIndexedEntity(argc, 1);
 472                                 float tell_accepted = VerifyClientEntity(tell_to, TRUE, FALSE);
 473
 474                                 if(tell_accepted > 0) // the target is a real client
 475                                 {
 476                                         if(tell_to != self) // and we're allowed to send to them :D
 477                                         {
 478                                                 Say(self, FALSE, tell_to, substring(command, argv_start_index(next_token), argv_end_index(-1) - argv_start_index(next_token)), TRUE);
 479                                                 return;
 480                                         }
 481                                         else { print_to(self, "You can't ^2tell^7 a message to yourself."); return; }
 482                                 }
 483                                 else if(argv(1) == "#0")
 484                                 {
 485                                         trigger_magicear_processmessage_forallears(self, -1, world, substring(command, argv_start_index(next_token), argv_end_index(-1) - argv_start_index(next_token)));
 486                                         return;
 487                                 }
 488                                 else { print_to(self, strcat("tell: ", GetClientErrorString(tell_accepted, argv(1)), ".")); return; }
 489                         }
 490                 }
 491
 492                 default:
 493                         sprint(self, "Incorrect parameters for ^2tell^7\n");
 494                 case CMD_REQUEST_USAGE:
 495                 {
 496                         sprint(self, "\nUsage:^3 cmd tell client <message>\n");
 497                         sprint(self, "  Where 'client' is the entity number or name of the player to send 'message' to.\n");
 498                         return;
 499                 }
 500         }
 501 }
 502
 503 void ClientCommand_voice(float request, float argc, string command)
 504 {
 505         switch(request)
 506         {
 507                 case CMD_REQUEST_COMMAND:
 508                 {
 509                         if(argv(1) != "")
 510                         {
 511                                 if(argc >= 3)
 512                                         VoiceMessage(argv(1), substring(command, argv_start_index(2), argv_end_index(-1) - argv_start_index(2)));
 513                                 else
 514                                         VoiceMessage(argv(1), "");
 515
 516                                 return;
 517                         }
 518                 }
 519
 520                 default:
 521                         sprint(self, "Incorrect parameters for ^2voice^7\n");
 522                 case CMD_REQUEST_USAGE:
 523                 {
 524                         sprint(self, "\nUsage:^3 cmd voice messagetype <soundname>\n");
 525                         sprint(self, "  'messagetype' is the type of broadcast to do, like team only or such,\n");
 526                         sprint(self, "  and 'soundname' is the string/filename of the sound/voice message to play.\n");
 527                         return;
 528                 }
 529         }
 530 }
 531
 532 /* use this when creating a new command, making sure to place it in alphabetical order... also,
 533 ** ADD ALL NEW COMMANDS TO commands.cfg WITH PROPER ALIASES IN THE SAME FASHION!
 534 void ClientCommand_(float request)
 535 {
 536         switch(request)
 537         {
 538                 case CMD_REQUEST_COMMAND:
 539                 {
 540
 541                         return; // never fall through to usage
 542                 }
 543
 544                 default:
 545                 case CMD_REQUEST_USAGE:
 546                 {
 547                         sprint(self, "\nUsage:^3 cmd \n");
 548                         sprint(self, "  No arguments required.\n");
 549                         return;
 550                 }
 551         }
 552 }
 553 */
 554
 555
 556 // =====================================
 557 //  Macro system for networked commands
 558 // =====================================
 559
 560 // Do not hard code aliases for these, instead create them in commands.cfg... also: keep in alphabetical order, please ;)
 561 #define CLIENT_COMMANDS(request,arguments,command) \
 562         CLIENT_COMMAND("autoswitch", ClientCommand_autoswitch(request, arguments), "Whether or not to switch automatically when getting a better weapon") \
 563         CLIENT_COMMAND("checkfail", ClientCommand_checkfail(request, command), "Report if a client-side check failed") \
 564         CLIENT_COMMAND("clientversion", ClientCommand_clientversion(request, arguments), "Release version of the game") \
 565         CLIENT_COMMAND("mv_getpicture", ClientCommand_mv_getpicture(request, arguments), "Retrieve mapshot picture from the server") \
 566         CLIENT_COMMAND("join", ClientCommand_join(request), "Become a player in the game") \
 567         CLIENT_COMMAND("ready", ClientCommand_ready(request), "Qualify as ready to end warmup stage (or restart server if allowed)") \
 568         CLIENT_COMMAND("say", ClientCommand_say(request, arguments, command), "Print a message to chat to all players") \
 569         CLIENT_COMMAND("say_team", ClientCommand_say_team(request, arguments, command), "Print a message to chat to all team mates") \
 570         CLIENT_COMMAND("selectteam", ClientCommand_selectteam(request, arguments), "Attempt to choose a team to join into") \
 571         CLIENT_COMMAND("selfstuff", ClientCommand_selfstuff(request, command), "Stuffcmd a command to your own client") \
 572         CLIENT_COMMAND("sentcvar", ClientCommand_sentcvar(request, arguments, command), "New system for sending a client cvar to the server") \
 573         CLIENT_COMMAND("spectate", ClientCommand_spectate(request), "Become an observer") \
 574         CLIENT_COMMAND("suggestmap", ClientCommand_suggestmap(request, arguments), "Suggest a map to the mapvote at match end") \
 575         CLIENT_COMMAND("tell", ClientCommand_tell(request, arguments, command), "Send a message directly to a player") \
 576         CLIENT_COMMAND("voice", ClientCommand_voice(request, arguments, command), "Send voice message via sound") \
 577         /* nothing */
 578
 579 void ClientCommand_macro_help()
 580 {
 581         #define CLIENT_COMMAND(name,function,description) \
 582                 { sprint(self, "  ^2", name, "^7: ", description, "\n"); }
 583
 584         CLIENT_COMMANDS(0, 0, "")
 585         #undef CLIENT_COMMAND
 586
 587         return;
 588 }
 589
 590 float ClientCommand_macro_command(float argc, string command)
 591 {
 592         #define CLIENT_COMMAND(name,function,description) \
 593                 { if(name == strtolower(argv(0))) { function; return TRUE; } }
 594
 595         CLIENT_COMMANDS(CMD_REQUEST_COMMAND, argc, command)
 596         #undef CLIENT_COMMAND
 597
 598         return FALSE;
 599 }
 600
 601 float ClientCommand_macro_usage(float argc)
 602 {
 603         #define CLIENT_COMMAND(name,function,description) \
 604                 { if(name == strtolower(argv(1))) { function; return TRUE; } }
 605
 606         CLIENT_COMMANDS(CMD_REQUEST_USAGE, argc, "")
 607         #undef CLIENT_COMMAND
 608
 609         return FALSE;
 610 }
 611
 612 void ClientCommand_macro_write_aliases(float fh)
 613 {
 614         #define CLIENT_COMMAND(name,function,description) \
 615                 { CMD_Write_Alias("qc_cmd_cmd", name, description); }
 616
 617         CLIENT_COMMANDS(0, 0, "")
 618         #undef CLIENT_COMMAND
 619
 620         return;
 621 }
 622
 623 // ======================================
 624 //  Main Function Called By Engine (cmd)
 625 // ======================================
 626 // If this function exists, server game code parses clientcommand before the engine code gets it.
 627
 628 void SV_ParseClientCommand(string command)
 629 {
 630         // if we're banned, don't even parse the command
 631         if(Ban_MaybeEnforceBanOnce(self))
 632                 return;
 633
 634         float argc = tokenize_console(command);
 635
 636         // for the mutator hook system
 637         cmd_name = strtolower(argv(0));
 638         cmd_argc = argc;
 639         cmd_string = command;
 640
 641         // Guide for working with argc arguments by example:
 642         // argc:   1    - 2      - 3     - 4
 643         // argv:   0    - 1      - 2     - 3
 644         // cmd     vote - master - login - password
 645
 646         // for floodcheck
 647         switch(strtolower(argv(0)))
 648         {
 649                 // exempt commands which are not subject to floodcheck
 650                 case "begin": break; // handled by engine in host_cmd.c
 651                 case "download": break; // handled by engine in cl_parse.c
 652                 case "mv_getpicture": break; // handled by server in this file
 653                 case "pause": break; // handled by engine in host_cmd.c
 654                 case "prespawn": break; // handled by engine in host_cmd.c
 655                 case "sentcvar": break; // handled by server in this file
 656                 case "spawn": break; // handled by engine in host_cmd.c
 657
 658                 default:
 659                         if(SV_ParseClientCommand_floodcheck())
 660                                 break; // "TRUE": continue, as we're not flooding yet
 661                         else
 662                                 return; // "FALSE": not allowed to continue, halt // print("^1ERROR: ^7ANTISPAM CAUGHT: ", command, ".\n");
 663         }
 664
 665         /* NOTE: should this be disabled? It can be spammy perhaps, but hopefully it's okay for now */
 666         if(argv(0) == "help")
 667         {
 668                 if(argc == 1)
 669                 {
 670                         sprint(self, "\nClient networked commands:\n");
 671                         ClientCommand_macro_help();
 672
 673                         sprint(self, "\nCommon networked commands:\n");
 674                         CommonCommand_macro_help(self);
 675
 676                         sprint(self, "\nUsage:^3 cmd COMMAND...^7, where possible commands are listed above.\n");
 677                         sprint(self, "For help about a specific command, type cmd help COMMAND\n");
 678                         return;
 679                 }
 680                 else if(CommonCommand_macro_usage(argc, self)) // Instead of trying to call a command, we're going to see detailed information about it
 681                 {
 682                         return;
 683                 }
 684                 else if(ClientCommand_macro_usage(argc)) // same, but for normal commands now
 685                 {
 686                         return;
 687                 }
 688         }
 689         else if(MUTATOR_CALLHOOK(SV_ParseClientCommand))
 690         {
 691                 return; // handled by a mutator
 692         }
 693         else if(CheatCommand(argc))
 694         {
 695                 return; // handled by server/cheats.qc
 696         }
 697         else if(CommonCommand_macro_command(argc, self, command))
 698         {
 699                 return; // handled by server/command/common.qc
 700         }
 701         else if(ClientCommand_macro_command(argc, command)) // continue as usual and scan for normal commands
 702         {
 703                 return; // handled by one of the above ClientCommand_* functions
 704         }
 705         else
 706                 clientcommand(self, command);
 707 }