qcsrc/server/command/cmd.qc

   1 // =========================================================
   2 //  Server side networked commands code, reworked by Samual
   3 //  Last updated: December 28th, 2011
   4 // =========================================================
   5
   6 float SV_ParseClientCommand_floodcheck()
   7 {
   8         if (!timeout_status) // not while paused
   9         {
  10                 if(time <= (self.cmd_floodtime + autocvar_sv_clientcommand_antispam_time))
  11                 {
  12                         self.cmd_floodcount += 1;
  13                         if(self.cmd_floodcount > autocvar_sv_clientcommand_antispam_count) { return FALSE; } // too much spam, halt
  14                 }
  15                 else
  16                 {
  17                         self.cmd_floodtime = time;
  18                         self.cmd_floodcount = 1;
  19                 }
  20         }
  21         return TRUE; // continue, as we're not flooding yet
  22 }
  23
  24
  25 // =======================
  26 //  Command Sub-Functions
  27 // =======================
  28
  29 void ClientCommand_autoswitch(float request, float argc)
  30 {
  31         switch(request)
  32         {
  33                 case CMD_REQUEST_COMMAND:
  34                 {
  35                         if(argv(1) != "")
  36                         {
  37                                 self.autoswitch = InterpretBoolean(argv(1));
  38                                 sprint(self, strcat("^1autoswitch is currently turned ", (self.autoswitch ? "on" : "off"), ".\n"));
  39                                 return;
  40                         }
  41                 }
  42
  43                 default:
  44                         sprint(self, "Incorrect parameters for ^2autoswitch^7\n");
  45                 case CMD_REQUEST_USAGE:
  46                 {
  47                         sprint(self, "\nUsage:^3 cmd autoswitch selection\n");
  48                         sprint(self, "  Where 'selection' controls if autoswitch is on or off.\n");
  49                         return;
  50                 }
  51         }
  52 }
  53
  54 void ClientCommand_checkfail(float request, string command) // internal command, used only by code
  55 {
  56         switch(request)
  57         {
  58                 case CMD_REQUEST_COMMAND:
  59                 {
  60                         printf("CHECKFAIL: %s (%s) epically failed check %s\n", self.netname, self.netaddress, substring(command, argv_start_index(1), argv_end_index(-1) - argv_start_index(1)));
  61                         self.checkfail = 1;
  62                         return; // never fall through to usage
  63                 }
  64
  65                 default:
  66                         sprint(self, "Incorrect parameters for ^2checkfail^7\n");
  67                 case CMD_REQUEST_USAGE:
  68                 {
  69                         sprint(self, "\nUsage:^3 cmd checkfail <message>\n");
  70                         sprint(self, "  Where 'message' is the message reported by client about the fail.\n");
  71                         return;
  72                 }
  73         }
  74 }
  75
  76 void ClientCommand_clientversion(float request, float argc) // internal command, used only by code
  77 {
  78         switch(request)
  79         {
  80                 case CMD_REQUEST_COMMAND:
  81                 {
  82                         if(argv(1) != "")
  83                         {
  84                                 if(IS_CLIENT(self))
  85                                 {
  86                                         self.version = ((argv(1) == "$gameversion") ? 1 : stof(argv(1)));
  87
  88                                         if(self.version < autocvar_gameversion_min || self.version > autocvar_gameversion_max)
  89                                         {
  90                                                 self.version_mismatch = 1;
  91                                                 ClientKill_TeamChange(-2); // observe
  92                                         }
  93                                         else if(autocvar_g_campaign || autocvar_g_balance_teams)
  94                                         {
  95                                                 //JoinBestTeam(self, FALSE, TRUE);
  96                                         }
  97                                         else if(teamplay && !autocvar_sv_spectate && !(self.team_forced > 0))
  98                                         {
  99                                                 self.classname = "observer"; // really?
 100                                                 stuffcmd(self, "menu_showteamselect\n");
 101                                         }
 102                                 }
 103
 104                                 return;
 105                         }
 106                 }
 107
 108                 default:
 109                         sprint(self, "Incorrect parameters for ^2clientversion^7\n");
 110                 case CMD_REQUEST_USAGE:
 111                 {
 112                         sprint(self, "\nUsage:^3 cmd clientversion version\n");
 113                         sprint(self, "  Where 'version' is the game version reported by self.\n");
 114                         return;
 115                 }
 116         }
 117 }
 118
 119 void ClientCommand_mv_getpicture(float request, float argc) // internal command, used only by code
 120 {
 121         switch(request)
 122         {
 123                 case CMD_REQUEST_COMMAND:
 124                 {
 125                         if(argv(1) != "")
 126                         {
 127                                 if(intermission_running)
 128                                         MapVote_SendPicture(stof(argv(1)));
 129
 130                                 return;
 131                         }
 132                 }
 133
 134                 default:
 135                         sprint(self, "Incorrect parameters for ^2mv_getpicture^7\n");
 136                 case CMD_REQUEST_USAGE:
 137                 {
 138                         sprint(self, "\nUsage:^3 cmd mv_getpicture mapid\n");
 139                         sprint(self, "  Where 'mapid' is the id number of the map to request an image of on the map vote selection menu.\n");
 140                         return;
 141                 }
 142         }
 143 }
 144
 145 void ClientCommand_join(float request)
 146 {
 147         switch(request)
 148         {
 149                 case CMD_REQUEST_COMMAND:
 150                 {
 151                         if(IS_CLIENT(self))
 152                         {
 153                                 if(!IS_PLAYER(self) && !lockteams && !gameover)
 154                                 {
 155                                         if(self.caplayer)
 156                                                 return;
 157                                         if(nJoinAllowed(self))
 158                                         {
 159                                                 if(autocvar_g_campaign) { campaign_bots_may_start = 1; }
 160
 161                                                 self.classname = "player";
 162                                                 PlayerScore_Clear(self);
 163                                                 Kill_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER_CPID, CPID_PREVENT_JOIN);
 164                                                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_JOIN_PLAY, self.netname);
 165                                                 PutClientInServer();
 166                                         }
 167                                         else
 168                                         {
 169                                                 //player may not join because of g_maxplayers is set
 170                                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_JOIN_PREVENT);
 171                                         }
 172                                 }
 173                         }
 174                         return; // never fall through to usage
 175                 }
 176
 177                 default:
 178                 case CMD_REQUEST_USAGE:
 179                 {
 180                         sprint(self, "\nUsage:^3 cmd join\n");
 181                         sprint(self, "  No arguments required.\n");
 182                         return;
 183                 }
 184         }
 185 }
 186
 187 void ClientCommand_mobedit(float request, float argc)
 188 {
 189         switch(request)
 190         {
 191                 case CMD_REQUEST_COMMAND:
 192                 {
 193                         if(argv(1) && argv(2))
 194                         {
 195                                 makevectors(self.v_angle);
 196                                 WarpZone_TraceLine(self.origin + self.view_ofs, self.origin + self.view_ofs + v_forward * 100, MOVE_NORMAL, self);
 197
 198                                 if(!autocvar_g_monsters_edit) { sprint(self, "Monster property editing is not enabled.\n"); return; }
 199                                 if(trace_ent.flags & FL_MONSTER)
 200                                 {
 201                                         if(trace_ent.realowner != self) { sprint(self, "That monster does not belong to you.\n"); return; }
 202                                         switch(argv(1))
 203                                         {
 204                                                 case "skin":
 205                                                 {
 206                                                         if(trace_ent.monsterid != MON_MAGE)
 207                                                                 trace_ent.skin = stof(argv(2));
 208                                                         return;
 209                                                 }
 210                                                 case "movetarget":
 211                                                 {
 212                                                         trace_ent.monster_moveflags = stof(argv(2));
 213                                                         return;
 214                                                 }
 215                                         }
 216                                 }
 217                         }
 218                 }
 219                 default:
 220                         sprint(self, "Incorrect parameters for ^2mobedit^7\n");
 221                 case CMD_REQUEST_USAGE:
 222                 {
 223                         sprint(self, "\nUsage:^3 cmd mobedit [argument]\n");
 224                         sprint(self, "  Where 'argument' can be skin or movetarget.\n");
 225                         sprint(self, "  Aim at your monster to edit its properties.\n");
 226                         return;
 227                 }
 228         }
 229 }
 230
 231 void ClientCommand_mobkill(float request)
 232 {
 233         switch(request)
 234         {
 235                 case CMD_REQUEST_COMMAND:
 236                 {
 237                         makevectors(self.v_angle);
 238                         WarpZone_TraceLine(self.origin + self.view_ofs, self.origin + self.view_ofs + v_forward * 100, MOVE_NORMAL, self);
 239
 240                         if(trace_ent.flags & FL_MONSTER)
 241                         {
 242                                 if(trace_ent.realowner != self)
 243                                 {
 244                                         sprint(self, "That monster does not belong to you.\n");
 245                                         return;
 246                                 }
 247                                 sprint(self, strcat("Your pet '", trace_ent.monster_name, "' has been brutally mutilated.\n"));
 248                                 Damage (trace_ent, world, world, trace_ent.health + trace_ent.max_health + 200, DEATH_KILL, trace_ent.origin, '0 0 0');
 249                                 return;
 250                         }
 251                 }
 252
 253                 default:
 254                         sprint(self, "Incorrect parameters for ^2mobkill^7\n");
 255                 case CMD_REQUEST_USAGE:
 256                 {
 257                         sprint(self, "\nUsage:^3 cmd mobkill\n");
 258                         sprint(self, "  Aim at your monster to kill it.\n");
 259                         return;
 260                 }
 261         }
 262 }
 263
 264 void ClientCommand_mobspawn(float request, float argc)
 265 {
 266         switch(request)
 267         {
 268                 case CMD_REQUEST_COMMAND:
 269                 {
 270                         entity e;
 271                         string tospawn;
 272                         float moveflag, monstercount = 0;
 273
 274                         moveflag = (argv(2) ? stof(argv(2)) : 1); // follow owner if not defined
 275                         tospawn = strtolower(argv(1));
 276
 277                         if(tospawn == "list")
 278                         {
 279                                 sprint(self, monsterlist_reply);
 280                                 return;
 281                         }
 282
 283                         FOR_EACH_MONSTER(e)
 284                         {
 285                                 if(e.realowner == self)
 286                                         ++monstercount;
 287                         }
 288
 289                         if(autocvar_g_monsters_max <= 0 || autocvar_g_monsters_max_perplayer <= 0) { sprint(self, "Monster spawning is disabled.\n"); return; }
 290                         else if(!IS_PLAYER(self)) { sprint(self, "You can't spawn monsters while spectating.\n"); return; }
 291                         else if(MUTATOR_CALLHOOK(AllowMobSpawning)) { sprint(self, "Monster spawning is currently disabled by a mutator.\n"); return; }
 292                         else if(!autocvar_g_monsters) { Send_Notification(NOTIF_ONE, self, MSG_INFO, INFO_MONSTERS_DISABLED); return; }
 293                         else if(self.vehicle) { sprint(self, "You can't spawn monsters while driving a vehicle.\n"); return; }
 294                         else if(self.frozen) { sprint(self, "You can't spawn monsters while frozen.\n"); return; }
 295                         else if(autocvar_g_campaign) { sprint(self, "You can't spawn monsters in campaign mode.\n"); return; }
 296                         else if(self.deadflag != DEAD_NO) { sprint(self, "You can't spawn monsters while dead.\n"); return; }
 297                         else if(monstercount >= autocvar_g_monsters_max_perplayer) { sprint(self, "You have spawned too many monsters, kill some before trying to spawn any more.\n"); return; }
 298                         else if(totalspawned >= autocvar_g_monsters_max) { sprint(self, "The global maximum monster count has been reached, kill some before trying to spawn any more.\n"); return; }
 299                         else if(tospawn != "")
 300                         {
 301                                 float found = 0, i;
 302                                 entity mon;
 303
 304                                 for(i = MON_FIRST; i <= MON_LAST; ++i)
 305                                 {
 306                                         mon = get_monsterinfo(i);
 307                                         if(mon.netname == tospawn)
 308                                         {
 309                                                 found = TRUE;
 310                                                 break;
 311                                         }
 312                                 }
 313
 314                                 if(found || tospawn == "random")
 315                                 {
 316                                         totalspawned += 1;
 317
 318                                         makevectors(self.v_angle);
 319                                         WarpZone_TraceBox (CENTER_OR_VIEWOFS(self), PL_MIN, PL_MAX, CENTER_OR_VIEWOFS(self) + v_forward * 150, TRUE, self);
 320                                         //WarpZone_TraceLine(self.origin + self.view_ofs, self.origin + self.view_ofs + v_forward * 150, MOVE_NORMAL, self);
 321
 322                                         e = spawnmonster(tospawn, 0, self, self, trace_endpos, FALSE, FALSE, moveflag);
 323
 324                                         sprint(self, strcat("Spawned ", e.monster_name, "\n"));
 325
 326                                         return;
 327                                 }
 328                         }
 329                 }
 330
 331                 default:
 332                         sprint(self, "Incorrect parameters for ^2mobspawn^7\n");
 333                 case CMD_REQUEST_USAGE:
 334                 {
 335                         sprint(self, "\nUsage:^3 cmd mobspawn <random> <monster> [movetype]\n");
 336                         sprint(self, "  See 'cmd mobspawn list' for available monsters.\n");
 337                         sprint(self, "  Argument 'random' spawns a random monster.\n");
 338                         sprint(self, "  Monster will follow the owner if second argument is not defined.\n");
 339                         return;
 340                 }
 341         }
 342 }
 343
 344 void ClientCommand_physics(float request, float argc)
 345 {
 346         switch(request)
 347         {
 348                 case CMD_REQUEST_COMMAND:
 349                 {
 350                         string command = strtolower(argv(1));
 351
 352                         if(!autocvar_g_physics_clientselect)
 353                         {
 354                                 sprint(self, "Client physics selection is currently disabled.\n");
 355                                 return;
 356                         }
 357
 358                         if(command == "list" || command == "help")
 359                         {
 360                                 sprint(self, strcat("Available physics sets: \n\n", autocvar_g_physics_clientselect_options, " default\n"));
 361                                 return;
 362                         }
 363
 364                         if(Physics_Valid(command) || command == "default")
 365                         {
 366                                 stuffcmd(self, strcat("\nseta cl_physics ", command, "\nsendcvar cl_physics\n"));
 367                                 sprint(self, strcat("^2Physics set successfully changed to ^3", command, "\n"));
 368                                 return;
 369                         }
 370                 }
 371
 372                 default:
 373                         sprint(self, strcat("Current physics set: ^3", self.cvar_cl_physics, "\n"));
 374                 case CMD_REQUEST_USAGE:
 375                 {
 376                         sprint(self, "\nUsage:^3 cmd physics <physics>\n");
 377                         sprint(self, "  See 'cmd physics list' for available physics sets.\n");
 378                         sprint(self, "  Argument 'default' resets to standard physics.\n");
 379                         return;
 380                 }
 381         }
 382 }
 383
 384 void ClientCommand_ready(float request) // todo: anti-spam for toggling readyness
 385 {
 386         switch(request)
 387         {
 388                 case CMD_REQUEST_COMMAND:
 389                 {
 390                         if(IS_CLIENT(self))
 391                         {
 392                                 if(warmup_stage || autocvar_sv_ready_restart || g_race_qualifying == 2)
 393                                 {
 394                                         if(!readyrestart_happened || autocvar_sv_ready_restart_repeatable)
 395                                         {
 396                                                 if(time < game_starttime) // game is already restarting
 397                                                         return;
 398                                                 if (self.ready) // toggle
 399                                                 {
 400                                                         self.ready = FALSE;
 401                                                         bprint(self.netname, "^2 is ^1NOT^2 ready\n");
 402                                                 }
 403                                                 else
 404                                                 {
 405                                                         self.ready = TRUE;
 406                                                         bprint(self.netname, "^2 is ready\n");
 407                                                 }
 408
 409                                                 // cannot reset the game while a timeout is active!
 410                                                 if (!timeout_status)
 411                                                         ReadyCount();
 412                                         } else {
 413                                                 sprint(self, "^1Game has already been restarted\n");
 414                                         }
 415                                 }
 416                         }
 417                         return; // never fall through to usage
 418                 }
 419
 420                 default:
 421                 case CMD_REQUEST_USAGE:
 422                 {
 423                         sprint(self, "\nUsage:^3 cmd ready\n");
 424                         sprint(self, "  No arguments required.\n");
 425                         return;
 426                 }
 427         }
 428 }
 429
 430 void ClientCommand_say(float request, float argc, string command)
 431 {
 432         switch(request)
 433         {
 434                 case CMD_REQUEST_COMMAND:
 435                 {
 436                         if(argc >= 2) { Say(self, FALSE, world, substring(command, argv_start_index(1), argv_end_index(-1) - argv_start_index(1)), 1); }
 437                         return; // never fall through to usage
 438                 }
 439
 440                 default:
 441                 case CMD_REQUEST_USAGE:
 442                 {
 443                         sprint(self, "\nUsage:^3 cmd say <message>\n");
 444                         sprint(self, "  Where 'message' is the string of text to say.\n");
 445                         return;
 446                 }
 447         }
 448 }
 449
 450 void ClientCommand_say_team(float request, float argc, string command)
 451 {
 452         switch(request)
 453         {
 454                 case CMD_REQUEST_COMMAND:
 455                 {
 456                         if(argc >= 2) { Say(self, TRUE, world, substring(command, argv_start_index(1), argv_end_index(-1) - argv_start_index(1)), 1); }
 457                         return; // never fall through to usage
 458                 }
 459
 460                 default:
 461                 case CMD_REQUEST_USAGE:
 462                 {
 463                         sprint(self, "\nUsage:^3 cmd say_team <message>\n");
 464                         sprint(self, "  Where 'message' is the string of text to say.\n");
 465                         return;
 466                 }
 467         }
 468 }
 469
 470 void ClientCommand_selectteam(float request, float argc)
 471 {
 472         switch(request)
 473         {
 474                 case CMD_REQUEST_COMMAND:
 475                 {
 476                         if(argv(1) != "")
 477                         {
 478                                 if(IS_CLIENT(self))
 479                                 {
 480                                         if(teamplay)
 481                                                 if(self.team_forced <= 0)
 482                                                         if (!lockteams)
 483                                                         {
 484                                                                 float selection;
 485
 486                                                                 switch(argv(1))
 487                                                                 {
 488                                                                         case "red": selection = NUM_TEAM_1; break;
 489                                                                         case "blue": selection = NUM_TEAM_2; break;
 490                                                                         case "yellow": selection = NUM_TEAM_3; break;
 491                                                                         case "pink": selection = NUM_TEAM_4; break;
 492                                                                         case "auto": selection = (-1); break;
 493
 494                                                                         default: selection = 0; break;
 495                                                                 }
 496
 497                                                                 if(selection)
 498                                                                 {
 499                                                                         if(self.team == selection && self.deadflag == DEAD_NO)
 500                                                                                 sprint(self, "^7You already are on that team.\n");
 501                                                                         else if(self.wasplayer && autocvar_g_changeteam_banned)
 502                                                                                 sprint(self, "^1You cannot change team, forbidden by the server.\n");
 503                                                                         else
 504                                                                         {
 505                                                                                 if(autocvar_g_balance_teams && autocvar_g_balance_teams_prevent_imbalance)
 506                                                                                 {
 507                                                                                         CheckAllowedTeams(self);
 508                                                                                         GetTeamCounts(self);
 509                                                                                         if(!TeamSmallerEqThanTeam(Team_TeamToNumber(selection), Team_TeamToNumber(self.team), self))
 510                                                                                         {
 511                                                                                                 Send_Notification(NOTIF_ONE, self, MSG_INFO, INFO_TEAMCHANGE_LARGERTEAM);
 512                                                                                                 return;
 513                                                                                         }
 514                                                                                 }
 515                                                                                 ClientKill_TeamChange(selection);
 516                                                                         }
 517                                                                 }
 518                                                         }
 519                                                         else
 520                                                                 sprint(self, "^7The game has already begun, you must wait until the next map to be able to join a team.\n");
 521                                                 else
 522                                                         sprint(self, "^7selectteam can not be used as your team is forced\n");
 523                                         else
 524                                                 sprint(self, "^7selectteam can only be used in teamgames\n");
 525                                 }
 526                                 return;
 527                         }
 528                 }
 529
 530                 default:
 531                         sprint(self, "Incorrect parameters for ^2selectteam^7\n");
 532                 case CMD_REQUEST_USAGE:
 533                 {
 534                         sprint(self, "\nUsage:^3 cmd selectteam team\n");
 535                         sprint(self, "  Where 'team' is the prefered team to try and join.\n");
 536                         sprint(self, "  Full list of options here: \"red, blue, yellow, pink, auto\"\n");
 537                         return;
 538                 }
 539         }
 540 }
 541
 542 void ClientCommand_selfstuff(float request, string command)
 543 {
 544         switch(request)
 545         {
 546                 case CMD_REQUEST_COMMAND:
 547                 {
 548                         if(argv(1) != "")
 549                         {
 550                                 stuffcmd(self, substring(command, argv_start_index(1), argv_end_index(-1) - argv_start_index(1)));
 551                                 return;
 552                         }
 553                 }
 554
 555                 default:
 556                         sprint(self, "Incorrect parameters for ^2selectteam^7\n");
 557                 case CMD_REQUEST_USAGE:
 558                 {
 559                         sprint(self, "\nUsage:^3 cmd selfstuff <command>\n");
 560                         sprint(self, "  Where 'command' is the string to be stuffed to your client.\n");
 561                         return;
 562                 }
 563         }
 564 }
 565
 566 void ClientCommand_sentcvar(float request, float argc, string command)
 567 {
 568         switch(request)
 569         {
 570                 case CMD_REQUEST_COMMAND:
 571                 {
 572                         if(argv(1) != "")
 573                         {
 574                                 //float tokens;
 575                                 string s;
 576
 577                                 if(argc == 2) // undefined cvar: use the default value on the server then
 578                                 {
 579                                         s = strcat(substring(command, argv_start_index(0), argv_end_index(1) - argv_start_index(0)), " \"", cvar_defstring(argv(1)), "\"");
 580                                         tokenize_console(s);
 581                                 }
 582
 583                                 GetCvars(1);
 584
 585                                 return;
 586                         }
 587                 }
 588
 589                 default:
 590                         sprint(self, "Incorrect parameters for ^2sentcvar^7\n");
 591                 case CMD_REQUEST_USAGE:
 592                 {
 593                         sprint(self, "\nUsage:^3 cmd sentcvar <cvar>\n");
 594                         sprint(self, "  Where 'cvar' is the cvar plus arguments to send to the server.\n");
 595                         return;
 596                 }
 597         }
 598 }
 599
 600 void ClientCommand_spectate(float request)
 601 {
 602         switch(request)
 603         {
 604                 case CMD_REQUEST_COMMAND:
 605                 {
 606                         if(IS_CLIENT(self))
 607                         {
 608                                 if(g_lms)
 609                                 {
 610                                         if(self.lms_spectate_warning)
 611                                         {
 612                                                 // for the forfeit message...
 613                                                 self.lms_spectate_warning = 2;
 614                                                 // mark player as spectator
 615                                                 PlayerScore_Add(self, SP_LMS_RANK, 666 - PlayerScore_Add(self, SP_LMS_RANK, 0));
 616                                         }
 617                                         else
 618                                         {
 619                                                 self.lms_spectate_warning = 1;
 620                                                 sprint(self, "WARNING: you won't be able to enter the game again after spectating in LMS. Use the same command again to spectate anyway.\n");
 621                                                 return;
 622                                         }
 623                                 }
 624
 625                                 if((IS_PLAYER(self) || self.caplayer) && autocvar_sv_spectate == 1)
 626                                 {
 627                                         if(self.caplayer && (IS_SPEC(self) || IS_OBSERVER(self)))
 628                                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_CA_LEAVE);
 629                                         ClientKill_TeamChange(-2); // observe
 630                                 }
 631                         }
 632                         return; // never fall through to usage
 633                 }
 634
 635                 default:
 636                 case CMD_REQUEST_USAGE:
 637                 {
 638                         sprint(self, "\nUsage:^3 cmd spectate\n");
 639                         sprint(self, "  No arguments required.\n");
 640                         return;
 641                 }
 642         }
 643 }
 644
 645 void ClientCommand_suggestmap(float request, float argc)
 646 {
 647         switch(request)
 648         {
 649                 case CMD_REQUEST_COMMAND:
 650                 {
 651                         if(argv(1) != "")
 652                         {
 653                                 sprint(self, strcat(MapVote_Suggest(argv(1)), "\n"));
 654                                 return;
 655                         }
 656                 }
 657
 658                 default:
 659                         sprint(self, "Incorrect parameters for ^2suggestmap^7\n");
 660                 case CMD_REQUEST_USAGE:
 661                 {
 662                         sprint(self, "\nUsage:^3 cmd suggestmap map\n");
 663                         sprint(self, "  Where 'map' is the name of the map to suggest.\n");
 664                         return;
 665                 }
 666         }
 667 }
 668
 669 void ClientCommand_tell(float request, float argc, string command)
 670 {
 671         switch(request)
 672         {
 673                 case CMD_REQUEST_COMMAND:
 674                 {
 675                         if(argc >= 3)
 676                         {
 677                                 entity tell_to = GetIndexedEntity(argc, 1);
 678                                 float tell_accepted = VerifyClientEntity(tell_to, TRUE, FALSE);
 679
 680                                 if(tell_accepted > 0) // the target is a real client
 681                                 {
 682                                         if(tell_to != self) // and we're allowed to send to them :D
 683                                         {
 684                                                 Say(self, FALSE, tell_to, substring(command, argv_start_index(next_token), argv_end_index(-1) - argv_start_index(next_token)), TRUE);
 685                                                 return;
 686                                         }
 687                                         else { print_to(self, "You can't ^2tell^7 a message to yourself."); return; }
 688                                 }
 689                                 else if(argv(1) == "#0")
 690                                 {
 691                                         trigger_magicear_processmessage_forallears(self, -1, world, substring(command, argv_start_index(next_token), argv_end_index(-1) - argv_start_index(next_token)));
 692                                         return;
 693                                 }
 694                                 else { print_to(self, strcat("tell: ", GetClientErrorString(tell_accepted, argv(1)), ".")); return; }
 695                         }
 696                 }
 697
 698                 default:
 699                         sprint(self, "Incorrect parameters for ^2tell^7\n");
 700                 case CMD_REQUEST_USAGE:
 701                 {
 702                         sprint(self, "\nUsage:^3 cmd tell client <message>\n");
 703                         sprint(self, "  Where 'client' is the entity number or name of the player to send 'message' to.\n");
 704                         return;
 705                 }
 706         }
 707 }
 708
 709 void ClientCommand_voice(float request, float argc, string command)
 710 {
 711         switch(request)
 712         {
 713                 case CMD_REQUEST_COMMAND:
 714                 {
 715                         if(argv(1) != "")
 716                         {
 717                                 if(argc >= 3)
 718                                         VoiceMessage(argv(1), substring(command, argv_start_index(2), argv_end_index(-1) - argv_start_index(2)));
 719                                 else
 720                                         VoiceMessage(argv(1), "");
 721
 722                                 return;
 723                         }
 724                 }
 725
 726                 default:
 727                         sprint(self, "Incorrect parameters for ^2voice^7\n");
 728                 case CMD_REQUEST_USAGE:
 729                 {
 730                         sprint(self, "\nUsage:^3 cmd voice messagetype <soundname>\n");
 731                         sprint(self, "  'messagetype' is the type of broadcast to do, like team only or such,\n");
 732                         sprint(self, "  and 'soundname' is the string/filename of the sound/voice message to play.\n");
 733                         return;
 734                 }
 735         }
 736 }
 737
 738 /* use this when creating a new command, making sure to place it in alphabetical order... also,
 739 ** ADD ALL NEW COMMANDS TO commands.cfg WITH PROPER ALIASES IN THE SAME FASHION!
 740 void ClientCommand_(float request)
 741 {
 742         switch(request)
 743         {
 744                 case CMD_REQUEST_COMMAND:
 745                 {
 746
 747                         return; // never fall through to usage
 748                 }
 749
 750                 default:
 751                 case CMD_REQUEST_USAGE:
 752                 {
 753                         sprint(self, "\nUsage:^3 cmd \n");
 754                         sprint(self, "  No arguments required.\n");
 755                         return;
 756                 }
 757         }
 758 }
 759 */
 760
 761
 762 // =====================================
 763 //  Macro system for networked commands
 764 // =====================================
 765
 766 // Do not hard code aliases for these, instead create them in commands.cfg... also: keep in alphabetical order, please ;)
 767 #define CLIENT_COMMANDS(request,arguments,command) \
 768         CLIENT_COMMAND("autoswitch", ClientCommand_autoswitch(request, arguments), "Whether or not to switch automatically when getting a better weapon") \
 769         CLIENT_COMMAND("checkfail", ClientCommand_checkfail(request, command), "Report if a client-side check failed") \
 770         CLIENT_COMMAND("clientversion", ClientCommand_clientversion(request, arguments), "Release version of the game") \
 771         CLIENT_COMMAND("mv_getpicture", ClientCommand_mv_getpicture(request, arguments), "Retrieve mapshot picture from the server") \
 772         CLIENT_COMMAND("join", ClientCommand_join(request), "Become a player in the game") \
 773         CLIENT_COMMAND("mobedit", ClientCommand_mobedit(request, arguments), "Edit your monster's properties") \
 774         CLIENT_COMMAND("mobkill", ClientCommand_mobkill(request), "Kills your monster") \
 775         CLIENT_COMMAND("mobspawn", ClientCommand_mobspawn(request, arguments), "Spawn monsters infront of yourself") \
 776         CLIENT_COMMAND("physics", ClientCommand_physics(request, arguments), "Change physics set") \
 777         CLIENT_COMMAND("ready", ClientCommand_ready(request), "Qualify as ready to end warmup stage (or restart server if allowed)") \
 778         CLIENT_COMMAND("say", ClientCommand_say(request, arguments, command), "Print a message to chat to all players") \
 779         CLIENT_COMMAND("say_team", ClientCommand_say_team(request, arguments, command), "Print a message to chat to all team mates") \
 780         CLIENT_COMMAND("selectteam", ClientCommand_selectteam(request, arguments), "Attempt to choose a team to join into") \
 781         CLIENT_COMMAND("selfstuff", ClientCommand_selfstuff(request, command), "Stuffcmd a command to your own client") \
 782         CLIENT_COMMAND("sentcvar", ClientCommand_sentcvar(request, arguments, command), "New system for sending a client cvar to the server") \
 783         CLIENT_COMMAND("spectate", ClientCommand_spectate(request), "Become an observer") \
 784         CLIENT_COMMAND("suggestmap", ClientCommand_suggestmap(request, arguments), "Suggest a map to the mapvote at match end") \
 785         CLIENT_COMMAND("tell", ClientCommand_tell(request, arguments, command), "Send a message directly to a player") \
 786         CLIENT_COMMAND("voice", ClientCommand_voice(request, arguments, command), "Send voice message via sound") \
 787         /* nothing */
 788
 789 void ClientCommand_macro_help()
 790 {
 791         #define CLIENT_COMMAND(name,function,description) \
 792                 { sprint(self, "  ^2", name, "^7: ", description, "\n"); }
 793
 794         CLIENT_COMMANDS(0, 0, "")
 795         #undef CLIENT_COMMAND
 796
 797         return;
 798 }
 799
 800 float ClientCommand_macro_command(float argc, string command)
 801 {
 802         #define CLIENT_COMMAND(name,function,description) \
 803                 { if(name == strtolower(argv(0))) { function; return TRUE; } }
 804
 805         CLIENT_COMMANDS(CMD_REQUEST_COMMAND, argc, command)
 806         #undef CLIENT_COMMAND
 807
 808         return FALSE;
 809 }
 810
 811 float ClientCommand_macro_usage(float argc)
 812 {
 813         #define CLIENT_COMMAND(name,function,description) \
 814                 { if(name == strtolower(argv(1))) { function; return TRUE; } }
 815
 816         CLIENT_COMMANDS(CMD_REQUEST_USAGE, argc, "")
 817         #undef CLIENT_COMMAND
 818
 819         return FALSE;
 820 }
 821
 822 void ClientCommand_macro_write_aliases(float fh)
 823 {
 824         #define CLIENT_COMMAND(name,function,description) \
 825                 { CMD_Write_Alias("qc_cmd_cmd", name, description); }
 826
 827         CLIENT_COMMANDS(0, 0, "")
 828         #undef CLIENT_COMMAND
 829
 830         return;
 831 }
 832
 833 // ======================================
 834 //  Main Function Called By Engine (cmd)
 835 // ======================================
 836 // If this function exists, server game code parses clientcommand before the engine code gets it.
 837
 838 void SV_ParseClientCommand(string command)
 839 {
 840         // if we're banned, don't even parse the command
 841         if(Ban_MaybeEnforceBanOnce(self))
 842                 return;
 843
 844         float argc = tokenize_console(command);
 845
 846         // for the mutator hook system
 847         cmd_name = strtolower(argv(0));
 848         cmd_argc = argc;
 849         cmd_string = command;
 850
 851         // Guide for working with argc arguments by example:
 852         // argc:   1    - 2      - 3     - 4
 853         // argv:   0    - 1      - 2     - 3
 854         // cmd     vote - master - login - password
 855
 856         // for floodcheck
 857         switch(strtolower(argv(0)))
 858         {
 859                 // exempt commands which are not subject to floodcheck
 860                 case "begin": break; // handled by engine in host_cmd.c
 861                 case "download": break; // handled by engine in cl_parse.c
 862                 case "mv_getpicture": break; // handled by server in this file
 863                 case "pause": break; // handled by engine in host_cmd.c
 864                 case "prespawn": break; // handled by engine in host_cmd.c
 865                 case "sentcvar": break; // handled by server in this file
 866                 case "spawn": break; // handled by engine in host_cmd.c
 867
 868                 default:
 869                         if(SV_ParseClientCommand_floodcheck())
 870                                 break; // "TRUE": continue, as we're not flooding yet
 871                         else
 872                                 return; // "FALSE": not allowed to continue, halt // print("^1ERROR: ^7ANTISPAM CAUGHT: ", command, ".\n");
 873         }
 874
 875         /* NOTE: should this be disabled? It can be spammy perhaps, but hopefully it's okay for now */
 876         if(argv(0) == "help")
 877         {
 878                 if(argc == 1)
 879                 {
 880                         sprint(self, "\nClient networked commands:\n");
 881                         ClientCommand_macro_help();
 882
 883                         sprint(self, "\nCommon networked commands:\n");
 884                         CommonCommand_macro_help(self);
 885
 886                         sprint(self, "\nUsage:^3 cmd COMMAND...^7, where possible commands are listed above.\n");
 887                         sprint(self, "For help about a specific command, type cmd help COMMAND\n");
 888                         return;
 889                 }
 890                 else if(CommonCommand_macro_usage(argc, self)) // Instead of trying to call a command, we're going to see detailed information about it
 891                 {
 892                         return;
 893                 }
 894                 else if(ClientCommand_macro_usage(argc)) // same, but for normal commands now
 895                 {
 896                         return;
 897                 }
 898         }
 899         else if(MUTATOR_CALLHOOK(SV_ParseClientCommand))
 900         {
 901                 return; // handled by a mutator
 902         }
 903         else if(CheatCommand(argc))
 904         {
 905                 return; // handled by server/cheats.qc
 906         }
 907         else if(CommonCommand_macro_command(argc, self, command))
 908         {
 909                 return; // handled by server/command/common.qc
 910         }
 911         else if(ClientCommand_macro_command(argc, command)) // continue as usual and scan for normal commands
 912         {
 913                 return; // handled by one of the above ClientCommand_* functions
 914         }
 915         else
 916                 clientcommand(self, command);
 917 }