qcsrc/server/command/cmd.qc

   1 #include "cmd.qh"
   2
   3 #include <server/defs.qh>
   4 #include <server/miscfunctions.qh>
   5
   6 #include <common/command/_mod.qh>
   7
   8 #include "common.qh"
   9 #include "vote.qh"
  10
  11 #include "../campaign.qh"
  12 #include "../cheats.qh"
  13 #include "../player.qh"
  14 #include "../ipban.qh"
  15 #include "../mapvoting.qh"
  16 #include "../scores.qh"
  17 #include "../teamplay.qh"
  18
  19 #include "../mutators/_mod.qh"
  20
  21 #ifdef SVQC
  22         #include <common/vehicles/all.qh>
  23 #endif
  24
  25 #include <common/constants.qh>
  26 #include <common/deathtypes/all.qh>
  27 #include <common/effects/all.qh>
  28 #include <common/mapinfo.qh>
  29 #include <common/notifications/all.qh>
  30 #include <common/physics/player.qh>
  31 #include <common/teams.qh>
  32 #include <common/util.qh>
  33 #include <common/triggers/triggers.qh>
  34
  35 #include <common/minigames/sv_minigames.qh>
  36
  37 #include <common/monsters/_mod.qh>
  38 #include <common/monsters/sv_spawn.qh>
  39 #include <common/monsters/sv_monsters.qh>
  40
  41 #include <lib/warpzone/common.qh>
  42
  43 void ClientKill_TeamChange(entity this, float targetteam);  // 0 = don't change, -1 = auto, -2 = spec
  44
  45 // =========================================================
  46 //  Server side networked commands code, reworked by Samual
  47 //  Last updated: December 28th, 2011
  48 // =========================================================
  49
  50 bool SV_ParseClientCommand_floodcheck(entity this)
  51 {
  52         entity store = IS_CLIENT(this) ? CS(this) : this; // unfortunately, we need to store these on the client initially
  53
  54         if (!timeout_status)  // not while paused
  55         {
  56                 if (time <= (store.cmd_floodtime + autocvar_sv_clientcommand_antispam_time))
  57                 {
  58                         store.cmd_floodcount += 1;
  59                         if (store.cmd_floodcount > autocvar_sv_clientcommand_antispam_count)   return false;  // too much spam, halt
  60                 }
  61                 else
  62                 {
  63                         store.cmd_floodtime = time;
  64                         store.cmd_floodcount = 1;
  65                 }
  66         }
  67         return true;  // continue, as we're not flooding yet
  68 }
  69
  70
  71 // =======================
  72 //  Command Sub-Functions
  73 // =======================
  74
  75 void ClientCommand_autoswitch(entity caller, float request, float argc)
  76 {
  77         switch (request)
  78         {
  79                 case CMD_REQUEST_COMMAND:
  80                 {
  81                         if (argv(1) != "")
  82                         {
  83                                 CS(caller).autoswitch = InterpretBoolean(argv(1));
  84                                 sprint(caller, strcat("^1autoswitch is currently turned ", (CS(caller).autoswitch ? "on" : "off"), ".\n"));
  85                                 return;
  86                         }
  87                 }
  88
  89                 default:
  90                         sprint(caller, "Incorrect parameters for ^2autoswitch^7\n");
  91                 case CMD_REQUEST_USAGE:
  92                 {
  93                         sprint(caller, "\nUsage:^3 cmd autoswitch selection\n");
  94                         sprint(caller, "  Where 'selection' controls if autoswitch is on or off.\n");
  95                         return;
  96                 }
  97         }
  98 }
  99
 100 void ClientCommand_clientversion(entity caller, float request, float argc)  // internal command, used only by code
 101 {
 102         switch (request)
 103         {
 104                 case CMD_REQUEST_COMMAND:
 105                 {
 106                         if (argv(1) != "")
 107                         {
 108                                 if (IS_CLIENT(caller))
 109                                 {
 110                                         CS(caller).version = ((argv(1) == "$gameversion") ? 1 : stof(argv(1)));
 111
 112                                         if (CS(caller).version < autocvar_gameversion_min || CS(caller).version > autocvar_gameversion_max)
 113                                         {
 114                                                 CS(caller).version_mismatch = true;
 115                                                 ClientKill_TeamChange(caller, -2);  // observe
 116                                         }
 117                                         else if (autocvar_g_campaign || autocvar_g_balance_teams)
 118                                         {
 119                                                 // JoinBestTeam(caller, false, true);
 120                                         }
 121                                         else if (teamplay && !autocvar_sv_spectate && !(caller.team_forced > 0))
 122                                         {
 123                                                 TRANSMUTE(Observer, caller);  // really?
 124                                                 stuffcmd(caller, "menu_showteamselect\n");
 125                                         }
 126                                 }
 127
 128                                 return;
 129                         }
 130                 }
 131
 132                 default:
 133                         sprint(caller, "Incorrect parameters for ^2clientversion^7\n");
 134                 case CMD_REQUEST_USAGE:
 135                 {
 136                         sprint(caller, "\nUsage:^3 cmd clientversion version\n");
 137                         sprint(caller, "  Where 'version' is the game version reported by caller.\n");
 138                         return;
 139                 }
 140         }
 141 }
 142
 143 void ClientCommand_mv_getpicture(entity caller, float request, float argc)  // internal command, used only by code
 144 {
 145         switch (request)
 146         {
 147                 case CMD_REQUEST_COMMAND:
 148                 {
 149                         if (argv(1) != "")
 150                         {
 151                                 if (intermission_running) MapVote_SendPicture(caller, stof(argv(1)));
 152
 153                                 return;
 154                         }
 155                 }
 156
 157                 default:
 158                         sprint(caller, "Incorrect parameters for ^2mv_getpicture^7\n");
 159                 case CMD_REQUEST_USAGE:
 160                 {
 161                         sprint(caller, "\nUsage:^3 cmd mv_getpicture mapid\n");
 162                         sprint(caller, "  Where 'mapid' is the id number of the map to request an image of on the map vote selection menu.\n");
 163                         return;
 164                 }
 165         }
 166 }
 167
 168 bool joinAllowed(entity this);
 169 void Join(entity this);
 170 void ClientCommand_join(entity caller, float request)
 171 {
 172         switch (request)
 173         {
 174                 case CMD_REQUEST_COMMAND:
 175                 {
 176                         if (!game_stopped)
 177                         if (IS_CLIENT(caller) && !IS_PLAYER(caller))
 178                         if (joinAllowed(caller))
 179                                 Join(caller);
 180
 181                         return;  // never fall through to usage
 182                 }
 183
 184                 default:
 185                 case CMD_REQUEST_USAGE:
 186                 {
 187                         sprint(caller, "\nUsage:^3 cmd join\n");
 188                         sprint(caller, "  No arguments required.\n");
 189                         return;
 190                 }
 191         }
 192 }
 193
 194 void ClientCommand_physics(entity caller, float request, float argc)
 195 {
 196         switch (request)
 197         {
 198                 case CMD_REQUEST_COMMAND:
 199                 {
 200                         string command = strtolower(argv(1));
 201
 202                         if (!autocvar_g_physics_clientselect)
 203                         {
 204                                 sprint(caller, "Client physics selection is currently disabled.\n");
 205                                 return;
 206                         }
 207
 208                         if (command == "list" || command == "help")
 209                         {
 210                                 sprint(caller, strcat("Available physics sets: \n\n", autocvar_g_physics_clientselect_options, " default\n"));
 211                                 return;
 212                         }
 213
 214                         if (Physics_Valid(command) || command == "default")
 215                         {
 216                                 stuffcmd(caller, strcat("\nseta cl_physics ", command, "\nsendcvar cl_physics\n"));
 217                                 sprint(caller, strcat("^2Physics set successfully changed to ^3", command, "\n"));
 218                                 return;
 219                         }
 220                 }
 221
 222                 default:
 223                         sprint(caller, strcat("Current physics set: ^3", CS(caller).cvar_cl_physics, "\n"));
 224                 case CMD_REQUEST_USAGE:
 225                 {
 226                         sprint(caller, "\nUsage:^3 cmd physics <physics>\n");
 227                         sprint(caller, "  See 'cmd physics list' for available physics sets.\n");
 228                         sprint(caller, "  Argument 'default' resets to standard physics.\n");
 229                         return;
 230                 }
 231         }
 232 }
 233
 234 void ClientCommand_ready(entity caller, float request)  // todo: anti-spam for toggling readyness
 235 {
 236         switch (request)
 237         {
 238                 case CMD_REQUEST_COMMAND:
 239                 {
 240                         if (IS_CLIENT(caller))
 241                         {
 242                                 if (warmup_stage || autocvar_sv_ready_restart || g_race_qualifying == 2)
 243                                 {
 244                                         if (!readyrestart_happened || autocvar_sv_ready_restart_repeatable)
 245                                         {
 246                                                 if (time < game_starttime) // game is already restarting
 247                                                         return;
 248                                                 if (caller.ready)            // toggle
 249                                                 {
 250                                                         caller.ready = false;
 251                                                         bprint(playername(caller, false), "^2 is ^1NOT^2 ready\n");
 252                                                 }
 253                                                 else
 254                                                 {
 255                                                         caller.ready = true;
 256                                                         bprint(playername(caller, false), "^2 is ready\n");
 257                                                 }
 258
 259                                                 // cannot reset the game while a timeout is active!
 260                                                 if (!timeout_status) ReadyCount();
 261                                         }
 262                                         else
 263                                         {
 264                                                 sprint(caller, "^1Game has already been restarted\n");
 265                                         }
 266                                 }
 267                         }
 268                         return;  // never fall through to usage
 269                 }
 270
 271                 default:
 272                 case CMD_REQUEST_USAGE:
 273                 {
 274                         sprint(caller, "\nUsage:^3 cmd ready\n");
 275                         sprint(caller, "  No arguments required.\n");
 276                         return;
 277                 }
 278         }
 279 }
 280
 281 void ClientCommand_say(entity caller, float request, float argc, string command)
 282 {
 283         switch (request)
 284         {
 285                 case CMD_REQUEST_COMMAND:
 286                 {
 287                         if (argc >= 2)   Say(caller, false, NULL, substring(command, argv_start_index(1), argv_end_index(-1) - argv_start_index(1)), 1);
 288                         return;  // never fall through to usage
 289                 }
 290
 291                 default:
 292                 case CMD_REQUEST_USAGE:
 293                 {
 294                         sprint(caller, "\nUsage:^3 cmd say <message>\n");
 295                         sprint(caller, "  Where 'message' is the string of text to say.\n");
 296                         return;
 297                 }
 298         }
 299 }
 300
 301 void ClientCommand_say_team(entity caller, float request, float argc, string command)
 302 {
 303         switch (request)
 304         {
 305                 case CMD_REQUEST_COMMAND:
 306                 {
 307                         if (argc >= 2)   Say(caller, true, NULL, substring(command, argv_start_index(1), argv_end_index(-1) - argv_start_index(1)), 1);
 308                         return;  // never fall through to usage
 309                 }
 310
 311                 default:
 312                 case CMD_REQUEST_USAGE:
 313                 {
 314                         sprint(caller, "\nUsage:^3 cmd say_team <message>\n");
 315                         sprint(caller, "  Where 'message' is the string of text to say.\n");
 316                         return;
 317                 }
 318         }
 319 }
 320
 321 .bool team_selected;
 322 void ClientCommand_selectteam(entity caller, float request, float argc)
 323 {
 324         switch (request)
 325         {
 326                 case CMD_REQUEST_COMMAND:
 327                 {
 328                         if (argv(1) != "")
 329                         {
 330                                 if (IS_CLIENT(caller))
 331                                 {
 332                                         if (teamplay)
 333                                         {
 334                                                 if (caller.team_forced <= 0)
 335                                                 {
 336                                                         if (!lockteams)
 337                                                         {
 338                                                                 float selection;
 339
 340                                                                 switch (argv(1))
 341                                                                 {
 342                                                                         case "red": selection = NUM_TEAM_1;
 343                                                                                 break;
 344                                                                         case "blue": selection = NUM_TEAM_2;
 345                                                                                 break;
 346                                                                         case "yellow": selection = NUM_TEAM_3;
 347                                                                                 break;
 348                                                                         case "pink": selection = NUM_TEAM_4;
 349                                                                                 break;
 350                                                                         case "auto": selection = (-1);
 351                                                                                 break;
 352
 353                                                                         default: selection = 0;
 354                                                                                 break;
 355                                                                 }
 356
 357                                                                 if (selection)
 358                                                                 {
 359                                                                         if (caller.team == selection && selection != -1 && !IS_DEAD(caller))
 360                                                                         {
 361                                                                                 sprint(caller, "^7You already are on that team.\n");
 362                                                                         }
 363                                                                         else if (CS(caller).wasplayer && autocvar_g_changeteam_banned)
 364                                                                         {
 365                                                                                 sprint(caller, "^1You cannot change team, forbidden by the server.\n");
 366                                                                         }
 367                                                                         else
 368                                                                         {
 369                                                                                 if (autocvar_g_balance_teams && autocvar_g_balance_teams_prevent_imbalance)
 370                                                                                 {
 371                                                                                         CheckAllowedTeams(caller);
 372                                                                                         GetTeamCounts(caller);
 373                                                                                         if (!TeamSmallerEqThanTeam(Team_TeamToNumber(selection), Team_TeamToNumber(caller.team), caller))
 374                                                                                         {
 375                                                                                                 Send_Notification(NOTIF_ONE, caller, MSG_INFO, INFO_TEAMCHANGE_LARGERTEAM);
 376                                                                                                 return;
 377                                                                                         }
 378                                                                                 }
 379                                                                                 ClientKill_TeamChange(caller, selection);
 380                                                                         }
 381                                                                         if(!IS_PLAYER(caller))
 382                                                                                 caller.team_selected = true; // avoids asking again for team selection on join
 383                                                                 }
 384                                                         }
 385                                                         else
 386                                                         {
 387                                                                 sprint(caller, "^7The game has already begun, you must wait until the next map to be able to join a team.\n");
 388                                                         }
 389                                                 }
 390                                                 else
 391                                                 {
 392                                                         sprint(caller, "^7selectteam can not be used as your team is forced\n");
 393                                                 }
 394                                         }
 395                                         else
 396                                         {
 397                                                 sprint(caller, "^7selectteam can only be used in teamgames\n");
 398                                         }
 399                                 }
 400                                 return;
 401                         }
 402                 }
 403
 404                 default:
 405                         sprint(caller, "Incorrect parameters for ^2selectteam^7\n");
 406                 case CMD_REQUEST_USAGE:
 407                 {
 408                         sprint(caller, "\nUsage:^3 cmd selectteam team\n");
 409                         sprint(caller, "  Where 'team' is the prefered team to try and join.\n");
 410                         sprint(caller, "  Full list of options here: \"red, blue, yellow, pink, auto\"\n");
 411                         return;
 412                 }
 413         }
 414 }
 415
 416 void ClientCommand_selfstuff(entity caller, float request, string command)
 417 {
 418         switch (request)
 419         {
 420                 case CMD_REQUEST_COMMAND:
 421                 {
 422                         if (argv(1) != "")
 423                         {
 424                                 stuffcmd(caller, substring(command, argv_start_index(1), argv_end_index(-1) - argv_start_index(1)));
 425                                 return;
 426                         }
 427                 }
 428
 429                 default:
 430                         sprint(caller, "Incorrect parameters for ^2selfstuff^7\n");
 431                 case CMD_REQUEST_USAGE:
 432                 {
 433                         sprint(caller, "\nUsage:^3 cmd selfstuff <command>\n");
 434                         sprint(caller, "  Where 'command' is the string to be stuffed to your client.\n");
 435                         return;
 436                 }
 437         }
 438 }
 439
 440 void ClientCommand_sentcvar(entity caller, float request, float argc, string command)
 441 {
 442         switch (request)
 443         {
 444                 case CMD_REQUEST_COMMAND:
 445                 {
 446                         if (argv(1) != "")
 447                         {
 448                                 // float tokens;
 449                                 string s;
 450
 451                                 if (argc == 2)  // undefined cvar: use the default value on the server then
 452                                 {
 453                                         s = strcat(substring(command, argv_start_index(0), argv_end_index(1) - argv_start_index(0)), " \"", cvar_defstring(argv(1)), "\"");
 454                                         tokenize_console(s);
 455                                 }
 456
 457                                 GetCvars(caller, CS(caller), 1);
 458
 459                                 return;
 460                         }
 461                 }
 462
 463                 default:
 464                         sprint(caller, "Incorrect parameters for ^2sentcvar^7\n");
 465                 case CMD_REQUEST_USAGE:
 466                 {
 467                         sprint(caller, "\nUsage:^3 cmd sentcvar <cvar>\n");
 468                         sprint(caller, "  Where 'cvar' is the cvar plus arguments to send to the server.\n");
 469                         return;
 470                 }
 471         }
 472 }
 473
 474 void ClientCommand_spectate(entity caller, float request)
 475 {
 476         switch (request)
 477         {
 478                 case CMD_REQUEST_COMMAND:
 479                 {
 480                         if (!intermission_running && IS_CLIENT(caller))
 481                         {
 482                                 if((IS_SPEC(caller) || IS_OBSERVER(caller)) && argv(1) != "")
 483                                 {
 484                                         entity client = GetFilteredEntity(argv(1));
 485                                         int spec_accepted = VerifyClientEntity(client, false, false);
 486                                         if(spec_accepted > 0 && IS_PLAYER(client))
 487                                         {
 488                                                 if(Spectate(caller, client))
 489                                                         return; // fall back to regular handling
 490                                         }
 491                                 }
 492
 493                                 int mutator_returnvalue = MUTATOR_CALLHOOK(ClientCommand_Spectate, caller);
 494
 495                                 if (mutator_returnvalue == MUT_SPECCMD_RETURN) return;
 496
 497                                 if ((IS_PLAYER(caller) || mutator_returnvalue == MUT_SPECCMD_FORCE))
 498                                 if (autocvar_sv_spectate == 1)
 499                                         ClientKill_TeamChange(caller, -2); // observe
 500                         }
 501                         return; // never fall through to usage
 502                 }
 503
 504                 default:
 505                 case CMD_REQUEST_USAGE:
 506                 {
 507                         sprint(caller, "\nUsage:^3 cmd spectate <client>\n");
 508                         sprint(caller, "  Where 'client' can be the player to spectate.\n");
 509                         return;
 510                 }
 511         }
 512 }
 513
 514 void ClientCommand_suggestmap(entity caller, float request, float argc)
 515 {
 516         switch (request)
 517         {
 518                 case CMD_REQUEST_COMMAND:
 519                 {
 520                         if (argv(1) != "")
 521                         {
 522                                 sprint(caller, strcat(MapVote_Suggest(caller, argv(1)), "\n"));
 523                                 return;
 524                         }
 525                 }
 526
 527                 default:
 528                         sprint(caller, "Incorrect parameters for ^2suggestmap^7\n");
 529                 case CMD_REQUEST_USAGE:
 530                 {
 531                         sprint(caller, "\nUsage:^3 cmd suggestmap map\n");
 532                         sprint(caller, "  Where 'map' is the name of the map to suggest.\n");
 533                         return;
 534                 }
 535         }
 536 }
 537
 538 void ClientCommand_tell(entity caller, float request, float argc, string command)
 539 {
 540         switch (request)
 541         {
 542                 case CMD_REQUEST_COMMAND:
 543                 {
 544                         if (argc >= 3)
 545                         {
 546                                 if(!IS_CLIENT(caller) && IS_REAL_CLIENT(caller)) // connecting
 547                                 {
 548                                         print_to(caller, "You can't ^2tell^7 a message while connecting.");
 549                                         return;
 550                                 }
 551
 552                                 entity tell_to = GetIndexedEntity(argc, 1);
 553                                 float tell_accepted = VerifyClientEntity(tell_to, true, false);
 554
 555                                 if (tell_accepted > 0)   // the target is a real client
 556                                 {
 557                                         if (tell_to != caller) // and we're allowed to send to them :D
 558                                         {
 559                                                 // workaround for argv indexes indexing ascii chars instead of utf8 chars
 560                                                 // In this case when the player name contains utf8 chars
 561                                                 // the message gets partially trimmed in the beginning.
 562                                                 // Potentially this bug affects any substring call that uses
 563                                                 // argv_start_index and argv_end_index.
 564
 565                                                 string utf8_enable_save = cvar_string("utf8_enable");
 566                                                 cvar_set("utf8_enable", "0");
 567                                                 string msg = substring(command, argv_start_index(next_token), argv_end_index(-1) - argv_start_index(next_token));
 568                                                 cvar_set("utf8_enable", utf8_enable_save);
 569
 570                                                 Say(caller, false, tell_to, msg, true);
 571                                                 return;
 572                                         }
 573                                         else { print_to(caller, "You can't ^2tell^7 a message to yourself."); return; }
 574                                 }
 575                                 else if (argv(1) == "#0")
 576                                 {
 577                                         trigger_magicear_processmessage_forallears(caller, -1, NULL, substring(command, argv_start_index(next_token), argv_end_index(-1) - argv_start_index(next_token)));
 578                                         return;
 579                                 }
 580                                 else { print_to(caller, strcat("tell: ", GetClientErrorString(tell_accepted, argv(1)), ".")); return; }
 581                         }
 582                 }
 583
 584                 default:
 585                         sprint(caller, "Incorrect parameters for ^2tell^7\n");
 586                 case CMD_REQUEST_USAGE:
 587                 {
 588                         sprint(caller, "\nUsage:^3 cmd tell client <message>\n");
 589                         sprint(caller, "  Where 'client' is the entity number or name of the player to send 'message' to.\n");
 590                         return;
 591                 }
 592         }
 593 }
 594
 595 void ClientCommand_voice(entity caller, float request, float argc, string command)
 596 {
 597         switch (request)
 598         {
 599                 case CMD_REQUEST_COMMAND:
 600                 {
 601                         if (argv(1) != "")
 602                         {
 603                                 entity e = GetVoiceMessage(argv(1));
 604                                 if (!e)
 605                                 {
 606                                         sprint(caller, sprintf("Invalid voice. Use one of: %s\n", allvoicesamples));
 607                                         return;
 608                                 }
 609                                 if (argc >= 3) VoiceMessage(caller, e, substring(command, argv_start_index(2), argv_end_index(-1) - argv_start_index(2)));
 610                                 else VoiceMessage(caller, e, "");
 611
 612                                 return;
 613                         }
 614                 }
 615
 616                 default:
 617                         sprint(caller, "Incorrect parameters for ^2voice^7\n");
 618                 case CMD_REQUEST_USAGE:
 619                 {
 620                         sprint(caller, "\nUsage:^3 cmd voice messagetype <soundname>\n");
 621                         sprint(caller, "  'messagetype' is the type of broadcast to do, like team only or such,\n");
 622                         sprint(caller, "  and 'soundname' is the string/filename of the sound/voice message to play.\n");
 623                         return;
 624                 }
 625         }
 626 }
 627
 628 /* use this when creating a new command, making sure to place it in alphabetical order... also,
 629 ** ADD ALL NEW COMMANDS TO commands.cfg WITH PROPER ALIASES IN THE SAME FASHION!
 630 void ClientCommand_(entity caller, float request)
 631 {
 632     switch(request)
 633     {
 634         case CMD_REQUEST_COMMAND:
 635         {
 636
 637             return; // never fall through to usage
 638         }
 639
 640         default:
 641         case CMD_REQUEST_USAGE:
 642         {
 643             sprint(caller, "\nUsage:^3 cmd \n");
 644             sprint(caller, "  No arguments required.\n");
 645             return;
 646         }
 647     }
 648 }
 649 */
 650
 651
 652 // =====================================
 653 //  Macro system for networked commands
 654 // =====================================
 655
 656 // Do not hard code aliases for these, instead create them in commands.cfg... also: keep in alphabetical order, please ;)
 657 #define CLIENT_COMMANDS(ent, request, arguments, command) \
 658         CLIENT_COMMAND("autoswitch", ClientCommand_autoswitch(ent, request, arguments), "Whether or not to switch automatically when getting a better weapon") \
 659         CLIENT_COMMAND("clientversion", ClientCommand_clientversion(ent, request, arguments), "Release version of the game") \
 660         CLIENT_COMMAND("mv_getpicture", ClientCommand_mv_getpicture(ent, request, arguments), "Retrieve mapshot picture from the server") \
 661         CLIENT_COMMAND("join", ClientCommand_join(ent, request), "Become a player in the game") \
 662         CLIENT_COMMAND("physics", ClientCommand_physics(ent, request, arguments), "Change physics set") \
 663         CLIENT_COMMAND("ready", ClientCommand_ready(ent, request), "Qualify as ready to end warmup stage (or restart server if allowed)") \
 664         CLIENT_COMMAND("say", ClientCommand_say(ent, request, arguments, command), "Print a message to chat to all players") \
 665         CLIENT_COMMAND("say_team", ClientCommand_say_team(ent, request, arguments, command), "Print a message to chat to all team mates") \
 666         CLIENT_COMMAND("selectteam", ClientCommand_selectteam(ent, request, arguments), "Attempt to choose a team to join into") \
 667         CLIENT_COMMAND("selfstuff", ClientCommand_selfstuff(ent, request, command), "Stuffcmd a command to your own client") \
 668         CLIENT_COMMAND("sentcvar", ClientCommand_sentcvar(ent, request, arguments, command), "New system for sending a client cvar to the server") \
 669         CLIENT_COMMAND("spectate", ClientCommand_spectate(ent, request), "Become an observer") \
 670         CLIENT_COMMAND("suggestmap", ClientCommand_suggestmap(ent, request, arguments), "Suggest a map to the mapvote at match end") \
 671         CLIENT_COMMAND("tell", ClientCommand_tell(ent, request, arguments, command), "Send a message directly to a player") \
 672         CLIENT_COMMAND("voice", ClientCommand_voice(ent, request, arguments, command), "Send voice message via sound") \
 673         CLIENT_COMMAND("minigame", ClientCommand_minigame(ent, request, arguments, command), "Start a minigame") \
 674         /* nothing */
 675
 676 void ClientCommand_macro_help(entity caller)
 677 {
 678         #define CLIENT_COMMAND(name, function, description) \
 679                 { sprint(caller, "  ^2", name, "^7: ", description, "\n"); }
 680
 681         CLIENT_COMMANDS(NULL, 0, 0, "");
 682 #undef CLIENT_COMMAND
 683 }
 684
 685 float ClientCommand_macro_command(float argc, entity caller, string command)
 686 {
 687         #define CLIENT_COMMAND(name, function, description) \
 688                 { if (name == strtolower(argv(0))) { function; return true; } }
 689
 690         CLIENT_COMMANDS(caller, CMD_REQUEST_COMMAND, argc, command);
 691 #undef CLIENT_COMMAND
 692
 693         return false;
 694 }
 695
 696 float ClientCommand_macro_usage(float argc, entity caller)
 697 {
 698         #define CLIENT_COMMAND(name, function, description) \
 699                 { if (name == strtolower(argv(1))) { function; return true; } }
 700
 701         CLIENT_COMMANDS(caller, CMD_REQUEST_USAGE, argc, "");
 702 #undef CLIENT_COMMAND
 703
 704         return false;
 705 }
 706
 707 void ClientCommand_macro_write_aliases(float fh)
 708 {
 709         #define CLIENT_COMMAND(name, function, description) \
 710                 { CMD_Write_Alias("qc_cmd_cmd", name, description); }
 711
 712         CLIENT_COMMANDS(NULL, 0, 0, "");
 713 #undef CLIENT_COMMAND
 714 }
 715
 716 // ======================================
 717 //  Main Function Called By Engine (cmd)
 718 // ======================================
 719 // If this function exists, server game code parses clientcommand before the engine code gets it.
 720
 721 void SV_ParseClientCommand(entity this, string command)
 722 {
 723         // If invalid UTF-8, don't even parse it
 724         string command2 = "";
 725         float len = strlen(command);
 726         float i;
 727         for (i = 0; i < len; ++i)
 728                 command2 = strcat(command2, chr2str(str2chr(command, i)));
 729         if (command != command2) return;
 730
 731         // if we're banned, don't even parse the command
 732         if (Ban_MaybeEnforceBanOnce(this)) return;
 733
 734         float argc = tokenize_console(command);
 735
 736         // Guide for working with argc arguments by example:
 737         // argc:   1    - 2      - 3     - 4
 738         // argv:   0    - 1      - 2     - 3
 739         // cmd     vote - master - login - password
 740
 741         // for floodcheck
 742         switch (strtolower(argv(0)))
 743         {
 744                 // exempt commands which are not subject to floodcheck
 745                 case "begin": break;                               // handled by engine in host_cmd.c
 746                 case "download": break;                            // handled by engine in cl_parse.c
 747                 case "mv_getpicture": break;                       // handled by server in this file
 748                 case "pause": break;                               // handled by engine in host_cmd.c
 749                 case "prespawn": break;                            // handled by engine in host_cmd.c
 750                 case "sentcvar": break;                            // handled by server in this file
 751                 case "spawn": break;                               // handled by engine in host_cmd.c
 752                 case "c2s": Net_ClientCommand(this, command); return; // handled by net.qh
 753
 754                 default:
 755                         if (SV_ParseClientCommand_floodcheck(this)) break; // "true": continue, as we're not flooding yet
 756                         else return;                                   // "false": not allowed to continue, halt // print("^1ERROR: ^7ANTISPAM CAUGHT: ", command, ".\n");
 757         }
 758
 759         /* NOTE: should this be disabled? It can be spammy perhaps, but hopefully it's okay for now */
 760         if (argv(0) == "help")
 761         {
 762                 if (argc == 1)
 763                 {
 764                         sprint(this, "\nClient networked commands:\n");
 765                         ClientCommand_macro_help(this);
 766
 767                         sprint(this, "\nCommon networked commands:\n");
 768                         CommonCommand_macro_help(this);
 769
 770                         sprint(this, "\nUsage:^3 cmd COMMAND...^7, where possible commands are listed above.\n");
 771                         sprint(this, "For help about a specific command, type cmd help COMMAND\n");
 772                         return;
 773                 }
 774                 else if (CommonCommand_macro_usage(argc, this))  // Instead of trying to call a command, we're going to see detailed information about it
 775                 {
 776                         return;
 777                 }
 778                 else if (ClientCommand_macro_usage(argc, this))  // same, but for normal commands now
 779                 {
 780                         return;
 781                 }
 782         }
 783         else if (MUTATOR_CALLHOOK(SV_ParseClientCommand, this, strtolower(argv(0)), argc, command))
 784         {
 785                 return;  // handled by a mutator
 786         }
 787         else if (CheatCommand(this, argc))
 788         {
 789                 return;  // handled by server/cheats.qc
 790         }
 791         else if (CommonCommand_macro_command(argc, this, command))
 792         {
 793                 return;                                          // handled by server/command/common.qc
 794         }
 795         else if (ClientCommand_macro_command(argc, this, command)) // continue as usual and scan for normal commands
 796         {
 797                 return;                                          // handled by one of the above ClientCommand_* functions
 798         }
 799         else
 800         {
 801                 clientcommand(this, command);
 802         }
 803 }