qcsrc/server/command/common.qc

   1 #include "common.qh"
   2 #include <common/command/command.qh>
   3 #include "common.qh"
   4
   5 #include "../scores.qh"
   6
   7 #include <common/monsters/all.qh>
   8 #include <common/notifications/all.qh>
   9 #include <lib/warpzone/common.qh>
  10
  11
  12 // ====================================================
  13 //  Shared code for server commands, written by Samual
  14 //  Last updated: December 27th, 2011
  15 // ====================================================
  16
  17 // select the proper prefix for usage and other messages
  18 string GetCommandPrefix(entity caller)
  19 {
  20         if (caller) return "cmd";
  21         else return "sv_cmd";
  22 }
  23
  24 // if client return player nickname, or if server return admin nickname
  25 string GetCallerName(entity caller)
  26 {
  27         if (caller) return caller.netname;
  28         else return admin_name();  // ((autocvar_sv_adminnick != "") ? autocvar_sv_adminnick : autocvar_hostname);
  29 }
  30
  31 // verify that the client provided is acceptable for kicking
  32 float VerifyKickableEntity(entity client)
  33 {
  34         if (!IS_REAL_CLIENT(client)) return CLIENT_NOT_REAL;
  35         return CLIENT_ACCEPTABLE;
  36 }
  37
  38 // verify that the client provided is acceptable for use
  39 float VerifyClientEntity(entity client, float must_be_real, float must_be_bots)
  40 {
  41         if (!IS_CLIENT(client)) return CLIENT_DOESNT_EXIST;
  42         else if (must_be_real && !IS_REAL_CLIENT(client)) return CLIENT_NOT_REAL;
  43         else if (must_be_bots && !IS_BOT_CLIENT(client)) return CLIENT_NOT_BOT;
  44
  45         return CLIENT_ACCEPTABLE;
  46 }
  47
  48 // if the client is not acceptable, return a string to be used for error messages
  49 string GetClientErrorString_color(float clienterror, string original_input, string col)
  50 {
  51         switch (clienterror)
  52         {
  53                 case CLIENT_DOESNT_EXIST:
  54                 { return strcat(col, "Client '", original_input, col, "' doesn't exist");
  55                 }
  56                 case CLIENT_NOT_REAL:
  57                 { return strcat(col, "Client '", original_input, col, "' is not real");
  58                 }
  59                 case CLIENT_NOT_BOT:
  60                 { return strcat(col, "Client '", original_input, col, "' is not a bot");
  61                 }
  62                 default:
  63                 { return "Incorrect usage of GetClientErrorString";
  64                 }
  65         }
  66 }
  67
  68 // is this entity number even in the possible range of entities?
  69 float VerifyClientNumber(float tmp_number)
  70 {
  71         if ((tmp_number < 1) || (tmp_number > maxclients)) return false;
  72         else return true;
  73 }
  74
  75 entity GetIndexedEntity(float argc, float start_index)
  76 {
  77         entity selection;
  78         float tmp_number, index;
  79         string tmp_string;
  80
  81         next_token = -1;
  82         index = start_index;
  83         selection = world;
  84
  85         if (argc > start_index)
  86         {
  87                 if (substring(argv(index), 0, 1) == "#")
  88                 {
  89                         tmp_string = substring(argv(index), 1, -1);
  90                         ++index;
  91
  92                         if (tmp_string != "")  // is it all one token? like #1
  93                         {
  94                                 tmp_number = stof(tmp_string);
  95                         }
  96                         else if (argc > index)  // no, it's two tokens? # 1
  97                         {
  98                                 tmp_number = stof(argv(index));
  99                                 ++index;
 100                         }
 101                         else
 102                         {
 103                                 tmp_number = 0;
 104                         }
 105                 }
 106                 else  // maybe it's ONLY a number?
 107                 {
 108                         tmp_number = stof(argv(index));
 109                         ++index;
 110                 }
 111
 112                 if (VerifyClientNumber(tmp_number))
 113                 {
 114                         selection = edict_num(tmp_number);  // yes, it was a number
 115                 }
 116                 else  // no, maybe it's a name?
 117                 {
 118                         FOREACH_CLIENT(true, LAMBDA(
 119                                 if(strdecolorize(it.netname) == strdecolorize(argv(start_index)))
 120                                 {
 121                                         selection = it;
 122                                         break; // no reason to keep looking
 123                                 }
 124                         ));
 125
 126                         index = (start_index + 1);
 127                 }
 128         }
 129
 130         next_token = index;
 131         // print(strcat("start_index: ", ftos(start_index), ", next_token: ", ftos(next_token), ", edict: ", ftos(num_for_edict(selection)), ".\n"));
 132         return selection;
 133 }
 134
 135 // find a player which matches the input string, and return their entity
 136 entity GetFilteredEntity(string input)
 137 {
 138         entity selection;
 139         float tmp_number;
 140
 141         if (substring(input, 0, 1) == "#") tmp_number = stof(substring(input, 1, -1));
 142         else tmp_number = stof(input);
 143
 144         if (VerifyClientNumber(tmp_number))
 145         {
 146                 selection = edict_num(tmp_number);
 147         }
 148         else
 149         {
 150                 selection = world;
 151                 FOREACH_CLIENT(true, LAMBDA(
 152                         if(strdecolorize(it.netname) == strdecolorize(input))
 153                         {
 154                                 selection = it;
 155                                 break; // no reason to keep looking
 156                         }
 157                 ));
 158         }
 159
 160         return selection;
 161 }
 162
 163 // same thing, but instead return their edict number
 164 float GetFilteredNumber(string input)
 165 {
 166         entity selection = GetFilteredEntity(input);
 167         float output;
 168
 169         output = etof(selection);
 170
 171         return output;
 172 }
 173
 174 // switch between sprint and print depending on whether the receiver is the server or a player
 175 void print_to(entity to, string input)
 176 {
 177         if (to) sprint(to, strcat(input, "\n"));
 178         else LOG_INFO(input, "\n");
 179 }
 180
 181 // ==========================================
 182 //  Supporting functions for common commands
 183 // ==========================================
 184
 185 // used by CommonCommand_timeout() and CommonCommand_timein() to handle game pausing and messaging and such.
 186 void timeout_handler_reset()
 187 {
 188         SELFPARAM();
 189         timeout_caller = world;
 190         timeout_time = 0;
 191         timeout_leadtime = 0;
 192
 193         remove(self);
 194 }
 195
 196 void timeout_handler_think()
 197 {
 198         SELFPARAM();
 199         switch (timeout_status)
 200         {
 201                 case TIMEOUT_ACTIVE:
 202                 {
 203                         if (timeout_time > 0)  // countdown is still going
 204                         {
 205                                 Send_Notification(NOTIF_ALL, world, MSG_CENTER, CENTER_TIMEOUT_ENDING, timeout_time);
 206
 207                                 if (timeout_time == autocvar_sv_timeout_resumetime) // play a warning sound when only <sv_timeout_resumetime> seconds are left
 208                                         Send_Notification(NOTIF_ALL, world, MSG_ANNCE, ANNCE_PREPARE);
 209
 210                                 self.nextthink = time + TIMEOUT_SLOWMO_VALUE;       // think again in one second
 211                                 timeout_time -= 1;                                  // decrease the time counter
 212                         }
 213                         else  // time to end the timeout
 214                         {
 215                                 timeout_status = TIMEOUT_INACTIVE;
 216
 217                                 // reset the slowmo value back to normal
 218                                 cvar_set("slowmo", ftos(orig_slowmo));
 219
 220                                 // unlock the view for players so they can move around again
 221                                 FOREACH_CLIENT(IS_PLAYER(it) && IS_REAL_CLIENT(it), LAMBDA(
 222                                         it.fixangle = false;
 223                                 ));
 224
 225                                 timeout_handler_reset();
 226                         }
 227
 228                         return;
 229                 }
 230
 231                 case TIMEOUT_LEADTIME:
 232                 {
 233                         if (timeout_leadtime > 0)  // countdown is still going
 234                         {
 235                                 Send_Notification(NOTIF_ALL, world, MSG_CENTER, CENTER_TIMEOUT_BEGINNING, timeout_leadtime);
 236
 237                                 self.nextthink = time + 1; // think again in one second
 238                                 timeout_leadtime -= 1;     // decrease the time counter
 239                         }
 240                         else  // time to begin the timeout
 241                         {
 242                                 timeout_status = TIMEOUT_ACTIVE;
 243
 244                                 // set the slowmo value to the timeout default slowmo value
 245                                 cvar_set("slowmo", ftos(TIMEOUT_SLOWMO_VALUE));
 246
 247                                 // reset all the flood variables
 248                                 FOREACH_CLIENT(true, LAMBDA(
 249                                         it.nickspamcount = it.nickspamtime = it.floodcontrol_chat =
 250                                                 it.floodcontrol_chatteam = it.floodcontrol_chattell =
 251                                                         it.floodcontrol_voice = it.floodcontrol_voiceteam = 0;
 252                                 ));
 253
 254                                 // copy .v_angle to .lastV_angle for every player in order to fix their view during pause (see PlayerPreThink)
 255                                 FOREACH_CLIENT(IS_PLAYER(it) && IS_REAL_CLIENT(it), LAMBDA(
 256                                         it.lastV_angle = it.v_angle;
 257                                 ));
 258
 259                                 self.nextthink = time;  // think again next frame to handle it under TIMEOUT_ACTIVE code
 260                         }
 261
 262                         return;
 263                 }
 264
 265
 266                 case TIMEOUT_INACTIVE:
 267                 default:
 268                 {
 269                         timeout_handler_reset();
 270                         return;
 271                 }
 272         }
 273 }
 274
 275
 276 // ===================================================
 277 //  Common commands used in both sv_cmd.qc and cmd.qc
 278 // ===================================================
 279
 280 void CommonCommand_cvar_changes(float request, entity caller)
 281 {
 282         switch (request)
 283         {
 284                 case CMD_REQUEST_COMMAND:
 285                 {
 286                         print_to(caller, cvar_changes);
 287                         return;  // never fall through to usage
 288                 }
 289
 290                 default:
 291                 case CMD_REQUEST_USAGE:
 292                 {
 293                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " cvar_changes"));
 294                         print_to(caller, "  No arguments required.");
 295                         print_to(caller, "See also: ^2cvar_purechanges^7");
 296                         return;
 297                 }
 298         }
 299 }
 300
 301 void CommonCommand_cvar_purechanges(float request, entity caller)
 302 {
 303         switch (request)
 304         {
 305                 case CMD_REQUEST_COMMAND:
 306                 {
 307                         print_to(caller, cvar_purechanges);
 308                         return;  // never fall through to usage
 309                 }
 310
 311                 default:
 312                 case CMD_REQUEST_USAGE:
 313                 {
 314                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " cvar_purechanges"));
 315                         print_to(caller, "  No arguments required.");
 316                         print_to(caller, "See also: ^2cvar_changes^7");
 317                         return;
 318                 }
 319         }
 320 }
 321
 322 void CommonCommand_editmob(int request, entity caller, int argc)
 323 {
 324         switch (request)
 325         {
 326                 case CMD_REQUEST_COMMAND:
 327                 {
 328                         if (autocvar_g_campaign) { print_to(caller, "Monster editing is disabled in singleplayer"); return; }
 329                         // no checks for g_monsters here, as it may be toggled mid match which existing monsters
 330
 331                         if (caller)
 332                         {
 333                                 makevectors(caller.v_angle);
 334                                 WarpZone_TraceLine(caller.origin + caller.view_ofs, caller.origin + caller.view_ofs + v_forward * 100, MOVE_NORMAL, caller);
 335                         }
 336
 337                         entity mon = trace_ent;
 338                         bool is_visible = IS_MONSTER(mon);
 339                         string argument = argv(2);
 340
 341                         switch (argv(1))
 342                         {
 343                                 case "name":
 344                                 {
 345                                         if (!caller) { print_to(caller, "Only players can edit monsters"); return; }
 346                                         if (!argument)   break;  // escape to usage
 347                                         if (!autocvar_g_monsters_edit) { print_to(caller, "Monster editing is disabled"); return; }
 348                                         if (mon.realowner != caller && autocvar_g_monsters_edit < 2) { print_to(caller, "This monster does not belong to you"); return; }
 349                                         if (!is_visible) { print_to(caller, "You must look at your monster to edit it"); return; }
 350
 351                                         string mon_oldname = mon.monster_name;
 352
 353                                         mon.monster_name = argument;
 354                                         if (mon.sprite)   WaypointSprite_UpdateSprites(mon.sprite, WP_Monster, WP_Null, WP_Null);
 355                                         print_to(caller, sprintf("Your pet '%s' is now known as '%s'", mon_oldname, mon.monster_name));
 356                                         return;
 357                                 }
 358                                 case "spawn":
 359                                 {
 360                                         if (!caller) { print_to(caller, "Only players can spawn monsters"); return; }
 361                                         if (!argv(2))   break;  // escape to usage
 362
 363                                         int moveflag, tmp_moncount = 0;
 364                                         string arg_lower = strtolower(argument);
 365                                         moveflag = (argv(3)) ? stof(argv(3)) : 1;  // follow owner if not defined
 366                                         ret_string = "Monster spawning is currently disabled by a mutator";
 367
 368                                         if (arg_lower == "list") { print_to(caller, monsterlist_reply); return; }
 369
 370                                         FOREACH_ENTITY_FLAGS(flags, FL_MONSTER, LAMBDA(
 371                                                 if(it.realowner == caller)
 372                                                         ++tmp_moncount;
 373                                         ));
 374
 375                                         if (!autocvar_g_monsters) { print_to(caller, "Monsters are disabled"); return; }
 376                                         if (autocvar_g_monsters_max <= 0 || autocvar_g_monsters_max_perplayer <= 0) { print_to(caller, "Monster spawning is disabled"); return; }
 377                                         if (!IS_PLAYER(caller)) { print_to(caller, "You must be playing to spawn a monster"); return; }
 378                                         if (MUTATOR_CALLHOOK(AllowMobSpawning)) { print_to(caller, ret_string); return; }
 379                                         if (caller.vehicle) { print_to(caller, "You can't spawn monsters while driving a vehicle"); return; }
 380                                         if (STAT(FROZEN, caller)) { print_to(caller, "You can't spawn monsters while frozen"); return; }
 381                                         if (IS_DEAD(caller)) { print_to(caller, "You can't spawn monsters while dead"); return; }
 382                                         if (tmp_moncount >= autocvar_g_monsters_max) { print_to(caller, "The maximum monster count has been reached"); return; }
 383                                         if (tmp_moncount >= autocvar_g_monsters_max_perplayer) { print_to(caller, "You can't spawn any more monsters"); return; }
 384
 385                                         bool found = false;
 386                                         for (int i = MON_FIRST; i <= MON_LAST; ++i)
 387                                         {
 388                                                 mon = get_monsterinfo(i);
 389                                                 if (mon.netname == arg_lower) { found = true; break; }
 390                                         }
 391
 392                                         if (!found && arg_lower != "random") { print_to(caller, "Invalid monster"); return; }
 393
 394                                         totalspawned += 1;
 395                                         WarpZone_TraceBox(CENTER_OR_VIEWOFS(caller), caller.mins, caller.maxs, CENTER_OR_VIEWOFS(caller) + v_forward * 150, true, caller);
 396                                         mon = spawnmonster(arg_lower, 0, caller, caller, trace_endpos, false, false, moveflag);
 397                                         print_to(caller, strcat("Spawned ", mon.monster_name));
 398                                         return;
 399                                 }
 400                                 case "kill":
 401                                 {
 402                                         if (!caller) { print_to(caller, "Only players can kill monsters"); return; }
 403                                         if (mon.realowner != caller && autocvar_g_monsters_edit < 2) { print_to(caller, "This monster does not belong to you"); return; }
 404                                         if (!is_visible) { print_to(caller, "You must look at your monster to edit it"); return; }
 405
 406                                         Damage(mon, world, world, mon.health + mon.max_health + 200, DEATH_KILL.m_id, mon.origin, '0 0 0');
 407                                         print_to(caller, strcat("Your pet '", mon.monster_name, "' has been brutally mutilated"));
 408                                         return;
 409                                 }
 410                                 case "skin":
 411                                 {
 412                                         if (!caller) { print_to(caller, "Only players can edit monsters"); return; }
 413                                         if (!argument)   break;  // escape to usage
 414                                         if (!autocvar_g_monsters_edit) { print_to(caller, "Monster editing is disabled"); return; }
 415                                         if (!is_visible) { print_to(caller, "You must look at your monster to edit it"); return; }
 416                                         if (mon.realowner != caller && autocvar_g_monsters_edit < 2) { print_to(caller, "This monster does not belong to you"); return; }
 417                                         if (mon.monsterid == MON_MAGE.monsterid) { print_to(caller, "Mage skins can't be changed"); return; }  // TODO
 418
 419                                         mon.skin = stof(argument);
 420                                         print_to(caller, strcat("Monster skin successfully changed to ", ftos(mon.skin)));
 421                                         return;
 422                                 }
 423                                 case "movetarget":
 424                                 {
 425                                         if (!caller) { print_to(caller, "Only players can edit monsters"); return; }
 426                                         if (!argument)   break;  // escape to usage
 427                                         if (!autocvar_g_monsters_edit) { print_to(caller, "Monster editing is disabled"); return; }
 428                                         if (!is_visible) { print_to(caller, "You must look at your monster to edit it"); return; }
 429                                         if (mon.realowner != caller && autocvar_g_monsters_edit < 2) { print_to(caller, "This monster does not belong to you"); return; }
 430
 431                                         mon.monster_moveflags = stof(argument);
 432                                         print_to(caller, strcat("Monster move target successfully changed to ", ftos(mon.monster_moveflags)));
 433                                         return;
 434                                 }
 435                                 case "butcher":
 436                                 {
 437                                         if (caller) { print_to(caller, "This command is not available to players"); return; }
 438                                         if (MUTATOR_CALLHOOK(AllowMobButcher)) { LOG_INFO(ret_string, "\n"); return; }
 439
 440                                         int tmp_remcount = 0;
 441
 442                                         FOREACH_ENTITY_FLAGS(flags, FL_MONSTER, LAMBDA(
 443                                                 Monster_Remove(it);
 444                                                 ++tmp_remcount;
 445                                         ));
 446
 447                                         monsters_total = monsters_killed = totalspawned = 0;
 448
 449                                         print_to(caller, (tmp_remcount) ? sprintf("Killed %d monster%s", tmp_remcount, (tmp_remcount == 1) ? "" : "s") : "No monsters to kill");
 450                                         return;
 451                                 }
 452                         }
 453                 }
 454
 455                 default:
 456                 case CMD_REQUEST_USAGE:
 457                 {
 458                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " editmob command [arguments]"));
 459                         print_to(caller, "  Where 'command' can be butcher spawn skin movetarget kill name");
 460                         print_to(caller, "  spawn, skin, movetarget and name require 'arguments'");
 461                         print_to(caller, "  spawn also takes arguments list and random");
 462                         print_to(caller, "  Monster will follow owner if third argument of spawn command is not defined");
 463                         return;
 464                 }
 465         }
 466 }
 467
 468 void CommonCommand_info(float request, entity caller, float argc)
 469 {
 470         switch (request)
 471         {
 472                 case CMD_REQUEST_COMMAND:
 473                 {
 474                         string command = builtin_cvar_string(strcat("sv_info_", argv(1)));
 475
 476                         if (command) wordwrap_sprint(command, 1000);
 477                         else print_to(caller, "ERROR: unsupported info command");
 478
 479                         return;  // never fall through to usage
 480                 }
 481
 482                 default:
 483                 case CMD_REQUEST_USAGE:
 484                 {
 485                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " info request"));
 486                         print_to(caller, "  Where 'request' is the suffixed string appended onto the request for cvar.");
 487                         return;
 488                 }
 489         }
 490 }
 491
 492 void CommonCommand_ladder(float request, entity caller)
 493 {
 494         switch (request)
 495         {
 496                 case CMD_REQUEST_COMMAND:
 497                 {
 498                         print_to(caller, ladder_reply);
 499                         return;  // never fall through to usage
 500                 }
 501
 502                 default:
 503                 case CMD_REQUEST_USAGE:
 504                 {
 505                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " ladder"));
 506                         print_to(caller, "  No arguments required.");
 507                         return;
 508                 }
 509         }
 510 }
 511
 512 void CommonCommand_lsmaps(float request, entity caller)
 513 {
 514         switch (request)
 515         {
 516                 case CMD_REQUEST_COMMAND:
 517                 {
 518                         print_to(caller, lsmaps_reply);
 519                         return;  // never fall through to usage
 520                 }
 521
 522                 default:
 523                 case CMD_REQUEST_USAGE:
 524                 {
 525                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " lsmaps"));
 526                         print_to(caller, "  No arguments required.");
 527                         return;
 528                 }
 529         }
 530 }
 531
 532 void CommonCommand_printmaplist(float request, entity caller)
 533 {
 534         switch (request)
 535         {
 536                 case CMD_REQUEST_COMMAND:
 537                 {
 538                         print_to(caller, maplist_reply);
 539                         return;  // never fall through to usage
 540                 }
 541
 542                 default:
 543                 case CMD_REQUEST_USAGE:
 544                 {
 545                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " printmaplist"));
 546                         print_to(caller, "  No arguments required.");
 547                         return;
 548                 }
 549         }
 550 }
 551
 552 void CommonCommand_rankings(float request, entity caller)
 553 {
 554         switch (request)
 555         {
 556                 case CMD_REQUEST_COMMAND:
 557                 {
 558                         print_to(caller, rankings_reply);
 559                         return;  // never fall through to usage
 560                 }
 561
 562                 default:
 563                 case CMD_REQUEST_USAGE:
 564                 {
 565                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " rankings"));
 566                         print_to(caller, "  No arguments required.");
 567                         return;
 568                 }
 569         }
 570 }
 571
 572 void CommonCommand_records(float request, entity caller)
 573 {
 574         switch (request)
 575         {
 576                 case CMD_REQUEST_COMMAND:
 577                 {
 578                         for (int i = 0; i < 10; ++i)
 579                                 if (records_reply[i] != "") print_to(caller, records_reply[i]);
 580
 581                         return;  // never fall through to usage
 582                 }
 583
 584                 default:
 585                 case CMD_REQUEST_USAGE:
 586                 {
 587                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " records"));
 588                         print_to(caller, "  No arguments required.");
 589                         return;
 590                 }
 591         }
 592 }
 593
 594 void CommonCommand_teamstatus(float request, entity caller)
 595 {
 596         switch (request)
 597         {
 598                 case CMD_REQUEST_COMMAND:
 599                 {
 600                         Score_NicePrint(caller);
 601                         return;  // never fall through to usage
 602                 }
 603
 604                 default:
 605                 case CMD_REQUEST_USAGE:
 606                 {
 607                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " teamstatus"));
 608                         print_to(caller, "  No arguments required.");
 609                         return;
 610                 }
 611         }
 612 }
 613
 614 void CommonCommand_time(float request, entity caller)
 615 {
 616         switch (request)
 617         {
 618                 case CMD_REQUEST_COMMAND:
 619                 {
 620                         print_to(caller, strcat("time = ", ftos(time)));
 621                         print_to(caller, strcat("frame start = ", ftos(gettime(GETTIME_FRAMESTART))));
 622                         print_to(caller, strcat("realtime = ", ftos(gettime(GETTIME_REALTIME))));
 623                         print_to(caller, strcat("hires = ", ftos(gettime(GETTIME_HIRES))));
 624                         print_to(caller, strcat("uptime = ", ftos(gettime(GETTIME_UPTIME))));
 625                         print_to(caller, strcat("localtime = ", strftime(true, "%a %b %e %H:%M:%S %Z %Y")));
 626                         print_to(caller, strcat("gmtime = ", strftime(false, "%a %b %e %H:%M:%S %Z %Y")));
 627                         return;
 628                 }
 629
 630                 default:
 631                 case CMD_REQUEST_USAGE:
 632                 {
 633                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " time"));
 634                         print_to(caller, "  No arguments required.");
 635                         return;
 636                 }
 637         }
 638 }
 639
 640 void CommonCommand_timein(float request, entity caller)
 641 {
 642         switch (request)
 643         {
 644                 case CMD_REQUEST_COMMAND:
 645                 {
 646                         if (!caller || autocvar_sv_timeout)
 647                         {
 648                                 if (!timeout_status) { print_to(caller, "^7Error: There is no active timeout called."); }
 649                                 else if (caller && (caller != timeout_caller))
 650                                 {
 651                                         print_to(caller, "^7Error: You are not allowed to stop the active timeout.");
 652                                 }
 653
 654                                 else  // everything should be okay, continue aborting timeout
 655                                 {
 656                                         switch (timeout_status)
 657                                         {
 658                                                 case TIMEOUT_LEADTIME:
 659                                                 {
 660                                                         timeout_status = TIMEOUT_INACTIVE;
 661                                                         timeout_time = 0;
 662                                                         timeout_handler.nextthink = time;  // timeout_handler has to take care of it immediately
 663                                                         bprint(strcat("^7The timeout was aborted by ", GetCallerName(caller), " !\n"));
 664                                                         return;
 665                                                 }
 666
 667                                                 case TIMEOUT_ACTIVE:
 668                                                 {
 669                                                         timeout_time = autocvar_sv_timeout_resumetime;
 670                                                         timeout_handler.nextthink = time;  // timeout_handler has to take care of it immediately
 671                                                         bprint(strcat("^1Attention: ^7", GetCallerName(caller), " resumed the game! Prepare for battle!\n"));
 672                                                         return;
 673                                                 }
 674
 675                                                 default: LOG_TRACE("timeout status was inactive, but this code was executed anyway?");
 676                                                         return;
 677                                         }
 678                                 }
 679                         }
 680                         else { print_to(caller, "^1Timeins are not allowed to be called, enable them with sv_timeout 1.\n"); }
 681
 682                         return;  // never fall through to usage
 683                 }
 684
 685                 default:
 686                 case CMD_REQUEST_USAGE:
 687                 {
 688                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " timein"));
 689                         print_to(caller, "  No arguments required.");
 690                         return;
 691                 }
 692         }
 693 }
 694
 695 void CommonCommand_timeout(float request, entity caller)  // DEAR GOD THIS COMMAND IS TERRIBLE.
 696 {
 697         switch (request)
 698         {
 699                 case CMD_REQUEST_COMMAND:
 700                 {
 701                         if (!caller || autocvar_sv_timeout)
 702                         {
 703                                 float last_possible_timeout = ((autocvar_timelimit * 60) - autocvar_sv_timeout_leadtime - 1);
 704
 705                                 if (timeout_status) { print_to(caller, "^7Error: A timeout is already active."); }
 706                                 else if (vote_called)
 707                                 {
 708                                         print_to(caller, "^7Error: You can not call a timeout while a vote is active.");
 709                                 }
 710                                 else if (warmup_stage && !g_warmup_allow_timeout)
 711                                 {
 712                                         print_to(caller, "^7Error: You can not call a timeout in warmup-stage.");
 713                                 }
 714                                 else if (time < game_starttime)
 715                                 {
 716                                         print_to(caller, "^7Error: You can not call a timeout while the map is being restarted.");
 717                                 }
 718                                 else if (caller && (caller.allowed_timeouts < 1))
 719                                 {
 720                                         print_to(caller, "^7Error: You already used all your timeout calls for this map.");
 721                                 }
 722                                 else if (caller && !IS_PLAYER(caller))
 723                                 {
 724                                         print_to(caller, "^7Error: You must be a player to call a timeout.");
 725                                 }
 726                                 else if ((autocvar_timelimit) && (last_possible_timeout < time - game_starttime))
 727                                 {
 728                                         print_to(caller, "^7Error: It is too late to call a timeout now!");
 729                                 }
 730
 731                                 else  // everything should be okay, proceed with starting the timeout
 732                                 {
 733                                         if (caller)   caller.allowed_timeouts -= 1;
 734                                         // write a bprint who started the timeout (and how many they have left)
 735                                         bprint(GetCallerName(caller), " ^7called a timeout", (caller ? strcat(" (", ftos(caller.allowed_timeouts), " timeout(s) left)") : ""), "!\n");
 736
 737                                         timeout_status = TIMEOUT_LEADTIME;
 738                                         timeout_caller = caller;
 739                                         timeout_time = autocvar_sv_timeout_length;
 740                                         timeout_leadtime = autocvar_sv_timeout_leadtime;
 741
 742                                         timeout_handler = spawn();
 743                                         timeout_handler.think = timeout_handler_think;
 744                                         timeout_handler.nextthink = time;  // always let the entity think asap
 745
 746                                         Send_Notification(NOTIF_ALL, world, MSG_ANNCE, ANNCE_TIMEOUT);
 747                                 }
 748                         }
 749                         else { print_to(caller, "^1Timeouts are not allowed to be called, enable them with sv_timeout 1.\n"); }
 750
 751                         return;  // never fall through to usage
 752                 }
 753
 754                 default:
 755                 case CMD_REQUEST_USAGE:
 756                 {
 757                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " timeout"));
 758                         print_to(caller, "  No arguments required.");
 759                         return;
 760                 }
 761         }
 762 }
 763
 764 void CommonCommand_who(float request, entity caller, float argc)
 765 {
 766         switch (request)
 767         {
 768                 case CMD_REQUEST_COMMAND:
 769                 {
 770                         float total_listed_players, is_bot;
 771
 772                         float privacy = (caller && autocvar_sv_status_privacy);
 773                         string separator = strreplace("%", " ", strcat((argv(1) ? argv(1) : " "), "^7"));
 774                         string tmp_netaddress, tmp_crypto_idfp;
 775
 776                         print_to(caller, strcat("List of client information", (privacy ? " (some data is hidden for privacy)" : ""), ":"));
 777                         print_to(caller, sprintf(strreplace(" ", separator, " %-4s %-20s %-5s %-3s %-9s %-16s %s "),
 778                                 "ent", "nickname", "ping", "pl", "time", "ip", "crypto_id"));
 779
 780                         total_listed_players = 0;
 781                         FOREACH_CLIENT(true, LAMBDA(
 782                                 is_bot = (IS_BOT_CLIENT(it));
 783
 784                                 if (is_bot)
 785                                 {
 786                                         tmp_netaddress = "null/botclient";
 787                                         tmp_crypto_idfp = "null/botclient";
 788                                 }
 789                                 else if (privacy)
 790                                 {
 791                                         tmp_netaddress = "hidden";
 792                                         tmp_crypto_idfp = "hidden";
 793                                 }
 794                                 else
 795                                 {
 796                                         tmp_netaddress = it.netaddress;
 797                                         tmp_crypto_idfp = it.crypto_idfp;
 798                                 }
 799
 800                                 print_to(caller, sprintf(strreplace(" ", separator, " #%-3d %-20.20s %-5d %-3d %-9s %-16s %s "),
 801                                         etof(it),
 802                                         it.netname,
 803                                         it.ping,
 804                                         it.ping_packetloss,
 805                                         process_time(1, time - it.jointime),
 806                                         tmp_netaddress,
 807                                         tmp_crypto_idfp));
 808
 809                                 ++total_listed_players;
 810                         ));
 811
 812                         print_to(caller, strcat("Finished listing ", ftos(total_listed_players), " client(s) out of ", ftos(maxclients), " slots."));
 813
 814                         return;  // never fall through to usage
 815                 }
 816
 817                 default:
 818                 case CMD_REQUEST_USAGE:
 819                 {
 820                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " who [separator]"));
 821                         print_to(caller, "  Where 'separator' is the optional string to separate the values with, default is a space.");
 822                         return;
 823                 }
 824         }
 825 }
 826
 827 /* use this when creating a new command, making sure to place it in alphabetical order... also,
 828 ** ADD ALL NEW COMMANDS TO commands.cfg WITH PROPER ALIASES IN THE SAME FASHION!
 829 void CommonCommand_(float request, entity caller)
 830 {
 831     switch(request)
 832     {
 833         case CMD_REQUEST_COMMAND:
 834         {
 835
 836             return; // never fall through to usage
 837         }
 838
 839         default:
 840         case CMD_REQUEST_USAGE:
 841         {
 842             print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " "));
 843             print_to(caller, "  No arguments required.");
 844             return;
 845         }
 846     }
 847 }
 848 */